lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->_resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my @subq_attrs = qw/prefetch collapse group_by having having_bind/;
1159
1160   # if we are not paged - we are simply asking for a limit
1161   if (not $self->{attrs}{page} and not $self->{attrs}{software_limit}) {
1162     push @subq_attrs, qw/rows offset/;
1163   }
1164
1165   return $self->_has_attr (@subq_attrs)
1166     ? $self->_count_subq
1167     : $self->_count_simple
1168 }
1169
1170 sub _count_subq {
1171   my $self = shift;
1172
1173   my $attrs = { %{$self->_resolved_attrs} };
1174
1175   # copy for the subquery, we need to do some adjustments to it too
1176   my $sub_attrs = { %$attrs };
1177
1178   # these can not go in the subquery either
1179   delete $sub_attrs->{$_} for qw/prefetch select +select as +as columns +columns/;
1180
1181   # force a group_by and the same set of columns (most databases require this)
1182   $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1183
1184   $attrs->{from} = [{
1185     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1186   }];
1187
1188   # the subquery replaces this
1189   delete $attrs->{$_} for qw/where bind prefetch collapse group_by having/;
1190
1191   return $self->__count ($attrs);
1192 }
1193
1194 sub _count_simple {
1195   my $self = shift;
1196
1197   my $count = $self->__count;
1198   return 0 unless $count;
1199
1200   # need to take offset from resolved attrs
1201
1202   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1203   $count = $self->{attrs}{rows} if
1204     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1205   $count = 0 if ($count < 0);
1206   return $count;
1207 }
1208
1209 sub __count {
1210   my ($self, $attrs) = @_;
1211
1212   $attrs ||= { %{$self->{attrs}} };
1213
1214   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1215   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1216
1217   $attrs->{select} = { count => '*' };
1218   $attrs->{as} = [qw/count/];
1219
1220   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1221   my ($count) = $tmp_rs->cursor->next;
1222
1223   return $count;
1224 }
1225
1226 sub _bool {
1227   return 1;
1228 }
1229
1230 =head2 count_literal
1231
1232 =over 4
1233
1234 =item Arguments: $sql_fragment, @bind_values
1235
1236 =item Return Value: $count
1237
1238 =back
1239
1240 Counts the results in a literal query. Equivalent to calling L</search_literal>
1241 with the passed arguments, then L</count>.
1242
1243 =cut
1244
1245 sub count_literal { shift->search_literal(@_)->count; }
1246
1247 =head2 all
1248
1249 =over 4
1250
1251 =item Arguments: none
1252
1253 =item Return Value: @objects
1254
1255 =back
1256
1257 Returns all elements in the resultset. Called implicitly if the resultset
1258 is returned in list context.
1259
1260 =cut
1261
1262 sub all {
1263   my $self = shift;
1264   if(@_) {
1265       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1266   }
1267
1268   return @{ $self->get_cache } if $self->get_cache;
1269
1270   my @obj;
1271
1272   # TODO: don't call resolve here
1273   if (keys %{$self->_resolved_attrs->{collapse}}) {
1274 #  if ($self->{attrs}{prefetch}) {
1275       # Using $self->cursor->all is really just an optimisation.
1276       # If we're collapsing has_many prefetches it probably makes
1277       # very little difference, and this is cleaner than hacking
1278       # _construct_object to survive the approach
1279     my @row = $self->cursor->next;
1280     while (@row) {
1281       push(@obj, $self->_construct_object(@row));
1282       @row = (exists $self->{stashed_row}
1283                ? @{delete $self->{stashed_row}}
1284                : $self->cursor->next);
1285     }
1286   } else {
1287     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1288   }
1289
1290   $self->set_cache(\@obj) if $self->{attrs}{cache};
1291   return @obj;
1292 }
1293
1294 =head2 reset
1295
1296 =over 4
1297
1298 =item Arguments: none
1299
1300 =item Return Value: $self
1301
1302 =back
1303
1304 Resets the resultset's cursor, so you can iterate through the elements again.
1305
1306 =cut
1307
1308 sub reset {
1309   my ($self) = @_;
1310   delete $self->{_attrs} if exists $self->{_attrs};
1311   $self->{all_cache_position} = 0;
1312   $self->cursor->reset;
1313   return $self;
1314 }
1315
1316 =head2 first
1317
1318 =over 4
1319
1320 =item Arguments: none
1321
1322 =item Return Value: $object?
1323
1324 =back
1325
1326 Resets the resultset and returns an object for the first result (if the
1327 resultset returns anything).
1328
1329 =cut
1330
1331 sub first {
1332   return $_[0]->reset->next;
1333 }
1334
1335
1336 # _update_delete_via_subq
1337 #
1338 # Presence of some rs attributes requires a subquery to reliably
1339 # update/deletre
1340 #
1341
1342 sub _update_delete_via_subq {
1343   return $_[0]->_has_attr (qw/join seen_join group_by row offset page/);
1344 }
1345
1346
1347 # _cond_for_update_delete
1348 #
1349 # update/delete require the condition to be modified to handle
1350 # the differing SQL syntax available.  This transforms the $self->{cond}
1351 # appropriately, returning the new condition.
1352
1353 sub _cond_for_update_delete {
1354   my ($self, $full_cond) = @_;
1355   my $cond = {};
1356
1357   $full_cond ||= $self->{cond};
1358   # No-op. No condition, we're updating/deleting everything
1359   return $cond unless ref $full_cond;
1360
1361   if (ref $full_cond eq 'ARRAY') {
1362     $cond = [
1363       map {
1364         my %hash;
1365         foreach my $key (keys %{$_}) {
1366           $key =~ /([^.]+)$/;
1367           $hash{$1} = $_->{$key};
1368         }
1369         \%hash;
1370       } @{$full_cond}
1371     ];
1372   }
1373   elsif (ref $full_cond eq 'HASH') {
1374     if ((keys %{$full_cond})[0] eq '-and') {
1375       $cond->{-and} = [];
1376       my @cond = @{$full_cond->{-and}};
1377        for (my $i = 0; $i < @cond; $i++) {
1378         my $entry = $cond[$i];
1379         my $hash;
1380         if (ref $entry eq 'HASH') {
1381           $hash = $self->_cond_for_update_delete($entry);
1382         }
1383         else {
1384           $entry =~ /([^.]+)$/;
1385           $hash->{$1} = $cond[++$i];
1386         }
1387         push @{$cond->{-and}}, $hash;
1388       }
1389     }
1390     else {
1391       foreach my $key (keys %{$full_cond}) {
1392         $key =~ /([^.]+)$/;
1393         $cond->{$1} = $full_cond->{$key};
1394       }
1395     }
1396   }
1397   else {
1398     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1399   }
1400
1401   return $cond;
1402 }
1403
1404
1405 =head2 update
1406
1407 =over 4
1408
1409 =item Arguments: \%values
1410
1411 =item Return Value: $storage_rv
1412
1413 =back
1414
1415 Sets the specified columns in the resultset to the supplied values in a
1416 single query. Return value will be true if the update succeeded or false
1417 if no records were updated; exact type of success value is storage-dependent.
1418
1419 =cut
1420
1421 sub update {
1422   my ($self, $values) = @_;
1423   $self->throw_exception('Values for update must be a hash')
1424     unless ref $values eq 'HASH';
1425
1426   # rs operations with subqueries are Storage dependent - delegate
1427   if ($self->_update_delete_via_subq) {
1428     return $self->result_source->storage->subq_update_delete($self, 'update', $values);
1429   }
1430
1431   my $cond = $self->_cond_for_update_delete;
1432
1433   return $self->result_source->storage->update(
1434     $self->result_source, $values, $cond
1435   );
1436 }
1437
1438 =head2 update_all
1439
1440 =over 4
1441
1442 =item Arguments: \%values
1443
1444 =item Return Value: 1
1445
1446 =back
1447
1448 Fetches all objects and updates them one at a time. Note that C<update_all>
1449 will run DBIC cascade triggers, while L</update> will not.
1450
1451 =cut
1452
1453 sub update_all {
1454   my ($self, $values) = @_;
1455   $self->throw_exception('Values for update_all must be a hash')
1456     unless ref $values eq 'HASH';
1457   foreach my $obj ($self->all) {
1458     $obj->set_columns($values)->update;
1459   }
1460   return 1;
1461 }
1462
1463 =head2 delete
1464
1465 =over 4
1466
1467 =item Arguments: none
1468
1469 =item Return Value: 1
1470
1471 =back
1472
1473 Deletes the contents of the resultset from its result source. Note that this
1474 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1475 to run. See also L<DBIx::Class::Row/delete>.
1476
1477 delete may not generate correct SQL for a query with joins or a resultset
1478 chained from a related resultset.  In this case it will generate a warning:-
1479
1480 In these cases you may find that delete_all is more appropriate, or you
1481 need to respecify your query in a way that can be expressed without a join.
1482
1483 =cut
1484
1485 sub delete {
1486   my $self = shift;
1487   $self->throw_exception('delete does not accept any arguments')
1488     if @_;
1489
1490   # rs operations with subqueries are Storage dependent - delegate
1491   if ($self->_update_delete_via_subq) {
1492     return $self->result_source->storage->subq_update_delete($self, 'delete');
1493   }
1494
1495   my $cond = $self->_cond_for_update_delete;
1496
1497   $self->result_source->storage->delete($self->result_source, $cond);
1498   return 1;
1499 }
1500
1501 =head2 delete_all
1502
1503 =over 4
1504
1505 =item Arguments: none
1506
1507 =item Return Value: 1
1508
1509 =back
1510
1511 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1512 will run DBIC cascade triggers, while L</delete> will not.
1513
1514 =cut
1515
1516 sub delete_all {
1517   my $self = shift;
1518   $self->throw_exception('delete_all does not accept any arguments')
1519     if @_;
1520
1521   $_->delete for $self->all;
1522   return 1;
1523 }
1524
1525 =head2 populate
1526
1527 =over 4
1528
1529 =item Arguments: \@data;
1530
1531 =back
1532
1533 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1534 For the arrayref of hashrefs style each hashref should be a structure suitable
1535 forsubmitting to a $resultset->create(...) method.
1536
1537 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1538 to insert the data, as this is a faster method.
1539
1540 Otherwise, each set of data is inserted into the database using
1541 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1542 objects is returned.
1543
1544 Example:  Assuming an Artist Class that has many CDs Classes relating:
1545
1546   my $Artist_rs = $schema->resultset("Artist");
1547
1548   ## Void Context Example
1549   $Artist_rs->populate([
1550      { artistid => 4, name => 'Manufactured Crap', cds => [
1551         { title => 'My First CD', year => 2006 },
1552         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1553       ],
1554      },
1555      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1556         { title => 'My parents sold me to a record company' ,year => 2005 },
1557         { title => 'Why Am I So Ugly?', year => 2006 },
1558         { title => 'I Got Surgery and am now Popular', year => 2007 }
1559       ],
1560      },
1561   ]);
1562
1563   ## Array Context Example
1564   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1565     { name => "Artist One"},
1566     { name => "Artist Two"},
1567     { name => "Artist Three", cds=> [
1568     { title => "First CD", year => 2007},
1569     { title => "Second CD", year => 2008},
1570   ]}
1571   ]);
1572
1573   print $ArtistOne->name; ## response is 'Artist One'
1574   print $ArtistThree->cds->count ## reponse is '2'
1575
1576 For the arrayref of arrayrefs style,  the first element should be a list of the
1577 fieldsnames to which the remaining elements are rows being inserted.  For
1578 example:
1579
1580   $Arstist_rs->populate([
1581     [qw/artistid name/],
1582     [100, 'A Formally Unknown Singer'],
1583     [101, 'A singer that jumped the shark two albums ago'],
1584     [102, 'An actually cool singer.'],
1585   ]);
1586
1587 Please note an important effect on your data when choosing between void and
1588 wantarray context. Since void context goes straight to C<insert_bulk> in
1589 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1590 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1591 create primary keys for you, you will find that your PKs are empty.  In this
1592 case you will have to use the wantarray context in order to create those
1593 values.
1594
1595 =cut
1596
1597 sub populate {
1598   my $self = shift @_;
1599   my $data = ref $_[0][0] eq 'HASH'
1600     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1601     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1602
1603   if(defined wantarray) {
1604     my @created;
1605     foreach my $item (@$data) {
1606       push(@created, $self->create($item));
1607     }
1608     return @created;
1609   } else {
1610     my ($first, @rest) = @$data;
1611
1612     my @names = grep {!ref $first->{$_}} keys %$first;
1613     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1614     my @pks = $self->result_source->primary_columns;
1615
1616     ## do the belongs_to relationships
1617     foreach my $index (0..$#$data) {
1618       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1619         my @ret = $self->populate($data);
1620         return;
1621       }
1622
1623       foreach my $rel (@rels) {
1624         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1625         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1626         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1627         my $related = $result->result_source->_resolve_condition(
1628           $result->result_source->relationship_info($reverse)->{cond},
1629           $self,
1630           $result,
1631         );
1632
1633         delete $data->[$index]->{$rel};
1634         $data->[$index] = {%{$data->[$index]}, %$related};
1635
1636         push @names, keys %$related if $index == 0;
1637       }
1638     }
1639
1640     ## do bulk insert on current row
1641     my @values = map { [ @$_{@names} ] } @$data;
1642
1643     $self->result_source->storage->insert_bulk(
1644       $self->result_source,
1645       \@names,
1646       \@values,
1647     );
1648
1649     ## do the has_many relationships
1650     foreach my $item (@$data) {
1651
1652       foreach my $rel (@rels) {
1653         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1654
1655         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1656      || $self->throw_exception('Cannot find the relating object.');
1657
1658         my $child = $parent->$rel;
1659
1660         my $related = $child->result_source->_resolve_condition(
1661           $parent->result_source->relationship_info($rel)->{cond},
1662           $child,
1663           $parent,
1664         );
1665
1666         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1667         my @populate = map { {%$_, %$related} } @rows_to_add;
1668
1669         $child->populate( \@populate );
1670       }
1671     }
1672   }
1673 }
1674
1675 =head2 _normalize_populate_args ($args)
1676
1677 Private method used by L</populate> to normalize its incoming arguments.  Factored
1678 out in case you want to subclass and accept new argument structures to the
1679 L</populate> method.
1680
1681 =cut
1682
1683 sub _normalize_populate_args {
1684   my ($self, $data) = @_;
1685   my @names = @{shift(@$data)};
1686   my @results_to_create;
1687   foreach my $datum (@$data) {
1688     my %result_to_create;
1689     foreach my $index (0..$#names) {
1690       $result_to_create{$names[$index]} = $$datum[$index];
1691     }
1692     push @results_to_create, \%result_to_create;
1693   }
1694   return \@results_to_create;
1695 }
1696
1697 =head2 pager
1698
1699 =over 4
1700
1701 =item Arguments: none
1702
1703 =item Return Value: $pager
1704
1705 =back
1706
1707 Return Value a L<Data::Page> object for the current resultset. Only makes
1708 sense for queries with a C<page> attribute.
1709
1710 To get the full count of entries for a paged resultset, call
1711 C<total_entries> on the L<Data::Page> object.
1712
1713 =cut
1714
1715 sub pager {
1716   my ($self) = @_;
1717
1718   return $self->{pager} if $self->{pager};
1719
1720   my $attrs = $self->{attrs};
1721   $self->throw_exception("Can't create pager for non-paged rs")
1722     unless $self->{attrs}{page};
1723   $attrs->{rows} ||= 10;
1724
1725   # throw away the paging flags and re-run the count (possibly
1726   # with a subselect) to get the real total count
1727   my $count_attrs = { %$attrs };
1728   delete $count_attrs->{$_} for qw/rows offset page pager/;
1729   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1730
1731   return $self->{pager} = Data::Page->new(
1732     $total_count,
1733     $attrs->{rows},
1734     $self->{attrs}{page}
1735   );
1736 }
1737
1738 =head2 page
1739
1740 =over 4
1741
1742 =item Arguments: $page_number
1743
1744 =item Return Value: $rs
1745
1746 =back
1747
1748 Returns a resultset for the $page_number page of the resultset on which page
1749 is called, where each page contains a number of rows equal to the 'rows'
1750 attribute set on the resultset (10 by default).
1751
1752 =cut
1753
1754 sub page {
1755   my ($self, $page) = @_;
1756   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1757 }
1758
1759 =head2 new_result
1760
1761 =over 4
1762
1763 =item Arguments: \%vals
1764
1765 =item Return Value: $rowobject
1766
1767 =back
1768
1769 Creates a new row object in the resultset's result class and returns
1770 it. The row is not inserted into the database at this point, call
1771 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1772 will tell you whether the row object has been inserted or not.
1773
1774 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1775
1776 =cut
1777
1778 sub new_result {
1779   my ($self, $values) = @_;
1780   $self->throw_exception( "new_result needs a hash" )
1781     unless (ref $values eq 'HASH');
1782
1783   my %new;
1784   my $alias = $self->{attrs}{alias};
1785
1786   if (
1787     defined $self->{cond}
1788     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1789   ) {
1790     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1791     $new{-from_resultset} = [ keys %new ] if keys %new;
1792   } else {
1793     $self->throw_exception(
1794       "Can't abstract implicit construct, condition not a hash"
1795     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1796
1797     my $collapsed_cond = (
1798       $self->{cond}
1799         ? $self->_collapse_cond($self->{cond})
1800         : {}
1801     );
1802
1803     # precendence must be given to passed values over values inherited from
1804     # the cond, so the order here is important.
1805     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1806     while( my($col,$value) = each %implied ){
1807       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1808         $new{$col} = $value->{'='};
1809         next;
1810       }
1811       $new{$col} = $value if $self->_is_deterministic_value($value);
1812     }
1813   }
1814
1815   %new = (
1816     %new,
1817     %{ $self->_remove_alias($values, $alias) },
1818     -source_handle => $self->_source_handle,
1819     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1820   );
1821
1822   return $self->result_class->new(\%new);
1823 }
1824
1825 # _is_deterministic_value
1826 #
1827 # Make an effor to strip non-deterministic values from the condition,
1828 # to make sure new_result chokes less
1829
1830 sub _is_deterministic_value {
1831   my $self = shift;
1832   my $value = shift;
1833   my $ref_type = ref $value;
1834   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1835   return 1 if Scalar::Util::blessed($value);
1836   return 0;
1837 }
1838
1839 # _has_attr
1840 #
1841 # determines if the resultset defines at least one
1842 # of the attributes supplied
1843 #
1844 # used to determine if a subquery is neccessary
1845
1846 sub _has_attr {
1847   my ($self, @attr_names) = @_;
1848
1849   my $attrs = $self->_resolved_attrs;
1850
1851   my $join_check_req;
1852
1853   for my $n (@attr_names) {
1854     ++$join_check_req if $n =~ /join/;
1855
1856     my $attr =  $attrs->{$n};
1857
1858     next if not defined $attr;
1859
1860     if (ref $attr eq 'HASH') {
1861       return 1 if keys %$attr;
1862     }
1863     elsif (ref $attr eq 'ARRAY') {
1864       return 1 if @$attr;
1865     }
1866     else {
1867       return 1 if $attr;
1868     }
1869   }
1870
1871   # a join can be expressed as a multi-level from
1872   return 1 if (
1873     $join_check_req
1874       and
1875     ref $attrs->{from} eq 'ARRAY'
1876       and
1877     @{$attrs->{from}} > 1
1878   );
1879
1880   return 0;
1881 }
1882
1883 # _collapse_cond
1884 #
1885 # Recursively collapse the condition.
1886
1887 sub _collapse_cond {
1888   my ($self, $cond, $collapsed) = @_;
1889
1890   $collapsed ||= {};
1891
1892   if (ref $cond eq 'ARRAY') {
1893     foreach my $subcond (@$cond) {
1894       next unless ref $subcond;  # -or
1895       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1896     }
1897   }
1898   elsif (ref $cond eq 'HASH') {
1899     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1900       foreach my $subcond (@{$cond->{-and}}) {
1901         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1902       }
1903     }
1904     else {
1905       foreach my $col (keys %$cond) {
1906         my $value = $cond->{$col};
1907         $collapsed->{$col} = $value;
1908       }
1909     }
1910   }
1911
1912   return $collapsed;
1913 }
1914
1915 # _remove_alias
1916 #
1917 # Remove the specified alias from the specified query hash. A copy is made so
1918 # the original query is not modified.
1919
1920 sub _remove_alias {
1921   my ($self, $query, $alias) = @_;
1922
1923   my %orig = %{ $query || {} };
1924   my %unaliased;
1925
1926   foreach my $key (keys %orig) {
1927     if ($key !~ /\./) {
1928       $unaliased{$key} = $orig{$key};
1929       next;
1930     }
1931     $unaliased{$1} = $orig{$key}
1932       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1933   }
1934
1935   return \%unaliased;
1936 }
1937
1938 =head2 as_query (EXPERIMENTAL)
1939
1940 =over 4
1941
1942 =item Arguments: none
1943
1944 =item Return Value: \[ $sql, @bind ]
1945
1946 =back
1947
1948 Returns the SQL query and bind vars associated with the invocant.
1949
1950 This is generally used as the RHS for a subquery.
1951
1952 B<NOTE>: This feature is still experimental.
1953
1954 =cut
1955
1956 sub as_query { return shift->cursor->as_query(@_) }
1957
1958 =head2 find_or_new
1959
1960 =over 4
1961
1962 =item Arguments: \%vals, \%attrs?
1963
1964 =item Return Value: $rowobject
1965
1966 =back
1967
1968   my $artist = $schema->resultset('Artist')->find_or_new(
1969     { artist => 'fred' }, { key => 'artists' });
1970
1971   $cd->cd_to_producer->find_or_new({ producer => $producer },
1972                                    { key => 'primary });
1973
1974 Find an existing record from this resultset, based on its primary
1975 key, or a unique constraint. If none exists, instantiate a new result
1976 object and return it. The object will not be saved into your storage
1977 until you call L<DBIx::Class::Row/insert> on it.
1978
1979 You most likely want this method when looking for existing rows using
1980 a unique constraint that is not the primary key, or looking for
1981 related rows.
1982
1983 If you want objects to be saved immediately, use L</find_or_create> instead.
1984
1985 B<Note>: C<find_or_new> is probably not what you want when creating a
1986 new row in a table that uses primary keys supplied by the
1987 database. Passing in a primary key column with a value of I<undef>
1988 will cause L</find> to attempt to search for a row with a value of
1989 I<NULL>.
1990
1991 =cut
1992
1993 sub find_or_new {
1994   my $self     = shift;
1995   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1996   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1997   my $exists   = $self->find($hash, $attrs);
1998   return defined $exists ? $exists : $self->new_result($hash);
1999 }
2000
2001 =head2 create
2002
2003 =over 4
2004
2005 =item Arguments: \%vals
2006
2007 =item Return Value: a L<DBIx::Class::Row> $object
2008
2009 =back
2010
2011 Attempt to create a single new row or a row with multiple related rows
2012 in the table represented by the resultset (and related tables). This
2013 will not check for duplicate rows before inserting, use
2014 L</find_or_create> to do that.
2015
2016 To create one row for this resultset, pass a hashref of key/value
2017 pairs representing the columns of the table and the values you wish to
2018 store. If the appropriate relationships are set up, foreign key fields
2019 can also be passed an object representing the foreign row, and the
2020 value will be set to its primary key.
2021
2022 To create related objects, pass a hashref for the value if the related
2023 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2024 and use the name of the relationship as the key. (NOT the name of the field,
2025 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2026 of hashrefs containing the data for each of the rows to create in the foreign
2027 tables, again using the relationship name as the key.
2028
2029 Instead of hashrefs of plain related data (key/value pairs), you may
2030 also pass new or inserted objects. New objects (not inserted yet, see
2031 L</new>), will be inserted into their appropriate tables.
2032
2033 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2034
2035 Example of creating a new row.
2036
2037   $person_rs->create({
2038     name=>"Some Person",
2039     email=>"somebody@someplace.com"
2040   });
2041
2042 Example of creating a new row and also creating rows in a related C<has_many>
2043 or C<has_one> resultset.  Note Arrayref.
2044
2045   $artist_rs->create(
2046      { artistid => 4, name => 'Manufactured Crap', cds => [
2047         { title => 'My First CD', year => 2006 },
2048         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2049       ],
2050      },
2051   );
2052
2053 Example of creating a new row and also creating a row in a related
2054 C<belongs_to>resultset. Note Hashref.
2055
2056   $cd_rs->create({
2057     title=>"Music for Silly Walks",
2058     year=>2000,
2059     artist => {
2060       name=>"Silly Musician",
2061     }
2062   });
2063
2064 =cut
2065
2066 sub create {
2067   my ($self, $attrs) = @_;
2068   $self->throw_exception( "create needs a hashref" )
2069     unless ref $attrs eq 'HASH';
2070   return $self->new_result($attrs)->insert;
2071 }
2072
2073 =head2 find_or_create
2074
2075 =over 4
2076
2077 =item Arguments: \%vals, \%attrs?
2078
2079 =item Return Value: $rowobject
2080
2081 =back
2082
2083   $cd->cd_to_producer->find_or_create({ producer => $producer },
2084                                       { key => 'primary });
2085
2086 Tries to find a record based on its primary key or unique constraints; if none
2087 is found, creates one and returns that instead.
2088
2089   my $cd = $schema->resultset('CD')->find_or_create({
2090     cdid   => 5,
2091     artist => 'Massive Attack',
2092     title  => 'Mezzanine',
2093     year   => 2005,
2094   });
2095
2096 Also takes an optional C<key> attribute, to search by a specific key or unique
2097 constraint. For example:
2098
2099   my $cd = $schema->resultset('CD')->find_or_create(
2100     {
2101       artist => 'Massive Attack',
2102       title  => 'Mezzanine',
2103     },
2104     { key => 'cd_artist_title' }
2105   );
2106
2107 B<Note>: Because find_or_create() reads from the database and then
2108 possibly inserts based on the result, this method is subject to a race
2109 condition. Another process could create a record in the table after
2110 the find has completed and before the create has started. To avoid
2111 this problem, use find_or_create() inside a transaction.
2112
2113 B<Note>: C<find_or_create> is probably not what you want when creating
2114 a new row in a table that uses primary keys supplied by the
2115 database. Passing in a primary key column with a value of I<undef>
2116 will cause L</find> to attempt to search for a row with a value of
2117 I<NULL>.
2118
2119 See also L</find> and L</update_or_create>. For information on how to declare
2120 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2121
2122 =cut
2123
2124 sub find_or_create {
2125   my $self     = shift;
2126   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2127   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2128   my $exists   = $self->find($hash, $attrs);
2129   return defined $exists ? $exists : $self->create($hash);
2130 }
2131
2132 =head2 update_or_create
2133
2134 =over 4
2135
2136 =item Arguments: \%col_values, { key => $unique_constraint }?
2137
2138 =item Return Value: $rowobject
2139
2140 =back
2141
2142   $resultset->update_or_create({ col => $val, ... });
2143
2144 First, searches for an existing row matching one of the unique constraints
2145 (including the primary key) on the source of this resultset. If a row is
2146 found, updates it with the other given column values. Otherwise, creates a new
2147 row.
2148
2149 Takes an optional C<key> attribute to search on a specific unique constraint.
2150 For example:
2151
2152   # In your application
2153   my $cd = $schema->resultset('CD')->update_or_create(
2154     {
2155       artist => 'Massive Attack',
2156       title  => 'Mezzanine',
2157       year   => 1998,
2158     },
2159     { key => 'cd_artist_title' }
2160   );
2161
2162   $cd->cd_to_producer->update_or_create({
2163     producer => $producer,
2164     name => 'harry',
2165   }, {
2166     key => 'primary,
2167   });
2168
2169
2170 If no C<key> is specified, it searches on all unique constraints defined on the
2171 source, including the primary key.
2172
2173 If the C<key> is specified as C<primary>, it searches only on the primary key.
2174
2175 See also L</find> and L</find_or_create>. For information on how to declare
2176 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2177
2178 B<Note>: C<update_or_create> is probably not what you want when
2179 looking for a row in a table that uses primary keys supplied by the
2180 database, unless you actually have a key value. Passing in a primary
2181 key column with a value of I<undef> will cause L</find> to attempt to
2182 search for a row with a value of I<NULL>.
2183
2184 =cut
2185
2186 sub update_or_create {
2187   my $self = shift;
2188   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2189   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2190
2191   my $row = $self->find($cond, $attrs);
2192   if (defined $row) {
2193     $row->update($cond);
2194     return $row;
2195   }
2196
2197   return $self->create($cond);
2198 }
2199
2200 =head2 update_or_new
2201
2202 =over 4
2203
2204 =item Arguments: \%col_values, { key => $unique_constraint }?
2205
2206 =item Return Value: $rowobject
2207
2208 =back
2209
2210   $resultset->update_or_new({ col => $val, ... });
2211
2212 First, searches for an existing row matching one of the unique constraints
2213 (including the primary key) on the source of this resultset. If a row is
2214 found, updates it with the other given column values. Otherwise, instantiate
2215 a new result object and return it. The object will not be saved into your storage
2216 until you call L<DBIx::Class::Row/insert> on it.
2217
2218 Takes an optional C<key> attribute to search on a specific unique constraint.
2219 For example:
2220
2221   # In your application
2222   my $cd = $schema->resultset('CD')->update_or_new(
2223     {
2224       artist => 'Massive Attack',
2225       title  => 'Mezzanine',
2226       year   => 1998,
2227     },
2228     { key => 'cd_artist_title' }
2229   );
2230
2231   if ($cd->in_storage) {
2232       # the cd was updated
2233   }
2234   else {
2235       # the cd is not yet in the database, let's insert it
2236       $cd->insert;
2237   }
2238
2239 See also L</find>, L</find_or_create> and L<find_or_new>.
2240
2241 =cut
2242
2243 sub update_or_new {
2244     my $self  = shift;
2245     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2246     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2247
2248     my $row = $self->find( $cond, $attrs );
2249     if ( defined $row ) {
2250         $row->update($cond);
2251         return $row;
2252     }
2253
2254     return $self->new_result($cond);
2255 }
2256
2257 =head2 get_cache
2258
2259 =over 4
2260
2261 =item Arguments: none
2262
2263 =item Return Value: \@cache_objects?
2264
2265 =back
2266
2267 Gets the contents of the cache for the resultset, if the cache is set.
2268
2269 The cache is populated either by using the L</prefetch> attribute to
2270 L</search> or by calling L</set_cache>.
2271
2272 =cut
2273
2274 sub get_cache {
2275   shift->{all_cache};
2276 }
2277
2278 =head2 set_cache
2279
2280 =over 4
2281
2282 =item Arguments: \@cache_objects
2283
2284 =item Return Value: \@cache_objects
2285
2286 =back
2287
2288 Sets the contents of the cache for the resultset. Expects an arrayref
2289 of objects of the same class as those produced by the resultset. Note that
2290 if the cache is set the resultset will return the cached objects rather
2291 than re-querying the database even if the cache attr is not set.
2292
2293 The contents of the cache can also be populated by using the
2294 L</prefetch> attribute to L</search>.
2295
2296 =cut
2297
2298 sub set_cache {
2299   my ( $self, $data ) = @_;
2300   $self->throw_exception("set_cache requires an arrayref")
2301       if defined($data) && (ref $data ne 'ARRAY');
2302   $self->{all_cache} = $data;
2303 }
2304
2305 =head2 clear_cache
2306
2307 =over 4
2308
2309 =item Arguments: none
2310
2311 =item Return Value: []
2312
2313 =back
2314
2315 Clears the cache for the resultset.
2316
2317 =cut
2318
2319 sub clear_cache {
2320   shift->set_cache(undef);
2321 }
2322
2323 =head2 related_resultset
2324
2325 =over 4
2326
2327 =item Arguments: $relationship_name
2328
2329 =item Return Value: $resultset
2330
2331 =back
2332
2333 Returns a related resultset for the supplied relationship name.
2334
2335   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2336
2337 =cut
2338
2339 sub related_resultset {
2340   my ($self, $rel) = @_;
2341
2342   $self->{related_resultsets} ||= {};
2343   return $self->{related_resultsets}{$rel} ||= do {
2344     my $rel_obj = $self->result_source->relationship_info($rel);
2345
2346     $self->throw_exception(
2347       "search_related: result source '" . $self->result_source->source_name .
2348         "' has no such relationship $rel")
2349       unless $rel_obj;
2350
2351     my ($from,$seen) = $self->_resolve_from($rel);
2352
2353     my $join_count = $seen->{$rel};
2354     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2355
2356     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2357     my %attrs = %{$self->{attrs}||{}};
2358     delete @attrs{qw(result_class alias)};
2359
2360     my $new_cache;
2361
2362     if (my $cache = $self->get_cache) {
2363       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2364         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2365                         @$cache ];
2366       }
2367     }
2368
2369     my $rel_source = $self->result_source->related_source($rel);
2370
2371     my $new = do {
2372
2373       # The reason we do this now instead of passing the alias to the
2374       # search_rs below is that if you wrap/overload resultset on the
2375       # source you need to know what alias it's -going- to have for things
2376       # to work sanely (e.g. RestrictWithObject wants to be able to add
2377       # extra query restrictions, and these may need to be $alias.)
2378
2379       my $attrs = $rel_source->resultset_attributes;
2380       local $attrs->{alias} = $alias;
2381
2382       $rel_source->resultset
2383                  ->search_rs(
2384                      undef, {
2385                        %attrs,
2386                        join => undef,
2387                        prefetch => undef,
2388                        select => undef,
2389                        as => undef,
2390                        where => $self->{cond},
2391                        seen_join => $seen,
2392                        from => $from,
2393                    });
2394     };
2395     $new->set_cache($new_cache) if $new_cache;
2396     $new;
2397   };
2398 }
2399
2400 =head2 current_source_alias
2401
2402 =over 4
2403
2404 =item Arguments: none
2405
2406 =item Return Value: $source_alias
2407
2408 =back
2409
2410 Returns the current table alias for the result source this resultset is built
2411 on, that will be used in the SQL query. Usually it is C<me>.
2412
2413 Currently the source alias that refers to the result set returned by a
2414 L</search>/L</find> family method depends on how you got to the resultset: it's
2415 C<me> by default, but eg. L</search_related> aliases it to the related result
2416 source name (and keeps C<me> referring to the original result set). The long
2417 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2418 (and make this method unnecessary).
2419
2420 Thus it's currently necessary to use this method in predefined queries (see
2421 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2422 source alias of the current result set:
2423
2424   # in a result set class
2425   sub modified_by {
2426     my ($self, $user) = @_;
2427
2428     my $me = $self->current_source_alias;
2429
2430     return $self->search(
2431       "$me.modified" => $user->id,
2432     );
2433   }
2434
2435 =cut
2436
2437 sub current_source_alias {
2438   my ($self) = @_;
2439
2440   return ($self->{attrs} || {})->{alias} || 'me';
2441 }
2442
2443 # This code is called by search_related, and makes sure there
2444 # is clear separation between the joins before, during, and
2445 # after the relationship. This information is needed later
2446 # in order to properly resolve prefetch aliases (any alias
2447 # with a relation_chain_depth less than the depth of the
2448 # current prefetch is not considered)
2449 sub _resolve_from {
2450   my ($self, $extra_join) = @_;
2451   my $source = $self->result_source;
2452   my $attrs = $self->{attrs};
2453
2454   my $from = $attrs->{from}
2455     || [ { $attrs->{alias} => $source->from } ];
2456
2457   my $seen = { %{$attrs->{seen_join}||{}} };
2458
2459   # we need to take the prefetch the attrs into account before we
2460   # ->_resolve_join as otherwise they get lost - captainL
2461   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2462
2463   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2464
2465   ++$seen->{-relation_chain_depth};
2466
2467   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2468
2469   ++$seen->{-relation_chain_depth};
2470
2471   return ($from,$seen);
2472 }
2473
2474 sub _resolved_attrs {
2475   my $self = shift;
2476   return $self->{_attrs} if $self->{_attrs};
2477
2478   my $attrs  = { %{ $self->{attrs} || {} } };
2479   my $source = $self->result_source;
2480   my $alias  = $attrs->{alias};
2481
2482   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2483   my @colbits;
2484
2485   # build columns (as long as select isn't set) into a set of as/select hashes
2486   unless ( $attrs->{select} ) {
2487       @colbits = map {
2488           ( ref($_) eq 'HASH' )
2489               ? $_
2490               : {
2491                   (
2492                     /^\Q${alias}.\E(.+)$/
2493                       ? "$1"
2494                       : "$_"
2495                   )
2496                 =>
2497                   (
2498                     /\./
2499                       ? "$_"
2500                       : "${alias}.$_"
2501                   )
2502             }
2503       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2504   }
2505   # add the additional columns on
2506   foreach ( 'include_columns', '+columns' ) {
2507       push @colbits, map {
2508           ( ref($_) eq 'HASH' )
2509             ? $_
2510             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2511       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2512   }
2513
2514   # start with initial select items
2515   if ( $attrs->{select} ) {
2516     $attrs->{select} =
2517         ( ref $attrs->{select} eq 'ARRAY' )
2518       ? [ @{ $attrs->{select} } ]
2519       : [ $attrs->{select} ];
2520     $attrs->{as} = (
2521       $attrs->{as}
2522       ? (
2523         ref $attrs->{as} eq 'ARRAY'
2524         ? [ @{ $attrs->{as} } ]
2525         : [ $attrs->{as} ]
2526         )
2527       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2528     );
2529   }
2530   else {
2531
2532     # otherwise we intialise select & as to empty
2533     $attrs->{select} = [];
2534     $attrs->{as}     = [];
2535   }
2536
2537   # now add colbits to select/as
2538   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2539   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2540
2541   my $adds;
2542   if ( $adds = delete $attrs->{'+select'} ) {
2543     $adds = [$adds] unless ref $adds eq 'ARRAY';
2544     push(
2545       @{ $attrs->{select} },
2546       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2547     );
2548   }
2549   if ( $adds = delete $attrs->{'+as'} ) {
2550     $adds = [$adds] unless ref $adds eq 'ARRAY';
2551     push( @{ $attrs->{as} }, @$adds );
2552   }
2553
2554   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2555
2556   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2557     my $join = delete $attrs->{join} || {};
2558
2559     if ( defined $attrs->{prefetch} ) {
2560       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2561
2562     }
2563
2564     $attrs->{from} =    # have to copy here to avoid corrupting the original
2565       [
2566       @{ $attrs->{from} },
2567       $source->_resolve_join(
2568         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2569       )
2570       ];
2571
2572   }
2573
2574   $attrs->{group_by} ||= $attrs->{select}
2575     if delete $attrs->{distinct};
2576   if ( $attrs->{order_by} ) {
2577     $attrs->{order_by} = (
2578       ref( $attrs->{order_by} ) eq 'ARRAY'
2579       ? [ @{ $attrs->{order_by} } ]
2580       : [ $attrs->{order_by} ]
2581     );
2582   }
2583   else {
2584     $attrs->{order_by} = [];
2585   }
2586
2587   my $collapse = $attrs->{collapse} || {};
2588   if ( my $prefetch = delete $attrs->{prefetch} ) {
2589     $prefetch = $self->_merge_attr( {}, $prefetch );
2590     my @pre_order;
2591     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2592
2593       # bring joins back to level of current class
2594       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2595       my @prefetch =
2596         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2597       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2598       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2599     }
2600     push( @{ $attrs->{order_by} }, @pre_order );
2601   }
2602   $attrs->{collapse} = $collapse;
2603
2604   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2605     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2606   }
2607
2608   return $self->{_attrs} = $attrs;
2609 }
2610
2611 sub _joinpath_aliases {
2612   my ($self, $fromspec, $seen) = @_;
2613
2614   my $paths = {};
2615   return $paths unless ref $fromspec eq 'ARRAY';
2616
2617   for my $j (@$fromspec) {
2618
2619     next if ref $j ne 'ARRAY';
2620     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2621
2622     my $p = $paths;
2623     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2624     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2625   }
2626
2627   return $paths;
2628 }
2629
2630 sub _rollout_attr {
2631   my ($self, $attr) = @_;
2632
2633   if (ref $attr eq 'HASH') {
2634     return $self->_rollout_hash($attr);
2635   } elsif (ref $attr eq 'ARRAY') {
2636     return $self->_rollout_array($attr);
2637   } else {
2638     return [$attr];
2639   }
2640 }
2641
2642 sub _rollout_array {
2643   my ($self, $attr) = @_;
2644
2645   my @rolled_array;
2646   foreach my $element (@{$attr}) {
2647     if (ref $element eq 'HASH') {
2648       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2649     } elsif (ref $element eq 'ARRAY') {
2650       #  XXX - should probably recurse here
2651       push( @rolled_array, @{$self->_rollout_array($element)} );
2652     } else {
2653       push( @rolled_array, $element );
2654     }
2655   }
2656   return \@rolled_array;
2657 }
2658
2659 sub _rollout_hash {
2660   my ($self, $attr) = @_;
2661
2662   my @rolled_array;
2663   foreach my $key (keys %{$attr}) {
2664     push( @rolled_array, { $key => $attr->{$key} } );
2665   }
2666   return \@rolled_array;
2667 }
2668
2669 sub _calculate_score {
2670   my ($self, $a, $b) = @_;
2671
2672   if (ref $b eq 'HASH') {
2673     my ($b_key) = keys %{$b};
2674     if (ref $a eq 'HASH') {
2675       my ($a_key) = keys %{$a};
2676       if ($a_key eq $b_key) {
2677         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2678       } else {
2679         return 0;
2680       }
2681     } else {
2682       return ($a eq $b_key) ? 1 : 0;
2683     }
2684   } else {
2685     if (ref $a eq 'HASH') {
2686       my ($a_key) = keys %{$a};
2687       return ($b eq $a_key) ? 1 : 0;
2688     } else {
2689       return ($b eq $a) ? 1 : 0;
2690     }
2691   }
2692 }
2693
2694 sub _merge_attr {
2695   my ($self, $orig, $import) = @_;
2696
2697   return $import unless defined($orig);
2698   return $orig unless defined($import);
2699
2700   $orig = $self->_rollout_attr($orig);
2701   $import = $self->_rollout_attr($import);
2702
2703   my $seen_keys;
2704   foreach my $import_element ( @{$import} ) {
2705     # find best candidate from $orig to merge $b_element into
2706     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2707     foreach my $orig_element ( @{$orig} ) {
2708       my $score = $self->_calculate_score( $orig_element, $import_element );
2709       if ($score > $best_candidate->{score}) {
2710         $best_candidate->{position} = $position;
2711         $best_candidate->{score} = $score;
2712       }
2713       $position++;
2714     }
2715     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2716
2717     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2718       push( @{$orig}, $import_element );
2719     } else {
2720       my $orig_best = $orig->[$best_candidate->{position}];
2721       # merge orig_best and b_element together and replace original with merged
2722       if (ref $orig_best ne 'HASH') {
2723         $orig->[$best_candidate->{position}] = $import_element;
2724       } elsif (ref $import_element eq 'HASH') {
2725         my ($key) = keys %{$orig_best};
2726         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2727       }
2728     }
2729     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2730   }
2731
2732   return $orig;
2733 }
2734
2735 sub result_source {
2736     my $self = shift;
2737
2738     if (@_) {
2739         $self->_source_handle($_[0]->handle);
2740     } else {
2741         $self->_source_handle->resolve;
2742     }
2743 }
2744
2745 =head2 throw_exception
2746
2747 See L<DBIx::Class::Schema/throw_exception> for details.
2748
2749 =cut
2750
2751 sub throw_exception {
2752   my $self=shift;
2753   if (ref $self && $self->_source_handle->schema) {
2754     $self->_source_handle->schema->throw_exception(@_)
2755   } else {
2756     croak(@_);
2757   }
2758
2759 }
2760
2761 # XXX: FIXME: Attributes docs need clearing up
2762
2763 =head1 ATTRIBUTES
2764
2765 Attributes are used to refine a ResultSet in various ways when
2766 searching for data. They can be passed to any method which takes an
2767 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2768 L</count>.
2769
2770 These are in no particular order:
2771
2772 =head2 order_by
2773
2774 =over 4
2775
2776 =item Value: ( $order_by | \@order_by | \%order_by )
2777
2778 =back
2779
2780 Which column(s) to order the results by. If a single column name, or
2781 an arrayref of names is supplied, the argument is passed through
2782 directly to SQL. The hashref syntax allows for connection-agnostic
2783 specification of ordering direction:
2784
2785  For descending order:
2786
2787   order_by => { -desc => [qw/col1 col2 col3/] }
2788
2789  For explicit ascending order:
2790
2791   order_by => { -asc => 'col' }
2792
2793 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2794 supported, although you are strongly encouraged to use the hashref
2795 syntax as outlined above.
2796
2797 =head2 columns
2798
2799 =over 4
2800
2801 =item Value: \@columns
2802
2803 =back
2804
2805 Shortcut to request a particular set of columns to be retrieved. Each
2806 column spec may be a string (a table column name), or a hash (in which
2807 case the key is the C<as> value, and the value is used as the C<select>
2808 expression). Adds C<me.> onto the start of any column without a C<.> in
2809 it and sets C<select> from that, then auto-populates C<as> from
2810 C<select> as normal. (You may also use the C<cols> attribute, as in
2811 earlier versions of DBIC.)
2812
2813 =head2 +columns
2814
2815 =over 4
2816
2817 =item Value: \@columns
2818
2819 =back
2820
2821 Indicates additional columns to be selected from storage. Works the same
2822 as L</columns> but adds columns to the selection. (You may also use the
2823 C<include_columns> attribute, as in earlier versions of DBIC). For
2824 example:-
2825
2826   $schema->resultset('CD')->search(undef, {
2827     '+columns' => ['artist.name'],
2828     join => ['artist']
2829   });
2830
2831 would return all CDs and include a 'name' column to the information
2832 passed to object inflation. Note that the 'artist' is the name of the
2833 column (or relationship) accessor, and 'name' is the name of the column
2834 accessor in the related table.
2835
2836 =head2 include_columns
2837
2838 =over 4
2839
2840 =item Value: \@columns
2841
2842 =back
2843
2844 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2845
2846 =head2 select
2847
2848 =over 4
2849
2850 =item Value: \@select_columns
2851
2852 =back
2853
2854 Indicates which columns should be selected from the storage. You can use
2855 column names, or in the case of RDBMS back ends, function or stored procedure
2856 names:
2857
2858   $rs = $schema->resultset('Employee')->search(undef, {
2859     select => [
2860       'name',
2861       { count => 'employeeid' },
2862       { sum => 'salary' }
2863     ]
2864   });
2865
2866 When you use function/stored procedure names and do not supply an C<as>
2867 attribute, the column names returned are storage-dependent. E.g. MySQL would
2868 return a column named C<count(employeeid)> in the above example.
2869
2870 =head2 +select
2871
2872 =over 4
2873
2874 Indicates additional columns to be selected from storage.  Works the same as
2875 L</select> but adds columns to the selection.
2876
2877 =back
2878
2879 =head2 +as
2880
2881 =over 4
2882
2883 Indicates additional column names for those added via L</+select>. See L</as>.
2884
2885 =back
2886
2887 =head2 as
2888
2889 =over 4
2890
2891 =item Value: \@inflation_names
2892
2893 =back
2894
2895 Indicates column names for object inflation. That is, C<as>
2896 indicates the name that the column can be accessed as via the
2897 C<get_column> method (or via the object accessor, B<if one already
2898 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2899
2900 The C<as> attribute is used in conjunction with C<select>,
2901 usually when C<select> contains one or more function or stored
2902 procedure names:
2903
2904   $rs = $schema->resultset('Employee')->search(undef, {
2905     select => [
2906       'name',
2907       { count => 'employeeid' }
2908     ],
2909     as => ['name', 'employee_count'],
2910   });
2911
2912   my $employee = $rs->first(); # get the first Employee
2913
2914 If the object against which the search is performed already has an accessor
2915 matching a column name specified in C<as>, the value can be retrieved using
2916 the accessor as normal:
2917
2918   my $name = $employee->name();
2919
2920 If on the other hand an accessor does not exist in the object, you need to
2921 use C<get_column> instead:
2922
2923   my $employee_count = $employee->get_column('employee_count');
2924
2925 You can create your own accessors if required - see
2926 L<DBIx::Class::Manual::Cookbook> for details.
2927
2928 Please note: This will NOT insert an C<AS employee_count> into the SQL
2929 statement produced, it is used for internal access only. Thus
2930 attempting to use the accessor in an C<order_by> clause or similar
2931 will fail miserably.
2932
2933 To get around this limitation, you can supply literal SQL to your
2934 C<select> attibute that contains the C<AS alias> text, eg:
2935
2936   select => [\'myfield AS alias']
2937
2938 =head2 join
2939
2940 =over 4
2941
2942 =item Value: ($rel_name | \@rel_names | \%rel_names)
2943
2944 =back
2945
2946 Contains a list of relationships that should be joined for this query.  For
2947 example:
2948
2949   # Get CDs by Nine Inch Nails
2950   my $rs = $schema->resultset('CD')->search(
2951     { 'artist.name' => 'Nine Inch Nails' },
2952     { join => 'artist' }
2953   );
2954
2955 Can also contain a hash reference to refer to the other relation's relations.
2956 For example:
2957
2958   package MyApp::Schema::Track;
2959   use base qw/DBIx::Class/;
2960   __PACKAGE__->table('track');
2961   __PACKAGE__->add_columns(qw/trackid cd position title/);
2962   __PACKAGE__->set_primary_key('trackid');
2963   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2964   1;
2965
2966   # In your application
2967   my $rs = $schema->resultset('Artist')->search(
2968     { 'track.title' => 'Teardrop' },
2969     {
2970       join     => { cd => 'track' },
2971       order_by => 'artist.name',
2972     }
2973   );
2974
2975 You need to use the relationship (not the table) name in  conditions,
2976 because they are aliased as such. The current table is aliased as "me", so
2977 you need to use me.column_name in order to avoid ambiguity. For example:
2978
2979   # Get CDs from 1984 with a 'Foo' track
2980   my $rs = $schema->resultset('CD')->search(
2981     {
2982       'me.year' => 1984,
2983       'tracks.name' => 'Foo'
2984     },
2985     { join => 'tracks' }
2986   );
2987
2988 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2989 similarly for a third time). For e.g.
2990
2991   my $rs = $schema->resultset('Artist')->search({
2992     'cds.title'   => 'Down to Earth',
2993     'cds_2.title' => 'Popular',
2994   }, {
2995     join => [ qw/cds cds/ ],
2996   });
2997
2998 will return a set of all artists that have both a cd with title 'Down
2999 to Earth' and a cd with title 'Popular'.
3000
3001 If you want to fetch related objects from other tables as well, see C<prefetch>
3002 below.
3003
3004 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3005
3006 =head2 prefetch
3007
3008 =over 4
3009
3010 =item Value: ($rel_name | \@rel_names | \%rel_names)
3011
3012 =back
3013
3014 Contains one or more relationships that should be fetched along with
3015 the main query (when they are accessed afterwards the data will
3016 already be available, without extra queries to the database).  This is
3017 useful for when you know you will need the related objects, because it
3018 saves at least one query:
3019
3020   my $rs = $schema->resultset('Tag')->search(
3021     undef,
3022     {
3023       prefetch => {
3024         cd => 'artist'
3025       }
3026     }
3027   );
3028
3029 The initial search results in SQL like the following:
3030
3031   SELECT tag.*, cd.*, artist.* FROM tag
3032   JOIN cd ON tag.cd = cd.cdid
3033   JOIN artist ON cd.artist = artist.artistid
3034
3035 L<DBIx::Class> has no need to go back to the database when we access the
3036 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3037 case.
3038
3039 Simple prefetches will be joined automatically, so there is no need
3040 for a C<join> attribute in the above search.
3041
3042 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3043 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3044 with an accessor type of 'single' or 'filter'). A more complex example that
3045 prefetches an artists cds, the tracks on those cds, and the tags associted
3046 with that artist is given below (assuming many-to-many from artists to tags):
3047
3048  my $rs = $schema->resultset('Artist')->search(
3049    undef,
3050    {
3051      prefetch => [
3052        { cds => 'tracks' },
3053        { artist_tags => 'tags' }
3054      ]
3055    }
3056  );
3057
3058
3059 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3060 attributes will be ignored.
3061
3062 =head2 page
3063
3064 =over 4
3065
3066 =item Value: $page
3067
3068 =back
3069
3070 Makes the resultset paged and specifies the page to retrieve. Effectively
3071 identical to creating a non-pages resultset and then calling ->page($page)
3072 on it.
3073
3074 If L<rows> attribute is not specified it defualts to 10 rows per page.
3075
3076 When you have a paged resultset, L</count> will only return the number
3077 of rows in the page. To get the total, use the L</pager> and call
3078 C<total_entries> on it.
3079
3080 =head2 rows
3081
3082 =over 4
3083
3084 =item Value: $rows
3085
3086 =back
3087
3088 Specifes the maximum number of rows for direct retrieval or the number of
3089 rows per page if the page attribute or method is used.
3090
3091 =head2 offset
3092
3093 =over 4
3094
3095 =item Value: $offset
3096
3097 =back
3098
3099 Specifies the (zero-based) row number for the  first row to be returned, or the
3100 of the first row of the first page if paging is used.
3101
3102 =head2 group_by
3103
3104 =over 4
3105
3106 =item Value: \@columns
3107
3108 =back
3109
3110 A arrayref of columns to group by. Can include columns of joined tables.
3111
3112   group_by => [qw/ column1 column2 ... /]
3113
3114 =head2 having
3115
3116 =over 4
3117
3118 =item Value: $condition
3119
3120 =back
3121
3122 HAVING is a select statement attribute that is applied between GROUP BY and
3123 ORDER BY. It is applied to the after the grouping calculations have been
3124 done.
3125
3126   having => { 'count(employee)' => { '>=', 100 } }
3127
3128 =head2 distinct
3129
3130 =over 4
3131
3132 =item Value: (0 | 1)
3133
3134 =back
3135
3136 Set to 1 to group by all columns.
3137
3138 =head2 where
3139
3140 =over 4
3141
3142 Adds to the WHERE clause.
3143
3144   # only return rows WHERE deleted IS NULL for all searches
3145   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3146
3147 Can be overridden by passing C<{ where => undef }> as an attribute
3148 to a resulset.
3149
3150 =back
3151
3152 =head2 cache
3153
3154 Set to 1 to cache search results. This prevents extra SQL queries if you
3155 revisit rows in your ResultSet:
3156
3157   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3158
3159   while( my $artist = $resultset->next ) {
3160     ... do stuff ...
3161   }
3162
3163   $rs->first; # without cache, this would issue a query
3164
3165 By default, searches are not cached.
3166
3167 For more examples of using these attributes, see
3168 L<DBIx::Class::Manual::Cookbook>.
3169
3170 =head2 from
3171
3172 =over 4
3173
3174 =item Value: \@from_clause
3175
3176 =back
3177
3178 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3179 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3180 clauses.
3181
3182 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3183
3184 C<join> will usually do what you need and it is strongly recommended that you
3185 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3186 And we really do mean "cannot", not just tried and failed. Attempting to use
3187 this because you're having problems with C<join> is like trying to use x86
3188 ASM because you've got a syntax error in your C. Trust us on this.
3189
3190 Now, if you're still really, really sure you need to use this (and if you're
3191 not 100% sure, ask the mailing list first), here's an explanation of how this
3192 works.
3193
3194 The syntax is as follows -
3195
3196   [
3197     { <alias1> => <table1> },
3198     [
3199       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3200       [], # nested JOIN (optional)
3201       { <table1.column1> => <table2.column2>, ... (more conditions) },
3202     ],
3203     # More of the above [ ] may follow for additional joins
3204   ]
3205
3206   <table1> <alias1>
3207   JOIN
3208     <table2> <alias2>
3209     [JOIN ...]
3210   ON <table1.column1> = <table2.column2>
3211   <more joins may follow>
3212
3213 An easy way to follow the examples below is to remember the following:
3214
3215     Anything inside "[]" is a JOIN
3216     Anything inside "{}" is a condition for the enclosing JOIN
3217
3218 The following examples utilize a "person" table in a family tree application.
3219 In order to express parent->child relationships, this table is self-joined:
3220
3221     # Person->belongs_to('father' => 'Person');
3222     # Person->belongs_to('mother' => 'Person');
3223
3224 C<from> can be used to nest joins. Here we return all children with a father,
3225 then search against all mothers of those children:
3226
3227   $rs = $schema->resultset('Person')->search(
3228       undef,
3229       {
3230           alias => 'mother', # alias columns in accordance with "from"
3231           from => [
3232               { mother => 'person' },
3233               [
3234                   [
3235                       { child => 'person' },
3236                       [
3237                           { father => 'person' },
3238                           { 'father.person_id' => 'child.father_id' }
3239                       ]
3240                   ],
3241                   { 'mother.person_id' => 'child.mother_id' }
3242               ],
3243           ]
3244       },
3245   );
3246
3247   # Equivalent SQL:
3248   # SELECT mother.* FROM person mother
3249   # JOIN (
3250   #   person child
3251   #   JOIN person father
3252   #   ON ( father.person_id = child.father_id )
3253   # )
3254   # ON ( mother.person_id = child.mother_id )
3255
3256 The type of any join can be controlled manually. To search against only people
3257 with a father in the person table, we could explicitly use C<INNER JOIN>:
3258
3259     $rs = $schema->resultset('Person')->search(
3260         undef,
3261         {
3262             alias => 'child', # alias columns in accordance with "from"
3263             from => [
3264                 { child => 'person' },
3265                 [
3266                     { father => 'person', -join_type => 'inner' },
3267                     { 'father.id' => 'child.father_id' }
3268                 ],
3269             ]
3270         },
3271     );
3272
3273     # Equivalent SQL:
3274     # SELECT child.* FROM person child
3275     # INNER JOIN person father ON child.father_id = father.id
3276
3277 If you need to express really complex joins or you need a subselect, you
3278 can supply literal SQL to C<from> via a scalar reference. In this case
3279 the contents of the scalar will replace the table name asscoiated with the
3280 resultsource.
3281
3282 WARNING: This technique might very well not work as expected on chained
3283 searches - you have been warned.
3284
3285     # Assuming the Event resultsource is defined as:
3286
3287         MySchema::Event->add_columns (
3288             sequence => {
3289                 data_type => 'INT',
3290                 is_auto_increment => 1,
3291             },
3292             location => {
3293                 data_type => 'INT',
3294             },
3295             type => {
3296                 data_type => 'INT',
3297             },
3298         );
3299         MySchema::Event->set_primary_key ('sequence');
3300
3301     # This will get back the latest event for every location. The column
3302     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3303     # combo to limit the resultset
3304
3305     $rs = $schema->resultset('Event');
3306     $table = $rs->result_source->name;
3307     $latest = $rs->search (
3308         undef,
3309         { from => \ "
3310             (SELECT e1.* FROM $table e1
3311                 JOIN $table e2
3312                     ON e1.location = e2.location
3313                     AND e1.sequence < e2.sequence
3314                 WHERE e2.sequence is NULL
3315             ) me",
3316         },
3317     );
3318
3319     # Equivalent SQL (with the DBIC chunks added):
3320
3321     SELECT me.sequence, me.location, me.type FROM
3322        (SELECT e1.* FROM events e1
3323            JOIN events e2
3324                ON e1.location = e2.location
3325                AND e1.sequence < e2.sequence
3326            WHERE e2.sequence is NULL
3327        ) me;
3328
3329 =head2 for
3330
3331 =over 4
3332
3333 =item Value: ( 'update' | 'shared' )
3334
3335 =back
3336
3337 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3338 ... FOR SHARED.
3339
3340 =cut
3341
3342 1;