7d8f6a7bea64936be829ef0edca7d091388303c4
[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / ResultSource / RowParser / Util.pm
1 package # hide from the pauses
2   DBIx::Class::ResultSource::RowParser::Util;
3
4 use strict;
5 use warnings;
6
7 use List::Util 'first';
8 use B 'perlstring';
9
10 use base 'Exporter';
11 our @EXPORT_OK = qw(
12   assemble_simple_parser
13   assemble_collapsing_parser
14 );
15
16 # working title - we are hoping to extract this eventually...
17 our $null_branch_class = 'DBIx::ResultParser::RelatedNullBranch';
18
19 sub assemble_simple_parser {
20   #my ($args) = @_;
21
22   # the non-collapsing assembler is easy
23   # FIXME SUBOPTIMAL there could be a yet faster way to do things here, but
24   # need to try an actual implementation and benchmark it:
25   #
26   # <timbunce_> First setup the nested data structure you want for each row
27   #   Then call bind_col() to alias the row fields into the right place in
28   #   the data structure, then to fetch the data do:
29   # push @rows, dclone($row_data_struct) while ($sth->fetchrow);
30   #
31   my $parser_src = sprintf('$_ = %s for @{$_[0]}', __visit_infmap_simple($_[0]) );
32
33   # change the quoted placeholders to unquoted alias-references
34   $parser_src =~ s/ \' \xFF__VALPOS__(\d+)__\xFF \' /"\$_->[$1]"/gex;
35
36   $parser_src = "  { use strict; use warnings FATAL => 'all';\n$parser_src\n  }";
37 }
38
39 # the simple non-collapsing nested structure recursor
40 sub __visit_infmap_simple {
41   my $args = shift;
42
43   my $my_cols = {};
44   my $rel_cols;
45   for (keys %{$args->{val_index}}) {
46     if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
47       $rel_cols->{$1}{$2} = $args->{val_index}{$_};
48     }
49     else {
50       $my_cols->{$_} = $args->{val_index}{$_};
51     }
52   }
53
54   my @relperl;
55   for my $rel (sort keys %$rel_cols) {
56
57     my $rel_struct = __visit_infmap_simple({ %$args,
58       val_index => $rel_cols->{$rel},
59     });
60
61     if (keys %$my_cols) {
62
63       my $branch_null_checks = join ' && ', map
64         { "( ! defined '\xFF__VALPOS__${_}__\xFF' )" }
65         sort { $a <=> $b } values %{$rel_cols->{$rel}}
66       ;
67
68       if ($args->{prune_null_branches}) {
69         $rel_struct = sprintf ( '( (%s) ? undef : %s )',
70           $branch_null_checks,
71           $rel_struct,
72         );
73       }
74       else {
75         $rel_struct = sprintf ( '( (%s) ? bless( (%s), %s ) : %s )',
76           $branch_null_checks,
77           $rel_struct,
78           perlstring($null_branch_class),
79           $rel_struct,
80         );
81       }
82     }
83
84     push @relperl, sprintf '( %s => %s )',
85       perlstring($rel),
86       $rel_struct,
87     ;
88
89   }
90
91   my $me_struct;
92   $me_struct = __result_struct_to_source($my_cols) if keys %$my_cols;
93
94   if ($args->{hri_style}) {
95     $me_struct =~ s/^ \s* \{ | \} \s* $//gx
96       if $me_struct;
97
98     return sprintf '{ %s }', join (', ', $me_struct||(), @relperl);
99   }
100   else {
101     return sprintf '[%s]', join (',',
102       $me_struct || 'undef',
103       @relperl ? sprintf ('{ %s }', join (',', @relperl)) : (),
104     );
105   }
106 }
107
108 sub assemble_collapsing_parser {
109   my $args = shift;
110
111   # it may get unset further down
112   my $no_rowid_container = $args->{prune_null_branches};
113
114   my ($top_node_key, $top_node_key_assembler);
115
116   if (scalar @{$args->{collapse_map}{-identifying_columns}}) {
117     $top_node_key = join ('', map
118       { "{'\xFF__IDVALPOS__${_}__\xFF'}" }
119       @{$args->{collapse_map}{-identifying_columns}}
120     );
121   }
122   elsif( my @variants = @{$args->{collapse_map}{-identifying_columns_variants}} ) {
123
124     my @path_parts = map { sprintf
125       "( ( defined '\xFF__VALPOS__%d__\xFF' ) && (join qq(\xFF), '', %s, '') )",
126       $_->[0],  # checking just first is enough - one ID defined, all defined
127       ( join ', ', map { "'\xFF__VALPOS__${_}__\xFF'" } @$_ ),
128     } @variants;
129
130     my $virtual_column_idx = (scalar keys %{$args->{val_index}} ) + 1;
131
132     $top_node_key = "{'\xFF__IDVALPOS__${virtual_column_idx}__\xFF'}";
133
134     $top_node_key_assembler = sprintf "'\xFF__IDVALPOS__%d__\xFF' = (%s);",
135       $virtual_column_idx,
136       "\n" . join( "\n  or\n", @path_parts, qq{"\0\$rows_pos\0"} )
137     ;
138
139     $args->{collapse_map} = {
140       %{$args->{collapse_map}},
141       -custom_node_key => $top_node_key,
142     };
143
144     $no_rowid_container = 0;
145   }
146   else {
147     die('Unexpected collapse map contents');
148   }
149
150   my ($data_assemblers, $stats) = __visit_infmap_collapse ($args);
151
152   my @idcol_args = $no_rowid_container ? ('', '') : (
153     ', %cur_row_ids', # only declare the variable if we'll use it
154     join ("\n", map {
155       # in case we prune - we will never hit these undefs
156       $args->{prune_null_branches}
157         ? qq(\$cur_row_ids{$_} = \$cur_row_data->[$_];)
158         : qq(\$cur_row_ids{$_} = defined(\$cur_row_data->[$_]) ? \$cur_row_data->[$_] : "\0NULL\xFF\$rows_pos\xFF$_\0";)
159     } sort { $a <=> $b } keys %{ $stats->{idcols_seen} } ),
160   );
161
162   my $parser_src = sprintf (<<'EOS', @idcol_args, $top_node_key_assembler||'', $top_node_key, join( "\n", @{$data_assemblers||[]} ) );
163 ### BEGIN LITERAL STRING EVAL
164   my $rows_pos = 0;
165   my ($result_pos, @collapse_idx, $cur_row_data %1$s);
166
167   # this loop is a bit arcane - the rationale is that the passed in
168   # $_[0] will either have only one row (->next) or will have all
169   # rows already pulled in (->all and/or unordered). Given that the
170   # result can be rather large - we reuse the same already allocated
171   # array, since the collapsed prefetch is smaller by definition.
172   # At the end we cut the leftovers away and move on.
173   while ($cur_row_data = (
174     ( $rows_pos >= 0 and $_[0][$rows_pos++] )
175       or
176     ( $_[1] and $rows_pos = -1 and $_[1]->() )
177   ) ) {
178
179     # this code exists only when we are using a cur_row_ids
180     # furthermore the undef checks may or may not be there
181     # depending on whether we prune or not
182     #
183     # due to left joins some of the ids may be NULL/undef, and
184     # won't play well when used as hash lookups
185     # we also need to differentiate NULLs on per-row/per-col basis
186     # (otherwise folding of optional 1:1s will be greatly confused
187 %2$s
188
189     # in the case of an underdefined root - calculate the virtual id (otherwise no code at all)
190 %3$s
191
192     # if we were supplied a coderef - we are collapsing lazily (the set
193     # is ordered properly)
194     # as long as we have a result already and the next result is new we
195     # return the pre-read data and bail
196 $_[1] and $result_pos and ! $collapse_idx[0]%4$s and (unshift @{$_[2]}, $cur_row_data) and last;
197
198     # the rel assemblers
199 %5$s
200
201   }
202
203   $#{$_[0]} = $result_pos - 1; # truncate the passed in array to where we filled it with results
204 ### END LITERAL STRING EVAL
205 EOS
206
207   # !!! note - different var than the one above
208   # change the quoted placeholders to unquoted alias-references
209   $parser_src =~ s/ \' \xFF__VALPOS__(\d+)__\xFF \' /"\$cur_row_data->[$1]"/gex;
210   $parser_src =~ s/
211     \' \xFF__IDVALPOS__(\d+)__\xFF \'
212   /
213     $no_rowid_container ? "\$cur_row_data->[$1]" : "\$cur_row_ids{$1}"
214   /gex;
215
216   $parser_src = "  { use strict; use warnings FATAL => 'all';\n$parser_src\n  }";
217 }
218
219
220 # the collapsing nested structure recursor
221 sub __visit_infmap_collapse {
222   my $args = {%{ shift() }};
223
224   my $cur_node_idx = ${ $args->{-node_idx_counter} ||= \do { my $x = 0} }++;
225
226   my ($my_cols, $rel_cols) = {};
227   for ( keys %{$args->{val_index}} ) {
228     if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
229       $rel_cols->{$1}{$2} = $args->{val_index}{$_};
230     }
231     else {
232       $my_cols->{$_} = $args->{val_index}{$_};
233     }
234   }
235
236
237   if ($args->{hri_style}) {
238     delete $my_cols->{$_} for grep { $rel_cols->{$_} } keys %$my_cols;
239   }
240
241   my $me_struct;
242   $me_struct = __result_struct_to_source($my_cols) if keys %$my_cols;
243
244   $me_struct = sprintf( '[ %s ]', $me_struct||'' )
245     unless $args->{hri_style};
246
247
248   my $node_key = $args->{collapse_map}->{-custom_node_key} || join ('', map
249     { "{'\xFF__IDVALPOS__${_}__\xFF'}" }
250     @{$args->{collapse_map}->{-identifying_columns}}
251   );
252   my $node_idx_slot = sprintf '$collapse_idx[%d]%s', $cur_node_idx, $node_key;
253
254
255   my @src;
256
257   if ($cur_node_idx == 0) {
258     push @src, sprintf( '%s ||= $_[0][$result_pos++] = %s;',
259       $node_idx_slot,
260       $me_struct || '{}',
261     );
262   }
263   else {
264     my $parent_attach_slot = sprintf( '$collapse_idx[%d]%s%s{%s}',
265       @{$args}{qw/-parent_node_idx -parent_node_key/},
266       $args->{hri_style} ? '' : '[1]',
267       perlstring($args->{-node_relname}),
268     );
269
270     if ($args->{collapse_map}->{-is_single}) {
271       push @src, sprintf ( '%s ||= %s%s;',
272         $parent_attach_slot,
273         $node_idx_slot,
274         $me_struct ? " = $me_struct" : '',
275       );
276     }
277     else {
278       push @src, sprintf('(! %s) and push @{%s}, %s%s;',
279         $node_idx_slot,
280         $parent_attach_slot,
281         $node_idx_slot,
282         $me_struct ? " = $me_struct" : '',
283       );
284     }
285   }
286
287   my $known_present_ids = { map { $_ => 1 } @{$args->{collapse_map}{-identifying_columns}} };
288   my ($stats, $rel_src);
289
290   for my $rel (sort keys %$rel_cols) {
291
292     my $relinfo = $args->{collapse_map}{$rel};
293
294     ($rel_src, $stats->{$rel}) = __visit_infmap_collapse({ %$args,
295       val_index => $rel_cols->{$rel},
296       collapse_map => $relinfo,
297       -parent_node_idx => $cur_node_idx,
298       -parent_node_key => $node_key,
299       -node_relname => $rel,
300     });
301
302     my $rel_src_pos = $#src + 1;
303     push @src, @$rel_src;
304
305     if (
306       $relinfo->{-is_optional}
307         and
308       defined ( my $first_distinct_child_idcol = first
309         { ! $known_present_ids->{$_} }
310         @{$relinfo->{-identifying_columns}}
311       )
312     ) {
313
314       if ($args->{prune_null_branches}) {
315
316         # start of wrap of the entire chain in a conditional
317         splice @src, $rel_src_pos, 0, sprintf "( ! defined %s )\n  ? %s%s{%s} = %s\n  : do {",
318           "'\xFF__VALPOS__${first_distinct_child_idcol}__\xFF'",
319           $node_idx_slot,
320           $args->{hri_style} ? '' : '[1]',
321           perlstring($rel),
322           ($args->{hri_style} && $relinfo->{-is_single}) ? 'undef' : '[]'
323         ;
324
325         # end of wrap
326         push @src, '};'
327       }
328       else {
329
330         splice @src, $rel_src_pos + 1, 0, sprintf ( '(defined %s) or bless (%s[1]{%s}, %s);',
331           "'\xFF__VALPOS__${first_distinct_child_idcol}__\xFF'",
332           $node_idx_slot,
333           perlstring($rel),
334           perlstring($null_branch_class),
335         );
336       }
337     }
338   }
339
340   return (
341     \@src,
342     {
343       idcols_seen => {
344         ( map { %{ $_->{idcols_seen} } } values %$stats ),
345         ( map { $_ => 1 } @{$args->{collapse_map}->{-identifying_columns}} ),
346       }
347     }
348   );
349 }
350
351 sub __result_struct_to_source {
352   sprintf( '{ %s }', join (', ', map
353     { sprintf "%s => '\xFF__VALPOS__%d__\xFF'", perlstring($_), $_[0]{$_} }
354     sort keys %{$_[0]}
355   ));
356 }
357
358 1;