lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  77
  78 If you want to make your custom ResultSet classes with L<Moose>, use a template
  79 similar to:
  80
  81     package MyApp::Schema::ResultSet::User;
  82
  83     use Moose;
  84     use namespace::autoclean;
  85     use MooseX::NonMoose;
  86     extends 'DBIx::Class::ResultSet';
  87
  88     sub BUILDARGS { $_[2] }
  89
  90     ...your code...
  91
  92     __PACKAGE__->meta->make_immutable;
  93
  94     1;
  95
  96 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  97 clash with the regular ResultSet constructor. Alternatively, you can use:
  98
  99     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 100
 101 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 102 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 103
 104 =head1 EXAMPLES
 105
 106 =head2 Chaining resultsets
 107
 108 Let's say you've got a query that needs to be run to return some data
 109 to the user. But, you have an authorization system in place that
 110 prevents certain users from seeing certain information. So, you want
 111 to construct the basic query in one method, but add constraints to it in
 112 another.
 113
 114   sub get_data {
 115     my $self = shift;
 116     my $request = $self->get_request; # Get a request object somehow.
 117     my $schema = $self->result_source->schema;
 118
 119     my $cd_rs = $schema->resultset('CD')->search({
 120       title => $request->param('title'),
 121       year => $request->param('year'),
 122     });
 123
 124     $cd_rs = $self->apply_security_policy( $cd_rs );
 125
 126     return $cd_rs->all();
 127   }
 128
 129   sub apply_security_policy {
 130     my $self = shift;
 131     my ($rs) = @_;
 132
 133     return $rs->search({
 134       subversive => 0,
 135     });
 136   }
 137
 138 =head3 Resolving conditions and attributes
 139
 140 When a resultset is chained from another resultset (ie:
 141 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 142 and attributes with the same keys need resolving.
 143
 144 If any of L</columns>, L</select>, L</as> are present, they reset the
 145 original selection, and start the selection "clean".
 146
 147 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 148 are merged into the existing ones from the original resultset.
 149
 150 The L</where> and L</having> attributes, and any search conditions, are
 151 merged with an SQL C<AND> to the existing condition from the original
 152 resultset.
 153
 154 All other attributes are overridden by any new ones supplied in the
 155 search attributes.
 156
 157 =head2 Multiple queries
 158
 159 Since a resultset just defines a query, you can do all sorts of
 160 things with it with the same object.
 161
 162   # Don't hit the DB yet.
 163   my $cd_rs = $schema->resultset('CD')->search({
 164     title => 'something',
 165     year => 2009,
 166   });
 167
 168   # Each of these hits the DB individually.
 169   my $count = $cd_rs->count;
 170   my $most_recent = $cd_rs->get_column('date_released')->max();
 171   my @records = $cd_rs->all;
 172
 173 And it's not just limited to SELECT statements.
 174
 175   $cd_rs->delete();
 176
 177 This is even cooler:
 178
 179   $cd_rs->create({ artist => 'Fred' });
 180
 181 Which is the same as:
 182
 183   $schema->resultset('CD')->create({
 184     title => 'something',
 185     year => 2009,
 186     artist => 'Fred'
 187   });
 188
 189 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 190
 191 =head1 METHODS
 192
 193 =head2 new
 194
 195 =over 4
 196
 197 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 198
 199 =item Return Value: L<$resultset|/search>
 200
 201 =back
 202
 203 The resultset constructor. Takes a source object (usually a
 204 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 205 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 206 executed as needed by the other methods.
 207
 208 Generally you never construct a resultset manually. Instead you get one
 209 from e.g. a
 210 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 211 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 212 scalar context):
 213
 214   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 215
 216 =over
 217
 218 =item WARNING
 219
 220 If called on an object, proxies to L</new_result> instead, so
 221
 222   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 223
 224 will return a CD object, not a ResultSet, and is equivalent to:
 225
 226   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 227
 228 Please also keep in mind that many internals call L</new_result> directly,
 229 so overloading this method with the idea of intercepting new result object
 230 creation B<will not work>. See also warning pertaining to L</create>.
 231
 232 =back
 233
 234 =cut
 235
 236 sub new {
 237   my $class = shift;
 238   return $class->new_result(@_) if ref $class;
 239
 240   my ($source, $attrs) = @_;
 241   $source = $source->resolve
 242     if $source->isa('DBIx::Class::ResultSourceHandle');
 243   $attrs = { %{$attrs||{}} };
 244
 245   if ($attrs->{page}) {
 246     $attrs->{rows} ||= 10;
 247   }
 248
 249   $attrs->{alias} ||= 'me';
 250
 251   my $self = bless {
 252     result_source => $source,
 253     cond => $attrs->{where},
 254     pager => undef,
 255     attrs => $attrs,
 256   }, $class;
 257
 258   # if there is a dark selector, this means we are already in a
 259   # chain and the cleanup/sanification was taken care of by
 260   # _search_rs already
 261   $self->_normalize_selection($attrs)
 262     unless $attrs->{_dark_selector};
 263
 264   $self->result_class(
 265     $attrs->{result_class} || $source->result_class
 266   );
 267
 268   $self;
 269 }
 270
 271 =head2 search
 272
 273 =over 4
 274
 275 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 276
 277 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 278
 279 =back
 280
 281   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 282   my $new_rs = $cd_rs->search({ year => 2005 });
 283
 284   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 285                  # year = 2005 OR year = 2004
 286
 287 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 288 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 289 To avoid that, use L</search_rs>.
 290
 291 If you need to pass in additional attributes but no additional condition,
 292 call it as C<search(undef, \%attrs)>.
 293
 294   # "SELECT name, artistid FROM $artist_table"
 295   my @all_artists = $schema->resultset('Artist')->search(undef, {
 296     columns => [qw/name artistid/],
 297   });
 298
 299 For a list of attributes that can be passed to C<search>, see
 300 L</ATTRIBUTES>. For more examples of using this function, see
 301 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 302 documentation for the first argument, see L<SQL::Abstract>
 303 and its extension L<DBIx::Class::SQLMaker>.
 304
 305 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 306
 307 =head3 CAVEAT
 308
 309 Note that L</search> does not process/deflate any of the values passed in the
 310 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 311 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 312 manually that any value passed to this method will stringify to something the
 313 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 314 objects, for more info see:
 315 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 316
 317 =cut
 318
 319 sub search {
 320   my $self = shift;
 321   my $rs = $self->search_rs( @_ );
 322
 323   if (wantarray) {
 324     return $rs->all;
 325   }
 326   elsif (defined wantarray) {
 327     return $rs;
 328   }
 329   else {
 330     # we can be called by a relationship helper, which in
 331     # turn may be called in void context due to some braindead
 332     # overload or whatever else the user decided to be clever
 333     # at this particular day. Thus limit the exception to
 334     # external code calls only
 335     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 336       if (caller)[0] !~ /^\QDBIx::Class::/;
 337
 338     return ();
 339   }
 340 }
 341
 342 =head2 search_rs
 343
 344 =over 4
 345
 346 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 347
 348 =item Return Value: L<$resultset|/search>
 349
 350 =back
 351
 352 This method does the same exact thing as search() except it will
 353 always return a resultset, even in list context.
 354
 355 =cut
 356
 357 sub search_rs {
 358   my $self = shift;
 359
 360   my $rsrc = $self->result_source;
 361   my ($call_cond, $call_attrs);
 362
 363   # Special-case handling for (undef, undef) or (undef)
 364   # Note that (foo => undef) is valid deprecated syntax
 365   @_ = () if not scalar grep { defined $_ } @_;
 366
 367   # just a cond
 368   if (@_ == 1) {
 369     $call_cond = shift;
 370   }
 371   # fish out attrs in the ($condref, $attr) case
 372   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 373     ($call_cond, $call_attrs) = @_;
 374   }
 375   elsif (@_ % 2) {
 376     $self->throw_exception('Odd number of arguments to search')
 377   }
 378   # legacy search
 379   elsif (@_) {
 380     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 381       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 382
 383     for my $i (0 .. $#_) {
 384       next if $i % 2;
 385       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 386         if (! defined $_[$i] or ref $_[$i] ne '');
 387     }
 388
 389     $call_cond = { @_ };
 390   }
 391
 392   # see if we can keep the cache (no $rs changes)
 393   my $cache;
 394   my %safe = (alias => 1, cache => 1);
 395   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 396     ! defined $_[0]
 397       or
 398     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 399       or
 400     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 401   )) {
 402     $cache = $self->get_cache;
 403   }
 404
 405   my $old_attrs = { %{$self->{attrs}} };
 406   my $old_having = delete $old_attrs->{having};
 407   my $old_where = delete $old_attrs->{where};
 408
 409   my $new_attrs = { %$old_attrs };
 410
 411   # take care of call attrs (only if anything is changing)
 412   if ($call_attrs and keys %$call_attrs) {
 413
 414     # copy for _normalize_selection
 415     $call_attrs = { %$call_attrs };
 416
 417     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 418
 419     # reset the current selector list if new selectors are supplied
 420     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 421       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 422     }
 423
 424     # Normalize the new selector list (operates on the passed-in attr structure)
 425     # Need to do it on every chain instead of only once on _resolved_attrs, in
 426     # order to allow detection of empty vs partial 'as'
 427     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 428       if $old_attrs->{_dark_selector};
 429     $self->_normalize_selection ($call_attrs);
 430
 431     # start with blind overwriting merge, exclude selector attrs
 432     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 433     delete @{$new_attrs}{@selector_attrs};
 434
 435     for (@selector_attrs) {
 436       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 437         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 438     }
 439
 440     # older deprecated name, use only if {columns} is not there
 441     if (my $c = delete $new_attrs->{cols}) {
 442       if ($new_attrs->{columns}) {
 443         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 444       }
 445       else {
 446         $new_attrs->{columns} = $c;
 447       }
 448     }
 449
 450
 451     # join/prefetch use their own crazy merging heuristics
 452     foreach my $key (qw/join prefetch/) {
 453       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 454         if exists $call_attrs->{$key};
 455     }
 456
 457     # stack binds together
 458     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 459   }
 460
 461
 462   for ($old_where, $call_cond) {
 463     if (defined $_) {
 464       $new_attrs->{where} = $self->_stack_cond (
 465         $_, $new_attrs->{where}
 466       );
 467     }
 468   }
 469
 470   if (defined $old_having) {
 471     $new_attrs->{having} = $self->_stack_cond (
 472       $old_having, $new_attrs->{having}
 473     )
 474   }
 475
 476   my $rs = (ref $self)->new($rsrc, $new_attrs);
 477
 478   $rs->set_cache($cache) if ($cache);
 479
 480   return $rs;
 481 }
 482
 483 my $dark_sel_dumper;
 484 sub _normalize_selection {
 485   my ($self, $attrs) = @_;
 486
 487   # legacy syntax
 488   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 489     if exists $attrs->{include_columns};
 490
 491   # columns are always placed first, however
 492
 493   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 494   # delay the decision on whether to use a default select list ($rsrc->columns)
 495   # allowing stuff like the remove_columns helper to work
 496   #
 497   # select/as +select/+as pairs need special handling - the amount of select/as
 498   # elements in each pair does *not* have to be equal (think multicolumn
 499   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 500   # supplied at all) - try to infer the alias, either from the -as parameter
 501   # of the selector spec, or use the parameter whole if it looks like a column
 502   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 503   # is ok as well), but make sure no more additions to the 'as' chain take place
 504   for my $pref ('', '+') {
 505
 506     my ($sel, $as) = map {
 507       my $key = "${pref}${_}";
 508
 509       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 510         ? @{$attrs->{$key}}
 511         : $attrs->{$key} || ()
 512       ];
 513       delete $attrs->{$key};
 514       $val;
 515     } qw/select as/;
 516
 517     if (! @$as and ! @$sel ) {
 518       next;
 519     }
 520     elsif (@$as and ! @$sel) {
 521       $self->throw_exception(
 522         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 523       );
 524     }
 525     elsif( ! @$as ) {
 526       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 527       # if any @$as has been supplied we assume the user knows what (s)he is doing
 528       # and blindly keep stacking up pieces
 529       unless ($attrs->{_dark_selector}) {
 530         SELECTOR:
 531         for (@$sel) {
 532           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 533             push @$as, $_->{-as};
 534           }
 535           # assume any plain no-space, no-parenthesis string to be a column spec
 536           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 537           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 538             push @$as, $_;
 539           }
 540           # if all else fails - raise a flag that no more aliasing will be allowed
 541           else {
 542             $attrs->{_dark_selector} = {
 543               plus_stage => $pref,
 544               string => ($dark_sel_dumper ||= do {
 545                   require Data::Dumper::Concise;
 546                   Data::Dumper::Concise::DumperObject()->Indent(0);
 547                 })->Values([$_])->Dump
 548               ,
 549             };
 550             last SELECTOR;
 551           }
 552         }
 553       }
 554     }
 555     elsif (@$as < @$sel) {
 556       $self->throw_exception(
 557         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 558       );
 559     }
 560     elsif ($pref and $attrs->{_dark_selector}) {
 561       $self->throw_exception(
 562         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 563       );
 564     }
 565
 566
 567     # merge result
 568     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 569     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 570   }
 571 }
 572
 573 sub _stack_cond {
 574   my ($self, $left, $right) = @_;
 575
 576   # collapse single element top-level conditions
 577   # (single pass only, unlikely to need recursion)
 578   for ($left, $right) {
 579     if (ref $_ eq 'ARRAY') {
 580       if (@$_ == 0) {
 581         $_ = undef;
 582       }
 583       elsif (@$_ == 1) {
 584         $_ = $_->[0];
 585       }
 586     }
 587     elsif (ref $_ eq 'HASH') {
 588       my ($first, $more) = keys %$_;
 589
 590       # empty hash
 591       if (! defined $first) {
 592         $_ = undef;
 593       }
 594       # one element hash
 595       elsif (! defined $more) {
 596         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 597           $_ = $_->{'-and'};
 598         }
 599         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 600           $_ = $_->{'-or'};
 601         }
 602       }
 603     }
 604   }
 605
 606   # merge hashes with weeding out of duplicates (simple cases only)
 607   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 608
 609     # shallow copy to destroy
 610     $right = { %$right };
 611     for (grep { exists $right->{$_} } keys %$left) {
 612       # the use of eq_deeply here is justified - the rhs of an
 613       # expression can contain a lot of twisted weird stuff
 614       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 615     }
 616
 617     $right = undef unless keys %$right;
 618   }
 619
 620
 621   if (defined $left xor defined $right) {
 622     return defined $left ? $left : $right;
 623   }
 624   elsif (! defined $left) {
 625     return undef;
 626   }
 627   else {
 628     return { -and => [ $left, $right ] };
 629   }
 630 }
 631
 632 =head2 search_literal
 633
 634 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 635 should only be used in that context. C<search_literal> is a convenience
 636 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 637 want to ensure columns are bound correctly, use L</search>.
 638
 639 See L<DBIx::Class::Manual::Cookbook/Searching> and
 640 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 641 require C<search_literal>.
 642
 643 =over 4
 644
 645 =item Arguments: $sql_fragment, @standalone_bind_values
 646
 647 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 648
 649 =back
 650
 651   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 652   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 653
 654 Pass a literal chunk of SQL to be added to the conditional part of the
 655 resultset query.
 656
 657 Example of how to use C<search> instead of C<search_literal>
 658
 659   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 660   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 661
 662 =cut
 663
 664 sub search_literal {
 665   my ($self, $sql, @bind) = @_;
 666   my $attr;
 667   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 668     $attr = pop @bind;
 669   }
 670   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 671 }
 672
 673 =head2 find
 674
 675 =over 4
 676
 677 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 678
 679 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 680
 681 =back
 682
 683 Finds and returns a single row based on supplied criteria. Takes either a
 684 hashref with the same format as L</create> (including inference of foreign
 685 keys from related objects), or a list of primary key values in the same
 686 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 687 declaration on the L</result_source>.
 688
 689 In either case an attempt is made to combine conditions already existing on
 690 the resultset with the condition passed to this method.
 691
 692 To aid with preparing the correct query for the storage you may supply the
 693 C<key> attribute, which is the name of a
 694 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 695 unique constraint corresponding to the
 696 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 697 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 698 to construct a query that satisfies the named unique constraint fully (
 699 non-NULL values for each column member of the constraint) an exception is
 700 thrown.
 701
 702 If no C<key> is specified, the search is carried over all unique constraints
 703 which are fully defined by the available condition.
 704
 705 If no such constraint is found, C<find> currently defaults to a simple
 706 C<< search->(\%column_values) >> which may or may not do what you expect.
 707 Note that this fallback behavior may be deprecated in further versions. If
 708 you need to search with arbitrary conditions - use L</search>. If the query
 709 resulting from this fallback produces more than one row, a warning to the
 710 effect is issued, though only the first row is constructed and returned as
 711 C<$result_object>.
 712
 713 In addition to C<key>, L</find> recognizes and applies standard
 714 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 715
 716 Note that if you have extra concerns about the correctness of the resulting
 717 query you need to specify the C<key> attribute and supply the entire condition
 718 as an argument to find (since it is not always possible to perform the
 719 combination of the resultset condition with the supplied one, especially if
 720 the resultset condition contains literal sql).
 721
 722 For example, to find a row by its primary key:
 723
 724   my $cd = $schema->resultset('CD')->find(5);
 725
 726 You can also find a row by a specific unique constraint:
 727
 728   my $cd = $schema->resultset('CD')->find(
 729     {
 730       artist => 'Massive Attack',
 731       title  => 'Mezzanine',
 732     },
 733     { key => 'cd_artist_title' }
 734   );
 735
 736 See also L</find_or_create> and L</update_or_create>.
 737
 738 =cut
 739
 740 sub find {
 741   my $self = shift;
 742   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 743
 744   my $rsrc = $self->result_source;
 745
 746   my $constraint_name;
 747   if (exists $attrs->{key}) {
 748     $constraint_name = defined $attrs->{key}
 749       ? $attrs->{key}
 750       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 751     ;
 752   }
 753
 754   # Parse out the condition from input
 755   my $call_cond;
 756
 757   if (ref $_[0] eq 'HASH') {
 758     $call_cond = { %{$_[0]} };
 759   }
 760   else {
 761     # if only values are supplied we need to default to 'primary'
 762     $constraint_name = 'primary' unless defined $constraint_name;
 763
 764     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 765
 766     $self->throw_exception(
 767       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 768     ) unless @c_cols;
 769
 770     $self->throw_exception (
 771       'find() expects either a column/value hashref, or a list of values '
 772     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 773     ) unless @c_cols == @_;
 774
 775     $call_cond = {};
 776     @{$call_cond}{@c_cols} = @_;
 777   }
 778
 779   my %related;
 780   for my $key (keys %$call_cond) {
 781     if (
 782       my $keyref = ref($call_cond->{$key})
 783         and
 784       my $relinfo = $rsrc->relationship_info($key)
 785     ) {
 786       my $val = delete $call_cond->{$key};
 787
 788       next if $keyref eq 'ARRAY'; # has_many for multi_create
 789
 790       my $rel_q = $rsrc->_resolve_condition(
 791         $relinfo->{cond}, $val, $key, $key
 792       );
 793       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 794       @related{keys %$rel_q} = values %$rel_q;
 795     }
 796   }
 797
 798   # relationship conditions take precedence (?)
 799   @{$call_cond}{keys %related} = values %related;
 800
 801   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 802   my $final_cond;
 803   if (defined $constraint_name) {
 804     $final_cond = $self->_qualify_cond_columns (
 805
 806       $self->_build_unique_cond (
 807         $constraint_name,
 808         $call_cond,
 809       ),
 810
 811       $alias,
 812     );
 813   }
 814   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 815     # This means that we got here after a merger of relationship conditions
 816     # in ::Relationship::Base::search_related (the row method), and furthermore
 817     # the relationship is of the 'single' type. This means that the condition
 818     # provided by the relationship (already attached to $self) is sufficient,
 819     # as there can be only one row in the database that would satisfy the
 820     # relationship
 821   }
 822   else {
 823     # no key was specified - fall down to heuristics mode:
 824     # run through all unique queries registered on the resultset, and
 825     # 'OR' all qualifying queries together
 826     my (@unique_queries, %seen_column_combinations);
 827     for my $c_name ($rsrc->unique_constraint_names) {
 828       next if $seen_column_combinations{
 829         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 830       }++;
 831
 832       push @unique_queries, try {
 833         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 834       } || ();
 835     }
 836
 837     $final_cond = @unique_queries
 838       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 839       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 840     ;
 841   }
 842
 843   # Run the query, passing the result_class since it should propagate for find
 844   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 845   if ($rs->_resolved_attrs->{collapse}) {
 846     my $row = $rs->next;
 847     carp "Query returned more than one row" if $rs->next;
 848     return $row;
 849   }
 850   else {
 851     return $rs->single;
 852   }
 853 }
 854
 855 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 856 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 857 #
 858 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 859 # condition. It is provided for overrides until a saner way forward is devised
 860 #
 861 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 862 # the road. Please adjust your tests accordingly to catch this situation early
 863 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 864 #
 865 # The method will not be removed without an adequately complete replacement
 866 # for strict-mode enforcement
 867 sub _non_unique_find_fallback {
 868   my ($self, $cond, $attrs) = @_;
 869
 870   return $self->_qualify_cond_columns(
 871     $cond,
 872     exists $attrs->{alias}
 873       ? $attrs->{alias}
 874       : $self->{attrs}{alias}
 875   );
 876 }
 877
 878
 879 sub _qualify_cond_columns {
 880   my ($self, $cond, $alias) = @_;
 881
 882   my %aliased = %$cond;
 883   for (keys %aliased) {
 884     $aliased{"$alias.$_"} = delete $aliased{$_}
 885       if $_ !~ /\./;
 886   }
 887
 888   return \%aliased;
 889 }
 890
 891 sub _build_unique_cond {
 892   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 893
 894   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 895
 896   # combination may fail if $self->{cond} is non-trivial
 897   my ($final_cond) = try {
 898     $self->_merge_with_rscond ($extra_cond)
 899   } catch {
 900     +{ %$extra_cond }
 901   };
 902
 903   # trim out everything not in $columns
 904   $final_cond = { map {
 905     exists $final_cond->{$_}
 906       ? ( $_ => $final_cond->{$_} )
 907       : ()
 908   } @c_cols };
 909
 910   if (my @missing = grep
 911     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 912     (@c_cols)
 913   ) {
 914     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 915       $constraint_name,
 916       join (', ', map { "'$_'" } @missing),
 917     ) );
 918   }
 919
 920   if (
 921     !$croak_on_null
 922       and
 923     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 924       and
 925     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 926   ) {
 927     carp_unique ( sprintf (
 928       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 929     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 930     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 931       $constraint_name,
 932       join (', ', map { "'$_'" } @undefs),
 933     ));
 934   }
 935
 936   return $final_cond;
 937 }
 938
 939 =head2 search_related
 940
 941 =over 4
 942
 943 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 944
 945 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 946
 947 =back
 948
 949   $new_rs = $cd_rs->search_related('artist', {
 950     name => 'Emo-R-Us',
 951   });
 952
 953 Searches the specified relationship, optionally specifying a condition and
 954 attributes for matching records. See L</ATTRIBUTES> for more information.
 955
 956 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 957 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 958
 959 See also L</search_related_rs>.
 960
 961 =cut
 962
 963 sub search_related {
 964   return shift->related_resultset(shift)->search(@_);
 965 }
 966
 967 =head2 search_related_rs
 968
 969 This method works exactly the same as search_related, except that
 970 it guarantees a resultset, even in list context.
 971
 972 =cut
 973
 974 sub search_related_rs {
 975   return shift->related_resultset(shift)->search_rs(@_);
 976 }
 977
 978 =head2 cursor
 979
 980 =over 4
 981
 982 =item Arguments: none
 983
 984 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 985
 986 =back
 987
 988 Returns a storage-driven cursor to the given resultset. See
 989 L<DBIx::Class::Cursor> for more information.
 990
 991 =cut
 992
 993 sub cursor {
 994   my $self = shift;
 995
 996   return $self->{cursor} ||= do {
 997     my $attrs = { %{$self->_resolved_attrs } };
 998     $self->result_source->storage->select(
 999       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1000     );
1001   };
1002 }
1003
1004 =head2 single
1005
1006 =over 4
1007
1008 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1009
1010 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1011
1012 =back
1013
1014   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1015
1016 Inflates the first result without creating a cursor if the resultset has
1017 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1018 of L</search>.
1019
1020 While this method can take an optional search condition (just like L</search>)
1021 being a fast-code-path it does not recognize search attributes. If you need to
1022 add extra joins or similar, call L</search> and then chain-call L</single> on the
1023 L<DBIx::Class::ResultSet> returned.
1024
1025 =over
1026
1027 =item B<Note>
1028
1029 As of 0.08100, this method enforces the assumption that the preceding
1030 query returns only one row. If more than one row is returned, you will receive
1031 a warning:
1032
1033   Query returned more than one row
1034
1035 In this case, you should be using L</next> or L</find> instead, or if you really
1036 know what you are doing, use the L</rows> attribute to explicitly limit the size
1037 of the resultset.
1038
1039 This method will also throw an exception if it is called on a resultset prefetching
1040 has_many, as such a prefetch implies fetching multiple rows from the database in
1041 order to assemble the resulting object.
1042
1043 =back
1044
1045 =cut
1046
1047 sub single {
1048   my ($self, $where) = @_;
1049   if(@_ > 2) {
1050       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1051   }
1052
1053   my $attrs = { %{$self->_resolved_attrs} };
1054
1055   $self->throw_exception(
1056     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1057   ) if $attrs->{collapse};
1058
1059   if ($where) {
1060     if (defined $attrs->{where}) {
1061       $attrs->{where} = {
1062         '-and' =>
1063             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1064                $where, delete $attrs->{where} ]
1065       };
1066     } else {
1067       $attrs->{where} = $where;
1068     }
1069   }
1070
1071   my $data = [ $self->result_source->storage->select_single(
1072     $attrs->{from}, $attrs->{select},
1073     $attrs->{where}, $attrs
1074   )];
1075   return undef unless @$data;
1076   $self->{stashed_rows} = [ $data ];
1077   $self->_construct_objects->[0];
1078 }
1079
1080
1081 # _collapse_query
1082 #
1083 # Recursively collapse the query, accumulating values for each column.
1084
1085 sub _collapse_query {
1086   my ($self, $query, $collapsed) = @_;
1087
1088   $collapsed ||= {};
1089
1090   if (ref $query eq 'ARRAY') {
1091     foreach my $subquery (@$query) {
1092       next unless ref $subquery;  # -or
1093       $collapsed = $self->_collapse_query($subquery, $collapsed);
1094     }
1095   }
1096   elsif (ref $query eq 'HASH') {
1097     if (keys %$query and (keys %$query)[0] eq '-and') {
1098       foreach my $subquery (@{$query->{-and}}) {
1099         $collapsed = $self->_collapse_query($subquery, $collapsed);
1100       }
1101     }
1102     else {
1103       foreach my $col (keys %$query) {
1104         my $value = $query->{$col};
1105         $collapsed->{$col}{$value}++;
1106       }
1107     }
1108   }
1109
1110   return $collapsed;
1111 }
1112
1113 =head2 get_column
1114
1115 =over 4
1116
1117 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1118
1119 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1120
1121 =back
1122
1123   my $max_length = $rs->get_column('length')->max;
1124
1125 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1126
1127 =cut
1128
1129 sub get_column {
1130   my ($self, $column) = @_;
1131   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1132   return $new;
1133 }
1134
1135 =head2 search_like
1136
1137 =over 4
1138
1139 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1140
1141 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1142
1143 =back
1144
1145   # WHERE title LIKE '%blue%'
1146   $cd_rs = $rs->search_like({ title => '%blue%'});
1147
1148 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1149 that this is simply a convenience method retained for ex Class::DBI users.
1150 You most likely want to use L</search> with specific operators.
1151
1152 For more information, see L<DBIx::Class::Manual::Cookbook>.
1153
1154 This method is deprecated and will be removed in 0.09. Use L</search()>
1155 instead. An example conversion is:
1156
1157   ->search_like({ foo => 'bar' });
1158
1159   # Becomes
1160
1161   ->search({ foo => { like => 'bar' } });
1162
1163 =cut
1164
1165 sub search_like {
1166   my $class = shift;
1167   carp_unique (
1168     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1169    .' Instead use ->search({ x => { -like => "y%" } })'
1170    .' (note the outer pair of {}s - they are important!)'
1171   );
1172   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1173   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1174   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1175   return $class->search($query, { %$attrs });
1176 }
1177
1178 =head2 slice
1179
1180 =over 4
1181
1182 =item Arguments: $first, $last
1183
1184 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1185
1186 =back
1187
1188 Returns a resultset or object list representing a subset of elements from the
1189 resultset slice is called on. Indexes are from 0, i.e., to get the first
1190 three records, call:
1191
1192   my ($one, $two, $three) = $rs->slice(0, 2);
1193
1194 =cut
1195
1196 sub slice {
1197   my ($self, $min, $max) = @_;
1198   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1199   $attrs->{offset} = $self->{attrs}{offset} || 0;
1200   $attrs->{offset} += $min;
1201   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1202   return $self->search(undef, $attrs);
1203   #my $slice = (ref $self)->new($self->result_source, $attrs);
1204   #return (wantarray ? $slice->all : $slice);
1205 }
1206
1207 =head2 next
1208
1209 =over 4
1210
1211 =item Arguments: none
1212
1213 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1214
1215 =back
1216
1217 Returns the next element in the resultset (C<undef> is there is none).
1218
1219 Can be used to efficiently iterate over records in the resultset:
1220
1221   my $rs = $schema->resultset('CD')->search;
1222   while (my $cd = $rs->next) {
1223     print $cd->title;
1224   }
1225
1226 Note that you need to store the resultset object, and call C<next> on it.
1227 Calling C<< resultset('Table')->next >> repeatedly will always return the
1228 first record from the resultset.
1229
1230 =cut
1231
1232 sub next {
1233   my ($self) = @_;
1234
1235   if (my $cache = $self->get_cache) {
1236     $self->{all_cache_position} ||= 0;
1237     return $cache->[$self->{all_cache_position}++];
1238   }
1239
1240   if ($self->{attrs}{cache}) {
1241     delete $self->{pager};
1242     $self->{all_cache_position} = 1;
1243     return ($self->all)[0];
1244   }
1245
1246   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1247
1248   $self->{stashed_objects} = $self->_construct_objects
1249     or return undef;
1250
1251   return shift @{$self->{stashed_objects}};
1252 }
1253
1254 # Constructs as many objects as it can in one pass while respecting
1255 # cursor laziness. Several modes of operation:
1256 #
1257 # * Always builds everything present in @{$self->{stashed_rows}}
1258 # * If called with $fetch_all true - pulls everything off the cursor and
1259 #   builds all objects in one pass
1260 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1261 #   and if the resultset is ordered properly by the left side:
1262 #   * Fetches stuff off the cursor until the "master object" changes,
1263 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1264 #   OR
1265 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1266 #     was requested (there is no other way to collapse except for an
1267 #     eager cursor)
1268 # * If no collapse is requested - just get the next row, construct and
1269 #   return
1270 sub _construct_objects {
1271   my ($self, $fetch_all) = @_;
1272
1273   my $rsrc = $self->result_source;
1274   my $attrs = $self->_resolved_attrs;
1275
1276   if (!$fetch_all and ! $attrs->{order_by} and $attrs->{collapse}) {
1277     # default order for collapsing unless the user asked for something
1278     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} $rsrc->primary_columns ];
1279     $attrs->{_ordered_for_collapse} = 1;
1280     $attrs->{_order_is_artificial} = 1;
1281   }
1282
1283   my $cursor = $self->cursor;
1284
1285   # this will be used as both initial raw-row collector AND as a RV of
1286   # _construct_objects. Not regrowing the array twice matters a lot...
1287   # a suprising amount actually
1288   my $rows = delete $self->{stashed_rows};
1289
1290   if ($fetch_all) {
1291     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1292     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1293   }
1294   elsif( $attrs->{collapse} ) {
1295
1296     $attrs->{_ordered_for_collapse} = (!$attrs->{order_by}) ? 0 : do {
1297       my $st = $rsrc->schema->storage;
1298       my @ord_cols = map
1299         { $_->[0] }
1300         ( $st->_extract_order_criteria($attrs->{order_by}) )
1301       ;
1302
1303       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1304
1305       for (0 .. $#ord_cols) {
1306         if (
1307           ! $colinfos->{$ord_cols[$_]}
1308             or
1309           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1310         ) {
1311           splice @ord_cols, $_;
1312           last;
1313         }
1314       }
1315
1316       # since all we check here are the start of the order_by belonging to the
1317       # top level $rsrc, a present identifying set will mean that the resultset
1318       # is ordered by its leftmost table in a tsable manner
1319       (@ord_cols and $rsrc->_identifying_column_set({ map
1320         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1321         @ord_cols
1322       })) ? 1 : 0;
1323     } unless defined $attrs->{_ordered_for_collapse};
1324
1325     if (! $attrs->{_ordered_for_collapse}) {
1326       $fetch_all = 1;
1327
1328       # instead of looping over ->next, use ->all in stealth mode
1329       # *without* calling a ->reset afterwards
1330       # FIXME - encapsulation breach, got to be a better way
1331       if (! $cursor->{_done}) {
1332         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1333         $cursor->{_done} = 1;
1334       }
1335     }
1336   }
1337
1338   if (! $fetch_all and ! @{$rows||[]} ) {
1339     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1340     if (scalar (my @r = $cursor->next) ) {
1341       $rows = [ \@r ];
1342     }
1343   }
1344
1345   return undef unless @{$rows||[]};
1346
1347   my @extra_collapser_args;
1348   if ($attrs->{collapse} and ! $fetch_all ) {
1349
1350     @extra_collapser_args = (
1351       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1352       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1353       ($self->{stashed_rows} = []),                 # where does it stuff excess
1354     );
1355   }
1356
1357   # hotspot - skip the setter
1358   my $res_class = $self->_result_class;
1359
1360   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1361     $res_class->can ('inflate_result')
1362       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1363   };
1364
1365   my $infmap = $attrs->{as};
1366
1367   $self->{_result_inflator}{is_hri} = do { ( $inflator_cref == (
1368     require DBIx::Class::ResultClass::HashRefInflator
1369       &&
1370     DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1371   ) ) ? 1 : 0
1372   } unless defined $self->{_result_inflator}{is_hri};
1373
1374   if ($attrs->{_single_resultclass_inflation}) {
1375     # construct a much simpler array->hash folder for the one-table cases right here
1376     if ($self->{_result_inflator}{is_hri}) {
1377       for my $r (@$rows) {
1378         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1379       }
1380     }
1381     # FIXME SUBOPTIMAL this is a very very very hot spot
1382     # while rather optimal we can *still* do much better, by
1383     # building a smarter Row::inflate_result(), and
1384     # switch to feeding it data via a much leaner interface
1385     #
1386     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1387     # this particular resultset size
1388     elsif (@$rows < 60) {
1389       for my $r (@$rows) {
1390         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1391       }
1392     }
1393     else {
1394       eval sprintf (
1395         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1396         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1397       );
1398     }
1399   }
1400   # Special-case multi-object HRI (we always prune)
1401   elsif ($self->{_result_inflator}{is_hri}) {
1402     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1403       eval => 1,
1404       inflate_map => $infmap,
1405       selection => $attrs->{select},
1406       collapse => $attrs->{collapse},
1407       premultiplied => $attrs->{_main_source_premultiplied},
1408       hri_style => 1,
1409       prune_null_branches => 1,
1410     }) )->($rows, @extra_collapser_args);
1411   }
1412   # Regular multi-object
1413   else {
1414
1415     # The rationale is - if this is the ::Row inflator itself, or an around()
1416     # we do prune, because we expect it.
1417     # If not the case - let the user deal with the full output themselves
1418     # Warn them while we are at it so we get a better idea what is out there
1419     # on the DarkPan
1420     $self->{_result_inflator}{prune_null_branches} = do {
1421       $res_class->isa('DBIx::Class::Row')
1422     } ? 1 : 0 unless defined $self->{_result_inflator}{prune_null_branches};
1423
1424     unless ($self->{_result_inflator}{prune_null_branches}) {
1425       carp_once (
1426         "ResultClass $res_class does not inherit from DBIx::Class::Row and "
1427       . 'therefore its inflate_result() will receive the full prefetched data '
1428       . 'tree, without any branch definedness checks. This is a compatibility '
1429       . 'measure which will eventually disappear entirely. Please refer to '
1430       . 't/resultset/inflate_result_api.t for an exhaustive description of the '
1431       . 'upcoming changes'
1432       );
1433     }
1434
1435     ( $self->{_row_parser}{classic}{$self->{_result_inflator}{prune_null_branches}} ||= $rsrc->_mk_row_parser({
1436       eval => 1,
1437       inflate_map => $infmap,
1438       selection => $attrs->{select},
1439       collapse => $attrs->{collapse},
1440       premultiplied => $attrs->{_main_source_premultiplied},
1441       prune_null_branches => $self->{_result_inflator}{prune_null_branches},
1442     }) )->($rows, @extra_collapser_args);
1443
1444     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1445   }
1446
1447   # CDBI compat stuff
1448   if ($attrs->{record_filter}) {
1449     $_ = $attrs->{record_filter}->($_) for @$rows;
1450   }
1451
1452   return $rows;
1453 }
1454
1455 =head2 result_source
1456
1457 =over 4
1458
1459 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1460
1461 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1462
1463 =back
1464
1465 An accessor for the primary ResultSource object from which this ResultSet
1466 is derived.
1467
1468 =head2 result_class
1469
1470 =over 4
1471
1472 =item Arguments: $result_class?
1473
1474 =item Return Value: $result_class
1475
1476 =back
1477
1478 An accessor for the class to use when creating result objects. Defaults to
1479 C<< result_source->result_class >> - which in most cases is the name of the
1480 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1481
1482 Note that changing the result_class will also remove any components
1483 that were originally loaded in the source class via
1484 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1485 in the original source class will not run.
1486
1487 =cut
1488
1489 sub result_class {
1490   my ($self, $result_class) = @_;
1491   if ($result_class) {
1492
1493     unless (ref $result_class) { # don't fire this for an object
1494       $self->ensure_class_loaded($result_class);
1495     }
1496     $self->_result_class($result_class);
1497     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1498     # permit the user to set result class on one result set only; it only
1499     # chains if provided to search()
1500     #$self->{attrs}{result_class} = $result_class if ref $self;
1501
1502     delete $self->{_result_inflator};
1503   }
1504   $self->_result_class;
1505 }
1506
1507 =head2 count
1508
1509 =over 4
1510
1511 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1512
1513 =item Return Value: $count
1514
1515 =back
1516
1517 Performs an SQL C<COUNT> with the same query as the resultset was built
1518 with to find the number of elements. Passing arguments is equivalent to
1519 C<< $rs->search ($cond, \%attrs)->count >>
1520
1521 =cut
1522
1523 sub count {
1524   my $self = shift;
1525   return $self->search(@_)->count if @_ and defined $_[0];
1526   return scalar @{ $self->get_cache } if $self->get_cache;
1527
1528   my $attrs = { %{ $self->_resolved_attrs } };
1529
1530   # this is a little optimization - it is faster to do the limit
1531   # adjustments in software, instead of a subquery
1532   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1533
1534   my $crs;
1535   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1536     $crs = $self->_count_subq_rs ($attrs);
1537   }
1538   else {
1539     $crs = $self->_count_rs ($attrs);
1540   }
1541   my $count = $crs->next;
1542
1543   $count -= $offset if $offset;
1544   $count = $rows if $rows and $rows < $count;
1545   $count = 0 if ($count < 0);
1546
1547   return $count;
1548 }
1549
1550 =head2 count_rs
1551
1552 =over 4
1553
1554 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1555
1556 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1557
1558 =back
1559
1560 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1561 This can be very handy for subqueries:
1562
1563   ->search( { amount => $some_rs->count_rs->as_query } )
1564
1565 As with regular resultsets the SQL query will be executed only after
1566 the resultset is accessed via L</next> or L</all>. That would return
1567 the same single value obtainable via L</count>.
1568
1569 =cut
1570
1571 sub count_rs {
1572   my $self = shift;
1573   return $self->search(@_)->count_rs if @_;
1574
1575   # this may look like a lack of abstraction (count() does about the same)
1576   # but in fact an _rs *must* use a subquery for the limits, as the
1577   # software based limiting can not be ported if this $rs is to be used
1578   # in a subquery itself (i.e. ->as_query)
1579   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1580     return $self->_count_subq_rs;
1581   }
1582   else {
1583     return $self->_count_rs;
1584   }
1585 }
1586
1587 #
1588 # returns a ResultSetColumn object tied to the count query
1589 #
1590 sub _count_rs {
1591   my ($self, $attrs) = @_;
1592
1593   my $rsrc = $self->result_source;
1594   $attrs ||= $self->_resolved_attrs;
1595
1596   my $tmp_attrs = { %$attrs };
1597   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1598   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1599
1600   # overwrite the selector (supplied by the storage)
1601   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1602   $tmp_attrs->{as} = 'count';
1603
1604   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1605
1606   return $tmp_rs;
1607 }
1608
1609 #
1610 # same as above but uses a subquery
1611 #
1612 sub _count_subq_rs {
1613   my ($self, $attrs) = @_;
1614
1615   my $rsrc = $self->result_source;
1616   $attrs ||= $self->_resolved_attrs;
1617
1618   my $sub_attrs = { %$attrs };
1619   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1620   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1621
1622   # if we multi-prefetch we group_by something unique, as this is what we would
1623   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1624   if ( $attrs->{collapse}  ) {
1625     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1626       $rsrc->_identifying_column_set || $self->throw_exception(
1627         'Unable to construct a unique group_by criteria properly collapsing the '
1628       . 'has_many prefetch before count()'
1629       );
1630     } ]
1631   }
1632
1633   # Calculate subquery selector
1634   if (my $g = $sub_attrs->{group_by}) {
1635
1636     my $sql_maker = $rsrc->storage->sql_maker;
1637
1638     # necessary as the group_by may refer to aliased functions
1639     my $sel_index;
1640     for my $sel (@{$attrs->{select}}) {
1641       $sel_index->{$sel->{-as}} = $sel
1642         if (ref $sel eq 'HASH' and $sel->{-as});
1643     }
1644
1645     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1646     # also look for named aggregates referred in the having clause
1647     # having often contains scalarrefs - thus parse it out entirely
1648     my @parts = @$g;
1649     if ($attrs->{having}) {
1650       local $sql_maker->{having_bind};
1651       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1652       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1653       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1654         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1655         # if we don't unset it we screw up retarded but unfortunately working
1656         # 'MAX(foo.bar)' => { '>', 3 }
1657         $sql_maker->{name_sep} = '';
1658       }
1659
1660       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1661
1662       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1663       my %seen_having;
1664
1665       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1666       # and if all fails for an utterly naive quoted scalar-with-function
1667       while ($having_sql =~ /
1668         $rquote $sep $lquote (.+?) $rquote
1669           |
1670         [\s,] \w+ \. (\w+) [\s,]
1671           |
1672         [\s,] $lquote (.+?) $rquote [\s,]
1673       /gx) {
1674         my $part = $1 || $2 || $3;  # one of them matched if we got here
1675         unless ($seen_having{$part}++) {
1676           push @parts, $part;
1677         }
1678       }
1679     }
1680
1681     for (@parts) {
1682       my $colpiece = $sel_index->{$_} || $_;
1683
1684       # unqualify join-based group_by's. Arcane but possible query
1685       # also horrible horrible hack to alias a column (not a func.)
1686       # (probably need to introduce SQLA syntax)
1687       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1688         my $as = $colpiece;
1689         $as =~ s/\./__/;
1690         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1691       }
1692       push @{$sub_attrs->{select}}, $colpiece;
1693     }
1694   }
1695   else {
1696     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1697     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1698   }
1699
1700   return $rsrc->resultset_class
1701                ->new ($rsrc, $sub_attrs)
1702                 ->as_subselect_rs
1703                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1704                   ->get_column ('count');
1705 }
1706
1707 sub _bool {
1708   return 1;
1709 }
1710
1711 =head2 count_literal
1712
1713 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1714 should only be used in that context. See L</search_literal> for further info.
1715
1716 =over 4
1717
1718 =item Arguments: $sql_fragment, @standalone_bind_values
1719
1720 =item Return Value: $count
1721
1722 =back
1723
1724 Counts the results in a literal query. Equivalent to calling L</search_literal>
1725 with the passed arguments, then L</count>.
1726
1727 =cut
1728
1729 sub count_literal { shift->search_literal(@_)->count; }
1730
1731 =head2 all
1732
1733 =over 4
1734
1735 =item Arguments: none
1736
1737 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1738
1739 =back
1740
1741 Returns all elements in the resultset.
1742
1743 =cut
1744
1745 sub all {
1746   my $self = shift;
1747   if(@_) {
1748     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1749   }
1750
1751   delete @{$self}{qw/stashed_rows stashed_objects/};
1752
1753   if (my $c = $self->get_cache) {
1754     return @$c;
1755   }
1756
1757   $self->cursor->reset;
1758
1759   my $objs = $self->_construct_objects('fetch_all') || [];
1760
1761   $self->set_cache($objs) if $self->{attrs}{cache};
1762
1763   return @$objs;
1764 }
1765
1766 =head2 reset
1767
1768 =over 4
1769
1770 =item Arguments: none
1771
1772 =item Return Value: $self
1773
1774 =back
1775
1776 Resets the resultset's cursor, so you can iterate through the elements again.
1777 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1778 another query.
1779
1780 =cut
1781
1782 sub reset {
1783   my ($self) = @_;
1784
1785   delete @{$self}{qw/stashed_rows stashed_objects/};
1786   $self->{all_cache_position} = 0;
1787   $self->cursor->reset;
1788   return $self;
1789 }
1790
1791 =head2 first
1792
1793 =over 4
1794
1795 =item Arguments: none
1796
1797 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1798
1799 =back
1800
1801 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1802 an object for the first result (or C<undef> if the resultset is empty).
1803
1804 =cut
1805
1806 sub first {
1807   return $_[0]->reset->next;
1808 }
1809
1810
1811 # _rs_update_delete
1812 #
1813 # Determines whether and what type of subquery is required for the $rs operation.
1814 # If grouping is necessary either supplies its own, or verifies the current one
1815 # After all is done delegates to the proper storage method.
1816
1817 sub _rs_update_delete {
1818   my ($self, $op, $values) = @_;
1819
1820   my $rsrc = $self->result_source;
1821   my $storage = $rsrc->schema->storage;
1822
1823   my $attrs = { %{$self->_resolved_attrs} };
1824
1825   my $join_classifications;
1826   my $existing_group_by = delete $attrs->{group_by};
1827
1828   # do we need a subquery for any reason?
1829   my $needs_subq = (
1830     defined $existing_group_by
1831       or
1832     # if {from} is unparseable wrap a subq
1833     ref($attrs->{from}) ne 'ARRAY'
1834       or
1835     # limits call for a subq
1836     $self->_has_resolved_attr(qw/rows offset/)
1837   );
1838
1839   # simplify the joinmap, so we can further decide if a subq is necessary
1840   if (!$needs_subq and @{$attrs->{from}} > 1) {
1841     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1842
1843     # check if there are any joins left after the prune
1844     if ( @{$attrs->{from}} > 1 ) {
1845       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1846         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1847         $attrs->{select},
1848         $self->{cond},
1849         $attrs
1850       );
1851
1852       # any non-pruneable joins imply subq
1853       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1854     }
1855   }
1856
1857   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1858   $needs_subq ||= (
1859     (ref $attrs->{from}[0]) ne 'HASH'
1860       or
1861     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1862   );
1863
1864   my ($cond, $guard);
1865   # do we need anything like a subquery?
1866   if (! $needs_subq) {
1867     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1868     # a condition containing 'me' or other table prefixes will not work
1869     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1870     $cond = do {
1871       my $sqla = $rsrc->storage->sql_maker;
1872       local $sqla->{_dequalify_idents} = 1;
1873       \[ $sqla->_recurse_where($self->{cond}) ];
1874     };
1875   }
1876   else {
1877     # we got this far - means it is time to wrap a subquery
1878     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1879       sprintf(
1880         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1881         $op,
1882         $rsrc->source_name,
1883       )
1884     );
1885
1886     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1887     delete $attrs->{$_} for qw/collapse select _prefetch_selector_range as/;
1888     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1889     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1890     my $subrs = (ref $self)->new($rsrc, $attrs);
1891
1892     if (@$idcols == 1) {
1893       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1894     }
1895     elsif ($storage->_use_multicolumn_in) {
1896       # no syntax for calling this properly yet
1897       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1898       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1899         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1900         $subrs->as_query
1901       ),
1902     }
1903     else {
1904       # if all else fails - get all primary keys and operate over a ORed set
1905       # wrap in a transaction for consistency
1906       # this is where the group_by/multiplication starts to matter
1907       if (
1908         $existing_group_by
1909           or
1910         keys %{ $join_classifications->{multiplying} || {} }
1911       ) {
1912         # make sure if there is a supplied group_by it matches the columns compiled above
1913         # perfectly. Anything else can not be sanely executed on most databases so croak
1914         # right then and there
1915         if ($existing_group_by) {
1916           my @current_group_by = map
1917             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1918             @$existing_group_by
1919           ;
1920
1921           if (
1922             join ("\x00", sort @current_group_by)
1923               ne
1924             join ("\x00", sort @{$attrs->{columns}} )
1925           ) {
1926             $self->throw_exception (
1927               "You have just attempted a $op operation on a resultset which does group_by"
1928               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1929               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1930               . ' kind of queries. Please retry the operation with a modified group_by or'
1931               . ' without using one at all.'
1932             );
1933           }
1934         }
1935
1936         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1937       }
1938
1939       $guard = $storage->txn_scope_guard;
1940
1941       $cond = [];
1942       for my $row ($subrs->cursor->all) {
1943         push @$cond, { map
1944           { $idcols->[$_] => $row->[$_] }
1945           (0 .. $#$idcols)
1946         };
1947       }
1948     }
1949   }
1950
1951   my $res = $storage->$op (
1952     $rsrc,
1953     $op eq 'update' ? $values : (),
1954     $cond,
1955   );
1956
1957   $guard->commit if $guard;
1958
1959   return $res;
1960 }
1961
1962 =head2 update
1963
1964 =over 4
1965
1966 =item Arguments: \%values
1967
1968 =item Return Value: $underlying_storage_rv
1969
1970 =back
1971
1972 Sets the specified columns in the resultset to the supplied values in a
1973 single query. Note that this will not run any accessor/set_column/update
1974 triggers, nor will it update any result object instances derived from this
1975 resultset (this includes the contents of the L<resultset cache|/set_cache>
1976 if any). See L</update_all> if you need to execute any on-update
1977 triggers or cascades defined either by you or a
1978 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1979
1980 The return value is a pass through of what the underlying
1981 storage backend returned, and may vary. See L<DBI/execute> for the most
1982 common case.
1983
1984 =head3 CAVEAT
1985
1986 Note that L</update> does not process/deflate any of the values passed in.
1987 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1988 ensure manually that any value passed to this method will stringify to
1989 something the RDBMS knows how to deal with. A notable example is the
1990 handling of L<DateTime> objects, for more info see:
1991 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1992
1993 =cut
1994
1995 sub update {
1996   my ($self, $values) = @_;
1997   $self->throw_exception('Values for update must be a hash')
1998     unless ref $values eq 'HASH';
1999
2000   return $self->_rs_update_delete ('update', $values);
2001 }
2002
2003 =head2 update_all
2004
2005 =over 4
2006
2007 =item Arguments: \%values
2008
2009 =item Return Value: 1
2010
2011 =back
2012
2013 Fetches all objects and updates them one at a time via
2014 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2015 triggers, while L</update> will not.
2016
2017 =cut
2018
2019 sub update_all {
2020   my ($self, $values) = @_;
2021   $self->throw_exception('Values for update_all must be a hash')
2022     unless ref $values eq 'HASH';
2023
2024   my $guard = $self->result_source->schema->txn_scope_guard;
2025   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2026   $guard->commit;
2027   return 1;
2028 }
2029
2030 =head2 delete
2031
2032 =over 4
2033
2034 =item Arguments: none
2035
2036 =item Return Value: $underlying_storage_rv
2037
2038 =back
2039
2040 Deletes the rows matching this resultset in a single query. Note that this
2041 will not run any delete triggers, nor will it alter the
2042 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2043 derived from this resultset (this includes the contents of the
2044 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2045 execute any on-delete triggers or cascades defined either by you or a
2046 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2047
2048 The return value is a pass through of what the underlying storage backend
2049 returned, and may vary. See L<DBI/execute> for the most common case.
2050
2051 =cut
2052
2053 sub delete {
2054   my $self = shift;
2055   $self->throw_exception('delete does not accept any arguments')
2056     if @_;
2057
2058   return $self->_rs_update_delete ('delete');
2059 }
2060
2061 =head2 delete_all
2062
2063 =over 4
2064
2065 =item Arguments: none
2066
2067 =item Return Value: 1
2068
2069 =back
2070
2071 Fetches all objects and deletes them one at a time via
2072 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2073 triggers, while L</delete> will not.
2074
2075 =cut
2076
2077 sub delete_all {
2078   my $self = shift;
2079   $self->throw_exception('delete_all does not accept any arguments')
2080     if @_;
2081
2082   my $guard = $self->result_source->schema->txn_scope_guard;
2083   $_->delete for $self->all;
2084   $guard->commit;
2085   return 1;
2086 }
2087
2088 =head2 populate
2089
2090 =over 4
2091
2092 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2093
2094 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2095
2096 =back
2097
2098 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2099 arrayrefs.
2100
2101 =over
2102
2103 =item NOTE
2104
2105 The context of this method call has an important effect on what is
2106 submitted to storage. In void context data is fed directly to fastpath
2107 insertion routines provided by the underlying storage (most often
2108 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2109 L<insert|DBIx::Class::Row/insert> calls on the
2110 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2111 augmentation of these methods provided by components. For example if you
2112 are using something like L<DBIx::Class::UUIDColumns> to create primary
2113 keys for you, you will find that your PKs are empty.  In this case you
2114 will have to explicitly force scalar or list context in order to create
2115 those values.
2116
2117 =back
2118
2119 In non-void (scalar or list) context, this method is simply a wrapper
2120 for L</create>. Depending on list or scalar context either a list of
2121 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2122 containing these objects is returned.
2123
2124 When supplying data in "arrayref of arrayrefs" invocation style, the
2125 first element should be a list of column names and each subsequent
2126 element should be a data value in the earlier specified column order.
2127 For example:
2128
2129   $Arstist_rs->populate([
2130     [ qw( artistid name ) ],
2131     [ 100, 'A Formally Unknown Singer' ],
2132     [ 101, 'A singer that jumped the shark two albums ago' ],
2133     [ 102, 'An actually cool singer' ],
2134   ]);
2135
2136 For the arrayref of hashrefs style each hashref should be a structure
2137 suitable for passing to L</create>. Multi-create is also permitted with
2138 this syntax.
2139
2140   $schema->resultset("Artist")->populate([
2141      { artistid => 4, name => 'Manufactured Crap', cds => [
2142         { title => 'My First CD', year => 2006 },
2143         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2144       ],
2145      },
2146      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2147         { title => 'My parents sold me to a record company', year => 2005 },
2148         { title => 'Why Am I So Ugly?', year => 2006 },
2149         { title => 'I Got Surgery and am now Popular', year => 2007 }
2150       ],
2151      },
2152   ]);
2153
2154 If you attempt a void-context multi-create as in the example above (each
2155 Artist also has the related list of CDs), and B<do not> supply the
2156 necessary autoinc foreign key information, this method will proxy to the
2157 less efficient L</create>, and then throw the Result objects away. In this
2158 case there are obviously no benefits to using this method over L</create>.
2159
2160 =cut
2161
2162 sub populate {
2163   my $self = shift;
2164
2165   # cruft placed in standalone method
2166   my $data = $self->_normalize_populate_args(@_);
2167
2168   return unless @$data;
2169
2170   if(defined wantarray) {
2171     my @created = map { $self->create($_) } @$data;
2172     return wantarray ? @created : \@created;
2173   }
2174   else {
2175     my $first = $data->[0];
2176
2177     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2178     # it relationship data
2179     my (@rels, @columns);
2180     my $rsrc = $self->result_source;
2181     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2182     for (keys %$first) {
2183       my $ref = ref $first->{$_};
2184       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2185         ? push @rels, $_
2186         : push @columns, $_
2187       ;
2188     }
2189
2190     my @pks = $rsrc->primary_columns;
2191
2192     ## do the belongs_to relationships
2193     foreach my $index (0..$#$data) {
2194
2195       # delegate to create() for any dataset without primary keys with specified relationships
2196       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2197         for my $r (@rels) {
2198           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2199             my @ret = $self->populate($data);
2200             return;
2201           }
2202         }
2203       }
2204
2205       foreach my $rel (@rels) {
2206         next unless ref $data->[$index]->{$rel} eq "HASH";
2207         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2208         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2209         my $related = $result->result_source->_resolve_condition(
2210           $reverse_relinfo->{cond},
2211           $self,
2212           $result,
2213           $rel,
2214         );
2215
2216         delete $data->[$index]->{$rel};
2217         $data->[$index] = {%{$data->[$index]}, %$related};
2218
2219         push @columns, keys %$related if $index == 0;
2220       }
2221     }
2222
2223     ## inherit the data locked in the conditions of the resultset
2224     my ($rs_data) = $self->_merge_with_rscond({});
2225     delete @{$rs_data}{@columns};
2226
2227     ## do bulk insert on current row
2228     $rsrc->storage->insert_bulk(
2229       $rsrc,
2230       [@columns, keys %$rs_data],
2231       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2232     );
2233
2234     ## do the has_many relationships
2235     foreach my $item (@$data) {
2236
2237       my $main_row;
2238
2239       foreach my $rel (@rels) {
2240         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2241
2242         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2243
2244         my $child = $main_row->$rel;
2245
2246         my $related = $child->result_source->_resolve_condition(
2247           $rels->{$rel}{cond},
2248           $child,
2249           $main_row,
2250           $rel,
2251         );
2252
2253         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2254         my @populate = map { {%$_, %$related} } @rows_to_add;
2255
2256         $child->populate( \@populate );
2257       }
2258     }
2259   }
2260 }
2261
2262
2263 # populate() argumnets went over several incarnations
2264 # What we ultimately support is AoH
2265 sub _normalize_populate_args {
2266   my ($self, $arg) = @_;
2267
2268   if (ref $arg eq 'ARRAY') {
2269     if (!@$arg) {
2270       return [];
2271     }
2272     elsif (ref $arg->[0] eq 'HASH') {
2273       return $arg;
2274     }
2275     elsif (ref $arg->[0] eq 'ARRAY') {
2276       my @ret;
2277       my @colnames = @{$arg->[0]};
2278       foreach my $values (@{$arg}[1 .. $#$arg]) {
2279         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2280       }
2281       return \@ret;
2282     }
2283   }
2284
2285   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2286 }
2287
2288 =head2 pager
2289
2290 =over 4
2291
2292 =item Arguments: none
2293
2294 =item Return Value: L<$pager|Data::Page>
2295
2296 =back
2297
2298 Returns a L<Data::Page> object for the current resultset. Only makes
2299 sense for queries with a C<page> attribute.
2300
2301 To get the full count of entries for a paged resultset, call
2302 C<total_entries> on the L<Data::Page> object.
2303
2304 =cut
2305
2306 sub pager {
2307   my ($self) = @_;
2308
2309   return $self->{pager} if $self->{pager};
2310
2311   my $attrs = $self->{attrs};
2312   if (!defined $attrs->{page}) {
2313     $self->throw_exception("Can't create pager for non-paged rs");
2314   }
2315   elsif ($attrs->{page} <= 0) {
2316     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2317   }
2318   $attrs->{rows} ||= 10;
2319
2320   # throw away the paging flags and re-run the count (possibly
2321   # with a subselect) to get the real total count
2322   my $count_attrs = { %$attrs };
2323   delete @{$count_attrs}{qw/rows offset page pager/};
2324
2325   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2326
2327   require DBIx::Class::ResultSet::Pager;
2328   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2329     sub { $total_rs->count },  #lazy-get the total
2330     $attrs->{rows},
2331     $self->{attrs}{page},
2332   );
2333 }
2334
2335 =head2 page
2336
2337 =over 4
2338
2339 =item Arguments: $page_number
2340
2341 =item Return Value: L<$resultset|/search>
2342
2343 =back
2344
2345 Returns a resultset for the $page_number page of the resultset on which page
2346 is called, where each page contains a number of rows equal to the 'rows'
2347 attribute set on the resultset (10 by default).
2348
2349 =cut
2350
2351 sub page {
2352   my ($self, $page) = @_;
2353   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2354 }
2355
2356 =head2 new_result
2357
2358 =over 4
2359
2360 =item Arguments: \%col_data
2361
2362 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2363
2364 =back
2365
2366 Creates a new result object in the resultset's result class and returns
2367 it. The row is not inserted into the database at this point, call
2368 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2369 will tell you whether the result object has been inserted or not.
2370
2371 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2372
2373 =cut
2374
2375 sub new_result {
2376   my ($self, $values) = @_;
2377
2378   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2379     if @_ > 2;
2380
2381   $self->throw_exception( "new_result expects a hashref" )
2382     unless (ref $values eq 'HASH');
2383
2384   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2385
2386   my %new = (
2387     %$merged_cond,
2388     @$cols_from_relations
2389       ? (-cols_from_relations => $cols_from_relations)
2390       : (),
2391     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2392   );
2393
2394   return $self->result_class->new(\%new);
2395 }
2396
2397 # _merge_with_rscond
2398 #
2399 # Takes a simple hash of K/V data and returns its copy merged with the
2400 # condition already present on the resultset. Additionally returns an
2401 # arrayref of value/condition names, which were inferred from related
2402 # objects (this is needed for in-memory related objects)
2403 sub _merge_with_rscond {
2404   my ($self, $data) = @_;
2405
2406   my (%new_data, @cols_from_relations);
2407
2408   my $alias = $self->{attrs}{alias};
2409
2410   if (! defined $self->{cond}) {
2411     # just massage $data below
2412   }
2413   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2414     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2415     @cols_from_relations = keys %new_data;
2416   }
2417   elsif (ref $self->{cond} ne 'HASH') {
2418     $self->throw_exception(
2419       "Can't abstract implicit construct, resultset condition not a hash"
2420     );
2421   }
2422   else {
2423     # precendence must be given to passed values over values inherited from
2424     # the cond, so the order here is important.
2425     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2426     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2427
2428     while ( my($col, $value) = each %implied ) {
2429       my $vref = ref $value;
2430       if (
2431         $vref eq 'HASH'
2432           and
2433         keys(%$value) == 1
2434           and
2435         (keys %$value)[0] eq '='
2436       ) {
2437         $new_data{$col} = $value->{'='};
2438       }
2439       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2440         $new_data{$col} = $value;
2441       }
2442     }
2443   }
2444
2445   %new_data = (
2446     %new_data,
2447     %{ $self->_remove_alias($data, $alias) },
2448   );
2449
2450   return (\%new_data, \@cols_from_relations);
2451 }
2452
2453 # _has_resolved_attr
2454 #
2455 # determines if the resultset defines at least one
2456 # of the attributes supplied
2457 #
2458 # used to determine if a subquery is neccessary
2459 #
2460 # supports some virtual attributes:
2461 #   -join
2462 #     This will scan for any joins being present on the resultset.
2463 #     It is not a mere key-search but a deep inspection of {from}
2464 #
2465
2466 sub _has_resolved_attr {
2467   my ($self, @attr_names) = @_;
2468
2469   my $attrs = $self->_resolved_attrs;
2470
2471   my %extra_checks;
2472
2473   for my $n (@attr_names) {
2474     if (grep { $n eq $_ } (qw/-join/) ) {
2475       $extra_checks{$n}++;
2476       next;
2477     }
2478
2479     my $attr =  $attrs->{$n};
2480
2481     next if not defined $attr;
2482
2483     if (ref $attr eq 'HASH') {
2484       return 1 if keys %$attr;
2485     }
2486     elsif (ref $attr eq 'ARRAY') {
2487       return 1 if @$attr;
2488     }
2489     else {
2490       return 1 if $attr;
2491     }
2492   }
2493
2494   # a resolved join is expressed as a multi-level from
2495   return 1 if (
2496     $extra_checks{-join}
2497       and
2498     ref $attrs->{from} eq 'ARRAY'
2499       and
2500     @{$attrs->{from}} > 1
2501   );
2502
2503   return 0;
2504 }
2505
2506 # _collapse_cond
2507 #
2508 # Recursively collapse the condition.
2509
2510 sub _collapse_cond {
2511   my ($self, $cond, $collapsed) = @_;
2512
2513   $collapsed ||= {};
2514
2515   if (ref $cond eq 'ARRAY') {
2516     foreach my $subcond (@$cond) {
2517       next unless ref $subcond;  # -or
2518       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2519     }
2520   }
2521   elsif (ref $cond eq 'HASH') {
2522     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2523       foreach my $subcond (@{$cond->{-and}}) {
2524         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2525       }
2526     }
2527     else {
2528       foreach my $col (keys %$cond) {
2529         my $value = $cond->{$col};
2530         $collapsed->{$col} = $value;
2531       }
2532     }
2533   }
2534
2535   return $collapsed;
2536 }
2537
2538 # _remove_alias
2539 #
2540 # Remove the specified alias from the specified query hash. A copy is made so
2541 # the original query is not modified.
2542
2543 sub _remove_alias {
2544   my ($self, $query, $alias) = @_;
2545
2546   my %orig = %{ $query || {} };
2547   my %unaliased;
2548
2549   foreach my $key (keys %orig) {
2550     if ($key !~ /\./) {
2551       $unaliased{$key} = $orig{$key};
2552       next;
2553     }
2554     $unaliased{$1} = $orig{$key}
2555       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2556   }
2557
2558   return \%unaliased;
2559 }
2560
2561 =head2 as_query
2562
2563 =over 4
2564
2565 =item Arguments: none
2566
2567 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2568
2569 =back
2570
2571 Returns the SQL query and bind vars associated with the invocant.
2572
2573 This is generally used as the RHS for a subquery.
2574
2575 =cut
2576
2577 sub as_query {
2578   my $self = shift;
2579
2580   my $attrs = { %{ $self->_resolved_attrs } };
2581
2582   # For future use:
2583   #
2584   # in list ctx:
2585   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2586   # $sql also has no wrapping parenthesis in list ctx
2587   #
2588   my $sqlbind = $self->result_source->storage
2589     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2590
2591   return $sqlbind;
2592 }
2593
2594 =head2 find_or_new
2595
2596 =over 4
2597
2598 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2599
2600 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2601
2602 =back
2603
2604   my $artist = $schema->resultset('Artist')->find_or_new(
2605     { artist => 'fred' }, { key => 'artists' });
2606
2607   $cd->cd_to_producer->find_or_new({ producer => $producer },
2608                                    { key => 'primary });
2609
2610 Find an existing record from this resultset using L</find>. if none exists,
2611 instantiate a new result object and return it. The object will not be saved
2612 into your storage until you call L<DBIx::Class::Row/insert> on it.
2613
2614 You most likely want this method when looking for existing rows using a unique
2615 constraint that is not the primary key, or looking for related rows.
2616
2617 If you want objects to be saved immediately, use L</find_or_create> instead.
2618
2619 B<Note>: Make sure to read the documentation of L</find> and understand the
2620 significance of the C<key> attribute, as its lack may skew your search, and
2621 subsequently result in spurious new objects.
2622
2623 B<Note>: Take care when using C<find_or_new> with a table having
2624 columns with default values that you intend to be automatically
2625 supplied by the database (e.g. an auto_increment primary key column).
2626 In normal usage, the value of such columns should NOT be included at
2627 all in the call to C<find_or_new>, even when set to C<undef>.
2628
2629 =cut
2630
2631 sub find_or_new {
2632   my $self     = shift;
2633   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2634   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2635   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2636     return $row;
2637   }
2638   return $self->new_result($hash);
2639 }
2640
2641 =head2 create
2642
2643 =over 4
2644
2645 =item Arguments: \%col_data
2646
2647 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2648
2649 =back
2650
2651 Attempt to create a single new row or a row with multiple related rows
2652 in the table represented by the resultset (and related tables). This
2653 will not check for duplicate rows before inserting, use
2654 L</find_or_create> to do that.
2655
2656 To create one row for this resultset, pass a hashref of key/value
2657 pairs representing the columns of the table and the values you wish to
2658 store. If the appropriate relationships are set up, foreign key fields
2659 can also be passed an object representing the foreign row, and the
2660 value will be set to its primary key.
2661
2662 To create related objects, pass a hashref of related-object column values
2663 B<keyed on the relationship name>. If the relationship is of type C<multi>
2664 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2665 The process will correctly identify columns holding foreign keys, and will
2666 transparently populate them from the keys of the corresponding relation.
2667 This can be applied recursively, and will work correctly for a structure
2668 with an arbitrary depth and width, as long as the relationships actually
2669 exists and the correct column data has been supplied.
2670
2671 Instead of hashrefs of plain related data (key/value pairs), you may
2672 also pass new or inserted objects. New objects (not inserted yet, see
2673 L</new_result>), will be inserted into their appropriate tables.
2674
2675 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2676
2677 Example of creating a new row.
2678
2679   $person_rs->create({
2680     name=>"Some Person",
2681     email=>"somebody@someplace.com"
2682   });
2683
2684 Example of creating a new row and also creating rows in a related C<has_many>
2685 or C<has_one> resultset.  Note Arrayref.
2686
2687   $artist_rs->create(
2688      { artistid => 4, name => 'Manufactured Crap', cds => [
2689         { title => 'My First CD', year => 2006 },
2690         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2691       ],
2692      },
2693   );
2694
2695 Example of creating a new row and also creating a row in a related
2696 C<belongs_to> resultset. Note Hashref.
2697
2698   $cd_rs->create({
2699     title=>"Music for Silly Walks",
2700     year=>2000,
2701     artist => {
2702       name=>"Silly Musician",
2703     }
2704   });
2705
2706 =over
2707
2708 =item WARNING
2709
2710 When subclassing ResultSet never attempt to override this method. Since
2711 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2712 lot of the internals simply never call it, so your override will be
2713 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2714 or L<DBIx::Class::Row/insert> depending on how early in the
2715 L</create> process you need to intervene. See also warning pertaining to
2716 L</new>.
2717
2718 =back
2719
2720 =cut
2721
2722 sub create {
2723   my ($self, $attrs) = @_;
2724   $self->throw_exception( "create needs a hashref" )
2725     unless ref $attrs eq 'HASH';
2726   return $self->new_result($attrs)->insert;
2727 }
2728
2729 =head2 find_or_create
2730
2731 =over 4
2732
2733 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2734
2735 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2736
2737 =back
2738
2739   $cd->cd_to_producer->find_or_create({ producer => $producer },
2740                                       { key => 'primary' });
2741
2742 Tries to find a record based on its primary key or unique constraints; if none
2743 is found, creates one and returns that instead.
2744
2745   my $cd = $schema->resultset('CD')->find_or_create({
2746     cdid   => 5,
2747     artist => 'Massive Attack',
2748     title  => 'Mezzanine',
2749     year   => 2005,
2750   });
2751
2752 Also takes an optional C<key> attribute, to search by a specific key or unique
2753 constraint. For example:
2754
2755   my $cd = $schema->resultset('CD')->find_or_create(
2756     {
2757       artist => 'Massive Attack',
2758       title  => 'Mezzanine',
2759     },
2760     { key => 'cd_artist_title' }
2761   );
2762
2763 B<Note>: Make sure to read the documentation of L</find> and understand the
2764 significance of the C<key> attribute, as its lack may skew your search, and
2765 subsequently result in spurious row creation.
2766
2767 B<Note>: Because find_or_create() reads from the database and then
2768 possibly inserts based on the result, this method is subject to a race
2769 condition. Another process could create a record in the table after
2770 the find has completed and before the create has started. To avoid
2771 this problem, use find_or_create() inside a transaction.
2772
2773 B<Note>: Take care when using C<find_or_create> with a table having
2774 columns with default values that you intend to be automatically
2775 supplied by the database (e.g. an auto_increment primary key column).
2776 In normal usage, the value of such columns should NOT be included at
2777 all in the call to C<find_or_create>, even when set to C<undef>.
2778
2779 See also L</find> and L</update_or_create>. For information on how to declare
2780 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2781
2782 If you need to know if an existing row was found or a new one created use
2783 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2784 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2785 database!
2786
2787   my $cd = $schema->resultset('CD')->find_or_new({
2788     cdid   => 5,
2789     artist => 'Massive Attack',
2790     title  => 'Mezzanine',
2791     year   => 2005,
2792   });
2793
2794   if( !$cd->in_storage ) {
2795       # do some stuff
2796       $cd->insert;
2797   }
2798
2799 =cut
2800
2801 sub find_or_create {
2802   my $self     = shift;
2803   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2804   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2805   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2806     return $row;
2807   }
2808   return $self->create($hash);
2809 }
2810
2811 =head2 update_or_create
2812
2813 =over 4
2814
2815 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2816
2817 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2818
2819 =back
2820
2821   $resultset->update_or_create({ col => $val, ... });
2822
2823 Like L</find_or_create>, but if a row is found it is immediately updated via
2824 C<< $found_row->update (\%col_data) >>.
2825
2826
2827 Takes an optional C<key> attribute to search on a specific unique constraint.
2828 For example:
2829
2830   # In your application
2831   my $cd = $schema->resultset('CD')->update_or_create(
2832     {
2833       artist => 'Massive Attack',
2834       title  => 'Mezzanine',
2835       year   => 1998,
2836     },
2837     { key => 'cd_artist_title' }
2838   );
2839
2840   $cd->cd_to_producer->update_or_create({
2841     producer => $producer,
2842     name => 'harry',
2843   }, {
2844     key => 'primary',
2845   });
2846
2847 B<Note>: Make sure to read the documentation of L</find> and understand the
2848 significance of the C<key> attribute, as its lack may skew your search, and
2849 subsequently result in spurious row creation.
2850
2851 B<Note>: Take care when using C<update_or_create> with a table having
2852 columns with default values that you intend to be automatically
2853 supplied by the database (e.g. an auto_increment primary key column).
2854 In normal usage, the value of such columns should NOT be included at
2855 all in the call to C<update_or_create>, even when set to C<undef>.
2856
2857 See also L</find> and L</find_or_create>. For information on how to declare
2858 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2859
2860 If you need to know if an existing row was updated or a new one created use
2861 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2862 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2863 database!
2864
2865 =cut
2866
2867 sub update_or_create {
2868   my $self = shift;
2869   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2870   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2871
2872   my $row = $self->find($cond, $attrs);
2873   if (defined $row) {
2874     $row->update($cond);
2875     return $row;
2876   }
2877
2878   return $self->create($cond);
2879 }
2880
2881 =head2 update_or_new
2882
2883 =over 4
2884
2885 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2886
2887 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2888
2889 =back
2890
2891   $resultset->update_or_new({ col => $val, ... });
2892
2893 Like L</find_or_new> but if a row is found it is immediately updated via
2894 C<< $found_row->update (\%col_data) >>.
2895
2896 For example:
2897
2898   # In your application
2899   my $cd = $schema->resultset('CD')->update_or_new(
2900     {
2901       artist => 'Massive Attack',
2902       title  => 'Mezzanine',
2903       year   => 1998,
2904     },
2905     { key => 'cd_artist_title' }
2906   );
2907
2908   if ($cd->in_storage) {
2909       # the cd was updated
2910   }
2911   else {
2912       # the cd is not yet in the database, let's insert it
2913       $cd->insert;
2914   }
2915
2916 B<Note>: Make sure to read the documentation of L</find> and understand the
2917 significance of the C<key> attribute, as its lack may skew your search, and
2918 subsequently result in spurious new objects.
2919
2920 B<Note>: Take care when using C<update_or_new> with a table having
2921 columns with default values that you intend to be automatically
2922 supplied by the database (e.g. an auto_increment primary key column).
2923 In normal usage, the value of such columns should NOT be included at
2924 all in the call to C<update_or_new>, even when set to C<undef>.
2925
2926 See also L</find>, L</find_or_create> and L</find_or_new>.
2927
2928 =cut
2929
2930 sub update_or_new {
2931     my $self  = shift;
2932     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2933     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2934
2935     my $row = $self->find( $cond, $attrs );
2936     if ( defined $row ) {
2937         $row->update($cond);
2938         return $row;
2939     }
2940
2941     return $self->new_result($cond);
2942 }
2943
2944 =head2 get_cache
2945
2946 =over 4
2947
2948 =item Arguments: none
2949
2950 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2951
2952 =back
2953
2954 Gets the contents of the cache for the resultset, if the cache is set.
2955
2956 The cache is populated either by using the L</prefetch> attribute to
2957 L</search> or by calling L</set_cache>.
2958
2959 =cut
2960
2961 sub get_cache {
2962   shift->{all_cache};
2963 }
2964
2965 =head2 set_cache
2966
2967 =over 4
2968
2969 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2970
2971 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2972
2973 =back
2974
2975 Sets the contents of the cache for the resultset. Expects an arrayref
2976 of objects of the same class as those produced by the resultset. Note that
2977 if the cache is set, the resultset will return the cached objects rather
2978 than re-querying the database even if the cache attr is not set.
2979
2980 The contents of the cache can also be populated by using the
2981 L</prefetch> attribute to L</search>.
2982
2983 =cut
2984
2985 sub set_cache {
2986   my ( $self, $data ) = @_;
2987   $self->throw_exception("set_cache requires an arrayref")
2988       if defined($data) && (ref $data ne 'ARRAY');
2989   $self->{all_cache} = $data;
2990 }
2991
2992 =head2 clear_cache
2993
2994 =over 4
2995
2996 =item Arguments: none
2997
2998 =item Return Value: undef
2999
3000 =back
3001
3002 Clears the cache for the resultset.
3003
3004 =cut
3005
3006 sub clear_cache {
3007   shift->set_cache(undef);
3008 }
3009
3010 =head2 is_paged
3011
3012 =over 4
3013
3014 =item Arguments: none
3015
3016 =item Return Value: true, if the resultset has been paginated
3017
3018 =back
3019
3020 =cut
3021
3022 sub is_paged {
3023   my ($self) = @_;
3024   return !!$self->{attrs}{page};
3025 }
3026
3027 =head2 is_ordered
3028
3029 =over 4
3030
3031 =item Arguments: none
3032
3033 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3034
3035 =back
3036
3037 =cut
3038
3039 sub is_ordered {
3040   my ($self) = @_;
3041   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3042 }
3043
3044 =head2 related_resultset
3045
3046 =over 4
3047
3048 =item Arguments: $rel_name
3049
3050 =item Return Value: L<$resultset|/search>
3051
3052 =back
3053
3054 Returns a related resultset for the supplied relationship name.
3055
3056   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3057
3058 =cut
3059
3060 sub related_resultset {
3061   my ($self, $rel) = @_;
3062
3063   return $self->{related_resultsets}{$rel} ||= do {
3064     my $rsrc = $self->result_source;
3065     my $rel_info = $rsrc->relationship_info($rel);
3066
3067     $self->throw_exception(
3068       "search_related: result source '" . $rsrc->source_name .
3069         "' has no such relationship $rel")
3070       unless $rel_info;
3071
3072     my $attrs = $self->_chain_relationship($rel);
3073
3074     my $join_count = $attrs->{seen_join}{$rel};
3075
3076     my $alias = $self->result_source->storage
3077         ->relname_to_table_alias($rel, $join_count);
3078
3079     # since this is search_related, and we already slid the select window inwards
3080     # (the select/as attrs were deleted in the beginning), we need to flip all
3081     # left joins to inner, so we get the expected results
3082     # read the comment on top of the actual function to see what this does
3083     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3084
3085
3086     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3087     delete @{$attrs}{qw(result_class alias)};
3088
3089     my $related_cache;
3090
3091     if (my $cache = $self->get_cache) {
3092       $related_cache = [ map
3093         { @{$_->related_resultset($rel)->get_cache||[]} }
3094         @$cache
3095       ];
3096     }
3097
3098     my $rel_source = $rsrc->related_source($rel);
3099
3100     my $new = do {
3101
3102       # The reason we do this now instead of passing the alias to the
3103       # search_rs below is that if you wrap/overload resultset on the
3104       # source you need to know what alias it's -going- to have for things
3105       # to work sanely (e.g. RestrictWithObject wants to be able to add
3106       # extra query restrictions, and these may need to be $alias.)
3107
3108       my $rel_attrs = $rel_source->resultset_attributes;
3109       local $rel_attrs->{alias} = $alias;
3110
3111       $rel_source->resultset
3112                  ->search_rs(
3113                      undef, {
3114                        %$attrs,
3115                        where => $attrs->{where},
3116                    });
3117     };
3118     $new->set_cache($related_cache) if $related_cache;
3119     $new;
3120   };
3121 }
3122
3123 =head2 current_source_alias
3124
3125 =over 4
3126
3127 =item Arguments: none
3128
3129 =item Return Value: $source_alias
3130
3131 =back
3132
3133 Returns the current table alias for the result source this resultset is built
3134 on, that will be used in the SQL query. Usually it is C<me>.
3135
3136 Currently the source alias that refers to the result set returned by a
3137 L</search>/L</find> family method depends on how you got to the resultset: it's
3138 C<me> by default, but eg. L</search_related> aliases it to the related result
3139 source name (and keeps C<me> referring to the original result set). The long
3140 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3141 (and make this method unnecessary).
3142
3143 Thus it's currently necessary to use this method in predefined queries (see
3144 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3145 source alias of the current result set:
3146
3147   # in a result set class
3148   sub modified_by {
3149     my ($self, $user) = @_;
3150
3151     my $me = $self->current_source_alias;
3152
3153     return $self->search({
3154       "$me.modified" => $user->id,
3155     });
3156   }
3157
3158 =cut
3159
3160 sub current_source_alias {
3161   return (shift->{attrs} || {})->{alias} || 'me';
3162 }
3163
3164 =head2 as_subselect_rs
3165
3166 =over 4
3167
3168 =item Arguments: none
3169
3170 =item Return Value: L<$resultset|/search>
3171
3172 =back
3173
3174 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3175 "virtual view" by including it as a subquery within the from clause.  From this
3176 point on, any joined tables are inaccessible to ->search on the resultset (as if
3177 it were simply where-filtered without joins).  For example:
3178
3179  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3180
3181  # 'x' now pollutes the query namespace
3182
3183  # So the following works as expected
3184  my $ok_rs = $rs->search({'x.other' => 1});
3185
3186  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3187  # def) we look for one row with contradictory terms and join in another table
3188  # (aliased 'x_2') which we never use
3189  my $broken_rs = $rs->search({'x.name' => 'def'});
3190
3191  my $rs2 = $rs->as_subselect_rs;
3192
3193  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3194  my $not_joined_rs = $rs2->search({'x.other' => 1});
3195
3196  # works as expected: finds a 'table' row related to two x rows (abc and def)
3197  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3198
3199 Another example of when one might use this would be to select a subset of
3200 columns in a group by clause:
3201
3202  my $rs = $schema->resultset('Bar')->search(undef, {
3203    group_by => [qw{ id foo_id baz_id }],
3204  })->as_subselect_rs->search(undef, {
3205    columns => [qw{ id foo_id }]
3206  });
3207
3208 In the above example normally columns would have to be equal to the group by,
3209 but because we isolated the group by into a subselect the above works.
3210
3211 =cut
3212
3213 sub as_subselect_rs {
3214   my $self = shift;
3215
3216   my $attrs = $self->_resolved_attrs;
3217
3218   my $fresh_rs = (ref $self)->new (
3219     $self->result_source
3220   );
3221
3222   # these pieces will be locked in the subquery
3223   delete $fresh_rs->{cond};
3224   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3225
3226   return $fresh_rs->search( {}, {
3227     from => [{
3228       $attrs->{alias} => $self->as_query,
3229       -alias  => $attrs->{alias},
3230       -rsrc   => $self->result_source,
3231     }],
3232     alias => $attrs->{alias},
3233   });
3234 }
3235
3236 # This code is called by search_related, and makes sure there
3237 # is clear separation between the joins before, during, and
3238 # after the relationship. This information is needed later
3239 # in order to properly resolve prefetch aliases (any alias
3240 # with a relation_chain_depth less than the depth of the
3241 # current prefetch is not considered)
3242 #
3243 # The increments happen twice per join. An even number means a
3244 # relationship specified via a search_related, whereas an odd
3245 # number indicates a join/prefetch added via attributes
3246 #
3247 # Also this code will wrap the current resultset (the one we
3248 # chain to) in a subselect IFF it contains limiting attributes
3249 sub _chain_relationship {
3250   my ($self, $rel) = @_;
3251   my $source = $self->result_source;
3252   my $attrs = { %{$self->{attrs}||{}} };
3253
3254   # we need to take the prefetch the attrs into account before we
3255   # ->_resolve_join as otherwise they get lost - captainL
3256   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3257
3258   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3259
3260   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3261
3262   my $from;
3263   my @force_subq_attrs = qw/offset rows group_by having/;
3264
3265   if (
3266     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3267       ||
3268     $self->_has_resolved_attr (@force_subq_attrs)
3269   ) {
3270     # Nuke the prefetch (if any) before the new $rs attrs
3271     # are resolved (prefetch is useless - we are wrapping
3272     # a subquery anyway).
3273     my $rs_copy = $self->search;
3274     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3275       $rs_copy->{attrs}{join},
3276       delete $rs_copy->{attrs}{prefetch},
3277     );
3278
3279     $from = [{
3280       -rsrc   => $source,
3281       -alias  => $attrs->{alias},
3282       $attrs->{alias} => $rs_copy->as_query,
3283     }];
3284     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3285     $seen->{-relation_chain_depth} = 0;
3286   }
3287   elsif ($attrs->{from}) {  #shallow copy suffices
3288     $from = [ @{$attrs->{from}} ];
3289   }
3290   else {
3291     $from = [{
3292       -rsrc  => $source,
3293       -alias => $attrs->{alias},
3294       $attrs->{alias} => $source->from,
3295     }];
3296   }
3297
3298   my $jpath = ($seen->{-relation_chain_depth})
3299     ? $from->[-1][0]{-join_path}
3300     : [];
3301
3302   my @requested_joins = $source->_resolve_join(
3303     $join,
3304     $attrs->{alias},
3305     $seen,
3306     $jpath,
3307   );
3308
3309   push @$from, @requested_joins;
3310
3311   $seen->{-relation_chain_depth}++;
3312
3313   # if $self already had a join/prefetch specified on it, the requested
3314   # $rel might very well be already included. What we do in this case
3315   # is effectively a no-op (except that we bump up the chain_depth on
3316   # the join in question so we could tell it *is* the search_related)
3317   my $already_joined;
3318
3319   # we consider the last one thus reverse
3320   for my $j (reverse @requested_joins) {
3321     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3322     if ($rel eq $last_j) {
3323       $j->[0]{-relation_chain_depth}++;
3324       $already_joined++;
3325       last;
3326     }
3327   }
3328
3329   unless ($already_joined) {
3330     push @$from, $source->_resolve_join(
3331       $rel,
3332       $attrs->{alias},
3333       $seen,
3334       $jpath,
3335     );
3336   }
3337
3338   $seen->{-relation_chain_depth}++;
3339
3340   return {%$attrs, from => $from, seen_join => $seen};
3341 }
3342
3343 # FIXME - this needs to go live in Schema with the tree walker... or
3344 # something
3345 my $inflatemap_checker;
3346 $inflatemap_checker = sub {
3347   my ($rsrc, $relpaths) = @_;
3348
3349   my $rels;
3350
3351   for (@$relpaths) {
3352     $_ =~ /^ ( [^\.]+ ) \. (.+) $/x
3353       or next;
3354
3355     push @{$rels->{$1}}, $2;
3356   }
3357
3358   for my $rel (keys %$rels) {
3359     my $rel_rsrc = try {
3360       $rsrc->related_source ($rel)
3361     } catch {
3362     $rsrc->throw_exception(sprintf(
3363       "Inflation into non-existent relationship '%s' of '%s' requested, "
3364     . "check the inflation specification (columns/as) ending in '...%s.%s'",
3365       $rel,
3366       $rsrc->source_name,
3367       $rel,
3368       ( sort { length($a) <=> length ($b) } @{$rels->{$rel}} )[0],
3369     ))};
3370
3371     $inflatemap_checker->($rel_rsrc, $rels->{$rel});
3372   }
3373
3374   return;
3375 };
3376
3377 sub _resolved_attrs {
3378   my $self = shift;
3379   return $self->{_attrs} if $self->{_attrs};
3380
3381   my $attrs  = { %{ $self->{attrs} || {} } };
3382   my $source = $self->result_source;
3383   my $alias  = $attrs->{alias};
3384
3385   # default selection list
3386   $attrs->{columns} = [ $source->columns ]
3387     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3388
3389   # merge selectors together
3390   for (qw/columns select as/) {
3391     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3392       if $attrs->{$_} or $attrs->{"+$_"};
3393   }
3394
3395   # disassemble columns
3396   my (@sel, @as);
3397   if (my $cols = delete $attrs->{columns}) {
3398     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3399       if (ref $c eq 'HASH') {
3400         for my $as (sort keys %$c) {
3401           push @sel, $c->{$as};
3402           push @as, $as;
3403         }
3404       }
3405       else {
3406         push @sel, $c;
3407         push @as, $c;
3408       }
3409     }
3410   }
3411
3412   # when trying to weed off duplicates later do not go past this point -
3413   # everything added from here on is unbalanced "anyone's guess" stuff
3414   my $dedup_stop_idx = $#as;
3415
3416   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3417     if $attrs->{as};
3418   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3419     if $attrs->{select};
3420
3421   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3422   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3423
3424   # disqualify all $alias.col as-bits (inflate-map mandated)
3425   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3426
3427   # de-duplicate the result (remove *identical* select/as pairs)
3428   # and also die on duplicate {as} pointing to different {select}s
3429   # not using a c-style for as the condition is prone to shrinkage
3430   my $seen;
3431   my $i = 0;
3432   while ($i <= $dedup_stop_idx) {
3433     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3434       splice @sel, $i, 1;
3435       splice @as, $i, 1;
3436       $dedup_stop_idx--;
3437     }
3438     elsif ($seen->{$as[$i]}++) {
3439       $self->throw_exception(
3440         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3441       );
3442     }
3443     else {
3444       $i++;
3445     }
3446   }
3447
3448   # validate the user-supplied 'as' chain
3449   # folks get too confused by the (logical) exception message, need to
3450   # go to some lengths to clarify the text
3451   #
3452   # FIXME - this needs to go live in Schema with the tree walker... or
3453   # something
3454   $inflatemap_checker->($source, \@as);
3455
3456   $attrs->{select} = \@sel;
3457   $attrs->{as} = \@as;
3458
3459   $attrs->{from} ||= [{
3460     -rsrc   => $source,
3461     -alias  => $self->{attrs}{alias},
3462     $self->{attrs}{alias} => $source->from,
3463   }];
3464
3465   if ( $attrs->{join} || $attrs->{prefetch} ) {
3466
3467     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3468       if ref $attrs->{from} ne 'ARRAY';
3469
3470     my $join = (delete $attrs->{join}) || {};
3471
3472     if ( defined $attrs->{prefetch} ) {
3473       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3474     }
3475
3476     $attrs->{from} =    # have to copy here to avoid corrupting the original
3477       [
3478         @{ $attrs->{from} },
3479         $source->_resolve_join(
3480           $join,
3481           $alias,
3482           { %{ $attrs->{seen_join} || {} } },
3483           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3484             ? $attrs->{from}[-1][0]{-join_path}
3485             : []
3486           ,
3487         )
3488       ];
3489   }
3490
3491   if ( defined $attrs->{order_by} ) {
3492     $attrs->{order_by} = (
3493       ref( $attrs->{order_by} ) eq 'ARRAY'
3494       ? [ @{ $attrs->{order_by} } ]
3495       : [ $attrs->{order_by} || () ]
3496     );
3497   }
3498
3499   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3500     $attrs->{group_by} = [ $attrs->{group_by} ];
3501   }
3502
3503   # generate the distinct induced group_by early, as prefetch will be carried via a
3504   # subquery (since a group_by is present)
3505   if (delete $attrs->{distinct}) {
3506     if ($attrs->{group_by}) {
3507       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3508     }
3509     else {
3510       # distinct affects only the main selection part, not what prefetch may
3511       # add below.
3512       $attrs->{group_by} = $source->storage->_group_over_selection (
3513         $attrs->{from},
3514         $attrs->{select},
3515         $attrs->{order_by},
3516       );
3517     }
3518   }
3519
3520   # generate selections based on the prefetch helper
3521   my $prefetch;
3522   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3523     if defined $attrs->{prefetch};
3524
3525   if ($prefetch) {
3526
3527     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3528       if $attrs->{_dark_selector};
3529
3530     $attrs->{collapse} = 1;
3531
3532     # this is a separate structure (we don't look in {from} directly)
3533     # as the resolver needs to shift things off the lists to work
3534     # properly (identical-prefetches on different branches)
3535     my $join_map = {};
3536     if (ref $attrs->{from} eq 'ARRAY') {
3537
3538       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3539
3540       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3541         next unless $j->[0]{-alias};
3542         next unless $j->[0]{-join_path};
3543         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3544
3545         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3546
3547         my $p = $join_map;
3548         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3549         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3550       }
3551     }
3552
3553     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3554
3555     # we need to somehow mark which columns came from prefetch
3556     if (@prefetch) {
3557       my $sel_end = $#{$attrs->{select}};
3558       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3559     }
3560
3561     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3562     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3563   }
3564
3565   if ( ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3566     $attrs->{_single_resultclass_inflation} = 1;
3567     $attrs->{collapse} = 0;
3568   }
3569
3570   # run through the resulting joinstructure (starting from our current slot)
3571   # and unset collapse if proven unnesessary
3572   #
3573   # also while we are at it find out if the current root source has
3574   # been premultiplied by previous related_source chaining
3575   #
3576   # this allows to predict whether a root object with all other relation
3577   # data set to NULL is in fact unique
3578   if ($attrs->{collapse}) {
3579
3580     if (ref $attrs->{from} eq 'ARRAY') {
3581
3582       if (@{$attrs->{from}} <= 1) {
3583         # no joins - no collapse
3584         $attrs->{collapse} = 0;
3585       }
3586       else {
3587         # find where our table-spec starts
3588         my @fromlist = @{$attrs->{from}};
3589         while (@fromlist) {
3590           my $t = shift @fromlist;
3591
3592           my $is_multi;
3593           # me vs join from-spec distinction - a ref means non-root
3594           if (ref $t eq 'ARRAY') {
3595             $t = $t->[0];
3596             $is_multi ||= ! $t->{-is_single};
3597           }
3598           last if ($t->{-alias} && $t->{-alias} eq $alias);
3599           $attrs->{_main_source_premultiplied} ||= $is_multi;
3600         }
3601
3602         # no non-singles remaining, nor any premultiplication - nothing to collapse
3603         if (
3604           ! $attrs->{_main_source_premultiplied}
3605             and
3606           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3607         ) {
3608           $attrs->{collapse} = 0;
3609         }
3610       }
3611     }
3612
3613     else {
3614       # if we can not analyze the from - err on the side of safety
3615       $attrs->{_main_source_premultiplied} = 1;
3616     }
3617   }
3618
3619   # if both page and offset are specified, produce a combined offset
3620   # even though it doesn't make much sense, this is what pre 081xx has
3621   # been doing
3622   if (my $page = delete $attrs->{page}) {
3623     $attrs->{offset} =
3624       ($attrs->{rows} * ($page - 1))
3625             +
3626       ($attrs->{offset} || 0)
3627     ;
3628   }
3629
3630   return $self->{_attrs} = $attrs;
3631 }
3632
3633 sub _rollout_attr {
3634   my ($self, $attr) = @_;
3635
3636   if (ref $attr eq 'HASH') {
3637     return $self->_rollout_hash($attr);
3638   } elsif (ref $attr eq 'ARRAY') {
3639     return $self->_rollout_array($attr);
3640   } else {
3641     return [$attr];
3642   }
3643 }
3644
3645 sub _rollout_array {
3646   my ($self, $attr) = @_;
3647
3648   my @rolled_array;
3649   foreach my $element (@{$attr}) {
3650     if (ref $element eq 'HASH') {
3651       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3652     } elsif (ref $element eq 'ARRAY') {
3653       #  XXX - should probably recurse here
3654       push( @rolled_array, @{$self->_rollout_array($element)} );
3655     } else {
3656       push( @rolled_array, $element );
3657     }
3658   }
3659   return \@rolled_array;
3660 }
3661
3662 sub _rollout_hash {
3663   my ($self, $attr) = @_;
3664
3665   my @rolled_array;
3666   foreach my $key (keys %{$attr}) {
3667     push( @rolled_array, { $key => $attr->{$key} } );
3668   }
3669   return \@rolled_array;
3670 }
3671
3672 sub _calculate_score {
3673   my ($self, $a, $b) = @_;
3674
3675   if (defined $a xor defined $b) {
3676     return 0;
3677   }
3678   elsif (not defined $a) {
3679     return 1;
3680   }
3681
3682   if (ref $b eq 'HASH') {
3683     my ($b_key) = keys %{$b};
3684     if (ref $a eq 'HASH') {
3685       my ($a_key) = keys %{$a};
3686       if ($a_key eq $b_key) {
3687         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3688       } else {
3689         return 0;
3690       }
3691     } else {
3692       return ($a eq $b_key) ? 1 : 0;
3693     }
3694   } else {
3695     if (ref $a eq 'HASH') {
3696       my ($a_key) = keys %{$a};
3697       return ($b eq $a_key) ? 1 : 0;
3698     } else {
3699       return ($b eq $a) ? 1 : 0;
3700     }
3701   }
3702 }
3703
3704 sub _merge_joinpref_attr {
3705   my ($self, $orig, $import) = @_;
3706
3707   return $import unless defined($orig);
3708   return $orig unless defined($import);
3709
3710   $orig = $self->_rollout_attr($orig);
3711   $import = $self->_rollout_attr($import);
3712
3713   my $seen_keys;
3714   foreach my $import_element ( @{$import} ) {
3715     # find best candidate from $orig to merge $b_element into
3716     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3717     foreach my $orig_element ( @{$orig} ) {
3718       my $score = $self->_calculate_score( $orig_element, $import_element );
3719       if ($score > $best_candidate->{score}) {
3720         $best_candidate->{position} = $position;
3721         $best_candidate->{score} = $score;
3722       }
3723       $position++;
3724     }
3725     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3726     $import_key = '' if not defined $import_key;
3727
3728     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3729       push( @{$orig}, $import_element );
3730     } else {
3731       my $orig_best = $orig->[$best_candidate->{position}];
3732       # merge orig_best and b_element together and replace original with merged
3733       if (ref $orig_best ne 'HASH') {
3734         $orig->[$best_candidate->{position}] = $import_element;
3735       } elsif (ref $import_element eq 'HASH') {
3736         my ($key) = keys %{$orig_best};
3737         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3738       }
3739     }
3740     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3741   }
3742
3743   return @$orig ? $orig : ();
3744 }
3745
3746 {
3747   my $hm;
3748
3749   sub _merge_attr {
3750     $hm ||= do {
3751       require Hash::Merge;
3752       my $hm = Hash::Merge->new;
3753
3754       $hm->specify_behavior({
3755         SCALAR => {
3756           SCALAR => sub {
3757             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3758
3759             if ($defl xor $defr) {
3760               return [ $defl ? $_[0] : $_[1] ];
3761             }
3762             elsif (! $defl) {
3763               return [];
3764             }
3765             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3766               return [ $_[0] ];
3767             }
3768             else {
3769               return [$_[0], $_[1]];
3770             }
3771           },
3772           ARRAY => sub {
3773             return $_[1] if !defined $_[0];
3774             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3775             return [$_[0], @{$_[1]}]
3776           },
3777           HASH  => sub {
3778             return [] if !defined $_[0] and !keys %{$_[1]};
3779             return [ $_[1] ] if !defined $_[0];
3780             return [ $_[0] ] if !keys %{$_[1]};
3781             return [$_[0], $_[1]]
3782           },
3783         },
3784         ARRAY => {
3785           SCALAR => sub {
3786             return $_[0] if !defined $_[1];
3787             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3788             return [@{$_[0]}, $_[1]]
3789           },
3790           ARRAY => sub {
3791             my @ret = @{$_[0]} or return $_[1];
3792             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3793             my %idx = map { $_ => 1 } @ret;
3794             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3795             \@ret;
3796           },
3797           HASH => sub {
3798             return [ $_[1] ] if ! @{$_[0]};
3799             return $_[0] if !keys %{$_[1]};
3800             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3801             return [ @{$_[0]}, $_[1] ];
3802           },
3803         },
3804         HASH => {
3805           SCALAR => sub {
3806             return [] if !keys %{$_[0]} and !defined $_[1];
3807             return [ $_[0] ] if !defined $_[1];
3808             return [ $_[1] ] if !keys %{$_[0]};
3809             return [$_[0], $_[1]]
3810           },
3811           ARRAY => sub {
3812             return [] if !keys %{$_[0]} and !@{$_[1]};
3813             return [ $_[0] ] if !@{$_[1]};
3814             return $_[1] if !keys %{$_[0]};
3815             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3816             return [ $_[0], @{$_[1]} ];
3817           },
3818           HASH => sub {
3819             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3820             return [ $_[0] ] if !keys %{$_[1]};
3821             return [ $_[1] ] if !keys %{$_[0]};
3822             return [ $_[0] ] if $_[0] eq $_[1];
3823             return [ $_[0], $_[1] ];
3824           },
3825         }
3826       } => 'DBIC_RS_ATTR_MERGER');
3827       $hm;
3828     };
3829
3830     return $hm->merge ($_[1], $_[2]);
3831   }
3832 }
3833
3834 sub STORABLE_freeze {
3835   my ($self, $cloning) = @_;
3836   my $to_serialize = { %$self };
3837
3838   # A cursor in progress can't be serialized (and would make little sense anyway)
3839   # the parser can be regenerated (and can't be serialized)
3840   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3841
3842   # nor is it sensical to store a not-yet-fired-count pager
3843   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3844     delete $to_serialize->{pager};
3845   }
3846
3847   Storable::nfreeze($to_serialize);
3848 }
3849
3850 # need this hook for symmetry
3851 sub STORABLE_thaw {
3852   my ($self, $cloning, $serialized) = @_;
3853
3854   %$self = %{ Storable::thaw($serialized) };
3855
3856   $self;
3857 }
3858
3859
3860 =head2 throw_exception
3861
3862 See L<DBIx::Class::Schema/throw_exception> for details.
3863
3864 =cut
3865
3866 sub throw_exception {
3867   my $self=shift;
3868
3869   if (ref $self and my $rsrc = $self->result_source) {
3870     $rsrc->throw_exception(@_)
3871   }
3872   else {
3873     DBIx::Class::Exception->throw(@_);
3874   }
3875 }
3876
3877 1;
3878
3879 __END__
3880
3881 # XXX: FIXME: Attributes docs need clearing up
3882
3883 =head1 ATTRIBUTES
3884
3885 Attributes are used to refine a ResultSet in various ways when
3886 searching for data. They can be passed to any method which takes an
3887 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3888 L</count>.
3889
3890 Default attributes can be set on the result class using
3891 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3892 the CAVEATS on that feature before using it!)
3893
3894 These are in no particular order:
3895
3896 =head2 order_by
3897
3898 =over 4
3899
3900 =item Value: ( $order_by | \@order_by | \%order_by )
3901
3902 =back
3903
3904 Which column(s) to order the results by.
3905
3906 [The full list of suitable values is documented in
3907 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3908 common options.]
3909
3910 If a single column name, or an arrayref of names is supplied, the
3911 argument is passed through directly to SQL. The hashref syntax allows
3912 for connection-agnostic specification of ordering direction:
3913
3914  For descending order:
3915
3916   order_by => { -desc => [qw/col1 col2 col3/] }
3917
3918  For explicit ascending order:
3919
3920   order_by => { -asc => 'col' }
3921
3922 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3923 supported, although you are strongly encouraged to use the hashref
3924 syntax as outlined above.
3925
3926 =head2 columns
3927
3928 =over 4
3929
3930 =item Value: \@columns | \%columns | $column
3931
3932 =back
3933
3934 Shortcut to request a particular set of columns to be retrieved. Each
3935 column spec may be a string (a table column name), or a hash (in which
3936 case the key is the C<as> value, and the value is used as the C<select>
3937 expression). Adds C<me.> onto the start of any column without a C<.> in
3938 it and sets C<select> from that, then auto-populates C<as> from
3939 C<select> as normal. (You may also use the C<cols> attribute, as in
3940 earlier versions of DBIC.)
3941
3942 Essentially C<columns> does the same as L</select> and L</as>.
3943
3944     columns => [ 'foo', { bar => 'baz' } ]
3945
3946 is the same as
3947
3948     select => [qw/foo baz/],
3949     as => [qw/foo bar/]
3950
3951 =head2 +columns
3952
3953 =over 4
3954
3955 =item Value: \@columns
3956
3957 =back
3958
3959 Indicates additional columns to be selected from storage. Works the same
3960 as L</columns> but adds columns to the selection. (You may also use the
3961 C<include_columns> attribute, as in earlier versions of DBIC). For
3962 example:-
3963
3964   $schema->resultset('CD')->search(undef, {
3965     '+columns' => ['artist.name'],
3966     join => ['artist']
3967   });
3968
3969 would return all CDs and include a 'name' column to the information
3970 passed to object inflation. Note that the 'artist' is the name of the
3971 column (or relationship) accessor, and 'name' is the name of the column
3972 accessor in the related table.
3973
3974 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3975 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3976 unary plus operator before it.
3977
3978 =head2 include_columns
3979
3980 =over 4
3981
3982 =item Value: \@columns
3983
3984 =back
3985
3986 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3987
3988 =head2 select
3989
3990 =over 4
3991
3992 =item Value: \@select_columns
3993
3994 =back
3995
3996 Indicates which columns should be selected from the storage. You can use
3997 column names, or in the case of RDBMS back ends, function or stored procedure
3998 names:
3999
4000   $rs = $schema->resultset('Employee')->search(undef, {
4001     select => [
4002       'name',
4003       { count => 'employeeid' },
4004       { max => { length => 'name' }, -as => 'longest_name' }
4005     ]
4006   });
4007
4008   # Equivalent SQL
4009   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4010
4011 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4012 use L</select>, to instruct DBIx::Class how to store the result of the column.
4013 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4014 identifier aliasing. You can however alias a function, so you can use it in
4015 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4016 attribute> supplied as shown in the example above.
4017
4018 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4019 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4020 unary plus operator before it.
4021
4022 =head2 +select
4023
4024 =over 4
4025
4026 Indicates additional columns to be selected from storage.  Works the same as
4027 L</select> but adds columns to the default selection, instead of specifying
4028 an explicit list.
4029
4030 =back
4031
4032 =head2 as
4033
4034 =over 4
4035
4036 =item Value: \@inflation_names
4037
4038 =back
4039
4040 Indicates column names for object inflation. That is L</as> indicates the
4041 slot name in which the column value will be stored within the
4042 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4043 identifier by the C<get_column> method (or via the object accessor B<if one
4044 with the same name already exists>) as shown below. The L</as> attribute has
4045 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4046
4047   $rs = $schema->resultset('Employee')->search(undef, {
4048     select => [
4049       'name',
4050       { count => 'employeeid' },
4051       { max => { length => 'name' }, -as => 'longest_name' }
4052     ],
4053     as => [qw/
4054       name
4055       employee_count
4056       max_name_length
4057     /],
4058   });
4059
4060 If the object against which the search is performed already has an accessor
4061 matching a column name specified in C<as>, the value can be retrieved using
4062 the accessor as normal:
4063
4064   my $name = $employee->name();
4065
4066 If on the other hand an accessor does not exist in the object, you need to
4067 use C<get_column> instead:
4068
4069   my $employee_count = $employee->get_column('employee_count');
4070
4071 You can create your own accessors if required - see
4072 L<DBIx::Class::Manual::Cookbook> for details.
4073
4074 =head2 +as
4075
4076 =over 4
4077
4078 Indicates additional column names for those added via L</+select>. See L</as>.
4079
4080 =back
4081
4082 =head2 join
4083
4084 =over 4
4085
4086 =item Value: ($rel_name | \@rel_names | \%rel_names)
4087
4088 =back
4089
4090 Contains a list of relationships that should be joined for this query.  For
4091 example:
4092
4093   # Get CDs by Nine Inch Nails
4094   my $rs = $schema->resultset('CD')->search(
4095     { 'artist.name' => 'Nine Inch Nails' },
4096     { join => 'artist' }
4097   );
4098
4099 Can also contain a hash reference to refer to the other relation's relations.
4100 For example:
4101
4102   package MyApp::Schema::Track;
4103   use base qw/DBIx::Class/;
4104   __PACKAGE__->table('track');
4105   __PACKAGE__->add_columns(qw/trackid cd position title/);
4106   __PACKAGE__->set_primary_key('trackid');
4107   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4108   1;
4109
4110   # In your application
4111   my $rs = $schema->resultset('Artist')->search(
4112     { 'track.title' => 'Teardrop' },
4113     {
4114       join     => { cd => 'track' },
4115       order_by => 'artist.name',
4116     }
4117   );
4118
4119 You need to use the relationship (not the table) name in  conditions,
4120 because they are aliased as such. The current table is aliased as "me", so
4121 you need to use me.column_name in order to avoid ambiguity. For example:
4122
4123   # Get CDs from 1984 with a 'Foo' track
4124   my $rs = $schema->resultset('CD')->search(
4125     {
4126       'me.year' => 1984,
4127       'tracks.name' => 'Foo'
4128     },
4129     { join => 'tracks' }
4130   );
4131
4132 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4133 similarly for a third time). For e.g.
4134
4135   my $rs = $schema->resultset('Artist')->search({
4136     'cds.title'   => 'Down to Earth',
4137     'cds_2.title' => 'Popular',
4138   }, {
4139     join => [ qw/cds cds/ ],
4140   });
4141
4142 will return a set of all artists that have both a cd with title 'Down
4143 to Earth' and a cd with title 'Popular'.
4144
4145 If you want to fetch related objects from other tables as well, see L</prefetch>
4146 below.
4147
4148  NOTE: An internal join-chain pruner will discard certain joins while
4149  constructing the actual SQL query, as long as the joins in question do not
4150  affect the retrieved result. This for example includes 1:1 left joins
4151  that are not part of the restriction specification (WHERE/HAVING) nor are
4152  a part of the query selection.
4153
4154 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4155
4156 =head2 collapse
4157
4158 =over 4
4159
4160 =item Value: (0 | 1)
4161
4162 =back
4163
4164 When set to a true value, indicates that any rows fetched from joined has_many
4165 relationships are to be aggregated into the corresponding "parent" object. For
4166 example, the resultset:
4167
4168   my $rs = $schema->resultset('CD')->search({}, {
4169     '+columns' => [ qw/ tracks.title tracks.position / ],
4170     join => 'tracks',
4171     collapse => 1,
4172   });
4173
4174 While executing the following query:
4175
4176   SELECT me.*, tracks.title, tracks.position
4177     FROM cd me
4178     LEFT JOIN track tracks
4179       ON tracks.cdid = me.cdid
4180
4181 Will return only as many objects as there are rows in the CD source, even
4182 though the result of the query may span many rows. Each of these CD objects
4183 will in turn have multiple "Track" objects hidden behind the has_many
4184 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4185 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4186 product"), with each CD object containing exactly one of all fetched Track data.
4187
4188 When a collapse is requested on a non-ordered resultset, an order by some
4189 unique part of the main source (the left-most table) is inserted automatically.
4190 This is done so that the resultset is allowed to be "lazy" - calling
4191 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4192 object with all of its related data.
4193
4194 If an L</order_by> is already declared, and orders the resultset in a way that
4195 makes collapsing as described above impossible (e.g. C<< ORDER BY
4196 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4197 switch to "eager" mode and slurp the entire resultset before consturcting the
4198 first object returned by L</next>.
4199
4200 Setting this attribute on a resultset that does not join any has_many
4201 relations is a no-op.
4202
4203 For a more in-depth discussion, see L</PREFETCHING>.
4204
4205 =head2 prefetch
4206
4207 =over 4
4208
4209 =item Value: ($rel_name | \@rel_names | \%rel_names)
4210
4211 =back
4212
4213 This attribute is a shorthand for specifying a L</join> spec, adding all
4214 columns from the joined related sources as L</+columns> and setting
4215 L</collapse> to a true value. For example, the following two queries are
4216 equivalent:
4217
4218   my $rs = $schema->resultset('Artist')->search({}, {
4219     prefetch => { cds => ['genre', 'tracks' ] },
4220   });
4221
4222 and
4223
4224   my $rs = $schema->resultset('Artist')->search({}, {
4225     join => { cds => ['genre', 'tracks' ] },
4226     collapse => 1,
4227     '+columns' => [
4228       (map
4229         { +{ "cds.$_" => "cds.$_" } }
4230         $schema->source('Artist')->related_source('cds')->columns
4231       ),
4232       (map
4233         { +{ "cds.genre.$_" => "genre.$_" } }
4234         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4235       ),
4236       (map
4237         { +{ "cds.tracks.$_" => "tracks.$_" } }
4238         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4239       ),
4240     ],
4241   });
4242
4243 Both producing the following SQL:
4244
4245   SELECT  me.artistid, me.name, me.rank, me.charfield,
4246           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4247           genre.genreid, genre.name,
4248           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4249     FROM artist me
4250     LEFT JOIN cd cds
4251       ON cds.artist = me.artistid
4252     LEFT JOIN genre genre
4253       ON genre.genreid = cds.genreid
4254     LEFT JOIN track tracks
4255       ON tracks.cd = cds.cdid
4256   ORDER BY me.artistid
4257
4258 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4259 the arguments are properly merged and generally do the right thing. For
4260 example, you may want to do the following:
4261
4262   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4263     { 'genre.genreid' => undef },
4264     {
4265       join => { cds => 'genre' },
4266       prefetch => 'cds',
4267     }
4268   );
4269
4270 Which generates the following SQL:
4271
4272   SELECT  me.artistid, me.name, me.rank, me.charfield,
4273           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4274     FROM artist me
4275     LEFT JOIN cd cds
4276       ON cds.artist = me.artistid
4277     LEFT JOIN genre genre
4278       ON genre.genreid = cds.genreid
4279   WHERE genre.genreid IS NULL
4280   ORDER BY me.artistid
4281
4282 For a more in-depth discussion, see L</PREFETCHING>.
4283
4284 =head2 alias
4285
4286 =over 4
4287
4288 =item Value: $source_alias
4289
4290 =back
4291
4292 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4293 nested search queries (sub-SELECTs) might need specific aliases set to
4294 reference inner queries.  For example:
4295
4296    my $q = $rs
4297       ->related_resultset('CDs')
4298       ->related_resultset('Tracks')
4299       ->search({
4300          'track.id' => { -ident => 'none_search.id' },
4301       })
4302       ->as_query;
4303
4304    my $ids = $self->search({
4305       -not_exists => $q,
4306    }, {
4307       alias    => 'none_search',
4308       group_by => 'none_search.id',
4309    })->get_column('id')->as_query;
4310
4311    $self->search({ id => { -in => $ids } })
4312
4313 This attribute is directly tied to L</current_source_alias>.
4314
4315 =head2 page
4316
4317 =over 4
4318
4319 =item Value: $page
4320
4321 =back
4322
4323 Makes the resultset paged and specifies the page to retrieve. Effectively
4324 identical to creating a non-pages resultset and then calling ->page($page)
4325 on it.
4326
4327 If L</rows> attribute is not specified it defaults to 10 rows per page.
4328
4329 When you have a paged resultset, L</count> will only return the number
4330 of rows in the page. To get the total, use the L</pager> and call
4331 C<total_entries> on it.
4332
4333 =head2 rows
4334
4335 =over 4
4336
4337 =item Value: $rows
4338
4339 =back
4340
4341 Specifies the maximum number of rows for direct retrieval or the number of
4342 rows per page if the page attribute or method is used.
4343
4344 =head2 offset
4345
4346 =over 4
4347
4348 =item Value: $offset
4349
4350 =back
4351
4352 Specifies the (zero-based) row number for the  first row to be returned, or the
4353 of the first row of the first page if paging is used.
4354
4355 =head2 software_limit
4356
4357 =over 4
4358
4359 =item Value: (0 | 1)
4360
4361 =back
4362
4363 When combined with L</rows> and/or L</offset> the generated SQL will not
4364 include any limit dialect stanzas. Instead the entire result will be selected
4365 as if no limits were specified, and DBIC will perform the limit locally, by
4366 artificially advancing and finishing the resulting L</cursor>.
4367
4368 This is the recommended way of performing resultset limiting when no sane RDBMS
4369 implementation is available (e.g.
4370 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4371 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4372
4373 =head2 group_by
4374
4375 =over 4
4376
4377 =item Value: \@columns
4378
4379 =back
4380
4381 A arrayref of columns to group by. Can include columns of joined tables.
4382
4383   group_by => [qw/ column1 column2 ... /]
4384
4385 =head2 having
4386
4387 =over 4
4388
4389 =item Value: $condition
4390
4391 =back
4392
4393 HAVING is a select statement attribute that is applied between GROUP BY and
4394 ORDER BY. It is applied to the after the grouping calculations have been
4395 done.
4396
4397   having => { 'count_employee' => { '>=', 100 } }
4398
4399 or with an in-place function in which case literal SQL is required:
4400
4401   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4402
4403 =head2 distinct
4404
4405 =over 4
4406
4407 =item Value: (0 | 1)
4408
4409 =back
4410
4411 Set to 1 to group by all columns. If the resultset already has a group_by
4412 attribute, this setting is ignored and an appropriate warning is issued.
4413
4414 =head2 where
4415
4416 =over 4
4417
4418 Adds to the WHERE clause.
4419
4420   # only return rows WHERE deleted IS NULL for all searches
4421   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4422
4423 Can be overridden by passing C<< { where => undef } >> as an attribute
4424 to a resultset.
4425
4426 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4427
4428 =back
4429
4430 =head2 cache
4431
4432 Set to 1 to cache search results. This prevents extra SQL queries if you
4433 revisit rows in your ResultSet:
4434
4435   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4436
4437   while( my $artist = $resultset->next ) {
4438     ... do stuff ...
4439   }
4440
4441   $rs->first; # without cache, this would issue a query
4442
4443 By default, searches are not cached.
4444
4445 For more examples of using these attributes, see
4446 L<DBIx::Class::Manual::Cookbook>.
4447
4448 =head2 for
4449
4450 =over 4
4451
4452 =item Value: ( 'update' | 'shared' | \$scalar )
4453
4454 =back
4455
4456 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4457 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4458 query.
4459
4460 =head1 PREFETCHING
4461
4462 DBIx::Class supports arbitrary related data prefetching from multiple related
4463 sources. Any combination of relationship types and column sets are supported.
4464 If L<collapsing|/collapse> is requested, there is an additional requirement of
4465 selecting enough data to make every individual object uniquely identifiable.
4466
4467 Here are some more involved examples, based on the following relationship map:
4468
4469   # Assuming:
4470   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4471   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4472   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4473
4474   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4475
4476   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4477
4478
4479
4480   my $rs = $schema->resultset('Tag')->search(
4481     undef,
4482     {
4483       prefetch => {
4484         cd => 'artist'
4485       }
4486     }
4487   );
4488
4489 The initial search results in SQL like the following:
4490
4491   SELECT tag.*, cd.*, artist.* FROM tag
4492   JOIN cd ON tag.cd = cd.cdid
4493   JOIN artist ON cd.artist = artist.artistid
4494
4495 L<DBIx::Class> has no need to go back to the database when we access the
4496 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4497 case.
4498
4499 Simple prefetches will be joined automatically, so there is no need
4500 for a C<join> attribute in the above search.
4501
4502 The L</prefetch> attribute can be used with any of the relationship types
4503 and multiple prefetches can be specified together. Below is a more complex
4504 example that prefetches a CD's artist, its liner notes (if present),
4505 the cover image, the tracks on that CD, and the guests on those
4506 tracks.
4507
4508   my $rs = $schema->resultset('CD')->search(
4509     undef,
4510     {
4511       prefetch => [
4512         { artist => 'record_label'},  # belongs_to => belongs_to
4513         'liner_note',                 # might_have
4514         'cover_image',                # has_one
4515         { tracks => 'guests' },       # has_many => has_many
4516       ]
4517     }
4518   );
4519
4520 This will produce SQL like the following:
4521
4522   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4523          tracks.*, guests.*
4524     FROM cd me
4525     JOIN artist artist
4526       ON artist.artistid = me.artistid
4527     JOIN record_label record_label
4528       ON record_label.labelid = artist.labelid
4529     LEFT JOIN track tracks
4530       ON tracks.cdid = me.cdid
4531     LEFT JOIN guest guests
4532       ON guests.trackid = track.trackid
4533     LEFT JOIN liner_notes liner_note
4534       ON liner_note.cdid = me.cdid
4535     JOIN cd_artwork cover_image
4536       ON cover_image.cdid = me.cdid
4537   ORDER BY tracks.cd
4538
4539 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4540 C<tracks>, and C<guests> of the CD will all be available through the
4541 relationship accessors without the need for additional queries to the
4542 database.
4543
4544 =head3 CAVEATS
4545
4546 Prefetch does a lot of deep magic. As such, it may not behave exactly
4547 as you might expect.
4548
4549 =over 4
4550
4551 =item *
4552
4553 Prefetch uses the L</cache> to populate the prefetched relationships. This
4554 may or may not be what you want.
4555
4556 =item *
4557
4558 If you specify a condition on a prefetched relationship, ONLY those
4559 rows that match the prefetched condition will be fetched into that relationship.
4560 This means that adding prefetch to a search() B<may alter> what is returned by
4561 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4562
4563   my $artist_rs = $schema->resultset('Artist')->search({
4564       'cds.year' => 2008,
4565   }, {
4566       join => 'cds',
4567   });
4568
4569   my $count = $artist_rs->first->cds->count;
4570
4571   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4572
4573   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4574
4575   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4576
4577 That cmp_ok() may or may not pass depending on the datasets involved. This
4578 behavior may or may not survive the 0.09 transition.
4579
4580 =back
4581
4582 =head1 DBIC BIND VALUES
4583
4584 Because DBIC may need more information to bind values than just the column name
4585 and value itself, it uses a special format for both passing and receiving bind
4586 values.  Each bind value should be composed of an arrayref of
4587 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4588
4589 =over 4
4590
4591 =item dbd_attrs
4592
4593 If present (in any form), this is what is being passed directly to bind_param.
4594 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4595 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4596
4597 If this is specified, all other bind options described below are ignored.
4598
4599 =item sqlt_datatype
4600
4601 If present, this is used to infer the actual bind attribute by passing to
4602 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4603 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4604
4605 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4606 currently drivers are expected to "Do the Right Thing" when given a common
4607 datatype name.  (Not ideal, but that's what we got at this point.)
4608
4609 =item sqlt_size
4610
4611 Currently used to correctly allocate buffers for bind_param_inout().
4612 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4613 or to a sensible value based on the "data_type".
4614
4615 =item dbic_colname
4616
4617 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4618 explicitly specified they are never overriden).  Also used by some weird DBDs,
4619 where the column name should be available at bind_param time (e.g. Oracle).
4620
4621 =back
4622
4623 For backwards compatibility and convenience, the following shortcuts are
4624 supported:
4625
4626   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4627   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4628   [ undef,   $val ] === [ {}, $val ]
4629
4630 =head1 AUTHOR AND CONTRIBUTORS
4631
4632 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4633
4634 =head1 LICENSE
4635
4636 You may distribute this code under the same terms as Perl itself.
4637