support INSERT ... RETURNING in Oracle 8i and later
[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / SQLMaker.pm
1 package DBIx::Class::SQLMaker;
2
3 =head1 NAME
4
5 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
6
7 =head1 DESCRIPTION
8
9 This module is a subclass of L<SQL::Abstract> and includes a number of
10 DBIC-specific workarounds, not yet suitable for inclusion into the
11 L<SQL::Abstract> core. It also provides all (and more than) the functionality
12 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
13 more info.
14
15 Currently the enhancements to L<SQL::Abstract> are:
16
17 =over
18
19 =item * Support for C<JOIN> statements (via extended C<table/from> support)
20
21 =item * Support of functions in C<SELECT> lists
22
23 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
24
25 =item * Support of C<...FOR UPDATE> type of select statement modifiers
26
27 =item * The -ident operator
28
29 =item * The -value operator
30
31 =back
32
33 =cut
34
35 use base qw/
36   DBIx::Class::SQLMaker::LimitDialects
37   SQL::Abstract
38   Class::Accessor::Grouped
39 /;
40 use mro 'c3';
41 use strict;
42 use warnings;
43 use Sub::Name 'subname';
44 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract|^Try::Tiny/;
45 use namespace::clean;
46
47 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
48
49 # for when I need a normalized l/r pair
50 sub _quote_chars {
51   map
52     { defined $_ ? $_ : '' }
53     ( ref $_[0]->{quote_char} ? (@{$_[0]->{quote_char}}) : ( ($_[0]->{quote_char}) x 2 ) )
54   ;
55 }
56
57 BEGIN {
58   # reinstall the carp()/croak() functions imported into SQL::Abstract
59   # as Carp and Carp::Clan do not like each other much
60   no warnings qw/redefine/;
61   no strict qw/refs/;
62   for my $f (qw/carp croak/) {
63
64     my $orig = \&{"SQL::Abstract::$f"};
65     my $clan_import = \&{$f};
66     *{"SQL::Abstract::$f"} = subname "SQL::Abstract::$f" =>
67       sub {
68         if (Carp::longmess() =~ /DBIx::Class::SQLMaker::[\w]+ .+? called \s at/x) {
69           goto $clan_import;
70         }
71         else {
72           goto $orig;
73         }
74       };
75   }
76 }
77
78 # the "oh noes offset/top without limit" constant
79 # limited to 32 bits for sanity (and consistency,
80 # since it is ultimately handed to sprintf %u)
81 # Implemented as a method, since ::Storage::DBI also
82 # refers to it (i.e. for the case of software_limit or
83 # as the value to abuse with MSSQL ordered subqueries)
84 sub __max_int { 0xFFFFFFFF };
85
86 sub new {
87   my $self = shift->next::method(@_);
88
89   # use the same coderefs, they are prepared to handle both cases
90   my @extra_dbic_syntax = (
91     { regex => qr/^ ident $/xi, handler => '_where_op_IDENT' },
92     { regex => qr/^ value $/xi, handler => '_where_op_VALUE' },
93   );
94
95   push @{$self->{special_ops}}, @extra_dbic_syntax;
96   push @{$self->{unary_ops}}, @extra_dbic_syntax;
97
98   $self;
99 }
100
101 sub _where_op_IDENT {
102   my $self = shift;
103   my ($op, $rhs) = splice @_, -2;
104   if (ref $rhs) {
105     croak "-$op takes a single scalar argument (a quotable identifier)";
106   }
107
108   # in case we are called as a top level special op (no '=')
109   my $lhs = shift;
110
111   $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
112
113   return $lhs
114     ? "$lhs = $rhs"
115     : $rhs
116   ;
117 }
118
119 sub _where_op_VALUE {
120   my $self = shift;
121   my ($op, $rhs) = splice @_, -2;
122
123   # in case we are called as a top level special op (no '=')
124   my $lhs = shift;
125
126   my @bind = [
127     ($lhs || $self->{_nested_func_lhs} || croak "Unable to find bindtype for -value $rhs"),
128     $rhs
129   ];
130
131   return $lhs
132     ? (
133       $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
134       @bind
135     )
136     : (
137       $self->_convert('?'),
138       @bind,
139     )
140   ;
141 }
142
143 # Handle limit-dialect selection
144 sub select {
145   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
146
147
148   $fields = $self->_recurse_fields($fields);
149
150   if (defined $offset) {
151     croak ('A supplied offset must be a non-negative integer')
152       if ( $offset =~ /\D/ or $offset < 0 );
153   }
154   $offset ||= 0;
155
156   if (defined $limit) {
157     croak ('A supplied limit must be a positive integer')
158       if ( $limit =~ /\D/ or $limit <= 0 );
159   }
160   elsif ($offset) {
161     $limit = $self->__max_int;
162   }
163
164
165   my ($sql, @bind);
166   if ($limit) {
167     # this is legacy code-flow from SQLA::Limit, it is not set in stone
168
169     ($sql, @bind) = $self->next::method ($table, $fields, $where);
170
171     my $limiter =
172       $self->can ('emulate_limit')  # also backcompat hook from SQLA::Limit
173         ||
174       do {
175         my $dialect = $self->limit_dialect
176           or croak "Unable to generate SQL-limit - no limit dialect specified on $self, and no emulate_limit method found";
177         $self->can ("_$dialect")
178           or croak (__PACKAGE__ . " does not implement the requested dialect '$dialect'");
179       }
180     ;
181
182     $sql = $self->$limiter ($sql, $rs_attrs, $limit, $offset);
183   }
184   else {
185     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
186   }
187
188   push @{$self->{where_bind}}, @bind;
189
190 # this *must* be called, otherwise extra binds will remain in the sql-maker
191   my @all_bind = $self->_assemble_binds;
192
193   $sql .= $self->_lock_select ($rs_attrs->{for})
194     if $rs_attrs->{for};
195
196   return wantarray ? ($sql, @all_bind) : $sql;
197 }
198
199 sub _assemble_binds {
200   my $self = shift;
201   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/from where having order/);
202 }
203
204 my $for_syntax = {
205   update => 'FOR UPDATE',
206   shared => 'FOR SHARE',
207 };
208 sub _lock_select {
209   my ($self, $type) = @_;
210   my $sql = $for_syntax->{$type} || croak "Unknown SELECT .. FOR type '$type' requested";
211   return " $sql";
212 }
213
214 # Handle default inserts
215 sub insert {
216 # optimized due to hotttnesss
217 #  my ($self, $table, $data, $options) = @_;
218
219   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
220   # which is sadly understood only by MySQL. Change default behavior here,
221   # until SQLA2 comes with proper dialect support
222   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
223     my @bind;
224     my $sql = sprintf(
225       'INSERT INTO %s DEFAULT VALUES', $_[0]->_quote($_[1])
226     );
227
228     if ( ($_[3]||{})->{returning} ) {
229       my $s;
230       ($s, @bind) = $_[0]->_insert_returning ($_[3]);
231       $sql .= $s;
232     }
233
234     return ($sql, @bind);
235   }
236
237   next::method(@_);
238 }
239
240 sub _recurse_fields {
241   my ($self, $fields) = @_;
242   my $ref = ref $fields;
243   return $self->_quote($fields) unless $ref;
244   return $$fields if $ref eq 'SCALAR';
245
246   if ($ref eq 'ARRAY') {
247     return join(', ', map { $self->_recurse_fields($_) } @$fields);
248   }
249   elsif ($ref eq 'HASH') {
250     my %hash = %$fields;  # shallow copy
251
252     my $as = delete $hash{-as};   # if supplied
253
254     my ($func, $args, @toomany) = %hash;
255
256     # there should be only one pair
257     if (@toomany) {
258       croak "Malformed select argument - too many keys in hash: " . join (',', keys %$fields );
259     }
260
261     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
262       croak (
263         'The select => { distinct => ... } syntax is not supported for multiple columns.'
264        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
265        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
266       );
267     }
268
269     my $select = sprintf ('%s( %s )%s',
270       $self->_sqlcase($func),
271       $self->_recurse_fields($args),
272       $as
273         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
274         : ''
275     );
276
277     return $select;
278   }
279   # Is the second check absolutely necessary?
280   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
281     return $self->_fold_sqlbind( $fields );
282   }
283   else {
284     croak($ref . qq{ unexpected in _recurse_fields()})
285   }
286 }
287
288
289 # this used to be a part of _order_by but is broken out for clarity.
290 # What we have been doing forever is hijacking the $order arg of
291 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
292 # then pretty much the entire resultset attr-hash, as more and more
293 # things in the SQLA space need to have mopre info about the $rs they
294 # create SQL for. The alternative would be to keep expanding the
295 # signature of _select with more and more positional parameters, which
296 # is just gross. All hail SQLA2!
297 sub _parse_rs_attrs {
298   my ($self, $arg) = @_;
299
300   my $sql = '';
301
302   if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
303     $sql .= $self->_sqlcase(' group by ') . $g;
304   }
305
306   if (defined $arg->{having}) {
307     my ($frag, @bind) = $self->_recurse_where($arg->{having});
308     push(@{$self->{having_bind}}, @bind);
309     $sql .= $self->_sqlcase(' having ') . $frag;
310   }
311
312   if (defined $arg->{order_by}) {
313     $sql .= $self->_order_by ($arg->{order_by});
314   }
315
316   return $sql;
317 }
318
319 sub _order_by {
320   my ($self, $arg) = @_;
321
322   # check that we are not called in legacy mode (order_by as 4th argument)
323   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
324     return $self->_parse_rs_attrs ($arg);
325   }
326   else {
327     my ($sql, @bind) = $self->next::method($arg);
328     push @{$self->{order_bind}}, @bind;
329     return $sql;
330   }
331 }
332
333 sub _table {
334 # optimized due to hotttnesss
335 #  my ($self, $from) = @_;
336   if (my $ref = ref $_[1] ) {
337     if ($ref eq 'ARRAY') {
338       return $_[0]->_recurse_from(@{$_[1]});
339     }
340     elsif ($ref eq 'HASH') {
341       return $_[0]->_make_as($_[1]);
342     }
343   }
344
345   return $_[0]->next::method ($_[1]);
346 }
347
348 sub _generate_join_clause {
349     my ($self, $join_type) = @_;
350
351     return sprintf ('%s JOIN ',
352       $join_type ?  ' ' . uc($join_type) : ''
353     );
354 }
355
356 sub _recurse_from {
357   my ($self, $from, @join) = @_;
358   my @sqlf;
359   push(@sqlf, $self->_make_as($from));
360   foreach my $j (@join) {
361     my ($to, $on) = @$j;
362
363
364     # check whether a join type exists
365     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
366     my $join_type;
367     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
368       $join_type = $to_jt->{-join_type};
369       $join_type =~ s/^\s+ | \s+$//xg;
370     }
371
372     $join_type = $self->{_default_jointype} if not defined $join_type;
373
374     push @sqlf, $self->_generate_join_clause( $join_type );
375
376     if (ref $to eq 'ARRAY') {
377       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
378     } else {
379       push(@sqlf, $self->_make_as($to));
380     }
381     push(@sqlf, ' ON ', $self->_join_condition($on));
382   }
383   return join('', @sqlf);
384 }
385
386 sub _fold_sqlbind {
387   my ($self, $sqlbind) = @_;
388
389   my @sqlbind = @$$sqlbind; # copy
390   my $sql = shift @sqlbind;
391   push @{$self->{from_bind}}, @sqlbind;
392
393   return $sql;
394 }
395
396 sub _make_as {
397   my ($self, $from) = @_;
398   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
399                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
400                         : $self->_quote($_))
401                        } reverse each %{$self->_skip_options($from)});
402 }
403
404 sub _skip_options {
405   my ($self, $hash) = @_;
406   my $clean_hash = {};
407   $clean_hash->{$_} = $hash->{$_}
408     for grep {!/^-/} keys %$hash;
409   return $clean_hash;
410 }
411
412 sub _join_condition {
413   my ($self, $cond) = @_;
414   if (ref $cond eq 'HASH') {
415     my %j;
416     for (keys %$cond) {
417       my $v = $cond->{$_};
418       if (ref $v) {
419         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
420             if ref($v) ne 'SCALAR';
421         $j{$_} = $v;
422       }
423       else {
424         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
425       }
426     };
427     return scalar($self->_recurse_where(\%j));
428   } elsif (ref $cond eq 'ARRAY') {
429     return join(' OR ', map { $self->_join_condition($_) } @$cond);
430   } else {
431     croak "Can't handle this yet!";
432   }
433 }
434
435 1;
436
437 =head1 AUTHORS
438
439 See L<DBIx::Class/CONTRIBUTORS>.
440
441 =head1 LICENSE
442
443 You may distribute this code under the same terms as Perl itself.
444
445 =cut