lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  77
  78 If you want to make your custom ResultSet classes with L<Moose>, use a template
  79 similar to:
  80
  81     package MyApp::Schema::ResultSet::User;
  82
  83     use Moose;
  84     use namespace::autoclean;
  85     use MooseX::NonMoose;
  86     extends 'DBIx::Class::ResultSet';
  87
  88     sub BUILDARGS { $_[2] }
  89
  90     ...your code...
  91
  92     __PACKAGE__->meta->make_immutable;
  93
  94     1;
  95
  96 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  97 clash with the regular ResultSet constructor. Alternatively, you can use:
  98
  99     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 100
 101 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 102 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 103
 104 =head1 EXAMPLES
 105
 106 =head2 Chaining resultsets
 107
 108 Let's say you've got a query that needs to be run to return some data
 109 to the user. But, you have an authorization system in place that
 110 prevents certain users from seeing certain information. So, you want
 111 to construct the basic query in one method, but add constraints to it in
 112 another.
 113
 114   sub get_data {
 115     my $self = shift;
 116     my $request = $self->get_request; # Get a request object somehow.
 117     my $schema = $self->result_source->schema;
 118
 119     my $cd_rs = $schema->resultset('CD')->search({
 120       title => $request->param('title'),
 121       year => $request->param('year'),
 122     });
 123
 124     $cd_rs = $self->apply_security_policy( $cd_rs );
 125
 126     return $cd_rs->all();
 127   }
 128
 129   sub apply_security_policy {
 130     my $self = shift;
 131     my ($rs) = @_;
 132
 133     return $rs->search({
 134       subversive => 0,
 135     });
 136   }
 137
 138 =head3 Resolving conditions and attributes
 139
 140 When a resultset is chained from another resultset (ie:
 141 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 142 and attributes with the same keys need resolving.
 143
 144 If any of L</columns>, L</select>, L</as> are present, they reset the
 145 original selection, and start the selection "clean".
 146
 147 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 148 are merged into the existing ones from the original resultset.
 149
 150 The L</where> and L</having> attributes, and any search conditions, are
 151 merged with an SQL C<AND> to the existing condition from the original
 152 resultset.
 153
 154 All other attributes are overridden by any new ones supplied in the
 155 search attributes.
 156
 157 =head2 Multiple queries
 158
 159 Since a resultset just defines a query, you can do all sorts of
 160 things with it with the same object.
 161
 162   # Don't hit the DB yet.
 163   my $cd_rs = $schema->resultset('CD')->search({
 164     title => 'something',
 165     year => 2009,
 166   });
 167
 168   # Each of these hits the DB individually.
 169   my $count = $cd_rs->count;
 170   my $most_recent = $cd_rs->get_column('date_released')->max();
 171   my @records = $cd_rs->all;
 172
 173 And it's not just limited to SELECT statements.
 174
 175   $cd_rs->delete();
 176
 177 This is even cooler:
 178
 179   $cd_rs->create({ artist => 'Fred' });
 180
 181 Which is the same as:
 182
 183   $schema->resultset('CD')->create({
 184     title => 'something',
 185     year => 2009,
 186     artist => 'Fred'
 187   });
 188
 189 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 190
 191 =head1 METHODS
 192
 193 =head2 new
 194
 195 =over 4
 196
 197 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 198
 199 =item Return Value: L<$resultset|/search>
 200
 201 =back
 202
 203 The resultset constructor. Takes a source object (usually a
 204 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 205 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 206 executed as needed by the other methods.
 207
 208 Generally you never construct a resultset manually. Instead you get one
 209 from e.g. a
 210 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 211 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 212 scalar context):
 213
 214   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 215
 216 =over
 217
 218 =item WARNING
 219
 220 If called on an object, proxies to L</new_result> instead, so
 221
 222   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 223
 224 will return a CD object, not a ResultSet, and is equivalent to:
 225
 226   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 227
 228 Please also keep in mind that many internals call L</new_result> directly,
 229 so overloading this method with the idea of intercepting new result object
 230 creation B<will not work>. See also warning pertaining to L</create>.
 231
 232 =back
 233
 234 =cut
 235
 236 sub new {
 237   my $class = shift;
 238   return $class->new_result(@_) if ref $class;
 239
 240   my ($source, $attrs) = @_;
 241   $source = $source->resolve
 242     if $source->isa('DBIx::Class::ResultSourceHandle');
 243   $attrs = { %{$attrs||{}} };
 244
 245   if ($attrs->{page}) {
 246     $attrs->{rows} ||= 10;
 247   }
 248
 249   $attrs->{alias} ||= 'me';
 250
 251   my $self = bless {
 252     result_source => $source,
 253     cond => $attrs->{where},
 254     pager => undef,
 255     attrs => $attrs,
 256   }, $class;
 257
 258   # if there is a dark selector, this means we are already in a
 259   # chain and the cleanup/sanification was taken care of by
 260   # _search_rs already
 261   $self->_normalize_selection($attrs)
 262     unless $attrs->{_dark_selector};
 263
 264   $self->result_class(
 265     $attrs->{result_class} || $source->result_class
 266   );
 267
 268   $self;
 269 }
 270
 271 =head2 search
 272
 273 =over 4
 274
 275 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 276
 277 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 278
 279 =back
 280
 281   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 282   my $new_rs = $cd_rs->search({ year => 2005 });
 283
 284   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 285                  # year = 2005 OR year = 2004
 286
 287 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 288 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 289 To avoid that, use L</search_rs>.
 290
 291 If you need to pass in additional attributes but no additional condition,
 292 call it as C<search(undef, \%attrs)>.
 293
 294   # "SELECT name, artistid FROM $artist_table"
 295   my @all_artists = $schema->resultset('Artist')->search(undef, {
 296     columns => [qw/name artistid/],
 297   });
 298
 299 For a list of attributes that can be passed to C<search>, see
 300 L</ATTRIBUTES>. For more examples of using this function, see
 301 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 302 documentation for the first argument, see L<SQL::Abstract>
 303 and its extension L<DBIx::Class::SQLMaker>.
 304
 305 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 306
 307 =head3 CAVEAT
 308
 309 Note that L</search> does not process/deflate any of the values passed in the
 310 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 311 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 312 manually that any value passed to this method will stringify to something the
 313 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 314 objects, for more info see:
 315 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 316
 317 =cut
 318
 319 sub search {
 320   my $self = shift;
 321   my $rs = $self->search_rs( @_ );
 322
 323   if (wantarray) {
 324     return $rs->all;
 325   }
 326   elsif (defined wantarray) {
 327     return $rs;
 328   }
 329   else {
 330     # we can be called by a relationship helper, which in
 331     # turn may be called in void context due to some braindead
 332     # overload or whatever else the user decided to be clever
 333     # at this particular day. Thus limit the exception to
 334     # external code calls only
 335     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 336       if (caller)[0] !~ /^\QDBIx::Class::/;
 337
 338     return ();
 339   }
 340 }
 341
 342 =head2 search_rs
 343
 344 =over 4
 345
 346 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 347
 348 =item Return Value: L<$resultset|/search>
 349
 350 =back
 351
 352 This method does the same exact thing as search() except it will
 353 always return a resultset, even in list context.
 354
 355 =cut
 356
 357 sub search_rs {
 358   my $self = shift;
 359
 360   my $rsrc = $self->result_source;
 361   my ($call_cond, $call_attrs);
 362
 363   # Special-case handling for (undef, undef) or (undef)
 364   # Note that (foo => undef) is valid deprecated syntax
 365   @_ = () if not scalar grep { defined $_ } @_;
 366
 367   # just a cond
 368   if (@_ == 1) {
 369     $call_cond = shift;
 370   }
 371   # fish out attrs in the ($condref, $attr) case
 372   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 373     ($call_cond, $call_attrs) = @_;
 374   }
 375   elsif (@_ % 2) {
 376     $self->throw_exception('Odd number of arguments to search')
 377   }
 378   # legacy search
 379   elsif (@_) {
 380     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 381       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 382
 383     for my $i (0 .. $#_) {
 384       next if $i % 2;
 385       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 386         if (! defined $_[$i] or ref $_[$i] ne '');
 387     }
 388
 389     $call_cond = { @_ };
 390   }
 391
 392   # see if we can keep the cache (no $rs changes)
 393   my $cache;
 394   my %safe = (alias => 1, cache => 1);
 395   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 396     ! defined $_[0]
 397       or
 398     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 399       or
 400     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 401   )) {
 402     $cache = $self->get_cache;
 403   }
 404
 405   my $old_attrs = { %{$self->{attrs}} };
 406   my $old_having = delete $old_attrs->{having};
 407   my $old_where = delete $old_attrs->{where};
 408
 409   my $new_attrs = { %$old_attrs };
 410
 411   # take care of call attrs (only if anything is changing)
 412   if ($call_attrs and keys %$call_attrs) {
 413
 414     # copy for _normalize_selection
 415     $call_attrs = { %$call_attrs };
 416
 417     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 418
 419     # reset the current selector list if new selectors are supplied
 420     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 421       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 422     }
 423
 424     # Normalize the new selector list (operates on the passed-in attr structure)
 425     # Need to do it on every chain instead of only once on _resolved_attrs, in
 426     # order to allow detection of empty vs partial 'as'
 427     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 428       if $old_attrs->{_dark_selector};
 429     $self->_normalize_selection ($call_attrs);
 430
 431     # start with blind overwriting merge, exclude selector attrs
 432     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 433     delete @{$new_attrs}{@selector_attrs};
 434
 435     for (@selector_attrs) {
 436       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 437         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 438     }
 439
 440     # older deprecated name, use only if {columns} is not there
 441     if (my $c = delete $new_attrs->{cols}) {
 442       if ($new_attrs->{columns}) {
 443         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 444       }
 445       else {
 446         $new_attrs->{columns} = $c;
 447       }
 448     }
 449
 450
 451     # join/prefetch use their own crazy merging heuristics
 452     foreach my $key (qw/join prefetch/) {
 453       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 454         if exists $call_attrs->{$key};
 455     }
 456
 457     # stack binds together
 458     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 459   }
 460
 461
 462   for ($old_where, $call_cond) {
 463     if (defined $_) {
 464       $new_attrs->{where} = $self->_stack_cond (
 465         $_, $new_attrs->{where}
 466       );
 467     }
 468   }
 469
 470   if (defined $old_having) {
 471     $new_attrs->{having} = $self->_stack_cond (
 472       $old_having, $new_attrs->{having}
 473     )
 474   }
 475
 476   my $rs = (ref $self)->new($rsrc, $new_attrs);
 477
 478   $rs->set_cache($cache) if ($cache);
 479
 480   return $rs;
 481 }
 482
 483 my $dark_sel_dumper;
 484 sub _normalize_selection {
 485   my ($self, $attrs) = @_;
 486
 487   # legacy syntax
 488   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 489     if exists $attrs->{include_columns};
 490
 491   # columns are always placed first, however
 492
 493   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 494   # delay the decision on whether to use a default select list ($rsrc->columns)
 495   # allowing stuff like the remove_columns helper to work
 496   #
 497   # select/as +select/+as pairs need special handling - the amount of select/as
 498   # elements in each pair does *not* have to be equal (think multicolumn
 499   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 500   # supplied at all) - try to infer the alias, either from the -as parameter
 501   # of the selector spec, or use the parameter whole if it looks like a column
 502   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 503   # is ok as well), but make sure no more additions to the 'as' chain take place
 504   for my $pref ('', '+') {
 505
 506     my ($sel, $as) = map {
 507       my $key = "${pref}${_}";
 508
 509       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 510         ? @{$attrs->{$key}}
 511         : $attrs->{$key} || ()
 512       ];
 513       delete $attrs->{$key};
 514       $val;
 515     } qw/select as/;
 516
 517     if (! @$as and ! @$sel ) {
 518       next;
 519     }
 520     elsif (@$as and ! @$sel) {
 521       $self->throw_exception(
 522         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 523       );
 524     }
 525     elsif( ! @$as ) {
 526       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 527       # if any @$as has been supplied we assume the user knows what (s)he is doing
 528       # and blindly keep stacking up pieces
 529       unless ($attrs->{_dark_selector}) {
 530         SELECTOR:
 531         for (@$sel) {
 532           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 533             push @$as, $_->{-as};
 534           }
 535           # assume any plain no-space, no-parenthesis string to be a column spec
 536           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 537           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 538             push @$as, $_;
 539           }
 540           # if all else fails - raise a flag that no more aliasing will be allowed
 541           else {
 542             $attrs->{_dark_selector} = {
 543               plus_stage => $pref,
 544               string => ($dark_sel_dumper ||= do {
 545                   require Data::Dumper::Concise;
 546                   Data::Dumper::Concise::DumperObject()->Indent(0);
 547                 })->Values([$_])->Dump
 548               ,
 549             };
 550             last SELECTOR;
 551           }
 552         }
 553       }
 554     }
 555     elsif (@$as < @$sel) {
 556       $self->throw_exception(
 557         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 558       );
 559     }
 560     elsif ($pref and $attrs->{_dark_selector}) {
 561       $self->throw_exception(
 562         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 563       );
 564     }
 565
 566
 567     # merge result
 568     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 569     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 570   }
 571 }
 572
 573 sub _stack_cond {
 574   my ($self, $left, $right) = @_;
 575
 576   # collapse single element top-level conditions
 577   # (single pass only, unlikely to need recursion)
 578   for ($left, $right) {
 579     if (ref $_ eq 'ARRAY') {
 580       if (@$_ == 0) {
 581         $_ = undef;
 582       }
 583       elsif (@$_ == 1) {
 584         $_ = $_->[0];
 585       }
 586     }
 587     elsif (ref $_ eq 'HASH') {
 588       my ($first, $more) = keys %$_;
 589
 590       # empty hash
 591       if (! defined $first) {
 592         $_ = undef;
 593       }
 594       # one element hash
 595       elsif (! defined $more) {
 596         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 597           $_ = $_->{'-and'};
 598         }
 599         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 600           $_ = $_->{'-or'};
 601         }
 602       }
 603     }
 604   }
 605
 606   # merge hashes with weeding out of duplicates (simple cases only)
 607   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 608
 609     # shallow copy to destroy
 610     $right = { %$right };
 611     for (grep { exists $right->{$_} } keys %$left) {
 612       # the use of eq_deeply here is justified - the rhs of an
 613       # expression can contain a lot of twisted weird stuff
 614       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 615     }
 616
 617     $right = undef unless keys %$right;
 618   }
 619
 620
 621   if (defined $left xor defined $right) {
 622     return defined $left ? $left : $right;
 623   }
 624   elsif (! defined $left) {
 625     return undef;
 626   }
 627   else {
 628     return { -and => [ $left, $right ] };
 629   }
 630 }
 631
 632 =head2 search_literal
 633
 634 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 635 should only be used in that context. C<search_literal> is a convenience
 636 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 637 want to ensure columns are bound correctly, use L</search>.
 638
 639 See L<DBIx::Class::Manual::Cookbook/Searching> and
 640 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 641 require C<search_literal>.
 642
 643 =over 4
 644
 645 =item Arguments: $sql_fragment, @standalone_bind_values
 646
 647 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 648
 649 =back
 650
 651   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 652   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 653
 654 Pass a literal chunk of SQL to be added to the conditional part of the
 655 resultset query.
 656
 657 Example of how to use C<search> instead of C<search_literal>
 658
 659   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 660   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 661
 662 =cut
 663
 664 sub search_literal {
 665   my ($self, $sql, @bind) = @_;
 666   my $attr;
 667   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 668     $attr = pop @bind;
 669   }
 670   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 671 }
 672
 673 =head2 find
 674
 675 =over 4
 676
 677 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 678
 679 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 680
 681 =back
 682
 683 Finds and returns a single row based on supplied criteria. Takes either a
 684 hashref with the same format as L</create> (including inference of foreign
 685 keys from related objects), or a list of primary key values in the same
 686 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 687 declaration on the L</result_source>.
 688
 689 In either case an attempt is made to combine conditions already existing on
 690 the resultset with the condition passed to this method.
 691
 692 To aid with preparing the correct query for the storage you may supply the
 693 C<key> attribute, which is the name of a
 694 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 695 unique constraint corresponding to the
 696 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 697 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 698 to construct a query that satisfies the named unique constraint fully (
 699 non-NULL values for each column member of the constraint) an exception is
 700 thrown.
 701
 702 If no C<key> is specified, the search is carried over all unique constraints
 703 which are fully defined by the available condition.
 704
 705 If no such constraint is found, C<find> currently defaults to a simple
 706 C<< search->(\%column_values) >> which may or may not do what you expect.
 707 Note that this fallback behavior may be deprecated in further versions. If
 708 you need to search with arbitrary conditions - use L</search>. If the query
 709 resulting from this fallback produces more than one row, a warning to the
 710 effect is issued, though only the first row is constructed and returned as
 711 C<$result_object>.
 712
 713 In addition to C<key>, L</find> recognizes and applies standard
 714 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 715
 716 Note that if you have extra concerns about the correctness of the resulting
 717 query you need to specify the C<key> attribute and supply the entire condition
 718 as an argument to find (since it is not always possible to perform the
 719 combination of the resultset condition with the supplied one, especially if
 720 the resultset condition contains literal sql).
 721
 722 For example, to find a row by its primary key:
 723
 724   my $cd = $schema->resultset('CD')->find(5);
 725
 726 You can also find a row by a specific unique constraint:
 727
 728   my $cd = $schema->resultset('CD')->find(
 729     {
 730       artist => 'Massive Attack',
 731       title  => 'Mezzanine',
 732     },
 733     { key => 'cd_artist_title' }
 734   );
 735
 736 See also L</find_or_create> and L</update_or_create>.
 737
 738 =cut
 739
 740 sub find {
 741   my $self = shift;
 742   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 743
 744   my $rsrc = $self->result_source;
 745
 746   my $constraint_name;
 747   if (exists $attrs->{key}) {
 748     $constraint_name = defined $attrs->{key}
 749       ? $attrs->{key}
 750       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 751     ;
 752   }
 753
 754   # Parse out the condition from input
 755   my $call_cond;
 756
 757   if (ref $_[0] eq 'HASH') {
 758     $call_cond = { %{$_[0]} };
 759   }
 760   else {
 761     # if only values are supplied we need to default to 'primary'
 762     $constraint_name = 'primary' unless defined $constraint_name;
 763
 764     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 765
 766     $self->throw_exception(
 767       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 768     ) unless @c_cols;
 769
 770     $self->throw_exception (
 771       'find() expects either a column/value hashref, or a list of values '
 772     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 773     ) unless @c_cols == @_;
 774
 775     $call_cond = {};
 776     @{$call_cond}{@c_cols} = @_;
 777   }
 778
 779   my %related;
 780   for my $key (keys %$call_cond) {
 781     if (
 782       my $keyref = ref($call_cond->{$key})
 783         and
 784       my $relinfo = $rsrc->relationship_info($key)
 785     ) {
 786       my $val = delete $call_cond->{$key};
 787
 788       next if $keyref eq 'ARRAY'; # has_many for multi_create
 789
 790       my $rel_q = $rsrc->_resolve_condition(
 791         $relinfo->{cond}, $val, $key, $key
 792       );
 793       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 794       @related{keys %$rel_q} = values %$rel_q;
 795     }
 796   }
 797
 798   # relationship conditions take precedence (?)
 799   @{$call_cond}{keys %related} = values %related;
 800
 801   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 802   my $final_cond;
 803   if (defined $constraint_name) {
 804     $final_cond = $self->_qualify_cond_columns (
 805
 806       $self->_build_unique_cond (
 807         $constraint_name,
 808         $call_cond,
 809       ),
 810
 811       $alias,
 812     );
 813   }
 814   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 815     # This means that we got here after a merger of relationship conditions
 816     # in ::Relationship::Base::search_related (the row method), and furthermore
 817     # the relationship is of the 'single' type. This means that the condition
 818     # provided by the relationship (already attached to $self) is sufficient,
 819     # as there can be only one row in the database that would satisfy the
 820     # relationship
 821   }
 822   else {
 823     # no key was specified - fall down to heuristics mode:
 824     # run through all unique queries registered on the resultset, and
 825     # 'OR' all qualifying queries together
 826     my (@unique_queries, %seen_column_combinations);
 827     for my $c_name ($rsrc->unique_constraint_names) {
 828       next if $seen_column_combinations{
 829         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 830       }++;
 831
 832       push @unique_queries, try {
 833         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 834       } || ();
 835     }
 836
 837     $final_cond = @unique_queries
 838       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 839       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 840     ;
 841   }
 842
 843   # Run the query, passing the result_class since it should propagate for find
 844   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 845   if ($rs->_resolved_attrs->{collapse}) {
 846     my $row = $rs->next;
 847     carp "Query returned more than one row" if $rs->next;
 848     return $row;
 849   }
 850   else {
 851     return $rs->single;
 852   }
 853 }
 854
 855 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 856 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 857 #
 858 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 859 # condition. It is provided for overrides until a saner way forward is devised
 860 #
 861 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 862 # the road. Please adjust your tests accordingly to catch this situation early
 863 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 864 #
 865 # The method will not be removed without an adequately complete replacement
 866 # for strict-mode enforcement
 867 sub _non_unique_find_fallback {
 868   my ($self, $cond, $attrs) = @_;
 869
 870   return $self->_qualify_cond_columns(
 871     $cond,
 872     exists $attrs->{alias}
 873       ? $attrs->{alias}
 874       : $self->{attrs}{alias}
 875   );
 876 }
 877
 878
 879 sub _qualify_cond_columns {
 880   my ($self, $cond, $alias) = @_;
 881
 882   my %aliased = %$cond;
 883   for (keys %aliased) {
 884     $aliased{"$alias.$_"} = delete $aliased{$_}
 885       if $_ !~ /\./;
 886   }
 887
 888   return \%aliased;
 889 }
 890
 891 sub _build_unique_cond {
 892   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 893
 894   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 895
 896   # combination may fail if $self->{cond} is non-trivial
 897   my ($final_cond) = try {
 898     $self->_merge_with_rscond ($extra_cond)
 899   } catch {
 900     +{ %$extra_cond }
 901   };
 902
 903   # trim out everything not in $columns
 904   $final_cond = { map {
 905     exists $final_cond->{$_}
 906       ? ( $_ => $final_cond->{$_} )
 907       : ()
 908   } @c_cols };
 909
 910   if (my @missing = grep
 911     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 912     (@c_cols)
 913   ) {
 914     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 915       $constraint_name,
 916       join (', ', map { "'$_'" } @missing),
 917     ) );
 918   }
 919
 920   if (
 921     !$croak_on_null
 922       and
 923     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 924       and
 925     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 926   ) {
 927     carp_unique ( sprintf (
 928       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 929     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 930     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 931       $constraint_name,
 932       join (', ', map { "'$_'" } @undefs),
 933     ));
 934   }
 935
 936   return $final_cond;
 937 }
 938
 939 =head2 search_related
 940
 941 =over 4
 942
 943 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 944
 945 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 946
 947 =back
 948
 949   $new_rs = $cd_rs->search_related('artist', {
 950     name => 'Emo-R-Us',
 951   });
 952
 953 Searches the specified relationship, optionally specifying a condition and
 954 attributes for matching records. See L</ATTRIBUTES> for more information.
 955
 956 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 957 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 958
 959 See also L</search_related_rs>.
 960
 961 =cut
 962
 963 sub search_related {
 964   return shift->related_resultset(shift)->search(@_);
 965 }
 966
 967 =head2 search_related_rs
 968
 969 This method works exactly the same as search_related, except that
 970 it guarantees a resultset, even in list context.
 971
 972 =cut
 973
 974 sub search_related_rs {
 975   return shift->related_resultset(shift)->search_rs(@_);
 976 }
 977
 978 =head2 cursor
 979
 980 =over 4
 981
 982 =item Arguments: none
 983
 984 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 985
 986 =back
 987
 988 Returns a storage-driven cursor to the given resultset. See
 989 L<DBIx::Class::Cursor> for more information.
 990
 991 =cut
 992
 993 sub cursor {
 994   my $self = shift;
 995
 996   return $self->{cursor} ||= do {
 997     my $attrs = { %{$self->_resolved_attrs } };
 998     $self->result_source->storage->select(
 999       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1000     );
1001   };
1002 }
1003
1004 =head2 single
1005
1006 =over 4
1007
1008 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1009
1010 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1011
1012 =back
1013
1014   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1015
1016 Inflates the first result without creating a cursor if the resultset has
1017 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1018 of L</search>.
1019
1020 While this method can take an optional search condition (just like L</search>)
1021 being a fast-code-path it does not recognize search attributes. If you need to
1022 add extra joins or similar, call L</search> and then chain-call L</single> on the
1023 L<DBIx::Class::ResultSet> returned.
1024
1025 =over
1026
1027 =item B<Note>
1028
1029 As of 0.08100, this method enforces the assumption that the preceding
1030 query returns only one row. If more than one row is returned, you will receive
1031 a warning:
1032
1033   Query returned more than one row
1034
1035 In this case, you should be using L</next> or L</find> instead, or if you really
1036 know what you are doing, use the L</rows> attribute to explicitly limit the size
1037 of the resultset.
1038
1039 This method will also throw an exception if it is called on a resultset prefetching
1040 has_many, as such a prefetch implies fetching multiple rows from the database in
1041 order to assemble the resulting object.
1042
1043 =back
1044
1045 =cut
1046
1047 sub single {
1048   my ($self, $where) = @_;
1049   if(@_ > 2) {
1050       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1051   }
1052
1053   my $attrs = { %{$self->_resolved_attrs} };
1054
1055   $self->throw_exception(
1056     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1057   ) if $attrs->{collapse};
1058
1059   if ($where) {
1060     if (defined $attrs->{where}) {
1061       $attrs->{where} = {
1062         '-and' =>
1063             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1064                $where, delete $attrs->{where} ]
1065       };
1066     } else {
1067       $attrs->{where} = $where;
1068     }
1069   }
1070
1071   my $data = [ $self->result_source->storage->select_single(
1072     $attrs->{from}, $attrs->{select},
1073     $attrs->{where}, $attrs
1074   )];
1075   return undef unless @$data;
1076   $self->{stashed_rows} = [ $data ];
1077   $self->_construct_objects->[0];
1078 }
1079
1080
1081 # _collapse_query
1082 #
1083 # Recursively collapse the query, accumulating values for each column.
1084
1085 sub _collapse_query {
1086   my ($self, $query, $collapsed) = @_;
1087
1088   $collapsed ||= {};
1089
1090   if (ref $query eq 'ARRAY') {
1091     foreach my $subquery (@$query) {
1092       next unless ref $subquery;  # -or
1093       $collapsed = $self->_collapse_query($subquery, $collapsed);
1094     }
1095   }
1096   elsif (ref $query eq 'HASH') {
1097     if (keys %$query and (keys %$query)[0] eq '-and') {
1098       foreach my $subquery (@{$query->{-and}}) {
1099         $collapsed = $self->_collapse_query($subquery, $collapsed);
1100       }
1101     }
1102     else {
1103       foreach my $col (keys %$query) {
1104         my $value = $query->{$col};
1105         $collapsed->{$col}{$value}++;
1106       }
1107     }
1108   }
1109
1110   return $collapsed;
1111 }
1112
1113 =head2 get_column
1114
1115 =over 4
1116
1117 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1118
1119 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1120
1121 =back
1122
1123   my $max_length = $rs->get_column('length')->max;
1124
1125 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1126
1127 =cut
1128
1129 sub get_column {
1130   my ($self, $column) = @_;
1131   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1132   return $new;
1133 }
1134
1135 =head2 search_like
1136
1137 =over 4
1138
1139 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1140
1141 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1142
1143 =back
1144
1145   # WHERE title LIKE '%blue%'
1146   $cd_rs = $rs->search_like({ title => '%blue%'});
1147
1148 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1149 that this is simply a convenience method retained for ex Class::DBI users.
1150 You most likely want to use L</search> with specific operators.
1151
1152 For more information, see L<DBIx::Class::Manual::Cookbook>.
1153
1154 This method is deprecated and will be removed in 0.09. Use L</search()>
1155 instead. An example conversion is:
1156
1157   ->search_like({ foo => 'bar' });
1158
1159   # Becomes
1160
1161   ->search({ foo => { like => 'bar' } });
1162
1163 =cut
1164
1165 sub search_like {
1166   my $class = shift;
1167   carp_unique (
1168     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1169    .' Instead use ->search({ x => { -like => "y%" } })'
1170    .' (note the outer pair of {}s - they are important!)'
1171   );
1172   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1173   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1174   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1175   return $class->search($query, { %$attrs });
1176 }
1177
1178 =head2 slice
1179
1180 =over 4
1181
1182 =item Arguments: $first, $last
1183
1184 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1185
1186 =back
1187
1188 Returns a resultset or object list representing a subset of elements from the
1189 resultset slice is called on. Indexes are from 0, i.e., to get the first
1190 three records, call:
1191
1192   my ($one, $two, $three) = $rs->slice(0, 2);
1193
1194 =cut
1195
1196 sub slice {
1197   my ($self, $min, $max) = @_;
1198   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1199   $attrs->{offset} = $self->{attrs}{offset} || 0;
1200   $attrs->{offset} += $min;
1201   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1202   return $self->search(undef, $attrs);
1203   #my $slice = (ref $self)->new($self->result_source, $attrs);
1204   #return (wantarray ? $slice->all : $slice);
1205 }
1206
1207 =head2 next
1208
1209 =over 4
1210
1211 =item Arguments: none
1212
1213 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1214
1215 =back
1216
1217 Returns the next element in the resultset (C<undef> is there is none).
1218
1219 Can be used to efficiently iterate over records in the resultset:
1220
1221   my $rs = $schema->resultset('CD')->search;
1222   while (my $cd = $rs->next) {
1223     print $cd->title;
1224   }
1225
1226 Note that you need to store the resultset object, and call C<next> on it.
1227 Calling C<< resultset('Table')->next >> repeatedly will always return the
1228 first record from the resultset.
1229
1230 =cut
1231
1232 sub next {
1233   my ($self) = @_;
1234
1235   if (my $cache = $self->get_cache) {
1236     $self->{all_cache_position} ||= 0;
1237     return $cache->[$self->{all_cache_position}++];
1238   }
1239
1240   if ($self->{attrs}{cache}) {
1241     delete $self->{pager};
1242     $self->{all_cache_position} = 1;
1243     return ($self->all)[0];
1244   }
1245
1246   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1247
1248   $self->{stashed_objects} = $self->_construct_objects
1249     or return undef;
1250
1251   return shift @{$self->{stashed_objects}};
1252 }
1253
1254 # Constructs as many objects as it can in one pass while respecting
1255 # cursor laziness. Several modes of operation:
1256 #
1257 # * Always builds everything present in @{$self->{stashed_rows}}
1258 # * If called with $fetch_all true - pulls everything off the cursor and
1259 #   builds all objects in one pass
1260 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1261 #   and if the resultset is ordered properly by the left side:
1262 #   * Fetches stuff off the cursor until the "master object" changes,
1263 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1264 #   OR
1265 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1266 #     was requested (there is no other way to collapse except for an
1267 #     eager cursor)
1268 # * If no collapse is requested - just get the next row, construct and
1269 #   return
1270 sub _construct_objects {
1271   my ($self, $fetch_all) = @_;
1272
1273   my $rsrc = $self->result_source;
1274   my $attrs = $self->_resolved_attrs;
1275
1276   if (!$fetch_all and ! $attrs->{order_by} and $attrs->{collapse}) {
1277     # default order for collapsing unless the user asked for something
1278     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} $rsrc->primary_columns ];
1279     $attrs->{_ordered_for_collapse} = 1;
1280     $attrs->{_order_is_artificial} = 1;
1281   }
1282
1283   my $cursor = $self->cursor;
1284
1285   # this will be used as both initial raw-row collector AND as a RV of
1286   # _construct_objects. Not regrowing the array twice matters a lot...
1287   # a suprising amount actually
1288   my $rows = delete $self->{stashed_rows};
1289
1290   if ($fetch_all) {
1291     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1292     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1293   }
1294   elsif( $attrs->{collapse} ) {
1295
1296     $attrs->{_ordered_for_collapse} = (!$attrs->{order_by}) ? 0 : do {
1297       my $st = $rsrc->schema->storage;
1298       my @ord_cols = map
1299         { $_->[0] }
1300         ( $st->_extract_order_criteria($attrs->{order_by}) )
1301       ;
1302
1303       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1304
1305       for (0 .. $#ord_cols) {
1306         if (
1307           ! $colinfos->{$ord_cols[$_]}
1308             or
1309           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1310         ) {
1311           splice @ord_cols, $_;
1312           last;
1313         }
1314       }
1315
1316       # since all we check here are the start of the order_by belonging to the
1317       # top level $rsrc, a present identifying set will mean that the resultset
1318       # is ordered by its leftmost table in a tsable manner
1319       (@ord_cols and $rsrc->_identifying_column_set({ map
1320         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1321         @ord_cols
1322       })) ? 1 : 0;
1323     } unless defined $attrs->{_ordered_for_collapse};
1324
1325     if (! $attrs->{_ordered_for_collapse}) {
1326       $fetch_all = 1;
1327
1328       # instead of looping over ->next, use ->all in stealth mode
1329       # *without* calling a ->reset afterwards
1330       # FIXME - encapsulation breach, got to be a better way
1331       if (! $cursor->{_done}) {
1332         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1333         $cursor->{_done} = 1;
1334       }
1335     }
1336   }
1337
1338   if (! $fetch_all and ! @{$rows||[]} ) {
1339     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1340     if (scalar (my @r = $cursor->next) ) {
1341       $rows = [ \@r ];
1342     }
1343   }
1344
1345   return undef unless @{$rows||[]};
1346
1347   my @extra_collapser_args;
1348   if ($attrs->{collapse} and ! $fetch_all ) {
1349
1350     @extra_collapser_args = (
1351       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1352       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1353       ($self->{stashed_rows} = []),                 # where does it stuff excess
1354     );
1355   }
1356
1357   # hotspot - skip the setter
1358   my $res_class = $self->_result_class;
1359
1360   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1361     $res_class->can ('inflate_result')
1362       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1363   };
1364
1365   my $infmap = $attrs->{as};
1366
1367   $self->{_result_inflator}{is_hri} = do { ( $inflator_cref == (
1368     require DBIx::Class::ResultClass::HashRefInflator
1369       &&
1370     DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1371   ) ) ? 1 : 0
1372   } unless defined $self->{_result_inflator}{is_hri};
1373
1374   if ($attrs->{_single_resultclass_inflation}) {
1375     # construct a much simpler array->hash folder for the one-table cases right here
1376     if ($self->{_result_inflator}{is_hri}) {
1377       for my $r (@$rows) {
1378         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1379       }
1380     }
1381     # FIXME SUBOPTIMAL this is a very very very hot spot
1382     # while rather optimal we can *still* do much better, by
1383     # building a smarter Row::inflate_result(), and
1384     # switch to feeding it data via a much leaner interface
1385     #
1386     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1387     # this particular resultset size
1388     elsif (@$rows < 60) {
1389       for my $r (@$rows) {
1390         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1391       }
1392     }
1393     else {
1394       eval sprintf (
1395         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1396         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1397       );
1398     }
1399   }
1400   # Special-case multi-object HRI (we always prune)
1401   elsif ($self->{_result_inflator}{is_hri}) {
1402     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1403       eval => 1,
1404       inflate_map => $infmap,
1405       selection => $attrs->{select},
1406       collapse => $attrs->{collapse},
1407       premultiplied => $attrs->{_main_source_premultiplied},
1408       hri_style => 1,
1409     }) )->($rows, @extra_collapser_args);
1410   }
1411   # Regular multi-object
1412   else {
1413
1414     ( $self->{_row_parser}{classic} ||= $rsrc->_mk_row_parser({
1415       eval => 1,
1416       inflate_map => $infmap,
1417       selection => $attrs->{select},
1418       collapse => $attrs->{collapse},
1419       premultiplied => $attrs->{_main_source_premultiplied},
1420     }) )->($rows, @extra_collapser_args);
1421
1422     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1423   }
1424
1425   # CDBI compat stuff
1426   if ($attrs->{record_filter}) {
1427     $_ = $attrs->{record_filter}->($_) for @$rows;
1428   }
1429
1430   return $rows;
1431 }
1432
1433 =head2 result_source
1434
1435 =over 4
1436
1437 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1438
1439 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1440
1441 =back
1442
1443 An accessor for the primary ResultSource object from which this ResultSet
1444 is derived.
1445
1446 =head2 result_class
1447
1448 =over 4
1449
1450 =item Arguments: $result_class?
1451
1452 =item Return Value: $result_class
1453
1454 =back
1455
1456 An accessor for the class to use when creating result objects. Defaults to
1457 C<< result_source->result_class >> - which in most cases is the name of the
1458 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1459
1460 Note that changing the result_class will also remove any components
1461 that were originally loaded in the source class via
1462 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1463 in the original source class will not run.
1464
1465 =cut
1466
1467 sub result_class {
1468   my ($self, $result_class) = @_;
1469   if ($result_class) {
1470
1471     unless (ref $result_class) { # don't fire this for an object
1472       $self->ensure_class_loaded($result_class);
1473     }
1474     $self->_result_class($result_class);
1475     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1476     # permit the user to set result class on one result set only; it only
1477     # chains if provided to search()
1478     #$self->{attrs}{result_class} = $result_class if ref $self;
1479
1480     delete $self->{_result_inflator};
1481   }
1482   $self->_result_class;
1483 }
1484
1485 =head2 count
1486
1487 =over 4
1488
1489 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1490
1491 =item Return Value: $count
1492
1493 =back
1494
1495 Performs an SQL C<COUNT> with the same query as the resultset was built
1496 with to find the number of elements. Passing arguments is equivalent to
1497 C<< $rs->search ($cond, \%attrs)->count >>
1498
1499 =cut
1500
1501 sub count {
1502   my $self = shift;
1503   return $self->search(@_)->count if @_ and defined $_[0];
1504   return scalar @{ $self->get_cache } if $self->get_cache;
1505
1506   my $attrs = { %{ $self->_resolved_attrs } };
1507
1508   # this is a little optimization - it is faster to do the limit
1509   # adjustments in software, instead of a subquery
1510   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1511
1512   my $crs;
1513   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1514     $crs = $self->_count_subq_rs ($attrs);
1515   }
1516   else {
1517     $crs = $self->_count_rs ($attrs);
1518   }
1519   my $count = $crs->next;
1520
1521   $count -= $offset if $offset;
1522   $count = $rows if $rows and $rows < $count;
1523   $count = 0 if ($count < 0);
1524
1525   return $count;
1526 }
1527
1528 =head2 count_rs
1529
1530 =over 4
1531
1532 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1533
1534 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1535
1536 =back
1537
1538 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1539 This can be very handy for subqueries:
1540
1541   ->search( { amount => $some_rs->count_rs->as_query } )
1542
1543 As with regular resultsets the SQL query will be executed only after
1544 the resultset is accessed via L</next> or L</all>. That would return
1545 the same single value obtainable via L</count>.
1546
1547 =cut
1548
1549 sub count_rs {
1550   my $self = shift;
1551   return $self->search(@_)->count_rs if @_;
1552
1553   # this may look like a lack of abstraction (count() does about the same)
1554   # but in fact an _rs *must* use a subquery for the limits, as the
1555   # software based limiting can not be ported if this $rs is to be used
1556   # in a subquery itself (i.e. ->as_query)
1557   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1558     return $self->_count_subq_rs;
1559   }
1560   else {
1561     return $self->_count_rs;
1562   }
1563 }
1564
1565 #
1566 # returns a ResultSetColumn object tied to the count query
1567 #
1568 sub _count_rs {
1569   my ($self, $attrs) = @_;
1570
1571   my $rsrc = $self->result_source;
1572   $attrs ||= $self->_resolved_attrs;
1573
1574   my $tmp_attrs = { %$attrs };
1575   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1576   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1577
1578   # overwrite the selector (supplied by the storage)
1579   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1580   $tmp_attrs->{as} = 'count';
1581
1582   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1583
1584   return $tmp_rs;
1585 }
1586
1587 #
1588 # same as above but uses a subquery
1589 #
1590 sub _count_subq_rs {
1591   my ($self, $attrs) = @_;
1592
1593   my $rsrc = $self->result_source;
1594   $attrs ||= $self->_resolved_attrs;
1595
1596   my $sub_attrs = { %$attrs };
1597   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1598   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1599
1600   # if we multi-prefetch we group_by something unique, as this is what we would
1601   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1602   if ( $attrs->{collapse}  ) {
1603     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1604       $rsrc->_identifying_column_set || $self->throw_exception(
1605         'Unable to construct a unique group_by criteria properly collapsing the '
1606       . 'has_many prefetch before count()'
1607       );
1608     } ]
1609   }
1610
1611   # Calculate subquery selector
1612   if (my $g = $sub_attrs->{group_by}) {
1613
1614     my $sql_maker = $rsrc->storage->sql_maker;
1615
1616     # necessary as the group_by may refer to aliased functions
1617     my $sel_index;
1618     for my $sel (@{$attrs->{select}}) {
1619       $sel_index->{$sel->{-as}} = $sel
1620         if (ref $sel eq 'HASH' and $sel->{-as});
1621     }
1622
1623     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1624     # also look for named aggregates referred in the having clause
1625     # having often contains scalarrefs - thus parse it out entirely
1626     my @parts = @$g;
1627     if ($attrs->{having}) {
1628       local $sql_maker->{having_bind};
1629       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1630       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1631       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1632         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1633         # if we don't unset it we screw up retarded but unfortunately working
1634         # 'MAX(foo.bar)' => { '>', 3 }
1635         $sql_maker->{name_sep} = '';
1636       }
1637
1638       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1639
1640       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1641       my %seen_having;
1642
1643       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1644       # and if all fails for an utterly naive quoted scalar-with-function
1645       while ($having_sql =~ /
1646         $rquote $sep $lquote (.+?) $rquote
1647           |
1648         [\s,] \w+ \. (\w+) [\s,]
1649           |
1650         [\s,] $lquote (.+?) $rquote [\s,]
1651       /gx) {
1652         my $part = $1 || $2 || $3;  # one of them matched if we got here
1653         unless ($seen_having{$part}++) {
1654           push @parts, $part;
1655         }
1656       }
1657     }
1658
1659     for (@parts) {
1660       my $colpiece = $sel_index->{$_} || $_;
1661
1662       # unqualify join-based group_by's. Arcane but possible query
1663       # also horrible horrible hack to alias a column (not a func.)
1664       # (probably need to introduce SQLA syntax)
1665       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1666         my $as = $colpiece;
1667         $as =~ s/\./__/;
1668         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1669       }
1670       push @{$sub_attrs->{select}}, $colpiece;
1671     }
1672   }
1673   else {
1674     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1675     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1676   }
1677
1678   return $rsrc->resultset_class
1679                ->new ($rsrc, $sub_attrs)
1680                 ->as_subselect_rs
1681                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1682                   ->get_column ('count');
1683 }
1684
1685 sub _bool {
1686   return 1;
1687 }
1688
1689 =head2 count_literal
1690
1691 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1692 should only be used in that context. See L</search_literal> for further info.
1693
1694 =over 4
1695
1696 =item Arguments: $sql_fragment, @standalone_bind_values
1697
1698 =item Return Value: $count
1699
1700 =back
1701
1702 Counts the results in a literal query. Equivalent to calling L</search_literal>
1703 with the passed arguments, then L</count>.
1704
1705 =cut
1706
1707 sub count_literal { shift->search_literal(@_)->count; }
1708
1709 =head2 all
1710
1711 =over 4
1712
1713 =item Arguments: none
1714
1715 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1716
1717 =back
1718
1719 Returns all elements in the resultset.
1720
1721 =cut
1722
1723 sub all {
1724   my $self = shift;
1725   if(@_) {
1726     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1727   }
1728
1729   delete @{$self}{qw/stashed_rows stashed_objects/};
1730
1731   if (my $c = $self->get_cache) {
1732     return @$c;
1733   }
1734
1735   $self->cursor->reset;
1736
1737   my $objs = $self->_construct_objects('fetch_all') || [];
1738
1739   $self->set_cache($objs) if $self->{attrs}{cache};
1740
1741   return @$objs;
1742 }
1743
1744 =head2 reset
1745
1746 =over 4
1747
1748 =item Arguments: none
1749
1750 =item Return Value: $self
1751
1752 =back
1753
1754 Resets the resultset's cursor, so you can iterate through the elements again.
1755 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1756 another query.
1757
1758 =cut
1759
1760 sub reset {
1761   my ($self) = @_;
1762
1763   delete @{$self}{qw/stashed_rows stashed_objects/};
1764   $self->{all_cache_position} = 0;
1765   $self->cursor->reset;
1766   return $self;
1767 }
1768
1769 =head2 first
1770
1771 =over 4
1772
1773 =item Arguments: none
1774
1775 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1776
1777 =back
1778
1779 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1780 an object for the first result (or C<undef> if the resultset is empty).
1781
1782 =cut
1783
1784 sub first {
1785   return $_[0]->reset->next;
1786 }
1787
1788
1789 # _rs_update_delete
1790 #
1791 # Determines whether and what type of subquery is required for the $rs operation.
1792 # If grouping is necessary either supplies its own, or verifies the current one
1793 # After all is done delegates to the proper storage method.
1794
1795 sub _rs_update_delete {
1796   my ($self, $op, $values) = @_;
1797
1798   my $rsrc = $self->result_source;
1799   my $storage = $rsrc->schema->storage;
1800
1801   my $attrs = { %{$self->_resolved_attrs} };
1802
1803   my $join_classifications;
1804   my $existing_group_by = delete $attrs->{group_by};
1805
1806   # do we need a subquery for any reason?
1807   my $needs_subq = (
1808     defined $existing_group_by
1809       or
1810     # if {from} is unparseable wrap a subq
1811     ref($attrs->{from}) ne 'ARRAY'
1812       or
1813     # limits call for a subq
1814     $self->_has_resolved_attr(qw/rows offset/)
1815   );
1816
1817   # simplify the joinmap, so we can further decide if a subq is necessary
1818   if (!$needs_subq and @{$attrs->{from}} > 1) {
1819     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1820
1821     # check if there are any joins left after the prune
1822     if ( @{$attrs->{from}} > 1 ) {
1823       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1824         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1825         $attrs->{select},
1826         $self->{cond},
1827         $attrs
1828       );
1829
1830       # any non-pruneable joins imply subq
1831       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1832     }
1833   }
1834
1835   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1836   $needs_subq ||= (
1837     (ref $attrs->{from}[0]) ne 'HASH'
1838       or
1839     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1840   );
1841
1842   my ($cond, $guard);
1843   # do we need anything like a subquery?
1844   if (! $needs_subq) {
1845     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1846     # a condition containing 'me' or other table prefixes will not work
1847     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1848     $cond = do {
1849       my $sqla = $rsrc->storage->sql_maker;
1850       local $sqla->{_dequalify_idents} = 1;
1851       \[ $sqla->_recurse_where($self->{cond}) ];
1852     };
1853   }
1854   else {
1855     # we got this far - means it is time to wrap a subquery
1856     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1857       sprintf(
1858         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1859         $op,
1860         $rsrc->source_name,
1861       )
1862     );
1863
1864     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1865     delete $attrs->{$_} for qw/collapse select _prefetch_selector_range as/;
1866     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1867     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1868     my $subrs = (ref $self)->new($rsrc, $attrs);
1869
1870     if (@$idcols == 1) {
1871       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1872     }
1873     elsif ($storage->_use_multicolumn_in) {
1874       # no syntax for calling this properly yet
1875       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1876       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1877         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1878         $subrs->as_query
1879       ),
1880     }
1881     else {
1882       # if all else fails - get all primary keys and operate over a ORed set
1883       # wrap in a transaction for consistency
1884       # this is where the group_by/multiplication starts to matter
1885       if (
1886         $existing_group_by
1887           or
1888         keys %{ $join_classifications->{multiplying} || {} }
1889       ) {
1890         # make sure if there is a supplied group_by it matches the columns compiled above
1891         # perfectly. Anything else can not be sanely executed on most databases so croak
1892         # right then and there
1893         if ($existing_group_by) {
1894           my @current_group_by = map
1895             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1896             @$existing_group_by
1897           ;
1898
1899           if (
1900             join ("\x00", sort @current_group_by)
1901               ne
1902             join ("\x00", sort @{$attrs->{columns}} )
1903           ) {
1904             $self->throw_exception (
1905               "You have just attempted a $op operation on a resultset which does group_by"
1906               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1907               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1908               . ' kind of queries. Please retry the operation with a modified group_by or'
1909               . ' without using one at all.'
1910             );
1911           }
1912         }
1913
1914         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1915       }
1916
1917       $guard = $storage->txn_scope_guard;
1918
1919       $cond = [];
1920       for my $row ($subrs->cursor->all) {
1921         push @$cond, { map
1922           { $idcols->[$_] => $row->[$_] }
1923           (0 .. $#$idcols)
1924         };
1925       }
1926     }
1927   }
1928
1929   my $res = $storage->$op (
1930     $rsrc,
1931     $op eq 'update' ? $values : (),
1932     $cond,
1933   );
1934
1935   $guard->commit if $guard;
1936
1937   return $res;
1938 }
1939
1940 =head2 update
1941
1942 =over 4
1943
1944 =item Arguments: \%values
1945
1946 =item Return Value: $underlying_storage_rv
1947
1948 =back
1949
1950 Sets the specified columns in the resultset to the supplied values in a
1951 single query. Note that this will not run any accessor/set_column/update
1952 triggers, nor will it update any result object instances derived from this
1953 resultset (this includes the contents of the L<resultset cache|/set_cache>
1954 if any). See L</update_all> if you need to execute any on-update
1955 triggers or cascades defined either by you or a
1956 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1957
1958 The return value is a pass through of what the underlying
1959 storage backend returned, and may vary. See L<DBI/execute> for the most
1960 common case.
1961
1962 =head3 CAVEAT
1963
1964 Note that L</update> does not process/deflate any of the values passed in.
1965 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1966 ensure manually that any value passed to this method will stringify to
1967 something the RDBMS knows how to deal with. A notable example is the
1968 handling of L<DateTime> objects, for more info see:
1969 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1970
1971 =cut
1972
1973 sub update {
1974   my ($self, $values) = @_;
1975   $self->throw_exception('Values for update must be a hash')
1976     unless ref $values eq 'HASH';
1977
1978   return $self->_rs_update_delete ('update', $values);
1979 }
1980
1981 =head2 update_all
1982
1983 =over 4
1984
1985 =item Arguments: \%values
1986
1987 =item Return Value: 1
1988
1989 =back
1990
1991 Fetches all objects and updates them one at a time via
1992 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1993 triggers, while L</update> will not.
1994
1995 =cut
1996
1997 sub update_all {
1998   my ($self, $values) = @_;
1999   $self->throw_exception('Values for update_all must be a hash')
2000     unless ref $values eq 'HASH';
2001
2002   my $guard = $self->result_source->schema->txn_scope_guard;
2003   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2004   $guard->commit;
2005   return 1;
2006 }
2007
2008 =head2 delete
2009
2010 =over 4
2011
2012 =item Arguments: none
2013
2014 =item Return Value: $underlying_storage_rv
2015
2016 =back
2017
2018 Deletes the rows matching this resultset in a single query. Note that this
2019 will not run any delete triggers, nor will it alter the
2020 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2021 derived from this resultset (this includes the contents of the
2022 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2023 execute any on-delete triggers or cascades defined either by you or a
2024 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2025
2026 The return value is a pass through of what the underlying storage backend
2027 returned, and may vary. See L<DBI/execute> for the most common case.
2028
2029 =cut
2030
2031 sub delete {
2032   my $self = shift;
2033   $self->throw_exception('delete does not accept any arguments')
2034     if @_;
2035
2036   return $self->_rs_update_delete ('delete');
2037 }
2038
2039 =head2 delete_all
2040
2041 =over 4
2042
2043 =item Arguments: none
2044
2045 =item Return Value: 1
2046
2047 =back
2048
2049 Fetches all objects and deletes them one at a time via
2050 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2051 triggers, while L</delete> will not.
2052
2053 =cut
2054
2055 sub delete_all {
2056   my $self = shift;
2057   $self->throw_exception('delete_all does not accept any arguments')
2058     if @_;
2059
2060   my $guard = $self->result_source->schema->txn_scope_guard;
2061   $_->delete for $self->all;
2062   $guard->commit;
2063   return 1;
2064 }
2065
2066 =head2 populate
2067
2068 =over 4
2069
2070 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2071
2072 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2073
2074 =back
2075
2076 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2077 arrayrefs.
2078
2079 =over
2080
2081 =item NOTE
2082
2083 The context of this method call has an important effect on what is
2084 submitted to storage. In void context data is fed directly to fastpath
2085 insertion routines provided by the underlying storage (most often
2086 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2087 L<insert|DBIx::Class::Row/insert> calls on the
2088 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2089 augmentation of these methods provided by components. For example if you
2090 are using something like L<DBIx::Class::UUIDColumns> to create primary
2091 keys for you, you will find that your PKs are empty.  In this case you
2092 will have to explicitly force scalar or list context in order to create
2093 those values.
2094
2095 =back
2096
2097 In non-void (scalar or list) context, this method is simply a wrapper
2098 for L</create>. Depending on list or scalar context either a list of
2099 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2100 containing these objects is returned.
2101
2102 When supplying data in "arrayref of arrayrefs" invocation style, the
2103 first element should be a list of column names and each subsequent
2104 element should be a data value in the earlier specified column order.
2105 For example:
2106
2107   $Arstist_rs->populate([
2108     [ qw( artistid name ) ],
2109     [ 100, 'A Formally Unknown Singer' ],
2110     [ 101, 'A singer that jumped the shark two albums ago' ],
2111     [ 102, 'An actually cool singer' ],
2112   ]);
2113
2114 For the arrayref of hashrefs style each hashref should be a structure
2115 suitable for passing to L</create>. Multi-create is also permitted with
2116 this syntax.
2117
2118   $schema->resultset("Artist")->populate([
2119      { artistid => 4, name => 'Manufactured Crap', cds => [
2120         { title => 'My First CD', year => 2006 },
2121         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2122       ],
2123      },
2124      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2125         { title => 'My parents sold me to a record company', year => 2005 },
2126         { title => 'Why Am I So Ugly?', year => 2006 },
2127         { title => 'I Got Surgery and am now Popular', year => 2007 }
2128       ],
2129      },
2130   ]);
2131
2132 If you attempt a void-context multi-create as in the example above (each
2133 Artist also has the related list of CDs), and B<do not> supply the
2134 necessary autoinc foreign key information, this method will proxy to the
2135 less efficient L</create>, and then throw the Result objects away. In this
2136 case there are obviously no benefits to using this method over L</create>.
2137
2138 =cut
2139
2140 sub populate {
2141   my $self = shift;
2142
2143   # cruft placed in standalone method
2144   my $data = $self->_normalize_populate_args(@_);
2145
2146   return unless @$data;
2147
2148   if(defined wantarray) {
2149     my @created = map { $self->create($_) } @$data;
2150     return wantarray ? @created : \@created;
2151   }
2152   else {
2153     my $first = $data->[0];
2154
2155     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2156     # it relationship data
2157     my (@rels, @columns);
2158     my $rsrc = $self->result_source;
2159     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2160     for (keys %$first) {
2161       my $ref = ref $first->{$_};
2162       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2163         ? push @rels, $_
2164         : push @columns, $_
2165       ;
2166     }
2167
2168     my @pks = $rsrc->primary_columns;
2169
2170     ## do the belongs_to relationships
2171     foreach my $index (0..$#$data) {
2172
2173       # delegate to create() for any dataset without primary keys with specified relationships
2174       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2175         for my $r (@rels) {
2176           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2177             my @ret = $self->populate($data);
2178             return;
2179           }
2180         }
2181       }
2182
2183       foreach my $rel (@rels) {
2184         next unless ref $data->[$index]->{$rel} eq "HASH";
2185         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2186         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2187         my $related = $result->result_source->_resolve_condition(
2188           $reverse_relinfo->{cond},
2189           $self,
2190           $result,
2191           $rel,
2192         );
2193
2194         delete $data->[$index]->{$rel};
2195         $data->[$index] = {%{$data->[$index]}, %$related};
2196
2197         push @columns, keys %$related if $index == 0;
2198       }
2199     }
2200
2201     ## inherit the data locked in the conditions of the resultset
2202     my ($rs_data) = $self->_merge_with_rscond({});
2203     delete @{$rs_data}{@columns};
2204
2205     ## do bulk insert on current row
2206     $rsrc->storage->insert_bulk(
2207       $rsrc,
2208       [@columns, keys %$rs_data],
2209       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2210     );
2211
2212     ## do the has_many relationships
2213     foreach my $item (@$data) {
2214
2215       my $main_row;
2216
2217       foreach my $rel (@rels) {
2218         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2219
2220         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2221
2222         my $child = $main_row->$rel;
2223
2224         my $related = $child->result_source->_resolve_condition(
2225           $rels->{$rel}{cond},
2226           $child,
2227           $main_row,
2228           $rel,
2229         );
2230
2231         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2232         my @populate = map { {%$_, %$related} } @rows_to_add;
2233
2234         $child->populate( \@populate );
2235       }
2236     }
2237   }
2238 }
2239
2240
2241 # populate() argumnets went over several incarnations
2242 # What we ultimately support is AoH
2243 sub _normalize_populate_args {
2244   my ($self, $arg) = @_;
2245
2246   if (ref $arg eq 'ARRAY') {
2247     if (!@$arg) {
2248       return [];
2249     }
2250     elsif (ref $arg->[0] eq 'HASH') {
2251       return $arg;
2252     }
2253     elsif (ref $arg->[0] eq 'ARRAY') {
2254       my @ret;
2255       my @colnames = @{$arg->[0]};
2256       foreach my $values (@{$arg}[1 .. $#$arg]) {
2257         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2258       }
2259       return \@ret;
2260     }
2261   }
2262
2263   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2264 }
2265
2266 =head2 pager
2267
2268 =over 4
2269
2270 =item Arguments: none
2271
2272 =item Return Value: L<$pager|Data::Page>
2273
2274 =back
2275
2276 Returns a L<Data::Page> object for the current resultset. Only makes
2277 sense for queries with a C<page> attribute.
2278
2279 To get the full count of entries for a paged resultset, call
2280 C<total_entries> on the L<Data::Page> object.
2281
2282 =cut
2283
2284 sub pager {
2285   my ($self) = @_;
2286
2287   return $self->{pager} if $self->{pager};
2288
2289   my $attrs = $self->{attrs};
2290   if (!defined $attrs->{page}) {
2291     $self->throw_exception("Can't create pager for non-paged rs");
2292   }
2293   elsif ($attrs->{page} <= 0) {
2294     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2295   }
2296   $attrs->{rows} ||= 10;
2297
2298   # throw away the paging flags and re-run the count (possibly
2299   # with a subselect) to get the real total count
2300   my $count_attrs = { %$attrs };
2301   delete @{$count_attrs}{qw/rows offset page pager/};
2302
2303   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2304
2305   require DBIx::Class::ResultSet::Pager;
2306   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2307     sub { $total_rs->count },  #lazy-get the total
2308     $attrs->{rows},
2309     $self->{attrs}{page},
2310   );
2311 }
2312
2313 =head2 page
2314
2315 =over 4
2316
2317 =item Arguments: $page_number
2318
2319 =item Return Value: L<$resultset|/search>
2320
2321 =back
2322
2323 Returns a resultset for the $page_number page of the resultset on which page
2324 is called, where each page contains a number of rows equal to the 'rows'
2325 attribute set on the resultset (10 by default).
2326
2327 =cut
2328
2329 sub page {
2330   my ($self, $page) = @_;
2331   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2332 }
2333
2334 =head2 new_result
2335
2336 =over 4
2337
2338 =item Arguments: \%col_data
2339
2340 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2341
2342 =back
2343
2344 Creates a new result object in the resultset's result class and returns
2345 it. The row is not inserted into the database at this point, call
2346 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2347 will tell you whether the result object has been inserted or not.
2348
2349 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2350
2351 =cut
2352
2353 sub new_result {
2354   my ($self, $values) = @_;
2355
2356   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2357     if @_ > 2;
2358
2359   $self->throw_exception( "new_result expects a hashref" )
2360     unless (ref $values eq 'HASH');
2361
2362   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2363
2364   my %new = (
2365     %$merged_cond,
2366     @$cols_from_relations
2367       ? (-cols_from_relations => $cols_from_relations)
2368       : (),
2369     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2370   );
2371
2372   return $self->result_class->new(\%new);
2373 }
2374
2375 # _merge_with_rscond
2376 #
2377 # Takes a simple hash of K/V data and returns its copy merged with the
2378 # condition already present on the resultset. Additionally returns an
2379 # arrayref of value/condition names, which were inferred from related
2380 # objects (this is needed for in-memory related objects)
2381 sub _merge_with_rscond {
2382   my ($self, $data) = @_;
2383
2384   my (%new_data, @cols_from_relations);
2385
2386   my $alias = $self->{attrs}{alias};
2387
2388   if (! defined $self->{cond}) {
2389     # just massage $data below
2390   }
2391   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2392     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2393     @cols_from_relations = keys %new_data;
2394   }
2395   elsif (ref $self->{cond} ne 'HASH') {
2396     $self->throw_exception(
2397       "Can't abstract implicit construct, resultset condition not a hash"
2398     );
2399   }
2400   else {
2401     # precendence must be given to passed values over values inherited from
2402     # the cond, so the order here is important.
2403     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2404     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2405
2406     while ( my($col, $value) = each %implied ) {
2407       my $vref = ref $value;
2408       if (
2409         $vref eq 'HASH'
2410           and
2411         keys(%$value) == 1
2412           and
2413         (keys %$value)[0] eq '='
2414       ) {
2415         $new_data{$col} = $value->{'='};
2416       }
2417       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2418         $new_data{$col} = $value;
2419       }
2420     }
2421   }
2422
2423   %new_data = (
2424     %new_data,
2425     %{ $self->_remove_alias($data, $alias) },
2426   );
2427
2428   return (\%new_data, \@cols_from_relations);
2429 }
2430
2431 # _has_resolved_attr
2432 #
2433 # determines if the resultset defines at least one
2434 # of the attributes supplied
2435 #
2436 # used to determine if a subquery is neccessary
2437 #
2438 # supports some virtual attributes:
2439 #   -join
2440 #     This will scan for any joins being present on the resultset.
2441 #     It is not a mere key-search but a deep inspection of {from}
2442 #
2443
2444 sub _has_resolved_attr {
2445   my ($self, @attr_names) = @_;
2446
2447   my $attrs = $self->_resolved_attrs;
2448
2449   my %extra_checks;
2450
2451   for my $n (@attr_names) {
2452     if (grep { $n eq $_ } (qw/-join/) ) {
2453       $extra_checks{$n}++;
2454       next;
2455     }
2456
2457     my $attr =  $attrs->{$n};
2458
2459     next if not defined $attr;
2460
2461     if (ref $attr eq 'HASH') {
2462       return 1 if keys %$attr;
2463     }
2464     elsif (ref $attr eq 'ARRAY') {
2465       return 1 if @$attr;
2466     }
2467     else {
2468       return 1 if $attr;
2469     }
2470   }
2471
2472   # a resolved join is expressed as a multi-level from
2473   return 1 if (
2474     $extra_checks{-join}
2475       and
2476     ref $attrs->{from} eq 'ARRAY'
2477       and
2478     @{$attrs->{from}} > 1
2479   );
2480
2481   return 0;
2482 }
2483
2484 # _collapse_cond
2485 #
2486 # Recursively collapse the condition.
2487
2488 sub _collapse_cond {
2489   my ($self, $cond, $collapsed) = @_;
2490
2491   $collapsed ||= {};
2492
2493   if (ref $cond eq 'ARRAY') {
2494     foreach my $subcond (@$cond) {
2495       next unless ref $subcond;  # -or
2496       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2497     }
2498   }
2499   elsif (ref $cond eq 'HASH') {
2500     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2501       foreach my $subcond (@{$cond->{-and}}) {
2502         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2503       }
2504     }
2505     else {
2506       foreach my $col (keys %$cond) {
2507         my $value = $cond->{$col};
2508         $collapsed->{$col} = $value;
2509       }
2510     }
2511   }
2512
2513   return $collapsed;
2514 }
2515
2516 # _remove_alias
2517 #
2518 # Remove the specified alias from the specified query hash. A copy is made so
2519 # the original query is not modified.
2520
2521 sub _remove_alias {
2522   my ($self, $query, $alias) = @_;
2523
2524   my %orig = %{ $query || {} };
2525   my %unaliased;
2526
2527   foreach my $key (keys %orig) {
2528     if ($key !~ /\./) {
2529       $unaliased{$key} = $orig{$key};
2530       next;
2531     }
2532     $unaliased{$1} = $orig{$key}
2533       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2534   }
2535
2536   return \%unaliased;
2537 }
2538
2539 =head2 as_query
2540
2541 =over 4
2542
2543 =item Arguments: none
2544
2545 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2546
2547 =back
2548
2549 Returns the SQL query and bind vars associated with the invocant.
2550
2551 This is generally used as the RHS for a subquery.
2552
2553 =cut
2554
2555 sub as_query {
2556   my $self = shift;
2557
2558   my $attrs = { %{ $self->_resolved_attrs } };
2559
2560   # For future use:
2561   #
2562   # in list ctx:
2563   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2564   # $sql also has no wrapping parenthesis in list ctx
2565   #
2566   my $sqlbind = $self->result_source->storage
2567     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2568
2569   return $sqlbind;
2570 }
2571
2572 =head2 find_or_new
2573
2574 =over 4
2575
2576 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2577
2578 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2579
2580 =back
2581
2582   my $artist = $schema->resultset('Artist')->find_or_new(
2583     { artist => 'fred' }, { key => 'artists' });
2584
2585   $cd->cd_to_producer->find_or_new({ producer => $producer },
2586                                    { key => 'primary });
2587
2588 Find an existing record from this resultset using L</find>. if none exists,
2589 instantiate a new result object and return it. The object will not be saved
2590 into your storage until you call L<DBIx::Class::Row/insert> on it.
2591
2592 You most likely want this method when looking for existing rows using a unique
2593 constraint that is not the primary key, or looking for related rows.
2594
2595 If you want objects to be saved immediately, use L</find_or_create> instead.
2596
2597 B<Note>: Make sure to read the documentation of L</find> and understand the
2598 significance of the C<key> attribute, as its lack may skew your search, and
2599 subsequently result in spurious new objects.
2600
2601 B<Note>: Take care when using C<find_or_new> with a table having
2602 columns with default values that you intend to be automatically
2603 supplied by the database (e.g. an auto_increment primary key column).
2604 In normal usage, the value of such columns should NOT be included at
2605 all in the call to C<find_or_new>, even when set to C<undef>.
2606
2607 =cut
2608
2609 sub find_or_new {
2610   my $self     = shift;
2611   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2612   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2613   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2614     return $row;
2615   }
2616   return $self->new_result($hash);
2617 }
2618
2619 =head2 create
2620
2621 =over 4
2622
2623 =item Arguments: \%col_data
2624
2625 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2626
2627 =back
2628
2629 Attempt to create a single new row or a row with multiple related rows
2630 in the table represented by the resultset (and related tables). This
2631 will not check for duplicate rows before inserting, use
2632 L</find_or_create> to do that.
2633
2634 To create one row for this resultset, pass a hashref of key/value
2635 pairs representing the columns of the table and the values you wish to
2636 store. If the appropriate relationships are set up, foreign key fields
2637 can also be passed an object representing the foreign row, and the
2638 value will be set to its primary key.
2639
2640 To create related objects, pass a hashref of related-object column values
2641 B<keyed on the relationship name>. If the relationship is of type C<multi>
2642 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2643 The process will correctly identify columns holding foreign keys, and will
2644 transparently populate them from the keys of the corresponding relation.
2645 This can be applied recursively, and will work correctly for a structure
2646 with an arbitrary depth and width, as long as the relationships actually
2647 exists and the correct column data has been supplied.
2648
2649 Instead of hashrefs of plain related data (key/value pairs), you may
2650 also pass new or inserted objects. New objects (not inserted yet, see
2651 L</new_result>), will be inserted into their appropriate tables.
2652
2653 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2654
2655 Example of creating a new row.
2656
2657   $person_rs->create({
2658     name=>"Some Person",
2659     email=>"somebody@someplace.com"
2660   });
2661
2662 Example of creating a new row and also creating rows in a related C<has_many>
2663 or C<has_one> resultset.  Note Arrayref.
2664
2665   $artist_rs->create(
2666      { artistid => 4, name => 'Manufactured Crap', cds => [
2667         { title => 'My First CD', year => 2006 },
2668         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2669       ],
2670      },
2671   );
2672
2673 Example of creating a new row and also creating a row in a related
2674 C<belongs_to> resultset. Note Hashref.
2675
2676   $cd_rs->create({
2677     title=>"Music for Silly Walks",
2678     year=>2000,
2679     artist => {
2680       name=>"Silly Musician",
2681     }
2682   });
2683
2684 =over
2685
2686 =item WARNING
2687
2688 When subclassing ResultSet never attempt to override this method. Since
2689 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2690 lot of the internals simply never call it, so your override will be
2691 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2692 or L<DBIx::Class::Row/insert> depending on how early in the
2693 L</create> process you need to intervene. See also warning pertaining to
2694 L</new>.
2695
2696 =back
2697
2698 =cut
2699
2700 sub create {
2701   my ($self, $attrs) = @_;
2702   $self->throw_exception( "create needs a hashref" )
2703     unless ref $attrs eq 'HASH';
2704   return $self->new_result($attrs)->insert;
2705 }
2706
2707 =head2 find_or_create
2708
2709 =over 4
2710
2711 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2712
2713 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2714
2715 =back
2716
2717   $cd->cd_to_producer->find_or_create({ producer => $producer },
2718                                       { key => 'primary' });
2719
2720 Tries to find a record based on its primary key or unique constraints; if none
2721 is found, creates one and returns that instead.
2722
2723   my $cd = $schema->resultset('CD')->find_or_create({
2724     cdid   => 5,
2725     artist => 'Massive Attack',
2726     title  => 'Mezzanine',
2727     year   => 2005,
2728   });
2729
2730 Also takes an optional C<key> attribute, to search by a specific key or unique
2731 constraint. For example:
2732
2733   my $cd = $schema->resultset('CD')->find_or_create(
2734     {
2735       artist => 'Massive Attack',
2736       title  => 'Mezzanine',
2737     },
2738     { key => 'cd_artist_title' }
2739   );
2740
2741 B<Note>: Make sure to read the documentation of L</find> and understand the
2742 significance of the C<key> attribute, as its lack may skew your search, and
2743 subsequently result in spurious row creation.
2744
2745 B<Note>: Because find_or_create() reads from the database and then
2746 possibly inserts based on the result, this method is subject to a race
2747 condition. Another process could create a record in the table after
2748 the find has completed and before the create has started. To avoid
2749 this problem, use find_or_create() inside a transaction.
2750
2751 B<Note>: Take care when using C<find_or_create> with a table having
2752 columns with default values that you intend to be automatically
2753 supplied by the database (e.g. an auto_increment primary key column).
2754 In normal usage, the value of such columns should NOT be included at
2755 all in the call to C<find_or_create>, even when set to C<undef>.
2756
2757 See also L</find> and L</update_or_create>. For information on how to declare
2758 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2759
2760 If you need to know if an existing row was found or a new one created use
2761 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2762 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2763 database!
2764
2765   my $cd = $schema->resultset('CD')->find_or_new({
2766     cdid   => 5,
2767     artist => 'Massive Attack',
2768     title  => 'Mezzanine',
2769     year   => 2005,
2770   });
2771
2772   if( !$cd->in_storage ) {
2773       # do some stuff
2774       $cd->insert;
2775   }
2776
2777 =cut
2778
2779 sub find_or_create {
2780   my $self     = shift;
2781   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2782   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2783   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2784     return $row;
2785   }
2786   return $self->create($hash);
2787 }
2788
2789 =head2 update_or_create
2790
2791 =over 4
2792
2793 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2794
2795 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2796
2797 =back
2798
2799   $resultset->update_or_create({ col => $val, ... });
2800
2801 Like L</find_or_create>, but if a row is found it is immediately updated via
2802 C<< $found_row->update (\%col_data) >>.
2803
2804
2805 Takes an optional C<key> attribute to search on a specific unique constraint.
2806 For example:
2807
2808   # In your application
2809   my $cd = $schema->resultset('CD')->update_or_create(
2810     {
2811       artist => 'Massive Attack',
2812       title  => 'Mezzanine',
2813       year   => 1998,
2814     },
2815     { key => 'cd_artist_title' }
2816   );
2817
2818   $cd->cd_to_producer->update_or_create({
2819     producer => $producer,
2820     name => 'harry',
2821   }, {
2822     key => 'primary',
2823   });
2824
2825 B<Note>: Make sure to read the documentation of L</find> and understand the
2826 significance of the C<key> attribute, as its lack may skew your search, and
2827 subsequently result in spurious row creation.
2828
2829 B<Note>: Take care when using C<update_or_create> with a table having
2830 columns with default values that you intend to be automatically
2831 supplied by the database (e.g. an auto_increment primary key column).
2832 In normal usage, the value of such columns should NOT be included at
2833 all in the call to C<update_or_create>, even when set to C<undef>.
2834
2835 See also L</find> and L</find_or_create>. For information on how to declare
2836 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2837
2838 If you need to know if an existing row was updated or a new one created use
2839 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2840 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2841 database!
2842
2843 =cut
2844
2845 sub update_or_create {
2846   my $self = shift;
2847   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2848   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2849
2850   my $row = $self->find($cond, $attrs);
2851   if (defined $row) {
2852     $row->update($cond);
2853     return $row;
2854   }
2855
2856   return $self->create($cond);
2857 }
2858
2859 =head2 update_or_new
2860
2861 =over 4
2862
2863 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2864
2865 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2866
2867 =back
2868
2869   $resultset->update_or_new({ col => $val, ... });
2870
2871 Like L</find_or_new> but if a row is found it is immediately updated via
2872 C<< $found_row->update (\%col_data) >>.
2873
2874 For example:
2875
2876   # In your application
2877   my $cd = $schema->resultset('CD')->update_or_new(
2878     {
2879       artist => 'Massive Attack',
2880       title  => 'Mezzanine',
2881       year   => 1998,
2882     },
2883     { key => 'cd_artist_title' }
2884   );
2885
2886   if ($cd->in_storage) {
2887       # the cd was updated
2888   }
2889   else {
2890       # the cd is not yet in the database, let's insert it
2891       $cd->insert;
2892   }
2893
2894 B<Note>: Make sure to read the documentation of L</find> and understand the
2895 significance of the C<key> attribute, as its lack may skew your search, and
2896 subsequently result in spurious new objects.
2897
2898 B<Note>: Take care when using C<update_or_new> with a table having
2899 columns with default values that you intend to be automatically
2900 supplied by the database (e.g. an auto_increment primary key column).
2901 In normal usage, the value of such columns should NOT be included at
2902 all in the call to C<update_or_new>, even when set to C<undef>.
2903
2904 See also L</find>, L</find_or_create> and L</find_or_new>.
2905
2906 =cut
2907
2908 sub update_or_new {
2909     my $self  = shift;
2910     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2911     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2912
2913     my $row = $self->find( $cond, $attrs );
2914     if ( defined $row ) {
2915         $row->update($cond);
2916         return $row;
2917     }
2918
2919     return $self->new_result($cond);
2920 }
2921
2922 =head2 get_cache
2923
2924 =over 4
2925
2926 =item Arguments: none
2927
2928 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2929
2930 =back
2931
2932 Gets the contents of the cache for the resultset, if the cache is set.
2933
2934 The cache is populated either by using the L</prefetch> attribute to
2935 L</search> or by calling L</set_cache>.
2936
2937 =cut
2938
2939 sub get_cache {
2940   shift->{all_cache};
2941 }
2942
2943 =head2 set_cache
2944
2945 =over 4
2946
2947 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2948
2949 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2950
2951 =back
2952
2953 Sets the contents of the cache for the resultset. Expects an arrayref
2954 of objects of the same class as those produced by the resultset. Note that
2955 if the cache is set, the resultset will return the cached objects rather
2956 than re-querying the database even if the cache attr is not set.
2957
2958 The contents of the cache can also be populated by using the
2959 L</prefetch> attribute to L</search>.
2960
2961 =cut
2962
2963 sub set_cache {
2964   my ( $self, $data ) = @_;
2965   $self->throw_exception("set_cache requires an arrayref")
2966       if defined($data) && (ref $data ne 'ARRAY');
2967   $self->{all_cache} = $data;
2968 }
2969
2970 =head2 clear_cache
2971
2972 =over 4
2973
2974 =item Arguments: none
2975
2976 =item Return Value: undef
2977
2978 =back
2979
2980 Clears the cache for the resultset.
2981
2982 =cut
2983
2984 sub clear_cache {
2985   shift->set_cache(undef);
2986 }
2987
2988 =head2 is_paged
2989
2990 =over 4
2991
2992 =item Arguments: none
2993
2994 =item Return Value: true, if the resultset has been paginated
2995
2996 =back
2997
2998 =cut
2999
3000 sub is_paged {
3001   my ($self) = @_;
3002   return !!$self->{attrs}{page};
3003 }
3004
3005 =head2 is_ordered
3006
3007 =over 4
3008
3009 =item Arguments: none
3010
3011 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3012
3013 =back
3014
3015 =cut
3016
3017 sub is_ordered {
3018   my ($self) = @_;
3019   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3020 }
3021
3022 =head2 related_resultset
3023
3024 =over 4
3025
3026 =item Arguments: $rel_name
3027
3028 =item Return Value: L<$resultset|/search>
3029
3030 =back
3031
3032 Returns a related resultset for the supplied relationship name.
3033
3034   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3035
3036 =cut
3037
3038 sub related_resultset {
3039   my ($self, $rel) = @_;
3040
3041   return $self->{related_resultsets}{$rel} ||= do {
3042     my $rsrc = $self->result_source;
3043     my $rel_info = $rsrc->relationship_info($rel);
3044
3045     $self->throw_exception(
3046       "search_related: result source '" . $rsrc->source_name .
3047         "' has no such relationship $rel")
3048       unless $rel_info;
3049
3050     my $attrs = $self->_chain_relationship($rel);
3051
3052     my $join_count = $attrs->{seen_join}{$rel};
3053
3054     my $alias = $self->result_source->storage
3055         ->relname_to_table_alias($rel, $join_count);
3056
3057     # since this is search_related, and we already slid the select window inwards
3058     # (the select/as attrs were deleted in the beginning), we need to flip all
3059     # left joins to inner, so we get the expected results
3060     # read the comment on top of the actual function to see what this does
3061     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3062
3063
3064     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3065     delete @{$attrs}{qw(result_class alias)};
3066
3067     my $related_cache;
3068
3069     if (my $cache = $self->get_cache) {
3070       $related_cache = [ map
3071         { @{$_->related_resultset($rel)->get_cache||[]} }
3072         @$cache
3073       ];
3074     }
3075
3076     my $rel_source = $rsrc->related_source($rel);
3077
3078     my $new = do {
3079
3080       # The reason we do this now instead of passing the alias to the
3081       # search_rs below is that if you wrap/overload resultset on the
3082       # source you need to know what alias it's -going- to have for things
3083       # to work sanely (e.g. RestrictWithObject wants to be able to add
3084       # extra query restrictions, and these may need to be $alias.)
3085
3086       my $rel_attrs = $rel_source->resultset_attributes;
3087       local $rel_attrs->{alias} = $alias;
3088
3089       $rel_source->resultset
3090                  ->search_rs(
3091                      undef, {
3092                        %$attrs,
3093                        where => $attrs->{where},
3094                    });
3095     };
3096     $new->set_cache($related_cache) if $related_cache;
3097     $new;
3098   };
3099 }
3100
3101 =head2 current_source_alias
3102
3103 =over 4
3104
3105 =item Arguments: none
3106
3107 =item Return Value: $source_alias
3108
3109 =back
3110
3111 Returns the current table alias for the result source this resultset is built
3112 on, that will be used in the SQL query. Usually it is C<me>.
3113
3114 Currently the source alias that refers to the result set returned by a
3115 L</search>/L</find> family method depends on how you got to the resultset: it's
3116 C<me> by default, but eg. L</search_related> aliases it to the related result
3117 source name (and keeps C<me> referring to the original result set). The long
3118 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3119 (and make this method unnecessary).
3120
3121 Thus it's currently necessary to use this method in predefined queries (see
3122 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3123 source alias of the current result set:
3124
3125   # in a result set class
3126   sub modified_by {
3127     my ($self, $user) = @_;
3128
3129     my $me = $self->current_source_alias;
3130
3131     return $self->search({
3132       "$me.modified" => $user->id,
3133     });
3134   }
3135
3136 =cut
3137
3138 sub current_source_alias {
3139   return (shift->{attrs} || {})->{alias} || 'me';
3140 }
3141
3142 =head2 as_subselect_rs
3143
3144 =over 4
3145
3146 =item Arguments: none
3147
3148 =item Return Value: L<$resultset|/search>
3149
3150 =back
3151
3152 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3153 "virtual view" by including it as a subquery within the from clause.  From this
3154 point on, any joined tables are inaccessible to ->search on the resultset (as if
3155 it were simply where-filtered without joins).  For example:
3156
3157  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3158
3159  # 'x' now pollutes the query namespace
3160
3161  # So the following works as expected
3162  my $ok_rs = $rs->search({'x.other' => 1});
3163
3164  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3165  # def) we look for one row with contradictory terms and join in another table
3166  # (aliased 'x_2') which we never use
3167  my $broken_rs = $rs->search({'x.name' => 'def'});
3168
3169  my $rs2 = $rs->as_subselect_rs;
3170
3171  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3172  my $not_joined_rs = $rs2->search({'x.other' => 1});
3173
3174  # works as expected: finds a 'table' row related to two x rows (abc and def)
3175  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3176
3177 Another example of when one might use this would be to select a subset of
3178 columns in a group by clause:
3179
3180  my $rs = $schema->resultset('Bar')->search(undef, {
3181    group_by => [qw{ id foo_id baz_id }],
3182  })->as_subselect_rs->search(undef, {
3183    columns => [qw{ id foo_id }]
3184  });
3185
3186 In the above example normally columns would have to be equal to the group by,
3187 but because we isolated the group by into a subselect the above works.
3188
3189 =cut
3190
3191 sub as_subselect_rs {
3192   my $self = shift;
3193
3194   my $attrs = $self->_resolved_attrs;
3195
3196   my $fresh_rs = (ref $self)->new (
3197     $self->result_source
3198   );
3199
3200   # these pieces will be locked in the subquery
3201   delete $fresh_rs->{cond};
3202   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3203
3204   return $fresh_rs->search( {}, {
3205     from => [{
3206       $attrs->{alias} => $self->as_query,
3207       -alias  => $attrs->{alias},
3208       -rsrc   => $self->result_source,
3209     }],
3210     alias => $attrs->{alias},
3211   });
3212 }
3213
3214 # This code is called by search_related, and makes sure there
3215 # is clear separation between the joins before, during, and
3216 # after the relationship. This information is needed later
3217 # in order to properly resolve prefetch aliases (any alias
3218 # with a relation_chain_depth less than the depth of the
3219 # current prefetch is not considered)
3220 #
3221 # The increments happen twice per join. An even number means a
3222 # relationship specified via a search_related, whereas an odd
3223 # number indicates a join/prefetch added via attributes
3224 #
3225 # Also this code will wrap the current resultset (the one we
3226 # chain to) in a subselect IFF it contains limiting attributes
3227 sub _chain_relationship {
3228   my ($self, $rel) = @_;
3229   my $source = $self->result_source;
3230   my $attrs = { %{$self->{attrs}||{}} };
3231
3232   # we need to take the prefetch the attrs into account before we
3233   # ->_resolve_join as otherwise they get lost - captainL
3234   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3235
3236   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3237
3238   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3239
3240   my $from;
3241   my @force_subq_attrs = qw/offset rows group_by having/;
3242
3243   if (
3244     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3245       ||
3246     $self->_has_resolved_attr (@force_subq_attrs)
3247   ) {
3248     # Nuke the prefetch (if any) before the new $rs attrs
3249     # are resolved (prefetch is useless - we are wrapping
3250     # a subquery anyway).
3251     my $rs_copy = $self->search;
3252     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3253       $rs_copy->{attrs}{join},
3254       delete $rs_copy->{attrs}{prefetch},
3255     );
3256
3257     $from = [{
3258       -rsrc   => $source,
3259       -alias  => $attrs->{alias},
3260       $attrs->{alias} => $rs_copy->as_query,
3261     }];
3262     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3263     $seen->{-relation_chain_depth} = 0;
3264   }
3265   elsif ($attrs->{from}) {  #shallow copy suffices
3266     $from = [ @{$attrs->{from}} ];
3267   }
3268   else {
3269     $from = [{
3270       -rsrc  => $source,
3271       -alias => $attrs->{alias},
3272       $attrs->{alias} => $source->from,
3273     }];
3274   }
3275
3276   my $jpath = ($seen->{-relation_chain_depth})
3277     ? $from->[-1][0]{-join_path}
3278     : [];
3279
3280   my @requested_joins = $source->_resolve_join(
3281     $join,
3282     $attrs->{alias},
3283     $seen,
3284     $jpath,
3285   );
3286
3287   push @$from, @requested_joins;
3288
3289   $seen->{-relation_chain_depth}++;
3290
3291   # if $self already had a join/prefetch specified on it, the requested
3292   # $rel might very well be already included. What we do in this case
3293   # is effectively a no-op (except that we bump up the chain_depth on
3294   # the join in question so we could tell it *is* the search_related)
3295   my $already_joined;
3296
3297   # we consider the last one thus reverse
3298   for my $j (reverse @requested_joins) {
3299     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3300     if ($rel eq $last_j) {
3301       $j->[0]{-relation_chain_depth}++;
3302       $already_joined++;
3303       last;
3304     }
3305   }
3306
3307   unless ($already_joined) {
3308     push @$from, $source->_resolve_join(
3309       $rel,
3310       $attrs->{alias},
3311       $seen,
3312       $jpath,
3313     );
3314   }
3315
3316   $seen->{-relation_chain_depth}++;
3317
3318   return {%$attrs, from => $from, seen_join => $seen};
3319 }
3320
3321 # FIXME - this needs to go live in Schema with the tree walker... or
3322 # something
3323 my $inflatemap_checker;
3324 $inflatemap_checker = sub {
3325   my ($rsrc, $relpaths) = @_;
3326
3327   my $rels;
3328
3329   for (@$relpaths) {
3330     $_ =~ /^ ( [^\.]+ ) \. (.+) $/x
3331       or next;
3332
3333     push @{$rels->{$1}}, $2;
3334   }
3335
3336   for my $rel (keys %$rels) {
3337     my $rel_rsrc = try {
3338       $rsrc->related_source ($rel)
3339     } catch {
3340     $rsrc->throw_exception(sprintf(
3341       "Inflation into non-existent relationship '%s' of '%s' requested, "
3342     . "check the inflation specification (columns/as) ending in '...%s.%s'",
3343       $rel,
3344       $rsrc->source_name,
3345       $rel,
3346       ( sort { length($a) <=> length ($b) } @{$rels->{$rel}} )[0],
3347     ))};
3348
3349     $inflatemap_checker->($rel_rsrc, $rels->{$rel});
3350   }
3351
3352   return;
3353 };
3354
3355 sub _resolved_attrs {
3356   my $self = shift;
3357   return $self->{_attrs} if $self->{_attrs};
3358
3359   my $attrs  = { %{ $self->{attrs} || {} } };
3360   my $source = $self->result_source;
3361   my $alias  = $attrs->{alias};
3362
3363   # default selection list
3364   $attrs->{columns} = [ $source->columns ]
3365     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3366
3367   # merge selectors together
3368   for (qw/columns select as/) {
3369     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3370       if $attrs->{$_} or $attrs->{"+$_"};
3371   }
3372
3373   # disassemble columns
3374   my (@sel, @as);
3375   if (my $cols = delete $attrs->{columns}) {
3376     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3377       if (ref $c eq 'HASH') {
3378         for my $as (sort keys %$c) {
3379           push @sel, $c->{$as};
3380           push @as, $as;
3381         }
3382       }
3383       else {
3384         push @sel, $c;
3385         push @as, $c;
3386       }
3387     }
3388   }
3389
3390   # when trying to weed off duplicates later do not go past this point -
3391   # everything added from here on is unbalanced "anyone's guess" stuff
3392   my $dedup_stop_idx = $#as;
3393
3394   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3395     if $attrs->{as};
3396   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3397     if $attrs->{select};
3398
3399   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3400   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3401
3402   # disqualify all $alias.col as-bits (inflate-map mandated)
3403   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3404
3405   # de-duplicate the result (remove *identical* select/as pairs)
3406   # and also die on duplicate {as} pointing to different {select}s
3407   # not using a c-style for as the condition is prone to shrinkage
3408   my $seen;
3409   my $i = 0;
3410   while ($i <= $dedup_stop_idx) {
3411     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3412       splice @sel, $i, 1;
3413       splice @as, $i, 1;
3414       $dedup_stop_idx--;
3415     }
3416     elsif ($seen->{$as[$i]}++) {
3417       $self->throw_exception(
3418         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3419       );
3420     }
3421     else {
3422       $i++;
3423     }
3424   }
3425
3426   # validate the user-supplied 'as' chain
3427   # folks get too confused by the (logical) exception message, need to
3428   # go to some lengths to clarify the text
3429   #
3430   # FIXME - this needs to go live in Schema with the tree walker... or
3431   # something
3432   $inflatemap_checker->($source, \@as);
3433
3434   $attrs->{select} = \@sel;
3435   $attrs->{as} = \@as;
3436
3437   $attrs->{from} ||= [{
3438     -rsrc   => $source,
3439     -alias  => $self->{attrs}{alias},
3440     $self->{attrs}{alias} => $source->from,
3441   }];
3442
3443   if ( $attrs->{join} || $attrs->{prefetch} ) {
3444
3445     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3446       if ref $attrs->{from} ne 'ARRAY';
3447
3448     my $join = (delete $attrs->{join}) || {};
3449
3450     if ( defined $attrs->{prefetch} ) {
3451       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3452     }
3453
3454     $attrs->{from} =    # have to copy here to avoid corrupting the original
3455       [
3456         @{ $attrs->{from} },
3457         $source->_resolve_join(
3458           $join,
3459           $alias,
3460           { %{ $attrs->{seen_join} || {} } },
3461           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3462             ? $attrs->{from}[-1][0]{-join_path}
3463             : []
3464           ,
3465         )
3466       ];
3467   }
3468
3469   if ( defined $attrs->{order_by} ) {
3470     $attrs->{order_by} = (
3471       ref( $attrs->{order_by} ) eq 'ARRAY'
3472       ? [ @{ $attrs->{order_by} } ]
3473       : [ $attrs->{order_by} || () ]
3474     );
3475   }
3476
3477   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3478     $attrs->{group_by} = [ $attrs->{group_by} ];
3479   }
3480
3481   # generate the distinct induced group_by early, as prefetch will be carried via a
3482   # subquery (since a group_by is present)
3483   if (delete $attrs->{distinct}) {
3484     if ($attrs->{group_by}) {
3485       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3486     }
3487     else {
3488       # distinct affects only the main selection part, not what prefetch may
3489       # add below.
3490       $attrs->{group_by} = $source->storage->_group_over_selection (
3491         $attrs->{from},
3492         $attrs->{select},
3493         $attrs->{order_by},
3494       );
3495     }
3496   }
3497
3498   # generate selections based on the prefetch helper
3499   my $prefetch;
3500   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3501     if defined $attrs->{prefetch};
3502
3503   if ($prefetch) {
3504
3505     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3506       if $attrs->{_dark_selector};
3507
3508     $attrs->{collapse} = 1;
3509
3510     # this is a separate structure (we don't look in {from} directly)
3511     # as the resolver needs to shift things off the lists to work
3512     # properly (identical-prefetches on different branches)
3513     my $join_map = {};
3514     if (ref $attrs->{from} eq 'ARRAY') {
3515
3516       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3517
3518       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3519         next unless $j->[0]{-alias};
3520         next unless $j->[0]{-join_path};
3521         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3522
3523         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3524
3525         my $p = $join_map;
3526         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3527         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3528       }
3529     }
3530
3531     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3532
3533     # we need to somehow mark which columns came from prefetch
3534     if (@prefetch) {
3535       my $sel_end = $#{$attrs->{select}};
3536       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3537     }
3538
3539     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3540     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3541   }
3542
3543   if ( ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3544     $attrs->{_single_resultclass_inflation} = 1;
3545     $attrs->{collapse} = 0;
3546   }
3547
3548   # run through the resulting joinstructure (starting from our current slot)
3549   # and unset collapse if proven unnesessary
3550   #
3551   # also while we are at it find out if the current root source has
3552   # been premultiplied by previous related_source chaining
3553   #
3554   # this allows to predict whether a root object with all other relation
3555   # data set to NULL is in fact unique
3556   if ($attrs->{collapse}) {
3557
3558     if (ref $attrs->{from} eq 'ARRAY') {
3559
3560       if (@{$attrs->{from}} <= 1) {
3561         # no joins - no collapse
3562         $attrs->{collapse} = 0;
3563       }
3564       else {
3565         # find where our table-spec starts
3566         my @fromlist = @{$attrs->{from}};
3567         while (@fromlist) {
3568           my $t = shift @fromlist;
3569
3570           my $is_multi;
3571           # me vs join from-spec distinction - a ref means non-root
3572           if (ref $t eq 'ARRAY') {
3573             $t = $t->[0];
3574             $is_multi ||= ! $t->{-is_single};
3575           }
3576           last if ($t->{-alias} && $t->{-alias} eq $alias);
3577           $attrs->{_main_source_premultiplied} ||= $is_multi;
3578         }
3579
3580         # no non-singles remaining, nor any premultiplication - nothing to collapse
3581         if (
3582           ! $attrs->{_main_source_premultiplied}
3583             and
3584           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3585         ) {
3586           $attrs->{collapse} = 0;
3587         }
3588       }
3589     }
3590
3591     else {
3592       # if we can not analyze the from - err on the side of safety
3593       $attrs->{_main_source_premultiplied} = 1;
3594     }
3595   }
3596
3597   # if both page and offset are specified, produce a combined offset
3598   # even though it doesn't make much sense, this is what pre 081xx has
3599   # been doing
3600   if (my $page = delete $attrs->{page}) {
3601     $attrs->{offset} =
3602       ($attrs->{rows} * ($page - 1))
3603             +
3604       ($attrs->{offset} || 0)
3605     ;
3606   }
3607
3608   return $self->{_attrs} = $attrs;
3609 }
3610
3611 sub _rollout_attr {
3612   my ($self, $attr) = @_;
3613
3614   if (ref $attr eq 'HASH') {
3615     return $self->_rollout_hash($attr);
3616   } elsif (ref $attr eq 'ARRAY') {
3617     return $self->_rollout_array($attr);
3618   } else {
3619     return [$attr];
3620   }
3621 }
3622
3623 sub _rollout_array {
3624   my ($self, $attr) = @_;
3625
3626   my @rolled_array;
3627   foreach my $element (@{$attr}) {
3628     if (ref $element eq 'HASH') {
3629       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3630     } elsif (ref $element eq 'ARRAY') {
3631       #  XXX - should probably recurse here
3632       push( @rolled_array, @{$self->_rollout_array($element)} );
3633     } else {
3634       push( @rolled_array, $element );
3635     }
3636   }
3637   return \@rolled_array;
3638 }
3639
3640 sub _rollout_hash {
3641   my ($self, $attr) = @_;
3642
3643   my @rolled_array;
3644   foreach my $key (keys %{$attr}) {
3645     push( @rolled_array, { $key => $attr->{$key} } );
3646   }
3647   return \@rolled_array;
3648 }
3649
3650 sub _calculate_score {
3651   my ($self, $a, $b) = @_;
3652
3653   if (defined $a xor defined $b) {
3654     return 0;
3655   }
3656   elsif (not defined $a) {
3657     return 1;
3658   }
3659
3660   if (ref $b eq 'HASH') {
3661     my ($b_key) = keys %{$b};
3662     if (ref $a eq 'HASH') {
3663       my ($a_key) = keys %{$a};
3664       if ($a_key eq $b_key) {
3665         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3666       } else {
3667         return 0;
3668       }
3669     } else {
3670       return ($a eq $b_key) ? 1 : 0;
3671     }
3672   } else {
3673     if (ref $a eq 'HASH') {
3674       my ($a_key) = keys %{$a};
3675       return ($b eq $a_key) ? 1 : 0;
3676     } else {
3677       return ($b eq $a) ? 1 : 0;
3678     }
3679   }
3680 }
3681
3682 sub _merge_joinpref_attr {
3683   my ($self, $orig, $import) = @_;
3684
3685   return $import unless defined($orig);
3686   return $orig unless defined($import);
3687
3688   $orig = $self->_rollout_attr($orig);
3689   $import = $self->_rollout_attr($import);
3690
3691   my $seen_keys;
3692   foreach my $import_element ( @{$import} ) {
3693     # find best candidate from $orig to merge $b_element into
3694     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3695     foreach my $orig_element ( @{$orig} ) {
3696       my $score = $self->_calculate_score( $orig_element, $import_element );
3697       if ($score > $best_candidate->{score}) {
3698         $best_candidate->{position} = $position;
3699         $best_candidate->{score} = $score;
3700       }
3701       $position++;
3702     }
3703     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3704     $import_key = '' if not defined $import_key;
3705
3706     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3707       push( @{$orig}, $import_element );
3708     } else {
3709       my $orig_best = $orig->[$best_candidate->{position}];
3710       # merge orig_best and b_element together and replace original with merged
3711       if (ref $orig_best ne 'HASH') {
3712         $orig->[$best_candidate->{position}] = $import_element;
3713       } elsif (ref $import_element eq 'HASH') {
3714         my ($key) = keys %{$orig_best};
3715         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3716       }
3717     }
3718     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3719   }
3720
3721   return @$orig ? $orig : ();
3722 }
3723
3724 {
3725   my $hm;
3726
3727   sub _merge_attr {
3728     $hm ||= do {
3729       require Hash::Merge;
3730       my $hm = Hash::Merge->new;
3731
3732       $hm->specify_behavior({
3733         SCALAR => {
3734           SCALAR => sub {
3735             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3736
3737             if ($defl xor $defr) {
3738               return [ $defl ? $_[0] : $_[1] ];
3739             }
3740             elsif (! $defl) {
3741               return [];
3742             }
3743             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3744               return [ $_[0] ];
3745             }
3746             else {
3747               return [$_[0], $_[1]];
3748             }
3749           },
3750           ARRAY => sub {
3751             return $_[1] if !defined $_[0];
3752             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3753             return [$_[0], @{$_[1]}]
3754           },
3755           HASH  => sub {
3756             return [] if !defined $_[0] and !keys %{$_[1]};
3757             return [ $_[1] ] if !defined $_[0];
3758             return [ $_[0] ] if !keys %{$_[1]};
3759             return [$_[0], $_[1]]
3760           },
3761         },
3762         ARRAY => {
3763           SCALAR => sub {
3764             return $_[0] if !defined $_[1];
3765             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3766             return [@{$_[0]}, $_[1]]
3767           },
3768           ARRAY => sub {
3769             my @ret = @{$_[0]} or return $_[1];
3770             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3771             my %idx = map { $_ => 1 } @ret;
3772             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3773             \@ret;
3774           },
3775           HASH => sub {
3776             return [ $_[1] ] if ! @{$_[0]};
3777             return $_[0] if !keys %{$_[1]};
3778             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3779             return [ @{$_[0]}, $_[1] ];
3780           },
3781         },
3782         HASH => {
3783           SCALAR => sub {
3784             return [] if !keys %{$_[0]} and !defined $_[1];
3785             return [ $_[0] ] if !defined $_[1];
3786             return [ $_[1] ] if !keys %{$_[0]};
3787             return [$_[0], $_[1]]
3788           },
3789           ARRAY => sub {
3790             return [] if !keys %{$_[0]} and !@{$_[1]};
3791             return [ $_[0] ] if !@{$_[1]};
3792             return $_[1] if !keys %{$_[0]};
3793             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3794             return [ $_[0], @{$_[1]} ];
3795           },
3796           HASH => sub {
3797             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3798             return [ $_[0] ] if !keys %{$_[1]};
3799             return [ $_[1] ] if !keys %{$_[0]};
3800             return [ $_[0] ] if $_[0] eq $_[1];
3801             return [ $_[0], $_[1] ];
3802           },
3803         }
3804       } => 'DBIC_RS_ATTR_MERGER');
3805       $hm;
3806     };
3807
3808     return $hm->merge ($_[1], $_[2]);
3809   }
3810 }
3811
3812 sub STORABLE_freeze {
3813   my ($self, $cloning) = @_;
3814   my $to_serialize = { %$self };
3815
3816   # A cursor in progress can't be serialized (and would make little sense anyway)
3817   # the parser can be regenerated (and can't be serialized)
3818   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3819
3820   # nor is it sensical to store a not-yet-fired-count pager
3821   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3822     delete $to_serialize->{pager};
3823   }
3824
3825   Storable::nfreeze($to_serialize);
3826 }
3827
3828 # need this hook for symmetry
3829 sub STORABLE_thaw {
3830   my ($self, $cloning, $serialized) = @_;
3831
3832   %$self = %{ Storable::thaw($serialized) };
3833
3834   $self;
3835 }
3836
3837
3838 =head2 throw_exception
3839
3840 See L<DBIx::Class::Schema/throw_exception> for details.
3841
3842 =cut
3843
3844 sub throw_exception {
3845   my $self=shift;
3846
3847   if (ref $self and my $rsrc = $self->result_source) {
3848     $rsrc->throw_exception(@_)
3849   }
3850   else {
3851     DBIx::Class::Exception->throw(@_);
3852   }
3853 }
3854
3855 1;
3856
3857 __END__
3858
3859 # XXX: FIXME: Attributes docs need clearing up
3860
3861 =head1 ATTRIBUTES
3862
3863 Attributes are used to refine a ResultSet in various ways when
3864 searching for data. They can be passed to any method which takes an
3865 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3866 L</count>.
3867
3868 Default attributes can be set on the result class using
3869 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3870 the CAVEATS on that feature before using it!)
3871
3872 These are in no particular order:
3873
3874 =head2 order_by
3875
3876 =over 4
3877
3878 =item Value: ( $order_by | \@order_by | \%order_by )
3879
3880 =back
3881
3882 Which column(s) to order the results by.
3883
3884 [The full list of suitable values is documented in
3885 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3886 common options.]
3887
3888 If a single column name, or an arrayref of names is supplied, the
3889 argument is passed through directly to SQL. The hashref syntax allows
3890 for connection-agnostic specification of ordering direction:
3891
3892  For descending order:
3893
3894   order_by => { -desc => [qw/col1 col2 col3/] }
3895
3896  For explicit ascending order:
3897
3898   order_by => { -asc => 'col' }
3899
3900 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3901 supported, although you are strongly encouraged to use the hashref
3902 syntax as outlined above.
3903
3904 =head2 columns
3905
3906 =over 4
3907
3908 =item Value: \@columns | \%columns | $column
3909
3910 =back
3911
3912 Shortcut to request a particular set of columns to be retrieved. Each
3913 column spec may be a string (a table column name), or a hash (in which
3914 case the key is the C<as> value, and the value is used as the C<select>
3915 expression). Adds C<me.> onto the start of any column without a C<.> in
3916 it and sets C<select> from that, then auto-populates C<as> from
3917 C<select> as normal. (You may also use the C<cols> attribute, as in
3918 earlier versions of DBIC.)
3919
3920 Essentially C<columns> does the same as L</select> and L</as>.
3921
3922     columns => [ 'foo', { bar => 'baz' } ]
3923
3924 is the same as
3925
3926     select => [qw/foo baz/],
3927     as => [qw/foo bar/]
3928
3929 =head2 +columns
3930
3931 =over 4
3932
3933 =item Value: \@columns
3934
3935 =back
3936
3937 Indicates additional columns to be selected from storage. Works the same
3938 as L</columns> but adds columns to the selection. (You may also use the
3939 C<include_columns> attribute, as in earlier versions of DBIC). For
3940 example:-
3941
3942   $schema->resultset('CD')->search(undef, {
3943     '+columns' => ['artist.name'],
3944     join => ['artist']
3945   });
3946
3947 would return all CDs and include a 'name' column to the information
3948 passed to object inflation. Note that the 'artist' is the name of the
3949 column (or relationship) accessor, and 'name' is the name of the column
3950 accessor in the related table.
3951
3952 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3953 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3954 unary plus operator before it.
3955
3956 =head2 include_columns
3957
3958 =over 4
3959
3960 =item Value: \@columns
3961
3962 =back
3963
3964 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3965
3966 =head2 select
3967
3968 =over 4
3969
3970 =item Value: \@select_columns
3971
3972 =back
3973
3974 Indicates which columns should be selected from the storage. You can use
3975 column names, or in the case of RDBMS back ends, function or stored procedure
3976 names:
3977
3978   $rs = $schema->resultset('Employee')->search(undef, {
3979     select => [
3980       'name',
3981       { count => 'employeeid' },
3982       { max => { length => 'name' }, -as => 'longest_name' }
3983     ]
3984   });
3985
3986   # Equivalent SQL
3987   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3988
3989 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3990 use L</select>, to instruct DBIx::Class how to store the result of the column.
3991 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3992 identifier aliasing. You can however alias a function, so you can use it in
3993 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3994 attribute> supplied as shown in the example above.
3995
3996 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3997 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3998 unary plus operator before it.
3999
4000 =head2 +select
4001
4002 =over 4
4003
4004 Indicates additional columns to be selected from storage.  Works the same as
4005 L</select> but adds columns to the default selection, instead of specifying
4006 an explicit list.
4007
4008 =back
4009
4010 =head2 as
4011
4012 =over 4
4013
4014 =item Value: \@inflation_names
4015
4016 =back
4017
4018 Indicates column names for object inflation. That is L</as> indicates the
4019 slot name in which the column value will be stored within the
4020 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4021 identifier by the C<get_column> method (or via the object accessor B<if one
4022 with the same name already exists>) as shown below. The L</as> attribute has
4023 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4024
4025   $rs = $schema->resultset('Employee')->search(undef, {
4026     select => [
4027       'name',
4028       { count => 'employeeid' },
4029       { max => { length => 'name' }, -as => 'longest_name' }
4030     ],
4031     as => [qw/
4032       name
4033       employee_count
4034       max_name_length
4035     /],
4036   });
4037
4038 If the object against which the search is performed already has an accessor
4039 matching a column name specified in C<as>, the value can be retrieved using
4040 the accessor as normal:
4041
4042   my $name = $employee->name();
4043
4044 If on the other hand an accessor does not exist in the object, you need to
4045 use C<get_column> instead:
4046
4047   my $employee_count = $employee->get_column('employee_count');
4048
4049 You can create your own accessors if required - see
4050 L<DBIx::Class::Manual::Cookbook> for details.
4051
4052 =head2 +as
4053
4054 =over 4
4055
4056 Indicates additional column names for those added via L</+select>. See L</as>.
4057
4058 =back
4059
4060 =head2 join
4061
4062 =over 4
4063
4064 =item Value: ($rel_name | \@rel_names | \%rel_names)
4065
4066 =back
4067
4068 Contains a list of relationships that should be joined for this query.  For
4069 example:
4070
4071   # Get CDs by Nine Inch Nails
4072   my $rs = $schema->resultset('CD')->search(
4073     { 'artist.name' => 'Nine Inch Nails' },
4074     { join => 'artist' }
4075   );
4076
4077 Can also contain a hash reference to refer to the other relation's relations.
4078 For example:
4079
4080   package MyApp::Schema::Track;
4081   use base qw/DBIx::Class/;
4082   __PACKAGE__->table('track');
4083   __PACKAGE__->add_columns(qw/trackid cd position title/);
4084   __PACKAGE__->set_primary_key('trackid');
4085   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4086   1;
4087
4088   # In your application
4089   my $rs = $schema->resultset('Artist')->search(
4090     { 'track.title' => 'Teardrop' },
4091     {
4092       join     => { cd => 'track' },
4093       order_by => 'artist.name',
4094     }
4095   );
4096
4097 You need to use the relationship (not the table) name in  conditions,
4098 because they are aliased as such. The current table is aliased as "me", so
4099 you need to use me.column_name in order to avoid ambiguity. For example:
4100
4101   # Get CDs from 1984 with a 'Foo' track
4102   my $rs = $schema->resultset('CD')->search(
4103     {
4104       'me.year' => 1984,
4105       'tracks.name' => 'Foo'
4106     },
4107     { join => 'tracks' }
4108   );
4109
4110 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4111 similarly for a third time). For e.g.
4112
4113   my $rs = $schema->resultset('Artist')->search({
4114     'cds.title'   => 'Down to Earth',
4115     'cds_2.title' => 'Popular',
4116   }, {
4117     join => [ qw/cds cds/ ],
4118   });
4119
4120 will return a set of all artists that have both a cd with title 'Down
4121 to Earth' and a cd with title 'Popular'.
4122
4123 If you want to fetch related objects from other tables as well, see L</prefetch>
4124 below.
4125
4126  NOTE: An internal join-chain pruner will discard certain joins while
4127  constructing the actual SQL query, as long as the joins in question do not
4128  affect the retrieved result. This for example includes 1:1 left joins
4129  that are not part of the restriction specification (WHERE/HAVING) nor are
4130  a part of the query selection.
4131
4132 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4133
4134 =head2 collapse
4135
4136 =over 4
4137
4138 =item Value: (0 | 1)
4139
4140 =back
4141
4142 When set to a true value, indicates that any rows fetched from joined has_many
4143 relationships are to be aggregated into the corresponding "parent" object. For
4144 example, the resultset:
4145
4146   my $rs = $schema->resultset('CD')->search({}, {
4147     '+columns' => [ qw/ tracks.title tracks.position / ],
4148     join => 'tracks',
4149     collapse => 1,
4150   });
4151
4152 While executing the following query:
4153
4154   SELECT me.*, tracks.title, tracks.position
4155     FROM cd me
4156     LEFT JOIN track tracks
4157       ON tracks.cdid = me.cdid
4158
4159 Will return only as many objects as there are rows in the CD source, even
4160 though the result of the query may span many rows. Each of these CD objects
4161 will in turn have multiple "Track" objects hidden behind the has_many
4162 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4163 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4164 product"), with each CD object containing exactly one of all fetched Track data.
4165
4166 When a collapse is requested on a non-ordered resultset, an order by some
4167 unique part of the main source (the left-most table) is inserted automatically.
4168 This is done so that the resultset is allowed to be "lazy" - calling
4169 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4170 object with all of its related data.
4171
4172 If an L</order_by> is already declared, and orders the resultset in a way that
4173 makes collapsing as described above impossible (e.g. C<< ORDER BY
4174 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4175 switch to "eager" mode and slurp the entire resultset before consturcting the
4176 first object returned by L</next>.
4177
4178 Setting this attribute on a resultset that does not join any has_many
4179 relations is a no-op.
4180
4181 For a more in-depth discussion, see L</PREFETCHING>.
4182
4183 =head2 prefetch
4184
4185 =over 4
4186
4187 =item Value: ($rel_name | \@rel_names | \%rel_names)
4188
4189 =back
4190
4191 This attribute is a shorthand for specifying a L</join> spec, adding all
4192 columns from the joined related sources as L</+columns> and setting
4193 L</collapse> to a true value. For example, the following two queries are
4194 equivalent:
4195
4196   my $rs = $schema->resultset('Artist')->search({}, {
4197     prefetch => { cds => ['genre', 'tracks' ] },
4198   });
4199
4200 and
4201
4202   my $rs = $schema->resultset('Artist')->search({}, {
4203     join => { cds => ['genre', 'tracks' ] },
4204     collapse => 1,
4205     '+columns' => [
4206       (map
4207         { +{ "cds.$_" => "cds.$_" } }
4208         $schema->source('Artist')->related_source('cds')->columns
4209       ),
4210       (map
4211         { +{ "cds.genre.$_" => "genre.$_" } }
4212         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4213       ),
4214       (map
4215         { +{ "cds.tracks.$_" => "tracks.$_" } }
4216         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4217       ),
4218     ],
4219   });
4220
4221 Both producing the following SQL:
4222
4223   SELECT  me.artistid, me.name, me.rank, me.charfield,
4224           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4225           genre.genreid, genre.name,
4226           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4227     FROM artist me
4228     LEFT JOIN cd cds
4229       ON cds.artist = me.artistid
4230     LEFT JOIN genre genre
4231       ON genre.genreid = cds.genreid
4232     LEFT JOIN track tracks
4233       ON tracks.cd = cds.cdid
4234   ORDER BY me.artistid
4235
4236 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4237 the arguments are properly merged and generally do the right thing. For
4238 example, you may want to do the following:
4239
4240   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4241     { 'genre.genreid' => undef },
4242     {
4243       join => { cds => 'genre' },
4244       prefetch => 'cds',
4245     }
4246   );
4247
4248 Which generates the following SQL:
4249
4250   SELECT  me.artistid, me.name, me.rank, me.charfield,
4251           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4252     FROM artist me
4253     LEFT JOIN cd cds
4254       ON cds.artist = me.artistid
4255     LEFT JOIN genre genre
4256       ON genre.genreid = cds.genreid
4257   WHERE genre.genreid IS NULL
4258   ORDER BY me.artistid
4259
4260 For a more in-depth discussion, see L</PREFETCHING>.
4261
4262 =head2 alias
4263
4264 =over 4
4265
4266 =item Value: $source_alias
4267
4268 =back
4269
4270 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4271 nested search queries (sub-SELECTs) might need specific aliases set to
4272 reference inner queries.  For example:
4273
4274    my $q = $rs
4275       ->related_resultset('CDs')
4276       ->related_resultset('Tracks')
4277       ->search({
4278          'track.id' => { -ident => 'none_search.id' },
4279       })
4280       ->as_query;
4281
4282    my $ids = $self->search({
4283       -not_exists => $q,
4284    }, {
4285       alias    => 'none_search',
4286       group_by => 'none_search.id',
4287    })->get_column('id')->as_query;
4288
4289    $self->search({ id => { -in => $ids } })
4290
4291 This attribute is directly tied to L</current_source_alias>.
4292
4293 =head2 page
4294
4295 =over 4
4296
4297 =item Value: $page
4298
4299 =back
4300
4301 Makes the resultset paged and specifies the page to retrieve. Effectively
4302 identical to creating a non-pages resultset and then calling ->page($page)
4303 on it.
4304
4305 If L</rows> attribute is not specified it defaults to 10 rows per page.
4306
4307 When you have a paged resultset, L</count> will only return the number
4308 of rows in the page. To get the total, use the L</pager> and call
4309 C<total_entries> on it.
4310
4311 =head2 rows
4312
4313 =over 4
4314
4315 =item Value: $rows
4316
4317 =back
4318
4319 Specifies the maximum number of rows for direct retrieval or the number of
4320 rows per page if the page attribute or method is used.
4321
4322 =head2 offset
4323
4324 =over 4
4325
4326 =item Value: $offset
4327
4328 =back
4329
4330 Specifies the (zero-based) row number for the  first row to be returned, or the
4331 of the first row of the first page if paging is used.
4332
4333 =head2 software_limit
4334
4335 =over 4
4336
4337 =item Value: (0 | 1)
4338
4339 =back
4340
4341 When combined with L</rows> and/or L</offset> the generated SQL will not
4342 include any limit dialect stanzas. Instead the entire result will be selected
4343 as if no limits were specified, and DBIC will perform the limit locally, by
4344 artificially advancing and finishing the resulting L</cursor>.
4345
4346 This is the recommended way of performing resultset limiting when no sane RDBMS
4347 implementation is available (e.g.
4348 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4349 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4350
4351 =head2 group_by
4352
4353 =over 4
4354
4355 =item Value: \@columns
4356
4357 =back
4358
4359 A arrayref of columns to group by. Can include columns of joined tables.
4360
4361   group_by => [qw/ column1 column2 ... /]
4362
4363 =head2 having
4364
4365 =over 4
4366
4367 =item Value: $condition
4368
4369 =back
4370
4371 HAVING is a select statement attribute that is applied between GROUP BY and
4372 ORDER BY. It is applied to the after the grouping calculations have been
4373 done.
4374
4375   having => { 'count_employee' => { '>=', 100 } }
4376
4377 or with an in-place function in which case literal SQL is required:
4378
4379   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4380
4381 =head2 distinct
4382
4383 =over 4
4384
4385 =item Value: (0 | 1)
4386
4387 =back
4388
4389 Set to 1 to group by all columns. If the resultset already has a group_by
4390 attribute, this setting is ignored and an appropriate warning is issued.
4391
4392 =head2 where
4393
4394 =over 4
4395
4396 Adds to the WHERE clause.
4397
4398   # only return rows WHERE deleted IS NULL for all searches
4399   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4400
4401 Can be overridden by passing C<< { where => undef } >> as an attribute
4402 to a resultset.
4403
4404 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4405
4406 =back
4407
4408 =head2 cache
4409
4410 Set to 1 to cache search results. This prevents extra SQL queries if you
4411 revisit rows in your ResultSet:
4412
4413   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4414
4415   while( my $artist = $resultset->next ) {
4416     ... do stuff ...
4417   }
4418
4419   $rs->first; # without cache, this would issue a query
4420
4421 By default, searches are not cached.
4422
4423 For more examples of using these attributes, see
4424 L<DBIx::Class::Manual::Cookbook>.
4425
4426 =head2 for
4427
4428 =over 4
4429
4430 =item Value: ( 'update' | 'shared' | \$scalar )
4431
4432 =back
4433
4434 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4435 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4436 query.
4437
4438 =head1 PREFETCHING
4439
4440 DBIx::Class supports arbitrary related data prefetching from multiple related
4441 sources. Any combination of relationship types and column sets are supported.
4442 If L<collapsing|/collapse> is requested, there is an additional requirement of
4443 selecting enough data to make every individual object uniquely identifiable.
4444
4445 Here are some more involved examples, based on the following relationship map:
4446
4447   # Assuming:
4448   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4449   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4450   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4451
4452   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4453
4454   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4455
4456
4457
4458   my $rs = $schema->resultset('Tag')->search(
4459     undef,
4460     {
4461       prefetch => {
4462         cd => 'artist'
4463       }
4464     }
4465   );
4466
4467 The initial search results in SQL like the following:
4468
4469   SELECT tag.*, cd.*, artist.* FROM tag
4470   JOIN cd ON tag.cd = cd.cdid
4471   JOIN artist ON cd.artist = artist.artistid
4472
4473 L<DBIx::Class> has no need to go back to the database when we access the
4474 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4475 case.
4476
4477 Simple prefetches will be joined automatically, so there is no need
4478 for a C<join> attribute in the above search.
4479
4480 The L</prefetch> attribute can be used with any of the relationship types
4481 and multiple prefetches can be specified together. Below is a more complex
4482 example that prefetches a CD's artist, its liner notes (if present),
4483 the cover image, the tracks on that CD, and the guests on those
4484 tracks.
4485
4486   my $rs = $schema->resultset('CD')->search(
4487     undef,
4488     {
4489       prefetch => [
4490         { artist => 'record_label'},  # belongs_to => belongs_to
4491         'liner_note',                 # might_have
4492         'cover_image',                # has_one
4493         { tracks => 'guests' },       # has_many => has_many
4494       ]
4495     }
4496   );
4497
4498 This will produce SQL like the following:
4499
4500   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4501          tracks.*, guests.*
4502     FROM cd me
4503     JOIN artist artist
4504       ON artist.artistid = me.artistid
4505     JOIN record_label record_label
4506       ON record_label.labelid = artist.labelid
4507     LEFT JOIN track tracks
4508       ON tracks.cdid = me.cdid
4509     LEFT JOIN guest guests
4510       ON guests.trackid = track.trackid
4511     LEFT JOIN liner_notes liner_note
4512       ON liner_note.cdid = me.cdid
4513     JOIN cd_artwork cover_image
4514       ON cover_image.cdid = me.cdid
4515   ORDER BY tracks.cd
4516
4517 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4518 C<tracks>, and C<guests> of the CD will all be available through the
4519 relationship accessors without the need for additional queries to the
4520 database.
4521
4522 =head3 CAVEATS
4523
4524 Prefetch does a lot of deep magic. As such, it may not behave exactly
4525 as you might expect.
4526
4527 =over 4
4528
4529 =item *
4530
4531 Prefetch uses the L</cache> to populate the prefetched relationships. This
4532 may or may not be what you want.
4533
4534 =item *
4535
4536 If you specify a condition on a prefetched relationship, ONLY those
4537 rows that match the prefetched condition will be fetched into that relationship.
4538 This means that adding prefetch to a search() B<may alter> what is returned by
4539 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4540
4541   my $artist_rs = $schema->resultset('Artist')->search({
4542       'cds.year' => 2008,
4543   }, {
4544       join => 'cds',
4545   });
4546
4547   my $count = $artist_rs->first->cds->count;
4548
4549   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4550
4551   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4552
4553   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4554
4555 That cmp_ok() may or may not pass depending on the datasets involved. In other
4556 words the C<WHERE> condition would apply to the entire dataset, just like
4557 it would in regular SQL. If you want to add a condition only to the "right side"
4558 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4559 condition|DBIx::Class::Relationship::Base/condition>
4560
4561 =back
4562
4563 =head1 DBIC BIND VALUES
4564
4565 Because DBIC may need more information to bind values than just the column name
4566 and value itself, it uses a special format for both passing and receiving bind
4567 values.  Each bind value should be composed of an arrayref of
4568 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4569
4570 =over 4
4571
4572 =item dbd_attrs
4573
4574 If present (in any form), this is what is being passed directly to bind_param.
4575 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4576 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4577
4578 If this is specified, all other bind options described below are ignored.
4579
4580 =item sqlt_datatype
4581
4582 If present, this is used to infer the actual bind attribute by passing to
4583 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4584 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4585
4586 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4587 currently drivers are expected to "Do the Right Thing" when given a common
4588 datatype name.  (Not ideal, but that's what we got at this point.)
4589
4590 =item sqlt_size
4591
4592 Currently used to correctly allocate buffers for bind_param_inout().
4593 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4594 or to a sensible value based on the "data_type".
4595
4596 =item dbic_colname
4597
4598 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4599 explicitly specified they are never overriden).  Also used by some weird DBDs,
4600 where the column name should be available at bind_param time (e.g. Oracle).
4601
4602 =back
4603
4604 For backwards compatibility and convenience, the following shortcuts are
4605 supported:
4606
4607   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4608   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4609   [ undef,   $val ] === [ {}, $val ]
4610
4611 =head1 AUTHOR AND CONTRIBUTORS
4612
4613 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4614
4615 =head1 LICENSE
4616
4617 You may distribute this code under the same terms as Perl itself.
4618