lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (ie:
 145 C<my $new_rs = $old_rs->search(\%extra_cond, \%attrs)>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247
 248   $attrs = { %{$attrs||{}} };
 249   delete @{$attrs}{qw(_sqlmaker_select_args _related_results_construction)};
 250
 251   if ($attrs->{page}) {
 252     $attrs->{rows} ||= 10;
 253   }
 254
 255   $attrs->{alias} ||= 'me';
 256
 257   my $self = bless {
 258     result_source => $source,
 259     cond => $attrs->{where},
 260     pager => undef,
 261     attrs => $attrs,
 262   }, $class;
 263
 264   # if there is a dark selector, this means we are already in a
 265   # chain and the cleanup/sanification was taken care of by
 266   # _search_rs already
 267   $self->_normalize_selection($attrs)
 268     unless $attrs->{_dark_selector};
 269
 270   $self->result_class(
 271     $attrs->{result_class} || $source->result_class
 272   );
 273
 274   $self;
 275 }
 276
 277 =head2 search
 278
 279 =over 4
 280
 281 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 282
 283 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 284
 285 =back
 286
 287   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 288   my $new_rs = $cd_rs->search({ year => 2005 });
 289
 290   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 291                  # year = 2005 OR year = 2004
 292
 293 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 294 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 295 To avoid that, use L</search_rs>.
 296
 297 If you need to pass in additional attributes but no additional condition,
 298 call it as C<search(undef, \%attrs)>.
 299
 300   # "SELECT name, artistid FROM $artist_table"
 301   my @all_artists = $schema->resultset('Artist')->search(undef, {
 302     columns => [qw/name artistid/],
 303   });
 304
 305 For a list of attributes that can be passed to C<search>, see
 306 L</ATTRIBUTES>. For more examples of using this function, see
 307 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 308 documentation for the first argument, see L<SQL::Abstract>
 309 and its extension L<DBIx::Class::SQLMaker>.
 310
 311 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 312
 313 =head3 CAVEAT
 314
 315 Note that L</search> does not process/deflate any of the values passed in the
 316 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 317 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 318 manually that any value passed to this method will stringify to something the
 319 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 320 objects, for more info see:
 321 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 322
 323 =cut
 324
 325 sub search {
 326   my $self = shift;
 327   my $rs = $self->search_rs( @_ );
 328
 329   if (wantarray) {
 330     return $rs->all;
 331   }
 332   elsif (defined wantarray) {
 333     return $rs;
 334   }
 335   else {
 336     # we can be called by a relationship helper, which in
 337     # turn may be called in void context due to some braindead
 338     # overload or whatever else the user decided to be clever
 339     # at this particular day. Thus limit the exception to
 340     # external code calls only
 341     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 342       if (caller)[0] !~ /^\QDBIx::Class::/;
 343
 344     return ();
 345   }
 346 }
 347
 348 =head2 search_rs
 349
 350 =over 4
 351
 352 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 353
 354 =item Return Value: L<$resultset|/search>
 355
 356 =back
 357
 358 This method does the same exact thing as search() except it will
 359 always return a resultset, even in list context.
 360
 361 =cut
 362
 363 sub search_rs {
 364   my $self = shift;
 365
 366   my $rsrc = $self->result_source;
 367   my ($call_cond, $call_attrs);
 368
 369   # Special-case handling for (undef, undef) or (undef)
 370   # Note that (foo => undef) is valid deprecated syntax
 371   @_ = () if not scalar grep { defined $_ } @_;
 372
 373   # just a cond
 374   if (@_ == 1) {
 375     $call_cond = shift;
 376   }
 377   # fish out attrs in the ($condref, $attr) case
 378   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 379     ($call_cond, $call_attrs) = @_;
 380   }
 381   elsif (@_ % 2) {
 382     $self->throw_exception('Odd number of arguments to search')
 383   }
 384   # legacy search
 385   elsif (@_) {
 386     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 387       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 388
 389     for my $i (0 .. $#_) {
 390       next if $i % 2;
 391       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 392         if (! defined $_[$i] or ref $_[$i] ne '');
 393     }
 394
 395     $call_cond = { @_ };
 396   }
 397
 398   # see if we can keep the cache (no $rs changes)
 399   my $cache;
 400   my %safe = (alias => 1, cache => 1);
 401   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 402     ! defined $call_cond
 403       or
 404     ref $call_cond eq 'HASH' && ! keys %$call_cond
 405       or
 406     ref $call_cond eq 'ARRAY' && ! @$call_cond
 407   )) {
 408     $cache = $self->get_cache;
 409   }
 410
 411   my $old_attrs = { %{$self->{attrs}} };
 412   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 413
 414   my $new_attrs = { %$old_attrs };
 415
 416   # take care of call attrs (only if anything is changing)
 417   if ($call_attrs and keys %$call_attrs) {
 418
 419     # copy for _normalize_selection
 420     $call_attrs = { %$call_attrs };
 421
 422     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 423
 424     # reset the current selector list if new selectors are supplied
 425     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 426       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 427     }
 428
 429     # Normalize the new selector list (operates on the passed-in attr structure)
 430     # Need to do it on every chain instead of only once on _resolved_attrs, in
 431     # order to allow detection of empty vs partial 'as'
 432     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 433       if $old_attrs->{_dark_selector};
 434     $self->_normalize_selection ($call_attrs);
 435
 436     # start with blind overwriting merge, exclude selector attrs
 437     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 438     delete @{$new_attrs}{@selector_attrs};
 439
 440     for (@selector_attrs) {
 441       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 442         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 443     }
 444
 445     # older deprecated name, use only if {columns} is not there
 446     if (my $c = delete $new_attrs->{cols}) {
 447       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 448       if ($new_attrs->{columns}) {
 449         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 450       }
 451       else {
 452         $new_attrs->{columns} = $c;
 453       }
 454     }
 455
 456
 457     # join/prefetch use their own crazy merging heuristics
 458     foreach my $key (qw/join prefetch/) {
 459       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 460         if exists $call_attrs->{$key};
 461     }
 462
 463     # stack binds together
 464     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 465   }
 466
 467
 468   for ($old_where, $call_cond) {
 469     if (defined $_) {
 470       $new_attrs->{where} = $self->_stack_cond (
 471         $_, $new_attrs->{where}
 472       );
 473     }
 474   }
 475
 476   if (defined $old_having) {
 477     $new_attrs->{having} = $self->_stack_cond (
 478       $old_having, $new_attrs->{having}
 479     )
 480   }
 481
 482   my $rs = (ref $self)->new($rsrc, $new_attrs);
 483
 484   $rs->set_cache($cache) if ($cache);
 485
 486   return $rs;
 487 }
 488
 489 my $dark_sel_dumper;
 490 sub _normalize_selection {
 491   my ($self, $attrs) = @_;
 492
 493   # legacy syntax
 494   if ( exists $attrs->{include_columns} ) {
 495     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 496     $attrs->{'+columns'} = $self->_merge_attr(
 497       $attrs->{'+columns'}, delete $attrs->{include_columns}
 498     );
 499   }
 500
 501   # columns are always placed first, however
 502
 503   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 504   # delay the decision on whether to use a default select list ($rsrc->columns)
 505   # allowing stuff like the remove_columns helper to work
 506   #
 507   # select/as +select/+as pairs need special handling - the amount of select/as
 508   # elements in each pair does *not* have to be equal (think multicolumn
 509   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 510   # supplied at all) - try to infer the alias, either from the -as parameter
 511   # of the selector spec, or use the parameter whole if it looks like a column
 512   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 513   # is ok as well), but make sure no more additions to the 'as' chain take place
 514   for my $pref ('', '+') {
 515
 516     my ($sel, $as) = map {
 517       my $key = "${pref}${_}";
 518
 519       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 520         ? @{$attrs->{$key}}
 521         : $attrs->{$key} || ()
 522       ];
 523       delete $attrs->{$key};
 524       $val;
 525     } qw/select as/;
 526
 527     if (! @$as and ! @$sel ) {
 528       next;
 529     }
 530     elsif (@$as and ! @$sel) {
 531       $self->throw_exception(
 532         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 533       );
 534     }
 535     elsif( ! @$as ) {
 536       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 537       # if any @$as has been supplied we assume the user knows what (s)he is doing
 538       # and blindly keep stacking up pieces
 539       unless ($attrs->{_dark_selector}) {
 540         SELECTOR:
 541         for (@$sel) {
 542           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 543             push @$as, $_->{-as};
 544           }
 545           # assume any plain no-space, no-parenthesis string to be a column spec
 546           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 547           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 548             push @$as, $_;
 549           }
 550           # if all else fails - raise a flag that no more aliasing will be allowed
 551           else {
 552             $attrs->{_dark_selector} = {
 553               plus_stage => $pref,
 554               string => ($dark_sel_dumper ||= do {
 555                   require Data::Dumper::Concise;
 556                   Data::Dumper::Concise::DumperObject()->Indent(0);
 557                 })->Values([$_])->Dump
 558               ,
 559             };
 560             last SELECTOR;
 561           }
 562         }
 563       }
 564     }
 565     elsif (@$as < @$sel) {
 566       $self->throw_exception(
 567         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 568       );
 569     }
 570     elsif ($pref and $attrs->{_dark_selector}) {
 571       $self->throw_exception(
 572         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 573       );
 574     }
 575
 576
 577     # merge result
 578     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 579     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 580   }
 581 }
 582
 583 sub _stack_cond {
 584   my ($self, $left, $right) = @_;
 585
 586   # collapse single element top-level conditions
 587   # (single pass only, unlikely to need recursion)
 588   for ($left, $right) {
 589     if (ref $_ eq 'ARRAY') {
 590       if (@$_ == 0) {
 591         $_ = undef;
 592       }
 593       elsif (@$_ == 1) {
 594         $_ = $_->[0];
 595       }
 596     }
 597     elsif (ref $_ eq 'HASH') {
 598       my ($first, $more) = keys %$_;
 599
 600       # empty hash
 601       if (! defined $first) {
 602         $_ = undef;
 603       }
 604       # one element hash
 605       elsif (! defined $more) {
 606         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 607           $_ = $_->{'-and'};
 608         }
 609         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 610           $_ = $_->{'-or'};
 611         }
 612       }
 613     }
 614   }
 615
 616   # merge hashes with weeding out of duplicates (simple cases only)
 617   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 618
 619     # shallow copy to destroy
 620     $right = { %$right };
 621     for (grep { exists $right->{$_} } keys %$left) {
 622       # the use of eq_deeply here is justified - the rhs of an
 623       # expression can contain a lot of twisted weird stuff
 624       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 625     }
 626
 627     $right = undef unless keys %$right;
 628   }
 629
 630
 631   if (defined $left xor defined $right) {
 632     return defined $left ? $left : $right;
 633   }
 634   elsif (! defined $left) {
 635     return undef;
 636   }
 637   else {
 638     return { -and => [ $left, $right ] };
 639   }
 640 }
 641
 642 =head2 search_literal
 643
 644 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 645 should only be used in that context. C<search_literal> is a convenience
 646 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 647 want to ensure columns are bound correctly, use L</search>.
 648
 649 See L<DBIx::Class::Manual::Cookbook/Searching> and
 650 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 651 require C<search_literal>.
 652
 653 =over 4
 654
 655 =item Arguments: $sql_fragment, @standalone_bind_values
 656
 657 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 658
 659 =back
 660
 661   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 662   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 663
 664 Pass a literal chunk of SQL to be added to the conditional part of the
 665 resultset query.
 666
 667 Example of how to use C<search> instead of C<search_literal>
 668
 669   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 670   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 671
 672 =cut
 673
 674 sub search_literal {
 675   my ($self, $sql, @bind) = @_;
 676   my $attr;
 677   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 678     $attr = pop @bind;
 679   }
 680   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 681 }
 682
 683 =head2 find
 684
 685 =over 4
 686
 687 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 688
 689 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 690
 691 =back
 692
 693 Finds and returns a single row based on supplied criteria. Takes either a
 694 hashref with the same format as L</create> (including inference of foreign
 695 keys from related objects), or a list of primary key values in the same
 696 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 697 declaration on the L</result_source>.
 698
 699 In either case an attempt is made to combine conditions already existing on
 700 the resultset with the condition passed to this method.
 701
 702 To aid with preparing the correct query for the storage you may supply the
 703 C<key> attribute, which is the name of a
 704 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 705 unique constraint corresponding to the
 706 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 707 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 708 to construct a query that satisfies the named unique constraint fully (
 709 non-NULL values for each column member of the constraint) an exception is
 710 thrown.
 711
 712 If no C<key> is specified, the search is carried over all unique constraints
 713 which are fully defined by the available condition.
 714
 715 If no such constraint is found, C<find> currently defaults to a simple
 716 C<< search->(\%column_values) >> which may or may not do what you expect.
 717 Note that this fallback behavior may be deprecated in further versions. If
 718 you need to search with arbitrary conditions - use L</search>. If the query
 719 resulting from this fallback produces more than one row, a warning to the
 720 effect is issued, though only the first row is constructed and returned as
 721 C<$result_object>.
 722
 723 In addition to C<key>, L</find> recognizes and applies standard
 724 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 725
 726 Note that if you have extra concerns about the correctness of the resulting
 727 query you need to specify the C<key> attribute and supply the entire condition
 728 as an argument to find (since it is not always possible to perform the
 729 combination of the resultset condition with the supplied one, especially if
 730 the resultset condition contains literal sql).
 731
 732 For example, to find a row by its primary key:
 733
 734   my $cd = $schema->resultset('CD')->find(5);
 735
 736 You can also find a row by a specific unique constraint:
 737
 738   my $cd = $schema->resultset('CD')->find(
 739     {
 740       artist => 'Massive Attack',
 741       title  => 'Mezzanine',
 742     },
 743     { key => 'cd_artist_title' }
 744   );
 745
 746 See also L</find_or_create> and L</update_or_create>.
 747
 748 =cut
 749
 750 sub find {
 751   my $self = shift;
 752   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 753
 754   my $rsrc = $self->result_source;
 755
 756   my $constraint_name;
 757   if (exists $attrs->{key}) {
 758     $constraint_name = defined $attrs->{key}
 759       ? $attrs->{key}
 760       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 761     ;
 762   }
 763
 764   # Parse out the condition from input
 765   my $call_cond;
 766
 767   if (ref $_[0] eq 'HASH') {
 768     $call_cond = { %{$_[0]} };
 769   }
 770   else {
 771     # if only values are supplied we need to default to 'primary'
 772     $constraint_name = 'primary' unless defined $constraint_name;
 773
 774     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 775
 776     $self->throw_exception(
 777       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 778     ) unless @c_cols;
 779
 780     $self->throw_exception (
 781       'find() expects either a column/value hashref, or a list of values '
 782     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 783     ) unless @c_cols == @_;
 784
 785     $call_cond = {};
 786     @{$call_cond}{@c_cols} = @_;
 787   }
 788
 789   my %related;
 790   for my $key (keys %$call_cond) {
 791     if (
 792       my $keyref = ref($call_cond->{$key})
 793         and
 794       my $relinfo = $rsrc->relationship_info($key)
 795     ) {
 796       my $val = delete $call_cond->{$key};
 797
 798       next if $keyref eq 'ARRAY'; # has_many for multi_create
 799
 800       my $rel_q = $rsrc->_resolve_condition(
 801         $relinfo->{cond}, $val, $key, $key
 802       );
 803       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 804       @related{keys %$rel_q} = values %$rel_q;
 805     }
 806   }
 807
 808   # relationship conditions take precedence (?)
 809   @{$call_cond}{keys %related} = values %related;
 810
 811   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 812   my $final_cond;
 813   if (defined $constraint_name) {
 814     $final_cond = $self->_qualify_cond_columns (
 815
 816       $self->_build_unique_cond (
 817         $constraint_name,
 818         $call_cond,
 819       ),
 820
 821       $alias,
 822     );
 823   }
 824   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 825     # This means that we got here after a merger of relationship conditions
 826     # in ::Relationship::Base::search_related (the row method), and furthermore
 827     # the relationship is of the 'single' type. This means that the condition
 828     # provided by the relationship (already attached to $self) is sufficient,
 829     # as there can be only one row in the database that would satisfy the
 830     # relationship
 831   }
 832   else {
 833     # no key was specified - fall down to heuristics mode:
 834     # run through all unique queries registered on the resultset, and
 835     # 'OR' all qualifying queries together
 836     my (@unique_queries, %seen_column_combinations);
 837     for my $c_name ($rsrc->unique_constraint_names) {
 838       next if $seen_column_combinations{
 839         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 840       }++;
 841
 842       push @unique_queries, try {
 843         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 844       } || ();
 845     }
 846
 847     $final_cond = @unique_queries
 848       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 849       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 850     ;
 851   }
 852
 853   # Run the query, passing the result_class since it should propagate for find
 854   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 855   if ($rs->_resolved_attrs->{collapse}) {
 856     my $row = $rs->next;
 857     carp "Query returned more than one row" if $rs->next;
 858     return $row;
 859   }
 860   else {
 861     return $rs->single;
 862   }
 863 }
 864
 865 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 866 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 867 #
 868 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 869 # condition. It is provided for overrides until a saner way forward is devised
 870 #
 871 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 872 # the road. Please adjust your tests accordingly to catch this situation early
 873 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 874 #
 875 # The method will not be removed without an adequately complete replacement
 876 # for strict-mode enforcement
 877 sub _non_unique_find_fallback {
 878   my ($self, $cond, $attrs) = @_;
 879
 880   return $self->_qualify_cond_columns(
 881     $cond,
 882     exists $attrs->{alias}
 883       ? $attrs->{alias}
 884       : $self->{attrs}{alias}
 885   );
 886 }
 887
 888
 889 sub _qualify_cond_columns {
 890   my ($self, $cond, $alias) = @_;
 891
 892   my %aliased = %$cond;
 893   for (keys %aliased) {
 894     $aliased{"$alias.$_"} = delete $aliased{$_}
 895       if $_ !~ /\./;
 896   }
 897
 898   return \%aliased;
 899 }
 900
 901 sub _build_unique_cond {
 902   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 903
 904   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 905
 906   # combination may fail if $self->{cond} is non-trivial
 907   my ($final_cond) = try {
 908     $self->_merge_with_rscond ($extra_cond)
 909   } catch {
 910     +{ %$extra_cond }
 911   };
 912
 913   # trim out everything not in $columns
 914   $final_cond = { map {
 915     exists $final_cond->{$_}
 916       ? ( $_ => $final_cond->{$_} )
 917       : ()
 918   } @c_cols };
 919
 920   if (my @missing = grep
 921     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 922     (@c_cols)
 923   ) {
 924     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 925       $constraint_name,
 926       join (', ', map { "'$_'" } @missing),
 927     ) );
 928   }
 929
 930   if (
 931     !$croak_on_null
 932       and
 933     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 934       and
 935     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 936   ) {
 937     carp_unique ( sprintf (
 938       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 939     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 940     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 941       $constraint_name,
 942       join (', ', map { "'$_'" } @undefs),
 943     ));
 944   }
 945
 946   return $final_cond;
 947 }
 948
 949 =head2 search_related
 950
 951 =over 4
 952
 953 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 954
 955 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 956
 957 =back
 958
 959   $new_rs = $cd_rs->search_related('artist', {
 960     name => 'Emo-R-Us',
 961   });
 962
 963 Searches the specified relationship, optionally specifying a condition and
 964 attributes for matching records. See L</ATTRIBUTES> for more information.
 965
 966 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 967 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 968
 969 See also L</search_related_rs>.
 970
 971 =cut
 972
 973 sub search_related {
 974   return shift->related_resultset(shift)->search(@_);
 975 }
 976
 977 =head2 search_related_rs
 978
 979 This method works exactly the same as search_related, except that
 980 it guarantees a resultset, even in list context.
 981
 982 =cut
 983
 984 sub search_related_rs {
 985   return shift->related_resultset(shift)->search_rs(@_);
 986 }
 987
 988 =head2 cursor
 989
 990 =over 4
 991
 992 =item Arguments: none
 993
 994 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 995
 996 =back
 997
 998 Returns a storage-driven cursor to the given resultset. See
 999 L<DBIx::Class::Cursor> for more information.
1000
1001 =cut
1002
1003 sub cursor {
1004   my $self = shift;
1005
1006   return $self->{cursor} ||= do {
1007     my $attrs = $self->_resolved_attrs;
1008     $self->result_source->storage->select(
1009       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1010     );
1011   };
1012 }
1013
1014 =head2 single
1015
1016 =over 4
1017
1018 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1019
1020 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1021
1022 =back
1023
1024   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1025
1026 Inflates the first result without creating a cursor if the resultset has
1027 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1028 of L</search>.
1029
1030 While this method can take an optional search condition (just like L</search>)
1031 being a fast-code-path it does not recognize search attributes. If you need to
1032 add extra joins or similar, call L</search> and then chain-call L</single> on the
1033 L<DBIx::Class::ResultSet> returned.
1034
1035 =over
1036
1037 =item B<Note>
1038
1039 As of 0.08100, this method enforces the assumption that the preceding
1040 query returns only one row. If more than one row is returned, you will receive
1041 a warning:
1042
1043   Query returned more than one row
1044
1045 In this case, you should be using L</next> or L</find> instead, or if you really
1046 know what you are doing, use the L</rows> attribute to explicitly limit the size
1047 of the resultset.
1048
1049 This method will also throw an exception if it is called on a resultset prefetching
1050 has_many, as such a prefetch implies fetching multiple rows from the database in
1051 order to assemble the resulting object.
1052
1053 =back
1054
1055 =cut
1056
1057 sub single {
1058   my ($self, $where) = @_;
1059   if(@_ > 2) {
1060       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1061   }
1062
1063   my $attrs = { %{$self->_resolved_attrs} };
1064
1065   $self->throw_exception(
1066     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1067   ) if $attrs->{collapse};
1068
1069   if ($where) {
1070     if (defined $attrs->{where}) {
1071       $attrs->{where} = {
1072         '-and' =>
1073             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1074                $where, delete $attrs->{where} ]
1075       };
1076     } else {
1077       $attrs->{where} = $where;
1078     }
1079   }
1080
1081   my $data = [ $self->result_source->storage->select_single(
1082     $attrs->{from}, $attrs->{select},
1083     $attrs->{where}, $attrs
1084   )];
1085   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
1086   return undef unless @$data;
1087   $self->{_stashed_rows} = [ $data ];
1088   $self->_construct_results->[0];
1089 }
1090
1091
1092 # _collapse_query
1093 #
1094 # Recursively collapse the query, accumulating values for each column.
1095
1096 sub _collapse_query {
1097   my ($self, $query, $collapsed) = @_;
1098
1099   $collapsed ||= {};
1100
1101   if (ref $query eq 'ARRAY') {
1102     foreach my $subquery (@$query) {
1103       next unless ref $subquery;  # -or
1104       $collapsed = $self->_collapse_query($subquery, $collapsed);
1105     }
1106   }
1107   elsif (ref $query eq 'HASH') {
1108     if (keys %$query and (keys %$query)[0] eq '-and') {
1109       foreach my $subquery (@{$query->{-and}}) {
1110         $collapsed = $self->_collapse_query($subquery, $collapsed);
1111       }
1112     }
1113     else {
1114       foreach my $col (keys %$query) {
1115         my $value = $query->{$col};
1116         $collapsed->{$col}{$value}++;
1117       }
1118     }
1119   }
1120
1121   return $collapsed;
1122 }
1123
1124 =head2 get_column
1125
1126 =over 4
1127
1128 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1129
1130 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1131
1132 =back
1133
1134   my $max_length = $rs->get_column('length')->max;
1135
1136 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1137
1138 =cut
1139
1140 sub get_column {
1141   my ($self, $column) = @_;
1142   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1143   return $new;
1144 }
1145
1146 =head2 search_like
1147
1148 =over 4
1149
1150 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1151
1152 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1153
1154 =back
1155
1156   # WHERE title LIKE '%blue%'
1157   $cd_rs = $rs->search_like({ title => '%blue%'});
1158
1159 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1160 that this is simply a convenience method retained for ex Class::DBI users.
1161 You most likely want to use L</search> with specific operators.
1162
1163 For more information, see L<DBIx::Class::Manual::Cookbook>.
1164
1165 This method is deprecated and will be removed in 0.09. Use L</search()>
1166 instead. An example conversion is:
1167
1168   ->search_like({ foo => 'bar' });
1169
1170   # Becomes
1171
1172   ->search({ foo => { like => 'bar' } });
1173
1174 =cut
1175
1176 sub search_like {
1177   my $class = shift;
1178   carp_unique (
1179     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1180    .' Instead use ->search({ x => { -like => "y%" } })'
1181    .' (note the outer pair of {}s - they are important!)'
1182   );
1183   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1184   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1185   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1186   return $class->search($query, { %$attrs });
1187 }
1188
1189 =head2 slice
1190
1191 =over 4
1192
1193 =item Arguments: $first, $last
1194
1195 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1196
1197 =back
1198
1199 Returns a resultset or object list representing a subset of elements from the
1200 resultset slice is called on. Indexes are from 0, i.e., to get the first
1201 three records, call:
1202
1203   my ($one, $two, $three) = $rs->slice(0, 2);
1204
1205 =cut
1206
1207 sub slice {
1208   my ($self, $min, $max) = @_;
1209   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1210   $attrs->{offset} = $self->{attrs}{offset} || 0;
1211   $attrs->{offset} += $min;
1212   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1213   return $self->search(undef, $attrs);
1214   #my $slice = (ref $self)->new($self->result_source, $attrs);
1215   #return (wantarray ? $slice->all : $slice);
1216 }
1217
1218 =head2 next
1219
1220 =over 4
1221
1222 =item Arguments: none
1223
1224 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1225
1226 =back
1227
1228 Returns the next element in the resultset (C<undef> is there is none).
1229
1230 Can be used to efficiently iterate over records in the resultset:
1231
1232   my $rs = $schema->resultset('CD')->search;
1233   while (my $cd = $rs->next) {
1234     print $cd->title;
1235   }
1236
1237 Note that you need to store the resultset object, and call C<next> on it.
1238 Calling C<< resultset('Table')->next >> repeatedly will always return the
1239 first record from the resultset.
1240
1241 =cut
1242
1243 sub next {
1244   my ($self) = @_;
1245
1246   if (my $cache = $self->get_cache) {
1247     $self->{all_cache_position} ||= 0;
1248     return $cache->[$self->{all_cache_position}++];
1249   }
1250
1251   if ($self->{attrs}{cache}) {
1252     delete $self->{pager};
1253     $self->{all_cache_position} = 1;
1254     return ($self->all)[0];
1255   }
1256
1257   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1258
1259   $self->{_stashed_results} = $self->_construct_results
1260     or return undef;
1261
1262   return shift @{$self->{_stashed_results}};
1263 }
1264
1265 # Constructs as many results as it can in one pass while respecting
1266 # cursor laziness. Several modes of operation:
1267 #
1268 # * Always builds everything present in @{$self->{_stashed_rows}}
1269 # * If called with $fetch_all true - pulls everything off the cursor and
1270 #   builds all result structures (or objects) in one pass
1271 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1272 #   and if the resultset is ordered properly by the left side:
1273 #   * Fetches stuff off the cursor until the "master object" changes,
1274 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1275 #   OR
1276 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1277 #     was requested (there is no other way to collapse except for an
1278 #     eager cursor)
1279 # * If no collapse is requested - just get the next row, construct and
1280 #   return
1281 sub _construct_results {
1282   my ($self, $fetch_all) = @_;
1283
1284   my $rsrc = $self->result_source;
1285   my $attrs = $self->_resolved_attrs;
1286
1287   if (
1288     ! $fetch_all
1289       and
1290     ! $attrs->{order_by}
1291       and
1292     $attrs->{collapse}
1293       and
1294     my @pcols = $rsrc->primary_columns
1295   ) {
1296     # default order for collapsing unless the user asked for something
1297     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1298     $attrs->{_ordered_for_collapse} = 1;
1299     $attrs->{_order_is_artificial} = 1;
1300   }
1301
1302   my $cursor = $self->cursor;
1303
1304   # this will be used as both initial raw-row collector AND as a RV of
1305   # _construct_results. Not regrowing the array twice matters a lot...
1306   # a surprising amount actually
1307   my $rows = delete $self->{_stashed_rows};
1308
1309   my $did_fetch_all = $fetch_all;
1310
1311   if ($fetch_all) {
1312     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1313     $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1314   }
1315   elsif( $attrs->{collapse} ) {
1316
1317     $attrs->{_ordered_for_collapse} = (
1318       (
1319         $attrs->{order_by}
1320           and
1321         $rsrc->schema
1322               ->storage
1323                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1324       ) ? 1 : 0
1325     ) unless defined $attrs->{_ordered_for_collapse};
1326
1327     if (! $attrs->{_ordered_for_collapse}) {
1328       $did_fetch_all = 1;
1329
1330       # instead of looping over ->next, use ->all in stealth mode
1331       # *without* calling a ->reset afterwards
1332       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1333       if (! $cursor->{_done}) {
1334         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1335         $cursor->{_done} = 1;
1336       }
1337     }
1338   }
1339
1340   if (! $did_fetch_all and ! @{$rows||[]} ) {
1341     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1342     if (scalar (my @r = $cursor->next) ) {
1343       $rows = [ \@r ];
1344     }
1345   }
1346
1347   return undef unless @{$rows||[]};
1348
1349   my @extra_collapser_args;
1350   if ($attrs->{collapse} and ! $did_fetch_all ) {
1351
1352     @extra_collapser_args = (
1353       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1354       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1355       ($self->{_stashed_rows} = []),                # where does it stuff excess
1356     );
1357   }
1358
1359   # hotspot - skip the setter
1360   my $res_class = $self->_result_class;
1361
1362   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1363     $res_class->can ('inflate_result')
1364       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1365   };
1366
1367   my $infmap = $attrs->{as};
1368
1369   $self->{_result_inflator}{is_core_row} = ( (
1370     $inflator_cref
1371       ==
1372     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1373   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1374
1375   $self->{_result_inflator}{is_hri} = ( (
1376     ! $self->{_result_inflator}{is_core_row}
1377       and
1378     $inflator_cref == (
1379       require DBIx::Class::ResultClass::HashRefInflator
1380         &&
1381       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1382     )
1383   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1384
1385
1386   if (! $attrs->{_related_results_construction}) {
1387     # construct a much simpler array->hash folder for the one-table cases right here
1388     if ($self->{_result_inflator}{is_hri}) {
1389       for my $r (@$rows) {
1390         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1391       }
1392     }
1393     # FIXME SUBOPTIMAL this is a very very very hot spot
1394     # while rather optimal we can *still* do much better, by
1395     # building a smarter Row::inflate_result(), and
1396     # switch to feeding it data via a much leaner interface
1397     #
1398     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1399     # this particular resultset size
1400     elsif (@$rows < 60) {
1401       for my $r (@$rows) {
1402         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1403       }
1404     }
1405     else {
1406       eval sprintf (
1407         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1408         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1409       );
1410     }
1411   }
1412   # Special-case multi-object HRI (we always prune, and there is no $inflator_cref pass)
1413   elsif ($self->{_result_inflator}{is_hri}) {
1414
1415     # $args and $attrs to _mk_row_parser are seperated to delineate what is
1416     # core collapser stuff and what is dbic $rs specific
1417     ( $self->{_row_parser}{hri} ||= $rsrc->_mk_row_parser({
1418       eval => 1,
1419       inflate_map => $infmap,
1420       collapse => $attrs->{collapse},
1421       premultiplied => $attrs->{_main_source_premultiplied},
1422       hri_style => 1,
1423       prune_null_branches => 1,
1424     }, $attrs) )->($rows, @extra_collapser_args);
1425   }
1426   # Regular multi-object
1427   else {
1428     my $parser_type = $self->{_result_inflator}{is_core_row} ? 'classic_pruning' : 'classic_nonpruning';
1429
1430     # $args and $attrs to _mk_row_parser are seperated to delineate what is
1431     # core collapser stuff and what is dbic $rs specific
1432     ( $self->{_row_parser}{$parser_type} ||= $rsrc->_mk_row_parser({
1433       eval => 1,
1434       inflate_map => $infmap,
1435       collapse => $attrs->{collapse},
1436       premultiplied => $attrs->{_main_source_premultiplied},
1437       prune_null_branches => $self->{_result_inflator}{is_core_row},
1438     }, $attrs) )->($rows, @extra_collapser_args);
1439
1440     $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows;
1441   }
1442
1443   # The @$rows check seems odd at first - why wouldn't we want to warn
1444   # regardless? The issue is things like find() etc, where the user
1445   # *knows* only one result will come back. In these cases the ->all
1446   # is not a pessimization, but rather something we actually want
1447   carp_unique(
1448     'Unable to properly collapse has_many results in iterator mode due '
1449   . 'to order criteria - performed an eager cursor slurp underneath. '
1450   . 'Consider using ->all() instead'
1451   ) if ( ! $fetch_all and @$rows > 1 );
1452
1453   return $rows;
1454 }
1455
1456 =head2 result_source
1457
1458 =over 4
1459
1460 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1461
1462 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1463
1464 =back
1465
1466 An accessor for the primary ResultSource object from which this ResultSet
1467 is derived.
1468
1469 =head2 result_class
1470
1471 =over 4
1472
1473 =item Arguments: $result_class?
1474
1475 =item Return Value: $result_class
1476
1477 =back
1478
1479 An accessor for the class to use when creating result objects. Defaults to
1480 C<< result_source->result_class >> - which in most cases is the name of the
1481 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1482
1483 Note that changing the result_class will also remove any components
1484 that were originally loaded in the source class via
1485 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1486 in the original source class will not run.
1487
1488 =cut
1489
1490 sub result_class {
1491   my ($self, $result_class) = @_;
1492   if ($result_class) {
1493
1494     # don't fire this for an object
1495     $self->ensure_class_loaded($result_class)
1496       unless ref($result_class);
1497
1498     if ($self->get_cache) {
1499       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1500     }
1501     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1502     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1503       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1504     }
1505
1506     $self->_result_class($result_class);
1507
1508     delete $self->{_result_inflator};
1509   }
1510   $self->_result_class;
1511 }
1512
1513 =head2 count
1514
1515 =over 4
1516
1517 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1518
1519 =item Return Value: $count
1520
1521 =back
1522
1523 Performs an SQL C<COUNT> with the same query as the resultset was built
1524 with to find the number of elements. Passing arguments is equivalent to
1525 C<< $rs->search ($cond, \%attrs)->count >>
1526
1527 =cut
1528
1529 sub count {
1530   my $self = shift;
1531   return $self->search(@_)->count if @_ and defined $_[0];
1532   return scalar @{ $self->get_cache } if $self->get_cache;
1533
1534   my $attrs = { %{ $self->_resolved_attrs } };
1535
1536   # this is a little optimization - it is faster to do the limit
1537   # adjustments in software, instead of a subquery
1538   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1539
1540   my $crs;
1541   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1542     $crs = $self->_count_subq_rs ($attrs);
1543   }
1544   else {
1545     $crs = $self->_count_rs ($attrs);
1546   }
1547   my $count = $crs->next;
1548
1549   $count -= $offset if $offset;
1550   $count = $rows if $rows and $rows < $count;
1551   $count = 0 if ($count < 0);
1552
1553   return $count;
1554 }
1555
1556 =head2 count_rs
1557
1558 =over 4
1559
1560 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1561
1562 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1563
1564 =back
1565
1566 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1567 This can be very handy for subqueries:
1568
1569   ->search( { amount => $some_rs->count_rs->as_query } )
1570
1571 As with regular resultsets the SQL query will be executed only after
1572 the resultset is accessed via L</next> or L</all>. That would return
1573 the same single value obtainable via L</count>.
1574
1575 =cut
1576
1577 sub count_rs {
1578   my $self = shift;
1579   return $self->search(@_)->count_rs if @_;
1580
1581   # this may look like a lack of abstraction (count() does about the same)
1582   # but in fact an _rs *must* use a subquery for the limits, as the
1583   # software based limiting can not be ported if this $rs is to be used
1584   # in a subquery itself (i.e. ->as_query)
1585   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1586     return $self->_count_subq_rs($self->{_attrs});
1587   }
1588   else {
1589     return $self->_count_rs($self->{_attrs});
1590   }
1591 }
1592
1593 #
1594 # returns a ResultSetColumn object tied to the count query
1595 #
1596 sub _count_rs {
1597   my ($self, $attrs) = @_;
1598
1599   my $rsrc = $self->result_source;
1600
1601   my $tmp_attrs = { %$attrs };
1602   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1603   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1604
1605   # overwrite the selector (supplied by the storage)
1606   $rsrc->resultset_class->new($rsrc, {
1607     %$tmp_attrs,
1608     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1609     as => 'count',
1610   })->get_column ('count');
1611 }
1612
1613 #
1614 # same as above but uses a subquery
1615 #
1616 sub _count_subq_rs {
1617   my ($self, $attrs) = @_;
1618
1619   my $rsrc = $self->result_source;
1620
1621   my $sub_attrs = { %$attrs };
1622   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1623   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1624
1625   # if we multi-prefetch we group_by something unique, as this is what we would
1626   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1627   if ( $attrs->{collapse}  ) {
1628     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1629       $rsrc->_identifying_column_set || $self->throw_exception(
1630         'Unable to construct a unique group_by criteria properly collapsing the '
1631       . 'has_many prefetch before count()'
1632       );
1633     } ]
1634   }
1635
1636   # Calculate subquery selector
1637   if (my $g = $sub_attrs->{group_by}) {
1638
1639     my $sql_maker = $rsrc->storage->sql_maker;
1640
1641     # necessary as the group_by may refer to aliased functions
1642     my $sel_index;
1643     for my $sel (@{$attrs->{select}}) {
1644       $sel_index->{$sel->{-as}} = $sel
1645         if (ref $sel eq 'HASH' and $sel->{-as});
1646     }
1647
1648     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1649     # also look for named aggregates referred in the having clause
1650     # having often contains scalarrefs - thus parse it out entirely
1651     my @parts = @$g;
1652     if ($attrs->{having}) {
1653       local $sql_maker->{having_bind};
1654       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1655       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1656       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1657         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1658         # if we don't unset it we screw up retarded but unfortunately working
1659         # 'MAX(foo.bar)' => { '>', 3 }
1660         $sql_maker->{name_sep} = '';
1661       }
1662
1663       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1664
1665       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1666       my %seen_having;
1667
1668       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1669       # and if all fails for an utterly naive quoted scalar-with-function
1670       while ($having_sql =~ /
1671         $rquote $sep $lquote (.+?) $rquote
1672           |
1673         [\s,] \w+ \. (\w+) [\s,]
1674           |
1675         [\s,] $lquote (.+?) $rquote [\s,]
1676       /gx) {
1677         my $part = $1 || $2 || $3;  # one of them matched if we got here
1678         unless ($seen_having{$part}++) {
1679           push @parts, $part;
1680         }
1681       }
1682     }
1683
1684     for (@parts) {
1685       my $colpiece = $sel_index->{$_} || $_;
1686
1687       # unqualify join-based group_by's. Arcane but possible query
1688       # also horrible horrible hack to alias a column (not a func.)
1689       # (probably need to introduce SQLA syntax)
1690       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1691         my $as = $colpiece;
1692         $as =~ s/\./__/;
1693         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1694       }
1695       push @{$sub_attrs->{select}}, $colpiece;
1696     }
1697   }
1698   else {
1699     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1700     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1701   }
1702
1703   return $rsrc->resultset_class
1704                ->new ($rsrc, $sub_attrs)
1705                 ->as_subselect_rs
1706                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1707                   ->get_column ('count');
1708 }
1709
1710
1711 =head2 count_literal
1712
1713 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1714 should only be used in that context. See L</search_literal> for further info.
1715
1716 =over 4
1717
1718 =item Arguments: $sql_fragment, @standalone_bind_values
1719
1720 =item Return Value: $count
1721
1722 =back
1723
1724 Counts the results in a literal query. Equivalent to calling L</search_literal>
1725 with the passed arguments, then L</count>.
1726
1727 =cut
1728
1729 sub count_literal { shift->search_literal(@_)->count; }
1730
1731 =head2 all
1732
1733 =over 4
1734
1735 =item Arguments: none
1736
1737 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1738
1739 =back
1740
1741 Returns all elements in the resultset.
1742
1743 =cut
1744
1745 sub all {
1746   my $self = shift;
1747   if(@_) {
1748     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1749   }
1750
1751   delete @{$self}{qw/_stashed_rows _stashed_results/};
1752
1753   if (my $c = $self->get_cache) {
1754     return @$c;
1755   }
1756
1757   $self->cursor->reset;
1758
1759   my $objs = $self->_construct_results('fetch_all') || [];
1760
1761   $self->set_cache($objs) if $self->{attrs}{cache};
1762
1763   return @$objs;
1764 }
1765
1766 =head2 reset
1767
1768 =over 4
1769
1770 =item Arguments: none
1771
1772 =item Return Value: $self
1773
1774 =back
1775
1776 Resets the resultset's cursor, so you can iterate through the elements again.
1777 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1778 another query.
1779
1780 =cut
1781
1782 sub reset {
1783   my ($self) = @_;
1784
1785   delete @{$self}{qw/_stashed_rows _stashed_results/};
1786   $self->{all_cache_position} = 0;
1787   $self->cursor->reset;
1788   return $self;
1789 }
1790
1791 =head2 first
1792
1793 =over 4
1794
1795 =item Arguments: none
1796
1797 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1798
1799 =back
1800
1801 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1802 an object for the first result (or C<undef> if the resultset is empty).
1803
1804 =cut
1805
1806 sub first {
1807   return $_[0]->reset->next;
1808 }
1809
1810
1811 # _rs_update_delete
1812 #
1813 # Determines whether and what type of subquery is required for the $rs operation.
1814 # If grouping is necessary either supplies its own, or verifies the current one
1815 # After all is done delegates to the proper storage method.
1816
1817 sub _rs_update_delete {
1818   my ($self, $op, $values) = @_;
1819
1820   my $rsrc = $self->result_source;
1821   my $storage = $rsrc->schema->storage;
1822
1823   my $attrs = { %{$self->_resolved_attrs} };
1824
1825   my $join_classifications;
1826   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1827
1828   # do we need a subquery for any reason?
1829   my $needs_subq = (
1830     defined $existing_group_by
1831       or
1832     # if {from} is unparseable wrap a subq
1833     ref($attrs->{from}) ne 'ARRAY'
1834       or
1835     # limits call for a subq
1836     $self->_has_resolved_attr(qw/rows offset/)
1837   );
1838
1839   # simplify the joinmap, so we can further decide if a subq is necessary
1840   if (!$needs_subq and @{$attrs->{from}} > 1) {
1841
1842     ($attrs->{from}, $join_classifications) =
1843       $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1844
1845     # any non-pruneable non-local restricting joins imply subq
1846     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1847   }
1848
1849   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1850   $needs_subq ||= (
1851     (ref $attrs->{from}[0]) ne 'HASH'
1852       or
1853     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1854   );
1855
1856   my ($cond, $guard);
1857   # do we need anything like a subquery?
1858   if (! $needs_subq) {
1859     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1860     # a condition containing 'me' or other table prefixes will not work
1861     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1862     $cond = do {
1863       my $sqla = $rsrc->storage->sql_maker;
1864       local $sqla->{_dequalify_idents} = 1;
1865       \[ $sqla->_recurse_where($self->{cond}) ];
1866     };
1867   }
1868   else {
1869     # we got this far - means it is time to wrap a subquery
1870     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1871       sprintf(
1872         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1873         $op,
1874         $rsrc->source_name,
1875       )
1876     );
1877
1878     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1879     delete $attrs->{$_} for qw/select as collapse/;
1880     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1881
1882     # this will be consumed by the pruner waaaaay down the stack
1883     $attrs->{_force_prune_multiplying_joins} = 1;
1884
1885     my $subrs = (ref $self)->new($rsrc, $attrs);
1886
1887     if (@$idcols == 1) {
1888       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1889     }
1890     elsif ($storage->_use_multicolumn_in) {
1891       # no syntax for calling this properly yet
1892       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1893       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1894         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1895         $subrs->as_query
1896       ),
1897     }
1898     else {
1899       # if all else fails - get all primary keys and operate over a ORed set
1900       # wrap in a transaction for consistency
1901       # this is where the group_by/multiplication starts to matter
1902       if (
1903         $existing_group_by
1904           or
1905         keys %{ $join_classifications->{multiplying} || {} }
1906       ) {
1907         # make sure if there is a supplied group_by it matches the columns compiled above
1908         # perfectly. Anything else can not be sanely executed on most databases so croak
1909         # right then and there
1910         if ($existing_group_by) {
1911           my @current_group_by = map
1912             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1913             @$existing_group_by
1914           ;
1915
1916           if (
1917             join ("\x00", sort @current_group_by)
1918               ne
1919             join ("\x00", sort @{$attrs->{columns}} )
1920           ) {
1921             $self->throw_exception (
1922               "You have just attempted a $op operation on a resultset which does group_by"
1923               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1924               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1925               . ' kind of queries. Please retry the operation with a modified group_by or'
1926               . ' without using one at all.'
1927             );
1928           }
1929         }
1930
1931         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1932       }
1933
1934       $guard = $storage->txn_scope_guard;
1935
1936       $cond = [];
1937       for my $row ($subrs->cursor->all) {
1938         push @$cond, { map
1939           { $idcols->[$_] => $row->[$_] }
1940           (0 .. $#$idcols)
1941         };
1942       }
1943     }
1944   }
1945
1946   my $res = $storage->$op (
1947     $rsrc,
1948     $op eq 'update' ? $values : (),
1949     $cond,
1950   );
1951
1952   $guard->commit if $guard;
1953
1954   return $res;
1955 }
1956
1957 =head2 update
1958
1959 =over 4
1960
1961 =item Arguments: \%values
1962
1963 =item Return Value: $underlying_storage_rv
1964
1965 =back
1966
1967 Sets the specified columns in the resultset to the supplied values in a
1968 single query. Note that this will not run any accessor/set_column/update
1969 triggers, nor will it update any result object instances derived from this
1970 resultset (this includes the contents of the L<resultset cache|/set_cache>
1971 if any). See L</update_all> if you need to execute any on-update
1972 triggers or cascades defined either by you or a
1973 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1974
1975 The return value is a pass through of what the underlying
1976 storage backend returned, and may vary. See L<DBI/execute> for the most
1977 common case.
1978
1979 =head3 CAVEAT
1980
1981 Note that L</update> does not process/deflate any of the values passed in.
1982 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1983 ensure manually that any value passed to this method will stringify to
1984 something the RDBMS knows how to deal with. A notable example is the
1985 handling of L<DateTime> objects, for more info see:
1986 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1987
1988 =cut
1989
1990 sub update {
1991   my ($self, $values) = @_;
1992   $self->throw_exception('Values for update must be a hash')
1993     unless ref $values eq 'HASH';
1994
1995   return $self->_rs_update_delete ('update', $values);
1996 }
1997
1998 =head2 update_all
1999
2000 =over 4
2001
2002 =item Arguments: \%values
2003
2004 =item Return Value: 1
2005
2006 =back
2007
2008 Fetches all objects and updates them one at a time via
2009 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2010 triggers, while L</update> will not.
2011
2012 =cut
2013
2014 sub update_all {
2015   my ($self, $values) = @_;
2016   $self->throw_exception('Values for update_all must be a hash')
2017     unless ref $values eq 'HASH';
2018
2019   my $guard = $self->result_source->schema->txn_scope_guard;
2020   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2021   $guard->commit;
2022   return 1;
2023 }
2024
2025 =head2 delete
2026
2027 =over 4
2028
2029 =item Arguments: none
2030
2031 =item Return Value: $underlying_storage_rv
2032
2033 =back
2034
2035 Deletes the rows matching this resultset in a single query. Note that this
2036 will not run any delete triggers, nor will it alter the
2037 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2038 derived from this resultset (this includes the contents of the
2039 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2040 execute any on-delete triggers or cascades defined either by you or a
2041 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2042
2043 The return value is a pass through of what the underlying storage backend
2044 returned, and may vary. See L<DBI/execute> for the most common case.
2045
2046 =cut
2047
2048 sub delete {
2049   my $self = shift;
2050   $self->throw_exception('delete does not accept any arguments')
2051     if @_;
2052
2053   return $self->_rs_update_delete ('delete');
2054 }
2055
2056 =head2 delete_all
2057
2058 =over 4
2059
2060 =item Arguments: none
2061
2062 =item Return Value: 1
2063
2064 =back
2065
2066 Fetches all objects and deletes them one at a time via
2067 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2068 triggers, while L</delete> will not.
2069
2070 =cut
2071
2072 sub delete_all {
2073   my $self = shift;
2074   $self->throw_exception('delete_all does not accept any arguments')
2075     if @_;
2076
2077   my $guard = $self->result_source->schema->txn_scope_guard;
2078   $_->delete for $self->all;
2079   $guard->commit;
2080   return 1;
2081 }
2082
2083 =head2 populate
2084
2085 =over 4
2086
2087 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2088
2089 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2090
2091 =back
2092
2093 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2094 arrayrefs.
2095
2096 =over
2097
2098 =item NOTE
2099
2100 The context of this method call has an important effect on what is
2101 submitted to storage. In void context data is fed directly to fastpath
2102 insertion routines provided by the underlying storage (most often
2103 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2104 L<insert|DBIx::Class::Row/insert> calls on the
2105 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2106 augmentation of these methods provided by components. For example if you
2107 are using something like L<DBIx::Class::UUIDColumns> to create primary
2108 keys for you, you will find that your PKs are empty.  In this case you
2109 will have to explicitly force scalar or list context in order to create
2110 those values.
2111
2112 =back
2113
2114 In non-void (scalar or list) context, this method is simply a wrapper
2115 for L</create>. Depending on list or scalar context either a list of
2116 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2117 containing these objects is returned.
2118
2119 When supplying data in "arrayref of arrayrefs" invocation style, the
2120 first element should be a list of column names and each subsequent
2121 element should be a data value in the earlier specified column order.
2122 For example:
2123
2124   $Arstist_rs->populate([
2125     [ qw( artistid name ) ],
2126     [ 100, 'A Formally Unknown Singer' ],
2127     [ 101, 'A singer that jumped the shark two albums ago' ],
2128     [ 102, 'An actually cool singer' ],
2129   ]);
2130
2131 For the arrayref of hashrefs style each hashref should be a structure
2132 suitable for passing to L</create>. Multi-create is also permitted with
2133 this syntax.
2134
2135   $schema->resultset("Artist")->populate([
2136      { artistid => 4, name => 'Manufactured Crap', cds => [
2137         { title => 'My First CD', year => 2006 },
2138         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2139       ],
2140      },
2141      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2142         { title => 'My parents sold me to a record company', year => 2005 },
2143         { title => 'Why Am I So Ugly?', year => 2006 },
2144         { title => 'I Got Surgery and am now Popular', year => 2007 }
2145       ],
2146      },
2147   ]);
2148
2149 If you attempt a void-context multi-create as in the example above (each
2150 Artist also has the related list of CDs), and B<do not> supply the
2151 necessary autoinc foreign key information, this method will proxy to the
2152 less efficient L</create>, and then throw the Result objects away. In this
2153 case there are obviously no benefits to using this method over L</create>.
2154
2155 =cut
2156
2157 sub populate {
2158   my $self = shift;
2159
2160   # cruft placed in standalone method
2161   my $data = $self->_normalize_populate_args(@_);
2162
2163   return unless @$data;
2164
2165   if(defined wantarray) {
2166     my @created = map { $self->create($_) } @$data;
2167     return wantarray ? @created : \@created;
2168   }
2169   else {
2170     my $first = $data->[0];
2171
2172     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2173     # it relationship data
2174     my (@rels, @columns);
2175     my $rsrc = $self->result_source;
2176     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2177     for (keys %$first) {
2178       my $ref = ref $first->{$_};
2179       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2180         ? push @rels, $_
2181         : push @columns, $_
2182       ;
2183     }
2184
2185     my @pks = $rsrc->primary_columns;
2186
2187     ## do the belongs_to relationships
2188     foreach my $index (0..$#$data) {
2189
2190       # delegate to create() for any dataset without primary keys with specified relationships
2191       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2192         for my $r (@rels) {
2193           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2194             my @ret = $self->populate($data);
2195             return;
2196           }
2197         }
2198       }
2199
2200       foreach my $rel (@rels) {
2201         next unless ref $data->[$index]->{$rel} eq "HASH";
2202         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2203         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2204         my $related = $result->result_source->_resolve_condition(
2205           $reverse_relinfo->{cond},
2206           $self,
2207           $result,
2208           $rel,
2209         );
2210
2211         delete $data->[$index]->{$rel};
2212         $data->[$index] = {%{$data->[$index]}, %$related};
2213
2214         push @columns, keys %$related if $index == 0;
2215       }
2216     }
2217
2218     ## inherit the data locked in the conditions of the resultset
2219     my ($rs_data) = $self->_merge_with_rscond({});
2220     delete @{$rs_data}{@columns};
2221
2222     ## do bulk insert on current row
2223     $rsrc->storage->insert_bulk(
2224       $rsrc,
2225       [@columns, keys %$rs_data],
2226       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2227     );
2228
2229     ## do the has_many relationships
2230     foreach my $item (@$data) {
2231
2232       my $main_row;
2233
2234       foreach my $rel (@rels) {
2235         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2236
2237         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2238
2239         my $child = $main_row->$rel;
2240
2241         my $related = $child->result_source->_resolve_condition(
2242           $rels->{$rel}{cond},
2243           $child,
2244           $main_row,
2245           $rel,
2246         );
2247
2248         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2249         my @populate = map { {%$_, %$related} } @rows_to_add;
2250
2251         $child->populate( \@populate );
2252       }
2253     }
2254   }
2255 }
2256
2257
2258 # populate() argumnets went over several incarnations
2259 # What we ultimately support is AoH
2260 sub _normalize_populate_args {
2261   my ($self, $arg) = @_;
2262
2263   if (ref $arg eq 'ARRAY') {
2264     if (!@$arg) {
2265       return [];
2266     }
2267     elsif (ref $arg->[0] eq 'HASH') {
2268       return $arg;
2269     }
2270     elsif (ref $arg->[0] eq 'ARRAY') {
2271       my @ret;
2272       my @colnames = @{$arg->[0]};
2273       foreach my $values (@{$arg}[1 .. $#$arg]) {
2274         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2275       }
2276       return \@ret;
2277     }
2278   }
2279
2280   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2281 }
2282
2283 =head2 pager
2284
2285 =over 4
2286
2287 =item Arguments: none
2288
2289 =item Return Value: L<$pager|Data::Page>
2290
2291 =back
2292
2293 Returns a L<Data::Page> object for the current resultset. Only makes
2294 sense for queries with a C<page> attribute.
2295
2296 To get the full count of entries for a paged resultset, call
2297 C<total_entries> on the L<Data::Page> object.
2298
2299 =cut
2300
2301 sub pager {
2302   my ($self) = @_;
2303
2304   return $self->{pager} if $self->{pager};
2305
2306   my $attrs = $self->{attrs};
2307   if (!defined $attrs->{page}) {
2308     $self->throw_exception("Can't create pager for non-paged rs");
2309   }
2310   elsif ($attrs->{page} <= 0) {
2311     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2312   }
2313   $attrs->{rows} ||= 10;
2314
2315   # throw away the paging flags and re-run the count (possibly
2316   # with a subselect) to get the real total count
2317   my $count_attrs = { %$attrs };
2318   delete @{$count_attrs}{qw/rows offset page pager/};
2319
2320   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2321
2322   require DBIx::Class::ResultSet::Pager;
2323   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2324     sub { $total_rs->count },  #lazy-get the total
2325     $attrs->{rows},
2326     $self->{attrs}{page},
2327   );
2328 }
2329
2330 =head2 page
2331
2332 =over 4
2333
2334 =item Arguments: $page_number
2335
2336 =item Return Value: L<$resultset|/search>
2337
2338 =back
2339
2340 Returns a resultset for the $page_number page of the resultset on which page
2341 is called, where each page contains a number of rows equal to the 'rows'
2342 attribute set on the resultset (10 by default).
2343
2344 =cut
2345
2346 sub page {
2347   my ($self, $page) = @_;
2348   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2349 }
2350
2351 =head2 new_result
2352
2353 =over 4
2354
2355 =item Arguments: \%col_data
2356
2357 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2358
2359 =back
2360
2361 Creates a new result object in the resultset's result class and returns
2362 it. The row is not inserted into the database at this point, call
2363 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2364 will tell you whether the result object has been inserted or not.
2365
2366 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2367
2368 =cut
2369
2370 sub new_result {
2371   my ($self, $values) = @_;
2372
2373   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2374     if @_ > 2;
2375
2376   $self->throw_exception( "new_result expects a hashref" )
2377     unless (ref $values eq 'HASH');
2378
2379   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2380
2381   my $new = $self->result_class->new({
2382     %$merged_cond,
2383     ( @$cols_from_relations
2384       ? (-cols_from_relations => $cols_from_relations)
2385       : ()
2386     ),
2387     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2388   });
2389
2390   if (
2391     reftype($new) eq 'HASH'
2392       and
2393     ! keys %$new
2394       and
2395     blessed($new)
2396   ) {
2397     carp_unique (sprintf (
2398       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2399       $self->result_class,
2400     ));
2401   }
2402
2403   $new;
2404 }
2405
2406 # _merge_with_rscond
2407 #
2408 # Takes a simple hash of K/V data and returns its copy merged with the
2409 # condition already present on the resultset. Additionally returns an
2410 # arrayref of value/condition names, which were inferred from related
2411 # objects (this is needed for in-memory related objects)
2412 sub _merge_with_rscond {
2413   my ($self, $data) = @_;
2414
2415   my (%new_data, @cols_from_relations);
2416
2417   my $alias = $self->{attrs}{alias};
2418
2419   if (! defined $self->{cond}) {
2420     # just massage $data below
2421   }
2422   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2423     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2424     @cols_from_relations = keys %new_data;
2425   }
2426   elsif (ref $self->{cond} ne 'HASH') {
2427     $self->throw_exception(
2428       "Can't abstract implicit construct, resultset condition not a hash"
2429     );
2430   }
2431   else {
2432     # precendence must be given to passed values over values inherited from
2433     # the cond, so the order here is important.
2434     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2435     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2436
2437     while ( my($col, $value) = each %implied ) {
2438       my $vref = ref $value;
2439       if (
2440         $vref eq 'HASH'
2441           and
2442         keys(%$value) == 1
2443           and
2444         (keys %$value)[0] eq '='
2445       ) {
2446         $new_data{$col} = $value->{'='};
2447       }
2448       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2449         $new_data{$col} = $value;
2450       }
2451     }
2452   }
2453
2454   %new_data = (
2455     %new_data,
2456     %{ $self->_remove_alias($data, $alias) },
2457   );
2458
2459   return (\%new_data, \@cols_from_relations);
2460 }
2461
2462 # _has_resolved_attr
2463 #
2464 # determines if the resultset defines at least one
2465 # of the attributes supplied
2466 #
2467 # used to determine if a subquery is neccessary
2468 #
2469 # supports some virtual attributes:
2470 #   -join
2471 #     This will scan for any joins being present on the resultset.
2472 #     It is not a mere key-search but a deep inspection of {from}
2473 #
2474
2475 sub _has_resolved_attr {
2476   my ($self, @attr_names) = @_;
2477
2478   my $attrs = $self->_resolved_attrs;
2479
2480   my %extra_checks;
2481
2482   for my $n (@attr_names) {
2483     if (grep { $n eq $_ } (qw/-join/) ) {
2484       $extra_checks{$n}++;
2485       next;
2486     }
2487
2488     my $attr =  $attrs->{$n};
2489
2490     next if not defined $attr;
2491
2492     if (ref $attr eq 'HASH') {
2493       return 1 if keys %$attr;
2494     }
2495     elsif (ref $attr eq 'ARRAY') {
2496       return 1 if @$attr;
2497     }
2498     else {
2499       return 1 if $attr;
2500     }
2501   }
2502
2503   # a resolved join is expressed as a multi-level from
2504   return 1 if (
2505     $extra_checks{-join}
2506       and
2507     ref $attrs->{from} eq 'ARRAY'
2508       and
2509     @{$attrs->{from}} > 1
2510   );
2511
2512   return 0;
2513 }
2514
2515 # _collapse_cond
2516 #
2517 # Recursively collapse the condition.
2518
2519 sub _collapse_cond {
2520   my ($self, $cond, $collapsed) = @_;
2521
2522   $collapsed ||= {};
2523
2524   if (ref $cond eq 'ARRAY') {
2525     foreach my $subcond (@$cond) {
2526       next unless ref $subcond;  # -or
2527       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2528     }
2529   }
2530   elsif (ref $cond eq 'HASH') {
2531     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2532       foreach my $subcond (@{$cond->{-and}}) {
2533         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2534       }
2535     }
2536     else {
2537       foreach my $col (keys %$cond) {
2538         my $value = $cond->{$col};
2539         $collapsed->{$col} = $value;
2540       }
2541     }
2542   }
2543
2544   return $collapsed;
2545 }
2546
2547 # _remove_alias
2548 #
2549 # Remove the specified alias from the specified query hash. A copy is made so
2550 # the original query is not modified.
2551
2552 sub _remove_alias {
2553   my ($self, $query, $alias) = @_;
2554
2555   my %orig = %{ $query || {} };
2556   my %unaliased;
2557
2558   foreach my $key (keys %orig) {
2559     if ($key !~ /\./) {
2560       $unaliased{$key} = $orig{$key};
2561       next;
2562     }
2563     $unaliased{$1} = $orig{$key}
2564       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2565   }
2566
2567   return \%unaliased;
2568 }
2569
2570 =head2 as_query
2571
2572 =over 4
2573
2574 =item Arguments: none
2575
2576 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2577
2578 =back
2579
2580 Returns the SQL query and bind vars associated with the invocant.
2581
2582 This is generally used as the RHS for a subquery.
2583
2584 =cut
2585
2586 sub as_query {
2587   my $self = shift;
2588
2589   my $attrs = { %{ $self->_resolved_attrs } };
2590
2591   my $aq = $self->result_source->storage->_select_args_to_query (
2592     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2593   );
2594
2595   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
2596
2597   $aq;
2598 }
2599
2600 =head2 find_or_new
2601
2602 =over 4
2603
2604 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2605
2606 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2607
2608 =back
2609
2610   my $artist = $schema->resultset('Artist')->find_or_new(
2611     { artist => 'fred' }, { key => 'artists' });
2612
2613   $cd->cd_to_producer->find_or_new({ producer => $producer },
2614                                    { key => 'primary });
2615
2616 Find an existing record from this resultset using L</find>. if none exists,
2617 instantiate a new result object and return it. The object will not be saved
2618 into your storage until you call L<DBIx::Class::Row/insert> on it.
2619
2620 You most likely want this method when looking for existing rows using a unique
2621 constraint that is not the primary key, or looking for related rows.
2622
2623 If you want objects to be saved immediately, use L</find_or_create> instead.
2624
2625 B<Note>: Make sure to read the documentation of L</find> and understand the
2626 significance of the C<key> attribute, as its lack may skew your search, and
2627 subsequently result in spurious new objects.
2628
2629 B<Note>: Take care when using C<find_or_new> with a table having
2630 columns with default values that you intend to be automatically
2631 supplied by the database (e.g. an auto_increment primary key column).
2632 In normal usage, the value of such columns should NOT be included at
2633 all in the call to C<find_or_new>, even when set to C<undef>.
2634
2635 =cut
2636
2637 sub find_or_new {
2638   my $self     = shift;
2639   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2640   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2641   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2642     return $row;
2643   }
2644   return $self->new_result($hash);
2645 }
2646
2647 =head2 create
2648
2649 =over 4
2650
2651 =item Arguments: \%col_data
2652
2653 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2654
2655 =back
2656
2657 Attempt to create a single new row or a row with multiple related rows
2658 in the table represented by the resultset (and related tables). This
2659 will not check for duplicate rows before inserting, use
2660 L</find_or_create> to do that.
2661
2662 To create one row for this resultset, pass a hashref of key/value
2663 pairs representing the columns of the table and the values you wish to
2664 store. If the appropriate relationships are set up, foreign key fields
2665 can also be passed an object representing the foreign row, and the
2666 value will be set to its primary key.
2667
2668 To create related objects, pass a hashref of related-object column values
2669 B<keyed on the relationship name>. If the relationship is of type C<multi>
2670 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2671 The process will correctly identify columns holding foreign keys, and will
2672 transparently populate them from the keys of the corresponding relation.
2673 This can be applied recursively, and will work correctly for a structure
2674 with an arbitrary depth and width, as long as the relationships actually
2675 exists and the correct column data has been supplied.
2676
2677 Instead of hashrefs of plain related data (key/value pairs), you may
2678 also pass new or inserted objects. New objects (not inserted yet, see
2679 L</new_result>), will be inserted into their appropriate tables.
2680
2681 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2682
2683 Example of creating a new row.
2684
2685   $person_rs->create({
2686     name=>"Some Person",
2687     email=>"somebody@someplace.com"
2688   });
2689
2690 Example of creating a new row and also creating rows in a related C<has_many>
2691 or C<has_one> resultset.  Note Arrayref.
2692
2693   $artist_rs->create(
2694      { artistid => 4, name => 'Manufactured Crap', cds => [
2695         { title => 'My First CD', year => 2006 },
2696         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2697       ],
2698      },
2699   );
2700
2701 Example of creating a new row and also creating a row in a related
2702 C<belongs_to> resultset. Note Hashref.
2703
2704   $cd_rs->create({
2705     title=>"Music for Silly Walks",
2706     year=>2000,
2707     artist => {
2708       name=>"Silly Musician",
2709     }
2710   });
2711
2712 =over
2713
2714 =item WARNING
2715
2716 When subclassing ResultSet never attempt to override this method. Since
2717 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2718 lot of the internals simply never call it, so your override will be
2719 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2720 or L<DBIx::Class::Row/insert> depending on how early in the
2721 L</create> process you need to intervene. See also warning pertaining to
2722 L</new>.
2723
2724 =back
2725
2726 =cut
2727
2728 sub create {
2729   my ($self, $col_data) = @_;
2730   $self->throw_exception( "create needs a hashref" )
2731     unless ref $col_data eq 'HASH';
2732   return $self->new_result($col_data)->insert;
2733 }
2734
2735 =head2 find_or_create
2736
2737 =over 4
2738
2739 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2740
2741 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2742
2743 =back
2744
2745   $cd->cd_to_producer->find_or_create({ producer => $producer },
2746                                       { key => 'primary' });
2747
2748 Tries to find a record based on its primary key or unique constraints; if none
2749 is found, creates one and returns that instead.
2750
2751   my $cd = $schema->resultset('CD')->find_or_create({
2752     cdid   => 5,
2753     artist => 'Massive Attack',
2754     title  => 'Mezzanine',
2755     year   => 2005,
2756   });
2757
2758 Also takes an optional C<key> attribute, to search by a specific key or unique
2759 constraint. For example:
2760
2761   my $cd = $schema->resultset('CD')->find_or_create(
2762     {
2763       artist => 'Massive Attack',
2764       title  => 'Mezzanine',
2765     },
2766     { key => 'cd_artist_title' }
2767   );
2768
2769 B<Note>: Make sure to read the documentation of L</find> and understand the
2770 significance of the C<key> attribute, as its lack may skew your search, and
2771 subsequently result in spurious row creation.
2772
2773 B<Note>: Because find_or_create() reads from the database and then
2774 possibly inserts based on the result, this method is subject to a race
2775 condition. Another process could create a record in the table after
2776 the find has completed and before the create has started. To avoid
2777 this problem, use find_or_create() inside a transaction.
2778
2779 B<Note>: Take care when using C<find_or_create> with a table having
2780 columns with default values that you intend to be automatically
2781 supplied by the database (e.g. an auto_increment primary key column).
2782 In normal usage, the value of such columns should NOT be included at
2783 all in the call to C<find_or_create>, even when set to C<undef>.
2784
2785 See also L</find> and L</update_or_create>. For information on how to declare
2786 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2787
2788 If you need to know if an existing row was found or a new one created use
2789 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2790 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2791 database!
2792
2793   my $cd = $schema->resultset('CD')->find_or_new({
2794     cdid   => 5,
2795     artist => 'Massive Attack',
2796     title  => 'Mezzanine',
2797     year   => 2005,
2798   });
2799
2800   if( !$cd->in_storage ) {
2801       # do some stuff
2802       $cd->insert;
2803   }
2804
2805 =cut
2806
2807 sub find_or_create {
2808   my $self     = shift;
2809   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2810   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2811   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2812     return $row;
2813   }
2814   return $self->create($hash);
2815 }
2816
2817 =head2 update_or_create
2818
2819 =over 4
2820
2821 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2822
2823 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2824
2825 =back
2826
2827   $resultset->update_or_create({ col => $val, ... });
2828
2829 Like L</find_or_create>, but if a row is found it is immediately updated via
2830 C<< $found_row->update (\%col_data) >>.
2831
2832
2833 Takes an optional C<key> attribute to search on a specific unique constraint.
2834 For example:
2835
2836   # In your application
2837   my $cd = $schema->resultset('CD')->update_or_create(
2838     {
2839       artist => 'Massive Attack',
2840       title  => 'Mezzanine',
2841       year   => 1998,
2842     },
2843     { key => 'cd_artist_title' }
2844   );
2845
2846   $cd->cd_to_producer->update_or_create({
2847     producer => $producer,
2848     name => 'harry',
2849   }, {
2850     key => 'primary',
2851   });
2852
2853 B<Note>: Make sure to read the documentation of L</find> and understand the
2854 significance of the C<key> attribute, as its lack may skew your search, and
2855 subsequently result in spurious row creation.
2856
2857 B<Note>: Take care when using C<update_or_create> with a table having
2858 columns with default values that you intend to be automatically
2859 supplied by the database (e.g. an auto_increment primary key column).
2860 In normal usage, the value of such columns should NOT be included at
2861 all in the call to C<update_or_create>, even when set to C<undef>.
2862
2863 See also L</find> and L</find_or_create>. For information on how to declare
2864 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2865
2866 If you need to know if an existing row was updated or a new one created use
2867 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2868 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2869 database!
2870
2871 =cut
2872
2873 sub update_or_create {
2874   my $self = shift;
2875   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2876   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2877
2878   my $row = $self->find($cond, $attrs);
2879   if (defined $row) {
2880     $row->update($cond);
2881     return $row;
2882   }
2883
2884   return $self->create($cond);
2885 }
2886
2887 =head2 update_or_new
2888
2889 =over 4
2890
2891 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2892
2893 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2894
2895 =back
2896
2897   $resultset->update_or_new({ col => $val, ... });
2898
2899 Like L</find_or_new> but if a row is found it is immediately updated via
2900 C<< $found_row->update (\%col_data) >>.
2901
2902 For example:
2903
2904   # In your application
2905   my $cd = $schema->resultset('CD')->update_or_new(
2906     {
2907       artist => 'Massive Attack',
2908       title  => 'Mezzanine',
2909       year   => 1998,
2910     },
2911     { key => 'cd_artist_title' }
2912   );
2913
2914   if ($cd->in_storage) {
2915       # the cd was updated
2916   }
2917   else {
2918       # the cd is not yet in the database, let's insert it
2919       $cd->insert;
2920   }
2921
2922 B<Note>: Make sure to read the documentation of L</find> and understand the
2923 significance of the C<key> attribute, as its lack may skew your search, and
2924 subsequently result in spurious new objects.
2925
2926 B<Note>: Take care when using C<update_or_new> with a table having
2927 columns with default values that you intend to be automatically
2928 supplied by the database (e.g. an auto_increment primary key column).
2929 In normal usage, the value of such columns should NOT be included at
2930 all in the call to C<update_or_new>, even when set to C<undef>.
2931
2932 See also L</find>, L</find_or_create> and L</find_or_new>.
2933
2934 =cut
2935
2936 sub update_or_new {
2937     my $self  = shift;
2938     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2939     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2940
2941     my $row = $self->find( $cond, $attrs );
2942     if ( defined $row ) {
2943         $row->update($cond);
2944         return $row;
2945     }
2946
2947     return $self->new_result($cond);
2948 }
2949
2950 =head2 get_cache
2951
2952 =over 4
2953
2954 =item Arguments: none
2955
2956 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2957
2958 =back
2959
2960 Gets the contents of the cache for the resultset, if the cache is set.
2961
2962 The cache is populated either by using the L</prefetch> attribute to
2963 L</search> or by calling L</set_cache>.
2964
2965 =cut
2966
2967 sub get_cache {
2968   shift->{all_cache};
2969 }
2970
2971 =head2 set_cache
2972
2973 =over 4
2974
2975 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2976
2977 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2978
2979 =back
2980
2981 Sets the contents of the cache for the resultset. Expects an arrayref
2982 of objects of the same class as those produced by the resultset. Note that
2983 if the cache is set, the resultset will return the cached objects rather
2984 than re-querying the database even if the cache attr is not set.
2985
2986 The contents of the cache can also be populated by using the
2987 L</prefetch> attribute to L</search>.
2988
2989 =cut
2990
2991 sub set_cache {
2992   my ( $self, $data ) = @_;
2993   $self->throw_exception("set_cache requires an arrayref")
2994       if defined($data) && (ref $data ne 'ARRAY');
2995   $self->{all_cache} = $data;
2996 }
2997
2998 =head2 clear_cache
2999
3000 =over 4
3001
3002 =item Arguments: none
3003
3004 =item Return Value: undef
3005
3006 =back
3007
3008 Clears the cache for the resultset.
3009
3010 =cut
3011
3012 sub clear_cache {
3013   shift->set_cache(undef);
3014 }
3015
3016 =head2 is_paged
3017
3018 =over 4
3019
3020 =item Arguments: none
3021
3022 =item Return Value: true, if the resultset has been paginated
3023
3024 =back
3025
3026 =cut
3027
3028 sub is_paged {
3029   my ($self) = @_;
3030   return !!$self->{attrs}{page};
3031 }
3032
3033 =head2 is_ordered
3034
3035 =over 4
3036
3037 =item Arguments: none
3038
3039 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3040
3041 =back
3042
3043 =cut
3044
3045 sub is_ordered {
3046   my ($self) = @_;
3047   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3048 }
3049
3050 =head2 related_resultset
3051
3052 =over 4
3053
3054 =item Arguments: $rel_name
3055
3056 =item Return Value: L<$resultset|/search>
3057
3058 =back
3059
3060 Returns a related resultset for the supplied relationship name.
3061
3062   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3063
3064 =cut
3065
3066 sub related_resultset {
3067   my ($self, $rel) = @_;
3068
3069   return $self->{related_resultsets}{$rel}
3070     if defined $self->{related_resultsets}{$rel};
3071
3072   return $self->{related_resultsets}{$rel} = do {
3073     my $rsrc = $self->result_source;
3074     my $rel_info = $rsrc->relationship_info($rel);
3075
3076     $self->throw_exception(
3077       "search_related: result source '" . $rsrc->source_name .
3078         "' has no such relationship $rel")
3079       unless $rel_info;
3080
3081     my $attrs = $self->_chain_relationship($rel);
3082
3083     my $join_count = $attrs->{seen_join}{$rel};
3084
3085     my $alias = $self->result_source->storage
3086         ->relname_to_table_alias($rel, $join_count);
3087
3088     # since this is search_related, and we already slid the select window inwards
3089     # (the select/as attrs were deleted in the beginning), we need to flip all
3090     # left joins to inner, so we get the expected results
3091     # read the comment on top of the actual function to see what this does
3092     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3093
3094
3095     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3096     delete @{$attrs}{qw(result_class alias)};
3097
3098     my $related_cache;
3099
3100     if (my $cache = $self->get_cache) {
3101       $related_cache = [ map
3102         { @{$_->related_resultset($rel)->get_cache||[]} }
3103         @$cache
3104       ];
3105     }
3106
3107     my $rel_source = $rsrc->related_source($rel);
3108
3109     my $new = do {
3110
3111       # The reason we do this now instead of passing the alias to the
3112       # search_rs below is that if you wrap/overload resultset on the
3113       # source you need to know what alias it's -going- to have for things
3114       # to work sanely (e.g. RestrictWithObject wants to be able to add
3115       # extra query restrictions, and these may need to be $alias.)
3116
3117       my $rel_attrs = $rel_source->resultset_attributes;
3118       local $rel_attrs->{alias} = $alias;
3119
3120       $rel_source->resultset
3121                  ->search_rs(
3122                      undef, {
3123                        %$attrs,
3124                        where => $attrs->{where},
3125                    });
3126     };
3127     $new->set_cache($related_cache) if $related_cache;
3128     $new;
3129   };
3130 }
3131
3132 =head2 current_source_alias
3133
3134 =over 4
3135
3136 =item Arguments: none
3137
3138 =item Return Value: $source_alias
3139
3140 =back
3141
3142 Returns the current table alias for the result source this resultset is built
3143 on, that will be used in the SQL query. Usually it is C<me>.
3144
3145 Currently the source alias that refers to the result set returned by a
3146 L</search>/L</find> family method depends on how you got to the resultset: it's
3147 C<me> by default, but eg. L</search_related> aliases it to the related result
3148 source name (and keeps C<me> referring to the original result set). The long
3149 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3150 (and make this method unnecessary).
3151
3152 Thus it's currently necessary to use this method in predefined queries (see
3153 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3154 source alias of the current result set:
3155
3156   # in a result set class
3157   sub modified_by {
3158     my ($self, $user) = @_;
3159
3160     my $me = $self->current_source_alias;
3161
3162     return $self->search({
3163       "$me.modified" => $user->id,
3164     });
3165   }
3166
3167 =cut
3168
3169 sub current_source_alias {
3170   return (shift->{attrs} || {})->{alias} || 'me';
3171 }
3172
3173 =head2 as_subselect_rs
3174
3175 =over 4
3176
3177 =item Arguments: none
3178
3179 =item Return Value: L<$resultset|/search>
3180
3181 =back
3182
3183 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3184 "virtual view" by including it as a subquery within the from clause.  From this
3185 point on, any joined tables are inaccessible to ->search on the resultset (as if
3186 it were simply where-filtered without joins).  For example:
3187
3188  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3189
3190  # 'x' now pollutes the query namespace
3191
3192  # So the following works as expected
3193  my $ok_rs = $rs->search({'x.other' => 1});
3194
3195  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3196  # def) we look for one row with contradictory terms and join in another table
3197  # (aliased 'x_2') which we never use
3198  my $broken_rs = $rs->search({'x.name' => 'def'});
3199
3200  my $rs2 = $rs->as_subselect_rs;
3201
3202  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3203  my $not_joined_rs = $rs2->search({'x.other' => 1});
3204
3205  # works as expected: finds a 'table' row related to two x rows (abc and def)
3206  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3207
3208 Another example of when one might use this would be to select a subset of
3209 columns in a group by clause:
3210
3211  my $rs = $schema->resultset('Bar')->search(undef, {
3212    group_by => [qw{ id foo_id baz_id }],
3213  })->as_subselect_rs->search(undef, {
3214    columns => [qw{ id foo_id }]
3215  });
3216
3217 In the above example normally columns would have to be equal to the group by,
3218 but because we isolated the group by into a subselect the above works.
3219
3220 =cut
3221
3222 sub as_subselect_rs {
3223   my $self = shift;
3224
3225   my $attrs = $self->_resolved_attrs;
3226
3227   my $fresh_rs = (ref $self)->new (
3228     $self->result_source
3229   );
3230
3231   # these pieces will be locked in the subquery
3232   delete $fresh_rs->{cond};
3233   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3234
3235   return $fresh_rs->search( {}, {
3236     from => [{
3237       $attrs->{alias} => $self->as_query,
3238       -alias  => $attrs->{alias},
3239       -rsrc   => $self->result_source,
3240     }],
3241     alias => $attrs->{alias},
3242   });
3243 }
3244
3245 # This code is called by search_related, and makes sure there
3246 # is clear separation between the joins before, during, and
3247 # after the relationship. This information is needed later
3248 # in order to properly resolve prefetch aliases (any alias
3249 # with a relation_chain_depth less than the depth of the
3250 # current prefetch is not considered)
3251 #
3252 # The increments happen twice per join. An even number means a
3253 # relationship specified via a search_related, whereas an odd
3254 # number indicates a join/prefetch added via attributes
3255 #
3256 # Also this code will wrap the current resultset (the one we
3257 # chain to) in a subselect IFF it contains limiting attributes
3258 sub _chain_relationship {
3259   my ($self, $rel) = @_;
3260   my $source = $self->result_source;
3261   my $attrs = { %{$self->{attrs}||{}} };
3262
3263   # we need to take the prefetch the attrs into account before we
3264   # ->_resolve_join as otherwise they get lost - captainL
3265   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3266
3267   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3268
3269   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3270
3271   my $from;
3272   my @force_subq_attrs = qw/offset rows group_by having/;
3273
3274   if (
3275     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3276       ||
3277     $self->_has_resolved_attr (@force_subq_attrs)
3278   ) {
3279     # Nuke the prefetch (if any) before the new $rs attrs
3280     # are resolved (prefetch is useless - we are wrapping
3281     # a subquery anyway).
3282     my $rs_copy = $self->search;
3283     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3284       $rs_copy->{attrs}{join},
3285       delete $rs_copy->{attrs}{prefetch},
3286     );
3287
3288     $from = [{
3289       -rsrc   => $source,
3290       -alias  => $attrs->{alias},
3291       $attrs->{alias} => $rs_copy->as_query,
3292     }];
3293     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3294     $seen->{-relation_chain_depth} = 0;
3295   }
3296   elsif ($attrs->{from}) {  #shallow copy suffices
3297     $from = [ @{$attrs->{from}} ];
3298   }
3299   else {
3300     $from = [{
3301       -rsrc  => $source,
3302       -alias => $attrs->{alias},
3303       $attrs->{alias} => $source->from,
3304     }];
3305   }
3306
3307   my $jpath = ($seen->{-relation_chain_depth})
3308     ? $from->[-1][0]{-join_path}
3309     : [];
3310
3311   my @requested_joins = $source->_resolve_join(
3312     $join,
3313     $attrs->{alias},
3314     $seen,
3315     $jpath,
3316   );
3317
3318   push @$from, @requested_joins;
3319
3320   $seen->{-relation_chain_depth}++;
3321
3322   # if $self already had a join/prefetch specified on it, the requested
3323   # $rel might very well be already included. What we do in this case
3324   # is effectively a no-op (except that we bump up the chain_depth on
3325   # the join in question so we could tell it *is* the search_related)
3326   my $already_joined;
3327
3328   # we consider the last one thus reverse
3329   for my $j (reverse @requested_joins) {
3330     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3331     if ($rel eq $last_j) {
3332       $j->[0]{-relation_chain_depth}++;
3333       $already_joined++;
3334       last;
3335     }
3336   }
3337
3338   unless ($already_joined) {
3339     push @$from, $source->_resolve_join(
3340       $rel,
3341       $attrs->{alias},
3342       $seen,
3343       $jpath,
3344     );
3345   }
3346
3347   $seen->{-relation_chain_depth}++;
3348
3349   return {%$attrs, from => $from, seen_join => $seen};
3350 }
3351
3352 sub _resolved_attrs {
3353   my $self = shift;
3354   return $self->{_attrs} if $self->{_attrs};
3355
3356   my $attrs  = { %{ $self->{attrs} || {} } };
3357   my $source = $self->result_source;
3358   my $alias  = $attrs->{alias};
3359
3360   # default selection list
3361   $attrs->{columns} = [ $source->columns ]
3362     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3363
3364   # merge selectors together
3365   for (qw/columns select as/) {
3366     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3367       if $attrs->{$_} or $attrs->{"+$_"};
3368   }
3369
3370   # disassemble columns
3371   my (@sel, @as);
3372   if (my $cols = delete $attrs->{columns}) {
3373     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3374       if (ref $c eq 'HASH') {
3375         for my $as (sort keys %$c) {
3376           push @sel, $c->{$as};
3377           push @as, $as;
3378         }
3379       }
3380       else {
3381         push @sel, $c;
3382         push @as, $c;
3383       }
3384     }
3385   }
3386
3387   # when trying to weed off duplicates later do not go past this point -
3388   # everything added from here on is unbalanced "anyone's guess" stuff
3389   my $dedup_stop_idx = $#as;
3390
3391   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3392     if $attrs->{as};
3393   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3394     if $attrs->{select};
3395
3396   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3397   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3398
3399   # disqualify all $alias.col as-bits (inflate-map mandated)
3400   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3401
3402   # de-duplicate the result (remove *identical* select/as pairs)
3403   # and also die on duplicate {as} pointing to different {select}s
3404   # not using a c-style for as the condition is prone to shrinkage
3405   my $seen;
3406   my $i = 0;
3407   while ($i <= $dedup_stop_idx) {
3408     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3409       splice @sel, $i, 1;
3410       splice @as, $i, 1;
3411       $dedup_stop_idx--;
3412     }
3413     elsif ($seen->{$as[$i]}++) {
3414       $self->throw_exception(
3415         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3416       );
3417     }
3418     else {
3419       $i++;
3420     }
3421   }
3422
3423   $attrs->{select} = \@sel;
3424   $attrs->{as} = \@as;
3425
3426   $attrs->{from} ||= [{
3427     -rsrc   => $source,
3428     -alias  => $self->{attrs}{alias},
3429     $self->{attrs}{alias} => $source->from,
3430   }];
3431
3432   if ( $attrs->{join} || $attrs->{prefetch} ) {
3433
3434     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3435       if ref $attrs->{from} ne 'ARRAY';
3436
3437     my $join = (delete $attrs->{join}) || {};
3438
3439     if ( defined $attrs->{prefetch} ) {
3440       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3441     }
3442
3443     $attrs->{from} =    # have to copy here to avoid corrupting the original
3444       [
3445         @{ $attrs->{from} },
3446         $source->_resolve_join(
3447           $join,
3448           $alias,
3449           { %{ $attrs->{seen_join} || {} } },
3450           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3451             ? $attrs->{from}[-1][0]{-join_path}
3452             : []
3453           ,
3454         )
3455       ];
3456   }
3457
3458   if ( defined $attrs->{order_by} ) {
3459     $attrs->{order_by} = (
3460       ref( $attrs->{order_by} ) eq 'ARRAY'
3461       ? [ @{ $attrs->{order_by} } ]
3462       : [ $attrs->{order_by} || () ]
3463     );
3464   }
3465
3466   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3467     $attrs->{group_by} = [ $attrs->{group_by} ];
3468   }
3469
3470   # generate the distinct induced group_by early, as prefetch will be carried via a
3471   # subquery (since a group_by is present)
3472   if (delete $attrs->{distinct}) {
3473     if ($attrs->{group_by}) {
3474       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3475     }
3476     else {
3477       $attrs->{_grouped_by_distinct} = 1;
3478       # distinct affects only the main selection part, not what prefetch may
3479       # add below.
3480       $attrs->{group_by} = $source->storage->_group_over_selection($attrs);
3481     }
3482   }
3483
3484   # generate selections based on the prefetch helper
3485   my $prefetch;
3486   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3487     if defined $attrs->{prefetch};
3488
3489   if ($prefetch) {
3490
3491     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3492       if $attrs->{_dark_selector};
3493
3494     $attrs->{collapse} = 1;
3495
3496     # this is a separate structure (we don't look in {from} directly)
3497     # as the resolver needs to shift things off the lists to work
3498     # properly (identical-prefetches on different branches)
3499     my $join_map = {};
3500     if (ref $attrs->{from} eq 'ARRAY') {
3501
3502       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3503
3504       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3505         next unless $j->[0]{-alias};
3506         next unless $j->[0]{-join_path};
3507         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3508
3509         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3510
3511         my $p = $join_map;
3512         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3513         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3514       }
3515     }
3516
3517     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3518
3519     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3520     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3521   }
3522
3523   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3524     $attrs->{_related_results_construction} = 1;
3525   }
3526   else {
3527     $attrs->{collapse} = 0;
3528   }
3529
3530   # run through the resulting joinstructure (starting from our current slot)
3531   # and unset collapse if proven unnesessary
3532   #
3533   # also while we are at it find out if the current root source has
3534   # been premultiplied by previous related_source chaining
3535   #
3536   # this allows to predict whether a root object with all other relation
3537   # data set to NULL is in fact unique
3538   if ($attrs->{collapse}) {
3539
3540     if (ref $attrs->{from} eq 'ARRAY') {
3541
3542       if (@{$attrs->{from}} == 1) {
3543         # no joins - no collapse
3544         $attrs->{collapse} = 0;
3545       }
3546       else {
3547         # find where our table-spec starts
3548         my @fromlist = @{$attrs->{from}};
3549         while (@fromlist) {
3550           my $t = shift @fromlist;
3551
3552           my $is_multi;
3553           # me vs join from-spec distinction - a ref means non-root
3554           if (ref $t eq 'ARRAY') {
3555             $t = $t->[0];
3556             $is_multi ||= ! $t->{-is_single};
3557           }
3558           last if ($t->{-alias} && $t->{-alias} eq $alias);
3559           $attrs->{_main_source_premultiplied} ||= $is_multi;
3560         }
3561
3562         # no non-singles remaining, nor any premultiplication - nothing to collapse
3563         if (
3564           ! $attrs->{_main_source_premultiplied}
3565             and
3566           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3567         ) {
3568           $attrs->{collapse} = 0;
3569         }
3570       }
3571     }
3572
3573     else {
3574       # if we can not analyze the from - err on the side of safety
3575       $attrs->{_main_source_premultiplied} = 1;
3576     }
3577   }
3578
3579   # if both page and offset are specified, produce a combined offset
3580   # even though it doesn't make much sense, this is what pre 081xx has
3581   # been doing
3582   if (my $page = delete $attrs->{page}) {
3583     $attrs->{offset} =
3584       ($attrs->{rows} * ($page - 1))
3585             +
3586       ($attrs->{offset} || 0)
3587     ;
3588   }
3589
3590   return $self->{_attrs} = $attrs;
3591 }
3592
3593 sub _rollout_attr {
3594   my ($self, $attr) = @_;
3595
3596   if (ref $attr eq 'HASH') {
3597     return $self->_rollout_hash($attr);
3598   } elsif (ref $attr eq 'ARRAY') {
3599     return $self->_rollout_array($attr);
3600   } else {
3601     return [$attr];
3602   }
3603 }
3604
3605 sub _rollout_array {
3606   my ($self, $attr) = @_;
3607
3608   my @rolled_array;
3609   foreach my $element (@{$attr}) {
3610     if (ref $element eq 'HASH') {
3611       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3612     } elsif (ref $element eq 'ARRAY') {
3613       #  XXX - should probably recurse here
3614       push( @rolled_array, @{$self->_rollout_array($element)} );
3615     } else {
3616       push( @rolled_array, $element );
3617     }
3618   }
3619   return \@rolled_array;
3620 }
3621
3622 sub _rollout_hash {
3623   my ($self, $attr) = @_;
3624
3625   my @rolled_array;
3626   foreach my $key (keys %{$attr}) {
3627     push( @rolled_array, { $key => $attr->{$key} } );
3628   }
3629   return \@rolled_array;
3630 }
3631
3632 sub _calculate_score {
3633   my ($self, $a, $b) = @_;
3634
3635   if (defined $a xor defined $b) {
3636     return 0;
3637   }
3638   elsif (not defined $a) {
3639     return 1;
3640   }
3641
3642   if (ref $b eq 'HASH') {
3643     my ($b_key) = keys %{$b};
3644     if (ref $a eq 'HASH') {
3645       my ($a_key) = keys %{$a};
3646       if ($a_key eq $b_key) {
3647         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3648       } else {
3649         return 0;
3650       }
3651     } else {
3652       return ($a eq $b_key) ? 1 : 0;
3653     }
3654   } else {
3655     if (ref $a eq 'HASH') {
3656       my ($a_key) = keys %{$a};
3657       return ($b eq $a_key) ? 1 : 0;
3658     } else {
3659       return ($b eq $a) ? 1 : 0;
3660     }
3661   }
3662 }
3663
3664 sub _merge_joinpref_attr {
3665   my ($self, $orig, $import) = @_;
3666
3667   return $import unless defined($orig);
3668   return $orig unless defined($import);
3669
3670   $orig = $self->_rollout_attr($orig);
3671   $import = $self->_rollout_attr($import);
3672
3673   my $seen_keys;
3674   foreach my $import_element ( @{$import} ) {
3675     # find best candidate from $orig to merge $b_element into
3676     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3677     foreach my $orig_element ( @{$orig} ) {
3678       my $score = $self->_calculate_score( $orig_element, $import_element );
3679       if ($score > $best_candidate->{score}) {
3680         $best_candidate->{position} = $position;
3681         $best_candidate->{score} = $score;
3682       }
3683       $position++;
3684     }
3685     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3686     $import_key = '' if not defined $import_key;
3687
3688     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3689       push( @{$orig}, $import_element );
3690     } else {
3691       my $orig_best = $orig->[$best_candidate->{position}];
3692       # merge orig_best and b_element together and replace original with merged
3693       if (ref $orig_best ne 'HASH') {
3694         $orig->[$best_candidate->{position}] = $import_element;
3695       } elsif (ref $import_element eq 'HASH') {
3696         my ($key) = keys %{$orig_best};
3697         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3698       }
3699     }
3700     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3701   }
3702
3703   return @$orig ? $orig : ();
3704 }
3705
3706 {
3707   my $hm;
3708
3709   sub _merge_attr {
3710     $hm ||= do {
3711       require Hash::Merge;
3712       my $hm = Hash::Merge->new;
3713
3714       $hm->specify_behavior({
3715         SCALAR => {
3716           SCALAR => sub {
3717             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3718
3719             if ($defl xor $defr) {
3720               return [ $defl ? $_[0] : $_[1] ];
3721             }
3722             elsif (! $defl) {
3723               return [];
3724             }
3725             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3726               return [ $_[0] ];
3727             }
3728             else {
3729               return [$_[0], $_[1]];
3730             }
3731           },
3732           ARRAY => sub {
3733             return $_[1] if !defined $_[0];
3734             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3735             return [$_[0], @{$_[1]}]
3736           },
3737           HASH  => sub {
3738             return [] if !defined $_[0] and !keys %{$_[1]};
3739             return [ $_[1] ] if !defined $_[0];
3740             return [ $_[0] ] if !keys %{$_[1]};
3741             return [$_[0], $_[1]]
3742           },
3743         },
3744         ARRAY => {
3745           SCALAR => sub {
3746             return $_[0] if !defined $_[1];
3747             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3748             return [@{$_[0]}, $_[1]]
3749           },
3750           ARRAY => sub {
3751             my @ret = @{$_[0]} or return $_[1];
3752             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3753             my %idx = map { $_ => 1 } @ret;
3754             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3755             \@ret;
3756           },
3757           HASH => sub {
3758             return [ $_[1] ] if ! @{$_[0]};
3759             return $_[0] if !keys %{$_[1]};
3760             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3761             return [ @{$_[0]}, $_[1] ];
3762           },
3763         },
3764         HASH => {
3765           SCALAR => sub {
3766             return [] if !keys %{$_[0]} and !defined $_[1];
3767             return [ $_[0] ] if !defined $_[1];
3768             return [ $_[1] ] if !keys %{$_[0]};
3769             return [$_[0], $_[1]]
3770           },
3771           ARRAY => sub {
3772             return [] if !keys %{$_[0]} and !@{$_[1]};
3773             return [ $_[0] ] if !@{$_[1]};
3774             return $_[1] if !keys %{$_[0]};
3775             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3776             return [ $_[0], @{$_[1]} ];
3777           },
3778           HASH => sub {
3779             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3780             return [ $_[0] ] if !keys %{$_[1]};
3781             return [ $_[1] ] if !keys %{$_[0]};
3782             return [ $_[0] ] if $_[0] eq $_[1];
3783             return [ $_[0], $_[1] ];
3784           },
3785         }
3786       } => 'DBIC_RS_ATTR_MERGER');
3787       $hm;
3788     };
3789
3790     return $hm->merge ($_[1], $_[2]);
3791   }
3792 }
3793
3794 sub STORABLE_freeze {
3795   my ($self, $cloning) = @_;
3796   my $to_serialize = { %$self };
3797
3798   # A cursor in progress can't be serialized (and would make little sense anyway)
3799   # the parser can be regenerated (and can't be serialized)
3800   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3801
3802   # nor is it sensical to store a not-yet-fired-count pager
3803   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3804     delete $to_serialize->{pager};
3805   }
3806
3807   Storable::nfreeze($to_serialize);
3808 }
3809
3810 # need this hook for symmetry
3811 sub STORABLE_thaw {
3812   my ($self, $cloning, $serialized) = @_;
3813
3814   %$self = %{ Storable::thaw($serialized) };
3815
3816   $self;
3817 }
3818
3819
3820 =head2 throw_exception
3821
3822 See L<DBIx::Class::Schema/throw_exception> for details.
3823
3824 =cut
3825
3826 sub throw_exception {
3827   my $self=shift;
3828
3829   if (ref $self and my $rsrc = $self->result_source) {
3830     $rsrc->throw_exception(@_)
3831   }
3832   else {
3833     DBIx::Class::Exception->throw(@_);
3834   }
3835 }
3836
3837 1;
3838
3839 __END__
3840
3841 # XXX: FIXME: Attributes docs need clearing up
3842
3843 =head1 ATTRIBUTES
3844
3845 Attributes are used to refine a ResultSet in various ways when
3846 searching for data. They can be passed to any method which takes an
3847 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3848 L</count>.
3849
3850 Default attributes can be set on the result class using
3851 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3852 the CAVEATS on that feature before using it!)
3853
3854 These are in no particular order:
3855
3856 =head2 order_by
3857
3858 =over 4
3859
3860 =item Value: ( $order_by | \@order_by | \%order_by )
3861
3862 =back
3863
3864 Which column(s) to order the results by.
3865
3866 [The full list of suitable values is documented in
3867 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3868 common options.]
3869
3870 If a single column name, or an arrayref of names is supplied, the
3871 argument is passed through directly to SQL. The hashref syntax allows
3872 for connection-agnostic specification of ordering direction:
3873
3874  For descending order:
3875
3876   order_by => { -desc => [qw/col1 col2 col3/] }
3877
3878  For explicit ascending order:
3879
3880   order_by => { -asc => 'col' }
3881
3882 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3883 supported, although you are strongly encouraged to use the hashref
3884 syntax as outlined above.
3885
3886 =head2 columns
3887
3888 =over 4
3889
3890 =item Value: \@columns | \%columns | $column
3891
3892 =back
3893
3894 Shortcut to request a particular set of columns to be retrieved. Each
3895 column spec may be a string (a table column name), or a hash (in which
3896 case the key is the C<as> value, and the value is used as the C<select>
3897 expression). Adds C<me.> onto the start of any column without a C<.> in
3898 it and sets C<select> from that, then auto-populates C<as> from
3899 C<select> as normal. (You may also use the C<cols> attribute, as in
3900 earlier versions of DBIC, but this is deprecated.)
3901
3902 Essentially C<columns> does the same as L</select> and L</as>.
3903
3904     columns => [ 'foo', { bar => 'baz' } ]
3905
3906 is the same as
3907
3908     select => [qw/foo baz/],
3909     as => [qw/foo bar/]
3910
3911 =head2 +columns
3912
3913 =over 4
3914
3915 =item Value: \@columns
3916
3917 =back
3918
3919 Indicates additional columns to be selected from storage. Works the same as
3920 L</columns> but adds columns to the selection. (You may also use the
3921 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3922 deprecated). For example:-
3923
3924   $schema->resultset('CD')->search(undef, {
3925     '+columns' => ['artist.name'],
3926     join => ['artist']
3927   });
3928
3929 would return all CDs and include a 'name' column to the information
3930 passed to object inflation. Note that the 'artist' is the name of the
3931 column (or relationship) accessor, and 'name' is the name of the column
3932 accessor in the related table.
3933
3934 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3935 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3936 unary plus operator before it.
3937
3938 =head2 include_columns
3939
3940 =over 4
3941
3942 =item Value: \@columns
3943
3944 =back
3945
3946 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3947
3948 =head2 select
3949
3950 =over 4
3951
3952 =item Value: \@select_columns
3953
3954 =back
3955
3956 Indicates which columns should be selected from the storage. You can use
3957 column names, or in the case of RDBMS back ends, function or stored procedure
3958 names:
3959
3960   $rs = $schema->resultset('Employee')->search(undef, {
3961     select => [
3962       'name',
3963       { count => 'employeeid' },
3964       { max => { length => 'name' }, -as => 'longest_name' }
3965     ]
3966   });
3967
3968   # Equivalent SQL
3969   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3970
3971 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3972 use L</select>, to instruct DBIx::Class how to store the result of the column.
3973 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3974 identifier aliasing. You can however alias a function, so you can use it in
3975 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3976 attribute> supplied as shown in the example above.
3977
3978 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3979 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3980 unary plus operator before it.
3981
3982 =head2 +select
3983
3984 =over 4
3985
3986 Indicates additional columns to be selected from storage.  Works the same as
3987 L</select> but adds columns to the default selection, instead of specifying
3988 an explicit list.
3989
3990 =back
3991
3992 =head2 as
3993
3994 =over 4
3995
3996 =item Value: \@inflation_names
3997
3998 =back
3999
4000 Indicates column names for object inflation. That is L</as> indicates the
4001 slot name in which the column value will be stored within the
4002 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4003 identifier by the C<get_column> method (or via the object accessor B<if one
4004 with the same name already exists>) as shown below. The L</as> attribute has
4005 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4006
4007   $rs = $schema->resultset('Employee')->search(undef, {
4008     select => [
4009       'name',
4010       { count => 'employeeid' },
4011       { max => { length => 'name' }, -as => 'longest_name' }
4012     ],
4013     as => [qw/
4014       name
4015       employee_count
4016       max_name_length
4017     /],
4018   });
4019
4020 If the object against which the search is performed already has an accessor
4021 matching a column name specified in C<as>, the value can be retrieved using
4022 the accessor as normal:
4023
4024   my $name = $employee->name();
4025
4026 If on the other hand an accessor does not exist in the object, you need to
4027 use C<get_column> instead:
4028
4029   my $employee_count = $employee->get_column('employee_count');
4030
4031 You can create your own accessors if required - see
4032 L<DBIx::Class::Manual::Cookbook> for details.
4033
4034 =head2 +as
4035
4036 =over 4
4037
4038 Indicates additional column names for those added via L</+select>. See L</as>.
4039
4040 =back
4041
4042 =head2 join
4043
4044 =over 4
4045
4046 =item Value: ($rel_name | \@rel_names | \%rel_names)
4047
4048 =back
4049
4050 Contains a list of relationships that should be joined for this query.  For
4051 example:
4052
4053   # Get CDs by Nine Inch Nails
4054   my $rs = $schema->resultset('CD')->search(
4055     { 'artist.name' => 'Nine Inch Nails' },
4056     { join => 'artist' }
4057   );
4058
4059 Can also contain a hash reference to refer to the other relation's relations.
4060 For example:
4061
4062   package MyApp::Schema::Track;
4063   use base qw/DBIx::Class/;
4064   __PACKAGE__->table('track');
4065   __PACKAGE__->add_columns(qw/trackid cd position title/);
4066   __PACKAGE__->set_primary_key('trackid');
4067   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4068   1;
4069
4070   # In your application
4071   my $rs = $schema->resultset('Artist')->search(
4072     { 'track.title' => 'Teardrop' },
4073     {
4074       join     => { cd => 'track' },
4075       order_by => 'artist.name',
4076     }
4077   );
4078
4079 You need to use the relationship (not the table) name in  conditions,
4080 because they are aliased as such. The current table is aliased as "me", so
4081 you need to use me.column_name in order to avoid ambiguity. For example:
4082
4083   # Get CDs from 1984 with a 'Foo' track
4084   my $rs = $schema->resultset('CD')->search(
4085     {
4086       'me.year' => 1984,
4087       'tracks.name' => 'Foo'
4088     },
4089     { join => 'tracks' }
4090   );
4091
4092 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4093 similarly for a third time). For e.g.
4094
4095   my $rs = $schema->resultset('Artist')->search({
4096     'cds.title'   => 'Down to Earth',
4097     'cds_2.title' => 'Popular',
4098   }, {
4099     join => [ qw/cds cds/ ],
4100   });
4101
4102 will return a set of all artists that have both a cd with title 'Down
4103 to Earth' and a cd with title 'Popular'.
4104
4105 If you want to fetch related objects from other tables as well, see L</prefetch>
4106 below.
4107
4108  NOTE: An internal join-chain pruner will discard certain joins while
4109  constructing the actual SQL query, as long as the joins in question do not
4110  affect the retrieved result. This for example includes 1:1 left joins
4111  that are not part of the restriction specification (WHERE/HAVING) nor are
4112  a part of the query selection.
4113
4114 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4115
4116 =head2 collapse
4117
4118 =over 4
4119
4120 =item Value: (0 | 1)
4121
4122 =back
4123
4124 When set to a true value, indicates that any rows fetched from joined has_many
4125 relationships are to be aggregated into the corresponding "parent" object. For
4126 example, the resultset:
4127
4128   my $rs = $schema->resultset('CD')->search({}, {
4129     '+columns' => [ qw/ tracks.title tracks.position / ],
4130     join => 'tracks',
4131     collapse => 1,
4132   });
4133
4134 While executing the following query:
4135
4136   SELECT me.*, tracks.title, tracks.position
4137     FROM cd me
4138     LEFT JOIN track tracks
4139       ON tracks.cdid = me.cdid
4140
4141 Will return only as many objects as there are rows in the CD source, even
4142 though the result of the query may span many rows. Each of these CD objects
4143 will in turn have multiple "Track" objects hidden behind the has_many
4144 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4145 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4146 product"), with each CD object containing exactly one of all fetched Track data.
4147
4148 When a collapse is requested on a non-ordered resultset, an order by some
4149 unique part of the main source (the left-most table) is inserted automatically.
4150 This is done so that the resultset is allowed to be "lazy" - calling
4151 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4152 object with all of its related data.
4153
4154 If an L</order_by> is already declared, and orders the resultset in a way that
4155 makes collapsing as described above impossible (e.g. C<< ORDER BY
4156 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4157 switch to "eager" mode and slurp the entire resultset before consturcting the
4158 first object returned by L</next>.
4159
4160 Setting this attribute on a resultset that does not join any has_many
4161 relations is a no-op.
4162
4163 For a more in-depth discussion, see L</PREFETCHING>.
4164
4165 =head2 prefetch
4166
4167 =over 4
4168
4169 =item Value: ($rel_name | \@rel_names | \%rel_names)
4170
4171 =back
4172
4173 This attribute is a shorthand for specifying a L</join> spec, adding all
4174 columns from the joined related sources as L</+columns> and setting
4175 L</collapse> to a true value. For example, the following two queries are
4176 equivalent:
4177
4178   my $rs = $schema->resultset('Artist')->search({}, {
4179     prefetch => { cds => ['genre', 'tracks' ] },
4180   });
4181
4182 and
4183
4184   my $rs = $schema->resultset('Artist')->search({}, {
4185     join => { cds => ['genre', 'tracks' ] },
4186     collapse => 1,
4187     '+columns' => [
4188       (map
4189         { +{ "cds.$_" => "cds.$_" } }
4190         $schema->source('Artist')->related_source('cds')->columns
4191       ),
4192       (map
4193         { +{ "cds.genre.$_" => "genre.$_" } }
4194         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4195       ),
4196       (map
4197         { +{ "cds.tracks.$_" => "tracks.$_" } }
4198         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4199       ),
4200     ],
4201   });
4202
4203 Both producing the following SQL:
4204
4205   SELECT  me.artistid, me.name, me.rank, me.charfield,
4206           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4207           genre.genreid, genre.name,
4208           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4209     FROM artist me
4210     LEFT JOIN cd cds
4211       ON cds.artist = me.artistid
4212     LEFT JOIN genre genre
4213       ON genre.genreid = cds.genreid
4214     LEFT JOIN track tracks
4215       ON tracks.cd = cds.cdid
4216   ORDER BY me.artistid
4217
4218 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4219 the arguments are properly merged and generally do the right thing. For
4220 example, you may want to do the following:
4221
4222   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4223     { 'genre.genreid' => undef },
4224     {
4225       join => { cds => 'genre' },
4226       prefetch => 'cds',
4227     }
4228   );
4229
4230 Which generates the following SQL:
4231
4232   SELECT  me.artistid, me.name, me.rank, me.charfield,
4233           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4234     FROM artist me
4235     LEFT JOIN cd cds
4236       ON cds.artist = me.artistid
4237     LEFT JOIN genre genre
4238       ON genre.genreid = cds.genreid
4239   WHERE genre.genreid IS NULL
4240   ORDER BY me.artistid
4241
4242 For a more in-depth discussion, see L</PREFETCHING>.
4243
4244 =head2 alias
4245
4246 =over 4
4247
4248 =item Value: $source_alias
4249
4250 =back
4251
4252 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4253 nested search queries (sub-SELECTs) might need specific aliases set to
4254 reference inner queries.  For example:
4255
4256    my $q = $rs
4257       ->related_resultset('CDs')
4258       ->related_resultset('Tracks')
4259       ->search({
4260          'track.id' => { -ident => 'none_search.id' },
4261       })
4262       ->as_query;
4263
4264    my $ids = $self->search({
4265       -not_exists => $q,
4266    }, {
4267       alias    => 'none_search',
4268       group_by => 'none_search.id',
4269    })->get_column('id')->as_query;
4270
4271    $self->search({ id => { -in => $ids } })
4272
4273 This attribute is directly tied to L</current_source_alias>.
4274
4275 =head2 page
4276
4277 =over 4
4278
4279 =item Value: $page
4280
4281 =back
4282
4283 Makes the resultset paged and specifies the page to retrieve. Effectively
4284 identical to creating a non-pages resultset and then calling ->page($page)
4285 on it.
4286
4287 If L</rows> attribute is not specified it defaults to 10 rows per page.
4288
4289 When you have a paged resultset, L</count> will only return the number
4290 of rows in the page. To get the total, use the L</pager> and call
4291 C<total_entries> on it.
4292
4293 =head2 rows
4294
4295 =over 4
4296
4297 =item Value: $rows
4298
4299 =back
4300
4301 Specifies the maximum number of rows for direct retrieval or the number of
4302 rows per page if the page attribute or method is used.
4303
4304 =head2 offset
4305
4306 =over 4
4307
4308 =item Value: $offset
4309
4310 =back
4311
4312 Specifies the (zero-based) row number for the  first row to be returned, or the
4313 of the first row of the first page if paging is used.
4314
4315 =head2 software_limit
4316
4317 =over 4
4318
4319 =item Value: (0 | 1)
4320
4321 =back
4322
4323 When combined with L</rows> and/or L</offset> the generated SQL will not
4324 include any limit dialect stanzas. Instead the entire result will be selected
4325 as if no limits were specified, and DBIC will perform the limit locally, by
4326 artificially advancing and finishing the resulting L</cursor>.
4327
4328 This is the recommended way of performing resultset limiting when no sane RDBMS
4329 implementation is available (e.g.
4330 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4331 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4332
4333 =head2 group_by
4334
4335 =over 4
4336
4337 =item Value: \@columns
4338
4339 =back
4340
4341 A arrayref of columns to group by. Can include columns of joined tables.
4342
4343   group_by => [qw/ column1 column2 ... /]
4344
4345 =head2 having
4346
4347 =over 4
4348
4349 =item Value: $condition
4350
4351 =back
4352
4353 HAVING is a select statement attribute that is applied between GROUP BY and
4354 ORDER BY. It is applied to the after the grouping calculations have been
4355 done.
4356
4357   having => { 'count_employee' => { '>=', 100 } }
4358
4359 or with an in-place function in which case literal SQL is required:
4360
4361   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4362
4363 =head2 distinct
4364
4365 =over 4
4366
4367 =item Value: (0 | 1)
4368
4369 =back
4370
4371 Set to 1 to group by all columns. If the resultset already has a group_by
4372 attribute, this setting is ignored and an appropriate warning is issued.
4373
4374 =head2 where
4375
4376 =over 4
4377
4378 Adds to the WHERE clause.
4379
4380   # only return rows WHERE deleted IS NULL for all searches
4381   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4382
4383 Can be overridden by passing C<< { where => undef } >> as an attribute
4384 to a resultset.
4385
4386 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4387
4388 =back
4389
4390 =head2 cache
4391
4392 Set to 1 to cache search results. This prevents extra SQL queries if you
4393 revisit rows in your ResultSet:
4394
4395   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4396
4397   while( my $artist = $resultset->next ) {
4398     ... do stuff ...
4399   }
4400
4401   $rs->first; # without cache, this would issue a query
4402
4403 By default, searches are not cached.
4404
4405 For more examples of using these attributes, see
4406 L<DBIx::Class::Manual::Cookbook>.
4407
4408 =head2 for
4409
4410 =over 4
4411
4412 =item Value: ( 'update' | 'shared' | \$scalar )
4413
4414 =back
4415
4416 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4417 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4418 query.
4419
4420 =head1 PREFETCHING
4421
4422 DBIx::Class supports arbitrary related data prefetching from multiple related
4423 sources. Any combination of relationship types and column sets are supported.
4424 If L<collapsing|/collapse> is requested, there is an additional requirement of
4425 selecting enough data to make every individual object uniquely identifiable.
4426
4427 Here are some more involved examples, based on the following relationship map:
4428
4429   # Assuming:
4430   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4431   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4432   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4433
4434   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4435
4436   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4437
4438
4439
4440   my $rs = $schema->resultset('Tag')->search(
4441     undef,
4442     {
4443       prefetch => {
4444         cd => 'artist'
4445       }
4446     }
4447   );
4448
4449 The initial search results in SQL like the following:
4450
4451   SELECT tag.*, cd.*, artist.* FROM tag
4452   JOIN cd ON tag.cd = cd.cdid
4453   JOIN artist ON cd.artist = artist.artistid
4454
4455 L<DBIx::Class> has no need to go back to the database when we access the
4456 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4457 case.
4458
4459 Simple prefetches will be joined automatically, so there is no need
4460 for a C<join> attribute in the above search.
4461
4462 The L</prefetch> attribute can be used with any of the relationship types
4463 and multiple prefetches can be specified together. Below is a more complex
4464 example that prefetches a CD's artist, its liner notes (if present),
4465 the cover image, the tracks on that CD, and the guests on those
4466 tracks.
4467
4468   my $rs = $schema->resultset('CD')->search(
4469     undef,
4470     {
4471       prefetch => [
4472         { artist => 'record_label'},  # belongs_to => belongs_to
4473         'liner_note',                 # might_have
4474         'cover_image',                # has_one
4475         { tracks => 'guests' },       # has_many => has_many
4476       ]
4477     }
4478   );
4479
4480 This will produce SQL like the following:
4481
4482   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4483          tracks.*, guests.*
4484     FROM cd me
4485     JOIN artist artist
4486       ON artist.artistid = me.artistid
4487     JOIN record_label record_label
4488       ON record_label.labelid = artist.labelid
4489     LEFT JOIN track tracks
4490       ON tracks.cdid = me.cdid
4491     LEFT JOIN guest guests
4492       ON guests.trackid = track.trackid
4493     LEFT JOIN liner_notes liner_note
4494       ON liner_note.cdid = me.cdid
4495     JOIN cd_artwork cover_image
4496       ON cover_image.cdid = me.cdid
4497   ORDER BY tracks.cd
4498
4499 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4500 C<tracks>, and C<guests> of the CD will all be available through the
4501 relationship accessors without the need for additional queries to the
4502 database.
4503
4504 =head3 CAVEATS
4505
4506 Prefetch does a lot of deep magic. As such, it may not behave exactly
4507 as you might expect.
4508
4509 =over 4
4510
4511 =item *
4512
4513 Prefetch uses the L</cache> to populate the prefetched relationships. This
4514 may or may not be what you want.
4515
4516 =item *
4517
4518 If you specify a condition on a prefetched relationship, ONLY those
4519 rows that match the prefetched condition will be fetched into that relationship.
4520 This means that adding prefetch to a search() B<may alter> what is returned by
4521 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4522
4523   my $artist_rs = $schema->resultset('Artist')->search({
4524       'cds.year' => 2008,
4525   }, {
4526       join => 'cds',
4527   });
4528
4529   my $count = $artist_rs->first->cds->count;
4530
4531   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4532
4533   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4534
4535   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4536
4537 That cmp_ok() may or may not pass depending on the datasets involved. In other
4538 words the C<WHERE> condition would apply to the entire dataset, just like
4539 it would in regular SQL. If you want to add a condition only to the "right side"
4540 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4541 condition|DBIx::Class::Relationship::Base/condition>
4542
4543 =back
4544
4545 =head1 DBIC BIND VALUES
4546
4547 Because DBIC may need more information to bind values than just the column name
4548 and value itself, it uses a special format for both passing and receiving bind
4549 values.  Each bind value should be composed of an arrayref of
4550 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4551
4552 =over 4
4553
4554 =item dbd_attrs
4555
4556 If present (in any form), this is what is being passed directly to bind_param.
4557 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4558 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4559
4560 If this is specified, all other bind options described below are ignored.
4561
4562 =item sqlt_datatype
4563
4564 If present, this is used to infer the actual bind attribute by passing to
4565 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4566 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4567
4568 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4569 currently drivers are expected to "Do the Right Thing" when given a common
4570 datatype name.  (Not ideal, but that's what we got at this point.)
4571
4572 =item sqlt_size
4573
4574 Currently used to correctly allocate buffers for bind_param_inout().
4575 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4576 or to a sensible value based on the "data_type".
4577
4578 =item dbic_colname
4579
4580 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4581 explicitly specified they are never overriden).  Also used by some weird DBDs,
4582 where the column name should be available at bind_param time (e.g. Oracle).
4583
4584 =back
4585
4586 For backwards compatibility and convenience, the following shortcuts are
4587 supported:
4588
4589   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4590   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4591   [ undef,   $val ] === [ {}, $val ]
4592
4593 =head1 AUTHOR AND CONTRIBUTORS
4594
4595 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4596
4597 =head1 LICENSE
4598
4599 You may distribute this code under the same terms as Perl itself.
4600