lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs   = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: $source, \%$attrs
 195
 196 =item Return Value: $rs
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you won't need to construct a resultset manually.  You'll
 206 automatically get one from e.g. a L</search> called in scalar context:
 207
 208   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 209
 210 =over
 211
 212 =item WARNING
 213
 214 If called on an object, proxies to L</new_result> instead, so
 215
 216   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 217
 218 will return a CD object, not a ResultSet, and is equivalent to:
 219
 220   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 221
 222 Please also keep in mind that many internals call C<new_result> directly,
 223 so overloading this method with the idea of intercepting new result object
 224 creation B<will not work>. See also warning pertaining to L</create>.
 225
 226 =back
 227
 228 =cut
 229
 230 sub new {
 231   my $class = shift;
 232   return $class->new_result(@_) if ref $class;
 233
 234   my ($source, $attrs) = @_;
 235   $source = $source->resolve
 236     if $source->isa('DBIx::Class::ResultSourceHandle');
 237   $attrs = { %{$attrs||{}} };
 238
 239   if ($attrs->{page}) {
 240     $attrs->{rows} ||= 10;
 241   }
 242
 243   $attrs->{alias} ||= 'me';
 244
 245   my $self = bless {
 246     result_source => $source,
 247     cond => $attrs->{where},
 248     pager => undef,
 249     attrs => $attrs,
 250   }, $class;
 251
 252   # if there is a dark selector, this means we are already in a
 253   # chain and the cleanup/sanification was taken care of by
 254   # _search_rs already
 255   $self->_normalize_selection($attrs)
 256     unless $attrs->{_dark_selector};
 257
 258   $self->result_class(
 259     $attrs->{result_class} || $source->result_class
 260   );
 261
 262   $self;
 263 }
 264
 265 =head2 search
 266
 267 =over 4
 268
 269 =item Arguments: $cond, \%attrs?
 270
 271 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 272
 273 =back
 274
 275   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 276   my $new_rs = $cd_rs->search({ year => 2005 });
 277
 278   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 279                  # year = 2005 OR year = 2004
 280
 281 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 282 returning a list of row objects instead. To avoid that, use L</search_rs>.
 283
 284 If you need to pass in additional attributes but no additional condition,
 285 call it as C<search(undef, \%attrs)>.
 286
 287   # "SELECT name, artistid FROM $artist_table"
 288   my @all_artists = $schema->resultset('Artist')->search(undef, {
 289     columns => [qw/name artistid/],
 290   });
 291
 292 For a list of attributes that can be passed to C<search>, see
 293 L</ATTRIBUTES>. For more examples of using this function, see
 294 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 295 documentation for the first argument, see L<SQL::Abstract>
 296 and its extension L<DBIx::Class::SQLMaker>.
 297
 298 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 299
 300 =head3 CAVEAT
 301
 302 Note that L</search> does not process/deflate any of the values passed in the
 303 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 304 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 305 manually that any value passed to this method will stringify to something the
 306 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 307 objects, for more info see:
 308 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 309
 310 =cut
 311
 312 sub search {
 313   my $self = shift;
 314   my $rs = $self->search_rs( @_ );
 315
 316   if (wantarray) {
 317     return $rs->all;
 318   }
 319   elsif (defined wantarray) {
 320     return $rs;
 321   }
 322   else {
 323     # we can be called by a relationship helper, which in
 324     # turn may be called in void context due to some braindead
 325     # overload or whatever else the user decided to be clever
 326     # at this particular day. Thus limit the exception to
 327     # external code calls only
 328     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 329       if (caller)[0] !~ /^\QDBIx::Class::/;
 330
 331     return ();
 332   }
 333 }
 334
 335 =head2 search_rs
 336
 337 =over 4
 338
 339 =item Arguments: $cond, \%attrs?
 340
 341 =item Return Value: $resultset
 342
 343 =back
 344
 345 This method does the same exact thing as search() except it will
 346 always return a resultset, even in list context.
 347
 348 =cut
 349
 350 sub search_rs {
 351   my $self = shift;
 352
 353   # Special-case handling for (undef, undef).
 354   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 355     @_ = ();
 356   }
 357
 358   my $call_attrs = {};
 359   if (@_ > 1) {
 360     if (ref $_[-1] eq 'HASH') {
 361       # copy for _normalize_selection
 362       $call_attrs = { %{ pop @_ } };
 363     }
 364     elsif (! defined $_[-1] ) {
 365       pop @_;   # search({}, undef)
 366     }
 367   }
 368
 369   # see if we can keep the cache (no $rs changes)
 370   my $cache;
 371   my %safe = (alias => 1, cache => 1);
 372   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 373     ! defined $_[0]
 374       or
 375     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 376       or
 377     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 378   )) {
 379     $cache = $self->get_cache;
 380   }
 381
 382   my $rsrc = $self->result_source;
 383
 384   my $old_attrs = { %{$self->{attrs}} };
 385   my $old_having = delete $old_attrs->{having};
 386   my $old_where = delete $old_attrs->{where};
 387
 388   my $new_attrs = { %$old_attrs };
 389
 390   # take care of call attrs (only if anything is changing)
 391   if (keys %$call_attrs) {
 392
 393     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 394
 395     # reset the current selector list if new selectors are supplied
 396     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 397       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 398     }
 399
 400     # Normalize the new selector list (operates on the passed-in attr structure)
 401     # Need to do it on every chain instead of only once on _resolved_attrs, in
 402     # order to allow detection of empty vs partial 'as'
 403     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 404       if $old_attrs->{_dark_selector};
 405     $self->_normalize_selection ($call_attrs);
 406
 407     # start with blind overwriting merge, exclude selector attrs
 408     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 409     delete @{$new_attrs}{@selector_attrs};
 410
 411     for (@selector_attrs) {
 412       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 413         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 414     }
 415
 416     # older deprecated name, use only if {columns} is not there
 417     if (my $c = delete $new_attrs->{cols}) {
 418       if ($new_attrs->{columns}) {
 419         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 420       }
 421       else {
 422         $new_attrs->{columns} = $c;
 423       }
 424     }
 425
 426
 427     # join/prefetch use their own crazy merging heuristics
 428     foreach my $key (qw/join prefetch/) {
 429       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 430         if exists $call_attrs->{$key};
 431     }
 432
 433     # stack binds together
 434     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 435   }
 436
 437
 438   # rip apart the rest of @_, parse a condition
 439   my $call_cond = do {
 440
 441     if (ref $_[0] eq 'HASH') {
 442       (keys %{$_[0]}) ? $_[0] : undef
 443     }
 444     elsif (@_ == 1) {
 445       $_[0]
 446     }
 447     elsif (@_ % 2) {
 448       $self->throw_exception('Odd number of arguments to search')
 449     }
 450     else {
 451       +{ @_ }
 452     }
 453
 454   } if @_;
 455
 456   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 457     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 458   }
 459
 460   for ($old_where, $call_cond) {
 461     if (defined $_) {
 462       $new_attrs->{where} = $self->_stack_cond (
 463         $_, $new_attrs->{where}
 464       );
 465     }
 466   }
 467
 468   if (defined $old_having) {
 469     $new_attrs->{having} = $self->_stack_cond (
 470       $old_having, $new_attrs->{having}
 471     )
 472   }
 473
 474   my $rs = (ref $self)->new($rsrc, $new_attrs);
 475
 476   $rs->set_cache($cache) if ($cache);
 477
 478   return $rs;
 479 }
 480
 481 my $dark_sel_dumper;
 482 sub _normalize_selection {
 483   my ($self, $attrs) = @_;
 484
 485   # legacy syntax
 486   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 487     if exists $attrs->{include_columns};
 488
 489   # columns are always placed first, however
 490
 491   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 492   # delay the decision on whether to use a default select list ($rsrc->columns)
 493   # allowing stuff like the remove_columns helper to work
 494   #
 495   # select/as +select/+as pairs need special handling - the amount of select/as
 496   # elements in each pair does *not* have to be equal (think multicolumn
 497   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 498   # supplied at all) - try to infer the alias, either from the -as parameter
 499   # of the selector spec, or use the parameter whole if it looks like a column
 500   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 501   # is ok as well), but make sure no more additions to the 'as' chain take place
 502   for my $pref ('', '+') {
 503
 504     my ($sel, $as) = map {
 505       my $key = "${pref}${_}";
 506
 507       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 508         ? @{$attrs->{$key}}
 509         : $attrs->{$key} || ()
 510       ];
 511       delete $attrs->{$key};
 512       $val;
 513     } qw/select as/;
 514
 515     if (! @$as and ! @$sel ) {
 516       next;
 517     }
 518     elsif (@$as and ! @$sel) {
 519       $self->throw_exception(
 520         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 521       );
 522     }
 523     elsif( ! @$as ) {
 524       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 525       # if any @$as has been supplied we assume the user knows what (s)he is doing
 526       # and blindly keep stacking up pieces
 527       unless ($attrs->{_dark_selector}) {
 528         SELECTOR:
 529         for (@$sel) {
 530           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 531             push @$as, $_->{-as};
 532           }
 533           # assume any plain no-space, no-parenthesis string to be a column spec
 534           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 535           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 536             push @$as, $_;
 537           }
 538           # if all else fails - raise a flag that no more aliasing will be allowed
 539           else {
 540             $attrs->{_dark_selector} = {
 541               plus_stage => $pref,
 542               string => ($dark_sel_dumper ||= do {
 543                   require Data::Dumper::Concise;
 544                   Data::Dumper::Concise::DumperObject()->Indent(0);
 545                 })->Values([$_])->Dump
 546               ,
 547             };
 548             last SELECTOR;
 549           }
 550         }
 551       }
 552     }
 553     elsif (@$as < @$sel) {
 554       $self->throw_exception(
 555         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 556       );
 557     }
 558     elsif ($pref and $attrs->{_dark_selector}) {
 559       $self->throw_exception(
 560         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 561       );
 562     }
 563
 564
 565     # merge result
 566     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 567     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 568   }
 569 }
 570
 571 sub _stack_cond {
 572   my ($self, $left, $right) = @_;
 573
 574   # collapse single element top-level conditions
 575   # (single pass only, unlikely to need recursion)
 576   for ($left, $right) {
 577     if (ref $_ eq 'ARRAY') {
 578       if (@$_ == 0) {
 579         $_ = undef;
 580       }
 581       elsif (@$_ == 1) {
 582         $_ = $_->[0];
 583       }
 584     }
 585     elsif (ref $_ eq 'HASH') {
 586       my ($first, $more) = keys %$_;
 587
 588       # empty hash
 589       if (! defined $first) {
 590         $_ = undef;
 591       }
 592       # one element hash
 593       elsif (! defined $more) {
 594         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 595           $_ = $_->{'-and'};
 596         }
 597         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 598           $_ = $_->{'-or'};
 599         }
 600       }
 601     }
 602   }
 603
 604   # merge hashes with weeding out of duplicates (simple cases only)
 605   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 606
 607     # shallow copy to destroy
 608     $right = { %$right };
 609     for (grep { exists $right->{$_} } keys %$left) {
 610       # the use of eq_deeply here is justified - the rhs of an
 611       # expression can contain a lot of twisted weird stuff
 612       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 613     }
 614
 615     $right = undef unless keys %$right;
 616   }
 617
 618
 619   if (defined $left xor defined $right) {
 620     return defined $left ? $left : $right;
 621   }
 622   elsif (! defined $left) {
 623     return undef;
 624   }
 625   else {
 626     return { -and => [ $left, $right ] };
 627   }
 628 }
 629
 630 =head2 search_literal
 631
 632 =over 4
 633
 634 =item Arguments: $sql_fragment, @bind_values
 635
 636 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 637
 638 =back
 639
 640   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 641   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 642
 643 Pass a literal chunk of SQL to be added to the conditional part of the
 644 resultset query.
 645
 646 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 647 only be used in that context. C<search_literal> is a convenience method.
 648 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 649 columns are bound correctly, use C<search>.
 650
 651 Example of how to use C<search> instead of C<search_literal>
 652
 653   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 654   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 655
 656
 657 See L<DBIx::Class::Manual::Cookbook/Searching> and
 658 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 659 require C<search_literal>.
 660
 661 =cut
 662
 663 sub search_literal {
 664   my ($self, $sql, @bind) = @_;
 665   my $attr;
 666   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 667     $attr = pop @bind;
 668   }
 669   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 670 }
 671
 672 =head2 find
 673
 674 =over 4
 675
 676 =item Arguments: \%columns_values | @pk_values, \%attrs?
 677
 678 =item Return Value: $row_object | undef
 679
 680 =back
 681
 682 Finds and returns a single row based on supplied criteria. Takes either a
 683 hashref with the same format as L</create> (including inference of foreign
 684 keys from related objects), or a list of primary key values in the same
 685 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 686 declaration on the L</result_source>.
 687
 688 In either case an attempt is made to combine conditions already existing on
 689 the resultset with the condition passed to this method.
 690
 691 To aid with preparing the correct query for the storage you may supply the
 692 C<key> attribute, which is the name of a
 693 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 694 unique constraint corresponding to the
 695 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 696 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 697 to construct a query that satisfies the named unique constraint fully (
 698 non-NULL values for each column member of the constraint) an exception is
 699 thrown.
 700
 701 If no C<key> is specified, the search is carried over all unique constraints
 702 which are fully defined by the available condition.
 703
 704 If no such constraint is found, C<find> currently defaults to a simple
 705 C<< search->(\%column_values) >> which may or may not do what you expect.
 706 Note that this fallback behavior may be deprecated in further versions. If
 707 you need to search with arbitrary conditions - use L</search>. If the query
 708 resulting from this fallback produces more than one row, a warning to the
 709 effect is issued, though only the first row is constructed and returned as
 710 C<$row_object>.
 711
 712 In addition to C<key>, L</find> recognizes and applies standard
 713 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 714
 715 Note that if you have extra concerns about the correctness of the resulting
 716 query you need to specify the C<key> attribute and supply the entire condition
 717 as an argument to find (since it is not always possible to perform the
 718 combination of the resultset condition with the supplied one, especially if
 719 the resultset condition contains literal sql).
 720
 721 For example, to find a row by its primary key:
 722
 723   my $cd = $schema->resultset('CD')->find(5);
 724
 725 You can also find a row by a specific unique constraint:
 726
 727   my $cd = $schema->resultset('CD')->find(
 728     {
 729       artist => 'Massive Attack',
 730       title  => 'Mezzanine',
 731     },
 732     { key => 'cd_artist_title' }
 733   );
 734
 735 See also L</find_or_create> and L</update_or_create>.
 736
 737 =cut
 738
 739 sub find {
 740   my $self = shift;
 741   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 742
 743   my $rsrc = $self->result_source;
 744
 745   my $constraint_name;
 746   if (exists $attrs->{key}) {
 747     $constraint_name = defined $attrs->{key}
 748       ? $attrs->{key}
 749       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 750     ;
 751   }
 752
 753   # Parse out the condition from input
 754   my $call_cond;
 755
 756   if (ref $_[0] eq 'HASH') {
 757     $call_cond = { %{$_[0]} };
 758   }
 759   else {
 760     # if only values are supplied we need to default to 'primary'
 761     $constraint_name = 'primary' unless defined $constraint_name;
 762
 763     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 764
 765     $self->throw_exception(
 766       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 767     ) unless @c_cols;
 768
 769     $self->throw_exception (
 770       'find() expects either a column/value hashref, or a list of values '
 771     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 772     ) unless @c_cols == @_;
 773
 774     $call_cond = {};
 775     @{$call_cond}{@c_cols} = @_;
 776   }
 777
 778   my %related;
 779   for my $key (keys %$call_cond) {
 780     if (
 781       my $keyref = ref($call_cond->{$key})
 782         and
 783       my $relinfo = $rsrc->relationship_info($key)
 784     ) {
 785       my $val = delete $call_cond->{$key};
 786
 787       next if $keyref eq 'ARRAY'; # has_many for multi_create
 788
 789       my $rel_q = $rsrc->_resolve_condition(
 790         $relinfo->{cond}, $val, $key, $key
 791       );
 792       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 793       @related{keys %$rel_q} = values %$rel_q;
 794     }
 795   }
 796
 797   # relationship conditions take precedence (?)
 798   @{$call_cond}{keys %related} = values %related;
 799
 800   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 801   my $final_cond;
 802   if (defined $constraint_name) {
 803     $final_cond = $self->_qualify_cond_columns (
 804
 805       $self->_build_unique_cond (
 806         $constraint_name,
 807         $call_cond,
 808       ),
 809
 810       $alias,
 811     );
 812   }
 813   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 814     # This means that we got here after a merger of relationship conditions
 815     # in ::Relationship::Base::search_related (the row method), and furthermore
 816     # the relationship is of the 'single' type. This means that the condition
 817     # provided by the relationship (already attached to $self) is sufficient,
 818     # as there can be only one row in the database that would satisfy the
 819     # relationship
 820   }
 821   else {
 822     # no key was specified - fall down to heuristics mode:
 823     # run through all unique queries registered on the resultset, and
 824     # 'OR' all qualifying queries together
 825     my (@unique_queries, %seen_column_combinations);
 826     for my $c_name ($rsrc->unique_constraint_names) {
 827       next if $seen_column_combinations{
 828         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 829       }++;
 830
 831       push @unique_queries, try {
 832         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 833       } || ();
 834     }
 835
 836     $final_cond = @unique_queries
 837       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 838       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 839     ;
 840   }
 841
 842   # Run the query, passing the result_class since it should propagate for find
 843   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 844   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 845     my $row = $rs->next;
 846     carp "Query returned more than one row" if $rs->next;
 847     return $row;
 848   }
 849   else {
 850     return $rs->single;
 851   }
 852 }
 853
 854 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 855 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 856 #
 857 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 858 # condition. It is provided for overrides until a saner way forward is devised
 859 #
 860 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 861 # the road. Please adjust your tests accordingly to catch this situation early
 862 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 863 #
 864 # The method will not be removed without an adequately complete replacement
 865 # for strict-mode enforcement
 866 sub _non_unique_find_fallback {
 867   my ($self, $cond, $attrs) = @_;
 868
 869   return $self->_qualify_cond_columns(
 870     $cond,
 871     exists $attrs->{alias}
 872       ? $attrs->{alias}
 873       : $self->{attrs}{alias}
 874   );
 875 }
 876
 877
 878 sub _qualify_cond_columns {
 879   my ($self, $cond, $alias) = @_;
 880
 881   my %aliased = %$cond;
 882   for (keys %aliased) {
 883     $aliased{"$alias.$_"} = delete $aliased{$_}
 884       if $_ !~ /\./;
 885   }
 886
 887   return \%aliased;
 888 }
 889
 890 sub _build_unique_cond {
 891   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 892
 893   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 894
 895   # combination may fail if $self->{cond} is non-trivial
 896   my ($final_cond) = try {
 897     $self->_merge_with_rscond ($extra_cond)
 898   } catch {
 899     +{ %$extra_cond }
 900   };
 901
 902   # trim out everything not in $columns
 903   $final_cond = { map {
 904     exists $final_cond->{$_}
 905       ? ( $_ => $final_cond->{$_} )
 906       : ()
 907   } @c_cols };
 908
 909   if (my @missing = grep
 910     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 911     (@c_cols)
 912   ) {
 913     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 914       $constraint_name,
 915       join (', ', map { "'$_'" } @missing),
 916     ) );
 917   }
 918
 919   if (
 920     !$croak_on_null
 921       and
 922     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 923       and
 924     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 925   ) {
 926     carp_unique ( sprintf (
 927       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 928     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 929     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 930       $constraint_name,
 931       join (', ', map { "'$_'" } @undefs),
 932     ));
 933   }
 934
 935   return $final_cond;
 936 }
 937
 938 =head2 search_related
 939
 940 =over 4
 941
 942 =item Arguments: $rel, $cond?, \%attrs?
 943
 944 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 945
 946 =back
 947
 948   $new_rs = $cd_rs->search_related('artist', {
 949     name => 'Emo-R-Us',
 950   });
 951
 952 Searches the specified relationship, optionally specifying a condition and
 953 attributes for matching records. See L</ATTRIBUTES> for more information.
 954
 955 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 956 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 957
 958 See also L</search_related_rs>.
 959
 960 =cut
 961
 962 sub search_related {
 963   return shift->related_resultset(shift)->search(@_);
 964 }
 965
 966 =head2 search_related_rs
 967
 968 This method works exactly the same as search_related, except that
 969 it guarantees a resultset, even in list context.
 970
 971 =cut
 972
 973 sub search_related_rs {
 974   return shift->related_resultset(shift)->search_rs(@_);
 975 }
 976
 977 =head2 cursor
 978
 979 =over 4
 980
 981 =item Arguments: none
 982
 983 =item Return Value: $cursor
 984
 985 =back
 986
 987 Returns a storage-driven cursor to the given resultset. See
 988 L<DBIx::Class::Cursor> for more information.
 989
 990 =cut
 991
 992 sub cursor {
 993   my ($self) = @_;
 994
 995   my $attrs = $self->_resolved_attrs_copy;
 996
 997   return $self->{cursor}
 998     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 999           $attrs->{where},$attrs);
1000 }
1001
1002 =head2 single
1003
1004 =over 4
1005
1006 =item Arguments: $cond?
1007
1008 =item Return Value: $row_object | undef
1009
1010 =back
1011
1012   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1013
1014 Inflates the first result without creating a cursor if the resultset has
1015 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1016 of L</search>.
1017
1018 While this method can take an optional search condition (just like L</search>)
1019 being a fast-code-path it does not recognize search attributes. If you need to
1020 add extra joins or similar, call L</search> and then chain-call L</single> on the
1021 L<DBIx::Class::ResultSet> returned.
1022
1023 =over
1024
1025 =item B<Note>
1026
1027 As of 0.08100, this method enforces the assumption that the preceding
1028 query returns only one row. If more than one row is returned, you will receive
1029 a warning:
1030
1031   Query returned more than one row
1032
1033 In this case, you should be using L</next> or L</find> instead, or if you really
1034 know what you are doing, use the L</rows> attribute to explicitly limit the size
1035 of the resultset.
1036
1037 This method will also throw an exception if it is called on a resultset prefetching
1038 has_many, as such a prefetch implies fetching multiple rows from the database in
1039 order to assemble the resulting object.
1040
1041 =back
1042
1043 =cut
1044
1045 sub single {
1046   my ($self, $where) = @_;
1047   if(@_ > 2) {
1048       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1049   }
1050
1051   my $attrs = $self->_resolved_attrs_copy;
1052
1053   if (keys %{$attrs->{collapse}}) {
1054     $self->throw_exception(
1055       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1056     );
1057   }
1058
1059   if ($where) {
1060     if (defined $attrs->{where}) {
1061       $attrs->{where} = {
1062         '-and' =>
1063             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1064                $where, delete $attrs->{where} ]
1065       };
1066     } else {
1067       $attrs->{where} = $where;
1068     }
1069   }
1070
1071   my @data = $self->result_source->storage->select_single(
1072     $attrs->{from}, $attrs->{select},
1073     $attrs->{where}, $attrs
1074   );
1075
1076   return (@data ? ($self->_construct_object(@data))[0] : undef);
1077 }
1078
1079
1080 # _collapse_query
1081 #
1082 # Recursively collapse the query, accumulating values for each column.
1083
1084 sub _collapse_query {
1085   my ($self, $query, $collapsed) = @_;
1086
1087   $collapsed ||= {};
1088
1089   if (ref $query eq 'ARRAY') {
1090     foreach my $subquery (@$query) {
1091       next unless ref $subquery;  # -or
1092       $collapsed = $self->_collapse_query($subquery, $collapsed);
1093     }
1094   }
1095   elsif (ref $query eq 'HASH') {
1096     if (keys %$query and (keys %$query)[0] eq '-and') {
1097       foreach my $subquery (@{$query->{-and}}) {
1098         $collapsed = $self->_collapse_query($subquery, $collapsed);
1099       }
1100     }
1101     else {
1102       foreach my $col (keys %$query) {
1103         my $value = $query->{$col};
1104         $collapsed->{$col}{$value}++;
1105       }
1106     }
1107   }
1108
1109   return $collapsed;
1110 }
1111
1112 =head2 get_column
1113
1114 =over 4
1115
1116 =item Arguments: $cond?
1117
1118 =item Return Value: $resultsetcolumn
1119
1120 =back
1121
1122   my $max_length = $rs->get_column('length')->max;
1123
1124 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1125
1126 =cut
1127
1128 sub get_column {
1129   my ($self, $column) = @_;
1130   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1131   return $new;
1132 }
1133
1134 =head2 search_like
1135
1136 =over 4
1137
1138 =item Arguments: $cond, \%attrs?
1139
1140 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1141
1142 =back
1143
1144   # WHERE title LIKE '%blue%'
1145   $cd_rs = $rs->search_like({ title => '%blue%'});
1146
1147 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1148 that this is simply a convenience method retained for ex Class::DBI users.
1149 You most likely want to use L</search> with specific operators.
1150
1151 For more information, see L<DBIx::Class::Manual::Cookbook>.
1152
1153 This method is deprecated and will be removed in 0.09. Use L</search()>
1154 instead. An example conversion is:
1155
1156   ->search_like({ foo => 'bar' });
1157
1158   # Becomes
1159
1160   ->search({ foo => { like => 'bar' } });
1161
1162 =cut
1163
1164 sub search_like {
1165   my $class = shift;
1166   carp_unique (
1167     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1168    .' Instead use ->search({ x => { -like => "y%" } })'
1169    .' (note the outer pair of {}s - they are important!)'
1170   );
1171   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1172   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1173   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1174   return $class->search($query, { %$attrs });
1175 }
1176
1177 =head2 slice
1178
1179 =over 4
1180
1181 =item Arguments: $first, $last
1182
1183 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1184
1185 =back
1186
1187 Returns a resultset or object list representing a subset of elements from the
1188 resultset slice is called on. Indexes are from 0, i.e., to get the first
1189 three records, call:
1190
1191   my ($one, $two, $three) = $rs->slice(0, 2);
1192
1193 =cut
1194
1195 sub slice {
1196   my ($self, $min, $max) = @_;
1197   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1198   $attrs->{offset} = $self->{attrs}{offset} || 0;
1199   $attrs->{offset} += $min;
1200   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1201   return $self->search(undef, $attrs);
1202   #my $slice = (ref $self)->new($self->result_source, $attrs);
1203   #return (wantarray ? $slice->all : $slice);
1204 }
1205
1206 =head2 next
1207
1208 =over 4
1209
1210 =item Arguments: none
1211
1212 =item Return Value: $result | undef
1213
1214 =back
1215
1216 Returns the next element in the resultset (C<undef> is there is none).
1217
1218 Can be used to efficiently iterate over records in the resultset:
1219
1220   my $rs = $schema->resultset('CD')->search;
1221   while (my $cd = $rs->next) {
1222     print $cd->title;
1223   }
1224
1225 Note that you need to store the resultset object, and call C<next> on it.
1226 Calling C<< resultset('Table')->next >> repeatedly will always return the
1227 first record from the resultset.
1228
1229 =cut
1230
1231 sub next {
1232   my ($self) = @_;
1233   if (my $cache = $self->get_cache) {
1234     $self->{all_cache_position} ||= 0;
1235     return $cache->[$self->{all_cache_position}++];
1236   }
1237   if ($self->{attrs}{cache}) {
1238     delete $self->{pager};
1239     $self->{all_cache_position} = 1;
1240     return ($self->all)[0];
1241   }
1242   if ($self->{stashed_objects}) {
1243     my $obj = shift(@{$self->{stashed_objects}});
1244     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1245     return $obj;
1246   }
1247   my @row = (
1248     exists $self->{stashed_row}
1249       ? @{delete $self->{stashed_row}}
1250       : $self->cursor->next
1251   );
1252   return undef unless (@row);
1253   my ($row, @more) = $self->_construct_object(@row);
1254   $self->{stashed_objects} = \@more if @more;
1255   return $row;
1256 }
1257
1258 sub _construct_object {
1259   my ($self, @row) = @_;
1260
1261   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1262     or return ();
1263   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1264   @new = $self->{_attrs}{record_filter}->(@new)
1265     if exists $self->{_attrs}{record_filter};
1266   return @new;
1267 }
1268
1269 sub _collapse_result {
1270   my ($self, $as_proto, $row) = @_;
1271
1272   my @copy = @$row;
1273
1274   # 'foo'         => [ undef, 'foo' ]
1275   # 'foo.bar'     => [ 'foo', 'bar' ]
1276   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1277
1278   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1279
1280   my %collapse = %{$self->{_attrs}{collapse}||{}};
1281
1282   my @pri_index;
1283
1284   # if we're doing collapsing (has_many prefetch) we need to grab records
1285   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1286   # we know we don't have to bother.
1287
1288   # the reason for not using the collapse stuff directly is because if you
1289   # had for e.g. two artists in a row with no cds, the collapse info for
1290   # both would be NULL (undef) so you'd lose the second artist
1291
1292   # store just the index so we can check the array positions from the row
1293   # without having to contruct the full hash
1294
1295   if (keys %collapse) {
1296     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1297     foreach my $i (0 .. $#construct_as) {
1298       next if defined($construct_as[$i][0]); # only self table
1299       if (delete $pri{$construct_as[$i][1]}) {
1300         push(@pri_index, $i);
1301       }
1302       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1303     }
1304   }
1305
1306   # no need to do an if, it'll be empty if @pri_index is empty anyway
1307
1308   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1309
1310   my @const_rows;
1311
1312   do { # no need to check anything at the front, we always want the first row
1313
1314     my %const;
1315
1316     foreach my $this_as (@construct_as) {
1317       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1318     }
1319
1320     push(@const_rows, \%const);
1321
1322   } until ( # no pri_index => no collapse => drop straight out
1323       !@pri_index
1324     or
1325       do { # get another row, stash it, drop out if different PK
1326
1327         @copy = $self->cursor->next;
1328         $self->{stashed_row} = \@copy;
1329
1330         # last thing in do block, counts as true if anything doesn't match
1331
1332         # check xor defined first for NULL vs. NOT NULL then if one is
1333         # defined the other must be so check string equality
1334
1335         grep {
1336           (defined $pri_vals{$_} ^ defined $copy[$_])
1337           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1338         } @pri_index;
1339       }
1340   );
1341
1342   my $alias = $self->{attrs}{alias};
1343   my $info = [];
1344
1345   my %collapse_pos;
1346
1347   my @const_keys;
1348
1349   foreach my $const (@const_rows) {
1350     scalar @const_keys or do {
1351       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1352     };
1353     foreach my $key (@const_keys) {
1354       if (length $key) {
1355         my $target = $info;
1356         my @parts = split(/\./, $key);
1357         my $cur = '';
1358         my $data = $const->{$key};
1359         foreach my $p (@parts) {
1360           $target = $target->[1]->{$p} ||= [];
1361           $cur .= ".${p}";
1362           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1363             # collapsing at this point and on final part
1364             my $pos = $collapse_pos{$cur};
1365             CK: foreach my $ck (@ckey) {
1366               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1367                 $collapse_pos{$cur} = $data;
1368                 delete @collapse_pos{ # clear all positioning for sub-entries
1369                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1370                 };
1371                 push(@$target, []);
1372                 last CK;
1373               }
1374             }
1375           }
1376           if (exists $collapse{$cur}) {
1377             $target = $target->[-1];
1378           }
1379         }
1380         $target->[0] = $data;
1381       } else {
1382         $info->[0] = $const->{$key};
1383       }
1384     }
1385   }
1386
1387   return $info;
1388 }
1389
1390 =head2 result_source
1391
1392 =over 4
1393
1394 =item Arguments: $result_source?
1395
1396 =item Return Value: $result_source
1397
1398 =back
1399
1400 An accessor for the primary ResultSource object from which this ResultSet
1401 is derived.
1402
1403 =head2 result_class
1404
1405 =over 4
1406
1407 =item Arguments: $result_class?
1408
1409 =item Return Value: $result_class
1410
1411 =back
1412
1413 An accessor for the class to use when creating row objects. Defaults to
1414 C<< result_source->result_class >> - which in most cases is the name of the
1415 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1416
1417 Note that changing the result_class will also remove any components
1418 that were originally loaded in the source class via
1419 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1420 in the original source class will not run.
1421
1422 =cut
1423
1424 sub result_class {
1425   my ($self, $result_class) = @_;
1426   if ($result_class) {
1427     unless (ref $result_class) { # don't fire this for an object
1428       $self->ensure_class_loaded($result_class);
1429     }
1430     $self->_result_class($result_class);
1431     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1432     # permit the user to set result class on one result set only; it only
1433     # chains if provided to search()
1434     #$self->{attrs}{result_class} = $result_class if ref $self;
1435   }
1436   $self->_result_class;
1437 }
1438
1439 =head2 count
1440
1441 =over 4
1442
1443 =item Arguments: $cond, \%attrs??
1444
1445 =item Return Value: $count
1446
1447 =back
1448
1449 Performs an SQL C<COUNT> with the same query as the resultset was built
1450 with to find the number of elements. Passing arguments is equivalent to
1451 C<< $rs->search ($cond, \%attrs)->count >>
1452
1453 =cut
1454
1455 sub count {
1456   my $self = shift;
1457   return $self->search(@_)->count if @_ and defined $_[0];
1458   return scalar @{ $self->get_cache } if $self->get_cache;
1459
1460   my $attrs = $self->_resolved_attrs_copy;
1461
1462   # this is a little optimization - it is faster to do the limit
1463   # adjustments in software, instead of a subquery
1464   my $rows = delete $attrs->{rows};
1465   my $offset = delete $attrs->{offset};
1466
1467   my $crs;
1468   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1469     $crs = $self->_count_subq_rs ($attrs);
1470   }
1471   else {
1472     $crs = $self->_count_rs ($attrs);
1473   }
1474   my $count = $crs->next;
1475
1476   $count -= $offset if $offset;
1477   $count = $rows if $rows and $rows < $count;
1478   $count = 0 if ($count < 0);
1479
1480   return $count;
1481 }
1482
1483 =head2 count_rs
1484
1485 =over 4
1486
1487 =item Arguments: $cond, \%attrs??
1488
1489 =item Return Value: $count_rs
1490
1491 =back
1492
1493 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1494 This can be very handy for subqueries:
1495
1496   ->search( { amount => $some_rs->count_rs->as_query } )
1497
1498 As with regular resultsets the SQL query will be executed only after
1499 the resultset is accessed via L</next> or L</all>. That would return
1500 the same single value obtainable via L</count>.
1501
1502 =cut
1503
1504 sub count_rs {
1505   my $self = shift;
1506   return $self->search(@_)->count_rs if @_;
1507
1508   # this may look like a lack of abstraction (count() does about the same)
1509   # but in fact an _rs *must* use a subquery for the limits, as the
1510   # software based limiting can not be ported if this $rs is to be used
1511   # in a subquery itself (i.e. ->as_query)
1512   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1513     return $self->_count_subq_rs;
1514   }
1515   else {
1516     return $self->_count_rs;
1517   }
1518 }
1519
1520 #
1521 # returns a ResultSetColumn object tied to the count query
1522 #
1523 sub _count_rs {
1524   my ($self, $attrs) = @_;
1525
1526   my $rsrc = $self->result_source;
1527   $attrs ||= $self->_resolved_attrs;
1528
1529   my $tmp_attrs = { %$attrs };
1530   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1531   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1532
1533   # overwrite the selector (supplied by the storage)
1534   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1535   $tmp_attrs->{as} = 'count';
1536   delete @{$tmp_attrs}{qw/columns/};
1537
1538   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1539
1540   return $tmp_rs;
1541 }
1542
1543 #
1544 # same as above but uses a subquery
1545 #
1546 sub _count_subq_rs {
1547   my ($self, $attrs) = @_;
1548
1549   my $rsrc = $self->result_source;
1550   $attrs ||= $self->_resolved_attrs;
1551
1552   my $sub_attrs = { %$attrs };
1553   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1554   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1555
1556   # if we multi-prefetch we group_by something unique, as this is what we would
1557   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1558   if ( keys %{$attrs->{collapse}}  ) {
1559     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1560       $rsrc->_identifying_column_set || $self->throw_exception(
1561         'Unable to construct a unique group_by criteria properly collapsing the '
1562       . 'has_many prefetch before count()'
1563       );
1564     } ]
1565   }
1566
1567   # Calculate subquery selector
1568   if (my $g = $sub_attrs->{group_by}) {
1569
1570     my $sql_maker = $rsrc->storage->sql_maker;
1571
1572     # necessary as the group_by may refer to aliased functions
1573     my $sel_index;
1574     for my $sel (@{$attrs->{select}}) {
1575       $sel_index->{$sel->{-as}} = $sel
1576         if (ref $sel eq 'HASH' and $sel->{-as});
1577     }
1578
1579     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1580     # also look for named aggregates referred in the having clause
1581     # having often contains scalarrefs - thus parse it out entirely
1582     my @parts = @$g;
1583     if ($attrs->{having}) {
1584       local $sql_maker->{having_bind};
1585       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1586       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1587       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1588         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1589         # if we don't unset it we screw up retarded but unfortunately working
1590         # 'MAX(foo.bar)' => { '>', 3 }
1591         $sql_maker->{name_sep} = '';
1592       }
1593
1594       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1595
1596       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1597
1598       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1599       # and if all fails for an utterly naive quoted scalar-with-function
1600       while ($sql =~ /
1601         $rquote $sep $lquote (.+?) $rquote
1602           |
1603         [\s,] \w+ \. (\w+) [\s,]
1604           |
1605         [\s,] $lquote (.+?) $rquote [\s,]
1606       /gx) {
1607         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1608       }
1609     }
1610
1611     for (@parts) {
1612       my $colpiece = $sel_index->{$_} || $_;
1613
1614       # unqualify join-based group_by's. Arcane but possible query
1615       # also horrible horrible hack to alias a column (not a func.)
1616       # (probably need to introduce SQLA syntax)
1617       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1618         my $as = $colpiece;
1619         $as =~ s/\./__/;
1620         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1621       }
1622       push @{$sub_attrs->{select}}, $colpiece;
1623     }
1624   }
1625   else {
1626     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1627     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1628   }
1629
1630   return $rsrc->resultset_class
1631                ->new ($rsrc, $sub_attrs)
1632                 ->as_subselect_rs
1633                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1634                   ->get_column ('count');
1635 }
1636
1637 sub _bool {
1638   return 1;
1639 }
1640
1641 =head2 count_literal
1642
1643 =over 4
1644
1645 =item Arguments: $sql_fragment, @bind_values
1646
1647 =item Return Value: $count
1648
1649 =back
1650
1651 Counts the results in a literal query. Equivalent to calling L</search_literal>
1652 with the passed arguments, then L</count>.
1653
1654 =cut
1655
1656 sub count_literal { shift->search_literal(@_)->count; }
1657
1658 =head2 all
1659
1660 =over 4
1661
1662 =item Arguments: none
1663
1664 =item Return Value: @objects
1665
1666 =back
1667
1668 Returns all elements in the resultset.
1669
1670 =cut
1671
1672 sub all {
1673   my $self = shift;
1674   if(@_) {
1675       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1676   }
1677
1678   return @{ $self->get_cache } if $self->get_cache;
1679
1680   my @obj;
1681
1682   if (keys %{$self->_resolved_attrs->{collapse}}) {
1683     # Using $self->cursor->all is really just an optimisation.
1684     # If we're collapsing has_many prefetches it probably makes
1685     # very little difference, and this is cleaner than hacking
1686     # _construct_object to survive the approach
1687     $self->cursor->reset;
1688     my @row = $self->cursor->next;
1689     while (@row) {
1690       push(@obj, $self->_construct_object(@row));
1691       @row = (exists $self->{stashed_row}
1692                ? @{delete $self->{stashed_row}}
1693                : $self->cursor->next);
1694     }
1695   } else {
1696     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1697   }
1698
1699   $self->set_cache(\@obj) if $self->{attrs}{cache};
1700
1701   return @obj;
1702 }
1703
1704 =head2 reset
1705
1706 =over 4
1707
1708 =item Arguments: none
1709
1710 =item Return Value: $self
1711
1712 =back
1713
1714 Resets the resultset's cursor, so you can iterate through the elements again.
1715 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1716 another query.
1717
1718 =cut
1719
1720 sub reset {
1721   my ($self) = @_;
1722   delete $self->{_attrs} if exists $self->{_attrs};
1723   $self->{all_cache_position} = 0;
1724   $self->cursor->reset;
1725   return $self;
1726 }
1727
1728 =head2 first
1729
1730 =over 4
1731
1732 =item Arguments: none
1733
1734 =item Return Value: $object | undef
1735
1736 =back
1737
1738 Resets the resultset and returns an object for the first result (or C<undef>
1739 if the resultset is empty).
1740
1741 =cut
1742
1743 sub first {
1744   return $_[0]->reset->next;
1745 }
1746
1747
1748 # _rs_update_delete
1749 #
1750 # Determines whether and what type of subquery is required for the $rs operation.
1751 # If grouping is necessary either supplies its own, or verifies the current one
1752 # After all is done delegates to the proper storage method.
1753
1754 sub _rs_update_delete {
1755   my ($self, $op, $values) = @_;
1756
1757   my $cond = $self->{cond};
1758   my $rsrc = $self->result_source;
1759   my $storage = $rsrc->schema->storage;
1760
1761   my $attrs = { %{$self->_resolved_attrs} };
1762
1763   # "needs" is a strong word here - if the subquery is part of an IN clause - no point of
1764   # even adding the group_by. It will really be used only when composing a poor-man's
1765   # multicolumn-IN equivalent OR set
1766   my $needs_group_by_subq = defined $attrs->{group_by};
1767
1768   # simplify the joinmap and maybe decide if a grouping (and thus subquery) is necessary
1769   my $relation_classifications;
1770   if (ref($attrs->{from}) eq 'ARRAY') {
1771     if (@{$attrs->{from}} == 1) {
1772       # not a fucking JOIN at all, quit with the dickery
1773       $relation_classifications = {};
1774     } else {
1775       $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1776
1777       $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1778         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1779         $attrs->{select},
1780         $cond,
1781         $attrs
1782       ) unless $needs_group_by_subq;  # we already know we need a group, no point of resolving them
1783     }
1784   }
1785   else {
1786     $needs_group_by_subq ||= 1; # if {from} is unparseable assume the worst
1787   }
1788
1789   $needs_group_by_subq ||= exists $relation_classifications->{multiplying};
1790
1791   # if no subquery - life is easy-ish
1792   unless (
1793     $needs_group_by_subq
1794       or
1795     keys %$relation_classifications # if any joins at all - need to wrap a subq
1796       or
1797     $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1798   ) {
1799     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1800     # a condition containing 'me' or other table prefixes will not work
1801     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1802     my $sqla = $rsrc->storage->sql_maker;
1803     local $sqla->{_dequalify_idents} = 1;
1804     return $rsrc->storage->$op(
1805       $rsrc,
1806       $op eq 'update' ? $values : (),
1807       $self->{cond},
1808     );
1809   }
1810
1811   # we got this far - means it is time to wrap a subquery
1812   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1813     sprintf(
1814       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1815       $op,
1816       $rsrc->source_name,
1817     )
1818   );
1819   my $existing_group_by = delete $attrs->{group_by};
1820
1821   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1822   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1823   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1824   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1825   my $subrs = (ref $self)->new($rsrc, $attrs);
1826
1827   if (@$idcols == 1) {
1828     return $storage->$op (
1829       $rsrc,
1830       $op eq 'update' ? $values : (),
1831       { $idcols->[0] => { -in => $subrs->as_query } },
1832     );
1833   }
1834   elsif ($storage->_use_multicolumn_in) {
1835     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1836     my $sql_maker = $storage->sql_maker;
1837     my ($sql, @bind) = @${$subrs->as_query};
1838     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1839       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1840       $sql,
1841     );
1842
1843     return $storage->$op (
1844       $rsrc,
1845       $op eq 'update' ? $values : (),
1846       \[$sql, @bind],
1847     );
1848   }
1849   else {
1850     # if all else fails - get all primary keys and operate over a ORed set
1851     # wrap in a transaction for consistency
1852     # this is where the group_by starts to matter
1853     my $subq_group_by;
1854     if ($needs_group_by_subq) {
1855       $subq_group_by = $attrs->{columns};
1856
1857       # make sure if there is a supplied group_by it matches the columns compiled above
1858       # perfectly. Anything else can not be sanely executed on most databases so croak
1859       # right then and there
1860       if ($existing_group_by) {
1861         my @current_group_by = map
1862           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1863           @$existing_group_by
1864         ;
1865
1866         if (
1867           join ("\x00", sort @current_group_by)
1868             ne
1869           join ("\x00", sort @$subq_group_by )
1870         ) {
1871           $self->throw_exception (
1872             "You have just attempted a $op operation on a resultset which does group_by"
1873             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1874             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1875             . ' kind of queries. Please retry the operation with a modified group_by or'
1876             . ' without using one at all.'
1877           );
1878         }
1879       }
1880     }
1881
1882     my $guard = $storage->txn_scope_guard;
1883
1884     my @op_condition;
1885     for my $row ($subrs->search({}, { group_by => $subq_group_by })->cursor->all) {
1886       push @op_condition, { map
1887         { $idcols->[$_] => $row->[$_] }
1888         (0 .. $#$idcols)
1889       };
1890     }
1891
1892     my $res = $storage->$op (
1893       $rsrc,
1894       $op eq 'update' ? $values : (),
1895       \@op_condition,
1896     );
1897
1898     $guard->commit;
1899
1900     return $res;
1901   }
1902 }
1903
1904 =head2 update
1905
1906 =over 4
1907
1908 =item Arguments: \%values
1909
1910 =item Return Value: $storage_rv
1911
1912 =back
1913
1914 Sets the specified columns in the resultset to the supplied values in a
1915 single query. Note that this will not run any accessor/set_column/update
1916 triggers, nor will it update any row object instances derived from this
1917 resultset (this includes the contents of the L<resultset cache|/set_cache>
1918 if any). See L</update_all> if you need to execute any on-update
1919 triggers or cascades defined either by you or a
1920 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1921
1922 The return value is a pass through of what the underlying
1923 storage backend returned, and may vary. See L<DBI/execute> for the most
1924 common case.
1925
1926 =head3 CAVEAT
1927
1928 Note that L</update> does not process/deflate any of the values passed in.
1929 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1930 ensure manually that any value passed to this method will stringify to
1931 something the RDBMS knows how to deal with. A notable example is the
1932 handling of L<DateTime> objects, for more info see:
1933 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1934
1935 =cut
1936
1937 sub update {
1938   my ($self, $values) = @_;
1939   $self->throw_exception('Values for update must be a hash')
1940     unless ref $values eq 'HASH';
1941
1942   return $self->_rs_update_delete ('update', $values);
1943 }
1944
1945 =head2 update_all
1946
1947 =over 4
1948
1949 =item Arguments: \%values
1950
1951 =item Return Value: 1
1952
1953 =back
1954
1955 Fetches all objects and updates them one at a time via
1956 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1957 triggers, while L</update> will not.
1958
1959 =cut
1960
1961 sub update_all {
1962   my ($self, $values) = @_;
1963   $self->throw_exception('Values for update_all must be a hash')
1964     unless ref $values eq 'HASH';
1965
1966   my $guard = $self->result_source->schema->txn_scope_guard;
1967   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1968   $guard->commit;
1969   return 1;
1970 }
1971
1972 =head2 delete
1973
1974 =over 4
1975
1976 =item Arguments: none
1977
1978 =item Return Value: $storage_rv
1979
1980 =back
1981
1982 Deletes the rows matching this resultset in a single query. Note that this
1983 will not run any delete triggers, nor will it alter the
1984 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1985 derived from this resultset (this includes the contents of the
1986 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1987 execute any on-delete triggers or cascades defined either by you or a
1988 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1989
1990 The return value is a pass through of what the underlying storage backend
1991 returned, and may vary. See L<DBI/execute> for the most common case.
1992
1993 =cut
1994
1995 sub delete {
1996   my $self = shift;
1997   $self->throw_exception('delete does not accept any arguments')
1998     if @_;
1999
2000   return $self->_rs_update_delete ('delete');
2001 }
2002
2003 =head2 delete_all
2004
2005 =over 4
2006
2007 =item Arguments: none
2008
2009 =item Return Value: 1
2010
2011 =back
2012
2013 Fetches all objects and deletes them one at a time via
2014 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2015 triggers, while L</delete> will not.
2016
2017 =cut
2018
2019 sub delete_all {
2020   my $self = shift;
2021   $self->throw_exception('delete_all does not accept any arguments')
2022     if @_;
2023
2024   my $guard = $self->result_source->schema->txn_scope_guard;
2025   $_->delete for $self->all;
2026   $guard->commit;
2027   return 1;
2028 }
2029
2030 =head2 populate
2031
2032 =over 4
2033
2034 =item Arguments: \@data;
2035
2036 =back
2037
2038 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
2039 For the arrayref of hashrefs style each hashref should be a structure suitable
2040 for submitting to a $resultset->create(...) method.
2041
2042 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
2043 to insert the data, as this is a faster method.
2044
2045 Otherwise, each set of data is inserted into the database using
2046 L<DBIx::Class::ResultSet/create>, and the resulting objects are
2047 accumulated into an array. The array itself, or an array reference
2048 is returned depending on scalar or list context.
2049
2050 Example:  Assuming an Artist Class that has many CDs Classes relating:
2051
2052   my $Artist_rs = $schema->resultset("Artist");
2053
2054   ## Void Context Example
2055   $Artist_rs->populate([
2056      { artistid => 4, name => 'Manufactured Crap', cds => [
2057         { title => 'My First CD', year => 2006 },
2058         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2059       ],
2060      },
2061      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2062         { title => 'My parents sold me to a record company', year => 2005 },
2063         { title => 'Why Am I So Ugly?', year => 2006 },
2064         { title => 'I Got Surgery and am now Popular', year => 2007 }
2065       ],
2066      },
2067   ]);
2068
2069   ## Array Context Example
2070   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
2071     { name => "Artist One"},
2072     { name => "Artist Two"},
2073     { name => "Artist Three", cds=> [
2074     { title => "First CD", year => 2007},
2075     { title => "Second CD", year => 2008},
2076   ]}
2077   ]);
2078
2079   print $ArtistOne->name; ## response is 'Artist One'
2080   print $ArtistThree->cds->count ## reponse is '2'
2081
2082 For the arrayref of arrayrefs style,  the first element should be a list of the
2083 fieldsnames to which the remaining elements are rows being inserted.  For
2084 example:
2085
2086   $Arstist_rs->populate([
2087     [qw/artistid name/],
2088     [100, 'A Formally Unknown Singer'],
2089     [101, 'A singer that jumped the shark two albums ago'],
2090     [102, 'An actually cool singer'],
2091   ]);
2092
2093 Please note an important effect on your data when choosing between void and
2094 wantarray context. Since void context goes straight to C<insert_bulk> in
2095 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
2096 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
2097 create primary keys for you, you will find that your PKs are empty.  In this
2098 case you will have to use the wantarray context in order to create those
2099 values.
2100
2101 =cut
2102
2103 sub populate {
2104   my $self = shift;
2105
2106   # cruft placed in standalone method
2107   my $data = $self->_normalize_populate_args(@_);
2108
2109   return unless @$data;
2110
2111   if(defined wantarray) {
2112     my @created;
2113     foreach my $item (@$data) {
2114       push(@created, $self->create($item));
2115     }
2116     return wantarray ? @created : \@created;
2117   }
2118   else {
2119     my $first = $data->[0];
2120
2121     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2122     # it relationship data
2123     my (@rels, @columns);
2124     my $rsrc = $self->result_source;
2125     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2126     for (keys %$first) {
2127       my $ref = ref $first->{$_};
2128       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2129         ? push @rels, $_
2130         : push @columns, $_
2131       ;
2132     }
2133
2134     my @pks = $rsrc->primary_columns;
2135
2136     ## do the belongs_to relationships
2137     foreach my $index (0..$#$data) {
2138
2139       # delegate to create() for any dataset without primary keys with specified relationships
2140       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2141         for my $r (@rels) {
2142           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2143             my @ret = $self->populate($data);
2144             return;
2145           }
2146         }
2147       }
2148
2149       foreach my $rel (@rels) {
2150         next unless ref $data->[$index]->{$rel} eq "HASH";
2151         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2152         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2153         my $related = $result->result_source->_resolve_condition(
2154           $reverse_relinfo->{cond},
2155           $self,
2156           $result,
2157           $rel,
2158         );
2159
2160         delete $data->[$index]->{$rel};
2161         $data->[$index] = {%{$data->[$index]}, %$related};
2162
2163         push @columns, keys %$related if $index == 0;
2164       }
2165     }
2166
2167     ## inherit the data locked in the conditions of the resultset
2168     my ($rs_data) = $self->_merge_with_rscond({});
2169     delete @{$rs_data}{@columns};
2170     my @inherit_cols = keys %$rs_data;
2171     my @inherit_data = values %$rs_data;
2172
2173     ## do bulk insert on current row
2174     $rsrc->storage->insert_bulk(
2175       $rsrc,
2176       [@columns, @inherit_cols],
2177       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
2178     );
2179
2180     ## do the has_many relationships
2181     foreach my $item (@$data) {
2182
2183       my $main_row;
2184
2185       foreach my $rel (@rels) {
2186         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2187
2188         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2189
2190         my $child = $main_row->$rel;
2191
2192         my $related = $child->result_source->_resolve_condition(
2193           $rels->{$rel}{cond},
2194           $child,
2195           $main_row,
2196           $rel,
2197         );
2198
2199         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2200         my @populate = map { {%$_, %$related} } @rows_to_add;
2201
2202         $child->populate( \@populate );
2203       }
2204     }
2205   }
2206 }
2207
2208
2209 # populate() argumnets went over several incarnations
2210 # What we ultimately support is AoH
2211 sub _normalize_populate_args {
2212   my ($self, $arg) = @_;
2213
2214   if (ref $arg eq 'ARRAY') {
2215     if (!@$arg) {
2216       return [];
2217     }
2218     elsif (ref $arg->[0] eq 'HASH') {
2219       return $arg;
2220     }
2221     elsif (ref $arg->[0] eq 'ARRAY') {
2222       my @ret;
2223       my @colnames = @{$arg->[0]};
2224       foreach my $values (@{$arg}[1 .. $#$arg]) {
2225         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2226       }
2227       return \@ret;
2228     }
2229   }
2230
2231   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2232 }
2233
2234 =head2 pager
2235
2236 =over 4
2237
2238 =item Arguments: none
2239
2240 =item Return Value: $pager
2241
2242 =back
2243
2244 Return Value a L<Data::Page> object for the current resultset. Only makes
2245 sense for queries with a C<page> attribute.
2246
2247 To get the full count of entries for a paged resultset, call
2248 C<total_entries> on the L<Data::Page> object.
2249
2250 =cut
2251
2252 sub pager {
2253   my ($self) = @_;
2254
2255   return $self->{pager} if $self->{pager};
2256
2257   my $attrs = $self->{attrs};
2258   if (!defined $attrs->{page}) {
2259     $self->throw_exception("Can't create pager for non-paged rs");
2260   }
2261   elsif ($attrs->{page} <= 0) {
2262     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2263   }
2264   $attrs->{rows} ||= 10;
2265
2266   # throw away the paging flags and re-run the count (possibly
2267   # with a subselect) to get the real total count
2268   my $count_attrs = { %$attrs };
2269   delete $count_attrs->{$_} for qw/rows offset page pager/;
2270
2271   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2272
2273   require DBIx::Class::ResultSet::Pager;
2274   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2275     sub { $total_rs->count },  #lazy-get the total
2276     $attrs->{rows},
2277     $self->{attrs}{page},
2278   );
2279 }
2280
2281 =head2 page
2282
2283 =over 4
2284
2285 =item Arguments: $page_number
2286
2287 =item Return Value: $rs
2288
2289 =back
2290
2291 Returns a resultset for the $page_number page of the resultset on which page
2292 is called, where each page contains a number of rows equal to the 'rows'
2293 attribute set on the resultset (10 by default).
2294
2295 =cut
2296
2297 sub page {
2298   my ($self, $page) = @_;
2299   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2300 }
2301
2302 =head2 new_result
2303
2304 =over 4
2305
2306 =item Arguments: \%vals
2307
2308 =item Return Value: $rowobject
2309
2310 =back
2311
2312 Creates a new row object in the resultset's result class and returns
2313 it. The row is not inserted into the database at this point, call
2314 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2315 will tell you whether the row object has been inserted or not.
2316
2317 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2318
2319 =cut
2320
2321 sub new_result {
2322   my ($self, $values) = @_;
2323
2324   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2325     if @_ > 2;
2326
2327   $self->throw_exception( "new_result expects a hashref" )
2328     unless (ref $values eq 'HASH');
2329
2330   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2331
2332   my %new = (
2333     %$merged_cond,
2334     @$cols_from_relations
2335       ? (-cols_from_relations => $cols_from_relations)
2336       : (),
2337     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2338   );
2339
2340   return $self->result_class->new(\%new);
2341 }
2342
2343 # _merge_with_rscond
2344 #
2345 # Takes a simple hash of K/V data and returns its copy merged with the
2346 # condition already present on the resultset. Additionally returns an
2347 # arrayref of value/condition names, which were inferred from related
2348 # objects (this is needed for in-memory related objects)
2349 sub _merge_with_rscond {
2350   my ($self, $data) = @_;
2351
2352   my (%new_data, @cols_from_relations);
2353
2354   my $alias = $self->{attrs}{alias};
2355
2356   if (! defined $self->{cond}) {
2357     # just massage $data below
2358   }
2359   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2360     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2361     @cols_from_relations = keys %new_data;
2362   }
2363   elsif (ref $self->{cond} ne 'HASH') {
2364     $self->throw_exception(
2365       "Can't abstract implicit construct, resultset condition not a hash"
2366     );
2367   }
2368   else {
2369     # precendence must be given to passed values over values inherited from
2370     # the cond, so the order here is important.
2371     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2372     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2373
2374     while ( my($col, $value) = each %implied ) {
2375       my $vref = ref $value;
2376       if (
2377         $vref eq 'HASH'
2378           and
2379         keys(%$value) == 1
2380           and
2381         (keys %$value)[0] eq '='
2382       ) {
2383         $new_data{$col} = $value->{'='};
2384       }
2385       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2386         $new_data{$col} = $value;
2387       }
2388     }
2389   }
2390
2391   %new_data = (
2392     %new_data,
2393     %{ $self->_remove_alias($data, $alias) },
2394   );
2395
2396   return (\%new_data, \@cols_from_relations);
2397 }
2398
2399 # _has_resolved_attr
2400 #
2401 # determines if the resultset defines at least one
2402 # of the attributes supplied
2403 #
2404 # used to determine if a subquery is neccessary
2405 #
2406 # supports some virtual attributes:
2407 #   -join
2408 #     This will scan for any joins being present on the resultset.
2409 #     It is not a mere key-search but a deep inspection of {from}
2410 #
2411
2412 sub _has_resolved_attr {
2413   my ($self, @attr_names) = @_;
2414
2415   my $attrs = $self->_resolved_attrs;
2416
2417   my %extra_checks;
2418
2419   for my $n (@attr_names) {
2420     if (grep { $n eq $_ } (qw/-join/) ) {
2421       $extra_checks{$n}++;
2422       next;
2423     }
2424
2425     my $attr =  $attrs->{$n};
2426
2427     next if not defined $attr;
2428
2429     if (ref $attr eq 'HASH') {
2430       return 1 if keys %$attr;
2431     }
2432     elsif (ref $attr eq 'ARRAY') {
2433       return 1 if @$attr;
2434     }
2435     else {
2436       return 1 if $attr;
2437     }
2438   }
2439
2440   # a resolved join is expressed as a multi-level from
2441   return 1 if (
2442     $extra_checks{-join}
2443       and
2444     ref $attrs->{from} eq 'ARRAY'
2445       and
2446     @{$attrs->{from}} > 1
2447   );
2448
2449   return 0;
2450 }
2451
2452 # _collapse_cond
2453 #
2454 # Recursively collapse the condition.
2455
2456 sub _collapse_cond {
2457   my ($self, $cond, $collapsed) = @_;
2458
2459   $collapsed ||= {};
2460
2461   if (ref $cond eq 'ARRAY') {
2462     foreach my $subcond (@$cond) {
2463       next unless ref $subcond;  # -or
2464       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2465     }
2466   }
2467   elsif (ref $cond eq 'HASH') {
2468     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2469       foreach my $subcond (@{$cond->{-and}}) {
2470         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2471       }
2472     }
2473     else {
2474       foreach my $col (keys %$cond) {
2475         my $value = $cond->{$col};
2476         $collapsed->{$col} = $value;
2477       }
2478     }
2479   }
2480
2481   return $collapsed;
2482 }
2483
2484 # _remove_alias
2485 #
2486 # Remove the specified alias from the specified query hash. A copy is made so
2487 # the original query is not modified.
2488
2489 sub _remove_alias {
2490   my ($self, $query, $alias) = @_;
2491
2492   my %orig = %{ $query || {} };
2493   my %unaliased;
2494
2495   foreach my $key (keys %orig) {
2496     if ($key !~ /\./) {
2497       $unaliased{$key} = $orig{$key};
2498       next;
2499     }
2500     $unaliased{$1} = $orig{$key}
2501       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2502   }
2503
2504   return \%unaliased;
2505 }
2506
2507 =head2 as_query
2508
2509 =over 4
2510
2511 =item Arguments: none
2512
2513 =item Return Value: \[ $sql, @bind ]
2514
2515 =back
2516
2517 Returns the SQL query and bind vars associated with the invocant.
2518
2519 This is generally used as the RHS for a subquery.
2520
2521 =cut
2522
2523 sub as_query {
2524   my $self = shift;
2525
2526   my $attrs = $self->_resolved_attrs_copy;
2527
2528   # For future use:
2529   #
2530   # in list ctx:
2531   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2532   # $sql also has no wrapping parenthesis in list ctx
2533   #
2534   my $sqlbind = $self->result_source->storage
2535     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2536
2537   return $sqlbind;
2538 }
2539
2540 =head2 find_or_new
2541
2542 =over 4
2543
2544 =item Arguments: \%vals, \%attrs?
2545
2546 =item Return Value: $rowobject
2547
2548 =back
2549
2550   my $artist = $schema->resultset('Artist')->find_or_new(
2551     { artist => 'fred' }, { key => 'artists' });
2552
2553   $cd->cd_to_producer->find_or_new({ producer => $producer },
2554                                    { key => 'primary });
2555
2556 Find an existing record from this resultset using L</find>. if none exists,
2557 instantiate a new result object and return it. The object will not be saved
2558 into your storage until you call L<DBIx::Class::Row/insert> on it.
2559
2560 You most likely want this method when looking for existing rows using a unique
2561 constraint that is not the primary key, or looking for related rows.
2562
2563 If you want objects to be saved immediately, use L</find_or_create> instead.
2564
2565 B<Note>: Make sure to read the documentation of L</find> and understand the
2566 significance of the C<key> attribute, as its lack may skew your search, and
2567 subsequently result in spurious new objects.
2568
2569 B<Note>: Take care when using C<find_or_new> with a table having
2570 columns with default values that you intend to be automatically
2571 supplied by the database (e.g. an auto_increment primary key column).
2572 In normal usage, the value of such columns should NOT be included at
2573 all in the call to C<find_or_new>, even when set to C<undef>.
2574
2575 =cut
2576
2577 sub find_or_new {
2578   my $self     = shift;
2579   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2580   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2581   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2582     return $row;
2583   }
2584   return $self->new_result($hash);
2585 }
2586
2587 =head2 create
2588
2589 =over 4
2590
2591 =item Arguments: \%vals
2592
2593 =item Return Value: a L<DBIx::Class::Row> $object
2594
2595 =back
2596
2597 Attempt to create a single new row or a row with multiple related rows
2598 in the table represented by the resultset (and related tables). This
2599 will not check for duplicate rows before inserting, use
2600 L</find_or_create> to do that.
2601
2602 To create one row for this resultset, pass a hashref of key/value
2603 pairs representing the columns of the table and the values you wish to
2604 store. If the appropriate relationships are set up, foreign key fields
2605 can also be passed an object representing the foreign row, and the
2606 value will be set to its primary key.
2607
2608 To create related objects, pass a hashref of related-object column values
2609 B<keyed on the relationship name>. If the relationship is of type C<multi>
2610 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2611 The process will correctly identify columns holding foreign keys, and will
2612 transparently populate them from the keys of the corresponding relation.
2613 This can be applied recursively, and will work correctly for a structure
2614 with an arbitrary depth and width, as long as the relationships actually
2615 exists and the correct column data has been supplied.
2616
2617
2618 Instead of hashrefs of plain related data (key/value pairs), you may
2619 also pass new or inserted objects. New objects (not inserted yet, see
2620 L</new>), will be inserted into their appropriate tables.
2621
2622 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2623
2624 Example of creating a new row.
2625
2626   $person_rs->create({
2627     name=>"Some Person",
2628     email=>"somebody@someplace.com"
2629   });
2630
2631 Example of creating a new row and also creating rows in a related C<has_many>
2632 or C<has_one> resultset.  Note Arrayref.
2633
2634   $artist_rs->create(
2635      { artistid => 4, name => 'Manufactured Crap', cds => [
2636         { title => 'My First CD', year => 2006 },
2637         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2638       ],
2639      },
2640   );
2641
2642 Example of creating a new row and also creating a row in a related
2643 C<belongs_to> resultset. Note Hashref.
2644
2645   $cd_rs->create({
2646     title=>"Music for Silly Walks",
2647     year=>2000,
2648     artist => {
2649       name=>"Silly Musician",
2650     }
2651   });
2652
2653 =over
2654
2655 =item WARNING
2656
2657 When subclassing ResultSet never attempt to override this method. Since
2658 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2659 lot of the internals simply never call it, so your override will be
2660 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2661 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2662 L</create> process you need to intervene. See also warning pertaining to
2663 L</new>.
2664
2665 =back
2666
2667 =cut
2668
2669 sub create {
2670   my ($self, $attrs) = @_;
2671   $self->throw_exception( "create needs a hashref" )
2672     unless ref $attrs eq 'HASH';
2673   return $self->new_result($attrs)->insert;
2674 }
2675
2676 =head2 find_or_create
2677
2678 =over 4
2679
2680 =item Arguments: \%vals, \%attrs?
2681
2682 =item Return Value: $rowobject
2683
2684 =back
2685
2686   $cd->cd_to_producer->find_or_create({ producer => $producer },
2687                                       { key => 'primary' });
2688
2689 Tries to find a record based on its primary key or unique constraints; if none
2690 is found, creates one and returns that instead.
2691
2692   my $cd = $schema->resultset('CD')->find_or_create({
2693     cdid   => 5,
2694     artist => 'Massive Attack',
2695     title  => 'Mezzanine',
2696     year   => 2005,
2697   });
2698
2699 Also takes an optional C<key> attribute, to search by a specific key or unique
2700 constraint. For example:
2701
2702   my $cd = $schema->resultset('CD')->find_or_create(
2703     {
2704       artist => 'Massive Attack',
2705       title  => 'Mezzanine',
2706     },
2707     { key => 'cd_artist_title' }
2708   );
2709
2710 B<Note>: Make sure to read the documentation of L</find> and understand the
2711 significance of the C<key> attribute, as its lack may skew your search, and
2712 subsequently result in spurious row creation.
2713
2714 B<Note>: Because find_or_create() reads from the database and then
2715 possibly inserts based on the result, this method is subject to a race
2716 condition. Another process could create a record in the table after
2717 the find has completed and before the create has started. To avoid
2718 this problem, use find_or_create() inside a transaction.
2719
2720 B<Note>: Take care when using C<find_or_create> with a table having
2721 columns with default values that you intend to be automatically
2722 supplied by the database (e.g. an auto_increment primary key column).
2723 In normal usage, the value of such columns should NOT be included at
2724 all in the call to C<find_or_create>, even when set to C<undef>.
2725
2726 See also L</find> and L</update_or_create>. For information on how to declare
2727 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2728
2729 If you need to know if an existing row was found or a new one created use
2730 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2731 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2732 database!
2733
2734   my $cd = $schema->resultset('CD')->find_or_new({
2735     cdid   => 5,
2736     artist => 'Massive Attack',
2737     title  => 'Mezzanine',
2738     year   => 2005,
2739   });
2740
2741   if( $cd->in_storage ) {
2742       # do some stuff
2743       $cd->insert;
2744   }
2745
2746 =cut
2747
2748 sub find_or_create {
2749   my $self     = shift;
2750   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2751   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2752   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2753     return $row;
2754   }
2755   return $self->create($hash);
2756 }
2757
2758 =head2 update_or_create
2759
2760 =over 4
2761
2762 =item Arguments: \%col_values, { key => $unique_constraint }?
2763
2764 =item Return Value: $row_object
2765
2766 =back
2767
2768   $resultset->update_or_create({ col => $val, ... });
2769
2770 Like L</find_or_create>, but if a row is found it is immediately updated via
2771 C<< $found_row->update (\%col_values) >>.
2772
2773
2774 Takes an optional C<key> attribute to search on a specific unique constraint.
2775 For example:
2776
2777   # In your application
2778   my $cd = $schema->resultset('CD')->update_or_create(
2779     {
2780       artist => 'Massive Attack',
2781       title  => 'Mezzanine',
2782       year   => 1998,
2783     },
2784     { key => 'cd_artist_title' }
2785   );
2786
2787   $cd->cd_to_producer->update_or_create({
2788     producer => $producer,
2789     name => 'harry',
2790   }, {
2791     key => 'primary',
2792   });
2793
2794 B<Note>: Make sure to read the documentation of L</find> and understand the
2795 significance of the C<key> attribute, as its lack may skew your search, and
2796 subsequently result in spurious row creation.
2797
2798 B<Note>: Take care when using C<update_or_create> with a table having
2799 columns with default values that you intend to be automatically
2800 supplied by the database (e.g. an auto_increment primary key column).
2801 In normal usage, the value of such columns should NOT be included at
2802 all in the call to C<update_or_create>, even when set to C<undef>.
2803
2804 See also L</find> and L</find_or_create>. For information on how to declare
2805 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2806
2807 If you need to know if an existing row was updated or a new one created use
2808 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2809 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2810 database!
2811
2812   my $cd = $schema->resultset('CD')->update_or_new(
2813     {
2814       artist => 'Massive Attack',
2815       title  => 'Mezzanine',
2816       year   => 1998,
2817     },
2818     { key => 'cd_artist_title' }
2819   );
2820
2821   if( $cd->in_storage ) {
2822       # do some stuff
2823       $cd->insert;
2824   }
2825
2826 =cut
2827
2828 sub update_or_create {
2829   my $self = shift;
2830   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2831   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2832
2833   my $row = $self->find($cond, $attrs);
2834   if (defined $row) {
2835     $row->update($cond);
2836     return $row;
2837   }
2838
2839   return $self->create($cond);
2840 }
2841
2842 =head2 update_or_new
2843
2844 =over 4
2845
2846 =item Arguments: \%col_values, { key => $unique_constraint }?
2847
2848 =item Return Value: $rowobject
2849
2850 =back
2851
2852   $resultset->update_or_new({ col => $val, ... });
2853
2854 Like L</find_or_new> but if a row is found it is immediately updated via
2855 C<< $found_row->update (\%col_values) >>.
2856
2857 For example:
2858
2859   # In your application
2860   my $cd = $schema->resultset('CD')->update_or_new(
2861     {
2862       artist => 'Massive Attack',
2863       title  => 'Mezzanine',
2864       year   => 1998,
2865     },
2866     { key => 'cd_artist_title' }
2867   );
2868
2869   if ($cd->in_storage) {
2870       # the cd was updated
2871   }
2872   else {
2873       # the cd is not yet in the database, let's insert it
2874       $cd->insert;
2875   }
2876
2877 B<Note>: Make sure to read the documentation of L</find> and understand the
2878 significance of the C<key> attribute, as its lack may skew your search, and
2879 subsequently result in spurious new objects.
2880
2881 B<Note>: Take care when using C<update_or_new> with a table having
2882 columns with default values that you intend to be automatically
2883 supplied by the database (e.g. an auto_increment primary key column).
2884 In normal usage, the value of such columns should NOT be included at
2885 all in the call to C<update_or_new>, even when set to C<undef>.
2886
2887 See also L</find>, L</find_or_create> and L</find_or_new>.
2888
2889 =cut
2890
2891 sub update_or_new {
2892     my $self  = shift;
2893     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2894     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2895
2896     my $row = $self->find( $cond, $attrs );
2897     if ( defined $row ) {
2898         $row->update($cond);
2899         return $row;
2900     }
2901
2902     return $self->new_result($cond);
2903 }
2904
2905 =head2 get_cache
2906
2907 =over 4
2908
2909 =item Arguments: none
2910
2911 =item Return Value: \@cache_objects | undef
2912
2913 =back
2914
2915 Gets the contents of the cache for the resultset, if the cache is set.
2916
2917 The cache is populated either by using the L</prefetch> attribute to
2918 L</search> or by calling L</set_cache>.
2919
2920 =cut
2921
2922 sub get_cache {
2923   shift->{all_cache};
2924 }
2925
2926 =head2 set_cache
2927
2928 =over 4
2929
2930 =item Arguments: \@cache_objects
2931
2932 =item Return Value: \@cache_objects
2933
2934 =back
2935
2936 Sets the contents of the cache for the resultset. Expects an arrayref
2937 of objects of the same class as those produced by the resultset. Note that
2938 if the cache is set the resultset will return the cached objects rather
2939 than re-querying the database even if the cache attr is not set.
2940
2941 The contents of the cache can also be populated by using the
2942 L</prefetch> attribute to L</search>.
2943
2944 =cut
2945
2946 sub set_cache {
2947   my ( $self, $data ) = @_;
2948   $self->throw_exception("set_cache requires an arrayref")
2949       if defined($data) && (ref $data ne 'ARRAY');
2950   $self->{all_cache} = $data;
2951 }
2952
2953 =head2 clear_cache
2954
2955 =over 4
2956
2957 =item Arguments: none
2958
2959 =item Return Value: undef
2960
2961 =back
2962
2963 Clears the cache for the resultset.
2964
2965 =cut
2966
2967 sub clear_cache {
2968   shift->set_cache(undef);
2969 }
2970
2971 =head2 is_paged
2972
2973 =over 4
2974
2975 =item Arguments: none
2976
2977 =item Return Value: true, if the resultset has been paginated
2978
2979 =back
2980
2981 =cut
2982
2983 sub is_paged {
2984   my ($self) = @_;
2985   return !!$self->{attrs}{page};
2986 }
2987
2988 =head2 is_ordered
2989
2990 =over 4
2991
2992 =item Arguments: none
2993
2994 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2995
2996 =back
2997
2998 =cut
2999
3000 sub is_ordered {
3001   my ($self) = @_;
3002   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3003 }
3004
3005 =head2 related_resultset
3006
3007 =over 4
3008
3009 =item Arguments: $relationship_name
3010
3011 =item Return Value: $resultset
3012
3013 =back
3014
3015 Returns a related resultset for the supplied relationship name.
3016
3017   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3018
3019 =cut
3020
3021 sub related_resultset {
3022   my ($self, $rel) = @_;
3023
3024   $self->{related_resultsets} ||= {};
3025   return $self->{related_resultsets}{$rel} ||= do {
3026     my $rsrc = $self->result_source;
3027     my $rel_info = $rsrc->relationship_info($rel);
3028
3029     $self->throw_exception(
3030       "search_related: result source '" . $rsrc->source_name .
3031         "' has no such relationship $rel")
3032       unless $rel_info;
3033
3034     my $attrs = $self->_chain_relationship($rel);
3035
3036     my $join_count = $attrs->{seen_join}{$rel};
3037
3038     my $alias = $self->result_source->storage
3039         ->relname_to_table_alias($rel, $join_count);
3040
3041     # since this is search_related, and we already slid the select window inwards
3042     # (the select/as attrs were deleted in the beginning), we need to flip all
3043     # left joins to inner, so we get the expected results
3044     # read the comment on top of the actual function to see what this does
3045     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3046
3047
3048     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3049     delete @{$attrs}{qw(result_class alias)};
3050
3051     my $new_cache;
3052
3053     if (my $cache = $self->get_cache) {
3054       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3055         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3056                         @$cache ];
3057       }
3058     }
3059
3060     my $rel_source = $rsrc->related_source($rel);
3061
3062     my $new = do {
3063
3064       # The reason we do this now instead of passing the alias to the
3065       # search_rs below is that if you wrap/overload resultset on the
3066       # source you need to know what alias it's -going- to have for things
3067       # to work sanely (e.g. RestrictWithObject wants to be able to add
3068       # extra query restrictions, and these may need to be $alias.)
3069
3070       my $rel_attrs = $rel_source->resultset_attributes;
3071       local $rel_attrs->{alias} = $alias;
3072
3073       $rel_source->resultset
3074                  ->search_rs(
3075                      undef, {
3076                        %$attrs,
3077                        where => $attrs->{where},
3078                    });
3079     };
3080     $new->set_cache($new_cache) if $new_cache;
3081     $new;
3082   };
3083 }
3084
3085 =head2 current_source_alias
3086
3087 =over 4
3088
3089 =item Arguments: none
3090
3091 =item Return Value: $source_alias
3092
3093 =back
3094
3095 Returns the current table alias for the result source this resultset is built
3096 on, that will be used in the SQL query. Usually it is C<me>.
3097
3098 Currently the source alias that refers to the result set returned by a
3099 L</search>/L</find> family method depends on how you got to the resultset: it's
3100 C<me> by default, but eg. L</search_related> aliases it to the related result
3101 source name (and keeps C<me> referring to the original result set). The long
3102 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3103 (and make this method unnecessary).
3104
3105 Thus it's currently necessary to use this method in predefined queries (see
3106 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3107 source alias of the current result set:
3108
3109   # in a result set class
3110   sub modified_by {
3111     my ($self, $user) = @_;
3112
3113     my $me = $self->current_source_alias;
3114
3115     return $self->search({
3116       "$me.modified" => $user->id,
3117     });
3118   }
3119
3120 =cut
3121
3122 sub current_source_alias {
3123   my ($self) = @_;
3124
3125   return ($self->{attrs} || {})->{alias} || 'me';
3126 }
3127
3128 =head2 as_subselect_rs
3129
3130 =over 4
3131
3132 =item Arguments: none
3133
3134 =item Return Value: $resultset
3135
3136 =back
3137
3138 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3139 "virtual view" by including it as a subquery within the from clause.  From this
3140 point on, any joined tables are inaccessible to ->search on the resultset (as if
3141 it were simply where-filtered without joins).  For example:
3142
3143  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3144
3145  # 'x' now pollutes the query namespace
3146
3147  # So the following works as expected
3148  my $ok_rs = $rs->search({'x.other' => 1});
3149
3150  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3151  # def) we look for one row with contradictory terms and join in another table
3152  # (aliased 'x_2') which we never use
3153  my $broken_rs = $rs->search({'x.name' => 'def'});
3154
3155  my $rs2 = $rs->as_subselect_rs;
3156
3157  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3158  my $not_joined_rs = $rs2->search({'x.other' => 1});
3159
3160  # works as expected: finds a 'table' row related to two x rows (abc and def)
3161  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3162
3163 Another example of when one might use this would be to select a subset of
3164 columns in a group by clause:
3165
3166  my $rs = $schema->resultset('Bar')->search(undef, {
3167    group_by => [qw{ id foo_id baz_id }],
3168  })->as_subselect_rs->search(undef, {
3169    columns => [qw{ id foo_id }]
3170  });
3171
3172 In the above example normally columns would have to be equal to the group by,
3173 but because we isolated the group by into a subselect the above works.
3174
3175 =cut
3176
3177 sub as_subselect_rs {
3178   my $self = shift;
3179
3180   my $attrs = $self->_resolved_attrs;
3181
3182   my $fresh_rs = (ref $self)->new (
3183     $self->result_source
3184   );
3185
3186   # these pieces will be locked in the subquery
3187   delete $fresh_rs->{cond};
3188   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3189
3190   return $fresh_rs->search( {}, {
3191     from => [{
3192       $attrs->{alias} => $self->as_query,
3193       -alias  => $attrs->{alias},
3194       -rsrc   => $self->result_source,
3195     }],
3196     alias => $attrs->{alias},
3197   });
3198 }
3199
3200 # This code is called by search_related, and makes sure there
3201 # is clear separation between the joins before, during, and
3202 # after the relationship. This information is needed later
3203 # in order to properly resolve prefetch aliases (any alias
3204 # with a relation_chain_depth less than the depth of the
3205 # current prefetch is not considered)
3206 #
3207 # The increments happen twice per join. An even number means a
3208 # relationship specified via a search_related, whereas an odd
3209 # number indicates a join/prefetch added via attributes
3210 #
3211 # Also this code will wrap the current resultset (the one we
3212 # chain to) in a subselect IFF it contains limiting attributes
3213 sub _chain_relationship {
3214   my ($self, $rel) = @_;
3215   my $source = $self->result_source;
3216   my $attrs = { %{$self->{attrs}||{}} };
3217
3218   # we need to take the prefetch the attrs into account before we
3219   # ->_resolve_join as otherwise they get lost - captainL
3220   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3221
3222   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3223
3224   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3225
3226   my $from;
3227   my @force_subq_attrs = qw/offset rows group_by having/;
3228
3229   if (
3230     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3231       ||
3232     $self->_has_resolved_attr (@force_subq_attrs)
3233   ) {
3234     # Nuke the prefetch (if any) before the new $rs attrs
3235     # are resolved (prefetch is useless - we are wrapping
3236     # a subquery anyway).
3237     my $rs_copy = $self->search;
3238     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3239       $rs_copy->{attrs}{join},
3240       delete $rs_copy->{attrs}{prefetch},
3241     );
3242
3243     $from = [{
3244       -rsrc   => $source,
3245       -alias  => $attrs->{alias},
3246       $attrs->{alias} => $rs_copy->as_query,
3247     }];
3248     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3249     $seen->{-relation_chain_depth} = 0;
3250   }
3251   elsif ($attrs->{from}) {  #shallow copy suffices
3252     $from = [ @{$attrs->{from}} ];
3253   }
3254   else {
3255     $from = [{
3256       -rsrc  => $source,
3257       -alias => $attrs->{alias},
3258       $attrs->{alias} => $source->from,
3259     }];
3260   }
3261
3262   my $jpath = ($seen->{-relation_chain_depth})
3263     ? $from->[-1][0]{-join_path}
3264     : [];
3265
3266   my @requested_joins = $source->_resolve_join(
3267     $join,
3268     $attrs->{alias},
3269     $seen,
3270     $jpath,
3271   );
3272
3273   push @$from, @requested_joins;
3274
3275   $seen->{-relation_chain_depth}++;
3276
3277   # if $self already had a join/prefetch specified on it, the requested
3278   # $rel might very well be already included. What we do in this case
3279   # is effectively a no-op (except that we bump up the chain_depth on
3280   # the join in question so we could tell it *is* the search_related)
3281   my $already_joined;
3282
3283   # we consider the last one thus reverse
3284   for my $j (reverse @requested_joins) {
3285     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3286     if ($rel eq $last_j) {
3287       $j->[0]{-relation_chain_depth}++;
3288       $already_joined++;
3289       last;
3290     }
3291   }
3292
3293   unless ($already_joined) {
3294     push @$from, $source->_resolve_join(
3295       $rel,
3296       $attrs->{alias},
3297       $seen,
3298       $jpath,
3299     );
3300   }
3301
3302   $seen->{-relation_chain_depth}++;
3303
3304   return {%$attrs, from => $from, seen_join => $seen};
3305 }
3306
3307 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3308 sub _resolved_attrs_copy {
3309   my $self = shift;
3310   return { %{$self->_resolved_attrs (@_)} };
3311 }
3312
3313 sub _resolved_attrs {
3314   my $self = shift;
3315   return $self->{_attrs} if $self->{_attrs};
3316
3317   my $attrs  = { %{ $self->{attrs} || {} } };
3318   my $source = $self->result_source;
3319   my $alias  = $attrs->{alias};
3320
3321   # default selection list
3322   $attrs->{columns} = [ $source->columns ]
3323     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3324
3325   # merge selectors together
3326   for (qw/columns select as/) {
3327     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3328       if $attrs->{$_} or $attrs->{"+$_"};
3329   }
3330
3331   # disassemble columns
3332   my (@sel, @as);
3333   if (my $cols = delete $attrs->{columns}) {
3334     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3335       if (ref $c eq 'HASH') {
3336         for my $as (keys %$c) {
3337           push @sel, $c->{$as};
3338           push @as, $as;
3339         }
3340       }
3341       else {
3342         push @sel, $c;
3343         push @as, $c;
3344       }
3345     }
3346   }
3347
3348   # when trying to weed off duplicates later do not go past this point -
3349   # everything added from here on is unbalanced "anyone's guess" stuff
3350   my $dedup_stop_idx = $#as;
3351
3352   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3353     if $attrs->{as};
3354   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3355     if $attrs->{select};
3356
3357   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3358   for (@sel) {
3359     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3360   }
3361
3362   # disqualify all $alias.col as-bits (collapser mandated)
3363   for (@as) {
3364     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3365   }
3366
3367   # de-duplicate the result (remove *identical* select/as pairs)
3368   # and also die on duplicate {as} pointing to different {select}s
3369   # not using a c-style for as the condition is prone to shrinkage
3370   my $seen;
3371   my $i = 0;
3372   while ($i <= $dedup_stop_idx) {
3373     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3374       splice @sel, $i, 1;
3375       splice @as, $i, 1;
3376       $dedup_stop_idx--;
3377     }
3378     elsif ($seen->{$as[$i]}++) {
3379       $self->throw_exception(
3380         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3381       );
3382     }
3383     else {
3384       $i++;
3385     }
3386   }
3387
3388   $attrs->{select} = \@sel;
3389   $attrs->{as} = \@as;
3390
3391   $attrs->{from} ||= [{
3392     -rsrc   => $source,
3393     -alias  => $self->{attrs}{alias},
3394     $self->{attrs}{alias} => $source->from,
3395   }];
3396
3397   if ( $attrs->{join} || $attrs->{prefetch} ) {
3398
3399     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3400       if ref $attrs->{from} ne 'ARRAY';
3401
3402     my $join = (delete $attrs->{join}) || {};
3403
3404     if ( defined $attrs->{prefetch} ) {
3405       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3406     }
3407
3408     $attrs->{from} =    # have to copy here to avoid corrupting the original
3409       [
3410         @{ $attrs->{from} },
3411         $source->_resolve_join(
3412           $join,
3413           $alias,
3414           { %{ $attrs->{seen_join} || {} } },
3415           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3416             ? $attrs->{from}[-1][0]{-join_path}
3417             : []
3418           ,
3419         )
3420       ];
3421   }
3422
3423   if ( defined $attrs->{order_by} ) {
3424     $attrs->{order_by} = (
3425       ref( $attrs->{order_by} ) eq 'ARRAY'
3426       ? [ @{ $attrs->{order_by} } ]
3427       : [ $attrs->{order_by} || () ]
3428     );
3429   }
3430
3431   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3432     $attrs->{group_by} = [ $attrs->{group_by} ];
3433   }
3434
3435   # generate the distinct induced group_by early, as prefetch will be carried via a
3436   # subquery (since a group_by is present)
3437   if (delete $attrs->{distinct}) {
3438     if ($attrs->{group_by}) {
3439       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3440     }
3441     else {
3442       # distinct affects only the main selection part, not what prefetch may
3443       # add below.
3444       $attrs->{group_by} = $source->storage->_group_over_selection (
3445         $attrs->{from},
3446         $attrs->{select},
3447         $attrs->{order_by},
3448       );
3449     }
3450   }
3451
3452   $attrs->{collapse} ||= {};
3453   if ($attrs->{prefetch}) {
3454
3455     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3456       if $attrs->{_dark_selector};
3457
3458     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3459
3460     my $prefetch_ordering = [];
3461
3462     # this is a separate structure (we don't look in {from} directly)
3463     # as the resolver needs to shift things off the lists to work
3464     # properly (identical-prefetches on different branches)
3465     my $join_map = {};
3466     if (ref $attrs->{from} eq 'ARRAY') {
3467
3468       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3469
3470       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3471         next unless $j->[0]{-alias};
3472         next unless $j->[0]{-join_path};
3473         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3474
3475         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3476
3477         my $p = $join_map;
3478         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3479         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3480       }
3481     }
3482
3483     my @prefetch =
3484       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3485
3486     # we need to somehow mark which columns came from prefetch
3487     if (@prefetch) {
3488       my $sel_end = $#{$attrs->{select}};
3489       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3490     }
3491
3492     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3493     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3494
3495     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3496     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3497   }
3498
3499   # if both page and offset are specified, produce a combined offset
3500   # even though it doesn't make much sense, this is what pre 081xx has
3501   # been doing
3502   if (my $page = delete $attrs->{page}) {
3503     $attrs->{offset} =
3504       ($attrs->{rows} * ($page - 1))
3505             +
3506       ($attrs->{offset} || 0)
3507     ;
3508   }
3509
3510   return $self->{_attrs} = $attrs;
3511 }
3512
3513 sub _rollout_attr {
3514   my ($self, $attr) = @_;
3515
3516   if (ref $attr eq 'HASH') {
3517     return $self->_rollout_hash($attr);
3518   } elsif (ref $attr eq 'ARRAY') {
3519     return $self->_rollout_array($attr);
3520   } else {
3521     return [$attr];
3522   }
3523 }
3524
3525 sub _rollout_array {
3526   my ($self, $attr) = @_;
3527
3528   my @rolled_array;
3529   foreach my $element (@{$attr}) {
3530     if (ref $element eq 'HASH') {
3531       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3532     } elsif (ref $element eq 'ARRAY') {
3533       #  XXX - should probably recurse here
3534       push( @rolled_array, @{$self->_rollout_array($element)} );
3535     } else {
3536       push( @rolled_array, $element );
3537     }
3538   }
3539   return \@rolled_array;
3540 }
3541
3542 sub _rollout_hash {
3543   my ($self, $attr) = @_;
3544
3545   my @rolled_array;
3546   foreach my $key (keys %{$attr}) {
3547     push( @rolled_array, { $key => $attr->{$key} } );
3548   }
3549   return \@rolled_array;
3550 }
3551
3552 sub _calculate_score {
3553   my ($self, $a, $b) = @_;
3554
3555   if (defined $a xor defined $b) {
3556     return 0;
3557   }
3558   elsif (not defined $a) {
3559     return 1;
3560   }
3561
3562   if (ref $b eq 'HASH') {
3563     my ($b_key) = keys %{$b};
3564     if (ref $a eq 'HASH') {
3565       my ($a_key) = keys %{$a};
3566       if ($a_key eq $b_key) {
3567         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3568       } else {
3569         return 0;
3570       }
3571     } else {
3572       return ($a eq $b_key) ? 1 : 0;
3573     }
3574   } else {
3575     if (ref $a eq 'HASH') {
3576       my ($a_key) = keys %{$a};
3577       return ($b eq $a_key) ? 1 : 0;
3578     } else {
3579       return ($b eq $a) ? 1 : 0;
3580     }
3581   }
3582 }
3583
3584 sub _merge_joinpref_attr {
3585   my ($self, $orig, $import) = @_;
3586
3587   return $import unless defined($orig);
3588   return $orig unless defined($import);
3589
3590   $orig = $self->_rollout_attr($orig);
3591   $import = $self->_rollout_attr($import);
3592
3593   my $seen_keys;
3594   foreach my $import_element ( @{$import} ) {
3595     # find best candidate from $orig to merge $b_element into
3596     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3597     foreach my $orig_element ( @{$orig} ) {
3598       my $score = $self->_calculate_score( $orig_element, $import_element );
3599       if ($score > $best_candidate->{score}) {
3600         $best_candidate->{position} = $position;
3601         $best_candidate->{score} = $score;
3602       }
3603       $position++;
3604     }
3605     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3606     $import_key = '' if not defined $import_key;
3607
3608     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3609       push( @{$orig}, $import_element );
3610     } else {
3611       my $orig_best = $orig->[$best_candidate->{position}];
3612       # merge orig_best and b_element together and replace original with merged
3613       if (ref $orig_best ne 'HASH') {
3614         $orig->[$best_candidate->{position}] = $import_element;
3615       } elsif (ref $import_element eq 'HASH') {
3616         my ($key) = keys %{$orig_best};
3617         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3618       }
3619     }
3620     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3621   }
3622
3623   return $orig;
3624 }
3625
3626 {
3627   my $hm;
3628
3629   sub _merge_attr {
3630     $hm ||= do {
3631       require Hash::Merge;
3632       my $hm = Hash::Merge->new;
3633
3634       $hm->specify_behavior({
3635         SCALAR => {
3636           SCALAR => sub {
3637             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3638
3639             if ($defl xor $defr) {
3640               return [ $defl ? $_[0] : $_[1] ];
3641             }
3642             elsif (! $defl) {
3643               return [];
3644             }
3645             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3646               return [ $_[0] ];
3647             }
3648             else {
3649               return [$_[0], $_[1]];
3650             }
3651           },
3652           ARRAY => sub {
3653             return $_[1] if !defined $_[0];
3654             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3655             return [$_[0], @{$_[1]}]
3656           },
3657           HASH  => sub {
3658             return [] if !defined $_[0] and !keys %{$_[1]};
3659             return [ $_[1] ] if !defined $_[0];
3660             return [ $_[0] ] if !keys %{$_[1]};
3661             return [$_[0], $_[1]]
3662           },
3663         },
3664         ARRAY => {
3665           SCALAR => sub {
3666             return $_[0] if !defined $_[1];
3667             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3668             return [@{$_[0]}, $_[1]]
3669           },
3670           ARRAY => sub {
3671             my @ret = @{$_[0]} or return $_[1];
3672             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3673             my %idx = map { $_ => 1 } @ret;
3674             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3675             \@ret;
3676           },
3677           HASH => sub {
3678             return [ $_[1] ] if ! @{$_[0]};
3679             return $_[0] if !keys %{$_[1]};
3680             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3681             return [ @{$_[0]}, $_[1] ];
3682           },
3683         },
3684         HASH => {
3685           SCALAR => sub {
3686             return [] if !keys %{$_[0]} and !defined $_[1];
3687             return [ $_[0] ] if !defined $_[1];
3688             return [ $_[1] ] if !keys %{$_[0]};
3689             return [$_[0], $_[1]]
3690           },
3691           ARRAY => sub {
3692             return [] if !keys %{$_[0]} and !@{$_[1]};
3693             return [ $_[0] ] if !@{$_[1]};
3694             return $_[1] if !keys %{$_[0]};
3695             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3696             return [ $_[0], @{$_[1]} ];
3697           },
3698           HASH => sub {
3699             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3700             return [ $_[0] ] if !keys %{$_[1]};
3701             return [ $_[1] ] if !keys %{$_[0]};
3702             return [ $_[0] ] if $_[0] eq $_[1];
3703             return [ $_[0], $_[1] ];
3704           },
3705         }
3706       } => 'DBIC_RS_ATTR_MERGER');
3707       $hm;
3708     };
3709
3710     return $hm->merge ($_[1], $_[2]);
3711   }
3712 }
3713
3714 sub STORABLE_freeze {
3715   my ($self, $cloning) = @_;
3716   my $to_serialize = { %$self };
3717
3718   # A cursor in progress can't be serialized (and would make little sense anyway)
3719   delete $to_serialize->{cursor};
3720
3721   # nor is it sensical to store a not-yet-fired-count pager
3722   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3723     delete $to_serialize->{pager};
3724   }
3725
3726   Storable::nfreeze($to_serialize);
3727 }
3728
3729 # need this hook for symmetry
3730 sub STORABLE_thaw {
3731   my ($self, $cloning, $serialized) = @_;
3732
3733   %$self = %{ Storable::thaw($serialized) };
3734
3735   $self;
3736 }
3737
3738
3739 =head2 throw_exception
3740
3741 See L<DBIx::Class::Schema/throw_exception> for details.
3742
3743 =cut
3744
3745 sub throw_exception {
3746   my $self=shift;
3747
3748   if (ref $self and my $rsrc = $self->result_source) {
3749     $rsrc->throw_exception(@_)
3750   }
3751   else {
3752     DBIx::Class::Exception->throw(@_);
3753   }
3754 }
3755
3756 # XXX: FIXME: Attributes docs need clearing up
3757
3758 =head1 ATTRIBUTES
3759
3760 Attributes are used to refine a ResultSet in various ways when
3761 searching for data. They can be passed to any method which takes an
3762 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3763 L</count>.
3764
3765 These are in no particular order:
3766
3767 =head2 order_by
3768
3769 =over 4
3770
3771 =item Value: ( $order_by | \@order_by | \%order_by )
3772
3773 =back
3774
3775 Which column(s) to order the results by.
3776
3777 [The full list of suitable values is documented in
3778 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3779 common options.]
3780
3781 If a single column name, or an arrayref of names is supplied, the
3782 argument is passed through directly to SQL. The hashref syntax allows
3783 for connection-agnostic specification of ordering direction:
3784
3785  For descending order:
3786
3787   order_by => { -desc => [qw/col1 col2 col3/] }
3788
3789  For explicit ascending order:
3790
3791   order_by => { -asc => 'col' }
3792
3793 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3794 supported, although you are strongly encouraged to use the hashref
3795 syntax as outlined above.
3796
3797 =head2 columns
3798
3799 =over 4
3800
3801 =item Value: \@columns
3802
3803 =back
3804
3805 Shortcut to request a particular set of columns to be retrieved. Each
3806 column spec may be a string (a table column name), or a hash (in which
3807 case the key is the C<as> value, and the value is used as the C<select>
3808 expression). Adds C<me.> onto the start of any column without a C<.> in
3809 it and sets C<select> from that, then auto-populates C<as> from
3810 C<select> as normal. (You may also use the C<cols> attribute, as in
3811 earlier versions of DBIC.)
3812
3813 Essentially C<columns> does the same as L</select> and L</as>.
3814
3815     columns => [ 'foo', { bar => 'baz' } ]
3816
3817 is the same as
3818
3819     select => [qw/foo baz/],
3820     as => [qw/foo bar/]
3821
3822 =head2 +columns
3823
3824 =over 4
3825
3826 =item Value: \@columns
3827
3828 =back
3829
3830 Indicates additional columns to be selected from storage. Works the same
3831 as L</columns> but adds columns to the selection. (You may also use the
3832 C<include_columns> attribute, as in earlier versions of DBIC). For
3833 example:-
3834
3835   $schema->resultset('CD')->search(undef, {
3836     '+columns' => ['artist.name'],
3837     join => ['artist']
3838   });
3839
3840 would return all CDs and include a 'name' column to the information
3841 passed to object inflation. Note that the 'artist' is the name of the
3842 column (or relationship) accessor, and 'name' is the name of the column
3843 accessor in the related table.
3844
3845 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3846 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3847 unary plus operator before it.
3848
3849 =head2 include_columns
3850
3851 =over 4
3852
3853 =item Value: \@columns
3854
3855 =back
3856
3857 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3858
3859 =head2 select
3860
3861 =over 4
3862
3863 =item Value: \@select_columns
3864
3865 =back
3866
3867 Indicates which columns should be selected from the storage. You can use
3868 column names, or in the case of RDBMS back ends, function or stored procedure
3869 names:
3870
3871   $rs = $schema->resultset('Employee')->search(undef, {
3872     select => [
3873       'name',
3874       { count => 'employeeid' },
3875       { max => { length => 'name' }, -as => 'longest_name' }
3876     ]
3877   });
3878
3879   # Equivalent SQL
3880   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3881
3882 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3883 use L</select>, to instruct DBIx::Class how to store the result of the column.
3884 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3885 identifier aliasing. You can however alias a function, so you can use it in
3886 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3887 attribute> supplied as shown in the example above.
3888
3889 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3890 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3891 unary plus operator before it.
3892
3893 =head2 +select
3894
3895 =over 4
3896
3897 Indicates additional columns to be selected from storage.  Works the same as
3898 L</select> but adds columns to the default selection, instead of specifying
3899 an explicit list.
3900
3901 =back
3902
3903 =head2 +as
3904
3905 =over 4
3906
3907 Indicates additional column names for those added via L</+select>. See L</as>.
3908
3909 =back
3910
3911 =head2 as
3912
3913 =over 4
3914
3915 =item Value: \@inflation_names
3916
3917 =back
3918
3919 Indicates column names for object inflation. That is L</as> indicates the
3920 slot name in which the column value will be stored within the
3921 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3922 identifier by the C<get_column> method (or via the object accessor B<if one
3923 with the same name already exists>) as shown below. The L</as> attribute has
3924 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3925
3926   $rs = $schema->resultset('Employee')->search(undef, {
3927     select => [
3928       'name',
3929       { count => 'employeeid' },
3930       { max => { length => 'name' }, -as => 'longest_name' }
3931     ],
3932     as => [qw/
3933       name
3934       employee_count
3935       max_name_length
3936     /],
3937   });
3938
3939 If the object against which the search is performed already has an accessor
3940 matching a column name specified in C<as>, the value can be retrieved using
3941 the accessor as normal:
3942
3943   my $name = $employee->name();
3944
3945 If on the other hand an accessor does not exist in the object, you need to
3946 use C<get_column> instead:
3947
3948   my $employee_count = $employee->get_column('employee_count');
3949
3950 You can create your own accessors if required - see
3951 L<DBIx::Class::Manual::Cookbook> for details.
3952
3953 =head2 join
3954
3955 =over 4
3956
3957 =item Value: ($rel_name | \@rel_names | \%rel_names)
3958
3959 =back
3960
3961 Contains a list of relationships that should be joined for this query.  For
3962 example:
3963
3964   # Get CDs by Nine Inch Nails
3965   my $rs = $schema->resultset('CD')->search(
3966     { 'artist.name' => 'Nine Inch Nails' },
3967     { join => 'artist' }
3968   );
3969
3970 Can also contain a hash reference to refer to the other relation's relations.
3971 For example:
3972
3973   package MyApp::Schema::Track;
3974   use base qw/DBIx::Class/;
3975   __PACKAGE__->table('track');
3976   __PACKAGE__->add_columns(qw/trackid cd position title/);
3977   __PACKAGE__->set_primary_key('trackid');
3978   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3979   1;
3980
3981   # In your application
3982   my $rs = $schema->resultset('Artist')->search(
3983     { 'track.title' => 'Teardrop' },
3984     {
3985       join     => { cd => 'track' },
3986       order_by => 'artist.name',
3987     }
3988   );
3989
3990 You need to use the relationship (not the table) name in  conditions,
3991 because they are aliased as such. The current table is aliased as "me", so
3992 you need to use me.column_name in order to avoid ambiguity. For example:
3993
3994   # Get CDs from 1984 with a 'Foo' track
3995   my $rs = $schema->resultset('CD')->search(
3996     {
3997       'me.year' => 1984,
3998       'tracks.name' => 'Foo'
3999     },
4000     { join => 'tracks' }
4001   );
4002
4003 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4004 similarly for a third time). For e.g.
4005
4006   my $rs = $schema->resultset('Artist')->search({
4007     'cds.title'   => 'Down to Earth',
4008     'cds_2.title' => 'Popular',
4009   }, {
4010     join => [ qw/cds cds/ ],
4011   });
4012
4013 will return a set of all artists that have both a cd with title 'Down
4014 to Earth' and a cd with title 'Popular'.
4015
4016 If you want to fetch related objects from other tables as well, see C<prefetch>
4017 below.
4018
4019  NOTE: An internal join-chain pruner will discard certain joins while
4020  constructing the actual SQL query, as long as the joins in question do not
4021  affect the retrieved result. This for example includes 1:1 left joins
4022  that are not part of the restriction specification (WHERE/HAVING) nor are
4023  a part of the query selection.
4024
4025 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4026
4027 =head2 prefetch
4028
4029 =over 4
4030
4031 =item Value: ($rel_name | \@rel_names | \%rel_names)
4032
4033 =back
4034
4035 Contains one or more relationships that should be fetched along with
4036 the main query (when they are accessed afterwards the data will
4037 already be available, without extra queries to the database).  This is
4038 useful for when you know you will need the related objects, because it
4039 saves at least one query:
4040
4041   my $rs = $schema->resultset('Tag')->search(
4042     undef,
4043     {
4044       prefetch => {
4045         cd => 'artist'
4046       }
4047     }
4048   );
4049
4050 The initial search results in SQL like the following:
4051
4052   SELECT tag.*, cd.*, artist.* FROM tag
4053   JOIN cd ON tag.cd = cd.cdid
4054   JOIN artist ON cd.artist = artist.artistid
4055
4056 L<DBIx::Class> has no need to go back to the database when we access the
4057 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4058 case.
4059
4060 Simple prefetches will be joined automatically, so there is no need
4061 for a C<join> attribute in the above search.
4062
4063 L</prefetch> can be used with the any of the relationship types and
4064 multiple prefetches can be specified together. Below is a more complex
4065 example that prefetches a CD's artist, its liner notes (if present),
4066 the cover image, the tracks on that cd, and the guests on those
4067 tracks.
4068
4069  # Assuming:
4070  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4071  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4072  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4073  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4074
4075  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4076
4077  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4078
4079
4080  my $rs = $schema->resultset('CD')->search(
4081    undef,
4082    {
4083      prefetch => [
4084        { artist => 'record_label'},  # belongs_to => belongs_to
4085        'liner_note',                 # might_have
4086        'cover_image',                # has_one
4087        { tracks => 'guests' },       # has_many => has_many
4088      ]
4089    }
4090  );
4091
4092 This will produce SQL like the following:
4093
4094  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4095         tracks.*, guests.*
4096    FROM cd me
4097    JOIN artist artist
4098      ON artist.artistid = me.artistid
4099    JOIN record_label record_label
4100      ON record_label.labelid = artist.labelid
4101    LEFT JOIN track tracks
4102      ON tracks.cdid = me.cdid
4103    LEFT JOIN guest guests
4104      ON guests.trackid = track.trackid
4105    LEFT JOIN liner_notes liner_note
4106      ON liner_note.cdid = me.cdid
4107    JOIN cd_artwork cover_image
4108      ON cover_image.cdid = me.cdid
4109  ORDER BY tracks.cd
4110
4111 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4112 C<tracks>, and C<guests> of the CD will all be available through the
4113 relationship accessors without the need for additional queries to the
4114 database.
4115
4116 However, there is one caveat to be observed: it can be dangerous to
4117 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4118 relationship on a given level. e.g.:
4119
4120  my $rs = $schema->resultset('CD')->search(
4121    undef,
4122    {
4123      prefetch => [
4124        'tracks',                         # has_many
4125        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4126      ]
4127    }
4128  );
4129
4130 In fact, C<DBIx::Class> will emit the following warning:
4131
4132  Prefetching multiple has_many rels tracks and cd_to_producer at top
4133  level will explode the number of row objects retrievable via ->next
4134  or ->all. Use at your own risk.
4135
4136 The collapser currently can't identify duplicate tuples for multiple
4137 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4138 result the second L<has_many|DBIx::Class::Relationship/has_many>
4139 relation could contain redundant objects.
4140
4141 =head3 Using L</prefetch> with L</join>
4142
4143 L</prefetch> implies a L</join> with the equivalent argument, and is
4144 properly merged with any existing L</join> specification. So the
4145 following:
4146
4147   my $rs = $schema->resultset('CD')->search(
4148    {'record_label.name' => 'Music Product Ltd.'},
4149    {
4150      join     => {artist => 'record_label'},
4151      prefetch => 'artist',
4152    }
4153  );
4154
4155 ... will work, searching on the record label's name, but only
4156 prefetching the C<artist>.
4157
4158 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4159
4160 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4161 prefetched relations.  So given:
4162
4163   my $rs = $schema->resultset('CD')->search(
4164    undef,
4165    {
4166      select   => ['cd.title'],
4167      as       => ['cd_title'],
4168      prefetch => 'artist',
4169    }
4170  );
4171
4172 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4173 becomes: C<'cd_title', 'artist.*'>.
4174
4175 =head3 CAVEATS
4176
4177 Prefetch does a lot of deep magic. As such, it may not behave exactly
4178 as you might expect.
4179
4180 =over 4
4181
4182 =item *
4183
4184 Prefetch uses the L</cache> to populate the prefetched relationships. This
4185 may or may not be what you want.
4186
4187 =item *
4188
4189 If you specify a condition on a prefetched relationship, ONLY those
4190 rows that match the prefetched condition will be fetched into that relationship.
4191 This means that adding prefetch to a search() B<may alter> what is returned by
4192 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4193
4194   my $artist_rs = $schema->resultset('Artist')->search({
4195       'cds.year' => 2008,
4196   }, {
4197       join => 'cds',
4198   });
4199
4200   my $count = $artist_rs->first->cds->count;
4201
4202   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4203
4204   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4205
4206   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4207
4208 that cmp_ok() may or may not pass depending on the datasets involved. This
4209 behavior may or may not survive the 0.09 transition.
4210
4211 =back
4212
4213 =head2 page
4214
4215 =over 4
4216
4217 =item Value: $page
4218
4219 =back
4220
4221 Makes the resultset paged and specifies the page to retrieve. Effectively
4222 identical to creating a non-pages resultset and then calling ->page($page)
4223 on it.
4224
4225 If L</rows> attribute is not specified it defaults to 10 rows per page.
4226
4227 When you have a paged resultset, L</count> will only return the number
4228 of rows in the page. To get the total, use the L</pager> and call
4229 C<total_entries> on it.
4230
4231 =head2 rows
4232
4233 =over 4
4234
4235 =item Value: $rows
4236
4237 =back
4238
4239 Specifies the maximum number of rows for direct retrieval or the number of
4240 rows per page if the page attribute or method is used.
4241
4242 =head2 offset
4243
4244 =over 4
4245
4246 =item Value: $offset
4247
4248 =back
4249
4250 Specifies the (zero-based) row number for the  first row to be returned, or the
4251 of the first row of the first page if paging is used.
4252
4253 =head2 software_limit
4254
4255 =over 4
4256
4257 =item Value: (0 | 1)
4258
4259 =back
4260
4261 When combined with L</rows> and/or L</offset> the generated SQL will not
4262 include any limit dialect stanzas. Instead the entire result will be selected
4263 as if no limits were specified, and DBIC will perform the limit locally, by
4264 artificially advancing and finishing the resulting L</cursor>.
4265
4266 This is the recommended way of performing resultset limiting when no sane RDBMS
4267 implementation is available (e.g.
4268 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4269 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4270
4271 =head2 group_by
4272
4273 =over 4
4274
4275 =item Value: \@columns
4276
4277 =back
4278
4279 A arrayref of columns to group by. Can include columns of joined tables.
4280
4281   group_by => [qw/ column1 column2 ... /]
4282
4283 =head2 having
4284
4285 =over 4
4286
4287 =item Value: $condition
4288
4289 =back
4290
4291 HAVING is a select statement attribute that is applied between GROUP BY and
4292 ORDER BY. It is applied to the after the grouping calculations have been
4293 done.
4294
4295   having => { 'count_employee' => { '>=', 100 } }
4296
4297 or with an in-place function in which case literal SQL is required:
4298
4299   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4300
4301 =head2 distinct
4302
4303 =over 4
4304
4305 =item Value: (0 | 1)
4306
4307 =back
4308
4309 Set to 1 to group by all columns. If the resultset already has a group_by
4310 attribute, this setting is ignored and an appropriate warning is issued.
4311
4312 =head2 where
4313
4314 =over 4
4315
4316 Adds to the WHERE clause.
4317
4318   # only return rows WHERE deleted IS NULL for all searches
4319   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4320
4321 Can be overridden by passing C<< { where => undef } >> as an attribute
4322 to a resultset.
4323
4324 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4325
4326 =back
4327
4328 =head2 cache
4329
4330 Set to 1 to cache search results. This prevents extra SQL queries if you
4331 revisit rows in your ResultSet:
4332
4333   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4334
4335   while( my $artist = $resultset->next ) {
4336     ... do stuff ...
4337   }
4338
4339   $rs->first; # without cache, this would issue a query
4340
4341 By default, searches are not cached.
4342
4343 For more examples of using these attributes, see
4344 L<DBIx::Class::Manual::Cookbook>.
4345
4346 =head2 for
4347
4348 =over 4
4349
4350 =item Value: ( 'update' | 'shared' | \$scalar )
4351
4352 =back
4353
4354 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4355 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4356 query.
4357
4358 =cut
4359
4360 1;