First part of changes for better unexpected NULL reporting
[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / ResultSource / RowParser / Util.pm
1 package # hide from the pauses
2   DBIx::Class::ResultSource::RowParser::Util;
3
4 use strict;
5 use warnings;
6
7 use DBIx::Class::_Util qw( perlstring dump_value );
8
9 use constant HAS_DOR => ( "$]" < 5.010 ? 0 : 1 );
10
11 use base 'Exporter';
12 our @EXPORT_OK = qw(
13   assemble_simple_parser
14   assemble_collapsing_parser
15 );
16
17 # working title - we are hoping to extract this eventually...
18 our $null_branch_class = 'DBIx::ResultParser::RelatedNullBranch';
19
20 sub __wrap_in_strictured_scope {
21   "  { use strict; use warnings; use warnings FATAL => 'uninitialized';\n$_[0]\n  }"
22 }
23
24 sub assemble_simple_parser {
25   #my ($args) = @_;
26
27   # the non-collapsing assembler is easy
28   # FIXME SUBOPTIMAL there could be a yet faster way to do things here, but
29   # need to try an actual implementation and benchmark it:
30   #
31   # <timbunce_> First setup the nested data structure you want for each row
32   #   Then call bind_col() to alias the row fields into the right place in
33   #   the data structure, then to fetch the data do:
34   # push @rows, dclone($row_data_struct) while ($sth->fetchrow);
35   #
36
37   __wrap_in_strictured_scope( sprintf
38     '$_ = %s for @{$_[0]}',
39     __visit_infmap_simple( $_[0] )
40   );
41 }
42
43 # the simple non-collapsing nested structure recursor
44 sub __visit_infmap_simple {
45   my $args = shift;
46
47   my $my_cols = {};
48   my $rel_cols;
49   for (keys %{$args->{val_index}}) {
50     if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
51       $rel_cols->{$1}{$2} = $args->{val_index}{$_};
52     }
53     else {
54       $my_cols->{$_} = $args->{val_index}{$_};
55     }
56   }
57
58   my @relperl;
59   for my $rel (sort keys %$rel_cols) {
60
61     my $rel_struct = __visit_infmap_simple({ %$args,
62       val_index => $rel_cols->{$rel},
63     });
64
65     if (keys %$my_cols) {
66
67       my $branch_null_checks = join ' && ', map
68         { "( ! defined \$_->[$_] )" }
69         sort { $a <=> $b } values %{$rel_cols->{$rel}}
70       ;
71
72       if ($args->{prune_null_branches}) {
73         $rel_struct = sprintf ( '( (%s) ? undef : %s )',
74           $branch_null_checks,
75           $rel_struct,
76         );
77       }
78       else {
79         $rel_struct = sprintf ( '( (%s) ? bless( (%s), %s ) : %s )',
80           $branch_null_checks,
81           $rel_struct,
82           perlstring($null_branch_class),
83           $rel_struct,
84         );
85       }
86     }
87
88     push @relperl, sprintf '( %s => %s )',
89       perlstring($rel),
90       $rel_struct,
91     ;
92
93   }
94
95   my $me_struct;
96   $me_struct = __result_struct_to_source($my_cols) if keys %$my_cols;
97
98   if ($args->{hri_style}) {
99     $me_struct =~ s/^ \s* \{ | \} \s* $//gx
100       if $me_struct;
101
102     return sprintf '{ %s }', join (', ', $me_struct||(), @relperl);
103   }
104   else {
105     return sprintf '[%s]', join (',',
106       $me_struct || 'undef',
107       @relperl ? sprintf ('{ %s }', join (',', @relperl)) : (),
108     );
109   }
110 }
111
112 sub assemble_collapsing_parser {
113   my $args = shift;
114
115   my ($top_node_key, $top_node_key_assembler, $variant_idcols);
116
117   if (scalar @{$args->{collapse_map}{-identifying_columns}}) {
118     $top_node_key = join ('', map
119       { "{ \$cur_row_ids{$_} }" }
120       @{$args->{collapse_map}{-identifying_columns}}
121     );
122
123     $top_node_key_assembler = '';
124   }
125   elsif( my @variants = @{$args->{collapse_map}{-identifying_columns_variants}} ) {
126
127     my @path_parts = map { sprintf
128       "( ( defined \$cur_row_data->[%d] ) && (join qq(\xFF), '', %s, '') )",
129       $_->[0],  # checking just first is enough - one ID defined, all defined
130       ( join ', ', map { $variant_idcols->{$_} = 1; " \$cur_row_ids{$_} " } @$_ ),
131     } @variants;
132
133     my $virtual_column_idx = (scalar keys %{$args->{val_index}} ) + 1;
134
135     $top_node_key = "{ \$cur_row_ids{$virtual_column_idx} }";
136
137     $top_node_key_assembler = sprintf "( \$cur_row_ids{%d} = (%s) ),",
138       $virtual_column_idx,
139       "\n" . join( "\n  or\n", @path_parts, qq{"\0\$rows_pos\0"} )
140     ;
141
142     $args->{collapse_map} = {
143       %{$args->{collapse_map}},
144       -custom_node_key => $top_node_key,
145     };
146   }
147   else {
148     DBIx::Class::Exception->throw(
149      'Unexpected collapse map contents: ' . dump_value $args->{collapse_map},
150       1,
151     )
152   }
153
154   my ($data_assemblers, $stats) = __visit_infmap_collapse ($args);
155
156   # variants do not necessarily overlap with true idcols
157   my @row_ids = sort { $a <=> $b } keys %{ {
158     %{ $variant_idcols || {} },
159     %{ $stats->{idcols_seen} },
160   } };
161
162   my $row_id_defs = sprintf "( \@cur_row_ids{( %s )} = (\n%s\n ) ),",
163     join (', ', @row_ids ),
164     # in case we prune - we will never hit undefs/NULLs as pigeon-hole-criteria
165     ( $args->{prune_null_branches}
166       ? sprintf( '@{$cur_row_data}[( %s )]', join ', ', @row_ids )
167       : join (",\n", map {
168         $stats->{nullchecks}{mandatory}{$_}
169           ? qq!( \$cur_row_data->[$_] )!
170           : do {
171             my $quoted_null_val = qq("\0NULL\xFF\${rows_pos}\xFF${_}\0");
172             HAS_DOR
173               ? qq!( \$cur_row_data->[$_] // $quoted_null_val )!
174               : qq!( defined(\$cur_row_data->[$_]) ? \$cur_row_data->[$_] : $quoted_null_val )!
175           }
176       } @row_ids)
177     )
178   ;
179
180   my $parser_src = sprintf (<<'EOS', $row_id_defs, $top_node_key_assembler, $top_node_key, join( "\n", @$data_assemblers ) );
181 ### BEGIN LITERAL STRING EVAL
182   my $rows_pos = 0;
183   my ($result_pos, @collapse_idx, $cur_row_data, %%cur_row_ids );
184
185   # this loop is a bit arcane - the rationale is that the passed in
186   # $_[0] will either have only one row (->next) or will have all
187   # rows already pulled in (->all and/or unordered). Given that the
188   # result can be rather large - we reuse the same already allocated
189   # array, since the collapsed prefetch is smaller by definition.
190   # At the end we cut the leftovers away and move on.
191   while ($cur_row_data = (
192     (
193       $rows_pos >= 0
194         and
195       (
196         $_[0][$rows_pos++]
197           or
198         # It may be tempting to drop the -1 and undef $rows_pos instead
199         # thus saving the >= comparison above as well
200         # However NULL-handlers and underdefined root markers both use
201         # $rows_pos as a last-resort-uniqueness marker (it either is
202         # monotonically increasing while we parse ->all, or is set at
203         # a steady -1 when we are dealing with a single root node). For
204         # the time being the complication of changing all callsites seems
205         # overkill, for what is going to be a very modest saving of ops
206         ( ($rows_pos = -1), undef )
207       )
208     )
209       or
210     ( $_[1] and $_[1]->() )
211   ) ) {
212
213     # the undef checks may or may not be there
214     # depending on whether we prune or not
215     #
216     # due to left joins some of the ids may be NULL/undef, and
217     # won't play well when used as hash lookups
218     # we also need to differentiate NULLs on per-row/per-col basis
219     # (otherwise folding of optional 1:1s will be greatly confused
220 %s
221
222     # in the case of an underdefined root - calculate the virtual id (otherwise no code at all)
223 %s
224
225     # if we were supplied a coderef - we are collapsing lazily (the set
226     # is ordered properly)
227     # as long as we have a result already and the next result is new we
228     # return the pre-read data and bail
229 ( $_[1] and $result_pos and ! $collapse_idx[0]%s and (unshift @{$_[2]}, $cur_row_data) and last ),
230
231     # the rel assemblers
232 %s
233
234   }
235
236   $#{$_[0]} = $result_pos - 1; # truncate the passed in array to where we filled it with results
237 ### END LITERAL STRING EVAL
238 EOS
239
240   __wrap_in_strictured_scope($parser_src);
241 }
242
243
244 # the collapsing nested structure recursor
245 sub __visit_infmap_collapse {
246   my $args = {%{ shift() }};
247
248   my $cur_node_idx = ${ $args->{-node_idx_counter} ||= \do { my $x = 0} }++;
249
250   $args->{-mandatory_ids} ||= {};
251   $args->{-seen_ids} ||= {};
252   $args->{-all_or_nothing_sets} ||= [];
253   $args->{-null_from} ||= [];
254
255   $args->{-seen_ids}{$_} = 1
256     for @{$args->{collapse_map}->{-identifying_columns}};
257
258   my $node_specific_ids = { map { $_ => 1 } grep
259     { ! $args->{-parent_ids}{$_} }
260     @{$args->{collapse_map}->{-identifying_columns}}
261   };
262
263   if (not ( $args->{-chain_is_optional} ||= $args->{collapse_map}{-is_optional} ) ) {
264     $args->{-mandatory_ids}{$_} = 1
265       for @{$args->{collapse_map}->{-identifying_columns}};
266   }
267   elsif ( keys %$node_specific_ids > 1 ) {
268     push @{$args->{-all_or_nothing_sets}}, $node_specific_ids;
269   }
270
271   my ($my_cols, $rel_cols) = {};
272   for ( keys %{$args->{val_index}} ) {
273     if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
274       $rel_cols->{$1}{$2} = $args->{val_index}{$_};
275     }
276     else {
277       $my_cols->{$_} = $args->{val_index}{$_};
278     }
279   }
280
281
282   if ($args->{hri_style}) {
283     delete $my_cols->{$_} for grep { $rel_cols->{$_} } keys %$my_cols;
284   }
285
286   my $me_struct;
287   $me_struct = __result_struct_to_source($my_cols, 1) if keys %$my_cols;
288
289   $me_struct = sprintf( '[ %s ]', $me_struct||'' )
290     unless $args->{hri_style};
291
292
293   my $node_key = $args->{collapse_map}->{-custom_node_key} || join ('', map
294     { "{ \$cur_row_ids{$_} }" }
295     @{$args->{collapse_map}->{-identifying_columns}}
296   );
297   my $node_idx_slot = sprintf '$collapse_idx[%d]%s', $cur_node_idx, $node_key;
298
299
300   my @src;
301
302   if ($cur_node_idx == 0) {
303     push @src, sprintf( '( %s %s $_[0][$result_pos++] = %s ),',
304       $node_idx_slot,
305       (HAS_DOR ? '//=' : '||='),
306       $me_struct || '{}',
307     );
308   }
309   else {
310     my $parent_attach_slot = sprintf( '$collapse_idx[%d]%s%s{%s}',
311       @{$args}{qw/-parent_node_idx -parent_node_key/},
312       $args->{hri_style} ? '' : '[1]',
313       perlstring($args->{-node_rel_name}),
314     );
315
316     if ($args->{collapse_map}->{-is_single}) {
317       push @src, sprintf ( '( %s %s %s = %s ),',
318         $parent_attach_slot,
319         (HAS_DOR ? '//=' : '||='),
320         $node_idx_slot,
321         $me_struct || '{}',
322       );
323     }
324     else {
325       push @src, sprintf('( (! %s) and push @{%s}, %s = %s ),',
326         $node_idx_slot,
327         $parent_attach_slot,
328         $node_idx_slot,
329         $me_struct || '{}',
330       );
331     }
332   }
333
334   my $known_present_ids = { map { $_ => 1 } @{$args->{collapse_map}{-identifying_columns}} };
335   my $rel_src;
336
337   for my $rel (sort keys %$rel_cols) {
338
339     my $relinfo = $args->{collapse_map}{$rel};
340
341     ($rel_src) = __visit_infmap_collapse({ %$args,
342       val_index => $rel_cols->{$rel},
343       collapse_map => $relinfo,
344       -parent_node_idx => $cur_node_idx,
345       -parent_node_key => $node_key,
346       -parent_id_path => [ @{$args->{-parent_id_path}||[]}, sort { $a <=> $b } keys %$node_specific_ids ],
347       -parent_ids => { map { %$_ } $node_specific_ids, $args->{-parent_ids}||{} },
348       -node_rel_name => $rel,
349     });
350
351     my $rel_src_pos = $#src + 1;
352     push @src, @$rel_src;
353
354     if (
355       $relinfo->{-is_optional}
356     ) {
357
358       my ($first_distinct_child_idcol) = grep
359         { ! $known_present_ids->{$_} }
360         @{$relinfo->{-identifying_columns}}
361       ;
362
363       DBIx::Class::Exception->throw(
364         "An optional node *without* a distinct identifying set shouldn't be possible: " . dump_value $args->{collapse_map},
365         1,
366       ) unless defined $first_distinct_child_idcol;
367
368       if ($args->{prune_null_branches}) {
369
370         # start of wrap of the entire chain in a conditional
371         splice @src, $rel_src_pos, 0, sprintf "( ( ! defined %s )\n  ? %s%s{%s} = %s\n  : do {",
372           "\$cur_row_data->[$first_distinct_child_idcol]",
373           $node_idx_slot,
374           $args->{hri_style} ? '' : '[1]',
375           perlstring($rel),
376           ($args->{hri_style} && $relinfo->{-is_single}) ? 'undef' : '[]'
377         ;
378
379         # end of wrap
380         push @src, '} ),'
381       }
382       else {
383
384         splice @src, $rel_src_pos + 1, 0, sprintf ( '( (defined %s) or bless (%s[1]{%s}, %s) ),',
385           "\$cur_row_data->[$first_distinct_child_idcol]",
386           $node_idx_slot,
387           perlstring($rel),
388           perlstring($null_branch_class),
389         );
390       }
391     }
392   }
393
394   if (
395
396     # calculation only valid for leaf nodes
397     ! values %$rel_cols
398
399       and
400
401     # child of underdefined path doesn't leave us anything to test
402     @{$args->{-parent_id_path} || []}
403
404       and
405
406     (my @nullable_portion = grep
407       { ! $args->{-mandatory_ids}{$_} }
408       (
409         @{$args->{-parent_id_path}},
410         sort { $a <=> $b } keys %$node_specific_ids
411       )
412     ) > 1
413   ) {
414     # there may be 1:1 overlap with a specific all_or_nothing
415     push @{$args->{-null_from}}, \@nullable_portion unless grep
416       {
417         my $a_o_n_set = $_;
418
419         keys %$a_o_n_set == @nullable_portion
420           and
421         ! grep { ! $a_o_n_set->{$_} } @nullable_portion
422       }
423       @{ $args->{-all_or_nothing_sets} || [] }
424     ;
425   }
426
427   return (
428     \@src,
429     ( $cur_node_idx != 0 ) ? () : {
430       idcols_seen => $args->{-seen_ids},
431       nullchecks => {
432         ( keys %{$args->{-mandatory_ids} }
433           ? ( mandatory => $args->{-mandatory_ids} )
434           : ()
435         ),
436         ( @{$args->{-all_or_nothing_sets}}
437           ? ( all_or_nothing => $args->{-all_or_nothing_sets} )
438           : ()
439         ),
440         ( @{$args->{-null_from}}
441           ? ( from_first_encounter => $args->{-null_from} )
442           : ()
443         ),
444       },
445     },
446   );
447 }
448
449 sub __result_struct_to_source {
450   my ($data, $is_collapsing) = @_;
451
452   sprintf( '{ %s }',
453     join (', ', map {
454       sprintf ( "%s => %s",
455         perlstring($_),
456         $is_collapsing
457           ? "\$cur_row_data->[$data->{$_}]"
458           : "\$_->[ $data->{$_} ]"
459       )
460     } sort keys %{$data}
461     )
462   );
463 }
464
465 1;