lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => \&count,
   7         'bool'   => sub { 1; },
   8         fallback => 1;
   9 use Data::Page;
  10 use Storable;
  11 use Scalar::Util qw/weaken/;
  12
  13 use base qw/DBIx::Class/;
  14 __PACKAGE__->load_components(qw/AccessorGroup/);
  15 __PACKAGE__->mk_group_accessors('simple' => qw/result_source result_class/);
  16
  17 =head1 NAME
  18
  19 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  20
  21 =head1 SYNOPSIS
  22
  23   my $rs   = $schema->resultset('User')->search(registered => 1);
  24   my @rows = $schema->resultset('CD')->search(year => 2005);
  25
  26 =head1 DESCRIPTION
  27
  28 The resultset is also known as an iterator. It is responsible for handling
  29 queries that may return an arbitrary number of rows, e.g. via L</search>
  30 or a C<has_many> relationship.
  31
  32 In the examples below, the following table classes are used:
  33
  34   package MyApp::Schema::Artist;
  35   use base qw/DBIx::Class/;
  36   __PACKAGE__->load_components(qw/Core/);
  37   __PACKAGE__->table('artist');
  38   __PACKAGE__->add_columns(qw/artistid name/);
  39   __PACKAGE__->set_primary_key('artistid');
  40   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  41   1;
  42
  43   package MyApp::Schema::CD;
  44   use base qw/DBIx::Class/;
  45   __PACKAGE__->load_components(qw/Core/);
  46   __PACKAGE__->table('cd');
  47   __PACKAGE__->add_columns(qw/cdid artist title year/);
  48   __PACKAGE__->set_primary_key('cdid');
  49   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  50   1;
  51
  52 =head1 METHODS
  53
  54 =head2 new
  55
  56 =over 4
  57
  58 =item Arguments: $source, \%$attrs
  59
  60 =item Return Value: $rs
  61
  62 =back
  63
  64 The resultset constructor. Takes a source object (usually a
  65 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  66 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  67 executed as needed by the other methods.
  68
  69 Generally you won't need to construct a resultset manually.  You'll
  70 automatically get one from e.g. a L</search> called in scalar context:
  71
  72   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  73
  74 IMPORTANT: If called on an object, proxies to new_result instead so
  75
  76   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  77
  78 will return a CD object, not a ResultSet.
  79
  80 =cut
  81
  82 sub new {
  83   my $class = shift;
  84   return $class->new_result(@_) if ref $class;
  85
  86   my ($source, $attrs) = @_;
  87   weaken $source;
  88   $attrs = Storable::dclone($attrs || {}); # { %{ $attrs || {} } };
  89   #use Data::Dumper; warn Dumper($attrs);
  90   my $alias = ($attrs->{alias} ||= 'me');
  91
  92   $attrs->{columns} ||= delete $attrs->{cols} if $attrs->{cols};
  93   delete $attrs->{as} if $attrs->{columns};
  94   $attrs->{columns} ||= [ $source->columns ] unless $attrs->{select};
  95   $attrs->{select} = [
  96     map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}}
  97   ] if $attrs->{columns};
  98   $attrs->{as} ||= [
  99     map { m/^\Q$alias.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}}
 100   ];
 101   if (my $include = delete $attrs->{include_columns}) {
 102     push(@{$attrs->{select}}, @$include);
 103     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1; } @$include);
 104   }
 105   #use Data::Dumper; warn Dumper(@{$attrs}{qw/select as/});
 106
 107   $attrs->{from} ||= [ { $alias => $source->from } ];
 108   $attrs->{seen_join} ||= {};
 109   my %seen;
 110   if (my $join = delete $attrs->{join}) {
 111     foreach my $j (ref $join eq 'ARRAY' ? @$join : ($join)) {
 112       if (ref $j eq 'HASH') {
 113         $seen{$_} = 1 foreach keys %$j;
 114       } else {
 115         $seen{$j} = 1;
 116       }
 117     }
 118     push(@{$attrs->{from}}, $source->resolve_join(
 119       $join, $attrs->{alias}, $attrs->{seen_join})
 120     );
 121   }
 122
 123   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
 124   $attrs->{order_by} = [ $attrs->{order_by} ] if
 125     $attrs->{order_by} and !ref($attrs->{order_by});
 126   $attrs->{order_by} ||= [];
 127
 128   my $collapse = $attrs->{collapse} || {};
 129   if (my $prefetch = delete $attrs->{prefetch}) {
 130     my @pre_order;
 131     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
 132       if ( ref $p eq 'HASH' ) {
 133         foreach my $key (keys %$p) {
 134           push(@{$attrs->{from}}, $source->resolve_join($p, $attrs->{alias}))
 135             unless $seen{$key};
 136         }
 137       } else {
 138         push(@{$attrs->{from}}, $source->resolve_join($p, $attrs->{alias}))
 139             unless $seen{$p};
 140       }
 141       my @prefetch = $source->resolve_prefetch(
 142            $p, $attrs->{alias}, {}, \@pre_order, $collapse);
 143       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
 144       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
 145     }
 146     push(@{$attrs->{order_by}}, @pre_order);
 147   }
 148   $attrs->{collapse} = $collapse;
 149 #  use Data::Dumper; warn Dumper($collapse) if keys %{$collapse};
 150
 151   if ($attrs->{page}) {
 152     $attrs->{rows} ||= 10;
 153     $attrs->{offset} ||= 0;
 154     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
 155   }
 156
 157   bless {
 158     result_source => $source,
 159     result_class => $attrs->{result_class} || $source->result_class,
 160     cond => $attrs->{where},
 161     from => $attrs->{from},
 162     collapse => $collapse,
 163     count => undef,
 164     page => delete $attrs->{page},
 165     pager => undef,
 166     attrs => $attrs
 167   }, $class;
 168 }
 169
 170 =head2 search
 171
 172 =over 4
 173
 174 =item Arguments: $cond, \%attrs?
 175
 176 =item Return Value: $resultset (scalar context), @row_objs (list context)
 177
 178 =back
 179
 180   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 181   my $new_rs = $cd_rs->search({ year => 2005 });
 182
 183   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 184                  # year = 2005 OR year = 2004
 185
 186 If you need to pass in additional attributes but no additional condition,
 187 call it as C<search(undef, \%attrs)>.
 188
 189   # "SELECT name, artistid FROM $artist_table"
 190   my @all_artists = $schema->resultset('Artist')->search(undef, {
 191     columns => [qw/name artistid/],
 192   });
 193
 194 =cut
 195
 196 sub search {
 197   my $self = shift;
 198
 199   my $attrs = { %{$self->{attrs}} };
 200   my $having = delete $attrs->{having};
 201   $attrs = { %$attrs, %{ pop(@_) } } if @_ > 1 and ref $_[$#_] eq 'HASH';
 202
 203   my $where = (@_
 204                 ? ((@_ == 1 || ref $_[0] eq "HASH")
 205                     ? shift
 206                     : ((@_ % 2)
 207                         ? $self->throw_exception(
 208                             "Odd number of arguments to search")
 209                         : {@_}))
 210                 : undef());
 211   if (defined $where) {
 212     $attrs->{where} = (defined $attrs->{where}
 213               ? { '-and' =>
 214                   [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 215                       $where, $attrs->{where} ] }
 216               : $where);
 217   }
 218
 219   if (defined $having) {
 220     $attrs->{having} = (defined $attrs->{having}
 221               ? { '-and' =>
 222                   [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 223                       $having, $attrs->{having} ] }
 224               : $having);
 225   }
 226
 227   my $rs = (ref $self)->new($self->result_source, $attrs);
 228
 229   unless (@_) { # no search, effectively just a clone
 230     my $rows = $self->get_cache;
 231     if ($rows) {
 232       $rs->set_cache($rows);
 233     }
 234   }
 235
 236   return (wantarray ? $rs->all : $rs);
 237 }
 238
 239 =head2 search_literal
 240
 241 =over 4
 242
 243 =item Arguments: $sql_fragment, @bind_values
 244
 245 =item Return Value: $resultset (scalar context), @row_objs (list context)
 246
 247 =back
 248
 249   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 250   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 251
 252 Pass a literal chunk of SQL to be added to the conditional part of the
 253 resultset query.
 254
 255 =cut
 256
 257 sub search_literal {
 258   my ($self, $cond, @vals) = @_;
 259   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 260   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 261   return $self->search(\$cond, $attrs);
 262 }
 263
 264 =head2 find
 265
 266 =over 4
 267
 268 =item Arguments: @values | \%cols, \%attrs?
 269
 270 =item Return Value: $row_object
 271
 272 =back
 273
 274 Finds a row based on its primary key or unique constraint. For example:
 275
 276   my $cd = $schema->resultset('CD')->find(5);
 277
 278 Also takes an optional C<key> attribute, to search by a specific key or unique
 279 constraint. For example:
 280
 281   my $cd = $schema->resultset('CD')->find(
 282     {
 283       artist => 'Massive Attack',
 284       title  => 'Mezzanine',
 285     },
 286     { key => 'artist_title' }
 287   );
 288
 289 See also L</find_or_create> and L</update_or_create>.
 290
 291 =cut
 292
 293 sub find {
 294   my ($self, @vals) = @_;
 295   my $attrs = (@vals > 1 && ref $vals[$#vals] eq 'HASH' ? pop(@vals) : {});
 296
 297   my @cols = $self->result_source->primary_columns;
 298   if (exists $attrs->{key}) {
 299     my %uniq = $self->result_source->unique_constraints;
 300     $self->throw_exception(
 301       "Unknown key $attrs->{key} on '" . $self->result_source->name . "'"
 302     ) unless exists $uniq{$attrs->{key}};
 303     @cols = @{ $uniq{$attrs->{key}} };
 304   }
 305   #use Data::Dumper; warn Dumper($attrs, @vals, @cols);
 306   $self->throw_exception(
 307     "Can't find unless a primary key or unique constraint is defined"
 308   ) unless @cols;
 309
 310   my $query;
 311   if (ref $vals[0] eq 'HASH') {
 312     $query = { %{$vals[0]} };
 313   } elsif (@cols == @vals) {
 314     $query = {};
 315     @{$query}{@cols} = @vals;
 316   } else {
 317     $query = {@vals};
 318   }
 319   foreach my $key (grep { ! m/\./ } keys %$query) {
 320     $query->{"$self->{attrs}{alias}.$key"} = delete $query->{$key};
 321   }
 322   #warn Dumper($query);
 323
 324   if (keys %$attrs) {
 325       my $rs = $self->search($query,$attrs);
 326       return keys %{$rs->{collapse}} ? $rs->next : $rs->single;
 327   } else {
 328       return keys %{$self->{collapse}} ?
 329         $self->search($query)->next :
 330         $self->single($query);
 331   }
 332 }
 333
 334 =head2 search_related
 335
 336 =over 4
 337
 338 =item Arguments: $cond, \%attrs?
 339
 340 =item Return Value: $new_resultset
 341
 342 =back
 343
 344   $new_rs = $cd_rs->search_related('artist', {
 345     name => 'Emo-R-Us',
 346   });
 347
 348 Searches the specified relationship, optionally specifying a condition and
 349 attributes for matching records. See L</ATTRIBUTES> for more information.
 350
 351 =cut
 352
 353 sub search_related {
 354   return shift->related_resultset(shift)->search(@_);
 355 }
 356
 357 =head2 cursor
 358
 359 =over 4
 360
 361 =item Arguments: none
 362
 363 =item Return Value: $cursor
 364
 365 =back
 366
 367 Returns a storage-driven cursor to the given resultset. See
 368 L<DBIx::Class::Cursor> for more information.
 369
 370 =cut
 371
 372 sub cursor {
 373   my ($self) = @_;
 374   my $attrs = { %{$self->{attrs}} };
 375   return $self->{cursor}
 376     ||= $self->result_source->storage->select($self->{from}, $attrs->{select},
 377           $attrs->{where},$attrs);
 378 }
 379
 380 =head2 single
 381
 382 =over 4
 383
 384 =item Arguments: $cond?
 385
 386 =item Return Value: $row_object?
 387
 388 =back
 389
 390   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 391
 392 Inflates the first result without creating a cursor if the resultset has
 393 any records in it; if not returns nothing. Used by find() as an optimisation.
 394
 395 Can optionally take an additional condition *only* - this is a fast-code-path
 396 method; if you need to add extra joins or similar call ->search and then
 397 ->single without a condition on the $rs returned from that.
 398
 399 =cut
 400
 401 sub single {
 402   my ($self, $where) = @_;
 403   my $attrs = { %{$self->{attrs}} };
 404   if ($where) {
 405     if (defined $attrs->{where}) {
 406       $attrs->{where} = {
 407         '-and' =>
 408             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 409                $where, delete $attrs->{where} ]
 410       };
 411     } else {
 412       $attrs->{where} = $where;
 413     }
 414   }
 415   my @data = $self->result_source->storage->select_single(
 416           $self->{from}, $attrs->{select},
 417           $attrs->{where},$attrs);
 418   return (@data ? $self->_construct_object(@data) : ());
 419 }
 420
 421
 422 =head2 search_like
 423
 424 =over 4
 425
 426 =item Arguments: $cond, \%attrs?
 427
 428 =item Return Value: $resultset (scalar context), @row_objs (list context)
 429
 430 =back
 431
 432   # WHERE title LIKE '%blue%'
 433   $cd_rs = $rs->search_like({ title => '%blue%'});
 434
 435 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 436 that this is simply a convenience method. You most likely want to use
 437 L</search> with specific operators.
 438
 439 For more information, see L<DBIx::Class::Manual::Cookbook>.
 440
 441 =cut
 442
 443 sub search_like {
 444   my $class = shift;
 445   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 446   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 447   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 448   return $class->search($query, { %$attrs });
 449 }
 450
 451 =head2 slice
 452
 453 =over 4
 454
 455 =item Arguments: $first, $last
 456
 457 =item Return Value: $resultset (scalar context), @row_objs (list context)
 458
 459 =back
 460
 461 Returns a resultset or object list representing a subset of elements from the
 462 resultset slice is called on. Indexes are from 0, i.e., to get the first
 463 three records, call:
 464
 465   my ($one, $two, $three) = $rs->slice(0, 2);
 466
 467 =cut
 468
 469 sub slice {
 470   my ($self, $min, $max) = @_;
 471   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 472   $attrs->{offset} = $self->{attrs}{offset} || 0;
 473   $attrs->{offset} += $min;
 474   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 475   return $self->search(undef(), $attrs);
 476   #my $slice = (ref $self)->new($self->result_source, $attrs);
 477   #return (wantarray ? $slice->all : $slice);
 478 }
 479
 480 =head2 next
 481
 482 =over 4
 483
 484 =item Arguments: none
 485
 486 =item Return Value: $result?
 487
 488 =back
 489
 490 Returns the next element in the resultset (C<undef> is there is none).
 491
 492 Can be used to efficiently iterate over records in the resultset:
 493
 494   my $rs = $schema->resultset('CD')->search;
 495   while (my $cd = $rs->next) {
 496     print $cd->title;
 497   }
 498
 499 Note that you need to store the resultset object, and call C<next> on it.
 500 Calling C<< resultset('Table')->next >> repeatedly will always return the
 501 first record from the resultset.
 502
 503 =cut
 504
 505 sub next {
 506   my ($self) = @_;
 507   if (my $cache = $self->get_cache) {
 508     $self->{all_cache_position} ||= 0;
 509     return $cache->[$self->{all_cache_position}++];
 510   }
 511   if ($self->{attrs}{cache}) {
 512     $self->{all_cache_position} = 1;
 513     return ($self->all)[0];
 514   }
 515   my @row = (exists $self->{stashed_row} ?
 516                @{delete $self->{stashed_row}} :
 517                $self->cursor->next
 518   );
 519 #  warn Dumper(\@row); use Data::Dumper;
 520   return unless (@row);
 521   return $self->_construct_object(@row);
 522 }
 523
 524 sub _construct_object {
 525   my ($self, @row) = @_;
 526   my @as = @{ $self->{attrs}{as} };
 527
 528   my $info = $self->_collapse_result(\@as, \@row);
 529
 530   my $new = $self->result_class->inflate_result($self->result_source, @$info);
 531
 532   $new = $self->{attrs}{record_filter}->($new)
 533     if exists $self->{attrs}{record_filter};
 534   return $new;
 535 }
 536
 537 sub _collapse_result {
 538   my ($self, $as, $row, $prefix) = @_;
 539
 540   my %const;
 541
 542   my @copy = @$row;
 543   foreach my $this_as (@$as) {
 544     my $val = shift @copy;
 545     if (defined $prefix) {
 546       if ($this_as =~ m/^\Q${prefix}.\E(.+)$/) {
 547         my $remain = $1;
 548         $remain =~ /^(?:(.*)\.)?([^.]+)$/;
 549         $const{$1||''}{$2} = $val;
 550       }
 551     } else {
 552       $this_as =~ /^(?:(.*)\.)?([^.]+)$/;
 553       $const{$1||''}{$2} = $val;
 554     }
 555   }
 556
 557   my $info = [ {}, {} ];
 558   foreach my $key (keys %const) {
 559     if (length $key) {
 560       my $target = $info;
 561       my @parts = split(/\./, $key);
 562       foreach my $p (@parts) {
 563         $target = $target->[1]->{$p} ||= [];
 564       }
 565       $target->[0] = $const{$key};
 566     } else {
 567       $info->[0] = $const{$key};
 568     }
 569   }
 570
 571   my @collapse;
 572   if (defined $prefix) {
 573     @collapse = map {
 574         m/^\Q${prefix}.\E(.+)$/ ? ($1) : ()
 575     } keys %{$self->{collapse}}
 576   } else {
 577     @collapse = keys %{$self->{collapse}};
 578   };
 579
 580   if (@collapse) {
 581     my ($c) = sort { length $a <=> length $b } @collapse;
 582     my $target = $info;
 583     foreach my $p (split(/\./, $c)) {
 584       $target = $target->[1]->{$p} ||= [];
 585     }
 586     my $c_prefix = (defined($prefix) ? "${prefix}.${c}" : $c);
 587     my @co_key = @{$self->{collapse}{$c_prefix}};
 588     my %co_check = map { ($_, $target->[0]->{$_}); } @co_key;
 589     my $tree = $self->_collapse_result($as, $row, $c_prefix);
 590     my (@final, @raw);
 591     while ( !(grep {
 592                 !defined($tree->[0]->{$_}) ||
 593                 $co_check{$_} ne $tree->[0]->{$_}
 594               } @co_key) ) {
 595       push(@final, $tree);
 596       last unless (@raw = $self->cursor->next);
 597       $row = $self->{stashed_row} = \@raw;
 598       $tree = $self->_collapse_result($as, $row, $c_prefix);
 599     }
 600     @$target = (@final ? @final : [ {}, {} ]);
 601       # single empty result to indicate an empty prefetched has_many
 602   }
 603
 604   return $info;
 605 }
 606
 607 =head2 result_source
 608
 609 =over 4
 610
 611 =item Arguments: $result_source?
 612
 613 =item Return Value: $result_source
 614
 615 =back
 616
 617 An accessor for the primary ResultSource object from which this ResultSet
 618 is derived.
 619
 620 =cut
 621
 622
 623 =head2 count
 624
 625 =over 4
 626
 627 =item Arguments: $cond, \%attrs??
 628
 629 =item Return Value: $count
 630
 631 =back
 632
 633 Performs an SQL C<COUNT> with the same query as the resultset was built
 634 with to find the number of elements. If passed arguments, does a search
 635 on the resultset and counts the results of that.
 636
 637 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 638 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 639 not support C<DISTINCT> with multiple columns. If you are using such a
 640 database, you should only use columns from the main table in your C<group_by>
 641 clause.
 642
 643 =cut
 644
 645 sub count {
 646   my $self = shift;
 647   return $self->search(@_)->count if @_ and defined $_[0];
 648   return scalar @{ $self->get_cache } if $self->get_cache;
 649
 650   my $count = $self->_count;
 651   return 0 unless $count;
 652
 653   $count -= $self->{attrs}{offset} if $self->{attrs}{offset};
 654   $count = $self->{attrs}{rows} if
 655     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 656   return $count;
 657 }
 658
 659 sub _count { # Separated out so pager can get the full count
 660   my $self = shift;
 661   my $select = { count => '*' };
 662   my $attrs = { %{ $self->{attrs} } };
 663   if (my $group_by = delete $attrs->{group_by}) {
 664     delete $attrs->{having};
 665     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 666     # todo: try CONCAT for multi-column pk
 667     my @pk = $self->result_source->primary_columns;
 668     if (@pk == 1) {
 669       foreach my $column (@distinct) {
 670         if ($column =~ qr/^(?:\Q$attrs->{alias}.\E)?$pk[0]$/) {
 671           @distinct = ($column);
 672           last;
 673         }
 674       }
 675     }
 676
 677     $select = { count => { distinct => \@distinct } };
 678     #use Data::Dumper; die Dumper $select;
 679   }
 680
 681   $attrs->{select} = $select;
 682   $attrs->{as} = [qw/count/];
 683
 684   # offset, order by and page are not needed to count. record_filter is cdbi
 685   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 686
 687   my ($count) = (ref $self)->new($self->result_source, $attrs)->cursor->next;
 688   return $count;
 689 }
 690
 691 =head2 count_literal
 692
 693 =over 4
 694
 695 =item Arguments: $sql_fragment, @bind_values
 696
 697 =item Return Value: $count
 698
 699 =back
 700
 701 Counts the results in a literal query. Equivalent to calling L</search_literal>
 702 with the passed arguments, then L</count>.
 703
 704 =cut
 705
 706 sub count_literal { shift->search_literal(@_)->count; }
 707
 708 =head2 all
 709
 710 =over 4
 711
 712 =item Arguments: none
 713
 714 =item Return Value: @objects
 715
 716 =back
 717
 718 Returns all elements in the resultset. Called implicitly if the resultset
 719 is returned in list context.
 720
 721 =cut
 722
 723 sub all {
 724   my ($self) = @_;
 725   return @{ $self->get_cache } if $self->get_cache;
 726
 727   my @obj;
 728
 729   if (keys %{$self->{collapse}}) {
 730       # Using $self->cursor->all is really just an optimisation.
 731       # If we're collapsing has_many prefetches it probably makes
 732       # very little difference, and this is cleaner than hacking
 733       # _construct_object to survive the approach
 734     $self->cursor->reset;
 735     my @row = $self->cursor->next;
 736     while (@row) {
 737       push(@obj, $self->_construct_object(@row));
 738       @row = (exists $self->{stashed_row}
 739                ? @{delete $self->{stashed_row}}
 740                : $self->cursor->next);
 741     }
 742   } else {
 743     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
 744   }
 745
 746   $self->set_cache(\@obj) if $self->{attrs}{cache};
 747   return @obj;
 748 }
 749
 750 =head2 reset
 751
 752 =over 4
 753
 754 =item Arguments: none
 755
 756 =item Return Value: $self
 757
 758 =back
 759
 760 Resets the resultset's cursor, so you can iterate through the elements again.
 761
 762 =cut
 763
 764 sub reset {
 765   my ($self) = @_;
 766   $self->{all_cache_position} = 0;
 767   $self->cursor->reset;
 768   return $self;
 769 }
 770
 771 =head2 first
 772
 773 =over 4
 774
 775 =item Arguments: none
 776
 777 =item Return Value: $object?
 778
 779 =back
 780
 781 Resets the resultset and returns an object for the first result (if the
 782 resultset returns anything).
 783
 784 =cut
 785
 786 sub first {
 787   return $_[0]->reset->next;
 788 }
 789
 790 # _cond_for_update_delete
 791 #
 792 # update/delete require the condition to be modified to handle
 793 # the differing SQL syntax available.  This transforms the $self->{cond}
 794 # appropriately, returning the new condition.
 795
 796 sub _cond_for_update_delete {
 797   my ($self) = @_;
 798   my $cond = {};
 799
 800   if (!ref($self->{cond})) {
 801     # No-op. No condition, we're updating/deleting everything
 802   }
 803   elsif (ref $self->{cond} eq 'ARRAY') {
 804     $cond = [
 805       map {
 806         my %hash;
 807         foreach my $key (keys %{$_}) {
 808           $key =~ /([^.]+)$/;
 809           $hash{$1} = $_->{$key};
 810         }
 811         \%hash;
 812       } @{$self->{cond}}
 813     ];
 814   }
 815   elsif (ref $self->{cond} eq 'HASH') {
 816     if ((keys %{$self->{cond}})[0] eq '-and') {
 817       $cond->{-and} = [];
 818
 819       my @cond = @{$self->{cond}{-and}};
 820       for (my $i = 0; $i < @cond - 1; $i++) {
 821         my $entry = $cond[$i];
 822
 823         my %hash;
 824         if (ref $entry eq 'HASH') {
 825           foreach my $key (keys %{$entry}) {
 826             $key =~ /([^.]+)$/;
 827             $hash{$1} = $entry->{$key};
 828           }
 829         }
 830         else {
 831           $entry =~ /([^.]+)$/;
 832           $hash{$entry} = $cond[++$i];
 833         }
 834
 835         push @{$cond->{-and}}, \%hash;
 836       }
 837     }
 838     else {
 839       foreach my $key (keys %{$self->{cond}}) {
 840         $key =~ /([^.]+)$/;
 841         $cond->{$1} = $self->{cond}{$key};
 842       }
 843     }
 844   }
 845   else {
 846     $self->throw_exception(
 847       "Can't update/delete on resultset with condition unless hash or array"
 848     );
 849   }
 850
 851   return $cond;
 852 }
 853
 854
 855 =head2 update
 856
 857 =over 4
 858
 859 =item Arguments: \%values
 860
 861 =item Return Value: $storage_rv
 862
 863 =back
 864
 865 Sets the specified columns in the resultset to the supplied values in a
 866 single query. Return value will be true if the update succeeded or false
 867 if no records were updated; exact type of success value is storage-dependent.
 868
 869 =cut
 870
 871 sub update {
 872   my ($self, $values) = @_;
 873   $self->throw_exception("Values for update must be a hash")
 874     unless ref $values eq 'HASH';
 875
 876   my $cond = $self->_cond_for_update_delete;
 877
 878   return $self->result_source->storage->update(
 879     $self->result_source->from, $values, $cond
 880   );
 881 }
 882
 883 =head2 update_all
 884
 885 =over 4
 886
 887 =item Arguments: \%values
 888
 889 =item Return Value: 1
 890
 891 =back
 892
 893 Fetches all objects and updates them one at a time. Note that C<update_all>
 894 will run DBIC cascade triggers, while L</update> will not.
 895
 896 =cut
 897
 898 sub update_all {
 899   my ($self, $values) = @_;
 900   $self->throw_exception("Values for update must be a hash")
 901     unless ref $values eq 'HASH';
 902   foreach my $obj ($self->all) {
 903     $obj->set_columns($values)->update;
 904   }
 905   return 1;
 906 }
 907
 908 =head2 delete
 909
 910 =over 4
 911
 912 =item Arguments: none
 913
 914 =item Return Value: 1
 915
 916 =back
 917
 918 Deletes the contents of the resultset from its result source. Note that this
 919 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
 920 to run.
 921
 922 =cut
 923
 924 sub delete {
 925   my ($self) = @_;
 926   my $del = {};
 927
 928   my $cond = $self->_cond_for_update_delete;
 929
 930   $self->result_source->storage->delete($self->result_source->from, $cond);
 931   return 1;
 932 }
 933
 934 =head2 delete_all
 935
 936 =over 4
 937
 938 =item Arguments: none
 939
 940 =item Return Value: 1
 941
 942 =back
 943
 944 Fetches all objects and deletes them one at a time. Note that C<delete_all>
 945 will run DBIC cascade triggers, while L</delete> will not.
 946
 947 =cut
 948
 949 sub delete_all {
 950   my ($self) = @_;
 951   $_->delete for $self->all;
 952   return 1;
 953 }
 954
 955 =head2 pager
 956
 957 =over 4
 958
 959 =item Arguments: none
 960
 961 =item Return Value: $pager
 962
 963 =back
 964
 965 Return Value a L<Data::Page> object for the current resultset. Only makes
 966 sense for queries with a C<page> attribute.
 967
 968 =cut
 969
 970 sub pager {
 971   my ($self) = @_;
 972   my $attrs = $self->{attrs};
 973   $self->throw_exception("Can't create pager for non-paged rs")
 974     unless $self->{page};
 975   $attrs->{rows} ||= 10;
 976   return $self->{pager} ||= Data::Page->new(
 977     $self->_count, $attrs->{rows}, $self->{page});
 978 }
 979
 980 =head2 page
 981
 982 =over 4
 983
 984 =item Arguments: $page_number
 985
 986 =item Return Value: $rs
 987
 988 =back
 989
 990 Returns a resultset for the $page_number page of the resultset on which page
 991 is called, where each page contains a number of rows equal to the 'rows'
 992 attribute set on the resultset (10 by default).
 993
 994 =cut
 995
 996 sub page {
 997   my ($self, $page) = @_;
 998   my $attrs = { %{$self->{attrs}} };
 999   $attrs->{page} = $page;
1000   return (ref $self)->new($self->result_source, $attrs);
1001 }
1002
1003 =head2 new_result
1004
1005 =over 4
1006
1007 =item Arguments: \%vals
1008
1009 =item Return Value: $object
1010
1011 =back
1012
1013 Creates an object in the resultset's result class and returns it.
1014
1015 =cut
1016
1017 sub new_result {
1018   my ($self, $values) = @_;
1019   $self->throw_exception( "new_result needs a hash" )
1020     unless (ref $values eq 'HASH');
1021   $self->throw_exception(
1022     "Can't abstract implicit construct, condition not a hash"
1023   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1024   my %new = %$values;
1025   my $alias = $self->{attrs}{alias};
1026   foreach my $key (keys %{$self->{cond}||{}}) {
1027     $new{$1} = $self->{cond}{$key} if ($key =~ m/^(?:\Q${alias}.\E)?([^.]+)$/);
1028   }
1029   my $obj = $self->result_class->new(\%new);
1030   $obj->result_source($self->result_source) if $obj->can('result_source');
1031   return $obj;
1032 }
1033
1034 =head2 create
1035
1036 =over 4
1037
1038 =item Arguments: \%vals
1039
1040 =item Return Value: $object
1041
1042 =back
1043
1044 Inserts a record into the resultset and returns the object representing it.
1045
1046 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1047
1048 =cut
1049
1050 sub create {
1051   my ($self, $attrs) = @_;
1052   $self->throw_exception( "create needs a hashref" )
1053     unless ref $attrs eq 'HASH';
1054   return $self->new_result($attrs)->insert;
1055 }
1056
1057 =head2 find_or_create
1058
1059 =over 4
1060
1061 =item Arguments: \%vals, \%attrs?
1062
1063 =item Return Value: $object
1064
1065 =back
1066
1067   $class->find_or_create({ key => $val, ... });
1068
1069 Searches for a record matching the search condition; if it doesn't find one,
1070 creates one and returns that instead.
1071
1072   my $cd = $schema->resultset('CD')->find_or_create({
1073     cdid   => 5,
1074     artist => 'Massive Attack',
1075     title  => 'Mezzanine',
1076     year   => 2005,
1077   });
1078
1079 Also takes an optional C<key> attribute, to search by a specific key or unique
1080 constraint. For example:
1081
1082   my $cd = $schema->resultset('CD')->find_or_create(
1083     {
1084       artist => 'Massive Attack',
1085       title  => 'Mezzanine',
1086     },
1087     { key => 'artist_title' }
1088   );
1089
1090 See also L</find> and L</update_or_create>.
1091
1092 =cut
1093
1094 sub find_or_create {
1095   my $self     = shift;
1096   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1097   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1098   my $exists   = $self->find($hash, $attrs);
1099   return defined $exists ? $exists : $self->create($hash);
1100 }
1101
1102 =head2 update_or_create
1103
1104 =over 4
1105
1106 =item Arguments: \%col_values, { key => $unique_constraint }?
1107
1108 =item Return Value: $object
1109
1110 =back
1111
1112   $class->update_or_create({ col => $val, ... });
1113
1114 First, searches for an existing row matching one of the unique constraints
1115 (including the primary key) on the source of this resultset. If a row is
1116 found, updates it with the other given column values. Otherwise, creates a new
1117 row.
1118
1119 Takes an optional C<key> attribute to search on a specific unique constraint.
1120 For example:
1121
1122   # In your application
1123   my $cd = $schema->resultset('CD')->update_or_create(
1124     {
1125       artist => 'Massive Attack',
1126       title  => 'Mezzanine',
1127       year   => 1998,
1128     },
1129     { key => 'artist_title' }
1130   );
1131
1132 If no C<key> is specified, it searches on all unique constraints defined on the
1133 source, including the primary key.
1134
1135 If the C<key> is specified as C<primary>, it searches only on the primary key.
1136
1137 See also L</find> and L</find_or_create>.
1138
1139 =cut
1140
1141 sub update_or_create {
1142   my $self = shift;
1143   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1144   my $hash = ref $_[0] eq 'HASH' ? shift : {@_};
1145
1146   my %unique_constraints = $self->result_source->unique_constraints;
1147   my @constraint_names   = (exists $attrs->{key}
1148                             ? ($attrs->{key})
1149                             : keys %unique_constraints);
1150
1151   my @unique_hashes;
1152   foreach my $name (@constraint_names) {
1153     my @unique_cols = @{ $unique_constraints{$name} };
1154     my %unique_hash =
1155       map  { $_ => $hash->{$_} }
1156       grep { exists $hash->{$_} }
1157       @unique_cols;
1158
1159     push @unique_hashes, \%unique_hash
1160       if (scalar keys %unique_hash == scalar @unique_cols);
1161   }
1162
1163   if (@unique_hashes) {
1164     my $row = $self->single(\@unique_hashes);
1165     if (defined $row) {
1166       $row->update($hash);
1167       return $row;
1168     }
1169   }
1170
1171   return $self->create($hash);
1172 }
1173
1174 =head2 get_cache
1175
1176 =over 4
1177
1178 =item Arguments: none
1179
1180 =item Return Value: \@cache_objects?
1181
1182 =back
1183
1184 Gets the contents of the cache for the resultset, if the cache is set.
1185
1186 =cut
1187
1188 sub get_cache {
1189   shift->{all_cache};
1190 }
1191
1192 =head2 set_cache
1193
1194 =over 4
1195
1196 =item Arguments: \@cache_objects
1197
1198 =item Return Value: \@cache_objects
1199
1200 =back
1201
1202 Sets the contents of the cache for the resultset. Expects an arrayref
1203 of objects of the same class as those produced by the resultset. Note that
1204 if the cache is set the resultset will return the cached objects rather
1205 than re-querying the database even if the cache attr is not set.
1206
1207 =cut
1208
1209 sub set_cache {
1210   my ( $self, $data ) = @_;
1211   $self->throw_exception("set_cache requires an arrayref")
1212     if defined($data) && (ref $data ne 'ARRAY');
1213   $self->{all_cache} = $data;
1214 }
1215
1216 =head2 clear_cache
1217
1218 =over 4
1219
1220 =item Arguments: none
1221
1222 =item Return Value: []
1223
1224 =back
1225
1226 Clears the cache for the resultset.
1227
1228 =cut
1229
1230 sub clear_cache {
1231   shift->set_cache(undef);
1232 }
1233
1234 =head2 related_resultset
1235
1236 =over 4
1237
1238 =item Arguments: $relationship_name
1239
1240 =item Return Value: $resultset
1241
1242 =back
1243
1244 Returns a related resultset for the supplied relationship name.
1245
1246   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1247
1248 =cut
1249
1250 sub related_resultset {
1251   my ( $self, $rel ) = @_;
1252   $self->{related_resultsets} ||= {};
1253   return $self->{related_resultsets}{$rel} ||= do {
1254       #warn "fetching related resultset for rel '$rel'";
1255       my $rel_obj = $self->result_source->relationship_info($rel);
1256       $self->throw_exception(
1257         "search_related: result source '" . $self->result_source->name .
1258         "' has no such relationship ${rel}")
1259         unless $rel_obj; #die Dumper $self->{attrs};
1260
1261       my $rs = $self->search(undef, { join => $rel });
1262       my $alias = defined $rs->{attrs}{seen_join}{$rel}
1263                     && $rs->{attrs}{seen_join}{$rel} > 1
1264                   ? join('_', $rel, $rs->{attrs}{seen_join}{$rel})
1265                   : $rel;
1266
1267       $self->result_source->schema->resultset($rel_obj->{class}
1268            )->search( undef,
1269              { %{$rs->{attrs}},
1270                alias => $alias,
1271                select => undef,
1272                as => undef }
1273            );
1274   };
1275 }
1276
1277 =head2 throw_exception
1278
1279 See L<DBIx::Class::Schema/throw_exception> for details.
1280
1281 =cut
1282
1283 sub throw_exception {
1284   my $self=shift;
1285   $self->result_source->schema->throw_exception(@_);
1286 }
1287
1288 # XXX: FIXME: Attributes docs need clearing up
1289
1290 =head1 ATTRIBUTES
1291
1292 The resultset takes various attributes that modify its behavior. Here's an
1293 overview of them:
1294
1295 =head2 order_by
1296
1297 =over 4
1298
1299 =item Value: ($order_by | \@order_by)
1300
1301 =back
1302
1303 Which column(s) to order the results by. This is currently passed
1304 through directly to SQL, so you can give e.g. C<year DESC> for a
1305 descending order on the column `year'.
1306
1307 =head2 columns
1308
1309 =over 4
1310
1311 =item Value: \@columns
1312
1313 =back
1314
1315 Shortcut to request a particular set of columns to be retrieved.  Adds
1316 C<me.> onto the start of any column without a C<.> in it and sets C<select>
1317 from that, then auto-populates C<as> from C<select> as normal. (You may also
1318 use the C<cols> attribute, as in earlier versions of DBIC.)
1319
1320 =head2 include_columns
1321
1322 =over 4
1323
1324 =item Value: \@columns
1325
1326 =back
1327
1328 Shortcut to include additional columns in the returned results - for example
1329
1330   $schema->resultset('CD')->search(undef, {
1331     include_columns => ['artist.name'],
1332     join => ['artist']
1333   });
1334
1335 would return all CDs and include a 'name' column to the information
1336 passed to object inflation
1337
1338 =head2 select
1339
1340 =over 4
1341
1342 =item Value: \@select_columns
1343
1344 =back
1345
1346 Indicates which columns should be selected from the storage. You can use
1347 column names, or in the case of RDBMS back ends, function or stored procedure
1348 names:
1349
1350   $rs = $schema->resultset('Employee')->search(undef, {
1351     select => [
1352       'name',
1353       { count => 'employeeid' },
1354       { sum => 'salary' }
1355     ]
1356   });
1357
1358 When you use function/stored procedure names and do not supply an C<as>
1359 attribute, the column names returned are storage-dependent. E.g. MySQL would
1360 return a column named C<count(employeeid)> in the above example.
1361
1362 =head2 as
1363
1364 =over 4
1365
1366 =item Value: \@inflation_names
1367
1368 =back
1369
1370 Indicates column names for object inflation. This is used in conjunction with
1371 C<select>, usually when C<select> contains one or more function or stored
1372 procedure names:
1373
1374   $rs = $schema->resultset('Employee')->search(undef, {
1375     select => [
1376       'name',
1377       { count => 'employeeid' }
1378     ],
1379     as => ['name', 'employee_count'],
1380   });
1381
1382   my $employee = $rs->first(); # get the first Employee
1383
1384 If the object against which the search is performed already has an accessor
1385 matching a column name specified in C<as>, the value can be retrieved using
1386 the accessor as normal:
1387
1388   my $name = $employee->name();
1389
1390 If on the other hand an accessor does not exist in the object, you need to
1391 use C<get_column> instead:
1392
1393   my $employee_count = $employee->get_column('employee_count');
1394
1395 You can create your own accessors if required - see
1396 L<DBIx::Class::Manual::Cookbook> for details.
1397
1398 Please note: This will NOT insert an C<AS employee_count> into the SQL statement
1399 produced, it is used for internal access only. Thus attempting to use the accessor
1400 in an C<order_by> clause or similar will fail misrably.
1401
1402 =head2 join
1403
1404 =over 4
1405
1406 =item Value: ($rel_name | \@rel_names | \%rel_names)
1407
1408 =back
1409
1410 Contains a list of relationships that should be joined for this query.  For
1411 example:
1412
1413   # Get CDs by Nine Inch Nails
1414   my $rs = $schema->resultset('CD')->search(
1415     { 'artist.name' => 'Nine Inch Nails' },
1416     { join => 'artist' }
1417   );
1418
1419 Can also contain a hash reference to refer to the other relation's relations.
1420 For example:
1421
1422   package MyApp::Schema::Track;
1423   use base qw/DBIx::Class/;
1424   __PACKAGE__->table('track');
1425   __PACKAGE__->add_columns(qw/trackid cd position title/);
1426   __PACKAGE__->set_primary_key('trackid');
1427   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
1428   1;
1429
1430   # In your application
1431   my $rs = $schema->resultset('Artist')->search(
1432     { 'track.title' => 'Teardrop' },
1433     {
1434       join     => { cd => 'track' },
1435       order_by => 'artist.name',
1436     }
1437   );
1438
1439 If the same join is supplied twice, it will be aliased to <rel>_2 (and
1440 similarly for a third time). For e.g.
1441
1442   my $rs = $schema->resultset('Artist')->search({
1443     'cds.title'   => 'Down to Earth',
1444     'cds_2.title' => 'Popular',
1445   }, {
1446     join => [ qw/cds cds/ ],
1447   });
1448
1449 will return a set of all artists that have both a cd with title 'Down
1450 to Earth' and a cd with title 'Popular'.
1451
1452 If you want to fetch related objects from other tables as well, see C<prefetch>
1453 below.
1454
1455 =head2 prefetch
1456
1457 =over 4
1458
1459 =item Value: ($rel_name | \@rel_names | \%rel_names)
1460
1461 =back
1462
1463 Contains one or more relationships that should be fetched along with the main
1464 query (when they are accessed afterwards they will have already been
1465 "prefetched").  This is useful for when you know you will need the related
1466 objects, because it saves at least one query:
1467
1468   my $rs = $schema->resultset('Tag')->search(
1469     undef,
1470     {
1471       prefetch => {
1472         cd => 'artist'
1473       }
1474     }
1475   );
1476
1477 The initial search results in SQL like the following:
1478
1479   SELECT tag.*, cd.*, artist.* FROM tag
1480   JOIN cd ON tag.cd = cd.cdid
1481   JOIN artist ON cd.artist = artist.artistid
1482
1483 L<DBIx::Class> has no need to go back to the database when we access the
1484 C<cd> or C<artist> relationships, which saves us two SQL statements in this
1485 case.
1486
1487 Simple prefetches will be joined automatically, so there is no need
1488 for a C<join> attribute in the above search. If you're prefetching to
1489 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
1490 specify the join as well.
1491
1492 C<prefetch> can be used with the following relationship types: C<belongs_to>,
1493 C<has_one> (or if you're using C<add_relationship>, any relationship declared
1494 with an accessor type of 'single' or 'filter').
1495
1496 =head2 page
1497
1498 =over 4
1499
1500 =item Value: $page
1501
1502 =back
1503
1504 Makes the resultset paged and specifies the page to retrieve. Effectively
1505 identical to creating a non-pages resultset and then calling ->page($page)
1506 on it.
1507
1508 =head2 rows
1509
1510 =over 4
1511
1512 =item Value: $rows
1513
1514 =back
1515
1516 Specifes the maximum number of rows for direct retrieval or the number of
1517 rows per page if the page attribute or method is used.
1518
1519 =head2 group_by
1520
1521 =over 4
1522
1523 =item Value: \@columns
1524
1525 =back
1526
1527 A arrayref of columns to group by. Can include columns of joined tables.
1528
1529   group_by => [qw/ column1 column2 ... /]
1530
1531 =head2 having
1532
1533 =over 4
1534
1535 =item Value: $condition
1536
1537 =back
1538
1539 HAVING is a select statement attribute that is applied between GROUP BY and
1540 ORDER BY. It is applied to the after the grouping calculations have been
1541 done.
1542
1543   having => { 'count(employee)' => { '>=', 100 } }
1544
1545 =head2 distinct
1546
1547 =over 4
1548
1549 =item Value: (0 | 1)
1550
1551 =back
1552
1553 Set to 1 to group by all columns.
1554
1555 =head2 cache
1556
1557 Set to 1 to cache search results. This prevents extra SQL queries if you
1558 revisit rows in your ResultSet:
1559
1560   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
1561
1562   while( my $artist = $resultset->next ) {
1563     ... do stuff ...
1564   }
1565
1566   $rs->first; # without cache, this would issue a query
1567
1568 By default, searches are not cached.
1569
1570 For more examples of using these attributes, see
1571 L<DBIx::Class::Manual::Cookbook>.
1572
1573 =head2 from
1574
1575 =over 4
1576
1577 =item Value: \@from_clause
1578
1579 =back
1580
1581 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
1582 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
1583 clauses.
1584
1585 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
1586
1587 C<join> will usually do what you need and it is strongly recommended that you
1588 avoid using C<from> unless you cannot achieve the desired result using C<join>.
1589 And we really do mean "cannot", not just tried and failed. Attempting to use
1590 this because you're having problems with C<join> is like trying to use x86
1591 ASM because you've got a syntax error in your C. Trust us on this.
1592
1593 Now, if you're still really, really sure you need to use this (and if you're
1594 not 100% sure, ask the mailing list first), here's an explanation of how this
1595 works.
1596
1597 The syntax is as follows -
1598
1599   [
1600     { <alias1> => <table1> },
1601     [
1602       { <alias2> => <table2>, -join_type => 'inner|left|right' },
1603       [], # nested JOIN (optional)
1604       { <table1.column1> => <table2.column2>, ... (more conditions) },
1605     ],
1606     # More of the above [ ] may follow for additional joins
1607   ]
1608
1609   <table1> <alias1>
1610   JOIN
1611     <table2> <alias2>
1612     [JOIN ...]
1613   ON <table1.column1> = <table2.column2>
1614   <more joins may follow>
1615
1616 An easy way to follow the examples below is to remember the following:
1617
1618     Anything inside "[]" is a JOIN
1619     Anything inside "{}" is a condition for the enclosing JOIN
1620
1621 The following examples utilize a "person" table in a family tree application.
1622 In order to express parent->child relationships, this table is self-joined:
1623
1624     # Person->belongs_to('father' => 'Person');
1625     # Person->belongs_to('mother' => 'Person');
1626
1627 C<from> can be used to nest joins. Here we return all children with a father,
1628 then search against all mothers of those children:
1629
1630   $rs = $schema->resultset('Person')->search(
1631       undef,
1632       {
1633           alias => 'mother', # alias columns in accordance with "from"
1634           from => [
1635               { mother => 'person' },
1636               [
1637                   [
1638                       { child => 'person' },
1639                       [
1640                           { father => 'person' },
1641                           { 'father.person_id' => 'child.father_id' }
1642                       ]
1643                   ],
1644                   { 'mother.person_id' => 'child.mother_id' }
1645               ],
1646           ]
1647       },
1648   );
1649
1650   # Equivalent SQL:
1651   # SELECT mother.* FROM person mother
1652   # JOIN (
1653   #   person child
1654   #   JOIN person father
1655   #   ON ( father.person_id = child.father_id )
1656   # )
1657   # ON ( mother.person_id = child.mother_id )
1658
1659 The type of any join can be controlled manually. To search against only people
1660 with a father in the person table, we could explicitly use C<INNER JOIN>:
1661
1662     $rs = $schema->resultset('Person')->search(
1663         undef,
1664         {
1665             alias => 'child', # alias columns in accordance with "from"
1666             from => [
1667                 { child => 'person' },
1668                 [
1669                     { father => 'person', -join_type => 'inner' },
1670                     { 'father.id' => 'child.father_id' }
1671                 ],
1672             ]
1673         },
1674     );
1675
1676     # Equivalent SQL:
1677     # SELECT child.* FROM person child
1678     # INNER JOIN person father ON child.father_id = father.id
1679
1680 =cut
1681
1682 1;