lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157   my $count = $self->_count;
1158   return 0 unless $count;
1159
1160   # need to take offset from resolved attrs
1161
1162   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1163   $count = $self->{attrs}{rows} if
1164     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1165   $count = 0 if ($count < 0);
1166   return $count;
1167 }
1168
1169 sub _count { # Separated out so pager can get the full count
1170   my $self = shift;
1171   my $attrs = { %{$self->_resolved_attrs} };
1172
1173   if (my $group_by = $attrs->{group_by}) {
1174     delete $attrs->{order_by};
1175
1176     $attrs->{select} = $group_by;
1177     $attrs->{from} = [ { 'mesub' => (ref $self)->new($self->result_source, $attrs)->cursor->as_query } ];
1178     delete $attrs->{where};
1179   }
1180
1181   $attrs->{select} = { count => '*' };
1182   $attrs->{as} = [qw/count/];
1183
1184   # offset, order by, group by, where and page are not needed to count. record_filter is cdbi
1185   delete $attrs->{$_} for qw/rows offset order_by group_by page pager record_filter/;
1186
1187   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1188   my ($count) = $tmp_rs->cursor->next;
1189   return $count;
1190 }
1191
1192 sub _bool {
1193   return 1;
1194 }
1195
1196 =head2 count_literal
1197
1198 =over 4
1199
1200 =item Arguments: $sql_fragment, @bind_values
1201
1202 =item Return Value: $count
1203
1204 =back
1205
1206 Counts the results in a literal query. Equivalent to calling L</search_literal>
1207 with the passed arguments, then L</count>.
1208
1209 =cut
1210
1211 sub count_literal { shift->search_literal(@_)->count; }
1212
1213 =head2 all
1214
1215 =over 4
1216
1217 =item Arguments: none
1218
1219 =item Return Value: @objects
1220
1221 =back
1222
1223 Returns all elements in the resultset. Called implicitly if the resultset
1224 is returned in list context.
1225
1226 =cut
1227
1228 sub all {
1229   my $self = shift;
1230   if(@_) {
1231       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1232   }
1233
1234   return @{ $self->get_cache } if $self->get_cache;
1235
1236   my @obj;
1237
1238   # TODO: don't call resolve here
1239   if (keys %{$self->_resolved_attrs->{collapse}}) {
1240 #  if ($self->{attrs}{prefetch}) {
1241       # Using $self->cursor->all is really just an optimisation.
1242       # If we're collapsing has_many prefetches it probably makes
1243       # very little difference, and this is cleaner than hacking
1244       # _construct_object to survive the approach
1245     my @row = $self->cursor->next;
1246     while (@row) {
1247       push(@obj, $self->_construct_object(@row));
1248       @row = (exists $self->{stashed_row}
1249                ? @{delete $self->{stashed_row}}
1250                : $self->cursor->next);
1251     }
1252   } else {
1253     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1254   }
1255
1256   $self->set_cache(\@obj) if $self->{attrs}{cache};
1257   return @obj;
1258 }
1259
1260 =head2 reset
1261
1262 =over 4
1263
1264 =item Arguments: none
1265
1266 =item Return Value: $self
1267
1268 =back
1269
1270 Resets the resultset's cursor, so you can iterate through the elements again.
1271
1272 =cut
1273
1274 sub reset {
1275   my ($self) = @_;
1276   delete $self->{_attrs} if exists $self->{_attrs};
1277   $self->{all_cache_position} = 0;
1278   $self->cursor->reset;
1279   return $self;
1280 }
1281
1282 =head2 first
1283
1284 =over 4
1285
1286 =item Arguments: none
1287
1288 =item Return Value: $object?
1289
1290 =back
1291
1292 Resets the resultset and returns an object for the first result (if the
1293 resultset returns anything).
1294
1295 =cut
1296
1297 sub first {
1298   return $_[0]->reset->next;
1299 }
1300
1301 # _cond_for_update_delete
1302 #
1303 # update/delete require the condition to be modified to handle
1304 # the differing SQL syntax available.  This transforms the $self->{cond}
1305 # appropriately, returning the new condition.
1306
1307 sub _cond_for_update_delete {
1308   my ($self, $full_cond) = @_;
1309   my $cond = {};
1310
1311   $full_cond ||= $self->{cond};
1312   # No-op. No condition, we're updating/deleting everything
1313   return $cond unless ref $full_cond;
1314
1315   foreach my $pk ($self->result_source->primary_columns) {
1316       $cond->{$pk} = { -in => $self->get_column($pk)->as_query };
1317   }
1318
1319   return $cond;
1320 }
1321
1322
1323 =head2 update
1324
1325 =over 4
1326
1327 =item Arguments: \%values
1328
1329 =item Return Value: $storage_rv
1330
1331 =back
1332
1333 Sets the specified columns in the resultset to the supplied values in a
1334 single query. Return value will be true if the update succeeded or false
1335 if no records were updated; exact type of success value is storage-dependent.
1336
1337 =cut
1338
1339 sub update {
1340   my ($self, $values) = @_;
1341   $self->throw_exception("Values for update must be a hash")
1342     unless ref $values eq 'HASH';
1343
1344   my $cond = $self->_cond_for_update_delete;
1345
1346   return $self->result_source->storage->update(
1347     $self->result_source, $values, $cond
1348   );
1349 }
1350
1351 =head2 update_all
1352
1353 =over 4
1354
1355 =item Arguments: \%values
1356
1357 =item Return Value: 1
1358
1359 =back
1360
1361 Fetches all objects and updates them one at a time. Note that C<update_all>
1362 will run DBIC cascade triggers, while L</update> will not.
1363
1364 =cut
1365
1366 sub update_all {
1367   my ($self, $values) = @_;
1368   $self->throw_exception("Values for update must be a hash")
1369     unless ref $values eq 'HASH';
1370   foreach my $obj ($self->all) {
1371     $obj->set_columns($values)->update;
1372   }
1373   return 1;
1374 }
1375
1376 =head2 delete
1377
1378 =over 4
1379
1380 =item Arguments: none
1381
1382 =item Return Value: 1
1383
1384 =back
1385
1386 Deletes the contents of the resultset from its result source. Note that this
1387 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1388 to run. See also L<DBIx::Class::Row/delete>.
1389
1390 delete may not generate correct SQL for a query with joins or a resultset
1391 chained from a related resultset.  In this case it will generate a warning:-
1392
1393 In these cases you may find that delete_all is more appropriate, or you
1394 need to respecify your query in a way that can be expressed without a join.
1395
1396 =cut
1397
1398 sub delete {
1399   my ($self) = @_;
1400   $self->throw_exception("Delete should not be passed any arguments")
1401     if $_[1];
1402
1403   my $cond = $self->_cond_for_update_delete;
1404
1405   $self->result_source->storage->delete($self->result_source, $cond);
1406   return 1;
1407 }
1408
1409 =head2 delete_all
1410
1411 =over 4
1412
1413 =item Arguments: none
1414
1415 =item Return Value: 1
1416
1417 =back
1418
1419 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1420 will run DBIC cascade triggers, while L</delete> will not.
1421
1422 =cut
1423
1424 sub delete_all {
1425   my ($self) = @_;
1426   $_->delete for $self->all;
1427   return 1;
1428 }
1429
1430 =head2 populate
1431
1432 =over 4
1433
1434 =item Arguments: \@data;
1435
1436 =back
1437
1438 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1439 For the arrayref of hashrefs style each hashref should be a structure suitable
1440 forsubmitting to a $resultset->create(...) method.
1441
1442 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1443 to insert the data, as this is a faster method.
1444
1445 Otherwise, each set of data is inserted into the database using
1446 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1447 objects is returned.
1448
1449 Example:  Assuming an Artist Class that has many CDs Classes relating:
1450
1451   my $Artist_rs = $schema->resultset("Artist");
1452
1453   ## Void Context Example
1454   $Artist_rs->populate([
1455      { artistid => 4, name => 'Manufactured Crap', cds => [
1456         { title => 'My First CD', year => 2006 },
1457         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1458       ],
1459      },
1460      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1461         { title => 'My parents sold me to a record company' ,year => 2005 },
1462         { title => 'Why Am I So Ugly?', year => 2006 },
1463         { title => 'I Got Surgery and am now Popular', year => 2007 }
1464       ],
1465      },
1466   ]);
1467
1468   ## Array Context Example
1469   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1470     { name => "Artist One"},
1471     { name => "Artist Two"},
1472     { name => "Artist Three", cds=> [
1473     { title => "First CD", year => 2007},
1474     { title => "Second CD", year => 2008},
1475   ]}
1476   ]);
1477
1478   print $ArtistOne->name; ## response is 'Artist One'
1479   print $ArtistThree->cds->count ## reponse is '2'
1480
1481 For the arrayref of arrayrefs style,  the first element should be a list of the
1482 fieldsnames to which the remaining elements are rows being inserted.  For
1483 example:
1484
1485   $Arstist_rs->populate([
1486     [qw/artistid name/],
1487     [100, 'A Formally Unknown Singer'],
1488     [101, 'A singer that jumped the shark two albums ago'],
1489     [102, 'An actually cool singer.'],
1490   ]);
1491
1492 Please note an important effect on your data when choosing between void and
1493 wantarray context. Since void context goes straight to C<insert_bulk> in
1494 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1495 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1496 create primary keys for you, you will find that your PKs are empty.  In this
1497 case you will have to use the wantarray context in order to create those
1498 values.
1499
1500 =cut
1501
1502 sub populate {
1503   my $self = shift @_;
1504   my $data = ref $_[0][0] eq 'HASH'
1505     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1506     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1507
1508   if(defined wantarray) {
1509     my @created;
1510     foreach my $item (@$data) {
1511       push(@created, $self->create($item));
1512     }
1513     return @created;
1514   } else {
1515     my ($first, @rest) = @$data;
1516
1517     my @names = grep {!ref $first->{$_}} keys %$first;
1518     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1519     my @pks = $self->result_source->primary_columns;
1520
1521     ## do the belongs_to relationships
1522     foreach my $index (0..$#$data) {
1523       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1524         my @ret = $self->populate($data);
1525         return;
1526       }
1527
1528       foreach my $rel (@rels) {
1529         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1530         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1531         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1532         my $related = $result->result_source->resolve_condition(
1533           $result->result_source->relationship_info($reverse)->{cond},
1534           $self,
1535           $result,
1536         );
1537
1538         delete $data->[$index]->{$rel};
1539         $data->[$index] = {%{$data->[$index]}, %$related};
1540
1541         push @names, keys %$related if $index == 0;
1542       }
1543     }
1544
1545     ## do bulk insert on current row
1546     my @values = map { [ @$_{@names} ] } @$data;
1547
1548     $self->result_source->storage->insert_bulk(
1549       $self->result_source,
1550       \@names,
1551       \@values,
1552     );
1553
1554     ## do the has_many relationships
1555     foreach my $item (@$data) {
1556
1557       foreach my $rel (@rels) {
1558         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1559
1560         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1561      || $self->throw_exception('Cannot find the relating object.');
1562
1563         my $child = $parent->$rel;
1564
1565         my $related = $child->result_source->resolve_condition(
1566           $parent->result_source->relationship_info($rel)->{cond},
1567           $child,
1568           $parent,
1569         );
1570
1571         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1572         my @populate = map { {%$_, %$related} } @rows_to_add;
1573
1574         $child->populate( \@populate );
1575       }
1576     }
1577   }
1578 }
1579
1580 =head2 _normalize_populate_args ($args)
1581
1582 Private method used by L</populate> to normalize its incoming arguments.  Factored
1583 out in case you want to subclass and accept new argument structures to the
1584 L</populate> method.
1585
1586 =cut
1587
1588 sub _normalize_populate_args {
1589   my ($self, $data) = @_;
1590   my @names = @{shift(@$data)};
1591   my @results_to_create;
1592   foreach my $datum (@$data) {
1593     my %result_to_create;
1594     foreach my $index (0..$#names) {
1595       $result_to_create{$names[$index]} = $$datum[$index];
1596     }
1597     push @results_to_create, \%result_to_create;
1598   }
1599   return \@results_to_create;
1600 }
1601
1602 =head2 pager
1603
1604 =over 4
1605
1606 =item Arguments: none
1607
1608 =item Return Value: $pager
1609
1610 =back
1611
1612 Return Value a L<Data::Page> object for the current resultset. Only makes
1613 sense for queries with a C<page> attribute.
1614
1615 To get the full count of entries for a paged resultset, call
1616 C<total_entries> on the L<Data::Page> object.
1617
1618 =cut
1619
1620 sub pager {
1621   my ($self) = @_;
1622   my $attrs = $self->{attrs};
1623   $self->throw_exception("Can't create pager for non-paged rs")
1624     unless $self->{attrs}{page};
1625   $attrs->{rows} ||= 10;
1626   return $self->{pager} ||= Data::Page->new(
1627     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1628 }
1629
1630 =head2 page
1631
1632 =over 4
1633
1634 =item Arguments: $page_number
1635
1636 =item Return Value: $rs
1637
1638 =back
1639
1640 Returns a resultset for the $page_number page of the resultset on which page
1641 is called, where each page contains a number of rows equal to the 'rows'
1642 attribute set on the resultset (10 by default).
1643
1644 =cut
1645
1646 sub page {
1647   my ($self, $page) = @_;
1648   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1649 }
1650
1651 =head2 new_result
1652
1653 =over 4
1654
1655 =item Arguments: \%vals
1656
1657 =item Return Value: $rowobject
1658
1659 =back
1660
1661 Creates a new row object in the resultset's result class and returns
1662 it. The row is not inserted into the database at this point, call
1663 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1664 will tell you whether the row object has been inserted or not.
1665
1666 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1667
1668 =cut
1669
1670 sub new_result {
1671   my ($self, $values) = @_;
1672   $self->throw_exception( "new_result needs a hash" )
1673     unless (ref $values eq 'HASH');
1674
1675   my %new;
1676   my $alias = $self->{attrs}{alias};
1677
1678   if (
1679     defined $self->{cond}
1680     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1681   ) {
1682     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1683     $new{-from_resultset} = [ keys %new ] if keys %new;
1684   } else {
1685     $self->throw_exception(
1686       "Can't abstract implicit construct, condition not a hash"
1687     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1688
1689     my $collapsed_cond = (
1690       $self->{cond}
1691         ? $self->_collapse_cond($self->{cond})
1692         : {}
1693     );
1694
1695     # precendence must be given to passed values over values inherited from
1696     # the cond, so the order here is important.
1697     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1698     while( my($col,$value) = each %implied ){
1699       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1700         $new{$col} = $value->{'='};
1701         next;
1702       }
1703       $new{$col} = $value if $self->_is_deterministic_value($value);
1704     }
1705   }
1706
1707   %new = (
1708     %new,
1709     %{ $self->_remove_alias($values, $alias) },
1710     -source_handle => $self->_source_handle,
1711     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1712   );
1713
1714   return $self->result_class->new(\%new);
1715 }
1716
1717 # _is_deterministic_value
1718 #
1719 # Make an effor to strip non-deterministic values from the condition,
1720 # to make sure new_result chokes less
1721
1722 sub _is_deterministic_value {
1723   my $self = shift;
1724   my $value = shift;
1725   my $ref_type = ref $value;
1726   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1727   return 1 if Scalar::Util::blessed($value);
1728   return 0;
1729 }
1730
1731 # _collapse_cond
1732 #
1733 # Recursively collapse the condition.
1734
1735 sub _collapse_cond {
1736   my ($self, $cond, $collapsed) = @_;
1737
1738   $collapsed ||= {};
1739
1740   if (ref $cond eq 'ARRAY') {
1741     foreach my $subcond (@$cond) {
1742       next unless ref $subcond;  # -or
1743       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1744     }
1745   }
1746   elsif (ref $cond eq 'HASH') {
1747     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1748       foreach my $subcond (@{$cond->{-and}}) {
1749         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1750       }
1751     }
1752     else {
1753       foreach my $col (keys %$cond) {
1754         my $value = $cond->{$col};
1755         $collapsed->{$col} = $value;
1756       }
1757     }
1758   }
1759
1760   return $collapsed;
1761 }
1762
1763 # _remove_alias
1764 #
1765 # Remove the specified alias from the specified query hash. A copy is made so
1766 # the original query is not modified.
1767
1768 sub _remove_alias {
1769   my ($self, $query, $alias) = @_;
1770
1771   my %orig = %{ $query || {} };
1772   my %unaliased;
1773
1774   foreach my $key (keys %orig) {
1775     if ($key !~ /\./) {
1776       $unaliased{$key} = $orig{$key};
1777       next;
1778     }
1779     $unaliased{$1} = $orig{$key}
1780       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1781   }
1782
1783   return \%unaliased;
1784 }
1785
1786 =head2 as_query (EXPERIMENTAL)
1787
1788 =over 4
1789
1790 =item Arguments: none
1791
1792 =item Return Value: \[ $sql, @bind ]
1793
1794 =back
1795
1796 Returns the SQL query and bind vars associated with the invocant.
1797
1798 This is generally used as the RHS for a subquery.
1799
1800 B<NOTE>: This feature is still experimental.
1801
1802 =cut
1803
1804 sub as_query { return shift->cursor->as_query(@_) }
1805
1806 =head2 find_or_new
1807
1808 =over 4
1809
1810 =item Arguments: \%vals, \%attrs?
1811
1812 =item Return Value: $rowobject
1813
1814 =back
1815
1816   my $artist = $schema->resultset('Artist')->find_or_new(
1817     { artist => 'fred' }, { key => 'artists' });
1818
1819   $cd->cd_to_producer->find_or_new({ producer => $producer },
1820                                    { key => 'primary });
1821
1822 Find an existing record from this resultset, based on its primary
1823 key, or a unique constraint. If none exists, instantiate a new result
1824 object and return it. The object will not be saved into your storage
1825 until you call L<DBIx::Class::Row/insert> on it.
1826
1827 You most likely want this method when looking for existing rows using
1828 a unique constraint that is not the primary key, or looking for
1829 related rows.
1830
1831 If you want objects to be saved immediately, use L</find_or_create> instead.
1832
1833 B<Note>: C<find_or_new> is probably not what you want when creating a
1834 new row in a table that uses primary keys supplied by the
1835 database. Passing in a primary key column with a value of I<undef>
1836 will cause L</find> to attempt to search for a row with a value of
1837 I<NULL>.
1838
1839 =cut
1840
1841 sub find_or_new {
1842   my $self     = shift;
1843   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1844   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1845   my $exists   = $self->find($hash, $attrs);
1846   return defined $exists ? $exists : $self->new_result($hash);
1847 }
1848
1849 =head2 create
1850
1851 =over 4
1852
1853 =item Arguments: \%vals
1854
1855 =item Return Value: a L<DBIx::Class::Row> $object
1856
1857 =back
1858
1859 Attempt to create a single new row or a row with multiple related rows
1860 in the table represented by the resultset (and related tables). This
1861 will not check for duplicate rows before inserting, use
1862 L</find_or_create> to do that.
1863
1864 To create one row for this resultset, pass a hashref of key/value
1865 pairs representing the columns of the table and the values you wish to
1866 store. If the appropriate relationships are set up, foreign key fields
1867 can also be passed an object representing the foreign row, and the
1868 value will be set to its primary key.
1869
1870 To create related objects, pass a hashref for the value if the related
1871 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1872 and use the name of the relationship as the key. (NOT the name of the field,
1873 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1874 of hashrefs containing the data for each of the rows to create in the foreign
1875 tables, again using the relationship name as the key.
1876
1877 Instead of hashrefs of plain related data (key/value pairs), you may
1878 also pass new or inserted objects. New objects (not inserted yet, see
1879 L</new>), will be inserted into their appropriate tables.
1880
1881 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1882
1883 Example of creating a new row.
1884
1885   $person_rs->create({
1886     name=>"Some Person",
1887     email=>"somebody@someplace.com"
1888   });
1889
1890 Example of creating a new row and also creating rows in a related C<has_many>
1891 or C<has_one> resultset.  Note Arrayref.
1892
1893   $artist_rs->create(
1894      { artistid => 4, name => 'Manufactured Crap', cds => [
1895         { title => 'My First CD', year => 2006 },
1896         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1897       ],
1898      },
1899   );
1900
1901 Example of creating a new row and also creating a row in a related
1902 C<belongs_to>resultset. Note Hashref.
1903
1904   $cd_rs->create({
1905     title=>"Music for Silly Walks",
1906     year=>2000,
1907     artist => {
1908       name=>"Silly Musician",
1909     }
1910   });
1911
1912 =cut
1913
1914 sub create {
1915   my ($self, $attrs) = @_;
1916   $self->throw_exception( "create needs a hashref" )
1917     unless ref $attrs eq 'HASH';
1918   return $self->new_result($attrs)->insert;
1919 }
1920
1921 =head2 find_or_create
1922
1923 =over 4
1924
1925 =item Arguments: \%vals, \%attrs?
1926
1927 =item Return Value: $rowobject
1928
1929 =back
1930
1931   $cd->cd_to_producer->find_or_create({ producer => $producer },
1932                                       { key => 'primary });
1933
1934 Tries to find a record based on its primary key or unique constraints; if none
1935 is found, creates one and returns that instead.
1936
1937   my $cd = $schema->resultset('CD')->find_or_create({
1938     cdid   => 5,
1939     artist => 'Massive Attack',
1940     title  => 'Mezzanine',
1941     year   => 2005,
1942   });
1943
1944 Also takes an optional C<key> attribute, to search by a specific key or unique
1945 constraint. For example:
1946
1947   my $cd = $schema->resultset('CD')->find_or_create(
1948     {
1949       artist => 'Massive Attack',
1950       title  => 'Mezzanine',
1951     },
1952     { key => 'cd_artist_title' }
1953   );
1954
1955 B<Note>: Because find_or_create() reads from the database and then
1956 possibly inserts based on the result, this method is subject to a race
1957 condition. Another process could create a record in the table after
1958 the find has completed and before the create has started. To avoid
1959 this problem, use find_or_create() inside a transaction.
1960
1961 B<Note>: C<find_or_create> is probably not what you want when creating
1962 a new row in a table that uses primary keys supplied by the
1963 database. Passing in a primary key column with a value of I<undef>
1964 will cause L</find> to attempt to search for a row with a value of
1965 I<NULL>.
1966
1967 See also L</find> and L</update_or_create>. For information on how to declare
1968 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1969
1970 =cut
1971
1972 sub find_or_create {
1973   my $self     = shift;
1974   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1975   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1976   my $exists   = $self->find($hash, $attrs);
1977   return defined $exists ? $exists : $self->create($hash);
1978 }
1979
1980 =head2 update_or_create
1981
1982 =over 4
1983
1984 =item Arguments: \%col_values, { key => $unique_constraint }?
1985
1986 =item Return Value: $rowobject
1987
1988 =back
1989
1990   $resultset->update_or_create({ col => $val, ... });
1991
1992 First, searches for an existing row matching one of the unique constraints
1993 (including the primary key) on the source of this resultset. If a row is
1994 found, updates it with the other given column values. Otherwise, creates a new
1995 row.
1996
1997 Takes an optional C<key> attribute to search on a specific unique constraint.
1998 For example:
1999
2000   # In your application
2001   my $cd = $schema->resultset('CD')->update_or_create(
2002     {
2003       artist => 'Massive Attack',
2004       title  => 'Mezzanine',
2005       year   => 1998,
2006     },
2007     { key => 'cd_artist_title' }
2008   );
2009
2010   $cd->cd_to_producer->update_or_create({
2011     producer => $producer,
2012     name => 'harry',
2013   }, {
2014     key => 'primary,
2015   });
2016
2017
2018 If no C<key> is specified, it searches on all unique constraints defined on the
2019 source, including the primary key.
2020
2021 If the C<key> is specified as C<primary>, it searches only on the primary key.
2022
2023 See also L</find> and L</find_or_create>. For information on how to declare
2024 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2025
2026 B<Note>: C<update_or_create> is probably not what you want when
2027 looking for a row in a table that uses primary keys supplied by the
2028 database, unless you actually have a key value. Passing in a primary
2029 key column with a value of I<undef> will cause L</find> to attempt to
2030 search for a row with a value of I<NULL>.
2031
2032 =cut
2033
2034 sub update_or_create {
2035   my $self = shift;
2036   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2037   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2038
2039   my $row = $self->find($cond, $attrs);
2040   if (defined $row) {
2041     $row->update($cond);
2042     return $row;
2043   }
2044
2045   return $self->create($cond);
2046 }
2047
2048 =head2 update_or_new
2049
2050 =over 4
2051
2052 =item Arguments: \%col_values, { key => $unique_constraint }?
2053
2054 =item Return Value: $rowobject
2055
2056 =back
2057
2058   $resultset->update_or_new({ col => $val, ... });
2059
2060 First, searches for an existing row matching one of the unique constraints
2061 (including the primary key) on the source of this resultset. If a row is
2062 found, updates it with the other given column values. Otherwise, instantiate
2063 a new result object and return it. The object will not be saved into your storage
2064 until you call L<DBIx::Class::Row/insert> on it.
2065
2066 Takes an optional C<key> attribute to search on a specific unique constraint.
2067 For example:
2068
2069   # In your application
2070   my $cd = $schema->resultset('CD')->update_or_new(
2071     {
2072       artist => 'Massive Attack',
2073       title  => 'Mezzanine',
2074       year   => 1998,
2075     },
2076     { key => 'cd_artist_title' }
2077   );
2078
2079   if ($cd->in_storage) {
2080       # the cd was updated
2081   }
2082   else {
2083       # the cd is not yet in the database, let's insert it
2084       $cd->insert;
2085   }
2086
2087 See also L</find>, L</find_or_create> and L<find_or_new>.
2088
2089 =cut
2090
2091 sub update_or_new {
2092     my $self  = shift;
2093     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2094     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2095
2096     my $row = $self->find( $cond, $attrs );
2097     if ( defined $row ) {
2098         $row->update($cond);
2099         return $row;
2100     }
2101
2102     return $self->new_result($cond);
2103 }
2104
2105 =head2 get_cache
2106
2107 =over 4
2108
2109 =item Arguments: none
2110
2111 =item Return Value: \@cache_objects?
2112
2113 =back
2114
2115 Gets the contents of the cache for the resultset, if the cache is set.
2116
2117 The cache is populated either by using the L</prefetch> attribute to
2118 L</search> or by calling L</set_cache>.
2119
2120 =cut
2121
2122 sub get_cache {
2123   shift->{all_cache};
2124 }
2125
2126 =head2 set_cache
2127
2128 =over 4
2129
2130 =item Arguments: \@cache_objects
2131
2132 =item Return Value: \@cache_objects
2133
2134 =back
2135
2136 Sets the contents of the cache for the resultset. Expects an arrayref
2137 of objects of the same class as those produced by the resultset. Note that
2138 if the cache is set the resultset will return the cached objects rather
2139 than re-querying the database even if the cache attr is not set.
2140
2141 The contents of the cache can also be populated by using the
2142 L</prefetch> attribute to L</search>.
2143
2144 =cut
2145
2146 sub set_cache {
2147   my ( $self, $data ) = @_;
2148   $self->throw_exception("set_cache requires an arrayref")
2149       if defined($data) && (ref $data ne 'ARRAY');
2150   $self->{all_cache} = $data;
2151 }
2152
2153 =head2 clear_cache
2154
2155 =over 4
2156
2157 =item Arguments: none
2158
2159 =item Return Value: []
2160
2161 =back
2162
2163 Clears the cache for the resultset.
2164
2165 =cut
2166
2167 sub clear_cache {
2168   shift->set_cache(undef);
2169 }
2170
2171 =head2 related_resultset
2172
2173 =over 4
2174
2175 =item Arguments: $relationship_name
2176
2177 =item Return Value: $resultset
2178
2179 =back
2180
2181 Returns a related resultset for the supplied relationship name.
2182
2183   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2184
2185 =cut
2186
2187 sub related_resultset {
2188   my ($self, $rel) = @_;
2189
2190   $self->{related_resultsets} ||= {};
2191   return $self->{related_resultsets}{$rel} ||= do {
2192     my $rel_obj = $self->result_source->relationship_info($rel);
2193
2194     $self->throw_exception(
2195       "search_related: result source '" . $self->result_source->source_name .
2196         "' has no such relationship $rel")
2197       unless $rel_obj;
2198
2199     my ($from,$seen) = $self->_resolve_from($rel);
2200
2201     my $join_count = $seen->{$rel};
2202     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2203
2204     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2205     my %attrs = %{$self->{attrs}||{}};
2206     delete @attrs{qw(result_class alias)};
2207
2208     my $new_cache;
2209
2210     if (my $cache = $self->get_cache) {
2211       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2212         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2213                         @$cache ];
2214       }
2215     }
2216
2217     my $rel_source = $self->result_source->related_source($rel);
2218
2219     my $new = do {
2220
2221       # The reason we do this now instead of passing the alias to the
2222       # search_rs below is that if you wrap/overload resultset on the
2223       # source you need to know what alias it's -going- to have for things
2224       # to work sanely (e.g. RestrictWithObject wants to be able to add
2225       # extra query restrictions, and these may need to be $alias.)
2226
2227       my $attrs = $rel_source->resultset_attributes;
2228       local $attrs->{alias} = $alias;
2229
2230       $rel_source->resultset
2231                  ->search_rs(
2232                      undef, {
2233                        %attrs,
2234                        join => undef,
2235                        prefetch => undef,
2236                        select => undef,
2237                        as => undef,
2238                        where => $self->{cond},
2239                        seen_join => $seen,
2240                        from => $from,
2241                    });
2242     };
2243     $new->set_cache($new_cache) if $new_cache;
2244     $new;
2245   };
2246 }
2247
2248 =head2 current_source_alias
2249
2250 =over 4
2251
2252 =item Arguments: none
2253
2254 =item Return Value: $source_alias
2255
2256 =back
2257
2258 Returns the current table alias for the result source this resultset is built
2259 on, that will be used in the SQL query. Usually it is C<me>.
2260
2261 Currently the source alias that refers to the result set returned by a
2262 L</search>/L</find> family method depends on how you got to the resultset: it's
2263 C<me> by default, but eg. L</search_related> aliases it to the related result
2264 source name (and keeps C<me> referring to the original result set). The long
2265 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2266 (and make this method unnecessary).
2267
2268 Thus it's currently necessary to use this method in predefined queries (see
2269 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2270 source alias of the current result set:
2271
2272   # in a result set class
2273   sub modified_by {
2274     my ($self, $user) = @_;
2275
2276     my $me = $self->current_source_alias;
2277
2278     return $self->search(
2279       "$me.modified" => $user->id,
2280     );
2281   }
2282
2283 =cut
2284
2285 sub current_source_alias {
2286   my ($self) = @_;
2287
2288   return ($self->{attrs} || {})->{alias} || 'me';
2289 }
2290
2291 sub _resolve_from {
2292   my ($self, $extra_join) = @_;
2293   my $source = $self->result_source;
2294   my $attrs = $self->{attrs};
2295
2296   my $from = $attrs->{from}
2297     || [ { $attrs->{alias} => $source->from } ];
2298
2299   my $seen = { %{$attrs->{seen_join}||{}} };
2300
2301   my $join = ($attrs->{join}
2302                ? [ $attrs->{join}, $extra_join ]
2303                : $extra_join);
2304
2305   # we need to take the prefetch the attrs into account before we
2306   # ->resolve_join as otherwise they get lost - captainL
2307   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2308
2309   $from = [
2310     @$from,
2311     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2312   ];
2313
2314   return ($from,$seen);
2315 }
2316
2317 sub _resolved_attrs {
2318   my $self = shift;
2319   return $self->{_attrs} if $self->{_attrs};
2320
2321   my $attrs  = { %{ $self->{attrs} || {} } };
2322   my $source = $self->result_source;
2323   my $alias  = $attrs->{alias};
2324
2325   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2326   my @colbits;
2327
2328   # build columns (as long as select isn't set) into a set of as/select hashes
2329   unless ( $attrs->{select} ) {
2330       @colbits = map {
2331           ( ref($_) eq 'HASH' )
2332               ? $_
2333               : {
2334                   (
2335                     /^\Q${alias}.\E(.+)$/
2336                       ? "$1"
2337                       : "$_"
2338                   )
2339                 =>
2340                   (
2341                     /\./
2342                       ? "$_"
2343                       : "${alias}.$_"
2344                   )
2345             }
2346       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2347   }
2348   # add the additional columns on
2349   foreach ( 'include_columns', '+columns' ) {
2350       push @colbits, map {
2351           ( ref($_) eq 'HASH' )
2352             ? $_
2353             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2354       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2355   }
2356
2357   # start with initial select items
2358   if ( $attrs->{select} ) {
2359     $attrs->{select} =
2360         ( ref $attrs->{select} eq 'ARRAY' )
2361       ? [ @{ $attrs->{select} } ]
2362       : [ $attrs->{select} ];
2363     $attrs->{as} = (
2364       $attrs->{as}
2365       ? (
2366         ref $attrs->{as} eq 'ARRAY'
2367         ? [ @{ $attrs->{as} } ]
2368         : [ $attrs->{as} ]
2369         )
2370       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2371     );
2372   }
2373   else {
2374
2375     # otherwise we intialise select & as to empty
2376     $attrs->{select} = [];
2377     $attrs->{as}     = [];
2378   }
2379
2380   # now add colbits to select/as
2381   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2382   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2383
2384   my $adds;
2385   if ( $adds = delete $attrs->{'+select'} ) {
2386     $adds = [$adds] unless ref $adds eq 'ARRAY';
2387     push(
2388       @{ $attrs->{select} },
2389       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2390     );
2391   }
2392   if ( $adds = delete $attrs->{'+as'} ) {
2393     $adds = [$adds] unless ref $adds eq 'ARRAY';
2394     push( @{ $attrs->{as} }, @$adds );
2395   }
2396
2397   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2398
2399   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2400     my $join = delete $attrs->{join} || {};
2401
2402     if ( defined $attrs->{prefetch} ) {
2403       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2404
2405     }
2406
2407     $attrs->{from} =    # have to copy here to avoid corrupting the original
2408       [
2409       @{ $attrs->{from} },
2410       $source->resolve_join(
2411         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2412       )
2413       ];
2414
2415   }
2416
2417   $attrs->{group_by} ||= $attrs->{select}
2418     if delete $attrs->{distinct};
2419   if ( $attrs->{order_by} ) {
2420     $attrs->{order_by} = (
2421       ref( $attrs->{order_by} ) eq 'ARRAY'
2422       ? [ @{ $attrs->{order_by} } ]
2423       : [ $attrs->{order_by} ]
2424     );
2425   }
2426   else {
2427     $attrs->{order_by} = [];
2428   }
2429
2430   my $collapse = $attrs->{collapse} || {};
2431   if ( my $prefetch = delete $attrs->{prefetch} ) {
2432     $prefetch = $self->_merge_attr( {}, $prefetch );
2433     my @pre_order;
2434     my $seen = { %{ $attrs->{seen_join} || {} } };
2435     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2436
2437       # bring joins back to level of current class
2438       my @prefetch =
2439         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2440       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2441       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2442     }
2443     push( @{ $attrs->{order_by} }, @pre_order );
2444   }
2445   $attrs->{collapse} = $collapse;
2446
2447   if ( $attrs->{page} ) {
2448     $attrs->{offset} ||= 0;
2449     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2450   }
2451
2452   return $self->{_attrs} = $attrs;
2453 }
2454
2455 sub _rollout_attr {
2456   my ($self, $attr) = @_;
2457
2458   if (ref $attr eq 'HASH') {
2459     return $self->_rollout_hash($attr);
2460   } elsif (ref $attr eq 'ARRAY') {
2461     return $self->_rollout_array($attr);
2462   } else {
2463     return [$attr];
2464   }
2465 }
2466
2467 sub _rollout_array {
2468   my ($self, $attr) = @_;
2469
2470   my @rolled_array;
2471   foreach my $element (@{$attr}) {
2472     if (ref $element eq 'HASH') {
2473       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2474     } elsif (ref $element eq 'ARRAY') {
2475       #  XXX - should probably recurse here
2476       push( @rolled_array, @{$self->_rollout_array($element)} );
2477     } else {
2478       push( @rolled_array, $element );
2479     }
2480   }
2481   return \@rolled_array;
2482 }
2483
2484 sub _rollout_hash {
2485   my ($self, $attr) = @_;
2486
2487   my @rolled_array;
2488   foreach my $key (keys %{$attr}) {
2489     push( @rolled_array, { $key => $attr->{$key} } );
2490   }
2491   return \@rolled_array;
2492 }
2493
2494 sub _calculate_score {
2495   my ($self, $a, $b) = @_;
2496
2497   if (ref $b eq 'HASH') {
2498     my ($b_key) = keys %{$b};
2499     if (ref $a eq 'HASH') {
2500       my ($a_key) = keys %{$a};
2501       if ($a_key eq $b_key) {
2502         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2503       } else {
2504         return 0;
2505       }
2506     } else {
2507       return ($a eq $b_key) ? 1 : 0;
2508     }
2509   } else {
2510     if (ref $a eq 'HASH') {
2511       my ($a_key) = keys %{$a};
2512       return ($b eq $a_key) ? 1 : 0;
2513     } else {
2514       return ($b eq $a) ? 1 : 0;
2515     }
2516   }
2517 }
2518
2519 sub _merge_attr {
2520   my ($self, $orig, $import) = @_;
2521
2522   return $import unless defined($orig);
2523   return $orig unless defined($import);
2524
2525   $orig = $self->_rollout_attr($orig);
2526   $import = $self->_rollout_attr($import);
2527
2528   my $seen_keys;
2529   foreach my $import_element ( @{$import} ) {
2530     # find best candidate from $orig to merge $b_element into
2531     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2532     foreach my $orig_element ( @{$orig} ) {
2533       my $score = $self->_calculate_score( $orig_element, $import_element );
2534       if ($score > $best_candidate->{score}) {
2535         $best_candidate->{position} = $position;
2536         $best_candidate->{score} = $score;
2537       }
2538       $position++;
2539     }
2540     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2541
2542     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2543       push( @{$orig}, $import_element );
2544     } else {
2545       my $orig_best = $orig->[$best_candidate->{position}];
2546       # merge orig_best and b_element together and replace original with merged
2547       if (ref $orig_best ne 'HASH') {
2548         $orig->[$best_candidate->{position}] = $import_element;
2549       } elsif (ref $import_element eq 'HASH') {
2550         my ($key) = keys %{$orig_best};
2551         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2552       }
2553     }
2554     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2555   }
2556
2557   return $orig;
2558 }
2559
2560 sub result_source {
2561     my $self = shift;
2562
2563     if (@_) {
2564         $self->_source_handle($_[0]->handle);
2565     } else {
2566         $self->_source_handle->resolve;
2567     }
2568 }
2569
2570 =head2 throw_exception
2571
2572 See L<DBIx::Class::Schema/throw_exception> for details.
2573
2574 =cut
2575
2576 sub throw_exception {
2577   my $self=shift;
2578   if (ref $self && $self->_source_handle->schema) {
2579     $self->_source_handle->schema->throw_exception(@_)
2580   } else {
2581     croak(@_);
2582   }
2583
2584 }
2585
2586 # XXX: FIXME: Attributes docs need clearing up
2587
2588 =head1 ATTRIBUTES
2589
2590 Attributes are used to refine a ResultSet in various ways when
2591 searching for data. They can be passed to any method which takes an
2592 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2593 L</count>.
2594
2595 These are in no particular order:
2596
2597 =head2 order_by
2598
2599 =over 4
2600
2601 =item Value: ( $order_by | \@order_by | \%order_by )
2602
2603 =back
2604
2605 Which column(s) to order the results by. If a single column name, or
2606 an arrayref of names is supplied, the argument is passed through
2607 directly to SQL. The hashref syntax allows for connection-agnostic
2608 specification of ordering direction:
2609
2610  For descending order:
2611
2612   order_by => { -desc => [qw/col1 col2 col3/] }
2613
2614  For explicit ascending order:
2615
2616   order_by => { -asc => 'col' }
2617
2618 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2619 supported, although you are strongly encouraged to use the hashref
2620 syntax as outlined above.
2621
2622 =head2 columns
2623
2624 =over 4
2625
2626 =item Value: \@columns
2627
2628 =back
2629
2630 Shortcut to request a particular set of columns to be retrieved. Each
2631 column spec may be a string (a table column name), or a hash (in which
2632 case the key is the C<as> value, and the value is used as the C<select>
2633 expression). Adds C<me.> onto the start of any column without a C<.> in
2634 it and sets C<select> from that, then auto-populates C<as> from
2635 C<select> as normal. (You may also use the C<cols> attribute, as in
2636 earlier versions of DBIC.)
2637
2638 =head2 +columns
2639
2640 =over 4
2641
2642 =item Value: \@columns
2643
2644 =back
2645
2646 Indicates additional columns to be selected from storage. Works the same
2647 as L</columns> but adds columns to the selection. (You may also use the
2648 C<include_columns> attribute, as in earlier versions of DBIC). For
2649 example:-
2650
2651   $schema->resultset('CD')->search(undef, {
2652     '+columns' => ['artist.name'],
2653     join => ['artist']
2654   });
2655
2656 would return all CDs and include a 'name' column to the information
2657 passed to object inflation. Note that the 'artist' is the name of the
2658 column (or relationship) accessor, and 'name' is the name of the column
2659 accessor in the related table.
2660
2661 =head2 include_columns
2662
2663 =over 4
2664
2665 =item Value: \@columns
2666
2667 =back
2668
2669 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2670
2671 =head2 select
2672
2673 =over 4
2674
2675 =item Value: \@select_columns
2676
2677 =back
2678
2679 Indicates which columns should be selected from the storage. You can use
2680 column names, or in the case of RDBMS back ends, function or stored procedure
2681 names:
2682
2683   $rs = $schema->resultset('Employee')->search(undef, {
2684     select => [
2685       'name',
2686       { count => 'employeeid' },
2687       { sum => 'salary' }
2688     ]
2689   });
2690
2691 When you use function/stored procedure names and do not supply an C<as>
2692 attribute, the column names returned are storage-dependent. E.g. MySQL would
2693 return a column named C<count(employeeid)> in the above example.
2694
2695 =head2 +select
2696
2697 =over 4
2698
2699 Indicates additional columns to be selected from storage.  Works the same as
2700 L</select> but adds columns to the selection.
2701
2702 =back
2703
2704 =head2 +as
2705
2706 =over 4
2707
2708 Indicates additional column names for those added via L</+select>. See L</as>.
2709
2710 =back
2711
2712 =head2 as
2713
2714 =over 4
2715
2716 =item Value: \@inflation_names
2717
2718 =back
2719
2720 Indicates column names for object inflation. That is, C<as>
2721 indicates the name that the column can be accessed as via the
2722 C<get_column> method (or via the object accessor, B<if one already
2723 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2724
2725 The C<as> attribute is used in conjunction with C<select>,
2726 usually when C<select> contains one or more function or stored
2727 procedure names:
2728
2729   $rs = $schema->resultset('Employee')->search(undef, {
2730     select => [
2731       'name',
2732       { count => 'employeeid' }
2733     ],
2734     as => ['name', 'employee_count'],
2735   });
2736
2737   my $employee = $rs->first(); # get the first Employee
2738
2739 If the object against which the search is performed already has an accessor
2740 matching a column name specified in C<as>, the value can be retrieved using
2741 the accessor as normal:
2742
2743   my $name = $employee->name();
2744
2745 If on the other hand an accessor does not exist in the object, you need to
2746 use C<get_column> instead:
2747
2748   my $employee_count = $employee->get_column('employee_count');
2749
2750 You can create your own accessors if required - see
2751 L<DBIx::Class::Manual::Cookbook> for details.
2752
2753 Please note: This will NOT insert an C<AS employee_count> into the SQL
2754 statement produced, it is used for internal access only. Thus
2755 attempting to use the accessor in an C<order_by> clause or similar
2756 will fail miserably.
2757
2758 To get around this limitation, you can supply literal SQL to your
2759 C<select> attibute that contains the C<AS alias> text, eg:
2760
2761   select => [\'myfield AS alias']
2762
2763 =head2 join
2764
2765 =over 4
2766
2767 =item Value: ($rel_name | \@rel_names | \%rel_names)
2768
2769 =back
2770
2771 Contains a list of relationships that should be joined for this query.  For
2772 example:
2773
2774   # Get CDs by Nine Inch Nails
2775   my $rs = $schema->resultset('CD')->search(
2776     { 'artist.name' => 'Nine Inch Nails' },
2777     { join => 'artist' }
2778   );
2779
2780 Can also contain a hash reference to refer to the other relation's relations.
2781 For example:
2782
2783   package MyApp::Schema::Track;
2784   use base qw/DBIx::Class/;
2785   __PACKAGE__->table('track');
2786   __PACKAGE__->add_columns(qw/trackid cd position title/);
2787   __PACKAGE__->set_primary_key('trackid');
2788   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2789   1;
2790
2791   # In your application
2792   my $rs = $schema->resultset('Artist')->search(
2793     { 'track.title' => 'Teardrop' },
2794     {
2795       join     => { cd => 'track' },
2796       order_by => 'artist.name',
2797     }
2798   );
2799
2800 You need to use the relationship (not the table) name in  conditions,
2801 because they are aliased as such. The current table is aliased as "me", so
2802 you need to use me.column_name in order to avoid ambiguity. For example:
2803
2804   # Get CDs from 1984 with a 'Foo' track
2805   my $rs = $schema->resultset('CD')->search(
2806     {
2807       'me.year' => 1984,
2808       'tracks.name' => 'Foo'
2809     },
2810     { join => 'tracks' }
2811   );
2812
2813 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2814 similarly for a third time). For e.g.
2815
2816   my $rs = $schema->resultset('Artist')->search({
2817     'cds.title'   => 'Down to Earth',
2818     'cds_2.title' => 'Popular',
2819   }, {
2820     join => [ qw/cds cds/ ],
2821   });
2822
2823 will return a set of all artists that have both a cd with title 'Down
2824 to Earth' and a cd with title 'Popular'.
2825
2826 If you want to fetch related objects from other tables as well, see C<prefetch>
2827 below.
2828
2829 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2830
2831 =head2 prefetch
2832
2833 =over 4
2834
2835 =item Value: ($rel_name | \@rel_names | \%rel_names)
2836
2837 =back
2838
2839 Contains one or more relationships that should be fetched along with
2840 the main query (when they are accessed afterwards the data will
2841 already be available, without extra queries to the database).  This is
2842 useful for when you know you will need the related objects, because it
2843 saves at least one query:
2844
2845   my $rs = $schema->resultset('Tag')->search(
2846     undef,
2847     {
2848       prefetch => {
2849         cd => 'artist'
2850       }
2851     }
2852   );
2853
2854 The initial search results in SQL like the following:
2855
2856   SELECT tag.*, cd.*, artist.* FROM tag
2857   JOIN cd ON tag.cd = cd.cdid
2858   JOIN artist ON cd.artist = artist.artistid
2859
2860 L<DBIx::Class> has no need to go back to the database when we access the
2861 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2862 case.
2863
2864 Simple prefetches will be joined automatically, so there is no need
2865 for a C<join> attribute in the above search.
2866
2867 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2868 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2869 with an accessor type of 'single' or 'filter'). A more complex example that
2870 prefetches an artists cds, the tracks on those cds, and the tags associted
2871 with that artist is given below (assuming many-to-many from artists to tags):
2872
2873  my $rs = $schema->resultset('Artist')->search(
2874    undef,
2875    {
2876      prefetch => [
2877        { cds => 'tracks' },
2878        { artist_tags => 'tags' }
2879      ]
2880    }
2881  );
2882
2883
2884 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2885 attributes will be ignored.
2886
2887 =head2 page
2888
2889 =over 4
2890
2891 =item Value: $page
2892
2893 =back
2894
2895 Makes the resultset paged and specifies the page to retrieve. Effectively
2896 identical to creating a non-pages resultset and then calling ->page($page)
2897 on it.
2898
2899 If L<rows> attribute is not specified it defualts to 10 rows per page.
2900
2901 When you have a paged resultset, L</count> will only return the number
2902 of rows in the page. To get the total, use the L</pager> and call
2903 C<total_entries> on it.
2904
2905 =head2 rows
2906
2907 =over 4
2908
2909 =item Value: $rows
2910
2911 =back
2912
2913 Specifes the maximum number of rows for direct retrieval or the number of
2914 rows per page if the page attribute or method is used.
2915
2916 =head2 offset
2917
2918 =over 4
2919
2920 =item Value: $offset
2921
2922 =back
2923
2924 Specifies the (zero-based) row number for the  first row to be returned, or the
2925 of the first row of the first page if paging is used.
2926
2927 =head2 group_by
2928
2929 =over 4
2930
2931 =item Value: \@columns
2932
2933 =back
2934
2935 A arrayref of columns to group by. Can include columns of joined tables.
2936
2937   group_by => [qw/ column1 column2 ... /]
2938
2939 =head2 having
2940
2941 =over 4
2942
2943 =item Value: $condition
2944
2945 =back
2946
2947 HAVING is a select statement attribute that is applied between GROUP BY and
2948 ORDER BY. It is applied to the after the grouping calculations have been
2949 done.
2950
2951   having => { 'count(employee)' => { '>=', 100 } }
2952
2953 =head2 distinct
2954
2955 =over 4
2956
2957 =item Value: (0 | 1)
2958
2959 =back
2960
2961 Set to 1 to group by all columns.
2962
2963 =head2 where
2964
2965 =over 4
2966
2967 Adds to the WHERE clause.
2968
2969   # only return rows WHERE deleted IS NULL for all searches
2970   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2971
2972 Can be overridden by passing C<{ where => undef }> as an attribute
2973 to a resulset.
2974
2975 =back
2976
2977 =head2 cache
2978
2979 Set to 1 to cache search results. This prevents extra SQL queries if you
2980 revisit rows in your ResultSet:
2981
2982   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2983
2984   while( my $artist = $resultset->next ) {
2985     ... do stuff ...
2986   }
2987
2988   $rs->first; # without cache, this would issue a query
2989
2990 By default, searches are not cached.
2991
2992 For more examples of using these attributes, see
2993 L<DBIx::Class::Manual::Cookbook>.
2994
2995 =head2 from
2996
2997 =over 4
2998
2999 =item Value: \@from_clause
3000
3001 =back
3002
3003 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3004 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3005 clauses.
3006
3007 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3008
3009 C<join> will usually do what you need and it is strongly recommended that you
3010 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3011 And we really do mean "cannot", not just tried and failed. Attempting to use
3012 this because you're having problems with C<join> is like trying to use x86
3013 ASM because you've got a syntax error in your C. Trust us on this.
3014
3015 Now, if you're still really, really sure you need to use this (and if you're
3016 not 100% sure, ask the mailing list first), here's an explanation of how this
3017 works.
3018
3019 The syntax is as follows -
3020
3021   [
3022     { <alias1> => <table1> },
3023     [
3024       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3025       [], # nested JOIN (optional)
3026       { <table1.column1> => <table2.column2>, ... (more conditions) },
3027     ],
3028     # More of the above [ ] may follow for additional joins
3029   ]
3030
3031   <table1> <alias1>
3032   JOIN
3033     <table2> <alias2>
3034     [JOIN ...]
3035   ON <table1.column1> = <table2.column2>
3036   <more joins may follow>
3037
3038 An easy way to follow the examples below is to remember the following:
3039
3040     Anything inside "[]" is a JOIN
3041     Anything inside "{}" is a condition for the enclosing JOIN
3042
3043 The following examples utilize a "person" table in a family tree application.
3044 In order to express parent->child relationships, this table is self-joined:
3045
3046     # Person->belongs_to('father' => 'Person');
3047     # Person->belongs_to('mother' => 'Person');
3048
3049 C<from> can be used to nest joins. Here we return all children with a father,
3050 then search against all mothers of those children:
3051
3052   $rs = $schema->resultset('Person')->search(
3053       undef,
3054       {
3055           alias => 'mother', # alias columns in accordance with "from"
3056           from => [
3057               { mother => 'person' },
3058               [
3059                   [
3060                       { child => 'person' },
3061                       [
3062                           { father => 'person' },
3063                           { 'father.person_id' => 'child.father_id' }
3064                       ]
3065                   ],
3066                   { 'mother.person_id' => 'child.mother_id' }
3067               ],
3068           ]
3069       },
3070   );
3071
3072   # Equivalent SQL:
3073   # SELECT mother.* FROM person mother
3074   # JOIN (
3075   #   person child
3076   #   JOIN person father
3077   #   ON ( father.person_id = child.father_id )
3078   # )
3079   # ON ( mother.person_id = child.mother_id )
3080
3081 The type of any join can be controlled manually. To search against only people
3082 with a father in the person table, we could explicitly use C<INNER JOIN>:
3083
3084     $rs = $schema->resultset('Person')->search(
3085         undef,
3086         {
3087             alias => 'child', # alias columns in accordance with "from"
3088             from => [
3089                 { child => 'person' },
3090                 [
3091                     { father => 'person', -join_type => 'inner' },
3092                     { 'father.id' => 'child.father_id' }
3093                 ],
3094             ]
3095         },
3096     );
3097
3098     # Equivalent SQL:
3099     # SELECT child.* FROM person child
3100     # INNER JOIN person father ON child.father_id = father.id
3101
3102 If you need to express really complex joins or you need a subselect, you
3103 can supply literal SQL to C<from> via a scalar reference. In this case
3104 the contents of the scalar will replace the table name asscoiated with the
3105 resultsource.
3106
3107 WARNING: This technique might very well not work as expected on chained
3108 searches - you have been warned.
3109
3110     # Assuming the Event resultsource is defined as:
3111
3112         MySchema::Event->add_columns (
3113             sequence => {
3114                 data_type => 'INT',
3115                 is_auto_increment => 1,
3116             },
3117             location => {
3118                 data_type => 'INT',
3119             },
3120             type => {
3121                 data_type => 'INT',
3122             },
3123         );
3124         MySchema::Event->set_primary_key ('sequence');
3125
3126     # This will get back the latest event for every location. The column
3127     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3128     # combo to limit the resultset
3129
3130     $rs = $schema->resultset('Event');
3131     $table = $rs->result_source->name;
3132     $latest = $rs->search (
3133         undef,
3134         { from => \ "
3135             (SELECT e1.* FROM $table e1
3136                 JOIN $table e2
3137                     ON e1.location = e2.location
3138                     AND e1.sequence < e2.sequence
3139                 WHERE e2.sequence is NULL
3140             ) me",
3141         },
3142     );
3143
3144     # Equivalent SQL (with the DBIC chunks added):
3145
3146     SELECT me.sequence, me.location, me.type FROM
3147        (SELECT e1.* FROM events e1
3148            JOIN events e2
3149                ON e1.location = e2.location
3150                AND e1.sequence < e2.sequence
3151            WHERE e2.sequence is NULL
3152        ) me;
3153
3154 =head2 for
3155
3156 =over 4
3157
3158 =item Value: ( 'update' | 'shared' )
3159
3160 =back
3161
3162 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3163 ... FOR SHARED.
3164
3165 =cut
3166
3167 1;