lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 665
 666   return $self->{cursor}
 667     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 668           $attrs->{where},$attrs);
 669 }
 670
 671 =head2 single
 672
 673 =over 4
 674
 675 =item Arguments: $cond?
 676
 677 =item Return Value: $row_object?
 678
 679 =back
 680
 681   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 682
 683 Inflates the first result without creating a cursor if the resultset has
 684 any records in it; if not returns nothing. Used by L</find> as a lean version of
 685 L</search>.
 686
 687 While this method can take an optional search condition (just like L</search>)
 688 being a fast-code-path it does not recognize search attributes. If you need to
 689 add extra joins or similar, call L</search> and then chain-call L</single> on the
 690 L<DBIx::Class::ResultSet> returned.
 691
 692 =over
 693
 694 =item B<Note>
 695
 696 As of 0.08100, this method enforces the assumption that the preceeding
 697 query returns only one row. If more than one row is returned, you will receive
 698 a warning:
 699
 700   Query returned more than one row
 701
 702 In this case, you should be using L</first> or L</find> instead, or if you really
 703 know what you are doing, use the L</rows> attribute to explicitly limit the size
 704 of the resultset.
 705
 706 =back
 707
 708 =cut
 709
 710 sub single {
 711   my ($self, $where) = @_;
 712   if(@_ > 2) {
 713       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 714   }
 715
 716   my $attrs = $self->_resolved_attrs_copy;
 717   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 718
 719   if ($where) {
 720     if (defined $attrs->{where}) {
 721       $attrs->{where} = {
 722         '-and' =>
 723             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 724                $where, delete $attrs->{where} ]
 725       };
 726     } else {
 727       $attrs->{where} = $where;
 728     }
 729   }
 730
 731 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 732 #  unless ($self->_is_unique_query($attrs->{where})) {
 733 #    carp "Query not guaranteed to return a single row"
 734 #      . "; please declare your unique constraints or use search instead";
 735 #  }
 736
 737   my @data = $self->result_source->storage->select_single(
 738     $attrs->{from}, $attrs->{select},
 739     $attrs->{where}, $attrs
 740   );
 741
 742   return (@data ? ($self->_construct_object(@data))[0] : undef);
 743 }
 744
 745 # _gen_virtual_order
 746 #
 747 # This is a horrble hack, but seems like the best we can do at this point
 748 # Some limit emulations (Top) require an ordered resultset in order to
 749 # function at all. So supply a PK order to be used if necessary
 750
 751 sub _gen_virtual_order {
 752   return [ shift->result_source->primary_columns ];
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp (
 874     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 875    .' Instead use ->search({ x => { -like => "y%" } })'
 876    .' (note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. Passing arguments is equivalent to
1149 C<< $rs->search ($cond, \%attrs)->count >>
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my $meth = $self->_has_attr (qw/prefetch collapse distinct group_by/)
1159     ? 'count_grouped'
1160     : 'count'
1161   ;
1162
1163   my $attrs = $self->_resolved_attrs_copy;
1164   my $rsrc = $self->result_source;
1165
1166   return $rsrc->storage->$meth ($rsrc, $attrs);
1167 }
1168
1169 sub _bool {
1170   return 1;
1171 }
1172
1173 =head2 count_literal
1174
1175 =over 4
1176
1177 =item Arguments: $sql_fragment, @bind_values
1178
1179 =item Return Value: $count
1180
1181 =back
1182
1183 Counts the results in a literal query. Equivalent to calling L</search_literal>
1184 with the passed arguments, then L</count>.
1185
1186 =cut
1187
1188 sub count_literal { shift->search_literal(@_)->count; }
1189
1190 =head2 all
1191
1192 =over 4
1193
1194 =item Arguments: none
1195
1196 =item Return Value: @objects
1197
1198 =back
1199
1200 Returns all elements in the resultset. Called implicitly if the resultset
1201 is returned in list context.
1202
1203 =cut
1204
1205 sub all {
1206   my $self = shift;
1207   if(@_) {
1208       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1209   }
1210
1211   return @{ $self->get_cache } if $self->get_cache;
1212
1213   my @obj;
1214
1215   # TODO: don't call resolve here
1216   if (keys %{$self->_resolved_attrs->{collapse}}) {
1217 #  if ($self->{attrs}{prefetch}) {
1218       # Using $self->cursor->all is really just an optimisation.
1219       # If we're collapsing has_many prefetches it probably makes
1220       # very little difference, and this is cleaner than hacking
1221       # _construct_object to survive the approach
1222     my @row = $self->cursor->next;
1223     while (@row) {
1224       push(@obj, $self->_construct_object(@row));
1225       @row = (exists $self->{stashed_row}
1226                ? @{delete $self->{stashed_row}}
1227                : $self->cursor->next);
1228     }
1229   } else {
1230     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1231   }
1232
1233   $self->set_cache(\@obj) if $self->{attrs}{cache};
1234   return @obj;
1235 }
1236
1237 =head2 reset
1238
1239 =over 4
1240
1241 =item Arguments: none
1242
1243 =item Return Value: $self
1244
1245 =back
1246
1247 Resets the resultset's cursor, so you can iterate through the elements again.
1248
1249 =cut
1250
1251 sub reset {
1252   my ($self) = @_;
1253   delete $self->{_attrs} if exists $self->{_attrs};
1254   $self->{all_cache_position} = 0;
1255   $self->cursor->reset;
1256   return $self;
1257 }
1258
1259 =head2 first
1260
1261 =over 4
1262
1263 =item Arguments: none
1264
1265 =item Return Value: $object?
1266
1267 =back
1268
1269 Resets the resultset and returns an object for the first result (if the
1270 resultset returns anything).
1271
1272 =cut
1273
1274 sub first {
1275   return $_[0]->reset->next;
1276 }
1277
1278
1279 # _rs_update_delete
1280 #
1281 # Determines whether and what type of subquery is required for the $rs operation.
1282 # If grouping is necessary either supplies its own, or verifies the current one
1283 # After all is done delegates to the proper storage method.
1284
1285 sub _rs_update_delete {
1286   my ($self, $op, $values) = @_;
1287
1288   my $rsrc = $self->result_source;
1289
1290   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1291   my $needs_subq = $self->_has_attr (qw/row offset page/);
1292
1293   if ($needs_group_by_subq or $needs_subq) {
1294
1295     # make a new $rs selecting only the PKs (that's all we really need)
1296     my $attrs = $self->_resolved_attrs_copy;
1297
1298     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1299     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1300
1301     if ($needs_group_by_subq) {
1302       # make sure no group_by was supplied, or if there is one - make sure it matches
1303       # the columns compiled above perfectly. Anything else can not be sanely executed
1304       # on most databases so croak right then and there
1305
1306       if (my $g = $attrs->{group_by}) {
1307         my @current_group_by = map
1308           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1309           (ref $g eq 'ARRAY' ? @$g : $g );
1310
1311         if (
1312           join ("\x00", sort @current_group_by)
1313             ne
1314           join ("\x00", sort @{$attrs->{columns}} )
1315         ) {
1316           $self->throw_exception (
1317             "You have just attempted a $op operation on a resultset which does group_by"
1318             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1319             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1320             . ' kind of queries. Please retry the operation with a modified group_by or'
1321             . ' without using one at all.'
1322           );
1323         }
1324       }
1325       else {
1326         $attrs->{group_by} = $attrs->{columns};
1327       }
1328     }
1329
1330     my $subrs = (ref $self)->new($rsrc, $attrs);
1331
1332     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1333   }
1334   else {
1335     return $rsrc->storage->$op(
1336       $rsrc,
1337       $op eq 'update' ? $values : (),
1338       $self->_cond_for_update_delete,
1339     );
1340   }
1341 }
1342
1343
1344 # _cond_for_update_delete
1345 #
1346 # update/delete require the condition to be modified to handle
1347 # the differing SQL syntax available.  This transforms the $self->{cond}
1348 # appropriately, returning the new condition.
1349
1350 sub _cond_for_update_delete {
1351   my ($self, $full_cond) = @_;
1352   my $cond = {};
1353
1354   $full_cond ||= $self->{cond};
1355   # No-op. No condition, we're updating/deleting everything
1356   return $cond unless ref $full_cond;
1357
1358   if (ref $full_cond eq 'ARRAY') {
1359     $cond = [
1360       map {
1361         my %hash;
1362         foreach my $key (keys %{$_}) {
1363           $key =~ /([^.]+)$/;
1364           $hash{$1} = $_->{$key};
1365         }
1366         \%hash;
1367       } @{$full_cond}
1368     ];
1369   }
1370   elsif (ref $full_cond eq 'HASH') {
1371     if ((keys %{$full_cond})[0] eq '-and') {
1372       $cond->{-and} = [];
1373       my @cond = @{$full_cond->{-and}};
1374        for (my $i = 0; $i < @cond; $i++) {
1375         my $entry = $cond[$i];
1376         my $hash;
1377         if (ref $entry eq 'HASH') {
1378           $hash = $self->_cond_for_update_delete($entry);
1379         }
1380         else {
1381           $entry =~ /([^.]+)$/;
1382           $hash->{$1} = $cond[++$i];
1383         }
1384         push @{$cond->{-and}}, $hash;
1385       }
1386     }
1387     else {
1388       foreach my $key (keys %{$full_cond}) {
1389         $key =~ /([^.]+)$/;
1390         $cond->{$1} = $full_cond->{$key};
1391       }
1392     }
1393   }
1394   else {
1395     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1396   }
1397
1398   return $cond;
1399 }
1400
1401
1402 =head2 update
1403
1404 =over 4
1405
1406 =item Arguments: \%values
1407
1408 =item Return Value: $storage_rv
1409
1410 =back
1411
1412 Sets the specified columns in the resultset to the supplied values in a
1413 single query. Return value will be true if the update succeeded or false
1414 if no records were updated; exact type of success value is storage-dependent.
1415
1416 =cut
1417
1418 sub update {
1419   my ($self, $values) = @_;
1420   $self->throw_exception('Values for update must be a hash')
1421     unless ref $values eq 'HASH';
1422
1423   return $self->_rs_update_delete ('update', $values);
1424 }
1425
1426 =head2 update_all
1427
1428 =over 4
1429
1430 =item Arguments: \%values
1431
1432 =item Return Value: 1
1433
1434 =back
1435
1436 Fetches all objects and updates them one at a time. Note that C<update_all>
1437 will run DBIC cascade triggers, while L</update> will not.
1438
1439 =cut
1440
1441 sub update_all {
1442   my ($self, $values) = @_;
1443   $self->throw_exception('Values for update_all must be a hash')
1444     unless ref $values eq 'HASH';
1445   foreach my $obj ($self->all) {
1446     $obj->set_columns($values)->update;
1447   }
1448   return 1;
1449 }
1450
1451 =head2 delete
1452
1453 =over 4
1454
1455 =item Arguments: none
1456
1457 =item Return Value: $storage_rv
1458
1459 =back
1460
1461 Deletes the contents of the resultset from its result source. Note that this
1462 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1463 to run. See also L<DBIx::Class::Row/delete>.
1464
1465 Return value will be the amount of rows deleted; exact type of return value
1466 is storage-dependent.
1467
1468 =cut
1469
1470 sub delete {
1471   my $self = shift;
1472   $self->throw_exception('delete does not accept any arguments')
1473     if @_;
1474
1475   return $self->_rs_update_delete ('delete');
1476 }
1477
1478 =head2 delete_all
1479
1480 =over 4
1481
1482 =item Arguments: none
1483
1484 =item Return Value: 1
1485
1486 =back
1487
1488 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1489 will run DBIC cascade triggers, while L</delete> will not.
1490
1491 =cut
1492
1493 sub delete_all {
1494   my $self = shift;
1495   $self->throw_exception('delete_all does not accept any arguments')
1496     if @_;
1497
1498   $_->delete for $self->all;
1499   return 1;
1500 }
1501
1502 =head2 populate
1503
1504 =over 4
1505
1506 =item Arguments: \@data;
1507
1508 =back
1509
1510 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1511 For the arrayref of hashrefs style each hashref should be a structure suitable
1512 forsubmitting to a $resultset->create(...) method.
1513
1514 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1515 to insert the data, as this is a faster method.
1516
1517 Otherwise, each set of data is inserted into the database using
1518 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1519 objects is returned.
1520
1521 Example:  Assuming an Artist Class that has many CDs Classes relating:
1522
1523   my $Artist_rs = $schema->resultset("Artist");
1524
1525   ## Void Context Example
1526   $Artist_rs->populate([
1527      { artistid => 4, name => 'Manufactured Crap', cds => [
1528         { title => 'My First CD', year => 2006 },
1529         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1530       ],
1531      },
1532      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1533         { title => 'My parents sold me to a record company' ,year => 2005 },
1534         { title => 'Why Am I So Ugly?', year => 2006 },
1535         { title => 'I Got Surgery and am now Popular', year => 2007 }
1536       ],
1537      },
1538   ]);
1539
1540   ## Array Context Example
1541   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1542     { name => "Artist One"},
1543     { name => "Artist Two"},
1544     { name => "Artist Three", cds=> [
1545     { title => "First CD", year => 2007},
1546     { title => "Second CD", year => 2008},
1547   ]}
1548   ]);
1549
1550   print $ArtistOne->name; ## response is 'Artist One'
1551   print $ArtistThree->cds->count ## reponse is '2'
1552
1553 For the arrayref of arrayrefs style,  the first element should be a list of the
1554 fieldsnames to which the remaining elements are rows being inserted.  For
1555 example:
1556
1557   $Arstist_rs->populate([
1558     [qw/artistid name/],
1559     [100, 'A Formally Unknown Singer'],
1560     [101, 'A singer that jumped the shark two albums ago'],
1561     [102, 'An actually cool singer.'],
1562   ]);
1563
1564 Please note an important effect on your data when choosing between void and
1565 wantarray context. Since void context goes straight to C<insert_bulk> in
1566 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1567 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1568 create primary keys for you, you will find that your PKs are empty.  In this
1569 case you will have to use the wantarray context in order to create those
1570 values.
1571
1572 =cut
1573
1574 sub populate {
1575   my $self = shift @_;
1576   my $data = ref $_[0][0] eq 'HASH'
1577     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1578     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1579
1580   if(defined wantarray) {
1581     my @created;
1582     foreach my $item (@$data) {
1583       push(@created, $self->create($item));
1584     }
1585     return @created;
1586   } else {
1587     my ($first, @rest) = @$data;
1588
1589     my @names = grep {!ref $first->{$_}} keys %$first;
1590     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1591     my @pks = $self->result_source->primary_columns;
1592
1593     ## do the belongs_to relationships
1594     foreach my $index (0..$#$data) {
1595
1596       # delegate to create() for any dataset without primary keys with specified relationships
1597       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1598         for my $r (@rels) {
1599           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1600             my @ret = $self->populate($data);
1601             return;
1602           }
1603         }
1604       }
1605
1606       foreach my $rel (@rels) {
1607         next unless ref $data->[$index]->{$rel} eq "HASH";
1608         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1609         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1610         my $related = $result->result_source->_resolve_condition(
1611           $result->result_source->relationship_info($reverse)->{cond},
1612           $self,
1613           $result,
1614         );
1615
1616         delete $data->[$index]->{$rel};
1617         $data->[$index] = {%{$data->[$index]}, %$related};
1618
1619         push @names, keys %$related if $index == 0;
1620       }
1621     }
1622
1623     ## do bulk insert on current row
1624     my @values = map { [ @$_{@names} ] } @$data;
1625
1626     $self->result_source->storage->insert_bulk(
1627       $self->result_source,
1628       \@names,
1629       \@values,
1630     );
1631
1632     ## do the has_many relationships
1633     foreach my $item (@$data) {
1634
1635       foreach my $rel (@rels) {
1636         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1637
1638         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1639      || $self->throw_exception('Cannot find the relating object.');
1640
1641         my $child = $parent->$rel;
1642
1643         my $related = $child->result_source->_resolve_condition(
1644           $parent->result_source->relationship_info($rel)->{cond},
1645           $child,
1646           $parent,
1647         );
1648
1649         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1650         my @populate = map { {%$_, %$related} } @rows_to_add;
1651
1652         $child->populate( \@populate );
1653       }
1654     }
1655   }
1656 }
1657
1658 =head2 _normalize_populate_args ($args)
1659
1660 Private method used by L</populate> to normalize its incoming arguments.  Factored
1661 out in case you want to subclass and accept new argument structures to the
1662 L</populate> method.
1663
1664 =cut
1665
1666 sub _normalize_populate_args {
1667   my ($self, $data) = @_;
1668   my @names = @{shift(@$data)};
1669   my @results_to_create;
1670   foreach my $datum (@$data) {
1671     my %result_to_create;
1672     foreach my $index (0..$#names) {
1673       $result_to_create{$names[$index]} = $$datum[$index];
1674     }
1675     push @results_to_create, \%result_to_create;
1676   }
1677   return \@results_to_create;
1678 }
1679
1680 =head2 pager
1681
1682 =over 4
1683
1684 =item Arguments: none
1685
1686 =item Return Value: $pager
1687
1688 =back
1689
1690 Return Value a L<Data::Page> object for the current resultset. Only makes
1691 sense for queries with a C<page> attribute.
1692
1693 To get the full count of entries for a paged resultset, call
1694 C<total_entries> on the L<Data::Page> object.
1695
1696 =cut
1697
1698 sub pager {
1699   my ($self) = @_;
1700
1701   return $self->{pager} if $self->{pager};
1702
1703   my $attrs = $self->{attrs};
1704   $self->throw_exception("Can't create pager for non-paged rs")
1705     unless $self->{attrs}{page};
1706   $attrs->{rows} ||= 10;
1707
1708   # throw away the paging flags and re-run the count (possibly
1709   # with a subselect) to get the real total count
1710   my $count_attrs = { %$attrs };
1711   delete $count_attrs->{$_} for qw/rows offset page pager/;
1712   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1713
1714   return $self->{pager} = Data::Page->new(
1715     $total_count,
1716     $attrs->{rows},
1717     $self->{attrs}{page}
1718   );
1719 }
1720
1721 =head2 page
1722
1723 =over 4
1724
1725 =item Arguments: $page_number
1726
1727 =item Return Value: $rs
1728
1729 =back
1730
1731 Returns a resultset for the $page_number page of the resultset on which page
1732 is called, where each page contains a number of rows equal to the 'rows'
1733 attribute set on the resultset (10 by default).
1734
1735 =cut
1736
1737 sub page {
1738   my ($self, $page) = @_;
1739   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1740 }
1741
1742 =head2 new_result
1743
1744 =over 4
1745
1746 =item Arguments: \%vals
1747
1748 =item Return Value: $rowobject
1749
1750 =back
1751
1752 Creates a new row object in the resultset's result class and returns
1753 it. The row is not inserted into the database at this point, call
1754 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1755 will tell you whether the row object has been inserted or not.
1756
1757 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1758
1759 =cut
1760
1761 sub new_result {
1762   my ($self, $values) = @_;
1763   $self->throw_exception( "new_result needs a hash" )
1764     unless (ref $values eq 'HASH');
1765
1766   my %new;
1767   my $alias = $self->{attrs}{alias};
1768
1769   if (
1770     defined $self->{cond}
1771     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1772   ) {
1773     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1774     $new{-from_resultset} = [ keys %new ] if keys %new;
1775   } else {
1776     $self->throw_exception(
1777       "Can't abstract implicit construct, condition not a hash"
1778     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1779
1780     my $collapsed_cond = (
1781       $self->{cond}
1782         ? $self->_collapse_cond($self->{cond})
1783         : {}
1784     );
1785
1786     # precendence must be given to passed values over values inherited from
1787     # the cond, so the order here is important.
1788     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1789     while( my($col,$value) = each %implied ){
1790       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1791         $new{$col} = $value->{'='};
1792         next;
1793       }
1794       $new{$col} = $value if $self->_is_deterministic_value($value);
1795     }
1796   }
1797
1798   %new = (
1799     %new,
1800     %{ $self->_remove_alias($values, $alias) },
1801     -source_handle => $self->_source_handle,
1802     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1803   );
1804
1805   return $self->result_class->new(\%new);
1806 }
1807
1808 # _is_deterministic_value
1809 #
1810 # Make an effor to strip non-deterministic values from the condition,
1811 # to make sure new_result chokes less
1812
1813 sub _is_deterministic_value {
1814   my $self = shift;
1815   my $value = shift;
1816   my $ref_type = ref $value;
1817   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1818   return 1 if Scalar::Util::blessed($value);
1819   return 0;
1820 }
1821
1822 # _has_attr
1823 #
1824 # determines if the resultset defines at least one
1825 # of the attributes supplied
1826 #
1827 # used to determine if a subquery is neccessary
1828
1829 sub _has_attr {
1830   my ($self, @attr_names) = @_;
1831
1832   my $attrs = $self->_resolved_attrs;
1833
1834   my $join_check_req;
1835
1836   for my $n (@attr_names) {
1837     ++$join_check_req if $n =~ /join/;
1838
1839     my $attr =  $attrs->{$n};
1840
1841     next if not defined $attr;
1842
1843     if (ref $attr eq 'HASH') {
1844       return 1 if keys %$attr;
1845     }
1846     elsif (ref $attr eq 'ARRAY') {
1847       return 1 if @$attr;
1848     }
1849     else {
1850       return 1 if $attr;
1851     }
1852   }
1853
1854   # a join can be expressed as a multi-level from
1855   return 1 if (
1856     $join_check_req
1857       and
1858     ref $attrs->{from} eq 'ARRAY'
1859       and
1860     @{$attrs->{from}} > 1
1861   );
1862
1863   return 0;
1864 }
1865
1866 # _collapse_cond
1867 #
1868 # Recursively collapse the condition.
1869
1870 sub _collapse_cond {
1871   my ($self, $cond, $collapsed) = @_;
1872
1873   $collapsed ||= {};
1874
1875   if (ref $cond eq 'ARRAY') {
1876     foreach my $subcond (@$cond) {
1877       next unless ref $subcond;  # -or
1878       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1879     }
1880   }
1881   elsif (ref $cond eq 'HASH') {
1882     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1883       foreach my $subcond (@{$cond->{-and}}) {
1884         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1885       }
1886     }
1887     else {
1888       foreach my $col (keys %$cond) {
1889         my $value = $cond->{$col};
1890         $collapsed->{$col} = $value;
1891       }
1892     }
1893   }
1894
1895   return $collapsed;
1896 }
1897
1898 # _remove_alias
1899 #
1900 # Remove the specified alias from the specified query hash. A copy is made so
1901 # the original query is not modified.
1902
1903 sub _remove_alias {
1904   my ($self, $query, $alias) = @_;
1905
1906   my %orig = %{ $query || {} };
1907   my %unaliased;
1908
1909   foreach my $key (keys %orig) {
1910     if ($key !~ /\./) {
1911       $unaliased{$key} = $orig{$key};
1912       next;
1913     }
1914     $unaliased{$1} = $orig{$key}
1915       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1916   }
1917
1918   return \%unaliased;
1919 }
1920
1921 =head2 as_query (EXPERIMENTAL)
1922
1923 =over 4
1924
1925 =item Arguments: none
1926
1927 =item Return Value: \[ $sql, @bind ]
1928
1929 =back
1930
1931 Returns the SQL query and bind vars associated with the invocant.
1932
1933 This is generally used as the RHS for a subquery.
1934
1935 B<NOTE>: This feature is still experimental.
1936
1937 =cut
1938
1939 sub as_query { return shift->cursor->as_query(@_) }
1940
1941 =head2 find_or_new
1942
1943 =over 4
1944
1945 =item Arguments: \%vals, \%attrs?
1946
1947 =item Return Value: $rowobject
1948
1949 =back
1950
1951   my $artist = $schema->resultset('Artist')->find_or_new(
1952     { artist => 'fred' }, { key => 'artists' });
1953
1954   $cd->cd_to_producer->find_or_new({ producer => $producer },
1955                                    { key => 'primary });
1956
1957 Find an existing record from this resultset, based on its primary
1958 key, or a unique constraint. If none exists, instantiate a new result
1959 object and return it. The object will not be saved into your storage
1960 until you call L<DBIx::Class::Row/insert> on it.
1961
1962 You most likely want this method when looking for existing rows using
1963 a unique constraint that is not the primary key, or looking for
1964 related rows.
1965
1966 If you want objects to be saved immediately, use L</find_or_create> instead.
1967
1968 B<Note>: C<find_or_new> is probably not what you want when creating a
1969 new row in a table that uses primary keys supplied by the
1970 database. Passing in a primary key column with a value of I<undef>
1971 will cause L</find> to attempt to search for a row with a value of
1972 I<NULL>.
1973
1974 =cut
1975
1976 sub find_or_new {
1977   my $self     = shift;
1978   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1979   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1980   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
1981     return $row;
1982   }
1983   return $self->new_result($hash);
1984 }
1985
1986 =head2 create
1987
1988 =over 4
1989
1990 =item Arguments: \%vals
1991
1992 =item Return Value: a L<DBIx::Class::Row> $object
1993
1994 =back
1995
1996 Attempt to create a single new row or a row with multiple related rows
1997 in the table represented by the resultset (and related tables). This
1998 will not check for duplicate rows before inserting, use
1999 L</find_or_create> to do that.
2000
2001 To create one row for this resultset, pass a hashref of key/value
2002 pairs representing the columns of the table and the values you wish to
2003 store. If the appropriate relationships are set up, foreign key fields
2004 can also be passed an object representing the foreign row, and the
2005 value will be set to its primary key.
2006
2007 To create related objects, pass a hashref for the value if the related
2008 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2009 and use the name of the relationship as the key. (NOT the name of the field,
2010 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2011 of hashrefs containing the data for each of the rows to create in the foreign
2012 tables, again using the relationship name as the key.
2013
2014 Instead of hashrefs of plain related data (key/value pairs), you may
2015 also pass new or inserted objects. New objects (not inserted yet, see
2016 L</new>), will be inserted into their appropriate tables.
2017
2018 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2019
2020 Example of creating a new row.
2021
2022   $person_rs->create({
2023     name=>"Some Person",
2024     email=>"somebody@someplace.com"
2025   });
2026
2027 Example of creating a new row and also creating rows in a related C<has_many>
2028 or C<has_one> resultset.  Note Arrayref.
2029
2030   $artist_rs->create(
2031      { artistid => 4, name => 'Manufactured Crap', cds => [
2032         { title => 'My First CD', year => 2006 },
2033         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2034       ],
2035      },
2036   );
2037
2038 Example of creating a new row and also creating a row in a related
2039 C<belongs_to>resultset. Note Hashref.
2040
2041   $cd_rs->create({
2042     title=>"Music for Silly Walks",
2043     year=>2000,
2044     artist => {
2045       name=>"Silly Musician",
2046     }
2047   });
2048
2049 =cut
2050
2051 sub create {
2052   my ($self, $attrs) = @_;
2053   $self->throw_exception( "create needs a hashref" )
2054     unless ref $attrs eq 'HASH';
2055   return $self->new_result($attrs)->insert;
2056 }
2057
2058 =head2 find_or_create
2059
2060 =over 4
2061
2062 =item Arguments: \%vals, \%attrs?
2063
2064 =item Return Value: $rowobject
2065
2066 =back
2067
2068   $cd->cd_to_producer->find_or_create({ producer => $producer },
2069                                       { key => 'primary });
2070
2071 Tries to find a record based on its primary key or unique constraints; if none
2072 is found, creates one and returns that instead.
2073
2074   my $cd = $schema->resultset('CD')->find_or_create({
2075     cdid   => 5,
2076     artist => 'Massive Attack',
2077     title  => 'Mezzanine',
2078     year   => 2005,
2079   });
2080
2081 Also takes an optional C<key> attribute, to search by a specific key or unique
2082 constraint. For example:
2083
2084   my $cd = $schema->resultset('CD')->find_or_create(
2085     {
2086       artist => 'Massive Attack',
2087       title  => 'Mezzanine',
2088     },
2089     { key => 'cd_artist_title' }
2090   );
2091
2092 B<Note>: Because find_or_create() reads from the database and then
2093 possibly inserts based on the result, this method is subject to a race
2094 condition. Another process could create a record in the table after
2095 the find has completed and before the create has started. To avoid
2096 this problem, use find_or_create() inside a transaction.
2097
2098 B<Note>: C<find_or_create> is probably not what you want when creating
2099 a new row in a table that uses primary keys supplied by the
2100 database. Passing in a primary key column with a value of I<undef>
2101 will cause L</find> to attempt to search for a row with a value of
2102 I<NULL>.
2103
2104 See also L</find> and L</update_or_create>. For information on how to declare
2105 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2106
2107 =cut
2108
2109 sub find_or_create {
2110   my $self     = shift;
2111   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2112   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2113   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2114     return $row;
2115   }
2116   return $self->create($hash);
2117 }
2118
2119 =head2 update_or_create
2120
2121 =over 4
2122
2123 =item Arguments: \%col_values, { key => $unique_constraint }?
2124
2125 =item Return Value: $rowobject
2126
2127 =back
2128
2129   $resultset->update_or_create({ col => $val, ... });
2130
2131 First, searches for an existing row matching one of the unique constraints
2132 (including the primary key) on the source of this resultset. If a row is
2133 found, updates it with the other given column values. Otherwise, creates a new
2134 row.
2135
2136 Takes an optional C<key> attribute to search on a specific unique constraint.
2137 For example:
2138
2139   # In your application
2140   my $cd = $schema->resultset('CD')->update_or_create(
2141     {
2142       artist => 'Massive Attack',
2143       title  => 'Mezzanine',
2144       year   => 1998,
2145     },
2146     { key => 'cd_artist_title' }
2147   );
2148
2149   $cd->cd_to_producer->update_or_create({
2150     producer => $producer,
2151     name => 'harry',
2152   }, {
2153     key => 'primary,
2154   });
2155
2156
2157 If no C<key> is specified, it searches on all unique constraints defined on the
2158 source, including the primary key.
2159
2160 If the C<key> is specified as C<primary>, it searches only on the primary key.
2161
2162 See also L</find> and L</find_or_create>. For information on how to declare
2163 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2164
2165 B<Note>: C<update_or_create> is probably not what you want when
2166 looking for a row in a table that uses primary keys supplied by the
2167 database, unless you actually have a key value. Passing in a primary
2168 key column with a value of I<undef> will cause L</find> to attempt to
2169 search for a row with a value of I<NULL>.
2170
2171 =cut
2172
2173 sub update_or_create {
2174   my $self = shift;
2175   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2176   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2177
2178   my $row = $self->find($cond, $attrs);
2179   if (defined $row) {
2180     $row->update($cond);
2181     return $row;
2182   }
2183
2184   return $self->create($cond);
2185 }
2186
2187 =head2 update_or_new
2188
2189 =over 4
2190
2191 =item Arguments: \%col_values, { key => $unique_constraint }?
2192
2193 =item Return Value: $rowobject
2194
2195 =back
2196
2197   $resultset->update_or_new({ col => $val, ... });
2198
2199 First, searches for an existing row matching one of the unique constraints
2200 (including the primary key) on the source of this resultset. If a row is
2201 found, updates it with the other given column values. Otherwise, instantiate
2202 a new result object and return it. The object will not be saved into your storage
2203 until you call L<DBIx::Class::Row/insert> on it.
2204
2205 Takes an optional C<key> attribute to search on a specific unique constraint.
2206 For example:
2207
2208   # In your application
2209   my $cd = $schema->resultset('CD')->update_or_new(
2210     {
2211       artist => 'Massive Attack',
2212       title  => 'Mezzanine',
2213       year   => 1998,
2214     },
2215     { key => 'cd_artist_title' }
2216   );
2217
2218   if ($cd->in_storage) {
2219       # the cd was updated
2220   }
2221   else {
2222       # the cd is not yet in the database, let's insert it
2223       $cd->insert;
2224   }
2225
2226 See also L</find>, L</find_or_create> and L<find_or_new>.
2227
2228 =cut
2229
2230 sub update_or_new {
2231     my $self  = shift;
2232     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2233     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2234
2235     my $row = $self->find( $cond, $attrs );
2236     if ( defined $row ) {
2237         $row->update($cond);
2238         return $row;
2239     }
2240
2241     return $self->new_result($cond);
2242 }
2243
2244 =head2 get_cache
2245
2246 =over 4
2247
2248 =item Arguments: none
2249
2250 =item Return Value: \@cache_objects?
2251
2252 =back
2253
2254 Gets the contents of the cache for the resultset, if the cache is set.
2255
2256 The cache is populated either by using the L</prefetch> attribute to
2257 L</search> or by calling L</set_cache>.
2258
2259 =cut
2260
2261 sub get_cache {
2262   shift->{all_cache};
2263 }
2264
2265 =head2 set_cache
2266
2267 =over 4
2268
2269 =item Arguments: \@cache_objects
2270
2271 =item Return Value: \@cache_objects
2272
2273 =back
2274
2275 Sets the contents of the cache for the resultset. Expects an arrayref
2276 of objects of the same class as those produced by the resultset. Note that
2277 if the cache is set the resultset will return the cached objects rather
2278 than re-querying the database even if the cache attr is not set.
2279
2280 The contents of the cache can also be populated by using the
2281 L</prefetch> attribute to L</search>.
2282
2283 =cut
2284
2285 sub set_cache {
2286   my ( $self, $data ) = @_;
2287   $self->throw_exception("set_cache requires an arrayref")
2288       if defined($data) && (ref $data ne 'ARRAY');
2289   $self->{all_cache} = $data;
2290 }
2291
2292 =head2 clear_cache
2293
2294 =over 4
2295
2296 =item Arguments: none
2297
2298 =item Return Value: []
2299
2300 =back
2301
2302 Clears the cache for the resultset.
2303
2304 =cut
2305
2306 sub clear_cache {
2307   shift->set_cache(undef);
2308 }
2309
2310 =head2 related_resultset
2311
2312 =over 4
2313
2314 =item Arguments: $relationship_name
2315
2316 =item Return Value: $resultset
2317
2318 =back
2319
2320 Returns a related resultset for the supplied relationship name.
2321
2322   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2323
2324 =cut
2325
2326 sub related_resultset {
2327   my ($self, $rel) = @_;
2328
2329   $self->{related_resultsets} ||= {};
2330   return $self->{related_resultsets}{$rel} ||= do {
2331     my $rel_obj = $self->result_source->relationship_info($rel);
2332
2333     $self->throw_exception(
2334       "search_related: result source '" . $self->result_source->source_name .
2335         "' has no such relationship $rel")
2336       unless $rel_obj;
2337
2338     my ($from,$seen) = $self->_resolve_from($rel);
2339
2340     my $join_count = $seen->{$rel};
2341     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2342
2343     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2344     my %attrs = %{$self->{attrs}||{}};
2345     delete @attrs{qw(result_class alias)};
2346
2347     my $new_cache;
2348
2349     if (my $cache = $self->get_cache) {
2350       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2351         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2352                         @$cache ];
2353       }
2354     }
2355
2356     my $rel_source = $self->result_source->related_source($rel);
2357
2358     my $new = do {
2359
2360       # The reason we do this now instead of passing the alias to the
2361       # search_rs below is that if you wrap/overload resultset on the
2362       # source you need to know what alias it's -going- to have for things
2363       # to work sanely (e.g. RestrictWithObject wants to be able to add
2364       # extra query restrictions, and these may need to be $alias.)
2365
2366       my $attrs = $rel_source->resultset_attributes;
2367       local $attrs->{alias} = $alias;
2368
2369       $rel_source->resultset
2370                  ->search_rs(
2371                      undef, {
2372                        %attrs,
2373                        join => undef,
2374                        prefetch => undef,
2375                        select => undef,
2376                        as => undef,
2377                        where => $self->{cond},
2378                        seen_join => $seen,
2379                        from => $from,
2380                    });
2381     };
2382     $new->set_cache($new_cache) if $new_cache;
2383     $new;
2384   };
2385 }
2386
2387 =head2 current_source_alias
2388
2389 =over 4
2390
2391 =item Arguments: none
2392
2393 =item Return Value: $source_alias
2394
2395 =back
2396
2397 Returns the current table alias for the result source this resultset is built
2398 on, that will be used in the SQL query. Usually it is C<me>.
2399
2400 Currently the source alias that refers to the result set returned by a
2401 L</search>/L</find> family method depends on how you got to the resultset: it's
2402 C<me> by default, but eg. L</search_related> aliases it to the related result
2403 source name (and keeps C<me> referring to the original result set). The long
2404 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2405 (and make this method unnecessary).
2406
2407 Thus it's currently necessary to use this method in predefined queries (see
2408 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2409 source alias of the current result set:
2410
2411   # in a result set class
2412   sub modified_by {
2413     my ($self, $user) = @_;
2414
2415     my $me = $self->current_source_alias;
2416
2417     return $self->search(
2418       "$me.modified" => $user->id,
2419     );
2420   }
2421
2422 =cut
2423
2424 sub current_source_alias {
2425   my ($self) = @_;
2426
2427   return ($self->{attrs} || {})->{alias} || 'me';
2428 }
2429
2430 # This code is called by search_related, and makes sure there
2431 # is clear separation between the joins before, during, and
2432 # after the relationship. This information is needed later
2433 # in order to properly resolve prefetch aliases (any alias
2434 # with a relation_chain_depth less than the depth of the
2435 # current prefetch is not considered)
2436 sub _resolve_from {
2437   my ($self, $extra_join) = @_;
2438   my $source = $self->result_source;
2439   my $attrs = $self->{attrs};
2440
2441   my $from = $attrs->{from}
2442     || [ { $attrs->{alias} => $source->from } ];
2443
2444   my $seen = { %{$attrs->{seen_join} || {} } };
2445
2446   # we need to take the prefetch the attrs into account before we
2447   # ->_resolve_join as otherwise they get lost - captainL
2448   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2449
2450   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2451
2452   ++$seen->{-relation_chain_depth};
2453
2454   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2455
2456   ++$seen->{-relation_chain_depth};
2457
2458   return ($from,$seen);
2459 }
2460
2461 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2462 sub _resolved_attrs_copy {
2463   my $self = shift;
2464   return { %{$self->_resolved_attrs (@_)} };
2465 }
2466
2467 sub _resolved_attrs {
2468   my $self = shift;
2469   return $self->{_attrs} if $self->{_attrs};
2470
2471   my $attrs  = { %{ $self->{attrs} || {} } };
2472   my $source = $self->result_source;
2473   my $alias  = $attrs->{alias};
2474
2475   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2476   my @colbits;
2477
2478   # build columns (as long as select isn't set) into a set of as/select hashes
2479   unless ( $attrs->{select} ) {
2480       @colbits = map {
2481           ( ref($_) eq 'HASH' )
2482               ? $_
2483               : {
2484                   (
2485                     /^\Q${alias}.\E(.+)$/
2486                       ? "$1"
2487                       : "$_"
2488                   )
2489                 =>
2490                   (
2491                     /\./
2492                       ? "$_"
2493                       : "${alias}.$_"
2494                   )
2495             }
2496       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2497   }
2498   # add the additional columns on
2499   foreach ( 'include_columns', '+columns' ) {
2500       push @colbits, map {
2501           ( ref($_) eq 'HASH' )
2502             ? $_
2503             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2504       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2505   }
2506
2507   # start with initial select items
2508   if ( $attrs->{select} ) {
2509     $attrs->{select} =
2510         ( ref $attrs->{select} eq 'ARRAY' )
2511       ? [ @{ $attrs->{select} } ]
2512       : [ $attrs->{select} ];
2513     $attrs->{as} = (
2514       $attrs->{as}
2515       ? (
2516         ref $attrs->{as} eq 'ARRAY'
2517         ? [ @{ $attrs->{as} } ]
2518         : [ $attrs->{as} ]
2519         )
2520       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2521     );
2522   }
2523   else {
2524
2525     # otherwise we intialise select & as to empty
2526     $attrs->{select} = [];
2527     $attrs->{as}     = [];
2528   }
2529
2530   # now add colbits to select/as
2531   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2532   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2533
2534   my $adds;
2535   if ( $adds = delete $attrs->{'+select'} ) {
2536     $adds = [$adds] unless ref $adds eq 'ARRAY';
2537     push(
2538       @{ $attrs->{select} },
2539       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2540     );
2541   }
2542   if ( $adds = delete $attrs->{'+as'} ) {
2543     $adds = [$adds] unless ref $adds eq 'ARRAY';
2544     push( @{ $attrs->{as} }, @$adds );
2545   }
2546
2547   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2548
2549   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2550     my $join = delete $attrs->{join} || {};
2551
2552     if ( defined $attrs->{prefetch} ) {
2553       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2554
2555     }
2556
2557     $attrs->{from} =    # have to copy here to avoid corrupting the original
2558       [
2559       @{ $attrs->{from} },
2560       $source->_resolve_join(
2561         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2562       )
2563       ];
2564
2565   }
2566
2567   if ( $attrs->{order_by} ) {
2568     $attrs->{order_by} = (
2569       ref( $attrs->{order_by} ) eq 'ARRAY'
2570       ? [ @{ $attrs->{order_by} } ]
2571       : [ $attrs->{order_by} ]
2572     );
2573   }
2574   else {
2575     $attrs->{order_by} = [];
2576   }
2577
2578   my $collapse = $attrs->{collapse} || {};
2579   if ( my $prefetch = delete $attrs->{prefetch} ) {
2580     $prefetch = $self->_merge_attr( {}, $prefetch );
2581     my @pre_order;
2582     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2583
2584       # bring joins back to level of current class
2585       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2586       my @prefetch =
2587         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2588       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2589       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2590     }
2591     push( @{ $attrs->{order_by} }, @pre_order );
2592   }
2593
2594   if (delete $attrs->{distinct}) {
2595     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2596   }
2597
2598   $attrs->{collapse} = $collapse;
2599
2600   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2601     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2602   }
2603
2604   return $self->{_attrs} = $attrs;
2605 }
2606
2607 sub _joinpath_aliases {
2608   my ($self, $fromspec, $seen) = @_;
2609
2610   my $paths = {};
2611   return $paths unless ref $fromspec eq 'ARRAY';
2612
2613   for my $j (@$fromspec) {
2614
2615     next if ref $j ne 'ARRAY';
2616     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2617
2618     my $p = $paths;
2619     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2620     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2621   }
2622
2623   return $paths;
2624 }
2625
2626 sub _rollout_attr {
2627   my ($self, $attr) = @_;
2628
2629   if (ref $attr eq 'HASH') {
2630     return $self->_rollout_hash($attr);
2631   } elsif (ref $attr eq 'ARRAY') {
2632     return $self->_rollout_array($attr);
2633   } else {
2634     return [$attr];
2635   }
2636 }
2637
2638 sub _rollout_array {
2639   my ($self, $attr) = @_;
2640
2641   my @rolled_array;
2642   foreach my $element (@{$attr}) {
2643     if (ref $element eq 'HASH') {
2644       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2645     } elsif (ref $element eq 'ARRAY') {
2646       #  XXX - should probably recurse here
2647       push( @rolled_array, @{$self->_rollout_array($element)} );
2648     } else {
2649       push( @rolled_array, $element );
2650     }
2651   }
2652   return \@rolled_array;
2653 }
2654
2655 sub _rollout_hash {
2656   my ($self, $attr) = @_;
2657
2658   my @rolled_array;
2659   foreach my $key (keys %{$attr}) {
2660     push( @rolled_array, { $key => $attr->{$key} } );
2661   }
2662   return \@rolled_array;
2663 }
2664
2665 sub _calculate_score {
2666   my ($self, $a, $b) = @_;
2667
2668   if (ref $b eq 'HASH') {
2669     my ($b_key) = keys %{$b};
2670     if (ref $a eq 'HASH') {
2671       my ($a_key) = keys %{$a};
2672       if ($a_key eq $b_key) {
2673         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2674       } else {
2675         return 0;
2676       }
2677     } else {
2678       return ($a eq $b_key) ? 1 : 0;
2679     }
2680   } else {
2681     if (ref $a eq 'HASH') {
2682       my ($a_key) = keys %{$a};
2683       return ($b eq $a_key) ? 1 : 0;
2684     } else {
2685       return ($b eq $a) ? 1 : 0;
2686     }
2687   }
2688 }
2689
2690 sub _merge_attr {
2691   my ($self, $orig, $import) = @_;
2692
2693   return $import unless defined($orig);
2694   return $orig unless defined($import);
2695
2696   $orig = $self->_rollout_attr($orig);
2697   $import = $self->_rollout_attr($import);
2698
2699   my $seen_keys;
2700   foreach my $import_element ( @{$import} ) {
2701     # find best candidate from $orig to merge $b_element into
2702     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2703     foreach my $orig_element ( @{$orig} ) {
2704       my $score = $self->_calculate_score( $orig_element, $import_element );
2705       if ($score > $best_candidate->{score}) {
2706         $best_candidate->{position} = $position;
2707         $best_candidate->{score} = $score;
2708       }
2709       $position++;
2710     }
2711     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2712
2713     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2714       push( @{$orig}, $import_element );
2715     } else {
2716       my $orig_best = $orig->[$best_candidate->{position}];
2717       # merge orig_best and b_element together and replace original with merged
2718       if (ref $orig_best ne 'HASH') {
2719         $orig->[$best_candidate->{position}] = $import_element;
2720       } elsif (ref $import_element eq 'HASH') {
2721         my ($key) = keys %{$orig_best};
2722         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2723       }
2724     }
2725     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2726   }
2727
2728   return $orig;
2729 }
2730
2731 sub result_source {
2732     my $self = shift;
2733
2734     if (@_) {
2735         $self->_source_handle($_[0]->handle);
2736     } else {
2737         $self->_source_handle->resolve;
2738     }
2739 }
2740
2741 =head2 throw_exception
2742
2743 See L<DBIx::Class::Schema/throw_exception> for details.
2744
2745 =cut
2746
2747 sub throw_exception {
2748   my $self=shift;
2749   if (ref $self && $self->_source_handle->schema) {
2750     $self->_source_handle->schema->throw_exception(@_)
2751   } else {
2752     croak(@_);
2753   }
2754
2755 }
2756
2757 # XXX: FIXME: Attributes docs need clearing up
2758
2759 =head1 ATTRIBUTES
2760
2761 Attributes are used to refine a ResultSet in various ways when
2762 searching for data. They can be passed to any method which takes an
2763 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2764 L</count>.
2765
2766 These are in no particular order:
2767
2768 =head2 order_by
2769
2770 =over 4
2771
2772 =item Value: ( $order_by | \@order_by | \%order_by )
2773
2774 =back
2775
2776 Which column(s) to order the results by. If a single column name, or
2777 an arrayref of names is supplied, the argument is passed through
2778 directly to SQL. The hashref syntax allows for connection-agnostic
2779 specification of ordering direction:
2780
2781  For descending order:
2782
2783   order_by => { -desc => [qw/col1 col2 col3/] }
2784
2785  For explicit ascending order:
2786
2787   order_by => { -asc => 'col' }
2788
2789 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2790 supported, although you are strongly encouraged to use the hashref
2791 syntax as outlined above.
2792
2793 =head2 columns
2794
2795 =over 4
2796
2797 =item Value: \@columns
2798
2799 =back
2800
2801 Shortcut to request a particular set of columns to be retrieved. Each
2802 column spec may be a string (a table column name), or a hash (in which
2803 case the key is the C<as> value, and the value is used as the C<select>
2804 expression). Adds C<me.> onto the start of any column without a C<.> in
2805 it and sets C<select> from that, then auto-populates C<as> from
2806 C<select> as normal. (You may also use the C<cols> attribute, as in
2807 earlier versions of DBIC.)
2808
2809 =head2 +columns
2810
2811 =over 4
2812
2813 =item Value: \@columns
2814
2815 =back
2816
2817 Indicates additional columns to be selected from storage. Works the same
2818 as L</columns> but adds columns to the selection. (You may also use the
2819 C<include_columns> attribute, as in earlier versions of DBIC). For
2820 example:-
2821
2822   $schema->resultset('CD')->search(undef, {
2823     '+columns' => ['artist.name'],
2824     join => ['artist']
2825   });
2826
2827 would return all CDs and include a 'name' column to the information
2828 passed to object inflation. Note that the 'artist' is the name of the
2829 column (or relationship) accessor, and 'name' is the name of the column
2830 accessor in the related table.
2831
2832 =head2 include_columns
2833
2834 =over 4
2835
2836 =item Value: \@columns
2837
2838 =back
2839
2840 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2841
2842 =head2 select
2843
2844 =over 4
2845
2846 =item Value: \@select_columns
2847
2848 =back
2849
2850 Indicates which columns should be selected from the storage. You can use
2851 column names, or in the case of RDBMS back ends, function or stored procedure
2852 names:
2853
2854   $rs = $schema->resultset('Employee')->search(undef, {
2855     select => [
2856       'name',
2857       { count => 'employeeid' },
2858       { sum => 'salary' }
2859     ]
2860   });
2861
2862 When you use function/stored procedure names and do not supply an C<as>
2863 attribute, the column names returned are storage-dependent. E.g. MySQL would
2864 return a column named C<count(employeeid)> in the above example.
2865
2866 =head2 +select
2867
2868 =over 4
2869
2870 Indicates additional columns to be selected from storage.  Works the same as
2871 L</select> but adds columns to the selection.
2872
2873 =back
2874
2875 =head2 +as
2876
2877 =over 4
2878
2879 Indicates additional column names for those added via L</+select>. See L</as>.
2880
2881 =back
2882
2883 =head2 as
2884
2885 =over 4
2886
2887 =item Value: \@inflation_names
2888
2889 =back
2890
2891 Indicates column names for object inflation. That is, C<as>
2892 indicates the name that the column can be accessed as via the
2893 C<get_column> method (or via the object accessor, B<if one already
2894 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2895
2896 The C<as> attribute is used in conjunction with C<select>,
2897 usually when C<select> contains one or more function or stored
2898 procedure names:
2899
2900   $rs = $schema->resultset('Employee')->search(undef, {
2901     select => [
2902       'name',
2903       { count => 'employeeid' }
2904     ],
2905     as => ['name', 'employee_count'],
2906   });
2907
2908   my $employee = $rs->first(); # get the first Employee
2909
2910 If the object against which the search is performed already has an accessor
2911 matching a column name specified in C<as>, the value can be retrieved using
2912 the accessor as normal:
2913
2914   my $name = $employee->name();
2915
2916 If on the other hand an accessor does not exist in the object, you need to
2917 use C<get_column> instead:
2918
2919   my $employee_count = $employee->get_column('employee_count');
2920
2921 You can create your own accessors if required - see
2922 L<DBIx::Class::Manual::Cookbook> for details.
2923
2924 Please note: This will NOT insert an C<AS employee_count> into the SQL
2925 statement produced, it is used for internal access only. Thus
2926 attempting to use the accessor in an C<order_by> clause or similar
2927 will fail miserably.
2928
2929 To get around this limitation, you can supply literal SQL to your
2930 C<select> attibute that contains the C<AS alias> text, eg:
2931
2932   select => [\'myfield AS alias']
2933
2934 =head2 join
2935
2936 =over 4
2937
2938 =item Value: ($rel_name | \@rel_names | \%rel_names)
2939
2940 =back
2941
2942 Contains a list of relationships that should be joined for this query.  For
2943 example:
2944
2945   # Get CDs by Nine Inch Nails
2946   my $rs = $schema->resultset('CD')->search(
2947     { 'artist.name' => 'Nine Inch Nails' },
2948     { join => 'artist' }
2949   );
2950
2951 Can also contain a hash reference to refer to the other relation's relations.
2952 For example:
2953
2954   package MyApp::Schema::Track;
2955   use base qw/DBIx::Class/;
2956   __PACKAGE__->table('track');
2957   __PACKAGE__->add_columns(qw/trackid cd position title/);
2958   __PACKAGE__->set_primary_key('trackid');
2959   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2960   1;
2961
2962   # In your application
2963   my $rs = $schema->resultset('Artist')->search(
2964     { 'track.title' => 'Teardrop' },
2965     {
2966       join     => { cd => 'track' },
2967       order_by => 'artist.name',
2968     }
2969   );
2970
2971 You need to use the relationship (not the table) name in  conditions,
2972 because they are aliased as such. The current table is aliased as "me", so
2973 you need to use me.column_name in order to avoid ambiguity. For example:
2974
2975   # Get CDs from 1984 with a 'Foo' track
2976   my $rs = $schema->resultset('CD')->search(
2977     {
2978       'me.year' => 1984,
2979       'tracks.name' => 'Foo'
2980     },
2981     { join => 'tracks' }
2982   );
2983
2984 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2985 similarly for a third time). For e.g.
2986
2987   my $rs = $schema->resultset('Artist')->search({
2988     'cds.title'   => 'Down to Earth',
2989     'cds_2.title' => 'Popular',
2990   }, {
2991     join => [ qw/cds cds/ ],
2992   });
2993
2994 will return a set of all artists that have both a cd with title 'Down
2995 to Earth' and a cd with title 'Popular'.
2996
2997 If you want to fetch related objects from other tables as well, see C<prefetch>
2998 below.
2999
3000 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3001
3002 =head2 prefetch
3003
3004 =over 4
3005
3006 =item Value: ($rel_name | \@rel_names | \%rel_names)
3007
3008 =back
3009
3010 Contains one or more relationships that should be fetched along with
3011 the main query (when they are accessed afterwards the data will
3012 already be available, without extra queries to the database).  This is
3013 useful for when you know you will need the related objects, because it
3014 saves at least one query:
3015
3016   my $rs = $schema->resultset('Tag')->search(
3017     undef,
3018     {
3019       prefetch => {
3020         cd => 'artist'
3021       }
3022     }
3023   );
3024
3025 The initial search results in SQL like the following:
3026
3027   SELECT tag.*, cd.*, artist.* FROM tag
3028   JOIN cd ON tag.cd = cd.cdid
3029   JOIN artist ON cd.artist = artist.artistid
3030
3031 L<DBIx::Class> has no need to go back to the database when we access the
3032 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3033 case.
3034
3035 Simple prefetches will be joined automatically, so there is no need
3036 for a C<join> attribute in the above search.
3037
3038 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3039 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3040 with an accessor type of 'single' or 'filter'). A more complex example that
3041 prefetches an artists cds, the tracks on those cds, and the tags associted
3042 with that artist is given below (assuming many-to-many from artists to tags):
3043
3044  my $rs = $schema->resultset('Artist')->search(
3045    undef,
3046    {
3047      prefetch => [
3048        { cds => 'tracks' },
3049        { artist_tags => 'tags' }
3050      ]
3051    }
3052  );
3053
3054
3055 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3056 attributes will be ignored.
3057
3058 =head2 page
3059
3060 =over 4
3061
3062 =item Value: $page
3063
3064 =back
3065
3066 Makes the resultset paged and specifies the page to retrieve. Effectively
3067 identical to creating a non-pages resultset and then calling ->page($page)
3068 on it.
3069
3070 If L<rows> attribute is not specified it defualts to 10 rows per page.
3071
3072 When you have a paged resultset, L</count> will only return the number
3073 of rows in the page. To get the total, use the L</pager> and call
3074 C<total_entries> on it.
3075
3076 =head2 rows
3077
3078 =over 4
3079
3080 =item Value: $rows
3081
3082 =back
3083
3084 Specifes the maximum number of rows for direct retrieval or the number of
3085 rows per page if the page attribute or method is used.
3086
3087 =head2 offset
3088
3089 =over 4
3090
3091 =item Value: $offset
3092
3093 =back
3094
3095 Specifies the (zero-based) row number for the  first row to be returned, or the
3096 of the first row of the first page if paging is used.
3097
3098 =head2 group_by
3099
3100 =over 4
3101
3102 =item Value: \@columns
3103
3104 =back
3105
3106 A arrayref of columns to group by. Can include columns of joined tables.
3107
3108   group_by => [qw/ column1 column2 ... /]
3109
3110 =head2 having
3111
3112 =over 4
3113
3114 =item Value: $condition
3115
3116 =back
3117
3118 HAVING is a select statement attribute that is applied between GROUP BY and
3119 ORDER BY. It is applied to the after the grouping calculations have been
3120 done.
3121
3122   having => { 'count(employee)' => { '>=', 100 } }
3123
3124 =head2 distinct
3125
3126 =over 4
3127
3128 =item Value: (0 | 1)
3129
3130 =back
3131
3132 Set to 1 to group by all columns.
3133
3134 =head2 where
3135
3136 =over 4
3137
3138 Adds to the WHERE clause.
3139
3140   # only return rows WHERE deleted IS NULL for all searches
3141   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3142
3143 Can be overridden by passing C<{ where => undef }> as an attribute
3144 to a resulset.
3145
3146 =back
3147
3148 =head2 cache
3149
3150 Set to 1 to cache search results. This prevents extra SQL queries if you
3151 revisit rows in your ResultSet:
3152
3153   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3154
3155   while( my $artist = $resultset->next ) {
3156     ... do stuff ...
3157   }
3158
3159   $rs->first; # without cache, this would issue a query
3160
3161 By default, searches are not cached.
3162
3163 For more examples of using these attributes, see
3164 L<DBIx::Class::Manual::Cookbook>.
3165
3166 =head2 from
3167
3168 =over 4
3169
3170 =item Value: \@from_clause
3171
3172 =back
3173
3174 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3175 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3176 clauses.
3177
3178 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3179
3180 C<join> will usually do what you need and it is strongly recommended that you
3181 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3182 And we really do mean "cannot", not just tried and failed. Attempting to use
3183 this because you're having problems with C<join> is like trying to use x86
3184 ASM because you've got a syntax error in your C. Trust us on this.
3185
3186 Now, if you're still really, really sure you need to use this (and if you're
3187 not 100% sure, ask the mailing list first), here's an explanation of how this
3188 works.
3189
3190 The syntax is as follows -
3191
3192   [
3193     { <alias1> => <table1> },
3194     [
3195       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3196       [], # nested JOIN (optional)
3197       { <table1.column1> => <table2.column2>, ... (more conditions) },
3198     ],
3199     # More of the above [ ] may follow for additional joins
3200   ]
3201
3202   <table1> <alias1>
3203   JOIN
3204     <table2> <alias2>
3205     [JOIN ...]
3206   ON <table1.column1> = <table2.column2>
3207   <more joins may follow>
3208
3209 An easy way to follow the examples below is to remember the following:
3210
3211     Anything inside "[]" is a JOIN
3212     Anything inside "{}" is a condition for the enclosing JOIN
3213
3214 The following examples utilize a "person" table in a family tree application.
3215 In order to express parent->child relationships, this table is self-joined:
3216
3217     # Person->belongs_to('father' => 'Person');
3218     # Person->belongs_to('mother' => 'Person');
3219
3220 C<from> can be used to nest joins. Here we return all children with a father,
3221 then search against all mothers of those children:
3222
3223   $rs = $schema->resultset('Person')->search(
3224       undef,
3225       {
3226           alias => 'mother', # alias columns in accordance with "from"
3227           from => [
3228               { mother => 'person' },
3229               [
3230                   [
3231                       { child => 'person' },
3232                       [
3233                           { father => 'person' },
3234                           { 'father.person_id' => 'child.father_id' }
3235                       ]
3236                   ],
3237                   { 'mother.person_id' => 'child.mother_id' }
3238               ],
3239           ]
3240       },
3241   );
3242
3243   # Equivalent SQL:
3244   # SELECT mother.* FROM person mother
3245   # JOIN (
3246   #   person child
3247   #   JOIN person father
3248   #   ON ( father.person_id = child.father_id )
3249   # )
3250   # ON ( mother.person_id = child.mother_id )
3251
3252 The type of any join can be controlled manually. To search against only people
3253 with a father in the person table, we could explicitly use C<INNER JOIN>:
3254
3255     $rs = $schema->resultset('Person')->search(
3256         undef,
3257         {
3258             alias => 'child', # alias columns in accordance with "from"
3259             from => [
3260                 { child => 'person' },
3261                 [
3262                     { father => 'person', -join_type => 'inner' },
3263                     { 'father.id' => 'child.father_id' }
3264                 ],
3265             ]
3266         },
3267     );
3268
3269     # Equivalent SQL:
3270     # SELECT child.* FROM person child
3271     # INNER JOIN person father ON child.father_id = father.id
3272
3273 If you need to express really complex joins or you need a subselect, you
3274 can supply literal SQL to C<from> via a scalar reference. In this case
3275 the contents of the scalar will replace the table name asscoiated with the
3276 resultsource.
3277
3278 WARNING: This technique might very well not work as expected on chained
3279 searches - you have been warned.
3280
3281     # Assuming the Event resultsource is defined as:
3282
3283         MySchema::Event->add_columns (
3284             sequence => {
3285                 data_type => 'INT',
3286                 is_auto_increment => 1,
3287             },
3288             location => {
3289                 data_type => 'INT',
3290             },
3291             type => {
3292                 data_type => 'INT',
3293             },
3294         );
3295         MySchema::Event->set_primary_key ('sequence');
3296
3297     # This will get back the latest event for every location. The column
3298     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3299     # combo to limit the resultset
3300
3301     $rs = $schema->resultset('Event');
3302     $table = $rs->result_source->name;
3303     $latest = $rs->search (
3304         undef,
3305         { from => \ "
3306             (SELECT e1.* FROM $table e1
3307                 JOIN $table e2
3308                     ON e1.location = e2.location
3309                     AND e1.sequence < e2.sequence
3310                 WHERE e2.sequence is NULL
3311             ) me",
3312         },
3313     );
3314
3315     # Equivalent SQL (with the DBIC chunks added):
3316
3317     SELECT me.sequence, me.location, me.type FROM
3318        (SELECT e1.* FROM events e1
3319            JOIN events e2
3320                ON e1.location = e2.location
3321                AND e1.sequence < e2.sequence
3322            WHERE e2.sequence is NULL
3323        ) me;
3324
3325 =head2 for
3326
3327 =over 4
3328
3329 =item Value: ( 'update' | 'shared' )
3330
3331 =back
3332
3333 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3334 ... FOR SHARED.
3335
3336 =cut
3337
3338 1;