lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset, conditions and
 145 attributes with the same keys need resolving.
 146
 147 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 148 into the existing ones from the original resultset.
 149
 150 The L</where> and L</having> attributes, and any search conditions, are
 151 merged with an SQL C<AND> to the existing condition from the original
 152 resultset.
 153
 154 All other attributes are overridden by any new ones supplied in the
 155 search attributes.
 156
 157 =head2 Multiple queries
 158
 159 Since a resultset just defines a query, you can do all sorts of
 160 things with it with the same object.
 161
 162   # Don't hit the DB yet.
 163   my $cd_rs = $schema->resultset('CD')->search({
 164     title => 'something',
 165     year => 2009,
 166   });
 167
 168   # Each of these hits the DB individually.
 169   my $count = $cd_rs->count;
 170   my $most_recent = $cd_rs->get_column('date_released')->max();
 171   my @records = $cd_rs->all;
 172
 173 And it's not just limited to SELECT statements.
 174
 175   $cd_rs->delete();
 176
 177 This is even cooler:
 178
 179   $cd_rs->create({ artist => 'Fred' });
 180
 181 Which is the same as:
 182
 183   $schema->resultset('CD')->create({
 184     title => 'something',
 185     year => 2009,
 186     artist => 'Fred'
 187   });
 188
 189 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 190
 191 =head1 METHODS
 192
 193 =head2 new
 194
 195 =over 4
 196
 197 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 198
 199 =item Return Value: L<$resultset|/search>
 200
 201 =back
 202
 203 The resultset constructor. Takes a source object (usually a
 204 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 205 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 206 executed as needed by the other methods.
 207
 208 Generally you never construct a resultset manually. Instead you get one
 209 from e.g. a
 210 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 211 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 212 scalar context):
 213
 214   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 215
 216 =over
 217
 218 =item WARNING
 219
 220 If called on an object, proxies to L</new_result> instead, so
 221
 222   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 223
 224 will return a CD object, not a ResultSet, and is equivalent to:
 225
 226   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 227
 228 Please also keep in mind that many internals call L</new_result> directly,
 229 so overloading this method with the idea of intercepting new result object
 230 creation B<will not work>. See also warning pertaining to L</create>.
 231
 232 =back
 233
 234 =cut
 235
 236 sub new {
 237   my $class = shift;
 238   return $class->new_result(@_) if ref $class;
 239
 240   my ($source, $attrs) = @_;
 241   $source = $source->resolve
 242     if $source->isa('DBIx::Class::ResultSourceHandle');
 243   $attrs = { %{$attrs||{}} };
 244
 245   if ($attrs->{page}) {
 246     $attrs->{rows} ||= 10;
 247   }
 248
 249   $attrs->{alias} ||= 'me';
 250
 251   my $self = bless {
 252     result_source => $source,
 253     cond => $attrs->{where},
 254     pager => undef,
 255     attrs => $attrs,
 256   }, $class;
 257
 258   # if there is a dark selector, this means we are already in a
 259   # chain and the cleanup/sanification was taken care of by
 260   # _search_rs already
 261   $self->_normalize_selection($attrs)
 262     unless $attrs->{_dark_selector};
 263
 264   $self->result_class(
 265     $attrs->{result_class} || $source->result_class
 266   );
 267
 268   $self;
 269 }
 270
 271 =head2 search
 272
 273 =over 4
 274
 275 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 276
 277 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 278
 279 =back
 280
 281   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 282   my $new_rs = $cd_rs->search({ year => 2005 });
 283
 284   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 285                  # year = 2005 OR year = 2004
 286
 287 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 288 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 289 To avoid that, use L</search_rs>.
 290
 291 If you need to pass in additional attributes but no additional condition,
 292 call it as C<search(undef, \%attrs)>.
 293
 294   # "SELECT name, artistid FROM $artist_table"
 295   my @all_artists = $schema->resultset('Artist')->search(undef, {
 296     columns => [qw/name artistid/],
 297   });
 298
 299 For a list of attributes that can be passed to C<search>, see
 300 L</ATTRIBUTES>. For more examples of using this function, see
 301 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 302 documentation for the first argument, see L<SQL::Abstract>
 303 and its extension L<DBIx::Class::SQLMaker>.
 304
 305 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 306
 307 =head3 CAVEAT
 308
 309 Note that L</search> does not process/deflate any of the values passed in the
 310 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 311 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 312 manually that any value passed to this method will stringify to something the
 313 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 314 objects, for more info see:
 315 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 316
 317 =cut
 318
 319 sub search {
 320   my $self = shift;
 321   my $rs = $self->search_rs( @_ );
 322
 323   if (wantarray) {
 324     return $rs->all;
 325   }
 326   elsif (defined wantarray) {
 327     return $rs;
 328   }
 329   else {
 330     # we can be called by a relationship helper, which in
 331     # turn may be called in void context due to some braindead
 332     # overload or whatever else the user decided to be clever
 333     # at this particular day. Thus limit the exception to
 334     # external code calls only
 335     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 336       if (caller)[0] !~ /^\QDBIx::Class::/;
 337
 338     return ();
 339   }
 340 }
 341
 342 =head2 search_rs
 343
 344 =over 4
 345
 346 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 347
 348 =item Return Value: L<$resultset|/search>
 349
 350 =back
 351
 352 This method does the same exact thing as search() except it will
 353 always return a resultset, even in list context.
 354
 355 =cut
 356
 357 sub search_rs {
 358   my $self = shift;
 359
 360   my $rsrc = $self->result_source;
 361   my ($call_cond, $call_attrs);
 362
 363   # Special-case handling for (undef, undef) or (undef)
 364   # Note that (foo => undef) is valid deprecated syntax
 365   @_ = () if not scalar grep { defined $_ } @_;
 366
 367   # just a cond
 368   if (@_ == 1) {
 369     $call_cond = shift;
 370   }
 371   # fish out attrs in the ($condref, $attr) case
 372   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 373     ($call_cond, $call_attrs) = @_;
 374   }
 375   elsif (@_ % 2) {
 376     $self->throw_exception('Odd number of arguments to search')
 377   }
 378   # legacy search
 379   elsif (@_) {
 380     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 381       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 382
 383     for my $i (0 .. $#_) {
 384       next if $i % 2;
 385       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 386         if (! defined $_[$i] or ref $_[$i] ne '');
 387     }
 388
 389     $call_cond = { @_ };
 390   }
 391
 392   # see if we can keep the cache (no $rs changes)
 393   my $cache;
 394   my %safe = (alias => 1, cache => 1);
 395   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 396     ! defined $call_cond
 397       or
 398     ref $call_cond eq 'HASH' && ! keys %$call_cond
 399       or
 400     ref $call_cond eq 'ARRAY' && ! @$call_cond
 401   )) {
 402     $cache = $self->get_cache;
 403   }
 404
 405   my $old_attrs = { %{$self->{attrs}} };
 406   my $old_having = delete $old_attrs->{having};
 407   my $old_where = delete $old_attrs->{where};
 408
 409   my $new_attrs = { %$old_attrs };
 410
 411   # take care of call attrs (only if anything is changing)
 412   if ($call_attrs and keys %$call_attrs) {
 413
 414     # copy for _normalize_selection
 415     $call_attrs = { %$call_attrs };
 416
 417     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 418
 419     # reset the current selector list if new selectors are supplied
 420     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 421       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 422     }
 423
 424     # Normalize the new selector list (operates on the passed-in attr structure)
 425     # Need to do it on every chain instead of only once on _resolved_attrs, in
 426     # order to allow detection of empty vs partial 'as'
 427     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 428       if $old_attrs->{_dark_selector};
 429     $self->_normalize_selection ($call_attrs);
 430
 431     # start with blind overwriting merge, exclude selector attrs
 432     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 433     delete @{$new_attrs}{@selector_attrs};
 434
 435     for (@selector_attrs) {
 436       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 437         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 438     }
 439
 440     # older deprecated name, use only if {columns} is not there
 441     if (my $c = delete $new_attrs->{cols}) {
 442       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 443       if ($new_attrs->{columns}) {
 444         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 445       }
 446       else {
 447         $new_attrs->{columns} = $c;
 448       }
 449     }
 450
 451
 452     # join/prefetch use their own crazy merging heuristics
 453     foreach my $key (qw/join prefetch/) {
 454       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 455         if exists $call_attrs->{$key};
 456     }
 457
 458     # stack binds together
 459     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 460   }
 461
 462
 463   for ($old_where, $call_cond) {
 464     if (defined $_) {
 465       $new_attrs->{where} = $self->_stack_cond (
 466         $_, $new_attrs->{where}
 467       );
 468     }
 469   }
 470
 471   if (defined $old_having) {
 472     $new_attrs->{having} = $self->_stack_cond (
 473       $old_having, $new_attrs->{having}
 474     )
 475   }
 476
 477   my $rs = (ref $self)->new($rsrc, $new_attrs);
 478
 479   $rs->set_cache($cache) if ($cache);
 480
 481   return $rs;
 482 }
 483
 484 my $dark_sel_dumper;
 485 sub _normalize_selection {
 486   my ($self, $attrs) = @_;
 487
 488   # legacy syntax
 489   if ( exists $attrs->{include_columns} ) {
 490     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 491     $attrs->{'+columns'} = $self->_merge_attr(
 492       $attrs->{'+columns'}, delete $attrs->{include_columns}
 493     );
 494   }
 495
 496   # columns are always placed first, however
 497
 498   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 499   # delay the decision on whether to use a default select list ($rsrc->columns)
 500   # allowing stuff like the remove_columns helper to work
 501   #
 502   # select/as +select/+as pairs need special handling - the amount of select/as
 503   # elements in each pair does *not* have to be equal (think multicolumn
 504   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 505   # supplied at all) - try to infer the alias, either from the -as parameter
 506   # of the selector spec, or use the parameter whole if it looks like a column
 507   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 508   # is ok as well), but make sure no more additions to the 'as' chain take place
 509   for my $pref ('', '+') {
 510
 511     my ($sel, $as) = map {
 512       my $key = "${pref}${_}";
 513
 514       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 515         ? @{$attrs->{$key}}
 516         : $attrs->{$key} || ()
 517       ];
 518       delete $attrs->{$key};
 519       $val;
 520     } qw/select as/;
 521
 522     if (! @$as and ! @$sel ) {
 523       next;
 524     }
 525     elsif (@$as and ! @$sel) {
 526       $self->throw_exception(
 527         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 528       );
 529     }
 530     elsif( ! @$as ) {
 531       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 532       # if any @$as has been supplied we assume the user knows what (s)he is doing
 533       # and blindly keep stacking up pieces
 534       unless ($attrs->{_dark_selector}) {
 535         SELECTOR:
 536         for (@$sel) {
 537           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 538             push @$as, $_->{-as};
 539           }
 540           # assume any plain no-space, no-parenthesis string to be a column spec
 541           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 542           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 543             push @$as, $_;
 544           }
 545           # if all else fails - raise a flag that no more aliasing will be allowed
 546           else {
 547             $attrs->{_dark_selector} = {
 548               plus_stage => $pref,
 549               string => ($dark_sel_dumper ||= do {
 550                   require Data::Dumper::Concise;
 551                   Data::Dumper::Concise::DumperObject()->Indent(0);
 552                 })->Values([$_])->Dump
 553               ,
 554             };
 555             last SELECTOR;
 556           }
 557         }
 558       }
 559     }
 560     elsif (@$as < @$sel) {
 561       $self->throw_exception(
 562         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 563       );
 564     }
 565     elsif ($pref and $attrs->{_dark_selector}) {
 566       $self->throw_exception(
 567         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 568       );
 569     }
 570
 571
 572     # merge result
 573     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 574     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 575   }
 576 }
 577
 578 sub _stack_cond {
 579   my ($self, $left, $right) = @_;
 580
 581   # collapse single element top-level conditions
 582   # (single pass only, unlikely to need recursion)
 583   for ($left, $right) {
 584     if (ref $_ eq 'ARRAY') {
 585       if (@$_ == 0) {
 586         $_ = undef;
 587       }
 588       elsif (@$_ == 1) {
 589         $_ = $_->[0];
 590       }
 591     }
 592     elsif (ref $_ eq 'HASH') {
 593       my ($first, $more) = keys %$_;
 594
 595       # empty hash
 596       if (! defined $first) {
 597         $_ = undef;
 598       }
 599       # one element hash
 600       elsif (! defined $more) {
 601         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 602           $_ = $_->{'-and'};
 603         }
 604         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 605           $_ = $_->{'-or'};
 606         }
 607       }
 608     }
 609   }
 610
 611   # merge hashes with weeding out of duplicates (simple cases only)
 612   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 613
 614     # shallow copy to destroy
 615     $right = { %$right };
 616     for (grep { exists $right->{$_} } keys %$left) {
 617       # the use of eq_deeply here is justified - the rhs of an
 618       # expression can contain a lot of twisted weird stuff
 619       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 620     }
 621
 622     $right = undef unless keys %$right;
 623   }
 624
 625
 626   if (defined $left xor defined $right) {
 627     return defined $left ? $left : $right;
 628   }
 629   elsif (! defined $left) {
 630     return undef;
 631   }
 632   else {
 633     return { -and => [ $left, $right ] };
 634   }
 635 }
 636
 637 =head2 search_literal
 638
 639 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 640 should only be used in that context. C<search_literal> is a convenience
 641 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 642 want to ensure columns are bound correctly, use L</search>.
 643
 644 See L<DBIx::Class::Manual::Cookbook/Searching> and
 645 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 646 require C<search_literal>.
 647
 648 =over 4
 649
 650 =item Arguments: $sql_fragment, @standalone_bind_values
 651
 652 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 653
 654 =back
 655
 656   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 657   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 658
 659 Pass a literal chunk of SQL to be added to the conditional part of the
 660 resultset query.
 661
 662 Example of how to use C<search> instead of C<search_literal>
 663
 664   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 665   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 666
 667 =cut
 668
 669 sub search_literal {
 670   my ($self, $sql, @bind) = @_;
 671   my $attr;
 672   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 673     $attr = pop @bind;
 674   }
 675   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 676 }
 677
 678 =head2 find
 679
 680 =over 4
 681
 682 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 683
 684 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 685
 686 =back
 687
 688 Finds and returns a single row based on supplied criteria. Takes either a
 689 hashref with the same format as L</create> (including inference of foreign
 690 keys from related objects), or a list of primary key values in the same
 691 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 692 declaration on the L</result_source>.
 693
 694 In either case an attempt is made to combine conditions already existing on
 695 the resultset with the condition passed to this method.
 696
 697 To aid with preparing the correct query for the storage you may supply the
 698 C<key> attribute, which is the name of a
 699 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 700 unique constraint corresponding to the
 701 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 702 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 703 to construct a query that satisfies the named unique constraint fully (
 704 non-NULL values for each column member of the constraint) an exception is
 705 thrown.
 706
 707 If no C<key> is specified, the search is carried over all unique constraints
 708 which are fully defined by the available condition.
 709
 710 If no such constraint is found, C<find> currently defaults to a simple
 711 C<< search->(\%column_values) >> which may or may not do what you expect.
 712 Note that this fallback behavior may be deprecated in further versions. If
 713 you need to search with arbitrary conditions - use L</search>. If the query
 714 resulting from this fallback produces more than one row, a warning to the
 715 effect is issued, though only the first row is constructed and returned as
 716 C<$result_object>.
 717
 718 In addition to C<key>, L</find> recognizes and applies standard
 719 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 720
 721 Note that if you have extra concerns about the correctness of the resulting
 722 query you need to specify the C<key> attribute and supply the entire condition
 723 as an argument to find (since it is not always possible to perform the
 724 combination of the resultset condition with the supplied one, especially if
 725 the resultset condition contains literal sql).
 726
 727 For example, to find a row by its primary key:
 728
 729   my $cd = $schema->resultset('CD')->find(5);
 730
 731 You can also find a row by a specific unique constraint:
 732
 733   my $cd = $schema->resultset('CD')->find(
 734     {
 735       artist => 'Massive Attack',
 736       title  => 'Mezzanine',
 737     },
 738     { key => 'cd_artist_title' }
 739   );
 740
 741 See also L</find_or_create> and L</update_or_create>.
 742
 743 =cut
 744
 745 sub find {
 746   my $self = shift;
 747   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 748
 749   my $rsrc = $self->result_source;
 750
 751   my $constraint_name;
 752   if (exists $attrs->{key}) {
 753     $constraint_name = defined $attrs->{key}
 754       ? $attrs->{key}
 755       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 756     ;
 757   }
 758
 759   # Parse out the condition from input
 760   my $call_cond;
 761
 762   if (ref $_[0] eq 'HASH') {
 763     $call_cond = { %{$_[0]} };
 764   }
 765   else {
 766     # if only values are supplied we need to default to 'primary'
 767     $constraint_name = 'primary' unless defined $constraint_name;
 768
 769     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 770
 771     $self->throw_exception(
 772       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 773     ) unless @c_cols;
 774
 775     $self->throw_exception (
 776       'find() expects either a column/value hashref, or a list of values '
 777     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 778     ) unless @c_cols == @_;
 779
 780     $call_cond = {};
 781     @{$call_cond}{@c_cols} = @_;
 782   }
 783
 784   my %related;
 785   for my $key (keys %$call_cond) {
 786     if (
 787       my $keyref = ref($call_cond->{$key})
 788         and
 789       my $relinfo = $rsrc->relationship_info($key)
 790     ) {
 791       my $val = delete $call_cond->{$key};
 792
 793       next if $keyref eq 'ARRAY'; # has_many for multi_create
 794
 795       my $rel_q = $rsrc->_resolve_condition(
 796         $relinfo->{cond}, $val, $key, $key
 797       );
 798       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 799       @related{keys %$rel_q} = values %$rel_q;
 800     }
 801   }
 802
 803   # relationship conditions take precedence (?)
 804   @{$call_cond}{keys %related} = values %related;
 805
 806   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 807   my $final_cond;
 808   if (defined $constraint_name) {
 809     $final_cond = $self->_qualify_cond_columns (
 810
 811       $self->_build_unique_cond (
 812         $constraint_name,
 813         $call_cond,
 814       ),
 815
 816       $alias,
 817     );
 818   }
 819   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 820     # This means that we got here after a merger of relationship conditions
 821     # in ::Relationship::Base::search_related (the row method), and furthermore
 822     # the relationship is of the 'single' type. This means that the condition
 823     # provided by the relationship (already attached to $self) is sufficient,
 824     # as there can be only one row in the database that would satisfy the
 825     # relationship
 826   }
 827   else {
 828     # no key was specified - fall down to heuristics mode:
 829     # run through all unique queries registered on the resultset, and
 830     # 'OR' all qualifying queries together
 831     my (@unique_queries, %seen_column_combinations);
 832     for my $c_name ($rsrc->unique_constraint_names) {
 833       next if $seen_column_combinations{
 834         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 835       }++;
 836
 837       push @unique_queries, try {
 838         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 839       } || ();
 840     }
 841
 842     $final_cond = @unique_queries
 843       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 844       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 845     ;
 846   }
 847
 848   # Run the query, passing the result_class since it should propagate for find
 849   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 850   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 851     my $row = $rs->next;
 852     carp "Query returned more than one row" if $rs->next;
 853     return $row;
 854   }
 855   else {
 856     return $rs->single;
 857   }
 858 }
 859
 860 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 861 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 862 #
 863 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 864 # condition. It is provided for overrides until a saner way forward is devised
 865 #
 866 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 867 # the road. Please adjust your tests accordingly to catch this situation early
 868 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 869 #
 870 # The method will not be removed without an adequately complete replacement
 871 # for strict-mode enforcement
 872 sub _non_unique_find_fallback {
 873   my ($self, $cond, $attrs) = @_;
 874
 875   return $self->_qualify_cond_columns(
 876     $cond,
 877     exists $attrs->{alias}
 878       ? $attrs->{alias}
 879       : $self->{attrs}{alias}
 880   );
 881 }
 882
 883
 884 sub _qualify_cond_columns {
 885   my ($self, $cond, $alias) = @_;
 886
 887   my %aliased = %$cond;
 888   for (keys %aliased) {
 889     $aliased{"$alias.$_"} = delete $aliased{$_}
 890       if $_ !~ /\./;
 891   }
 892
 893   return \%aliased;
 894 }
 895
 896 sub _build_unique_cond {
 897   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 898
 899   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 900
 901   # combination may fail if $self->{cond} is non-trivial
 902   my ($final_cond) = try {
 903     $self->_merge_with_rscond ($extra_cond)
 904   } catch {
 905     +{ %$extra_cond }
 906   };
 907
 908   # trim out everything not in $columns
 909   $final_cond = { map {
 910     exists $final_cond->{$_}
 911       ? ( $_ => $final_cond->{$_} )
 912       : ()
 913   } @c_cols };
 914
 915   if (my @missing = grep
 916     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 917     (@c_cols)
 918   ) {
 919     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 920       $constraint_name,
 921       join (', ', map { "'$_'" } @missing),
 922     ) );
 923   }
 924
 925   if (
 926     !$croak_on_null
 927       and
 928     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 929       and
 930     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 931   ) {
 932     carp_unique ( sprintf (
 933       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 934     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 935     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 936       $constraint_name,
 937       join (', ', map { "'$_'" } @undefs),
 938     ));
 939   }
 940
 941   return $final_cond;
 942 }
 943
 944 =head2 search_related
 945
 946 =over 4
 947
 948 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 949
 950 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 951
 952 =back
 953
 954   $new_rs = $cd_rs->search_related('artist', {
 955     name => 'Emo-R-Us',
 956   });
 957
 958 Searches the specified relationship, optionally specifying a condition and
 959 attributes for matching records. See L</ATTRIBUTES> for more information.
 960
 961 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 962 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 963
 964 See also L</search_related_rs>.
 965
 966 =cut
 967
 968 sub search_related {
 969   return shift->related_resultset(shift)->search(@_);
 970 }
 971
 972 =head2 search_related_rs
 973
 974 This method works exactly the same as search_related, except that
 975 it guarantees a resultset, even in list context.
 976
 977 =cut
 978
 979 sub search_related_rs {
 980   return shift->related_resultset(shift)->search_rs(@_);
 981 }
 982
 983 =head2 cursor
 984
 985 =over 4
 986
 987 =item Arguments: none
 988
 989 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 990
 991 =back
 992
 993 Returns a storage-driven cursor to the given resultset. See
 994 L<DBIx::Class::Cursor> for more information.
 995
 996 =cut
 997
 998 sub cursor {
 999   my $self = shift;
1000
1001   return $self->{cursor} ||= do {
1002     my $attrs = { %{$self->_resolved_attrs } };
1003     $self->result_source->storage->select(
1004       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1005     );
1006   };
1007 }
1008
1009 =head2 single
1010
1011 =over 4
1012
1013 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1014
1015 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1016
1017 =back
1018
1019   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1020
1021 Inflates the first result without creating a cursor if the resultset has
1022 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1023 of L</search>.
1024
1025 While this method can take an optional search condition (just like L</search>)
1026 being a fast-code-path it does not recognize search attributes. If you need to
1027 add extra joins or similar, call L</search> and then chain-call L</single> on the
1028 L<DBIx::Class::ResultSet> returned.
1029
1030 =over
1031
1032 =item B<Note>
1033
1034 As of 0.08100, this method enforces the assumption that the preceding
1035 query returns only one row. If more than one row is returned, you will receive
1036 a warning:
1037
1038   Query returned more than one row
1039
1040 In this case, you should be using L</next> or L</find> instead, or if you really
1041 know what you are doing, use the L</rows> attribute to explicitly limit the size
1042 of the resultset.
1043
1044 This method will also throw an exception if it is called on a resultset prefetching
1045 has_many, as such a prefetch implies fetching multiple rows from the database in
1046 order to assemble the resulting object.
1047
1048 =back
1049
1050 =cut
1051
1052 sub single {
1053   my ($self, $where) = @_;
1054   if(@_ > 2) {
1055       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1056   }
1057
1058   my $attrs = { %{$self->_resolved_attrs} };
1059
1060   if (keys %{$attrs->{collapse}}) {
1061     $self->throw_exception(
1062       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1063     );
1064   }
1065
1066   if ($where) {
1067     if (defined $attrs->{where}) {
1068       $attrs->{where} = {
1069         '-and' =>
1070             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1071                $where, delete $attrs->{where} ]
1072       };
1073     } else {
1074       $attrs->{where} = $where;
1075     }
1076   }
1077
1078   my @data = $self->result_source->storage->select_single(
1079     $attrs->{from}, $attrs->{select},
1080     $attrs->{where}, $attrs
1081   );
1082
1083   return (@data ? ($self->_construct_object(@data))[0] : undef);
1084 }
1085
1086
1087 # _collapse_query
1088 #
1089 # Recursively collapse the query, accumulating values for each column.
1090
1091 sub _collapse_query {
1092   my ($self, $query, $collapsed) = @_;
1093
1094   $collapsed ||= {};
1095
1096   if (ref $query eq 'ARRAY') {
1097     foreach my $subquery (@$query) {
1098       next unless ref $subquery;  # -or
1099       $collapsed = $self->_collapse_query($subquery, $collapsed);
1100     }
1101   }
1102   elsif (ref $query eq 'HASH') {
1103     if (keys %$query and (keys %$query)[0] eq '-and') {
1104       foreach my $subquery (@{$query->{-and}}) {
1105         $collapsed = $self->_collapse_query($subquery, $collapsed);
1106       }
1107     }
1108     else {
1109       foreach my $col (keys %$query) {
1110         my $value = $query->{$col};
1111         $collapsed->{$col}{$value}++;
1112       }
1113     }
1114   }
1115
1116   return $collapsed;
1117 }
1118
1119 =head2 get_column
1120
1121 =over 4
1122
1123 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1124
1125 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1126
1127 =back
1128
1129   my $max_length = $rs->get_column('length')->max;
1130
1131 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1132
1133 =cut
1134
1135 sub get_column {
1136   my ($self, $column) = @_;
1137   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1138   return $new;
1139 }
1140
1141 =head2 search_like
1142
1143 =over 4
1144
1145 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1146
1147 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1148
1149 =back
1150
1151   # WHERE title LIKE '%blue%'
1152   $cd_rs = $rs->search_like({ title => '%blue%'});
1153
1154 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1155 that this is simply a convenience method retained for ex Class::DBI users.
1156 You most likely want to use L</search> with specific operators.
1157
1158 For more information, see L<DBIx::Class::Manual::Cookbook>.
1159
1160 This method is deprecated and will be removed in 0.09. Use L</search()>
1161 instead. An example conversion is:
1162
1163   ->search_like({ foo => 'bar' });
1164
1165   # Becomes
1166
1167   ->search({ foo => { like => 'bar' } });
1168
1169 =cut
1170
1171 sub search_like {
1172   my $class = shift;
1173   carp_unique (
1174     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1175    .' Instead use ->search({ x => { -like => "y%" } })'
1176    .' (note the outer pair of {}s - they are important!)'
1177   );
1178   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1179   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1180   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1181   return $class->search($query, { %$attrs });
1182 }
1183
1184 =head2 slice
1185
1186 =over 4
1187
1188 =item Arguments: $first, $last
1189
1190 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1191
1192 =back
1193
1194 Returns a resultset or object list representing a subset of elements from the
1195 resultset slice is called on. Indexes are from 0, i.e., to get the first
1196 three records, call:
1197
1198   my ($one, $two, $three) = $rs->slice(0, 2);
1199
1200 =cut
1201
1202 sub slice {
1203   my ($self, $min, $max) = @_;
1204   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1205   $attrs->{offset} = $self->{attrs}{offset} || 0;
1206   $attrs->{offset} += $min;
1207   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1208   return $self->search(undef, $attrs);
1209   #my $slice = (ref $self)->new($self->result_source, $attrs);
1210   #return (wantarray ? $slice->all : $slice);
1211 }
1212
1213 =head2 next
1214
1215 =over 4
1216
1217 =item Arguments: none
1218
1219 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1220
1221 =back
1222
1223 Returns the next element in the resultset (C<undef> is there is none).
1224
1225 Can be used to efficiently iterate over records in the resultset:
1226
1227   my $rs = $schema->resultset('CD')->search;
1228   while (my $cd = $rs->next) {
1229     print $cd->title;
1230   }
1231
1232 Note that you need to store the resultset object, and call C<next> on it.
1233 Calling C<< resultset('Table')->next >> repeatedly will always return the
1234 first record from the resultset.
1235
1236 =cut
1237
1238 sub next {
1239   my ($self) = @_;
1240   if (my $cache = $self->get_cache) {
1241     $self->{all_cache_position} ||= 0;
1242     return $cache->[$self->{all_cache_position}++];
1243   }
1244   if ($self->{attrs}{cache}) {
1245     delete $self->{pager};
1246     $self->{all_cache_position} = 1;
1247     return ($self->all)[0];
1248   }
1249   if ($self->{stashed_objects}) {
1250     my $obj = shift(@{$self->{stashed_objects}});
1251     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1252     return $obj;
1253   }
1254   my @row = (
1255     exists $self->{stashed_row}
1256       ? @{delete $self->{stashed_row}}
1257       : $self->cursor->next
1258   );
1259   return undef unless (@row);
1260   my ($row, @more) = $self->_construct_object(@row);
1261   $self->{stashed_objects} = \@more if @more;
1262   return $row;
1263 }
1264
1265 sub _construct_object {
1266   my ($self, @row) = @_;
1267
1268   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1269     or return ();
1270   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1271   @new = $self->{_attrs}{record_filter}->(@new)
1272     if exists $self->{_attrs}{record_filter};
1273   return @new;
1274 }
1275
1276 sub _collapse_result {
1277   my ($self, $as_proto, $row) = @_;
1278
1279   my @copy = @$row;
1280
1281   # 'foo'         => [ undef, 'foo' ]
1282   # 'foo.bar'     => [ 'foo', 'bar' ]
1283   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1284
1285   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1286
1287   my %collapse = %{$self->{_attrs}{collapse}||{}};
1288
1289   my @pri_index;
1290
1291   # if we're doing collapsing (has_many prefetch) we need to grab records
1292   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1293   # we know we don't have to bother.
1294
1295   # the reason for not using the collapse stuff directly is because if you
1296   # had for e.g. two artists in a row with no cds, the collapse info for
1297   # both would be NULL (undef) so you'd lose the second artist
1298
1299   # store just the index so we can check the array positions from the row
1300   # without having to contruct the full hash
1301
1302   if (keys %collapse) {
1303     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1304     foreach my $i (0 .. $#construct_as) {
1305       next if defined($construct_as[$i][0]); # only self table
1306       if (delete $pri{$construct_as[$i][1]}) {
1307         push(@pri_index, $i);
1308       }
1309       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1310     }
1311   }
1312
1313   # no need to do an if, it'll be empty if @pri_index is empty anyway
1314
1315   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1316
1317   my @const_rows;
1318
1319   do { # no need to check anything at the front, we always want the first row
1320
1321     my %const;
1322
1323     foreach my $this_as (@construct_as) {
1324       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1325     }
1326
1327     push(@const_rows, \%const);
1328
1329   } until ( # no pri_index => no collapse => drop straight out
1330       !@pri_index
1331     or
1332       do { # get another row, stash it, drop out if different PK
1333
1334         @copy = $self->cursor->next;
1335         $self->{stashed_row} = \@copy;
1336
1337         # last thing in do block, counts as true if anything doesn't match
1338
1339         # check xor defined first for NULL vs. NOT NULL then if one is
1340         # defined the other must be so check string equality
1341
1342         grep {
1343           (defined $pri_vals{$_} ^ defined $copy[$_])
1344           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1345         } @pri_index;
1346       }
1347   );
1348
1349   my $alias = $self->{attrs}{alias};
1350   my $info = [];
1351
1352   my %collapse_pos;
1353
1354   my @const_keys;
1355
1356   foreach my $const (@const_rows) {
1357     scalar @const_keys or do {
1358       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1359     };
1360     foreach my $key (@const_keys) {
1361       if (length $key) {
1362         my $target = $info;
1363         my @parts = split(/\./, $key);
1364         my $cur = '';
1365         my $data = $const->{$key};
1366         foreach my $p (@parts) {
1367           $target = $target->[1]->{$p} ||= [];
1368           $cur .= ".${p}";
1369           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1370             # collapsing at this point and on final part
1371             my $pos = $collapse_pos{$cur};
1372             CK: foreach my $ck (@ckey) {
1373               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1374                 $collapse_pos{$cur} = $data;
1375                 delete @collapse_pos{ # clear all positioning for sub-entries
1376                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1377                 };
1378                 push(@$target, []);
1379                 last CK;
1380               }
1381             }
1382           }
1383           if (exists $collapse{$cur}) {
1384             $target = $target->[-1];
1385           }
1386         }
1387         $target->[0] = $data;
1388       } else {
1389         $info->[0] = $const->{$key};
1390       }
1391     }
1392   }
1393
1394   return $info;
1395 }
1396
1397 =head2 result_source
1398
1399 =over 4
1400
1401 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1402
1403 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1404
1405 =back
1406
1407 An accessor for the primary ResultSource object from which this ResultSet
1408 is derived.
1409
1410 =head2 result_class
1411
1412 =over 4
1413
1414 =item Arguments: $result_class?
1415
1416 =item Return Value: $result_class
1417
1418 =back
1419
1420 An accessor for the class to use when creating result objects. Defaults to
1421 C<< result_source->result_class >> - which in most cases is the name of the
1422 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1423
1424 Note that changing the result_class will also remove any components
1425 that were originally loaded in the source class via
1426 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1427 in the original source class will not run.
1428
1429 =cut
1430
1431 sub result_class {
1432   my ($self, $result_class) = @_;
1433   if ($result_class) {
1434     unless (ref $result_class) { # don't fire this for an object
1435       $self->ensure_class_loaded($result_class);
1436     }
1437     $self->_result_class($result_class);
1438     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1439     # permit the user to set result class on one result set only; it only
1440     # chains if provided to search()
1441     #$self->{attrs}{result_class} = $result_class if ref $self;
1442   }
1443   $self->_result_class;
1444 }
1445
1446 =head2 count
1447
1448 =over 4
1449
1450 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1451
1452 =item Return Value: $count
1453
1454 =back
1455
1456 Performs an SQL C<COUNT> with the same query as the resultset was built
1457 with to find the number of elements. Passing arguments is equivalent to
1458 C<< $rs->search ($cond, \%attrs)->count >>
1459
1460 =cut
1461
1462 sub count {
1463   my $self = shift;
1464   return $self->search(@_)->count if @_ and defined $_[0];
1465   return scalar @{ $self->get_cache } if $self->get_cache;
1466
1467   my $attrs = { %{ $self->_resolved_attrs } };
1468
1469   # this is a little optimization - it is faster to do the limit
1470   # adjustments in software, instead of a subquery
1471   my $rows = delete $attrs->{rows};
1472   my $offset = delete $attrs->{offset};
1473
1474   my $crs;
1475   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1476     $crs = $self->_count_subq_rs ($attrs);
1477   }
1478   else {
1479     $crs = $self->_count_rs ($attrs);
1480   }
1481   my $count = $crs->next;
1482
1483   $count -= $offset if $offset;
1484   $count = $rows if $rows and $rows < $count;
1485   $count = 0 if ($count < 0);
1486
1487   return $count;
1488 }
1489
1490 =head2 count_rs
1491
1492 =over 4
1493
1494 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1495
1496 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1497
1498 =back
1499
1500 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1501 This can be very handy for subqueries:
1502
1503   ->search( { amount => $some_rs->count_rs->as_query } )
1504
1505 As with regular resultsets the SQL query will be executed only after
1506 the resultset is accessed via L</next> or L</all>. That would return
1507 the same single value obtainable via L</count>.
1508
1509 =cut
1510
1511 sub count_rs {
1512   my $self = shift;
1513   return $self->search(@_)->count_rs if @_;
1514
1515   # this may look like a lack of abstraction (count() does about the same)
1516   # but in fact an _rs *must* use a subquery for the limits, as the
1517   # software based limiting can not be ported if this $rs is to be used
1518   # in a subquery itself (i.e. ->as_query)
1519   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1520     return $self->_count_subq_rs;
1521   }
1522   else {
1523     return $self->_count_rs;
1524   }
1525 }
1526
1527 #
1528 # returns a ResultSetColumn object tied to the count query
1529 #
1530 sub _count_rs {
1531   my ($self, $attrs) = @_;
1532
1533   my $rsrc = $self->result_source;
1534   $attrs ||= $self->_resolved_attrs;
1535
1536   my $tmp_attrs = { %$attrs };
1537   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1538   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1539
1540   # overwrite the selector (supplied by the storage)
1541   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1542   $tmp_attrs->{as} = 'count';
1543   delete @{$tmp_attrs}{qw/columns/};
1544
1545   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1546
1547   return $tmp_rs;
1548 }
1549
1550 #
1551 # same as above but uses a subquery
1552 #
1553 sub _count_subq_rs {
1554   my ($self, $attrs) = @_;
1555
1556   my $rsrc = $self->result_source;
1557   $attrs ||= $self->_resolved_attrs;
1558
1559   my $sub_attrs = { %$attrs };
1560   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1561   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1562
1563   # if we multi-prefetch we group_by something unique, as this is what we would
1564   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1565   if ( keys %{$attrs->{collapse}}  ) {
1566     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1567       $rsrc->_identifying_column_set || $self->throw_exception(
1568         'Unable to construct a unique group_by criteria properly collapsing the '
1569       . 'has_many prefetch before count()'
1570       );
1571     } ]
1572   }
1573
1574   # Calculate subquery selector
1575   if (my $g = $sub_attrs->{group_by}) {
1576
1577     my $sql_maker = $rsrc->storage->sql_maker;
1578
1579     # necessary as the group_by may refer to aliased functions
1580     my $sel_index;
1581     for my $sel (@{$attrs->{select}}) {
1582       $sel_index->{$sel->{-as}} = $sel
1583         if (ref $sel eq 'HASH' and $sel->{-as});
1584     }
1585
1586     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1587     # also look for named aggregates referred in the having clause
1588     # having often contains scalarrefs - thus parse it out entirely
1589     my @parts = @$g;
1590     if ($attrs->{having}) {
1591       local $sql_maker->{having_bind};
1592       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1593       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1594       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1595         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1596         # if we don't unset it we screw up retarded but unfortunately working
1597         # 'MAX(foo.bar)' => { '>', 3 }
1598         $sql_maker->{name_sep} = '';
1599       }
1600
1601       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1602
1603       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1604       my %seen_having;
1605
1606       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1607       # and if all fails for an utterly naive quoted scalar-with-function
1608       while ($having_sql =~ /
1609         $rquote $sep $lquote (.+?) $rquote
1610           |
1611         [\s,] \w+ \. (\w+) [\s,]
1612           |
1613         [\s,] $lquote (.+?) $rquote [\s,]
1614       /gx) {
1615         my $part = $1 || $2 || $3;  # one of them matched if we got here
1616         unless ($seen_having{$part}++) {
1617           push @parts, $part;
1618         }
1619       }
1620     }
1621
1622     for (@parts) {
1623       my $colpiece = $sel_index->{$_} || $_;
1624
1625       # unqualify join-based group_by's. Arcane but possible query
1626       # also horrible horrible hack to alias a column (not a func.)
1627       # (probably need to introduce SQLA syntax)
1628       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1629         my $as = $colpiece;
1630         $as =~ s/\./__/;
1631         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1632       }
1633       push @{$sub_attrs->{select}}, $colpiece;
1634     }
1635   }
1636   else {
1637     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1638     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1639   }
1640
1641   return $rsrc->resultset_class
1642                ->new ($rsrc, $sub_attrs)
1643                 ->as_subselect_rs
1644                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1645                   ->get_column ('count');
1646 }
1647
1648
1649 =head2 count_literal
1650
1651 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1652 should only be used in that context. See L</search_literal> for further info.
1653
1654 =over 4
1655
1656 =item Arguments: $sql_fragment, @standalone_bind_values
1657
1658 =item Return Value: $count
1659
1660 =back
1661
1662 Counts the results in a literal query. Equivalent to calling L</search_literal>
1663 with the passed arguments, then L</count>.
1664
1665 =cut
1666
1667 sub count_literal { shift->search_literal(@_)->count; }
1668
1669 =head2 all
1670
1671 =over 4
1672
1673 =item Arguments: none
1674
1675 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1676
1677 =back
1678
1679 Returns all elements in the resultset.
1680
1681 =cut
1682
1683 sub all {
1684   my $self = shift;
1685   if(@_) {
1686       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1687   }
1688
1689   return @{ $self->get_cache } if $self->get_cache;
1690
1691   my @obj;
1692
1693   if (keys %{$self->_resolved_attrs->{collapse}}) {
1694     # Using $self->cursor->all is really just an optimisation.
1695     # If we're collapsing has_many prefetches it probably makes
1696     # very little difference, and this is cleaner than hacking
1697     # _construct_object to survive the approach
1698     $self->cursor->reset;
1699     my @row = $self->cursor->next;
1700     while (@row) {
1701       push(@obj, $self->_construct_object(@row));
1702       @row = (exists $self->{stashed_row}
1703                ? @{delete $self->{stashed_row}}
1704                : $self->cursor->next);
1705     }
1706   } else {
1707     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1708   }
1709
1710   $self->set_cache(\@obj) if $self->{attrs}{cache};
1711
1712   return @obj;
1713 }
1714
1715 =head2 reset
1716
1717 =over 4
1718
1719 =item Arguments: none
1720
1721 =item Return Value: $self
1722
1723 =back
1724
1725 Resets the resultset's cursor, so you can iterate through the elements again.
1726 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1727 another query.
1728
1729 =cut
1730
1731 sub reset {
1732   my ($self) = @_;
1733   $self->{all_cache_position} = 0;
1734   $self->cursor->reset;
1735   return $self;
1736 }
1737
1738 =head2 first
1739
1740 =over 4
1741
1742 =item Arguments: none
1743
1744 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1745
1746 =back
1747
1748 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1749 an object for the first result (or C<undef> if the resultset is empty).
1750
1751 =cut
1752
1753 sub first {
1754   return $_[0]->reset->next;
1755 }
1756
1757
1758 # _rs_update_delete
1759 #
1760 # Determines whether and what type of subquery is required for the $rs operation.
1761 # If grouping is necessary either supplies its own, or verifies the current one
1762 # After all is done delegates to the proper storage method.
1763
1764 sub _rs_update_delete {
1765   my ($self, $op, $values) = @_;
1766
1767   my $rsrc = $self->result_source;
1768   my $storage = $rsrc->schema->storage;
1769
1770   my $attrs = { %{$self->_resolved_attrs} };
1771
1772   my $join_classifications;
1773   my $existing_group_by = delete $attrs->{group_by};
1774
1775   # do we need a subquery for any reason?
1776   my $needs_subq = (
1777     defined $existing_group_by
1778       or
1779     # if {from} is unparseable wrap a subq
1780     ref($attrs->{from}) ne 'ARRAY'
1781       or
1782     # limits call for a subq
1783     $self->_has_resolved_attr(qw/rows offset/)
1784   );
1785
1786   # simplify the joinmap, so we can further decide if a subq is necessary
1787   if (!$needs_subq and @{$attrs->{from}} > 1) {
1788     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1789
1790     # check if there are any joins left after the prune
1791     if ( @{$attrs->{from}} > 1 ) {
1792       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1793         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1794         $attrs->{select},
1795         $self->{cond},
1796         $attrs
1797       );
1798
1799       # any non-pruneable joins imply subq
1800       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1801     }
1802   }
1803
1804   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1805   $needs_subq ||= (
1806     (ref $attrs->{from}[0]) ne 'HASH'
1807       or
1808     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1809   );
1810
1811   my ($cond, $guard);
1812   # do we need anything like a subquery?
1813   if (! $needs_subq) {
1814     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1815     # a condition containing 'me' or other table prefixes will not work
1816     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1817     $cond = do {
1818       my $sqla = $rsrc->storage->sql_maker;
1819       local $sqla->{_dequalify_idents} = 1;
1820       \[ $sqla->_recurse_where($self->{cond}) ];
1821     };
1822   }
1823   else {
1824     # we got this far - means it is time to wrap a subquery
1825     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1826       sprintf(
1827         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1828         $op,
1829         $rsrc->source_name,
1830       )
1831     );
1832
1833     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1834     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1835     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1836     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1837     my $subrs = (ref $self)->new($rsrc, $attrs);
1838
1839     if (@$idcols == 1) {
1840       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1841     }
1842     elsif ($storage->_use_multicolumn_in) {
1843       # no syntax for calling this properly yet
1844       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1845       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1846         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1847         $subrs->as_query
1848       ),
1849     }
1850     else {
1851       # if all else fails - get all primary keys and operate over a ORed set
1852       # wrap in a transaction for consistency
1853       # this is where the group_by/multiplication starts to matter
1854       if (
1855         $existing_group_by
1856           or
1857         keys %{ $join_classifications->{multiplying} || {} }
1858       ) {
1859         # make sure if there is a supplied group_by it matches the columns compiled above
1860         # perfectly. Anything else can not be sanely executed on most databases so croak
1861         # right then and there
1862         if ($existing_group_by) {
1863           my @current_group_by = map
1864             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1865             @$existing_group_by
1866           ;
1867
1868           if (
1869             join ("\x00", sort @current_group_by)
1870               ne
1871             join ("\x00", sort @{$attrs->{columns}} )
1872           ) {
1873             $self->throw_exception (
1874               "You have just attempted a $op operation on a resultset which does group_by"
1875               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1876               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1877               . ' kind of queries. Please retry the operation with a modified group_by or'
1878               . ' without using one at all.'
1879             );
1880           }
1881         }
1882
1883         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1884       }
1885
1886       $guard = $storage->txn_scope_guard;
1887
1888       $cond = [];
1889       for my $row ($subrs->cursor->all) {
1890         push @$cond, { map
1891           { $idcols->[$_] => $row->[$_] }
1892           (0 .. $#$idcols)
1893         };
1894       }
1895     }
1896   }
1897
1898   my $res = $storage->$op (
1899     $rsrc,
1900     $op eq 'update' ? $values : (),
1901     $cond,
1902   );
1903
1904   $guard->commit if $guard;
1905
1906   return $res;
1907 }
1908
1909 =head2 update
1910
1911 =over 4
1912
1913 =item Arguments: \%values
1914
1915 =item Return Value: $underlying_storage_rv
1916
1917 =back
1918
1919 Sets the specified columns in the resultset to the supplied values in a
1920 single query. Note that this will not run any accessor/set_column/update
1921 triggers, nor will it update any result object instances derived from this
1922 resultset (this includes the contents of the L<resultset cache|/set_cache>
1923 if any). See L</update_all> if you need to execute any on-update
1924 triggers or cascades defined either by you or a
1925 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1926
1927 The return value is a pass through of what the underlying
1928 storage backend returned, and may vary. See L<DBI/execute> for the most
1929 common case.
1930
1931 =head3 CAVEAT
1932
1933 Note that L</update> does not process/deflate any of the values passed in.
1934 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1935 ensure manually that any value passed to this method will stringify to
1936 something the RDBMS knows how to deal with. A notable example is the
1937 handling of L<DateTime> objects, for more info see:
1938 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1939
1940 =cut
1941
1942 sub update {
1943   my ($self, $values) = @_;
1944   $self->throw_exception('Values for update must be a hash')
1945     unless ref $values eq 'HASH';
1946
1947   return $self->_rs_update_delete ('update', $values);
1948 }
1949
1950 =head2 update_all
1951
1952 =over 4
1953
1954 =item Arguments: \%values
1955
1956 =item Return Value: 1
1957
1958 =back
1959
1960 Fetches all objects and updates them one at a time via
1961 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1962 triggers, while L</update> will not.
1963
1964 =cut
1965
1966 sub update_all {
1967   my ($self, $values) = @_;
1968   $self->throw_exception('Values for update_all must be a hash')
1969     unless ref $values eq 'HASH';
1970
1971   my $guard = $self->result_source->schema->txn_scope_guard;
1972   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1973   $guard->commit;
1974   return 1;
1975 }
1976
1977 =head2 delete
1978
1979 =over 4
1980
1981 =item Arguments: none
1982
1983 =item Return Value: $underlying_storage_rv
1984
1985 =back
1986
1987 Deletes the rows matching this resultset in a single query. Note that this
1988 will not run any delete triggers, nor will it alter the
1989 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1990 derived from this resultset (this includes the contents of the
1991 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1992 execute any on-delete triggers or cascades defined either by you or a
1993 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1994
1995 The return value is a pass through of what the underlying storage backend
1996 returned, and may vary. See L<DBI/execute> for the most common case.
1997
1998 =cut
1999
2000 sub delete {
2001   my $self = shift;
2002   $self->throw_exception('delete does not accept any arguments')
2003     if @_;
2004
2005   return $self->_rs_update_delete ('delete');
2006 }
2007
2008 =head2 delete_all
2009
2010 =over 4
2011
2012 =item Arguments: none
2013
2014 =item Return Value: 1
2015
2016 =back
2017
2018 Fetches all objects and deletes them one at a time via
2019 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2020 triggers, while L</delete> will not.
2021
2022 =cut
2023
2024 sub delete_all {
2025   my $self = shift;
2026   $self->throw_exception('delete_all does not accept any arguments')
2027     if @_;
2028
2029   my $guard = $self->result_source->schema->txn_scope_guard;
2030   $_->delete for $self->all;
2031   $guard->commit;
2032   return 1;
2033 }
2034
2035 =head2 populate
2036
2037 =over 4
2038
2039 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2040
2041 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2042
2043 =back
2044
2045 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2046 arrayrefs.
2047
2048 =over
2049
2050 =item NOTE
2051
2052 The context of this method call has an important effect on what is
2053 submitted to storage. In void context data is fed directly to fastpath
2054 insertion routines provided by the underlying storage (most often
2055 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2056 L<insert|DBIx::Class::Row/insert> calls on the
2057 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2058 augmentation of these methods provided by components. For example if you
2059 are using something like L<DBIx::Class::UUIDColumns> to create primary
2060 keys for you, you will find that your PKs are empty.  In this case you
2061 will have to explicitly force scalar or list context in order to create
2062 those values.
2063
2064 =back
2065
2066 In non-void (scalar or list) context, this method is simply a wrapper
2067 for L</create>. Depending on list or scalar context either a list of
2068 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2069 containing these objects is returned.
2070
2071 When supplying data in "arrayref of arrayrefs" invocation style, the
2072 first element should be a list of column names and each subsequent
2073 element should be a data value in the earlier specified column order.
2074 For example:
2075
2076   $Arstist_rs->populate([
2077     [ qw( artistid name ) ],
2078     [ 100, 'A Formally Unknown Singer' ],
2079     [ 101, 'A singer that jumped the shark two albums ago' ],
2080     [ 102, 'An actually cool singer' ],
2081   ]);
2082
2083 For the arrayref of hashrefs style each hashref should be a structure
2084 suitable for passing to L</create>. Multi-create is also permitted with
2085 this syntax.
2086
2087   $schema->resultset("Artist")->populate([
2088      { artistid => 4, name => 'Manufactured Crap', cds => [
2089         { title => 'My First CD', year => 2006 },
2090         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2091       ],
2092      },
2093      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2094         { title => 'My parents sold me to a record company', year => 2005 },
2095         { title => 'Why Am I So Ugly?', year => 2006 },
2096         { title => 'I Got Surgery and am now Popular', year => 2007 }
2097       ],
2098      },
2099   ]);
2100
2101 If you attempt a void-context multi-create as in the example above (each
2102 Artist also has the related list of CDs), and B<do not> supply the
2103 necessary autoinc foreign key information, this method will proxy to the
2104 less efficient L</create>, and then throw the Result objects away. In this
2105 case there are obviously no benefits to using this method over L</create>.
2106
2107 =cut
2108
2109 sub populate {
2110   my $self = shift;
2111
2112   # cruft placed in standalone method
2113   my $data = $self->_normalize_populate_args(@_);
2114
2115   return unless @$data;
2116
2117   if(defined wantarray) {
2118     my @created = map { $self->create($_) } @$data;
2119     return wantarray ? @created : \@created;
2120   }
2121   else {
2122     my $first = $data->[0];
2123
2124     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2125     # it relationship data
2126     my (@rels, @columns);
2127     my $rsrc = $self->result_source;
2128     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2129     for (keys %$first) {
2130       my $ref = ref $first->{$_};
2131       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2132         ? push @rels, $_
2133         : push @columns, $_
2134       ;
2135     }
2136
2137     my @pks = $rsrc->primary_columns;
2138
2139     ## do the belongs_to relationships
2140     foreach my $index (0..$#$data) {
2141
2142       # delegate to create() for any dataset without primary keys with specified relationships
2143       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2144         for my $r (@rels) {
2145           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2146             my @ret = $self->populate($data);
2147             return;
2148           }
2149         }
2150       }
2151
2152       foreach my $rel (@rels) {
2153         next unless ref $data->[$index]->{$rel} eq "HASH";
2154         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2155         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2156         my $related = $result->result_source->_resolve_condition(
2157           $reverse_relinfo->{cond},
2158           $self,
2159           $result,
2160           $rel,
2161         );
2162
2163         delete $data->[$index]->{$rel};
2164         $data->[$index] = {%{$data->[$index]}, %$related};
2165
2166         push @columns, keys %$related if $index == 0;
2167       }
2168     }
2169
2170     ## inherit the data locked in the conditions of the resultset
2171     my ($rs_data) = $self->_merge_with_rscond({});
2172     delete @{$rs_data}{@columns};
2173
2174     ## do bulk insert on current row
2175     $rsrc->storage->insert_bulk(
2176       $rsrc,
2177       [@columns, keys %$rs_data],
2178       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2179     );
2180
2181     ## do the has_many relationships
2182     foreach my $item (@$data) {
2183
2184       my $main_row;
2185
2186       foreach my $rel (@rels) {
2187         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2188
2189         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2190
2191         my $child = $main_row->$rel;
2192
2193         my $related = $child->result_source->_resolve_condition(
2194           $rels->{$rel}{cond},
2195           $child,
2196           $main_row,
2197           $rel,
2198         );
2199
2200         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2201         my @populate = map { {%$_, %$related} } @rows_to_add;
2202
2203         $child->populate( \@populate );
2204       }
2205     }
2206   }
2207 }
2208
2209
2210 # populate() argumnets went over several incarnations
2211 # What we ultimately support is AoH
2212 sub _normalize_populate_args {
2213   my ($self, $arg) = @_;
2214
2215   if (ref $arg eq 'ARRAY') {
2216     if (!@$arg) {
2217       return [];
2218     }
2219     elsif (ref $arg->[0] eq 'HASH') {
2220       return $arg;
2221     }
2222     elsif (ref $arg->[0] eq 'ARRAY') {
2223       my @ret;
2224       my @colnames = @{$arg->[0]};
2225       foreach my $values (@{$arg}[1 .. $#$arg]) {
2226         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2227       }
2228       return \@ret;
2229     }
2230   }
2231
2232   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2233 }
2234
2235 =head2 pager
2236
2237 =over 4
2238
2239 =item Arguments: none
2240
2241 =item Return Value: L<$pager|Data::Page>
2242
2243 =back
2244
2245 Returns a L<Data::Page> object for the current resultset. Only makes
2246 sense for queries with a C<page> attribute.
2247
2248 To get the full count of entries for a paged resultset, call
2249 C<total_entries> on the L<Data::Page> object.
2250
2251 =cut
2252
2253 sub pager {
2254   my ($self) = @_;
2255
2256   return $self->{pager} if $self->{pager};
2257
2258   my $attrs = $self->{attrs};
2259   if (!defined $attrs->{page}) {
2260     $self->throw_exception("Can't create pager for non-paged rs");
2261   }
2262   elsif ($attrs->{page} <= 0) {
2263     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2264   }
2265   $attrs->{rows} ||= 10;
2266
2267   # throw away the paging flags and re-run the count (possibly
2268   # with a subselect) to get the real total count
2269   my $count_attrs = { %$attrs };
2270   delete $count_attrs->{$_} for qw/rows offset page pager/;
2271
2272   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2273
2274   require DBIx::Class::ResultSet::Pager;
2275   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2276     sub { $total_rs->count },  #lazy-get the total
2277     $attrs->{rows},
2278     $self->{attrs}{page},
2279   );
2280 }
2281
2282 =head2 page
2283
2284 =over 4
2285
2286 =item Arguments: $page_number
2287
2288 =item Return Value: L<$resultset|/search>
2289
2290 =back
2291
2292 Returns a resultset for the $page_number page of the resultset on which page
2293 is called, where each page contains a number of rows equal to the 'rows'
2294 attribute set on the resultset (10 by default).
2295
2296 =cut
2297
2298 sub page {
2299   my ($self, $page) = @_;
2300   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2301 }
2302
2303 =head2 new_result
2304
2305 =over 4
2306
2307 =item Arguments: \%col_data
2308
2309 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2310
2311 =back
2312
2313 Creates a new result object in the resultset's result class and returns
2314 it. The row is not inserted into the database at this point, call
2315 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2316 will tell you whether the result object has been inserted or not.
2317
2318 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2319
2320 =cut
2321
2322 sub new_result {
2323   my ($self, $values) = @_;
2324
2325   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2326     if @_ > 2;
2327
2328   $self->throw_exception( "new_result expects a hashref" )
2329     unless (ref $values eq 'HASH');
2330
2331   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2332
2333   my $new = $self->result_class->new({
2334     %$merged_cond,
2335     ( @$cols_from_relations
2336       ? (-cols_from_relations => $cols_from_relations)
2337       : ()
2338     ),
2339     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2340   });
2341
2342   if (
2343     reftype($new) eq 'HASH'
2344       and
2345     ! keys %$new
2346       and
2347     blessed($new)
2348   ) {
2349     carp_unique (sprintf (
2350       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2351       $self->result_class,
2352     ));
2353   }
2354
2355   $new;
2356 }
2357
2358 # _merge_with_rscond
2359 #
2360 # Takes a simple hash of K/V data and returns its copy merged with the
2361 # condition already present on the resultset. Additionally returns an
2362 # arrayref of value/condition names, which were inferred from related
2363 # objects (this is needed for in-memory related objects)
2364 sub _merge_with_rscond {
2365   my ($self, $data) = @_;
2366
2367   my (%new_data, @cols_from_relations);
2368
2369   my $alias = $self->{attrs}{alias};
2370
2371   if (! defined $self->{cond}) {
2372     # just massage $data below
2373   }
2374   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2375     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2376     @cols_from_relations = keys %new_data;
2377   }
2378   elsif (ref $self->{cond} ne 'HASH') {
2379     $self->throw_exception(
2380       "Can't abstract implicit construct, resultset condition not a hash"
2381     );
2382   }
2383   else {
2384     # precendence must be given to passed values over values inherited from
2385     # the cond, so the order here is important.
2386     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2387     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2388
2389     while ( my($col, $value) = each %implied ) {
2390       my $vref = ref $value;
2391       if (
2392         $vref eq 'HASH'
2393           and
2394         keys(%$value) == 1
2395           and
2396         (keys %$value)[0] eq '='
2397       ) {
2398         $new_data{$col} = $value->{'='};
2399       }
2400       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2401         $new_data{$col} = $value;
2402       }
2403     }
2404   }
2405
2406   %new_data = (
2407     %new_data,
2408     %{ $self->_remove_alias($data, $alias) },
2409   );
2410
2411   return (\%new_data, \@cols_from_relations);
2412 }
2413
2414 # _has_resolved_attr
2415 #
2416 # determines if the resultset defines at least one
2417 # of the attributes supplied
2418 #
2419 # used to determine if a subquery is neccessary
2420 #
2421 # supports some virtual attributes:
2422 #   -join
2423 #     This will scan for any joins being present on the resultset.
2424 #     It is not a mere key-search but a deep inspection of {from}
2425 #
2426
2427 sub _has_resolved_attr {
2428   my ($self, @attr_names) = @_;
2429
2430   my $attrs = $self->_resolved_attrs;
2431
2432   my %extra_checks;
2433
2434   for my $n (@attr_names) {
2435     if (grep { $n eq $_ } (qw/-join/) ) {
2436       $extra_checks{$n}++;
2437       next;
2438     }
2439
2440     my $attr =  $attrs->{$n};
2441
2442     next if not defined $attr;
2443
2444     if (ref $attr eq 'HASH') {
2445       return 1 if keys %$attr;
2446     }
2447     elsif (ref $attr eq 'ARRAY') {
2448       return 1 if @$attr;
2449     }
2450     else {
2451       return 1 if $attr;
2452     }
2453   }
2454
2455   # a resolved join is expressed as a multi-level from
2456   return 1 if (
2457     $extra_checks{-join}
2458       and
2459     ref $attrs->{from} eq 'ARRAY'
2460       and
2461     @{$attrs->{from}} > 1
2462   );
2463
2464   return 0;
2465 }
2466
2467 # _collapse_cond
2468 #
2469 # Recursively collapse the condition.
2470
2471 sub _collapse_cond {
2472   my ($self, $cond, $collapsed) = @_;
2473
2474   $collapsed ||= {};
2475
2476   if (ref $cond eq 'ARRAY') {
2477     foreach my $subcond (@$cond) {
2478       next unless ref $subcond;  # -or
2479       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2480     }
2481   }
2482   elsif (ref $cond eq 'HASH') {
2483     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2484       foreach my $subcond (@{$cond->{-and}}) {
2485         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2486       }
2487     }
2488     else {
2489       foreach my $col (keys %$cond) {
2490         my $value = $cond->{$col};
2491         $collapsed->{$col} = $value;
2492       }
2493     }
2494   }
2495
2496   return $collapsed;
2497 }
2498
2499 # _remove_alias
2500 #
2501 # Remove the specified alias from the specified query hash. A copy is made so
2502 # the original query is not modified.
2503
2504 sub _remove_alias {
2505   my ($self, $query, $alias) = @_;
2506
2507   my %orig = %{ $query || {} };
2508   my %unaliased;
2509
2510   foreach my $key (keys %orig) {
2511     if ($key !~ /\./) {
2512       $unaliased{$key} = $orig{$key};
2513       next;
2514     }
2515     $unaliased{$1} = $orig{$key}
2516       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2517   }
2518
2519   return \%unaliased;
2520 }
2521
2522 =head2 as_query
2523
2524 =over 4
2525
2526 =item Arguments: none
2527
2528 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2529
2530 =back
2531
2532 Returns the SQL query and bind vars associated with the invocant.
2533
2534 This is generally used as the RHS for a subquery.
2535
2536 =cut
2537
2538 sub as_query {
2539   my $self = shift;
2540
2541   my $attrs = { %{ $self->_resolved_attrs } };
2542
2543   $self->result_source->storage->_select_args_to_query (
2544     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2545   );
2546 }
2547
2548 =head2 find_or_new
2549
2550 =over 4
2551
2552 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2553
2554 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2555
2556 =back
2557
2558   my $artist = $schema->resultset('Artist')->find_or_new(
2559     { artist => 'fred' }, { key => 'artists' });
2560
2561   $cd->cd_to_producer->find_or_new({ producer => $producer },
2562                                    { key => 'primary });
2563
2564 Find an existing record from this resultset using L</find>. if none exists,
2565 instantiate a new result object and return it. The object will not be saved
2566 into your storage until you call L<DBIx::Class::Row/insert> on it.
2567
2568 You most likely want this method when looking for existing rows using a unique
2569 constraint that is not the primary key, or looking for related rows.
2570
2571 If you want objects to be saved immediately, use L</find_or_create> instead.
2572
2573 B<Note>: Make sure to read the documentation of L</find> and understand the
2574 significance of the C<key> attribute, as its lack may skew your search, and
2575 subsequently result in spurious new objects.
2576
2577 B<Note>: Take care when using C<find_or_new> with a table having
2578 columns with default values that you intend to be automatically
2579 supplied by the database (e.g. an auto_increment primary key column).
2580 In normal usage, the value of such columns should NOT be included at
2581 all in the call to C<find_or_new>, even when set to C<undef>.
2582
2583 =cut
2584
2585 sub find_or_new {
2586   my $self     = shift;
2587   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2588   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2589   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2590     return $row;
2591   }
2592   return $self->new_result($hash);
2593 }
2594
2595 =head2 create
2596
2597 =over 4
2598
2599 =item Arguments: \%col_data
2600
2601 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2602
2603 =back
2604
2605 Attempt to create a single new row or a row with multiple related rows
2606 in the table represented by the resultset (and related tables). This
2607 will not check for duplicate rows before inserting, use
2608 L</find_or_create> to do that.
2609
2610 To create one row for this resultset, pass a hashref of key/value
2611 pairs representing the columns of the table and the values you wish to
2612 store. If the appropriate relationships are set up, foreign key fields
2613 can also be passed an object representing the foreign row, and the
2614 value will be set to its primary key.
2615
2616 To create related objects, pass a hashref of related-object column values
2617 B<keyed on the relationship name>. If the relationship is of type C<multi>
2618 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2619 The process will correctly identify columns holding foreign keys, and will
2620 transparently populate them from the keys of the corresponding relation.
2621 This can be applied recursively, and will work correctly for a structure
2622 with an arbitrary depth and width, as long as the relationships actually
2623 exists and the correct column data has been supplied.
2624
2625 Instead of hashrefs of plain related data (key/value pairs), you may
2626 also pass new or inserted objects. New objects (not inserted yet, see
2627 L</new_result>), will be inserted into their appropriate tables.
2628
2629 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2630
2631 Example of creating a new row.
2632
2633   $person_rs->create({
2634     name=>"Some Person",
2635     email=>"somebody@someplace.com"
2636   });
2637
2638 Example of creating a new row and also creating rows in a related C<has_many>
2639 or C<has_one> resultset.  Note Arrayref.
2640
2641   $artist_rs->create(
2642      { artistid => 4, name => 'Manufactured Crap', cds => [
2643         { title => 'My First CD', year => 2006 },
2644         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2645       ],
2646      },
2647   );
2648
2649 Example of creating a new row and also creating a row in a related
2650 C<belongs_to> resultset. Note Hashref.
2651
2652   $cd_rs->create({
2653     title=>"Music for Silly Walks",
2654     year=>2000,
2655     artist => {
2656       name=>"Silly Musician",
2657     }
2658   });
2659
2660 =over
2661
2662 =item WARNING
2663
2664 When subclassing ResultSet never attempt to override this method. Since
2665 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2666 lot of the internals simply never call it, so your override will be
2667 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2668 or L<DBIx::Class::Row/insert> depending on how early in the
2669 L</create> process you need to intervene. See also warning pertaining to
2670 L</new>.
2671
2672 =back
2673
2674 =cut
2675
2676 sub create {
2677   my ($self, $attrs) = @_;
2678   $self->throw_exception( "create needs a hashref" )
2679     unless ref $attrs eq 'HASH';
2680   return $self->new_result($attrs)->insert;
2681 }
2682
2683 =head2 find_or_create
2684
2685 =over 4
2686
2687 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2688
2689 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2690
2691 =back
2692
2693   $cd->cd_to_producer->find_or_create({ producer => $producer },
2694                                       { key => 'primary' });
2695
2696 Tries to find a record based on its primary key or unique constraints; if none
2697 is found, creates one and returns that instead.
2698
2699   my $cd = $schema->resultset('CD')->find_or_create({
2700     cdid   => 5,
2701     artist => 'Massive Attack',
2702     title  => 'Mezzanine',
2703     year   => 2005,
2704   });
2705
2706 Also takes an optional C<key> attribute, to search by a specific key or unique
2707 constraint. For example:
2708
2709   my $cd = $schema->resultset('CD')->find_or_create(
2710     {
2711       artist => 'Massive Attack',
2712       title  => 'Mezzanine',
2713     },
2714     { key => 'cd_artist_title' }
2715   );
2716
2717 B<Note>: Make sure to read the documentation of L</find> and understand the
2718 significance of the C<key> attribute, as its lack may skew your search, and
2719 subsequently result in spurious row creation.
2720
2721 B<Note>: Because find_or_create() reads from the database and then
2722 possibly inserts based on the result, this method is subject to a race
2723 condition. Another process could create a record in the table after
2724 the find has completed and before the create has started. To avoid
2725 this problem, use find_or_create() inside a transaction.
2726
2727 B<Note>: Take care when using C<find_or_create> with a table having
2728 columns with default values that you intend to be automatically
2729 supplied by the database (e.g. an auto_increment primary key column).
2730 In normal usage, the value of such columns should NOT be included at
2731 all in the call to C<find_or_create>, even when set to C<undef>.
2732
2733 See also L</find> and L</update_or_create>. For information on how to declare
2734 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2735
2736 If you need to know if an existing row was found or a new one created use
2737 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2738 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2739 database!
2740
2741   my $cd = $schema->resultset('CD')->find_or_new({
2742     cdid   => 5,
2743     artist => 'Massive Attack',
2744     title  => 'Mezzanine',
2745     year   => 2005,
2746   });
2747
2748   if( !$cd->in_storage ) {
2749       # do some stuff
2750       $cd->insert;
2751   }
2752
2753 =cut
2754
2755 sub find_or_create {
2756   my $self     = shift;
2757   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2758   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2759   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2760     return $row;
2761   }
2762   return $self->create($hash);
2763 }
2764
2765 =head2 update_or_create
2766
2767 =over 4
2768
2769 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2770
2771 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2772
2773 =back
2774
2775   $resultset->update_or_create({ col => $val, ... });
2776
2777 Like L</find_or_create>, but if a row is found it is immediately updated via
2778 C<< $found_row->update (\%col_data) >>.
2779
2780
2781 Takes an optional C<key> attribute to search on a specific unique constraint.
2782 For example:
2783
2784   # In your application
2785   my $cd = $schema->resultset('CD')->update_or_create(
2786     {
2787       artist => 'Massive Attack',
2788       title  => 'Mezzanine',
2789       year   => 1998,
2790     },
2791     { key => 'cd_artist_title' }
2792   );
2793
2794   $cd->cd_to_producer->update_or_create({
2795     producer => $producer,
2796     name => 'harry',
2797   }, {
2798     key => 'primary',
2799   });
2800
2801 B<Note>: Make sure to read the documentation of L</find> and understand the
2802 significance of the C<key> attribute, as its lack may skew your search, and
2803 subsequently result in spurious row creation.
2804
2805 B<Note>: Take care when using C<update_or_create> with a table having
2806 columns with default values that you intend to be automatically
2807 supplied by the database (e.g. an auto_increment primary key column).
2808 In normal usage, the value of such columns should NOT be included at
2809 all in the call to C<update_or_create>, even when set to C<undef>.
2810
2811 See also L</find> and L</find_or_create>. For information on how to declare
2812 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2813
2814 If you need to know if an existing row was updated or a new one created use
2815 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2816 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2817 database!
2818
2819 =cut
2820
2821 sub update_or_create {
2822   my $self = shift;
2823   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2824   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2825
2826   my $row = $self->find($cond, $attrs);
2827   if (defined $row) {
2828     $row->update($cond);
2829     return $row;
2830   }
2831
2832   return $self->create($cond);
2833 }
2834
2835 =head2 update_or_new
2836
2837 =over 4
2838
2839 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2840
2841 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2842
2843 =back
2844
2845   $resultset->update_or_new({ col => $val, ... });
2846
2847 Like L</find_or_new> but if a row is found it is immediately updated via
2848 C<< $found_row->update (\%col_data) >>.
2849
2850 For example:
2851
2852   # In your application
2853   my $cd = $schema->resultset('CD')->update_or_new(
2854     {
2855       artist => 'Massive Attack',
2856       title  => 'Mezzanine',
2857       year   => 1998,
2858     },
2859     { key => 'cd_artist_title' }
2860   );
2861
2862   if ($cd->in_storage) {
2863       # the cd was updated
2864   }
2865   else {
2866       # the cd is not yet in the database, let's insert it
2867       $cd->insert;
2868   }
2869
2870 B<Note>: Make sure to read the documentation of L</find> and understand the
2871 significance of the C<key> attribute, as its lack may skew your search, and
2872 subsequently result in spurious new objects.
2873
2874 B<Note>: Take care when using C<update_or_new> with a table having
2875 columns with default values that you intend to be automatically
2876 supplied by the database (e.g. an auto_increment primary key column).
2877 In normal usage, the value of such columns should NOT be included at
2878 all in the call to C<update_or_new>, even when set to C<undef>.
2879
2880 See also L</find>, L</find_or_create> and L</find_or_new>.
2881
2882 =cut
2883
2884 sub update_or_new {
2885     my $self  = shift;
2886     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2887     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2888
2889     my $row = $self->find( $cond, $attrs );
2890     if ( defined $row ) {
2891         $row->update($cond);
2892         return $row;
2893     }
2894
2895     return $self->new_result($cond);
2896 }
2897
2898 =head2 get_cache
2899
2900 =over 4
2901
2902 =item Arguments: none
2903
2904 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2905
2906 =back
2907
2908 Gets the contents of the cache for the resultset, if the cache is set.
2909
2910 The cache is populated either by using the L</prefetch> attribute to
2911 L</search> or by calling L</set_cache>.
2912
2913 =cut
2914
2915 sub get_cache {
2916   shift->{all_cache};
2917 }
2918
2919 =head2 set_cache
2920
2921 =over 4
2922
2923 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2924
2925 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2926
2927 =back
2928
2929 Sets the contents of the cache for the resultset. Expects an arrayref
2930 of objects of the same class as those produced by the resultset. Note that
2931 if the cache is set, the resultset will return the cached objects rather
2932 than re-querying the database even if the cache attr is not set.
2933
2934 The contents of the cache can also be populated by using the
2935 L</prefetch> attribute to L</search>.
2936
2937 =cut
2938
2939 sub set_cache {
2940   my ( $self, $data ) = @_;
2941   $self->throw_exception("set_cache requires an arrayref")
2942       if defined($data) && (ref $data ne 'ARRAY');
2943   $self->{all_cache} = $data;
2944 }
2945
2946 =head2 clear_cache
2947
2948 =over 4
2949
2950 =item Arguments: none
2951
2952 =item Return Value: undef
2953
2954 =back
2955
2956 Clears the cache for the resultset.
2957
2958 =cut
2959
2960 sub clear_cache {
2961   shift->set_cache(undef);
2962 }
2963
2964 =head2 is_paged
2965
2966 =over 4
2967
2968 =item Arguments: none
2969
2970 =item Return Value: true, if the resultset has been paginated
2971
2972 =back
2973
2974 =cut
2975
2976 sub is_paged {
2977   my ($self) = @_;
2978   return !!$self->{attrs}{page};
2979 }
2980
2981 =head2 is_ordered
2982
2983 =over 4
2984
2985 =item Arguments: none
2986
2987 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2988
2989 =back
2990
2991 =cut
2992
2993 sub is_ordered {
2994   my ($self) = @_;
2995   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2996 }
2997
2998 =head2 related_resultset
2999
3000 =over 4
3001
3002 =item Arguments: $rel_name
3003
3004 =item Return Value: L<$resultset|/search>
3005
3006 =back
3007
3008 Returns a related resultset for the supplied relationship name.
3009
3010   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3011
3012 =cut
3013
3014 sub related_resultset {
3015   my ($self, $rel) = @_;
3016
3017   $self->{related_resultsets} ||= {};
3018   return $self->{related_resultsets}{$rel} ||= do {
3019     my $rsrc = $self->result_source;
3020     my $rel_info = $rsrc->relationship_info($rel);
3021
3022     $self->throw_exception(
3023       "search_related: result source '" . $rsrc->source_name .
3024         "' has no such relationship $rel")
3025       unless $rel_info;
3026
3027     my $attrs = $self->_chain_relationship($rel);
3028
3029     my $join_count = $attrs->{seen_join}{$rel};
3030
3031     my $alias = $self->result_source->storage
3032         ->relname_to_table_alias($rel, $join_count);
3033
3034     # since this is search_related, and we already slid the select window inwards
3035     # (the select/as attrs were deleted in the beginning), we need to flip all
3036     # left joins to inner, so we get the expected results
3037     # read the comment on top of the actual function to see what this does
3038     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3039
3040
3041     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3042     delete @{$attrs}{qw(result_class alias)};
3043
3044     my $new_cache;
3045
3046     if (my $cache = $self->get_cache) {
3047       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3048         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3049                         @$cache ];
3050       }
3051     }
3052
3053     my $rel_source = $rsrc->related_source($rel);
3054
3055     my $new = do {
3056
3057       # The reason we do this now instead of passing the alias to the
3058       # search_rs below is that if you wrap/overload resultset on the
3059       # source you need to know what alias it's -going- to have for things
3060       # to work sanely (e.g. RestrictWithObject wants to be able to add
3061       # extra query restrictions, and these may need to be $alias.)
3062
3063       my $rel_attrs = $rel_source->resultset_attributes;
3064       local $rel_attrs->{alias} = $alias;
3065
3066       $rel_source->resultset
3067                  ->search_rs(
3068                      undef, {
3069                        %$attrs,
3070                        where => $attrs->{where},
3071                    });
3072     };
3073     $new->set_cache($new_cache) if $new_cache;
3074     $new;
3075   };
3076 }
3077
3078 =head2 current_source_alias
3079
3080 =over 4
3081
3082 =item Arguments: none
3083
3084 =item Return Value: $source_alias
3085
3086 =back
3087
3088 Returns the current table alias for the result source this resultset is built
3089 on, that will be used in the SQL query. Usually it is C<me>.
3090
3091 Currently the source alias that refers to the result set returned by a
3092 L</search>/L</find> family method depends on how you got to the resultset: it's
3093 C<me> by default, but eg. L</search_related> aliases it to the related result
3094 source name (and keeps C<me> referring to the original result set). The long
3095 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3096 (and make this method unnecessary).
3097
3098 Thus it's currently necessary to use this method in predefined queries (see
3099 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3100 source alias of the current result set:
3101
3102   # in a result set class
3103   sub modified_by {
3104     my ($self, $user) = @_;
3105
3106     my $me = $self->current_source_alias;
3107
3108     return $self->search({
3109       "$me.modified" => $user->id,
3110     });
3111   }
3112
3113 =cut
3114
3115 sub current_source_alias {
3116   return (shift->{attrs} || {})->{alias} || 'me';
3117 }
3118
3119 =head2 as_subselect_rs
3120
3121 =over 4
3122
3123 =item Arguments: none
3124
3125 =item Return Value: L<$resultset|/search>
3126
3127 =back
3128
3129 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3130 "virtual view" by including it as a subquery within the from clause.  From this
3131 point on, any joined tables are inaccessible to ->search on the resultset (as if
3132 it were simply where-filtered without joins).  For example:
3133
3134  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3135
3136  # 'x' now pollutes the query namespace
3137
3138  # So the following works as expected
3139  my $ok_rs = $rs->search({'x.other' => 1});
3140
3141  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3142  # def) we look for one row with contradictory terms and join in another table
3143  # (aliased 'x_2') which we never use
3144  my $broken_rs = $rs->search({'x.name' => 'def'});
3145
3146  my $rs2 = $rs->as_subselect_rs;
3147
3148  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3149  my $not_joined_rs = $rs2->search({'x.other' => 1});
3150
3151  # works as expected: finds a 'table' row related to two x rows (abc and def)
3152  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3153
3154 Another example of when one might use this would be to select a subset of
3155 columns in a group by clause:
3156
3157  my $rs = $schema->resultset('Bar')->search(undef, {
3158    group_by => [qw{ id foo_id baz_id }],
3159  })->as_subselect_rs->search(undef, {
3160    columns => [qw{ id foo_id }]
3161  });
3162
3163 In the above example normally columns would have to be equal to the group by,
3164 but because we isolated the group by into a subselect the above works.
3165
3166 =cut
3167
3168 sub as_subselect_rs {
3169   my $self = shift;
3170
3171   my $attrs = $self->_resolved_attrs;
3172
3173   my $fresh_rs = (ref $self)->new (
3174     $self->result_source
3175   );
3176
3177   # these pieces will be locked in the subquery
3178   delete $fresh_rs->{cond};
3179   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3180
3181   return $fresh_rs->search( {}, {
3182     from => [{
3183       $attrs->{alias} => $self->as_query,
3184       -alias  => $attrs->{alias},
3185       -rsrc   => $self->result_source,
3186     }],
3187     alias => $attrs->{alias},
3188   });
3189 }
3190
3191 # This code is called by search_related, and makes sure there
3192 # is clear separation between the joins before, during, and
3193 # after the relationship. This information is needed later
3194 # in order to properly resolve prefetch aliases (any alias
3195 # with a relation_chain_depth less than the depth of the
3196 # current prefetch is not considered)
3197 #
3198 # The increments happen twice per join. An even number means a
3199 # relationship specified via a search_related, whereas an odd
3200 # number indicates a join/prefetch added via attributes
3201 #
3202 # Also this code will wrap the current resultset (the one we
3203 # chain to) in a subselect IFF it contains limiting attributes
3204 sub _chain_relationship {
3205   my ($self, $rel) = @_;
3206   my $source = $self->result_source;
3207   my $attrs = { %{$self->{attrs}||{}} };
3208
3209   # we need to take the prefetch the attrs into account before we
3210   # ->_resolve_join as otherwise they get lost - captainL
3211   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3212
3213   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3214
3215   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3216
3217   my $from;
3218   my @force_subq_attrs = qw/offset rows group_by having/;
3219
3220   if (
3221     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3222       ||
3223     $self->_has_resolved_attr (@force_subq_attrs)
3224   ) {
3225     # Nuke the prefetch (if any) before the new $rs attrs
3226     # are resolved (prefetch is useless - we are wrapping
3227     # a subquery anyway).
3228     my $rs_copy = $self->search;
3229     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3230       $rs_copy->{attrs}{join},
3231       delete $rs_copy->{attrs}{prefetch},
3232     );
3233
3234     $from = [{
3235       -rsrc   => $source,
3236       -alias  => $attrs->{alias},
3237       $attrs->{alias} => $rs_copy->as_query,
3238     }];
3239     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3240     $seen->{-relation_chain_depth} = 0;
3241   }
3242   elsif ($attrs->{from}) {  #shallow copy suffices
3243     $from = [ @{$attrs->{from}} ];
3244   }
3245   else {
3246     $from = [{
3247       -rsrc  => $source,
3248       -alias => $attrs->{alias},
3249       $attrs->{alias} => $source->from,
3250     }];
3251   }
3252
3253   my $jpath = ($seen->{-relation_chain_depth})
3254     ? $from->[-1][0]{-join_path}
3255     : [];
3256
3257   my @requested_joins = $source->_resolve_join(
3258     $join,
3259     $attrs->{alias},
3260     $seen,
3261     $jpath,
3262   );
3263
3264   push @$from, @requested_joins;
3265
3266   $seen->{-relation_chain_depth}++;
3267
3268   # if $self already had a join/prefetch specified on it, the requested
3269   # $rel might very well be already included. What we do in this case
3270   # is effectively a no-op (except that we bump up the chain_depth on
3271   # the join in question so we could tell it *is* the search_related)
3272   my $already_joined;
3273
3274   # we consider the last one thus reverse
3275   for my $j (reverse @requested_joins) {
3276     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3277     if ($rel eq $last_j) {
3278       $j->[0]{-relation_chain_depth}++;
3279       $already_joined++;
3280       last;
3281     }
3282   }
3283
3284   unless ($already_joined) {
3285     push @$from, $source->_resolve_join(
3286       $rel,
3287       $attrs->{alias},
3288       $seen,
3289       $jpath,
3290     );
3291   }
3292
3293   $seen->{-relation_chain_depth}++;
3294
3295   return {%$attrs, from => $from, seen_join => $seen};
3296 }
3297
3298 sub _resolved_attrs {
3299   my $self = shift;
3300   return $self->{_attrs} if $self->{_attrs};
3301
3302   my $attrs  = { %{ $self->{attrs} || {} } };
3303   my $source = $self->result_source;
3304   my $alias  = $attrs->{alias};
3305
3306   # default selection list
3307   $attrs->{columns} = [ $source->columns ]
3308     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3309
3310   # merge selectors together
3311   for (qw/columns select as/) {
3312     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3313       if $attrs->{$_} or $attrs->{"+$_"};
3314   }
3315
3316   # disassemble columns
3317   my (@sel, @as);
3318   if (my $cols = delete $attrs->{columns}) {
3319     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3320       if (ref $c eq 'HASH') {
3321         for my $as (sort keys %$c) {
3322           push @sel, $c->{$as};
3323           push @as, $as;
3324         }
3325       }
3326       else {
3327         push @sel, $c;
3328         push @as, $c;
3329       }
3330     }
3331   }
3332
3333   # when trying to weed off duplicates later do not go past this point -
3334   # everything added from here on is unbalanced "anyone's guess" stuff
3335   my $dedup_stop_idx = $#as;
3336
3337   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3338     if $attrs->{as};
3339   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3340     if $attrs->{select};
3341
3342   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3343   for (@sel) {
3344     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3345   }
3346
3347   # disqualify all $alias.col as-bits (collapser mandated)
3348   for (@as) {
3349     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3350   }
3351
3352   # de-duplicate the result (remove *identical* select/as pairs)
3353   # and also die on duplicate {as} pointing to different {select}s
3354   # not using a c-style for as the condition is prone to shrinkage
3355   my $seen;
3356   my $i = 0;
3357   while ($i <= $dedup_stop_idx) {
3358     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3359       splice @sel, $i, 1;
3360       splice @as, $i, 1;
3361       $dedup_stop_idx--;
3362     }
3363     elsif ($seen->{$as[$i]}++) {
3364       $self->throw_exception(
3365         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3366       );
3367     }
3368     else {
3369       $i++;
3370     }
3371   }
3372
3373   $attrs->{select} = \@sel;
3374   $attrs->{as} = \@as;
3375
3376   $attrs->{from} ||= [{
3377     -rsrc   => $source,
3378     -alias  => $self->{attrs}{alias},
3379     $self->{attrs}{alias} => $source->from,
3380   }];
3381
3382   if ( $attrs->{join} || $attrs->{prefetch} ) {
3383
3384     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3385       if ref $attrs->{from} ne 'ARRAY';
3386
3387     my $join = (delete $attrs->{join}) || {};
3388
3389     if ( defined $attrs->{prefetch} ) {
3390       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3391     }
3392
3393     $attrs->{from} =    # have to copy here to avoid corrupting the original
3394       [
3395         @{ $attrs->{from} },
3396         $source->_resolve_join(
3397           $join,
3398           $alias,
3399           { %{ $attrs->{seen_join} || {} } },
3400           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3401             ? $attrs->{from}[-1][0]{-join_path}
3402             : []
3403           ,
3404         )
3405       ];
3406   }
3407
3408   if ( defined $attrs->{order_by} ) {
3409     $attrs->{order_by} = (
3410       ref( $attrs->{order_by} ) eq 'ARRAY'
3411       ? [ @{ $attrs->{order_by} } ]
3412       : [ $attrs->{order_by} || () ]
3413     );
3414   }
3415
3416   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3417     $attrs->{group_by} = [ $attrs->{group_by} ];
3418   }
3419
3420   # generate the distinct induced group_by early, as prefetch will be carried via a
3421   # subquery (since a group_by is present)
3422   if (delete $attrs->{distinct}) {
3423     if ($attrs->{group_by}) {
3424       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3425     }
3426     else {
3427       # distinct affects only the main selection part, not what prefetch may
3428       # add below.
3429       $attrs->{group_by} = $source->storage->_group_over_selection (
3430         $attrs->{from},
3431         $attrs->{select},
3432         $attrs->{order_by},
3433       );
3434     }
3435   }
3436
3437   $attrs->{collapse} ||= {};
3438   if ($attrs->{prefetch}) {
3439
3440     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3441       if $attrs->{_dark_selector};
3442
3443     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3444
3445     my $prefetch_ordering = [];
3446
3447     # this is a separate structure (we don't look in {from} directly)
3448     # as the resolver needs to shift things off the lists to work
3449     # properly (identical-prefetches on different branches)
3450     my $join_map = {};
3451     if (ref $attrs->{from} eq 'ARRAY') {
3452
3453       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3454
3455       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3456         next unless $j->[0]{-alias};
3457         next unless $j->[0]{-join_path};
3458         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3459
3460         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3461
3462         my $p = $join_map;
3463         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3464         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3465       }
3466     }
3467
3468     my @prefetch =
3469       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3470
3471     # we need to somehow mark which columns came from prefetch
3472     if (@prefetch) {
3473       my $sel_end = $#{$attrs->{select}};
3474       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3475     }
3476
3477     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3478     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3479
3480     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3481     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3482   }
3483
3484   # if both page and offset are specified, produce a combined offset
3485   # even though it doesn't make much sense, this is what pre 081xx has
3486   # been doing
3487   if (my $page = delete $attrs->{page}) {
3488     $attrs->{offset} =
3489       ($attrs->{rows} * ($page - 1))
3490             +
3491       ($attrs->{offset} || 0)
3492     ;
3493   }
3494
3495   return $self->{_attrs} = $attrs;
3496 }
3497
3498 sub _rollout_attr {
3499   my ($self, $attr) = @_;
3500
3501   if (ref $attr eq 'HASH') {
3502     return $self->_rollout_hash($attr);
3503   } elsif (ref $attr eq 'ARRAY') {
3504     return $self->_rollout_array($attr);
3505   } else {
3506     return [$attr];
3507   }
3508 }
3509
3510 sub _rollout_array {
3511   my ($self, $attr) = @_;
3512
3513   my @rolled_array;
3514   foreach my $element (@{$attr}) {
3515     if (ref $element eq 'HASH') {
3516       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3517     } elsif (ref $element eq 'ARRAY') {
3518       #  XXX - should probably recurse here
3519       push( @rolled_array, @{$self->_rollout_array($element)} );
3520     } else {
3521       push( @rolled_array, $element );
3522     }
3523   }
3524   return \@rolled_array;
3525 }
3526
3527 sub _rollout_hash {
3528   my ($self, $attr) = @_;
3529
3530   my @rolled_array;
3531   foreach my $key (keys %{$attr}) {
3532     push( @rolled_array, { $key => $attr->{$key} } );
3533   }
3534   return \@rolled_array;
3535 }
3536
3537 sub _calculate_score {
3538   my ($self, $a, $b) = @_;
3539
3540   if (defined $a xor defined $b) {
3541     return 0;
3542   }
3543   elsif (not defined $a) {
3544     return 1;
3545   }
3546
3547   if (ref $b eq 'HASH') {
3548     my ($b_key) = keys %{$b};
3549     if (ref $a eq 'HASH') {
3550       my ($a_key) = keys %{$a};
3551       if ($a_key eq $b_key) {
3552         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3553       } else {
3554         return 0;
3555       }
3556     } else {
3557       return ($a eq $b_key) ? 1 : 0;
3558     }
3559   } else {
3560     if (ref $a eq 'HASH') {
3561       my ($a_key) = keys %{$a};
3562       return ($b eq $a_key) ? 1 : 0;
3563     } else {
3564       return ($b eq $a) ? 1 : 0;
3565     }
3566   }
3567 }
3568
3569 sub _merge_joinpref_attr {
3570   my ($self, $orig, $import) = @_;
3571
3572   return $import unless defined($orig);
3573   return $orig unless defined($import);
3574
3575   $orig = $self->_rollout_attr($orig);
3576   $import = $self->_rollout_attr($import);
3577
3578   my $seen_keys;
3579   foreach my $import_element ( @{$import} ) {
3580     # find best candidate from $orig to merge $b_element into
3581     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3582     foreach my $orig_element ( @{$orig} ) {
3583       my $score = $self->_calculate_score( $orig_element, $import_element );
3584       if ($score > $best_candidate->{score}) {
3585         $best_candidate->{position} = $position;
3586         $best_candidate->{score} = $score;
3587       }
3588       $position++;
3589     }
3590     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3591     $import_key = '' if not defined $import_key;
3592
3593     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3594       push( @{$orig}, $import_element );
3595     } else {
3596       my $orig_best = $orig->[$best_candidate->{position}];
3597       # merge orig_best and b_element together and replace original with merged
3598       if (ref $orig_best ne 'HASH') {
3599         $orig->[$best_candidate->{position}] = $import_element;
3600       } elsif (ref $import_element eq 'HASH') {
3601         my ($key) = keys %{$orig_best};
3602         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3603       }
3604     }
3605     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3606   }
3607
3608   return $orig;
3609 }
3610
3611 {
3612   my $hm;
3613
3614   sub _merge_attr {
3615     $hm ||= do {
3616       require Hash::Merge;
3617       my $hm = Hash::Merge->new;
3618
3619       $hm->specify_behavior({
3620         SCALAR => {
3621           SCALAR => sub {
3622             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3623
3624             if ($defl xor $defr) {
3625               return [ $defl ? $_[0] : $_[1] ];
3626             }
3627             elsif (! $defl) {
3628               return [];
3629             }
3630             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3631               return [ $_[0] ];
3632             }
3633             else {
3634               return [$_[0], $_[1]];
3635             }
3636           },
3637           ARRAY => sub {
3638             return $_[1] if !defined $_[0];
3639             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3640             return [$_[0], @{$_[1]}]
3641           },
3642           HASH  => sub {
3643             return [] if !defined $_[0] and !keys %{$_[1]};
3644             return [ $_[1] ] if !defined $_[0];
3645             return [ $_[0] ] if !keys %{$_[1]};
3646             return [$_[0], $_[1]]
3647           },
3648         },
3649         ARRAY => {
3650           SCALAR => sub {
3651             return $_[0] if !defined $_[1];
3652             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3653             return [@{$_[0]}, $_[1]]
3654           },
3655           ARRAY => sub {
3656             my @ret = @{$_[0]} or return $_[1];
3657             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3658             my %idx = map { $_ => 1 } @ret;
3659             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3660             \@ret;
3661           },
3662           HASH => sub {
3663             return [ $_[1] ] if ! @{$_[0]};
3664             return $_[0] if !keys %{$_[1]};
3665             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3666             return [ @{$_[0]}, $_[1] ];
3667           },
3668         },
3669         HASH => {
3670           SCALAR => sub {
3671             return [] if !keys %{$_[0]} and !defined $_[1];
3672             return [ $_[0] ] if !defined $_[1];
3673             return [ $_[1] ] if !keys %{$_[0]};
3674             return [$_[0], $_[1]]
3675           },
3676           ARRAY => sub {
3677             return [] if !keys %{$_[0]} and !@{$_[1]};
3678             return [ $_[0] ] if !@{$_[1]};
3679             return $_[1] if !keys %{$_[0]};
3680             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3681             return [ $_[0], @{$_[1]} ];
3682           },
3683           HASH => sub {
3684             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3685             return [ $_[0] ] if !keys %{$_[1]};
3686             return [ $_[1] ] if !keys %{$_[0]};
3687             return [ $_[0] ] if $_[0] eq $_[1];
3688             return [ $_[0], $_[1] ];
3689           },
3690         }
3691       } => 'DBIC_RS_ATTR_MERGER');
3692       $hm;
3693     };
3694
3695     return $hm->merge ($_[1], $_[2]);
3696   }
3697 }
3698
3699 sub STORABLE_freeze {
3700   my ($self, $cloning) = @_;
3701   my $to_serialize = { %$self };
3702
3703   # A cursor in progress can't be serialized (and would make little sense anyway)
3704   delete $to_serialize->{cursor};
3705
3706   # nor is it sensical to store a not-yet-fired-count pager
3707   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3708     delete $to_serialize->{pager};
3709   }
3710
3711   Storable::nfreeze($to_serialize);
3712 }
3713
3714 # need this hook for symmetry
3715 sub STORABLE_thaw {
3716   my ($self, $cloning, $serialized) = @_;
3717
3718   %$self = %{ Storable::thaw($serialized) };
3719
3720   $self;
3721 }
3722
3723
3724 =head2 throw_exception
3725
3726 See L<DBIx::Class::Schema/throw_exception> for details.
3727
3728 =cut
3729
3730 sub throw_exception {
3731   my $self=shift;
3732
3733   if (ref $self and my $rsrc = $self->result_source) {
3734     $rsrc->throw_exception(@_)
3735   }
3736   else {
3737     DBIx::Class::Exception->throw(@_);
3738   }
3739 }
3740
3741 # XXX: FIXME: Attributes docs need clearing up
3742
3743 =head1 ATTRIBUTES
3744
3745 Attributes are used to refine a ResultSet in various ways when
3746 searching for data. They can be passed to any method which takes an
3747 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3748 L</count>.
3749
3750 Default attributes can be set on the result class using
3751 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3752 the CAVEATS on that feature before using it!)
3753
3754 These are in no particular order:
3755
3756 =head2 order_by
3757
3758 =over 4
3759
3760 =item Value: ( $order_by | \@order_by | \%order_by )
3761
3762 =back
3763
3764 Which column(s) to order the results by.
3765
3766 [The full list of suitable values is documented in
3767 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3768 common options.]
3769
3770 If a single column name, or an arrayref of names is supplied, the
3771 argument is passed through directly to SQL. The hashref syntax allows
3772 for connection-agnostic specification of ordering direction:
3773
3774  For descending order:
3775
3776   order_by => { -desc => [qw/col1 col2 col3/] }
3777
3778  For explicit ascending order:
3779
3780   order_by => { -asc => 'col' }
3781
3782 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3783 supported, although you are strongly encouraged to use the hashref
3784 syntax as outlined above.
3785
3786 =head2 columns
3787
3788 =over 4
3789
3790 =item Value: \@columns
3791
3792 =back
3793
3794 Shortcut to request a particular set of columns to be retrieved. Each
3795 column spec may be a string (a table column name), or a hash (in which
3796 case the key is the C<as> value, and the value is used as the C<select>
3797 expression). Adds C<me.> onto the start of any column without a C<.> in
3798 it and sets C<select> from that, then auto-populates C<as> from
3799 C<select> as normal. (You may also use the C<cols> attribute, as in
3800 earlier versions of DBIC, but this is deprecated.)
3801
3802 Essentially C<columns> does the same as L</select> and L</as>.
3803
3804     columns => [ 'foo', { bar => 'baz' } ]
3805
3806 is the same as
3807
3808     select => [qw/foo baz/],
3809     as => [qw/foo bar/]
3810
3811 =head2 +columns
3812
3813 =over 4
3814
3815 =item Value: \@columns
3816
3817 =back
3818
3819 Indicates additional columns to be selected from storage. Works the same as
3820 L</columns> but adds columns to the selection. (You may also use the
3821 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3822 deprecated). For example:-
3823
3824   $schema->resultset('CD')->search(undef, {
3825     '+columns' => ['artist.name'],
3826     join => ['artist']
3827   });
3828
3829 would return all CDs and include a 'name' column to the information
3830 passed to object inflation. Note that the 'artist' is the name of the
3831 column (or relationship) accessor, and 'name' is the name of the column
3832 accessor in the related table.
3833
3834 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3835 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3836 unary plus operator before it.
3837
3838 =head2 include_columns
3839
3840 =over 4
3841
3842 =item Value: \@columns
3843
3844 =back
3845
3846 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3847
3848 =head2 select
3849
3850 =over 4
3851
3852 =item Value: \@select_columns
3853
3854 =back
3855
3856 Indicates which columns should be selected from the storage. You can use
3857 column names, or in the case of RDBMS back ends, function or stored procedure
3858 names:
3859
3860   $rs = $schema->resultset('Employee')->search(undef, {
3861     select => [
3862       'name',
3863       { count => 'employeeid' },
3864       { max => { length => 'name' }, -as => 'longest_name' }
3865     ]
3866   });
3867
3868   # Equivalent SQL
3869   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3870
3871 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3872 use L</select>, to instruct DBIx::Class how to store the result of the column.
3873 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3874 identifier aliasing. You can however alias a function, so you can use it in
3875 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3876 attribute> supplied as shown in the example above.
3877
3878 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3879 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3880 unary plus operator before it.
3881
3882 =head2 +select
3883
3884 =over 4
3885
3886 Indicates additional columns to be selected from storage.  Works the same as
3887 L</select> but adds columns to the default selection, instead of specifying
3888 an explicit list.
3889
3890 =back
3891
3892 =head2 +as
3893
3894 =over 4
3895
3896 Indicates additional column names for those added via L</+select>. See L</as>.
3897
3898 =back
3899
3900 =head2 as
3901
3902 =over 4
3903
3904 =item Value: \@inflation_names
3905
3906 =back
3907
3908 Indicates column names for object inflation. That is L</as> indicates the
3909 slot name in which the column value will be stored within the
3910 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3911 identifier by the C<get_column> method (or via the object accessor B<if one
3912 with the same name already exists>) as shown below. The L</as> attribute has
3913 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3914
3915   $rs = $schema->resultset('Employee')->search(undef, {
3916     select => [
3917       'name',
3918       { count => 'employeeid' },
3919       { max => { length => 'name' }, -as => 'longest_name' }
3920     ],
3921     as => [qw/
3922       name
3923       employee_count
3924       max_name_length
3925     /],
3926   });
3927
3928 If the object against which the search is performed already has an accessor
3929 matching a column name specified in C<as>, the value can be retrieved using
3930 the accessor as normal:
3931
3932   my $name = $employee->name();
3933
3934 If on the other hand an accessor does not exist in the object, you need to
3935 use C<get_column> instead:
3936
3937   my $employee_count = $employee->get_column('employee_count');
3938
3939 You can create your own accessors if required - see
3940 L<DBIx::Class::Manual::Cookbook> for details.
3941
3942 =head2 join
3943
3944 =over 4
3945
3946 =item Value: ($rel_name | \@rel_names | \%rel_names)
3947
3948 =back
3949
3950 Contains a list of relationships that should be joined for this query.  For
3951 example:
3952
3953   # Get CDs by Nine Inch Nails
3954   my $rs = $schema->resultset('CD')->search(
3955     { 'artist.name' => 'Nine Inch Nails' },
3956     { join => 'artist' }
3957   );
3958
3959 Can also contain a hash reference to refer to the other relation's relations.
3960 For example:
3961
3962   package MyApp::Schema::Track;
3963   use base qw/DBIx::Class/;
3964   __PACKAGE__->table('track');
3965   __PACKAGE__->add_columns(qw/trackid cd position title/);
3966   __PACKAGE__->set_primary_key('trackid');
3967   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3968   1;
3969
3970   # In your application
3971   my $rs = $schema->resultset('Artist')->search(
3972     { 'track.title' => 'Teardrop' },
3973     {
3974       join     => { cd => 'track' },
3975       order_by => 'artist.name',
3976     }
3977   );
3978
3979 You need to use the relationship (not the table) name in  conditions,
3980 because they are aliased as such. The current table is aliased as "me", so
3981 you need to use me.column_name in order to avoid ambiguity. For example:
3982
3983   # Get CDs from 1984 with a 'Foo' track
3984   my $rs = $schema->resultset('CD')->search(
3985     {
3986       'me.year' => 1984,
3987       'tracks.name' => 'Foo'
3988     },
3989     { join => 'tracks' }
3990   );
3991
3992 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3993 similarly for a third time). For e.g.
3994
3995   my $rs = $schema->resultset('Artist')->search({
3996     'cds.title'   => 'Down to Earth',
3997     'cds_2.title' => 'Popular',
3998   }, {
3999     join => [ qw/cds cds/ ],
4000   });
4001
4002 will return a set of all artists that have both a cd with title 'Down
4003 to Earth' and a cd with title 'Popular'.
4004
4005 If you want to fetch related objects from other tables as well, see C<prefetch>
4006 below.
4007
4008  NOTE: An internal join-chain pruner will discard certain joins while
4009  constructing the actual SQL query, as long as the joins in question do not
4010  affect the retrieved result. This for example includes 1:1 left joins
4011  that are not part of the restriction specification (WHERE/HAVING) nor are
4012  a part of the query selection.
4013
4014 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4015
4016 =head2 prefetch
4017
4018 =over 4
4019
4020 =item Value: ($rel_name | \@rel_names | \%rel_names)
4021
4022 =back
4023
4024 Contains one or more relationships that should be fetched along with
4025 the main query (when they are accessed afterwards the data will
4026 already be available, without extra queries to the database).  This is
4027 useful for when you know you will need the related objects, because it
4028 saves at least one query:
4029
4030   my $rs = $schema->resultset('Tag')->search(
4031     undef,
4032     {
4033       prefetch => {
4034         cd => 'artist'
4035       }
4036     }
4037   );
4038
4039 The initial search results in SQL like the following:
4040
4041   SELECT tag.*, cd.*, artist.* FROM tag
4042   JOIN cd ON tag.cd = cd.cdid
4043   JOIN artist ON cd.artist = artist.artistid
4044
4045 L<DBIx::Class> has no need to go back to the database when we access the
4046 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4047 case.
4048
4049 Simple prefetches will be joined automatically, so there is no need
4050 for a C<join> attribute in the above search.
4051
4052 L</prefetch> can be used with the any of the relationship types and
4053 multiple prefetches can be specified together. Below is a more complex
4054 example that prefetches a CD's artist, its liner notes (if present),
4055 the cover image, the tracks on that cd, and the guests on those
4056 tracks.
4057
4058  # Assuming:
4059  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4060  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4061  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4062  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4063
4064  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4065
4066  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4067
4068
4069  my $rs = $schema->resultset('CD')->search(
4070    undef,
4071    {
4072      prefetch => [
4073        { artist => 'record_label'},  # belongs_to => belongs_to
4074        'liner_note',                 # might_have
4075        'cover_image',                # has_one
4076        { tracks => 'guests' },       # has_many => has_many
4077      ]
4078    }
4079  );
4080
4081 This will produce SQL like the following:
4082
4083  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4084         tracks.*, guests.*
4085    FROM cd me
4086    JOIN artist artist
4087      ON artist.artistid = me.artistid
4088    JOIN record_label record_label
4089      ON record_label.labelid = artist.labelid
4090    LEFT JOIN track tracks
4091      ON tracks.cdid = me.cdid
4092    LEFT JOIN guest guests
4093      ON guests.trackid = track.trackid
4094    LEFT JOIN liner_notes liner_note
4095      ON liner_note.cdid = me.cdid
4096    JOIN cd_artwork cover_image
4097      ON cover_image.cdid = me.cdid
4098  ORDER BY tracks.cd
4099
4100 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4101 C<tracks>, and C<guests> of the CD will all be available through the
4102 relationship accessors without the need for additional queries to the
4103 database.
4104
4105 However, there is one caveat to be observed: it can be dangerous to
4106 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4107 relationship on a given level. e.g.:
4108
4109  my $rs = $schema->resultset('CD')->search(
4110    undef,
4111    {
4112      prefetch => [
4113        'tracks',                         # has_many
4114        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4115      ]
4116    }
4117  );
4118
4119 The collapser currently can't identify duplicate tuples for multiple
4120 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4121 result the second L<has_many|DBIx::Class::Relationship/has_many>
4122 relation could contain redundant objects.
4123
4124 =head3 Using L</prefetch> with L</join>
4125
4126 L</prefetch> implies a L</join> with the equivalent argument, and is
4127 properly merged with any existing L</join> specification. So the
4128 following:
4129
4130   my $rs = $schema->resultset('CD')->search(
4131    {'record_label.name' => 'Music Product Ltd.'},
4132    {
4133      join     => {artist => 'record_label'},
4134      prefetch => 'artist',
4135    }
4136  );
4137
4138 ... will work, searching on the record label's name, but only
4139 prefetching the C<artist>.
4140
4141 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4142
4143 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4144 prefetched relations.  So given:
4145
4146   my $rs = $schema->resultset('CD')->search(
4147    undef,
4148    {
4149      select   => ['cd.title'],
4150      as       => ['cd_title'],
4151      prefetch => 'artist',
4152    }
4153  );
4154
4155 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4156 becomes: C<'cd_title', 'artist.*'>.
4157
4158 =head3 CAVEATS
4159
4160 Prefetch does a lot of deep magic. As such, it may not behave exactly
4161 as you might expect.
4162
4163 =over 4
4164
4165 =item *
4166
4167 Prefetch uses the L</cache> to populate the prefetched relationships. This
4168 may or may not be what you want.
4169
4170 =item *
4171
4172 If you specify a condition on a prefetched relationship, ONLY those
4173 rows that match the prefetched condition will be fetched into that relationship.
4174 This means that adding prefetch to a search() B<may alter> what is returned by
4175 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4176
4177   my $artist_rs = $schema->resultset('Artist')->search({
4178       'cds.year' => 2008,
4179   }, {
4180       join => 'cds',
4181   });
4182
4183   my $count = $artist_rs->first->cds->count;
4184
4185   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4186
4187   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4188
4189   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4190
4191 that cmp_ok() may or may not pass depending on the datasets involved. This
4192 behavior may or may not survive the 0.09 transition.
4193
4194 =back
4195
4196 =head2 alias
4197
4198 =over 4
4199
4200 =item Value: $source_alias
4201
4202 =back
4203
4204 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4205 nested search queries (sub-SELECTs) might need specific aliases set to
4206 reference inner queries.  For example:
4207
4208    my $q = $rs
4209       ->related_resultset('CDs')
4210       ->related_resultset('Tracks')
4211       ->search({
4212          'track.id' => { -ident => 'none_search.id' },
4213       })
4214       ->as_query;
4215
4216    my $ids = $self->search({
4217       -not_exists => $q,
4218    }, {
4219       alias    => 'none_search',
4220       group_by => 'none_search.id',
4221    })->get_column('id')->as_query;
4222
4223    $self->search({ id => { -in => $ids } })
4224
4225 This attribute is directly tied to L</current_source_alias>.
4226
4227 =head2 page
4228
4229 =over 4
4230
4231 =item Value: $page
4232
4233 =back
4234
4235 Makes the resultset paged and specifies the page to retrieve. Effectively
4236 identical to creating a non-pages resultset and then calling ->page($page)
4237 on it.
4238
4239 If L</rows> attribute is not specified it defaults to 10 rows per page.
4240
4241 When you have a paged resultset, L</count> will only return the number
4242 of rows in the page. To get the total, use the L</pager> and call
4243 C<total_entries> on it.
4244
4245 =head2 rows
4246
4247 =over 4
4248
4249 =item Value: $rows
4250
4251 =back
4252
4253 Specifies the maximum number of rows for direct retrieval or the number of
4254 rows per page if the page attribute or method is used.
4255
4256 =head2 offset
4257
4258 =over 4
4259
4260 =item Value: $offset
4261
4262 =back
4263
4264 Specifies the (zero-based) row number for the  first row to be returned, or the
4265 of the first row of the first page if paging is used.
4266
4267 =head2 software_limit
4268
4269 =over 4
4270
4271 =item Value: (0 | 1)
4272
4273 =back
4274
4275 When combined with L</rows> and/or L</offset> the generated SQL will not
4276 include any limit dialect stanzas. Instead the entire result will be selected
4277 as if no limits were specified, and DBIC will perform the limit locally, by
4278 artificially advancing and finishing the resulting L</cursor>.
4279
4280 This is the recommended way of performing resultset limiting when no sane RDBMS
4281 implementation is available (e.g.
4282 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4283 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4284
4285 =head2 group_by
4286
4287 =over 4
4288
4289 =item Value: \@columns
4290
4291 =back
4292
4293 A arrayref of columns to group by. Can include columns of joined tables.
4294
4295   group_by => [qw/ column1 column2 ... /]
4296
4297 =head2 having
4298
4299 =over 4
4300
4301 =item Value: $condition
4302
4303 =back
4304
4305 HAVING is a select statement attribute that is applied between GROUP BY and
4306 ORDER BY. It is applied to the after the grouping calculations have been
4307 done.
4308
4309   having => { 'count_employee' => { '>=', 100 } }
4310
4311 or with an in-place function in which case literal SQL is required:
4312
4313   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4314
4315 =head2 distinct
4316
4317 =over 4
4318
4319 =item Value: (0 | 1)
4320
4321 =back
4322
4323 Set to 1 to group by all columns. If the resultset already has a group_by
4324 attribute, this setting is ignored and an appropriate warning is issued.
4325
4326 =head2 where
4327
4328 =over 4
4329
4330 Adds to the WHERE clause.
4331
4332   # only return rows WHERE deleted IS NULL for all searches
4333   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4334
4335 Can be overridden by passing C<< { where => undef } >> as an attribute
4336 to a resultset.
4337
4338 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4339
4340 =back
4341
4342 =head2 cache
4343
4344 Set to 1 to cache search results. This prevents extra SQL queries if you
4345 revisit rows in your ResultSet:
4346
4347   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4348
4349   while( my $artist = $resultset->next ) {
4350     ... do stuff ...
4351   }
4352
4353   $rs->first; # without cache, this would issue a query
4354
4355 By default, searches are not cached.
4356
4357 For more examples of using these attributes, see
4358 L<DBIx::Class::Manual::Cookbook>.
4359
4360 =head2 for
4361
4362 =over 4
4363
4364 =item Value: ( 'update' | 'shared' | \$scalar )
4365
4366 =back
4367
4368 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4369 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4370 query.
4371
4372 =head1 DBIC BIND VALUES
4373
4374 Because DBIC may need more information to bind values than just the column name
4375 and value itself, it uses a special format for both passing and receiving bind
4376 values.  Each bind value should be composed of an arrayref of
4377 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4378
4379 =over 4
4380
4381 =item dbd_attrs
4382
4383 If present (in any form), this is what is being passed directly to bind_param.
4384 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4385 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4386
4387 If this is specified, all other bind options described below are ignored.
4388
4389 =item sqlt_datatype
4390
4391 If present, this is used to infer the actual bind attribute by passing to
4392 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4393 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4394
4395 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4396 currently drivers are expected to "Do the Right Thing" when given a common
4397 datatype name.  (Not ideal, but that's what we got at this point.)
4398
4399 =item sqlt_size
4400
4401 Currently used to correctly allocate buffers for bind_param_inout().
4402 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4403 or to a sensible value based on the "data_type".
4404
4405 =item dbic_colname
4406
4407 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4408 explicitly specified they are never overriden).  Also used by some weird DBDs,
4409 where the column name should be available at bind_param time (e.g. Oracle).
4410
4411 =back
4412
4413 For backwards compatibility and convenience, the following shortcuts are
4414 supported:
4415
4416   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4417   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4418   [ undef,   $val ] === [ {}, $val ]
4419
4420 =head1 AUTHOR AND CONTRIBUTORS
4421
4422 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4423
4424 =head1 LICENSE
4425
4426 You may distribute this code under the same terms as Perl itself.
4427
4428 =cut
4429
4430 1;