lib/DBIx/Class/SQLAHacks.pm

   1 package # Hide from PAUSE
   2   DBIx::Class::SQLAHacks;
   3
   4 # This module is a subclass of SQL::Abstract::Limit and includes a number
   5 # of DBIC-specific workarounds, not yet suitable for inclusion into the
   6 # SQLA core
   7
   8 use base qw/SQL::Abstract::Limit/;
   9 use strict;
  10 use warnings;
  11 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract/;
  12 use Sub::Name();
  13
  14 BEGIN {
  15   # reinstall the carp()/croak() functions imported into SQL::Abstract
  16   # as Carp and Carp::Clan do not like each other much
  17   no warnings qw/redefine/;
  18   no strict qw/refs/;
  19   for my $f (qw/carp croak/) {
  20
  21     my $orig = \&{"SQL::Abstract::$f"};
  22     *{"SQL::Abstract::$f"} = Sub::Name::subname "SQL::Abstract::$f" =>
  23       sub {
  24         if (Carp::longmess() =~ /DBIx::Class::SQLAHacks::[\w]+ .+? called \s at/x) {
  25           __PACKAGE__->can($f)->(@_);
  26         }
  27         else {
  28           goto $orig;
  29         }
  30       };
  31   }
  32 }
  33
  34
  35 # Tries to determine limit dialect.
  36 #
  37 sub new {
  38   my $self = shift->SUPER::new(@_);
  39
  40   # This prevents the caching of $dbh in S::A::L, I believe
  41   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  42   #   it with what it resolves to:
  43   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  44     if ref $self->{limit_dialect};
  45
  46   $self;
  47 }
  48
  49 # !!! THIS IS ALSO HORRIFIC !!! /me ashamed
  50 #
  51 # generate inner/outer select lists for various limit dialects
  52 # which result in one or more subqueries (e.g. RNO, Top, RowNum)
  53 # Any non-root-table columns need to have their table qualifier
  54 # turned into a column alias (otherwise names in subqueries clash
  55 # and/or lose their source table)
  56 #
  57 # returns inner/outer strings of SQL QUOTED selectors with aliases
  58 # (to be used in whatever select statement), and an alias index hashref
  59 # of QUOTED SEL => QUOTED ALIAS pairs (to maybe be used for string-subst
  60 # higher up)
  61 #
  62 # If the $scan_order option is supplied, it signals that the limit dialect
  63 # needs to order the outer side of the query, which in turn means that the
  64 # inner select needs to bring out columns used in implicit (non-selected)
  65 # orders, and the order condition itself needs to be realiased to the proper
  66 # names in the outer query.
  67 #
  68 # In this case ($scan_order os true) we also return a hashref (order doesn't
  69 # matter) of QUOTED EXTRA-SEL => QUOTED ALIAS pairs, which is a list of extra
  70 # selectors that do *not* exist in the original select list
  71
  72 sub _subqueried_limit_attrs {
  73   my ($self, $rs_attrs, $scan_order) = @_;
  74
  75   croak 'Limit dialect implementation usable only in the context of DBIC (missing $rs_attrs)'
  76     unless ref ($rs_attrs) eq 'HASH';
  77
  78   my ($re_sep, $re_alias) = map { quotemeta $_ } (
  79     $self->name_sep || '.',
  80     $rs_attrs->{alias},
  81   );
  82
  83   # correlate select and as, build selection index
  84   my (@sel, $in_sel_index);
  85   for my $i (0 .. $#{$rs_attrs->{select}}) {
  86
  87     my $s = $rs_attrs->{select}[$i];
  88     my $sql_sel = $self->_recurse_fields ($s);
  89     my $sql_alias = (ref $s) eq 'HASH' ? $s->{-as} : undef;
  90
  91
  92     push @sel, {
  93       sql => $sql_sel,
  94       unquoted_sql => do { local $self->{quote_char}; $self->_recurse_fields ($s) },
  95       as =>
  96         $sql_alias
  97           ||
  98         $rs_attrs->{as}[$i]
  99           ||
 100         croak "Select argument $i ($s) without corresponding 'as'"
 101       ,
 102     };
 103
 104     $in_sel_index->{$sql_sel}++;
 105     $in_sel_index->{$self->_quote ($sql_alias)}++ if $sql_alias;
 106
 107 # this *may* turn out to be necessary, not sure yet
 108 #    my ($sql_unqualified_sel) = $sql_sel =~ / $re_sep (.+) $/x
 109 #      if ! ref $s;
 110 #    $in_sel_index->{$sql_unqualified_sel}++;
 111   }
 112
 113
 114   # re-alias and remove any name separators from aliases,
 115   # unless we are dealing with the current source alias
 116   # (which will transcend the subqueries as it is necessary
 117   # for possible further chaining)
 118   my (@in_sel, @out_sel, %renamed);
 119   for my $node (@sel) {
 120     if (List::Util::first { $_ =~ / (?<! $re_alias ) $re_sep /x } ($node->{as}, $node->{unquoted_sql}) )  {
 121       $node->{as} =~ s/ $re_sep /__/xg;
 122       my $quoted_as = $self->_quote($node->{as});
 123       push @in_sel, sprintf '%s AS %s', $node->{sql}, $quoted_as;
 124       push @out_sel, $quoted_as;
 125       $renamed{$node->{sql}} = $quoted_as;
 126     }
 127     else {
 128       push @in_sel, $node->{sql};
 129       push @out_sel, $self->_quote ($node->{as});
 130     }
 131   }
 132
 133   my %extra_order_sel;
 134   if ($scan_order) {
 135     for my $chunk ($self->_order_by_chunks ($rs_attrs->{order_by})) {
 136       # order with bind
 137       $chunk = $chunk->[0] if (ref $chunk) eq 'ARRAY';
 138       $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
 139
 140       next if $in_sel_index->{$chunk};
 141
 142       $extra_order_sel{$chunk} ||= $self->_quote (
 143         'ORDER__BY__' . scalar keys %extra_order_sel
 144       );
 145     }
 146   }
 147   return (
 148     (map { join (', ', @$_ ) } (
 149       \@in_sel,
 150       \@out_sel)
 151     ),
 152     \%renamed,
 153     keys %extra_order_sel ? \%extra_order_sel : (),
 154   );
 155 }
 156
 157 # ANSI standard Limit/Offset implementation. DB2 and MSSQL >= 2005 use this
 158 sub _RowNumberOver {
 159   my ($self, $sql, $rs_attrs, $rows, $offset ) = @_;
 160
 161   # mangle the input sql as we will be replacing the selector
 162   $sql =~ s/^ \s* SELECT \s+ .+? \s+ (?= \b FROM \b )//ix
 163     or croak "Unrecognizable SELECT: $sql";
 164
 165   # get selectors, and scan the order_by (if any)
 166   my ($in_sel, $out_sel, $alias_map, $extra_order_sel) = $self->_subqueried_limit_attrs (
 167     $rs_attrs, 'scan_order_by',
 168   );
 169
 170   # make up an order if none exists
 171   my $requested_order = (delete $rs_attrs->{order_by}) || $self->_rno_default_order;
 172   my $rno_ord = $self->_order_by ($requested_order);
 173
 174   # this is the order supplement magic
 175   my $mid_sel = $out_sel;
 176   if ($extra_order_sel) {
 177     for my $extra_col (sort
 178       { $extra_order_sel->{$a} cmp $extra_order_sel->{$b} }
 179       keys %$extra_order_sel
 180     ) {
 181       $in_sel .= sprintf (', %s AS %s',
 182         $extra_col,
 183         $extra_order_sel->{$extra_col},
 184       );
 185
 186       $mid_sel .= ', ' . $extra_order_sel->{$extra_col};
 187     }
 188   }
 189
 190   # and this is order re-alias magic
 191   for ($extra_order_sel, $alias_map) {
 192     for my $col (keys %$_) {
 193       my $re_col = quotemeta ($col);
 194       $rno_ord =~ s/$re_col/$_->{$col}/;
 195     }
 196   }
 197
 198   # whatever is left of the order_by (only where is processed at this point)
 199   my $group_having = $self->_parse_rs_attrs($rs_attrs);
 200
 201   my $qalias = $self->_quote ($rs_attrs->{alias});
 202   my $idx_name = $self->_quote ('rno__row__index');
 203
 204   $sql = sprintf (<<EOS, $offset + 1, $offset + $rows, );
 205
 206 SELECT $out_sel FROM (
 207   SELECT $mid_sel, ROW_NUMBER() OVER( $rno_ord ) AS $idx_name FROM (
 208     SELECT $in_sel ${sql}${group_having}
 209   ) $qalias
 210 ) $qalias WHERE $idx_name BETWEEN %d AND %d
 211
 212 EOS
 213
 214   $sql =~ s/\s*\n\s*/ /g;   # easier to read in the debugger
 215   return $sql;
 216 }
 217
 218 # some databases are happy with OVER (), some need OVER (ORDER BY (SELECT (1)) )
 219 sub _rno_default_order {
 220   return undef;
 221 }
 222
 223 # Informix specific limit, almost like LIMIT/OFFSET
 224 sub _SkipFirst {
 225   my ($self, $sql, $rs_attrs, $rows, $offset) = @_;
 226
 227   $sql =~ s/^ \s* SELECT \s+ //ix
 228     or croak "Unrecognizable SELECT: $sql";
 229
 230   return sprintf ('SELECT %s%s%s%s',
 231     $offset
 232       ? sprintf ('SKIP %d ', $offset)
 233       : ''
 234     ,
 235     sprintf ('FIRST %d ', $rows),
 236     $sql,
 237     $self->_parse_rs_attrs ($rs_attrs),
 238   );
 239 }
 240
 241 # Firebird specific limit, reverse of _SkipFirst for Informix
 242 sub _FirstSkip {
 243   my ($self, $sql, $rs_attrs, $rows, $offset) = @_;
 244
 245   $sql =~ s/^ \s* SELECT \s+ //ix
 246     or croak "Unrecognizable SELECT: $sql";
 247
 248   return sprintf ('SELECT %s%s%s%s',
 249     sprintf ('FIRST %d ', $rows),
 250     $offset
 251       ? sprintf ('SKIP %d ', $offset)
 252       : ''
 253     ,
 254     $sql,
 255     $self->_parse_rs_attrs ($rs_attrs),
 256   );
 257 }
 258
 259 # WhOracle limits
 260 sub _RowNum {
 261   my ( $self, $sql, $rs_attrs, $rows, $offset ) = @_;
 262
 263   # mangle the input sql as we will be replacing the selector
 264   $sql =~ s/^ \s* SELECT \s+ .+? \s+ (?= \b FROM \b )//ix
 265     or croak "Unrecognizable SELECT: $sql";
 266
 267   my ($insel, $outsel) = $self->_subqueried_limit_attrs ($rs_attrs);
 268
 269   my $qalias = $self->_quote ($rs_attrs->{alias});
 270   my $idx_name = $self->_quote ('rownum__index');
 271   my $order_group_having = $self->_parse_rs_attrs($rs_attrs);
 272
 273   $sql = sprintf (<<EOS, $offset + 1, $offset + $rows, );
 274
 275 SELECT $outsel FROM (
 276   SELECT $outsel, ROWNUM $idx_name FROM (
 277     SELECT $insel ${sql}${order_group_having}
 278   ) $qalias
 279 ) $qalias WHERE $idx_name BETWEEN %d AND %d
 280
 281 EOS
 282
 283   $sql =~ s/\s*\n\s*/ /g;   # easier to read in the debugger
 284   return $sql;
 285 }
 286
 287 # Crappy Top based Limit/Offset support. Legacy for MSSQL < 2005
 288 sub _Top {
 289   my ( $self, $sql, $rs_attrs, $rows, $offset ) = @_;
 290
 291   # mangle the input sql as we will be replacing the selector
 292   $sql =~ s/^ \s* SELECT \s+ .+? \s+ (?= \b FROM \b )//ix
 293     or croak "Unrecognizable SELECT: $sql";
 294
 295   # get selectors
 296   my ($in_sel, $out_sel, $alias_map, $extra_order_sel)
 297     = $self->_subqueried_limit_attrs ($rs_attrs, 'outer_order_by');
 298
 299   my $requested_order = delete $rs_attrs->{order_by};
 300
 301   my $order_by_requested = $self->_order_by ($requested_order);
 302
 303   # make up an order unless supplied
 304   my $inner_order = ($order_by_requested
 305     ? $requested_order
 306     : [ map
 307       { join ('', $rs_attrs->{alias}, $self->{name_sep}||'.', $_ ) }
 308       ( $rs_attrs->{_rsroot_source_handle}->resolve->_pri_cols )
 309     ]
 310   );
 311
 312   my ($order_by_inner, $order_by_reversed);
 313
 314   # localise as we already have all the bind values we need
 315   {
 316     local $self->{order_bind};
 317     $order_by_inner = $self->_order_by ($inner_order);
 318
 319     my @out_chunks;
 320     for my $ch ($self->_order_by_chunks ($inner_order)) {
 321       $ch = $ch->[0] if ref $ch eq 'ARRAY';
 322
 323       $ch =~ s/\s+ ( ASC|DESC ) \s* $//ix;
 324       my $dir = uc ($1||'ASC');
 325
 326       push @out_chunks, \join (' ', $ch, $dir eq 'ASC' ? 'DESC' : 'ASC' );
 327     }
 328
 329     $order_by_reversed = $self->_order_by (\@out_chunks);
 330   }
 331
 332   # this is the order supplement magic
 333   my $mid_sel = $out_sel;
 334   if ($extra_order_sel) {
 335     for my $extra_col (sort
 336       { $extra_order_sel->{$a} cmp $extra_order_sel->{$b} }
 337       keys %$extra_order_sel
 338     ) {
 339       $in_sel .= sprintf (', %s AS %s',
 340         $extra_col,
 341         $extra_order_sel->{$extra_col},
 342       );
 343
 344       $mid_sel .= ', ' . $extra_order_sel->{$extra_col};
 345     }
 346   }
 347
 348   # and this is order re-alias magic
 349   for my $map ($extra_order_sel, $alias_map) {
 350     for my $col (keys %$map) {
 351       my $re_col = quotemeta ($col);
 352       $_ =~ s/$re_col/$map->{$col}/
 353         for ($order_by_reversed, $order_by_requested);
 354     }
 355   }
 356
 357   # generate the rest of the sql
 358   my $grpby_having = $self->_parse_rs_attrs ($rs_attrs);
 359
 360   my $quoted_rs_alias = $self->_quote ($rs_attrs->{alias});
 361
 362   $sql = sprintf ('SELECT TOP %d %s %s %s %s',
 363     $rows + ($offset||0),
 364     $in_sel,
 365     $sql,
 366     $grpby_having,
 367     $order_by_inner,
 368   );
 369
 370   $sql = sprintf ('SELECT TOP %d %s FROM ( %s ) %s %s',
 371     $rows,
 372     $mid_sel,
 373     $sql,
 374     $quoted_rs_alias,
 375     $order_by_reversed,
 376   ) if $offset;
 377
 378   $sql = sprintf ('SELECT TOP %d %s FROM ( %s ) %s %s',
 379     $rows,
 380     $out_sel,
 381     $sql,
 382     $quoted_rs_alias,
 383     $order_by_requested,
 384   ) if ( ($offset && $order_by_requested) || ($mid_sel ne $out_sel) );
 385
 386   return $sql;
 387 }
 388
 389
 390 # While we're at it, this should make LIMIT queries more efficient,
 391 #  without digging into things too deeply
 392 sub _find_syntax {
 393   my ($self, $syntax) = @_;
 394   return $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
 395 }
 396
 397 # Quotes table names, handles "limit" dialects (e.g. where rownum between x and
 398 # y)
 399 sub select {
 400   my ($self, $table, $fields, $where, $rs_attrs, @rest) = @_;
 401
 402   $self->{"${_}_bind"} = [] for (qw/having from order/);
 403
 404   if (not ref($table) or ref($table) eq 'SCALAR') {
 405     $table = $self->_quote($table);
 406   }
 407
 408   @rest = (-1) unless defined $rest[0];
 409   croak "LIMIT 0 Does Not Compute" if $rest[0] == 0;
 410     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 411
 412   my ($sql, @where_bind) = $self->SUPER::select(
 413     $table, $self->_recurse_fields($fields), $where, $rs_attrs, @rest
 414   );
 415   return wantarray ? ($sql, @{$self->{from_bind}}, @where_bind, @{$self->{having_bind}}, @{$self->{order_bind}} ) : $sql;
 416 }
 417
 418 # Quotes table names, and handles default inserts
 419 sub insert {
 420   my $self = shift;
 421   my $table = shift;
 422   $table = $self->_quote($table);
 423
 424   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 425   # which is sadly understood only by MySQL. Change default behavior here,
 426   # until SQLA2 comes with proper dialect support
 427   if (! $_[0] or (ref $_[0] eq 'HASH' and !keys %{$_[0]} ) ) {
 428     my $sql = "INSERT INTO ${table} DEFAULT VALUES";
 429
 430     if (my $ret = ($_[1]||{})->{returning} ) {
 431       $sql .= $self->_insert_returning ($ret);
 432     }
 433
 434     return $sql;
 435   }
 436
 437   $self->SUPER::insert($table, @_);
 438 }
 439
 440 # Just quotes table names.
 441 sub update {
 442   my $self = shift;
 443   my $table = shift;
 444   $table = $self->_quote($table);
 445   $self->SUPER::update($table, @_);
 446 }
 447
 448 # Just quotes table names.
 449 sub delete {
 450   my $self = shift;
 451   my $table = shift;
 452   $table = $self->_quote($table);
 453   $self->SUPER::delete($table, @_);
 454 }
 455
 456 sub _emulate_limit {
 457   my $self = shift;
 458   # my ( $syntax, $sql, $order, $rows, $offset ) = @_;
 459
 460   if ($_[3] == -1) {
 461     return $_[1] . $self->_parse_rs_attrs($_[2]);
 462   } else {
 463     return $self->SUPER::_emulate_limit(@_);
 464   }
 465 }
 466
 467 sub _recurse_fields {
 468   my ($self, $fields) = @_;
 469   my $ref = ref $fields;
 470   return $self->_quote($fields) unless $ref;
 471   return $$fields if $ref eq 'SCALAR';
 472
 473   if ($ref eq 'ARRAY') {
 474     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 475   }
 476   elsif ($ref eq 'HASH') {
 477     my %hash = %$fields;  # shallow copy
 478
 479     my $as = delete $hash{-as};   # if supplied
 480
 481     my ($func, $args, @toomany) = %hash;
 482
 483     # there should be only one pair
 484     if (@toomany) {
 485       croak "Malformed select argument - too many keys in hash: " . join (',', keys %$fields );
 486     }
 487
 488     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 489       croak (
 490         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 491        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 492        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 493       );
 494     }
 495
 496     my $select = sprintf ('%s( %s )%s',
 497       $self->_sqlcase($func),
 498       $self->_recurse_fields($args),
 499       $as
 500         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 501         : ''
 502     );
 503
 504     return $select;
 505   }
 506   # Is the second check absolutely necessary?
 507   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 508     return $self->_fold_sqlbind( $fields );
 509   }
 510   else {
 511     croak($ref . qq{ unexpected in _recurse_fields()})
 512   }
 513 }
 514
 515 my $for_syntax = {
 516   update => 'FOR UPDATE',
 517   shared => 'FOR SHARE',
 518 };
 519
 520 # this used to be a part of _order_by but is broken out for clarity.
 521 # What we have been doing forever is hijacking the $order arg of
 522 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 523 # then pretty much the entire resultset attr-hash, as more and more
 524 # things in the SQLA space need to have mopre info about the $rs they
 525 # create SQL for. The alternative would be to keep expanding the
 526 # signature of _select with more and more positional parameters, which
 527 # is just gross. All hail SQLA2!
 528 sub _parse_rs_attrs {
 529   my ($self, $arg) = @_;
 530
 531   my $sql = '';
 532
 533   if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 534     $sql .= $self->_sqlcase(' group by ') . $g;
 535   }
 536
 537   if (defined $arg->{having}) {
 538     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 539     push(@{$self->{having_bind}}, @bind);
 540     $sql .= $self->_sqlcase(' having ') . $frag;
 541   }
 542
 543   if (defined $arg->{order_by}) {
 544     $sql .= $self->_order_by ($arg->{order_by});
 545   }
 546
 547   if (my $for = $arg->{for}) {
 548     $sql .= " $for_syntax->{$for}" if $for_syntax->{$for};
 549   }
 550
 551   return $sql;
 552 }
 553
 554 sub _order_by {
 555   my ($self, $arg) = @_;
 556
 557   # check that we are not called in legacy mode (order_by as 4th argument)
 558   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 559     return $self->_parse_rs_attrs ($arg);
 560   }
 561   else {
 562     my ($sql, @bind) = $self->SUPER::_order_by ($arg);
 563     push @{$self->{order_bind}}, @bind;
 564     return $sql;
 565   }
 566 }
 567
 568 sub _order_directions {
 569   my ($self, $order) = @_;
 570
 571   # strip bind values - none of the current _order_directions users support them
 572   return $self->SUPER::_order_directions( [ map
 573     { ref $_ ? $_->[0] : $_ }
 574     $self->_order_by_chunks ($order)
 575   ]);
 576 }
 577
 578 sub _table {
 579   my ($self, $from) = @_;
 580   if (ref $from eq 'ARRAY') {
 581     return $self->_recurse_from(@$from);
 582   } elsif (ref $from eq 'HASH') {
 583     return $self->_make_as($from);
 584   } else {
 585     return $from; # would love to quote here but _table ends up getting called
 586                   # twice during an ->select without a limit clause due to
 587                   # the way S::A::Limit->select works. should maybe consider
 588                   # bypassing this and doing S::A::select($self, ...) in
 589                   # our select method above. meantime, quoting shims have
 590                   # been added to select/insert/update/delete here
 591   }
 592 }
 593
 594 sub _generate_join_clause {
 595     my ($self, $join_type) = @_;
 596
 597     return sprintf ('%s JOIN ',
 598       $join_type ?  ' ' . uc($join_type) : ''
 599     );
 600 }
 601
 602 sub _recurse_from {
 603   my ($self, $from, @join) = @_;
 604   my @sqlf;
 605   push(@sqlf, $self->_make_as($from));
 606   foreach my $j (@join) {
 607     my ($to, $on) = @$j;
 608
 609
 610     # check whether a join type exists
 611     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 612     my $join_type;
 613     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 614       $join_type = $to_jt->{-join_type};
 615       $join_type =~ s/^\s+ | \s+$//xg;
 616     }
 617
 618     $join_type = $self->{_default_jointype} if not defined $join_type;
 619
 620     push @sqlf, $self->_generate_join_clause( $join_type );
 621
 622     if (ref $to eq 'ARRAY') {
 623       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 624     } else {
 625       push(@sqlf, $self->_make_as($to));
 626     }
 627     push(@sqlf, ' ON ', $self->_join_condition($on));
 628   }
 629   return join('', @sqlf);
 630 }
 631
 632 sub _fold_sqlbind {
 633   my ($self, $sqlbind) = @_;
 634
 635   my @sqlbind = @$$sqlbind; # copy
 636   my $sql = shift @sqlbind;
 637   push @{$self->{from_bind}}, @sqlbind;
 638
 639   return $sql;
 640 }
 641
 642 sub _make_as {
 643   my ($self, $from) = @_;
 644   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 645                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 646                         : $self->_quote($_))
 647                        } reverse each %{$self->_skip_options($from)});
 648 }
 649
 650 sub _skip_options {
 651   my ($self, $hash) = @_;
 652   my $clean_hash = {};
 653   $clean_hash->{$_} = $hash->{$_}
 654     for grep {!/^-/} keys %$hash;
 655   return $clean_hash;
 656 }
 657
 658 sub _join_condition {
 659   my ($self, $cond) = @_;
 660   if (ref $cond eq 'HASH') {
 661     my %j;
 662     for (keys %$cond) {
 663       my $v = $cond->{$_};
 664       if (ref $v) {
 665         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 666             if ref($v) ne 'SCALAR';
 667         $j{$_} = $v;
 668       }
 669       else {
 670         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 671       }
 672     };
 673     return scalar($self->_recurse_where(\%j));
 674   } elsif (ref $cond eq 'ARRAY') {
 675     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 676   } else {
 677     die "Can't handle this yet!";
 678   }
 679 }
 680
 681 sub limit_dialect {
 682     my $self = shift;
 683     if (@_) {
 684       $self->{limit_dialect} = shift;
 685       undef $self->{_cached_syntax};
 686     }
 687     return $self->{limit_dialect};
 688 }
 689
 690 # Set to an array-ref to specify separate left and right quotes for table names.
 691 # A single scalar is equivalen to [ $char, $char ]
 692 sub quote_char {
 693     my $self = shift;
 694     $self->{quote_char} = shift if @_;
 695     return $self->{quote_char};
 696 }
 697
 698 # Character separating quoted table names.
 699 sub name_sep {
 700     my $self = shift;
 701     $self->{name_sep} = shift if @_;
 702     return $self->{name_sep};
 703 }
 704
 705 1;