lib/DBIx/Class/ResultSourceProxy/Table.pm

   1 package DBIx::Class::ResultSourceProxy::Table;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::ResultSourceProxy/;
   7
   8 use DBIx::Class::ResultSource::Table;
   9 use Scalar::Util 'blessed';
  10 use namespace::clean;
  11
  12 # FIXME - both of these *PROBABLY* need to be 'inherited_ro_instance' type
  13 __PACKAGE__->mk_classaccessor(table_class => 'DBIx::Class::ResultSource::Table');
  14 # FIXME: Doesn't actually do anything yet!
  15 __PACKAGE__->mk_group_accessors( inherited => 'table_alias' );
  16
  17 sub _init_result_source_instance {
  18     my $class = shift;
  19
  20     $class->mk_group_accessors( inherited => 'result_source_instance' )
  21       unless $class->can('result_source_instance');
  22
  23     # might be pre-made for us courtesy of DBIC::DB::result_source_instance()
  24     my $rsrc = $class->result_source_instance;
  25
  26     return $rsrc
  27       if $rsrc and $rsrc->result_class eq $class;
  28
  29     my $table_class = $class->table_class;
  30     $class->ensure_class_loaded($table_class);
  31
  32     if( $rsrc ) {
  33         $rsrc = $table_class->new({
  34             %$rsrc,
  35             result_class => $class,
  36             source_name => undef,
  37             schema => undef
  38         });
  39     }
  40     else {
  41         $rsrc = $table_class->new({
  42             name            => undef,
  43             result_class    => $class,
  44             source_name     => undef,
  45         });
  46     }
  47
  48     $class->result_source_instance($rsrc);
  49 }
  50
  51 =head1 NAME
  52
  53 DBIx::Class::ResultSourceProxy::Table - provides a classdata table
  54 object and method proxies
  55
  56 =head1 SYNOPSIS
  57
  58   __PACKAGE__->table('cd');
  59   __PACKAGE__->add_columns(qw/cdid artist title year/);
  60   __PACKAGE__->set_primary_key('cdid');
  61
  62 =head1 METHODS
  63
  64 =head2 add_columns
  65
  66   __PACKAGE__->add_columns(qw/cdid artist title year/);
  67
  68 Adds columns to the current class and creates accessors for them.
  69
  70 =cut
  71
  72 =head2 table
  73
  74   __PACKAGE__->table('tbl_name');
  75
  76 Gets or sets the table name.
  77
  78 =cut
  79
  80 sub table {
  81   return $_[0]->result_source_instance->name unless @_ > 1;
  82
  83   my ($class, $table) = @_;
  84
  85   unless (blessed $table && $table->isa($class->table_class)) {
  86
  87     my $table_class = $class->table_class;
  88     $class->ensure_class_loaded($table_class);
  89
  90     $table = $table_class->new({
  91         $class->can('result_source_instance')
  92           ? %{$class->result_source_instance||{}}
  93           : ()
  94         ,
  95         name => $table,
  96         result_class => $class,
  97     });
  98   }
  99
 100   $class->mk_group_accessors(inherited => 'result_source_instance')
 101     unless $class->can('result_source_instance');
 102
 103   $class->result_source_instance($table)->name;
 104 }
 105
 106 =head2 table_class
 107
 108   __PACKAGE__->table_class('DBIx::Class::ResultSource::Table');
 109
 110 Gets or sets the table class used for construction and validation.
 111
 112 =head2 has_column
 113
 114   if ($obj->has_column($col)) { ... }
 115
 116 Returns 1 if the class has a column of this name, 0 otherwise.
 117
 118 =head2 column_info
 119
 120   my $info = $obj->column_info($col);
 121
 122 Returns the column metadata hashref for a column. For a description of
 123 the various types of column data in this hashref, see
 124 L<DBIx::Class::ResultSource/add_column>
 125
 126 =head2 columns
 127
 128   my @column_names = $obj->columns;
 129
 130 =head1 FURTHER QUESTIONS?
 131
 132 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 133
 134 =head1 COPYRIGHT AND LICENSE
 135
 136 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 137 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 138 redistribute it and/or modify it under the same terms as the
 139 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 140
 141 =cut
 142
 143 1;
 144
 145