lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 my @count_via_subq_attrs = qw/join seen_join group_by/;
1154 sub count {
1155   my $self = shift;
1156   return $self->search(@_)->count if @_ and defined $_[0];
1157   return scalar @{ $self->get_cache } if $self->get_cache;
1158
1159   my @check_attrs = @count_via_subq_attrs;
1160
1161   # if we are not paged - we are simply asking for a limit
1162   if (not $self->{attrs}{page} and not $self->{attrs}{software_limit}) {
1163     push @check_attrs, qw/rows offset/;
1164   }
1165
1166   return $self->_has_attr (@check_attrs)
1167     ? $self->_count_subq
1168     : $self->_count_simple
1169 }
1170
1171 sub _count_subq {
1172   my $self = shift;
1173
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   my $select_cols = $attrs->{group_by} || [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1177   $attrs->{from} = [{
1178     count_subq => $self->search ({}, { columns => $select_cols, group_by => $select_cols })
1179                          ->as_query
1180   }];
1181
1182   # the subquery above will integrate everything, including 'where' and any pagers
1183   delete $attrs->{$_} for (@count_via_subq_attrs, qw/where rows offset pager page/ );
1184
1185   return $self->__count ($attrs);
1186 }
1187
1188 sub _count_simple {
1189   my $self = shift;
1190
1191   my $count = $self->__count;
1192   return 0 unless $count;
1193
1194   # need to take offset from resolved attrs
1195
1196   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1197   $count = $self->{attrs}{rows} if
1198     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1199   $count = 0 if ($count < 0);
1200   return $count;
1201 }
1202
1203 sub __count {
1204   my ($self, $attrs) = @_;
1205
1206   $attrs ||= { %{$self->{attrs}} };
1207
1208   $attrs->{select} = { count => '*' };
1209   $attrs->{as} = [qw/count/];
1210
1211   # take off any pagers, record_filter is cdbi, and no point of ordering a count
1212   delete $attrs->{$_} for qw/rows offset page pager order_by record_filter/;
1213
1214   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1215   my ($count) = $tmp_rs->cursor->next;
1216
1217   return $count;
1218 }
1219
1220 sub _bool {
1221   return 1;
1222 }
1223
1224 =head2 count_literal
1225
1226 =over 4
1227
1228 =item Arguments: $sql_fragment, @bind_values
1229
1230 =item Return Value: $count
1231
1232 =back
1233
1234 Counts the results in a literal query. Equivalent to calling L</search_literal>
1235 with the passed arguments, then L</count>.
1236
1237 =cut
1238
1239 sub count_literal { shift->search_literal(@_)->count; }
1240
1241 =head2 all
1242
1243 =over 4
1244
1245 =item Arguments: none
1246
1247 =item Return Value: @objects
1248
1249 =back
1250
1251 Returns all elements in the resultset. Called implicitly if the resultset
1252 is returned in list context.
1253
1254 =cut
1255
1256 sub all {
1257   my $self = shift;
1258   if(@_) {
1259       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1260   }
1261
1262   return @{ $self->get_cache } if $self->get_cache;
1263
1264   my @obj;
1265
1266   # TODO: don't call resolve here
1267   if (keys %{$self->_resolved_attrs->{collapse}}) {
1268 #  if ($self->{attrs}{prefetch}) {
1269       # Using $self->cursor->all is really just an optimisation.
1270       # If we're collapsing has_many prefetches it probably makes
1271       # very little difference, and this is cleaner than hacking
1272       # _construct_object to survive the approach
1273     my @row = $self->cursor->next;
1274     while (@row) {
1275       push(@obj, $self->_construct_object(@row));
1276       @row = (exists $self->{stashed_row}
1277                ? @{delete $self->{stashed_row}}
1278                : $self->cursor->next);
1279     }
1280   } else {
1281     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1282   }
1283
1284   $self->set_cache(\@obj) if $self->{attrs}{cache};
1285   return @obj;
1286 }
1287
1288 =head2 reset
1289
1290 =over 4
1291
1292 =item Arguments: none
1293
1294 =item Return Value: $self
1295
1296 =back
1297
1298 Resets the resultset's cursor, so you can iterate through the elements again.
1299
1300 =cut
1301
1302 sub reset {
1303   my ($self) = @_;
1304   delete $self->{_attrs} if exists $self->{_attrs};
1305   $self->{all_cache_position} = 0;
1306   $self->cursor->reset;
1307   return $self;
1308 }
1309
1310 =head2 first
1311
1312 =over 4
1313
1314 =item Arguments: none
1315
1316 =item Return Value: $object?
1317
1318 =back
1319
1320 Resets the resultset and returns an object for the first result (if the
1321 resultset returns anything).
1322
1323 =cut
1324
1325 sub first {
1326   return $_[0]->reset->next;
1327 }
1328
1329
1330 # _update_delete_via_subq
1331 #
1332 # Presence of some rs attributes requires a subquery to reliably
1333 # update/deletre
1334 #
1335
1336 sub _update_delete_via_subq {
1337   return $_[0]->_has_attr (qw/join seen_join group_by row offset page/);
1338 }
1339
1340
1341 # _cond_for_update_delete
1342 #
1343 # update/delete require the condition to be modified to handle
1344 # the differing SQL syntax available.  This transforms the $self->{cond}
1345 # appropriately, returning the new condition.
1346
1347 sub _cond_for_update_delete {
1348   my ($self, $full_cond) = @_;
1349   my $cond = {};
1350
1351   $full_cond ||= $self->{cond};
1352   # No-op. No condition, we're updating/deleting everything
1353   return $cond unless ref $full_cond;
1354
1355   if (ref $full_cond eq 'ARRAY') {
1356     $cond = [
1357       map {
1358         my %hash;
1359         foreach my $key (keys %{$_}) {
1360           $key =~ /([^.]+)$/;
1361           $hash{$1} = $_->{$key};
1362         }
1363         \%hash;
1364       } @{$full_cond}
1365     ];
1366   }
1367   elsif (ref $full_cond eq 'HASH') {
1368     if ((keys %{$full_cond})[0] eq '-and') {
1369       $cond->{-and} = [];
1370       my @cond = @{$full_cond->{-and}};
1371        for (my $i = 0; $i < @cond; $i++) {
1372         my $entry = $cond[$i];
1373         my $hash;
1374         if (ref $entry eq 'HASH') {
1375           $hash = $self->_cond_for_update_delete($entry);
1376         }
1377         else {
1378           $entry =~ /([^.]+)$/;
1379           $hash->{$1} = $cond[++$i];
1380         }
1381         push @{$cond->{-and}}, $hash;
1382       }
1383     }
1384     else {
1385       foreach my $key (keys %{$full_cond}) {
1386         $key =~ /([^.]+)$/;
1387         $cond->{$1} = $full_cond->{$key};
1388       }
1389     }
1390   }
1391   else {
1392     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1393   }
1394
1395   return $cond;
1396 }
1397
1398
1399 =head2 update
1400
1401 =over 4
1402
1403 =item Arguments: \%values
1404
1405 =item Return Value: $storage_rv
1406
1407 =back
1408
1409 Sets the specified columns in the resultset to the supplied values in a
1410 single query. Return value will be true if the update succeeded or false
1411 if no records were updated; exact type of success value is storage-dependent.
1412
1413 =cut
1414
1415 sub update {
1416   my ($self, $values) = @_;
1417   $self->throw_exception('Values for update must be a hash')
1418     unless ref $values eq 'HASH';
1419
1420   # rs operations with subqueries are Storage dependent - delegate
1421   if ($self->_update_delete_via_subq) {
1422     return $self->result_source->storage->subq_update_delete($self, 'update', $values);
1423   }
1424
1425   my $cond = $self->_cond_for_update_delete;
1426
1427   return $self->result_source->storage->update(
1428     $self->result_source, $values, $cond
1429   );
1430 }
1431
1432 =head2 update_all
1433
1434 =over 4
1435
1436 =item Arguments: \%values
1437
1438 =item Return Value: 1
1439
1440 =back
1441
1442 Fetches all objects and updates them one at a time. Note that C<update_all>
1443 will run DBIC cascade triggers, while L</update> will not.
1444
1445 =cut
1446
1447 sub update_all {
1448   my ($self, $values) = @_;
1449   $self->throw_exception('Values for update_all must be a hash')
1450     unless ref $values eq 'HASH';
1451   foreach my $obj ($self->all) {
1452     $obj->set_columns($values)->update;
1453   }
1454   return 1;
1455 }
1456
1457 =head2 delete
1458
1459 =over 4
1460
1461 =item Arguments: none
1462
1463 =item Return Value: 1
1464
1465 =back
1466
1467 Deletes the contents of the resultset from its result source. Note that this
1468 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1469 to run. See also L<DBIx::Class::Row/delete>.
1470
1471 delete may not generate correct SQL for a query with joins or a resultset
1472 chained from a related resultset.  In this case it will generate a warning:-
1473
1474 In these cases you may find that delete_all is more appropriate, or you
1475 need to respecify your query in a way that can be expressed without a join.
1476
1477 =cut
1478
1479 sub delete {
1480   my $self = shift;
1481   $self->throw_exception('delete does not accept any arguments')
1482     if @_;
1483
1484   # rs operations with subqueries are Storage dependent - delegate
1485   if ($self->_update_delete_via_subq) {
1486     return $self->result_source->storage->subq_update_delete($self, 'delete');
1487   }
1488
1489   my $cond = $self->_cond_for_update_delete;
1490
1491   $self->result_source->storage->delete($self->result_source, $cond);
1492   return 1;
1493 }
1494
1495 =head2 delete_all
1496
1497 =over 4
1498
1499 =item Arguments: none
1500
1501 =item Return Value: 1
1502
1503 =back
1504
1505 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1506 will run DBIC cascade triggers, while L</delete> will not.
1507
1508 =cut
1509
1510 sub delete_all {
1511   my $self = shift;
1512   $self->throw_exception('delete_all does not accept any arguments')
1513     if @_;
1514
1515   $_->delete for $self->all;
1516   return 1;
1517 }
1518
1519 =head2 populate
1520
1521 =over 4
1522
1523 =item Arguments: \@data;
1524
1525 =back
1526
1527 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1528 For the arrayref of hashrefs style each hashref should be a structure suitable
1529 forsubmitting to a $resultset->create(...) method.
1530
1531 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1532 to insert the data, as this is a faster method.
1533
1534 Otherwise, each set of data is inserted into the database using
1535 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1536 objects is returned.
1537
1538 Example:  Assuming an Artist Class that has many CDs Classes relating:
1539
1540   my $Artist_rs = $schema->resultset("Artist");
1541
1542   ## Void Context Example
1543   $Artist_rs->populate([
1544      { artistid => 4, name => 'Manufactured Crap', cds => [
1545         { title => 'My First CD', year => 2006 },
1546         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1547       ],
1548      },
1549      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1550         { title => 'My parents sold me to a record company' ,year => 2005 },
1551         { title => 'Why Am I So Ugly?', year => 2006 },
1552         { title => 'I Got Surgery and am now Popular', year => 2007 }
1553       ],
1554      },
1555   ]);
1556
1557   ## Array Context Example
1558   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1559     { name => "Artist One"},
1560     { name => "Artist Two"},
1561     { name => "Artist Three", cds=> [
1562     { title => "First CD", year => 2007},
1563     { title => "Second CD", year => 2008},
1564   ]}
1565   ]);
1566
1567   print $ArtistOne->name; ## response is 'Artist One'
1568   print $ArtistThree->cds->count ## reponse is '2'
1569
1570 For the arrayref of arrayrefs style,  the first element should be a list of the
1571 fieldsnames to which the remaining elements are rows being inserted.  For
1572 example:
1573
1574   $Arstist_rs->populate([
1575     [qw/artistid name/],
1576     [100, 'A Formally Unknown Singer'],
1577     [101, 'A singer that jumped the shark two albums ago'],
1578     [102, 'An actually cool singer.'],
1579   ]);
1580
1581 Please note an important effect on your data when choosing between void and
1582 wantarray context. Since void context goes straight to C<insert_bulk> in
1583 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1584 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1585 create primary keys for you, you will find that your PKs are empty.  In this
1586 case you will have to use the wantarray context in order to create those
1587 values.
1588
1589 =cut
1590
1591 sub populate {
1592   my $self = shift @_;
1593   my $data = ref $_[0][0] eq 'HASH'
1594     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1595     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1596
1597   if(defined wantarray) {
1598     my @created;
1599     foreach my $item (@$data) {
1600       push(@created, $self->create($item));
1601     }
1602     return @created;
1603   } else {
1604     my ($first, @rest) = @$data;
1605
1606     my @names = grep {!ref $first->{$_}} keys %$first;
1607     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1608     my @pks = $self->result_source->primary_columns;
1609
1610     ## do the belongs_to relationships
1611     foreach my $index (0..$#$data) {
1612       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1613         my @ret = $self->populate($data);
1614         return;
1615       }
1616
1617       foreach my $rel (@rels) {
1618         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1619         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1620         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1621         my $related = $result->result_source->resolve_condition(
1622           $result->result_source->relationship_info($reverse)->{cond},
1623           $self,
1624           $result,
1625         );
1626
1627         delete $data->[$index]->{$rel};
1628         $data->[$index] = {%{$data->[$index]}, %$related};
1629
1630         push @names, keys %$related if $index == 0;
1631       }
1632     }
1633
1634     ## do bulk insert on current row
1635     my @values = map { [ @$_{@names} ] } @$data;
1636
1637     $self->result_source->storage->insert_bulk(
1638       $self->result_source,
1639       \@names,
1640       \@values,
1641     );
1642
1643     ## do the has_many relationships
1644     foreach my $item (@$data) {
1645
1646       foreach my $rel (@rels) {
1647         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1648
1649         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1650      || $self->throw_exception('Cannot find the relating object.');
1651
1652         my $child = $parent->$rel;
1653
1654         my $related = $child->result_source->resolve_condition(
1655           $parent->result_source->relationship_info($rel)->{cond},
1656           $child,
1657           $parent,
1658         );
1659
1660         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1661         my @populate = map { {%$_, %$related} } @rows_to_add;
1662
1663         $child->populate( \@populate );
1664       }
1665     }
1666   }
1667 }
1668
1669 =head2 _normalize_populate_args ($args)
1670
1671 Private method used by L</populate> to normalize its incoming arguments.  Factored
1672 out in case you want to subclass and accept new argument structures to the
1673 L</populate> method.
1674
1675 =cut
1676
1677 sub _normalize_populate_args {
1678   my ($self, $data) = @_;
1679   my @names = @{shift(@$data)};
1680   my @results_to_create;
1681   foreach my $datum (@$data) {
1682     my %result_to_create;
1683     foreach my $index (0..$#names) {
1684       $result_to_create{$names[$index]} = $$datum[$index];
1685     }
1686     push @results_to_create, \%result_to_create;
1687   }
1688   return \@results_to_create;
1689 }
1690
1691 =head2 pager
1692
1693 =over 4
1694
1695 =item Arguments: none
1696
1697 =item Return Value: $pager
1698
1699 =back
1700
1701 Return Value a L<Data::Page> object for the current resultset. Only makes
1702 sense for queries with a C<page> attribute.
1703
1704 To get the full count of entries for a paged resultset, call
1705 C<total_entries> on the L<Data::Page> object.
1706
1707 =cut
1708
1709 sub pager {
1710   my ($self) = @_;
1711
1712   return $self->{pager} if $self->{pager};
1713
1714   my $attrs = $self->{attrs};
1715   $self->throw_exception("Can't create pager for non-paged rs")
1716     unless $self->{attrs}{page};
1717   $attrs->{rows} ||= 10;
1718
1719   # throw away the paging flags and re-run the count (possibly
1720   # with a subselect) to get the real total count
1721   my $count_attrs = { %$attrs };
1722   delete $count_attrs->{$_} for qw/rows offset page pager/;
1723   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1724
1725   return $self->{pager} = Data::Page->new(
1726     $total_count,
1727     $attrs->{rows},
1728     $self->{attrs}{page}
1729   );
1730 }
1731
1732 =head2 page
1733
1734 =over 4
1735
1736 =item Arguments: $page_number
1737
1738 =item Return Value: $rs
1739
1740 =back
1741
1742 Returns a resultset for the $page_number page of the resultset on which page
1743 is called, where each page contains a number of rows equal to the 'rows'
1744 attribute set on the resultset (10 by default).
1745
1746 =cut
1747
1748 sub page {
1749   my ($self, $page) = @_;
1750   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1751 }
1752
1753 =head2 new_result
1754
1755 =over 4
1756
1757 =item Arguments: \%vals
1758
1759 =item Return Value: $rowobject
1760
1761 =back
1762
1763 Creates a new row object in the resultset's result class and returns
1764 it. The row is not inserted into the database at this point, call
1765 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1766 will tell you whether the row object has been inserted or not.
1767
1768 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1769
1770 =cut
1771
1772 sub new_result {
1773   my ($self, $values) = @_;
1774   $self->throw_exception( "new_result needs a hash" )
1775     unless (ref $values eq 'HASH');
1776
1777   my %new;
1778   my $alias = $self->{attrs}{alias};
1779
1780   if (
1781     defined $self->{cond}
1782     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1783   ) {
1784     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1785     $new{-from_resultset} = [ keys %new ] if keys %new;
1786   } else {
1787     $self->throw_exception(
1788       "Can't abstract implicit construct, condition not a hash"
1789     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1790
1791     my $collapsed_cond = (
1792       $self->{cond}
1793         ? $self->_collapse_cond($self->{cond})
1794         : {}
1795     );
1796
1797     # precendence must be given to passed values over values inherited from
1798     # the cond, so the order here is important.
1799     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1800     while( my($col,$value) = each %implied ){
1801       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1802         $new{$col} = $value->{'='};
1803         next;
1804       }
1805       $new{$col} = $value if $self->_is_deterministic_value($value);
1806     }
1807   }
1808
1809   %new = (
1810     %new,
1811     %{ $self->_remove_alias($values, $alias) },
1812     -source_handle => $self->_source_handle,
1813     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1814   );
1815
1816   return $self->result_class->new(\%new);
1817 }
1818
1819 # _is_deterministic_value
1820 #
1821 # Make an effor to strip non-deterministic values from the condition,
1822 # to make sure new_result chokes less
1823
1824 sub _is_deterministic_value {
1825   my $self = shift;
1826   my $value = shift;
1827   my $ref_type = ref $value;
1828   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1829   return 1 if Scalar::Util::blessed($value);
1830   return 0;
1831 }
1832
1833 # _has_attr
1834 #
1835 # determines if the resultset defines at least one
1836 # of the attributes supplied
1837 #
1838 # used to determine if a subquery is neccessary
1839
1840 sub _has_attr {
1841   my ($self, @attr_names) = @_;
1842
1843   my $attrs = $self->_resolved_attrs;
1844
1845   my $join_check_req;
1846
1847   for my $n (@attr_names) {
1848     return 1 if defined $attrs->{$n};
1849     ++$join_check_req if $n =~ /join/;
1850   }
1851
1852   # a join can be expressed as a multi-level from
1853   return 1 if (
1854     $join_check_req
1855       and
1856     ref $attrs->{from} eq 'ARRAY'
1857       and
1858     @{$attrs->{from}} > 1
1859   );
1860
1861   return 0;
1862 }
1863
1864 # _collapse_cond
1865 #
1866 # Recursively collapse the condition.
1867
1868 sub _collapse_cond {
1869   my ($self, $cond, $collapsed) = @_;
1870
1871   $collapsed ||= {};
1872
1873   if (ref $cond eq 'ARRAY') {
1874     foreach my $subcond (@$cond) {
1875       next unless ref $subcond;  # -or
1876       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1877     }
1878   }
1879   elsif (ref $cond eq 'HASH') {
1880     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1881       foreach my $subcond (@{$cond->{-and}}) {
1882         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1883       }
1884     }
1885     else {
1886       foreach my $col (keys %$cond) {
1887         my $value = $cond->{$col};
1888         $collapsed->{$col} = $value;
1889       }
1890     }
1891   }
1892
1893   return $collapsed;
1894 }
1895
1896 # _remove_alias
1897 #
1898 # Remove the specified alias from the specified query hash. A copy is made so
1899 # the original query is not modified.
1900
1901 sub _remove_alias {
1902   my ($self, $query, $alias) = @_;
1903
1904   my %orig = %{ $query || {} };
1905   my %unaliased;
1906
1907   foreach my $key (keys %orig) {
1908     if ($key !~ /\./) {
1909       $unaliased{$key} = $orig{$key};
1910       next;
1911     }
1912     $unaliased{$1} = $orig{$key}
1913       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1914   }
1915
1916   return \%unaliased;
1917 }
1918
1919 =head2 as_query (EXPERIMENTAL)
1920
1921 =over 4
1922
1923 =item Arguments: none
1924
1925 =item Return Value: \[ $sql, @bind ]
1926
1927 =back
1928
1929 Returns the SQL query and bind vars associated with the invocant.
1930
1931 This is generally used as the RHS for a subquery.
1932
1933 B<NOTE>: This feature is still experimental.
1934
1935 =cut
1936
1937 sub as_query { return shift->cursor->as_query(@_) }
1938
1939 =head2 find_or_new
1940
1941 =over 4
1942
1943 =item Arguments: \%vals, \%attrs?
1944
1945 =item Return Value: $rowobject
1946
1947 =back
1948
1949   my $artist = $schema->resultset('Artist')->find_or_new(
1950     { artist => 'fred' }, { key => 'artists' });
1951
1952   $cd->cd_to_producer->find_or_new({ producer => $producer },
1953                                    { key => 'primary });
1954
1955 Find an existing record from this resultset, based on its primary
1956 key, or a unique constraint. If none exists, instantiate a new result
1957 object and return it. The object will not be saved into your storage
1958 until you call L<DBIx::Class::Row/insert> on it.
1959
1960 You most likely want this method when looking for existing rows using
1961 a unique constraint that is not the primary key, or looking for
1962 related rows.
1963
1964 If you want objects to be saved immediately, use L</find_or_create> instead.
1965
1966 B<Note>: C<find_or_new> is probably not what you want when creating a
1967 new row in a table that uses primary keys supplied by the
1968 database. Passing in a primary key column with a value of I<undef>
1969 will cause L</find> to attempt to search for a row with a value of
1970 I<NULL>.
1971
1972 =cut
1973
1974 sub find_or_new {
1975   my $self     = shift;
1976   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1977   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1978   my $exists   = $self->find($hash, $attrs);
1979   return defined $exists ? $exists : $self->new_result($hash);
1980 }
1981
1982 =head2 create
1983
1984 =over 4
1985
1986 =item Arguments: \%vals
1987
1988 =item Return Value: a L<DBIx::Class::Row> $object
1989
1990 =back
1991
1992 Attempt to create a single new row or a row with multiple related rows
1993 in the table represented by the resultset (and related tables). This
1994 will not check for duplicate rows before inserting, use
1995 L</find_or_create> to do that.
1996
1997 To create one row for this resultset, pass a hashref of key/value
1998 pairs representing the columns of the table and the values you wish to
1999 store. If the appropriate relationships are set up, foreign key fields
2000 can also be passed an object representing the foreign row, and the
2001 value will be set to its primary key.
2002
2003 To create related objects, pass a hashref for the value if the related
2004 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2005 and use the name of the relationship as the key. (NOT the name of the field,
2006 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2007 of hashrefs containing the data for each of the rows to create in the foreign
2008 tables, again using the relationship name as the key.
2009
2010 Instead of hashrefs of plain related data (key/value pairs), you may
2011 also pass new or inserted objects. New objects (not inserted yet, see
2012 L</new>), will be inserted into their appropriate tables.
2013
2014 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2015
2016 Example of creating a new row.
2017
2018   $person_rs->create({
2019     name=>"Some Person",
2020     email=>"somebody@someplace.com"
2021   });
2022
2023 Example of creating a new row and also creating rows in a related C<has_many>
2024 or C<has_one> resultset.  Note Arrayref.
2025
2026   $artist_rs->create(
2027      { artistid => 4, name => 'Manufactured Crap', cds => [
2028         { title => 'My First CD', year => 2006 },
2029         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2030       ],
2031      },
2032   );
2033
2034 Example of creating a new row and also creating a row in a related
2035 C<belongs_to>resultset. Note Hashref.
2036
2037   $cd_rs->create({
2038     title=>"Music for Silly Walks",
2039     year=>2000,
2040     artist => {
2041       name=>"Silly Musician",
2042     }
2043   });
2044
2045 =cut
2046
2047 sub create {
2048   my ($self, $attrs) = @_;
2049   $self->throw_exception( "create needs a hashref" )
2050     unless ref $attrs eq 'HASH';
2051   return $self->new_result($attrs)->insert;
2052 }
2053
2054 =head2 find_or_create
2055
2056 =over 4
2057
2058 =item Arguments: \%vals, \%attrs?
2059
2060 =item Return Value: $rowobject
2061
2062 =back
2063
2064   $cd->cd_to_producer->find_or_create({ producer => $producer },
2065                                       { key => 'primary });
2066
2067 Tries to find a record based on its primary key or unique constraints; if none
2068 is found, creates one and returns that instead.
2069
2070   my $cd = $schema->resultset('CD')->find_or_create({
2071     cdid   => 5,
2072     artist => 'Massive Attack',
2073     title  => 'Mezzanine',
2074     year   => 2005,
2075   });
2076
2077 Also takes an optional C<key> attribute, to search by a specific key or unique
2078 constraint. For example:
2079
2080   my $cd = $schema->resultset('CD')->find_or_create(
2081     {
2082       artist => 'Massive Attack',
2083       title  => 'Mezzanine',
2084     },
2085     { key => 'cd_artist_title' }
2086   );
2087
2088 B<Note>: Because find_or_create() reads from the database and then
2089 possibly inserts based on the result, this method is subject to a race
2090 condition. Another process could create a record in the table after
2091 the find has completed and before the create has started. To avoid
2092 this problem, use find_or_create() inside a transaction.
2093
2094 B<Note>: C<find_or_create> is probably not what you want when creating
2095 a new row in a table that uses primary keys supplied by the
2096 database. Passing in a primary key column with a value of I<undef>
2097 will cause L</find> to attempt to search for a row with a value of
2098 I<NULL>.
2099
2100 See also L</find> and L</update_or_create>. For information on how to declare
2101 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2102
2103 =cut
2104
2105 sub find_or_create {
2106   my $self     = shift;
2107   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2108   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2109   my $exists   = $self->find($hash, $attrs);
2110   return defined $exists ? $exists : $self->create($hash);
2111 }
2112
2113 =head2 update_or_create
2114
2115 =over 4
2116
2117 =item Arguments: \%col_values, { key => $unique_constraint }?
2118
2119 =item Return Value: $rowobject
2120
2121 =back
2122
2123   $resultset->update_or_create({ col => $val, ... });
2124
2125 First, searches for an existing row matching one of the unique constraints
2126 (including the primary key) on the source of this resultset. If a row is
2127 found, updates it with the other given column values. Otherwise, creates a new
2128 row.
2129
2130 Takes an optional C<key> attribute to search on a specific unique constraint.
2131 For example:
2132
2133   # In your application
2134   my $cd = $schema->resultset('CD')->update_or_create(
2135     {
2136       artist => 'Massive Attack',
2137       title  => 'Mezzanine',
2138       year   => 1998,
2139     },
2140     { key => 'cd_artist_title' }
2141   );
2142
2143   $cd->cd_to_producer->update_or_create({
2144     producer => $producer,
2145     name => 'harry',
2146   }, {
2147     key => 'primary,
2148   });
2149
2150
2151 If no C<key> is specified, it searches on all unique constraints defined on the
2152 source, including the primary key.
2153
2154 If the C<key> is specified as C<primary>, it searches only on the primary key.
2155
2156 See also L</find> and L</find_or_create>. For information on how to declare
2157 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2158
2159 B<Note>: C<update_or_create> is probably not what you want when
2160 looking for a row in a table that uses primary keys supplied by the
2161 database, unless you actually have a key value. Passing in a primary
2162 key column with a value of I<undef> will cause L</find> to attempt to
2163 search for a row with a value of I<NULL>.
2164
2165 =cut
2166
2167 sub update_or_create {
2168   my $self = shift;
2169   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2170   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2171
2172   my $row = $self->find($cond, $attrs);
2173   if (defined $row) {
2174     $row->update($cond);
2175     return $row;
2176   }
2177
2178   return $self->create($cond);
2179 }
2180
2181 =head2 update_or_new
2182
2183 =over 4
2184
2185 =item Arguments: \%col_values, { key => $unique_constraint }?
2186
2187 =item Return Value: $rowobject
2188
2189 =back
2190
2191   $resultset->update_or_new({ col => $val, ... });
2192
2193 First, searches for an existing row matching one of the unique constraints
2194 (including the primary key) on the source of this resultset. If a row is
2195 found, updates it with the other given column values. Otherwise, instantiate
2196 a new result object and return it. The object will not be saved into your storage
2197 until you call L<DBIx::Class::Row/insert> on it.
2198
2199 Takes an optional C<key> attribute to search on a specific unique constraint.
2200 For example:
2201
2202   # In your application
2203   my $cd = $schema->resultset('CD')->update_or_new(
2204     {
2205       artist => 'Massive Attack',
2206       title  => 'Mezzanine',
2207       year   => 1998,
2208     },
2209     { key => 'cd_artist_title' }
2210   );
2211
2212   if ($cd->in_storage) {
2213       # the cd was updated
2214   }
2215   else {
2216       # the cd is not yet in the database, let's insert it
2217       $cd->insert;
2218   }
2219
2220 See also L</find>, L</find_or_create> and L<find_or_new>.
2221
2222 =cut
2223
2224 sub update_or_new {
2225     my $self  = shift;
2226     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2227     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2228
2229     my $row = $self->find( $cond, $attrs );
2230     if ( defined $row ) {
2231         $row->update($cond);
2232         return $row;
2233     }
2234
2235     return $self->new_result($cond);
2236 }
2237
2238 =head2 get_cache
2239
2240 =over 4
2241
2242 =item Arguments: none
2243
2244 =item Return Value: \@cache_objects?
2245
2246 =back
2247
2248 Gets the contents of the cache for the resultset, if the cache is set.
2249
2250 The cache is populated either by using the L</prefetch> attribute to
2251 L</search> or by calling L</set_cache>.
2252
2253 =cut
2254
2255 sub get_cache {
2256   shift->{all_cache};
2257 }
2258
2259 =head2 set_cache
2260
2261 =over 4
2262
2263 =item Arguments: \@cache_objects
2264
2265 =item Return Value: \@cache_objects
2266
2267 =back
2268
2269 Sets the contents of the cache for the resultset. Expects an arrayref
2270 of objects of the same class as those produced by the resultset. Note that
2271 if the cache is set the resultset will return the cached objects rather
2272 than re-querying the database even if the cache attr is not set.
2273
2274 The contents of the cache can also be populated by using the
2275 L</prefetch> attribute to L</search>.
2276
2277 =cut
2278
2279 sub set_cache {
2280   my ( $self, $data ) = @_;
2281   $self->throw_exception("set_cache requires an arrayref")
2282       if defined($data) && (ref $data ne 'ARRAY');
2283   $self->{all_cache} = $data;
2284 }
2285
2286 =head2 clear_cache
2287
2288 =over 4
2289
2290 =item Arguments: none
2291
2292 =item Return Value: []
2293
2294 =back
2295
2296 Clears the cache for the resultset.
2297
2298 =cut
2299
2300 sub clear_cache {
2301   shift->set_cache(undef);
2302 }
2303
2304 =head2 related_resultset
2305
2306 =over 4
2307
2308 =item Arguments: $relationship_name
2309
2310 =item Return Value: $resultset
2311
2312 =back
2313
2314 Returns a related resultset for the supplied relationship name.
2315
2316   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2317
2318 =cut
2319
2320 sub related_resultset {
2321   my ($self, $rel) = @_;
2322
2323   $self->{related_resultsets} ||= {};
2324   return $self->{related_resultsets}{$rel} ||= do {
2325     my $rel_obj = $self->result_source->relationship_info($rel);
2326
2327     $self->throw_exception(
2328       "search_related: result source '" . $self->result_source->source_name .
2329         "' has no such relationship $rel")
2330       unless $rel_obj;
2331
2332     my ($from,$seen) = $self->_resolve_from($rel);
2333
2334     my $join_count = $seen->{$rel};
2335     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2336
2337     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2338     my %attrs = %{$self->{attrs}||{}};
2339     delete @attrs{qw(result_class alias)};
2340
2341     my $new_cache;
2342
2343     if (my $cache = $self->get_cache) {
2344       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2345         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2346                         @$cache ];
2347       }
2348     }
2349
2350     my $rel_source = $self->result_source->related_source($rel);
2351
2352     my $new = do {
2353
2354       # The reason we do this now instead of passing the alias to the
2355       # search_rs below is that if you wrap/overload resultset on the
2356       # source you need to know what alias it's -going- to have for things
2357       # to work sanely (e.g. RestrictWithObject wants to be able to add
2358       # extra query restrictions, and these may need to be $alias.)
2359
2360       my $attrs = $rel_source->resultset_attributes;
2361       local $attrs->{alias} = $alias;
2362
2363       $rel_source->resultset
2364                  ->search_rs(
2365                      undef, {
2366                        %attrs,
2367                        join => undef,
2368                        prefetch => undef,
2369                        select => undef,
2370                        as => undef,
2371                        where => $self->{cond},
2372                        seen_join => $seen,
2373                        from => $from,
2374                    });
2375     };
2376     $new->set_cache($new_cache) if $new_cache;
2377     $new;
2378   };
2379 }
2380
2381 =head2 current_source_alias
2382
2383 =over 4
2384
2385 =item Arguments: none
2386
2387 =item Return Value: $source_alias
2388
2389 =back
2390
2391 Returns the current table alias for the result source this resultset is built
2392 on, that will be used in the SQL query. Usually it is C<me>.
2393
2394 Currently the source alias that refers to the result set returned by a
2395 L</search>/L</find> family method depends on how you got to the resultset: it's
2396 C<me> by default, but eg. L</search_related> aliases it to the related result
2397 source name (and keeps C<me> referring to the original result set). The long
2398 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2399 (and make this method unnecessary).
2400
2401 Thus it's currently necessary to use this method in predefined queries (see
2402 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2403 source alias of the current result set:
2404
2405   # in a result set class
2406   sub modified_by {
2407     my ($self, $user) = @_;
2408
2409     my $me = $self->current_source_alias;
2410
2411     return $self->search(
2412       "$me.modified" => $user->id,
2413     );
2414   }
2415
2416 =cut
2417
2418 sub current_source_alias {
2419   my ($self) = @_;
2420
2421   return ($self->{attrs} || {})->{alias} || 'me';
2422 }
2423
2424 # This code is called by search_related, and makes sure there
2425 # is clear separation between the joins before, during, and
2426 # after the relationship. This information is needed later
2427 # in order to properly resolve prefetch aliases (any alias
2428 # with a relation_chain_depth less than the depth of the
2429 # current prefetch is not considered)
2430 sub _resolve_from {
2431   my ($self, $extra_join) = @_;
2432   my $source = $self->result_source;
2433   my $attrs = $self->{attrs};
2434
2435   my $from = $attrs->{from}
2436     || [ { $attrs->{alias} => $source->from } ];
2437
2438   my $seen = { %{$attrs->{seen_join}||{}} };
2439
2440   # we need to take the prefetch the attrs into account before we
2441   # ->resolve_join as otherwise they get lost - captainL
2442   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2443
2444   push @$from, $source->resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2445
2446   ++$seen->{-relation_chain_depth};
2447
2448   push @$from, $source->resolve_join($extra_join, $attrs->{alias}, $seen);
2449
2450   ++$seen->{-relation_chain_depth};
2451
2452   return ($from,$seen);
2453 }
2454
2455 sub _resolved_attrs {
2456   my $self = shift;
2457   return $self->{_attrs} if $self->{_attrs};
2458
2459   my $attrs  = { %{ $self->{attrs} || {} } };
2460   my $source = $self->result_source;
2461   my $alias  = $attrs->{alias};
2462
2463   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2464   my @colbits;
2465
2466   # build columns (as long as select isn't set) into a set of as/select hashes
2467   unless ( $attrs->{select} ) {
2468       @colbits = map {
2469           ( ref($_) eq 'HASH' )
2470               ? $_
2471               : {
2472                   (
2473                     /^\Q${alias}.\E(.+)$/
2474                       ? "$1"
2475                       : "$_"
2476                   )
2477                 =>
2478                   (
2479                     /\./
2480                       ? "$_"
2481                       : "${alias}.$_"
2482                   )
2483             }
2484       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2485   }
2486   # add the additional columns on
2487   foreach ( 'include_columns', '+columns' ) {
2488       push @colbits, map {
2489           ( ref($_) eq 'HASH' )
2490             ? $_
2491             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2492       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2493   }
2494
2495   # start with initial select items
2496   if ( $attrs->{select} ) {
2497     $attrs->{select} =
2498         ( ref $attrs->{select} eq 'ARRAY' )
2499       ? [ @{ $attrs->{select} } ]
2500       : [ $attrs->{select} ];
2501     $attrs->{as} = (
2502       $attrs->{as}
2503       ? (
2504         ref $attrs->{as} eq 'ARRAY'
2505         ? [ @{ $attrs->{as} } ]
2506         : [ $attrs->{as} ]
2507         )
2508       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2509     );
2510   }
2511   else {
2512
2513     # otherwise we intialise select & as to empty
2514     $attrs->{select} = [];
2515     $attrs->{as}     = [];
2516   }
2517
2518   # now add colbits to select/as
2519   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2520   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2521
2522   my $adds;
2523   if ( $adds = delete $attrs->{'+select'} ) {
2524     $adds = [$adds] unless ref $adds eq 'ARRAY';
2525     push(
2526       @{ $attrs->{select} },
2527       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2528     );
2529   }
2530   if ( $adds = delete $attrs->{'+as'} ) {
2531     $adds = [$adds] unless ref $adds eq 'ARRAY';
2532     push( @{ $attrs->{as} }, @$adds );
2533   }
2534
2535   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2536
2537   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2538     my $join = delete $attrs->{join} || {};
2539
2540     if ( defined $attrs->{prefetch} ) {
2541       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2542
2543     }
2544
2545     $attrs->{from} =    # have to copy here to avoid corrupting the original
2546       [
2547       @{ $attrs->{from} },
2548       $source->resolve_join(
2549         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2550       )
2551       ];
2552
2553   }
2554
2555   $attrs->{group_by} ||= $attrs->{select}
2556     if delete $attrs->{distinct};
2557   if ( $attrs->{order_by} ) {
2558     $attrs->{order_by} = (
2559       ref( $attrs->{order_by} ) eq 'ARRAY'
2560       ? [ @{ $attrs->{order_by} } ]
2561       : [ $attrs->{order_by} ]
2562     );
2563   }
2564   else {
2565     $attrs->{order_by} = [];
2566   }
2567
2568   my $collapse = $attrs->{collapse} || {};
2569   if ( my $prefetch = delete $attrs->{prefetch} ) {
2570     $prefetch = $self->_merge_attr( {}, $prefetch );
2571     my @pre_order;
2572     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2573
2574       # bring joins back to level of current class
2575       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2576       my @prefetch =
2577         $source->resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2578       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2579       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2580     }
2581     push( @{ $attrs->{order_by} }, @pre_order );
2582   }
2583   $attrs->{collapse} = $collapse;
2584
2585   if ( $attrs->{page} ) {
2586     $attrs->{offset} ||= 0;
2587     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2588   }
2589
2590   return $self->{_attrs} = $attrs;
2591 }
2592
2593 sub _joinpath_aliases {
2594   my ($self, $fromspec, $seen) = @_;
2595
2596   my $paths = {};
2597   return $paths unless ref $fromspec eq 'ARRAY';
2598
2599   for my $j (@$fromspec) {
2600
2601     next if ref $j ne 'ARRAY';
2602     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2603
2604     my $p = $paths;
2605     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2606     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2607   }
2608
2609   return $paths;
2610 }
2611
2612 sub _rollout_attr {
2613   my ($self, $attr) = @_;
2614
2615   if (ref $attr eq 'HASH') {
2616     return $self->_rollout_hash($attr);
2617   } elsif (ref $attr eq 'ARRAY') {
2618     return $self->_rollout_array($attr);
2619   } else {
2620     return [$attr];
2621   }
2622 }
2623
2624 sub _rollout_array {
2625   my ($self, $attr) = @_;
2626
2627   my @rolled_array;
2628   foreach my $element (@{$attr}) {
2629     if (ref $element eq 'HASH') {
2630       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2631     } elsif (ref $element eq 'ARRAY') {
2632       #  XXX - should probably recurse here
2633       push( @rolled_array, @{$self->_rollout_array($element)} );
2634     } else {
2635       push( @rolled_array, $element );
2636     }
2637   }
2638   return \@rolled_array;
2639 }
2640
2641 sub _rollout_hash {
2642   my ($self, $attr) = @_;
2643
2644   my @rolled_array;
2645   foreach my $key (keys %{$attr}) {
2646     push( @rolled_array, { $key => $attr->{$key} } );
2647   }
2648   return \@rolled_array;
2649 }
2650
2651 sub _calculate_score {
2652   my ($self, $a, $b) = @_;
2653
2654   if (ref $b eq 'HASH') {
2655     my ($b_key) = keys %{$b};
2656     if (ref $a eq 'HASH') {
2657       my ($a_key) = keys %{$a};
2658       if ($a_key eq $b_key) {
2659         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2660       } else {
2661         return 0;
2662       }
2663     } else {
2664       return ($a eq $b_key) ? 1 : 0;
2665     }
2666   } else {
2667     if (ref $a eq 'HASH') {
2668       my ($a_key) = keys %{$a};
2669       return ($b eq $a_key) ? 1 : 0;
2670     } else {
2671       return ($b eq $a) ? 1 : 0;
2672     }
2673   }
2674 }
2675
2676 sub _merge_attr {
2677   my ($self, $orig, $import) = @_;
2678
2679   return $import unless defined($orig);
2680   return $orig unless defined($import);
2681
2682   $orig = $self->_rollout_attr($orig);
2683   $import = $self->_rollout_attr($import);
2684
2685   my $seen_keys;
2686   foreach my $import_element ( @{$import} ) {
2687     # find best candidate from $orig to merge $b_element into
2688     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2689     foreach my $orig_element ( @{$orig} ) {
2690       my $score = $self->_calculate_score( $orig_element, $import_element );
2691       if ($score > $best_candidate->{score}) {
2692         $best_candidate->{position} = $position;
2693         $best_candidate->{score} = $score;
2694       }
2695       $position++;
2696     }
2697     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2698
2699     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2700       push( @{$orig}, $import_element );
2701     } else {
2702       my $orig_best = $orig->[$best_candidate->{position}];
2703       # merge orig_best and b_element together and replace original with merged
2704       if (ref $orig_best ne 'HASH') {
2705         $orig->[$best_candidate->{position}] = $import_element;
2706       } elsif (ref $import_element eq 'HASH') {
2707         my ($key) = keys %{$orig_best};
2708         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2709       }
2710     }
2711     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2712   }
2713
2714   return $orig;
2715 }
2716
2717 sub result_source {
2718     my $self = shift;
2719
2720     if (@_) {
2721         $self->_source_handle($_[0]->handle);
2722     } else {
2723         $self->_source_handle->resolve;
2724     }
2725 }
2726
2727 =head2 throw_exception
2728
2729 See L<DBIx::Class::Schema/throw_exception> for details.
2730
2731 =cut
2732
2733 sub throw_exception {
2734   my $self=shift;
2735   if (ref $self && $self->_source_handle->schema) {
2736     $self->_source_handle->schema->throw_exception(@_)
2737   } else {
2738     croak(@_);
2739   }
2740
2741 }
2742
2743 # XXX: FIXME: Attributes docs need clearing up
2744
2745 =head1 ATTRIBUTES
2746
2747 Attributes are used to refine a ResultSet in various ways when
2748 searching for data. They can be passed to any method which takes an
2749 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2750 L</count>.
2751
2752 These are in no particular order:
2753
2754 =head2 order_by
2755
2756 =over 4
2757
2758 =item Value: ( $order_by | \@order_by | \%order_by )
2759
2760 =back
2761
2762 Which column(s) to order the results by. If a single column name, or
2763 an arrayref of names is supplied, the argument is passed through
2764 directly to SQL. The hashref syntax allows for connection-agnostic
2765 specification of ordering direction:
2766
2767  For descending order:
2768
2769   order_by => { -desc => [qw/col1 col2 col3/] }
2770
2771  For explicit ascending order:
2772
2773   order_by => { -asc => 'col' }
2774
2775 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2776 supported, although you are strongly encouraged to use the hashref
2777 syntax as outlined above.
2778
2779 =head2 columns
2780
2781 =over 4
2782
2783 =item Value: \@columns
2784
2785 =back
2786
2787 Shortcut to request a particular set of columns to be retrieved. Each
2788 column spec may be a string (a table column name), or a hash (in which
2789 case the key is the C<as> value, and the value is used as the C<select>
2790 expression). Adds C<me.> onto the start of any column without a C<.> in
2791 it and sets C<select> from that, then auto-populates C<as> from
2792 C<select> as normal. (You may also use the C<cols> attribute, as in
2793 earlier versions of DBIC.)
2794
2795 =head2 +columns
2796
2797 =over 4
2798
2799 =item Value: \@columns
2800
2801 =back
2802
2803 Indicates additional columns to be selected from storage. Works the same
2804 as L</columns> but adds columns to the selection. (You may also use the
2805 C<include_columns> attribute, as in earlier versions of DBIC). For
2806 example:-
2807
2808   $schema->resultset('CD')->search(undef, {
2809     '+columns' => ['artist.name'],
2810     join => ['artist']
2811   });
2812
2813 would return all CDs and include a 'name' column to the information
2814 passed to object inflation. Note that the 'artist' is the name of the
2815 column (or relationship) accessor, and 'name' is the name of the column
2816 accessor in the related table.
2817
2818 =head2 include_columns
2819
2820 =over 4
2821
2822 =item Value: \@columns
2823
2824 =back
2825
2826 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2827
2828 =head2 select
2829
2830 =over 4
2831
2832 =item Value: \@select_columns
2833
2834 =back
2835
2836 Indicates which columns should be selected from the storage. You can use
2837 column names, or in the case of RDBMS back ends, function or stored procedure
2838 names:
2839
2840   $rs = $schema->resultset('Employee')->search(undef, {
2841     select => [
2842       'name',
2843       { count => 'employeeid' },
2844       { sum => 'salary' }
2845     ]
2846   });
2847
2848 When you use function/stored procedure names and do not supply an C<as>
2849 attribute, the column names returned are storage-dependent. E.g. MySQL would
2850 return a column named C<count(employeeid)> in the above example.
2851
2852 =head2 +select
2853
2854 =over 4
2855
2856 Indicates additional columns to be selected from storage.  Works the same as
2857 L</select> but adds columns to the selection.
2858
2859 =back
2860
2861 =head2 +as
2862
2863 =over 4
2864
2865 Indicates additional column names for those added via L</+select>. See L</as>.
2866
2867 =back
2868
2869 =head2 as
2870
2871 =over 4
2872
2873 =item Value: \@inflation_names
2874
2875 =back
2876
2877 Indicates column names for object inflation. That is, C<as>
2878 indicates the name that the column can be accessed as via the
2879 C<get_column> method (or via the object accessor, B<if one already
2880 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2881
2882 The C<as> attribute is used in conjunction with C<select>,
2883 usually when C<select> contains one or more function or stored
2884 procedure names:
2885
2886   $rs = $schema->resultset('Employee')->search(undef, {
2887     select => [
2888       'name',
2889       { count => 'employeeid' }
2890     ],
2891     as => ['name', 'employee_count'],
2892   });
2893
2894   my $employee = $rs->first(); # get the first Employee
2895
2896 If the object against which the search is performed already has an accessor
2897 matching a column name specified in C<as>, the value can be retrieved using
2898 the accessor as normal:
2899
2900   my $name = $employee->name();
2901
2902 If on the other hand an accessor does not exist in the object, you need to
2903 use C<get_column> instead:
2904
2905   my $employee_count = $employee->get_column('employee_count');
2906
2907 You can create your own accessors if required - see
2908 L<DBIx::Class::Manual::Cookbook> for details.
2909
2910 Please note: This will NOT insert an C<AS employee_count> into the SQL
2911 statement produced, it is used for internal access only. Thus
2912 attempting to use the accessor in an C<order_by> clause or similar
2913 will fail miserably.
2914
2915 To get around this limitation, you can supply literal SQL to your
2916 C<select> attibute that contains the C<AS alias> text, eg:
2917
2918   select => [\'myfield AS alias']
2919
2920 =head2 join
2921
2922 =over 4
2923
2924 =item Value: ($rel_name | \@rel_names | \%rel_names)
2925
2926 =back
2927
2928 Contains a list of relationships that should be joined for this query.  For
2929 example:
2930
2931   # Get CDs by Nine Inch Nails
2932   my $rs = $schema->resultset('CD')->search(
2933     { 'artist.name' => 'Nine Inch Nails' },
2934     { join => 'artist' }
2935   );
2936
2937 Can also contain a hash reference to refer to the other relation's relations.
2938 For example:
2939
2940   package MyApp::Schema::Track;
2941   use base qw/DBIx::Class/;
2942   __PACKAGE__->table('track');
2943   __PACKAGE__->add_columns(qw/trackid cd position title/);
2944   __PACKAGE__->set_primary_key('trackid');
2945   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2946   1;
2947
2948   # In your application
2949   my $rs = $schema->resultset('Artist')->search(
2950     { 'track.title' => 'Teardrop' },
2951     {
2952       join     => { cd => 'track' },
2953       order_by => 'artist.name',
2954     }
2955   );
2956
2957 You need to use the relationship (not the table) name in  conditions,
2958 because they are aliased as such. The current table is aliased as "me", so
2959 you need to use me.column_name in order to avoid ambiguity. For example:
2960
2961   # Get CDs from 1984 with a 'Foo' track
2962   my $rs = $schema->resultset('CD')->search(
2963     {
2964       'me.year' => 1984,
2965       'tracks.name' => 'Foo'
2966     },
2967     { join => 'tracks' }
2968   );
2969
2970 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2971 similarly for a third time). For e.g.
2972
2973   my $rs = $schema->resultset('Artist')->search({
2974     'cds.title'   => 'Down to Earth',
2975     'cds_2.title' => 'Popular',
2976   }, {
2977     join => [ qw/cds cds/ ],
2978   });
2979
2980 will return a set of all artists that have both a cd with title 'Down
2981 to Earth' and a cd with title 'Popular'.
2982
2983 If you want to fetch related objects from other tables as well, see C<prefetch>
2984 below.
2985
2986 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2987
2988 =head2 prefetch
2989
2990 =over 4
2991
2992 =item Value: ($rel_name | \@rel_names | \%rel_names)
2993
2994 =back
2995
2996 Contains one or more relationships that should be fetched along with
2997 the main query (when they are accessed afterwards the data will
2998 already be available, without extra queries to the database).  This is
2999 useful for when you know you will need the related objects, because it
3000 saves at least one query:
3001
3002   my $rs = $schema->resultset('Tag')->search(
3003     undef,
3004     {
3005       prefetch => {
3006         cd => 'artist'
3007       }
3008     }
3009   );
3010
3011 The initial search results in SQL like the following:
3012
3013   SELECT tag.*, cd.*, artist.* FROM tag
3014   JOIN cd ON tag.cd = cd.cdid
3015   JOIN artist ON cd.artist = artist.artistid
3016
3017 L<DBIx::Class> has no need to go back to the database when we access the
3018 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3019 case.
3020
3021 Simple prefetches will be joined automatically, so there is no need
3022 for a C<join> attribute in the above search.
3023
3024 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3025 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3026 with an accessor type of 'single' or 'filter'). A more complex example that
3027 prefetches an artists cds, the tracks on those cds, and the tags associted
3028 with that artist is given below (assuming many-to-many from artists to tags):
3029
3030  my $rs = $schema->resultset('Artist')->search(
3031    undef,
3032    {
3033      prefetch => [
3034        { cds => 'tracks' },
3035        { artist_tags => 'tags' }
3036      ]
3037    }
3038  );
3039
3040
3041 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3042 attributes will be ignored.
3043
3044 =head2 page
3045
3046 =over 4
3047
3048 =item Value: $page
3049
3050 =back
3051
3052 Makes the resultset paged and specifies the page to retrieve. Effectively
3053 identical to creating a non-pages resultset and then calling ->page($page)
3054 on it.
3055
3056 If L<rows> attribute is not specified it defualts to 10 rows per page.
3057
3058 When you have a paged resultset, L</count> will only return the number
3059 of rows in the page. To get the total, use the L</pager> and call
3060 C<total_entries> on it.
3061
3062 =head2 rows
3063
3064 =over 4
3065
3066 =item Value: $rows
3067
3068 =back
3069
3070 Specifes the maximum number of rows for direct retrieval or the number of
3071 rows per page if the page attribute or method is used.
3072
3073 =head2 offset
3074
3075 =over 4
3076
3077 =item Value: $offset
3078
3079 =back
3080
3081 Specifies the (zero-based) row number for the  first row to be returned, or the
3082 of the first row of the first page if paging is used.
3083
3084 =head2 group_by
3085
3086 =over 4
3087
3088 =item Value: \@columns
3089
3090 =back
3091
3092 A arrayref of columns to group by. Can include columns of joined tables.
3093
3094   group_by => [qw/ column1 column2 ... /]
3095
3096 =head2 having
3097
3098 =over 4
3099
3100 =item Value: $condition
3101
3102 =back
3103
3104 HAVING is a select statement attribute that is applied between GROUP BY and
3105 ORDER BY. It is applied to the after the grouping calculations have been
3106 done.
3107
3108   having => { 'count(employee)' => { '>=', 100 } }
3109
3110 =head2 distinct
3111
3112 =over 4
3113
3114 =item Value: (0 | 1)
3115
3116 =back
3117
3118 Set to 1 to group by all columns.
3119
3120 =head2 where
3121
3122 =over 4
3123
3124 Adds to the WHERE clause.
3125
3126   # only return rows WHERE deleted IS NULL for all searches
3127   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3128
3129 Can be overridden by passing C<{ where => undef }> as an attribute
3130 to a resulset.
3131
3132 =back
3133
3134 =head2 cache
3135
3136 Set to 1 to cache search results. This prevents extra SQL queries if you
3137 revisit rows in your ResultSet:
3138
3139   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3140
3141   while( my $artist = $resultset->next ) {
3142     ... do stuff ...
3143   }
3144
3145   $rs->first; # without cache, this would issue a query
3146
3147 By default, searches are not cached.
3148
3149 For more examples of using these attributes, see
3150 L<DBIx::Class::Manual::Cookbook>.
3151
3152 =head2 from
3153
3154 =over 4
3155
3156 =item Value: \@from_clause
3157
3158 =back
3159
3160 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3161 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3162 clauses.
3163
3164 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3165
3166 C<join> will usually do what you need and it is strongly recommended that you
3167 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3168 And we really do mean "cannot", not just tried and failed. Attempting to use
3169 this because you're having problems with C<join> is like trying to use x86
3170 ASM because you've got a syntax error in your C. Trust us on this.
3171
3172 Now, if you're still really, really sure you need to use this (and if you're
3173 not 100% sure, ask the mailing list first), here's an explanation of how this
3174 works.
3175
3176 The syntax is as follows -
3177
3178   [
3179     { <alias1> => <table1> },
3180     [
3181       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3182       [], # nested JOIN (optional)
3183       { <table1.column1> => <table2.column2>, ... (more conditions) },
3184     ],
3185     # More of the above [ ] may follow for additional joins
3186   ]
3187
3188   <table1> <alias1>
3189   JOIN
3190     <table2> <alias2>
3191     [JOIN ...]
3192   ON <table1.column1> = <table2.column2>
3193   <more joins may follow>
3194
3195 An easy way to follow the examples below is to remember the following:
3196
3197     Anything inside "[]" is a JOIN
3198     Anything inside "{}" is a condition for the enclosing JOIN
3199
3200 The following examples utilize a "person" table in a family tree application.
3201 In order to express parent->child relationships, this table is self-joined:
3202
3203     # Person->belongs_to('father' => 'Person');
3204     # Person->belongs_to('mother' => 'Person');
3205
3206 C<from> can be used to nest joins. Here we return all children with a father,
3207 then search against all mothers of those children:
3208
3209   $rs = $schema->resultset('Person')->search(
3210       undef,
3211       {
3212           alias => 'mother', # alias columns in accordance with "from"
3213           from => [
3214               { mother => 'person' },
3215               [
3216                   [
3217                       { child => 'person' },
3218                       [
3219                           { father => 'person' },
3220                           { 'father.person_id' => 'child.father_id' }
3221                       ]
3222                   ],
3223                   { 'mother.person_id' => 'child.mother_id' }
3224               ],
3225           ]
3226       },
3227   );
3228
3229   # Equivalent SQL:
3230   # SELECT mother.* FROM person mother
3231   # JOIN (
3232   #   person child
3233   #   JOIN person father
3234   #   ON ( father.person_id = child.father_id )
3235   # )
3236   # ON ( mother.person_id = child.mother_id )
3237
3238 The type of any join can be controlled manually. To search against only people
3239 with a father in the person table, we could explicitly use C<INNER JOIN>:
3240
3241     $rs = $schema->resultset('Person')->search(
3242         undef,
3243         {
3244             alias => 'child', # alias columns in accordance with "from"
3245             from => [
3246                 { child => 'person' },
3247                 [
3248                     { father => 'person', -join_type => 'inner' },
3249                     { 'father.id' => 'child.father_id' }
3250                 ],
3251             ]
3252         },
3253     );
3254
3255     # Equivalent SQL:
3256     # SELECT child.* FROM person child
3257     # INNER JOIN person father ON child.father_id = father.id
3258
3259 If you need to express really complex joins or you need a subselect, you
3260 can supply literal SQL to C<from> via a scalar reference. In this case
3261 the contents of the scalar will replace the table name asscoiated with the
3262 resultsource.
3263
3264 WARNING: This technique might very well not work as expected on chained
3265 searches - you have been warned.
3266
3267     # Assuming the Event resultsource is defined as:
3268
3269         MySchema::Event->add_columns (
3270             sequence => {
3271                 data_type => 'INT',
3272                 is_auto_increment => 1,
3273             },
3274             location => {
3275                 data_type => 'INT',
3276             },
3277             type => {
3278                 data_type => 'INT',
3279             },
3280         );
3281         MySchema::Event->set_primary_key ('sequence');
3282
3283     # This will get back the latest event for every location. The column
3284     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3285     # combo to limit the resultset
3286
3287     $rs = $schema->resultset('Event');
3288     $table = $rs->result_source->name;
3289     $latest = $rs->search (
3290         undef,
3291         { from => \ "
3292             (SELECT e1.* FROM $table e1
3293                 JOIN $table e2
3294                     ON e1.location = e2.location
3295                     AND e1.sequence < e2.sequence
3296                 WHERE e2.sequence is NULL
3297             ) me",
3298         },
3299     );
3300
3301     # Equivalent SQL (with the DBIC chunks added):
3302
3303     SELECT me.sequence, me.location, me.type FROM
3304        (SELECT e1.* FROM events e1
3305            JOIN events e2
3306                ON e1.location = e2.location
3307                AND e1.sequence < e2.sequence
3308            WHERE e2.sequence is NULL
3309        ) me;
3310
3311 =head2 for
3312
3313 =over 4
3314
3315 =item Value: ( 'update' | 'shared' )
3316
3317 =back
3318
3319 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3320 ... FOR SHARED.
3321
3322 =cut
3323
3324 1;