lib/DBIx/Class/SQLAHacks.pm

   1 package # Hide from PAUSE
   2   DBIx::Class::SQLAHacks;
   3
   4 # This module is a subclass of SQL::Abstract::Limit and includes a number
   5 # of DBIC-specific workarounds, not yet suitable for inclusion into the
   6 # SQLA core
   7
   8 use base qw/SQL::Abstract::Limit/;
   9 use strict;
  10 use warnings;
  11 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract/;
  12 use Sub::Name();
  13
  14 BEGIN {
  15   # reinstall the carp()/croak() functions imported into SQL::Abstract
  16   # as Carp and Carp::Clan do not like each other much
  17   no warnings qw/redefine/;
  18   no strict qw/refs/;
  19   for my $f (qw/carp croak/) {
  20
  21     my $orig = \&{"SQL::Abstract::$f"};
  22     *{"SQL::Abstract::$f"} = Sub::Name::subname "SQL::Abstract::$f" =>
  23       sub {
  24         if (Carp::longmess() =~ /DBIx::Class::SQLAHacks::[\w]+ .+? called \s at/x) {
  25           __PACKAGE__->can($f)->(@_);
  26         }
  27         else {
  28           goto $orig;
  29         }
  30       };
  31   }
  32 }
  33
  34
  35 # Tries to determine limit dialect.
  36 #
  37 sub new {
  38   my $self = shift->SUPER::new(@_);
  39
  40   # This prevents the caching of $dbh in S::A::L, I believe
  41   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  42   #   it with what it resolves to:
  43   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  44     if ref $self->{limit_dialect};
  45
  46   $self;
  47 }
  48
  49
  50 # ANSI standard Limit/Offset implementation. DB2 and MSSQL use this
  51 sub _RowNumberOver {
  52   my ($self, $sql, $order, $rows, $offset ) = @_;
  53
  54   # get the order_by only (or make up an order if none exists)
  55   my $order_by = $self->_order_by(
  56     (delete $order->{order_by}) || $self->_rno_default_order
  57   );
  58
  59   # whatever is left
  60   my $group_having = $self->_order_by($order);
  61
  62   $sql = sprintf (<<'EOS', $order_by, $sql, $group_having, $offset + 1, $offset + $rows, );
  63
  64 SELECT * FROM (
  65   SELECT orig_query.*, ROW_NUMBER() OVER(%s ) AS rno__row__index FROM (%s%s) orig_query
  66 ) rno_subq WHERE rno__row__index BETWEEN %d AND %d
  67
  68 EOS
  69
  70   $sql =~ s/\s*\n\s*/ /g;   # easier to read in the debugger
  71   return $sql;
  72 }
  73
  74 # some databases are happy with OVER (), some need OVER (ORDER BY (SELECT (1)) )
  75 sub _rno_default_order {
  76   return undef;
  77 }
  78
  79 # Crappy Top based Limit/Offset support. Legacy from MSSQL.
  80 sub _Top {
  81   my ( $self, $sql, $order, $rows, $offset ) = @_;
  82
  83   # mangle the input sql so it can be properly aliased in the outer queries
  84   $sql =~ s/^ \s* SELECT \s+ (.+?) \s+ (?=FROM)//ix
  85     or croak "Unrecognizable SELECT: $sql";
  86   my $sql_select = $1;
  87   my @sql_select = split (/\s*,\s*/, $sql_select);
  88
  89   # we can't support subqueries (in fact MSSQL can't) - croak
  90   if (@sql_select != @{$self->{_dbic_rs_attrs}{select}}) {
  91     croak (sprintf (
  92       'SQL SELECT did not parse cleanly - retrieved %d comma separated elements, while '
  93     . 'the resultset select attribure contains %d elements: %s',
  94       scalar @sql_select,
  95       scalar @{$self->{_dbic_rs_attrs}{select}},
  96       $sql_select,
  97     ));
  98   }
  99
 100   my $name_sep = $self->name_sep || '.';
 101   my $esc_name_sep = "\Q$name_sep\E";
 102   my $col_re = qr/ ^ (?: (.+) $esc_name_sep )? ([^$esc_name_sep]+) $ /x;
 103
 104   my $rs_alias = $self->{_dbic_rs_attrs}{alias};
 105   my $quoted_rs_alias = $self->_quote ($rs_alias);
 106
 107   # construct the new select lists, rename(alias) some columns if necessary
 108   my (@outer_select, @inner_select, %seen_names, %col_aliases, %outer_col_aliases);
 109
 110   for (@{$self->{_dbic_rs_attrs}{select}}) {
 111     next if ref $_;
 112     my ($table, $orig_colname) = ( $_ =~ $col_re );
 113     next unless $table;
 114     $seen_names{$orig_colname}++;
 115   }
 116
 117   for my $i (0 .. $#sql_select) {
 118
 119     my $colsel_arg = $self->{_dbic_rs_attrs}{select}[$i];
 120     my $colsel_sql = $sql_select[$i];
 121
 122     # this may or may not work (in case of a scalarref or something)
 123     my ($table, $orig_colname) = ( $colsel_arg =~ $col_re );
 124
 125     my $quoted_alias;
 126     # do not attempt to understand non-scalar selects - alias numerically
 127     if (ref $colsel_arg) {
 128       $quoted_alias = $self->_quote ('column_' . (@inner_select + 1) );
 129     }
 130     # column name seen more than once - alias it
 131     elsif ($orig_colname &&
 132           ($seen_names{$orig_colname} && $seen_names{$orig_colname} > 1) ) {
 133       $quoted_alias = $self->_quote ("${table}__${orig_colname}");
 134     }
 135
 136     # we did rename - make a record and adjust
 137     if ($quoted_alias) {
 138       # alias inner
 139       push @inner_select, "$colsel_sql AS $quoted_alias";
 140
 141       # push alias to outer
 142       push @outer_select, $quoted_alias;
 143
 144       # Any aliasing accumulated here will be considered
 145       # both for inner and outer adjustments of ORDER BY
 146       $self->__record_alias (
 147         \%col_aliases,
 148         $quoted_alias,
 149         $colsel_arg,
 150         $table ? $orig_colname : undef,
 151       );
 152     }
 153
 154     # otherwise just leave things intact inside, and use the abbreviated one outside
 155     # (as we do not have table names anymore)
 156     else {
 157       push @inner_select, $colsel_sql;
 158
 159       my $outer_quoted = $self->_quote ($orig_colname);  # it was not a duplicate so should just work
 160       push @outer_select, $outer_quoted;
 161       $self->__record_alias (
 162         \%outer_col_aliases,
 163         $outer_quoted,
 164         $colsel_arg,
 165         $table ? $orig_colname : undef,
 166       );
 167     }
 168   }
 169
 170   my $outer_select = join (', ', @outer_select );
 171   my $inner_select = join (', ', @inner_select );
 172
 173   %outer_col_aliases = (%outer_col_aliases, %col_aliases);
 174
 175   # deal with order
 176   croak '$order supplied to SQLAHacks limit emulators must be a hash'
 177     if (ref $order ne 'HASH');
 178
 179   $order = { %$order }; #copy
 180
 181   my $req_order = $order->{order_by};
 182
 183   # examine normalized version, collapses nesting
 184   my $limit_order;
 185   if (scalar $self->_order_by_chunks ($req_order)) {
 186     $limit_order = $req_order;
 187   }
 188   else {
 189     $limit_order = [ map
 190       { join ('', $rs_alias, $name_sep, $_ ) }
 191       ( $self->{_dbic_rs_attrs}{_source_handle}->resolve->primary_columns )
 192     ];
 193   }
 194
 195   my ( $order_by_inner, $order_by_outer ) = $self->_order_directions($limit_order);
 196   my $order_by_requested = $self->_order_by ($req_order);
 197
 198   # generate the rest
 199   delete $order->{order_by};
 200   my $grpby_having = $self->_order_by ($order);
 201
 202   # short circuit for counts - the ordering complexity is needless
 203   if ($self->{_dbic_rs_attrs}{-for_count_only}) {
 204     return "SELECT TOP $rows $inner_select $sql $grpby_having $order_by_outer";
 205   }
 206
 207   # we can't really adjust the order_by columns, as introspection is lacking
 208   # resort to simple substitution
 209   for my $col (keys %outer_col_aliases) {
 210     for ($order_by_requested, $order_by_outer) {
 211       $_ =~ s/\s+$col\s+/ $outer_col_aliases{$col} /g;
 212     }
 213   }
 214   for my $col (keys %col_aliases) {
 215     $order_by_inner =~ s/\s+$col\s+/ $col_aliases{$col} /g;
 216   }
 217
 218
 219   my $inner_lim = $rows + $offset;
 220
 221   $sql = "SELECT TOP $inner_lim $inner_select $sql $grpby_having $order_by_inner";
 222
 223   if ($offset) {
 224     $sql = <<"SQL";
 225
 226     SELECT TOP $rows $outer_select FROM
 227     (
 228       $sql
 229     ) $quoted_rs_alias
 230     $order_by_outer
 231 SQL
 232
 233   }
 234
 235   if ($order_by_requested) {
 236     $sql = <<"SQL";
 237
 238     SELECT $outer_select FROM
 239       ( $sql ) $quoted_rs_alias
 240     $order_by_requested
 241 SQL
 242
 243   }
 244
 245   $sql =~ s/\s*\n\s*/ /g; # parsing out multiline statements is harder than a single line
 246   return $sql;
 247 }
 248
 249 # action at a distance to shorten Top code above
 250 sub __record_alias {
 251   my ($self, $register, $alias, $fqcol, $col) = @_;
 252
 253   # record qualified name
 254   $register->{$fqcol} = $alias;
 255   $register->{$self->_quote($fqcol)} = $alias;
 256
 257   return unless $col;
 258
 259   # record unqualified name, undef (no adjustment) if a duplicate is found
 260   if (exists $register->{$col}) {
 261     $register->{$col} = undef;
 262   }
 263   else {
 264     $register->{$col} = $alias;
 265   }
 266
 267   $register->{$self->_quote($col)} = $register->{$col};
 268 }
 269
 270
 271
 272 # While we're at it, this should make LIMIT queries more efficient,
 273 #  without digging into things too deeply
 274 sub _find_syntax {
 275   my ($self, $syntax) = @_;
 276   return $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
 277 }
 278
 279 my $for_syntax = {
 280   update => 'FOR UPDATE',
 281   shared => 'FOR SHARE',
 282 };
 283 # Quotes table names, handles "limit" dialects (e.g. where rownum between x and
 284 # y), supports SELECT ... FOR UPDATE and SELECT ... FOR SHARE.
 285 sub select {
 286   my ($self, $table, $fields, $where, $order, @rest) = @_;
 287
 288   $self->{"${_}_bind"} = [] for (qw/having from order/);
 289
 290   if (not ref($table) or ref($table) eq 'SCALAR') {
 291     $table = $self->_quote($table);
 292   }
 293
 294   local $self->{rownum_hack_count} = 1
 295     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
 296   @rest = (-1) unless defined $rest[0];
 297   croak "LIMIT 0 Does Not Compute" if $rest[0] == 0;
 298     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 299   my ($sql, @where_bind) = $self->SUPER::select(
 300     $table, $self->_recurse_fields($fields), $where, $order, @rest
 301   );
 302   if (my $for = delete $self->{_dbic_rs_attrs}{for}) {
 303     $sql .= " $for_syntax->{$for}" if $for_syntax->{$for};
 304   }
 305
 306   return wantarray ? ($sql, @{$self->{from_bind}}, @where_bind, @{$self->{having_bind}}, @{$self->{order_bind}} ) : $sql;
 307 }
 308
 309 # Quotes table names, and handles default inserts
 310 sub insert {
 311   my $self = shift;
 312   my $table = shift;
 313   $table = $self->_quote($table);
 314
 315   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 316   # which is sadly understood only by MySQL. Change default behavior here,
 317   # until SQLA2 comes with proper dialect support
 318   if (! $_[0] or (ref $_[0] eq 'HASH' and !keys %{$_[0]} ) ) {
 319     return "INSERT INTO ${table} DEFAULT VALUES"
 320   }
 321
 322   $self->SUPER::insert($table, @_);
 323 }
 324
 325 # Just quotes table names.
 326 sub update {
 327   my $self = shift;
 328   my $table = shift;
 329   $table = $self->_quote($table);
 330   $self->SUPER::update($table, @_);
 331 }
 332
 333 # Just quotes table names.
 334 sub delete {
 335   my $self = shift;
 336   my $table = shift;
 337   $table = $self->_quote($table);
 338   $self->SUPER::delete($table, @_);
 339 }
 340
 341 sub _emulate_limit {
 342   my $self = shift;
 343   if ($_[3] == -1) {
 344     return $_[1].$self->_order_by($_[2]);
 345   } else {
 346     return $self->SUPER::_emulate_limit(@_);
 347   }
 348 }
 349
 350 sub _recurse_fields {
 351   my ($self, $fields, $params) = @_;
 352   my $ref = ref $fields;
 353   return $self->_quote($fields) unless $ref;
 354   return $$fields if $ref eq 'SCALAR';
 355
 356   if ($ref eq 'ARRAY') {
 357     return join(', ', map {
 358       $self->_recurse_fields($_)
 359         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 360           ? ' AS col'.$self->{rownum_hack_count}++
 361           : '')
 362       } @$fields);
 363   }
 364   elsif ($ref eq 'HASH') {
 365     my %hash = %$fields;
 366
 367     my $as = delete $hash{-as};   # if supplied
 368
 369     my ($func, $args) = each %hash;
 370     delete $hash{$func};
 371
 372     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 373       croak (
 374         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 375        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 376        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 377       );
 378     }
 379
 380     my $select = sprintf ('%s( %s )%s',
 381       $self->_sqlcase($func),
 382       $self->_recurse_fields($args),
 383       $as
 384         ? sprintf (' %s %s', $self->_sqlcase('as'), $as)
 385         : ''
 386     );
 387
 388     # there should be nothing left
 389     if (keys %hash) {
 390       croak "Malformed select argument - too many keys in hash: " . join (',', keys %$fields );
 391     }
 392
 393     return $select;
 394   }
 395   # Is the second check absolutely necessary?
 396   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 397     return $self->_fold_sqlbind( $fields );
 398   }
 399   else {
 400     croak($ref . qq{ unexpected in _recurse_fields()})
 401   }
 402 }
 403
 404 sub _order_by {
 405   my ($self, $arg) = @_;
 406
 407   if (ref $arg eq 'HASH' and keys %$arg and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 408
 409     my $ret = '';
 410
 411     if (my $g = $self->_recurse_fields($arg->{group_by}, { no_rownum_hack => 1 }) ) {
 412       $ret = $self->_sqlcase(' group by ') . $g;
 413     }
 414
 415     if (defined $arg->{having}) {
 416       my ($frag, @bind) = $self->_recurse_where($arg->{having});
 417       push(@{$self->{having_bind}}, @bind);
 418       $ret .= $self->_sqlcase(' having ').$frag;
 419     }
 420
 421     if (defined $arg->{order_by}) {
 422       my ($frag, @bind) = $self->SUPER::_order_by($arg->{order_by});
 423       push(@{$self->{order_bind}}, @bind);
 424       $ret .= $frag;
 425     }
 426
 427     return $ret;
 428   }
 429   else {
 430     my ($sql, @bind) = $self->SUPER::_order_by ($arg);
 431     push(@{$self->{order_bind}}, @bind);
 432     return $sql;
 433   }
 434 }
 435
 436 sub _order_directions {
 437   my ($self, $order) = @_;
 438
 439   # strip bind values - none of the current _order_directions users support them
 440   return $self->SUPER::_order_directions( [ map
 441     { ref $_ ? $_->[0] : $_ }
 442     $self->_order_by_chunks ($order)
 443   ]);
 444 }
 445
 446 sub _table {
 447   my ($self, $from) = @_;
 448   if (ref $from eq 'ARRAY') {
 449     return $self->_recurse_from(@$from);
 450   } elsif (ref $from eq 'HASH') {
 451     return $self->_make_as($from);
 452   } else {
 453     return $from; # would love to quote here but _table ends up getting called
 454                   # twice during an ->select without a limit clause due to
 455                   # the way S::A::Limit->select works. should maybe consider
 456                   # bypassing this and doing S::A::select($self, ...) in
 457                   # our select method above. meantime, quoting shims have
 458                   # been added to select/insert/update/delete here
 459   }
 460 }
 461
 462 sub _recurse_from {
 463   my ($self, $from, @join) = @_;
 464   my @sqlf;
 465   push(@sqlf, $self->_make_as($from));
 466   foreach my $j (@join) {
 467     my ($to, $on) = @$j;
 468
 469
 470     # check whether a join type exists
 471     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 472     my $join_type;
 473     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 474       $join_type = $to_jt->{-join_type};
 475       $join_type =~ s/^\s+ | \s+$//xg;
 476     }
 477
 478     $join_type = $self->{_default_jointype} if not defined $join_type;
 479
 480     my $join_clause = sprintf ('%s JOIN ',
 481       $join_type ?  ' ' . uc($join_type) : ''
 482     );
 483     push @sqlf, $join_clause;
 484
 485     if (ref $to eq 'ARRAY') {
 486       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 487     } else {
 488       push(@sqlf, $self->_make_as($to));
 489     }
 490     push(@sqlf, ' ON ', $self->_join_condition($on));
 491   }
 492   return join('', @sqlf);
 493 }
 494
 495 sub _fold_sqlbind {
 496   my ($self, $sqlbind) = @_;
 497
 498   my @sqlbind = @$$sqlbind; # copy
 499   my $sql = shift @sqlbind;
 500   push @{$self->{from_bind}}, @sqlbind;
 501
 502   return $sql;
 503 }
 504
 505 sub _make_as {
 506   my ($self, $from) = @_;
 507   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 508                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 509                         : $self->_quote($_))
 510                        } reverse each %{$self->_skip_options($from)});
 511 }
 512
 513 sub _skip_options {
 514   my ($self, $hash) = @_;
 515   my $clean_hash = {};
 516   $clean_hash->{$_} = $hash->{$_}
 517     for grep {!/^-/} keys %$hash;
 518   return $clean_hash;
 519 }
 520
 521 sub _join_condition {
 522   my ($self, $cond) = @_;
 523   if (ref $cond eq 'HASH') {
 524     my %j;
 525     for (keys %$cond) {
 526       my $v = $cond->{$_};
 527       if (ref $v) {
 528         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 529             if ref($v) ne 'SCALAR';
 530         $j{$_} = $v;
 531       }
 532       else {
 533         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 534       }
 535     };
 536     return scalar($self->_recurse_where(\%j));
 537   } elsif (ref $cond eq 'ARRAY') {
 538     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 539   } else {
 540     die "Can't handle this yet!";
 541   }
 542 }
 543
 544 sub _quote {
 545   my ($self, $label) = @_;
 546   return '' unless defined $label;
 547   return $$label if ref($label) eq 'SCALAR';
 548   return "*" if $label eq '*';
 549   return $label unless $self->{quote_char};
 550   if(ref $self->{quote_char} eq "ARRAY"){
 551     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 552       if !defined $self->{name_sep};
 553     my $sep = $self->{name_sep};
 554     return join($self->{name_sep},
 555         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 556        split(/\Q$sep\E/,$label));
 557   }
 558   return $self->SUPER::_quote($label);
 559 }
 560
 561 sub limit_dialect {
 562     my $self = shift;
 563     $self->{limit_dialect} = shift if @_;
 564     return $self->{limit_dialect};
 565 }
 566
 567 # Set to an array-ref to specify separate left and right quotes for table names.
 568 # A single scalar is equivalen to [ $char, $char ]
 569 sub quote_char {
 570     my $self = shift;
 571     $self->{quote_char} = shift if @_;
 572     return $self->{quote_char};
 573 }
 574
 575 # Character separating quoted table names.
 576 sub name_sep {
 577     my $self = shift;
 578     $self->{name_sep} = shift if @_;
 579     return $self->{name_sep};
 580 }
 581
 582 1;