lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray is_plain_value is_literal_value
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose
 211
 212 If you want to make your custom ResultSet classes with L<Moose>, use a template
 213 similar to:
 214
 215   package MyApp::Schema::ResultSet::User;
 216
 217   use Moose;
 218   use MooseX::NonMoose;
 219   extends 'DBIx::Class::ResultSet';
 220
 221   sub BUILDARGS { $_[2] }
 222
 223   ...your code...
 224
 225   __PACKAGE__->meta->make_immutable;
 226
 227   1;
 228
 229 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 230 clash with the regular ResultSet constructor. Alternatively, you can use:
 231
 232   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 233
 234 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 235 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 236
 237 =head1 METHODS
 238
 239 =head2 new
 240
 241 =over 4
 242
 243 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 244
 245 =item Return Value: L<$resultset|/search>
 246
 247 =back
 248
 249 The resultset constructor. Takes a source object (usually a
 250 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 251 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 252 executed as needed by the other methods.
 253
 254 Generally you never construct a resultset manually. Instead you get one
 255 from e.g. a
 256 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 257 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 258 scalar context):
 259
 260   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 261
 262 =over
 263
 264 =item WARNING
 265
 266 If called on an object, proxies to L</new_result> instead, so
 267
 268   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 269
 270 will return a CD object, not a ResultSet, and is equivalent to:
 271
 272   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 273
 274 Please also keep in mind that many internals call L</new_result> directly,
 275 so overloading this method with the idea of intercepting new result object
 276 creation B<will not work>. See also warning pertaining to L</create>.
 277
 278 =back
 279
 280 =cut
 281
 282 sub new {
 283   my $class = shift;
 284   return $class->new_result(@_) if ref $class;
 285
 286   my ($source, $attrs) = @_;
 287   $source = $source->resolve
 288     if $source->isa('DBIx::Class::ResultSourceHandle');
 289
 290   $attrs = { %{$attrs||{}} };
 291   delete @{$attrs}{qw(_last_sqlmaker_alias_map _related_results_construction)};
 292
 293   if ($attrs->{page}) {
 294     $attrs->{rows} ||= 10;
 295   }
 296
 297   $attrs->{alias} ||= 'me';
 298
 299   my $self = bless {
 300     result_source => $source,
 301     cond => $attrs->{where},
 302     pager => undef,
 303     attrs => $attrs,
 304   }, $class;
 305
 306   # if there is a dark selector, this means we are already in a
 307   # chain and the cleanup/sanification was taken care of by
 308   # _search_rs already
 309   $self->_normalize_selection($attrs)
 310     unless $attrs->{_dark_selector};
 311
 312   $self->result_class(
 313     $attrs->{result_class} || $source->result_class
 314   );
 315
 316   $self;
 317 }
 318
 319 =head2 search
 320
 321 =over 4
 322
 323 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 324
 325 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 326
 327 =back
 328
 329   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 330   my $new_rs = $cd_rs->search({ year => 2005 });
 331
 332   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 333                  # year = 2005 OR year = 2004
 334
 335 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 336 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 337 To avoid that, use L</search_rs>.
 338
 339 If you need to pass in additional attributes but no additional condition,
 340 call it as C<search(undef, \%attrs)>.
 341
 342   # "SELECT name, artistid FROM $artist_table"
 343   my @all_artists = $schema->resultset('Artist')->search(undef, {
 344     columns => [qw/name artistid/],
 345   });
 346
 347 For a list of attributes that can be passed to C<search>, see
 348 L</ATTRIBUTES>. For more examples of using this function, see
 349 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 350 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 351 and its extension L<DBIx::Class::SQLMaker>.
 352
 353 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 354
 355 =head3 CAVEAT
 356
 357 Note that L</search> does not process/deflate any of the values passed in the
 358 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 359 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 360 manually that any value passed to this method will stringify to something the
 361 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 362 objects, for more info see:
 363 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 364
 365 =cut
 366
 367 sub search {
 368   my $self = shift;
 369   my $rs = $self->search_rs( @_ );
 370
 371   if (wantarray) {
 372     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray($rs);
 373     return $rs->all;
 374   }
 375   elsif (defined wantarray) {
 376     return $rs;
 377   }
 378   else {
 379     # we can be called by a relationship helper, which in
 380     # turn may be called in void context due to some braindead
 381     # overload or whatever else the user decided to be clever
 382     # at this particular day. Thus limit the exception to
 383     # external code calls only
 384     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 385       if (caller)[0] !~ /^\QDBIx::Class::/;
 386
 387     return ();
 388   }
 389 }
 390
 391 =head2 search_rs
 392
 393 =over 4
 394
 395 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 396
 397 =item Return Value: L<$resultset|/search>
 398
 399 =back
 400
 401 This method does the same exact thing as search() except it will
 402 always return a resultset, even in list context.
 403
 404 =cut
 405
 406 sub search_rs {
 407   my $self = shift;
 408
 409   my $rsrc = $self->result_source;
 410   my ($call_cond, $call_attrs);
 411
 412   # Special-case handling for (undef, undef) or (undef)
 413   # Note that (foo => undef) is valid deprecated syntax
 414   @_ = () if not scalar grep { defined $_ } @_;
 415
 416   # just a cond
 417   if (@_ == 1) {
 418     $call_cond = shift;
 419   }
 420   # fish out attrs in the ($condref, $attr) case
 421   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 422     ($call_cond, $call_attrs) = @_;
 423   }
 424   elsif (@_ % 2) {
 425     $self->throw_exception('Odd number of arguments to search')
 426   }
 427   # legacy search
 428   elsif (@_) {
 429     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 430       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 431
 432     for my $i (0 .. $#_) {
 433       next if $i % 2;
 434       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 435         if (! defined $_[$i] or ref $_[$i] ne '');
 436     }
 437
 438     $call_cond = { @_ };
 439   }
 440
 441   # see if we can keep the cache (no $rs changes)
 442   my $cache;
 443   my %safe = (alias => 1, cache => 1);
 444   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 445     ! defined $call_cond
 446       or
 447     ref $call_cond eq 'HASH' && ! keys %$call_cond
 448       or
 449     ref $call_cond eq 'ARRAY' && ! @$call_cond
 450   )) {
 451     $cache = $self->get_cache;
 452   }
 453
 454   my $old_attrs = { %{$self->{attrs}} };
 455   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 456
 457   my $new_attrs = { %$old_attrs };
 458
 459   # take care of call attrs (only if anything is changing)
 460   if ($call_attrs and keys %$call_attrs) {
 461
 462     # copy for _normalize_selection
 463     $call_attrs = { %$call_attrs };
 464
 465     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 466
 467     # reset the current selector list if new selectors are supplied
 468     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 469       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 470     }
 471
 472     # Normalize the new selector list (operates on the passed-in attr structure)
 473     # Need to do it on every chain instead of only once on _resolved_attrs, in
 474     # order to allow detection of empty vs partial 'as'
 475     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 476       if $old_attrs->{_dark_selector};
 477     $self->_normalize_selection ($call_attrs);
 478
 479     # start with blind overwriting merge, exclude selector attrs
 480     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 481     delete @{$new_attrs}{@selector_attrs};
 482
 483     for (@selector_attrs) {
 484       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 485         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 486     }
 487
 488     # older deprecated name, use only if {columns} is not there
 489     if (my $c = delete $new_attrs->{cols}) {
 490       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 491       if ($new_attrs->{columns}) {
 492         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 493       }
 494       else {
 495         $new_attrs->{columns} = $c;
 496       }
 497     }
 498
 499
 500     # join/prefetch use their own crazy merging heuristics
 501     foreach my $key (qw/join prefetch/) {
 502       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 503         if exists $call_attrs->{$key};
 504     }
 505
 506     # stack binds together
 507     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 508   }
 509
 510
 511   for ($old_where, $call_cond) {
 512     if (defined $_) {
 513       $new_attrs->{where} = $self->_stack_cond (
 514         $_, $new_attrs->{where}
 515       );
 516     }
 517   }
 518
 519   if (defined $old_having) {
 520     $new_attrs->{having} = $self->_stack_cond (
 521       $old_having, $new_attrs->{having}
 522     )
 523   }
 524
 525   my $rs = (ref $self)->new($rsrc, $new_attrs);
 526
 527   $rs->set_cache($cache) if ($cache);
 528
 529   return $rs;
 530 }
 531
 532 my $dark_sel_dumper;
 533 sub _normalize_selection {
 534   my ($self, $attrs) = @_;
 535
 536   # legacy syntax
 537   if ( exists $attrs->{include_columns} ) {
 538     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 539     $attrs->{'+columns'} = $self->_merge_attr(
 540       $attrs->{'+columns'}, delete $attrs->{include_columns}
 541     );
 542   }
 543
 544   # columns are always placed first, however
 545
 546   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 547   # delay the decision on whether to use a default select list ($rsrc->columns)
 548   # allowing stuff like the remove_columns helper to work
 549   #
 550   # select/as +select/+as pairs need special handling - the amount of select/as
 551   # elements in each pair does *not* have to be equal (think multicolumn
 552   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 553   # supplied at all) - try to infer the alias, either from the -as parameter
 554   # of the selector spec, or use the parameter whole if it looks like a column
 555   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 556   # is ok as well), but make sure no more additions to the 'as' chain take place
 557   for my $pref ('', '+') {
 558
 559     my ($sel, $as) = map {
 560       my $key = "${pref}${_}";
 561
 562       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 563         ? @{$attrs->{$key}}
 564         : $attrs->{$key} || ()
 565       ];
 566       delete $attrs->{$key};
 567       $val;
 568     } qw/select as/;
 569
 570     if (! @$as and ! @$sel ) {
 571       next;
 572     }
 573     elsif (@$as and ! @$sel) {
 574       $self->throw_exception(
 575         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 576       );
 577     }
 578     elsif( ! @$as ) {
 579       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 580       # if any @$as has been supplied we assume the user knows what (s)he is doing
 581       # and blindly keep stacking up pieces
 582       unless ($attrs->{_dark_selector}) {
 583         SELECTOR:
 584         for (@$sel) {
 585           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 586             push @$as, $_->{-as};
 587           }
 588           # assume any plain no-space, no-parenthesis string to be a column spec
 589           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 590           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 591             push @$as, $_;
 592           }
 593           # if all else fails - raise a flag that no more aliasing will be allowed
 594           else {
 595             $attrs->{_dark_selector} = {
 596               plus_stage => $pref,
 597               string => ($dark_sel_dumper ||= do {
 598                   require Data::Dumper::Concise;
 599                   Data::Dumper::Concise::DumperObject()->Indent(0);
 600                 })->Values([$_])->Dump
 601               ,
 602             };
 603             last SELECTOR;
 604           }
 605         }
 606       }
 607     }
 608     elsif (@$as < @$sel) {
 609       $self->throw_exception(
 610         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 611       );
 612     }
 613     elsif ($pref and $attrs->{_dark_selector}) {
 614       $self->throw_exception(
 615         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 616       );
 617     }
 618
 619
 620     # merge result
 621     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 622     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 623   }
 624 }
 625
 626 sub _stack_cond {
 627   my ($self, $left, $right) = @_;
 628
 629   (
 630     (ref $_ eq 'ARRAY' and !@$_)
 631       or
 632     (ref $_ eq 'HASH' and ! keys %$_)
 633   ) and $_ = undef for ($left, $right);
 634
 635   # either on of the two undef or both undef
 636   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 637     return defined $left ? $left : $right;
 638   }
 639
 640   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 641
 642   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 643
 644     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 645     my @fin = shift @vals;
 646
 647     for my $v (@vals) {
 648       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 649     }
 650
 651     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 652   }
 653
 654   $cond;
 655 }
 656
 657 =head2 search_literal
 658
 659 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 660 should only be used in that context. C<search_literal> is a convenience
 661 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 662 want to ensure columns are bound correctly, use L</search>.
 663
 664 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 665 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 666 require C<search_literal>.
 667
 668 =over 4
 669
 670 =item Arguments: $sql_fragment, @standalone_bind_values
 671
 672 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 673
 674 =back
 675
 676   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 677   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 678
 679 Pass a literal chunk of SQL to be added to the conditional part of the
 680 resultset query.
 681
 682 Example of how to use C<search> instead of C<search_literal>
 683
 684   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 685   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 686
 687 =cut
 688
 689 sub search_literal {
 690   my ($self, $sql, @bind) = @_;
 691   my $attr;
 692   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 693     $attr = pop @bind;
 694   }
 695   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 696 }
 697
 698 =head2 find
 699
 700 =over 4
 701
 702 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 703
 704 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 705
 706 =back
 707
 708 Finds and returns a single row based on supplied criteria. Takes either a
 709 hashref with the same format as L</create> (including inference of foreign
 710 keys from related objects), or a list of primary key values in the same
 711 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 712 declaration on the L</result_source>.
 713
 714 In either case an attempt is made to combine conditions already existing on
 715 the resultset with the condition passed to this method.
 716
 717 To aid with preparing the correct query for the storage you may supply the
 718 C<key> attribute, which is the name of a
 719 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 720 unique constraint corresponding to the
 721 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 722 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 723 to construct a query that satisfies the named unique constraint fully (
 724 non-NULL values for each column member of the constraint) an exception is
 725 thrown.
 726
 727 If no C<key> is specified, the search is carried over all unique constraints
 728 which are fully defined by the available condition.
 729
 730 If no such constraint is found, C<find> currently defaults to a simple
 731 C<< search->(\%column_values) >> which may or may not do what you expect.
 732 Note that this fallback behavior may be deprecated in further versions. If
 733 you need to search with arbitrary conditions - use L</search>. If the query
 734 resulting from this fallback produces more than one row, a warning to the
 735 effect is issued, though only the first row is constructed and returned as
 736 C<$result_object>.
 737
 738 In addition to C<key>, L</find> recognizes and applies standard
 739 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 740
 741 Note that if you have extra concerns about the correctness of the resulting
 742 query you need to specify the C<key> attribute and supply the entire condition
 743 as an argument to find (since it is not always possible to perform the
 744 combination of the resultset condition with the supplied one, especially if
 745 the resultset condition contains literal sql).
 746
 747 For example, to find a row by its primary key:
 748
 749   my $cd = $schema->resultset('CD')->find(5);
 750
 751 You can also find a row by a specific unique constraint:
 752
 753   my $cd = $schema->resultset('CD')->find(
 754     {
 755       artist => 'Massive Attack',
 756       title  => 'Mezzanine',
 757     },
 758     { key => 'cd_artist_title' }
 759   );
 760
 761 See also L</find_or_create> and L</update_or_create>.
 762
 763 =cut
 764
 765 sub find {
 766   my $self = shift;
 767   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 768
 769   my $rsrc = $self->result_source;
 770
 771   my $constraint_name;
 772   if (exists $attrs->{key}) {
 773     $constraint_name = defined $attrs->{key}
 774       ? $attrs->{key}
 775       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 776     ;
 777   }
 778
 779   # Parse out the condition from input
 780   my $call_cond;
 781
 782   if (ref $_[0] eq 'HASH') {
 783     $call_cond = { %{$_[0]} };
 784   }
 785   else {
 786     # if only values are supplied we need to default to 'primary'
 787     $constraint_name = 'primary' unless defined $constraint_name;
 788
 789     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 790
 791     $self->throw_exception(
 792       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 793     ) unless @c_cols;
 794
 795     $self->throw_exception (
 796       'find() expects either a column/value hashref, or a list of values '
 797     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 798     ) unless @c_cols == @_;
 799
 800     $call_cond = {};
 801     @{$call_cond}{@c_cols} = @_;
 802   }
 803
 804   my %related;
 805   for my $key (keys %$call_cond) {
 806     if (
 807       my $keyref = ref($call_cond->{$key})
 808         and
 809       my $relinfo = $rsrc->relationship_info($key)
 810     ) {
 811       my $val = delete $call_cond->{$key};
 812
 813       next if $keyref eq 'ARRAY'; # has_many for multi_create
 814
 815       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 816         $relinfo->{cond}, $val, $key, $key
 817       );
 818
 819       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 820          if $crosstable or ref($rel_cond) ne 'HASH';
 821
 822       # supplement
 823       @related{keys %$rel_cond} = values %$rel_cond;
 824     }
 825   }
 826
 827   # relationship conditions take precedence (?)
 828   @{$call_cond}{keys %related} = values %related;
 829
 830   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 831   my $final_cond;
 832   if (defined $constraint_name) {
 833     $final_cond = $self->_qualify_cond_columns (
 834
 835       $self->_build_unique_cond (
 836         $constraint_name,
 837         $call_cond,
 838       ),
 839
 840       $alias,
 841     );
 842   }
 843   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 844     # This means that we got here after a merger of relationship conditions
 845     # in ::Relationship::Base::search_related (the row method), and furthermore
 846     # the relationship is of the 'single' type. This means that the condition
 847     # provided by the relationship (already attached to $self) is sufficient,
 848     # as there can be only one row in the database that would satisfy the
 849     # relationship
 850   }
 851   else {
 852     # no key was specified - fall down to heuristics mode:
 853     # run through all unique queries registered on the resultset, and
 854     # 'OR' all qualifying queries together
 855     my (@unique_queries, %seen_column_combinations);
 856     for my $c_name ($rsrc->unique_constraint_names) {
 857       next if $seen_column_combinations{
 858         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 859       }++;
 860
 861       push @unique_queries, try {
 862         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 863       } || ();
 864     }
 865
 866     $final_cond = @unique_queries
 867       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 868       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 869     ;
 870   }
 871
 872   # Run the query, passing the result_class since it should propagate for find
 873   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 874   if ($rs->_resolved_attrs->{collapse}) {
 875     my $row = $rs->next;
 876     carp "Query returned more than one row" if $rs->next;
 877     return $row;
 878   }
 879   else {
 880     return $rs->single;
 881   }
 882 }
 883
 884 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 885 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 886 #
 887 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 888 # condition. It is provided for overrides until a saner way forward is devised
 889 #
 890 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 891 # the road. Please adjust your tests accordingly to catch this situation early
 892 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 893 #
 894 # The method will not be removed without an adequately complete replacement
 895 # for strict-mode enforcement
 896 sub _non_unique_find_fallback {
 897   my ($self, $cond, $attrs) = @_;
 898
 899   return $self->_qualify_cond_columns(
 900     $cond,
 901     exists $attrs->{alias}
 902       ? $attrs->{alias}
 903       : $self->{attrs}{alias}
 904   );
 905 }
 906
 907
 908 sub _qualify_cond_columns {
 909   my ($self, $cond, $alias) = @_;
 910
 911   my %aliased = %$cond;
 912   for (keys %aliased) {
 913     $aliased{"$alias.$_"} = delete $aliased{$_}
 914       if $_ !~ /\./;
 915   }
 916
 917   return \%aliased;
 918 }
 919
 920 sub _build_unique_cond {
 921   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 922
 923   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 924
 925   # combination may fail if $self->{cond} is non-trivial
 926   my ($final_cond) = try {
 927     $self->_merge_with_rscond ($extra_cond)
 928   } catch {
 929     +{ %$extra_cond }
 930   };
 931
 932   # trim out everything not in $columns
 933   $final_cond = { map {
 934     exists $final_cond->{$_}
 935       ? ( $_ => $final_cond->{$_} )
 936       : ()
 937   } @c_cols };
 938
 939   if (my @missing = grep
 940     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 941     (@c_cols)
 942   ) {
 943     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 944       $constraint_name,
 945       join (', ', map { "'$_'" } @missing),
 946     ) );
 947   }
 948
 949   if (
 950     !$croak_on_null
 951       and
 952     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 953       and
 954     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 955   ) {
 956     carp_unique ( sprintf (
 957       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 958     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 959     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 960       $constraint_name,
 961       join (', ', map { "'$_'" } @undefs),
 962     ));
 963   }
 964
 965   return $final_cond;
 966 }
 967
 968 =head2 search_related
 969
 970 =over 4
 971
 972 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 973
 974 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 975
 976 =back
 977
 978   $new_rs = $cd_rs->search_related('artist', {
 979     name => 'Emo-R-Us',
 980   });
 981
 982 Searches the specified relationship, optionally specifying a condition and
 983 attributes for matching records. See L</ATTRIBUTES> for more information.
 984
 985 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 986 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 987
 988 See also L</search_related_rs>.
 989
 990 =cut
 991
 992 sub search_related {
 993   return shift->related_resultset(shift)->search(@_);
 994 }
 995
 996 =head2 search_related_rs
 997
 998 This method works exactly the same as search_related, except that
 999 it guarantees a resultset, even in list context.
1000
1001 =cut
1002
1003 sub search_related_rs {
1004   return shift->related_resultset(shift)->search_rs(@_);
1005 }
1006
1007 =head2 cursor
1008
1009 =over 4
1010
1011 =item Arguments: none
1012
1013 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1014
1015 =back
1016
1017 Returns a storage-driven cursor to the given resultset. See
1018 L<DBIx::Class::Cursor> for more information.
1019
1020 =cut
1021
1022 sub cursor {
1023   my $self = shift;
1024
1025   return $self->{cursor} ||= do {
1026     my $attrs = $self->_resolved_attrs;
1027     $self->result_source->storage->select(
1028       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1029     );
1030   };
1031 }
1032
1033 =head2 single
1034
1035 =over 4
1036
1037 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1038
1039 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1040
1041 =back
1042
1043   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1044
1045 Inflates the first result without creating a cursor if the resultset has
1046 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1047 of L</search>.
1048
1049 While this method can take an optional search condition (just like L</search>)
1050 being a fast-code-path it does not recognize search attributes. If you need to
1051 add extra joins or similar, call L</search> and then chain-call L</single> on the
1052 L<DBIx::Class::ResultSet> returned.
1053
1054 =over
1055
1056 =item B<Note>
1057
1058 As of 0.08100, this method enforces the assumption that the preceding
1059 query returns only one row. If more than one row is returned, you will receive
1060 a warning:
1061
1062   Query returned more than one row
1063
1064 In this case, you should be using L</next> or L</find> instead, or if you really
1065 know what you are doing, use the L</rows> attribute to explicitly limit the size
1066 of the resultset.
1067
1068 This method will also throw an exception if it is called on a resultset prefetching
1069 has_many, as such a prefetch implies fetching multiple rows from the database in
1070 order to assemble the resulting object.
1071
1072 =back
1073
1074 =cut
1075
1076 sub single {
1077   my ($self, $where) = @_;
1078   if(@_ > 2) {
1079       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1080   }
1081
1082   my $attrs = { %{$self->_resolved_attrs} };
1083
1084   $self->throw_exception(
1085     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1086   ) if $attrs->{collapse};
1087
1088   if ($where) {
1089     if (defined $attrs->{where}) {
1090       $attrs->{where} = {
1091         '-and' =>
1092             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1093                $where, delete $attrs->{where} ]
1094       };
1095     } else {
1096       $attrs->{where} = $where;
1097     }
1098   }
1099
1100   my $data = [ $self->result_source->storage->select_single(
1101     $attrs->{from}, $attrs->{select},
1102     $attrs->{where}, $attrs
1103   )];
1104
1105   return undef unless @$data;
1106   $self->{_stashed_rows} = [ $data ];
1107   $self->_construct_results->[0];
1108 }
1109
1110 =head2 get_column
1111
1112 =over 4
1113
1114 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1115
1116 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1117
1118 =back
1119
1120   my $max_length = $rs->get_column('length')->max;
1121
1122 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1123
1124 =cut
1125
1126 sub get_column {
1127   my ($self, $column) = @_;
1128   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1129   return $new;
1130 }
1131
1132 =head2 search_like
1133
1134 =over 4
1135
1136 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1137
1138 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1139
1140 =back
1141
1142   # WHERE title LIKE '%blue%'
1143   $cd_rs = $rs->search_like({ title => '%blue%'});
1144
1145 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1146 that this is simply a convenience method retained for ex Class::DBI users.
1147 You most likely want to use L</search> with specific operators.
1148
1149 For more information, see L<DBIx::Class::Manual::Cookbook>.
1150
1151 This method is deprecated and will be removed in 0.09. Use L</search()>
1152 instead. An example conversion is:
1153
1154   ->search_like({ foo => 'bar' });
1155
1156   # Becomes
1157
1158   ->search({ foo => { like => 'bar' } });
1159
1160 =cut
1161
1162 sub search_like {
1163   my $class = shift;
1164   carp_unique (
1165     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1166    .' Instead use ->search({ x => { -like => "y%" } })'
1167    .' (note the outer pair of {}s - they are important!)'
1168   );
1169   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1170   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1171   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1172   return $class->search($query, { %$attrs });
1173 }
1174
1175 =head2 slice
1176
1177 =over 4
1178
1179 =item Arguments: $first, $last
1180
1181 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1182
1183 =back
1184
1185 Returns a resultset or object list representing a subset of elements from the
1186 resultset slice is called on. Indexes are from 0, i.e., to get the first
1187 three records, call:
1188
1189   my ($one, $two, $three) = $rs->slice(0, 2);
1190
1191 =cut
1192
1193 sub slice {
1194   my ($self, $min, $max) = @_;
1195   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1196   $attrs->{offset} = $self->{attrs}{offset} || 0;
1197   $attrs->{offset} += $min;
1198   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1199   return $self->search(undef, $attrs);
1200 }
1201
1202 =head2 next
1203
1204 =over 4
1205
1206 =item Arguments: none
1207
1208 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1209
1210 =back
1211
1212 Returns the next element in the resultset (C<undef> is there is none).
1213
1214 Can be used to efficiently iterate over records in the resultset:
1215
1216   my $rs = $schema->resultset('CD')->search;
1217   while (my $cd = $rs->next) {
1218     print $cd->title;
1219   }
1220
1221 Note that you need to store the resultset object, and call C<next> on it.
1222 Calling C<< resultset('Table')->next >> repeatedly will always return the
1223 first record from the resultset.
1224
1225 =cut
1226
1227 sub next {
1228   my ($self) = @_;
1229
1230   if (my $cache = $self->get_cache) {
1231     $self->{all_cache_position} ||= 0;
1232     return $cache->[$self->{all_cache_position}++];
1233   }
1234
1235   if ($self->{attrs}{cache}) {
1236     delete $self->{pager};
1237     $self->{all_cache_position} = 1;
1238     return ($self->all)[0];
1239   }
1240
1241   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1242
1243   $self->{_stashed_results} = $self->_construct_results
1244     or return undef;
1245
1246   return shift @{$self->{_stashed_results}};
1247 }
1248
1249 # Constructs as many results as it can in one pass while respecting
1250 # cursor laziness. Several modes of operation:
1251 #
1252 # * Always builds everything present in @{$self->{_stashed_rows}}
1253 # * If called with $fetch_all true - pulls everything off the cursor and
1254 #   builds all result structures (or objects) in one pass
1255 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1256 #   and if the resultset is ordered properly by the left side:
1257 #   * Fetches stuff off the cursor until the "master object" changes,
1258 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1259 #   OR
1260 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1261 #     was requested (there is no other way to collapse except for an
1262 #     eager cursor)
1263 # * If no collapse is requested - just get the next row, construct and
1264 #   return
1265 sub _construct_results {
1266   my ($self, $fetch_all) = @_;
1267
1268   my $rsrc = $self->result_source;
1269   my $attrs = $self->_resolved_attrs;
1270
1271   if (
1272     ! $fetch_all
1273       and
1274     ! $attrs->{order_by}
1275       and
1276     $attrs->{collapse}
1277       and
1278     my @pcols = $rsrc->primary_columns
1279   ) {
1280     # default order for collapsing unless the user asked for something
1281     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1282     $attrs->{_ordered_for_collapse} = 1;
1283     $attrs->{_order_is_artificial} = 1;
1284   }
1285
1286   # this will be used as both initial raw-row collector AND as a RV of
1287   # _construct_results. Not regrowing the array twice matters a lot...
1288   # a surprising amount actually
1289   my $rows = delete $self->{_stashed_rows};
1290
1291   my $cursor; # we may not need one at all
1292
1293   my $did_fetch_all = $fetch_all;
1294
1295   if ($fetch_all) {
1296     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1297     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1298   }
1299   elsif( $attrs->{collapse} ) {
1300
1301     # a cursor will need to be closed over in case of collapse
1302     $cursor = $self->cursor;
1303
1304     $attrs->{_ordered_for_collapse} = (
1305       (
1306         $attrs->{order_by}
1307           and
1308         $rsrc->schema
1309               ->storage
1310                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1311       ) ? 1 : 0
1312     ) unless defined $attrs->{_ordered_for_collapse};
1313
1314     if (! $attrs->{_ordered_for_collapse}) {
1315       $did_fetch_all = 1;
1316
1317       # instead of looping over ->next, use ->all in stealth mode
1318       # *without* calling a ->reset afterwards
1319       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1320       if (! $cursor->{_done}) {
1321         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1322         $cursor->{_done} = 1;
1323       }
1324     }
1325   }
1326
1327   if (! $did_fetch_all and ! @{$rows||[]} ) {
1328     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1329     $cursor ||= $self->cursor;
1330     if (scalar (my @r = $cursor->next) ) {
1331       $rows = [ \@r ];
1332     }
1333   }
1334
1335   return undef unless @{$rows||[]};
1336
1337   # sanity check - people are too clever for their own good
1338   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1339
1340     my $multiplied_selectors;
1341     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1342       if (
1343         $aliastypes->{multiplying}{$sel_alias}
1344           or
1345         $aliastypes->{premultiplied}{$sel_alias}
1346       ) {
1347         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1348       }
1349     }
1350
1351     for my $i (0 .. $#{$attrs->{as}} ) {
1352       my $sel = $attrs->{select}[$i];
1353
1354       if (ref $sel eq 'SCALAR') {
1355         $sel = $$sel;
1356       }
1357       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1358         $sel = $$sel->[0];
1359       }
1360
1361       $self->throw_exception(
1362         'Result collapse not possible - selection from a has_many source redirected to the main object'
1363       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1364     }
1365   }
1366
1367   # hotspot - skip the setter
1368   my $res_class = $self->_result_class;
1369
1370   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1371     $res_class->can ('inflate_result')
1372       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1373   };
1374
1375   my $infmap = $attrs->{as};
1376
1377   $self->{_result_inflator}{is_core_row} = ( (
1378     $inflator_cref
1379       ==
1380     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1381   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1382
1383   $self->{_result_inflator}{is_hri} = ( (
1384     ! $self->{_result_inflator}{is_core_row}
1385       and
1386     $inflator_cref == (
1387       require DBIx::Class::ResultClass::HashRefInflator
1388         &&
1389       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1390     )
1391   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1392
1393
1394   if (! $attrs->{_related_results_construction}) {
1395     # construct a much simpler array->hash folder for the one-table cases right here
1396     if ($self->{_result_inflator}{is_hri}) {
1397       for my $r (@$rows) {
1398         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1399       }
1400     }
1401     # FIXME SUBOPTIMAL this is a very very very hot spot
1402     # while rather optimal we can *still* do much better, by
1403     # building a smarter Row::inflate_result(), and
1404     # switch to feeding it data via a much leaner interface
1405     #
1406     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1407     # this particular resultset size
1408     elsif (@$rows < 60) {
1409       for my $r (@$rows) {
1410         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1411       }
1412     }
1413     else {
1414       eval sprintf (
1415         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1416         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1417       );
1418     }
1419   }
1420   else {
1421     my $parser_type =
1422         $self->{_result_inflator}{is_hri}       ? 'hri'
1423       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1424       :                                           'classic_nonpruning'
1425     ;
1426
1427     # $args and $attrs to _mk_row_parser are separated to delineate what is
1428     # core collapser stuff and what is dbic $rs specific
1429     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1430       eval => 1,
1431       inflate_map => $infmap,
1432       collapse => $attrs->{collapse},
1433       premultiplied => $attrs->{_main_source_premultiplied},
1434       hri_style => $self->{_result_inflator}{is_hri},
1435       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1436     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1437
1438     # column_info metadata historically hasn't been too reliable.
1439     # We need to start fixing this somehow (the collapse resolver
1440     # can't work without it). Add an explicit check for the *main*
1441     # result, hopefully this will gradually weed out such errors
1442     #
1443     # FIXME - this is a temporary kludge that reduces performance
1444     # It is however necessary for the time being
1445     my ($unrolled_non_null_cols_to_check, $err);
1446
1447     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1448
1449       $err =
1450         'Collapse aborted due to invalid ResultSource metadata - the following '
1451       . 'selections are declared non-nullable but NULLs were retrieved: '
1452       ;
1453
1454       my @violating_idx;
1455       COL: for my $i (@$check_non_null_cols) {
1456         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1457       }
1458
1459       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1460         if @violating_idx;
1461
1462       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1463     }
1464
1465     my $next_cref =
1466       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1467     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1468 sub {
1469   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1470   my @r = $cursor->next or return;
1471   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1472     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1473   }
1474   \@r
1475 }
1476 EOS
1477     : sub {
1478         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1479         my @r = $cursor->next or return;
1480         \@r
1481       }
1482     ;
1483
1484     $self->{_row_parser}{$parser_type}{cref}->(
1485       $rows,
1486       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1487     );
1488
1489     # Special-case multi-object HRI - there is no $inflator_cref pass
1490     unless ($self->{_result_inflator}{is_hri}) {
1491       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1492     }
1493   }
1494
1495   # The @$rows check seems odd at first - why wouldn't we want to warn
1496   # regardless? The issue is things like find() etc, where the user
1497   # *knows* only one result will come back. In these cases the ->all
1498   # is not a pessimization, but rather something we actually want
1499   carp_unique(
1500     'Unable to properly collapse has_many results in iterator mode due '
1501   . 'to order criteria - performed an eager cursor slurp underneath. '
1502   . 'Consider using ->all() instead'
1503   ) if ( ! $fetch_all and @$rows > 1 );
1504
1505   return $rows;
1506 }
1507
1508 =head2 result_source
1509
1510 =over 4
1511
1512 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1513
1514 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1515
1516 =back
1517
1518 An accessor for the primary ResultSource object from which this ResultSet
1519 is derived.
1520
1521 =head2 result_class
1522
1523 =over 4
1524
1525 =item Arguments: $result_class?
1526
1527 =item Return Value: $result_class
1528
1529 =back
1530
1531 An accessor for the class to use when creating result objects. Defaults to
1532 C<< result_source->result_class >> - which in most cases is the name of the
1533 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1534
1535 Note that changing the result_class will also remove any components
1536 that were originally loaded in the source class via
1537 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1538 in the original source class will not run.
1539
1540 =cut
1541
1542 sub result_class {
1543   my ($self, $result_class) = @_;
1544   if ($result_class) {
1545
1546     # don't fire this for an object
1547     $self->ensure_class_loaded($result_class)
1548       unless ref($result_class);
1549
1550     if ($self->get_cache) {
1551       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1552     }
1553     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1554     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1555       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1556     }
1557
1558     $self->_result_class($result_class);
1559
1560     delete $self->{_result_inflator};
1561   }
1562   $self->_result_class;
1563 }
1564
1565 =head2 count
1566
1567 =over 4
1568
1569 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1570
1571 =item Return Value: $count
1572
1573 =back
1574
1575 Performs an SQL C<COUNT> with the same query as the resultset was built
1576 with to find the number of elements. Passing arguments is equivalent to
1577 C<< $rs->search ($cond, \%attrs)->count >>
1578
1579 =cut
1580
1581 sub count {
1582   my $self = shift;
1583   return $self->search(@_)->count if @_ and defined $_[0];
1584   return scalar @{ $self->get_cache } if $self->get_cache;
1585
1586   my $attrs = { %{ $self->_resolved_attrs } };
1587
1588   # this is a little optimization - it is faster to do the limit
1589   # adjustments in software, instead of a subquery
1590   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1591
1592   my $crs;
1593   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1594     $crs = $self->_count_subq_rs ($attrs);
1595   }
1596   else {
1597     $crs = $self->_count_rs ($attrs);
1598   }
1599   my $count = $crs->next;
1600
1601   $count -= $offset if $offset;
1602   $count = $rows if $rows and $rows < $count;
1603   $count = 0 if ($count < 0);
1604
1605   return $count;
1606 }
1607
1608 =head2 count_rs
1609
1610 =over 4
1611
1612 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1613
1614 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1615
1616 =back
1617
1618 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1619 This can be very handy for subqueries:
1620
1621   ->search( { amount => $some_rs->count_rs->as_query } )
1622
1623 As with regular resultsets the SQL query will be executed only after
1624 the resultset is accessed via L</next> or L</all>. That would return
1625 the same single value obtainable via L</count>.
1626
1627 =cut
1628
1629 sub count_rs {
1630   my $self = shift;
1631   return $self->search(@_)->count_rs if @_;
1632
1633   # this may look like a lack of abstraction (count() does about the same)
1634   # but in fact an _rs *must* use a subquery for the limits, as the
1635   # software based limiting can not be ported if this $rs is to be used
1636   # in a subquery itself (i.e. ->as_query)
1637   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1638     return $self->_count_subq_rs($self->{_attrs});
1639   }
1640   else {
1641     return $self->_count_rs($self->{_attrs});
1642   }
1643 }
1644
1645 #
1646 # returns a ResultSetColumn object tied to the count query
1647 #
1648 sub _count_rs {
1649   my ($self, $attrs) = @_;
1650
1651   my $rsrc = $self->result_source;
1652
1653   my $tmp_attrs = { %$attrs };
1654   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1655   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1656
1657   # overwrite the selector (supplied by the storage)
1658   $rsrc->resultset_class->new($rsrc, {
1659     %$tmp_attrs,
1660     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1661     as => 'count',
1662   })->get_column ('count');
1663 }
1664
1665 #
1666 # same as above but uses a subquery
1667 #
1668 sub _count_subq_rs {
1669   my ($self, $attrs) = @_;
1670
1671   my $rsrc = $self->result_source;
1672
1673   my $sub_attrs = { %$attrs };
1674   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1675   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1676
1677   # if we multi-prefetch we group_by something unique, as this is what we would
1678   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1679   if ( $attrs->{collapse}  ) {
1680     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1681       $rsrc->_identifying_column_set || $self->throw_exception(
1682         'Unable to construct a unique group_by criteria properly collapsing the '
1683       . 'has_many prefetch before count()'
1684       );
1685     } ]
1686   }
1687
1688   # Calculate subquery selector
1689   if (my $g = $sub_attrs->{group_by}) {
1690
1691     my $sql_maker = $rsrc->storage->sql_maker;
1692
1693     # necessary as the group_by may refer to aliased functions
1694     my $sel_index;
1695     for my $sel (@{$attrs->{select}}) {
1696       $sel_index->{$sel->{-as}} = $sel
1697         if (ref $sel eq 'HASH' and $sel->{-as});
1698     }
1699
1700     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1701     # also look for named aggregates referred in the having clause
1702     # having often contains scalarrefs - thus parse it out entirely
1703     my @parts = @$g;
1704     if ($attrs->{having}) {
1705       local $sql_maker->{having_bind};
1706       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1707       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1708       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1709         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1710         # if we don't unset it we screw up retarded but unfortunately working
1711         # 'MAX(foo.bar)' => { '>', 3 }
1712         $sql_maker->{name_sep} = '';
1713       }
1714
1715       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1716
1717       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1718       my %seen_having;
1719
1720       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1721       # and if all fails for an utterly naive quoted scalar-with-function
1722       while ($having_sql =~ /
1723         $rquote $sep $lquote (.+?) $rquote
1724           |
1725         [\s,] \w+ \. (\w+) [\s,]
1726           |
1727         [\s,] $lquote (.+?) $rquote [\s,]
1728       /gx) {
1729         my $part = $1 || $2 || $3;  # one of them matched if we got here
1730         unless ($seen_having{$part}++) {
1731           push @parts, $part;
1732         }
1733       }
1734     }
1735
1736     for (@parts) {
1737       my $colpiece = $sel_index->{$_} || $_;
1738
1739       # unqualify join-based group_by's. Arcane but possible query
1740       # also horrible horrible hack to alias a column (not a func.)
1741       # (probably need to introduce SQLA syntax)
1742       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1743         my $as = $colpiece;
1744         $as =~ s/\./__/;
1745         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1746       }
1747       push @{$sub_attrs->{select}}, $colpiece;
1748     }
1749   }
1750   else {
1751     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1752     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1753   }
1754
1755   return $rsrc->resultset_class
1756                ->new ($rsrc, $sub_attrs)
1757                 ->as_subselect_rs
1758                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1759                   ->get_column ('count');
1760 }
1761
1762
1763 =head2 count_literal
1764
1765 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1766 should only be used in that context. See L</search_literal> for further info.
1767
1768 =over 4
1769
1770 =item Arguments: $sql_fragment, @standalone_bind_values
1771
1772 =item Return Value: $count
1773
1774 =back
1775
1776 Counts the results in a literal query. Equivalent to calling L</search_literal>
1777 with the passed arguments, then L</count>.
1778
1779 =cut
1780
1781 sub count_literal { shift->search_literal(@_)->count; }
1782
1783 =head2 all
1784
1785 =over 4
1786
1787 =item Arguments: none
1788
1789 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1790
1791 =back
1792
1793 Returns all elements in the resultset.
1794
1795 =cut
1796
1797 sub all {
1798   my $self = shift;
1799   if(@_) {
1800     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1801   }
1802
1803   delete @{$self}{qw/_stashed_rows _stashed_results/};
1804
1805   if (my $c = $self->get_cache) {
1806     return @$c;
1807   }
1808
1809   $self->cursor->reset;
1810
1811   my $objs = $self->_construct_results('fetch_all') || [];
1812
1813   $self->set_cache($objs) if $self->{attrs}{cache};
1814
1815   return @$objs;
1816 }
1817
1818 =head2 reset
1819
1820 =over 4
1821
1822 =item Arguments: none
1823
1824 =item Return Value: $self
1825
1826 =back
1827
1828 Resets the resultset's cursor, so you can iterate through the elements again.
1829 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1830 another query.
1831
1832 =cut
1833
1834 sub reset {
1835   my ($self) = @_;
1836
1837   delete @{$self}{qw/_stashed_rows _stashed_results/};
1838   $self->{all_cache_position} = 0;
1839   $self->cursor->reset;
1840   return $self;
1841 }
1842
1843 =head2 first
1844
1845 =over 4
1846
1847 =item Arguments: none
1848
1849 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1850
1851 =back
1852
1853 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1854 an object for the first result (or C<undef> if the resultset is empty).
1855
1856 =cut
1857
1858 sub first {
1859   return $_[0]->reset->next;
1860 }
1861
1862
1863 # _rs_update_delete
1864 #
1865 # Determines whether and what type of subquery is required for the $rs operation.
1866 # If grouping is necessary either supplies its own, or verifies the current one
1867 # After all is done delegates to the proper storage method.
1868
1869 sub _rs_update_delete {
1870   my ($self, $op, $values) = @_;
1871
1872   my $rsrc = $self->result_source;
1873   my $storage = $rsrc->schema->storage;
1874
1875   my $attrs = { %{$self->_resolved_attrs} };
1876
1877   my $join_classifications;
1878   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1879
1880   # do we need a subquery for any reason?
1881   my $needs_subq = (
1882     defined $existing_group_by
1883       or
1884     # if {from} is unparseable wrap a subq
1885     ref($attrs->{from}) ne 'ARRAY'
1886       or
1887     # limits call for a subq
1888     $self->_has_resolved_attr(qw/rows offset/)
1889   );
1890
1891   # simplify the joinmap, so we can further decide if a subq is necessary
1892   if (!$needs_subq and @{$attrs->{from}} > 1) {
1893
1894     ($attrs->{from}, $join_classifications) =
1895       $storage->_prune_unused_joins ($attrs);
1896
1897     # any non-pruneable non-local restricting joins imply subq
1898     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1899   }
1900
1901   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1902   $needs_subq ||= (
1903     (ref $attrs->{from}[0]) ne 'HASH'
1904       or
1905     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1906   );
1907
1908   my ($cond, $guard);
1909   # do we need anything like a subquery?
1910   if (! $needs_subq) {
1911     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1912     # a condition containing 'me' or other table prefixes will not work
1913     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1914     $cond = do {
1915       my $sqla = $rsrc->storage->sql_maker;
1916       local $sqla->{_dequalify_idents} = 1;
1917       \[ $sqla->_recurse_where($self->{cond}) ];
1918     };
1919   }
1920   else {
1921     # we got this far - means it is time to wrap a subquery
1922     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1923       sprintf(
1924         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1925         $op,
1926         $rsrc->source_name,
1927       )
1928     );
1929
1930     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1931     delete $attrs->{$_} for qw/select as collapse/;
1932     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1933
1934     # this will be consumed by the pruner waaaaay down the stack
1935     $attrs->{_force_prune_multiplying_joins} = 1;
1936
1937     my $subrs = (ref $self)->new($rsrc, $attrs);
1938
1939     if (@$idcols == 1) {
1940       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1941     }
1942     elsif ($storage->_use_multicolumn_in) {
1943       # no syntax for calling this properly yet
1944       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1945       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1946         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1947         $subrs->as_query
1948       ),
1949     }
1950     else {
1951       # if all else fails - get all primary keys and operate over a ORed set
1952       # wrap in a transaction for consistency
1953       # this is where the group_by/multiplication starts to matter
1954       if (
1955         $existing_group_by
1956           or
1957         # we do not need to check pre-multipliers, since if the premulti is there, its
1958         # parent (who is multi) will be there too
1959         keys %{ $join_classifications->{multiplying} || {} }
1960       ) {
1961         # make sure if there is a supplied group_by it matches the columns compiled above
1962         # perfectly. Anything else can not be sanely executed on most databases so croak
1963         # right then and there
1964         if ($existing_group_by) {
1965           my @current_group_by = map
1966             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1967             @$existing_group_by
1968           ;
1969
1970           if (
1971             join ("\x00", sort @current_group_by)
1972               ne
1973             join ("\x00", sort @{$attrs->{columns}} )
1974           ) {
1975             $self->throw_exception (
1976               "You have just attempted a $op operation on a resultset which does group_by"
1977               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1978               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1979               . ' kind of queries. Please retry the operation with a modified group_by or'
1980               . ' without using one at all.'
1981             );
1982           }
1983         }
1984
1985         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1986       }
1987
1988       $guard = $storage->txn_scope_guard;
1989
1990       for my $row ($subrs->cursor->all) {
1991         push @$cond, { map
1992           { $idcols->[$_] => $row->[$_] }
1993           (0 .. $#$idcols)
1994         };
1995       }
1996     }
1997   }
1998
1999   my $res = $cond ? $storage->$op (
2000     $rsrc,
2001     $op eq 'update' ? $values : (),
2002     $cond,
2003   ) : '0E0';
2004
2005   $guard->commit if $guard;
2006
2007   return $res;
2008 }
2009
2010 =head2 update
2011
2012 =over 4
2013
2014 =item Arguments: \%values
2015
2016 =item Return Value: $underlying_storage_rv
2017
2018 =back
2019
2020 Sets the specified columns in the resultset to the supplied values in a
2021 single query. Note that this will not run any accessor/set_column/update
2022 triggers, nor will it update any result object instances derived from this
2023 resultset (this includes the contents of the L<resultset cache|/set_cache>
2024 if any). See L</update_all> if you need to execute any on-update
2025 triggers or cascades defined either by you or a
2026 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2027
2028 The return value is a pass through of what the underlying
2029 storage backend returned, and may vary. See L<DBI/execute> for the most
2030 common case.
2031
2032 =head3 CAVEAT
2033
2034 Note that L</update> does not process/deflate any of the values passed in.
2035 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2036 ensure manually that any value passed to this method will stringify to
2037 something the RDBMS knows how to deal with. A notable example is the
2038 handling of L<DateTime> objects, for more info see:
2039 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2040
2041 =cut
2042
2043 sub update {
2044   my ($self, $values) = @_;
2045   $self->throw_exception('Values for update must be a hash')
2046     unless ref $values eq 'HASH';
2047
2048   return $self->_rs_update_delete ('update', $values);
2049 }
2050
2051 =head2 update_all
2052
2053 =over 4
2054
2055 =item Arguments: \%values
2056
2057 =item Return Value: 1
2058
2059 =back
2060
2061 Fetches all objects and updates them one at a time via
2062 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2063 triggers, while L</update> will not.
2064
2065 =cut
2066
2067 sub update_all {
2068   my ($self, $values) = @_;
2069   $self->throw_exception('Values for update_all must be a hash')
2070     unless ref $values eq 'HASH';
2071
2072   my $guard = $self->result_source->schema->txn_scope_guard;
2073   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2074   $guard->commit;
2075   return 1;
2076 }
2077
2078 =head2 delete
2079
2080 =over 4
2081
2082 =item Arguments: none
2083
2084 =item Return Value: $underlying_storage_rv
2085
2086 =back
2087
2088 Deletes the rows matching this resultset in a single query. Note that this
2089 will not run any delete triggers, nor will it alter the
2090 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2091 derived from this resultset (this includes the contents of the
2092 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2093 execute any on-delete triggers or cascades defined either by you or a
2094 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2095
2096 The return value is a pass through of what the underlying storage backend
2097 returned, and may vary. See L<DBI/execute> for the most common case.
2098
2099 =cut
2100
2101 sub delete {
2102   my $self = shift;
2103   $self->throw_exception('delete does not accept any arguments')
2104     if @_;
2105
2106   return $self->_rs_update_delete ('delete');
2107 }
2108
2109 =head2 delete_all
2110
2111 =over 4
2112
2113 =item Arguments: none
2114
2115 =item Return Value: 1
2116
2117 =back
2118
2119 Fetches all objects and deletes them one at a time via
2120 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2121 triggers, while L</delete> will not.
2122
2123 =cut
2124
2125 sub delete_all {
2126   my $self = shift;
2127   $self->throw_exception('delete_all does not accept any arguments')
2128     if @_;
2129
2130   my $guard = $self->result_source->schema->txn_scope_guard;
2131   $_->delete for $self->all;
2132   $guard->commit;
2133   return 1;
2134 }
2135
2136 =head2 populate
2137
2138 =over 4
2139
2140 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2141
2142 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2143
2144 =back
2145
2146 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2147 arrayrefs.
2148
2149 =over
2150
2151 =item NOTE
2152
2153 The context of this method call has an important effect on what is
2154 submitted to storage. In void context data is fed directly to fastpath
2155 insertion routines provided by the underlying storage (most often
2156 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2157 L<insert|DBIx::Class::Row/insert> calls on the
2158 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2159 augmentation of these methods provided by components. For example if you
2160 are using something like L<DBIx::Class::UUIDColumns> to create primary
2161 keys for you, you will find that your PKs are empty.  In this case you
2162 will have to explicitly force scalar or list context in order to create
2163 those values.
2164
2165 =back
2166
2167 In non-void (scalar or list) context, this method is simply a wrapper
2168 for L</create>. Depending on list or scalar context either a list of
2169 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2170 containing these objects is returned.
2171
2172 When supplying data in "arrayref of arrayrefs" invocation style, the
2173 first element should be a list of column names and each subsequent
2174 element should be a data value in the earlier specified column order.
2175 For example:
2176
2177   $schema->resultset("Artist")->populate([
2178     [ qw( artistid name ) ],
2179     [ 100, 'A Formally Unknown Singer' ],
2180     [ 101, 'A singer that jumped the shark two albums ago' ],
2181     [ 102, 'An actually cool singer' ],
2182   ]);
2183
2184 For the arrayref of hashrefs style each hashref should be a structure
2185 suitable for passing to L</create>. Multi-create is also permitted with
2186 this syntax.
2187
2188   $schema->resultset("Artist")->populate([
2189      { artistid => 4, name => 'Manufactured Crap', cds => [
2190         { title => 'My First CD', year => 2006 },
2191         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2192       ],
2193      },
2194      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2195         { title => 'My parents sold me to a record company', year => 2005 },
2196         { title => 'Why Am I So Ugly?', year => 2006 },
2197         { title => 'I Got Surgery and am now Popular', year => 2007 }
2198       ],
2199      },
2200   ]);
2201
2202 If you attempt a void-context multi-create as in the example above (each
2203 Artist also has the related list of CDs), and B<do not> supply the
2204 necessary autoinc foreign key information, this method will proxy to the
2205 less efficient L</create>, and then throw the Result objects away. In this
2206 case there are obviously no benefits to using this method over L</create>.
2207
2208 =cut
2209
2210 sub populate {
2211   my $self = shift;
2212
2213   # cruft placed in standalone method
2214   my $data = $self->_normalize_populate_args(@_);
2215
2216   return unless @$data;
2217
2218   if(defined wantarray) {
2219     my @created = map { $self->create($_) } @$data;
2220     return wantarray ? @created : \@created;
2221   }
2222   else {
2223     my $first = $data->[0];
2224
2225     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2226     # it relationship data
2227     my (@rels, @columns);
2228     my $rsrc = $self->result_source;
2229     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2230     for (keys %$first) {
2231       my $ref = ref $first->{$_};
2232       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2233         ? push @rels, $_
2234         : push @columns, $_
2235       ;
2236     }
2237
2238     my @pks = $rsrc->primary_columns;
2239
2240     ## do the belongs_to relationships
2241     foreach my $index (0..$#$data) {
2242
2243       # delegate to create() for any dataset without primary keys with specified relationships
2244       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2245         for my $r (@rels) {
2246           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2247             my @ret = $self->populate($data);
2248             return;
2249           }
2250         }
2251       }
2252
2253       foreach my $rel (@rels) {
2254         next unless ref $data->[$index]->{$rel} eq "HASH";
2255         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2256         my (undef, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2257         my $related = $result->result_source->_resolve_condition(
2258           $reverse_relinfo->{cond},
2259           $self,
2260           $result,
2261           $rel,
2262         );
2263
2264         delete $data->[$index]->{$rel};
2265         $data->[$index] = {%{$data->[$index]}, %$related};
2266
2267         push @columns, keys %$related if $index == 0;
2268       }
2269     }
2270
2271     ## inherit the data locked in the conditions of the resultset
2272     my ($rs_data) = $self->_merge_with_rscond({});
2273     delete @{$rs_data}{@columns};
2274
2275     ## do bulk insert on current row
2276     $rsrc->storage->insert_bulk(
2277       $rsrc,
2278       [@columns, keys %$rs_data],
2279       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2280     );
2281
2282     ## do the has_many relationships
2283     foreach my $item (@$data) {
2284
2285       my $main_row;
2286
2287       foreach my $rel (@rels) {
2288         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2289
2290         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2291
2292         my $child = $main_row->$rel;
2293
2294         my $related = $child->result_source->_resolve_condition(
2295           $rels->{$rel}{cond},
2296           $child,
2297           $main_row,
2298           $rel,
2299         );
2300
2301         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2302         my @populate = map { {%$_, %$related} } @rows_to_add;
2303
2304         $child->populate( \@populate );
2305       }
2306     }
2307   }
2308 }
2309
2310
2311 # populate() arguments went over several incarnations
2312 # What we ultimately support is AoH
2313 sub _normalize_populate_args {
2314   my ($self, $arg) = @_;
2315
2316   if (ref $arg eq 'ARRAY') {
2317     if (!@$arg) {
2318       return [];
2319     }
2320     elsif (ref $arg->[0] eq 'HASH') {
2321       return $arg;
2322     }
2323     elsif (ref $arg->[0] eq 'ARRAY') {
2324       my @ret;
2325       my @colnames = @{$arg->[0]};
2326       foreach my $values (@{$arg}[1 .. $#$arg]) {
2327         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2328       }
2329       return \@ret;
2330     }
2331   }
2332
2333   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2334 }
2335
2336 =head2 pager
2337
2338 =over 4
2339
2340 =item Arguments: none
2341
2342 =item Return Value: L<$pager|Data::Page>
2343
2344 =back
2345
2346 Returns a L<Data::Page> object for the current resultset. Only makes
2347 sense for queries with a C<page> attribute.
2348
2349 To get the full count of entries for a paged resultset, call
2350 C<total_entries> on the L<Data::Page> object.
2351
2352 =cut
2353
2354 sub pager {
2355   my ($self) = @_;
2356
2357   return $self->{pager} if $self->{pager};
2358
2359   my $attrs = $self->{attrs};
2360   if (!defined $attrs->{page}) {
2361     $self->throw_exception("Can't create pager for non-paged rs");
2362   }
2363   elsif ($attrs->{page} <= 0) {
2364     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2365   }
2366   $attrs->{rows} ||= 10;
2367
2368   # throw away the paging flags and re-run the count (possibly
2369   # with a subselect) to get the real total count
2370   my $count_attrs = { %$attrs };
2371   delete @{$count_attrs}{qw/rows offset page pager/};
2372
2373   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2374
2375   require DBIx::Class::ResultSet::Pager;
2376   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2377     sub { $total_rs->count },  #lazy-get the total
2378     $attrs->{rows},
2379     $self->{attrs}{page},
2380   );
2381 }
2382
2383 =head2 page
2384
2385 =over 4
2386
2387 =item Arguments: $page_number
2388
2389 =item Return Value: L<$resultset|/search>
2390
2391 =back
2392
2393 Returns a resultset for the $page_number page of the resultset on which page
2394 is called, where each page contains a number of rows equal to the 'rows'
2395 attribute set on the resultset (10 by default).
2396
2397 =cut
2398
2399 sub page {
2400   my ($self, $page) = @_;
2401   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2402 }
2403
2404 =head2 new_result
2405
2406 =over 4
2407
2408 =item Arguments: \%col_data
2409
2410 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2411
2412 =back
2413
2414 Creates a new result object in the resultset's result class and returns
2415 it. The row is not inserted into the database at this point, call
2416 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2417 will tell you whether the result object has been inserted or not.
2418
2419 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2420
2421 =cut
2422
2423 sub new_result {
2424   my ($self, $values) = @_;
2425
2426   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2427     if @_ > 2;
2428
2429   $self->throw_exception( "new_result expects a hashref" )
2430     unless (ref $values eq 'HASH');
2431
2432   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2433
2434   my $new = $self->result_class->new({
2435     %$merged_cond,
2436     ( @$cols_from_relations
2437       ? (-cols_from_relations => $cols_from_relations)
2438       : ()
2439     ),
2440     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2441   });
2442
2443   if (
2444     reftype($new) eq 'HASH'
2445       and
2446     ! keys %$new
2447       and
2448     blessed($new)
2449   ) {
2450     carp_unique (sprintf (
2451       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2452       $self->result_class,
2453     ));
2454   }
2455
2456   $new;
2457 }
2458
2459 # _merge_with_rscond
2460 #
2461 # Takes a simple hash of K/V data and returns its copy merged with the
2462 # condition already present on the resultset. Additionally returns an
2463 # arrayref of value/condition names, which were inferred from related
2464 # objects (this is needed for in-memory related objects)
2465 sub _merge_with_rscond {
2466   my ($self, $data) = @_;
2467
2468   my (%new_data, @cols_from_relations);
2469
2470   my $alias = $self->{attrs}{alias};
2471
2472   if (! defined $self->{cond}) {
2473     # just massage $data below
2474   }
2475   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2476     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2477     @cols_from_relations = keys %new_data;
2478   }
2479   elsif (ref $self->{cond} ne 'HASH') {
2480     $self->throw_exception(
2481       "Can't abstract implicit construct, resultset condition not a hash"
2482     );
2483   }
2484   else {
2485     if ($self->{cond}) {
2486       my $implied = $self->_remove_alias(
2487         $self->result_source->schema->storage->_collapse_cond($self->{cond}),
2488         $alias,
2489       );
2490
2491       for my $c (keys %$implied) {
2492         my $v = $implied->{$c};
2493         if ( ! length ref $v or is_plain_value($v) ) {
2494           $new_data{$c} = $v;
2495         }
2496         elsif (
2497           ref $v eq 'HASH' and keys %$v == 1 and exists $v->{'='} and is_literal_value($v->{'='})
2498         ) {
2499           $new_data{$c} = $v->{'='};
2500         }
2501       }
2502     }
2503   }
2504
2505   # precedence must be given to passed values over values inherited from
2506   # the cond, so the order here is important.
2507   %new_data = (
2508     %new_data,
2509     %{ $self->_remove_alias($data, $alias) },
2510   );
2511
2512   return (\%new_data, \@cols_from_relations);
2513 }
2514
2515 # _has_resolved_attr
2516 #
2517 # determines if the resultset defines at least one
2518 # of the attributes supplied
2519 #
2520 # used to determine if a subquery is necessary
2521 #
2522 # supports some virtual attributes:
2523 #   -join
2524 #     This will scan for any joins being present on the resultset.
2525 #     It is not a mere key-search but a deep inspection of {from}
2526 #
2527
2528 sub _has_resolved_attr {
2529   my ($self, @attr_names) = @_;
2530
2531   my $attrs = $self->_resolved_attrs;
2532
2533   my %extra_checks;
2534
2535   for my $n (@attr_names) {
2536     if (grep { $n eq $_ } (qw/-join/) ) {
2537       $extra_checks{$n}++;
2538       next;
2539     }
2540
2541     my $attr =  $attrs->{$n};
2542
2543     next if not defined $attr;
2544
2545     if (ref $attr eq 'HASH') {
2546       return 1 if keys %$attr;
2547     }
2548     elsif (ref $attr eq 'ARRAY') {
2549       return 1 if @$attr;
2550     }
2551     else {
2552       return 1 if $attr;
2553     }
2554   }
2555
2556   # a resolved join is expressed as a multi-level from
2557   return 1 if (
2558     $extra_checks{-join}
2559       and
2560     ref $attrs->{from} eq 'ARRAY'
2561       and
2562     @{$attrs->{from}} > 1
2563   );
2564
2565   return 0;
2566 }
2567
2568 # _remove_alias
2569 #
2570 # Remove the specified alias from the specified query hash. A copy is made so
2571 # the original query is not modified.
2572
2573 sub _remove_alias {
2574   my ($self, $query, $alias) = @_;
2575
2576   my %orig = %{ $query || {} };
2577   my %unaliased;
2578
2579   foreach my $key (keys %orig) {
2580     if ($key !~ /\./) {
2581       $unaliased{$key} = $orig{$key};
2582       next;
2583     }
2584     $unaliased{$1} = $orig{$key}
2585       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2586   }
2587
2588   return \%unaliased;
2589 }
2590
2591 =head2 as_query
2592
2593 =over 4
2594
2595 =item Arguments: none
2596
2597 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2598
2599 =back
2600
2601 Returns the SQL query and bind vars associated with the invocant.
2602
2603 This is generally used as the RHS for a subquery.
2604
2605 =cut
2606
2607 sub as_query {
2608   my $self = shift;
2609
2610   my $attrs = { %{ $self->_resolved_attrs } };
2611
2612   my $aq = $self->result_source->storage->_select_args_to_query (
2613     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2614   );
2615
2616   $aq;
2617 }
2618
2619 =head2 find_or_new
2620
2621 =over 4
2622
2623 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2624
2625 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2626
2627 =back
2628
2629   my $artist = $schema->resultset('Artist')->find_or_new(
2630     { artist => 'fred' }, { key => 'artists' });
2631
2632   $cd->cd_to_producer->find_or_new({ producer => $producer },
2633                                    { key => 'primary' });
2634
2635 Find an existing record from this resultset using L</find>. if none exists,
2636 instantiate a new result object and return it. The object will not be saved
2637 into your storage until you call L<DBIx::Class::Row/insert> on it.
2638
2639 You most likely want this method when looking for existing rows using a unique
2640 constraint that is not the primary key, or looking for related rows.
2641
2642 If you want objects to be saved immediately, use L</find_or_create> instead.
2643
2644 B<Note>: Make sure to read the documentation of L</find> and understand the
2645 significance of the C<key> attribute, as its lack may skew your search, and
2646 subsequently result in spurious new objects.
2647
2648 B<Note>: Take care when using C<find_or_new> with a table having
2649 columns with default values that you intend to be automatically
2650 supplied by the database (e.g. an auto_increment primary key column).
2651 In normal usage, the value of such columns should NOT be included at
2652 all in the call to C<find_or_new>, even when set to C<undef>.
2653
2654 =cut
2655
2656 sub find_or_new {
2657   my $self     = shift;
2658   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2659   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2660   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2661     return $row;
2662   }
2663   return $self->new_result($hash);
2664 }
2665
2666 =head2 create
2667
2668 =over 4
2669
2670 =item Arguments: \%col_data
2671
2672 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2673
2674 =back
2675
2676 Attempt to create a single new row or a row with multiple related rows
2677 in the table represented by the resultset (and related tables). This
2678 will not check for duplicate rows before inserting, use
2679 L</find_or_create> to do that.
2680
2681 To create one row for this resultset, pass a hashref of key/value
2682 pairs representing the columns of the table and the values you wish to
2683 store. If the appropriate relationships are set up, foreign key fields
2684 can also be passed an object representing the foreign row, and the
2685 value will be set to its primary key.
2686
2687 To create related objects, pass a hashref of related-object column values
2688 B<keyed on the relationship name>. If the relationship is of type C<multi>
2689 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2690 The process will correctly identify columns holding foreign keys, and will
2691 transparently populate them from the keys of the corresponding relation.
2692 This can be applied recursively, and will work correctly for a structure
2693 with an arbitrary depth and width, as long as the relationships actually
2694 exists and the correct column data has been supplied.
2695
2696 Instead of hashrefs of plain related data (key/value pairs), you may
2697 also pass new or inserted objects. New objects (not inserted yet, see
2698 L</new_result>), will be inserted into their appropriate tables.
2699
2700 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2701
2702 Example of creating a new row.
2703
2704   $person_rs->create({
2705     name=>"Some Person",
2706     email=>"somebody@someplace.com"
2707   });
2708
2709 Example of creating a new row and also creating rows in a related C<has_many>
2710 or C<has_one> resultset.  Note Arrayref.
2711
2712   $artist_rs->create(
2713      { artistid => 4, name => 'Manufactured Crap', cds => [
2714         { title => 'My First CD', year => 2006 },
2715         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2716       ],
2717      },
2718   );
2719
2720 Example of creating a new row and also creating a row in a related
2721 C<belongs_to> resultset. Note Hashref.
2722
2723   $cd_rs->create({
2724     title=>"Music for Silly Walks",
2725     year=>2000,
2726     artist => {
2727       name=>"Silly Musician",
2728     }
2729   });
2730
2731 =over
2732
2733 =item WARNING
2734
2735 When subclassing ResultSet never attempt to override this method. Since
2736 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2737 lot of the internals simply never call it, so your override will be
2738 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2739 or L<DBIx::Class::Row/insert> depending on how early in the
2740 L</create> process you need to intervene. See also warning pertaining to
2741 L</new>.
2742
2743 =back
2744
2745 =cut
2746
2747 sub create {
2748   my ($self, $col_data) = @_;
2749   $self->throw_exception( "create needs a hashref" )
2750     unless ref $col_data eq 'HASH';
2751   return $self->new_result($col_data)->insert;
2752 }
2753
2754 =head2 find_or_create
2755
2756 =over 4
2757
2758 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2759
2760 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2761
2762 =back
2763
2764   $cd->cd_to_producer->find_or_create({ producer => $producer },
2765                                       { key => 'primary' });
2766
2767 Tries to find a record based on its primary key or unique constraints; if none
2768 is found, creates one and returns that instead.
2769
2770   my $cd = $schema->resultset('CD')->find_or_create({
2771     cdid   => 5,
2772     artist => 'Massive Attack',
2773     title  => 'Mezzanine',
2774     year   => 2005,
2775   });
2776
2777 Also takes an optional C<key> attribute, to search by a specific key or unique
2778 constraint. For example:
2779
2780   my $cd = $schema->resultset('CD')->find_or_create(
2781     {
2782       artist => 'Massive Attack',
2783       title  => 'Mezzanine',
2784     },
2785     { key => 'cd_artist_title' }
2786   );
2787
2788 B<Note>: Make sure to read the documentation of L</find> and understand the
2789 significance of the C<key> attribute, as its lack may skew your search, and
2790 subsequently result in spurious row creation.
2791
2792 B<Note>: Because find_or_create() reads from the database and then
2793 possibly inserts based on the result, this method is subject to a race
2794 condition. Another process could create a record in the table after
2795 the find has completed and before the create has started. To avoid
2796 this problem, use find_or_create() inside a transaction.
2797
2798 B<Note>: Take care when using C<find_or_create> with a table having
2799 columns with default values that you intend to be automatically
2800 supplied by the database (e.g. an auto_increment primary key column).
2801 In normal usage, the value of such columns should NOT be included at
2802 all in the call to C<find_or_create>, even when set to C<undef>.
2803
2804 See also L</find> and L</update_or_create>. For information on how to declare
2805 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2806
2807 If you need to know if an existing row was found or a new one created use
2808 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2809 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2810 database!
2811
2812   my $cd = $schema->resultset('CD')->find_or_new({
2813     cdid   => 5,
2814     artist => 'Massive Attack',
2815     title  => 'Mezzanine',
2816     year   => 2005,
2817   });
2818
2819   if( !$cd->in_storage ) {
2820       # do some stuff
2821       $cd->insert;
2822   }
2823
2824 =cut
2825
2826 sub find_or_create {
2827   my $self     = shift;
2828   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2829   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2830   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2831     return $row;
2832   }
2833   return $self->create($hash);
2834 }
2835
2836 =head2 update_or_create
2837
2838 =over 4
2839
2840 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2841
2842 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2843
2844 =back
2845
2846   $resultset->update_or_create({ col => $val, ... });
2847
2848 Like L</find_or_create>, but if a row is found it is immediately updated via
2849 C<< $found_row->update (\%col_data) >>.
2850
2851
2852 Takes an optional C<key> attribute to search on a specific unique constraint.
2853 For example:
2854
2855   # In your application
2856   my $cd = $schema->resultset('CD')->update_or_create(
2857     {
2858       artist => 'Massive Attack',
2859       title  => 'Mezzanine',
2860       year   => 1998,
2861     },
2862     { key => 'cd_artist_title' }
2863   );
2864
2865   $cd->cd_to_producer->update_or_create({
2866     producer => $producer,
2867     name => 'harry',
2868   }, {
2869     key => 'primary',
2870   });
2871
2872 B<Note>: Make sure to read the documentation of L</find> and understand the
2873 significance of the C<key> attribute, as its lack may skew your search, and
2874 subsequently result in spurious row creation.
2875
2876 B<Note>: Take care when using C<update_or_create> with a table having
2877 columns with default values that you intend to be automatically
2878 supplied by the database (e.g. an auto_increment primary key column).
2879 In normal usage, the value of such columns should NOT be included at
2880 all in the call to C<update_or_create>, even when set to C<undef>.
2881
2882 See also L</find> and L</find_or_create>. For information on how to declare
2883 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2884
2885 If you need to know if an existing row was updated or a new one created use
2886 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2887 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2888 database!
2889
2890 =cut
2891
2892 sub update_or_create {
2893   my $self = shift;
2894   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2895   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2896
2897   my $row = $self->find($cond, $attrs);
2898   if (defined $row) {
2899     $row->update($cond);
2900     return $row;
2901   }
2902
2903   return $self->create($cond);
2904 }
2905
2906 =head2 update_or_new
2907
2908 =over 4
2909
2910 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2911
2912 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2913
2914 =back
2915
2916   $resultset->update_or_new({ col => $val, ... });
2917
2918 Like L</find_or_new> but if a row is found it is immediately updated via
2919 C<< $found_row->update (\%col_data) >>.
2920
2921 For example:
2922
2923   # In your application
2924   my $cd = $schema->resultset('CD')->update_or_new(
2925     {
2926       artist => 'Massive Attack',
2927       title  => 'Mezzanine',
2928       year   => 1998,
2929     },
2930     { key => 'cd_artist_title' }
2931   );
2932
2933   if ($cd->in_storage) {
2934       # the cd was updated
2935   }
2936   else {
2937       # the cd is not yet in the database, let's insert it
2938       $cd->insert;
2939   }
2940
2941 B<Note>: Make sure to read the documentation of L</find> and understand the
2942 significance of the C<key> attribute, as its lack may skew your search, and
2943 subsequently result in spurious new objects.
2944
2945 B<Note>: Take care when using C<update_or_new> with a table having
2946 columns with default values that you intend to be automatically
2947 supplied by the database (e.g. an auto_increment primary key column).
2948 In normal usage, the value of such columns should NOT be included at
2949 all in the call to C<update_or_new>, even when set to C<undef>.
2950
2951 See also L</find>, L</find_or_create> and L</find_or_new>.
2952
2953 =cut
2954
2955 sub update_or_new {
2956     my $self  = shift;
2957     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2958     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2959
2960     my $row = $self->find( $cond, $attrs );
2961     if ( defined $row ) {
2962         $row->update($cond);
2963         return $row;
2964     }
2965
2966     return $self->new_result($cond);
2967 }
2968
2969 =head2 get_cache
2970
2971 =over 4
2972
2973 =item Arguments: none
2974
2975 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2976
2977 =back
2978
2979 Gets the contents of the cache for the resultset, if the cache is set.
2980
2981 The cache is populated either by using the L</prefetch> attribute to
2982 L</search> or by calling L</set_cache>.
2983
2984 =cut
2985
2986 sub get_cache {
2987   shift->{all_cache};
2988 }
2989
2990 =head2 set_cache
2991
2992 =over 4
2993
2994 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2995
2996 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2997
2998 =back
2999
3000 Sets the contents of the cache for the resultset. Expects an arrayref
3001 of objects of the same class as those produced by the resultset. Note that
3002 if the cache is set, the resultset will return the cached objects rather
3003 than re-querying the database even if the cache attr is not set.
3004
3005 The contents of the cache can also be populated by using the
3006 L</prefetch> attribute to L</search>.
3007
3008 =cut
3009
3010 sub set_cache {
3011   my ( $self, $data ) = @_;
3012   $self->throw_exception("set_cache requires an arrayref")
3013       if defined($data) && (ref $data ne 'ARRAY');
3014   $self->{all_cache} = $data;
3015 }
3016
3017 =head2 clear_cache
3018
3019 =over 4
3020
3021 =item Arguments: none
3022
3023 =item Return Value: undef
3024
3025 =back
3026
3027 Clears the cache for the resultset.
3028
3029 =cut
3030
3031 sub clear_cache {
3032   shift->set_cache(undef);
3033 }
3034
3035 =head2 is_paged
3036
3037 =over 4
3038
3039 =item Arguments: none
3040
3041 =item Return Value: true, if the resultset has been paginated
3042
3043 =back
3044
3045 =cut
3046
3047 sub is_paged {
3048   my ($self) = @_;
3049   return !!$self->{attrs}{page};
3050 }
3051
3052 =head2 is_ordered
3053
3054 =over 4
3055
3056 =item Arguments: none
3057
3058 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3059
3060 =back
3061
3062 =cut
3063
3064 sub is_ordered {
3065   my ($self) = @_;
3066   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3067 }
3068
3069 =head2 related_resultset
3070
3071 =over 4
3072
3073 =item Arguments: $rel_name
3074
3075 =item Return Value: L<$resultset|/search>
3076
3077 =back
3078
3079 Returns a related resultset for the supplied relationship name.
3080
3081   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3082
3083 =cut
3084
3085 sub related_resultset {
3086   my ($self, $rel) = @_;
3087
3088   return $self->{related_resultsets}{$rel}
3089     if defined $self->{related_resultsets}{$rel};
3090
3091   return $self->{related_resultsets}{$rel} = do {
3092     my $rsrc = $self->result_source;
3093     my $rel_info = $rsrc->relationship_info($rel);
3094
3095     $self->throw_exception(
3096       "search_related: result source '" . $rsrc->source_name .
3097         "' has no such relationship $rel")
3098       unless $rel_info;
3099
3100     my $attrs = $self->_chain_relationship($rel);
3101
3102     my $join_count = $attrs->{seen_join}{$rel};
3103
3104     my $alias = $self->result_source->storage
3105         ->relname_to_table_alias($rel, $join_count);
3106
3107     # since this is search_related, and we already slid the select window inwards
3108     # (the select/as attrs were deleted in the beginning), we need to flip all
3109     # left joins to inner, so we get the expected results
3110     # read the comment on top of the actual function to see what this does
3111     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3112
3113
3114     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3115     delete @{$attrs}{qw(result_class alias)};
3116
3117     my $rel_source = $rsrc->related_source($rel);
3118
3119     my $new = do {
3120
3121       # The reason we do this now instead of passing the alias to the
3122       # search_rs below is that if you wrap/overload resultset on the
3123       # source you need to know what alias it's -going- to have for things
3124       # to work sanely (e.g. RestrictWithObject wants to be able to add
3125       # extra query restrictions, and these may need to be $alias.)
3126
3127       my $rel_attrs = $rel_source->resultset_attributes;
3128       local $rel_attrs->{alias} = $alias;
3129
3130       $rel_source->resultset
3131                  ->search_rs(
3132                      undef, {
3133                        %$attrs,
3134                        where => $attrs->{where},
3135                    });
3136     };
3137
3138     if (my $cache = $self->get_cache) {
3139       my @related_cache = map
3140         { $_->related_resultset($rel)->get_cache || () }
3141         @$cache
3142       ;
3143
3144       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3145     }
3146
3147     $new;
3148   };
3149 }
3150
3151 =head2 current_source_alias
3152
3153 =over 4
3154
3155 =item Arguments: none
3156
3157 =item Return Value: $source_alias
3158
3159 =back
3160
3161 Returns the current table alias for the result source this resultset is built
3162 on, that will be used in the SQL query. Usually it is C<me>.
3163
3164 Currently the source alias that refers to the result set returned by a
3165 L</search>/L</find> family method depends on how you got to the resultset: it's
3166 C<me> by default, but eg. L</search_related> aliases it to the related result
3167 source name (and keeps C<me> referring to the original result set). The long
3168 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3169 (and make this method unnecessary).
3170
3171 Thus it's currently necessary to use this method in predefined queries (see
3172 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3173 source alias of the current result set:
3174
3175   # in a result set class
3176   sub modified_by {
3177     my ($self, $user) = @_;
3178
3179     my $me = $self->current_source_alias;
3180
3181     return $self->search({
3182       "$me.modified" => $user->id,
3183     });
3184   }
3185
3186 =cut
3187
3188 sub current_source_alias {
3189   return (shift->{attrs} || {})->{alias} || 'me';
3190 }
3191
3192 =head2 as_subselect_rs
3193
3194 =over 4
3195
3196 =item Arguments: none
3197
3198 =item Return Value: L<$resultset|/search>
3199
3200 =back
3201
3202 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3203 "virtual view" by including it as a subquery within the from clause.  From this
3204 point on, any joined tables are inaccessible to ->search on the resultset (as if
3205 it were simply where-filtered without joins).  For example:
3206
3207  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3208
3209  # 'x' now pollutes the query namespace
3210
3211  # So the following works as expected
3212  my $ok_rs = $rs->search({'x.other' => 1});
3213
3214  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3215  # def) we look for one row with contradictory terms and join in another table
3216  # (aliased 'x_2') which we never use
3217  my $broken_rs = $rs->search({'x.name' => 'def'});
3218
3219  my $rs2 = $rs->as_subselect_rs;
3220
3221  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3222  my $not_joined_rs = $rs2->search({'x.other' => 1});
3223
3224  # works as expected: finds a 'table' row related to two x rows (abc and def)
3225  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3226
3227 Another example of when one might use this would be to select a subset of
3228 columns in a group by clause:
3229
3230  my $rs = $schema->resultset('Bar')->search(undef, {
3231    group_by => [qw{ id foo_id baz_id }],
3232  })->as_subselect_rs->search(undef, {
3233    columns => [qw{ id foo_id }]
3234  });
3235
3236 In the above example normally columns would have to be equal to the group by,
3237 but because we isolated the group by into a subselect the above works.
3238
3239 =cut
3240
3241 sub as_subselect_rs {
3242   my $self = shift;
3243
3244   my $attrs = $self->_resolved_attrs;
3245
3246   my $fresh_rs = (ref $self)->new (
3247     $self->result_source
3248   );
3249
3250   # these pieces will be locked in the subquery
3251   delete $fresh_rs->{cond};
3252   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3253
3254   return $fresh_rs->search( {}, {
3255     from => [{
3256       $attrs->{alias} => $self->as_query,
3257       -alias  => $attrs->{alias},
3258       -rsrc   => $self->result_source,
3259     }],
3260     alias => $attrs->{alias},
3261   });
3262 }
3263
3264 # This code is called by search_related, and makes sure there
3265 # is clear separation between the joins before, during, and
3266 # after the relationship. This information is needed later
3267 # in order to properly resolve prefetch aliases (any alias
3268 # with a relation_chain_depth less than the depth of the
3269 # current prefetch is not considered)
3270 #
3271 # The increments happen twice per join. An even number means a
3272 # relationship specified via a search_related, whereas an odd
3273 # number indicates a join/prefetch added via attributes
3274 #
3275 # Also this code will wrap the current resultset (the one we
3276 # chain to) in a subselect IFF it contains limiting attributes
3277 sub _chain_relationship {
3278   my ($self, $rel) = @_;
3279   my $source = $self->result_source;
3280   my $attrs = { %{$self->{attrs}||{}} };
3281
3282   # we need to take the prefetch the attrs into account before we
3283   # ->_resolve_join as otherwise they get lost - captainL
3284   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3285
3286   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3287
3288   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3289
3290   my $from;
3291   my @force_subq_attrs = qw/offset rows group_by having/;
3292
3293   if (
3294     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3295       ||
3296     $self->_has_resolved_attr (@force_subq_attrs)
3297   ) {
3298     # Nuke the prefetch (if any) before the new $rs attrs
3299     # are resolved (prefetch is useless - we are wrapping
3300     # a subquery anyway).
3301     my $rs_copy = $self->search;
3302     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3303       $rs_copy->{attrs}{join},
3304       delete $rs_copy->{attrs}{prefetch},
3305     );
3306
3307     $from = [{
3308       -rsrc   => $source,
3309       -alias  => $attrs->{alias},
3310       $attrs->{alias} => $rs_copy->as_query,
3311     }];
3312     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3313     $seen->{-relation_chain_depth} = 0;
3314   }
3315   elsif ($attrs->{from}) {  #shallow copy suffices
3316     $from = [ @{$attrs->{from}} ];
3317   }
3318   else {
3319     $from = [{
3320       -rsrc  => $source,
3321       -alias => $attrs->{alias},
3322       $attrs->{alias} => $source->from,
3323     }];
3324   }
3325
3326   my $jpath = ($seen->{-relation_chain_depth})
3327     ? $from->[-1][0]{-join_path}
3328     : [];
3329
3330   my @requested_joins = $source->_resolve_join(
3331     $join,
3332     $attrs->{alias},
3333     $seen,
3334     $jpath,
3335   );
3336
3337   push @$from, @requested_joins;
3338
3339   $seen->{-relation_chain_depth}++;
3340
3341   # if $self already had a join/prefetch specified on it, the requested
3342   # $rel might very well be already included. What we do in this case
3343   # is effectively a no-op (except that we bump up the chain_depth on
3344   # the join in question so we could tell it *is* the search_related)
3345   my $already_joined;
3346
3347   # we consider the last one thus reverse
3348   for my $j (reverse @requested_joins) {
3349     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3350     if ($rel eq $last_j) {
3351       $j->[0]{-relation_chain_depth}++;
3352       $already_joined++;
3353       last;
3354     }
3355   }
3356
3357   unless ($already_joined) {
3358     push @$from, $source->_resolve_join(
3359       $rel,
3360       $attrs->{alias},
3361       $seen,
3362       $jpath,
3363     );
3364   }
3365
3366   $seen->{-relation_chain_depth}++;
3367
3368   return {%$attrs, from => $from, seen_join => $seen};
3369 }
3370
3371 sub _resolved_attrs {
3372   my $self = shift;
3373   return $self->{_attrs} if $self->{_attrs};
3374
3375   my $attrs  = { %{ $self->{attrs} || {} } };
3376   my $source = $self->result_source;
3377   my $alias  = $attrs->{alias};
3378
3379   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3380     if $attrs->{collapse} and $attrs->{distinct};
3381
3382   # default selection list
3383   $attrs->{columns} = [ $source->columns ]
3384     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3385
3386   # merge selectors together
3387   for (qw/columns select as/) {
3388     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3389       if $attrs->{$_} or $attrs->{"+$_"};
3390   }
3391
3392   # disassemble columns
3393   my (@sel, @as);
3394   if (my $cols = delete $attrs->{columns}) {
3395     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3396       if (ref $c eq 'HASH') {
3397         for my $as (sort keys %$c) {
3398           push @sel, $c->{$as};
3399           push @as, $as;
3400         }
3401       }
3402       else {
3403         push @sel, $c;
3404         push @as, $c;
3405       }
3406     }
3407   }
3408
3409   # when trying to weed off duplicates later do not go past this point -
3410   # everything added from here on is unbalanced "anyone's guess" stuff
3411   my $dedup_stop_idx = $#as;
3412
3413   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3414     if $attrs->{as};
3415   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3416     if $attrs->{select};
3417
3418   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3419   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3420
3421   # disqualify all $alias.col as-bits (inflate-map mandated)
3422   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3423
3424   # de-duplicate the result (remove *identical* select/as pairs)
3425   # and also die on duplicate {as} pointing to different {select}s
3426   # not using a c-style for as the condition is prone to shrinkage
3427   my $seen;
3428   my $i = 0;
3429   while ($i <= $dedup_stop_idx) {
3430     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3431       splice @sel, $i, 1;
3432       splice @as, $i, 1;
3433       $dedup_stop_idx--;
3434     }
3435     elsif ($seen->{$as[$i]}++) {
3436       $self->throw_exception(
3437         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3438       );
3439     }
3440     else {
3441       $i++;
3442     }
3443   }
3444
3445   $attrs->{select} = \@sel;
3446   $attrs->{as} = \@as;
3447
3448   $attrs->{from} ||= [{
3449     -rsrc   => $source,
3450     -alias  => $self->{attrs}{alias},
3451     $self->{attrs}{alias} => $source->from,
3452   }];
3453
3454   if ( $attrs->{join} || $attrs->{prefetch} ) {
3455
3456     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3457       if ref $attrs->{from} ne 'ARRAY';
3458
3459     my $join = (delete $attrs->{join}) || {};
3460
3461     if ( defined $attrs->{prefetch} ) {
3462       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3463     }
3464
3465     $attrs->{from} =    # have to copy here to avoid corrupting the original
3466       [
3467         @{ $attrs->{from} },
3468         $source->_resolve_join(
3469           $join,
3470           $alias,
3471           { %{ $attrs->{seen_join} || {} } },
3472           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3473             ? $attrs->{from}[-1][0]{-join_path}
3474             : []
3475           ,
3476         )
3477       ];
3478   }
3479
3480   if ( defined $attrs->{order_by} ) {
3481     $attrs->{order_by} = (
3482       ref( $attrs->{order_by} ) eq 'ARRAY'
3483       ? [ @{ $attrs->{order_by} } ]
3484       : [ $attrs->{order_by} || () ]
3485     );
3486   }
3487
3488   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3489     $attrs->{group_by} = [ $attrs->{group_by} ];
3490   }
3491
3492
3493   # generate selections based on the prefetch helper
3494   my ($prefetch, @prefetch_select, @prefetch_as);
3495   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3496     if defined $attrs->{prefetch};
3497
3498   if ($prefetch) {
3499
3500     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3501       if $attrs->{_dark_selector};
3502
3503     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3504       if defined $attrs->{collapse} and ! $attrs->{collapse};
3505
3506     $attrs->{collapse} = 1;
3507
3508     # this is a separate structure (we don't look in {from} directly)
3509     # as the resolver needs to shift things off the lists to work
3510     # properly (identical-prefetches on different branches)
3511     my $join_map = {};
3512     if (ref $attrs->{from} eq 'ARRAY') {
3513
3514       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3515
3516       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3517         next unless $j->[0]{-alias};
3518         next unless $j->[0]{-join_path};
3519         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3520
3521         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3522
3523         my $p = $join_map;
3524         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3525         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3526       }
3527     }
3528
3529     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3530
3531     # save these for after distinct resolution
3532     @prefetch_select = map { $_->[0] } @prefetch;
3533     @prefetch_as = map { $_->[1] } @prefetch;
3534   }
3535
3536   # run through the resulting joinstructure (starting from our current slot)
3537   # and unset collapse if proven unnecessary
3538   #
3539   # also while we are at it find out if the current root source has
3540   # been premultiplied by previous related_source chaining
3541   #
3542   # this allows to predict whether a root object with all other relation
3543   # data set to NULL is in fact unique
3544   if ($attrs->{collapse}) {
3545
3546     if (ref $attrs->{from} eq 'ARRAY') {
3547
3548       if (@{$attrs->{from}} == 1) {
3549         # no joins - no collapse
3550         $attrs->{collapse} = 0;
3551       }
3552       else {
3553         # find where our table-spec starts
3554         my @fromlist = @{$attrs->{from}};
3555         while (@fromlist) {
3556           my $t = shift @fromlist;
3557
3558           my $is_multi;
3559           # me vs join from-spec distinction - a ref means non-root
3560           if (ref $t eq 'ARRAY') {
3561             $t = $t->[0];
3562             $is_multi ||= ! $t->{-is_single};
3563           }
3564           last if ($t->{-alias} && $t->{-alias} eq $alias);
3565           $attrs->{_main_source_premultiplied} ||= $is_multi;
3566         }
3567
3568         # no non-singles remaining, nor any premultiplication - nothing to collapse
3569         if (
3570           ! $attrs->{_main_source_premultiplied}
3571             and
3572           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3573         ) {
3574           $attrs->{collapse} = 0;
3575         }
3576       }
3577     }
3578
3579     else {
3580       # if we can not analyze the from - err on the side of safety
3581       $attrs->{_main_source_premultiplied} = 1;
3582     }
3583   }
3584
3585   # generate the distinct induced group_by before injecting the prefetched select/as parts
3586   if (delete $attrs->{distinct}) {
3587     if ($attrs->{group_by}) {
3588       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3589     }
3590     else {
3591       $attrs->{_grouped_by_distinct} = 1;
3592       # distinct affects only the main selection part, not what prefetch may add below
3593       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3594
3595       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3596       # The thinking is: if we are collapsing the subquerying prefetch engine will
3597       # rip stuff apart for us anyway, and we do not want to have a potentially
3598       # function-converted external order_by
3599       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3600       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3601     }
3602   }
3603
3604   # inject prefetch-bound selection (if any)
3605   push @{$attrs->{select}}, @prefetch_select;
3606   push @{$attrs->{as}}, @prefetch_as;
3607
3608   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3609   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3610     $attrs->{_related_results_construction} = 1;
3611   }
3612
3613   # if both page and offset are specified, produce a combined offset
3614   # even though it doesn't make much sense, this is what pre 081xx has
3615   # been doing
3616   if (my $page = delete $attrs->{page}) {
3617     $attrs->{offset} =
3618       ($attrs->{rows} * ($page - 1))
3619             +
3620       ($attrs->{offset} || 0)
3621     ;
3622   }
3623
3624   return $self->{_attrs} = $attrs;
3625 }
3626
3627 sub _rollout_attr {
3628   my ($self, $attr) = @_;
3629
3630   if (ref $attr eq 'HASH') {
3631     return $self->_rollout_hash($attr);
3632   } elsif (ref $attr eq 'ARRAY') {
3633     return $self->_rollout_array($attr);
3634   } else {
3635     return [$attr];
3636   }
3637 }
3638
3639 sub _rollout_array {
3640   my ($self, $attr) = @_;
3641
3642   my @rolled_array;
3643   foreach my $element (@{$attr}) {
3644     if (ref $element eq 'HASH') {
3645       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3646     } elsif (ref $element eq 'ARRAY') {
3647       #  XXX - should probably recurse here
3648       push( @rolled_array, @{$self->_rollout_array($element)} );
3649     } else {
3650       push( @rolled_array, $element );
3651     }
3652   }
3653   return \@rolled_array;
3654 }
3655
3656 sub _rollout_hash {
3657   my ($self, $attr) = @_;
3658
3659   my @rolled_array;
3660   foreach my $key (keys %{$attr}) {
3661     push( @rolled_array, { $key => $attr->{$key} } );
3662   }
3663   return \@rolled_array;
3664 }
3665
3666 sub _calculate_score {
3667   my ($self, $a, $b) = @_;
3668
3669   if (defined $a xor defined $b) {
3670     return 0;
3671   }
3672   elsif (not defined $a) {
3673     return 1;
3674   }
3675
3676   if (ref $b eq 'HASH') {
3677     my ($b_key) = keys %{$b};
3678     if (ref $a eq 'HASH') {
3679       my ($a_key) = keys %{$a};
3680       if ($a_key eq $b_key) {
3681         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3682       } else {
3683         return 0;
3684       }
3685     } else {
3686       return ($a eq $b_key) ? 1 : 0;
3687     }
3688   } else {
3689     if (ref $a eq 'HASH') {
3690       my ($a_key) = keys %{$a};
3691       return ($b eq $a_key) ? 1 : 0;
3692     } else {
3693       return ($b eq $a) ? 1 : 0;
3694     }
3695   }
3696 }
3697
3698 sub _merge_joinpref_attr {
3699   my ($self, $orig, $import) = @_;
3700
3701   return $import unless defined($orig);
3702   return $orig unless defined($import);
3703
3704   $orig = $self->_rollout_attr($orig);
3705   $import = $self->_rollout_attr($import);
3706
3707   my $seen_keys;
3708   foreach my $import_element ( @{$import} ) {
3709     # find best candidate from $orig to merge $b_element into
3710     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3711     foreach my $orig_element ( @{$orig} ) {
3712       my $score = $self->_calculate_score( $orig_element, $import_element );
3713       if ($score > $best_candidate->{score}) {
3714         $best_candidate->{position} = $position;
3715         $best_candidate->{score} = $score;
3716       }
3717       $position++;
3718     }
3719     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3720     $import_key = '' if not defined $import_key;
3721
3722     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3723       push( @{$orig}, $import_element );
3724     } else {
3725       my $orig_best = $orig->[$best_candidate->{position}];
3726       # merge orig_best and b_element together and replace original with merged
3727       if (ref $orig_best ne 'HASH') {
3728         $orig->[$best_candidate->{position}] = $import_element;
3729       } elsif (ref $import_element eq 'HASH') {
3730         my ($key) = keys %{$orig_best};
3731         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3732       }
3733     }
3734     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3735   }
3736
3737   return @$orig ? $orig : ();
3738 }
3739
3740 {
3741   my $hm;
3742
3743   sub _merge_attr {
3744     $hm ||= do {
3745       require Hash::Merge;
3746       my $hm = Hash::Merge->new;
3747
3748       $hm->specify_behavior({
3749         SCALAR => {
3750           SCALAR => sub {
3751             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3752
3753             if ($defl xor $defr) {
3754               return [ $defl ? $_[0] : $_[1] ];
3755             }
3756             elsif (! $defl) {
3757               return [];
3758             }
3759             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3760               return [ $_[0] ];
3761             }
3762             else {
3763               return [$_[0], $_[1]];
3764             }
3765           },
3766           ARRAY => sub {
3767             return $_[1] if !defined $_[0];
3768             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3769             return [$_[0], @{$_[1]}]
3770           },
3771           HASH  => sub {
3772             return [] if !defined $_[0] and !keys %{$_[1]};
3773             return [ $_[1] ] if !defined $_[0];
3774             return [ $_[0] ] if !keys %{$_[1]};
3775             return [$_[0], $_[1]]
3776           },
3777         },
3778         ARRAY => {
3779           SCALAR => sub {
3780             return $_[0] if !defined $_[1];
3781             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3782             return [@{$_[0]}, $_[1]]
3783           },
3784           ARRAY => sub {
3785             my @ret = @{$_[0]} or return $_[1];
3786             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3787             my %idx = map { $_ => 1 } @ret;
3788             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3789             \@ret;
3790           },
3791           HASH => sub {
3792             return [ $_[1] ] if ! @{$_[0]};
3793             return $_[0] if !keys %{$_[1]};
3794             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3795             return [ @{$_[0]}, $_[1] ];
3796           },
3797         },
3798         HASH => {
3799           SCALAR => sub {
3800             return [] if !keys %{$_[0]} and !defined $_[1];
3801             return [ $_[0] ] if !defined $_[1];
3802             return [ $_[1] ] if !keys %{$_[0]};
3803             return [$_[0], $_[1]]
3804           },
3805           ARRAY => sub {
3806             return [] if !keys %{$_[0]} and !@{$_[1]};
3807             return [ $_[0] ] if !@{$_[1]};
3808             return $_[1] if !keys %{$_[0]};
3809             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3810             return [ $_[0], @{$_[1]} ];
3811           },
3812           HASH => sub {
3813             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3814             return [ $_[0] ] if !keys %{$_[1]};
3815             return [ $_[1] ] if !keys %{$_[0]};
3816             return [ $_[0] ] if $_[0] eq $_[1];
3817             return [ $_[0], $_[1] ];
3818           },
3819         }
3820       } => 'DBIC_RS_ATTR_MERGER');
3821       $hm;
3822     };
3823
3824     return $hm->merge ($_[1], $_[2]);
3825   }
3826 }
3827
3828 sub STORABLE_freeze {
3829   my ($self, $cloning) = @_;
3830   my $to_serialize = { %$self };
3831
3832   # A cursor in progress can't be serialized (and would make little sense anyway)
3833   # the parser can be regenerated (and can't be serialized)
3834   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3835
3836   # nor is it sensical to store a not-yet-fired-count pager
3837   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3838     delete $to_serialize->{pager};
3839   }
3840
3841   Storable::nfreeze($to_serialize);
3842 }
3843
3844 # need this hook for symmetry
3845 sub STORABLE_thaw {
3846   my ($self, $cloning, $serialized) = @_;
3847
3848   %$self = %{ Storable::thaw($serialized) };
3849
3850   $self;
3851 }
3852
3853
3854 =head2 throw_exception
3855
3856 See L<DBIx::Class::Schema/throw_exception> for details.
3857
3858 =cut
3859
3860 sub throw_exception {
3861   my $self=shift;
3862
3863   if (ref $self and my $rsrc = $self->result_source) {
3864     $rsrc->throw_exception(@_)
3865   }
3866   else {
3867     DBIx::Class::Exception->throw(@_);
3868   }
3869 }
3870
3871 1;
3872
3873 __END__
3874
3875 # XXX: FIXME: Attributes docs need clearing up
3876
3877 =head1 ATTRIBUTES
3878
3879 Attributes are used to refine a ResultSet in various ways when
3880 searching for data. They can be passed to any method which takes an
3881 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3882 L</count>.
3883
3884 Default attributes can be set on the result class using
3885 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3886 the CAVEATS on that feature before using it!)
3887
3888 These are in no particular order:
3889
3890 =head2 order_by
3891
3892 =over 4
3893
3894 =item Value: ( $order_by | \@order_by | \%order_by )
3895
3896 =back
3897
3898 Which column(s) to order the results by.
3899
3900 [The full list of suitable values is documented in
3901 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3902 common options.]
3903
3904 If a single column name, or an arrayref of names is supplied, the
3905 argument is passed through directly to SQL. The hashref syntax allows
3906 for connection-agnostic specification of ordering direction:
3907
3908  For descending order:
3909
3910   order_by => { -desc => [qw/col1 col2 col3/] }
3911
3912  For explicit ascending order:
3913
3914   order_by => { -asc => 'col' }
3915
3916 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3917 supported, although you are strongly encouraged to use the hashref
3918 syntax as outlined above.
3919
3920 =head2 columns
3921
3922 =over 4
3923
3924 =item Value: \@columns | \%columns | $column
3925
3926 =back
3927
3928 Shortcut to request a particular set of columns to be retrieved. Each
3929 column spec may be a string (a table column name), or a hash (in which
3930 case the key is the C<as> value, and the value is used as the C<select>
3931 expression). Adds C<me.> onto the start of any column without a C<.> in
3932 it and sets C<select> from that, then auto-populates C<as> from
3933 C<select> as normal. (You may also use the C<cols> attribute, as in
3934 earlier versions of DBIC, but this is deprecated)
3935
3936 Essentially C<columns> does the same as L</select> and L</as>.
3937
3938     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
3939
3940 is the same as
3941
3942     select => [qw(some_column another_column)],
3943     as     => [qw(some_column dbic_slot)]
3944
3945 If you want to individually retrieve related columns (in essence perform
3946 manual prefetch) you have to make sure to specify the correct inflation slot
3947 chain such that it matches existing relationships:
3948
3949     my $rs = $schema->resultset('Artist')->search({}, {
3950         # required to tell DBIC to collapse has_many relationships
3951         collapse => 1,
3952         join     => { cds => 'tracks'},
3953         '+columns'  => {
3954           'cds.cdid'         => 'cds.cdid',
3955           'cds.tracks.title' => 'tracks.title',
3956         },
3957     });
3958
3959 =head2 +columns
3960
3961 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
3962 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
3963 with a unary plus operator before it, which is the same as simply C<columns>.
3964
3965 =over 4
3966
3967 =item Value: \@extra_columns
3968
3969 =back
3970
3971 Indicates additional columns to be selected from storage. Works the same as
3972 L</columns> but adds columns to the current selection. (You may also use the
3973 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3974 deprecated)
3975
3976   $schema->resultset('CD')->search(undef, {
3977     '+columns' => ['artist.name'],
3978     join => ['artist']
3979   });
3980
3981 would return all CDs and include a 'name' column to the information
3982 passed to object inflation. Note that the 'artist' is the name of the
3983 column (or relationship) accessor, and 'name' is the name of the column
3984 accessor in the related table.
3985
3986 =head2 select
3987
3988 =over 4
3989
3990 =item Value: \@select_columns
3991
3992 =back
3993
3994 Indicates which columns should be selected from the storage. You can use
3995 column names, or in the case of RDBMS back ends, function or stored procedure
3996 names:
3997
3998   $rs = $schema->resultset('Employee')->search(undef, {
3999     select => [
4000       'name',
4001       { count => 'employeeid' },
4002       { max => { length => 'name' }, -as => 'longest_name' }
4003     ]
4004   });
4005
4006   # Equivalent SQL
4007   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4008
4009 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4010 use L</select>, to instruct DBIx::Class how to store the result of the column.
4011 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4012 identifier aliasing. You can however alias a function, so you can use it in
4013 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4014 attribute> supplied as shown in the example above.
4015
4016 =head2 +select
4017
4018 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4019 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4020 with a unary plus operator before it, which is the same as simply C<select>.
4021
4022 =over 4
4023
4024 =item Value: \@extra_select_columns
4025
4026 =back
4027
4028 Indicates additional columns to be selected from storage.  Works the same as
4029 L</select> but adds columns to the current selection, instead of specifying
4030 a new explicit list.
4031
4032 =head2 as
4033
4034 =over 4
4035
4036 =item Value: \@inflation_names
4037
4038 =back
4039
4040 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4041 slot name in which the column value will be stored within the
4042 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4043 identifier by the C<get_column> method (or via the object accessor B<if one
4044 with the same name already exists>) as shown below. The L</as> attribute has
4045 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4046
4047   $rs = $schema->resultset('Employee')->search(undef, {
4048     select => [
4049       'name',
4050       { count => 'employeeid' },
4051       { max => { length => 'name' }, -as => 'longest_name' }
4052     ],
4053     as => [qw/
4054       name
4055       employee_count
4056       max_name_length
4057     /],
4058   });
4059
4060 If the object against which the search is performed already has an accessor
4061 matching a column name specified in C<as>, the value can be retrieved using
4062 the accessor as normal:
4063
4064   my $name = $employee->name();
4065
4066 If on the other hand an accessor does not exist in the object, you need to
4067 use C<get_column> instead:
4068
4069   my $employee_count = $employee->get_column('employee_count');
4070
4071 You can create your own accessors if required - see
4072 L<DBIx::Class::Manual::Cookbook> for details.
4073
4074 =head2 +as
4075
4076 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4077 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4078 with a unary plus operator before it, which is the same as simply C<as>.
4079
4080 =over 4
4081
4082 =item Value: \@extra_inflation_names
4083
4084 =back
4085
4086 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4087
4088 =head2 join
4089
4090 =over 4
4091
4092 =item Value: ($rel_name | \@rel_names | \%rel_names)
4093
4094 =back
4095
4096 Contains a list of relationships that should be joined for this query.  For
4097 example:
4098
4099   # Get CDs by Nine Inch Nails
4100   my $rs = $schema->resultset('CD')->search(
4101     { 'artist.name' => 'Nine Inch Nails' },
4102     { join => 'artist' }
4103   );
4104
4105 Can also contain a hash reference to refer to the other relation's relations.
4106 For example:
4107
4108   package MyApp::Schema::Track;
4109   use base qw/DBIx::Class/;
4110   __PACKAGE__->table('track');
4111   __PACKAGE__->add_columns(qw/trackid cd position title/);
4112   __PACKAGE__->set_primary_key('trackid');
4113   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4114   1;
4115
4116   # In your application
4117   my $rs = $schema->resultset('Artist')->search(
4118     { 'track.title' => 'Teardrop' },
4119     {
4120       join     => { cd => 'track' },
4121       order_by => 'artist.name',
4122     }
4123   );
4124
4125 You need to use the relationship (not the table) name in  conditions,
4126 because they are aliased as such. The current table is aliased as "me", so
4127 you need to use me.column_name in order to avoid ambiguity. For example:
4128
4129   # Get CDs from 1984 with a 'Foo' track
4130   my $rs = $schema->resultset('CD')->search(
4131     {
4132       'me.year' => 1984,
4133       'tracks.name' => 'Foo'
4134     },
4135     { join => 'tracks' }
4136   );
4137
4138 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4139 similarly for a third time). For e.g.
4140
4141   my $rs = $schema->resultset('Artist')->search({
4142     'cds.title'   => 'Down to Earth',
4143     'cds_2.title' => 'Popular',
4144   }, {
4145     join => [ qw/cds cds/ ],
4146   });
4147
4148 will return a set of all artists that have both a cd with title 'Down
4149 to Earth' and a cd with title 'Popular'.
4150
4151 If you want to fetch related objects from other tables as well, see L</prefetch>
4152 below.
4153
4154  NOTE: An internal join-chain pruner will discard certain joins while
4155  constructing the actual SQL query, as long as the joins in question do not
4156  affect the retrieved result. This for example includes 1:1 left joins
4157  that are not part of the restriction specification (WHERE/HAVING) nor are
4158  a part of the query selection.
4159
4160 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4161
4162 =head2 collapse
4163
4164 =over 4
4165
4166 =item Value: (0 | 1)
4167
4168 =back
4169
4170 When set to a true value, indicates that any rows fetched from joined has_many
4171 relationships are to be aggregated into the corresponding "parent" object. For
4172 example, the resultset:
4173
4174   my $rs = $schema->resultset('CD')->search({}, {
4175     '+columns' => [ qw/ tracks.title tracks.position / ],
4176     join => 'tracks',
4177     collapse => 1,
4178   });
4179
4180 While executing the following query:
4181
4182   SELECT me.*, tracks.title, tracks.position
4183     FROM cd me
4184     LEFT JOIN track tracks
4185       ON tracks.cdid = me.cdid
4186
4187 Will return only as many objects as there are rows in the CD source, even
4188 though the result of the query may span many rows. Each of these CD objects
4189 will in turn have multiple "Track" objects hidden behind the has_many
4190 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4191 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4192 product"), with each CD object containing exactly one of all fetched Track data.
4193
4194 When a collapse is requested on a non-ordered resultset, an order by some
4195 unique part of the main source (the left-most table) is inserted automatically.
4196 This is done so that the resultset is allowed to be "lazy" - calling
4197 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4198 object with all of its related data.
4199
4200 If an L</order_by> is already declared, and orders the resultset in a way that
4201 makes collapsing as described above impossible (e.g. C<< ORDER BY
4202 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4203 switch to "eager" mode and slurp the entire resultset before constructing the
4204 first object returned by L</next>.
4205
4206 Setting this attribute on a resultset that does not join any has_many
4207 relations is a no-op.
4208
4209 For a more in-depth discussion, see L</PREFETCHING>.
4210
4211 =head2 prefetch
4212
4213 =over 4
4214
4215 =item Value: ($rel_name | \@rel_names | \%rel_names)
4216
4217 =back
4218
4219 This attribute is a shorthand for specifying a L</join> spec, adding all
4220 columns from the joined related sources as L</+columns> and setting
4221 L</collapse> to a true value. For example, the following two queries are
4222 equivalent:
4223
4224   my $rs = $schema->resultset('Artist')->search({}, {
4225     prefetch => { cds => ['genre', 'tracks' ] },
4226   });
4227
4228 and
4229
4230   my $rs = $schema->resultset('Artist')->search({}, {
4231     join => { cds => ['genre', 'tracks' ] },
4232     collapse => 1,
4233     '+columns' => [
4234       (map
4235         { +{ "cds.$_" => "cds.$_" } }
4236         $schema->source('Artist')->related_source('cds')->columns
4237       ),
4238       (map
4239         { +{ "cds.genre.$_" => "genre.$_" } }
4240         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4241       ),
4242       (map
4243         { +{ "cds.tracks.$_" => "tracks.$_" } }
4244         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4245       ),
4246     ],
4247   });
4248
4249 Both producing the following SQL:
4250
4251   SELECT  me.artistid, me.name, me.rank, me.charfield,
4252           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4253           genre.genreid, genre.name,
4254           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4255     FROM artist me
4256     LEFT JOIN cd cds
4257       ON cds.artist = me.artistid
4258     LEFT JOIN genre genre
4259       ON genre.genreid = cds.genreid
4260     LEFT JOIN track tracks
4261       ON tracks.cd = cds.cdid
4262   ORDER BY me.artistid
4263
4264 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4265 the arguments are properly merged and generally do the right thing. For
4266 example, you may want to do the following:
4267
4268   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4269     { 'genre.genreid' => undef },
4270     {
4271       join => { cds => 'genre' },
4272       prefetch => 'cds',
4273     }
4274   );
4275
4276 Which generates the following SQL:
4277
4278   SELECT  me.artistid, me.name, me.rank, me.charfield,
4279           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4280     FROM artist me
4281     LEFT JOIN cd cds
4282       ON cds.artist = me.artistid
4283     LEFT JOIN genre genre
4284       ON genre.genreid = cds.genreid
4285   WHERE genre.genreid IS NULL
4286   ORDER BY me.artistid
4287
4288 For a more in-depth discussion, see L</PREFETCHING>.
4289
4290 =head2 alias
4291
4292 =over 4
4293
4294 =item Value: $source_alias
4295
4296 =back
4297
4298 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4299 nested search queries (sub-SELECTs) might need specific aliases set to
4300 reference inner queries.  For example:
4301
4302    my $q = $rs
4303       ->related_resultset('CDs')
4304       ->related_resultset('Tracks')
4305       ->search({
4306          'track.id' => { -ident => 'none_search.id' },
4307       })
4308       ->as_query;
4309
4310    my $ids = $self->search({
4311       -not_exists => $q,
4312    }, {
4313       alias    => 'none_search',
4314       group_by => 'none_search.id',
4315    })->get_column('id')->as_query;
4316
4317    $self->search({ id => { -in => $ids } })
4318
4319 This attribute is directly tied to L</current_source_alias>.
4320
4321 =head2 page
4322
4323 =over 4
4324
4325 =item Value: $page
4326
4327 =back
4328
4329 Makes the resultset paged and specifies the page to retrieve. Effectively
4330 identical to creating a non-pages resultset and then calling ->page($page)
4331 on it.
4332
4333 If L</rows> attribute is not specified it defaults to 10 rows per page.
4334
4335 When you have a paged resultset, L</count> will only return the number
4336 of rows in the page. To get the total, use the L</pager> and call
4337 C<total_entries> on it.
4338
4339 =head2 rows
4340
4341 =over 4
4342
4343 =item Value: $rows
4344
4345 =back
4346
4347 Specifies the maximum number of rows for direct retrieval or the number of
4348 rows per page if the page attribute or method is used.
4349
4350 =head2 offset
4351
4352 =over 4
4353
4354 =item Value: $offset
4355
4356 =back
4357
4358 Specifies the (zero-based) row number for the  first row to be returned, or the
4359 of the first row of the first page if paging is used.
4360
4361 =head2 software_limit
4362
4363 =over 4
4364
4365 =item Value: (0 | 1)
4366
4367 =back
4368
4369 When combined with L</rows> and/or L</offset> the generated SQL will not
4370 include any limit dialect stanzas. Instead the entire result will be selected
4371 as if no limits were specified, and DBIC will perform the limit locally, by
4372 artificially advancing and finishing the resulting L</cursor>.
4373
4374 This is the recommended way of performing resultset limiting when no sane RDBMS
4375 implementation is available (e.g.
4376 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4377 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4378
4379 =head2 group_by
4380
4381 =over 4
4382
4383 =item Value: \@columns
4384
4385 =back
4386
4387 A arrayref of columns to group by. Can include columns of joined tables.
4388
4389   group_by => [qw/ column1 column2 ... /]
4390
4391 =head2 having
4392
4393 =over 4
4394
4395 =item Value: $condition
4396
4397 =back
4398
4399 HAVING is a select statement attribute that is applied between GROUP BY and
4400 ORDER BY. It is applied to the after the grouping calculations have been
4401 done.
4402
4403   having => { 'count_employee' => { '>=', 100 } }
4404
4405 or with an in-place function in which case literal SQL is required:
4406
4407   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4408
4409 =head2 distinct
4410
4411 =over 4
4412
4413 =item Value: (0 | 1)
4414
4415 =back
4416
4417 Set to 1 to automatically generate a L</group_by> clause based on the selection
4418 (including intelligent handling of L</order_by> contents). Note that the group
4419 criteria calculation takes place over the B<final> selection. This includes
4420 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4421 L</search> calls, and standalone columns selected via
4422 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4423 extra selections specified via L</prefetch> - such selections are explicitly
4424 excluded from group criteria calculations.
4425
4426 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4427 setting is ignored and an appropriate warning is issued.
4428
4429 =head2 where
4430
4431 =over 4
4432
4433 Adds to the WHERE clause.
4434
4435   # only return rows WHERE deleted IS NULL for all searches
4436   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4437
4438 Can be overridden by passing C<< { where => undef } >> as an attribute
4439 to a resultset.
4440
4441 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4442
4443 =back
4444
4445 =head2 cache
4446
4447 Set to 1 to cache search results. This prevents extra SQL queries if you
4448 revisit rows in your ResultSet:
4449
4450   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4451
4452   while( my $artist = $resultset->next ) {
4453     ... do stuff ...
4454   }
4455
4456   $rs->first; # without cache, this would issue a query
4457
4458 By default, searches are not cached.
4459
4460 For more examples of using these attributes, see
4461 L<DBIx::Class::Manual::Cookbook>.
4462
4463 =head2 for
4464
4465 =over 4
4466
4467 =item Value: ( 'update' | 'shared' | \$scalar )
4468
4469 =back
4470
4471 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4472 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4473 query.
4474
4475 =head1 PREFETCHING
4476
4477 DBIx::Class supports arbitrary related data prefetching from multiple related
4478 sources. Any combination of relationship types and column sets are supported.
4479 If L<collapsing|/collapse> is requested, there is an additional requirement of
4480 selecting enough data to make every individual object uniquely identifiable.
4481
4482 Here are some more involved examples, based on the following relationship map:
4483
4484   # Assuming:
4485   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4486   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4487   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4488
4489   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4490
4491   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4492
4493
4494
4495   my $rs = $schema->resultset('Tag')->search(
4496     undef,
4497     {
4498       prefetch => {
4499         cd => 'artist'
4500       }
4501     }
4502   );
4503
4504 The initial search results in SQL like the following:
4505
4506   SELECT tag.*, cd.*, artist.* FROM tag
4507   JOIN cd ON tag.cd = cd.cdid
4508   JOIN artist ON cd.artist = artist.artistid
4509
4510 L<DBIx::Class> has no need to go back to the database when we access the
4511 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4512 case.
4513
4514 Simple prefetches will be joined automatically, so there is no need
4515 for a C<join> attribute in the above search.
4516
4517 The L</prefetch> attribute can be used with any of the relationship types
4518 and multiple prefetches can be specified together. Below is a more complex
4519 example that prefetches a CD's artist, its liner notes (if present),
4520 the cover image, the tracks on that CD, and the guests on those
4521 tracks.
4522
4523   my $rs = $schema->resultset('CD')->search(
4524     undef,
4525     {
4526       prefetch => [
4527         { artist => 'record_label'},  # belongs_to => belongs_to
4528         'liner_note',                 # might_have
4529         'cover_image',                # has_one
4530         { tracks => 'guests' },       # has_many => has_many
4531       ]
4532     }
4533   );
4534
4535 This will produce SQL like the following:
4536
4537   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4538          tracks.*, guests.*
4539     FROM cd me
4540     JOIN artist artist
4541       ON artist.artistid = me.artistid
4542     JOIN record_label record_label
4543       ON record_label.labelid = artist.labelid
4544     LEFT JOIN track tracks
4545       ON tracks.cdid = me.cdid
4546     LEFT JOIN guest guests
4547       ON guests.trackid = track.trackid
4548     LEFT JOIN liner_notes liner_note
4549       ON liner_note.cdid = me.cdid
4550     JOIN cd_artwork cover_image
4551       ON cover_image.cdid = me.cdid
4552   ORDER BY tracks.cd
4553
4554 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4555 C<tracks>, and C<guests> of the CD will all be available through the
4556 relationship accessors without the need for additional queries to the
4557 database.
4558
4559 =head3 CAVEATS
4560
4561 Prefetch does a lot of deep magic. As such, it may not behave exactly
4562 as you might expect.
4563
4564 =over 4
4565
4566 =item *
4567
4568 Prefetch uses the L</cache> to populate the prefetched relationships. This
4569 may or may not be what you want.
4570
4571 =item *
4572
4573 If you specify a condition on a prefetched relationship, ONLY those
4574 rows that match the prefetched condition will be fetched into that relationship.
4575 This means that adding prefetch to a search() B<may alter> what is returned by
4576 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4577
4578   my $artist_rs = $schema->resultset('Artist')->search({
4579       'cds.year' => 2008,
4580   }, {
4581       join => 'cds',
4582   });
4583
4584   my $count = $artist_rs->first->cds->count;
4585
4586   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4587
4588   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4589
4590   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4591
4592 That cmp_ok() may or may not pass depending on the datasets involved. In other
4593 words the C<WHERE> condition would apply to the entire dataset, just like
4594 it would in regular SQL. If you want to add a condition only to the "right side"
4595 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4596 condition|DBIx::Class::Relationship::Base/condition>
4597
4598 =back
4599
4600 =head1 DBIC BIND VALUES
4601
4602 Because DBIC may need more information to bind values than just the column name
4603 and value itself, it uses a special format for both passing and receiving bind
4604 values.  Each bind value should be composed of an arrayref of
4605 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4606
4607 =over 4
4608
4609 =item dbd_attrs
4610
4611 If present (in any form), this is what is being passed directly to bind_param.
4612 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4613 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4614
4615 If this is specified, all other bind options described below are ignored.
4616
4617 =item sqlt_datatype
4618
4619 If present, this is used to infer the actual bind attribute by passing to
4620 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4621 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4622
4623 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4624 currently drivers are expected to "Do the Right Thing" when given a common
4625 datatype name.  (Not ideal, but that's what we got at this point.)
4626
4627 =item sqlt_size
4628
4629 Currently used to correctly allocate buffers for bind_param_inout().
4630 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4631 or to a sensible value based on the "data_type".
4632
4633 =item dbic_colname
4634
4635 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4636 explicitly specified they are never overridden).  Also used by some weird DBDs,
4637 where the column name should be available at bind_param time (e.g. Oracle).
4638
4639 =back
4640
4641 For backwards compatibility and convenience, the following shortcuts are
4642 supported:
4643
4644   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4645   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4646   [ undef,   $val ] === [ {}, $val ]
4647   $val              === [ {}, $val ]
4648
4649 =head1 AUTHOR AND CONTRIBUTORS
4650
4651 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4652
4653 =head1 LICENSE
4654
4655 You may distribute this code under the same terms as Perl itself.
4656