lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use DBIx::Class::Exception;
   8 use Data::Page;
   9 use Storable;
  10 use DBIx::Class::ResultSetColumn;
  11 use DBIx::Class::ResultSourceHandle;
  12 use Hash::Merge ();
  13 use Scalar::Util qw/blessed weaken/;
  14 use Try::Tiny;
  15 use Storable qw/nfreeze thaw/;
  16
  17 # not importing first() as it will clash with our own method
  18 use List::Util ();
  19
  20 use namespace::clean;
  21
  22
  23 BEGIN {
  24   # De-duplication in _merge_attr() is disabled, but left in for reference
  25   # (the merger is used for other things that ought not to be de-duped)
  26   *__HM_DEDUP = sub () { 0 };
  27 }
  28
  29 use overload
  30         '0+'     => "count",
  31         'bool'   => "_bool",
  32         fallback => 1;
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  35
  36 =head1 NAME
  37
  38 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  39
  40 =head1 SYNOPSIS
  41
  42   my $users_rs   = $schema->resultset('User');
  43   while( $user = $users_rs->next) {
  44     print $user->username;
  45   }
  46
  47   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  48   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  49
  50 =head1 DESCRIPTION
  51
  52 A ResultSet is an object which stores a set of conditions representing
  53 a query. It is the backbone of DBIx::Class (i.e. the really
  54 important/useful bit).
  55
  56 No SQL is executed on the database when a ResultSet is created, it
  57 just stores all the conditions needed to create the query.
  58
  59 A basic ResultSet representing the data of an entire table is returned
  60 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  61 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  62
  63   my $users_rs = $schema->resultset('User');
  64
  65 A new ResultSet is returned from calling L</search> on an existing
  66 ResultSet. The new one will contain all the conditions of the
  67 original, plus any new conditions added in the C<search> call.
  68
  69 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  70 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  71 represents.
  72
  73 The query that the ResultSet represents is B<only> executed against
  74 the database when these methods are called:
  75 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  76
  77 If a resultset is used in a numeric context it returns the L</count>.
  78 However, if it is used in a boolean context it is B<always> true.  So if
  79 you want to check if a resultset has any results, you must use C<if $rs
  80 != 0>.
  81
  82 =head1 EXAMPLES
  83
  84 =head2 Chaining resultsets
  85
  86 Let's say you've got a query that needs to be run to return some data
  87 to the user. But, you have an authorization system in place that
  88 prevents certain users from seeing certain information. So, you want
  89 to construct the basic query in one method, but add constraints to it in
  90 another.
  91
  92   sub get_data {
  93     my $self = shift;
  94     my $request = $self->get_request; # Get a request object somehow.
  95     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  96
  97     my $cd_rs = $schema->resultset('CD')->search({
  98       title => $request->param('title'),
  99       year => $request->param('year'),
 100     });
 101
 102     $self->apply_security_policy( $cd_rs );
 103
 104     return $cd_rs->all();
 105   }
 106
 107   sub apply_security_policy {
 108     my $self = shift;
 109     my ($rs) = @_;
 110
 111     return $rs->search({
 112       subversive => 0,
 113     });
 114   }
 115
 116 =head3 Resolving conditions and attributes
 117
 118 When a resultset is chained from another resultset, conditions and
 119 attributes with the same keys need resolving.
 120
 121 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 122 into the existing ones from the original resultset.
 123
 124 The L</where> and L</having> attributes, and any search conditions, are
 125 merged with an SQL C<AND> to the existing condition from the original
 126 resultset.
 127
 128 All other attributes are overridden by any new ones supplied in the
 129 search attributes.
 130
 131 =head2 Multiple queries
 132
 133 Since a resultset just defines a query, you can do all sorts of
 134 things with it with the same object.
 135
 136   # Don't hit the DB yet.
 137   my $cd_rs = $schema->resultset('CD')->search({
 138     title => 'something',
 139     year => 2009,
 140   });
 141
 142   # Each of these hits the DB individually.
 143   my $count = $cd_rs->count;
 144   my $most_recent = $cd_rs->get_column('date_released')->max();
 145   my @records = $cd_rs->all;
 146
 147 And it's not just limited to SELECT statements.
 148
 149   $cd_rs->delete();
 150
 151 This is even cooler:
 152
 153   $cd_rs->create({ artist => 'Fred' });
 154
 155 Which is the same as:
 156
 157   $schema->resultset('CD')->create({
 158     title => 'something',
 159     year => 2009,
 160     artist => 'Fred'
 161   });
 162
 163 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 164
 165 =head1 METHODS
 166
 167 =head2 new
 168
 169 =over 4
 170
 171 =item Arguments: $source, \%$attrs
 172
 173 =item Return Value: $rs
 174
 175 =back
 176
 177 The resultset constructor. Takes a source object (usually a
 178 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 179 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 180 executed as needed by the other methods.
 181
 182 Generally you won't need to construct a resultset manually.  You'll
 183 automatically get one from e.g. a L</search> called in scalar context:
 184
 185   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 186
 187 IMPORTANT: If called on an object, proxies to new_result instead so
 188
 189   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 190
 191 will return a CD object, not a ResultSet.
 192
 193 =cut
 194
 195 sub new {
 196   my $class = shift;
 197   return $class->new_result(@_) if ref $class;
 198
 199   my ($source, $attrs) = @_;
 200   $source = $source->handle
 201     unless $source->isa('DBIx::Class::ResultSourceHandle');
 202   $attrs = { %{$attrs||{}} };
 203
 204   if ($attrs->{page}) {
 205     $attrs->{rows} ||= 10;
 206   }
 207
 208   $attrs->{alias} ||= 'me';
 209
 210   # Creation of {} and bless separated to mitigate RH perl bug
 211   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 212   my $self = {
 213     _source_handle => $source,
 214     cond => $attrs->{where},
 215     pager => undef,
 216     attrs => $attrs
 217   };
 218
 219   bless $self, $class;
 220
 221   $self->result_class(
 222     $attrs->{result_class} || $source->resolve->result_class
 223   );
 224
 225   return $self;
 226 }
 227
 228 =head2 search
 229
 230 =over 4
 231
 232 =item Arguments: $cond, \%attrs?
 233
 234 =item Return Value: $resultset (scalar context), @row_objs (list context)
 235
 236 =back
 237
 238   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 239   my $new_rs = $cd_rs->search({ year => 2005 });
 240
 241   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 242                  # year = 2005 OR year = 2004
 243
 244 If you need to pass in additional attributes but no additional condition,
 245 call it as C<search(undef, \%attrs)>.
 246
 247   # "SELECT name, artistid FROM $artist_table"
 248   my @all_artists = $schema->resultset('Artist')->search(undef, {
 249     columns => [qw/name artistid/],
 250   });
 251
 252 For a list of attributes that can be passed to C<search>, see
 253 L</ATTRIBUTES>. For more examples of using this function, see
 254 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 255 documentation for the first argument, see L<SQL::Abstract>.
 256
 257 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 258
 259 =head3 CAVEAT
 260
 261 Note that L</search> does not process/deflate any of the values passed in the
 262 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 263 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 264 manually that any value passed to this method will stringify to something the
 265 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 266 objects, for more info see:
 267 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
 268
 269 =cut
 270
 271 sub search {
 272   my $self = shift;
 273   my $rs = $self->search_rs( @_ );
 274
 275   if (wantarray) {
 276     return $rs->all;
 277   }
 278   elsif (defined wantarray) {
 279     return $rs;
 280   }
 281   else {
 282     # we can be called by a relationship helper, which in
 283     # turn may be called in void context due to some braindead
 284     # overload or whatever else the user decided to be clever
 285     # at this particular day. Thus limit the exception to
 286     # external code calls only
 287     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 288       if (caller)[0] !~ /^\QDBIx::Class::/;
 289
 290     return ();
 291   }
 292 }
 293
 294 =head2 search_rs
 295
 296 =over 4
 297
 298 =item Arguments: $cond, \%attrs?
 299
 300 =item Return Value: $resultset
 301
 302 =back
 303
 304 This method does the same exact thing as search() except it will
 305 always return a resultset, even in list context.
 306
 307 =cut
 308
 309 my $callsites_warned;
 310 sub search_rs {
 311   my $self = shift;
 312
 313   # Special-case handling for (undef, undef).
 314   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 315     @_ = ();
 316   }
 317
 318   my $call_attrs = {};
 319   if (@_ > 1) {
 320     if (ref $_[-1] eq 'HASH') {
 321       # copy for _normalize_selection
 322       $call_attrs = { %{ pop @_ } };
 323     }
 324     elsif (! defined $_[-1] ) {
 325       pop @_;   # search({}, undef)
 326     }
 327   }
 328
 329   # see if we can keep the cache (no $rs changes)
 330   my $cache;
 331   my %safe = (alias => 1, cache => 1);
 332   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 333     ! defined $_[0]
 334       or
 335     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 336       or
 337     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 338   )) {
 339     $cache = $self->get_cache;
 340   }
 341
 342   my $rsrc = $self->result_source;
 343
 344   my $old_attrs = { %{$self->{attrs}} };
 345   my $old_having = delete $old_attrs->{having};
 346   my $old_where = delete $old_attrs->{where};
 347
 348   my $new_attrs = { %$old_attrs };
 349
 350   # take care of call attrs (only if anything is changing)
 351   if (keys %$call_attrs) {
 352
 353     $self->throw_exception ('_trailing_select is not a public attribute - do not use it in search()')
 354       if ( exists $call_attrs->{_trailing_select} or exists $call_attrs->{'+_trailing_select'} );
 355
 356     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns _trailing_select +_trailing_select/;
 357
 358     # Normalize the selector list (operates on the passed-in attr structure)
 359     # Need to do it on every chain instead of only once on _resolved_attrs, in
 360     # order to separate 'as'-ed from blind 'select's
 361     $self->_normalize_selection ($call_attrs);
 362
 363     # start with blind overwriting merge, exclude selector attrs
 364     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 365     delete @{$new_attrs}{@selector_attrs};
 366
 367     # reset the current selector list if new selectors are supplied
 368     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 369       delete @{$old_attrs}{@selector_attrs};
 370     }
 371
 372     for (@selector_attrs) {
 373       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 374         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 375     }
 376
 377     # older deprecated name, use only if {columns} is not there
 378     if (my $c = delete $new_attrs->{cols}) {
 379       if ($new_attrs->{columns}) {
 380         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 381       }
 382       else {
 383         $new_attrs->{columns} = $c;
 384       }
 385     }
 386
 387
 388     # join/prefetch use their own crazy merging heuristics
 389     foreach my $key (qw/join prefetch/) {
 390       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 391         if exists $call_attrs->{$key};
 392     }
 393
 394     # stack binds together
 395     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 396   }
 397
 398
 399   # rip apart the rest of @_, parse a condition
 400   my $call_cond = do {
 401
 402     if (ref $_[0] eq 'HASH') {
 403       (keys %{$_[0]}) ? $_[0] : undef
 404     }
 405     elsif (@_ == 1) {
 406       $_[0]
 407     }
 408     elsif (@_ % 2) {
 409       $self->throw_exception('Odd number of arguments to search')
 410     }
 411     else {
 412       +{ @_ }
 413     }
 414
 415   } if @_;
 416
 417   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 418     # determine callsite obeying Carp::Clan rules (fucking ugly but don't have better ideas)
 419     my $callsite = do {
 420       my $w;
 421       local $SIG{__WARN__} = sub { $w = shift };
 422       carp;
 423       $w
 424     };
 425     carp 'search( %condition ) is deprecated, use search( \%condition ) instead'
 426       unless $callsites_warned->{$callsite}++;
 427   }
 428
 429   for ($old_where, $call_cond) {
 430     if (defined $_) {
 431       $new_attrs->{where} = $self->_stack_cond (
 432         $_, $new_attrs->{where}
 433       );
 434     }
 435   }
 436
 437   if (defined $old_having) {
 438     $new_attrs->{having} = $self->_stack_cond (
 439       $old_having, $new_attrs->{having}
 440     )
 441   }
 442
 443   my $rs = (ref $self)->new($rsrc, $new_attrs);
 444
 445   $rs->set_cache($cache) if ($cache);
 446
 447   return $rs;
 448 }
 449
 450 sub _normalize_selection {
 451   my ($self, $attrs) = @_;
 452
 453   # legacy syntax
 454   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 455     if exists $attrs->{include_columns};
 456
 457   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 458   # delay the decision on whether to use a default select list ($rsrc->columns)
 459   # allowing stuff like the remove_columns helper to work
 460   #
 461   # select/as +select/+as pairs need special handling - the amount of select/as
 462   # elements in each pair does *not* have to be equal (think multicolumn
 463   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 464   # supplied at all) - try to infer the alias, either from the -as parameter
 465   # of the selector spec, or use the parameter whole if it looks like a column
 466   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 467   # is ok as well), but transport it over a separate attribute to make sure it is
 468   # the last thing in the select list, thus unable to throw off the corresponding
 469   # 'as' chain
 470   for my $pref ('', '+') {
 471
 472     my ($sel, $as) = map {
 473       my $key = "${pref}${_}";
 474
 475       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 476         ? @{$attrs->{$key}}
 477         : $attrs->{$key} || ()
 478       ];
 479       delete $attrs->{$key};
 480       $val;
 481     } qw/select as/;
 482
 483     if (! @$as and ! @$sel ) {
 484       next;
 485     }
 486     elsif (@$as and ! @$sel) {
 487       $self->throw_exception(
 488         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 489       );
 490     }
 491     elsif( ! @$as ) {
 492       # no as part supplied at all - try to deduce
 493       # if any @$as has been supplied we assume the user knows what (s)he is doing
 494       # and blindly keep stacking up pieces
 495       my (@new_sel, @new_trailing);
 496       for (@$sel) {
 497         if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 498           push @$as, $_->{-as};
 499           push @new_sel, $_;
 500         }
 501         # assume any plain no-space, no-parenthesis string to be a column spec
 502         # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 503         elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 504           push @$as, $_;
 505           push @new_sel, $_;
 506         }
 507         # if all else fails - shove the selection to the trailing stack and move on
 508         else {
 509           push @new_trailing, $_;
 510         }
 511       }
 512
 513       @$sel = @new_sel;
 514       $attrs->{"${pref}_trailing_select"} = $self->_merge_attr($attrs->{"${pref}_trailing_select"}, \@new_trailing)
 515         if @new_trailing;
 516     }
 517     elsif (@$as < @$sel) {
 518       $self->throw_exception(
 519         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 520       );
 521     }
 522
 523     # now see what the result for this pair looks like:
 524     if (@$as == @$sel) {
 525
 526       # if balanced - treat as a columns entry
 527       $attrs->{"${pref}columns"} = $self->_merge_attr(
 528         $attrs->{"${pref}columns"},
 529         { map { $as->[$_] => $sel->[$_] } ( 0 .. $#$as ) }
 530       );
 531     }
 532     else {
 533       # unbalanced - shove in select/as, not subject to deduplication in _resolved_attrs
 534       $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 535       $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 536     }
 537   }
 538
 539 }
 540
 541 sub _stack_cond {
 542   my ($self, $left, $right) = @_;
 543   if (defined $left xor defined $right) {
 544     return defined $left ? $left : $right;
 545   }
 546   elsif (defined $left) {
 547     return { -and => [ map
 548       { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 549       ($left, $right)
 550     ]};
 551   }
 552
 553   return undef;
 554 }
 555
 556 =head2 search_literal
 557
 558 =over 4
 559
 560 =item Arguments: $sql_fragment, @bind_values
 561
 562 =item Return Value: $resultset (scalar context), @row_objs (list context)
 563
 564 =back
 565
 566   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 567   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 568
 569 Pass a literal chunk of SQL to be added to the conditional part of the
 570 resultset query.
 571
 572 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 573 only be used in that context. C<search_literal> is a convenience method.
 574 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 575 columns are bound correctly, use C<search>.
 576
 577 Example of how to use C<search> instead of C<search_literal>
 578
 579   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 580   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 581
 582
 583 See L<DBIx::Class::Manual::Cookbook/Searching> and
 584 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 585 require C<search_literal>.
 586
 587 =cut
 588
 589 sub search_literal {
 590   my ($self, $sql, @bind) = @_;
 591   my $attr;
 592   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 593     $attr = pop @bind;
 594   }
 595   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 596 }
 597
 598 =head2 find
 599
 600 =over 4
 601
 602 =item Arguments: \%columns_values | @pk_values, \%attrs?
 603
 604 =item Return Value: $row_object | undef
 605
 606 =back
 607
 608 Finds and returns a single row based on supplied criteria. Takes either a
 609 hashref with the same format as L</create> (including inference of foreign
 610 keys from related objects), or a list of primary key values in the same
 611 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 612 declaration on the L</result_source>.
 613
 614 In either case an attempt is made to combine conditions already existing on
 615 the resultset with the condition passed to this method.
 616
 617 To aid with preparing the correct query for the storage you may supply the
 618 C<key> attribute, which is the name of a
 619 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 620 unique constraint corresponding to the
 621 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 622 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 623 to construct a query that satisfies the named unique constraint fully (
 624 non-NULL values for each column member of the constraint) an exception is
 625 thrown.
 626
 627 If no C<key> is specified, the search is carried over all unique constraints
 628 which are fully defined by the available condition.
 629
 630 If no such constraint is found, C<find> currently defaults to a simple
 631 C<< search->(\%column_values) >> which may or may not do what you expect.
 632 Note that this fallback behavior may be deprecated in further versions. If
 633 you need to search with arbitrary conditions - use L</search>. If the query
 634 resulting from this fallback produces more than one row, a warning to the
 635 effect is issued, though only the first row is constructed and returned as
 636 C<$row_object>.
 637
 638 In addition to C<key>, L</find> recognizes and applies standard
 639 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 640
 641 Note that if you have extra concerns about the correctness of the resulting
 642 query you need to specify the C<key> attribute and supply the entire condition
 643 as an argument to find (since it is not always possible to perform the
 644 combination of the resultset condition with the supplied one, especially if
 645 the resultset condition contains literal sql).
 646
 647 For example, to find a row by its primary key:
 648
 649   my $cd = $schema->resultset('CD')->find(5);
 650
 651 You can also find a row by a specific unique constraint:
 652
 653   my $cd = $schema->resultset('CD')->find(
 654     {
 655       artist => 'Massive Attack',
 656       title  => 'Mezzanine',
 657     },
 658     { key => 'cd_artist_title' }
 659   );
 660
 661 See also L</find_or_create> and L</update_or_create>.
 662
 663 =cut
 664
 665 sub find {
 666   my $self = shift;
 667   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 668
 669   my $rsrc = $self->result_source;
 670
 671   # Parse out the condition from input
 672   my $call_cond;
 673   if (ref $_[0] eq 'HASH') {
 674     $call_cond = { %{$_[0]} };
 675   }
 676   else {
 677     my $constraint = exists $attrs->{key} ? $attrs->{key} : 'primary';
 678     my @c_cols = $rsrc->unique_constraint_columns($constraint);
 679
 680     $self->throw_exception(
 681       "No constraint columns, maybe a malformed '$constraint' constraint?"
 682     ) unless @c_cols;
 683
 684     $self->throw_exception (
 685       'find() expects either a column/value hashref, or a list of values '
 686     . "corresponding to the columns of the specified unique constraint '$constraint'"
 687     ) unless @c_cols == @_;
 688
 689     $call_cond = {};
 690     @{$call_cond}{@c_cols} = @_;
 691   }
 692
 693   my %related;
 694   for my $key (keys %$call_cond) {
 695     if (
 696       my $keyref = ref($call_cond->{$key})
 697         and
 698       my $relinfo = $rsrc->relationship_info($key)
 699     ) {
 700       my $val = delete $call_cond->{$key};
 701
 702       next if $keyref eq 'ARRAY'; # has_many for multi_create
 703
 704       my $rel_q = $rsrc->_resolve_condition(
 705         $relinfo->{cond}, $val, $key
 706       );
 707       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 708       @related{keys %$rel_q} = values %$rel_q;
 709     }
 710   }
 711
 712   # relationship conditions take precedence (?)
 713   @{$call_cond}{keys %related} = values %related;
 714
 715   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 716   my $final_cond;
 717   if (exists $attrs->{key}) {
 718     $final_cond = $self->_qualify_cond_columns (
 719
 720       $self->_build_unique_cond (
 721         $attrs->{key},
 722         $call_cond,
 723       ),
 724
 725       $alias,
 726     );
 727   }
 728   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 729     # This means that we got here after a merger of relationship conditions
 730     # in ::Relationship::Base::search_related (the row method), and furthermore
 731     # the relationship is of the 'single' type. This means that the condition
 732     # provided by the relationship (already attached to $self) is sufficient,
 733     # as there can be only one row in the database that would satisfy the
 734     # relationship
 735   }
 736   else {
 737     # no key was specified - fall down to heuristics mode:
 738     # run through all unique queries registered on the resultset, and
 739     # 'OR' all qualifying queries together
 740     my (@unique_queries, %seen_column_combinations);
 741     for my $c_name ($rsrc->unique_constraint_names) {
 742       next if $seen_column_combinations{
 743         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 744       }++;
 745
 746       push @unique_queries, try {
 747         $self->_build_unique_cond ($c_name, $call_cond)
 748       } || ();
 749     }
 750
 751     $final_cond = @unique_queries
 752       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 753       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 754     ;
 755   }
 756
 757   # Run the query, passing the result_class since it should propagate for find
 758   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 759   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 760     my $row = $rs->next;
 761     carp "Query returned more than one row" if $rs->next;
 762     return $row;
 763   }
 764   else {
 765     return $rs->single;
 766   }
 767 }
 768
 769 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 770 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 771 #
 772 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 773 # condition. It is provided for overrides until a saner way forward is devised
 774 #
 775 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 776 # the road. Please adjust your tests accordingly to catch this situation early
 777 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 778 #
 779 # The method will not be removed without an adequately complete replacement
 780 # for strict-mode enforcement
 781 sub _non_unique_find_fallback {
 782   my ($self, $cond, $attrs) = @_;
 783
 784   return $self->_qualify_cond_columns(
 785     $cond,
 786     exists $attrs->{alias}
 787       ? $attrs->{alias}
 788       : $self->{attrs}{alias}
 789   );
 790 }
 791
 792
 793 sub _qualify_cond_columns {
 794   my ($self, $cond, $alias) = @_;
 795
 796   my %aliased = %$cond;
 797   for (keys %aliased) {
 798     $aliased{"$alias.$_"} = delete $aliased{$_}
 799       if $_ !~ /\./;
 800   }
 801
 802   return \%aliased;
 803 }
 804
 805 sub _build_unique_cond {
 806   my ($self, $constraint_name, $extra_cond) = @_;
 807
 808   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 809
 810   # combination may fail if $self->{cond} is non-trivial
 811   my ($final_cond) = try {
 812     $self->_merge_with_rscond ($extra_cond)
 813   } catch {
 814     +{ %$extra_cond }
 815   };
 816
 817   # trim out everything not in $columns
 818   $final_cond = { map { $_ => $final_cond->{$_} } @c_cols };
 819
 820   if (my @missing = grep { ! defined $final_cond->{$_} } (@c_cols) ) {
 821     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 822       $constraint_name,
 823       join (', ', map { "'$_'" } @missing),
 824     ) );
 825   }
 826
 827   return $final_cond;
 828 }
 829
 830 =head2 search_related
 831
 832 =over 4
 833
 834 =item Arguments: $rel, $cond, \%attrs?
 835
 836 =item Return Value: $new_resultset
 837
 838 =back
 839
 840   $new_rs = $cd_rs->search_related('artist', {
 841     name => 'Emo-R-Us',
 842   });
 843
 844 Searches the specified relationship, optionally specifying a condition and
 845 attributes for matching records. See L</ATTRIBUTES> for more information.
 846
 847 =cut
 848
 849 sub search_related {
 850   return shift->related_resultset(shift)->search(@_);
 851 }
 852
 853 =head2 search_related_rs
 854
 855 This method works exactly the same as search_related, except that
 856 it guarantees a resultset, even in list context.
 857
 858 =cut
 859
 860 sub search_related_rs {
 861   return shift->related_resultset(shift)->search_rs(@_);
 862 }
 863
 864 =head2 cursor
 865
 866 =over 4
 867
 868 =item Arguments: none
 869
 870 =item Return Value: $cursor
 871
 872 =back
 873
 874 Returns a storage-driven cursor to the given resultset. See
 875 L<DBIx::Class::Cursor> for more information.
 876
 877 =cut
 878
 879 sub cursor {
 880   my ($self) = @_;
 881
 882   my $attrs = $self->_resolved_attrs_copy;
 883
 884   return $self->{cursor}
 885     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 886           $attrs->{where},$attrs);
 887 }
 888
 889 =head2 single
 890
 891 =over 4
 892
 893 =item Arguments: $cond?
 894
 895 =item Return Value: $row_object | undef
 896
 897 =back
 898
 899   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 900
 901 Inflates the first result without creating a cursor if the resultset has
 902 any records in it; if not returns C<undef>. Used by L</find> as a lean version
 903 of L</search>.
 904
 905 While this method can take an optional search condition (just like L</search>)
 906 being a fast-code-path it does not recognize search attributes. If you need to
 907 add extra joins or similar, call L</search> and then chain-call L</single> on the
 908 L<DBIx::Class::ResultSet> returned.
 909
 910 =over
 911
 912 =item B<Note>
 913
 914 As of 0.08100, this method enforces the assumption that the preceding
 915 query returns only one row. If more than one row is returned, you will receive
 916 a warning:
 917
 918   Query returned more than one row
 919
 920 In this case, you should be using L</next> or L</find> instead, or if you really
 921 know what you are doing, use the L</rows> attribute to explicitly limit the size
 922 of the resultset.
 923
 924 This method will also throw an exception if it is called on a resultset prefetching
 925 has_many, as such a prefetch implies fetching multiple rows from the database in
 926 order to assemble the resulting object.
 927
 928 =back
 929
 930 =cut
 931
 932 sub single {
 933   my ($self, $where) = @_;
 934   if(@_ > 2) {
 935       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 936   }
 937
 938   my $attrs = $self->_resolved_attrs_copy;
 939
 940   if (keys %{$attrs->{collapse}}) {
 941     $self->throw_exception(
 942       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 943     );
 944   }
 945
 946   if ($where) {
 947     if (defined $attrs->{where}) {
 948       $attrs->{where} = {
 949         '-and' =>
 950             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 951                $where, delete $attrs->{where} ]
 952       };
 953     } else {
 954       $attrs->{where} = $where;
 955     }
 956   }
 957
 958   my @data = $self->result_source->storage->select_single(
 959     $attrs->{from}, $attrs->{select},
 960     $attrs->{where}, $attrs
 961   );
 962
 963   return (@data ? ($self->_construct_object(@data))[0] : undef);
 964 }
 965
 966
 967 # _collapse_query
 968 #
 969 # Recursively collapse the query, accumulating values for each column.
 970
 971 sub _collapse_query {
 972   my ($self, $query, $collapsed) = @_;
 973
 974   $collapsed ||= {};
 975
 976   if (ref $query eq 'ARRAY') {
 977     foreach my $subquery (@$query) {
 978       next unless ref $subquery;  # -or
 979       $collapsed = $self->_collapse_query($subquery, $collapsed);
 980     }
 981   }
 982   elsif (ref $query eq 'HASH') {
 983     if (keys %$query and (keys %$query)[0] eq '-and') {
 984       foreach my $subquery (@{$query->{-and}}) {
 985         $collapsed = $self->_collapse_query($subquery, $collapsed);
 986       }
 987     }
 988     else {
 989       foreach my $col (keys %$query) {
 990         my $value = $query->{$col};
 991         $collapsed->{$col}{$value}++;
 992       }
 993     }
 994   }
 995
 996   return $collapsed;
 997 }
 998
 999 =head2 get_column
1000
1001 =over 4
1002
1003 =item Arguments: $cond?
1004
1005 =item Return Value: $resultsetcolumn
1006
1007 =back
1008
1009   my $max_length = $rs->get_column('length')->max;
1010
1011 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1012
1013 =cut
1014
1015 sub get_column {
1016   my ($self, $column) = @_;
1017   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1018   return $new;
1019 }
1020
1021 =head2 search_like
1022
1023 =over 4
1024
1025 =item Arguments: $cond, \%attrs?
1026
1027 =item Return Value: $resultset (scalar context), @row_objs (list context)
1028
1029 =back
1030
1031   # WHERE title LIKE '%blue%'
1032   $cd_rs = $rs->search_like({ title => '%blue%'});
1033
1034 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1035 that this is simply a convenience method retained for ex Class::DBI users.
1036 You most likely want to use L</search> with specific operators.
1037
1038 For more information, see L<DBIx::Class::Manual::Cookbook>.
1039
1040 This method is deprecated and will be removed in 0.09. Use L</search()>
1041 instead. An example conversion is:
1042
1043   ->search_like({ foo => 'bar' });
1044
1045   # Becomes
1046
1047   ->search({ foo => { like => 'bar' } });
1048
1049 =cut
1050
1051 sub search_like {
1052   my $class = shift;
1053   carp (
1054     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1055    .' Instead use ->search({ x => { -like => "y%" } })'
1056    .' (note the outer pair of {}s - they are important!)'
1057   );
1058   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1059   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1060   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1061   return $class->search($query, { %$attrs });
1062 }
1063
1064 =head2 slice
1065
1066 =over 4
1067
1068 =item Arguments: $first, $last
1069
1070 =item Return Value: $resultset (scalar context), @row_objs (list context)
1071
1072 =back
1073
1074 Returns a resultset or object list representing a subset of elements from the
1075 resultset slice is called on. Indexes are from 0, i.e., to get the first
1076 three records, call:
1077
1078   my ($one, $two, $three) = $rs->slice(0, 2);
1079
1080 =cut
1081
1082 sub slice {
1083   my ($self, $min, $max) = @_;
1084   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1085   $attrs->{offset} = $self->{attrs}{offset} || 0;
1086   $attrs->{offset} += $min;
1087   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1088   return $self->search(undef, $attrs);
1089   #my $slice = (ref $self)->new($self->result_source, $attrs);
1090   #return (wantarray ? $slice->all : $slice);
1091 }
1092
1093 =head2 next
1094
1095 =over 4
1096
1097 =item Arguments: none
1098
1099 =item Return Value: $result | undef
1100
1101 =back
1102
1103 Returns the next element in the resultset (C<undef> is there is none).
1104
1105 Can be used to efficiently iterate over records in the resultset:
1106
1107   my $rs = $schema->resultset('CD')->search;
1108   while (my $cd = $rs->next) {
1109     print $cd->title;
1110   }
1111
1112 Note that you need to store the resultset object, and call C<next> on it.
1113 Calling C<< resultset('Table')->next >> repeatedly will always return the
1114 first record from the resultset.
1115
1116 =cut
1117
1118 sub next {
1119   my ($self) = @_;
1120   if (my $cache = $self->get_cache) {
1121     $self->{all_cache_position} ||= 0;
1122     return $cache->[$self->{all_cache_position}++];
1123   }
1124   if ($self->{attrs}{cache}) {
1125     delete $self->{pager};
1126     $self->{all_cache_position} = 1;
1127     return ($self->all)[0];
1128   }
1129   if ($self->{stashed_objects}) {
1130     my $obj = shift(@{$self->{stashed_objects}});
1131     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1132     return $obj;
1133   }
1134   my @row = (
1135     exists $self->{stashed_row}
1136       ? @{delete $self->{stashed_row}}
1137       : $self->cursor->next
1138   );
1139   return undef unless (@row);
1140   my ($row, @more) = $self->_construct_object(@row);
1141   $self->{stashed_objects} = \@more if @more;
1142   return $row;
1143 }
1144
1145 sub _construct_object {
1146   my ($self, @row) = @_;
1147
1148   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1149     or return ();
1150   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1151   @new = $self->{_attrs}{record_filter}->(@new)
1152     if exists $self->{_attrs}{record_filter};
1153   return @new;
1154 }
1155
1156 sub _collapse_result {
1157   my ($self, $as_proto, $row) = @_;
1158
1159   my @copy = @$row;
1160
1161   # 'foo'         => [ undef, 'foo' ]
1162   # 'foo.bar'     => [ 'foo', 'bar' ]
1163   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1164
1165   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1166
1167   my %collapse = %{$self->{_attrs}{collapse}||{}};
1168
1169   my @pri_index;
1170
1171   # if we're doing collapsing (has_many prefetch) we need to grab records
1172   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1173   # we know we don't have to bother.
1174
1175   # the reason for not using the collapse stuff directly is because if you
1176   # had for e.g. two artists in a row with no cds, the collapse info for
1177   # both would be NULL (undef) so you'd lose the second artist
1178
1179   # store just the index so we can check the array positions from the row
1180   # without having to contruct the full hash
1181
1182   if (keys %collapse) {
1183     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1184     foreach my $i (0 .. $#construct_as) {
1185       next if defined($construct_as[$i][0]); # only self table
1186       if (delete $pri{$construct_as[$i][1]}) {
1187         push(@pri_index, $i);
1188       }
1189       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1190     }
1191   }
1192
1193   # no need to do an if, it'll be empty if @pri_index is empty anyway
1194
1195   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1196
1197   my @const_rows;
1198
1199   do { # no need to check anything at the front, we always want the first row
1200
1201     my %const;
1202
1203     foreach my $this_as (@construct_as) {
1204       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1205     }
1206
1207     push(@const_rows, \%const);
1208
1209   } until ( # no pri_index => no collapse => drop straight out
1210       !@pri_index
1211     or
1212       do { # get another row, stash it, drop out if different PK
1213
1214         @copy = $self->cursor->next;
1215         $self->{stashed_row} = \@copy;
1216
1217         # last thing in do block, counts as true if anything doesn't match
1218
1219         # check xor defined first for NULL vs. NOT NULL then if one is
1220         # defined the other must be so check string equality
1221
1222         grep {
1223           (defined $pri_vals{$_} ^ defined $copy[$_])
1224           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1225         } @pri_index;
1226       }
1227   );
1228
1229   my $alias = $self->{attrs}{alias};
1230   my $info = [];
1231
1232   my %collapse_pos;
1233
1234   my @const_keys;
1235
1236   foreach my $const (@const_rows) {
1237     scalar @const_keys or do {
1238       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1239     };
1240     foreach my $key (@const_keys) {
1241       if (length $key) {
1242         my $target = $info;
1243         my @parts = split(/\./, $key);
1244         my $cur = '';
1245         my $data = $const->{$key};
1246         foreach my $p (@parts) {
1247           $target = $target->[1]->{$p} ||= [];
1248           $cur .= ".${p}";
1249           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1250             # collapsing at this point and on final part
1251             my $pos = $collapse_pos{$cur};
1252             CK: foreach my $ck (@ckey) {
1253               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1254                 $collapse_pos{$cur} = $data;
1255                 delete @collapse_pos{ # clear all positioning for sub-entries
1256                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1257                 };
1258                 push(@$target, []);
1259                 last CK;
1260               }
1261             }
1262           }
1263           if (exists $collapse{$cur}) {
1264             $target = $target->[-1];
1265           }
1266         }
1267         $target->[0] = $data;
1268       } else {
1269         $info->[0] = $const->{$key};
1270       }
1271     }
1272   }
1273
1274   return $info;
1275 }
1276
1277 =head2 result_source
1278
1279 =over 4
1280
1281 =item Arguments: $result_source?
1282
1283 =item Return Value: $result_source
1284
1285 =back
1286
1287 An accessor for the primary ResultSource object from which this ResultSet
1288 is derived.
1289
1290 =head2 result_class
1291
1292 =over 4
1293
1294 =item Arguments: $result_class?
1295
1296 =item Return Value: $result_class
1297
1298 =back
1299
1300 An accessor for the class to use when creating row objects. Defaults to
1301 C<< result_source->result_class >> - which in most cases is the name of the
1302 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1303
1304 Note that changing the result_class will also remove any components
1305 that were originally loaded in the source class via
1306 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1307 in the original source class will not run.
1308
1309 =cut
1310
1311 sub result_class {
1312   my ($self, $result_class) = @_;
1313   if ($result_class) {
1314     unless (ref $result_class) { # don't fire this for an object
1315       $self->ensure_class_loaded($result_class);
1316     }
1317     $self->_result_class($result_class);
1318     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1319     # permit the user to set result class on one result set only; it only
1320     # chains if provided to search()
1321     #$self->{attrs}{result_class} = $result_class if ref $self;
1322   }
1323   $self->_result_class;
1324 }
1325
1326 =head2 count
1327
1328 =over 4
1329
1330 =item Arguments: $cond, \%attrs??
1331
1332 =item Return Value: $count
1333
1334 =back
1335
1336 Performs an SQL C<COUNT> with the same query as the resultset was built
1337 with to find the number of elements. Passing arguments is equivalent to
1338 C<< $rs->search ($cond, \%attrs)->count >>
1339
1340 =cut
1341
1342 sub count {
1343   my $self = shift;
1344   return $self->search(@_)->count if @_ and defined $_[0];
1345   return scalar @{ $self->get_cache } if $self->get_cache;
1346
1347   my $attrs = $self->_resolved_attrs_copy;
1348
1349   # this is a little optimization - it is faster to do the limit
1350   # adjustments in software, instead of a subquery
1351   my $rows = delete $attrs->{rows};
1352   my $offset = delete $attrs->{offset};
1353
1354   my $crs;
1355   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1356     $crs = $self->_count_subq_rs ($attrs);
1357   }
1358   else {
1359     $crs = $self->_count_rs ($attrs);
1360   }
1361   my $count = $crs->next;
1362
1363   $count -= $offset if $offset;
1364   $count = $rows if $rows and $rows < $count;
1365   $count = 0 if ($count < 0);
1366
1367   return $count;
1368 }
1369
1370 =head2 count_rs
1371
1372 =over 4
1373
1374 =item Arguments: $cond, \%attrs??
1375
1376 =item Return Value: $count_rs
1377
1378 =back
1379
1380 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1381 This can be very handy for subqueries:
1382
1383   ->search( { amount => $some_rs->count_rs->as_query } )
1384
1385 As with regular resultsets the SQL query will be executed only after
1386 the resultset is accessed via L</next> or L</all>. That would return
1387 the same single value obtainable via L</count>.
1388
1389 =cut
1390
1391 sub count_rs {
1392   my $self = shift;
1393   return $self->search(@_)->count_rs if @_;
1394
1395   # this may look like a lack of abstraction (count() does about the same)
1396   # but in fact an _rs *must* use a subquery for the limits, as the
1397   # software based limiting can not be ported if this $rs is to be used
1398   # in a subquery itself (i.e. ->as_query)
1399   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1400     return $self->_count_subq_rs;
1401   }
1402   else {
1403     return $self->_count_rs;
1404   }
1405 }
1406
1407 #
1408 # returns a ResultSetColumn object tied to the count query
1409 #
1410 sub _count_rs {
1411   my ($self, $attrs) = @_;
1412
1413   my $rsrc = $self->result_source;
1414   $attrs ||= $self->_resolved_attrs;
1415
1416   my $tmp_attrs = { %$attrs };
1417   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1418   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1419
1420   # overwrite the selector (supplied by the storage)
1421   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1422   $tmp_attrs->{as} = 'count';
1423   delete @{$tmp_attrs}{qw/columns _trailing_select/};
1424
1425   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1426
1427   return $tmp_rs;
1428 }
1429
1430 #
1431 # same as above but uses a subquery
1432 #
1433 sub _count_subq_rs {
1434   my ($self, $attrs) = @_;
1435
1436   my $rsrc = $self->result_source;
1437   $attrs ||= $self->_resolved_attrs;
1438
1439   my $sub_attrs = { %$attrs };
1440   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1441   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range _trailing_select order_by for/};
1442
1443   # if we multi-prefetch we group_by primary keys only as this is what we would
1444   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1445   if ( keys %{$attrs->{collapse}}  ) {
1446     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1447   }
1448
1449   # Calculate subquery selector
1450   if (my $g = $sub_attrs->{group_by}) {
1451
1452     my $sql_maker = $rsrc->storage->sql_maker;
1453
1454     # necessary as the group_by may refer to aliased functions
1455     my $sel_index;
1456     for my $sel (@{$attrs->{select}}) {
1457       $sel_index->{$sel->{-as}} = $sel
1458         if (ref $sel eq 'HASH' and $sel->{-as});
1459     }
1460
1461     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1462     # also look for named aggregates referred in the having clause
1463     # having often contains scalarrefs - thus parse it out entirely
1464     my @parts = @$g;
1465     if ($attrs->{having}) {
1466       local $sql_maker->{having_bind};
1467       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1468       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1469       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1470         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1471         # if we don't unset it we screw up retarded but unfortunately working
1472         # 'MAX(foo.bar)' => { '>', 3 }
1473         $sql_maker->{name_sep} = '';
1474       }
1475
1476       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1477
1478       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1479
1480       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1481       # and if all fails for an utterly naive quoted scalar-with-function
1482       while ($sql =~ /
1483         $rquote $sep $lquote (.+?) $rquote
1484           |
1485         [\s,] \w+ \. (\w+) [\s,]
1486           |
1487         [\s,] $lquote (.+?) $rquote [\s,]
1488       /gx) {
1489         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1490       }
1491     }
1492
1493     for (@parts) {
1494       my $colpiece = $sel_index->{$_} || $_;
1495
1496       # unqualify join-based group_by's. Arcane but possible query
1497       # also horrible horrible hack to alias a column (not a func.)
1498       # (probably need to introduce SQLA syntax)
1499       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1500         my $as = $colpiece;
1501         $as =~ s/\./__/;
1502         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1503       }
1504       push @{$sub_attrs->{select}}, $colpiece;
1505     }
1506   }
1507   else {
1508     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1509     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1510   }
1511
1512   return $rsrc->resultset_class
1513                ->new ($rsrc, $sub_attrs)
1514                 ->as_subselect_rs
1515                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1516                   ->get_column ('count');
1517 }
1518
1519 sub _bool {
1520   return 1;
1521 }
1522
1523 =head2 count_literal
1524
1525 =over 4
1526
1527 =item Arguments: $sql_fragment, @bind_values
1528
1529 =item Return Value: $count
1530
1531 =back
1532
1533 Counts the results in a literal query. Equivalent to calling L</search_literal>
1534 with the passed arguments, then L</count>.
1535
1536 =cut
1537
1538 sub count_literal { shift->search_literal(@_)->count; }
1539
1540 =head2 all
1541
1542 =over 4
1543
1544 =item Arguments: none
1545
1546 =item Return Value: @objects
1547
1548 =back
1549
1550 Returns all elements in the resultset. Called implicitly if the resultset
1551 is returned in list context.
1552
1553 =cut
1554
1555 sub all {
1556   my $self = shift;
1557   if(@_) {
1558       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1559   }
1560
1561   return @{ $self->get_cache } if $self->get_cache;
1562
1563   my @obj;
1564
1565   if (keys %{$self->_resolved_attrs->{collapse}}) {
1566     # Using $self->cursor->all is really just an optimisation.
1567     # If we're collapsing has_many prefetches it probably makes
1568     # very little difference, and this is cleaner than hacking
1569     # _construct_object to survive the approach
1570     $self->cursor->reset;
1571     my @row = $self->cursor->next;
1572     while (@row) {
1573       push(@obj, $self->_construct_object(@row));
1574       @row = (exists $self->{stashed_row}
1575                ? @{delete $self->{stashed_row}}
1576                : $self->cursor->next);
1577     }
1578   } else {
1579     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1580   }
1581
1582   $self->set_cache(\@obj) if $self->{attrs}{cache};
1583
1584   return @obj;
1585 }
1586
1587 =head2 reset
1588
1589 =over 4
1590
1591 =item Arguments: none
1592
1593 =item Return Value: $self
1594
1595 =back
1596
1597 Resets the resultset's cursor, so you can iterate through the elements again.
1598 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1599 another query.
1600
1601 =cut
1602
1603 sub reset {
1604   my ($self) = @_;
1605   delete $self->{_attrs} if exists $self->{_attrs};
1606   $self->{all_cache_position} = 0;
1607   $self->cursor->reset;
1608   return $self;
1609 }
1610
1611 =head2 first
1612
1613 =over 4
1614
1615 =item Arguments: none
1616
1617 =item Return Value: $object | undef
1618
1619 =back
1620
1621 Resets the resultset and returns an object for the first result (or C<undef>
1622 if the resultset is empty).
1623
1624 =cut
1625
1626 sub first {
1627   return $_[0]->reset->next;
1628 }
1629
1630
1631 # _rs_update_delete
1632 #
1633 # Determines whether and what type of subquery is required for the $rs operation.
1634 # If grouping is necessary either supplies its own, or verifies the current one
1635 # After all is done delegates to the proper storage method.
1636
1637 sub _rs_update_delete {
1638   my ($self, $op, $values) = @_;
1639
1640   my $rsrc = $self->result_source;
1641
1642   # if a condition exists we need to strip all table qualifiers
1643   # if this is not possible we'll force a subquery below
1644   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1645
1646   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1647   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1648
1649   if ($needs_group_by_subq or $needs_subq) {
1650
1651     # make a new $rs selecting only the PKs (that's all we really need)
1652     my $attrs = $self->_resolved_attrs_copy;
1653
1654
1655     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1656     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1657
1658     if ($needs_group_by_subq) {
1659       # make sure no group_by was supplied, or if there is one - make sure it matches
1660       # the columns compiled above perfectly. Anything else can not be sanely executed
1661       # on most databases so croak right then and there
1662
1663       if (my $g = $attrs->{group_by}) {
1664         my @current_group_by = map
1665           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1666           @$g
1667         ;
1668
1669         if (
1670           join ("\x00", sort @current_group_by)
1671             ne
1672           join ("\x00", sort @{$attrs->{columns}} )
1673         ) {
1674           $self->throw_exception (
1675             "You have just attempted a $op operation on a resultset which does group_by"
1676             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1677             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1678             . ' kind of queries. Please retry the operation with a modified group_by or'
1679             . ' without using one at all.'
1680           );
1681         }
1682       }
1683       else {
1684         $attrs->{group_by} = $attrs->{columns};
1685       }
1686     }
1687
1688     my $subrs = (ref $self)->new($rsrc, $attrs);
1689     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1690   }
1691   else {
1692     return $rsrc->storage->$op(
1693       $rsrc,
1694       $op eq 'update' ? $values : (),
1695       $cond,
1696     );
1697   }
1698 }
1699
1700 =head2 update
1701
1702 =over 4
1703
1704 =item Arguments: \%values
1705
1706 =item Return Value: $storage_rv
1707
1708 =back
1709
1710 Sets the specified columns in the resultset to the supplied values in a
1711 single query. Note that this will not run any accessor/set_column/update
1712 triggers, nor will it update any row object instances derived from this
1713 resultset (this includes the contents of the L<resultset cache|/set_cache>
1714 if any). See L</update_all> if you need to execute any on-update
1715 triggers or cascades defined either by you or a
1716 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1717
1718 The return value is a pass through of what the underlying
1719 storage backend returned, and may vary. See L<DBI/execute> for the most
1720 common case.
1721
1722 =head3 CAVEAT
1723
1724 Note that L</update> does not process/deflate any of the values passed in.
1725 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1726 ensure manually that any value passed to this method will stringify to
1727 something the RDBMS knows how to deal with. A notable example is the
1728 handling of L<DateTime> objects, for more info see:
1729 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
1730
1731 =cut
1732
1733 sub update {
1734   my ($self, $values) = @_;
1735   $self->throw_exception('Values for update must be a hash')
1736     unless ref $values eq 'HASH';
1737
1738   return $self->_rs_update_delete ('update', $values);
1739 }
1740
1741 =head2 update_all
1742
1743 =over 4
1744
1745 =item Arguments: \%values
1746
1747 =item Return Value: 1
1748
1749 =back
1750
1751 Fetches all objects and updates them one at a time via
1752 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1753 triggers, while L</update> will not.
1754
1755 =cut
1756
1757 sub update_all {
1758   my ($self, $values) = @_;
1759   $self->throw_exception('Values for update_all must be a hash')
1760     unless ref $values eq 'HASH';
1761
1762   my $guard = $self->result_source->schema->txn_scope_guard;
1763   $_->update($values) for $self->all;
1764   $guard->commit;
1765   return 1;
1766 }
1767
1768 =head2 delete
1769
1770 =over 4
1771
1772 =item Arguments: none
1773
1774 =item Return Value: $storage_rv
1775
1776 =back
1777
1778 Deletes the rows matching this resultset in a single query. Note that this
1779 will not run any delete triggers, nor will it alter the
1780 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1781 derived from this resultset (this includes the contents of the
1782 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1783 execute any on-delete triggers or cascades defined either by you or a
1784 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1785
1786 The return value is a pass through of what the underlying storage backend
1787 returned, and may vary. See L<DBI/execute> for the most common case.
1788
1789 =cut
1790
1791 sub delete {
1792   my $self = shift;
1793   $self->throw_exception('delete does not accept any arguments')
1794     if @_;
1795
1796   return $self->_rs_update_delete ('delete');
1797 }
1798
1799 =head2 delete_all
1800
1801 =over 4
1802
1803 =item Arguments: none
1804
1805 =item Return Value: 1
1806
1807 =back
1808
1809 Fetches all objects and deletes them one at a time via
1810 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1811 triggers, while L</delete> will not.
1812
1813 =cut
1814
1815 sub delete_all {
1816   my $self = shift;
1817   $self->throw_exception('delete_all does not accept any arguments')
1818     if @_;
1819
1820   my $guard = $self->result_source->schema->txn_scope_guard;
1821   $_->delete for $self->all;
1822   $guard->commit;
1823   return 1;
1824 }
1825
1826 =head2 populate
1827
1828 =over 4
1829
1830 =item Arguments: \@data;
1831
1832 =back
1833
1834 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1835 For the arrayref of hashrefs style each hashref should be a structure suitable
1836 forsubmitting to a $resultset->create(...) method.
1837
1838 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1839 to insert the data, as this is a faster method.
1840
1841 Otherwise, each set of data is inserted into the database using
1842 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1843 accumulated into an array. The array itself, or an array reference
1844 is returned depending on scalar or list context.
1845
1846 Example:  Assuming an Artist Class that has many CDs Classes relating:
1847
1848   my $Artist_rs = $schema->resultset("Artist");
1849
1850   ## Void Context Example
1851   $Artist_rs->populate([
1852      { artistid => 4, name => 'Manufactured Crap', cds => [
1853         { title => 'My First CD', year => 2006 },
1854         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1855       ],
1856      },
1857      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1858         { title => 'My parents sold me to a record company', year => 2005 },
1859         { title => 'Why Am I So Ugly?', year => 2006 },
1860         { title => 'I Got Surgery and am now Popular', year => 2007 }
1861       ],
1862      },
1863   ]);
1864
1865   ## Array Context Example
1866   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1867     { name => "Artist One"},
1868     { name => "Artist Two"},
1869     { name => "Artist Three", cds=> [
1870     { title => "First CD", year => 2007},
1871     { title => "Second CD", year => 2008},
1872   ]}
1873   ]);
1874
1875   print $ArtistOne->name; ## response is 'Artist One'
1876   print $ArtistThree->cds->count ## reponse is '2'
1877
1878 For the arrayref of arrayrefs style,  the first element should be a list of the
1879 fieldsnames to which the remaining elements are rows being inserted.  For
1880 example:
1881
1882   $Arstist_rs->populate([
1883     [qw/artistid name/],
1884     [100, 'A Formally Unknown Singer'],
1885     [101, 'A singer that jumped the shark two albums ago'],
1886     [102, 'An actually cool singer'],
1887   ]);
1888
1889 Please note an important effect on your data when choosing between void and
1890 wantarray context. Since void context goes straight to C<insert_bulk> in
1891 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1892 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1893 create primary keys for you, you will find that your PKs are empty.  In this
1894 case you will have to use the wantarray context in order to create those
1895 values.
1896
1897 =cut
1898
1899 sub populate {
1900   my $self = shift;
1901
1902   # cruft placed in standalone method
1903   my $data = $self->_normalize_populate_args(@_);
1904
1905   if(defined wantarray) {
1906     my @created;
1907     foreach my $item (@$data) {
1908       push(@created, $self->create($item));
1909     }
1910     return wantarray ? @created : \@created;
1911   } else {
1912     my $first = $data->[0];
1913
1914     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1915     # it relationship data
1916     my (@rels, @columns);
1917     for (keys %$first) {
1918       my $ref = ref $first->{$_};
1919       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1920         ? push @rels, $_
1921         : push @columns, $_
1922       ;
1923     }
1924
1925     my @pks = $self->result_source->primary_columns;
1926
1927     ## do the belongs_to relationships
1928     foreach my $index (0..$#$data) {
1929
1930       # delegate to create() for any dataset without primary keys with specified relationships
1931       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1932         for my $r (@rels) {
1933           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1934             my @ret = $self->populate($data);
1935             return;
1936           }
1937         }
1938       }
1939
1940       foreach my $rel (@rels) {
1941         next unless ref $data->[$index]->{$rel} eq "HASH";
1942         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1943         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1944         my $related = $result->result_source->_resolve_condition(
1945           $result->result_source->relationship_info($reverse)->{cond},
1946           $self,
1947           $result,
1948         );
1949
1950         delete $data->[$index]->{$rel};
1951         $data->[$index] = {%{$data->[$index]}, %$related};
1952
1953         push @columns, keys %$related if $index == 0;
1954       }
1955     }
1956
1957     ## inherit the data locked in the conditions of the resultset
1958     my ($rs_data) = $self->_merge_with_rscond({});
1959     delete @{$rs_data}{@columns};
1960     my @inherit_cols = keys %$rs_data;
1961     my @inherit_data = values %$rs_data;
1962
1963     ## do bulk insert on current row
1964     $self->result_source->storage->insert_bulk(
1965       $self->result_source,
1966       [@columns, @inherit_cols],
1967       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1968     );
1969
1970     ## do the has_many relationships
1971     foreach my $item (@$data) {
1972
1973       foreach my $rel (@rels) {
1974         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1975
1976         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1977      || $self->throw_exception('Cannot find the relating object.');
1978
1979         my $child = $parent->$rel;
1980
1981         my $related = $child->result_source->_resolve_condition(
1982           $parent->result_source->relationship_info($rel)->{cond},
1983           $child,
1984           $parent,
1985         );
1986
1987         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1988         my @populate = map { {%$_, %$related} } @rows_to_add;
1989
1990         $child->populate( \@populate );
1991       }
1992     }
1993   }
1994 }
1995
1996
1997 # populate() argumnets went over several incarnations
1998 # What we ultimately support is AoH
1999 sub _normalize_populate_args {
2000   my ($self, $arg) = @_;
2001
2002   if (ref $arg eq 'ARRAY') {
2003     if (ref $arg->[0] eq 'HASH') {
2004       return $arg;
2005     }
2006     elsif (ref $arg->[0] eq 'ARRAY') {
2007       my @ret;
2008       my @colnames = @{$arg->[0]};
2009       foreach my $values (@{$arg}[1 .. $#$arg]) {
2010         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2011       }
2012       return \@ret;
2013     }
2014   }
2015
2016   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2017 }
2018
2019 =head2 pager
2020
2021 =over 4
2022
2023 =item Arguments: none
2024
2025 =item Return Value: $pager
2026
2027 =back
2028
2029 Return Value a L<Data::Page> object for the current resultset. Only makes
2030 sense for queries with a C<page> attribute.
2031
2032 To get the full count of entries for a paged resultset, call
2033 C<total_entries> on the L<Data::Page> object.
2034
2035 =cut
2036
2037 # make a wizard good for both a scalar and a hashref
2038 my $mk_lazy_count_wizard = sub {
2039   require Variable::Magic;
2040
2041   my $stash = { total_rs => shift };
2042   my $slot = shift; # only used by the hashref magic
2043
2044   my $magic = Variable::Magic::wizard (
2045     data => sub { $stash },
2046
2047     (!$slot)
2048     ? (
2049       # the scalar magic
2050       get => sub {
2051         # set value lazily, and dispell for good
2052         ${$_[0]} = $_[1]{total_rs}->count;
2053         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref});
2054         return 1;
2055       },
2056       set => sub {
2057         # an explicit set implies dispell as well
2058         # the unless() is to work around "fun and giggles" below
2059         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref})
2060           unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2061         return 1;
2062       },
2063     )
2064     : (
2065       # the uvar magic
2066       fetch => sub {
2067         if ($_[2] eq $slot and !$_[1]{inactive}) {
2068           my $cnt = $_[1]{total_rs}->count;
2069           $_[0]->{$slot} = $cnt;
2070
2071           # attempting to dispell in a fetch handle (works in store), seems
2072           # to invariable segfault on 5.10, 5.12, 5.13 :(
2073           # so use an inactivator instead
2074           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2075           $_[1]{inactive}++;
2076         }
2077         return 1;
2078       },
2079       store => sub {
2080         if (! $_[1]{inactive} and $_[2] eq $slot) {
2081           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2082           $_[1]{inactive}++
2083             unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2084         }
2085         return 1;
2086       },
2087     ),
2088   );
2089
2090   $stash->{magic_selfref} = $magic;
2091   weaken ($stash->{magic_selfref}); # this fails on 5.8.1
2092
2093   return $magic;
2094 };
2095
2096 # the tie class for 5.8.1
2097 {
2098   package # hide from pause
2099     DBIx::Class::__DBIC_LAZY_RS_COUNT__;
2100   use base qw/Tie::Hash/;
2101
2102   sub FIRSTKEY { my $dummy = scalar keys %{$_[0]{data}}; each %{$_[0]{data}} }
2103   sub NEXTKEY  { each %{$_[0]{data}} }
2104   sub EXISTS   { exists $_[0]{data}{$_[1]} }
2105   sub DELETE   { delete $_[0]{data}{$_[1]} }
2106   sub CLEAR    { %{$_[0]{data}} = () }
2107   sub SCALAR   { scalar %{$_[0]{data}} }
2108
2109   sub TIEHASH {
2110     $_[1]{data} = {%{$_[1]{selfref}}};
2111     %{$_[1]{selfref}} = ();
2112     Scalar::Util::weaken ($_[1]{selfref});
2113     return bless ($_[1], $_[0]);
2114   };
2115
2116   sub FETCH {
2117     if ($_[1] eq $_[0]{slot}) {
2118       my $cnt = $_[0]{data}{$_[1]} = $_[0]{total_rs}->count;
2119       untie %{$_[0]{selfref}};
2120       %{$_[0]{selfref}} = %{$_[0]{data}};
2121       return $cnt;
2122     }
2123     else {
2124       $_[0]{data}{$_[1]};
2125     }
2126   }
2127
2128   sub STORE {
2129     $_[0]{data}{$_[1]} = $_[2];
2130     if ($_[1] eq $_[0]{slot}) {
2131       untie %{$_[0]{selfref}};
2132       %{$_[0]{selfref}} = %{$_[0]{data}};
2133     }
2134     $_[2];
2135   }
2136 }
2137
2138 sub pager {
2139   my ($self) = @_;
2140
2141   return $self->{pager} if $self->{pager};
2142
2143   if ($self->get_cache) {
2144     $self->throw_exception ('Pagers on cached resultsets are not supported');
2145   }
2146
2147   my $attrs = $self->{attrs};
2148   if (!defined $attrs->{page}) {
2149     $self->throw_exception("Can't create pager for non-paged rs");
2150   }
2151   elsif ($attrs->{page} <= 0) {
2152     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2153   }
2154   $attrs->{rows} ||= 10;
2155
2156   # throw away the paging flags and re-run the count (possibly
2157   # with a subselect) to get the real total count
2158   my $count_attrs = { %$attrs };
2159   delete $count_attrs->{$_} for qw/rows offset page pager/;
2160   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2161
2162
2163 ### the following may seem awkward and dirty, but it's a thought-experiment
2164 ### necessary for future development of DBIx::DS. Do *NOT* change this code
2165 ### before talking to ribasushi/mst
2166
2167   my $pager = Data::Page->new(
2168     0,  #start with an empty set
2169     $attrs->{rows},
2170     $self->{attrs}{page},
2171   );
2172
2173   my $data_slot = 'total_entries';
2174
2175   # Since we are interested in a cached value (once it's set - it's set), every
2176   # technique will detach from the magic-host once the time comes to fire the
2177   # ->count (or in the segfaulting case of >= 5.10 it will deactivate itself)
2178
2179   if ($] < 5.008003) {
2180     # 5.8.1 throws 'Modification of a read-only value attempted' when one tries
2181     # to weakref the magic container :(
2182     # tested on 5.8.1
2183     tie (%$pager, 'DBIx::Class::__DBIC_LAZY_RS_COUNT__',
2184       { slot => $data_slot, total_rs => $total_rs, selfref => $pager }
2185     );
2186   }
2187   elsif ($] < 5.010) {
2188     # We can use magic on the hash value slot. It's interesting that the magic is
2189     # attached to the hash-slot, and does *not* stop working once I do the dummy
2190     # assignments after the cast()
2191     # tested on 5.8.3 and 5.8.9
2192     my $magic = $mk_lazy_count_wizard->($total_rs);
2193     Variable::Magic::cast ( $pager->{$data_slot}, $magic );
2194
2195     # this is for fun and giggles
2196     $pager->{$data_slot} = -1;
2197     $pager->{$data_slot} = 0;
2198
2199     # this does not work for scalars, but works with
2200     # uvar magic below
2201     #my %vals = %$pager;
2202     #%$pager = ();
2203     #%{$pager} = %vals;
2204   }
2205   else {
2206     # And the uvar magic
2207     # works on 5.10.1, 5.12.1 and 5.13.4 in its current form,
2208     # however see the wizard maker for more notes
2209     my $magic = $mk_lazy_count_wizard->($total_rs, $data_slot);
2210     Variable::Magic::cast ( %$pager, $magic );
2211
2212     # still works
2213     $pager->{$data_slot} = -1;
2214     $pager->{$data_slot} = 0;
2215
2216     # this now works
2217     my %vals = %$pager;
2218     %$pager = ();
2219     %{$pager} = %vals;
2220   }
2221
2222   return $self->{pager} = $pager;
2223 }
2224
2225 =head2 page
2226
2227 =over 4
2228
2229 =item Arguments: $page_number
2230
2231 =item Return Value: $rs
2232
2233 =back
2234
2235 Returns a resultset for the $page_number page of the resultset on which page
2236 is called, where each page contains a number of rows equal to the 'rows'
2237 attribute set on the resultset (10 by default).
2238
2239 =cut
2240
2241 sub page {
2242   my ($self, $page) = @_;
2243   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2244 }
2245
2246 =head2 new_result
2247
2248 =over 4
2249
2250 =item Arguments: \%vals
2251
2252 =item Return Value: $rowobject
2253
2254 =back
2255
2256 Creates a new row object in the resultset's result class and returns
2257 it. The row is not inserted into the database at this point, call
2258 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2259 will tell you whether the row object has been inserted or not.
2260
2261 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2262
2263 =cut
2264
2265 sub new_result {
2266   my ($self, $values) = @_;
2267   $self->throw_exception( "new_result needs a hash" )
2268     unless (ref $values eq 'HASH');
2269
2270   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2271
2272   my %new = (
2273     %$merged_cond,
2274     @$cols_from_relations
2275       ? (-cols_from_relations => $cols_from_relations)
2276       : (),
2277     -source_handle => $self->_source_handle,
2278     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2279   );
2280
2281   return $self->result_class->new(\%new);
2282 }
2283
2284 # _merge_with_rscond
2285 #
2286 # Takes a simple hash of K/V data and returns its copy merged with the
2287 # condition already present on the resultset. Additionally returns an
2288 # arrayref of value/condition names, which were inferred from related
2289 # objects (this is needed for in-memory related objects)
2290 sub _merge_with_rscond {
2291   my ($self, $data) = @_;
2292
2293   my (%new_data, @cols_from_relations);
2294
2295   my $alias = $self->{attrs}{alias};
2296
2297   if (! defined $self->{cond}) {
2298     # just massage $data below
2299   }
2300   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2301     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2302     @cols_from_relations = keys %new_data;
2303   }
2304   elsif (ref $self->{cond} ne 'HASH') {
2305     $self->throw_exception(
2306       "Can't abstract implicit construct, resultset condition not a hash"
2307     );
2308   }
2309   else {
2310     # precendence must be given to passed values over values inherited from
2311     # the cond, so the order here is important.
2312     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2313     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2314
2315     while ( my($col, $value) = each %implied ) {
2316       my $vref = ref $value;
2317       if ($vref eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
2318         $new_data{$col} = $value->{'='};
2319       }
2320       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2321         $new_data{$col} = $value;
2322       }
2323     }
2324   }
2325
2326   %new_data = (
2327     %new_data,
2328     %{ $self->_remove_alias($data, $alias) },
2329   );
2330
2331   return (\%new_data, \@cols_from_relations);
2332 }
2333
2334 # _has_resolved_attr
2335 #
2336 # determines if the resultset defines at least one
2337 # of the attributes supplied
2338 #
2339 # used to determine if a subquery is neccessary
2340 #
2341 # supports some virtual attributes:
2342 #   -join
2343 #     This will scan for any joins being present on the resultset.
2344 #     It is not a mere key-search but a deep inspection of {from}
2345 #
2346
2347 sub _has_resolved_attr {
2348   my ($self, @attr_names) = @_;
2349
2350   my $attrs = $self->_resolved_attrs;
2351
2352   my %extra_checks;
2353
2354   for my $n (@attr_names) {
2355     if (grep { $n eq $_ } (qw/-join/) ) {
2356       $extra_checks{$n}++;
2357       next;
2358     }
2359
2360     my $attr =  $attrs->{$n};
2361
2362     next if not defined $attr;
2363
2364     if (ref $attr eq 'HASH') {
2365       return 1 if keys %$attr;
2366     }
2367     elsif (ref $attr eq 'ARRAY') {
2368       return 1 if @$attr;
2369     }
2370     else {
2371       return 1 if $attr;
2372     }
2373   }
2374
2375   # a resolved join is expressed as a multi-level from
2376   return 1 if (
2377     $extra_checks{-join}
2378       and
2379     ref $attrs->{from} eq 'ARRAY'
2380       and
2381     @{$attrs->{from}} > 1
2382   );
2383
2384   return 0;
2385 }
2386
2387 # _collapse_cond
2388 #
2389 # Recursively collapse the condition.
2390
2391 sub _collapse_cond {
2392   my ($self, $cond, $collapsed) = @_;
2393
2394   $collapsed ||= {};
2395
2396   if (ref $cond eq 'ARRAY') {
2397     foreach my $subcond (@$cond) {
2398       next unless ref $subcond;  # -or
2399       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2400     }
2401   }
2402   elsif (ref $cond eq 'HASH') {
2403     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2404       foreach my $subcond (@{$cond->{-and}}) {
2405         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2406       }
2407     }
2408     else {
2409       foreach my $col (keys %$cond) {
2410         my $value = $cond->{$col};
2411         $collapsed->{$col} = $value;
2412       }
2413     }
2414   }
2415
2416   return $collapsed;
2417 }
2418
2419 # _remove_alias
2420 #
2421 # Remove the specified alias from the specified query hash. A copy is made so
2422 # the original query is not modified.
2423
2424 sub _remove_alias {
2425   my ($self, $query, $alias) = @_;
2426
2427   my %orig = %{ $query || {} };
2428   my %unaliased;
2429
2430   foreach my $key (keys %orig) {
2431     if ($key !~ /\./) {
2432       $unaliased{$key} = $orig{$key};
2433       next;
2434     }
2435     $unaliased{$1} = $orig{$key}
2436       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2437   }
2438
2439   return \%unaliased;
2440 }
2441
2442 =head2 as_query
2443
2444 =over 4
2445
2446 =item Arguments: none
2447
2448 =item Return Value: \[ $sql, @bind ]
2449
2450 =back
2451
2452 Returns the SQL query and bind vars associated with the invocant.
2453
2454 This is generally used as the RHS for a subquery.
2455
2456 =cut
2457
2458 sub as_query {
2459   my $self = shift;
2460
2461   my $attrs = $self->_resolved_attrs_copy;
2462
2463   # For future use:
2464   #
2465   # in list ctx:
2466   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2467   # $sql also has no wrapping parenthesis in list ctx
2468   #
2469   my $sqlbind = $self->result_source->storage
2470     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2471
2472   return $sqlbind;
2473 }
2474
2475 =head2 find_or_new
2476
2477 =over 4
2478
2479 =item Arguments: \%vals, \%attrs?
2480
2481 =item Return Value: $rowobject
2482
2483 =back
2484
2485   my $artist = $schema->resultset('Artist')->find_or_new(
2486     { artist => 'fred' }, { key => 'artists' });
2487
2488   $cd->cd_to_producer->find_or_new({ producer => $producer },
2489                                    { key => 'primary });
2490
2491 Find an existing record from this resultset using L</find>. if none exists,
2492 instantiate a new result object and return it. The object will not be saved
2493 into your storage until you call L<DBIx::Class::Row/insert> on it.
2494
2495 You most likely want this method when looking for existing rows using a unique
2496 constraint that is not the primary key, or looking for related rows.
2497
2498 If you want objects to be saved immediately, use L</find_or_create> instead.
2499
2500 B<Note>: Make sure to read the documentation of L</find> and understand the
2501 significance of the C<key> attribute, as its lack may skew your search, and
2502 subsequently result in spurious new objects.
2503
2504 B<Note>: Take care when using C<find_or_new> with a table having
2505 columns with default values that you intend to be automatically
2506 supplied by the database (e.g. an auto_increment primary key column).
2507 In normal usage, the value of such columns should NOT be included at
2508 all in the call to C<find_or_new>, even when set to C<undef>.
2509
2510 =cut
2511
2512 sub find_or_new {
2513   my $self     = shift;
2514   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2515   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2516   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2517     return $row;
2518   }
2519   return $self->new_result($hash);
2520 }
2521
2522 =head2 create
2523
2524 =over 4
2525
2526 =item Arguments: \%vals
2527
2528 =item Return Value: a L<DBIx::Class::Row> $object
2529
2530 =back
2531
2532 Attempt to create a single new row or a row with multiple related rows
2533 in the table represented by the resultset (and related tables). This
2534 will not check for duplicate rows before inserting, use
2535 L</find_or_create> to do that.
2536
2537 To create one row for this resultset, pass a hashref of key/value
2538 pairs representing the columns of the table and the values you wish to
2539 store. If the appropriate relationships are set up, foreign key fields
2540 can also be passed an object representing the foreign row, and the
2541 value will be set to its primary key.
2542
2543 To create related objects, pass a hashref of related-object column values
2544 B<keyed on the relationship name>. If the relationship is of type C<multi>
2545 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2546 The process will correctly identify columns holding foreign keys, and will
2547 transparently populate them from the keys of the corresponding relation.
2548 This can be applied recursively, and will work correctly for a structure
2549 with an arbitrary depth and width, as long as the relationships actually
2550 exists and the correct column data has been supplied.
2551
2552
2553 Instead of hashrefs of plain related data (key/value pairs), you may
2554 also pass new or inserted objects. New objects (not inserted yet, see
2555 L</new>), will be inserted into their appropriate tables.
2556
2557 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2558
2559 Example of creating a new row.
2560
2561   $person_rs->create({
2562     name=>"Some Person",
2563     email=>"somebody@someplace.com"
2564   });
2565
2566 Example of creating a new row and also creating rows in a related C<has_many>
2567 or C<has_one> resultset.  Note Arrayref.
2568
2569   $artist_rs->create(
2570      { artistid => 4, name => 'Manufactured Crap', cds => [
2571         { title => 'My First CD', year => 2006 },
2572         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2573       ],
2574      },
2575   );
2576
2577 Example of creating a new row and also creating a row in a related
2578 C<belongs_to> resultset. Note Hashref.
2579
2580   $cd_rs->create({
2581     title=>"Music for Silly Walks",
2582     year=>2000,
2583     artist => {
2584       name=>"Silly Musician",
2585     }
2586   });
2587
2588 =over
2589
2590 =item WARNING
2591
2592 When subclassing ResultSet never attempt to override this method. Since
2593 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2594 lot of the internals simply never call it, so your override will be
2595 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2596 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2597 L</create> process you need to intervene.
2598
2599 =back
2600
2601 =cut
2602
2603 sub create {
2604   my ($self, $attrs) = @_;
2605   $self->throw_exception( "create needs a hashref" )
2606     unless ref $attrs eq 'HASH';
2607   return $self->new_result($attrs)->insert;
2608 }
2609
2610 =head2 find_or_create
2611
2612 =over 4
2613
2614 =item Arguments: \%vals, \%attrs?
2615
2616 =item Return Value: $rowobject
2617
2618 =back
2619
2620   $cd->cd_to_producer->find_or_create({ producer => $producer },
2621                                       { key => 'primary' });
2622
2623 Tries to find a record based on its primary key or unique constraints; if none
2624 is found, creates one and returns that instead.
2625
2626   my $cd = $schema->resultset('CD')->find_or_create({
2627     cdid   => 5,
2628     artist => 'Massive Attack',
2629     title  => 'Mezzanine',
2630     year   => 2005,
2631   });
2632
2633 Also takes an optional C<key> attribute, to search by a specific key or unique
2634 constraint. For example:
2635
2636   my $cd = $schema->resultset('CD')->find_or_create(
2637     {
2638       artist => 'Massive Attack',
2639       title  => 'Mezzanine',
2640     },
2641     { key => 'cd_artist_title' }
2642   );
2643
2644 B<Note>: Make sure to read the documentation of L</find> and understand the
2645 significance of the C<key> attribute, as its lack may skew your search, and
2646 subsequently result in spurious row creation.
2647
2648 B<Note>: Because find_or_create() reads from the database and then
2649 possibly inserts based on the result, this method is subject to a race
2650 condition. Another process could create a record in the table after
2651 the find has completed and before the create has started. To avoid
2652 this problem, use find_or_create() inside a transaction.
2653
2654 B<Note>: Take care when using C<find_or_create> with a table having
2655 columns with default values that you intend to be automatically
2656 supplied by the database (e.g. an auto_increment primary key column).
2657 In normal usage, the value of such columns should NOT be included at
2658 all in the call to C<find_or_create>, even when set to C<undef>.
2659
2660 See also L</find> and L</update_or_create>. For information on how to declare
2661 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2662
2663 =cut
2664
2665 sub find_or_create {
2666   my $self     = shift;
2667   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2668   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2669   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2670     return $row;
2671   }
2672   return $self->create($hash);
2673 }
2674
2675 =head2 update_or_create
2676
2677 =over 4
2678
2679 =item Arguments: \%col_values, { key => $unique_constraint }?
2680
2681 =item Return Value: $row_object
2682
2683 =back
2684
2685   $resultset->update_or_create({ col => $val, ... });
2686
2687 Like L</find_or_create>, but if a row is found it is immediately updated via
2688 C<< $found_row->update (\%col_values) >>.
2689
2690
2691 Takes an optional C<key> attribute to search on a specific unique constraint.
2692 For example:
2693
2694   # In your application
2695   my $cd = $schema->resultset('CD')->update_or_create(
2696     {
2697       artist => 'Massive Attack',
2698       title  => 'Mezzanine',
2699       year   => 1998,
2700     },
2701     { key => 'cd_artist_title' }
2702   );
2703
2704   $cd->cd_to_producer->update_or_create({
2705     producer => $producer,
2706     name => 'harry',
2707   }, {
2708     key => 'primary',
2709   });
2710
2711 B<Note>: Make sure to read the documentation of L</find> and understand the
2712 significance of the C<key> attribute, as its lack may skew your search, and
2713 subsequently result in spurious row creation.
2714
2715 B<Note>: Take care when using C<update_or_create> with a table having
2716 columns with default values that you intend to be automatically
2717 supplied by the database (e.g. an auto_increment primary key column).
2718 In normal usage, the value of such columns should NOT be included at
2719 all in the call to C<update_or_create>, even when set to C<undef>.
2720
2721 See also L</find> and L</find_or_create>. For information on how to declare
2722 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2723
2724 =cut
2725
2726 sub update_or_create {
2727   my $self = shift;
2728   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2729   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2730
2731   my $row = $self->find($cond, $attrs);
2732   if (defined $row) {
2733     $row->update($cond);
2734     return $row;
2735   }
2736
2737   return $self->create($cond);
2738 }
2739
2740 =head2 update_or_new
2741
2742 =over 4
2743
2744 =item Arguments: \%col_values, { key => $unique_constraint }?
2745
2746 =item Return Value: $rowobject
2747
2748 =back
2749
2750   $resultset->update_or_new({ col => $val, ... });
2751
2752 Like L</find_or_new> but if a row is found it is immediately updated via
2753 C<< $found_row->update (\%col_values) >>.
2754
2755 For example:
2756
2757   # In your application
2758   my $cd = $schema->resultset('CD')->update_or_new(
2759     {
2760       artist => 'Massive Attack',
2761       title  => 'Mezzanine',
2762       year   => 1998,
2763     },
2764     { key => 'cd_artist_title' }
2765   );
2766
2767   if ($cd->in_storage) {
2768       # the cd was updated
2769   }
2770   else {
2771       # the cd is not yet in the database, let's insert it
2772       $cd->insert;
2773   }
2774
2775 B<Note>: Make sure to read the documentation of L</find> and understand the
2776 significance of the C<key> attribute, as its lack may skew your search, and
2777 subsequently result in spurious new objects.
2778
2779 B<Note>: Take care when using C<update_or_new> with a table having
2780 columns with default values that you intend to be automatically
2781 supplied by the database (e.g. an auto_increment primary key column).
2782 In normal usage, the value of such columns should NOT be included at
2783 all in the call to C<update_or_new>, even when set to C<undef>.
2784
2785 See also L</find>, L</find_or_create> and L</find_or_new>.
2786
2787 =cut
2788
2789 sub update_or_new {
2790     my $self  = shift;
2791     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2792     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2793
2794     my $row = $self->find( $cond, $attrs );
2795     if ( defined $row ) {
2796         $row->update($cond);
2797         return $row;
2798     }
2799
2800     return $self->new_result($cond);
2801 }
2802
2803 =head2 get_cache
2804
2805 =over 4
2806
2807 =item Arguments: none
2808
2809 =item Return Value: \@cache_objects | undef
2810
2811 =back
2812
2813 Gets the contents of the cache for the resultset, if the cache is set.
2814
2815 The cache is populated either by using the L</prefetch> attribute to
2816 L</search> or by calling L</set_cache>.
2817
2818 =cut
2819
2820 sub get_cache {
2821   shift->{all_cache};
2822 }
2823
2824 =head2 set_cache
2825
2826 =over 4
2827
2828 =item Arguments: \@cache_objects
2829
2830 =item Return Value: \@cache_objects
2831
2832 =back
2833
2834 Sets the contents of the cache for the resultset. Expects an arrayref
2835 of objects of the same class as those produced by the resultset. Note that
2836 if the cache is set the resultset will return the cached objects rather
2837 than re-querying the database even if the cache attr is not set.
2838
2839 The contents of the cache can also be populated by using the
2840 L</prefetch> attribute to L</search>.
2841
2842 =cut
2843
2844 sub set_cache {
2845   my ( $self, $data ) = @_;
2846   $self->throw_exception("set_cache requires an arrayref")
2847       if defined($data) && (ref $data ne 'ARRAY');
2848   $self->{all_cache} = $data;
2849 }
2850
2851 =head2 clear_cache
2852
2853 =over 4
2854
2855 =item Arguments: none
2856
2857 =item Return Value: undef
2858
2859 =back
2860
2861 Clears the cache for the resultset.
2862
2863 =cut
2864
2865 sub clear_cache {
2866   shift->set_cache(undef);
2867 }
2868
2869 =head2 is_paged
2870
2871 =over 4
2872
2873 =item Arguments: none
2874
2875 =item Return Value: true, if the resultset has been paginated
2876
2877 =back
2878
2879 =cut
2880
2881 sub is_paged {
2882   my ($self) = @_;
2883   return !!$self->{attrs}{page};
2884 }
2885
2886 =head2 is_ordered
2887
2888 =over 4
2889
2890 =item Arguments: none
2891
2892 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2893
2894 =back
2895
2896 =cut
2897
2898 sub is_ordered {
2899   my ($self) = @_;
2900   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2901 }
2902
2903 =head2 related_resultset
2904
2905 =over 4
2906
2907 =item Arguments: $relationship_name
2908
2909 =item Return Value: $resultset
2910
2911 =back
2912
2913 Returns a related resultset for the supplied relationship name.
2914
2915   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2916
2917 =cut
2918
2919 sub related_resultset {
2920   my ($self, $rel) = @_;
2921
2922   $self->{related_resultsets} ||= {};
2923   return $self->{related_resultsets}{$rel} ||= do {
2924     my $rsrc = $self->result_source;
2925     my $rel_info = $rsrc->relationship_info($rel);
2926
2927     $self->throw_exception(
2928       "search_related: result source '" . $rsrc->source_name .
2929         "' has no such relationship $rel")
2930       unless $rel_info;
2931
2932     my $attrs = $self->_chain_relationship($rel);
2933
2934     my $join_count = $attrs->{seen_join}{$rel};
2935
2936     my $alias = $self->result_source->storage
2937         ->relname_to_table_alias($rel, $join_count);
2938
2939     # since this is search_related, and we already slid the select window inwards
2940     # (the select/as attrs were deleted in the beginning), we need to flip all
2941     # left joins to inner, so we get the expected results
2942     # read the comment on top of the actual function to see what this does
2943     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2944
2945
2946     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2947     delete @{$attrs}{qw(result_class alias)};
2948
2949     my $new_cache;
2950
2951     if (my $cache = $self->get_cache) {
2952       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2953         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2954                         @$cache ];
2955       }
2956     }
2957
2958     my $rel_source = $rsrc->related_source($rel);
2959
2960     my $new = do {
2961
2962       # The reason we do this now instead of passing the alias to the
2963       # search_rs below is that if you wrap/overload resultset on the
2964       # source you need to know what alias it's -going- to have for things
2965       # to work sanely (e.g. RestrictWithObject wants to be able to add
2966       # extra query restrictions, and these may need to be $alias.)
2967
2968       my $rel_attrs = $rel_source->resultset_attributes;
2969       local $rel_attrs->{alias} = $alias;
2970
2971       $rel_source->resultset
2972                  ->search_rs(
2973                      undef, {
2974                        %$attrs,
2975                        where => $attrs->{where},
2976                    });
2977     };
2978     $new->set_cache($new_cache) if $new_cache;
2979     $new;
2980   };
2981 }
2982
2983 =head2 current_source_alias
2984
2985 =over 4
2986
2987 =item Arguments: none
2988
2989 =item Return Value: $source_alias
2990
2991 =back
2992
2993 Returns the current table alias for the result source this resultset is built
2994 on, that will be used in the SQL query. Usually it is C<me>.
2995
2996 Currently the source alias that refers to the result set returned by a
2997 L</search>/L</find> family method depends on how you got to the resultset: it's
2998 C<me> by default, but eg. L</search_related> aliases it to the related result
2999 source name (and keeps C<me> referring to the original result set). The long
3000 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3001 (and make this method unnecessary).
3002
3003 Thus it's currently necessary to use this method in predefined queries (see
3004 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3005 source alias of the current result set:
3006
3007   # in a result set class
3008   sub modified_by {
3009     my ($self, $user) = @_;
3010
3011     my $me = $self->current_source_alias;
3012
3013     return $self->search(
3014       "$me.modified" => $user->id,
3015     );
3016   }
3017
3018 =cut
3019
3020 sub current_source_alias {
3021   my ($self) = @_;
3022
3023   return ($self->{attrs} || {})->{alias} || 'me';
3024 }
3025
3026 =head2 as_subselect_rs
3027
3028 =over 4
3029
3030 =item Arguments: none
3031
3032 =item Return Value: $resultset
3033
3034 =back
3035
3036 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3037 "virtual view" by including it as a subquery within the from clause.  From this
3038 point on, any joined tables are inaccessible to ->search on the resultset (as if
3039 it were simply where-filtered without joins).  For example:
3040
3041  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3042
3043  # 'x' now pollutes the query namespace
3044
3045  # So the following works as expected
3046  my $ok_rs = $rs->search({'x.other' => 1});
3047
3048  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3049  # def) we look for one row with contradictory terms and join in another table
3050  # (aliased 'x_2') which we never use
3051  my $broken_rs = $rs->search({'x.name' => 'def'});
3052
3053  my $rs2 = $rs->as_subselect_rs;
3054
3055  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3056  my $not_joined_rs = $rs2->search({'x.other' => 1});
3057
3058  # works as expected: finds a 'table' row related to two x rows (abc and def)
3059  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3060
3061 Another example of when one might use this would be to select a subset of
3062 columns in a group by clause:
3063
3064  my $rs = $schema->resultset('Bar')->search(undef, {
3065    group_by => [qw{ id foo_id baz_id }],
3066  })->as_subselect_rs->search(undef, {
3067    columns => [qw{ id foo_id }]
3068  });
3069
3070 In the above example normally columns would have to be equal to the group by,
3071 but because we isolated the group by into a subselect the above works.
3072
3073 =cut
3074
3075 sub as_subselect_rs {
3076   my $self = shift;
3077
3078   my $attrs = $self->_resolved_attrs;
3079
3080   my $fresh_rs = (ref $self)->new (
3081     $self->result_source
3082   );
3083
3084   # these pieces will be locked in the subquery
3085   delete $fresh_rs->{cond};
3086   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3087
3088   return $fresh_rs->search( {}, {
3089     from => [{
3090       $attrs->{alias} => $self->as_query,
3091       -alias         => $attrs->{alias},
3092       -source_handle => $self->result_source->handle,
3093     }],
3094     alias => $attrs->{alias},
3095   });
3096 }
3097
3098 # This code is called by search_related, and makes sure there
3099 # is clear separation between the joins before, during, and
3100 # after the relationship. This information is needed later
3101 # in order to properly resolve prefetch aliases (any alias
3102 # with a relation_chain_depth less than the depth of the
3103 # current prefetch is not considered)
3104 #
3105 # The increments happen twice per join. An even number means a
3106 # relationship specified via a search_related, whereas an odd
3107 # number indicates a join/prefetch added via attributes
3108 #
3109 # Also this code will wrap the current resultset (the one we
3110 # chain to) in a subselect IFF it contains limiting attributes
3111 sub _chain_relationship {
3112   my ($self, $rel) = @_;
3113   my $source = $self->result_source;
3114   my $attrs = { %{$self->{attrs}||{}} };
3115
3116   # we need to take the prefetch the attrs into account before we
3117   # ->_resolve_join as otherwise they get lost - captainL
3118   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3119
3120   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3121
3122   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3123
3124   my $from;
3125   my @force_subq_attrs = qw/offset rows group_by having/;
3126
3127   if (
3128     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3129       ||
3130     $self->_has_resolved_attr (@force_subq_attrs)
3131   ) {
3132     # Nuke the prefetch (if any) before the new $rs attrs
3133     # are resolved (prefetch is useless - we are wrapping
3134     # a subquery anyway).
3135     my $rs_copy = $self->search;
3136     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3137       $rs_copy->{attrs}{join},
3138       delete $rs_copy->{attrs}{prefetch},
3139     );
3140
3141     $from = [{
3142       -source_handle => $source->handle,
3143       -alias => $attrs->{alias},
3144       $attrs->{alias} => $rs_copy->as_query,
3145     }];
3146     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3147     $seen->{-relation_chain_depth} = 0;
3148   }
3149   elsif ($attrs->{from}) {  #shallow copy suffices
3150     $from = [ @{$attrs->{from}} ];
3151   }
3152   else {
3153     $from = [{
3154       -source_handle => $source->handle,
3155       -alias => $attrs->{alias},
3156       $attrs->{alias} => $source->from,
3157     }];
3158   }
3159
3160   my $jpath = ($seen->{-relation_chain_depth})
3161     ? $from->[-1][0]{-join_path}
3162     : [];
3163
3164   my @requested_joins = $source->_resolve_join(
3165     $join,
3166     $attrs->{alias},
3167     $seen,
3168     $jpath,
3169   );
3170
3171   push @$from, @requested_joins;
3172
3173   $seen->{-relation_chain_depth}++;
3174
3175   # if $self already had a join/prefetch specified on it, the requested
3176   # $rel might very well be already included. What we do in this case
3177   # is effectively a no-op (except that we bump up the chain_depth on
3178   # the join in question so we could tell it *is* the search_related)
3179   my $already_joined;
3180
3181   # we consider the last one thus reverse
3182   for my $j (reverse @requested_joins) {
3183     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3184     if ($rel eq $last_j) {
3185       $j->[0]{-relation_chain_depth}++;
3186       $already_joined++;
3187       last;
3188     }
3189   }
3190
3191   unless ($already_joined) {
3192     push @$from, $source->_resolve_join(
3193       $rel,
3194       $attrs->{alias},
3195       $seen,
3196       $jpath,
3197     );
3198   }
3199
3200   $seen->{-relation_chain_depth}++;
3201
3202   return {%$attrs, from => $from, seen_join => $seen};
3203 }
3204
3205 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3206 sub _resolved_attrs_copy {
3207   my $self = shift;
3208   return { %{$self->_resolved_attrs (@_)} };
3209 }
3210
3211 sub _resolved_attrs {
3212   my $self = shift;
3213   return $self->{_attrs} if $self->{_attrs};
3214
3215   my $attrs  = { %{ $self->{attrs} || {} } };
3216   my $source = $self->result_source;
3217   my $alias  = $attrs->{alias};
3218
3219   # one last pass of normalization
3220   $self->_normalize_selection($attrs);
3221
3222   # default selection list
3223   $attrs->{columns} = [ $source->columns ]
3224     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as _trailing_select/;
3225
3226   # merge selectors together
3227   for (qw/columns select as _trailing_select/) {
3228     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, $attrs->{"+$_"})
3229       if $attrs->{$_} or $attrs->{"+$_"};
3230   }
3231
3232   # disassemble columns
3233   my (@sel, @as);
3234   for my $c (@{
3235     ref $attrs->{columns} eq 'ARRAY' ? $attrs->{columns} : [ $attrs->{columns} || () ]
3236   }) {
3237     if (ref $c eq 'HASH') {
3238       for my $as (keys %$c) {
3239         push @sel, $c->{$as};
3240         push @as, $as;
3241       }
3242     }
3243     else {
3244       push @sel, $c;
3245       push @as, $c;
3246     }
3247   }
3248
3249   # when trying to weed off duplicates later do not go past this point -
3250   # everything added from here on is unbalanced "anyone's guess" stuff
3251   my $dedup_stop_idx = $#as;
3252
3253   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3254     if $attrs->{as};
3255   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3256     if $attrs->{select};
3257
3258   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3259   for (@sel) {
3260     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3261   }
3262
3263   # disqualify all $alias.col as-bits (collapser mandated)
3264   for (@as) {
3265     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3266   }
3267
3268   # de-duplicate the result (remove *identical* select/as pairs)
3269   # and also die on duplicate {as} pointing to different {select}s
3270   # not using a c-style for as the condition is prone to shrinkage
3271   my $seen;
3272   my $i = 0;
3273   while ($i <= $dedup_stop_idx) {
3274     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3275       splice @sel, $i, 1;
3276       splice @as, $i, 1;
3277       $dedup_stop_idx--;
3278     }
3279     elsif ($seen->{$as[$i]}++) {
3280       $self->throw_exception(
3281         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3282       );
3283     }
3284     else {
3285       $i++;
3286     }
3287   }
3288
3289   $attrs->{select} = \@sel;
3290   $attrs->{as} = \@as;
3291
3292   $attrs->{from} ||= [{
3293     -source_handle => $source->handle,
3294     -alias => $self->{attrs}{alias},
3295     $self->{attrs}{alias} => $source->from,
3296   }];
3297
3298   if ( $attrs->{join} || $attrs->{prefetch} ) {
3299
3300     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3301       if ref $attrs->{from} ne 'ARRAY';
3302
3303     my $join = (delete $attrs->{join}) || {};
3304
3305     if ( defined $attrs->{prefetch} ) {
3306       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3307     }
3308
3309     $attrs->{from} =    # have to copy here to avoid corrupting the original
3310       [
3311         @{ $attrs->{from} },
3312         $source->_resolve_join(
3313           $join,
3314           $alias,
3315           { %{ $attrs->{seen_join} || {} } },
3316           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3317             ? $attrs->{from}[-1][0]{-join_path}
3318             : []
3319           ,
3320         )
3321       ];
3322   }
3323
3324   if ( defined $attrs->{order_by} ) {
3325     $attrs->{order_by} = (
3326       ref( $attrs->{order_by} ) eq 'ARRAY'
3327       ? [ @{ $attrs->{order_by} } ]
3328       : [ $attrs->{order_by} || () ]
3329     );
3330   }
3331
3332   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3333     $attrs->{group_by} = [ $attrs->{group_by} ];
3334   }
3335
3336   # generate the distinct induced group_by early, as prefetch will be carried via a
3337   # subquery (since a group_by is present)
3338   if (delete $attrs->{distinct}) {
3339     if ($attrs->{group_by}) {
3340       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3341     }
3342     else {
3343       # distinct affects only the main selection part, not what prefetch may
3344       # add below. However trailing is not yet a part of the selection as
3345       # prefetch must insert before it
3346       $attrs->{group_by} = $source->storage->_group_over_selection (
3347         $attrs->{from},
3348         [ @{$attrs->{select}||[]}, @{$attrs->{_trailing_select}||[]} ],
3349         $attrs->{order_by},
3350       );
3351     }
3352   }
3353
3354   $attrs->{collapse} ||= {};
3355   if ($attrs->{prefetch}) {
3356     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3357
3358     my $prefetch_ordering = [];
3359
3360     # this is a separate structure (we don't look in {from} directly)
3361     # as the resolver needs to shift things off the lists to work
3362     # properly (identical-prefetches on different branches)
3363     my $join_map = {};
3364     if (ref $attrs->{from} eq 'ARRAY') {
3365
3366       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3367
3368       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3369         next unless $j->[0]{-alias};
3370         next unless $j->[0]{-join_path};
3371         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3372
3373         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3374
3375         my $p = $join_map;
3376         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3377         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3378       }
3379     }
3380
3381     my @prefetch =
3382       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3383
3384     # we need to somehow mark which columns came from prefetch
3385     if (@prefetch) {
3386       my $sel_end = $#{$attrs->{select}};
3387       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3388     }
3389
3390     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3391     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3392
3393     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3394     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3395   }
3396
3397
3398   push @{ $attrs->{select} }, @{$attrs->{_trailing_select}}
3399     if $attrs->{_trailing_select};
3400
3401   # if both page and offset are specified, produce a combined offset
3402   # even though it doesn't make much sense, this is what pre 081xx has
3403   # been doing
3404   if (my $page = delete $attrs->{page}) {
3405     $attrs->{offset} =
3406       ($attrs->{rows} * ($page - 1))
3407             +
3408       ($attrs->{offset} || 0)
3409     ;
3410   }
3411
3412   return $self->{_attrs} = $attrs;
3413 }
3414
3415 sub _rollout_attr {
3416   my ($self, $attr) = @_;
3417
3418   if (ref $attr eq 'HASH') {
3419     return $self->_rollout_hash($attr);
3420   } elsif (ref $attr eq 'ARRAY') {
3421     return $self->_rollout_array($attr);
3422   } else {
3423     return [$attr];
3424   }
3425 }
3426
3427 sub _rollout_array {
3428   my ($self, $attr) = @_;
3429
3430   my @rolled_array;
3431   foreach my $element (@{$attr}) {
3432     if (ref $element eq 'HASH') {
3433       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3434     } elsif (ref $element eq 'ARRAY') {
3435       #  XXX - should probably recurse here
3436       push( @rolled_array, @{$self->_rollout_array($element)} );
3437     } else {
3438       push( @rolled_array, $element );
3439     }
3440   }
3441   return \@rolled_array;
3442 }
3443
3444 sub _rollout_hash {
3445   my ($self, $attr) = @_;
3446
3447   my @rolled_array;
3448   foreach my $key (keys %{$attr}) {
3449     push( @rolled_array, { $key => $attr->{$key} } );
3450   }
3451   return \@rolled_array;
3452 }
3453
3454 sub _calculate_score {
3455   my ($self, $a, $b) = @_;
3456
3457   if (defined $a xor defined $b) {
3458     return 0;
3459   }
3460   elsif (not defined $a) {
3461     return 1;
3462   }
3463
3464   if (ref $b eq 'HASH') {
3465     my ($b_key) = keys %{$b};
3466     if (ref $a eq 'HASH') {
3467       my ($a_key) = keys %{$a};
3468       if ($a_key eq $b_key) {
3469         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3470       } else {
3471         return 0;
3472       }
3473     } else {
3474       return ($a eq $b_key) ? 1 : 0;
3475     }
3476   } else {
3477     if (ref $a eq 'HASH') {
3478       my ($a_key) = keys %{$a};
3479       return ($b eq $a_key) ? 1 : 0;
3480     } else {
3481       return ($b eq $a) ? 1 : 0;
3482     }
3483   }
3484 }
3485
3486 sub _merge_joinpref_attr {
3487   my ($self, $orig, $import) = @_;
3488
3489   return $import unless defined($orig);
3490   return $orig unless defined($import);
3491
3492   $orig = $self->_rollout_attr($orig);
3493   $import = $self->_rollout_attr($import);
3494
3495   my $seen_keys;
3496   foreach my $import_element ( @{$import} ) {
3497     # find best candidate from $orig to merge $b_element into
3498     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3499     foreach my $orig_element ( @{$orig} ) {
3500       my $score = $self->_calculate_score( $orig_element, $import_element );
3501       if ($score > $best_candidate->{score}) {
3502         $best_candidate->{position} = $position;
3503         $best_candidate->{score} = $score;
3504       }
3505       $position++;
3506     }
3507     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3508
3509     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3510       push( @{$orig}, $import_element );
3511     } else {
3512       my $orig_best = $orig->[$best_candidate->{position}];
3513       # merge orig_best and b_element together and replace original with merged
3514       if (ref $orig_best ne 'HASH') {
3515         $orig->[$best_candidate->{position}] = $import_element;
3516       } elsif (ref $import_element eq 'HASH') {
3517         my ($key) = keys %{$orig_best};
3518         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3519       }
3520     }
3521     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3522   }
3523
3524   return $orig;
3525 }
3526
3527 {
3528   my $hm;
3529
3530   sub _merge_attr {
3531     $hm ||= do {
3532       my $hm = Hash::Merge->new;
3533
3534       $hm->specify_behavior({
3535         SCALAR => {
3536           SCALAR => sub {
3537             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3538
3539             if ($defl xor $defr) {
3540               return [ $defl ? $_[0] : $_[1] ];
3541             }
3542             elsif (! $defl) {
3543               return [];
3544             }
3545             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3546               return [ $_[0] ];
3547             }
3548             else {
3549               return [$_[0], $_[1]];
3550             }
3551           },
3552           ARRAY => sub {
3553             return $_[1] if !defined $_[0];
3554             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3555             return [$_[0], @{$_[1]}]
3556           },
3557           HASH  => sub {
3558             return [] if !defined $_[0] and !keys %{$_[1]};
3559             return [ $_[1] ] if !defined $_[0];
3560             return [ $_[0] ] if !keys %{$_[1]};
3561             return [$_[0], $_[1]]
3562           },
3563         },
3564         ARRAY => {
3565           SCALAR => sub {
3566             return $_[0] if !defined $_[1];
3567             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3568             return [@{$_[0]}, $_[1]]
3569           },
3570           ARRAY => sub {
3571             my @ret = @{$_[0]} or return $_[1];
3572             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3573             my %idx = map { $_ => 1 } @ret;
3574             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3575             \@ret;
3576           },
3577           HASH => sub {
3578             return [ $_[1] ] if ! @{$_[0]};
3579             return $_[0] if !keys %{$_[1]};
3580             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3581             return [ @{$_[0]}, $_[1] ];
3582           },
3583         },
3584         HASH => {
3585           SCALAR => sub {
3586             return [] if !keys %{$_[0]} and !defined $_[1];
3587             return [ $_[0] ] if !defined $_[1];
3588             return [ $_[1] ] if !keys %{$_[0]};
3589             return [$_[0], $_[1]]
3590           },
3591           ARRAY => sub {
3592             return [] if !keys %{$_[0]} and !@{$_[1]};
3593             return [ $_[0] ] if !@{$_[1]};
3594             return $_[1] if !keys %{$_[0]};
3595             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3596             return [ $_[0], @{$_[1]} ];
3597           },
3598           HASH => sub {
3599             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3600             return [ $_[0] ] if !keys %{$_[1]};
3601             return [ $_[1] ] if !keys %{$_[0]};
3602             return [ $_[0] ] if $_[0] eq $_[1];
3603             return [ $_[0], $_[1] ];
3604           },
3605         }
3606       } => 'DBIC_RS_ATTR_MERGER');
3607       $hm;
3608     };
3609
3610     return $hm->merge ($_[1], $_[2]);
3611   }
3612 }
3613
3614 sub result_source {
3615     my $self = shift;
3616
3617     if (@_) {
3618         $self->_source_handle($_[0]->handle);
3619     } else {
3620         $self->_source_handle->resolve;
3621     }
3622 }
3623
3624
3625 sub STORABLE_freeze {
3626   my ($self, $cloning) = @_;
3627   my $to_serialize = { %$self };
3628
3629   # A cursor in progress can't be serialized (and would make little sense anyway)
3630   delete $to_serialize->{cursor};
3631
3632   return nfreeze($to_serialize);
3633 }
3634
3635 # need this hook for symmetry
3636 sub STORABLE_thaw {
3637   my ($self, $cloning, $serialized) = @_;
3638
3639   %$self = %{ thaw($serialized) };
3640
3641   return $self;
3642 }
3643
3644
3645 =head2 throw_exception
3646
3647 See L<DBIx::Class::Schema/throw_exception> for details.
3648
3649 =cut
3650
3651 sub throw_exception {
3652   my $self=shift;
3653
3654   if (ref $self && $self->_source_handle->schema) {
3655     $self->_source_handle->schema->throw_exception(@_)
3656   }
3657   else {
3658     DBIx::Class::Exception->throw(@_);
3659   }
3660 }
3661
3662 # XXX: FIXME: Attributes docs need clearing up
3663
3664 =head1 ATTRIBUTES
3665
3666 Attributes are used to refine a ResultSet in various ways when
3667 searching for data. They can be passed to any method which takes an
3668 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3669 L</count>.
3670
3671 These are in no particular order:
3672
3673 =head2 order_by
3674
3675 =over 4
3676
3677 =item Value: ( $order_by | \@order_by | \%order_by )
3678
3679 =back
3680
3681 Which column(s) to order the results by.
3682
3683 [The full list of suitable values is documented in
3684 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3685 common options.]
3686
3687 If a single column name, or an arrayref of names is supplied, the
3688 argument is passed through directly to SQL. The hashref syntax allows
3689 for connection-agnostic specification of ordering direction:
3690
3691  For descending order:
3692
3693   order_by => { -desc => [qw/col1 col2 col3/] }
3694
3695  For explicit ascending order:
3696
3697   order_by => { -asc => 'col' }
3698
3699 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3700 supported, although you are strongly encouraged to use the hashref
3701 syntax as outlined above.
3702
3703 =head2 columns
3704
3705 =over 4
3706
3707 =item Value: \@columns
3708
3709 =back
3710
3711 Shortcut to request a particular set of columns to be retrieved. Each
3712 column spec may be a string (a table column name), or a hash (in which
3713 case the key is the C<as> value, and the value is used as the C<select>
3714 expression). Adds C<me.> onto the start of any column without a C<.> in
3715 it and sets C<select> from that, then auto-populates C<as> from
3716 C<select> as normal. (You may also use the C<cols> attribute, as in
3717 earlier versions of DBIC.)
3718
3719 Essentially C<columns> does the same as L</select> and L</as>.
3720
3721     columns => [ 'foo', { bar => 'baz' } ]
3722
3723 is the same as
3724
3725     select => [qw/foo baz/],
3726     as => [qw/foo bar/]
3727
3728 =head2 +columns
3729
3730 =over 4
3731
3732 =item Value: \@columns
3733
3734 =back
3735
3736 Indicates additional columns to be selected from storage. Works the same
3737 as L</columns> but adds columns to the selection. (You may also use the
3738 C<include_columns> attribute, as in earlier versions of DBIC). For
3739 example:-
3740
3741   $schema->resultset('CD')->search(undef, {
3742     '+columns' => ['artist.name'],
3743     join => ['artist']
3744   });
3745
3746 would return all CDs and include a 'name' column to the information
3747 passed to object inflation. Note that the 'artist' is the name of the
3748 column (or relationship) accessor, and 'name' is the name of the column
3749 accessor in the related table.
3750
3751 =head2 include_columns
3752
3753 =over 4
3754
3755 =item Value: \@columns
3756
3757 =back
3758
3759 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3760
3761 =head2 select
3762
3763 =over 4
3764
3765 =item Value: \@select_columns
3766
3767 =back
3768
3769 Indicates which columns should be selected from the storage. You can use
3770 column names, or in the case of RDBMS back ends, function or stored procedure
3771 names:
3772
3773   $rs = $schema->resultset('Employee')->search(undef, {
3774     select => [
3775       'name',
3776       { count => 'employeeid' },
3777       { max => { length => 'name' }, -as => 'longest_name' }
3778     ]
3779   });
3780
3781   # Equivalent SQL
3782   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3783
3784 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3785 use L</select>, to instruct DBIx::Class how to store the result of the column.
3786 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3787 identifier aliasing. You can however alias a function, so you can use it in
3788 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3789 attribute> supplied as shown in the example above.
3790
3791 =head2 +select
3792
3793 =over 4
3794
3795 Indicates additional columns to be selected from storage.  Works the same as
3796 L</select> but adds columns to the default selection, instead of specifying
3797 an explicit list.
3798
3799 =back
3800
3801 =head2 +as
3802
3803 =over 4
3804
3805 Indicates additional column names for those added via L</+select>. See L</as>.
3806
3807 =back
3808
3809 =head2 as
3810
3811 =over 4
3812
3813 =item Value: \@inflation_names
3814
3815 =back
3816
3817 Indicates column names for object inflation. That is L</as> indicates the
3818 slot name in which the column value will be stored within the
3819 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3820 identifier by the C<get_column> method (or via the object accessor B<if one
3821 with the same name already exists>) as shown below. The L</as> attribute has
3822 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3823
3824   $rs = $schema->resultset('Employee')->search(undef, {
3825     select => [
3826       'name',
3827       { count => 'employeeid' },
3828       { max => { length => 'name' }, -as => 'longest_name' }
3829     ],
3830     as => [qw/
3831       name
3832       employee_count
3833       max_name_length
3834     /],
3835   });
3836
3837 If the object against which the search is performed already has an accessor
3838 matching a column name specified in C<as>, the value can be retrieved using
3839 the accessor as normal:
3840
3841   my $name = $employee->name();
3842
3843 If on the other hand an accessor does not exist in the object, you need to
3844 use C<get_column> instead:
3845
3846   my $employee_count = $employee->get_column('employee_count');
3847
3848 You can create your own accessors if required - see
3849 L<DBIx::Class::Manual::Cookbook> for details.
3850
3851 =head2 join
3852
3853 =over 4
3854
3855 =item Value: ($rel_name | \@rel_names | \%rel_names)
3856
3857 =back
3858
3859 Contains a list of relationships that should be joined for this query.  For
3860 example:
3861
3862   # Get CDs by Nine Inch Nails
3863   my $rs = $schema->resultset('CD')->search(
3864     { 'artist.name' => 'Nine Inch Nails' },
3865     { join => 'artist' }
3866   );
3867
3868 Can also contain a hash reference to refer to the other relation's relations.
3869 For example:
3870
3871   package MyApp::Schema::Track;
3872   use base qw/DBIx::Class/;
3873   __PACKAGE__->table('track');
3874   __PACKAGE__->add_columns(qw/trackid cd position title/);
3875   __PACKAGE__->set_primary_key('trackid');
3876   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3877   1;
3878
3879   # In your application
3880   my $rs = $schema->resultset('Artist')->search(
3881     { 'track.title' => 'Teardrop' },
3882     {
3883       join     => { cd => 'track' },
3884       order_by => 'artist.name',
3885     }
3886   );
3887
3888 You need to use the relationship (not the table) name in  conditions,
3889 because they are aliased as such. The current table is aliased as "me", so
3890 you need to use me.column_name in order to avoid ambiguity. For example:
3891
3892   # Get CDs from 1984 with a 'Foo' track
3893   my $rs = $schema->resultset('CD')->search(
3894     {
3895       'me.year' => 1984,
3896       'tracks.name' => 'Foo'
3897     },
3898     { join => 'tracks' }
3899   );
3900
3901 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3902 similarly for a third time). For e.g.
3903
3904   my $rs = $schema->resultset('Artist')->search({
3905     'cds.title'   => 'Down to Earth',
3906     'cds_2.title' => 'Popular',
3907   }, {
3908     join => [ qw/cds cds/ ],
3909   });
3910
3911 will return a set of all artists that have both a cd with title 'Down
3912 to Earth' and a cd with title 'Popular'.
3913
3914 If you want to fetch related objects from other tables as well, see C<prefetch>
3915 below.
3916
3917 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3918
3919 =head2 prefetch
3920
3921 =over 4
3922
3923 =item Value: ($rel_name | \@rel_names | \%rel_names)
3924
3925 =back
3926
3927 Contains one or more relationships that should be fetched along with
3928 the main query (when they are accessed afterwards the data will
3929 already be available, without extra queries to the database).  This is
3930 useful for when you know you will need the related objects, because it
3931 saves at least one query:
3932
3933   my $rs = $schema->resultset('Tag')->search(
3934     undef,
3935     {
3936       prefetch => {
3937         cd => 'artist'
3938       }
3939     }
3940   );
3941
3942 The initial search results in SQL like the following:
3943
3944   SELECT tag.*, cd.*, artist.* FROM tag
3945   JOIN cd ON tag.cd = cd.cdid
3946   JOIN artist ON cd.artist = artist.artistid
3947
3948 L<DBIx::Class> has no need to go back to the database when we access the
3949 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3950 case.
3951
3952 Simple prefetches will be joined automatically, so there is no need
3953 for a C<join> attribute in the above search.
3954
3955 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3956 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3957 with an accessor type of 'single' or 'filter'). A more complex example that
3958 prefetches an artists cds, the tracks on those cds, and the tags associated
3959 with that artist is given below (assuming many-to-many from artists to tags):
3960
3961  my $rs = $schema->resultset('Artist')->search(
3962    undef,
3963    {
3964      prefetch => [
3965        { cds => 'tracks' },
3966        { artist_tags => 'tags' }
3967      ]
3968    }
3969  );
3970
3971
3972 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3973 attributes will be ignored.
3974
3975 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3976 exactly as you might expect.
3977
3978 =over 4
3979
3980 =item *
3981
3982 Prefetch uses the L</cache> to populate the prefetched relationships. This
3983 may or may not be what you want.
3984
3985 =item *
3986
3987 If you specify a condition on a prefetched relationship, ONLY those
3988 rows that match the prefetched condition will be fetched into that relationship.
3989 This means that adding prefetch to a search() B<may alter> what is returned by
3990 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3991
3992   my $artist_rs = $schema->resultset('Artist')->search({
3993       'cds.year' => 2008,
3994   }, {
3995       join => 'cds',
3996   });
3997
3998   my $count = $artist_rs->first->cds->count;
3999
4000   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4001
4002   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4003
4004   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4005
4006 that cmp_ok() may or may not pass depending on the datasets involved. This
4007 behavior may or may not survive the 0.09 transition.
4008
4009 =back
4010
4011 =head2 page
4012
4013 =over 4
4014
4015 =item Value: $page
4016
4017 =back
4018
4019 Makes the resultset paged and specifies the page to retrieve. Effectively
4020 identical to creating a non-pages resultset and then calling ->page($page)
4021 on it.
4022
4023 If L<rows> attribute is not specified it defaults to 10 rows per page.
4024
4025 When you have a paged resultset, L</count> will only return the number
4026 of rows in the page. To get the total, use the L</pager> and call
4027 C<total_entries> on it.
4028
4029 =head2 rows
4030
4031 =over 4
4032
4033 =item Value: $rows
4034
4035 =back
4036
4037 Specifies the maximum number of rows for direct retrieval or the number of
4038 rows per page if the page attribute or method is used.
4039
4040 =head2 offset
4041
4042 =over 4
4043
4044 =item Value: $offset
4045
4046 =back
4047
4048 Specifies the (zero-based) row number for the  first row to be returned, or the
4049 of the first row of the first page if paging is used.
4050
4051 =head2 group_by
4052
4053 =over 4
4054
4055 =item Value: \@columns
4056
4057 =back
4058
4059 A arrayref of columns to group by. Can include columns of joined tables.
4060
4061   group_by => [qw/ column1 column2 ... /]
4062
4063 =head2 having
4064
4065 =over 4
4066
4067 =item Value: $condition
4068
4069 =back
4070
4071 HAVING is a select statement attribute that is applied between GROUP BY and
4072 ORDER BY. It is applied to the after the grouping calculations have been
4073 done.
4074
4075   having => { 'count_employee' => { '>=', 100 } }
4076
4077 or with an in-place function in which case literal SQL is required:
4078
4079   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4080
4081 =head2 distinct
4082
4083 =over 4
4084
4085 =item Value: (0 | 1)
4086
4087 =back
4088
4089 Set to 1 to group by all columns. If the resultset already has a group_by
4090 attribute, this setting is ignored and an appropriate warning is issued.
4091
4092 =head2 where
4093
4094 =over 4
4095
4096 Adds to the WHERE clause.
4097
4098   # only return rows WHERE deleted IS NULL for all searches
4099   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4100
4101 Can be overridden by passing C<< { where => undef } >> as an attribute
4102 to a resultset.
4103
4104 =back
4105
4106 =head2 cache
4107
4108 Set to 1 to cache search results. This prevents extra SQL queries if you
4109 revisit rows in your ResultSet:
4110
4111   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4112
4113   while( my $artist = $resultset->next ) {
4114     ... do stuff ...
4115   }
4116
4117   $rs->first; # without cache, this would issue a query
4118
4119 By default, searches are not cached.
4120
4121 For more examples of using these attributes, see
4122 L<DBIx::Class::Manual::Cookbook>.
4123
4124 =head2 for
4125
4126 =over 4
4127
4128 =item Value: ( 'update' | 'shared' )
4129
4130 =back
4131
4132 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4133 ... FOR SHARED.
4134
4135 =cut
4136
4137 1;