lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960
 961   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 962     or return ();
 963   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 964   @new = $self->{_attrs}{record_filter}->(@new)
 965     if exists $self->{_attrs}{record_filter};
 966   return @new;
 967 }
 968
 969 sub _collapse_result {
 970   my ($self, $as_proto, $row) = @_;
 971
 972   # if the first row that ever came in is totally empty - this means we got
 973   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 974   # instead of producing a {}
 975   #
 976   my $has_def;
 977   for (@$row) {
 978     if (defined $_) {
 979       $has_def++;
 980       last;
 981     }
 982   }
 983   return undef unless $has_def;
 984
 985   my @copy = @$row;
 986
 987   # 'foo'         => [ undef, 'foo' ]
 988   # 'foo.bar'     => [ 'foo', 'bar' ]
 989   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 990
 991   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 992
 993   my %collapse = %{$self->{_attrs}{collapse}||{}};
 994
 995   my @pri_index;
 996
 997   # if we're doing collapsing (has_many prefetch) we need to grab records
 998   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 999   # we know we don't have to bother.
1000
1001   # the reason for not using the collapse stuff directly is because if you
1002   # had for e.g. two artists in a row with no cds, the collapse info for
1003   # both would be NULL (undef) so you'd lose the second artist
1004
1005   # store just the index so we can check the array positions from the row
1006   # without having to contruct the full hash
1007
1008   if (keys %collapse) {
1009     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1010     foreach my $i (0 .. $#construct_as) {
1011       next if defined($construct_as[$i][0]); # only self table
1012       if (delete $pri{$construct_as[$i][1]}) {
1013         push(@pri_index, $i);
1014       }
1015       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1016     }
1017   }
1018
1019   # no need to do an if, it'll be empty if @pri_index is empty anyway
1020
1021   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1022
1023   my @const_rows;
1024
1025   do { # no need to check anything at the front, we always want the first row
1026
1027     my %const;
1028
1029     foreach my $this_as (@construct_as) {
1030       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1031     }
1032
1033     push(@const_rows, \%const);
1034
1035   } until ( # no pri_index => no collapse => drop straight out
1036       !@pri_index
1037     or
1038       do { # get another row, stash it, drop out if different PK
1039
1040         @copy = $self->cursor->next;
1041         $self->{stashed_row} = \@copy;
1042
1043         # last thing in do block, counts as true if anything doesn't match
1044
1045         # check xor defined first for NULL vs. NOT NULL then if one is
1046         # defined the other must be so check string equality
1047
1048         grep {
1049           (defined $pri_vals{$_} ^ defined $copy[$_])
1050           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1051         } @pri_index;
1052       }
1053   );
1054
1055   my $alias = $self->{attrs}{alias};
1056   my $info = [];
1057
1058   my %collapse_pos;
1059
1060   my @const_keys;
1061
1062   foreach my $const (@const_rows) {
1063     scalar @const_keys or do {
1064       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1065     };
1066     foreach my $key (@const_keys) {
1067       if (length $key) {
1068         my $target = $info;
1069         my @parts = split(/\./, $key);
1070         my $cur = '';
1071         my $data = $const->{$key};
1072         foreach my $p (@parts) {
1073           $target = $target->[1]->{$p} ||= [];
1074           $cur .= ".${p}";
1075           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1076             # collapsing at this point and on final part
1077             my $pos = $collapse_pos{$cur};
1078             CK: foreach my $ck (@ckey) {
1079               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1080                 $collapse_pos{$cur} = $data;
1081                 delete @collapse_pos{ # clear all positioning for sub-entries
1082                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1083                 };
1084                 push(@$target, []);
1085                 last CK;
1086               }
1087             }
1088           }
1089           if (exists $collapse{$cur}) {
1090             $target = $target->[-1];
1091           }
1092         }
1093         $target->[0] = $data;
1094       } else {
1095         $info->[0] = $const->{$key};
1096       }
1097     }
1098   }
1099
1100   return $info;
1101 }
1102
1103 =head2 result_source
1104
1105 =over 4
1106
1107 =item Arguments: $result_source?
1108
1109 =item Return Value: $result_source
1110
1111 =back
1112
1113 An accessor for the primary ResultSource object from which this ResultSet
1114 is derived.
1115
1116 =head2 result_class
1117
1118 =over 4
1119
1120 =item Arguments: $result_class?
1121
1122 =item Return Value: $result_class
1123
1124 =back
1125
1126 An accessor for the class to use when creating row objects. Defaults to
1127 C<< result_source->result_class >> - which in most cases is the name of the
1128 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1129
1130 Note that changing the result_class will also remove any components
1131 that were originally loaded in the source class via
1132 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1133 in the original source class will not run.
1134
1135 =cut
1136
1137 sub result_class {
1138   my ($self, $result_class) = @_;
1139   if ($result_class) {
1140     $self->ensure_class_loaded($result_class);
1141     $self->_result_class($result_class);
1142   }
1143   $self->_result_class;
1144 }
1145
1146 =head2 count
1147
1148 =over 4
1149
1150 =item Arguments: $cond, \%attrs??
1151
1152 =item Return Value: $count
1153
1154 =back
1155
1156 Performs an SQL C<COUNT> with the same query as the resultset was built
1157 with to find the number of elements. Passing arguments is equivalent to
1158 C<< $rs->search ($cond, \%attrs)->count >>
1159
1160 =cut
1161
1162 sub count {
1163   my $self = shift;
1164   return $self->search(@_)->count if @_ and defined $_[0];
1165   return scalar @{ $self->get_cache } if $self->get_cache;
1166
1167   my $attrs = $self->_resolved_attrs_copy;
1168
1169   # this is a little optimization - it is faster to do the limit
1170   # adjustments in software, instead of a subquery
1171   my $rows = delete $attrs->{rows};
1172   my $offset = delete $attrs->{offset};
1173
1174   my $crs;
1175   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1176     $crs = $self->_count_subq_rs ($attrs);
1177   }
1178   else {
1179     $crs = $self->_count_rs ($attrs);
1180   }
1181   my $count = $crs->next;
1182
1183   $count -= $offset if $offset;
1184   $count = $rows if $rows and $rows < $count;
1185   $count = 0 if ($count < 0);
1186
1187   return $count;
1188 }
1189
1190 =head2 count_rs
1191
1192 =over 4
1193
1194 =item Arguments: $cond, \%attrs??
1195
1196 =item Return Value: $count_rs
1197
1198 =back
1199
1200 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1201 This can be very handy for subqueries:
1202
1203   ->search( { amount => $some_rs->count_rs->as_query } )
1204
1205 As with regular resultsets the SQL query will be executed only after
1206 the resultset is accessed via L</next> or L</all>. That would return
1207 the same single value obtainable via L</count>.
1208
1209 =cut
1210
1211 sub count_rs {
1212   my $self = shift;
1213   return $self->search(@_)->count_rs if @_;
1214
1215   # this may look like a lack of abstraction (count() does about the same)
1216   # but in fact an _rs *must* use a subquery for the limits, as the
1217   # software based limiting can not be ported if this $rs is to be used
1218   # in a subquery itself (i.e. ->as_query)
1219   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1220     return $self->_count_subq_rs;
1221   }
1222   else {
1223     return $self->_count_rs;
1224   }
1225 }
1226
1227 #
1228 # returns a ResultSetColumn object tied to the count query
1229 #
1230 sub _count_rs {
1231   my ($self, $attrs) = @_;
1232
1233   my $rsrc = $self->result_source;
1234   $attrs ||= $self->_resolved_attrs;
1235
1236   my $tmp_attrs = { %$attrs };
1237
1238   # take off any limits, record_filter is cdbi, and no point of ordering a count
1239   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1240
1241   # overwrite the selector (supplied by the storage)
1242   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1243   $tmp_attrs->{as} = 'count';
1244
1245   # read the comment on top of the actual function to see what this does
1246   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1247     $tmp_attrs->{from}, $tmp_attrs->{alias}
1248   );
1249
1250   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1251
1252   return $tmp_rs;
1253 }
1254
1255 #
1256 # same as above but uses a subquery
1257 #
1258 sub _count_subq_rs {
1259   my ($self, $attrs) = @_;
1260
1261   my $rsrc = $self->result_source;
1262   $attrs ||= $self->_resolved_attrs_copy;
1263
1264   my $sub_attrs = { %$attrs };
1265
1266   # extra selectors do not go in the subquery and there is no point of ordering it
1267   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1268
1269   # if we prefetch, we group_by primary keys only as this is what we would get out
1270   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1271   if ( keys %{$attrs->{collapse}} ) {
1272     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1273   }
1274
1275   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1276
1277   # read the comment on top of the actual function to see what this does
1278   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1279     $sub_attrs->{from}, $sub_attrs->{alias}
1280   );
1281
1282   # this is so that ordering can be thrown away in things like Top limit
1283   $sub_attrs->{-for_count_only} = 1;
1284
1285   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1286
1287   $attrs->{from} = [{
1288     -alias => 'count_subq',
1289     -source_handle => $rsrc->handle,
1290     count_subq => $sub_rs->as_query,
1291   }];
1292
1293   # the subquery replaces this
1294   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1295
1296   return $self->_count_rs ($attrs);
1297 }
1298
1299
1300 # The DBIC relationship chaining implementation is pretty simple - every
1301 # new related_relationship is pushed onto the {from} stack, and the {select}
1302 # window simply slides further in. This means that when we count somewhere
1303 # in the middle, we got to make sure that everything in the join chain is an
1304 # actual inner join, otherwise the count will come back with unpredictable
1305 # results (a resultset may be generated with _some_ rows regardless of if
1306 # the relation which the $rs currently selects has rows or not). E.g.
1307 # $artist_rs->cds->count - normally generates:
1308 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1309 # which actually returns the number of artists * (number of cds || 1)
1310 #
1311 # So what we do here is crawl {from}, determine if the current alias is at
1312 # the top of the stack, and if not - make sure the chain is inner-joined down
1313 # to the root.
1314 #
1315 sub _switch_to_inner_join_if_needed {
1316   my ($self, $from, $alias) = @_;
1317
1318   # subqueries and other oddness is naturally not supported
1319   return $from if (
1320     ref $from ne 'ARRAY'
1321       ||
1322     @$from <= 1
1323       ||
1324     ref $from->[0] ne 'HASH'
1325       ||
1326     ! $from->[0]{-alias}
1327       ||
1328     $from->[0]{-alias} eq $alias
1329   );
1330
1331   my $switch_branch;
1332   JOINSCAN:
1333   for my $j (@{$from}[1 .. $#$from]) {
1334     if ($j->[0]{-alias} eq $alias) {
1335       $switch_branch = $j->[0]{-join_path};
1336       last JOINSCAN;
1337     }
1338   }
1339
1340   # something else went wrong
1341   return $from unless $switch_branch;
1342
1343   # So it looks like we will have to switch some stuff around.
1344   # local() is useless here as we will be leaving the scope
1345   # anyway, and deep cloning is just too fucking expensive
1346   # So replace the inner hashref manually
1347   my @new_from = ($from->[0]);
1348   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1349
1350   for my $j (@{$from}[1 .. $#$from]) {
1351     my $jalias = $j->[0]{-alias};
1352
1353     if ($sw_idx->{$jalias}) {
1354       my %attrs = %{$j->[0]};
1355       delete $attrs{-join_type};
1356       push @new_from, [
1357         \%attrs,
1358         @{$j}[ 1 .. $#$j ],
1359       ];
1360     }
1361     else {
1362       push @new_from, $j;
1363     }
1364   }
1365
1366   return \@new_from;
1367 }
1368
1369
1370 sub _bool {
1371   return 1;
1372 }
1373
1374 =head2 count_literal
1375
1376 =over 4
1377
1378 =item Arguments: $sql_fragment, @bind_values
1379
1380 =item Return Value: $count
1381
1382 =back
1383
1384 Counts the results in a literal query. Equivalent to calling L</search_literal>
1385 with the passed arguments, then L</count>.
1386
1387 =cut
1388
1389 sub count_literal { shift->search_literal(@_)->count; }
1390
1391 =head2 all
1392
1393 =over 4
1394
1395 =item Arguments: none
1396
1397 =item Return Value: @objects
1398
1399 =back
1400
1401 Returns all elements in the resultset. Called implicitly if the resultset
1402 is returned in list context.
1403
1404 =cut
1405
1406 sub all {
1407   my $self = shift;
1408   if(@_) {
1409       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1410   }
1411
1412   return @{ $self->get_cache } if $self->get_cache;
1413
1414   my @obj;
1415
1416   if (keys %{$self->_resolved_attrs->{collapse}}) {
1417     # Using $self->cursor->all is really just an optimisation.
1418     # If we're collapsing has_many prefetches it probably makes
1419     # very little difference, and this is cleaner than hacking
1420     # _construct_object to survive the approach
1421     $self->cursor->reset;
1422     my @row = $self->cursor->next;
1423     while (@row) {
1424       push(@obj, $self->_construct_object(@row));
1425       @row = (exists $self->{stashed_row}
1426                ? @{delete $self->{stashed_row}}
1427                : $self->cursor->next);
1428     }
1429   } else {
1430     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1431   }
1432
1433   $self->set_cache(\@obj) if $self->{attrs}{cache};
1434
1435   return @obj;
1436 }
1437
1438 =head2 reset
1439
1440 =over 4
1441
1442 =item Arguments: none
1443
1444 =item Return Value: $self
1445
1446 =back
1447
1448 Resets the resultset's cursor, so you can iterate through the elements again.
1449 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1450 another query.
1451
1452 =cut
1453
1454 sub reset {
1455   my ($self) = @_;
1456   delete $self->{_attrs} if exists $self->{_attrs};
1457   $self->{all_cache_position} = 0;
1458   $self->cursor->reset;
1459   return $self;
1460 }
1461
1462 =head2 first
1463
1464 =over 4
1465
1466 =item Arguments: none
1467
1468 =item Return Value: $object?
1469
1470 =back
1471
1472 Resets the resultset and returns an object for the first result (if the
1473 resultset returns anything).
1474
1475 =cut
1476
1477 sub first {
1478   return $_[0]->reset->next;
1479 }
1480
1481
1482 # _rs_update_delete
1483 #
1484 # Determines whether and what type of subquery is required for the $rs operation.
1485 # If grouping is necessary either supplies its own, or verifies the current one
1486 # After all is done delegates to the proper storage method.
1487
1488 sub _rs_update_delete {
1489   my ($self, $op, $values) = @_;
1490
1491   my $rsrc = $self->result_source;
1492
1493   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1494   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1495
1496   if ($needs_group_by_subq or $needs_subq) {
1497
1498     # make a new $rs selecting only the PKs (that's all we really need)
1499     my $attrs = $self->_resolved_attrs_copy;
1500
1501     delete $attrs->{$_} for qw/collapse select as/;
1502     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1503
1504     if ($needs_group_by_subq) {
1505       # make sure no group_by was supplied, or if there is one - make sure it matches
1506       # the columns compiled above perfectly. Anything else can not be sanely executed
1507       # on most databases so croak right then and there
1508
1509       if (my $g = $attrs->{group_by}) {
1510         my @current_group_by = map
1511           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1512           @$g
1513         ;
1514
1515         if (
1516           join ("\x00", sort @current_group_by)
1517             ne
1518           join ("\x00", sort @{$attrs->{columns}} )
1519         ) {
1520           $self->throw_exception (
1521             "You have just attempted a $op operation on a resultset which does group_by"
1522             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1523             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1524             . ' kind of queries. Please retry the operation with a modified group_by or'
1525             . ' without using one at all.'
1526           );
1527         }
1528       }
1529       else {
1530         $attrs->{group_by} = $attrs->{columns};
1531       }
1532     }
1533
1534     my $subrs = (ref $self)->new($rsrc, $attrs);
1535
1536     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1537   }
1538   else {
1539     return $rsrc->storage->$op(
1540       $rsrc,
1541       $op eq 'update' ? $values : (),
1542       $self->_cond_for_update_delete,
1543     );
1544   }
1545 }
1546
1547
1548 # _cond_for_update_delete
1549 #
1550 # update/delete require the condition to be modified to handle
1551 # the differing SQL syntax available.  This transforms the $self->{cond}
1552 # appropriately, returning the new condition.
1553
1554 sub _cond_for_update_delete {
1555   my ($self, $full_cond) = @_;
1556   my $cond = {};
1557
1558   $full_cond ||= $self->{cond};
1559   # No-op. No condition, we're updating/deleting everything
1560   return $cond unless ref $full_cond;
1561
1562   if (ref $full_cond eq 'ARRAY') {
1563     $cond = [
1564       map {
1565         my %hash;
1566         foreach my $key (keys %{$_}) {
1567           $key =~ /([^.]+)$/;
1568           $hash{$1} = $_->{$key};
1569         }
1570         \%hash;
1571       } @{$full_cond}
1572     ];
1573   }
1574   elsif (ref $full_cond eq 'HASH') {
1575     if ((keys %{$full_cond})[0] eq '-and') {
1576       $cond->{-and} = [];
1577       my @cond = @{$full_cond->{-and}};
1578        for (my $i = 0; $i < @cond; $i++) {
1579         my $entry = $cond[$i];
1580         my $hash;
1581         if (ref $entry eq 'HASH') {
1582           $hash = $self->_cond_for_update_delete($entry);
1583         }
1584         else {
1585           $entry =~ /([^.]+)$/;
1586           $hash->{$1} = $cond[++$i];
1587         }
1588         push @{$cond->{-and}}, $hash;
1589       }
1590     }
1591     else {
1592       foreach my $key (keys %{$full_cond}) {
1593         $key =~ /([^.]+)$/;
1594         $cond->{$1} = $full_cond->{$key};
1595       }
1596     }
1597   }
1598   else {
1599     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1600   }
1601
1602   return $cond;
1603 }
1604
1605
1606 =head2 update
1607
1608 =over 4
1609
1610 =item Arguments: \%values
1611
1612 =item Return Value: $storage_rv
1613
1614 =back
1615
1616 Sets the specified columns in the resultset to the supplied values in a
1617 single query. Return value will be true if the update succeeded or false
1618 if no records were updated; exact type of success value is storage-dependent.
1619
1620 =cut
1621
1622 sub update {
1623   my ($self, $values) = @_;
1624   $self->throw_exception('Values for update must be a hash')
1625     unless ref $values eq 'HASH';
1626
1627   return $self->_rs_update_delete ('update', $values);
1628 }
1629
1630 =head2 update_all
1631
1632 =over 4
1633
1634 =item Arguments: \%values
1635
1636 =item Return Value: 1
1637
1638 =back
1639
1640 Fetches all objects and updates them one at a time. Note that C<update_all>
1641 will run DBIC cascade triggers, while L</update> will not.
1642
1643 =cut
1644
1645 sub update_all {
1646   my ($self, $values) = @_;
1647   $self->throw_exception('Values for update_all must be a hash')
1648     unless ref $values eq 'HASH';
1649   foreach my $obj ($self->all) {
1650     $obj->set_columns($values)->update;
1651   }
1652   return 1;
1653 }
1654
1655 =head2 delete
1656
1657 =over 4
1658
1659 =item Arguments: none
1660
1661 =item Return Value: $storage_rv
1662
1663 =back
1664
1665 Deletes the contents of the resultset from its result source. Note that this
1666 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1667 to run. See also L<DBIx::Class::Row/delete>.
1668
1669 Return value will be the amount of rows deleted; exact type of return value
1670 is storage-dependent.
1671
1672 =cut
1673
1674 sub delete {
1675   my $self = shift;
1676   $self->throw_exception('delete does not accept any arguments')
1677     if @_;
1678
1679   return $self->_rs_update_delete ('delete');
1680 }
1681
1682 =head2 delete_all
1683
1684 =over 4
1685
1686 =item Arguments: none
1687
1688 =item Return Value: 1
1689
1690 =back
1691
1692 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1693 will run DBIC cascade triggers, while L</delete> will not.
1694
1695 =cut
1696
1697 sub delete_all {
1698   my $self = shift;
1699   $self->throw_exception('delete_all does not accept any arguments')
1700     if @_;
1701
1702   $_->delete for $self->all;
1703   return 1;
1704 }
1705
1706 =head2 populate
1707
1708 =over 4
1709
1710 =item Arguments: \@data;
1711
1712 =back
1713
1714 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1715 For the arrayref of hashrefs style each hashref should be a structure suitable
1716 forsubmitting to a $resultset->create(...) method.
1717
1718 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1719 to insert the data, as this is a faster method.
1720
1721 Otherwise, each set of data is inserted into the database using
1722 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1723 accumulated into an array. The array itself, or an array reference
1724 is returned depending on scalar or list context.
1725
1726 Example:  Assuming an Artist Class that has many CDs Classes relating:
1727
1728   my $Artist_rs = $schema->resultset("Artist");
1729
1730   ## Void Context Example
1731   $Artist_rs->populate([
1732      { artistid => 4, name => 'Manufactured Crap', cds => [
1733         { title => 'My First CD', year => 2006 },
1734         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1735       ],
1736      },
1737      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1738         { title => 'My parents sold me to a record company' ,year => 2005 },
1739         { title => 'Why Am I So Ugly?', year => 2006 },
1740         { title => 'I Got Surgery and am now Popular', year => 2007 }
1741       ],
1742      },
1743   ]);
1744
1745   ## Array Context Example
1746   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1747     { name => "Artist One"},
1748     { name => "Artist Two"},
1749     { name => "Artist Three", cds=> [
1750     { title => "First CD", year => 2007},
1751     { title => "Second CD", year => 2008},
1752   ]}
1753   ]);
1754
1755   print $ArtistOne->name; ## response is 'Artist One'
1756   print $ArtistThree->cds->count ## reponse is '2'
1757
1758 For the arrayref of arrayrefs style,  the first element should be a list of the
1759 fieldsnames to which the remaining elements are rows being inserted.  For
1760 example:
1761
1762   $Arstist_rs->populate([
1763     [qw/artistid name/],
1764     [100, 'A Formally Unknown Singer'],
1765     [101, 'A singer that jumped the shark two albums ago'],
1766     [102, 'An actually cool singer.'],
1767   ]);
1768
1769 Please note an important effect on your data when choosing between void and
1770 wantarray context. Since void context goes straight to C<insert_bulk> in
1771 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1772 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1773 create primary keys for you, you will find that your PKs are empty.  In this
1774 case you will have to use the wantarray context in order to create those
1775 values.
1776
1777 =cut
1778
1779 sub populate {
1780   my $self = shift @_;
1781   my $data = ref $_[0][0] eq 'HASH'
1782     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1783     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1784
1785   if(defined wantarray) {
1786     my @created;
1787     foreach my $item (@$data) {
1788       push(@created, $self->create($item));
1789     }
1790     return wantarray ? @created : \@created;
1791   } else {
1792     my ($first, @rest) = @$data;
1793
1794     my @names = grep {!ref $first->{$_}} keys %$first;
1795     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1796     my @pks = $self->result_source->primary_columns;
1797
1798     ## do the belongs_to relationships
1799     foreach my $index (0..$#$data) {
1800
1801       # delegate to create() for any dataset without primary keys with specified relationships
1802       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1803         for my $r (@rels) {
1804           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1805             my @ret = $self->populate($data);
1806             return;
1807           }
1808         }
1809       }
1810
1811       foreach my $rel (@rels) {
1812         next unless ref $data->[$index]->{$rel} eq "HASH";
1813         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1814         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1815         my $related = $result->result_source->_resolve_condition(
1816           $result->result_source->relationship_info($reverse)->{cond},
1817           $self,
1818           $result,
1819         );
1820
1821         delete $data->[$index]->{$rel};
1822         $data->[$index] = {%{$data->[$index]}, %$related};
1823
1824         push @names, keys %$related if $index == 0;
1825       }
1826     }
1827
1828     ## do bulk insert on current row
1829     my @values = map { [ @$_{@names} ] } @$data;
1830
1831     $self->result_source->storage->insert_bulk(
1832       $self->result_source,
1833       \@names,
1834       \@values,
1835     );
1836
1837     ## do the has_many relationships
1838     foreach my $item (@$data) {
1839
1840       foreach my $rel (@rels) {
1841         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1842
1843         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1844      || $self->throw_exception('Cannot find the relating object.');
1845
1846         my $child = $parent->$rel;
1847
1848         my $related = $child->result_source->_resolve_condition(
1849           $parent->result_source->relationship_info($rel)->{cond},
1850           $child,
1851           $parent,
1852         );
1853
1854         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1855         my @populate = map { {%$_, %$related} } @rows_to_add;
1856
1857         $child->populate( \@populate );
1858       }
1859     }
1860   }
1861 }
1862
1863 =head2 _normalize_populate_args ($args)
1864
1865 Private method used by L</populate> to normalize its incoming arguments.  Factored
1866 out in case you want to subclass and accept new argument structures to the
1867 L</populate> method.
1868
1869 =cut
1870
1871 sub _normalize_populate_args {
1872   my ($self, $data) = @_;
1873   my @names = @{shift(@$data)};
1874   my @results_to_create;
1875   foreach my $datum (@$data) {
1876     my %result_to_create;
1877     foreach my $index (0..$#names) {
1878       $result_to_create{$names[$index]} = $$datum[$index];
1879     }
1880     push @results_to_create, \%result_to_create;
1881   }
1882   return \@results_to_create;
1883 }
1884
1885 =head2 pager
1886
1887 =over 4
1888
1889 =item Arguments: none
1890
1891 =item Return Value: $pager
1892
1893 =back
1894
1895 Return Value a L<Data::Page> object for the current resultset. Only makes
1896 sense for queries with a C<page> attribute.
1897
1898 To get the full count of entries for a paged resultset, call
1899 C<total_entries> on the L<Data::Page> object.
1900
1901 =cut
1902
1903 sub pager {
1904   my ($self) = @_;
1905
1906   return $self->{pager} if $self->{pager};
1907
1908   my $attrs = $self->{attrs};
1909   $self->throw_exception("Can't create pager for non-paged rs")
1910     unless $self->{attrs}{page};
1911   $attrs->{rows} ||= 10;
1912
1913   # throw away the paging flags and re-run the count (possibly
1914   # with a subselect) to get the real total count
1915   my $count_attrs = { %$attrs };
1916   delete $count_attrs->{$_} for qw/rows offset page pager/;
1917   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1918
1919   return $self->{pager} = Data::Page->new(
1920     $total_count,
1921     $attrs->{rows},
1922     $self->{attrs}{page}
1923   );
1924 }
1925
1926 =head2 page
1927
1928 =over 4
1929
1930 =item Arguments: $page_number
1931
1932 =item Return Value: $rs
1933
1934 =back
1935
1936 Returns a resultset for the $page_number page of the resultset on which page
1937 is called, where each page contains a number of rows equal to the 'rows'
1938 attribute set on the resultset (10 by default).
1939
1940 =cut
1941
1942 sub page {
1943   my ($self, $page) = @_;
1944   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1945 }
1946
1947 =head2 new_result
1948
1949 =over 4
1950
1951 =item Arguments: \%vals
1952
1953 =item Return Value: $rowobject
1954
1955 =back
1956
1957 Creates a new row object in the resultset's result class and returns
1958 it. The row is not inserted into the database at this point, call
1959 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1960 will tell you whether the row object has been inserted or not.
1961
1962 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1963
1964 =cut
1965
1966 sub new_result {
1967   my ($self, $values) = @_;
1968   $self->throw_exception( "new_result needs a hash" )
1969     unless (ref $values eq 'HASH');
1970
1971   my %new;
1972   my $alias = $self->{attrs}{alias};
1973
1974   if (
1975     defined $self->{cond}
1976     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1977   ) {
1978     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1979     $new{-from_resultset} = [ keys %new ] if keys %new;
1980   } else {
1981     $self->throw_exception(
1982       "Can't abstract implicit construct, condition not a hash"
1983     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1984
1985     my $collapsed_cond = (
1986       $self->{cond}
1987         ? $self->_collapse_cond($self->{cond})
1988         : {}
1989     );
1990
1991     # precendence must be given to passed values over values inherited from
1992     # the cond, so the order here is important.
1993     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1994     while( my($col,$value) = each %implied ){
1995       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1996         $new{$col} = $value->{'='};
1997         next;
1998       }
1999       $new{$col} = $value if $self->_is_deterministic_value($value);
2000     }
2001   }
2002
2003   %new = (
2004     %new,
2005     %{ $self->_remove_alias($values, $alias) },
2006     -source_handle => $self->_source_handle,
2007     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2008   );
2009
2010   return $self->result_class->new(\%new);
2011 }
2012
2013 # _is_deterministic_value
2014 #
2015 # Make an effor to strip non-deterministic values from the condition,
2016 # to make sure new_result chokes less
2017
2018 sub _is_deterministic_value {
2019   my $self = shift;
2020   my $value = shift;
2021   my $ref_type = ref $value;
2022   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2023   return 1 if Scalar::Util::blessed($value);
2024   return 0;
2025 }
2026
2027 # _has_resolved_attr
2028 #
2029 # determines if the resultset defines at least one
2030 # of the attributes supplied
2031 #
2032 # used to determine if a subquery is neccessary
2033 #
2034 # supports some virtual attributes:
2035 #   -join
2036 #     This will scan for any joins being present on the resultset.
2037 #     It is not a mere key-search but a deep inspection of {from}
2038 #
2039
2040 sub _has_resolved_attr {
2041   my ($self, @attr_names) = @_;
2042
2043   my $attrs = $self->_resolved_attrs;
2044
2045   my %extra_checks;
2046
2047   for my $n (@attr_names) {
2048     if (grep { $n eq $_ } (qw/-join/) ) {
2049       $extra_checks{$n}++;
2050       next;
2051     }
2052
2053     my $attr =  $attrs->{$n};
2054
2055     next if not defined $attr;
2056
2057     if (ref $attr eq 'HASH') {
2058       return 1 if keys %$attr;
2059     }
2060     elsif (ref $attr eq 'ARRAY') {
2061       return 1 if @$attr;
2062     }
2063     else {
2064       return 1 if $attr;
2065     }
2066   }
2067
2068   # a resolved join is expressed as a multi-level from
2069   return 1 if (
2070     $extra_checks{-join}
2071       and
2072     ref $attrs->{from} eq 'ARRAY'
2073       and
2074     @{$attrs->{from}} > 1
2075   );
2076
2077   return 0;
2078 }
2079
2080 # _collapse_cond
2081 #
2082 # Recursively collapse the condition.
2083
2084 sub _collapse_cond {
2085   my ($self, $cond, $collapsed) = @_;
2086
2087   $collapsed ||= {};
2088
2089   if (ref $cond eq 'ARRAY') {
2090     foreach my $subcond (@$cond) {
2091       next unless ref $subcond;  # -or
2092       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2093     }
2094   }
2095   elsif (ref $cond eq 'HASH') {
2096     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2097       foreach my $subcond (@{$cond->{-and}}) {
2098         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2099       }
2100     }
2101     else {
2102       foreach my $col (keys %$cond) {
2103         my $value = $cond->{$col};
2104         $collapsed->{$col} = $value;
2105       }
2106     }
2107   }
2108
2109   return $collapsed;
2110 }
2111
2112 # _remove_alias
2113 #
2114 # Remove the specified alias from the specified query hash. A copy is made so
2115 # the original query is not modified.
2116
2117 sub _remove_alias {
2118   my ($self, $query, $alias) = @_;
2119
2120   my %orig = %{ $query || {} };
2121   my %unaliased;
2122
2123   foreach my $key (keys %orig) {
2124     if ($key !~ /\./) {
2125       $unaliased{$key} = $orig{$key};
2126       next;
2127     }
2128     $unaliased{$1} = $orig{$key}
2129       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2130   }
2131
2132   return \%unaliased;
2133 }
2134
2135 =head2 as_query (EXPERIMENTAL)
2136
2137 =over 4
2138
2139 =item Arguments: none
2140
2141 =item Return Value: \[ $sql, @bind ]
2142
2143 =back
2144
2145 Returns the SQL query and bind vars associated with the invocant.
2146
2147 This is generally used as the RHS for a subquery.
2148
2149 B<NOTE>: This feature is still experimental.
2150
2151 =cut
2152
2153 sub as_query {
2154   my $self = shift;
2155
2156   my $attrs = $self->_resolved_attrs_copy;
2157
2158   # For future use:
2159   #
2160   # in list ctx:
2161   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2162   # $sql also has no wrapping parenthesis in list ctx
2163   #
2164   my $sqlbind = $self->result_source->storage
2165     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2166
2167   return $sqlbind;
2168 }
2169
2170 =head2 find_or_new
2171
2172 =over 4
2173
2174 =item Arguments: \%vals, \%attrs?
2175
2176 =item Return Value: $rowobject
2177
2178 =back
2179
2180   my $artist = $schema->resultset('Artist')->find_or_new(
2181     { artist => 'fred' }, { key => 'artists' });
2182
2183   $cd->cd_to_producer->find_or_new({ producer => $producer },
2184                                    { key => 'primary });
2185
2186 Find an existing record from this resultset, based on its primary
2187 key, or a unique constraint. If none exists, instantiate a new result
2188 object and return it. The object will not be saved into your storage
2189 until you call L<DBIx::Class::Row/insert> on it.
2190
2191 You most likely want this method when looking for existing rows using
2192 a unique constraint that is not the primary key, or looking for
2193 related rows.
2194
2195 If you want objects to be saved immediately, use L</find_or_create> instead.
2196
2197 B<Note>: C<find_or_new> is probably not what you want when creating a
2198 new row in a table that uses primary keys supplied by the
2199 database. Passing in a primary key column with a value of I<undef>
2200 will cause L</find> to attempt to search for a row with a value of
2201 I<NULL>.
2202
2203 =cut
2204
2205 sub find_or_new {
2206   my $self     = shift;
2207   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2208   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2209   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2210     return $row;
2211   }
2212   return $self->new_result($hash);
2213 }
2214
2215 =head2 create
2216
2217 =over 4
2218
2219 =item Arguments: \%vals
2220
2221 =item Return Value: a L<DBIx::Class::Row> $object
2222
2223 =back
2224
2225 Attempt to create a single new row or a row with multiple related rows
2226 in the table represented by the resultset (and related tables). This
2227 will not check for duplicate rows before inserting, use
2228 L</find_or_create> to do that.
2229
2230 To create one row for this resultset, pass a hashref of key/value
2231 pairs representing the columns of the table and the values you wish to
2232 store. If the appropriate relationships are set up, foreign key fields
2233 can also be passed an object representing the foreign row, and the
2234 value will be set to its primary key.
2235
2236 To create related objects, pass a hashref of related-object column values
2237 B<keyed on the relationship name>. If the relationship is of type C<multi>
2238 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2239 The process will correctly identify columns holding foreign keys, and will
2240 transparrently populate them from the keys of the corresponding relation.
2241 This can be applied recursively, and will work correctly for a structure
2242 with an arbitrary depth and width, as long as the relationships actually
2243 exists and the correct column data has been supplied.
2244
2245
2246 Instead of hashrefs of plain related data (key/value pairs), you may
2247 also pass new or inserted objects. New objects (not inserted yet, see
2248 L</new>), will be inserted into their appropriate tables.
2249
2250 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2251
2252 Example of creating a new row.
2253
2254   $person_rs->create({
2255     name=>"Some Person",
2256     email=>"somebody@someplace.com"
2257   });
2258
2259 Example of creating a new row and also creating rows in a related C<has_many>
2260 or C<has_one> resultset.  Note Arrayref.
2261
2262   $artist_rs->create(
2263      { artistid => 4, name => 'Manufactured Crap', cds => [
2264         { title => 'My First CD', year => 2006 },
2265         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2266       ],
2267      },
2268   );
2269
2270 Example of creating a new row and also creating a row in a related
2271 C<belongs_to>resultset. Note Hashref.
2272
2273   $cd_rs->create({
2274     title=>"Music for Silly Walks",
2275     year=>2000,
2276     artist => {
2277       name=>"Silly Musician",
2278     }
2279   });
2280
2281 =cut
2282
2283 sub create {
2284   my ($self, $attrs) = @_;
2285   $self->throw_exception( "create needs a hashref" )
2286     unless ref $attrs eq 'HASH';
2287   return $self->new_result($attrs)->insert;
2288 }
2289
2290 =head2 find_or_create
2291
2292 =over 4
2293
2294 =item Arguments: \%vals, \%attrs?
2295
2296 =item Return Value: $rowobject
2297
2298 =back
2299
2300   $cd->cd_to_producer->find_or_create({ producer => $producer },
2301                                       { key => 'primary' });
2302
2303 Tries to find a record based on its primary key or unique constraints; if none
2304 is found, creates one and returns that instead.
2305
2306   my $cd = $schema->resultset('CD')->find_or_create({
2307     cdid   => 5,
2308     artist => 'Massive Attack',
2309     title  => 'Mezzanine',
2310     year   => 2005,
2311   });
2312
2313 Also takes an optional C<key> attribute, to search by a specific key or unique
2314 constraint. For example:
2315
2316   my $cd = $schema->resultset('CD')->find_or_create(
2317     {
2318       artist => 'Massive Attack',
2319       title  => 'Mezzanine',
2320     },
2321     { key => 'cd_artist_title' }
2322   );
2323
2324 B<Note>: Because find_or_create() reads from the database and then
2325 possibly inserts based on the result, this method is subject to a race
2326 condition. Another process could create a record in the table after
2327 the find has completed and before the create has started. To avoid
2328 this problem, use find_or_create() inside a transaction.
2329
2330 B<Note>: C<find_or_create> is probably not what you want when creating
2331 a new row in a table that uses primary keys supplied by the
2332 database. Passing in a primary key column with a value of I<undef>
2333 will cause L</find> to attempt to search for a row with a value of
2334 I<NULL>.
2335
2336 See also L</find> and L</update_or_create>. For information on how to declare
2337 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2338
2339 =cut
2340
2341 sub find_or_create {
2342   my $self     = shift;
2343   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2344   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2345   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2346     return $row;
2347   }
2348   return $self->create($hash);
2349 }
2350
2351 =head2 update_or_create
2352
2353 =over 4
2354
2355 =item Arguments: \%col_values, { key => $unique_constraint }?
2356
2357 =item Return Value: $rowobject
2358
2359 =back
2360
2361   $resultset->update_or_create({ col => $val, ... });
2362
2363 First, searches for an existing row matching one of the unique constraints
2364 (including the primary key) on the source of this resultset. If a row is
2365 found, updates it with the other given column values. Otherwise, creates a new
2366 row.
2367
2368 Takes an optional C<key> attribute to search on a specific unique constraint.
2369 For example:
2370
2371   # In your application
2372   my $cd = $schema->resultset('CD')->update_or_create(
2373     {
2374       artist => 'Massive Attack',
2375       title  => 'Mezzanine',
2376       year   => 1998,
2377     },
2378     { key => 'cd_artist_title' }
2379   );
2380
2381   $cd->cd_to_producer->update_or_create({
2382     producer => $producer,
2383     name => 'harry',
2384   }, {
2385     key => 'primary,
2386   });
2387
2388
2389 If no C<key> is specified, it searches on all unique constraints defined on the
2390 source, including the primary key.
2391
2392 If the C<key> is specified as C<primary>, it searches only on the primary key.
2393
2394 See also L</find> and L</find_or_create>. For information on how to declare
2395 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2396
2397 B<Note>: C<update_or_create> is probably not what you want when
2398 looking for a row in a table that uses primary keys supplied by the
2399 database, unless you actually have a key value. Passing in a primary
2400 key column with a value of I<undef> will cause L</find> to attempt to
2401 search for a row with a value of I<NULL>.
2402
2403 =cut
2404
2405 sub update_or_create {
2406   my $self = shift;
2407   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2408   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2409
2410   my $row = $self->find($cond, $attrs);
2411   if (defined $row) {
2412     $row->update($cond);
2413     return $row;
2414   }
2415
2416   return $self->create($cond);
2417 }
2418
2419 =head2 update_or_new
2420
2421 =over 4
2422
2423 =item Arguments: \%col_values, { key => $unique_constraint }?
2424
2425 =item Return Value: $rowobject
2426
2427 =back
2428
2429   $resultset->update_or_new({ col => $val, ... });
2430
2431 First, searches for an existing row matching one of the unique constraints
2432 (including the primary key) on the source of this resultset. If a row is
2433 found, updates it with the other given column values. Otherwise, instantiate
2434 a new result object and return it. The object will not be saved into your storage
2435 until you call L<DBIx::Class::Row/insert> on it.
2436
2437 Takes an optional C<key> attribute to search on a specific unique constraint.
2438 For example:
2439
2440   # In your application
2441   my $cd = $schema->resultset('CD')->update_or_new(
2442     {
2443       artist => 'Massive Attack',
2444       title  => 'Mezzanine',
2445       year   => 1998,
2446     },
2447     { key => 'cd_artist_title' }
2448   );
2449
2450   if ($cd->in_storage) {
2451       # the cd was updated
2452   }
2453   else {
2454       # the cd is not yet in the database, let's insert it
2455       $cd->insert;
2456   }
2457
2458 See also L</find>, L</find_or_create> and L<find_or_new>.
2459
2460 =cut
2461
2462 sub update_or_new {
2463     my $self  = shift;
2464     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2465     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2466
2467     my $row = $self->find( $cond, $attrs );
2468     if ( defined $row ) {
2469         $row->update($cond);
2470         return $row;
2471     }
2472
2473     return $self->new_result($cond);
2474 }
2475
2476 =head2 get_cache
2477
2478 =over 4
2479
2480 =item Arguments: none
2481
2482 =item Return Value: \@cache_objects?
2483
2484 =back
2485
2486 Gets the contents of the cache for the resultset, if the cache is set.
2487
2488 The cache is populated either by using the L</prefetch> attribute to
2489 L</search> or by calling L</set_cache>.
2490
2491 =cut
2492
2493 sub get_cache {
2494   shift->{all_cache};
2495 }
2496
2497 =head2 set_cache
2498
2499 =over 4
2500
2501 =item Arguments: \@cache_objects
2502
2503 =item Return Value: \@cache_objects
2504
2505 =back
2506
2507 Sets the contents of the cache for the resultset. Expects an arrayref
2508 of objects of the same class as those produced by the resultset. Note that
2509 if the cache is set the resultset will return the cached objects rather
2510 than re-querying the database even if the cache attr is not set.
2511
2512 The contents of the cache can also be populated by using the
2513 L</prefetch> attribute to L</search>.
2514
2515 =cut
2516
2517 sub set_cache {
2518   my ( $self, $data ) = @_;
2519   $self->throw_exception("set_cache requires an arrayref")
2520       if defined($data) && (ref $data ne 'ARRAY');
2521   $self->{all_cache} = $data;
2522 }
2523
2524 =head2 clear_cache
2525
2526 =over 4
2527
2528 =item Arguments: none
2529
2530 =item Return Value: []
2531
2532 =back
2533
2534 Clears the cache for the resultset.
2535
2536 =cut
2537
2538 sub clear_cache {
2539   shift->set_cache(undef);
2540 }
2541
2542 =head2 related_resultset
2543
2544 =over 4
2545
2546 =item Arguments: $relationship_name
2547
2548 =item Return Value: $resultset
2549
2550 =back
2551
2552 Returns a related resultset for the supplied relationship name.
2553
2554   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2555
2556 =cut
2557
2558 sub related_resultset {
2559   my ($self, $rel) = @_;
2560
2561   $self->{related_resultsets} ||= {};
2562   return $self->{related_resultsets}{$rel} ||= do {
2563     my $rel_info = $self->result_source->relationship_info($rel);
2564
2565     $self->throw_exception(
2566       "search_related: result source '" . $self->result_source->source_name .
2567         "' has no such relationship $rel")
2568       unless $rel_info;
2569
2570     my ($from,$seen) = $self->_chain_relationship($rel);
2571
2572     my $join_count = $seen->{$rel};
2573     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2574
2575     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2576     my %attrs = %{$self->{attrs}||{}};
2577     delete @attrs{qw(result_class alias)};
2578
2579     my $new_cache;
2580
2581     if (my $cache = $self->get_cache) {
2582       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2583         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2584                         @$cache ];
2585       }
2586     }
2587
2588     my $rel_source = $self->result_source->related_source($rel);
2589
2590     my $new = do {
2591
2592       # The reason we do this now instead of passing the alias to the
2593       # search_rs below is that if you wrap/overload resultset on the
2594       # source you need to know what alias it's -going- to have for things
2595       # to work sanely (e.g. RestrictWithObject wants to be able to add
2596       # extra query restrictions, and these may need to be $alias.)
2597
2598       my $attrs = $rel_source->resultset_attributes;
2599       local $attrs->{alias} = $alias;
2600
2601       $rel_source->resultset
2602                  ->search_rs(
2603                      undef, {
2604                        %attrs,
2605                        join => undef,
2606                        prefetch => undef,
2607                        select => undef,
2608                        as => undef,
2609                        where => $self->{cond},
2610                        seen_join => $seen,
2611                        from => $from,
2612                    });
2613     };
2614     $new->set_cache($new_cache) if $new_cache;
2615     $new;
2616   };
2617 }
2618
2619 =head2 current_source_alias
2620
2621 =over 4
2622
2623 =item Arguments: none
2624
2625 =item Return Value: $source_alias
2626
2627 =back
2628
2629 Returns the current table alias for the result source this resultset is built
2630 on, that will be used in the SQL query. Usually it is C<me>.
2631
2632 Currently the source alias that refers to the result set returned by a
2633 L</search>/L</find> family method depends on how you got to the resultset: it's
2634 C<me> by default, but eg. L</search_related> aliases it to the related result
2635 source name (and keeps C<me> referring to the original result set). The long
2636 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2637 (and make this method unnecessary).
2638
2639 Thus it's currently necessary to use this method in predefined queries (see
2640 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2641 source alias of the current result set:
2642
2643   # in a result set class
2644   sub modified_by {
2645     my ($self, $user) = @_;
2646
2647     my $me = $self->current_source_alias;
2648
2649     return $self->search(
2650       "$me.modified" => $user->id,
2651     );
2652   }
2653
2654 =cut
2655
2656 sub current_source_alias {
2657   my ($self) = @_;
2658
2659   return ($self->{attrs} || {})->{alias} || 'me';
2660 }
2661
2662 # This code is called by search_related, and makes sure there
2663 # is clear separation between the joins before, during, and
2664 # after the relationship. This information is needed later
2665 # in order to properly resolve prefetch aliases (any alias
2666 # with a relation_chain_depth less than the depth of the
2667 # current prefetch is not considered)
2668 #
2669 # The increments happen in 1/2s to make it easier to correlate the
2670 # join depth with the join path. An integer means a relationship
2671 # specified via a search_related, whereas a fraction means an added
2672 # join/prefetch via attributes
2673 sub _chain_relationship {
2674   my ($self, $rel) = @_;
2675   my $source = $self->result_source;
2676   my $attrs = $self->{attrs};
2677
2678   my $from = [ @{
2679       $attrs->{from}
2680         ||
2681       [{
2682         -source_handle => $source->handle,
2683         -alias => $attrs->{alias},
2684         $attrs->{alias} => $source->from,
2685       }]
2686   }];
2687
2688   my $seen = { %{$attrs->{seen_join} || {} } };
2689   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2690     ? $from->[-1][0]{-join_path}
2691     : [];
2692
2693
2694   # we need to take the prefetch the attrs into account before we
2695   # ->_resolve_join as otherwise they get lost - captainL
2696   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2697
2698   my @requested_joins = $source->_resolve_join(
2699     $merged,
2700     $attrs->{alias},
2701     $seen,
2702     $jpath,
2703   );
2704
2705   push @$from, @requested_joins;
2706
2707   $seen->{-relation_chain_depth} += 0.5;
2708
2709   # if $self already had a join/prefetch specified on it, the requested
2710   # $rel might very well be already included. What we do in this case
2711   # is effectively a no-op (except that we bump up the chain_depth on
2712   # the join in question so we could tell it *is* the search_related)
2713   my $already_joined;
2714
2715
2716   # we consider the last one thus reverse
2717   for my $j (reverse @requested_joins) {
2718     if ($rel eq $j->[0]{-join_path}[-1]) {
2719       $j->[0]{-relation_chain_depth} += 0.5;
2720       $already_joined++;
2721       last;
2722     }
2723   }
2724
2725 # alternative way to scan the entire chain - not backwards compatible
2726 #  for my $j (reverse @$from) {
2727 #    next unless ref $j eq 'ARRAY';
2728 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2729 #      $j->[0]{-relation_chain_depth} += 0.5;
2730 #      $already_joined++;
2731 #      last;
2732 #    }
2733 #  }
2734
2735   unless ($already_joined) {
2736     push @$from, $source->_resolve_join(
2737       $rel,
2738       $attrs->{alias},
2739       $seen,
2740       $jpath,
2741     );
2742   }
2743
2744   $seen->{-relation_chain_depth} += 0.5;
2745
2746   return ($from,$seen);
2747 }
2748
2749 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2750 sub _resolved_attrs_copy {
2751   my $self = shift;
2752   return { %{$self->_resolved_attrs (@_)} };
2753 }
2754
2755 sub _resolved_attrs {
2756   my $self = shift;
2757   return $self->{_attrs} if $self->{_attrs};
2758
2759   my $attrs  = { %{ $self->{attrs} || {} } };
2760   my $source = $self->result_source;
2761   my $alias  = $attrs->{alias};
2762
2763   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2764   my @colbits;
2765
2766   # build columns (as long as select isn't set) into a set of as/select hashes
2767   unless ( $attrs->{select} ) {
2768       @colbits = map {
2769           ( ref($_) eq 'HASH' )
2770               ? $_
2771               : {
2772                   (
2773                     /^\Q${alias}.\E(.+)$/
2774                       ? "$1"
2775                       : "$_"
2776                   )
2777                 =>
2778                   (
2779                     /\./
2780                       ? "$_"
2781                       : "${alias}.$_"
2782                   )
2783             }
2784       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2785   }
2786   # add the additional columns on
2787   foreach ( 'include_columns', '+columns' ) {
2788       push @colbits, map {
2789           ( ref($_) eq 'HASH' )
2790             ? $_
2791             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2792       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2793   }
2794
2795   # start with initial select items
2796   if ( $attrs->{select} ) {
2797     $attrs->{select} =
2798         ( ref $attrs->{select} eq 'ARRAY' )
2799       ? [ @{ $attrs->{select} } ]
2800       : [ $attrs->{select} ];
2801     $attrs->{as} = (
2802       $attrs->{as}
2803       ? (
2804         ref $attrs->{as} eq 'ARRAY'
2805         ? [ @{ $attrs->{as} } ]
2806         : [ $attrs->{as} ]
2807         )
2808       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2809     );
2810   }
2811   else {
2812
2813     # otherwise we intialise select & as to empty
2814     $attrs->{select} = [];
2815     $attrs->{as}     = [];
2816   }
2817
2818   # now add colbits to select/as
2819   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2820   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2821
2822   my $adds;
2823   if ( $adds = delete $attrs->{'+select'} ) {
2824     $adds = [$adds] unless ref $adds eq 'ARRAY';
2825     push(
2826       @{ $attrs->{select} },
2827       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2828     );
2829   }
2830   if ( $adds = delete $attrs->{'+as'} ) {
2831     $adds = [$adds] unless ref $adds eq 'ARRAY';
2832     push( @{ $attrs->{as} }, @$adds );
2833   }
2834
2835   $attrs->{from} ||= [ {
2836     -source_handle => $source->handle,
2837     -alias => $self->{attrs}{alias},
2838     $self->{attrs}{alias} => $source->from,
2839   } ];
2840
2841   if ( $attrs->{join} || $attrs->{prefetch} ) {
2842
2843     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2844       if ref $attrs->{from} ne 'ARRAY';
2845
2846     my $join = delete $attrs->{join} || {};
2847
2848     if ( defined $attrs->{prefetch} ) {
2849       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2850     }
2851
2852     $attrs->{from} =    # have to copy here to avoid corrupting the original
2853       [
2854         @{ $attrs->{from} },
2855         $source->_resolve_join(
2856           $join,
2857           $alias,
2858           { %{ $attrs->{seen_join} || {} } },
2859           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2860             ? $attrs->{from}[-1][0]{-join_path}
2861             : []
2862           ,
2863         )
2864       ];
2865   }
2866
2867   if ( defined $attrs->{order_by} ) {
2868     $attrs->{order_by} = (
2869       ref( $attrs->{order_by} ) eq 'ARRAY'
2870       ? [ @{ $attrs->{order_by} } ]
2871       : [ $attrs->{order_by} || () ]
2872     );
2873   }
2874
2875   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2876     $attrs->{group_by} = [ $attrs->{group_by} ];
2877   }
2878
2879   # generate the distinct induced group_by early, as prefetch will be carried via a
2880   # subquery (since a group_by is present)
2881   if (delete $attrs->{distinct}) {
2882     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2883   }
2884
2885   $attrs->{collapse} ||= {};
2886   if ( my $prefetch = delete $attrs->{prefetch} ) {
2887     $prefetch = $self->_merge_attr( {}, $prefetch );
2888
2889     my $prefetch_ordering = [];
2890
2891     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2892
2893     my @prefetch =
2894       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2895
2896     # we need to somehow mark which columns came from prefetch
2897     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2898
2899     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2900     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2901
2902     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2903     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2904   }
2905
2906   # if both page and offset are specified, produce a combined offset
2907   # even though it doesn't make much sense, this is what pre 081xx has
2908   # been doing
2909   if (my $page = delete $attrs->{page}) {
2910     $attrs->{offset} =
2911       ($attrs->{rows} * ($page - 1))
2912             +
2913       ($attrs->{offset} || 0)
2914     ;
2915   }
2916
2917   return $self->{_attrs} = $attrs;
2918 }
2919
2920 sub _joinpath_aliases {
2921   my ($self, $fromspec, $seen) = @_;
2922
2923   my $paths = {};
2924   return $paths unless ref $fromspec eq 'ARRAY';
2925
2926   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2927
2928   if (int ($cur_depth) != $cur_depth) {
2929     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2930   }
2931
2932   for my $j (@$fromspec) {
2933
2934     next if ref $j ne 'ARRAY';
2935     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2936
2937     my $jpath = $j->[0]{-join_path};
2938
2939     my $p = $paths;
2940     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2941     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2942   }
2943
2944   return $paths;
2945 }
2946
2947 sub _rollout_attr {
2948   my ($self, $attr) = @_;
2949
2950   if (ref $attr eq 'HASH') {
2951     return $self->_rollout_hash($attr);
2952   } elsif (ref $attr eq 'ARRAY') {
2953     return $self->_rollout_array($attr);
2954   } else {
2955     return [$attr];
2956   }
2957 }
2958
2959 sub _rollout_array {
2960   my ($self, $attr) = @_;
2961
2962   my @rolled_array;
2963   foreach my $element (@{$attr}) {
2964     if (ref $element eq 'HASH') {
2965       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2966     } elsif (ref $element eq 'ARRAY') {
2967       #  XXX - should probably recurse here
2968       push( @rolled_array, @{$self->_rollout_array($element)} );
2969     } else {
2970       push( @rolled_array, $element );
2971     }
2972   }
2973   return \@rolled_array;
2974 }
2975
2976 sub _rollout_hash {
2977   my ($self, $attr) = @_;
2978
2979   my @rolled_array;
2980   foreach my $key (keys %{$attr}) {
2981     push( @rolled_array, { $key => $attr->{$key} } );
2982   }
2983   return \@rolled_array;
2984 }
2985
2986 sub _calculate_score {
2987   my ($self, $a, $b) = @_;
2988
2989   if (ref $b eq 'HASH') {
2990     my ($b_key) = keys %{$b};
2991     if (ref $a eq 'HASH') {
2992       my ($a_key) = keys %{$a};
2993       if ($a_key eq $b_key) {
2994         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2995       } else {
2996         return 0;
2997       }
2998     } else {
2999       return ($a eq $b_key) ? 1 : 0;
3000     }
3001   } else {
3002     if (ref $a eq 'HASH') {
3003       my ($a_key) = keys %{$a};
3004       return ($b eq $a_key) ? 1 : 0;
3005     } else {
3006       return ($b eq $a) ? 1 : 0;
3007     }
3008   }
3009 }
3010
3011 sub _merge_attr {
3012   my ($self, $orig, $import) = @_;
3013
3014   return $import unless defined($orig);
3015   return $orig unless defined($import);
3016
3017   $orig = $self->_rollout_attr($orig);
3018   $import = $self->_rollout_attr($import);
3019
3020   my $seen_keys;
3021   foreach my $import_element ( @{$import} ) {
3022     # find best candidate from $orig to merge $b_element into
3023     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3024     foreach my $orig_element ( @{$orig} ) {
3025       my $score = $self->_calculate_score( $orig_element, $import_element );
3026       if ($score > $best_candidate->{score}) {
3027         $best_candidate->{position} = $position;
3028         $best_candidate->{score} = $score;
3029       }
3030       $position++;
3031     }
3032     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3033
3034     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3035       push( @{$orig}, $import_element );
3036     } else {
3037       my $orig_best = $orig->[$best_candidate->{position}];
3038       # merge orig_best and b_element together and replace original with merged
3039       if (ref $orig_best ne 'HASH') {
3040         $orig->[$best_candidate->{position}] = $import_element;
3041       } elsif (ref $import_element eq 'HASH') {
3042         my ($key) = keys %{$orig_best};
3043         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3044       }
3045     }
3046     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3047   }
3048
3049   return $orig;
3050 }
3051
3052 sub result_source {
3053     my $self = shift;
3054
3055     if (@_) {
3056         $self->_source_handle($_[0]->handle);
3057     } else {
3058         $self->_source_handle->resolve;
3059     }
3060 }
3061
3062 =head2 throw_exception
3063
3064 See L<DBIx::Class::Schema/throw_exception> for details.
3065
3066 =cut
3067
3068 sub throw_exception {
3069   my $self=shift;
3070   if (ref $self && $self->_source_handle->schema) {
3071     $self->_source_handle->schema->throw_exception(@_)
3072   } else {
3073     croak(@_);
3074   }
3075
3076 }
3077
3078 # XXX: FIXME: Attributes docs need clearing up
3079
3080 =head1 ATTRIBUTES
3081
3082 Attributes are used to refine a ResultSet in various ways when
3083 searching for data. They can be passed to any method which takes an
3084 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3085 L</count>.
3086
3087 These are in no particular order:
3088
3089 =head2 order_by
3090
3091 =over 4
3092
3093 =item Value: ( $order_by | \@order_by | \%order_by )
3094
3095 =back
3096
3097 Which column(s) to order the results by.
3098
3099 [The full list of suitable values is documented in
3100 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3101 common options.]
3102
3103 If a single column name, or an arrayref of names is supplied, the
3104 argument is passed through directly to SQL. The hashref syntax allows
3105 for connection-agnostic specification of ordering direction:
3106
3107  For descending order:
3108
3109   order_by => { -desc => [qw/col1 col2 col3/] }
3110
3111  For explicit ascending order:
3112
3113   order_by => { -asc => 'col' }
3114
3115 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3116 supported, although you are strongly encouraged to use the hashref
3117 syntax as outlined above.
3118
3119 =head2 columns
3120
3121 =over 4
3122
3123 =item Value: \@columns
3124
3125 =back
3126
3127 Shortcut to request a particular set of columns to be retrieved. Each
3128 column spec may be a string (a table column name), or a hash (in which
3129 case the key is the C<as> value, and the value is used as the C<select>
3130 expression). Adds C<me.> onto the start of any column without a C<.> in
3131 it and sets C<select> from that, then auto-populates C<as> from
3132 C<select> as normal. (You may also use the C<cols> attribute, as in
3133 earlier versions of DBIC.)
3134
3135 =head2 +columns
3136
3137 =over 4
3138
3139 =item Value: \@columns
3140
3141 =back
3142
3143 Indicates additional columns to be selected from storage. Works the same
3144 as L</columns> but adds columns to the selection. (You may also use the
3145 C<include_columns> attribute, as in earlier versions of DBIC). For
3146 example:-
3147
3148   $schema->resultset('CD')->search(undef, {
3149     '+columns' => ['artist.name'],
3150     join => ['artist']
3151   });
3152
3153 would return all CDs and include a 'name' column to the information
3154 passed to object inflation. Note that the 'artist' is the name of the
3155 column (or relationship) accessor, and 'name' is the name of the column
3156 accessor in the related table.
3157
3158 =head2 include_columns
3159
3160 =over 4
3161
3162 =item Value: \@columns
3163
3164 =back
3165
3166 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3167
3168 =head2 select
3169
3170 =over 4
3171
3172 =item Value: \@select_columns
3173
3174 =back
3175
3176 Indicates which columns should be selected from the storage. You can use
3177 column names, or in the case of RDBMS back ends, function or stored procedure
3178 names:
3179
3180   $rs = $schema->resultset('Employee')->search(undef, {
3181     select => [
3182       'name',
3183       { count => 'employeeid' },
3184       { sum => 'salary' }
3185     ]
3186   });
3187
3188 When you use function/stored procedure names and do not supply an C<as>
3189 attribute, the column names returned are storage-dependent. E.g. MySQL would
3190 return a column named C<count(employeeid)> in the above example.
3191
3192 =head2 +select
3193
3194 =over 4
3195
3196 Indicates additional columns to be selected from storage.  Works the same as
3197 L</select> but adds columns to the selection.
3198
3199 =back
3200
3201 =head2 +as
3202
3203 =over 4
3204
3205 Indicates additional column names for those added via L</+select>. See L</as>.
3206
3207 =back
3208
3209 =head2 as
3210
3211 =over 4
3212
3213 =item Value: \@inflation_names
3214
3215 =back
3216
3217 Indicates column names for object inflation. That is, C<as>
3218 indicates the name that the column can be accessed as via the
3219 C<get_column> method (or via the object accessor, B<if one already
3220 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3221
3222 The C<as> attribute is used in conjunction with C<select>,
3223 usually when C<select> contains one or more function or stored
3224 procedure names:
3225
3226   $rs = $schema->resultset('Employee')->search(undef, {
3227     select => [
3228       'name',
3229       { count => 'employeeid' }
3230     ],
3231     as => ['name', 'employee_count'],
3232   });
3233
3234   my $employee = $rs->first(); # get the first Employee
3235
3236 If the object against which the search is performed already has an accessor
3237 matching a column name specified in C<as>, the value can be retrieved using
3238 the accessor as normal:
3239
3240   my $name = $employee->name();
3241
3242 If on the other hand an accessor does not exist in the object, you need to
3243 use C<get_column> instead:
3244
3245   my $employee_count = $employee->get_column('employee_count');
3246
3247 You can create your own accessors if required - see
3248 L<DBIx::Class::Manual::Cookbook> for details.
3249
3250 Please note: This will NOT insert an C<AS employee_count> into the SQL
3251 statement produced, it is used for internal access only. Thus
3252 attempting to use the accessor in an C<order_by> clause or similar
3253 will fail miserably.
3254
3255 To get around this limitation, you can supply literal SQL to your
3256 C<select> attibute that contains the C<AS alias> text, eg:
3257
3258   select => [\'myfield AS alias']
3259
3260 =head2 join
3261
3262 =over 4
3263
3264 =item Value: ($rel_name | \@rel_names | \%rel_names)
3265
3266 =back
3267
3268 Contains a list of relationships that should be joined for this query.  For
3269 example:
3270
3271   # Get CDs by Nine Inch Nails
3272   my $rs = $schema->resultset('CD')->search(
3273     { 'artist.name' => 'Nine Inch Nails' },
3274     { join => 'artist' }
3275   );
3276
3277 Can also contain a hash reference to refer to the other relation's relations.
3278 For example:
3279
3280   package MyApp::Schema::Track;
3281   use base qw/DBIx::Class/;
3282   __PACKAGE__->table('track');
3283   __PACKAGE__->add_columns(qw/trackid cd position title/);
3284   __PACKAGE__->set_primary_key('trackid');
3285   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3286   1;
3287
3288   # In your application
3289   my $rs = $schema->resultset('Artist')->search(
3290     { 'track.title' => 'Teardrop' },
3291     {
3292       join     => { cd => 'track' },
3293       order_by => 'artist.name',
3294     }
3295   );
3296
3297 You need to use the relationship (not the table) name in  conditions,
3298 because they are aliased as such. The current table is aliased as "me", so
3299 you need to use me.column_name in order to avoid ambiguity. For example:
3300
3301   # Get CDs from 1984 with a 'Foo' track
3302   my $rs = $schema->resultset('CD')->search(
3303     {
3304       'me.year' => 1984,
3305       'tracks.name' => 'Foo'
3306     },
3307     { join => 'tracks' }
3308   );
3309
3310 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3311 similarly for a third time). For e.g.
3312
3313   my $rs = $schema->resultset('Artist')->search({
3314     'cds.title'   => 'Down to Earth',
3315     'cds_2.title' => 'Popular',
3316   }, {
3317     join => [ qw/cds cds/ ],
3318   });
3319
3320 will return a set of all artists that have both a cd with title 'Down
3321 to Earth' and a cd with title 'Popular'.
3322
3323 If you want to fetch related objects from other tables as well, see C<prefetch>
3324 below.
3325
3326 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3327
3328 =head2 prefetch
3329
3330 =over 4
3331
3332 =item Value: ($rel_name | \@rel_names | \%rel_names)
3333
3334 =back
3335
3336 Contains one or more relationships that should be fetched along with
3337 the main query (when they are accessed afterwards the data will
3338 already be available, without extra queries to the database).  This is
3339 useful for when you know you will need the related objects, because it
3340 saves at least one query:
3341
3342   my $rs = $schema->resultset('Tag')->search(
3343     undef,
3344     {
3345       prefetch => {
3346         cd => 'artist'
3347       }
3348     }
3349   );
3350
3351 The initial search results in SQL like the following:
3352
3353   SELECT tag.*, cd.*, artist.* FROM tag
3354   JOIN cd ON tag.cd = cd.cdid
3355   JOIN artist ON cd.artist = artist.artistid
3356
3357 L<DBIx::Class> has no need to go back to the database when we access the
3358 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3359 case.
3360
3361 Simple prefetches will be joined automatically, so there is no need
3362 for a C<join> attribute in the above search.
3363
3364 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3365 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3366 with an accessor type of 'single' or 'filter'). A more complex example that
3367 prefetches an artists cds, the tracks on those cds, and the tags associted
3368 with that artist is given below (assuming many-to-many from artists to tags):
3369
3370  my $rs = $schema->resultset('Artist')->search(
3371    undef,
3372    {
3373      prefetch => [
3374        { cds => 'tracks' },
3375        { artist_tags => 'tags' }
3376      ]
3377    }
3378  );
3379
3380
3381 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3382 attributes will be ignored.
3383
3384 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3385 exactly as you might expect.
3386
3387 =over 4
3388
3389 =item *
3390
3391 Prefetch uses the L</cache> to populate the prefetched relationships. This
3392 may or may not be what you want.
3393
3394 =item *
3395
3396 If you specify a condition on a prefetched relationship, ONLY those
3397 rows that match the prefetched condition will be fetched into that relationship.
3398 This means that adding prefetch to a search() B<may alter> what is returned by
3399 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3400
3401   my $artist_rs = $schema->resultset('Artist')->search({
3402       'cds.year' => 2008,
3403   }, {
3404       join => 'cds',
3405   });
3406
3407   my $count = $artist_rs->first->cds->count;
3408
3409   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3410
3411   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3412
3413   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3414
3415 that cmp_ok() may or may not pass depending on the datasets involved. This
3416 behavior may or may not survive the 0.09 transition.
3417
3418 =back
3419
3420 =head2 page
3421
3422 =over 4
3423
3424 =item Value: $page
3425
3426 =back
3427
3428 Makes the resultset paged and specifies the page to retrieve. Effectively
3429 identical to creating a non-pages resultset and then calling ->page($page)
3430 on it.
3431
3432 If L<rows> attribute is not specified it defaults to 10 rows per page.
3433
3434 When you have a paged resultset, L</count> will only return the number
3435 of rows in the page. To get the total, use the L</pager> and call
3436 C<total_entries> on it.
3437
3438 =head2 rows
3439
3440 =over 4
3441
3442 =item Value: $rows
3443
3444 =back
3445
3446 Specifes the maximum number of rows for direct retrieval or the number of
3447 rows per page if the page attribute or method is used.
3448
3449 =head2 offset
3450
3451 =over 4
3452
3453 =item Value: $offset
3454
3455 =back
3456
3457 Specifies the (zero-based) row number for the  first row to be returned, or the
3458 of the first row of the first page if paging is used.
3459
3460 =head2 group_by
3461
3462 =over 4
3463
3464 =item Value: \@columns
3465
3466 =back
3467
3468 A arrayref of columns to group by. Can include columns of joined tables.
3469
3470   group_by => [qw/ column1 column2 ... /]
3471
3472 =head2 having
3473
3474 =over 4
3475
3476 =item Value: $condition
3477
3478 =back
3479
3480 HAVING is a select statement attribute that is applied between GROUP BY and
3481 ORDER BY. It is applied to the after the grouping calculations have been
3482 done.
3483
3484   having => { 'count(employee)' => { '>=', 100 } }
3485
3486 =head2 distinct
3487
3488 =over 4
3489
3490 =item Value: (0 | 1)
3491
3492 =back
3493
3494 Set to 1 to group by all columns.
3495
3496 =head2 where
3497
3498 =over 4
3499
3500 Adds to the WHERE clause.
3501
3502   # only return rows WHERE deleted IS NULL for all searches
3503   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3504
3505 Can be overridden by passing C<{ where => undef }> as an attribute
3506 to a resulset.
3507
3508 =back
3509
3510 =head2 cache
3511
3512 Set to 1 to cache search results. This prevents extra SQL queries if you
3513 revisit rows in your ResultSet:
3514
3515   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3516
3517   while( my $artist = $resultset->next ) {
3518     ... do stuff ...
3519   }
3520
3521   $rs->first; # without cache, this would issue a query
3522
3523 By default, searches are not cached.
3524
3525 For more examples of using these attributes, see
3526 L<DBIx::Class::Manual::Cookbook>.
3527
3528 =head2 from
3529
3530 =over 4
3531
3532 =item Value: \@from_clause
3533
3534 =back
3535
3536 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3537 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3538 clauses.
3539
3540 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3541
3542 C<join> will usually do what you need and it is strongly recommended that you
3543 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3544 And we really do mean "cannot", not just tried and failed. Attempting to use
3545 this because you're having problems with C<join> is like trying to use x86
3546 ASM because you've got a syntax error in your C. Trust us on this.
3547
3548 Now, if you're still really, really sure you need to use this (and if you're
3549 not 100% sure, ask the mailing list first), here's an explanation of how this
3550 works.
3551
3552 The syntax is as follows -
3553
3554   [
3555     { <alias1> => <table1> },
3556     [
3557       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3558       [], # nested JOIN (optional)
3559       { <table1.column1> => <table2.column2>, ... (more conditions) },
3560     ],
3561     # More of the above [ ] may follow for additional joins
3562   ]
3563
3564   <table1> <alias1>
3565   JOIN
3566     <table2> <alias2>
3567     [JOIN ...]
3568   ON <table1.column1> = <table2.column2>
3569   <more joins may follow>
3570
3571 An easy way to follow the examples below is to remember the following:
3572
3573     Anything inside "[]" is a JOIN
3574     Anything inside "{}" is a condition for the enclosing JOIN
3575
3576 The following examples utilize a "person" table in a family tree application.
3577 In order to express parent->child relationships, this table is self-joined:
3578
3579     # Person->belongs_to('father' => 'Person');
3580     # Person->belongs_to('mother' => 'Person');
3581
3582 C<from> can be used to nest joins. Here we return all children with a father,
3583 then search against all mothers of those children:
3584
3585   $rs = $schema->resultset('Person')->search(
3586       undef,
3587       {
3588           alias => 'mother', # alias columns in accordance with "from"
3589           from => [
3590               { mother => 'person' },
3591               [
3592                   [
3593                       { child => 'person' },
3594                       [
3595                           { father => 'person' },
3596                           { 'father.person_id' => 'child.father_id' }
3597                       ]
3598                   ],
3599                   { 'mother.person_id' => 'child.mother_id' }
3600               ],
3601           ]
3602       },
3603   );
3604
3605   # Equivalent SQL:
3606   # SELECT mother.* FROM person mother
3607   # JOIN (
3608   #   person child
3609   #   JOIN person father
3610   #   ON ( father.person_id = child.father_id )
3611   # )
3612   # ON ( mother.person_id = child.mother_id )
3613
3614 The type of any join can be controlled manually. To search against only people
3615 with a father in the person table, we could explicitly use C<INNER JOIN>:
3616
3617     $rs = $schema->resultset('Person')->search(
3618         undef,
3619         {
3620             alias => 'child', # alias columns in accordance with "from"
3621             from => [
3622                 { child => 'person' },
3623                 [
3624                     { father => 'person', -join_type => 'inner' },
3625                     { 'father.id' => 'child.father_id' }
3626                 ],
3627             ]
3628         },
3629     );
3630
3631     # Equivalent SQL:
3632     # SELECT child.* FROM person child
3633     # INNER JOIN person father ON child.father_id = father.id
3634
3635 You can select from a subquery by passing a resultset to from as follows.
3636
3637     $schema->resultset('Artist')->search(
3638         undef,
3639         {   alias => 'artist2',
3640             from  => [ { artist2 => $artist_rs->as_query } ],
3641         } );
3642
3643     # and you'll get sql like this..
3644     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3645     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3646
3647 If you need to express really complex joins, you
3648 can supply literal SQL to C<from> via a scalar reference. In this case
3649 the contents of the scalar will replace the table name associated with the
3650 resultsource.
3651
3652 WARNING: This technique might very well not work as expected on chained
3653 searches - you have been warned.
3654
3655     # Assuming the Event resultsource is defined as:
3656
3657         MySchema::Event->add_columns (
3658             sequence => {
3659                 data_type => 'INT',
3660                 is_auto_increment => 1,
3661             },
3662             location => {
3663                 data_type => 'INT',
3664             },
3665             type => {
3666                 data_type => 'INT',
3667             },
3668         );
3669         MySchema::Event->set_primary_key ('sequence');
3670
3671     # This will get back the latest event for every location. The column
3672     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3673     # combo to limit the resultset
3674
3675     $rs = $schema->resultset('Event');
3676     $table = $rs->result_source->name;
3677     $latest = $rs->search (
3678         undef,
3679         { from => \ "
3680             (SELECT e1.* FROM $table e1
3681                 JOIN $table e2
3682                     ON e1.location = e2.location
3683                     AND e1.sequence < e2.sequence
3684                 WHERE e2.sequence is NULL
3685             ) me",
3686         },
3687     );
3688
3689     # Equivalent SQL (with the DBIC chunks added):
3690
3691     SELECT me.sequence, me.location, me.type FROM
3692        (SELECT e1.* FROM events e1
3693            JOIN events e2
3694                ON e1.location = e2.location
3695                AND e1.sequence < e2.sequence
3696            WHERE e2.sequence is NULL
3697        ) me;
3698
3699 =head2 for
3700
3701 =over 4
3702
3703 =item Value: ( 'update' | 'shared' )
3704
3705 =back
3706
3707 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3708 ... FOR SHARED.
3709
3710 =cut
3711
3712 1;