lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs   = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: $source, \%$attrs
 195
 196 =item Return Value: $rs
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you won't need to construct a resultset manually.  You'll
 206 automatically get one from e.g. a L</search> called in scalar context:
 207
 208   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 209
 210 IMPORTANT: If called on an object, proxies to new_result instead so
 211
 212   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 213
 214 will return a CD object, not a ResultSet.
 215
 216 =cut
 217
 218 sub new {
 219   my $class = shift;
 220   return $class->new_result(@_) if ref $class;
 221
 222   my ($source, $attrs) = @_;
 223   $source = $source->resolve
 224     if $source->isa('DBIx::Class::ResultSourceHandle');
 225   $attrs = { %{$attrs||{}} };
 226
 227   if ($attrs->{page}) {
 228     $attrs->{rows} ||= 10;
 229   }
 230
 231   $attrs->{alias} ||= 'me';
 232
 233   my $self = bless {
 234     result_source => $source,
 235     cond => $attrs->{where},
 236     pager => undef,
 237     attrs => $attrs,
 238   }, $class;
 239
 240   # if there is a dark selector, this means we are already in a
 241   # chain and the cleanup/sanification was taken care of by
 242   # _search_rs already
 243   $self->_normalize_selection($attrs)
 244     unless $attrs->{_dark_selector};
 245
 246   $self->result_class(
 247     $attrs->{result_class} || $source->result_class
 248   );
 249
 250   $self;
 251 }
 252
 253 =head2 search
 254
 255 =over 4
 256
 257 =item Arguments: $cond, \%attrs?
 258
 259 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 260
 261 =back
 262
 263   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 264   my $new_rs = $cd_rs->search({ year => 2005 });
 265
 266   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 267                  # year = 2005 OR year = 2004
 268
 269 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 270 returning a list of row objects instead. To avoid that, use L</search_rs>.
 271
 272 If you need to pass in additional attributes but no additional condition,
 273 call it as C<search(undef, \%attrs)>.
 274
 275   # "SELECT name, artistid FROM $artist_table"
 276   my @all_artists = $schema->resultset('Artist')->search(undef, {
 277     columns => [qw/name artistid/],
 278   });
 279
 280 For a list of attributes that can be passed to C<search>, see
 281 L</ATTRIBUTES>. For more examples of using this function, see
 282 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 283 documentation for the first argument, see L<SQL::Abstract>
 284 and its extension L<DBIx::Class::SQLMaker>.
 285
 286 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 287
 288 =head3 CAVEAT
 289
 290 Note that L</search> does not process/deflate any of the values passed in the
 291 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 292 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 293 manually that any value passed to this method will stringify to something the
 294 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 295 objects, for more info see:
 296 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 297
 298 =cut
 299
 300 sub search {
 301   my $self = shift;
 302   my $rs = $self->search_rs( @_ );
 303
 304   if (wantarray) {
 305     return $rs->all;
 306   }
 307   elsif (defined wantarray) {
 308     return $rs;
 309   }
 310   else {
 311     # we can be called by a relationship helper, which in
 312     # turn may be called in void context due to some braindead
 313     # overload or whatever else the user decided to be clever
 314     # at this particular day. Thus limit the exception to
 315     # external code calls only
 316     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 317       if (caller)[0] !~ /^\QDBIx::Class::/;
 318
 319     return ();
 320   }
 321 }
 322
 323 =head2 search_rs
 324
 325 =over 4
 326
 327 =item Arguments: $cond, \%attrs?
 328
 329 =item Return Value: $resultset
 330
 331 =back
 332
 333 This method does the same exact thing as search() except it will
 334 always return a resultset, even in list context.
 335
 336 =cut
 337
 338 sub search_rs {
 339   my $self = shift;
 340
 341   # Special-case handling for (undef, undef).
 342   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 343     @_ = ();
 344   }
 345
 346   my $call_attrs = {};
 347   if (@_ > 1) {
 348     if (ref $_[-1] eq 'HASH') {
 349       # copy for _normalize_selection
 350       $call_attrs = { %{ pop @_ } };
 351     }
 352     elsif (! defined $_[-1] ) {
 353       pop @_;   # search({}, undef)
 354     }
 355   }
 356
 357   # see if we can keep the cache (no $rs changes)
 358   my $cache;
 359   my %safe = (alias => 1, cache => 1);
 360   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 361     ! defined $_[0]
 362       or
 363     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 364       or
 365     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 366   )) {
 367     $cache = $self->get_cache;
 368   }
 369
 370   my $rsrc = $self->result_source;
 371
 372   my $old_attrs = { %{$self->{attrs}} };
 373   my $old_having = delete $old_attrs->{having};
 374   my $old_where = delete $old_attrs->{where};
 375
 376   my $new_attrs = { %$old_attrs };
 377
 378   # take care of call attrs (only if anything is changing)
 379   if (keys %$call_attrs) {
 380
 381     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 382
 383     # reset the current selector list if new selectors are supplied
 384     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 385       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 386     }
 387
 388     # Normalize the new selector list (operates on the passed-in attr structure)
 389     # Need to do it on every chain instead of only once on _resolved_attrs, in
 390     # order to allow detection of empty vs partial 'as'
 391     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 392       if $old_attrs->{_dark_selector};
 393     $self->_normalize_selection ($call_attrs);
 394
 395     # start with blind overwriting merge, exclude selector attrs
 396     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 397     delete @{$new_attrs}{@selector_attrs};
 398
 399     for (@selector_attrs) {
 400       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 401         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 402     }
 403
 404     # older deprecated name, use only if {columns} is not there
 405     if (my $c = delete $new_attrs->{cols}) {
 406       if ($new_attrs->{columns}) {
 407         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 408       }
 409       else {
 410         $new_attrs->{columns} = $c;
 411       }
 412     }
 413
 414
 415     # join/prefetch use their own crazy merging heuristics
 416     foreach my $key (qw/join prefetch/) {
 417       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 418         if exists $call_attrs->{$key};
 419     }
 420
 421     # stack binds together
 422     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 423   }
 424
 425
 426   # rip apart the rest of @_, parse a condition
 427   my $call_cond = do {
 428
 429     if (ref $_[0] eq 'HASH') {
 430       (keys %{$_[0]}) ? $_[0] : undef
 431     }
 432     elsif (@_ == 1) {
 433       $_[0]
 434     }
 435     elsif (@_ % 2) {
 436       $self->throw_exception('Odd number of arguments to search')
 437     }
 438     else {
 439       +{ @_ }
 440     }
 441
 442   } if @_;
 443
 444   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 445     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 446   }
 447
 448   for ($old_where, $call_cond) {
 449     if (defined $_) {
 450       $new_attrs->{where} = $self->_stack_cond (
 451         $_, $new_attrs->{where}
 452       );
 453     }
 454   }
 455
 456   if (defined $old_having) {
 457     $new_attrs->{having} = $self->_stack_cond (
 458       $old_having, $new_attrs->{having}
 459     )
 460   }
 461
 462   my $rs = (ref $self)->new($rsrc, $new_attrs);
 463
 464   $rs->set_cache($cache) if ($cache);
 465
 466   return $rs;
 467 }
 468
 469 my $dark_sel_dumper;
 470 sub _normalize_selection {
 471   my ($self, $attrs) = @_;
 472
 473   # legacy syntax
 474   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 475     if exists $attrs->{include_columns};
 476
 477   # columns are always placed first, however
 478
 479   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 480   # delay the decision on whether to use a default select list ($rsrc->columns)
 481   # allowing stuff like the remove_columns helper to work
 482   #
 483   # select/as +select/+as pairs need special handling - the amount of select/as
 484   # elements in each pair does *not* have to be equal (think multicolumn
 485   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 486   # supplied at all) - try to infer the alias, either from the -as parameter
 487   # of the selector spec, or use the parameter whole if it looks like a column
 488   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 489   # is ok as well), but make sure no more additions to the 'as' chain take place
 490   for my $pref ('', '+') {
 491
 492     my ($sel, $as) = map {
 493       my $key = "${pref}${_}";
 494
 495       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 496         ? @{$attrs->{$key}}
 497         : $attrs->{$key} || ()
 498       ];
 499       delete $attrs->{$key};
 500       $val;
 501     } qw/select as/;
 502
 503     if (! @$as and ! @$sel ) {
 504       next;
 505     }
 506     elsif (@$as and ! @$sel) {
 507       $self->throw_exception(
 508         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 509       );
 510     }
 511     elsif( ! @$as ) {
 512       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 513       # if any @$as has been supplied we assume the user knows what (s)he is doing
 514       # and blindly keep stacking up pieces
 515       unless ($attrs->{_dark_selector}) {
 516         SELECTOR:
 517         for (@$sel) {
 518           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 519             push @$as, $_->{-as};
 520           }
 521           # assume any plain no-space, no-parenthesis string to be a column spec
 522           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 523           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 524             push @$as, $_;
 525           }
 526           # if all else fails - raise a flag that no more aliasing will be allowed
 527           else {
 528             $attrs->{_dark_selector} = {
 529               plus_stage => $pref,
 530               string => ($dark_sel_dumper ||= do {
 531                   require Data::Dumper::Concise;
 532                   Data::Dumper::Concise::DumperObject()->Indent(0);
 533                 })->Values([$_])->Dump
 534               ,
 535             };
 536             last SELECTOR;
 537           }
 538         }
 539       }
 540     }
 541     elsif (@$as < @$sel) {
 542       $self->throw_exception(
 543         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 544       );
 545     }
 546     elsif ($pref and $attrs->{_dark_selector}) {
 547       $self->throw_exception(
 548         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 549       );
 550     }
 551
 552
 553     # merge result
 554     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 555     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 556   }
 557 }
 558
 559 sub _stack_cond {
 560   my ($self, $left, $right) = @_;
 561
 562   # collapse single element top-level conditions
 563   # (single pass only, unlikely to need recursion)
 564   for ($left, $right) {
 565     if (ref $_ eq 'ARRAY') {
 566       if (@$_ == 0) {
 567         $_ = undef;
 568       }
 569       elsif (@$_ == 1) {
 570         $_ = $_->[0];
 571       }
 572     }
 573     elsif (ref $_ eq 'HASH') {
 574       my ($first, $more) = keys %$_;
 575
 576       # empty hash
 577       if (! defined $first) {
 578         $_ = undef;
 579       }
 580       # one element hash
 581       elsif (! defined $more) {
 582         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 583           $_ = $_->{'-and'};
 584         }
 585         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 586           $_ = $_->{'-or'};
 587         }
 588       }
 589     }
 590   }
 591
 592   # merge hashes with weeding out of duplicates (simple cases only)
 593   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 594
 595     # shallow copy to destroy
 596     $right = { %$right };
 597     for (grep { exists $right->{$_} } keys %$left) {
 598       # the use of eq_deeply here is justified - the rhs of an
 599       # expression can contain a lot of twisted weird stuff
 600       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 601     }
 602
 603     $right = undef unless keys %$right;
 604   }
 605
 606
 607   if (defined $left xor defined $right) {
 608     return defined $left ? $left : $right;
 609   }
 610   elsif (! defined $left) {
 611     return undef;
 612   }
 613   else {
 614     return { -and => [ $left, $right ] };
 615   }
 616 }
 617
 618 =head2 search_literal
 619
 620 =over 4
 621
 622 =item Arguments: $sql_fragment, @bind_values
 623
 624 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 625
 626 =back
 627
 628   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 629   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 630
 631 Pass a literal chunk of SQL to be added to the conditional part of the
 632 resultset query.
 633
 634 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 635 only be used in that context. C<search_literal> is a convenience method.
 636 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 637 columns are bound correctly, use C<search>.
 638
 639 Example of how to use C<search> instead of C<search_literal>
 640
 641   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 642   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 643
 644
 645 See L<DBIx::Class::Manual::Cookbook/Searching> and
 646 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 647 require C<search_literal>.
 648
 649 =cut
 650
 651 sub search_literal {
 652   my ($self, $sql, @bind) = @_;
 653   my $attr;
 654   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 655     $attr = pop @bind;
 656   }
 657   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 658 }
 659
 660 =head2 find
 661
 662 =over 4
 663
 664 =item Arguments: \%columns_values | @pk_values, \%attrs?
 665
 666 =item Return Value: $row_object | undef
 667
 668 =back
 669
 670 Finds and returns a single row based on supplied criteria. Takes either a
 671 hashref with the same format as L</create> (including inference of foreign
 672 keys from related objects), or a list of primary key values in the same
 673 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 674 declaration on the L</result_source>.
 675
 676 In either case an attempt is made to combine conditions already existing on
 677 the resultset with the condition passed to this method.
 678
 679 To aid with preparing the correct query for the storage you may supply the
 680 C<key> attribute, which is the name of a
 681 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 682 unique constraint corresponding to the
 683 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 684 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 685 to construct a query that satisfies the named unique constraint fully (
 686 non-NULL values for each column member of the constraint) an exception is
 687 thrown.
 688
 689 If no C<key> is specified, the search is carried over all unique constraints
 690 which are fully defined by the available condition.
 691
 692 If no such constraint is found, C<find> currently defaults to a simple
 693 C<< search->(\%column_values) >> which may or may not do what you expect.
 694 Note that this fallback behavior may be deprecated in further versions. If
 695 you need to search with arbitrary conditions - use L</search>. If the query
 696 resulting from this fallback produces more than one row, a warning to the
 697 effect is issued, though only the first row is constructed and returned as
 698 C<$row_object>.
 699
 700 In addition to C<key>, L</find> recognizes and applies standard
 701 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 702
 703 Note that if you have extra concerns about the correctness of the resulting
 704 query you need to specify the C<key> attribute and supply the entire condition
 705 as an argument to find (since it is not always possible to perform the
 706 combination of the resultset condition with the supplied one, especially if
 707 the resultset condition contains literal sql).
 708
 709 For example, to find a row by its primary key:
 710
 711   my $cd = $schema->resultset('CD')->find(5);
 712
 713 You can also find a row by a specific unique constraint:
 714
 715   my $cd = $schema->resultset('CD')->find(
 716     {
 717       artist => 'Massive Attack',
 718       title  => 'Mezzanine',
 719     },
 720     { key => 'cd_artist_title' }
 721   );
 722
 723 See also L</find_or_create> and L</update_or_create>.
 724
 725 =cut
 726
 727 sub find {
 728   my $self = shift;
 729   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 730
 731   my $rsrc = $self->result_source;
 732
 733   my $constraint_name;
 734   if (exists $attrs->{key}) {
 735     $constraint_name = defined $attrs->{key}
 736       ? $attrs->{key}
 737       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 738     ;
 739   }
 740
 741   # Parse out the condition from input
 742   my $call_cond;
 743
 744   if (ref $_[0] eq 'HASH') {
 745     $call_cond = { %{$_[0]} };
 746   }
 747   else {
 748     # if only values are supplied we need to default to 'primary'
 749     $constraint_name = 'primary' unless defined $constraint_name;
 750
 751     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 752
 753     $self->throw_exception(
 754       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 755     ) unless @c_cols;
 756
 757     $self->throw_exception (
 758       'find() expects either a column/value hashref, or a list of values '
 759     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 760     ) unless @c_cols == @_;
 761
 762     $call_cond = {};
 763     @{$call_cond}{@c_cols} = @_;
 764   }
 765
 766   my %related;
 767   for my $key (keys %$call_cond) {
 768     if (
 769       my $keyref = ref($call_cond->{$key})
 770         and
 771       my $relinfo = $rsrc->relationship_info($key)
 772     ) {
 773       my $val = delete $call_cond->{$key};
 774
 775       next if $keyref eq 'ARRAY'; # has_many for multi_create
 776
 777       my $rel_q = $rsrc->_resolve_condition(
 778         $relinfo->{cond}, $val, $key, $key
 779       );
 780       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 781       @related{keys %$rel_q} = values %$rel_q;
 782     }
 783   }
 784
 785   # relationship conditions take precedence (?)
 786   @{$call_cond}{keys %related} = values %related;
 787
 788   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 789   my $final_cond;
 790   if (defined $constraint_name) {
 791     $final_cond = $self->_qualify_cond_columns (
 792
 793       $self->_build_unique_cond (
 794         $constraint_name,
 795         $call_cond,
 796       ),
 797
 798       $alias,
 799     );
 800   }
 801   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 802     # This means that we got here after a merger of relationship conditions
 803     # in ::Relationship::Base::search_related (the row method), and furthermore
 804     # the relationship is of the 'single' type. This means that the condition
 805     # provided by the relationship (already attached to $self) is sufficient,
 806     # as there can be only one row in the database that would satisfy the
 807     # relationship
 808   }
 809   else {
 810     # no key was specified - fall down to heuristics mode:
 811     # run through all unique queries registered on the resultset, and
 812     # 'OR' all qualifying queries together
 813     my (@unique_queries, %seen_column_combinations);
 814     for my $c_name ($rsrc->unique_constraint_names) {
 815       next if $seen_column_combinations{
 816         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 817       }++;
 818
 819       push @unique_queries, try {
 820         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 821       } || ();
 822     }
 823
 824     $final_cond = @unique_queries
 825       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 826       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 827     ;
 828   }
 829
 830   # Run the query, passing the result_class since it should propagate for find
 831   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 832   if ($rs->_resolved_attrs->{collapse}) {
 833     my $row = $rs->next;
 834     carp "Query returned more than one row" if $rs->next;
 835     return $row;
 836   }
 837   else {
 838     return $rs->single;
 839   }
 840 }
 841
 842 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 843 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 844 #
 845 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 846 # condition. It is provided for overrides until a saner way forward is devised
 847 #
 848 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 849 # the road. Please adjust your tests accordingly to catch this situation early
 850 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 851 #
 852 # The method will not be removed without an adequately complete replacement
 853 # for strict-mode enforcement
 854 sub _non_unique_find_fallback {
 855   my ($self, $cond, $attrs) = @_;
 856
 857   return $self->_qualify_cond_columns(
 858     $cond,
 859     exists $attrs->{alias}
 860       ? $attrs->{alias}
 861       : $self->{attrs}{alias}
 862   );
 863 }
 864
 865
 866 sub _qualify_cond_columns {
 867   my ($self, $cond, $alias) = @_;
 868
 869   my %aliased = %$cond;
 870   for (keys %aliased) {
 871     $aliased{"$alias.$_"} = delete $aliased{$_}
 872       if $_ !~ /\./;
 873   }
 874
 875   return \%aliased;
 876 }
 877
 878 sub _build_unique_cond {
 879   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 880
 881   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 882
 883   # combination may fail if $self->{cond} is non-trivial
 884   my ($final_cond) = try {
 885     $self->_merge_with_rscond ($extra_cond)
 886   } catch {
 887     +{ %$extra_cond }
 888   };
 889
 890   # trim out everything not in $columns
 891   $final_cond = { map {
 892     exists $final_cond->{$_}
 893       ? ( $_ => $final_cond->{$_} )
 894       : ()
 895   } @c_cols };
 896
 897   if (my @missing = grep
 898     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 899     (@c_cols)
 900   ) {
 901     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 902       $constraint_name,
 903       join (', ', map { "'$_'" } @missing),
 904     ) );
 905   }
 906
 907   if (
 908     !$croak_on_null
 909       and
 910     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 911       and
 912     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 913   ) {
 914     carp_unique ( sprintf (
 915       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 916     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 917     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 918       $constraint_name,
 919       join (', ', map { "'$_'" } @undefs),
 920     ));
 921   }
 922
 923   return $final_cond;
 924 }
 925
 926 =head2 search_related
 927
 928 =over 4
 929
 930 =item Arguments: $rel, $cond?, \%attrs?
 931
 932 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 933
 934 =back
 935
 936   $new_rs = $cd_rs->search_related('artist', {
 937     name => 'Emo-R-Us',
 938   });
 939
 940 Searches the specified relationship, optionally specifying a condition and
 941 attributes for matching records. See L</ATTRIBUTES> for more information.
 942
 943 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 944 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 945
 946 See also L</search_related_rs>.
 947
 948 =cut
 949
 950 sub search_related {
 951   return shift->related_resultset(shift)->search(@_);
 952 }
 953
 954 =head2 search_related_rs
 955
 956 This method works exactly the same as search_related, except that
 957 it guarantees a resultset, even in list context.
 958
 959 =cut
 960
 961 sub search_related_rs {
 962   return shift->related_resultset(shift)->search_rs(@_);
 963 }
 964
 965 =head2 cursor
 966
 967 =over 4
 968
 969 =item Arguments: none
 970
 971 =item Return Value: $cursor
 972
 973 =back
 974
 975 Returns a storage-driven cursor to the given resultset. See
 976 L<DBIx::Class::Cursor> for more information.
 977
 978 =cut
 979
 980 sub cursor {
 981   my ($self) = @_;
 982
 983   my $attrs = $self->_resolved_attrs_copy;
 984
 985   return $self->{cursor}
 986     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 987           $attrs->{where},$attrs);
 988 }
 989
 990 =head2 single
 991
 992 =over 4
 993
 994 =item Arguments: $cond?
 995
 996 =item Return Value: $row_object | undef
 997
 998 =back
 999
1000   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1001
1002 Inflates the first result without creating a cursor if the resultset has
1003 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1004 of L</search>.
1005
1006 While this method can take an optional search condition (just like L</search>)
1007 being a fast-code-path it does not recognize search attributes. If you need to
1008 add extra joins or similar, call L</search> and then chain-call L</single> on the
1009 L<DBIx::Class::ResultSet> returned.
1010
1011 =over
1012
1013 =item B<Note>
1014
1015 As of 0.08100, this method enforces the assumption that the preceding
1016 query returns only one row. If more than one row is returned, you will receive
1017 a warning:
1018
1019   Query returned more than one row
1020
1021 In this case, you should be using L</next> or L</find> instead, or if you really
1022 know what you are doing, use the L</rows> attribute to explicitly limit the size
1023 of the resultset.
1024
1025 This method will also throw an exception if it is called on a resultset prefetching
1026 has_many, as such a prefetch implies fetching multiple rows from the database in
1027 order to assemble the resulting object.
1028
1029 =back
1030
1031 =cut
1032
1033 sub single {
1034   my ($self, $where) = @_;
1035   if(@_ > 2) {
1036       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1037   }
1038
1039   my $attrs = $self->_resolved_attrs_copy;
1040
1041   $self->throw_exception(
1042     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1043   ) if $attrs->{collapse};
1044
1045   if ($where) {
1046     if (defined $attrs->{where}) {
1047       $attrs->{where} = {
1048         '-and' =>
1049             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1050                $where, delete $attrs->{where} ]
1051       };
1052     } else {
1053       $attrs->{where} = $where;
1054     }
1055   }
1056
1057   my $data = [ $self->result_source->storage->select_single(
1058     $attrs->{from}, $attrs->{select},
1059     $attrs->{where}, $attrs
1060   )];
1061   return undef unless @$data;
1062   $self->{stashed_rows} = [ $data ];
1063   $self->_construct_objects->[0];
1064 }
1065
1066
1067 # _collapse_query
1068 #
1069 # Recursively collapse the query, accumulating values for each column.
1070
1071 sub _collapse_query {
1072   my ($self, $query, $collapsed) = @_;
1073
1074   $collapsed ||= {};
1075
1076   if (ref $query eq 'ARRAY') {
1077     foreach my $subquery (@$query) {
1078       next unless ref $subquery;  # -or
1079       $collapsed = $self->_collapse_query($subquery, $collapsed);
1080     }
1081   }
1082   elsif (ref $query eq 'HASH') {
1083     if (keys %$query and (keys %$query)[0] eq '-and') {
1084       foreach my $subquery (@{$query->{-and}}) {
1085         $collapsed = $self->_collapse_query($subquery, $collapsed);
1086       }
1087     }
1088     else {
1089       foreach my $col (keys %$query) {
1090         my $value = $query->{$col};
1091         $collapsed->{$col}{$value}++;
1092       }
1093     }
1094   }
1095
1096   return $collapsed;
1097 }
1098
1099 =head2 get_column
1100
1101 =over 4
1102
1103 =item Arguments: $cond?
1104
1105 =item Return Value: $resultsetcolumn
1106
1107 =back
1108
1109   my $max_length = $rs->get_column('length')->max;
1110
1111 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1112
1113 =cut
1114
1115 sub get_column {
1116   my ($self, $column) = @_;
1117   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1118   return $new;
1119 }
1120
1121 =head2 search_like
1122
1123 =over 4
1124
1125 =item Arguments: $cond, \%attrs?
1126
1127 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1128
1129 =back
1130
1131   # WHERE title LIKE '%blue%'
1132   $cd_rs = $rs->search_like({ title => '%blue%'});
1133
1134 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1135 that this is simply a convenience method retained for ex Class::DBI users.
1136 You most likely want to use L</search> with specific operators.
1137
1138 For more information, see L<DBIx::Class::Manual::Cookbook>.
1139
1140 This method is deprecated and will be removed in 0.09. Use L</search()>
1141 instead. An example conversion is:
1142
1143   ->search_like({ foo => 'bar' });
1144
1145   # Becomes
1146
1147   ->search({ foo => { like => 'bar' } });
1148
1149 =cut
1150
1151 sub search_like {
1152   my $class = shift;
1153   carp_unique (
1154     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1155    .' Instead use ->search({ x => { -like => "y%" } })'
1156    .' (note the outer pair of {}s - they are important!)'
1157   );
1158   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1159   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1160   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1161   return $class->search($query, { %$attrs });
1162 }
1163
1164 =head2 slice
1165
1166 =over 4
1167
1168 =item Arguments: $first, $last
1169
1170 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1171
1172 =back
1173
1174 Returns a resultset or object list representing a subset of elements from the
1175 resultset slice is called on. Indexes are from 0, i.e., to get the first
1176 three records, call:
1177
1178   my ($one, $two, $three) = $rs->slice(0, 2);
1179
1180 =cut
1181
1182 sub slice {
1183   my ($self, $min, $max) = @_;
1184   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1185   $attrs->{offset} = $self->{attrs}{offset} || 0;
1186   $attrs->{offset} += $min;
1187   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1188   return $self->search(undef, $attrs);
1189   #my $slice = (ref $self)->new($self->result_source, $attrs);
1190   #return (wantarray ? $slice->all : $slice);
1191 }
1192
1193 =head2 next
1194
1195 =over 4
1196
1197 =item Arguments: none
1198
1199 =item Return Value: $result | undef
1200
1201 =back
1202
1203 Returns the next element in the resultset (C<undef> is there is none).
1204
1205 Can be used to efficiently iterate over records in the resultset:
1206
1207   my $rs = $schema->resultset('CD')->search;
1208   while (my $cd = $rs->next) {
1209     print $cd->title;
1210   }
1211
1212 Note that you need to store the resultset object, and call C<next> on it.
1213 Calling C<< resultset('Table')->next >> repeatedly will always return the
1214 first record from the resultset.
1215
1216 =cut
1217
1218 sub next {
1219   my ($self) = @_;
1220
1221   if (my $cache = $self->get_cache) {
1222     $self->{all_cache_position} ||= 0;
1223     return $cache->[$self->{all_cache_position}++];
1224   }
1225
1226   if ($self->{attrs}{cache}) {
1227     delete $self->{pager};
1228     $self->{all_cache_position} = 1;
1229     return ($self->all)[0];
1230   }
1231
1232   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1233
1234   $self->{stashed_objects} = $self->_construct_objects
1235     or return undef;
1236
1237   return shift @{$self->{stashed_objects}};
1238 }
1239
1240 # Constructs as many objects as it can in one pass while respecting
1241 # cursor laziness. Several modes of operation:
1242 #
1243 # * Always builds everything present in @{$self->{stashed_rows}}
1244 # * If called with $fetch_all true - pulls everything off the cursor and
1245 #   builds all objects in one pass
1246 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1247 #   and if the resultset is ordered properly by the left side:
1248 #   * Fetches stuff off the cursor until the "master object" changes,
1249 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1250 #   OR
1251 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1252 #     was requested (there is no other way to collapse except for an
1253 #     eager cursor)
1254 # * If no collapse is requested - just get the next row, construct and
1255 #   return
1256 sub _construct_objects {
1257   my ($self, $fetch_all) = @_;
1258
1259   my $rsrc = $self->result_source;
1260   my $attrs = $self->_resolved_attrs;
1261   my $cursor = $self->cursor;
1262
1263   # this will be used as both initial raw-row collector AND as a RV of
1264   # _construct_objects. Not regrowing the array twice matters a lot...
1265   # a suprising amount actually
1266   my $rows = (delete $self->{stashed_rows}) || [];
1267   if ($fetch_all) {
1268     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1269     $rows = [ @$rows, $cursor->all ];
1270   }
1271   elsif (!$attrs->{collapse}) {
1272     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1273     push @$rows, do { my @r = $cursor->next; @r ? \@r : () }
1274       unless @$rows;
1275   }
1276   else {
1277     $attrs->{_ordered_for_collapse} ||= (!$attrs->{order_by}) ? undef : do {
1278       my $st = $rsrc->schema->storage;
1279       my @ord_cols = map
1280         { $_->[0] }
1281         ( $st->_extract_order_criteria($attrs->{order_by}) )
1282       ;
1283
1284       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1285
1286       for (0 .. $#ord_cols) {
1287         if (
1288           ! $colinfos->{$ord_cols[$_]}
1289             or
1290           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1291         ) {
1292           splice @ord_cols, $_;
1293           last;
1294         }
1295       }
1296
1297       # since all we check here are the start of the order_by belonging to the
1298       # top level $rsrc, a present identifying set will mean that the resultset
1299       # is ordered by its leftmost table in a tsable manner
1300       (@ord_cols and $rsrc->_identifying_column_set({ map
1301         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1302         @ord_cols
1303       })) ? 1 : 0;
1304     };
1305
1306     if ($attrs->{_ordered_for_collapse}) {
1307       push @$rows, do { my @r = $cursor->next; @r ? \@r : () };
1308     }
1309     # instead of looping over ->next, use ->all in stealth mode
1310     # FIXME - encapsulation breach, got to be a better way
1311     elsif (! $cursor->{done}) {
1312       push @$rows, $cursor->all;
1313       $cursor->{done} = 1;
1314       $fetch_all = 1;
1315     }
1316   }
1317
1318   return undef unless @$rows;
1319
1320   my $res_class = $self->result_class;
1321   my $inflator = $res_class->can ('inflate_result')
1322     or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1323
1324   my $infmap = $attrs->{as};
1325
1326   if (!$attrs->{collapse} and $attrs->{_single_object_inflation}) {
1327     # construct a much simpler array->hash folder for the one-table cases right here
1328
1329     # FIXME SUBOPTIMAL this is a very very very hot spot
1330     # while rather optimal we can *still* do much better, by
1331     # building a smarter [Row|HRI]::inflate_result(), and
1332     # switch to feeding it data via a much leaner interface
1333     #
1334     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1335     # this particular resultset size
1336     if (@$rows < 60) {
1337       my @as_idx = 0..$#$infmap;
1338       for my $r (@$rows) {
1339         $r = $inflator->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } @as_idx } );
1340       }
1341     }
1342     else {
1343       eval sprintf (
1344         '$_ = $inflator->($res_class, $rsrc, { %s }) for @$rows',
1345         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1346       );
1347     }
1348   }
1349   else {
1350     ($self->{_row_parser} ||= eval sprintf 'sub { %s }', $rsrc->_mk_row_parser({
1351       inflate_map => $infmap,
1352       selection => $attrs->{select},
1353       collapse => $attrs->{collapse},
1354     }) or die $@)->($rows, $fetch_all ? () : (
1355       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1356       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1357       ($self->{stashed_rows} = []),                 # where does it stuff excess
1358     ));  # modify $rows in-place, shrinking/extending as necessary
1359
1360     $_ = $inflator->($res_class, $rsrc, @$_) for @$rows;
1361
1362   }
1363
1364   # CDBI compat stuff
1365   if ($attrs->{record_filter}) {
1366     $_ = $attrs->{record_filter}->($_) for @$rows;
1367   }
1368
1369   return $rows;
1370 }
1371
1372 =head2 result_source
1373
1374 =over 4
1375
1376 =item Arguments: $result_source?
1377
1378 =item Return Value: $result_source
1379
1380 =back
1381
1382 An accessor for the primary ResultSource object from which this ResultSet
1383 is derived.
1384
1385 =head2 result_class
1386
1387 =over 4
1388
1389 =item Arguments: $result_class?
1390
1391 =item Return Value: $result_class
1392
1393 =back
1394
1395 An accessor for the class to use when creating row objects. Defaults to
1396 C<< result_source->result_class >> - which in most cases is the name of the
1397 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1398
1399 Note that changing the result_class will also remove any components
1400 that were originally loaded in the source class via
1401 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1402 in the original source class will not run.
1403
1404 =cut
1405
1406 sub result_class {
1407   my ($self, $result_class) = @_;
1408   if ($result_class) {
1409     unless (ref $result_class) { # don't fire this for an object
1410       $self->ensure_class_loaded($result_class);
1411     }
1412     $self->_result_class($result_class);
1413     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1414     # permit the user to set result class on one result set only; it only
1415     # chains if provided to search()
1416     #$self->{attrs}{result_class} = $result_class if ref $self;
1417   }
1418   $self->_result_class;
1419 }
1420
1421 =head2 count
1422
1423 =over 4
1424
1425 =item Arguments: $cond, \%attrs??
1426
1427 =item Return Value: $count
1428
1429 =back
1430
1431 Performs an SQL C<COUNT> with the same query as the resultset was built
1432 with to find the number of elements. Passing arguments is equivalent to
1433 C<< $rs->search ($cond, \%attrs)->count >>
1434
1435 =cut
1436
1437 sub count {
1438   my $self = shift;
1439   return $self->search(@_)->count if @_ and defined $_[0];
1440   return scalar @{ $self->get_cache } if $self->get_cache;
1441
1442   my $attrs = $self->_resolved_attrs_copy;
1443
1444   # this is a little optimization - it is faster to do the limit
1445   # adjustments in software, instead of a subquery
1446   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1447
1448   my $crs;
1449   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1450     $crs = $self->_count_subq_rs ($attrs);
1451   }
1452   else {
1453     $crs = $self->_count_rs ($attrs);
1454   }
1455   my $count = $crs->next;
1456
1457   $count -= $offset if $offset;
1458   $count = $rows if $rows and $rows < $count;
1459   $count = 0 if ($count < 0);
1460
1461   return $count;
1462 }
1463
1464 =head2 count_rs
1465
1466 =over 4
1467
1468 =item Arguments: $cond, \%attrs??
1469
1470 =item Return Value: $count_rs
1471
1472 =back
1473
1474 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1475 This can be very handy for subqueries:
1476
1477   ->search( { amount => $some_rs->count_rs->as_query } )
1478
1479 As with regular resultsets the SQL query will be executed only after
1480 the resultset is accessed via L</next> or L</all>. That would return
1481 the same single value obtainable via L</count>.
1482
1483 =cut
1484
1485 sub count_rs {
1486   my $self = shift;
1487   return $self->search(@_)->count_rs if @_;
1488
1489   # this may look like a lack of abstraction (count() does about the same)
1490   # but in fact an _rs *must* use a subquery for the limits, as the
1491   # software based limiting can not be ported if this $rs is to be used
1492   # in a subquery itself (i.e. ->as_query)
1493   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1494     return $self->_count_subq_rs;
1495   }
1496   else {
1497     return $self->_count_rs;
1498   }
1499 }
1500
1501 #
1502 # returns a ResultSetColumn object tied to the count query
1503 #
1504 sub _count_rs {
1505   my ($self, $attrs) = @_;
1506
1507   my $rsrc = $self->result_source;
1508   $attrs ||= $self->_resolved_attrs;
1509
1510   my $tmp_attrs = { %$attrs };
1511   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1512   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1513
1514   # overwrite the selector (supplied by the storage)
1515   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1516   $tmp_attrs->{as} = 'count';
1517
1518   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1519
1520   return $tmp_rs;
1521 }
1522
1523 #
1524 # same as above but uses a subquery
1525 #
1526 sub _count_subq_rs {
1527   my ($self, $attrs) = @_;
1528
1529   my $rsrc = $self->result_source;
1530   $attrs ||= $self->_resolved_attrs;
1531
1532   my $sub_attrs = { %$attrs };
1533   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1534   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1535
1536   # if we multi-prefetch we group_by something unique, as this is what we would
1537   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1538   if ( $attrs->{collapse}  ) {
1539     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1540       $rsrc->_identifying_column_set || $self->throw_exception(
1541         'Unable to construct a unique group_by criteria properly collapsing the '
1542       . 'has_many prefetch before count()'
1543       );
1544     } ]
1545   }
1546
1547   # Calculate subquery selector
1548   if (my $g = $sub_attrs->{group_by}) {
1549
1550     my $sql_maker = $rsrc->storage->sql_maker;
1551
1552     # necessary as the group_by may refer to aliased functions
1553     my $sel_index;
1554     for my $sel (@{$attrs->{select}}) {
1555       $sel_index->{$sel->{-as}} = $sel
1556         if (ref $sel eq 'HASH' and $sel->{-as});
1557     }
1558
1559     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1560     # also look for named aggregates referred in the having clause
1561     # having often contains scalarrefs - thus parse it out entirely
1562     my @parts = @$g;
1563     if ($attrs->{having}) {
1564       local $sql_maker->{having_bind};
1565       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1566       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1567       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1568         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1569         # if we don't unset it we screw up retarded but unfortunately working
1570         # 'MAX(foo.bar)' => { '>', 3 }
1571         $sql_maker->{name_sep} = '';
1572       }
1573
1574       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1575
1576       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1577
1578       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1579       # and if all fails for an utterly naive quoted scalar-with-function
1580       while ($sql =~ /
1581         $rquote $sep $lquote (.+?) $rquote
1582           |
1583         [\s,] \w+ \. (\w+) [\s,]
1584           |
1585         [\s,] $lquote (.+?) $rquote [\s,]
1586       /gx) {
1587         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1588       }
1589     }
1590
1591     for (@parts) {
1592       my $colpiece = $sel_index->{$_} || $_;
1593
1594       # unqualify join-based group_by's. Arcane but possible query
1595       # also horrible horrible hack to alias a column (not a func.)
1596       # (probably need to introduce SQLA syntax)
1597       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1598         my $as = $colpiece;
1599         $as =~ s/\./__/;
1600         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1601       }
1602       push @{$sub_attrs->{select}}, $colpiece;
1603     }
1604   }
1605   else {
1606     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1607     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1608   }
1609
1610   return $rsrc->resultset_class
1611                ->new ($rsrc, $sub_attrs)
1612                 ->as_subselect_rs
1613                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1614                   ->get_column ('count');
1615 }
1616
1617 sub _bool {
1618   return 1;
1619 }
1620
1621 =head2 count_literal
1622
1623 =over 4
1624
1625 =item Arguments: $sql_fragment, @bind_values
1626
1627 =item Return Value: $count
1628
1629 =back
1630
1631 Counts the results in a literal query. Equivalent to calling L</search_literal>
1632 with the passed arguments, then L</count>.
1633
1634 =cut
1635
1636 sub count_literal { shift->search_literal(@_)->count; }
1637
1638 =head2 all
1639
1640 =over 4
1641
1642 =item Arguments: none
1643
1644 =item Return Value: @objects
1645
1646 =back
1647
1648 Returns all elements in the resultset.
1649
1650 =cut
1651
1652 sub all {
1653   my $self = shift;
1654   if(@_) {
1655     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1656   }
1657
1658   delete @{$self}{qw/stashed_rows stashed_objects/};
1659
1660   if (my $c = $self->get_cache) {
1661     return @$c;
1662   }
1663
1664   $self->cursor->reset;
1665
1666   my $objs = $self->_construct_objects('fetch_all') || [];
1667
1668   $self->set_cache($objs) if $self->{attrs}{cache};
1669
1670   return @$objs;
1671 }
1672
1673 =head2 reset
1674
1675 =over 4
1676
1677 =item Arguments: none
1678
1679 =item Return Value: $self
1680
1681 =back
1682
1683 Resets the resultset's cursor, so you can iterate through the elements again.
1684 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1685 another query.
1686
1687 =cut
1688
1689 sub reset {
1690   my ($self) = @_;
1691
1692   delete @{$self}{qw/_attrs stashed_rows stashed_objects/};
1693
1694   $self->{all_cache_position} = 0;
1695   $self->cursor->reset;
1696   return $self;
1697 }
1698
1699 =head2 first
1700
1701 =over 4
1702
1703 =item Arguments: none
1704
1705 =item Return Value: $object | undef
1706
1707 =back
1708
1709 Resets the resultset and returns an object for the first result (or C<undef>
1710 if the resultset is empty).
1711
1712 =cut
1713
1714 sub first {
1715   return $_[0]->reset->next;
1716 }
1717
1718
1719 # _rs_update_delete
1720 #
1721 # Determines whether and what type of subquery is required for the $rs operation.
1722 # If grouping is necessary either supplies its own, or verifies the current one
1723 # After all is done delegates to the proper storage method.
1724
1725 sub _rs_update_delete {
1726   my ($self, $op, $values) = @_;
1727
1728   my $cond = $self->{cond};
1729   my $rsrc = $self->result_source;
1730   my $storage = $rsrc->schema->storage;
1731
1732   my $attrs = { %{$self->_resolved_attrs} };
1733
1734   # "needs" is a strong word here - if the subquery is part of an IN clause - no point of
1735   # even adding the group_by. It will really be used only when composing a poor-man's
1736   # multicolumn-IN equivalent OR set
1737   my $needs_group_by_subq = defined $attrs->{group_by};
1738
1739   # simplify the joinmap and maybe decide if a grouping (and thus subquery) is necessary
1740   my $relation_classifications;
1741   if (ref($attrs->{from}) eq 'ARRAY') {
1742     if (@{$attrs->{from}} == 1) {
1743       # not a fucking JOIN at all, quit with the dickery
1744       $relation_classifications = {};
1745     } else {
1746       $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1747
1748       $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1749         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1750         $attrs->{select},
1751         $cond,
1752         $attrs
1753       ) unless $needs_group_by_subq;  # we already know we need a group, no point of resolving them
1754     }
1755   }
1756   else {
1757     $needs_group_by_subq ||= 1; # if {from} is unparseable assume the worst
1758   }
1759
1760   $needs_group_by_subq ||= exists $relation_classifications->{multiplying};
1761
1762   # if no subquery - life is easy-ish
1763   unless (
1764     $needs_group_by_subq
1765       or
1766     keys %$relation_classifications # if any joins at all - need to wrap a subq
1767       or
1768     $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1769   ) {
1770     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1771     # a condition containing 'me' or other table prefixes will not work
1772     # at all. What this code tries to do (badly) is to generate a condition
1773     # with the qualifiers removed, by exploiting the quote mechanism of sqla
1774     #
1775     # this is atrocious and should be replaced by normal sqla introspection
1776     # one sunny day
1777     my ($sql, @bind) = do {
1778       my $sqla = $rsrc->storage->sql_maker;
1779       local $sqla->{_dequalify_idents} = 1;
1780       $sqla->_recurse_where($self->{cond});
1781     } if $self->{cond};
1782
1783     return $rsrc->storage->$op(
1784       $rsrc,
1785       $op eq 'update' ? $values : (),
1786       $self->{cond} ? \[$sql, @bind] : (),
1787     );
1788   }
1789
1790   # we got this far - means it is time to wrap a subquery
1791   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1792     sprintf(
1793       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1794       $op,
1795       $rsrc->source_name,
1796     )
1797   );
1798   my $existing_group_by = delete $attrs->{group_by};
1799
1800   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1801   delete @{$attrs}{qw/collapse select _prefetch_selector_range as/};
1802   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1803   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1804   my $subrs = (ref $self)->new($rsrc, $attrs);
1805
1806   if (@$idcols == 1) {
1807     return $storage->$op (
1808       $rsrc,
1809       $op eq 'update' ? $values : (),
1810       { $idcols->[0] => { -in => $subrs->as_query } },
1811     );
1812   }
1813   elsif ($storage->_use_multicolumn_in) {
1814     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1815     my $sql_maker = $storage->sql_maker;
1816     my ($sql, @bind) = @${$subrs->as_query};
1817     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1818       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1819       $sql,
1820     );
1821
1822     return $storage->$op (
1823       $rsrc,
1824       $op eq 'update' ? $values : (),
1825       \[$sql, @bind],
1826     );
1827   }
1828   else {
1829     # if all else fails - get all primary keys and operate over a ORed set
1830     # wrap in a transaction for consistency
1831     # this is where the group_by starts to matter
1832     my $subq_group_by;
1833     if ($needs_group_by_subq) {
1834       $subq_group_by = $attrs->{columns};
1835
1836       # make sure if there is a supplied group_by it matches the columns compiled above
1837       # perfectly. Anything else can not be sanely executed on most databases so croak
1838       # right then and there
1839       if ($existing_group_by) {
1840         my @current_group_by = map
1841           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1842           @$existing_group_by
1843         ;
1844
1845         if (
1846           join ("\x00", sort @current_group_by)
1847             ne
1848           join ("\x00", sort @$subq_group_by )
1849         ) {
1850           $self->throw_exception (
1851             "You have just attempted a $op operation on a resultset which does group_by"
1852             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1853             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1854             . ' kind of queries. Please retry the operation with a modified group_by or'
1855             . ' without using one at all.'
1856           );
1857         }
1858       }
1859     }
1860
1861     my $guard = $storage->txn_scope_guard;
1862
1863     my @op_condition;
1864     for my $row ($subrs->search({}, { group_by => $subq_group_by })->cursor->all) {
1865       push @op_condition, { map
1866         { $idcols->[$_] => $row->[$_] }
1867         (0 .. $#$idcols)
1868       };
1869     }
1870
1871     my $res = $storage->$op (
1872       $rsrc,
1873       $op eq 'update' ? $values : (),
1874       \@op_condition,
1875     );
1876
1877     $guard->commit;
1878
1879     return $res;
1880   }
1881 }
1882
1883 =head2 update
1884
1885 =over 4
1886
1887 =item Arguments: \%values
1888
1889 =item Return Value: $storage_rv
1890
1891 =back
1892
1893 Sets the specified columns in the resultset to the supplied values in a
1894 single query. Note that this will not run any accessor/set_column/update
1895 triggers, nor will it update any row object instances derived from this
1896 resultset (this includes the contents of the L<resultset cache|/set_cache>
1897 if any). See L</update_all> if you need to execute any on-update
1898 triggers or cascades defined either by you or a
1899 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1900
1901 The return value is a pass through of what the underlying
1902 storage backend returned, and may vary. See L<DBI/execute> for the most
1903 common case.
1904
1905 =head3 CAVEAT
1906
1907 Note that L</update> does not process/deflate any of the values passed in.
1908 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1909 ensure manually that any value passed to this method will stringify to
1910 something the RDBMS knows how to deal with. A notable example is the
1911 handling of L<DateTime> objects, for more info see:
1912 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1913
1914 =cut
1915
1916 sub update {
1917   my ($self, $values) = @_;
1918   $self->throw_exception('Values for update must be a hash')
1919     unless ref $values eq 'HASH';
1920
1921   return $self->_rs_update_delete ('update', $values);
1922 }
1923
1924 =head2 update_all
1925
1926 =over 4
1927
1928 =item Arguments: \%values
1929
1930 =item Return Value: 1
1931
1932 =back
1933
1934 Fetches all objects and updates them one at a time via
1935 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1936 triggers, while L</update> will not.
1937
1938 =cut
1939
1940 sub update_all {
1941   my ($self, $values) = @_;
1942   $self->throw_exception('Values for update_all must be a hash')
1943     unless ref $values eq 'HASH';
1944
1945   my $guard = $self->result_source->schema->txn_scope_guard;
1946   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1947   $guard->commit;
1948   return 1;
1949 }
1950
1951 =head2 delete
1952
1953 =over 4
1954
1955 =item Arguments: none
1956
1957 =item Return Value: $storage_rv
1958
1959 =back
1960
1961 Deletes the rows matching this resultset in a single query. Note that this
1962 will not run any delete triggers, nor will it alter the
1963 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1964 derived from this resultset (this includes the contents of the
1965 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1966 execute any on-delete triggers or cascades defined either by you or a
1967 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1968
1969 The return value is a pass through of what the underlying storage backend
1970 returned, and may vary. See L<DBI/execute> for the most common case.
1971
1972 =cut
1973
1974 sub delete {
1975   my $self = shift;
1976   $self->throw_exception('delete does not accept any arguments')
1977     if @_;
1978
1979   return $self->_rs_update_delete ('delete');
1980 }
1981
1982 =head2 delete_all
1983
1984 =over 4
1985
1986 =item Arguments: none
1987
1988 =item Return Value: 1
1989
1990 =back
1991
1992 Fetches all objects and deletes them one at a time via
1993 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1994 triggers, while L</delete> will not.
1995
1996 =cut
1997
1998 sub delete_all {
1999   my $self = shift;
2000   $self->throw_exception('delete_all does not accept any arguments')
2001     if @_;
2002
2003   my $guard = $self->result_source->schema->txn_scope_guard;
2004   $_->delete for $self->all;
2005   $guard->commit;
2006   return 1;
2007 }
2008
2009 =head2 populate
2010
2011 =over 4
2012
2013 =item Arguments: \@data;
2014
2015 =back
2016
2017 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
2018 For the arrayref of hashrefs style each hashref should be a structure suitable
2019 for submitting to a $resultset->create(...) method.
2020
2021 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
2022 to insert the data, as this is a faster method.
2023
2024 Otherwise, each set of data is inserted into the database using
2025 L<DBIx::Class::ResultSet/create>, and the resulting objects are
2026 accumulated into an array. The array itself, or an array reference
2027 is returned depending on scalar or list context.
2028
2029 Example:  Assuming an Artist Class that has many CDs Classes relating:
2030
2031   my $Artist_rs = $schema->resultset("Artist");
2032
2033   ## Void Context Example
2034   $Artist_rs->populate([
2035      { artistid => 4, name => 'Manufactured Crap', cds => [
2036         { title => 'My First CD', year => 2006 },
2037         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2038       ],
2039      },
2040      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2041         { title => 'My parents sold me to a record company', year => 2005 },
2042         { title => 'Why Am I So Ugly?', year => 2006 },
2043         { title => 'I Got Surgery and am now Popular', year => 2007 }
2044       ],
2045      },
2046   ]);
2047
2048   ## Array Context Example
2049   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
2050     { name => "Artist One"},
2051     { name => "Artist Two"},
2052     { name => "Artist Three", cds=> [
2053     { title => "First CD", year => 2007},
2054     { title => "Second CD", year => 2008},
2055   ]}
2056   ]);
2057
2058   print $ArtistOne->name; ## response is 'Artist One'
2059   print $ArtistThree->cds->count ## reponse is '2'
2060
2061 For the arrayref of arrayrefs style,  the first element should be a list of the
2062 fieldsnames to which the remaining elements are rows being inserted.  For
2063 example:
2064
2065   $Arstist_rs->populate([
2066     [qw/artistid name/],
2067     [100, 'A Formally Unknown Singer'],
2068     [101, 'A singer that jumped the shark two albums ago'],
2069     [102, 'An actually cool singer'],
2070   ]);
2071
2072 Please note an important effect on your data when choosing between void and
2073 wantarray context. Since void context goes straight to C<insert_bulk> in
2074 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
2075 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
2076 create primary keys for you, you will find that your PKs are empty.  In this
2077 case you will have to use the wantarray context in order to create those
2078 values.
2079
2080 =cut
2081
2082 sub populate {
2083   my $self = shift;
2084
2085   # cruft placed in standalone method
2086   my $data = $self->_normalize_populate_args(@_);
2087
2088   return unless @$data;
2089
2090   if(defined wantarray) {
2091     my @created;
2092     foreach my $item (@$data) {
2093       push(@created, $self->create($item));
2094     }
2095     return wantarray ? @created : \@created;
2096   }
2097   else {
2098     my $first = $data->[0];
2099
2100     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2101     # it relationship data
2102     my (@rels, @columns);
2103     my $rsrc = $self->result_source;
2104     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2105     for (keys %$first) {
2106       my $ref = ref $first->{$_};
2107       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2108         ? push @rels, $_
2109         : push @columns, $_
2110       ;
2111     }
2112
2113     my @pks = $rsrc->primary_columns;
2114
2115     ## do the belongs_to relationships
2116     foreach my $index (0..$#$data) {
2117
2118       # delegate to create() for any dataset without primary keys with specified relationships
2119       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2120         for my $r (@rels) {
2121           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2122             my @ret = $self->populate($data);
2123             return;
2124           }
2125         }
2126       }
2127
2128       foreach my $rel (@rels) {
2129         next unless ref $data->[$index]->{$rel} eq "HASH";
2130         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2131         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2132         my $related = $result->result_source->_resolve_condition(
2133           $reverse_relinfo->{cond},
2134           $self,
2135           $result,
2136           $rel,
2137         );
2138
2139         delete $data->[$index]->{$rel};
2140         $data->[$index] = {%{$data->[$index]}, %$related};
2141
2142         push @columns, keys %$related if $index == 0;
2143       }
2144     }
2145
2146     ## inherit the data locked in the conditions of the resultset
2147     my ($rs_data) = $self->_merge_with_rscond({});
2148     delete @{$rs_data}{@columns};
2149     my @inherit_cols = keys %$rs_data;
2150     my @inherit_data = values %$rs_data;
2151
2152     ## do bulk insert on current row
2153     $rsrc->storage->insert_bulk(
2154       $rsrc,
2155       [@columns, @inherit_cols],
2156       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
2157     );
2158
2159     ## do the has_many relationships
2160     foreach my $item (@$data) {
2161
2162       my $main_row;
2163
2164       foreach my $rel (@rels) {
2165         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2166
2167         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2168
2169         my $child = $main_row->$rel;
2170
2171         my $related = $child->result_source->_resolve_condition(
2172           $rels->{$rel}{cond},
2173           $child,
2174           $main_row,
2175           $rel,
2176         );
2177
2178         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2179         my @populate = map { {%$_, %$related} } @rows_to_add;
2180
2181         $child->populate( \@populate );
2182       }
2183     }
2184   }
2185 }
2186
2187
2188 # populate() argumnets went over several incarnations
2189 # What we ultimately support is AoH
2190 sub _normalize_populate_args {
2191   my ($self, $arg) = @_;
2192
2193   if (ref $arg eq 'ARRAY') {
2194     if (!@$arg) {
2195       return [];
2196     }
2197     elsif (ref $arg->[0] eq 'HASH') {
2198       return $arg;
2199     }
2200     elsif (ref $arg->[0] eq 'ARRAY') {
2201       my @ret;
2202       my @colnames = @{$arg->[0]};
2203       foreach my $values (@{$arg}[1 .. $#$arg]) {
2204         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2205       }
2206       return \@ret;
2207     }
2208   }
2209
2210   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2211 }
2212
2213 =head2 pager
2214
2215 =over 4
2216
2217 =item Arguments: none
2218
2219 =item Return Value: $pager
2220
2221 =back
2222
2223 Return Value a L<Data::Page> object for the current resultset. Only makes
2224 sense for queries with a C<page> attribute.
2225
2226 To get the full count of entries for a paged resultset, call
2227 C<total_entries> on the L<Data::Page> object.
2228
2229 =cut
2230
2231 sub pager {
2232   my ($self) = @_;
2233
2234   return $self->{pager} if $self->{pager};
2235
2236   my $attrs = $self->{attrs};
2237   if (!defined $attrs->{page}) {
2238     $self->throw_exception("Can't create pager for non-paged rs");
2239   }
2240   elsif ($attrs->{page} <= 0) {
2241     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2242   }
2243   $attrs->{rows} ||= 10;
2244
2245   # throw away the paging flags and re-run the count (possibly
2246   # with a subselect) to get the real total count
2247   my $count_attrs = { %$attrs };
2248   delete @{$count_attrs}{qw/rows offset page pager/};
2249
2250   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2251
2252   require DBIx::Class::ResultSet::Pager;
2253   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2254     sub { $total_rs->count },  #lazy-get the total
2255     $attrs->{rows},
2256     $self->{attrs}{page},
2257   );
2258 }
2259
2260 =head2 page
2261
2262 =over 4
2263
2264 =item Arguments: $page_number
2265
2266 =item Return Value: $rs
2267
2268 =back
2269
2270 Returns a resultset for the $page_number page of the resultset on which page
2271 is called, where each page contains a number of rows equal to the 'rows'
2272 attribute set on the resultset (10 by default).
2273
2274 =cut
2275
2276 sub page {
2277   my ($self, $page) = @_;
2278   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2279 }
2280
2281 =head2 new_result
2282
2283 =over 4
2284
2285 =item Arguments: \%vals
2286
2287 =item Return Value: $rowobject
2288
2289 =back
2290
2291 Creates a new row object in the resultset's result class and returns
2292 it. The row is not inserted into the database at this point, call
2293 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2294 will tell you whether the row object has been inserted or not.
2295
2296 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2297
2298 =cut
2299
2300 sub new_result {
2301   my ($self, $values) = @_;
2302   $self->throw_exception( "new_result needs a hash" )
2303     unless (ref $values eq 'HASH');
2304
2305   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2306
2307   my %new = (
2308     %$merged_cond,
2309     @$cols_from_relations
2310       ? (-cols_from_relations => $cols_from_relations)
2311       : (),
2312     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2313   );
2314
2315   return $self->result_class->new(\%new);
2316 }
2317
2318 # _merge_with_rscond
2319 #
2320 # Takes a simple hash of K/V data and returns its copy merged with the
2321 # condition already present on the resultset. Additionally returns an
2322 # arrayref of value/condition names, which were inferred from related
2323 # objects (this is needed for in-memory related objects)
2324 sub _merge_with_rscond {
2325   my ($self, $data) = @_;
2326
2327   my (%new_data, @cols_from_relations);
2328
2329   my $alias = $self->{attrs}{alias};
2330
2331   if (! defined $self->{cond}) {
2332     # just massage $data below
2333   }
2334   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2335     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2336     @cols_from_relations = keys %new_data;
2337   }
2338   elsif (ref $self->{cond} ne 'HASH') {
2339     $self->throw_exception(
2340       "Can't abstract implicit construct, resultset condition not a hash"
2341     );
2342   }
2343   else {
2344     # precendence must be given to passed values over values inherited from
2345     # the cond, so the order here is important.
2346     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2347     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2348
2349     while ( my($col, $value) = each %implied ) {
2350       my $vref = ref $value;
2351       if (
2352         $vref eq 'HASH'
2353           and
2354         keys(%$value) == 1
2355           and
2356         (keys %$value)[0] eq '='
2357       ) {
2358         $new_data{$col} = $value->{'='};
2359       }
2360       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2361         $new_data{$col} = $value;
2362       }
2363     }
2364   }
2365
2366   %new_data = (
2367     %new_data,
2368     %{ $self->_remove_alias($data, $alias) },
2369   );
2370
2371   return (\%new_data, \@cols_from_relations);
2372 }
2373
2374 # _has_resolved_attr
2375 #
2376 # determines if the resultset defines at least one
2377 # of the attributes supplied
2378 #
2379 # used to determine if a subquery is neccessary
2380 #
2381 # supports some virtual attributes:
2382 #   -join
2383 #     This will scan for any joins being present on the resultset.
2384 #     It is not a mere key-search but a deep inspection of {from}
2385 #
2386
2387 sub _has_resolved_attr {
2388   my ($self, @attr_names) = @_;
2389
2390   my $attrs = $self->_resolved_attrs;
2391
2392   my %extra_checks;
2393
2394   for my $n (@attr_names) {
2395     if (grep { $n eq $_ } (qw/-join/) ) {
2396       $extra_checks{$n}++;
2397       next;
2398     }
2399
2400     my $attr =  $attrs->{$n};
2401
2402     next if not defined $attr;
2403
2404     if (ref $attr eq 'HASH') {
2405       return 1 if keys %$attr;
2406     }
2407     elsif (ref $attr eq 'ARRAY') {
2408       return 1 if @$attr;
2409     }
2410     else {
2411       return 1 if $attr;
2412     }
2413   }
2414
2415   # a resolved join is expressed as a multi-level from
2416   return 1 if (
2417     $extra_checks{-join}
2418       and
2419     ref $attrs->{from} eq 'ARRAY'
2420       and
2421     @{$attrs->{from}} > 1
2422   );
2423
2424   return 0;
2425 }
2426
2427 # _collapse_cond
2428 #
2429 # Recursively collapse the condition.
2430
2431 sub _collapse_cond {
2432   my ($self, $cond, $collapsed) = @_;
2433
2434   $collapsed ||= {};
2435
2436   if (ref $cond eq 'ARRAY') {
2437     foreach my $subcond (@$cond) {
2438       next unless ref $subcond;  # -or
2439       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2440     }
2441   }
2442   elsif (ref $cond eq 'HASH') {
2443     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2444       foreach my $subcond (@{$cond->{-and}}) {
2445         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2446       }
2447     }
2448     else {
2449       foreach my $col (keys %$cond) {
2450         my $value = $cond->{$col};
2451         $collapsed->{$col} = $value;
2452       }
2453     }
2454   }
2455
2456   return $collapsed;
2457 }
2458
2459 # _remove_alias
2460 #
2461 # Remove the specified alias from the specified query hash. A copy is made so
2462 # the original query is not modified.
2463
2464 sub _remove_alias {
2465   my ($self, $query, $alias) = @_;
2466
2467   my %orig = %{ $query || {} };
2468   my %unaliased;
2469
2470   foreach my $key (keys %orig) {
2471     if ($key !~ /\./) {
2472       $unaliased{$key} = $orig{$key};
2473       next;
2474     }
2475     $unaliased{$1} = $orig{$key}
2476       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2477   }
2478
2479   return \%unaliased;
2480 }
2481
2482 =head2 as_query
2483
2484 =over 4
2485
2486 =item Arguments: none
2487
2488 =item Return Value: \[ $sql, @bind ]
2489
2490 =back
2491
2492 Returns the SQL query and bind vars associated with the invocant.
2493
2494 This is generally used as the RHS for a subquery.
2495
2496 =cut
2497
2498 sub as_query {
2499   my $self = shift;
2500
2501   my $attrs = $self->_resolved_attrs_copy;
2502
2503   # For future use:
2504   #
2505   # in list ctx:
2506   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2507   # $sql also has no wrapping parenthesis in list ctx
2508   #
2509   my $sqlbind = $self->result_source->storage
2510     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2511
2512   return $sqlbind;
2513 }
2514
2515 =head2 find_or_new
2516
2517 =over 4
2518
2519 =item Arguments: \%vals, \%attrs?
2520
2521 =item Return Value: $rowobject
2522
2523 =back
2524
2525   my $artist = $schema->resultset('Artist')->find_or_new(
2526     { artist => 'fred' }, { key => 'artists' });
2527
2528   $cd->cd_to_producer->find_or_new({ producer => $producer },
2529                                    { key => 'primary });
2530
2531 Find an existing record from this resultset using L</find>. if none exists,
2532 instantiate a new result object and return it. The object will not be saved
2533 into your storage until you call L<DBIx::Class::Row/insert> on it.
2534
2535 You most likely want this method when looking for existing rows using a unique
2536 constraint that is not the primary key, or looking for related rows.
2537
2538 If you want objects to be saved immediately, use L</find_or_create> instead.
2539
2540 B<Note>: Make sure to read the documentation of L</find> and understand the
2541 significance of the C<key> attribute, as its lack may skew your search, and
2542 subsequently result in spurious new objects.
2543
2544 B<Note>: Take care when using C<find_or_new> with a table having
2545 columns with default values that you intend to be automatically
2546 supplied by the database (e.g. an auto_increment primary key column).
2547 In normal usage, the value of such columns should NOT be included at
2548 all in the call to C<find_or_new>, even when set to C<undef>.
2549
2550 =cut
2551
2552 sub find_or_new {
2553   my $self     = shift;
2554   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2555   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2556   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2557     return $row;
2558   }
2559   return $self->new_result($hash);
2560 }
2561
2562 =head2 create
2563
2564 =over 4
2565
2566 =item Arguments: \%vals
2567
2568 =item Return Value: a L<DBIx::Class::Row> $object
2569
2570 =back
2571
2572 Attempt to create a single new row or a row with multiple related rows
2573 in the table represented by the resultset (and related tables). This
2574 will not check for duplicate rows before inserting, use
2575 L</find_or_create> to do that.
2576
2577 To create one row for this resultset, pass a hashref of key/value
2578 pairs representing the columns of the table and the values you wish to
2579 store. If the appropriate relationships are set up, foreign key fields
2580 can also be passed an object representing the foreign row, and the
2581 value will be set to its primary key.
2582
2583 To create related objects, pass a hashref of related-object column values
2584 B<keyed on the relationship name>. If the relationship is of type C<multi>
2585 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2586 The process will correctly identify columns holding foreign keys, and will
2587 transparently populate them from the keys of the corresponding relation.
2588 This can be applied recursively, and will work correctly for a structure
2589 with an arbitrary depth and width, as long as the relationships actually
2590 exists and the correct column data has been supplied.
2591
2592
2593 Instead of hashrefs of plain related data (key/value pairs), you may
2594 also pass new or inserted objects. New objects (not inserted yet, see
2595 L</new>), will be inserted into their appropriate tables.
2596
2597 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2598
2599 Example of creating a new row.
2600
2601   $person_rs->create({
2602     name=>"Some Person",
2603     email=>"somebody@someplace.com"
2604   });
2605
2606 Example of creating a new row and also creating rows in a related C<has_many>
2607 or C<has_one> resultset.  Note Arrayref.
2608
2609   $artist_rs->create(
2610      { artistid => 4, name => 'Manufactured Crap', cds => [
2611         { title => 'My First CD', year => 2006 },
2612         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2613       ],
2614      },
2615   );
2616
2617 Example of creating a new row and also creating a row in a related
2618 C<belongs_to> resultset. Note Hashref.
2619
2620   $cd_rs->create({
2621     title=>"Music for Silly Walks",
2622     year=>2000,
2623     artist => {
2624       name=>"Silly Musician",
2625     }
2626   });
2627
2628 =over
2629
2630 =item WARNING
2631
2632 When subclassing ResultSet never attempt to override this method. Since
2633 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2634 lot of the internals simply never call it, so your override will be
2635 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2636 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2637 L</create> process you need to intervene.
2638
2639 =back
2640
2641 =cut
2642
2643 sub create {
2644   my ($self, $attrs) = @_;
2645   $self->throw_exception( "create needs a hashref" )
2646     unless ref $attrs eq 'HASH';
2647   return $self->new_result($attrs)->insert;
2648 }
2649
2650 =head2 find_or_create
2651
2652 =over 4
2653
2654 =item Arguments: \%vals, \%attrs?
2655
2656 =item Return Value: $rowobject
2657
2658 =back
2659
2660   $cd->cd_to_producer->find_or_create({ producer => $producer },
2661                                       { key => 'primary' });
2662
2663 Tries to find a record based on its primary key or unique constraints; if none
2664 is found, creates one and returns that instead.
2665
2666   my $cd = $schema->resultset('CD')->find_or_create({
2667     cdid   => 5,
2668     artist => 'Massive Attack',
2669     title  => 'Mezzanine',
2670     year   => 2005,
2671   });
2672
2673 Also takes an optional C<key> attribute, to search by a specific key or unique
2674 constraint. For example:
2675
2676   my $cd = $schema->resultset('CD')->find_or_create(
2677     {
2678       artist => 'Massive Attack',
2679       title  => 'Mezzanine',
2680     },
2681     { key => 'cd_artist_title' }
2682   );
2683
2684 B<Note>: Make sure to read the documentation of L</find> and understand the
2685 significance of the C<key> attribute, as its lack may skew your search, and
2686 subsequently result in spurious row creation.
2687
2688 B<Note>: Because find_or_create() reads from the database and then
2689 possibly inserts based on the result, this method is subject to a race
2690 condition. Another process could create a record in the table after
2691 the find has completed and before the create has started. To avoid
2692 this problem, use find_or_create() inside a transaction.
2693
2694 B<Note>: Take care when using C<find_or_create> with a table having
2695 columns with default values that you intend to be automatically
2696 supplied by the database (e.g. an auto_increment primary key column).
2697 In normal usage, the value of such columns should NOT be included at
2698 all in the call to C<find_or_create>, even when set to C<undef>.
2699
2700 See also L</find> and L</update_or_create>. For information on how to declare
2701 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2702
2703 If you need to know if an existing row was found or a new one created use
2704 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2705 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2706 database!
2707
2708   my $cd = $schema->resultset('CD')->find_or_new({
2709     cdid   => 5,
2710     artist => 'Massive Attack',
2711     title  => 'Mezzanine',
2712     year   => 2005,
2713   });
2714
2715   if( $cd->in_storage ) {
2716       # do some stuff
2717       $cd->insert;
2718   }
2719
2720 =cut
2721
2722 sub find_or_create {
2723   my $self     = shift;
2724   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2725   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2726   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2727     return $row;
2728   }
2729   return $self->create($hash);
2730 }
2731
2732 =head2 update_or_create
2733
2734 =over 4
2735
2736 =item Arguments: \%col_values, { key => $unique_constraint }?
2737
2738 =item Return Value: $row_object
2739
2740 =back
2741
2742   $resultset->update_or_create({ col => $val, ... });
2743
2744 Like L</find_or_create>, but if a row is found it is immediately updated via
2745 C<< $found_row->update (\%col_values) >>.
2746
2747
2748 Takes an optional C<key> attribute to search on a specific unique constraint.
2749 For example:
2750
2751   # In your application
2752   my $cd = $schema->resultset('CD')->update_or_create(
2753     {
2754       artist => 'Massive Attack',
2755       title  => 'Mezzanine',
2756       year   => 1998,
2757     },
2758     { key => 'cd_artist_title' }
2759   );
2760
2761   $cd->cd_to_producer->update_or_create({
2762     producer => $producer,
2763     name => 'harry',
2764   }, {
2765     key => 'primary',
2766   });
2767
2768 B<Note>: Make sure to read the documentation of L</find> and understand the
2769 significance of the C<key> attribute, as its lack may skew your search, and
2770 subsequently result in spurious row creation.
2771
2772 B<Note>: Take care when using C<update_or_create> with a table having
2773 columns with default values that you intend to be automatically
2774 supplied by the database (e.g. an auto_increment primary key column).
2775 In normal usage, the value of such columns should NOT be included at
2776 all in the call to C<update_or_create>, even when set to C<undef>.
2777
2778 See also L</find> and L</find_or_create>. For information on how to declare
2779 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2780
2781 If you need to know if an existing row was updated or a new one created use
2782 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2783 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2784 database!
2785
2786   my $cd = $schema->resultset('CD')->update_or_new(
2787     {
2788       artist => 'Massive Attack',
2789       title  => 'Mezzanine',
2790       year   => 1998,
2791     },
2792     { key => 'cd_artist_title' }
2793   );
2794
2795   if( $cd->in_storage ) {
2796       # do some stuff
2797       $cd->insert;
2798   }
2799
2800 =cut
2801
2802 sub update_or_create {
2803   my $self = shift;
2804   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2805   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2806
2807   my $row = $self->find($cond, $attrs);
2808   if (defined $row) {
2809     $row->update($cond);
2810     return $row;
2811   }
2812
2813   return $self->create($cond);
2814 }
2815
2816 =head2 update_or_new
2817
2818 =over 4
2819
2820 =item Arguments: \%col_values, { key => $unique_constraint }?
2821
2822 =item Return Value: $rowobject
2823
2824 =back
2825
2826   $resultset->update_or_new({ col => $val, ... });
2827
2828 Like L</find_or_new> but if a row is found it is immediately updated via
2829 C<< $found_row->update (\%col_values) >>.
2830
2831 For example:
2832
2833   # In your application
2834   my $cd = $schema->resultset('CD')->update_or_new(
2835     {
2836       artist => 'Massive Attack',
2837       title  => 'Mezzanine',
2838       year   => 1998,
2839     },
2840     { key => 'cd_artist_title' }
2841   );
2842
2843   if ($cd->in_storage) {
2844       # the cd was updated
2845   }
2846   else {
2847       # the cd is not yet in the database, let's insert it
2848       $cd->insert;
2849   }
2850
2851 B<Note>: Make sure to read the documentation of L</find> and understand the
2852 significance of the C<key> attribute, as its lack may skew your search, and
2853 subsequently result in spurious new objects.
2854
2855 B<Note>: Take care when using C<update_or_new> with a table having
2856 columns with default values that you intend to be automatically
2857 supplied by the database (e.g. an auto_increment primary key column).
2858 In normal usage, the value of such columns should NOT be included at
2859 all in the call to C<update_or_new>, even when set to C<undef>.
2860
2861 See also L</find>, L</find_or_create> and L</find_or_new>.
2862
2863 =cut
2864
2865 sub update_or_new {
2866     my $self  = shift;
2867     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2868     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2869
2870     my $row = $self->find( $cond, $attrs );
2871     if ( defined $row ) {
2872         $row->update($cond);
2873         return $row;
2874     }
2875
2876     return $self->new_result($cond);
2877 }
2878
2879 =head2 get_cache
2880
2881 =over 4
2882
2883 =item Arguments: none
2884
2885 =item Return Value: \@cache_objects | undef
2886
2887 =back
2888
2889 Gets the contents of the cache for the resultset, if the cache is set.
2890
2891 The cache is populated either by using the L</prefetch> attribute to
2892 L</search> or by calling L</set_cache>.
2893
2894 =cut
2895
2896 sub get_cache {
2897   shift->{all_cache};
2898 }
2899
2900 =head2 set_cache
2901
2902 =over 4
2903
2904 =item Arguments: \@cache_objects
2905
2906 =item Return Value: \@cache_objects
2907
2908 =back
2909
2910 Sets the contents of the cache for the resultset. Expects an arrayref
2911 of objects of the same class as those produced by the resultset. Note that
2912 if the cache is set the resultset will return the cached objects rather
2913 than re-querying the database even if the cache attr is not set.
2914
2915 The contents of the cache can also be populated by using the
2916 L</prefetch> attribute to L</search>.
2917
2918 =cut
2919
2920 sub set_cache {
2921   my ( $self, $data ) = @_;
2922   $self->throw_exception("set_cache requires an arrayref")
2923       if defined($data) && (ref $data ne 'ARRAY');
2924   $self->{all_cache} = $data;
2925 }
2926
2927 =head2 clear_cache
2928
2929 =over 4
2930
2931 =item Arguments: none
2932
2933 =item Return Value: undef
2934
2935 =back
2936
2937 Clears the cache for the resultset.
2938
2939 =cut
2940
2941 sub clear_cache {
2942   shift->set_cache(undef);
2943 }
2944
2945 =head2 is_paged
2946
2947 =over 4
2948
2949 =item Arguments: none
2950
2951 =item Return Value: true, if the resultset has been paginated
2952
2953 =back
2954
2955 =cut
2956
2957 sub is_paged {
2958   my ($self) = @_;
2959   return !!$self->{attrs}{page};
2960 }
2961
2962 =head2 is_ordered
2963
2964 =over 4
2965
2966 =item Arguments: none
2967
2968 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2969
2970 =back
2971
2972 =cut
2973
2974 sub is_ordered {
2975   my ($self) = @_;
2976   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2977 }
2978
2979 =head2 related_resultset
2980
2981 =over 4
2982
2983 =item Arguments: $relationship_name
2984
2985 =item Return Value: $resultset
2986
2987 =back
2988
2989 Returns a related resultset for the supplied relationship name.
2990
2991   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2992
2993 =cut
2994
2995 sub related_resultset {
2996   my ($self, $rel) = @_;
2997
2998   $self->{related_resultsets} ||= {};
2999   return $self->{related_resultsets}{$rel} ||= do {
3000     my $rsrc = $self->result_source;
3001     my $rel_info = $rsrc->relationship_info($rel);
3002
3003     $self->throw_exception(
3004       "search_related: result source '" . $rsrc->source_name .
3005         "' has no such relationship $rel")
3006       unless $rel_info;
3007
3008     my $attrs = $self->_chain_relationship($rel);
3009
3010     my $join_count = $attrs->{seen_join}{$rel};
3011
3012     my $alias = $self->result_source->storage
3013         ->relname_to_table_alias($rel, $join_count);
3014
3015     # since this is search_related, and we already slid the select window inwards
3016     # (the select/as attrs were deleted in the beginning), we need to flip all
3017     # left joins to inner, so we get the expected results
3018     # read the comment on top of the actual function to see what this does
3019     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3020
3021
3022     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3023     delete @{$attrs}{qw(result_class alias)};
3024
3025     my $new_cache;
3026
3027     if (my $cache = $self->get_cache) {
3028       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3029         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache||[]} }
3030                         @$cache ];
3031       }
3032     }
3033
3034     my $rel_source = $rsrc->related_source($rel);
3035
3036     my $new = do {
3037
3038       # The reason we do this now instead of passing the alias to the
3039       # search_rs below is that if you wrap/overload resultset on the
3040       # source you need to know what alias it's -going- to have for things
3041       # to work sanely (e.g. RestrictWithObject wants to be able to add
3042       # extra query restrictions, and these may need to be $alias.)
3043
3044       my $rel_attrs = $rel_source->resultset_attributes;
3045       local $rel_attrs->{alias} = $alias;
3046
3047       $rel_source->resultset
3048                  ->search_rs(
3049                      undef, {
3050                        %$attrs,
3051                        where => $attrs->{where},
3052                    });
3053     };
3054     $new->set_cache($new_cache) if $new_cache;
3055     $new;
3056   };
3057 }
3058
3059 =head2 current_source_alias
3060
3061 =over 4
3062
3063 =item Arguments: none
3064
3065 =item Return Value: $source_alias
3066
3067 =back
3068
3069 Returns the current table alias for the result source this resultset is built
3070 on, that will be used in the SQL query. Usually it is C<me>.
3071
3072 Currently the source alias that refers to the result set returned by a
3073 L</search>/L</find> family method depends on how you got to the resultset: it's
3074 C<me> by default, but eg. L</search_related> aliases it to the related result
3075 source name (and keeps C<me> referring to the original result set). The long
3076 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3077 (and make this method unnecessary).
3078
3079 Thus it's currently necessary to use this method in predefined queries (see
3080 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3081 source alias of the current result set:
3082
3083   # in a result set class
3084   sub modified_by {
3085     my ($self, $user) = @_;
3086
3087     my $me = $self->current_source_alias;
3088
3089     return $self->search({
3090       "$me.modified" => $user->id,
3091     });
3092   }
3093
3094 =cut
3095
3096 sub current_source_alias {
3097   my ($self) = @_;
3098
3099   return ($self->{attrs} || {})->{alias} || 'me';
3100 }
3101
3102 =head2 as_subselect_rs
3103
3104 =over 4
3105
3106 =item Arguments: none
3107
3108 =item Return Value: $resultset
3109
3110 =back
3111
3112 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3113 "virtual view" by including it as a subquery within the from clause.  From this
3114 point on, any joined tables are inaccessible to ->search on the resultset (as if
3115 it were simply where-filtered without joins).  For example:
3116
3117  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3118
3119  # 'x' now pollutes the query namespace
3120
3121  # So the following works as expected
3122  my $ok_rs = $rs->search({'x.other' => 1});
3123
3124  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3125  # def) we look for one row with contradictory terms and join in another table
3126  # (aliased 'x_2') which we never use
3127  my $broken_rs = $rs->search({'x.name' => 'def'});
3128
3129  my $rs2 = $rs->as_subselect_rs;
3130
3131  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3132  my $not_joined_rs = $rs2->search({'x.other' => 1});
3133
3134  # works as expected: finds a 'table' row related to two x rows (abc and def)
3135  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3136
3137 Another example of when one might use this would be to select a subset of
3138 columns in a group by clause:
3139
3140  my $rs = $schema->resultset('Bar')->search(undef, {
3141    group_by => [qw{ id foo_id baz_id }],
3142  })->as_subselect_rs->search(undef, {
3143    columns => [qw{ id foo_id }]
3144  });
3145
3146 In the above example normally columns would have to be equal to the group by,
3147 but because we isolated the group by into a subselect the above works.
3148
3149 =cut
3150
3151 sub as_subselect_rs {
3152   my $self = shift;
3153
3154   my $attrs = $self->_resolved_attrs;
3155
3156   my $fresh_rs = (ref $self)->new (
3157     $self->result_source
3158   );
3159
3160   # these pieces will be locked in the subquery
3161   delete $fresh_rs->{cond};
3162   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3163
3164   return $fresh_rs->search( {}, {
3165     from => [{
3166       $attrs->{alias} => $self->as_query,
3167       -alias  => $attrs->{alias},
3168       -rsrc   => $self->result_source,
3169     }],
3170     alias => $attrs->{alias},
3171   });
3172 }
3173
3174 # This code is called by search_related, and makes sure there
3175 # is clear separation between the joins before, during, and
3176 # after the relationship. This information is needed later
3177 # in order to properly resolve prefetch aliases (any alias
3178 # with a relation_chain_depth less than the depth of the
3179 # current prefetch is not considered)
3180 #
3181 # The increments happen twice per join. An even number means a
3182 # relationship specified via a search_related, whereas an odd
3183 # number indicates a join/prefetch added via attributes
3184 #
3185 # Also this code will wrap the current resultset (the one we
3186 # chain to) in a subselect IFF it contains limiting attributes
3187 sub _chain_relationship {
3188   my ($self, $rel) = @_;
3189   my $source = $self->result_source;
3190   my $attrs = { %{$self->{attrs}||{}} };
3191
3192   # we need to take the prefetch the attrs into account before we
3193   # ->_resolve_join as otherwise they get lost - captainL
3194   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3195
3196   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3197
3198   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3199
3200   my $from;
3201   my @force_subq_attrs = qw/offset rows group_by having/;
3202
3203   if (
3204     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3205       ||
3206     $self->_has_resolved_attr (@force_subq_attrs)
3207   ) {
3208     # Nuke the prefetch (if any) before the new $rs attrs
3209     # are resolved (prefetch is useless - we are wrapping
3210     # a subquery anyway).
3211     my $rs_copy = $self->search;
3212     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3213       $rs_copy->{attrs}{join},
3214       delete $rs_copy->{attrs}{prefetch},
3215     );
3216
3217     $from = [{
3218       -rsrc   => $source,
3219       -alias  => $attrs->{alias},
3220       $attrs->{alias} => $rs_copy->as_query,
3221     }];
3222     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3223     $seen->{-relation_chain_depth} = 0;
3224   }
3225   elsif ($attrs->{from}) {  #shallow copy suffices
3226     $from = [ @{$attrs->{from}} ];
3227   }
3228   else {
3229     $from = [{
3230       -rsrc  => $source,
3231       -alias => $attrs->{alias},
3232       $attrs->{alias} => $source->from,
3233     }];
3234   }
3235
3236   my $jpath = ($seen->{-relation_chain_depth})
3237     ? $from->[-1][0]{-join_path}
3238     : [];
3239
3240   my @requested_joins = $source->_resolve_join(
3241     $join,
3242     $attrs->{alias},
3243     $seen,
3244     $jpath,
3245   );
3246
3247   push @$from, @requested_joins;
3248
3249   $seen->{-relation_chain_depth}++;
3250
3251   # if $self already had a join/prefetch specified on it, the requested
3252   # $rel might very well be already included. What we do in this case
3253   # is effectively a no-op (except that we bump up the chain_depth on
3254   # the join in question so we could tell it *is* the search_related)
3255   my $already_joined;
3256
3257   # we consider the last one thus reverse
3258   for my $j (reverse @requested_joins) {
3259     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3260     if ($rel eq $last_j) {
3261       $j->[0]{-relation_chain_depth}++;
3262       $already_joined++;
3263       last;
3264     }
3265   }
3266
3267   unless ($already_joined) {
3268     push @$from, $source->_resolve_join(
3269       $rel,
3270       $attrs->{alias},
3271       $seen,
3272       $jpath,
3273     );
3274   }
3275
3276   $seen->{-relation_chain_depth}++;
3277
3278   return {%$attrs, from => $from, seen_join => $seen};
3279 }
3280
3281 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3282 sub _resolved_attrs_copy {
3283   my $self = shift;
3284   return { %{$self->_resolved_attrs (@_)} };
3285 }
3286
3287 sub _resolved_attrs {
3288   my $self = shift;
3289   return $self->{_attrs} if $self->{_attrs};
3290
3291   my $attrs  = { %{ $self->{attrs} || {} } };
3292   my $source = $self->result_source;
3293   my $alias  = $attrs->{alias};
3294
3295   # default selection list
3296   $attrs->{columns} = [ $source->columns ]
3297     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3298
3299   # merge selectors together
3300   for (qw/columns select as/) {
3301     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3302       if $attrs->{$_} or $attrs->{"+$_"};
3303   }
3304
3305   # disassemble columns
3306   my (@sel, @as);
3307   if (my $cols = delete $attrs->{columns}) {
3308     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3309       if (ref $c eq 'HASH') {
3310         for my $as (keys %$c) {
3311           push @sel, $c->{$as};
3312           push @as, $as;
3313         }
3314       }
3315       else {
3316         push @sel, $c;
3317         push @as, $c;
3318       }
3319     }
3320   }
3321
3322   # when trying to weed off duplicates later do not go past this point -
3323   # everything added from here on is unbalanced "anyone's guess" stuff
3324   my $dedup_stop_idx = $#as;
3325
3326   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3327     if $attrs->{as};
3328   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3329     if $attrs->{select};
3330
3331   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3332   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3333
3334   # disqualify all $alias.col as-bits (inflate-map mandated)
3335   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3336
3337   # de-duplicate the result (remove *identical* select/as pairs)
3338   # and also die on duplicate {as} pointing to different {select}s
3339   # not using a c-style for as the condition is prone to shrinkage
3340   my $seen;
3341   my $i = 0;
3342   while ($i <= $dedup_stop_idx) {
3343     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3344       splice @sel, $i, 1;
3345       splice @as, $i, 1;
3346       $dedup_stop_idx--;
3347     }
3348     elsif ($seen->{$as[$i]}++) {
3349       $self->throw_exception(
3350         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3351       );
3352     }
3353     else {
3354       $i++;
3355     }
3356   }
3357
3358   $attrs->{select} = \@sel;
3359   $attrs->{as} = \@as;
3360
3361   $attrs->{from} ||= [{
3362     -rsrc   => $source,
3363     -alias  => $self->{attrs}{alias},
3364     $self->{attrs}{alias} => $source->from,
3365   }];
3366
3367   if ( $attrs->{join} || $attrs->{prefetch} ) {
3368
3369     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3370       if ref $attrs->{from} ne 'ARRAY';
3371
3372     my $join = (delete $attrs->{join}) || {};
3373
3374     if ( defined $attrs->{prefetch} ) {
3375       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3376     }
3377
3378     $attrs->{from} =    # have to copy here to avoid corrupting the original
3379       [
3380         @{ $attrs->{from} },
3381         $source->_resolve_join(
3382           $join,
3383           $alias,
3384           { %{ $attrs->{seen_join} || {} } },
3385           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3386             ? $attrs->{from}[-1][0]{-join_path}
3387             : []
3388           ,
3389         )
3390       ];
3391   }
3392
3393   if ( defined $attrs->{order_by} ) {
3394     $attrs->{order_by} = (
3395       ref( $attrs->{order_by} ) eq 'ARRAY'
3396       ? [ @{ $attrs->{order_by} } ]
3397       : [ $attrs->{order_by} || () ]
3398     );
3399   }
3400
3401   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3402     $attrs->{group_by} = [ $attrs->{group_by} ];
3403   }
3404
3405   # generate the distinct induced group_by early, as prefetch will be carried via a
3406   # subquery (since a group_by is present)
3407   if (delete $attrs->{distinct}) {
3408     if ($attrs->{group_by}) {
3409       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3410     }
3411     else {
3412       # distinct affects only the main selection part, not what prefetch may
3413       # add below.
3414       $attrs->{group_by} = $source->storage->_group_over_selection (
3415         $attrs->{from},
3416         $attrs->{select},
3417         $attrs->{order_by},
3418       );
3419     }
3420   }
3421
3422   # generate selections based on the prefetch helper
3423   my $prefetch;
3424   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3425     if defined $attrs->{prefetch};
3426
3427   if ($prefetch) {
3428
3429     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3430       if $attrs->{_dark_selector};
3431
3432     $attrs->{collapse} = 1;
3433
3434     # this is a separate structure (we don't look in {from} directly)
3435     # as the resolver needs to shift things off the lists to work
3436     # properly (identical-prefetches on different branches)
3437     my $join_map = {};
3438     if (ref $attrs->{from} eq 'ARRAY') {
3439
3440       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3441
3442       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3443         next unless $j->[0]{-alias};
3444         next unless $j->[0]{-join_path};
3445         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3446
3447         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3448
3449         my $p = $join_map;
3450         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3451         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3452       }
3453     }
3454
3455     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3456
3457     # we need to somehow mark which columns came from prefetch
3458     if (@prefetch) {
3459       my $sel_end = $#{$attrs->{select}};
3460       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3461     }
3462
3463     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3464     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3465   }
3466
3467   $attrs->{_single_object_inflation} = ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}};
3468
3469   # run through the resulting joinstructure (starting from our current slot)
3470   # and unset collapse if proven unnesessary
3471   if ($attrs->{collapse} && ref $attrs->{from} eq 'ARRAY') {
3472
3473     if (@{$attrs->{from}} > 1) {
3474
3475       # find where our table-spec starts and consider only things after us
3476       my @fromlist = @{$attrs->{from}};
3477       while (@fromlist) {
3478         my $t = shift @fromlist;
3479         $t = $t->[0] if ref $t eq 'ARRAY';  #me vs join from-spec mismatch
3480         last if ($t->{-alias} && $t->{-alias} eq $alias);
3481       }
3482
3483       for (@fromlist) {
3484         $attrs->{collapse} = ! $_->[0]{-is_single}
3485           and last;
3486       }
3487     }
3488     else {
3489       # no joins - no collapse
3490       $attrs->{collapse} = 0;
3491     }
3492   }
3493
3494   if (! $attrs->{order_by} and $attrs->{collapse}) {
3495     # default order for collapsing unless the user asked for something
3496     $attrs->{order_by} = [ map { "$alias.$_" } $source->primary_columns ];
3497     $attrs->{_ordered_for_collapse} = 1;
3498   }
3499
3500   # if both page and offset are specified, produce a combined offset
3501   # even though it doesn't make much sense, this is what pre 081xx has
3502   # been doing
3503   if (my $page = delete $attrs->{page}) {
3504     $attrs->{offset} =
3505       ($attrs->{rows} * ($page - 1))
3506             +
3507       ($attrs->{offset} || 0)
3508     ;
3509   }
3510
3511   return $self->{_attrs} = $attrs;
3512 }
3513
3514 sub _rollout_attr {
3515   my ($self, $attr) = @_;
3516
3517   if (ref $attr eq 'HASH') {
3518     return $self->_rollout_hash($attr);
3519   } elsif (ref $attr eq 'ARRAY') {
3520     return $self->_rollout_array($attr);
3521   } else {
3522     return [$attr];
3523   }
3524 }
3525
3526 sub _rollout_array {
3527   my ($self, $attr) = @_;
3528
3529   my @rolled_array;
3530   foreach my $element (@{$attr}) {
3531     if (ref $element eq 'HASH') {
3532       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3533     } elsif (ref $element eq 'ARRAY') {
3534       #  XXX - should probably recurse here
3535       push( @rolled_array, @{$self->_rollout_array($element)} );
3536     } else {
3537       push( @rolled_array, $element );
3538     }
3539   }
3540   return \@rolled_array;
3541 }
3542
3543 sub _rollout_hash {
3544   my ($self, $attr) = @_;
3545
3546   my @rolled_array;
3547   foreach my $key (keys %{$attr}) {
3548     push( @rolled_array, { $key => $attr->{$key} } );
3549   }
3550   return \@rolled_array;
3551 }
3552
3553 sub _calculate_score {
3554   my ($self, $a, $b) = @_;
3555
3556   if (defined $a xor defined $b) {
3557     return 0;
3558   }
3559   elsif (not defined $a) {
3560     return 1;
3561   }
3562
3563   if (ref $b eq 'HASH') {
3564     my ($b_key) = keys %{$b};
3565     if (ref $a eq 'HASH') {
3566       my ($a_key) = keys %{$a};
3567       if ($a_key eq $b_key) {
3568         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3569       } else {
3570         return 0;
3571       }
3572     } else {
3573       return ($a eq $b_key) ? 1 : 0;
3574     }
3575   } else {
3576     if (ref $a eq 'HASH') {
3577       my ($a_key) = keys %{$a};
3578       return ($b eq $a_key) ? 1 : 0;
3579     } else {
3580       return ($b eq $a) ? 1 : 0;
3581     }
3582   }
3583 }
3584
3585 sub _merge_joinpref_attr {
3586   my ($self, $orig, $import) = @_;
3587
3588   return $import unless defined($orig);
3589   return $orig unless defined($import);
3590
3591   $orig = $self->_rollout_attr($orig);
3592   $import = $self->_rollout_attr($import);
3593
3594   my $seen_keys;
3595   foreach my $import_element ( @{$import} ) {
3596     # find best candidate from $orig to merge $b_element into
3597     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3598     foreach my $orig_element ( @{$orig} ) {
3599       my $score = $self->_calculate_score( $orig_element, $import_element );
3600       if ($score > $best_candidate->{score}) {
3601         $best_candidate->{position} = $position;
3602         $best_candidate->{score} = $score;
3603       }
3604       $position++;
3605     }
3606     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3607     $import_key = '' if not defined $import_key;
3608
3609     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3610       push( @{$orig}, $import_element );
3611     } else {
3612       my $orig_best = $orig->[$best_candidate->{position}];
3613       # merge orig_best and b_element together and replace original with merged
3614       if (ref $orig_best ne 'HASH') {
3615         $orig->[$best_candidate->{position}] = $import_element;
3616       } elsif (ref $import_element eq 'HASH') {
3617         my ($key) = keys %{$orig_best};
3618         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3619       }
3620     }
3621     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3622   }
3623
3624   return $orig;
3625 }
3626
3627 {
3628   my $hm;
3629
3630   sub _merge_attr {
3631     $hm ||= do {
3632       require Hash::Merge;
3633       my $hm = Hash::Merge->new;
3634
3635       $hm->specify_behavior({
3636         SCALAR => {
3637           SCALAR => sub {
3638             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3639
3640             if ($defl xor $defr) {
3641               return [ $defl ? $_[0] : $_[1] ];
3642             }
3643             elsif (! $defl) {
3644               return [];
3645             }
3646             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3647               return [ $_[0] ];
3648             }
3649             else {
3650               return [$_[0], $_[1]];
3651             }
3652           },
3653           ARRAY => sub {
3654             return $_[1] if !defined $_[0];
3655             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3656             return [$_[0], @{$_[1]}]
3657           },
3658           HASH  => sub {
3659             return [] if !defined $_[0] and !keys %{$_[1]};
3660             return [ $_[1] ] if !defined $_[0];
3661             return [ $_[0] ] if !keys %{$_[1]};
3662             return [$_[0], $_[1]]
3663           },
3664         },
3665         ARRAY => {
3666           SCALAR => sub {
3667             return $_[0] if !defined $_[1];
3668             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3669             return [@{$_[0]}, $_[1]]
3670           },
3671           ARRAY => sub {
3672             my @ret = @{$_[0]} or return $_[1];
3673             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3674             my %idx = map { $_ => 1 } @ret;
3675             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3676             \@ret;
3677           },
3678           HASH => sub {
3679             return [ $_[1] ] if ! @{$_[0]};
3680             return $_[0] if !keys %{$_[1]};
3681             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3682             return [ @{$_[0]}, $_[1] ];
3683           },
3684         },
3685         HASH => {
3686           SCALAR => sub {
3687             return [] if !keys %{$_[0]} and !defined $_[1];
3688             return [ $_[0] ] if !defined $_[1];
3689             return [ $_[1] ] if !keys %{$_[0]};
3690             return [$_[0], $_[1]]
3691           },
3692           ARRAY => sub {
3693             return [] if !keys %{$_[0]} and !@{$_[1]};
3694             return [ $_[0] ] if !@{$_[1]};
3695             return $_[1] if !keys %{$_[0]};
3696             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3697             return [ $_[0], @{$_[1]} ];
3698           },
3699           HASH => sub {
3700             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3701             return [ $_[0] ] if !keys %{$_[1]};
3702             return [ $_[1] ] if !keys %{$_[0]};
3703             return [ $_[0] ] if $_[0] eq $_[1];
3704             return [ $_[0], $_[1] ];
3705           },
3706         }
3707       } => 'DBIC_RS_ATTR_MERGER');
3708       $hm;
3709     };
3710
3711     return $hm->merge ($_[1], $_[2]);
3712   }
3713 }
3714
3715 sub STORABLE_freeze {
3716   my ($self, $cloning) = @_;
3717   my $to_serialize = { %$self };
3718
3719   # A cursor in progress can't be serialized (and would make little sense anyway)
3720   # the parser can be regenerated (and can't be serialized)
3721   delete @{$to_serialize}{qw/cursor _row_parser/};
3722
3723   # nor is it sensical to store a not-yet-fired-count pager
3724   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3725     delete $to_serialize->{pager};
3726   }
3727
3728   Storable::nfreeze($to_serialize);
3729 }
3730
3731 # need this hook for symmetry
3732 sub STORABLE_thaw {
3733   my ($self, $cloning, $serialized) = @_;
3734
3735   %$self = %{ Storable::thaw($serialized) };
3736
3737   $self;
3738 }
3739
3740
3741 =head2 throw_exception
3742
3743 See L<DBIx::Class::Schema/throw_exception> for details.
3744
3745 =cut
3746
3747 sub throw_exception {
3748   my $self=shift;
3749
3750   if (ref $self and my $rsrc = $self->result_source) {
3751     $rsrc->throw_exception(@_)
3752   }
3753   else {
3754     DBIx::Class::Exception->throw(@_);
3755   }
3756 }
3757
3758 # XXX: FIXME: Attributes docs need clearing up
3759
3760 =head1 ATTRIBUTES
3761
3762 Attributes are used to refine a ResultSet in various ways when
3763 searching for data. They can be passed to any method which takes an
3764 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3765 L</count>.
3766
3767 These are in no particular order:
3768
3769 =head2 order_by
3770
3771 =over 4
3772
3773 =item Value: ( $order_by | \@order_by | \%order_by )
3774
3775 =back
3776
3777 Which column(s) to order the results by.
3778
3779 [The full list of suitable values is documented in
3780 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3781 common options.]
3782
3783 If a single column name, or an arrayref of names is supplied, the
3784 argument is passed through directly to SQL. The hashref syntax allows
3785 for connection-agnostic specification of ordering direction:
3786
3787  For descending order:
3788
3789   order_by => { -desc => [qw/col1 col2 col3/] }
3790
3791  For explicit ascending order:
3792
3793   order_by => { -asc => 'col' }
3794
3795 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3796 supported, although you are strongly encouraged to use the hashref
3797 syntax as outlined above.
3798
3799 =head2 columns
3800
3801 =over 4
3802
3803 =item Value: \@columns
3804
3805 =back
3806
3807 Shortcut to request a particular set of columns to be retrieved. Each
3808 column spec may be a string (a table column name), or a hash (in which
3809 case the key is the C<as> value, and the value is used as the C<select>
3810 expression). Adds C<me.> onto the start of any column without a C<.> in
3811 it and sets C<select> from that, then auto-populates C<as> from
3812 C<select> as normal. (You may also use the C<cols> attribute, as in
3813 earlier versions of DBIC.)
3814
3815 Essentially C<columns> does the same as L</select> and L</as>.
3816
3817     columns => [ 'foo', { bar => 'baz' } ]
3818
3819 is the same as
3820
3821     select => [qw/foo baz/],
3822     as => [qw/foo bar/]
3823
3824 =head2 +columns
3825
3826 =over 4
3827
3828 =item Value: \@columns
3829
3830 =back
3831
3832 Indicates additional columns to be selected from storage. Works the same
3833 as L</columns> but adds columns to the selection. (You may also use the
3834 C<include_columns> attribute, as in earlier versions of DBIC). For
3835 example:-
3836
3837   $schema->resultset('CD')->search(undef, {
3838     '+columns' => ['artist.name'],
3839     join => ['artist']
3840   });
3841
3842 would return all CDs and include a 'name' column to the information
3843 passed to object inflation. Note that the 'artist' is the name of the
3844 column (or relationship) accessor, and 'name' is the name of the column
3845 accessor in the related table.
3846
3847 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3848 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3849 unary plus operator before it.
3850
3851 =head2 include_columns
3852
3853 =over 4
3854
3855 =item Value: \@columns
3856
3857 =back
3858
3859 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3860
3861 =head2 select
3862
3863 =over 4
3864
3865 =item Value: \@select_columns
3866
3867 =back
3868
3869 Indicates which columns should be selected from the storage. You can use
3870 column names, or in the case of RDBMS back ends, function or stored procedure
3871 names:
3872
3873   $rs = $schema->resultset('Employee')->search(undef, {
3874     select => [
3875       'name',
3876       { count => 'employeeid' },
3877       { max => { length => 'name' }, -as => 'longest_name' }
3878     ]
3879   });
3880
3881   # Equivalent SQL
3882   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3883
3884 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3885 use L</select>, to instruct DBIx::Class how to store the result of the column.
3886 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3887 identifier aliasing. You can however alias a function, so you can use it in
3888 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3889 attribute> supplied as shown in the example above.
3890
3891 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3892 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3893 unary plus operator before it.
3894
3895 =head2 +select
3896
3897 =over 4
3898
3899 Indicates additional columns to be selected from storage.  Works the same as
3900 L</select> but adds columns to the default selection, instead of specifying
3901 an explicit list.
3902
3903 =back
3904
3905 =head2 +as
3906
3907 =over 4
3908
3909 Indicates additional column names for those added via L</+select>. See L</as>.
3910
3911 =back
3912
3913 =head2 as
3914
3915 =over 4
3916
3917 =item Value: \@inflation_names
3918
3919 =back
3920
3921 Indicates column names for object inflation. That is L</as> indicates the
3922 slot name in which the column value will be stored within the
3923 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3924 identifier by the C<get_column> method (or via the object accessor B<if one
3925 with the same name already exists>) as shown below. The L</as> attribute has
3926 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3927
3928   $rs = $schema->resultset('Employee')->search(undef, {
3929     select => [
3930       'name',
3931       { count => 'employeeid' },
3932       { max => { length => 'name' }, -as => 'longest_name' }
3933     ],
3934     as => [qw/
3935       name
3936       employee_count
3937       max_name_length
3938     /],
3939   });
3940
3941 If the object against which the search is performed already has an accessor
3942 matching a column name specified in C<as>, the value can be retrieved using
3943 the accessor as normal:
3944
3945   my $name = $employee->name();
3946
3947 If on the other hand an accessor does not exist in the object, you need to
3948 use C<get_column> instead:
3949
3950   my $employee_count = $employee->get_column('employee_count');
3951
3952 You can create your own accessors if required - see
3953 L<DBIx::Class::Manual::Cookbook> for details.
3954
3955 =head2 join
3956
3957 =over 4
3958
3959 =item Value: ($rel_name | \@rel_names | \%rel_names)
3960
3961 =back
3962
3963 Contains a list of relationships that should be joined for this query.  For
3964 example:
3965
3966   # Get CDs by Nine Inch Nails
3967   my $rs = $schema->resultset('CD')->search(
3968     { 'artist.name' => 'Nine Inch Nails' },
3969     { join => 'artist' }
3970   );
3971
3972 Can also contain a hash reference to refer to the other relation's relations.
3973 For example:
3974
3975   package MyApp::Schema::Track;
3976   use base qw/DBIx::Class/;
3977   __PACKAGE__->table('track');
3978   __PACKAGE__->add_columns(qw/trackid cd position title/);
3979   __PACKAGE__->set_primary_key('trackid');
3980   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3981   1;
3982
3983   # In your application
3984   my $rs = $schema->resultset('Artist')->search(
3985     { 'track.title' => 'Teardrop' },
3986     {
3987       join     => { cd => 'track' },
3988       order_by => 'artist.name',
3989     }
3990   );
3991
3992 You need to use the relationship (not the table) name in  conditions,
3993 because they are aliased as such. The current table is aliased as "me", so
3994 you need to use me.column_name in order to avoid ambiguity. For example:
3995
3996   # Get CDs from 1984 with a 'Foo' track
3997   my $rs = $schema->resultset('CD')->search(
3998     {
3999       'me.year' => 1984,
4000       'tracks.name' => 'Foo'
4001     },
4002     { join => 'tracks' }
4003   );
4004
4005 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4006 similarly for a third time). For e.g.
4007
4008   my $rs = $schema->resultset('Artist')->search({
4009     'cds.title'   => 'Down to Earth',
4010     'cds_2.title' => 'Popular',
4011   }, {
4012     join => [ qw/cds cds/ ],
4013   });
4014
4015 will return a set of all artists that have both a cd with title 'Down
4016 to Earth' and a cd with title 'Popular'.
4017
4018 If you want to fetch related objects from other tables as well, see C<prefetch>
4019 below.
4020
4021 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4022
4023 =head2 prefetch
4024
4025 =over 4
4026
4027 =item Value: ($rel_name | \@rel_names | \%rel_names)
4028
4029 =back
4030
4031 Contains one or more relationships that should be fetched along with
4032 the main query (when they are accessed afterwards the data will
4033 already be available, without extra queries to the database).  This is
4034 useful for when you know you will need the related objects, because it
4035 saves at least one query:
4036
4037   my $rs = $schema->resultset('Tag')->search(
4038     undef,
4039     {
4040       prefetch => {
4041         cd => 'artist'
4042       }
4043     }
4044   );
4045
4046 The initial search results in SQL like the following:
4047
4048   SELECT tag.*, cd.*, artist.* FROM tag
4049   JOIN cd ON tag.cd = cd.cdid
4050   JOIN artist ON cd.artist = artist.artistid
4051
4052 L<DBIx::Class> has no need to go back to the database when we access the
4053 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4054 case.
4055
4056 Simple prefetches will be joined automatically, so there is no need
4057 for a C<join> attribute in the above search.
4058
4059 L</prefetch> can be used with the any of the relationship types and
4060 multiple prefetches can be specified together. Below is a more complex
4061 example that prefetches a CD's artist, its liner notes (if present),
4062 the cover image, the tracks on that cd, and the guests on those
4063 tracks.
4064
4065  # Assuming:
4066  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4067  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4068  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4069  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4070
4071  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4072
4073  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4074
4075
4076  my $rs = $schema->resultset('CD')->search(
4077    undef,
4078    {
4079      prefetch => [
4080        { artist => 'record_label'},  # belongs_to => belongs_to
4081        'liner_note',                 # might_have
4082        'cover_image',                # has_one
4083        { tracks => 'guests' },       # has_many => has_many
4084      ]
4085    }
4086  );
4087
4088 This will produce SQL like the following:
4089
4090  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4091         tracks.*, guests.*
4092    FROM cd me
4093    JOIN artist artist
4094      ON artist.artistid = me.artistid
4095    JOIN record_label record_label
4096      ON record_label.labelid = artist.labelid
4097    LEFT JOIN track tracks
4098      ON tracks.cdid = me.cdid
4099    LEFT JOIN guest guests
4100      ON guests.trackid = track.trackid
4101    LEFT JOIN liner_notes liner_note
4102      ON liner_note.cdid = me.cdid
4103    JOIN cd_artwork cover_image
4104      ON cover_image.cdid = me.cdid
4105  ORDER BY tracks.cd
4106
4107 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4108 C<tracks>, and C<guests> of the CD will all be available through the
4109 relationship accessors without the need for additional queries to the
4110 database.
4111
4112 However, there is one caveat to be observed: it can be dangerous to
4113 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4114 relationship on a given level. e.g.:
4115
4116  my $rs = $schema->resultset('CD')->search(
4117    undef,
4118    {
4119      prefetch => [
4120        'tracks',                         # has_many
4121        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4122      ]
4123    }
4124  );
4125
4126 In fact, C<DBIx::Class> will emit the following warning:
4127
4128  Prefetching multiple has_many rels tracks and cd_to_producer at top
4129  level will explode the number of row objects retrievable via ->next
4130  or ->all. Use at your own risk.
4131
4132 The collapser currently can't identify duplicate tuples for multiple
4133 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4134 result the second L<has_many|DBIx::Class::Relationship/has_many>
4135 relation could contain redundant objects.
4136
4137 =head3 Using L</prefetch> with L</join>
4138
4139 L</prefetch> implies a L</join> with the equivalent argument, and is
4140 properly merged with any existing L</join> specification. So the
4141 following:
4142
4143   my $rs = $schema->resultset('CD')->search(
4144    {'record_label.name' => 'Music Product Ltd.'},
4145    {
4146      join     => {artist => 'record_label'},
4147      prefetch => 'artist',
4148    }
4149  );
4150
4151 ... will work, searching on the record label's name, but only
4152 prefetching the C<artist>.
4153
4154 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4155
4156 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4157 prefetched relations.  So given:
4158
4159   my $rs = $schema->resultset('CD')->search(
4160    undef,
4161    {
4162      select   => ['cd.title'],
4163      as       => ['cd_title'],
4164      prefetch => 'artist',
4165    }
4166  );
4167
4168 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4169 becomes: C<'cd_title', 'artist.*'>.
4170
4171 =head3 CAVEATS
4172
4173 Prefetch does a lot of deep magic. As such, it may not behave exactly
4174 as you might expect.
4175
4176 =over 4
4177
4178 =item *
4179
4180 Prefetch uses the L</cache> to populate the prefetched relationships. This
4181 may or may not be what you want.
4182
4183 =item *
4184
4185 If you specify a condition on a prefetched relationship, ONLY those
4186 rows that match the prefetched condition will be fetched into that relationship.
4187 This means that adding prefetch to a search() B<may alter> what is returned by
4188 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4189
4190   my $artist_rs = $schema->resultset('Artist')->search({
4191       'cds.year' => 2008,
4192   }, {
4193       join => 'cds',
4194   });
4195
4196   my $count = $artist_rs->first->cds->count;
4197
4198   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4199
4200   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4201
4202   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4203
4204 that cmp_ok() may or may not pass depending on the datasets involved. This
4205 behavior may or may not survive the 0.09 transition.
4206
4207 =back
4208
4209 =head2 page
4210
4211 =over 4
4212
4213 =item Value: $page
4214
4215 =back
4216
4217 Makes the resultset paged and specifies the page to retrieve. Effectively
4218 identical to creating a non-pages resultset and then calling ->page($page)
4219 on it.
4220
4221 If L</rows> attribute is not specified it defaults to 10 rows per page.
4222
4223 When you have a paged resultset, L</count> will only return the number
4224 of rows in the page. To get the total, use the L</pager> and call
4225 C<total_entries> on it.
4226
4227 =head2 rows
4228
4229 =over 4
4230
4231 =item Value: $rows
4232
4233 =back
4234
4235 Specifies the maximum number of rows for direct retrieval or the number of
4236 rows per page if the page attribute or method is used.
4237
4238 =head2 offset
4239
4240 =over 4
4241
4242 =item Value: $offset
4243
4244 =back
4245
4246 Specifies the (zero-based) row number for the  first row to be returned, or the
4247 of the first row of the first page if paging is used.
4248
4249 =head2 software_limit
4250
4251 =over 4
4252
4253 =item Value: (0 | 1)
4254
4255 =back
4256
4257 When combined with L</rows> and/or L</offset> the generated SQL will not
4258 include any limit dialect stanzas. Instead the entire result will be selected
4259 as if no limits were specified, and DBIC will perform the limit locally, by
4260 artificially advancing and finishing the resulting L</cursor>.
4261
4262 This is the recommended way of performing resultset limiting when no sane RDBMS
4263 implementation is available (e.g.
4264 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4265 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4266
4267 =head2 group_by
4268
4269 =over 4
4270
4271 =item Value: \@columns
4272
4273 =back
4274
4275 A arrayref of columns to group by. Can include columns of joined tables.
4276
4277   group_by => [qw/ column1 column2 ... /]
4278
4279 =head2 having
4280
4281 =over 4
4282
4283 =item Value: $condition
4284
4285 =back
4286
4287 HAVING is a select statement attribute that is applied between GROUP BY and
4288 ORDER BY. It is applied to the after the grouping calculations have been
4289 done.
4290
4291   having => { 'count_employee' => { '>=', 100 } }
4292
4293 or with an in-place function in which case literal SQL is required:
4294
4295   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4296
4297 =head2 distinct
4298
4299 =over 4
4300
4301 =item Value: (0 | 1)
4302
4303 =back
4304
4305 Set to 1 to group by all columns. If the resultset already has a group_by
4306 attribute, this setting is ignored and an appropriate warning is issued.
4307
4308 =head2 where
4309
4310 =over 4
4311
4312 Adds to the WHERE clause.
4313
4314   # only return rows WHERE deleted IS NULL for all searches
4315   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4316
4317 Can be overridden by passing C<< { where => undef } >> as an attribute
4318 to a resultset.
4319
4320 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4321
4322 =back
4323
4324 =head2 cache
4325
4326 Set to 1 to cache search results. This prevents extra SQL queries if you
4327 revisit rows in your ResultSet:
4328
4329   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4330
4331   while( my $artist = $resultset->next ) {
4332     ... do stuff ...
4333   }
4334
4335   $rs->first; # without cache, this would issue a query
4336
4337 By default, searches are not cached.
4338
4339 For more examples of using these attributes, see
4340 L<DBIx::Class::Manual::Cookbook>.
4341
4342 =head2 for
4343
4344 =over 4
4345
4346 =item Value: ( 'update' | 'shared' )
4347
4348 =back
4349
4350 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4351 ... FOR SHARED.
4352
4353 =cut
4354
4355 1;