lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   9
  10 =head1 DESCRIPTION
  11
  12 This module is a subclass of L<SQL::Abstract> and includes a number of
  13 DBIC-specific workarounds, not yet suitable for inclusion into the
  14 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  15 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  16 more info.
  17
  18 Currently the enhancements to L<SQL::Abstract> are:
  19
  20 =over
  21
  22 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  23
  24 =item * Support of functions in C<SELECT> lists
  25
  26 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  27
  28 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  29
  30 =back
  31
  32 =cut
  33
  34 use base qw/
  35   DBIx::Class::SQLMaker::LimitDialects
  36   SQL::Abstract
  37   DBIx::Class
  38 /;
  39 use mro 'c3';
  40
  41 use Sub::Name 'subname';
  42 use DBIx::Class::Carp;
  43 use DBIx::Class::Exception;
  44 use namespace::clean;
  45
  46 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  47
  48 # for when I need a normalized l/r pair
  49 sub _quote_chars {
  50   map
  51     { defined $_ ? $_ : '' }
  52     ( ref $_[0]->{quote_char} ? (@{$_[0]->{quote_char}}) : ( ($_[0]->{quote_char}) x 2 ) )
  53   ;
  54 }
  55
  56 # FIXME when we bring in the storage weaklink, check its schema
  57 # weaklink and channel through $schema->throw_exception
  58 sub throw_exception { DBIx::Class::Exception->throw($_[1]) }
  59
  60 BEGIN {
  61   # reinstall the belch()/puke() functions of SQL::Abstract with custom versions
  62   # that use DBIx::Class::Carp/DBIx::Class::Exception instead of plain Carp
  63   no warnings qw/redefine/;
  64
  65   *SQL::Abstract::belch = subname 'SQL::Abstract::belch' => sub (@) {
  66     my($func) = (caller(1))[3];
  67     carp "[$func] Warning: ", @_;
  68   };
  69
  70   *SQL::Abstract::puke = subname 'SQL::Abstract::puke' => sub (@) {
  71     my($func) = (caller(1))[3];
  72     __PACKAGE__->throw_exception("[$func] Fatal: " . join ('',  @_));
  73   };
  74
  75   # Current SQLA pollutes its namespace - clean for the time being
  76   namespace::clean->clean_subroutines(qw/SQL::Abstract carp croak confess/);
  77 }
  78
  79 # the "oh noes offset/top without limit" constant
  80 # limited to 31 bits for sanity (and consistency,
  81 # since it may be handed to the like of sprintf %u)
  82 #
  83 # Also *some* builds of SQLite fail the test
  84 #   some_column BETWEEN ? AND ?: 1, 4294967295
  85 # with the proper integer bind attrs
  86 #
  87 # Implemented as a method, since ::Storage::DBI also
  88 # refers to it (i.e. for the case of software_limit or
  89 # as the value to abuse with MSSQL ordered subqueries)
  90 sub __max_int () { 0x7FFFFFFF };
  91
  92 # poor man's de-qualifier
  93 sub _quote {
  94   $_[0]->next::method( ( $_[0]{_dequalify_idents} and ! ref $_[1] )
  95     ? $_[1] =~ / ([^\.]+) $ /x
  96     : $_[1]
  97   );
  98 }
  99
 100 sub _where_op_NEST {
 101   carp_unique ("-nest in search conditions is deprecated, you most probably wanted:\n"
 102       .q|{..., -and => [ \%cond0, \@cond1, \'cond2', \[ 'cond3', [ col => bind ] ], etc. ], ... }|
 103   );
 104
 105   shift->next::method(@_);
 106 }
 107
 108 # Handle limit-dialect selection
 109 sub select {
 110   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
 111
 112
 113   $fields = $self->_recurse_fields($fields);
 114
 115   if (defined $offset) {
 116     $self->throw_exception('A supplied offset must be a non-negative integer')
 117       if ( $offset =~ /\D/ or $offset < 0 );
 118   }
 119   $offset ||= 0;
 120
 121   if (defined $limit) {
 122     $self->throw_exception('A supplied limit must be a positive integer')
 123       if ( $limit =~ /\D/ or $limit <= 0 );
 124   }
 125   elsif ($offset) {
 126     $limit = $self->__max_int;
 127   }
 128
 129
 130   my ($sql, @bind);
 131   if ($limit) {
 132     # this is legacy code-flow from SQLA::Limit, it is not set in stone
 133
 134     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 135
 136     my $limiter;
 137
 138     if( $limiter = $self->can ('emulate_limit') ) {
 139       carp_unique(
 140         'Support for the legacy emulate_limit() mechanism inherited from '
 141       . 'SQL::Abstract::Limit has been deprecated, and will be removed when '
 142       . 'DBIC transitions to Data::Query. If your code uses this type of '
 143       . 'limit specification please file an RT and provide the source of '
 144       . 'your emulate_limit() implementation, so an acceptable upgrade-path '
 145       . 'can be devised'
 146       );
 147     }
 148     else {
 149       my $dialect = $self->limit_dialect
 150         or $self->throw_exception( "Unable to generate SQL-limit - no limit dialect specified on $self" );
 151
 152       $limiter = $self->can ("_$dialect")
 153         or $self->throw_exception(__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 154     }
 155
 156     $sql = $self->$limiter (
 157       $sql,
 158       { %{$rs_attrs||{}}, _selector_sql => $fields },
 159       $limit,
 160       $offset
 161     );
 162   }
 163   else {
 164     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 165   }
 166
 167   push @{$self->{where_bind}}, @bind;
 168
 169 # this *must* be called, otherwise extra binds will remain in the sql-maker
 170   my @all_bind = $self->_assemble_binds;
 171
 172   $sql .= $self->_lock_select ($rs_attrs->{for})
 173     if $rs_attrs->{for};
 174
 175   return wantarray ? ($sql, @all_bind) : $sql;
 176 }
 177
 178 sub _assemble_binds {
 179   my $self = shift;
 180   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/pre_select select from where group having order limit/);
 181 }
 182
 183 my $for_syntax = {
 184   update => 'FOR UPDATE',
 185   shared => 'FOR SHARE',
 186 };
 187 sub _lock_select {
 188   my ($self, $type) = @_;
 189
 190   my $sql;
 191   if (ref($type) eq 'SCALAR') {
 192     $sql = "FOR $$type";
 193   }
 194   else {
 195     $sql = $for_syntax->{$type} || $self->throw_exception( "Unknown SELECT .. FOR type '$type' requested" );
 196   }
 197
 198   return " $sql";
 199 }
 200
 201 # Handle default inserts
 202 sub insert {
 203 # optimized due to hotttnesss
 204 #  my ($self, $table, $data, $options) = @_;
 205
 206   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 207   # which is sadly understood only by MySQL. Change default behavior here,
 208   # until SQLA2 comes with proper dialect support
 209   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 210     my @bind;
 211     my $sql = sprintf(
 212       'INSERT INTO %s DEFAULT VALUES', $_[0]->_quote($_[1])
 213     );
 214
 215     if ( ($_[3]||{})->{returning} ) {
 216       my $s;
 217       ($s, @bind) = $_[0]->_insert_returning ($_[3]);
 218       $sql .= $s;
 219     }
 220
 221     return ($sql, @bind);
 222   }
 223
 224   next::method(@_);
 225 }
 226
 227 sub _recurse_fields {
 228   my ($self, $fields) = @_;
 229   my $ref = ref $fields;
 230   return $self->_quote($fields) unless $ref;
 231   return $$fields if $ref eq 'SCALAR';
 232
 233   if ($ref eq 'ARRAY') {
 234     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 235   }
 236   elsif ($ref eq 'HASH') {
 237     my %hash = %$fields;  # shallow copy
 238
 239     my $as = delete $hash{-as};   # if supplied
 240
 241     my ($func, $args, @toomany) = %hash;
 242
 243     # there should be only one pair
 244     if (@toomany) {
 245       $self->throw_exception( "Malformed select argument - too many keys in hash: " . join (',', keys %$fields ) );
 246     }
 247
 248     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 249       $self->throw_exception (
 250         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 251        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 252        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 253       );
 254     }
 255
 256     my $select = sprintf ('%s( %s )%s',
 257       $self->_sqlcase($func),
 258       $self->_recurse_fields($args),
 259       $as
 260         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 261         : ''
 262     );
 263
 264     return $select;
 265   }
 266   # Is the second check absolutely necessary?
 267   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 268     push @{$self->{select_bind}}, @{$$fields}[1..$#$$fields];
 269     return $$fields->[0];
 270   }
 271   else {
 272     $self->throw_exception( $ref . qq{ unexpected in _recurse_fields()} );
 273   }
 274 }
 275
 276
 277 # this used to be a part of _order_by but is broken out for clarity.
 278 # What we have been doing forever is hijacking the $order arg of
 279 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 280 # then pretty much the entire resultset attr-hash, as more and more
 281 # things in the SQLA space need to have mopre info about the $rs they
 282 # create SQL for. The alternative would be to keep expanding the
 283 # signature of _select with more and more positional parameters, which
 284 # is just gross. All hail SQLA2!
 285 sub _parse_rs_attrs {
 286   my ($self, $arg) = @_;
 287
 288   my $sql = '';
 289
 290   if ($arg->{group_by}) {
 291     # horible horrible, waiting for refactor
 292     local $self->{select_bind};
 293     if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 294       $sql .= $self->_sqlcase(' group by ') . $g;
 295       push @{$self->{group_bind} ||= []}, @{$self->{select_bind}||[]};
 296     }
 297   }
 298
 299   if (defined $arg->{having}) {
 300     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 301     push(@{$self->{having_bind}}, @bind);
 302     $sql .= $self->_sqlcase(' having ') . $frag;
 303   }
 304
 305   if (defined $arg->{order_by}) {
 306     $sql .= $self->_order_by ($arg->{order_by});
 307   }
 308
 309   return $sql;
 310 }
 311
 312 sub _order_by {
 313   my ($self, $arg) = @_;
 314
 315   # check that we are not called in legacy mode (order_by as 4th argument)
 316   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 317     return $self->_parse_rs_attrs ($arg);
 318   }
 319   else {
 320     my ($sql, @bind) = $self->next::method($arg);
 321     push @{$self->{order_bind}}, @bind;
 322     return $sql;
 323   }
 324 }
 325
 326 sub _table {
 327 # optimized due to hotttnesss
 328 #  my ($self, $from) = @_;
 329   if (my $ref = ref $_[1] ) {
 330     if ($ref eq 'ARRAY') {
 331       return $_[0]->_recurse_from(@{$_[1]});
 332     }
 333     elsif ($ref eq 'HASH') {
 334       return $_[0]->_recurse_from($_[1]);
 335     }
 336     elsif ($ref eq 'REF' && ref ${$_[1]} eq 'ARRAY') {
 337       my ($sql, @bind) = @{ ${$_[1]} };
 338       push @{$_[0]->{from_bind}}, @bind;
 339       return $sql
 340     }
 341   }
 342   return $_[0]->next::method ($_[1]);
 343 }
 344
 345 sub _generate_join_clause {
 346     my ($self, $join_type) = @_;
 347
 348     $join_type = $self->{_default_jointype}
 349       if ! defined $join_type;
 350
 351     return sprintf ('%s JOIN ',
 352       $join_type ?  $self->_sqlcase($join_type) : ''
 353     );
 354 }
 355
 356 sub _recurse_from {
 357   my $self = shift;
 358
 359   return join (' ', $self->_gen_from_blocks(@_) );
 360 }
 361
 362 sub _gen_from_blocks {
 363   my ($self, $from, @joins) = @_;
 364
 365   my @fchunks = $self->_from_chunk_to_sql($from);
 366
 367   for (@joins) {
 368     my ($to, $on) = @$_;
 369
 370     # check whether a join type exists
 371     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 372     my $join_type;
 373     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 374       $join_type = $to_jt->{-join_type};
 375       $join_type =~ s/^\s+ | \s+$//xg;
 376     }
 377
 378     my @j = $self->_generate_join_clause( $join_type );
 379
 380     if (ref $to eq 'ARRAY') {
 381       push(@j, '(', $self->_recurse_from(@$to), ')');
 382     }
 383     else {
 384       push(@j, $self->_from_chunk_to_sql($to));
 385     }
 386
 387     my ($sql, @bind) = $self->_join_condition($on);
 388     push(@j, ' ON ', $sql);
 389     push @{$self->{from_bind}}, @bind;
 390
 391     push @fchunks, join '', @j;
 392   }
 393
 394   return @fchunks;
 395 }
 396
 397 sub _from_chunk_to_sql {
 398   my ($self, $fromspec) = @_;
 399
 400   return join (' ', do {
 401     if (! ref $fromspec) {
 402       $self->_quote($fromspec);
 403     }
 404     elsif (ref $fromspec eq 'SCALAR') {
 405       $$fromspec;
 406     }
 407     elsif (ref $fromspec eq 'REF' and ref $$fromspec eq 'ARRAY') {
 408       push @{$self->{from_bind}}, @{$$fromspec}[1..$#$$fromspec];
 409       $$fromspec->[0];
 410     }
 411     elsif (ref $fromspec eq 'HASH') {
 412       my ($as, $table, $toomuch) = ( map
 413         { $_ => $fromspec->{$_} }
 414         ( grep { $_ !~ /^\-/ } keys %$fromspec )
 415       );
 416
 417       $self->throw_exception( "Only one table/as pair expected in from-spec but an exra '$toomuch' key present" )
 418         if defined $toomuch;
 419
 420       ($self->_from_chunk_to_sql($table), $self->_quote($as) );
 421     }
 422     else {
 423       $self->throw_exception('Unsupported from refkind: ' . ref $fromspec );
 424     }
 425   });
 426 }
 427
 428 sub _join_condition {
 429   my ($self, $cond) = @_;
 430
 431   # Backcompat for the old days when a plain hashref
 432   # { 't1.col1' => 't2.col2' } meant ON t1.col1 = t2.col2
 433   # Once things settle we should start warning here so that
 434   # folks unroll their hacks
 435   if (
 436     ref $cond eq 'HASH'
 437       and
 438     keys %$cond == 1
 439       and
 440     (keys %$cond)[0] =~ /\./
 441       and
 442     ! ref ( (values %$cond)[0] )
 443   ) {
 444     $cond = { keys %$cond => { -ident => values %$cond } }
 445   }
 446   elsif ( ref $cond eq 'ARRAY' ) {
 447     # do our own ORing so that the hashref-shim above is invoked
 448     my @parts;
 449     my @binds;
 450     foreach my $c (@$cond) {
 451       my ($sql, @bind) = $self->_join_condition($c);
 452       push @binds, @bind;
 453       push @parts, $sql;
 454     }
 455     return join(' OR ', @parts), @binds;
 456   }
 457
 458   return $self->_recurse_where($cond);
 459 }
 460
 461 1;
 462
 463 =head1 AUTHORS
 464
 465 See L<DBIx::Class/CONTRIBUTORS>.
 466
 467 =head1 LICENSE
 468
 469 You may distribute this code under the same terms as Perl itself.
 470
 471 =cut