lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   9
  10 =head1 DESCRIPTION
  11
  12 This module is a subclass of L<SQL::Abstract> and includes a number of
  13 DBIC-specific workarounds, not yet suitable for inclusion into the
  14 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  15 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  16 more info.
  17
  18 Currently the enhancements to L<SQL::Abstract> are:
  19
  20 =over
  21
  22 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  23
  24 =item * Support of functions in C<SELECT> lists
  25
  26 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  27
  28 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  29
  30 =item * The -ident operator
  31
  32 =item * The -value operator
  33
  34 =back
  35
  36 =cut
  37
  38 use base qw/
  39   DBIx::Class::SQLMaker::LimitDialects
  40   SQL::Abstract
  41   DBIx::Class
  42 /;
  43 use mro 'c3';
  44
  45 use Sub::Name 'subname';
  46 use DBIx::Class::Carp;
  47 use DBIx::Class::Exception;
  48 use namespace::clean;
  49
  50 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  51
  52 # for when I need a normalized l/r pair
  53 sub _quote_chars {
  54   map
  55     { defined $_ ? $_ : '' }
  56     ( ref $_[0]->{quote_char} ? (@{$_[0]->{quote_char}}) : ( ($_[0]->{quote_char}) x 2 ) )
  57   ;
  58 }
  59
  60 # FIXME when we bring in the storage weaklink, check its schema
  61 # weaklink and channel through $schema->throw_exception
  62 sub throw_exception { DBIx::Class::Exception->throw($_[1]) }
  63
  64 BEGIN {
  65   # reinstall the belch()/puke() functions of SQL::Abstract with custom versions
  66   # that use DBIx::Class::Carp/DBIx::Class::Exception instead of plain Carp
  67   no warnings qw/redefine/;
  68
  69   *SQL::Abstract::belch = subname 'SQL::Abstract::belch' => sub (@) {
  70     my($func) = (caller(1))[3];
  71     carp "[$func] Warning: ", @_;
  72   };
  73
  74   *SQL::Abstract::puke = subname 'SQL::Abstract::puke' => sub (@) {
  75     my($func) = (caller(1))[3];
  76     __PACKAGE__->throw_exception("[$func] Fatal: " . join ('',  @_));
  77   };
  78
  79   # Current SQLA pollutes its namespace - clean for the time being
  80   namespace::clean->clean_subroutines(qw/SQL::Abstract carp croak confess/);
  81 }
  82
  83 # the "oh noes offset/top without limit" constant
  84 # limited to 32 bits for sanity (and consistency,
  85 # since it is ultimately handed to sprintf %u)
  86 # Implemented as a method, since ::Storage::DBI also
  87 # refers to it (i.e. for the case of software_limit or
  88 # as the value to abuse with MSSQL ordered subqueries)
  89 sub __max_int { 0xFFFFFFFF };
  90
  91 sub new {
  92   my $self = shift->next::method(@_);
  93
  94   # use the same coderefs, they are prepared to handle both cases
  95   my @extra_dbic_syntax = (
  96     { regex => qr/^ ident $/xi, handler => '_where_op_IDENT' },
  97     { regex => qr/^ value $/xi, handler => '_where_op_VALUE' },
  98   );
  99
 100   push @{$self->{special_ops}}, @extra_dbic_syntax;
 101   push @{$self->{unary_ops}}, @extra_dbic_syntax;
 102
 103   $self;
 104 }
 105
 106 sub _where_op_IDENT {
 107   my $self = shift;
 108   my ($op, $rhs) = splice @_, -2;
 109   if (ref $rhs) {
 110     $self->throw_exception("-$op takes a single scalar argument (a quotable identifier)");
 111   }
 112
 113   # in case we are called as a top level special op (no '=')
 114   my $lhs = shift;
 115
 116   $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
 117
 118   return $lhs
 119     ? "$lhs = $rhs"
 120     : $rhs
 121   ;
 122 }
 123
 124 sub _where_op_VALUE {
 125   my $self = shift;
 126   my ($op, $rhs) = splice @_, -2;
 127
 128   # in case we are called as a top level special op (no '=')
 129   my $lhs = shift;
 130
 131   my @bind = [
 132     ($lhs || $self->{_nested_func_lhs} || $self->throw_exception("Unable to find bindtype for -value $rhs") ),
 133     $rhs
 134   ];
 135
 136   return $lhs
 137     ? (
 138       $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
 139       @bind
 140     )
 141     : (
 142       $self->_convert('?'),
 143       @bind,
 144     )
 145   ;
 146 }
 147
 148 sub _where_op_NEST {
 149   carp_unique ("-nest in search conditions is deprecated, you most probably wanted:\n"
 150       .q|{..., -and => [ \%cond0, \@cond1, \'cond2', \[ 'cond3', [ col => bind ] ], etc. ], ... }|
 151   );
 152
 153   shift->next::method(@_);
 154 }
 155
 156 # Handle limit-dialect selection
 157 sub select {
 158   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
 159
 160
 161   $fields = $self->_recurse_fields($fields);
 162
 163   if (defined $offset) {
 164     $self->throw_exception('A supplied offset must be a non-negative integer')
 165       if ( $offset =~ /\D/ or $offset < 0 );
 166   }
 167   $offset ||= 0;
 168
 169   if (defined $limit) {
 170     $self->throw_exception('A supplied limit must be a positive integer')
 171       if ( $limit =~ /\D/ or $limit <= 0 );
 172   }
 173   elsif ($offset) {
 174     $limit = $self->__max_int;
 175   }
 176
 177
 178   my ($sql, @bind);
 179   if ($limit) {
 180     # this is legacy code-flow from SQLA::Limit, it is not set in stone
 181
 182     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 183
 184     my $limiter =
 185       $self->can ('emulate_limit')  # also backcompat hook from SQLA::Limit
 186         ||
 187       do {
 188         my $dialect = $self->limit_dialect
 189           or $self->throw_exception( "Unable to generate SQL-limit - no limit dialect specified on $self, and no emulate_limit method found" );
 190         $self->can ("_$dialect")
 191           or $self->throw_exception(__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 192       }
 193     ;
 194
 195     $sql = $self->$limiter ($sql, $rs_attrs, $limit, $offset);
 196   }
 197   else {
 198     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 199   }
 200
 201   push @{$self->{where_bind}}, @bind;
 202
 203 # this *must* be called, otherwise extra binds will remain in the sql-maker
 204   my @all_bind = $self->_assemble_binds;
 205
 206   $sql .= $self->_lock_select ($rs_attrs->{for})
 207     if $rs_attrs->{for};
 208
 209   return wantarray ? ($sql, @all_bind) : $sql;
 210 }
 211
 212 sub _assemble_binds {
 213   my $self = shift;
 214   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/select from where group having order/);
 215 }
 216
 217 my $for_syntax = {
 218   update => 'FOR UPDATE',
 219   shared => 'FOR SHARE',
 220 };
 221 sub _lock_select {
 222   my ($self, $type) = @_;
 223   my $sql = $for_syntax->{$type} || $self->throw_exception( "Unknown SELECT .. FOR type '$type' requested" );
 224   return " $sql";
 225 }
 226
 227 # Handle default inserts
 228 sub insert {
 229 # optimized due to hotttnesss
 230 #  my ($self, $table, $data, $options) = @_;
 231
 232   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 233   # which is sadly understood only by MySQL. Change default behavior here,
 234   # until SQLA2 comes with proper dialect support
 235   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 236     my @bind;
 237     my $sql = sprintf(
 238       'INSERT INTO %s DEFAULT VALUES', $_[0]->_quote($_[1])
 239     );
 240
 241     if ( ($_[3]||{})->{returning} ) {
 242       my $s;
 243       ($s, @bind) = $_[0]->_insert_returning ($_[3]);
 244       $sql .= $s;
 245     }
 246
 247     return ($sql, @bind);
 248   }
 249
 250   next::method(@_);
 251 }
 252
 253 sub _recurse_fields {
 254   my ($self, $fields) = @_;
 255   my $ref = ref $fields;
 256   return $self->_quote($fields) unless $ref;
 257   return $$fields if $ref eq 'SCALAR';
 258
 259   if ($ref eq 'ARRAY') {
 260     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 261   }
 262   elsif ($ref eq 'HASH') {
 263     my %hash = %$fields;  # shallow copy
 264
 265     my $as = delete $hash{-as};   # if supplied
 266
 267     my ($func, $args, @toomany) = %hash;
 268
 269     # there should be only one pair
 270     if (@toomany) {
 271       $self->throw_exception( "Malformed select argument - too many keys in hash: " . join (',', keys %$fields ) );
 272     }
 273
 274     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 275       $self->throw_exception (
 276         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 277        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 278        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 279       );
 280     }
 281
 282     my $select = sprintf ('%s( %s )%s',
 283       $self->_sqlcase($func),
 284       $self->_recurse_fields($args),
 285       $as
 286         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 287         : ''
 288     );
 289
 290     return $select;
 291   }
 292   # Is the second check absolutely necessary?
 293   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 294     push @{$self->{select_bind}}, @{$$fields}[1..$#$$fields];
 295     return $$fields->[0];
 296   }
 297   else {
 298     $self->throw_exception( $ref . qq{ unexpected in _recurse_fields()} );
 299   }
 300 }
 301
 302
 303 # this used to be a part of _order_by but is broken out for clarity.
 304 # What we have been doing forever is hijacking the $order arg of
 305 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 306 # then pretty much the entire resultset attr-hash, as more and more
 307 # things in the SQLA space need to have mopre info about the $rs they
 308 # create SQL for. The alternative would be to keep expanding the
 309 # signature of _select with more and more positional parameters, which
 310 # is just gross. All hail SQLA2!
 311 sub _parse_rs_attrs {
 312   my ($self, $arg) = @_;
 313
 314   my $sql = '';
 315
 316   if ($arg->{group_by}) {
 317     # horible horrible, waiting for refactor
 318     local $self->{select_bind};
 319     if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 320       $sql .= $self->_sqlcase(' group by ') . $g;
 321       push @{$self->{group_bind} ||= []}, @{$self->{select_bind}||[]};
 322     }
 323   }
 324
 325   if (defined $arg->{having}) {
 326     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 327     push(@{$self->{having_bind}}, @bind);
 328     $sql .= $self->_sqlcase(' having ') . $frag;
 329   }
 330
 331   if (defined $arg->{order_by}) {
 332     $sql .= $self->_order_by ($arg->{order_by});
 333   }
 334
 335   return $sql;
 336 }
 337
 338 sub _order_by {
 339   my ($self, $arg) = @_;
 340
 341   # check that we are not called in legacy mode (order_by as 4th argument)
 342   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 343     return $self->_parse_rs_attrs ($arg);
 344   }
 345   else {
 346     my ($sql, @bind) = $self->next::method($arg);
 347     push @{$self->{order_bind}}, @bind;
 348     return $sql;
 349   }
 350 }
 351
 352 sub _table {
 353 # optimized due to hotttnesss
 354 #  my ($self, $from) = @_;
 355   if (my $ref = ref $_[1] ) {
 356     if ($ref eq 'ARRAY') {
 357       return $_[0]->_recurse_from(@{$_[1]});
 358     }
 359     elsif ($ref eq 'HASH') {
 360       return $_[0]->_recurse_from($_[1]);
 361     }
 362     elsif ($ref eq 'REF' && ref ${$_[1]} eq 'ARRAY') {
 363       my ($sql, @bind) = @{ ${$_[1]} };
 364       push @{$_[0]->{from_bind}}, @bind;
 365       return $sql
 366     }
 367   }
 368   return $_[0]->next::method ($_[1]);
 369 }
 370
 371 sub _generate_join_clause {
 372     my ($self, $join_type) = @_;
 373
 374     $join_type = $self->{_default_jointype}
 375       if ! defined $join_type;
 376
 377     return sprintf ('%s JOIN ',
 378       $join_type ?  $self->_sqlcase($join_type) : ''
 379     );
 380 }
 381
 382 sub _recurse_from {
 383   my $self = shift;
 384
 385   return join (' ', $self->_gen_from_blocks(@_) );
 386 }
 387
 388 sub _gen_from_blocks {
 389   my ($self, $from, @joins) = @_;
 390
 391   my @fchunks = $self->_from_chunk_to_sql($from);
 392
 393   for (@joins) {
 394     my ($to, $on) = @$_;
 395
 396     # check whether a join type exists
 397     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 398     my $join_type;
 399     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 400       $join_type = $to_jt->{-join_type};
 401       $join_type =~ s/^\s+ | \s+$//xg;
 402     }
 403
 404     my @j = $self->_generate_join_clause( $join_type );
 405
 406     if (ref $to eq 'ARRAY') {
 407       push(@j, '(', $self->_recurse_from(@$to), ')');
 408     }
 409     else {
 410       push(@j, $self->_from_chunk_to_sql($to));
 411     }
 412
 413     my ($sql, @bind) = $self->_join_condition($on);
 414     push(@j, ' ON ', $sql);
 415     push @{$self->{from_bind}}, @bind;
 416
 417     push @fchunks, join '', @j;
 418   }
 419
 420   return @fchunks;
 421 }
 422
 423 sub _from_chunk_to_sql {
 424   my ($self, $fromspec) = @_;
 425
 426   return join (' ', $self->_SWITCH_refkind($fromspec, {
 427     SCALARREF => sub {
 428       $$fromspec;
 429     },
 430     ARRAYREFREF => sub {
 431       push @{$self->{from_bind}}, @{$$fromspec}[1..$#$$fromspec];
 432       $$fromspec->[0];
 433     },
 434     HASHREF => sub {
 435       my ($as, $table, $toomuch) = ( map
 436         { $_ => $fromspec->{$_} }
 437         ( grep { $_ !~ /^\-/ } keys %$fromspec )
 438       );
 439
 440       $self->throw_exception( "Only one table/as pair expected in from-spec but an exra '$toomuch' key present" )
 441         if defined $toomuch;
 442
 443       ($self->_from_chunk_to_sql($table), $self->_quote($as) );
 444     },
 445     SCALAR => sub {
 446       $self->_quote($fromspec);
 447     },
 448   }));
 449 }
 450
 451 sub _join_condition {
 452   my ($self, $cond) = @_;
 453
 454   # Backcompat for the old days when a plain hashref
 455   # { 't1.col1' => 't2.col2' } meant ON t1.col1 = t2.col2
 456   # Once things settle we should start warning here so that
 457   # folks unroll their hacks
 458   if (
 459     ref $cond eq 'HASH'
 460       and
 461     keys %$cond == 1
 462       and
 463     (keys %$cond)[0] =~ /\./
 464       and
 465     ! ref ( (values %$cond)[0] )
 466   ) {
 467     $cond = { keys %$cond => { -ident => values %$cond } }
 468   }
 469   elsif ( ref $cond eq 'ARRAY' ) {
 470     # do our own ORing so that the hashref-shim above is invoked
 471     my @parts;
 472     my @binds;
 473     foreach my $c (@$cond) {
 474       my ($sql, @bind) = $self->_join_condition($c);
 475       push @binds, @bind;
 476       push @parts, $sql;
 477     }
 478     return join(' OR ', @parts), @binds;
 479   }
 480
 481   return $self->_recurse_where($cond);
 482 }
 483
 484 1;
 485
 486 =head1 AUTHORS
 487
 488 See L<DBIx::Class/CONTRIBUTORS>.
 489
 490 =head1 LICENSE
 491
 492 You may distribute this code under the same terms as Perl itself.
 493
 494 =cut