lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  77
  78 If you want to make your custom ResultSet classes with L<Moose>, use a template
  79 similar to:
  80
  81     package MyApp::Schema::ResultSet::User;
  82
  83     use Moose;
  84     use namespace::autoclean;
  85     use MooseX::NonMoose;
  86     extends 'DBIx::Class::ResultSet';
  87
  88     sub BUILDARGS { $_[2] }
  89
  90     ...your code...
  91
  92     __PACKAGE__->meta->make_immutable;
  93
  94     1;
  95
  96 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  97 clash with the regular ResultSet constructor. Alternatively, you can use:
  98
  99     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 100
 101 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 102 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 103
 104 =head1 EXAMPLES
 105
 106 =head2 Chaining resultsets
 107
 108 Let's say you've got a query that needs to be run to return some data
 109 to the user. But, you have an authorization system in place that
 110 prevents certain users from seeing certain information. So, you want
 111 to construct the basic query in one method, but add constraints to it in
 112 another.
 113
 114   sub get_data {
 115     my $self = shift;
 116     my $request = $self->get_request; # Get a request object somehow.
 117     my $schema = $self->result_source->schema;
 118
 119     my $cd_rs = $schema->resultset('CD')->search({
 120       title => $request->param('title'),
 121       year => $request->param('year'),
 122     });
 123
 124     $cd_rs = $self->apply_security_policy( $cd_rs );
 125
 126     return $cd_rs->all();
 127   }
 128
 129   sub apply_security_policy {
 130     my $self = shift;
 131     my ($rs) = @_;
 132
 133     return $rs->search({
 134       subversive => 0,
 135     });
 136   }
 137
 138 =head3 Resolving conditions and attributes
 139
 140 When a resultset is chained from another resultset, conditions and
 141 attributes with the same keys need resolving.
 142
 143 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 144 into the existing ones from the original resultset.
 145
 146 The L</where> and L</having> attributes, and any search conditions, are
 147 merged with an SQL C<AND> to the existing condition from the original
 148 resultset.
 149
 150 All other attributes are overridden by any new ones supplied in the
 151 search attributes.
 152
 153 =head2 Multiple queries
 154
 155 Since a resultset just defines a query, you can do all sorts of
 156 things with it with the same object.
 157
 158   # Don't hit the DB yet.
 159   my $cd_rs = $schema->resultset('CD')->search({
 160     title => 'something',
 161     year => 2009,
 162   });
 163
 164   # Each of these hits the DB individually.
 165   my $count = $cd_rs->count;
 166   my $most_recent = $cd_rs->get_column('date_released')->max();
 167   my @records = $cd_rs->all;
 168
 169 And it's not just limited to SELECT statements.
 170
 171   $cd_rs->delete();
 172
 173 This is even cooler:
 174
 175   $cd_rs->create({ artist => 'Fred' });
 176
 177 Which is the same as:
 178
 179   $schema->resultset('CD')->create({
 180     title => 'something',
 181     year => 2009,
 182     artist => 'Fred'
 183   });
 184
 185 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 186
 187 =head1 METHODS
 188
 189 =head2 new
 190
 191 =over 4
 192
 193 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 194
 195 =item Return Value: L<$resultset|/search>
 196
 197 =back
 198
 199 The resultset constructor. Takes a source object (usually a
 200 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 201 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 202 executed as needed by the other methods.
 203
 204 Generally you never construct a resultset manually. Instead you get one
 205 from e.g. a
 206 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 207 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 208 scalar context):
 209
 210   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 211
 212 =over
 213
 214 =item WARNING
 215
 216 If called on an object, proxies to L</new_result> instead, so
 217
 218   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 219
 220 will return a CD object, not a ResultSet, and is equivalent to:
 221
 222   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 223
 224 Please also keep in mind that many internals call L</new_result> directly,
 225 so overloading this method with the idea of intercepting new result object
 226 creation B<will not work>. See also warning pertaining to L</create>.
 227
 228 =back
 229
 230 =cut
 231
 232 sub new {
 233   my $class = shift;
 234   return $class->new_result(@_) if ref $class;
 235
 236   my ($source, $attrs) = @_;
 237   $source = $source->resolve
 238     if $source->isa('DBIx::Class::ResultSourceHandle');
 239   $attrs = { %{$attrs||{}} };
 240
 241   if ($attrs->{page}) {
 242     $attrs->{rows} ||= 10;
 243   }
 244
 245   $attrs->{alias} ||= 'me';
 246
 247   my $self = bless {
 248     result_source => $source,
 249     cond => $attrs->{where},
 250     pager => undef,
 251     attrs => $attrs,
 252   }, $class;
 253
 254   # if there is a dark selector, this means we are already in a
 255   # chain and the cleanup/sanification was taken care of by
 256   # _search_rs already
 257   $self->_normalize_selection($attrs)
 258     unless $attrs->{_dark_selector};
 259
 260   $self->result_class(
 261     $attrs->{result_class} || $source->result_class
 262   );
 263
 264   $self;
 265 }
 266
 267 =head2 search
 268
 269 =over 4
 270
 271 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 272
 273 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 274
 275 =back
 276
 277   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 278   my $new_rs = $cd_rs->search({ year => 2005 });
 279
 280   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 281                  # year = 2005 OR year = 2004
 282
 283 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 284 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 285 To avoid that, use L</search_rs>.
 286
 287 If you need to pass in additional attributes but no additional condition,
 288 call it as C<search(undef, \%attrs)>.
 289
 290   # "SELECT name, artistid FROM $artist_table"
 291   my @all_artists = $schema->resultset('Artist')->search(undef, {
 292     columns => [qw/name artistid/],
 293   });
 294
 295 For a list of attributes that can be passed to C<search>, see
 296 L</ATTRIBUTES>. For more examples of using this function, see
 297 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 298 documentation for the first argument, see L<SQL::Abstract>
 299 and its extension L<DBIx::Class::SQLMaker>.
 300
 301 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 302
 303 =head3 CAVEAT
 304
 305 Note that L</search> does not process/deflate any of the values passed in the
 306 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 307 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 308 manually that any value passed to this method will stringify to something the
 309 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 310 objects, for more info see:
 311 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 312
 313 =cut
 314
 315 sub search {
 316   my $self = shift;
 317   my $rs = $self->search_rs( @_ );
 318
 319   if (wantarray) {
 320     return $rs->all;
 321   }
 322   elsif (defined wantarray) {
 323     return $rs;
 324   }
 325   else {
 326     # we can be called by a relationship helper, which in
 327     # turn may be called in void context due to some braindead
 328     # overload or whatever else the user decided to be clever
 329     # at this particular day. Thus limit the exception to
 330     # external code calls only
 331     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 332       if (caller)[0] !~ /^\QDBIx::Class::/;
 333
 334     return ();
 335   }
 336 }
 337
 338 =head2 search_rs
 339
 340 =over 4
 341
 342 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 343
 344 =item Return Value: L<$resultset|/search>
 345
 346 =back
 347
 348 This method does the same exact thing as search() except it will
 349 always return a resultset, even in list context.
 350
 351 =cut
 352
 353 sub search_rs {
 354   my $self = shift;
 355
 356   my $rsrc = $self->result_source;
 357   my ($call_cond, $call_attrs);
 358
 359   # Special-case handling for (undef, undef) or (undef)
 360   # Note that (foo => undef) is valid deprecated syntax
 361   @_ = () if not scalar grep { defined $_ } @_;
 362
 363   # just a cond
 364   if (@_ == 1) {
 365     $call_cond = shift;
 366   }
 367   # fish out attrs in the ($condref, $attr) case
 368   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 369     ($call_cond, $call_attrs) = @_;
 370   }
 371   elsif (@_ % 2) {
 372     $self->throw_exception('Odd number of arguments to search')
 373   }
 374   # legacy search
 375   elsif (@_) {
 376     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 377       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 378
 379     for my $i (0 .. $#_) {
 380       next if $i % 2;
 381       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 382         if (! defined $_[$i] or ref $_[$i] ne '');
 383     }
 384
 385     $call_cond = { @_ };
 386   }
 387
 388   # see if we can keep the cache (no $rs changes)
 389   my $cache;
 390   my %safe = (alias => 1, cache => 1);
 391   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 392     ! defined $_[0]
 393       or
 394     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 395       or
 396     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 397   )) {
 398     $cache = $self->get_cache;
 399   }
 400
 401   my $old_attrs = { %{$self->{attrs}} };
 402   my $old_having = delete $old_attrs->{having};
 403   my $old_where = delete $old_attrs->{where};
 404
 405   my $new_attrs = { %$old_attrs };
 406
 407   # take care of call attrs (only if anything is changing)
 408   if ($call_attrs and keys %$call_attrs) {
 409
 410     # copy for _normalize_selection
 411     $call_attrs = { %$call_attrs };
 412
 413     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 414
 415     # reset the current selector list if new selectors are supplied
 416     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 417       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 418     }
 419
 420     # Normalize the new selector list (operates on the passed-in attr structure)
 421     # Need to do it on every chain instead of only once on _resolved_attrs, in
 422     # order to allow detection of empty vs partial 'as'
 423     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 424       if $old_attrs->{_dark_selector};
 425     $self->_normalize_selection ($call_attrs);
 426
 427     # start with blind overwriting merge, exclude selector attrs
 428     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 429     delete @{$new_attrs}{@selector_attrs};
 430
 431     for (@selector_attrs) {
 432       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 433         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 434     }
 435
 436     # older deprecated name, use only if {columns} is not there
 437     if (my $c = delete $new_attrs->{cols}) {
 438       if ($new_attrs->{columns}) {
 439         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 440       }
 441       else {
 442         $new_attrs->{columns} = $c;
 443       }
 444     }
 445
 446
 447     # join/prefetch use their own crazy merging heuristics
 448     foreach my $key (qw/join prefetch/) {
 449       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 450         if exists $call_attrs->{$key};
 451     }
 452
 453     # stack binds together
 454     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 455   }
 456
 457
 458   for ($old_where, $call_cond) {
 459     if (defined $_) {
 460       $new_attrs->{where} = $self->_stack_cond (
 461         $_, $new_attrs->{where}
 462       );
 463     }
 464   }
 465
 466   if (defined $old_having) {
 467     $new_attrs->{having} = $self->_stack_cond (
 468       $old_having, $new_attrs->{having}
 469     )
 470   }
 471
 472   my $rs = (ref $self)->new($rsrc, $new_attrs);
 473
 474   $rs->set_cache($cache) if ($cache);
 475
 476   return $rs;
 477 }
 478
 479 my $dark_sel_dumper;
 480 sub _normalize_selection {
 481   my ($self, $attrs) = @_;
 482
 483   # legacy syntax
 484   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 485     if exists $attrs->{include_columns};
 486
 487   # columns are always placed first, however
 488
 489   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 490   # delay the decision on whether to use a default select list ($rsrc->columns)
 491   # allowing stuff like the remove_columns helper to work
 492   #
 493   # select/as +select/+as pairs need special handling - the amount of select/as
 494   # elements in each pair does *not* have to be equal (think multicolumn
 495   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 496   # supplied at all) - try to infer the alias, either from the -as parameter
 497   # of the selector spec, or use the parameter whole if it looks like a column
 498   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 499   # is ok as well), but make sure no more additions to the 'as' chain take place
 500   for my $pref ('', '+') {
 501
 502     my ($sel, $as) = map {
 503       my $key = "${pref}${_}";
 504
 505       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 506         ? @{$attrs->{$key}}
 507         : $attrs->{$key} || ()
 508       ];
 509       delete $attrs->{$key};
 510       $val;
 511     } qw/select as/;
 512
 513     if (! @$as and ! @$sel ) {
 514       next;
 515     }
 516     elsif (@$as and ! @$sel) {
 517       $self->throw_exception(
 518         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 519       );
 520     }
 521     elsif( ! @$as ) {
 522       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 523       # if any @$as has been supplied we assume the user knows what (s)he is doing
 524       # and blindly keep stacking up pieces
 525       unless ($attrs->{_dark_selector}) {
 526         SELECTOR:
 527         for (@$sel) {
 528           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 529             push @$as, $_->{-as};
 530           }
 531           # assume any plain no-space, no-parenthesis string to be a column spec
 532           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 533           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 534             push @$as, $_;
 535           }
 536           # if all else fails - raise a flag that no more aliasing will be allowed
 537           else {
 538             $attrs->{_dark_selector} = {
 539               plus_stage => $pref,
 540               string => ($dark_sel_dumper ||= do {
 541                   require Data::Dumper::Concise;
 542                   Data::Dumper::Concise::DumperObject()->Indent(0);
 543                 })->Values([$_])->Dump
 544               ,
 545             };
 546             last SELECTOR;
 547           }
 548         }
 549       }
 550     }
 551     elsif (@$as < @$sel) {
 552       $self->throw_exception(
 553         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 554       );
 555     }
 556     elsif ($pref and $attrs->{_dark_selector}) {
 557       $self->throw_exception(
 558         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 559       );
 560     }
 561
 562
 563     # merge result
 564     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 565     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 566   }
 567 }
 568
 569 sub _stack_cond {
 570   my ($self, $left, $right) = @_;
 571
 572   # collapse single element top-level conditions
 573   # (single pass only, unlikely to need recursion)
 574   for ($left, $right) {
 575     if (ref $_ eq 'ARRAY') {
 576       if (@$_ == 0) {
 577         $_ = undef;
 578       }
 579       elsif (@$_ == 1) {
 580         $_ = $_->[0];
 581       }
 582     }
 583     elsif (ref $_ eq 'HASH') {
 584       my ($first, $more) = keys %$_;
 585
 586       # empty hash
 587       if (! defined $first) {
 588         $_ = undef;
 589       }
 590       # one element hash
 591       elsif (! defined $more) {
 592         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 593           $_ = $_->{'-and'};
 594         }
 595         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 596           $_ = $_->{'-or'};
 597         }
 598       }
 599     }
 600   }
 601
 602   # merge hashes with weeding out of duplicates (simple cases only)
 603   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 604
 605     # shallow copy to destroy
 606     $right = { %$right };
 607     for (grep { exists $right->{$_} } keys %$left) {
 608       # the use of eq_deeply here is justified - the rhs of an
 609       # expression can contain a lot of twisted weird stuff
 610       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 611     }
 612
 613     $right = undef unless keys %$right;
 614   }
 615
 616
 617   if (defined $left xor defined $right) {
 618     return defined $left ? $left : $right;
 619   }
 620   elsif (! defined $left) {
 621     return undef;
 622   }
 623   else {
 624     return { -and => [ $left, $right ] };
 625   }
 626 }
 627
 628 =head2 search_literal
 629
 630 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 631 should only be used in that context. C<search_literal> is a convenience
 632 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 633 want to ensure columns are bound correctly, use L</search>.
 634
 635 See L<DBIx::Class::Manual::Cookbook/Searching> and
 636 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 637 require C<search_literal>.
 638
 639 =over 4
 640
 641 =item Arguments: $sql_fragment, @standalone_bind_values
 642
 643 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 644
 645 =back
 646
 647   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 648   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 649
 650 Pass a literal chunk of SQL to be added to the conditional part of the
 651 resultset query.
 652
 653 Example of how to use C<search> instead of C<search_literal>
 654
 655   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 656   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 657
 658 =cut
 659
 660 sub search_literal {
 661   my ($self, $sql, @bind) = @_;
 662   my $attr;
 663   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 664     $attr = pop @bind;
 665   }
 666   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 667 }
 668
 669 =head2 find
 670
 671 =over 4
 672
 673 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 674
 675 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 676
 677 =back
 678
 679 Finds and returns a single row based on supplied criteria. Takes either a
 680 hashref with the same format as L</create> (including inference of foreign
 681 keys from related objects), or a list of primary key values in the same
 682 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 683 declaration on the L</result_source>.
 684
 685 In either case an attempt is made to combine conditions already existing on
 686 the resultset with the condition passed to this method.
 687
 688 To aid with preparing the correct query for the storage you may supply the
 689 C<key> attribute, which is the name of a
 690 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 691 unique constraint corresponding to the
 692 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 693 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 694 to construct a query that satisfies the named unique constraint fully (
 695 non-NULL values for each column member of the constraint) an exception is
 696 thrown.
 697
 698 If no C<key> is specified, the search is carried over all unique constraints
 699 which are fully defined by the available condition.
 700
 701 If no such constraint is found, C<find> currently defaults to a simple
 702 C<< search->(\%column_values) >> which may or may not do what you expect.
 703 Note that this fallback behavior may be deprecated in further versions. If
 704 you need to search with arbitrary conditions - use L</search>. If the query
 705 resulting from this fallback produces more than one row, a warning to the
 706 effect is issued, though only the first row is constructed and returned as
 707 C<$result_object>.
 708
 709 In addition to C<key>, L</find> recognizes and applies standard
 710 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 711
 712 Note that if you have extra concerns about the correctness of the resulting
 713 query you need to specify the C<key> attribute and supply the entire condition
 714 as an argument to find (since it is not always possible to perform the
 715 combination of the resultset condition with the supplied one, especially if
 716 the resultset condition contains literal sql).
 717
 718 For example, to find a row by its primary key:
 719
 720   my $cd = $schema->resultset('CD')->find(5);
 721
 722 You can also find a row by a specific unique constraint:
 723
 724   my $cd = $schema->resultset('CD')->find(
 725     {
 726       artist => 'Massive Attack',
 727       title  => 'Mezzanine',
 728     },
 729     { key => 'cd_artist_title' }
 730   );
 731
 732 See also L</find_or_create> and L</update_or_create>.
 733
 734 =cut
 735
 736 sub find {
 737   my $self = shift;
 738   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 739
 740   my $rsrc = $self->result_source;
 741
 742   my $constraint_name;
 743   if (exists $attrs->{key}) {
 744     $constraint_name = defined $attrs->{key}
 745       ? $attrs->{key}
 746       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 747     ;
 748   }
 749
 750   # Parse out the condition from input
 751   my $call_cond;
 752
 753   if (ref $_[0] eq 'HASH') {
 754     $call_cond = { %{$_[0]} };
 755   }
 756   else {
 757     # if only values are supplied we need to default to 'primary'
 758     $constraint_name = 'primary' unless defined $constraint_name;
 759
 760     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 761
 762     $self->throw_exception(
 763       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 764     ) unless @c_cols;
 765
 766     $self->throw_exception (
 767       'find() expects either a column/value hashref, or a list of values '
 768     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 769     ) unless @c_cols == @_;
 770
 771     $call_cond = {};
 772     @{$call_cond}{@c_cols} = @_;
 773   }
 774
 775   my %related;
 776   for my $key (keys %$call_cond) {
 777     if (
 778       my $keyref = ref($call_cond->{$key})
 779         and
 780       my $relinfo = $rsrc->relationship_info($key)
 781     ) {
 782       my $val = delete $call_cond->{$key};
 783
 784       next if $keyref eq 'ARRAY'; # has_many for multi_create
 785
 786       my $rel_q = $rsrc->_resolve_condition(
 787         $relinfo->{cond}, $val, $key, $key
 788       );
 789       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 790       @related{keys %$rel_q} = values %$rel_q;
 791     }
 792   }
 793
 794   # relationship conditions take precedence (?)
 795   @{$call_cond}{keys %related} = values %related;
 796
 797   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 798   my $final_cond;
 799   if (defined $constraint_name) {
 800     $final_cond = $self->_qualify_cond_columns (
 801
 802       $self->_build_unique_cond (
 803         $constraint_name,
 804         $call_cond,
 805       ),
 806
 807       $alias,
 808     );
 809   }
 810   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 811     # This means that we got here after a merger of relationship conditions
 812     # in ::Relationship::Base::search_related (the row method), and furthermore
 813     # the relationship is of the 'single' type. This means that the condition
 814     # provided by the relationship (already attached to $self) is sufficient,
 815     # as there can be only one row in the database that would satisfy the
 816     # relationship
 817   }
 818   else {
 819     # no key was specified - fall down to heuristics mode:
 820     # run through all unique queries registered on the resultset, and
 821     # 'OR' all qualifying queries together
 822     my (@unique_queries, %seen_column_combinations);
 823     for my $c_name ($rsrc->unique_constraint_names) {
 824       next if $seen_column_combinations{
 825         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 826       }++;
 827
 828       push @unique_queries, try {
 829         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 830       } || ();
 831     }
 832
 833     $final_cond = @unique_queries
 834       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 835       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 836     ;
 837   }
 838
 839   # Run the query, passing the result_class since it should propagate for find
 840   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 841   if ($rs->_resolved_attrs->{collapse}) {
 842     my $row = $rs->next;
 843     carp "Query returned more than one row" if $rs->next;
 844     return $row;
 845   }
 846   else {
 847     return $rs->single;
 848   }
 849 }
 850
 851 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 852 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 853 #
 854 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 855 # condition. It is provided for overrides until a saner way forward is devised
 856 #
 857 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 858 # the road. Please adjust your tests accordingly to catch this situation early
 859 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 860 #
 861 # The method will not be removed without an adequately complete replacement
 862 # for strict-mode enforcement
 863 sub _non_unique_find_fallback {
 864   my ($self, $cond, $attrs) = @_;
 865
 866   return $self->_qualify_cond_columns(
 867     $cond,
 868     exists $attrs->{alias}
 869       ? $attrs->{alias}
 870       : $self->{attrs}{alias}
 871   );
 872 }
 873
 874
 875 sub _qualify_cond_columns {
 876   my ($self, $cond, $alias) = @_;
 877
 878   my %aliased = %$cond;
 879   for (keys %aliased) {
 880     $aliased{"$alias.$_"} = delete $aliased{$_}
 881       if $_ !~ /\./;
 882   }
 883
 884   return \%aliased;
 885 }
 886
 887 sub _build_unique_cond {
 888   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 889
 890   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 891
 892   # combination may fail if $self->{cond} is non-trivial
 893   my ($final_cond) = try {
 894     $self->_merge_with_rscond ($extra_cond)
 895   } catch {
 896     +{ %$extra_cond }
 897   };
 898
 899   # trim out everything not in $columns
 900   $final_cond = { map {
 901     exists $final_cond->{$_}
 902       ? ( $_ => $final_cond->{$_} )
 903       : ()
 904   } @c_cols };
 905
 906   if (my @missing = grep
 907     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 908     (@c_cols)
 909   ) {
 910     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 911       $constraint_name,
 912       join (', ', map { "'$_'" } @missing),
 913     ) );
 914   }
 915
 916   if (
 917     !$croak_on_null
 918       and
 919     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 920       and
 921     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 922   ) {
 923     carp_unique ( sprintf (
 924       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 925     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 926     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 927       $constraint_name,
 928       join (', ', map { "'$_'" } @undefs),
 929     ));
 930   }
 931
 932   return $final_cond;
 933 }
 934
 935 =head2 search_related
 936
 937 =over 4
 938
 939 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 940
 941 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 942
 943 =back
 944
 945   $new_rs = $cd_rs->search_related('artist', {
 946     name => 'Emo-R-Us',
 947   });
 948
 949 Searches the specified relationship, optionally specifying a condition and
 950 attributes for matching records. See L</ATTRIBUTES> for more information.
 951
 952 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 953 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 954
 955 See also L</search_related_rs>.
 956
 957 =cut
 958
 959 sub search_related {
 960   return shift->related_resultset(shift)->search(@_);
 961 }
 962
 963 =head2 search_related_rs
 964
 965 This method works exactly the same as search_related, except that
 966 it guarantees a resultset, even in list context.
 967
 968 =cut
 969
 970 sub search_related_rs {
 971   return shift->related_resultset(shift)->search_rs(@_);
 972 }
 973
 974 =head2 cursor
 975
 976 =over 4
 977
 978 =item Arguments: none
 979
 980 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 981
 982 =back
 983
 984 Returns a storage-driven cursor to the given resultset. See
 985 L<DBIx::Class::Cursor> for more information.
 986
 987 =cut
 988
 989 sub cursor {
 990   my $self = shift;
 991
 992   return $self->{cursor} ||= do {
 993     my $attrs = { %{$self->_resolved_attrs } };
 994     $self->result_source->storage->select(
 995       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 996     );
 997   };
 998 }
 999
1000 =head2 single
1001
1002 =over 4
1003
1004 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1005
1006 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1007
1008 =back
1009
1010   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1011
1012 Inflates the first result without creating a cursor if the resultset has
1013 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1014 of L</search>.
1015
1016 While this method can take an optional search condition (just like L</search>)
1017 being a fast-code-path it does not recognize search attributes. If you need to
1018 add extra joins or similar, call L</search> and then chain-call L</single> on the
1019 L<DBIx::Class::ResultSet> returned.
1020
1021 =over
1022
1023 =item B<Note>
1024
1025 As of 0.08100, this method enforces the assumption that the preceding
1026 query returns only one row. If more than one row is returned, you will receive
1027 a warning:
1028
1029   Query returned more than one row
1030
1031 In this case, you should be using L</next> or L</find> instead, or if you really
1032 know what you are doing, use the L</rows> attribute to explicitly limit the size
1033 of the resultset.
1034
1035 This method will also throw an exception if it is called on a resultset prefetching
1036 has_many, as such a prefetch implies fetching multiple rows from the database in
1037 order to assemble the resulting object.
1038
1039 =back
1040
1041 =cut
1042
1043 sub single {
1044   my ($self, $where) = @_;
1045   if(@_ > 2) {
1046       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1047   }
1048
1049   my $attrs = { %{$self->_resolved_attrs} };
1050
1051   $self->throw_exception(
1052     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1053   ) if $attrs->{collapse};
1054
1055   if ($where) {
1056     if (defined $attrs->{where}) {
1057       $attrs->{where} = {
1058         '-and' =>
1059             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1060                $where, delete $attrs->{where} ]
1061       };
1062     } else {
1063       $attrs->{where} = $where;
1064     }
1065   }
1066
1067   my $data = [ $self->result_source->storage->select_single(
1068     $attrs->{from}, $attrs->{select},
1069     $attrs->{where}, $attrs
1070   )];
1071   return undef unless @$data;
1072   $self->{stashed_rows} = [ $data ];
1073   $self->_construct_objects->[0];
1074 }
1075
1076
1077 # _collapse_query
1078 #
1079 # Recursively collapse the query, accumulating values for each column.
1080
1081 sub _collapse_query {
1082   my ($self, $query, $collapsed) = @_;
1083
1084   $collapsed ||= {};
1085
1086   if (ref $query eq 'ARRAY') {
1087     foreach my $subquery (@$query) {
1088       next unless ref $subquery;  # -or
1089       $collapsed = $self->_collapse_query($subquery, $collapsed);
1090     }
1091   }
1092   elsif (ref $query eq 'HASH') {
1093     if (keys %$query and (keys %$query)[0] eq '-and') {
1094       foreach my $subquery (@{$query->{-and}}) {
1095         $collapsed = $self->_collapse_query($subquery, $collapsed);
1096       }
1097     }
1098     else {
1099       foreach my $col (keys %$query) {
1100         my $value = $query->{$col};
1101         $collapsed->{$col}{$value}++;
1102       }
1103     }
1104   }
1105
1106   return $collapsed;
1107 }
1108
1109 =head2 get_column
1110
1111 =over 4
1112
1113 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1114
1115 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1116
1117 =back
1118
1119   my $max_length = $rs->get_column('length')->max;
1120
1121 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1122
1123 =cut
1124
1125 sub get_column {
1126   my ($self, $column) = @_;
1127   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1128   return $new;
1129 }
1130
1131 =head2 search_like
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1136
1137 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1138
1139 =back
1140
1141   # WHERE title LIKE '%blue%'
1142   $cd_rs = $rs->search_like({ title => '%blue%'});
1143
1144 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1145 that this is simply a convenience method retained for ex Class::DBI users.
1146 You most likely want to use L</search> with specific operators.
1147
1148 For more information, see L<DBIx::Class::Manual::Cookbook>.
1149
1150 This method is deprecated and will be removed in 0.09. Use L</search()>
1151 instead. An example conversion is:
1152
1153   ->search_like({ foo => 'bar' });
1154
1155   # Becomes
1156
1157   ->search({ foo => { like => 'bar' } });
1158
1159 =cut
1160
1161 sub search_like {
1162   my $class = shift;
1163   carp_unique (
1164     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1165    .' Instead use ->search({ x => { -like => "y%" } })'
1166    .' (note the outer pair of {}s - they are important!)'
1167   );
1168   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1169   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1170   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1171   return $class->search($query, { %$attrs });
1172 }
1173
1174 =head2 slice
1175
1176 =over 4
1177
1178 =item Arguments: $first, $last
1179
1180 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1181
1182 =back
1183
1184 Returns a resultset or object list representing a subset of elements from the
1185 resultset slice is called on. Indexes are from 0, i.e., to get the first
1186 three records, call:
1187
1188   my ($one, $two, $three) = $rs->slice(0, 2);
1189
1190 =cut
1191
1192 sub slice {
1193   my ($self, $min, $max) = @_;
1194   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1195   $attrs->{offset} = $self->{attrs}{offset} || 0;
1196   $attrs->{offset} += $min;
1197   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1198   return $self->search(undef, $attrs);
1199   #my $slice = (ref $self)->new($self->result_source, $attrs);
1200   #return (wantarray ? $slice->all : $slice);
1201 }
1202
1203 =head2 next
1204
1205 =over 4
1206
1207 =item Arguments: none
1208
1209 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1210
1211 =back
1212
1213 Returns the next element in the resultset (C<undef> is there is none).
1214
1215 Can be used to efficiently iterate over records in the resultset:
1216
1217   my $rs = $schema->resultset('CD')->search;
1218   while (my $cd = $rs->next) {
1219     print $cd->title;
1220   }
1221
1222 Note that you need to store the resultset object, and call C<next> on it.
1223 Calling C<< resultset('Table')->next >> repeatedly will always return the
1224 first record from the resultset.
1225
1226 =cut
1227
1228 sub next {
1229   my ($self) = @_;
1230
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235
1236   if ($self->{attrs}{cache}) {
1237     delete $self->{pager};
1238     $self->{all_cache_position} = 1;
1239     return ($self->all)[0];
1240   }
1241
1242   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1243
1244   $self->{stashed_objects} = $self->_construct_objects
1245     or return undef;
1246
1247   return shift @{$self->{stashed_objects}};
1248 }
1249
1250 # Constructs as many objects as it can in one pass while respecting
1251 # cursor laziness. Several modes of operation:
1252 #
1253 # * Always builds everything present in @{$self->{stashed_rows}}
1254 # * If called with $fetch_all true - pulls everything off the cursor and
1255 #   builds all objects in one pass
1256 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1257 #   and if the resultset is ordered properly by the left side:
1258 #   * Fetches stuff off the cursor until the "master object" changes,
1259 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1260 #   OR
1261 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1262 #     was requested (there is no other way to collapse except for an
1263 #     eager cursor)
1264 # * If no collapse is requested - just get the next row, construct and
1265 #   return
1266 sub _construct_objects {
1267   my ($self, $fetch_all) = @_;
1268
1269   my $rsrc = $self->result_source;
1270   my $attrs = $self->_resolved_attrs;
1271
1272   if (!$fetch_all and ! $attrs->{order_by} and $attrs->{collapse}) {
1273     # default order for collapsing unless the user asked for something
1274     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} $rsrc->primary_columns ];
1275     $attrs->{_ordered_for_collapse} = 1;
1276     $attrs->{_order_is_artificial} = 1;
1277   }
1278
1279   my $cursor = $self->cursor;
1280
1281   # this will be used as both initial raw-row collector AND as a RV of
1282   # _construct_objects. Not regrowing the array twice matters a lot...
1283   # a suprising amount actually
1284   my $rows = delete $self->{stashed_rows};
1285
1286   if ($fetch_all) {
1287     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1288     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1289   }
1290   elsif( $attrs->{collapse} ) {
1291
1292     $attrs->{_ordered_for_collapse} = (!$attrs->{order_by}) ? 0 : do {
1293       my $st = $rsrc->schema->storage;
1294       my @ord_cols = map
1295         { $_->[0] }
1296         ( $st->_extract_order_criteria($attrs->{order_by}) )
1297       ;
1298
1299       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1300
1301       for (0 .. $#ord_cols) {
1302         if (
1303           ! $colinfos->{$ord_cols[$_]}
1304             or
1305           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1306         ) {
1307           splice @ord_cols, $_;
1308           last;
1309         }
1310       }
1311
1312       # since all we check here are the start of the order_by belonging to the
1313       # top level $rsrc, a present identifying set will mean that the resultset
1314       # is ordered by its leftmost table in a tsable manner
1315       (@ord_cols and $rsrc->_identifying_column_set({ map
1316         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1317         @ord_cols
1318       })) ? 1 : 0;
1319     } unless defined $attrs->{_ordered_for_collapse};
1320
1321     if (! $attrs->{_ordered_for_collapse}) {
1322       $fetch_all = 1;
1323
1324       # instead of looping over ->next, use ->all in stealth mode
1325       # *without* calling a ->reset afterwards
1326       # FIXME - encapsulation breach, got to be a better way
1327       if (! $cursor->{_done}) {
1328         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1329         $cursor->{_done} = 1;
1330       }
1331     }
1332   }
1333
1334   if (! $fetch_all and ! @{$rows||[]} ) {
1335     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1336     if (scalar (my @r = $cursor->next) ) {
1337       $rows = [ \@r ];
1338     }
1339   }
1340
1341   return undef unless @{$rows||[]};
1342
1343   my @extra_collapser_args;
1344   if ($attrs->{collapse} and ! $fetch_all ) {
1345
1346     @extra_collapser_args = (
1347       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1348       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1349       ($self->{stashed_rows} = []),                 # where does it stuff excess
1350     );
1351   }
1352
1353   # hotspot - skip the setter
1354   my $res_class = $self->_result_class;
1355
1356   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1357     $res_class->can ('inflate_result')
1358       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1359   };
1360
1361   my $infmap = $attrs->{as};
1362
1363   $self->{_result_inflator}{is_hri} = do { ( $inflator_cref == (
1364     require DBIx::Class::ResultClass::HashRefInflator
1365       &&
1366     DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1367   ) ) ? 1 : 0
1368   } unless defined $self->{_result_inflator}{is_hri};
1369
1370   if ($attrs->{_single_resultclass_inflation}) {
1371     # construct a much simpler array->hash folder for the one-table cases right here
1372     if ($self->{_result_inflator}{is_hri}) {
1373       for my $r (@$rows) {
1374         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1375       }
1376     }
1377     # FIXME SUBOPTIMAL this is a very very very hot spot
1378     # while rather optimal we can *still* do much better, by
1379     # building a smarter Row::inflate_result(), and
1380     # switch to feeding it data via a much leaner interface
1381     #
1382     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1383     # this particular resultset size
1384     elsif (@$rows < 60) {
1385       for my $r (@$rows) {
1386         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1387       }
1388     }
1389     else {
1390       eval sprintf (
1391         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1392         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1393       );
1394     }
1395   }
1396   # Special-case multi-object HRI (we always prune)
1397   elsif ($self->{_result_inflator}{is_hri}) {
1398     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1399       eval => 1,
1400       inflate_map => $infmap,
1401       selection => $attrs->{select},
1402       collapse => $attrs->{collapse},
1403       premultiplied => $attrs->{_main_source_premultiplied},
1404       hri_style => 1,
1405       prune_null_branches => 1,
1406     }) )->($rows, @extra_collapser_args);
1407   }
1408   # Regular multi-object
1409   else {
1410
1411     # The rationale is - if this is the ::Row inflator itself, or an around()
1412     # we do prune, because we expect it.
1413     # If not the case - let the user deal with the full output themselves
1414     # Warn them while we are at it so we get a better idea what is out there
1415     # on the DarkPan
1416     $self->{_result_inflator}{prune_null_branches} = do {
1417       $res_class->isa('DBIx::Class::Row')
1418     } ? 1 : 0 unless defined $self->{_result_inflator}{prune_null_branches};
1419
1420     unless ($self->{_result_inflator}{prune_null_branches}) {
1421       carp_once (
1422         "ResultClass $res_class does not inherit from DBIx::Class::Row and "
1423       . 'therefore its inflate_result() will receive the full prefetched data '
1424       . 'tree, without any branch definedness checks. This is a compatibility '
1425       . 'measure which will eventually disappear entirely. Please refer to '
1426       . 't/resultset/inflate_result_api.t for an exhaustive description of the '
1427       . 'upcoming changes'
1428       );
1429     }
1430
1431     ( $self->{_row_parser}{classic}{$self->{_result_inflator}{prune_null_branches}} ||= $rsrc->_mk_row_parser({
1432       eval => 1,
1433       inflate_map => $infmap,
1434       selection => $attrs->{select},
1435       collapse => $attrs->{collapse},
1436       premultiplied => $attrs->{_main_source_premultiplied},
1437       prune_null_branches => $self->{_result_inflator}{prune_null_branches},
1438     }) )->($rows, @extra_collapser_args);
1439
1440     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1441   }
1442
1443   # CDBI compat stuff
1444   if ($attrs->{record_filter}) {
1445     $_ = $attrs->{record_filter}->($_) for @$rows;
1446   }
1447
1448   return $rows;
1449 }
1450
1451 =head2 result_source
1452
1453 =over 4
1454
1455 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1456
1457 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1458
1459 =back
1460
1461 An accessor for the primary ResultSource object from which this ResultSet
1462 is derived.
1463
1464 =head2 result_class
1465
1466 =over 4
1467
1468 =item Arguments: $result_class?
1469
1470 =item Return Value: $result_class
1471
1472 =back
1473
1474 An accessor for the class to use when creating result objects. Defaults to
1475 C<< result_source->result_class >> - which in most cases is the name of the
1476 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1477
1478 Note that changing the result_class will also remove any components
1479 that were originally loaded in the source class via
1480 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1481 in the original source class will not run.
1482
1483 =cut
1484
1485 sub result_class {
1486   my ($self, $result_class) = @_;
1487   if ($result_class) {
1488
1489     unless (ref $result_class) { # don't fire this for an object
1490       $self->ensure_class_loaded($result_class);
1491     }
1492     $self->_result_class($result_class);
1493     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1494     # permit the user to set result class on one result set only; it only
1495     # chains if provided to search()
1496     #$self->{attrs}{result_class} = $result_class if ref $self;
1497
1498     delete $self->{_result_inflator};
1499   }
1500   $self->_result_class;
1501 }
1502
1503 =head2 count
1504
1505 =over 4
1506
1507 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1508
1509 =item Return Value: $count
1510
1511 =back
1512
1513 Performs an SQL C<COUNT> with the same query as the resultset was built
1514 with to find the number of elements. Passing arguments is equivalent to
1515 C<< $rs->search ($cond, \%attrs)->count >>
1516
1517 =cut
1518
1519 sub count {
1520   my $self = shift;
1521   return $self->search(@_)->count if @_ and defined $_[0];
1522   return scalar @{ $self->get_cache } if $self->get_cache;
1523
1524   my $attrs = { %{ $self->_resolved_attrs } };
1525
1526   # this is a little optimization - it is faster to do the limit
1527   # adjustments in software, instead of a subquery
1528   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1529
1530   my $crs;
1531   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1532     $crs = $self->_count_subq_rs ($attrs);
1533   }
1534   else {
1535     $crs = $self->_count_rs ($attrs);
1536   }
1537   my $count = $crs->next;
1538
1539   $count -= $offset if $offset;
1540   $count = $rows if $rows and $rows < $count;
1541   $count = 0 if ($count < 0);
1542
1543   return $count;
1544 }
1545
1546 =head2 count_rs
1547
1548 =over 4
1549
1550 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1551
1552 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1553
1554 =back
1555
1556 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1557 This can be very handy for subqueries:
1558
1559   ->search( { amount => $some_rs->count_rs->as_query } )
1560
1561 As with regular resultsets the SQL query will be executed only after
1562 the resultset is accessed via L</next> or L</all>. That would return
1563 the same single value obtainable via L</count>.
1564
1565 =cut
1566
1567 sub count_rs {
1568   my $self = shift;
1569   return $self->search(@_)->count_rs if @_;
1570
1571   # this may look like a lack of abstraction (count() does about the same)
1572   # but in fact an _rs *must* use a subquery for the limits, as the
1573   # software based limiting can not be ported if this $rs is to be used
1574   # in a subquery itself (i.e. ->as_query)
1575   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1576     return $self->_count_subq_rs;
1577   }
1578   else {
1579     return $self->_count_rs;
1580   }
1581 }
1582
1583 #
1584 # returns a ResultSetColumn object tied to the count query
1585 #
1586 sub _count_rs {
1587   my ($self, $attrs) = @_;
1588
1589   my $rsrc = $self->result_source;
1590   $attrs ||= $self->_resolved_attrs;
1591
1592   my $tmp_attrs = { %$attrs };
1593   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1594   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1595
1596   # overwrite the selector (supplied by the storage)
1597   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1598   $tmp_attrs->{as} = 'count';
1599
1600   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1601
1602   return $tmp_rs;
1603 }
1604
1605 #
1606 # same as above but uses a subquery
1607 #
1608 sub _count_subq_rs {
1609   my ($self, $attrs) = @_;
1610
1611   my $rsrc = $self->result_source;
1612   $attrs ||= $self->_resolved_attrs;
1613
1614   my $sub_attrs = { %$attrs };
1615   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1616   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1617
1618   # if we multi-prefetch we group_by something unique, as this is what we would
1619   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1620   if ( $attrs->{collapse}  ) {
1621     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1622       $rsrc->_identifying_column_set || $self->throw_exception(
1623         'Unable to construct a unique group_by criteria properly collapsing the '
1624       . 'has_many prefetch before count()'
1625       );
1626     } ]
1627   }
1628
1629   # Calculate subquery selector
1630   if (my $g = $sub_attrs->{group_by}) {
1631
1632     my $sql_maker = $rsrc->storage->sql_maker;
1633
1634     # necessary as the group_by may refer to aliased functions
1635     my $sel_index;
1636     for my $sel (@{$attrs->{select}}) {
1637       $sel_index->{$sel->{-as}} = $sel
1638         if (ref $sel eq 'HASH' and $sel->{-as});
1639     }
1640
1641     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1642     # also look for named aggregates referred in the having clause
1643     # having often contains scalarrefs - thus parse it out entirely
1644     my @parts = @$g;
1645     if ($attrs->{having}) {
1646       local $sql_maker->{having_bind};
1647       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1648       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1649       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1650         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1651         # if we don't unset it we screw up retarded but unfortunately working
1652         # 'MAX(foo.bar)' => { '>', 3 }
1653         $sql_maker->{name_sep} = '';
1654       }
1655
1656       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1657
1658       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1659       my %seen_having;
1660
1661       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1662       # and if all fails for an utterly naive quoted scalar-with-function
1663       while ($having_sql =~ /
1664         $rquote $sep $lquote (.+?) $rquote
1665           |
1666         [\s,] \w+ \. (\w+) [\s,]
1667           |
1668         [\s,] $lquote (.+?) $rquote [\s,]
1669       /gx) {
1670         my $part = $1 || $2 || $3;  # one of them matched if we got here
1671         unless ($seen_having{$part}++) {
1672           push @parts, $part;
1673         }
1674       }
1675     }
1676
1677     for (@parts) {
1678       my $colpiece = $sel_index->{$_} || $_;
1679
1680       # unqualify join-based group_by's. Arcane but possible query
1681       # also horrible horrible hack to alias a column (not a func.)
1682       # (probably need to introduce SQLA syntax)
1683       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1684         my $as = $colpiece;
1685         $as =~ s/\./__/;
1686         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1687       }
1688       push @{$sub_attrs->{select}}, $colpiece;
1689     }
1690   }
1691   else {
1692     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1693     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1694   }
1695
1696   return $rsrc->resultset_class
1697                ->new ($rsrc, $sub_attrs)
1698                 ->as_subselect_rs
1699                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1700                   ->get_column ('count');
1701 }
1702
1703 sub _bool {
1704   return 1;
1705 }
1706
1707 =head2 count_literal
1708
1709 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1710 should only be used in that context. See L</search_literal> for further info.
1711
1712 =over 4
1713
1714 =item Arguments: $sql_fragment, @standalone_bind_values
1715
1716 =item Return Value: $count
1717
1718 =back
1719
1720 Counts the results in a literal query. Equivalent to calling L</search_literal>
1721 with the passed arguments, then L</count>.
1722
1723 =cut
1724
1725 sub count_literal { shift->search_literal(@_)->count; }
1726
1727 =head2 all
1728
1729 =over 4
1730
1731 =item Arguments: none
1732
1733 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1734
1735 =back
1736
1737 Returns all elements in the resultset.
1738
1739 =cut
1740
1741 sub all {
1742   my $self = shift;
1743   if(@_) {
1744     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1745   }
1746
1747   delete @{$self}{qw/stashed_rows stashed_objects/};
1748
1749   if (my $c = $self->get_cache) {
1750     return @$c;
1751   }
1752
1753   $self->cursor->reset;
1754
1755   my $objs = $self->_construct_objects('fetch_all') || [];
1756
1757   $self->set_cache($objs) if $self->{attrs}{cache};
1758
1759   return @$objs;
1760 }
1761
1762 =head2 reset
1763
1764 =over 4
1765
1766 =item Arguments: none
1767
1768 =item Return Value: $self
1769
1770 =back
1771
1772 Resets the resultset's cursor, so you can iterate through the elements again.
1773 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1774 another query.
1775
1776 =cut
1777
1778 sub reset {
1779   my ($self) = @_;
1780
1781   delete @{$self}{qw/stashed_rows stashed_objects/};
1782   $self->{all_cache_position} = 0;
1783   $self->cursor->reset;
1784   return $self;
1785 }
1786
1787 =head2 first
1788
1789 =over 4
1790
1791 =item Arguments: none
1792
1793 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1794
1795 =back
1796
1797 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1798 an object for the first result (or C<undef> if the resultset is empty).
1799
1800 =cut
1801
1802 sub first {
1803   return $_[0]->reset->next;
1804 }
1805
1806
1807 # _rs_update_delete
1808 #
1809 # Determines whether and what type of subquery is required for the $rs operation.
1810 # If grouping is necessary either supplies its own, or verifies the current one
1811 # After all is done delegates to the proper storage method.
1812
1813 sub _rs_update_delete {
1814   my ($self, $op, $values) = @_;
1815
1816   my $rsrc = $self->result_source;
1817   my $storage = $rsrc->schema->storage;
1818
1819   my $attrs = { %{$self->_resolved_attrs} };
1820
1821   my $join_classifications;
1822   my $existing_group_by = delete $attrs->{group_by};
1823
1824   # do we need a subquery for any reason?
1825   my $needs_subq = (
1826     defined $existing_group_by
1827       or
1828     # if {from} is unparseable wrap a subq
1829     ref($attrs->{from}) ne 'ARRAY'
1830       or
1831     # limits call for a subq
1832     $self->_has_resolved_attr(qw/rows offset/)
1833   );
1834
1835   # simplify the joinmap, so we can further decide if a subq is necessary
1836   if (!$needs_subq and @{$attrs->{from}} > 1) {
1837     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1838
1839     # check if there are any joins left after the prune
1840     if ( @{$attrs->{from}} > 1 ) {
1841       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1842         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1843         $attrs->{select},
1844         $self->{cond},
1845         $attrs
1846       );
1847
1848       # any non-pruneable joins imply subq
1849       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1850     }
1851   }
1852
1853   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1854   $needs_subq ||= (
1855     (ref $attrs->{from}[0]) ne 'HASH'
1856       or
1857     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1858   );
1859
1860   my ($cond, $guard);
1861   # do we need anything like a subquery?
1862   if (! $needs_subq) {
1863     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1864     # a condition containing 'me' or other table prefixes will not work
1865     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1866     $cond = do {
1867       my $sqla = $rsrc->storage->sql_maker;
1868       local $sqla->{_dequalify_idents} = 1;
1869       \[ $sqla->_recurse_where($self->{cond}) ];
1870     };
1871   }
1872   else {
1873     # we got this far - means it is time to wrap a subquery
1874     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1875       sprintf(
1876         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1877         $op,
1878         $rsrc->source_name,
1879       )
1880     );
1881
1882     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1883     delete $attrs->{$_} for qw/collapse select _prefetch_selector_range as/;
1884     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1885     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1886     my $subrs = (ref $self)->new($rsrc, $attrs);
1887
1888     if (@$idcols == 1) {
1889       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1890     }
1891     elsif ($storage->_use_multicolumn_in) {
1892       # no syntax for calling this properly yet
1893       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1894       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1895         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1896         $subrs->as_query
1897       ),
1898     }
1899     else {
1900       # if all else fails - get all primary keys and operate over a ORed set
1901       # wrap in a transaction for consistency
1902       # this is where the group_by/multiplication starts to matter
1903       if (
1904         $existing_group_by
1905           or
1906         keys %{ $join_classifications->{multiplying} || {} }
1907       ) {
1908         # make sure if there is a supplied group_by it matches the columns compiled above
1909         # perfectly. Anything else can not be sanely executed on most databases so croak
1910         # right then and there
1911         if ($existing_group_by) {
1912           my @current_group_by = map
1913             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1914             @$existing_group_by
1915           ;
1916
1917           if (
1918             join ("\x00", sort @current_group_by)
1919               ne
1920             join ("\x00", sort @{$attrs->{columns}} )
1921           ) {
1922             $self->throw_exception (
1923               "You have just attempted a $op operation on a resultset which does group_by"
1924               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1925               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1926               . ' kind of queries. Please retry the operation with a modified group_by or'
1927               . ' without using one at all.'
1928             );
1929           }
1930         }
1931
1932         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1933       }
1934
1935       $guard = $storage->txn_scope_guard;
1936
1937       $cond = [];
1938       for my $row ($subrs->cursor->all) {
1939         push @$cond, { map
1940           { $idcols->[$_] => $row->[$_] }
1941           (0 .. $#$idcols)
1942         };
1943       }
1944     }
1945   }
1946
1947   my $res = $storage->$op (
1948     $rsrc,
1949     $op eq 'update' ? $values : (),
1950     $cond,
1951   );
1952
1953   $guard->commit if $guard;
1954
1955   return $res;
1956 }
1957
1958 =head2 update
1959
1960 =over 4
1961
1962 =item Arguments: \%values
1963
1964 =item Return Value: $underlying_storage_rv
1965
1966 =back
1967
1968 Sets the specified columns in the resultset to the supplied values in a
1969 single query. Note that this will not run any accessor/set_column/update
1970 triggers, nor will it update any result object instances derived from this
1971 resultset (this includes the contents of the L<resultset cache|/set_cache>
1972 if any). See L</update_all> if you need to execute any on-update
1973 triggers or cascades defined either by you or a
1974 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1975
1976 The return value is a pass through of what the underlying
1977 storage backend returned, and may vary. See L<DBI/execute> for the most
1978 common case.
1979
1980 =head3 CAVEAT
1981
1982 Note that L</update> does not process/deflate any of the values passed in.
1983 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1984 ensure manually that any value passed to this method will stringify to
1985 something the RDBMS knows how to deal with. A notable example is the
1986 handling of L<DateTime> objects, for more info see:
1987 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1988
1989 =cut
1990
1991 sub update {
1992   my ($self, $values) = @_;
1993   $self->throw_exception('Values for update must be a hash')
1994     unless ref $values eq 'HASH';
1995
1996   return $self->_rs_update_delete ('update', $values);
1997 }
1998
1999 =head2 update_all
2000
2001 =over 4
2002
2003 =item Arguments: \%values
2004
2005 =item Return Value: 1
2006
2007 =back
2008
2009 Fetches all objects and updates them one at a time via
2010 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2011 triggers, while L</update> will not.
2012
2013 =cut
2014
2015 sub update_all {
2016   my ($self, $values) = @_;
2017   $self->throw_exception('Values for update_all must be a hash')
2018     unless ref $values eq 'HASH';
2019
2020   my $guard = $self->result_source->schema->txn_scope_guard;
2021   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2022   $guard->commit;
2023   return 1;
2024 }
2025
2026 =head2 delete
2027
2028 =over 4
2029
2030 =item Arguments: none
2031
2032 =item Return Value: $underlying_storage_rv
2033
2034 =back
2035
2036 Deletes the rows matching this resultset in a single query. Note that this
2037 will not run any delete triggers, nor will it alter the
2038 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2039 derived from this resultset (this includes the contents of the
2040 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2041 execute any on-delete triggers or cascades defined either by you or a
2042 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2043
2044 The return value is a pass through of what the underlying storage backend
2045 returned, and may vary. See L<DBI/execute> for the most common case.
2046
2047 =cut
2048
2049 sub delete {
2050   my $self = shift;
2051   $self->throw_exception('delete does not accept any arguments')
2052     if @_;
2053
2054   return $self->_rs_update_delete ('delete');
2055 }
2056
2057 =head2 delete_all
2058
2059 =over 4
2060
2061 =item Arguments: none
2062
2063 =item Return Value: 1
2064
2065 =back
2066
2067 Fetches all objects and deletes them one at a time via
2068 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2069 triggers, while L</delete> will not.
2070
2071 =cut
2072
2073 sub delete_all {
2074   my $self = shift;
2075   $self->throw_exception('delete_all does not accept any arguments')
2076     if @_;
2077
2078   my $guard = $self->result_source->schema->txn_scope_guard;
2079   $_->delete for $self->all;
2080   $guard->commit;
2081   return 1;
2082 }
2083
2084 =head2 populate
2085
2086 =over 4
2087
2088 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2089
2090 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2091
2092 =back
2093
2094 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2095 arrayrefs.
2096
2097 =over
2098
2099 =item NOTE
2100
2101 The context of this method call has an important effect on what is
2102 submitted to storage. In void context data is fed directly to fastpath
2103 insertion routines provided by the underlying storage (most often
2104 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2105 L<insert|DBIx::Class::Row/insert> calls on the
2106 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2107 augmentation of these methods provided by components. For example if you
2108 are using something like L<DBIx::Class::UUIDColumns> to create primary
2109 keys for you, you will find that your PKs are empty.  In this case you
2110 will have to explicitly force scalar or list context in order to create
2111 those values.
2112
2113 =back
2114
2115 In non-void (scalar or list) context, this method is simply a wrapper
2116 for L</create>. Depending on list or scalar context either a list of
2117 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2118 containing these objects is returned.
2119
2120 When supplying data in "arrayref of arrayrefs" invocation style, the
2121 first element should be a list of column names and each subsequent
2122 element should be a data value in the earlier specified column order.
2123 For example:
2124
2125   $Arstist_rs->populate([
2126     [ qw( artistid name ) ],
2127     [ 100, 'A Formally Unknown Singer' ],
2128     [ 101, 'A singer that jumped the shark two albums ago' ],
2129     [ 102, 'An actually cool singer' ],
2130   ]);
2131
2132 For the arrayref of hashrefs style each hashref should be a structure
2133 suitable for passing to L</create>. Multi-create is also permitted with
2134 this syntax.
2135
2136   $schema->resultset("Artist")->populate([
2137      { artistid => 4, name => 'Manufactured Crap', cds => [
2138         { title => 'My First CD', year => 2006 },
2139         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2140       ],
2141      },
2142      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2143         { title => 'My parents sold me to a record company', year => 2005 },
2144         { title => 'Why Am I So Ugly?', year => 2006 },
2145         { title => 'I Got Surgery and am now Popular', year => 2007 }
2146       ],
2147      },
2148   ]);
2149
2150 If you attempt a void-context multi-create as in the example above (each
2151 Artist also has the related list of CDs), and B<do not> supply the
2152 necessary autoinc foreign key information, this method will proxy to the
2153 less efficient L</create>, and then throw the Result objects away. In this
2154 case there are obviously no benefits to using this method over L</create>.
2155
2156 =cut
2157
2158 sub populate {
2159   my $self = shift;
2160
2161   # cruft placed in standalone method
2162   my $data = $self->_normalize_populate_args(@_);
2163
2164   return unless @$data;
2165
2166   if(defined wantarray) {
2167     my @created = map { $self->create($_) } @$data;
2168     return wantarray ? @created : \@created;
2169   }
2170   else {
2171     my $first = $data->[0];
2172
2173     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2174     # it relationship data
2175     my (@rels, @columns);
2176     my $rsrc = $self->result_source;
2177     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2178     for (keys %$first) {
2179       my $ref = ref $first->{$_};
2180       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2181         ? push @rels, $_
2182         : push @columns, $_
2183       ;
2184     }
2185
2186     my @pks = $rsrc->primary_columns;
2187
2188     ## do the belongs_to relationships
2189     foreach my $index (0..$#$data) {
2190
2191       # delegate to create() for any dataset without primary keys with specified relationships
2192       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2193         for my $r (@rels) {
2194           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2195             my @ret = $self->populate($data);
2196             return;
2197           }
2198         }
2199       }
2200
2201       foreach my $rel (@rels) {
2202         next unless ref $data->[$index]->{$rel} eq "HASH";
2203         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2204         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2205         my $related = $result->result_source->_resolve_condition(
2206           $reverse_relinfo->{cond},
2207           $self,
2208           $result,
2209           $rel,
2210         );
2211
2212         delete $data->[$index]->{$rel};
2213         $data->[$index] = {%{$data->[$index]}, %$related};
2214
2215         push @columns, keys %$related if $index == 0;
2216       }
2217     }
2218
2219     ## inherit the data locked in the conditions of the resultset
2220     my ($rs_data) = $self->_merge_with_rscond({});
2221     delete @{$rs_data}{@columns};
2222
2223     ## do bulk insert on current row
2224     $rsrc->storage->insert_bulk(
2225       $rsrc,
2226       [@columns, keys %$rs_data],
2227       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2228     );
2229
2230     ## do the has_many relationships
2231     foreach my $item (@$data) {
2232
2233       my $main_row;
2234
2235       foreach my $rel (@rels) {
2236         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2237
2238         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2239
2240         my $child = $main_row->$rel;
2241
2242         my $related = $child->result_source->_resolve_condition(
2243           $rels->{$rel}{cond},
2244           $child,
2245           $main_row,
2246           $rel,
2247         );
2248
2249         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2250         my @populate = map { {%$_, %$related} } @rows_to_add;
2251
2252         $child->populate( \@populate );
2253       }
2254     }
2255   }
2256 }
2257
2258
2259 # populate() argumnets went over several incarnations
2260 # What we ultimately support is AoH
2261 sub _normalize_populate_args {
2262   my ($self, $arg) = @_;
2263
2264   if (ref $arg eq 'ARRAY') {
2265     if (!@$arg) {
2266       return [];
2267     }
2268     elsif (ref $arg->[0] eq 'HASH') {
2269       return $arg;
2270     }
2271     elsif (ref $arg->[0] eq 'ARRAY') {
2272       my @ret;
2273       my @colnames = @{$arg->[0]};
2274       foreach my $values (@{$arg}[1 .. $#$arg]) {
2275         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2276       }
2277       return \@ret;
2278     }
2279   }
2280
2281   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2282 }
2283
2284 =head2 pager
2285
2286 =over 4
2287
2288 =item Arguments: none
2289
2290 =item Return Value: L<$pager|Data::Page>
2291
2292 =back
2293
2294 Returns a L<Data::Page> object for the current resultset. Only makes
2295 sense for queries with a C<page> attribute.
2296
2297 To get the full count of entries for a paged resultset, call
2298 C<total_entries> on the L<Data::Page> object.
2299
2300 =cut
2301
2302 sub pager {
2303   my ($self) = @_;
2304
2305   return $self->{pager} if $self->{pager};
2306
2307   my $attrs = $self->{attrs};
2308   if (!defined $attrs->{page}) {
2309     $self->throw_exception("Can't create pager for non-paged rs");
2310   }
2311   elsif ($attrs->{page} <= 0) {
2312     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2313   }
2314   $attrs->{rows} ||= 10;
2315
2316   # throw away the paging flags and re-run the count (possibly
2317   # with a subselect) to get the real total count
2318   my $count_attrs = { %$attrs };
2319   delete @{$count_attrs}{qw/rows offset page pager/};
2320
2321   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2322
2323   require DBIx::Class::ResultSet::Pager;
2324   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2325     sub { $total_rs->count },  #lazy-get the total
2326     $attrs->{rows},
2327     $self->{attrs}{page},
2328   );
2329 }
2330
2331 =head2 page
2332
2333 =over 4
2334
2335 =item Arguments: $page_number
2336
2337 =item Return Value: L<$resultset|/search>
2338
2339 =back
2340
2341 Returns a resultset for the $page_number page of the resultset on which page
2342 is called, where each page contains a number of rows equal to the 'rows'
2343 attribute set on the resultset (10 by default).
2344
2345 =cut
2346
2347 sub page {
2348   my ($self, $page) = @_;
2349   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2350 }
2351
2352 =head2 new_result
2353
2354 =over 4
2355
2356 =item Arguments: \%col_data
2357
2358 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2359
2360 =back
2361
2362 Creates a new result object in the resultset's result class and returns
2363 it. The row is not inserted into the database at this point, call
2364 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2365 will tell you whether the result object has been inserted or not.
2366
2367 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2368
2369 =cut
2370
2371 sub new_result {
2372   my ($self, $values) = @_;
2373
2374   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2375     if @_ > 2;
2376
2377   $self->throw_exception( "new_result expects a hashref" )
2378     unless (ref $values eq 'HASH');
2379
2380   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2381
2382   my %new = (
2383     %$merged_cond,
2384     @$cols_from_relations
2385       ? (-cols_from_relations => $cols_from_relations)
2386       : (),
2387     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2388   );
2389
2390   return $self->result_class->new(\%new);
2391 }
2392
2393 # _merge_with_rscond
2394 #
2395 # Takes a simple hash of K/V data and returns its copy merged with the
2396 # condition already present on the resultset. Additionally returns an
2397 # arrayref of value/condition names, which were inferred from related
2398 # objects (this is needed for in-memory related objects)
2399 sub _merge_with_rscond {
2400   my ($self, $data) = @_;
2401
2402   my (%new_data, @cols_from_relations);
2403
2404   my $alias = $self->{attrs}{alias};
2405
2406   if (! defined $self->{cond}) {
2407     # just massage $data below
2408   }
2409   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2410     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2411     @cols_from_relations = keys %new_data;
2412   }
2413   elsif (ref $self->{cond} ne 'HASH') {
2414     $self->throw_exception(
2415       "Can't abstract implicit construct, resultset condition not a hash"
2416     );
2417   }
2418   else {
2419     # precendence must be given to passed values over values inherited from
2420     # the cond, so the order here is important.
2421     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2422     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2423
2424     while ( my($col, $value) = each %implied ) {
2425       my $vref = ref $value;
2426       if (
2427         $vref eq 'HASH'
2428           and
2429         keys(%$value) == 1
2430           and
2431         (keys %$value)[0] eq '='
2432       ) {
2433         $new_data{$col} = $value->{'='};
2434       }
2435       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2436         $new_data{$col} = $value;
2437       }
2438     }
2439   }
2440
2441   %new_data = (
2442     %new_data,
2443     %{ $self->_remove_alias($data, $alias) },
2444   );
2445
2446   return (\%new_data, \@cols_from_relations);
2447 }
2448
2449 # _has_resolved_attr
2450 #
2451 # determines if the resultset defines at least one
2452 # of the attributes supplied
2453 #
2454 # used to determine if a subquery is neccessary
2455 #
2456 # supports some virtual attributes:
2457 #   -join
2458 #     This will scan for any joins being present on the resultset.
2459 #     It is not a mere key-search but a deep inspection of {from}
2460 #
2461
2462 sub _has_resolved_attr {
2463   my ($self, @attr_names) = @_;
2464
2465   my $attrs = $self->_resolved_attrs;
2466
2467   my %extra_checks;
2468
2469   for my $n (@attr_names) {
2470     if (grep { $n eq $_ } (qw/-join/) ) {
2471       $extra_checks{$n}++;
2472       next;
2473     }
2474
2475     my $attr =  $attrs->{$n};
2476
2477     next if not defined $attr;
2478
2479     if (ref $attr eq 'HASH') {
2480       return 1 if keys %$attr;
2481     }
2482     elsif (ref $attr eq 'ARRAY') {
2483       return 1 if @$attr;
2484     }
2485     else {
2486       return 1 if $attr;
2487     }
2488   }
2489
2490   # a resolved join is expressed as a multi-level from
2491   return 1 if (
2492     $extra_checks{-join}
2493       and
2494     ref $attrs->{from} eq 'ARRAY'
2495       and
2496     @{$attrs->{from}} > 1
2497   );
2498
2499   return 0;
2500 }
2501
2502 # _collapse_cond
2503 #
2504 # Recursively collapse the condition.
2505
2506 sub _collapse_cond {
2507   my ($self, $cond, $collapsed) = @_;
2508
2509   $collapsed ||= {};
2510
2511   if (ref $cond eq 'ARRAY') {
2512     foreach my $subcond (@$cond) {
2513       next unless ref $subcond;  # -or
2514       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2515     }
2516   }
2517   elsif (ref $cond eq 'HASH') {
2518     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2519       foreach my $subcond (@{$cond->{-and}}) {
2520         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2521       }
2522     }
2523     else {
2524       foreach my $col (keys %$cond) {
2525         my $value = $cond->{$col};
2526         $collapsed->{$col} = $value;
2527       }
2528     }
2529   }
2530
2531   return $collapsed;
2532 }
2533
2534 # _remove_alias
2535 #
2536 # Remove the specified alias from the specified query hash. A copy is made so
2537 # the original query is not modified.
2538
2539 sub _remove_alias {
2540   my ($self, $query, $alias) = @_;
2541
2542   my %orig = %{ $query || {} };
2543   my %unaliased;
2544
2545   foreach my $key (keys %orig) {
2546     if ($key !~ /\./) {
2547       $unaliased{$key} = $orig{$key};
2548       next;
2549     }
2550     $unaliased{$1} = $orig{$key}
2551       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2552   }
2553
2554   return \%unaliased;
2555 }
2556
2557 =head2 as_query
2558
2559 =over 4
2560
2561 =item Arguments: none
2562
2563 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2564
2565 =back
2566
2567 Returns the SQL query and bind vars associated with the invocant.
2568
2569 This is generally used as the RHS for a subquery.
2570
2571 =cut
2572
2573 sub as_query {
2574   my $self = shift;
2575
2576   my $attrs = { %{ $self->_resolved_attrs } };
2577
2578   # For future use:
2579   #
2580   # in list ctx:
2581   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2582   # $sql also has no wrapping parenthesis in list ctx
2583   #
2584   my $sqlbind = $self->result_source->storage
2585     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2586
2587   return $sqlbind;
2588 }
2589
2590 =head2 find_or_new
2591
2592 =over 4
2593
2594 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2595
2596 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2597
2598 =back
2599
2600   my $artist = $schema->resultset('Artist')->find_or_new(
2601     { artist => 'fred' }, { key => 'artists' });
2602
2603   $cd->cd_to_producer->find_or_new({ producer => $producer },
2604                                    { key => 'primary });
2605
2606 Find an existing record from this resultset using L</find>. if none exists,
2607 instantiate a new result object and return it. The object will not be saved
2608 into your storage until you call L<DBIx::Class::Row/insert> on it.
2609
2610 You most likely want this method when looking for existing rows using a unique
2611 constraint that is not the primary key, or looking for related rows.
2612
2613 If you want objects to be saved immediately, use L</find_or_create> instead.
2614
2615 B<Note>: Make sure to read the documentation of L</find> and understand the
2616 significance of the C<key> attribute, as its lack may skew your search, and
2617 subsequently result in spurious new objects.
2618
2619 B<Note>: Take care when using C<find_or_new> with a table having
2620 columns with default values that you intend to be automatically
2621 supplied by the database (e.g. an auto_increment primary key column).
2622 In normal usage, the value of such columns should NOT be included at
2623 all in the call to C<find_or_new>, even when set to C<undef>.
2624
2625 =cut
2626
2627 sub find_or_new {
2628   my $self     = shift;
2629   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2630   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2631   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2632     return $row;
2633   }
2634   return $self->new_result($hash);
2635 }
2636
2637 =head2 create
2638
2639 =over 4
2640
2641 =item Arguments: \%col_data
2642
2643 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2644
2645 =back
2646
2647 Attempt to create a single new row or a row with multiple related rows
2648 in the table represented by the resultset (and related tables). This
2649 will not check for duplicate rows before inserting, use
2650 L</find_or_create> to do that.
2651
2652 To create one row for this resultset, pass a hashref of key/value
2653 pairs representing the columns of the table and the values you wish to
2654 store. If the appropriate relationships are set up, foreign key fields
2655 can also be passed an object representing the foreign row, and the
2656 value will be set to its primary key.
2657
2658 To create related objects, pass a hashref of related-object column values
2659 B<keyed on the relationship name>. If the relationship is of type C<multi>
2660 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2661 The process will correctly identify columns holding foreign keys, and will
2662 transparently populate them from the keys of the corresponding relation.
2663 This can be applied recursively, and will work correctly for a structure
2664 with an arbitrary depth and width, as long as the relationships actually
2665 exists and the correct column data has been supplied.
2666
2667 Instead of hashrefs of plain related data (key/value pairs), you may
2668 also pass new or inserted objects. New objects (not inserted yet, see
2669 L</new_result>), will be inserted into their appropriate tables.
2670
2671 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2672
2673 Example of creating a new row.
2674
2675   $person_rs->create({
2676     name=>"Some Person",
2677     email=>"somebody@someplace.com"
2678   });
2679
2680 Example of creating a new row and also creating rows in a related C<has_many>
2681 or C<has_one> resultset.  Note Arrayref.
2682
2683   $artist_rs->create(
2684      { artistid => 4, name => 'Manufactured Crap', cds => [
2685         { title => 'My First CD', year => 2006 },
2686         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2687       ],
2688      },
2689   );
2690
2691 Example of creating a new row and also creating a row in a related
2692 C<belongs_to> resultset. Note Hashref.
2693
2694   $cd_rs->create({
2695     title=>"Music for Silly Walks",
2696     year=>2000,
2697     artist => {
2698       name=>"Silly Musician",
2699     }
2700   });
2701
2702 =over
2703
2704 =item WARNING
2705
2706 When subclassing ResultSet never attempt to override this method. Since
2707 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2708 lot of the internals simply never call it, so your override will be
2709 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2710 or L<DBIx::Class::Row/insert> depending on how early in the
2711 L</create> process you need to intervene. See also warning pertaining to
2712 L</new>.
2713
2714 =back
2715
2716 =cut
2717
2718 sub create {
2719   my ($self, $attrs) = @_;
2720   $self->throw_exception( "create needs a hashref" )
2721     unless ref $attrs eq 'HASH';
2722   return $self->new_result($attrs)->insert;
2723 }
2724
2725 =head2 find_or_create
2726
2727 =over 4
2728
2729 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2730
2731 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2732
2733 =back
2734
2735   $cd->cd_to_producer->find_or_create({ producer => $producer },
2736                                       { key => 'primary' });
2737
2738 Tries to find a record based on its primary key or unique constraints; if none
2739 is found, creates one and returns that instead.
2740
2741   my $cd = $schema->resultset('CD')->find_or_create({
2742     cdid   => 5,
2743     artist => 'Massive Attack',
2744     title  => 'Mezzanine',
2745     year   => 2005,
2746   });
2747
2748 Also takes an optional C<key> attribute, to search by a specific key or unique
2749 constraint. For example:
2750
2751   my $cd = $schema->resultset('CD')->find_or_create(
2752     {
2753       artist => 'Massive Attack',
2754       title  => 'Mezzanine',
2755     },
2756     { key => 'cd_artist_title' }
2757   );
2758
2759 B<Note>: Make sure to read the documentation of L</find> and understand the
2760 significance of the C<key> attribute, as its lack may skew your search, and
2761 subsequently result in spurious row creation.
2762
2763 B<Note>: Because find_or_create() reads from the database and then
2764 possibly inserts based on the result, this method is subject to a race
2765 condition. Another process could create a record in the table after
2766 the find has completed and before the create has started. To avoid
2767 this problem, use find_or_create() inside a transaction.
2768
2769 B<Note>: Take care when using C<find_or_create> with a table having
2770 columns with default values that you intend to be automatically
2771 supplied by the database (e.g. an auto_increment primary key column).
2772 In normal usage, the value of such columns should NOT be included at
2773 all in the call to C<find_or_create>, even when set to C<undef>.
2774
2775 See also L</find> and L</update_or_create>. For information on how to declare
2776 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2777
2778 If you need to know if an existing row was found or a new one created use
2779 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2780 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2781 database!
2782
2783   my $cd = $schema->resultset('CD')->find_or_new({
2784     cdid   => 5,
2785     artist => 'Massive Attack',
2786     title  => 'Mezzanine',
2787     year   => 2005,
2788   });
2789
2790   if( !$cd->in_storage ) {
2791       # do some stuff
2792       $cd->insert;
2793   }
2794
2795 =cut
2796
2797 sub find_or_create {
2798   my $self     = shift;
2799   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2800   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2801   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2802     return $row;
2803   }
2804   return $self->create($hash);
2805 }
2806
2807 =head2 update_or_create
2808
2809 =over 4
2810
2811 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2812
2813 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2814
2815 =back
2816
2817   $resultset->update_or_create({ col => $val, ... });
2818
2819 Like L</find_or_create>, but if a row is found it is immediately updated via
2820 C<< $found_row->update (\%col_data) >>.
2821
2822
2823 Takes an optional C<key> attribute to search on a specific unique constraint.
2824 For example:
2825
2826   # In your application
2827   my $cd = $schema->resultset('CD')->update_or_create(
2828     {
2829       artist => 'Massive Attack',
2830       title  => 'Mezzanine',
2831       year   => 1998,
2832     },
2833     { key => 'cd_artist_title' }
2834   );
2835
2836   $cd->cd_to_producer->update_or_create({
2837     producer => $producer,
2838     name => 'harry',
2839   }, {
2840     key => 'primary',
2841   });
2842
2843 B<Note>: Make sure to read the documentation of L</find> and understand the
2844 significance of the C<key> attribute, as its lack may skew your search, and
2845 subsequently result in spurious row creation.
2846
2847 B<Note>: Take care when using C<update_or_create> with a table having
2848 columns with default values that you intend to be automatically
2849 supplied by the database (e.g. an auto_increment primary key column).
2850 In normal usage, the value of such columns should NOT be included at
2851 all in the call to C<update_or_create>, even when set to C<undef>.
2852
2853 See also L</find> and L</find_or_create>. For information on how to declare
2854 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2855
2856 If you need to know if an existing row was updated or a new one created use
2857 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2858 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2859 database!
2860
2861 =cut
2862
2863 sub update_or_create {
2864   my $self = shift;
2865   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2866   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2867
2868   my $row = $self->find($cond, $attrs);
2869   if (defined $row) {
2870     $row->update($cond);
2871     return $row;
2872   }
2873
2874   return $self->create($cond);
2875 }
2876
2877 =head2 update_or_new
2878
2879 =over 4
2880
2881 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2882
2883 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2884
2885 =back
2886
2887   $resultset->update_or_new({ col => $val, ... });
2888
2889 Like L</find_or_new> but if a row is found it is immediately updated via
2890 C<< $found_row->update (\%col_data) >>.
2891
2892 For example:
2893
2894   # In your application
2895   my $cd = $schema->resultset('CD')->update_or_new(
2896     {
2897       artist => 'Massive Attack',
2898       title  => 'Mezzanine',
2899       year   => 1998,
2900     },
2901     { key => 'cd_artist_title' }
2902   );
2903
2904   if ($cd->in_storage) {
2905       # the cd was updated
2906   }
2907   else {
2908       # the cd is not yet in the database, let's insert it
2909       $cd->insert;
2910   }
2911
2912 B<Note>: Make sure to read the documentation of L</find> and understand the
2913 significance of the C<key> attribute, as its lack may skew your search, and
2914 subsequently result in spurious new objects.
2915
2916 B<Note>: Take care when using C<update_or_new> with a table having
2917 columns with default values that you intend to be automatically
2918 supplied by the database (e.g. an auto_increment primary key column).
2919 In normal usage, the value of such columns should NOT be included at
2920 all in the call to C<update_or_new>, even when set to C<undef>.
2921
2922 See also L</find>, L</find_or_create> and L</find_or_new>.
2923
2924 =cut
2925
2926 sub update_or_new {
2927     my $self  = shift;
2928     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2929     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2930
2931     my $row = $self->find( $cond, $attrs );
2932     if ( defined $row ) {
2933         $row->update($cond);
2934         return $row;
2935     }
2936
2937     return $self->new_result($cond);
2938 }
2939
2940 =head2 get_cache
2941
2942 =over 4
2943
2944 =item Arguments: none
2945
2946 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2947
2948 =back
2949
2950 Gets the contents of the cache for the resultset, if the cache is set.
2951
2952 The cache is populated either by using the L</prefetch> attribute to
2953 L</search> or by calling L</set_cache>.
2954
2955 =cut
2956
2957 sub get_cache {
2958   shift->{all_cache};
2959 }
2960
2961 =head2 set_cache
2962
2963 =over 4
2964
2965 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2966
2967 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2968
2969 =back
2970
2971 Sets the contents of the cache for the resultset. Expects an arrayref
2972 of objects of the same class as those produced by the resultset. Note that
2973 if the cache is set, the resultset will return the cached objects rather
2974 than re-querying the database even if the cache attr is not set.
2975
2976 The contents of the cache can also be populated by using the
2977 L</prefetch> attribute to L</search>.
2978
2979 =cut
2980
2981 sub set_cache {
2982   my ( $self, $data ) = @_;
2983   $self->throw_exception("set_cache requires an arrayref")
2984       if defined($data) && (ref $data ne 'ARRAY');
2985   $self->{all_cache} = $data;
2986 }
2987
2988 =head2 clear_cache
2989
2990 =over 4
2991
2992 =item Arguments: none
2993
2994 =item Return Value: undef
2995
2996 =back
2997
2998 Clears the cache for the resultset.
2999
3000 =cut
3001
3002 sub clear_cache {
3003   shift->set_cache(undef);
3004 }
3005
3006 =head2 is_paged
3007
3008 =over 4
3009
3010 =item Arguments: none
3011
3012 =item Return Value: true, if the resultset has been paginated
3013
3014 =back
3015
3016 =cut
3017
3018 sub is_paged {
3019   my ($self) = @_;
3020   return !!$self->{attrs}{page};
3021 }
3022
3023 =head2 is_ordered
3024
3025 =over 4
3026
3027 =item Arguments: none
3028
3029 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3030
3031 =back
3032
3033 =cut
3034
3035 sub is_ordered {
3036   my ($self) = @_;
3037   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3038 }
3039
3040 =head2 related_resultset
3041
3042 =over 4
3043
3044 =item Arguments: $rel_name
3045
3046 =item Return Value: L<$resultset|/search>
3047
3048 =back
3049
3050 Returns a related resultset for the supplied relationship name.
3051
3052   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3053
3054 =cut
3055
3056 sub related_resultset {
3057   my ($self, $rel) = @_;
3058
3059   return $self->{related_resultsets}{$rel} ||= do {
3060     my $rsrc = $self->result_source;
3061     my $rel_info = $rsrc->relationship_info($rel);
3062
3063     $self->throw_exception(
3064       "search_related: result source '" . $rsrc->source_name .
3065         "' has no such relationship $rel")
3066       unless $rel_info;
3067
3068     my $attrs = $self->_chain_relationship($rel);
3069
3070     my $join_count = $attrs->{seen_join}{$rel};
3071
3072     my $alias = $self->result_source->storage
3073         ->relname_to_table_alias($rel, $join_count);
3074
3075     # since this is search_related, and we already slid the select window inwards
3076     # (the select/as attrs were deleted in the beginning), we need to flip all
3077     # left joins to inner, so we get the expected results
3078     # read the comment on top of the actual function to see what this does
3079     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3080
3081
3082     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3083     delete @{$attrs}{qw(result_class alias)};
3084
3085     my $related_cache;
3086
3087     if (my $cache = $self->get_cache) {
3088       $related_cache = [ map
3089         { @{$_->related_resultset($rel)->get_cache||[]} }
3090         @$cache
3091       ];
3092     }
3093
3094     my $rel_source = $rsrc->related_source($rel);
3095
3096     my $new = do {
3097
3098       # The reason we do this now instead of passing the alias to the
3099       # search_rs below is that if you wrap/overload resultset on the
3100       # source you need to know what alias it's -going- to have for things
3101       # to work sanely (e.g. RestrictWithObject wants to be able to add
3102       # extra query restrictions, and these may need to be $alias.)
3103
3104       my $rel_attrs = $rel_source->resultset_attributes;
3105       local $rel_attrs->{alias} = $alias;
3106
3107       $rel_source->resultset
3108                  ->search_rs(
3109                      undef, {
3110                        %$attrs,
3111                        where => $attrs->{where},
3112                    });
3113     };
3114     $new->set_cache($related_cache) if $related_cache;
3115     $new;
3116   };
3117 }
3118
3119 =head2 current_source_alias
3120
3121 =over 4
3122
3123 =item Arguments: none
3124
3125 =item Return Value: $source_alias
3126
3127 =back
3128
3129 Returns the current table alias for the result source this resultset is built
3130 on, that will be used in the SQL query. Usually it is C<me>.
3131
3132 Currently the source alias that refers to the result set returned by a
3133 L</search>/L</find> family method depends on how you got to the resultset: it's
3134 C<me> by default, but eg. L</search_related> aliases it to the related result
3135 source name (and keeps C<me> referring to the original result set). The long
3136 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3137 (and make this method unnecessary).
3138
3139 Thus it's currently necessary to use this method in predefined queries (see
3140 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3141 source alias of the current result set:
3142
3143   # in a result set class
3144   sub modified_by {
3145     my ($self, $user) = @_;
3146
3147     my $me = $self->current_source_alias;
3148
3149     return $self->search({
3150       "$me.modified" => $user->id,
3151     });
3152   }
3153
3154 =cut
3155
3156 sub current_source_alias {
3157   return (shift->{attrs} || {})->{alias} || 'me';
3158 }
3159
3160 =head2 as_subselect_rs
3161
3162 =over 4
3163
3164 =item Arguments: none
3165
3166 =item Return Value: L<$resultset|/search>
3167
3168 =back
3169
3170 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3171 "virtual view" by including it as a subquery within the from clause.  From this
3172 point on, any joined tables are inaccessible to ->search on the resultset (as if
3173 it were simply where-filtered without joins).  For example:
3174
3175  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3176
3177  # 'x' now pollutes the query namespace
3178
3179  # So the following works as expected
3180  my $ok_rs = $rs->search({'x.other' => 1});
3181
3182  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3183  # def) we look for one row with contradictory terms and join in another table
3184  # (aliased 'x_2') which we never use
3185  my $broken_rs = $rs->search({'x.name' => 'def'});
3186
3187  my $rs2 = $rs->as_subselect_rs;
3188
3189  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3190  my $not_joined_rs = $rs2->search({'x.other' => 1});
3191
3192  # works as expected: finds a 'table' row related to two x rows (abc and def)
3193  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3194
3195 Another example of when one might use this would be to select a subset of
3196 columns in a group by clause:
3197
3198  my $rs = $schema->resultset('Bar')->search(undef, {
3199    group_by => [qw{ id foo_id baz_id }],
3200  })->as_subselect_rs->search(undef, {
3201    columns => [qw{ id foo_id }]
3202  });
3203
3204 In the above example normally columns would have to be equal to the group by,
3205 but because we isolated the group by into a subselect the above works.
3206
3207 =cut
3208
3209 sub as_subselect_rs {
3210   my $self = shift;
3211
3212   my $attrs = $self->_resolved_attrs;
3213
3214   my $fresh_rs = (ref $self)->new (
3215     $self->result_source
3216   );
3217
3218   # these pieces will be locked in the subquery
3219   delete $fresh_rs->{cond};
3220   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3221
3222   return $fresh_rs->search( {}, {
3223     from => [{
3224       $attrs->{alias} => $self->as_query,
3225       -alias  => $attrs->{alias},
3226       -rsrc   => $self->result_source,
3227     }],
3228     alias => $attrs->{alias},
3229   });
3230 }
3231
3232 # This code is called by search_related, and makes sure there
3233 # is clear separation between the joins before, during, and
3234 # after the relationship. This information is needed later
3235 # in order to properly resolve prefetch aliases (any alias
3236 # with a relation_chain_depth less than the depth of the
3237 # current prefetch is not considered)
3238 #
3239 # The increments happen twice per join. An even number means a
3240 # relationship specified via a search_related, whereas an odd
3241 # number indicates a join/prefetch added via attributes
3242 #
3243 # Also this code will wrap the current resultset (the one we
3244 # chain to) in a subselect IFF it contains limiting attributes
3245 sub _chain_relationship {
3246   my ($self, $rel) = @_;
3247   my $source = $self->result_source;
3248   my $attrs = { %{$self->{attrs}||{}} };
3249
3250   # we need to take the prefetch the attrs into account before we
3251   # ->_resolve_join as otherwise they get lost - captainL
3252   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3253
3254   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3255
3256   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3257
3258   my $from;
3259   my @force_subq_attrs = qw/offset rows group_by having/;
3260
3261   if (
3262     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3263       ||
3264     $self->_has_resolved_attr (@force_subq_attrs)
3265   ) {
3266     # Nuke the prefetch (if any) before the new $rs attrs
3267     # are resolved (prefetch is useless - we are wrapping
3268     # a subquery anyway).
3269     my $rs_copy = $self->search;
3270     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3271       $rs_copy->{attrs}{join},
3272       delete $rs_copy->{attrs}{prefetch},
3273     );
3274
3275     $from = [{
3276       -rsrc   => $source,
3277       -alias  => $attrs->{alias},
3278       $attrs->{alias} => $rs_copy->as_query,
3279     }];
3280     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3281     $seen->{-relation_chain_depth} = 0;
3282   }
3283   elsif ($attrs->{from}) {  #shallow copy suffices
3284     $from = [ @{$attrs->{from}} ];
3285   }
3286   else {
3287     $from = [{
3288       -rsrc  => $source,
3289       -alias => $attrs->{alias},
3290       $attrs->{alias} => $source->from,
3291     }];
3292   }
3293
3294   my $jpath = ($seen->{-relation_chain_depth})
3295     ? $from->[-1][0]{-join_path}
3296     : [];
3297
3298   my @requested_joins = $source->_resolve_join(
3299     $join,
3300     $attrs->{alias},
3301     $seen,
3302     $jpath,
3303   );
3304
3305   push @$from, @requested_joins;
3306
3307   $seen->{-relation_chain_depth}++;
3308
3309   # if $self already had a join/prefetch specified on it, the requested
3310   # $rel might very well be already included. What we do in this case
3311   # is effectively a no-op (except that we bump up the chain_depth on
3312   # the join in question so we could tell it *is* the search_related)
3313   my $already_joined;
3314
3315   # we consider the last one thus reverse
3316   for my $j (reverse @requested_joins) {
3317     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3318     if ($rel eq $last_j) {
3319       $j->[0]{-relation_chain_depth}++;
3320       $already_joined++;
3321       last;
3322     }
3323   }
3324
3325   unless ($already_joined) {
3326     push @$from, $source->_resolve_join(
3327       $rel,
3328       $attrs->{alias},
3329       $seen,
3330       $jpath,
3331     );
3332   }
3333
3334   $seen->{-relation_chain_depth}++;
3335
3336   return {%$attrs, from => $from, seen_join => $seen};
3337 }
3338
3339 # FIXME - this needs to go live in Schema with the tree walker... or
3340 # something
3341 my $inflatemap_checker;
3342 $inflatemap_checker = sub {
3343   my ($rsrc, $relpaths) = @_;
3344
3345   my $rels;
3346
3347   for (@$relpaths) {
3348     $_ =~ /^ ( [^\.]+ ) \. (.+) $/x
3349       or next;
3350
3351     push @{$rels->{$1}}, $2;
3352   }
3353
3354   for my $rel (keys %$rels) {
3355     my $rel_rsrc = try {
3356       $rsrc->related_source ($rel)
3357     } catch {
3358     $rsrc->throw_exception(sprintf(
3359       "Inflation into non-existent relationship '%s' of '%s' requested, "
3360     . "check the inflation specification (columns/as) ending in '...%s.%s'",
3361       $rel,
3362       $rsrc->source_name,
3363       $rel,
3364       ( sort { length($a) <=> length ($b) } @{$rels->{$rel}} )[0],
3365     ))};
3366
3367     $inflatemap_checker->($rel_rsrc, $rels->{$rel});
3368   }
3369
3370   return;
3371 };
3372
3373 sub _resolved_attrs {
3374   my $self = shift;
3375   return $self->{_attrs} if $self->{_attrs};
3376
3377   my $attrs  = { %{ $self->{attrs} || {} } };
3378   my $source = $self->result_source;
3379   my $alias  = $attrs->{alias};
3380
3381   # default selection list
3382   $attrs->{columns} = [ $source->columns ]
3383     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3384
3385   # merge selectors together
3386   for (qw/columns select as/) {
3387     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3388       if $attrs->{$_} or $attrs->{"+$_"};
3389   }
3390
3391   # disassemble columns
3392   my (@sel, @as);
3393   if (my $cols = delete $attrs->{columns}) {
3394     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3395       if (ref $c eq 'HASH') {
3396         for my $as (sort keys %$c) {
3397           push @sel, $c->{$as};
3398           push @as, $as;
3399         }
3400       }
3401       else {
3402         push @sel, $c;
3403         push @as, $c;
3404       }
3405     }
3406   }
3407
3408   # when trying to weed off duplicates later do not go past this point -
3409   # everything added from here on is unbalanced "anyone's guess" stuff
3410   my $dedup_stop_idx = $#as;
3411
3412   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3413     if $attrs->{as};
3414   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3415     if $attrs->{select};
3416
3417   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3418   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3419
3420   # disqualify all $alias.col as-bits (inflate-map mandated)
3421   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3422
3423   # de-duplicate the result (remove *identical* select/as pairs)
3424   # and also die on duplicate {as} pointing to different {select}s
3425   # not using a c-style for as the condition is prone to shrinkage
3426   my $seen;
3427   my $i = 0;
3428   while ($i <= $dedup_stop_idx) {
3429     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3430       splice @sel, $i, 1;
3431       splice @as, $i, 1;
3432       $dedup_stop_idx--;
3433     }
3434     elsif ($seen->{$as[$i]}++) {
3435       $self->throw_exception(
3436         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3437       );
3438     }
3439     else {
3440       $i++;
3441     }
3442   }
3443
3444   # validate the user-supplied 'as' chain
3445   # folks get too confused by the (logical) exception message, need to
3446   # go to some lengths to clarify the text
3447   #
3448   # FIXME - this needs to go live in Schema with the tree walker... or
3449   # something
3450   $inflatemap_checker->($source, \@as);
3451
3452   $attrs->{select} = \@sel;
3453   $attrs->{as} = \@as;
3454
3455   $attrs->{from} ||= [{
3456     -rsrc   => $source,
3457     -alias  => $self->{attrs}{alias},
3458     $self->{attrs}{alias} => $source->from,
3459   }];
3460
3461   if ( $attrs->{join} || $attrs->{prefetch} ) {
3462
3463     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3464       if ref $attrs->{from} ne 'ARRAY';
3465
3466     my $join = (delete $attrs->{join}) || {};
3467
3468     if ( defined $attrs->{prefetch} ) {
3469       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3470     }
3471
3472     $attrs->{from} =    # have to copy here to avoid corrupting the original
3473       [
3474         @{ $attrs->{from} },
3475         $source->_resolve_join(
3476           $join,
3477           $alias,
3478           { %{ $attrs->{seen_join} || {} } },
3479           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3480             ? $attrs->{from}[-1][0]{-join_path}
3481             : []
3482           ,
3483         )
3484       ];
3485   }
3486
3487   if ( defined $attrs->{order_by} ) {
3488     $attrs->{order_by} = (
3489       ref( $attrs->{order_by} ) eq 'ARRAY'
3490       ? [ @{ $attrs->{order_by} } ]
3491       : [ $attrs->{order_by} || () ]
3492     );
3493   }
3494
3495   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3496     $attrs->{group_by} = [ $attrs->{group_by} ];
3497   }
3498
3499   # generate the distinct induced group_by early, as prefetch will be carried via a
3500   # subquery (since a group_by is present)
3501   if (delete $attrs->{distinct}) {
3502     if ($attrs->{group_by}) {
3503       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3504     }
3505     else {
3506       # distinct affects only the main selection part, not what prefetch may
3507       # add below.
3508       $attrs->{group_by} = $source->storage->_group_over_selection (
3509         $attrs->{from},
3510         $attrs->{select},
3511         $attrs->{order_by},
3512       );
3513     }
3514   }
3515
3516   # generate selections based on the prefetch helper
3517   my $prefetch;
3518   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3519     if defined $attrs->{prefetch};
3520
3521   if ($prefetch) {
3522
3523     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3524       if $attrs->{_dark_selector};
3525
3526     $attrs->{collapse} = 1;
3527
3528     # this is a separate structure (we don't look in {from} directly)
3529     # as the resolver needs to shift things off the lists to work
3530     # properly (identical-prefetches on different branches)
3531     my $join_map = {};
3532     if (ref $attrs->{from} eq 'ARRAY') {
3533
3534       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3535
3536       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3537         next unless $j->[0]{-alias};
3538         next unless $j->[0]{-join_path};
3539         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3540
3541         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3542
3543         my $p = $join_map;
3544         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3545         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3546       }
3547     }
3548
3549     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3550
3551     # we need to somehow mark which columns came from prefetch
3552     if (@prefetch) {
3553       my $sel_end = $#{$attrs->{select}};
3554       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3555     }
3556
3557     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3558     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3559   }
3560
3561   if ( ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3562     $attrs->{_single_resultclass_inflation} = 1;
3563     $attrs->{collapse} = 0;
3564   }
3565
3566   # run through the resulting joinstructure (starting from our current slot)
3567   # and unset collapse if proven unnesessary
3568   #
3569   # also while we are at it find out if the current root source has
3570   # been premultiplied by previous related_source chaining
3571   #
3572   # this allows to predict whether a root object with all other relation
3573   # data set to NULL is in fact unique
3574   if ($attrs->{collapse}) {
3575
3576     if (ref $attrs->{from} eq 'ARRAY') {
3577
3578       if (@{$attrs->{from}} <= 1) {
3579         # no joins - no collapse
3580         $attrs->{collapse} = 0;
3581       }
3582       else {
3583         # find where our table-spec starts
3584         my @fromlist = @{$attrs->{from}};
3585         while (@fromlist) {
3586           my $t = shift @fromlist;
3587
3588           my $is_multi;
3589           # me vs join from-spec distinction - a ref means non-root
3590           if (ref $t eq 'ARRAY') {
3591             $t = $t->[0];
3592             $is_multi ||= ! $t->{-is_single};
3593           }
3594           last if ($t->{-alias} && $t->{-alias} eq $alias);
3595           $attrs->{_main_source_premultiplied} ||= $is_multi;
3596         }
3597
3598         # no non-singles remaining, nor any premultiplication - nothing to collapse
3599         if (
3600           ! $attrs->{_main_source_premultiplied}
3601             and
3602           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3603         ) {
3604           $attrs->{collapse} = 0;
3605         }
3606       }
3607     }
3608
3609     else {
3610       # if we can not analyze the from - err on the side of safety
3611       $attrs->{_main_source_premultiplied} = 1;
3612     }
3613   }
3614
3615   # if both page and offset are specified, produce a combined offset
3616   # even though it doesn't make much sense, this is what pre 081xx has
3617   # been doing
3618   if (my $page = delete $attrs->{page}) {
3619     $attrs->{offset} =
3620       ($attrs->{rows} * ($page - 1))
3621             +
3622       ($attrs->{offset} || 0)
3623     ;
3624   }
3625
3626   return $self->{_attrs} = $attrs;
3627 }
3628
3629 sub _rollout_attr {
3630   my ($self, $attr) = @_;
3631
3632   if (ref $attr eq 'HASH') {
3633     return $self->_rollout_hash($attr);
3634   } elsif (ref $attr eq 'ARRAY') {
3635     return $self->_rollout_array($attr);
3636   } else {
3637     return [$attr];
3638   }
3639 }
3640
3641 sub _rollout_array {
3642   my ($self, $attr) = @_;
3643
3644   my @rolled_array;
3645   foreach my $element (@{$attr}) {
3646     if (ref $element eq 'HASH') {
3647       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3648     } elsif (ref $element eq 'ARRAY') {
3649       #  XXX - should probably recurse here
3650       push( @rolled_array, @{$self->_rollout_array($element)} );
3651     } else {
3652       push( @rolled_array, $element );
3653     }
3654   }
3655   return \@rolled_array;
3656 }
3657
3658 sub _rollout_hash {
3659   my ($self, $attr) = @_;
3660
3661   my @rolled_array;
3662   foreach my $key (keys %{$attr}) {
3663     push( @rolled_array, { $key => $attr->{$key} } );
3664   }
3665   return \@rolled_array;
3666 }
3667
3668 sub _calculate_score {
3669   my ($self, $a, $b) = @_;
3670
3671   if (defined $a xor defined $b) {
3672     return 0;
3673   }
3674   elsif (not defined $a) {
3675     return 1;
3676   }
3677
3678   if (ref $b eq 'HASH') {
3679     my ($b_key) = keys %{$b};
3680     if (ref $a eq 'HASH') {
3681       my ($a_key) = keys %{$a};
3682       if ($a_key eq $b_key) {
3683         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3684       } else {
3685         return 0;
3686       }
3687     } else {
3688       return ($a eq $b_key) ? 1 : 0;
3689     }
3690   } else {
3691     if (ref $a eq 'HASH') {
3692       my ($a_key) = keys %{$a};
3693       return ($b eq $a_key) ? 1 : 0;
3694     } else {
3695       return ($b eq $a) ? 1 : 0;
3696     }
3697   }
3698 }
3699
3700 sub _merge_joinpref_attr {
3701   my ($self, $orig, $import) = @_;
3702
3703   return $import unless defined($orig);
3704   return $orig unless defined($import);
3705
3706   $orig = $self->_rollout_attr($orig);
3707   $import = $self->_rollout_attr($import);
3708
3709   my $seen_keys;
3710   foreach my $import_element ( @{$import} ) {
3711     # find best candidate from $orig to merge $b_element into
3712     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3713     foreach my $orig_element ( @{$orig} ) {
3714       my $score = $self->_calculate_score( $orig_element, $import_element );
3715       if ($score > $best_candidate->{score}) {
3716         $best_candidate->{position} = $position;
3717         $best_candidate->{score} = $score;
3718       }
3719       $position++;
3720     }
3721     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3722     $import_key = '' if not defined $import_key;
3723
3724     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3725       push( @{$orig}, $import_element );
3726     } else {
3727       my $orig_best = $orig->[$best_candidate->{position}];
3728       # merge orig_best and b_element together and replace original with merged
3729       if (ref $orig_best ne 'HASH') {
3730         $orig->[$best_candidate->{position}] = $import_element;
3731       } elsif (ref $import_element eq 'HASH') {
3732         my ($key) = keys %{$orig_best};
3733         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3734       }
3735     }
3736     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3737   }
3738
3739   return @$orig ? $orig : ();
3740 }
3741
3742 {
3743   my $hm;
3744
3745   sub _merge_attr {
3746     $hm ||= do {
3747       require Hash::Merge;
3748       my $hm = Hash::Merge->new;
3749
3750       $hm->specify_behavior({
3751         SCALAR => {
3752           SCALAR => sub {
3753             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3754
3755             if ($defl xor $defr) {
3756               return [ $defl ? $_[0] : $_[1] ];
3757             }
3758             elsif (! $defl) {
3759               return [];
3760             }
3761             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3762               return [ $_[0] ];
3763             }
3764             else {
3765               return [$_[0], $_[1]];
3766             }
3767           },
3768           ARRAY => sub {
3769             return $_[1] if !defined $_[0];
3770             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3771             return [$_[0], @{$_[1]}]
3772           },
3773           HASH  => sub {
3774             return [] if !defined $_[0] and !keys %{$_[1]};
3775             return [ $_[1] ] if !defined $_[0];
3776             return [ $_[0] ] if !keys %{$_[1]};
3777             return [$_[0], $_[1]]
3778           },
3779         },
3780         ARRAY => {
3781           SCALAR => sub {
3782             return $_[0] if !defined $_[1];
3783             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3784             return [@{$_[0]}, $_[1]]
3785           },
3786           ARRAY => sub {
3787             my @ret = @{$_[0]} or return $_[1];
3788             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3789             my %idx = map { $_ => 1 } @ret;
3790             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3791             \@ret;
3792           },
3793           HASH => sub {
3794             return [ $_[1] ] if ! @{$_[0]};
3795             return $_[0] if !keys %{$_[1]};
3796             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3797             return [ @{$_[0]}, $_[1] ];
3798           },
3799         },
3800         HASH => {
3801           SCALAR => sub {
3802             return [] if !keys %{$_[0]} and !defined $_[1];
3803             return [ $_[0] ] if !defined $_[1];
3804             return [ $_[1] ] if !keys %{$_[0]};
3805             return [$_[0], $_[1]]
3806           },
3807           ARRAY => sub {
3808             return [] if !keys %{$_[0]} and !@{$_[1]};
3809             return [ $_[0] ] if !@{$_[1]};
3810             return $_[1] if !keys %{$_[0]};
3811             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3812             return [ $_[0], @{$_[1]} ];
3813           },
3814           HASH => sub {
3815             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3816             return [ $_[0] ] if !keys %{$_[1]};
3817             return [ $_[1] ] if !keys %{$_[0]};
3818             return [ $_[0] ] if $_[0] eq $_[1];
3819             return [ $_[0], $_[1] ];
3820           },
3821         }
3822       } => 'DBIC_RS_ATTR_MERGER');
3823       $hm;
3824     };
3825
3826     return $hm->merge ($_[1], $_[2]);
3827   }
3828 }
3829
3830 sub STORABLE_freeze {
3831   my ($self, $cloning) = @_;
3832   my $to_serialize = { %$self };
3833
3834   # A cursor in progress can't be serialized (and would make little sense anyway)
3835   # the parser can be regenerated (and can't be serialized)
3836   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3837
3838   # nor is it sensical to store a not-yet-fired-count pager
3839   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3840     delete $to_serialize->{pager};
3841   }
3842
3843   Storable::nfreeze($to_serialize);
3844 }
3845
3846 # need this hook for symmetry
3847 sub STORABLE_thaw {
3848   my ($self, $cloning, $serialized) = @_;
3849
3850   %$self = %{ Storable::thaw($serialized) };
3851
3852   $self;
3853 }
3854
3855
3856 =head2 throw_exception
3857
3858 See L<DBIx::Class::Schema/throw_exception> for details.
3859
3860 =cut
3861
3862 sub throw_exception {
3863   my $self=shift;
3864
3865   if (ref $self and my $rsrc = $self->result_source) {
3866     $rsrc->throw_exception(@_)
3867   }
3868   else {
3869     DBIx::Class::Exception->throw(@_);
3870   }
3871 }
3872
3873 # XXX: FIXME: Attributes docs need clearing up
3874
3875 =head1 ATTRIBUTES
3876
3877 Attributes are used to refine a ResultSet in various ways when
3878 searching for data. They can be passed to any method which takes an
3879 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3880 L</count>.
3881
3882 Default attributes can be set on the result class using
3883 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3884 the CAVEATS on that feature before using it!)
3885
3886 These are in no particular order:
3887
3888 =head2 order_by
3889
3890 =over 4
3891
3892 =item Value: ( $order_by | \@order_by | \%order_by )
3893
3894 =back
3895
3896 Which column(s) to order the results by.
3897
3898 [The full list of suitable values is documented in
3899 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3900 common options.]
3901
3902 If a single column name, or an arrayref of names is supplied, the
3903 argument is passed through directly to SQL. The hashref syntax allows
3904 for connection-agnostic specification of ordering direction:
3905
3906  For descending order:
3907
3908   order_by => { -desc => [qw/col1 col2 col3/] }
3909
3910  For explicit ascending order:
3911
3912   order_by => { -asc => 'col' }
3913
3914 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3915 supported, although you are strongly encouraged to use the hashref
3916 syntax as outlined above.
3917
3918 =head2 columns
3919
3920 =over 4
3921
3922 =item Value: \@columns
3923
3924 =back
3925
3926 Shortcut to request a particular set of columns to be retrieved. Each
3927 column spec may be a string (a table column name), or a hash (in which
3928 case the key is the C<as> value, and the value is used as the C<select>
3929 expression). Adds C<me.> onto the start of any column without a C<.> in
3930 it and sets C<select> from that, then auto-populates C<as> from
3931 C<select> as normal. (You may also use the C<cols> attribute, as in
3932 earlier versions of DBIC.)
3933
3934 Essentially C<columns> does the same as L</select> and L</as>.
3935
3936     columns => [ 'foo', { bar => 'baz' } ]
3937
3938 is the same as
3939
3940     select => [qw/foo baz/],
3941     as => [qw/foo bar/]
3942
3943 =head2 +columns
3944
3945 =over 4
3946
3947 =item Value: \@columns
3948
3949 =back
3950
3951 Indicates additional columns to be selected from storage. Works the same
3952 as L</columns> but adds columns to the selection. (You may also use the
3953 C<include_columns> attribute, as in earlier versions of DBIC). For
3954 example:-
3955
3956   $schema->resultset('CD')->search(undef, {
3957     '+columns' => ['artist.name'],
3958     join => ['artist']
3959   });
3960
3961 would return all CDs and include a 'name' column to the information
3962 passed to object inflation. Note that the 'artist' is the name of the
3963 column (or relationship) accessor, and 'name' is the name of the column
3964 accessor in the related table.
3965
3966 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3967 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3968 unary plus operator before it.
3969
3970 =head2 include_columns
3971
3972 =over 4
3973
3974 =item Value: \@columns
3975
3976 =back
3977
3978 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3979
3980 =head2 select
3981
3982 =over 4
3983
3984 =item Value: \@select_columns
3985
3986 =back
3987
3988 Indicates which columns should be selected from the storage. You can use
3989 column names, or in the case of RDBMS back ends, function or stored procedure
3990 names:
3991
3992   $rs = $schema->resultset('Employee')->search(undef, {
3993     select => [
3994       'name',
3995       { count => 'employeeid' },
3996       { max => { length => 'name' }, -as => 'longest_name' }
3997     ]
3998   });
3999
4000   # Equivalent SQL
4001   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4002
4003 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4004 use L</select>, to instruct DBIx::Class how to store the result of the column.
4005 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4006 identifier aliasing. You can however alias a function, so you can use it in
4007 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4008 attribute> supplied as shown in the example above.
4009
4010 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4011 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4012 unary plus operator before it.
4013
4014 =head2 +select
4015
4016 =over 4
4017
4018 Indicates additional columns to be selected from storage.  Works the same as
4019 L</select> but adds columns to the default selection, instead of specifying
4020 an explicit list.
4021
4022 =back
4023
4024 =head2 +as
4025
4026 =over 4
4027
4028 Indicates additional column names for those added via L</+select>. See L</as>.
4029
4030 =back
4031
4032 =head2 as
4033
4034 =over 4
4035
4036 =item Value: \@inflation_names
4037
4038 =back
4039
4040 Indicates column names for object inflation. That is L</as> indicates the
4041 slot name in which the column value will be stored within the
4042 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4043 identifier by the C<get_column> method (or via the object accessor B<if one
4044 with the same name already exists>) as shown below. The L</as> attribute has
4045 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4046
4047   $rs = $schema->resultset('Employee')->search(undef, {
4048     select => [
4049       'name',
4050       { count => 'employeeid' },
4051       { max => { length => 'name' }, -as => 'longest_name' }
4052     ],
4053     as => [qw/
4054       name
4055       employee_count
4056       max_name_length
4057     /],
4058   });
4059
4060 If the object against which the search is performed already has an accessor
4061 matching a column name specified in C<as>, the value can be retrieved using
4062 the accessor as normal:
4063
4064   my $name = $employee->name();
4065
4066 If on the other hand an accessor does not exist in the object, you need to
4067 use C<get_column> instead:
4068
4069   my $employee_count = $employee->get_column('employee_count');
4070
4071 You can create your own accessors if required - see
4072 L<DBIx::Class::Manual::Cookbook> for details.
4073
4074 =head2 join
4075
4076 =over 4
4077
4078 =item Value: ($rel_name | \@rel_names | \%rel_names)
4079
4080 =back
4081
4082 Contains a list of relationships that should be joined for this query.  For
4083 example:
4084
4085   # Get CDs by Nine Inch Nails
4086   my $rs = $schema->resultset('CD')->search(
4087     { 'artist.name' => 'Nine Inch Nails' },
4088     { join => 'artist' }
4089   );
4090
4091 Can also contain a hash reference to refer to the other relation's relations.
4092 For example:
4093
4094   package MyApp::Schema::Track;
4095   use base qw/DBIx::Class/;
4096   __PACKAGE__->table('track');
4097   __PACKAGE__->add_columns(qw/trackid cd position title/);
4098   __PACKAGE__->set_primary_key('trackid');
4099   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4100   1;
4101
4102   # In your application
4103   my $rs = $schema->resultset('Artist')->search(
4104     { 'track.title' => 'Teardrop' },
4105     {
4106       join     => { cd => 'track' },
4107       order_by => 'artist.name',
4108     }
4109   );
4110
4111 You need to use the relationship (not the table) name in  conditions,
4112 because they are aliased as such. The current table is aliased as "me", so
4113 you need to use me.column_name in order to avoid ambiguity. For example:
4114
4115   # Get CDs from 1984 with a 'Foo' track
4116   my $rs = $schema->resultset('CD')->search(
4117     {
4118       'me.year' => 1984,
4119       'tracks.name' => 'Foo'
4120     },
4121     { join => 'tracks' }
4122   );
4123
4124 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4125 similarly for a third time). For e.g.
4126
4127   my $rs = $schema->resultset('Artist')->search({
4128     'cds.title'   => 'Down to Earth',
4129     'cds_2.title' => 'Popular',
4130   }, {
4131     join => [ qw/cds cds/ ],
4132   });
4133
4134 will return a set of all artists that have both a cd with title 'Down
4135 to Earth' and a cd with title 'Popular'.
4136
4137 If you want to fetch related objects from other tables as well, see C<prefetch>
4138 below.
4139
4140  NOTE: An internal join-chain pruner will discard certain joins while
4141  constructing the actual SQL query, as long as the joins in question do not
4142  affect the retrieved result. This for example includes 1:1 left joins
4143  that are not part of the restriction specification (WHERE/HAVING) nor are
4144  a part of the query selection.
4145
4146 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4147
4148 =head2 prefetch
4149
4150 =over 4
4151
4152 =item Value: ($rel_name | \@rel_names | \%rel_names)
4153
4154 =back
4155
4156 Contains one or more relationships that should be fetched along with
4157 the main query (when they are accessed afterwards the data will
4158 already be available, without extra queries to the database).  This is
4159 useful for when you know you will need the related objects, because it
4160 saves at least one query:
4161
4162   my $rs = $schema->resultset('Tag')->search(
4163     undef,
4164     {
4165       prefetch => {
4166         cd => 'artist'
4167       }
4168     }
4169   );
4170
4171 The initial search results in SQL like the following:
4172
4173   SELECT tag.*, cd.*, artist.* FROM tag
4174   JOIN cd ON tag.cd = cd.cdid
4175   JOIN artist ON cd.artist = artist.artistid
4176
4177 L<DBIx::Class> has no need to go back to the database when we access the
4178 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4179 case.
4180
4181 Simple prefetches will be joined automatically, so there is no need
4182 for a C<join> attribute in the above search.
4183
4184 L</prefetch> can be used with the any of the relationship types and
4185 multiple prefetches can be specified together. Below is a more complex
4186 example that prefetches a CD's artist, its liner notes (if present),
4187 the cover image, the tracks on that cd, and the guests on those
4188 tracks.
4189
4190  # Assuming:
4191  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4192  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4193  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4194  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4195
4196  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4197
4198  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4199
4200
4201  my $rs = $schema->resultset('CD')->search(
4202    undef,
4203    {
4204      prefetch => [
4205        { artist => 'record_label'},  # belongs_to => belongs_to
4206        'liner_note',                 # might_have
4207        'cover_image',                # has_one
4208        { tracks => 'guests' },       # has_many => has_many
4209      ]
4210    }
4211  );
4212
4213 This will produce SQL like the following:
4214
4215  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4216         tracks.*, guests.*
4217    FROM cd me
4218    JOIN artist artist
4219      ON artist.artistid = me.artistid
4220    JOIN record_label record_label
4221      ON record_label.labelid = artist.labelid
4222    LEFT JOIN track tracks
4223      ON tracks.cdid = me.cdid
4224    LEFT JOIN guest guests
4225      ON guests.trackid = track.trackid
4226    LEFT JOIN liner_notes liner_note
4227      ON liner_note.cdid = me.cdid
4228    JOIN cd_artwork cover_image
4229      ON cover_image.cdid = me.cdid
4230  ORDER BY tracks.cd
4231
4232 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4233 C<tracks>, and C<guests> of the CD will all be available through the
4234 relationship accessors without the need for additional queries to the
4235 database.
4236
4237 However, there is one caveat to be observed: it can be dangerous to
4238 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4239 relationship on a given level. e.g.:
4240
4241  my $rs = $schema->resultset('CD')->search(
4242    undef,
4243    {
4244      prefetch => [
4245        'tracks',                         # has_many
4246        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4247      ]
4248    }
4249  );
4250
4251 The collapser currently can't identify duplicate tuples for multiple
4252 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4253 result the second L<has_many|DBIx::Class::Relationship/has_many>
4254 relation could contain redundant objects.
4255
4256 =head3 Using L</prefetch> with L</join>
4257
4258 L</prefetch> implies a L</join> with the equivalent argument, and is
4259 properly merged with any existing L</join> specification. So the
4260 following:
4261
4262   my $rs = $schema->resultset('CD')->search(
4263    {'record_label.name' => 'Music Product Ltd.'},
4264    {
4265      join     => {artist => 'record_label'},
4266      prefetch => 'artist',
4267    }
4268  );
4269
4270 ... will work, searching on the record label's name, but only
4271 prefetching the C<artist>.
4272
4273 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4274
4275 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4276 prefetched relations.  So given:
4277
4278   my $rs = $schema->resultset('CD')->search(
4279    undef,
4280    {
4281      select   => ['cd.title'],
4282      as       => ['cd_title'],
4283      prefetch => 'artist',
4284    }
4285  );
4286
4287 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4288 becomes: C<'cd_title', 'artist.*'>.
4289
4290 =head3 CAVEATS
4291
4292 Prefetch does a lot of deep magic. As such, it may not behave exactly
4293 as you might expect.
4294
4295 =over 4
4296
4297 =item *
4298
4299 Prefetch uses the L</cache> to populate the prefetched relationships. This
4300 may or may not be what you want.
4301
4302 =item *
4303
4304 If you specify a condition on a prefetched relationship, ONLY those
4305 rows that match the prefetched condition will be fetched into that relationship.
4306 This means that adding prefetch to a search() B<may alter> what is returned by
4307 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4308
4309   my $artist_rs = $schema->resultset('Artist')->search({
4310       'cds.year' => 2008,
4311   }, {
4312       join => 'cds',
4313   });
4314
4315   my $count = $artist_rs->first->cds->count;
4316
4317   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4318
4319   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4320
4321   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4322
4323 that cmp_ok() may or may not pass depending on the datasets involved. This
4324 behavior may or may not survive the 0.09 transition.
4325
4326 =back
4327
4328 =head2 alias
4329
4330 =over 4
4331
4332 =item Value: $source_alias
4333
4334 =back
4335
4336 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4337 nested search queries (sub-SELECTs) might need specific aliases set to
4338 reference inner queries.  For example:
4339
4340    my $q = $rs
4341       ->related_resultset('CDs')
4342       ->related_resultset('Tracks')
4343       ->search({
4344          'track.id' => { -ident => 'none_search.id' },
4345       })
4346       ->as_query;
4347
4348    my $ids = $self->search({
4349       -not_exists => $q,
4350    }, {
4351       alias    => 'none_search',
4352       group_by => 'none_search.id',
4353    })->get_column('id')->as_query;
4354
4355    $self->search({ id => { -in => $ids } })
4356
4357 This attribute is directly tied to L</current_source_alias>.
4358
4359 =head2 page
4360
4361 =over 4
4362
4363 =item Value: $page
4364
4365 =back
4366
4367 Makes the resultset paged and specifies the page to retrieve. Effectively
4368 identical to creating a non-pages resultset and then calling ->page($page)
4369 on it.
4370
4371 If L</rows> attribute is not specified it defaults to 10 rows per page.
4372
4373 When you have a paged resultset, L</count> will only return the number
4374 of rows in the page. To get the total, use the L</pager> and call
4375 C<total_entries> on it.
4376
4377 =head2 rows
4378
4379 =over 4
4380
4381 =item Value: $rows
4382
4383 =back
4384
4385 Specifies the maximum number of rows for direct retrieval or the number of
4386 rows per page if the page attribute or method is used.
4387
4388 =head2 offset
4389
4390 =over 4
4391
4392 =item Value: $offset
4393
4394 =back
4395
4396 Specifies the (zero-based) row number for the  first row to be returned, or the
4397 of the first row of the first page if paging is used.
4398
4399 =head2 software_limit
4400
4401 =over 4
4402
4403 =item Value: (0 | 1)
4404
4405 =back
4406
4407 When combined with L</rows> and/or L</offset> the generated SQL will not
4408 include any limit dialect stanzas. Instead the entire result will be selected
4409 as if no limits were specified, and DBIC will perform the limit locally, by
4410 artificially advancing and finishing the resulting L</cursor>.
4411
4412 This is the recommended way of performing resultset limiting when no sane RDBMS
4413 implementation is available (e.g.
4414 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4415 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4416
4417 =head2 group_by
4418
4419 =over 4
4420
4421 =item Value: \@columns
4422
4423 =back
4424
4425 A arrayref of columns to group by. Can include columns of joined tables.
4426
4427   group_by => [qw/ column1 column2 ... /]
4428
4429 =head2 having
4430
4431 =over 4
4432
4433 =item Value: $condition
4434
4435 =back
4436
4437 HAVING is a select statement attribute that is applied between GROUP BY and
4438 ORDER BY. It is applied to the after the grouping calculations have been
4439 done.
4440
4441   having => { 'count_employee' => { '>=', 100 } }
4442
4443 or with an in-place function in which case literal SQL is required:
4444
4445   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4446
4447 =head2 distinct
4448
4449 =over 4
4450
4451 =item Value: (0 | 1)
4452
4453 =back
4454
4455 Set to 1 to group by all columns. If the resultset already has a group_by
4456 attribute, this setting is ignored and an appropriate warning is issued.
4457
4458 =head2 where
4459
4460 =over 4
4461
4462 Adds to the WHERE clause.
4463
4464   # only return rows WHERE deleted IS NULL for all searches
4465   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4466
4467 Can be overridden by passing C<< { where => undef } >> as an attribute
4468 to a resultset.
4469
4470 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4471
4472 =back
4473
4474 =head2 cache
4475
4476 Set to 1 to cache search results. This prevents extra SQL queries if you
4477 revisit rows in your ResultSet:
4478
4479   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4480
4481   while( my $artist = $resultset->next ) {
4482     ... do stuff ...
4483   }
4484
4485   $rs->first; # without cache, this would issue a query
4486
4487 By default, searches are not cached.
4488
4489 For more examples of using these attributes, see
4490 L<DBIx::Class::Manual::Cookbook>.
4491
4492 =head2 for
4493
4494 =over 4
4495
4496 =item Value: ( 'update' | 'shared' | \$scalar )
4497
4498 =back
4499
4500 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4501 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4502 query.
4503
4504 =head1 DBIC BIND VALUES
4505
4506 Because DBIC may need more information to bind values than just the column name
4507 and value itself, it uses a special format for both passing and receiving bind
4508 values.  Each bind value should be composed of an arrayref of
4509 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4510
4511 =over 4
4512
4513 =item dbd_attrs
4514
4515 If present (in any form), this is what is being passed directly to bind_param.
4516 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4517 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4518
4519 If this is specified, all other bind options described below are ignored.
4520
4521 =item sqlt_datatype
4522
4523 If present, this is used to infer the actual bind attribute by passing to
4524 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4525 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4526
4527 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4528 currently drivers are expected to "Do the Right Thing" when given a common
4529 datatype name.  (Not ideal, but that's what we got at this point.)
4530
4531 =item sqlt_size
4532
4533 Currently used to correctly allocate buffers for bind_param_inout().
4534 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4535 or to a sensible value based on the "data_type".
4536
4537 =item dbic_colname
4538
4539 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4540 explicitly specified they are never overriden).  Also used by some weird DBDs,
4541 where the column name should be available at bind_param time (e.g. Oracle).
4542
4543 =back
4544
4545 For backwards compatibility and convenience, the following shortcuts are
4546 supported:
4547
4548   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4549   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4550   [ undef,   $val ] === [ {}, $val ]
4551
4552 =head1 AUTHOR AND CONTRIBUTORS
4553
4554 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4555
4556 =head1 LICENSE
4557
4558 You may distribute this code under the same terms as Perl itself.
4559
4560 =cut
4561
4562 1;