lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 my @count_via_subq_attrs = qw/join seen_join group_by/;
1154 sub count {
1155   my $self = shift;
1156   return $self->search(@_)->count if @_ and defined $_[0];
1157   return scalar @{ $self->get_cache } if $self->get_cache;
1158
1159   my @check_attrs = @count_via_subq_attrs;
1160
1161   # if we are not paged - we are simply asking for a limit
1162   if (not $self->{attrs}{page} and not $self->{attrs}{software_limit}) {
1163     push @check_attrs, qw/rows offset/;
1164   }
1165
1166   return $self->_has_attr (@check_attrs)
1167     ? $self->_count_subq
1168     : $self->_count_simple
1169 }
1170
1171 sub _count_subq {
1172   my $self = shift;
1173
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   my $select_cols = $attrs->{group_by} || [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1177   $attrs->{from} = [{
1178     count_subq => $self->search ({}, { columns => $select_cols, group_by => $select_cols })
1179                          ->as_query
1180   }];
1181
1182   # the subquery above will integrate everything, including 'where' and any pagers
1183   delete $attrs->{$_} for (@count_via_subq_attrs, qw/where rows offset pager page/ );
1184
1185   return $self->__count ($attrs);
1186 }
1187
1188 sub _count_simple {
1189   my $self = shift;
1190
1191   my $count = $self->__count;
1192   return 0 unless $count;
1193
1194   # need to take offset from resolved attrs
1195
1196   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1197   $count = $self->{attrs}{rows} if
1198     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1199   $count = 0 if ($count < 0);
1200   return $count;
1201 }
1202
1203 sub __count {
1204   my ($self, $attrs) = @_;
1205
1206   $attrs ||= { %{$self->{attrs}} };
1207
1208   $attrs->{select} = { count => '*' };
1209   $attrs->{as} = [qw/count/];
1210
1211   # take off any pagers, record_filter is cdbi, and no point of ordering a count
1212   delete $attrs->{$_} for qw/rows offset page pager order_by record_filter/;
1213
1214   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1215   my ($count) = $tmp_rs->cursor->next;
1216
1217   return $count;
1218 }
1219
1220 sub _bool {
1221   return 1;
1222 }
1223
1224 =head2 count_literal
1225
1226 =over 4
1227
1228 =item Arguments: $sql_fragment, @bind_values
1229
1230 =item Return Value: $count
1231
1232 =back
1233
1234 Counts the results in a literal query. Equivalent to calling L</search_literal>
1235 with the passed arguments, then L</count>.
1236
1237 =cut
1238
1239 sub count_literal { shift->search_literal(@_)->count; }
1240
1241 =head2 all
1242
1243 =over 4
1244
1245 =item Arguments: none
1246
1247 =item Return Value: @objects
1248
1249 =back
1250
1251 Returns all elements in the resultset. Called implicitly if the resultset
1252 is returned in list context.
1253
1254 =cut
1255
1256 sub all {
1257   my $self = shift;
1258   if(@_) {
1259       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1260   }
1261
1262   return @{ $self->get_cache } if $self->get_cache;
1263
1264   my @obj;
1265
1266   # TODO: don't call resolve here
1267   if (keys %{$self->_resolved_attrs->{collapse}}) {
1268 #  if ($self->{attrs}{prefetch}) {
1269       # Using $self->cursor->all is really just an optimisation.
1270       # If we're collapsing has_many prefetches it probably makes
1271       # very little difference, and this is cleaner than hacking
1272       # _construct_object to survive the approach
1273     my @row = $self->cursor->next;
1274     while (@row) {
1275       push(@obj, $self->_construct_object(@row));
1276       @row = (exists $self->{stashed_row}
1277                ? @{delete $self->{stashed_row}}
1278                : $self->cursor->next);
1279     }
1280   } else {
1281     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1282   }
1283
1284   $self->set_cache(\@obj) if $self->{attrs}{cache};
1285   return @obj;
1286 }
1287
1288 =head2 reset
1289
1290 =over 4
1291
1292 =item Arguments: none
1293
1294 =item Return Value: $self
1295
1296 =back
1297
1298 Resets the resultset's cursor, so you can iterate through the elements again.
1299
1300 =cut
1301
1302 sub reset {
1303   my ($self) = @_;
1304   delete $self->{_attrs} if exists $self->{_attrs};
1305   $self->{all_cache_position} = 0;
1306   $self->cursor->reset;
1307   return $self;
1308 }
1309
1310 =head2 first
1311
1312 =over 4
1313
1314 =item Arguments: none
1315
1316 =item Return Value: $object?
1317
1318 =back
1319
1320 Resets the resultset and returns an object for the first result (if the
1321 resultset returns anything).
1322
1323 =cut
1324
1325 sub first {
1326   return $_[0]->reset->next;
1327 }
1328
1329
1330 # _update_delete_via_subq
1331 #
1332 # Presence of some rs attributes requires a subquery to reliably
1333 # update/deletre
1334 #
1335
1336 sub _update_delete_via_subq {
1337   return $_[0]->_has_attr (qw/join seen_join group_by row offset page/);
1338 }
1339
1340
1341 # _cond_for_update_delete
1342 #
1343 # update/delete require the condition to be modified to handle
1344 # the differing SQL syntax available.  This transforms the $self->{cond}
1345 # appropriately, returning the new condition.
1346
1347 sub _cond_for_update_delete {
1348   my ($self, $full_cond) = @_;
1349   my $cond = {};
1350
1351   $full_cond ||= $self->{cond};
1352   # No-op. No condition, we're updating/deleting everything
1353   return $cond unless ref $full_cond;
1354
1355   if (ref $full_cond eq 'ARRAY') {
1356     $cond = [
1357       map {
1358         my %hash;
1359         foreach my $key (keys %{$_}) {
1360           $key =~ /([^.]+)$/;
1361           $hash{$1} = $_->{$key};
1362         }
1363         \%hash;
1364       } @{$full_cond}
1365     ];
1366   }
1367   elsif (ref $full_cond eq 'HASH') {
1368     if ((keys %{$full_cond})[0] eq '-and') {
1369       $cond->{-and} = [];
1370       my @cond = @{$full_cond->{-and}};
1371        for (my $i = 0; $i < @cond; $i++) {
1372         my $entry = $cond[$i];
1373         my $hash;
1374         if (ref $entry eq 'HASH') {
1375           $hash = $self->_cond_for_update_delete($entry);
1376         }
1377         else {
1378           $entry =~ /([^.]+)$/;
1379           $hash->{$1} = $cond[++$i];
1380         }
1381         push @{$cond->{-and}}, $hash;
1382       }
1383     }
1384     else {
1385       foreach my $key (keys %{$full_cond}) {
1386         $key =~ /([^.]+)$/;
1387         $cond->{$1} = $full_cond->{$key};
1388       }
1389     }
1390   }
1391   else {
1392     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1393   }
1394
1395   return $cond;
1396 }
1397
1398
1399 =head2 update
1400
1401 =over 4
1402
1403 =item Arguments: \%values
1404
1405 =item Return Value: $storage_rv
1406
1407 =back
1408
1409 Sets the specified columns in the resultset to the supplied values in a
1410 single query. Return value will be true if the update succeeded or false
1411 if no records were updated; exact type of success value is storage-dependent.
1412
1413 =cut
1414
1415 sub update {
1416   my ($self, $values) = @_;
1417   $self->throw_exception('Values for update must be a hash')
1418     unless ref $values eq 'HASH';
1419
1420   # rs operations with subqueries are Storage dependent - delegate
1421   if ($self->_update_delete_via_subq) {
1422     return $self->result_source->storage->subq_update_delete($self, 'update', $values);
1423   }
1424
1425   my $cond = $self->_cond_for_update_delete;
1426
1427   return $self->result_source->storage->update(
1428     $self->result_source, $values, $cond
1429   );
1430 }
1431
1432 =head2 update_all
1433
1434 =over 4
1435
1436 =item Arguments: \%values
1437
1438 =item Return Value: 1
1439
1440 =back
1441
1442 Fetches all objects and updates them one at a time. Note that C<update_all>
1443 will run DBIC cascade triggers, while L</update> will not.
1444
1445 =cut
1446
1447 sub update_all {
1448   my ($self, $values) = @_;
1449   $self->throw_exception('Values for update_all must be a hash')
1450     unless ref $values eq 'HASH';
1451   foreach my $obj ($self->all) {
1452     $obj->set_columns($values)->update;
1453   }
1454   return 1;
1455 }
1456
1457 =head2 delete
1458
1459 =over 4
1460
1461 =item Arguments: none
1462
1463 =item Return Value: 1
1464
1465 =back
1466
1467 Deletes the contents of the resultset from its result source. Note that this
1468 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1469 to run. See also L<DBIx::Class::Row/delete>.
1470
1471 delete may not generate correct SQL for a query with joins or a resultset
1472 chained from a related resultset.  In this case it will generate a warning:-
1473
1474 In these cases you may find that delete_all is more appropriate, or you
1475 need to respecify your query in a way that can be expressed without a join.
1476
1477 =cut
1478
1479 sub delete {
1480   my $self = shift;
1481   $self->throw_exception('delete does not accept any arguments')
1482     if @_;
1483
1484   # rs operations with subqueries are Storage dependent - delegate
1485   if ($self->_update_delete_via_subq) {
1486     return $self->result_source->storage->subq_update_delete($self, 'delete');
1487   }
1488
1489   my $cond = $self->_cond_for_update_delete;
1490
1491   $self->result_source->storage->delete($self->result_source, $cond);
1492   return 1;
1493 }
1494
1495 =head2 delete_all
1496
1497 =over 4
1498
1499 =item Arguments: none
1500
1501 =item Return Value: 1
1502
1503 =back
1504
1505 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1506 will run DBIC cascade triggers, while L</delete> will not.
1507
1508 =cut
1509
1510 sub delete_all {
1511   my $self = shift;
1512   $self->throw_exception('delete_all does not accept any arguments')
1513     if @_;
1514
1515   $_->delete for $self->all;
1516   return 1;
1517 }
1518
1519 =head2 populate
1520
1521 =over 4
1522
1523 =item Arguments: \@data;
1524
1525 =back
1526
1527 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1528 For the arrayref of hashrefs style each hashref should be a structure suitable
1529 forsubmitting to a $resultset->create(...) method.
1530
1531 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1532 to insert the data, as this is a faster method.
1533
1534 Otherwise, each set of data is inserted into the database using
1535 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1536 objects is returned.
1537
1538 Example:  Assuming an Artist Class that has many CDs Classes relating:
1539
1540   my $Artist_rs = $schema->resultset("Artist");
1541
1542   ## Void Context Example
1543   $Artist_rs->populate([
1544      { artistid => 4, name => 'Manufactured Crap', cds => [
1545         { title => 'My First CD', year => 2006 },
1546         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1547       ],
1548      },
1549      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1550         { title => 'My parents sold me to a record company' ,year => 2005 },
1551         { title => 'Why Am I So Ugly?', year => 2006 },
1552         { title => 'I Got Surgery and am now Popular', year => 2007 }
1553       ],
1554      },
1555   ]);
1556
1557   ## Array Context Example
1558   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1559     { name => "Artist One"},
1560     { name => "Artist Two"},
1561     { name => "Artist Three", cds=> [
1562     { title => "First CD", year => 2007},
1563     { title => "Second CD", year => 2008},
1564   ]}
1565   ]);
1566
1567   print $ArtistOne->name; ## response is 'Artist One'
1568   print $ArtistThree->cds->count ## reponse is '2'
1569
1570 For the arrayref of arrayrefs style,  the first element should be a list of the
1571 fieldsnames to which the remaining elements are rows being inserted.  For
1572 example:
1573
1574   $Arstist_rs->populate([
1575     [qw/artistid name/],
1576     [100, 'A Formally Unknown Singer'],
1577     [101, 'A singer that jumped the shark two albums ago'],
1578     [102, 'An actually cool singer.'],
1579   ]);
1580
1581 Please note an important effect on your data when choosing between void and
1582 wantarray context. Since void context goes straight to C<insert_bulk> in
1583 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1584 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1585 create primary keys for you, you will find that your PKs are empty.  In this
1586 case you will have to use the wantarray context in order to create those
1587 values.
1588
1589 =cut
1590
1591 sub populate {
1592   my $self = shift @_;
1593   my $data = ref $_[0][0] eq 'HASH'
1594     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1595     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1596
1597   if(defined wantarray) {
1598     my @created;
1599     foreach my $item (@$data) {
1600       push(@created, $self->create($item));
1601     }
1602     return @created;
1603   } else {
1604     my ($first, @rest) = @$data;
1605
1606     my @names = grep {!ref $first->{$_}} keys %$first;
1607     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1608     my @pks = $self->result_source->primary_columns;
1609
1610     ## do the belongs_to relationships
1611     foreach my $index (0..$#$data) {
1612       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1613         my @ret = $self->populate($data);
1614         return;
1615       }
1616
1617       foreach my $rel (@rels) {
1618         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1619         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1620         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1621         my $related = $result->result_source->resolve_condition(
1622           $result->result_source->relationship_info($reverse)->{cond},
1623           $self,
1624           $result,
1625         );
1626
1627         delete $data->[$index]->{$rel};
1628         $data->[$index] = {%{$data->[$index]}, %$related};
1629
1630         push @names, keys %$related if $index == 0;
1631       }
1632     }
1633
1634     ## do bulk insert on current row
1635     my @values = map { [ @$_{@names} ] } @$data;
1636
1637     $self->result_source->storage->insert_bulk(
1638       $self->result_source,
1639       \@names,
1640       \@values,
1641     );
1642
1643     ## do the has_many relationships
1644     foreach my $item (@$data) {
1645
1646       foreach my $rel (@rels) {
1647         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1648
1649         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1650      || $self->throw_exception('Cannot find the relating object.');
1651
1652         my $child = $parent->$rel;
1653
1654         my $related = $child->result_source->resolve_condition(
1655           $parent->result_source->relationship_info($rel)->{cond},
1656           $child,
1657           $parent,
1658         );
1659
1660         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1661         my @populate = map { {%$_, %$related} } @rows_to_add;
1662
1663         $child->populate( \@populate );
1664       }
1665     }
1666   }
1667 }
1668
1669 =head2 _normalize_populate_args ($args)
1670
1671 Private method used by L</populate> to normalize its incoming arguments.  Factored
1672 out in case you want to subclass and accept new argument structures to the
1673 L</populate> method.
1674
1675 =cut
1676
1677 sub _normalize_populate_args {
1678   my ($self, $data) = @_;
1679   my @names = @{shift(@$data)};
1680   my @results_to_create;
1681   foreach my $datum (@$data) {
1682     my %result_to_create;
1683     foreach my $index (0..$#names) {
1684       $result_to_create{$names[$index]} = $$datum[$index];
1685     }
1686     push @results_to_create, \%result_to_create;
1687   }
1688   return \@results_to_create;
1689 }
1690
1691 =head2 pager
1692
1693 =over 4
1694
1695 =item Arguments: none
1696
1697 =item Return Value: $pager
1698
1699 =back
1700
1701 Return Value a L<Data::Page> object for the current resultset. Only makes
1702 sense for queries with a C<page> attribute.
1703
1704 To get the full count of entries for a paged resultset, call
1705 C<total_entries> on the L<Data::Page> object.
1706
1707 =cut
1708
1709 sub pager {
1710   my ($self) = @_;
1711   my $attrs = $self->{attrs};
1712   $self->throw_exception("Can't create pager for non-paged rs")
1713     unless $self->{attrs}{page};
1714   $attrs->{rows} ||= 10;
1715
1716   # throw away the paging flags and re-run the count (possibly
1717   # with a subselect) to get the real total count
1718   my $count_attrs = { %$attrs };
1719   delete $count_attrs->{$_} for qw/rows offset page pager/;
1720   my $total_count = (ref $self)->new($self->result_source, $count_attrs);
1721
1722   return $self->{pager} ||= Data::Page->new(
1723     $total_count, $attrs->{rows}, $self->{attrs}{page});
1724 }
1725
1726 =head2 page
1727
1728 =over 4
1729
1730 =item Arguments: $page_number
1731
1732 =item Return Value: $rs
1733
1734 =back
1735
1736 Returns a resultset for the $page_number page of the resultset on which page
1737 is called, where each page contains a number of rows equal to the 'rows'
1738 attribute set on the resultset (10 by default).
1739
1740 =cut
1741
1742 sub page {
1743   my ($self, $page) = @_;
1744   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1745 }
1746
1747 =head2 new_result
1748
1749 =over 4
1750
1751 =item Arguments: \%vals
1752
1753 =item Return Value: $rowobject
1754
1755 =back
1756
1757 Creates a new row object in the resultset's result class and returns
1758 it. The row is not inserted into the database at this point, call
1759 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1760 will tell you whether the row object has been inserted or not.
1761
1762 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1763
1764 =cut
1765
1766 sub new_result {
1767   my ($self, $values) = @_;
1768   $self->throw_exception( "new_result needs a hash" )
1769     unless (ref $values eq 'HASH');
1770
1771   my %new;
1772   my $alias = $self->{attrs}{alias};
1773
1774   if (
1775     defined $self->{cond}
1776     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1777   ) {
1778     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1779     $new{-from_resultset} = [ keys %new ] if keys %new;
1780   } else {
1781     $self->throw_exception(
1782       "Can't abstract implicit construct, condition not a hash"
1783     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1784
1785     my $collapsed_cond = (
1786       $self->{cond}
1787         ? $self->_collapse_cond($self->{cond})
1788         : {}
1789     );
1790
1791     # precendence must be given to passed values over values inherited from
1792     # the cond, so the order here is important.
1793     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1794     while( my($col,$value) = each %implied ){
1795       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1796         $new{$col} = $value->{'='};
1797         next;
1798       }
1799       $new{$col} = $value if $self->_is_deterministic_value($value);
1800     }
1801   }
1802
1803   %new = (
1804     %new,
1805     %{ $self->_remove_alias($values, $alias) },
1806     -source_handle => $self->_source_handle,
1807     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1808   );
1809
1810   return $self->result_class->new(\%new);
1811 }
1812
1813 # _is_deterministic_value
1814 #
1815 # Make an effor to strip non-deterministic values from the condition,
1816 # to make sure new_result chokes less
1817
1818 sub _is_deterministic_value {
1819   my $self = shift;
1820   my $value = shift;
1821   my $ref_type = ref $value;
1822   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1823   return 1 if Scalar::Util::blessed($value);
1824   return 0;
1825 }
1826
1827 # _has_attr
1828 #
1829 # determines if the resultset defines at least one
1830 # of the attributes supplied
1831 #
1832 # used to determine if a subquery is neccessary
1833
1834 sub _has_attr {
1835   my ($self, @attr_names) = @_;
1836
1837   my $attrs = $self->_resolved_attrs;
1838
1839   my $join_check_req;
1840
1841   for my $n (@attr_names) {
1842     return 1 if defined $attrs->{$n};
1843     ++$join_check_req if $n =~ /join/;
1844   }
1845
1846   # a join can be expressed as a multi-level from
1847   return 1 if (
1848     $join_check_req
1849       and
1850     ref $attrs->{from} eq 'ARRAY'
1851       and
1852     @{$attrs->{from}} > 1
1853   );
1854
1855   return 0;
1856 }
1857
1858 # _collapse_cond
1859 #
1860 # Recursively collapse the condition.
1861
1862 sub _collapse_cond {
1863   my ($self, $cond, $collapsed) = @_;
1864
1865   $collapsed ||= {};
1866
1867   if (ref $cond eq 'ARRAY') {
1868     foreach my $subcond (@$cond) {
1869       next unless ref $subcond;  # -or
1870       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1871     }
1872   }
1873   elsif (ref $cond eq 'HASH') {
1874     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1875       foreach my $subcond (@{$cond->{-and}}) {
1876         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1877       }
1878     }
1879     else {
1880       foreach my $col (keys %$cond) {
1881         my $value = $cond->{$col};
1882         $collapsed->{$col} = $value;
1883       }
1884     }
1885   }
1886
1887   return $collapsed;
1888 }
1889
1890 # _remove_alias
1891 #
1892 # Remove the specified alias from the specified query hash. A copy is made so
1893 # the original query is not modified.
1894
1895 sub _remove_alias {
1896   my ($self, $query, $alias) = @_;
1897
1898   my %orig = %{ $query || {} };
1899   my %unaliased;
1900
1901   foreach my $key (keys %orig) {
1902     if ($key !~ /\./) {
1903       $unaliased{$key} = $orig{$key};
1904       next;
1905     }
1906     $unaliased{$1} = $orig{$key}
1907       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1908   }
1909
1910   return \%unaliased;
1911 }
1912
1913 =head2 as_query (EXPERIMENTAL)
1914
1915 =over 4
1916
1917 =item Arguments: none
1918
1919 =item Return Value: \[ $sql, @bind ]
1920
1921 =back
1922
1923 Returns the SQL query and bind vars associated with the invocant.
1924
1925 This is generally used as the RHS for a subquery.
1926
1927 B<NOTE>: This feature is still experimental.
1928
1929 =cut
1930
1931 sub as_query { return shift->cursor->as_query(@_) }
1932
1933 =head2 find_or_new
1934
1935 =over 4
1936
1937 =item Arguments: \%vals, \%attrs?
1938
1939 =item Return Value: $rowobject
1940
1941 =back
1942
1943   my $artist = $schema->resultset('Artist')->find_or_new(
1944     { artist => 'fred' }, { key => 'artists' });
1945
1946   $cd->cd_to_producer->find_or_new({ producer => $producer },
1947                                    { key => 'primary });
1948
1949 Find an existing record from this resultset, based on its primary
1950 key, or a unique constraint. If none exists, instantiate a new result
1951 object and return it. The object will not be saved into your storage
1952 until you call L<DBIx::Class::Row/insert> on it.
1953
1954 You most likely want this method when looking for existing rows using
1955 a unique constraint that is not the primary key, or looking for
1956 related rows.
1957
1958 If you want objects to be saved immediately, use L</find_or_create> instead.
1959
1960 B<Note>: C<find_or_new> is probably not what you want when creating a
1961 new row in a table that uses primary keys supplied by the
1962 database. Passing in a primary key column with a value of I<undef>
1963 will cause L</find> to attempt to search for a row with a value of
1964 I<NULL>.
1965
1966 =cut
1967
1968 sub find_or_new {
1969   my $self     = shift;
1970   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1971   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1972   my $exists   = $self->find($hash, $attrs);
1973   return defined $exists ? $exists : $self->new_result($hash);
1974 }
1975
1976 =head2 create
1977
1978 =over 4
1979
1980 =item Arguments: \%vals
1981
1982 =item Return Value: a L<DBIx::Class::Row> $object
1983
1984 =back
1985
1986 Attempt to create a single new row or a row with multiple related rows
1987 in the table represented by the resultset (and related tables). This
1988 will not check for duplicate rows before inserting, use
1989 L</find_or_create> to do that.
1990
1991 To create one row for this resultset, pass a hashref of key/value
1992 pairs representing the columns of the table and the values you wish to
1993 store. If the appropriate relationships are set up, foreign key fields
1994 can also be passed an object representing the foreign row, and the
1995 value will be set to its primary key.
1996
1997 To create related objects, pass a hashref for the value if the related
1998 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1999 and use the name of the relationship as the key. (NOT the name of the field,
2000 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2001 of hashrefs containing the data for each of the rows to create in the foreign
2002 tables, again using the relationship name as the key.
2003
2004 Instead of hashrefs of plain related data (key/value pairs), you may
2005 also pass new or inserted objects. New objects (not inserted yet, see
2006 L</new>), will be inserted into their appropriate tables.
2007
2008 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2009
2010 Example of creating a new row.
2011
2012   $person_rs->create({
2013     name=>"Some Person",
2014     email=>"somebody@someplace.com"
2015   });
2016
2017 Example of creating a new row and also creating rows in a related C<has_many>
2018 or C<has_one> resultset.  Note Arrayref.
2019
2020   $artist_rs->create(
2021      { artistid => 4, name => 'Manufactured Crap', cds => [
2022         { title => 'My First CD', year => 2006 },
2023         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2024       ],
2025      },
2026   );
2027
2028 Example of creating a new row and also creating a row in a related
2029 C<belongs_to>resultset. Note Hashref.
2030
2031   $cd_rs->create({
2032     title=>"Music for Silly Walks",
2033     year=>2000,
2034     artist => {
2035       name=>"Silly Musician",
2036     }
2037   });
2038
2039 =cut
2040
2041 sub create {
2042   my ($self, $attrs) = @_;
2043   $self->throw_exception( "create needs a hashref" )
2044     unless ref $attrs eq 'HASH';
2045   return $self->new_result($attrs)->insert;
2046 }
2047
2048 =head2 find_or_create
2049
2050 =over 4
2051
2052 =item Arguments: \%vals, \%attrs?
2053
2054 =item Return Value: $rowobject
2055
2056 =back
2057
2058   $cd->cd_to_producer->find_or_create({ producer => $producer },
2059                                       { key => 'primary });
2060
2061 Tries to find a record based on its primary key or unique constraints; if none
2062 is found, creates one and returns that instead.
2063
2064   my $cd = $schema->resultset('CD')->find_or_create({
2065     cdid   => 5,
2066     artist => 'Massive Attack',
2067     title  => 'Mezzanine',
2068     year   => 2005,
2069   });
2070
2071 Also takes an optional C<key> attribute, to search by a specific key or unique
2072 constraint. For example:
2073
2074   my $cd = $schema->resultset('CD')->find_or_create(
2075     {
2076       artist => 'Massive Attack',
2077       title  => 'Mezzanine',
2078     },
2079     { key => 'cd_artist_title' }
2080   );
2081
2082 B<Note>: Because find_or_create() reads from the database and then
2083 possibly inserts based on the result, this method is subject to a race
2084 condition. Another process could create a record in the table after
2085 the find has completed and before the create has started. To avoid
2086 this problem, use find_or_create() inside a transaction.
2087
2088 B<Note>: C<find_or_create> is probably not what you want when creating
2089 a new row in a table that uses primary keys supplied by the
2090 database. Passing in a primary key column with a value of I<undef>
2091 will cause L</find> to attempt to search for a row with a value of
2092 I<NULL>.
2093
2094 See also L</find> and L</update_or_create>. For information on how to declare
2095 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2096
2097 =cut
2098
2099 sub find_or_create {
2100   my $self     = shift;
2101   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2102   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2103   my $exists   = $self->find($hash, $attrs);
2104   return defined $exists ? $exists : $self->create($hash);
2105 }
2106
2107 =head2 update_or_create
2108
2109 =over 4
2110
2111 =item Arguments: \%col_values, { key => $unique_constraint }?
2112
2113 =item Return Value: $rowobject
2114
2115 =back
2116
2117   $resultset->update_or_create({ col => $val, ... });
2118
2119 First, searches for an existing row matching one of the unique constraints
2120 (including the primary key) on the source of this resultset. If a row is
2121 found, updates it with the other given column values. Otherwise, creates a new
2122 row.
2123
2124 Takes an optional C<key> attribute to search on a specific unique constraint.
2125 For example:
2126
2127   # In your application
2128   my $cd = $schema->resultset('CD')->update_or_create(
2129     {
2130       artist => 'Massive Attack',
2131       title  => 'Mezzanine',
2132       year   => 1998,
2133     },
2134     { key => 'cd_artist_title' }
2135   );
2136
2137   $cd->cd_to_producer->update_or_create({
2138     producer => $producer,
2139     name => 'harry',
2140   }, {
2141     key => 'primary,
2142   });
2143
2144
2145 If no C<key> is specified, it searches on all unique constraints defined on the
2146 source, including the primary key.
2147
2148 If the C<key> is specified as C<primary>, it searches only on the primary key.
2149
2150 See also L</find> and L</find_or_create>. For information on how to declare
2151 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2152
2153 B<Note>: C<update_or_create> is probably not what you want when
2154 looking for a row in a table that uses primary keys supplied by the
2155 database, unless you actually have a key value. Passing in a primary
2156 key column with a value of I<undef> will cause L</find> to attempt to
2157 search for a row with a value of I<NULL>.
2158
2159 =cut
2160
2161 sub update_or_create {
2162   my $self = shift;
2163   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2164   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2165
2166   my $row = $self->find($cond, $attrs);
2167   if (defined $row) {
2168     $row->update($cond);
2169     return $row;
2170   }
2171
2172   return $self->create($cond);
2173 }
2174
2175 =head2 update_or_new
2176
2177 =over 4
2178
2179 =item Arguments: \%col_values, { key => $unique_constraint }?
2180
2181 =item Return Value: $rowobject
2182
2183 =back
2184
2185   $resultset->update_or_new({ col => $val, ... });
2186
2187 First, searches for an existing row matching one of the unique constraints
2188 (including the primary key) on the source of this resultset. If a row is
2189 found, updates it with the other given column values. Otherwise, instantiate
2190 a new result object and return it. The object will not be saved into your storage
2191 until you call L<DBIx::Class::Row/insert> on it.
2192
2193 Takes an optional C<key> attribute to search on a specific unique constraint.
2194 For example:
2195
2196   # In your application
2197   my $cd = $schema->resultset('CD')->update_or_new(
2198     {
2199       artist => 'Massive Attack',
2200       title  => 'Mezzanine',
2201       year   => 1998,
2202     },
2203     { key => 'cd_artist_title' }
2204   );
2205
2206   if ($cd->in_storage) {
2207       # the cd was updated
2208   }
2209   else {
2210       # the cd is not yet in the database, let's insert it
2211       $cd->insert;
2212   }
2213
2214 See also L</find>, L</find_or_create> and L<find_or_new>.
2215
2216 =cut
2217
2218 sub update_or_new {
2219     my $self  = shift;
2220     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2221     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2222
2223     my $row = $self->find( $cond, $attrs );
2224     if ( defined $row ) {
2225         $row->update($cond);
2226         return $row;
2227     }
2228
2229     return $self->new_result($cond);
2230 }
2231
2232 =head2 get_cache
2233
2234 =over 4
2235
2236 =item Arguments: none
2237
2238 =item Return Value: \@cache_objects?
2239
2240 =back
2241
2242 Gets the contents of the cache for the resultset, if the cache is set.
2243
2244 The cache is populated either by using the L</prefetch> attribute to
2245 L</search> or by calling L</set_cache>.
2246
2247 =cut
2248
2249 sub get_cache {
2250   shift->{all_cache};
2251 }
2252
2253 =head2 set_cache
2254
2255 =over 4
2256
2257 =item Arguments: \@cache_objects
2258
2259 =item Return Value: \@cache_objects
2260
2261 =back
2262
2263 Sets the contents of the cache for the resultset. Expects an arrayref
2264 of objects of the same class as those produced by the resultset. Note that
2265 if the cache is set the resultset will return the cached objects rather
2266 than re-querying the database even if the cache attr is not set.
2267
2268 The contents of the cache can also be populated by using the
2269 L</prefetch> attribute to L</search>.
2270
2271 =cut
2272
2273 sub set_cache {
2274   my ( $self, $data ) = @_;
2275   $self->throw_exception("set_cache requires an arrayref")
2276       if defined($data) && (ref $data ne 'ARRAY');
2277   $self->{all_cache} = $data;
2278 }
2279
2280 =head2 clear_cache
2281
2282 =over 4
2283
2284 =item Arguments: none
2285
2286 =item Return Value: []
2287
2288 =back
2289
2290 Clears the cache for the resultset.
2291
2292 =cut
2293
2294 sub clear_cache {
2295   shift->set_cache(undef);
2296 }
2297
2298 =head2 related_resultset
2299
2300 =over 4
2301
2302 =item Arguments: $relationship_name
2303
2304 =item Return Value: $resultset
2305
2306 =back
2307
2308 Returns a related resultset for the supplied relationship name.
2309
2310   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2311
2312 =cut
2313
2314 sub related_resultset {
2315   my ($self, $rel) = @_;
2316
2317   $self->{related_resultsets} ||= {};
2318   return $self->{related_resultsets}{$rel} ||= do {
2319     my $rel_obj = $self->result_source->relationship_info($rel);
2320
2321     $self->throw_exception(
2322       "search_related: result source '" . $self->result_source->source_name .
2323         "' has no such relationship $rel")
2324       unless $rel_obj;
2325
2326     my ($from,$seen) = $self->_resolve_from($rel);
2327
2328     my $join_count = $seen->{$rel};
2329     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2330
2331     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2332     my %attrs = %{$self->{attrs}||{}};
2333     delete @attrs{qw(result_class alias)};
2334
2335     my $new_cache;
2336
2337     if (my $cache = $self->get_cache) {
2338       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2339         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2340                         @$cache ];
2341       }
2342     }
2343
2344     my $rel_source = $self->result_source->related_source($rel);
2345
2346     my $new = do {
2347
2348       # The reason we do this now instead of passing the alias to the
2349       # search_rs below is that if you wrap/overload resultset on the
2350       # source you need to know what alias it's -going- to have for things
2351       # to work sanely (e.g. RestrictWithObject wants to be able to add
2352       # extra query restrictions, and these may need to be $alias.)
2353
2354       my $attrs = $rel_source->resultset_attributes;
2355       local $attrs->{alias} = $alias;
2356
2357       $rel_source->resultset
2358                  ->search_rs(
2359                      undef, {
2360                        %attrs,
2361                        join => undef,
2362                        prefetch => undef,
2363                        select => undef,
2364                        as => undef,
2365                        where => $self->{cond},
2366                        seen_join => $seen,
2367                        from => $from,
2368                    });
2369     };
2370     $new->set_cache($new_cache) if $new_cache;
2371     $new;
2372   };
2373 }
2374
2375 =head2 current_source_alias
2376
2377 =over 4
2378
2379 =item Arguments: none
2380
2381 =item Return Value: $source_alias
2382
2383 =back
2384
2385 Returns the current table alias for the result source this resultset is built
2386 on, that will be used in the SQL query. Usually it is C<me>.
2387
2388 Currently the source alias that refers to the result set returned by a
2389 L</search>/L</find> family method depends on how you got to the resultset: it's
2390 C<me> by default, but eg. L</search_related> aliases it to the related result
2391 source name (and keeps C<me> referring to the original result set). The long
2392 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2393 (and make this method unnecessary).
2394
2395 Thus it's currently necessary to use this method in predefined queries (see
2396 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2397 source alias of the current result set:
2398
2399   # in a result set class
2400   sub modified_by {
2401     my ($self, $user) = @_;
2402
2403     my $me = $self->current_source_alias;
2404
2405     return $self->search(
2406       "$me.modified" => $user->id,
2407     );
2408   }
2409
2410 =cut
2411
2412 sub current_source_alias {
2413   my ($self) = @_;
2414
2415   return ($self->{attrs} || {})->{alias} || 'me';
2416 }
2417
2418 sub _resolve_from {
2419   my ($self, $extra_join) = @_;
2420   my $source = $self->result_source;
2421   my $attrs = $self->{attrs};
2422
2423   my $from = $attrs->{from}
2424     || [ { $attrs->{alias} => $source->from } ];
2425
2426   my $seen = { %{$attrs->{seen_join}||{}} };
2427
2428   my $join = ($attrs->{join}
2429                ? [ $attrs->{join}, $extra_join ]
2430                : $extra_join);
2431
2432   # we need to take the prefetch the attrs into account before we
2433   # ->resolve_join as otherwise they get lost - captainL
2434   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2435
2436   $from = [
2437     @$from,
2438     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2439   ];
2440
2441   return ($from,$seen);
2442 }
2443
2444 sub _resolved_attrs {
2445   my $self = shift;
2446   return $self->{_attrs} if $self->{_attrs};
2447
2448   my $attrs  = { %{ $self->{attrs} || {} } };
2449   my $source = $self->result_source;
2450   my $alias  = $attrs->{alias};
2451
2452   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2453   my @colbits;
2454
2455   # build columns (as long as select isn't set) into a set of as/select hashes
2456   unless ( $attrs->{select} ) {
2457       @colbits = map {
2458           ( ref($_) eq 'HASH' )
2459               ? $_
2460               : {
2461                   (
2462                     /^\Q${alias}.\E(.+)$/
2463                       ? "$1"
2464                       : "$_"
2465                   )
2466                 =>
2467                   (
2468                     /\./
2469                       ? "$_"
2470                       : "${alias}.$_"
2471                   )
2472             }
2473       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2474   }
2475   # add the additional columns on
2476   foreach ( 'include_columns', '+columns' ) {
2477       push @colbits, map {
2478           ( ref($_) eq 'HASH' )
2479             ? $_
2480             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2481       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2482   }
2483
2484   # start with initial select items
2485   if ( $attrs->{select} ) {
2486     $attrs->{select} =
2487         ( ref $attrs->{select} eq 'ARRAY' )
2488       ? [ @{ $attrs->{select} } ]
2489       : [ $attrs->{select} ];
2490     $attrs->{as} = (
2491       $attrs->{as}
2492       ? (
2493         ref $attrs->{as} eq 'ARRAY'
2494         ? [ @{ $attrs->{as} } ]
2495         : [ $attrs->{as} ]
2496         )
2497       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2498     );
2499   }
2500   else {
2501
2502     # otherwise we intialise select & as to empty
2503     $attrs->{select} = [];
2504     $attrs->{as}     = [];
2505   }
2506
2507   # now add colbits to select/as
2508   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2509   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2510
2511   my $adds;
2512   if ( $adds = delete $attrs->{'+select'} ) {
2513     $adds = [$adds] unless ref $adds eq 'ARRAY';
2514     push(
2515       @{ $attrs->{select} },
2516       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2517     );
2518   }
2519   if ( $adds = delete $attrs->{'+as'} ) {
2520     $adds = [$adds] unless ref $adds eq 'ARRAY';
2521     push( @{ $attrs->{as} }, @$adds );
2522   }
2523
2524   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2525
2526   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2527     my $join = delete $attrs->{join} || {};
2528
2529     if ( defined $attrs->{prefetch} ) {
2530       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2531
2532     }
2533
2534     $attrs->{from} =    # have to copy here to avoid corrupting the original
2535       [
2536       @{ $attrs->{from} },
2537       $source->resolve_join(
2538         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2539       )
2540       ];
2541
2542   }
2543
2544   $attrs->{group_by} ||= $attrs->{select}
2545     if delete $attrs->{distinct};
2546   if ( $attrs->{order_by} ) {
2547     $attrs->{order_by} = (
2548       ref( $attrs->{order_by} ) eq 'ARRAY'
2549       ? [ @{ $attrs->{order_by} } ]
2550       : [ $attrs->{order_by} ]
2551     );
2552   }
2553   else {
2554     $attrs->{order_by} = [];
2555   }
2556
2557   my $collapse = $attrs->{collapse} || {};
2558   if ( my $prefetch = delete $attrs->{prefetch} ) {
2559     $prefetch = $self->_merge_attr( {}, $prefetch );
2560     my @pre_order;
2561     my $seen = { %{ $attrs->{seen_join} || {} } };
2562     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2563
2564       # bring joins back to level of current class
2565       my @prefetch =
2566         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2567       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2568       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2569     }
2570     push( @{ $attrs->{order_by} }, @pre_order );
2571   }
2572   $attrs->{collapse} = $collapse;
2573
2574   if ( $attrs->{page} ) {
2575     $attrs->{offset} ||= 0;
2576     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2577   }
2578
2579   return $self->{_attrs} = $attrs;
2580 }
2581
2582 sub _rollout_attr {
2583   my ($self, $attr) = @_;
2584
2585   if (ref $attr eq 'HASH') {
2586     return $self->_rollout_hash($attr);
2587   } elsif (ref $attr eq 'ARRAY') {
2588     return $self->_rollout_array($attr);
2589   } else {
2590     return [$attr];
2591   }
2592 }
2593
2594 sub _rollout_array {
2595   my ($self, $attr) = @_;
2596
2597   my @rolled_array;
2598   foreach my $element (@{$attr}) {
2599     if (ref $element eq 'HASH') {
2600       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2601     } elsif (ref $element eq 'ARRAY') {
2602       #  XXX - should probably recurse here
2603       push( @rolled_array, @{$self->_rollout_array($element)} );
2604     } else {
2605       push( @rolled_array, $element );
2606     }
2607   }
2608   return \@rolled_array;
2609 }
2610
2611 sub _rollout_hash {
2612   my ($self, $attr) = @_;
2613
2614   my @rolled_array;
2615   foreach my $key (keys %{$attr}) {
2616     push( @rolled_array, { $key => $attr->{$key} } );
2617   }
2618   return \@rolled_array;
2619 }
2620
2621 sub _calculate_score {
2622   my ($self, $a, $b) = @_;
2623
2624   if (ref $b eq 'HASH') {
2625     my ($b_key) = keys %{$b};
2626     if (ref $a eq 'HASH') {
2627       my ($a_key) = keys %{$a};
2628       if ($a_key eq $b_key) {
2629         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2630       } else {
2631         return 0;
2632       }
2633     } else {
2634       return ($a eq $b_key) ? 1 : 0;
2635     }
2636   } else {
2637     if (ref $a eq 'HASH') {
2638       my ($a_key) = keys %{$a};
2639       return ($b eq $a_key) ? 1 : 0;
2640     } else {
2641       return ($b eq $a) ? 1 : 0;
2642     }
2643   }
2644 }
2645
2646 sub _merge_attr {
2647   my ($self, $orig, $import) = @_;
2648
2649   return $import unless defined($orig);
2650   return $orig unless defined($import);
2651
2652   $orig = $self->_rollout_attr($orig);
2653   $import = $self->_rollout_attr($import);
2654
2655   my $seen_keys;
2656   foreach my $import_element ( @{$import} ) {
2657     # find best candidate from $orig to merge $b_element into
2658     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2659     foreach my $orig_element ( @{$orig} ) {
2660       my $score = $self->_calculate_score( $orig_element, $import_element );
2661       if ($score > $best_candidate->{score}) {
2662         $best_candidate->{position} = $position;
2663         $best_candidate->{score} = $score;
2664       }
2665       $position++;
2666     }
2667     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2668
2669     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2670       push( @{$orig}, $import_element );
2671     } else {
2672       my $orig_best = $orig->[$best_candidate->{position}];
2673       # merge orig_best and b_element together and replace original with merged
2674       if (ref $orig_best ne 'HASH') {
2675         $orig->[$best_candidate->{position}] = $import_element;
2676       } elsif (ref $import_element eq 'HASH') {
2677         my ($key) = keys %{$orig_best};
2678         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2679       }
2680     }
2681     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2682   }
2683
2684   return $orig;
2685 }
2686
2687 sub result_source {
2688     my $self = shift;
2689
2690     if (@_) {
2691         $self->_source_handle($_[0]->handle);
2692     } else {
2693         $self->_source_handle->resolve;
2694     }
2695 }
2696
2697 =head2 throw_exception
2698
2699 See L<DBIx::Class::Schema/throw_exception> for details.
2700
2701 =cut
2702
2703 sub throw_exception {
2704   my $self=shift;
2705   if (ref $self && $self->_source_handle->schema) {
2706     $self->_source_handle->schema->throw_exception(@_)
2707   } else {
2708     croak(@_);
2709   }
2710
2711 }
2712
2713 # XXX: FIXME: Attributes docs need clearing up
2714
2715 =head1 ATTRIBUTES
2716
2717 Attributes are used to refine a ResultSet in various ways when
2718 searching for data. They can be passed to any method which takes an
2719 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2720 L</count>.
2721
2722 These are in no particular order:
2723
2724 =head2 order_by
2725
2726 =over 4
2727
2728 =item Value: ( $order_by | \@order_by | \%order_by )
2729
2730 =back
2731
2732 Which column(s) to order the results by. If a single column name, or
2733 an arrayref of names is supplied, the argument is passed through
2734 directly to SQL. The hashref syntax allows for connection-agnostic
2735 specification of ordering direction:
2736
2737  For descending order:
2738
2739   order_by => { -desc => [qw/col1 col2 col3/] }
2740
2741  For explicit ascending order:
2742
2743   order_by => { -asc => 'col' }
2744
2745 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2746 supported, although you are strongly encouraged to use the hashref
2747 syntax as outlined above.
2748
2749 =head2 columns
2750
2751 =over 4
2752
2753 =item Value: \@columns
2754
2755 =back
2756
2757 Shortcut to request a particular set of columns to be retrieved. Each
2758 column spec may be a string (a table column name), or a hash (in which
2759 case the key is the C<as> value, and the value is used as the C<select>
2760 expression). Adds C<me.> onto the start of any column without a C<.> in
2761 it and sets C<select> from that, then auto-populates C<as> from
2762 C<select> as normal. (You may also use the C<cols> attribute, as in
2763 earlier versions of DBIC.)
2764
2765 =head2 +columns
2766
2767 =over 4
2768
2769 =item Value: \@columns
2770
2771 =back
2772
2773 Indicates additional columns to be selected from storage. Works the same
2774 as L</columns> but adds columns to the selection. (You may also use the
2775 C<include_columns> attribute, as in earlier versions of DBIC). For
2776 example:-
2777
2778   $schema->resultset('CD')->search(undef, {
2779     '+columns' => ['artist.name'],
2780     join => ['artist']
2781   });
2782
2783 would return all CDs and include a 'name' column to the information
2784 passed to object inflation. Note that the 'artist' is the name of the
2785 column (or relationship) accessor, and 'name' is the name of the column
2786 accessor in the related table.
2787
2788 =head2 include_columns
2789
2790 =over 4
2791
2792 =item Value: \@columns
2793
2794 =back
2795
2796 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2797
2798 =head2 select
2799
2800 =over 4
2801
2802 =item Value: \@select_columns
2803
2804 =back
2805
2806 Indicates which columns should be selected from the storage. You can use
2807 column names, or in the case of RDBMS back ends, function or stored procedure
2808 names:
2809
2810   $rs = $schema->resultset('Employee')->search(undef, {
2811     select => [
2812       'name',
2813       { count => 'employeeid' },
2814       { sum => 'salary' }
2815     ]
2816   });
2817
2818 When you use function/stored procedure names and do not supply an C<as>
2819 attribute, the column names returned are storage-dependent. E.g. MySQL would
2820 return a column named C<count(employeeid)> in the above example.
2821
2822 =head2 +select
2823
2824 =over 4
2825
2826 Indicates additional columns to be selected from storage.  Works the same as
2827 L</select> but adds columns to the selection.
2828
2829 =back
2830
2831 =head2 +as
2832
2833 =over 4
2834
2835 Indicates additional column names for those added via L</+select>. See L</as>.
2836
2837 =back
2838
2839 =head2 as
2840
2841 =over 4
2842
2843 =item Value: \@inflation_names
2844
2845 =back
2846
2847 Indicates column names for object inflation. That is, C<as>
2848 indicates the name that the column can be accessed as via the
2849 C<get_column> method (or via the object accessor, B<if one already
2850 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2851
2852 The C<as> attribute is used in conjunction with C<select>,
2853 usually when C<select> contains one or more function or stored
2854 procedure names:
2855
2856   $rs = $schema->resultset('Employee')->search(undef, {
2857     select => [
2858       'name',
2859       { count => 'employeeid' }
2860     ],
2861     as => ['name', 'employee_count'],
2862   });
2863
2864   my $employee = $rs->first(); # get the first Employee
2865
2866 If the object against which the search is performed already has an accessor
2867 matching a column name specified in C<as>, the value can be retrieved using
2868 the accessor as normal:
2869
2870   my $name = $employee->name();
2871
2872 If on the other hand an accessor does not exist in the object, you need to
2873 use C<get_column> instead:
2874
2875   my $employee_count = $employee->get_column('employee_count');
2876
2877 You can create your own accessors if required - see
2878 L<DBIx::Class::Manual::Cookbook> for details.
2879
2880 Please note: This will NOT insert an C<AS employee_count> into the SQL
2881 statement produced, it is used for internal access only. Thus
2882 attempting to use the accessor in an C<order_by> clause or similar
2883 will fail miserably.
2884
2885 To get around this limitation, you can supply literal SQL to your
2886 C<select> attibute that contains the C<AS alias> text, eg:
2887
2888   select => [\'myfield AS alias']
2889
2890 =head2 join
2891
2892 =over 4
2893
2894 =item Value: ($rel_name | \@rel_names | \%rel_names)
2895
2896 =back
2897
2898 Contains a list of relationships that should be joined for this query.  For
2899 example:
2900
2901   # Get CDs by Nine Inch Nails
2902   my $rs = $schema->resultset('CD')->search(
2903     { 'artist.name' => 'Nine Inch Nails' },
2904     { join => 'artist' }
2905   );
2906
2907 Can also contain a hash reference to refer to the other relation's relations.
2908 For example:
2909
2910   package MyApp::Schema::Track;
2911   use base qw/DBIx::Class/;
2912   __PACKAGE__->table('track');
2913   __PACKAGE__->add_columns(qw/trackid cd position title/);
2914   __PACKAGE__->set_primary_key('trackid');
2915   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2916   1;
2917
2918   # In your application
2919   my $rs = $schema->resultset('Artist')->search(
2920     { 'track.title' => 'Teardrop' },
2921     {
2922       join     => { cd => 'track' },
2923       order_by => 'artist.name',
2924     }
2925   );
2926
2927 You need to use the relationship (not the table) name in  conditions,
2928 because they are aliased as such. The current table is aliased as "me", so
2929 you need to use me.column_name in order to avoid ambiguity. For example:
2930
2931   # Get CDs from 1984 with a 'Foo' track
2932   my $rs = $schema->resultset('CD')->search(
2933     {
2934       'me.year' => 1984,
2935       'tracks.name' => 'Foo'
2936     },
2937     { join => 'tracks' }
2938   );
2939
2940 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2941 similarly for a third time). For e.g.
2942
2943   my $rs = $schema->resultset('Artist')->search({
2944     'cds.title'   => 'Down to Earth',
2945     'cds_2.title' => 'Popular',
2946   }, {
2947     join => [ qw/cds cds/ ],
2948   });
2949
2950 will return a set of all artists that have both a cd with title 'Down
2951 to Earth' and a cd with title 'Popular'.
2952
2953 If you want to fetch related objects from other tables as well, see C<prefetch>
2954 below.
2955
2956 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2957
2958 =head2 prefetch
2959
2960 =over 4
2961
2962 =item Value: ($rel_name | \@rel_names | \%rel_names)
2963
2964 =back
2965
2966 Contains one or more relationships that should be fetched along with
2967 the main query (when they are accessed afterwards the data will
2968 already be available, without extra queries to the database).  This is
2969 useful for when you know you will need the related objects, because it
2970 saves at least one query:
2971
2972   my $rs = $schema->resultset('Tag')->search(
2973     undef,
2974     {
2975       prefetch => {
2976         cd => 'artist'
2977       }
2978     }
2979   );
2980
2981 The initial search results in SQL like the following:
2982
2983   SELECT tag.*, cd.*, artist.* FROM tag
2984   JOIN cd ON tag.cd = cd.cdid
2985   JOIN artist ON cd.artist = artist.artistid
2986
2987 L<DBIx::Class> has no need to go back to the database when we access the
2988 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2989 case.
2990
2991 Simple prefetches will be joined automatically, so there is no need
2992 for a C<join> attribute in the above search.
2993
2994 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2995 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2996 with an accessor type of 'single' or 'filter'). A more complex example that
2997 prefetches an artists cds, the tracks on those cds, and the tags associted
2998 with that artist is given below (assuming many-to-many from artists to tags):
2999
3000  my $rs = $schema->resultset('Artist')->search(
3001    undef,
3002    {
3003      prefetch => [
3004        { cds => 'tracks' },
3005        { artist_tags => 'tags' }
3006      ]
3007    }
3008  );
3009
3010
3011 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3012 attributes will be ignored.
3013
3014 =head2 page
3015
3016 =over 4
3017
3018 =item Value: $page
3019
3020 =back
3021
3022 Makes the resultset paged and specifies the page to retrieve. Effectively
3023 identical to creating a non-pages resultset and then calling ->page($page)
3024 on it.
3025
3026 If L<rows> attribute is not specified it defualts to 10 rows per page.
3027
3028 When you have a paged resultset, L</count> will only return the number
3029 of rows in the page. To get the total, use the L</pager> and call
3030 C<total_entries> on it.
3031
3032 =head2 rows
3033
3034 =over 4
3035
3036 =item Value: $rows
3037
3038 =back
3039
3040 Specifes the maximum number of rows for direct retrieval or the number of
3041 rows per page if the page attribute or method is used.
3042
3043 =head2 offset
3044
3045 =over 4
3046
3047 =item Value: $offset
3048
3049 =back
3050
3051 Specifies the (zero-based) row number for the  first row to be returned, or the
3052 of the first row of the first page if paging is used.
3053
3054 =head2 group_by
3055
3056 =over 4
3057
3058 =item Value: \@columns
3059
3060 =back
3061
3062 A arrayref of columns to group by. Can include columns of joined tables.
3063
3064   group_by => [qw/ column1 column2 ... /]
3065
3066 =head2 having
3067
3068 =over 4
3069
3070 =item Value: $condition
3071
3072 =back
3073
3074 HAVING is a select statement attribute that is applied between GROUP BY and
3075 ORDER BY. It is applied to the after the grouping calculations have been
3076 done.
3077
3078   having => { 'count(employee)' => { '>=', 100 } }
3079
3080 =head2 distinct
3081
3082 =over 4
3083
3084 =item Value: (0 | 1)
3085
3086 =back
3087
3088 Set to 1 to group by all columns.
3089
3090 =head2 where
3091
3092 =over 4
3093
3094 Adds to the WHERE clause.
3095
3096   # only return rows WHERE deleted IS NULL for all searches
3097   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3098
3099 Can be overridden by passing C<{ where => undef }> as an attribute
3100 to a resulset.
3101
3102 =back
3103
3104 =head2 cache
3105
3106 Set to 1 to cache search results. This prevents extra SQL queries if you
3107 revisit rows in your ResultSet:
3108
3109   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3110
3111   while( my $artist = $resultset->next ) {
3112     ... do stuff ...
3113   }
3114
3115   $rs->first; # without cache, this would issue a query
3116
3117 By default, searches are not cached.
3118
3119 For more examples of using these attributes, see
3120 L<DBIx::Class::Manual::Cookbook>.
3121
3122 =head2 from
3123
3124 =over 4
3125
3126 =item Value: \@from_clause
3127
3128 =back
3129
3130 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3131 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3132 clauses.
3133
3134 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3135
3136 C<join> will usually do what you need and it is strongly recommended that you
3137 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3138 And we really do mean "cannot", not just tried and failed. Attempting to use
3139 this because you're having problems with C<join> is like trying to use x86
3140 ASM because you've got a syntax error in your C. Trust us on this.
3141
3142 Now, if you're still really, really sure you need to use this (and if you're
3143 not 100% sure, ask the mailing list first), here's an explanation of how this
3144 works.
3145
3146 The syntax is as follows -
3147
3148   [
3149     { <alias1> => <table1> },
3150     [
3151       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3152       [], # nested JOIN (optional)
3153       { <table1.column1> => <table2.column2>, ... (more conditions) },
3154     ],
3155     # More of the above [ ] may follow for additional joins
3156   ]
3157
3158   <table1> <alias1>
3159   JOIN
3160     <table2> <alias2>
3161     [JOIN ...]
3162   ON <table1.column1> = <table2.column2>
3163   <more joins may follow>
3164
3165 An easy way to follow the examples below is to remember the following:
3166
3167     Anything inside "[]" is a JOIN
3168     Anything inside "{}" is a condition for the enclosing JOIN
3169
3170 The following examples utilize a "person" table in a family tree application.
3171 In order to express parent->child relationships, this table is self-joined:
3172
3173     # Person->belongs_to('father' => 'Person');
3174     # Person->belongs_to('mother' => 'Person');
3175
3176 C<from> can be used to nest joins. Here we return all children with a father,
3177 then search against all mothers of those children:
3178
3179   $rs = $schema->resultset('Person')->search(
3180       undef,
3181       {
3182           alias => 'mother', # alias columns in accordance with "from"
3183           from => [
3184               { mother => 'person' },
3185               [
3186                   [
3187                       { child => 'person' },
3188                       [
3189                           { father => 'person' },
3190                           { 'father.person_id' => 'child.father_id' }
3191                       ]
3192                   ],
3193                   { 'mother.person_id' => 'child.mother_id' }
3194               ],
3195           ]
3196       },
3197   );
3198
3199   # Equivalent SQL:
3200   # SELECT mother.* FROM person mother
3201   # JOIN (
3202   #   person child
3203   #   JOIN person father
3204   #   ON ( father.person_id = child.father_id )
3205   # )
3206   # ON ( mother.person_id = child.mother_id )
3207
3208 The type of any join can be controlled manually. To search against only people
3209 with a father in the person table, we could explicitly use C<INNER JOIN>:
3210
3211     $rs = $schema->resultset('Person')->search(
3212         undef,
3213         {
3214             alias => 'child', # alias columns in accordance with "from"
3215             from => [
3216                 { child => 'person' },
3217                 [
3218                     { father => 'person', -join_type => 'inner' },
3219                     { 'father.id' => 'child.father_id' }
3220                 ],
3221             ]
3222         },
3223     );
3224
3225     # Equivalent SQL:
3226     # SELECT child.* FROM person child
3227     # INNER JOIN person father ON child.father_id = father.id
3228
3229 If you need to express really complex joins or you need a subselect, you
3230 can supply literal SQL to C<from> via a scalar reference. In this case
3231 the contents of the scalar will replace the table name asscoiated with the
3232 resultsource.
3233
3234 WARNING: This technique might very well not work as expected on chained
3235 searches - you have been warned.
3236
3237     # Assuming the Event resultsource is defined as:
3238
3239         MySchema::Event->add_columns (
3240             sequence => {
3241                 data_type => 'INT',
3242                 is_auto_increment => 1,
3243             },
3244             location => {
3245                 data_type => 'INT',
3246             },
3247             type => {
3248                 data_type => 'INT',
3249             },
3250         );
3251         MySchema::Event->set_primary_key ('sequence');
3252
3253     # This will get back the latest event for every location. The column
3254     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3255     # combo to limit the resultset
3256
3257     $rs = $schema->resultset('Event');
3258     $table = $rs->result_source->name;
3259     $latest = $rs->search (
3260         undef,
3261         { from => \ "
3262             (SELECT e1.* FROM $table e1
3263                 JOIN $table e2
3264                     ON e1.location = e2.location
3265                     AND e1.sequence < e2.sequence
3266                 WHERE e2.sequence is NULL
3267             ) me",
3268         },
3269     );
3270
3271     # Equivalent SQL (with the DBIC chunks added):
3272
3273     SELECT me.sequence, me.location, me.type FROM
3274        (SELECT e1.* FROM events e1
3275            JOIN events e2
3276                ON e1.location = e2.location
3277                AND e1.sequence < e2.sequence
3278            WHERE e2.sequence is NULL
3279        ) me;
3280
3281 =head2 for
3282
3283 =over 4
3284
3285 =item Value: ( 'update' | 'shared' )
3286
3287 =back
3288
3289 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3290 ... FOR SHARED.
3291
3292 =cut
3293
3294 1;