lib/DBIx/Class/ResultSource/RowParser.pm

   1 package # hide from the pauses
   2   DBIx::Class::ResultSource::RowParser;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base 'DBIx::Class';
   8
   9 use Try::Tiny;
  10 use List::Util qw(first max);
  11 use B 'perlstring';
  12
  13 use DBIx::Class::ResultSource::RowParser::Util qw(
  14   assemble_simple_parser
  15   assemble_collapsing_parser
  16 );
  17
  18 use namespace::clean;
  19
  20 # Accepts one or more relationships for the current source and returns an
  21 # array of column names for each of those relationships. Column names are
  22 # prefixed relative to the current source, in accordance with where they appear
  23 # in the supplied relationships.
  24 sub _resolve_prefetch {
  25   my ($self, $pre, $alias, $alias_map, $order, $pref_path) = @_;
  26   $pref_path ||= [];
  27
  28   if (not defined $pre or not length $pre) {
  29     return ();
  30   }
  31   elsif( ref $pre eq 'ARRAY' ) {
  32     return
  33       map { $self->_resolve_prefetch( $_, $alias, $alias_map, $order, [ @$pref_path ] ) }
  34         @$pre;
  35   }
  36   elsif( ref $pre eq 'HASH' ) {
  37     my @ret =
  38     map {
  39       $self->_resolve_prefetch($_, $alias, $alias_map, $order, [ @$pref_path ] ),
  40       $self->related_source($_)->_resolve_prefetch(
  41          $pre->{$_}, "${alias}.$_", $alias_map, $order, [ @$pref_path, $_] )
  42     } keys %$pre;
  43     return @ret;
  44   }
  45   elsif( ref $pre ) {
  46     $self->throw_exception(
  47       "don't know how to resolve prefetch reftype ".ref($pre));
  48   }
  49   else {
  50     my $p = $alias_map;
  51     $p = $p->{$_} for (@$pref_path, $pre);
  52
  53     $self->throw_exception (
  54       "Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
  55       . join (' -> ', @$pref_path, $pre)
  56     ) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );
  57
  58     my $as = shift @{$p->{-join_aliases}};
  59
  60     my $rel_info = $self->relationship_info( $pre );
  61     $self->throw_exception( $self->source_name . " has no such relationship '$pre'" )
  62       unless $rel_info;
  63
  64     my $as_prefix = ($alias =~ /^.*?\.(.+)$/ ? $1.'.' : '');
  65
  66     return map { [ "${as}.$_", "${as_prefix}${pre}.$_", ] }
  67       $self->related_source($pre)->columns;
  68   }
  69 }
  70
  71 # Takes an arrayref of {as} dbic column aliases and the collapse and select
  72 # attributes from the same $rs (the selector requirement is a temporary
  73 # workaround... I hope), and returns a coderef capable of:
  74 # my $me_pref_clps = $coderef->([$rs->cursor->next/all])
  75 # Where the $me_pref_clps arrayref is the future argument to inflate_result()
  76 #
  77 # For an example of this coderef in action (and to see its guts) look at
  78 # t/resultset/rowparser_internals.t
  79 #
  80 # This is a huge performance win, as we call the same code for every row
  81 # returned from the db, thus avoiding repeated method lookups when traversing
  82 # relationships
  83 #
  84 # Also since the coderef is completely stateless (the returned structure is
  85 # always fresh on every new invocation) this is a very good opportunity for
  86 # memoization if further speed improvements are needed
  87 #
  88 # The way we construct this coderef is somewhat fugly, although the result is
  89 # really worth it. The final coderef does not perform any kind of recursion -
  90 # the entire nested structure constructor is rolled out into a single scope.
  91 #
  92 # In any case - the output of this thing is meticulously micro-tested, so
  93 # any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
  94 #
  95 sub _mk_row_parser {
  96   my ($self, $args) = @_;
  97
  98   my $val_index = { map
  99     { $args->{inflate_map}[$_] => $_ }
 100     ( 0 .. $#{$args->{inflate_map}} )
 101   };
 102
 103   my $src;
 104
 105   if (! $args->{collapse} ) {
 106     $src = assemble_simple_parser({
 107       val_index => $val_index,
 108       hri_style => $args->{hri_style},
 109     });
 110   }
 111   else {
 112     my $collapse_map = $self->_resolve_collapse ({
 113       premultiplied => $args->{premultiplied},
 114       # FIXME
 115       # only consider real columns (not functions) during collapse resolution
 116       # this check shouldn't really be here, as fucktards are not supposed to
 117       # alias random crap to existing column names anyway, but still - just in
 118       # case
 119       # FIXME !!!! - this does not yet deal with unbalanced selectors correctly
 120       # (it is now trivial as the attrs specify where things go out of sync
 121       # needs MOAR tests)
 122       as => { map
 123         { ref $args->{selection}[$val_index->{$_}] ? () : ( $_ => $val_index->{$_} ) }
 124         keys %$val_index
 125       }
 126     });
 127
 128     $src = assemble_collapsing_parser({
 129       val_index => $val_index,
 130       collapse_map => $collapse_map,
 131       hri_style => $args->{hri_style},
 132     });
 133   }
 134
 135   return $args->{eval}
 136     ? ( eval "sub { $src }" || die $@ )
 137     : $src
 138   ;
 139 }
 140
 141
 142 # Takes an arrayref selection list and generates a collapse-map representing
 143 # row-object fold-points. Every relationship is assigned a set of unique,
 144 # non-nullable columns (which may *not even be* from the same resultset)
 145 # and the collapser will use this information to correctly distinguish
 146 # data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
 147 # for extensive RV examples
 148 sub _resolve_collapse {
 149   my ($self, $args, $common_args) = @_;
 150
 151   # for comprehensible error messages put ourselves at the head of the relationship chain
 152   $args->{_rel_chain} ||= [ $self->source_name ];
 153
 154   # record top-level fully-qualified column index, signify toplevelness
 155   unless ($common_args->{_as_fq_idx}) {
 156     $common_args->{_as_fq_idx} = { %{$args->{as}} };
 157     $args->{_is_top_level} = 1;
 158   };
 159
 160   my ($my_cols, $rel_cols);
 161   for (keys %{$args->{as}}) {
 162     if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
 163       $rel_cols->{$1}{$2} = 1;
 164     }
 165     else {
 166       $my_cols->{$_} = {};  # important for ||='s below
 167     }
 168   }
 169
 170   my $relinfo;
 171   # run through relationships, collect metadata
 172   for my $rel (keys %$rel_cols) {
 173     my $inf = $self->relationship_info ($rel);
 174
 175     $relinfo->{$rel} = {
 176       is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
 177       is_inner => ( ( $inf->{attrs}{join_type} || '' ) !~ /^left/i),
 178       rsrc => $self->related_source($rel),
 179     };
 180
 181     # FIME - need to use _resolve_cond here instead
 182     my $cond = $inf->{cond};
 183
 184     if (
 185       ref $cond eq 'HASH'
 186         and
 187       keys %$cond
 188         and
 189       ! defined first { $_ !~ /^foreign\./ } (keys %$cond)
 190         and
 191       ! defined first { $_ !~ /^self\./ } (values %$cond)
 192     ) {
 193       for my $f (keys %$cond) {
 194         my $s = $cond->{$f};
 195         $_ =~ s/^ (?: foreign | self ) \.//x for ($f, $s);
 196         $relinfo->{$rel}{fk_map}{$s} = $f;
 197       }
 198     }
 199   }
 200
 201   # inject non-left fk-bridges from *INNER-JOINED* children (if any)
 202   for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
 203     my $ri = $relinfo->{$rel};
 204     for (keys %{$ri->{fk_map}} ) {
 205       # need to know source from *our* pov, hence $rel.col
 206       $my_cols->{$_} ||= { via_fk => "$rel.$ri->{fk_map}{$_}" }
 207         if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
 208     }
 209   }
 210
 211   # if the parent is already defined *AND* we have an inner reverse relationship
 212   # (i.e. do not exist without it) , assume all of its related FKs are selected
 213   # (even if they in fact are NOT in the select list). Keep a record of what we
 214   # assumed, and if any such phantom-column becomes part of our own collapser,
 215   # throw everything assumed-from-parent away and replace with the collapser of
 216   # the parent (whatever it may be)
 217   my $assumed_from_parent;
 218   if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
 219     for my $col ( values %{$args->{_parent_info}{rel_condition} || {}} ) {
 220       next if exists $my_cols->{$col};
 221       $my_cols->{$col} = { via_collapse => $args->{_parent_info}{collapse_on_idcols} };
 222       $assumed_from_parent->{columns}{$col}++;
 223     }
 224   }
 225
 226   # get colinfo for everything
 227   if ($my_cols) {
 228     my $ci = $self->columns_info;
 229     $my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
 230   }
 231
 232   my $collapse_map;
 233
 234   # first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
 235   # (makes for a leaner coderef later)
 236   unless ($collapse_map->{-identifying_columns}) {
 237     $collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
 238       if $args->{_parent_info}{collapser_reusable};
 239   }
 240
 241   # Still dont know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
 242   if (
 243     ! $collapse_map->{-identifying_columns}
 244       and
 245     $my_cols
 246       and
 247     my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
 248   ) {
 249     # see if the resulting collapser relies on any implied columns,
 250     # and fix stuff up if this is the case
 251     my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;
 252
 253     $collapse_map->{-identifying_columns} = [ __unique_numlist(
 254       @{ $args->{_parent_info}{collapse_on_idcols}||[] },
 255
 256       (map
 257         {
 258           my $fqc = join ('.',
 259             @{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
 260             ( $my_cols->{$_}{via_fk} || $_ ),
 261           );
 262
 263           $common_args->{_as_fq_idx}->{$fqc};
 264         }
 265         @reduced_set
 266       ),
 267     )];
 268   }
 269
 270   # Stil don't know how to collapse - keep descending down 1:1 chains - if
 271   # a related non-LEFT 1:1 is resolvable - its condition will collapse us
 272   # too
 273   unless ($collapse_map->{-identifying_columns}) {
 274     my @candidates;
 275
 276     for my $rel (keys %$relinfo) {
 277       next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
 278
 279       if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
 280         as => $rel_cols->{$rel},
 281         _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
 282         _parent_info => { underdefined => 1 },
 283       }, $common_args)) {
 284         push @candidates, $rel_collapse->{-identifying_columns};
 285       }
 286     }
 287
 288     # get the set with least amount of columns
 289     # FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
 290     # to a single varchar)
 291     if (@candidates) {
 292       ($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
 293     }
 294   }
 295
 296   # Stil don't know how to collapse, and we are the root node. Last ditch
 297   # effort in case we are *NOT* premultiplied.
 298   # Run through *each multi* all the way down, left or not, and all
 299   # *left* singles (a single may become a multi underneath) . When everything
 300   # gets back see if all the rels link to us definitively. If this is the
 301   # case we are good - either one of them will define us, or if all are NULLs
 302   # we know we are "unique" due to the "non-premultiplied" check
 303   if (
 304     ! $collapse_map->{-identifying_columns}
 305       and
 306     ! $args->{premultiplied}
 307       and
 308     $args->{_is_top_level}
 309   ) {
 310     my (@collapse_sets, $uncollapsible_chain);
 311
 312     for my $rel (keys %$relinfo) {
 313
 314       # we already looked at these higher up
 315       next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
 316
 317       if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
 318         as => $rel_cols->{$rel},
 319         _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
 320         _parent_info => { underdefined => 1 },
 321       }, $common_args) ) {
 322
 323         # for singles use the idcols wholesale (either there or not)
 324         if ($relinfo->{$rel}{is_single}) {
 325           push @collapse_sets, $clps->{-identifying_columns};
 326         }
 327         elsif (! $relinfo->{$rel}{fk_map}) {
 328           $uncollapsible_chain = 1;
 329           last;
 330         }
 331         else {
 332           my $defined_cols_parent_side;
 333
 334           for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
 335             my ($col) = $fq_col =~ /([^\.]+)$/;
 336
 337             $defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
 338               { $relinfo->{$rel}{fk_map}{$_} eq $col }
 339               keys %{$relinfo->{$rel}{fk_map}}
 340             ;
 341           }
 342
 343           if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
 344             push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
 345           }
 346           else {
 347             $uncollapsible_chain = 1;
 348             last;
 349           }
 350         }
 351       }
 352       else {
 353         $uncollapsible_chain = 1;
 354         last;
 355       }
 356     }
 357
 358     unless ($uncollapsible_chain) {
 359       # if we got here - we are good to go, but the construction is tricky
 360       # since our children will want to include our collapse criteria - we
 361       # don't give them anything (safe, since they are all collapsible on their own)
 362       # in addition we record the individual collapse posibilities
 363       # of all left children node collapsers, and merge them in the rowparser
 364       # coderef later
 365       $collapse_map->{-identifying_columns} = [];
 366       $collapse_map->{-identifying_columns_variants} = [ sort {
 367         (scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
 368       } @collapse_sets ];
 369     }
 370   }
 371
 372   # stop descending into children if we were called by a parent for first-pass
 373   # and don't despair if nothing was found (there may be other parallel branches
 374   # to dive into)
 375   if ($args->{_parent_info}{underdefined}) {
 376     return $collapse_map->{-identifying_columns} ? $collapse_map : undef
 377   }
 378   # nothing down the chain resolved - can't calculate a collapse-map
 379   elsif (! $collapse_map->{-identifying_columns}) {
 380     $self->throw_exception ( sprintf
 381       "Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
 382       $self->source_name,
 383       @{$args->{_rel_chain}} > 1
 384         ? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
 385         : ''
 386       ,
 387     );
 388   }
 389
 390   # If we got that far - we are collapsable - GREAT! Now go down all children
 391   # a second time, and fill in the rest
 392
 393   $collapse_map->{-identifying_columns} = [ __unique_numlist(
 394     @{ $args->{_parent_info}{collapse_on_idcols}||[] },
 395     @{ $collapse_map->{-identifying_columns} },
 396   )];
 397
 398   my @id_sets;
 399   for my $rel (sort keys %$relinfo) {
 400
 401     $collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
 402       as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
 403       _rel_chain => [ @{$args->{_rel_chain}}, $rel],
 404       _parent_info => {
 405         # shallow copy
 406         collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],
 407
 408         rel_condition => $relinfo->{$rel}{fk_map},
 409
 410         is_optional => ! $relinfo->{$rel}{is_inner},
 411
 412         # if there is at least one *inner* reverse relationship which is HASH-based (equality only)
 413         # we can safely assume that the child can not exist without us
 414         rev_rel_is_optional => ( first
 415           { ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}||'') !~ /^left/i }
 416           values %{ $self->reverse_relationship_info($rel) },
 417         ) ? 0 : 1,
 418
 419         # if this is a 1:1 our own collapser can be used as a collapse-map
 420         # (regardless of left or not)
 421         collapser_reusable => (
 422           $relinfo->{$rel}{is_single}
 423             &&
 424           $relinfo->{$rel}{is_inner}
 425             &&
 426           @{$collapse_map->{-identifying_columns}}
 427         ) ? 1 : 0,
 428       },
 429     }, $common_args );
 430
 431     $collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
 432     $collapse_map->{$rel}{-is_optional} ||= 1 unless $relinfo->{$rel}{is_inner};
 433   }
 434
 435   return $collapse_map;
 436 }
 437
 438 # adding a dep on MoreUtils *just* for this is retarded
 439 sub __unique_numlist {
 440   sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
 441 }
 442
 443 1;