lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360
 361   $rs->set_cache($rows) if ($rows);
 362
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   # if the first row that ever came in is totally empty - this means we got
 978   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 979   # instead of producing a {}
 980   #
 981   my $has_def;
 982   for (@$row) {
 983     if (defined $_) {
 984       $has_def++;
 985       last;
 986     }
 987   }
 988   return undef unless $has_def;
 989
 990   my @copy = @$row;
 991
 992   # 'foo'         => [ undef, 'foo' ]
 993   # 'foo.bar'     => [ 'foo', 'bar' ]
 994   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 995
 996   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 997
 998   my %collapse = %{$self->{_attrs}{collapse}||{}};
 999
1000   my @pri_index;
1001
1002   # if we're doing collapsing (has_many prefetch) we need to grab records
1003   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1004   # we know we don't have to bother.
1005
1006   # the reason for not using the collapse stuff directly is because if you
1007   # had for e.g. two artists in a row with no cds, the collapse info for
1008   # both would be NULL (undef) so you'd lose the second artist
1009
1010   # store just the index so we can check the array positions from the row
1011   # without having to contruct the full hash
1012
1013   if (keys %collapse) {
1014     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1015     foreach my $i (0 .. $#construct_as) {
1016       next if defined($construct_as[$i][0]); # only self table
1017       if (delete $pri{$construct_as[$i][1]}) {
1018         push(@pri_index, $i);
1019       }
1020       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1021     }
1022   }
1023
1024   # no need to do an if, it'll be empty if @pri_index is empty anyway
1025
1026   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1027
1028   my @const_rows;
1029
1030   do { # no need to check anything at the front, we always want the first row
1031
1032     my %const;
1033
1034     foreach my $this_as (@construct_as) {
1035       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1036     }
1037
1038     push(@const_rows, \%const);
1039
1040   } until ( # no pri_index => no collapse => drop straight out
1041       !@pri_index
1042     or
1043       do { # get another row, stash it, drop out if different PK
1044
1045         @copy = $self->cursor->next;
1046         $self->{stashed_row} = \@copy;
1047
1048         # last thing in do block, counts as true if anything doesn't match
1049
1050         # check xor defined first for NULL vs. NOT NULL then if one is
1051         # defined the other must be so check string equality
1052
1053         grep {
1054           (defined $pri_vals{$_} ^ defined $copy[$_])
1055           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1056         } @pri_index;
1057       }
1058   );
1059
1060   my $alias = $self->{attrs}{alias};
1061   my $info = [];
1062
1063   my %collapse_pos;
1064
1065   my @const_keys;
1066
1067   foreach my $const (@const_rows) {
1068     scalar @const_keys or do {
1069       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1070     };
1071     foreach my $key (@const_keys) {
1072       if (length $key) {
1073         my $target = $info;
1074         my @parts = split(/\./, $key);
1075         my $cur = '';
1076         my $data = $const->{$key};
1077         foreach my $p (@parts) {
1078           $target = $target->[1]->{$p} ||= [];
1079           $cur .= ".${p}";
1080           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1081             # collapsing at this point and on final part
1082             my $pos = $collapse_pos{$cur};
1083             CK: foreach my $ck (@ckey) {
1084               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1085                 $collapse_pos{$cur} = $data;
1086                 delete @collapse_pos{ # clear all positioning for sub-entries
1087                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1088                 };
1089                 push(@$target, []);
1090                 last CK;
1091               }
1092             }
1093           }
1094           if (exists $collapse{$cur}) {
1095             $target = $target->[-1];
1096           }
1097         }
1098         $target->[0] = $data;
1099       } else {
1100         $info->[0] = $const->{$key};
1101       }
1102     }
1103   }
1104
1105   return $info;
1106 }
1107
1108 =head2 result_source
1109
1110 =over 4
1111
1112 =item Arguments: $result_source?
1113
1114 =item Return Value: $result_source
1115
1116 =back
1117
1118 An accessor for the primary ResultSource object from which this ResultSet
1119 is derived.
1120
1121 =head2 result_class
1122
1123 =over 4
1124
1125 =item Arguments: $result_class?
1126
1127 =item Return Value: $result_class
1128
1129 =back
1130
1131 An accessor for the class to use when creating row objects. Defaults to
1132 C<< result_source->result_class >> - which in most cases is the name of the
1133 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1134
1135 Note that changing the result_class will also remove any components
1136 that were originally loaded in the source class via
1137 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1138 in the original source class will not run.
1139
1140 =cut
1141
1142 sub result_class {
1143   my ($self, $result_class) = @_;
1144   if ($result_class) {
1145     $self->ensure_class_loaded($result_class);
1146     $self->_result_class($result_class);
1147   }
1148   $self->_result_class;
1149 }
1150
1151 =head2 count
1152
1153 =over 4
1154
1155 =item Arguments: $cond, \%attrs??
1156
1157 =item Return Value: $count
1158
1159 =back
1160
1161 Performs an SQL C<COUNT> with the same query as the resultset was built
1162 with to find the number of elements. Passing arguments is equivalent to
1163 C<< $rs->search ($cond, \%attrs)->count >>
1164
1165 =cut
1166
1167 sub count {
1168   my $self = shift;
1169   return $self->search(@_)->count if @_ and defined $_[0];
1170   return scalar @{ $self->get_cache } if $self->get_cache;
1171
1172   my $attrs = $self->_resolved_attrs_copy;
1173
1174   # this is a little optimization - it is faster to do the limit
1175   # adjustments in software, instead of a subquery
1176   my $rows = delete $attrs->{rows};
1177   my $offset = delete $attrs->{offset};
1178
1179   my $crs;
1180   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1181     $crs = $self->_count_subq_rs ($attrs);
1182   }
1183   else {
1184     $crs = $self->_count_rs ($attrs);
1185   }
1186   my $count = $crs->next;
1187
1188   $count -= $offset if $offset;
1189   $count = $rows if $rows and $rows < $count;
1190   $count = 0 if ($count < 0);
1191
1192   return $count;
1193 }
1194
1195 =head2 count_rs
1196
1197 =over 4
1198
1199 =item Arguments: $cond, \%attrs??
1200
1201 =item Return Value: $count_rs
1202
1203 =back
1204
1205 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1206 This can be very handy for subqueries:
1207
1208   ->search( { amount => $some_rs->count_rs->as_query } )
1209
1210 As with regular resultsets the SQL query will be executed only after
1211 the resultset is accessed via L</next> or L</all>. That would return
1212 the same single value obtainable via L</count>.
1213
1214 =cut
1215
1216 sub count_rs {
1217   my $self = shift;
1218   return $self->search(@_)->count_rs if @_;
1219
1220   # this may look like a lack of abstraction (count() does about the same)
1221   # but in fact an _rs *must* use a subquery for the limits, as the
1222   # software based limiting can not be ported if this $rs is to be used
1223   # in a subquery itself (i.e. ->as_query)
1224   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1225     return $self->_count_subq_rs;
1226   }
1227   else {
1228     return $self->_count_rs;
1229   }
1230 }
1231
1232 #
1233 # returns a ResultSetColumn object tied to the count query
1234 #
1235 sub _count_rs {
1236   my ($self, $attrs) = @_;
1237
1238   my $rsrc = $self->result_source;
1239   $attrs ||= $self->_resolved_attrs;
1240
1241   my $tmp_attrs = { %$attrs };
1242
1243   # take off any limits, record_filter is cdbi, and no point of ordering a count
1244   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   # read the comment on top of the actual function to see what this does
1251   $tmp_attrs->{from} = $self->result_source->schema->storage->_straight_join_to_node (
1252     $tmp_attrs->{from}, $tmp_attrs->{alias}
1253   );
1254
1255   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1256
1257   return $tmp_rs;
1258 }
1259
1260 #
1261 # same as above but uses a subquery
1262 #
1263 sub _count_subq_rs {
1264   my ($self, $attrs) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   $attrs ||= $self->_resolved_attrs_copy;
1268
1269   my $sub_attrs = { %$attrs };
1270
1271   # extra selectors do not go in the subquery and there is no point of ordering it
1272   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1273
1274   # if we prefetch, we group_by primary keys only as this is what we would get out
1275   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1276   if ( keys %{$attrs->{collapse}} ) {
1277     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1278   }
1279
1280   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1281
1282   # read the comment on top of the actual function to see what this does
1283   $sub_attrs->{from} = $self->result_source->schema->storage->_straight_join_to_node (
1284     $sub_attrs->{from}, $sub_attrs->{alias}
1285   );
1286
1287   # this is so that the query can be simplified e.g.
1288   # * non-limiting joins can be pruned
1289   # * ordering can be thrown away in things like Top limit
1290   $sub_attrs->{-for_count_only} = 1;
1291
1292   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1293
1294   $attrs->{from} = [{
1295     -alias => 'count_subq',
1296     -source_handle => $rsrc->handle,
1297     count_subq => $sub_rs->as_query,
1298   }];
1299
1300   # the subquery replaces this
1301   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1302
1303   return $self->_count_rs ($attrs);
1304 }
1305
1306 sub _bool {
1307   return 1;
1308 }
1309
1310 =head2 count_literal
1311
1312 =over 4
1313
1314 =item Arguments: $sql_fragment, @bind_values
1315
1316 =item Return Value: $count
1317
1318 =back
1319
1320 Counts the results in a literal query. Equivalent to calling L</search_literal>
1321 with the passed arguments, then L</count>.
1322
1323 =cut
1324
1325 sub count_literal { shift->search_literal(@_)->count; }
1326
1327 =head2 all
1328
1329 =over 4
1330
1331 =item Arguments: none
1332
1333 =item Return Value: @objects
1334
1335 =back
1336
1337 Returns all elements in the resultset. Called implicitly if the resultset
1338 is returned in list context.
1339
1340 =cut
1341
1342 sub all {
1343   my $self = shift;
1344   if(@_) {
1345       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1346   }
1347
1348   return @{ $self->get_cache } if $self->get_cache;
1349
1350   my @obj;
1351
1352   if (keys %{$self->_resolved_attrs->{collapse}}) {
1353     # Using $self->cursor->all is really just an optimisation.
1354     # If we're collapsing has_many prefetches it probably makes
1355     # very little difference, and this is cleaner than hacking
1356     # _construct_object to survive the approach
1357     $self->cursor->reset;
1358     my @row = $self->cursor->next;
1359     while (@row) {
1360       push(@obj, $self->_construct_object(@row));
1361       @row = (exists $self->{stashed_row}
1362                ? @{delete $self->{stashed_row}}
1363                : $self->cursor->next);
1364     }
1365   } else {
1366     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1367   }
1368
1369   $self->set_cache(\@obj) if $self->{attrs}{cache};
1370
1371   return @obj;
1372 }
1373
1374 =head2 reset
1375
1376 =over 4
1377
1378 =item Arguments: none
1379
1380 =item Return Value: $self
1381
1382 =back
1383
1384 Resets the resultset's cursor, so you can iterate through the elements again.
1385 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1386 another query.
1387
1388 =cut
1389
1390 sub reset {
1391   my ($self) = @_;
1392   delete $self->{_attrs} if exists $self->{_attrs};
1393   $self->{all_cache_position} = 0;
1394   $self->cursor->reset;
1395   return $self;
1396 }
1397
1398 =head2 first
1399
1400 =over 4
1401
1402 =item Arguments: none
1403
1404 =item Return Value: $object?
1405
1406 =back
1407
1408 Resets the resultset and returns an object for the first result (if the
1409 resultset returns anything).
1410
1411 =cut
1412
1413 sub first {
1414   return $_[0]->reset->next;
1415 }
1416
1417
1418 # _rs_update_delete
1419 #
1420 # Determines whether and what type of subquery is required for the $rs operation.
1421 # If grouping is necessary either supplies its own, or verifies the current one
1422 # After all is done delegates to the proper storage method.
1423
1424 sub _rs_update_delete {
1425   my ($self, $op, $values) = @_;
1426
1427   my $rsrc = $self->result_source;
1428
1429   # if a condition exists we need to strip all table qualifiers
1430   # if this is not possible we'll force a subquery below
1431   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1432
1433   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1434   my $needs_subq = (not defined $cond) || $self->_has_resolved_attr(qw/row offset/);
1435
1436   if ($needs_group_by_subq or $needs_subq) {
1437
1438     # make a new $rs selecting only the PKs (that's all we really need)
1439     my $attrs = $self->_resolved_attrs_copy;
1440
1441     delete $attrs->{$_} for qw/collapse select as/;
1442     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1443
1444     if ($needs_group_by_subq) {
1445       # make sure no group_by was supplied, or if there is one - make sure it matches
1446       # the columns compiled above perfectly. Anything else can not be sanely executed
1447       # on most databases so croak right then and there
1448
1449       if (my $g = $attrs->{group_by}) {
1450         my @current_group_by = map
1451           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1452           @$g
1453         ;
1454
1455         if (
1456           join ("\x00", sort @current_group_by)
1457             ne
1458           join ("\x00", sort @{$attrs->{columns}} )
1459         ) {
1460           $self->throw_exception (
1461             "You have just attempted a $op operation on a resultset which does group_by"
1462             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1463             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1464             . ' kind of queries. Please retry the operation with a modified group_by or'
1465             . ' without using one at all.'
1466           );
1467         }
1468       }
1469       else {
1470         $attrs->{group_by} = $attrs->{columns};
1471       }
1472     }
1473
1474     my $subrs = (ref $self)->new($rsrc, $attrs);
1475
1476     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1477   }
1478   else {
1479     return $rsrc->storage->$op(
1480       $rsrc,
1481       $op eq 'update' ? $values : (),
1482       $cond,
1483     );
1484   }
1485 }
1486
1487 =head2 update
1488
1489 =over 4
1490
1491 =item Arguments: \%values
1492
1493 =item Return Value: $storage_rv
1494
1495 =back
1496
1497 Sets the specified columns in the resultset to the supplied values in a
1498 single query. Return value will be true if the update succeeded or false
1499 if no records were updated; exact type of success value is storage-dependent.
1500
1501 =cut
1502
1503 sub update {
1504   my ($self, $values) = @_;
1505   $self->throw_exception('Values for update must be a hash')
1506     unless ref $values eq 'HASH';
1507
1508   return $self->_rs_update_delete ('update', $values);
1509 }
1510
1511 =head2 update_all
1512
1513 =over 4
1514
1515 =item Arguments: \%values
1516
1517 =item Return Value: 1
1518
1519 =back
1520
1521 Fetches all objects and updates them one at a time. Note that C<update_all>
1522 will run DBIC cascade triggers, while L</update> will not.
1523
1524 =cut
1525
1526 sub update_all {
1527   my ($self, $values) = @_;
1528   $self->throw_exception('Values for update_all must be a hash')
1529     unless ref $values eq 'HASH';
1530   foreach my $obj ($self->all) {
1531     $obj->set_columns($values)->update;
1532   }
1533   return 1;
1534 }
1535
1536 =head2 delete
1537
1538 =over 4
1539
1540 =item Arguments: none
1541
1542 =item Return Value: $storage_rv
1543
1544 =back
1545
1546 Deletes the contents of the resultset from its result source. Note that this
1547 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1548 to run. See also L<DBIx::Class::Row/delete>.
1549
1550 Return value will be the amount of rows deleted; exact type of return value
1551 is storage-dependent.
1552
1553 =cut
1554
1555 sub delete {
1556   my $self = shift;
1557   $self->throw_exception('delete does not accept any arguments')
1558     if @_;
1559
1560   return $self->_rs_update_delete ('delete');
1561 }
1562
1563 =head2 delete_all
1564
1565 =over 4
1566
1567 =item Arguments: none
1568
1569 =item Return Value: 1
1570
1571 =back
1572
1573 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1574 will run DBIC cascade triggers, while L</delete> will not.
1575
1576 =cut
1577
1578 sub delete_all {
1579   my $self = shift;
1580   $self->throw_exception('delete_all does not accept any arguments')
1581     if @_;
1582
1583   $_->delete for $self->all;
1584   return 1;
1585 }
1586
1587 =head2 populate
1588
1589 =over 4
1590
1591 =item Arguments: \@data;
1592
1593 =back
1594
1595 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1596 For the arrayref of hashrefs style each hashref should be a structure suitable
1597 forsubmitting to a $resultset->create(...) method.
1598
1599 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1600 to insert the data, as this is a faster method.
1601
1602 Otherwise, each set of data is inserted into the database using
1603 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1604 accumulated into an array. The array itself, or an array reference
1605 is returned depending on scalar or list context.
1606
1607 Example:  Assuming an Artist Class that has many CDs Classes relating:
1608
1609   my $Artist_rs = $schema->resultset("Artist");
1610
1611   ## Void Context Example
1612   $Artist_rs->populate([
1613      { artistid => 4, name => 'Manufactured Crap', cds => [
1614         { title => 'My First CD', year => 2006 },
1615         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1616       ],
1617      },
1618      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1619         { title => 'My parents sold me to a record company' ,year => 2005 },
1620         { title => 'Why Am I So Ugly?', year => 2006 },
1621         { title => 'I Got Surgery and am now Popular', year => 2007 }
1622       ],
1623      },
1624   ]);
1625
1626   ## Array Context Example
1627   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1628     { name => "Artist One"},
1629     { name => "Artist Two"},
1630     { name => "Artist Three", cds=> [
1631     { title => "First CD", year => 2007},
1632     { title => "Second CD", year => 2008},
1633   ]}
1634   ]);
1635
1636   print $ArtistOne->name; ## response is 'Artist One'
1637   print $ArtistThree->cds->count ## reponse is '2'
1638
1639 For the arrayref of arrayrefs style,  the first element should be a list of the
1640 fieldsnames to which the remaining elements are rows being inserted.  For
1641 example:
1642
1643   $Arstist_rs->populate([
1644     [qw/artistid name/],
1645     [100, 'A Formally Unknown Singer'],
1646     [101, 'A singer that jumped the shark two albums ago'],
1647     [102, 'An actually cool singer.'],
1648   ]);
1649
1650 Please note an important effect on your data when choosing between void and
1651 wantarray context. Since void context goes straight to C<insert_bulk> in
1652 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1653 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1654 create primary keys for you, you will find that your PKs are empty.  In this
1655 case you will have to use the wantarray context in order to create those
1656 values.
1657
1658 =cut
1659
1660 sub populate {
1661   my $self = shift @_;
1662   my $data = ref $_[0][0] eq 'HASH'
1663     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1664     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1665
1666   if(defined wantarray) {
1667     my @created;
1668     foreach my $item (@$data) {
1669       push(@created, $self->create($item));
1670     }
1671     return wantarray ? @created : \@created;
1672   } else {
1673     my $first = $data->[0];
1674
1675     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1676     # it relationship data
1677     my (@rels, @columns);
1678     for (keys %$first) {
1679       my $ref = ref $first->{$_};
1680       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1681         ? push @rels, $_
1682         : push @columns, $_
1683       ;
1684     }
1685
1686     my @pks = $self->result_source->primary_columns;
1687
1688     ## do the belongs_to relationships
1689     foreach my $index (0..$#$data) {
1690
1691       # delegate to create() for any dataset without primary keys with specified relationships
1692       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1693         for my $r (@rels) {
1694           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1695             my @ret = $self->populate($data);
1696             return;
1697           }
1698         }
1699       }
1700
1701       foreach my $rel (@rels) {
1702         next unless ref $data->[$index]->{$rel} eq "HASH";
1703         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1704         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1705         my $related = $result->result_source->_resolve_condition(
1706           $result->result_source->relationship_info($reverse)->{cond},
1707           $self,
1708           $result,
1709         );
1710
1711         delete $data->[$index]->{$rel};
1712         $data->[$index] = {%{$data->[$index]}, %$related};
1713
1714         push @columns, keys %$related if $index == 0;
1715       }
1716     }
1717
1718     ## inherit the data locked in the conditions of the resultset
1719     my ($rs_data) = $self->_merge_cond_with_data({});
1720     delete @{$rs_data}{@columns};
1721     my @inherit_cols = keys %$rs_data;
1722     my @inherit_data = values %$rs_data;
1723
1724     ## do bulk insert on current row
1725     $self->result_source->storage->insert_bulk(
1726       $self->result_source,
1727       [@columns, @inherit_cols],
1728       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1729     );
1730
1731     ## do the has_many relationships
1732     foreach my $item (@$data) {
1733
1734       foreach my $rel (@rels) {
1735         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1736
1737         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1738      || $self->throw_exception('Cannot find the relating object.');
1739
1740         my $child = $parent->$rel;
1741
1742         my $related = $child->result_source->_resolve_condition(
1743           $parent->result_source->relationship_info($rel)->{cond},
1744           $child,
1745           $parent,
1746         );
1747
1748         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1749         my @populate = map { {%$_, %$related} } @rows_to_add;
1750
1751         $child->populate( \@populate );
1752       }
1753     }
1754   }
1755 }
1756
1757 =head2 _normalize_populate_args ($args)
1758
1759 Private method used by L</populate> to normalize its incoming arguments.  Factored
1760 out in case you want to subclass and accept new argument structures to the
1761 L</populate> method.
1762
1763 =cut
1764
1765 sub _normalize_populate_args {
1766   my ($self, $data) = @_;
1767   my @names = @{shift(@$data)};
1768   my @results_to_create;
1769   foreach my $datum (@$data) {
1770     my %result_to_create;
1771     foreach my $index (0..$#names) {
1772       $result_to_create{$names[$index]} = $$datum[$index];
1773     }
1774     push @results_to_create, \%result_to_create;
1775   }
1776   return \@results_to_create;
1777 }
1778
1779 =head2 pager
1780
1781 =over 4
1782
1783 =item Arguments: none
1784
1785 =item Return Value: $pager
1786
1787 =back
1788
1789 Return Value a L<Data::Page> object for the current resultset. Only makes
1790 sense for queries with a C<page> attribute.
1791
1792 To get the full count of entries for a paged resultset, call
1793 C<total_entries> on the L<Data::Page> object.
1794
1795 =cut
1796
1797 sub pager {
1798   my ($self) = @_;
1799
1800   return $self->{pager} if $self->{pager};
1801
1802   my $attrs = $self->{attrs};
1803   $self->throw_exception("Can't create pager for non-paged rs")
1804     unless $self->{attrs}{page};
1805   $attrs->{rows} ||= 10;
1806
1807   # throw away the paging flags and re-run the count (possibly
1808   # with a subselect) to get the real total count
1809   my $count_attrs = { %$attrs };
1810   delete $count_attrs->{$_} for qw/rows offset page pager/;
1811   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1812
1813   return $self->{pager} = Data::Page->new(
1814     $total_count,
1815     $attrs->{rows},
1816     $self->{attrs}{page}
1817   );
1818 }
1819
1820 =head2 page
1821
1822 =over 4
1823
1824 =item Arguments: $page_number
1825
1826 =item Return Value: $rs
1827
1828 =back
1829
1830 Returns a resultset for the $page_number page of the resultset on which page
1831 is called, where each page contains a number of rows equal to the 'rows'
1832 attribute set on the resultset (10 by default).
1833
1834 =cut
1835
1836 sub page {
1837   my ($self, $page) = @_;
1838   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1839 }
1840
1841 =head2 new_result
1842
1843 =over 4
1844
1845 =item Arguments: \%vals
1846
1847 =item Return Value: $rowobject
1848
1849 =back
1850
1851 Creates a new row object in the resultset's result class and returns
1852 it. The row is not inserted into the database at this point, call
1853 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1854 will tell you whether the row object has been inserted or not.
1855
1856 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1857
1858 =cut
1859
1860 sub new_result {
1861   my ($self, $values) = @_;
1862   $self->throw_exception( "new_result needs a hash" )
1863     unless (ref $values eq 'HASH');
1864
1865   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1866
1867   my %new = (
1868     %$merged_cond,
1869     @$cols_from_relations
1870       ? (-cols_from_relations => $cols_from_relations)
1871       : (),
1872     -source_handle => $self->_source_handle,
1873     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1874   );
1875
1876   return $self->result_class->new(\%new);
1877 }
1878
1879 # _merge_cond_with_data
1880 #
1881 # Takes a simple hash of K/V data and returns its copy merged with the
1882 # condition already present on the resultset. Additionally returns an
1883 # arrayref of value/condition names, which were inferred from related
1884 # objects (this is needed for in-memory related objects)
1885 sub _merge_cond_with_data {
1886   my ($self, $data) = @_;
1887
1888   my (%new_data, @cols_from_relations);
1889
1890   my $alias = $self->{attrs}{alias};
1891
1892   if (! defined $self->{cond}) {
1893     # just massage $data below
1894   }
1895   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1896     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1897     @cols_from_relations = keys %new_data;
1898   }
1899   elsif (ref $self->{cond} ne 'HASH') {
1900     $self->throw_exception(
1901       "Can't abstract implicit construct, resultset condition not a hash"
1902     );
1903   }
1904   else {
1905     # precendence must be given to passed values over values inherited from
1906     # the cond, so the order here is important.
1907     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1908     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1909
1910     while ( my($col, $value) = each %implied ) {
1911       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1912         $new_data{$col} = $value->{'='};
1913         next;
1914       }
1915       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1916     }
1917   }
1918
1919   %new_data = (
1920     %new_data,
1921     %{ $self->_remove_alias($data, $alias) },
1922   );
1923
1924   return (\%new_data, \@cols_from_relations);
1925 }
1926
1927 # _is_deterministic_value
1928 #
1929 # Make an effor to strip non-deterministic values from the condition,
1930 # to make sure new_result chokes less
1931
1932 sub _is_deterministic_value {
1933   my $self = shift;
1934   my $value = shift;
1935   my $ref_type = ref $value;
1936   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1937   return 1 if Scalar::Util::blessed($value);
1938   return 0;
1939 }
1940
1941 # _has_resolved_attr
1942 #
1943 # determines if the resultset defines at least one
1944 # of the attributes supplied
1945 #
1946 # used to determine if a subquery is neccessary
1947 #
1948 # supports some virtual attributes:
1949 #   -join
1950 #     This will scan for any joins being present on the resultset.
1951 #     It is not a mere key-search but a deep inspection of {from}
1952 #
1953
1954 sub _has_resolved_attr {
1955   my ($self, @attr_names) = @_;
1956
1957   my $attrs = $self->_resolved_attrs;
1958
1959   my %extra_checks;
1960
1961   for my $n (@attr_names) {
1962     if (grep { $n eq $_ } (qw/-join/) ) {
1963       $extra_checks{$n}++;
1964       next;
1965     }
1966
1967     my $attr =  $attrs->{$n};
1968
1969     next if not defined $attr;
1970
1971     if (ref $attr eq 'HASH') {
1972       return 1 if keys %$attr;
1973     }
1974     elsif (ref $attr eq 'ARRAY') {
1975       return 1 if @$attr;
1976     }
1977     else {
1978       return 1 if $attr;
1979     }
1980   }
1981
1982   # a resolved join is expressed as a multi-level from
1983   return 1 if (
1984     $extra_checks{-join}
1985       and
1986     ref $attrs->{from} eq 'ARRAY'
1987       and
1988     @{$attrs->{from}} > 1
1989   );
1990
1991   return 0;
1992 }
1993
1994 # _collapse_cond
1995 #
1996 # Recursively collapse the condition.
1997
1998 sub _collapse_cond {
1999   my ($self, $cond, $collapsed) = @_;
2000
2001   $collapsed ||= {};
2002
2003   if (ref $cond eq 'ARRAY') {
2004     foreach my $subcond (@$cond) {
2005       next unless ref $subcond;  # -or
2006       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2007     }
2008   }
2009   elsif (ref $cond eq 'HASH') {
2010     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2011       foreach my $subcond (@{$cond->{-and}}) {
2012         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2013       }
2014     }
2015     else {
2016       foreach my $col (keys %$cond) {
2017         my $value = $cond->{$col};
2018         $collapsed->{$col} = $value;
2019       }
2020     }
2021   }
2022
2023   return $collapsed;
2024 }
2025
2026 # _remove_alias
2027 #
2028 # Remove the specified alias from the specified query hash. A copy is made so
2029 # the original query is not modified.
2030
2031 sub _remove_alias {
2032   my ($self, $query, $alias) = @_;
2033
2034   my %orig = %{ $query || {} };
2035   my %unaliased;
2036
2037   foreach my $key (keys %orig) {
2038     if ($key !~ /\./) {
2039       $unaliased{$key} = $orig{$key};
2040       next;
2041     }
2042     $unaliased{$1} = $orig{$key}
2043       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2044   }
2045
2046   return \%unaliased;
2047 }
2048
2049 =head2 as_query (EXPERIMENTAL)
2050
2051 =over 4
2052
2053 =item Arguments: none
2054
2055 =item Return Value: \[ $sql, @bind ]
2056
2057 =back
2058
2059 Returns the SQL query and bind vars associated with the invocant.
2060
2061 This is generally used as the RHS for a subquery.
2062
2063 B<NOTE>: This feature is still experimental.
2064
2065 =cut
2066
2067 sub as_query {
2068   my $self = shift;
2069
2070   my $attrs = $self->_resolved_attrs_copy;
2071
2072   # For future use:
2073   #
2074   # in list ctx:
2075   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2076   # $sql also has no wrapping parenthesis in list ctx
2077   #
2078   my $sqlbind = $self->result_source->storage
2079     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2080
2081   return $sqlbind;
2082 }
2083
2084 =head2 find_or_new
2085
2086 =over 4
2087
2088 =item Arguments: \%vals, \%attrs?
2089
2090 =item Return Value: $rowobject
2091
2092 =back
2093
2094   my $artist = $schema->resultset('Artist')->find_or_new(
2095     { artist => 'fred' }, { key => 'artists' });
2096
2097   $cd->cd_to_producer->find_or_new({ producer => $producer },
2098                                    { key => 'primary });
2099
2100 Find an existing record from this resultset, based on its primary
2101 key, or a unique constraint. If none exists, instantiate a new result
2102 object and return it. The object will not be saved into your storage
2103 until you call L<DBIx::Class::Row/insert> on it.
2104
2105 You most likely want this method when looking for existing rows using
2106 a unique constraint that is not the primary key, or looking for
2107 related rows.
2108
2109 If you want objects to be saved immediately, use L</find_or_create>
2110 instead.
2111
2112 B<Note>: Take care when using C<find_or_new> with a table having
2113 columns with default values that you intend to be automatically
2114 supplied by the database (e.g. an auto_increment primary key column).
2115 In normal usage, the value of such columns should NOT be included at
2116 all in the call to C<find_or_new>, even when set to C<undef>.
2117
2118 =cut
2119
2120 sub find_or_new {
2121   my $self     = shift;
2122   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2123   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2124   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2125     return $row;
2126   }
2127   return $self->new_result($hash);
2128 }
2129
2130 =head2 create
2131
2132 =over 4
2133
2134 =item Arguments: \%vals
2135
2136 =item Return Value: a L<DBIx::Class::Row> $object
2137
2138 =back
2139
2140 Attempt to create a single new row or a row with multiple related rows
2141 in the table represented by the resultset (and related tables). This
2142 will not check for duplicate rows before inserting, use
2143 L</find_or_create> to do that.
2144
2145 To create one row for this resultset, pass a hashref of key/value
2146 pairs representing the columns of the table and the values you wish to
2147 store. If the appropriate relationships are set up, foreign key fields
2148 can also be passed an object representing the foreign row, and the
2149 value will be set to its primary key.
2150
2151 To create related objects, pass a hashref of related-object column values
2152 B<keyed on the relationship name>. If the relationship is of type C<multi>
2153 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2154 The process will correctly identify columns holding foreign keys, and will
2155 transparrently populate them from the keys of the corresponding relation.
2156 This can be applied recursively, and will work correctly for a structure
2157 with an arbitrary depth and width, as long as the relationships actually
2158 exists and the correct column data has been supplied.
2159
2160
2161 Instead of hashrefs of plain related data (key/value pairs), you may
2162 also pass new or inserted objects. New objects (not inserted yet, see
2163 L</new>), will be inserted into their appropriate tables.
2164
2165 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2166
2167 Example of creating a new row.
2168
2169   $person_rs->create({
2170     name=>"Some Person",
2171     email=>"somebody@someplace.com"
2172   });
2173
2174 Example of creating a new row and also creating rows in a related C<has_many>
2175 or C<has_one> resultset.  Note Arrayref.
2176
2177   $artist_rs->create(
2178      { artistid => 4, name => 'Manufactured Crap', cds => [
2179         { title => 'My First CD', year => 2006 },
2180         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2181       ],
2182      },
2183   );
2184
2185 Example of creating a new row and also creating a row in a related
2186 C<belongs_to>resultset. Note Hashref.
2187
2188   $cd_rs->create({
2189     title=>"Music for Silly Walks",
2190     year=>2000,
2191     artist => {
2192       name=>"Silly Musician",
2193     }
2194   });
2195
2196 =over
2197
2198 =item WARNING
2199
2200 When subclassing ResultSet never attempt to override this method. Since
2201 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2202 lot of the internals simply never call it, so your override will be
2203 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2204 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2205 L</create> process you need to intervene.
2206
2207 =back
2208
2209 =cut
2210
2211 sub create {
2212   my ($self, $attrs) = @_;
2213   $self->throw_exception( "create needs a hashref" )
2214     unless ref $attrs eq 'HASH';
2215   return $self->new_result($attrs)->insert;
2216 }
2217
2218 =head2 find_or_create
2219
2220 =over 4
2221
2222 =item Arguments: \%vals, \%attrs?
2223
2224 =item Return Value: $rowobject
2225
2226 =back
2227
2228   $cd->cd_to_producer->find_or_create({ producer => $producer },
2229                                       { key => 'primary' });
2230
2231 Tries to find a record based on its primary key or unique constraints; if none
2232 is found, creates one and returns that instead.
2233
2234   my $cd = $schema->resultset('CD')->find_or_create({
2235     cdid   => 5,
2236     artist => 'Massive Attack',
2237     title  => 'Mezzanine',
2238     year   => 2005,
2239   });
2240
2241 Also takes an optional C<key> attribute, to search by a specific key or unique
2242 constraint. For example:
2243
2244   my $cd = $schema->resultset('CD')->find_or_create(
2245     {
2246       artist => 'Massive Attack',
2247       title  => 'Mezzanine',
2248     },
2249     { key => 'cd_artist_title' }
2250   );
2251
2252 B<Note>: Because find_or_create() reads from the database and then
2253 possibly inserts based on the result, this method is subject to a race
2254 condition. Another process could create a record in the table after
2255 the find has completed and before the create has started. To avoid
2256 this problem, use find_or_create() inside a transaction.
2257
2258 B<Note>: Take care when using C<find_or_create> with a table having
2259 columns with default values that you intend to be automatically
2260 supplied by the database (e.g. an auto_increment primary key column).
2261 In normal usage, the value of such columns should NOT be included at
2262 all in the call to C<find_or_create>, even when set to C<undef>.
2263
2264 See also L</find> and L</update_or_create>. For information on how to declare
2265 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2266
2267 =cut
2268
2269 sub find_or_create {
2270   my $self     = shift;
2271   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2272   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2273   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2274     return $row;
2275   }
2276   return $self->create($hash);
2277 }
2278
2279 =head2 update_or_create
2280
2281 =over 4
2282
2283 =item Arguments: \%col_values, { key => $unique_constraint }?
2284
2285 =item Return Value: $rowobject
2286
2287 =back
2288
2289   $resultset->update_or_create({ col => $val, ... });
2290
2291 First, searches for an existing row matching one of the unique constraints
2292 (including the primary key) on the source of this resultset. If a row is
2293 found, updates it with the other given column values. Otherwise, creates a new
2294 row.
2295
2296 Takes an optional C<key> attribute to search on a specific unique constraint.
2297 For example:
2298
2299   # In your application
2300   my $cd = $schema->resultset('CD')->update_or_create(
2301     {
2302       artist => 'Massive Attack',
2303       title  => 'Mezzanine',
2304       year   => 1998,
2305     },
2306     { key => 'cd_artist_title' }
2307   );
2308
2309   $cd->cd_to_producer->update_or_create({
2310     producer => $producer,
2311     name => 'harry',
2312   }, {
2313     key => 'primary,
2314   });
2315
2316
2317 If no C<key> is specified, it searches on all unique constraints defined on the
2318 source, including the primary key.
2319
2320 If the C<key> is specified as C<primary>, it searches only on the primary key.
2321
2322 See also L</find> and L</find_or_create>. For information on how to declare
2323 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2324
2325 B<Note>: Take care when using C<update_or_create> with a table having
2326 columns with default values that you intend to be automatically
2327 supplied by the database (e.g. an auto_increment primary key column).
2328 In normal usage, the value of such columns should NOT be included at
2329 all in the call to C<update_or_create>, even when set to C<undef>.
2330
2331 =cut
2332
2333 sub update_or_create {
2334   my $self = shift;
2335   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2336   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2337
2338   my $row = $self->find($cond, $attrs);
2339   if (defined $row) {
2340     $row->update($cond);
2341     return $row;
2342   }
2343
2344   return $self->create($cond);
2345 }
2346
2347 =head2 update_or_new
2348
2349 =over 4
2350
2351 =item Arguments: \%col_values, { key => $unique_constraint }?
2352
2353 =item Return Value: $rowobject
2354
2355 =back
2356
2357   $resultset->update_or_new({ col => $val, ... });
2358
2359 First, searches for an existing row matching one of the unique constraints
2360 (including the primary key) on the source of this resultset. If a row is
2361 found, updates it with the other given column values. Otherwise, instantiate
2362 a new result object and return it. The object will not be saved into your storage
2363 until you call L<DBIx::Class::Row/insert> on it.
2364
2365 Takes an optional C<key> attribute to search on a specific unique constraint.
2366 For example:
2367
2368   # In your application
2369   my $cd = $schema->resultset('CD')->update_or_new(
2370     {
2371       artist => 'Massive Attack',
2372       title  => 'Mezzanine',
2373       year   => 1998,
2374     },
2375     { key => 'cd_artist_title' }
2376   );
2377
2378   if ($cd->in_storage) {
2379       # the cd was updated
2380   }
2381   else {
2382       # the cd is not yet in the database, let's insert it
2383       $cd->insert;
2384   }
2385
2386 B<Note>: Take care when using C<update_or_new> with a table having
2387 columns with default values that you intend to be automatically
2388 supplied by the database (e.g. an auto_increment primary key column).
2389 In normal usage, the value of such columns should NOT be included at
2390 all in the call to C<update_or_new>, even when set to C<undef>.
2391
2392 See also L</find>, L</find_or_create> and L</find_or_new>.
2393
2394 =cut
2395
2396 sub update_or_new {
2397     my $self  = shift;
2398     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2399     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2400
2401     my $row = $self->find( $cond, $attrs );
2402     if ( defined $row ) {
2403         $row->update($cond);
2404         return $row;
2405     }
2406
2407     return $self->new_result($cond);
2408 }
2409
2410 =head2 get_cache
2411
2412 =over 4
2413
2414 =item Arguments: none
2415
2416 =item Return Value: \@cache_objects?
2417
2418 =back
2419
2420 Gets the contents of the cache for the resultset, if the cache is set.
2421
2422 The cache is populated either by using the L</prefetch> attribute to
2423 L</search> or by calling L</set_cache>.
2424
2425 =cut
2426
2427 sub get_cache {
2428   shift->{all_cache};
2429 }
2430
2431 =head2 set_cache
2432
2433 =over 4
2434
2435 =item Arguments: \@cache_objects
2436
2437 =item Return Value: \@cache_objects
2438
2439 =back
2440
2441 Sets the contents of the cache for the resultset. Expects an arrayref
2442 of objects of the same class as those produced by the resultset. Note that
2443 if the cache is set the resultset will return the cached objects rather
2444 than re-querying the database even if the cache attr is not set.
2445
2446 The contents of the cache can also be populated by using the
2447 L</prefetch> attribute to L</search>.
2448
2449 =cut
2450
2451 sub set_cache {
2452   my ( $self, $data ) = @_;
2453   $self->throw_exception("set_cache requires an arrayref")
2454       if defined($data) && (ref $data ne 'ARRAY');
2455   $self->{all_cache} = $data;
2456 }
2457
2458 =head2 clear_cache
2459
2460 =over 4
2461
2462 =item Arguments: none
2463
2464 =item Return Value: []
2465
2466 =back
2467
2468 Clears the cache for the resultset.
2469
2470 =cut
2471
2472 sub clear_cache {
2473   shift->set_cache(undef);
2474 }
2475
2476 =head2 is_paged
2477
2478 =over 4
2479
2480 =item Arguments: none
2481
2482 =item Return Value: true, if the resultset has been paginated
2483
2484 =back
2485
2486 =cut
2487
2488 sub is_paged {
2489   my ($self) = @_;
2490   return !!$self->{attrs}{page};
2491 }
2492
2493 =head2 related_resultset
2494
2495 =over 4
2496
2497 =item Arguments: $relationship_name
2498
2499 =item Return Value: $resultset
2500
2501 =back
2502
2503 Returns a related resultset for the supplied relationship name.
2504
2505   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2506
2507 =cut
2508
2509 sub related_resultset {
2510   my ($self, $rel) = @_;
2511
2512   $self->{related_resultsets} ||= {};
2513   return $self->{related_resultsets}{$rel} ||= do {
2514     my $rel_info = $self->result_source->relationship_info($rel);
2515
2516     $self->throw_exception(
2517       "search_related: result source '" . $self->result_source->source_name .
2518         "' has no such relationship $rel")
2519       unless $rel_info;
2520
2521     my ($from,$seen) = $self->_chain_relationship($rel);
2522
2523     my $join_count = $seen->{$rel};
2524     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2525
2526     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2527     my %attrs = %{$self->{attrs}||{}};
2528     delete @attrs{qw(result_class alias)};
2529
2530     my $new_cache;
2531
2532     if (my $cache = $self->get_cache) {
2533       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2534         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2535                         @$cache ];
2536       }
2537     }
2538
2539     my $rel_source = $self->result_source->related_source($rel);
2540
2541     my $new = do {
2542
2543       # The reason we do this now instead of passing the alias to the
2544       # search_rs below is that if you wrap/overload resultset on the
2545       # source you need to know what alias it's -going- to have for things
2546       # to work sanely (e.g. RestrictWithObject wants to be able to add
2547       # extra query restrictions, and these may need to be $alias.)
2548
2549       my $attrs = $rel_source->resultset_attributes;
2550       local $attrs->{alias} = $alias;
2551
2552       $rel_source->resultset
2553                  ->search_rs(
2554                      undef, {
2555                        %attrs,
2556                        join => undef,
2557                        prefetch => undef,
2558                        select => undef,
2559                        as => undef,
2560                        where => $self->{cond},
2561                        seen_join => $seen,
2562                        from => $from,
2563                    });
2564     };
2565     $new->set_cache($new_cache) if $new_cache;
2566     $new;
2567   };
2568 }
2569
2570 =head2 current_source_alias
2571
2572 =over 4
2573
2574 =item Arguments: none
2575
2576 =item Return Value: $source_alias
2577
2578 =back
2579
2580 Returns the current table alias for the result source this resultset is built
2581 on, that will be used in the SQL query. Usually it is C<me>.
2582
2583 Currently the source alias that refers to the result set returned by a
2584 L</search>/L</find> family method depends on how you got to the resultset: it's
2585 C<me> by default, but eg. L</search_related> aliases it to the related result
2586 source name (and keeps C<me> referring to the original result set). The long
2587 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2588 (and make this method unnecessary).
2589
2590 Thus it's currently necessary to use this method in predefined queries (see
2591 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2592 source alias of the current result set:
2593
2594   # in a result set class
2595   sub modified_by {
2596     my ($self, $user) = @_;
2597
2598     my $me = $self->current_source_alias;
2599
2600     return $self->search(
2601       "$me.modified" => $user->id,
2602     );
2603   }
2604
2605 =cut
2606
2607 sub current_source_alias {
2608   my ($self) = @_;
2609
2610   return ($self->{attrs} || {})->{alias} || 'me';
2611 }
2612
2613 # This code is called by search_related, and makes sure there
2614 # is clear separation between the joins before, during, and
2615 # after the relationship. This information is needed later
2616 # in order to properly resolve prefetch aliases (any alias
2617 # with a relation_chain_depth less than the depth of the
2618 # current prefetch is not considered)
2619 #
2620 # The increments happen in 1/2s to make it easier to correlate the
2621 # join depth with the join path. An integer means a relationship
2622 # specified via a search_related, whereas a fraction means an added
2623 # join/prefetch via attributes
2624 sub _chain_relationship {
2625   my ($self, $rel) = @_;
2626   my $source = $self->result_source;
2627   my $attrs = $self->{attrs};
2628
2629   my $from = [ @{
2630       $attrs->{from}
2631         ||
2632       [{
2633         -source_handle => $source->handle,
2634         -alias => $attrs->{alias},
2635         $attrs->{alias} => $source->from,
2636       }]
2637   }];
2638
2639   my $seen = { %{$attrs->{seen_join} || {} } };
2640   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2641     ? $from->[-1][0]{-join_path}
2642     : [];
2643
2644
2645   # we need to take the prefetch the attrs into account before we
2646   # ->_resolve_join as otherwise they get lost - captainL
2647   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2648
2649   my @requested_joins = $source->_resolve_join(
2650     $merged,
2651     $attrs->{alias},
2652     $seen,
2653     $jpath,
2654   );
2655
2656   push @$from, @requested_joins;
2657
2658   $seen->{-relation_chain_depth} += 0.5;
2659
2660   # if $self already had a join/prefetch specified on it, the requested
2661   # $rel might very well be already included. What we do in this case
2662   # is effectively a no-op (except that we bump up the chain_depth on
2663   # the join in question so we could tell it *is* the search_related)
2664   my $already_joined;
2665
2666
2667   # we consider the last one thus reverse
2668   for my $j (reverse @requested_joins) {
2669     if ($rel eq $j->[0]{-join_path}[-1]) {
2670       $j->[0]{-relation_chain_depth} += 0.5;
2671       $already_joined++;
2672       last;
2673     }
2674   }
2675
2676 # alternative way to scan the entire chain - not backwards compatible
2677 #  for my $j (reverse @$from) {
2678 #    next unless ref $j eq 'ARRAY';
2679 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2680 #      $j->[0]{-relation_chain_depth} += 0.5;
2681 #      $already_joined++;
2682 #      last;
2683 #    }
2684 #  }
2685
2686   unless ($already_joined) {
2687     push @$from, $source->_resolve_join(
2688       $rel,
2689       $attrs->{alias},
2690       $seen,
2691       $jpath,
2692     );
2693   }
2694
2695   $seen->{-relation_chain_depth} += 0.5;
2696
2697   return ($from,$seen);
2698 }
2699
2700 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2701 sub _resolved_attrs_copy {
2702   my $self = shift;
2703   return { %{$self->_resolved_attrs (@_)} };
2704 }
2705
2706 sub _resolved_attrs {
2707   my $self = shift;
2708   return $self->{_attrs} if $self->{_attrs};
2709
2710   my $attrs  = { %{ $self->{attrs} || {} } };
2711   my $source = $self->result_source;
2712   my $alias  = $attrs->{alias};
2713
2714   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2715   my @colbits;
2716
2717   # build columns (as long as select isn't set) into a set of as/select hashes
2718   unless ( $attrs->{select} ) {
2719
2720     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2721       ? @{ delete $attrs->{columns}}
2722       : (
2723           ( delete $attrs->{columns} )
2724             ||
2725           $source->columns
2726         )
2727     ;
2728
2729     @colbits = map {
2730       ( ref($_) eq 'HASH' )
2731       ? $_
2732       : {
2733           (
2734             /^\Q${alias}.\E(.+)$/
2735               ? "$1"
2736               : "$_"
2737           )
2738             =>
2739           (
2740             /\./
2741               ? "$_"
2742               : "${alias}.$_"
2743           )
2744         }
2745     } @cols;
2746   }
2747
2748   # add the additional columns on
2749   foreach ( 'include_columns', '+columns' ) {
2750       push @colbits, map {
2751           ( ref($_) eq 'HASH' )
2752             ? $_
2753             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2754       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2755   }
2756
2757   # start with initial select items
2758   if ( $attrs->{select} ) {
2759     $attrs->{select} =
2760         ( ref $attrs->{select} eq 'ARRAY' )
2761       ? [ @{ $attrs->{select} } ]
2762       : [ $attrs->{select} ];
2763     $attrs->{as} = (
2764       $attrs->{as}
2765       ? (
2766         ref $attrs->{as} eq 'ARRAY'
2767         ? [ @{ $attrs->{as} } ]
2768         : [ $attrs->{as} ]
2769         )
2770       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2771     );
2772   }
2773   else {
2774
2775     # otherwise we intialise select & as to empty
2776     $attrs->{select} = [];
2777     $attrs->{as}     = [];
2778   }
2779
2780   # now add colbits to select/as
2781   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2782   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2783
2784   my $adds;
2785   if ( $adds = delete $attrs->{'+select'} ) {
2786     $adds = [$adds] unless ref $adds eq 'ARRAY';
2787     push(
2788       @{ $attrs->{select} },
2789       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2790     );
2791   }
2792   if ( $adds = delete $attrs->{'+as'} ) {
2793     $adds = [$adds] unless ref $adds eq 'ARRAY';
2794     push( @{ $attrs->{as} }, @$adds );
2795   }
2796
2797   $attrs->{from} ||= [ {
2798     -source_handle => $source->handle,
2799     -alias => $self->{attrs}{alias},
2800     $self->{attrs}{alias} => $source->from,
2801   } ];
2802
2803   if ( $attrs->{join} || $attrs->{prefetch} ) {
2804
2805     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2806       if ref $attrs->{from} ne 'ARRAY';
2807
2808     my $join = delete $attrs->{join} || {};
2809
2810     if ( defined $attrs->{prefetch} ) {
2811       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2812     }
2813
2814     $attrs->{from} =    # have to copy here to avoid corrupting the original
2815       [
2816         @{ $attrs->{from} },
2817         $source->_resolve_join(
2818           $join,
2819           $alias,
2820           { %{ $attrs->{seen_join} || {} } },
2821           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2822             ? $attrs->{from}[-1][0]{-join_path}
2823             : []
2824           ,
2825         )
2826       ];
2827   }
2828
2829   if ( defined $attrs->{order_by} ) {
2830     $attrs->{order_by} = (
2831       ref( $attrs->{order_by} ) eq 'ARRAY'
2832       ? [ @{ $attrs->{order_by} } ]
2833       : [ $attrs->{order_by} || () ]
2834     );
2835   }
2836
2837   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2838     $attrs->{group_by} = [ $attrs->{group_by} ];
2839   }
2840
2841   # generate the distinct induced group_by early, as prefetch will be carried via a
2842   # subquery (since a group_by is present)
2843   if (delete $attrs->{distinct}) {
2844     if ($attrs->{group_by}) {
2845       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2846     }
2847     else {
2848       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2849
2850       # add any order_by parts that are not already present in the group_by
2851       # we need to be careful not to add any named functions/aggregates
2852       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2853       my %already_grouped = map { $_ => 1 } (@{$attrs->{group_by}});
2854
2855       my $storage = $self->result_source->schema->storage;
2856       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2857       my @chunks = $storage->sql_maker->_order_by_chunks ($attrs->{order_by});
2858
2859       for my $chunk (map { ref $_ ? @$_ : $_ } (@chunks) ) {
2860         $chunk =~ s/\s+ (?: ASC|DESC ) \s* $//ix;
2861         if ($rs_column_list->{$chunk} && not $already_grouped{$chunk}++) {
2862           push @{$attrs->{group_by}}, $chunk;
2863         }
2864       }
2865     }
2866   }
2867
2868   $attrs->{collapse} ||= {};
2869   if ( my $prefetch = delete $attrs->{prefetch} ) {
2870     $prefetch = $self->_merge_attr( {}, $prefetch );
2871
2872     my $prefetch_ordering = [];
2873
2874     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2875
2876     my @prefetch =
2877       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2878
2879     # we need to somehow mark which columns came from prefetch
2880     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2881
2882     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2883     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2884
2885     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2886     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2887   }
2888
2889   # if both page and offset are specified, produce a combined offset
2890   # even though it doesn't make much sense, this is what pre 081xx has
2891   # been doing
2892   if (my $page = delete $attrs->{page}) {
2893     $attrs->{offset} =
2894       ($attrs->{rows} * ($page - 1))
2895             +
2896       ($attrs->{offset} || 0)
2897     ;
2898   }
2899
2900   return $self->{_attrs} = $attrs;
2901 }
2902
2903 sub _joinpath_aliases {
2904   my ($self, $fromspec, $seen) = @_;
2905
2906   my $paths = {};
2907   return $paths unless ref $fromspec eq 'ARRAY';
2908
2909   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2910
2911   if (int ($cur_depth) != $cur_depth) {
2912     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2913   }
2914
2915   for my $j (@$fromspec) {
2916
2917     next if ref $j ne 'ARRAY';
2918     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2919
2920     my $jpath = $j->[0]{-join_path};
2921
2922     my $p = $paths;
2923     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2924     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2925   }
2926
2927   return $paths;
2928 }
2929
2930 sub _rollout_attr {
2931   my ($self, $attr) = @_;
2932
2933   if (ref $attr eq 'HASH') {
2934     return $self->_rollout_hash($attr);
2935   } elsif (ref $attr eq 'ARRAY') {
2936     return $self->_rollout_array($attr);
2937   } else {
2938     return [$attr];
2939   }
2940 }
2941
2942 sub _rollout_array {
2943   my ($self, $attr) = @_;
2944
2945   my @rolled_array;
2946   foreach my $element (@{$attr}) {
2947     if (ref $element eq 'HASH') {
2948       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2949     } elsif (ref $element eq 'ARRAY') {
2950       #  XXX - should probably recurse here
2951       push( @rolled_array, @{$self->_rollout_array($element)} );
2952     } else {
2953       push( @rolled_array, $element );
2954     }
2955   }
2956   return \@rolled_array;
2957 }
2958
2959 sub _rollout_hash {
2960   my ($self, $attr) = @_;
2961
2962   my @rolled_array;
2963   foreach my $key (keys %{$attr}) {
2964     push( @rolled_array, { $key => $attr->{$key} } );
2965   }
2966   return \@rolled_array;
2967 }
2968
2969 sub _calculate_score {
2970   my ($self, $a, $b) = @_;
2971
2972   if (defined $a xor defined $b) {
2973     return 0;
2974   }
2975   elsif (not defined $a) {
2976     return 1;
2977   }
2978
2979   if (ref $b eq 'HASH') {
2980     my ($b_key) = keys %{$b};
2981     if (ref $a eq 'HASH') {
2982       my ($a_key) = keys %{$a};
2983       if ($a_key eq $b_key) {
2984         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2985       } else {
2986         return 0;
2987       }
2988     } else {
2989       return ($a eq $b_key) ? 1 : 0;
2990     }
2991   } else {
2992     if (ref $a eq 'HASH') {
2993       my ($a_key) = keys %{$a};
2994       return ($b eq $a_key) ? 1 : 0;
2995     } else {
2996       return ($b eq $a) ? 1 : 0;
2997     }
2998   }
2999 }
3000
3001 sub _merge_attr {
3002   my ($self, $orig, $import) = @_;
3003
3004   return $import unless defined($orig);
3005   return $orig unless defined($import);
3006
3007   $orig = $self->_rollout_attr($orig);
3008   $import = $self->_rollout_attr($import);
3009
3010   my $seen_keys;
3011   foreach my $import_element ( @{$import} ) {
3012     # find best candidate from $orig to merge $b_element into
3013     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3014     foreach my $orig_element ( @{$orig} ) {
3015       my $score = $self->_calculate_score( $orig_element, $import_element );
3016       if ($score > $best_candidate->{score}) {
3017         $best_candidate->{position} = $position;
3018         $best_candidate->{score} = $score;
3019       }
3020       $position++;
3021     }
3022     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3023
3024     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3025       push( @{$orig}, $import_element );
3026     } else {
3027       my $orig_best = $orig->[$best_candidate->{position}];
3028       # merge orig_best and b_element together and replace original with merged
3029       if (ref $orig_best ne 'HASH') {
3030         $orig->[$best_candidate->{position}] = $import_element;
3031       } elsif (ref $import_element eq 'HASH') {
3032         my ($key) = keys %{$orig_best};
3033         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3034       }
3035     }
3036     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3037   }
3038
3039   return $orig;
3040 }
3041
3042 sub result_source {
3043     my $self = shift;
3044
3045     if (@_) {
3046         $self->_source_handle($_[0]->handle);
3047     } else {
3048         $self->_source_handle->resolve;
3049     }
3050 }
3051
3052 =head2 throw_exception
3053
3054 See L<DBIx::Class::Schema/throw_exception> for details.
3055
3056 =cut
3057
3058 sub throw_exception {
3059   my $self=shift;
3060
3061   if (ref $self && $self->_source_handle->schema) {
3062     $self->_source_handle->schema->throw_exception(@_)
3063   }
3064   else {
3065     DBIx::Class::Exception->throw(@_);
3066   }
3067 }
3068
3069 # XXX: FIXME: Attributes docs need clearing up
3070
3071 =head1 ATTRIBUTES
3072
3073 Attributes are used to refine a ResultSet in various ways when
3074 searching for data. They can be passed to any method which takes an
3075 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3076 L</count>.
3077
3078 These are in no particular order:
3079
3080 =head2 order_by
3081
3082 =over 4
3083
3084 =item Value: ( $order_by | \@order_by | \%order_by )
3085
3086 =back
3087
3088 Which column(s) to order the results by.
3089
3090 [The full list of suitable values is documented in
3091 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3092 common options.]
3093
3094 If a single column name, or an arrayref of names is supplied, the
3095 argument is passed through directly to SQL. The hashref syntax allows
3096 for connection-agnostic specification of ordering direction:
3097
3098  For descending order:
3099
3100   order_by => { -desc => [qw/col1 col2 col3/] }
3101
3102  For explicit ascending order:
3103
3104   order_by => { -asc => 'col' }
3105
3106 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3107 supported, although you are strongly encouraged to use the hashref
3108 syntax as outlined above.
3109
3110 =head2 columns
3111
3112 =over 4
3113
3114 =item Value: \@columns
3115
3116 =back
3117
3118 Shortcut to request a particular set of columns to be retrieved. Each
3119 column spec may be a string (a table column name), or a hash (in which
3120 case the key is the C<as> value, and the value is used as the C<select>
3121 expression). Adds C<me.> onto the start of any column without a C<.> in
3122 it and sets C<select> from that, then auto-populates C<as> from
3123 C<select> as normal. (You may also use the C<cols> attribute, as in
3124 earlier versions of DBIC.)
3125
3126 =head2 +columns
3127
3128 =over 4
3129
3130 =item Value: \@columns
3131
3132 =back
3133
3134 Indicates additional columns to be selected from storage. Works the same
3135 as L</columns> but adds columns to the selection. (You may also use the
3136 C<include_columns> attribute, as in earlier versions of DBIC). For
3137 example:-
3138
3139   $schema->resultset('CD')->search(undef, {
3140     '+columns' => ['artist.name'],
3141     join => ['artist']
3142   });
3143
3144 would return all CDs and include a 'name' column to the information
3145 passed to object inflation. Note that the 'artist' is the name of the
3146 column (or relationship) accessor, and 'name' is the name of the column
3147 accessor in the related table.
3148
3149 =head2 include_columns
3150
3151 =over 4
3152
3153 =item Value: \@columns
3154
3155 =back
3156
3157 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3158
3159 =head2 select
3160
3161 =over 4
3162
3163 =item Value: \@select_columns
3164
3165 =back
3166
3167 Indicates which columns should be selected from the storage. You can use
3168 column names, or in the case of RDBMS back ends, function or stored procedure
3169 names:
3170
3171   $rs = $schema->resultset('Employee')->search(undef, {
3172     select => [
3173       'name',
3174       { count => 'employeeid' },
3175       { sum => 'salary' }
3176     ]
3177   });
3178
3179 When you use function/stored procedure names and do not supply an C<as>
3180 attribute, the column names returned are storage-dependent. E.g. MySQL would
3181 return a column named C<count(employeeid)> in the above example.
3182
3183 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3184 'select'.
3185
3186 =head2 +select
3187
3188 =over 4
3189
3190 Indicates additional columns to be selected from storage.  Works the same as
3191 L</select> but adds columns to the selection.
3192
3193 =back
3194
3195 =head2 +as
3196
3197 =over 4
3198
3199 Indicates additional column names for those added via L</+select>. See L</as>.
3200
3201 =back
3202
3203 =head2 as
3204
3205 =over 4
3206
3207 =item Value: \@inflation_names
3208
3209 =back
3210
3211 Indicates column names for object inflation. That is, C<as>
3212 indicates the name that the column can be accessed as via the
3213 C<get_column> method (or via the object accessor, B<if one already
3214 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3215
3216 The C<as> attribute is used in conjunction with C<select>,
3217 usually when C<select> contains one or more function or stored
3218 procedure names:
3219
3220   $rs = $schema->resultset('Employee')->search(undef, {
3221     select => [
3222       'name',
3223       { count => 'employeeid' }
3224     ],
3225     as => ['name', 'employee_count'],
3226   });
3227
3228   my $employee = $rs->first(); # get the first Employee
3229
3230 If the object against which the search is performed already has an accessor
3231 matching a column name specified in C<as>, the value can be retrieved using
3232 the accessor as normal:
3233
3234   my $name = $employee->name();
3235
3236 If on the other hand an accessor does not exist in the object, you need to
3237 use C<get_column> instead:
3238
3239   my $employee_count = $employee->get_column('employee_count');
3240
3241 You can create your own accessors if required - see
3242 L<DBIx::Class::Manual::Cookbook> for details.
3243
3244 Please note: This will NOT insert an C<AS employee_count> into the SQL
3245 statement produced, it is used for internal access only. Thus
3246 attempting to use the accessor in an C<order_by> clause or similar
3247 will fail miserably.
3248
3249 To get around this limitation, you can supply literal SQL to your
3250 C<select> attibute that contains the C<AS alias> text, eg:
3251
3252   select => [\'myfield AS alias']
3253
3254 =head2 join
3255
3256 =over 4
3257
3258 =item Value: ($rel_name | \@rel_names | \%rel_names)
3259
3260 =back
3261
3262 Contains a list of relationships that should be joined for this query.  For
3263 example:
3264
3265   # Get CDs by Nine Inch Nails
3266   my $rs = $schema->resultset('CD')->search(
3267     { 'artist.name' => 'Nine Inch Nails' },
3268     { join => 'artist' }
3269   );
3270
3271 Can also contain a hash reference to refer to the other relation's relations.
3272 For example:
3273
3274   package MyApp::Schema::Track;
3275   use base qw/DBIx::Class/;
3276   __PACKAGE__->table('track');
3277   __PACKAGE__->add_columns(qw/trackid cd position title/);
3278   __PACKAGE__->set_primary_key('trackid');
3279   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3280   1;
3281
3282   # In your application
3283   my $rs = $schema->resultset('Artist')->search(
3284     { 'track.title' => 'Teardrop' },
3285     {
3286       join     => { cd => 'track' },
3287       order_by => 'artist.name',
3288     }
3289   );
3290
3291 You need to use the relationship (not the table) name in  conditions,
3292 because they are aliased as such. The current table is aliased as "me", so
3293 you need to use me.column_name in order to avoid ambiguity. For example:
3294
3295   # Get CDs from 1984 with a 'Foo' track
3296   my $rs = $schema->resultset('CD')->search(
3297     {
3298       'me.year' => 1984,
3299       'tracks.name' => 'Foo'
3300     },
3301     { join => 'tracks' }
3302   );
3303
3304 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3305 similarly for a third time). For e.g.
3306
3307   my $rs = $schema->resultset('Artist')->search({
3308     'cds.title'   => 'Down to Earth',
3309     'cds_2.title' => 'Popular',
3310   }, {
3311     join => [ qw/cds cds/ ],
3312   });
3313
3314 will return a set of all artists that have both a cd with title 'Down
3315 to Earth' and a cd with title 'Popular'.
3316
3317 If you want to fetch related objects from other tables as well, see C<prefetch>
3318 below.
3319
3320 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3321
3322 =head2 prefetch
3323
3324 =over 4
3325
3326 =item Value: ($rel_name | \@rel_names | \%rel_names)
3327
3328 =back
3329
3330 Contains one or more relationships that should be fetched along with
3331 the main query (when they are accessed afterwards the data will
3332 already be available, without extra queries to the database).  This is
3333 useful for when you know you will need the related objects, because it
3334 saves at least one query:
3335
3336   my $rs = $schema->resultset('Tag')->search(
3337     undef,
3338     {
3339       prefetch => {
3340         cd => 'artist'
3341       }
3342     }
3343   );
3344
3345 The initial search results in SQL like the following:
3346
3347   SELECT tag.*, cd.*, artist.* FROM tag
3348   JOIN cd ON tag.cd = cd.cdid
3349   JOIN artist ON cd.artist = artist.artistid
3350
3351 L<DBIx::Class> has no need to go back to the database when we access the
3352 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3353 case.
3354
3355 Simple prefetches will be joined automatically, so there is no need
3356 for a C<join> attribute in the above search.
3357
3358 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3359 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3360 with an accessor type of 'single' or 'filter'). A more complex example that
3361 prefetches an artists cds, the tracks on those cds, and the tags associted
3362 with that artist is given below (assuming many-to-many from artists to tags):
3363
3364  my $rs = $schema->resultset('Artist')->search(
3365    undef,
3366    {
3367      prefetch => [
3368        { cds => 'tracks' },
3369        { artist_tags => 'tags' }
3370      ]
3371    }
3372  );
3373
3374
3375 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3376 attributes will be ignored.
3377
3378 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3379 exactly as you might expect.
3380
3381 =over 4
3382
3383 =item *
3384
3385 Prefetch uses the L</cache> to populate the prefetched relationships. This
3386 may or may not be what you want.
3387
3388 =item *
3389
3390 If you specify a condition on a prefetched relationship, ONLY those
3391 rows that match the prefetched condition will be fetched into that relationship.
3392 This means that adding prefetch to a search() B<may alter> what is returned by
3393 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3394
3395   my $artist_rs = $schema->resultset('Artist')->search({
3396       'cds.year' => 2008,
3397   }, {
3398       join => 'cds',
3399   });
3400
3401   my $count = $artist_rs->first->cds->count;
3402
3403   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3404
3405   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3406
3407   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3408
3409 that cmp_ok() may or may not pass depending on the datasets involved. This
3410 behavior may or may not survive the 0.09 transition.
3411
3412 =back
3413
3414 =head2 page
3415
3416 =over 4
3417
3418 =item Value: $page
3419
3420 =back
3421
3422 Makes the resultset paged and specifies the page to retrieve. Effectively
3423 identical to creating a non-pages resultset and then calling ->page($page)
3424 on it.
3425
3426 If L<rows> attribute is not specified it defaults to 10 rows per page.
3427
3428 When you have a paged resultset, L</count> will only return the number
3429 of rows in the page. To get the total, use the L</pager> and call
3430 C<total_entries> on it.
3431
3432 =head2 rows
3433
3434 =over 4
3435
3436 =item Value: $rows
3437
3438 =back
3439
3440 Specifes the maximum number of rows for direct retrieval or the number of
3441 rows per page if the page attribute or method is used.
3442
3443 =head2 offset
3444
3445 =over 4
3446
3447 =item Value: $offset
3448
3449 =back
3450
3451 Specifies the (zero-based) row number for the  first row to be returned, or the
3452 of the first row of the first page if paging is used.
3453
3454 =head2 group_by
3455
3456 =over 4
3457
3458 =item Value: \@columns
3459
3460 =back
3461
3462 A arrayref of columns to group by. Can include columns of joined tables.
3463
3464   group_by => [qw/ column1 column2 ... /]
3465
3466 =head2 having
3467
3468 =over 4
3469
3470 =item Value: $condition
3471
3472 =back
3473
3474 HAVING is a select statement attribute that is applied between GROUP BY and
3475 ORDER BY. It is applied to the after the grouping calculations have been
3476 done.
3477
3478   having => { 'count(employee)' => { '>=', 100 } }
3479
3480 =head2 distinct
3481
3482 =over 4
3483
3484 =item Value: (0 | 1)
3485
3486 =back
3487
3488 Set to 1 to group by all columns. If the resultset already has a group_by
3489 attribute, this setting is ignored and an appropriate warning is issued.
3490
3491 =head2 where
3492
3493 =over 4
3494
3495 Adds to the WHERE clause.
3496
3497   # only return rows WHERE deleted IS NULL for all searches
3498   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3499
3500 Can be overridden by passing C<< { where => undef } >> as an attribute
3501 to a resultset.
3502
3503 =back
3504
3505 =head2 cache
3506
3507 Set to 1 to cache search results. This prevents extra SQL queries if you
3508 revisit rows in your ResultSet:
3509
3510   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3511
3512   while( my $artist = $resultset->next ) {
3513     ... do stuff ...
3514   }
3515
3516   $rs->first; # without cache, this would issue a query
3517
3518 By default, searches are not cached.
3519
3520 For more examples of using these attributes, see
3521 L<DBIx::Class::Manual::Cookbook>.
3522
3523 =head2 for
3524
3525 =over 4
3526
3527 =item Value: ( 'update' | 'shared' )
3528
3529 =back
3530
3531 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3532 ... FOR SHARED.
3533
3534 =cut
3535
3536 1;