lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799 #      warn "ARRAY: " . Dumper $subquery;
 800       $collapsed = $self->_collapse_query($subquery, $collapsed);
 801     }
 802   }
 803   elsif (ref $query eq 'HASH') {
 804     if (keys %$query and (keys %$query)[0] eq '-and') {
 805       foreach my $subquery (@{$query->{-and}}) {
 806 #        warn "HASH: " . Dumper $subquery;
 807         $collapsed = $self->_collapse_query($subquery, $collapsed);
 808       }
 809     }
 810     else {
 811 #      warn "LEAF: " . Dumper $query;
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 This method is deprecated and will be removed in 0.09. Use L</search()>
 864 instead. An example conversion is:
 865
 866   ->search_like({ foo => 'bar' });
 867
 868   # Becomes
 869
 870   ->search({ foo => { like => 'bar' } });
 871
 872 =cut
 873
 874 sub search_like {
 875   my $class = shift;
 876   carp join ("\n",
 877     'search_like() is deprecated and will be removed in 0.09.',
 878     'Instead use ->search({ x => { -like => "y%" } })',
 879     '(note the outer pair of {}s - they are important!)'
 880   );
 881   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 882   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 883   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 884   return $class->search($query, { %$attrs });
 885 }
 886
 887 =head2 slice
 888
 889 =over 4
 890
 891 =item Arguments: $first, $last
 892
 893 =item Return Value: $resultset (scalar context), @row_objs (list context)
 894
 895 =back
 896
 897 Returns a resultset or object list representing a subset of elements from the
 898 resultset slice is called on. Indexes are from 0, i.e., to get the first
 899 three records, call:
 900
 901   my ($one, $two, $three) = $rs->slice(0, 2);
 902
 903 =cut
 904
 905 sub slice {
 906   my ($self, $min, $max) = @_;
 907   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 908   $attrs->{offset} = $self->{attrs}{offset} || 0;
 909   $attrs->{offset} += $min;
 910   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 911   return $self->search(undef(), $attrs);
 912   #my $slice = (ref $self)->new($self->result_source, $attrs);
 913   #return (wantarray ? $slice->all : $slice);
 914 }
 915
 916 =head2 next
 917
 918 =over 4
 919
 920 =item Arguments: none
 921
 922 =item Return Value: $result?
 923
 924 =back
 925
 926 Returns the next element in the resultset (C<undef> is there is none).
 927
 928 Can be used to efficiently iterate over records in the resultset:
 929
 930   my $rs = $schema->resultset('CD')->search;
 931   while (my $cd = $rs->next) {
 932     print $cd->title;
 933   }
 934
 935 Note that you need to store the resultset object, and call C<next> on it.
 936 Calling C<< resultset('Table')->next >> repeatedly will always return the
 937 first record from the resultset.
 938
 939 =cut
 940
 941 sub next {
 942   my ($self) = @_;
 943   if (my $cache = $self->get_cache) {
 944     $self->{all_cache_position} ||= 0;
 945     return $cache->[$self->{all_cache_position}++];
 946   }
 947   if ($self->{attrs}{cache}) {
 948     $self->{all_cache_position} = 1;
 949     return ($self->all)[0];
 950   }
 951   if ($self->{stashed_objects}) {
 952     my $obj = shift(@{$self->{stashed_objects}});
 953     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 954     return $obj;
 955   }
 956   my @row = (
 957     exists $self->{stashed_row}
 958       ? @{delete $self->{stashed_row}}
 959       : $self->cursor->next
 960   );
 961   return undef unless (@row);
 962   my ($row, @more) = $self->_construct_object(@row);
 963   $self->{stashed_objects} = \@more if @more;
 964   return $row;
 965 }
 966
 967 sub _construct_object {
 968   my ($self, @row) = @_;
 969   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 970   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 971   @new = $self->{_attrs}{record_filter}->(@new)
 972     if exists $self->{_attrs}{record_filter};
 973   return @new;
 974 }
 975
 976 sub _collapse_result {
 977   my ($self, $as_proto, $row) = @_;
 978
 979   my @copy = @$row;
 980
 981   # 'foo'         => [ undef, 'foo' ]
 982   # 'foo.bar'     => [ 'foo', 'bar' ]
 983   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 984
 985   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 986
 987   my %collapse = %{$self->{_attrs}{collapse}||{}};
 988
 989   my @pri_index;
 990
 991   # if we're doing collapsing (has_many prefetch) we need to grab records
 992   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 993   # we know we don't have to bother.
 994
 995   # the reason for not using the collapse stuff directly is because if you
 996   # had for e.g. two artists in a row with no cds, the collapse info for
 997   # both would be NULL (undef) so you'd lose the second artist
 998
 999   # store just the index so we can check the array positions from the row
1000   # without having to contruct the full hash
1001
1002   if (keys %collapse) {
1003     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1004     foreach my $i (0 .. $#construct_as) {
1005       next if defined($construct_as[$i][0]); # only self table
1006       if (delete $pri{$construct_as[$i][1]}) {
1007         push(@pri_index, $i);
1008       }
1009       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1010     }
1011   }
1012
1013   # no need to do an if, it'll be empty if @pri_index is empty anyway
1014
1015   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1016
1017   my @const_rows;
1018
1019   do { # no need to check anything at the front, we always want the first row
1020
1021     my %const;
1022
1023     foreach my $this_as (@construct_as) {
1024       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1025     }
1026
1027     push(@const_rows, \%const);
1028
1029   } until ( # no pri_index => no collapse => drop straight out
1030       !@pri_index
1031     or
1032       do { # get another row, stash it, drop out if different PK
1033
1034         @copy = $self->cursor->next;
1035         $self->{stashed_row} = \@copy;
1036
1037         # last thing in do block, counts as true if anything doesn't match
1038
1039         # check xor defined first for NULL vs. NOT NULL then if one is
1040         # defined the other must be so check string equality
1041
1042         grep {
1043           (defined $pri_vals{$_} ^ defined $copy[$_])
1044           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1045         } @pri_index;
1046       }
1047   );
1048
1049   my $alias = $self->{attrs}{alias};
1050   my $info = [];
1051
1052   my %collapse_pos;
1053
1054   my @const_keys;
1055
1056   foreach my $const (@const_rows) {
1057     scalar @const_keys or do {
1058       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1059     };
1060     foreach my $key (@const_keys) {
1061       if (length $key) {
1062         my $target = $info;
1063         my @parts = split(/\./, $key);
1064         my $cur = '';
1065         my $data = $const->{$key};
1066         foreach my $p (@parts) {
1067           $target = $target->[1]->{$p} ||= [];
1068           $cur .= ".${p}";
1069           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1070             # collapsing at this point and on final part
1071             my $pos = $collapse_pos{$cur};
1072             CK: foreach my $ck (@ckey) {
1073               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1074                 $collapse_pos{$cur} = $data;
1075                 delete @collapse_pos{ # clear all positioning for sub-entries
1076                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1077                 };
1078                 push(@$target, []);
1079                 last CK;
1080               }
1081             }
1082           }
1083           if (exists $collapse{$cur}) {
1084             $target = $target->[-1];
1085           }
1086         }
1087         $target->[0] = $data;
1088       } else {
1089         $info->[0] = $const->{$key};
1090       }
1091     }
1092   }
1093
1094   return $info;
1095 }
1096
1097 =head2 result_source
1098
1099 =over 4
1100
1101 =item Arguments: $result_source?
1102
1103 =item Return Value: $result_source
1104
1105 =back
1106
1107 An accessor for the primary ResultSource object from which this ResultSet
1108 is derived.
1109
1110 =head2 result_class
1111
1112 =over 4
1113
1114 =item Arguments: $result_class?
1115
1116 =item Return Value: $result_class
1117
1118 =back
1119
1120 An accessor for the class to use when creating row objects. Defaults to
1121 C<< result_source->result_class >> - which in most cases is the name of the
1122 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1123
1124 =cut
1125
1126 sub result_class {
1127   my ($self, $result_class) = @_;
1128   if ($result_class) {
1129     $self->ensure_class_loaded($result_class);
1130     $self->_result_class($result_class);
1131   }
1132   $self->_result_class;
1133 }
1134
1135 =head2 count
1136
1137 =over 4
1138
1139 =item Arguments: $cond, \%attrs??
1140
1141 =item Return Value: $count
1142
1143 =back
1144
1145 Performs an SQL C<COUNT> with the same query as the resultset was built
1146 with to find the number of elements. If passed arguments, does a search
1147 on the resultset and counts the results of that.
1148
1149 =cut
1150
1151 sub count {
1152   my $self = shift;
1153   return $self->search(@_)->count if @_ and defined $_[0];
1154   return scalar @{ $self->get_cache } if $self->get_cache;
1155   my $count = $self->_count;
1156   return 0 unless $count;
1157
1158   # need to take offset from resolved attrs
1159
1160   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1161   $count = $self->{attrs}{rows} if
1162     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1163   $count = 0 if ($count < 0);
1164   return $count;
1165 }
1166
1167 sub _count { # Separated out so pager can get the full count
1168   my $self = shift;
1169   my $attrs = { %{$self->_resolved_attrs} };
1170
1171   if (my $group_by = $attrs->{group_by}) {
1172     delete $attrs->{order_by};
1173
1174     $attrs->{select} = $group_by;
1175     $attrs->{from} = [ { 'mesub' => (ref $self)->new($self->result_source, $attrs)->cursor->as_query } ];
1176     delete $attrs->{where};
1177   }
1178
1179   $attrs->{select} = { count => '*' };
1180   $attrs->{as} = [qw/count/];
1181
1182   # offset, order by, group by, where and page are not needed to count. record_filter is cdbi
1183   delete $attrs->{$_} for qw/rows offset order_by group_by page pager record_filter/;
1184
1185   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1186   my ($count) = $tmp_rs->cursor->next;
1187   return $count;
1188 }
1189
1190 sub _bool {
1191   return 1;
1192 }
1193
1194 =head2 count_literal
1195
1196 =over 4
1197
1198 =item Arguments: $sql_fragment, @bind_values
1199
1200 =item Return Value: $count
1201
1202 =back
1203
1204 Counts the results in a literal query. Equivalent to calling L</search_literal>
1205 with the passed arguments, then L</count>.
1206
1207 =cut
1208
1209 sub count_literal { shift->search_literal(@_)->count; }
1210
1211 =head2 all
1212
1213 =over 4
1214
1215 =item Arguments: none
1216
1217 =item Return Value: @objects
1218
1219 =back
1220
1221 Returns all elements in the resultset. Called implicitly if the resultset
1222 is returned in list context.
1223
1224 =cut
1225
1226 sub all {
1227   my $self = shift;
1228   if(@_) {
1229       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1230   }
1231
1232   return @{ $self->get_cache } if $self->get_cache;
1233
1234   my @obj;
1235
1236   # TODO: don't call resolve here
1237   if (keys %{$self->_resolved_attrs->{collapse}}) {
1238 #  if ($self->{attrs}{prefetch}) {
1239       # Using $self->cursor->all is really just an optimisation.
1240       # If we're collapsing has_many prefetches it probably makes
1241       # very little difference, and this is cleaner than hacking
1242       # _construct_object to survive the approach
1243     my @row = $self->cursor->next;
1244     while (@row) {
1245       push(@obj, $self->_construct_object(@row));
1246       @row = (exists $self->{stashed_row}
1247                ? @{delete $self->{stashed_row}}
1248                : $self->cursor->next);
1249     }
1250   } else {
1251     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1252   }
1253
1254   $self->set_cache(\@obj) if $self->{attrs}{cache};
1255   return @obj;
1256 }
1257
1258 =head2 reset
1259
1260 =over 4
1261
1262 =item Arguments: none
1263
1264 =item Return Value: $self
1265
1266 =back
1267
1268 Resets the resultset's cursor, so you can iterate through the elements again.
1269
1270 =cut
1271
1272 sub reset {
1273   my ($self) = @_;
1274   delete $self->{_attrs} if exists $self->{_attrs};
1275   $self->{all_cache_position} = 0;
1276   $self->cursor->reset;
1277   return $self;
1278 }
1279
1280 =head2 first
1281
1282 =over 4
1283
1284 =item Arguments: none
1285
1286 =item Return Value: $object?
1287
1288 =back
1289
1290 Resets the resultset and returns an object for the first result (if the
1291 resultset returns anything).
1292
1293 =cut
1294
1295 sub first {
1296   return $_[0]->reset->next;
1297 }
1298
1299 # _cond_for_update_delete
1300 #
1301 # update/delete require the condition to be modified to handle
1302 # the differing SQL syntax available.  This transforms the $self->{cond}
1303 # appropriately, returning the new condition.
1304
1305 sub _cond_for_update_delete {
1306   my ($self, $full_cond) = @_;
1307   my $cond = {};
1308
1309   $full_cond ||= $self->{cond};
1310   # No-op. No condition, we're updating/deleting everything
1311   return $cond unless ref $full_cond;
1312
1313   if (ref $full_cond eq 'ARRAY') {
1314     $cond = [
1315       map {
1316         my %hash;
1317         foreach my $key (keys %{$_}) {
1318           $key =~ /([^.]+)$/;
1319           $hash{$1} = $_->{$key};
1320         }
1321         \%hash;
1322       } @{$full_cond}
1323     ];
1324   }
1325   elsif (ref $full_cond eq 'HASH') {
1326     if ((keys %{$full_cond})[0] eq '-and') {
1327       $cond->{-and} = [];
1328
1329       my @cond = @{$full_cond->{-and}};
1330       for (my $i = 0; $i < @cond; $i++) {
1331         my $entry = $cond[$i];
1332
1333         my $hash;
1334         if (ref $entry eq 'HASH') {
1335           $hash = $self->_cond_for_update_delete($entry);
1336         }
1337         else {
1338           $entry =~ /([^.]+)$/;
1339           $hash->{$1} = $cond[++$i];
1340         }
1341
1342         push @{$cond->{-and}}, $hash;
1343       }
1344     }
1345     else {
1346       foreach my $key (keys %{$full_cond}) {
1347         $key =~ /([^.]+)$/;
1348         $cond->{$1} = $full_cond->{$key};
1349       }
1350     }
1351   }
1352   else {
1353     $self->throw_exception(
1354       "Can't update/delete on resultset with condition unless hash or array"
1355     );
1356   }
1357
1358   return $cond;
1359 }
1360
1361
1362 =head2 update
1363
1364 =over 4
1365
1366 =item Arguments: \%values
1367
1368 =item Return Value: $storage_rv
1369
1370 =back
1371
1372 Sets the specified columns in the resultset to the supplied values in a
1373 single query. Return value will be true if the update succeeded or false
1374 if no records were updated; exact type of success value is storage-dependent.
1375
1376 =cut
1377
1378 sub update {
1379   my ($self, $values) = @_;
1380   $self->throw_exception("Values for update must be a hash")
1381     unless ref $values eq 'HASH';
1382
1383   carp(   'WARNING! Currently $rs->update() does not generate proper SQL'
1384         . ' on joined resultsets, and may affect rows well outside of the'
1385         . ' contents of $rs. Use at your own risk' )
1386     if ( $self->{attrs}{seen_join} );
1387
1388   my $cond = $self->_cond_for_update_delete;
1389
1390   return $self->result_source->storage->update(
1391     $self->result_source, $values, $cond
1392   );
1393 }
1394
1395 =head2 update_all
1396
1397 =over 4
1398
1399 =item Arguments: \%values
1400
1401 =item Return Value: 1
1402
1403 =back
1404
1405 Fetches all objects and updates them one at a time. Note that C<update_all>
1406 will run DBIC cascade triggers, while L</update> will not.
1407
1408 =cut
1409
1410 sub update_all {
1411   my ($self, $values) = @_;
1412   $self->throw_exception("Values for update must be a hash")
1413     unless ref $values eq 'HASH';
1414   foreach my $obj ($self->all) {
1415     $obj->set_columns($values)->update;
1416   }
1417   return 1;
1418 }
1419
1420 =head2 delete
1421
1422 =over 4
1423
1424 =item Arguments: none
1425
1426 =item Return Value: 1
1427
1428 =back
1429
1430 Deletes the contents of the resultset from its result source. Note that this
1431 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1432 to run. See also L<DBIx::Class::Row/delete>.
1433
1434 delete may not generate correct SQL for a query with joins or a resultset
1435 chained from a related resultset.  In this case it will generate a warning:-
1436
1437   WARNING! Currently $rs->delete() does not generate proper SQL on
1438   joined resultsets, and may delete rows well outside of the contents
1439   of $rs. Use at your own risk
1440
1441 In these cases you may find that delete_all is more appropriate, or you
1442 need to respecify your query in a way that can be expressed without a join.
1443
1444 =cut
1445
1446 sub delete {
1447   my ($self) = @_;
1448   $self->throw_exception("Delete should not be passed any arguments")
1449     if $_[1];
1450   carp(   'WARNING! Currently $rs->delete() does not generate proper SQL'
1451         . ' on joined resultsets, and may delete rows well outside of the'
1452         . ' contents of $rs. Use at your own risk' )
1453     if ( $self->{attrs}{seen_join} );
1454   my $cond = $self->_cond_for_update_delete;
1455
1456   $self->result_source->storage->delete($self->result_source, $cond);
1457   return 1;
1458 }
1459
1460 =head2 delete_all
1461
1462 =over 4
1463
1464 =item Arguments: none
1465
1466 =item Return Value: 1
1467
1468 =back
1469
1470 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1471 will run DBIC cascade triggers, while L</delete> will not.
1472
1473 =cut
1474
1475 sub delete_all {
1476   my ($self) = @_;
1477   $_->delete for $self->all;
1478   return 1;
1479 }
1480
1481 =head2 populate
1482
1483 =over 4
1484
1485 =item Arguments: \@data;
1486
1487 =back
1488
1489 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1490 For the arrayref of hashrefs style each hashref should be a structure suitable
1491 forsubmitting to a $resultset->create(...) method.
1492
1493 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1494 to insert the data, as this is a faster method.
1495
1496 Otherwise, each set of data is inserted into the database using
1497 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1498 objects is returned.
1499
1500 Example:  Assuming an Artist Class that has many CDs Classes relating:
1501
1502   my $Artist_rs = $schema->resultset("Artist");
1503
1504   ## Void Context Example
1505   $Artist_rs->populate([
1506      { artistid => 4, name => 'Manufactured Crap', cds => [
1507         { title => 'My First CD', year => 2006 },
1508         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1509       ],
1510      },
1511      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1512         { title => 'My parents sold me to a record company' ,year => 2005 },
1513         { title => 'Why Am I So Ugly?', year => 2006 },
1514         { title => 'I Got Surgery and am now Popular', year => 2007 }
1515       ],
1516      },
1517   ]);
1518
1519   ## Array Context Example
1520   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1521     { name => "Artist One"},
1522     { name => "Artist Two"},
1523     { name => "Artist Three", cds=> [
1524     { title => "First CD", year => 2007},
1525     { title => "Second CD", year => 2008},
1526   ]}
1527   ]);
1528
1529   print $ArtistOne->name; ## response is 'Artist One'
1530   print $ArtistThree->cds->count ## reponse is '2'
1531
1532 For the arrayref of arrayrefs style,  the first element should be a list of the
1533 fieldsnames to which the remaining elements are rows being inserted.  For
1534 example:
1535
1536   $Arstist_rs->populate([
1537     [qw/artistid name/],
1538     [100, 'A Formally Unknown Singer'],
1539     [101, 'A singer that jumped the shark two albums ago'],
1540     [102, 'An actually cool singer.'],
1541   ]);
1542
1543 Please note an important effect on your data when choosing between void and
1544 wantarray context. Since void context goes straight to C<insert_bulk> in
1545 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1546 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1547 create primary keys for you, you will find that your PKs are empty.  In this
1548 case you will have to use the wantarray context in order to create those
1549 values.
1550
1551 =cut
1552
1553 sub populate {
1554   my $self = shift @_;
1555   my $data = ref $_[0][0] eq 'HASH'
1556     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1557     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1558
1559   if(defined wantarray) {
1560     my @created;
1561     foreach my $item (@$data) {
1562       push(@created, $self->create($item));
1563     }
1564     return @created;
1565   } else {
1566     my ($first, @rest) = @$data;
1567
1568     my @names = grep {!ref $first->{$_}} keys %$first;
1569     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1570     my @pks = $self->result_source->primary_columns;
1571
1572     ## do the belongs_to relationships
1573     foreach my $index (0..$#$data) {
1574       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1575         my @ret = $self->populate($data);
1576         return;
1577       }
1578
1579       foreach my $rel (@rels) {
1580         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1581         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1582         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1583         my $related = $result->result_source->resolve_condition(
1584           $result->result_source->relationship_info($reverse)->{cond},
1585           $self,
1586           $result,
1587         );
1588
1589         delete $data->[$index]->{$rel};
1590         $data->[$index] = {%{$data->[$index]}, %$related};
1591
1592         push @names, keys %$related if $index == 0;
1593       }
1594     }
1595
1596     ## do bulk insert on current row
1597     my @values = map { [ @$_{@names} ] } @$data;
1598
1599     $self->result_source->storage->insert_bulk(
1600       $self->result_source,
1601       \@names,
1602       \@values,
1603     );
1604
1605     ## do the has_many relationships
1606     foreach my $item (@$data) {
1607
1608       foreach my $rel (@rels) {
1609         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1610
1611         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1612      || $self->throw_exception('Cannot find the relating object.');
1613
1614         my $child = $parent->$rel;
1615
1616         my $related = $child->result_source->resolve_condition(
1617           $parent->result_source->relationship_info($rel)->{cond},
1618           $child,
1619           $parent,
1620         );
1621
1622         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1623         my @populate = map { {%$_, %$related} } @rows_to_add;
1624
1625         $child->populate( \@populate );
1626       }
1627     }
1628   }
1629 }
1630
1631 =head2 _normalize_populate_args ($args)
1632
1633 Private method used by L</populate> to normalize its incoming arguments.  Factored
1634 out in case you want to subclass and accept new argument structures to the
1635 L</populate> method.
1636
1637 =cut
1638
1639 sub _normalize_populate_args {
1640   my ($self, $data) = @_;
1641   my @names = @{shift(@$data)};
1642   my @results_to_create;
1643   foreach my $datum (@$data) {
1644     my %result_to_create;
1645     foreach my $index (0..$#names) {
1646       $result_to_create{$names[$index]} = $$datum[$index];
1647     }
1648     push @results_to_create, \%result_to_create;
1649   }
1650   return \@results_to_create;
1651 }
1652
1653 =head2 pager
1654
1655 =over 4
1656
1657 =item Arguments: none
1658
1659 =item Return Value: $pager
1660
1661 =back
1662
1663 Return Value a L<Data::Page> object for the current resultset. Only makes
1664 sense for queries with a C<page> attribute.
1665
1666 To get the full count of entries for a paged resultset, call
1667 C<total_entries> on the L<Data::Page> object.
1668
1669 =cut
1670
1671 sub pager {
1672   my ($self) = @_;
1673   my $attrs = $self->{attrs};
1674   $self->throw_exception("Can't create pager for non-paged rs")
1675     unless $self->{attrs}{page};
1676   $attrs->{rows} ||= 10;
1677   return $self->{pager} ||= Data::Page->new(
1678     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1679 }
1680
1681 =head2 page
1682
1683 =over 4
1684
1685 =item Arguments: $page_number
1686
1687 =item Return Value: $rs
1688
1689 =back
1690
1691 Returns a resultset for the $page_number page of the resultset on which page
1692 is called, where each page contains a number of rows equal to the 'rows'
1693 attribute set on the resultset (10 by default).
1694
1695 =cut
1696
1697 sub page {
1698   my ($self, $page) = @_;
1699   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1700 }
1701
1702 =head2 new_result
1703
1704 =over 4
1705
1706 =item Arguments: \%vals
1707
1708 =item Return Value: $rowobject
1709
1710 =back
1711
1712 Creates a new row object in the resultset's result class and returns
1713 it. The row is not inserted into the database at this point, call
1714 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1715 will tell you whether the row object has been inserted or not.
1716
1717 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1718
1719 =cut
1720
1721 sub new_result {
1722   my ($self, $values) = @_;
1723   $self->throw_exception( "new_result needs a hash" )
1724     unless (ref $values eq 'HASH');
1725
1726   my %new;
1727   my $alias = $self->{attrs}{alias};
1728
1729   if (
1730     defined $self->{cond}
1731     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1732   ) {
1733     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1734     $new{-from_resultset} = [ keys %new ] if keys %new;
1735   } else {
1736     $self->throw_exception(
1737       "Can't abstract implicit construct, condition not a hash"
1738     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1739
1740     my $collapsed_cond = (
1741       $self->{cond}
1742         ? $self->_collapse_cond($self->{cond})
1743         : {}
1744     );
1745
1746     # precendence must be given to passed values over values inherited from
1747     # the cond, so the order here is important.
1748     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1749     while( my($col,$value) = each %implied ){
1750       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1751         $new{$col} = $value->{'='};
1752         next;
1753       }
1754       $new{$col} = $value if $self->_is_deterministic_value($value);
1755     }
1756   }
1757
1758   %new = (
1759     %new,
1760     %{ $self->_remove_alias($values, $alias) },
1761     -source_handle => $self->_source_handle,
1762     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1763   );
1764
1765   return $self->result_class->new(\%new);
1766 }
1767
1768 # _is_deterministic_value
1769 #
1770 # Make an effor to strip non-deterministic values from the condition,
1771 # to make sure new_result chokes less
1772
1773 sub _is_deterministic_value {
1774   my $self = shift;
1775   my $value = shift;
1776   my $ref_type = ref $value;
1777   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1778   return 1 if Scalar::Util::blessed($value);
1779   return 0;
1780 }
1781
1782 # _collapse_cond
1783 #
1784 # Recursively collapse the condition.
1785
1786 sub _collapse_cond {
1787   my ($self, $cond, $collapsed) = @_;
1788
1789   $collapsed ||= {};
1790
1791   if (ref $cond eq 'ARRAY') {
1792     foreach my $subcond (@$cond) {
1793       next unless ref $subcond;  # -or
1794 #      warn "ARRAY: " . Dumper $subcond;
1795       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1796     }
1797   }
1798   elsif (ref $cond eq 'HASH') {
1799     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1800       foreach my $subcond (@{$cond->{-and}}) {
1801 #        warn "HASH: " . Dumper $subcond;
1802         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1803       }
1804     }
1805     else {
1806 #      warn "LEAF: " . Dumper $cond;
1807       foreach my $col (keys %$cond) {
1808         my $value = $cond->{$col};
1809         $collapsed->{$col} = $value;
1810       }
1811     }
1812   }
1813
1814   return $collapsed;
1815 }
1816
1817 # _remove_alias
1818 #
1819 # Remove the specified alias from the specified query hash. A copy is made so
1820 # the original query is not modified.
1821
1822 sub _remove_alias {
1823   my ($self, $query, $alias) = @_;
1824
1825   my %orig = %{ $query || {} };
1826   my %unaliased;
1827
1828   foreach my $key (keys %orig) {
1829     if ($key !~ /\./) {
1830       $unaliased{$key} = $orig{$key};
1831       next;
1832     }
1833     $unaliased{$1} = $orig{$key}
1834       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1835   }
1836
1837   return \%unaliased;
1838 }
1839
1840 =head2 as_query (EXPERIMENTAL)
1841
1842 =over 4
1843
1844 =item Arguments: none
1845
1846 =item Return Value: \[ $sql, @bind ]
1847
1848 =back
1849
1850 Returns the SQL query and bind vars associated with the invocant.
1851
1852 This is generally used as the RHS for a subquery.
1853
1854 B<NOTE>: This feature is still experimental.
1855
1856 =cut
1857
1858 sub as_query { return shift->cursor->as_query(@_) }
1859
1860 =head2 find_or_new
1861
1862 =over 4
1863
1864 =item Arguments: \%vals, \%attrs?
1865
1866 =item Return Value: $rowobject
1867
1868 =back
1869
1870   my $artist = $schema->resultset('Artist')->find_or_new(
1871     { artist => 'fred' }, { key => 'artists' });
1872
1873   $cd->cd_to_producer->find_or_new({ producer => $producer },
1874                                    { key => 'primary });
1875
1876 Find an existing record from this resultset, based on its primary
1877 key, or a unique constraint. If none exists, instantiate a new result
1878 object and return it. The object will not be saved into your storage
1879 until you call L<DBIx::Class::Row/insert> on it.
1880
1881 You most likely want this method when looking for existing rows using
1882 a unique constraint that is not the primary key, or looking for
1883 related rows.
1884
1885 If you want objects to be saved immediately, use L</find_or_create> instead.
1886
1887 B<Note>: C<find_or_new> is probably not what you want when creating a
1888 new row in a table that uses primary keys supplied by the
1889 database. Passing in a primary key column with a value of I<undef>
1890 will cause L</find> to attempt to search for a row with a value of
1891 I<NULL>.
1892
1893 =cut
1894
1895 sub find_or_new {
1896   my $self     = shift;
1897   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1898   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1899   my $exists   = $self->find($hash, $attrs);
1900   return defined $exists ? $exists : $self->new_result($hash);
1901 }
1902
1903 =head2 create
1904
1905 =over 4
1906
1907 =item Arguments: \%vals
1908
1909 =item Return Value: a L<DBIx::Class::Row> $object
1910
1911 =back
1912
1913 Attempt to create a single new row or a row with multiple related rows
1914 in the table represented by the resultset (and related tables). This
1915 will not check for duplicate rows before inserting, use
1916 L</find_or_create> to do that.
1917
1918 To create one row for this resultset, pass a hashref of key/value
1919 pairs representing the columns of the table and the values you wish to
1920 store. If the appropriate relationships are set up, foreign key fields
1921 can also be passed an object representing the foreign row, and the
1922 value will be set to its primary key.
1923
1924 To create related objects, pass a hashref for the value if the related
1925 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1926 and use the name of the relationship as the key. (NOT the name of the field,
1927 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1928 of hashrefs containing the data for each of the rows to create in the foreign
1929 tables, again using the relationship name as the key.
1930
1931 Instead of hashrefs of plain related data (key/value pairs), you may
1932 also pass new or inserted objects. New objects (not inserted yet, see
1933 L</new>), will be inserted into their appropriate tables.
1934
1935 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1936
1937 Example of creating a new row.
1938
1939   $person_rs->create({
1940     name=>"Some Person",
1941     email=>"somebody@someplace.com"
1942   });
1943
1944 Example of creating a new row and also creating rows in a related C<has_many>
1945 or C<has_one> resultset.  Note Arrayref.
1946
1947   $artist_rs->create(
1948      { artistid => 4, name => 'Manufactured Crap', cds => [
1949         { title => 'My First CD', year => 2006 },
1950         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1951       ],
1952      },
1953   );
1954
1955 Example of creating a new row and also creating a row in a related
1956 C<belongs_to>resultset. Note Hashref.
1957
1958   $cd_rs->create({
1959     title=>"Music for Silly Walks",
1960     year=>2000,
1961     artist => {
1962       name=>"Silly Musician",
1963     }
1964   });
1965
1966 =cut
1967
1968 sub create {
1969   my ($self, $attrs) = @_;
1970   $self->throw_exception( "create needs a hashref" )
1971     unless ref $attrs eq 'HASH';
1972   return $self->new_result($attrs)->insert;
1973 }
1974
1975 =head2 find_or_create
1976
1977 =over 4
1978
1979 =item Arguments: \%vals, \%attrs?
1980
1981 =item Return Value: $rowobject
1982
1983 =back
1984
1985   $cd->cd_to_producer->find_or_create({ producer => $producer },
1986                                       { key => 'primary });
1987
1988 Tries to find a record based on its primary key or unique constraints; if none
1989 is found, creates one and returns that instead.
1990
1991   my $cd = $schema->resultset('CD')->find_or_create({
1992     cdid   => 5,
1993     artist => 'Massive Attack',
1994     title  => 'Mezzanine',
1995     year   => 2005,
1996   });
1997
1998 Also takes an optional C<key> attribute, to search by a specific key or unique
1999 constraint. For example:
2000
2001   my $cd = $schema->resultset('CD')->find_or_create(
2002     {
2003       artist => 'Massive Attack',
2004       title  => 'Mezzanine',
2005     },
2006     { key => 'cd_artist_title' }
2007   );
2008
2009 B<Note>: Because find_or_create() reads from the database and then
2010 possibly inserts based on the result, this method is subject to a race
2011 condition. Another process could create a record in the table after
2012 the find has completed and before the create has started. To avoid
2013 this problem, use find_or_create() inside a transaction.
2014
2015 B<Note>: C<find_or_create> is probably not what you want when creating
2016 a new row in a table that uses primary keys supplied by the
2017 database. Passing in a primary key column with a value of I<undef>
2018 will cause L</find> to attempt to search for a row with a value of
2019 I<NULL>.
2020
2021 See also L</find> and L</update_or_create>. For information on how to declare
2022 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2023
2024 =cut
2025
2026 sub find_or_create {
2027   my $self     = shift;
2028   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2029   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2030   my $exists   = $self->find($hash, $attrs);
2031   return defined $exists ? $exists : $self->create($hash);
2032 }
2033
2034 =head2 update_or_create
2035
2036 =over 4
2037
2038 =item Arguments: \%col_values, { key => $unique_constraint }?
2039
2040 =item Return Value: $rowobject
2041
2042 =back
2043
2044   $resultset->update_or_create({ col => $val, ... });
2045
2046 First, searches for an existing row matching one of the unique constraints
2047 (including the primary key) on the source of this resultset. If a row is
2048 found, updates it with the other given column values. Otherwise, creates a new
2049 row.
2050
2051 Takes an optional C<key> attribute to search on a specific unique constraint.
2052 For example:
2053
2054   # In your application
2055   my $cd = $schema->resultset('CD')->update_or_create(
2056     {
2057       artist => 'Massive Attack',
2058       title  => 'Mezzanine',
2059       year   => 1998,
2060     },
2061     { key => 'cd_artist_title' }
2062   );
2063
2064   $cd->cd_to_producer->update_or_create({
2065     producer => $producer,
2066     name => 'harry',
2067   }, {
2068     key => 'primary,
2069   });
2070
2071
2072 If no C<key> is specified, it searches on all unique constraints defined on the
2073 source, including the primary key.
2074
2075 If the C<key> is specified as C<primary>, it searches only on the primary key.
2076
2077 See also L</find> and L</find_or_create>. For information on how to declare
2078 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2079
2080 B<Note>: C<update_or_create> is probably not what you want when
2081 looking for a row in a table that uses primary keys supplied by the
2082 database, unless you actually have a key value. Passing in a primary
2083 key column with a value of I<undef> will cause L</find> to attempt to
2084 search for a row with a value of I<NULL>.
2085
2086 =cut
2087
2088 sub update_or_create {
2089   my $self = shift;
2090   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2091   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2092
2093   my $row = $self->find($cond, $attrs);
2094   if (defined $row) {
2095     $row->update($cond);
2096     return $row;
2097   }
2098
2099   return $self->create($cond);
2100 }
2101
2102 =head2 update_or_new
2103
2104 =over 4
2105
2106 =item Arguments: \%col_values, { key => $unique_constraint }?
2107
2108 =item Return Value: $rowobject
2109
2110 =back
2111
2112   $resultset->update_or_new({ col => $val, ... });
2113
2114 First, searches for an existing row matching one of the unique constraints
2115 (including the primary key) on the source of this resultset. If a row is
2116 found, updates it with the other given column values. Otherwise, instantiate
2117 a new result object and return it. The object will not be saved into your storage
2118 until you call L<DBIx::Class::Row/insert> on it.
2119
2120 Takes an optional C<key> attribute to search on a specific unique constraint.
2121 For example:
2122
2123   # In your application
2124   my $cd = $schema->resultset('CD')->update_or_new(
2125     {
2126       artist => 'Massive Attack',
2127       title  => 'Mezzanine',
2128       year   => 1998,
2129     },
2130     { key => 'cd_artist_title' }
2131   );
2132
2133   if ($cd->in_storage) {
2134       # the cd was updated
2135   }
2136   else {
2137       # the cd is not yet in the database, let's insert it
2138       $cd->insert;
2139   }
2140
2141 See also L</find>, L</find_or_create> and L<find_or_new>.
2142
2143 =cut
2144
2145 sub update_or_new {
2146     my $self  = shift;
2147     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2148     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2149
2150     my $row = $self->find( $cond, $attrs );
2151     if ( defined $row ) {
2152         $row->update($cond);
2153         return $row;
2154     }
2155
2156     return $self->new_result($cond);
2157 }
2158
2159 =head2 get_cache
2160
2161 =over 4
2162
2163 =item Arguments: none
2164
2165 =item Return Value: \@cache_objects?
2166
2167 =back
2168
2169 Gets the contents of the cache for the resultset, if the cache is set.
2170
2171 The cache is populated either by using the L</prefetch> attribute to
2172 L</search> or by calling L</set_cache>.
2173
2174 =cut
2175
2176 sub get_cache {
2177   shift->{all_cache};
2178 }
2179
2180 =head2 set_cache
2181
2182 =over 4
2183
2184 =item Arguments: \@cache_objects
2185
2186 =item Return Value: \@cache_objects
2187
2188 =back
2189
2190 Sets the contents of the cache for the resultset. Expects an arrayref
2191 of objects of the same class as those produced by the resultset. Note that
2192 if the cache is set the resultset will return the cached objects rather
2193 than re-querying the database even if the cache attr is not set.
2194
2195 The contents of the cache can also be populated by using the
2196 L</prefetch> attribute to L</search>.
2197
2198 =cut
2199
2200 sub set_cache {
2201   my ( $self, $data ) = @_;
2202   $self->throw_exception("set_cache requires an arrayref")
2203       if defined($data) && (ref $data ne 'ARRAY');
2204   $self->{all_cache} = $data;
2205 }
2206
2207 =head2 clear_cache
2208
2209 =over 4
2210
2211 =item Arguments: none
2212
2213 =item Return Value: []
2214
2215 =back
2216
2217 Clears the cache for the resultset.
2218
2219 =cut
2220
2221 sub clear_cache {
2222   shift->set_cache(undef);
2223 }
2224
2225 =head2 related_resultset
2226
2227 =over 4
2228
2229 =item Arguments: $relationship_name
2230
2231 =item Return Value: $resultset
2232
2233 =back
2234
2235 Returns a related resultset for the supplied relationship name.
2236
2237   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2238
2239 =cut
2240
2241 sub related_resultset {
2242   my ($self, $rel) = @_;
2243
2244   $self->{related_resultsets} ||= {};
2245   return $self->{related_resultsets}{$rel} ||= do {
2246     my $rel_obj = $self->result_source->relationship_info($rel);
2247
2248     $self->throw_exception(
2249       "search_related: result source '" . $self->result_source->source_name .
2250         "' has no such relationship $rel")
2251       unless $rel_obj;
2252
2253     my ($from,$seen) = $self->_resolve_from($rel);
2254
2255     my $join_count = $seen->{$rel};
2256     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2257
2258     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2259     my %attrs = %{$self->{attrs}||{}};
2260     delete @attrs{qw(result_class alias)};
2261
2262     my $new_cache;
2263
2264     if (my $cache = $self->get_cache) {
2265       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2266         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2267                         @$cache ];
2268       }
2269     }
2270
2271     my $rel_source = $self->result_source->related_source($rel);
2272
2273     my $new = do {
2274
2275       # The reason we do this now instead of passing the alias to the
2276       # search_rs below is that if you wrap/overload resultset on the
2277       # source you need to know what alias it's -going- to have for things
2278       # to work sanely (e.g. RestrictWithObject wants to be able to add
2279       # extra query restrictions, and these may need to be $alias.)
2280
2281       my $attrs = $rel_source->resultset_attributes;
2282       local $attrs->{alias} = $alias;
2283
2284       $rel_source->resultset
2285                  ->search_rs(
2286                      undef, {
2287                        %attrs,
2288                        join => undef,
2289                        prefetch => undef,
2290                        select => undef,
2291                        as => undef,
2292                        where => $self->{cond},
2293                        seen_join => $seen,
2294                        from => $from,
2295                    });
2296     };
2297     $new->set_cache($new_cache) if $new_cache;
2298     $new;
2299   };
2300 }
2301
2302 =head2 current_source_alias
2303
2304 =over 4
2305
2306 =item Arguments: none
2307
2308 =item Return Value: $source_alias
2309
2310 =back
2311
2312 Returns the current table alias for the result source this resultset is built
2313 on, that will be used in the SQL query. Usually it is C<me>.
2314
2315 Currently the source alias that refers to the result set returned by a
2316 L</search>/L</find> family method depends on how you got to the resultset: it's
2317 C<me> by default, but eg. L</search_related> aliases it to the related result
2318 source name (and keeps C<me> referring to the original result set). The long
2319 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2320 (and make this method unnecessary).
2321
2322 Thus it's currently necessary to use this method in predefined queries (see
2323 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2324 source alias of the current result set:
2325
2326   # in a result set class
2327   sub modified_by {
2328     my ($self, $user) = @_;
2329
2330     my $me = $self->current_source_alias;
2331
2332     return $self->search(
2333       "$me.modified" => $user->id,
2334     );
2335   }
2336
2337 =cut
2338
2339 sub current_source_alias {
2340   my ($self) = @_;
2341
2342   return ($self->{attrs} || {})->{alias} || 'me';
2343 }
2344
2345 sub _resolve_from {
2346   my ($self, $extra_join) = @_;
2347   my $source = $self->result_source;
2348   my $attrs = $self->{attrs};
2349
2350   my $from = $attrs->{from}
2351     || [ { $attrs->{alias} => $source->from } ];
2352
2353   my $seen = { %{$attrs->{seen_join}||{}} };
2354
2355   my $join = ($attrs->{join}
2356                ? [ $attrs->{join}, $extra_join ]
2357                : $extra_join);
2358
2359   # we need to take the prefetch the attrs into account before we
2360   # ->resolve_join as otherwise they get lost - captainL
2361   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2362
2363   $from = [
2364     @$from,
2365     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2366   ];
2367
2368   return ($from,$seen);
2369 }
2370
2371 sub _resolved_attrs {
2372   my $self = shift;
2373   return $self->{_attrs} if $self->{_attrs};
2374
2375   my $attrs  = { %{ $self->{attrs} || {} } };
2376   my $source = $self->result_source;
2377   my $alias  = $attrs->{alias};
2378
2379   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2380   my @colbits;
2381
2382   # build columns (as long as select isn't set) into a set of as/select hashes
2383   unless ( $attrs->{select} ) {
2384       @colbits = map {
2385           ( ref($_) eq 'HASH' ) ? $_
2386             : {
2387               (
2388                   /^\Q${alias}.\E(.+)$/ ? $1
2389                   : $_
2390                 ) => ( /\./ ? $_ : "${alias}.$_" )
2391             }
2392       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2393   }
2394   # add the additional columns on
2395   foreach ( 'include_columns', '+columns' ) {
2396       push @colbits, map {
2397           ( ref($_) eq 'HASH' )
2398             ? $_
2399             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2400       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2401   }
2402
2403   # start with initial select items
2404   if ( $attrs->{select} ) {
2405     $attrs->{select} =
2406         ( ref $attrs->{select} eq 'ARRAY' )
2407       ? [ @{ $attrs->{select} } ]
2408       : [ $attrs->{select} ];
2409     $attrs->{as} = (
2410       $attrs->{as}
2411       ? (
2412         ref $attrs->{as} eq 'ARRAY'
2413         ? [ @{ $attrs->{as} } ]
2414         : [ $attrs->{as} ]
2415         )
2416       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2417     );
2418   }
2419   else {
2420
2421     # otherwise we intialise select & as to empty
2422     $attrs->{select} = [];
2423     $attrs->{as}     = [];
2424   }
2425
2426   # now add colbits to select/as
2427   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2428   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2429
2430   my $adds;
2431   if ( $adds = delete $attrs->{'+select'} ) {
2432     $adds = [$adds] unless ref $adds eq 'ARRAY';
2433     push(
2434       @{ $attrs->{select} },
2435       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2436     );
2437   }
2438   if ( $adds = delete $attrs->{'+as'} ) {
2439     $adds = [$adds] unless ref $adds eq 'ARRAY';
2440     push( @{ $attrs->{as} }, @$adds );
2441   }
2442
2443   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2444
2445   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2446     my $join = delete $attrs->{join} || {};
2447
2448     if ( defined $attrs->{prefetch} ) {
2449       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2450
2451     }
2452
2453     $attrs->{from} =    # have to copy here to avoid corrupting the original
2454       [
2455       @{ $attrs->{from} },
2456       $source->resolve_join(
2457         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2458       )
2459       ];
2460
2461   }
2462
2463   $attrs->{group_by} ||= $attrs->{select}
2464     if delete $attrs->{distinct};
2465   if ( $attrs->{order_by} ) {
2466     $attrs->{order_by} = (
2467       ref( $attrs->{order_by} ) eq 'ARRAY'
2468       ? [ @{ $attrs->{order_by} } ]
2469       : [ $attrs->{order_by} ]
2470     );
2471   }
2472   else {
2473     $attrs->{order_by} = [];
2474   }
2475
2476   my $collapse = $attrs->{collapse} || {};
2477   if ( my $prefetch = delete $attrs->{prefetch} ) {
2478     $prefetch = $self->_merge_attr( {}, $prefetch );
2479     my @pre_order;
2480     my $seen = { %{ $attrs->{seen_join} || {} } };
2481     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2482
2483       # bring joins back to level of current class
2484       my @prefetch =
2485         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2486       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2487       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2488     }
2489     push( @{ $attrs->{order_by} }, @pre_order );
2490   }
2491   $attrs->{collapse} = $collapse;
2492
2493   if ( $attrs->{page} ) {
2494     $attrs->{offset} ||= 0;
2495     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2496   }
2497
2498   return $self->{_attrs} = $attrs;
2499 }
2500
2501 sub _rollout_attr {
2502   my ($self, $attr) = @_;
2503
2504   if (ref $attr eq 'HASH') {
2505     return $self->_rollout_hash($attr);
2506   } elsif (ref $attr eq 'ARRAY') {
2507     return $self->_rollout_array($attr);
2508   } else {
2509     return [$attr];
2510   }
2511 }
2512
2513 sub _rollout_array {
2514   my ($self, $attr) = @_;
2515
2516   my @rolled_array;
2517   foreach my $element (@{$attr}) {
2518     if (ref $element eq 'HASH') {
2519       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2520     } elsif (ref $element eq 'ARRAY') {
2521       #  XXX - should probably recurse here
2522       push( @rolled_array, @{$self->_rollout_array($element)} );
2523     } else {
2524       push( @rolled_array, $element );
2525     }
2526   }
2527   return \@rolled_array;
2528 }
2529
2530 sub _rollout_hash {
2531   my ($self, $attr) = @_;
2532
2533   my @rolled_array;
2534   foreach my $key (keys %{$attr}) {
2535     push( @rolled_array, { $key => $attr->{$key} } );
2536   }
2537   return \@rolled_array;
2538 }
2539
2540 sub _calculate_score {
2541   my ($self, $a, $b) = @_;
2542
2543   if (ref $b eq 'HASH') {
2544     my ($b_key) = keys %{$b};
2545     if (ref $a eq 'HASH') {
2546       my ($a_key) = keys %{$a};
2547       if ($a_key eq $b_key) {
2548         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2549       } else {
2550         return 0;
2551       }
2552     } else {
2553       return ($a eq $b_key) ? 1 : 0;
2554     }
2555   } else {
2556     if (ref $a eq 'HASH') {
2557       my ($a_key) = keys %{$a};
2558       return ($b eq $a_key) ? 1 : 0;
2559     } else {
2560       return ($b eq $a) ? 1 : 0;
2561     }
2562   }
2563 }
2564
2565 sub _merge_attr {
2566   my ($self, $orig, $import) = @_;
2567
2568   return $import unless defined($orig);
2569   return $orig unless defined($import);
2570
2571   $orig = $self->_rollout_attr($orig);
2572   $import = $self->_rollout_attr($import);
2573
2574   my $seen_keys;
2575   foreach my $import_element ( @{$import} ) {
2576     # find best candidate from $orig to merge $b_element into
2577     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2578     foreach my $orig_element ( @{$orig} ) {
2579       my $score = $self->_calculate_score( $orig_element, $import_element );
2580       if ($score > $best_candidate->{score}) {
2581         $best_candidate->{position} = $position;
2582         $best_candidate->{score} = $score;
2583       }
2584       $position++;
2585     }
2586     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2587
2588     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2589       push( @{$orig}, $import_element );
2590     } else {
2591       my $orig_best = $orig->[$best_candidate->{position}];
2592       # merge orig_best and b_element together and replace original with merged
2593       if (ref $orig_best ne 'HASH') {
2594         $orig->[$best_candidate->{position}] = $import_element;
2595       } elsif (ref $import_element eq 'HASH') {
2596         my ($key) = keys %{$orig_best};
2597         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2598       }
2599     }
2600     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2601   }
2602
2603   return $orig;
2604 }
2605
2606 sub result_source {
2607     my $self = shift;
2608
2609     if (@_) {
2610         $self->_source_handle($_[0]->handle);
2611     } else {
2612         $self->_source_handle->resolve;
2613     }
2614 }
2615
2616 =head2 throw_exception
2617
2618 See L<DBIx::Class::Schema/throw_exception> for details.
2619
2620 =cut
2621
2622 sub throw_exception {
2623   my $self=shift;
2624   if (ref $self && $self->_source_handle->schema) {
2625     $self->_source_handle->schema->throw_exception(@_)
2626   } else {
2627     croak(@_);
2628   }
2629
2630 }
2631
2632 # XXX: FIXME: Attributes docs need clearing up
2633
2634 =head1 ATTRIBUTES
2635
2636 Attributes are used to refine a ResultSet in various ways when
2637 searching for data. They can be passed to any method which takes an
2638 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2639 L</count>.
2640
2641 These are in no particular order:
2642
2643 =head2 order_by
2644
2645 =over 4
2646
2647 =item Value: ( $order_by | \@order_by | \%order_by )
2648
2649 =back
2650
2651 Which column(s) to order the results by. If a single column name, or
2652 an arrayref of names is supplied, the argument is passed through
2653 directly to SQL. The hashref syntax allows for connection-agnostic
2654 specification of ordering direction:
2655
2656  For descending order:
2657
2658   order_by => { -desc => [qw/col1 col2 col3/] }
2659
2660  For explicit ascending order:
2661
2662   order_by => { -asc => 'col' }
2663
2664 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2665 supported, although you are strongly encouraged to use the hashref
2666 syntax as outlined above.
2667
2668 =head2 columns
2669
2670 =over 4
2671
2672 =item Value: \@columns
2673
2674 =back
2675
2676 Shortcut to request a particular set of columns to be retrieved. Each
2677 column spec may be a string (a table column name), or a hash (in which
2678 case the key is the C<as> value, and the value is used as the C<select>
2679 expression). Adds C<me.> onto the start of any column without a C<.> in
2680 it and sets C<select> from that, then auto-populates C<as> from
2681 C<select> as normal. (You may also use the C<cols> attribute, as in
2682 earlier versions of DBIC.)
2683
2684 =head2 +columns
2685
2686 =over 4
2687
2688 =item Value: \@columns
2689
2690 =back
2691
2692 Indicates additional columns to be selected from storage. Works the same
2693 as L</columns> but adds columns to the selection. (You may also use the
2694 C<include_columns> attribute, as in earlier versions of DBIC). For
2695 example:-
2696
2697   $schema->resultset('CD')->search(undef, {
2698     '+columns' => ['artist.name'],
2699     join => ['artist']
2700   });
2701
2702 would return all CDs and include a 'name' column to the information
2703 passed to object inflation. Note that the 'artist' is the name of the
2704 column (or relationship) accessor, and 'name' is the name of the column
2705 accessor in the related table.
2706
2707 =head2 include_columns
2708
2709 =over 4
2710
2711 =item Value: \@columns
2712
2713 =back
2714
2715 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2716
2717 =head2 select
2718
2719 =over 4
2720
2721 =item Value: \@select_columns
2722
2723 =back
2724
2725 Indicates which columns should be selected from the storage. You can use
2726 column names, or in the case of RDBMS back ends, function or stored procedure
2727 names:
2728
2729   $rs = $schema->resultset('Employee')->search(undef, {
2730     select => [
2731       'name',
2732       { count => 'employeeid' },
2733       { sum => 'salary' }
2734     ]
2735   });
2736
2737 When you use function/stored procedure names and do not supply an C<as>
2738 attribute, the column names returned are storage-dependent. E.g. MySQL would
2739 return a column named C<count(employeeid)> in the above example.
2740
2741 =head2 +select
2742
2743 =over 4
2744
2745 Indicates additional columns to be selected from storage.  Works the same as
2746 L</select> but adds columns to the selection.
2747
2748 =back
2749
2750 =head2 +as
2751
2752 =over 4
2753
2754 Indicates additional column names for those added via L</+select>. See L</as>.
2755
2756 =back
2757
2758 =head2 as
2759
2760 =over 4
2761
2762 =item Value: \@inflation_names
2763
2764 =back
2765
2766 Indicates column names for object inflation. That is, C<as>
2767 indicates the name that the column can be accessed as via the
2768 C<get_column> method (or via the object accessor, B<if one already
2769 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2770
2771 The C<as> attribute is used in conjunction with C<select>,
2772 usually when C<select> contains one or more function or stored
2773 procedure names:
2774
2775   $rs = $schema->resultset('Employee')->search(undef, {
2776     select => [
2777       'name',
2778       { count => 'employeeid' }
2779     ],
2780     as => ['name', 'employee_count'],
2781   });
2782
2783   my $employee = $rs->first(); # get the first Employee
2784
2785 If the object against which the search is performed already has an accessor
2786 matching a column name specified in C<as>, the value can be retrieved using
2787 the accessor as normal:
2788
2789   my $name = $employee->name();
2790
2791 If on the other hand an accessor does not exist in the object, you need to
2792 use C<get_column> instead:
2793
2794   my $employee_count = $employee->get_column('employee_count');
2795
2796 You can create your own accessors if required - see
2797 L<DBIx::Class::Manual::Cookbook> for details.
2798
2799 Please note: This will NOT insert an C<AS employee_count> into the SQL
2800 statement produced, it is used for internal access only. Thus
2801 attempting to use the accessor in an C<order_by> clause or similar
2802 will fail miserably.
2803
2804 To get around this limitation, you can supply literal SQL to your
2805 C<select> attibute that contains the C<AS alias> text, eg:
2806
2807   select => [\'myfield AS alias']
2808
2809 =head2 join
2810
2811 =over 4
2812
2813 =item Value: ($rel_name | \@rel_names | \%rel_names)
2814
2815 =back
2816
2817 Contains a list of relationships that should be joined for this query.  For
2818 example:
2819
2820   # Get CDs by Nine Inch Nails
2821   my $rs = $schema->resultset('CD')->search(
2822     { 'artist.name' => 'Nine Inch Nails' },
2823     { join => 'artist' }
2824   );
2825
2826 Can also contain a hash reference to refer to the other relation's relations.
2827 For example:
2828
2829   package MyApp::Schema::Track;
2830   use base qw/DBIx::Class/;
2831   __PACKAGE__->table('track');
2832   __PACKAGE__->add_columns(qw/trackid cd position title/);
2833   __PACKAGE__->set_primary_key('trackid');
2834   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2835   1;
2836
2837   # In your application
2838   my $rs = $schema->resultset('Artist')->search(
2839     { 'track.title' => 'Teardrop' },
2840     {
2841       join     => { cd => 'track' },
2842       order_by => 'artist.name',
2843     }
2844   );
2845
2846 You need to use the relationship (not the table) name in  conditions,
2847 because they are aliased as such. The current table is aliased as "me", so
2848 you need to use me.column_name in order to avoid ambiguity. For example:
2849
2850   # Get CDs from 1984 with a 'Foo' track
2851   my $rs = $schema->resultset('CD')->search(
2852     {
2853       'me.year' => 1984,
2854       'tracks.name' => 'Foo'
2855     },
2856     { join => 'tracks' }
2857   );
2858
2859 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2860 similarly for a third time). For e.g.
2861
2862   my $rs = $schema->resultset('Artist')->search({
2863     'cds.title'   => 'Down to Earth',
2864     'cds_2.title' => 'Popular',
2865   }, {
2866     join => [ qw/cds cds/ ],
2867   });
2868
2869 will return a set of all artists that have both a cd with title 'Down
2870 to Earth' and a cd with title 'Popular'.
2871
2872 If you want to fetch related objects from other tables as well, see C<prefetch>
2873 below.
2874
2875 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2876
2877 =head2 prefetch
2878
2879 =over 4
2880
2881 =item Value: ($rel_name | \@rel_names | \%rel_names)
2882
2883 =back
2884
2885 Contains one or more relationships that should be fetched along with
2886 the main query (when they are accessed afterwards the data will
2887 already be available, without extra queries to the database).  This is
2888 useful for when you know you will need the related objects, because it
2889 saves at least one query:
2890
2891   my $rs = $schema->resultset('Tag')->search(
2892     undef,
2893     {
2894       prefetch => {
2895         cd => 'artist'
2896       }
2897     }
2898   );
2899
2900 The initial search results in SQL like the following:
2901
2902   SELECT tag.*, cd.*, artist.* FROM tag
2903   JOIN cd ON tag.cd = cd.cdid
2904   JOIN artist ON cd.artist = artist.artistid
2905
2906 L<DBIx::Class> has no need to go back to the database when we access the
2907 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2908 case.
2909
2910 Simple prefetches will be joined automatically, so there is no need
2911 for a C<join> attribute in the above search.
2912
2913 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2914 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2915 with an accessor type of 'single' or 'filter'). A more complex example that
2916 prefetches an artists cds, the tracks on those cds, and the tags associted
2917 with that artist is given below (assuming many-to-many from artists to tags):
2918
2919  my $rs = $schema->resultset('Artist')->search(
2920    undef,
2921    {
2922      prefetch => [
2923        { cds => 'tracks' },
2924        { artist_tags => 'tags' }
2925      ]
2926    }
2927  );
2928
2929
2930 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2931 attributes will be ignored.
2932
2933 =head2 page
2934
2935 =over 4
2936
2937 =item Value: $page
2938
2939 =back
2940
2941 Makes the resultset paged and specifies the page to retrieve. Effectively
2942 identical to creating a non-pages resultset and then calling ->page($page)
2943 on it.
2944
2945 If L<rows> attribute is not specified it defualts to 10 rows per page.
2946
2947 When you have a paged resultset, L</count> will only return the number
2948 of rows in the page. To get the total, use the L</pager> and call
2949 C<total_entries> on it.
2950
2951 =head2 rows
2952
2953 =over 4
2954
2955 =item Value: $rows
2956
2957 =back
2958
2959 Specifes the maximum number of rows for direct retrieval or the number of
2960 rows per page if the page attribute or method is used.
2961
2962 =head2 offset
2963
2964 =over 4
2965
2966 =item Value: $offset
2967
2968 =back
2969
2970 Specifies the (zero-based) row number for the  first row to be returned, or the
2971 of the first row of the first page if paging is used.
2972
2973 =head2 group_by
2974
2975 =over 4
2976
2977 =item Value: \@columns
2978
2979 =back
2980
2981 A arrayref of columns to group by. Can include columns of joined tables.
2982
2983   group_by => [qw/ column1 column2 ... /]
2984
2985 =head2 having
2986
2987 =over 4
2988
2989 =item Value: $condition
2990
2991 =back
2992
2993 HAVING is a select statement attribute that is applied between GROUP BY and
2994 ORDER BY. It is applied to the after the grouping calculations have been
2995 done.
2996
2997   having => { 'count(employee)' => { '>=', 100 } }
2998
2999 =head2 distinct
3000
3001 =over 4
3002
3003 =item Value: (0 | 1)
3004
3005 =back
3006
3007 Set to 1 to group by all columns.
3008
3009 =head2 where
3010
3011 =over 4
3012
3013 Adds to the WHERE clause.
3014
3015   # only return rows WHERE deleted IS NULL for all searches
3016   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3017
3018 Can be overridden by passing C<{ where => undef }> as an attribute
3019 to a resulset.
3020
3021 =back
3022
3023 =head2 cache
3024
3025 Set to 1 to cache search results. This prevents extra SQL queries if you
3026 revisit rows in your ResultSet:
3027
3028   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3029
3030   while( my $artist = $resultset->next ) {
3031     ... do stuff ...
3032   }
3033
3034   $rs->first; # without cache, this would issue a query
3035
3036 By default, searches are not cached.
3037
3038 For more examples of using these attributes, see
3039 L<DBIx::Class::Manual::Cookbook>.
3040
3041 =head2 from
3042
3043 =over 4
3044
3045 =item Value: \@from_clause
3046
3047 =back
3048
3049 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3050 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3051 clauses.
3052
3053 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3054
3055 C<join> will usually do what you need and it is strongly recommended that you
3056 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3057 And we really do mean "cannot", not just tried and failed. Attempting to use
3058 this because you're having problems with C<join> is like trying to use x86
3059 ASM because you've got a syntax error in your C. Trust us on this.
3060
3061 Now, if you're still really, really sure you need to use this (and if you're
3062 not 100% sure, ask the mailing list first), here's an explanation of how this
3063 works.
3064
3065 The syntax is as follows -
3066
3067   [
3068     { <alias1> => <table1> },
3069     [
3070       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3071       [], # nested JOIN (optional)
3072       { <table1.column1> => <table2.column2>, ... (more conditions) },
3073     ],
3074     # More of the above [ ] may follow for additional joins
3075   ]
3076
3077   <table1> <alias1>
3078   JOIN
3079     <table2> <alias2>
3080     [JOIN ...]
3081   ON <table1.column1> = <table2.column2>
3082   <more joins may follow>
3083
3084 An easy way to follow the examples below is to remember the following:
3085
3086     Anything inside "[]" is a JOIN
3087     Anything inside "{}" is a condition for the enclosing JOIN
3088
3089 The following examples utilize a "person" table in a family tree application.
3090 In order to express parent->child relationships, this table is self-joined:
3091
3092     # Person->belongs_to('father' => 'Person');
3093     # Person->belongs_to('mother' => 'Person');
3094
3095 C<from> can be used to nest joins. Here we return all children with a father,
3096 then search against all mothers of those children:
3097
3098   $rs = $schema->resultset('Person')->search(
3099       undef,
3100       {
3101           alias => 'mother', # alias columns in accordance with "from"
3102           from => [
3103               { mother => 'person' },
3104               [
3105                   [
3106                       { child => 'person' },
3107                       [
3108                           { father => 'person' },
3109                           { 'father.person_id' => 'child.father_id' }
3110                       ]
3111                   ],
3112                   { 'mother.person_id' => 'child.mother_id' }
3113               ],
3114           ]
3115       },
3116   );
3117
3118   # Equivalent SQL:
3119   # SELECT mother.* FROM person mother
3120   # JOIN (
3121   #   person child
3122   #   JOIN person father
3123   #   ON ( father.person_id = child.father_id )
3124   # )
3125   # ON ( mother.person_id = child.mother_id )
3126
3127 The type of any join can be controlled manually. To search against only people
3128 with a father in the person table, we could explicitly use C<INNER JOIN>:
3129
3130     $rs = $schema->resultset('Person')->search(
3131         undef,
3132         {
3133             alias => 'child', # alias columns in accordance with "from"
3134             from => [
3135                 { child => 'person' },
3136                 [
3137                     { father => 'person', -join_type => 'inner' },
3138                     { 'father.id' => 'child.father_id' }
3139                 ],
3140             ]
3141         },
3142     );
3143
3144     # Equivalent SQL:
3145     # SELECT child.* FROM person child
3146     # INNER JOIN person father ON child.father_id = father.id
3147
3148 If you need to express really complex joins or you need a subselect, you
3149 can supply literal SQL to C<from> via a scalar reference. In this case
3150 the contents of the scalar will replace the table name asscoiated with the
3151 resultsource.
3152
3153 WARNING: This technique might very well not work as expected on chained
3154 searches - you have been warned.
3155
3156     # Assuming the Event resultsource is defined as:
3157
3158         MySchema::Event->add_columns (
3159             sequence => {
3160                 data_type => 'INT',
3161                 is_auto_increment => 1,
3162             },
3163             location => {
3164                 data_type => 'INT',
3165             },
3166             type => {
3167                 data_type => 'INT',
3168             },
3169         );
3170         MySchema::Event->set_primary_key ('sequence');
3171
3172     # This will get back the latest event for every location. The column
3173     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3174     # combo to limit the resultset
3175
3176     $rs = $schema->resultset('Event');
3177     $table = $rs->result_source->name;
3178     $latest = $rs->search (
3179         undef,
3180         { from => \ "
3181             (SELECT e1.* FROM $table e1
3182                 JOIN $table e2
3183                     ON e1.location = e2.location
3184                     AND e1.sequence < e2.sequence
3185                 WHERE e2.sequence is NULL
3186             ) me",
3187         },
3188     );
3189
3190     # Equivalent SQL (with the DBIC chunks added):
3191
3192     SELECT me.sequence, me.location, me.type FROM
3193        (SELECT e1.* FROM events e1
3194            JOIN events e2
3195                ON e1.location = e2.location
3196                AND e1.sequence < e2.sequence
3197            WHERE e2.sequence is NULL
3198        ) me;
3199
3200 =head2 for
3201
3202 =over 4
3203
3204 =item Value: ( 'update' | 'shared' )
3205
3206 =back
3207
3208 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3209 ... FOR SHARED.
3210
3211 =cut
3212
3213 1;