lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 961   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 962   @new = $self->{_attrs}{record_filter}->(@new)
 963     if exists $self->{_attrs}{record_filter};
 964   return @new;
 965 }
 966
 967 sub _collapse_result {
 968   my ($self, $as_proto, $row) = @_;
 969
 970   my @copy = @$row;
 971
 972   # 'foo'         => [ undef, 'foo' ]
 973   # 'foo.bar'     => [ 'foo', 'bar' ]
 974   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 975
 976   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 977
 978   my %collapse = %{$self->{_attrs}{collapse}||{}};
 979
 980   my @pri_index;
 981
 982   # if we're doing collapsing (has_many prefetch) we need to grab records
 983   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 984   # we know we don't have to bother.
 985
 986   # the reason for not using the collapse stuff directly is because if you
 987   # had for e.g. two artists in a row with no cds, the collapse info for
 988   # both would be NULL (undef) so you'd lose the second artist
 989
 990   # store just the index so we can check the array positions from the row
 991   # without having to contruct the full hash
 992
 993   if (keys %collapse) {
 994     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 995     foreach my $i (0 .. $#construct_as) {
 996       next if defined($construct_as[$i][0]); # only self table
 997       if (delete $pri{$construct_as[$i][1]}) {
 998         push(@pri_index, $i);
 999       }
1000       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1001     }
1002   }
1003
1004   # no need to do an if, it'll be empty if @pri_index is empty anyway
1005
1006   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1007
1008   my @const_rows;
1009
1010   do { # no need to check anything at the front, we always want the first row
1011
1012     my %const;
1013
1014     foreach my $this_as (@construct_as) {
1015       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1016     }
1017
1018     push(@const_rows, \%const);
1019
1020   } until ( # no pri_index => no collapse => drop straight out
1021       !@pri_index
1022     or
1023       do { # get another row, stash it, drop out if different PK
1024
1025         @copy = $self->cursor->next;
1026         $self->{stashed_row} = \@copy;
1027
1028         # last thing in do block, counts as true if anything doesn't match
1029
1030         # check xor defined first for NULL vs. NOT NULL then if one is
1031         # defined the other must be so check string equality
1032
1033         grep {
1034           (defined $pri_vals{$_} ^ defined $copy[$_])
1035           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1036         } @pri_index;
1037       }
1038   );
1039
1040   my $alias = $self->{attrs}{alias};
1041   my $info = [];
1042
1043   my %collapse_pos;
1044
1045   my @const_keys;
1046
1047   foreach my $const (@const_rows) {
1048     scalar @const_keys or do {
1049       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1050     };
1051     foreach my $key (@const_keys) {
1052       if (length $key) {
1053         my $target = $info;
1054         my @parts = split(/\./, $key);
1055         my $cur = '';
1056         my $data = $const->{$key};
1057         foreach my $p (@parts) {
1058           $target = $target->[1]->{$p} ||= [];
1059           $cur .= ".${p}";
1060           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1061             # collapsing at this point and on final part
1062             my $pos = $collapse_pos{$cur};
1063             CK: foreach my $ck (@ckey) {
1064               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1065                 $collapse_pos{$cur} = $data;
1066                 delete @collapse_pos{ # clear all positioning for sub-entries
1067                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1068                 };
1069                 push(@$target, []);
1070                 last CK;
1071               }
1072             }
1073           }
1074           if (exists $collapse{$cur}) {
1075             $target = $target->[-1];
1076           }
1077         }
1078         $target->[0] = $data;
1079       } else {
1080         $info->[0] = $const->{$key};
1081       }
1082     }
1083   }
1084
1085   return $info;
1086 }
1087
1088 =head2 result_source
1089
1090 =over 4
1091
1092 =item Arguments: $result_source?
1093
1094 =item Return Value: $result_source
1095
1096 =back
1097
1098 An accessor for the primary ResultSource object from which this ResultSet
1099 is derived.
1100
1101 =head2 result_class
1102
1103 =over 4
1104
1105 =item Arguments: $result_class?
1106
1107 =item Return Value: $result_class
1108
1109 =back
1110
1111 An accessor for the class to use when creating row objects. Defaults to
1112 C<< result_source->result_class >> - which in most cases is the name of the
1113 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1114
1115 Note that changing the result_class will also remove any components
1116 that were originally loaded in the source class via
1117 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1118 in the original source class will not run.
1119
1120 =cut
1121
1122 sub result_class {
1123   my ($self, $result_class) = @_;
1124   if ($result_class) {
1125     $self->ensure_class_loaded($result_class);
1126     $self->_result_class($result_class);
1127   }
1128   $self->_result_class;
1129 }
1130
1131 =head2 count
1132
1133 =over 4
1134
1135 =item Arguments: $cond, \%attrs??
1136
1137 =item Return Value: $count
1138
1139 =back
1140
1141 Performs an SQL C<COUNT> with the same query as the resultset was built
1142 with to find the number of elements. Passing arguments is equivalent to
1143 C<< $rs->search ($cond, \%attrs)->count >>
1144
1145 =cut
1146
1147 sub count {
1148   my $self = shift;
1149   return $self->search(@_)->count if @_ and defined $_[0];
1150   return scalar @{ $self->get_cache } if $self->get_cache;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153
1154   # this is a little optimization - it is faster to do the limit
1155   # adjustments in software, instead of a subquery
1156   my $rows = delete $attrs->{rows};
1157   my $offset = delete $attrs->{offset};
1158
1159   my $crs;
1160   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1161     $crs = $self->_count_subq_rs ($attrs);
1162   }
1163   else {
1164     $crs = $self->_count_rs ($attrs);
1165   }
1166   my $count = $crs->next;
1167
1168   $count -= $offset if $offset;
1169   $count = $rows if $rows and $rows < $count;
1170   $count = 0 if ($count < 0);
1171
1172   return $count;
1173 }
1174
1175 =head2 count_rs
1176
1177 =over 4
1178
1179 =item Arguments: $cond, \%attrs??
1180
1181 =item Return Value: $count_rs
1182
1183 =back
1184
1185 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1186 This can be very handy for subqueries:
1187
1188   ->search( { amount => $some_rs->count_rs->as_query } )
1189
1190 As with regular resultsets the SQL query will be executed only after
1191 the resultset is accessed via L</next> or L</all>. That would return
1192 the same single value obtainable via L</count>.
1193
1194 =cut
1195
1196 sub count_rs {
1197   my $self = shift;
1198   return $self->search(@_)->count_rs if @_;
1199
1200   # this may look like a lack of abstraction (count() does about the same)
1201   # but in fact an _rs *must* use a subquery for the limits, as the
1202   # software based limiting can not be ported if this $rs is to be used
1203   # in a subquery itself (i.e. ->as_query)
1204   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1205     return $self->_count_subq_rs;
1206   }
1207   else {
1208     return $self->_count_rs;
1209   }
1210 }
1211
1212 #
1213 # returns a ResultSetColumn object tied to the count query
1214 #
1215 sub _count_rs {
1216   my ($self, $attrs) = @_;
1217
1218   my $rsrc = $self->result_source;
1219   $attrs ||= $self->_resolved_attrs;
1220
1221   my $tmp_attrs = { %$attrs };
1222
1223   # take off any limits, record_filter is cdbi, and no point of ordering a count
1224   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1225
1226   # overwrite the selector (supplied by the storage)
1227   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1228   $tmp_attrs->{as} = 'count';
1229
1230   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1231
1232   return $tmp_rs;
1233 }
1234
1235 #
1236 # same as above but uses a subquery
1237 #
1238 sub _count_subq_rs {
1239   my ($self, $attrs) = @_;
1240
1241   my $rsrc = $self->result_source;
1242   $attrs ||= $self->_resolved_attrs_copy;
1243
1244   my $sub_attrs = { %$attrs };
1245
1246   # these can not go in the subquery, and there is no point of ordering it
1247   delete $sub_attrs->{$_} for qw/collapse select as order_by/;
1248
1249   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1250   # clobber old group_by regardless
1251   if ( keys %{$attrs->{collapse}} ) {
1252     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1253   }
1254
1255   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1256
1257   $attrs->{from} = [{
1258     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1259   }];
1260
1261   # the subquery replaces this
1262   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1263
1264   return $self->_count_rs ($attrs);
1265 }
1266
1267
1268 sub _bool {
1269   return 1;
1270 }
1271
1272 =head2 count_literal
1273
1274 =over 4
1275
1276 =item Arguments: $sql_fragment, @bind_values
1277
1278 =item Return Value: $count
1279
1280 =back
1281
1282 Counts the results in a literal query. Equivalent to calling L</search_literal>
1283 with the passed arguments, then L</count>.
1284
1285 =cut
1286
1287 sub count_literal { shift->search_literal(@_)->count; }
1288
1289 =head2 all
1290
1291 =over 4
1292
1293 =item Arguments: none
1294
1295 =item Return Value: @objects
1296
1297 =back
1298
1299 Returns all elements in the resultset. Called implicitly if the resultset
1300 is returned in list context.
1301
1302 =cut
1303
1304 sub all {
1305   my $self = shift;
1306   if(@_) {
1307       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1308   }
1309
1310   return @{ $self->get_cache } if $self->get_cache;
1311
1312   my @obj;
1313
1314   # TODO: don't call resolve here
1315   if (keys %{$self->_resolved_attrs->{collapse}}) {
1316 #  if ($self->{attrs}{prefetch}) {
1317       # Using $self->cursor->all is really just an optimisation.
1318       # If we're collapsing has_many prefetches it probably makes
1319       # very little difference, and this is cleaner than hacking
1320       # _construct_object to survive the approach
1321     my @row = $self->cursor->next;
1322     while (@row) {
1323       push(@obj, $self->_construct_object(@row));
1324       @row = (exists $self->{stashed_row}
1325                ? @{delete $self->{stashed_row}}
1326                : $self->cursor->next);
1327     }
1328   } else {
1329     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1330   }
1331
1332   $self->set_cache(\@obj) if $self->{attrs}{cache};
1333   return @obj;
1334 }
1335
1336 =head2 reset
1337
1338 =over 4
1339
1340 =item Arguments: none
1341
1342 =item Return Value: $self
1343
1344 =back
1345
1346 Resets the resultset's cursor, so you can iterate through the elements again.
1347
1348 =cut
1349
1350 sub reset {
1351   my ($self) = @_;
1352   delete $self->{_attrs} if exists $self->{_attrs};
1353   $self->{all_cache_position} = 0;
1354   $self->cursor->reset;
1355   return $self;
1356 }
1357
1358 =head2 first
1359
1360 =over 4
1361
1362 =item Arguments: none
1363
1364 =item Return Value: $object?
1365
1366 =back
1367
1368 Resets the resultset and returns an object for the first result (if the
1369 resultset returns anything).
1370
1371 =cut
1372
1373 sub first {
1374   return $_[0]->reset->next;
1375 }
1376
1377
1378 # _rs_update_delete
1379 #
1380 # Determines whether and what type of subquery is required for the $rs operation.
1381 # If grouping is necessary either supplies its own, or verifies the current one
1382 # After all is done delegates to the proper storage method.
1383
1384 sub _rs_update_delete {
1385   my ($self, $op, $values) = @_;
1386
1387   my $rsrc = $self->result_source;
1388
1389   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1390   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1391
1392   if ($needs_group_by_subq or $needs_subq) {
1393
1394     # make a new $rs selecting only the PKs (that's all we really need)
1395     my $attrs = $self->_resolved_attrs_copy;
1396
1397     delete $attrs->{$_} for qw/collapse select as/;
1398     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1399
1400     if ($needs_group_by_subq) {
1401       # make sure no group_by was supplied, or if there is one - make sure it matches
1402       # the columns compiled above perfectly. Anything else can not be sanely executed
1403       # on most databases so croak right then and there
1404
1405       if (my $g = $attrs->{group_by}) {
1406         my @current_group_by = map
1407           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1408           (ref $g eq 'ARRAY' ? @$g : $g );
1409
1410         if (
1411           join ("\x00", sort @current_group_by)
1412             ne
1413           join ("\x00", sort @{$attrs->{columns}} )
1414         ) {
1415           $self->throw_exception (
1416             "You have just attempted a $op operation on a resultset which does group_by"
1417             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1418             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1419             . ' kind of queries. Please retry the operation with a modified group_by or'
1420             . ' without using one at all.'
1421           );
1422         }
1423       }
1424       else {
1425         $attrs->{group_by} = $attrs->{columns};
1426       }
1427     }
1428
1429     my $subrs = (ref $self)->new($rsrc, $attrs);
1430
1431     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1432   }
1433   else {
1434     return $rsrc->storage->$op(
1435       $rsrc,
1436       $op eq 'update' ? $values : (),
1437       $self->_cond_for_update_delete,
1438     );
1439   }
1440 }
1441
1442
1443 # _cond_for_update_delete
1444 #
1445 # update/delete require the condition to be modified to handle
1446 # the differing SQL syntax available.  This transforms the $self->{cond}
1447 # appropriately, returning the new condition.
1448
1449 sub _cond_for_update_delete {
1450   my ($self, $full_cond) = @_;
1451   my $cond = {};
1452
1453   $full_cond ||= $self->{cond};
1454   # No-op. No condition, we're updating/deleting everything
1455   return $cond unless ref $full_cond;
1456
1457   if (ref $full_cond eq 'ARRAY') {
1458     $cond = [
1459       map {
1460         my %hash;
1461         foreach my $key (keys %{$_}) {
1462           $key =~ /([^.]+)$/;
1463           $hash{$1} = $_->{$key};
1464         }
1465         \%hash;
1466       } @{$full_cond}
1467     ];
1468   }
1469   elsif (ref $full_cond eq 'HASH') {
1470     if ((keys %{$full_cond})[0] eq '-and') {
1471       $cond->{-and} = [];
1472       my @cond = @{$full_cond->{-and}};
1473        for (my $i = 0; $i < @cond; $i++) {
1474         my $entry = $cond[$i];
1475         my $hash;
1476         if (ref $entry eq 'HASH') {
1477           $hash = $self->_cond_for_update_delete($entry);
1478         }
1479         else {
1480           $entry =~ /([^.]+)$/;
1481           $hash->{$1} = $cond[++$i];
1482         }
1483         push @{$cond->{-and}}, $hash;
1484       }
1485     }
1486     else {
1487       foreach my $key (keys %{$full_cond}) {
1488         $key =~ /([^.]+)$/;
1489         $cond->{$1} = $full_cond->{$key};
1490       }
1491     }
1492   }
1493   else {
1494     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1495   }
1496
1497   return $cond;
1498 }
1499
1500
1501 =head2 update
1502
1503 =over 4
1504
1505 =item Arguments: \%values
1506
1507 =item Return Value: $storage_rv
1508
1509 =back
1510
1511 Sets the specified columns in the resultset to the supplied values in a
1512 single query. Return value will be true if the update succeeded or false
1513 if no records were updated; exact type of success value is storage-dependent.
1514
1515 =cut
1516
1517 sub update {
1518   my ($self, $values) = @_;
1519   $self->throw_exception('Values for update must be a hash')
1520     unless ref $values eq 'HASH';
1521
1522   return $self->_rs_update_delete ('update', $values);
1523 }
1524
1525 =head2 update_all
1526
1527 =over 4
1528
1529 =item Arguments: \%values
1530
1531 =item Return Value: 1
1532
1533 =back
1534
1535 Fetches all objects and updates them one at a time. Note that C<update_all>
1536 will run DBIC cascade triggers, while L</update> will not.
1537
1538 =cut
1539
1540 sub update_all {
1541   my ($self, $values) = @_;
1542   $self->throw_exception('Values for update_all must be a hash')
1543     unless ref $values eq 'HASH';
1544   foreach my $obj ($self->all) {
1545     $obj->set_columns($values)->update;
1546   }
1547   return 1;
1548 }
1549
1550 =head2 delete
1551
1552 =over 4
1553
1554 =item Arguments: none
1555
1556 =item Return Value: $storage_rv
1557
1558 =back
1559
1560 Deletes the contents of the resultset from its result source. Note that this
1561 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1562 to run. See also L<DBIx::Class::Row/delete>.
1563
1564 Return value will be the amount of rows deleted; exact type of return value
1565 is storage-dependent.
1566
1567 =cut
1568
1569 sub delete {
1570   my $self = shift;
1571   $self->throw_exception('delete does not accept any arguments')
1572     if @_;
1573
1574   return $self->_rs_update_delete ('delete');
1575 }
1576
1577 =head2 delete_all
1578
1579 =over 4
1580
1581 =item Arguments: none
1582
1583 =item Return Value: 1
1584
1585 =back
1586
1587 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1588 will run DBIC cascade triggers, while L</delete> will not.
1589
1590 =cut
1591
1592 sub delete_all {
1593   my $self = shift;
1594   $self->throw_exception('delete_all does not accept any arguments')
1595     if @_;
1596
1597   $_->delete for $self->all;
1598   return 1;
1599 }
1600
1601 =head2 populate
1602
1603 =over 4
1604
1605 =item Arguments: \@data;
1606
1607 =back
1608
1609 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1610 For the arrayref of hashrefs style each hashref should be a structure suitable
1611 forsubmitting to a $resultset->create(...) method.
1612
1613 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1614 to insert the data, as this is a faster method.
1615
1616 Otherwise, each set of data is inserted into the database using
1617 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1618 accumulated into an array. The array itself, or an array reference
1619 is returned depending on scalar or list context.
1620
1621 Example:  Assuming an Artist Class that has many CDs Classes relating:
1622
1623   my $Artist_rs = $schema->resultset("Artist");
1624
1625   ## Void Context Example
1626   $Artist_rs->populate([
1627      { artistid => 4, name => 'Manufactured Crap', cds => [
1628         { title => 'My First CD', year => 2006 },
1629         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1630       ],
1631      },
1632      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1633         { title => 'My parents sold me to a record company' ,year => 2005 },
1634         { title => 'Why Am I So Ugly?', year => 2006 },
1635         { title => 'I Got Surgery and am now Popular', year => 2007 }
1636       ],
1637      },
1638   ]);
1639
1640   ## Array Context Example
1641   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1642     { name => "Artist One"},
1643     { name => "Artist Two"},
1644     { name => "Artist Three", cds=> [
1645     { title => "First CD", year => 2007},
1646     { title => "Second CD", year => 2008},
1647   ]}
1648   ]);
1649
1650   print $ArtistOne->name; ## response is 'Artist One'
1651   print $ArtistThree->cds->count ## reponse is '2'
1652
1653 For the arrayref of arrayrefs style,  the first element should be a list of the
1654 fieldsnames to which the remaining elements are rows being inserted.  For
1655 example:
1656
1657   $Arstist_rs->populate([
1658     [qw/artistid name/],
1659     [100, 'A Formally Unknown Singer'],
1660     [101, 'A singer that jumped the shark two albums ago'],
1661     [102, 'An actually cool singer.'],
1662   ]);
1663
1664 Please note an important effect on your data when choosing between void and
1665 wantarray context. Since void context goes straight to C<insert_bulk> in
1666 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1667 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1668 create primary keys for you, you will find that your PKs are empty.  In this
1669 case you will have to use the wantarray context in order to create those
1670 values.
1671
1672 =cut
1673
1674 sub populate {
1675   my $self = shift @_;
1676   my $data = ref $_[0][0] eq 'HASH'
1677     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1678     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1679
1680   if(defined wantarray) {
1681     my @created;
1682     foreach my $item (@$data) {
1683       push(@created, $self->create($item));
1684     }
1685     return wantarray ? @created : \@created;
1686   } else {
1687     my ($first, @rest) = @$data;
1688
1689     my @names = grep {!ref $first->{$_}} keys %$first;
1690     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1691     my @pks = $self->result_source->primary_columns;
1692
1693     ## do the belongs_to relationships
1694     foreach my $index (0..$#$data) {
1695
1696       # delegate to create() for any dataset without primary keys with specified relationships
1697       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1698         for my $r (@rels) {
1699           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1700             my @ret = $self->populate($data);
1701             return;
1702           }
1703         }
1704       }
1705
1706       foreach my $rel (@rels) {
1707         next unless ref $data->[$index]->{$rel} eq "HASH";
1708         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1709         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1710         my $related = $result->result_source->_resolve_condition(
1711           $result->result_source->relationship_info($reverse)->{cond},
1712           $self,
1713           $result,
1714         );
1715
1716         delete $data->[$index]->{$rel};
1717         $data->[$index] = {%{$data->[$index]}, %$related};
1718
1719         push @names, keys %$related if $index == 0;
1720       }
1721     }
1722
1723     ## do bulk insert on current row
1724     my @values = map { [ @$_{@names} ] } @$data;
1725
1726     $self->result_source->storage->insert_bulk(
1727       $self->result_source,
1728       \@names,
1729       \@values,
1730     );
1731
1732     ## do the has_many relationships
1733     foreach my $item (@$data) {
1734
1735       foreach my $rel (@rels) {
1736         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1737
1738         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1739      || $self->throw_exception('Cannot find the relating object.');
1740
1741         my $child = $parent->$rel;
1742
1743         my $related = $child->result_source->_resolve_condition(
1744           $parent->result_source->relationship_info($rel)->{cond},
1745           $child,
1746           $parent,
1747         );
1748
1749         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1750         my @populate = map { {%$_, %$related} } @rows_to_add;
1751
1752         $child->populate( \@populate );
1753       }
1754     }
1755   }
1756 }
1757
1758 =head2 _normalize_populate_args ($args)
1759
1760 Private method used by L</populate> to normalize its incoming arguments.  Factored
1761 out in case you want to subclass and accept new argument structures to the
1762 L</populate> method.
1763
1764 =cut
1765
1766 sub _normalize_populate_args {
1767   my ($self, $data) = @_;
1768   my @names = @{shift(@$data)};
1769   my @results_to_create;
1770   foreach my $datum (@$data) {
1771     my %result_to_create;
1772     foreach my $index (0..$#names) {
1773       $result_to_create{$names[$index]} = $$datum[$index];
1774     }
1775     push @results_to_create, \%result_to_create;
1776   }
1777   return \@results_to_create;
1778 }
1779
1780 =head2 pager
1781
1782 =over 4
1783
1784 =item Arguments: none
1785
1786 =item Return Value: $pager
1787
1788 =back
1789
1790 Return Value a L<Data::Page> object for the current resultset. Only makes
1791 sense for queries with a C<page> attribute.
1792
1793 To get the full count of entries for a paged resultset, call
1794 C<total_entries> on the L<Data::Page> object.
1795
1796 =cut
1797
1798 sub pager {
1799   my ($self) = @_;
1800
1801   return $self->{pager} if $self->{pager};
1802
1803   my $attrs = $self->{attrs};
1804   $self->throw_exception("Can't create pager for non-paged rs")
1805     unless $self->{attrs}{page};
1806   $attrs->{rows} ||= 10;
1807
1808   # throw away the paging flags and re-run the count (possibly
1809   # with a subselect) to get the real total count
1810   my $count_attrs = { %$attrs };
1811   delete $count_attrs->{$_} for qw/rows offset page pager/;
1812   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1813
1814   return $self->{pager} = Data::Page->new(
1815     $total_count,
1816     $attrs->{rows},
1817     $self->{attrs}{page}
1818   );
1819 }
1820
1821 =head2 page
1822
1823 =over 4
1824
1825 =item Arguments: $page_number
1826
1827 =item Return Value: $rs
1828
1829 =back
1830
1831 Returns a resultset for the $page_number page of the resultset on which page
1832 is called, where each page contains a number of rows equal to the 'rows'
1833 attribute set on the resultset (10 by default).
1834
1835 =cut
1836
1837 sub page {
1838   my ($self, $page) = @_;
1839   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1840 }
1841
1842 =head2 new_result
1843
1844 =over 4
1845
1846 =item Arguments: \%vals
1847
1848 =item Return Value: $rowobject
1849
1850 =back
1851
1852 Creates a new row object in the resultset's result class and returns
1853 it. The row is not inserted into the database at this point, call
1854 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1855 will tell you whether the row object has been inserted or not.
1856
1857 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1858
1859 =cut
1860
1861 sub new_result {
1862   my ($self, $values) = @_;
1863   $self->throw_exception( "new_result needs a hash" )
1864     unless (ref $values eq 'HASH');
1865
1866   my %new;
1867   my $alias = $self->{attrs}{alias};
1868
1869   if (
1870     defined $self->{cond}
1871     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1872   ) {
1873     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1874     $new{-from_resultset} = [ keys %new ] if keys %new;
1875   } else {
1876     $self->throw_exception(
1877       "Can't abstract implicit construct, condition not a hash"
1878     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1879
1880     my $collapsed_cond = (
1881       $self->{cond}
1882         ? $self->_collapse_cond($self->{cond})
1883         : {}
1884     );
1885
1886     # precendence must be given to passed values over values inherited from
1887     # the cond, so the order here is important.
1888     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1889     while( my($col,$value) = each %implied ){
1890       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1891         $new{$col} = $value->{'='};
1892         next;
1893       }
1894       $new{$col} = $value if $self->_is_deterministic_value($value);
1895     }
1896   }
1897
1898   %new = (
1899     %new,
1900     %{ $self->_remove_alias($values, $alias) },
1901     -source_handle => $self->_source_handle,
1902     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1903   );
1904
1905   return $self->result_class->new(\%new);
1906 }
1907
1908 # _is_deterministic_value
1909 #
1910 # Make an effor to strip non-deterministic values from the condition,
1911 # to make sure new_result chokes less
1912
1913 sub _is_deterministic_value {
1914   my $self = shift;
1915   my $value = shift;
1916   my $ref_type = ref $value;
1917   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1918   return 1 if Scalar::Util::blessed($value);
1919   return 0;
1920 }
1921
1922 # _has_resolved_attr
1923 #
1924 # determines if the resultset defines at least one
1925 # of the attributes supplied
1926 #
1927 # used to determine if a subquery is neccessary
1928
1929 sub _has_resolved_attr {
1930   my ($self, @attr_names) = @_;
1931
1932   my $attrs = $self->_resolved_attrs;
1933
1934   my $join_check_req;
1935
1936   for my $n (@attr_names) {
1937     ++$join_check_req if $n eq '-join';
1938
1939     my $attr =  $attrs->{$n};
1940
1941     next if not defined $attr;
1942
1943     if (ref $attr eq 'HASH') {
1944       return 1 if keys %$attr;
1945     }
1946     elsif (ref $attr eq 'ARRAY') {
1947       return 1 if @$attr;
1948     }
1949     else {
1950       return 1 if $attr;
1951     }
1952   }
1953
1954   # a resolved join is expressed as a multi-level from
1955   return 1 if (
1956     $join_check_req
1957       and
1958     ref $attrs->{from} eq 'ARRAY'
1959       and
1960     @{$attrs->{from}} > 1
1961   );
1962
1963   return 0;
1964 }
1965
1966 # _collapse_cond
1967 #
1968 # Recursively collapse the condition.
1969
1970 sub _collapse_cond {
1971   my ($self, $cond, $collapsed) = @_;
1972
1973   $collapsed ||= {};
1974
1975   if (ref $cond eq 'ARRAY') {
1976     foreach my $subcond (@$cond) {
1977       next unless ref $subcond;  # -or
1978       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1979     }
1980   }
1981   elsif (ref $cond eq 'HASH') {
1982     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1983       foreach my $subcond (@{$cond->{-and}}) {
1984         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1985       }
1986     }
1987     else {
1988       foreach my $col (keys %$cond) {
1989         my $value = $cond->{$col};
1990         $collapsed->{$col} = $value;
1991       }
1992     }
1993   }
1994
1995   return $collapsed;
1996 }
1997
1998 # _remove_alias
1999 #
2000 # Remove the specified alias from the specified query hash. A copy is made so
2001 # the original query is not modified.
2002
2003 sub _remove_alias {
2004   my ($self, $query, $alias) = @_;
2005
2006   my %orig = %{ $query || {} };
2007   my %unaliased;
2008
2009   foreach my $key (keys %orig) {
2010     if ($key !~ /\./) {
2011       $unaliased{$key} = $orig{$key};
2012       next;
2013     }
2014     $unaliased{$1} = $orig{$key}
2015       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2016   }
2017
2018   return \%unaliased;
2019 }
2020
2021 =head2 as_query (EXPERIMENTAL)
2022
2023 =over 4
2024
2025 =item Arguments: none
2026
2027 =item Return Value: \[ $sql, @bind ]
2028
2029 =back
2030
2031 Returns the SQL query and bind vars associated with the invocant.
2032
2033 This is generally used as the RHS for a subquery.
2034
2035 B<NOTE>: This feature is still experimental.
2036
2037 =cut
2038
2039 sub as_query {
2040   my $self = shift;
2041
2042   my $attrs = $self->_resolved_attrs_copy;
2043
2044   # For future use:
2045   #
2046   # in list ctx:
2047   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2048   # $sql also has no wrapping parenthesis in list ctx
2049   #
2050   my $sqlbind = $self->result_source->storage
2051     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2052
2053   return $sqlbind;
2054 }
2055
2056 =head2 find_or_new
2057
2058 =over 4
2059
2060 =item Arguments: \%vals, \%attrs?
2061
2062 =item Return Value: $rowobject
2063
2064 =back
2065
2066   my $artist = $schema->resultset('Artist')->find_or_new(
2067     { artist => 'fred' }, { key => 'artists' });
2068
2069   $cd->cd_to_producer->find_or_new({ producer => $producer },
2070                                    { key => 'primary });
2071
2072 Find an existing record from this resultset, based on its primary
2073 key, or a unique constraint. If none exists, instantiate a new result
2074 object and return it. The object will not be saved into your storage
2075 until you call L<DBIx::Class::Row/insert> on it.
2076
2077 You most likely want this method when looking for existing rows using
2078 a unique constraint that is not the primary key, or looking for
2079 related rows.
2080
2081 If you want objects to be saved immediately, use L</find_or_create> instead.
2082
2083 B<Note>: C<find_or_new> is probably not what you want when creating a
2084 new row in a table that uses primary keys supplied by the
2085 database. Passing in a primary key column with a value of I<undef>
2086 will cause L</find> to attempt to search for a row with a value of
2087 I<NULL>.
2088
2089 =cut
2090
2091 sub find_or_new {
2092   my $self     = shift;
2093   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2094   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2095   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2096     return $row;
2097   }
2098   return $self->new_result($hash);
2099 }
2100
2101 =head2 create
2102
2103 =over 4
2104
2105 =item Arguments: \%vals
2106
2107 =item Return Value: a L<DBIx::Class::Row> $object
2108
2109 =back
2110
2111 Attempt to create a single new row or a row with multiple related rows
2112 in the table represented by the resultset (and related tables). This
2113 will not check for duplicate rows before inserting, use
2114 L</find_or_create> to do that.
2115
2116 To create one row for this resultset, pass a hashref of key/value
2117 pairs representing the columns of the table and the values you wish to
2118 store. If the appropriate relationships are set up, foreign key fields
2119 can also be passed an object representing the foreign row, and the
2120 value will be set to its primary key.
2121
2122 To create related objects, pass a hashref for the value if the related
2123 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2124 and use the name of the relationship as the key. (NOT the name of the field,
2125 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2126 of hashrefs containing the data for each of the rows to create in the foreign
2127 tables, again using the relationship name as the key.
2128
2129 Instead of hashrefs of plain related data (key/value pairs), you may
2130 also pass new or inserted objects. New objects (not inserted yet, see
2131 L</new>), will be inserted into their appropriate tables.
2132
2133 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2134
2135 Example of creating a new row.
2136
2137   $person_rs->create({
2138     name=>"Some Person",
2139     email=>"somebody@someplace.com"
2140   });
2141
2142 Example of creating a new row and also creating rows in a related C<has_many>
2143 or C<has_one> resultset.  Note Arrayref.
2144
2145   $artist_rs->create(
2146      { artistid => 4, name => 'Manufactured Crap', cds => [
2147         { title => 'My First CD', year => 2006 },
2148         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2149       ],
2150      },
2151   );
2152
2153 Example of creating a new row and also creating a row in a related
2154 C<belongs_to>resultset. Note Hashref.
2155
2156   $cd_rs->create({
2157     title=>"Music for Silly Walks",
2158     year=>2000,
2159     artist => {
2160       name=>"Silly Musician",
2161     }
2162   });
2163
2164 =cut
2165
2166 sub create {
2167   my ($self, $attrs) = @_;
2168   $self->throw_exception( "create needs a hashref" )
2169     unless ref $attrs eq 'HASH';
2170   return $self->new_result($attrs)->insert;
2171 }
2172
2173 =head2 find_or_create
2174
2175 =over 4
2176
2177 =item Arguments: \%vals, \%attrs?
2178
2179 =item Return Value: $rowobject
2180
2181 =back
2182
2183   $cd->cd_to_producer->find_or_create({ producer => $producer },
2184                                       { key => 'primary' });
2185
2186 Tries to find a record based on its primary key or unique constraints; if none
2187 is found, creates one and returns that instead.
2188
2189   my $cd = $schema->resultset('CD')->find_or_create({
2190     cdid   => 5,
2191     artist => 'Massive Attack',
2192     title  => 'Mezzanine',
2193     year   => 2005,
2194   });
2195
2196 Also takes an optional C<key> attribute, to search by a specific key or unique
2197 constraint. For example:
2198
2199   my $cd = $schema->resultset('CD')->find_or_create(
2200     {
2201       artist => 'Massive Attack',
2202       title  => 'Mezzanine',
2203     },
2204     { key => 'cd_artist_title' }
2205   );
2206
2207 B<Note>: Because find_or_create() reads from the database and then
2208 possibly inserts based on the result, this method is subject to a race
2209 condition. Another process could create a record in the table after
2210 the find has completed and before the create has started. To avoid
2211 this problem, use find_or_create() inside a transaction.
2212
2213 B<Note>: C<find_or_create> is probably not what you want when creating
2214 a new row in a table that uses primary keys supplied by the
2215 database. Passing in a primary key column with a value of I<undef>
2216 will cause L</find> to attempt to search for a row with a value of
2217 I<NULL>.
2218
2219 See also L</find> and L</update_or_create>. For information on how to declare
2220 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2221
2222 =cut
2223
2224 sub find_or_create {
2225   my $self     = shift;
2226   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2227   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2228   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2229     return $row;
2230   }
2231   return $self->create($hash);
2232 }
2233
2234 =head2 update_or_create
2235
2236 =over 4
2237
2238 =item Arguments: \%col_values, { key => $unique_constraint }?
2239
2240 =item Return Value: $rowobject
2241
2242 =back
2243
2244   $resultset->update_or_create({ col => $val, ... });
2245
2246 First, searches for an existing row matching one of the unique constraints
2247 (including the primary key) on the source of this resultset. If a row is
2248 found, updates it with the other given column values. Otherwise, creates a new
2249 row.
2250
2251 Takes an optional C<key> attribute to search on a specific unique constraint.
2252 For example:
2253
2254   # In your application
2255   my $cd = $schema->resultset('CD')->update_or_create(
2256     {
2257       artist => 'Massive Attack',
2258       title  => 'Mezzanine',
2259       year   => 1998,
2260     },
2261     { key => 'cd_artist_title' }
2262   );
2263
2264   $cd->cd_to_producer->update_or_create({
2265     producer => $producer,
2266     name => 'harry',
2267   }, {
2268     key => 'primary,
2269   });
2270
2271
2272 If no C<key> is specified, it searches on all unique constraints defined on the
2273 source, including the primary key.
2274
2275 If the C<key> is specified as C<primary>, it searches only on the primary key.
2276
2277 See also L</find> and L</find_or_create>. For information on how to declare
2278 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2279
2280 B<Note>: C<update_or_create> is probably not what you want when
2281 looking for a row in a table that uses primary keys supplied by the
2282 database, unless you actually have a key value. Passing in a primary
2283 key column with a value of I<undef> will cause L</find> to attempt to
2284 search for a row with a value of I<NULL>.
2285
2286 =cut
2287
2288 sub update_or_create {
2289   my $self = shift;
2290   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2291   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2292
2293   my $row = $self->find($cond, $attrs);
2294   if (defined $row) {
2295     $row->update($cond);
2296     return $row;
2297   }
2298
2299   return $self->create($cond);
2300 }
2301
2302 =head2 update_or_new
2303
2304 =over 4
2305
2306 =item Arguments: \%col_values, { key => $unique_constraint }?
2307
2308 =item Return Value: $rowobject
2309
2310 =back
2311
2312   $resultset->update_or_new({ col => $val, ... });
2313
2314 First, searches for an existing row matching one of the unique constraints
2315 (including the primary key) on the source of this resultset. If a row is
2316 found, updates it with the other given column values. Otherwise, instantiate
2317 a new result object and return it. The object will not be saved into your storage
2318 until you call L<DBIx::Class::Row/insert> on it.
2319
2320 Takes an optional C<key> attribute to search on a specific unique constraint.
2321 For example:
2322
2323   # In your application
2324   my $cd = $schema->resultset('CD')->update_or_new(
2325     {
2326       artist => 'Massive Attack',
2327       title  => 'Mezzanine',
2328       year   => 1998,
2329     },
2330     { key => 'cd_artist_title' }
2331   );
2332
2333   if ($cd->in_storage) {
2334       # the cd was updated
2335   }
2336   else {
2337       # the cd is not yet in the database, let's insert it
2338       $cd->insert;
2339   }
2340
2341 See also L</find>, L</find_or_create> and L<find_or_new>.
2342
2343 =cut
2344
2345 sub update_or_new {
2346     my $self  = shift;
2347     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2348     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2349
2350     my $row = $self->find( $cond, $attrs );
2351     if ( defined $row ) {
2352         $row->update($cond);
2353         return $row;
2354     }
2355
2356     return $self->new_result($cond);
2357 }
2358
2359 =head2 get_cache
2360
2361 =over 4
2362
2363 =item Arguments: none
2364
2365 =item Return Value: \@cache_objects?
2366
2367 =back
2368
2369 Gets the contents of the cache for the resultset, if the cache is set.
2370
2371 The cache is populated either by using the L</prefetch> attribute to
2372 L</search> or by calling L</set_cache>.
2373
2374 =cut
2375
2376 sub get_cache {
2377   shift->{all_cache};
2378 }
2379
2380 =head2 set_cache
2381
2382 =over 4
2383
2384 =item Arguments: \@cache_objects
2385
2386 =item Return Value: \@cache_objects
2387
2388 =back
2389
2390 Sets the contents of the cache for the resultset. Expects an arrayref
2391 of objects of the same class as those produced by the resultset. Note that
2392 if the cache is set the resultset will return the cached objects rather
2393 than re-querying the database even if the cache attr is not set.
2394
2395 The contents of the cache can also be populated by using the
2396 L</prefetch> attribute to L</search>.
2397
2398 =cut
2399
2400 sub set_cache {
2401   my ( $self, $data ) = @_;
2402   $self->throw_exception("set_cache requires an arrayref")
2403       if defined($data) && (ref $data ne 'ARRAY');
2404   $self->{all_cache} = $data;
2405 }
2406
2407 =head2 clear_cache
2408
2409 =over 4
2410
2411 =item Arguments: none
2412
2413 =item Return Value: []
2414
2415 =back
2416
2417 Clears the cache for the resultset.
2418
2419 =cut
2420
2421 sub clear_cache {
2422   shift->set_cache(undef);
2423 }
2424
2425 =head2 related_resultset
2426
2427 =over 4
2428
2429 =item Arguments: $relationship_name
2430
2431 =item Return Value: $resultset
2432
2433 =back
2434
2435 Returns a related resultset for the supplied relationship name.
2436
2437   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2438
2439 =cut
2440
2441 sub related_resultset {
2442   my ($self, $rel) = @_;
2443
2444   $self->{related_resultsets} ||= {};
2445   return $self->{related_resultsets}{$rel} ||= do {
2446     my $rel_info = $self->result_source->relationship_info($rel);
2447
2448     $self->throw_exception(
2449       "search_related: result source '" . $self->result_source->source_name .
2450         "' has no such relationship $rel")
2451       unless $rel_info;
2452
2453     my ($from,$seen) = $self->_resolve_from($rel);
2454
2455     my $join_count = $seen->{$rel};
2456     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2457
2458     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2459     my %attrs = %{$self->{attrs}||{}};
2460     delete @attrs{qw(result_class alias)};
2461
2462     my $new_cache;
2463
2464     if (my $cache = $self->get_cache) {
2465       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2466         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2467                         @$cache ];
2468       }
2469     }
2470
2471     my $rel_source = $self->result_source->related_source($rel);
2472
2473     my $new = do {
2474
2475       # The reason we do this now instead of passing the alias to the
2476       # search_rs below is that if you wrap/overload resultset on the
2477       # source you need to know what alias it's -going- to have for things
2478       # to work sanely (e.g. RestrictWithObject wants to be able to add
2479       # extra query restrictions, and these may need to be $alias.)
2480
2481       my $attrs = $rel_source->resultset_attributes;
2482       local $attrs->{alias} = $alias;
2483
2484       $rel_source->resultset
2485                  ->search_rs(
2486                      undef, {
2487                        %attrs,
2488                        join => undef,
2489                        prefetch => undef,
2490                        select => undef,
2491                        as => undef,
2492                        where => $self->{cond},
2493                        seen_join => $seen,
2494                        from => $from,
2495                    });
2496     };
2497     $new->set_cache($new_cache) if $new_cache;
2498     $new;
2499   };
2500 }
2501
2502 =head2 current_source_alias
2503
2504 =over 4
2505
2506 =item Arguments: none
2507
2508 =item Return Value: $source_alias
2509
2510 =back
2511
2512 Returns the current table alias for the result source this resultset is built
2513 on, that will be used in the SQL query. Usually it is C<me>.
2514
2515 Currently the source alias that refers to the result set returned by a
2516 L</search>/L</find> family method depends on how you got to the resultset: it's
2517 C<me> by default, but eg. L</search_related> aliases it to the related result
2518 source name (and keeps C<me> referring to the original result set). The long
2519 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2520 (and make this method unnecessary).
2521
2522 Thus it's currently necessary to use this method in predefined queries (see
2523 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2524 source alias of the current result set:
2525
2526   # in a result set class
2527   sub modified_by {
2528     my ($self, $user) = @_;
2529
2530     my $me = $self->current_source_alias;
2531
2532     return $self->search(
2533       "$me.modified" => $user->id,
2534     );
2535   }
2536
2537 =cut
2538
2539 sub current_source_alias {
2540   my ($self) = @_;
2541
2542   return ($self->{attrs} || {})->{alias} || 'me';
2543 }
2544
2545 # This code is called by search_related, and makes sure there
2546 # is clear separation between the joins before, during, and
2547 # after the relationship. This information is needed later
2548 # in order to properly resolve prefetch aliases (any alias
2549 # with a relation_chain_depth less than the depth of the
2550 # current prefetch is not considered)
2551 sub _resolve_from {
2552   my ($self, $rel) = @_;
2553   my $source = $self->result_source;
2554   my $attrs = $self->{attrs};
2555
2556   my $from = [ @{
2557       $attrs->{from}
2558         ||
2559       [{
2560         -source_handle => $source->handle,
2561         -alias => $attrs->{alias},
2562         $attrs->{alias} => $source->from,
2563       }]
2564   }];
2565
2566   my $seen = { %{$attrs->{seen_join} || {} } };
2567
2568   # we need to take the prefetch the attrs into account before we
2569   # ->_resolve_join as otherwise they get lost - captainL
2570   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2571
2572   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2573
2574   ++$seen->{-relation_chain_depth};
2575
2576   push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2577
2578   ++$seen->{-relation_chain_depth};
2579
2580   return ($from,$seen);
2581 }
2582
2583 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2584 sub _resolved_attrs_copy {
2585   my $self = shift;
2586   return { %{$self->_resolved_attrs (@_)} };
2587 }
2588
2589 sub _resolved_attrs {
2590   my $self = shift;
2591   return $self->{_attrs} if $self->{_attrs};
2592
2593   my $attrs  = { %{ $self->{attrs} || {} } };
2594   my $source = $self->result_source;
2595   my $alias  = $attrs->{alias};
2596
2597   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2598   my @colbits;
2599
2600   # build columns (as long as select isn't set) into a set of as/select hashes
2601   unless ( $attrs->{select} ) {
2602       @colbits = map {
2603           ( ref($_) eq 'HASH' )
2604               ? $_
2605               : {
2606                   (
2607                     /^\Q${alias}.\E(.+)$/
2608                       ? "$1"
2609                       : "$_"
2610                   )
2611                 =>
2612                   (
2613                     /\./
2614                       ? "$_"
2615                       : "${alias}.$_"
2616                   )
2617             }
2618       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2619   }
2620   # add the additional columns on
2621   foreach ( 'include_columns', '+columns' ) {
2622       push @colbits, map {
2623           ( ref($_) eq 'HASH' )
2624             ? $_
2625             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2626       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2627   }
2628
2629   # start with initial select items
2630   if ( $attrs->{select} ) {
2631     $attrs->{select} =
2632         ( ref $attrs->{select} eq 'ARRAY' )
2633       ? [ @{ $attrs->{select} } ]
2634       : [ $attrs->{select} ];
2635     $attrs->{as} = (
2636       $attrs->{as}
2637       ? (
2638         ref $attrs->{as} eq 'ARRAY'
2639         ? [ @{ $attrs->{as} } ]
2640         : [ $attrs->{as} ]
2641         )
2642       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2643     );
2644   }
2645   else {
2646
2647     # otherwise we intialise select & as to empty
2648     $attrs->{select} = [];
2649     $attrs->{as}     = [];
2650   }
2651
2652   # now add colbits to select/as
2653   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2654   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2655
2656   my $adds;
2657   if ( $adds = delete $attrs->{'+select'} ) {
2658     $adds = [$adds] unless ref $adds eq 'ARRAY';
2659     push(
2660       @{ $attrs->{select} },
2661       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2662     );
2663   }
2664   if ( $adds = delete $attrs->{'+as'} ) {
2665     $adds = [$adds] unless ref $adds eq 'ARRAY';
2666     push( @{ $attrs->{as} }, @$adds );
2667   }
2668
2669   $attrs->{from} ||= [ {
2670     -source_handle => $source->handle,
2671     -alias => $self->{attrs}{alias},
2672     $self->{attrs}{alias} => $source->from,
2673   } ];
2674
2675   if ( $attrs->{join} || $attrs->{prefetch} ) {
2676
2677     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2678       if ref $attrs->{from} ne 'ARRAY';
2679
2680     my $join = delete $attrs->{join} || {};
2681
2682     if ( defined $attrs->{prefetch} ) {
2683       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2684     }
2685
2686     $attrs->{from} =    # have to copy here to avoid corrupting the original
2687       [
2688         @{ $attrs->{from} },
2689         $source->_resolve_join(
2690           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2691         )
2692       ];
2693   }
2694
2695   if ( $attrs->{order_by} ) {
2696     $attrs->{order_by} = (
2697       ref( $attrs->{order_by} ) eq 'ARRAY'
2698       ? [ @{ $attrs->{order_by} } ]
2699       : [ $attrs->{order_by} ]
2700     );
2701   }
2702   else {
2703     $attrs->{order_by} = [];
2704   }
2705
2706   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2707     $attrs->{group_by} = [ $attrs->{group_by} ];
2708   }
2709
2710   # If the order_by is otherwise empty - we will use this for TOP limit
2711   # emulation and the like.
2712   # Although this is needed only if the order_by is not defined, it is
2713   # actually cheaper to just populate this rather than properly examining
2714   # order_by (stuf like [ {} ] and the like)
2715   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2716
2717
2718   $attrs->{collapse} ||= {};
2719   if ( my $prefetch = delete $attrs->{prefetch} ) {
2720     $prefetch = $self->_merge_attr( {}, $prefetch );
2721
2722     my $prefetch_ordering = [];
2723
2724     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2725
2726     my @prefetch =
2727       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2728
2729     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2730     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2731
2732     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2733     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2734   }
2735
2736
2737   if (delete $attrs->{distinct}) {
2738     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2739   }
2740
2741   # if both page and offset are specified, produce a combined offset
2742   # even though it doesn't make much sense, this is what pre 081xx has
2743   # been doing
2744   if (my $page = delete $attrs->{page}) {
2745     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2746       ($attrs->{offset} || 0);
2747   }
2748
2749   return $self->{_attrs} = $attrs;
2750 }
2751
2752 sub _joinpath_aliases {
2753   my ($self, $fromspec, $seen) = @_;
2754
2755   my $paths = {};
2756   return $paths unless ref $fromspec eq 'ARRAY';
2757
2758   for my $j (@$fromspec) {
2759
2760     next if ref $j ne 'ARRAY';
2761     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2762
2763     my $p = $paths;
2764     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2765     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2766   }
2767
2768   return $paths;
2769 }
2770
2771 sub _rollout_attr {
2772   my ($self, $attr) = @_;
2773
2774   if (ref $attr eq 'HASH') {
2775     return $self->_rollout_hash($attr);
2776   } elsif (ref $attr eq 'ARRAY') {
2777     return $self->_rollout_array($attr);
2778   } else {
2779     return [$attr];
2780   }
2781 }
2782
2783 sub _rollout_array {
2784   my ($self, $attr) = @_;
2785
2786   my @rolled_array;
2787   foreach my $element (@{$attr}) {
2788     if (ref $element eq 'HASH') {
2789       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2790     } elsif (ref $element eq 'ARRAY') {
2791       #  XXX - should probably recurse here
2792       push( @rolled_array, @{$self->_rollout_array($element)} );
2793     } else {
2794       push( @rolled_array, $element );
2795     }
2796   }
2797   return \@rolled_array;
2798 }
2799
2800 sub _rollout_hash {
2801   my ($self, $attr) = @_;
2802
2803   my @rolled_array;
2804   foreach my $key (keys %{$attr}) {
2805     push( @rolled_array, { $key => $attr->{$key} } );
2806   }
2807   return \@rolled_array;
2808 }
2809
2810 sub _calculate_score {
2811   my ($self, $a, $b) = @_;
2812
2813   if (ref $b eq 'HASH') {
2814     my ($b_key) = keys %{$b};
2815     if (ref $a eq 'HASH') {
2816       my ($a_key) = keys %{$a};
2817       if ($a_key eq $b_key) {
2818         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2819       } else {
2820         return 0;
2821       }
2822     } else {
2823       return ($a eq $b_key) ? 1 : 0;
2824     }
2825   } else {
2826     if (ref $a eq 'HASH') {
2827       my ($a_key) = keys %{$a};
2828       return ($b eq $a_key) ? 1 : 0;
2829     } else {
2830       return ($b eq $a) ? 1 : 0;
2831     }
2832   }
2833 }
2834
2835 sub _merge_attr {
2836   my ($self, $orig, $import) = @_;
2837
2838   return $import unless defined($orig);
2839   return $orig unless defined($import);
2840
2841   $orig = $self->_rollout_attr($orig);
2842   $import = $self->_rollout_attr($import);
2843
2844   my $seen_keys;
2845   foreach my $import_element ( @{$import} ) {
2846     # find best candidate from $orig to merge $b_element into
2847     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2848     foreach my $orig_element ( @{$orig} ) {
2849       my $score = $self->_calculate_score( $orig_element, $import_element );
2850       if ($score > $best_candidate->{score}) {
2851         $best_candidate->{position} = $position;
2852         $best_candidate->{score} = $score;
2853       }
2854       $position++;
2855     }
2856     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2857
2858     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2859       push( @{$orig}, $import_element );
2860     } else {
2861       my $orig_best = $orig->[$best_candidate->{position}];
2862       # merge orig_best and b_element together and replace original with merged
2863       if (ref $orig_best ne 'HASH') {
2864         $orig->[$best_candidate->{position}] = $import_element;
2865       } elsif (ref $import_element eq 'HASH') {
2866         my ($key) = keys %{$orig_best};
2867         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2868       }
2869     }
2870     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2871   }
2872
2873   return $orig;
2874 }
2875
2876 sub result_source {
2877     my $self = shift;
2878
2879     if (@_) {
2880         $self->_source_handle($_[0]->handle);
2881     } else {
2882         $self->_source_handle->resolve;
2883     }
2884 }
2885
2886 =head2 throw_exception
2887
2888 See L<DBIx::Class::Schema/throw_exception> for details.
2889
2890 =cut
2891
2892 sub throw_exception {
2893   my $self=shift;
2894   if (ref $self && $self->_source_handle->schema) {
2895     $self->_source_handle->schema->throw_exception(@_)
2896   } else {
2897     croak(@_);
2898   }
2899
2900 }
2901
2902 # XXX: FIXME: Attributes docs need clearing up
2903
2904 =head1 ATTRIBUTES
2905
2906 Attributes are used to refine a ResultSet in various ways when
2907 searching for data. They can be passed to any method which takes an
2908 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2909 L</count>.
2910
2911 These are in no particular order:
2912
2913 =head2 order_by
2914
2915 =over 4
2916
2917 =item Value: ( $order_by | \@order_by | \%order_by )
2918
2919 =back
2920
2921 Which column(s) to order the results by. If a single column name, or
2922 an arrayref of names is supplied, the argument is passed through
2923 directly to SQL. The hashref syntax allows for connection-agnostic
2924 specification of ordering direction:
2925
2926  For descending order:
2927
2928   order_by => { -desc => [qw/col1 col2 col3/] }
2929
2930  For explicit ascending order:
2931
2932   order_by => { -asc => 'col' }
2933
2934 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2935 supported, although you are strongly encouraged to use the hashref
2936 syntax as outlined above.
2937
2938 =head2 columns
2939
2940 =over 4
2941
2942 =item Value: \@columns
2943
2944 =back
2945
2946 Shortcut to request a particular set of columns to be retrieved. Each
2947 column spec may be a string (a table column name), or a hash (in which
2948 case the key is the C<as> value, and the value is used as the C<select>
2949 expression). Adds C<me.> onto the start of any column without a C<.> in
2950 it and sets C<select> from that, then auto-populates C<as> from
2951 C<select> as normal. (You may also use the C<cols> attribute, as in
2952 earlier versions of DBIC.)
2953
2954 =head2 +columns
2955
2956 =over 4
2957
2958 =item Value: \@columns
2959
2960 =back
2961
2962 Indicates additional columns to be selected from storage. Works the same
2963 as L</columns> but adds columns to the selection. (You may also use the
2964 C<include_columns> attribute, as in earlier versions of DBIC). For
2965 example:-
2966
2967   $schema->resultset('CD')->search(undef, {
2968     '+columns' => ['artist.name'],
2969     join => ['artist']
2970   });
2971
2972 would return all CDs and include a 'name' column to the information
2973 passed to object inflation. Note that the 'artist' is the name of the
2974 column (or relationship) accessor, and 'name' is the name of the column
2975 accessor in the related table.
2976
2977 =head2 include_columns
2978
2979 =over 4
2980
2981 =item Value: \@columns
2982
2983 =back
2984
2985 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2986
2987 =head2 select
2988
2989 =over 4
2990
2991 =item Value: \@select_columns
2992
2993 =back
2994
2995 Indicates which columns should be selected from the storage. You can use
2996 column names, or in the case of RDBMS back ends, function or stored procedure
2997 names:
2998
2999   $rs = $schema->resultset('Employee')->search(undef, {
3000     select => [
3001       'name',
3002       { count => 'employeeid' },
3003       { sum => 'salary' }
3004     ]
3005   });
3006
3007 When you use function/stored procedure names and do not supply an C<as>
3008 attribute, the column names returned are storage-dependent. E.g. MySQL would
3009 return a column named C<count(employeeid)> in the above example.
3010
3011 =head2 +select
3012
3013 =over 4
3014
3015 Indicates additional columns to be selected from storage.  Works the same as
3016 L</select> but adds columns to the selection.
3017
3018 =back
3019
3020 =head2 +as
3021
3022 =over 4
3023
3024 Indicates additional column names for those added via L</+select>. See L</as>.
3025
3026 =back
3027
3028 =head2 as
3029
3030 =over 4
3031
3032 =item Value: \@inflation_names
3033
3034 =back
3035
3036 Indicates column names for object inflation. That is, C<as>
3037 indicates the name that the column can be accessed as via the
3038 C<get_column> method (or via the object accessor, B<if one already
3039 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3040
3041 The C<as> attribute is used in conjunction with C<select>,
3042 usually when C<select> contains one or more function or stored
3043 procedure names:
3044
3045   $rs = $schema->resultset('Employee')->search(undef, {
3046     select => [
3047       'name',
3048       { count => 'employeeid' }
3049     ],
3050     as => ['name', 'employee_count'],
3051   });
3052
3053   my $employee = $rs->first(); # get the first Employee
3054
3055 If the object against which the search is performed already has an accessor
3056 matching a column name specified in C<as>, the value can be retrieved using
3057 the accessor as normal:
3058
3059   my $name = $employee->name();
3060
3061 If on the other hand an accessor does not exist in the object, you need to
3062 use C<get_column> instead:
3063
3064   my $employee_count = $employee->get_column('employee_count');
3065
3066 You can create your own accessors if required - see
3067 L<DBIx::Class::Manual::Cookbook> for details.
3068
3069 Please note: This will NOT insert an C<AS employee_count> into the SQL
3070 statement produced, it is used for internal access only. Thus
3071 attempting to use the accessor in an C<order_by> clause or similar
3072 will fail miserably.
3073
3074 To get around this limitation, you can supply literal SQL to your
3075 C<select> attibute that contains the C<AS alias> text, eg:
3076
3077   select => [\'myfield AS alias']
3078
3079 =head2 join
3080
3081 =over 4
3082
3083 =item Value: ($rel_name | \@rel_names | \%rel_names)
3084
3085 =back
3086
3087 Contains a list of relationships that should be joined for this query.  For
3088 example:
3089
3090   # Get CDs by Nine Inch Nails
3091   my $rs = $schema->resultset('CD')->search(
3092     { 'artist.name' => 'Nine Inch Nails' },
3093     { join => 'artist' }
3094   );
3095
3096 Can also contain a hash reference to refer to the other relation's relations.
3097 For example:
3098
3099   package MyApp::Schema::Track;
3100   use base qw/DBIx::Class/;
3101   __PACKAGE__->table('track');
3102   __PACKAGE__->add_columns(qw/trackid cd position title/);
3103   __PACKAGE__->set_primary_key('trackid');
3104   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3105   1;
3106
3107   # In your application
3108   my $rs = $schema->resultset('Artist')->search(
3109     { 'track.title' => 'Teardrop' },
3110     {
3111       join     => { cd => 'track' },
3112       order_by => 'artist.name',
3113     }
3114   );
3115
3116 You need to use the relationship (not the table) name in  conditions,
3117 because they are aliased as such. The current table is aliased as "me", so
3118 you need to use me.column_name in order to avoid ambiguity. For example:
3119
3120   # Get CDs from 1984 with a 'Foo' track
3121   my $rs = $schema->resultset('CD')->search(
3122     {
3123       'me.year' => 1984,
3124       'tracks.name' => 'Foo'
3125     },
3126     { join => 'tracks' }
3127   );
3128
3129 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3130 similarly for a third time). For e.g.
3131
3132   my $rs = $schema->resultset('Artist')->search({
3133     'cds.title'   => 'Down to Earth',
3134     'cds_2.title' => 'Popular',
3135   }, {
3136     join => [ qw/cds cds/ ],
3137   });
3138
3139 will return a set of all artists that have both a cd with title 'Down
3140 to Earth' and a cd with title 'Popular'.
3141
3142 If you want to fetch related objects from other tables as well, see C<prefetch>
3143 below.
3144
3145 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3146
3147 =head2 prefetch
3148
3149 =over 4
3150
3151 =item Value: ($rel_name | \@rel_names | \%rel_names)
3152
3153 =back
3154
3155 Contains one or more relationships that should be fetched along with
3156 the main query (when they are accessed afterwards the data will
3157 already be available, without extra queries to the database).  This is
3158 useful for when you know you will need the related objects, because it
3159 saves at least one query:
3160
3161   my $rs = $schema->resultset('Tag')->search(
3162     undef,
3163     {
3164       prefetch => {
3165         cd => 'artist'
3166       }
3167     }
3168   );
3169
3170 The initial search results in SQL like the following:
3171
3172   SELECT tag.*, cd.*, artist.* FROM tag
3173   JOIN cd ON tag.cd = cd.cdid
3174   JOIN artist ON cd.artist = artist.artistid
3175
3176 L<DBIx::Class> has no need to go back to the database when we access the
3177 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3178 case.
3179
3180 Simple prefetches will be joined automatically, so there is no need
3181 for a C<join> attribute in the above search.
3182
3183 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3184 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3185 with an accessor type of 'single' or 'filter'). A more complex example that
3186 prefetches an artists cds, the tracks on those cds, and the tags associted
3187 with that artist is given below (assuming many-to-many from artists to tags):
3188
3189  my $rs = $schema->resultset('Artist')->search(
3190    undef,
3191    {
3192      prefetch => [
3193        { cds => 'tracks' },
3194        { artist_tags => 'tags' }
3195      ]
3196    }
3197  );
3198
3199
3200 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3201 attributes will be ignored.
3202
3203 =head2 page
3204
3205 =over 4
3206
3207 =item Value: $page
3208
3209 =back
3210
3211 Makes the resultset paged and specifies the page to retrieve. Effectively
3212 identical to creating a non-pages resultset and then calling ->page($page)
3213 on it.
3214
3215 If L<rows> attribute is not specified it defaults to 10 rows per page.
3216
3217 When you have a paged resultset, L</count> will only return the number
3218 of rows in the page. To get the total, use the L</pager> and call
3219 C<total_entries> on it.
3220
3221 =head2 rows
3222
3223 =over 4
3224
3225 =item Value: $rows
3226
3227 =back
3228
3229 Specifes the maximum number of rows for direct retrieval or the number of
3230 rows per page if the page attribute or method is used.
3231
3232 =head2 offset
3233
3234 =over 4
3235
3236 =item Value: $offset
3237
3238 =back
3239
3240 Specifies the (zero-based) row number for the  first row to be returned, or the
3241 of the first row of the first page if paging is used.
3242
3243 =head2 group_by
3244
3245 =over 4
3246
3247 =item Value: \@columns
3248
3249 =back
3250
3251 A arrayref of columns to group by. Can include columns of joined tables.
3252
3253   group_by => [qw/ column1 column2 ... /]
3254
3255 =head2 having
3256
3257 =over 4
3258
3259 =item Value: $condition
3260
3261 =back
3262
3263 HAVING is a select statement attribute that is applied between GROUP BY and
3264 ORDER BY. It is applied to the after the grouping calculations have been
3265 done.
3266
3267   having => { 'count(employee)' => { '>=', 100 } }
3268
3269 =head2 distinct
3270
3271 =over 4
3272
3273 =item Value: (0 | 1)
3274
3275 =back
3276
3277 Set to 1 to group by all columns.
3278
3279 =head2 where
3280
3281 =over 4
3282
3283 Adds to the WHERE clause.
3284
3285   # only return rows WHERE deleted IS NULL for all searches
3286   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3287
3288 Can be overridden by passing C<{ where => undef }> as an attribute
3289 to a resulset.
3290
3291 =back
3292
3293 =head2 cache
3294
3295 Set to 1 to cache search results. This prevents extra SQL queries if you
3296 revisit rows in your ResultSet:
3297
3298   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3299
3300   while( my $artist = $resultset->next ) {
3301     ... do stuff ...
3302   }
3303
3304   $rs->first; # without cache, this would issue a query
3305
3306 By default, searches are not cached.
3307
3308 For more examples of using these attributes, see
3309 L<DBIx::Class::Manual::Cookbook>.
3310
3311 =head2 from
3312
3313 =over 4
3314
3315 =item Value: \@from_clause
3316
3317 =back
3318
3319 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3320 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3321 clauses.
3322
3323 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3324
3325 C<join> will usually do what you need and it is strongly recommended that you
3326 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3327 And we really do mean "cannot", not just tried and failed. Attempting to use
3328 this because you're having problems with C<join> is like trying to use x86
3329 ASM because you've got a syntax error in your C. Trust us on this.
3330
3331 Now, if you're still really, really sure you need to use this (and if you're
3332 not 100% sure, ask the mailing list first), here's an explanation of how this
3333 works.
3334
3335 The syntax is as follows -
3336
3337   [
3338     { <alias1> => <table1> },
3339     [
3340       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3341       [], # nested JOIN (optional)
3342       { <table1.column1> => <table2.column2>, ... (more conditions) },
3343     ],
3344     # More of the above [ ] may follow for additional joins
3345   ]
3346
3347   <table1> <alias1>
3348   JOIN
3349     <table2> <alias2>
3350     [JOIN ...]
3351   ON <table1.column1> = <table2.column2>
3352   <more joins may follow>
3353
3354 An easy way to follow the examples below is to remember the following:
3355
3356     Anything inside "[]" is a JOIN
3357     Anything inside "{}" is a condition for the enclosing JOIN
3358
3359 The following examples utilize a "person" table in a family tree application.
3360 In order to express parent->child relationships, this table is self-joined:
3361
3362     # Person->belongs_to('father' => 'Person');
3363     # Person->belongs_to('mother' => 'Person');
3364
3365 C<from> can be used to nest joins. Here we return all children with a father,
3366 then search against all mothers of those children:
3367
3368   $rs = $schema->resultset('Person')->search(
3369       undef,
3370       {
3371           alias => 'mother', # alias columns in accordance with "from"
3372           from => [
3373               { mother => 'person' },
3374               [
3375                   [
3376                       { child => 'person' },
3377                       [
3378                           { father => 'person' },
3379                           { 'father.person_id' => 'child.father_id' }
3380                       ]
3381                   ],
3382                   { 'mother.person_id' => 'child.mother_id' }
3383               ],
3384           ]
3385       },
3386   );
3387
3388   # Equivalent SQL:
3389   # SELECT mother.* FROM person mother
3390   # JOIN (
3391   #   person child
3392   #   JOIN person father
3393   #   ON ( father.person_id = child.father_id )
3394   # )
3395   # ON ( mother.person_id = child.mother_id )
3396
3397 The type of any join can be controlled manually. To search against only people
3398 with a father in the person table, we could explicitly use C<INNER JOIN>:
3399
3400     $rs = $schema->resultset('Person')->search(
3401         undef,
3402         {
3403             alias => 'child', # alias columns in accordance with "from"
3404             from => [
3405                 { child => 'person' },
3406                 [
3407                     { father => 'person', -join_type => 'inner' },
3408                     { 'father.id' => 'child.father_id' }
3409                 ],
3410             ]
3411         },
3412     );
3413
3414     # Equivalent SQL:
3415     # SELECT child.* FROM person child
3416     # INNER JOIN person father ON child.father_id = father.id
3417
3418 You can select from a subquery by passing a resultset to from as follows.
3419
3420     $schema->resultset('Artist')->search(
3421         undef,
3422         {   alias => 'artist2',
3423             from  => [ { artist2 => $artist_rs->as_query } ],
3424         } );
3425
3426     # and you'll get sql like this..
3427     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3428     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3429
3430 If you need to express really complex joins, you
3431 can supply literal SQL to C<from> via a scalar reference. In this case
3432 the contents of the scalar will replace the table name associated with the
3433 resultsource.
3434
3435 WARNING: This technique might very well not work as expected on chained
3436 searches - you have been warned.
3437
3438     # Assuming the Event resultsource is defined as:
3439
3440         MySchema::Event->add_columns (
3441             sequence => {
3442                 data_type => 'INT',
3443                 is_auto_increment => 1,
3444             },
3445             location => {
3446                 data_type => 'INT',
3447             },
3448             type => {
3449                 data_type => 'INT',
3450             },
3451         );
3452         MySchema::Event->set_primary_key ('sequence');
3453
3454     # This will get back the latest event for every location. The column
3455     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3456     # combo to limit the resultset
3457
3458     $rs = $schema->resultset('Event');
3459     $table = $rs->result_source->name;
3460     $latest = $rs->search (
3461         undef,
3462         { from => \ "
3463             (SELECT e1.* FROM $table e1
3464                 JOIN $table e2
3465                     ON e1.location = e2.location
3466                     AND e1.sequence < e2.sequence
3467                 WHERE e2.sequence is NULL
3468             ) me",
3469         },
3470     );
3471
3472     # Equivalent SQL (with the DBIC chunks added):
3473
3474     SELECT me.sequence, me.location, me.type FROM
3475        (SELECT e1.* FROM events e1
3476            JOIN events e2
3477                ON e1.location = e2.location
3478                AND e1.sequence < e2.sequence
3479            WHERE e2.sequence is NULL
3480        ) me;
3481
3482 =head2 for
3483
3484 =over 4
3485
3486 =item Value: ( 'update' | 'shared' )
3487
3488 =back
3489
3490 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3491 ... FOR SHARED.
3492
3493 =cut
3494
3495 1;