lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 =head1 NAME
   4
   5 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   6
   7 =head1 DESCRIPTION
   8
   9 This module is a subclass of L<SQL::Abstract> and includes a number of
  10 DBIC-specific workarounds, not yet suitable for inclusion into the
  11 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  12 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  13 more info.
  14
  15 Currently the enhancements to L<SQL::Abstract> are:
  16
  17 =over
  18
  19 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  20
  21 =item * Support of functions in C<SELECT> lists
  22
  23 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  24
  25 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  26
  27 =back
  28
  29 =cut
  30
  31 use base qw/
  32   DBIx::Class::SQLMaker::LimitDialects
  33   SQL::Abstract
  34   Class::Accessor::Grouped
  35 /;
  36 use mro 'c3';
  37 use strict;
  38 use warnings;
  39 use Sub::Name 'subname';
  40 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract|^Try::Tiny/;
  41 use namespace::clean;
  42
  43 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  44
  45 BEGIN {
  46   # reinstall the carp()/croak() functions imported into SQL::Abstract
  47   # as Carp and Carp::Clan do not like each other much
  48   no warnings qw/redefine/;
  49   no strict qw/refs/;
  50   for my $f (qw/carp croak/) {
  51
  52     my $orig = \&{"SQL::Abstract::$f"};
  53     my $clan_import = \&{$f};
  54     *{"SQL::Abstract::$f"} = subname "SQL::Abstract::$f" =>
  55       sub {
  56         if (Carp::longmess() =~ /DBIx::Class::SQLMaker::[\w]+ .+? called \s at/x) {
  57           $clan_import->(@_);
  58         }
  59         else {
  60           goto $orig;
  61         }
  62       };
  63   }
  64 }
  65
  66 # the "oh noes offset/top without limit" constant
  67 # limited to 32 bits for sanity (and consistency,
  68 # since it is ultimately handed to sprintf %u)
  69 # Implemented as a method, since ::Storage::DBI also
  70 # refers to it (i.e. for the case of software_limit or
  71 # as the value to abuse with MSSQL ordered subqueries)
  72 sub __max_int { 0xFFFFFFFF };
  73
  74 # Handle limit-dialect selection
  75 sub select {
  76   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
  77
  78
  79   $fields = $self->_recurse_fields($fields);
  80
  81   if (defined $offset) {
  82     croak ('A supplied offset must be a non-negative integer')
  83       if ( $offset =~ /\D/ or $offset < 0 );
  84   }
  85   $offset ||= 0;
  86
  87   if (defined $limit) {
  88     croak ('A supplied limit must be a positive integer')
  89       if ( $limit =~ /\D/ or $limit <= 0 );
  90   }
  91   elsif ($offset) {
  92     $limit = $self->__max_int;
  93   }
  94
  95
  96   my ($sql, @bind);
  97   if ($limit) {
  98     # this is legacy code-flow from SQLA::Limit, it is not set in stone
  99
 100     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 101
 102     my $limiter =
 103       $self->can ('emulate_limit')  # also backcompat hook from SQLA::Limit
 104         ||
 105       do {
 106         my $dialect = $self->limit_dialect
 107           or croak "Unable to generate SQL-limit - no limit dialect specified on $self, and no emulate_limit method found";
 108         $self->can ("_$dialect")
 109           or croak (__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 110       }
 111     ;
 112
 113     $sql = $self->$limiter ($sql, $rs_attrs, $limit, $offset);
 114   }
 115   else {
 116     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 117   }
 118
 119   push @{$self->{where_bind}}, @bind;
 120
 121 # this *must* be called, otherwise extra binds will remain in the sql-maker
 122   my @all_bind = $self->_assemble_binds;
 123
 124   $sql .= $self->_lock_select ($rs_attrs->{for})
 125     if $rs_attrs->{for};
 126
 127   return wantarray ? ($sql, @all_bind) : $sql;
 128 }
 129
 130 sub _assemble_binds {
 131   my $self = shift;
 132   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/from where having order/);
 133 }
 134
 135 my $for_syntax = {
 136   update => 'FOR UPDATE',
 137   shared => 'FOR SHARE',
 138 };
 139 sub _lock_select {
 140   my ($self, $type) = @_;
 141   my $sql = $for_syntax->{$type} || croak "Unknown SELECT .. FOR type '$type' requested";
 142   return " $sql";
 143 }
 144
 145 # Handle default inserts
 146 sub insert {
 147 # optimized due to hotttnesss
 148 #  my ($self, $table, $data, $options) = @_;
 149
 150   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 151   # which is sadly understood only by MySQL. Change default behavior here,
 152   # until SQLA2 comes with proper dialect support
 153   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 154     my $sql = "INSERT INTO $_[1] DEFAULT VALUES";
 155
 156     if (my $ret = ($_[3]||{})->{returning} ) {
 157       $sql .= $_[0]->_insert_returning ($ret);
 158     }
 159
 160     return $sql;
 161   }
 162
 163   next::method(@_);
 164 }
 165
 166 sub _recurse_fields {
 167   my ($self, $fields) = @_;
 168   my $ref = ref $fields;
 169   return $self->_quote($fields) unless $ref;
 170   return $$fields if $ref eq 'SCALAR';
 171
 172   if ($ref eq 'ARRAY') {
 173     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 174   }
 175   elsif ($ref eq 'HASH') {
 176     my %hash = %$fields;  # shallow copy
 177
 178     my $as = delete $hash{-as};   # if supplied
 179
 180     my ($func, $args, @toomany) = %hash;
 181
 182     # there should be only one pair
 183     if (@toomany) {
 184       croak "Malformed select argument - too many keys in hash: " . join (',', keys %$fields );
 185     }
 186
 187     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 188       croak (
 189         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 190        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 191        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 192       );
 193     }
 194
 195     my $select = sprintf ('%s( %s )%s',
 196       $self->_sqlcase($func),
 197       $self->_recurse_fields($args),
 198       $as
 199         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 200         : ''
 201     );
 202
 203     return $select;
 204   }
 205   # Is the second check absolutely necessary?
 206   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 207     return $self->_fold_sqlbind( $fields );
 208   }
 209   else {
 210     croak($ref . qq{ unexpected in _recurse_fields()})
 211   }
 212 }
 213
 214
 215 # this used to be a part of _order_by but is broken out for clarity.
 216 # What we have been doing forever is hijacking the $order arg of
 217 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 218 # then pretty much the entire resultset attr-hash, as more and more
 219 # things in the SQLA space need to have mopre info about the $rs they
 220 # create SQL for. The alternative would be to keep expanding the
 221 # signature of _select with more and more positional parameters, which
 222 # is just gross. All hail SQLA2!
 223 sub _parse_rs_attrs {
 224   my ($self, $arg) = @_;
 225
 226   my $sql = '';
 227
 228   if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 229     $sql .= $self->_sqlcase(' group by ') . $g;
 230   }
 231
 232   if (defined $arg->{having}) {
 233     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 234     push(@{$self->{having_bind}}, @bind);
 235     $sql .= $self->_sqlcase(' having ') . $frag;
 236   }
 237
 238   if (defined $arg->{order_by}) {
 239     $sql .= $self->_order_by ($arg->{order_by});
 240   }
 241
 242   return $sql;
 243 }
 244
 245 sub _order_by {
 246   my ($self, $arg) = @_;
 247
 248   # check that we are not called in legacy mode (order_by as 4th argument)
 249   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 250     return $self->_parse_rs_attrs ($arg);
 251   }
 252   else {
 253     my ($sql, @bind) = $self->next::method($arg);
 254     push @{$self->{order_bind}}, @bind;
 255     return $sql;
 256   }
 257 }
 258
 259 sub _table {
 260 # optimized due to hotttnesss
 261 #  my ($self, $from) = @_;
 262   if (my $ref = ref $_[1] ) {
 263     if ($ref eq 'ARRAY') {
 264       return $_[0]->_recurse_from(@{$_[1]});
 265     }
 266     elsif ($ref eq 'HASH') {
 267       return $_[0]->_make_as($_[1]);
 268     }
 269   }
 270
 271   return $_[0]->next::method ($_[1]);
 272 }
 273
 274 sub _generate_join_clause {
 275     my ($self, $join_type) = @_;
 276
 277     return sprintf ('%s JOIN ',
 278       $join_type ?  ' ' . uc($join_type) : ''
 279     );
 280 }
 281
 282 sub _recurse_from {
 283   my ($self, $from, @join) = @_;
 284   my @sqlf;
 285   push(@sqlf, $self->_make_as($from));
 286   foreach my $j (@join) {
 287     my ($to, $on) = @$j;
 288
 289
 290     # check whether a join type exists
 291     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 292     my $join_type;
 293     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 294       $join_type = $to_jt->{-join_type};
 295       $join_type =~ s/^\s+ | \s+$//xg;
 296     }
 297
 298     $join_type = $self->{_default_jointype} if not defined $join_type;
 299
 300     push @sqlf, $self->_generate_join_clause( $join_type );
 301
 302     if (ref $to eq 'ARRAY') {
 303       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 304     } else {
 305       push(@sqlf, $self->_make_as($to));
 306     }
 307     push(@sqlf, ' ON ', $self->_join_condition($on));
 308   }
 309   return join('', @sqlf);
 310 }
 311
 312 sub _fold_sqlbind {
 313   my ($self, $sqlbind) = @_;
 314
 315   my @sqlbind = @$$sqlbind; # copy
 316   my $sql = shift @sqlbind;
 317   push @{$self->{from_bind}}, @sqlbind;
 318
 319   return $sql;
 320 }
 321
 322 sub _make_as {
 323   my ($self, $from) = @_;
 324   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 325                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 326                         : $self->_quote($_))
 327                        } reverse each %{$self->_skip_options($from)});
 328 }
 329
 330 sub _skip_options {
 331   my ($self, $hash) = @_;
 332   my $clean_hash = {};
 333   $clean_hash->{$_} = $hash->{$_}
 334     for grep {!/^-/} keys %$hash;
 335   return $clean_hash;
 336 }
 337
 338 sub _join_condition {
 339   my ($self, $cond) = @_;
 340   if (ref $cond eq 'HASH') {
 341     my %j;
 342     for (keys %$cond) {
 343       my $v = $cond->{$_};
 344       if (ref $v) {
 345         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 346             if ref($v) ne 'SCALAR';
 347         $j{$_} = $v;
 348       }
 349       else {
 350         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 351       }
 352     };
 353     return scalar($self->_recurse_where(\%j));
 354   } elsif (ref $cond eq 'ARRAY') {
 355     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 356   } else {
 357     croak "Can't handle this yet!";
 358   }
 359 }
 360
 361 1;
 362
 363 =head1 AUTHORS
 364
 365 See L<DBIx::Class/CONTRIBUTORS>.
 366
 367 =head1 LICENSE
 368
 369 You may distribute this code under the same terms as Perl itself.
 370
 371 =cut