lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  23
  24 =head1 SYNOPSIS
  25
  26   my $rs   = $schema->resultset('User')->search({ registered => 1 });
  27   my @rows = $schema->resultset('CD')->search({ year => 2005 })->all();
  28
  29 =head1 DESCRIPTION
  30
  31 The resultset is also known as an iterator. It is responsible for handling
  32 queries that may return an arbitrary number of rows, e.g. via L</search>
  33 or a C<has_many> relationship.
  34
  35 In the examples below, the following table classes are used:
  36
  37   package MyApp::Schema::Artist;
  38   use base qw/DBIx::Class/;
  39   __PACKAGE__->load_components(qw/Core/);
  40   __PACKAGE__->table('artist');
  41   __PACKAGE__->add_columns(qw/artistid name/);
  42   __PACKAGE__->set_primary_key('artistid');
  43   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  44   1;
  45
  46   package MyApp::Schema::CD;
  47   use base qw/DBIx::Class/;
  48   __PACKAGE__->load_components(qw/Core/);
  49   __PACKAGE__->table('cd');
  50   __PACKAGE__->add_columns(qw/cdid artist title year/);
  51   __PACKAGE__->set_primary_key('cdid');
  52   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  53   1;
  54
  55 =head1 DISCUSSION
  56
  57 When you create a resultset (usually as a result of calling search()), DBIx::Class
  58 B<doesn't> make a DB call. Not yet. A resultset is (in simplistic terms) a set of
  59 where conditions, join conditions, and other metadata that would be needed to execute
  60 a SELECT statement. This has several big implications:
  61
  62 =over 4
  63
  64 =item * You can chain resultsets
  65
  66 =item * You can run multiple queries using the same resultset
  67
  68 =back
  69
  70 =head2 Chaining resultsets
  71
  72 Let's say you've got a query that needs to be run to return some data to the user. But,
  73 you have an authorization system in place that prevents certain users from seeing certain
  74 information. So, you want to construct the query in one method, but add constraints to it
  75 in another.
  76
  77   sub get_data {
  78     my $self = shift;
  79     my $request = $self->get_request; # Get a request object somehow.
  80     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  81
  82     my $rs = $schema->resultset('some_data')->search({
  83       foo => $request->param('foo'),
  84       bar => $request->param('bar'),
  85     });
  86
  87     $self->apply_security_policy( $rs );
  88
  89     return $rs->all;
  90   }
  91
  92   sub apply_security_policy {
  93     my $self = shift;
  94     my ($rs) = @_;
  95
  96     return $rs->search({
  97       hidden_data => 0,
  98     });
  99   }
 100
 101 =head2 Multiple queries
 102
 103 Since a resultset hasn't hit the database yet, you can do all sorts of things with it.
 104
 105   # Don't hit the DB yet.
 106   my $rs = $schema->resultset('some_table')->search({
 107     foo => 1,
 108     bar => 2,
 109   });
 110
 111   # Each of these hits the DB individually.
 112   my $count = $rs->count;
 113   my $max_baz = $rs->get_column('baz')->max;
 114   my @records = $rs->all;
 115
 116 And it's not just limited to SELECT statements.
 117
 118   $rs->delete;
 119
 120 This is even cooler
 121
 122   $rs->create({ baz => 20 });
 123
 124 That is equivalent to
 125
 126   $schema->resultset('some_table')->create({
 127     foo => 1,
 128     bar => 2,
 129     baz => 20,
 130   });
 131
 132 Note that C<get_column()> returns a ResultSetColumn object. This will behave almost
 133 exactly like a resultset, except it has methods tuned for working with columns.
 134
 135 =head1 OVERLOADING
 136
 137 If a resultset is used in a numeric context it returns the L</count>.
 138 However, if it is used in a booleand context it is always true.  So if
 139 you want to check if a resultset has any results use C<if $rs != 0>.
 140 C<if $rs> will always be true.
 141
 142 =head1 METHODS
 143
 144 =head2 new
 145
 146 =over 4
 147
 148 =item Arguments: $source, \%$attrs
 149
 150 =item Return Value: $rs
 151
 152 =back
 153
 154 The resultset constructor. Takes a source object (usually a
 155 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 156 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 157 executed as needed by the other methods.
 158
 159 Generally you won't need to construct a resultset manually.  You'll
 160 automatically get one from e.g. a L</search> called in scalar context:
 161
 162   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 163
 164 IMPORTANT: If called on an object, proxies to new_result instead so
 165
 166   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 167
 168 will return a CD object, not a ResultSet.
 169
 170 =cut
 171
 172 sub new {
 173   my $class = shift;
 174   return $class->new_result(@_) if ref $class;
 175
 176   my ($source, $attrs) = @_;
 177   $source = $source->handle
 178     unless $source->isa('DBIx::Class::ResultSourceHandle');
 179   $attrs = { %{$attrs||{}} };
 180
 181   if ($attrs->{page}) {
 182     $attrs->{rows} ||= 10;
 183   }
 184
 185   $attrs->{alias} ||= 'me';
 186
 187   # Creation of {} and bless separated to mitigate RH perl bug
 188   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 189   my $self = {
 190     _source_handle => $source,
 191     cond => $attrs->{where},
 192     count => undef,
 193     pager => undef,
 194     attrs => $attrs
 195   };
 196
 197   bless $self, $class;
 198
 199   $self->result_class(
 200     $attrs->{result_class} || $source->resolve->result_class
 201   );
 202
 203   return $self;
 204 }
 205
 206 =head2 search
 207
 208 =over 4
 209
 210 =item Arguments: $cond, \%attrs?
 211
 212 =item Return Value: $resultset (scalar context), @row_objs (list context)
 213
 214 =back
 215
 216   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 217   my $new_rs = $cd_rs->search({ year => 2005 });
 218
 219   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 220                  # year = 2005 OR year = 2004
 221
 222 If you need to pass in additional attributes but no additional condition,
 223 call it as C<search(undef, \%attrs)>.
 224
 225   # "SELECT name, artistid FROM $artist_table"
 226   my @all_artists = $schema->resultset('Artist')->search(undef, {
 227     columns => [qw/name artistid/],
 228   });
 229
 230 For a list of attributes that can be passed to C<search>, see
 231 L</ATTRIBUTES>. For more examples of using this function, see
 232 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 233 documentation for the first argument, see L<SQL::Abstract>.
 234
 235 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 236
 237 =cut
 238
 239 sub search {
 240   my $self = shift;
 241   my $rs = $self->search_rs( @_ );
 242   return (wantarray ? $rs->all : $rs);
 243 }
 244
 245 =head2 search_rs
 246
 247 =over 4
 248
 249 =item Arguments: $cond, \%attrs?
 250
 251 =item Return Value: $resultset
 252
 253 =back
 254
 255 This method does the same exact thing as search() except it will
 256 always return a resultset, even in list context.
 257
 258 =cut
 259
 260 sub search_rs {
 261   my $self = shift;
 262
 263   my $attrs = {};
 264   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 265   my $our_attrs = { %{$self->{attrs}} };
 266   my $having = delete $our_attrs->{having};
 267   my $where = delete $our_attrs->{where};
 268
 269   my $rows;
 270
 271   my %safe = (alias => 1, cache => 1);
 272
 273   unless (
 274     (@_ && defined($_[0])) # @_ == () or (undef)
 275     ||
 276     (keys %$attrs # empty attrs or only 'safe' attrs
 277     && List::Util::first { !$safe{$_} } keys %$attrs)
 278   ) {
 279     # no search, effectively just a clone
 280     $rows = $self->get_cache;
 281   }
 282
 283   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 284
 285   # merge new attrs into inherited
 286   foreach my $key (qw/join prefetch +select +as/) {
 287     next unless exists $attrs->{$key};
 288     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 289   }
 290
 291   my $cond = (@_
 292     ? (
 293         (@_ == 1 || ref $_[0] eq "HASH")
 294           ? (
 295               (ref $_[0] eq 'HASH')
 296                 ? (
 297                     (keys %{ $_[0] }  > 0)
 298                       ? shift
 299                       : undef
 300                    )
 301                 :  shift
 302              )
 303           : (
 304               (@_ % 2)
 305                 ? $self->throw_exception("Odd number of arguments to search")
 306                 : {@_}
 307              )
 308       )
 309     : undef
 310   );
 311
 312   if (defined $where) {
 313     $new_attrs->{where} = (
 314       defined $new_attrs->{where}
 315         ? { '-and' => [
 316               map {
 317                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 318               } $where, $new_attrs->{where}
 319             ]
 320           }
 321         : $where);
 322   }
 323
 324   if (defined $cond) {
 325     $new_attrs->{where} = (
 326       defined $new_attrs->{where}
 327         ? { '-and' => [
 328               map {
 329                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 330               } $cond, $new_attrs->{where}
 331             ]
 332           }
 333         : $cond);
 334   }
 335
 336   if (defined $having) {
 337     $new_attrs->{having} = (
 338       defined $new_attrs->{having}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $having, $new_attrs->{having}
 343             ]
 344           }
 345         : $having);
 346   }
 347
 348   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 349   if ($rows) {
 350     $rs->set_cache($rows);
 351   }
 352   return $rs;
 353 }
 354
 355 =head2 search_literal
 356
 357 =over 4
 358
 359 =item Arguments: $sql_fragment, @bind_values
 360
 361 =item Return Value: $resultset (scalar context), @row_objs (list context)
 362
 363 =back
 364
 365   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 366   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 367
 368 Pass a literal chunk of SQL to be added to the conditional part of the
 369 resultset query.
 370
 371 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 372 only be used in that context. There are known problems using C<search_literal>
 373 in chained queries; it can result in bind values in the wrong order.  See
 374 L<DBIx::Class::Manual::Cookbook/Searching> and
 375 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 376 require C<search_literal>.
 377
 378 =cut
 379
 380 sub search_literal {
 381   my ($self, $cond, @vals) = @_;
 382   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 383   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 384   return $self->search(\$cond, $attrs);
 385 }
 386
 387 =head2 find
 388
 389 =over 4
 390
 391 =item Arguments: @values | \%cols, \%attrs?
 392
 393 =item Return Value: $row_object | undef
 394
 395 =back
 396
 397 Finds a row based on its primary key or unique constraint. For example, to find
 398 a row by its primary key:
 399
 400   my $cd = $schema->resultset('CD')->find(5);
 401
 402 You can also find a row by a specific unique constraint using the C<key>
 403 attribute. For example:
 404
 405   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 406     key => 'cd_artist_title'
 407   });
 408
 409 Additionally, you can specify the columns explicitly by name:
 410
 411   my $cd = $schema->resultset('CD')->find(
 412     {
 413       artist => 'Massive Attack',
 414       title  => 'Mezzanine',
 415     },
 416     { key => 'cd_artist_title' }
 417   );
 418
 419 If the C<key> is specified as C<primary>, it searches only on the primary key.
 420
 421 If no C<key> is specified, it searches on all unique constraints defined on the
 422 source for which column data is provided, including the primary key.
 423
 424 If your table does not have a primary key, you B<must> provide a value for the
 425 C<key> attribute matching one of the unique constraints on the source.
 426
 427 In addition to C<key>, L</find> recognizes and applies standard
 428 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 429
 430 Note: If your query does not return only one row, a warning is generated:
 431
 432   Query returned more than one row
 433
 434 See also L</find_or_create> and L</update_or_create>. For information on how to
 435 declare unique constraints, see
 436 L<DBIx::Class::ResultSource/add_unique_constraint>.
 437
 438 =cut
 439
 440 sub find {
 441   my $self = shift;
 442   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 443
 444   # Default to the primary key, but allow a specific key
 445   my @cols = exists $attrs->{key}
 446     ? $self->result_source->unique_constraint_columns($attrs->{key})
 447     : $self->result_source->primary_columns;
 448   $self->throw_exception(
 449     "Can't find unless a primary key is defined or unique constraint is specified"
 450   ) unless @cols;
 451
 452   # Parse out a hashref from input
 453   my $input_query;
 454   if (ref $_[0] eq 'HASH') {
 455     $input_query = { %{$_[0]} };
 456   }
 457   elsif (@_ == @cols) {
 458     $input_query = {};
 459     @{$input_query}{@cols} = @_;
 460   }
 461   else {
 462     # Compatibility: Allow e.g. find(id => $value)
 463     carp "Find by key => value deprecated; please use a hashref instead";
 464     $input_query = {@_};
 465   }
 466
 467   my (%related, $info);
 468
 469   KEY: foreach my $key (keys %$input_query) {
 470     if (ref($input_query->{$key})
 471         && ($info = $self->result_source->relationship_info($key))) {
 472       my $val = delete $input_query->{$key};
 473       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 474       my $rel_q = $self->result_source->resolve_condition(
 475                     $info->{cond}, $val, $key
 476                   );
 477       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 478       @related{keys %$rel_q} = values %$rel_q;
 479     }
 480   }
 481   if (my @keys = keys %related) {
 482     @{$input_query}{@keys} = values %related;
 483   }
 484
 485
 486   # Build the final query: Default to the disjunction of the unique queries,
 487   # but allow the input query in case the ResultSet defines the query or the
 488   # user is abusing find
 489   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 490   my $query;
 491   if (exists $attrs->{key}) {
 492     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 493     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 494     $query = $self->_add_alias($unique_query, $alias);
 495   }
 496   else {
 497     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 498     $query = @unique_queries
 499       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 500       : $self->_add_alias($input_query, $alias);
 501   }
 502
 503   # Run the query
 504   if (keys %$attrs) {
 505     my $rs = $self->search($query, $attrs);
 506     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 507       my $row = $rs->next;
 508       carp "Query returned more than one row" if $rs->next;
 509       return $row;
 510     }
 511     else {
 512       return $rs->single;
 513     }
 514   }
 515   else {
 516     if (keys %{$self->_resolved_attrs->{collapse}}) {
 517       my $rs = $self->search($query);
 518       my $row = $rs->next;
 519       carp "Query returned more than one row" if $rs->next;
 520       return $row;
 521     }
 522     else {
 523       return $self->single($query);
 524     }
 525   }
 526 }
 527
 528 # _add_alias
 529 #
 530 # Add the specified alias to the specified query hash. A copy is made so the
 531 # original query is not modified.
 532
 533 sub _add_alias {
 534   my ($self, $query, $alias) = @_;
 535
 536   my %aliased = %$query;
 537   foreach my $col (grep { ! m/\./ } keys %aliased) {
 538     $aliased{"$alias.$col"} = delete $aliased{$col};
 539   }
 540
 541   return \%aliased;
 542 }
 543
 544 # _unique_queries
 545 #
 546 # Build a list of queries which satisfy unique constraints.
 547
 548 sub _unique_queries {
 549   my ($self, $query, $attrs) = @_;
 550
 551   my @constraint_names = exists $attrs->{key}
 552     ? ($attrs->{key})
 553     : $self->result_source->unique_constraint_names;
 554
 555   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 556   my $num_where = scalar keys %$where;
 557
 558   my @unique_queries;
 559   foreach my $name (@constraint_names) {
 560     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 561     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 562
 563     my $num_cols = scalar @unique_cols;
 564     my $num_query = scalar keys %$unique_query;
 565
 566     my $total = $num_query + $num_where;
 567     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 568       # The query is either unique on its own or is unique in combination with
 569       # the existing where clause
 570       push @unique_queries, $unique_query;
 571     }
 572   }
 573
 574   return @unique_queries;
 575 }
 576
 577 # _build_unique_query
 578 #
 579 # Constrain the specified query hash based on the specified column names.
 580
 581 sub _build_unique_query {
 582   my ($self, $query, $unique_cols) = @_;
 583
 584   return {
 585     map  { $_ => $query->{$_} }
 586     grep { exists $query->{$_} }
 587       @$unique_cols
 588   };
 589 }
 590
 591 =head2 search_related
 592
 593 =over 4
 594
 595 =item Arguments: $rel, $cond, \%attrs?
 596
 597 =item Return Value: $new_resultset
 598
 599 =back
 600
 601   $new_rs = $cd_rs->search_related('artist', {
 602     name => 'Emo-R-Us',
 603   });
 604
 605 Searches the specified relationship, optionally specifying a condition and
 606 attributes for matching records. See L</ATTRIBUTES> for more information.
 607
 608 =cut
 609
 610 sub search_related {
 611   return shift->related_resultset(shift)->search(@_);
 612 }
 613
 614 =head2 search_related_rs
 615
 616 This method works exactly the same as search_related, except that
 617 it guarantees a restultset, even in list context.
 618
 619 =cut
 620
 621 sub search_related_rs {
 622   return shift->related_resultset(shift)->search_rs(@_);
 623 }
 624
 625 =head2 cursor
 626
 627 =over 4
 628
 629 =item Arguments: none
 630
 631 =item Return Value: $cursor
 632
 633 =back
 634
 635 Returns a storage-driven cursor to the given resultset. See
 636 L<DBIx::Class::Cursor> for more information.
 637
 638 =cut
 639
 640 sub cursor {
 641   my ($self) = @_;
 642
 643   my $attrs = { %{$self->_resolved_attrs} };
 644   return $self->{cursor}
 645     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 646           $attrs->{where},$attrs);
 647 }
 648
 649 =head2 single
 650
 651 =over 4
 652
 653 =item Arguments: $cond?
 654
 655 =item Return Value: $row_object?
 656
 657 =back
 658
 659   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 660
 661 Inflates the first result without creating a cursor if the resultset has
 662 any records in it; if not returns nothing. Used by L</find> as a lean version of
 663 L</search>.
 664
 665 While this method can take an optional search condition (just like L</search>)
 666 being a fast-code-path it does not recognize search attributes. If you need to
 667 add extra joins or similar, call L</search> and then chain-call L</single> on the
 668 L<DBIx::Class::ResultSet> returned.
 669
 670 =over
 671
 672 =item B<Note>
 673
 674 As of 0.08100, this method enforces the assumption that the preceeding
 675 query returns only one row. If more than one row is returned, you will receive
 676 a warning:
 677
 678   Query returned more than one row
 679
 680 In this case, you should be using L</first> or L</find> instead, or if you really
 681 know what you are doing, use the L</rows> attribute to explicitly limit the size
 682 of the resultset.
 683
 684 =back
 685
 686 =cut
 687
 688 sub single {
 689   my ($self, $where) = @_;
 690   if(@_ > 2) {
 691       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 692   }
 693
 694   my $attrs = { %{$self->_resolved_attrs} };
 695   if ($where) {
 696     if (defined $attrs->{where}) {
 697       $attrs->{where} = {
 698         '-and' =>
 699             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 700                $where, delete $attrs->{where} ]
 701       };
 702     } else {
 703       $attrs->{where} = $where;
 704     }
 705   }
 706
 707 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 708 #  unless ($self->_is_unique_query($attrs->{where})) {
 709 #    carp "Query not guaranteed to return a single row"
 710 #      . "; please declare your unique constraints or use search instead";
 711 #  }
 712
 713   my @data = $self->result_source->storage->select_single(
 714     $attrs->{from}, $attrs->{select},
 715     $attrs->{where}, $attrs
 716   );
 717
 718   return (@data ? ($self->_construct_object(@data))[0] : undef);
 719 }
 720
 721 # _is_unique_query
 722 #
 723 # Try to determine if the specified query is guaranteed to be unique, based on
 724 # the declared unique constraints.
 725
 726 sub _is_unique_query {
 727   my ($self, $query) = @_;
 728
 729   my $collapsed = $self->_collapse_query($query);
 730   my $alias = $self->{attrs}{alias};
 731
 732   foreach my $name ($self->result_source->unique_constraint_names) {
 733     my @unique_cols = map {
 734       "$alias.$_"
 735     } $self->result_source->unique_constraint_columns($name);
 736
 737     # Count the values for each unique column
 738     my %seen = map { $_ => 0 } @unique_cols;
 739
 740     foreach my $key (keys %$collapsed) {
 741       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 742       next unless exists $seen{$aliased};  # Additional constraints are okay
 743       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 744     }
 745
 746     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 747     return 1 unless grep { $_ != 1 } values %seen;
 748   }
 749
 750   return 0;
 751 }
 752
 753 # _collapse_query
 754 #
 755 # Recursively collapse the query, accumulating values for each column.
 756
 757 sub _collapse_query {
 758   my ($self, $query, $collapsed) = @_;
 759
 760   $collapsed ||= {};
 761
 762   if (ref $query eq 'ARRAY') {
 763     foreach my $subquery (@$query) {
 764       next unless ref $subquery;  # -or
 765 #      warn "ARRAY: " . Dumper $subquery;
 766       $collapsed = $self->_collapse_query($subquery, $collapsed);
 767     }
 768   }
 769   elsif (ref $query eq 'HASH') {
 770     if (keys %$query and (keys %$query)[0] eq '-and') {
 771       foreach my $subquery (@{$query->{-and}}) {
 772 #        warn "HASH: " . Dumper $subquery;
 773         $collapsed = $self->_collapse_query($subquery, $collapsed);
 774       }
 775     }
 776     else {
 777 #      warn "LEAF: " . Dumper $query;
 778       foreach my $col (keys %$query) {
 779         my $value = $query->{$col};
 780         $collapsed->{$col}{$value}++;
 781       }
 782     }
 783   }
 784
 785   return $collapsed;
 786 }
 787
 788 =head2 get_column
 789
 790 =over 4
 791
 792 =item Arguments: $cond?
 793
 794 =item Return Value: $resultsetcolumn
 795
 796 =back
 797
 798   my $max_length = $rs->get_column('length')->max;
 799
 800 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 801
 802 =cut
 803
 804 sub get_column {
 805   my ($self, $column) = @_;
 806   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 807   return $new;
 808 }
 809
 810 =head2 search_like
 811
 812 =over 4
 813
 814 =item Arguments: $cond, \%attrs?
 815
 816 =item Return Value: $resultset (scalar context), @row_objs (list context)
 817
 818 =back
 819
 820   # WHERE title LIKE '%blue%'
 821   $cd_rs = $rs->search_like({ title => '%blue%'});
 822
 823 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 824 that this is simply a convenience method retained for ex Class::DBI users.
 825 You most likely want to use L</search> with specific operators.
 826
 827 For more information, see L<DBIx::Class::Manual::Cookbook>.
 828
 829 =cut
 830
 831 sub search_like {
 832   my $class = shift;
 833   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 834   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 835   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 836   return $class->search($query, { %$attrs });
 837 }
 838
 839 =head2 slice
 840
 841 =over 4
 842
 843 =item Arguments: $first, $last
 844
 845 =item Return Value: $resultset (scalar context), @row_objs (list context)
 846
 847 =back
 848
 849 Returns a resultset or object list representing a subset of elements from the
 850 resultset slice is called on. Indexes are from 0, i.e., to get the first
 851 three records, call:
 852
 853   my ($one, $two, $three) = $rs->slice(0, 2);
 854
 855 =cut
 856
 857 sub slice {
 858   my ($self, $min, $max) = @_;
 859   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 860   $attrs->{offset} = $self->{attrs}{offset} || 0;
 861   $attrs->{offset} += $min;
 862   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 863   return $self->search(undef(), $attrs);
 864   #my $slice = (ref $self)->new($self->result_source, $attrs);
 865   #return (wantarray ? $slice->all : $slice);
 866 }
 867
 868 =head2 next
 869
 870 =over 4
 871
 872 =item Arguments: none
 873
 874 =item Return Value: $result?
 875
 876 =back
 877
 878 Returns the next element in the resultset (C<undef> is there is none).
 879
 880 Can be used to efficiently iterate over records in the resultset:
 881
 882   my $rs = $schema->resultset('CD')->search;
 883   while (my $cd = $rs->next) {
 884     print $cd->title;
 885   }
 886
 887 Note that you need to store the resultset object, and call C<next> on it.
 888 Calling C<< resultset('Table')->next >> repeatedly will always return the
 889 first record from the resultset.
 890
 891 =cut
 892
 893 sub next {
 894   my ($self) = @_;
 895   if (my $cache = $self->get_cache) {
 896     $self->{all_cache_position} ||= 0;
 897     return $cache->[$self->{all_cache_position}++];
 898   }
 899   if ($self->{attrs}{cache}) {
 900     $self->{all_cache_position} = 1;
 901     return ($self->all)[0];
 902   }
 903   if ($self->{stashed_objects}) {
 904     my $obj = shift(@{$self->{stashed_objects}});
 905     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 906     return $obj;
 907   }
 908   my @row = (
 909     exists $self->{stashed_row}
 910       ? @{delete $self->{stashed_row}}
 911       : $self->cursor->next
 912   );
 913   return undef unless (@row);
 914   my ($row, @more) = $self->_construct_object(@row);
 915   $self->{stashed_objects} = \@more if @more;
 916   return $row;
 917 }
 918
 919 sub _construct_object {
 920   my ($self, @row) = @_;
 921   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 922   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 923   @new = $self->{_attrs}{record_filter}->(@new)
 924     if exists $self->{_attrs}{record_filter};
 925   return @new;
 926 }
 927
 928 sub _collapse_result {
 929   my ($self, $as_proto, $row) = @_;
 930
 931   my @copy = @$row;
 932
 933   # 'foo'         => [ undef, 'foo' ]
 934   # 'foo.bar'     => [ 'foo', 'bar' ]
 935   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 936
 937   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 938
 939   my %collapse = %{$self->{_attrs}{collapse}||{}};
 940
 941   my @pri_index;
 942
 943   # if we're doing collapsing (has_many prefetch) we need to grab records
 944   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 945   # we know we don't have to bother.
 946
 947   # the reason for not using the collapse stuff directly is because if you
 948   # had for e.g. two artists in a row with no cds, the collapse info for
 949   # both would be NULL (undef) so you'd lose the second artist
 950
 951   # store just the index so we can check the array positions from the row
 952   # without having to contruct the full hash
 953
 954   if (keys %collapse) {
 955     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 956     foreach my $i (0 .. $#construct_as) {
 957       next if defined($construct_as[$i][0]); # only self table
 958       if (delete $pri{$construct_as[$i][1]}) {
 959         push(@pri_index, $i);
 960       }
 961       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 962     }
 963   }
 964
 965   # no need to do an if, it'll be empty if @pri_index is empty anyway
 966
 967   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 968
 969   my @const_rows;
 970
 971   do { # no need to check anything at the front, we always want the first row
 972
 973     my %const;
 974
 975     foreach my $this_as (@construct_as) {
 976       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 977     }
 978
 979     push(@const_rows, \%const);
 980
 981   } until ( # no pri_index => no collapse => drop straight out
 982       !@pri_index
 983     or
 984       do { # get another row, stash it, drop out if different PK
 985
 986         @copy = $self->cursor->next;
 987         $self->{stashed_row} = \@copy;
 988
 989         # last thing in do block, counts as true if anything doesn't match
 990
 991         # check xor defined first for NULL vs. NOT NULL then if one is
 992         # defined the other must be so check string equality
 993
 994         grep {
 995           (defined $pri_vals{$_} ^ defined $copy[$_])
 996           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 997         } @pri_index;
 998       }
 999   );
1000
1001   my $alias = $self->{attrs}{alias};
1002   my $info = [];
1003
1004   my %collapse_pos;
1005
1006   my @const_keys;
1007
1008   foreach my $const (@const_rows) {
1009     scalar @const_keys or do {
1010       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1011     };
1012     foreach my $key (@const_keys) {
1013       if (length $key) {
1014         my $target = $info;
1015         my @parts = split(/\./, $key);
1016         my $cur = '';
1017         my $data = $const->{$key};
1018         foreach my $p (@parts) {
1019           $target = $target->[1]->{$p} ||= [];
1020           $cur .= ".${p}";
1021           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1022             # collapsing at this point and on final part
1023             my $pos = $collapse_pos{$cur};
1024             CK: foreach my $ck (@ckey) {
1025               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1026                 $collapse_pos{$cur} = $data;
1027                 delete @collapse_pos{ # clear all positioning for sub-entries
1028                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1029                 };
1030                 push(@$target, []);
1031                 last CK;
1032               }
1033             }
1034           }
1035           if (exists $collapse{$cur}) {
1036             $target = $target->[-1];
1037           }
1038         }
1039         $target->[0] = $data;
1040       } else {
1041         $info->[0] = $const->{$key};
1042       }
1043     }
1044   }
1045
1046   return $info;
1047 }
1048
1049 =head2 result_source
1050
1051 =over 4
1052
1053 =item Arguments: $result_source?
1054
1055 =item Return Value: $result_source
1056
1057 =back
1058
1059 An accessor for the primary ResultSource object from which this ResultSet
1060 is derived.
1061
1062 =head2 result_class
1063
1064 =over 4
1065
1066 =item Arguments: $result_class?
1067
1068 =item Return Value: $result_class
1069
1070 =back
1071
1072 An accessor for the class to use when creating row objects. Defaults to
1073 C<< result_source->result_class >> - which in most cases is the name of the
1074 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1075
1076 =cut
1077
1078 sub result_class {
1079   my ($self, $result_class) = @_;
1080   if ($result_class) {
1081     $self->ensure_class_loaded($result_class);
1082     $self->_result_class($result_class);
1083   }
1084   $self->_result_class;
1085 }
1086
1087 =head2 count
1088
1089 =over 4
1090
1091 =item Arguments: $cond, \%attrs??
1092
1093 =item Return Value: $count
1094
1095 =back
1096
1097 Performs an SQL C<COUNT> with the same query as the resultset was built
1098 with to find the number of elements. If passed arguments, does a search
1099 on the resultset and counts the results of that.
1100
1101 Note: When using C<count> with C<group_by>, L<DBIx::Class> emulates C<GROUP BY>
1102 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
1103 not support C<DISTINCT> with multiple columns. If you are using such a
1104 database, you should only use columns from the main table in your C<group_by>
1105 clause.
1106
1107 =cut
1108
1109 sub count {
1110   my $self = shift;
1111   return $self->search(@_)->count if @_ and defined $_[0];
1112   return scalar @{ $self->get_cache } if $self->get_cache;
1113   my $count = $self->_count;
1114   return 0 unless $count;
1115
1116   # need to take offset from resolved attrs
1117
1118   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1119   $count = $self->{attrs}{rows} if
1120     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1121   $count = 0 if ($count < 0);
1122   return $count;
1123 }
1124
1125 sub _count { # Separated out so pager can get the full count
1126   my $self = shift;
1127   my $select = { count => '*' };
1128
1129   my $attrs = { %{$self->_resolved_attrs} };
1130   if (my $group_by = delete $attrs->{group_by}) {
1131     delete $attrs->{having};
1132     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
1133     # todo: try CONCAT for multi-column pk
1134     my @pk = $self->result_source->primary_columns;
1135     if (@pk == 1) {
1136       my $alias = $attrs->{alias};
1137       foreach my $column (@distinct) {
1138         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
1139           @distinct = ($column);
1140           last;
1141         }
1142       }
1143     }
1144
1145     $select = { count => { distinct => \@distinct } };
1146   }
1147
1148   $attrs->{select} = $select;
1149   $attrs->{as} = [qw/count/];
1150
1151   # offset, order by and page are not needed to count. record_filter is cdbi
1152   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
1153
1154   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1155   my ($count) = $tmp_rs->cursor->next;
1156   return $count;
1157 }
1158
1159 sub _bool {
1160   return 1;
1161 }
1162
1163 =head2 count_literal
1164
1165 =over 4
1166
1167 =item Arguments: $sql_fragment, @bind_values
1168
1169 =item Return Value: $count
1170
1171 =back
1172
1173 Counts the results in a literal query. Equivalent to calling L</search_literal>
1174 with the passed arguments, then L</count>.
1175
1176 =cut
1177
1178 sub count_literal { shift->search_literal(@_)->count; }
1179
1180 =head2 all
1181
1182 =over 4
1183
1184 =item Arguments: none
1185
1186 =item Return Value: @objects
1187
1188 =back
1189
1190 Returns all elements in the resultset. Called implicitly if the resultset
1191 is returned in list context.
1192
1193 =cut
1194
1195 sub all {
1196   my $self = shift;
1197   if(@_) {
1198       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1199   }
1200
1201   return @{ $self->get_cache } if $self->get_cache;
1202
1203   my @obj;
1204
1205   # TODO: don't call resolve here
1206   if (keys %{$self->_resolved_attrs->{collapse}}) {
1207 #  if ($self->{attrs}{prefetch}) {
1208       # Using $self->cursor->all is really just an optimisation.
1209       # If we're collapsing has_many prefetches it probably makes
1210       # very little difference, and this is cleaner than hacking
1211       # _construct_object to survive the approach
1212     my @row = $self->cursor->next;
1213     while (@row) {
1214       push(@obj, $self->_construct_object(@row));
1215       @row = (exists $self->{stashed_row}
1216                ? @{delete $self->{stashed_row}}
1217                : $self->cursor->next);
1218     }
1219   } else {
1220     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1221   }
1222
1223   $self->set_cache(\@obj) if $self->{attrs}{cache};
1224   return @obj;
1225 }
1226
1227 =head2 reset
1228
1229 =over 4
1230
1231 =item Arguments: none
1232
1233 =item Return Value: $self
1234
1235 =back
1236
1237 Resets the resultset's cursor, so you can iterate through the elements again.
1238
1239 =cut
1240
1241 sub reset {
1242   my ($self) = @_;
1243   delete $self->{_attrs} if exists $self->{_attrs};
1244   $self->{all_cache_position} = 0;
1245   $self->cursor->reset;
1246   return $self;
1247 }
1248
1249 =head2 first
1250
1251 =over 4
1252
1253 =item Arguments: none
1254
1255 =item Return Value: $object?
1256
1257 =back
1258
1259 Resets the resultset and returns an object for the first result (if the
1260 resultset returns anything).
1261
1262 =cut
1263
1264 sub first {
1265   return $_[0]->reset->next;
1266 }
1267
1268 # _cond_for_update_delete
1269 #
1270 # update/delete require the condition to be modified to handle
1271 # the differing SQL syntax available.  This transforms the $self->{cond}
1272 # appropriately, returning the new condition.
1273
1274 sub _cond_for_update_delete {
1275   my ($self, $full_cond) = @_;
1276   my $cond = {};
1277
1278   $full_cond ||= $self->{cond};
1279   # No-op. No condition, we're updating/deleting everything
1280   return $cond unless ref $full_cond;
1281
1282   if (ref $full_cond eq 'ARRAY') {
1283     $cond = [
1284       map {
1285         my %hash;
1286         foreach my $key (keys %{$_}) {
1287           $key =~ /([^.]+)$/;
1288           $hash{$1} = $_->{$key};
1289         }
1290         \%hash;
1291       } @{$full_cond}
1292     ];
1293   }
1294   elsif (ref $full_cond eq 'HASH') {
1295     if ((keys %{$full_cond})[0] eq '-and') {
1296       $cond->{-and} = [];
1297
1298       my @cond = @{$full_cond->{-and}};
1299       for (my $i = 0; $i < @cond; $i++) {
1300         my $entry = $cond[$i];
1301
1302         my $hash;
1303         if (ref $entry eq 'HASH') {
1304           $hash = $self->_cond_for_update_delete($entry);
1305         }
1306         else {
1307           $entry =~ /([^.]+)$/;
1308           $hash->{$1} = $cond[++$i];
1309         }
1310
1311         push @{$cond->{-and}}, $hash;
1312       }
1313     }
1314     else {
1315       foreach my $key (keys %{$full_cond}) {
1316         $key =~ /([^.]+)$/;
1317         $cond->{$1} = $full_cond->{$key};
1318       }
1319     }
1320   }
1321   else {
1322     $self->throw_exception(
1323       "Can't update/delete on resultset with condition unless hash or array"
1324     );
1325   }
1326
1327   return $cond;
1328 }
1329
1330
1331 =head2 update
1332
1333 =over 4
1334
1335 =item Arguments: \%values
1336
1337 =item Return Value: $storage_rv
1338
1339 =back
1340
1341 Sets the specified columns in the resultset to the supplied values in a
1342 single query. Return value will be true if the update succeeded or false
1343 if no records were updated; exact type of success value is storage-dependent.
1344
1345 =cut
1346
1347 sub update {
1348   my ($self, $values) = @_;
1349   $self->throw_exception("Values for update must be a hash")
1350     unless ref $values eq 'HASH';
1351
1352   carp(   'WARNING! Currently $rs->update() does not generate proper SQL'
1353         . ' on joined resultsets, and may affect rows well outside of the'
1354         . ' contents of $rs. Use at your own risk' )
1355     if ( $self->{attrs}{seen_join} );
1356
1357   my $cond = $self->_cond_for_update_delete;
1358
1359   return $self->result_source->storage->update(
1360     $self->result_source, $values, $cond
1361   );
1362 }
1363
1364 =head2 update_all
1365
1366 =over 4
1367
1368 =item Arguments: \%values
1369
1370 =item Return Value: 1
1371
1372 =back
1373
1374 Fetches all objects and updates them one at a time. Note that C<update_all>
1375 will run DBIC cascade triggers, while L</update> will not.
1376
1377 =cut
1378
1379 sub update_all {
1380   my ($self, $values) = @_;
1381   $self->throw_exception("Values for update must be a hash")
1382     unless ref $values eq 'HASH';
1383   foreach my $obj ($self->all) {
1384     $obj->set_columns($values)->update;
1385   }
1386   return 1;
1387 }
1388
1389 =head2 delete
1390
1391 =over 4
1392
1393 =item Arguments: none
1394
1395 =item Return Value: 1
1396
1397 =back
1398
1399 Deletes the contents of the resultset from its result source. Note that this
1400 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1401 to run. See also L<DBIx::Class::Row/delete>.
1402
1403 delete may not generate correct SQL for a query with joins or a resultset
1404 chained from a related resultset.  In this case it will generate a warning:-
1405
1406   WARNING! Currently $rs->delete() does not generate proper SQL on
1407   joined resultsets, and may delete rows well outside of the contents
1408   of $rs. Use at your own risk
1409
1410 In these cases you may find that delete_all is more appropriate, or you
1411 need to respecify your query in a way that can be expressed without a join.
1412
1413 =cut
1414
1415 sub delete {
1416   my ($self) = @_;
1417   $self->throw_exception("Delete should not be passed any arguments")
1418     if $_[1];
1419   carp(   'WARNING! Currently $rs->delete() does not generate proper SQL'
1420         . ' on joined resultsets, and may delete rows well outside of the'
1421         . ' contents of $rs. Use at your own risk' )
1422     if ( $self->{attrs}{seen_join} );
1423   my $cond = $self->_cond_for_update_delete;
1424
1425   $self->result_source->storage->delete($self->result_source, $cond);
1426   return 1;
1427 }
1428
1429 =head2 delete_all
1430
1431 =over 4
1432
1433 =item Arguments: none
1434
1435 =item Return Value: 1
1436
1437 =back
1438
1439 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1440 will run DBIC cascade triggers, while L</delete> will not.
1441
1442 =cut
1443
1444 sub delete_all {
1445   my ($self) = @_;
1446   $_->delete for $self->all;
1447   return 1;
1448 }
1449
1450 =head2 populate
1451
1452 =over 4
1453
1454 =item Arguments: \@data;
1455
1456 =back
1457
1458 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1459 For the arrayref of hashrefs style each hashref should be a structure suitable
1460 forsubmitting to a $resultset->create(...) method.
1461
1462 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1463 to insert the data, as this is a faster method.
1464
1465 Otherwise, each set of data is inserted into the database using
1466 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1467 objects is returned.
1468
1469 Example:  Assuming an Artist Class that has many CDs Classes relating:
1470
1471   my $Artist_rs = $schema->resultset("Artist");
1472
1473   ## Void Context Example
1474   $Artist_rs->populate([
1475      { artistid => 4, name => 'Manufactured Crap', cds => [
1476         { title => 'My First CD', year => 2006 },
1477         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1478       ],
1479      },
1480      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1481         { title => 'My parents sold me to a record company' ,year => 2005 },
1482         { title => 'Why Am I So Ugly?', year => 2006 },
1483         { title => 'I Got Surgery and am now Popular', year => 2007 }
1484       ],
1485      },
1486   ]);
1487
1488   ## Array Context Example
1489   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1490     { name => "Artist One"},
1491     { name => "Artist Two"},
1492     { name => "Artist Three", cds=> [
1493     { title => "First CD", year => 2007},
1494     { title => "Second CD", year => 2008},
1495   ]}
1496   ]);
1497
1498   print $ArtistOne->name; ## response is 'Artist One'
1499   print $ArtistThree->cds->count ## reponse is '2'
1500
1501 For the arrayref of arrayrefs style,  the first element should be a list of the
1502 fieldsnames to which the remaining elements are rows being inserted.  For
1503 example:
1504
1505   $Arstist_rs->populate([
1506     [qw/artistid name/],
1507     [100, 'A Formally Unknown Singer'],
1508     [101, 'A singer that jumped the shark two albums ago'],
1509     [102, 'An actually cool singer.'],
1510   ]);
1511
1512 Please note an important effect on your data when choosing between void and
1513 wantarray context. Since void context goes straight to C<insert_bulk> in
1514 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1515 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1516 create primary keys for you, you will find that your PKs are empty.  In this
1517 case you will have to use the wantarray context in order to create those
1518 values.
1519
1520 =cut
1521
1522 sub populate {
1523   my $self = shift @_;
1524   my $data = ref $_[0][0] eq 'HASH'
1525     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1526     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1527
1528   if(defined wantarray) {
1529     my @created;
1530     foreach my $item (@$data) {
1531       push(@created, $self->create($item));
1532     }
1533     return @created;
1534   } else {
1535     my ($first, @rest) = @$data;
1536
1537     my @names = grep {!ref $first->{$_}} keys %$first;
1538     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1539     my @pks = $self->result_source->primary_columns;
1540
1541     ## do the belongs_to relationships
1542     foreach my $index (0..$#$data) {
1543       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1544         my @ret = $self->populate($data);
1545         return;
1546       }
1547
1548       foreach my $rel (@rels) {
1549         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1550         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1551         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1552         my $related = $result->result_source->resolve_condition(
1553           $result->result_source->relationship_info($reverse)->{cond},
1554           $self,
1555           $result,
1556         );
1557
1558         delete $data->[$index]->{$rel};
1559         $data->[$index] = {%{$data->[$index]}, %$related};
1560
1561         push @names, keys %$related if $index == 0;
1562       }
1563     }
1564
1565     ## do bulk insert on current row
1566     my @values = map { [ @$_{@names} ] } @$data;
1567
1568     $self->result_source->storage->insert_bulk(
1569       $self->result_source,
1570       \@names,
1571       \@values,
1572     );
1573
1574     ## do the has_many relationships
1575     foreach my $item (@$data) {
1576
1577       foreach my $rel (@rels) {
1578         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1579
1580         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1581      || $self->throw_exception('Cannot find the relating object.');
1582
1583         my $child = $parent->$rel;
1584
1585         my $related = $child->result_source->resolve_condition(
1586           $parent->result_source->relationship_info($rel)->{cond},
1587           $child,
1588           $parent,
1589         );
1590
1591         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1592         my @populate = map { {%$_, %$related} } @rows_to_add;
1593
1594         $child->populate( \@populate );
1595       }
1596     }
1597   }
1598 }
1599
1600 =head2 _normalize_populate_args ($args)
1601
1602 Private method used by L</populate> to normalize its incoming arguments.  Factored
1603 out in case you want to subclass and accept new argument structures to the
1604 L</populate> method.
1605
1606 =cut
1607
1608 sub _normalize_populate_args {
1609   my ($self, $data) = @_;
1610   my @names = @{shift(@$data)};
1611   my @results_to_create;
1612   foreach my $datum (@$data) {
1613     my %result_to_create;
1614     foreach my $index (0..$#names) {
1615       $result_to_create{$names[$index]} = $$datum[$index];
1616     }
1617     push @results_to_create, \%result_to_create;
1618   }
1619   return \@results_to_create;
1620 }
1621
1622 =head2 pager
1623
1624 =over 4
1625
1626 =item Arguments: none
1627
1628 =item Return Value: $pager
1629
1630 =back
1631
1632 Return Value a L<Data::Page> object for the current resultset. Only makes
1633 sense for queries with a C<page> attribute.
1634
1635 =cut
1636
1637 sub pager {
1638   my ($self) = @_;
1639   my $attrs = $self->{attrs};
1640   $self->throw_exception("Can't create pager for non-paged rs")
1641     unless $self->{attrs}{page};
1642   $attrs->{rows} ||= 10;
1643   return $self->{pager} ||= Data::Page->new(
1644     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1645 }
1646
1647 =head2 page
1648
1649 =over 4
1650
1651 =item Arguments: $page_number
1652
1653 =item Return Value: $rs
1654
1655 =back
1656
1657 Returns a resultset for the $page_number page of the resultset on which page
1658 is called, where each page contains a number of rows equal to the 'rows'
1659 attribute set on the resultset (10 by default).
1660
1661 =cut
1662
1663 sub page {
1664   my ($self, $page) = @_;
1665   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1666 }
1667
1668 =head2 new_result
1669
1670 =over 4
1671
1672 =item Arguments: \%vals
1673
1674 =item Return Value: $rowobject
1675
1676 =back
1677
1678 Creates a new row object in the resultset's result class and returns
1679 it. The row is not inserted into the database at this point, call
1680 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1681 will tell you whether the row object has been inserted or not.
1682
1683 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1684
1685 =cut
1686
1687 sub new_result {
1688   my ($self, $values) = @_;
1689   $self->throw_exception( "new_result needs a hash" )
1690     unless (ref $values eq 'HASH');
1691
1692   my %new;
1693   my $alias = $self->{attrs}{alias};
1694
1695   if (
1696     defined $self->{cond}
1697     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1698   ) {
1699     %new = %{$self->{attrs}{related_objects}};
1700   } else {
1701     $self->throw_exception(
1702       "Can't abstract implicit construct, condition not a hash"
1703     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1704
1705     my $collapsed_cond = (
1706       $self->{cond}
1707         ? $self->_collapse_cond($self->{cond})
1708         : {}
1709     );
1710
1711     # precendence must be given to passed values over values inherited from
1712     # the cond, so the order here is important.
1713     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1714     while( my($col,$value) = each %implied ){
1715       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1716         $new{$col} = $value->{'='};
1717         next;
1718       }
1719       $new{$col} = $value if $self->_is_deterministic_value($value);
1720     }
1721   }
1722
1723   %new = (
1724     %new,
1725     %{ $self->_remove_alias($values, $alias) },
1726     -source_handle => $self->_source_handle,
1727     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1728   );
1729
1730   return $self->result_class->new(\%new);
1731 }
1732
1733 # _is_deterministic_value
1734 #
1735 # Make an effor to strip non-deterministic values from the condition,
1736 # to make sure new_result chokes less
1737
1738 sub _is_deterministic_value {
1739   my $self = shift;
1740   my $value = shift;
1741   my $ref_type = ref $value;
1742   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1743   return 1 if Scalar::Util::blessed($value);
1744   return 0;
1745 }
1746
1747 # _collapse_cond
1748 #
1749 # Recursively collapse the condition.
1750
1751 sub _collapse_cond {
1752   my ($self, $cond, $collapsed) = @_;
1753
1754   $collapsed ||= {};
1755
1756   if (ref $cond eq 'ARRAY') {
1757     foreach my $subcond (@$cond) {
1758       next unless ref $subcond;  # -or
1759 #      warn "ARRAY: " . Dumper $subcond;
1760       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1761     }
1762   }
1763   elsif (ref $cond eq 'HASH') {
1764     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1765       foreach my $subcond (@{$cond->{-and}}) {
1766 #        warn "HASH: " . Dumper $subcond;
1767         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1768       }
1769     }
1770     else {
1771 #      warn "LEAF: " . Dumper $cond;
1772       foreach my $col (keys %$cond) {
1773         my $value = $cond->{$col};
1774         $collapsed->{$col} = $value;
1775       }
1776     }
1777   }
1778
1779   return $collapsed;
1780 }
1781
1782 # _remove_alias
1783 #
1784 # Remove the specified alias from the specified query hash. A copy is made so
1785 # the original query is not modified.
1786
1787 sub _remove_alias {
1788   my ($self, $query, $alias) = @_;
1789
1790   my %orig = %{ $query || {} };
1791   my %unaliased;
1792
1793   foreach my $key (keys %orig) {
1794     if ($key !~ /\./) {
1795       $unaliased{$key} = $orig{$key};
1796       next;
1797     }
1798     $unaliased{$1} = $orig{$key}
1799       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1800   }
1801
1802   return \%unaliased;
1803 }
1804
1805 =head2 as_query
1806
1807 =over 4
1808
1809 =item Arguments: none
1810
1811 =item Return Value: \[ $sql, @bind ]
1812
1813 =back
1814
1815 Returns the SQL query and bind vars associated with the invocant.
1816
1817 This is generally used as the RHS for a subquery.
1818
1819 =cut
1820
1821 sub as_query { return shift->cursor->as_query(@_) }
1822
1823 =head2 find_or_new
1824
1825 =over 4
1826
1827 =item Arguments: \%vals, \%attrs?
1828
1829 =item Return Value: $rowobject
1830
1831 =back
1832
1833   my $artist = $schema->resultset('Artist')->find_or_new(
1834     { artist => 'fred' }, { key => 'artists' });
1835
1836   $cd->cd_to_producer->find_or_new({ producer => $producer },
1837                                    { key => 'primary });
1838
1839 Find an existing record from this resultset, based on its primary
1840 key, or a unique constraint. If none exists, instantiate a new result
1841 object and return it. The object will not be saved into your storage
1842 until you call L<DBIx::Class::Row/insert> on it.
1843
1844 You most likely want this method when looking for existing rows using
1845 a unique constraint that is not the primary key, or looking for
1846 related rows.
1847
1848 If you want objects to be saved immediately, use L</find_or_create> instead.
1849
1850 B<Note>: C<find_or_new> is probably not what you want when creating a
1851 new row in a table that uses primary keys supplied by the
1852 database. Passing in a primary key column with a value of I<undef>
1853 will cause L</find> to attempt to search for a row with a value of
1854 I<NULL>.
1855
1856 =cut
1857
1858 sub find_or_new {
1859   my $self     = shift;
1860   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1861   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1862   my $exists   = $self->find($hash, $attrs);
1863   return defined $exists ? $exists : $self->new_result($hash);
1864 }
1865
1866 =head2 create
1867
1868 =over 4
1869
1870 =item Arguments: \%vals
1871
1872 =item Return Value: a L<DBIx::Class::Row> $object
1873
1874 =back
1875
1876 Attempt to create a single new row or a row with multiple related rows
1877 in the table represented by the resultset (and related tables). This
1878 will not check for duplicate rows before inserting, use
1879 L</find_or_create> to do that.
1880
1881 To create one row for this resultset, pass a hashref of key/value
1882 pairs representing the columns of the table and the values you wish to
1883 store. If the appropriate relationships are set up, foreign key fields
1884 can also be passed an object representing the foreign row, and the
1885 value will be set to its primary key.
1886
1887 To create related objects, pass a hashref for the value if the related
1888 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1889 and use the name of the relationship as the key. (NOT the name of the field,
1890 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1891 of hashrefs containing the data for each of the rows to create in the foreign
1892 tables, again using the relationship name as the key.
1893
1894 Instead of hashrefs of plain related data (key/value pairs), you may
1895 also pass new or inserted objects. New objects (not inserted yet, see
1896 L</new>), will be inserted into their appropriate tables.
1897
1898 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1899
1900 Example of creating a new row.
1901
1902   $person_rs->create({
1903     name=>"Some Person",
1904     email=>"somebody@someplace.com"
1905   });
1906
1907 Example of creating a new row and also creating rows in a related C<has_many>
1908 or C<has_one> resultset.  Note Arrayref.
1909
1910   $artist_rs->create(
1911      { artistid => 4, name => 'Manufactured Crap', cds => [
1912         { title => 'My First CD', year => 2006 },
1913         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1914       ],
1915      },
1916   );
1917
1918 Example of creating a new row and also creating a row in a related
1919 C<belongs_to>resultset. Note Hashref.
1920
1921   $cd_rs->create({
1922     title=>"Music for Silly Walks",
1923     year=>2000,
1924     artist => {
1925       name=>"Silly Musician",
1926     }
1927   });
1928
1929 =cut
1930
1931 sub create {
1932   my ($self, $attrs) = @_;
1933   $self->throw_exception( "create needs a hashref" )
1934     unless ref $attrs eq 'HASH';
1935   return $self->new_result($attrs)->insert;
1936 }
1937
1938 =head2 find_or_create
1939
1940 =over 4
1941
1942 =item Arguments: \%vals, \%attrs?
1943
1944 =item Return Value: $rowobject
1945
1946 =back
1947
1948   $cd->cd_to_producer->find_or_create({ producer => $producer },
1949                                       { key => 'primary });
1950
1951 Tries to find a record based on its primary key or unique constraints; if none
1952 is found, creates one and returns that instead.
1953
1954   my $cd = $schema->resultset('CD')->find_or_create({
1955     cdid   => 5,
1956     artist => 'Massive Attack',
1957     title  => 'Mezzanine',
1958     year   => 2005,
1959   });
1960
1961 Also takes an optional C<key> attribute, to search by a specific key or unique
1962 constraint. For example:
1963
1964   my $cd = $schema->resultset('CD')->find_or_create(
1965     {
1966       artist => 'Massive Attack',
1967       title  => 'Mezzanine',
1968     },
1969     { key => 'cd_artist_title' }
1970   );
1971
1972 B<Note>: Because find_or_create() reads from the database and then
1973 possibly inserts based on the result, this method is subject to a race
1974 condition. Another process could create a record in the table after
1975 the find has completed and before the create has started. To avoid
1976 this problem, use find_or_create() inside a transaction.
1977
1978 B<Note>: C<find_or_create> is probably not what you want when creating
1979 a new row in a table that uses primary keys supplied by the
1980 database. Passing in a primary key column with a value of I<undef>
1981 will cause L</find> to attempt to search for a row with a value of
1982 I<NULL>.
1983
1984 See also L</find> and L</update_or_create>. For information on how to declare
1985 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1986
1987 =cut
1988
1989 sub find_or_create {
1990   my $self     = shift;
1991   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1992   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1993   my $exists   = $self->find($hash, $attrs);
1994   return defined $exists ? $exists : $self->create($hash);
1995 }
1996
1997 =head2 update_or_create
1998
1999 =over 4
2000
2001 =item Arguments: \%col_values, { key => $unique_constraint }?
2002
2003 =item Return Value: $rowobject
2004
2005 =back
2006
2007   $resultset->update_or_create({ col => $val, ... });
2008
2009 First, searches for an existing row matching one of the unique constraints
2010 (including the primary key) on the source of this resultset. If a row is
2011 found, updates it with the other given column values. Otherwise, creates a new
2012 row.
2013
2014 Takes an optional C<key> attribute to search on a specific unique constraint.
2015 For example:
2016
2017   # In your application
2018   my $cd = $schema->resultset('CD')->update_or_create(
2019     {
2020       artist => 'Massive Attack',
2021       title  => 'Mezzanine',
2022       year   => 1998,
2023     },
2024     { key => 'cd_artist_title' }
2025   );
2026
2027   $cd->cd_to_producer->update_or_create({
2028     producer => $producer,
2029     name => 'harry',
2030   }, {
2031     key => 'primary,
2032   });
2033
2034
2035 If no C<key> is specified, it searches on all unique constraints defined on the
2036 source, including the primary key.
2037
2038 If the C<key> is specified as C<primary>, it searches only on the primary key.
2039
2040 See also L</find> and L</find_or_create>. For information on how to declare
2041 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2042
2043 B<Note>: C<update_or_create> is probably not what you want when
2044 looking for a row in a table that uses primary keys supplied by the
2045 database, unless you actually have a key value. Passing in a primary
2046 key column with a value of I<undef> will cause L</find> to attempt to
2047 search for a row with a value of I<NULL>.
2048
2049 =cut
2050
2051 sub update_or_create {
2052   my $self = shift;
2053   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2054   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2055
2056   my $row = $self->find($cond, $attrs);
2057   if (defined $row) {
2058     $row->update($cond);
2059     return $row;
2060   }
2061
2062   return $self->create($cond);
2063 }
2064
2065 =head2 get_cache
2066
2067 =over 4
2068
2069 =item Arguments: none
2070
2071 =item Return Value: \@cache_objects?
2072
2073 =back
2074
2075 Gets the contents of the cache for the resultset, if the cache is set.
2076
2077 The cache is populated either by using the L</prefetch> attribute to
2078 L</search> or by calling L</set_cache>.
2079
2080 =cut
2081
2082 sub get_cache {
2083   shift->{all_cache};
2084 }
2085
2086 =head2 set_cache
2087
2088 =over 4
2089
2090 =item Arguments: \@cache_objects
2091
2092 =item Return Value: \@cache_objects
2093
2094 =back
2095
2096 Sets the contents of the cache for the resultset. Expects an arrayref
2097 of objects of the same class as those produced by the resultset. Note that
2098 if the cache is set the resultset will return the cached objects rather
2099 than re-querying the database even if the cache attr is not set.
2100
2101 The contents of the cache can also be populated by using the
2102 L</prefetch> attribute to L</search>.
2103
2104 =cut
2105
2106 sub set_cache {
2107   my ( $self, $data ) = @_;
2108   $self->throw_exception("set_cache requires an arrayref")
2109       if defined($data) && (ref $data ne 'ARRAY');
2110   $self->{all_cache} = $data;
2111 }
2112
2113 =head2 clear_cache
2114
2115 =over 4
2116
2117 =item Arguments: none
2118
2119 =item Return Value: []
2120
2121 =back
2122
2123 Clears the cache for the resultset.
2124
2125 =cut
2126
2127 sub clear_cache {
2128   shift->set_cache(undef);
2129 }
2130
2131 =head2 related_resultset
2132
2133 =over 4
2134
2135 =item Arguments: $relationship_name
2136
2137 =item Return Value: $resultset
2138
2139 =back
2140
2141 Returns a related resultset for the supplied relationship name.
2142
2143   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2144
2145 =cut
2146
2147 sub related_resultset {
2148   my ($self, $rel) = @_;
2149
2150   $self->{related_resultsets} ||= {};
2151   return $self->{related_resultsets}{$rel} ||= do {
2152     my $rel_obj = $self->result_source->relationship_info($rel);
2153
2154     $self->throw_exception(
2155       "search_related: result source '" . $self->result_source->source_name .
2156         "' has no such relationship $rel")
2157       unless $rel_obj;
2158
2159     my ($from,$seen) = $self->_resolve_from($rel);
2160
2161     my $join_count = $seen->{$rel};
2162     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2163
2164     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2165     my %attrs = %{$self->{attrs}||{}};
2166     delete @attrs{qw(result_class alias)};
2167
2168     my $new_cache;
2169
2170     if (my $cache = $self->get_cache) {
2171       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2172         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2173                         @$cache ];
2174       }
2175     }
2176
2177     my $rel_source = $self->result_source->related_source($rel);
2178
2179     my $new = do {
2180
2181       # The reason we do this now instead of passing the alias to the
2182       # search_rs below is that if you wrap/overload resultset on the
2183       # source you need to know what alias it's -going- to have for things
2184       # to work sanely (e.g. RestrictWithObject wants to be able to add
2185       # extra query restrictions, and these may need to be $alias.)
2186
2187       my $attrs = $rel_source->resultset_attributes;
2188       local $attrs->{alias} = $alias;
2189
2190       $rel_source->resultset
2191                  ->search_rs(
2192                      undef, {
2193                        %attrs,
2194                        join => undef,
2195                        prefetch => undef,
2196                        select => undef,
2197                        as => undef,
2198                        where => $self->{cond},
2199                        seen_join => $seen,
2200                        from => $from,
2201                    });
2202     };
2203     $new->set_cache($new_cache) if $new_cache;
2204     $new;
2205   };
2206 }
2207
2208 =head2 current_source_alias
2209
2210 =over 4
2211
2212 =item Arguments: none
2213
2214 =item Return Value: $source_alias
2215
2216 =back
2217
2218 Returns the current table alias for the result source this resultset is built
2219 on, that will be used in the SQL query. Usually it is C<me>.
2220
2221 Currently the source alias that refers to the result set returned by a
2222 L</search>/L</find> family method depends on how you got to the resultset: it's
2223 C<me> by default, but eg. L</search_related> aliases it to the related result
2224 source name (and keeps C<me> referring to the original result set). The long
2225 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2226 (and make this method unnecessary).
2227
2228 Thus it's currently necessary to use this method in predefined queries (see
2229 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2230 source alias of the current result set:
2231
2232   # in a result set class
2233   sub modified_by {
2234     my ($self, $user) = @_;
2235
2236     my $me = $self->current_source_alias;
2237
2238     return $self->search(
2239       "$me.modified" => $user->id,
2240     );
2241   }
2242
2243 =cut
2244
2245 sub current_source_alias {
2246   my ($self) = @_;
2247
2248   return ($self->{attrs} || {})->{alias} || 'me';
2249 }
2250
2251 sub _resolve_from {
2252   my ($self, $extra_join) = @_;
2253   my $source = $self->result_source;
2254   my $attrs = $self->{attrs};
2255
2256   my $from = $attrs->{from}
2257     || [ { $attrs->{alias} => $source->from } ];
2258
2259   my $seen = { %{$attrs->{seen_join}||{}} };
2260
2261   my $join = ($attrs->{join}
2262                ? [ $attrs->{join}, $extra_join ]
2263                : $extra_join);
2264
2265   # we need to take the prefetch the attrs into account before we
2266   # ->resolve_join as otherwise they get lost - captainL
2267   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2268
2269   $from = [
2270     @$from,
2271     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2272   ];
2273
2274   return ($from,$seen);
2275 }
2276
2277 sub _resolved_attrs {
2278   my $self = shift;
2279   return $self->{_attrs} if $self->{_attrs};
2280
2281   my $attrs = { %{$self->{attrs}||{}} };
2282   my $source = $self->result_source;
2283   my $alias = $attrs->{alias};
2284
2285   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2286   if ($attrs->{columns}) {
2287     delete $attrs->{as};
2288   } elsif (!$attrs->{select}) {
2289     $attrs->{columns} = [ $source->columns ];
2290   }
2291
2292   $attrs->{select} =
2293     ($attrs->{select}
2294       ? (ref $attrs->{select} eq 'ARRAY'
2295           ? [ @{$attrs->{select}} ]
2296           : [ $attrs->{select} ])
2297       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
2298     );
2299   $attrs->{as} =
2300     ($attrs->{as}
2301       ? (ref $attrs->{as} eq 'ARRAY'
2302           ? [ @{$attrs->{as}} ]
2303           : [ $attrs->{as} ])
2304       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
2305     );
2306
2307   my $adds;
2308   if ($adds = delete $attrs->{include_columns}) {
2309     $adds = [$adds] unless ref $adds eq 'ARRAY';
2310     push(@{$attrs->{select}}, @$adds);
2311     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
2312   }
2313   if ($adds = delete $attrs->{'+select'}) {
2314     $adds = [$adds] unless ref $adds eq 'ARRAY';
2315     push(@{$attrs->{select}},
2316            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
2317   }
2318   if (my $adds = delete $attrs->{'+as'}) {
2319     $adds = [$adds] unless ref $adds eq 'ARRAY';
2320     push(@{$attrs->{as}}, @$adds);
2321   }
2322
2323   $attrs->{from} ||= [ { 'me' => $source->from } ];
2324
2325   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
2326     my $join = delete $attrs->{join} || {};
2327
2328     if (defined $attrs->{prefetch}) {
2329       $join = $self->_merge_attr(
2330         $join, $attrs->{prefetch}
2331       );
2332
2333     }
2334
2335     $attrs->{from} =   # have to copy here to avoid corrupting the original
2336       [
2337         @{$attrs->{from}},
2338         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
2339       ];
2340
2341   }
2342
2343   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
2344   if ($attrs->{order_by}) {
2345     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
2346                            ? [ @{$attrs->{order_by}} ]
2347                            : [ $attrs->{order_by} ]);
2348   } else {
2349     $attrs->{order_by} = [];
2350   }
2351
2352   my $collapse = $attrs->{collapse} || {};
2353   if (my $prefetch = delete $attrs->{prefetch}) {
2354     $prefetch = $self->_merge_attr({}, $prefetch);
2355     my @pre_order;
2356     my $seen = { %{ $attrs->{seen_join} || {} } };
2357     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
2358       # bring joins back to level of current class
2359       my @prefetch = $source->resolve_prefetch(
2360         $p, $alias, $seen, \@pre_order, $collapse
2361       );
2362       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
2363       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
2364     }
2365     push(@{$attrs->{order_by}}, @pre_order);
2366   }
2367   $attrs->{collapse} = $collapse;
2368
2369   if ($attrs->{page}) {
2370     $attrs->{offset} ||= 0;
2371     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
2372   }
2373
2374   return $self->{_attrs} = $attrs;
2375 }
2376
2377 sub _rollout_attr {
2378   my ($self, $attr) = @_;
2379
2380   if (ref $attr eq 'HASH') {
2381     return $self->_rollout_hash($attr);
2382   } elsif (ref $attr eq 'ARRAY') {
2383     return $self->_rollout_array($attr);
2384   } else {
2385     return [$attr];
2386   }
2387 }
2388
2389 sub _rollout_array {
2390   my ($self, $attr) = @_;
2391
2392   my @rolled_array;
2393   foreach my $element (@{$attr}) {
2394     if (ref $element eq 'HASH') {
2395       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2396     } elsif (ref $element eq 'ARRAY') {
2397       #  XXX - should probably recurse here
2398       push( @rolled_array, @{$self->_rollout_array($element)} );
2399     } else {
2400       push( @rolled_array, $element );
2401     }
2402   }
2403   return \@rolled_array;
2404 }
2405
2406 sub _rollout_hash {
2407   my ($self, $attr) = @_;
2408
2409   my @rolled_array;
2410   foreach my $key (keys %{$attr}) {
2411     push( @rolled_array, { $key => $attr->{$key} } );
2412   }
2413   return \@rolled_array;
2414 }
2415
2416 sub _calculate_score {
2417   my ($self, $a, $b) = @_;
2418
2419   if (ref $b eq 'HASH') {
2420     my ($b_key) = keys %{$b};
2421     if (ref $a eq 'HASH') {
2422       my ($a_key) = keys %{$a};
2423       if ($a_key eq $b_key) {
2424         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2425       } else {
2426         return 0;
2427       }
2428     } else {
2429       return ($a eq $b_key) ? 1 : 0;
2430     }
2431   } else {
2432     if (ref $a eq 'HASH') {
2433       my ($a_key) = keys %{$a};
2434       return ($b eq $a_key) ? 1 : 0;
2435     } else {
2436       return ($b eq $a) ? 1 : 0;
2437     }
2438   }
2439 }
2440
2441 sub _merge_attr {
2442   my ($self, $orig, $import) = @_;
2443
2444   return $import unless defined($orig);
2445   return $orig unless defined($import);
2446
2447   $orig = $self->_rollout_attr($orig);
2448   $import = $self->_rollout_attr($import);
2449
2450   my $seen_keys;
2451   foreach my $import_element ( @{$import} ) {
2452     # find best candidate from $orig to merge $b_element into
2453     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2454     foreach my $orig_element ( @{$orig} ) {
2455       my $score = $self->_calculate_score( $orig_element, $import_element );
2456       if ($score > $best_candidate->{score}) {
2457         $best_candidate->{position} = $position;
2458         $best_candidate->{score} = $score;
2459       }
2460       $position++;
2461     }
2462     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2463
2464     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2465       push( @{$orig}, $import_element );
2466     } else {
2467       my $orig_best = $orig->[$best_candidate->{position}];
2468       # merge orig_best and b_element together and replace original with merged
2469       if (ref $orig_best ne 'HASH') {
2470         $orig->[$best_candidate->{position}] = $import_element;
2471       } elsif (ref $import_element eq 'HASH') {
2472         my ($key) = keys %{$orig_best};
2473         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2474       }
2475     }
2476     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2477   }
2478
2479   return $orig;
2480 }
2481
2482 sub result_source {
2483     my $self = shift;
2484
2485     if (@_) {
2486         $self->_source_handle($_[0]->handle);
2487     } else {
2488         $self->_source_handle->resolve;
2489     }
2490 }
2491
2492 =head2 throw_exception
2493
2494 See L<DBIx::Class::Schema/throw_exception> for details.
2495
2496 =cut
2497
2498 sub throw_exception {
2499   my $self=shift;
2500   if (ref $self && $self->_source_handle->schema) {
2501     $self->_source_handle->schema->throw_exception(@_)
2502   } else {
2503     croak(@_);
2504   }
2505
2506 }
2507
2508 # XXX: FIXME: Attributes docs need clearing up
2509
2510 =head1 ATTRIBUTES
2511
2512 Attributes are used to refine a ResultSet in various ways when
2513 searching for data. They can be passed to any method which takes an
2514 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2515 L</count>.
2516
2517 These are in no particular order:
2518
2519 =head2 order_by
2520
2521 =over 4
2522
2523 =item Value: ($order_by | \@order_by)
2524
2525 =back
2526
2527 Which column(s) to order the results by. This is currently passed
2528 through directly to SQL, so you can give e.g. C<year DESC> for a
2529 descending order on the column `year'.
2530
2531 Please note that if you have C<quote_char> enabled (see
2532 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
2533 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
2534 so you will need to manually quote things as appropriate.)
2535
2536 If your L<SQL::Abstract> version supports it (>=1.50), you can also use
2537 C<{-desc => 'year'}>, which takes care of the quoting for you. This is the
2538 recommended syntax.
2539
2540 =head2 columns
2541
2542 =over 4
2543
2544 =item Value: \@columns
2545
2546 =back
2547
2548 Shortcut to request a particular set of columns to be retrieved.  Adds
2549 C<me.> onto the start of any column without a C<.> in it and sets C<select>
2550 from that, then auto-populates C<as> from C<select> as normal. (You may also
2551 use the C<cols> attribute, as in earlier versions of DBIC.)
2552
2553 =head2 include_columns
2554
2555 =over 4
2556
2557 =item Value: \@columns
2558
2559 =back
2560
2561 Shortcut to include additional columns in the returned results - for example
2562
2563   $schema->resultset('CD')->search(undef, {
2564     include_columns => ['artist.name'],
2565     join => ['artist']
2566   });
2567
2568 would return all CDs and include a 'name' column to the information
2569 passed to object inflation. Note that the 'artist' is the name of the
2570 column (or relationship) accessor, and 'name' is the name of the column
2571 accessor in the related table.
2572
2573 =head2 select
2574
2575 =over 4
2576
2577 =item Value: \@select_columns
2578
2579 =back
2580
2581 Indicates which columns should be selected from the storage. You can use
2582 column names, or in the case of RDBMS back ends, function or stored procedure
2583 names:
2584
2585   $rs = $schema->resultset('Employee')->search(undef, {
2586     select => [
2587       'name',
2588       { count => 'employeeid' },
2589       { sum => 'salary' }
2590     ]
2591   });
2592
2593 When you use function/stored procedure names and do not supply an C<as>
2594 attribute, the column names returned are storage-dependent. E.g. MySQL would
2595 return a column named C<count(employeeid)> in the above example.
2596
2597 =head2 +select
2598
2599 =over 4
2600
2601 Indicates additional columns to be selected from storage.  Works the same as
2602 L</select> but adds columns to the selection.
2603
2604 =back
2605
2606 =head2 +as
2607
2608 =over 4
2609
2610 Indicates additional column names for those added via L</+select>. See L</as>.
2611
2612 =back
2613
2614 =head2 as
2615
2616 =over 4
2617
2618 =item Value: \@inflation_names
2619
2620 =back
2621
2622 Indicates column names for object inflation. That is, C<as>
2623 indicates the name that the column can be accessed as via the
2624 C<get_column> method (or via the object accessor, B<if one already
2625 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2626
2627 The C<as> attribute is used in conjunction with C<select>,
2628 usually when C<select> contains one or more function or stored
2629 procedure names:
2630
2631   $rs = $schema->resultset('Employee')->search(undef, {
2632     select => [
2633       'name',
2634       { count => 'employeeid' }
2635     ],
2636     as => ['name', 'employee_count'],
2637   });
2638
2639   my $employee = $rs->first(); # get the first Employee
2640
2641 If the object against which the search is performed already has an accessor
2642 matching a column name specified in C<as>, the value can be retrieved using
2643 the accessor as normal:
2644
2645   my $name = $employee->name();
2646
2647 If on the other hand an accessor does not exist in the object, you need to
2648 use C<get_column> instead:
2649
2650   my $employee_count = $employee->get_column('employee_count');
2651
2652 You can create your own accessors if required - see
2653 L<DBIx::Class::Manual::Cookbook> for details.
2654
2655 Please note: This will NOT insert an C<AS employee_count> into the SQL
2656 statement produced, it is used for internal access only. Thus
2657 attempting to use the accessor in an C<order_by> clause or similar
2658 will fail miserably.
2659
2660 To get around this limitation, you can supply literal SQL to your
2661 C<select> attibute that contains the C<AS alias> text, eg:
2662
2663   select => [\'myfield AS alias']
2664
2665 =head2 join
2666
2667 =over 4
2668
2669 =item Value: ($rel_name | \@rel_names | \%rel_names)
2670
2671 =back
2672
2673 Contains a list of relationships that should be joined for this query.  For
2674 example:
2675
2676   # Get CDs by Nine Inch Nails
2677   my $rs = $schema->resultset('CD')->search(
2678     { 'artist.name' => 'Nine Inch Nails' },
2679     { join => 'artist' }
2680   );
2681
2682 Can also contain a hash reference to refer to the other relation's relations.
2683 For example:
2684
2685   package MyApp::Schema::Track;
2686   use base qw/DBIx::Class/;
2687   __PACKAGE__->table('track');
2688   __PACKAGE__->add_columns(qw/trackid cd position title/);
2689   __PACKAGE__->set_primary_key('trackid');
2690   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2691   1;
2692
2693   # In your application
2694   my $rs = $schema->resultset('Artist')->search(
2695     { 'track.title' => 'Teardrop' },
2696     {
2697       join     => { cd => 'track' },
2698       order_by => 'artist.name',
2699     }
2700   );
2701
2702 You need to use the relationship (not the table) name in  conditions,
2703 because they are aliased as such. The current table is aliased as "me", so
2704 you need to use me.column_name in order to avoid ambiguity. For example:
2705
2706   # Get CDs from 1984 with a 'Foo' track
2707   my $rs = $schema->resultset('CD')->search(
2708     {
2709       'me.year' => 1984,
2710       'tracks.name' => 'Foo'
2711     },
2712     { join => 'tracks' }
2713   );
2714
2715 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2716 similarly for a third time). For e.g.
2717
2718   my $rs = $schema->resultset('Artist')->search({
2719     'cds.title'   => 'Down to Earth',
2720     'cds_2.title' => 'Popular',
2721   }, {
2722     join => [ qw/cds cds/ ],
2723   });
2724
2725 will return a set of all artists that have both a cd with title 'Down
2726 to Earth' and a cd with title 'Popular'.
2727
2728 If you want to fetch related objects from other tables as well, see C<prefetch>
2729 below.
2730
2731 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2732
2733 =head2 prefetch
2734
2735 =over 4
2736
2737 =item Value: ($rel_name | \@rel_names | \%rel_names)
2738
2739 =back
2740
2741 Contains one or more relationships that should be fetched along with
2742 the main query (when they are accessed afterwards the data will
2743 already be available, without extra queries to the database).  This is
2744 useful for when you know you will need the related objects, because it
2745 saves at least one query:
2746
2747   my $rs = $schema->resultset('Tag')->search(
2748     undef,
2749     {
2750       prefetch => {
2751         cd => 'artist'
2752       }
2753     }
2754   );
2755
2756 The initial search results in SQL like the following:
2757
2758   SELECT tag.*, cd.*, artist.* FROM tag
2759   JOIN cd ON tag.cd = cd.cdid
2760   JOIN artist ON cd.artist = artist.artistid
2761
2762 L<DBIx::Class> has no need to go back to the database when we access the
2763 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2764 case.
2765
2766 Simple prefetches will be joined automatically, so there is no need
2767 for a C<join> attribute in the above search.
2768
2769 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2770 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2771 with an accessor type of 'single' or 'filter'). A more complex example that
2772 prefetches an artists cds, the tracks on those cds, and the tags associted
2773 with that artist is given below (assuming many-to-many from artists to tags):
2774
2775  my $rs = $schema->resultset('Artist')->search(
2776    undef,
2777    {
2778      prefetch => [
2779        { cds => 'tracks' },
2780        { artist_tags => 'tags' }
2781      ]
2782    }
2783  );
2784
2785
2786 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2787 attributes will be ignored.
2788
2789 =head2 page
2790
2791 =over 4
2792
2793 =item Value: $page
2794
2795 =back
2796
2797 Makes the resultset paged and specifies the page to retrieve. Effectively
2798 identical to creating a non-pages resultset and then calling ->page($page)
2799 on it.
2800
2801 If L<rows> attribute is not specified it defualts to 10 rows per page.
2802
2803 =head2 rows
2804
2805 =over 4
2806
2807 =item Value: $rows
2808
2809 =back
2810
2811 Specifes the maximum number of rows for direct retrieval or the number of
2812 rows per page if the page attribute or method is used.
2813
2814 =head2 offset
2815
2816 =over 4
2817
2818 =item Value: $offset
2819
2820 =back
2821
2822 Specifies the (zero-based) row number for the  first row to be returned, or the
2823 of the first row of the first page if paging is used.
2824
2825 =head2 group_by
2826
2827 =over 4
2828
2829 =item Value: \@columns
2830
2831 =back
2832
2833 A arrayref of columns to group by. Can include columns of joined tables.
2834
2835   group_by => [qw/ column1 column2 ... /]
2836
2837 =head2 having
2838
2839 =over 4
2840
2841 =item Value: $condition
2842
2843 =back
2844
2845 HAVING is a select statement attribute that is applied between GROUP BY and
2846 ORDER BY. It is applied to the after the grouping calculations have been
2847 done.
2848
2849   having => { 'count(employee)' => { '>=', 100 } }
2850
2851 =head2 distinct
2852
2853 =over 4
2854
2855 =item Value: (0 | 1)
2856
2857 =back
2858
2859 Set to 1 to group by all columns.
2860
2861 =head2 where
2862
2863 =over 4
2864
2865 Adds to the WHERE clause.
2866
2867   # only return rows WHERE deleted IS NULL for all searches
2868   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2869
2870 Can be overridden by passing C<{ where => undef }> as an attribute
2871 to a resulset.
2872
2873 =back
2874
2875 =head2 cache
2876
2877 Set to 1 to cache search results. This prevents extra SQL queries if you
2878 revisit rows in your ResultSet:
2879
2880   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2881
2882   while( my $artist = $resultset->next ) {
2883     ... do stuff ...
2884   }
2885
2886   $rs->first; # without cache, this would issue a query
2887
2888 By default, searches are not cached.
2889
2890 For more examples of using these attributes, see
2891 L<DBIx::Class::Manual::Cookbook>.
2892
2893 =head2 from
2894
2895 =over 4
2896
2897 =item Value: \@from_clause
2898
2899 =back
2900
2901 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2902 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2903 clauses.
2904
2905 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2906
2907 C<join> will usually do what you need and it is strongly recommended that you
2908 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2909 And we really do mean "cannot", not just tried and failed. Attempting to use
2910 this because you're having problems with C<join> is like trying to use x86
2911 ASM because you've got a syntax error in your C. Trust us on this.
2912
2913 Now, if you're still really, really sure you need to use this (and if you're
2914 not 100% sure, ask the mailing list first), here's an explanation of how this
2915 works.
2916
2917 The syntax is as follows -
2918
2919   [
2920     { <alias1> => <table1> },
2921     [
2922       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2923       [], # nested JOIN (optional)
2924       { <table1.column1> => <table2.column2>, ... (more conditions) },
2925     ],
2926     # More of the above [ ] may follow for additional joins
2927   ]
2928
2929   <table1> <alias1>
2930   JOIN
2931     <table2> <alias2>
2932     [JOIN ...]
2933   ON <table1.column1> = <table2.column2>
2934   <more joins may follow>
2935
2936 An easy way to follow the examples below is to remember the following:
2937
2938     Anything inside "[]" is a JOIN
2939     Anything inside "{}" is a condition for the enclosing JOIN
2940
2941 The following examples utilize a "person" table in a family tree application.
2942 In order to express parent->child relationships, this table is self-joined:
2943
2944     # Person->belongs_to('father' => 'Person');
2945     # Person->belongs_to('mother' => 'Person');
2946
2947 C<from> can be used to nest joins. Here we return all children with a father,
2948 then search against all mothers of those children:
2949
2950   $rs = $schema->resultset('Person')->search(
2951       undef,
2952       {
2953           alias => 'mother', # alias columns in accordance with "from"
2954           from => [
2955               { mother => 'person' },
2956               [
2957                   [
2958                       { child => 'person' },
2959                       [
2960                           { father => 'person' },
2961                           { 'father.person_id' => 'child.father_id' }
2962                       ]
2963                   ],
2964                   { 'mother.person_id' => 'child.mother_id' }
2965               ],
2966           ]
2967       },
2968   );
2969
2970   # Equivalent SQL:
2971   # SELECT mother.* FROM person mother
2972   # JOIN (
2973   #   person child
2974   #   JOIN person father
2975   #   ON ( father.person_id = child.father_id )
2976   # )
2977   # ON ( mother.person_id = child.mother_id )
2978
2979 The type of any join can be controlled manually. To search against only people
2980 with a father in the person table, we could explicitly use C<INNER JOIN>:
2981
2982     $rs = $schema->resultset('Person')->search(
2983         undef,
2984         {
2985             alias => 'child', # alias columns in accordance with "from"
2986             from => [
2987                 { child => 'person' },
2988                 [
2989                     { father => 'person', -join_type => 'inner' },
2990                     { 'father.id' => 'child.father_id' }
2991                 ],
2992             ]
2993         },
2994     );
2995
2996     # Equivalent SQL:
2997     # SELECT child.* FROM person child
2998     # INNER JOIN person father ON child.father_id = father.id
2999
3000 If you need to express really complex joins or you need a subselect, you
3001 can supply literal SQL to C<from> via a scalar reference. In this case
3002 the contents of the scalar will replace the table name asscoiated with the
3003 resultsource.
3004
3005 WARNING: This technique might very well not work as expected on chained
3006 searches - you have been warned.
3007
3008     # Assuming the Event resultsource is defined as:
3009
3010         MySchema::Event->add_columns (
3011             sequence => {
3012                 data_type => 'INT',
3013                 is_auto_increment => 1,
3014             },
3015             location => {
3016                 data_type => 'INT',
3017             },
3018             type => {
3019                 data_type => 'INT',
3020             },
3021         );
3022         MySchema::Event->set_primary_key ('sequence');
3023
3024     # This will get back the latest event for every location. The column
3025     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3026     # combo to limit the resultset
3027
3028     $rs = $schema->resultset('Event');
3029     $table = $rs->result_source->name;
3030     $latest = $rs->search (
3031         undef,
3032         { from => \ "
3033             (SELECT e1.* FROM $table e1
3034                 JOIN $table e2
3035                     ON e1.location = e2.location
3036                     AND e1.sequence < e2.sequence
3037                 WHERE e2.sequence is NULL
3038             ) me",
3039         },
3040     );
3041
3042     # Equivalent SQL (with the DBIC chunks added):
3043
3044     SELECT me.sequence, me.location, me.type FROM
3045        (SELECT e1.* FROM events e1
3046            JOIN events e2
3047                ON e1.location = e2.location
3048                AND e1.sequence < e2.sequence
3049            WHERE e2.sequence is NULL
3050        ) me;
3051
3052 =head2 for
3053
3054 =over 4
3055
3056 =item Value: ( 'update' | 'shared' )
3057
3058 =back
3059
3060 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3061 ... FOR SHARED.
3062
3063 =cut
3064
3065 1;