lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use DBIx::Class::Exception;
   8 use Data::Page;
   9 use Storable;
  10 use DBIx::Class::ResultSetColumn;
  11 use DBIx::Class::ResultSourceHandle;
  12 use Hash::Merge ();
  13 use Scalar::Util qw/blessed weaken/;
  14 use Try::Tiny;
  15 use Storable qw/nfreeze thaw/;
  16
  17 # not importing first() as it will clash with our own method
  18 use List::Util ();
  19
  20 use namespace::clean;
  21
  22
  23 BEGIN {
  24   # De-duplication in _merge_attr() is disabled, but left in for reference
  25   # (the merger is used for other things that ought not to be de-duped)
  26   *__HM_DEDUP = sub () { 0 };
  27 }
  28
  29 use overload
  30         '0+'     => "count",
  31         'bool'   => "_bool",
  32         fallback => 1;
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  35
  36 =head1 NAME
  37
  38 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  39
  40 =head1 SYNOPSIS
  41
  42   my $users_rs   = $schema->resultset('User');
  43   while( $user = $users_rs->next) {
  44     print $user->username;
  45   }
  46
  47   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  48   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  49
  50 =head1 DESCRIPTION
  51
  52 A ResultSet is an object which stores a set of conditions representing
  53 a query. It is the backbone of DBIx::Class (i.e. the really
  54 important/useful bit).
  55
  56 No SQL is executed on the database when a ResultSet is created, it
  57 just stores all the conditions needed to create the query.
  58
  59 A basic ResultSet representing the data of an entire table is returned
  60 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  61 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  62
  63   my $users_rs = $schema->resultset('User');
  64
  65 A new ResultSet is returned from calling L</search> on an existing
  66 ResultSet. The new one will contain all the conditions of the
  67 original, plus any new conditions added in the C<search> call.
  68
  69 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  70 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  71 represents.
  72
  73 The query that the ResultSet represents is B<only> executed against
  74 the database when these methods are called:
  75 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  76
  77 If a resultset is used in a numeric context it returns the L</count>.
  78 However, if it is used in a boolean context it is B<always> true.  So if
  79 you want to check if a resultset has any results, you must use C<if $rs
  80 != 0>.
  81
  82 =head1 EXAMPLES
  83
  84 =head2 Chaining resultsets
  85
  86 Let's say you've got a query that needs to be run to return some data
  87 to the user. But, you have an authorization system in place that
  88 prevents certain users from seeing certain information. So, you want
  89 to construct the basic query in one method, but add constraints to it in
  90 another.
  91
  92   sub get_data {
  93     my $self = shift;
  94     my $request = $self->get_request; # Get a request object somehow.
  95     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  96
  97     my $cd_rs = $schema->resultset('CD')->search({
  98       title => $request->param('title'),
  99       year => $request->param('year'),
 100     });
 101
 102     $self->apply_security_policy( $cd_rs );
 103
 104     return $cd_rs->all();
 105   }
 106
 107   sub apply_security_policy {
 108     my $self = shift;
 109     my ($rs) = @_;
 110
 111     return $rs->search({
 112       subversive => 0,
 113     });
 114   }
 115
 116 =head3 Resolving conditions and attributes
 117
 118 When a resultset is chained from another resultset, conditions and
 119 attributes with the same keys need resolving.
 120
 121 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 122 into the existing ones from the original resultset.
 123
 124 The L</where> and L</having> attributes, and any search conditions, are
 125 merged with an SQL C<AND> to the existing condition from the original
 126 resultset.
 127
 128 All other attributes are overridden by any new ones supplied in the
 129 search attributes.
 130
 131 =head2 Multiple queries
 132
 133 Since a resultset just defines a query, you can do all sorts of
 134 things with it with the same object.
 135
 136   # Don't hit the DB yet.
 137   my $cd_rs = $schema->resultset('CD')->search({
 138     title => 'something',
 139     year => 2009,
 140   });
 141
 142   # Each of these hits the DB individually.
 143   my $count = $cd_rs->count;
 144   my $most_recent = $cd_rs->get_column('date_released')->max();
 145   my @records = $cd_rs->all;
 146
 147 And it's not just limited to SELECT statements.
 148
 149   $cd_rs->delete();
 150
 151 This is even cooler:
 152
 153   $cd_rs->create({ artist => 'Fred' });
 154
 155 Which is the same as:
 156
 157   $schema->resultset('CD')->create({
 158     title => 'something',
 159     year => 2009,
 160     artist => 'Fred'
 161   });
 162
 163 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 164
 165 =head1 METHODS
 166
 167 =head2 new
 168
 169 =over 4
 170
 171 =item Arguments: $source, \%$attrs
 172
 173 =item Return Value: $rs
 174
 175 =back
 176
 177 The resultset constructor. Takes a source object (usually a
 178 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 179 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 180 executed as needed by the other methods.
 181
 182 Generally you won't need to construct a resultset manually.  You'll
 183 automatically get one from e.g. a L</search> called in scalar context:
 184
 185   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 186
 187 IMPORTANT: If called on an object, proxies to new_result instead so
 188
 189   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 190
 191 will return a CD object, not a ResultSet.
 192
 193 =cut
 194
 195 sub new {
 196   my $class = shift;
 197   return $class->new_result(@_) if ref $class;
 198
 199   my ($source, $attrs) = @_;
 200   $source = $source->handle
 201     unless $source->isa('DBIx::Class::ResultSourceHandle');
 202   $attrs = { %{$attrs||{}} };
 203
 204   if ($attrs->{page}) {
 205     $attrs->{rows} ||= 10;
 206   }
 207
 208   $attrs->{alias} ||= 'me';
 209
 210   # Creation of {} and bless separated to mitigate RH perl bug
 211   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 212   my $self = {
 213     _source_handle => $source,
 214     cond => $attrs->{where},
 215     pager => undef,
 216     attrs => $attrs
 217   };
 218
 219   bless $self, $class;
 220
 221   $self->result_class(
 222     $attrs->{result_class} || $source->resolve->result_class
 223   );
 224
 225   return $self;
 226 }
 227
 228 =head2 search
 229
 230 =over 4
 231
 232 =item Arguments: $cond, \%attrs?
 233
 234 =item Return Value: $resultset (scalar context), @row_objs (list context)
 235
 236 =back
 237
 238   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 239   my $new_rs = $cd_rs->search({ year => 2005 });
 240
 241   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 242                  # year = 2005 OR year = 2004
 243
 244 If you need to pass in additional attributes but no additional condition,
 245 call it as C<search(undef, \%attrs)>.
 246
 247   # "SELECT name, artistid FROM $artist_table"
 248   my @all_artists = $schema->resultset('Artist')->search(undef, {
 249     columns => [qw/name artistid/],
 250   });
 251
 252 For a list of attributes that can be passed to C<search>, see
 253 L</ATTRIBUTES>. For more examples of using this function, see
 254 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 255 documentation for the first argument, see L<SQL::Abstract>.
 256
 257 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 258
 259 =head3 CAVEAT
 260
 261 Note that L</search> does not process/deflate any of the values passed in the
 262 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 263 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 264 manually that any value passed to this method will stringify to something the
 265 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 266 objects, for more info see:
 267 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
 268
 269 =cut
 270
 271 sub search {
 272   my $self = shift;
 273   my $rs = $self->search_rs( @_ );
 274
 275   if (wantarray) {
 276     return $rs->all;
 277   }
 278   elsif (defined wantarray) {
 279     return $rs;
 280   }
 281   else {
 282     # we can be called by a relationship helper, which in
 283     # turn may be called in void context due to some braindead
 284     # overload or whatever else the user decided to be clever
 285     # at this particular day. Thus limit the exception to
 286     # external code calls only
 287     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 288       if (caller)[0] !~ /^\QDBIx::Class::/;
 289
 290     return ();
 291   }
 292 }
 293
 294 =head2 search_rs
 295
 296 =over 4
 297
 298 =item Arguments: $cond, \%attrs?
 299
 300 =item Return Value: $resultset
 301
 302 =back
 303
 304 This method does the same exact thing as search() except it will
 305 always return a resultset, even in list context.
 306
 307 =cut
 308
 309 my $callsites_warned;
 310 sub search_rs {
 311   my $self = shift;
 312
 313   # Special-case handling for (undef, undef).
 314   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 315     @_ = ();
 316   }
 317
 318   my $call_attrs = {};
 319   if (@_ > 1) {
 320     if (ref $_[-1] eq 'HASH') {
 321       # copy for _normalize_selection
 322       $call_attrs = { %{ pop @_ } };
 323     }
 324     elsif (! defined $_[-1] ) {
 325       pop @_;   # search({}, undef)
 326     }
 327   }
 328
 329   # see if we can keep the cache (no $rs changes)
 330   my $cache;
 331   my %safe = (alias => 1, cache => 1);
 332   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 333     ! defined $_[0]
 334       or
 335     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 336       or
 337     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 338   )) {
 339     $cache = $self->get_cache;
 340   }
 341
 342   my $rsrc = $self->result_source;
 343
 344   my $old_attrs = { %{$self->{attrs}} };
 345   my $old_having = delete $old_attrs->{having};
 346   my $old_where = delete $old_attrs->{where};
 347
 348   my $new_attrs = { %$old_attrs };
 349
 350   # take care of call attrs (only if anything is changing)
 351   if (keys %$call_attrs) {
 352
 353     $self->throw_exception ('_trailing_select is not a public attribute - do not use it in search()')
 354       if ( exists $call_attrs->{_trailing_select} or exists $call_attrs->{'+_trailing_select'} );
 355
 356     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns _trailing_select +_trailing_select/;
 357
 358     # Normalize the selector list (operates on the passed-in attr structure)
 359     # Need to do it on every chain instead of only once on _resolved_attrs, in
 360     # order to separate 'as'-ed from blind 'select's
 361     $self->_normalize_selection ($call_attrs);
 362
 363     # start with blind overwriting merge, exclude selector attrs
 364     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 365     delete @{$new_attrs}{@selector_attrs};
 366
 367     # reset the current selector list if new selectors are supplied
 368     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 369       delete @{$old_attrs}{@selector_attrs};
 370     }
 371
 372     for (@selector_attrs) {
 373       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 374         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 375     }
 376
 377     # older deprecated name, use only if {columns} is not there
 378     if (my $c = delete $new_attrs->{cols}) {
 379       if ($new_attrs->{columns}) {
 380         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 381       }
 382       else {
 383         $new_attrs->{columns} = $c;
 384       }
 385     }
 386
 387
 388     # join/prefetch use their own crazy merging heuristics
 389     foreach my $key (qw/join prefetch/) {
 390       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 391         if exists $call_attrs->{$key};
 392     }
 393
 394     # stack binds together
 395     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 396   }
 397
 398
 399   # rip apart the rest of @_, parse a condition
 400   my $call_cond = do {
 401
 402     if (ref $_[0] eq 'HASH') {
 403       (keys %{$_[0]}) ? $_[0] : undef
 404     }
 405     elsif (@_ == 1) {
 406       $_[0]
 407     }
 408     elsif (@_ % 2) {
 409       $self->throw_exception('Odd number of arguments to search')
 410     }
 411     else {
 412       +{ @_ }
 413     }
 414
 415   } if @_;
 416
 417   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 418     # determine callsite obeying Carp::Clan rules (fucking ugly but don't have better ideas)
 419     my $callsite = do {
 420       my $w;
 421       local $SIG{__WARN__} = sub { $w = shift };
 422       carp;
 423       $w
 424     };
 425     carp 'search( %condition ) is deprecated, use search( \%condition ) instead'
 426       unless $callsites_warned->{$callsite}++;
 427   }
 428
 429   for ($old_where, $call_cond) {
 430     if (defined $_) {
 431       $new_attrs->{where} = $self->_stack_cond (
 432         $_, $new_attrs->{where}
 433       );
 434     }
 435   }
 436
 437   if (defined $old_having) {
 438     $new_attrs->{having} = $self->_stack_cond (
 439       $old_having, $new_attrs->{having}
 440     )
 441   }
 442
 443   my $rs = (ref $self)->new($rsrc, $new_attrs);
 444
 445   $rs->set_cache($cache) if ($cache);
 446
 447   return $rs;
 448 }
 449
 450 sub _normalize_selection {
 451   my ($self, $attrs) = @_;
 452
 453   # legacy syntax
 454   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 455     if exists $attrs->{include_columns};
 456
 457   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 458   # delay the decision on whether to use a default select list ($rsrc->columns)
 459   # allowing stuff like the remove_columns helper to work
 460   #
 461   # select/as +select/+as pairs need special handling - the amount of select/as
 462   # elements in each pair does *not* have to be equal (think multicolumn
 463   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 464   # supplied at all) - try to infer the alias, either from the -as parameter
 465   # of the selector spec, or use the parameter whole if it looks like a column
 466   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 467   # is ok as well), but transport it over a separate attribute to make sure it is
 468   # the last thing in the select list, thus unable to throw off the corresponding
 469   # 'as' chain
 470   for my $pref ('', '+') {
 471
 472     my ($sel, $as) = map {
 473       my $key = "${pref}${_}";
 474
 475       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 476         ? @{$attrs->{$key}}
 477         : $attrs->{$key} || ()
 478       ];
 479       delete $attrs->{$key};
 480       $val;
 481     } qw/select as/;
 482
 483     if (! @$as and ! @$sel ) {
 484       next;
 485     }
 486     elsif (@$as and ! @$sel) {
 487       $self->throw_exception(
 488         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 489       );
 490     }
 491     elsif( ! @$as ) {
 492       # no as part supplied at all - try to deduce
 493       # if any @$as has been supplied we assume the user knows what (s)he is doing
 494       # and blindly keep stacking up pieces
 495       my (@new_sel, @new_trailing);
 496       for (@$sel) {
 497         if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 498           push @$as, $_->{-as};
 499           push @new_sel, $_;
 500         }
 501         # assume any plain no-space, no-parenthesis string to be a column spec
 502         # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 503         elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 504           push @$as, $_;
 505           push @new_sel, $_;
 506         }
 507         # if all else fails - shove the selection to the trailing stack and move on
 508         else {
 509           push @new_trailing, $_;
 510         }
 511       }
 512
 513       @$sel = @new_sel;
 514       $attrs->{"${pref}_trailing_select"} = $self->_merge_attr($attrs->{"${pref}_trailing_select"}, \@new_trailing)
 515         if @new_trailing;
 516     }
 517     elsif (@$as < @$sel) {
 518       $self->throw_exception(
 519         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 520       );
 521     }
 522
 523     # now see what the result for this pair looks like:
 524     if (@$as == @$sel) {
 525
 526       # if balanced - treat as a columns entry
 527       $attrs->{"${pref}columns"} = $self->_merge_attr(
 528         $attrs->{"${pref}columns"},
 529         [ map { +{ $as->[$_] => $sel->[$_] } } ( 0 .. $#$as ) ]
 530       );
 531     }
 532     else {
 533       # unbalanced - shove in select/as, not subject to deduplication in _resolved_attrs
 534       $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 535       $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 536     }
 537   }
 538
 539 }
 540
 541 sub _stack_cond {
 542   my ($self, $left, $right) = @_;
 543   if (defined $left xor defined $right) {
 544     return defined $left ? $left : $right;
 545   }
 546   elsif (defined $left) {
 547     return { -and => [ map
 548       { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 549       ($left, $right)
 550     ]};
 551   }
 552
 553   return undef;
 554 }
 555
 556 =head2 search_literal
 557
 558 =over 4
 559
 560 =item Arguments: $sql_fragment, @bind_values
 561
 562 =item Return Value: $resultset (scalar context), @row_objs (list context)
 563
 564 =back
 565
 566   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 567   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 568
 569 Pass a literal chunk of SQL to be added to the conditional part of the
 570 resultset query.
 571
 572 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 573 only be used in that context. C<search_literal> is a convenience method.
 574 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 575 columns are bound correctly, use C<search>.
 576
 577 Example of how to use C<search> instead of C<search_literal>
 578
 579   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 580   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 581
 582
 583 See L<DBIx::Class::Manual::Cookbook/Searching> and
 584 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 585 require C<search_literal>.
 586
 587 =cut
 588
 589 sub search_literal {
 590   my ($self, $sql, @bind) = @_;
 591   my $attr;
 592   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 593     $attr = pop @bind;
 594   }
 595   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 596 }
 597
 598 =head2 find
 599
 600 =over 4
 601
 602 =item Arguments: \%columns_values | @pk_values, \%attrs?
 603
 604 =item Return Value: $row_object | undef
 605
 606 =back
 607
 608 Finds and returns a single row based on supplied criteria. Takes either a
 609 hashref with the same format as L</create> (including inference of foreign
 610 keys from related objects), or a list of primary key values in the same
 611 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 612 declaration on the L</result_source>.
 613
 614 In either case an attempt is made to combine conditions already existing on
 615 the resultset with the condition passed to this method.
 616
 617 To aid with preparing the correct query for the storage you may supply the
 618 C<key> attribute, which is the name of a
 619 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 620 unique constraint corresponding to the
 621 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 622 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 623 to construct a query that satisfies the named unique constraint fully (
 624 non-NULL values for each column member of the constraint) an exception is
 625 thrown.
 626
 627 If no C<key> is specified, the search is carried over all unique constraints
 628 which are fully defined by the available condition.
 629
 630 If no such constraint is found, C<find> currently defaults to a simple
 631 C<< search->(\%column_values) >> which may or may not do what you expect.
 632 Note that this fallback behavior may be deprecated in further versions. If
 633 you need to search with arbitrary conditions - use L</search>. If the query
 634 resulting from this fallback produces more than one row, a warning to the
 635 effect is issued, though only the first row is constructed and returned as
 636 C<$row_object>.
 637
 638 In addition to C<key>, L</find> recognizes and applies standard
 639 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 640
 641 Note that if you have extra concerns about the correctness of the resulting
 642 query you need to specify the C<key> attribute and supply the entire condition
 643 as an argument to find (since it is not always possible to perform the
 644 combination of the resultset condition with the supplied one, especially if
 645 the resultset condition contains literal sql).
 646
 647 For example, to find a row by its primary key:
 648
 649   my $cd = $schema->resultset('CD')->find(5);
 650
 651 You can also find a row by a specific unique constraint:
 652
 653   my $cd = $schema->resultset('CD')->find(
 654     {
 655       artist => 'Massive Attack',
 656       title  => 'Mezzanine',
 657     },
 658     { key => 'cd_artist_title' }
 659   );
 660
 661 See also L</find_or_create> and L</update_or_create>.
 662
 663 =cut
 664
 665 sub find {
 666   my $self = shift;
 667   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 668
 669   my $rsrc = $self->result_source;
 670
 671   # Parse out the condition from input
 672   my $call_cond;
 673   if (ref $_[0] eq 'HASH') {
 674     $call_cond = { %{$_[0]} };
 675   }
 676   else {
 677     my $constraint = exists $attrs->{key} ? $attrs->{key} : 'primary';
 678     my @c_cols = $rsrc->unique_constraint_columns($constraint);
 679
 680     $self->throw_exception(
 681       "No constraint columns, maybe a malformed '$constraint' constraint?"
 682     ) unless @c_cols;
 683
 684     $self->throw_exception (
 685       'find() expects either a column/value hashref, or a list of values '
 686     . "corresponding to the columns of the specified unique constraint '$constraint'"
 687     ) unless @c_cols == @_;
 688
 689     $call_cond = {};
 690     @{$call_cond}{@c_cols} = @_;
 691   }
 692
 693   my %related;
 694   for my $key (keys %$call_cond) {
 695     if (
 696       my $keyref = ref($call_cond->{$key})
 697         and
 698       my $relinfo = $rsrc->relationship_info($key)
 699     ) {
 700       my $val = delete $call_cond->{$key};
 701
 702       next if $keyref eq 'ARRAY'; # has_many for multi_create
 703
 704       my $rel_q = $rsrc->_resolve_condition(
 705         $relinfo->{cond}, $val, $key
 706       );
 707       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 708       @related{keys %$rel_q} = values %$rel_q;
 709     }
 710   }
 711
 712   # relationship conditions take precedence (?)
 713   @{$call_cond}{keys %related} = values %related;
 714
 715   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 716   my $final_cond;
 717   if (exists $attrs->{key}) {
 718     $final_cond = $self->_qualify_cond_columns (
 719
 720       $self->_build_unique_cond (
 721         $attrs->{key},
 722         $call_cond,
 723       ),
 724
 725       $alias,
 726     );
 727   }
 728   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 729     # This means that we got here after a merger of relationship conditions
 730     # in ::Relationship::Base::search_related (the row method), and furthermore
 731     # the relationship is of the 'single' type. This means that the condition
 732     # provided by the relationship (already attached to $self) is sufficient,
 733     # as there can be only one row in the database that would satisfy the
 734     # relationship
 735   }
 736   else {
 737     # no key was specified - fall down to heuristics mode:
 738     # run through all unique queries registered on the resultset, and
 739     # 'OR' all qualifying queries together
 740     my (@unique_queries, %seen_column_combinations);
 741     for my $c_name ($rsrc->unique_constraint_names) {
 742       next if $seen_column_combinations{
 743         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 744       }++;
 745
 746       push @unique_queries, try {
 747         $self->_build_unique_cond ($c_name, $call_cond)
 748       } || ();
 749     }
 750
 751     $final_cond = @unique_queries
 752       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 753       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 754     ;
 755   }
 756
 757   # Run the query, passing the result_class since it should propagate for find
 758   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 759   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 760     my $row = $rs->next;
 761     carp "Query returned more than one row" if $rs->next;
 762     return $row;
 763   }
 764   else {
 765     return $rs->single;
 766   }
 767 }
 768
 769 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 770 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 771 #
 772 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 773 # condition. It is provided for overrides until a saner way forward is devised
 774 #
 775 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 776 # the road. Please adjust your tests accordingly to catch this situation early
 777 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 778 #
 779 # The method will not be removed without an adequately complete replacement
 780 # for strict-mode enforcement
 781 sub _non_unique_find_fallback {
 782   my ($self, $cond, $attrs) = @_;
 783
 784   return $self->_qualify_cond_columns(
 785     $cond,
 786     exists $attrs->{alias}
 787       ? $attrs->{alias}
 788       : $self->{attrs}{alias}
 789   );
 790 }
 791
 792
 793 sub _qualify_cond_columns {
 794   my ($self, $cond, $alias) = @_;
 795
 796   my %aliased = %$cond;
 797   for (keys %aliased) {
 798     $aliased{"$alias.$_"} = delete $aliased{$_}
 799       if $_ !~ /\./;
 800   }
 801
 802   return \%aliased;
 803 }
 804
 805 sub _build_unique_cond {
 806   my ($self, $constraint_name, $extra_cond) = @_;
 807
 808   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 809
 810   # combination may fail if $self->{cond} is non-trivial
 811   my ($final_cond) = try {
 812     $self->_merge_with_rscond ($extra_cond)
 813   } catch {
 814     +{ %$extra_cond }
 815   };
 816
 817   # trim out everything not in $columns
 818   $final_cond = { map { $_ => $final_cond->{$_} } @c_cols };
 819
 820   if (my @missing = grep { ! defined $final_cond->{$_} } (@c_cols) ) {
 821     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 822       $constraint_name,
 823       join (', ', map { "'$_'" } @missing),
 824     ) );
 825   }
 826
 827   return $final_cond;
 828 }
 829
 830 =head2 search_related
 831
 832 =over 4
 833
 834 =item Arguments: $rel, $cond, \%attrs?
 835
 836 =item Return Value: $new_resultset
 837
 838 =back
 839
 840   $new_rs = $cd_rs->search_related('artist', {
 841     name => 'Emo-R-Us',
 842   });
 843
 844 Searches the specified relationship, optionally specifying a condition and
 845 attributes for matching records. See L</ATTRIBUTES> for more information.
 846
 847 =cut
 848
 849 sub search_related {
 850   return shift->related_resultset(shift)->search(@_);
 851 }
 852
 853 =head2 search_related_rs
 854
 855 This method works exactly the same as search_related, except that
 856 it guarantees a resultset, even in list context.
 857
 858 =cut
 859
 860 sub search_related_rs {
 861   return shift->related_resultset(shift)->search_rs(@_);
 862 }
 863
 864 =head2 cursor
 865
 866 =over 4
 867
 868 =item Arguments: none
 869
 870 =item Return Value: $cursor
 871
 872 =back
 873
 874 Returns a storage-driven cursor to the given resultset. See
 875 L<DBIx::Class::Cursor> for more information.
 876
 877 =cut
 878
 879 sub cursor {
 880   my ($self) = @_;
 881
 882   my $attrs = $self->_resolved_attrs_copy;
 883
 884   return $self->{cursor}
 885     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 886           $attrs->{where},$attrs);
 887 }
 888
 889 =head2 single
 890
 891 =over 4
 892
 893 =item Arguments: $cond?
 894
 895 =item Return Value: $row_object | undef
 896
 897 =back
 898
 899   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 900
 901 Inflates the first result without creating a cursor if the resultset has
 902 any records in it; if not returns C<undef>. Used by L</find> as a lean version
 903 of L</search>.
 904
 905 While this method can take an optional search condition (just like L</search>)
 906 being a fast-code-path it does not recognize search attributes. If you need to
 907 add extra joins or similar, call L</search> and then chain-call L</single> on the
 908 L<DBIx::Class::ResultSet> returned.
 909
 910 =over
 911
 912 =item B<Note>
 913
 914 As of 0.08100, this method enforces the assumption that the preceding
 915 query returns only one row. If more than one row is returned, you will receive
 916 a warning:
 917
 918   Query returned more than one row
 919
 920 In this case, you should be using L</next> or L</find> instead, or if you really
 921 know what you are doing, use the L</rows> attribute to explicitly limit the size
 922 of the resultset.
 923
 924 This method will also throw an exception if it is called on a resultset prefetching
 925 has_many, as such a prefetch implies fetching multiple rows from the database in
 926 order to assemble the resulting object.
 927
 928 =back
 929
 930 =cut
 931
 932 sub single {
 933   my ($self, $where) = @_;
 934   if(@_ > 2) {
 935       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 936   }
 937
 938   my $attrs = $self->_resolved_attrs_copy;
 939
 940   if (keys %{$attrs->{collapse}}) {
 941     $self->throw_exception(
 942       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 943     );
 944   }
 945
 946   if ($where) {
 947     if (defined $attrs->{where}) {
 948       $attrs->{where} = {
 949         '-and' =>
 950             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 951                $where, delete $attrs->{where} ]
 952       };
 953     } else {
 954       $attrs->{where} = $where;
 955     }
 956   }
 957
 958   my @data = $self->result_source->storage->select_single(
 959     $attrs->{from}, $attrs->{select},
 960     $attrs->{where}, $attrs
 961   );
 962
 963   return (@data ? ($self->_construct_object(@data))[0] : undef);
 964 }
 965
 966
 967 # _collapse_query
 968 #
 969 # Recursively collapse the query, accumulating values for each column.
 970
 971 sub _collapse_query {
 972   my ($self, $query, $collapsed) = @_;
 973
 974   $collapsed ||= {};
 975
 976   if (ref $query eq 'ARRAY') {
 977     foreach my $subquery (@$query) {
 978       next unless ref $subquery;  # -or
 979       $collapsed = $self->_collapse_query($subquery, $collapsed);
 980     }
 981   }
 982   elsif (ref $query eq 'HASH') {
 983     if (keys %$query and (keys %$query)[0] eq '-and') {
 984       foreach my $subquery (@{$query->{-and}}) {
 985         $collapsed = $self->_collapse_query($subquery, $collapsed);
 986       }
 987     }
 988     else {
 989       foreach my $col (keys %$query) {
 990         my $value = $query->{$col};
 991         $collapsed->{$col}{$value}++;
 992       }
 993     }
 994   }
 995
 996   return $collapsed;
 997 }
 998
 999 =head2 get_column
1000
1001 =over 4
1002
1003 =item Arguments: $cond?
1004
1005 =item Return Value: $resultsetcolumn
1006
1007 =back
1008
1009   my $max_length = $rs->get_column('length')->max;
1010
1011 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1012
1013 =cut
1014
1015 sub get_column {
1016   my ($self, $column) = @_;
1017   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1018   return $new;
1019 }
1020
1021 =head2 search_like
1022
1023 =over 4
1024
1025 =item Arguments: $cond, \%attrs?
1026
1027 =item Return Value: $resultset (scalar context), @row_objs (list context)
1028
1029 =back
1030
1031   # WHERE title LIKE '%blue%'
1032   $cd_rs = $rs->search_like({ title => '%blue%'});
1033
1034 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1035 that this is simply a convenience method retained for ex Class::DBI users.
1036 You most likely want to use L</search> with specific operators.
1037
1038 For more information, see L<DBIx::Class::Manual::Cookbook>.
1039
1040 This method is deprecated and will be removed in 0.09. Use L</search()>
1041 instead. An example conversion is:
1042
1043   ->search_like({ foo => 'bar' });
1044
1045   # Becomes
1046
1047   ->search({ foo => { like => 'bar' } });
1048
1049 =cut
1050
1051 sub search_like {
1052   my $class = shift;
1053   carp (
1054     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1055    .' Instead use ->search({ x => { -like => "y%" } })'
1056    .' (note the outer pair of {}s - they are important!)'
1057   );
1058   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1059   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1060   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1061   return $class->search($query, { %$attrs });
1062 }
1063
1064 =head2 slice
1065
1066 =over 4
1067
1068 =item Arguments: $first, $last
1069
1070 =item Return Value: $resultset (scalar context), @row_objs (list context)
1071
1072 =back
1073
1074 Returns a resultset or object list representing a subset of elements from the
1075 resultset slice is called on. Indexes are from 0, i.e., to get the first
1076 three records, call:
1077
1078   my ($one, $two, $three) = $rs->slice(0, 2);
1079
1080 =cut
1081
1082 sub slice {
1083   my ($self, $min, $max) = @_;
1084   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1085   $attrs->{offset} = $self->{attrs}{offset} || 0;
1086   $attrs->{offset} += $min;
1087   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1088   return $self->search(undef, $attrs);
1089   #my $slice = (ref $self)->new($self->result_source, $attrs);
1090   #return (wantarray ? $slice->all : $slice);
1091 }
1092
1093 =head2 next
1094
1095 =over 4
1096
1097 =item Arguments: none
1098
1099 =item Return Value: $result | undef
1100
1101 =back
1102
1103 Returns the next element in the resultset (C<undef> is there is none).
1104
1105 Can be used to efficiently iterate over records in the resultset:
1106
1107   my $rs = $schema->resultset('CD')->search;
1108   while (my $cd = $rs->next) {
1109     print $cd->title;
1110   }
1111
1112 Note that you need to store the resultset object, and call C<next> on it.
1113 Calling C<< resultset('Table')->next >> repeatedly will always return the
1114 first record from the resultset.
1115
1116 =cut
1117
1118 sub next {
1119   my ($self) = @_;
1120   if (my $cache = $self->get_cache) {
1121     $self->{all_cache_position} ||= 0;
1122     return $cache->[$self->{all_cache_position}++];
1123   }
1124   if ($self->{attrs}{cache}) {
1125     delete $self->{pager};
1126     $self->{all_cache_position} = 1;
1127     return ($self->all)[0];
1128   }
1129   if ($self->{stashed_objects}) {
1130     my $obj = shift(@{$self->{stashed_objects}});
1131     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1132     return $obj;
1133   }
1134   my @row = (
1135     exists $self->{stashed_row}
1136       ? @{delete $self->{stashed_row}}
1137       : $self->cursor->next
1138   );
1139   return undef unless (@row);
1140   my ($row, @more) = $self->_construct_object(@row);
1141   $self->{stashed_objects} = \@more if @more;
1142   return $row;
1143 }
1144
1145 sub _construct_object {
1146   my ($self, @row) = @_;
1147
1148   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1149     or return ();
1150   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1151   @new = $self->{_attrs}{record_filter}->(@new)
1152     if exists $self->{_attrs}{record_filter};
1153   return @new;
1154 }
1155
1156 sub _collapse_result {
1157   my ($self, $as_proto, $row) = @_;
1158
1159   my @copy = @$row;
1160
1161   # 'foo'         => [ undef, 'foo' ]
1162   # 'foo.bar'     => [ 'foo', 'bar' ]
1163   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1164
1165   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1166
1167   my %collapse = %{$self->{_attrs}{collapse}||{}};
1168
1169   my @pri_index;
1170
1171   # if we're doing collapsing (has_many prefetch) we need to grab records
1172   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1173   # we know we don't have to bother.
1174
1175   # the reason for not using the collapse stuff directly is because if you
1176   # had for e.g. two artists in a row with no cds, the collapse info for
1177   # both would be NULL (undef) so you'd lose the second artist
1178
1179   # store just the index so we can check the array positions from the row
1180   # without having to contruct the full hash
1181
1182   if (keys %collapse) {
1183     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1184     foreach my $i (0 .. $#construct_as) {
1185       next if defined($construct_as[$i][0]); # only self table
1186       if (delete $pri{$construct_as[$i][1]}) {
1187         push(@pri_index, $i);
1188       }
1189       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1190     }
1191   }
1192
1193   # no need to do an if, it'll be empty if @pri_index is empty anyway
1194
1195   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1196
1197   my @const_rows;
1198
1199   do { # no need to check anything at the front, we always want the first row
1200
1201     my %const;
1202
1203     foreach my $this_as (@construct_as) {
1204       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1205     }
1206
1207     push(@const_rows, \%const);
1208
1209   } until ( # no pri_index => no collapse => drop straight out
1210       !@pri_index
1211     or
1212       do { # get another row, stash it, drop out if different PK
1213
1214         @copy = $self->cursor->next;
1215         $self->{stashed_row} = \@copy;
1216
1217         # last thing in do block, counts as true if anything doesn't match
1218
1219         # check xor defined first for NULL vs. NOT NULL then if one is
1220         # defined the other must be so check string equality
1221
1222         grep {
1223           (defined $pri_vals{$_} ^ defined $copy[$_])
1224           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1225         } @pri_index;
1226       }
1227   );
1228
1229   my $alias = $self->{attrs}{alias};
1230   my $info = [];
1231
1232   my %collapse_pos;
1233
1234   my @const_keys;
1235
1236   foreach my $const (@const_rows) {
1237     scalar @const_keys or do {
1238       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1239     };
1240     foreach my $key (@const_keys) {
1241       if (length $key) {
1242         my $target = $info;
1243         my @parts = split(/\./, $key);
1244         my $cur = '';
1245         my $data = $const->{$key};
1246         foreach my $p (@parts) {
1247           $target = $target->[1]->{$p} ||= [];
1248           $cur .= ".${p}";
1249           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1250             # collapsing at this point and on final part
1251             my $pos = $collapse_pos{$cur};
1252             CK: foreach my $ck (@ckey) {
1253               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1254                 $collapse_pos{$cur} = $data;
1255                 delete @collapse_pos{ # clear all positioning for sub-entries
1256                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1257                 };
1258                 push(@$target, []);
1259                 last CK;
1260               }
1261             }
1262           }
1263           if (exists $collapse{$cur}) {
1264             $target = $target->[-1];
1265           }
1266         }
1267         $target->[0] = $data;
1268       } else {
1269         $info->[0] = $const->{$key};
1270       }
1271     }
1272   }
1273
1274   return $info;
1275 }
1276
1277 =head2 result_source
1278
1279 =over 4
1280
1281 =item Arguments: $result_source?
1282
1283 =item Return Value: $result_source
1284
1285 =back
1286
1287 An accessor for the primary ResultSource object from which this ResultSet
1288 is derived.
1289
1290 =head2 result_class
1291
1292 =over 4
1293
1294 =item Arguments: $result_class?
1295
1296 =item Return Value: $result_class
1297
1298 =back
1299
1300 An accessor for the class to use when creating row objects. Defaults to
1301 C<< result_source->result_class >> - which in most cases is the name of the
1302 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1303
1304 Note that changing the result_class will also remove any components
1305 that were originally loaded in the source class via
1306 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1307 in the original source class will not run.
1308
1309 =cut
1310
1311 sub result_class {
1312   my ($self, $result_class) = @_;
1313   if ($result_class) {
1314     unless (ref $result_class) { # don't fire this for an object
1315       $self->ensure_class_loaded($result_class);
1316     }
1317     $self->_result_class($result_class);
1318     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1319     # permit the user to set result class on one result set only; it only
1320     # chains if provided to search()
1321     #$self->{attrs}{result_class} = $result_class if ref $self;
1322   }
1323   $self->_result_class;
1324 }
1325
1326 =head2 count
1327
1328 =over 4
1329
1330 =item Arguments: $cond, \%attrs??
1331
1332 =item Return Value: $count
1333
1334 =back
1335
1336 Performs an SQL C<COUNT> with the same query as the resultset was built
1337 with to find the number of elements. Passing arguments is equivalent to
1338 C<< $rs->search ($cond, \%attrs)->count >>
1339
1340 =cut
1341
1342 sub count {
1343   my $self = shift;
1344   return $self->search(@_)->count if @_ and defined $_[0];
1345   return scalar @{ $self->get_cache } if $self->get_cache;
1346
1347   my $attrs = $self->_resolved_attrs_copy;
1348
1349   # this is a little optimization - it is faster to do the limit
1350   # adjustments in software, instead of a subquery
1351   my $rows = delete $attrs->{rows};
1352   my $offset = delete $attrs->{offset};
1353
1354   my $crs;
1355   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1356     $crs = $self->_count_subq_rs ($attrs);
1357   }
1358   else {
1359     $crs = $self->_count_rs ($attrs);
1360   }
1361   my $count = $crs->next;
1362
1363   $count -= $offset if $offset;
1364   $count = $rows if $rows and $rows < $count;
1365   $count = 0 if ($count < 0);
1366
1367   return $count;
1368 }
1369
1370 =head2 count_rs
1371
1372 =over 4
1373
1374 =item Arguments: $cond, \%attrs??
1375
1376 =item Return Value: $count_rs
1377
1378 =back
1379
1380 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1381 This can be very handy for subqueries:
1382
1383   ->search( { amount => $some_rs->count_rs->as_query } )
1384
1385 As with regular resultsets the SQL query will be executed only after
1386 the resultset is accessed via L</next> or L</all>. That would return
1387 the same single value obtainable via L</count>.
1388
1389 =cut
1390
1391 sub count_rs {
1392   my $self = shift;
1393   return $self->search(@_)->count_rs if @_;
1394
1395   # this may look like a lack of abstraction (count() does about the same)
1396   # but in fact an _rs *must* use a subquery for the limits, as the
1397   # software based limiting can not be ported if this $rs is to be used
1398   # in a subquery itself (i.e. ->as_query)
1399   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1400     return $self->_count_subq_rs;
1401   }
1402   else {
1403     return $self->_count_rs;
1404   }
1405 }
1406
1407 #
1408 # returns a ResultSetColumn object tied to the count query
1409 #
1410 sub _count_rs {
1411   my ($self, $attrs) = @_;
1412
1413   my $rsrc = $self->result_source;
1414   $attrs ||= $self->_resolved_attrs;
1415
1416   my $tmp_attrs = { %$attrs };
1417   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1418   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1419
1420   # overwrite the selector (supplied by the storage)
1421   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1422   $tmp_attrs->{as} = 'count';
1423   delete @{$tmp_attrs}{qw/columns _trailing_select/};
1424
1425   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1426
1427   return $tmp_rs;
1428 }
1429
1430 #
1431 # same as above but uses a subquery
1432 #
1433 sub _count_subq_rs {
1434   my ($self, $attrs) = @_;
1435
1436   my $rsrc = $self->result_source;
1437   $attrs ||= $self->_resolved_attrs;
1438
1439   my $sub_attrs = { %$attrs };
1440   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1441   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range _trailing_select order_by for/};
1442
1443   # if we multi-prefetch we group_by primary keys only as this is what we would
1444   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1445   if ( keys %{$attrs->{collapse}}  ) {
1446     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1447   }
1448
1449   # Calculate subquery selector
1450   if (my $g = $sub_attrs->{group_by}) {
1451
1452     my $sql_maker = $rsrc->storage->sql_maker;
1453
1454     # necessary as the group_by may refer to aliased functions
1455     my $sel_index;
1456     for my $sel (@{$attrs->{select}}) {
1457       $sel_index->{$sel->{-as}} = $sel
1458         if (ref $sel eq 'HASH' and $sel->{-as});
1459     }
1460
1461     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1462     # also look for named aggregates referred in the having clause
1463     # having often contains scalarrefs - thus parse it out entirely
1464     my @parts = @$g;
1465     if ($attrs->{having}) {
1466       local $sql_maker->{having_bind};
1467       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1468       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1469       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1470         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1471         # if we don't unset it we screw up retarded but unfortunately working
1472         # 'MAX(foo.bar)' => { '>', 3 }
1473         $sql_maker->{name_sep} = '';
1474       }
1475
1476       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1477
1478       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1479
1480       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1481       # and if all fails for an utterly naive quoted scalar-with-function
1482       while ($sql =~ /
1483         $rquote $sep $lquote (.+?) $rquote
1484           |
1485         [\s,] \w+ \. (\w+) [\s,]
1486           |
1487         [\s,] $lquote (.+?) $rquote [\s,]
1488       /gx) {
1489         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1490       }
1491     }
1492
1493     for (@parts) {
1494       my $colpiece = $sel_index->{$_} || $_;
1495
1496       # unqualify join-based group_by's. Arcane but possible query
1497       # also horrible horrible hack to alias a column (not a func.)
1498       # (probably need to introduce SQLA syntax)
1499       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1500         my $as = $colpiece;
1501         $as =~ s/\./__/;
1502         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1503       }
1504       push @{$sub_attrs->{select}}, $colpiece;
1505     }
1506   }
1507   else {
1508     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1509     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1510   }
1511
1512   return $rsrc->resultset_class
1513                ->new ($rsrc, $sub_attrs)
1514                 ->as_subselect_rs
1515                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1516                   ->get_column ('count');
1517 }
1518
1519 sub _bool {
1520   return 1;
1521 }
1522
1523 =head2 count_literal
1524
1525 =over 4
1526
1527 =item Arguments: $sql_fragment, @bind_values
1528
1529 =item Return Value: $count
1530
1531 =back
1532
1533 Counts the results in a literal query. Equivalent to calling L</search_literal>
1534 with the passed arguments, then L</count>.
1535
1536 =cut
1537
1538 sub count_literal { shift->search_literal(@_)->count; }
1539
1540 =head2 all
1541
1542 =over 4
1543
1544 =item Arguments: none
1545
1546 =item Return Value: @objects
1547
1548 =back
1549
1550 Returns all elements in the resultset. Called implicitly if the resultset
1551 is returned in list context.
1552
1553 =cut
1554
1555 sub all {
1556   my $self = shift;
1557   if(@_) {
1558       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1559   }
1560
1561   return @{ $self->get_cache } if $self->get_cache;
1562
1563   my @obj;
1564
1565   if (keys %{$self->_resolved_attrs->{collapse}}) {
1566     # Using $self->cursor->all is really just an optimisation.
1567     # If we're collapsing has_many prefetches it probably makes
1568     # very little difference, and this is cleaner than hacking
1569     # _construct_object to survive the approach
1570     $self->cursor->reset;
1571     my @row = $self->cursor->next;
1572     while (@row) {
1573       push(@obj, $self->_construct_object(@row));
1574       @row = (exists $self->{stashed_row}
1575                ? @{delete $self->{stashed_row}}
1576                : $self->cursor->next);
1577     }
1578   } else {
1579     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1580   }
1581
1582   $self->set_cache(\@obj) if $self->{attrs}{cache};
1583
1584   return @obj;
1585 }
1586
1587 =head2 reset
1588
1589 =over 4
1590
1591 =item Arguments: none
1592
1593 =item Return Value: $self
1594
1595 =back
1596
1597 Resets the resultset's cursor, so you can iterate through the elements again.
1598 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1599 another query.
1600
1601 =cut
1602
1603 sub reset {
1604   my ($self) = @_;
1605   delete $self->{_attrs} if exists $self->{_attrs};
1606   $self->{all_cache_position} = 0;
1607   $self->cursor->reset;
1608   return $self;
1609 }
1610
1611 =head2 first
1612
1613 =over 4
1614
1615 =item Arguments: none
1616
1617 =item Return Value: $object | undef
1618
1619 =back
1620
1621 Resets the resultset and returns an object for the first result (or C<undef>
1622 if the resultset is empty).
1623
1624 =cut
1625
1626 sub first {
1627   return $_[0]->reset->next;
1628 }
1629
1630
1631 # _rs_update_delete
1632 #
1633 # Determines whether and what type of subquery is required for the $rs operation.
1634 # If grouping is necessary either supplies its own, or verifies the current one
1635 # After all is done delegates to the proper storage method.
1636
1637 sub _rs_update_delete {
1638   my ($self, $op, $values) = @_;
1639
1640   my $rsrc = $self->result_source;
1641
1642   # if a condition exists we need to strip all table qualifiers
1643   # if this is not possible we'll force a subquery below
1644   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1645
1646   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1647   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1648
1649   if ($needs_group_by_subq or $needs_subq) {
1650
1651     # make a new $rs selecting only the PKs (that's all we really need)
1652     my $attrs = $self->_resolved_attrs_copy;
1653
1654
1655     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1656     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1657
1658     if ($needs_group_by_subq) {
1659       # make sure no group_by was supplied, or if there is one - make sure it matches
1660       # the columns compiled above perfectly. Anything else can not be sanely executed
1661       # on most databases so croak right then and there
1662
1663       if (my $g = $attrs->{group_by}) {
1664         my @current_group_by = map
1665           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1666           @$g
1667         ;
1668
1669         if (
1670           join ("\x00", sort @current_group_by)
1671             ne
1672           join ("\x00", sort @{$attrs->{columns}} )
1673         ) {
1674           $self->throw_exception (
1675             "You have just attempted a $op operation on a resultset which does group_by"
1676             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1677             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1678             . ' kind of queries. Please retry the operation with a modified group_by or'
1679             . ' without using one at all.'
1680           );
1681         }
1682       }
1683       else {
1684         $attrs->{group_by} = $attrs->{columns};
1685       }
1686     }
1687
1688     my $subrs = (ref $self)->new($rsrc, $attrs);
1689     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1690   }
1691   else {
1692     return $rsrc->storage->$op(
1693       $rsrc,
1694       $op eq 'update' ? $values : (),
1695       $cond,
1696     );
1697   }
1698 }
1699
1700 =head2 update
1701
1702 =over 4
1703
1704 =item Arguments: \%values
1705
1706 =item Return Value: $storage_rv
1707
1708 =back
1709
1710 Sets the specified columns in the resultset to the supplied values in a
1711 single query. Note that this will not run any accessor/set_column/update
1712 triggers, nor will it update any row object instances derived from this
1713 resultset (this includes the contents of the L<resultset cache|/set_cache>
1714 if any). See L</update_all> if you need to execute any on-update
1715 triggers or cascades defined either by you or a
1716 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1717
1718 The return value is a pass through of what the underlying
1719 storage backend returned, and may vary. See L<DBI/execute> for the most
1720 common case.
1721
1722 =head3 CAVEAT
1723
1724 Note that L</update> does not process/deflate any of the values passed in.
1725 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1726 ensure manually that any value passed to this method will stringify to
1727 something the RDBMS knows how to deal with. A notable example is the
1728 handling of L<DateTime> objects, for more info see:
1729 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
1730
1731 =cut
1732
1733 sub update {
1734   my ($self, $values) = @_;
1735   $self->throw_exception('Values for update must be a hash')
1736     unless ref $values eq 'HASH';
1737
1738   return $self->_rs_update_delete ('update', $values);
1739 }
1740
1741 =head2 update_all
1742
1743 =over 4
1744
1745 =item Arguments: \%values
1746
1747 =item Return Value: 1
1748
1749 =back
1750
1751 Fetches all objects and updates them one at a time via
1752 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1753 triggers, while L</update> will not.
1754
1755 =cut
1756
1757 sub update_all {
1758   my ($self, $values) = @_;
1759   $self->throw_exception('Values for update_all must be a hash')
1760     unless ref $values eq 'HASH';
1761
1762   my $guard = $self->result_source->schema->txn_scope_guard;
1763   $_->update($values) for $self->all;
1764   $guard->commit;
1765   return 1;
1766 }
1767
1768 =head2 delete
1769
1770 =over 4
1771
1772 =item Arguments: none
1773
1774 =item Return Value: $storage_rv
1775
1776 =back
1777
1778 Deletes the rows matching this resultset in a single query. Note that this
1779 will not run any delete triggers, nor will it alter the
1780 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1781 derived from this resultset (this includes the contents of the
1782 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1783 execute any on-delete triggers or cascades defined either by you or a
1784 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1785
1786 The return value is a pass through of what the underlying storage backend
1787 returned, and may vary. See L<DBI/execute> for the most common case.
1788
1789 =cut
1790
1791 sub delete {
1792   my $self = shift;
1793   $self->throw_exception('delete does not accept any arguments')
1794     if @_;
1795
1796   return $self->_rs_update_delete ('delete');
1797 }
1798
1799 =head2 delete_all
1800
1801 =over 4
1802
1803 =item Arguments: none
1804
1805 =item Return Value: 1
1806
1807 =back
1808
1809 Fetches all objects and deletes them one at a time via
1810 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1811 triggers, while L</delete> will not.
1812
1813 =cut
1814
1815 sub delete_all {
1816   my $self = shift;
1817   $self->throw_exception('delete_all does not accept any arguments')
1818     if @_;
1819
1820   my $guard = $self->result_source->schema->txn_scope_guard;
1821   $_->delete for $self->all;
1822   $guard->commit;
1823   return 1;
1824 }
1825
1826 =head2 populate
1827
1828 =over 4
1829
1830 =item Arguments: \@data;
1831
1832 =back
1833
1834 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1835 For the arrayref of hashrefs style each hashref should be a structure suitable
1836 forsubmitting to a $resultset->create(...) method.
1837
1838 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1839 to insert the data, as this is a faster method.
1840
1841 Otherwise, each set of data is inserted into the database using
1842 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1843 accumulated into an array. The array itself, or an array reference
1844 is returned depending on scalar or list context.
1845
1846 Example:  Assuming an Artist Class that has many CDs Classes relating:
1847
1848   my $Artist_rs = $schema->resultset("Artist");
1849
1850   ## Void Context Example
1851   $Artist_rs->populate([
1852      { artistid => 4, name => 'Manufactured Crap', cds => [
1853         { title => 'My First CD', year => 2006 },
1854         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1855       ],
1856      },
1857      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1858         { title => 'My parents sold me to a record company', year => 2005 },
1859         { title => 'Why Am I So Ugly?', year => 2006 },
1860         { title => 'I Got Surgery and am now Popular', year => 2007 }
1861       ],
1862      },
1863   ]);
1864
1865   ## Array Context Example
1866   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1867     { name => "Artist One"},
1868     { name => "Artist Two"},
1869     { name => "Artist Three", cds=> [
1870     { title => "First CD", year => 2007},
1871     { title => "Second CD", year => 2008},
1872   ]}
1873   ]);
1874
1875   print $ArtistOne->name; ## response is 'Artist One'
1876   print $ArtistThree->cds->count ## reponse is '2'
1877
1878 For the arrayref of arrayrefs style,  the first element should be a list of the
1879 fieldsnames to which the remaining elements are rows being inserted.  For
1880 example:
1881
1882   $Arstist_rs->populate([
1883     [qw/artistid name/],
1884     [100, 'A Formally Unknown Singer'],
1885     [101, 'A singer that jumped the shark two albums ago'],
1886     [102, 'An actually cool singer'],
1887   ]);
1888
1889 Please note an important effect on your data when choosing between void and
1890 wantarray context. Since void context goes straight to C<insert_bulk> in
1891 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1892 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1893 create primary keys for you, you will find that your PKs are empty.  In this
1894 case you will have to use the wantarray context in order to create those
1895 values.
1896
1897 =cut
1898
1899 sub populate {
1900   my $self = shift;
1901
1902   # cruft placed in standalone method
1903   my $data = $self->_normalize_populate_args(@_);
1904
1905   if(defined wantarray) {
1906     my @created;
1907     foreach my $item (@$data) {
1908       push(@created, $self->create($item));
1909     }
1910     return wantarray ? @created : \@created;
1911   }
1912   else {
1913     my $first = $data->[0];
1914
1915     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1916     # it relationship data
1917     my (@rels, @columns);
1918     my $rsrc = $self->result_source;
1919     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
1920     for (keys %$first) {
1921       my $ref = ref $first->{$_};
1922       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
1923         ? push @rels, $_
1924         : push @columns, $_
1925       ;
1926     }
1927
1928     my @pks = $rsrc->primary_columns;
1929
1930     ## do the belongs_to relationships
1931     foreach my $index (0..$#$data) {
1932
1933       # delegate to create() for any dataset without primary keys with specified relationships
1934       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1935         for my $r (@rels) {
1936           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1937             my @ret = $self->populate($data);
1938             return;
1939           }
1940         }
1941       }
1942
1943       foreach my $rel (@rels) {
1944         next unless ref $data->[$index]->{$rel} eq "HASH";
1945         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1946         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
1947         my $related = $result->result_source->_resolve_condition(
1948           $reverse_relinfo->{cond},
1949           $self,
1950           $result,
1951         );
1952
1953         delete $data->[$index]->{$rel};
1954         $data->[$index] = {%{$data->[$index]}, %$related};
1955
1956         push @columns, keys %$related if $index == 0;
1957       }
1958     }
1959
1960     ## inherit the data locked in the conditions of the resultset
1961     my ($rs_data) = $self->_merge_with_rscond({});
1962     delete @{$rs_data}{@columns};
1963     my @inherit_cols = keys %$rs_data;
1964     my @inherit_data = values %$rs_data;
1965
1966     ## do bulk insert on current row
1967     $rsrc->storage->insert_bulk(
1968       $rsrc,
1969       [@columns, @inherit_cols],
1970       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1971     );
1972
1973     ## do the has_many relationships
1974     foreach my $item (@$data) {
1975
1976       my $main_row;
1977
1978       foreach my $rel (@rels) {
1979         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
1980
1981         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
1982
1983         my $child = $main_row->$rel;
1984
1985         my $related = $child->result_source->_resolve_condition(
1986           $rels->{$rel}{cond},
1987           $child,
1988           $main_row,
1989         );
1990
1991         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1992         my @populate = map { {%$_, %$related} } @rows_to_add;
1993
1994         $child->populate( \@populate );
1995       }
1996     }
1997   }
1998 }
1999
2000
2001 # populate() argumnets went over several incarnations
2002 # What we ultimately support is AoH
2003 sub _normalize_populate_args {
2004   my ($self, $arg) = @_;
2005
2006   if (ref $arg eq 'ARRAY') {
2007     if (ref $arg->[0] eq 'HASH') {
2008       return $arg;
2009     }
2010     elsif (ref $arg->[0] eq 'ARRAY') {
2011       my @ret;
2012       my @colnames = @{$arg->[0]};
2013       foreach my $values (@{$arg}[1 .. $#$arg]) {
2014         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2015       }
2016       return \@ret;
2017     }
2018   }
2019
2020   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2021 }
2022
2023 =head2 pager
2024
2025 =over 4
2026
2027 =item Arguments: none
2028
2029 =item Return Value: $pager
2030
2031 =back
2032
2033 Return Value a L<Data::Page> object for the current resultset. Only makes
2034 sense for queries with a C<page> attribute.
2035
2036 To get the full count of entries for a paged resultset, call
2037 C<total_entries> on the L<Data::Page> object.
2038
2039 =cut
2040
2041 # make a wizard good for both a scalar and a hashref
2042 my $mk_lazy_count_wizard = sub {
2043   require Variable::Magic;
2044
2045   my $stash = { total_rs => shift };
2046   my $slot = shift; # only used by the hashref magic
2047
2048   my $magic = Variable::Magic::wizard (
2049     data => sub { $stash },
2050
2051     (!$slot)
2052     ? (
2053       # the scalar magic
2054       get => sub {
2055         # set value lazily, and dispell for good
2056         ${$_[0]} = $_[1]{total_rs}->count;
2057         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref});
2058         return 1;
2059       },
2060       set => sub {
2061         # an explicit set implies dispell as well
2062         # the unless() is to work around "fun and giggles" below
2063         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref})
2064           unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2065         return 1;
2066       },
2067     )
2068     : (
2069       # the uvar magic
2070       fetch => sub {
2071         if ($_[2] eq $slot and !$_[1]{inactive}) {
2072           my $cnt = $_[1]{total_rs}->count;
2073           $_[0]->{$slot} = $cnt;
2074
2075           # attempting to dispell in a fetch handle (works in store), seems
2076           # to invariable segfault on 5.10, 5.12, 5.13 :(
2077           # so use an inactivator instead
2078           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2079           $_[1]{inactive}++;
2080         }
2081         return 1;
2082       },
2083       store => sub {
2084         if (! $_[1]{inactive} and $_[2] eq $slot) {
2085           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2086           $_[1]{inactive}++
2087             unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2088         }
2089         return 1;
2090       },
2091     ),
2092   );
2093
2094   $stash->{magic_selfref} = $magic;
2095   weaken ($stash->{magic_selfref}); # this fails on 5.8.1
2096
2097   return $magic;
2098 };
2099
2100 # the tie class for 5.8.1
2101 {
2102   package # hide from pause
2103     DBIx::Class::__DBIC_LAZY_RS_COUNT__;
2104   use base qw/Tie::Hash/;
2105
2106   sub FIRSTKEY { my $dummy = scalar keys %{$_[0]{data}}; each %{$_[0]{data}} }
2107   sub NEXTKEY  { each %{$_[0]{data}} }
2108   sub EXISTS   { exists $_[0]{data}{$_[1]} }
2109   sub DELETE   { delete $_[0]{data}{$_[1]} }
2110   sub CLEAR    { %{$_[0]{data}} = () }
2111   sub SCALAR   { scalar %{$_[0]{data}} }
2112
2113   sub TIEHASH {
2114     $_[1]{data} = {%{$_[1]{selfref}}};
2115     %{$_[1]{selfref}} = ();
2116     Scalar::Util::weaken ($_[1]{selfref});
2117     return bless ($_[1], $_[0]);
2118   };
2119
2120   sub FETCH {
2121     if ($_[1] eq $_[0]{slot}) {
2122       my $cnt = $_[0]{data}{$_[1]} = $_[0]{total_rs}->count;
2123       untie %{$_[0]{selfref}};
2124       %{$_[0]{selfref}} = %{$_[0]{data}};
2125       return $cnt;
2126     }
2127     else {
2128       $_[0]{data}{$_[1]};
2129     }
2130   }
2131
2132   sub STORE {
2133     $_[0]{data}{$_[1]} = $_[2];
2134     if ($_[1] eq $_[0]{slot}) {
2135       untie %{$_[0]{selfref}};
2136       %{$_[0]{selfref}} = %{$_[0]{data}};
2137     }
2138     $_[2];
2139   }
2140 }
2141
2142 sub pager {
2143   my ($self) = @_;
2144
2145   return $self->{pager} if $self->{pager};
2146
2147   if ($self->get_cache) {
2148     $self->throw_exception ('Pagers on cached resultsets are not supported');
2149   }
2150
2151   my $attrs = $self->{attrs};
2152   if (!defined $attrs->{page}) {
2153     $self->throw_exception("Can't create pager for non-paged rs");
2154   }
2155   elsif ($attrs->{page} <= 0) {
2156     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2157   }
2158   $attrs->{rows} ||= 10;
2159
2160   # throw away the paging flags and re-run the count (possibly
2161   # with a subselect) to get the real total count
2162   my $count_attrs = { %$attrs };
2163   delete $count_attrs->{$_} for qw/rows offset page pager/;
2164   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2165
2166
2167 ### the following may seem awkward and dirty, but it's a thought-experiment
2168 ### necessary for future development of DBIx::DS. Do *NOT* change this code
2169 ### before talking to ribasushi/mst
2170
2171   my $pager = Data::Page->new(
2172     0,  #start with an empty set
2173     $attrs->{rows},
2174     $self->{attrs}{page},
2175   );
2176
2177   my $data_slot = 'total_entries';
2178
2179   # Since we are interested in a cached value (once it's set - it's set), every
2180   # technique will detach from the magic-host once the time comes to fire the
2181   # ->count (or in the segfaulting case of >= 5.10 it will deactivate itself)
2182
2183   if ($] < 5.008003) {
2184     # 5.8.1 throws 'Modification of a read-only value attempted' when one tries
2185     # to weakref the magic container :(
2186     # tested on 5.8.1
2187     tie (%$pager, 'DBIx::Class::__DBIC_LAZY_RS_COUNT__',
2188       { slot => $data_slot, total_rs => $total_rs, selfref => $pager }
2189     );
2190   }
2191   elsif ($] < 5.010) {
2192     # We can use magic on the hash value slot. It's interesting that the magic is
2193     # attached to the hash-slot, and does *not* stop working once I do the dummy
2194     # assignments after the cast()
2195     # tested on 5.8.3 and 5.8.9
2196     my $magic = $mk_lazy_count_wizard->($total_rs);
2197     Variable::Magic::cast ( $pager->{$data_slot}, $magic );
2198
2199     # this is for fun and giggles
2200     $pager->{$data_slot} = -1;
2201     $pager->{$data_slot} = 0;
2202
2203     # this does not work for scalars, but works with
2204     # uvar magic below
2205     #my %vals = %$pager;
2206     #%$pager = ();
2207     #%{$pager} = %vals;
2208   }
2209   else {
2210     # And the uvar magic
2211     # works on 5.10.1, 5.12.1 and 5.13.4 in its current form,
2212     # however see the wizard maker for more notes
2213     my $magic = $mk_lazy_count_wizard->($total_rs, $data_slot);
2214     Variable::Magic::cast ( %$pager, $magic );
2215
2216     # still works
2217     $pager->{$data_slot} = -1;
2218     $pager->{$data_slot} = 0;
2219
2220     # this now works
2221     my %vals = %$pager;
2222     %$pager = ();
2223     %{$pager} = %vals;
2224   }
2225
2226   return $self->{pager} = $pager;
2227 }
2228
2229 =head2 page
2230
2231 =over 4
2232
2233 =item Arguments: $page_number
2234
2235 =item Return Value: $rs
2236
2237 =back
2238
2239 Returns a resultset for the $page_number page of the resultset on which page
2240 is called, where each page contains a number of rows equal to the 'rows'
2241 attribute set on the resultset (10 by default).
2242
2243 =cut
2244
2245 sub page {
2246   my ($self, $page) = @_;
2247   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2248 }
2249
2250 =head2 new_result
2251
2252 =over 4
2253
2254 =item Arguments: \%vals
2255
2256 =item Return Value: $rowobject
2257
2258 =back
2259
2260 Creates a new row object in the resultset's result class and returns
2261 it. The row is not inserted into the database at this point, call
2262 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2263 will tell you whether the row object has been inserted or not.
2264
2265 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2266
2267 =cut
2268
2269 sub new_result {
2270   my ($self, $values) = @_;
2271   $self->throw_exception( "new_result needs a hash" )
2272     unless (ref $values eq 'HASH');
2273
2274   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2275
2276   my %new = (
2277     %$merged_cond,
2278     @$cols_from_relations
2279       ? (-cols_from_relations => $cols_from_relations)
2280       : (),
2281     -source_handle => $self->_source_handle,
2282     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2283   );
2284
2285   return $self->result_class->new(\%new);
2286 }
2287
2288 # _merge_with_rscond
2289 #
2290 # Takes a simple hash of K/V data and returns its copy merged with the
2291 # condition already present on the resultset. Additionally returns an
2292 # arrayref of value/condition names, which were inferred from related
2293 # objects (this is needed for in-memory related objects)
2294 sub _merge_with_rscond {
2295   my ($self, $data) = @_;
2296
2297   my (%new_data, @cols_from_relations);
2298
2299   my $alias = $self->{attrs}{alias};
2300
2301   if (! defined $self->{cond}) {
2302     # just massage $data below
2303   }
2304   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2305     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2306     @cols_from_relations = keys %new_data;
2307   }
2308   elsif (ref $self->{cond} ne 'HASH') {
2309     $self->throw_exception(
2310       "Can't abstract implicit construct, resultset condition not a hash"
2311     );
2312   }
2313   else {
2314     # precendence must be given to passed values over values inherited from
2315     # the cond, so the order here is important.
2316     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2317     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2318
2319     while ( my($col, $value) = each %implied ) {
2320       my $vref = ref $value;
2321       if ($vref eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
2322         $new_data{$col} = $value->{'='};
2323       }
2324       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2325         $new_data{$col} = $value;
2326       }
2327     }
2328   }
2329
2330   %new_data = (
2331     %new_data,
2332     %{ $self->_remove_alias($data, $alias) },
2333   );
2334
2335   return (\%new_data, \@cols_from_relations);
2336 }
2337
2338 # _has_resolved_attr
2339 #
2340 # determines if the resultset defines at least one
2341 # of the attributes supplied
2342 #
2343 # used to determine if a subquery is neccessary
2344 #
2345 # supports some virtual attributes:
2346 #   -join
2347 #     This will scan for any joins being present on the resultset.
2348 #     It is not a mere key-search but a deep inspection of {from}
2349 #
2350
2351 sub _has_resolved_attr {
2352   my ($self, @attr_names) = @_;
2353
2354   my $attrs = $self->_resolved_attrs;
2355
2356   my %extra_checks;
2357
2358   for my $n (@attr_names) {
2359     if (grep { $n eq $_ } (qw/-join/) ) {
2360       $extra_checks{$n}++;
2361       next;
2362     }
2363
2364     my $attr =  $attrs->{$n};
2365
2366     next if not defined $attr;
2367
2368     if (ref $attr eq 'HASH') {
2369       return 1 if keys %$attr;
2370     }
2371     elsif (ref $attr eq 'ARRAY') {
2372       return 1 if @$attr;
2373     }
2374     else {
2375       return 1 if $attr;
2376     }
2377   }
2378
2379   # a resolved join is expressed as a multi-level from
2380   return 1 if (
2381     $extra_checks{-join}
2382       and
2383     ref $attrs->{from} eq 'ARRAY'
2384       and
2385     @{$attrs->{from}} > 1
2386   );
2387
2388   return 0;
2389 }
2390
2391 # _collapse_cond
2392 #
2393 # Recursively collapse the condition.
2394
2395 sub _collapse_cond {
2396   my ($self, $cond, $collapsed) = @_;
2397
2398   $collapsed ||= {};
2399
2400   if (ref $cond eq 'ARRAY') {
2401     foreach my $subcond (@$cond) {
2402       next unless ref $subcond;  # -or
2403       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2404     }
2405   }
2406   elsif (ref $cond eq 'HASH') {
2407     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2408       foreach my $subcond (@{$cond->{-and}}) {
2409         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2410       }
2411     }
2412     else {
2413       foreach my $col (keys %$cond) {
2414         my $value = $cond->{$col};
2415         $collapsed->{$col} = $value;
2416       }
2417     }
2418   }
2419
2420   return $collapsed;
2421 }
2422
2423 # _remove_alias
2424 #
2425 # Remove the specified alias from the specified query hash. A copy is made so
2426 # the original query is not modified.
2427
2428 sub _remove_alias {
2429   my ($self, $query, $alias) = @_;
2430
2431   my %orig = %{ $query || {} };
2432   my %unaliased;
2433
2434   foreach my $key (keys %orig) {
2435     if ($key !~ /\./) {
2436       $unaliased{$key} = $orig{$key};
2437       next;
2438     }
2439     $unaliased{$1} = $orig{$key}
2440       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2441   }
2442
2443   return \%unaliased;
2444 }
2445
2446 =head2 as_query
2447
2448 =over 4
2449
2450 =item Arguments: none
2451
2452 =item Return Value: \[ $sql, @bind ]
2453
2454 =back
2455
2456 Returns the SQL query and bind vars associated with the invocant.
2457
2458 This is generally used as the RHS for a subquery.
2459
2460 =cut
2461
2462 sub as_query {
2463   my $self = shift;
2464
2465   my $attrs = $self->_resolved_attrs_copy;
2466
2467   # For future use:
2468   #
2469   # in list ctx:
2470   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2471   # $sql also has no wrapping parenthesis in list ctx
2472   #
2473   my $sqlbind = $self->result_source->storage
2474     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2475
2476   return $sqlbind;
2477 }
2478
2479 =head2 find_or_new
2480
2481 =over 4
2482
2483 =item Arguments: \%vals, \%attrs?
2484
2485 =item Return Value: $rowobject
2486
2487 =back
2488
2489   my $artist = $schema->resultset('Artist')->find_or_new(
2490     { artist => 'fred' }, { key => 'artists' });
2491
2492   $cd->cd_to_producer->find_or_new({ producer => $producer },
2493                                    { key => 'primary });
2494
2495 Find an existing record from this resultset using L</find>. if none exists,
2496 instantiate a new result object and return it. The object will not be saved
2497 into your storage until you call L<DBIx::Class::Row/insert> on it.
2498
2499 You most likely want this method when looking for existing rows using a unique
2500 constraint that is not the primary key, or looking for related rows.
2501
2502 If you want objects to be saved immediately, use L</find_or_create> instead.
2503
2504 B<Note>: Make sure to read the documentation of L</find> and understand the
2505 significance of the C<key> attribute, as its lack may skew your search, and
2506 subsequently result in spurious new objects.
2507
2508 B<Note>: Take care when using C<find_or_new> with a table having
2509 columns with default values that you intend to be automatically
2510 supplied by the database (e.g. an auto_increment primary key column).
2511 In normal usage, the value of such columns should NOT be included at
2512 all in the call to C<find_or_new>, even when set to C<undef>.
2513
2514 =cut
2515
2516 sub find_or_new {
2517   my $self     = shift;
2518   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2519   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2520   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2521     return $row;
2522   }
2523   return $self->new_result($hash);
2524 }
2525
2526 =head2 create
2527
2528 =over 4
2529
2530 =item Arguments: \%vals
2531
2532 =item Return Value: a L<DBIx::Class::Row> $object
2533
2534 =back
2535
2536 Attempt to create a single new row or a row with multiple related rows
2537 in the table represented by the resultset (and related tables). This
2538 will not check for duplicate rows before inserting, use
2539 L</find_or_create> to do that.
2540
2541 To create one row for this resultset, pass a hashref of key/value
2542 pairs representing the columns of the table and the values you wish to
2543 store. If the appropriate relationships are set up, foreign key fields
2544 can also be passed an object representing the foreign row, and the
2545 value will be set to its primary key.
2546
2547 To create related objects, pass a hashref of related-object column values
2548 B<keyed on the relationship name>. If the relationship is of type C<multi>
2549 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2550 The process will correctly identify columns holding foreign keys, and will
2551 transparently populate them from the keys of the corresponding relation.
2552 This can be applied recursively, and will work correctly for a structure
2553 with an arbitrary depth and width, as long as the relationships actually
2554 exists and the correct column data has been supplied.
2555
2556
2557 Instead of hashrefs of plain related data (key/value pairs), you may
2558 also pass new or inserted objects. New objects (not inserted yet, see
2559 L</new>), will be inserted into their appropriate tables.
2560
2561 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2562
2563 Example of creating a new row.
2564
2565   $person_rs->create({
2566     name=>"Some Person",
2567     email=>"somebody@someplace.com"
2568   });
2569
2570 Example of creating a new row and also creating rows in a related C<has_many>
2571 or C<has_one> resultset.  Note Arrayref.
2572
2573   $artist_rs->create(
2574      { artistid => 4, name => 'Manufactured Crap', cds => [
2575         { title => 'My First CD', year => 2006 },
2576         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2577       ],
2578      },
2579   );
2580
2581 Example of creating a new row and also creating a row in a related
2582 C<belongs_to> resultset. Note Hashref.
2583
2584   $cd_rs->create({
2585     title=>"Music for Silly Walks",
2586     year=>2000,
2587     artist => {
2588       name=>"Silly Musician",
2589     }
2590   });
2591
2592 =over
2593
2594 =item WARNING
2595
2596 When subclassing ResultSet never attempt to override this method. Since
2597 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2598 lot of the internals simply never call it, so your override will be
2599 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2600 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2601 L</create> process you need to intervene.
2602
2603 =back
2604
2605 =cut
2606
2607 sub create {
2608   my ($self, $attrs) = @_;
2609   $self->throw_exception( "create needs a hashref" )
2610     unless ref $attrs eq 'HASH';
2611   return $self->new_result($attrs)->insert;
2612 }
2613
2614 =head2 find_or_create
2615
2616 =over 4
2617
2618 =item Arguments: \%vals, \%attrs?
2619
2620 =item Return Value: $rowobject
2621
2622 =back
2623
2624   $cd->cd_to_producer->find_or_create({ producer => $producer },
2625                                       { key => 'primary' });
2626
2627 Tries to find a record based on its primary key or unique constraints; if none
2628 is found, creates one and returns that instead.
2629
2630   my $cd = $schema->resultset('CD')->find_or_create({
2631     cdid   => 5,
2632     artist => 'Massive Attack',
2633     title  => 'Mezzanine',
2634     year   => 2005,
2635   });
2636
2637 Also takes an optional C<key> attribute, to search by a specific key or unique
2638 constraint. For example:
2639
2640   my $cd = $schema->resultset('CD')->find_or_create(
2641     {
2642       artist => 'Massive Attack',
2643       title  => 'Mezzanine',
2644     },
2645     { key => 'cd_artist_title' }
2646   );
2647
2648 B<Note>: Make sure to read the documentation of L</find> and understand the
2649 significance of the C<key> attribute, as its lack may skew your search, and
2650 subsequently result in spurious row creation.
2651
2652 B<Note>: Because find_or_create() reads from the database and then
2653 possibly inserts based on the result, this method is subject to a race
2654 condition. Another process could create a record in the table after
2655 the find has completed and before the create has started. To avoid
2656 this problem, use find_or_create() inside a transaction.
2657
2658 B<Note>: Take care when using C<find_or_create> with a table having
2659 columns with default values that you intend to be automatically
2660 supplied by the database (e.g. an auto_increment primary key column).
2661 In normal usage, the value of such columns should NOT be included at
2662 all in the call to C<find_or_create>, even when set to C<undef>.
2663
2664 See also L</find> and L</update_or_create>. For information on how to declare
2665 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2666
2667 =cut
2668
2669 sub find_or_create {
2670   my $self     = shift;
2671   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2672   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2673   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2674     return $row;
2675   }
2676   return $self->create($hash);
2677 }
2678
2679 =head2 update_or_create
2680
2681 =over 4
2682
2683 =item Arguments: \%col_values, { key => $unique_constraint }?
2684
2685 =item Return Value: $row_object
2686
2687 =back
2688
2689   $resultset->update_or_create({ col => $val, ... });
2690
2691 Like L</find_or_create>, but if a row is found it is immediately updated via
2692 C<< $found_row->update (\%col_values) >>.
2693
2694
2695 Takes an optional C<key> attribute to search on a specific unique constraint.
2696 For example:
2697
2698   # In your application
2699   my $cd = $schema->resultset('CD')->update_or_create(
2700     {
2701       artist => 'Massive Attack',
2702       title  => 'Mezzanine',
2703       year   => 1998,
2704     },
2705     { key => 'cd_artist_title' }
2706   );
2707
2708   $cd->cd_to_producer->update_or_create({
2709     producer => $producer,
2710     name => 'harry',
2711   }, {
2712     key => 'primary',
2713   });
2714
2715 B<Note>: Make sure to read the documentation of L</find> and understand the
2716 significance of the C<key> attribute, as its lack may skew your search, and
2717 subsequently result in spurious row creation.
2718
2719 B<Note>: Take care when using C<update_or_create> with a table having
2720 columns with default values that you intend to be automatically
2721 supplied by the database (e.g. an auto_increment primary key column).
2722 In normal usage, the value of such columns should NOT be included at
2723 all in the call to C<update_or_create>, even when set to C<undef>.
2724
2725 See also L</find> and L</find_or_create>. For information on how to declare
2726 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2727
2728 =cut
2729
2730 sub update_or_create {
2731   my $self = shift;
2732   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2733   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2734
2735   my $row = $self->find($cond, $attrs);
2736   if (defined $row) {
2737     $row->update($cond);
2738     return $row;
2739   }
2740
2741   return $self->create($cond);
2742 }
2743
2744 =head2 update_or_new
2745
2746 =over 4
2747
2748 =item Arguments: \%col_values, { key => $unique_constraint }?
2749
2750 =item Return Value: $rowobject
2751
2752 =back
2753
2754   $resultset->update_or_new({ col => $val, ... });
2755
2756 Like L</find_or_new> but if a row is found it is immediately updated via
2757 C<< $found_row->update (\%col_values) >>.
2758
2759 For example:
2760
2761   # In your application
2762   my $cd = $schema->resultset('CD')->update_or_new(
2763     {
2764       artist => 'Massive Attack',
2765       title  => 'Mezzanine',
2766       year   => 1998,
2767     },
2768     { key => 'cd_artist_title' }
2769   );
2770
2771   if ($cd->in_storage) {
2772       # the cd was updated
2773   }
2774   else {
2775       # the cd is not yet in the database, let's insert it
2776       $cd->insert;
2777   }
2778
2779 B<Note>: Make sure to read the documentation of L</find> and understand the
2780 significance of the C<key> attribute, as its lack may skew your search, and
2781 subsequently result in spurious new objects.
2782
2783 B<Note>: Take care when using C<update_or_new> with a table having
2784 columns with default values that you intend to be automatically
2785 supplied by the database (e.g. an auto_increment primary key column).
2786 In normal usage, the value of such columns should NOT be included at
2787 all in the call to C<update_or_new>, even when set to C<undef>.
2788
2789 See also L</find>, L</find_or_create> and L</find_or_new>.
2790
2791 =cut
2792
2793 sub update_or_new {
2794     my $self  = shift;
2795     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2796     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2797
2798     my $row = $self->find( $cond, $attrs );
2799     if ( defined $row ) {
2800         $row->update($cond);
2801         return $row;
2802     }
2803
2804     return $self->new_result($cond);
2805 }
2806
2807 =head2 get_cache
2808
2809 =over 4
2810
2811 =item Arguments: none
2812
2813 =item Return Value: \@cache_objects | undef
2814
2815 =back
2816
2817 Gets the contents of the cache for the resultset, if the cache is set.
2818
2819 The cache is populated either by using the L</prefetch> attribute to
2820 L</search> or by calling L</set_cache>.
2821
2822 =cut
2823
2824 sub get_cache {
2825   shift->{all_cache};
2826 }
2827
2828 =head2 set_cache
2829
2830 =over 4
2831
2832 =item Arguments: \@cache_objects
2833
2834 =item Return Value: \@cache_objects
2835
2836 =back
2837
2838 Sets the contents of the cache for the resultset. Expects an arrayref
2839 of objects of the same class as those produced by the resultset. Note that
2840 if the cache is set the resultset will return the cached objects rather
2841 than re-querying the database even if the cache attr is not set.
2842
2843 The contents of the cache can also be populated by using the
2844 L</prefetch> attribute to L</search>.
2845
2846 =cut
2847
2848 sub set_cache {
2849   my ( $self, $data ) = @_;
2850   $self->throw_exception("set_cache requires an arrayref")
2851       if defined($data) && (ref $data ne 'ARRAY');
2852   $self->{all_cache} = $data;
2853 }
2854
2855 =head2 clear_cache
2856
2857 =over 4
2858
2859 =item Arguments: none
2860
2861 =item Return Value: undef
2862
2863 =back
2864
2865 Clears the cache for the resultset.
2866
2867 =cut
2868
2869 sub clear_cache {
2870   shift->set_cache(undef);
2871 }
2872
2873 =head2 is_paged
2874
2875 =over 4
2876
2877 =item Arguments: none
2878
2879 =item Return Value: true, if the resultset has been paginated
2880
2881 =back
2882
2883 =cut
2884
2885 sub is_paged {
2886   my ($self) = @_;
2887   return !!$self->{attrs}{page};
2888 }
2889
2890 =head2 is_ordered
2891
2892 =over 4
2893
2894 =item Arguments: none
2895
2896 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2897
2898 =back
2899
2900 =cut
2901
2902 sub is_ordered {
2903   my ($self) = @_;
2904   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2905 }
2906
2907 =head2 related_resultset
2908
2909 =over 4
2910
2911 =item Arguments: $relationship_name
2912
2913 =item Return Value: $resultset
2914
2915 =back
2916
2917 Returns a related resultset for the supplied relationship name.
2918
2919   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2920
2921 =cut
2922
2923 sub related_resultset {
2924   my ($self, $rel) = @_;
2925
2926   $self->{related_resultsets} ||= {};
2927   return $self->{related_resultsets}{$rel} ||= do {
2928     my $rsrc = $self->result_source;
2929     my $rel_info = $rsrc->relationship_info($rel);
2930
2931     $self->throw_exception(
2932       "search_related: result source '" . $rsrc->source_name .
2933         "' has no such relationship $rel")
2934       unless $rel_info;
2935
2936     my $attrs = $self->_chain_relationship($rel);
2937
2938     my $join_count = $attrs->{seen_join}{$rel};
2939
2940     my $alias = $self->result_source->storage
2941         ->relname_to_table_alias($rel, $join_count);
2942
2943     # since this is search_related, and we already slid the select window inwards
2944     # (the select/as attrs were deleted in the beginning), we need to flip all
2945     # left joins to inner, so we get the expected results
2946     # read the comment on top of the actual function to see what this does
2947     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2948
2949
2950     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2951     delete @{$attrs}{qw(result_class alias)};
2952
2953     my $new_cache;
2954
2955     if (my $cache = $self->get_cache) {
2956       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2957         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2958                         @$cache ];
2959       }
2960     }
2961
2962     my $rel_source = $rsrc->related_source($rel);
2963
2964     my $new = do {
2965
2966       # The reason we do this now instead of passing the alias to the
2967       # search_rs below is that if you wrap/overload resultset on the
2968       # source you need to know what alias it's -going- to have for things
2969       # to work sanely (e.g. RestrictWithObject wants to be able to add
2970       # extra query restrictions, and these may need to be $alias.)
2971
2972       my $rel_attrs = $rel_source->resultset_attributes;
2973       local $rel_attrs->{alias} = $alias;
2974
2975       $rel_source->resultset
2976                  ->search_rs(
2977                      undef, {
2978                        %$attrs,
2979                        where => $attrs->{where},
2980                    });
2981     };
2982     $new->set_cache($new_cache) if $new_cache;
2983     $new;
2984   };
2985 }
2986
2987 =head2 current_source_alias
2988
2989 =over 4
2990
2991 =item Arguments: none
2992
2993 =item Return Value: $source_alias
2994
2995 =back
2996
2997 Returns the current table alias for the result source this resultset is built
2998 on, that will be used in the SQL query. Usually it is C<me>.
2999
3000 Currently the source alias that refers to the result set returned by a
3001 L</search>/L</find> family method depends on how you got to the resultset: it's
3002 C<me> by default, but eg. L</search_related> aliases it to the related result
3003 source name (and keeps C<me> referring to the original result set). The long
3004 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3005 (and make this method unnecessary).
3006
3007 Thus it's currently necessary to use this method in predefined queries (see
3008 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3009 source alias of the current result set:
3010
3011   # in a result set class
3012   sub modified_by {
3013     my ($self, $user) = @_;
3014
3015     my $me = $self->current_source_alias;
3016
3017     return $self->search(
3018       "$me.modified" => $user->id,
3019     );
3020   }
3021
3022 =cut
3023
3024 sub current_source_alias {
3025   my ($self) = @_;
3026
3027   return ($self->{attrs} || {})->{alias} || 'me';
3028 }
3029
3030 =head2 as_subselect_rs
3031
3032 =over 4
3033
3034 =item Arguments: none
3035
3036 =item Return Value: $resultset
3037
3038 =back
3039
3040 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3041 "virtual view" by including it as a subquery within the from clause.  From this
3042 point on, any joined tables are inaccessible to ->search on the resultset (as if
3043 it were simply where-filtered without joins).  For example:
3044
3045  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3046
3047  # 'x' now pollutes the query namespace
3048
3049  # So the following works as expected
3050  my $ok_rs = $rs->search({'x.other' => 1});
3051
3052  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3053  # def) we look for one row with contradictory terms and join in another table
3054  # (aliased 'x_2') which we never use
3055  my $broken_rs = $rs->search({'x.name' => 'def'});
3056
3057  my $rs2 = $rs->as_subselect_rs;
3058
3059  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3060  my $not_joined_rs = $rs2->search({'x.other' => 1});
3061
3062  # works as expected: finds a 'table' row related to two x rows (abc and def)
3063  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3064
3065 Another example of when one might use this would be to select a subset of
3066 columns in a group by clause:
3067
3068  my $rs = $schema->resultset('Bar')->search(undef, {
3069    group_by => [qw{ id foo_id baz_id }],
3070  })->as_subselect_rs->search(undef, {
3071    columns => [qw{ id foo_id }]
3072  });
3073
3074 In the above example normally columns would have to be equal to the group by,
3075 but because we isolated the group by into a subselect the above works.
3076
3077 =cut
3078
3079 sub as_subselect_rs {
3080   my $self = shift;
3081
3082   my $attrs = $self->_resolved_attrs;
3083
3084   my $fresh_rs = (ref $self)->new (
3085     $self->result_source
3086   );
3087
3088   # these pieces will be locked in the subquery
3089   delete $fresh_rs->{cond};
3090   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3091
3092   return $fresh_rs->search( {}, {
3093     from => [{
3094       $attrs->{alias} => $self->as_query,
3095       -alias         => $attrs->{alias},
3096       -source_handle => $self->result_source->handle,
3097     }],
3098     alias => $attrs->{alias},
3099   });
3100 }
3101
3102 # This code is called by search_related, and makes sure there
3103 # is clear separation between the joins before, during, and
3104 # after the relationship. This information is needed later
3105 # in order to properly resolve prefetch aliases (any alias
3106 # with a relation_chain_depth less than the depth of the
3107 # current prefetch is not considered)
3108 #
3109 # The increments happen twice per join. An even number means a
3110 # relationship specified via a search_related, whereas an odd
3111 # number indicates a join/prefetch added via attributes
3112 #
3113 # Also this code will wrap the current resultset (the one we
3114 # chain to) in a subselect IFF it contains limiting attributes
3115 sub _chain_relationship {
3116   my ($self, $rel) = @_;
3117   my $source = $self->result_source;
3118   my $attrs = { %{$self->{attrs}||{}} };
3119
3120   # we need to take the prefetch the attrs into account before we
3121   # ->_resolve_join as otherwise they get lost - captainL
3122   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3123
3124   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3125
3126   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3127
3128   my $from;
3129   my @force_subq_attrs = qw/offset rows group_by having/;
3130
3131   if (
3132     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3133       ||
3134     $self->_has_resolved_attr (@force_subq_attrs)
3135   ) {
3136     # Nuke the prefetch (if any) before the new $rs attrs
3137     # are resolved (prefetch is useless - we are wrapping
3138     # a subquery anyway).
3139     my $rs_copy = $self->search;
3140     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3141       $rs_copy->{attrs}{join},
3142       delete $rs_copy->{attrs}{prefetch},
3143     );
3144
3145     $from = [{
3146       -source_handle => $source->handle,
3147       -alias => $attrs->{alias},
3148       $attrs->{alias} => $rs_copy->as_query,
3149     }];
3150     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3151     $seen->{-relation_chain_depth} = 0;
3152   }
3153   elsif ($attrs->{from}) {  #shallow copy suffices
3154     $from = [ @{$attrs->{from}} ];
3155   }
3156   else {
3157     $from = [{
3158       -source_handle => $source->handle,
3159       -alias => $attrs->{alias},
3160       $attrs->{alias} => $source->from,
3161     }];
3162   }
3163
3164   my $jpath = ($seen->{-relation_chain_depth})
3165     ? $from->[-1][0]{-join_path}
3166     : [];
3167
3168   my @requested_joins = $source->_resolve_join(
3169     $join,
3170     $attrs->{alias},
3171     $seen,
3172     $jpath,
3173   );
3174
3175   push @$from, @requested_joins;
3176
3177   $seen->{-relation_chain_depth}++;
3178
3179   # if $self already had a join/prefetch specified on it, the requested
3180   # $rel might very well be already included. What we do in this case
3181   # is effectively a no-op (except that we bump up the chain_depth on
3182   # the join in question so we could tell it *is* the search_related)
3183   my $already_joined;
3184
3185   # we consider the last one thus reverse
3186   for my $j (reverse @requested_joins) {
3187     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3188     if ($rel eq $last_j) {
3189       $j->[0]{-relation_chain_depth}++;
3190       $already_joined++;
3191       last;
3192     }
3193   }
3194
3195   unless ($already_joined) {
3196     push @$from, $source->_resolve_join(
3197       $rel,
3198       $attrs->{alias},
3199       $seen,
3200       $jpath,
3201     );
3202   }
3203
3204   $seen->{-relation_chain_depth}++;
3205
3206   return {%$attrs, from => $from, seen_join => $seen};
3207 }
3208
3209 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3210 sub _resolved_attrs_copy {
3211   my $self = shift;
3212   return { %{$self->_resolved_attrs (@_)} };
3213 }
3214
3215 sub _resolved_attrs {
3216   my $self = shift;
3217   return $self->{_attrs} if $self->{_attrs};
3218
3219   my $attrs  = { %{ $self->{attrs} || {} } };
3220   my $source = $self->result_source;
3221   my $alias  = $attrs->{alias};
3222
3223   # one last pass of normalization
3224   $self->_normalize_selection($attrs);
3225
3226   # default selection list
3227   $attrs->{columns} = [ $source->columns ]
3228     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as _trailing_select/;
3229
3230   # merge selectors together
3231   for (qw/columns select as _trailing_select/) {
3232     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, $attrs->{"+$_"})
3233       if $attrs->{$_} or $attrs->{"+$_"};
3234   }
3235
3236   # disassemble columns
3237   my (@sel, @as);
3238   if (my $cols = delete $attrs->{columns}) {
3239     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3240       if (ref $c eq 'HASH') {
3241         for my $as (keys %$c) {
3242           push @sel, $c->{$as};
3243           push @as, $as;
3244         }
3245       }
3246       else {
3247         push @sel, $c;
3248         push @as, $c;
3249       }
3250     }
3251   }
3252
3253   # when trying to weed off duplicates later do not go past this point -
3254   # everything added from here on is unbalanced "anyone's guess" stuff
3255   my $dedup_stop_idx = $#as;
3256
3257   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3258     if $attrs->{as};
3259   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3260     if $attrs->{select};
3261
3262   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3263   for (@sel) {
3264     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3265   }
3266
3267   # disqualify all $alias.col as-bits (collapser mandated)
3268   for (@as) {
3269     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3270   }
3271
3272   # de-duplicate the result (remove *identical* select/as pairs)
3273   # and also die on duplicate {as} pointing to different {select}s
3274   # not using a c-style for as the condition is prone to shrinkage
3275   my $seen;
3276   my $i = 0;
3277   while ($i <= $dedup_stop_idx) {
3278     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3279       splice @sel, $i, 1;
3280       splice @as, $i, 1;
3281       $dedup_stop_idx--;
3282     }
3283     elsif ($seen->{$as[$i]}++) {
3284       $self->throw_exception(
3285         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3286       );
3287     }
3288     else {
3289       $i++;
3290     }
3291   }
3292
3293   $attrs->{select} = \@sel;
3294   $attrs->{as} = \@as;
3295
3296   $attrs->{from} ||= [{
3297     -source_handle => $source->handle,
3298     -alias => $self->{attrs}{alias},
3299     $self->{attrs}{alias} => $source->from,
3300   }];
3301
3302   if ( $attrs->{join} || $attrs->{prefetch} ) {
3303
3304     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3305       if ref $attrs->{from} ne 'ARRAY';
3306
3307     my $join = (delete $attrs->{join}) || {};
3308
3309     if ( defined $attrs->{prefetch} ) {
3310       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3311     }
3312
3313     $attrs->{from} =    # have to copy here to avoid corrupting the original
3314       [
3315         @{ $attrs->{from} },
3316         $source->_resolve_join(
3317           $join,
3318           $alias,
3319           { %{ $attrs->{seen_join} || {} } },
3320           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3321             ? $attrs->{from}[-1][0]{-join_path}
3322             : []
3323           ,
3324         )
3325       ];
3326   }
3327
3328   if ( defined $attrs->{order_by} ) {
3329     $attrs->{order_by} = (
3330       ref( $attrs->{order_by} ) eq 'ARRAY'
3331       ? [ @{ $attrs->{order_by} } ]
3332       : [ $attrs->{order_by} || () ]
3333     );
3334   }
3335
3336   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3337     $attrs->{group_by} = [ $attrs->{group_by} ];
3338   }
3339
3340   # generate the distinct induced group_by early, as prefetch will be carried via a
3341   # subquery (since a group_by is present)
3342   if (delete $attrs->{distinct}) {
3343     if ($attrs->{group_by}) {
3344       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3345     }
3346     else {
3347       # distinct affects only the main selection part, not what prefetch may
3348       # add below. However trailing is not yet a part of the selection as
3349       # prefetch must insert before it
3350       $attrs->{group_by} = $source->storage->_group_over_selection (
3351         $attrs->{from},
3352         [ @{$attrs->{select}||[]}, @{$attrs->{_trailing_select}||[]} ],
3353         $attrs->{order_by},
3354       );
3355     }
3356   }
3357
3358   $attrs->{collapse} ||= {};
3359   if ($attrs->{prefetch}) {
3360     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3361
3362     my $prefetch_ordering = [];
3363
3364     # this is a separate structure (we don't look in {from} directly)
3365     # as the resolver needs to shift things off the lists to work
3366     # properly (identical-prefetches on different branches)
3367     my $join_map = {};
3368     if (ref $attrs->{from} eq 'ARRAY') {
3369
3370       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3371
3372       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3373         next unless $j->[0]{-alias};
3374         next unless $j->[0]{-join_path};
3375         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3376
3377         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3378
3379         my $p = $join_map;
3380         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3381         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3382       }
3383     }
3384
3385     my @prefetch =
3386       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3387
3388     # we need to somehow mark which columns came from prefetch
3389     if (@prefetch) {
3390       my $sel_end = $#{$attrs->{select}};
3391       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3392     }
3393
3394     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3395     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3396
3397     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3398     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3399   }
3400
3401
3402   push @{ $attrs->{select} }, @{$attrs->{_trailing_select}}
3403     if $attrs->{_trailing_select};
3404
3405   # if both page and offset are specified, produce a combined offset
3406   # even though it doesn't make much sense, this is what pre 081xx has
3407   # been doing
3408   if (my $page = delete $attrs->{page}) {
3409     $attrs->{offset} =
3410       ($attrs->{rows} * ($page - 1))
3411             +
3412       ($attrs->{offset} || 0)
3413     ;
3414   }
3415
3416   return $self->{_attrs} = $attrs;
3417 }
3418
3419 sub _rollout_attr {
3420   my ($self, $attr) = @_;
3421
3422   if (ref $attr eq 'HASH') {
3423     return $self->_rollout_hash($attr);
3424   } elsif (ref $attr eq 'ARRAY') {
3425     return $self->_rollout_array($attr);
3426   } else {
3427     return [$attr];
3428   }
3429 }
3430
3431 sub _rollout_array {
3432   my ($self, $attr) = @_;
3433
3434   my @rolled_array;
3435   foreach my $element (@{$attr}) {
3436     if (ref $element eq 'HASH') {
3437       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3438     } elsif (ref $element eq 'ARRAY') {
3439       #  XXX - should probably recurse here
3440       push( @rolled_array, @{$self->_rollout_array($element)} );
3441     } else {
3442       push( @rolled_array, $element );
3443     }
3444   }
3445   return \@rolled_array;
3446 }
3447
3448 sub _rollout_hash {
3449   my ($self, $attr) = @_;
3450
3451   my @rolled_array;
3452   foreach my $key (keys %{$attr}) {
3453     push( @rolled_array, { $key => $attr->{$key} } );
3454   }
3455   return \@rolled_array;
3456 }
3457
3458 sub _calculate_score {
3459   my ($self, $a, $b) = @_;
3460
3461   if (defined $a xor defined $b) {
3462     return 0;
3463   }
3464   elsif (not defined $a) {
3465     return 1;
3466   }
3467
3468   if (ref $b eq 'HASH') {
3469     my ($b_key) = keys %{$b};
3470     if (ref $a eq 'HASH') {
3471       my ($a_key) = keys %{$a};
3472       if ($a_key eq $b_key) {
3473         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3474       } else {
3475         return 0;
3476       }
3477     } else {
3478       return ($a eq $b_key) ? 1 : 0;
3479     }
3480   } else {
3481     if (ref $a eq 'HASH') {
3482       my ($a_key) = keys %{$a};
3483       return ($b eq $a_key) ? 1 : 0;
3484     } else {
3485       return ($b eq $a) ? 1 : 0;
3486     }
3487   }
3488 }
3489
3490 sub _merge_joinpref_attr {
3491   my ($self, $orig, $import) = @_;
3492
3493   return $import unless defined($orig);
3494   return $orig unless defined($import);
3495
3496   $orig = $self->_rollout_attr($orig);
3497   $import = $self->_rollout_attr($import);
3498
3499   my $seen_keys;
3500   foreach my $import_element ( @{$import} ) {
3501     # find best candidate from $orig to merge $b_element into
3502     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3503     foreach my $orig_element ( @{$orig} ) {
3504       my $score = $self->_calculate_score( $orig_element, $import_element );
3505       if ($score > $best_candidate->{score}) {
3506         $best_candidate->{position} = $position;
3507         $best_candidate->{score} = $score;
3508       }
3509       $position++;
3510     }
3511     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3512
3513     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3514       push( @{$orig}, $import_element );
3515     } else {
3516       my $orig_best = $orig->[$best_candidate->{position}];
3517       # merge orig_best and b_element together and replace original with merged
3518       if (ref $orig_best ne 'HASH') {
3519         $orig->[$best_candidate->{position}] = $import_element;
3520       } elsif (ref $import_element eq 'HASH') {
3521         my ($key) = keys %{$orig_best};
3522         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3523       }
3524     }
3525     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3526   }
3527
3528   return $orig;
3529 }
3530
3531 {
3532   my $hm;
3533
3534   sub _merge_attr {
3535     $hm ||= do {
3536       my $hm = Hash::Merge->new;
3537
3538       $hm->specify_behavior({
3539         SCALAR => {
3540           SCALAR => sub {
3541             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3542
3543             if ($defl xor $defr) {
3544               return [ $defl ? $_[0] : $_[1] ];
3545             }
3546             elsif (! $defl) {
3547               return [];
3548             }
3549             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3550               return [ $_[0] ];
3551             }
3552             else {
3553               return [$_[0], $_[1]];
3554             }
3555           },
3556           ARRAY => sub {
3557             return $_[1] if !defined $_[0];
3558             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3559             return [$_[0], @{$_[1]}]
3560           },
3561           HASH  => sub {
3562             return [] if !defined $_[0] and !keys %{$_[1]};
3563             return [ $_[1] ] if !defined $_[0];
3564             return [ $_[0] ] if !keys %{$_[1]};
3565             return [$_[0], $_[1]]
3566           },
3567         },
3568         ARRAY => {
3569           SCALAR => sub {
3570             return $_[0] if !defined $_[1];
3571             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3572             return [@{$_[0]}, $_[1]]
3573           },
3574           ARRAY => sub {
3575             my @ret = @{$_[0]} or return $_[1];
3576             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3577             my %idx = map { $_ => 1 } @ret;
3578             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3579             \@ret;
3580           },
3581           HASH => sub {
3582             return [ $_[1] ] if ! @{$_[0]};
3583             return $_[0] if !keys %{$_[1]};
3584             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3585             return [ @{$_[0]}, $_[1] ];
3586           },
3587         },
3588         HASH => {
3589           SCALAR => sub {
3590             return [] if !keys %{$_[0]} and !defined $_[1];
3591             return [ $_[0] ] if !defined $_[1];
3592             return [ $_[1] ] if !keys %{$_[0]};
3593             return [$_[0], $_[1]]
3594           },
3595           ARRAY => sub {
3596             return [] if !keys %{$_[0]} and !@{$_[1]};
3597             return [ $_[0] ] if !@{$_[1]};
3598             return $_[1] if !keys %{$_[0]};
3599             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3600             return [ $_[0], @{$_[1]} ];
3601           },
3602           HASH => sub {
3603             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3604             return [ $_[0] ] if !keys %{$_[1]};
3605             return [ $_[1] ] if !keys %{$_[0]};
3606             return [ $_[0] ] if $_[0] eq $_[1];
3607             return [ $_[0], $_[1] ];
3608           },
3609         }
3610       } => 'DBIC_RS_ATTR_MERGER');
3611       $hm;
3612     };
3613
3614     return $hm->merge ($_[1], $_[2]);
3615   }
3616 }
3617
3618 sub result_source {
3619     my $self = shift;
3620
3621     if (@_) {
3622         $self->_source_handle($_[0]->handle);
3623     } else {
3624         $self->_source_handle->resolve;
3625     }
3626 }
3627
3628
3629 sub STORABLE_freeze {
3630   my ($self, $cloning) = @_;
3631   my $to_serialize = { %$self };
3632
3633   # A cursor in progress can't be serialized (and would make little sense anyway)
3634   delete $to_serialize->{cursor};
3635
3636   return nfreeze($to_serialize);
3637 }
3638
3639 # need this hook for symmetry
3640 sub STORABLE_thaw {
3641   my ($self, $cloning, $serialized) = @_;
3642
3643   %$self = %{ thaw($serialized) };
3644
3645   return $self;
3646 }
3647
3648
3649 =head2 throw_exception
3650
3651 See L<DBIx::Class::Schema/throw_exception> for details.
3652
3653 =cut
3654
3655 sub throw_exception {
3656   my $self=shift;
3657
3658   if (ref $self && $self->_source_handle->schema) {
3659     $self->_source_handle->schema->throw_exception(@_)
3660   }
3661   else {
3662     DBIx::Class::Exception->throw(@_);
3663   }
3664 }
3665
3666 # XXX: FIXME: Attributes docs need clearing up
3667
3668 =head1 ATTRIBUTES
3669
3670 Attributes are used to refine a ResultSet in various ways when
3671 searching for data. They can be passed to any method which takes an
3672 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3673 L</count>.
3674
3675 These are in no particular order:
3676
3677 =head2 order_by
3678
3679 =over 4
3680
3681 =item Value: ( $order_by | \@order_by | \%order_by )
3682
3683 =back
3684
3685 Which column(s) to order the results by.
3686
3687 [The full list of suitable values is documented in
3688 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3689 common options.]
3690
3691 If a single column name, or an arrayref of names is supplied, the
3692 argument is passed through directly to SQL. The hashref syntax allows
3693 for connection-agnostic specification of ordering direction:
3694
3695  For descending order:
3696
3697   order_by => { -desc => [qw/col1 col2 col3/] }
3698
3699  For explicit ascending order:
3700
3701   order_by => { -asc => 'col' }
3702
3703 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3704 supported, although you are strongly encouraged to use the hashref
3705 syntax as outlined above.
3706
3707 =head2 columns
3708
3709 =over 4
3710
3711 =item Value: \@columns
3712
3713 =back
3714
3715 Shortcut to request a particular set of columns to be retrieved. Each
3716 column spec may be a string (a table column name), or a hash (in which
3717 case the key is the C<as> value, and the value is used as the C<select>
3718 expression). Adds C<me.> onto the start of any column without a C<.> in
3719 it and sets C<select> from that, then auto-populates C<as> from
3720 C<select> as normal. (You may also use the C<cols> attribute, as in
3721 earlier versions of DBIC.)
3722
3723 Essentially C<columns> does the same as L</select> and L</as>.
3724
3725     columns => [ 'foo', { bar => 'baz' } ]
3726
3727 is the same as
3728
3729     select => [qw/foo baz/],
3730     as => [qw/foo bar/]
3731
3732 =head2 +columns
3733
3734 =over 4
3735
3736 =item Value: \@columns
3737
3738 =back
3739
3740 Indicates additional columns to be selected from storage. Works the same
3741 as L</columns> but adds columns to the selection. (You may also use the
3742 C<include_columns> attribute, as in earlier versions of DBIC). For
3743 example:-
3744
3745   $schema->resultset('CD')->search(undef, {
3746     '+columns' => ['artist.name'],
3747     join => ['artist']
3748   });
3749
3750 would return all CDs and include a 'name' column to the information
3751 passed to object inflation. Note that the 'artist' is the name of the
3752 column (or relationship) accessor, and 'name' is the name of the column
3753 accessor in the related table.
3754
3755 =head2 include_columns
3756
3757 =over 4
3758
3759 =item Value: \@columns
3760
3761 =back
3762
3763 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3764
3765 =head2 select
3766
3767 =over 4
3768
3769 =item Value: \@select_columns
3770
3771 =back
3772
3773 Indicates which columns should be selected from the storage. You can use
3774 column names, or in the case of RDBMS back ends, function or stored procedure
3775 names:
3776
3777   $rs = $schema->resultset('Employee')->search(undef, {
3778     select => [
3779       'name',
3780       { count => 'employeeid' },
3781       { max => { length => 'name' }, -as => 'longest_name' }
3782     ]
3783   });
3784
3785   # Equivalent SQL
3786   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3787
3788 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3789 use L</select>, to instruct DBIx::Class how to store the result of the column.
3790 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3791 identifier aliasing. You can however alias a function, so you can use it in
3792 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3793 attribute> supplied as shown in the example above.
3794
3795 =head2 +select
3796
3797 =over 4
3798
3799 Indicates additional columns to be selected from storage.  Works the same as
3800 L</select> but adds columns to the default selection, instead of specifying
3801 an explicit list.
3802
3803 =back
3804
3805 =head2 +as
3806
3807 =over 4
3808
3809 Indicates additional column names for those added via L</+select>. See L</as>.
3810
3811 =back
3812
3813 =head2 as
3814
3815 =over 4
3816
3817 =item Value: \@inflation_names
3818
3819 =back
3820
3821 Indicates column names for object inflation. That is L</as> indicates the
3822 slot name in which the column value will be stored within the
3823 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3824 identifier by the C<get_column> method (or via the object accessor B<if one
3825 with the same name already exists>) as shown below. The L</as> attribute has
3826 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3827
3828   $rs = $schema->resultset('Employee')->search(undef, {
3829     select => [
3830       'name',
3831       { count => 'employeeid' },
3832       { max => { length => 'name' }, -as => 'longest_name' }
3833     ],
3834     as => [qw/
3835       name
3836       employee_count
3837       max_name_length
3838     /],
3839   });
3840
3841 If the object against which the search is performed already has an accessor
3842 matching a column name specified in C<as>, the value can be retrieved using
3843 the accessor as normal:
3844
3845   my $name = $employee->name();
3846
3847 If on the other hand an accessor does not exist in the object, you need to
3848 use C<get_column> instead:
3849
3850   my $employee_count = $employee->get_column('employee_count');
3851
3852 You can create your own accessors if required - see
3853 L<DBIx::Class::Manual::Cookbook> for details.
3854
3855 =head2 join
3856
3857 =over 4
3858
3859 =item Value: ($rel_name | \@rel_names | \%rel_names)
3860
3861 =back
3862
3863 Contains a list of relationships that should be joined for this query.  For
3864 example:
3865
3866   # Get CDs by Nine Inch Nails
3867   my $rs = $schema->resultset('CD')->search(
3868     { 'artist.name' => 'Nine Inch Nails' },
3869     { join => 'artist' }
3870   );
3871
3872 Can also contain a hash reference to refer to the other relation's relations.
3873 For example:
3874
3875   package MyApp::Schema::Track;
3876   use base qw/DBIx::Class/;
3877   __PACKAGE__->table('track');
3878   __PACKAGE__->add_columns(qw/trackid cd position title/);
3879   __PACKAGE__->set_primary_key('trackid');
3880   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3881   1;
3882
3883   # In your application
3884   my $rs = $schema->resultset('Artist')->search(
3885     { 'track.title' => 'Teardrop' },
3886     {
3887       join     => { cd => 'track' },
3888       order_by => 'artist.name',
3889     }
3890   );
3891
3892 You need to use the relationship (not the table) name in  conditions,
3893 because they are aliased as such. The current table is aliased as "me", so
3894 you need to use me.column_name in order to avoid ambiguity. For example:
3895
3896   # Get CDs from 1984 with a 'Foo' track
3897   my $rs = $schema->resultset('CD')->search(
3898     {
3899       'me.year' => 1984,
3900       'tracks.name' => 'Foo'
3901     },
3902     { join => 'tracks' }
3903   );
3904
3905 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3906 similarly for a third time). For e.g.
3907
3908   my $rs = $schema->resultset('Artist')->search({
3909     'cds.title'   => 'Down to Earth',
3910     'cds_2.title' => 'Popular',
3911   }, {
3912     join => [ qw/cds cds/ ],
3913   });
3914
3915 will return a set of all artists that have both a cd with title 'Down
3916 to Earth' and a cd with title 'Popular'.
3917
3918 If you want to fetch related objects from other tables as well, see C<prefetch>
3919 below.
3920
3921 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3922
3923 =head2 prefetch
3924
3925 =over 4
3926
3927 =item Value: ($rel_name | \@rel_names | \%rel_names)
3928
3929 =back
3930
3931 Contains one or more relationships that should be fetched along with
3932 the main query (when they are accessed afterwards the data will
3933 already be available, without extra queries to the database).  This is
3934 useful for when you know you will need the related objects, because it
3935 saves at least one query:
3936
3937   my $rs = $schema->resultset('Tag')->search(
3938     undef,
3939     {
3940       prefetch => {
3941         cd => 'artist'
3942       }
3943     }
3944   );
3945
3946 The initial search results in SQL like the following:
3947
3948   SELECT tag.*, cd.*, artist.* FROM tag
3949   JOIN cd ON tag.cd = cd.cdid
3950   JOIN artist ON cd.artist = artist.artistid
3951
3952 L<DBIx::Class> has no need to go back to the database when we access the
3953 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3954 case.
3955
3956 Simple prefetches will be joined automatically, so there is no need
3957 for a C<join> attribute in the above search.
3958
3959 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3960 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3961 with an accessor type of 'single' or 'filter'). A more complex example that
3962 prefetches an artists cds, the tracks on those cds, and the tags associated
3963 with that artist is given below (assuming many-to-many from artists to tags):
3964
3965  my $rs = $schema->resultset('Artist')->search(
3966    undef,
3967    {
3968      prefetch => [
3969        { cds => 'tracks' },
3970        { artist_tags => 'tags' }
3971      ]
3972    }
3973  );
3974
3975
3976 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3977 attributes will be ignored.
3978
3979 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3980 exactly as you might expect.
3981
3982 =over 4
3983
3984 =item *
3985
3986 Prefetch uses the L</cache> to populate the prefetched relationships. This
3987 may or may not be what you want.
3988
3989 =item *
3990
3991 If you specify a condition on a prefetched relationship, ONLY those
3992 rows that match the prefetched condition will be fetched into that relationship.
3993 This means that adding prefetch to a search() B<may alter> what is returned by
3994 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3995
3996   my $artist_rs = $schema->resultset('Artist')->search({
3997       'cds.year' => 2008,
3998   }, {
3999       join => 'cds',
4000   });
4001
4002   my $count = $artist_rs->first->cds->count;
4003
4004   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4005
4006   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4007
4008   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4009
4010 that cmp_ok() may or may not pass depending on the datasets involved. This
4011 behavior may or may not survive the 0.09 transition.
4012
4013 =back
4014
4015 =head2 page
4016
4017 =over 4
4018
4019 =item Value: $page
4020
4021 =back
4022
4023 Makes the resultset paged and specifies the page to retrieve. Effectively
4024 identical to creating a non-pages resultset and then calling ->page($page)
4025 on it.
4026
4027 If L<rows> attribute is not specified it defaults to 10 rows per page.
4028
4029 When you have a paged resultset, L</count> will only return the number
4030 of rows in the page. To get the total, use the L</pager> and call
4031 C<total_entries> on it.
4032
4033 =head2 rows
4034
4035 =over 4
4036
4037 =item Value: $rows
4038
4039 =back
4040
4041 Specifies the maximum number of rows for direct retrieval or the number of
4042 rows per page if the page attribute or method is used.
4043
4044 =head2 offset
4045
4046 =over 4
4047
4048 =item Value: $offset
4049
4050 =back
4051
4052 Specifies the (zero-based) row number for the  first row to be returned, or the
4053 of the first row of the first page if paging is used.
4054
4055 =head2 group_by
4056
4057 =over 4
4058
4059 =item Value: \@columns
4060
4061 =back
4062
4063 A arrayref of columns to group by. Can include columns of joined tables.
4064
4065   group_by => [qw/ column1 column2 ... /]
4066
4067 =head2 having
4068
4069 =over 4
4070
4071 =item Value: $condition
4072
4073 =back
4074
4075 HAVING is a select statement attribute that is applied between GROUP BY and
4076 ORDER BY. It is applied to the after the grouping calculations have been
4077 done.
4078
4079   having => { 'count_employee' => { '>=', 100 } }
4080
4081 or with an in-place function in which case literal SQL is required:
4082
4083   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4084
4085 =head2 distinct
4086
4087 =over 4
4088
4089 =item Value: (0 | 1)
4090
4091 =back
4092
4093 Set to 1 to group by all columns. If the resultset already has a group_by
4094 attribute, this setting is ignored and an appropriate warning is issued.
4095
4096 =head2 where
4097
4098 =over 4
4099
4100 Adds to the WHERE clause.
4101
4102   # only return rows WHERE deleted IS NULL for all searches
4103   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4104
4105 Can be overridden by passing C<< { where => undef } >> as an attribute
4106 to a resultset.
4107
4108 =back
4109
4110 =head2 cache
4111
4112 Set to 1 to cache search results. This prevents extra SQL queries if you
4113 revisit rows in your ResultSet:
4114
4115   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4116
4117   while( my $artist = $resultset->next ) {
4118     ... do stuff ...
4119   }
4120
4121   $rs->first; # without cache, this would issue a query
4122
4123 By default, searches are not cached.
4124
4125 For more examples of using these attributes, see
4126 L<DBIx::Class::Manual::Cookbook>.
4127
4128 =head2 for
4129
4130 =over 4
4131
4132 =item Value: ( 'update' | 'shared' )
4133
4134 =back
4135
4136 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4137 ... FOR SHARED.
4138
4139 =cut
4140
4141 1;