lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 =head1 NAME
   4
   5 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   6
   7 =head1 DESCRIPTION
   8
   9 This module is a subclass of L<SQL::Abstract> and includes a number of
  10 DBIC-specific workarounds, not yet suitable for inclusion into the
  11 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  12 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  13 more info.
  14
  15 Currently the enhancements to L<SQL::Abstract> are:
  16
  17 =over
  18
  19 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  20
  21 =item * Support of functions in C<SELECT> lists
  22
  23 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  24
  25 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  26
  27 =back
  28
  29 =cut
  30
  31 use base qw/
  32   DBIx::Class::SQLMaker::LimitDialects
  33   SQL::Abstract
  34   Class::Accessor::Grouped
  35 /;
  36 use mro 'c3';
  37 use strict;
  38 use warnings;
  39 use Sub::Name 'subname';
  40 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract|^Try::Tiny/;
  41 use namespace::clean;
  42
  43 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  44
  45 BEGIN {
  46   # reinstall the carp()/croak() functions imported into SQL::Abstract
  47   # as Carp and Carp::Clan do not like each other much
  48   no warnings qw/redefine/;
  49   no strict qw/refs/;
  50   for my $f (qw/carp croak/) {
  51
  52     my $orig = \&{"SQL::Abstract::$f"};
  53     my $clan_import = \&{$f};
  54     *{"SQL::Abstract::$f"} = subname "SQL::Abstract::$f" =>
  55       sub {
  56         if (Carp::longmess() =~ /DBIx::Class::SQLMaker::[\w]+ .+? called \s at/x) {
  57           $clan_import->(@_);
  58         }
  59         else {
  60           goto $orig;
  61         }
  62       };
  63   }
  64 }
  65
  66 # the "oh noes offset/top without limit" constant
  67 # limited to 32 bits for sanity (and consistency,
  68 # since it is ultimately handed to sprintf %u)
  69 # Implemented as a method, since ::Storage::DBI also
  70 # refers to it (i.e. for the case of software_limit or
  71 # as the value to abuse with MSSQL ordered subqueries)
  72 sub __max_int { 0xFFFFFFFF };
  73
  74 # Handle limit-dialect selection
  75 sub select {
  76   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
  77
  78
  79   $fields = $self->_recurse_fields($fields);
  80
  81   if (defined $offset) {
  82     croak ('A supplied offset must be a non-negative integer')
  83       if ( $offset =~ /\D/ or $offset < 0 );
  84   }
  85   $offset ||= 0;
  86
  87   if (defined $limit) {
  88     croak ('A supplied limit must be a positive integer')
  89       if ( $limit =~ /\D/ or $limit <= 0 );
  90   }
  91   elsif ($offset) {
  92     $limit = $self->__max_int;
  93   }
  94
  95
  96   my ($sql, @bind);
  97   if ($limit) {
  98     # this is legacy code-flow from SQLA::Limit, it is not set in stone
  99
 100     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 101
 102     my $limiter =
 103       $self->can ('emulate_limit')  # also backcompat hook from SQLA::Limit
 104         ||
 105       do {
 106         my $dialect = $self->limit_dialect
 107           or croak "Unable to generate SQL-limit - no limit dialect specified on $self, and no emulate_limit method found";
 108         $self->can ("_$dialect")
 109           or croak (__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 110       }
 111     ;
 112
 113     $sql = $self->$limiter ($sql, $rs_attrs, $limit, $offset);
 114   }
 115   else {
 116     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 117   }
 118
 119   push @{$self->{where_bind}}, @bind;
 120
 121 # this *must* be called, otherwise extra binds will remain in the sql-maker
 122   my @all_bind = $self->_assemble_binds;
 123
 124   return wantarray ? ($sql, @all_bind) : $sql;
 125 }
 126
 127 sub _assemble_binds {
 128   my $self = shift;
 129   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/from where having order/);
 130 }
 131
 132 # Handle default inserts
 133 sub insert {
 134 # optimized due to hotttnesss
 135 #  my ($self, $table, $data, $options) = @_;
 136
 137   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 138   # which is sadly understood only by MySQL. Change default behavior here,
 139   # until SQLA2 comes with proper dialect support
 140   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 141     my $sql = "INSERT INTO $_[1] DEFAULT VALUES";
 142
 143     if (my $ret = ($_[3]||{})->{returning} ) {
 144       $sql .= $_[0]->_insert_returning ($ret);
 145     }
 146
 147     return $sql;
 148   }
 149
 150   next::method(@_);
 151 }
 152
 153 sub _recurse_fields {
 154   my ($self, $fields) = @_;
 155   my $ref = ref $fields;
 156   return $self->_quote($fields) unless $ref;
 157   return $$fields if $ref eq 'SCALAR';
 158
 159   if ($ref eq 'ARRAY') {
 160     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 161   }
 162   elsif ($ref eq 'HASH') {
 163     my %hash = %$fields;  # shallow copy
 164
 165     my $as = delete $hash{-as};   # if supplied
 166
 167     my ($func, $args, @toomany) = %hash;
 168
 169     # there should be only one pair
 170     if (@toomany) {
 171       croak "Malformed select argument - too many keys in hash: " . join (',', keys %$fields );
 172     }
 173
 174     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 175       croak (
 176         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 177        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 178        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 179       );
 180     }
 181
 182     my $select = sprintf ('%s( %s )%s',
 183       $self->_sqlcase($func),
 184       $self->_recurse_fields($args),
 185       $as
 186         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 187         : ''
 188     );
 189
 190     return $select;
 191   }
 192   # Is the second check absolutely necessary?
 193   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 194     return $self->_fold_sqlbind( $fields );
 195   }
 196   else {
 197     croak($ref . qq{ unexpected in _recurse_fields()})
 198   }
 199 }
 200
 201 my $for_syntax = {
 202   update => 'FOR UPDATE',
 203   shared => 'FOR SHARE',
 204 };
 205
 206 # this used to be a part of _order_by but is broken out for clarity.
 207 # What we have been doing forever is hijacking the $order arg of
 208 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 209 # then pretty much the entire resultset attr-hash, as more and more
 210 # things in the SQLA space need to have mopre info about the $rs they
 211 # create SQL for. The alternative would be to keep expanding the
 212 # signature of _select with more and more positional parameters, which
 213 # is just gross. All hail SQLA2!
 214 sub _parse_rs_attrs {
 215   my ($self, $arg) = @_;
 216
 217   my $sql = '';
 218
 219   if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 220     $sql .= $self->_sqlcase(' group by ') . $g;
 221   }
 222
 223   if (defined $arg->{having}) {
 224     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 225     push(@{$self->{having_bind}}, @bind);
 226     $sql .= $self->_sqlcase(' having ') . $frag;
 227   }
 228
 229   if (defined $arg->{order_by}) {
 230     $sql .= $self->_order_by ($arg->{order_by});
 231   }
 232
 233   if (my $for = $arg->{for}) {
 234     $sql .= " $for_syntax->{$for}" if $for_syntax->{$for};
 235   }
 236
 237   return $sql;
 238 }
 239
 240 sub _order_by {
 241   my ($self, $arg) = @_;
 242
 243   # check that we are not called in legacy mode (order_by as 4th argument)
 244   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 245     return $self->_parse_rs_attrs ($arg);
 246   }
 247   else {
 248     my ($sql, @bind) = $self->next::method($arg);
 249     push @{$self->{order_bind}}, @bind;
 250     return $sql;
 251   }
 252 }
 253
 254 sub _table {
 255 # optimized due to hotttnesss
 256 #  my ($self, $from) = @_;
 257   if (my $ref = ref $_[1] ) {
 258     if ($ref eq 'ARRAY') {
 259       return $_[0]->_recurse_from(@{$_[1]});
 260     }
 261     elsif ($ref eq 'HASH') {
 262       return $_[0]->_make_as($_[1]);
 263     }
 264   }
 265
 266   return $_[0]->next::method ($_[1]);
 267 }
 268
 269 sub _generate_join_clause {
 270     my ($self, $join_type) = @_;
 271
 272     return sprintf ('%s JOIN ',
 273       $join_type ?  ' ' . uc($join_type) : ''
 274     );
 275 }
 276
 277 sub _recurse_from {
 278   my ($self, $from, @join) = @_;
 279   my @sqlf;
 280   push(@sqlf, $self->_make_as($from));
 281   foreach my $j (@join) {
 282     my ($to, $on) = @$j;
 283
 284
 285     # check whether a join type exists
 286     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 287     my $join_type;
 288     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 289       $join_type = $to_jt->{-join_type};
 290       $join_type =~ s/^\s+ | \s+$//xg;
 291     }
 292
 293     $join_type = $self->{_default_jointype} if not defined $join_type;
 294
 295     push @sqlf, $self->_generate_join_clause( $join_type );
 296
 297     if (ref $to eq 'ARRAY') {
 298       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 299     } else {
 300       push(@sqlf, $self->_make_as($to));
 301     }
 302     push(@sqlf, ' ON ', $self->_join_condition($on));
 303   }
 304   return join('', @sqlf);
 305 }
 306
 307 sub _fold_sqlbind {
 308   my ($self, $sqlbind) = @_;
 309
 310   my @sqlbind = @$$sqlbind; # copy
 311   my $sql = shift @sqlbind;
 312   push @{$self->{from_bind}}, @sqlbind;
 313
 314   return $sql;
 315 }
 316
 317 sub _make_as {
 318   my ($self, $from) = @_;
 319   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 320                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 321                         : $self->_quote($_))
 322                        } reverse each %{$self->_skip_options($from)});
 323 }
 324
 325 sub _skip_options {
 326   my ($self, $hash) = @_;
 327   my $clean_hash = {};
 328   $clean_hash->{$_} = $hash->{$_}
 329     for grep {!/^-/} keys %$hash;
 330   return $clean_hash;
 331 }
 332
 333 sub _join_condition {
 334   my ($self, $cond) = @_;
 335   if (ref $cond eq 'HASH') {
 336     my %j;
 337     for (keys %$cond) {
 338       my $v = $cond->{$_};
 339       if (ref $v) {
 340         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 341             if ref($v) ne 'SCALAR';
 342         $j{$_} = $v;
 343       }
 344       else {
 345         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 346       }
 347     };
 348     return scalar($self->_recurse_where(\%j));
 349   } elsif (ref $cond eq 'ARRAY') {
 350     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 351   } else {
 352     croak "Can't handle this yet!";
 353   }
 354 }
 355
 356 1;
 357
 358 =head1 AUTHORS
 359
 360 See L<DBIx::Class/CONTRIBUTORS>.
 361
 362 =head1 LICENSE
 363
 364 You may distribute this code under the same terms as Perl itself.
 365
 366 =cut