lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 966   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 967   @new = $self->{_attrs}{record_filter}->(@new)
 968     if exists $self->{_attrs}{record_filter};
 969   return @new;
 970 }
 971
 972 sub _collapse_result {
 973   my ($self, $as_proto, $row) = @_;
 974
 975   my @copy = @$row;
 976
 977   # 'foo'         => [ undef, 'foo' ]
 978   # 'foo.bar'     => [ 'foo', 'bar' ]
 979   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 980
 981   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 982
 983   my %collapse = %{$self->{_attrs}{collapse}||{}};
 984
 985   my @pri_index;
 986
 987   # if we're doing collapsing (has_many prefetch) we need to grab records
 988   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 989   # we know we don't have to bother.
 990
 991   # the reason for not using the collapse stuff directly is because if you
 992   # had for e.g. two artists in a row with no cds, the collapse info for
 993   # both would be NULL (undef) so you'd lose the second artist
 994
 995   # store just the index so we can check the array positions from the row
 996   # without having to contruct the full hash
 997
 998   if (keys %collapse) {
 999     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1000     foreach my $i (0 .. $#construct_as) {
1001       next if defined($construct_as[$i][0]); # only self table
1002       if (delete $pri{$construct_as[$i][1]}) {
1003         push(@pri_index, $i);
1004       }
1005       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1006     }
1007   }
1008
1009   # no need to do an if, it'll be empty if @pri_index is empty anyway
1010
1011   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1012
1013   my @const_rows;
1014
1015   do { # no need to check anything at the front, we always want the first row
1016
1017     my %const;
1018
1019     foreach my $this_as (@construct_as) {
1020       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1021     }
1022
1023     push(@const_rows, \%const);
1024
1025   } until ( # no pri_index => no collapse => drop straight out
1026       !@pri_index
1027     or
1028       do { # get another row, stash it, drop out if different PK
1029
1030         @copy = $self->cursor->next;
1031         $self->{stashed_row} = \@copy;
1032
1033         # last thing in do block, counts as true if anything doesn't match
1034
1035         # check xor defined first for NULL vs. NOT NULL then if one is
1036         # defined the other must be so check string equality
1037
1038         grep {
1039           (defined $pri_vals{$_} ^ defined $copy[$_])
1040           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1041         } @pri_index;
1042       }
1043   );
1044
1045   my $alias = $self->{attrs}{alias};
1046   my $info = [];
1047
1048   my %collapse_pos;
1049
1050   my @const_keys;
1051
1052   foreach my $const (@const_rows) {
1053     scalar @const_keys or do {
1054       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1055     };
1056     foreach my $key (@const_keys) {
1057       if (length $key) {
1058         my $target = $info;
1059         my @parts = split(/\./, $key);
1060         my $cur = '';
1061         my $data = $const->{$key};
1062         foreach my $p (@parts) {
1063           $target = $target->[1]->{$p} ||= [];
1064           $cur .= ".${p}";
1065           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1066             # collapsing at this point and on final part
1067             my $pos = $collapse_pos{$cur};
1068             CK: foreach my $ck (@ckey) {
1069               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1070                 $collapse_pos{$cur} = $data;
1071                 delete @collapse_pos{ # clear all positioning for sub-entries
1072                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1073                 };
1074                 push(@$target, []);
1075                 last CK;
1076               }
1077             }
1078           }
1079           if (exists $collapse{$cur}) {
1080             $target = $target->[-1];
1081           }
1082         }
1083         $target->[0] = $data;
1084       } else {
1085         $info->[0] = $const->{$key};
1086       }
1087     }
1088   }
1089
1090   return $info;
1091 }
1092
1093 =head2 result_source
1094
1095 =over 4
1096
1097 =item Arguments: $result_source?
1098
1099 =item Return Value: $result_source
1100
1101 =back
1102
1103 An accessor for the primary ResultSource object from which this ResultSet
1104 is derived.
1105
1106 =head2 result_class
1107
1108 =over 4
1109
1110 =item Arguments: $result_class?
1111
1112 =item Return Value: $result_class
1113
1114 =back
1115
1116 An accessor for the class to use when creating row objects. Defaults to
1117 C<< result_source->result_class >> - which in most cases is the name of the
1118 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1119
1120 Note that changing the result_class will also remove any components
1121 that were originally loaded in the source class via
1122 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1123 in the original source class will not run.
1124
1125 =cut
1126
1127 sub result_class {
1128   my ($self, $result_class) = @_;
1129   if ($result_class) {
1130     $self->ensure_class_loaded($result_class);
1131     $self->_result_class($result_class);
1132   }
1133   $self->_result_class;
1134 }
1135
1136 =head2 count
1137
1138 =over 4
1139
1140 =item Arguments: $cond, \%attrs??
1141
1142 =item Return Value: $count
1143
1144 =back
1145
1146 Performs an SQL C<COUNT> with the same query as the resultset was built
1147 with to find the number of elements. Passing arguments is equivalent to
1148 C<< $rs->search ($cond, \%attrs)->count >>
1149
1150 =cut
1151
1152 sub count {
1153   my $self = shift;
1154   return $self->search(@_)->count if @_ and defined $_[0];
1155   return scalar @{ $self->get_cache } if $self->get_cache;
1156
1157   my $meth = $self->_has_resolved_attr (qw/collapse group_by/)
1158     ? 'count_grouped'
1159     : 'count'
1160   ;
1161
1162   my $attrs = $self->_resolved_attrs_copy;
1163   my $rsrc = $self->result_source;
1164
1165   return $rsrc->storage->$meth ($rsrc, $attrs);
1166 }
1167
1168 sub _bool {
1169   return 1;
1170 }
1171
1172 =head2 count_literal
1173
1174 =over 4
1175
1176 =item Arguments: $sql_fragment, @bind_values
1177
1178 =item Return Value: $count
1179
1180 =back
1181
1182 Counts the results in a literal query. Equivalent to calling L</search_literal>
1183 with the passed arguments, then L</count>.
1184
1185 =cut
1186
1187 sub count_literal { shift->search_literal(@_)->count; }
1188
1189 =head2 all
1190
1191 =over 4
1192
1193 =item Arguments: none
1194
1195 =item Return Value: @objects
1196
1197 =back
1198
1199 Returns all elements in the resultset. Called implicitly if the resultset
1200 is returned in list context.
1201
1202 =cut
1203
1204 sub all {
1205   my $self = shift;
1206   if(@_) {
1207       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1208   }
1209
1210   return @{ $self->get_cache } if $self->get_cache;
1211
1212   my @obj;
1213
1214   # TODO: don't call resolve here
1215   if (keys %{$self->_resolved_attrs->{collapse}}) {
1216 #  if ($self->{attrs}{prefetch}) {
1217       # Using $self->cursor->all is really just an optimisation.
1218       # If we're collapsing has_many prefetches it probably makes
1219       # very little difference, and this is cleaner than hacking
1220       # _construct_object to survive the approach
1221     my @row = $self->cursor->next;
1222     while (@row) {
1223       push(@obj, $self->_construct_object(@row));
1224       @row = (exists $self->{stashed_row}
1225                ? @{delete $self->{stashed_row}}
1226                : $self->cursor->next);
1227     }
1228   } else {
1229     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1230   }
1231
1232   $self->set_cache(\@obj) if $self->{attrs}{cache};
1233   return @obj;
1234 }
1235
1236 =head2 reset
1237
1238 =over 4
1239
1240 =item Arguments: none
1241
1242 =item Return Value: $self
1243
1244 =back
1245
1246 Resets the resultset's cursor, so you can iterate through the elements again.
1247
1248 =cut
1249
1250 sub reset {
1251   my ($self) = @_;
1252   delete $self->{_attrs} if exists $self->{_attrs};
1253   $self->{all_cache_position} = 0;
1254   $self->cursor->reset;
1255   return $self;
1256 }
1257
1258 =head2 first
1259
1260 =over 4
1261
1262 =item Arguments: none
1263
1264 =item Return Value: $object?
1265
1266 =back
1267
1268 Resets the resultset and returns an object for the first result (if the
1269 resultset returns anything).
1270
1271 =cut
1272
1273 sub first {
1274   return $_[0]->reset->next;
1275 }
1276
1277
1278 # _rs_update_delete
1279 #
1280 # Determines whether and what type of subquery is required for the $rs operation.
1281 # If grouping is necessary either supplies its own, or verifies the current one
1282 # After all is done delegates to the proper storage method.
1283
1284 sub _rs_update_delete {
1285   my ($self, $op, $values) = @_;
1286
1287   my $rsrc = $self->result_source;
1288
1289   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1290   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1291
1292   if ($needs_group_by_subq or $needs_subq) {
1293
1294     # make a new $rs selecting only the PKs (that's all we really need)
1295     my $attrs = $self->_resolved_attrs_copy;
1296
1297     delete $attrs->{$_} for qw/collapse select as/;
1298     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1299
1300     if ($needs_group_by_subq) {
1301       # make sure no group_by was supplied, or if there is one - make sure it matches
1302       # the columns compiled above perfectly. Anything else can not be sanely executed
1303       # on most databases so croak right then and there
1304
1305       if (my $g = $attrs->{group_by}) {
1306         my @current_group_by = map
1307           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1308           (ref $g eq 'ARRAY' ? @$g : $g );
1309
1310         if (
1311           join ("\x00", sort @current_group_by)
1312             ne
1313           join ("\x00", sort @{$attrs->{columns}} )
1314         ) {
1315           $self->throw_exception (
1316             "You have just attempted a $op operation on a resultset which does group_by"
1317             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1318             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1319             . ' kind of queries. Please retry the operation with a modified group_by or'
1320             . ' without using one at all.'
1321           );
1322         }
1323       }
1324       else {
1325         $attrs->{group_by} = $attrs->{columns};
1326       }
1327     }
1328
1329     my $subrs = (ref $self)->new($rsrc, $attrs);
1330
1331     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1332   }
1333   else {
1334     return $rsrc->storage->$op(
1335       $rsrc,
1336       $op eq 'update' ? $values : (),
1337       $self->_cond_for_update_delete,
1338     );
1339   }
1340 }
1341
1342
1343 # _cond_for_update_delete
1344 #
1345 # update/delete require the condition to be modified to handle
1346 # the differing SQL syntax available.  This transforms the $self->{cond}
1347 # appropriately, returning the new condition.
1348
1349 sub _cond_for_update_delete {
1350   my ($self, $full_cond) = @_;
1351   my $cond = {};
1352
1353   $full_cond ||= $self->{cond};
1354   # No-op. No condition, we're updating/deleting everything
1355   return $cond unless ref $full_cond;
1356
1357   if (ref $full_cond eq 'ARRAY') {
1358     $cond = [
1359       map {
1360         my %hash;
1361         foreach my $key (keys %{$_}) {
1362           $key =~ /([^.]+)$/;
1363           $hash{$1} = $_->{$key};
1364         }
1365         \%hash;
1366       } @{$full_cond}
1367     ];
1368   }
1369   elsif (ref $full_cond eq 'HASH') {
1370     if ((keys %{$full_cond})[0] eq '-and') {
1371       $cond->{-and} = [];
1372       my @cond = @{$full_cond->{-and}};
1373        for (my $i = 0; $i < @cond; $i++) {
1374         my $entry = $cond[$i];
1375         my $hash;
1376         if (ref $entry eq 'HASH') {
1377           $hash = $self->_cond_for_update_delete($entry);
1378         }
1379         else {
1380           $entry =~ /([^.]+)$/;
1381           $hash->{$1} = $cond[++$i];
1382         }
1383         push @{$cond->{-and}}, $hash;
1384       }
1385     }
1386     else {
1387       foreach my $key (keys %{$full_cond}) {
1388         $key =~ /([^.]+)$/;
1389         $cond->{$1} = $full_cond->{$key};
1390       }
1391     }
1392   }
1393   else {
1394     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1395   }
1396
1397   return $cond;
1398 }
1399
1400
1401 =head2 update
1402
1403 =over 4
1404
1405 =item Arguments: \%values
1406
1407 =item Return Value: $storage_rv
1408
1409 =back
1410
1411 Sets the specified columns in the resultset to the supplied values in a
1412 single query. Return value will be true if the update succeeded or false
1413 if no records were updated; exact type of success value is storage-dependent.
1414
1415 =cut
1416
1417 sub update {
1418   my ($self, $values) = @_;
1419   $self->throw_exception('Values for update must be a hash')
1420     unless ref $values eq 'HASH';
1421
1422   return $self->_rs_update_delete ('update', $values);
1423 }
1424
1425 =head2 update_all
1426
1427 =over 4
1428
1429 =item Arguments: \%values
1430
1431 =item Return Value: 1
1432
1433 =back
1434
1435 Fetches all objects and updates them one at a time. Note that C<update_all>
1436 will run DBIC cascade triggers, while L</update> will not.
1437
1438 =cut
1439
1440 sub update_all {
1441   my ($self, $values) = @_;
1442   $self->throw_exception('Values for update_all must be a hash')
1443     unless ref $values eq 'HASH';
1444   foreach my $obj ($self->all) {
1445     $obj->set_columns($values)->update;
1446   }
1447   return 1;
1448 }
1449
1450 =head2 delete
1451
1452 =over 4
1453
1454 =item Arguments: none
1455
1456 =item Return Value: $storage_rv
1457
1458 =back
1459
1460 Deletes the contents of the resultset from its result source. Note that this
1461 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1462 to run. See also L<DBIx::Class::Row/delete>.
1463
1464 Return value will be the amount of rows deleted; exact type of return value
1465 is storage-dependent.
1466
1467 =cut
1468
1469 sub delete {
1470   my $self = shift;
1471   $self->throw_exception('delete does not accept any arguments')
1472     if @_;
1473
1474   return $self->_rs_update_delete ('delete');
1475 }
1476
1477 =head2 delete_all
1478
1479 =over 4
1480
1481 =item Arguments: none
1482
1483 =item Return Value: 1
1484
1485 =back
1486
1487 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1488 will run DBIC cascade triggers, while L</delete> will not.
1489
1490 =cut
1491
1492 sub delete_all {
1493   my $self = shift;
1494   $self->throw_exception('delete_all does not accept any arguments')
1495     if @_;
1496
1497   $_->delete for $self->all;
1498   return 1;
1499 }
1500
1501 =head2 populate
1502
1503 =over 4
1504
1505 =item Arguments: \@data;
1506
1507 =back
1508
1509 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1510 For the arrayref of hashrefs style each hashref should be a structure suitable
1511 forsubmitting to a $resultset->create(...) method.
1512
1513 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1514 to insert the data, as this is a faster method.
1515
1516 Otherwise, each set of data is inserted into the database using
1517 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1518 accumulated into an array. The array itself, or an array reference
1519 is returned depending on scalar or list context.
1520
1521 Example:  Assuming an Artist Class that has many CDs Classes relating:
1522
1523   my $Artist_rs = $schema->resultset("Artist");
1524
1525   ## Void Context Example
1526   $Artist_rs->populate([
1527      { artistid => 4, name => 'Manufactured Crap', cds => [
1528         { title => 'My First CD', year => 2006 },
1529         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1530       ],
1531      },
1532      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1533         { title => 'My parents sold me to a record company' ,year => 2005 },
1534         { title => 'Why Am I So Ugly?', year => 2006 },
1535         { title => 'I Got Surgery and am now Popular', year => 2007 }
1536       ],
1537      },
1538   ]);
1539
1540   ## Array Context Example
1541   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1542     { name => "Artist One"},
1543     { name => "Artist Two"},
1544     { name => "Artist Three", cds=> [
1545     { title => "First CD", year => 2007},
1546     { title => "Second CD", year => 2008},
1547   ]}
1548   ]);
1549
1550   print $ArtistOne->name; ## response is 'Artist One'
1551   print $ArtistThree->cds->count ## reponse is '2'
1552
1553 For the arrayref of arrayrefs style,  the first element should be a list of the
1554 fieldsnames to which the remaining elements are rows being inserted.  For
1555 example:
1556
1557   $Arstist_rs->populate([
1558     [qw/artistid name/],
1559     [100, 'A Formally Unknown Singer'],
1560     [101, 'A singer that jumped the shark two albums ago'],
1561     [102, 'An actually cool singer.'],
1562   ]);
1563
1564 Please note an important effect on your data when choosing between void and
1565 wantarray context. Since void context goes straight to C<insert_bulk> in
1566 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1567 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1568 create primary keys for you, you will find that your PKs are empty.  In this
1569 case you will have to use the wantarray context in order to create those
1570 values.
1571
1572 =cut
1573
1574 sub populate {
1575   my $self = shift @_;
1576   my $data = ref $_[0][0] eq 'HASH'
1577     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1578     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1579
1580   if(defined wantarray) {
1581     my @created;
1582     foreach my $item (@$data) {
1583       push(@created, $self->create($item));
1584     }
1585     return wantarray ? @created : \@created;
1586   } else {
1587     my ($first, @rest) = @$data;
1588
1589     my @names = grep {!ref $first->{$_}} keys %$first;
1590     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1591     my @pks = $self->result_source->primary_columns;
1592
1593     ## do the belongs_to relationships
1594     foreach my $index (0..$#$data) {
1595
1596       # delegate to create() for any dataset without primary keys with specified relationships
1597       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1598         for my $r (@rels) {
1599           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1600             my @ret = $self->populate($data);
1601             return;
1602           }
1603         }
1604       }
1605
1606       foreach my $rel (@rels) {
1607         next unless ref $data->[$index]->{$rel} eq "HASH";
1608         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1609         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1610         my $related = $result->result_source->_resolve_condition(
1611           $result->result_source->relationship_info($reverse)->{cond},
1612           $self,
1613           $result,
1614         );
1615
1616         delete $data->[$index]->{$rel};
1617         $data->[$index] = {%{$data->[$index]}, %$related};
1618
1619         push @names, keys %$related if $index == 0;
1620       }
1621     }
1622
1623     ## do bulk insert on current row
1624     my @values = map { [ @$_{@names} ] } @$data;
1625
1626     $self->result_source->storage->insert_bulk(
1627       $self->result_source,
1628       \@names,
1629       \@values,
1630     );
1631
1632     ## do the has_many relationships
1633     foreach my $item (@$data) {
1634
1635       foreach my $rel (@rels) {
1636         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1637
1638         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1639      || $self->throw_exception('Cannot find the relating object.');
1640
1641         my $child = $parent->$rel;
1642
1643         my $related = $child->result_source->_resolve_condition(
1644           $parent->result_source->relationship_info($rel)->{cond},
1645           $child,
1646           $parent,
1647         );
1648
1649         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1650         my @populate = map { {%$_, %$related} } @rows_to_add;
1651
1652         $child->populate( \@populate );
1653       }
1654     }
1655   }
1656 }
1657
1658 =head2 _normalize_populate_args ($args)
1659
1660 Private method used by L</populate> to normalize its incoming arguments.  Factored
1661 out in case you want to subclass and accept new argument structures to the
1662 L</populate> method.
1663
1664 =cut
1665
1666 sub _normalize_populate_args {
1667   my ($self, $data) = @_;
1668   my @names = @{shift(@$data)};
1669   my @results_to_create;
1670   foreach my $datum (@$data) {
1671     my %result_to_create;
1672     foreach my $index (0..$#names) {
1673       $result_to_create{$names[$index]} = $$datum[$index];
1674     }
1675     push @results_to_create, \%result_to_create;
1676   }
1677   return \@results_to_create;
1678 }
1679
1680 =head2 pager
1681
1682 =over 4
1683
1684 =item Arguments: none
1685
1686 =item Return Value: $pager
1687
1688 =back
1689
1690 Return Value a L<Data::Page> object for the current resultset. Only makes
1691 sense for queries with a C<page> attribute.
1692
1693 To get the full count of entries for a paged resultset, call
1694 C<total_entries> on the L<Data::Page> object.
1695
1696 =cut
1697
1698 sub pager {
1699   my ($self) = @_;
1700
1701   return $self->{pager} if $self->{pager};
1702
1703   my $attrs = $self->{attrs};
1704   $self->throw_exception("Can't create pager for non-paged rs")
1705     unless $self->{attrs}{page};
1706   $attrs->{rows} ||= 10;
1707
1708   # throw away the paging flags and re-run the count (possibly
1709   # with a subselect) to get the real total count
1710   my $count_attrs = { %$attrs };
1711   delete $count_attrs->{$_} for qw/rows offset page pager/;
1712   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1713
1714   return $self->{pager} = Data::Page->new(
1715     $total_count,
1716     $attrs->{rows},
1717     $self->{attrs}{page}
1718   );
1719 }
1720
1721 =head2 page
1722
1723 =over 4
1724
1725 =item Arguments: $page_number
1726
1727 =item Return Value: $rs
1728
1729 =back
1730
1731 Returns a resultset for the $page_number page of the resultset on which page
1732 is called, where each page contains a number of rows equal to the 'rows'
1733 attribute set on the resultset (10 by default).
1734
1735 =cut
1736
1737 sub page {
1738   my ($self, $page) = @_;
1739   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1740 }
1741
1742 =head2 new_result
1743
1744 =over 4
1745
1746 =item Arguments: \%vals
1747
1748 =item Return Value: $rowobject
1749
1750 =back
1751
1752 Creates a new row object in the resultset's result class and returns
1753 it. The row is not inserted into the database at this point, call
1754 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1755 will tell you whether the row object has been inserted or not.
1756
1757 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1758
1759 =cut
1760
1761 sub new_result {
1762   my ($self, $values) = @_;
1763   $self->throw_exception( "new_result needs a hash" )
1764     unless (ref $values eq 'HASH');
1765
1766   my %new;
1767   my $alias = $self->{attrs}{alias};
1768
1769   if (
1770     defined $self->{cond}
1771     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1772   ) {
1773     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1774     $new{-from_resultset} = [ keys %new ] if keys %new;
1775   } else {
1776     $self->throw_exception(
1777       "Can't abstract implicit construct, condition not a hash"
1778     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1779
1780     my $collapsed_cond = (
1781       $self->{cond}
1782         ? $self->_collapse_cond($self->{cond})
1783         : {}
1784     );
1785
1786     # precendence must be given to passed values over values inherited from
1787     # the cond, so the order here is important.
1788     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1789     while( my($col,$value) = each %implied ){
1790       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1791         $new{$col} = $value->{'='};
1792         next;
1793       }
1794       $new{$col} = $value if $self->_is_deterministic_value($value);
1795     }
1796   }
1797
1798   %new = (
1799     %new,
1800     %{ $self->_remove_alias($values, $alias) },
1801     -source_handle => $self->_source_handle,
1802     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1803   );
1804
1805   return $self->result_class->new(\%new);
1806 }
1807
1808 # _is_deterministic_value
1809 #
1810 # Make an effor to strip non-deterministic values from the condition,
1811 # to make sure new_result chokes less
1812
1813 sub _is_deterministic_value {
1814   my $self = shift;
1815   my $value = shift;
1816   my $ref_type = ref $value;
1817   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1818   return 1 if Scalar::Util::blessed($value);
1819   return 0;
1820 }
1821
1822 # _has_resolved_attr
1823 #
1824 # determines if the resultset defines at least one
1825 # of the attributes supplied
1826 #
1827 # used to determine if a subquery is neccessary
1828
1829 sub _has_resolved_attr {
1830   my ($self, @attr_names) = @_;
1831
1832   my $attrs = $self->_resolved_attrs;
1833
1834   my $join_check_req;
1835
1836   for my $n (@attr_names) {
1837     ++$join_check_req if $n eq '-join';
1838
1839     my $attr =  $attrs->{$n};
1840
1841     next if not defined $attr;
1842
1843     if (ref $attr eq 'HASH') {
1844       return 1 if keys %$attr;
1845     }
1846     elsif (ref $attr eq 'ARRAY') {
1847       return 1 if @$attr;
1848     }
1849     else {
1850       return 1 if $attr;
1851     }
1852   }
1853
1854   # a resolved join is expressed as a multi-level from
1855   return 1 if (
1856     $join_check_req
1857       and
1858     ref $attrs->{from} eq 'ARRAY'
1859       and
1860     @{$attrs->{from}} > 1
1861   );
1862
1863   return 0;
1864 }
1865
1866 # _collapse_cond
1867 #
1868 # Recursively collapse the condition.
1869
1870 sub _collapse_cond {
1871   my ($self, $cond, $collapsed) = @_;
1872
1873   $collapsed ||= {};
1874
1875   if (ref $cond eq 'ARRAY') {
1876     foreach my $subcond (@$cond) {
1877       next unless ref $subcond;  # -or
1878       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1879     }
1880   }
1881   elsif (ref $cond eq 'HASH') {
1882     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1883       foreach my $subcond (@{$cond->{-and}}) {
1884         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1885       }
1886     }
1887     else {
1888       foreach my $col (keys %$cond) {
1889         my $value = $cond->{$col};
1890         $collapsed->{$col} = $value;
1891       }
1892     }
1893   }
1894
1895   return $collapsed;
1896 }
1897
1898 # _remove_alias
1899 #
1900 # Remove the specified alias from the specified query hash. A copy is made so
1901 # the original query is not modified.
1902
1903 sub _remove_alias {
1904   my ($self, $query, $alias) = @_;
1905
1906   my %orig = %{ $query || {} };
1907   my %unaliased;
1908
1909   foreach my $key (keys %orig) {
1910     if ($key !~ /\./) {
1911       $unaliased{$key} = $orig{$key};
1912       next;
1913     }
1914     $unaliased{$1} = $orig{$key}
1915       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1916   }
1917
1918   return \%unaliased;
1919 }
1920
1921 =head2 as_query (EXPERIMENTAL)
1922
1923 =over 4
1924
1925 =item Arguments: none
1926
1927 =item Return Value: \[ $sql, @bind ]
1928
1929 =back
1930
1931 Returns the SQL query and bind vars associated with the invocant.
1932
1933 This is generally used as the RHS for a subquery.
1934
1935 B<NOTE>: This feature is still experimental.
1936
1937 =cut
1938
1939 sub as_query {
1940   my $self = shift;
1941
1942   my $attrs = $self->_resolved_attrs_copy;
1943
1944   # For future use:
1945   #
1946   # in list ctx:
1947   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
1948   # $sql also has no wrapping parenthesis in list ctx
1949   #
1950   my $sqlbind = $self->result_source->storage
1951     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
1952
1953   return $sqlbind;
1954 }
1955
1956 =head2 find_or_new
1957
1958 =over 4
1959
1960 =item Arguments: \%vals, \%attrs?
1961
1962 =item Return Value: $rowobject
1963
1964 =back
1965
1966   my $artist = $schema->resultset('Artist')->find_or_new(
1967     { artist => 'fred' }, { key => 'artists' });
1968
1969   $cd->cd_to_producer->find_or_new({ producer => $producer },
1970                                    { key => 'primary });
1971
1972 Find an existing record from this resultset, based on its primary
1973 key, or a unique constraint. If none exists, instantiate a new result
1974 object and return it. The object will not be saved into your storage
1975 until you call L<DBIx::Class::Row/insert> on it.
1976
1977 You most likely want this method when looking for existing rows using
1978 a unique constraint that is not the primary key, or looking for
1979 related rows.
1980
1981 If you want objects to be saved immediately, use L</find_or_create> instead.
1982
1983 B<Note>: C<find_or_new> is probably not what you want when creating a
1984 new row in a table that uses primary keys supplied by the
1985 database. Passing in a primary key column with a value of I<undef>
1986 will cause L</find> to attempt to search for a row with a value of
1987 I<NULL>.
1988
1989 =cut
1990
1991 sub find_or_new {
1992   my $self     = shift;
1993   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1994   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1995   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
1996     return $row;
1997   }
1998   return $self->new_result($hash);
1999 }
2000
2001 =head2 create
2002
2003 =over 4
2004
2005 =item Arguments: \%vals
2006
2007 =item Return Value: a L<DBIx::Class::Row> $object
2008
2009 =back
2010
2011 Attempt to create a single new row or a row with multiple related rows
2012 in the table represented by the resultset (and related tables). This
2013 will not check for duplicate rows before inserting, use
2014 L</find_or_create> to do that.
2015
2016 To create one row for this resultset, pass a hashref of key/value
2017 pairs representing the columns of the table and the values you wish to
2018 store. If the appropriate relationships are set up, foreign key fields
2019 can also be passed an object representing the foreign row, and the
2020 value will be set to its primary key.
2021
2022 To create related objects, pass a hashref for the value if the related
2023 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2024 and use the name of the relationship as the key. (NOT the name of the field,
2025 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2026 of hashrefs containing the data for each of the rows to create in the foreign
2027 tables, again using the relationship name as the key.
2028
2029 Instead of hashrefs of plain related data (key/value pairs), you may
2030 also pass new or inserted objects. New objects (not inserted yet, see
2031 L</new>), will be inserted into their appropriate tables.
2032
2033 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2034
2035 Example of creating a new row.
2036
2037   $person_rs->create({
2038     name=>"Some Person",
2039     email=>"somebody@someplace.com"
2040   });
2041
2042 Example of creating a new row and also creating rows in a related C<has_many>
2043 or C<has_one> resultset.  Note Arrayref.
2044
2045   $artist_rs->create(
2046      { artistid => 4, name => 'Manufactured Crap', cds => [
2047         { title => 'My First CD', year => 2006 },
2048         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2049       ],
2050      },
2051   );
2052
2053 Example of creating a new row and also creating a row in a related
2054 C<belongs_to>resultset. Note Hashref.
2055
2056   $cd_rs->create({
2057     title=>"Music for Silly Walks",
2058     year=>2000,
2059     artist => {
2060       name=>"Silly Musician",
2061     }
2062   });
2063
2064 =cut
2065
2066 sub create {
2067   my ($self, $attrs) = @_;
2068   $self->throw_exception( "create needs a hashref" )
2069     unless ref $attrs eq 'HASH';
2070   return $self->new_result($attrs)->insert;
2071 }
2072
2073 =head2 find_or_create
2074
2075 =over 4
2076
2077 =item Arguments: \%vals, \%attrs?
2078
2079 =item Return Value: $rowobject
2080
2081 =back
2082
2083   $cd->cd_to_producer->find_or_create({ producer => $producer },
2084                                       { key => 'primary });
2085
2086 Tries to find a record based on its primary key or unique constraints; if none
2087 is found, creates one and returns that instead.
2088
2089   my $cd = $schema->resultset('CD')->find_or_create({
2090     cdid   => 5,
2091     artist => 'Massive Attack',
2092     title  => 'Mezzanine',
2093     year   => 2005,
2094   });
2095
2096 Also takes an optional C<key> attribute, to search by a specific key or unique
2097 constraint. For example:
2098
2099   my $cd = $schema->resultset('CD')->find_or_create(
2100     {
2101       artist => 'Massive Attack',
2102       title  => 'Mezzanine',
2103     },
2104     { key => 'cd_artist_title' }
2105   );
2106
2107 B<Note>: Because find_or_create() reads from the database and then
2108 possibly inserts based on the result, this method is subject to a race
2109 condition. Another process could create a record in the table after
2110 the find has completed and before the create has started. To avoid
2111 this problem, use find_or_create() inside a transaction.
2112
2113 B<Note>: C<find_or_create> is probably not what you want when creating
2114 a new row in a table that uses primary keys supplied by the
2115 database. Passing in a primary key column with a value of I<undef>
2116 will cause L</find> to attempt to search for a row with a value of
2117 I<NULL>.
2118
2119 See also L</find> and L</update_or_create>. For information on how to declare
2120 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2121
2122 =cut
2123
2124 sub find_or_create {
2125   my $self     = shift;
2126   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2127   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2128   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2129     return $row;
2130   }
2131   return $self->create($hash);
2132 }
2133
2134 =head2 update_or_create
2135
2136 =over 4
2137
2138 =item Arguments: \%col_values, { key => $unique_constraint }?
2139
2140 =item Return Value: $rowobject
2141
2142 =back
2143
2144   $resultset->update_or_create({ col => $val, ... });
2145
2146 First, searches for an existing row matching one of the unique constraints
2147 (including the primary key) on the source of this resultset. If a row is
2148 found, updates it with the other given column values. Otherwise, creates a new
2149 row.
2150
2151 Takes an optional C<key> attribute to search on a specific unique constraint.
2152 For example:
2153
2154   # In your application
2155   my $cd = $schema->resultset('CD')->update_or_create(
2156     {
2157       artist => 'Massive Attack',
2158       title  => 'Mezzanine',
2159       year   => 1998,
2160     },
2161     { key => 'cd_artist_title' }
2162   );
2163
2164   $cd->cd_to_producer->update_or_create({
2165     producer => $producer,
2166     name => 'harry',
2167   }, {
2168     key => 'primary,
2169   });
2170
2171
2172 If no C<key> is specified, it searches on all unique constraints defined on the
2173 source, including the primary key.
2174
2175 If the C<key> is specified as C<primary>, it searches only on the primary key.
2176
2177 See also L</find> and L</find_or_create>. For information on how to declare
2178 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2179
2180 B<Note>: C<update_or_create> is probably not what you want when
2181 looking for a row in a table that uses primary keys supplied by the
2182 database, unless you actually have a key value. Passing in a primary
2183 key column with a value of I<undef> will cause L</find> to attempt to
2184 search for a row with a value of I<NULL>.
2185
2186 =cut
2187
2188 sub update_or_create {
2189   my $self = shift;
2190   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2191   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2192
2193   my $row = $self->find($cond, $attrs);
2194   if (defined $row) {
2195     $row->update($cond);
2196     return $row;
2197   }
2198
2199   return $self->create($cond);
2200 }
2201
2202 =head2 update_or_new
2203
2204 =over 4
2205
2206 =item Arguments: \%col_values, { key => $unique_constraint }?
2207
2208 =item Return Value: $rowobject
2209
2210 =back
2211
2212   $resultset->update_or_new({ col => $val, ... });
2213
2214 First, searches for an existing row matching one of the unique constraints
2215 (including the primary key) on the source of this resultset. If a row is
2216 found, updates it with the other given column values. Otherwise, instantiate
2217 a new result object and return it. The object will not be saved into your storage
2218 until you call L<DBIx::Class::Row/insert> on it.
2219
2220 Takes an optional C<key> attribute to search on a specific unique constraint.
2221 For example:
2222
2223   # In your application
2224   my $cd = $schema->resultset('CD')->update_or_new(
2225     {
2226       artist => 'Massive Attack',
2227       title  => 'Mezzanine',
2228       year   => 1998,
2229     },
2230     { key => 'cd_artist_title' }
2231   );
2232
2233   if ($cd->in_storage) {
2234       # the cd was updated
2235   }
2236   else {
2237       # the cd is not yet in the database, let's insert it
2238       $cd->insert;
2239   }
2240
2241 See also L</find>, L</find_or_create> and L<find_or_new>.
2242
2243 =cut
2244
2245 sub update_or_new {
2246     my $self  = shift;
2247     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2248     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2249
2250     my $row = $self->find( $cond, $attrs );
2251     if ( defined $row ) {
2252         $row->update($cond);
2253         return $row;
2254     }
2255
2256     return $self->new_result($cond);
2257 }
2258
2259 =head2 get_cache
2260
2261 =over 4
2262
2263 =item Arguments: none
2264
2265 =item Return Value: \@cache_objects?
2266
2267 =back
2268
2269 Gets the contents of the cache for the resultset, if the cache is set.
2270
2271 The cache is populated either by using the L</prefetch> attribute to
2272 L</search> or by calling L</set_cache>.
2273
2274 =cut
2275
2276 sub get_cache {
2277   shift->{all_cache};
2278 }
2279
2280 =head2 set_cache
2281
2282 =over 4
2283
2284 =item Arguments: \@cache_objects
2285
2286 =item Return Value: \@cache_objects
2287
2288 =back
2289
2290 Sets the contents of the cache for the resultset. Expects an arrayref
2291 of objects of the same class as those produced by the resultset. Note that
2292 if the cache is set the resultset will return the cached objects rather
2293 than re-querying the database even if the cache attr is not set.
2294
2295 The contents of the cache can also be populated by using the
2296 L</prefetch> attribute to L</search>.
2297
2298 =cut
2299
2300 sub set_cache {
2301   my ( $self, $data ) = @_;
2302   $self->throw_exception("set_cache requires an arrayref")
2303       if defined($data) && (ref $data ne 'ARRAY');
2304   $self->{all_cache} = $data;
2305 }
2306
2307 =head2 clear_cache
2308
2309 =over 4
2310
2311 =item Arguments: none
2312
2313 =item Return Value: []
2314
2315 =back
2316
2317 Clears the cache for the resultset.
2318
2319 =cut
2320
2321 sub clear_cache {
2322   shift->set_cache(undef);
2323 }
2324
2325 =head2 related_resultset
2326
2327 =over 4
2328
2329 =item Arguments: $relationship_name
2330
2331 =item Return Value: $resultset
2332
2333 =back
2334
2335 Returns a related resultset for the supplied relationship name.
2336
2337   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2338
2339 =cut
2340
2341 sub related_resultset {
2342   my ($self, $rel) = @_;
2343
2344   $self->{related_resultsets} ||= {};
2345   return $self->{related_resultsets}{$rel} ||= do {
2346     my $rel_obj = $self->result_source->relationship_info($rel);
2347
2348     $self->throw_exception(
2349       "search_related: result source '" . $self->result_source->source_name .
2350         "' has no such relationship $rel")
2351       unless $rel_obj;
2352
2353     my ($from,$seen) = $self->_resolve_from($rel);
2354
2355     my $join_count = $seen->{$rel};
2356     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2357
2358     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2359     my %attrs = %{$self->{attrs}||{}};
2360     delete @attrs{qw(result_class alias)};
2361
2362     my $new_cache;
2363
2364     if (my $cache = $self->get_cache) {
2365       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2366         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2367                         @$cache ];
2368       }
2369     }
2370
2371     my $rel_source = $self->result_source->related_source($rel);
2372
2373     my $new = do {
2374
2375       # The reason we do this now instead of passing the alias to the
2376       # search_rs below is that if you wrap/overload resultset on the
2377       # source you need to know what alias it's -going- to have for things
2378       # to work sanely (e.g. RestrictWithObject wants to be able to add
2379       # extra query restrictions, and these may need to be $alias.)
2380
2381       my $attrs = $rel_source->resultset_attributes;
2382       local $attrs->{alias} = $alias;
2383
2384       $rel_source->resultset
2385                  ->search_rs(
2386                      undef, {
2387                        %attrs,
2388                        join => undef,
2389                        prefetch => undef,
2390                        select => undef,
2391                        as => undef,
2392                        where => $self->{cond},
2393                        seen_join => $seen,
2394                        from => $from,
2395                    });
2396     };
2397     $new->set_cache($new_cache) if $new_cache;
2398     $new;
2399   };
2400 }
2401
2402 =head2 current_source_alias
2403
2404 =over 4
2405
2406 =item Arguments: none
2407
2408 =item Return Value: $source_alias
2409
2410 =back
2411
2412 Returns the current table alias for the result source this resultset is built
2413 on, that will be used in the SQL query. Usually it is C<me>.
2414
2415 Currently the source alias that refers to the result set returned by a
2416 L</search>/L</find> family method depends on how you got to the resultset: it's
2417 C<me> by default, but eg. L</search_related> aliases it to the related result
2418 source name (and keeps C<me> referring to the original result set). The long
2419 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2420 (and make this method unnecessary).
2421
2422 Thus it's currently necessary to use this method in predefined queries (see
2423 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2424 source alias of the current result set:
2425
2426   # in a result set class
2427   sub modified_by {
2428     my ($self, $user) = @_;
2429
2430     my $me = $self->current_source_alias;
2431
2432     return $self->search(
2433       "$me.modified" => $user->id,
2434     );
2435   }
2436
2437 =cut
2438
2439 sub current_source_alias {
2440   my ($self) = @_;
2441
2442   return ($self->{attrs} || {})->{alias} || 'me';
2443 }
2444
2445 # This code is called by search_related, and makes sure there
2446 # is clear separation between the joins before, during, and
2447 # after the relationship. This information is needed later
2448 # in order to properly resolve prefetch aliases (any alias
2449 # with a relation_chain_depth less than the depth of the
2450 # current prefetch is not considered)
2451 sub _resolve_from {
2452   my ($self, $extra_join) = @_;
2453   my $source = $self->result_source;
2454   my $attrs = $self->{attrs};
2455
2456   my $from = [ @{
2457       $attrs->{from}
2458         ||
2459       [{
2460         -source_handle => $source->handle,
2461         -alias => $attrs->{alias},
2462         $attrs->{alias} => $source->from,
2463       }]
2464   }];
2465
2466   my $seen = { %{$attrs->{seen_join} || {} } };
2467
2468   # we need to take the prefetch the attrs into account before we
2469   # ->_resolve_join as otherwise they get lost - captainL
2470   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2471
2472   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2473
2474   ++$seen->{-relation_chain_depth};
2475
2476   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2477
2478   ++$seen->{-relation_chain_depth};
2479
2480   return ($from,$seen);
2481 }
2482
2483 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2484 sub _resolved_attrs_copy {
2485   my $self = shift;
2486   return { %{$self->_resolved_attrs (@_)} };
2487 }
2488
2489 sub _resolved_attrs {
2490   my $self = shift;
2491   return $self->{_attrs} if $self->{_attrs};
2492
2493   my $attrs  = { %{ $self->{attrs} || {} } };
2494   my $source = $self->result_source;
2495   my $alias  = $attrs->{alias};
2496
2497   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2498   my @colbits;
2499
2500   # build columns (as long as select isn't set) into a set of as/select hashes
2501   unless ( $attrs->{select} ) {
2502       @colbits = map {
2503           ( ref($_) eq 'HASH' )
2504               ? $_
2505               : {
2506                   (
2507                     /^\Q${alias}.\E(.+)$/
2508                       ? "$1"
2509                       : "$_"
2510                   )
2511                 =>
2512                   (
2513                     /\./
2514                       ? "$_"
2515                       : "${alias}.$_"
2516                   )
2517             }
2518       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2519   }
2520   # add the additional columns on
2521   foreach ( 'include_columns', '+columns' ) {
2522       push @colbits, map {
2523           ( ref($_) eq 'HASH' )
2524             ? $_
2525             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2526       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2527   }
2528
2529   # start with initial select items
2530   if ( $attrs->{select} ) {
2531     $attrs->{select} =
2532         ( ref $attrs->{select} eq 'ARRAY' )
2533       ? [ @{ $attrs->{select} } ]
2534       : [ $attrs->{select} ];
2535     $attrs->{as} = (
2536       $attrs->{as}
2537       ? (
2538         ref $attrs->{as} eq 'ARRAY'
2539         ? [ @{ $attrs->{as} } ]
2540         : [ $attrs->{as} ]
2541         )
2542       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2543     );
2544   }
2545   else {
2546
2547     # otherwise we intialise select & as to empty
2548     $attrs->{select} = [];
2549     $attrs->{as}     = [];
2550   }
2551
2552   # now add colbits to select/as
2553   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2554   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2555
2556   my $adds;
2557   if ( $adds = delete $attrs->{'+select'} ) {
2558     $adds = [$adds] unless ref $adds eq 'ARRAY';
2559     push(
2560       @{ $attrs->{select} },
2561       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2562     );
2563   }
2564   if ( $adds = delete $attrs->{'+as'} ) {
2565     $adds = [$adds] unless ref $adds eq 'ARRAY';
2566     push( @{ $attrs->{as} }, @$adds );
2567   }
2568
2569   $attrs->{from} ||= [ {
2570     -source_handle => $source->handle,
2571     -alias => $self->{attrs}{alias},
2572     $self->{attrs}{alias} => $source->from,
2573   } ];
2574
2575   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2576     my $join = delete $attrs->{join} || {};
2577
2578     if ( defined $attrs->{prefetch} ) {
2579       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2580
2581     }
2582
2583     $attrs->{from} =    # have to copy here to avoid corrupting the original
2584       [
2585       @{ $attrs->{from} },
2586       $source->_resolve_join(
2587         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2588       )
2589       ];
2590
2591   }
2592
2593   if ( $attrs->{order_by} ) {
2594     $attrs->{order_by} = (
2595       ref( $attrs->{order_by} ) eq 'ARRAY'
2596       ? [ @{ $attrs->{order_by} } ]
2597       : [ $attrs->{order_by} ]
2598     );
2599   }
2600   else {
2601     $attrs->{order_by} = [];
2602   }
2603
2604   # If the order_by is otherwise empty - we will use this for TOP limit
2605   # emulation and the like.
2606   # Although this is needed only if the order_by is not defined, it is
2607   # actually cheaper to just populate this rather than properly examining
2608   # order_by (stuf like [ {} ] and the like)
2609   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2610
2611
2612   $attrs->{collapse} ||= {};
2613   if ( my $prefetch = delete $attrs->{prefetch} ) {
2614     $prefetch = $self->_merge_attr( {}, $prefetch );
2615
2616     my $prefetch_ordering = [];
2617
2618     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2619
2620     my @prefetch =
2621       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2622
2623     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2624     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2625
2626     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2627     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2628   }
2629
2630
2631   if (delete $attrs->{distinct}) {
2632     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2633   }
2634
2635   # if both page and offset are specified, produce a combined offset
2636   # even though it doesn't make much sense, this is what pre 081xx has
2637   # been doing
2638   if (my $page = delete $attrs->{page}) {
2639     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2640       ($attrs->{offset} || 0);
2641   }
2642
2643   return $self->{_attrs} = $attrs;
2644 }
2645
2646 sub _joinpath_aliases {
2647   my ($self, $fromspec, $seen) = @_;
2648
2649   my $paths = {};
2650   return $paths unless ref $fromspec eq 'ARRAY';
2651
2652   for my $j (@$fromspec) {
2653
2654     next if ref $j ne 'ARRAY';
2655     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2656
2657     my $p = $paths;
2658     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2659     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2660   }
2661
2662   return $paths;
2663 }
2664
2665 sub _rollout_attr {
2666   my ($self, $attr) = @_;
2667
2668   if (ref $attr eq 'HASH') {
2669     return $self->_rollout_hash($attr);
2670   } elsif (ref $attr eq 'ARRAY') {
2671     return $self->_rollout_array($attr);
2672   } else {
2673     return [$attr];
2674   }
2675 }
2676
2677 sub _rollout_array {
2678   my ($self, $attr) = @_;
2679
2680   my @rolled_array;
2681   foreach my $element (@{$attr}) {
2682     if (ref $element eq 'HASH') {
2683       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2684     } elsif (ref $element eq 'ARRAY') {
2685       #  XXX - should probably recurse here
2686       push( @rolled_array, @{$self->_rollout_array($element)} );
2687     } else {
2688       push( @rolled_array, $element );
2689     }
2690   }
2691   return \@rolled_array;
2692 }
2693
2694 sub _rollout_hash {
2695   my ($self, $attr) = @_;
2696
2697   my @rolled_array;
2698   foreach my $key (keys %{$attr}) {
2699     push( @rolled_array, { $key => $attr->{$key} } );
2700   }
2701   return \@rolled_array;
2702 }
2703
2704 sub _calculate_score {
2705   my ($self, $a, $b) = @_;
2706
2707   if (ref $b eq 'HASH') {
2708     my ($b_key) = keys %{$b};
2709     if (ref $a eq 'HASH') {
2710       my ($a_key) = keys %{$a};
2711       if ($a_key eq $b_key) {
2712         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2713       } else {
2714         return 0;
2715       }
2716     } else {
2717       return ($a eq $b_key) ? 1 : 0;
2718     }
2719   } else {
2720     if (ref $a eq 'HASH') {
2721       my ($a_key) = keys %{$a};
2722       return ($b eq $a_key) ? 1 : 0;
2723     } else {
2724       return ($b eq $a) ? 1 : 0;
2725     }
2726   }
2727 }
2728
2729 sub _merge_attr {
2730   my ($self, $orig, $import) = @_;
2731
2732   return $import unless defined($orig);
2733   return $orig unless defined($import);
2734
2735   $orig = $self->_rollout_attr($orig);
2736   $import = $self->_rollout_attr($import);
2737
2738   my $seen_keys;
2739   foreach my $import_element ( @{$import} ) {
2740     # find best candidate from $orig to merge $b_element into
2741     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2742     foreach my $orig_element ( @{$orig} ) {
2743       my $score = $self->_calculate_score( $orig_element, $import_element );
2744       if ($score > $best_candidate->{score}) {
2745         $best_candidate->{position} = $position;
2746         $best_candidate->{score} = $score;
2747       }
2748       $position++;
2749     }
2750     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2751
2752     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2753       push( @{$orig}, $import_element );
2754     } else {
2755       my $orig_best = $orig->[$best_candidate->{position}];
2756       # merge orig_best and b_element together and replace original with merged
2757       if (ref $orig_best ne 'HASH') {
2758         $orig->[$best_candidate->{position}] = $import_element;
2759       } elsif (ref $import_element eq 'HASH') {
2760         my ($key) = keys %{$orig_best};
2761         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2762       }
2763     }
2764     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2765   }
2766
2767   return $orig;
2768 }
2769
2770 sub result_source {
2771     my $self = shift;
2772
2773     if (@_) {
2774         $self->_source_handle($_[0]->handle);
2775     } else {
2776         $self->_source_handle->resolve;
2777     }
2778 }
2779
2780 =head2 throw_exception
2781
2782 See L<DBIx::Class::Schema/throw_exception> for details.
2783
2784 =cut
2785
2786 sub throw_exception {
2787   my $self=shift;
2788   if (ref $self && $self->_source_handle->schema) {
2789     $self->_source_handle->schema->throw_exception(@_)
2790   } else {
2791     croak(@_);
2792   }
2793
2794 }
2795
2796 # XXX: FIXME: Attributes docs need clearing up
2797
2798 =head1 ATTRIBUTES
2799
2800 Attributes are used to refine a ResultSet in various ways when
2801 searching for data. They can be passed to any method which takes an
2802 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2803 L</count>.
2804
2805 These are in no particular order:
2806
2807 =head2 order_by
2808
2809 =over 4
2810
2811 =item Value: ( $order_by | \@order_by | \%order_by )
2812
2813 =back
2814
2815 Which column(s) to order the results by. If a single column name, or
2816 an arrayref of names is supplied, the argument is passed through
2817 directly to SQL. The hashref syntax allows for connection-agnostic
2818 specification of ordering direction:
2819
2820  For descending order:
2821
2822   order_by => { -desc => [qw/col1 col2 col3/] }
2823
2824  For explicit ascending order:
2825
2826   order_by => { -asc => 'col' }
2827
2828 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2829 supported, although you are strongly encouraged to use the hashref
2830 syntax as outlined above.
2831
2832 =head2 columns
2833
2834 =over 4
2835
2836 =item Value: \@columns
2837
2838 =back
2839
2840 Shortcut to request a particular set of columns to be retrieved. Each
2841 column spec may be a string (a table column name), or a hash (in which
2842 case the key is the C<as> value, and the value is used as the C<select>
2843 expression). Adds C<me.> onto the start of any column without a C<.> in
2844 it and sets C<select> from that, then auto-populates C<as> from
2845 C<select> as normal. (You may also use the C<cols> attribute, as in
2846 earlier versions of DBIC.)
2847
2848 =head2 +columns
2849
2850 =over 4
2851
2852 =item Value: \@columns
2853
2854 =back
2855
2856 Indicates additional columns to be selected from storage. Works the same
2857 as L</columns> but adds columns to the selection. (You may also use the
2858 C<include_columns> attribute, as in earlier versions of DBIC). For
2859 example:-
2860
2861   $schema->resultset('CD')->search(undef, {
2862     '+columns' => ['artist.name'],
2863     join => ['artist']
2864   });
2865
2866 would return all CDs and include a 'name' column to the information
2867 passed to object inflation. Note that the 'artist' is the name of the
2868 column (or relationship) accessor, and 'name' is the name of the column
2869 accessor in the related table.
2870
2871 =head2 include_columns
2872
2873 =over 4
2874
2875 =item Value: \@columns
2876
2877 =back
2878
2879 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2880
2881 =head2 select
2882
2883 =over 4
2884
2885 =item Value: \@select_columns
2886
2887 =back
2888
2889 Indicates which columns should be selected from the storage. You can use
2890 column names, or in the case of RDBMS back ends, function or stored procedure
2891 names:
2892
2893   $rs = $schema->resultset('Employee')->search(undef, {
2894     select => [
2895       'name',
2896       { count => 'employeeid' },
2897       { sum => 'salary' }
2898     ]
2899   });
2900
2901 When you use function/stored procedure names and do not supply an C<as>
2902 attribute, the column names returned are storage-dependent. E.g. MySQL would
2903 return a column named C<count(employeeid)> in the above example.
2904
2905 =head2 +select
2906
2907 =over 4
2908
2909 Indicates additional columns to be selected from storage.  Works the same as
2910 L</select> but adds columns to the selection.
2911
2912 =back
2913
2914 =head2 +as
2915
2916 =over 4
2917
2918 Indicates additional column names for those added via L</+select>. See L</as>.
2919
2920 =back
2921
2922 =head2 as
2923
2924 =over 4
2925
2926 =item Value: \@inflation_names
2927
2928 =back
2929
2930 Indicates column names for object inflation. That is, C<as>
2931 indicates the name that the column can be accessed as via the
2932 C<get_column> method (or via the object accessor, B<if one already
2933 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2934
2935 The C<as> attribute is used in conjunction with C<select>,
2936 usually when C<select> contains one or more function or stored
2937 procedure names:
2938
2939   $rs = $schema->resultset('Employee')->search(undef, {
2940     select => [
2941       'name',
2942       { count => 'employeeid' }
2943     ],
2944     as => ['name', 'employee_count'],
2945   });
2946
2947   my $employee = $rs->first(); # get the first Employee
2948
2949 If the object against which the search is performed already has an accessor
2950 matching a column name specified in C<as>, the value can be retrieved using
2951 the accessor as normal:
2952
2953   my $name = $employee->name();
2954
2955 If on the other hand an accessor does not exist in the object, you need to
2956 use C<get_column> instead:
2957
2958   my $employee_count = $employee->get_column('employee_count');
2959
2960 You can create your own accessors if required - see
2961 L<DBIx::Class::Manual::Cookbook> for details.
2962
2963 Please note: This will NOT insert an C<AS employee_count> into the SQL
2964 statement produced, it is used for internal access only. Thus
2965 attempting to use the accessor in an C<order_by> clause or similar
2966 will fail miserably.
2967
2968 To get around this limitation, you can supply literal SQL to your
2969 C<select> attibute that contains the C<AS alias> text, eg:
2970
2971   select => [\'myfield AS alias']
2972
2973 =head2 join
2974
2975 =over 4
2976
2977 =item Value: ($rel_name | \@rel_names | \%rel_names)
2978
2979 =back
2980
2981 Contains a list of relationships that should be joined for this query.  For
2982 example:
2983
2984   # Get CDs by Nine Inch Nails
2985   my $rs = $schema->resultset('CD')->search(
2986     { 'artist.name' => 'Nine Inch Nails' },
2987     { join => 'artist' }
2988   );
2989
2990 Can also contain a hash reference to refer to the other relation's relations.
2991 For example:
2992
2993   package MyApp::Schema::Track;
2994   use base qw/DBIx::Class/;
2995   __PACKAGE__->table('track');
2996   __PACKAGE__->add_columns(qw/trackid cd position title/);
2997   __PACKAGE__->set_primary_key('trackid');
2998   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2999   1;
3000
3001   # In your application
3002   my $rs = $schema->resultset('Artist')->search(
3003     { 'track.title' => 'Teardrop' },
3004     {
3005       join     => { cd => 'track' },
3006       order_by => 'artist.name',
3007     }
3008   );
3009
3010 You need to use the relationship (not the table) name in  conditions,
3011 because they are aliased as such. The current table is aliased as "me", so
3012 you need to use me.column_name in order to avoid ambiguity. For example:
3013
3014   # Get CDs from 1984 with a 'Foo' track
3015   my $rs = $schema->resultset('CD')->search(
3016     {
3017       'me.year' => 1984,
3018       'tracks.name' => 'Foo'
3019     },
3020     { join => 'tracks' }
3021   );
3022
3023 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3024 similarly for a third time). For e.g.
3025
3026   my $rs = $schema->resultset('Artist')->search({
3027     'cds.title'   => 'Down to Earth',
3028     'cds_2.title' => 'Popular',
3029   }, {
3030     join => [ qw/cds cds/ ],
3031   });
3032
3033 will return a set of all artists that have both a cd with title 'Down
3034 to Earth' and a cd with title 'Popular'.
3035
3036 If you want to fetch related objects from other tables as well, see C<prefetch>
3037 below.
3038
3039 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3040
3041 =head2 prefetch
3042
3043 =over 4
3044
3045 =item Value: ($rel_name | \@rel_names | \%rel_names)
3046
3047 =back
3048
3049 Contains one or more relationships that should be fetched along with
3050 the main query (when they are accessed afterwards the data will
3051 already be available, without extra queries to the database).  This is
3052 useful for when you know you will need the related objects, because it
3053 saves at least one query:
3054
3055   my $rs = $schema->resultset('Tag')->search(
3056     undef,
3057     {
3058       prefetch => {
3059         cd => 'artist'
3060       }
3061     }
3062   );
3063
3064 The initial search results in SQL like the following:
3065
3066   SELECT tag.*, cd.*, artist.* FROM tag
3067   JOIN cd ON tag.cd = cd.cdid
3068   JOIN artist ON cd.artist = artist.artistid
3069
3070 L<DBIx::Class> has no need to go back to the database when we access the
3071 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3072 case.
3073
3074 Simple prefetches will be joined automatically, so there is no need
3075 for a C<join> attribute in the above search.
3076
3077 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3078 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3079 with an accessor type of 'single' or 'filter'). A more complex example that
3080 prefetches an artists cds, the tracks on those cds, and the tags associted
3081 with that artist is given below (assuming many-to-many from artists to tags):
3082
3083  my $rs = $schema->resultset('Artist')->search(
3084    undef,
3085    {
3086      prefetch => [
3087        { cds => 'tracks' },
3088        { artist_tags => 'tags' }
3089      ]
3090    }
3091  );
3092
3093
3094 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3095 attributes will be ignored.
3096
3097 =head2 page
3098
3099 =over 4
3100
3101 =item Value: $page
3102
3103 =back
3104
3105 Makes the resultset paged and specifies the page to retrieve. Effectively
3106 identical to creating a non-pages resultset and then calling ->page($page)
3107 on it.
3108
3109 If L<rows> attribute is not specified it defualts to 10 rows per page.
3110
3111 When you have a paged resultset, L</count> will only return the number
3112 of rows in the page. To get the total, use the L</pager> and call
3113 C<total_entries> on it.
3114
3115 =head2 rows
3116
3117 =over 4
3118
3119 =item Value: $rows
3120
3121 =back
3122
3123 Specifes the maximum number of rows for direct retrieval or the number of
3124 rows per page if the page attribute or method is used.
3125
3126 =head2 offset
3127
3128 =over 4
3129
3130 =item Value: $offset
3131
3132 =back
3133
3134 Specifies the (zero-based) row number for the  first row to be returned, or the
3135 of the first row of the first page if paging is used.
3136
3137 =head2 group_by
3138
3139 =over 4
3140
3141 =item Value: \@columns
3142
3143 =back
3144
3145 A arrayref of columns to group by. Can include columns of joined tables.
3146
3147   group_by => [qw/ column1 column2 ... /]
3148
3149 =head2 having
3150
3151 =over 4
3152
3153 =item Value: $condition
3154
3155 =back
3156
3157 HAVING is a select statement attribute that is applied between GROUP BY and
3158 ORDER BY. It is applied to the after the grouping calculations have been
3159 done.
3160
3161   having => { 'count(employee)' => { '>=', 100 } }
3162
3163 =head2 distinct
3164
3165 =over 4
3166
3167 =item Value: (0 | 1)
3168
3169 =back
3170
3171 Set to 1 to group by all columns.
3172
3173 =head2 where
3174
3175 =over 4
3176
3177 Adds to the WHERE clause.
3178
3179   # only return rows WHERE deleted IS NULL for all searches
3180   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3181
3182 Can be overridden by passing C<{ where => undef }> as an attribute
3183 to a resulset.
3184
3185 =back
3186
3187 =head2 cache
3188
3189 Set to 1 to cache search results. This prevents extra SQL queries if you
3190 revisit rows in your ResultSet:
3191
3192   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3193
3194   while( my $artist = $resultset->next ) {
3195     ... do stuff ...
3196   }
3197
3198   $rs->first; # without cache, this would issue a query
3199
3200 By default, searches are not cached.
3201
3202 For more examples of using these attributes, see
3203 L<DBIx::Class::Manual::Cookbook>.
3204
3205 =head2 from
3206
3207 =over 4
3208
3209 =item Value: \@from_clause
3210
3211 =back
3212
3213 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3214 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3215 clauses.
3216
3217 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3218
3219 C<join> will usually do what you need and it is strongly recommended that you
3220 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3221 And we really do mean "cannot", not just tried and failed. Attempting to use
3222 this because you're having problems with C<join> is like trying to use x86
3223 ASM because you've got a syntax error in your C. Trust us on this.
3224
3225 Now, if you're still really, really sure you need to use this (and if you're
3226 not 100% sure, ask the mailing list first), here's an explanation of how this
3227 works.
3228
3229 The syntax is as follows -
3230
3231   [
3232     { <alias1> => <table1> },
3233     [
3234       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3235       [], # nested JOIN (optional)
3236       { <table1.column1> => <table2.column2>, ... (more conditions) },
3237     ],
3238     # More of the above [ ] may follow for additional joins
3239   ]
3240
3241   <table1> <alias1>
3242   JOIN
3243     <table2> <alias2>
3244     [JOIN ...]
3245   ON <table1.column1> = <table2.column2>
3246   <more joins may follow>
3247
3248 An easy way to follow the examples below is to remember the following:
3249
3250     Anything inside "[]" is a JOIN
3251     Anything inside "{}" is a condition for the enclosing JOIN
3252
3253 The following examples utilize a "person" table in a family tree application.
3254 In order to express parent->child relationships, this table is self-joined:
3255
3256     # Person->belongs_to('father' => 'Person');
3257     # Person->belongs_to('mother' => 'Person');
3258
3259 C<from> can be used to nest joins. Here we return all children with a father,
3260 then search against all mothers of those children:
3261
3262   $rs = $schema->resultset('Person')->search(
3263       undef,
3264       {
3265           alias => 'mother', # alias columns in accordance with "from"
3266           from => [
3267               { mother => 'person' },
3268               [
3269                   [
3270                       { child => 'person' },
3271                       [
3272                           { father => 'person' },
3273                           { 'father.person_id' => 'child.father_id' }
3274                       ]
3275                   ],
3276                   { 'mother.person_id' => 'child.mother_id' }
3277               ],
3278           ]
3279       },
3280   );
3281
3282   # Equivalent SQL:
3283   # SELECT mother.* FROM person mother
3284   # JOIN (
3285   #   person child
3286   #   JOIN person father
3287   #   ON ( father.person_id = child.father_id )
3288   # )
3289   # ON ( mother.person_id = child.mother_id )
3290
3291 The type of any join can be controlled manually. To search against only people
3292 with a father in the person table, we could explicitly use C<INNER JOIN>:
3293
3294     $rs = $schema->resultset('Person')->search(
3295         undef,
3296         {
3297             alias => 'child', # alias columns in accordance with "from"
3298             from => [
3299                 { child => 'person' },
3300                 [
3301                     { father => 'person', -join_type => 'inner' },
3302                     { 'father.id' => 'child.father_id' }
3303                 ],
3304             ]
3305         },
3306     );
3307
3308     # Equivalent SQL:
3309     # SELECT child.* FROM person child
3310     # INNER JOIN person father ON child.father_id = father.id
3311
3312 You can select from a subquery by passing a resultset to from as follows.
3313
3314     $schema->resultset('Artist')->search(
3315         undef,
3316         {   alias => 'artist2',
3317             from  => [ { artist2 => $artist_rs->as_query } ],
3318         } );
3319
3320     # and you'll get sql like this..
3321     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3322     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3323
3324 If you need to express really complex joins, you
3325 can supply literal SQL to C<from> via a scalar reference. In this case
3326 the contents of the scalar will replace the table name associated with the
3327 resultsource.
3328
3329 WARNING: This technique might very well not work as expected on chained
3330 searches - you have been warned.
3331
3332     # Assuming the Event resultsource is defined as:
3333
3334         MySchema::Event->add_columns (
3335             sequence => {
3336                 data_type => 'INT',
3337                 is_auto_increment => 1,
3338             },
3339             location => {
3340                 data_type => 'INT',
3341             },
3342             type => {
3343                 data_type => 'INT',
3344             },
3345         );
3346         MySchema::Event->set_primary_key ('sequence');
3347
3348     # This will get back the latest event for every location. The column
3349     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3350     # combo to limit the resultset
3351
3352     $rs = $schema->resultset('Event');
3353     $table = $rs->result_source->name;
3354     $latest = $rs->search (
3355         undef,
3356         { from => \ "
3357             (SELECT e1.* FROM $table e1
3358                 JOIN $table e2
3359                     ON e1.location = e2.location
3360                     AND e1.sequence < e2.sequence
3361                 WHERE e2.sequence is NULL
3362             ) me",
3363         },
3364     );
3365
3366     # Equivalent SQL (with the DBIC chunks added):
3367
3368     SELECT me.sequence, me.location, me.type FROM
3369        (SELECT e1.* FROM events e1
3370            JOIN events e2
3371                ON e1.location = e2.location
3372                AND e1.sequence < e2.sequence
3373            WHERE e2.sequence is NULL
3374        ) me;
3375
3376 =head2 for
3377
3378 =over 4
3379
3380 =item Value: ( 'update' | 'shared' )
3381
3382 =back
3383
3384 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3385 ... FOR SHARED.
3386
3387 =cut
3388
3389 1;