lib/DBIx/Class/ResultSource/RowParser/Util.pm

   1 package # hide from the pauses
   2   DBIx::Class::ResultSource::RowParser::Util;
   3
   4 use strict;
   5 use warnings;
   6
   7 use List::Util 'first';
   8 use B 'perlstring';
   9
  10 use base 'Exporter';
  11 our @EXPORT_OK = qw(
  12   assemble_simple_parser
  13   assemble_collapsing_parser
  14 );
  15
  16 # working title - we are hoping to extract this eventually...
  17 our $null_branch_class = 'DBIx::ResultParser::RelatedNullBranch';
  18
  19 sub assemble_simple_parser {
  20   #my ($args) = @_;
  21
  22   # the non-collapsing assembler is easy
  23   # FIXME SUBOPTIMAL there could be a yet faster way to do things here, but
  24   # need to try an actual implementation and benchmark it:
  25   #
  26   # <timbunce_> First setup the nested data structure you want for each row
  27   #   Then call bind_col() to alias the row fields into the right place in
  28   #   the data structure, then to fetch the data do:
  29   # push @rows, dclone($row_data_struct) while ($sth->fetchrow);
  30   #
  31   my $parser_src = sprintf('$_ = %s for @{$_[0]}', __visit_infmap_simple($_[0]) );
  32
  33   # change the quoted placeholders to unquoted alias-references
  34   $parser_src =~ s/ \' \xFF__VALPOS__(\d+)__\xFF \' /"\$_->[$1]"/gex;
  35
  36   $parser_src = "  { use strict; use warnings FATAL => 'all';\n$parser_src\n  }";
  37 }
  38
  39 # the simple non-collapsing nested structure recursor
  40 sub __visit_infmap_simple {
  41   my $args = shift;
  42
  43   my $my_cols = {};
  44   my $rel_cols;
  45   for (keys %{$args->{val_index}}) {
  46     if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
  47       $rel_cols->{$1}{$2} = $args->{val_index}{$_};
  48     }
  49     else {
  50       $my_cols->{$_} = $args->{val_index}{$_};
  51     }
  52   }
  53
  54   my @relperl;
  55   for my $rel (sort keys %$rel_cols) {
  56
  57     my $rel_struct = __visit_infmap_simple({ %$args,
  58       val_index => $rel_cols->{$rel},
  59     });
  60
  61     if (keys %$my_cols) {
  62
  63       my $branch_null_checks = join ' && ', map
  64         { "( ! defined '\xFF__VALPOS__${_}__\xFF' )" }
  65         sort { $a <=> $b } values %{$rel_cols->{$rel}}
  66       ;
  67
  68       if ($args->{hri_style}) {
  69         $rel_struct = sprintf ( '( (%s) ? undef : %s )',
  70           $branch_null_checks,
  71           $rel_struct,
  72         );
  73       }
  74       else {
  75         $rel_struct = sprintf ( '( (%s) ? bless( (%s), %s ) : %s )',
  76           $branch_null_checks,
  77           $rel_struct,
  78           perlstring($null_branch_class),
  79           $rel_struct,
  80         );
  81       }
  82     }
  83
  84     push @relperl, sprintf '( %s => %s )',
  85       perlstring($rel),
  86       $rel_struct,
  87     ;
  88
  89   }
  90
  91   my $me_struct;
  92   $me_struct = __result_struct_to_source($my_cols) if keys %$my_cols;
  93
  94   if ($args->{hri_style}) {
  95     $me_struct =~ s/^ \s* \{ | \} \s* $//gx
  96       if $me_struct;
  97
  98     return sprintf '{ %s }', join (', ', $me_struct||(), @relperl);
  99   }
 100   else {
 101     return sprintf '[%s]', join (',',
 102       $me_struct || 'undef',
 103       @relperl ? sprintf ('{ %s }', join (',', @relperl)) : (),
 104     );
 105   }
 106 }
 107
 108 sub assemble_collapsing_parser {
 109   my $args = shift;
 110
 111   my ($top_node_key, $top_node_key_assembler);
 112
 113   if (scalar @{$args->{collapse_map}{-identifying_columns}}) {
 114     $top_node_key = join ('', map
 115       { "{'\xFF__IDVALPOS__${_}__\xFF'}" }
 116       @{$args->{collapse_map}{-identifying_columns}}
 117     );
 118   }
 119   elsif( my @variants = @{$args->{collapse_map}{-identifying_columns_variants}} ) {
 120
 121     my @path_parts = map { sprintf
 122       "( ( defined '\xFF__VALPOS__%d__\xFF' ) && (join qq(\xFF), '', %s, '') )",
 123       $_->[0],  # checking just first is enough - one ID defined, all defined
 124       ( join ', ', map { "'\xFF__VALPOS__${_}__\xFF'" } @$_ ),
 125     } @variants;
 126
 127     my $virtual_column_idx = (scalar keys %{$args->{val_index}} ) + 1;
 128
 129     $top_node_key = "{'\xFF__IDVALPOS__${virtual_column_idx}__\xFF'}";
 130
 131     $top_node_key_assembler = sprintf "'\xFF__IDVALPOS__%d__\xFF' = (%s);",
 132       $virtual_column_idx,
 133       "\n" . join( "\n  or\n", @path_parts, qq{"\0\$rows_pos\0"} )
 134     ;
 135
 136     $args->{collapse_map} = {
 137       %{$args->{collapse_map}},
 138       -custom_node_key => $top_node_key,
 139     };
 140
 141   }
 142   else {
 143     die('Unexpected collapse map contents');
 144   }
 145
 146   my ($data_assemblers, $stats) = __visit_infmap_collapse ($args);
 147
 148   my @idcol_args = $args->{hri_style} ? ('', '') : (
 149     ', %cur_row_ids', # only declare the variable if we'll use it
 150
 151     sprintf( <<'EOS', join ', ', sort { $a <=> $b } keys %{ $stats->{idcols_seen} } ),
 152   $cur_row_ids{$_} = defined($cur_row_data->[$_]) ? $cur_row_data->[$_] : "\0NULL\xFF$rows_pos\xFF$_\0"
 153     for (%s);
 154 EOS
 155   );
 156
 157   my $parser_src = sprintf (<<'EOS', @idcol_args, $top_node_key_assembler||'', $top_node_key, join( "\n", @{$data_assemblers||[]} ) );
 158 ### BEGIN LITERAL STRING EVAL
 159   my $rows_pos = 0;
 160   my ($result_pos, @collapse_idx, $cur_row_data %1$s);
 161
 162   # this loop is a bit arcane - the rationale is that the passed in
 163   # $_[0] will either have only one row (->next) or will have all
 164   # rows already pulled in (->all and/or unordered). Given that the
 165   # result can be rather large - we reuse the same already allocated
 166   # array, since the collapsed prefetch is smaller by definition.
 167   # At the end we cut the leftovers away and move on.
 168   while ($cur_row_data =
 169     ( ( $rows_pos >= 0 and $_[0][$rows_pos++] ) or do { $rows_pos = -1; undef } )
 170       ||
 171     ($_[1] and $_[1]->())
 172   ) {
 173     # this code exists only when we are *not* assembling direct to HRI
 174     #
 175     # due to left joins some of the ids may be NULL/undef, and
 176     # won't play well when used as hash lookups
 177     # we also need to differentiate NULLs on per-row/per-col basis
 178     # (otherwise folding of optional 1:1s will be greatly confused
 179     %2$s
 180
 181     # in the case of an underdefined root - calculate the virtual id (otherwise no code at all)
 182     %3$s
 183
 184     # if we were supplied a coderef - we are collapsing lazily (the set
 185     # is ordered properly)
 186     # as long as we have a result already and the next result is new we
 187     # return the pre-read data and bail
 188     $_[1] and $result_pos and ! $collapse_idx[0]%4$s and (unshift @{$_[2]}, $cur_row_data) and last;
 189
 190     # the rel assemblers
 191 %5$s
 192
 193   }
 194
 195   $#{$_[0]} = $result_pos - 1; # truncate the passed in array to where we filled it with results
 196 ### END LITERAL STRING EVAL
 197 EOS
 198
 199   # !!! note - different var than the one above
 200   # change the quoted placeholders to unquoted alias-references
 201   $parser_src =~ s/ \' \xFF__VALPOS__(\d+)__\xFF \' /"\$cur_row_data->[$1]"/gex;
 202   $parser_src =~ s/ \' \xFF__IDVALPOS__(\d+)__\xFF \' /$args->{hri_style} ? "\$cur_row_data->[$1]" : "\$cur_row_ids{$1}" /gex;
 203
 204   $parser_src = "  { use strict; use warnings FATAL => 'all';\n$parser_src\n  }";
 205 }
 206
 207
 208 # the collapsing nested structure recursor
 209 sub __visit_infmap_collapse {
 210   my $args = {%{ shift() }};
 211
 212   my $cur_node_idx = ${ $args->{-node_idx_counter} ||= \do { my $x = 0} }++;
 213
 214   my ($my_cols, $rel_cols) = {};
 215   for ( keys %{$args->{val_index}} ) {
 216     if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
 217       $rel_cols->{$1}{$2} = $args->{val_index}{$_};
 218     }
 219     else {
 220       $my_cols->{$_} = $args->{val_index}{$_};
 221     }
 222   }
 223
 224
 225   if ($args->{hri_style}) {
 226     delete $my_cols->{$_} for grep { $rel_cols->{$_} } keys %$my_cols;
 227   }
 228
 229   my $me_struct;
 230   $me_struct = __result_struct_to_source($my_cols) if keys %$my_cols;
 231
 232   $me_struct = sprintf( '[ %s ]', $me_struct||'' )
 233     unless $args->{hri_style};
 234
 235
 236   my $node_key = $args->{collapse_map}->{-custom_node_key} || join ('', map
 237     { "{'\xFF__IDVALPOS__${_}__\xFF'}" }
 238     @{$args->{collapse_map}->{-identifying_columns}}
 239   );
 240   my $node_idx_slot = sprintf '$collapse_idx[%d]%s', $cur_node_idx, $node_key;
 241
 242
 243   my @src;
 244
 245   if ($cur_node_idx == 0) {
 246     push @src, sprintf( '%s ||= $_[0][$result_pos++] = %s;',
 247       $node_idx_slot,
 248       $me_struct || '{}',
 249     );
 250   }
 251   else {
 252     my $parent_attach_slot = sprintf( '$collapse_idx[%d]%s%s{%s}',
 253       @{$args}{qw/-parent_node_idx -parent_node_key/},
 254       $args->{hri_style} ? '' : '[1]',
 255       perlstring($args->{-node_relname}),
 256     );
 257
 258     if ($args->{collapse_map}->{-is_single}) {
 259       push @src, sprintf ( '%s ||= %s%s;',
 260         $parent_attach_slot,
 261         $node_idx_slot,
 262         $me_struct ? " = $me_struct" : '',
 263       );
 264     }
 265     else {
 266       push @src, sprintf('(! %s) and push @{%s}, %s%s;',
 267         $node_idx_slot,
 268         $parent_attach_slot,
 269         $node_idx_slot,
 270         $me_struct ? " = $me_struct" : '',
 271       );
 272     }
 273   }
 274
 275   my $known_present_ids = { map { $_ => 1 } @{$args->{collapse_map}{-identifying_columns}} };
 276   my ($stats, $rel_src);
 277
 278   for my $rel (sort keys %$rel_cols) {
 279
 280     my $relinfo = $args->{collapse_map}{$rel};
 281
 282     ($rel_src, $stats->{$rel}) = __visit_infmap_collapse({ %$args,
 283       val_index => $rel_cols->{$rel},
 284       collapse_map => $relinfo,
 285       -parent_node_idx => $cur_node_idx,
 286       -parent_node_key => $node_key,
 287       -node_relname => $rel,
 288     });
 289
 290     my $rel_src_pos = $#src + 1;
 291     push @src, @$rel_src;
 292
 293     if (
 294       $relinfo->{-is_optional}
 295         and
 296       defined ( my $first_distinct_child_idcol = first
 297         { ! $known_present_ids->{$_} }
 298         @{$relinfo->{-identifying_columns}}
 299       )
 300     ) {
 301
 302       if ($args->{hri_style}) {
 303
 304         # start of wrap of the entire chain in a conditional
 305         splice @src, $rel_src_pos, 0, sprintf "( ! defined %s )\n  ? %s{%s} = %s\n  : do {",
 306           "'\xFF__VALPOS__${first_distinct_child_idcol}__\xFF'",
 307           $node_idx_slot,
 308           perlstring($rel),
 309           $relinfo->{-is_single} ? 'undef' : '[]'
 310         ;
 311
 312         # end of wrap
 313         push @src, '};'
 314       }
 315       else {
 316
 317         splice @src, $rel_src_pos + 1, 0, sprintf ( '(defined %s) or bless (%s[1]{%s}, %s);',
 318           "'\xFF__VALPOS__${first_distinct_child_idcol}__\xFF'",
 319           $node_idx_slot,
 320           perlstring($rel),
 321           perlstring($null_branch_class),
 322         );
 323       }
 324     }
 325   }
 326
 327   return (
 328     \@src,
 329     {
 330       idcols_seen => {
 331         ( map { %{ $_->{idcols_seen} } } values %$stats ),
 332         ( map { $_ => 1 } @{$args->{collapse_map}->{-identifying_columns}} ),
 333       }
 334     }
 335   );
 336 }
 337
 338 sub __result_struct_to_source {
 339   sprintf( '{ %s }', join (', ', map
 340     { sprintf "%s => '\xFF__VALPOS__%d__\xFF'", perlstring($_), $_[0]{$_} }
 341     sort keys %{$_[0]}
 342   ));
 343 }
 344
 345 1;