lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->_resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my @subq_attrs = qw/prefetch collapse distinct group_by having having_bind/;
1159
1160   # if we are not paged - we are simply asking for a limit
1161   if (not $self->{attrs}{page} and not $self->{attrs}{software_limit}) {
1162     push @subq_attrs, qw/rows offset/;
1163   }
1164
1165   return $self->_has_attr (@subq_attrs)
1166     ? $self->_count_subq
1167     : $self->_count_simple
1168 }
1169
1170 sub _count_subq {
1171   my $self = shift;
1172
1173   my $attrs = { %{$self->_resolved_attrs} };
1174
1175   # copy for the subquery, we need to do some adjustments to it too
1176   my $sub_attrs = { %$attrs };
1177
1178   # these can not go in the subquery either
1179   delete $sub_attrs->{$_} for qw/prefetch select +select as +as columns +columns/;
1180
1181   # force a group_by and the same set of columns (most databases require this)
1182   $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1183
1184   $attrs->{from} = [{
1185     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1186   }];
1187
1188   # the subquery replaces this
1189   delete $attrs->{$_} for qw/where bind prefetch collapse group_by having/;
1190
1191   return $self->__count ($attrs);
1192 }
1193
1194 sub _count_simple {
1195   my $self = shift;
1196
1197   my $count = $self->__count;
1198   return 0 unless $count;
1199
1200   # need to take offset from resolved attrs
1201
1202   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1203   $count = $self->{attrs}{rows} if
1204     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1205   $count = 0 if ($count < 0);
1206   return $count;
1207 }
1208
1209 sub __count {
1210   my ($self, $attrs) = @_;
1211
1212   $attrs ||= { %{$self->{attrs}} };
1213
1214   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1215   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1216
1217   $attrs->{select} = { count => '*' };
1218   $attrs->{as} = [qw/count/];
1219
1220   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1221   my ($count) = $tmp_rs->cursor->next;
1222
1223   return $count;
1224 }
1225
1226 sub _bool {
1227   return 1;
1228 }
1229
1230 =head2 count_literal
1231
1232 =over 4
1233
1234 =item Arguments: $sql_fragment, @bind_values
1235
1236 =item Return Value: $count
1237
1238 =back
1239
1240 Counts the results in a literal query. Equivalent to calling L</search_literal>
1241 with the passed arguments, then L</count>.
1242
1243 =cut
1244
1245 sub count_literal { shift->search_literal(@_)->count; }
1246
1247 =head2 all
1248
1249 =over 4
1250
1251 =item Arguments: none
1252
1253 =item Return Value: @objects
1254
1255 =back
1256
1257 Returns all elements in the resultset. Called implicitly if the resultset
1258 is returned in list context.
1259
1260 =cut
1261
1262 sub all {
1263   my $self = shift;
1264   if(@_) {
1265       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1266   }
1267
1268   return @{ $self->get_cache } if $self->get_cache;
1269
1270   my @obj;
1271
1272   # TODO: don't call resolve here
1273   if (keys %{$self->_resolved_attrs->{collapse}}) {
1274 #  if ($self->{attrs}{prefetch}) {
1275       # Using $self->cursor->all is really just an optimisation.
1276       # If we're collapsing has_many prefetches it probably makes
1277       # very little difference, and this is cleaner than hacking
1278       # _construct_object to survive the approach
1279     my @row = $self->cursor->next;
1280     while (@row) {
1281       push(@obj, $self->_construct_object(@row));
1282       @row = (exists $self->{stashed_row}
1283                ? @{delete $self->{stashed_row}}
1284                : $self->cursor->next);
1285     }
1286   } else {
1287     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1288   }
1289
1290   $self->set_cache(\@obj) if $self->{attrs}{cache};
1291   return @obj;
1292 }
1293
1294 =head2 reset
1295
1296 =over 4
1297
1298 =item Arguments: none
1299
1300 =item Return Value: $self
1301
1302 =back
1303
1304 Resets the resultset's cursor, so you can iterate through the elements again.
1305
1306 =cut
1307
1308 sub reset {
1309   my ($self) = @_;
1310   delete $self->{_attrs} if exists $self->{_attrs};
1311   $self->{all_cache_position} = 0;
1312   $self->cursor->reset;
1313   return $self;
1314 }
1315
1316 =head2 first
1317
1318 =over 4
1319
1320 =item Arguments: none
1321
1322 =item Return Value: $object?
1323
1324 =back
1325
1326 Resets the resultset and returns an object for the first result (if the
1327 resultset returns anything).
1328
1329 =cut
1330
1331 sub first {
1332   return $_[0]->reset->next;
1333 }
1334
1335
1336 # _rs_update_delete
1337 #
1338 # Determines whether and what type of subquery is required for the $rs operation.
1339 # If grouping is necessary either supplies its own, or verifies the current one
1340 # After all is done delegates to the proper storage method.
1341
1342 sub _rs_update_delete {
1343   my ($self, $op, $values) = @_;
1344
1345   my $rsrc = $self->result_source;
1346
1347   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1348   my $needs_subq = $self->_has_attr (qw/row offset page/);
1349
1350   if ($needs_group_by_subq or $needs_subq) {
1351
1352     # make a new $rs selecting only the PKs (that's all we really need)
1353     my $attrs = $self->_resolved_attrs;
1354
1355     delete $attrs->{$_} for qw/prefetch select +select as +as columns +columns/;
1356     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1357
1358     if ($needs_group_by_subq) {
1359       # make sure no group_by was supplied, or if there is one - make sure it matches
1360       # the columns compiled above perfectly. Anything else can not be sanely executed
1361       # on most databases so croak right then and there
1362
1363       if (my $g = $attrs->{group_by}) {
1364         my @current_group_by = map
1365           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1366           (ref $g eq 'ARRAY' ? @$g : $g );
1367
1368         if (
1369           join ("\x00", sort @current_group_by)
1370             ne
1371           join ("\x00", sort @{$attrs->{columns}} )
1372         ) {
1373           $self->throw_exception (
1374             "You have just attempted a $op operation on a resultset which does group_by"
1375             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1376             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1377             . ' kind of queries. Please retry the operation with a modified group_by or'
1378             . ' without using one at all.'
1379           );
1380         }
1381       }
1382       else {
1383         $attrs->{group_by} = $attrs->{columns};
1384       }
1385     }
1386
1387     my $subrs = (ref $self)->new($rsrc, $attrs);
1388
1389     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1390   }
1391   else {
1392     return $rsrc->storage->$op(
1393       $rsrc,
1394       $op eq 'update' ? $values : (),
1395       $self->_cond_for_update_delete,
1396     );
1397   }
1398 }
1399
1400
1401 # _cond_for_update_delete
1402 #
1403 # update/delete require the condition to be modified to handle
1404 # the differing SQL syntax available.  This transforms the $self->{cond}
1405 # appropriately, returning the new condition.
1406
1407 sub _cond_for_update_delete {
1408   my ($self, $full_cond) = @_;
1409   my $cond = {};
1410
1411   $full_cond ||= $self->{cond};
1412   # No-op. No condition, we're updating/deleting everything
1413   return $cond unless ref $full_cond;
1414
1415   if (ref $full_cond eq 'ARRAY') {
1416     $cond = [
1417       map {
1418         my %hash;
1419         foreach my $key (keys %{$_}) {
1420           $key =~ /([^.]+)$/;
1421           $hash{$1} = $_->{$key};
1422         }
1423         \%hash;
1424       } @{$full_cond}
1425     ];
1426   }
1427   elsif (ref $full_cond eq 'HASH') {
1428     if ((keys %{$full_cond})[0] eq '-and') {
1429       $cond->{-and} = [];
1430       my @cond = @{$full_cond->{-and}};
1431        for (my $i = 0; $i < @cond; $i++) {
1432         my $entry = $cond[$i];
1433         my $hash;
1434         if (ref $entry eq 'HASH') {
1435           $hash = $self->_cond_for_update_delete($entry);
1436         }
1437         else {
1438           $entry =~ /([^.]+)$/;
1439           $hash->{$1} = $cond[++$i];
1440         }
1441         push @{$cond->{-and}}, $hash;
1442       }
1443     }
1444     else {
1445       foreach my $key (keys %{$full_cond}) {
1446         $key =~ /([^.]+)$/;
1447         $cond->{$1} = $full_cond->{$key};
1448       }
1449     }
1450   }
1451   else {
1452     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1453   }
1454
1455   return $cond;
1456 }
1457
1458
1459 =head2 update
1460
1461 =over 4
1462
1463 =item Arguments: \%values
1464
1465 =item Return Value: $storage_rv
1466
1467 =back
1468
1469 Sets the specified columns in the resultset to the supplied values in a
1470 single query. Return value will be true if the update succeeded or false
1471 if no records were updated; exact type of success value is storage-dependent.
1472
1473 =cut
1474
1475 sub update {
1476   my ($self, $values) = @_;
1477   $self->throw_exception('Values for update must be a hash')
1478     unless ref $values eq 'HASH';
1479
1480   return $self->_rs_update_delete ('update', $values);
1481 }
1482
1483 =head2 update_all
1484
1485 =over 4
1486
1487 =item Arguments: \%values
1488
1489 =item Return Value: 1
1490
1491 =back
1492
1493 Fetches all objects and updates them one at a time. Note that C<update_all>
1494 will run DBIC cascade triggers, while L</update> will not.
1495
1496 =cut
1497
1498 sub update_all {
1499   my ($self, $values) = @_;
1500   $self->throw_exception('Values for update_all must be a hash')
1501     unless ref $values eq 'HASH';
1502   foreach my $obj ($self->all) {
1503     $obj->set_columns($values)->update;
1504   }
1505   return 1;
1506 }
1507
1508 =head2 delete
1509
1510 =over 4
1511
1512 =item Arguments: none
1513
1514 =item Return Value: 1
1515
1516 =back
1517
1518 Deletes the contents of the resultset from its result source. Note that this
1519 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1520 to run. See also L<DBIx::Class::Row/delete>.
1521
1522 delete may not generate correct SQL for a query with joins or a resultset
1523 chained from a related resultset.  In this case it will generate a warning:-
1524
1525 In these cases you may find that delete_all is more appropriate, or you
1526 need to respecify your query in a way that can be expressed without a join.
1527
1528 =cut
1529
1530 sub delete {
1531   my $self = shift;
1532   $self->throw_exception('delete does not accept any arguments')
1533     if @_;
1534
1535   return $self->_rs_update_delete ('delete');
1536 }
1537
1538 =head2 delete_all
1539
1540 =over 4
1541
1542 =item Arguments: none
1543
1544 =item Return Value: 1
1545
1546 =back
1547
1548 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1549 will run DBIC cascade triggers, while L</delete> will not.
1550
1551 =cut
1552
1553 sub delete_all {
1554   my $self = shift;
1555   $self->throw_exception('delete_all does not accept any arguments')
1556     if @_;
1557
1558   $_->delete for $self->all;
1559   return 1;
1560 }
1561
1562 =head2 populate
1563
1564 =over 4
1565
1566 =item Arguments: \@data;
1567
1568 =back
1569
1570 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1571 For the arrayref of hashrefs style each hashref should be a structure suitable
1572 forsubmitting to a $resultset->create(...) method.
1573
1574 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1575 to insert the data, as this is a faster method.
1576
1577 Otherwise, each set of data is inserted into the database using
1578 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1579 objects is returned.
1580
1581 Example:  Assuming an Artist Class that has many CDs Classes relating:
1582
1583   my $Artist_rs = $schema->resultset("Artist");
1584
1585   ## Void Context Example
1586   $Artist_rs->populate([
1587      { artistid => 4, name => 'Manufactured Crap', cds => [
1588         { title => 'My First CD', year => 2006 },
1589         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1590       ],
1591      },
1592      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1593         { title => 'My parents sold me to a record company' ,year => 2005 },
1594         { title => 'Why Am I So Ugly?', year => 2006 },
1595         { title => 'I Got Surgery and am now Popular', year => 2007 }
1596       ],
1597      },
1598   ]);
1599
1600   ## Array Context Example
1601   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1602     { name => "Artist One"},
1603     { name => "Artist Two"},
1604     { name => "Artist Three", cds=> [
1605     { title => "First CD", year => 2007},
1606     { title => "Second CD", year => 2008},
1607   ]}
1608   ]);
1609
1610   print $ArtistOne->name; ## response is 'Artist One'
1611   print $ArtistThree->cds->count ## reponse is '2'
1612
1613 For the arrayref of arrayrefs style,  the first element should be a list of the
1614 fieldsnames to which the remaining elements are rows being inserted.  For
1615 example:
1616
1617   $Arstist_rs->populate([
1618     [qw/artistid name/],
1619     [100, 'A Formally Unknown Singer'],
1620     [101, 'A singer that jumped the shark two albums ago'],
1621     [102, 'An actually cool singer.'],
1622   ]);
1623
1624 Please note an important effect on your data when choosing between void and
1625 wantarray context. Since void context goes straight to C<insert_bulk> in
1626 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1627 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1628 create primary keys for you, you will find that your PKs are empty.  In this
1629 case you will have to use the wantarray context in order to create those
1630 values.
1631
1632 =cut
1633
1634 sub populate {
1635   my $self = shift @_;
1636   my $data = ref $_[0][0] eq 'HASH'
1637     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1638     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1639
1640   if(defined wantarray) {
1641     my @created;
1642     foreach my $item (@$data) {
1643       push(@created, $self->create($item));
1644     }
1645     return @created;
1646   } else {
1647     my ($first, @rest) = @$data;
1648
1649     my @names = grep {!ref $first->{$_}} keys %$first;
1650     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1651     my @pks = $self->result_source->primary_columns;
1652
1653     ## do the belongs_to relationships
1654     foreach my $index (0..$#$data) {
1655       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1656         my @ret = $self->populate($data);
1657         return;
1658       }
1659
1660       foreach my $rel (@rels) {
1661         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1662         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1663         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1664         my $related = $result->result_source->_resolve_condition(
1665           $result->result_source->relationship_info($reverse)->{cond},
1666           $self,
1667           $result,
1668         );
1669
1670         delete $data->[$index]->{$rel};
1671         $data->[$index] = {%{$data->[$index]}, %$related};
1672
1673         push @names, keys %$related if $index == 0;
1674       }
1675     }
1676
1677     ## do bulk insert on current row
1678     my @values = map { [ @$_{@names} ] } @$data;
1679
1680     $self->result_source->storage->insert_bulk(
1681       $self->result_source,
1682       \@names,
1683       \@values,
1684     );
1685
1686     ## do the has_many relationships
1687     foreach my $item (@$data) {
1688
1689       foreach my $rel (@rels) {
1690         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1691
1692         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1693      || $self->throw_exception('Cannot find the relating object.');
1694
1695         my $child = $parent->$rel;
1696
1697         my $related = $child->result_source->_resolve_condition(
1698           $parent->result_source->relationship_info($rel)->{cond},
1699           $child,
1700           $parent,
1701         );
1702
1703         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1704         my @populate = map { {%$_, %$related} } @rows_to_add;
1705
1706         $child->populate( \@populate );
1707       }
1708     }
1709   }
1710 }
1711
1712 =head2 _normalize_populate_args ($args)
1713
1714 Private method used by L</populate> to normalize its incoming arguments.  Factored
1715 out in case you want to subclass and accept new argument structures to the
1716 L</populate> method.
1717
1718 =cut
1719
1720 sub _normalize_populate_args {
1721   my ($self, $data) = @_;
1722   my @names = @{shift(@$data)};
1723   my @results_to_create;
1724   foreach my $datum (@$data) {
1725     my %result_to_create;
1726     foreach my $index (0..$#names) {
1727       $result_to_create{$names[$index]} = $$datum[$index];
1728     }
1729     push @results_to_create, \%result_to_create;
1730   }
1731   return \@results_to_create;
1732 }
1733
1734 =head2 pager
1735
1736 =over 4
1737
1738 =item Arguments: none
1739
1740 =item Return Value: $pager
1741
1742 =back
1743
1744 Return Value a L<Data::Page> object for the current resultset. Only makes
1745 sense for queries with a C<page> attribute.
1746
1747 To get the full count of entries for a paged resultset, call
1748 C<total_entries> on the L<Data::Page> object.
1749
1750 =cut
1751
1752 sub pager {
1753   my ($self) = @_;
1754
1755   return $self->{pager} if $self->{pager};
1756
1757   my $attrs = $self->{attrs};
1758   $self->throw_exception("Can't create pager for non-paged rs")
1759     unless $self->{attrs}{page};
1760   $attrs->{rows} ||= 10;
1761
1762   # throw away the paging flags and re-run the count (possibly
1763   # with a subselect) to get the real total count
1764   my $count_attrs = { %$attrs };
1765   delete $count_attrs->{$_} for qw/rows offset page pager/;
1766   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1767
1768   return $self->{pager} = Data::Page->new(
1769     $total_count,
1770     $attrs->{rows},
1771     $self->{attrs}{page}
1772   );
1773 }
1774
1775 =head2 page
1776
1777 =over 4
1778
1779 =item Arguments: $page_number
1780
1781 =item Return Value: $rs
1782
1783 =back
1784
1785 Returns a resultset for the $page_number page of the resultset on which page
1786 is called, where each page contains a number of rows equal to the 'rows'
1787 attribute set on the resultset (10 by default).
1788
1789 =cut
1790
1791 sub page {
1792   my ($self, $page) = @_;
1793   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1794 }
1795
1796 =head2 new_result
1797
1798 =over 4
1799
1800 =item Arguments: \%vals
1801
1802 =item Return Value: $rowobject
1803
1804 =back
1805
1806 Creates a new row object in the resultset's result class and returns
1807 it. The row is not inserted into the database at this point, call
1808 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1809 will tell you whether the row object has been inserted or not.
1810
1811 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1812
1813 =cut
1814
1815 sub new_result {
1816   my ($self, $values) = @_;
1817   $self->throw_exception( "new_result needs a hash" )
1818     unless (ref $values eq 'HASH');
1819
1820   my %new;
1821   my $alias = $self->{attrs}{alias};
1822
1823   if (
1824     defined $self->{cond}
1825     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1826   ) {
1827     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1828     $new{-from_resultset} = [ keys %new ] if keys %new;
1829   } else {
1830     $self->throw_exception(
1831       "Can't abstract implicit construct, condition not a hash"
1832     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1833
1834     my $collapsed_cond = (
1835       $self->{cond}
1836         ? $self->_collapse_cond($self->{cond})
1837         : {}
1838     );
1839
1840     # precendence must be given to passed values over values inherited from
1841     # the cond, so the order here is important.
1842     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1843     while( my($col,$value) = each %implied ){
1844       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1845         $new{$col} = $value->{'='};
1846         next;
1847       }
1848       $new{$col} = $value if $self->_is_deterministic_value($value);
1849     }
1850   }
1851
1852   %new = (
1853     %new,
1854     %{ $self->_remove_alias($values, $alias) },
1855     -source_handle => $self->_source_handle,
1856     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1857   );
1858
1859   return $self->result_class->new(\%new);
1860 }
1861
1862 # _is_deterministic_value
1863 #
1864 # Make an effor to strip non-deterministic values from the condition,
1865 # to make sure new_result chokes less
1866
1867 sub _is_deterministic_value {
1868   my $self = shift;
1869   my $value = shift;
1870   my $ref_type = ref $value;
1871   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1872   return 1 if Scalar::Util::blessed($value);
1873   return 0;
1874 }
1875
1876 # _has_attr
1877 #
1878 # determines if the resultset defines at least one
1879 # of the attributes supplied
1880 #
1881 # used to determine if a subquery is neccessary
1882
1883 sub _has_attr {
1884   my ($self, @attr_names) = @_;
1885
1886   my $attrs = $self->_resolved_attrs;
1887
1888   my $join_check_req;
1889
1890   for my $n (@attr_names) {
1891     ++$join_check_req if $n =~ /join/;
1892
1893     my $attr =  $attrs->{$n};
1894
1895     next if not defined $attr;
1896
1897     if (ref $attr eq 'HASH') {
1898       return 1 if keys %$attr;
1899     }
1900     elsif (ref $attr eq 'ARRAY') {
1901       return 1 if @$attr;
1902     }
1903     else {
1904       return 1 if $attr;
1905     }
1906   }
1907
1908   # a join can be expressed as a multi-level from
1909   return 1 if (
1910     $join_check_req
1911       and
1912     ref $attrs->{from} eq 'ARRAY'
1913       and
1914     @{$attrs->{from}} > 1
1915   );
1916
1917   return 0;
1918 }
1919
1920 # _collapse_cond
1921 #
1922 # Recursively collapse the condition.
1923
1924 sub _collapse_cond {
1925   my ($self, $cond, $collapsed) = @_;
1926
1927   $collapsed ||= {};
1928
1929   if (ref $cond eq 'ARRAY') {
1930     foreach my $subcond (@$cond) {
1931       next unless ref $subcond;  # -or
1932       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1933     }
1934   }
1935   elsif (ref $cond eq 'HASH') {
1936     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1937       foreach my $subcond (@{$cond->{-and}}) {
1938         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1939       }
1940     }
1941     else {
1942       foreach my $col (keys %$cond) {
1943         my $value = $cond->{$col};
1944         $collapsed->{$col} = $value;
1945       }
1946     }
1947   }
1948
1949   return $collapsed;
1950 }
1951
1952 # _remove_alias
1953 #
1954 # Remove the specified alias from the specified query hash. A copy is made so
1955 # the original query is not modified.
1956
1957 sub _remove_alias {
1958   my ($self, $query, $alias) = @_;
1959
1960   my %orig = %{ $query || {} };
1961   my %unaliased;
1962
1963   foreach my $key (keys %orig) {
1964     if ($key !~ /\./) {
1965       $unaliased{$key} = $orig{$key};
1966       next;
1967     }
1968     $unaliased{$1} = $orig{$key}
1969       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1970   }
1971
1972   return \%unaliased;
1973 }
1974
1975 =head2 as_query (EXPERIMENTAL)
1976
1977 =over 4
1978
1979 =item Arguments: none
1980
1981 =item Return Value: \[ $sql, @bind ]
1982
1983 =back
1984
1985 Returns the SQL query and bind vars associated with the invocant.
1986
1987 This is generally used as the RHS for a subquery.
1988
1989 B<NOTE>: This feature is still experimental.
1990
1991 =cut
1992
1993 sub as_query { return shift->cursor->as_query(@_) }
1994
1995 =head2 find_or_new
1996
1997 =over 4
1998
1999 =item Arguments: \%vals, \%attrs?
2000
2001 =item Return Value: $rowobject
2002
2003 =back
2004
2005   my $artist = $schema->resultset('Artist')->find_or_new(
2006     { artist => 'fred' }, { key => 'artists' });
2007
2008   $cd->cd_to_producer->find_or_new({ producer => $producer },
2009                                    { key => 'primary });
2010
2011 Find an existing record from this resultset, based on its primary
2012 key, or a unique constraint. If none exists, instantiate a new result
2013 object and return it. The object will not be saved into your storage
2014 until you call L<DBIx::Class::Row/insert> on it.
2015
2016 You most likely want this method when looking for existing rows using
2017 a unique constraint that is not the primary key, or looking for
2018 related rows.
2019
2020 If you want objects to be saved immediately, use L</find_or_create> instead.
2021
2022 B<Note>: C<find_or_new> is probably not what you want when creating a
2023 new row in a table that uses primary keys supplied by the
2024 database. Passing in a primary key column with a value of I<undef>
2025 will cause L</find> to attempt to search for a row with a value of
2026 I<NULL>.
2027
2028 =cut
2029
2030 sub find_or_new {
2031   my $self     = shift;
2032   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2033   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2034   my $exists   = $self->find($hash, $attrs);
2035   return defined $exists ? $exists : $self->new_result($hash);
2036 }
2037
2038 =head2 create
2039
2040 =over 4
2041
2042 =item Arguments: \%vals
2043
2044 =item Return Value: a L<DBIx::Class::Row> $object
2045
2046 =back
2047
2048 Attempt to create a single new row or a row with multiple related rows
2049 in the table represented by the resultset (and related tables). This
2050 will not check for duplicate rows before inserting, use
2051 L</find_or_create> to do that.
2052
2053 To create one row for this resultset, pass a hashref of key/value
2054 pairs representing the columns of the table and the values you wish to
2055 store. If the appropriate relationships are set up, foreign key fields
2056 can also be passed an object representing the foreign row, and the
2057 value will be set to its primary key.
2058
2059 To create related objects, pass a hashref for the value if the related
2060 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2061 and use the name of the relationship as the key. (NOT the name of the field,
2062 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2063 of hashrefs containing the data for each of the rows to create in the foreign
2064 tables, again using the relationship name as the key.
2065
2066 Instead of hashrefs of plain related data (key/value pairs), you may
2067 also pass new or inserted objects. New objects (not inserted yet, see
2068 L</new>), will be inserted into their appropriate tables.
2069
2070 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2071
2072 Example of creating a new row.
2073
2074   $person_rs->create({
2075     name=>"Some Person",
2076     email=>"somebody@someplace.com"
2077   });
2078
2079 Example of creating a new row and also creating rows in a related C<has_many>
2080 or C<has_one> resultset.  Note Arrayref.
2081
2082   $artist_rs->create(
2083      { artistid => 4, name => 'Manufactured Crap', cds => [
2084         { title => 'My First CD', year => 2006 },
2085         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2086       ],
2087      },
2088   );
2089
2090 Example of creating a new row and also creating a row in a related
2091 C<belongs_to>resultset. Note Hashref.
2092
2093   $cd_rs->create({
2094     title=>"Music for Silly Walks",
2095     year=>2000,
2096     artist => {
2097       name=>"Silly Musician",
2098     }
2099   });
2100
2101 =cut
2102
2103 sub create {
2104   my ($self, $attrs) = @_;
2105   $self->throw_exception( "create needs a hashref" )
2106     unless ref $attrs eq 'HASH';
2107   return $self->new_result($attrs)->insert;
2108 }
2109
2110 =head2 find_or_create
2111
2112 =over 4
2113
2114 =item Arguments: \%vals, \%attrs?
2115
2116 =item Return Value: $rowobject
2117
2118 =back
2119
2120   $cd->cd_to_producer->find_or_create({ producer => $producer },
2121                                       { key => 'primary });
2122
2123 Tries to find a record based on its primary key or unique constraints; if none
2124 is found, creates one and returns that instead.
2125
2126   my $cd = $schema->resultset('CD')->find_or_create({
2127     cdid   => 5,
2128     artist => 'Massive Attack',
2129     title  => 'Mezzanine',
2130     year   => 2005,
2131   });
2132
2133 Also takes an optional C<key> attribute, to search by a specific key or unique
2134 constraint. For example:
2135
2136   my $cd = $schema->resultset('CD')->find_or_create(
2137     {
2138       artist => 'Massive Attack',
2139       title  => 'Mezzanine',
2140     },
2141     { key => 'cd_artist_title' }
2142   );
2143
2144 B<Note>: Because find_or_create() reads from the database and then
2145 possibly inserts based on the result, this method is subject to a race
2146 condition. Another process could create a record in the table after
2147 the find has completed and before the create has started. To avoid
2148 this problem, use find_or_create() inside a transaction.
2149
2150 B<Note>: C<find_or_create> is probably not what you want when creating
2151 a new row in a table that uses primary keys supplied by the
2152 database. Passing in a primary key column with a value of I<undef>
2153 will cause L</find> to attempt to search for a row with a value of
2154 I<NULL>.
2155
2156 See also L</find> and L</update_or_create>. For information on how to declare
2157 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2158
2159 =cut
2160
2161 sub find_or_create {
2162   my $self     = shift;
2163   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2164   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2165   my $exists   = $self->find($hash, $attrs);
2166   return defined $exists ? $exists : $self->create($hash);
2167 }
2168
2169 =head2 update_or_create
2170
2171 =over 4
2172
2173 =item Arguments: \%col_values, { key => $unique_constraint }?
2174
2175 =item Return Value: $rowobject
2176
2177 =back
2178
2179   $resultset->update_or_create({ col => $val, ... });
2180
2181 First, searches for an existing row matching one of the unique constraints
2182 (including the primary key) on the source of this resultset. If a row is
2183 found, updates it with the other given column values. Otherwise, creates a new
2184 row.
2185
2186 Takes an optional C<key> attribute to search on a specific unique constraint.
2187 For example:
2188
2189   # In your application
2190   my $cd = $schema->resultset('CD')->update_or_create(
2191     {
2192       artist => 'Massive Attack',
2193       title  => 'Mezzanine',
2194       year   => 1998,
2195     },
2196     { key => 'cd_artist_title' }
2197   );
2198
2199   $cd->cd_to_producer->update_or_create({
2200     producer => $producer,
2201     name => 'harry',
2202   }, {
2203     key => 'primary,
2204   });
2205
2206
2207 If no C<key> is specified, it searches on all unique constraints defined on the
2208 source, including the primary key.
2209
2210 If the C<key> is specified as C<primary>, it searches only on the primary key.
2211
2212 See also L</find> and L</find_or_create>. For information on how to declare
2213 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2214
2215 B<Note>: C<update_or_create> is probably not what you want when
2216 looking for a row in a table that uses primary keys supplied by the
2217 database, unless you actually have a key value. Passing in a primary
2218 key column with a value of I<undef> will cause L</find> to attempt to
2219 search for a row with a value of I<NULL>.
2220
2221 =cut
2222
2223 sub update_or_create {
2224   my $self = shift;
2225   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2226   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2227
2228   my $row = $self->find($cond, $attrs);
2229   if (defined $row) {
2230     $row->update($cond);
2231     return $row;
2232   }
2233
2234   return $self->create($cond);
2235 }
2236
2237 =head2 update_or_new
2238
2239 =over 4
2240
2241 =item Arguments: \%col_values, { key => $unique_constraint }?
2242
2243 =item Return Value: $rowobject
2244
2245 =back
2246
2247   $resultset->update_or_new({ col => $val, ... });
2248
2249 First, searches for an existing row matching one of the unique constraints
2250 (including the primary key) on the source of this resultset. If a row is
2251 found, updates it with the other given column values. Otherwise, instantiate
2252 a new result object and return it. The object will not be saved into your storage
2253 until you call L<DBIx::Class::Row/insert> on it.
2254
2255 Takes an optional C<key> attribute to search on a specific unique constraint.
2256 For example:
2257
2258   # In your application
2259   my $cd = $schema->resultset('CD')->update_or_new(
2260     {
2261       artist => 'Massive Attack',
2262       title  => 'Mezzanine',
2263       year   => 1998,
2264     },
2265     { key => 'cd_artist_title' }
2266   );
2267
2268   if ($cd->in_storage) {
2269       # the cd was updated
2270   }
2271   else {
2272       # the cd is not yet in the database, let's insert it
2273       $cd->insert;
2274   }
2275
2276 See also L</find>, L</find_or_create> and L<find_or_new>.
2277
2278 =cut
2279
2280 sub update_or_new {
2281     my $self  = shift;
2282     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2283     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2284
2285     my $row = $self->find( $cond, $attrs );
2286     if ( defined $row ) {
2287         $row->update($cond);
2288         return $row;
2289     }
2290
2291     return $self->new_result($cond);
2292 }
2293
2294 =head2 get_cache
2295
2296 =over 4
2297
2298 =item Arguments: none
2299
2300 =item Return Value: \@cache_objects?
2301
2302 =back
2303
2304 Gets the contents of the cache for the resultset, if the cache is set.
2305
2306 The cache is populated either by using the L</prefetch> attribute to
2307 L</search> or by calling L</set_cache>.
2308
2309 =cut
2310
2311 sub get_cache {
2312   shift->{all_cache};
2313 }
2314
2315 =head2 set_cache
2316
2317 =over 4
2318
2319 =item Arguments: \@cache_objects
2320
2321 =item Return Value: \@cache_objects
2322
2323 =back
2324
2325 Sets the contents of the cache for the resultset. Expects an arrayref
2326 of objects of the same class as those produced by the resultset. Note that
2327 if the cache is set the resultset will return the cached objects rather
2328 than re-querying the database even if the cache attr is not set.
2329
2330 The contents of the cache can also be populated by using the
2331 L</prefetch> attribute to L</search>.
2332
2333 =cut
2334
2335 sub set_cache {
2336   my ( $self, $data ) = @_;
2337   $self->throw_exception("set_cache requires an arrayref")
2338       if defined($data) && (ref $data ne 'ARRAY');
2339   $self->{all_cache} = $data;
2340 }
2341
2342 =head2 clear_cache
2343
2344 =over 4
2345
2346 =item Arguments: none
2347
2348 =item Return Value: []
2349
2350 =back
2351
2352 Clears the cache for the resultset.
2353
2354 =cut
2355
2356 sub clear_cache {
2357   shift->set_cache(undef);
2358 }
2359
2360 =head2 related_resultset
2361
2362 =over 4
2363
2364 =item Arguments: $relationship_name
2365
2366 =item Return Value: $resultset
2367
2368 =back
2369
2370 Returns a related resultset for the supplied relationship name.
2371
2372   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2373
2374 =cut
2375
2376 sub related_resultset {
2377   my ($self, $rel) = @_;
2378
2379   $self->{related_resultsets} ||= {};
2380   return $self->{related_resultsets}{$rel} ||= do {
2381     my $rel_obj = $self->result_source->relationship_info($rel);
2382
2383     $self->throw_exception(
2384       "search_related: result source '" . $self->result_source->source_name .
2385         "' has no such relationship $rel")
2386       unless $rel_obj;
2387
2388     my ($from,$seen) = $self->_resolve_from($rel);
2389
2390     my $join_count = $seen->{$rel};
2391     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2392
2393     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2394     my %attrs = %{$self->{attrs}||{}};
2395     delete @attrs{qw(result_class alias)};
2396
2397     my $new_cache;
2398
2399     if (my $cache = $self->get_cache) {
2400       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2401         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2402                         @$cache ];
2403       }
2404     }
2405
2406     my $rel_source = $self->result_source->related_source($rel);
2407
2408     my $new = do {
2409
2410       # The reason we do this now instead of passing the alias to the
2411       # search_rs below is that if you wrap/overload resultset on the
2412       # source you need to know what alias it's -going- to have for things
2413       # to work sanely (e.g. RestrictWithObject wants to be able to add
2414       # extra query restrictions, and these may need to be $alias.)
2415
2416       my $attrs = $rel_source->resultset_attributes;
2417       local $attrs->{alias} = $alias;
2418
2419       $rel_source->resultset
2420                  ->search_rs(
2421                      undef, {
2422                        %attrs,
2423                        join => undef,
2424                        prefetch => undef,
2425                        select => undef,
2426                        as => undef,
2427                        where => $self->{cond},
2428                        seen_join => $seen,
2429                        from => $from,
2430                    });
2431     };
2432     $new->set_cache($new_cache) if $new_cache;
2433     $new;
2434   };
2435 }
2436
2437 =head2 current_source_alias
2438
2439 =over 4
2440
2441 =item Arguments: none
2442
2443 =item Return Value: $source_alias
2444
2445 =back
2446
2447 Returns the current table alias for the result source this resultset is built
2448 on, that will be used in the SQL query. Usually it is C<me>.
2449
2450 Currently the source alias that refers to the result set returned by a
2451 L</search>/L</find> family method depends on how you got to the resultset: it's
2452 C<me> by default, but eg. L</search_related> aliases it to the related result
2453 source name (and keeps C<me> referring to the original result set). The long
2454 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2455 (and make this method unnecessary).
2456
2457 Thus it's currently necessary to use this method in predefined queries (see
2458 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2459 source alias of the current result set:
2460
2461   # in a result set class
2462   sub modified_by {
2463     my ($self, $user) = @_;
2464
2465     my $me = $self->current_source_alias;
2466
2467     return $self->search(
2468       "$me.modified" => $user->id,
2469     );
2470   }
2471
2472 =cut
2473
2474 sub current_source_alias {
2475   my ($self) = @_;
2476
2477   return ($self->{attrs} || {})->{alias} || 'me';
2478 }
2479
2480 # This code is called by search_related, and makes sure there
2481 # is clear separation between the joins before, during, and
2482 # after the relationship. This information is needed later
2483 # in order to properly resolve prefetch aliases (any alias
2484 # with a relation_chain_depth less than the depth of the
2485 # current prefetch is not considered)
2486 sub _resolve_from {
2487   my ($self, $extra_join) = @_;
2488   my $source = $self->result_source;
2489   my $attrs = $self->{attrs};
2490
2491   my $from = $attrs->{from}
2492     || [ { $attrs->{alias} => $source->from } ];
2493
2494   my $seen = { %{$attrs->{seen_join}||{}} };
2495
2496   # we need to take the prefetch the attrs into account before we
2497   # ->_resolve_join as otherwise they get lost - captainL
2498   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2499
2500   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2501
2502   ++$seen->{-relation_chain_depth};
2503
2504   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2505
2506   ++$seen->{-relation_chain_depth};
2507
2508   return ($from,$seen);
2509 }
2510
2511 sub _resolved_attrs {
2512   my $self = shift;
2513   return $self->{_attrs} if $self->{_attrs};
2514
2515   my $attrs  = { %{ $self->{attrs} || {} } };
2516   my $source = $self->result_source;
2517   my $alias  = $attrs->{alias};
2518
2519   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2520   my @colbits;
2521
2522   # build columns (as long as select isn't set) into a set of as/select hashes
2523   unless ( $attrs->{select} ) {
2524       @colbits = map {
2525           ( ref($_) eq 'HASH' )
2526               ? $_
2527               : {
2528                   (
2529                     /^\Q${alias}.\E(.+)$/
2530                       ? "$1"
2531                       : "$_"
2532                   )
2533                 =>
2534                   (
2535                     /\./
2536                       ? "$_"
2537                       : "${alias}.$_"
2538                   )
2539             }
2540       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2541   }
2542   # add the additional columns on
2543   foreach ( 'include_columns', '+columns' ) {
2544       push @colbits, map {
2545           ( ref($_) eq 'HASH' )
2546             ? $_
2547             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2548       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2549   }
2550
2551   # start with initial select items
2552   if ( $attrs->{select} ) {
2553     $attrs->{select} =
2554         ( ref $attrs->{select} eq 'ARRAY' )
2555       ? [ @{ $attrs->{select} } ]
2556       : [ $attrs->{select} ];
2557     $attrs->{as} = (
2558       $attrs->{as}
2559       ? (
2560         ref $attrs->{as} eq 'ARRAY'
2561         ? [ @{ $attrs->{as} } ]
2562         : [ $attrs->{as} ]
2563         )
2564       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2565     );
2566   }
2567   else {
2568
2569     # otherwise we intialise select & as to empty
2570     $attrs->{select} = [];
2571     $attrs->{as}     = [];
2572   }
2573
2574   # now add colbits to select/as
2575   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2576   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2577
2578   my $adds;
2579   if ( $adds = delete $attrs->{'+select'} ) {
2580     $adds = [$adds] unless ref $adds eq 'ARRAY';
2581     push(
2582       @{ $attrs->{select} },
2583       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2584     );
2585   }
2586   if ( $adds = delete $attrs->{'+as'} ) {
2587     $adds = [$adds] unless ref $adds eq 'ARRAY';
2588     push( @{ $attrs->{as} }, @$adds );
2589   }
2590
2591   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2592
2593   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2594     my $join = delete $attrs->{join} || {};
2595
2596     if ( defined $attrs->{prefetch} ) {
2597       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2598
2599     }
2600
2601     $attrs->{from} =    # have to copy here to avoid corrupting the original
2602       [
2603       @{ $attrs->{from} },
2604       $source->_resolve_join(
2605         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2606       )
2607       ];
2608
2609   }
2610
2611   $attrs->{group_by} ||= $attrs->{select}
2612     if delete $attrs->{distinct};
2613   if ( $attrs->{order_by} ) {
2614     $attrs->{order_by} = (
2615       ref( $attrs->{order_by} ) eq 'ARRAY'
2616       ? [ @{ $attrs->{order_by} } ]
2617       : [ $attrs->{order_by} ]
2618     );
2619   }
2620   else {
2621     $attrs->{order_by} = [];
2622   }
2623
2624   my $collapse = $attrs->{collapse} || {};
2625   if ( my $prefetch = delete $attrs->{prefetch} ) {
2626     $prefetch = $self->_merge_attr( {}, $prefetch );
2627     my @pre_order;
2628     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2629
2630       # bring joins back to level of current class
2631       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2632       my @prefetch =
2633         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2634       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2635       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2636     }
2637     push( @{ $attrs->{order_by} }, @pre_order );
2638   }
2639   $attrs->{collapse} = $collapse;
2640
2641   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2642     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2643   }
2644
2645   return $self->{_attrs} = $attrs;
2646 }
2647
2648 sub _joinpath_aliases {
2649   my ($self, $fromspec, $seen) = @_;
2650
2651   my $paths = {};
2652   return $paths unless ref $fromspec eq 'ARRAY';
2653
2654   for my $j (@$fromspec) {
2655
2656     next if ref $j ne 'ARRAY';
2657     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2658
2659     my $p = $paths;
2660     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2661     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2662   }
2663
2664   return $paths;
2665 }
2666
2667 sub _rollout_attr {
2668   my ($self, $attr) = @_;
2669
2670   if (ref $attr eq 'HASH') {
2671     return $self->_rollout_hash($attr);
2672   } elsif (ref $attr eq 'ARRAY') {
2673     return $self->_rollout_array($attr);
2674   } else {
2675     return [$attr];
2676   }
2677 }
2678
2679 sub _rollout_array {
2680   my ($self, $attr) = @_;
2681
2682   my @rolled_array;
2683   foreach my $element (@{$attr}) {
2684     if (ref $element eq 'HASH') {
2685       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2686     } elsif (ref $element eq 'ARRAY') {
2687       #  XXX - should probably recurse here
2688       push( @rolled_array, @{$self->_rollout_array($element)} );
2689     } else {
2690       push( @rolled_array, $element );
2691     }
2692   }
2693   return \@rolled_array;
2694 }
2695
2696 sub _rollout_hash {
2697   my ($self, $attr) = @_;
2698
2699   my @rolled_array;
2700   foreach my $key (keys %{$attr}) {
2701     push( @rolled_array, { $key => $attr->{$key} } );
2702   }
2703   return \@rolled_array;
2704 }
2705
2706 sub _calculate_score {
2707   my ($self, $a, $b) = @_;
2708
2709   if (ref $b eq 'HASH') {
2710     my ($b_key) = keys %{$b};
2711     if (ref $a eq 'HASH') {
2712       my ($a_key) = keys %{$a};
2713       if ($a_key eq $b_key) {
2714         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2715       } else {
2716         return 0;
2717       }
2718     } else {
2719       return ($a eq $b_key) ? 1 : 0;
2720     }
2721   } else {
2722     if (ref $a eq 'HASH') {
2723       my ($a_key) = keys %{$a};
2724       return ($b eq $a_key) ? 1 : 0;
2725     } else {
2726       return ($b eq $a) ? 1 : 0;
2727     }
2728   }
2729 }
2730
2731 sub _merge_attr {
2732   my ($self, $orig, $import) = @_;
2733
2734   return $import unless defined($orig);
2735   return $orig unless defined($import);
2736
2737   $orig = $self->_rollout_attr($orig);
2738   $import = $self->_rollout_attr($import);
2739
2740   my $seen_keys;
2741   foreach my $import_element ( @{$import} ) {
2742     # find best candidate from $orig to merge $b_element into
2743     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2744     foreach my $orig_element ( @{$orig} ) {
2745       my $score = $self->_calculate_score( $orig_element, $import_element );
2746       if ($score > $best_candidate->{score}) {
2747         $best_candidate->{position} = $position;
2748         $best_candidate->{score} = $score;
2749       }
2750       $position++;
2751     }
2752     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2753
2754     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2755       push( @{$orig}, $import_element );
2756     } else {
2757       my $orig_best = $orig->[$best_candidate->{position}];
2758       # merge orig_best and b_element together and replace original with merged
2759       if (ref $orig_best ne 'HASH') {
2760         $orig->[$best_candidate->{position}] = $import_element;
2761       } elsif (ref $import_element eq 'HASH') {
2762         my ($key) = keys %{$orig_best};
2763         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2764       }
2765     }
2766     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2767   }
2768
2769   return $orig;
2770 }
2771
2772 sub result_source {
2773     my $self = shift;
2774
2775     if (@_) {
2776         $self->_source_handle($_[0]->handle);
2777     } else {
2778         $self->_source_handle->resolve;
2779     }
2780 }
2781
2782 =head2 throw_exception
2783
2784 See L<DBIx::Class::Schema/throw_exception> for details.
2785
2786 =cut
2787
2788 sub throw_exception {
2789   my $self=shift;
2790   if (ref $self && $self->_source_handle->schema) {
2791     $self->_source_handle->schema->throw_exception(@_)
2792   } else {
2793     croak(@_);
2794   }
2795
2796 }
2797
2798 # XXX: FIXME: Attributes docs need clearing up
2799
2800 =head1 ATTRIBUTES
2801
2802 Attributes are used to refine a ResultSet in various ways when
2803 searching for data. They can be passed to any method which takes an
2804 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2805 L</count>.
2806
2807 These are in no particular order:
2808
2809 =head2 order_by
2810
2811 =over 4
2812
2813 =item Value: ( $order_by | \@order_by | \%order_by )
2814
2815 =back
2816
2817 Which column(s) to order the results by. If a single column name, or
2818 an arrayref of names is supplied, the argument is passed through
2819 directly to SQL. The hashref syntax allows for connection-agnostic
2820 specification of ordering direction:
2821
2822  For descending order:
2823
2824   order_by => { -desc => [qw/col1 col2 col3/] }
2825
2826  For explicit ascending order:
2827
2828   order_by => { -asc => 'col' }
2829
2830 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2831 supported, although you are strongly encouraged to use the hashref
2832 syntax as outlined above.
2833
2834 =head2 columns
2835
2836 =over 4
2837
2838 =item Value: \@columns
2839
2840 =back
2841
2842 Shortcut to request a particular set of columns to be retrieved. Each
2843 column spec may be a string (a table column name), or a hash (in which
2844 case the key is the C<as> value, and the value is used as the C<select>
2845 expression). Adds C<me.> onto the start of any column without a C<.> in
2846 it and sets C<select> from that, then auto-populates C<as> from
2847 C<select> as normal. (You may also use the C<cols> attribute, as in
2848 earlier versions of DBIC.)
2849
2850 =head2 +columns
2851
2852 =over 4
2853
2854 =item Value: \@columns
2855
2856 =back
2857
2858 Indicates additional columns to be selected from storage. Works the same
2859 as L</columns> but adds columns to the selection. (You may also use the
2860 C<include_columns> attribute, as in earlier versions of DBIC). For
2861 example:-
2862
2863   $schema->resultset('CD')->search(undef, {
2864     '+columns' => ['artist.name'],
2865     join => ['artist']
2866   });
2867
2868 would return all CDs and include a 'name' column to the information
2869 passed to object inflation. Note that the 'artist' is the name of the
2870 column (or relationship) accessor, and 'name' is the name of the column
2871 accessor in the related table.
2872
2873 =head2 include_columns
2874
2875 =over 4
2876
2877 =item Value: \@columns
2878
2879 =back
2880
2881 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2882
2883 =head2 select
2884
2885 =over 4
2886
2887 =item Value: \@select_columns
2888
2889 =back
2890
2891 Indicates which columns should be selected from the storage. You can use
2892 column names, or in the case of RDBMS back ends, function or stored procedure
2893 names:
2894
2895   $rs = $schema->resultset('Employee')->search(undef, {
2896     select => [
2897       'name',
2898       { count => 'employeeid' },
2899       { sum => 'salary' }
2900     ]
2901   });
2902
2903 When you use function/stored procedure names and do not supply an C<as>
2904 attribute, the column names returned are storage-dependent. E.g. MySQL would
2905 return a column named C<count(employeeid)> in the above example.
2906
2907 =head2 +select
2908
2909 =over 4
2910
2911 Indicates additional columns to be selected from storage.  Works the same as
2912 L</select> but adds columns to the selection.
2913
2914 =back
2915
2916 =head2 +as
2917
2918 =over 4
2919
2920 Indicates additional column names for those added via L</+select>. See L</as>.
2921
2922 =back
2923
2924 =head2 as
2925
2926 =over 4
2927
2928 =item Value: \@inflation_names
2929
2930 =back
2931
2932 Indicates column names for object inflation. That is, C<as>
2933 indicates the name that the column can be accessed as via the
2934 C<get_column> method (or via the object accessor, B<if one already
2935 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2936
2937 The C<as> attribute is used in conjunction with C<select>,
2938 usually when C<select> contains one or more function or stored
2939 procedure names:
2940
2941   $rs = $schema->resultset('Employee')->search(undef, {
2942     select => [
2943       'name',
2944       { count => 'employeeid' }
2945     ],
2946     as => ['name', 'employee_count'],
2947   });
2948
2949   my $employee = $rs->first(); # get the first Employee
2950
2951 If the object against which the search is performed already has an accessor
2952 matching a column name specified in C<as>, the value can be retrieved using
2953 the accessor as normal:
2954
2955   my $name = $employee->name();
2956
2957 If on the other hand an accessor does not exist in the object, you need to
2958 use C<get_column> instead:
2959
2960   my $employee_count = $employee->get_column('employee_count');
2961
2962 You can create your own accessors if required - see
2963 L<DBIx::Class::Manual::Cookbook> for details.
2964
2965 Please note: This will NOT insert an C<AS employee_count> into the SQL
2966 statement produced, it is used for internal access only. Thus
2967 attempting to use the accessor in an C<order_by> clause or similar
2968 will fail miserably.
2969
2970 To get around this limitation, you can supply literal SQL to your
2971 C<select> attibute that contains the C<AS alias> text, eg:
2972
2973   select => [\'myfield AS alias']
2974
2975 =head2 join
2976
2977 =over 4
2978
2979 =item Value: ($rel_name | \@rel_names | \%rel_names)
2980
2981 =back
2982
2983 Contains a list of relationships that should be joined for this query.  For
2984 example:
2985
2986   # Get CDs by Nine Inch Nails
2987   my $rs = $schema->resultset('CD')->search(
2988     { 'artist.name' => 'Nine Inch Nails' },
2989     { join => 'artist' }
2990   );
2991
2992 Can also contain a hash reference to refer to the other relation's relations.
2993 For example:
2994
2995   package MyApp::Schema::Track;
2996   use base qw/DBIx::Class/;
2997   __PACKAGE__->table('track');
2998   __PACKAGE__->add_columns(qw/trackid cd position title/);
2999   __PACKAGE__->set_primary_key('trackid');
3000   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3001   1;
3002
3003   # In your application
3004   my $rs = $schema->resultset('Artist')->search(
3005     { 'track.title' => 'Teardrop' },
3006     {
3007       join     => { cd => 'track' },
3008       order_by => 'artist.name',
3009     }
3010   );
3011
3012 You need to use the relationship (not the table) name in  conditions,
3013 because they are aliased as such. The current table is aliased as "me", so
3014 you need to use me.column_name in order to avoid ambiguity. For example:
3015
3016   # Get CDs from 1984 with a 'Foo' track
3017   my $rs = $schema->resultset('CD')->search(
3018     {
3019       'me.year' => 1984,
3020       'tracks.name' => 'Foo'
3021     },
3022     { join => 'tracks' }
3023   );
3024
3025 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3026 similarly for a third time). For e.g.
3027
3028   my $rs = $schema->resultset('Artist')->search({
3029     'cds.title'   => 'Down to Earth',
3030     'cds_2.title' => 'Popular',
3031   }, {
3032     join => [ qw/cds cds/ ],
3033   });
3034
3035 will return a set of all artists that have both a cd with title 'Down
3036 to Earth' and a cd with title 'Popular'.
3037
3038 If you want to fetch related objects from other tables as well, see C<prefetch>
3039 below.
3040
3041 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3042
3043 =head2 prefetch
3044
3045 =over 4
3046
3047 =item Value: ($rel_name | \@rel_names | \%rel_names)
3048
3049 =back
3050
3051 Contains one or more relationships that should be fetched along with
3052 the main query (when they are accessed afterwards the data will
3053 already be available, without extra queries to the database).  This is
3054 useful for when you know you will need the related objects, because it
3055 saves at least one query:
3056
3057   my $rs = $schema->resultset('Tag')->search(
3058     undef,
3059     {
3060       prefetch => {
3061         cd => 'artist'
3062       }
3063     }
3064   );
3065
3066 The initial search results in SQL like the following:
3067
3068   SELECT tag.*, cd.*, artist.* FROM tag
3069   JOIN cd ON tag.cd = cd.cdid
3070   JOIN artist ON cd.artist = artist.artistid
3071
3072 L<DBIx::Class> has no need to go back to the database when we access the
3073 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3074 case.
3075
3076 Simple prefetches will be joined automatically, so there is no need
3077 for a C<join> attribute in the above search.
3078
3079 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3080 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3081 with an accessor type of 'single' or 'filter'). A more complex example that
3082 prefetches an artists cds, the tracks on those cds, and the tags associted
3083 with that artist is given below (assuming many-to-many from artists to tags):
3084
3085  my $rs = $schema->resultset('Artist')->search(
3086    undef,
3087    {
3088      prefetch => [
3089        { cds => 'tracks' },
3090        { artist_tags => 'tags' }
3091      ]
3092    }
3093  );
3094
3095
3096 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3097 attributes will be ignored.
3098
3099 =head2 page
3100
3101 =over 4
3102
3103 =item Value: $page
3104
3105 =back
3106
3107 Makes the resultset paged and specifies the page to retrieve. Effectively
3108 identical to creating a non-pages resultset and then calling ->page($page)
3109 on it.
3110
3111 If L<rows> attribute is not specified it defualts to 10 rows per page.
3112
3113 When you have a paged resultset, L</count> will only return the number
3114 of rows in the page. To get the total, use the L</pager> and call
3115 C<total_entries> on it.
3116
3117 =head2 rows
3118
3119 =over 4
3120
3121 =item Value: $rows
3122
3123 =back
3124
3125 Specifes the maximum number of rows for direct retrieval or the number of
3126 rows per page if the page attribute or method is used.
3127
3128 =head2 offset
3129
3130 =over 4
3131
3132 =item Value: $offset
3133
3134 =back
3135
3136 Specifies the (zero-based) row number for the  first row to be returned, or the
3137 of the first row of the first page if paging is used.
3138
3139 =head2 group_by
3140
3141 =over 4
3142
3143 =item Value: \@columns
3144
3145 =back
3146
3147 A arrayref of columns to group by. Can include columns of joined tables.
3148
3149   group_by => [qw/ column1 column2 ... /]
3150
3151 =head2 having
3152
3153 =over 4
3154
3155 =item Value: $condition
3156
3157 =back
3158
3159 HAVING is a select statement attribute that is applied between GROUP BY and
3160 ORDER BY. It is applied to the after the grouping calculations have been
3161 done.
3162
3163   having => { 'count(employee)' => { '>=', 100 } }
3164
3165 =head2 distinct
3166
3167 =over 4
3168
3169 =item Value: (0 | 1)
3170
3171 =back
3172
3173 Set to 1 to group by all columns.
3174
3175 =head2 where
3176
3177 =over 4
3178
3179 Adds to the WHERE clause.
3180
3181   # only return rows WHERE deleted IS NULL for all searches
3182   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3183
3184 Can be overridden by passing C<{ where => undef }> as an attribute
3185 to a resulset.
3186
3187 =back
3188
3189 =head2 cache
3190
3191 Set to 1 to cache search results. This prevents extra SQL queries if you
3192 revisit rows in your ResultSet:
3193
3194   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3195
3196   while( my $artist = $resultset->next ) {
3197     ... do stuff ...
3198   }
3199
3200   $rs->first; # without cache, this would issue a query
3201
3202 By default, searches are not cached.
3203
3204 For more examples of using these attributes, see
3205 L<DBIx::Class::Manual::Cookbook>.
3206
3207 =head2 from
3208
3209 =over 4
3210
3211 =item Value: \@from_clause
3212
3213 =back
3214
3215 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3216 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3217 clauses.
3218
3219 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3220
3221 C<join> will usually do what you need and it is strongly recommended that you
3222 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3223 And we really do mean "cannot", not just tried and failed. Attempting to use
3224 this because you're having problems with C<join> is like trying to use x86
3225 ASM because you've got a syntax error in your C. Trust us on this.
3226
3227 Now, if you're still really, really sure you need to use this (and if you're
3228 not 100% sure, ask the mailing list first), here's an explanation of how this
3229 works.
3230
3231 The syntax is as follows -
3232
3233   [
3234     { <alias1> => <table1> },
3235     [
3236       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3237       [], # nested JOIN (optional)
3238       { <table1.column1> => <table2.column2>, ... (more conditions) },
3239     ],
3240     # More of the above [ ] may follow for additional joins
3241   ]
3242
3243   <table1> <alias1>
3244   JOIN
3245     <table2> <alias2>
3246     [JOIN ...]
3247   ON <table1.column1> = <table2.column2>
3248   <more joins may follow>
3249
3250 An easy way to follow the examples below is to remember the following:
3251
3252     Anything inside "[]" is a JOIN
3253     Anything inside "{}" is a condition for the enclosing JOIN
3254
3255 The following examples utilize a "person" table in a family tree application.
3256 In order to express parent->child relationships, this table is self-joined:
3257
3258     # Person->belongs_to('father' => 'Person');
3259     # Person->belongs_to('mother' => 'Person');
3260
3261 C<from> can be used to nest joins. Here we return all children with a father,
3262 then search against all mothers of those children:
3263
3264   $rs = $schema->resultset('Person')->search(
3265       undef,
3266       {
3267           alias => 'mother', # alias columns in accordance with "from"
3268           from => [
3269               { mother => 'person' },
3270               [
3271                   [
3272                       { child => 'person' },
3273                       [
3274                           { father => 'person' },
3275                           { 'father.person_id' => 'child.father_id' }
3276                       ]
3277                   ],
3278                   { 'mother.person_id' => 'child.mother_id' }
3279               ],
3280           ]
3281       },
3282   );
3283
3284   # Equivalent SQL:
3285   # SELECT mother.* FROM person mother
3286   # JOIN (
3287   #   person child
3288   #   JOIN person father
3289   #   ON ( father.person_id = child.father_id )
3290   # )
3291   # ON ( mother.person_id = child.mother_id )
3292
3293 The type of any join can be controlled manually. To search against only people
3294 with a father in the person table, we could explicitly use C<INNER JOIN>:
3295
3296     $rs = $schema->resultset('Person')->search(
3297         undef,
3298         {
3299             alias => 'child', # alias columns in accordance with "from"
3300             from => [
3301                 { child => 'person' },
3302                 [
3303                     { father => 'person', -join_type => 'inner' },
3304                     { 'father.id' => 'child.father_id' }
3305                 ],
3306             ]
3307         },
3308     );
3309
3310     # Equivalent SQL:
3311     # SELECT child.* FROM person child
3312     # INNER JOIN person father ON child.father_id = father.id
3313
3314 If you need to express really complex joins or you need a subselect, you
3315 can supply literal SQL to C<from> via a scalar reference. In this case
3316 the contents of the scalar will replace the table name asscoiated with the
3317 resultsource.
3318
3319 WARNING: This technique might very well not work as expected on chained
3320 searches - you have been warned.
3321
3322     # Assuming the Event resultsource is defined as:
3323
3324         MySchema::Event->add_columns (
3325             sequence => {
3326                 data_type => 'INT',
3327                 is_auto_increment => 1,
3328             },
3329             location => {
3330                 data_type => 'INT',
3331             },
3332             type => {
3333                 data_type => 'INT',
3334             },
3335         );
3336         MySchema::Event->set_primary_key ('sequence');
3337
3338     # This will get back the latest event for every location. The column
3339     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3340     # combo to limit the resultset
3341
3342     $rs = $schema->resultset('Event');
3343     $table = $rs->result_source->name;
3344     $latest = $rs->search (
3345         undef,
3346         { from => \ "
3347             (SELECT e1.* FROM $table e1
3348                 JOIN $table e2
3349                     ON e1.location = e2.location
3350                     AND e1.sequence < e2.sequence
3351                 WHERE e2.sequence is NULL
3352             ) me",
3353         },
3354     );
3355
3356     # Equivalent SQL (with the DBIC chunks added):
3357
3358     SELECT me.sequence, me.location, me.type FROM
3359        (SELECT e1.* FROM events e1
3360            JOIN events e2
3361                ON e1.location = e2.location
3362                AND e1.sequence < e2.sequence
3363            WHERE e2.sequence is NULL
3364        ) me;
3365
3366 =head2 for
3367
3368 =over 4
3369
3370 =item Value: ( 'update' | 'shared' )
3371
3372 =back
3373
3374 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3375 ... FOR SHARED.
3376
3377 =cut
3378
3379 1;