lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (ie:
 145 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247   $attrs = { %{$attrs||{}} };
 248
 249   if ($attrs->{page}) {
 250     $attrs->{rows} ||= 10;
 251   }
 252
 253   $attrs->{alias} ||= 'me';
 254
 255   my $self = bless {
 256     result_source => $source,
 257     cond => $attrs->{where},
 258     pager => undef,
 259     attrs => $attrs,
 260   }, $class;
 261
 262   # if there is a dark selector, this means we are already in a
 263   # chain and the cleanup/sanification was taken care of by
 264   # _search_rs already
 265   $self->_normalize_selection($attrs)
 266     unless $attrs->{_dark_selector};
 267
 268   $self->result_class(
 269     $attrs->{result_class} || $source->result_class
 270   );
 271
 272   $self;
 273 }
 274
 275 =head2 search
 276
 277 =over 4
 278
 279 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 280
 281 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 282
 283 =back
 284
 285   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 286   my $new_rs = $cd_rs->search({ year => 2005 });
 287
 288   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 289                  # year = 2005 OR year = 2004
 290
 291 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 292 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 293 To avoid that, use L</search_rs>.
 294
 295 If you need to pass in additional attributes but no additional condition,
 296 call it as C<search(undef, \%attrs)>.
 297
 298   # "SELECT name, artistid FROM $artist_table"
 299   my @all_artists = $schema->resultset('Artist')->search(undef, {
 300     columns => [qw/name artistid/],
 301   });
 302
 303 For a list of attributes that can be passed to C<search>, see
 304 L</ATTRIBUTES>. For more examples of using this function, see
 305 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 306 documentation for the first argument, see L<SQL::Abstract>
 307 and its extension L<DBIx::Class::SQLMaker>.
 308
 309 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 310
 311 =head3 CAVEAT
 312
 313 Note that L</search> does not process/deflate any of the values passed in the
 314 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 315 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 316 manually that any value passed to this method will stringify to something the
 317 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 318 objects, for more info see:
 319 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 320
 321 =cut
 322
 323 sub search {
 324   my $self = shift;
 325   my $rs = $self->search_rs( @_ );
 326
 327   if (wantarray) {
 328     return $rs->all;
 329   }
 330   elsif (defined wantarray) {
 331     return $rs;
 332   }
 333   else {
 334     # we can be called by a relationship helper, which in
 335     # turn may be called in void context due to some braindead
 336     # overload or whatever else the user decided to be clever
 337     # at this particular day. Thus limit the exception to
 338     # external code calls only
 339     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 340       if (caller)[0] !~ /^\QDBIx::Class::/;
 341
 342     return ();
 343   }
 344 }
 345
 346 =head2 search_rs
 347
 348 =over 4
 349
 350 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 351
 352 =item Return Value: L<$resultset|/search>
 353
 354 =back
 355
 356 This method does the same exact thing as search() except it will
 357 always return a resultset, even in list context.
 358
 359 =cut
 360
 361 sub search_rs {
 362   my $self = shift;
 363
 364   my $rsrc = $self->result_source;
 365   my ($call_cond, $call_attrs);
 366
 367   # Special-case handling for (undef, undef) or (undef)
 368   # Note that (foo => undef) is valid deprecated syntax
 369   @_ = () if not scalar grep { defined $_ } @_;
 370
 371   # just a cond
 372   if (@_ == 1) {
 373     $call_cond = shift;
 374   }
 375   # fish out attrs in the ($condref, $attr) case
 376   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 377     ($call_cond, $call_attrs) = @_;
 378   }
 379   elsif (@_ % 2) {
 380     $self->throw_exception('Odd number of arguments to search')
 381   }
 382   # legacy search
 383   elsif (@_) {
 384     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 385       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 386
 387     for my $i (0 .. $#_) {
 388       next if $i % 2;
 389       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 390         if (! defined $_[$i] or ref $_[$i] ne '');
 391     }
 392
 393     $call_cond = { @_ };
 394   }
 395
 396   # see if we can keep the cache (no $rs changes)
 397   my $cache;
 398   my %safe = (alias => 1, cache => 1);
 399   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 400     ! defined $call_cond
 401       or
 402     ref $call_cond eq 'HASH' && ! keys %$call_cond
 403       or
 404     ref $call_cond eq 'ARRAY' && ! @$call_cond
 405   )) {
 406     $cache = $self->get_cache;
 407   }
 408
 409   my $old_attrs = { %{$self->{attrs}} };
 410   my $old_having = delete $old_attrs->{having};
 411   my $old_where = delete $old_attrs->{where};
 412
 413   my $new_attrs = { %$old_attrs };
 414
 415   # take care of call attrs (only if anything is changing)
 416   if ($call_attrs and keys %$call_attrs) {
 417
 418     # copy for _normalize_selection
 419     $call_attrs = { %$call_attrs };
 420
 421     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 422
 423     # reset the current selector list if new selectors are supplied
 424     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 425       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 426     }
 427
 428     # Normalize the new selector list (operates on the passed-in attr structure)
 429     # Need to do it on every chain instead of only once on _resolved_attrs, in
 430     # order to allow detection of empty vs partial 'as'
 431     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 432       if $old_attrs->{_dark_selector};
 433     $self->_normalize_selection ($call_attrs);
 434
 435     # start with blind overwriting merge, exclude selector attrs
 436     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 437     delete @{$new_attrs}{@selector_attrs};
 438
 439     for (@selector_attrs) {
 440       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 441         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 442     }
 443
 444     # older deprecated name, use only if {columns} is not there
 445     if (my $c = delete $new_attrs->{cols}) {
 446       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 447       if ($new_attrs->{columns}) {
 448         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 449       }
 450       else {
 451         $new_attrs->{columns} = $c;
 452       }
 453     }
 454
 455
 456     # join/prefetch use their own crazy merging heuristics
 457     foreach my $key (qw/join prefetch/) {
 458       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 459         if exists $call_attrs->{$key};
 460     }
 461
 462     # stack binds together
 463     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 464   }
 465
 466
 467   for ($old_where, $call_cond) {
 468     if (defined $_) {
 469       $new_attrs->{where} = $self->_stack_cond (
 470         $_, $new_attrs->{where}
 471       );
 472     }
 473   }
 474
 475   if (defined $old_having) {
 476     $new_attrs->{having} = $self->_stack_cond (
 477       $old_having, $new_attrs->{having}
 478     )
 479   }
 480
 481   my $rs = (ref $self)->new($rsrc, $new_attrs);
 482
 483   $rs->set_cache($cache) if ($cache);
 484
 485   return $rs;
 486 }
 487
 488 my $dark_sel_dumper;
 489 sub _normalize_selection {
 490   my ($self, $attrs) = @_;
 491
 492   # legacy syntax
 493   if ( exists $attrs->{include_columns} ) {
 494     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 495     $attrs->{'+columns'} = $self->_merge_attr(
 496       $attrs->{'+columns'}, delete $attrs->{include_columns}
 497     );
 498   }
 499
 500   # columns are always placed first, however
 501
 502   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 503   # delay the decision on whether to use a default select list ($rsrc->columns)
 504   # allowing stuff like the remove_columns helper to work
 505   #
 506   # select/as +select/+as pairs need special handling - the amount of select/as
 507   # elements in each pair does *not* have to be equal (think multicolumn
 508   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 509   # supplied at all) - try to infer the alias, either from the -as parameter
 510   # of the selector spec, or use the parameter whole if it looks like a column
 511   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 512   # is ok as well), but make sure no more additions to the 'as' chain take place
 513   for my $pref ('', '+') {
 514
 515     my ($sel, $as) = map {
 516       my $key = "${pref}${_}";
 517
 518       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 519         ? @{$attrs->{$key}}
 520         : $attrs->{$key} || ()
 521       ];
 522       delete $attrs->{$key};
 523       $val;
 524     } qw/select as/;
 525
 526     if (! @$as and ! @$sel ) {
 527       next;
 528     }
 529     elsif (@$as and ! @$sel) {
 530       $self->throw_exception(
 531         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 532       );
 533     }
 534     elsif( ! @$as ) {
 535       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 536       # if any @$as has been supplied we assume the user knows what (s)he is doing
 537       # and blindly keep stacking up pieces
 538       unless ($attrs->{_dark_selector}) {
 539         SELECTOR:
 540         for (@$sel) {
 541           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 542             push @$as, $_->{-as};
 543           }
 544           # assume any plain no-space, no-parenthesis string to be a column spec
 545           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 546           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 547             push @$as, $_;
 548           }
 549           # if all else fails - raise a flag that no more aliasing will be allowed
 550           else {
 551             $attrs->{_dark_selector} = {
 552               plus_stage => $pref,
 553               string => ($dark_sel_dumper ||= do {
 554                   require Data::Dumper::Concise;
 555                   Data::Dumper::Concise::DumperObject()->Indent(0);
 556                 })->Values([$_])->Dump
 557               ,
 558             };
 559             last SELECTOR;
 560           }
 561         }
 562       }
 563     }
 564     elsif (@$as < @$sel) {
 565       $self->throw_exception(
 566         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 567       );
 568     }
 569     elsif ($pref and $attrs->{_dark_selector}) {
 570       $self->throw_exception(
 571         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 572       );
 573     }
 574
 575
 576     # merge result
 577     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 578     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 579   }
 580 }
 581
 582 sub _stack_cond {
 583   my ($self, $left, $right) = @_;
 584
 585   # collapse single element top-level conditions
 586   # (single pass only, unlikely to need recursion)
 587   for ($left, $right) {
 588     if (ref $_ eq 'ARRAY') {
 589       if (@$_ == 0) {
 590         $_ = undef;
 591       }
 592       elsif (@$_ == 1) {
 593         $_ = $_->[0];
 594       }
 595     }
 596     elsif (ref $_ eq 'HASH') {
 597       my ($first, $more) = keys %$_;
 598
 599       # empty hash
 600       if (! defined $first) {
 601         $_ = undef;
 602       }
 603       # one element hash
 604       elsif (! defined $more) {
 605         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 606           $_ = $_->{'-and'};
 607         }
 608         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 609           $_ = $_->{'-or'};
 610         }
 611       }
 612     }
 613   }
 614
 615   # merge hashes with weeding out of duplicates (simple cases only)
 616   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 617
 618     # shallow copy to destroy
 619     $right = { %$right };
 620     for (grep { exists $right->{$_} } keys %$left) {
 621       # the use of eq_deeply here is justified - the rhs of an
 622       # expression can contain a lot of twisted weird stuff
 623       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 624     }
 625
 626     $right = undef unless keys %$right;
 627   }
 628
 629
 630   if (defined $left xor defined $right) {
 631     return defined $left ? $left : $right;
 632   }
 633   elsif (! defined $left) {
 634     return undef;
 635   }
 636   else {
 637     return { -and => [ $left, $right ] };
 638   }
 639 }
 640
 641 =head2 search_literal
 642
 643 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 644 should only be used in that context. C<search_literal> is a convenience
 645 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 646 want to ensure columns are bound correctly, use L</search>.
 647
 648 See L<DBIx::Class::Manual::Cookbook/Searching> and
 649 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 650 require C<search_literal>.
 651
 652 =over 4
 653
 654 =item Arguments: $sql_fragment, @standalone_bind_values
 655
 656 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 657
 658 =back
 659
 660   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 661   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 662
 663 Pass a literal chunk of SQL to be added to the conditional part of the
 664 resultset query.
 665
 666 Example of how to use C<search> instead of C<search_literal>
 667
 668   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 669   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 670
 671 =cut
 672
 673 sub search_literal {
 674   my ($self, $sql, @bind) = @_;
 675   my $attr;
 676   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 677     $attr = pop @bind;
 678   }
 679   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 680 }
 681
 682 =head2 find
 683
 684 =over 4
 685
 686 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 687
 688 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 689
 690 =back
 691
 692 Finds and returns a single row based on supplied criteria. Takes either a
 693 hashref with the same format as L</create> (including inference of foreign
 694 keys from related objects), or a list of primary key values in the same
 695 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 696 declaration on the L</result_source>.
 697
 698 In either case an attempt is made to combine conditions already existing on
 699 the resultset with the condition passed to this method.
 700
 701 To aid with preparing the correct query for the storage you may supply the
 702 C<key> attribute, which is the name of a
 703 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 704 unique constraint corresponding to the
 705 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 706 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 707 to construct a query that satisfies the named unique constraint fully (
 708 non-NULL values for each column member of the constraint) an exception is
 709 thrown.
 710
 711 If no C<key> is specified, the search is carried over all unique constraints
 712 which are fully defined by the available condition.
 713
 714 If no such constraint is found, C<find> currently defaults to a simple
 715 C<< search->(\%column_values) >> which may or may not do what you expect.
 716 Note that this fallback behavior may be deprecated in further versions. If
 717 you need to search with arbitrary conditions - use L</search>. If the query
 718 resulting from this fallback produces more than one row, a warning to the
 719 effect is issued, though only the first row is constructed and returned as
 720 C<$result_object>.
 721
 722 In addition to C<key>, L</find> recognizes and applies standard
 723 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 724
 725 Note that if you have extra concerns about the correctness of the resulting
 726 query you need to specify the C<key> attribute and supply the entire condition
 727 as an argument to find (since it is not always possible to perform the
 728 combination of the resultset condition with the supplied one, especially if
 729 the resultset condition contains literal sql).
 730
 731 For example, to find a row by its primary key:
 732
 733   my $cd = $schema->resultset('CD')->find(5);
 734
 735 You can also find a row by a specific unique constraint:
 736
 737   my $cd = $schema->resultset('CD')->find(
 738     {
 739       artist => 'Massive Attack',
 740       title  => 'Mezzanine',
 741     },
 742     { key => 'cd_artist_title' }
 743   );
 744
 745 See also L</find_or_create> and L</update_or_create>.
 746
 747 =cut
 748
 749 sub find {
 750   my $self = shift;
 751   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 752
 753   my $rsrc = $self->result_source;
 754
 755   my $constraint_name;
 756   if (exists $attrs->{key}) {
 757     $constraint_name = defined $attrs->{key}
 758       ? $attrs->{key}
 759       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 760     ;
 761   }
 762
 763   # Parse out the condition from input
 764   my $call_cond;
 765
 766   if (ref $_[0] eq 'HASH') {
 767     $call_cond = { %{$_[0]} };
 768   }
 769   else {
 770     # if only values are supplied we need to default to 'primary'
 771     $constraint_name = 'primary' unless defined $constraint_name;
 772
 773     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 774
 775     $self->throw_exception(
 776       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 777     ) unless @c_cols;
 778
 779     $self->throw_exception (
 780       'find() expects either a column/value hashref, or a list of values '
 781     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 782     ) unless @c_cols == @_;
 783
 784     $call_cond = {};
 785     @{$call_cond}{@c_cols} = @_;
 786   }
 787
 788   my %related;
 789   for my $key (keys %$call_cond) {
 790     if (
 791       my $keyref = ref($call_cond->{$key})
 792         and
 793       my $relinfo = $rsrc->relationship_info($key)
 794     ) {
 795       my $val = delete $call_cond->{$key};
 796
 797       next if $keyref eq 'ARRAY'; # has_many for multi_create
 798
 799       my $rel_q = $rsrc->_resolve_condition(
 800         $relinfo->{cond}, $val, $key, $key
 801       );
 802       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 803       @related{keys %$rel_q} = values %$rel_q;
 804     }
 805   }
 806
 807   # relationship conditions take precedence (?)
 808   @{$call_cond}{keys %related} = values %related;
 809
 810   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 811   my $final_cond;
 812   if (defined $constraint_name) {
 813     $final_cond = $self->_qualify_cond_columns (
 814
 815       $self->_build_unique_cond (
 816         $constraint_name,
 817         $call_cond,
 818       ),
 819
 820       $alias,
 821     );
 822   }
 823   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 824     # This means that we got here after a merger of relationship conditions
 825     # in ::Relationship::Base::search_related (the row method), and furthermore
 826     # the relationship is of the 'single' type. This means that the condition
 827     # provided by the relationship (already attached to $self) is sufficient,
 828     # as there can be only one row in the database that would satisfy the
 829     # relationship
 830   }
 831   else {
 832     # no key was specified - fall down to heuristics mode:
 833     # run through all unique queries registered on the resultset, and
 834     # 'OR' all qualifying queries together
 835     my (@unique_queries, %seen_column_combinations);
 836     for my $c_name ($rsrc->unique_constraint_names) {
 837       next if $seen_column_combinations{
 838         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 839       }++;
 840
 841       push @unique_queries, try {
 842         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 843       } || ();
 844     }
 845
 846     $final_cond = @unique_queries
 847       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 848       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 849     ;
 850   }
 851
 852   # Run the query, passing the result_class since it should propagate for find
 853   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 854   if ($rs->_resolved_attrs->{collapse}) {
 855     my $row = $rs->next;
 856     carp "Query returned more than one row" if $rs->next;
 857     return $row;
 858   }
 859   else {
 860     return $rs->single;
 861   }
 862 }
 863
 864 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 865 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 866 #
 867 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 868 # condition. It is provided for overrides until a saner way forward is devised
 869 #
 870 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 871 # the road. Please adjust your tests accordingly to catch this situation early
 872 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 873 #
 874 # The method will not be removed without an adequately complete replacement
 875 # for strict-mode enforcement
 876 sub _non_unique_find_fallback {
 877   my ($self, $cond, $attrs) = @_;
 878
 879   return $self->_qualify_cond_columns(
 880     $cond,
 881     exists $attrs->{alias}
 882       ? $attrs->{alias}
 883       : $self->{attrs}{alias}
 884   );
 885 }
 886
 887
 888 sub _qualify_cond_columns {
 889   my ($self, $cond, $alias) = @_;
 890
 891   my %aliased = %$cond;
 892   for (keys %aliased) {
 893     $aliased{"$alias.$_"} = delete $aliased{$_}
 894       if $_ !~ /\./;
 895   }
 896
 897   return \%aliased;
 898 }
 899
 900 sub _build_unique_cond {
 901   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 902
 903   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 904
 905   # combination may fail if $self->{cond} is non-trivial
 906   my ($final_cond) = try {
 907     $self->_merge_with_rscond ($extra_cond)
 908   } catch {
 909     +{ %$extra_cond }
 910   };
 911
 912   # trim out everything not in $columns
 913   $final_cond = { map {
 914     exists $final_cond->{$_}
 915       ? ( $_ => $final_cond->{$_} )
 916       : ()
 917   } @c_cols };
 918
 919   if (my @missing = grep
 920     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 921     (@c_cols)
 922   ) {
 923     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 924       $constraint_name,
 925       join (', ', map { "'$_'" } @missing),
 926     ) );
 927   }
 928
 929   if (
 930     !$croak_on_null
 931       and
 932     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 933       and
 934     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 935   ) {
 936     carp_unique ( sprintf (
 937       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 938     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 939     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 940       $constraint_name,
 941       join (', ', map { "'$_'" } @undefs),
 942     ));
 943   }
 944
 945   return $final_cond;
 946 }
 947
 948 =head2 search_related
 949
 950 =over 4
 951
 952 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 953
 954 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 955
 956 =back
 957
 958   $new_rs = $cd_rs->search_related('artist', {
 959     name => 'Emo-R-Us',
 960   });
 961
 962 Searches the specified relationship, optionally specifying a condition and
 963 attributes for matching records. See L</ATTRIBUTES> for more information.
 964
 965 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 966 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 967
 968 See also L</search_related_rs>.
 969
 970 =cut
 971
 972 sub search_related {
 973   return shift->related_resultset(shift)->search(@_);
 974 }
 975
 976 =head2 search_related_rs
 977
 978 This method works exactly the same as search_related, except that
 979 it guarantees a resultset, even in list context.
 980
 981 =cut
 982
 983 sub search_related_rs {
 984   return shift->related_resultset(shift)->search_rs(@_);
 985 }
 986
 987 =head2 cursor
 988
 989 =over 4
 990
 991 =item Arguments: none
 992
 993 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 994
 995 =back
 996
 997 Returns a storage-driven cursor to the given resultset. See
 998 L<DBIx::Class::Cursor> for more information.
 999
1000 =cut
1001
1002 sub cursor {
1003   my $self = shift;
1004
1005   return $self->{cursor} ||= do {
1006     my $attrs = { %{$self->_resolved_attrs } };
1007     $self->result_source->storage->select(
1008       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1009     );
1010   };
1011 }
1012
1013 =head2 single
1014
1015 =over 4
1016
1017 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1018
1019 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1020
1021 =back
1022
1023   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1024
1025 Inflates the first result without creating a cursor if the resultset has
1026 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1027 of L</search>.
1028
1029 While this method can take an optional search condition (just like L</search>)
1030 being a fast-code-path it does not recognize search attributes. If you need to
1031 add extra joins or similar, call L</search> and then chain-call L</single> on the
1032 L<DBIx::Class::ResultSet> returned.
1033
1034 =over
1035
1036 =item B<Note>
1037
1038 As of 0.08100, this method enforces the assumption that the preceding
1039 query returns only one row. If more than one row is returned, you will receive
1040 a warning:
1041
1042   Query returned more than one row
1043
1044 In this case, you should be using L</next> or L</find> instead, or if you really
1045 know what you are doing, use the L</rows> attribute to explicitly limit the size
1046 of the resultset.
1047
1048 This method will also throw an exception if it is called on a resultset prefetching
1049 has_many, as such a prefetch implies fetching multiple rows from the database in
1050 order to assemble the resulting object.
1051
1052 =back
1053
1054 =cut
1055
1056 sub single {
1057   my ($self, $where) = @_;
1058   if(@_ > 2) {
1059       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1060   }
1061
1062   my $attrs = { %{$self->_resolved_attrs} };
1063
1064   $self->throw_exception(
1065     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1066   ) if $attrs->{collapse};
1067
1068   if ($where) {
1069     if (defined $attrs->{where}) {
1070       $attrs->{where} = {
1071         '-and' =>
1072             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1073                $where, delete $attrs->{where} ]
1074       };
1075     } else {
1076       $attrs->{where} = $where;
1077     }
1078   }
1079
1080   my $data = [ $self->result_source->storage->select_single(
1081     $attrs->{from}, $attrs->{select},
1082     $attrs->{where}, $attrs
1083   )];
1084   return undef unless @$data;
1085   $self->{_stashed_rows} = [ $data ];
1086   $self->_construct_results->[0];
1087 }
1088
1089
1090 # _collapse_query
1091 #
1092 # Recursively collapse the query, accumulating values for each column.
1093
1094 sub _collapse_query {
1095   my ($self, $query, $collapsed) = @_;
1096
1097   $collapsed ||= {};
1098
1099   if (ref $query eq 'ARRAY') {
1100     foreach my $subquery (@$query) {
1101       next unless ref $subquery;  # -or
1102       $collapsed = $self->_collapse_query($subquery, $collapsed);
1103     }
1104   }
1105   elsif (ref $query eq 'HASH') {
1106     if (keys %$query and (keys %$query)[0] eq '-and') {
1107       foreach my $subquery (@{$query->{-and}}) {
1108         $collapsed = $self->_collapse_query($subquery, $collapsed);
1109       }
1110     }
1111     else {
1112       foreach my $col (keys %$query) {
1113         my $value = $query->{$col};
1114         $collapsed->{$col}{$value}++;
1115       }
1116     }
1117   }
1118
1119   return $collapsed;
1120 }
1121
1122 =head2 get_column
1123
1124 =over 4
1125
1126 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1127
1128 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1129
1130 =back
1131
1132   my $max_length = $rs->get_column('length')->max;
1133
1134 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1135
1136 =cut
1137
1138 sub get_column {
1139   my ($self, $column) = @_;
1140   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1141   return $new;
1142 }
1143
1144 =head2 search_like
1145
1146 =over 4
1147
1148 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1149
1150 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1151
1152 =back
1153
1154   # WHERE title LIKE '%blue%'
1155   $cd_rs = $rs->search_like({ title => '%blue%'});
1156
1157 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1158 that this is simply a convenience method retained for ex Class::DBI users.
1159 You most likely want to use L</search> with specific operators.
1160
1161 For more information, see L<DBIx::Class::Manual::Cookbook>.
1162
1163 This method is deprecated and will be removed in 0.09. Use L</search()>
1164 instead. An example conversion is:
1165
1166   ->search_like({ foo => 'bar' });
1167
1168   # Becomes
1169
1170   ->search({ foo => { like => 'bar' } });
1171
1172 =cut
1173
1174 sub search_like {
1175   my $class = shift;
1176   carp_unique (
1177     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1178    .' Instead use ->search({ x => { -like => "y%" } })'
1179    .' (note the outer pair of {}s - they are important!)'
1180   );
1181   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1182   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1183   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1184   return $class->search($query, { %$attrs });
1185 }
1186
1187 =head2 slice
1188
1189 =over 4
1190
1191 =item Arguments: $first, $last
1192
1193 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1194
1195 =back
1196
1197 Returns a resultset or object list representing a subset of elements from the
1198 resultset slice is called on. Indexes are from 0, i.e., to get the first
1199 three records, call:
1200
1201   my ($one, $two, $three) = $rs->slice(0, 2);
1202
1203 =cut
1204
1205 sub slice {
1206   my ($self, $min, $max) = @_;
1207   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1208   $attrs->{offset} = $self->{attrs}{offset} || 0;
1209   $attrs->{offset} += $min;
1210   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1211   return $self->search(undef, $attrs);
1212   #my $slice = (ref $self)->new($self->result_source, $attrs);
1213   #return (wantarray ? $slice->all : $slice);
1214 }
1215
1216 =head2 next
1217
1218 =over 4
1219
1220 =item Arguments: none
1221
1222 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1223
1224 =back
1225
1226 Returns the next element in the resultset (C<undef> is there is none).
1227
1228 Can be used to efficiently iterate over records in the resultset:
1229
1230   my $rs = $schema->resultset('CD')->search;
1231   while (my $cd = $rs->next) {
1232     print $cd->title;
1233   }
1234
1235 Note that you need to store the resultset object, and call C<next> on it.
1236 Calling C<< resultset('Table')->next >> repeatedly will always return the
1237 first record from the resultset.
1238
1239 =cut
1240
1241 sub next {
1242   my ($self) = @_;
1243
1244   if (my $cache = $self->get_cache) {
1245     $self->{all_cache_position} ||= 0;
1246     return $cache->[$self->{all_cache_position}++];
1247   }
1248
1249   if ($self->{attrs}{cache}) {
1250     delete $self->{pager};
1251     $self->{all_cache_position} = 1;
1252     return ($self->all)[0];
1253   }
1254
1255   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1256
1257   $self->{_stashed_results} = $self->_construct_results
1258     or return undef;
1259
1260   return shift @{$self->{_stashed_results}};
1261 }
1262
1263 # Constructs as many results as it can in one pass while respecting
1264 # cursor laziness. Several modes of operation:
1265 #
1266 # * Always builds everything present in @{$self->{_stashed_rows}}
1267 # * If called with $fetch_all true - pulls everything off the cursor and
1268 #   builds all result structures (or objects) in one pass
1269 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1270 #   and if the resultset is ordered properly by the left side:
1271 #   * Fetches stuff off the cursor until the "master object" changes,
1272 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1273 #   OR
1274 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1275 #     was requested (there is no other way to collapse except for an
1276 #     eager cursor)
1277 # * If no collapse is requested - just get the next row, construct and
1278 #   return
1279 sub _construct_results {
1280   my ($self, $fetch_all) = @_;
1281
1282   my $rsrc = $self->result_source;
1283   my $attrs = $self->_resolved_attrs;
1284
1285   if (
1286     ! $fetch_all
1287       and
1288     ! $attrs->{order_by}
1289       and
1290     $attrs->{collapse}
1291       and
1292     my @pcols = $rsrc->primary_columns
1293   ) {
1294     # default order for collapsing unless the user asked for something
1295     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1296     $attrs->{_ordered_for_collapse} = 1;
1297     $attrs->{_order_is_artificial} = 1;
1298   }
1299
1300   my $cursor = $self->cursor;
1301
1302   # this will be used as both initial raw-row collector AND as a RV of
1303   # _construct_results. Not regrowing the array twice matters a lot...
1304   # a surprising amount actually
1305   my $rows = delete $self->{_stashed_rows};
1306
1307   my $did_fetch_all = $fetch_all;
1308
1309   if ($fetch_all) {
1310     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1311     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1312   }
1313   elsif( $attrs->{collapse} ) {
1314
1315     $attrs->{_ordered_for_collapse} = (
1316       (
1317         $attrs->{order_by}
1318           and
1319         $rsrc->schema
1320               ->storage
1321                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1322       ) ? 1 : 0
1323     ) unless defined $attrs->{_ordered_for_collapse};
1324
1325     if (! $attrs->{_ordered_for_collapse}) {
1326       $did_fetch_all = 1;
1327
1328       # instead of looping over ->next, use ->all in stealth mode
1329       # *without* calling a ->reset afterwards
1330       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1331       if (! $cursor->{_done}) {
1332         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1333         $cursor->{_done} = 1;
1334       }
1335     }
1336   }
1337
1338   if (! $did_fetch_all and ! @{$rows||[]} ) {
1339     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1340     if (scalar (my @r = $cursor->next) ) {
1341       $rows = [ \@r ];
1342     }
1343   }
1344
1345   return undef unless @{$rows||[]};
1346
1347   my @extra_collapser_args;
1348   if ($attrs->{collapse} and ! $did_fetch_all ) {
1349
1350     @extra_collapser_args = (
1351       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1352       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1353       ($self->{_stashed_rows} = []),                # where does it stuff excess
1354     );
1355   }
1356
1357   # hotspot - skip the setter
1358   my $res_class = $self->_result_class;
1359
1360   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1361     $res_class->can ('inflate_result')
1362       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1363   };
1364
1365   my $infmap = $attrs->{as};
1366
1367
1368   $self->{_result_inflator}{is_core_row} = ( (
1369     $inflator_cref
1370       ==
1371     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1372   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1373
1374   $self->{_result_inflator}{is_hri} = ( (
1375     ! $self->{_result_inflator}{is_core_row}
1376       and
1377     $inflator_cref == (
1378       require DBIx::Class::ResultClass::HashRefInflator
1379         &&
1380       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1381     )
1382   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1383
1384
1385   if (! $attrs->{_related_results_construction}) {
1386     # construct a much simpler array->hash folder for the one-table cases right here
1387     if ($self->{_result_inflator}{is_hri}) {
1388       for my $r (@$rows) {
1389         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1390       }
1391     }
1392     # FIXME SUBOPTIMAL this is a very very very hot spot
1393     # while rather optimal we can *still* do much better, by
1394     # building a smarter Row::inflate_result(), and
1395     # switch to feeding it data via a much leaner interface
1396     #
1397     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1398     # this particular resultset size
1399     elsif (@$rows < 60) {
1400       for my $r (@$rows) {
1401         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1402       }
1403     }
1404     else {
1405       eval sprintf (
1406         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1407         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1408       );
1409     }
1410   }
1411   # Special-case multi-object HRI (we always prune, and there is no $inflator_cref pass)
1412   elsif ($self->{_result_inflator}{is_hri}) {
1413     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1414       eval => 1,
1415       inflate_map => $infmap,
1416       selection => $attrs->{select},
1417       collapse => $attrs->{collapse},
1418       premultiplied => $attrs->{_main_source_premultiplied},
1419       hri_style => 1,
1420       prune_null_branches => 1,
1421     }) )->($rows, @extra_collapser_args);
1422   }
1423   # Regular multi-object
1424   else {
1425     my $parser_type = $self->{_result_inflator}{is_core_row} ? 'classic_pruning' : 'classic_nonpruning';
1426
1427     ( $self->{_row_parser}{$parser_type} ||= $rsrc->_mk_row_parser({
1428       eval => 1,
1429       inflate_map => $infmap,
1430       selection => $attrs->{select},
1431       collapse => $attrs->{collapse},
1432       premultiplied => $attrs->{_main_source_premultiplied},
1433       prune_null_branches => $self->{_result_inflator}{is_core_row},
1434     }) )->($rows, @extra_collapser_args);
1435
1436     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1437   }
1438
1439   # The @$rows check seems odd at first - why wouldn't we want to warn
1440   # regardless? The issue is things like find() etc, where the user
1441   # *knows* only one result will come back. In these cases the ->all
1442   # is not a pessimization, but rather something we actually want
1443   carp_unique(
1444     'Unable to properly collapse has_many results in iterator mode due '
1445   . 'to order criteria - performed an eager cursor slurp underneath. '
1446   . 'Consider using ->all() instead'
1447   ) if ( ! $fetch_all and @$rows > 1 );
1448
1449   return $rows;
1450 }
1451
1452 =head2 result_source
1453
1454 =over 4
1455
1456 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1457
1458 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1459
1460 =back
1461
1462 An accessor for the primary ResultSource object from which this ResultSet
1463 is derived.
1464
1465 =head2 result_class
1466
1467 =over 4
1468
1469 =item Arguments: $result_class?
1470
1471 =item Return Value: $result_class
1472
1473 =back
1474
1475 An accessor for the class to use when creating result objects. Defaults to
1476 C<< result_source->result_class >> - which in most cases is the name of the
1477 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1478
1479 Note that changing the result_class will also remove any components
1480 that were originally loaded in the source class via
1481 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1482 in the original source class will not run.
1483
1484 =cut
1485
1486 sub result_class {
1487   my ($self, $result_class) = @_;
1488   if ($result_class) {
1489
1490     # don't fire this for an object
1491     $self->ensure_class_loaded($result_class)
1492       unless ref($result_class);
1493
1494     if ($self->get_cache) {
1495       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1496     }
1497     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1498     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1499       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1500     }
1501
1502     $self->_result_class($result_class);
1503
1504     delete $self->{_result_inflator};
1505   }
1506   $self->_result_class;
1507 }
1508
1509 =head2 count
1510
1511 =over 4
1512
1513 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1514
1515 =item Return Value: $count
1516
1517 =back
1518
1519 Performs an SQL C<COUNT> with the same query as the resultset was built
1520 with to find the number of elements. Passing arguments is equivalent to
1521 C<< $rs->search ($cond, \%attrs)->count >>
1522
1523 =cut
1524
1525 sub count {
1526   my $self = shift;
1527   return $self->search(@_)->count if @_ and defined $_[0];
1528   return scalar @{ $self->get_cache } if $self->get_cache;
1529
1530   my $attrs = { %{ $self->_resolved_attrs } };
1531
1532   # this is a little optimization - it is faster to do the limit
1533   # adjustments in software, instead of a subquery
1534   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1535
1536   my $crs;
1537   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1538     $crs = $self->_count_subq_rs ($attrs);
1539   }
1540   else {
1541     $crs = $self->_count_rs ($attrs);
1542   }
1543   my $count = $crs->next;
1544
1545   $count -= $offset if $offset;
1546   $count = $rows if $rows and $rows < $count;
1547   $count = 0 if ($count < 0);
1548
1549   return $count;
1550 }
1551
1552 =head2 count_rs
1553
1554 =over 4
1555
1556 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1557
1558 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1559
1560 =back
1561
1562 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1563 This can be very handy for subqueries:
1564
1565   ->search( { amount => $some_rs->count_rs->as_query } )
1566
1567 As with regular resultsets the SQL query will be executed only after
1568 the resultset is accessed via L</next> or L</all>. That would return
1569 the same single value obtainable via L</count>.
1570
1571 =cut
1572
1573 sub count_rs {
1574   my $self = shift;
1575   return $self->search(@_)->count_rs if @_;
1576
1577   # this may look like a lack of abstraction (count() does about the same)
1578   # but in fact an _rs *must* use a subquery for the limits, as the
1579   # software based limiting can not be ported if this $rs is to be used
1580   # in a subquery itself (i.e. ->as_query)
1581   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1582     return $self->_count_subq_rs;
1583   }
1584   else {
1585     return $self->_count_rs;
1586   }
1587 }
1588
1589 #
1590 # returns a ResultSetColumn object tied to the count query
1591 #
1592 sub _count_rs {
1593   my ($self, $attrs) = @_;
1594
1595   my $rsrc = $self->result_source;
1596   $attrs ||= $self->_resolved_attrs;
1597
1598   my $tmp_attrs = { %$attrs };
1599   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1600   delete @{$tmp_attrs}{qw/rows offset order_by _related_results_construction record_filter for/};
1601
1602   # overwrite the selector (supplied by the storage)
1603   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1604   $tmp_attrs->{as} = 'count';
1605
1606   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1607
1608   return $tmp_rs;
1609 }
1610
1611 #
1612 # same as above but uses a subquery
1613 #
1614 sub _count_subq_rs {
1615   my ($self, $attrs) = @_;
1616
1617   my $rsrc = $self->result_source;
1618   $attrs ||= $self->_resolved_attrs;
1619
1620   my $sub_attrs = { %$attrs };
1621   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1622   delete @{$sub_attrs}{qw/collapse columns as select _related_results_construction order_by for/};
1623
1624   # if we multi-prefetch we group_by something unique, as this is what we would
1625   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1626   if ( $attrs->{collapse}  ) {
1627     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1628       $rsrc->_identifying_column_set || $self->throw_exception(
1629         'Unable to construct a unique group_by criteria properly collapsing the '
1630       . 'has_many prefetch before count()'
1631       );
1632     } ]
1633   }
1634
1635   # Calculate subquery selector
1636   if (my $g = $sub_attrs->{group_by}) {
1637
1638     my $sql_maker = $rsrc->storage->sql_maker;
1639
1640     # necessary as the group_by may refer to aliased functions
1641     my $sel_index;
1642     for my $sel (@{$attrs->{select}}) {
1643       $sel_index->{$sel->{-as}} = $sel
1644         if (ref $sel eq 'HASH' and $sel->{-as});
1645     }
1646
1647     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1648     # also look for named aggregates referred in the having clause
1649     # having often contains scalarrefs - thus parse it out entirely
1650     my @parts = @$g;
1651     if ($attrs->{having}) {
1652       local $sql_maker->{having_bind};
1653       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1654       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1655       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1656         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1657         # if we don't unset it we screw up retarded but unfortunately working
1658         # 'MAX(foo.bar)' => { '>', 3 }
1659         $sql_maker->{name_sep} = '';
1660       }
1661
1662       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1663
1664       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1665       my %seen_having;
1666
1667       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1668       # and if all fails for an utterly naive quoted scalar-with-function
1669       while ($having_sql =~ /
1670         $rquote $sep $lquote (.+?) $rquote
1671           |
1672         [\s,] \w+ \. (\w+) [\s,]
1673           |
1674         [\s,] $lquote (.+?) $rquote [\s,]
1675       /gx) {
1676         my $part = $1 || $2 || $3;  # one of them matched if we got here
1677         unless ($seen_having{$part}++) {
1678           push @parts, $part;
1679         }
1680       }
1681     }
1682
1683     for (@parts) {
1684       my $colpiece = $sel_index->{$_} || $_;
1685
1686       # unqualify join-based group_by's. Arcane but possible query
1687       # also horrible horrible hack to alias a column (not a func.)
1688       # (probably need to introduce SQLA syntax)
1689       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1690         my $as = $colpiece;
1691         $as =~ s/\./__/;
1692         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1693       }
1694       push @{$sub_attrs->{select}}, $colpiece;
1695     }
1696   }
1697   else {
1698     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1699     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1700   }
1701
1702   return $rsrc->resultset_class
1703                ->new ($rsrc, $sub_attrs)
1704                 ->as_subselect_rs
1705                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1706                   ->get_column ('count');
1707 }
1708
1709
1710 =head2 count_literal
1711
1712 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1713 should only be used in that context. See L</search_literal> for further info.
1714
1715 =over 4
1716
1717 =item Arguments: $sql_fragment, @standalone_bind_values
1718
1719 =item Return Value: $count
1720
1721 =back
1722
1723 Counts the results in a literal query. Equivalent to calling L</search_literal>
1724 with the passed arguments, then L</count>.
1725
1726 =cut
1727
1728 sub count_literal { shift->search_literal(@_)->count; }
1729
1730 =head2 all
1731
1732 =over 4
1733
1734 =item Arguments: none
1735
1736 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1737
1738 =back
1739
1740 Returns all elements in the resultset.
1741
1742 =cut
1743
1744 sub all {
1745   my $self = shift;
1746   if(@_) {
1747     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1748   }
1749
1750   delete @{$self}{qw/_stashed_rows _stashed_results/};
1751
1752   if (my $c = $self->get_cache) {
1753     return @$c;
1754   }
1755
1756   $self->cursor->reset;
1757
1758   my $objs = $self->_construct_results('fetch_all') || [];
1759
1760   $self->set_cache($objs) if $self->{attrs}{cache};
1761
1762   return @$objs;
1763 }
1764
1765 =head2 reset
1766
1767 =over 4
1768
1769 =item Arguments: none
1770
1771 =item Return Value: $self
1772
1773 =back
1774
1775 Resets the resultset's cursor, so you can iterate through the elements again.
1776 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1777 another query.
1778
1779 =cut
1780
1781 sub reset {
1782   my ($self) = @_;
1783
1784   delete @{$self}{qw/_stashed_rows _stashed_results/};
1785   $self->{all_cache_position} = 0;
1786   $self->cursor->reset;
1787   return $self;
1788 }
1789
1790 =head2 first
1791
1792 =over 4
1793
1794 =item Arguments: none
1795
1796 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1797
1798 =back
1799
1800 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1801 an object for the first result (or C<undef> if the resultset is empty).
1802
1803 =cut
1804
1805 sub first {
1806   return $_[0]->reset->next;
1807 }
1808
1809
1810 # _rs_update_delete
1811 #
1812 # Determines whether and what type of subquery is required for the $rs operation.
1813 # If grouping is necessary either supplies its own, or verifies the current one
1814 # After all is done delegates to the proper storage method.
1815
1816 sub _rs_update_delete {
1817   my ($self, $op, $values) = @_;
1818
1819   my $rsrc = $self->result_source;
1820   my $storage = $rsrc->schema->storage;
1821
1822   my $attrs = { %{$self->_resolved_attrs} };
1823
1824   my $join_classifications;
1825   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1826
1827   # do we need a subquery for any reason?
1828   my $needs_subq = (
1829     defined $existing_group_by
1830       or
1831     # if {from} is unparseable wrap a subq
1832     ref($attrs->{from}) ne 'ARRAY'
1833       or
1834     # limits call for a subq
1835     $self->_has_resolved_attr(qw/rows offset/)
1836   );
1837
1838   # simplify the joinmap, so we can further decide if a subq is necessary
1839   if (!$needs_subq and @{$attrs->{from}} > 1) {
1840
1841     ($attrs->{from}, $join_classifications) =
1842       $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1843
1844     # any non-pruneable non-local restricting joins imply subq
1845     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1846   }
1847
1848   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1849   $needs_subq ||= (
1850     (ref $attrs->{from}[0]) ne 'HASH'
1851       or
1852     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1853   );
1854
1855   my ($cond, $guard);
1856   # do we need anything like a subquery?
1857   if (! $needs_subq) {
1858     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1859     # a condition containing 'me' or other table prefixes will not work
1860     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1861     $cond = do {
1862       my $sqla = $rsrc->storage->sql_maker;
1863       local $sqla->{_dequalify_idents} = 1;
1864       \[ $sqla->_recurse_where($self->{cond}) ];
1865     };
1866   }
1867   else {
1868     # we got this far - means it is time to wrap a subquery
1869     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1870       sprintf(
1871         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1872         $op,
1873         $rsrc->source_name,
1874       )
1875     );
1876
1877     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1878     delete $attrs->{$_} for qw/select as collapse _related_results_construction/;
1879     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1880
1881     # this will be consumed by the pruner waaaaay down the stack
1882     $attrs->{_force_prune_multiplying_joins} = 1;
1883
1884     my $subrs = (ref $self)->new($rsrc, $attrs);
1885
1886     if (@$idcols == 1) {
1887       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1888     }
1889     elsif ($storage->_use_multicolumn_in) {
1890       # no syntax for calling this properly yet
1891       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1892       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1893         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1894         $subrs->as_query
1895       ),
1896     }
1897     else {
1898       # if all else fails - get all primary keys and operate over a ORed set
1899       # wrap in a transaction for consistency
1900       # this is where the group_by/multiplication starts to matter
1901       if (
1902         $existing_group_by
1903           or
1904         keys %{ $join_classifications->{multiplying} || {} }
1905       ) {
1906         # make sure if there is a supplied group_by it matches the columns compiled above
1907         # perfectly. Anything else can not be sanely executed on most databases so croak
1908         # right then and there
1909         if ($existing_group_by) {
1910           my @current_group_by = map
1911             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1912             @$existing_group_by
1913           ;
1914
1915           if (
1916             join ("\x00", sort @current_group_by)
1917               ne
1918             join ("\x00", sort @{$attrs->{columns}} )
1919           ) {
1920             $self->throw_exception (
1921               "You have just attempted a $op operation on a resultset which does group_by"
1922               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1923               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1924               . ' kind of queries. Please retry the operation with a modified group_by or'
1925               . ' without using one at all.'
1926             );
1927           }
1928         }
1929
1930         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1931       }
1932
1933       $guard = $storage->txn_scope_guard;
1934
1935       $cond = [];
1936       for my $row ($subrs->cursor->all) {
1937         push @$cond, { map
1938           { $idcols->[$_] => $row->[$_] }
1939           (0 .. $#$idcols)
1940         };
1941       }
1942     }
1943   }
1944
1945   my $res = $storage->$op (
1946     $rsrc,
1947     $op eq 'update' ? $values : (),
1948     $cond,
1949   );
1950
1951   $guard->commit if $guard;
1952
1953   return $res;
1954 }
1955
1956 =head2 update
1957
1958 =over 4
1959
1960 =item Arguments: \%values
1961
1962 =item Return Value: $underlying_storage_rv
1963
1964 =back
1965
1966 Sets the specified columns in the resultset to the supplied values in a
1967 single query. Note that this will not run any accessor/set_column/update
1968 triggers, nor will it update any result object instances derived from this
1969 resultset (this includes the contents of the L<resultset cache|/set_cache>
1970 if any). See L</update_all> if you need to execute any on-update
1971 triggers or cascades defined either by you or a
1972 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1973
1974 The return value is a pass through of what the underlying
1975 storage backend returned, and may vary. See L<DBI/execute> for the most
1976 common case.
1977
1978 =head3 CAVEAT
1979
1980 Note that L</update> does not process/deflate any of the values passed in.
1981 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1982 ensure manually that any value passed to this method will stringify to
1983 something the RDBMS knows how to deal with. A notable example is the
1984 handling of L<DateTime> objects, for more info see:
1985 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1986
1987 =cut
1988
1989 sub update {
1990   my ($self, $values) = @_;
1991   $self->throw_exception('Values for update must be a hash')
1992     unless ref $values eq 'HASH';
1993
1994   return $self->_rs_update_delete ('update', $values);
1995 }
1996
1997 =head2 update_all
1998
1999 =over 4
2000
2001 =item Arguments: \%values
2002
2003 =item Return Value: 1
2004
2005 =back
2006
2007 Fetches all objects and updates them one at a time via
2008 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2009 triggers, while L</update> will not.
2010
2011 =cut
2012
2013 sub update_all {
2014   my ($self, $values) = @_;
2015   $self->throw_exception('Values for update_all must be a hash')
2016     unless ref $values eq 'HASH';
2017
2018   my $guard = $self->result_source->schema->txn_scope_guard;
2019   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2020   $guard->commit;
2021   return 1;
2022 }
2023
2024 =head2 delete
2025
2026 =over 4
2027
2028 =item Arguments: none
2029
2030 =item Return Value: $underlying_storage_rv
2031
2032 =back
2033
2034 Deletes the rows matching this resultset in a single query. Note that this
2035 will not run any delete triggers, nor will it alter the
2036 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2037 derived from this resultset (this includes the contents of the
2038 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2039 execute any on-delete triggers or cascades defined either by you or a
2040 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2041
2042 The return value is a pass through of what the underlying storage backend
2043 returned, and may vary. See L<DBI/execute> for the most common case.
2044
2045 =cut
2046
2047 sub delete {
2048   my $self = shift;
2049   $self->throw_exception('delete does not accept any arguments')
2050     if @_;
2051
2052   return $self->_rs_update_delete ('delete');
2053 }
2054
2055 =head2 delete_all
2056
2057 =over 4
2058
2059 =item Arguments: none
2060
2061 =item Return Value: 1
2062
2063 =back
2064
2065 Fetches all objects and deletes them one at a time via
2066 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2067 triggers, while L</delete> will not.
2068
2069 =cut
2070
2071 sub delete_all {
2072   my $self = shift;
2073   $self->throw_exception('delete_all does not accept any arguments')
2074     if @_;
2075
2076   my $guard = $self->result_source->schema->txn_scope_guard;
2077   $_->delete for $self->all;
2078   $guard->commit;
2079   return 1;
2080 }
2081
2082 =head2 populate
2083
2084 =over 4
2085
2086 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2087
2088 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2089
2090 =back
2091
2092 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2093 arrayrefs.
2094
2095 =over
2096
2097 =item NOTE
2098
2099 The context of this method call has an important effect on what is
2100 submitted to storage. In void context data is fed directly to fastpath
2101 insertion routines provided by the underlying storage (most often
2102 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2103 L<insert|DBIx::Class::Row/insert> calls on the
2104 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2105 augmentation of these methods provided by components. For example if you
2106 are using something like L<DBIx::Class::UUIDColumns> to create primary
2107 keys for you, you will find that your PKs are empty.  In this case you
2108 will have to explicitly force scalar or list context in order to create
2109 those values.
2110
2111 =back
2112
2113 In non-void (scalar or list) context, this method is simply a wrapper
2114 for L</create>. Depending on list or scalar context either a list of
2115 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2116 containing these objects is returned.
2117
2118 When supplying data in "arrayref of arrayrefs" invocation style, the
2119 first element should be a list of column names and each subsequent
2120 element should be a data value in the earlier specified column order.
2121 For example:
2122
2123   $Arstist_rs->populate([
2124     [ qw( artistid name ) ],
2125     [ 100, 'A Formally Unknown Singer' ],
2126     [ 101, 'A singer that jumped the shark two albums ago' ],
2127     [ 102, 'An actually cool singer' ],
2128   ]);
2129
2130 For the arrayref of hashrefs style each hashref should be a structure
2131 suitable for passing to L</create>. Multi-create is also permitted with
2132 this syntax.
2133
2134   $schema->resultset("Artist")->populate([
2135      { artistid => 4, name => 'Manufactured Crap', cds => [
2136         { title => 'My First CD', year => 2006 },
2137         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2138       ],
2139      },
2140      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2141         { title => 'My parents sold me to a record company', year => 2005 },
2142         { title => 'Why Am I So Ugly?', year => 2006 },
2143         { title => 'I Got Surgery and am now Popular', year => 2007 }
2144       ],
2145      },
2146   ]);
2147
2148 If you attempt a void-context multi-create as in the example above (each
2149 Artist also has the related list of CDs), and B<do not> supply the
2150 necessary autoinc foreign key information, this method will proxy to the
2151 less efficient L</create>, and then throw the Result objects away. In this
2152 case there are obviously no benefits to using this method over L</create>.
2153
2154 =cut
2155
2156 sub populate {
2157   my $self = shift;
2158
2159   # cruft placed in standalone method
2160   my $data = $self->_normalize_populate_args(@_);
2161
2162   return unless @$data;
2163
2164   if(defined wantarray) {
2165     my @created = map { $self->create($_) } @$data;
2166     return wantarray ? @created : \@created;
2167   }
2168   else {
2169     my $first = $data->[0];
2170
2171     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2172     # it relationship data
2173     my (@rels, @columns);
2174     my $rsrc = $self->result_source;
2175     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2176     for (keys %$first) {
2177       my $ref = ref $first->{$_};
2178       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2179         ? push @rels, $_
2180         : push @columns, $_
2181       ;
2182     }
2183
2184     my @pks = $rsrc->primary_columns;
2185
2186     ## do the belongs_to relationships
2187     foreach my $index (0..$#$data) {
2188
2189       # delegate to create() for any dataset without primary keys with specified relationships
2190       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2191         for my $r (@rels) {
2192           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2193             my @ret = $self->populate($data);
2194             return;
2195           }
2196         }
2197       }
2198
2199       foreach my $rel (@rels) {
2200         next unless ref $data->[$index]->{$rel} eq "HASH";
2201         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2202         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2203         my $related = $result->result_source->_resolve_condition(
2204           $reverse_relinfo->{cond},
2205           $self,
2206           $result,
2207           $rel,
2208         );
2209
2210         delete $data->[$index]->{$rel};
2211         $data->[$index] = {%{$data->[$index]}, %$related};
2212
2213         push @columns, keys %$related if $index == 0;
2214       }
2215     }
2216
2217     ## inherit the data locked in the conditions of the resultset
2218     my ($rs_data) = $self->_merge_with_rscond({});
2219     delete @{$rs_data}{@columns};
2220
2221     ## do bulk insert on current row
2222     $rsrc->storage->insert_bulk(
2223       $rsrc,
2224       [@columns, keys %$rs_data],
2225       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2226     );
2227
2228     ## do the has_many relationships
2229     foreach my $item (@$data) {
2230
2231       my $main_row;
2232
2233       foreach my $rel (@rels) {
2234         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2235
2236         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2237
2238         my $child = $main_row->$rel;
2239
2240         my $related = $child->result_source->_resolve_condition(
2241           $rels->{$rel}{cond},
2242           $child,
2243           $main_row,
2244           $rel,
2245         );
2246
2247         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2248         my @populate = map { {%$_, %$related} } @rows_to_add;
2249
2250         $child->populate( \@populate );
2251       }
2252     }
2253   }
2254 }
2255
2256
2257 # populate() argumnets went over several incarnations
2258 # What we ultimately support is AoH
2259 sub _normalize_populate_args {
2260   my ($self, $arg) = @_;
2261
2262   if (ref $arg eq 'ARRAY') {
2263     if (!@$arg) {
2264       return [];
2265     }
2266     elsif (ref $arg->[0] eq 'HASH') {
2267       return $arg;
2268     }
2269     elsif (ref $arg->[0] eq 'ARRAY') {
2270       my @ret;
2271       my @colnames = @{$arg->[0]};
2272       foreach my $values (@{$arg}[1 .. $#$arg]) {
2273         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2274       }
2275       return \@ret;
2276     }
2277   }
2278
2279   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2280 }
2281
2282 =head2 pager
2283
2284 =over 4
2285
2286 =item Arguments: none
2287
2288 =item Return Value: L<$pager|Data::Page>
2289
2290 =back
2291
2292 Returns a L<Data::Page> object for the current resultset. Only makes
2293 sense for queries with a C<page> attribute.
2294
2295 To get the full count of entries for a paged resultset, call
2296 C<total_entries> on the L<Data::Page> object.
2297
2298 =cut
2299
2300 sub pager {
2301   my ($self) = @_;
2302
2303   return $self->{pager} if $self->{pager};
2304
2305   my $attrs = $self->{attrs};
2306   if (!defined $attrs->{page}) {
2307     $self->throw_exception("Can't create pager for non-paged rs");
2308   }
2309   elsif ($attrs->{page} <= 0) {
2310     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2311   }
2312   $attrs->{rows} ||= 10;
2313
2314   # throw away the paging flags and re-run the count (possibly
2315   # with a subselect) to get the real total count
2316   my $count_attrs = { %$attrs };
2317   delete @{$count_attrs}{qw/rows offset page pager/};
2318
2319   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2320
2321   require DBIx::Class::ResultSet::Pager;
2322   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2323     sub { $total_rs->count },  #lazy-get the total
2324     $attrs->{rows},
2325     $self->{attrs}{page},
2326   );
2327 }
2328
2329 =head2 page
2330
2331 =over 4
2332
2333 =item Arguments: $page_number
2334
2335 =item Return Value: L<$resultset|/search>
2336
2337 =back
2338
2339 Returns a resultset for the $page_number page of the resultset on which page
2340 is called, where each page contains a number of rows equal to the 'rows'
2341 attribute set on the resultset (10 by default).
2342
2343 =cut
2344
2345 sub page {
2346   my ($self, $page) = @_;
2347   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2348 }
2349
2350 =head2 new_result
2351
2352 =over 4
2353
2354 =item Arguments: \%col_data
2355
2356 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2357
2358 =back
2359
2360 Creates a new result object in the resultset's result class and returns
2361 it. The row is not inserted into the database at this point, call
2362 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2363 will tell you whether the result object has been inserted or not.
2364
2365 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2366
2367 =cut
2368
2369 sub new_result {
2370   my ($self, $values) = @_;
2371
2372   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2373     if @_ > 2;
2374
2375   $self->throw_exception( "new_result expects a hashref" )
2376     unless (ref $values eq 'HASH');
2377
2378   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2379
2380   my $new = $self->result_class->new({
2381     %$merged_cond,
2382     ( @$cols_from_relations
2383       ? (-cols_from_relations => $cols_from_relations)
2384       : ()
2385     ),
2386     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2387   });
2388
2389   if (
2390     reftype($new) eq 'HASH'
2391       and
2392     ! keys %$new
2393       and
2394     blessed($new)
2395   ) {
2396     carp_unique (sprintf (
2397       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2398       $self->result_class,
2399     ));
2400   }
2401
2402   $new;
2403 }
2404
2405 # _merge_with_rscond
2406 #
2407 # Takes a simple hash of K/V data and returns its copy merged with the
2408 # condition already present on the resultset. Additionally returns an
2409 # arrayref of value/condition names, which were inferred from related
2410 # objects (this is needed for in-memory related objects)
2411 sub _merge_with_rscond {
2412   my ($self, $data) = @_;
2413
2414   my (%new_data, @cols_from_relations);
2415
2416   my $alias = $self->{attrs}{alias};
2417
2418   if (! defined $self->{cond}) {
2419     # just massage $data below
2420   }
2421   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2422     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2423     @cols_from_relations = keys %new_data;
2424   }
2425   elsif (ref $self->{cond} ne 'HASH') {
2426     $self->throw_exception(
2427       "Can't abstract implicit construct, resultset condition not a hash"
2428     );
2429   }
2430   else {
2431     # precendence must be given to passed values over values inherited from
2432     # the cond, so the order here is important.
2433     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2434     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2435
2436     while ( my($col, $value) = each %implied ) {
2437       my $vref = ref $value;
2438       if (
2439         $vref eq 'HASH'
2440           and
2441         keys(%$value) == 1
2442           and
2443         (keys %$value)[0] eq '='
2444       ) {
2445         $new_data{$col} = $value->{'='};
2446       }
2447       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2448         $new_data{$col} = $value;
2449       }
2450     }
2451   }
2452
2453   %new_data = (
2454     %new_data,
2455     %{ $self->_remove_alias($data, $alias) },
2456   );
2457
2458   return (\%new_data, \@cols_from_relations);
2459 }
2460
2461 # _has_resolved_attr
2462 #
2463 # determines if the resultset defines at least one
2464 # of the attributes supplied
2465 #
2466 # used to determine if a subquery is neccessary
2467 #
2468 # supports some virtual attributes:
2469 #   -join
2470 #     This will scan for any joins being present on the resultset.
2471 #     It is not a mere key-search but a deep inspection of {from}
2472 #
2473
2474 sub _has_resolved_attr {
2475   my ($self, @attr_names) = @_;
2476
2477   my $attrs = $self->_resolved_attrs;
2478
2479   my %extra_checks;
2480
2481   for my $n (@attr_names) {
2482     if (grep { $n eq $_ } (qw/-join/) ) {
2483       $extra_checks{$n}++;
2484       next;
2485     }
2486
2487     my $attr =  $attrs->{$n};
2488
2489     next if not defined $attr;
2490
2491     if (ref $attr eq 'HASH') {
2492       return 1 if keys %$attr;
2493     }
2494     elsif (ref $attr eq 'ARRAY') {
2495       return 1 if @$attr;
2496     }
2497     else {
2498       return 1 if $attr;
2499     }
2500   }
2501
2502   # a resolved join is expressed as a multi-level from
2503   return 1 if (
2504     $extra_checks{-join}
2505       and
2506     ref $attrs->{from} eq 'ARRAY'
2507       and
2508     @{$attrs->{from}} > 1
2509   );
2510
2511   return 0;
2512 }
2513
2514 # _collapse_cond
2515 #
2516 # Recursively collapse the condition.
2517
2518 sub _collapse_cond {
2519   my ($self, $cond, $collapsed) = @_;
2520
2521   $collapsed ||= {};
2522
2523   if (ref $cond eq 'ARRAY') {
2524     foreach my $subcond (@$cond) {
2525       next unless ref $subcond;  # -or
2526       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2527     }
2528   }
2529   elsif (ref $cond eq 'HASH') {
2530     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2531       foreach my $subcond (@{$cond->{-and}}) {
2532         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2533       }
2534     }
2535     else {
2536       foreach my $col (keys %$cond) {
2537         my $value = $cond->{$col};
2538         $collapsed->{$col} = $value;
2539       }
2540     }
2541   }
2542
2543   return $collapsed;
2544 }
2545
2546 # _remove_alias
2547 #
2548 # Remove the specified alias from the specified query hash. A copy is made so
2549 # the original query is not modified.
2550
2551 sub _remove_alias {
2552   my ($self, $query, $alias) = @_;
2553
2554   my %orig = %{ $query || {} };
2555   my %unaliased;
2556
2557   foreach my $key (keys %orig) {
2558     if ($key !~ /\./) {
2559       $unaliased{$key} = $orig{$key};
2560       next;
2561     }
2562     $unaliased{$1} = $orig{$key}
2563       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2564   }
2565
2566   return \%unaliased;
2567 }
2568
2569 =head2 as_query
2570
2571 =over 4
2572
2573 =item Arguments: none
2574
2575 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2576
2577 =back
2578
2579 Returns the SQL query and bind vars associated with the invocant.
2580
2581 This is generally used as the RHS for a subquery.
2582
2583 =cut
2584
2585 sub as_query {
2586   my $self = shift;
2587
2588   my $attrs = { %{ $self->_resolved_attrs } };
2589
2590   $self->result_source->storage->_select_args_to_query (
2591     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2592   );
2593 }
2594
2595 =head2 find_or_new
2596
2597 =over 4
2598
2599 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2600
2601 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2602
2603 =back
2604
2605   my $artist = $schema->resultset('Artist')->find_or_new(
2606     { artist => 'fred' }, { key => 'artists' });
2607
2608   $cd->cd_to_producer->find_or_new({ producer => $producer },
2609                                    { key => 'primary });
2610
2611 Find an existing record from this resultset using L</find>. if none exists,
2612 instantiate a new result object and return it. The object will not be saved
2613 into your storage until you call L<DBIx::Class::Row/insert> on it.
2614
2615 You most likely want this method when looking for existing rows using a unique
2616 constraint that is not the primary key, or looking for related rows.
2617
2618 If you want objects to be saved immediately, use L</find_or_create> instead.
2619
2620 B<Note>: Make sure to read the documentation of L</find> and understand the
2621 significance of the C<key> attribute, as its lack may skew your search, and
2622 subsequently result in spurious new objects.
2623
2624 B<Note>: Take care when using C<find_or_new> with a table having
2625 columns with default values that you intend to be automatically
2626 supplied by the database (e.g. an auto_increment primary key column).
2627 In normal usage, the value of such columns should NOT be included at
2628 all in the call to C<find_or_new>, even when set to C<undef>.
2629
2630 =cut
2631
2632 sub find_or_new {
2633   my $self     = shift;
2634   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2635   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2636   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2637     return $row;
2638   }
2639   return $self->new_result($hash);
2640 }
2641
2642 =head2 create
2643
2644 =over 4
2645
2646 =item Arguments: \%col_data
2647
2648 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2649
2650 =back
2651
2652 Attempt to create a single new row or a row with multiple related rows
2653 in the table represented by the resultset (and related tables). This
2654 will not check for duplicate rows before inserting, use
2655 L</find_or_create> to do that.
2656
2657 To create one row for this resultset, pass a hashref of key/value
2658 pairs representing the columns of the table and the values you wish to
2659 store. If the appropriate relationships are set up, foreign key fields
2660 can also be passed an object representing the foreign row, and the
2661 value will be set to its primary key.
2662
2663 To create related objects, pass a hashref of related-object column values
2664 B<keyed on the relationship name>. If the relationship is of type C<multi>
2665 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2666 The process will correctly identify columns holding foreign keys, and will
2667 transparently populate them from the keys of the corresponding relation.
2668 This can be applied recursively, and will work correctly for a structure
2669 with an arbitrary depth and width, as long as the relationships actually
2670 exists and the correct column data has been supplied.
2671
2672 Instead of hashrefs of plain related data (key/value pairs), you may
2673 also pass new or inserted objects. New objects (not inserted yet, see
2674 L</new_result>), will be inserted into their appropriate tables.
2675
2676 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2677
2678 Example of creating a new row.
2679
2680   $person_rs->create({
2681     name=>"Some Person",
2682     email=>"somebody@someplace.com"
2683   });
2684
2685 Example of creating a new row and also creating rows in a related C<has_many>
2686 or C<has_one> resultset.  Note Arrayref.
2687
2688   $artist_rs->create(
2689      { artistid => 4, name => 'Manufactured Crap', cds => [
2690         { title => 'My First CD', year => 2006 },
2691         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2692       ],
2693      },
2694   );
2695
2696 Example of creating a new row and also creating a row in a related
2697 C<belongs_to> resultset. Note Hashref.
2698
2699   $cd_rs->create({
2700     title=>"Music for Silly Walks",
2701     year=>2000,
2702     artist => {
2703       name=>"Silly Musician",
2704     }
2705   });
2706
2707 =over
2708
2709 =item WARNING
2710
2711 When subclassing ResultSet never attempt to override this method. Since
2712 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2713 lot of the internals simply never call it, so your override will be
2714 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2715 or L<DBIx::Class::Row/insert> depending on how early in the
2716 L</create> process you need to intervene. See also warning pertaining to
2717 L</new>.
2718
2719 =back
2720
2721 =cut
2722
2723 sub create {
2724   my ($self, $col_data) = @_;
2725   $self->throw_exception( "create needs a hashref" )
2726     unless ref $col_data eq 'HASH';
2727   return $self->new_result($col_data)->insert;
2728 }
2729
2730 =head2 find_or_create
2731
2732 =over 4
2733
2734 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2735
2736 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2737
2738 =back
2739
2740   $cd->cd_to_producer->find_or_create({ producer => $producer },
2741                                       { key => 'primary' });
2742
2743 Tries to find a record based on its primary key or unique constraints; if none
2744 is found, creates one and returns that instead.
2745
2746   my $cd = $schema->resultset('CD')->find_or_create({
2747     cdid   => 5,
2748     artist => 'Massive Attack',
2749     title  => 'Mezzanine',
2750     year   => 2005,
2751   });
2752
2753 Also takes an optional C<key> attribute, to search by a specific key or unique
2754 constraint. For example:
2755
2756   my $cd = $schema->resultset('CD')->find_or_create(
2757     {
2758       artist => 'Massive Attack',
2759       title  => 'Mezzanine',
2760     },
2761     { key => 'cd_artist_title' }
2762   );
2763
2764 B<Note>: Make sure to read the documentation of L</find> and understand the
2765 significance of the C<key> attribute, as its lack may skew your search, and
2766 subsequently result in spurious row creation.
2767
2768 B<Note>: Because find_or_create() reads from the database and then
2769 possibly inserts based on the result, this method is subject to a race
2770 condition. Another process could create a record in the table after
2771 the find has completed and before the create has started. To avoid
2772 this problem, use find_or_create() inside a transaction.
2773
2774 B<Note>: Take care when using C<find_or_create> with a table having
2775 columns with default values that you intend to be automatically
2776 supplied by the database (e.g. an auto_increment primary key column).
2777 In normal usage, the value of such columns should NOT be included at
2778 all in the call to C<find_or_create>, even when set to C<undef>.
2779
2780 See also L</find> and L</update_or_create>. For information on how to declare
2781 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2782
2783 If you need to know if an existing row was found or a new one created use
2784 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2785 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2786 database!
2787
2788   my $cd = $schema->resultset('CD')->find_or_new({
2789     cdid   => 5,
2790     artist => 'Massive Attack',
2791     title  => 'Mezzanine',
2792     year   => 2005,
2793   });
2794
2795   if( !$cd->in_storage ) {
2796       # do some stuff
2797       $cd->insert;
2798   }
2799
2800 =cut
2801
2802 sub find_or_create {
2803   my $self     = shift;
2804   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2805   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2806   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2807     return $row;
2808   }
2809   return $self->create($hash);
2810 }
2811
2812 =head2 update_or_create
2813
2814 =over 4
2815
2816 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2817
2818 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2819
2820 =back
2821
2822   $resultset->update_or_create({ col => $val, ... });
2823
2824 Like L</find_or_create>, but if a row is found it is immediately updated via
2825 C<< $found_row->update (\%col_data) >>.
2826
2827
2828 Takes an optional C<key> attribute to search on a specific unique constraint.
2829 For example:
2830
2831   # In your application
2832   my $cd = $schema->resultset('CD')->update_or_create(
2833     {
2834       artist => 'Massive Attack',
2835       title  => 'Mezzanine',
2836       year   => 1998,
2837     },
2838     { key => 'cd_artist_title' }
2839   );
2840
2841   $cd->cd_to_producer->update_or_create({
2842     producer => $producer,
2843     name => 'harry',
2844   }, {
2845     key => 'primary',
2846   });
2847
2848 B<Note>: Make sure to read the documentation of L</find> and understand the
2849 significance of the C<key> attribute, as its lack may skew your search, and
2850 subsequently result in spurious row creation.
2851
2852 B<Note>: Take care when using C<update_or_create> with a table having
2853 columns with default values that you intend to be automatically
2854 supplied by the database (e.g. an auto_increment primary key column).
2855 In normal usage, the value of such columns should NOT be included at
2856 all in the call to C<update_or_create>, even when set to C<undef>.
2857
2858 See also L</find> and L</find_or_create>. For information on how to declare
2859 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2860
2861 If you need to know if an existing row was updated or a new one created use
2862 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2863 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2864 database!
2865
2866 =cut
2867
2868 sub update_or_create {
2869   my $self = shift;
2870   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2871   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2872
2873   my $row = $self->find($cond, $attrs);
2874   if (defined $row) {
2875     $row->update($cond);
2876     return $row;
2877   }
2878
2879   return $self->create($cond);
2880 }
2881
2882 =head2 update_or_new
2883
2884 =over 4
2885
2886 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2887
2888 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2889
2890 =back
2891
2892   $resultset->update_or_new({ col => $val, ... });
2893
2894 Like L</find_or_new> but if a row is found it is immediately updated via
2895 C<< $found_row->update (\%col_data) >>.
2896
2897 For example:
2898
2899   # In your application
2900   my $cd = $schema->resultset('CD')->update_or_new(
2901     {
2902       artist => 'Massive Attack',
2903       title  => 'Mezzanine',
2904       year   => 1998,
2905     },
2906     { key => 'cd_artist_title' }
2907   );
2908
2909   if ($cd->in_storage) {
2910       # the cd was updated
2911   }
2912   else {
2913       # the cd is not yet in the database, let's insert it
2914       $cd->insert;
2915   }
2916
2917 B<Note>: Make sure to read the documentation of L</find> and understand the
2918 significance of the C<key> attribute, as its lack may skew your search, and
2919 subsequently result in spurious new objects.
2920
2921 B<Note>: Take care when using C<update_or_new> with a table having
2922 columns with default values that you intend to be automatically
2923 supplied by the database (e.g. an auto_increment primary key column).
2924 In normal usage, the value of such columns should NOT be included at
2925 all in the call to C<update_or_new>, even when set to C<undef>.
2926
2927 See also L</find>, L</find_or_create> and L</find_or_new>.
2928
2929 =cut
2930
2931 sub update_or_new {
2932     my $self  = shift;
2933     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2934     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2935
2936     my $row = $self->find( $cond, $attrs );
2937     if ( defined $row ) {
2938         $row->update($cond);
2939         return $row;
2940     }
2941
2942     return $self->new_result($cond);
2943 }
2944
2945 =head2 get_cache
2946
2947 =over 4
2948
2949 =item Arguments: none
2950
2951 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2952
2953 =back
2954
2955 Gets the contents of the cache for the resultset, if the cache is set.
2956
2957 The cache is populated either by using the L</prefetch> attribute to
2958 L</search> or by calling L</set_cache>.
2959
2960 =cut
2961
2962 sub get_cache {
2963   shift->{all_cache};
2964 }
2965
2966 =head2 set_cache
2967
2968 =over 4
2969
2970 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2971
2972 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2973
2974 =back
2975
2976 Sets the contents of the cache for the resultset. Expects an arrayref
2977 of objects of the same class as those produced by the resultset. Note that
2978 if the cache is set, the resultset will return the cached objects rather
2979 than re-querying the database even if the cache attr is not set.
2980
2981 The contents of the cache can also be populated by using the
2982 L</prefetch> attribute to L</search>.
2983
2984 =cut
2985
2986 sub set_cache {
2987   my ( $self, $data ) = @_;
2988   $self->throw_exception("set_cache requires an arrayref")
2989       if defined($data) && (ref $data ne 'ARRAY');
2990   $self->{all_cache} = $data;
2991 }
2992
2993 =head2 clear_cache
2994
2995 =over 4
2996
2997 =item Arguments: none
2998
2999 =item Return Value: undef
3000
3001 =back
3002
3003 Clears the cache for the resultset.
3004
3005 =cut
3006
3007 sub clear_cache {
3008   shift->set_cache(undef);
3009 }
3010
3011 =head2 is_paged
3012
3013 =over 4
3014
3015 =item Arguments: none
3016
3017 =item Return Value: true, if the resultset has been paginated
3018
3019 =back
3020
3021 =cut
3022
3023 sub is_paged {
3024   my ($self) = @_;
3025   return !!$self->{attrs}{page};
3026 }
3027
3028 =head2 is_ordered
3029
3030 =over 4
3031
3032 =item Arguments: none
3033
3034 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3035
3036 =back
3037
3038 =cut
3039
3040 sub is_ordered {
3041   my ($self) = @_;
3042   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3043 }
3044
3045 =head2 related_resultset
3046
3047 =over 4
3048
3049 =item Arguments: $rel_name
3050
3051 =item Return Value: L<$resultset|/search>
3052
3053 =back
3054
3055 Returns a related resultset for the supplied relationship name.
3056
3057   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3058
3059 =cut
3060
3061 sub related_resultset {
3062   my ($self, $rel) = @_;
3063
3064   return $self->{related_resultsets}{$rel}
3065     if defined $self->{related_resultsets}{$rel};
3066
3067   return $self->{related_resultsets}{$rel} = do {
3068     my $rsrc = $self->result_source;
3069     my $rel_info = $rsrc->relationship_info($rel);
3070
3071     $self->throw_exception(
3072       "search_related: result source '" . $rsrc->source_name .
3073         "' has no such relationship $rel")
3074       unless $rel_info;
3075
3076     my $attrs = $self->_chain_relationship($rel);
3077
3078     my $join_count = $attrs->{seen_join}{$rel};
3079
3080     my $alias = $self->result_source->storage
3081         ->relname_to_table_alias($rel, $join_count);
3082
3083     # since this is search_related, and we already slid the select window inwards
3084     # (the select/as attrs were deleted in the beginning), we need to flip all
3085     # left joins to inner, so we get the expected results
3086     # read the comment on top of the actual function to see what this does
3087     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3088
3089
3090     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3091     delete @{$attrs}{qw(result_class alias)};
3092
3093     my $related_cache;
3094
3095     if (my $cache = $self->get_cache) {
3096       $related_cache = [ map
3097         { @{$_->related_resultset($rel)->get_cache||[]} }
3098         @$cache
3099       ];
3100     }
3101
3102     my $rel_source = $rsrc->related_source($rel);
3103
3104     my $new = do {
3105
3106       # The reason we do this now instead of passing the alias to the
3107       # search_rs below is that if you wrap/overload resultset on the
3108       # source you need to know what alias it's -going- to have for things
3109       # to work sanely (e.g. RestrictWithObject wants to be able to add
3110       # extra query restrictions, and these may need to be $alias.)
3111
3112       my $rel_attrs = $rel_source->resultset_attributes;
3113       local $rel_attrs->{alias} = $alias;
3114
3115       $rel_source->resultset
3116                  ->search_rs(
3117                      undef, {
3118                        %$attrs,
3119                        where => $attrs->{where},
3120                    });
3121     };
3122     $new->set_cache($related_cache) if $related_cache;
3123     $new;
3124   };
3125 }
3126
3127 =head2 current_source_alias
3128
3129 =over 4
3130
3131 =item Arguments: none
3132
3133 =item Return Value: $source_alias
3134
3135 =back
3136
3137 Returns the current table alias for the result source this resultset is built
3138 on, that will be used in the SQL query. Usually it is C<me>.
3139
3140 Currently the source alias that refers to the result set returned by a
3141 L</search>/L</find> family method depends on how you got to the resultset: it's
3142 C<me> by default, but eg. L</search_related> aliases it to the related result
3143 source name (and keeps C<me> referring to the original result set). The long
3144 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3145 (and make this method unnecessary).
3146
3147 Thus it's currently necessary to use this method in predefined queries (see
3148 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3149 source alias of the current result set:
3150
3151   # in a result set class
3152   sub modified_by {
3153     my ($self, $user) = @_;
3154
3155     my $me = $self->current_source_alias;
3156
3157     return $self->search({
3158       "$me.modified" => $user->id,
3159     });
3160   }
3161
3162 =cut
3163
3164 sub current_source_alias {
3165   return (shift->{attrs} || {})->{alias} || 'me';
3166 }
3167
3168 =head2 as_subselect_rs
3169
3170 =over 4
3171
3172 =item Arguments: none
3173
3174 =item Return Value: L<$resultset|/search>
3175
3176 =back
3177
3178 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3179 "virtual view" by including it as a subquery within the from clause.  From this
3180 point on, any joined tables are inaccessible to ->search on the resultset (as if
3181 it were simply where-filtered without joins).  For example:
3182
3183  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3184
3185  # 'x' now pollutes the query namespace
3186
3187  # So the following works as expected
3188  my $ok_rs = $rs->search({'x.other' => 1});
3189
3190  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3191  # def) we look for one row with contradictory terms and join in another table
3192  # (aliased 'x_2') which we never use
3193  my $broken_rs = $rs->search({'x.name' => 'def'});
3194
3195  my $rs2 = $rs->as_subselect_rs;
3196
3197  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3198  my $not_joined_rs = $rs2->search({'x.other' => 1});
3199
3200  # works as expected: finds a 'table' row related to two x rows (abc and def)
3201  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3202
3203 Another example of when one might use this would be to select a subset of
3204 columns in a group by clause:
3205
3206  my $rs = $schema->resultset('Bar')->search(undef, {
3207    group_by => [qw{ id foo_id baz_id }],
3208  })->as_subselect_rs->search(undef, {
3209    columns => [qw{ id foo_id }]
3210  });
3211
3212 In the above example normally columns would have to be equal to the group by,
3213 but because we isolated the group by into a subselect the above works.
3214
3215 =cut
3216
3217 sub as_subselect_rs {
3218   my $self = shift;
3219
3220   my $attrs = $self->_resolved_attrs;
3221
3222   my $fresh_rs = (ref $self)->new (
3223     $self->result_source
3224   );
3225
3226   # these pieces will be locked in the subquery
3227   delete $fresh_rs->{cond};
3228   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3229
3230   return $fresh_rs->search( {}, {
3231     from => [{
3232       $attrs->{alias} => $self->as_query,
3233       -alias  => $attrs->{alias},
3234       -rsrc   => $self->result_source,
3235     }],
3236     alias => $attrs->{alias},
3237   });
3238 }
3239
3240 # This code is called by search_related, and makes sure there
3241 # is clear separation between the joins before, during, and
3242 # after the relationship. This information is needed later
3243 # in order to properly resolve prefetch aliases (any alias
3244 # with a relation_chain_depth less than the depth of the
3245 # current prefetch is not considered)
3246 #
3247 # The increments happen twice per join. An even number means a
3248 # relationship specified via a search_related, whereas an odd
3249 # number indicates a join/prefetch added via attributes
3250 #
3251 # Also this code will wrap the current resultset (the one we
3252 # chain to) in a subselect IFF it contains limiting attributes
3253 sub _chain_relationship {
3254   my ($self, $rel) = @_;
3255   my $source = $self->result_source;
3256   my $attrs = { %{$self->{attrs}||{}} };
3257
3258   # we need to take the prefetch the attrs into account before we
3259   # ->_resolve_join as otherwise they get lost - captainL
3260   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3261
3262   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3263
3264   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3265
3266   my $from;
3267   my @force_subq_attrs = qw/offset rows group_by having/;
3268
3269   if (
3270     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3271       ||
3272     $self->_has_resolved_attr (@force_subq_attrs)
3273   ) {
3274     # Nuke the prefetch (if any) before the new $rs attrs
3275     # are resolved (prefetch is useless - we are wrapping
3276     # a subquery anyway).
3277     my $rs_copy = $self->search;
3278     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3279       $rs_copy->{attrs}{join},
3280       delete $rs_copy->{attrs}{prefetch},
3281     );
3282
3283     $from = [{
3284       -rsrc   => $source,
3285       -alias  => $attrs->{alias},
3286       $attrs->{alias} => $rs_copy->as_query,
3287     }];
3288     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3289     $seen->{-relation_chain_depth} = 0;
3290   }
3291   elsif ($attrs->{from}) {  #shallow copy suffices
3292     $from = [ @{$attrs->{from}} ];
3293   }
3294   else {
3295     $from = [{
3296       -rsrc  => $source,
3297       -alias => $attrs->{alias},
3298       $attrs->{alias} => $source->from,
3299     }];
3300   }
3301
3302   my $jpath = ($seen->{-relation_chain_depth})
3303     ? $from->[-1][0]{-join_path}
3304     : [];
3305
3306   my @requested_joins = $source->_resolve_join(
3307     $join,
3308     $attrs->{alias},
3309     $seen,
3310     $jpath,
3311   );
3312
3313   push @$from, @requested_joins;
3314
3315   $seen->{-relation_chain_depth}++;
3316
3317   # if $self already had a join/prefetch specified on it, the requested
3318   # $rel might very well be already included. What we do in this case
3319   # is effectively a no-op (except that we bump up the chain_depth on
3320   # the join in question so we could tell it *is* the search_related)
3321   my $already_joined;
3322
3323   # we consider the last one thus reverse
3324   for my $j (reverse @requested_joins) {
3325     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3326     if ($rel eq $last_j) {
3327       $j->[0]{-relation_chain_depth}++;
3328       $already_joined++;
3329       last;
3330     }
3331   }
3332
3333   unless ($already_joined) {
3334     push @$from, $source->_resolve_join(
3335       $rel,
3336       $attrs->{alias},
3337       $seen,
3338       $jpath,
3339     );
3340   }
3341
3342   $seen->{-relation_chain_depth}++;
3343
3344   return {%$attrs, from => $from, seen_join => $seen};
3345 }
3346
3347 sub _resolved_attrs {
3348   my $self = shift;
3349   return $self->{_attrs} if $self->{_attrs};
3350
3351   my $attrs  = { %{ $self->{attrs} || {} } };
3352   my $source = $self->result_source;
3353   my $alias  = $attrs->{alias};
3354
3355   # default selection list
3356   $attrs->{columns} = [ $source->columns ]
3357     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3358
3359   # merge selectors together
3360   for (qw/columns select as/) {
3361     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3362       if $attrs->{$_} or $attrs->{"+$_"};
3363   }
3364
3365   # disassemble columns
3366   my (@sel, @as);
3367   if (my $cols = delete $attrs->{columns}) {
3368     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3369       if (ref $c eq 'HASH') {
3370         for my $as (sort keys %$c) {
3371           push @sel, $c->{$as};
3372           push @as, $as;
3373         }
3374       }
3375       else {
3376         push @sel, $c;
3377         push @as, $c;
3378       }
3379     }
3380   }
3381
3382   # when trying to weed off duplicates later do not go past this point -
3383   # everything added from here on is unbalanced "anyone's guess" stuff
3384   my $dedup_stop_idx = $#as;
3385
3386   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3387     if $attrs->{as};
3388   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3389     if $attrs->{select};
3390
3391   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3392   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3393
3394   # disqualify all $alias.col as-bits (inflate-map mandated)
3395   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3396
3397   # de-duplicate the result (remove *identical* select/as pairs)
3398   # and also die on duplicate {as} pointing to different {select}s
3399   # not using a c-style for as the condition is prone to shrinkage
3400   my $seen;
3401   my $i = 0;
3402   while ($i <= $dedup_stop_idx) {
3403     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3404       splice @sel, $i, 1;
3405       splice @as, $i, 1;
3406       $dedup_stop_idx--;
3407     }
3408     elsif ($seen->{$as[$i]}++) {
3409       $self->throw_exception(
3410         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3411       );
3412     }
3413     else {
3414       $i++;
3415     }
3416   }
3417
3418   $attrs->{select} = \@sel;
3419   $attrs->{as} = \@as;
3420
3421   $attrs->{from} ||= [{
3422     -rsrc   => $source,
3423     -alias  => $self->{attrs}{alias},
3424     $self->{attrs}{alias} => $source->from,
3425   }];
3426
3427   if ( $attrs->{join} || $attrs->{prefetch} ) {
3428
3429     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3430       if ref $attrs->{from} ne 'ARRAY';
3431
3432     my $join = (delete $attrs->{join}) || {};
3433
3434     if ( defined $attrs->{prefetch} ) {
3435       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3436     }
3437
3438     $attrs->{from} =    # have to copy here to avoid corrupting the original
3439       [
3440         @{ $attrs->{from} },
3441         $source->_resolve_join(
3442           $join,
3443           $alias,
3444           { %{ $attrs->{seen_join} || {} } },
3445           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3446             ? $attrs->{from}[-1][0]{-join_path}
3447             : []
3448           ,
3449         )
3450       ];
3451   }
3452
3453   if ( defined $attrs->{order_by} ) {
3454     $attrs->{order_by} = (
3455       ref( $attrs->{order_by} ) eq 'ARRAY'
3456       ? [ @{ $attrs->{order_by} } ]
3457       : [ $attrs->{order_by} || () ]
3458     );
3459   }
3460
3461   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3462     $attrs->{group_by} = [ $attrs->{group_by} ];
3463   }
3464
3465   # generate the distinct induced group_by early, as prefetch will be carried via a
3466   # subquery (since a group_by is present)
3467   if (delete $attrs->{distinct}) {
3468     if ($attrs->{group_by}) {
3469       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3470     }
3471     else {
3472       $attrs->{_grouped_by_distinct} = 1;
3473       # distinct affects only the main selection part, not what prefetch may
3474       # add below.
3475       $attrs->{group_by} = $source->storage->_group_over_selection($attrs);
3476     }
3477   }
3478
3479   # generate selections based on the prefetch helper
3480   my $prefetch;
3481   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3482     if defined $attrs->{prefetch};
3483
3484   if ($prefetch) {
3485
3486     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3487       if $attrs->{_dark_selector};
3488
3489     $attrs->{collapse} = 1;
3490
3491     # this is a separate structure (we don't look in {from} directly)
3492     # as the resolver needs to shift things off the lists to work
3493     # properly (identical-prefetches on different branches)
3494     my $join_map = {};
3495     if (ref $attrs->{from} eq 'ARRAY') {
3496
3497       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3498
3499       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3500         next unless $j->[0]{-alias};
3501         next unless $j->[0]{-join_path};
3502         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3503
3504         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3505
3506         my $p = $join_map;
3507         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3508         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3509       }
3510     }
3511
3512     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3513
3514     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3515     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3516   }
3517
3518   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3519     $attrs->{_related_results_construction} = 1;
3520   }
3521   else {
3522     $attrs->{collapse} = 0;
3523   }
3524
3525   # run through the resulting joinstructure (starting from our current slot)
3526   # and unset collapse if proven unnesessary
3527   #
3528   # also while we are at it find out if the current root source has
3529   # been premultiplied by previous related_source chaining
3530   #
3531   # this allows to predict whether a root object with all other relation
3532   # data set to NULL is in fact unique
3533   if ($attrs->{collapse}) {
3534
3535     if (ref $attrs->{from} eq 'ARRAY') {
3536
3537       if (@{$attrs->{from}} <= 1) {
3538         # no joins - no collapse
3539         $attrs->{collapse} = 0;
3540       }
3541       else {
3542         # find where our table-spec starts
3543         my @fromlist = @{$attrs->{from}};
3544         while (@fromlist) {
3545           my $t = shift @fromlist;
3546
3547           my $is_multi;
3548           # me vs join from-spec distinction - a ref means non-root
3549           if (ref $t eq 'ARRAY') {
3550             $t = $t->[0];
3551             $is_multi ||= ! $t->{-is_single};
3552           }
3553           last if ($t->{-alias} && $t->{-alias} eq $alias);
3554           $attrs->{_main_source_premultiplied} ||= $is_multi;
3555         }
3556
3557         # no non-singles remaining, nor any premultiplication - nothing to collapse
3558         if (
3559           ! $attrs->{_main_source_premultiplied}
3560             and
3561           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3562         ) {
3563           $attrs->{collapse} = 0;
3564         }
3565       }
3566     }
3567
3568     else {
3569       # if we can not analyze the from - err on the side of safety
3570       $attrs->{_main_source_premultiplied} = 1;
3571     }
3572   }
3573
3574   # if both page and offset are specified, produce a combined offset
3575   # even though it doesn't make much sense, this is what pre 081xx has
3576   # been doing
3577   if (my $page = delete $attrs->{page}) {
3578     $attrs->{offset} =
3579       ($attrs->{rows} * ($page - 1))
3580             +
3581       ($attrs->{offset} || 0)
3582     ;
3583   }
3584
3585   return $self->{_attrs} = $attrs;
3586 }
3587
3588 sub _rollout_attr {
3589   my ($self, $attr) = @_;
3590
3591   if (ref $attr eq 'HASH') {
3592     return $self->_rollout_hash($attr);
3593   } elsif (ref $attr eq 'ARRAY') {
3594     return $self->_rollout_array($attr);
3595   } else {
3596     return [$attr];
3597   }
3598 }
3599
3600 sub _rollout_array {
3601   my ($self, $attr) = @_;
3602
3603   my @rolled_array;
3604   foreach my $element (@{$attr}) {
3605     if (ref $element eq 'HASH') {
3606       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3607     } elsif (ref $element eq 'ARRAY') {
3608       #  XXX - should probably recurse here
3609       push( @rolled_array, @{$self->_rollout_array($element)} );
3610     } else {
3611       push( @rolled_array, $element );
3612     }
3613   }
3614   return \@rolled_array;
3615 }
3616
3617 sub _rollout_hash {
3618   my ($self, $attr) = @_;
3619
3620   my @rolled_array;
3621   foreach my $key (keys %{$attr}) {
3622     push( @rolled_array, { $key => $attr->{$key} } );
3623   }
3624   return \@rolled_array;
3625 }
3626
3627 sub _calculate_score {
3628   my ($self, $a, $b) = @_;
3629
3630   if (defined $a xor defined $b) {
3631     return 0;
3632   }
3633   elsif (not defined $a) {
3634     return 1;
3635   }
3636
3637   if (ref $b eq 'HASH') {
3638     my ($b_key) = keys %{$b};
3639     if (ref $a eq 'HASH') {
3640       my ($a_key) = keys %{$a};
3641       if ($a_key eq $b_key) {
3642         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3643       } else {
3644         return 0;
3645       }
3646     } else {
3647       return ($a eq $b_key) ? 1 : 0;
3648     }
3649   } else {
3650     if (ref $a eq 'HASH') {
3651       my ($a_key) = keys %{$a};
3652       return ($b eq $a_key) ? 1 : 0;
3653     } else {
3654       return ($b eq $a) ? 1 : 0;
3655     }
3656   }
3657 }
3658
3659 sub _merge_joinpref_attr {
3660   my ($self, $orig, $import) = @_;
3661
3662   return $import unless defined($orig);
3663   return $orig unless defined($import);
3664
3665   $orig = $self->_rollout_attr($orig);
3666   $import = $self->_rollout_attr($import);
3667
3668   my $seen_keys;
3669   foreach my $import_element ( @{$import} ) {
3670     # find best candidate from $orig to merge $b_element into
3671     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3672     foreach my $orig_element ( @{$orig} ) {
3673       my $score = $self->_calculate_score( $orig_element, $import_element );
3674       if ($score > $best_candidate->{score}) {
3675         $best_candidate->{position} = $position;
3676         $best_candidate->{score} = $score;
3677       }
3678       $position++;
3679     }
3680     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3681     $import_key = '' if not defined $import_key;
3682
3683     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3684       push( @{$orig}, $import_element );
3685     } else {
3686       my $orig_best = $orig->[$best_candidate->{position}];
3687       # merge orig_best and b_element together and replace original with merged
3688       if (ref $orig_best ne 'HASH') {
3689         $orig->[$best_candidate->{position}] = $import_element;
3690       } elsif (ref $import_element eq 'HASH') {
3691         my ($key) = keys %{$orig_best};
3692         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3693       }
3694     }
3695     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3696   }
3697
3698   return @$orig ? $orig : ();
3699 }
3700
3701 {
3702   my $hm;
3703
3704   sub _merge_attr {
3705     $hm ||= do {
3706       require Hash::Merge;
3707       my $hm = Hash::Merge->new;
3708
3709       $hm->specify_behavior({
3710         SCALAR => {
3711           SCALAR => sub {
3712             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3713
3714             if ($defl xor $defr) {
3715               return [ $defl ? $_[0] : $_[1] ];
3716             }
3717             elsif (! $defl) {
3718               return [];
3719             }
3720             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3721               return [ $_[0] ];
3722             }
3723             else {
3724               return [$_[0], $_[1]];
3725             }
3726           },
3727           ARRAY => sub {
3728             return $_[1] if !defined $_[0];
3729             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3730             return [$_[0], @{$_[1]}]
3731           },
3732           HASH  => sub {
3733             return [] if !defined $_[0] and !keys %{$_[1]};
3734             return [ $_[1] ] if !defined $_[0];
3735             return [ $_[0] ] if !keys %{$_[1]};
3736             return [$_[0], $_[1]]
3737           },
3738         },
3739         ARRAY => {
3740           SCALAR => sub {
3741             return $_[0] if !defined $_[1];
3742             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3743             return [@{$_[0]}, $_[1]]
3744           },
3745           ARRAY => sub {
3746             my @ret = @{$_[0]} or return $_[1];
3747             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3748             my %idx = map { $_ => 1 } @ret;
3749             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3750             \@ret;
3751           },
3752           HASH => sub {
3753             return [ $_[1] ] if ! @{$_[0]};
3754             return $_[0] if !keys %{$_[1]};
3755             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3756             return [ @{$_[0]}, $_[1] ];
3757           },
3758         },
3759         HASH => {
3760           SCALAR => sub {
3761             return [] if !keys %{$_[0]} and !defined $_[1];
3762             return [ $_[0] ] if !defined $_[1];
3763             return [ $_[1] ] if !keys %{$_[0]};
3764             return [$_[0], $_[1]]
3765           },
3766           ARRAY => sub {
3767             return [] if !keys %{$_[0]} and !@{$_[1]};
3768             return [ $_[0] ] if !@{$_[1]};
3769             return $_[1] if !keys %{$_[0]};
3770             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3771             return [ $_[0], @{$_[1]} ];
3772           },
3773           HASH => sub {
3774             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3775             return [ $_[0] ] if !keys %{$_[1]};
3776             return [ $_[1] ] if !keys %{$_[0]};
3777             return [ $_[0] ] if $_[0] eq $_[1];
3778             return [ $_[0], $_[1] ];
3779           },
3780         }
3781       } => 'DBIC_RS_ATTR_MERGER');
3782       $hm;
3783     };
3784
3785     return $hm->merge ($_[1], $_[2]);
3786   }
3787 }
3788
3789 sub STORABLE_freeze {
3790   my ($self, $cloning) = @_;
3791   my $to_serialize = { %$self };
3792
3793   # A cursor in progress can't be serialized (and would make little sense anyway)
3794   # the parser can be regenerated (and can't be serialized)
3795   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3796
3797   # nor is it sensical to store a not-yet-fired-count pager
3798   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3799     delete $to_serialize->{pager};
3800   }
3801
3802   Storable::nfreeze($to_serialize);
3803 }
3804
3805 # need this hook for symmetry
3806 sub STORABLE_thaw {
3807   my ($self, $cloning, $serialized) = @_;
3808
3809   %$self = %{ Storable::thaw($serialized) };
3810
3811   $self;
3812 }
3813
3814
3815 =head2 throw_exception
3816
3817 See L<DBIx::Class::Schema/throw_exception> for details.
3818
3819 =cut
3820
3821 sub throw_exception {
3822   my $self=shift;
3823
3824   if (ref $self and my $rsrc = $self->result_source) {
3825     $rsrc->throw_exception(@_)
3826   }
3827   else {
3828     DBIx::Class::Exception->throw(@_);
3829   }
3830 }
3831
3832 1;
3833
3834 __END__
3835
3836 # XXX: FIXME: Attributes docs need clearing up
3837
3838 =head1 ATTRIBUTES
3839
3840 Attributes are used to refine a ResultSet in various ways when
3841 searching for data. They can be passed to any method which takes an
3842 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3843 L</count>.
3844
3845 Default attributes can be set on the result class using
3846 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3847 the CAVEATS on that feature before using it!)
3848
3849 These are in no particular order:
3850
3851 =head2 order_by
3852
3853 =over 4
3854
3855 =item Value: ( $order_by | \@order_by | \%order_by )
3856
3857 =back
3858
3859 Which column(s) to order the results by.
3860
3861 [The full list of suitable values is documented in
3862 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3863 common options.]
3864
3865 If a single column name, or an arrayref of names is supplied, the
3866 argument is passed through directly to SQL. The hashref syntax allows
3867 for connection-agnostic specification of ordering direction:
3868
3869  For descending order:
3870
3871   order_by => { -desc => [qw/col1 col2 col3/] }
3872
3873  For explicit ascending order:
3874
3875   order_by => { -asc => 'col' }
3876
3877 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3878 supported, although you are strongly encouraged to use the hashref
3879 syntax as outlined above.
3880
3881 =head2 columns
3882
3883 =over 4
3884
3885 =item Value: \@columns | \%columns | $column
3886
3887 =back
3888
3889 Shortcut to request a particular set of columns to be retrieved. Each
3890 column spec may be a string (a table column name), or a hash (in which
3891 case the key is the C<as> value, and the value is used as the C<select>
3892 expression). Adds C<me.> onto the start of any column without a C<.> in
3893 it and sets C<select> from that, then auto-populates C<as> from
3894 C<select> as normal. (You may also use the C<cols> attribute, as in
3895 earlier versions of DBIC, but this is deprecated.)
3896
3897 Essentially C<columns> does the same as L</select> and L</as>.
3898
3899     columns => [ 'foo', { bar => 'baz' } ]
3900
3901 is the same as
3902
3903     select => [qw/foo baz/],
3904     as => [qw/foo bar/]
3905
3906 =head2 +columns
3907
3908 =over 4
3909
3910 =item Value: \@columns
3911
3912 =back
3913
3914 Indicates additional columns to be selected from storage. Works the same as
3915 L</columns> but adds columns to the selection. (You may also use the
3916 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3917 deprecated). For example:-
3918
3919   $schema->resultset('CD')->search(undef, {
3920     '+columns' => ['artist.name'],
3921     join => ['artist']
3922   });
3923
3924 would return all CDs and include a 'name' column to the information
3925 passed to object inflation. Note that the 'artist' is the name of the
3926 column (or relationship) accessor, and 'name' is the name of the column
3927 accessor in the related table.
3928
3929 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3930 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3931 unary plus operator before it.
3932
3933 =head2 include_columns
3934
3935 =over 4
3936
3937 =item Value: \@columns
3938
3939 =back
3940
3941 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3942
3943 =head2 select
3944
3945 =over 4
3946
3947 =item Value: \@select_columns
3948
3949 =back
3950
3951 Indicates which columns should be selected from the storage. You can use
3952 column names, or in the case of RDBMS back ends, function or stored procedure
3953 names:
3954
3955   $rs = $schema->resultset('Employee')->search(undef, {
3956     select => [
3957       'name',
3958       { count => 'employeeid' },
3959       { max => { length => 'name' }, -as => 'longest_name' }
3960     ]
3961   });
3962
3963   # Equivalent SQL
3964   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3965
3966 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3967 use L</select>, to instruct DBIx::Class how to store the result of the column.
3968 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3969 identifier aliasing. You can however alias a function, so you can use it in
3970 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3971 attribute> supplied as shown in the example above.
3972
3973 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3974 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3975 unary plus operator before it.
3976
3977 =head2 +select
3978
3979 =over 4
3980
3981 Indicates additional columns to be selected from storage.  Works the same as
3982 L</select> but adds columns to the default selection, instead of specifying
3983 an explicit list.
3984
3985 =back
3986
3987 =head2 as
3988
3989 =over 4
3990
3991 =item Value: \@inflation_names
3992
3993 =back
3994
3995 Indicates column names for object inflation. That is L</as> indicates the
3996 slot name in which the column value will be stored within the
3997 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3998 identifier by the C<get_column> method (or via the object accessor B<if one
3999 with the same name already exists>) as shown below. The L</as> attribute has
4000 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4001
4002   $rs = $schema->resultset('Employee')->search(undef, {
4003     select => [
4004       'name',
4005       { count => 'employeeid' },
4006       { max => { length => 'name' }, -as => 'longest_name' }
4007     ],
4008     as => [qw/
4009       name
4010       employee_count
4011       max_name_length
4012     /],
4013   });
4014
4015 If the object against which the search is performed already has an accessor
4016 matching a column name specified in C<as>, the value can be retrieved using
4017 the accessor as normal:
4018
4019   my $name = $employee->name();
4020
4021 If on the other hand an accessor does not exist in the object, you need to
4022 use C<get_column> instead:
4023
4024   my $employee_count = $employee->get_column('employee_count');
4025
4026 You can create your own accessors if required - see
4027 L<DBIx::Class::Manual::Cookbook> for details.
4028
4029 =head2 +as
4030
4031 =over 4
4032
4033 Indicates additional column names for those added via L</+select>. See L</as>.
4034
4035 =back
4036
4037 =head2 join
4038
4039 =over 4
4040
4041 =item Value: ($rel_name | \@rel_names | \%rel_names)
4042
4043 =back
4044
4045 Contains a list of relationships that should be joined for this query.  For
4046 example:
4047
4048   # Get CDs by Nine Inch Nails
4049   my $rs = $schema->resultset('CD')->search(
4050     { 'artist.name' => 'Nine Inch Nails' },
4051     { join => 'artist' }
4052   );
4053
4054 Can also contain a hash reference to refer to the other relation's relations.
4055 For example:
4056
4057   package MyApp::Schema::Track;
4058   use base qw/DBIx::Class/;
4059   __PACKAGE__->table('track');
4060   __PACKAGE__->add_columns(qw/trackid cd position title/);
4061   __PACKAGE__->set_primary_key('trackid');
4062   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4063   1;
4064
4065   # In your application
4066   my $rs = $schema->resultset('Artist')->search(
4067     { 'track.title' => 'Teardrop' },
4068     {
4069       join     => { cd => 'track' },
4070       order_by => 'artist.name',
4071     }
4072   );
4073
4074 You need to use the relationship (not the table) name in  conditions,
4075 because they are aliased as such. The current table is aliased as "me", so
4076 you need to use me.column_name in order to avoid ambiguity. For example:
4077
4078   # Get CDs from 1984 with a 'Foo' track
4079   my $rs = $schema->resultset('CD')->search(
4080     {
4081       'me.year' => 1984,
4082       'tracks.name' => 'Foo'
4083     },
4084     { join => 'tracks' }
4085   );
4086
4087 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4088 similarly for a third time). For e.g.
4089
4090   my $rs = $schema->resultset('Artist')->search({
4091     'cds.title'   => 'Down to Earth',
4092     'cds_2.title' => 'Popular',
4093   }, {
4094     join => [ qw/cds cds/ ],
4095   });
4096
4097 will return a set of all artists that have both a cd with title 'Down
4098 to Earth' and a cd with title 'Popular'.
4099
4100 If you want to fetch related objects from other tables as well, see L</prefetch>
4101 below.
4102
4103  NOTE: An internal join-chain pruner will discard certain joins while
4104  constructing the actual SQL query, as long as the joins in question do not
4105  affect the retrieved result. This for example includes 1:1 left joins
4106  that are not part of the restriction specification (WHERE/HAVING) nor are
4107  a part of the query selection.
4108
4109 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4110
4111 =head2 collapse
4112
4113 =over 4
4114
4115 =item Value: (0 | 1)
4116
4117 =back
4118
4119 When set to a true value, indicates that any rows fetched from joined has_many
4120 relationships are to be aggregated into the corresponding "parent" object. For
4121 example, the resultset:
4122
4123   my $rs = $schema->resultset('CD')->search({}, {
4124     '+columns' => [ qw/ tracks.title tracks.position / ],
4125     join => 'tracks',
4126     collapse => 1,
4127   });
4128
4129 While executing the following query:
4130
4131   SELECT me.*, tracks.title, tracks.position
4132     FROM cd me
4133     LEFT JOIN track tracks
4134       ON tracks.cdid = me.cdid
4135
4136 Will return only as many objects as there are rows in the CD source, even
4137 though the result of the query may span many rows. Each of these CD objects
4138 will in turn have multiple "Track" objects hidden behind the has_many
4139 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4140 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4141 product"), with each CD object containing exactly one of all fetched Track data.
4142
4143 When a collapse is requested on a non-ordered resultset, an order by some
4144 unique part of the main source (the left-most table) is inserted automatically.
4145 This is done so that the resultset is allowed to be "lazy" - calling
4146 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4147 object with all of its related data.
4148
4149 If an L</order_by> is already declared, and orders the resultset in a way that
4150 makes collapsing as described above impossible (e.g. C<< ORDER BY
4151 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4152 switch to "eager" mode and slurp the entire resultset before consturcting the
4153 first object returned by L</next>.
4154
4155 Setting this attribute on a resultset that does not join any has_many
4156 relations is a no-op.
4157
4158 For a more in-depth discussion, see L</PREFETCHING>.
4159
4160 =head2 prefetch
4161
4162 =over 4
4163
4164 =item Value: ($rel_name | \@rel_names | \%rel_names)
4165
4166 =back
4167
4168 This attribute is a shorthand for specifying a L</join> spec, adding all
4169 columns from the joined related sources as L</+columns> and setting
4170 L</collapse> to a true value. For example, the following two queries are
4171 equivalent:
4172
4173   my $rs = $schema->resultset('Artist')->search({}, {
4174     prefetch => { cds => ['genre', 'tracks' ] },
4175   });
4176
4177 and
4178
4179   my $rs = $schema->resultset('Artist')->search({}, {
4180     join => { cds => ['genre', 'tracks' ] },
4181     collapse => 1,
4182     '+columns' => [
4183       (map
4184         { +{ "cds.$_" => "cds.$_" } }
4185         $schema->source('Artist')->related_source('cds')->columns
4186       ),
4187       (map
4188         { +{ "cds.genre.$_" => "genre.$_" } }
4189         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4190       ),
4191       (map
4192         { +{ "cds.tracks.$_" => "tracks.$_" } }
4193         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4194       ),
4195     ],
4196   });
4197
4198 Both producing the following SQL:
4199
4200   SELECT  me.artistid, me.name, me.rank, me.charfield,
4201           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4202           genre.genreid, genre.name,
4203           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4204     FROM artist me
4205     LEFT JOIN cd cds
4206       ON cds.artist = me.artistid
4207     LEFT JOIN genre genre
4208       ON genre.genreid = cds.genreid
4209     LEFT JOIN track tracks
4210       ON tracks.cd = cds.cdid
4211   ORDER BY me.artistid
4212
4213 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4214 the arguments are properly merged and generally do the right thing. For
4215 example, you may want to do the following:
4216
4217   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4218     { 'genre.genreid' => undef },
4219     {
4220       join => { cds => 'genre' },
4221       prefetch => 'cds',
4222     }
4223   );
4224
4225 Which generates the following SQL:
4226
4227   SELECT  me.artistid, me.name, me.rank, me.charfield,
4228           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4229     FROM artist me
4230     LEFT JOIN cd cds
4231       ON cds.artist = me.artistid
4232     LEFT JOIN genre genre
4233       ON genre.genreid = cds.genreid
4234   WHERE genre.genreid IS NULL
4235   ORDER BY me.artistid
4236
4237 For a more in-depth discussion, see L</PREFETCHING>.
4238
4239 =head2 alias
4240
4241 =over 4
4242
4243 =item Value: $source_alias
4244
4245 =back
4246
4247 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4248 nested search queries (sub-SELECTs) might need specific aliases set to
4249 reference inner queries.  For example:
4250
4251    my $q = $rs
4252       ->related_resultset('CDs')
4253       ->related_resultset('Tracks')
4254       ->search({
4255          'track.id' => { -ident => 'none_search.id' },
4256       })
4257       ->as_query;
4258
4259    my $ids = $self->search({
4260       -not_exists => $q,
4261    }, {
4262       alias    => 'none_search',
4263       group_by => 'none_search.id',
4264    })->get_column('id')->as_query;
4265
4266    $self->search({ id => { -in => $ids } })
4267
4268 This attribute is directly tied to L</current_source_alias>.
4269
4270 =head2 page
4271
4272 =over 4
4273
4274 =item Value: $page
4275
4276 =back
4277
4278 Makes the resultset paged and specifies the page to retrieve. Effectively
4279 identical to creating a non-pages resultset and then calling ->page($page)
4280 on it.
4281
4282 If L</rows> attribute is not specified it defaults to 10 rows per page.
4283
4284 When you have a paged resultset, L</count> will only return the number
4285 of rows in the page. To get the total, use the L</pager> and call
4286 C<total_entries> on it.
4287
4288 =head2 rows
4289
4290 =over 4
4291
4292 =item Value: $rows
4293
4294 =back
4295
4296 Specifies the maximum number of rows for direct retrieval or the number of
4297 rows per page if the page attribute or method is used.
4298
4299 =head2 offset
4300
4301 =over 4
4302
4303 =item Value: $offset
4304
4305 =back
4306
4307 Specifies the (zero-based) row number for the  first row to be returned, or the
4308 of the first row of the first page if paging is used.
4309
4310 =head2 software_limit
4311
4312 =over 4
4313
4314 =item Value: (0 | 1)
4315
4316 =back
4317
4318 When combined with L</rows> and/or L</offset> the generated SQL will not
4319 include any limit dialect stanzas. Instead the entire result will be selected
4320 as if no limits were specified, and DBIC will perform the limit locally, by
4321 artificially advancing and finishing the resulting L</cursor>.
4322
4323 This is the recommended way of performing resultset limiting when no sane RDBMS
4324 implementation is available (e.g.
4325 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4326 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4327
4328 =head2 group_by
4329
4330 =over 4
4331
4332 =item Value: \@columns
4333
4334 =back
4335
4336 A arrayref of columns to group by. Can include columns of joined tables.
4337
4338   group_by => [qw/ column1 column2 ... /]
4339
4340 =head2 having
4341
4342 =over 4
4343
4344 =item Value: $condition
4345
4346 =back
4347
4348 HAVING is a select statement attribute that is applied between GROUP BY and
4349 ORDER BY. It is applied to the after the grouping calculations have been
4350 done.
4351
4352   having => { 'count_employee' => { '>=', 100 } }
4353
4354 or with an in-place function in which case literal SQL is required:
4355
4356   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4357
4358 =head2 distinct
4359
4360 =over 4
4361
4362 =item Value: (0 | 1)
4363
4364 =back
4365
4366 Set to 1 to group by all columns. If the resultset already has a group_by
4367 attribute, this setting is ignored and an appropriate warning is issued.
4368
4369 =head2 where
4370
4371 =over 4
4372
4373 Adds to the WHERE clause.
4374
4375   # only return rows WHERE deleted IS NULL for all searches
4376   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4377
4378 Can be overridden by passing C<< { where => undef } >> as an attribute
4379 to a resultset.
4380
4381 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4382
4383 =back
4384
4385 =head2 cache
4386
4387 Set to 1 to cache search results. This prevents extra SQL queries if you
4388 revisit rows in your ResultSet:
4389
4390   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4391
4392   while( my $artist = $resultset->next ) {
4393     ... do stuff ...
4394   }
4395
4396   $rs->first; # without cache, this would issue a query
4397
4398 By default, searches are not cached.
4399
4400 For more examples of using these attributes, see
4401 L<DBIx::Class::Manual::Cookbook>.
4402
4403 =head2 for
4404
4405 =over 4
4406
4407 =item Value: ( 'update' | 'shared' | \$scalar )
4408
4409 =back
4410
4411 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4412 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4413 query.
4414
4415 =head1 PREFETCHING
4416
4417 DBIx::Class supports arbitrary related data prefetching from multiple related
4418 sources. Any combination of relationship types and column sets are supported.
4419 If L<collapsing|/collapse> is requested, there is an additional requirement of
4420 selecting enough data to make every individual object uniquely identifiable.
4421
4422 Here are some more involved examples, based on the following relationship map:
4423
4424   # Assuming:
4425   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4426   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4427   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4428
4429   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4430
4431   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4432
4433
4434
4435   my $rs = $schema->resultset('Tag')->search(
4436     undef,
4437     {
4438       prefetch => {
4439         cd => 'artist'
4440       }
4441     }
4442   );
4443
4444 The initial search results in SQL like the following:
4445
4446   SELECT tag.*, cd.*, artist.* FROM tag
4447   JOIN cd ON tag.cd = cd.cdid
4448   JOIN artist ON cd.artist = artist.artistid
4449
4450 L<DBIx::Class> has no need to go back to the database when we access the
4451 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4452 case.
4453
4454 Simple prefetches will be joined automatically, so there is no need
4455 for a C<join> attribute in the above search.
4456
4457 The L</prefetch> attribute can be used with any of the relationship types
4458 and multiple prefetches can be specified together. Below is a more complex
4459 example that prefetches a CD's artist, its liner notes (if present),
4460 the cover image, the tracks on that CD, and the guests on those
4461 tracks.
4462
4463   my $rs = $schema->resultset('CD')->search(
4464     undef,
4465     {
4466       prefetch => [
4467         { artist => 'record_label'},  # belongs_to => belongs_to
4468         'liner_note',                 # might_have
4469         'cover_image',                # has_one
4470         { tracks => 'guests' },       # has_many => has_many
4471       ]
4472     }
4473   );
4474
4475 This will produce SQL like the following:
4476
4477   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4478          tracks.*, guests.*
4479     FROM cd me
4480     JOIN artist artist
4481       ON artist.artistid = me.artistid
4482     JOIN record_label record_label
4483       ON record_label.labelid = artist.labelid
4484     LEFT JOIN track tracks
4485       ON tracks.cdid = me.cdid
4486     LEFT JOIN guest guests
4487       ON guests.trackid = track.trackid
4488     LEFT JOIN liner_notes liner_note
4489       ON liner_note.cdid = me.cdid
4490     JOIN cd_artwork cover_image
4491       ON cover_image.cdid = me.cdid
4492   ORDER BY tracks.cd
4493
4494 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4495 C<tracks>, and C<guests> of the CD will all be available through the
4496 relationship accessors without the need for additional queries to the
4497 database.
4498
4499 =head3 CAVEATS
4500
4501 Prefetch does a lot of deep magic. As such, it may not behave exactly
4502 as you might expect.
4503
4504 =over 4
4505
4506 =item *
4507
4508 Prefetch uses the L</cache> to populate the prefetched relationships. This
4509 may or may not be what you want.
4510
4511 =item *
4512
4513 If you specify a condition on a prefetched relationship, ONLY those
4514 rows that match the prefetched condition will be fetched into that relationship.
4515 This means that adding prefetch to a search() B<may alter> what is returned by
4516 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4517
4518   my $artist_rs = $schema->resultset('Artist')->search({
4519       'cds.year' => 2008,
4520   }, {
4521       join => 'cds',
4522   });
4523
4524   my $count = $artist_rs->first->cds->count;
4525
4526   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4527
4528   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4529
4530   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4531
4532 That cmp_ok() may or may not pass depending on the datasets involved. In other
4533 words the C<WHERE> condition would apply to the entire dataset, just like
4534 it would in regular SQL. If you want to add a condition only to the "right side"
4535 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4536 condition|DBIx::Class::Relationship::Base/condition>
4537
4538 =back
4539
4540 =head1 DBIC BIND VALUES
4541
4542 Because DBIC may need more information to bind values than just the column name
4543 and value itself, it uses a special format for both passing and receiving bind
4544 values.  Each bind value should be composed of an arrayref of
4545 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4546
4547 =over 4
4548
4549 =item dbd_attrs
4550
4551 If present (in any form), this is what is being passed directly to bind_param.
4552 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4553 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4554
4555 If this is specified, all other bind options described below are ignored.
4556
4557 =item sqlt_datatype
4558
4559 If present, this is used to infer the actual bind attribute by passing to
4560 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4561 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4562
4563 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4564 currently drivers are expected to "Do the Right Thing" when given a common
4565 datatype name.  (Not ideal, but that's what we got at this point.)
4566
4567 =item sqlt_size
4568
4569 Currently used to correctly allocate buffers for bind_param_inout().
4570 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4571 or to a sensible value based on the "data_type".
4572
4573 =item dbic_colname
4574
4575 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4576 explicitly specified they are never overriden).  Also used by some weird DBDs,
4577 where the column name should be available at bind_param time (e.g. Oracle).
4578
4579 =back
4580
4581 For backwards compatibility and convenience, the following shortcuts are
4582 supported:
4583
4584   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4585   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4586   [ undef,   $val ] === [ {}, $val ]
4587
4588 =head1 AUTHOR AND CONTRIBUTORS
4589
4590 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4591
4592 =head1 LICENSE
4593
4594 You may distribute this code under the same terms as Perl itself.
4595