lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   9
  10 =head1 DESCRIPTION
  11
  12 This module is a subclass of L<SQL::Abstract> and includes a number of
  13 DBIC-specific workarounds, not yet suitable for inclusion into the
  14 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  15 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  16 more info.
  17
  18 Currently the enhancements to L<SQL::Abstract> are:
  19
  20 =over
  21
  22 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  23
  24 =item * Support of functions in C<SELECT> lists
  25
  26 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  27
  28 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  29
  30 =back
  31
  32 =cut
  33
  34 use base qw/
  35   DBIx::Class::SQLMaker::LimitDialects
  36   SQL::Abstract
  37   DBIx::Class
  38 /;
  39 use mro 'c3';
  40
  41 use Sub::Name 'subname';
  42 use DBIx::Class::Carp;
  43 use namespace::clean;
  44
  45 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  46
  47 # for when I need a normalized l/r pair
  48 sub _quote_chars {
  49   map
  50     { defined $_ ? $_ : '' }
  51     ( ref $_[0]->{quote_char} ? (@{$_[0]->{quote_char}}) : ( ($_[0]->{quote_char}) x 2 ) )
  52   ;
  53 }
  54
  55 # FIXME when we bring in the storage weaklink, check its schema
  56 # weaklink and channel through $schema->throw_exception
  57 sub throw_exception { DBIx::Class::Exception->throw($_[1]) }
  58
  59 BEGIN {
  60   # reinstall the belch()/puke() functions of SQL::Abstract with custom versions
  61   # that use DBIx::Class::Carp/DBIx::Class::Exception instead of plain Carp
  62   no warnings qw/redefine/;
  63
  64   *SQL::Abstract::belch = subname 'SQL::Abstract::belch' => sub (@) {
  65     my($func) = (caller(1))[3];
  66     carp "[$func] Warning: ", @_;
  67   };
  68
  69   *SQL::Abstract::puke = subname 'SQL::Abstract::puke' => sub (@) {
  70     my($func) = (caller(1))[3];
  71     __PACKAGE__->throw_exception("[$func] Fatal: " . join ('',  @_));
  72   };
  73 }
  74
  75 # the "oh noes offset/top without limit" constant
  76 # limited to 31 bits for sanity (and consistency,
  77 # since it may be handed to the like of sprintf %u)
  78 #
  79 # Also *some* builds of SQLite fail the test
  80 #   some_column BETWEEN ? AND ?: 1, 4294967295
  81 # with the proper integer bind attrs
  82 #
  83 # Implemented as a method, since ::Storage::DBI also
  84 # refers to it (i.e. for the case of software_limit or
  85 # as the value to abuse with MSSQL ordered subqueries)
  86 sub __max_int () { 0x7FFFFFFF };
  87
  88 # poor man's de-qualifier
  89 sub _quote {
  90   $_[0]->next::method( ( $_[0]{_dequalify_idents} and ! ref $_[1] )
  91     ? $_[1] =~ / ([^\.]+) $ /x
  92     : $_[1]
  93   );
  94 }
  95
  96 sub _where_op_NEST {
  97   carp_unique ("-nest in search conditions is deprecated, you most probably wanted:\n"
  98       .q|{..., -and => [ \%cond0, \@cond1, \'cond2', \[ 'cond3', [ col => bind ] ], etc. ], ... }|
  99   );
 100
 101   shift->next::method(@_);
 102 }
 103
 104 # Handle limit-dialect selection
 105 sub select {
 106   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
 107
 108
 109   $fields = $self->_recurse_fields($fields);
 110
 111   if (defined $offset) {
 112     $self->throw_exception('A supplied offset must be a non-negative integer')
 113       if ( $offset =~ /\D/ or $offset < 0 );
 114   }
 115   $offset ||= 0;
 116
 117   if (defined $limit) {
 118     $self->throw_exception('A supplied limit must be a positive integer')
 119       if ( $limit =~ /\D/ or $limit <= 0 );
 120   }
 121   elsif ($offset) {
 122     $limit = $self->__max_int;
 123   }
 124
 125
 126   my ($sql, @bind);
 127   if ($limit) {
 128     # this is legacy code-flow from SQLA::Limit, it is not set in stone
 129
 130     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 131
 132     my $limiter;
 133
 134     if( $limiter = $self->can ('emulate_limit') ) {
 135       carp_unique(
 136         'Support for the legacy emulate_limit() mechanism inherited from '
 137       . 'SQL::Abstract::Limit has been deprecated, and will be removed when '
 138       . 'DBIC transitions to Data::Query. If your code uses this type of '
 139       . 'limit specification please file an RT and provide the source of '
 140       . 'your emulate_limit() implementation, so an acceptable upgrade-path '
 141       . 'can be devised'
 142       );
 143     }
 144     else {
 145       my $dialect = $self->limit_dialect
 146         or $self->throw_exception( "Unable to generate SQL-limit - no limit dialect specified on $self" );
 147
 148       $limiter = $self->can ("_$dialect")
 149         or $self->throw_exception(__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 150     }
 151
 152     $sql = $self->$limiter (
 153       $sql,
 154       { %{$rs_attrs||{}}, _selector_sql => $fields },
 155       $limit,
 156       $offset
 157     );
 158   }
 159   else {
 160     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 161   }
 162
 163   push @{$self->{where_bind}}, @bind;
 164
 165 # this *must* be called, otherwise extra binds will remain in the sql-maker
 166   my @all_bind = $self->_assemble_binds;
 167
 168   $sql .= $self->_lock_select ($rs_attrs->{for})
 169     if $rs_attrs->{for};
 170
 171   return wantarray ? ($sql, @all_bind) : $sql;
 172 }
 173
 174 sub _assemble_binds {
 175   my $self = shift;
 176   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/pre_select select from where group having order limit/);
 177 }
 178
 179 my $for_syntax = {
 180   update => 'FOR UPDATE',
 181   shared => 'FOR SHARE',
 182 };
 183 sub _lock_select {
 184   my ($self, $type) = @_;
 185
 186   my $sql;
 187   if (ref($type) eq 'SCALAR') {
 188     $sql = "FOR $$type";
 189   }
 190   else {
 191     $sql = $for_syntax->{$type} || $self->throw_exception( "Unknown SELECT .. FOR type '$type' requested" );
 192   }
 193
 194   return " $sql";
 195 }
 196
 197 # Handle default inserts
 198 sub insert {
 199 # optimized due to hotttnesss
 200 #  my ($self, $table, $data, $options) = @_;
 201
 202   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 203   # which is sadly understood only by MySQL. Change default behavior here,
 204   # until SQLA2 comes with proper dialect support
 205   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 206     my @bind;
 207     my $sql = sprintf(
 208       'INSERT INTO %s DEFAULT VALUES', $_[0]->_quote($_[1])
 209     );
 210
 211     if ( ($_[3]||{})->{returning} ) {
 212       my $s;
 213       ($s, @bind) = $_[0]->_insert_returning ($_[3]);
 214       $sql .= $s;
 215     }
 216
 217     return ($sql, @bind);
 218   }
 219
 220   next::method(@_);
 221 }
 222
 223 sub _recurse_fields {
 224   my ($self, $fields) = @_;
 225   my $ref = ref $fields;
 226   return $self->_quote($fields) unless $ref;
 227   return $$fields if $ref eq 'SCALAR';
 228
 229   if ($ref eq 'ARRAY') {
 230     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 231   }
 232   elsif ($ref eq 'HASH') {
 233     my %hash = %$fields;  # shallow copy
 234
 235     my $as = delete $hash{-as};   # if supplied
 236
 237     my ($func, $args, @toomany) = %hash;
 238
 239     # there should be only one pair
 240     if (@toomany) {
 241       $self->throw_exception( "Malformed select argument - too many keys in hash: " . join (',', keys %$fields ) );
 242     }
 243
 244     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 245       $self->throw_exception (
 246         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 247        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 248        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 249       );
 250     }
 251
 252     my $select = sprintf ('%s( %s )%s',
 253       $self->_sqlcase($func),
 254       $self->_recurse_fields($args),
 255       $as
 256         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 257         : ''
 258     );
 259
 260     return $select;
 261   }
 262   # Is the second check absolutely necessary?
 263   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 264     push @{$self->{select_bind}}, @{$$fields}[1..$#$$fields];
 265     return $$fields->[0];
 266   }
 267   else {
 268     $self->throw_exception( $ref . qq{ unexpected in _recurse_fields()} );
 269   }
 270 }
 271
 272
 273 # this used to be a part of _order_by but is broken out for clarity.
 274 # What we have been doing forever is hijacking the $order arg of
 275 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 276 # then pretty much the entire resultset attr-hash, as more and more
 277 # things in the SQLA space need to have mopre info about the $rs they
 278 # create SQL for. The alternative would be to keep expanding the
 279 # signature of _select with more and more positional parameters, which
 280 # is just gross. All hail SQLA2!
 281 sub _parse_rs_attrs {
 282   my ($self, $arg) = @_;
 283
 284   my $sql = '';
 285
 286   if ($arg->{group_by}) {
 287     # horible horrible, waiting for refactor
 288     local $self->{select_bind};
 289     if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 290       $sql .= $self->_sqlcase(' group by ') . $g;
 291       push @{$self->{group_bind} ||= []}, @{$self->{select_bind}||[]};
 292     }
 293   }
 294
 295   if (defined $arg->{having}) {
 296     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 297     push(@{$self->{having_bind}}, @bind);
 298     $sql .= $self->_sqlcase(' having ') . $frag;
 299   }
 300
 301   if (defined $arg->{order_by}) {
 302     $sql .= $self->_order_by ($arg->{order_by});
 303   }
 304
 305   return $sql;
 306 }
 307
 308 sub _order_by {
 309   my ($self, $arg) = @_;
 310
 311   # check that we are not called in legacy mode (order_by as 4th argument)
 312   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 313     return $self->_parse_rs_attrs ($arg);
 314   }
 315   else {
 316     my ($sql, @bind) = $self->next::method($arg);
 317     push @{$self->{order_bind}}, @bind;
 318     return $sql;
 319   }
 320 }
 321
 322 sub _table {
 323 # optimized due to hotttnesss
 324 #  my ($self, $from) = @_;
 325   if (my $ref = ref $_[1] ) {
 326     if ($ref eq 'ARRAY') {
 327       return $_[0]->_recurse_from(@{$_[1]});
 328     }
 329     elsif ($ref eq 'HASH') {
 330       return $_[0]->_recurse_from($_[1]);
 331     }
 332     elsif ($ref eq 'REF' && ref ${$_[1]} eq 'ARRAY') {
 333       my ($sql, @bind) = @{ ${$_[1]} };
 334       push @{$_[0]->{from_bind}}, @bind;
 335       return $sql
 336     }
 337   }
 338   return $_[0]->next::method ($_[1]);
 339 }
 340
 341 sub _generate_join_clause {
 342     my ($self, $join_type) = @_;
 343
 344     $join_type = $self->{_default_jointype}
 345       if ! defined $join_type;
 346
 347     return sprintf ('%s JOIN ',
 348       $join_type ?  $self->_sqlcase($join_type) : ''
 349     );
 350 }
 351
 352 sub _recurse_from {
 353   my $self = shift;
 354
 355   return join (' ', $self->_gen_from_blocks(@_) );
 356 }
 357
 358 sub _gen_from_blocks {
 359   my ($self, $from, @joins) = @_;
 360
 361   my @fchunks = $self->_from_chunk_to_sql($from);
 362
 363   for (@joins) {
 364     my ($to, $on) = @$_;
 365
 366     # check whether a join type exists
 367     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 368     my $join_type;
 369     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 370       $join_type = $to_jt->{-join_type};
 371       $join_type =~ s/^\s+ | \s+$//xg;
 372     }
 373
 374     my @j = $self->_generate_join_clause( $join_type );
 375
 376     if (ref $to eq 'ARRAY') {
 377       push(@j, '(', $self->_recurse_from(@$to), ')');
 378     }
 379     else {
 380       push(@j, $self->_from_chunk_to_sql($to));
 381     }
 382
 383     my ($sql, @bind) = $self->_join_condition($on);
 384     push(@j, ' ON ', $sql);
 385     push @{$self->{from_bind}}, @bind;
 386
 387     push @fchunks, join '', @j;
 388   }
 389
 390   return @fchunks;
 391 }
 392
 393 sub _from_chunk_to_sql {
 394   my ($self, $fromspec) = @_;
 395
 396   return join (' ', do {
 397     if (! ref $fromspec) {
 398       $self->_quote($fromspec);
 399     }
 400     elsif (ref $fromspec eq 'SCALAR') {
 401       $$fromspec;
 402     }
 403     elsif (ref $fromspec eq 'REF' and ref $$fromspec eq 'ARRAY') {
 404       push @{$self->{from_bind}}, @{$$fromspec}[1..$#$$fromspec];
 405       $$fromspec->[0];
 406     }
 407     elsif (ref $fromspec eq 'HASH') {
 408       my ($as, $table, $toomuch) = ( map
 409         { $_ => $fromspec->{$_} }
 410         ( grep { $_ !~ /^\-/ } keys %$fromspec )
 411       );
 412
 413       $self->throw_exception( "Only one table/as pair expected in from-spec but an exra '$toomuch' key present" )
 414         if defined $toomuch;
 415
 416       ($self->_from_chunk_to_sql($table), $self->_quote($as) );
 417     }
 418     else {
 419       $self->throw_exception('Unsupported from refkind: ' . ref $fromspec );
 420     }
 421   });
 422 }
 423
 424 sub _join_condition {
 425   my ($self, $cond) = @_;
 426
 427   # Backcompat for the old days when a plain hashref
 428   # { 't1.col1' => 't2.col2' } meant ON t1.col1 = t2.col2
 429   # Once things settle we should start warning here so that
 430   # folks unroll their hacks
 431   if (
 432     ref $cond eq 'HASH'
 433       and
 434     keys %$cond == 1
 435       and
 436     (keys %$cond)[0] =~ /\./
 437       and
 438     ! ref ( (values %$cond)[0] )
 439   ) {
 440     $cond = { keys %$cond => { -ident => values %$cond } }
 441   }
 442   elsif ( ref $cond eq 'ARRAY' ) {
 443     # do our own ORing so that the hashref-shim above is invoked
 444     my @parts;
 445     my @binds;
 446     foreach my $c (@$cond) {
 447       my ($sql, @bind) = $self->_join_condition($c);
 448       push @binds, @bind;
 449       push @parts, $sql;
 450     }
 451     return join(' OR ', @parts), @binds;
 452   }
 453
 454   return $self->_recurse_where($cond);
 455 }
 456
 457 # This is hideously ugly, but SQLA does not understand multicol IN expressions
 458 # FIXME TEMPORARY - DQ should have native syntax for this
 459 # moved here to raise API questions
 460 #
 461 # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
 462 sub _where_op_multicolumn_in {
 463   my ($self, $lhs, $rhs) = @_;
 464
 465   if (! ref $lhs or ref $lhs eq 'ARRAY') {
 466     my (@sql, @bind);
 467     for (ref $lhs ? @$lhs : $lhs) {
 468       if (! ref $_) {
 469         push @sql, $self->_quote($_);
 470       }
 471       elsif (ref $_ eq 'SCALAR') {
 472         push @sql, $$_;
 473       }
 474       elsif (ref $_ eq 'REF' and ref $$_ eq 'ARRAY') {
 475         my ($s, @b) = @$$_;
 476         push @sql, $s;
 477         push @bind, @b;
 478       }
 479       else {
 480         $self->throw_exception("ARRAY of @{[ ref $_ ]}es unsupported for multicolumn IN lhs...");
 481       }
 482     }
 483     $lhs = \[ join(', ', @sql), @bind];
 484   }
 485   elsif (ref $lhs eq 'SCALAR') {
 486     $lhs = \[ $$lhs ];
 487   }
 488   elsif (ref $lhs eq 'REF' and ref $$lhs eq 'ARRAY' ) {
 489     # noop
 490   }
 491   else {
 492     $self->throw_exception( ref($lhs) . "es unsupported for multicolumn IN lhs...");
 493   }
 494
 495   # is this proper...?
 496   $rhs = \[ $self->_recurse_where($rhs) ];
 497
 498   for ($lhs, $rhs) {
 499     $$_->[0] = "( $$_->[0] )"
 500       unless $$_->[0] =~ /^ \s* \( .* \) \s* ^/xs;
 501   }
 502
 503   \[ join( ' IN ', shift @$$lhs, shift @$$rhs ), @$$lhs, @$$rhs ];
 504 }
 505
 506 1;
 507
 508 =head1 AUTHORS
 509
 510 See L<DBIx::Class/CONTRIBUTORS>.
 511
 512 =head1 LICENSE
 513
 514 You may distribute this code under the same terms as Perl itself.
 515
 516 =cut