lib/DBIx/Class/SQLAHacks.pm

   1 package # Hide from PAUSE
   2   DBIx::Class::SQLAHacks;
   3
   4 use base qw/SQL::Abstract::Limit/;
   5 use strict;
   6 use warnings;
   7 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract/;
   8
   9 BEGIN {
  10   # reinstall the carp()/croak() functions imported into SQL::Abstract
  11   # as Carp and Carp::Clan do not like each other much
  12   no warnings qw/redefine/;
  13   no strict qw/refs/;
  14   for my $f (qw/carp croak/) {
  15     my $orig = \&{"SQL::Abstract::$f"};
  16     *{"SQL::Abstract::$f"} = sub {
  17
  18       local $Carp::CarpLevel = 1;   # even though Carp::Clan ignores this, $orig will not
  19
  20       if (Carp::longmess() =~ /DBIx::Class::SQLAHacks::[\w]+\(\) called/) {
  21         __PACKAGE__->can($f)->(@_);
  22       }
  23       else {
  24         $orig->(@_);
  25       }
  26     }
  27   }
  28 }
  29
  30 sub new {
  31   my $self = shift->SUPER::new(@_);
  32
  33   # This prevents the caching of $dbh in S::A::L, I believe
  34   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  35   #   it with what it resolves to:
  36   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  37     if ref $self->{limit_dialect};
  38
  39   $self;
  40 }
  41
  42
  43 # Some databases (sqlite) do not handle multiple parenthesis
  44 # around in/between arguments. A tentative x IN ( ( 1, 2 ,3) )
  45 # is interpreted as x IN 1 or something similar.
  46 #
  47 # Since we currently do not have access to the SQLA AST, resort
  48 # to barbaric mutilation of any SQL supplied in literal form
  49
  50 sub _strip_outer_paren {
  51   my ($self, $arg) = @_;
  52
  53   return $self->_SWITCH_refkind ($arg, {
  54     ARRAYREFREF => sub {
  55       $$arg->[0] = __strip_outer_paren ($$arg->[0]);
  56       return $arg;
  57     },
  58     SCALARREF => sub {
  59       return \__strip_outer_paren( $$arg );
  60     },
  61     FALLBACK => sub {
  62       return $arg
  63     },
  64   });
  65 }
  66
  67 sub __strip_outer_paren {
  68   my $sql = shift;
  69
  70   if ($sql and not ref $sql) {
  71     while ($sql =~ /^ \s* \( (.*) \) \s* $/x ) {
  72       $sql = $1;
  73     }
  74   }
  75
  76   return $sql;
  77 }
  78
  79 sub _where_field_IN {
  80   my ($self, $lhs, $op, $rhs) = @_;
  81   $rhs = $self->_strip_outer_paren ($rhs);
  82   return $self->SUPER::_where_field_IN ($lhs, $op, $rhs);
  83 }
  84
  85 sub _where_field_BETWEEN {
  86   my ($self, $lhs, $op, $rhs) = @_;
  87   $rhs = $self->_strip_outer_paren ($rhs);
  88   return $self->SUPER::_where_field_BETWEEN ($lhs, $op, $rhs);
  89 }
  90
  91 # Slow but ANSI standard Limit/Offset support. DB2 uses this
  92 sub _RowNumberOver {
  93   my ($self, $sql, $order, $rows, $offset ) = @_;
  94
  95   $offset += 1;
  96   my $last = $rows + $offset - 1;
  97   my ( $order_by ) = $self->_order_by( $order );
  98
  99   $sql = <<"SQL";
 100 SELECT * FROM
 101 (
 102    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
 103       $sql
 104       $order_by
 105    ) Q1
 106 ) Q2
 107 WHERE ROW_NUM BETWEEN $offset AND $last
 108
 109 SQL
 110
 111   return $sql;
 112 }
 113
 114 # Crappy Top based Limit/Offset support. MSSQL uses this currently,
 115 # but may have to switch to RowNumberOver one day
 116 sub _Top {
 117   my ( $self, $sql, $order, $rows, $offset ) = @_;
 118
 119   croak '$order supplied to SQLAHacks limit emulators must be a hash'
 120     if (ref $order ne 'HASH');
 121
 122   $order = { %$order }; #copy
 123
 124   my $last = $rows + $offset;
 125
 126   my $req_order = $self->_order_by ($order->{order_by});
 127
 128   my $limit_order = $req_order ? $order->{order_by} : $order->{_virtual_order_by};
 129
 130   delete $order->{$_} for qw/order_by _virtual_order_by/;
 131   my $grpby_having = $self->_order_by ($order);
 132
 133   my ( $order_by_inner, $order_by_outer ) = $self->_order_directions($limit_order);
 134
 135   $sql =~ s/^\s*(SELECT|select)//;
 136
 137   $sql = <<"SQL";
 138   SELECT * FROM
 139   (
 140     SELECT TOP $rows * FROM
 141     (
 142         SELECT TOP $last $sql $grpby_having $order_by_inner
 143     ) AS foo
 144     $order_by_outer
 145   ) AS bar
 146   $req_order
 147
 148 SQL
 149     return $sql;
 150 }
 151
 152
 153
 154 # While we're at it, this should make LIMIT queries more efficient,
 155 #  without digging into things too deeply
 156 sub _find_syntax {
 157   my ($self, $syntax) = @_;
 158   return $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
 159 }
 160
 161 sub select {
 162   my ($self, $table, $fields, $where, $order, @rest) = @_;
 163
 164   $self->{"${_}_bind"} = [] for (qw/having from order/);
 165
 166   if (ref $table eq 'SCALAR') {
 167     $table = $$table;
 168   }
 169   elsif (not ref $table) {
 170     $table = $self->_quote($table);
 171   }
 172   local $self->{rownum_hack_count} = 1
 173     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
 174   @rest = (-1) unless defined $rest[0];
 175   croak "LIMIT 0 Does Not Compute" if $rest[0] == 0;
 176     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 177   my ($sql, @where_bind) = $self->SUPER::select(
 178     $table, $self->_recurse_fields($fields), $where, $order, @rest
 179   );
 180   $sql .=
 181     $self->{for} ?
 182     (
 183       $self->{for} eq 'update' ? ' FOR UPDATE' :
 184       $self->{for} eq 'shared' ? ' FOR SHARE'  :
 185       ''
 186     ) :
 187     ''
 188   ;
 189   return wantarray ? ($sql, @{$self->{from_bind}}, @where_bind, @{$self->{having_bind}}, @{$self->{order_bind}} ) : $sql;
 190 }
 191
 192 sub insert {
 193   my $self = shift;
 194   my $table = shift;
 195   $table = $self->_quote($table) unless ref($table);
 196
 197   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 198   # which is sadly understood only by MySQL. Change default behavior here,
 199   # until SQLA2 comes with proper dialect support
 200   if (! $_[0] or (ref $_[0] eq 'HASH' and !keys %{$_[0]} ) ) {
 201     return "INSERT INTO ${table} DEFAULT VALUES"
 202   }
 203
 204   $self->SUPER::insert($table, @_);
 205 }
 206
 207 sub update {
 208   my $self = shift;
 209   my $table = shift;
 210   $table = $self->_quote($table) unless ref($table);
 211   $self->SUPER::update($table, @_);
 212 }
 213
 214 sub delete {
 215   my $self = shift;
 216   my $table = shift;
 217   $table = $self->_quote($table) unless ref($table);
 218   $self->SUPER::delete($table, @_);
 219 }
 220
 221 sub _emulate_limit {
 222   my $self = shift;
 223   if ($_[3] == -1) {
 224     return $_[1].$self->_order_by($_[2]);
 225   } else {
 226     return $self->SUPER::_emulate_limit(@_);
 227   }
 228 }
 229
 230 sub _recurse_fields {
 231   my ($self, $fields, $params) = @_;
 232   my $ref = ref $fields;
 233   return $self->_quote($fields) unless $ref;
 234   return $$fields if $ref eq 'SCALAR';
 235
 236   if ($ref eq 'ARRAY') {
 237     return join(', ', map {
 238       $self->_recurse_fields($_)
 239         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 240           ? ' AS col'.$self->{rownum_hack_count}++
 241           : '')
 242       } @$fields);
 243   } elsif ($ref eq 'HASH') {
 244     foreach my $func (keys %$fields) {
 245       if ($func eq 'distinct') {
 246         my $_fields = $fields->{$func};
 247         if (ref $_fields eq 'ARRAY' && @{$_fields} > 1) {
 248           croak (
 249             'The select => { distinct => ... } syntax is not supported for multiple columns.'
 250            .' Instead please use { group_by => [ qw/' . (join ' ', @$_fields) . '/ ] }'
 251            .' or { select => [ qw/' . (join ' ', @$_fields) . '/ ], distinct => 1 }'
 252           );
 253         }
 254         else {
 255           $_fields = @{$_fields}[0] if ref $_fields eq 'ARRAY';
 256           carp (
 257             'The select => { distinct => ... } syntax will be deprecated in DBIC version 0.09,'
 258            ." please use { group_by => '${_fields}' } or { select => '${_fields}', distinct => 1 }"
 259           );
 260         }
 261       }
 262       return $self->_sqlcase($func)
 263         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 264     }
 265   }
 266   # Is the second check absolutely necessary?
 267   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 268     return $self->_fold_sqlbind( $fields );
 269   }
 270   else {
 271     croak($ref . qq{ unexpected in _recurse_fields()})
 272   }
 273 }
 274
 275 sub _order_by {
 276   my ($self, $arg) = @_;
 277
 278   if (ref $arg eq 'HASH' and keys %$arg and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 279
 280     my $ret = '';
 281
 282     if (defined $arg->{group_by}) {
 283       $ret = $self->_sqlcase(' group by ')
 284         .$self->_recurse_fields($arg->{group_by}, { no_rownum_hack => 1 });
 285     }
 286
 287     if (defined $arg->{having}) {
 288       my ($frag, @bind) = $self->_recurse_where($arg->{having});
 289       push(@{$self->{having_bind}}, @bind);
 290       $ret .= $self->_sqlcase(' having ').$frag;
 291     }
 292
 293     if (defined $arg->{order_by}) {
 294       my ($frag, @bind) = $self->SUPER::_order_by($arg->{order_by});
 295       push(@{$self->{order_bind}}, @bind);
 296       $ret .= $frag;
 297     }
 298
 299     return $ret;
 300   }
 301   else {
 302     my ($sql, @bind) = $self->SUPER::_order_by ($arg);
 303     push(@{$self->{order_bind}}, @bind);
 304     return $sql;
 305   }
 306 }
 307
 308 sub _order_directions {
 309   my ($self, $order) = @_;
 310
 311   # strip bind values - none of the current _order_directions users support them
 312   return $self->SUPER::_order_directions( [ map
 313     { ref $_ ? $_->[0] : $_ }
 314     $self->_order_by_chunks ($order)
 315   ]);
 316 }
 317
 318 sub _table {
 319   my ($self, $from) = @_;
 320   if (ref $from eq 'ARRAY') {
 321     return $self->_recurse_from(@$from);
 322   } elsif (ref $from eq 'HASH') {
 323     return $self->_make_as($from);
 324   } else {
 325     return $from; # would love to quote here but _table ends up getting called
 326                   # twice during an ->select without a limit clause due to
 327                   # the way S::A::Limit->select works. should maybe consider
 328                   # bypassing this and doing S::A::select($self, ...) in
 329                   # our select method above. meantime, quoting shims have
 330                   # been added to select/insert/update/delete here
 331   }
 332 }
 333
 334 sub _recurse_from {
 335   my ($self, $from, @join) = @_;
 336   my @sqlf;
 337   push(@sqlf, $self->_make_as($from));
 338   foreach my $j (@join) {
 339     my ($to, $on) = @$j;
 340
 341     # check whether a join type exists
 342     my $join_clause = '';
 343     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 344     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 345       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 346     } else {
 347       $join_clause = ' JOIN ';
 348     }
 349     push(@sqlf, $join_clause);
 350
 351     if (ref $to eq 'ARRAY') {
 352       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 353     } else {
 354       push(@sqlf, $self->_make_as($to));
 355     }
 356     push(@sqlf, ' ON ', $self->_join_condition($on));
 357   }
 358   return join('', @sqlf);
 359 }
 360
 361 sub _fold_sqlbind {
 362   my ($self, $sqlbind) = @_;
 363
 364   my @sqlbind = @$$sqlbind; # copy
 365   my $sql = shift @sqlbind;
 366   push @{$self->{from_bind}}, @sqlbind;
 367
 368   return $sql;
 369 }
 370
 371 sub _make_as {
 372   my ($self, $from) = @_;
 373   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 374                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 375                         : $self->_quote($_))
 376                        } reverse each %{$self->_skip_options($from)});
 377 }
 378
 379 sub _skip_options {
 380   my ($self, $hash) = @_;
 381   my $clean_hash = {};
 382   $clean_hash->{$_} = $hash->{$_}
 383     for grep {!/^-/} keys %$hash;
 384   return $clean_hash;
 385 }
 386
 387 sub _join_condition {
 388   my ($self, $cond) = @_;
 389   if (ref $cond eq 'HASH') {
 390     my %j;
 391     for (keys %$cond) {
 392       my $v = $cond->{$_};
 393       if (ref $v) {
 394         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 395             if ref($v) ne 'SCALAR';
 396         $j{$_} = $v;
 397       }
 398       else {
 399         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 400       }
 401     };
 402     return scalar($self->_recurse_where(\%j));
 403   } elsif (ref $cond eq 'ARRAY') {
 404     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 405   } else {
 406     die "Can't handle this yet!";
 407   }
 408 }
 409
 410 sub _quote {
 411   my ($self, $label) = @_;
 412   return '' unless defined $label;
 413   return "*" if $label eq '*';
 414   return $label unless $self->{quote_char};
 415   if(ref $self->{quote_char} eq "ARRAY"){
 416     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 417       if !defined $self->{name_sep};
 418     my $sep = $self->{name_sep};
 419     return join($self->{name_sep},
 420         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 421        split(/\Q$sep\E/,$label));
 422   }
 423   return $self->SUPER::_quote($label);
 424 }
 425
 426 sub limit_dialect {
 427     my $self = shift;
 428     $self->{limit_dialect} = shift if @_;
 429     return $self->{limit_dialect};
 430 }
 431
 432 sub quote_char {
 433     my $self = shift;
 434     $self->{quote_char} = shift if @_;
 435     return $self->{quote_char};
 436 }
 437
 438 sub name_sep {
 439     my $self = shift;
 440     $self->{name_sep} = shift if @_;
 441     return $self->{name_sep};
 442 }
 443
 444 1;
 445
 446 __END__
 447
 448 =pod
 449
 450 =head1 NAME
 451
 452 DBIx::Class::SQLAHacks - This module is a subclass of SQL::Abstract::Limit
 453 and includes a number of DBIC-specific workarounds, not yet suitable for
 454 inclusion into SQLA proper.
 455
 456 =head1 METHODS
 457
 458 =head2 new
 459
 460 Tries to determine limit dialect.
 461
 462 =head2 select
 463
 464 Quotes table names, handles "limit" dialects (e.g. where rownum between x and
 465 y), supports SELECT ... FOR UPDATE and SELECT ... FOR SHARE.
 466
 467 =head2 insert update delete
 468
 469 Just quotes table names.
 470
 471 =head2 limit_dialect
 472
 473 Specifies the dialect of used for implementing an SQL "limit" clause for
 474 restricting the number of query results returned.  Valid values are: RowNum.
 475
 476 See L<DBIx::Class::Storage::DBI/connect_info> for details.
 477
 478 =head2 name_sep
 479
 480 Character separating quoted table names.
 481
 482 See L<DBIx::Class::Storage::DBI/connect_info> for details.
 483
 484 =head2 quote_char
 485
 486 Set to an array-ref to specify separate left and right quotes for table names.
 487
 488 See L<DBIx::Class::Storage::DBI/connect_info> for details.
 489
 490 =cut
 491