lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   return $self->{cursor}
 665     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 666           $attrs->{where},$attrs);
 667 }
 668
 669 =head2 single
 670
 671 =over 4
 672
 673 =item Arguments: $cond?
 674
 675 =item Return Value: $row_object?
 676
 677 =back
 678
 679   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 680
 681 Inflates the first result without creating a cursor if the resultset has
 682 any records in it; if not returns nothing. Used by L</find> as a lean version of
 683 L</search>.
 684
 685 While this method can take an optional search condition (just like L</search>)
 686 being a fast-code-path it does not recognize search attributes. If you need to
 687 add extra joins or similar, call L</search> and then chain-call L</single> on the
 688 L<DBIx::Class::ResultSet> returned.
 689
 690 =over
 691
 692 =item B<Note>
 693
 694 As of 0.08100, this method enforces the assumption that the preceeding
 695 query returns only one row. If more than one row is returned, you will receive
 696 a warning:
 697
 698   Query returned more than one row
 699
 700 In this case, you should be using L</first> or L</find> instead, or if you really
 701 know what you are doing, use the L</rows> attribute to explicitly limit the size
 702 of the resultset.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715   if ($where) {
 716     if (defined $attrs->{where}) {
 717       $attrs->{where} = {
 718         '-and' =>
 719             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 720                $where, delete $attrs->{where} ]
 721       };
 722     } else {
 723       $attrs->{where} = $where;
 724     }
 725   }
 726
 727 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 728 #  unless ($self->_is_unique_query($attrs->{where})) {
 729 #    carp "Query not guaranteed to return a single row"
 730 #      . "; please declare your unique constraints or use search instead";
 731 #  }
 732
 733   my @data = $self->result_source->storage->select_single(
 734     $attrs->{from}, $attrs->{select},
 735     $attrs->{where}, $attrs
 736   );
 737
 738   return (@data ? ($self->_construct_object(@data))[0] : undef);
 739 }
 740
 741 # _is_unique_query
 742 #
 743 # Try to determine if the specified query is guaranteed to be unique, based on
 744 # the declared unique constraints.
 745
 746 sub _is_unique_query {
 747   my ($self, $query) = @_;
 748
 749   my $collapsed = $self->_collapse_query($query);
 750   my $alias = $self->{attrs}{alias};
 751
 752   foreach my $name ($self->result_source->unique_constraint_names) {
 753     my @unique_cols = map {
 754       "$alias.$_"
 755     } $self->result_source->unique_constraint_columns($name);
 756
 757     # Count the values for each unique column
 758     my %seen = map { $_ => 0 } @unique_cols;
 759
 760     foreach my $key (keys %$collapsed) {
 761       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 762       next unless exists $seen{$aliased};  # Additional constraints are okay
 763       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 764     }
 765
 766     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 767     return 1 unless grep { $_ != 1 } values %seen;
 768   }
 769
 770   return 0;
 771 }
 772
 773 # _collapse_query
 774 #
 775 # Recursively collapse the query, accumulating values for each column.
 776
 777 sub _collapse_query {
 778   my ($self, $query, $collapsed) = @_;
 779
 780   $collapsed ||= {};
 781
 782   if (ref $query eq 'ARRAY') {
 783     foreach my $subquery (@$query) {
 784       next unless ref $subquery;  # -or
 785       $collapsed = $self->_collapse_query($subquery, $collapsed);
 786     }
 787   }
 788   elsif (ref $query eq 'HASH') {
 789     if (keys %$query and (keys %$query)[0] eq '-and') {
 790       foreach my $subquery (@{$query->{-and}}) {
 791         $collapsed = $self->_collapse_query($subquery, $collapsed);
 792       }
 793     }
 794     else {
 795       foreach my $col (keys %$query) {
 796         my $value = $query->{$col};
 797         $collapsed->{$col}{$value}++;
 798       }
 799     }
 800   }
 801
 802   return $collapsed;
 803 }
 804
 805 =head2 get_column
 806
 807 =over 4
 808
 809 =item Arguments: $cond?
 810
 811 =item Return Value: $resultsetcolumn
 812
 813 =back
 814
 815   my $max_length = $rs->get_column('length')->max;
 816
 817 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 818
 819 =cut
 820
 821 sub get_column {
 822   my ($self, $column) = @_;
 823   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 824   return $new;
 825 }
 826
 827 =head2 search_like
 828
 829 =over 4
 830
 831 =item Arguments: $cond, \%attrs?
 832
 833 =item Return Value: $resultset (scalar context), @row_objs (list context)
 834
 835 =back
 836
 837   # WHERE title LIKE '%blue%'
 838   $cd_rs = $rs->search_like({ title => '%blue%'});
 839
 840 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 841 that this is simply a convenience method retained for ex Class::DBI users.
 842 You most likely want to use L</search> with specific operators.
 843
 844 For more information, see L<DBIx::Class::Manual::Cookbook>.
 845
 846 This method is deprecated and will be removed in 0.09. Use L</search()>
 847 instead. An example conversion is:
 848
 849   ->search_like({ foo => 'bar' });
 850
 851   # Becomes
 852
 853   ->search({ foo => { like => 'bar' } });
 854
 855 =cut
 856
 857 sub search_like {
 858   my $class = shift;
 859   carp join ("\n",
 860     'search_like() is deprecated and will be removed in 0.09.',
 861     'Instead use ->search({ x => { -like => "y%" } })',
 862     '(note the outer pair of {}s - they are important!)'
 863   );
 864   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 865   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 866   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 867   return $class->search($query, { %$attrs });
 868 }
 869
 870 =head2 slice
 871
 872 =over 4
 873
 874 =item Arguments: $first, $last
 875
 876 =item Return Value: $resultset (scalar context), @row_objs (list context)
 877
 878 =back
 879
 880 Returns a resultset or object list representing a subset of elements from the
 881 resultset slice is called on. Indexes are from 0, i.e., to get the first
 882 three records, call:
 883
 884   my ($one, $two, $three) = $rs->slice(0, 2);
 885
 886 =cut
 887
 888 sub slice {
 889   my ($self, $min, $max) = @_;
 890   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 891   $attrs->{offset} = $self->{attrs}{offset} || 0;
 892   $attrs->{offset} += $min;
 893   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 894   return $self->search(undef(), $attrs);
 895   #my $slice = (ref $self)->new($self->result_source, $attrs);
 896   #return (wantarray ? $slice->all : $slice);
 897 }
 898
 899 =head2 next
 900
 901 =over 4
 902
 903 =item Arguments: none
 904
 905 =item Return Value: $result?
 906
 907 =back
 908
 909 Returns the next element in the resultset (C<undef> is there is none).
 910
 911 Can be used to efficiently iterate over records in the resultset:
 912
 913   my $rs = $schema->resultset('CD')->search;
 914   while (my $cd = $rs->next) {
 915     print $cd->title;
 916   }
 917
 918 Note that you need to store the resultset object, and call C<next> on it.
 919 Calling C<< resultset('Table')->next >> repeatedly will always return the
 920 first record from the resultset.
 921
 922 =cut
 923
 924 sub next {
 925   my ($self) = @_;
 926   if (my $cache = $self->get_cache) {
 927     $self->{all_cache_position} ||= 0;
 928     return $cache->[$self->{all_cache_position}++];
 929   }
 930   if ($self->{attrs}{cache}) {
 931     $self->{all_cache_position} = 1;
 932     return ($self->all)[0];
 933   }
 934   if ($self->{stashed_objects}) {
 935     my $obj = shift(@{$self->{stashed_objects}});
 936     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 937     return $obj;
 938   }
 939   my @row = (
 940     exists $self->{stashed_row}
 941       ? @{delete $self->{stashed_row}}
 942       : $self->cursor->next
 943   );
 944   return undef unless (@row);
 945   my ($row, @more) = $self->_construct_object(@row);
 946   $self->{stashed_objects} = \@more if @more;
 947   return $row;
 948 }
 949
 950 sub _construct_object {
 951   my ($self, @row) = @_;
 952   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 953   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 954   @new = $self->{_attrs}{record_filter}->(@new)
 955     if exists $self->{_attrs}{record_filter};
 956   return @new;
 957 }
 958
 959 sub _collapse_result {
 960   my ($self, $as_proto, $row) = @_;
 961
 962   my @copy = @$row;
 963
 964   # 'foo'         => [ undef, 'foo' ]
 965   # 'foo.bar'     => [ 'foo', 'bar' ]
 966   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 967
 968   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 969
 970   my %collapse = %{$self->{_attrs}{collapse}||{}};
 971
 972   my @pri_index;
 973
 974   # if we're doing collapsing (has_many prefetch) we need to grab records
 975   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 976   # we know we don't have to bother.
 977
 978   # the reason for not using the collapse stuff directly is because if you
 979   # had for e.g. two artists in a row with no cds, the collapse info for
 980   # both would be NULL (undef) so you'd lose the second artist
 981
 982   # store just the index so we can check the array positions from the row
 983   # without having to contruct the full hash
 984
 985   if (keys %collapse) {
 986     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 987     foreach my $i (0 .. $#construct_as) {
 988       next if defined($construct_as[$i][0]); # only self table
 989       if (delete $pri{$construct_as[$i][1]}) {
 990         push(@pri_index, $i);
 991       }
 992       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 993     }
 994   }
 995
 996   # no need to do an if, it'll be empty if @pri_index is empty anyway
 997
 998   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 999
1000   my @const_rows;
1001
1002   do { # no need to check anything at the front, we always want the first row
1003
1004     my %const;
1005
1006     foreach my $this_as (@construct_as) {
1007       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1008     }
1009
1010     push(@const_rows, \%const);
1011
1012   } until ( # no pri_index => no collapse => drop straight out
1013       !@pri_index
1014     or
1015       do { # get another row, stash it, drop out if different PK
1016
1017         @copy = $self->cursor->next;
1018         $self->{stashed_row} = \@copy;
1019
1020         # last thing in do block, counts as true if anything doesn't match
1021
1022         # check xor defined first for NULL vs. NOT NULL then if one is
1023         # defined the other must be so check string equality
1024
1025         grep {
1026           (defined $pri_vals{$_} ^ defined $copy[$_])
1027           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1028         } @pri_index;
1029       }
1030   );
1031
1032   my $alias = $self->{attrs}{alias};
1033   my $info = [];
1034
1035   my %collapse_pos;
1036
1037   my @const_keys;
1038
1039   foreach my $const (@const_rows) {
1040     scalar @const_keys or do {
1041       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1042     };
1043     foreach my $key (@const_keys) {
1044       if (length $key) {
1045         my $target = $info;
1046         my @parts = split(/\./, $key);
1047         my $cur = '';
1048         my $data = $const->{$key};
1049         foreach my $p (@parts) {
1050           $target = $target->[1]->{$p} ||= [];
1051           $cur .= ".${p}";
1052           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1053             # collapsing at this point and on final part
1054             my $pos = $collapse_pos{$cur};
1055             CK: foreach my $ck (@ckey) {
1056               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1057                 $collapse_pos{$cur} = $data;
1058                 delete @collapse_pos{ # clear all positioning for sub-entries
1059                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1060                 };
1061                 push(@$target, []);
1062                 last CK;
1063               }
1064             }
1065           }
1066           if (exists $collapse{$cur}) {
1067             $target = $target->[-1];
1068           }
1069         }
1070         $target->[0] = $data;
1071       } else {
1072         $info->[0] = $const->{$key};
1073       }
1074     }
1075   }
1076
1077   return $info;
1078 }
1079
1080 =head2 result_source
1081
1082 =over 4
1083
1084 =item Arguments: $result_source?
1085
1086 =item Return Value: $result_source
1087
1088 =back
1089
1090 An accessor for the primary ResultSource object from which this ResultSet
1091 is derived.
1092
1093 =head2 result_class
1094
1095 =over 4
1096
1097 =item Arguments: $result_class?
1098
1099 =item Return Value: $result_class
1100
1101 =back
1102
1103 An accessor for the class to use when creating row objects. Defaults to
1104 C<< result_source->result_class >> - which in most cases is the name of the
1105 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1106
1107 Note that changing the result_class will also remove any components
1108 that were originally loaded in the source class via
1109 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1110 in the original source class will not run.
1111
1112 =cut
1113
1114 sub result_class {
1115   my ($self, $result_class) = @_;
1116   if ($result_class) {
1117     $self->ensure_class_loaded($result_class);
1118     $self->_result_class($result_class);
1119   }
1120   $self->_result_class;
1121 }
1122
1123 =head2 count
1124
1125 =over 4
1126
1127 =item Arguments: $cond, \%attrs??
1128
1129 =item Return Value: $count
1130
1131 =back
1132
1133 Performs an SQL C<COUNT> with the same query as the resultset was built
1134 with to find the number of elements. Passing arguments is equivalent to
1135 C<< $rs->search ($cond, \%attrs)->count >>
1136
1137 =cut
1138
1139 sub count {
1140   my $self = shift;
1141   return $self->search(@_)->count if @_ and defined $_[0];
1142   return scalar @{ $self->get_cache } if $self->get_cache;
1143
1144   my @subq_attrs = qw/prefetch collapse distinct group_by having/;
1145   my $attrs = $self->_resolved_attrs;
1146
1147   # if we are not paged - we are simply asking for a limit
1148   if (not $attrs->{page} and not $attrs->{software_limit}) {
1149     push @subq_attrs, qw/rows offset/;
1150   }
1151
1152   return $self->_has_attr (@subq_attrs)
1153     ? $self->_count_subq
1154     : $self->_count_simple
1155 }
1156
1157 sub _count_subq {
1158   my $self = shift;
1159
1160   my $attrs = $self->_resolved_attrs_copy;
1161
1162   # copy for the subquery, we need to do some adjustments to it too
1163   my $sub_attrs = { %$attrs };
1164
1165   # these can not go in the subquery either
1166   delete $sub_attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1167
1168   # force a group_by and the same set of columns (most databases require this)
1169   $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1170
1171   $attrs->{from} = [{
1172     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1173   }];
1174
1175   # the subquery replaces this
1176   delete $attrs->{$_} for qw/where bind prefetch collapse distinct group_by having having_bind/;
1177
1178   return $self->__count ($attrs);
1179 }
1180
1181 sub _count_simple {
1182   my $self = shift;
1183
1184   my $count = $self->__count;
1185   return 0 unless $count;
1186
1187   # need to take offset from resolved attrs
1188
1189   my $attrs = $self->_resolved_attrs;
1190
1191   $count -= $attrs->{offset} if $attrs->{offset};
1192   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1193   $count = 0 if ($count < 0);
1194   return $count;
1195 }
1196
1197 sub __count {
1198   my ($self, $attrs) = @_;
1199
1200   $attrs ||= $self->_resolved_attrs_copy;
1201
1202   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1203   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1204
1205   $attrs->{select} = { count => '*' };
1206   $attrs->{as} = [qw/count/];
1207
1208   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1209   my ($count) = $tmp_rs->cursor->next;
1210
1211   return $count;
1212 }
1213
1214 sub _bool {
1215   return 1;
1216 }
1217
1218 =head2 count_literal
1219
1220 =over 4
1221
1222 =item Arguments: $sql_fragment, @bind_values
1223
1224 =item Return Value: $count
1225
1226 =back
1227
1228 Counts the results in a literal query. Equivalent to calling L</search_literal>
1229 with the passed arguments, then L</count>.
1230
1231 =cut
1232
1233 sub count_literal { shift->search_literal(@_)->count; }
1234
1235 =head2 all
1236
1237 =over 4
1238
1239 =item Arguments: none
1240
1241 =item Return Value: @objects
1242
1243 =back
1244
1245 Returns all elements in the resultset. Called implicitly if the resultset
1246 is returned in list context.
1247
1248 =cut
1249
1250 sub all {
1251   my $self = shift;
1252   if(@_) {
1253       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1254   }
1255
1256   return @{ $self->get_cache } if $self->get_cache;
1257
1258   my @obj;
1259
1260   # TODO: don't call resolve here
1261   if (keys %{$self->_resolved_attrs->{collapse}}) {
1262 #  if ($self->{attrs}{prefetch}) {
1263       # Using $self->cursor->all is really just an optimisation.
1264       # If we're collapsing has_many prefetches it probably makes
1265       # very little difference, and this is cleaner than hacking
1266       # _construct_object to survive the approach
1267     my @row = $self->cursor->next;
1268     while (@row) {
1269       push(@obj, $self->_construct_object(@row));
1270       @row = (exists $self->{stashed_row}
1271                ? @{delete $self->{stashed_row}}
1272                : $self->cursor->next);
1273     }
1274   } else {
1275     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1276   }
1277
1278   $self->set_cache(\@obj) if $self->{attrs}{cache};
1279   return @obj;
1280 }
1281
1282 =head2 reset
1283
1284 =over 4
1285
1286 =item Arguments: none
1287
1288 =item Return Value: $self
1289
1290 =back
1291
1292 Resets the resultset's cursor, so you can iterate through the elements again.
1293
1294 =cut
1295
1296 sub reset {
1297   my ($self) = @_;
1298   delete $self->{_attrs} if exists $self->{_attrs};
1299   $self->{all_cache_position} = 0;
1300   $self->cursor->reset;
1301   return $self;
1302 }
1303
1304 =head2 first
1305
1306 =over 4
1307
1308 =item Arguments: none
1309
1310 =item Return Value: $object?
1311
1312 =back
1313
1314 Resets the resultset and returns an object for the first result (if the
1315 resultset returns anything).
1316
1317 =cut
1318
1319 sub first {
1320   return $_[0]->reset->next;
1321 }
1322
1323
1324 # _rs_update_delete
1325 #
1326 # Determines whether and what type of subquery is required for the $rs operation.
1327 # If grouping is necessary either supplies its own, or verifies the current one
1328 # After all is done delegates to the proper storage method.
1329
1330 sub _rs_update_delete {
1331   my ($self, $op, $values) = @_;
1332
1333   my $rsrc = $self->result_source;
1334
1335   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1336   my $needs_subq = $self->_has_attr (qw/row offset page/);
1337
1338   if ($needs_group_by_subq or $needs_subq) {
1339
1340     # make a new $rs selecting only the PKs (that's all we really need)
1341     my $attrs = $self->_resolved_attrs_copy;
1342
1343     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1344     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1345
1346     if ($needs_group_by_subq) {
1347       # make sure no group_by was supplied, or if there is one - make sure it matches
1348       # the columns compiled above perfectly. Anything else can not be sanely executed
1349       # on most databases so croak right then and there
1350
1351       if (my $g = $attrs->{group_by}) {
1352         my @current_group_by = map
1353           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1354           (ref $g eq 'ARRAY' ? @$g : $g );
1355
1356         if (
1357           join ("\x00", sort @current_group_by)
1358             ne
1359           join ("\x00", sort @{$attrs->{columns}} )
1360         ) {
1361           $self->throw_exception (
1362             "You have just attempted a $op operation on a resultset which does group_by"
1363             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1364             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1365             . ' kind of queries. Please retry the operation with a modified group_by or'
1366             . ' without using one at all.'
1367           );
1368         }
1369       }
1370       else {
1371         $attrs->{group_by} = $attrs->{columns};
1372       }
1373     }
1374
1375     my $subrs = (ref $self)->new($rsrc, $attrs);
1376
1377     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1378   }
1379   else {
1380     return $rsrc->storage->$op(
1381       $rsrc,
1382       $op eq 'update' ? $values : (),
1383       $self->_cond_for_update_delete,
1384     );
1385   }
1386 }
1387
1388
1389 # _cond_for_update_delete
1390 #
1391 # update/delete require the condition to be modified to handle
1392 # the differing SQL syntax available.  This transforms the $self->{cond}
1393 # appropriately, returning the new condition.
1394
1395 sub _cond_for_update_delete {
1396   my ($self, $full_cond) = @_;
1397   my $cond = {};
1398
1399   $full_cond ||= $self->{cond};
1400   # No-op. No condition, we're updating/deleting everything
1401   return $cond unless ref $full_cond;
1402
1403   if (ref $full_cond eq 'ARRAY') {
1404     $cond = [
1405       map {
1406         my %hash;
1407         foreach my $key (keys %{$_}) {
1408           $key =~ /([^.]+)$/;
1409           $hash{$1} = $_->{$key};
1410         }
1411         \%hash;
1412       } @{$full_cond}
1413     ];
1414   }
1415   elsif (ref $full_cond eq 'HASH') {
1416     if ((keys %{$full_cond})[0] eq '-and') {
1417       $cond->{-and} = [];
1418       my @cond = @{$full_cond->{-and}};
1419        for (my $i = 0; $i < @cond; $i++) {
1420         my $entry = $cond[$i];
1421         my $hash;
1422         if (ref $entry eq 'HASH') {
1423           $hash = $self->_cond_for_update_delete($entry);
1424         }
1425         else {
1426           $entry =~ /([^.]+)$/;
1427           $hash->{$1} = $cond[++$i];
1428         }
1429         push @{$cond->{-and}}, $hash;
1430       }
1431     }
1432     else {
1433       foreach my $key (keys %{$full_cond}) {
1434         $key =~ /([^.]+)$/;
1435         $cond->{$1} = $full_cond->{$key};
1436       }
1437     }
1438   }
1439   else {
1440     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1441   }
1442
1443   return $cond;
1444 }
1445
1446
1447 =head2 update
1448
1449 =over 4
1450
1451 =item Arguments: \%values
1452
1453 =item Return Value: $storage_rv
1454
1455 =back
1456
1457 Sets the specified columns in the resultset to the supplied values in a
1458 single query. Return value will be true if the update succeeded or false
1459 if no records were updated; exact type of success value is storage-dependent.
1460
1461 =cut
1462
1463 sub update {
1464   my ($self, $values) = @_;
1465   $self->throw_exception('Values for update must be a hash')
1466     unless ref $values eq 'HASH';
1467
1468   return $self->_rs_update_delete ('update', $values);
1469 }
1470
1471 =head2 update_all
1472
1473 =over 4
1474
1475 =item Arguments: \%values
1476
1477 =item Return Value: 1
1478
1479 =back
1480
1481 Fetches all objects and updates them one at a time. Note that C<update_all>
1482 will run DBIC cascade triggers, while L</update> will not.
1483
1484 =cut
1485
1486 sub update_all {
1487   my ($self, $values) = @_;
1488   $self->throw_exception('Values for update_all must be a hash')
1489     unless ref $values eq 'HASH';
1490   foreach my $obj ($self->all) {
1491     $obj->set_columns($values)->update;
1492   }
1493   return 1;
1494 }
1495
1496 =head2 delete
1497
1498 =over 4
1499
1500 =item Arguments: none
1501
1502 =item Return Value: 1
1503
1504 =back
1505
1506 Deletes the contents of the resultset from its result source. Note that this
1507 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1508 to run. See also L<DBIx::Class::Row/delete>.
1509
1510 delete may not generate correct SQL for a query with joins or a resultset
1511 chained from a related resultset.  In this case it will generate a warning:-
1512
1513 In these cases you may find that delete_all is more appropriate, or you
1514 need to respecify your query in a way that can be expressed without a join.
1515
1516 =cut
1517
1518 sub delete {
1519   my $self = shift;
1520   $self->throw_exception('delete does not accept any arguments')
1521     if @_;
1522
1523   return $self->_rs_update_delete ('delete');
1524 }
1525
1526 =head2 delete_all
1527
1528 =over 4
1529
1530 =item Arguments: none
1531
1532 =item Return Value: 1
1533
1534 =back
1535
1536 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1537 will run DBIC cascade triggers, while L</delete> will not.
1538
1539 =cut
1540
1541 sub delete_all {
1542   my $self = shift;
1543   $self->throw_exception('delete_all does not accept any arguments')
1544     if @_;
1545
1546   $_->delete for $self->all;
1547   return 1;
1548 }
1549
1550 =head2 populate
1551
1552 =over 4
1553
1554 =item Arguments: \@data;
1555
1556 =back
1557
1558 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1559 For the arrayref of hashrefs style each hashref should be a structure suitable
1560 forsubmitting to a $resultset->create(...) method.
1561
1562 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1563 to insert the data, as this is a faster method.
1564
1565 Otherwise, each set of data is inserted into the database using
1566 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1567 objects is returned.
1568
1569 Example:  Assuming an Artist Class that has many CDs Classes relating:
1570
1571   my $Artist_rs = $schema->resultset("Artist");
1572
1573   ## Void Context Example
1574   $Artist_rs->populate([
1575      { artistid => 4, name => 'Manufactured Crap', cds => [
1576         { title => 'My First CD', year => 2006 },
1577         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1578       ],
1579      },
1580      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1581         { title => 'My parents sold me to a record company' ,year => 2005 },
1582         { title => 'Why Am I So Ugly?', year => 2006 },
1583         { title => 'I Got Surgery and am now Popular', year => 2007 }
1584       ],
1585      },
1586   ]);
1587
1588   ## Array Context Example
1589   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1590     { name => "Artist One"},
1591     { name => "Artist Two"},
1592     { name => "Artist Three", cds=> [
1593     { title => "First CD", year => 2007},
1594     { title => "Second CD", year => 2008},
1595   ]}
1596   ]);
1597
1598   print $ArtistOne->name; ## response is 'Artist One'
1599   print $ArtistThree->cds->count ## reponse is '2'
1600
1601 For the arrayref of arrayrefs style,  the first element should be a list of the
1602 fieldsnames to which the remaining elements are rows being inserted.  For
1603 example:
1604
1605   $Arstist_rs->populate([
1606     [qw/artistid name/],
1607     [100, 'A Formally Unknown Singer'],
1608     [101, 'A singer that jumped the shark two albums ago'],
1609     [102, 'An actually cool singer.'],
1610   ]);
1611
1612 Please note an important effect on your data when choosing between void and
1613 wantarray context. Since void context goes straight to C<insert_bulk> in
1614 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1615 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1616 create primary keys for you, you will find that your PKs are empty.  In this
1617 case you will have to use the wantarray context in order to create those
1618 values.
1619
1620 =cut
1621
1622 sub populate {
1623   my $self = shift @_;
1624   my $data = ref $_[0][0] eq 'HASH'
1625     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1626     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1627
1628   if(defined wantarray) {
1629     my @created;
1630     foreach my $item (@$data) {
1631       push(@created, $self->create($item));
1632     }
1633     return @created;
1634   } else {
1635     my ($first, @rest) = @$data;
1636
1637     my @names = grep {!ref $first->{$_}} keys %$first;
1638     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1639     my @pks = $self->result_source->primary_columns;
1640
1641     ## do the belongs_to relationships
1642     foreach my $index (0..$#$data) {
1643       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1644         my @ret = $self->populate($data);
1645         return;
1646       }
1647
1648       foreach my $rel (@rels) {
1649         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1650         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1651         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1652         my $related = $result->result_source->_resolve_condition(
1653           $result->result_source->relationship_info($reverse)->{cond},
1654           $self,
1655           $result,
1656         );
1657
1658         delete $data->[$index]->{$rel};
1659         $data->[$index] = {%{$data->[$index]}, %$related};
1660
1661         push @names, keys %$related if $index == 0;
1662       }
1663     }
1664
1665     ## do bulk insert on current row
1666     my @values = map { [ @$_{@names} ] } @$data;
1667
1668     $self->result_source->storage->insert_bulk(
1669       $self->result_source,
1670       \@names,
1671       \@values,
1672     );
1673
1674     ## do the has_many relationships
1675     foreach my $item (@$data) {
1676
1677       foreach my $rel (@rels) {
1678         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1679
1680         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1681      || $self->throw_exception('Cannot find the relating object.');
1682
1683         my $child = $parent->$rel;
1684
1685         my $related = $child->result_source->_resolve_condition(
1686           $parent->result_source->relationship_info($rel)->{cond},
1687           $child,
1688           $parent,
1689         );
1690
1691         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1692         my @populate = map { {%$_, %$related} } @rows_to_add;
1693
1694         $child->populate( \@populate );
1695       }
1696     }
1697   }
1698 }
1699
1700 =head2 _normalize_populate_args ($args)
1701
1702 Private method used by L</populate> to normalize its incoming arguments.  Factored
1703 out in case you want to subclass and accept new argument structures to the
1704 L</populate> method.
1705
1706 =cut
1707
1708 sub _normalize_populate_args {
1709   my ($self, $data) = @_;
1710   my @names = @{shift(@$data)};
1711   my @results_to_create;
1712   foreach my $datum (@$data) {
1713     my %result_to_create;
1714     foreach my $index (0..$#names) {
1715       $result_to_create{$names[$index]} = $$datum[$index];
1716     }
1717     push @results_to_create, \%result_to_create;
1718   }
1719   return \@results_to_create;
1720 }
1721
1722 =head2 pager
1723
1724 =over 4
1725
1726 =item Arguments: none
1727
1728 =item Return Value: $pager
1729
1730 =back
1731
1732 Return Value a L<Data::Page> object for the current resultset. Only makes
1733 sense for queries with a C<page> attribute.
1734
1735 To get the full count of entries for a paged resultset, call
1736 C<total_entries> on the L<Data::Page> object.
1737
1738 =cut
1739
1740 sub pager {
1741   my ($self) = @_;
1742
1743   return $self->{pager} if $self->{pager};
1744
1745   my $attrs = $self->{attrs};
1746   $self->throw_exception("Can't create pager for non-paged rs")
1747     unless $self->{attrs}{page};
1748   $attrs->{rows} ||= 10;
1749
1750   # throw away the paging flags and re-run the count (possibly
1751   # with a subselect) to get the real total count
1752   my $count_attrs = { %$attrs };
1753   delete $count_attrs->{$_} for qw/rows offset page pager/;
1754   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1755
1756   return $self->{pager} = Data::Page->new(
1757     $total_count,
1758     $attrs->{rows},
1759     $self->{attrs}{page}
1760   );
1761 }
1762
1763 =head2 page
1764
1765 =over 4
1766
1767 =item Arguments: $page_number
1768
1769 =item Return Value: $rs
1770
1771 =back
1772
1773 Returns a resultset for the $page_number page of the resultset on which page
1774 is called, where each page contains a number of rows equal to the 'rows'
1775 attribute set on the resultset (10 by default).
1776
1777 =cut
1778
1779 sub page {
1780   my ($self, $page) = @_;
1781   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1782 }
1783
1784 =head2 new_result
1785
1786 =over 4
1787
1788 =item Arguments: \%vals
1789
1790 =item Return Value: $rowobject
1791
1792 =back
1793
1794 Creates a new row object in the resultset's result class and returns
1795 it. The row is not inserted into the database at this point, call
1796 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1797 will tell you whether the row object has been inserted or not.
1798
1799 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1800
1801 =cut
1802
1803 sub new_result {
1804   my ($self, $values) = @_;
1805   $self->throw_exception( "new_result needs a hash" )
1806     unless (ref $values eq 'HASH');
1807
1808   my %new;
1809   my $alias = $self->{attrs}{alias};
1810
1811   if (
1812     defined $self->{cond}
1813     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1814   ) {
1815     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1816     $new{-from_resultset} = [ keys %new ] if keys %new;
1817   } else {
1818     $self->throw_exception(
1819       "Can't abstract implicit construct, condition not a hash"
1820     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1821
1822     my $collapsed_cond = (
1823       $self->{cond}
1824         ? $self->_collapse_cond($self->{cond})
1825         : {}
1826     );
1827
1828     # precendence must be given to passed values over values inherited from
1829     # the cond, so the order here is important.
1830     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1831     while( my($col,$value) = each %implied ){
1832       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1833         $new{$col} = $value->{'='};
1834         next;
1835       }
1836       $new{$col} = $value if $self->_is_deterministic_value($value);
1837     }
1838   }
1839
1840   %new = (
1841     %new,
1842     %{ $self->_remove_alias($values, $alias) },
1843     -source_handle => $self->_source_handle,
1844     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1845   );
1846
1847   return $self->result_class->new(\%new);
1848 }
1849
1850 # _is_deterministic_value
1851 #
1852 # Make an effor to strip non-deterministic values from the condition,
1853 # to make sure new_result chokes less
1854
1855 sub _is_deterministic_value {
1856   my $self = shift;
1857   my $value = shift;
1858   my $ref_type = ref $value;
1859   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1860   return 1 if Scalar::Util::blessed($value);
1861   return 0;
1862 }
1863
1864 # _has_attr
1865 #
1866 # determines if the resultset defines at least one
1867 # of the attributes supplied
1868 #
1869 # used to determine if a subquery is neccessary
1870
1871 sub _has_attr {
1872   my ($self, @attr_names) = @_;
1873
1874   my $attrs = $self->_resolved_attrs;
1875
1876   my $join_check_req;
1877
1878   for my $n (@attr_names) {
1879     ++$join_check_req if $n =~ /join/;
1880
1881     my $attr =  $attrs->{$n};
1882
1883     next if not defined $attr;
1884
1885     if (ref $attr eq 'HASH') {
1886       return 1 if keys %$attr;
1887     }
1888     elsif (ref $attr eq 'ARRAY') {
1889       return 1 if @$attr;
1890     }
1891     else {
1892       return 1 if $attr;
1893     }
1894   }
1895
1896   # a join can be expressed as a multi-level from
1897   return 1 if (
1898     $join_check_req
1899       and
1900     ref $attrs->{from} eq 'ARRAY'
1901       and
1902     @{$attrs->{from}} > 1
1903   );
1904
1905   return 0;
1906 }
1907
1908 # _collapse_cond
1909 #
1910 # Recursively collapse the condition.
1911
1912 sub _collapse_cond {
1913   my ($self, $cond, $collapsed) = @_;
1914
1915   $collapsed ||= {};
1916
1917   if (ref $cond eq 'ARRAY') {
1918     foreach my $subcond (@$cond) {
1919       next unless ref $subcond;  # -or
1920       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1921     }
1922   }
1923   elsif (ref $cond eq 'HASH') {
1924     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1925       foreach my $subcond (@{$cond->{-and}}) {
1926         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1927       }
1928     }
1929     else {
1930       foreach my $col (keys %$cond) {
1931         my $value = $cond->{$col};
1932         $collapsed->{$col} = $value;
1933       }
1934     }
1935   }
1936
1937   return $collapsed;
1938 }
1939
1940 # _remove_alias
1941 #
1942 # Remove the specified alias from the specified query hash. A copy is made so
1943 # the original query is not modified.
1944
1945 sub _remove_alias {
1946   my ($self, $query, $alias) = @_;
1947
1948   my %orig = %{ $query || {} };
1949   my %unaliased;
1950
1951   foreach my $key (keys %orig) {
1952     if ($key !~ /\./) {
1953       $unaliased{$key} = $orig{$key};
1954       next;
1955     }
1956     $unaliased{$1} = $orig{$key}
1957       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1958   }
1959
1960   return \%unaliased;
1961 }
1962
1963 =head2 as_query (EXPERIMENTAL)
1964
1965 =over 4
1966
1967 =item Arguments: none
1968
1969 =item Return Value: \[ $sql, @bind ]
1970
1971 =back
1972
1973 Returns the SQL query and bind vars associated with the invocant.
1974
1975 This is generally used as the RHS for a subquery.
1976
1977 B<NOTE>: This feature is still experimental.
1978
1979 =cut
1980
1981 sub as_query { return shift->cursor->as_query(@_) }
1982
1983 =head2 find_or_new
1984
1985 =over 4
1986
1987 =item Arguments: \%vals, \%attrs?
1988
1989 =item Return Value: $rowobject
1990
1991 =back
1992
1993   my $artist = $schema->resultset('Artist')->find_or_new(
1994     { artist => 'fred' }, { key => 'artists' });
1995
1996   $cd->cd_to_producer->find_or_new({ producer => $producer },
1997                                    { key => 'primary });
1998
1999 Find an existing record from this resultset, based on its primary
2000 key, or a unique constraint. If none exists, instantiate a new result
2001 object and return it. The object will not be saved into your storage
2002 until you call L<DBIx::Class::Row/insert> on it.
2003
2004 You most likely want this method when looking for existing rows using
2005 a unique constraint that is not the primary key, or looking for
2006 related rows.
2007
2008 If you want objects to be saved immediately, use L</find_or_create> instead.
2009
2010 B<Note>: C<find_or_new> is probably not what you want when creating a
2011 new row in a table that uses primary keys supplied by the
2012 database. Passing in a primary key column with a value of I<undef>
2013 will cause L</find> to attempt to search for a row with a value of
2014 I<NULL>.
2015
2016 =cut
2017
2018 sub find_or_new {
2019   my $self     = shift;
2020   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2021   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2022   my $exists   = $self->find($hash, $attrs);
2023   return defined $exists ? $exists : $self->new_result($hash);
2024 }
2025
2026 =head2 create
2027
2028 =over 4
2029
2030 =item Arguments: \%vals
2031
2032 =item Return Value: a L<DBIx::Class::Row> $object
2033
2034 =back
2035
2036 Attempt to create a single new row or a row with multiple related rows
2037 in the table represented by the resultset (and related tables). This
2038 will not check for duplicate rows before inserting, use
2039 L</find_or_create> to do that.
2040
2041 To create one row for this resultset, pass a hashref of key/value
2042 pairs representing the columns of the table and the values you wish to
2043 store. If the appropriate relationships are set up, foreign key fields
2044 can also be passed an object representing the foreign row, and the
2045 value will be set to its primary key.
2046
2047 To create related objects, pass a hashref for the value if the related
2048 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2049 and use the name of the relationship as the key. (NOT the name of the field,
2050 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2051 of hashrefs containing the data for each of the rows to create in the foreign
2052 tables, again using the relationship name as the key.
2053
2054 Instead of hashrefs of plain related data (key/value pairs), you may
2055 also pass new or inserted objects. New objects (not inserted yet, see
2056 L</new>), will be inserted into their appropriate tables.
2057
2058 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2059
2060 Example of creating a new row.
2061
2062   $person_rs->create({
2063     name=>"Some Person",
2064     email=>"somebody@someplace.com"
2065   });
2066
2067 Example of creating a new row and also creating rows in a related C<has_many>
2068 or C<has_one> resultset.  Note Arrayref.
2069
2070   $artist_rs->create(
2071      { artistid => 4, name => 'Manufactured Crap', cds => [
2072         { title => 'My First CD', year => 2006 },
2073         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2074       ],
2075      },
2076   );
2077
2078 Example of creating a new row and also creating a row in a related
2079 C<belongs_to>resultset. Note Hashref.
2080
2081   $cd_rs->create({
2082     title=>"Music for Silly Walks",
2083     year=>2000,
2084     artist => {
2085       name=>"Silly Musician",
2086     }
2087   });
2088
2089 =cut
2090
2091 sub create {
2092   my ($self, $attrs) = @_;
2093   $self->throw_exception( "create needs a hashref" )
2094     unless ref $attrs eq 'HASH';
2095   return $self->new_result($attrs)->insert;
2096 }
2097
2098 =head2 find_or_create
2099
2100 =over 4
2101
2102 =item Arguments: \%vals, \%attrs?
2103
2104 =item Return Value: $rowobject
2105
2106 =back
2107
2108   $cd->cd_to_producer->find_or_create({ producer => $producer },
2109                                       { key => 'primary });
2110
2111 Tries to find a record based on its primary key or unique constraints; if none
2112 is found, creates one and returns that instead.
2113
2114   my $cd = $schema->resultset('CD')->find_or_create({
2115     cdid   => 5,
2116     artist => 'Massive Attack',
2117     title  => 'Mezzanine',
2118     year   => 2005,
2119   });
2120
2121 Also takes an optional C<key> attribute, to search by a specific key or unique
2122 constraint. For example:
2123
2124   my $cd = $schema->resultset('CD')->find_or_create(
2125     {
2126       artist => 'Massive Attack',
2127       title  => 'Mezzanine',
2128     },
2129     { key => 'cd_artist_title' }
2130   );
2131
2132 B<Note>: Because find_or_create() reads from the database and then
2133 possibly inserts based on the result, this method is subject to a race
2134 condition. Another process could create a record in the table after
2135 the find has completed and before the create has started. To avoid
2136 this problem, use find_or_create() inside a transaction.
2137
2138 B<Note>: C<find_or_create> is probably not what you want when creating
2139 a new row in a table that uses primary keys supplied by the
2140 database. Passing in a primary key column with a value of I<undef>
2141 will cause L</find> to attempt to search for a row with a value of
2142 I<NULL>.
2143
2144 See also L</find> and L</update_or_create>. For information on how to declare
2145 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2146
2147 =cut
2148
2149 sub find_or_create {
2150   my $self     = shift;
2151   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2152   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2153   my $exists   = $self->find($hash, $attrs);
2154   return defined $exists ? $exists : $self->create($hash);
2155 }
2156
2157 =head2 update_or_create
2158
2159 =over 4
2160
2161 =item Arguments: \%col_values, { key => $unique_constraint }?
2162
2163 =item Return Value: $rowobject
2164
2165 =back
2166
2167   $resultset->update_or_create({ col => $val, ... });
2168
2169 First, searches for an existing row matching one of the unique constraints
2170 (including the primary key) on the source of this resultset. If a row is
2171 found, updates it with the other given column values. Otherwise, creates a new
2172 row.
2173
2174 Takes an optional C<key> attribute to search on a specific unique constraint.
2175 For example:
2176
2177   # In your application
2178   my $cd = $schema->resultset('CD')->update_or_create(
2179     {
2180       artist => 'Massive Attack',
2181       title  => 'Mezzanine',
2182       year   => 1998,
2183     },
2184     { key => 'cd_artist_title' }
2185   );
2186
2187   $cd->cd_to_producer->update_or_create({
2188     producer => $producer,
2189     name => 'harry',
2190   }, {
2191     key => 'primary,
2192   });
2193
2194
2195 If no C<key> is specified, it searches on all unique constraints defined on the
2196 source, including the primary key.
2197
2198 If the C<key> is specified as C<primary>, it searches only on the primary key.
2199
2200 See also L</find> and L</find_or_create>. For information on how to declare
2201 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2202
2203 B<Note>: C<update_or_create> is probably not what you want when
2204 looking for a row in a table that uses primary keys supplied by the
2205 database, unless you actually have a key value. Passing in a primary
2206 key column with a value of I<undef> will cause L</find> to attempt to
2207 search for a row with a value of I<NULL>.
2208
2209 =cut
2210
2211 sub update_or_create {
2212   my $self = shift;
2213   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2214   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2215
2216   my $row = $self->find($cond, $attrs);
2217   if (defined $row) {
2218     $row->update($cond);
2219     return $row;
2220   }
2221
2222   return $self->create($cond);
2223 }
2224
2225 =head2 update_or_new
2226
2227 =over 4
2228
2229 =item Arguments: \%col_values, { key => $unique_constraint }?
2230
2231 =item Return Value: $rowobject
2232
2233 =back
2234
2235   $resultset->update_or_new({ col => $val, ... });
2236
2237 First, searches for an existing row matching one of the unique constraints
2238 (including the primary key) on the source of this resultset. If a row is
2239 found, updates it with the other given column values. Otherwise, instantiate
2240 a new result object and return it. The object will not be saved into your storage
2241 until you call L<DBIx::Class::Row/insert> on it.
2242
2243 Takes an optional C<key> attribute to search on a specific unique constraint.
2244 For example:
2245
2246   # In your application
2247   my $cd = $schema->resultset('CD')->update_or_new(
2248     {
2249       artist => 'Massive Attack',
2250       title  => 'Mezzanine',
2251       year   => 1998,
2252     },
2253     { key => 'cd_artist_title' }
2254   );
2255
2256   if ($cd->in_storage) {
2257       # the cd was updated
2258   }
2259   else {
2260       # the cd is not yet in the database, let's insert it
2261       $cd->insert;
2262   }
2263
2264 See also L</find>, L</find_or_create> and L<find_or_new>.
2265
2266 =cut
2267
2268 sub update_or_new {
2269     my $self  = shift;
2270     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2271     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2272
2273     my $row = $self->find( $cond, $attrs );
2274     if ( defined $row ) {
2275         $row->update($cond);
2276         return $row;
2277     }
2278
2279     return $self->new_result($cond);
2280 }
2281
2282 =head2 get_cache
2283
2284 =over 4
2285
2286 =item Arguments: none
2287
2288 =item Return Value: \@cache_objects?
2289
2290 =back
2291
2292 Gets the contents of the cache for the resultset, if the cache is set.
2293
2294 The cache is populated either by using the L</prefetch> attribute to
2295 L</search> or by calling L</set_cache>.
2296
2297 =cut
2298
2299 sub get_cache {
2300   shift->{all_cache};
2301 }
2302
2303 =head2 set_cache
2304
2305 =over 4
2306
2307 =item Arguments: \@cache_objects
2308
2309 =item Return Value: \@cache_objects
2310
2311 =back
2312
2313 Sets the contents of the cache for the resultset. Expects an arrayref
2314 of objects of the same class as those produced by the resultset. Note that
2315 if the cache is set the resultset will return the cached objects rather
2316 than re-querying the database even if the cache attr is not set.
2317
2318 The contents of the cache can also be populated by using the
2319 L</prefetch> attribute to L</search>.
2320
2321 =cut
2322
2323 sub set_cache {
2324   my ( $self, $data ) = @_;
2325   $self->throw_exception("set_cache requires an arrayref")
2326       if defined($data) && (ref $data ne 'ARRAY');
2327   $self->{all_cache} = $data;
2328 }
2329
2330 =head2 clear_cache
2331
2332 =over 4
2333
2334 =item Arguments: none
2335
2336 =item Return Value: []
2337
2338 =back
2339
2340 Clears the cache for the resultset.
2341
2342 =cut
2343
2344 sub clear_cache {
2345   shift->set_cache(undef);
2346 }
2347
2348 =head2 related_resultset
2349
2350 =over 4
2351
2352 =item Arguments: $relationship_name
2353
2354 =item Return Value: $resultset
2355
2356 =back
2357
2358 Returns a related resultset for the supplied relationship name.
2359
2360   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2361
2362 =cut
2363
2364 sub related_resultset {
2365   my ($self, $rel) = @_;
2366
2367   $self->{related_resultsets} ||= {};
2368   return $self->{related_resultsets}{$rel} ||= do {
2369     my $rel_obj = $self->result_source->relationship_info($rel);
2370
2371     $self->throw_exception(
2372       "search_related: result source '" . $self->result_source->source_name .
2373         "' has no such relationship $rel")
2374       unless $rel_obj;
2375
2376     my ($from,$seen) = $self->_resolve_from($rel);
2377
2378     my $join_count = $seen->{$rel};
2379     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2380
2381     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2382     my %attrs = %{$self->{attrs}||{}};
2383     delete @attrs{qw(result_class alias)};
2384
2385     my $new_cache;
2386
2387     if (my $cache = $self->get_cache) {
2388       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2389         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2390                         @$cache ];
2391       }
2392     }
2393
2394     my $rel_source = $self->result_source->related_source($rel);
2395
2396     my $new = do {
2397
2398       # The reason we do this now instead of passing the alias to the
2399       # search_rs below is that if you wrap/overload resultset on the
2400       # source you need to know what alias it's -going- to have for things
2401       # to work sanely (e.g. RestrictWithObject wants to be able to add
2402       # extra query restrictions, and these may need to be $alias.)
2403
2404       my $attrs = $rel_source->resultset_attributes;
2405       local $attrs->{alias} = $alias;
2406
2407       $rel_source->resultset
2408                  ->search_rs(
2409                      undef, {
2410                        %attrs,
2411                        join => undef,
2412                        prefetch => undef,
2413                        select => undef,
2414                        as => undef,
2415                        where => $self->{cond},
2416                        seen_join => $seen,
2417                        from => $from,
2418                    });
2419     };
2420     $new->set_cache($new_cache) if $new_cache;
2421     $new;
2422   };
2423 }
2424
2425 =head2 current_source_alias
2426
2427 =over 4
2428
2429 =item Arguments: none
2430
2431 =item Return Value: $source_alias
2432
2433 =back
2434
2435 Returns the current table alias for the result source this resultset is built
2436 on, that will be used in the SQL query. Usually it is C<me>.
2437
2438 Currently the source alias that refers to the result set returned by a
2439 L</search>/L</find> family method depends on how you got to the resultset: it's
2440 C<me> by default, but eg. L</search_related> aliases it to the related result
2441 source name (and keeps C<me> referring to the original result set). The long
2442 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2443 (and make this method unnecessary).
2444
2445 Thus it's currently necessary to use this method in predefined queries (see
2446 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2447 source alias of the current result set:
2448
2449   # in a result set class
2450   sub modified_by {
2451     my ($self, $user) = @_;
2452
2453     my $me = $self->current_source_alias;
2454
2455     return $self->search(
2456       "$me.modified" => $user->id,
2457     );
2458   }
2459
2460 =cut
2461
2462 sub current_source_alias {
2463   my ($self) = @_;
2464
2465   return ($self->{attrs} || {})->{alias} || 'me';
2466 }
2467
2468 # This code is called by search_related, and makes sure there
2469 # is clear separation between the joins before, during, and
2470 # after the relationship. This information is needed later
2471 # in order to properly resolve prefetch aliases (any alias
2472 # with a relation_chain_depth less than the depth of the
2473 # current prefetch is not considered)
2474 sub _resolve_from {
2475   my ($self, $extra_join) = @_;
2476   my $source = $self->result_source;
2477   my $attrs = $self->{attrs};
2478
2479   my $from = $attrs->{from}
2480     || [ { $attrs->{alias} => $source->from } ];
2481
2482   my $seen = { %{$attrs->{seen_join}||{}} };
2483
2484   # we need to take the prefetch the attrs into account before we
2485   # ->_resolve_join as otherwise they get lost - captainL
2486   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2487
2488   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2489
2490   ++$seen->{-relation_chain_depth};
2491
2492   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2493
2494   ++$seen->{-relation_chain_depth};
2495
2496   return ($from,$seen);
2497 }
2498
2499 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2500 sub _resolved_attrs_copy {
2501   my $self = shift;
2502   return { %{$self->_resolved_attrs (@_)} };
2503 }
2504
2505 sub _resolved_attrs {
2506   my $self = shift;
2507   return $self->{_attrs} if $self->{_attrs};
2508
2509   my $attrs  = { %{ $self->{attrs} || {} } };
2510   my $source = $self->result_source;
2511   my $alias  = $attrs->{alias};
2512
2513   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2514   my @colbits;
2515
2516   # build columns (as long as select isn't set) into a set of as/select hashes
2517   unless ( $attrs->{select} ) {
2518       @colbits = map {
2519           ( ref($_) eq 'HASH' )
2520               ? $_
2521               : {
2522                   (
2523                     /^\Q${alias}.\E(.+)$/
2524                       ? "$1"
2525                       : "$_"
2526                   )
2527                 =>
2528                   (
2529                     /\./
2530                       ? "$_"
2531                       : "${alias}.$_"
2532                   )
2533             }
2534       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2535   }
2536   # add the additional columns on
2537   foreach ( 'include_columns', '+columns' ) {
2538       push @colbits, map {
2539           ( ref($_) eq 'HASH' )
2540             ? $_
2541             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2542       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2543   }
2544
2545   # start with initial select items
2546   if ( $attrs->{select} ) {
2547     $attrs->{select} =
2548         ( ref $attrs->{select} eq 'ARRAY' )
2549       ? [ @{ $attrs->{select} } ]
2550       : [ $attrs->{select} ];
2551     $attrs->{as} = (
2552       $attrs->{as}
2553       ? (
2554         ref $attrs->{as} eq 'ARRAY'
2555         ? [ @{ $attrs->{as} } ]
2556         : [ $attrs->{as} ]
2557         )
2558       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2559     );
2560   }
2561   else {
2562
2563     # otherwise we intialise select & as to empty
2564     $attrs->{select} = [];
2565     $attrs->{as}     = [];
2566   }
2567
2568   # now add colbits to select/as
2569   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2570   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2571
2572   my $adds;
2573   if ( $adds = delete $attrs->{'+select'} ) {
2574     $adds = [$adds] unless ref $adds eq 'ARRAY';
2575     push(
2576       @{ $attrs->{select} },
2577       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2578     );
2579   }
2580   if ( $adds = delete $attrs->{'+as'} ) {
2581     $adds = [$adds] unless ref $adds eq 'ARRAY';
2582     push( @{ $attrs->{as} }, @$adds );
2583   }
2584
2585   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2586
2587   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2588     my $join = delete $attrs->{join} || {};
2589
2590     if ( defined $attrs->{prefetch} ) {
2591       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2592
2593     }
2594
2595     $attrs->{from} =    # have to copy here to avoid corrupting the original
2596       [
2597       @{ $attrs->{from} },
2598       $source->_resolve_join(
2599         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2600       )
2601       ];
2602
2603   }
2604
2605   $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ]
2606     if delete $attrs->{distinct};
2607   if ( $attrs->{order_by} ) {
2608     $attrs->{order_by} = (
2609       ref( $attrs->{order_by} ) eq 'ARRAY'
2610       ? [ @{ $attrs->{order_by} } ]
2611       : [ $attrs->{order_by} ]
2612     );
2613   }
2614   else {
2615     $attrs->{order_by} = [];
2616   }
2617
2618   my $collapse = $attrs->{collapse} || {};
2619   if ( my $prefetch = delete $attrs->{prefetch} ) {
2620     $prefetch = $self->_merge_attr( {}, $prefetch );
2621     my @pre_order;
2622     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2623
2624       # bring joins back to level of current class
2625       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2626       my @prefetch =
2627         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2628       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2629       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2630     }
2631     push( @{ $attrs->{order_by} }, @pre_order );
2632   }
2633   $attrs->{collapse} = $collapse;
2634
2635   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2636     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2637   }
2638
2639   return $self->{_attrs} = $attrs;
2640 }
2641
2642 sub _joinpath_aliases {
2643   my ($self, $fromspec, $seen) = @_;
2644
2645   my $paths = {};
2646   return $paths unless ref $fromspec eq 'ARRAY';
2647
2648   for my $j (@$fromspec) {
2649
2650     next if ref $j ne 'ARRAY';
2651     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2652
2653     my $p = $paths;
2654     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2655     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2656   }
2657
2658   return $paths;
2659 }
2660
2661 sub _rollout_attr {
2662   my ($self, $attr) = @_;
2663
2664   if (ref $attr eq 'HASH') {
2665     return $self->_rollout_hash($attr);
2666   } elsif (ref $attr eq 'ARRAY') {
2667     return $self->_rollout_array($attr);
2668   } else {
2669     return [$attr];
2670   }
2671 }
2672
2673 sub _rollout_array {
2674   my ($self, $attr) = @_;
2675
2676   my @rolled_array;
2677   foreach my $element (@{$attr}) {
2678     if (ref $element eq 'HASH') {
2679       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2680     } elsif (ref $element eq 'ARRAY') {
2681       #  XXX - should probably recurse here
2682       push( @rolled_array, @{$self->_rollout_array($element)} );
2683     } else {
2684       push( @rolled_array, $element );
2685     }
2686   }
2687   return \@rolled_array;
2688 }
2689
2690 sub _rollout_hash {
2691   my ($self, $attr) = @_;
2692
2693   my @rolled_array;
2694   foreach my $key (keys %{$attr}) {
2695     push( @rolled_array, { $key => $attr->{$key} } );
2696   }
2697   return \@rolled_array;
2698 }
2699
2700 sub _calculate_score {
2701   my ($self, $a, $b) = @_;
2702
2703   if (ref $b eq 'HASH') {
2704     my ($b_key) = keys %{$b};
2705     if (ref $a eq 'HASH') {
2706       my ($a_key) = keys %{$a};
2707       if ($a_key eq $b_key) {
2708         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2709       } else {
2710         return 0;
2711       }
2712     } else {
2713       return ($a eq $b_key) ? 1 : 0;
2714     }
2715   } else {
2716     if (ref $a eq 'HASH') {
2717       my ($a_key) = keys %{$a};
2718       return ($b eq $a_key) ? 1 : 0;
2719     } else {
2720       return ($b eq $a) ? 1 : 0;
2721     }
2722   }
2723 }
2724
2725 sub _merge_attr {
2726   my ($self, $orig, $import) = @_;
2727
2728   return $import unless defined($orig);
2729   return $orig unless defined($import);
2730
2731   $orig = $self->_rollout_attr($orig);
2732   $import = $self->_rollout_attr($import);
2733
2734   my $seen_keys;
2735   foreach my $import_element ( @{$import} ) {
2736     # find best candidate from $orig to merge $b_element into
2737     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2738     foreach my $orig_element ( @{$orig} ) {
2739       my $score = $self->_calculate_score( $orig_element, $import_element );
2740       if ($score > $best_candidate->{score}) {
2741         $best_candidate->{position} = $position;
2742         $best_candidate->{score} = $score;
2743       }
2744       $position++;
2745     }
2746     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2747
2748     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2749       push( @{$orig}, $import_element );
2750     } else {
2751       my $orig_best = $orig->[$best_candidate->{position}];
2752       # merge orig_best and b_element together and replace original with merged
2753       if (ref $orig_best ne 'HASH') {
2754         $orig->[$best_candidate->{position}] = $import_element;
2755       } elsif (ref $import_element eq 'HASH') {
2756         my ($key) = keys %{$orig_best};
2757         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2758       }
2759     }
2760     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2761   }
2762
2763   return $orig;
2764 }
2765
2766 sub result_source {
2767     my $self = shift;
2768
2769     if (@_) {
2770         $self->_source_handle($_[0]->handle);
2771     } else {
2772         $self->_source_handle->resolve;
2773     }
2774 }
2775
2776 =head2 throw_exception
2777
2778 See L<DBIx::Class::Schema/throw_exception> for details.
2779
2780 =cut
2781
2782 sub throw_exception {
2783   my $self=shift;
2784   if (ref $self && $self->_source_handle->schema) {
2785     $self->_source_handle->schema->throw_exception(@_)
2786   } else {
2787     croak(@_);
2788   }
2789
2790 }
2791
2792 # XXX: FIXME: Attributes docs need clearing up
2793
2794 =head1 ATTRIBUTES
2795
2796 Attributes are used to refine a ResultSet in various ways when
2797 searching for data. They can be passed to any method which takes an
2798 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2799 L</count>.
2800
2801 These are in no particular order:
2802
2803 =head2 order_by
2804
2805 =over 4
2806
2807 =item Value: ( $order_by | \@order_by | \%order_by )
2808
2809 =back
2810
2811 Which column(s) to order the results by. If a single column name, or
2812 an arrayref of names is supplied, the argument is passed through
2813 directly to SQL. The hashref syntax allows for connection-agnostic
2814 specification of ordering direction:
2815
2816  For descending order:
2817
2818   order_by => { -desc => [qw/col1 col2 col3/] }
2819
2820  For explicit ascending order:
2821
2822   order_by => { -asc => 'col' }
2823
2824 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2825 supported, although you are strongly encouraged to use the hashref
2826 syntax as outlined above.
2827
2828 =head2 columns
2829
2830 =over 4
2831
2832 =item Value: \@columns
2833
2834 =back
2835
2836 Shortcut to request a particular set of columns to be retrieved. Each
2837 column spec may be a string (a table column name), or a hash (in which
2838 case the key is the C<as> value, and the value is used as the C<select>
2839 expression). Adds C<me.> onto the start of any column without a C<.> in
2840 it and sets C<select> from that, then auto-populates C<as> from
2841 C<select> as normal. (You may also use the C<cols> attribute, as in
2842 earlier versions of DBIC.)
2843
2844 =head2 +columns
2845
2846 =over 4
2847
2848 =item Value: \@columns
2849
2850 =back
2851
2852 Indicates additional columns to be selected from storage. Works the same
2853 as L</columns> but adds columns to the selection. (You may also use the
2854 C<include_columns> attribute, as in earlier versions of DBIC). For
2855 example:-
2856
2857   $schema->resultset('CD')->search(undef, {
2858     '+columns' => ['artist.name'],
2859     join => ['artist']
2860   });
2861
2862 would return all CDs and include a 'name' column to the information
2863 passed to object inflation. Note that the 'artist' is the name of the
2864 column (or relationship) accessor, and 'name' is the name of the column
2865 accessor in the related table.
2866
2867 =head2 include_columns
2868
2869 =over 4
2870
2871 =item Value: \@columns
2872
2873 =back
2874
2875 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2876
2877 =head2 select
2878
2879 =over 4
2880
2881 =item Value: \@select_columns
2882
2883 =back
2884
2885 Indicates which columns should be selected from the storage. You can use
2886 column names, or in the case of RDBMS back ends, function or stored procedure
2887 names:
2888
2889   $rs = $schema->resultset('Employee')->search(undef, {
2890     select => [
2891       'name',
2892       { count => 'employeeid' },
2893       { sum => 'salary' }
2894     ]
2895   });
2896
2897 When you use function/stored procedure names and do not supply an C<as>
2898 attribute, the column names returned are storage-dependent. E.g. MySQL would
2899 return a column named C<count(employeeid)> in the above example.
2900
2901 =head2 +select
2902
2903 =over 4
2904
2905 Indicates additional columns to be selected from storage.  Works the same as
2906 L</select> but adds columns to the selection.
2907
2908 =back
2909
2910 =head2 +as
2911
2912 =over 4
2913
2914 Indicates additional column names for those added via L</+select>. See L</as>.
2915
2916 =back
2917
2918 =head2 as
2919
2920 =over 4
2921
2922 =item Value: \@inflation_names
2923
2924 =back
2925
2926 Indicates column names for object inflation. That is, C<as>
2927 indicates the name that the column can be accessed as via the
2928 C<get_column> method (or via the object accessor, B<if one already
2929 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2930
2931 The C<as> attribute is used in conjunction with C<select>,
2932 usually when C<select> contains one or more function or stored
2933 procedure names:
2934
2935   $rs = $schema->resultset('Employee')->search(undef, {
2936     select => [
2937       'name',
2938       { count => 'employeeid' }
2939     ],
2940     as => ['name', 'employee_count'],
2941   });
2942
2943   my $employee = $rs->first(); # get the first Employee
2944
2945 If the object against which the search is performed already has an accessor
2946 matching a column name specified in C<as>, the value can be retrieved using
2947 the accessor as normal:
2948
2949   my $name = $employee->name();
2950
2951 If on the other hand an accessor does not exist in the object, you need to
2952 use C<get_column> instead:
2953
2954   my $employee_count = $employee->get_column('employee_count');
2955
2956 You can create your own accessors if required - see
2957 L<DBIx::Class::Manual::Cookbook> for details.
2958
2959 Please note: This will NOT insert an C<AS employee_count> into the SQL
2960 statement produced, it is used for internal access only. Thus
2961 attempting to use the accessor in an C<order_by> clause or similar
2962 will fail miserably.
2963
2964 To get around this limitation, you can supply literal SQL to your
2965 C<select> attibute that contains the C<AS alias> text, eg:
2966
2967   select => [\'myfield AS alias']
2968
2969 =head2 join
2970
2971 =over 4
2972
2973 =item Value: ($rel_name | \@rel_names | \%rel_names)
2974
2975 =back
2976
2977 Contains a list of relationships that should be joined for this query.  For
2978 example:
2979
2980   # Get CDs by Nine Inch Nails
2981   my $rs = $schema->resultset('CD')->search(
2982     { 'artist.name' => 'Nine Inch Nails' },
2983     { join => 'artist' }
2984   );
2985
2986 Can also contain a hash reference to refer to the other relation's relations.
2987 For example:
2988
2989   package MyApp::Schema::Track;
2990   use base qw/DBIx::Class/;
2991   __PACKAGE__->table('track');
2992   __PACKAGE__->add_columns(qw/trackid cd position title/);
2993   __PACKAGE__->set_primary_key('trackid');
2994   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2995   1;
2996
2997   # In your application
2998   my $rs = $schema->resultset('Artist')->search(
2999     { 'track.title' => 'Teardrop' },
3000     {
3001       join     => { cd => 'track' },
3002       order_by => 'artist.name',
3003     }
3004   );
3005
3006 You need to use the relationship (not the table) name in  conditions,
3007 because they are aliased as such. The current table is aliased as "me", so
3008 you need to use me.column_name in order to avoid ambiguity. For example:
3009
3010   # Get CDs from 1984 with a 'Foo' track
3011   my $rs = $schema->resultset('CD')->search(
3012     {
3013       'me.year' => 1984,
3014       'tracks.name' => 'Foo'
3015     },
3016     { join => 'tracks' }
3017   );
3018
3019 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3020 similarly for a third time). For e.g.
3021
3022   my $rs = $schema->resultset('Artist')->search({
3023     'cds.title'   => 'Down to Earth',
3024     'cds_2.title' => 'Popular',
3025   }, {
3026     join => [ qw/cds cds/ ],
3027   });
3028
3029 will return a set of all artists that have both a cd with title 'Down
3030 to Earth' and a cd with title 'Popular'.
3031
3032 If you want to fetch related objects from other tables as well, see C<prefetch>
3033 below.
3034
3035 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3036
3037 =head2 prefetch
3038
3039 =over 4
3040
3041 =item Value: ($rel_name | \@rel_names | \%rel_names)
3042
3043 =back
3044
3045 Contains one or more relationships that should be fetched along with
3046 the main query (when they are accessed afterwards the data will
3047 already be available, without extra queries to the database).  This is
3048 useful for when you know you will need the related objects, because it
3049 saves at least one query:
3050
3051   my $rs = $schema->resultset('Tag')->search(
3052     undef,
3053     {
3054       prefetch => {
3055         cd => 'artist'
3056       }
3057     }
3058   );
3059
3060 The initial search results in SQL like the following:
3061
3062   SELECT tag.*, cd.*, artist.* FROM tag
3063   JOIN cd ON tag.cd = cd.cdid
3064   JOIN artist ON cd.artist = artist.artistid
3065
3066 L<DBIx::Class> has no need to go back to the database when we access the
3067 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3068 case.
3069
3070 Simple prefetches will be joined automatically, so there is no need
3071 for a C<join> attribute in the above search.
3072
3073 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3074 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3075 with an accessor type of 'single' or 'filter'). A more complex example that
3076 prefetches an artists cds, the tracks on those cds, and the tags associted
3077 with that artist is given below (assuming many-to-many from artists to tags):
3078
3079  my $rs = $schema->resultset('Artist')->search(
3080    undef,
3081    {
3082      prefetch => [
3083        { cds => 'tracks' },
3084        { artist_tags => 'tags' }
3085      ]
3086    }
3087  );
3088
3089
3090 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3091 attributes will be ignored.
3092
3093 =head2 page
3094
3095 =over 4
3096
3097 =item Value: $page
3098
3099 =back
3100
3101 Makes the resultset paged and specifies the page to retrieve. Effectively
3102 identical to creating a non-pages resultset and then calling ->page($page)
3103 on it.
3104
3105 If L<rows> attribute is not specified it defualts to 10 rows per page.
3106
3107 When you have a paged resultset, L</count> will only return the number
3108 of rows in the page. To get the total, use the L</pager> and call
3109 C<total_entries> on it.
3110
3111 =head2 rows
3112
3113 =over 4
3114
3115 =item Value: $rows
3116
3117 =back
3118
3119 Specifes the maximum number of rows for direct retrieval or the number of
3120 rows per page if the page attribute or method is used.
3121
3122 =head2 offset
3123
3124 =over 4
3125
3126 =item Value: $offset
3127
3128 =back
3129
3130 Specifies the (zero-based) row number for the  first row to be returned, or the
3131 of the first row of the first page if paging is used.
3132
3133 =head2 group_by
3134
3135 =over 4
3136
3137 =item Value: \@columns
3138
3139 =back
3140
3141 A arrayref of columns to group by. Can include columns of joined tables.
3142
3143   group_by => [qw/ column1 column2 ... /]
3144
3145 =head2 having
3146
3147 =over 4
3148
3149 =item Value: $condition
3150
3151 =back
3152
3153 HAVING is a select statement attribute that is applied between GROUP BY and
3154 ORDER BY. It is applied to the after the grouping calculations have been
3155 done.
3156
3157   having => { 'count(employee)' => { '>=', 100 } }
3158
3159 =head2 distinct
3160
3161 =over 4
3162
3163 =item Value: (0 | 1)
3164
3165 =back
3166
3167 Set to 1 to group by all columns.
3168
3169 =head2 where
3170
3171 =over 4
3172
3173 Adds to the WHERE clause.
3174
3175   # only return rows WHERE deleted IS NULL for all searches
3176   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3177
3178 Can be overridden by passing C<{ where => undef }> as an attribute
3179 to a resulset.
3180
3181 =back
3182
3183 =head2 cache
3184
3185 Set to 1 to cache search results. This prevents extra SQL queries if you
3186 revisit rows in your ResultSet:
3187
3188   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3189
3190   while( my $artist = $resultset->next ) {
3191     ... do stuff ...
3192   }
3193
3194   $rs->first; # without cache, this would issue a query
3195
3196 By default, searches are not cached.
3197
3198 For more examples of using these attributes, see
3199 L<DBIx::Class::Manual::Cookbook>.
3200
3201 =head2 from
3202
3203 =over 4
3204
3205 =item Value: \@from_clause
3206
3207 =back
3208
3209 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3210 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3211 clauses.
3212
3213 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3214
3215 C<join> will usually do what you need and it is strongly recommended that you
3216 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3217 And we really do mean "cannot", not just tried and failed. Attempting to use
3218 this because you're having problems with C<join> is like trying to use x86
3219 ASM because you've got a syntax error in your C. Trust us on this.
3220
3221 Now, if you're still really, really sure you need to use this (and if you're
3222 not 100% sure, ask the mailing list first), here's an explanation of how this
3223 works.
3224
3225 The syntax is as follows -
3226
3227   [
3228     { <alias1> => <table1> },
3229     [
3230       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3231       [], # nested JOIN (optional)
3232       { <table1.column1> => <table2.column2>, ... (more conditions) },
3233     ],
3234     # More of the above [ ] may follow for additional joins
3235   ]
3236
3237   <table1> <alias1>
3238   JOIN
3239     <table2> <alias2>
3240     [JOIN ...]
3241   ON <table1.column1> = <table2.column2>
3242   <more joins may follow>
3243
3244 An easy way to follow the examples below is to remember the following:
3245
3246     Anything inside "[]" is a JOIN
3247     Anything inside "{}" is a condition for the enclosing JOIN
3248
3249 The following examples utilize a "person" table in a family tree application.
3250 In order to express parent->child relationships, this table is self-joined:
3251
3252     # Person->belongs_to('father' => 'Person');
3253     # Person->belongs_to('mother' => 'Person');
3254
3255 C<from> can be used to nest joins. Here we return all children with a father,
3256 then search against all mothers of those children:
3257
3258   $rs = $schema->resultset('Person')->search(
3259       undef,
3260       {
3261           alias => 'mother', # alias columns in accordance with "from"
3262           from => [
3263               { mother => 'person' },
3264               [
3265                   [
3266                       { child => 'person' },
3267                       [
3268                           { father => 'person' },
3269                           { 'father.person_id' => 'child.father_id' }
3270                       ]
3271                   ],
3272                   { 'mother.person_id' => 'child.mother_id' }
3273               ],
3274           ]
3275       },
3276   );
3277
3278   # Equivalent SQL:
3279   # SELECT mother.* FROM person mother
3280   # JOIN (
3281   #   person child
3282   #   JOIN person father
3283   #   ON ( father.person_id = child.father_id )
3284   # )
3285   # ON ( mother.person_id = child.mother_id )
3286
3287 The type of any join can be controlled manually. To search against only people
3288 with a father in the person table, we could explicitly use C<INNER JOIN>:
3289
3290     $rs = $schema->resultset('Person')->search(
3291         undef,
3292         {
3293             alias => 'child', # alias columns in accordance with "from"
3294             from => [
3295                 { child => 'person' },
3296                 [
3297                     { father => 'person', -join_type => 'inner' },
3298                     { 'father.id' => 'child.father_id' }
3299                 ],
3300             ]
3301         },
3302     );
3303
3304     # Equivalent SQL:
3305     # SELECT child.* FROM person child
3306     # INNER JOIN person father ON child.father_id = father.id
3307
3308 If you need to express really complex joins or you need a subselect, you
3309 can supply literal SQL to C<from> via a scalar reference. In this case
3310 the contents of the scalar will replace the table name asscoiated with the
3311 resultsource.
3312
3313 WARNING: This technique might very well not work as expected on chained
3314 searches - you have been warned.
3315
3316     # Assuming the Event resultsource is defined as:
3317
3318         MySchema::Event->add_columns (
3319             sequence => {
3320                 data_type => 'INT',
3321                 is_auto_increment => 1,
3322             },
3323             location => {
3324                 data_type => 'INT',
3325             },
3326             type => {
3327                 data_type => 'INT',
3328             },
3329         );
3330         MySchema::Event->set_primary_key ('sequence');
3331
3332     # This will get back the latest event for every location. The column
3333     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3334     # combo to limit the resultset
3335
3336     $rs = $schema->resultset('Event');
3337     $table = $rs->result_source->name;
3338     $latest = $rs->search (
3339         undef,
3340         { from => \ "
3341             (SELECT e1.* FROM $table e1
3342                 JOIN $table e2
3343                     ON e1.location = e2.location
3344                     AND e1.sequence < e2.sequence
3345                 WHERE e2.sequence is NULL
3346             ) me",
3347         },
3348     );
3349
3350     # Equivalent SQL (with the DBIC chunks added):
3351
3352     SELECT me.sequence, me.location, me.type FROM
3353        (SELECT e1.* FROM events e1
3354            JOIN events e2
3355                ON e1.location = e2.location
3356                AND e1.sequence < e2.sequence
3357            WHERE e2.sequence is NULL
3358        ) me;
3359
3360 =head2 for
3361
3362 =over 4
3363
3364 =item Value: ( 'update' | 'shared' )
3365
3366 =back
3367
3368 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3369 ... FOR SHARED.
3370
3371 =cut
3372
3373 1;