lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</first> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 =back
 706
 707 =cut
 708
 709 sub single {
 710   my ($self, $where) = @_;
 711   if(@_ > 2) {
 712       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 713   }
 714
 715   my $attrs = $self->_resolved_attrs_copy;
 716
 717   if ($where) {
 718     if (defined $attrs->{where}) {
 719       $attrs->{where} = {
 720         '-and' =>
 721             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 722                $where, delete $attrs->{where} ]
 723       };
 724     } else {
 725       $attrs->{where} = $where;
 726     }
 727   }
 728
 729 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 730 #  unless ($self->_is_unique_query($attrs->{where})) {
 731 #    carp "Query not guaranteed to return a single row"
 732 #      . "; please declare your unique constraints or use search instead";
 733 #  }
 734
 735   my @data = $self->result_source->storage->select_single(
 736     $attrs->{from}, $attrs->{select},
 737     $attrs->{where}, $attrs
 738   );
 739
 740   return (@data ? ($self->_construct_object(@data))[0] : undef);
 741 }
 742
 743
 744 # _is_unique_query
 745 #
 746 # Try to determine if the specified query is guaranteed to be unique, based on
 747 # the declared unique constraints.
 748
 749 sub _is_unique_query {
 750   my ($self, $query) = @_;
 751
 752   my $collapsed = $self->_collapse_query($query);
 753   my $alias = $self->{attrs}{alias};
 754
 755   foreach my $name ($self->result_source->unique_constraint_names) {
 756     my @unique_cols = map {
 757       "$alias.$_"
 758     } $self->result_source->unique_constraint_columns($name);
 759
 760     # Count the values for each unique column
 761     my %seen = map { $_ => 0 } @unique_cols;
 762
 763     foreach my $key (keys %$collapsed) {
 764       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 765       next unless exists $seen{$aliased};  # Additional constraints are okay
 766       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 767     }
 768
 769     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 770     return 1 unless grep { $_ != 1 } values %seen;
 771   }
 772
 773   return 0;
 774 }
 775
 776 # _collapse_query
 777 #
 778 # Recursively collapse the query, accumulating values for each column.
 779
 780 sub _collapse_query {
 781   my ($self, $query, $collapsed) = @_;
 782
 783   $collapsed ||= {};
 784
 785   if (ref $query eq 'ARRAY') {
 786     foreach my $subquery (@$query) {
 787       next unless ref $subquery;  # -or
 788       $collapsed = $self->_collapse_query($subquery, $collapsed);
 789     }
 790   }
 791   elsif (ref $query eq 'HASH') {
 792     if (keys %$query and (keys %$query)[0] eq '-and') {
 793       foreach my $subquery (@{$query->{-and}}) {
 794         $collapsed = $self->_collapse_query($subquery, $collapsed);
 795       }
 796     }
 797     else {
 798       foreach my $col (keys %$query) {
 799         my $value = $query->{$col};
 800         $collapsed->{$col}{$value}++;
 801       }
 802     }
 803   }
 804
 805   return $collapsed;
 806 }
 807
 808 =head2 get_column
 809
 810 =over 4
 811
 812 =item Arguments: $cond?
 813
 814 =item Return Value: $resultsetcolumn
 815
 816 =back
 817
 818   my $max_length = $rs->get_column('length')->max;
 819
 820 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 821
 822 =cut
 823
 824 sub get_column {
 825   my ($self, $column) = @_;
 826   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 827   return $new;
 828 }
 829
 830 =head2 search_like
 831
 832 =over 4
 833
 834 =item Arguments: $cond, \%attrs?
 835
 836 =item Return Value: $resultset (scalar context), @row_objs (list context)
 837
 838 =back
 839
 840   # WHERE title LIKE '%blue%'
 841   $cd_rs = $rs->search_like({ title => '%blue%'});
 842
 843 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 844 that this is simply a convenience method retained for ex Class::DBI users.
 845 You most likely want to use L</search> with specific operators.
 846
 847 For more information, see L<DBIx::Class::Manual::Cookbook>.
 848
 849 This method is deprecated and will be removed in 0.09. Use L</search()>
 850 instead. An example conversion is:
 851
 852   ->search_like({ foo => 'bar' });
 853
 854   # Becomes
 855
 856   ->search({ foo => { like => 'bar' } });
 857
 858 =cut
 859
 860 sub search_like {
 861   my $class = shift;
 862   carp (
 863     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 864    .' Instead use ->search({ x => { -like => "y%" } })'
 865    .' (note the outer pair of {}s - they are important!)'
 866   );
 867   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 868   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 869   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 870   return $class->search($query, { %$attrs });
 871 }
 872
 873 =head2 slice
 874
 875 =over 4
 876
 877 =item Arguments: $first, $last
 878
 879 =item Return Value: $resultset (scalar context), @row_objs (list context)
 880
 881 =back
 882
 883 Returns a resultset or object list representing a subset of elements from the
 884 resultset slice is called on. Indexes are from 0, i.e., to get the first
 885 three records, call:
 886
 887   my ($one, $two, $three) = $rs->slice(0, 2);
 888
 889 =cut
 890
 891 sub slice {
 892   my ($self, $min, $max) = @_;
 893   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 894   $attrs->{offset} = $self->{attrs}{offset} || 0;
 895   $attrs->{offset} += $min;
 896   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 897   return $self->search(undef(), $attrs);
 898   #my $slice = (ref $self)->new($self->result_source, $attrs);
 899   #return (wantarray ? $slice->all : $slice);
 900 }
 901
 902 =head2 next
 903
 904 =over 4
 905
 906 =item Arguments: none
 907
 908 =item Return Value: $result?
 909
 910 =back
 911
 912 Returns the next element in the resultset (C<undef> is there is none).
 913
 914 Can be used to efficiently iterate over records in the resultset:
 915
 916   my $rs = $schema->resultset('CD')->search;
 917   while (my $cd = $rs->next) {
 918     print $cd->title;
 919   }
 920
 921 Note that you need to store the resultset object, and call C<next> on it.
 922 Calling C<< resultset('Table')->next >> repeatedly will always return the
 923 first record from the resultset.
 924
 925 =cut
 926
 927 sub next {
 928   my ($self) = @_;
 929   if (my $cache = $self->get_cache) {
 930     $self->{all_cache_position} ||= 0;
 931     return $cache->[$self->{all_cache_position}++];
 932   }
 933   if ($self->{attrs}{cache}) {
 934     $self->{all_cache_position} = 1;
 935     return ($self->all)[0];
 936   }
 937   if ($self->{stashed_objects}) {
 938     my $obj = shift(@{$self->{stashed_objects}});
 939     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 940     return $obj;
 941   }
 942   my @row = (
 943     exists $self->{stashed_row}
 944       ? @{delete $self->{stashed_row}}
 945       : $self->cursor->next
 946   );
 947   return undef unless (@row);
 948   my ($row, @more) = $self->_construct_object(@row);
 949   $self->{stashed_objects} = \@more if @more;
 950   return $row;
 951 }
 952
 953 sub _construct_object {
 954   my ($self, @row) = @_;
 955   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 956   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 957   @new = $self->{_attrs}{record_filter}->(@new)
 958     if exists $self->{_attrs}{record_filter};
 959   return @new;
 960 }
 961
 962 sub _collapse_result {
 963   my ($self, $as_proto, $row) = @_;
 964
 965   my @copy = @$row;
 966
 967   # 'foo'         => [ undef, 'foo' ]
 968   # 'foo.bar'     => [ 'foo', 'bar' ]
 969   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 970
 971   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 972
 973   my %collapse = %{$self->{_attrs}{collapse}||{}};
 974
 975   my @pri_index;
 976
 977   # if we're doing collapsing (has_many prefetch) we need to grab records
 978   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 979   # we know we don't have to bother.
 980
 981   # the reason for not using the collapse stuff directly is because if you
 982   # had for e.g. two artists in a row with no cds, the collapse info for
 983   # both would be NULL (undef) so you'd lose the second artist
 984
 985   # store just the index so we can check the array positions from the row
 986   # without having to contruct the full hash
 987
 988   if (keys %collapse) {
 989     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 990     foreach my $i (0 .. $#construct_as) {
 991       next if defined($construct_as[$i][0]); # only self table
 992       if (delete $pri{$construct_as[$i][1]}) {
 993         push(@pri_index, $i);
 994       }
 995       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 996     }
 997   }
 998
 999   # no need to do an if, it'll be empty if @pri_index is empty anyway
1000
1001   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1002
1003   my @const_rows;
1004
1005   do { # no need to check anything at the front, we always want the first row
1006
1007     my %const;
1008
1009     foreach my $this_as (@construct_as) {
1010       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1011     }
1012
1013     push(@const_rows, \%const);
1014
1015   } until ( # no pri_index => no collapse => drop straight out
1016       !@pri_index
1017     or
1018       do { # get another row, stash it, drop out if different PK
1019
1020         @copy = $self->cursor->next;
1021         $self->{stashed_row} = \@copy;
1022
1023         # last thing in do block, counts as true if anything doesn't match
1024
1025         # check xor defined first for NULL vs. NOT NULL then if one is
1026         # defined the other must be so check string equality
1027
1028         grep {
1029           (defined $pri_vals{$_} ^ defined $copy[$_])
1030           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1031         } @pri_index;
1032       }
1033   );
1034
1035   my $alias = $self->{attrs}{alias};
1036   my $info = [];
1037
1038   my %collapse_pos;
1039
1040   my @const_keys;
1041
1042   foreach my $const (@const_rows) {
1043     scalar @const_keys or do {
1044       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1045     };
1046     foreach my $key (@const_keys) {
1047       if (length $key) {
1048         my $target = $info;
1049         my @parts = split(/\./, $key);
1050         my $cur = '';
1051         my $data = $const->{$key};
1052         foreach my $p (@parts) {
1053           $target = $target->[1]->{$p} ||= [];
1054           $cur .= ".${p}";
1055           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1056             # collapsing at this point and on final part
1057             my $pos = $collapse_pos{$cur};
1058             CK: foreach my $ck (@ckey) {
1059               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1060                 $collapse_pos{$cur} = $data;
1061                 delete @collapse_pos{ # clear all positioning for sub-entries
1062                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1063                 };
1064                 push(@$target, []);
1065                 last CK;
1066               }
1067             }
1068           }
1069           if (exists $collapse{$cur}) {
1070             $target = $target->[-1];
1071           }
1072         }
1073         $target->[0] = $data;
1074       } else {
1075         $info->[0] = $const->{$key};
1076       }
1077     }
1078   }
1079
1080   return $info;
1081 }
1082
1083 =head2 result_source
1084
1085 =over 4
1086
1087 =item Arguments: $result_source?
1088
1089 =item Return Value: $result_source
1090
1091 =back
1092
1093 An accessor for the primary ResultSource object from which this ResultSet
1094 is derived.
1095
1096 =head2 result_class
1097
1098 =over 4
1099
1100 =item Arguments: $result_class?
1101
1102 =item Return Value: $result_class
1103
1104 =back
1105
1106 An accessor for the class to use when creating row objects. Defaults to
1107 C<< result_source->result_class >> - which in most cases is the name of the
1108 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1109
1110 Note that changing the result_class will also remove any components
1111 that were originally loaded in the source class via
1112 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1113 in the original source class will not run.
1114
1115 =cut
1116
1117 sub result_class {
1118   my ($self, $result_class) = @_;
1119   if ($result_class) {
1120     $self->ensure_class_loaded($result_class);
1121     $self->_result_class($result_class);
1122   }
1123   $self->_result_class;
1124 }
1125
1126 =head2 count
1127
1128 =over 4
1129
1130 =item Arguments: $cond, \%attrs??
1131
1132 =item Return Value: $count
1133
1134 =back
1135
1136 Performs an SQL C<COUNT> with the same query as the resultset was built
1137 with to find the number of elements. Passing arguments is equivalent to
1138 C<< $rs->search ($cond, \%attrs)->count >>
1139
1140 =cut
1141
1142 sub count {
1143   my $self = shift;
1144   return $self->search(@_)->count if @_ and defined $_[0];
1145   return scalar @{ $self->get_cache } if $self->get_cache;
1146
1147   my $meth = $self->_has_attr (qw/prefetch collapse distinct group_by/)
1148     ? 'count_grouped'
1149     : 'count'
1150   ;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153   my $rsrc = $self->result_source;
1154
1155   return $rsrc->storage->$meth ($rsrc, $attrs);
1156 }
1157
1158 sub _bool {
1159   return 1;
1160 }
1161
1162 =head2 count_literal
1163
1164 =over 4
1165
1166 =item Arguments: $sql_fragment, @bind_values
1167
1168 =item Return Value: $count
1169
1170 =back
1171
1172 Counts the results in a literal query. Equivalent to calling L</search_literal>
1173 with the passed arguments, then L</count>.
1174
1175 =cut
1176
1177 sub count_literal { shift->search_literal(@_)->count; }
1178
1179 =head2 all
1180
1181 =over 4
1182
1183 =item Arguments: none
1184
1185 =item Return Value: @objects
1186
1187 =back
1188
1189 Returns all elements in the resultset. Called implicitly if the resultset
1190 is returned in list context.
1191
1192 =cut
1193
1194 sub all {
1195   my $self = shift;
1196   if(@_) {
1197       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1198   }
1199
1200   return @{ $self->get_cache } if $self->get_cache;
1201
1202   my @obj;
1203
1204   # TODO: don't call resolve here
1205   if (keys %{$self->_resolved_attrs->{collapse}}) {
1206 #  if ($self->{attrs}{prefetch}) {
1207       # Using $self->cursor->all is really just an optimisation.
1208       # If we're collapsing has_many prefetches it probably makes
1209       # very little difference, and this is cleaner than hacking
1210       # _construct_object to survive the approach
1211     my @row = $self->cursor->next;
1212     while (@row) {
1213       push(@obj, $self->_construct_object(@row));
1214       @row = (exists $self->{stashed_row}
1215                ? @{delete $self->{stashed_row}}
1216                : $self->cursor->next);
1217     }
1218   } else {
1219     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1220   }
1221
1222   $self->set_cache(\@obj) if $self->{attrs}{cache};
1223   return @obj;
1224 }
1225
1226 =head2 reset
1227
1228 =over 4
1229
1230 =item Arguments: none
1231
1232 =item Return Value: $self
1233
1234 =back
1235
1236 Resets the resultset's cursor, so you can iterate through the elements again.
1237
1238 =cut
1239
1240 sub reset {
1241   my ($self) = @_;
1242   delete $self->{_attrs} if exists $self->{_attrs};
1243   $self->{all_cache_position} = 0;
1244   $self->cursor->reset;
1245   return $self;
1246 }
1247
1248 =head2 first
1249
1250 =over 4
1251
1252 =item Arguments: none
1253
1254 =item Return Value: $object?
1255
1256 =back
1257
1258 Resets the resultset and returns an object for the first result (if the
1259 resultset returns anything).
1260
1261 =cut
1262
1263 sub first {
1264   return $_[0]->reset->next;
1265 }
1266
1267
1268 # _rs_update_delete
1269 #
1270 # Determines whether and what type of subquery is required for the $rs operation.
1271 # If grouping is necessary either supplies its own, or verifies the current one
1272 # After all is done delegates to the proper storage method.
1273
1274 sub _rs_update_delete {
1275   my ($self, $op, $values) = @_;
1276
1277   my $rsrc = $self->result_source;
1278
1279   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1280   my $needs_subq = $self->_has_attr (qw/row offset page/);
1281
1282   if ($needs_group_by_subq or $needs_subq) {
1283
1284     # make a new $rs selecting only the PKs (that's all we really need)
1285     my $attrs = $self->_resolved_attrs_copy;
1286
1287     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1288     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1289
1290     if ($needs_group_by_subq) {
1291       # make sure no group_by was supplied, or if there is one - make sure it matches
1292       # the columns compiled above perfectly. Anything else can not be sanely executed
1293       # on most databases so croak right then and there
1294
1295       if (my $g = $attrs->{group_by}) {
1296         my @current_group_by = map
1297           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1298           (ref $g eq 'ARRAY' ? @$g : $g );
1299
1300         if (
1301           join ("\x00", sort @current_group_by)
1302             ne
1303           join ("\x00", sort @{$attrs->{columns}} )
1304         ) {
1305           $self->throw_exception (
1306             "You have just attempted a $op operation on a resultset which does group_by"
1307             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1308             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1309             . ' kind of queries. Please retry the operation with a modified group_by or'
1310             . ' without using one at all.'
1311           );
1312         }
1313       }
1314       else {
1315         $attrs->{group_by} = $attrs->{columns};
1316       }
1317     }
1318
1319     my $subrs = (ref $self)->new($rsrc, $attrs);
1320
1321     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1322   }
1323   else {
1324     return $rsrc->storage->$op(
1325       $rsrc,
1326       $op eq 'update' ? $values : (),
1327       $self->_cond_for_update_delete,
1328     );
1329   }
1330 }
1331
1332
1333 # _cond_for_update_delete
1334 #
1335 # update/delete require the condition to be modified to handle
1336 # the differing SQL syntax available.  This transforms the $self->{cond}
1337 # appropriately, returning the new condition.
1338
1339 sub _cond_for_update_delete {
1340   my ($self, $full_cond) = @_;
1341   my $cond = {};
1342
1343   $full_cond ||= $self->{cond};
1344   # No-op. No condition, we're updating/deleting everything
1345   return $cond unless ref $full_cond;
1346
1347   if (ref $full_cond eq 'ARRAY') {
1348     $cond = [
1349       map {
1350         my %hash;
1351         foreach my $key (keys %{$_}) {
1352           $key =~ /([^.]+)$/;
1353           $hash{$1} = $_->{$key};
1354         }
1355         \%hash;
1356       } @{$full_cond}
1357     ];
1358   }
1359   elsif (ref $full_cond eq 'HASH') {
1360     if ((keys %{$full_cond})[0] eq '-and') {
1361       $cond->{-and} = [];
1362       my @cond = @{$full_cond->{-and}};
1363        for (my $i = 0; $i < @cond; $i++) {
1364         my $entry = $cond[$i];
1365         my $hash;
1366         if (ref $entry eq 'HASH') {
1367           $hash = $self->_cond_for_update_delete($entry);
1368         }
1369         else {
1370           $entry =~ /([^.]+)$/;
1371           $hash->{$1} = $cond[++$i];
1372         }
1373         push @{$cond->{-and}}, $hash;
1374       }
1375     }
1376     else {
1377       foreach my $key (keys %{$full_cond}) {
1378         $key =~ /([^.]+)$/;
1379         $cond->{$1} = $full_cond->{$key};
1380       }
1381     }
1382   }
1383   else {
1384     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1385   }
1386
1387   return $cond;
1388 }
1389
1390
1391 =head2 update
1392
1393 =over 4
1394
1395 =item Arguments: \%values
1396
1397 =item Return Value: $storage_rv
1398
1399 =back
1400
1401 Sets the specified columns in the resultset to the supplied values in a
1402 single query. Return value will be true if the update succeeded or false
1403 if no records were updated; exact type of success value is storage-dependent.
1404
1405 =cut
1406
1407 sub update {
1408   my ($self, $values) = @_;
1409   $self->throw_exception('Values for update must be a hash')
1410     unless ref $values eq 'HASH';
1411
1412   return $self->_rs_update_delete ('update', $values);
1413 }
1414
1415 =head2 update_all
1416
1417 =over 4
1418
1419 =item Arguments: \%values
1420
1421 =item Return Value: 1
1422
1423 =back
1424
1425 Fetches all objects and updates them one at a time. Note that C<update_all>
1426 will run DBIC cascade triggers, while L</update> will not.
1427
1428 =cut
1429
1430 sub update_all {
1431   my ($self, $values) = @_;
1432   $self->throw_exception('Values for update_all must be a hash')
1433     unless ref $values eq 'HASH';
1434   foreach my $obj ($self->all) {
1435     $obj->set_columns($values)->update;
1436   }
1437   return 1;
1438 }
1439
1440 =head2 delete
1441
1442 =over 4
1443
1444 =item Arguments: none
1445
1446 =item Return Value: $storage_rv
1447
1448 =back
1449
1450 Deletes the contents of the resultset from its result source. Note that this
1451 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1452 to run. See also L<DBIx::Class::Row/delete>.
1453
1454 Return value will be the amount of rows deleted; exact type of return value
1455 is storage-dependent.
1456
1457 =cut
1458
1459 sub delete {
1460   my $self = shift;
1461   $self->throw_exception('delete does not accept any arguments')
1462     if @_;
1463
1464   return $self->_rs_update_delete ('delete');
1465 }
1466
1467 =head2 delete_all
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: 1
1474
1475 =back
1476
1477 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1478 will run DBIC cascade triggers, while L</delete> will not.
1479
1480 =cut
1481
1482 sub delete_all {
1483   my $self = shift;
1484   $self->throw_exception('delete_all does not accept any arguments')
1485     if @_;
1486
1487   $_->delete for $self->all;
1488   return 1;
1489 }
1490
1491 =head2 populate
1492
1493 =over 4
1494
1495 =item Arguments: \@data;
1496
1497 =back
1498
1499 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1500 For the arrayref of hashrefs style each hashref should be a structure suitable
1501 forsubmitting to a $resultset->create(...) method.
1502
1503 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1504 to insert the data, as this is a faster method.
1505
1506 Otherwise, each set of data is inserted into the database using
1507 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1508 objects is returned.
1509
1510 Example:  Assuming an Artist Class that has many CDs Classes relating:
1511
1512   my $Artist_rs = $schema->resultset("Artist");
1513
1514   ## Void Context Example
1515   $Artist_rs->populate([
1516      { artistid => 4, name => 'Manufactured Crap', cds => [
1517         { title => 'My First CD', year => 2006 },
1518         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1519       ],
1520      },
1521      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1522         { title => 'My parents sold me to a record company' ,year => 2005 },
1523         { title => 'Why Am I So Ugly?', year => 2006 },
1524         { title => 'I Got Surgery and am now Popular', year => 2007 }
1525       ],
1526      },
1527   ]);
1528
1529   ## Array Context Example
1530   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1531     { name => "Artist One"},
1532     { name => "Artist Two"},
1533     { name => "Artist Three", cds=> [
1534     { title => "First CD", year => 2007},
1535     { title => "Second CD", year => 2008},
1536   ]}
1537   ]);
1538
1539   print $ArtistOne->name; ## response is 'Artist One'
1540   print $ArtistThree->cds->count ## reponse is '2'
1541
1542 For the arrayref of arrayrefs style,  the first element should be a list of the
1543 fieldsnames to which the remaining elements are rows being inserted.  For
1544 example:
1545
1546   $Arstist_rs->populate([
1547     [qw/artistid name/],
1548     [100, 'A Formally Unknown Singer'],
1549     [101, 'A singer that jumped the shark two albums ago'],
1550     [102, 'An actually cool singer.'],
1551   ]);
1552
1553 Please note an important effect on your data when choosing between void and
1554 wantarray context. Since void context goes straight to C<insert_bulk> in
1555 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1556 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1557 create primary keys for you, you will find that your PKs are empty.  In this
1558 case you will have to use the wantarray context in order to create those
1559 values.
1560
1561 =cut
1562
1563 sub populate {
1564   my $self = shift @_;
1565   my $data = ref $_[0][0] eq 'HASH'
1566     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1567     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1568
1569   if(defined wantarray) {
1570     my @created;
1571     foreach my $item (@$data) {
1572       push(@created, $self->create($item));
1573     }
1574     return @created;
1575   } else {
1576     my ($first, @rest) = @$data;
1577
1578     my @names = grep {!ref $first->{$_}} keys %$first;
1579     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1580     my @pks = $self->result_source->primary_columns;
1581
1582     ## do the belongs_to relationships
1583     foreach my $index (0..$#$data) {
1584
1585       # delegate to create() for any dataset without primary keys with specified relationships
1586       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1587         for my $r (@rels) {
1588           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1589             my @ret = $self->populate($data);
1590             return;
1591           }
1592         }
1593       }
1594
1595       foreach my $rel (@rels) {
1596         next unless ref $data->[$index]->{$rel} eq "HASH";
1597         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1598         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1599         my $related = $result->result_source->_resolve_condition(
1600           $result->result_source->relationship_info($reverse)->{cond},
1601           $self,
1602           $result,
1603         );
1604
1605         delete $data->[$index]->{$rel};
1606         $data->[$index] = {%{$data->[$index]}, %$related};
1607
1608         push @names, keys %$related if $index == 0;
1609       }
1610     }
1611
1612     ## do bulk insert on current row
1613     my @values = map { [ @$_{@names} ] } @$data;
1614
1615     $self->result_source->storage->insert_bulk(
1616       $self->result_source,
1617       \@names,
1618       \@values,
1619     );
1620
1621     ## do the has_many relationships
1622     foreach my $item (@$data) {
1623
1624       foreach my $rel (@rels) {
1625         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1626
1627         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1628      || $self->throw_exception('Cannot find the relating object.');
1629
1630         my $child = $parent->$rel;
1631
1632         my $related = $child->result_source->_resolve_condition(
1633           $parent->result_source->relationship_info($rel)->{cond},
1634           $child,
1635           $parent,
1636         );
1637
1638         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1639         my @populate = map { {%$_, %$related} } @rows_to_add;
1640
1641         $child->populate( \@populate );
1642       }
1643     }
1644   }
1645 }
1646
1647 =head2 _normalize_populate_args ($args)
1648
1649 Private method used by L</populate> to normalize its incoming arguments.  Factored
1650 out in case you want to subclass and accept new argument structures to the
1651 L</populate> method.
1652
1653 =cut
1654
1655 sub _normalize_populate_args {
1656   my ($self, $data) = @_;
1657   my @names = @{shift(@$data)};
1658   my @results_to_create;
1659   foreach my $datum (@$data) {
1660     my %result_to_create;
1661     foreach my $index (0..$#names) {
1662       $result_to_create{$names[$index]} = $$datum[$index];
1663     }
1664     push @results_to_create, \%result_to_create;
1665   }
1666   return \@results_to_create;
1667 }
1668
1669 =head2 pager
1670
1671 =over 4
1672
1673 =item Arguments: none
1674
1675 =item Return Value: $pager
1676
1677 =back
1678
1679 Return Value a L<Data::Page> object for the current resultset. Only makes
1680 sense for queries with a C<page> attribute.
1681
1682 To get the full count of entries for a paged resultset, call
1683 C<total_entries> on the L<Data::Page> object.
1684
1685 =cut
1686
1687 sub pager {
1688   my ($self) = @_;
1689
1690   return $self->{pager} if $self->{pager};
1691
1692   my $attrs = $self->{attrs};
1693   $self->throw_exception("Can't create pager for non-paged rs")
1694     unless $self->{attrs}{page};
1695   $attrs->{rows} ||= 10;
1696
1697   # throw away the paging flags and re-run the count (possibly
1698   # with a subselect) to get the real total count
1699   my $count_attrs = { %$attrs };
1700   delete $count_attrs->{$_} for qw/rows offset page pager/;
1701   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1702
1703   return $self->{pager} = Data::Page->new(
1704     $total_count,
1705     $attrs->{rows},
1706     $self->{attrs}{page}
1707   );
1708 }
1709
1710 =head2 page
1711
1712 =over 4
1713
1714 =item Arguments: $page_number
1715
1716 =item Return Value: $rs
1717
1718 =back
1719
1720 Returns a resultset for the $page_number page of the resultset on which page
1721 is called, where each page contains a number of rows equal to the 'rows'
1722 attribute set on the resultset (10 by default).
1723
1724 =cut
1725
1726 sub page {
1727   my ($self, $page) = @_;
1728   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1729 }
1730
1731 =head2 new_result
1732
1733 =over 4
1734
1735 =item Arguments: \%vals
1736
1737 =item Return Value: $rowobject
1738
1739 =back
1740
1741 Creates a new row object in the resultset's result class and returns
1742 it. The row is not inserted into the database at this point, call
1743 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1744 will tell you whether the row object has been inserted or not.
1745
1746 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1747
1748 =cut
1749
1750 sub new_result {
1751   my ($self, $values) = @_;
1752   $self->throw_exception( "new_result needs a hash" )
1753     unless (ref $values eq 'HASH');
1754
1755   my %new;
1756   my $alias = $self->{attrs}{alias};
1757
1758   if (
1759     defined $self->{cond}
1760     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1761   ) {
1762     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1763     $new{-from_resultset} = [ keys %new ] if keys %new;
1764   } else {
1765     $self->throw_exception(
1766       "Can't abstract implicit construct, condition not a hash"
1767     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1768
1769     my $collapsed_cond = (
1770       $self->{cond}
1771         ? $self->_collapse_cond($self->{cond})
1772         : {}
1773     );
1774
1775     # precendence must be given to passed values over values inherited from
1776     # the cond, so the order here is important.
1777     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1778     while( my($col,$value) = each %implied ){
1779       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1780         $new{$col} = $value->{'='};
1781         next;
1782       }
1783       $new{$col} = $value if $self->_is_deterministic_value($value);
1784     }
1785   }
1786
1787   %new = (
1788     %new,
1789     %{ $self->_remove_alias($values, $alias) },
1790     -source_handle => $self->_source_handle,
1791     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1792   );
1793
1794   return $self->result_class->new(\%new);
1795 }
1796
1797 # _is_deterministic_value
1798 #
1799 # Make an effor to strip non-deterministic values from the condition,
1800 # to make sure new_result chokes less
1801
1802 sub _is_deterministic_value {
1803   my $self = shift;
1804   my $value = shift;
1805   my $ref_type = ref $value;
1806   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1807   return 1 if Scalar::Util::blessed($value);
1808   return 0;
1809 }
1810
1811 # _has_attr
1812 #
1813 # determines if the resultset defines at least one
1814 # of the attributes supplied
1815 #
1816 # used to determine if a subquery is neccessary
1817
1818 sub _has_attr {
1819   my ($self, @attr_names) = @_;
1820
1821   my $attrs = $self->_resolved_attrs;
1822
1823   my $join_check_req;
1824
1825   for my $n (@attr_names) {
1826     ++$join_check_req if $n =~ /join/;
1827
1828     my $attr =  $attrs->{$n};
1829
1830     next if not defined $attr;
1831
1832     if (ref $attr eq 'HASH') {
1833       return 1 if keys %$attr;
1834     }
1835     elsif (ref $attr eq 'ARRAY') {
1836       return 1 if @$attr;
1837     }
1838     else {
1839       return 1 if $attr;
1840     }
1841   }
1842
1843   # a join can be expressed as a multi-level from
1844   return 1 if (
1845     $join_check_req
1846       and
1847     ref $attrs->{from} eq 'ARRAY'
1848       and
1849     @{$attrs->{from}} > 1
1850   );
1851
1852   return 0;
1853 }
1854
1855 # _collapse_cond
1856 #
1857 # Recursively collapse the condition.
1858
1859 sub _collapse_cond {
1860   my ($self, $cond, $collapsed) = @_;
1861
1862   $collapsed ||= {};
1863
1864   if (ref $cond eq 'ARRAY') {
1865     foreach my $subcond (@$cond) {
1866       next unless ref $subcond;  # -or
1867       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1868     }
1869   }
1870   elsif (ref $cond eq 'HASH') {
1871     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1872       foreach my $subcond (@{$cond->{-and}}) {
1873         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1874       }
1875     }
1876     else {
1877       foreach my $col (keys %$cond) {
1878         my $value = $cond->{$col};
1879         $collapsed->{$col} = $value;
1880       }
1881     }
1882   }
1883
1884   return $collapsed;
1885 }
1886
1887 # _remove_alias
1888 #
1889 # Remove the specified alias from the specified query hash. A copy is made so
1890 # the original query is not modified.
1891
1892 sub _remove_alias {
1893   my ($self, $query, $alias) = @_;
1894
1895   my %orig = %{ $query || {} };
1896   my %unaliased;
1897
1898   foreach my $key (keys %orig) {
1899     if ($key !~ /\./) {
1900       $unaliased{$key} = $orig{$key};
1901       next;
1902     }
1903     $unaliased{$1} = $orig{$key}
1904       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1905   }
1906
1907   return \%unaliased;
1908 }
1909
1910 =head2 as_query (EXPERIMENTAL)
1911
1912 =over 4
1913
1914 =item Arguments: none
1915
1916 =item Return Value: \[ $sql, @bind ]
1917
1918 =back
1919
1920 Returns the SQL query and bind vars associated with the invocant.
1921
1922 This is generally used as the RHS for a subquery.
1923
1924 B<NOTE>: This feature is still experimental.
1925
1926 =cut
1927
1928 sub as_query {
1929   my $self = shift;
1930
1931   my $attrs = $self->_resolved_attrs_copy;
1932
1933   # For future use:
1934   #
1935   # in list ctx:
1936   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
1937   # $sql also has no wrapping parenthesis in list ctx
1938   #
1939   my $sqlbind = $self->result_source->storage
1940     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
1941
1942   return $sqlbind;
1943 }
1944
1945 =head2 find_or_new
1946
1947 =over 4
1948
1949 =item Arguments: \%vals, \%attrs?
1950
1951 =item Return Value: $rowobject
1952
1953 =back
1954
1955   my $artist = $schema->resultset('Artist')->find_or_new(
1956     { artist => 'fred' }, { key => 'artists' });
1957
1958   $cd->cd_to_producer->find_or_new({ producer => $producer },
1959                                    { key => 'primary });
1960
1961 Find an existing record from this resultset, based on its primary
1962 key, or a unique constraint. If none exists, instantiate a new result
1963 object and return it. The object will not be saved into your storage
1964 until you call L<DBIx::Class::Row/insert> on it.
1965
1966 You most likely want this method when looking for existing rows using
1967 a unique constraint that is not the primary key, or looking for
1968 related rows.
1969
1970 If you want objects to be saved immediately, use L</find_or_create> instead.
1971
1972 B<Note>: C<find_or_new> is probably not what you want when creating a
1973 new row in a table that uses primary keys supplied by the
1974 database. Passing in a primary key column with a value of I<undef>
1975 will cause L</find> to attempt to search for a row with a value of
1976 I<NULL>.
1977
1978 =cut
1979
1980 sub find_or_new {
1981   my $self     = shift;
1982   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1983   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1984   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
1985     return $row;
1986   }
1987   return $self->new_result($hash);
1988 }
1989
1990 =head2 create
1991
1992 =over 4
1993
1994 =item Arguments: \%vals
1995
1996 =item Return Value: a L<DBIx::Class::Row> $object
1997
1998 =back
1999
2000 Attempt to create a single new row or a row with multiple related rows
2001 in the table represented by the resultset (and related tables). This
2002 will not check for duplicate rows before inserting, use
2003 L</find_or_create> to do that.
2004
2005 To create one row for this resultset, pass a hashref of key/value
2006 pairs representing the columns of the table and the values you wish to
2007 store. If the appropriate relationships are set up, foreign key fields
2008 can also be passed an object representing the foreign row, and the
2009 value will be set to its primary key.
2010
2011 To create related objects, pass a hashref for the value if the related
2012 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2013 and use the name of the relationship as the key. (NOT the name of the field,
2014 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2015 of hashrefs containing the data for each of the rows to create in the foreign
2016 tables, again using the relationship name as the key.
2017
2018 Instead of hashrefs of plain related data (key/value pairs), you may
2019 also pass new or inserted objects. New objects (not inserted yet, see
2020 L</new>), will be inserted into their appropriate tables.
2021
2022 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2023
2024 Example of creating a new row.
2025
2026   $person_rs->create({
2027     name=>"Some Person",
2028     email=>"somebody@someplace.com"
2029   });
2030
2031 Example of creating a new row and also creating rows in a related C<has_many>
2032 or C<has_one> resultset.  Note Arrayref.
2033
2034   $artist_rs->create(
2035      { artistid => 4, name => 'Manufactured Crap', cds => [
2036         { title => 'My First CD', year => 2006 },
2037         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2038       ],
2039      },
2040   );
2041
2042 Example of creating a new row and also creating a row in a related
2043 C<belongs_to>resultset. Note Hashref.
2044
2045   $cd_rs->create({
2046     title=>"Music for Silly Walks",
2047     year=>2000,
2048     artist => {
2049       name=>"Silly Musician",
2050     }
2051   });
2052
2053 =cut
2054
2055 sub create {
2056   my ($self, $attrs) = @_;
2057   $self->throw_exception( "create needs a hashref" )
2058     unless ref $attrs eq 'HASH';
2059   return $self->new_result($attrs)->insert;
2060 }
2061
2062 =head2 find_or_create
2063
2064 =over 4
2065
2066 =item Arguments: \%vals, \%attrs?
2067
2068 =item Return Value: $rowobject
2069
2070 =back
2071
2072   $cd->cd_to_producer->find_or_create({ producer => $producer },
2073                                       { key => 'primary });
2074
2075 Tries to find a record based on its primary key or unique constraints; if none
2076 is found, creates one and returns that instead.
2077
2078   my $cd = $schema->resultset('CD')->find_or_create({
2079     cdid   => 5,
2080     artist => 'Massive Attack',
2081     title  => 'Mezzanine',
2082     year   => 2005,
2083   });
2084
2085 Also takes an optional C<key> attribute, to search by a specific key or unique
2086 constraint. For example:
2087
2088   my $cd = $schema->resultset('CD')->find_or_create(
2089     {
2090       artist => 'Massive Attack',
2091       title  => 'Mezzanine',
2092     },
2093     { key => 'cd_artist_title' }
2094   );
2095
2096 B<Note>: Because find_or_create() reads from the database and then
2097 possibly inserts based on the result, this method is subject to a race
2098 condition. Another process could create a record in the table after
2099 the find has completed and before the create has started. To avoid
2100 this problem, use find_or_create() inside a transaction.
2101
2102 B<Note>: C<find_or_create> is probably not what you want when creating
2103 a new row in a table that uses primary keys supplied by the
2104 database. Passing in a primary key column with a value of I<undef>
2105 will cause L</find> to attempt to search for a row with a value of
2106 I<NULL>.
2107
2108 See also L</find> and L</update_or_create>. For information on how to declare
2109 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2110
2111 =cut
2112
2113 sub find_or_create {
2114   my $self     = shift;
2115   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2116   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2117   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2118     return $row;
2119   }
2120   return $self->create($hash);
2121 }
2122
2123 =head2 update_or_create
2124
2125 =over 4
2126
2127 =item Arguments: \%col_values, { key => $unique_constraint }?
2128
2129 =item Return Value: $rowobject
2130
2131 =back
2132
2133   $resultset->update_or_create({ col => $val, ... });
2134
2135 First, searches for an existing row matching one of the unique constraints
2136 (including the primary key) on the source of this resultset. If a row is
2137 found, updates it with the other given column values. Otherwise, creates a new
2138 row.
2139
2140 Takes an optional C<key> attribute to search on a specific unique constraint.
2141 For example:
2142
2143   # In your application
2144   my $cd = $schema->resultset('CD')->update_or_create(
2145     {
2146       artist => 'Massive Attack',
2147       title  => 'Mezzanine',
2148       year   => 1998,
2149     },
2150     { key => 'cd_artist_title' }
2151   );
2152
2153   $cd->cd_to_producer->update_or_create({
2154     producer => $producer,
2155     name => 'harry',
2156   }, {
2157     key => 'primary,
2158   });
2159
2160
2161 If no C<key> is specified, it searches on all unique constraints defined on the
2162 source, including the primary key.
2163
2164 If the C<key> is specified as C<primary>, it searches only on the primary key.
2165
2166 See also L</find> and L</find_or_create>. For information on how to declare
2167 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2168
2169 B<Note>: C<update_or_create> is probably not what you want when
2170 looking for a row in a table that uses primary keys supplied by the
2171 database, unless you actually have a key value. Passing in a primary
2172 key column with a value of I<undef> will cause L</find> to attempt to
2173 search for a row with a value of I<NULL>.
2174
2175 =cut
2176
2177 sub update_or_create {
2178   my $self = shift;
2179   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2180   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2181
2182   my $row = $self->find($cond, $attrs);
2183   if (defined $row) {
2184     $row->update($cond);
2185     return $row;
2186   }
2187
2188   return $self->create($cond);
2189 }
2190
2191 =head2 update_or_new
2192
2193 =over 4
2194
2195 =item Arguments: \%col_values, { key => $unique_constraint }?
2196
2197 =item Return Value: $rowobject
2198
2199 =back
2200
2201   $resultset->update_or_new({ col => $val, ... });
2202
2203 First, searches for an existing row matching one of the unique constraints
2204 (including the primary key) on the source of this resultset. If a row is
2205 found, updates it with the other given column values. Otherwise, instantiate
2206 a new result object and return it. The object will not be saved into your storage
2207 until you call L<DBIx::Class::Row/insert> on it.
2208
2209 Takes an optional C<key> attribute to search on a specific unique constraint.
2210 For example:
2211
2212   # In your application
2213   my $cd = $schema->resultset('CD')->update_or_new(
2214     {
2215       artist => 'Massive Attack',
2216       title  => 'Mezzanine',
2217       year   => 1998,
2218     },
2219     { key => 'cd_artist_title' }
2220   );
2221
2222   if ($cd->in_storage) {
2223       # the cd was updated
2224   }
2225   else {
2226       # the cd is not yet in the database, let's insert it
2227       $cd->insert;
2228   }
2229
2230 See also L</find>, L</find_or_create> and L<find_or_new>.
2231
2232 =cut
2233
2234 sub update_or_new {
2235     my $self  = shift;
2236     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2237     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2238
2239     my $row = $self->find( $cond, $attrs );
2240     if ( defined $row ) {
2241         $row->update($cond);
2242         return $row;
2243     }
2244
2245     return $self->new_result($cond);
2246 }
2247
2248 =head2 get_cache
2249
2250 =over 4
2251
2252 =item Arguments: none
2253
2254 =item Return Value: \@cache_objects?
2255
2256 =back
2257
2258 Gets the contents of the cache for the resultset, if the cache is set.
2259
2260 The cache is populated either by using the L</prefetch> attribute to
2261 L</search> or by calling L</set_cache>.
2262
2263 =cut
2264
2265 sub get_cache {
2266   shift->{all_cache};
2267 }
2268
2269 =head2 set_cache
2270
2271 =over 4
2272
2273 =item Arguments: \@cache_objects
2274
2275 =item Return Value: \@cache_objects
2276
2277 =back
2278
2279 Sets the contents of the cache for the resultset. Expects an arrayref
2280 of objects of the same class as those produced by the resultset. Note that
2281 if the cache is set the resultset will return the cached objects rather
2282 than re-querying the database even if the cache attr is not set.
2283
2284 The contents of the cache can also be populated by using the
2285 L</prefetch> attribute to L</search>.
2286
2287 =cut
2288
2289 sub set_cache {
2290   my ( $self, $data ) = @_;
2291   $self->throw_exception("set_cache requires an arrayref")
2292       if defined($data) && (ref $data ne 'ARRAY');
2293   $self->{all_cache} = $data;
2294 }
2295
2296 =head2 clear_cache
2297
2298 =over 4
2299
2300 =item Arguments: none
2301
2302 =item Return Value: []
2303
2304 =back
2305
2306 Clears the cache for the resultset.
2307
2308 =cut
2309
2310 sub clear_cache {
2311   shift->set_cache(undef);
2312 }
2313
2314 =head2 related_resultset
2315
2316 =over 4
2317
2318 =item Arguments: $relationship_name
2319
2320 =item Return Value: $resultset
2321
2322 =back
2323
2324 Returns a related resultset for the supplied relationship name.
2325
2326   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2327
2328 =cut
2329
2330 sub related_resultset {
2331   my ($self, $rel) = @_;
2332
2333   $self->{related_resultsets} ||= {};
2334   return $self->{related_resultsets}{$rel} ||= do {
2335     my $rel_obj = $self->result_source->relationship_info($rel);
2336
2337     $self->throw_exception(
2338       "search_related: result source '" . $self->result_source->source_name .
2339         "' has no such relationship $rel")
2340       unless $rel_obj;
2341
2342     my ($from,$seen) = $self->_resolve_from($rel);
2343
2344     my $join_count = $seen->{$rel};
2345     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2346
2347     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2348     my %attrs = %{$self->{attrs}||{}};
2349     delete @attrs{qw(result_class alias)};
2350
2351     my $new_cache;
2352
2353     if (my $cache = $self->get_cache) {
2354       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2355         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2356                         @$cache ];
2357       }
2358     }
2359
2360     my $rel_source = $self->result_source->related_source($rel);
2361
2362     my $new = do {
2363
2364       # The reason we do this now instead of passing the alias to the
2365       # search_rs below is that if you wrap/overload resultset on the
2366       # source you need to know what alias it's -going- to have for things
2367       # to work sanely (e.g. RestrictWithObject wants to be able to add
2368       # extra query restrictions, and these may need to be $alias.)
2369
2370       my $attrs = $rel_source->resultset_attributes;
2371       local $attrs->{alias} = $alias;
2372
2373       $rel_source->resultset
2374                  ->search_rs(
2375                      undef, {
2376                        %attrs,
2377                        join => undef,
2378                        prefetch => undef,
2379                        select => undef,
2380                        as => undef,
2381                        where => $self->{cond},
2382                        seen_join => $seen,
2383                        from => $from,
2384                    });
2385     };
2386     $new->set_cache($new_cache) if $new_cache;
2387     $new;
2388   };
2389 }
2390
2391 =head2 current_source_alias
2392
2393 =over 4
2394
2395 =item Arguments: none
2396
2397 =item Return Value: $source_alias
2398
2399 =back
2400
2401 Returns the current table alias for the result source this resultset is built
2402 on, that will be used in the SQL query. Usually it is C<me>.
2403
2404 Currently the source alias that refers to the result set returned by a
2405 L</search>/L</find> family method depends on how you got to the resultset: it's
2406 C<me> by default, but eg. L</search_related> aliases it to the related result
2407 source name (and keeps C<me> referring to the original result set). The long
2408 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2409 (and make this method unnecessary).
2410
2411 Thus it's currently necessary to use this method in predefined queries (see
2412 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2413 source alias of the current result set:
2414
2415   # in a result set class
2416   sub modified_by {
2417     my ($self, $user) = @_;
2418
2419     my $me = $self->current_source_alias;
2420
2421     return $self->search(
2422       "$me.modified" => $user->id,
2423     );
2424   }
2425
2426 =cut
2427
2428 sub current_source_alias {
2429   my ($self) = @_;
2430
2431   return ($self->{attrs} || {})->{alias} || 'me';
2432 }
2433
2434 # This code is called by search_related, and makes sure there
2435 # is clear separation between the joins before, during, and
2436 # after the relationship. This information is needed later
2437 # in order to properly resolve prefetch aliases (any alias
2438 # with a relation_chain_depth less than the depth of the
2439 # current prefetch is not considered)
2440 sub _resolve_from {
2441   my ($self, $extra_join) = @_;
2442   my $source = $self->result_source;
2443   my $attrs = $self->{attrs};
2444
2445   my $from = [ @{
2446       $attrs->{from}
2447         ||
2448       [{
2449         -source_handle => $source->handle,
2450         -alias => $attrs->{alias},
2451         $attrs->{alias} => $source->from,
2452       }]
2453   }];
2454
2455   my $seen = { %{$attrs->{seen_join} || {} } };
2456
2457   # we need to take the prefetch the attrs into account before we
2458   # ->_resolve_join as otherwise they get lost - captainL
2459   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2460
2461   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2462
2463   ++$seen->{-relation_chain_depth};
2464
2465   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2466
2467   ++$seen->{-relation_chain_depth};
2468
2469   return ($from,$seen);
2470 }
2471
2472 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2473 sub _resolved_attrs_copy {
2474   my $self = shift;
2475   return { %{$self->_resolved_attrs (@_)} };
2476 }
2477
2478 sub _resolved_attrs {
2479   my $self = shift;
2480   return $self->{_attrs} if $self->{_attrs};
2481
2482   my $attrs  = { %{ $self->{attrs} || {} } };
2483   my $source = $self->result_source;
2484   my $alias  = $attrs->{alias};
2485
2486   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2487   my @colbits;
2488
2489   # build columns (as long as select isn't set) into a set of as/select hashes
2490   unless ( $attrs->{select} ) {
2491       @colbits = map {
2492           ( ref($_) eq 'HASH' )
2493               ? $_
2494               : {
2495                   (
2496                     /^\Q${alias}.\E(.+)$/
2497                       ? "$1"
2498                       : "$_"
2499                   )
2500                 =>
2501                   (
2502                     /\./
2503                       ? "$_"
2504                       : "${alias}.$_"
2505                   )
2506             }
2507       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2508   }
2509   # add the additional columns on
2510   foreach ( 'include_columns', '+columns' ) {
2511       push @colbits, map {
2512           ( ref($_) eq 'HASH' )
2513             ? $_
2514             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2515       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2516   }
2517
2518   # start with initial select items
2519   if ( $attrs->{select} ) {
2520     $attrs->{select} =
2521         ( ref $attrs->{select} eq 'ARRAY' )
2522       ? [ @{ $attrs->{select} } ]
2523       : [ $attrs->{select} ];
2524     $attrs->{as} = (
2525       $attrs->{as}
2526       ? (
2527         ref $attrs->{as} eq 'ARRAY'
2528         ? [ @{ $attrs->{as} } ]
2529         : [ $attrs->{as} ]
2530         )
2531       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2532     );
2533   }
2534   else {
2535
2536     # otherwise we intialise select & as to empty
2537     $attrs->{select} = [];
2538     $attrs->{as}     = [];
2539   }
2540
2541   # now add colbits to select/as
2542   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2543   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2544
2545   my $adds;
2546   if ( $adds = delete $attrs->{'+select'} ) {
2547     $adds = [$adds] unless ref $adds eq 'ARRAY';
2548     push(
2549       @{ $attrs->{select} },
2550       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2551     );
2552   }
2553   if ( $adds = delete $attrs->{'+as'} ) {
2554     $adds = [$adds] unless ref $adds eq 'ARRAY';
2555     push( @{ $attrs->{as} }, @$adds );
2556   }
2557
2558   $attrs->{from} ||= [ {
2559     -source_handle => $source->handle,
2560     -alias => $self->{attrs}{alias},
2561     $self->{attrs}{alias} => $source->from,
2562   } ];
2563
2564   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2565     my $join = delete $attrs->{join} || {};
2566
2567     if ( defined $attrs->{prefetch} ) {
2568       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2569
2570     }
2571
2572     $attrs->{from} =    # have to copy here to avoid corrupting the original
2573       [
2574       @{ $attrs->{from} },
2575       $source->_resolve_join(
2576         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2577       )
2578       ];
2579
2580   }
2581
2582   if ( $attrs->{order_by} ) {
2583     $attrs->{order_by} = (
2584       ref( $attrs->{order_by} ) eq 'ARRAY'
2585       ? [ @{ $attrs->{order_by} } ]
2586       : [ $attrs->{order_by} ]
2587     );
2588   }
2589   else {
2590     $attrs->{order_by} = [];
2591   }
2592
2593   # If the order_by is otherwise empty - we will use this for TOP limit
2594   # emulation and the like.
2595   # Although this is needed only if the order_by is not defined, it is
2596   # actually cheaper to just populate this rather than properly examining
2597   # order_by (stuf like [ {} ] and the like)
2598   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2599
2600
2601   my $collapse = $attrs->{collapse} || {};
2602
2603   if ( my $prefetch = delete $attrs->{prefetch} ) {
2604     $prefetch = $self->_merge_attr( {}, $prefetch );
2605
2606     my $prefetch_ordering = [];
2607
2608     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2609
2610     my @prefetch =
2611       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $collapse );
2612
2613     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2614     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2615
2616     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2617   }
2618
2619   if (delete $attrs->{distinct}) {
2620     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2621   }
2622
2623   $attrs->{collapse} = $collapse;
2624
2625   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2626     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2627   }
2628
2629   return $self->{_attrs} = $attrs;
2630 }
2631
2632 sub _joinpath_aliases {
2633   my ($self, $fromspec, $seen) = @_;
2634
2635   my $paths = {};
2636   return $paths unless ref $fromspec eq 'ARRAY';
2637
2638   for my $j (@$fromspec) {
2639
2640     next if ref $j ne 'ARRAY';
2641     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2642
2643     my $p = $paths;
2644     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2645     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2646   }
2647
2648   return $paths;
2649 }
2650
2651 sub _rollout_attr {
2652   my ($self, $attr) = @_;
2653
2654   if (ref $attr eq 'HASH') {
2655     return $self->_rollout_hash($attr);
2656   } elsif (ref $attr eq 'ARRAY') {
2657     return $self->_rollout_array($attr);
2658   } else {
2659     return [$attr];
2660   }
2661 }
2662
2663 sub _rollout_array {
2664   my ($self, $attr) = @_;
2665
2666   my @rolled_array;
2667   foreach my $element (@{$attr}) {
2668     if (ref $element eq 'HASH') {
2669       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2670     } elsif (ref $element eq 'ARRAY') {
2671       #  XXX - should probably recurse here
2672       push( @rolled_array, @{$self->_rollout_array($element)} );
2673     } else {
2674       push( @rolled_array, $element );
2675     }
2676   }
2677   return \@rolled_array;
2678 }
2679
2680 sub _rollout_hash {
2681   my ($self, $attr) = @_;
2682
2683   my @rolled_array;
2684   foreach my $key (keys %{$attr}) {
2685     push( @rolled_array, { $key => $attr->{$key} } );
2686   }
2687   return \@rolled_array;
2688 }
2689
2690 sub _calculate_score {
2691   my ($self, $a, $b) = @_;
2692
2693   if (ref $b eq 'HASH') {
2694     my ($b_key) = keys %{$b};
2695     if (ref $a eq 'HASH') {
2696       my ($a_key) = keys %{$a};
2697       if ($a_key eq $b_key) {
2698         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2699       } else {
2700         return 0;
2701       }
2702     } else {
2703       return ($a eq $b_key) ? 1 : 0;
2704     }
2705   } else {
2706     if (ref $a eq 'HASH') {
2707       my ($a_key) = keys %{$a};
2708       return ($b eq $a_key) ? 1 : 0;
2709     } else {
2710       return ($b eq $a) ? 1 : 0;
2711     }
2712   }
2713 }
2714
2715 sub _merge_attr {
2716   my ($self, $orig, $import) = @_;
2717
2718   return $import unless defined($orig);
2719   return $orig unless defined($import);
2720
2721   $orig = $self->_rollout_attr($orig);
2722   $import = $self->_rollout_attr($import);
2723
2724   my $seen_keys;
2725   foreach my $import_element ( @{$import} ) {
2726     # find best candidate from $orig to merge $b_element into
2727     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2728     foreach my $orig_element ( @{$orig} ) {
2729       my $score = $self->_calculate_score( $orig_element, $import_element );
2730       if ($score > $best_candidate->{score}) {
2731         $best_candidate->{position} = $position;
2732         $best_candidate->{score} = $score;
2733       }
2734       $position++;
2735     }
2736     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2737
2738     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2739       push( @{$orig}, $import_element );
2740     } else {
2741       my $orig_best = $orig->[$best_candidate->{position}];
2742       # merge orig_best and b_element together and replace original with merged
2743       if (ref $orig_best ne 'HASH') {
2744         $orig->[$best_candidate->{position}] = $import_element;
2745       } elsif (ref $import_element eq 'HASH') {
2746         my ($key) = keys %{$orig_best};
2747         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2748       }
2749     }
2750     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2751   }
2752
2753   return $orig;
2754 }
2755
2756 sub result_source {
2757     my $self = shift;
2758
2759     if (@_) {
2760         $self->_source_handle($_[0]->handle);
2761     } else {
2762         $self->_source_handle->resolve;
2763     }
2764 }
2765
2766 =head2 throw_exception
2767
2768 See L<DBIx::Class::Schema/throw_exception> for details.
2769
2770 =cut
2771
2772 sub throw_exception {
2773   my $self=shift;
2774   if (ref $self && $self->_source_handle->schema) {
2775     $self->_source_handle->schema->throw_exception(@_)
2776   } else {
2777     croak(@_);
2778   }
2779
2780 }
2781
2782 # XXX: FIXME: Attributes docs need clearing up
2783
2784 =head1 ATTRIBUTES
2785
2786 Attributes are used to refine a ResultSet in various ways when
2787 searching for data. They can be passed to any method which takes an
2788 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2789 L</count>.
2790
2791 These are in no particular order:
2792
2793 =head2 order_by
2794
2795 =over 4
2796
2797 =item Value: ( $order_by | \@order_by | \%order_by )
2798
2799 =back
2800
2801 Which column(s) to order the results by. If a single column name, or
2802 an arrayref of names is supplied, the argument is passed through
2803 directly to SQL. The hashref syntax allows for connection-agnostic
2804 specification of ordering direction:
2805
2806  For descending order:
2807
2808   order_by => { -desc => [qw/col1 col2 col3/] }
2809
2810  For explicit ascending order:
2811
2812   order_by => { -asc => 'col' }
2813
2814 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2815 supported, although you are strongly encouraged to use the hashref
2816 syntax as outlined above.
2817
2818 =head2 columns
2819
2820 =over 4
2821
2822 =item Value: \@columns
2823
2824 =back
2825
2826 Shortcut to request a particular set of columns to be retrieved. Each
2827 column spec may be a string (a table column name), or a hash (in which
2828 case the key is the C<as> value, and the value is used as the C<select>
2829 expression). Adds C<me.> onto the start of any column without a C<.> in
2830 it and sets C<select> from that, then auto-populates C<as> from
2831 C<select> as normal. (You may also use the C<cols> attribute, as in
2832 earlier versions of DBIC.)
2833
2834 =head2 +columns
2835
2836 =over 4
2837
2838 =item Value: \@columns
2839
2840 =back
2841
2842 Indicates additional columns to be selected from storage. Works the same
2843 as L</columns> but adds columns to the selection. (You may also use the
2844 C<include_columns> attribute, as in earlier versions of DBIC). For
2845 example:-
2846
2847   $schema->resultset('CD')->search(undef, {
2848     '+columns' => ['artist.name'],
2849     join => ['artist']
2850   });
2851
2852 would return all CDs and include a 'name' column to the information
2853 passed to object inflation. Note that the 'artist' is the name of the
2854 column (or relationship) accessor, and 'name' is the name of the column
2855 accessor in the related table.
2856
2857 =head2 include_columns
2858
2859 =over 4
2860
2861 =item Value: \@columns
2862
2863 =back
2864
2865 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2866
2867 =head2 select
2868
2869 =over 4
2870
2871 =item Value: \@select_columns
2872
2873 =back
2874
2875 Indicates which columns should be selected from the storage. You can use
2876 column names, or in the case of RDBMS back ends, function or stored procedure
2877 names:
2878
2879   $rs = $schema->resultset('Employee')->search(undef, {
2880     select => [
2881       'name',
2882       { count => 'employeeid' },
2883       { sum => 'salary' }
2884     ]
2885   });
2886
2887 When you use function/stored procedure names and do not supply an C<as>
2888 attribute, the column names returned are storage-dependent. E.g. MySQL would
2889 return a column named C<count(employeeid)> in the above example.
2890
2891 =head2 +select
2892
2893 =over 4
2894
2895 Indicates additional columns to be selected from storage.  Works the same as
2896 L</select> but adds columns to the selection.
2897
2898 =back
2899
2900 =head2 +as
2901
2902 =over 4
2903
2904 Indicates additional column names for those added via L</+select>. See L</as>.
2905
2906 =back
2907
2908 =head2 as
2909
2910 =over 4
2911
2912 =item Value: \@inflation_names
2913
2914 =back
2915
2916 Indicates column names for object inflation. That is, C<as>
2917 indicates the name that the column can be accessed as via the
2918 C<get_column> method (or via the object accessor, B<if one already
2919 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2920
2921 The C<as> attribute is used in conjunction with C<select>,
2922 usually when C<select> contains one or more function or stored
2923 procedure names:
2924
2925   $rs = $schema->resultset('Employee')->search(undef, {
2926     select => [
2927       'name',
2928       { count => 'employeeid' }
2929     ],
2930     as => ['name', 'employee_count'],
2931   });
2932
2933   my $employee = $rs->first(); # get the first Employee
2934
2935 If the object against which the search is performed already has an accessor
2936 matching a column name specified in C<as>, the value can be retrieved using
2937 the accessor as normal:
2938
2939   my $name = $employee->name();
2940
2941 If on the other hand an accessor does not exist in the object, you need to
2942 use C<get_column> instead:
2943
2944   my $employee_count = $employee->get_column('employee_count');
2945
2946 You can create your own accessors if required - see
2947 L<DBIx::Class::Manual::Cookbook> for details.
2948
2949 Please note: This will NOT insert an C<AS employee_count> into the SQL
2950 statement produced, it is used for internal access only. Thus
2951 attempting to use the accessor in an C<order_by> clause or similar
2952 will fail miserably.
2953
2954 To get around this limitation, you can supply literal SQL to your
2955 C<select> attibute that contains the C<AS alias> text, eg:
2956
2957   select => [\'myfield AS alias']
2958
2959 =head2 join
2960
2961 =over 4
2962
2963 =item Value: ($rel_name | \@rel_names | \%rel_names)
2964
2965 =back
2966
2967 Contains a list of relationships that should be joined for this query.  For
2968 example:
2969
2970   # Get CDs by Nine Inch Nails
2971   my $rs = $schema->resultset('CD')->search(
2972     { 'artist.name' => 'Nine Inch Nails' },
2973     { join => 'artist' }
2974   );
2975
2976 Can also contain a hash reference to refer to the other relation's relations.
2977 For example:
2978
2979   package MyApp::Schema::Track;
2980   use base qw/DBIx::Class/;
2981   __PACKAGE__->table('track');
2982   __PACKAGE__->add_columns(qw/trackid cd position title/);
2983   __PACKAGE__->set_primary_key('trackid');
2984   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2985   1;
2986
2987   # In your application
2988   my $rs = $schema->resultset('Artist')->search(
2989     { 'track.title' => 'Teardrop' },
2990     {
2991       join     => { cd => 'track' },
2992       order_by => 'artist.name',
2993     }
2994   );
2995
2996 You need to use the relationship (not the table) name in  conditions,
2997 because they are aliased as such. The current table is aliased as "me", so
2998 you need to use me.column_name in order to avoid ambiguity. For example:
2999
3000   # Get CDs from 1984 with a 'Foo' track
3001   my $rs = $schema->resultset('CD')->search(
3002     {
3003       'me.year' => 1984,
3004       'tracks.name' => 'Foo'
3005     },
3006     { join => 'tracks' }
3007   );
3008
3009 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3010 similarly for a third time). For e.g.
3011
3012   my $rs = $schema->resultset('Artist')->search({
3013     'cds.title'   => 'Down to Earth',
3014     'cds_2.title' => 'Popular',
3015   }, {
3016     join => [ qw/cds cds/ ],
3017   });
3018
3019 will return a set of all artists that have both a cd with title 'Down
3020 to Earth' and a cd with title 'Popular'.
3021
3022 If you want to fetch related objects from other tables as well, see C<prefetch>
3023 below.
3024
3025 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3026
3027 =head2 prefetch
3028
3029 =over 4
3030
3031 =item Value: ($rel_name | \@rel_names | \%rel_names)
3032
3033 =back
3034
3035 Contains one or more relationships that should be fetched along with
3036 the main query (when they are accessed afterwards the data will
3037 already be available, without extra queries to the database).  This is
3038 useful for when you know you will need the related objects, because it
3039 saves at least one query:
3040
3041   my $rs = $schema->resultset('Tag')->search(
3042     undef,
3043     {
3044       prefetch => {
3045         cd => 'artist'
3046       }
3047     }
3048   );
3049
3050 The initial search results in SQL like the following:
3051
3052   SELECT tag.*, cd.*, artist.* FROM tag
3053   JOIN cd ON tag.cd = cd.cdid
3054   JOIN artist ON cd.artist = artist.artistid
3055
3056 L<DBIx::Class> has no need to go back to the database when we access the
3057 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3058 case.
3059
3060 Simple prefetches will be joined automatically, so there is no need
3061 for a C<join> attribute in the above search.
3062
3063 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3064 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3065 with an accessor type of 'single' or 'filter'). A more complex example that
3066 prefetches an artists cds, the tracks on those cds, and the tags associted
3067 with that artist is given below (assuming many-to-many from artists to tags):
3068
3069  my $rs = $schema->resultset('Artist')->search(
3070    undef,
3071    {
3072      prefetch => [
3073        { cds => 'tracks' },
3074        { artist_tags => 'tags' }
3075      ]
3076    }
3077  );
3078
3079
3080 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3081 attributes will be ignored.
3082
3083 =head2 page
3084
3085 =over 4
3086
3087 =item Value: $page
3088
3089 =back
3090
3091 Makes the resultset paged and specifies the page to retrieve. Effectively
3092 identical to creating a non-pages resultset and then calling ->page($page)
3093 on it.
3094
3095 If L<rows> attribute is not specified it defualts to 10 rows per page.
3096
3097 When you have a paged resultset, L</count> will only return the number
3098 of rows in the page. To get the total, use the L</pager> and call
3099 C<total_entries> on it.
3100
3101 =head2 rows
3102
3103 =over 4
3104
3105 =item Value: $rows
3106
3107 =back
3108
3109 Specifes the maximum number of rows for direct retrieval or the number of
3110 rows per page if the page attribute or method is used.
3111
3112 =head2 offset
3113
3114 =over 4
3115
3116 =item Value: $offset
3117
3118 =back
3119
3120 Specifies the (zero-based) row number for the  first row to be returned, or the
3121 of the first row of the first page if paging is used.
3122
3123 =head2 group_by
3124
3125 =over 4
3126
3127 =item Value: \@columns
3128
3129 =back
3130
3131 A arrayref of columns to group by. Can include columns of joined tables.
3132
3133   group_by => [qw/ column1 column2 ... /]
3134
3135 =head2 having
3136
3137 =over 4
3138
3139 =item Value: $condition
3140
3141 =back
3142
3143 HAVING is a select statement attribute that is applied between GROUP BY and
3144 ORDER BY. It is applied to the after the grouping calculations have been
3145 done.
3146
3147   having => { 'count(employee)' => { '>=', 100 } }
3148
3149 =head2 distinct
3150
3151 =over 4
3152
3153 =item Value: (0 | 1)
3154
3155 =back
3156
3157 Set to 1 to group by all columns.
3158
3159 =head2 where
3160
3161 =over 4
3162
3163 Adds to the WHERE clause.
3164
3165   # only return rows WHERE deleted IS NULL for all searches
3166   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3167
3168 Can be overridden by passing C<{ where => undef }> as an attribute
3169 to a resulset.
3170
3171 =back
3172
3173 =head2 cache
3174
3175 Set to 1 to cache search results. This prevents extra SQL queries if you
3176 revisit rows in your ResultSet:
3177
3178   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3179
3180   while( my $artist = $resultset->next ) {
3181     ... do stuff ...
3182   }
3183
3184   $rs->first; # without cache, this would issue a query
3185
3186 By default, searches are not cached.
3187
3188 For more examples of using these attributes, see
3189 L<DBIx::Class::Manual::Cookbook>.
3190
3191 =head2 from
3192
3193 =over 4
3194
3195 =item Value: \@from_clause
3196
3197 =back
3198
3199 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3200 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3201 clauses.
3202
3203 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3204
3205 C<join> will usually do what you need and it is strongly recommended that you
3206 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3207 And we really do mean "cannot", not just tried and failed. Attempting to use
3208 this because you're having problems with C<join> is like trying to use x86
3209 ASM because you've got a syntax error in your C. Trust us on this.
3210
3211 Now, if you're still really, really sure you need to use this (and if you're
3212 not 100% sure, ask the mailing list first), here's an explanation of how this
3213 works.
3214
3215 The syntax is as follows -
3216
3217   [
3218     { <alias1> => <table1> },
3219     [
3220       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3221       [], # nested JOIN (optional)
3222       { <table1.column1> => <table2.column2>, ... (more conditions) },
3223     ],
3224     # More of the above [ ] may follow for additional joins
3225   ]
3226
3227   <table1> <alias1>
3228   JOIN
3229     <table2> <alias2>
3230     [JOIN ...]
3231   ON <table1.column1> = <table2.column2>
3232   <more joins may follow>
3233
3234 An easy way to follow the examples below is to remember the following:
3235
3236     Anything inside "[]" is a JOIN
3237     Anything inside "{}" is a condition for the enclosing JOIN
3238
3239 The following examples utilize a "person" table in a family tree application.
3240 In order to express parent->child relationships, this table is self-joined:
3241
3242     # Person->belongs_to('father' => 'Person');
3243     # Person->belongs_to('mother' => 'Person');
3244
3245 C<from> can be used to nest joins. Here we return all children with a father,
3246 then search against all mothers of those children:
3247
3248   $rs = $schema->resultset('Person')->search(
3249       undef,
3250       {
3251           alias => 'mother', # alias columns in accordance with "from"
3252           from => [
3253               { mother => 'person' },
3254               [
3255                   [
3256                       { child => 'person' },
3257                       [
3258                           { father => 'person' },
3259                           { 'father.person_id' => 'child.father_id' }
3260                       ]
3261                   ],
3262                   { 'mother.person_id' => 'child.mother_id' }
3263               ],
3264           ]
3265       },
3266   );
3267
3268   # Equivalent SQL:
3269   # SELECT mother.* FROM person mother
3270   # JOIN (
3271   #   person child
3272   #   JOIN person father
3273   #   ON ( father.person_id = child.father_id )
3274   # )
3275   # ON ( mother.person_id = child.mother_id )
3276
3277 The type of any join can be controlled manually. To search against only people
3278 with a father in the person table, we could explicitly use C<INNER JOIN>:
3279
3280     $rs = $schema->resultset('Person')->search(
3281         undef,
3282         {
3283             alias => 'child', # alias columns in accordance with "from"
3284             from => [
3285                 { child => 'person' },
3286                 [
3287                     { father => 'person', -join_type => 'inner' },
3288                     { 'father.id' => 'child.father_id' }
3289                 ],
3290             ]
3291         },
3292     );
3293
3294     # Equivalent SQL:
3295     # SELECT child.* FROM person child
3296     # INNER JOIN person father ON child.father_id = father.id
3297
3298 You can select from a subquery by passing a resultset to from as follows.
3299
3300     $schema->resultset('Artist')->search(
3301         undef,
3302         {   alias => 'artist2',
3303             from  => [ { artist2 => $artist_rs->as_query } ],
3304         } );
3305
3306     # and you'll get sql like this..
3307     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3308     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3309
3310 If you need to express really complex joins, you
3311 can supply literal SQL to C<from> via a scalar reference. In this case
3312 the contents of the scalar will replace the table name associated with the
3313 resultsource.
3314
3315 WARNING: This technique might very well not work as expected on chained
3316 searches - you have been warned.
3317
3318     # Assuming the Event resultsource is defined as:
3319
3320         MySchema::Event->add_columns (
3321             sequence => {
3322                 data_type => 'INT',
3323                 is_auto_increment => 1,
3324             },
3325             location => {
3326                 data_type => 'INT',
3327             },
3328             type => {
3329                 data_type => 'INT',
3330             },
3331         );
3332         MySchema::Event->set_primary_key ('sequence');
3333
3334     # This will get back the latest event for every location. The column
3335     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3336     # combo to limit the resultset
3337
3338     $rs = $schema->resultset('Event');
3339     $table = $rs->result_source->name;
3340     $latest = $rs->search (
3341         undef,
3342         { from => \ "
3343             (SELECT e1.* FROM $table e1
3344                 JOIN $table e2
3345                     ON e1.location = e2.location
3346                     AND e1.sequence < e2.sequence
3347                 WHERE e2.sequence is NULL
3348             ) me",
3349         },
3350     );
3351
3352     # Equivalent SQL (with the DBIC chunks added):
3353
3354     SELECT me.sequence, me.location, me.type FROM
3355        (SELECT e1.* FROM events e1
3356            JOIN events e2
3357                ON e1.location = e2.location
3358                AND e1.sequence < e2.sequence
3359            WHERE e2.sequence is NULL
3360        ) me;
3361
3362 =head2 for
3363
3364 =over 4
3365
3366 =item Value: ( 'update' | 'shared' )
3367
3368 =back
3369
3370 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3371 ... FOR SHARED.
3372
3373 =cut
3374
3375 1;