lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'DBIx::Class';
   7
   8 use DBIx::Class::Carp;
   9 use DBIx::Class::ResultSetColumn;
  10 use DBIx::Class::ResultClass::HashRefInflator;
  11 use Scalar::Util qw( blessed reftype );
  12 use SQL::Abstract 'is_literal_value';
  13 use DBIx::Class::_Util qw(
  14   dbic_internal_try dbic_internal_catch dump_value emit_loud_diag
  15   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  16 );
  17 use DBIx::Class::SQLMaker::Util qw( normalize_sqla_condition extract_equality_conditions );
  18 use DBIx::Class::ResultSource::FromSpec::Util 'find_join_path_to_alias';
  19
  20 BEGIN {
  21   # De-duplication in _merge_attr() is disabled, but left in for reference
  22   # (the merger is used for other things that ought not to be de-duped)
  23   *__HM_DEDUP = sub () { 0 };
  24 }
  25
  26 use namespace::clean;
  27
  28 use overload
  29         '0+'     => "count",
  30         'bool'   => "_bool",
  31         fallback => 1;
  32
  33 # this is real - CDBICompat overrides it with insanity
  34 # yes, prototype won't matter, but that's for now ;)
  35 sub _bool () { 1 }
  36
  37 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  38
  39 =head1 NAME
  40
  41 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  42
  43 =head1 SYNOPSIS
  44
  45   my $users_rs = $schema->resultset('User');
  46   while( $user = $users_rs->next) {
  47     print $user->username;
  48   }
  49
  50   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  51   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  52
  53 =head1 DESCRIPTION
  54
  55 A ResultSet is an object which stores a set of conditions representing
  56 a query. It is the backbone of DBIx::Class (i.e. the really
  57 important/useful bit).
  58
  59 No SQL is executed on the database when a ResultSet is created, it
  60 just stores all the conditions needed to create the query.
  61
  62 A basic ResultSet representing the data of an entire table is returned
  63 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  64 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  65
  66   my $users_rs = $schema->resultset('User');
  67
  68 A new ResultSet is returned from calling L</search> on an existing
  69 ResultSet. The new one will contain all the conditions of the
  70 original, plus any new conditions added in the C<search> call.
  71
  72 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  73 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  74 represents.
  75
  76 The query that the ResultSet represents is B<only> executed against
  77 the database when these methods are called:
  78 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  79
  80 If a resultset is used in a numeric context it returns the L</count>.
  81 However, if it is used in a boolean context it is B<always> true.  So if
  82 you want to check if a resultset has any results, you must use C<if $rs
  83 != 0>.
  84
  85 =head1 EXAMPLES
  86
  87 =head2 Chaining resultsets
  88
  89 Let's say you've got a query that needs to be run to return some data
  90 to the user. But, you have an authorization system in place that
  91 prevents certain users from seeing certain information. So, you want
  92 to construct the basic query in one method, but add constraints to it in
  93 another.
  94
  95   sub get_data {
  96     my $self = shift;
  97     my $request = $self->get_request; # Get a request object somehow.
  98     my $schema = $self->result_source->schema;
  99
 100     my $cd_rs = $schema->resultset('CD')->search({
 101       title => $request->param('title'),
 102       year => $request->param('year'),
 103     });
 104
 105     $cd_rs = $self->apply_security_policy( $cd_rs );
 106
 107     return $cd_rs->all();
 108   }
 109
 110   sub apply_security_policy {
 111     my $self = shift;
 112     my ($rs) = @_;
 113
 114     return $rs->search({
 115       subversive => 0,
 116     });
 117   }
 118
 119 =head3 Resolving conditions and attributes
 120
 121 When a resultset is chained from another resultset (e.g.:
 122 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 123 and attributes with the same keys need resolving.
 124
 125 If any of L</columns>, L</select>, L</as> are present, they reset the
 126 original selection, and start the selection "clean".
 127
 128 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 129 are merged into the existing ones from the original resultset.
 130
 131 The L</where> and L</having> attributes, and any search conditions, are
 132 merged with an SQL C<AND> to the existing condition from the original
 133 resultset.
 134
 135 All other attributes are overridden by any new ones supplied in the
 136 search attributes.
 137
 138 =head2 Multiple queries
 139
 140 Since a resultset just defines a query, you can do all sorts of
 141 things with it with the same object.
 142
 143   # Don't hit the DB yet.
 144   my $cd_rs = $schema->resultset('CD')->search({
 145     title => 'something',
 146     year => 2009,
 147   });
 148
 149   # Each of these hits the DB individually.
 150   my $count = $cd_rs->count;
 151   my $most_recent = $cd_rs->get_column('date_released')->max();
 152   my @records = $cd_rs->all;
 153
 154 And it's not just limited to SELECT statements.
 155
 156   $cd_rs->delete();
 157
 158 This is even cooler:
 159
 160   $cd_rs->create({ artist => 'Fred' });
 161
 162 Which is the same as:
 163
 164   $schema->resultset('CD')->create({
 165     title => 'something',
 166     year => 2009,
 167     artist => 'Fred'
 168   });
 169
 170 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 171
 172 =head2 Custom ResultSet classes
 173
 174 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 175
 176   package MyApp::Schema::ResultSet::User;
 177
 178   use strict;
 179   use warnings;
 180
 181   use base 'DBIx::Class::ResultSet';
 182
 183   sub active {
 184     my $self = shift;
 185     $self->search({ $self->current_source_alias . '.active' => 1 });
 186   }
 187
 188   sub unverified {
 189     my $self = shift;
 190     $self->search({ $self->current_source_alias . '.verified' => 0 });
 191   }
 192
 193   sub created_n_days_ago {
 194     my ($self, $days_ago) = @_;
 195     $self->search({
 196       $self->current_source_alias . '.create_date' => {
 197         '<=',
 198       $self->result_source->schema->storage->datetime_parser->format_datetime(
 199         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 200       )}
 201     });
 202   }
 203
 204   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 205
 206   1;
 207
 208 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 209 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 210 L<ResulSet|DBIx::Class::ResultSet> classes.
 211
 212 =head3 ResultSet subclassing with Moose and similar constructor-providers
 213
 214 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 215 you may find it useful if your ResultSets contain a lot of business logic
 216 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 217 your code via roles.
 218
 219 In order to write custom ResultSet classes with L<Moo> you need to use the
 220 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 221 unusual signature of the L<constructor provided by DBIC
 222 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 223
 224   use Moo;
 225   extends 'DBIx::Class::ResultSet';
 226   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 227
 228   ...your code...
 229
 230   1;
 231
 232 If you want to build your custom ResultSet classes with L<Moose>, you need
 233 a similar, though a little more elaborate template in order to interface the
 234 inlining of the L<Moose>-provided
 235 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 236 with the DBIC one.
 237
 238   package MyApp::Schema::ResultSet::User;
 239
 240   use Moose;
 241   use MooseX::NonMoose;
 242   extends 'DBIx::Class::ResultSet';
 243
 244   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 245
 246   ...your code...
 247
 248   __PACKAGE__->meta->make_immutable;
 249
 250   1;
 251
 252 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 253 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 254 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 255 instead by doing:
 256
 257   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 258
 259 =head1 METHODS
 260
 261 =head2 new
 262
 263 =over 4
 264
 265 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 266
 267 =item Return Value: L<$resultset|/search>
 268
 269 =back
 270
 271 The resultset constructor. Takes a source object (usually a
 272 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 273 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 274 executed as needed by the other methods.
 275
 276 Generally you never construct a resultset manually. Instead you get one
 277 from e.g. a
 278 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 279 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 280 scalar context):
 281
 282   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 283
 284 =over
 285
 286 =item WARNING
 287
 288 If called on an object, proxies to L</new_result> instead, so
 289
 290   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 291
 292 will return a CD object, not a ResultSet, and is equivalent to:
 293
 294   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 295
 296 Please also keep in mind that many internals call L</new_result> directly,
 297 so overloading this method with the idea of intercepting new result object
 298 creation B<will not work>. See also warning pertaining to L</create>.
 299
 300 =back
 301
 302 =cut
 303
 304 sub new {
 305   my $class = shift;
 306
 307   if (ref $class) {
 308     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 309     return $class->new_result(@_);
 310   }
 311
 312   my ($source, $attrs) = @_;
 313   $source = $source->resolve
 314     if $source->isa('DBIx::Class::ResultSourceHandle');
 315
 316   $attrs = { %{$attrs||{}} };
 317   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 318
 319   if ($attrs->{page}) {
 320     $attrs->{rows} ||= 10;
 321   }
 322
 323   $attrs->{alias} ||= 'me';
 324
 325   my $self = bless {
 326     result_source => $source,
 327     cond => $attrs->{where},
 328     pager => undef,
 329     attrs => $attrs,
 330   }, $class;
 331
 332   # if there is a dark selector, this means we are already in a
 333   # chain and the cleanup/sanification was taken care of by
 334   # _search_rs already
 335   $self->_normalize_selection($attrs)
 336     unless $attrs->{_dark_selector};
 337
 338   $self->result_class(
 339     $attrs->{result_class} || $source->result_class
 340   );
 341
 342   $self;
 343 }
 344
 345 =head2 search
 346
 347 =over 4
 348
 349 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 350
 351 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 352
 353 =back
 354
 355   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 356   my $new_rs = $cd_rs->search({ year => 2005 });
 357
 358   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 359                  # year = 2005 OR year = 2004
 360
 361 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 362 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 363 To avoid that, use L</search_rs>.
 364
 365 If you need to pass in additional attributes but no additional condition,
 366 call it as C<search(undef, \%attrs)>.
 367
 368   # "SELECT name, artistid FROM $artist_table"
 369   my @all_artists = $schema->resultset('Artist')->search(undef, {
 370     columns => [qw/name artistid/],
 371   });
 372
 373 For a list of attributes that can be passed to C<search>, see
 374 L</ATTRIBUTES>. For more examples of using this function, see
 375 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 376 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 377 and its extension L<DBIx::Class::SQLMaker>.
 378
 379 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 380
 381 =head3 CAVEAT
 382
 383 Note that L</search> does not process/deflate any of the values passed in the
 384 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 385 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 386 manually that any value passed to this method will stringify to something the
 387 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 388 objects, for more info see:
 389 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 390
 391 =cut
 392
 393 sub search {
 394   my $self = shift;
 395   my $rs = $self->search_rs( @_ );
 396
 397   if (wantarray) {
 398     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 399     return $rs->all;
 400   }
 401   elsif (defined wantarray) {
 402     return $rs;
 403   }
 404   else {
 405     # we can be called by a relationship helper, which in
 406     # turn may be called in void context due to some braindead
 407     # overload or whatever else the user decided to be clever
 408     # at this particular day. Thus limit the exception to
 409     # external code calls only
 410     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 411       if (caller)[0] !~ /^\QDBIx::Class::/;
 412
 413     return ();
 414   }
 415 }
 416
 417 =head2 search_rs
 418
 419 =over 4
 420
 421 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 422
 423 =item Return Value: L<$resultset|/search>
 424
 425 =back
 426
 427 This method does the same exact thing as search() except it will
 428 always return a resultset, even in list context.
 429
 430 =cut
 431
 432 sub search_rs {
 433   my $self = shift;
 434
 435   my $rsrc = $self->result_source;
 436   my ($call_cond, $call_attrs);
 437
 438   # Special-case handling for (undef, undef) or (undef)
 439   # Note that (foo => undef) is valid deprecated syntax
 440   @_ = () if not scalar grep { defined $_ } @_;
 441
 442   # just a cond
 443   if (@_ == 1) {
 444     $call_cond = shift;
 445   }
 446   # fish out attrs in the ($condref, $attr) case
 447   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 448     ($call_cond, $call_attrs) = @_;
 449   }
 450   elsif (@_ % 2) {
 451     $self->throw_exception('Odd number of arguments to search')
 452   }
 453   # legacy search
 454   elsif (@_) {
 455     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 456       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 457
 458     for my $i (0 .. $#_) {
 459       next if $i % 2;
 460       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 461         if (! defined $_[$i] or length ref $_[$i] );
 462     }
 463
 464     $call_cond = { @_ };
 465   }
 466
 467   # see if we can keep the cache (no $rs changes)
 468   my $cache;
 469   my %safe = (alias => 1, cache => 1);
 470   if ( ! grep { !$safe{$_} } keys %$call_attrs and (
 471     ! defined $call_cond
 472       or
 473     ref $call_cond eq 'HASH' && ! keys %$call_cond
 474       or
 475     ref $call_cond eq 'ARRAY' && ! @$call_cond
 476   )) {
 477     $cache = $self->get_cache;
 478   }
 479
 480   my $old_attrs = { %{$self->{attrs}} };
 481   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 482
 483   my $new_attrs = { %$old_attrs };
 484
 485   # take care of call attrs (only if anything is changing)
 486   if ($call_attrs and keys %$call_attrs) {
 487
 488     # copy for _normalize_selection
 489     $call_attrs = { %$call_attrs };
 490
 491     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 492
 493     # reset the current selector list if new selectors are supplied
 494     delete @{$old_attrs}{(@selector_attrs, '_dark_selector')}
 495       if grep { exists $call_attrs->{$_} } qw(columns cols select as);
 496
 497     # Normalize the new selector list (operates on the passed-in attr structure)
 498     # Need to do it on every chain instead of only once on _resolved_attrs, in
 499     # order to allow detection of empty vs partial 'as'
 500     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 501       if $old_attrs->{_dark_selector};
 502     $self->_normalize_selection ($call_attrs);
 503
 504     # start with blind overwriting merge, exclude selector attrs
 505     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 506     delete @{$new_attrs}{@selector_attrs};
 507
 508     for (@selector_attrs) {
 509       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 510         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 511     }
 512
 513     # older deprecated name, use only if {columns} is not there
 514     if (my $c = delete $new_attrs->{cols}) {
 515       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 516       if ($new_attrs->{columns}) {
 517         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 518       }
 519       else {
 520         $new_attrs->{columns} = $c;
 521       }
 522     }
 523
 524
 525     # join/prefetch use their own crazy merging heuristics
 526     foreach my $key (qw/join prefetch/) {
 527       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 528         if exists $call_attrs->{$key};
 529     }
 530
 531     # stack binds together
 532     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 533   }
 534
 535
 536   for ($old_where, $call_cond) {
 537     if (defined $_) {
 538       $new_attrs->{where} = $self->_stack_cond (
 539         $_, $new_attrs->{where}
 540       );
 541     }
 542   }
 543
 544   if (defined $old_having) {
 545     $new_attrs->{having} = $self->_stack_cond (
 546       $old_having, $new_attrs->{having}
 547     )
 548   }
 549
 550   my $rs = (ref $self)->new($rsrc, $new_attrs);
 551
 552   $rs->set_cache($cache) if ($cache);
 553
 554   return $rs;
 555 }
 556
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => do {
 622                 local $Data::Dumper::Indent = 0;
 623                 dump_value $_;
 624               },
 625             };
 626             last SELECTOR;
 627           }
 628         }
 629       }
 630     }
 631     elsif (@$as < @$sel) {
 632       $self->throw_exception(
 633         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 634       );
 635     }
 636     elsif ($pref and $attrs->{_dark_selector}) {
 637       $self->throw_exception(
 638         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 639       );
 640     }
 641
 642
 643     # merge result
 644     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 645     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 646   }
 647 }
 648
 649 sub _stack_cond {
 650   my ($self, $left, $right) = @_;
 651
 652   (
 653     (ref $_ eq 'ARRAY' and !@$_)
 654       or
 655     (ref $_ eq 'HASH' and ! keys %$_)
 656   ) and $_ = undef for ($left, $right);
 657
 658   return(
 659     # either one of the two undef
 660     ( (defined $left) xor (defined $right) )  ? ( defined $left ? $left : $right )
 661
 662     # both undef
 663   : ( ! defined $left )                       ? undef
 664
 665                                               : { -and => [$left, $right] }
 666   );
 667 }
 668
 669 =head2 search_literal
 670
 671 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 672 should only be used in that context. C<search_literal> is a convenience
 673 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 674 want to ensure columns are bound correctly, use L</search>.
 675
 676 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 677 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 678 require C<search_literal>.
 679
 680 =over 4
 681
 682 =item Arguments: $sql_fragment, @standalone_bind_values
 683
 684 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 685
 686 =back
 687
 688   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 689   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 690
 691 Pass a literal chunk of SQL to be added to the conditional part of the
 692 resultset query.
 693
 694 Example of how to use C<search> instead of C<search_literal>
 695
 696   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 697   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 698
 699 =cut
 700
 701 sub search_literal {
 702   my ($self, $sql, @bind) = @_;
 703   my $attr;
 704   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 705     $attr = pop @bind;
 706   }
 707   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 708 }
 709
 710 =head2 find
 711
 712 =over 4
 713
 714 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 715
 716 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 717
 718 =back
 719
 720 Finds and returns a single row based on supplied criteria. Takes either a
 721 hashref with the same format as L</create> (including inference of foreign
 722 keys from related objects), or a list of primary key values in the same
 723 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 724 declaration on the L</result_source>.
 725
 726 In either case an attempt is made to combine conditions already existing on
 727 the resultset with the condition passed to this method.
 728
 729 To aid with preparing the correct query for the storage you may supply the
 730 C<key> attribute, which is the name of a
 731 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 732 unique constraint corresponding to the
 733 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 734 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 735 to construct a query that satisfies the named unique constraint fully (
 736 non-NULL values for each column member of the constraint) an exception is
 737 thrown.
 738
 739 If no C<key> is specified, the search is carried over all unique constraints
 740 which are fully defined by the available condition.
 741
 742 If no such constraint is found, C<find> currently defaults to a simple
 743 C<< search->(\%column_values) >> which may or may not do what you expect.
 744 Note that this fallback behavior may be deprecated in further versions. If
 745 you need to search with arbitrary conditions - use L</search>. If the query
 746 resulting from this fallback produces more than one row, a warning to the
 747 effect is issued, though only the first row is constructed and returned as
 748 C<$result_object>.
 749
 750 In addition to C<key>, L</find> recognizes and applies standard
 751 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 752
 753 Note that if you have extra concerns about the correctness of the resulting
 754 query you need to specify the C<key> attribute and supply the entire condition
 755 as an argument to find (since it is not always possible to perform the
 756 combination of the resultset condition with the supplied one, especially if
 757 the resultset condition contains literal sql).
 758
 759 For example, to find a row by its primary key:
 760
 761   my $cd = $schema->resultset('CD')->find(5);
 762
 763 You can also find a row by a specific unique constraint:
 764
 765   my $cd = $schema->resultset('CD')->find(
 766     {
 767       artist => 'Massive Attack',
 768       title  => 'Mezzanine',
 769     },
 770     { key => 'cd_artist_title' }
 771   );
 772
 773 See also L</find_or_create> and L</update_or_create>.
 774
 775 =cut
 776
 777 sub find {
 778   my $self = shift;
 779   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
 780
 781
 782   my $constraint_name;
 783   if (exists $attrs->{key}) {
 784     $constraint_name = defined $attrs->{key}
 785       ? $attrs->{key}
 786       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 787     ;
 788   }
 789
 790   # Parse out the condition from input
 791   my $call_cond;
 792
 793   my $rsrc = $self->result_source;
 794
 795   if (ref $_[0] eq 'HASH') {
 796     $call_cond = { %{$_[0]} };
 797   }
 798   else {
 799     # if only values are supplied we need to default to 'primary'
 800     $constraint_name = 'primary' unless defined $constraint_name;
 801
 802     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 803
 804     $self->throw_exception(
 805       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 806     ) unless @c_cols;
 807
 808     $self->throw_exception (
 809       'find() expects either a column/value hashref, or a list of values '
 810     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 811     ) unless @c_cols == @_;
 812
 813     @{$call_cond}{@c_cols} = @_;
 814   }
 815
 816   # process relationship data if any
 817   my $rel_list;
 818
 819   for my $key (keys %$call_cond) {
 820     if (
 821       length ref($call_cond->{$key})
 822         and
 823       ( $rel_list ||= { map { $_ => 1 } $rsrc->relationships } )
 824         ->{$key}
 825         and
 826       ! is_literal_value( $call_cond->{$key} )
 827         and
 828       # implicitly skip has_many's (likely MC), via the delete()
 829       ( ref( my $val = delete $call_cond->{$key} ) ne 'ARRAY' )
 830     ) {
 831
 832       # FIXME: it seems wrong that relationship conditions take precedence...?
 833       $call_cond = {
 834         %$call_cond,
 835
 836         %{ $rsrc->_resolve_relationship_condition(
 837           rel_name => $key,
 838           foreign_values => $val,
 839           infer_values_based_on => {},
 840
 841           self_alias => "\xFE", # irrelevant
 842           foreign_alias => "\xFF", # irrelevant
 843         )->{inferred_values} },
 844       };
 845     }
 846   }
 847
 848   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 849   my $final_cond;
 850   if (defined $constraint_name) {
 851     $final_cond = $self->_qualify_cond_columns (
 852
 853       $rsrc->_minimal_valueset_satisfying_constraint(
 854         constraint_name => $constraint_name,
 855         values => ($self->_merge_with_rscond($call_cond))[0],
 856         carp_on_nulls => 1,
 857       ),
 858
 859       $alias,
 860     );
 861   }
 862   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 863     # This means that we got here after a merger of relationship conditions
 864     # in ::Relationship::Base::search_related (the row method), and furthermore
 865     # the relationship is of the 'single' type. This means that the condition
 866     # provided by the relationship (already attached to $self) is sufficient,
 867     # as there can be only one row in the database that would satisfy the
 868     # relationship
 869   }
 870   else {
 871     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 872
 873     # no key was specified - fall down to heuristics mode:
 874     # run through all unique queries registered on the resultset, and
 875     # 'OR' all qualifying queries together
 876     #
 877     # always start from 'primary' if it exists at all
 878     for my $c_name ( sort {
 879         $a eq 'primary' ? -1
 880       : $b eq 'primary' ? 1
 881       : $a cmp $b
 882     } $rsrc->unique_constraint_names) {
 883
 884       next if $seen_column_combinations{
 885         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 886       }++;
 887
 888       dbic_internal_try {
 889         push @unique_queries, $self->_qualify_cond_columns(
 890           $rsrc->_minimal_valueset_satisfying_constraint(
 891             constraint_name => $c_name,
 892             values => ($self->_merge_with_rscond($call_cond))[0],
 893             columns_info => ($ci ||= $rsrc->columns_info),
 894           ),
 895           $alias
 896         );
 897       }
 898       dbic_internal_catch {
 899         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 900       };
 901     }
 902
 903     $final_cond =
 904         @unique_queries   ? \@unique_queries
 905       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 906       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 907     ;
 908   }
 909
 910   # Run the query, passing the result_class since it should propagate for find
 911   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 912   if ($rs->_resolved_attrs->{collapse}) {
 913     my $row = $rs->next;
 914     carp "Query returned more than one row" if $rs->next;
 915     return $row;
 916   }
 917   else {
 918     return $rs->single;
 919   }
 920 }
 921
 922 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 923 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 924 #
 925 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 926 # condition. It is provided for overrides until a saner way forward is devised
 927 #
 928 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 929 # the road. Please adjust your tests accordingly to catch this situation early
 930 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 931 #
 932 # The method will not be removed without an adequately complete replacement
 933 # for strict-mode enforcement
 934 sub _non_unique_find_fallback {
 935   my ($self, $cond, $attrs) = @_;
 936
 937   return $self->_qualify_cond_columns(
 938     $cond,
 939     exists $attrs->{alias}
 940       ? $attrs->{alias}
 941       : $self->{attrs}{alias}
 942   );
 943 }
 944
 945
 946 sub _qualify_cond_columns {
 947   my ($self, $cond, $alias) = @_;
 948
 949   my %aliased = %$cond;
 950   for (keys %aliased) {
 951     $aliased{"$alias.$_"} = delete $aliased{$_}
 952       if $_ !~ /\./;
 953   }
 954
 955   return \%aliased;
 956 }
 957
 958 sub _build_unique_cond {
 959   carp_unique sprintf
 960     '_build_unique_cond is a private method, and moreover is about to go '
 961   . 'away. Please contact the development team at %s if you believe you '
 962   . 'have a genuine use for this method, in order to discuss alternatives.',
 963     DBIx::Class::_ENV_::HELP_URL,
 964   ;
 965
 966   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 967
 968   $self->result_source->_minimal_valueset_satisfying_constraint(
 969     constraint_name => $constraint_name,
 970     values => $cond,
 971     carp_on_nulls => !$croak_on_null
 972   );
 973 }
 974
 975 =head2 search_related
 976
 977 =over 4
 978
 979 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 980
 981 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 982
 983 =back
 984
 985   $new_rs = $cd_rs->search_related('artist', {
 986     name => 'Emo-R-Us',
 987   });
 988
 989 Searches the specified relationship, optionally specifying a condition and
 990 attributes for matching records. See L</ATTRIBUTES> for more information.
 991
 992 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 993 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 994
 995 See also L</search_related_rs>.
 996
 997 =cut
 998
 999 sub search_related :DBIC_method_is_indirect_sugar {
1000   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1001   return shift->related_resultset(shift)->search(@_);
1002 }
1003
1004 =head2 search_related_rs
1005
1006 This method works exactly the same as search_related, except that
1007 it guarantees a resultset, even in list context.
1008
1009 =cut
1010
1011 sub search_related_rs :DBIC_method_is_indirect_sugar {
1012   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1013   return shift->related_resultset(shift)->search_rs(@_);
1014 }
1015
1016 =head2 cursor
1017
1018 =over 4
1019
1020 =item Arguments: none
1021
1022 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1023
1024 =back
1025
1026 Returns a storage-driven cursor to the given resultset. See
1027 L<DBIx::Class::Cursor> for more information.
1028
1029 =cut
1030
1031 sub cursor {
1032   my $self = shift;
1033
1034   return $self->{cursor} ||= do {
1035     my $attrs = $self->_resolved_attrs;
1036     $self->result_source->schema->storage->select(
1037       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1038     );
1039   };
1040 }
1041
1042 =head2 single
1043
1044 =over 4
1045
1046 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1047
1048 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1049
1050 =back
1051
1052   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1053
1054 Inflates the first result without creating a cursor if the resultset has
1055 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1056 of L</search>.
1057
1058 While this method can take an optional search condition (just like L</search>)
1059 being a fast-code-path it does not recognize search attributes. If you need to
1060 add extra joins or similar, call L</search> and then chain-call L</single> on the
1061 L<DBIx::Class::ResultSet> returned.
1062
1063 =over
1064
1065 =item B<Note>
1066
1067 As of 0.08100, this method enforces the assumption that the preceding
1068 query returns only one row. If more than one row is returned, you will receive
1069 a warning:
1070
1071   Query returned more than one row
1072
1073 In this case, you should be using L</next> or L</find> instead, or if you really
1074 know what you are doing, use the L</rows> attribute to explicitly limit the size
1075 of the resultset.
1076
1077 This method will also throw an exception if it is called on a resultset prefetching
1078 has_many, as such a prefetch implies fetching multiple rows from the database in
1079 order to assemble the resulting object.
1080
1081 =back
1082
1083 =cut
1084
1085 sub single {
1086   my ($self, $where) = @_;
1087   if(@_ > 2) {
1088       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1089   }
1090
1091   my $attrs = { %{$self->_resolved_attrs} };
1092
1093   $self->throw_exception(
1094     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1095   ) if $attrs->{collapse};
1096
1097   if ($where) {
1098     if (defined $attrs->{where}) {
1099       $attrs->{where} = {
1100         '-and' =>
1101             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1102                $where, delete $attrs->{where} ]
1103       };
1104     } else {
1105       $attrs->{where} = $where;
1106     }
1107   }
1108
1109   my $data = [ $self->result_source->schema->storage->select_single(
1110     $attrs->{from}, $attrs->{select},
1111     $attrs->{where}, $attrs
1112   )];
1113
1114   return undef unless @$data;
1115   $self->{_stashed_rows} = [ $data ];
1116   $self->_construct_results->[0];
1117 }
1118
1119 =head2 get_column
1120
1121 =over 4
1122
1123 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1124
1125 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1126
1127 =back
1128
1129   my $max_length = $rs->get_column('length')->max;
1130
1131 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1132
1133 =cut
1134
1135 sub get_column {
1136   DBIx::Class::ResultSetColumn->new(@_);
1137 }
1138
1139 =head2 search_like
1140
1141 =over 4
1142
1143 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1144
1145 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1146
1147 =back
1148
1149   # WHERE title LIKE '%blue%'
1150   $cd_rs = $rs->search_like({ title => '%blue%'});
1151
1152 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1153 that this is simply a convenience method retained for ex Class::DBI users.
1154 You most likely want to use L</search> with specific operators.
1155
1156 For more information, see L<DBIx::Class::Manual::Cookbook>.
1157
1158 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1159 instead. An example conversion is:
1160
1161   ->search_like({ foo => 'bar' });
1162
1163   # Becomes
1164
1165   ->search({ foo => { like => 'bar' } });
1166
1167 =cut
1168
1169 sub search_like {
1170   my $class = shift;
1171   carp_unique (
1172     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1173    .' Instead use ->search({ x => { -like => "y%" } })'
1174    .' (note the outer pair of {}s - they are important!)'
1175   );
1176   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
1177   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1178   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1179   return $class->search($query, { %$attrs });
1180 }
1181
1182 =head2 slice
1183
1184 =over 4
1185
1186 =item Arguments: $first, $last
1187
1188 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1189
1190 =back
1191
1192 Returns a resultset or object list representing a subset of elements from the
1193 resultset slice is called on. Indexes are from 0, i.e., to get the first
1194 three records, call:
1195
1196   my ($one, $two, $three) = $rs->slice(0, 2);
1197
1198 =cut
1199
1200 sub slice {
1201   my ($self, $min, $max) = @_;
1202   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1203   $attrs->{offset} = $self->{attrs}{offset} || 0;
1204   $attrs->{offset} += $min;
1205   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1206   return $self->search(undef, $attrs);
1207 }
1208
1209 =head2 next
1210
1211 =over 4
1212
1213 =item Arguments: none
1214
1215 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1216
1217 =back
1218
1219 Returns the next element in the resultset (C<undef> is there is none).
1220
1221 Can be used to efficiently iterate over records in the resultset:
1222
1223   my $rs = $schema->resultset('CD')->search;
1224   while (my $cd = $rs->next) {
1225     print $cd->title;
1226   }
1227
1228 Note that you need to store the resultset object, and call C<next> on it.
1229 Calling C<< resultset('Table')->next >> repeatedly will always return the
1230 first record from the resultset.
1231
1232 =cut
1233
1234 sub next {
1235   my ($self) = @_;
1236
1237   if (my $cache = $self->get_cache) {
1238     $self->{all_cache_position} ||= 0;
1239     return $cache->[$self->{all_cache_position}++];
1240   }
1241
1242   if ($self->{attrs}{cache}) {
1243     delete $self->{pager};
1244     $self->{all_cache_position} = 1;
1245     return ($self->all)[0];
1246   }
1247
1248   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1249
1250   $self->{_stashed_results} = $self->_construct_results
1251     or return undef;
1252
1253   return shift @{$self->{_stashed_results}};
1254 }
1255
1256 # Constructs as many results as it can in one pass while respecting
1257 # cursor laziness. Several modes of operation:
1258 #
1259 # * Always builds everything present in @{$self->{_stashed_rows}}
1260 # * If called with $fetch_all true - pulls everything off the cursor and
1261 #   builds all result structures (or objects) in one pass
1262 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1263 #   and if the resultset is ordered properly by the left side:
1264 #   * Fetches stuff off the cursor until the "master object" changes,
1265 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1266 #   OR
1267 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1268 #     was requested (there is no other way to collapse except for an
1269 #     eager cursor)
1270 # * If no collapse is requested - just get the next row, construct and
1271 #   return
1272 sub _construct_results {
1273   my ($self, $fetch_all) = @_;
1274
1275   my $rsrc = $self->result_source;
1276   my $attrs = $self->_resolved_attrs;
1277
1278   if (
1279     ! $fetch_all
1280       and
1281     ! $attrs->{order_by}
1282       and
1283     $attrs->{collapse}
1284       and
1285     my @pcols = $rsrc->primary_columns
1286   ) {
1287     # default order for collapsing unless the user asked for something
1288     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1289     $attrs->{_ordered_for_collapse} = 1;
1290     $attrs->{_order_is_artificial} = 1;
1291   }
1292
1293   # this will be used as both initial raw-row collector AND as a RV of
1294   # _construct_results. Not regrowing the array twice matters a lot...
1295   # a surprising amount actually
1296   my $rows = delete $self->{_stashed_rows};
1297
1298   my $cursor; # we may not need one at all
1299
1300   my $did_fetch_all = $fetch_all;
1301
1302   if ($fetch_all) {
1303     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1304     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1305   }
1306   elsif( $attrs->{collapse} ) {
1307
1308     # a cursor will need to be closed over in case of collapse
1309     $cursor = $self->cursor;
1310
1311     $attrs->{_ordered_for_collapse} = (
1312       (
1313         $attrs->{order_by}
1314           and
1315         $rsrc->schema
1316               ->storage
1317                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1318       ) ? 1 : 0
1319     ) unless defined $attrs->{_ordered_for_collapse};
1320
1321     if (! $attrs->{_ordered_for_collapse}) {
1322       $did_fetch_all = 1;
1323
1324       # instead of looping over ->next, use ->all in stealth mode
1325       # *without* calling a ->reset afterwards
1326       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1327       if (! $cursor->{_done}) {
1328         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1329         $cursor->{_done} = 1;
1330       }
1331     }
1332   }
1333
1334   if (! $did_fetch_all and ! @{$rows||[]} ) {
1335     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1336     $cursor ||= $self->cursor;
1337     if (scalar (my @r = $cursor->next) ) {
1338       $rows = [ \@r ];
1339     }
1340   }
1341
1342   return undef unless @{$rows||[]};
1343
1344   # sanity check - people are too clever for their own good
1345   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1346
1347     my $multiplied_selectors;
1348     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1349       if (
1350         $aliastypes->{multiplying}{$sel_alias}
1351           or
1352         $aliastypes->{premultiplied}{$sel_alias}
1353       ) {
1354         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1355       }
1356     }
1357
1358     for my $i (0 .. $#{$attrs->{as}} ) {
1359       my $sel = $attrs->{select}[$i];
1360
1361       if (ref $sel eq 'SCALAR') {
1362         $sel = $$sel;
1363       }
1364       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1365         $sel = $$sel->[0];
1366       }
1367
1368       $self->throw_exception(
1369         'Result collapse not possible - selection from a has_many source redirected to the main object'
1370       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1371     }
1372   }
1373
1374   # hotspot - skip the setter
1375   my $res_class = $self->_result_class;
1376
1377   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1378     $res_class->can ('inflate_result')
1379       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1380   };
1381
1382   my $infmap = $attrs->{as};
1383
1384   $self->{_result_inflator}{is_core_row} = ( (
1385     $inflator_cref
1386       ==
1387     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1388   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1389
1390   $self->{_result_inflator}{is_hri} = ( (
1391     ! $self->{_result_inflator}{is_core_row}
1392       and
1393     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1394   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1395
1396
1397   if ($attrs->{_simple_passthrough_construction}) {
1398     # construct a much simpler array->hash folder for the one-table HRI cases right here
1399     if ($self->{_result_inflator}{is_hri}) {
1400       for my $r (@$rows) {
1401         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1402       }
1403     }
1404     # FIXME SUBOPTIMAL this is a very very very hot spot
1405     # while rather optimal we can *still* do much better, by
1406     # building a smarter Row::inflate_result(), and
1407     # switch to feeding it data via a much leaner interface
1408     #
1409     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1410     # this particular resultset size
1411     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1412       for my $r (@$rows) {
1413         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1414       }
1415     }
1416     else {
1417       eval sprintf (
1418         ( $self->{_result_inflator}{is_core_row}
1419           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1420           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1421           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1422         ),
1423         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1424       ) . '; 1' or die;
1425     }
1426   }
1427   else {
1428     my $parser_type =
1429         $self->{_result_inflator}{is_hri}       ? 'hri'
1430       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1431       :                                           'classic_nonpruning'
1432     ;
1433
1434     unless( $self->{_row_parser}{$parser_type}{cref} ) {
1435
1436       # $args and $attrs to _mk_row_parser are separated to delineate what is
1437       # core collapser stuff and what is dbic $rs specific
1438       $self->{_row_parser}{$parser_type}{src} = $rsrc->_mk_row_parser({
1439         inflate_map => $infmap,
1440         collapse => $attrs->{collapse},
1441         premultiplied => $attrs->{_main_source_premultiplied},
1442         hri_style => $self->{_result_inflator}{is_hri},
1443         prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1444       }, $attrs);
1445
1446       $self->{_row_parser}{$parser_type}{cref} = do {
1447         package # hide form PAUSE
1448           DBIx::Class::__GENERATED_ROW_PARSER__;
1449
1450         eval $self->{_row_parser}{$parser_type}{src};
1451       } || die $@;
1452     }
1453
1454     # this needs to close over the *current* cursor, hence why it is not cached above
1455     my $next_cref = ($did_fetch_all or ! $attrs->{collapse})
1456       ? undef
1457       : sub {
1458         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1459         my @r = $cursor->next or return;
1460         \@r
1461       }
1462     ;
1463
1464     $self->{_row_parser}{$parser_type}{cref}->(
1465       $rows,
1466       $next_cref,
1467       ( $self->{_stashed_rows} = [] ),
1468       ( my $null_violations = {} ),
1469     );
1470
1471     $self->throw_exception(
1472       'Collapse aborted - the following columns are declared (or defaulted to) '
1473     . 'non-nullable within DBIC but NULLs were retrieved from storage: '
1474     . join( ', ', map { "'$infmap->[$_]'" } sort { $a <=> $b } keys %$null_violations )
1475     . ' within data row ' . dump_value({
1476       map {
1477         $infmap->[$_] =>
1478           ( ! defined $self->{_stashed_rows}[0][$_] or length $self->{_stashed_rows}[0][$_] < 50 )
1479             ? $self->{_stashed_rows}[0][$_]
1480             : substr( $self->{_stashed_rows}[0][$_], 0, 50 ) . '...'
1481       } 0 .. $#{$self->{_stashed_rows}[0]}
1482     })
1483     ) if keys %$null_violations;
1484
1485     # simple in-place substitution, does not regrow $rows
1486     if ($self->{_result_inflator}{is_core_row}) {
1487       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1488     }
1489     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1490     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1491       # the inflator may be a multiplier/reductor - put it in list ctx
1492       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1493     }
1494   }
1495
1496   # The @$rows check seems odd at first - why wouldn't we want to warn
1497   # regardless? The issue is things like find() etc, where the user
1498   # *knows* only one result will come back. In these cases the ->all
1499   # is not a pessimization, but rather something we actually want
1500   carp_unique(
1501     'Unable to properly collapse has_many results in iterator mode due '
1502   . 'to order criteria - performed an eager cursor slurp underneath. '
1503   . 'Consider using ->all() instead'
1504   ) if ( ! $fetch_all and @$rows > 1 );
1505
1506   return $rows;
1507 }
1508
1509 =head2 result_source
1510
1511 =over 4
1512
1513 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1514
1515 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1516
1517 =back
1518
1519 An accessor for the primary ResultSource object from which this ResultSet
1520 is derived.
1521
1522 =head2 result_class
1523
1524 =over 4
1525
1526 =item Arguments: $result_class?
1527
1528 =item Return Value: $result_class
1529
1530 =back
1531
1532 An accessor for the class to use when creating result objects. Defaults to
1533 C<< result_source->result_class >> - which in most cases is the name of the
1534 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1535
1536 Note that changing the result_class will also remove any components
1537 that were originally loaded in the source class via
1538 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1539 Any overloaded methods in the original source class will not run.
1540
1541 =cut
1542
1543 sub result_class {
1544   my ($self, $result_class) = @_;
1545   if ($result_class) {
1546
1547     # don't fire this for an object
1548     $self->ensure_class_loaded($result_class)
1549       unless ref($result_class);
1550
1551     if ($self->get_cache) {
1552       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1553     }
1554     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1555     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1556       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1557     }
1558
1559     $self->_result_class($result_class);
1560
1561     delete $self->{_result_inflator};
1562   }
1563   $self->_result_class;
1564 }
1565
1566 =head2 count
1567
1568 =over 4
1569
1570 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1571
1572 =item Return Value: $count
1573
1574 =back
1575
1576 Performs an SQL C<COUNT> with the same query as the resultset was built
1577 with to find the number of elements. Passing arguments is equivalent to
1578 C<< $rs->search ($cond, \%attrs)->count >>
1579
1580 =cut
1581
1582 sub count {
1583   my $self = shift;
1584   return $self->search(@_)->count if @_ and defined $_[0];
1585   return scalar @{ $self->get_cache } if $self->get_cache;
1586
1587   my $attrs = { %{ $self->_resolved_attrs } };
1588
1589   # this is a little optimization - it is faster to do the limit
1590   # adjustments in software, instead of a subquery
1591   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1592
1593   my $crs;
1594   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1595     $crs = $self->_count_subq_rs ($attrs);
1596   }
1597   else {
1598     $crs = $self->_count_rs ($attrs);
1599   }
1600   my $count = $crs->next;
1601
1602   $count -= $offset if $offset;
1603   $count = $rows if $rows and $rows < $count;
1604   $count = 0 if ($count < 0);
1605
1606   return $count;
1607 }
1608
1609 =head2 count_rs
1610
1611 =over 4
1612
1613 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1614
1615 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1616
1617 =back
1618
1619 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1620 This can be very handy for subqueries:
1621
1622   ->search( { amount => $some_rs->count_rs->as_query } )
1623
1624 As with regular resultsets the SQL query will be executed only after
1625 the resultset is accessed via L</next> or L</all>. That would return
1626 the same single value obtainable via L</count>.
1627
1628 =cut
1629
1630 sub count_rs {
1631   my $self = shift;
1632   return $self->search(@_)->count_rs if @_;
1633
1634   # this may look like a lack of abstraction (count() does about the same)
1635   # but in fact an _rs *must* use a subquery for the limits, as the
1636   # software based limiting can not be ported if this $rs is to be used
1637   # in a subquery itself (i.e. ->as_query)
1638   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1639     return $self->_count_subq_rs($self->{_attrs});
1640   }
1641   else {
1642     return $self->_count_rs($self->{_attrs});
1643   }
1644 }
1645
1646 #
1647 # returns a ResultSetColumn object tied to the count query
1648 #
1649 sub _count_rs {
1650   my ($self, $attrs) = @_;
1651
1652   my $rsrc = $self->result_source;
1653
1654   my $tmp_attrs = { %$attrs };
1655   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1656   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1657
1658   # overwrite the selector (supplied by the storage)
1659   $rsrc->resultset_class->new($rsrc, {
1660     %$tmp_attrs,
1661     select => $rsrc->schema->storage->_count_select ($rsrc, $attrs),
1662     as => 'count',
1663   })->get_column ('count');
1664 }
1665
1666 #
1667 # same as above but uses a subquery
1668 #
1669 sub _count_subq_rs {
1670   my ($self, $attrs) = @_;
1671
1672   my $rsrc = $self->result_source;
1673
1674   my $sub_attrs = { %$attrs };
1675   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1676   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1677
1678   # if we multi-prefetch we group_by something unique, as this is what we would
1679   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1680   if ( $attrs->{collapse}  ) {
1681     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1682       $rsrc->_identifying_column_set || $self->throw_exception(
1683         'Unable to construct a unique group_by criteria properly collapsing the '
1684       . 'has_many prefetch before count()'
1685       );
1686     } ]
1687   }
1688
1689   # Calculate subquery selector
1690   if (my $g = $sub_attrs->{group_by}) {
1691
1692     my $sql_maker = $rsrc->schema->storage->sql_maker;
1693
1694     # necessary as the group_by may refer to aliased functions
1695     my $sel_index;
1696     for my $sel (@{$attrs->{select}}) {
1697       $sel_index->{$sel->{-as}} = $sel
1698         if (ref $sel eq 'HASH' and $sel->{-as});
1699     }
1700
1701     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1702     # also look for named aggregates referred in the having clause
1703     # having often contains scalarrefs - thus parse it out entirely
1704     my @parts = @$g;
1705     if ($attrs->{having}) {
1706       local $sql_maker->{having_bind};
1707       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1708       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1709       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1710         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1711         # if we don't unset it we screw up retarded but unfortunately working
1712         # 'MAX(foo.bar)' => { '>', 3 }
1713         $sql_maker->{name_sep} = '';
1714       }
1715
1716       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1717
1718       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1719       my %seen_having;
1720
1721       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1722       # and if all fails for an utterly naive quoted scalar-with-function
1723       while ($having_sql =~ /
1724         $rquote $sep $lquote (.+?) $rquote
1725           |
1726         [\s,] \w+ \. (\w+) [\s,]
1727           |
1728         [\s,] $lquote (.+?) $rquote [\s,]
1729       /gx) {
1730         my $part = $1 || $2 || $3;  # one of them matched if we got here
1731         unless ($seen_having{$part}++) {
1732           push @parts, $part;
1733         }
1734       }
1735     }
1736
1737     for (@parts) {
1738       my $colpiece = $sel_index->{$_} || $_;
1739
1740       # unqualify join-based group_by's. Arcane but possible query
1741       # also horrible horrible hack to alias a column (not a func.)
1742       # (probably need to introduce SQLA syntax)
1743       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1744         my $as = $colpiece;
1745         $as =~ s/\./__/;
1746         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1747       }
1748       push @{$sub_attrs->{select}}, $colpiece;
1749     }
1750   }
1751   else {
1752     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1753     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1754   }
1755
1756   return $rsrc->resultset_class
1757                ->new ($rsrc, $sub_attrs)
1758                 ->as_subselect_rs
1759                  ->search ({}, { columns => { count => $rsrc->schema->storage->_count_select ($rsrc, $attrs) } })
1760                   ->get_column ('count');
1761 }
1762
1763
1764 =head2 count_literal
1765
1766 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1767 should only be used in that context. See L</search_literal> for further info.
1768
1769 =over 4
1770
1771 =item Arguments: $sql_fragment, @standalone_bind_values
1772
1773 =item Return Value: $count
1774
1775 =back
1776
1777 Counts the results in a literal query. Equivalent to calling L</search_literal>
1778 with the passed arguments, then L</count>.
1779
1780 =cut
1781
1782 sub count_literal :DBIC_method_is_indirect_sugar {
1783   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1784   shift->search_literal(@_)->count
1785 }
1786
1787 =head2 all
1788
1789 =over 4
1790
1791 =item Arguments: none
1792
1793 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1794
1795 =back
1796
1797 Returns all elements in the resultset.
1798
1799 =cut
1800
1801 sub all {
1802   my $self = shift;
1803   if(@_) {
1804     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1805   }
1806
1807   delete @{$self}{qw/_stashed_rows _stashed_results/};
1808
1809   if (my $c = $self->get_cache) {
1810     return @$c;
1811   }
1812
1813   $self->cursor->reset;
1814
1815   my $objs = $self->_construct_results('fetch_all') || [];
1816
1817   $self->set_cache($objs) if $self->{attrs}{cache};
1818
1819   return @$objs;
1820 }
1821
1822 =head2 reset
1823
1824 =over 4
1825
1826 =item Arguments: none
1827
1828 =item Return Value: $self
1829
1830 =back
1831
1832 Resets the resultset's cursor, so you can iterate through the elements again.
1833 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1834 another query.
1835
1836 =cut
1837
1838 sub reset {
1839   my ($self) = @_;
1840
1841   delete @{$self}{qw/_stashed_rows _stashed_results/};
1842   $self->{all_cache_position} = 0;
1843   $self->cursor->reset;
1844   return $self;
1845 }
1846
1847 =head2 first
1848
1849 =over 4
1850
1851 =item Arguments: none
1852
1853 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1854
1855 =back
1856
1857 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1858 an object for the first result (or C<undef> if the resultset is empty).
1859
1860 =cut
1861
1862 sub first :DBIC_method_is_indirect_sugar {
1863   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1864   return $_[0]->reset->next;
1865 }
1866
1867
1868 # _rs_update_delete
1869 #
1870 # Determines whether and what type of subquery is required for the $rs operation.
1871 # If grouping is necessary either supplies its own, or verifies the current one
1872 # After all is done delegates to the proper storage method.
1873
1874 sub _rs_update_delete {
1875   my ($self, $op, $values) = @_;
1876
1877   my $rsrc = $self->result_source;
1878   my $storage = $rsrc->schema->storage;
1879
1880   my $attrs = { %{$self->_resolved_attrs} };
1881
1882   my $join_classifications;
1883   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1884
1885   # do we need a subquery for any reason?
1886   my $needs_subq = (
1887     defined $existing_group_by
1888       or
1889     # if {from} is unparseable wrap a subq
1890     ref($attrs->{from}) ne 'ARRAY'
1891       or
1892     # limits call for a subq
1893     $self->_has_resolved_attr(qw/rows offset/)
1894   );
1895
1896   # simplify the joinmap, so we can further decide if a subq is necessary
1897   if (!$needs_subq and @{$attrs->{from}} > 1) {
1898
1899     ($attrs->{from}, $join_classifications) =
1900       $storage->_prune_unused_joins ($attrs);
1901
1902     # any non-pruneable non-local restricting joins imply subq
1903     $needs_subq = grep { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1904   }
1905
1906   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1907   $needs_subq ||= (
1908     (ref $attrs->{from}[0]) ne 'HASH'
1909       or
1910     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1911   );
1912
1913   my ($cond, $guard);
1914   # do we need anything like a subquery?
1915   if (! $needs_subq) {
1916     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1917     # a condition containing 'me' or other table prefixes will not work
1918     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1919     $cond = do {
1920       my $sqla = $rsrc->schema->storage->sql_maker;
1921       local $sqla->{_dequalify_idents} = 1;
1922       \[ $sqla->_recurse_where($self->{cond}) ];
1923     };
1924   }
1925   else {
1926     # we got this far - means it is time to wrap a subquery
1927     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1928       sprintf(
1929         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1930         $op,
1931         $rsrc->source_name,
1932       )
1933     );
1934
1935     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1936     delete $attrs->{$_} for qw/select as collapse/;
1937     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1938
1939     # this will be consumed by the pruner waaaaay down the stack
1940     $attrs->{_force_prune_multiplying_joins} = 1;
1941
1942     my $subrs = (ref $self)->new($rsrc, $attrs);
1943
1944     if (@$idcols == 1) {
1945       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1946     }
1947     elsif ($storage->_use_multicolumn_in) {
1948       # no syntax for calling this properly yet
1949       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1950       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1951         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1952         $subrs->as_query
1953       ),
1954     }
1955     else {
1956       # if all else fails - get all primary keys and operate over a ORed set
1957       # wrap in a transaction for consistency
1958       # this is where the group_by/multiplication starts to matter
1959       if (
1960         $existing_group_by
1961           or
1962         # we do not need to check pre-multipliers, since if the premulti is there, its
1963         # parent (who is multi) will be there too
1964         keys %{ $join_classifications->{multiplying} || {} }
1965       ) {
1966         # make sure if there is a supplied group_by it matches the columns compiled above
1967         # perfectly. Anything else can not be sanely executed on most databases so croak
1968         # right then and there
1969         if ($existing_group_by) {
1970           my @current_group_by = map
1971             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1972             @$existing_group_by
1973           ;
1974
1975           if (
1976             join ("\x00", sort @current_group_by)
1977               ne
1978             join ("\x00", sort @{$attrs->{columns}} )
1979           ) {
1980             $self->throw_exception (
1981               "You have just attempted a $op operation on a resultset which does group_by"
1982               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1983               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1984               . ' kind of queries. Please retry the operation with a modified group_by or'
1985               . ' without using one at all.'
1986             );
1987           }
1988         }
1989
1990         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1991       }
1992
1993       $guard = $storage->txn_scope_guard;
1994
1995       for my $row ($subrs->cursor->all) {
1996         push @$cond, { map
1997           { $idcols->[$_] => $row->[$_] }
1998           (0 .. $#$idcols)
1999         };
2000       }
2001     }
2002   }
2003
2004   my $res = $cond ? $storage->$op (
2005     $rsrc,
2006     $op eq 'update' ? $values : (),
2007     $cond,
2008   ) : '0E0';
2009
2010   $guard->commit if $guard;
2011
2012   return $res;
2013 }
2014
2015 =head2 update
2016
2017 =over 4
2018
2019 =item Arguments: \%values
2020
2021 =item Return Value: $underlying_storage_rv
2022
2023 =back
2024
2025 Sets the specified columns in the resultset to the supplied values in a
2026 single query. Note that this will not run any accessor/set_column/update
2027 triggers, nor will it update any result object instances derived from this
2028 resultset (this includes the contents of the L<resultset cache|/set_cache>
2029 if any). See L</update_all> if you need to execute any on-update
2030 triggers or cascades defined either by you or a
2031 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2032
2033 The return value is a pass through of what the underlying
2034 storage backend returned, and may vary. See L<DBI/execute> for the most
2035 common case.
2036
2037 =head3 CAVEAT
2038
2039 Note that L</update> does not process/deflate any of the values passed in.
2040 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2041 ensure manually that any value passed to this method will stringify to
2042 something the RDBMS knows how to deal with. A notable example is the
2043 handling of L<DateTime> objects, for more info see:
2044 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2045
2046 =cut
2047
2048 sub update {
2049   my ($self, $values) = @_;
2050   $self->throw_exception('Values for update must be a hash')
2051     unless ref $values eq 'HASH';
2052
2053   return $self->_rs_update_delete ('update', $values);
2054 }
2055
2056 =head2 update_all
2057
2058 =over 4
2059
2060 =item Arguments: \%values
2061
2062 =item Return Value: 1
2063
2064 =back
2065
2066 Fetches all objects and updates them one at a time via
2067 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2068 triggers, while L</update> will not.
2069
2070 =cut
2071
2072 sub update_all {
2073   my ($self, $values) = @_;
2074   $self->throw_exception('Values for update_all must be a hash')
2075     unless ref $values eq 'HASH';
2076
2077   my $guard = $self->result_source->schema->txn_scope_guard;
2078   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2079   $guard->commit;
2080   return 1;
2081 }
2082
2083 =head2 delete
2084
2085 =over 4
2086
2087 =item Arguments: none
2088
2089 =item Return Value: $underlying_storage_rv
2090
2091 =back
2092
2093 Deletes the rows matching this resultset in a single query. Note that this
2094 will not run any delete triggers, nor will it alter the
2095 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2096 derived from this resultset (this includes the contents of the
2097 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2098 execute any on-delete triggers or cascades defined either by you or a
2099 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2100
2101 The return value is a pass through of what the underlying storage backend
2102 returned, and may vary. See L<DBI/execute> for the most common case.
2103
2104 =cut
2105
2106 sub delete {
2107   my $self = shift;
2108   $self->throw_exception('delete does not accept any arguments')
2109     if @_;
2110
2111   return $self->_rs_update_delete ('delete');
2112 }
2113
2114 =head2 delete_all
2115
2116 =over 4
2117
2118 =item Arguments: none
2119
2120 =item Return Value: 1
2121
2122 =back
2123
2124 Fetches all objects and deletes them one at a time via
2125 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2126 triggers, while L</delete> will not.
2127
2128 =cut
2129
2130 sub delete_all {
2131   my $self = shift;
2132   $self->throw_exception('delete_all does not accept any arguments')
2133     if @_;
2134
2135   my $guard = $self->result_source->schema->txn_scope_guard;
2136   $_->delete for $self->all;
2137   $guard->commit;
2138   return 1;
2139 }
2140
2141 =head2 populate
2142
2143 =over 4
2144
2145 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2146
2147 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2148
2149 =back
2150
2151 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2152 arrayrefs.
2153
2154 =over
2155
2156 =item NOTE
2157
2158 The context of this method call has an important effect on what is
2159 submitted to storage. In void context data is fed directly to fastpath
2160 insertion routines provided by the underlying storage (most often
2161 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2162 L<insert|DBIx::Class::Row/insert> calls on the
2163 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2164 augmentation of these methods provided by components. For example if you
2165 are using something like L<DBIx::Class::UUIDColumns> to create primary
2166 keys for you, you will find that your PKs are empty.  In this case you
2167 will have to explicitly force scalar or list context in order to create
2168 those values.
2169
2170 =back
2171
2172 In non-void (scalar or list) context, this method is simply a wrapper
2173 for L</create>. Depending on list or scalar context either a list of
2174 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2175 containing these objects is returned.
2176
2177 When supplying data in "arrayref of arrayrefs" invocation style, the
2178 first element should be a list of column names and each subsequent
2179 element should be a data value in the earlier specified column order.
2180 For example:
2181
2182   $schema->resultset("Artist")->populate([
2183     [ qw( artistid name ) ],
2184     [ 100, 'A Formally Unknown Singer' ],
2185     [ 101, 'A singer that jumped the shark two albums ago' ],
2186     [ 102, 'An actually cool singer' ],
2187   ]);
2188
2189 For the arrayref of hashrefs style each hashref should be a structure
2190 suitable for passing to L</create>. Multi-create is also permitted with
2191 this syntax.
2192
2193   $schema->resultset("Artist")->populate([
2194      { artistid => 4, name => 'Manufactured Crap', cds => [
2195         { title => 'My First CD', year => 2006 },
2196         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2197       ],
2198      },
2199      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2200         { title => 'My parents sold me to a record company', year => 2005 },
2201         { title => 'Why Am I So Ugly?', year => 2006 },
2202         { title => 'I Got Surgery and am now Popular', year => 2007 }
2203       ],
2204      },
2205   ]);
2206
2207 If you attempt a void-context multi-create as in the example above (each
2208 Artist also has the related list of CDs), and B<do not> supply the
2209 necessary autoinc foreign key information, this method will proxy to the
2210 less efficient L</create>, and then throw the Result objects away. In this
2211 case there are obviously no benefits to using this method over L</create>.
2212
2213 =cut
2214
2215 sub populate {
2216   my $self = shift;
2217
2218   # this is naive and just a quick check
2219   # the types will need to be checked more thoroughly when the
2220   # multi-source populate gets added
2221   my $data = (
2222     ref $_[0] eq 'ARRAY'
2223       and
2224     ( @{$_[0]} or return )
2225       and
2226     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2227       and
2228     $_[0]
2229   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2230
2231   # FIXME - no cref handling
2232   # At this point assume either hashes or arrays
2233
2234   my $rsrc = $self->result_source;
2235   my $storage = $rsrc->schema->storage;
2236
2237   if(defined wantarray) {
2238     my (@results, $guard);
2239
2240     if (ref $data->[0] eq 'ARRAY') {
2241       # column names only, nothing to do
2242       return if @$data == 1;
2243
2244       $guard = $storage->txn_scope_guard
2245         if @$data > 2;
2246
2247       @results = map
2248         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2249         @{$data}[1 .. $#$data]
2250       ;
2251     }
2252     else {
2253
2254       $guard = $storage->txn_scope_guard
2255         if @$data > 1;
2256
2257       @results = map { $self->new_result($_)->insert } @$data;
2258     }
2259
2260     $guard->commit if $guard;
2261     return wantarray ? @results : \@results;
2262   }
2263
2264   # we have to deal with *possibly incomplete* related data
2265   # this means we have to walk the data structure twice
2266   # whether we want this or not
2267   # jnap, I hate you ;)
2268   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2269
2270   my ($colinfo, $colnames, $slices_with_rels);
2271   my $data_start = 0;
2272
2273   DATA_SLICE:
2274   for my $i (0 .. $#$data) {
2275
2276     my $current_slice_seen_rel_infos;
2277
2278 ### Determine/Supplement collists
2279 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2280     if( ref $data->[$i] eq 'ARRAY' ) {
2281
2282       # positional(!) explicit column list
2283       if ($i == 0) {
2284         # column names only, nothing to do
2285         return if @$data == 1;
2286
2287         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2288           for 0 .. $#{$data->[0]};
2289
2290         $data_start = 1;
2291
2292         next DATA_SLICE;
2293       }
2294       else {
2295         for (values %$colinfo) {
2296           if ($_->{is_rel} ||= (
2297             $rel_info->{$_->{name}}
2298               and
2299             (
2300               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2301                 or
2302               ref $data->[$i][$_->{pos}] eq 'HASH'
2303                 or
2304               (
2305                 defined blessed $data->[$i][$_->{pos}]
2306                   and
2307                 $data->[$i][$_->{pos}]->isa(
2308                   $DBIx::Class::ResultSource::__expected_result_class_isa
2309                     ||
2310                   emit_loud_diag(
2311                     confess => 1,
2312                     msg => 'Global $DBIx::Class::ResultSource::__expected_result_class_isa unexpectedly unset...'
2313                   )
2314                 )
2315               )
2316             )
2317               and
2318             1
2319           )) {
2320
2321             # moar sanity check... sigh
2322             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2323               if (
2324                 defined blessed $_
2325                   and
2326                 $_->isa(
2327                   $DBIx::Class::ResultSource::__expected_result_class_isa
2328                     ||
2329                   emit_loud_diag(
2330                     confess => 1,
2331                     msg => 'Global $DBIx::Class::ResultSource::__expected_result_class_isa unexpectedly unset...'
2332                   )
2333                 )
2334               ) {
2335                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2336                 return my $throwaway = $self->populate(@_);
2337               }
2338             }
2339
2340             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2341           }
2342         }
2343       }
2344
2345      if ($current_slice_seen_rel_infos) {
2346         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2347
2348         # this is needed further down to decide whether or not to fallback to create()
2349         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2350           for 0 .. $#$colnames;
2351       }
2352     }
2353     elsif( ref $data->[$i] eq 'HASH' ) {
2354
2355       for ( sort keys %{$data->[$i]} ) {
2356
2357         $colinfo->{$_} ||= do {
2358
2359           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2360             if $data_start; # it will be 0 on AoH, 1 on AoA
2361
2362           push @$colnames, $_;
2363
2364           # RV
2365           { pos => $#$colnames, name => $_ }
2366         };
2367
2368         if ($colinfo->{$_}{is_rel} ||= (
2369           $rel_info->{$_}
2370             and
2371           (
2372             ref $data->[$i]{$_} eq 'ARRAY'
2373               or
2374             ref $data->[$i]{$_} eq 'HASH'
2375               or
2376             (
2377               defined blessed $data->[$i]{$_}
2378                 and
2379               $data->[$i]{$_}->isa(
2380                 $DBIx::Class::ResultSource::__expected_result_class_isa
2381                   ||
2382                 emit_loud_diag(
2383                   confess => 1,
2384                   msg => 'Global $DBIx::Class::ResultSource::__expected_result_class_isa unexpectedly unset...'
2385                 )
2386               )
2387             )
2388           )
2389             and
2390           1
2391         )) {
2392
2393           # moar sanity check... sigh
2394           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2395             if (
2396               defined blessed $_
2397                 and
2398               $_->isa(
2399                 $DBIx::Class::ResultSource::__expected_result_class_isa
2400                   ||
2401                 emit_loud_diag(
2402                   confess => 1,
2403                   msg => 'Global $DBIx::Class::ResultSource::__expected_result_class_isa unexpectedly unset...'
2404                 )
2405               )
2406             ) {
2407               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2408               return my $throwaway = $self->populate(@_);
2409             }
2410           }
2411
2412           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2413         }
2414       }
2415
2416       if ($current_slice_seen_rel_infos) {
2417         push @$slices_with_rels, $data->[$i];
2418
2419         # this is needed further down to decide whether or not to fallback to create()
2420         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2421           for keys %{$data->[$i]};
2422       }
2423     }
2424     else {
2425       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2426     }
2427
2428     if ( grep
2429       { $_->{attrs}{is_depends_on} }
2430       @{ $current_slice_seen_rel_infos || [] }
2431     ) {
2432       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2433       return my $throwaway = $self->populate(@_);
2434     }
2435   }
2436
2437   if( $slices_with_rels ) {
2438
2439     # need to exclude the rel "columns"
2440     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2441
2442     # extra sanity check - ensure the main source is in fact identifiable
2443     # the localizing of nullability is insane, but oh well... the use-case is legit
2444     my $ci = $rsrc->columns_info($colnames);
2445
2446     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2447       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2448
2449     unless( $rsrc->_identifying_column_set($ci) ) {
2450       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2451       return my $throwaway = $self->populate(@_);
2452     }
2453   }
2454
2455 ### inherit the data locked in the conditions of the resultset
2456   my ($rs_data) = $self->_merge_with_rscond({});
2457   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2458
2459   # if anything left - decompose rs_data
2460   my $rs_data_vals;
2461   if (keys %$rs_data) {
2462      push @$rs_data_vals, $rs_data->{$_}
2463       for sort keys %$rs_data;
2464   }
2465
2466 ### start work
2467   my $guard;
2468   $guard = $storage->txn_scope_guard
2469     if $slices_with_rels;
2470
2471 ### main source data
2472   # FIXME - need to switch entirely to a coderef-based thing,
2473   # so that large sets aren't copied several times... I think
2474   $storage->_insert_bulk(
2475     $rsrc,
2476     [ @$colnames, sort keys %$rs_data ],
2477     [ map {
2478       ref $data->[$_] eq 'ARRAY'
2479       ? (
2480           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2481         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2482         :                     $data->[$_]
2483       )
2484       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2485     } $data_start .. $#$data ],
2486   );
2487
2488 ### do the children relationships
2489   if ( $slices_with_rels ) {
2490     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2491       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2492
2493     for my $sl (@$slices_with_rels) {
2494
2495       my ($main_proto, $main_proto_rs);
2496       for my $rel (@rels) {
2497         next unless defined $sl->{$rel};
2498
2499         $main_proto ||= {
2500           %$rs_data,
2501           (map { $_ => $sl->{$_} } @$colnames),
2502         };
2503
2504         unless (defined $colinfo->{$rel}{rs}) {
2505
2506           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2507
2508           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2509             rel_name => $rel,
2510             self_alias => "\xFE", # irrelevant
2511             foreign_alias => "\xFF", # irrelevant
2512           )->{identity_map} || {} } };
2513
2514         }
2515
2516         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2517           {
2518             $_ => { '=' =>
2519               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2520                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2521                  ->as_query
2522             }
2523           }
2524           keys %{$colinfo->{$rel}{fk_map}}
2525         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2526
2527         1;
2528       }
2529     }
2530   }
2531
2532   $guard->commit if $guard;
2533 }
2534
2535 =head2 pager
2536
2537 =over 4
2538
2539 =item Arguments: none
2540
2541 =item Return Value: L<$pager|Data::Page>
2542
2543 =back
2544
2545 Returns a L<Data::Page> object for the current resultset. Only makes
2546 sense for queries with a C<page> attribute.
2547
2548 To get the full count of entries for a paged resultset, call
2549 C<total_entries> on the L<Data::Page> object.
2550
2551 =cut
2552
2553 sub pager {
2554   my ($self) = @_;
2555
2556   return $self->{pager} if $self->{pager};
2557
2558   my $attrs = $self->{attrs};
2559   if (!defined $attrs->{page}) {
2560     $self->throw_exception("Can't create pager for non-paged rs");
2561   }
2562   elsif ($attrs->{page} <= 0) {
2563     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2564   }
2565   $attrs->{rows} ||= 10;
2566
2567   # throw away the paging flags and re-run the count (possibly
2568   # with a subselect) to get the real total count
2569   my $count_attrs = { %$attrs };
2570   delete @{$count_attrs}{qw/rows offset page pager/};
2571
2572   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2573
2574   require DBIx::Class::ResultSet::Pager;
2575   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2576     sub { $total_rs->count },  #lazy-get the total
2577     $attrs->{rows},
2578     $self->{attrs}{page},
2579   );
2580 }
2581
2582 =head2 page
2583
2584 =over 4
2585
2586 =item Arguments: $page_number
2587
2588 =item Return Value: L<$resultset|/search>
2589
2590 =back
2591
2592 Returns a resultset for the $page_number page of the resultset on which page
2593 is called, where each page contains a number of rows equal to the 'rows'
2594 attribute set on the resultset (10 by default).
2595
2596 =cut
2597
2598 sub page {
2599   my ($self, $page) = @_;
2600   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2601 }
2602
2603 =head2 new_result
2604
2605 =over 4
2606
2607 =item Arguments: \%col_data
2608
2609 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2610
2611 =back
2612
2613 Creates a new result object in the resultset's result class and returns
2614 it. The row is not inserted into the database at this point, call
2615 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2616 will tell you whether the result object has been inserted or not.
2617
2618 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2619
2620 =cut
2621
2622 sub new_result {
2623   my ($self, $values) = @_;
2624
2625   $self->throw_exception( "Result object instantiation requires a single hashref argument" )
2626     if @_ > 2 or ref $values ne 'HASH';
2627
2628   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2629
2630   my $new = $self->result_class->new({
2631     %$merged_cond,
2632     ( @$cols_from_relations
2633       ? (-cols_from_relations => $cols_from_relations)
2634       : ()
2635     ),
2636     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2637   });
2638
2639   if (
2640     reftype($new) eq 'HASH'
2641       and
2642     ! keys %$new
2643       and
2644     blessed($new)
2645   ) {
2646     carp_unique (sprintf (
2647       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2648       $self->result_class,
2649     ));
2650   }
2651
2652   $new;
2653 }
2654
2655 # _merge_with_rscond
2656 #
2657 # Takes a simple hash of K/V data and returns its copy merged with the
2658 # condition already present on the resultset. Additionally returns an
2659 # arrayref of value/condition names, which were inferred from related
2660 # objects (this is needed for in-memory related objects)
2661 sub _merge_with_rscond {
2662   my ($self, $data) = @_;
2663
2664   my ($implied_data, @cols_from_relations);
2665
2666   my $alias = $self->{attrs}{alias};
2667
2668   if (! defined $self->{cond}) {
2669     # just massage $data below
2670   }
2671   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2672     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2673     @cols_from_relations = keys %{ $implied_data || {} };
2674   }
2675   else {
2676     my $eqs = extract_equality_conditions( $self->{cond}, 'consider_nulls' );
2677     $implied_data = { map {
2678       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2679     } keys %$eqs };
2680   }
2681
2682   return (
2683     { map
2684       { %{ $self->_remove_alias($_, $alias) } }
2685       # precedence must be given to passed values over values inherited from
2686       # the cond, so the order here is important.
2687       ( $implied_data||(), $data)
2688     },
2689     \@cols_from_relations
2690   );
2691 }
2692
2693 # _has_resolved_attr
2694 #
2695 # determines if the resultset defines at least one
2696 # of the attributes supplied
2697 #
2698 # used to determine if a subquery is necessary
2699 #
2700 # supports some virtual attributes:
2701 #   -join
2702 #     This will scan for any joins being present on the resultset.
2703 #     It is not a mere key-search but a deep inspection of {from}
2704 #
2705
2706 sub _has_resolved_attr {
2707   my ($self, @attr_names) = @_;
2708
2709   my $attrs = $self->_resolved_attrs;
2710
2711   my %extra_checks;
2712
2713   for my $n (@attr_names) {
2714     if (grep { $n eq $_ } (qw/-join/) ) {
2715       $extra_checks{$n}++;
2716       next;
2717     }
2718
2719     my $attr =  $attrs->{$n};
2720
2721     next if not defined $attr;
2722
2723     if (ref $attr eq 'HASH') {
2724       return 1 if keys %$attr;
2725     }
2726     elsif (ref $attr eq 'ARRAY') {
2727       return 1 if @$attr;
2728     }
2729     else {
2730       return 1 if $attr;
2731     }
2732   }
2733
2734   # a resolved join is expressed as a multi-level from
2735   return 1 if (
2736     $extra_checks{-join}
2737       and
2738     ref $attrs->{from} eq 'ARRAY'
2739       and
2740     @{$attrs->{from}} > 1
2741   );
2742
2743   return 0;
2744 }
2745
2746 # _remove_alias
2747 #
2748 # Remove the specified alias from the specified query hash. A copy is made so
2749 # the original query is not modified.
2750
2751 sub _remove_alias {
2752   my ($self, $query, $alias) = @_;
2753
2754   my %orig = %{ $query || {} };
2755   my %unaliased;
2756
2757   foreach my $key (keys %orig) {
2758     if ($key !~ /\./) {
2759       $unaliased{$key} = $orig{$key};
2760       next;
2761     }
2762     $unaliased{$1} = $orig{$key}
2763       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2764   }
2765
2766   return \%unaliased;
2767 }
2768
2769 =head2 as_query
2770
2771 =over 4
2772
2773 =item Arguments: none
2774
2775 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2776
2777 =back
2778
2779 Returns the SQL query and bind vars associated with the invocant.
2780
2781 This is generally used as the RHS for a subquery.
2782
2783 =cut
2784
2785 sub as_query {
2786   my $self = shift;
2787
2788   my $attrs = { %{ $self->_resolved_attrs } };
2789
2790   my $aq = $self->result_source->schema->storage->_select_args_to_query (
2791     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2792   );
2793
2794   $aq;
2795 }
2796
2797 =head2 find_or_new
2798
2799 =over 4
2800
2801 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2802
2803 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2804
2805 =back
2806
2807   my $artist = $schema->resultset('Artist')->find_or_new(
2808     { artist => 'fred' }, { key => 'artists' });
2809
2810   $cd->cd_to_producer->find_or_new({ producer => $producer },
2811                                    { key => 'primary' });
2812
2813 Find an existing record from this resultset using L</find>. if none exists,
2814 instantiate a new result object and return it. The object will not be saved
2815 into your storage until you call L<DBIx::Class::Row/insert> on it.
2816
2817 You most likely want this method when looking for existing rows using a unique
2818 constraint that is not the primary key, or looking for related rows.
2819
2820 If you want objects to be saved immediately, use L</find_or_create> instead.
2821
2822 B<Note>: Make sure to read the documentation of L</find> and understand the
2823 significance of the C<key> attribute, as its lack may skew your search, and
2824 subsequently result in spurious new objects.
2825
2826 B<Note>: Take care when using C<find_or_new> with a table having
2827 columns with default values that you intend to be automatically
2828 supplied by the database (e.g. an auto_increment primary key column).
2829 In normal usage, the value of such columns should NOT be included at
2830 all in the call to C<find_or_new>, even when set to C<undef>.
2831
2832 =cut
2833
2834 sub find_or_new {
2835   my $self     = shift;
2836   my $attrs    = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
2837   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2838   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2839     return $row;
2840   }
2841   return $self->new_result($hash);
2842 }
2843
2844 =head2 create
2845
2846 =over 4
2847
2848 =item Arguments: \%col_data
2849
2850 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2851
2852 =back
2853
2854 Attempt to create a single new row or a row with multiple related rows
2855 in the table represented by the resultset (and related tables). This
2856 will not check for duplicate rows before inserting, use
2857 L</find_or_create> to do that.
2858
2859 To create one row for this resultset, pass a hashref of key/value
2860 pairs representing the columns of the table and the values you wish to
2861 store. If the appropriate relationships are set up, foreign key fields
2862 can also be passed an object representing the foreign row, and the
2863 value will be set to its primary key.
2864
2865 To create related objects, pass a hashref of related-object column values
2866 B<keyed on the relationship name>. If the relationship is of type C<multi>
2867 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2868 The process will correctly identify columns holding foreign keys, and will
2869 transparently populate them from the keys of the corresponding relation.
2870 This can be applied recursively, and will work correctly for a structure
2871 with an arbitrary depth and width, as long as the relationships actually
2872 exists and the correct column data has been supplied.
2873
2874 Instead of hashrefs of plain related data (key/value pairs), you may
2875 also pass new or inserted objects. New objects (not inserted yet, see
2876 L</new_result>), will be inserted into their appropriate tables.
2877
2878 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2879
2880 Example of creating a new row.
2881
2882   $person_rs->create({
2883     name=>"Some Person",
2884     email=>"somebody@someplace.com"
2885   });
2886
2887 Example of creating a new row and also creating rows in a related C<has_many>
2888 or C<has_one> resultset.  Note Arrayref.
2889
2890   $artist_rs->create(
2891      { artistid => 4, name => 'Manufactured Crap', cds => [
2892         { title => 'My First CD', year => 2006 },
2893         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2894       ],
2895      },
2896   );
2897
2898 Example of creating a new row and also creating a row in a related
2899 C<belongs_to> resultset. Note Hashref.
2900
2901   $cd_rs->create({
2902     title=>"Music for Silly Walks",
2903     year=>2000,
2904     artist => {
2905       name=>"Silly Musician",
2906     }
2907   });
2908
2909 =over
2910
2911 =item WARNING
2912
2913 When subclassing ResultSet never attempt to override this method. Since
2914 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2915 lot of the internals simply never call it, so your override will be
2916 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2917 or L<DBIx::Class::Row/insert> depending on how early in the
2918 L</create> process you need to intervene. See also warning pertaining to
2919 L</new>.
2920
2921 =back
2922
2923 =cut
2924
2925 sub create :DBIC_method_is_indirect_sugar {
2926   #my ($self, $col_data) = @_;
2927   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2928   return shift->new_result(shift)->insert;
2929 }
2930
2931 =head2 find_or_create
2932
2933 =over 4
2934
2935 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2936
2937 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2938
2939 =back
2940
2941   $cd->cd_to_producer->find_or_create({ producer => $producer },
2942                                       { key => 'primary' });
2943
2944 Tries to find a record based on its primary key or unique constraints; if none
2945 is found, creates one and returns that instead.
2946
2947   my $cd = $schema->resultset('CD')->find_or_create({
2948     cdid   => 5,
2949     artist => 'Massive Attack',
2950     title  => 'Mezzanine',
2951     year   => 2005,
2952   });
2953
2954 Also takes an optional C<key> attribute, to search by a specific key or unique
2955 constraint. For example:
2956
2957   my $cd = $schema->resultset('CD')->find_or_create(
2958     {
2959       artist => 'Massive Attack',
2960       title  => 'Mezzanine',
2961     },
2962     { key => 'cd_artist_title' }
2963   );
2964
2965 B<Note>: Make sure to read the documentation of L</find> and understand the
2966 significance of the C<key> attribute, as its lack may skew your search, and
2967 subsequently result in spurious row creation.
2968
2969 B<Note>: Because find_or_create() reads from the database and then
2970 possibly inserts based on the result, this method is subject to a race
2971 condition. Another process could create a record in the table after
2972 the find has completed and before the create has started. To avoid
2973 this problem, use find_or_create() inside a transaction.
2974
2975 B<Note>: Take care when using C<find_or_create> with a table having
2976 columns with default values that you intend to be automatically
2977 supplied by the database (e.g. an auto_increment primary key column).
2978 In normal usage, the value of such columns should NOT be included at
2979 all in the call to C<find_or_create>, even when set to C<undef>.
2980
2981 See also L</find> and L</update_or_create>. For information on how to declare
2982 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2983
2984 If you need to know if an existing row was found or a new one created use
2985 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2986 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2987 database!
2988
2989   my $cd = $schema->resultset('CD')->find_or_new({
2990     cdid   => 5,
2991     artist => 'Massive Attack',
2992     title  => 'Mezzanine',
2993     year   => 2005,
2994   });
2995
2996   if( !$cd->in_storage ) {
2997       # do some stuff
2998       $cd->insert;
2999   }
3000
3001 =cut
3002
3003 sub find_or_create {
3004   my $self     = shift;
3005   my $attrs    = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
3006   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
3007   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
3008     return $row;
3009   }
3010   return $self->new_result($hash)->insert;
3011 }
3012
3013 =head2 update_or_create
3014
3015 =over 4
3016
3017 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3018
3019 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3020
3021 =back
3022
3023   $resultset->update_or_create({ col => $val, ... });
3024
3025 Like L</find_or_create>, but if a row is found it is immediately updated via
3026 C<< $found_row->update (\%col_data) >>.
3027
3028
3029 Takes an optional C<key> attribute to search on a specific unique constraint.
3030 For example:
3031
3032   # In your application
3033   my $cd = $schema->resultset('CD')->update_or_create(
3034     {
3035       artist => 'Massive Attack',
3036       title  => 'Mezzanine',
3037       year   => 1998,
3038     },
3039     { key => 'cd_artist_title' }
3040   );
3041
3042   $cd->cd_to_producer->update_or_create({
3043     producer => $producer,
3044     name => 'harry',
3045   }, {
3046     key => 'primary',
3047   });
3048
3049 B<Note>: Make sure to read the documentation of L</find> and understand the
3050 significance of the C<key> attribute, as its lack may skew your search, and
3051 subsequently result in spurious row creation.
3052
3053 B<Note>: Take care when using C<update_or_create> with a table having
3054 columns with default values that you intend to be automatically
3055 supplied by the database (e.g. an auto_increment primary key column).
3056 In normal usage, the value of such columns should NOT be included at
3057 all in the call to C<update_or_create>, even when set to C<undef>.
3058
3059 See also L</find> and L</find_or_create>. For information on how to declare
3060 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3061
3062 If you need to know if an existing row was updated or a new one created use
3063 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3064 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3065 database!
3066
3067 =cut
3068
3069 sub update_or_create {
3070   my $self = shift;
3071   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
3072   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3073
3074   my $row = $self->find($cond, $attrs);
3075   if (defined $row) {
3076     $row->update($cond);
3077     return $row;
3078   }
3079
3080   return $self->new_result($cond)->insert;
3081 }
3082
3083 =head2 update_or_new
3084
3085 =over 4
3086
3087 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3088
3089 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3090
3091 =back
3092
3093   $resultset->update_or_new({ col => $val, ... });
3094
3095 Like L</find_or_new> but if a row is found it is immediately updated via
3096 C<< $found_row->update (\%col_data) >>.
3097
3098 For example:
3099
3100   # In your application
3101   my $cd = $schema->resultset('CD')->update_or_new(
3102     {
3103       artist => 'Massive Attack',
3104       title  => 'Mezzanine',
3105       year   => 1998,
3106     },
3107     { key => 'cd_artist_title' }
3108   );
3109
3110   if ($cd->in_storage) {
3111       # the cd was updated
3112   }
3113   else {
3114       # the cd is not yet in the database, let's insert it
3115       $cd->insert;
3116   }
3117
3118 B<Note>: Make sure to read the documentation of L</find> and understand the
3119 significance of the C<key> attribute, as its lack may skew your search, and
3120 subsequently result in spurious new objects.
3121
3122 B<Note>: Take care when using C<update_or_new> with a table having
3123 columns with default values that you intend to be automatically
3124 supplied by the database (e.g. an auto_increment primary key column).
3125 In normal usage, the value of such columns should NOT be included at
3126 all in the call to C<update_or_new>, even when set to C<undef>.
3127
3128 See also L</find>, L</find_or_create> and L</find_or_new>.
3129
3130 =cut
3131
3132 sub update_or_new {
3133     my $self  = shift;
3134     my $attrs = ( @_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {} );
3135     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3136
3137     my $row = $self->find( $cond, $attrs );
3138     if ( defined $row ) {
3139         $row->update($cond);
3140         return $row;
3141     }
3142
3143     return $self->new_result($cond);
3144 }
3145
3146 =head2 get_cache
3147
3148 =over 4
3149
3150 =item Arguments: none
3151
3152 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3153
3154 =back
3155
3156 Gets the contents of the cache for the resultset, if the cache is set.
3157
3158 The cache is populated either by using the L</prefetch> attribute to
3159 L</search> or by calling L</set_cache>.
3160
3161 =cut
3162
3163 sub get_cache {
3164   shift->{all_cache};
3165 }
3166
3167 =head2 set_cache
3168
3169 =over 4
3170
3171 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3172
3173 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3174
3175 =back
3176
3177 Sets the contents of the cache for the resultset. Expects an arrayref
3178 of objects of the same class as those produced by the resultset. Note that
3179 if the cache is set, the resultset will return the cached objects rather
3180 than re-querying the database even if the cache attr is not set.
3181
3182 The contents of the cache can also be populated by using the
3183 L</prefetch> attribute to L</search>.
3184
3185 =cut
3186
3187 sub set_cache {
3188   my ( $self, $data ) = @_;
3189   $self->throw_exception("set_cache requires an arrayref")
3190       if defined($data) && (ref $data ne 'ARRAY');
3191   $self->{all_cache} = $data;
3192 }
3193
3194 =head2 clear_cache
3195
3196 =over 4
3197
3198 =item Arguments: none
3199
3200 =item Return Value: undef
3201
3202 =back
3203
3204 Clears the cache for the resultset.
3205
3206 =cut
3207
3208 sub clear_cache {
3209   shift->set_cache(undef);
3210 }
3211
3212 =head2 is_paged
3213
3214 =over 4
3215
3216 =item Arguments: none
3217
3218 =item Return Value: true, if the resultset has been paginated
3219
3220 =back
3221
3222 =cut
3223
3224 sub is_paged {
3225   my ($self) = @_;
3226   return !!$self->{attrs}{page};
3227 }
3228
3229 =head2 is_ordered
3230
3231 =over 4
3232
3233 =item Arguments: none
3234
3235 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3236
3237 =back
3238
3239 =cut
3240
3241 sub is_ordered {
3242   my ($self) = @_;
3243   return scalar $self->result_source->schema->storage->_extract_order_criteria($self->{attrs}{order_by});
3244 }
3245
3246 =head2 related_resultset
3247
3248 =over 4
3249
3250 =item Arguments: $rel_name
3251
3252 =item Return Value: L<$resultset|/search>
3253
3254 =back
3255
3256 Returns a related resultset for the supplied relationship name.
3257
3258   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3259
3260 =cut
3261
3262 sub related_resultset {
3263   $_[0]->throw_exception(
3264     'Extra arguments to $rs->related_resultset() were always quietly '
3265   . 'discarded without consideration, you need to switch to '
3266   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3267   ) if @_ > 2;
3268
3269   return $_[0]->{related_resultsets}{$_[1]}
3270     if defined $_[0]->{related_resultsets}{$_[1]};
3271
3272   my ($self, $rel) = @_;
3273
3274   return $self->{related_resultsets}{$rel} = do {
3275     my $rsrc = $self->result_source;
3276     my $rel_info = $rsrc->relationship_info($rel);
3277
3278     $self->throw_exception(
3279       "search_related: result source '" . $rsrc->source_name .
3280         "' has no such relationship $rel")
3281       unless $rel_info;
3282
3283     my $attrs = $self->_chain_relationship($rel);
3284
3285     # Previously this atribute was deleted (instead of being set as it is now)
3286     # Doing so seems to be harmless in all available test permutations
3287     # See also 01d59a6a6 and mst's comment below
3288     #
3289     $attrs->{alias} = $rsrc->schema->storage->relname_to_table_alias(
3290       $rel,
3291       $attrs->{seen_join}{$rel}
3292     );
3293
3294     # since this is search_related, and we already slid the select window inwards
3295     # (the select/as attrs were deleted in the beginning), we need to flip all
3296     # left joins to inner, so we get the expected results
3297     #
3298     # The DBIC relationship chaining implementation is pretty simple - every
3299     # new related_relationship is pushed onto the {from} stack, and the {select}
3300     # window simply slides further in. This means that when we count somewhere
3301     # in the middle, we got to make sure that everything in the join chain is an
3302     # actual inner join, otherwise the count will come back with unpredictable
3303     # results (a resultset may be generated with _some_ rows regardless of if
3304     # the relation which the $rs currently selects has rows or not). E.g.
3305     # $artist_rs->cds->count - normally generates:
3306     # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
3307     # which actually returns the number of artists * (number of cds || 1)
3308     #
3309     # So what we do here is crawl {from}, determine if the current alias is at
3310     # the top of the stack, and if not - make sure the chain is inner-joined down
3311     # to the root.
3312     #
3313     my $switch_branch = find_join_path_to_alias(
3314       $attrs->{from},
3315       $attrs->{alias},
3316     );
3317
3318     if ( @{ $switch_branch || [] } ) {
3319
3320       # So it looks like we will have to switch some stuff around.
3321       # local() is useless here as we will be leaving the scope
3322       # anyway, and deep cloning is just too fucking expensive
3323       # So replace the first hashref in the node arrayref manually
3324       my @new_from = $attrs->{from}[0];
3325       my $sw_idx = { map { (values %$_), 1 } @$switch_branch }; #there's one k/v per join-path
3326
3327       for my $j ( @{$attrs->{from}}[ 1 .. $#{$attrs->{from}} ] ) {
3328         my $jalias = $j->[0]{-alias};
3329
3330         if ($sw_idx->{$jalias}) {
3331           my %attrs = %{$j->[0]};
3332           delete $attrs{-join_type};
3333           push @new_from, [
3334             \%attrs,
3335             @{$j}[ 1 .. $#$j ],
3336           ];
3337         }
3338         else {
3339           push @new_from, $j;
3340         }
3341       }
3342
3343       $attrs->{from} = \@new_from;
3344     }
3345
3346
3347     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3348     delete $attrs->{result_class};
3349
3350     my $new = do {
3351
3352       # The reason we do this now instead of passing the alias to the
3353       # search_rs below is that if you wrap/overload resultset on the
3354       # source you need to know what alias it's -going- to have for things
3355       # to work sanely (e.g. RestrictWithObject wants to be able to add
3356       # extra query restrictions, and these may need to be $alias.)
3357       #                                       -- mst ~ 2007 (01d59a6a6)
3358       #
3359       # FIXME - this seems to be no longer neccessary (perhaps due to the
3360       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3361       # dependent (as of Jun 2015 ) does not yield any difference with or
3362       # without this line. Nevertheless keep it as is for now, to minimize
3363       # churn, there is enough potential for breakage in 0.0829xx as it is
3364       #                                       -- ribasushi Jun 2015
3365       #
3366       my $rel_source = $rsrc->related_source($rel);
3367       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3368
3369       $rel_source->resultset->search_rs( undef, $attrs );
3370     };
3371
3372     if (my $cache = $self->get_cache) {
3373       my @related_cache = map
3374         { $_->related_resultset($rel)->get_cache || () }
3375         @$cache
3376       ;
3377
3378       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3379     }
3380
3381     $new;
3382   };
3383 }
3384
3385 =head2 current_source_alias
3386
3387 =over 4
3388
3389 =item Arguments: none
3390
3391 =item Return Value: $source_alias
3392
3393 =back
3394
3395 Returns the current table alias for the result source this resultset is built
3396 on, that will be used in the SQL query. Usually it is C<me>.
3397
3398 Currently the source alias that refers to the result set returned by a
3399 L</search>/L</find> family method depends on how you got to the resultset: it's
3400 C<me> by default, but eg. L</search_related> aliases it to the related result
3401 source name (and keeps C<me> referring to the original result set). The long
3402 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3403 (and make this method unnecessary).
3404
3405 Thus it's currently necessary to use this method in predefined queries (see
3406 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3407 source alias of the current result set:
3408
3409   # in a result set class
3410   sub modified_by {
3411     my ($self, $user) = @_;
3412
3413     my $me = $self->current_source_alias;
3414
3415     return $self->search({
3416       "$me.modified" => $user->id,
3417     });
3418   }
3419
3420 The alias of L<newly created resultsets|/search> can be altered by the
3421 L<alias attribute|/alias>.
3422
3423 =cut
3424
3425 sub current_source_alias {
3426   return (shift->{attrs} || {})->{alias} || 'me';
3427 }
3428
3429 =head2 as_subselect_rs
3430
3431 =over 4
3432
3433 =item Arguments: none
3434
3435 =item Return Value: L<$resultset|/search>
3436
3437 =back
3438
3439 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3440 "virtual view" by including it as a subquery within the from clause.  From this
3441 point on, any joined tables are inaccessible to ->search on the resultset (as if
3442 it were simply where-filtered without joins).  For example:
3443
3444  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3445
3446  # 'x' now pollutes the query namespace
3447
3448  # So the following works as expected
3449  my $ok_rs = $rs->search({'x.other' => 1});
3450
3451  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3452  # def) we look for one row with contradictory terms and join in another table
3453  # (aliased 'x_2') which we never use
3454  my $broken_rs = $rs->search({'x.name' => 'def'});
3455
3456  my $rs2 = $rs->as_subselect_rs;
3457
3458  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3459  my $not_joined_rs = $rs2->search({'x.other' => 1});
3460
3461  # works as expected: finds a 'table' row related to two x rows (abc and def)
3462  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3463
3464 Another example of when one might use this would be to select a subset of
3465 columns in a group by clause:
3466
3467  my $rs = $schema->resultset('Bar')->search(undef, {
3468    group_by => [qw{ id foo_id baz_id }],
3469  })->as_subselect_rs->search(undef, {
3470    columns => [qw{ id foo_id }]
3471  });
3472
3473 In the above example normally columns would have to be equal to the group by,
3474 but because we isolated the group by into a subselect the above works.
3475
3476 =cut
3477
3478 sub as_subselect_rs {
3479   my $self = shift;
3480
3481   my $attrs = $self->_resolved_attrs;
3482
3483   my $fresh_rs = (ref $self)->new (
3484     $self->result_source
3485   );
3486
3487   # these pieces will be locked in the subquery
3488   delete $fresh_rs->{cond};
3489   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3490
3491   return $fresh_rs->search( {}, {
3492     from => [{
3493       $attrs->{alias} => $self->as_query,
3494       -alias  => $attrs->{alias},
3495       -rsrc   => $self->result_source,
3496     }],
3497     alias => $attrs->{alias},
3498   });
3499 }
3500
3501 # This code is called by search_related, and makes sure there
3502 # is clear separation between the joins before, during, and
3503 # after the relationship. This information is needed later
3504 # in order to properly resolve prefetch aliases (any alias
3505 # with a relation_chain_depth less than the depth of the
3506 # current prefetch is not considered)
3507 #
3508 # The increments happen twice per join. An even number means a
3509 # relationship specified via a search_related, whereas an odd
3510 # number indicates a join/prefetch added via attributes
3511 #
3512 # Also this code will wrap the current resultset (the one we
3513 # chain to) in a subselect IFF it contains limiting attributes
3514 sub _chain_relationship {
3515   my ($self, $rel) = @_;
3516   my $source = $self->result_source;
3517   my $attrs = { %{$self->{attrs}||{}} };
3518
3519   # we need to take the prefetch the attrs into account before we
3520   # ->_resolve_join as otherwise they get lost - captainL
3521   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3522
3523   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3524
3525   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3526
3527   my $from;
3528   my @force_subq_attrs = qw/offset rows group_by having/;
3529
3530   if (
3531     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3532       ||
3533     $self->_has_resolved_attr (@force_subq_attrs)
3534   ) {
3535     # Nuke the prefetch (if any) before the new $rs attrs
3536     # are resolved (prefetch is useless - we are wrapping
3537     # a subquery anyway).
3538     my $rs_copy = $self->search;
3539     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3540       $rs_copy->{attrs}{join},
3541       delete $rs_copy->{attrs}{prefetch},
3542     );
3543
3544     $from = [{
3545       -rsrc   => $source,
3546       -alias  => $attrs->{alias},
3547       $attrs->{alias} => $rs_copy->as_query,
3548     }];
3549     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3550     $seen->{-relation_chain_depth} = 0;
3551   }
3552   elsif ($attrs->{from}) {  #shallow copy suffices
3553     $from = [ @{$attrs->{from}} ];
3554   }
3555   else {
3556     $from = [{
3557       -rsrc  => $source,
3558       -alias => $attrs->{alias},
3559       $attrs->{alias} => $source->from,
3560     }];
3561   }
3562
3563   my $jpath = ($seen->{-relation_chain_depth})
3564     ? $from->[-1][0]{-join_path}
3565     : [];
3566
3567   my @requested_joins = $source->_resolve_join(
3568     $join,
3569     $attrs->{alias},
3570     $seen,
3571     $jpath,
3572   );
3573
3574   push @$from, @requested_joins;
3575
3576   $seen->{-relation_chain_depth}++;
3577
3578   # if $self already had a join/prefetch specified on it, the requested
3579   # $rel might very well be already included. What we do in this case
3580   # is effectively a no-op (except that we bump up the chain_depth on
3581   # the join in question so we could tell it *is* the search_related)
3582   my $already_joined;
3583
3584   # we consider the last one thus reverse
3585   for my $j (reverse @requested_joins) {
3586     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3587     if ($rel eq $last_j) {
3588       $j->[0]{-relation_chain_depth}++;
3589       $already_joined++;
3590       last;
3591     }
3592   }
3593
3594   unless ($already_joined) {
3595     push @$from, $source->_resolve_join(
3596       $rel,
3597       $attrs->{alias},
3598       $seen,
3599       $jpath,
3600     );
3601   }
3602
3603   $seen->{-relation_chain_depth}++;
3604
3605   return {%$attrs, from => $from, seen_join => $seen};
3606 }
3607
3608 sub _resolved_attrs {
3609   my $self = shift;
3610   return $self->{_attrs} if $self->{_attrs};
3611
3612   my $attrs  = { %{ $self->{attrs} || {} } };
3613   my $source = $attrs->{result_source} = $self->result_source;
3614   my $alias  = $attrs->{alias};
3615
3616   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3617     if $attrs->{collapse} and $attrs->{distinct};
3618
3619
3620   # Sanity check the paging attributes
3621   # SQLMaker does it too, but in case of a software_limit we'll never get there
3622   if (defined $attrs->{offset}) {
3623     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3624       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3625   }
3626   if (defined $attrs->{rows}) {
3627     $self->throw_exception("The rows attribute must be a positive integer if present")
3628       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3629   }
3630
3631   # normalize where condition
3632   $attrs->{where} = normalize_sqla_condition( $attrs->{where} )
3633     if $attrs->{where};
3634
3635   # default selection list
3636   $attrs->{columns} = [ $source->columns ]
3637     unless grep { exists $attrs->{$_} } qw/columns cols select as/;
3638
3639   # merge selectors together
3640   for (qw/columns select as/) {
3641     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3642       if $attrs->{$_} or $attrs->{"+$_"};
3643   }
3644
3645   # disassemble columns
3646   my (@sel, @as);
3647   if (my $cols = delete $attrs->{columns}) {
3648     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3649       if (ref $c eq 'HASH') {
3650         for my $as (sort keys %$c) {
3651           push @sel, $c->{$as};
3652           push @as, $as;
3653         }
3654       }
3655       else {
3656         push @sel, $c;
3657         push @as, $c;
3658       }
3659     }
3660   }
3661
3662   # when trying to weed off duplicates later do not go past this point -
3663   # everything added from here on is unbalanced "anyone's guess" stuff
3664   my $dedup_stop_idx = $#as;
3665
3666   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3667     if $attrs->{as};
3668   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3669     if $attrs->{select};
3670
3671   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3672   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3673
3674   # disqualify all $alias.col as-bits (inflate-map mandated)
3675   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3676
3677   # de-duplicate the result (remove *identical* select/as pairs)
3678   # and also die on duplicate {as} pointing to different {select}s
3679   # not using a c-style for as the condition is prone to shrinkage
3680   my $seen;
3681   my $i = 0;
3682   while ($i <= $dedup_stop_idx) {
3683     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3684       splice @sel, $i, 1;
3685       splice @as, $i, 1;
3686       $dedup_stop_idx--;
3687     }
3688     elsif ($seen->{$as[$i]}++) {
3689       $self->throw_exception(
3690         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3691       );
3692     }
3693     else {
3694       $i++;
3695     }
3696   }
3697
3698   $attrs->{select} = \@sel;
3699   $attrs->{as} = \@as;
3700
3701   $attrs->{from} ||= [{
3702     -rsrc   => $source,
3703     -alias  => $self->{attrs}{alias},
3704     $self->{attrs}{alias} => $source->from,
3705   }];
3706
3707   if ( $attrs->{join} || $attrs->{prefetch} ) {
3708
3709     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3710       if ref $attrs->{from} ne 'ARRAY';
3711
3712     my $join = (delete $attrs->{join}) || {};
3713
3714     if ( defined $attrs->{prefetch} ) {
3715       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3716     }
3717
3718     $attrs->{from} =    # have to copy here to avoid corrupting the original
3719       [
3720         @{ $attrs->{from} },
3721         $source->_resolve_join(
3722           $join,
3723           $alias,
3724           { %{ $attrs->{seen_join} || {} } },
3725           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3726             ? $attrs->{from}[-1][0]{-join_path}
3727             : []
3728           ,
3729         )
3730       ];
3731   }
3732
3733
3734   for my $attr (qw(order_by group_by)) {
3735
3736     if ( defined $attrs->{$attr} ) {
3737       $attrs->{$attr} = (
3738         ref( $attrs->{$attr} ) eq 'ARRAY'
3739         ? [ @{ $attrs->{$attr} } ]
3740         : [ $attrs->{$attr} || () ]
3741       );
3742
3743       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3744     }
3745   }
3746
3747
3748   # set collapse default based on presence of prefetch
3749   my $prefetch;
3750   if (
3751     defined $attrs->{prefetch}
3752       and
3753     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3754   ) {
3755     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3756       if defined $attrs->{collapse} and ! $attrs->{collapse};
3757
3758     $attrs->{collapse} = 1;
3759   }
3760
3761
3762   # run through the resulting joinstructure (starting from our current slot)
3763   # and unset collapse if proven unnecessary
3764   #
3765   # also while we are at it find out if the current root source has
3766   # been premultiplied by previous related_source chaining
3767   #
3768   # this allows to predict whether a root object with all other relation
3769   # data set to NULL is in fact unique
3770   if ($attrs->{collapse}) {
3771
3772     if (ref $attrs->{from} eq 'ARRAY') {
3773
3774       if (@{$attrs->{from}} == 1) {
3775         # no joins - no collapse
3776         $attrs->{collapse} = 0;
3777       }
3778       else {
3779         # find where our table-spec starts
3780         my @fromlist = @{$attrs->{from}};
3781         while (@fromlist) {
3782           my $t = shift @fromlist;
3783
3784           my $is_multi;
3785           # me vs join from-spec distinction - a ref means non-root
3786           if (ref $t eq 'ARRAY') {
3787             $t = $t->[0];
3788             $is_multi ||= ! $t->{-is_single};
3789           }
3790           last if ($t->{-alias} && $t->{-alias} eq $alias);
3791           $attrs->{_main_source_premultiplied} ||= $is_multi;
3792         }
3793
3794         # no non-singles remaining, nor any premultiplication - nothing to collapse
3795         if (
3796           ! $attrs->{_main_source_premultiplied}
3797             and
3798           ! grep { ! $_->[0]{-is_single} } @fromlist
3799         ) {
3800           $attrs->{collapse} = 0;
3801         }
3802       }
3803     }
3804
3805     else {
3806       # if we can not analyze the from - err on the side of safety
3807       $attrs->{_main_source_premultiplied} = 1;
3808     }
3809   }
3810
3811
3812   # generate the distinct induced group_by before injecting the prefetched select/as parts
3813   if (delete $attrs->{distinct}) {
3814     if ($attrs->{group_by}) {
3815       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3816     }
3817     else {
3818       $attrs->{_grouped_by_distinct} = 1;
3819       # distinct affects only the main selection part, not what prefetch may add below
3820       ($attrs->{group_by}, my $new_order) = $source->schema->storage->_group_over_selection($attrs);
3821
3822       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3823       # The thinking is: if we are collapsing the subquerying prefetch engine will
3824       # rip stuff apart for us anyway, and we do not want to have a potentially
3825       # function-converted external order_by
3826       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3827       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3828     }
3829   }
3830
3831
3832   # generate selections based on the prefetch helper
3833   if ($prefetch) {
3834
3835     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3836       if $attrs->{_dark_selector};
3837
3838     # this is a separate structure (we don't look in {from} directly)
3839     # as the resolver needs to shift things off the lists to work
3840     # properly (identical-prefetches on different branches)
3841     my $joined_node_aliases_map = {};
3842     if (ref $attrs->{from} eq 'ARRAY') {
3843
3844       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3845
3846       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3847         next unless $j->[0]{-alias};
3848         next unless $j->[0]{-join_path};
3849         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3850
3851         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3852
3853         my $p = $joined_node_aliases_map;
3854         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3855         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3856       }
3857     }
3858
3859     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3860       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3861   }
3862
3863
3864   $attrs->{_simple_passthrough_construction} = !(
3865     $attrs->{collapse}
3866       or
3867     grep { $_ =~ /\./ } @{$attrs->{as}}
3868   );
3869
3870
3871   # if both page and offset are specified, produce a combined offset
3872   # even though it doesn't make much sense, this is what pre 081xx has
3873   # been doing
3874   if (my $page = delete $attrs->{page}) {
3875     $attrs->{offset} =
3876       ($attrs->{rows} * ($page - 1))
3877             +
3878       ($attrs->{offset} || 0)
3879     ;
3880   }
3881
3882   return $self->{_attrs} = $attrs;
3883 }
3884
3885 sub _rollout_attr {
3886   my ($self, $attr) = @_;
3887
3888   if (ref $attr eq 'HASH') {
3889     return $self->_rollout_hash($attr);
3890   } elsif (ref $attr eq 'ARRAY') {
3891     return $self->_rollout_array($attr);
3892   } else {
3893     return [$attr];
3894   }
3895 }
3896
3897 sub _rollout_array {
3898   my ($self, $attr) = @_;
3899
3900   my @rolled_array;
3901   foreach my $element (@{$attr}) {
3902     if (ref $element eq 'HASH') {
3903       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3904     } elsif (ref $element eq 'ARRAY') {
3905       #  XXX - should probably recurse here
3906       push( @rolled_array, @{$self->_rollout_array($element)} );
3907     } else {
3908       push( @rolled_array, $element );
3909     }
3910   }
3911   return \@rolled_array;
3912 }
3913
3914 sub _rollout_hash {
3915   my ($self, $attr) = @_;
3916
3917   my @rolled_array;
3918   foreach my $key (keys %{$attr}) {
3919     push( @rolled_array, { $key => $attr->{$key} } );
3920   }
3921   return \@rolled_array;
3922 }
3923
3924 sub _calculate_score {
3925   my ($self, $a, $b) = @_;
3926
3927   if (defined $a xor defined $b) {
3928     return 0;
3929   }
3930   elsif (not defined $a) {
3931     return 1;
3932   }
3933
3934   if (ref $b eq 'HASH') {
3935     my ($b_key) = keys %{$b};
3936     $b_key = '' if ! defined $b_key;
3937     if (ref $a eq 'HASH') {
3938       my ($a_key) = keys %{$a};
3939       $a_key = '' if ! defined $a_key;
3940       if ($a_key eq $b_key) {
3941         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3942       } else {
3943         return 0;
3944       }
3945     } else {
3946       return ($a eq $b_key) ? 1 : 0;
3947     }
3948   } else {
3949     if (ref $a eq 'HASH') {
3950       my ($a_key) = keys %{$a};
3951       return ($b eq $a_key) ? 1 : 0;
3952     } else {
3953       return ($b eq $a) ? 1 : 0;
3954     }
3955   }
3956 }
3957
3958 sub _merge_joinpref_attr {
3959   my ($self, $orig, $import) = @_;
3960
3961   return $import unless defined($orig);
3962   return $orig unless defined($import);
3963
3964   $orig = $self->_rollout_attr($orig);
3965   $import = $self->_rollout_attr($import);
3966
3967   my $seen_keys;
3968   foreach my $import_element ( @{$import} ) {
3969     # find best candidate from $orig to merge $b_element into
3970     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3971     foreach my $orig_element ( @{$orig} ) {
3972       my $score = $self->_calculate_score( $orig_element, $import_element );
3973       if ($score > $best_candidate->{score}) {
3974         $best_candidate->{position} = $position;
3975         $best_candidate->{score} = $score;
3976       }
3977       $position++;
3978     }
3979     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3980     $import_key = '' if not defined $import_key;
3981
3982     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3983       push( @{$orig}, $import_element );
3984     } else {
3985       my $orig_best = $orig->[$best_candidate->{position}];
3986       # merge orig_best and b_element together and replace original with merged
3987       if (ref $orig_best ne 'HASH') {
3988         $orig->[$best_candidate->{position}] = $import_element;
3989       } elsif (ref $import_element eq 'HASH') {
3990         my ($key) = keys %{$orig_best};
3991         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3992       }
3993     }
3994     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3995   }
3996
3997   return @$orig ? $orig : ();
3998 }
3999
4000 {
4001   my $hm;
4002
4003   sub _merge_attr {
4004     $hm ||= do {
4005       require Hash::Merge;
4006       my $hm = Hash::Merge->new;
4007
4008       $hm->specify_behavior({
4009         SCALAR => {
4010           SCALAR => sub {
4011             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
4012
4013             if ($defl xor $defr) {
4014               return [ $defl ? $_[0] : $_[1] ];
4015             }
4016             elsif (! $defl) {
4017               return [];
4018             }
4019             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
4020               return [ $_[0] ];
4021             }
4022             else {
4023               return [$_[0], $_[1]];
4024             }
4025           },
4026           ARRAY => sub {
4027             return $_[1] if !defined $_[0];
4028             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
4029             return [$_[0], @{$_[1]}]
4030           },
4031           HASH  => sub {
4032             return [] if !defined $_[0] and !keys %{$_[1]};
4033             return [ $_[1] ] if !defined $_[0];
4034             return [ $_[0] ] if !keys %{$_[1]};
4035             return [$_[0], $_[1]]
4036           },
4037         },
4038         ARRAY => {
4039           SCALAR => sub {
4040             return $_[0] if !defined $_[1];
4041             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
4042             return [@{$_[0]}, $_[1]]
4043           },
4044           ARRAY => sub {
4045             my @ret = @{$_[0]} or return $_[1];
4046             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
4047             my %idx = map { $_ => 1 } @ret;
4048             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
4049             \@ret;
4050           },
4051           HASH => sub {
4052             return [ $_[1] ] if ! @{$_[0]};
4053             return $_[0] if !keys %{$_[1]};
4054             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
4055             return [ @{$_[0]}, $_[1] ];
4056           },
4057         },
4058         HASH => {
4059           SCALAR => sub {
4060             return [] if !keys %{$_[0]} and !defined $_[1];
4061             return [ $_[0] ] if !defined $_[1];
4062             return [ $_[1] ] if !keys %{$_[0]};
4063             return [$_[0], $_[1]]
4064           },
4065           ARRAY => sub {
4066             return [] if !keys %{$_[0]} and !@{$_[1]};
4067             return [ $_[0] ] if !@{$_[1]};
4068             return $_[1] if !keys %{$_[0]};
4069             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
4070             return [ $_[0], @{$_[1]} ];
4071           },
4072           HASH => sub {
4073             return [] if !keys %{$_[0]} and !keys %{$_[1]};
4074             return [ $_[0] ] if !keys %{$_[1]};
4075             return [ $_[1] ] if !keys %{$_[0]};
4076             return [ $_[0] ] if $_[0] eq $_[1];
4077             return [ $_[0], $_[1] ];
4078           },
4079         }
4080       } => 'DBIC_RS_ATTR_MERGER');
4081       $hm;
4082     };
4083
4084     return $hm->merge ($_[1], $_[2]);
4085   }
4086 }
4087
4088 sub STORABLE_freeze {
4089   my ($self, $cloning) = @_;
4090   my $to_serialize = { %$self };
4091
4092   # A cursor in progress can't be serialized (and would make little sense anyway)
4093   # the parser can be regenerated (and can't be serialized)
4094   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
4095
4096   # nor is it sensical to store a not-yet-fired-count pager
4097   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
4098     delete $to_serialize->{pager};
4099   }
4100
4101   Storable::nfreeze($to_serialize);
4102 }
4103
4104 # need this hook for symmetry
4105 sub STORABLE_thaw {
4106   my ($self, $cloning, $serialized) = @_;
4107
4108   %$self = %{ Storable::thaw($serialized) };
4109
4110   $self;
4111 }
4112
4113
4114 =head2 throw_exception
4115
4116 See L<DBIx::Class::Schema/throw_exception> for details.
4117
4118 =cut
4119
4120 sub throw_exception {
4121   my $self=shift;
4122
4123   if (ref $self and my $rsrc = $self->result_source) {
4124     $rsrc->throw_exception(@_)
4125   }
4126   else {
4127     DBIx::Class::Exception->throw(@_);
4128   }
4129 }
4130
4131 1;
4132
4133 __END__
4134
4135 # XXX: FIXME: Attributes docs need clearing up
4136
4137 =head1 ATTRIBUTES
4138
4139 Attributes are used to refine a ResultSet in various ways when
4140 searching for data. They can be passed to any method which takes an
4141 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4142 L</count>.
4143
4144 Default attributes can be set on the result class using
4145 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4146 the CAVEATS on that feature before using it!)
4147
4148 These are in no particular order:
4149
4150 =head2 order_by
4151
4152 =over 4
4153
4154 =item Value: ( $order_by | \@order_by | \%order_by )
4155
4156 =back
4157
4158 Which column(s) to order the results by.
4159
4160 [The full list of suitable values is documented in
4161 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4162 common options.]
4163
4164 If a single column name, or an arrayref of names is supplied, the
4165 argument is passed through directly to SQL. The hashref syntax allows
4166 for connection-agnostic specification of ordering direction:
4167
4168  For descending order:
4169
4170   order_by => { -desc => [qw/col1 col2 col3/] }
4171
4172  For explicit ascending order:
4173
4174   order_by => { -asc => 'col' }
4175
4176 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4177 supported, although you are strongly encouraged to use the hashref
4178 syntax as outlined above.
4179
4180 =head2 columns
4181
4182 =over 4
4183
4184 =item Value: \@columns | \%columns | $column
4185
4186 =back
4187
4188 Shortcut to request a particular set of columns to be retrieved. Each
4189 column spec may be a string (a table column name), or a hash (in which
4190 case the key is the C<as> value, and the value is used as the C<select>
4191 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4192 it and sets C<select> from that, then auto-populates C<as> from
4193 C<select> as normal. (You may also use the C<cols> attribute, as in
4194 earlier versions of DBIC, but this is deprecated)
4195
4196 Essentially C<columns> does the same as L</select> and L</as>.
4197
4198     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4199
4200 is the same as
4201
4202     select => [qw(some_column another_column)],
4203     as     => [qw(some_column dbic_slot)]
4204
4205 If you want to individually retrieve related columns (in essence perform
4206 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4207 chain such that it matches existing relationships:
4208
4209     my $rs = $schema->resultset('Artist')->search({}, {
4210         # required to tell DBIC to collapse has_many relationships
4211         collapse => 1,
4212         join     => { cds => 'tracks' },
4213         '+columns'  => {
4214           'cds.cdid'         => 'cds.cdid',
4215           'cds.tracks.title' => 'tracks.title',
4216         },
4217     });
4218
4219 Like elsewhere, literal SQL or literal values can be included by using a
4220 scalar reference or a literal bind value, and these values will be available
4221 in the result with C<get_column> (see also
4222 L<SQL::Abstract/Literal SQL and value type operators>):
4223
4224     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4225     # bind values: $true_value, $false_value
4226     columns => [
4227         {
4228             foo => \1,
4229             bar => \q{'a string'},
4230             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4231         }
4232     ]
4233
4234 =head2 +columns
4235
4236 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4237 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4238 with a unary plus operator before it, which is the same as simply C<columns>.
4239
4240 =over 4
4241
4242 =item Value: \@extra_columns
4243
4244 =back
4245
4246 Indicates additional columns to be selected from storage. Works the same as
4247 L</columns> but adds columns to the current selection. (You may also use the
4248 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4249 deprecated)
4250
4251   $schema->resultset('CD')->search(undef, {
4252     '+columns' => ['artist.name'],
4253     join => ['artist']
4254   });
4255
4256 would return all CDs and include a 'name' column to the information
4257 passed to object inflation. Note that the 'artist' is the name of the
4258 column (or relationship) accessor, and 'name' is the name of the column
4259 accessor in the related table.
4260
4261 =head2 select
4262
4263 =over 4
4264
4265 =item Value: \@select_columns
4266
4267 =back
4268
4269 Indicates which columns should be selected from the storage. You can use
4270 column names, or in the case of RDBMS back ends, function or stored procedure
4271 names:
4272
4273   $rs = $schema->resultset('Employee')->search(undef, {
4274     select => [
4275       'name',
4276       { count => 'employeeid' },
4277       { max => { length => 'name' }, -as => 'longest_name' }
4278     ]
4279   });
4280
4281   # Equivalent SQL
4282   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4283
4284 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4285 use L</select>, to instruct DBIx::Class how to store the result of the column.
4286
4287 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4288 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4289 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4290 function attribute> supplied as shown in the example above.
4291
4292 =head2 +select
4293
4294 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4295 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4296 with a unary plus operator before it, which is the same as simply C<select>.
4297
4298 =over 4
4299
4300 =item Value: \@extra_select_columns
4301
4302 =back
4303
4304 Indicates additional columns to be selected from storage.  Works the same as
4305 L</select> but adds columns to the current selection, instead of specifying
4306 a new explicit list.
4307
4308 =head2 as
4309
4310 =over 4
4311
4312 =item Value: \@inflation_names
4313
4314 =back
4315
4316 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4317 slot name in which the column value will be stored within the
4318 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4319 identifier by the C<get_column> method (or via the object accessor B<if one
4320 with the same name already exists>) as shown below.
4321
4322 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4323 aliasing C<AS>. See L</select> for details.
4324
4325   $rs = $schema->resultset('Employee')->search(undef, {
4326     select => [
4327       'name',
4328       { count => 'employeeid' },
4329       { max => { length => 'name' }, -as => 'longest_name' }
4330     ],
4331     as => [qw/
4332       name
4333       employee_count
4334       max_name_length
4335     /],
4336   });
4337
4338 If the object against which the search is performed already has an accessor
4339 matching a column name specified in C<as>, the value can be retrieved using
4340 the accessor as normal:
4341
4342   my $name = $employee->name();
4343
4344 If on the other hand an accessor does not exist in the object, you need to
4345 use C<get_column> instead:
4346
4347   my $employee_count = $employee->get_column('employee_count');
4348
4349 You can create your own accessors if required - see
4350 L<DBIx::Class::Manual::Cookbook> for details.
4351
4352 =head2 +as
4353
4354 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4355 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4356 with a unary plus operator before it, which is the same as simply C<as>.
4357
4358 =over 4
4359
4360 =item Value: \@extra_inflation_names
4361
4362 =back
4363
4364 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4365
4366 =head2 join
4367
4368 =over 4
4369
4370 =item Value: ($rel_name | \@rel_names | \%rel_names)
4371
4372 =back
4373
4374 Contains a list of relationships that should be joined for this query.  For
4375 example:
4376
4377   # Get CDs by Nine Inch Nails
4378   my $rs = $schema->resultset('CD')->search(
4379     { 'artist.name' => 'Nine Inch Nails' },
4380     { join => 'artist' }
4381   );
4382
4383 Can also contain a hash reference to refer to the other relation's relations.
4384 For example:
4385
4386   package MyApp::Schema::Track;
4387   use base qw/DBIx::Class/;
4388   __PACKAGE__->table('track');
4389   __PACKAGE__->add_columns(qw/trackid cd position title/);
4390   __PACKAGE__->set_primary_key('trackid');
4391   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4392   1;
4393
4394   # In your application
4395   my $rs = $schema->resultset('Artist')->search(
4396     { 'track.title' => 'Teardrop' },
4397     {
4398       join     => { cd => 'track' },
4399       order_by => 'artist.name',
4400     }
4401   );
4402
4403 You need to use the relationship (not the table) name in  conditions,
4404 because they are aliased as such. The current table is aliased as "me", so
4405 you need to use me.column_name in order to avoid ambiguity. For example:
4406
4407   # Get CDs from 1984 with a 'Foo' track
4408   my $rs = $schema->resultset('CD')->search(
4409     {
4410       'me.year' => 1984,
4411       'tracks.name' => 'Foo'
4412     },
4413     { join => 'tracks' }
4414   );
4415
4416 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4417 similarly for a third time). For e.g.
4418
4419   my $rs = $schema->resultset('Artist')->search({
4420     'cds.title'   => 'Down to Earth',
4421     'cds_2.title' => 'Popular',
4422   }, {
4423     join => [ qw/cds cds/ ],
4424   });
4425
4426 will return a set of all artists that have both a cd with title 'Down
4427 to Earth' and a cd with title 'Popular'.
4428
4429 If you want to fetch related objects from other tables as well, see L</prefetch>
4430 below.
4431
4432  NOTE: An internal join-chain pruner will discard certain joins while
4433  constructing the actual SQL query, as long as the joins in question do not
4434  affect the retrieved result. This for example includes 1:1 left joins
4435  that are not part of the restriction specification (WHERE/HAVING) nor are
4436  a part of the query selection.
4437
4438 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4439
4440 =head2 collapse
4441
4442 =over 4
4443
4444 =item Value: (0 | 1)
4445
4446 =back
4447
4448 When set to a true value, indicates that any rows fetched from joined has_many
4449 relationships are to be aggregated into the corresponding "parent" object. For
4450 example, the resultset:
4451
4452   my $rs = $schema->resultset('CD')->search({}, {
4453     '+columns' => [ qw/ tracks.title tracks.position / ],
4454     join => 'tracks',
4455     collapse => 1,
4456   });
4457
4458 While executing the following query:
4459
4460   SELECT me.*, tracks.title, tracks.position
4461     FROM cd me
4462     LEFT JOIN track tracks
4463       ON tracks.cdid = me.cdid
4464
4465 Will return only as many objects as there are rows in the CD source, even
4466 though the result of the query may span many rows. Each of these CD objects
4467 will in turn have multiple "Track" objects hidden behind the has_many
4468 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4469 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4470 product"), with each CD object containing exactly one of all fetched Track data.
4471
4472 When a collapse is requested on a non-ordered resultset, an order by some
4473 unique part of the main source (the left-most table) is inserted automatically.
4474 This is done so that the resultset is allowed to be "lazy" - calling
4475 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4476 object with all of its related data.
4477
4478 If an L</order_by> is already declared, and orders the resultset in a way that
4479 makes collapsing as described above impossible (e.g. C<< ORDER BY
4480 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4481 switch to "eager" mode and slurp the entire resultset before constructing the
4482 first object returned by L</next>.
4483
4484 Setting this attribute on a resultset that does not join any has_many
4485 relations is a no-op.
4486
4487 For a more in-depth discussion, see L</PREFETCHING>.
4488
4489 =head2 prefetch
4490
4491 =over 4
4492
4493 =item Value: ($rel_name | \@rel_names | \%rel_names)
4494
4495 =back
4496
4497 This attribute is a shorthand for specifying a L</join> spec, adding all
4498 columns from the joined related sources as L</+columns> and setting
4499 L</collapse> to a true value. It can be thought of as a rough B<superset>
4500 of the L</join> attribute.
4501
4502 For example, the following two queries are equivalent:
4503
4504   my $rs = $schema->resultset('Artist')->search({}, {
4505     prefetch => { cds => ['genre', 'tracks' ] },
4506   });
4507
4508 and
4509
4510   my $rs = $schema->resultset('Artist')->search({}, {
4511     join => { cds => ['genre', 'tracks' ] },
4512     collapse => 1,
4513     '+columns' => [
4514       (map
4515         { +{ "cds.$_" => "cds.$_" } }
4516         $schema->source('Artist')->related_source('cds')->columns
4517       ),
4518       (map
4519         { +{ "cds.genre.$_" => "genre.$_" } }
4520         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4521       ),
4522       (map
4523         { +{ "cds.tracks.$_" => "tracks.$_" } }
4524         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4525       ),
4526     ],
4527   });
4528
4529 Both producing the following SQL:
4530
4531   SELECT  me.artistid, me.name, me.rank, me.charfield,
4532           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4533           genre.genreid, genre.name,
4534           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4535     FROM artist me
4536     LEFT JOIN cd cds
4537       ON cds.artist = me.artistid
4538     LEFT JOIN genre genre
4539       ON genre.genreid = cds.genreid
4540     LEFT JOIN track tracks
4541       ON tracks.cd = cds.cdid
4542   ORDER BY me.artistid
4543
4544 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4545 the arguments are properly merged and generally do the right thing. For
4546 example, you may want to do the following:
4547
4548   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4549     { 'genre.genreid' => undef },
4550     {
4551       join => { cds => 'genre' },
4552       prefetch => 'cds',
4553     }
4554   );
4555
4556 Which generates the following SQL:
4557
4558   SELECT  me.artistid, me.name, me.rank, me.charfield,
4559           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4560     FROM artist me
4561     LEFT JOIN cd cds
4562       ON cds.artist = me.artistid
4563     LEFT JOIN genre genre
4564       ON genre.genreid = cds.genreid
4565   WHERE genre.genreid IS NULL
4566   ORDER BY me.artistid
4567
4568 For a more in-depth discussion, see L</PREFETCHING>.
4569
4570 =head2 alias
4571
4572 =over 4
4573
4574 =item Value: $source_alias
4575
4576 =back
4577
4578 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4579 nested search queries (sub-SELECTs) might need specific aliases set to
4580 reference inner queries.  For example:
4581
4582    my $q = $rs
4583       ->related_resultset('CDs')
4584       ->related_resultset('Tracks')
4585       ->search({
4586          'track.id' => { -ident => 'none_search.id' },
4587       })
4588       ->as_query;
4589
4590    my $ids = $self->search({
4591       -not_exists => $q,
4592    }, {
4593       alias    => 'none_search',
4594       group_by => 'none_search.id',
4595    })->get_column('id')->as_query;
4596
4597    $self->search({ id => { -in => $ids } })
4598
4599 This attribute is directly tied to L</current_source_alias>.
4600
4601 =head2 page
4602
4603 =over 4
4604
4605 =item Value: $page
4606
4607 =back
4608
4609 Makes the resultset paged and specifies the page to retrieve. Effectively
4610 identical to creating a non-pages resultset and then calling ->page($page)
4611 on it.
4612
4613 If L</rows> attribute is not specified it defaults to 10 rows per page.
4614
4615 When you have a paged resultset, L</count> will only return the number
4616 of rows in the page. To get the total, use the L</pager> and call
4617 C<total_entries> on it.
4618
4619 =head2 rows
4620
4621 =over 4
4622
4623 =item Value: $rows
4624
4625 =back
4626
4627 Specifies the maximum number of rows for direct retrieval or the number of
4628 rows per page if the page attribute or method is used.
4629
4630 =head2 offset
4631
4632 =over 4
4633
4634 =item Value: $offset
4635
4636 =back
4637
4638 Specifies the (zero-based) row number for the  first row to be returned, or the
4639 of the first row of the first page if paging is used.
4640
4641 =head2 software_limit
4642
4643 =over 4
4644
4645 =item Value: (0 | 1)
4646
4647 =back
4648
4649 When combined with L</rows> and/or L</offset> the generated SQL will not
4650 include any limit dialect stanzas. Instead the entire result will be selected
4651 as if no limits were specified, and DBIC will perform the limit locally, by
4652 artificially advancing and finishing the resulting L</cursor>.
4653
4654 This is the recommended way of performing resultset limiting when no sane RDBMS
4655 implementation is available (e.g.
4656 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4657 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4658
4659 =head2 group_by
4660
4661 =over 4
4662
4663 =item Value: \@columns
4664
4665 =back
4666
4667 A arrayref of columns to group by. Can include columns of joined tables.
4668
4669   group_by => [qw/ column1 column2 ... /]
4670
4671 =head2 having
4672
4673 =over 4
4674
4675 =item Value: $condition
4676
4677 =back
4678
4679 The HAVING operator specifies a B<secondary> condition applied to the set
4680 after the grouping calculations have been done. In other words it is a
4681 constraint just like L</where> (and accepting the same
4682 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4683 as it exists after GROUP BY has taken place. Specifying L</having> without
4684 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4685
4686 E.g.
4687
4688   having => { 'count_employee' => { '>=', 100 } }
4689
4690 or with an in-place function in which case literal SQL is required:
4691
4692   having => \[ 'count(employee) >= ?', 100 ]
4693
4694 =head2 distinct
4695
4696 =over 4
4697
4698 =item Value: (0 | 1)
4699
4700 =back
4701
4702 Set to 1 to automatically generate a L</group_by> clause based on the selection
4703 (including intelligent handling of L</order_by> contents). Note that the group
4704 criteria calculation takes place over the B<final> selection. This includes
4705 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4706 L</search> calls, and standalone columns selected via
4707 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4708 extra selections specified via L</prefetch> - such selections are explicitly
4709 excluded from group criteria calculations.
4710
4711 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4712 setting is ignored and an appropriate warning is issued.
4713
4714 =head2 where
4715
4716 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4717 conditions, same as the B<first> argument to the L<search operator|/search>
4718
4719   # only return rows WHERE deleted IS NULL for all searches
4720   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4721
4722 Note that the above example is
4723 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4724
4725 =head2 cache
4726
4727 Set to 1 to cache search results. This prevents extra SQL queries if you
4728 revisit rows in your ResultSet:
4729
4730   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4731
4732   while( my $artist = $resultset->next ) {
4733     ... do stuff ...
4734   }
4735
4736   $resultset->first; # without cache, this would issue a query
4737
4738 By default, searches are not cached.
4739
4740 For more examples of using these attributes, see
4741 L<DBIx::Class::Manual::Cookbook>.
4742
4743 =head2 for
4744
4745 =over 4
4746
4747 =item Value: ( 'update' | 'shared' | \$scalar )
4748
4749 =back
4750
4751 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4752 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4753 query.
4754
4755 =head1 PREFETCHING
4756
4757 DBIx::Class supports arbitrary related data prefetching from multiple related
4758 sources. Any combination of relationship types and column sets are supported.
4759 If L<collapsing|/collapse> is requested, there is an additional requirement of
4760 selecting enough data to make every individual object uniquely identifiable.
4761
4762 Here are some more involved examples, based on the following relationship map:
4763
4764   # Assuming:
4765   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4766   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4767   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4768
4769   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4770
4771   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4772
4773
4774
4775   my $rs = $schema->resultset('Tag')->search(
4776     undef,
4777     {
4778       prefetch => {
4779         cd => 'artist'
4780       }
4781     }
4782   );
4783
4784 The initial search results in SQL like the following:
4785
4786   SELECT tag.*, cd.*, artist.* FROM tag
4787   JOIN cd ON tag.cd = cd.cdid
4788   JOIN artist ON cd.artist = artist.artistid
4789
4790 L<DBIx::Class> has no need to go back to the database when we access the
4791 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4792 case.
4793
4794 Simple prefetches will be joined automatically, so there is no need
4795 for a C<join> attribute in the above search.
4796
4797 The L</prefetch> attribute can be used with any of the relationship types
4798 and multiple prefetches can be specified together. Below is a more complex
4799 example that prefetches a CD's artist, its liner notes (if present),
4800 the cover image, the tracks on that CD, and the guests on those
4801 tracks.
4802
4803   my $rs = $schema->resultset('CD')->search(
4804     undef,
4805     {
4806       prefetch => [
4807         { artist => 'record_label'},  # belongs_to => belongs_to
4808         'liner_note',                 # might_have
4809         'cover_image',                # has_one
4810         { tracks => 'guests' },       # has_many => has_many
4811       ]
4812     }
4813   );
4814
4815 This will produce SQL like the following:
4816
4817   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4818          tracks.*, guests.*
4819     FROM cd me
4820     JOIN artist artist
4821       ON artist.artistid = me.artistid
4822     JOIN record_label record_label
4823       ON record_label.labelid = artist.labelid
4824     LEFT JOIN track tracks
4825       ON tracks.cdid = me.cdid
4826     LEFT JOIN guest guests
4827       ON guests.trackid = track.trackid
4828     LEFT JOIN liner_notes liner_note
4829       ON liner_note.cdid = me.cdid
4830     JOIN cd_artwork cover_image
4831       ON cover_image.cdid = me.cdid
4832   ORDER BY tracks.cd
4833
4834 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4835 C<tracks>, and C<guests> of the CD will all be available through the
4836 relationship accessors without the need for additional queries to the
4837 database.
4838
4839 =head3 CAVEATS
4840
4841 Prefetch does a lot of deep magic. As such, it may not behave exactly
4842 as you might expect.
4843
4844 =over 4
4845
4846 =item *
4847
4848 Prefetch uses the L</cache> to populate the prefetched relationships. This
4849 may or may not be what you want.
4850
4851 =item *
4852
4853 If you specify a condition on a prefetched relationship, ONLY those
4854 rows that match the prefetched condition will be fetched into that relationship.
4855 This means that adding prefetch to a search() B<may alter> what is returned by
4856 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4857
4858   my $artist_rs = $schema->resultset('Artist')->search({
4859       'cds.year' => 2008,
4860   }, {
4861       join => 'cds',
4862   });
4863
4864   my $count = $artist_rs->first->cds->count;
4865
4866   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4867
4868   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4869
4870   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4871
4872 That cmp_ok() may or may not pass depending on the datasets involved. In other
4873 words the C<WHERE> condition would apply to the entire dataset, just like
4874 it would in regular SQL. If you want to add a condition only to the "right side"
4875 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4876 condition|DBIx::Class::Relationship::Base/condition>
4877
4878 =back
4879
4880 =head1 DBIC BIND VALUES
4881
4882 Because DBIC may need more information to bind values than just the column name
4883 and value itself, it uses a special format for both passing and receiving bind
4884 values.  Each bind value should be composed of an arrayref of
4885 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4886
4887 =over 4
4888
4889 =item dbd_attrs
4890
4891 If present (in any form), this is what is being passed directly to bind_param.
4892 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4893 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4894
4895 If this is specified, all other bind options described below are ignored.
4896
4897 =item sqlt_datatype
4898
4899 If present, this is used to infer the actual bind attribute by passing to
4900 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4901 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4902
4903 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4904 currently drivers are expected to "Do the Right Thing" when given a common
4905 datatype name.  (Not ideal, but that's what we got at this point.)
4906
4907 =item sqlt_size
4908
4909 Currently used to correctly allocate buffers for bind_param_inout().
4910 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4911 or to a sensible value based on the "data_type".
4912
4913 =item dbic_colname
4914
4915 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4916 explicitly specified they are never overridden).  Also used by some weird DBDs,
4917 where the column name should be available at bind_param time (e.g. Oracle).
4918
4919 =back
4920
4921 For backwards compatibility and convenience, the following shortcuts are
4922 supported:
4923
4924   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4925   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4926   [ undef,   $val ] === [ {}, $val ]
4927   $val              === [ {}, $val ]
4928
4929 =head1 FURTHER QUESTIONS?
4930
4931 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4932
4933 =head1 COPYRIGHT AND LICENSE
4934
4935 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4936 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4937 redistribute it and/or modify it under the same terms as the
4938 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4939
4940 =cut