lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs   = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 EXAMPLES
  77
  78 =head2 Chaining resultsets
  79
  80 Let's say you've got a query that needs to be run to return some data
  81 to the user. But, you have an authorization system in place that
  82 prevents certain users from seeing certain information. So, you want
  83 to construct the basic query in one method, but add constraints to it in
  84 another.
  85
  86   sub get_data {
  87     my $self = shift;
  88     my $request = $self->get_request; # Get a request object somehow.
  89     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  90
  91     my $cd_rs = $schema->resultset('CD')->search({
  92       title => $request->param('title'),
  93       year => $request->param('year'),
  94     });
  95
  96     $cd_rs = $self->apply_security_policy( $cd_rs );
  97
  98     return $cd_rs->all();
  99   }
 100
 101   sub apply_security_policy {
 102     my $self = shift;
 103     my ($rs) = @_;
 104
 105     return $rs->search({
 106       subversive => 0,
 107     });
 108   }
 109
 110 =head3 Resolving conditions and attributes
 111
 112 When a resultset is chained from another resultset, conditions and
 113 attributes with the same keys need resolving.
 114
 115 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 116 into the existing ones from the original resultset.
 117
 118 The L</where> and L</having> attributes, and any search conditions, are
 119 merged with an SQL C<AND> to the existing condition from the original
 120 resultset.
 121
 122 All other attributes are overridden by any new ones supplied in the
 123 search attributes.
 124
 125 =head2 Multiple queries
 126
 127 Since a resultset just defines a query, you can do all sorts of
 128 things with it with the same object.
 129
 130   # Don't hit the DB yet.
 131   my $cd_rs = $schema->resultset('CD')->search({
 132     title => 'something',
 133     year => 2009,
 134   });
 135
 136   # Each of these hits the DB individually.
 137   my $count = $cd_rs->count;
 138   my $most_recent = $cd_rs->get_column('date_released')->max();
 139   my @records = $cd_rs->all;
 140
 141 And it's not just limited to SELECT statements.
 142
 143   $cd_rs->delete();
 144
 145 This is even cooler:
 146
 147   $cd_rs->create({ artist => 'Fred' });
 148
 149 Which is the same as:
 150
 151   $schema->resultset('CD')->create({
 152     title => 'something',
 153     year => 2009,
 154     artist => 'Fred'
 155   });
 156
 157 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 158
 159 =head1 METHODS
 160
 161 =head2 new
 162
 163 =over 4
 164
 165 =item Arguments: $source, \%$attrs
 166
 167 =item Return Value: $rs
 168
 169 =back
 170
 171 The resultset constructor. Takes a source object (usually a
 172 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 173 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 174 executed as needed by the other methods.
 175
 176 Generally you won't need to construct a resultset manually.  You'll
 177 automatically get one from e.g. a L</search> called in scalar context:
 178
 179   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 180
 181 IMPORTANT: If called on an object, proxies to new_result instead so
 182
 183   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 184
 185 will return a CD object, not a ResultSet.
 186
 187 =cut
 188
 189 sub new {
 190   my $class = shift;
 191   return $class->new_result(@_) if ref $class;
 192
 193   my ($source, $attrs) = @_;
 194   $source = $source->resolve
 195     if $source->isa('DBIx::Class::ResultSourceHandle');
 196   $attrs = { %{$attrs||{}} };
 197
 198   if ($attrs->{page}) {
 199     $attrs->{rows} ||= 10;
 200   }
 201
 202   $attrs->{alias} ||= 'me';
 203
 204   my $self = bless {
 205     result_source => $source,
 206     cond => $attrs->{where},
 207     pager => undef,
 208     attrs => $attrs,
 209   }, $class;
 210
 211   $self->result_class(
 212     $attrs->{result_class} || $source->result_class
 213   );
 214
 215   $self;
 216 }
 217
 218 =head2 search
 219
 220 =over 4
 221
 222 =item Arguments: $cond, \%attrs?
 223
 224 =item Return Value: $resultset (scalar context), @row_objs (list context)
 225
 226 =back
 227
 228   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 229   my $new_rs = $cd_rs->search({ year => 2005 });
 230
 231   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 232                  # year = 2005 OR year = 2004
 233
 234 If you need to pass in additional attributes but no additional condition,
 235 call it as C<search(undef, \%attrs)>.
 236
 237   # "SELECT name, artistid FROM $artist_table"
 238   my @all_artists = $schema->resultset('Artist')->search(undef, {
 239     columns => [qw/name artistid/],
 240   });
 241
 242 For a list of attributes that can be passed to C<search>, see
 243 L</ATTRIBUTES>. For more examples of using this function, see
 244 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 245 documentation for the first argument, see L<SQL::Abstract>.
 246
 247 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 248
 249 =head3 CAVEAT
 250
 251 Note that L</search> does not process/deflate any of the values passed in the
 252 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 253 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 254 manually that any value passed to this method will stringify to something the
 255 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 256 objects, for more info see:
 257 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
 258
 259 =cut
 260
 261 sub search {
 262   my $self = shift;
 263   my $rs = $self->search_rs( @_ );
 264
 265   if (wantarray) {
 266     return $rs->all;
 267   }
 268   elsif (defined wantarray) {
 269     return $rs;
 270   }
 271   else {
 272     # we can be called by a relationship helper, which in
 273     # turn may be called in void context due to some braindead
 274     # overload or whatever else the user decided to be clever
 275     # at this particular day. Thus limit the exception to
 276     # external code calls only
 277     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 278       if (caller)[0] !~ /^\QDBIx::Class::/;
 279
 280     return ();
 281   }
 282 }
 283
 284 =head2 search_rs
 285
 286 =over 4
 287
 288 =item Arguments: $cond, \%attrs?
 289
 290 =item Return Value: $resultset
 291
 292 =back
 293
 294 This method does the same exact thing as search() except it will
 295 always return a resultset, even in list context.
 296
 297 =cut
 298
 299 my $callsites_warned;
 300 sub search_rs {
 301   my $self = shift;
 302
 303   # Special-case handling for (undef, undef).
 304   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 305     @_ = ();
 306   }
 307
 308   my $call_attrs = {};
 309   if (@_ > 1) {
 310     if (ref $_[-1] eq 'HASH') {
 311       # copy for _normalize_selection
 312       $call_attrs = { %{ pop @_ } };
 313     }
 314     elsif (! defined $_[-1] ) {
 315       pop @_;   # search({}, undef)
 316     }
 317   }
 318
 319   # see if we can keep the cache (no $rs changes)
 320   my $cache;
 321   my %safe = (alias => 1, cache => 1);
 322   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 323     ! defined $_[0]
 324       or
 325     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 326       or
 327     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 328   )) {
 329     $cache = $self->get_cache;
 330   }
 331
 332   my $rsrc = $self->result_source;
 333
 334   my $old_attrs = { %{$self->{attrs}} };
 335   my $old_having = delete $old_attrs->{having};
 336   my $old_where = delete $old_attrs->{where};
 337
 338   my $new_attrs = { %$old_attrs };
 339
 340   # take care of call attrs (only if anything is changing)
 341   if (keys %$call_attrs) {
 342
 343     $self->throw_exception ('_trailing_select is not a public attribute - do not use it in search()')
 344       if ( exists $call_attrs->{_trailing_select} or exists $call_attrs->{'+_trailing_select'} );
 345
 346     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns _trailing_select +_trailing_select/;
 347
 348     # Normalize the selector list (operates on the passed-in attr structure)
 349     # Need to do it on every chain instead of only once on _resolved_attrs, in
 350     # order to separate 'as'-ed from blind 'select's
 351     $self->_normalize_selection ($call_attrs);
 352
 353     # start with blind overwriting merge, exclude selector attrs
 354     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 355     delete @{$new_attrs}{@selector_attrs};
 356
 357     # reset the current selector list if new selectors are supplied
 358     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 359       delete @{$old_attrs}{@selector_attrs};
 360     }
 361
 362     for (@selector_attrs) {
 363       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 364         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 365     }
 366
 367     # older deprecated name, use only if {columns} is not there
 368     if (my $c = delete $new_attrs->{cols}) {
 369       if ($new_attrs->{columns}) {
 370         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 371       }
 372       else {
 373         $new_attrs->{columns} = $c;
 374       }
 375     }
 376
 377
 378     # join/prefetch use their own crazy merging heuristics
 379     foreach my $key (qw/join prefetch/) {
 380       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 381         if exists $call_attrs->{$key};
 382     }
 383
 384     # stack binds together
 385     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 386   }
 387
 388
 389   # rip apart the rest of @_, parse a condition
 390   my $call_cond = do {
 391
 392     if (ref $_[0] eq 'HASH') {
 393       (keys %{$_[0]}) ? $_[0] : undef
 394     }
 395     elsif (@_ == 1) {
 396       $_[0]
 397     }
 398     elsif (@_ % 2) {
 399       $self->throw_exception('Odd number of arguments to search')
 400     }
 401     else {
 402       +{ @_ }
 403     }
 404
 405   } if @_;
 406
 407   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 408     # determine callsite obeying Carp::Clan rules (fucking ugly but don't have better ideas)
 409     my $callsite = do {
 410       my $w;
 411       local $SIG{__WARN__} = sub { $w = shift };
 412       carp;
 413       $w
 414     };
 415     carp 'search( %condition ) is deprecated, use search( \%condition ) instead'
 416       unless $callsites_warned->{$callsite}++;
 417   }
 418
 419   for ($old_where, $call_cond) {
 420     if (defined $_) {
 421       $new_attrs->{where} = $self->_stack_cond (
 422         $_, $new_attrs->{where}
 423       );
 424     }
 425   }
 426
 427   if (defined $old_having) {
 428     $new_attrs->{having} = $self->_stack_cond (
 429       $old_having, $new_attrs->{having}
 430     )
 431   }
 432
 433   my $rs = (ref $self)->new($rsrc, $new_attrs);
 434
 435   $rs->set_cache($cache) if ($cache);
 436
 437   return $rs;
 438 }
 439
 440 sub _normalize_selection {
 441   my ($self, $attrs) = @_;
 442
 443   # legacy syntax
 444   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 445     if exists $attrs->{include_columns};
 446
 447   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 448   # delay the decision on whether to use a default select list ($rsrc->columns)
 449   # allowing stuff like the remove_columns helper to work
 450   #
 451   # select/as +select/+as pairs need special handling - the amount of select/as
 452   # elements in each pair does *not* have to be equal (think multicolumn
 453   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 454   # supplied at all) - try to infer the alias, either from the -as parameter
 455   # of the selector spec, or use the parameter whole if it looks like a column
 456   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 457   # is ok as well), but transport it over a separate attribute to make sure it is
 458   # the last thing in the select list, thus unable to throw off the corresponding
 459   # 'as' chain
 460   for my $pref ('', '+') {
 461
 462     my ($sel, $as) = map {
 463       my $key = "${pref}${_}";
 464
 465       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 466         ? @{$attrs->{$key}}
 467         : $attrs->{$key} || ()
 468       ];
 469       delete $attrs->{$key};
 470       $val;
 471     } qw/select as/;
 472
 473     if (! @$as and ! @$sel ) {
 474       next;
 475     }
 476     elsif (@$as and ! @$sel) {
 477       $self->throw_exception(
 478         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 479       );
 480     }
 481     elsif( ! @$as ) {
 482       # no as part supplied at all - try to deduce
 483       # if any @$as has been supplied we assume the user knows what (s)he is doing
 484       # and blindly keep stacking up pieces
 485       my (@new_sel, @new_trailing);
 486       for (@$sel) {
 487         if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 488           push @$as, $_->{-as};
 489           push @new_sel, $_;
 490         }
 491         # assume any plain no-space, no-parenthesis string to be a column spec
 492         # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 493         elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 494           push @$as, $_;
 495           push @new_sel, $_;
 496         }
 497         # if all else fails - shove the selection to the trailing stack and move on
 498         else {
 499           push @new_trailing, $_;
 500         }
 501       }
 502
 503       @$sel = @new_sel;
 504       $attrs->{"${pref}_trailing_select"} = $self->_merge_attr($attrs->{"${pref}_trailing_select"}, \@new_trailing)
 505         if @new_trailing;
 506     }
 507     elsif (@$as < @$sel) {
 508       $self->throw_exception(
 509         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 510       );
 511     }
 512
 513     # now see what the result for this pair looks like:
 514     if (@$as == @$sel) {
 515
 516       # if balanced - treat as a columns entry
 517       $attrs->{"${pref}columns"} = $self->_merge_attr(
 518         $attrs->{"${pref}columns"},
 519         [ map { +{ $as->[$_] => $sel->[$_] } } ( 0 .. $#$as ) ]
 520       );
 521     }
 522     else {
 523       # unbalanced - shove in select/as, not subject to deduplication in _resolved_attrs
 524       $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 525       $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 526     }
 527   }
 528
 529 }
 530
 531 sub _stack_cond {
 532   my ($self, $left, $right) = @_;
 533   if (defined $left xor defined $right) {
 534     return defined $left ? $left : $right;
 535   }
 536   elsif (defined $left) {
 537     return { -and => [ map
 538       { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 539       ($left, $right)
 540     ]};
 541   }
 542
 543   return undef;
 544 }
 545
 546 =head2 search_literal
 547
 548 =over 4
 549
 550 =item Arguments: $sql_fragment, @bind_values
 551
 552 =item Return Value: $resultset (scalar context), @row_objs (list context)
 553
 554 =back
 555
 556   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 557   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 558
 559 Pass a literal chunk of SQL to be added to the conditional part of the
 560 resultset query.
 561
 562 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 563 only be used in that context. C<search_literal> is a convenience method.
 564 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 565 columns are bound correctly, use C<search>.
 566
 567 Example of how to use C<search> instead of C<search_literal>
 568
 569   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 570   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 571
 572
 573 See L<DBIx::Class::Manual::Cookbook/Searching> and
 574 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 575 require C<search_literal>.
 576
 577 =cut
 578
 579 sub search_literal {
 580   my ($self, $sql, @bind) = @_;
 581   my $attr;
 582   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 583     $attr = pop @bind;
 584   }
 585   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 586 }
 587
 588 =head2 find
 589
 590 =over 4
 591
 592 =item Arguments: \%columns_values | @pk_values, \%attrs?
 593
 594 =item Return Value: $row_object | undef
 595
 596 =back
 597
 598 Finds and returns a single row based on supplied criteria. Takes either a
 599 hashref with the same format as L</create> (including inference of foreign
 600 keys from related objects), or a list of primary key values in the same
 601 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 602 declaration on the L</result_source>.
 603
 604 In either case an attempt is made to combine conditions already existing on
 605 the resultset with the condition passed to this method.
 606
 607 To aid with preparing the correct query for the storage you may supply the
 608 C<key> attribute, which is the name of a
 609 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 610 unique constraint corresponding to the
 611 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 612 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 613 to construct a query that satisfies the named unique constraint fully (
 614 non-NULL values for each column member of the constraint) an exception is
 615 thrown.
 616
 617 If no C<key> is specified, the search is carried over all unique constraints
 618 which are fully defined by the available condition.
 619
 620 If no such constraint is found, C<find> currently defaults to a simple
 621 C<< search->(\%column_values) >> which may or may not do what you expect.
 622 Note that this fallback behavior may be deprecated in further versions. If
 623 you need to search with arbitrary conditions - use L</search>. If the query
 624 resulting from this fallback produces more than one row, a warning to the
 625 effect is issued, though only the first row is constructed and returned as
 626 C<$row_object>.
 627
 628 In addition to C<key>, L</find> recognizes and applies standard
 629 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 630
 631 Note that if you have extra concerns about the correctness of the resulting
 632 query you need to specify the C<key> attribute and supply the entire condition
 633 as an argument to find (since it is not always possible to perform the
 634 combination of the resultset condition with the supplied one, especially if
 635 the resultset condition contains literal sql).
 636
 637 For example, to find a row by its primary key:
 638
 639   my $cd = $schema->resultset('CD')->find(5);
 640
 641 You can also find a row by a specific unique constraint:
 642
 643   my $cd = $schema->resultset('CD')->find(
 644     {
 645       artist => 'Massive Attack',
 646       title  => 'Mezzanine',
 647     },
 648     { key => 'cd_artist_title' }
 649   );
 650
 651 See also L</find_or_create> and L</update_or_create>.
 652
 653 =cut
 654
 655 sub find {
 656   my $self = shift;
 657   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 658
 659   my $rsrc = $self->result_source;
 660
 661   # Parse out the condition from input
 662   my $call_cond;
 663   if (ref $_[0] eq 'HASH') {
 664     $call_cond = { %{$_[0]} };
 665   }
 666   else {
 667     my $constraint = exists $attrs->{key} ? $attrs->{key} : 'primary';
 668     my @c_cols = $rsrc->unique_constraint_columns($constraint);
 669
 670     $self->throw_exception(
 671       "No constraint columns, maybe a malformed '$constraint' constraint?"
 672     ) unless @c_cols;
 673
 674     $self->throw_exception (
 675       'find() expects either a column/value hashref, or a list of values '
 676     . "corresponding to the columns of the specified unique constraint '$constraint'"
 677     ) unless @c_cols == @_;
 678
 679     $call_cond = {};
 680     @{$call_cond}{@c_cols} = @_;
 681   }
 682
 683   my %related;
 684   for my $key (keys %$call_cond) {
 685     if (
 686       my $keyref = ref($call_cond->{$key})
 687         and
 688       my $relinfo = $rsrc->relationship_info($key)
 689     ) {
 690       my $val = delete $call_cond->{$key};
 691
 692       next if $keyref eq 'ARRAY'; # has_many for multi_create
 693
 694       my $rel_q = $rsrc->_resolve_condition(
 695         $relinfo->{cond}, $val, $key
 696       );
 697       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 698       @related{keys %$rel_q} = values %$rel_q;
 699     }
 700   }
 701
 702   # relationship conditions take precedence (?)
 703   @{$call_cond}{keys %related} = values %related;
 704
 705   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 706   my $final_cond;
 707   if (exists $attrs->{key}) {
 708     $final_cond = $self->_qualify_cond_columns (
 709
 710       $self->_build_unique_cond (
 711         $attrs->{key},
 712         $call_cond,
 713       ),
 714
 715       $alias,
 716     );
 717   }
 718   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 719     # This means that we got here after a merger of relationship conditions
 720     # in ::Relationship::Base::search_related (the row method), and furthermore
 721     # the relationship is of the 'single' type. This means that the condition
 722     # provided by the relationship (already attached to $self) is sufficient,
 723     # as there can be only one row in the database that would satisfy the
 724     # relationship
 725   }
 726   else {
 727     # no key was specified - fall down to heuristics mode:
 728     # run through all unique queries registered on the resultset, and
 729     # 'OR' all qualifying queries together
 730     my (@unique_queries, %seen_column_combinations);
 731     for my $c_name ($rsrc->unique_constraint_names) {
 732       next if $seen_column_combinations{
 733         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 734       }++;
 735
 736       push @unique_queries, try {
 737         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 738       } || ();
 739     }
 740
 741     $final_cond = @unique_queries
 742       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 743       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 744     ;
 745   }
 746
 747   # Run the query, passing the result_class since it should propagate for find
 748   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 749   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 750     my $row = $rs->next;
 751     carp "Query returned more than one row" if $rs->next;
 752     return $row;
 753   }
 754   else {
 755     return $rs->single;
 756   }
 757 }
 758
 759 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 760 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 761 #
 762 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 763 # condition. It is provided for overrides until a saner way forward is devised
 764 #
 765 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 766 # the road. Please adjust your tests accordingly to catch this situation early
 767 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 768 #
 769 # The method will not be removed without an adequately complete replacement
 770 # for strict-mode enforcement
 771 sub _non_unique_find_fallback {
 772   my ($self, $cond, $attrs) = @_;
 773
 774   return $self->_qualify_cond_columns(
 775     $cond,
 776     exists $attrs->{alias}
 777       ? $attrs->{alias}
 778       : $self->{attrs}{alias}
 779   );
 780 }
 781
 782
 783 sub _qualify_cond_columns {
 784   my ($self, $cond, $alias) = @_;
 785
 786   my %aliased = %$cond;
 787   for (keys %aliased) {
 788     $aliased{"$alias.$_"} = delete $aliased{$_}
 789       if $_ !~ /\./;
 790   }
 791
 792   return \%aliased;
 793 }
 794
 795 my $callsites_warned_ucond;
 796 sub _build_unique_cond {
 797   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 798
 799   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 800
 801   # combination may fail if $self->{cond} is non-trivial
 802   my ($final_cond) = try {
 803     $self->_merge_with_rscond ($extra_cond)
 804   } catch {
 805     +{ %$extra_cond }
 806   };
 807
 808   # trim out everything not in $columns
 809   $final_cond = { map {
 810     exists $final_cond->{$_}
 811       ? ( $_ => $final_cond->{$_} )
 812       : ()
 813   } @c_cols };
 814
 815   if (my @missing = grep
 816     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 817     (@c_cols)
 818   ) {
 819     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 820       $constraint_name,
 821       join (', ', map { "'$_'" } @missing),
 822     ) );
 823   }
 824
 825   if (
 826     !$croak_on_null
 827       and
 828     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 829       and
 830     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 831   ) {
 832     my $callsite = do {
 833       my $w;
 834       local $SIG{__WARN__} = sub { $w = shift };
 835       carp;
 836       $w
 837     };
 838
 839     carp ( sprintf (
 840       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 841     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 842     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 843       $constraint_name,
 844       join (', ', map { "'$_'" } @undefs),
 845     )) unless $callsites_warned_ucond->{$callsite}++;
 846   }
 847
 848   return $final_cond;
 849 }
 850
 851 =head2 search_related
 852
 853 =over 4
 854
 855 =item Arguments: $rel, $cond, \%attrs?
 856
 857 =item Return Value: $new_resultset
 858
 859 =back
 860
 861   $new_rs = $cd_rs->search_related('artist', {
 862     name => 'Emo-R-Us',
 863   });
 864
 865 Searches the specified relationship, optionally specifying a condition and
 866 attributes for matching records. See L</ATTRIBUTES> for more information.
 867
 868 =cut
 869
 870 sub search_related {
 871   return shift->related_resultset(shift)->search(@_);
 872 }
 873
 874 =head2 search_related_rs
 875
 876 This method works exactly the same as search_related, except that
 877 it guarantees a resultset, even in list context.
 878
 879 =cut
 880
 881 sub search_related_rs {
 882   return shift->related_resultset(shift)->search_rs(@_);
 883 }
 884
 885 =head2 cursor
 886
 887 =over 4
 888
 889 =item Arguments: none
 890
 891 =item Return Value: $cursor
 892
 893 =back
 894
 895 Returns a storage-driven cursor to the given resultset. See
 896 L<DBIx::Class::Cursor> for more information.
 897
 898 =cut
 899
 900 sub cursor {
 901   my ($self) = @_;
 902
 903   my $attrs = $self->_resolved_attrs_copy;
 904
 905   return $self->{cursor}
 906     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 907           $attrs->{where},$attrs);
 908 }
 909
 910 =head2 single
 911
 912 =over 4
 913
 914 =item Arguments: $cond?
 915
 916 =item Return Value: $row_object | undef
 917
 918 =back
 919
 920   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 921
 922 Inflates the first result without creating a cursor if the resultset has
 923 any records in it; if not returns C<undef>. Used by L</find> as a lean version
 924 of L</search>.
 925
 926 While this method can take an optional search condition (just like L</search>)
 927 being a fast-code-path it does not recognize search attributes. If you need to
 928 add extra joins or similar, call L</search> and then chain-call L</single> on the
 929 L<DBIx::Class::ResultSet> returned.
 930
 931 =over
 932
 933 =item B<Note>
 934
 935 As of 0.08100, this method enforces the assumption that the preceding
 936 query returns only one row. If more than one row is returned, you will receive
 937 a warning:
 938
 939   Query returned more than one row
 940
 941 In this case, you should be using L</next> or L</find> instead, or if you really
 942 know what you are doing, use the L</rows> attribute to explicitly limit the size
 943 of the resultset.
 944
 945 This method will also throw an exception if it is called on a resultset prefetching
 946 has_many, as such a prefetch implies fetching multiple rows from the database in
 947 order to assemble the resulting object.
 948
 949 =back
 950
 951 =cut
 952
 953 sub single {
 954   my ($self, $where) = @_;
 955   if(@_ > 2) {
 956       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 957   }
 958
 959   my $attrs = $self->_resolved_attrs_copy;
 960
 961   if (keys %{$attrs->{collapse}}) {
 962     $self->throw_exception(
 963       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 964     );
 965   }
 966
 967   if ($where) {
 968     if (defined $attrs->{where}) {
 969       $attrs->{where} = {
 970         '-and' =>
 971             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 972                $where, delete $attrs->{where} ]
 973       };
 974     } else {
 975       $attrs->{where} = $where;
 976     }
 977   }
 978
 979   my @data = $self->result_source->storage->select_single(
 980     $attrs->{from}, $attrs->{select},
 981     $attrs->{where}, $attrs
 982   );
 983
 984   return (@data ? ($self->_construct_object(@data))[0] : undef);
 985 }
 986
 987
 988 # _collapse_query
 989 #
 990 # Recursively collapse the query, accumulating values for each column.
 991
 992 sub _collapse_query {
 993   my ($self, $query, $collapsed) = @_;
 994
 995   $collapsed ||= {};
 996
 997   if (ref $query eq 'ARRAY') {
 998     foreach my $subquery (@$query) {
 999       next unless ref $subquery;  # -or
1000       $collapsed = $self->_collapse_query($subquery, $collapsed);
1001     }
1002   }
1003   elsif (ref $query eq 'HASH') {
1004     if (keys %$query and (keys %$query)[0] eq '-and') {
1005       foreach my $subquery (@{$query->{-and}}) {
1006         $collapsed = $self->_collapse_query($subquery, $collapsed);
1007       }
1008     }
1009     else {
1010       foreach my $col (keys %$query) {
1011         my $value = $query->{$col};
1012         $collapsed->{$col}{$value}++;
1013       }
1014     }
1015   }
1016
1017   return $collapsed;
1018 }
1019
1020 =head2 get_column
1021
1022 =over 4
1023
1024 =item Arguments: $cond?
1025
1026 =item Return Value: $resultsetcolumn
1027
1028 =back
1029
1030   my $max_length = $rs->get_column('length')->max;
1031
1032 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1033
1034 =cut
1035
1036 sub get_column {
1037   my ($self, $column) = @_;
1038   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1039   return $new;
1040 }
1041
1042 =head2 search_like
1043
1044 =over 4
1045
1046 =item Arguments: $cond, \%attrs?
1047
1048 =item Return Value: $resultset (scalar context), @row_objs (list context)
1049
1050 =back
1051
1052   # WHERE title LIKE '%blue%'
1053   $cd_rs = $rs->search_like({ title => '%blue%'});
1054
1055 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1056 that this is simply a convenience method retained for ex Class::DBI users.
1057 You most likely want to use L</search> with specific operators.
1058
1059 For more information, see L<DBIx::Class::Manual::Cookbook>.
1060
1061 This method is deprecated and will be removed in 0.09. Use L</search()>
1062 instead. An example conversion is:
1063
1064   ->search_like({ foo => 'bar' });
1065
1066   # Becomes
1067
1068   ->search({ foo => { like => 'bar' } });
1069
1070 =cut
1071
1072 sub search_like {
1073   my $class = shift;
1074   carp (
1075     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1076    .' Instead use ->search({ x => { -like => "y%" } })'
1077    .' (note the outer pair of {}s - they are important!)'
1078   );
1079   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1080   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1081   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1082   return $class->search($query, { %$attrs });
1083 }
1084
1085 =head2 slice
1086
1087 =over 4
1088
1089 =item Arguments: $first, $last
1090
1091 =item Return Value: $resultset (scalar context), @row_objs (list context)
1092
1093 =back
1094
1095 Returns a resultset or object list representing a subset of elements from the
1096 resultset slice is called on. Indexes are from 0, i.e., to get the first
1097 three records, call:
1098
1099   my ($one, $two, $three) = $rs->slice(0, 2);
1100
1101 =cut
1102
1103 sub slice {
1104   my ($self, $min, $max) = @_;
1105   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1106   $attrs->{offset} = $self->{attrs}{offset} || 0;
1107   $attrs->{offset} += $min;
1108   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1109   return $self->search(undef, $attrs);
1110   #my $slice = (ref $self)->new($self->result_source, $attrs);
1111   #return (wantarray ? $slice->all : $slice);
1112 }
1113
1114 =head2 next
1115
1116 =over 4
1117
1118 =item Arguments: none
1119
1120 =item Return Value: $result | undef
1121
1122 =back
1123
1124 Returns the next element in the resultset (C<undef> is there is none).
1125
1126 Can be used to efficiently iterate over records in the resultset:
1127
1128   my $rs = $schema->resultset('CD')->search;
1129   while (my $cd = $rs->next) {
1130     print $cd->title;
1131   }
1132
1133 Note that you need to store the resultset object, and call C<next> on it.
1134 Calling C<< resultset('Table')->next >> repeatedly will always return the
1135 first record from the resultset.
1136
1137 =cut
1138
1139 sub next {
1140   my ($self) = @_;
1141   if (my $cache = $self->get_cache) {
1142     $self->{all_cache_position} ||= 0;
1143     return $cache->[$self->{all_cache_position}++];
1144   }
1145   if ($self->{attrs}{cache}) {
1146     delete $self->{pager};
1147     $self->{all_cache_position} = 1;
1148     return ($self->all)[0];
1149   }
1150   if ($self->{stashed_objects}) {
1151     my $obj = shift(@{$self->{stashed_objects}});
1152     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1153     return $obj;
1154   }
1155   my @row = (
1156     exists $self->{stashed_row}
1157       ? @{delete $self->{stashed_row}}
1158       : $self->cursor->next
1159   );
1160   return undef unless (@row);
1161   my ($row, @more) = $self->_construct_object(@row);
1162   $self->{stashed_objects} = \@more if @more;
1163   return $row;
1164 }
1165
1166 sub _construct_object {
1167   my ($self, @row) = @_;
1168
1169   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1170     or return ();
1171   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1172   @new = $self->{_attrs}{record_filter}->(@new)
1173     if exists $self->{_attrs}{record_filter};
1174   return @new;
1175 }
1176
1177 sub _collapse_result {
1178   my ($self, $as_proto, $row) = @_;
1179
1180   my @copy = @$row;
1181
1182   # 'foo'         => [ undef, 'foo' ]
1183   # 'foo.bar'     => [ 'foo', 'bar' ]
1184   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1185
1186   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1187
1188   my %collapse = %{$self->{_attrs}{collapse}||{}};
1189
1190   my @pri_index;
1191
1192   # if we're doing collapsing (has_many prefetch) we need to grab records
1193   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1194   # we know we don't have to bother.
1195
1196   # the reason for not using the collapse stuff directly is because if you
1197   # had for e.g. two artists in a row with no cds, the collapse info for
1198   # both would be NULL (undef) so you'd lose the second artist
1199
1200   # store just the index so we can check the array positions from the row
1201   # without having to contruct the full hash
1202
1203   if (keys %collapse) {
1204     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1205     foreach my $i (0 .. $#construct_as) {
1206       next if defined($construct_as[$i][0]); # only self table
1207       if (delete $pri{$construct_as[$i][1]}) {
1208         push(@pri_index, $i);
1209       }
1210       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1211     }
1212   }
1213
1214   # no need to do an if, it'll be empty if @pri_index is empty anyway
1215
1216   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1217
1218   my @const_rows;
1219
1220   do { # no need to check anything at the front, we always want the first row
1221
1222     my %const;
1223
1224     foreach my $this_as (@construct_as) {
1225       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1226     }
1227
1228     push(@const_rows, \%const);
1229
1230   } until ( # no pri_index => no collapse => drop straight out
1231       !@pri_index
1232     or
1233       do { # get another row, stash it, drop out if different PK
1234
1235         @copy = $self->cursor->next;
1236         $self->{stashed_row} = \@copy;
1237
1238         # last thing in do block, counts as true if anything doesn't match
1239
1240         # check xor defined first for NULL vs. NOT NULL then if one is
1241         # defined the other must be so check string equality
1242
1243         grep {
1244           (defined $pri_vals{$_} ^ defined $copy[$_])
1245           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1246         } @pri_index;
1247       }
1248   );
1249
1250   my $alias = $self->{attrs}{alias};
1251   my $info = [];
1252
1253   my %collapse_pos;
1254
1255   my @const_keys;
1256
1257   foreach my $const (@const_rows) {
1258     scalar @const_keys or do {
1259       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1260     };
1261     foreach my $key (@const_keys) {
1262       if (length $key) {
1263         my $target = $info;
1264         my @parts = split(/\./, $key);
1265         my $cur = '';
1266         my $data = $const->{$key};
1267         foreach my $p (@parts) {
1268           $target = $target->[1]->{$p} ||= [];
1269           $cur .= ".${p}";
1270           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1271             # collapsing at this point and on final part
1272             my $pos = $collapse_pos{$cur};
1273             CK: foreach my $ck (@ckey) {
1274               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1275                 $collapse_pos{$cur} = $data;
1276                 delete @collapse_pos{ # clear all positioning for sub-entries
1277                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1278                 };
1279                 push(@$target, []);
1280                 last CK;
1281               }
1282             }
1283           }
1284           if (exists $collapse{$cur}) {
1285             $target = $target->[-1];
1286           }
1287         }
1288         $target->[0] = $data;
1289       } else {
1290         $info->[0] = $const->{$key};
1291       }
1292     }
1293   }
1294
1295   return $info;
1296 }
1297
1298 =head2 result_source
1299
1300 =over 4
1301
1302 =item Arguments: $result_source?
1303
1304 =item Return Value: $result_source
1305
1306 =back
1307
1308 An accessor for the primary ResultSource object from which this ResultSet
1309 is derived.
1310
1311 =head2 result_class
1312
1313 =over 4
1314
1315 =item Arguments: $result_class?
1316
1317 =item Return Value: $result_class
1318
1319 =back
1320
1321 An accessor for the class to use when creating row objects. Defaults to
1322 C<< result_source->result_class >> - which in most cases is the name of the
1323 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1324
1325 Note that changing the result_class will also remove any components
1326 that were originally loaded in the source class via
1327 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1328 in the original source class will not run.
1329
1330 =cut
1331
1332 sub result_class {
1333   my ($self, $result_class) = @_;
1334   if ($result_class) {
1335     unless (ref $result_class) { # don't fire this for an object
1336       $self->ensure_class_loaded($result_class);
1337     }
1338     $self->_result_class($result_class);
1339     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1340     # permit the user to set result class on one result set only; it only
1341     # chains if provided to search()
1342     #$self->{attrs}{result_class} = $result_class if ref $self;
1343   }
1344   $self->_result_class;
1345 }
1346
1347 =head2 count
1348
1349 =over 4
1350
1351 =item Arguments: $cond, \%attrs??
1352
1353 =item Return Value: $count
1354
1355 =back
1356
1357 Performs an SQL C<COUNT> with the same query as the resultset was built
1358 with to find the number of elements. Passing arguments is equivalent to
1359 C<< $rs->search ($cond, \%attrs)->count >>
1360
1361 =cut
1362
1363 sub count {
1364   my $self = shift;
1365   return $self->search(@_)->count if @_ and defined $_[0];
1366   return scalar @{ $self->get_cache } if $self->get_cache;
1367
1368   my $attrs = $self->_resolved_attrs_copy;
1369
1370   # this is a little optimization - it is faster to do the limit
1371   # adjustments in software, instead of a subquery
1372   my $rows = delete $attrs->{rows};
1373   my $offset = delete $attrs->{offset};
1374
1375   my $crs;
1376   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1377     $crs = $self->_count_subq_rs ($attrs);
1378   }
1379   else {
1380     $crs = $self->_count_rs ($attrs);
1381   }
1382   my $count = $crs->next;
1383
1384   $count -= $offset if $offset;
1385   $count = $rows if $rows and $rows < $count;
1386   $count = 0 if ($count < 0);
1387
1388   return $count;
1389 }
1390
1391 =head2 count_rs
1392
1393 =over 4
1394
1395 =item Arguments: $cond, \%attrs??
1396
1397 =item Return Value: $count_rs
1398
1399 =back
1400
1401 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1402 This can be very handy for subqueries:
1403
1404   ->search( { amount => $some_rs->count_rs->as_query } )
1405
1406 As with regular resultsets the SQL query will be executed only after
1407 the resultset is accessed via L</next> or L</all>. That would return
1408 the same single value obtainable via L</count>.
1409
1410 =cut
1411
1412 sub count_rs {
1413   my $self = shift;
1414   return $self->search(@_)->count_rs if @_;
1415
1416   # this may look like a lack of abstraction (count() does about the same)
1417   # but in fact an _rs *must* use a subquery for the limits, as the
1418   # software based limiting can not be ported if this $rs is to be used
1419   # in a subquery itself (i.e. ->as_query)
1420   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1421     return $self->_count_subq_rs;
1422   }
1423   else {
1424     return $self->_count_rs;
1425   }
1426 }
1427
1428 #
1429 # returns a ResultSetColumn object tied to the count query
1430 #
1431 sub _count_rs {
1432   my ($self, $attrs) = @_;
1433
1434   my $rsrc = $self->result_source;
1435   $attrs ||= $self->_resolved_attrs;
1436
1437   my $tmp_attrs = { %$attrs };
1438   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1439   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1440
1441   # overwrite the selector (supplied by the storage)
1442   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1443   $tmp_attrs->{as} = 'count';
1444   delete @{$tmp_attrs}{qw/columns _trailing_select/};
1445
1446   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1447
1448   return $tmp_rs;
1449 }
1450
1451 #
1452 # same as above but uses a subquery
1453 #
1454 sub _count_subq_rs {
1455   my ($self, $attrs) = @_;
1456
1457   my $rsrc = $self->result_source;
1458   $attrs ||= $self->_resolved_attrs;
1459
1460   my $sub_attrs = { %$attrs };
1461   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1462   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range _trailing_select order_by for/};
1463
1464   # if we multi-prefetch we group_by primary keys only as this is what we would
1465   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1466   if ( keys %{$attrs->{collapse}}  ) {
1467     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1468   }
1469
1470   # Calculate subquery selector
1471   if (my $g = $sub_attrs->{group_by}) {
1472
1473     my $sql_maker = $rsrc->storage->sql_maker;
1474
1475     # necessary as the group_by may refer to aliased functions
1476     my $sel_index;
1477     for my $sel (@{$attrs->{select}}) {
1478       $sel_index->{$sel->{-as}} = $sel
1479         if (ref $sel eq 'HASH' and $sel->{-as});
1480     }
1481
1482     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1483     # also look for named aggregates referred in the having clause
1484     # having often contains scalarrefs - thus parse it out entirely
1485     my @parts = @$g;
1486     if ($attrs->{having}) {
1487       local $sql_maker->{having_bind};
1488       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1489       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1490       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1491         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1492         # if we don't unset it we screw up retarded but unfortunately working
1493         # 'MAX(foo.bar)' => { '>', 3 }
1494         $sql_maker->{name_sep} = '';
1495       }
1496
1497       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1498
1499       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1500
1501       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1502       # and if all fails for an utterly naive quoted scalar-with-function
1503       while ($sql =~ /
1504         $rquote $sep $lquote (.+?) $rquote
1505           |
1506         [\s,] \w+ \. (\w+) [\s,]
1507           |
1508         [\s,] $lquote (.+?) $rquote [\s,]
1509       /gx) {
1510         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1511       }
1512     }
1513
1514     for (@parts) {
1515       my $colpiece = $sel_index->{$_} || $_;
1516
1517       # unqualify join-based group_by's. Arcane but possible query
1518       # also horrible horrible hack to alias a column (not a func.)
1519       # (probably need to introduce SQLA syntax)
1520       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1521         my $as = $colpiece;
1522         $as =~ s/\./__/;
1523         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1524       }
1525       push @{$sub_attrs->{select}}, $colpiece;
1526     }
1527   }
1528   else {
1529     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1530     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1531   }
1532
1533   return $rsrc->resultset_class
1534                ->new ($rsrc, $sub_attrs)
1535                 ->as_subselect_rs
1536                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1537                   ->get_column ('count');
1538 }
1539
1540 sub _bool {
1541   return 1;
1542 }
1543
1544 =head2 count_literal
1545
1546 =over 4
1547
1548 =item Arguments: $sql_fragment, @bind_values
1549
1550 =item Return Value: $count
1551
1552 =back
1553
1554 Counts the results in a literal query. Equivalent to calling L</search_literal>
1555 with the passed arguments, then L</count>.
1556
1557 =cut
1558
1559 sub count_literal { shift->search_literal(@_)->count; }
1560
1561 =head2 all
1562
1563 =over 4
1564
1565 =item Arguments: none
1566
1567 =item Return Value: @objects
1568
1569 =back
1570
1571 Returns all elements in the resultset. Called implicitly if the resultset
1572 is returned in list context.
1573
1574 =cut
1575
1576 sub all {
1577   my $self = shift;
1578   if(@_) {
1579       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1580   }
1581
1582   return @{ $self->get_cache } if $self->get_cache;
1583
1584   my @obj;
1585
1586   if (keys %{$self->_resolved_attrs->{collapse}}) {
1587     # Using $self->cursor->all is really just an optimisation.
1588     # If we're collapsing has_many prefetches it probably makes
1589     # very little difference, and this is cleaner than hacking
1590     # _construct_object to survive the approach
1591     $self->cursor->reset;
1592     my @row = $self->cursor->next;
1593     while (@row) {
1594       push(@obj, $self->_construct_object(@row));
1595       @row = (exists $self->{stashed_row}
1596                ? @{delete $self->{stashed_row}}
1597                : $self->cursor->next);
1598     }
1599   } else {
1600     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1601   }
1602
1603   $self->set_cache(\@obj) if $self->{attrs}{cache};
1604
1605   return @obj;
1606 }
1607
1608 =head2 reset
1609
1610 =over 4
1611
1612 =item Arguments: none
1613
1614 =item Return Value: $self
1615
1616 =back
1617
1618 Resets the resultset's cursor, so you can iterate through the elements again.
1619 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1620 another query.
1621
1622 =cut
1623
1624 sub reset {
1625   my ($self) = @_;
1626   delete $self->{_attrs} if exists $self->{_attrs};
1627   $self->{all_cache_position} = 0;
1628   $self->cursor->reset;
1629   return $self;
1630 }
1631
1632 =head2 first
1633
1634 =over 4
1635
1636 =item Arguments: none
1637
1638 =item Return Value: $object | undef
1639
1640 =back
1641
1642 Resets the resultset and returns an object for the first result (or C<undef>
1643 if the resultset is empty).
1644
1645 =cut
1646
1647 sub first {
1648   return $_[0]->reset->next;
1649 }
1650
1651
1652 # _rs_update_delete
1653 #
1654 # Determines whether and what type of subquery is required for the $rs operation.
1655 # If grouping is necessary either supplies its own, or verifies the current one
1656 # After all is done delegates to the proper storage method.
1657
1658 sub _rs_update_delete {
1659   my ($self, $op, $values) = @_;
1660
1661   my $rsrc = $self->result_source;
1662
1663   # if a condition exists we need to strip all table qualifiers
1664   # if this is not possible we'll force a subquery below
1665   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1666
1667   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1668   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1669
1670   if ($needs_group_by_subq or $needs_subq) {
1671
1672     # make a new $rs selecting only the PKs (that's all we really need)
1673     my $attrs = $self->_resolved_attrs_copy;
1674
1675
1676     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1677     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1678
1679     if ($needs_group_by_subq) {
1680       # make sure no group_by was supplied, or if there is one - make sure it matches
1681       # the columns compiled above perfectly. Anything else can not be sanely executed
1682       # on most databases so croak right then and there
1683
1684       if (my $g = $attrs->{group_by}) {
1685         my @current_group_by = map
1686           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1687           @$g
1688         ;
1689
1690         if (
1691           join ("\x00", sort @current_group_by)
1692             ne
1693           join ("\x00", sort @{$attrs->{columns}} )
1694         ) {
1695           $self->throw_exception (
1696             "You have just attempted a $op operation on a resultset which does group_by"
1697             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1698             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1699             . ' kind of queries. Please retry the operation with a modified group_by or'
1700             . ' without using one at all.'
1701           );
1702         }
1703       }
1704       else {
1705         $attrs->{group_by} = $attrs->{columns};
1706       }
1707     }
1708
1709     my $subrs = (ref $self)->new($rsrc, $attrs);
1710     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1711   }
1712   else {
1713     return $rsrc->storage->$op(
1714       $rsrc,
1715       $op eq 'update' ? $values : (),
1716       $cond,
1717     );
1718   }
1719 }
1720
1721 =head2 update
1722
1723 =over 4
1724
1725 =item Arguments: \%values
1726
1727 =item Return Value: $storage_rv
1728
1729 =back
1730
1731 Sets the specified columns in the resultset to the supplied values in a
1732 single query. Note that this will not run any accessor/set_column/update
1733 triggers, nor will it update any row object instances derived from this
1734 resultset (this includes the contents of the L<resultset cache|/set_cache>
1735 if any). See L</update_all> if you need to execute any on-update
1736 triggers or cascades defined either by you or a
1737 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1738
1739 The return value is a pass through of what the underlying
1740 storage backend returned, and may vary. See L<DBI/execute> for the most
1741 common case.
1742
1743 =head3 CAVEAT
1744
1745 Note that L</update> does not process/deflate any of the values passed in.
1746 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1747 ensure manually that any value passed to this method will stringify to
1748 something the RDBMS knows how to deal with. A notable example is the
1749 handling of L<DateTime> objects, for more info see:
1750 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
1751
1752 =cut
1753
1754 sub update {
1755   my ($self, $values) = @_;
1756   $self->throw_exception('Values for update must be a hash')
1757     unless ref $values eq 'HASH';
1758
1759   return $self->_rs_update_delete ('update', $values);
1760 }
1761
1762 =head2 update_all
1763
1764 =over 4
1765
1766 =item Arguments: \%values
1767
1768 =item Return Value: 1
1769
1770 =back
1771
1772 Fetches all objects and updates them one at a time via
1773 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1774 triggers, while L</update> will not.
1775
1776 =cut
1777
1778 sub update_all {
1779   my ($self, $values) = @_;
1780   $self->throw_exception('Values for update_all must be a hash')
1781     unless ref $values eq 'HASH';
1782
1783   my $guard = $self->result_source->schema->txn_scope_guard;
1784   $_->update($values) for $self->all;
1785   $guard->commit;
1786   return 1;
1787 }
1788
1789 =head2 delete
1790
1791 =over 4
1792
1793 =item Arguments: none
1794
1795 =item Return Value: $storage_rv
1796
1797 =back
1798
1799 Deletes the rows matching this resultset in a single query. Note that this
1800 will not run any delete triggers, nor will it alter the
1801 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1802 derived from this resultset (this includes the contents of the
1803 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1804 execute any on-delete triggers or cascades defined either by you or a
1805 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1806
1807 The return value is a pass through of what the underlying storage backend
1808 returned, and may vary. See L<DBI/execute> for the most common case.
1809
1810 =cut
1811
1812 sub delete {
1813   my $self = shift;
1814   $self->throw_exception('delete does not accept any arguments')
1815     if @_;
1816
1817   return $self->_rs_update_delete ('delete');
1818 }
1819
1820 =head2 delete_all
1821
1822 =over 4
1823
1824 =item Arguments: none
1825
1826 =item Return Value: 1
1827
1828 =back
1829
1830 Fetches all objects and deletes them one at a time via
1831 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1832 triggers, while L</delete> will not.
1833
1834 =cut
1835
1836 sub delete_all {
1837   my $self = shift;
1838   $self->throw_exception('delete_all does not accept any arguments')
1839     if @_;
1840
1841   my $guard = $self->result_source->schema->txn_scope_guard;
1842   $_->delete for $self->all;
1843   $guard->commit;
1844   return 1;
1845 }
1846
1847 =head2 populate
1848
1849 =over 4
1850
1851 =item Arguments: \@data;
1852
1853 =back
1854
1855 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1856 For the arrayref of hashrefs style each hashref should be a structure suitable
1857 forsubmitting to a $resultset->create(...) method.
1858
1859 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1860 to insert the data, as this is a faster method.
1861
1862 Otherwise, each set of data is inserted into the database using
1863 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1864 accumulated into an array. The array itself, or an array reference
1865 is returned depending on scalar or list context.
1866
1867 Example:  Assuming an Artist Class that has many CDs Classes relating:
1868
1869   my $Artist_rs = $schema->resultset("Artist");
1870
1871   ## Void Context Example
1872   $Artist_rs->populate([
1873      { artistid => 4, name => 'Manufactured Crap', cds => [
1874         { title => 'My First CD', year => 2006 },
1875         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1876       ],
1877      },
1878      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1879         { title => 'My parents sold me to a record company', year => 2005 },
1880         { title => 'Why Am I So Ugly?', year => 2006 },
1881         { title => 'I Got Surgery and am now Popular', year => 2007 }
1882       ],
1883      },
1884   ]);
1885
1886   ## Array Context Example
1887   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1888     { name => "Artist One"},
1889     { name => "Artist Two"},
1890     { name => "Artist Three", cds=> [
1891     { title => "First CD", year => 2007},
1892     { title => "Second CD", year => 2008},
1893   ]}
1894   ]);
1895
1896   print $ArtistOne->name; ## response is 'Artist One'
1897   print $ArtistThree->cds->count ## reponse is '2'
1898
1899 For the arrayref of arrayrefs style,  the first element should be a list of the
1900 fieldsnames to which the remaining elements are rows being inserted.  For
1901 example:
1902
1903   $Arstist_rs->populate([
1904     [qw/artistid name/],
1905     [100, 'A Formally Unknown Singer'],
1906     [101, 'A singer that jumped the shark two albums ago'],
1907     [102, 'An actually cool singer'],
1908   ]);
1909
1910 Please note an important effect on your data when choosing between void and
1911 wantarray context. Since void context goes straight to C<insert_bulk> in
1912 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1913 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1914 create primary keys for you, you will find that your PKs are empty.  In this
1915 case you will have to use the wantarray context in order to create those
1916 values.
1917
1918 =cut
1919
1920 sub populate {
1921   my $self = shift;
1922
1923   # cruft placed in standalone method
1924   my $data = $self->_normalize_populate_args(@_);
1925
1926   if(defined wantarray) {
1927     my @created;
1928     foreach my $item (@$data) {
1929       push(@created, $self->create($item));
1930     }
1931     return wantarray ? @created : \@created;
1932   }
1933   else {
1934     my $first = $data->[0];
1935
1936     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1937     # it relationship data
1938     my (@rels, @columns);
1939     my $rsrc = $self->result_source;
1940     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
1941     for (keys %$first) {
1942       my $ref = ref $first->{$_};
1943       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
1944         ? push @rels, $_
1945         : push @columns, $_
1946       ;
1947     }
1948
1949     my @pks = $rsrc->primary_columns;
1950
1951     ## do the belongs_to relationships
1952     foreach my $index (0..$#$data) {
1953
1954       # delegate to create() for any dataset without primary keys with specified relationships
1955       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1956         for my $r (@rels) {
1957           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1958             my @ret = $self->populate($data);
1959             return;
1960           }
1961         }
1962       }
1963
1964       foreach my $rel (@rels) {
1965         next unless ref $data->[$index]->{$rel} eq "HASH";
1966         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1967         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
1968         my $related = $result->result_source->_resolve_condition(
1969           $reverse_relinfo->{cond},
1970           $self,
1971           $result,
1972         );
1973
1974         delete $data->[$index]->{$rel};
1975         $data->[$index] = {%{$data->[$index]}, %$related};
1976
1977         push @columns, keys %$related if $index == 0;
1978       }
1979     }
1980
1981     ## inherit the data locked in the conditions of the resultset
1982     my ($rs_data) = $self->_merge_with_rscond({});
1983     delete @{$rs_data}{@columns};
1984     my @inherit_cols = keys %$rs_data;
1985     my @inherit_data = values %$rs_data;
1986
1987     ## do bulk insert on current row
1988     $rsrc->storage->insert_bulk(
1989       $rsrc,
1990       [@columns, @inherit_cols],
1991       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1992     );
1993
1994     ## do the has_many relationships
1995     foreach my $item (@$data) {
1996
1997       my $main_row;
1998
1999       foreach my $rel (@rels) {
2000         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2001
2002         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2003
2004         my $child = $main_row->$rel;
2005
2006         my $related = $child->result_source->_resolve_condition(
2007           $rels->{$rel}{cond},
2008           $child,
2009           $main_row,
2010         );
2011
2012         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2013         my @populate = map { {%$_, %$related} } @rows_to_add;
2014
2015         $child->populate( \@populate );
2016       }
2017     }
2018   }
2019 }
2020
2021
2022 # populate() argumnets went over several incarnations
2023 # What we ultimately support is AoH
2024 sub _normalize_populate_args {
2025   my ($self, $arg) = @_;
2026
2027   if (ref $arg eq 'ARRAY') {
2028     if (ref $arg->[0] eq 'HASH') {
2029       return $arg;
2030     }
2031     elsif (ref $arg->[0] eq 'ARRAY') {
2032       my @ret;
2033       my @colnames = @{$arg->[0]};
2034       foreach my $values (@{$arg}[1 .. $#$arg]) {
2035         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2036       }
2037       return \@ret;
2038     }
2039   }
2040
2041   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2042 }
2043
2044 =head2 pager
2045
2046 =over 4
2047
2048 =item Arguments: none
2049
2050 =item Return Value: $pager
2051
2052 =back
2053
2054 Return Value a L<Data::Page> object for the current resultset. Only makes
2055 sense for queries with a C<page> attribute.
2056
2057 To get the full count of entries for a paged resultset, call
2058 C<total_entries> on the L<Data::Page> object.
2059
2060 =cut
2061
2062 # make a wizard good for both a scalar and a hashref
2063 my $mk_lazy_count_wizard = sub {
2064   require Variable::Magic;
2065
2066   my $stash = { total_rs => shift };
2067   my $slot = shift; # only used by the hashref magic
2068
2069   my $magic = Variable::Magic::wizard (
2070     data => sub { $stash },
2071
2072     (!$slot)
2073     ? (
2074       # the scalar magic
2075       get => sub {
2076         # set value lazily, and dispell for good
2077         ${$_[0]} = $_[1]{total_rs}->count;
2078         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref});
2079         return 1;
2080       },
2081       set => sub {
2082         # an explicit set implies dispell as well
2083         # the unless() is to work around "fun and giggles" below
2084         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref})
2085           unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2086         return 1;
2087       },
2088     )
2089     : (
2090       # the uvar magic
2091       fetch => sub {
2092         if ($_[2] eq $slot and !$_[1]{inactive}) {
2093           my $cnt = $_[1]{total_rs}->count;
2094           $_[0]->{$slot} = $cnt;
2095
2096           # attempting to dispell in a fetch handle (works in store), seems
2097           # to invariable segfault on 5.10, 5.12, 5.13 :(
2098           # so use an inactivator instead
2099           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2100           $_[1]{inactive}++;
2101         }
2102         return 1;
2103       },
2104       store => sub {
2105         if (! $_[1]{inactive} and $_[2] eq $slot) {
2106           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2107           $_[1]{inactive}++
2108             unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2109         }
2110         return 1;
2111       },
2112     ),
2113   );
2114
2115   $stash->{magic_selfref} = $magic;
2116   weaken ($stash->{magic_selfref}); # this fails on 5.8.1
2117
2118   return $magic;
2119 };
2120
2121 # the tie class for 5.8.1
2122 {
2123   package # hide from pause
2124     DBIx::Class::__DBIC_LAZY_RS_COUNT__;
2125   use base qw/Tie::Hash/;
2126
2127   sub FIRSTKEY { my $dummy = scalar keys %{$_[0]{data}}; each %{$_[0]{data}} }
2128   sub NEXTKEY  { each %{$_[0]{data}} }
2129   sub EXISTS   { exists $_[0]{data}{$_[1]} }
2130   sub DELETE   { delete $_[0]{data}{$_[1]} }
2131   sub CLEAR    { %{$_[0]{data}} = () }
2132   sub SCALAR   { scalar %{$_[0]{data}} }
2133
2134   sub TIEHASH {
2135     $_[1]{data} = {%{$_[1]{selfref}}};
2136     %{$_[1]{selfref}} = ();
2137     Scalar::Util::weaken ($_[1]{selfref});
2138     return bless ($_[1], $_[0]);
2139   };
2140
2141   sub FETCH {
2142     if ($_[1] eq $_[0]{slot}) {
2143       my $cnt = $_[0]{data}{$_[1]} = $_[0]{total_rs}->count;
2144       untie %{$_[0]{selfref}};
2145       %{$_[0]{selfref}} = %{$_[0]{data}};
2146       return $cnt;
2147     }
2148     else {
2149       $_[0]{data}{$_[1]};
2150     }
2151   }
2152
2153   sub STORE {
2154     $_[0]{data}{$_[1]} = $_[2];
2155     if ($_[1] eq $_[0]{slot}) {
2156       untie %{$_[0]{selfref}};
2157       %{$_[0]{selfref}} = %{$_[0]{data}};
2158     }
2159     $_[2];
2160   }
2161 }
2162
2163 sub pager {
2164   my ($self) = @_;
2165
2166   return $self->{pager} if $self->{pager};
2167
2168   if ($self->get_cache) {
2169     $self->throw_exception ('Pagers on cached resultsets are not supported');
2170   }
2171
2172   my $attrs = $self->{attrs};
2173   if (!defined $attrs->{page}) {
2174     $self->throw_exception("Can't create pager for non-paged rs");
2175   }
2176   elsif ($attrs->{page} <= 0) {
2177     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2178   }
2179   $attrs->{rows} ||= 10;
2180
2181   # throw away the paging flags and re-run the count (possibly
2182   # with a subselect) to get the real total count
2183   my $count_attrs = { %$attrs };
2184   delete $count_attrs->{$_} for qw/rows offset page pager/;
2185   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2186
2187
2188 ### the following may seem awkward and dirty, but it's a thought-experiment
2189 ### necessary for future development of DBIx::DS. Do *NOT* change this code
2190 ### before talking to ribasushi/mst
2191
2192   require Data::Page;
2193   my $pager = Data::Page->new(
2194     0,  #start with an empty set
2195     $attrs->{rows},
2196     $self->{attrs}{page},
2197   );
2198
2199   my $data_slot = 'total_entries';
2200
2201   # Since we are interested in a cached value (once it's set - it's set), every
2202   # technique will detach from the magic-host once the time comes to fire the
2203   # ->count (or in the segfaulting case of >= 5.10 it will deactivate itself)
2204
2205   if ($] < 5.008003) {
2206     # 5.8.1 throws 'Modification of a read-only value attempted' when one tries
2207     # to weakref the magic container :(
2208     # tested on 5.8.1
2209     tie (%$pager, 'DBIx::Class::__DBIC_LAZY_RS_COUNT__',
2210       { slot => $data_slot, total_rs => $total_rs, selfref => $pager }
2211     );
2212   }
2213   elsif ($] < 5.010) {
2214     # We can use magic on the hash value slot. It's interesting that the magic is
2215     # attached to the hash-slot, and does *not* stop working once I do the dummy
2216     # assignments after the cast()
2217     # tested on 5.8.3 and 5.8.9
2218     my $magic = $mk_lazy_count_wizard->($total_rs);
2219     Variable::Magic::cast ( $pager->{$data_slot}, $magic );
2220
2221     # this is for fun and giggles
2222     $pager->{$data_slot} = -1;
2223     $pager->{$data_slot} = 0;
2224
2225     # this does not work for scalars, but works with
2226     # uvar magic below
2227     #my %vals = %$pager;
2228     #%$pager = ();
2229     #%{$pager} = %vals;
2230   }
2231   else {
2232     # And the uvar magic
2233     # works on 5.10.1, 5.12.1 and 5.13.4 in its current form,
2234     # however see the wizard maker for more notes
2235     my $magic = $mk_lazy_count_wizard->($total_rs, $data_slot);
2236     Variable::Magic::cast ( %$pager, $magic );
2237
2238     # still works
2239     $pager->{$data_slot} = -1;
2240     $pager->{$data_slot} = 0;
2241
2242     # this now works
2243     my %vals = %$pager;
2244     %$pager = ();
2245     %{$pager} = %vals;
2246   }
2247
2248   return $self->{pager} = $pager;
2249 }
2250
2251 =head2 page
2252
2253 =over 4
2254
2255 =item Arguments: $page_number
2256
2257 =item Return Value: $rs
2258
2259 =back
2260
2261 Returns a resultset for the $page_number page of the resultset on which page
2262 is called, where each page contains a number of rows equal to the 'rows'
2263 attribute set on the resultset (10 by default).
2264
2265 =cut
2266
2267 sub page {
2268   my ($self, $page) = @_;
2269   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2270 }
2271
2272 =head2 new_result
2273
2274 =over 4
2275
2276 =item Arguments: \%vals
2277
2278 =item Return Value: $rowobject
2279
2280 =back
2281
2282 Creates a new row object in the resultset's result class and returns
2283 it. The row is not inserted into the database at this point, call
2284 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2285 will tell you whether the row object has been inserted or not.
2286
2287 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2288
2289 =cut
2290
2291 sub new_result {
2292   my ($self, $values) = @_;
2293   $self->throw_exception( "new_result needs a hash" )
2294     unless (ref $values eq 'HASH');
2295
2296   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2297
2298   my %new = (
2299     %$merged_cond,
2300     @$cols_from_relations
2301       ? (-cols_from_relations => $cols_from_relations)
2302       : (),
2303     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2304   );
2305
2306   return $self->result_class->new(\%new);
2307 }
2308
2309 # _merge_with_rscond
2310 #
2311 # Takes a simple hash of K/V data and returns its copy merged with the
2312 # condition already present on the resultset. Additionally returns an
2313 # arrayref of value/condition names, which were inferred from related
2314 # objects (this is needed for in-memory related objects)
2315 sub _merge_with_rscond {
2316   my ($self, $data) = @_;
2317
2318   my (%new_data, @cols_from_relations);
2319
2320   my $alias = $self->{attrs}{alias};
2321
2322   if (! defined $self->{cond}) {
2323     # just massage $data below
2324   }
2325   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2326     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2327     @cols_from_relations = keys %new_data;
2328   }
2329   elsif (ref $self->{cond} ne 'HASH') {
2330     $self->throw_exception(
2331       "Can't abstract implicit construct, resultset condition not a hash"
2332     );
2333   }
2334   else {
2335     # precendence must be given to passed values over values inherited from
2336     # the cond, so the order here is important.
2337     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2338     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2339
2340     while ( my($col, $value) = each %implied ) {
2341       my $vref = ref $value;
2342       if ($vref eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
2343         $new_data{$col} = $value->{'='};
2344       }
2345       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2346         $new_data{$col} = $value;
2347       }
2348     }
2349   }
2350
2351   %new_data = (
2352     %new_data,
2353     %{ $self->_remove_alias($data, $alias) },
2354   );
2355
2356   return (\%new_data, \@cols_from_relations);
2357 }
2358
2359 # _has_resolved_attr
2360 #
2361 # determines if the resultset defines at least one
2362 # of the attributes supplied
2363 #
2364 # used to determine if a subquery is neccessary
2365 #
2366 # supports some virtual attributes:
2367 #   -join
2368 #     This will scan for any joins being present on the resultset.
2369 #     It is not a mere key-search but a deep inspection of {from}
2370 #
2371
2372 sub _has_resolved_attr {
2373   my ($self, @attr_names) = @_;
2374
2375   my $attrs = $self->_resolved_attrs;
2376
2377   my %extra_checks;
2378
2379   for my $n (@attr_names) {
2380     if (grep { $n eq $_ } (qw/-join/) ) {
2381       $extra_checks{$n}++;
2382       next;
2383     }
2384
2385     my $attr =  $attrs->{$n};
2386
2387     next if not defined $attr;
2388
2389     if (ref $attr eq 'HASH') {
2390       return 1 if keys %$attr;
2391     }
2392     elsif (ref $attr eq 'ARRAY') {
2393       return 1 if @$attr;
2394     }
2395     else {
2396       return 1 if $attr;
2397     }
2398   }
2399
2400   # a resolved join is expressed as a multi-level from
2401   return 1 if (
2402     $extra_checks{-join}
2403       and
2404     ref $attrs->{from} eq 'ARRAY'
2405       and
2406     @{$attrs->{from}} > 1
2407   );
2408
2409   return 0;
2410 }
2411
2412 # _collapse_cond
2413 #
2414 # Recursively collapse the condition.
2415
2416 sub _collapse_cond {
2417   my ($self, $cond, $collapsed) = @_;
2418
2419   $collapsed ||= {};
2420
2421   if (ref $cond eq 'ARRAY') {
2422     foreach my $subcond (@$cond) {
2423       next unless ref $subcond;  # -or
2424       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2425     }
2426   }
2427   elsif (ref $cond eq 'HASH') {
2428     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2429       foreach my $subcond (@{$cond->{-and}}) {
2430         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2431       }
2432     }
2433     else {
2434       foreach my $col (keys %$cond) {
2435         my $value = $cond->{$col};
2436         $collapsed->{$col} = $value;
2437       }
2438     }
2439   }
2440
2441   return $collapsed;
2442 }
2443
2444 # _remove_alias
2445 #
2446 # Remove the specified alias from the specified query hash. A copy is made so
2447 # the original query is not modified.
2448
2449 sub _remove_alias {
2450   my ($self, $query, $alias) = @_;
2451
2452   my %orig = %{ $query || {} };
2453   my %unaliased;
2454
2455   foreach my $key (keys %orig) {
2456     if ($key !~ /\./) {
2457       $unaliased{$key} = $orig{$key};
2458       next;
2459     }
2460     $unaliased{$1} = $orig{$key}
2461       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2462   }
2463
2464   return \%unaliased;
2465 }
2466
2467 =head2 as_query
2468
2469 =over 4
2470
2471 =item Arguments: none
2472
2473 =item Return Value: \[ $sql, @bind ]
2474
2475 =back
2476
2477 Returns the SQL query and bind vars associated with the invocant.
2478
2479 This is generally used as the RHS for a subquery.
2480
2481 =cut
2482
2483 sub as_query {
2484   my $self = shift;
2485
2486   my $attrs = $self->_resolved_attrs_copy;
2487
2488   # For future use:
2489   #
2490   # in list ctx:
2491   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2492   # $sql also has no wrapping parenthesis in list ctx
2493   #
2494   my $sqlbind = $self->result_source->storage
2495     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2496
2497   return $sqlbind;
2498 }
2499
2500 =head2 find_or_new
2501
2502 =over 4
2503
2504 =item Arguments: \%vals, \%attrs?
2505
2506 =item Return Value: $rowobject
2507
2508 =back
2509
2510   my $artist = $schema->resultset('Artist')->find_or_new(
2511     { artist => 'fred' }, { key => 'artists' });
2512
2513   $cd->cd_to_producer->find_or_new({ producer => $producer },
2514                                    { key => 'primary });
2515
2516 Find an existing record from this resultset using L</find>. if none exists,
2517 instantiate a new result object and return it. The object will not be saved
2518 into your storage until you call L<DBIx::Class::Row/insert> on it.
2519
2520 You most likely want this method when looking for existing rows using a unique
2521 constraint that is not the primary key, or looking for related rows.
2522
2523 If you want objects to be saved immediately, use L</find_or_create> instead.
2524
2525 B<Note>: Make sure to read the documentation of L</find> and understand the
2526 significance of the C<key> attribute, as its lack may skew your search, and
2527 subsequently result in spurious new objects.
2528
2529 B<Note>: Take care when using C<find_or_new> with a table having
2530 columns with default values that you intend to be automatically
2531 supplied by the database (e.g. an auto_increment primary key column).
2532 In normal usage, the value of such columns should NOT be included at
2533 all in the call to C<find_or_new>, even when set to C<undef>.
2534
2535 =cut
2536
2537 sub find_or_new {
2538   my $self     = shift;
2539   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2540   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2541   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2542     return $row;
2543   }
2544   return $self->new_result($hash);
2545 }
2546
2547 =head2 create
2548
2549 =over 4
2550
2551 =item Arguments: \%vals
2552
2553 =item Return Value: a L<DBIx::Class::Row> $object
2554
2555 =back
2556
2557 Attempt to create a single new row or a row with multiple related rows
2558 in the table represented by the resultset (and related tables). This
2559 will not check for duplicate rows before inserting, use
2560 L</find_or_create> to do that.
2561
2562 To create one row for this resultset, pass a hashref of key/value
2563 pairs representing the columns of the table and the values you wish to
2564 store. If the appropriate relationships are set up, foreign key fields
2565 can also be passed an object representing the foreign row, and the
2566 value will be set to its primary key.
2567
2568 To create related objects, pass a hashref of related-object column values
2569 B<keyed on the relationship name>. If the relationship is of type C<multi>
2570 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2571 The process will correctly identify columns holding foreign keys, and will
2572 transparently populate them from the keys of the corresponding relation.
2573 This can be applied recursively, and will work correctly for a structure
2574 with an arbitrary depth and width, as long as the relationships actually
2575 exists and the correct column data has been supplied.
2576
2577
2578 Instead of hashrefs of plain related data (key/value pairs), you may
2579 also pass new or inserted objects. New objects (not inserted yet, see
2580 L</new>), will be inserted into their appropriate tables.
2581
2582 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2583
2584 Example of creating a new row.
2585
2586   $person_rs->create({
2587     name=>"Some Person",
2588     email=>"somebody@someplace.com"
2589   });
2590
2591 Example of creating a new row and also creating rows in a related C<has_many>
2592 or C<has_one> resultset.  Note Arrayref.
2593
2594   $artist_rs->create(
2595      { artistid => 4, name => 'Manufactured Crap', cds => [
2596         { title => 'My First CD', year => 2006 },
2597         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2598       ],
2599      },
2600   );
2601
2602 Example of creating a new row and also creating a row in a related
2603 C<belongs_to> resultset. Note Hashref.
2604
2605   $cd_rs->create({
2606     title=>"Music for Silly Walks",
2607     year=>2000,
2608     artist => {
2609       name=>"Silly Musician",
2610     }
2611   });
2612
2613 =over
2614
2615 =item WARNING
2616
2617 When subclassing ResultSet never attempt to override this method. Since
2618 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2619 lot of the internals simply never call it, so your override will be
2620 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2621 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2622 L</create> process you need to intervene.
2623
2624 =back
2625
2626 =cut
2627
2628 sub create {
2629   my ($self, $attrs) = @_;
2630   $self->throw_exception( "create needs a hashref" )
2631     unless ref $attrs eq 'HASH';
2632   return $self->new_result($attrs)->insert;
2633 }
2634
2635 =head2 find_or_create
2636
2637 =over 4
2638
2639 =item Arguments: \%vals, \%attrs?
2640
2641 =item Return Value: $rowobject
2642
2643 =back
2644
2645   $cd->cd_to_producer->find_or_create({ producer => $producer },
2646                                       { key => 'primary' });
2647
2648 Tries to find a record based on its primary key or unique constraints; if none
2649 is found, creates one and returns that instead.
2650
2651   my $cd = $schema->resultset('CD')->find_or_create({
2652     cdid   => 5,
2653     artist => 'Massive Attack',
2654     title  => 'Mezzanine',
2655     year   => 2005,
2656   });
2657
2658 Also takes an optional C<key> attribute, to search by a specific key or unique
2659 constraint. For example:
2660
2661   my $cd = $schema->resultset('CD')->find_or_create(
2662     {
2663       artist => 'Massive Attack',
2664       title  => 'Mezzanine',
2665     },
2666     { key => 'cd_artist_title' }
2667   );
2668
2669 B<Note>: Make sure to read the documentation of L</find> and understand the
2670 significance of the C<key> attribute, as its lack may skew your search, and
2671 subsequently result in spurious row creation.
2672
2673 B<Note>: Because find_or_create() reads from the database and then
2674 possibly inserts based on the result, this method is subject to a race
2675 condition. Another process could create a record in the table after
2676 the find has completed and before the create has started. To avoid
2677 this problem, use find_or_create() inside a transaction.
2678
2679 B<Note>: Take care when using C<find_or_create> with a table having
2680 columns with default values that you intend to be automatically
2681 supplied by the database (e.g. an auto_increment primary key column).
2682 In normal usage, the value of such columns should NOT be included at
2683 all in the call to C<find_or_create>, even when set to C<undef>.
2684
2685 See also L</find> and L</update_or_create>. For information on how to declare
2686 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2687
2688 =cut
2689
2690 sub find_or_create {
2691   my $self     = shift;
2692   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2693   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2694   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2695     return $row;
2696   }
2697   return $self->create($hash);
2698 }
2699
2700 =head2 update_or_create
2701
2702 =over 4
2703
2704 =item Arguments: \%col_values, { key => $unique_constraint }?
2705
2706 =item Return Value: $row_object
2707
2708 =back
2709
2710   $resultset->update_or_create({ col => $val, ... });
2711
2712 Like L</find_or_create>, but if a row is found it is immediately updated via
2713 C<< $found_row->update (\%col_values) >>.
2714
2715
2716 Takes an optional C<key> attribute to search on a specific unique constraint.
2717 For example:
2718
2719   # In your application
2720   my $cd = $schema->resultset('CD')->update_or_create(
2721     {
2722       artist => 'Massive Attack',
2723       title  => 'Mezzanine',
2724       year   => 1998,
2725     },
2726     { key => 'cd_artist_title' }
2727   );
2728
2729   $cd->cd_to_producer->update_or_create({
2730     producer => $producer,
2731     name => 'harry',
2732   }, {
2733     key => 'primary',
2734   });
2735
2736 B<Note>: Make sure to read the documentation of L</find> and understand the
2737 significance of the C<key> attribute, as its lack may skew your search, and
2738 subsequently result in spurious row creation.
2739
2740 B<Note>: Take care when using C<update_or_create> with a table having
2741 columns with default values that you intend to be automatically
2742 supplied by the database (e.g. an auto_increment primary key column).
2743 In normal usage, the value of such columns should NOT be included at
2744 all in the call to C<update_or_create>, even when set to C<undef>.
2745
2746 See also L</find> and L</find_or_create>. For information on how to declare
2747 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2748
2749 =cut
2750
2751 sub update_or_create {
2752   my $self = shift;
2753   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2754   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2755
2756   my $row = $self->find($cond, $attrs);
2757   if (defined $row) {
2758     $row->update($cond);
2759     return $row;
2760   }
2761
2762   return $self->create($cond);
2763 }
2764
2765 =head2 update_or_new
2766
2767 =over 4
2768
2769 =item Arguments: \%col_values, { key => $unique_constraint }?
2770
2771 =item Return Value: $rowobject
2772
2773 =back
2774
2775   $resultset->update_or_new({ col => $val, ... });
2776
2777 Like L</find_or_new> but if a row is found it is immediately updated via
2778 C<< $found_row->update (\%col_values) >>.
2779
2780 For example:
2781
2782   # In your application
2783   my $cd = $schema->resultset('CD')->update_or_new(
2784     {
2785       artist => 'Massive Attack',
2786       title  => 'Mezzanine',
2787       year   => 1998,
2788     },
2789     { key => 'cd_artist_title' }
2790   );
2791
2792   if ($cd->in_storage) {
2793       # the cd was updated
2794   }
2795   else {
2796       # the cd is not yet in the database, let's insert it
2797       $cd->insert;
2798   }
2799
2800 B<Note>: Make sure to read the documentation of L</find> and understand the
2801 significance of the C<key> attribute, as its lack may skew your search, and
2802 subsequently result in spurious new objects.
2803
2804 B<Note>: Take care when using C<update_or_new> with a table having
2805 columns with default values that you intend to be automatically
2806 supplied by the database (e.g. an auto_increment primary key column).
2807 In normal usage, the value of such columns should NOT be included at
2808 all in the call to C<update_or_new>, even when set to C<undef>.
2809
2810 See also L</find>, L</find_or_create> and L</find_or_new>.
2811
2812 =cut
2813
2814 sub update_or_new {
2815     my $self  = shift;
2816     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2817     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2818
2819     my $row = $self->find( $cond, $attrs );
2820     if ( defined $row ) {
2821         $row->update($cond);
2822         return $row;
2823     }
2824
2825     return $self->new_result($cond);
2826 }
2827
2828 =head2 get_cache
2829
2830 =over 4
2831
2832 =item Arguments: none
2833
2834 =item Return Value: \@cache_objects | undef
2835
2836 =back
2837
2838 Gets the contents of the cache for the resultset, if the cache is set.
2839
2840 The cache is populated either by using the L</prefetch> attribute to
2841 L</search> or by calling L</set_cache>.
2842
2843 =cut
2844
2845 sub get_cache {
2846   shift->{all_cache};
2847 }
2848
2849 =head2 set_cache
2850
2851 =over 4
2852
2853 =item Arguments: \@cache_objects
2854
2855 =item Return Value: \@cache_objects
2856
2857 =back
2858
2859 Sets the contents of the cache for the resultset. Expects an arrayref
2860 of objects of the same class as those produced by the resultset. Note that
2861 if the cache is set the resultset will return the cached objects rather
2862 than re-querying the database even if the cache attr is not set.
2863
2864 The contents of the cache can also be populated by using the
2865 L</prefetch> attribute to L</search>.
2866
2867 =cut
2868
2869 sub set_cache {
2870   my ( $self, $data ) = @_;
2871   $self->throw_exception("set_cache requires an arrayref")
2872       if defined($data) && (ref $data ne 'ARRAY');
2873   $self->{all_cache} = $data;
2874 }
2875
2876 =head2 clear_cache
2877
2878 =over 4
2879
2880 =item Arguments: none
2881
2882 =item Return Value: undef
2883
2884 =back
2885
2886 Clears the cache for the resultset.
2887
2888 =cut
2889
2890 sub clear_cache {
2891   shift->set_cache(undef);
2892 }
2893
2894 =head2 is_paged
2895
2896 =over 4
2897
2898 =item Arguments: none
2899
2900 =item Return Value: true, if the resultset has been paginated
2901
2902 =back
2903
2904 =cut
2905
2906 sub is_paged {
2907   my ($self) = @_;
2908   return !!$self->{attrs}{page};
2909 }
2910
2911 =head2 is_ordered
2912
2913 =over 4
2914
2915 =item Arguments: none
2916
2917 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2918
2919 =back
2920
2921 =cut
2922
2923 sub is_ordered {
2924   my ($self) = @_;
2925   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2926 }
2927
2928 =head2 related_resultset
2929
2930 =over 4
2931
2932 =item Arguments: $relationship_name
2933
2934 =item Return Value: $resultset
2935
2936 =back
2937
2938 Returns a related resultset for the supplied relationship name.
2939
2940   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2941
2942 =cut
2943
2944 sub related_resultset {
2945   my ($self, $rel) = @_;
2946
2947   $self->{related_resultsets} ||= {};
2948   return $self->{related_resultsets}{$rel} ||= do {
2949     my $rsrc = $self->result_source;
2950     my $rel_info = $rsrc->relationship_info($rel);
2951
2952     $self->throw_exception(
2953       "search_related: result source '" . $rsrc->source_name .
2954         "' has no such relationship $rel")
2955       unless $rel_info;
2956
2957     my $attrs = $self->_chain_relationship($rel);
2958
2959     my $join_count = $attrs->{seen_join}{$rel};
2960
2961     my $alias = $self->result_source->storage
2962         ->relname_to_table_alias($rel, $join_count);
2963
2964     # since this is search_related, and we already slid the select window inwards
2965     # (the select/as attrs were deleted in the beginning), we need to flip all
2966     # left joins to inner, so we get the expected results
2967     # read the comment on top of the actual function to see what this does
2968     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2969
2970
2971     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2972     delete @{$attrs}{qw(result_class alias)};
2973
2974     my $new_cache;
2975
2976     if (my $cache = $self->get_cache) {
2977       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2978         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2979                         @$cache ];
2980       }
2981     }
2982
2983     my $rel_source = $rsrc->related_source($rel);
2984
2985     my $new = do {
2986
2987       # The reason we do this now instead of passing the alias to the
2988       # search_rs below is that if you wrap/overload resultset on the
2989       # source you need to know what alias it's -going- to have for things
2990       # to work sanely (e.g. RestrictWithObject wants to be able to add
2991       # extra query restrictions, and these may need to be $alias.)
2992
2993       my $rel_attrs = $rel_source->resultset_attributes;
2994       local $rel_attrs->{alias} = $alias;
2995
2996       $rel_source->resultset
2997                  ->search_rs(
2998                      undef, {
2999                        %$attrs,
3000                        where => $attrs->{where},
3001                    });
3002     };
3003     $new->set_cache($new_cache) if $new_cache;
3004     $new;
3005   };
3006 }
3007
3008 =head2 current_source_alias
3009
3010 =over 4
3011
3012 =item Arguments: none
3013
3014 =item Return Value: $source_alias
3015
3016 =back
3017
3018 Returns the current table alias for the result source this resultset is built
3019 on, that will be used in the SQL query. Usually it is C<me>.
3020
3021 Currently the source alias that refers to the result set returned by a
3022 L</search>/L</find> family method depends on how you got to the resultset: it's
3023 C<me> by default, but eg. L</search_related> aliases it to the related result
3024 source name (and keeps C<me> referring to the original result set). The long
3025 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3026 (and make this method unnecessary).
3027
3028 Thus it's currently necessary to use this method in predefined queries (see
3029 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3030 source alias of the current result set:
3031
3032   # in a result set class
3033   sub modified_by {
3034     my ($self, $user) = @_;
3035
3036     my $me = $self->current_source_alias;
3037
3038     return $self->search(
3039       "$me.modified" => $user->id,
3040     );
3041   }
3042
3043 =cut
3044
3045 sub current_source_alias {
3046   my ($self) = @_;
3047
3048   return ($self->{attrs} || {})->{alias} || 'me';
3049 }
3050
3051 =head2 as_subselect_rs
3052
3053 =over 4
3054
3055 =item Arguments: none
3056
3057 =item Return Value: $resultset
3058
3059 =back
3060
3061 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3062 "virtual view" by including it as a subquery within the from clause.  From this
3063 point on, any joined tables are inaccessible to ->search on the resultset (as if
3064 it were simply where-filtered without joins).  For example:
3065
3066  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3067
3068  # 'x' now pollutes the query namespace
3069
3070  # So the following works as expected
3071  my $ok_rs = $rs->search({'x.other' => 1});
3072
3073  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3074  # def) we look for one row with contradictory terms and join in another table
3075  # (aliased 'x_2') which we never use
3076  my $broken_rs = $rs->search({'x.name' => 'def'});
3077
3078  my $rs2 = $rs->as_subselect_rs;
3079
3080  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3081  my $not_joined_rs = $rs2->search({'x.other' => 1});
3082
3083  # works as expected: finds a 'table' row related to two x rows (abc and def)
3084  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3085
3086 Another example of when one might use this would be to select a subset of
3087 columns in a group by clause:
3088
3089  my $rs = $schema->resultset('Bar')->search(undef, {
3090    group_by => [qw{ id foo_id baz_id }],
3091  })->as_subselect_rs->search(undef, {
3092    columns => [qw{ id foo_id }]
3093  });
3094
3095 In the above example normally columns would have to be equal to the group by,
3096 but because we isolated the group by into a subselect the above works.
3097
3098 =cut
3099
3100 sub as_subselect_rs {
3101   my $self = shift;
3102
3103   my $attrs = $self->_resolved_attrs;
3104
3105   my $fresh_rs = (ref $self)->new (
3106     $self->result_source
3107   );
3108
3109   # these pieces will be locked in the subquery
3110   delete $fresh_rs->{cond};
3111   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3112
3113   return $fresh_rs->search( {}, {
3114     from => [{
3115       $attrs->{alias} => $self->as_query,
3116       -alias  => $attrs->{alias},
3117       -rsrc   => $self->result_source,
3118     }],
3119     alias => $attrs->{alias},
3120   });
3121 }
3122
3123 # This code is called by search_related, and makes sure there
3124 # is clear separation between the joins before, during, and
3125 # after the relationship. This information is needed later
3126 # in order to properly resolve prefetch aliases (any alias
3127 # with a relation_chain_depth less than the depth of the
3128 # current prefetch is not considered)
3129 #
3130 # The increments happen twice per join. An even number means a
3131 # relationship specified via a search_related, whereas an odd
3132 # number indicates a join/prefetch added via attributes
3133 #
3134 # Also this code will wrap the current resultset (the one we
3135 # chain to) in a subselect IFF it contains limiting attributes
3136 sub _chain_relationship {
3137   my ($self, $rel) = @_;
3138   my $source = $self->result_source;
3139   my $attrs = { %{$self->{attrs}||{}} };
3140
3141   # we need to take the prefetch the attrs into account before we
3142   # ->_resolve_join as otherwise they get lost - captainL
3143   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3144
3145   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3146
3147   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3148
3149   my $from;
3150   my @force_subq_attrs = qw/offset rows group_by having/;
3151
3152   if (
3153     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3154       ||
3155     $self->_has_resolved_attr (@force_subq_attrs)
3156   ) {
3157     # Nuke the prefetch (if any) before the new $rs attrs
3158     # are resolved (prefetch is useless - we are wrapping
3159     # a subquery anyway).
3160     my $rs_copy = $self->search;
3161     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3162       $rs_copy->{attrs}{join},
3163       delete $rs_copy->{attrs}{prefetch},
3164     );
3165
3166     $from = [{
3167       -rsrc   => $source,
3168       -alias  => $attrs->{alias},
3169       $attrs->{alias} => $rs_copy->as_query,
3170     }];
3171     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3172     $seen->{-relation_chain_depth} = 0;
3173   }
3174   elsif ($attrs->{from}) {  #shallow copy suffices
3175     $from = [ @{$attrs->{from}} ];
3176   }
3177   else {
3178     $from = [{
3179       -rsrc  => $source,
3180       -alias => $attrs->{alias},
3181       $attrs->{alias} => $source->from,
3182     }];
3183   }
3184
3185   my $jpath = ($seen->{-relation_chain_depth})
3186     ? $from->[-1][0]{-join_path}
3187     : [];
3188
3189   my @requested_joins = $source->_resolve_join(
3190     $join,
3191     $attrs->{alias},
3192     $seen,
3193     $jpath,
3194   );
3195
3196   push @$from, @requested_joins;
3197
3198   $seen->{-relation_chain_depth}++;
3199
3200   # if $self already had a join/prefetch specified on it, the requested
3201   # $rel might very well be already included. What we do in this case
3202   # is effectively a no-op (except that we bump up the chain_depth on
3203   # the join in question so we could tell it *is* the search_related)
3204   my $already_joined;
3205
3206   # we consider the last one thus reverse
3207   for my $j (reverse @requested_joins) {
3208     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3209     if ($rel eq $last_j) {
3210       $j->[0]{-relation_chain_depth}++;
3211       $already_joined++;
3212       last;
3213     }
3214   }
3215
3216   unless ($already_joined) {
3217     push @$from, $source->_resolve_join(
3218       $rel,
3219       $attrs->{alias},
3220       $seen,
3221       $jpath,
3222     );
3223   }
3224
3225   $seen->{-relation_chain_depth}++;
3226
3227   return {%$attrs, from => $from, seen_join => $seen};
3228 }
3229
3230 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3231 sub _resolved_attrs_copy {
3232   my $self = shift;
3233   return { %{$self->_resolved_attrs (@_)} };
3234 }
3235
3236 sub _resolved_attrs {
3237   my $self = shift;
3238   return $self->{_attrs} if $self->{_attrs};
3239
3240   my $attrs  = { %{ $self->{attrs} || {} } };
3241   my $source = $self->result_source;
3242   my $alias  = $attrs->{alias};
3243
3244   # one last pass of normalization
3245   $self->_normalize_selection($attrs);
3246
3247   # default selection list
3248   $attrs->{columns} = [ $source->columns ]
3249     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as _trailing_select/;
3250
3251   # merge selectors together
3252   for (qw/columns select as _trailing_select/) {
3253     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, $attrs->{"+$_"})
3254       if $attrs->{$_} or $attrs->{"+$_"};
3255   }
3256
3257   # disassemble columns
3258   my (@sel, @as);
3259   if (my $cols = delete $attrs->{columns}) {
3260     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3261       if (ref $c eq 'HASH') {
3262         for my $as (keys %$c) {
3263           push @sel, $c->{$as};
3264           push @as, $as;
3265         }
3266       }
3267       else {
3268         push @sel, $c;
3269         push @as, $c;
3270       }
3271     }
3272   }
3273
3274   # when trying to weed off duplicates later do not go past this point -
3275   # everything added from here on is unbalanced "anyone's guess" stuff
3276   my $dedup_stop_idx = $#as;
3277
3278   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3279     if $attrs->{as};
3280   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3281     if $attrs->{select};
3282
3283   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3284   for (@sel) {
3285     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3286   }
3287
3288   # disqualify all $alias.col as-bits (collapser mandated)
3289   for (@as) {
3290     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3291   }
3292
3293   # de-duplicate the result (remove *identical* select/as pairs)
3294   # and also die on duplicate {as} pointing to different {select}s
3295   # not using a c-style for as the condition is prone to shrinkage
3296   my $seen;
3297   my $i = 0;
3298   while ($i <= $dedup_stop_idx) {
3299     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3300       splice @sel, $i, 1;
3301       splice @as, $i, 1;
3302       $dedup_stop_idx--;
3303     }
3304     elsif ($seen->{$as[$i]}++) {
3305       $self->throw_exception(
3306         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3307       );
3308     }
3309     else {
3310       $i++;
3311     }
3312   }
3313
3314   $attrs->{select} = \@sel;
3315   $attrs->{as} = \@as;
3316
3317   $attrs->{from} ||= [{
3318     -rsrc   => $source,
3319     -alias  => $self->{attrs}{alias},
3320     $self->{attrs}{alias} => $source->from,
3321   }];
3322
3323   if ( $attrs->{join} || $attrs->{prefetch} ) {
3324
3325     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3326       if ref $attrs->{from} ne 'ARRAY';
3327
3328     my $join = (delete $attrs->{join}) || {};
3329
3330     if ( defined $attrs->{prefetch} ) {
3331       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3332     }
3333
3334     $attrs->{from} =    # have to copy here to avoid corrupting the original
3335       [
3336         @{ $attrs->{from} },
3337         $source->_resolve_join(
3338           $join,
3339           $alias,
3340           { %{ $attrs->{seen_join} || {} } },
3341           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3342             ? $attrs->{from}[-1][0]{-join_path}
3343             : []
3344           ,
3345         )
3346       ];
3347   }
3348
3349   if ( defined $attrs->{order_by} ) {
3350     $attrs->{order_by} = (
3351       ref( $attrs->{order_by} ) eq 'ARRAY'
3352       ? [ @{ $attrs->{order_by} } ]
3353       : [ $attrs->{order_by} || () ]
3354     );
3355   }
3356
3357   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3358     $attrs->{group_by} = [ $attrs->{group_by} ];
3359   }
3360
3361   # generate the distinct induced group_by early, as prefetch will be carried via a
3362   # subquery (since a group_by is present)
3363   if (delete $attrs->{distinct}) {
3364     if ($attrs->{group_by}) {
3365       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3366     }
3367     else {
3368       # distinct affects only the main selection part, not what prefetch may
3369       # add below. However trailing is not yet a part of the selection as
3370       # prefetch must insert before it
3371       $attrs->{group_by} = $source->storage->_group_over_selection (
3372         $attrs->{from},
3373         [ @{$attrs->{select}||[]}, @{$attrs->{_trailing_select}||[]} ],
3374         $attrs->{order_by},
3375       );
3376     }
3377   }
3378
3379   $attrs->{collapse} ||= {};
3380   if ($attrs->{prefetch}) {
3381     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3382
3383     my $prefetch_ordering = [];
3384
3385     # this is a separate structure (we don't look in {from} directly)
3386     # as the resolver needs to shift things off the lists to work
3387     # properly (identical-prefetches on different branches)
3388     my $join_map = {};
3389     if (ref $attrs->{from} eq 'ARRAY') {
3390
3391       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3392
3393       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3394         next unless $j->[0]{-alias};
3395         next unless $j->[0]{-join_path};
3396         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3397
3398         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3399
3400         my $p = $join_map;
3401         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3402         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3403       }
3404     }
3405
3406     my @prefetch =
3407       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3408
3409     # we need to somehow mark which columns came from prefetch
3410     if (@prefetch) {
3411       my $sel_end = $#{$attrs->{select}};
3412       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3413     }
3414
3415     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3416     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3417
3418     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3419     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3420   }
3421
3422
3423   push @{ $attrs->{select} }, @{$attrs->{_trailing_select}}
3424     if $attrs->{_trailing_select};
3425
3426   # if both page and offset are specified, produce a combined offset
3427   # even though it doesn't make much sense, this is what pre 081xx has
3428   # been doing
3429   if (my $page = delete $attrs->{page}) {
3430     $attrs->{offset} =
3431       ($attrs->{rows} * ($page - 1))
3432             +
3433       ($attrs->{offset} || 0)
3434     ;
3435   }
3436
3437   return $self->{_attrs} = $attrs;
3438 }
3439
3440 sub _rollout_attr {
3441   my ($self, $attr) = @_;
3442
3443   if (ref $attr eq 'HASH') {
3444     return $self->_rollout_hash($attr);
3445   } elsif (ref $attr eq 'ARRAY') {
3446     return $self->_rollout_array($attr);
3447   } else {
3448     return [$attr];
3449   }
3450 }
3451
3452 sub _rollout_array {
3453   my ($self, $attr) = @_;
3454
3455   my @rolled_array;
3456   foreach my $element (@{$attr}) {
3457     if (ref $element eq 'HASH') {
3458       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3459     } elsif (ref $element eq 'ARRAY') {
3460       #  XXX - should probably recurse here
3461       push( @rolled_array, @{$self->_rollout_array($element)} );
3462     } else {
3463       push( @rolled_array, $element );
3464     }
3465   }
3466   return \@rolled_array;
3467 }
3468
3469 sub _rollout_hash {
3470   my ($self, $attr) = @_;
3471
3472   my @rolled_array;
3473   foreach my $key (keys %{$attr}) {
3474     push( @rolled_array, { $key => $attr->{$key} } );
3475   }
3476   return \@rolled_array;
3477 }
3478
3479 sub _calculate_score {
3480   my ($self, $a, $b) = @_;
3481
3482   if (defined $a xor defined $b) {
3483     return 0;
3484   }
3485   elsif (not defined $a) {
3486     return 1;
3487   }
3488
3489   if (ref $b eq 'HASH') {
3490     my ($b_key) = keys %{$b};
3491     if (ref $a eq 'HASH') {
3492       my ($a_key) = keys %{$a};
3493       if ($a_key eq $b_key) {
3494         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3495       } else {
3496         return 0;
3497       }
3498     } else {
3499       return ($a eq $b_key) ? 1 : 0;
3500     }
3501   } else {
3502     if (ref $a eq 'HASH') {
3503       my ($a_key) = keys %{$a};
3504       return ($b eq $a_key) ? 1 : 0;
3505     } else {
3506       return ($b eq $a) ? 1 : 0;
3507     }
3508   }
3509 }
3510
3511 sub _merge_joinpref_attr {
3512   my ($self, $orig, $import) = @_;
3513
3514   return $import unless defined($orig);
3515   return $orig unless defined($import);
3516
3517   $orig = $self->_rollout_attr($orig);
3518   $import = $self->_rollout_attr($import);
3519
3520   my $seen_keys;
3521   foreach my $import_element ( @{$import} ) {
3522     # find best candidate from $orig to merge $b_element into
3523     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3524     foreach my $orig_element ( @{$orig} ) {
3525       my $score = $self->_calculate_score( $orig_element, $import_element );
3526       if ($score > $best_candidate->{score}) {
3527         $best_candidate->{position} = $position;
3528         $best_candidate->{score} = $score;
3529       }
3530       $position++;
3531     }
3532     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3533
3534     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3535       push( @{$orig}, $import_element );
3536     } else {
3537       my $orig_best = $orig->[$best_candidate->{position}];
3538       # merge orig_best and b_element together and replace original with merged
3539       if (ref $orig_best ne 'HASH') {
3540         $orig->[$best_candidate->{position}] = $import_element;
3541       } elsif (ref $import_element eq 'HASH') {
3542         my ($key) = keys %{$orig_best};
3543         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3544       }
3545     }
3546     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3547   }
3548
3549   return $orig;
3550 }
3551
3552 {
3553   my $hm;
3554
3555   sub _merge_attr {
3556     $hm ||= do {
3557       require Hash::Merge;
3558       my $hm = Hash::Merge->new;
3559
3560       $hm->specify_behavior({
3561         SCALAR => {
3562           SCALAR => sub {
3563             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3564
3565             if ($defl xor $defr) {
3566               return [ $defl ? $_[0] : $_[1] ];
3567             }
3568             elsif (! $defl) {
3569               return [];
3570             }
3571             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3572               return [ $_[0] ];
3573             }
3574             else {
3575               return [$_[0], $_[1]];
3576             }
3577           },
3578           ARRAY => sub {
3579             return $_[1] if !defined $_[0];
3580             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3581             return [$_[0], @{$_[1]}]
3582           },
3583           HASH  => sub {
3584             return [] if !defined $_[0] and !keys %{$_[1]};
3585             return [ $_[1] ] if !defined $_[0];
3586             return [ $_[0] ] if !keys %{$_[1]};
3587             return [$_[0], $_[1]]
3588           },
3589         },
3590         ARRAY => {
3591           SCALAR => sub {
3592             return $_[0] if !defined $_[1];
3593             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3594             return [@{$_[0]}, $_[1]]
3595           },
3596           ARRAY => sub {
3597             my @ret = @{$_[0]} or return $_[1];
3598             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3599             my %idx = map { $_ => 1 } @ret;
3600             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3601             \@ret;
3602           },
3603           HASH => sub {
3604             return [ $_[1] ] if ! @{$_[0]};
3605             return $_[0] if !keys %{$_[1]};
3606             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3607             return [ @{$_[0]}, $_[1] ];
3608           },
3609         },
3610         HASH => {
3611           SCALAR => sub {
3612             return [] if !keys %{$_[0]} and !defined $_[1];
3613             return [ $_[0] ] if !defined $_[1];
3614             return [ $_[1] ] if !keys %{$_[0]};
3615             return [$_[0], $_[1]]
3616           },
3617           ARRAY => sub {
3618             return [] if !keys %{$_[0]} and !@{$_[1]};
3619             return [ $_[0] ] if !@{$_[1]};
3620             return $_[1] if !keys %{$_[0]};
3621             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3622             return [ $_[0], @{$_[1]} ];
3623           },
3624           HASH => sub {
3625             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3626             return [ $_[0] ] if !keys %{$_[1]};
3627             return [ $_[1] ] if !keys %{$_[0]};
3628             return [ $_[0] ] if $_[0] eq $_[1];
3629             return [ $_[0], $_[1] ];
3630           },
3631         }
3632       } => 'DBIC_RS_ATTR_MERGER');
3633       $hm;
3634     };
3635
3636     return $hm->merge ($_[1], $_[2]);
3637   }
3638 }
3639
3640 sub STORABLE_freeze {
3641   my ($self, $cloning) = @_;
3642   my $to_serialize = { %$self };
3643
3644   # A cursor in progress can't be serialized (and would make little sense anyway)
3645   delete $to_serialize->{cursor};
3646
3647   Storable::nfreeze($to_serialize);
3648 }
3649
3650 # need this hook for symmetry
3651 sub STORABLE_thaw {
3652   my ($self, $cloning, $serialized) = @_;
3653
3654   %$self = %{ Storable::thaw($serialized) };
3655
3656   $self;
3657 }
3658
3659
3660 =head2 throw_exception
3661
3662 See L<DBIx::Class::Schema/throw_exception> for details.
3663
3664 =cut
3665
3666 sub throw_exception {
3667   my $self=shift;
3668
3669   if (ref $self and my $rsrc = $self->result_source) {
3670     $rsrc->throw_exception(@_)
3671   }
3672   else {
3673     DBIx::Class::Exception->throw(@_);
3674   }
3675 }
3676
3677 # XXX: FIXME: Attributes docs need clearing up
3678
3679 =head1 ATTRIBUTES
3680
3681 Attributes are used to refine a ResultSet in various ways when
3682 searching for data. They can be passed to any method which takes an
3683 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3684 L</count>.
3685
3686 These are in no particular order:
3687
3688 =head2 order_by
3689
3690 =over 4
3691
3692 =item Value: ( $order_by | \@order_by | \%order_by )
3693
3694 =back
3695
3696 Which column(s) to order the results by.
3697
3698 [The full list of suitable values is documented in
3699 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3700 common options.]
3701
3702 If a single column name, or an arrayref of names is supplied, the
3703 argument is passed through directly to SQL. The hashref syntax allows
3704 for connection-agnostic specification of ordering direction:
3705
3706  For descending order:
3707
3708   order_by => { -desc => [qw/col1 col2 col3/] }
3709
3710  For explicit ascending order:
3711
3712   order_by => { -asc => 'col' }
3713
3714 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3715 supported, although you are strongly encouraged to use the hashref
3716 syntax as outlined above.
3717
3718 =head2 columns
3719
3720 =over 4
3721
3722 =item Value: \@columns
3723
3724 =back
3725
3726 Shortcut to request a particular set of columns to be retrieved. Each
3727 column spec may be a string (a table column name), or a hash (in which
3728 case the key is the C<as> value, and the value is used as the C<select>
3729 expression). Adds C<me.> onto the start of any column without a C<.> in
3730 it and sets C<select> from that, then auto-populates C<as> from
3731 C<select> as normal. (You may also use the C<cols> attribute, as in
3732 earlier versions of DBIC.)
3733
3734 Essentially C<columns> does the same as L</select> and L</as>.
3735
3736     columns => [ 'foo', { bar => 'baz' } ]
3737
3738 is the same as
3739
3740     select => [qw/foo baz/],
3741     as => [qw/foo bar/]
3742
3743 =head2 +columns
3744
3745 =over 4
3746
3747 =item Value: \@columns
3748
3749 =back
3750
3751 Indicates additional columns to be selected from storage. Works the same
3752 as L</columns> but adds columns to the selection. (You may also use the
3753 C<include_columns> attribute, as in earlier versions of DBIC). For
3754 example:-
3755
3756   $schema->resultset('CD')->search(undef, {
3757     '+columns' => ['artist.name'],
3758     join => ['artist']
3759   });
3760
3761 would return all CDs and include a 'name' column to the information
3762 passed to object inflation. Note that the 'artist' is the name of the
3763 column (or relationship) accessor, and 'name' is the name of the column
3764 accessor in the related table.
3765
3766 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3767 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3768 unary plus operator before it.
3769
3770 =head2 include_columns
3771
3772 =over 4
3773
3774 =item Value: \@columns
3775
3776 =back
3777
3778 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3779
3780 =head2 select
3781
3782 =over 4
3783
3784 =item Value: \@select_columns
3785
3786 =back
3787
3788 Indicates which columns should be selected from the storage. You can use
3789 column names, or in the case of RDBMS back ends, function or stored procedure
3790 names:
3791
3792   $rs = $schema->resultset('Employee')->search(undef, {
3793     select => [
3794       'name',
3795       { count => 'employeeid' },
3796       { max => { length => 'name' }, -as => 'longest_name' }
3797     ]
3798   });
3799
3800   # Equivalent SQL
3801   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3802
3803 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3804 use L</select>, to instruct DBIx::Class how to store the result of the column.
3805 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3806 identifier aliasing. You can however alias a function, so you can use it in
3807 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3808 attribute> supplied as shown in the example above.
3809
3810 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3811 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3812 unary plus operator before it.
3813
3814 =head2 +select
3815
3816 =over 4
3817
3818 Indicates additional columns to be selected from storage.  Works the same as
3819 L</select> but adds columns to the default selection, instead of specifying
3820 an explicit list.
3821
3822 =back
3823
3824 =head2 +as
3825
3826 =over 4
3827
3828 Indicates additional column names for those added via L</+select>. See L</as>.
3829
3830 =back
3831
3832 =head2 as
3833
3834 =over 4
3835
3836 =item Value: \@inflation_names
3837
3838 =back
3839
3840 Indicates column names for object inflation. That is L</as> indicates the
3841 slot name in which the column value will be stored within the
3842 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3843 identifier by the C<get_column> method (or via the object accessor B<if one
3844 with the same name already exists>) as shown below. The L</as> attribute has
3845 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3846
3847   $rs = $schema->resultset('Employee')->search(undef, {
3848     select => [
3849       'name',
3850       { count => 'employeeid' },
3851       { max => { length => 'name' }, -as => 'longest_name' }
3852     ],
3853     as => [qw/
3854       name
3855       employee_count
3856       max_name_length
3857     /],
3858   });
3859
3860 If the object against which the search is performed already has an accessor
3861 matching a column name specified in C<as>, the value can be retrieved using
3862 the accessor as normal:
3863
3864   my $name = $employee->name();
3865
3866 If on the other hand an accessor does not exist in the object, you need to
3867 use C<get_column> instead:
3868
3869   my $employee_count = $employee->get_column('employee_count');
3870
3871 You can create your own accessors if required - see
3872 L<DBIx::Class::Manual::Cookbook> for details.
3873
3874 =head2 join
3875
3876 =over 4
3877
3878 =item Value: ($rel_name | \@rel_names | \%rel_names)
3879
3880 =back
3881
3882 Contains a list of relationships that should be joined for this query.  For
3883 example:
3884
3885   # Get CDs by Nine Inch Nails
3886   my $rs = $schema->resultset('CD')->search(
3887     { 'artist.name' => 'Nine Inch Nails' },
3888     { join => 'artist' }
3889   );
3890
3891 Can also contain a hash reference to refer to the other relation's relations.
3892 For example:
3893
3894   package MyApp::Schema::Track;
3895   use base qw/DBIx::Class/;
3896   __PACKAGE__->table('track');
3897   __PACKAGE__->add_columns(qw/trackid cd position title/);
3898   __PACKAGE__->set_primary_key('trackid');
3899   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3900   1;
3901
3902   # In your application
3903   my $rs = $schema->resultset('Artist')->search(
3904     { 'track.title' => 'Teardrop' },
3905     {
3906       join     => { cd => 'track' },
3907       order_by => 'artist.name',
3908     }
3909   );
3910
3911 You need to use the relationship (not the table) name in  conditions,
3912 because they are aliased as such. The current table is aliased as "me", so
3913 you need to use me.column_name in order to avoid ambiguity. For example:
3914
3915   # Get CDs from 1984 with a 'Foo' track
3916   my $rs = $schema->resultset('CD')->search(
3917     {
3918       'me.year' => 1984,
3919       'tracks.name' => 'Foo'
3920     },
3921     { join => 'tracks' }
3922   );
3923
3924 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3925 similarly for a third time). For e.g.
3926
3927   my $rs = $schema->resultset('Artist')->search({
3928     'cds.title'   => 'Down to Earth',
3929     'cds_2.title' => 'Popular',
3930   }, {
3931     join => [ qw/cds cds/ ],
3932   });
3933
3934 will return a set of all artists that have both a cd with title 'Down
3935 to Earth' and a cd with title 'Popular'.
3936
3937 If you want to fetch related objects from other tables as well, see C<prefetch>
3938 below.
3939
3940 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3941
3942 =head2 prefetch
3943
3944 =over 4
3945
3946 =item Value: ($rel_name | \@rel_names | \%rel_names)
3947
3948 =back
3949
3950 Contains one or more relationships that should be fetched along with
3951 the main query (when they are accessed afterwards the data will
3952 already be available, without extra queries to the database).  This is
3953 useful for when you know you will need the related objects, because it
3954 saves at least one query:
3955
3956   my $rs = $schema->resultset('Tag')->search(
3957     undef,
3958     {
3959       prefetch => {
3960         cd => 'artist'
3961       }
3962     }
3963   );
3964
3965 The initial search results in SQL like the following:
3966
3967   SELECT tag.*, cd.*, artist.* FROM tag
3968   JOIN cd ON tag.cd = cd.cdid
3969   JOIN artist ON cd.artist = artist.artistid
3970
3971 L<DBIx::Class> has no need to go back to the database when we access the
3972 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3973 case.
3974
3975 Simple prefetches will be joined automatically, so there is no need
3976 for a C<join> attribute in the above search.
3977
3978 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3979 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3980 with an accessor type of 'single' or 'filter'). A more complex example that
3981 prefetches an artists cds, the tracks on those cds, and the tags associated
3982 with that artist is given below (assuming many-to-many from artists to tags):
3983
3984  my $rs = $schema->resultset('Artist')->search(
3985    undef,
3986    {
3987      prefetch => [
3988        { cds => 'tracks' },
3989        { artist_tags => 'tags' }
3990      ]
3991    }
3992  );
3993
3994
3995 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3996 attributes will be ignored.
3997
3998 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3999 exactly as you might expect.
4000
4001 =over 4
4002
4003 =item *
4004
4005 Prefetch uses the L</cache> to populate the prefetched relationships. This
4006 may or may not be what you want.
4007
4008 =item *
4009
4010 If you specify a condition on a prefetched relationship, ONLY those
4011 rows that match the prefetched condition will be fetched into that relationship.
4012 This means that adding prefetch to a search() B<may alter> what is returned by
4013 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4014
4015   my $artist_rs = $schema->resultset('Artist')->search({
4016       'cds.year' => 2008,
4017   }, {
4018       join => 'cds',
4019   });
4020
4021   my $count = $artist_rs->first->cds->count;
4022
4023   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4024
4025   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4026
4027   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4028
4029 that cmp_ok() may or may not pass depending on the datasets involved. This
4030 behavior may or may not survive the 0.09 transition.
4031
4032 =back
4033
4034 =head2 page
4035
4036 =over 4
4037
4038 =item Value: $page
4039
4040 =back
4041
4042 Makes the resultset paged and specifies the page to retrieve. Effectively
4043 identical to creating a non-pages resultset and then calling ->page($page)
4044 on it.
4045
4046 If L</rows> attribute is not specified it defaults to 10 rows per page.
4047
4048 When you have a paged resultset, L</count> will only return the number
4049 of rows in the page. To get the total, use the L</pager> and call
4050 C<total_entries> on it.
4051
4052 =head2 rows
4053
4054 =over 4
4055
4056 =item Value: $rows
4057
4058 =back
4059
4060 Specifies the maximum number of rows for direct retrieval or the number of
4061 rows per page if the page attribute or method is used.
4062
4063 =head2 offset
4064
4065 =over 4
4066
4067 =item Value: $offset
4068
4069 =back
4070
4071 Specifies the (zero-based) row number for the  first row to be returned, or the
4072 of the first row of the first page if paging is used.
4073
4074 =head2 group_by
4075
4076 =over 4
4077
4078 =item Value: \@columns
4079
4080 =back
4081
4082 A arrayref of columns to group by. Can include columns of joined tables.
4083
4084   group_by => [qw/ column1 column2 ... /]
4085
4086 =head2 having
4087
4088 =over 4
4089
4090 =item Value: $condition
4091
4092 =back
4093
4094 HAVING is a select statement attribute that is applied between GROUP BY and
4095 ORDER BY. It is applied to the after the grouping calculations have been
4096 done.
4097
4098   having => { 'count_employee' => { '>=', 100 } }
4099
4100 or with an in-place function in which case literal SQL is required:
4101
4102   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4103
4104 =head2 distinct
4105
4106 =over 4
4107
4108 =item Value: (0 | 1)
4109
4110 =back
4111
4112 Set to 1 to group by all columns. If the resultset already has a group_by
4113 attribute, this setting is ignored and an appropriate warning is issued.
4114
4115 =head2 where
4116
4117 =over 4
4118
4119 Adds to the WHERE clause.
4120
4121   # only return rows WHERE deleted IS NULL for all searches
4122   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4123
4124 Can be overridden by passing C<< { where => undef } >> as an attribute
4125 to a resultset.
4126
4127 =back
4128
4129 =head2 cache
4130
4131 Set to 1 to cache search results. This prevents extra SQL queries if you
4132 revisit rows in your ResultSet:
4133
4134   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4135
4136   while( my $artist = $resultset->next ) {
4137     ... do stuff ...
4138   }
4139
4140   $rs->first; # without cache, this would issue a query
4141
4142 By default, searches are not cached.
4143
4144 For more examples of using these attributes, see
4145 L<DBIx::Class::Manual::Cookbook>.
4146
4147 =head2 for
4148
4149 =over 4
4150
4151 =item Value: ( 'update' | 'shared' )
4152
4153 =back
4154
4155 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4156 ... FOR SHARED.
4157
4158 =cut
4159
4160 1;