lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 961   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 962   @new = $self->{_attrs}{record_filter}->(@new)
 963     if exists $self->{_attrs}{record_filter};
 964   return @new;
 965 }
 966
 967 sub _collapse_result {
 968   my ($self, $as_proto, $row) = @_;
 969
 970   my @copy = @$row;
 971
 972   # 'foo'         => [ undef, 'foo' ]
 973   # 'foo.bar'     => [ 'foo', 'bar' ]
 974   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 975
 976   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 977
 978   my %collapse = %{$self->{_attrs}{collapse}||{}};
 979
 980   my @pri_index;
 981
 982   # if we're doing collapsing (has_many prefetch) we need to grab records
 983   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 984   # we know we don't have to bother.
 985
 986   # the reason for not using the collapse stuff directly is because if you
 987   # had for e.g. two artists in a row with no cds, the collapse info for
 988   # both would be NULL (undef) so you'd lose the second artist
 989
 990   # store just the index so we can check the array positions from the row
 991   # without having to contruct the full hash
 992
 993   if (keys %collapse) {
 994     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 995     foreach my $i (0 .. $#construct_as) {
 996       next if defined($construct_as[$i][0]); # only self table
 997       if (delete $pri{$construct_as[$i][1]}) {
 998         push(@pri_index, $i);
 999       }
1000       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1001     }
1002   }
1003
1004   # no need to do an if, it'll be empty if @pri_index is empty anyway
1005
1006   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1007
1008   my @const_rows;
1009
1010   do { # no need to check anything at the front, we always want the first row
1011
1012     my %const;
1013
1014     foreach my $this_as (@construct_as) {
1015       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1016     }
1017
1018     push(@const_rows, \%const);
1019
1020   } until ( # no pri_index => no collapse => drop straight out
1021       !@pri_index
1022     or
1023       do { # get another row, stash it, drop out if different PK
1024
1025         @copy = $self->cursor->next;
1026         $self->{stashed_row} = \@copy;
1027
1028         # last thing in do block, counts as true if anything doesn't match
1029
1030         # check xor defined first for NULL vs. NOT NULL then if one is
1031         # defined the other must be so check string equality
1032
1033         grep {
1034           (defined $pri_vals{$_} ^ defined $copy[$_])
1035           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1036         } @pri_index;
1037       }
1038   );
1039
1040   my $alias = $self->{attrs}{alias};
1041   my $info = [];
1042
1043   my %collapse_pos;
1044
1045   my @const_keys;
1046
1047   foreach my $const (@const_rows) {
1048     scalar @const_keys or do {
1049       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1050     };
1051     foreach my $key (@const_keys) {
1052       if (length $key) {
1053         my $target = $info;
1054         my @parts = split(/\./, $key);
1055         my $cur = '';
1056         my $data = $const->{$key};
1057         foreach my $p (@parts) {
1058           $target = $target->[1]->{$p} ||= [];
1059           $cur .= ".${p}";
1060           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1061             # collapsing at this point and on final part
1062             my $pos = $collapse_pos{$cur};
1063             CK: foreach my $ck (@ckey) {
1064               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1065                 $collapse_pos{$cur} = $data;
1066                 delete @collapse_pos{ # clear all positioning for sub-entries
1067                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1068                 };
1069                 push(@$target, []);
1070                 last CK;
1071               }
1072             }
1073           }
1074           if (exists $collapse{$cur}) {
1075             $target = $target->[-1];
1076           }
1077         }
1078         $target->[0] = $data;
1079       } else {
1080         $info->[0] = $const->{$key};
1081       }
1082     }
1083   }
1084
1085   return $info;
1086 }
1087
1088 =head2 result_source
1089
1090 =over 4
1091
1092 =item Arguments: $result_source?
1093
1094 =item Return Value: $result_source
1095
1096 =back
1097
1098 An accessor for the primary ResultSource object from which this ResultSet
1099 is derived.
1100
1101 =head2 result_class
1102
1103 =over 4
1104
1105 =item Arguments: $result_class?
1106
1107 =item Return Value: $result_class
1108
1109 =back
1110
1111 An accessor for the class to use when creating row objects. Defaults to
1112 C<< result_source->result_class >> - which in most cases is the name of the
1113 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1114
1115 Note that changing the result_class will also remove any components
1116 that were originally loaded in the source class via
1117 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1118 in the original source class will not run.
1119
1120 =cut
1121
1122 sub result_class {
1123   my ($self, $result_class) = @_;
1124   if ($result_class) {
1125     $self->ensure_class_loaded($result_class);
1126     $self->_result_class($result_class);
1127   }
1128   $self->_result_class;
1129 }
1130
1131 =head2 count
1132
1133 =over 4
1134
1135 =item Arguments: $cond, \%attrs??
1136
1137 =item Return Value: $count
1138
1139 =back
1140
1141 Performs an SQL C<COUNT> with the same query as the resultset was built
1142 with to find the number of elements. Passing arguments is equivalent to
1143 C<< $rs->search ($cond, \%attrs)->count >>
1144
1145 =cut
1146
1147 sub count {
1148   my $self = shift;
1149   return $self->search(@_)->count if @_ and defined $_[0];
1150   return scalar @{ $self->get_cache } if $self->get_cache;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153
1154   # this is a little optimization - it is faster to do the limit
1155   # adjustments in software, instead of a subquery
1156   my $rows = delete $attrs->{rows};
1157   my $offset = delete $attrs->{offset};
1158
1159   my $crs;
1160   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1161     $crs = $self->_count_subq_rs ($attrs);
1162   }
1163   else {
1164     $crs = $self->_count_rs ($attrs);
1165   }
1166   my $count = $crs->next;
1167
1168   $count -= $offset if $offset;
1169   $count = $rows if $rows and $rows < $count;
1170   $count = 0 if ($count < 0);
1171
1172   return $count;
1173 }
1174
1175 =head2 count_rs
1176
1177 =over 4
1178
1179 =item Arguments: $cond, \%attrs??
1180
1181 =item Return Value: $count_rs
1182
1183 =back
1184
1185 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1186 This can be very handy for subqueries:
1187
1188   ->search( { amount => $some_rs->count_rs->as_query } )
1189
1190 As with regular resultsets the SQL query will be executed only after
1191 the resultset is accessed via L</next> or L</all>. That would return
1192 the same single value obtainable via L</count>.
1193
1194 =cut
1195
1196 sub count_rs {
1197   my $self = shift;
1198   return $self->search(@_)->count_rs if @_;
1199
1200   # this may look like a lack of abstraction (count() does about the same)
1201   # but in fact an _rs *must* use a subquery for the limits, as the
1202   # software based limiting can not be ported if this $rs is to be used
1203   # in a subquery itself (i.e. ->as_query)
1204   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1205     return $self->_count_subq_rs;
1206   }
1207   else {
1208     return $self->_count_rs;
1209   }
1210 }
1211
1212 #
1213 # returns a ResultSetColumn object tied to the count query
1214 #
1215 sub _count_rs {
1216   my ($self, $attrs) = @_;
1217
1218   my $rsrc = $self->result_source;
1219   $attrs ||= $self->_resolved_attrs;
1220
1221   my $tmp_attrs = { %$attrs };
1222
1223   # take off any limits, record_filter is cdbi, and no point of ordering a count
1224   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1225
1226   # overwrite the selector (supplied by the storage)
1227   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1228   $tmp_attrs->{as} = 'count';
1229
1230   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1231
1232   return $tmp_rs;
1233 }
1234
1235 #
1236 # same as above but uses a subquery
1237 #
1238 sub _count_subq_rs {
1239   my ($self, $attrs) = @_;
1240
1241   my $rsrc = $self->result_source;
1242   $attrs ||= $self->_resolved_attrs_copy;
1243
1244   my $sub_attrs = { %$attrs };
1245
1246   # extra selectors do not go in the subquery and there is no point of ordering it
1247   delete $sub_attrs->{$_} for qw/collapse prefetch_select select as order_by/;
1248
1249   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1250   # clobber old group_by regardless
1251   if ( keys %{$attrs->{collapse}} ) {
1252     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1253   }
1254
1255   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1256
1257   $attrs->{from} = [{
1258     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1259   }];
1260
1261   # the subquery replaces this
1262   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1263
1264   return $self->_count_rs ($attrs);
1265 }
1266
1267
1268 sub _bool {
1269   return 1;
1270 }
1271
1272 =head2 count_literal
1273
1274 =over 4
1275
1276 =item Arguments: $sql_fragment, @bind_values
1277
1278 =item Return Value: $count
1279
1280 =back
1281
1282 Counts the results in a literal query. Equivalent to calling L</search_literal>
1283 with the passed arguments, then L</count>.
1284
1285 =cut
1286
1287 sub count_literal { shift->search_literal(@_)->count; }
1288
1289 =head2 all
1290
1291 =over 4
1292
1293 =item Arguments: none
1294
1295 =item Return Value: @objects
1296
1297 =back
1298
1299 Returns all elements in the resultset. Called implicitly if the resultset
1300 is returned in list context.
1301
1302 =cut
1303
1304 sub all {
1305   my $self = shift;
1306   if(@_) {
1307       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1308   }
1309
1310   return @{ $self->get_cache } if $self->get_cache;
1311
1312   my @obj;
1313
1314   if (keys %{$self->_resolved_attrs->{collapse}}) {
1315     # Using $self->cursor->all is really just an optimisation.
1316     # If we're collapsing has_many prefetches it probably makes
1317     # very little difference, and this is cleaner than hacking
1318     # _construct_object to survive the approach
1319     $self->cursor->reset;
1320     my @row = $self->cursor->next;
1321     while (@row) {
1322       push(@obj, $self->_construct_object(@row));
1323       @row = (exists $self->{stashed_row}
1324                ? @{delete $self->{stashed_row}}
1325                : $self->cursor->next);
1326     }
1327   } else {
1328     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1329   }
1330
1331   $self->set_cache(\@obj) if $self->{attrs}{cache};
1332   return @obj;
1333 }
1334
1335 =head2 reset
1336
1337 =over 4
1338
1339 =item Arguments: none
1340
1341 =item Return Value: $self
1342
1343 =back
1344
1345 Resets the resultset's cursor, so you can iterate through the elements again.
1346 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1347 another query.
1348
1349 =cut
1350
1351 sub reset {
1352   my ($self) = @_;
1353   delete $self->{_attrs} if exists $self->{_attrs};
1354   $self->{all_cache_position} = 0;
1355   $self->cursor->reset;
1356   return $self;
1357 }
1358
1359 =head2 first
1360
1361 =over 4
1362
1363 =item Arguments: none
1364
1365 =item Return Value: $object?
1366
1367 =back
1368
1369 Resets the resultset and returns an object for the first result (if the
1370 resultset returns anything).
1371
1372 =cut
1373
1374 sub first {
1375   return $_[0]->reset->next;
1376 }
1377
1378
1379 # _rs_update_delete
1380 #
1381 # Determines whether and what type of subquery is required for the $rs operation.
1382 # If grouping is necessary either supplies its own, or verifies the current one
1383 # After all is done delegates to the proper storage method.
1384
1385 sub _rs_update_delete {
1386   my ($self, $op, $values) = @_;
1387
1388   my $rsrc = $self->result_source;
1389
1390   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1391   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1392
1393   if ($needs_group_by_subq or $needs_subq) {
1394
1395     # make a new $rs selecting only the PKs (that's all we really need)
1396     my $attrs = $self->_resolved_attrs_copy;
1397
1398     delete $attrs->{$_} for qw/collapse select as/;
1399     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1400
1401     if ($needs_group_by_subq) {
1402       # make sure no group_by was supplied, or if there is one - make sure it matches
1403       # the columns compiled above perfectly. Anything else can not be sanely executed
1404       # on most databases so croak right then and there
1405
1406       if (my $g = $attrs->{group_by}) {
1407         my @current_group_by = map
1408           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1409           (ref $g eq 'ARRAY' ? @$g : $g );
1410
1411         if (
1412           join ("\x00", sort @current_group_by)
1413             ne
1414           join ("\x00", sort @{$attrs->{columns}} )
1415         ) {
1416           $self->throw_exception (
1417             "You have just attempted a $op operation on a resultset which does group_by"
1418             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1419             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1420             . ' kind of queries. Please retry the operation with a modified group_by or'
1421             . ' without using one at all.'
1422           );
1423         }
1424       }
1425       else {
1426         $attrs->{group_by} = $attrs->{columns};
1427       }
1428     }
1429
1430     my $subrs = (ref $self)->new($rsrc, $attrs);
1431
1432     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1433   }
1434   else {
1435     return $rsrc->storage->$op(
1436       $rsrc,
1437       $op eq 'update' ? $values : (),
1438       $self->_cond_for_update_delete,
1439     );
1440   }
1441 }
1442
1443
1444 # _cond_for_update_delete
1445 #
1446 # update/delete require the condition to be modified to handle
1447 # the differing SQL syntax available.  This transforms the $self->{cond}
1448 # appropriately, returning the new condition.
1449
1450 sub _cond_for_update_delete {
1451   my ($self, $full_cond) = @_;
1452   my $cond = {};
1453
1454   $full_cond ||= $self->{cond};
1455   # No-op. No condition, we're updating/deleting everything
1456   return $cond unless ref $full_cond;
1457
1458   if (ref $full_cond eq 'ARRAY') {
1459     $cond = [
1460       map {
1461         my %hash;
1462         foreach my $key (keys %{$_}) {
1463           $key =~ /([^.]+)$/;
1464           $hash{$1} = $_->{$key};
1465         }
1466         \%hash;
1467       } @{$full_cond}
1468     ];
1469   }
1470   elsif (ref $full_cond eq 'HASH') {
1471     if ((keys %{$full_cond})[0] eq '-and') {
1472       $cond->{-and} = [];
1473       my @cond = @{$full_cond->{-and}};
1474        for (my $i = 0; $i < @cond; $i++) {
1475         my $entry = $cond[$i];
1476         my $hash;
1477         if (ref $entry eq 'HASH') {
1478           $hash = $self->_cond_for_update_delete($entry);
1479         }
1480         else {
1481           $entry =~ /([^.]+)$/;
1482           $hash->{$1} = $cond[++$i];
1483         }
1484         push @{$cond->{-and}}, $hash;
1485       }
1486     }
1487     else {
1488       foreach my $key (keys %{$full_cond}) {
1489         $key =~ /([^.]+)$/;
1490         $cond->{$1} = $full_cond->{$key};
1491       }
1492     }
1493   }
1494   else {
1495     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1496   }
1497
1498   return $cond;
1499 }
1500
1501
1502 =head2 update
1503
1504 =over 4
1505
1506 =item Arguments: \%values
1507
1508 =item Return Value: $storage_rv
1509
1510 =back
1511
1512 Sets the specified columns in the resultset to the supplied values in a
1513 single query. Return value will be true if the update succeeded or false
1514 if no records were updated; exact type of success value is storage-dependent.
1515
1516 =cut
1517
1518 sub update {
1519   my ($self, $values) = @_;
1520   $self->throw_exception('Values for update must be a hash')
1521     unless ref $values eq 'HASH';
1522
1523   return $self->_rs_update_delete ('update', $values);
1524 }
1525
1526 =head2 update_all
1527
1528 =over 4
1529
1530 =item Arguments: \%values
1531
1532 =item Return Value: 1
1533
1534 =back
1535
1536 Fetches all objects and updates them one at a time. Note that C<update_all>
1537 will run DBIC cascade triggers, while L</update> will not.
1538
1539 =cut
1540
1541 sub update_all {
1542   my ($self, $values) = @_;
1543   $self->throw_exception('Values for update_all must be a hash')
1544     unless ref $values eq 'HASH';
1545   foreach my $obj ($self->all) {
1546     $obj->set_columns($values)->update;
1547   }
1548   return 1;
1549 }
1550
1551 =head2 delete
1552
1553 =over 4
1554
1555 =item Arguments: none
1556
1557 =item Return Value: $storage_rv
1558
1559 =back
1560
1561 Deletes the contents of the resultset from its result source. Note that this
1562 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1563 to run. See also L<DBIx::Class::Row/delete>.
1564
1565 Return value will be the amount of rows deleted; exact type of return value
1566 is storage-dependent.
1567
1568 =cut
1569
1570 sub delete {
1571   my $self = shift;
1572   $self->throw_exception('delete does not accept any arguments')
1573     if @_;
1574
1575   return $self->_rs_update_delete ('delete');
1576 }
1577
1578 =head2 delete_all
1579
1580 =over 4
1581
1582 =item Arguments: none
1583
1584 =item Return Value: 1
1585
1586 =back
1587
1588 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1589 will run DBIC cascade triggers, while L</delete> will not.
1590
1591 =cut
1592
1593 sub delete_all {
1594   my $self = shift;
1595   $self->throw_exception('delete_all does not accept any arguments')
1596     if @_;
1597
1598   $_->delete for $self->all;
1599   return 1;
1600 }
1601
1602 =head2 populate
1603
1604 =over 4
1605
1606 =item Arguments: \@data;
1607
1608 =back
1609
1610 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1611 For the arrayref of hashrefs style each hashref should be a structure suitable
1612 forsubmitting to a $resultset->create(...) method.
1613
1614 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1615 to insert the data, as this is a faster method.
1616
1617 Otherwise, each set of data is inserted into the database using
1618 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1619 accumulated into an array. The array itself, or an array reference
1620 is returned depending on scalar or list context.
1621
1622 Example:  Assuming an Artist Class that has many CDs Classes relating:
1623
1624   my $Artist_rs = $schema->resultset("Artist");
1625
1626   ## Void Context Example
1627   $Artist_rs->populate([
1628      { artistid => 4, name => 'Manufactured Crap', cds => [
1629         { title => 'My First CD', year => 2006 },
1630         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1631       ],
1632      },
1633      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1634         { title => 'My parents sold me to a record company' ,year => 2005 },
1635         { title => 'Why Am I So Ugly?', year => 2006 },
1636         { title => 'I Got Surgery and am now Popular', year => 2007 }
1637       ],
1638      },
1639   ]);
1640
1641   ## Array Context Example
1642   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1643     { name => "Artist One"},
1644     { name => "Artist Two"},
1645     { name => "Artist Three", cds=> [
1646     { title => "First CD", year => 2007},
1647     { title => "Second CD", year => 2008},
1648   ]}
1649   ]);
1650
1651   print $ArtistOne->name; ## response is 'Artist One'
1652   print $ArtistThree->cds->count ## reponse is '2'
1653
1654 For the arrayref of arrayrefs style,  the first element should be a list of the
1655 fieldsnames to which the remaining elements are rows being inserted.  For
1656 example:
1657
1658   $Arstist_rs->populate([
1659     [qw/artistid name/],
1660     [100, 'A Formally Unknown Singer'],
1661     [101, 'A singer that jumped the shark two albums ago'],
1662     [102, 'An actually cool singer.'],
1663   ]);
1664
1665 Please note an important effect on your data when choosing between void and
1666 wantarray context. Since void context goes straight to C<insert_bulk> in
1667 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1668 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1669 create primary keys for you, you will find that your PKs are empty.  In this
1670 case you will have to use the wantarray context in order to create those
1671 values.
1672
1673 =cut
1674
1675 sub populate {
1676   my $self = shift @_;
1677   my $data = ref $_[0][0] eq 'HASH'
1678     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1679     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1680
1681   if(defined wantarray) {
1682     my @created;
1683     foreach my $item (@$data) {
1684       push(@created, $self->create($item));
1685     }
1686     return wantarray ? @created : \@created;
1687   } else {
1688     my ($first, @rest) = @$data;
1689
1690     my @names = grep {!ref $first->{$_}} keys %$first;
1691     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1692     my @pks = $self->result_source->primary_columns;
1693
1694     ## do the belongs_to relationships
1695     foreach my $index (0..$#$data) {
1696
1697       # delegate to create() for any dataset without primary keys with specified relationships
1698       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1699         for my $r (@rels) {
1700           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1701             my @ret = $self->populate($data);
1702             return;
1703           }
1704         }
1705       }
1706
1707       foreach my $rel (@rels) {
1708         next unless ref $data->[$index]->{$rel} eq "HASH";
1709         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1710         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1711         my $related = $result->result_source->_resolve_condition(
1712           $result->result_source->relationship_info($reverse)->{cond},
1713           $self,
1714           $result,
1715         );
1716
1717         delete $data->[$index]->{$rel};
1718         $data->[$index] = {%{$data->[$index]}, %$related};
1719
1720         push @names, keys %$related if $index == 0;
1721       }
1722     }
1723
1724     ## do bulk insert on current row
1725     my @values = map { [ @$_{@names} ] } @$data;
1726
1727     $self->result_source->storage->insert_bulk(
1728       $self->result_source,
1729       \@names,
1730       \@values,
1731     );
1732
1733     ## do the has_many relationships
1734     foreach my $item (@$data) {
1735
1736       foreach my $rel (@rels) {
1737         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1738
1739         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1740      || $self->throw_exception('Cannot find the relating object.');
1741
1742         my $child = $parent->$rel;
1743
1744         my $related = $child->result_source->_resolve_condition(
1745           $parent->result_source->relationship_info($rel)->{cond},
1746           $child,
1747           $parent,
1748         );
1749
1750         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1751         my @populate = map { {%$_, %$related} } @rows_to_add;
1752
1753         $child->populate( \@populate );
1754       }
1755     }
1756   }
1757 }
1758
1759 =head2 _normalize_populate_args ($args)
1760
1761 Private method used by L</populate> to normalize its incoming arguments.  Factored
1762 out in case you want to subclass and accept new argument structures to the
1763 L</populate> method.
1764
1765 =cut
1766
1767 sub _normalize_populate_args {
1768   my ($self, $data) = @_;
1769   my @names = @{shift(@$data)};
1770   my @results_to_create;
1771   foreach my $datum (@$data) {
1772     my %result_to_create;
1773     foreach my $index (0..$#names) {
1774       $result_to_create{$names[$index]} = $$datum[$index];
1775     }
1776     push @results_to_create, \%result_to_create;
1777   }
1778   return \@results_to_create;
1779 }
1780
1781 =head2 pager
1782
1783 =over 4
1784
1785 =item Arguments: none
1786
1787 =item Return Value: $pager
1788
1789 =back
1790
1791 Return Value a L<Data::Page> object for the current resultset. Only makes
1792 sense for queries with a C<page> attribute.
1793
1794 To get the full count of entries for a paged resultset, call
1795 C<total_entries> on the L<Data::Page> object.
1796
1797 =cut
1798
1799 sub pager {
1800   my ($self) = @_;
1801
1802   return $self->{pager} if $self->{pager};
1803
1804   my $attrs = $self->{attrs};
1805   $self->throw_exception("Can't create pager for non-paged rs")
1806     unless $self->{attrs}{page};
1807   $attrs->{rows} ||= 10;
1808
1809   # throw away the paging flags and re-run the count (possibly
1810   # with a subselect) to get the real total count
1811   my $count_attrs = { %$attrs };
1812   delete $count_attrs->{$_} for qw/rows offset page pager/;
1813   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1814
1815   return $self->{pager} = Data::Page->new(
1816     $total_count,
1817     $attrs->{rows},
1818     $self->{attrs}{page}
1819   );
1820 }
1821
1822 =head2 page
1823
1824 =over 4
1825
1826 =item Arguments: $page_number
1827
1828 =item Return Value: $rs
1829
1830 =back
1831
1832 Returns a resultset for the $page_number page of the resultset on which page
1833 is called, where each page contains a number of rows equal to the 'rows'
1834 attribute set on the resultset (10 by default).
1835
1836 =cut
1837
1838 sub page {
1839   my ($self, $page) = @_;
1840   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1841 }
1842
1843 =head2 new_result
1844
1845 =over 4
1846
1847 =item Arguments: \%vals
1848
1849 =item Return Value: $rowobject
1850
1851 =back
1852
1853 Creates a new row object in the resultset's result class and returns
1854 it. The row is not inserted into the database at this point, call
1855 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1856 will tell you whether the row object has been inserted or not.
1857
1858 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1859
1860 =cut
1861
1862 sub new_result {
1863   my ($self, $values) = @_;
1864   $self->throw_exception( "new_result needs a hash" )
1865     unless (ref $values eq 'HASH');
1866
1867   my %new;
1868   my $alias = $self->{attrs}{alias};
1869
1870   if (
1871     defined $self->{cond}
1872     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1873   ) {
1874     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1875     $new{-from_resultset} = [ keys %new ] if keys %new;
1876   } else {
1877     $self->throw_exception(
1878       "Can't abstract implicit construct, condition not a hash"
1879     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1880
1881     my $collapsed_cond = (
1882       $self->{cond}
1883         ? $self->_collapse_cond($self->{cond})
1884         : {}
1885     );
1886
1887     # precendence must be given to passed values over values inherited from
1888     # the cond, so the order here is important.
1889     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1890     while( my($col,$value) = each %implied ){
1891       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1892         $new{$col} = $value->{'='};
1893         next;
1894       }
1895       $new{$col} = $value if $self->_is_deterministic_value($value);
1896     }
1897   }
1898
1899   %new = (
1900     %new,
1901     %{ $self->_remove_alias($values, $alias) },
1902     -source_handle => $self->_source_handle,
1903     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1904   );
1905
1906   return $self->result_class->new(\%new);
1907 }
1908
1909 # _is_deterministic_value
1910 #
1911 # Make an effor to strip non-deterministic values from the condition,
1912 # to make sure new_result chokes less
1913
1914 sub _is_deterministic_value {
1915   my $self = shift;
1916   my $value = shift;
1917   my $ref_type = ref $value;
1918   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1919   return 1 if Scalar::Util::blessed($value);
1920   return 0;
1921 }
1922
1923 # _has_resolved_attr
1924 #
1925 # determines if the resultset defines at least one
1926 # of the attributes supplied
1927 #
1928 # used to determine if a subquery is neccessary
1929
1930 sub _has_resolved_attr {
1931   my ($self, @attr_names) = @_;
1932
1933   my $attrs = $self->_resolved_attrs;
1934
1935   my $join_check_req;
1936
1937   for my $n (@attr_names) {
1938     ++$join_check_req if $n eq '-join';
1939
1940     my $attr =  $attrs->{$n};
1941
1942     next if not defined $attr;
1943
1944     if (ref $attr eq 'HASH') {
1945       return 1 if keys %$attr;
1946     }
1947     elsif (ref $attr eq 'ARRAY') {
1948       return 1 if @$attr;
1949     }
1950     else {
1951       return 1 if $attr;
1952     }
1953   }
1954
1955   # a resolved join is expressed as a multi-level from
1956   return 1 if (
1957     $join_check_req
1958       and
1959     ref $attrs->{from} eq 'ARRAY'
1960       and
1961     @{$attrs->{from}} > 1
1962   );
1963
1964   return 0;
1965 }
1966
1967 # _collapse_cond
1968 #
1969 # Recursively collapse the condition.
1970
1971 sub _collapse_cond {
1972   my ($self, $cond, $collapsed) = @_;
1973
1974   $collapsed ||= {};
1975
1976   if (ref $cond eq 'ARRAY') {
1977     foreach my $subcond (@$cond) {
1978       next unless ref $subcond;  # -or
1979       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1980     }
1981   }
1982   elsif (ref $cond eq 'HASH') {
1983     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1984       foreach my $subcond (@{$cond->{-and}}) {
1985         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1986       }
1987     }
1988     else {
1989       foreach my $col (keys %$cond) {
1990         my $value = $cond->{$col};
1991         $collapsed->{$col} = $value;
1992       }
1993     }
1994   }
1995
1996   return $collapsed;
1997 }
1998
1999 # _remove_alias
2000 #
2001 # Remove the specified alias from the specified query hash. A copy is made so
2002 # the original query is not modified.
2003
2004 sub _remove_alias {
2005   my ($self, $query, $alias) = @_;
2006
2007   my %orig = %{ $query || {} };
2008   my %unaliased;
2009
2010   foreach my $key (keys %orig) {
2011     if ($key !~ /\./) {
2012       $unaliased{$key} = $orig{$key};
2013       next;
2014     }
2015     $unaliased{$1} = $orig{$key}
2016       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2017   }
2018
2019   return \%unaliased;
2020 }
2021
2022 =head2 as_query (EXPERIMENTAL)
2023
2024 =over 4
2025
2026 =item Arguments: none
2027
2028 =item Return Value: \[ $sql, @bind ]
2029
2030 =back
2031
2032 Returns the SQL query and bind vars associated with the invocant.
2033
2034 This is generally used as the RHS for a subquery.
2035
2036 B<NOTE>: This feature is still experimental.
2037
2038 =cut
2039
2040 sub as_query {
2041   my $self = shift;
2042
2043   my $attrs = $self->_resolved_attrs_copy;
2044
2045   # For future use:
2046   #
2047   # in list ctx:
2048   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2049   # $sql also has no wrapping parenthesis in list ctx
2050   #
2051   my $sqlbind = $self->result_source->storage
2052     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2053
2054   return $sqlbind;
2055 }
2056
2057 =head2 find_or_new
2058
2059 =over 4
2060
2061 =item Arguments: \%vals, \%attrs?
2062
2063 =item Return Value: $rowobject
2064
2065 =back
2066
2067   my $artist = $schema->resultset('Artist')->find_or_new(
2068     { artist => 'fred' }, { key => 'artists' });
2069
2070   $cd->cd_to_producer->find_or_new({ producer => $producer },
2071                                    { key => 'primary });
2072
2073 Find an existing record from this resultset, based on its primary
2074 key, or a unique constraint. If none exists, instantiate a new result
2075 object and return it. The object will not be saved into your storage
2076 until you call L<DBIx::Class::Row/insert> on it.
2077
2078 You most likely want this method when looking for existing rows using
2079 a unique constraint that is not the primary key, or looking for
2080 related rows.
2081
2082 If you want objects to be saved immediately, use L</find_or_create> instead.
2083
2084 B<Note>: C<find_or_new> is probably not what you want when creating a
2085 new row in a table that uses primary keys supplied by the
2086 database. Passing in a primary key column with a value of I<undef>
2087 will cause L</find> to attempt to search for a row with a value of
2088 I<NULL>.
2089
2090 =cut
2091
2092 sub find_or_new {
2093   my $self     = shift;
2094   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2095   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2096   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2097     return $row;
2098   }
2099   return $self->new_result($hash);
2100 }
2101
2102 =head2 create
2103
2104 =over 4
2105
2106 =item Arguments: \%vals
2107
2108 =item Return Value: a L<DBIx::Class::Row> $object
2109
2110 =back
2111
2112 Attempt to create a single new row or a row with multiple related rows
2113 in the table represented by the resultset (and related tables). This
2114 will not check for duplicate rows before inserting, use
2115 L</find_or_create> to do that.
2116
2117 To create one row for this resultset, pass a hashref of key/value
2118 pairs representing the columns of the table and the values you wish to
2119 store. If the appropriate relationships are set up, foreign key fields
2120 can also be passed an object representing the foreign row, and the
2121 value will be set to its primary key.
2122
2123 To create related objects, pass a hashref for the value if the related
2124 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2125 and use the name of the relationship as the key. (NOT the name of the field,
2126 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2127 of hashrefs containing the data for each of the rows to create in the foreign
2128 tables, again using the relationship name as the key.
2129
2130 Instead of hashrefs of plain related data (key/value pairs), you may
2131 also pass new or inserted objects. New objects (not inserted yet, see
2132 L</new>), will be inserted into their appropriate tables.
2133
2134 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2135
2136 Example of creating a new row.
2137
2138   $person_rs->create({
2139     name=>"Some Person",
2140     email=>"somebody@someplace.com"
2141   });
2142
2143 Example of creating a new row and also creating rows in a related C<has_many>
2144 or C<has_one> resultset.  Note Arrayref.
2145
2146   $artist_rs->create(
2147      { artistid => 4, name => 'Manufactured Crap', cds => [
2148         { title => 'My First CD', year => 2006 },
2149         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2150       ],
2151      },
2152   );
2153
2154 Example of creating a new row and also creating a row in a related
2155 C<belongs_to>resultset. Note Hashref.
2156
2157   $cd_rs->create({
2158     title=>"Music for Silly Walks",
2159     year=>2000,
2160     artist => {
2161       name=>"Silly Musician",
2162     }
2163   });
2164
2165 =cut
2166
2167 sub create {
2168   my ($self, $attrs) = @_;
2169   $self->throw_exception( "create needs a hashref" )
2170     unless ref $attrs eq 'HASH';
2171   return $self->new_result($attrs)->insert;
2172 }
2173
2174 =head2 find_or_create
2175
2176 =over 4
2177
2178 =item Arguments: \%vals, \%attrs?
2179
2180 =item Return Value: $rowobject
2181
2182 =back
2183
2184   $cd->cd_to_producer->find_or_create({ producer => $producer },
2185                                       { key => 'primary' });
2186
2187 Tries to find a record based on its primary key or unique constraints; if none
2188 is found, creates one and returns that instead.
2189
2190   my $cd = $schema->resultset('CD')->find_or_create({
2191     cdid   => 5,
2192     artist => 'Massive Attack',
2193     title  => 'Mezzanine',
2194     year   => 2005,
2195   });
2196
2197 Also takes an optional C<key> attribute, to search by a specific key or unique
2198 constraint. For example:
2199
2200   my $cd = $schema->resultset('CD')->find_or_create(
2201     {
2202       artist => 'Massive Attack',
2203       title  => 'Mezzanine',
2204     },
2205     { key => 'cd_artist_title' }
2206   );
2207
2208 B<Note>: Because find_or_create() reads from the database and then
2209 possibly inserts based on the result, this method is subject to a race
2210 condition. Another process could create a record in the table after
2211 the find has completed and before the create has started. To avoid
2212 this problem, use find_or_create() inside a transaction.
2213
2214 B<Note>: C<find_or_create> is probably not what you want when creating
2215 a new row in a table that uses primary keys supplied by the
2216 database. Passing in a primary key column with a value of I<undef>
2217 will cause L</find> to attempt to search for a row with a value of
2218 I<NULL>.
2219
2220 See also L</find> and L</update_or_create>. For information on how to declare
2221 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2222
2223 =cut
2224
2225 sub find_or_create {
2226   my $self     = shift;
2227   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2228   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2229   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2230     return $row;
2231   }
2232   return $self->create($hash);
2233 }
2234
2235 =head2 update_or_create
2236
2237 =over 4
2238
2239 =item Arguments: \%col_values, { key => $unique_constraint }?
2240
2241 =item Return Value: $rowobject
2242
2243 =back
2244
2245   $resultset->update_or_create({ col => $val, ... });
2246
2247 First, searches for an existing row matching one of the unique constraints
2248 (including the primary key) on the source of this resultset. If a row is
2249 found, updates it with the other given column values. Otherwise, creates a new
2250 row.
2251
2252 Takes an optional C<key> attribute to search on a specific unique constraint.
2253 For example:
2254
2255   # In your application
2256   my $cd = $schema->resultset('CD')->update_or_create(
2257     {
2258       artist => 'Massive Attack',
2259       title  => 'Mezzanine',
2260       year   => 1998,
2261     },
2262     { key => 'cd_artist_title' }
2263   );
2264
2265   $cd->cd_to_producer->update_or_create({
2266     producer => $producer,
2267     name => 'harry',
2268   }, {
2269     key => 'primary,
2270   });
2271
2272
2273 If no C<key> is specified, it searches on all unique constraints defined on the
2274 source, including the primary key.
2275
2276 If the C<key> is specified as C<primary>, it searches only on the primary key.
2277
2278 See also L</find> and L</find_or_create>. For information on how to declare
2279 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2280
2281 B<Note>: C<update_or_create> is probably not what you want when
2282 looking for a row in a table that uses primary keys supplied by the
2283 database, unless you actually have a key value. Passing in a primary
2284 key column with a value of I<undef> will cause L</find> to attempt to
2285 search for a row with a value of I<NULL>.
2286
2287 =cut
2288
2289 sub update_or_create {
2290   my $self = shift;
2291   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2292   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2293
2294   my $row = $self->find($cond, $attrs);
2295   if (defined $row) {
2296     $row->update($cond);
2297     return $row;
2298   }
2299
2300   return $self->create($cond);
2301 }
2302
2303 =head2 update_or_new
2304
2305 =over 4
2306
2307 =item Arguments: \%col_values, { key => $unique_constraint }?
2308
2309 =item Return Value: $rowobject
2310
2311 =back
2312
2313   $resultset->update_or_new({ col => $val, ... });
2314
2315 First, searches for an existing row matching one of the unique constraints
2316 (including the primary key) on the source of this resultset. If a row is
2317 found, updates it with the other given column values. Otherwise, instantiate
2318 a new result object and return it. The object will not be saved into your storage
2319 until you call L<DBIx::Class::Row/insert> on it.
2320
2321 Takes an optional C<key> attribute to search on a specific unique constraint.
2322 For example:
2323
2324   # In your application
2325   my $cd = $schema->resultset('CD')->update_or_new(
2326     {
2327       artist => 'Massive Attack',
2328       title  => 'Mezzanine',
2329       year   => 1998,
2330     },
2331     { key => 'cd_artist_title' }
2332   );
2333
2334   if ($cd->in_storage) {
2335       # the cd was updated
2336   }
2337   else {
2338       # the cd is not yet in the database, let's insert it
2339       $cd->insert;
2340   }
2341
2342 See also L</find>, L</find_or_create> and L<find_or_new>.
2343
2344 =cut
2345
2346 sub update_or_new {
2347     my $self  = shift;
2348     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2349     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2350
2351     my $row = $self->find( $cond, $attrs );
2352     if ( defined $row ) {
2353         $row->update($cond);
2354         return $row;
2355     }
2356
2357     return $self->new_result($cond);
2358 }
2359
2360 =head2 get_cache
2361
2362 =over 4
2363
2364 =item Arguments: none
2365
2366 =item Return Value: \@cache_objects?
2367
2368 =back
2369
2370 Gets the contents of the cache for the resultset, if the cache is set.
2371
2372 The cache is populated either by using the L</prefetch> attribute to
2373 L</search> or by calling L</set_cache>.
2374
2375 =cut
2376
2377 sub get_cache {
2378   shift->{all_cache};
2379 }
2380
2381 =head2 set_cache
2382
2383 =over 4
2384
2385 =item Arguments: \@cache_objects
2386
2387 =item Return Value: \@cache_objects
2388
2389 =back
2390
2391 Sets the contents of the cache for the resultset. Expects an arrayref
2392 of objects of the same class as those produced by the resultset. Note that
2393 if the cache is set the resultset will return the cached objects rather
2394 than re-querying the database even if the cache attr is not set.
2395
2396 The contents of the cache can also be populated by using the
2397 L</prefetch> attribute to L</search>.
2398
2399 =cut
2400
2401 sub set_cache {
2402   my ( $self, $data ) = @_;
2403   $self->throw_exception("set_cache requires an arrayref")
2404       if defined($data) && (ref $data ne 'ARRAY');
2405   $self->{all_cache} = $data;
2406 }
2407
2408 =head2 clear_cache
2409
2410 =over 4
2411
2412 =item Arguments: none
2413
2414 =item Return Value: []
2415
2416 =back
2417
2418 Clears the cache for the resultset.
2419
2420 =cut
2421
2422 sub clear_cache {
2423   shift->set_cache(undef);
2424 }
2425
2426 =head2 related_resultset
2427
2428 =over 4
2429
2430 =item Arguments: $relationship_name
2431
2432 =item Return Value: $resultset
2433
2434 =back
2435
2436 Returns a related resultset for the supplied relationship name.
2437
2438   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2439
2440 =cut
2441
2442 sub related_resultset {
2443   my ($self, $rel) = @_;
2444
2445   $self->{related_resultsets} ||= {};
2446   return $self->{related_resultsets}{$rel} ||= do {
2447     my $rel_info = $self->result_source->relationship_info($rel);
2448
2449     $self->throw_exception(
2450       "search_related: result source '" . $self->result_source->source_name .
2451         "' has no such relationship $rel")
2452       unless $rel_info;
2453
2454     my ($from,$seen) = $self->_chain_relationship($rel);
2455
2456     my $join_count = $seen->{$rel};
2457     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2458
2459     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2460     my %attrs = %{$self->{attrs}||{}};
2461     delete @attrs{qw(result_class alias)};
2462
2463     my $new_cache;
2464
2465     if (my $cache = $self->get_cache) {
2466       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2467         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2468                         @$cache ];
2469       }
2470     }
2471
2472     my $rel_source = $self->result_source->related_source($rel);
2473
2474     my $new = do {
2475
2476       # The reason we do this now instead of passing the alias to the
2477       # search_rs below is that if you wrap/overload resultset on the
2478       # source you need to know what alias it's -going- to have for things
2479       # to work sanely (e.g. RestrictWithObject wants to be able to add
2480       # extra query restrictions, and these may need to be $alias.)
2481
2482       my $attrs = $rel_source->resultset_attributes;
2483       local $attrs->{alias} = $alias;
2484
2485       $rel_source->resultset
2486                  ->search_rs(
2487                      undef, {
2488                        %attrs,
2489                        join => undef,
2490                        prefetch => undef,
2491                        select => undef,
2492                        as => undef,
2493                        where => $self->{cond},
2494                        seen_join => $seen,
2495                        from => $from,
2496                    });
2497     };
2498     $new->set_cache($new_cache) if $new_cache;
2499     $new;
2500   };
2501 }
2502
2503 =head2 current_source_alias
2504
2505 =over 4
2506
2507 =item Arguments: none
2508
2509 =item Return Value: $source_alias
2510
2511 =back
2512
2513 Returns the current table alias for the result source this resultset is built
2514 on, that will be used in the SQL query. Usually it is C<me>.
2515
2516 Currently the source alias that refers to the result set returned by a
2517 L</search>/L</find> family method depends on how you got to the resultset: it's
2518 C<me> by default, but eg. L</search_related> aliases it to the related result
2519 source name (and keeps C<me> referring to the original result set). The long
2520 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2521 (and make this method unnecessary).
2522
2523 Thus it's currently necessary to use this method in predefined queries (see
2524 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2525 source alias of the current result set:
2526
2527   # in a result set class
2528   sub modified_by {
2529     my ($self, $user) = @_;
2530
2531     my $me = $self->current_source_alias;
2532
2533     return $self->search(
2534       "$me.modified" => $user->id,
2535     );
2536   }
2537
2538 =cut
2539
2540 sub current_source_alias {
2541   my ($self) = @_;
2542
2543   return ($self->{attrs} || {})->{alias} || 'me';
2544 }
2545
2546 # This code is called by search_related, and makes sure there
2547 # is clear separation between the joins before, during, and
2548 # after the relationship. This information is needed later
2549 # in order to properly resolve prefetch aliases (any alias
2550 # with a relation_chain_depth less than the depth of the
2551 # current prefetch is not considered)
2552 sub _chain_relationship {
2553   my ($self, $rel) = @_;
2554   my $source = $self->result_source;
2555   my $attrs = $self->{attrs};
2556
2557   my $from = [ @{
2558       $attrs->{from}
2559         ||
2560       [{
2561         -source_handle => $source->handle,
2562         -alias => $attrs->{alias},
2563         $attrs->{alias} => $source->from,
2564       }]
2565   }];
2566
2567   my $seen = { %{$attrs->{seen_join} || {} } };
2568
2569   # we need to take the prefetch the attrs into account before we
2570   # ->_resolve_join as otherwise they get lost - captainL
2571   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2572
2573   my @requested_joins = $source->_resolve_join($merged, $attrs->{alias}, $seen);
2574
2575   push @$from, @requested_joins;
2576
2577   ++$seen->{-relation_chain_depth};
2578
2579   # if $self already had a join/prefetch specified on it, the requested
2580   # $rel might very well be already included. What we do in this case
2581   # is effectively a no-op (except that we bump up the chain_depth on
2582   # the join in question so we could tell it *is* the search_related)
2583   my $already_joined;
2584
2585   # we consider the last one thus reverse
2586   for my $j (reverse @requested_joins) {
2587     if ($rel eq $j->[0]{-join_path}[-1]) {
2588       $j->[0]{-relation_chain_depth}++;
2589       $already_joined++;
2590       last;
2591     }
2592   }
2593   unless ($already_joined) {
2594     push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2595   }
2596
2597   ++$seen->{-relation_chain_depth};
2598
2599   return ($from,$seen);
2600 }
2601
2602 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2603 sub _resolved_attrs_copy {
2604   my $self = shift;
2605   return { %{$self->_resolved_attrs (@_)} };
2606 }
2607
2608 sub _resolved_attrs {
2609   my $self = shift;
2610   return $self->{_attrs} if $self->{_attrs};
2611
2612   my $attrs  = { %{ $self->{attrs} || {} } };
2613   my $source = $self->result_source;
2614   my $alias  = $attrs->{alias};
2615
2616   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2617   my @colbits;
2618
2619   # build columns (as long as select isn't set) into a set of as/select hashes
2620   unless ( $attrs->{select} ) {
2621       @colbits = map {
2622           ( ref($_) eq 'HASH' )
2623               ? $_
2624               : {
2625                   (
2626                     /^\Q${alias}.\E(.+)$/
2627                       ? "$1"
2628                       : "$_"
2629                   )
2630                 =>
2631                   (
2632                     /\./
2633                       ? "$_"
2634                       : "${alias}.$_"
2635                   )
2636             }
2637       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2638   }
2639   # add the additional columns on
2640   foreach ( 'include_columns', '+columns' ) {
2641       push @colbits, map {
2642           ( ref($_) eq 'HASH' )
2643             ? $_
2644             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2645       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2646   }
2647
2648   # start with initial select items
2649   if ( $attrs->{select} ) {
2650     $attrs->{select} =
2651         ( ref $attrs->{select} eq 'ARRAY' )
2652       ? [ @{ $attrs->{select} } ]
2653       : [ $attrs->{select} ];
2654     $attrs->{as} = (
2655       $attrs->{as}
2656       ? (
2657         ref $attrs->{as} eq 'ARRAY'
2658         ? [ @{ $attrs->{as} } ]
2659         : [ $attrs->{as} ]
2660         )
2661       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2662     );
2663   }
2664   else {
2665
2666     # otherwise we intialise select & as to empty
2667     $attrs->{select} = [];
2668     $attrs->{as}     = [];
2669   }
2670
2671   # now add colbits to select/as
2672   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2673   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2674
2675   my $adds;
2676   if ( $adds = delete $attrs->{'+select'} ) {
2677     $adds = [$adds] unless ref $adds eq 'ARRAY';
2678     push(
2679       @{ $attrs->{select} },
2680       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2681     );
2682   }
2683   if ( $adds = delete $attrs->{'+as'} ) {
2684     $adds = [$adds] unless ref $adds eq 'ARRAY';
2685     push( @{ $attrs->{as} }, @$adds );
2686   }
2687
2688   $attrs->{from} ||= [ {
2689     -source_handle => $source->handle,
2690     -alias => $self->{attrs}{alias},
2691     $self->{attrs}{alias} => $source->from,
2692   } ];
2693
2694   if ( $attrs->{join} || $attrs->{prefetch} ) {
2695
2696     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2697       if ref $attrs->{from} ne 'ARRAY';
2698
2699     my $join = delete $attrs->{join} || {};
2700
2701     if ( defined $attrs->{prefetch} ) {
2702       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2703     }
2704
2705     $attrs->{from} =    # have to copy here to avoid corrupting the original
2706       [
2707         @{ $attrs->{from} },
2708         $source->_resolve_join(
2709           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2710         )
2711       ];
2712   }
2713
2714   if ( $attrs->{order_by} ) {
2715     $attrs->{order_by} = (
2716       ref( $attrs->{order_by} ) eq 'ARRAY'
2717       ? [ @{ $attrs->{order_by} } ]
2718       : [ $attrs->{order_by} ]
2719     );
2720   }
2721
2722   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2723     $attrs->{group_by} = [ $attrs->{group_by} ];
2724   }
2725
2726   # If the order_by is otherwise empty - we will use this for TOP limit
2727   # emulation and the like.
2728   # Although this is needed only if the order_by is not defined, it is
2729   # actually cheaper to just populate this rather than properly examining
2730   # order_by (stuf like [ {} ] and the like)
2731   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2732
2733
2734   $attrs->{collapse} ||= {};
2735   if ( my $prefetch = delete $attrs->{prefetch} ) {
2736     $prefetch = $self->_merge_attr( {}, $prefetch );
2737
2738     my $prefetch_ordering = [];
2739
2740     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2741
2742     my @prefetch =
2743       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2744
2745     $attrs->{prefetch_select} = [ map { $_->[0] } @prefetch ];
2746     push @{ $attrs->{select} }, @{$attrs->{prefetch_select}};
2747     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2748
2749     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2750     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2751   }
2752
2753
2754   if (delete $attrs->{distinct}) {
2755     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2756   }
2757
2758   # if both page and offset are specified, produce a combined offset
2759   # even though it doesn't make much sense, this is what pre 081xx has
2760   # been doing
2761   if (my $page = delete $attrs->{page}) {
2762     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2763       ($attrs->{offset} || 0);
2764   }
2765
2766   return $self->{_attrs} = $attrs;
2767 }
2768
2769 sub _joinpath_aliases {
2770   my ($self, $fromspec, $seen) = @_;
2771
2772   my $paths = {};
2773   return $paths unless ref $fromspec eq 'ARRAY';
2774
2775   for my $j (@$fromspec) {
2776
2777     next if ref $j ne 'ARRAY';
2778     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2779
2780     my $p = $paths;
2781     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2782     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2783   }
2784
2785   return $paths;
2786 }
2787
2788 sub _rollout_attr {
2789   my ($self, $attr) = @_;
2790
2791   if (ref $attr eq 'HASH') {
2792     return $self->_rollout_hash($attr);
2793   } elsif (ref $attr eq 'ARRAY') {
2794     return $self->_rollout_array($attr);
2795   } else {
2796     return [$attr];
2797   }
2798 }
2799
2800 sub _rollout_array {
2801   my ($self, $attr) = @_;
2802
2803   my @rolled_array;
2804   foreach my $element (@{$attr}) {
2805     if (ref $element eq 'HASH') {
2806       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2807     } elsif (ref $element eq 'ARRAY') {
2808       #  XXX - should probably recurse here
2809       push( @rolled_array, @{$self->_rollout_array($element)} );
2810     } else {
2811       push( @rolled_array, $element );
2812     }
2813   }
2814   return \@rolled_array;
2815 }
2816
2817 sub _rollout_hash {
2818   my ($self, $attr) = @_;
2819
2820   my @rolled_array;
2821   foreach my $key (keys %{$attr}) {
2822     push( @rolled_array, { $key => $attr->{$key} } );
2823   }
2824   return \@rolled_array;
2825 }
2826
2827 sub _calculate_score {
2828   my ($self, $a, $b) = @_;
2829
2830   if (ref $b eq 'HASH') {
2831     my ($b_key) = keys %{$b};
2832     if (ref $a eq 'HASH') {
2833       my ($a_key) = keys %{$a};
2834       if ($a_key eq $b_key) {
2835         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2836       } else {
2837         return 0;
2838       }
2839     } else {
2840       return ($a eq $b_key) ? 1 : 0;
2841     }
2842   } else {
2843     if (ref $a eq 'HASH') {
2844       my ($a_key) = keys %{$a};
2845       return ($b eq $a_key) ? 1 : 0;
2846     } else {
2847       return ($b eq $a) ? 1 : 0;
2848     }
2849   }
2850 }
2851
2852 sub _merge_attr {
2853   my ($self, $orig, $import) = @_;
2854
2855   return $import unless defined($orig);
2856   return $orig unless defined($import);
2857
2858   $orig = $self->_rollout_attr($orig);
2859   $import = $self->_rollout_attr($import);
2860
2861   my $seen_keys;
2862   foreach my $import_element ( @{$import} ) {
2863     # find best candidate from $orig to merge $b_element into
2864     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2865     foreach my $orig_element ( @{$orig} ) {
2866       my $score = $self->_calculate_score( $orig_element, $import_element );
2867       if ($score > $best_candidate->{score}) {
2868         $best_candidate->{position} = $position;
2869         $best_candidate->{score} = $score;
2870       }
2871       $position++;
2872     }
2873     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2874
2875     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2876       push( @{$orig}, $import_element );
2877     } else {
2878       my $orig_best = $orig->[$best_candidate->{position}];
2879       # merge orig_best and b_element together and replace original with merged
2880       if (ref $orig_best ne 'HASH') {
2881         $orig->[$best_candidate->{position}] = $import_element;
2882       } elsif (ref $import_element eq 'HASH') {
2883         my ($key) = keys %{$orig_best};
2884         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2885       }
2886     }
2887     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2888   }
2889
2890   return $orig;
2891 }
2892
2893 sub result_source {
2894     my $self = shift;
2895
2896     if (@_) {
2897         $self->_source_handle($_[0]->handle);
2898     } else {
2899         $self->_source_handle->resolve;
2900     }
2901 }
2902
2903 =head2 throw_exception
2904
2905 See L<DBIx::Class::Schema/throw_exception> for details.
2906
2907 =cut
2908
2909 sub throw_exception {
2910   my $self=shift;
2911   if (ref $self && $self->_source_handle->schema) {
2912     $self->_source_handle->schema->throw_exception(@_)
2913   } else {
2914     croak(@_);
2915   }
2916
2917 }
2918
2919 # XXX: FIXME: Attributes docs need clearing up
2920
2921 =head1 ATTRIBUTES
2922
2923 Attributes are used to refine a ResultSet in various ways when
2924 searching for data. They can be passed to any method which takes an
2925 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2926 L</count>.
2927
2928 These are in no particular order:
2929
2930 =head2 order_by
2931
2932 =over 4
2933
2934 =item Value: ( $order_by | \@order_by | \%order_by )
2935
2936 =back
2937
2938 Which column(s) to order the results by. If a single column name, or
2939 an arrayref of names is supplied, the argument is passed through
2940 directly to SQL. The hashref syntax allows for connection-agnostic
2941 specification of ordering direction:
2942
2943  For descending order:
2944
2945   order_by => { -desc => [qw/col1 col2 col3/] }
2946
2947  For explicit ascending order:
2948
2949   order_by => { -asc => 'col' }
2950
2951 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2952 supported, although you are strongly encouraged to use the hashref
2953 syntax as outlined above.
2954
2955 =head2 columns
2956
2957 =over 4
2958
2959 =item Value: \@columns
2960
2961 =back
2962
2963 Shortcut to request a particular set of columns to be retrieved. Each
2964 column spec may be a string (a table column name), or a hash (in which
2965 case the key is the C<as> value, and the value is used as the C<select>
2966 expression). Adds C<me.> onto the start of any column without a C<.> in
2967 it and sets C<select> from that, then auto-populates C<as> from
2968 C<select> as normal. (You may also use the C<cols> attribute, as in
2969 earlier versions of DBIC.)
2970
2971 =head2 +columns
2972
2973 =over 4
2974
2975 =item Value: \@columns
2976
2977 =back
2978
2979 Indicates additional columns to be selected from storage. Works the same
2980 as L</columns> but adds columns to the selection. (You may also use the
2981 C<include_columns> attribute, as in earlier versions of DBIC). For
2982 example:-
2983
2984   $schema->resultset('CD')->search(undef, {
2985     '+columns' => ['artist.name'],
2986     join => ['artist']
2987   });
2988
2989 would return all CDs and include a 'name' column to the information
2990 passed to object inflation. Note that the 'artist' is the name of the
2991 column (or relationship) accessor, and 'name' is the name of the column
2992 accessor in the related table.
2993
2994 =head2 include_columns
2995
2996 =over 4
2997
2998 =item Value: \@columns
2999
3000 =back
3001
3002 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3003
3004 =head2 select
3005
3006 =over 4
3007
3008 =item Value: \@select_columns
3009
3010 =back
3011
3012 Indicates which columns should be selected from the storage. You can use
3013 column names, or in the case of RDBMS back ends, function or stored procedure
3014 names:
3015
3016   $rs = $schema->resultset('Employee')->search(undef, {
3017     select => [
3018       'name',
3019       { count => 'employeeid' },
3020       { sum => 'salary' }
3021     ]
3022   });
3023
3024 When you use function/stored procedure names and do not supply an C<as>
3025 attribute, the column names returned are storage-dependent. E.g. MySQL would
3026 return a column named C<count(employeeid)> in the above example.
3027
3028 =head2 +select
3029
3030 =over 4
3031
3032 Indicates additional columns to be selected from storage.  Works the same as
3033 L</select> but adds columns to the selection.
3034
3035 =back
3036
3037 =head2 +as
3038
3039 =over 4
3040
3041 Indicates additional column names for those added via L</+select>. See L</as>.
3042
3043 =back
3044
3045 =head2 as
3046
3047 =over 4
3048
3049 =item Value: \@inflation_names
3050
3051 =back
3052
3053 Indicates column names for object inflation. That is, C<as>
3054 indicates the name that the column can be accessed as via the
3055 C<get_column> method (or via the object accessor, B<if one already
3056 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3057
3058 The C<as> attribute is used in conjunction with C<select>,
3059 usually when C<select> contains one or more function or stored
3060 procedure names:
3061
3062   $rs = $schema->resultset('Employee')->search(undef, {
3063     select => [
3064       'name',
3065       { count => 'employeeid' }
3066     ],
3067     as => ['name', 'employee_count'],
3068   });
3069
3070   my $employee = $rs->first(); # get the first Employee
3071
3072 If the object against which the search is performed already has an accessor
3073 matching a column name specified in C<as>, the value can be retrieved using
3074 the accessor as normal:
3075
3076   my $name = $employee->name();
3077
3078 If on the other hand an accessor does not exist in the object, you need to
3079 use C<get_column> instead:
3080
3081   my $employee_count = $employee->get_column('employee_count');
3082
3083 You can create your own accessors if required - see
3084 L<DBIx::Class::Manual::Cookbook> for details.
3085
3086 Please note: This will NOT insert an C<AS employee_count> into the SQL
3087 statement produced, it is used for internal access only. Thus
3088 attempting to use the accessor in an C<order_by> clause or similar
3089 will fail miserably.
3090
3091 To get around this limitation, you can supply literal SQL to your
3092 C<select> attibute that contains the C<AS alias> text, eg:
3093
3094   select => [\'myfield AS alias']
3095
3096 =head2 join
3097
3098 =over 4
3099
3100 =item Value: ($rel_name | \@rel_names | \%rel_names)
3101
3102 =back
3103
3104 Contains a list of relationships that should be joined for this query.  For
3105 example:
3106
3107   # Get CDs by Nine Inch Nails
3108   my $rs = $schema->resultset('CD')->search(
3109     { 'artist.name' => 'Nine Inch Nails' },
3110     { join => 'artist' }
3111   );
3112
3113 Can also contain a hash reference to refer to the other relation's relations.
3114 For example:
3115
3116   package MyApp::Schema::Track;
3117   use base qw/DBIx::Class/;
3118   __PACKAGE__->table('track');
3119   __PACKAGE__->add_columns(qw/trackid cd position title/);
3120   __PACKAGE__->set_primary_key('trackid');
3121   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3122   1;
3123
3124   # In your application
3125   my $rs = $schema->resultset('Artist')->search(
3126     { 'track.title' => 'Teardrop' },
3127     {
3128       join     => { cd => 'track' },
3129       order_by => 'artist.name',
3130     }
3131   );
3132
3133 You need to use the relationship (not the table) name in  conditions,
3134 because they are aliased as such. The current table is aliased as "me", so
3135 you need to use me.column_name in order to avoid ambiguity. For example:
3136
3137   # Get CDs from 1984 with a 'Foo' track
3138   my $rs = $schema->resultset('CD')->search(
3139     {
3140       'me.year' => 1984,
3141       'tracks.name' => 'Foo'
3142     },
3143     { join => 'tracks' }
3144   );
3145
3146 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3147 similarly for a third time). For e.g.
3148
3149   my $rs = $schema->resultset('Artist')->search({
3150     'cds.title'   => 'Down to Earth',
3151     'cds_2.title' => 'Popular',
3152   }, {
3153     join => [ qw/cds cds/ ],
3154   });
3155
3156 will return a set of all artists that have both a cd with title 'Down
3157 to Earth' and a cd with title 'Popular'.
3158
3159 If you want to fetch related objects from other tables as well, see C<prefetch>
3160 below.
3161
3162 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3163
3164 =head2 prefetch
3165
3166 =over 4
3167
3168 =item Value: ($rel_name | \@rel_names | \%rel_names)
3169
3170 =back
3171
3172 Contains one or more relationships that should be fetched along with
3173 the main query (when they are accessed afterwards the data will
3174 already be available, without extra queries to the database).  This is
3175 useful for when you know you will need the related objects, because it
3176 saves at least one query:
3177
3178   my $rs = $schema->resultset('Tag')->search(
3179     undef,
3180     {
3181       prefetch => {
3182         cd => 'artist'
3183       }
3184     }
3185   );
3186
3187 The initial search results in SQL like the following:
3188
3189   SELECT tag.*, cd.*, artist.* FROM tag
3190   JOIN cd ON tag.cd = cd.cdid
3191   JOIN artist ON cd.artist = artist.artistid
3192
3193 L<DBIx::Class> has no need to go back to the database when we access the
3194 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3195 case.
3196
3197 Simple prefetches will be joined automatically, so there is no need
3198 for a C<join> attribute in the above search.
3199
3200 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3201 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3202 with an accessor type of 'single' or 'filter'). A more complex example that
3203 prefetches an artists cds, the tracks on those cds, and the tags associted
3204 with that artist is given below (assuming many-to-many from artists to tags):
3205
3206  my $rs = $schema->resultset('Artist')->search(
3207    undef,
3208    {
3209      prefetch => [
3210        { cds => 'tracks' },
3211        { artist_tags => 'tags' }
3212      ]
3213    }
3214  );
3215
3216
3217 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3218 attributes will be ignored.
3219
3220 =head2 page
3221
3222 =over 4
3223
3224 =item Value: $page
3225
3226 =back
3227
3228 Makes the resultset paged and specifies the page to retrieve. Effectively
3229 identical to creating a non-pages resultset and then calling ->page($page)
3230 on it.
3231
3232 If L<rows> attribute is not specified it defaults to 10 rows per page.
3233
3234 When you have a paged resultset, L</count> will only return the number
3235 of rows in the page. To get the total, use the L</pager> and call
3236 C<total_entries> on it.
3237
3238 =head2 rows
3239
3240 =over 4
3241
3242 =item Value: $rows
3243
3244 =back
3245
3246 Specifes the maximum number of rows for direct retrieval or the number of
3247 rows per page if the page attribute or method is used.
3248
3249 =head2 offset
3250
3251 =over 4
3252
3253 =item Value: $offset
3254
3255 =back
3256
3257 Specifies the (zero-based) row number for the  first row to be returned, or the
3258 of the first row of the first page if paging is used.
3259
3260 =head2 group_by
3261
3262 =over 4
3263
3264 =item Value: \@columns
3265
3266 =back
3267
3268 A arrayref of columns to group by. Can include columns of joined tables.
3269
3270   group_by => [qw/ column1 column2 ... /]
3271
3272 =head2 having
3273
3274 =over 4
3275
3276 =item Value: $condition
3277
3278 =back
3279
3280 HAVING is a select statement attribute that is applied between GROUP BY and
3281 ORDER BY. It is applied to the after the grouping calculations have been
3282 done.
3283
3284   having => { 'count(employee)' => { '>=', 100 } }
3285
3286 =head2 distinct
3287
3288 =over 4
3289
3290 =item Value: (0 | 1)
3291
3292 =back
3293
3294 Set to 1 to group by all columns.
3295
3296 =head2 where
3297
3298 =over 4
3299
3300 Adds to the WHERE clause.
3301
3302   # only return rows WHERE deleted IS NULL for all searches
3303   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3304
3305 Can be overridden by passing C<{ where => undef }> as an attribute
3306 to a resulset.
3307
3308 =back
3309
3310 =head2 cache
3311
3312 Set to 1 to cache search results. This prevents extra SQL queries if you
3313 revisit rows in your ResultSet:
3314
3315   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3316
3317   while( my $artist = $resultset->next ) {
3318     ... do stuff ...
3319   }
3320
3321   $rs->first; # without cache, this would issue a query
3322
3323 By default, searches are not cached.
3324
3325 For more examples of using these attributes, see
3326 L<DBIx::Class::Manual::Cookbook>.
3327
3328 =head2 from
3329
3330 =over 4
3331
3332 =item Value: \@from_clause
3333
3334 =back
3335
3336 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3337 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3338 clauses.
3339
3340 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3341
3342 C<join> will usually do what you need and it is strongly recommended that you
3343 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3344 And we really do mean "cannot", not just tried and failed. Attempting to use
3345 this because you're having problems with C<join> is like trying to use x86
3346 ASM because you've got a syntax error in your C. Trust us on this.
3347
3348 Now, if you're still really, really sure you need to use this (and if you're
3349 not 100% sure, ask the mailing list first), here's an explanation of how this
3350 works.
3351
3352 The syntax is as follows -
3353
3354   [
3355     { <alias1> => <table1> },
3356     [
3357       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3358       [], # nested JOIN (optional)
3359       { <table1.column1> => <table2.column2>, ... (more conditions) },
3360     ],
3361     # More of the above [ ] may follow for additional joins
3362   ]
3363
3364   <table1> <alias1>
3365   JOIN
3366     <table2> <alias2>
3367     [JOIN ...]
3368   ON <table1.column1> = <table2.column2>
3369   <more joins may follow>
3370
3371 An easy way to follow the examples below is to remember the following:
3372
3373     Anything inside "[]" is a JOIN
3374     Anything inside "{}" is a condition for the enclosing JOIN
3375
3376 The following examples utilize a "person" table in a family tree application.
3377 In order to express parent->child relationships, this table is self-joined:
3378
3379     # Person->belongs_to('father' => 'Person');
3380     # Person->belongs_to('mother' => 'Person');
3381
3382 C<from> can be used to nest joins. Here we return all children with a father,
3383 then search against all mothers of those children:
3384
3385   $rs = $schema->resultset('Person')->search(
3386       undef,
3387       {
3388           alias => 'mother', # alias columns in accordance with "from"
3389           from => [
3390               { mother => 'person' },
3391               [
3392                   [
3393                       { child => 'person' },
3394                       [
3395                           { father => 'person' },
3396                           { 'father.person_id' => 'child.father_id' }
3397                       ]
3398                   ],
3399                   { 'mother.person_id' => 'child.mother_id' }
3400               ],
3401           ]
3402       },
3403   );
3404
3405   # Equivalent SQL:
3406   # SELECT mother.* FROM person mother
3407   # JOIN (
3408   #   person child
3409   #   JOIN person father
3410   #   ON ( father.person_id = child.father_id )
3411   # )
3412   # ON ( mother.person_id = child.mother_id )
3413
3414 The type of any join can be controlled manually. To search against only people
3415 with a father in the person table, we could explicitly use C<INNER JOIN>:
3416
3417     $rs = $schema->resultset('Person')->search(
3418         undef,
3419         {
3420             alias => 'child', # alias columns in accordance with "from"
3421             from => [
3422                 { child => 'person' },
3423                 [
3424                     { father => 'person', -join_type => 'inner' },
3425                     { 'father.id' => 'child.father_id' }
3426                 ],
3427             ]
3428         },
3429     );
3430
3431     # Equivalent SQL:
3432     # SELECT child.* FROM person child
3433     # INNER JOIN person father ON child.father_id = father.id
3434
3435 You can select from a subquery by passing a resultset to from as follows.
3436
3437     $schema->resultset('Artist')->search(
3438         undef,
3439         {   alias => 'artist2',
3440             from  => [ { artist2 => $artist_rs->as_query } ],
3441         } );
3442
3443     # and you'll get sql like this..
3444     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3445     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3446
3447 If you need to express really complex joins, you
3448 can supply literal SQL to C<from> via a scalar reference. In this case
3449 the contents of the scalar will replace the table name associated with the
3450 resultsource.
3451
3452 WARNING: This technique might very well not work as expected on chained
3453 searches - you have been warned.
3454
3455     # Assuming the Event resultsource is defined as:
3456
3457         MySchema::Event->add_columns (
3458             sequence => {
3459                 data_type => 'INT',
3460                 is_auto_increment => 1,
3461             },
3462             location => {
3463                 data_type => 'INT',
3464             },
3465             type => {
3466                 data_type => 'INT',
3467             },
3468         );
3469         MySchema::Event->set_primary_key ('sequence');
3470
3471     # This will get back the latest event for every location. The column
3472     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3473     # combo to limit the resultset
3474
3475     $rs = $schema->resultset('Event');
3476     $table = $rs->result_source->name;
3477     $latest = $rs->search (
3478         undef,
3479         { from => \ "
3480             (SELECT e1.* FROM $table e1
3481                 JOIN $table e2
3482                     ON e1.location = e2.location
3483                     AND e1.sequence < e2.sequence
3484                 WHERE e2.sequence is NULL
3485             ) me",
3486         },
3487     );
3488
3489     # Equivalent SQL (with the DBIC chunks added):
3490
3491     SELECT me.sequence, me.location, me.type FROM
3492        (SELECT e1.* FROM events e1
3493            JOIN events e2
3494                ON e1.location = e2.location
3495                AND e1.sequence < e2.sequence
3496            WHERE e2.sequence is NULL
3497        ) me;
3498
3499 =head2 for
3500
3501 =over 4
3502
3503 =item Value: ( 'update' | 'shared' )
3504
3505 =back
3506
3507 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3508 ... FOR SHARED.
3509
3510 =cut
3511
3512 1;