lib/DBIx/Class/SQLAHacks.pm

   1 package # Hide from PAUSE
   2   DBIx::Class::SQLAHacks;
   3
   4 # This module is a subclass of SQL::Abstract::Limit and includes a number
   5 # of DBIC-specific workarounds, not yet suitable for inclusion into the
   6 # SQLA core
   7
   8 use base qw/SQL::Abstract::Limit/;
   9 use strict;
  10 use warnings;
  11 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract/;
  12 use Sub::Name();
  13
  14 BEGIN {
  15   # reinstall the carp()/croak() functions imported into SQL::Abstract
  16   # as Carp and Carp::Clan do not like each other much
  17   no warnings qw/redefine/;
  18   no strict qw/refs/;
  19   for my $f (qw/carp croak/) {
  20
  21     my $orig = \&{"SQL::Abstract::$f"};
  22     *{"SQL::Abstract::$f"} = Sub::Name::subname "SQL::Abstract::$f" =>
  23       sub {
  24         if (Carp::longmess() =~ /DBIx::Class::SQLAHacks::[\w]+ .+? called \s at/x) {
  25           __PACKAGE__->can($f)->(@_);
  26         }
  27         else {
  28           goto $orig;
  29         }
  30       };
  31   }
  32 }
  33
  34
  35 # Tries to determine limit dialect.
  36 #
  37 sub new {
  38   my $self = shift->SUPER::new(@_);
  39
  40   # This prevents the caching of $dbh in S::A::L, I believe
  41   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  42   #   it with what it resolves to:
  43   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  44     if ref $self->{limit_dialect};
  45
  46   $self;
  47 }
  48
  49 # !!! THIS IS ALSO HORRIFIC !!! /me ashamed
  50 #
  51 # Generates inner/outer select lists for various limit dialects
  52 # which result in one or more subqueries (e.g. RNO, Top, RowNum)
  53 # Any non-root-table columns need to have their table qualifier
  54 # turned into a column alias (otherwise names in subqueries clash
  55 # and/or lose their source table)
  56 #
  57 # Returns inner/outer strings of SQL QUOTED selectors with aliases
  58 # (to be used in whatever select statement), and an alias index hashref
  59 # of QUOTED SEL => QUOTED ALIAS pairs (to maybe be used for string-subst
  60 # higher up).
  61 # If an order_by is supplied, the inner select needs to bring out columns
  62 # used in implicit (non-selected) orders, and the order condition itself
  63 # needs to be realiased to the proper names in the outer query. Thus we
  64 # also return a hashref (order doesn't matter) of QUOTED EXTRA-SEL =>
  65 # QUOTED ALIAS pairs, which is a list of extra selectors that do *not*
  66 # exist in the original select list
  67
  68 sub _subqueried_limit_attrs {
  69   my ($self, $rs_attrs) = @_;
  70
  71   croak 'Limit dialect implementation usable only in the context of DBIC (missing $rs_attrs)'
  72     unless ref ($rs_attrs) eq 'HASH';
  73
  74   my ($re_sep, $re_alias) = map { quotemeta $_ } (
  75     $self->name_sep || '.',
  76     $rs_attrs->{alias},
  77   );
  78
  79   # correlate select and as, build selection index
  80   my (@sel, $in_sel_index);
  81   for my $i (0 .. $#{$rs_attrs->{select}}) {
  82
  83     my $s = $rs_attrs->{select}[$i];
  84     my $sql_sel = $self->_recurse_fields ($s);
  85     my $sql_alias = (ref $s) eq 'HASH' ? $s->{-as} : undef;
  86
  87
  88     push @sel, {
  89       sql => $sql_sel,
  90       unquoted_sql => do { local $self->{quote_char}; $self->_recurse_fields ($s) },
  91       as =>
  92         $sql_alias
  93           ||
  94         $rs_attrs->{as}[$i]
  95           ||
  96         croak "Select argument $i ($s) without corresponding 'as'"
  97       ,
  98     };
  99
 100     $in_sel_index->{$sql_sel}++;
 101     $in_sel_index->{$self->_quote ($sql_alias)}++ if $sql_alias;
 102
 103     # record unqualified versions too, so we do not have
 104     # to reselect the same column twice (in qualified and
 105     # unqualified form)
 106     if (! ref $s && $sql_sel =~ / $re_sep (.+) $/x) {
 107       $in_sel_index->{$1}++;
 108     }
 109   }
 110
 111
 112   # re-alias and remove any name separators from aliases,
 113   # unless we are dealing with the current source alias
 114   # (which will transcend the subqueries as it is necessary
 115   # for possible further chaining)
 116   my (@in_sel, @out_sel, %renamed);
 117   for my $node (@sel) {
 118     if (List::Util::first { $_ =~ / (?<! $re_alias ) $re_sep /x } ($node->{as}, $node->{unquoted_sql}) )  {
 119       $node->{as} =~ s/ $re_sep /__/xg;
 120       my $quoted_as = $self->_quote($node->{as});
 121       push @in_sel, sprintf '%s AS %s', $node->{sql}, $quoted_as;
 122       push @out_sel, $quoted_as;
 123       $renamed{$node->{sql}} = $quoted_as;
 124     }
 125     else {
 126       push @in_sel, $node->{sql};
 127       push @out_sel, $self->_quote ($node->{as});
 128     }
 129   }
 130
 131   # see if the order gives us anything
 132   my %extra_order_sel;
 133   for my $chunk ($self->_order_by_chunks ($rs_attrs->{order_by})) {
 134     # order with bind
 135     $chunk = $chunk->[0] if (ref $chunk) eq 'ARRAY';
 136     $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 137
 138     next if $in_sel_index->{$chunk};
 139
 140     $extra_order_sel{$chunk} ||= $self->_quote (
 141       'ORDER__BY__' . scalar keys %extra_order_sel
 142     );
 143   }
 144
 145   return (
 146     (map { join (', ', @$_ ) } (
 147       \@in_sel,
 148       \@out_sel)
 149     ),
 150     \%renamed,
 151     keys %extra_order_sel ? \%extra_order_sel : (),
 152   );
 153 }
 154
 155 # ANSI standard Limit/Offset implementation. DB2 and MSSQL >= 2005 use this
 156 sub _RowNumberOver {
 157   my ($self, $sql, $rs_attrs, $rows, $offset ) = @_;
 158
 159   # mangle the input sql as we will be replacing the selector
 160   $sql =~ s/^ \s* SELECT \s+ .+? \s+ (?= \b FROM \b )//ix
 161     or croak "Unrecognizable SELECT: $sql";
 162
 163   # get selectors, and scan the order_by (if any)
 164   my ($in_sel, $out_sel, $alias_map, $extra_order_sel)
 165     = $self->_subqueried_limit_attrs ( $rs_attrs );
 166
 167   # make up an order if none exists
 168   my $requested_order = (delete $rs_attrs->{order_by}) || $self->_rno_default_order;
 169   my $rno_ord = $self->_order_by ($requested_order);
 170
 171   # this is the order supplement magic
 172   my $mid_sel = $out_sel;
 173   if ($extra_order_sel) {
 174     for my $extra_col (sort
 175       { $extra_order_sel->{$a} cmp $extra_order_sel->{$b} }
 176       keys %$extra_order_sel
 177     ) {
 178       $in_sel .= sprintf (', %s AS %s',
 179         $extra_col,
 180         $extra_order_sel->{$extra_col},
 181       );
 182
 183       $mid_sel .= ', ' . $extra_order_sel->{$extra_col};
 184     }
 185   }
 186
 187   # and this is order re-alias magic
 188   for ($extra_order_sel, $alias_map) {
 189     for my $col (keys %$_) {
 190       my $re_col = quotemeta ($col);
 191       $rno_ord =~ s/$re_col/$_->{$col}/;
 192     }
 193   }
 194
 195   # whatever is left of the order_by (only where is processed at this point)
 196   my $group_having = $self->_parse_rs_attrs($rs_attrs);
 197
 198   my $qalias = $self->_quote ($rs_attrs->{alias});
 199   my $idx_name = $self->_quote ('rno__row__index');
 200
 201   $sql = sprintf (<<EOS, $offset + 1, $offset + $rows, );
 202
 203 SELECT $out_sel FROM (
 204   SELECT $mid_sel, ROW_NUMBER() OVER( $rno_ord ) AS $idx_name FROM (
 205     SELECT $in_sel ${sql}${group_having}
 206   ) $qalias
 207 ) $qalias WHERE $idx_name BETWEEN %u AND %u
 208
 209 EOS
 210
 211   $sql =~ s/\s*\n\s*/ /g;   # easier to read in the debugger
 212   return $sql;
 213 }
 214
 215 # some databases are happy with OVER (), some need OVER (ORDER BY (SELECT (1)) )
 216 sub _rno_default_order {
 217   return undef;
 218 }
 219
 220 # Informix specific limit, almost like LIMIT/OFFSET
 221 sub _SkipFirst {
 222   my ($self, $sql, $rs_attrs, $rows, $offset) = @_;
 223
 224   $sql =~ s/^ \s* SELECT \s+ //ix
 225     or croak "Unrecognizable SELECT: $sql";
 226
 227   return sprintf ('SELECT %s%s%s%s',
 228     $offset
 229       ? sprintf ('SKIP %u ', $offset)
 230       : ''
 231     ,
 232     sprintf ('FIRST %u ', $rows),
 233     $sql,
 234     $self->_parse_rs_attrs ($rs_attrs),
 235   );
 236 }
 237
 238 # Firebird specific limit, reverse of _SkipFirst for Informix
 239 sub _FirstSkip {
 240   my ($self, $sql, $rs_attrs, $rows, $offset) = @_;
 241
 242   $sql =~ s/^ \s* SELECT \s+ //ix
 243     or croak "Unrecognizable SELECT: $sql";
 244
 245   return sprintf ('SELECT %s%s%s%s',
 246     sprintf ('FIRST %u ', $rows),
 247     $offset
 248       ? sprintf ('SKIP %u ', $offset)
 249       : ''
 250     ,
 251     $sql,
 252     $self->_parse_rs_attrs ($rs_attrs),
 253   );
 254 }
 255
 256 # WhOracle limits
 257 sub _RowNum {
 258   my ( $self, $sql, $rs_attrs, $rows, $offset ) = @_;
 259
 260   # mangle the input sql as we will be replacing the selector
 261   $sql =~ s/^ \s* SELECT \s+ .+? \s+ (?= \b FROM \b )//ix
 262     or croak "Unrecognizable SELECT: $sql";
 263
 264   my ($insel, $outsel) = $self->_subqueried_limit_attrs ($rs_attrs);
 265
 266   my $qalias = $self->_quote ($rs_attrs->{alias});
 267   my $idx_name = $self->_quote ('rownum__index');
 268   my $order_group_having = $self->_parse_rs_attrs($rs_attrs);
 269
 270   $sql = sprintf (<<EOS, $offset + 1, $offset + $rows, );
 271
 272 SELECT $outsel FROM (
 273   SELECT $outsel, ROWNUM $idx_name FROM (
 274     SELECT $insel ${sql}${order_group_having}
 275   ) $qalias
 276 ) $qalias WHERE $idx_name BETWEEN %u AND %u
 277
 278 EOS
 279
 280   $sql =~ s/\s*\n\s*/ /g;   # easier to read in the debugger
 281   return $sql;
 282 }
 283
 284 # Crappy Top based Limit/Offset support. Legacy for MSSQL < 2005
 285 sub _Top {
 286   my ( $self, $sql, $rs_attrs, $rows, $offset ) = @_;
 287
 288   # mangle the input sql as we will be replacing the selector
 289   $sql =~ s/^ \s* SELECT \s+ .+? \s+ (?= \b FROM \b )//ix
 290     or croak "Unrecognizable SELECT: $sql";
 291
 292   # get selectors
 293   my ($in_sel, $out_sel, $alias_map, $extra_order_sel)
 294     = $self->_subqueried_limit_attrs ($rs_attrs);
 295
 296   my $requested_order = delete $rs_attrs->{order_by};
 297
 298   my $order_by_requested = $self->_order_by ($requested_order);
 299
 300   # make up an order unless supplied
 301   my $inner_order = ($order_by_requested
 302     ? $requested_order
 303     : [ map
 304       { join ('', $rs_attrs->{alias}, $self->{name_sep}||'.', $_ ) }
 305       ( $rs_attrs->{_rsroot_source_handle}->resolve->_pri_cols )
 306     ]
 307   );
 308
 309   my ($order_by_inner, $order_by_reversed);
 310
 311   # localise as we already have all the bind values we need
 312   {
 313     local $self->{order_bind};
 314     $order_by_inner = $self->_order_by ($inner_order);
 315
 316     my @out_chunks;
 317     for my $ch ($self->_order_by_chunks ($inner_order)) {
 318       $ch = $ch->[0] if ref $ch eq 'ARRAY';
 319
 320       $ch =~ s/\s+ ( ASC|DESC ) \s* $//ix;
 321       my $dir = uc ($1||'ASC');
 322
 323       push @out_chunks, \join (' ', $ch, $dir eq 'ASC' ? 'DESC' : 'ASC' );
 324     }
 325
 326     $order_by_reversed = $self->_order_by (\@out_chunks);
 327   }
 328
 329   # this is the order supplement magic
 330   my $mid_sel = $out_sel;
 331   if ($extra_order_sel) {
 332     for my $extra_col (sort
 333       { $extra_order_sel->{$a} cmp $extra_order_sel->{$b} }
 334       keys %$extra_order_sel
 335     ) {
 336       $in_sel .= sprintf (', %s AS %s',
 337         $extra_col,
 338         $extra_order_sel->{$extra_col},
 339       );
 340
 341       $mid_sel .= ', ' . $extra_order_sel->{$extra_col};
 342     }
 343
 344     # since whatever order bindvals there are, they will be realiased
 345     # and need to show up in front of the entire initial inner subquery
 346     # Unshift *from_bind* to make this happen (horrible, horrible, but
 347     # we don't have another mechanism yet)
 348     unshift @{$self->{from_bind}}, @{$self->{order_bind}};
 349   }
 350
 351   # and this is order re-alias magic
 352   for my $map ($extra_order_sel, $alias_map) {
 353     for my $col (keys %$map) {
 354       my $re_col = quotemeta ($col);
 355       $_ =~ s/$re_col/$map->{$col}/
 356         for ($order_by_reversed, $order_by_requested);
 357     }
 358   }
 359
 360   # generate the rest of the sql
 361   my $grpby_having = $self->_parse_rs_attrs ($rs_attrs);
 362
 363   my $quoted_rs_alias = $self->_quote ($rs_attrs->{alias});
 364
 365   $sql = sprintf ('SELECT TOP %u %s %s %s %s',
 366     $rows + ($offset||0),
 367     $in_sel,
 368     $sql,
 369     $grpby_having,
 370     $order_by_inner,
 371   );
 372
 373   $sql = sprintf ('SELECT TOP %u %s FROM ( %s ) %s %s',
 374     $rows,
 375     $mid_sel,
 376     $sql,
 377     $quoted_rs_alias,
 378     $order_by_reversed,
 379   ) if $offset;
 380
 381   $sql = sprintf ('SELECT TOP %u %s FROM ( %s ) %s %s',
 382     $rows,
 383     $out_sel,
 384     $sql,
 385     $quoted_rs_alias,
 386     $order_by_requested,
 387   ) if ( ($offset && $order_by_requested) || ($mid_sel ne $out_sel) );
 388
 389   $sql =~ s/\s*\n\s*/ /g;   # easier to read in the debugger
 390   return $sql;
 391 }
 392
 393 # This is the most evil limit "dialect" (more of a hack) for *really*
 394 # stupid databases. It works by ordering the set by some unique column,
 395 # and calculating amount of rows that have a less-er value (thus
 396 # emulating a RowNum-like index). Of course this implies the set can
 397 # only be ordered by a single unique columns.
 398 sub _GenericSubQ {
 399   my ($self, $sql, $rs_attrs, $rows, $offset) = @_;
 400
 401   my $root_rsrc = $rs_attrs->{_rsroot_source_handle}->resolve;
 402   my $root_tbl_name = $root_rsrc->name;
 403
 404   # mangle the input sql as we will be replacing the selector
 405   $sql =~ s/^ \s* SELECT \s+ .+? \s+ (?= \b FROM \b )//ix
 406     or croak "Unrecognizable SELECT: $sql";
 407
 408   my ($order_by, @rest) = do {
 409     local $self->{quote_char};
 410     $self->_order_by_chunks ($rs_attrs->{order_by})
 411   };
 412
 413   unless (
 414     $order_by
 415       &&
 416     ! @rest
 417       &&
 418     ( ! ref $order_by
 419         ||
 420       ( ref $order_by eq 'ARRAY' and @$order_by == 1 )
 421     )
 422   ) {
 423     croak (
 424       'Generic Subquery Limit does not work on resultsets without an order, or resultsets '
 425     . 'with complex order criteria (multicolumn and/or functions). Provide a single, '
 426     . 'unique-column order criteria.'
 427     );
 428   }
 429
 430   ($order_by) = @$order_by if ref $order_by;
 431
 432   $order_by =~ s/\s+ ( ASC|DESC ) \s* $//ix;
 433   my $direction = lc ($1 || 'asc');
 434
 435   my ($unq_sort_col) = $order_by =~ /(?:^|\.)([^\.]+)$/;
 436
 437   my $inf = $root_rsrc->storage->_resolve_column_info (
 438     $rs_attrs->{from}, [$order_by, $unq_sort_col]
 439   );
 440
 441   my $ord_colinfo = $inf->{$order_by} || croak "Unable to determine source of order-criteria '$order_by'";
 442
 443   if ($ord_colinfo->{-result_source}->name ne $root_tbl_name) {
 444     croak "Generic Subquery Limit order criteria can be only based on the root-source '"
 445         . $root_rsrc->source_name . "' (aliased as '$rs_attrs->{alias}')";
 446   }
 447
 448   # make sure order column is qualified
 449   $order_by = "$rs_attrs->{alias}.$order_by"
 450     unless $order_by =~ /^$rs_attrs->{alias}\./;
 451
 452   my $is_u;
 453   my $ucs = { $root_rsrc->unique_constraints };
 454   for (values %$ucs ) {
 455     if (@$_ == 1 && "$rs_attrs->{alias}.$_->[0]" eq $order_by) {
 456       $is_u++;
 457       last;
 458     }
 459   }
 460   croak "Generic Subquery Limit order criteria column '$order_by' must be unique (no unique constraint found)"
 461     unless $is_u;
 462
 463   my ($in_sel, $out_sel, $alias_map, $extra_order_sel)
 464     = $self->_subqueried_limit_attrs ($rs_attrs);
 465
 466   my $cmp_op = $direction eq 'desc' ? '>' : '<';
 467   my $count_tbl_alias = 'rownum__emulation';
 468
 469   my $order_group_having = $self->_parse_rs_attrs($rs_attrs);
 470
 471   # add the order supplement (if any) as this is what will be used for the outer WHERE
 472   $in_sel .= ", $_" for keys %{$extra_order_sel||{}};
 473
 474   $sql = sprintf (<<EOS,
 475 SELECT $out_sel
 476   FROM (
 477     SELECT $in_sel ${sql}${order_group_having}
 478   ) %s
 479 WHERE ( SELECT COUNT(*) FROM %s %s WHERE %s $cmp_op %s ) %s
 480 EOS
 481     ( map { $self->_quote ($_) } (
 482       $rs_attrs->{alias},
 483       $root_tbl_name,
 484       $count_tbl_alias,
 485       "$count_tbl_alias.$unq_sort_col",
 486       $order_by,
 487     )),
 488     $offset
 489       ? sprintf ('BETWEEN %u AND %u', $offset, $offset + $rows - 1)
 490       : sprintf ('< %u', $rows )
 491     ,
 492   );
 493
 494   $sql =~ s/\s*\n\s*/ /g;   # easier to read in the debugger
 495   return $sql;
 496 }
 497
 498
 499 # While we're at it, this should make LIMIT queries more efficient,
 500 #  without digging into things too deeply
 501 sub _find_syntax {
 502   my ($self, $syntax) = @_;
 503   return $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
 504 }
 505
 506 # Quotes table names, handles "limit" dialects (e.g. where rownum between x and
 507 # y)
 508 sub select {
 509   my ($self, $table, $fields, $where, $rs_attrs, @rest) = @_;
 510
 511   if (not ref($table) or ref($table) eq 'SCALAR') {
 512     $table = $self->_quote($table);
 513   }
 514
 515   @rest = (-1) unless defined $rest[0];
 516   croak "LIMIT 0 Does Not Compute" if $rest[0] == 0;
 517     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 518
 519   my ($sql, @bind) = $self->SUPER::select(
 520     $table, $self->_recurse_fields($fields), $where, $rs_attrs, @rest
 521   );
 522   push @{$self->{where_bind}}, @bind;
 523
 524 # this *must* be called, otherwise extra binds will remain in the sql-maker
 525   my @all_bind = $self->_assemble_binds;
 526
 527   return wantarray ? ($sql, @all_bind) : $sql;
 528 }
 529
 530 sub _assemble_binds {
 531   my $self = shift;
 532   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/from where having order/);
 533 }
 534
 535 # Quotes table names, and handles default inserts
 536 sub insert {
 537   my $self = shift;
 538   my $table = shift;
 539   $table = $self->_quote($table);
 540
 541   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 542   # which is sadly understood only by MySQL. Change default behavior here,
 543   # until SQLA2 comes with proper dialect support
 544   if (! $_[0] or (ref $_[0] eq 'HASH' and !keys %{$_[0]} ) ) {
 545     my $sql = "INSERT INTO ${table} DEFAULT VALUES";
 546
 547     if (my $ret = ($_[1]||{})->{returning} ) {
 548       $sql .= $self->_insert_returning ($ret);
 549     }
 550
 551     return $sql;
 552   }
 553
 554   $self->SUPER::insert($table, @_);
 555 }
 556
 557 # Just quotes table names.
 558 sub update {
 559   my $self = shift;
 560   my $table = shift;
 561   $table = $self->_quote($table);
 562   $self->SUPER::update($table, @_);
 563 }
 564
 565 # Just quotes table names.
 566 sub delete {
 567   my $self = shift;
 568   my $table = shift;
 569   $table = $self->_quote($table);
 570   $self->SUPER::delete($table, @_);
 571 }
 572
 573 sub _emulate_limit {
 574   my $self = shift;
 575   # my ( $syntax, $sql, $order, $rows, $offset ) = @_;
 576
 577   if ($_[3] == -1) {
 578     return $_[1] . $self->_parse_rs_attrs($_[2]);
 579   } else {
 580     return $self->SUPER::_emulate_limit(@_);
 581   }
 582 }
 583
 584 sub _recurse_fields {
 585   my ($self, $fields) = @_;
 586   my $ref = ref $fields;
 587   return $self->_quote($fields) unless $ref;
 588   return $$fields if $ref eq 'SCALAR';
 589
 590   if ($ref eq 'ARRAY') {
 591     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 592   }
 593   elsif ($ref eq 'HASH') {
 594     my %hash = %$fields;  # shallow copy
 595
 596     my $as = delete $hash{-as};   # if supplied
 597
 598     my ($func, $args, @toomany) = %hash;
 599
 600     # there should be only one pair
 601     if (@toomany) {
 602       croak "Malformed select argument - too many keys in hash: " . join (',', keys %$fields );
 603     }
 604
 605     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 606       croak (
 607         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 608        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 609        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 610       );
 611     }
 612
 613     my $select = sprintf ('%s( %s )%s',
 614       $self->_sqlcase($func),
 615       $self->_recurse_fields($args),
 616       $as
 617         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 618         : ''
 619     );
 620
 621     return $select;
 622   }
 623   # Is the second check absolutely necessary?
 624   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 625     return $self->_fold_sqlbind( $fields );
 626   }
 627   else {
 628     croak($ref . qq{ unexpected in _recurse_fields()})
 629   }
 630 }
 631
 632 my $for_syntax = {
 633   update => 'FOR UPDATE',
 634   shared => 'FOR SHARE',
 635 };
 636
 637 # this used to be a part of _order_by but is broken out for clarity.
 638 # What we have been doing forever is hijacking the $order arg of
 639 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 640 # then pretty much the entire resultset attr-hash, as more and more
 641 # things in the SQLA space need to have mopre info about the $rs they
 642 # create SQL for. The alternative would be to keep expanding the
 643 # signature of _select with more and more positional parameters, which
 644 # is just gross. All hail SQLA2!
 645 sub _parse_rs_attrs {
 646   my ($self, $arg) = @_;
 647
 648   my $sql = '';
 649
 650   if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 651     $sql .= $self->_sqlcase(' group by ') . $g;
 652   }
 653
 654   if (defined $arg->{having}) {
 655     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 656     push(@{$self->{having_bind}}, @bind);
 657     $sql .= $self->_sqlcase(' having ') . $frag;
 658   }
 659
 660   if (defined $arg->{order_by}) {
 661     $sql .= $self->_order_by ($arg->{order_by});
 662   }
 663
 664   if (my $for = $arg->{for}) {
 665     $sql .= " $for_syntax->{$for}" if $for_syntax->{$for};
 666   }
 667
 668   return $sql;
 669 }
 670
 671 sub _order_by {
 672   my ($self, $arg) = @_;
 673
 674   # check that we are not called in legacy mode (order_by as 4th argument)
 675   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 676     return $self->_parse_rs_attrs ($arg);
 677   }
 678   else {
 679     my ($sql, @bind) = $self->SUPER::_order_by ($arg);
 680     push @{$self->{order_bind}}, @bind;
 681     return $sql;
 682   }
 683 }
 684
 685 sub _order_directions {
 686   my ($self, $order) = @_;
 687
 688   # strip bind values - none of the current _order_directions users support them
 689   return $self->SUPER::_order_directions( [ map
 690     { ref $_ ? $_->[0] : $_ }
 691     $self->_order_by_chunks ($order)
 692   ]);
 693 }
 694
 695 sub _table {
 696   my ($self, $from) = @_;
 697   if (ref $from eq 'ARRAY') {
 698     return $self->_recurse_from(@$from);
 699   } elsif (ref $from eq 'HASH') {
 700     return $self->_make_as($from);
 701   } else {
 702     return $from; # would love to quote here but _table ends up getting called
 703                   # twice during an ->select without a limit clause due to
 704                   # the way S::A::Limit->select works. should maybe consider
 705                   # bypassing this and doing S::A::select($self, ...) in
 706                   # our select method above. meantime, quoting shims have
 707                   # been added to select/insert/update/delete here
 708   }
 709 }
 710
 711 sub _generate_join_clause {
 712     my ($self, $join_type) = @_;
 713
 714     return sprintf ('%s JOIN ',
 715       $join_type ?  ' ' . uc($join_type) : ''
 716     );
 717 }
 718
 719 sub _recurse_from {
 720   my ($self, $from, @join) = @_;
 721   my @sqlf;
 722   push(@sqlf, $self->_make_as($from));
 723   foreach my $j (@join) {
 724     my ($to, $on) = @$j;
 725
 726
 727     # check whether a join type exists
 728     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 729     my $join_type;
 730     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 731       $join_type = $to_jt->{-join_type};
 732       $join_type =~ s/^\s+ | \s+$//xg;
 733     }
 734
 735     $join_type = $self->{_default_jointype} if not defined $join_type;
 736
 737     push @sqlf, $self->_generate_join_clause( $join_type );
 738
 739     if (ref $to eq 'ARRAY') {
 740       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 741     } else {
 742       push(@sqlf, $self->_make_as($to));
 743     }
 744     push(@sqlf, ' ON ', $self->_join_condition($on));
 745   }
 746   return join('', @sqlf);
 747 }
 748
 749 sub _fold_sqlbind {
 750   my ($self, $sqlbind) = @_;
 751
 752   my @sqlbind = @$$sqlbind; # copy
 753   my $sql = shift @sqlbind;
 754   push @{$self->{from_bind}}, @sqlbind;
 755
 756   return $sql;
 757 }
 758
 759 sub _make_as {
 760   my ($self, $from) = @_;
 761   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 762                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 763                         : $self->_quote($_))
 764                        } reverse each %{$self->_skip_options($from)});
 765 }
 766
 767 sub _skip_options {
 768   my ($self, $hash) = @_;
 769   my $clean_hash = {};
 770   $clean_hash->{$_} = $hash->{$_}
 771     for grep {!/^-/} keys %$hash;
 772   return $clean_hash;
 773 }
 774
 775 sub _join_condition {
 776   my ($self, $cond) = @_;
 777   if (ref $cond eq 'HASH') {
 778     my %j;
 779     for (keys %$cond) {
 780       my $v = $cond->{$_};
 781       if (ref $v) {
 782         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 783             if ref($v) ne 'SCALAR';
 784         $j{$_} = $v;
 785       }
 786       else {
 787         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 788       }
 789     };
 790     return scalar($self->_recurse_where(\%j));
 791   } elsif (ref $cond eq 'ARRAY') {
 792     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 793   } else {
 794     die "Can't handle this yet!";
 795   }
 796 }
 797
 798 sub limit_dialect {
 799     my $self = shift;
 800     if (@_) {
 801       $self->{limit_dialect} = shift;
 802       undef $self->{_cached_syntax};
 803     }
 804     return $self->{limit_dialect};
 805 }
 806
 807 # Set to an array-ref to specify separate left and right quotes for table names.
 808 # A single scalar is equivalen to [ $char, $char ]
 809 sub quote_char {
 810     my $self = shift;
 811     $self->{quote_char} = shift if @_;
 812     return $self->{quote_char};
 813 }
 814
 815 # Character separating quoted table names.
 816 sub name_sep {
 817     my $self = shift;
 818     $self->{name_sep} = shift if @_;
 819     return $self->{name_sep};
 820 }
 821
 822 1;