lib/DBIx/Class/ResultSourceHandle.pm

   1 package DBIx::Class::ResultSourceHandle;
   2
   3 use strict;
   4 use warnings;
   5 use Storable;
   6 use Carp;
   7
   8 use base qw/DBIx::Class/;
   9
  10 use overload
  11     # on some RH perls the following line causes serious performance problem
  12     # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
  13     q/""/ => sub { __PACKAGE__ . ":" . shift->source_moniker; },
  14     fallback => 1;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/schema source_moniker/);
  17
  18 # Schema to use when thawing.
  19 our $thaw_schema;
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSourceHandle - Decouple Rows/ResultSets objects from their Source objects
  24
  25 =head1 DESCRIPTION
  26
  27 This module removes fixed link between Rows/ResultSets and the actual source
  28 objects, which gets round the following problems
  29
  30 =over 4
  31
  32 =item *
  33
  34 Needing to keep C<$schema> in scope, since any objects/result_sets
  35 will have a C<$schema> object through their source handle
  36
  37 =item *
  38
  39 Large output when using Data::Dump(er) since this class can be set to
  40 stringify to almost nothing
  41
  42 =back
  43
  44 =head1 METHODS
  45
  46 =head2 new
  47
  48 =cut
  49
  50 sub new {
  51     my ($class, $data) = @_;
  52
  53     $class = ref $class if ref $class;
  54
  55     bless $data, $class;
  56 }
  57
  58 =head2 resolve
  59
  60 Resolve the moniker into the actual ResultSource object
  61
  62 =cut
  63
  64 sub resolve { return $_[0]->schema->source($_[0]->source_moniker) }
  65
  66 =head2 STORABLE_freeze
  67
  68 Freezes a handle.
  69
  70 =cut
  71
  72 sub STORABLE_freeze {
  73     my ($self, $cloning) = @_;
  74
  75     my $to_serialize = { %$self };
  76
  77     delete $to_serialize->{schema};
  78     $to_serialize->{_frozen_from_class} = $self->schema->class($self->source_moniker);
  79
  80     return (Storable::nfreeze($to_serialize));
  81 }
  82
  83 =head2 STORABLE_thaw
  84
  85 Thaws frozen handle. Resets the internal schema reference to the package
  86 variable C<$thaw_schema>. The recommended way of setting this is to use
  87 C<< $schema->thaw($ice) >> which handles this for you.
  88
  89 =cut
  90
  91
  92 sub STORABLE_thaw {
  93     my ($self, $cloning, $ice) = @_;
  94     %$self = %{ Storable::thaw($ice) };
  95
  96     my $class = delete $self->{_frozen_from_class};
  97     if( $thaw_schema ) {
  98         $self->{schema} = $thaw_schema;
  99     }
 100     else {
 101         my $rs = $class->result_source_instance;
 102         $self->{schema} = $rs->schema if $rs;
 103     }
 104
 105     carp "Unable to restore schema. Look at 'freeze' and 'thaw' methods in DBIx::Class::Schema."
 106         unless $self->{schema};
 107 }
 108
 109 =head1 AUTHOR
 110
 111 Ash Berlin C<< <ash@cpan.org> >>
 112
 113 =cut
 114
 115 1;