lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => \&count,
   7         'bool'   => sub { 1; },
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use base qw/DBIx::Class/;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/result_class _source_handle/);
  17
  18 =head1 NAME
  19
  20 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  21
  22 =head1 SYNOPSIS
  23
  24   my $rs   = $schema->resultset('User')->search(registered => 1);
  25   my @rows = $schema->resultset('CD')->search(year => 2005);
  26
  27 =head1 DESCRIPTION
  28
  29 The resultset is also known as an iterator. It is responsible for handling
  30 queries that may return an arbitrary number of rows, e.g. via L</search>
  31 or a C<has_many> relationship.
  32
  33 In the examples below, the following table classes are used:
  34
  35   package MyApp::Schema::Artist;
  36   use base qw/DBIx::Class/;
  37   __PACKAGE__->load_components(qw/Core/);
  38   __PACKAGE__->table('artist');
  39   __PACKAGE__->add_columns(qw/artistid name/);
  40   __PACKAGE__->set_primary_key('artistid');
  41   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  42   1;
  43
  44   package MyApp::Schema::CD;
  45   use base qw/DBIx::Class/;
  46   __PACKAGE__->load_components(qw/Core/);
  47   __PACKAGE__->table('cd');
  48   __PACKAGE__->add_columns(qw/cdid artist title year/);
  49   __PACKAGE__->set_primary_key('cdid');
  50   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  51   1;
  52
  53 =head1 METHODS
  54
  55 =head2 new
  56
  57 =over 4
  58
  59 =item Arguments: $source, \%$attrs
  60
  61 =item Return Value: $rs
  62
  63 =back
  64
  65 The resultset constructor. Takes a source object (usually a
  66 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  67 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  68 executed as needed by the other methods.
  69
  70 Generally you won't need to construct a resultset manually.  You'll
  71 automatically get one from e.g. a L</search> called in scalar context:
  72
  73   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  74
  75 IMPORTANT: If called on an object, proxies to new_result instead so
  76
  77   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  78
  79 will return a CD object, not a ResultSet.
  80
  81 =cut
  82
  83 sub new {
  84   my $class = shift;
  85   return $class->new_result(@_) if ref $class;
  86
  87   my ($source, $attrs) = @_;
  88   $source = $source->handle
  89     unless $source->isa('DBIx::Class::ResultSourceHandle');
  90   $attrs = { %{$attrs||{}} };
  91
  92   if ($attrs->{page}) {
  93     $attrs->{rows} ||= 10;
  94     $attrs->{offset} ||= 0;
  95     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
  96   }
  97
  98   $attrs->{alias} ||= 'me';
  99
 100   my $self = {
 101     _source_handle => $source,
 102     result_class => $attrs->{result_class} || $source->resolve->result_class,
 103     cond => $attrs->{where},
 104     count => undef,
 105     pager => undef,
 106     attrs => $attrs
 107   };
 108
 109   bless $self, $class;
 110
 111   return $self;
 112 }
 113
 114 =head2 search
 115
 116 =over 4
 117
 118 =item Arguments: $cond, \%attrs?
 119
 120 =item Return Value: $resultset (scalar context), @row_objs (list context)
 121
 122 =back
 123
 124   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 125   my $new_rs = $cd_rs->search({ year => 2005 });
 126
 127   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 128                  # year = 2005 OR year = 2004
 129
 130 If you need to pass in additional attributes but no additional condition,
 131 call it as C<search(undef, \%attrs)>.
 132
 133   # "SELECT name, artistid FROM $artist_table"
 134   my @all_artists = $schema->resultset('Artist')->search(undef, {
 135     columns => [qw/name artistid/],
 136   });
 137
 138 For a list of attributes that can be passed to C<search>, see
 139 L</ATTRIBUTES>. For more examples of using this function, see
 140 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 141 documentation for the first argument, see L<SQL::Abstract>.
 142
 143 =cut
 144
 145 sub search {
 146   my $self = shift;
 147   my $rs = $self->search_rs( @_ );
 148   return (wantarray ? $rs->all : $rs);
 149 }
 150
 151 =head2 search_rs
 152
 153 =over 4
 154
 155 =item Arguments: $cond, \%attrs?
 156
 157 =item Return Value: $resultset
 158
 159 =back
 160
 161 This method does the same exact thing as search() except it will
 162 always return a resultset, even in list context.
 163
 164 =cut
 165
 166 sub search_rs {
 167   my $self = shift;
 168
 169   my $rows;
 170
 171   unless (@_) {                 # no search, effectively just a clone
 172     $rows = $self->get_cache;
 173   }
 174
 175   my $attrs = {};
 176   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 177   my $our_attrs = { %{$self->{attrs}} };
 178   my $having = delete $our_attrs->{having};
 179   my $where = delete $our_attrs->{where};
 180
 181   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 182
 183   # merge new attrs into inherited
 184   foreach my $key (qw/join prefetch/) {
 185     next unless exists $attrs->{$key};
 186     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 187   }
 188
 189   my $cond = (@_
 190     ? (
 191         (@_ == 1 || ref $_[0] eq "HASH")
 192           ? (
 193               (ref $_[0] eq 'HASH')
 194                 ? (
 195                     (keys %{ $_[0] }  > 0)
 196                       ? shift
 197                       : undef
 198                    )
 199                 :  shift
 200              )
 201           : (
 202               (@_ % 2)
 203                 ? $self->throw_exception("Odd number of arguments to search")
 204                 : {@_}
 205              )
 206       )
 207     : undef
 208   );
 209
 210   if (defined $where) {
 211     $new_attrs->{where} = (
 212       defined $new_attrs->{where}
 213         ? { '-and' => [
 214               map {
 215                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 216               } $where, $new_attrs->{where}
 217             ]
 218           }
 219         : $where);
 220   }
 221
 222   if (defined $cond) {
 223     $new_attrs->{where} = (
 224       defined $new_attrs->{where}
 225         ? { '-and' => [
 226               map {
 227                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 228               } $cond, $new_attrs->{where}
 229             ]
 230           }
 231         : $cond);
 232   }
 233
 234   if (defined $having) {
 235     $new_attrs->{having} = (
 236       defined $new_attrs->{having}
 237         ? { '-and' => [
 238               map {
 239                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 240               } $having, $new_attrs->{having}
 241             ]
 242           }
 243         : $having);
 244   }
 245
 246   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 247   if ($rows) {
 248     $rs->set_cache($rows);
 249   }
 250   return $rs;
 251 }
 252
 253 =head2 search_literal
 254
 255 =over 4
 256
 257 =item Arguments: $sql_fragment, @bind_values
 258
 259 =item Return Value: $resultset (scalar context), @row_objs (list context)
 260
 261 =back
 262
 263   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 264   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 265
 266 Pass a literal chunk of SQL to be added to the conditional part of the
 267 resultset query.
 268
 269 =cut
 270
 271 sub search_literal {
 272   my ($self, $cond, @vals) = @_;
 273   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 274   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 275   return $self->search(\$cond, $attrs);
 276 }
 277
 278 =head2 find
 279
 280 =over 4
 281
 282 =item Arguments: @values | \%cols, \%attrs?
 283
 284 =item Return Value: $row_object
 285
 286 =back
 287
 288 Finds a row based on its primary key or unique constraint. For example, to find
 289 a row by its primary key:
 290
 291   my $cd = $schema->resultset('CD')->find(5);
 292
 293 You can also find a row by a specific unique constraint using the C<key>
 294 attribute. For example:
 295
 296   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 297     key => 'cd_artist_title'
 298   });
 299
 300 Additionally, you can specify the columns explicitly by name:
 301
 302   my $cd = $schema->resultset('CD')->find(
 303     {
 304       artist => 'Massive Attack',
 305       title  => 'Mezzanine',
 306     },
 307     { key => 'cd_artist_title' }
 308   );
 309
 310 If the C<key> is specified as C<primary>, it searches only on the primary key.
 311
 312 If no C<key> is specified, it searches on all unique constraints defined on the
 313 source, including the primary key.
 314
 315 If your table does not have a primary key, you B<must> provide a value for the
 316 C<key> attribute matching one of the unique constraints on the source.
 317
 318 See also L</find_or_create> and L</update_or_create>. For information on how to
 319 declare unique constraints, see
 320 L<DBIx::Class::ResultSource/add_unique_constraint>.
 321
 322 =cut
 323
 324 sub find {
 325   my $self = shift;
 326   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 327
 328   # Default to the primary key, but allow a specific key
 329   my @cols = exists $attrs->{key}
 330     ? $self->result_source->unique_constraint_columns($attrs->{key})
 331     : $self->result_source->primary_columns;
 332   $self->throw_exception(
 333     "Can't find unless a primary key is defined or unique constraint is specified"
 334   ) unless @cols;
 335
 336   # Parse out a hashref from input
 337   my $input_query;
 338   if (ref $_[0] eq 'HASH') {
 339     $input_query = { %{$_[0]} };
 340   }
 341   elsif (@_ == @cols) {
 342     $input_query = {};
 343     @{$input_query}{@cols} = @_;
 344   }
 345   else {
 346     # Compatibility: Allow e.g. find(id => $value)
 347     carp "Find by key => value deprecated; please use a hashref instead";
 348     $input_query = {@_};
 349   }
 350
 351   my (%related, $info);
 352
 353   KEY: foreach my $key (keys %$input_query) {
 354     if (ref($input_query->{$key})
 355         && ($info = $self->result_source->relationship_info($key))) {
 356       my $val = delete $input_query->{$key};
 357       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 358       my $rel_q = $self->result_source->resolve_condition(
 359                     $info->{cond}, $val, $key
 360                   );
 361       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 362       @related{keys %$rel_q} = values %$rel_q;
 363     }
 364   }
 365   if (my @keys = keys %related) {
 366     @{$input_query}{@keys} = values %related;
 367   }
 368
 369   my @unique_queries = $self->_unique_queries($input_query, $attrs);
 370
 371   # Build the final query: Default to the disjunction of the unique queries,
 372   # but allow the input query in case the ResultSet defines the query or the
 373   # user is abusing find
 374   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 375   my $query = @unique_queries
 376     ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 377     : $self->_add_alias($input_query, $alias);
 378
 379   # Run the query
 380   if (keys %$attrs) {
 381     my $rs = $self->search($query, $attrs);
 382     return keys %{$rs->_resolved_attrs->{collapse}} ? $rs->next : $rs->single;
 383   }
 384   else {
 385     return keys %{$self->_resolved_attrs->{collapse}}
 386       ? $self->search($query)->next
 387       : $self->single($query);
 388   }
 389 }
 390
 391 # _add_alias
 392 #
 393 # Add the specified alias to the specified query hash. A copy is made so the
 394 # original query is not modified.
 395
 396 sub _add_alias {
 397   my ($self, $query, $alias) = @_;
 398
 399   my %aliased = %$query;
 400   foreach my $col (grep { ! m/\./ } keys %aliased) {
 401     $aliased{"$alias.$col"} = delete $aliased{$col};
 402   }
 403
 404   return \%aliased;
 405 }
 406
 407 # _unique_queries
 408 #
 409 # Build a list of queries which satisfy unique constraints.
 410
 411 sub _unique_queries {
 412   my ($self, $query, $attrs) = @_;
 413
 414   my @constraint_names = exists $attrs->{key}
 415     ? ($attrs->{key})
 416     : $self->result_source->unique_constraint_names;
 417
 418   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 419   my $num_where = scalar keys %$where;
 420
 421   my @unique_queries;
 422   foreach my $name (@constraint_names) {
 423     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 424     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 425
 426     my $num_cols = scalar @unique_cols;
 427     my $num_query = scalar keys %$unique_query;
 428
 429     my $total = $num_query + $num_where;
 430     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 431       # The query is either unique on its own or is unique in combination with
 432       # the existing where clause
 433       push @unique_queries, $unique_query;
 434     }
 435   }
 436
 437   return @unique_queries;
 438 }
 439
 440 # _build_unique_query
 441 #
 442 # Constrain the specified query hash based on the specified column names.
 443
 444 sub _build_unique_query {
 445   my ($self, $query, $unique_cols) = @_;
 446
 447   return {
 448     map  { $_ => $query->{$_} }
 449     grep { exists $query->{$_} }
 450       @$unique_cols
 451   };
 452 }
 453
 454 =head2 search_related
 455
 456 =over 4
 457
 458 =item Arguments: $rel, $cond, \%attrs?
 459
 460 =item Return Value: $new_resultset
 461
 462 =back
 463
 464   $new_rs = $cd_rs->search_related('artist', {
 465     name => 'Emo-R-Us',
 466   });
 467
 468 Searches the specified relationship, optionally specifying a condition and
 469 attributes for matching records. See L</ATTRIBUTES> for more information.
 470
 471 =cut
 472
 473 sub search_related {
 474   return shift->related_resultset(shift)->search(@_);
 475 }
 476
 477 =head2 cursor
 478
 479 =over 4
 480
 481 =item Arguments: none
 482
 483 =item Return Value: $cursor
 484
 485 =back
 486
 487 Returns a storage-driven cursor to the given resultset. See
 488 L<DBIx::Class::Cursor> for more information.
 489
 490 =cut
 491
 492 sub cursor {
 493   my ($self) = @_;
 494
 495   my $attrs = { %{$self->_resolved_attrs} };
 496   return $self->{cursor}
 497     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 498           $attrs->{where},$attrs);
 499 }
 500
 501 =head2 single
 502
 503 =over 4
 504
 505 =item Arguments: $cond?
 506
 507 =item Return Value: $row_object?
 508
 509 =back
 510
 511   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 512
 513 Inflates the first result without creating a cursor if the resultset has
 514 any records in it; if not returns nothing. Used by L</find> as an optimisation.
 515
 516 Can optionally take an additional condition *only* - this is a fast-code-path
 517 method; if you need to add extra joins or similar call ->search and then
 518 ->single without a condition on the $rs returned from that.
 519
 520 =cut
 521
 522 sub single {
 523   my ($self, $where) = @_;
 524   my $attrs = { %{$self->_resolved_attrs} };
 525   if ($where) {
 526     if (defined $attrs->{where}) {
 527       $attrs->{where} = {
 528         '-and' =>
 529             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 530                $where, delete $attrs->{where} ]
 531       };
 532     } else {
 533       $attrs->{where} = $where;
 534     }
 535   }
 536
 537 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 538 #  unless ($self->_is_unique_query($attrs->{where})) {
 539 #    carp "Query not guaranteed to return a single row"
 540 #      . "; please declare your unique constraints or use search instead";
 541 #  }
 542
 543   my @data = $self->result_source->storage->select_single(
 544     $attrs->{from}, $attrs->{select},
 545     $attrs->{where}, $attrs
 546   );
 547
 548   return (@data ? ($self->_construct_object(@data))[0] : ());
 549 }
 550
 551 # _is_unique_query
 552 #
 553 # Try to determine if the specified query is guaranteed to be unique, based on
 554 # the declared unique constraints.
 555
 556 sub _is_unique_query {
 557   my ($self, $query) = @_;
 558
 559   my $collapsed = $self->_collapse_query($query);
 560   my $alias = $self->{attrs}{alias};
 561
 562   foreach my $name ($self->result_source->unique_constraint_names) {
 563     my @unique_cols = map {
 564       "$alias.$_"
 565     } $self->result_source->unique_constraint_columns($name);
 566
 567     # Count the values for each unique column
 568     my %seen = map { $_ => 0 } @unique_cols;
 569
 570     foreach my $key (keys %$collapsed) {
 571       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 572       next unless exists $seen{$aliased};  # Additional constraints are okay
 573       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 574     }
 575
 576     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 577     return 1 unless grep { $_ != 1 } values %seen;
 578   }
 579
 580   return 0;
 581 }
 582
 583 # _collapse_query
 584 #
 585 # Recursively collapse the query, accumulating values for each column.
 586
 587 sub _collapse_query {
 588   my ($self, $query, $collapsed) = @_;
 589
 590   $collapsed ||= {};
 591
 592   if (ref $query eq 'ARRAY') {
 593     foreach my $subquery (@$query) {
 594       next unless ref $subquery;  # -or
 595 #      warn "ARRAY: " . Dumper $subquery;
 596       $collapsed = $self->_collapse_query($subquery, $collapsed);
 597     }
 598   }
 599   elsif (ref $query eq 'HASH') {
 600     if (keys %$query and (keys %$query)[0] eq '-and') {
 601       foreach my $subquery (@{$query->{-and}}) {
 602 #        warn "HASH: " . Dumper $subquery;
 603         $collapsed = $self->_collapse_query($subquery, $collapsed);
 604       }
 605     }
 606     else {
 607 #      warn "LEAF: " . Dumper $query;
 608       foreach my $col (keys %$query) {
 609         my $value = $query->{$col};
 610         $collapsed->{$col}{$value}++;
 611       }
 612     }
 613   }
 614
 615   return $collapsed;
 616 }
 617
 618 =head2 get_column
 619
 620 =over 4
 621
 622 =item Arguments: $cond?
 623
 624 =item Return Value: $resultsetcolumn
 625
 626 =back
 627
 628   my $max_length = $rs->get_column('length')->max;
 629
 630 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 631
 632 =cut
 633
 634 sub get_column {
 635   my ($self, $column) = @_;
 636   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 637   return $new;
 638 }
 639
 640 =head2 search_like
 641
 642 =over 4
 643
 644 =item Arguments: $cond, \%attrs?
 645
 646 =item Return Value: $resultset (scalar context), @row_objs (list context)
 647
 648 =back
 649
 650   # WHERE title LIKE '%blue%'
 651   $cd_rs = $rs->search_like({ title => '%blue%'});
 652
 653 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 654 that this is simply a convenience method. You most likely want to use
 655 L</search> with specific operators.
 656
 657 For more information, see L<DBIx::Class::Manual::Cookbook>.
 658
 659 =cut
 660
 661 sub search_like {
 662   my $class = shift;
 663   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 664   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 665   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 666   return $class->search($query, { %$attrs });
 667 }
 668
 669 =head2 slice
 670
 671 =over 4
 672
 673 =item Arguments: $first, $last
 674
 675 =item Return Value: $resultset (scalar context), @row_objs (list context)
 676
 677 =back
 678
 679 Returns a resultset or object list representing a subset of elements from the
 680 resultset slice is called on. Indexes are from 0, i.e., to get the first
 681 three records, call:
 682
 683   my ($one, $two, $three) = $rs->slice(0, 2);
 684
 685 =cut
 686
 687 sub slice {
 688   my ($self, $min, $max) = @_;
 689   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 690   $attrs->{offset} = $self->{attrs}{offset} || 0;
 691   $attrs->{offset} += $min;
 692   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 693   return $self->search(undef(), $attrs);
 694   #my $slice = (ref $self)->new($self->result_source, $attrs);
 695   #return (wantarray ? $slice->all : $slice);
 696 }
 697
 698 =head2 next
 699
 700 =over 4
 701
 702 =item Arguments: none
 703
 704 =item Return Value: $result?
 705
 706 =back
 707
 708 Returns the next element in the resultset (C<undef> is there is none).
 709
 710 Can be used to efficiently iterate over records in the resultset:
 711
 712   my $rs = $schema->resultset('CD')->search;
 713   while (my $cd = $rs->next) {
 714     print $cd->title;
 715   }
 716
 717 Note that you need to store the resultset object, and call C<next> on it.
 718 Calling C<< resultset('Table')->next >> repeatedly will always return the
 719 first record from the resultset.
 720
 721 =cut
 722
 723 sub next {
 724   my ($self) = @_;
 725   if (my $cache = $self->get_cache) {
 726     $self->{all_cache_position} ||= 0;
 727     return $cache->[$self->{all_cache_position}++];
 728   }
 729   if ($self->{attrs}{cache}) {
 730     $self->{all_cache_position} = 1;
 731     return ($self->all)[0];
 732   }
 733   if ($self->{stashed_objects}) {
 734     my $obj = shift(@{$self->{stashed_objects}});
 735     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 736     return $obj;
 737   }
 738   my @row = (
 739     exists $self->{stashed_row}
 740       ? @{delete $self->{stashed_row}}
 741       : $self->cursor->next
 742   );
 743   return unless (@row);
 744   my ($row, @more) = $self->_construct_object(@row);
 745   $self->{stashed_objects} = \@more if @more;
 746   return $row;
 747 }
 748
 749 sub _construct_object {
 750   my ($self, @row) = @_;
 751   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 752   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 753   @new = $self->{_attrs}{record_filter}->(@new)
 754     if exists $self->{_attrs}{record_filter};
 755   return @new;
 756 }
 757
 758 sub _collapse_result {
 759   my ($self, $as_proto, $row) = @_;
 760
 761   my @copy = @$row;
 762
 763   # 'foo'         => [ undef, 'foo' ]
 764   # 'foo.bar'     => [ 'foo', 'bar' ]
 765   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 766
 767   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 768
 769   my %collapse = %{$self->{_attrs}{collapse}||{}};
 770
 771   my @pri_index;
 772
 773   # if we're doing collapsing (has_many prefetch) we need to grab records
 774   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 775   # we know we don't have to bother.
 776
 777   # the reason for not using the collapse stuff directly is because if you
 778   # had for e.g. two artists in a row with no cds, the collapse info for
 779   # both would be NULL (undef) so you'd lose the second artist
 780
 781   # store just the index so we can check the array positions from the row
 782   # without having to contruct the full hash
 783
 784   if (keys %collapse) {
 785     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 786     foreach my $i (0 .. $#construct_as) {
 787       next if defined($construct_as[$i][0]); # only self table
 788       if (delete $pri{$construct_as[$i][1]}) {
 789         push(@pri_index, $i);
 790       }
 791       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 792     }
 793   }
 794
 795   # no need to do an if, it'll be empty if @pri_index is empty anyway
 796
 797   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 798
 799   my @const_rows;
 800
 801   do { # no need to check anything at the front, we always want the first row
 802
 803     my %const;
 804
 805     foreach my $this_as (@construct_as) {
 806       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 807     }
 808
 809     push(@const_rows, \%const);
 810
 811   } until ( # no pri_index => no collapse => drop straight out
 812       !@pri_index
 813     or
 814       do { # get another row, stash it, drop out if different PK
 815
 816         @copy = $self->cursor->next;
 817         $self->{stashed_row} = \@copy;
 818
 819         # last thing in do block, counts as true if anything doesn't match
 820
 821         # check xor defined first for NULL vs. NOT NULL then if one is
 822         # defined the other must be so check string equality
 823
 824         grep {
 825           (defined $pri_vals{$_} ^ defined $copy[$_])
 826           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 827         } @pri_index;
 828       }
 829   );
 830
 831   my $alias = $self->{attrs}{alias};
 832   my $info = [];
 833
 834   my %collapse_pos;
 835
 836   my @const_keys;
 837
 838   use Data::Dumper;
 839
 840   foreach my $const (@const_rows) {
 841     scalar @const_keys or do {
 842       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 843     };
 844     foreach my $key (@const_keys) {
 845       if (length $key) {
 846         my $target = $info;
 847         my @parts = split(/\./, $key);
 848         my $cur = '';
 849         my $data = $const->{$key};
 850         foreach my $p (@parts) {
 851           $target = $target->[1]->{$p} ||= [];
 852           $cur .= ".${p}";
 853           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 854             # collapsing at this point and on final part
 855             my $pos = $collapse_pos{$cur};
 856             CK: foreach my $ck (@ckey) {
 857               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 858                 $collapse_pos{$cur} = $data;
 859                 delete @collapse_pos{ # clear all positioning for sub-entries
 860                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 861                 };
 862                 push(@$target, []);
 863                 last CK;
 864               }
 865             }
 866           }
 867           if (exists $collapse{$cur}) {
 868             $target = $target->[-1];
 869           }
 870         }
 871         $target->[0] = $data;
 872       } else {
 873         $info->[0] = $const->{$key};
 874       }
 875     }
 876   }
 877
 878   return $info;
 879 }
 880
 881 =head2 result_source
 882
 883 =over 4
 884
 885 =item Arguments: $result_source?
 886
 887 =item Return Value: $result_source
 888
 889 =back
 890
 891 An accessor for the primary ResultSource object from which this ResultSet
 892 is derived.
 893
 894 =head2 result_class
 895
 896 =over 4
 897
 898 =item Arguments: $result_class?
 899
 900 =item Return Value: $result_class
 901
 902 =back
 903
 904 An accessor for the class to use when creating row objects. Defaults to
 905 C<< result_source->result_class >> - which in most cases is the name of the
 906 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 907
 908 =cut
 909
 910
 911 =head2 count
 912
 913 =over 4
 914
 915 =item Arguments: $cond, \%attrs??
 916
 917 =item Return Value: $count
 918
 919 =back
 920
 921 Performs an SQL C<COUNT> with the same query as the resultset was built
 922 with to find the number of elements. If passed arguments, does a search
 923 on the resultset and counts the results of that.
 924
 925 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 926 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 927 not support C<DISTINCT> with multiple columns. If you are using such a
 928 database, you should only use columns from the main table in your C<group_by>
 929 clause.
 930
 931 =cut
 932
 933 sub count {
 934   my $self = shift;
 935   return $self->search(@_)->count if @_ and defined $_[0];
 936   return scalar @{ $self->get_cache } if $self->get_cache;
 937   my $count = $self->_count;
 938   return 0 unless $count;
 939
 940   $count -= $self->{attrs}{offset} if $self->{attrs}{offset};
 941   $count = $self->{attrs}{rows} if
 942     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 943   return $count;
 944 }
 945
 946 sub _count { # Separated out so pager can get the full count
 947   my $self = shift;
 948   my $select = { count => '*' };
 949
 950   my $attrs = { %{$self->_resolved_attrs} };
 951   if (my $group_by = delete $attrs->{group_by}) {
 952     delete $attrs->{having};
 953     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 954     # todo: try CONCAT for multi-column pk
 955     my @pk = $self->result_source->primary_columns;
 956     if (@pk == 1) {
 957       my $alias = $attrs->{alias};
 958       foreach my $column (@distinct) {
 959         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
 960           @distinct = ($column);
 961           last;
 962         }
 963       }
 964     }
 965
 966     $select = { count => { distinct => \@distinct } };
 967   }
 968
 969   $attrs->{select} = $select;
 970   $attrs->{as} = [qw/count/];
 971
 972   # offset, order by and page are not needed to count. record_filter is cdbi
 973   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 974
 975   my $tmp_rs = (ref $self)->new($self->_source_handle, $attrs);
 976   my ($count) = $tmp_rs->cursor->next;
 977   return $count;
 978 }
 979
 980 =head2 count_literal
 981
 982 =over 4
 983
 984 =item Arguments: $sql_fragment, @bind_values
 985
 986 =item Return Value: $count
 987
 988 =back
 989
 990 Counts the results in a literal query. Equivalent to calling L</search_literal>
 991 with the passed arguments, then L</count>.
 992
 993 =cut
 994
 995 sub count_literal { shift->search_literal(@_)->count; }
 996
 997 =head2 all
 998
 999 =over 4
1000
1001 =item Arguments: none
1002
1003 =item Return Value: @objects
1004
1005 =back
1006
1007 Returns all elements in the resultset. Called implicitly if the resultset
1008 is returned in list context.
1009
1010 =cut
1011
1012 sub all {
1013   my ($self) = @_;
1014   return @{ $self->get_cache } if $self->get_cache;
1015
1016   my @obj;
1017
1018   # TODO: don't call resolve here
1019   if (keys %{$self->_resolved_attrs->{collapse}}) {
1020 #  if ($self->{attrs}{prefetch}) {
1021       # Using $self->cursor->all is really just an optimisation.
1022       # If we're collapsing has_many prefetches it probably makes
1023       # very little difference, and this is cleaner than hacking
1024       # _construct_object to survive the approach
1025     my @row = $self->cursor->next;
1026     while (@row) {
1027       push(@obj, $self->_construct_object(@row));
1028       @row = (exists $self->{stashed_row}
1029                ? @{delete $self->{stashed_row}}
1030                : $self->cursor->next);
1031     }
1032   } else {
1033     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1034   }
1035
1036   $self->set_cache(\@obj) if $self->{attrs}{cache};
1037   return @obj;
1038 }
1039
1040 =head2 reset
1041
1042 =over 4
1043
1044 =item Arguments: none
1045
1046 =item Return Value: $self
1047
1048 =back
1049
1050 Resets the resultset's cursor, so you can iterate through the elements again.
1051
1052 =cut
1053
1054 sub reset {
1055   my ($self) = @_;
1056   delete $self->{_attrs} if exists $self->{_attrs};
1057   $self->{all_cache_position} = 0;
1058   $self->cursor->reset;
1059   return $self;
1060 }
1061
1062 =head2 first
1063
1064 =over 4
1065
1066 =item Arguments: none
1067
1068 =item Return Value: $object?
1069
1070 =back
1071
1072 Resets the resultset and returns an object for the first result (if the
1073 resultset returns anything).
1074
1075 =cut
1076
1077 sub first {
1078   return $_[0]->reset->next;
1079 }
1080
1081 # _cond_for_update_delete
1082 #
1083 # update/delete require the condition to be modified to handle
1084 # the differing SQL syntax available.  This transforms the $self->{cond}
1085 # appropriately, returning the new condition.
1086
1087 sub _cond_for_update_delete {
1088   my ($self, $full_cond) = @_;
1089   my $cond = {};
1090
1091   $full_cond ||= $self->{cond};
1092   # No-op. No condition, we're updating/deleting everything
1093   return $cond unless ref $full_cond;
1094
1095   if (ref $full_cond eq 'ARRAY') {
1096     $cond = [
1097       map {
1098         my %hash;
1099         foreach my $key (keys %{$_}) {
1100           $key =~ /([^.]+)$/;
1101           $hash{$1} = $_->{$key};
1102         }
1103         \%hash;
1104       } @{$full_cond}
1105     ];
1106   }
1107   elsif (ref $full_cond eq 'HASH') {
1108     if ((keys %{$full_cond})[0] eq '-and') {
1109       $cond->{-and} = [];
1110
1111       my @cond = @{$full_cond->{-and}};
1112       for (my $i = 0; $i < @cond; $i++) {
1113         my $entry = $cond[$i];
1114
1115         my $hash;
1116         if (ref $entry eq 'HASH') {
1117           $hash = $self->_cond_for_update_delete($entry);
1118         }
1119         else {
1120           $entry =~ /([^.]+)$/;
1121           $hash->{$1} = $cond[++$i];
1122         }
1123
1124         push @{$cond->{-and}}, $hash;
1125       }
1126     }
1127     else {
1128       foreach my $key (keys %{$full_cond}) {
1129         $key =~ /([^.]+)$/;
1130         $cond->{$1} = $full_cond->{$key};
1131       }
1132     }
1133   }
1134   else {
1135     $self->throw_exception(
1136       "Can't update/delete on resultset with condition unless hash or array"
1137     );
1138   }
1139
1140   return $cond;
1141 }
1142
1143
1144 =head2 update
1145
1146 =over 4
1147
1148 =item Arguments: \%values
1149
1150 =item Return Value: $storage_rv
1151
1152 =back
1153
1154 Sets the specified columns in the resultset to the supplied values in a
1155 single query. Return value will be true if the update succeeded or false
1156 if no records were updated; exact type of success value is storage-dependent.
1157
1158 =cut
1159
1160 sub update {
1161   my ($self, $values) = @_;
1162   $self->throw_exception("Values for update must be a hash")
1163     unless ref $values eq 'HASH';
1164
1165   my $cond = $self->_cond_for_update_delete;
1166
1167   return $self->result_source->storage->update(
1168     $self->result_source, $values, $cond
1169   );
1170 }
1171
1172 =head2 update_all
1173
1174 =over 4
1175
1176 =item Arguments: \%values
1177
1178 =item Return Value: 1
1179
1180 =back
1181
1182 Fetches all objects and updates them one at a time. Note that C<update_all>
1183 will run DBIC cascade triggers, while L</update> will not.
1184
1185 =cut
1186
1187 sub update_all {
1188   my ($self, $values) = @_;
1189   $self->throw_exception("Values for update must be a hash")
1190     unless ref $values eq 'HASH';
1191   foreach my $obj ($self->all) {
1192     $obj->set_columns($values)->update;
1193   }
1194   return 1;
1195 }
1196
1197 =head2 delete
1198
1199 =over 4
1200
1201 =item Arguments: none
1202
1203 =item Return Value: 1
1204
1205 =back
1206
1207 Deletes the contents of the resultset from its result source. Note that this
1208 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1209 to run. See also L<DBIx::Class::Row/delete>.
1210
1211 =cut
1212
1213 sub delete {
1214   my ($self) = @_;
1215
1216   my $cond = $self->_cond_for_update_delete;
1217
1218   $self->result_source->storage->delete($self->result_source, $cond);
1219   return 1;
1220 }
1221
1222 =head2 delete_all
1223
1224 =over 4
1225
1226 =item Arguments: none
1227
1228 =item Return Value: 1
1229
1230 =back
1231
1232 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1233 will run DBIC cascade triggers, while L</delete> will not.
1234
1235 =cut
1236
1237 sub delete_all {
1238   my ($self) = @_;
1239   $_->delete for $self->all;
1240   return 1;
1241 }
1242
1243 =head2 populate
1244
1245 =over 4
1246
1247 =item Arguments: $source_name, \@data;
1248
1249 =back
1250
1251 Pass an arrayref of hashrefs. Each hashref should be a structure suitable for
1252 submitting to a $resultset->create(...) method.
1253
1254 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1255 to insert the data, as this is a fast method.
1256
1257 Otherwise, each set of data is inserted into the database using
1258 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1259 objects is returned.
1260
1261 i.e.,
1262
1263   $rs->populate( [
1264           { artistid => 4, name => 'Manufactured Crap', cds => [
1265                   { title => 'My First CD', year => 2006 },
1266                   { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1267                 ]
1268           },
1269           { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1270                   { title => 'My parents sold me to a record company' ,year => 2005 },
1271                   { title => 'Why Am I So Ugly?', year => 2006 },
1272                   { title => 'I Got Surgery and am now Popular', year => 2007 }
1273                 ]
1274           },
1275           { name => 'Like I Give a Damn' }
1276
1277         ] );
1278
1279 =cut
1280 use Data::Dump qw/dump/;
1281
1282 sub populate {
1283   my ($self, $data) = @_;
1284
1285   if(defined wantarray) {
1286     my @created;
1287     foreach my $item (@$data) {
1288       push(@created, $self->create($item));
1289     }
1290     return @created;
1291   }
1292   else
1293   {
1294     my ($first, @rest) = @$data;
1295     my @names = keys %$first;
1296
1297         warn dump keys %$_ for @$data;
1298
1299         #@$data = map { my %unit = %$_; warn dump @unit{qw/cds artistid/}; warn dump %unit; } @$data;
1300
1301         die "Void mode not supported yet :)";
1302
1303     #$self->result_source->storage->insert_bulk($self->result_source, \@names, $data);
1304   }
1305 }
1306
1307 =head2 pager
1308
1309 =over 4
1310
1311 =item Arguments: none
1312
1313 =item Return Value: $pager
1314
1315 =back
1316
1317 Return Value a L<Data::Page> object for the current resultset. Only makes
1318 sense for queries with a C<page> attribute.
1319
1320 =cut
1321
1322 sub pager {
1323   my ($self) = @_;
1324   my $attrs = $self->{attrs};
1325   $self->throw_exception("Can't create pager for non-paged rs")
1326     unless $self->{attrs}{page};
1327   $attrs->{rows} ||= 10;
1328   return $self->{pager} ||= Data::Page->new(
1329     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1330 }
1331
1332 =head2 page
1333
1334 =over 4
1335
1336 =item Arguments: $page_number
1337
1338 =item Return Value: $rs
1339
1340 =back
1341
1342 Returns a resultset for the $page_number page of the resultset on which page
1343 is called, where each page contains a number of rows equal to the 'rows'
1344 attribute set on the resultset (10 by default).
1345
1346 =cut
1347
1348 sub page {
1349   my ($self, $page) = @_;
1350   return (ref $self)->new($self->_source_handle, { %{$self->{attrs}}, page => $page });
1351 }
1352
1353 =head2 new_result
1354
1355 =over 4
1356
1357 =item Arguments: \%vals
1358
1359 =item Return Value: $object
1360
1361 =back
1362
1363 Creates an object in the resultset's result class and returns it.
1364
1365 =cut
1366
1367 sub new_result {
1368   my ($self, $values) = @_;
1369   $self->throw_exception( "new_result needs a hash" )
1370     unless (ref $values eq 'HASH');
1371   $self->throw_exception(
1372     "Can't abstract implicit construct, condition not a hash"
1373   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1374
1375   my $alias = $self->{attrs}{alias};
1376   my $collapsed_cond = $self->{cond} ? $self->_collapse_cond($self->{cond}) : {};
1377   my %new = (
1378     %{ $self->_remove_alias($values, $alias) },
1379     %{ $self->_remove_alias($collapsed_cond, $alias) },
1380     -source_handle => $self->_source_handle
1381   );
1382
1383   return $self->result_class->new(\%new);
1384 }
1385
1386 # _collapse_cond
1387 #
1388 # Recursively collapse the condition.
1389
1390 sub _collapse_cond {
1391   my ($self, $cond, $collapsed) = @_;
1392
1393   $collapsed ||= {};
1394
1395   if (ref $cond eq 'ARRAY') {
1396     foreach my $subcond (@$cond) {
1397       next unless ref $subcond;  # -or
1398 #      warn "ARRAY: " . Dumper $subcond;
1399       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1400     }
1401   }
1402   elsif (ref $cond eq 'HASH') {
1403     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1404       foreach my $subcond (@{$cond->{-and}}) {
1405 #        warn "HASH: " . Dumper $subcond;
1406         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1407       }
1408     }
1409     else {
1410 #      warn "LEAF: " . Dumper $cond;
1411       foreach my $col (keys %$cond) {
1412         my $value = $cond->{$col};
1413         $collapsed->{$col} = $value;
1414       }
1415     }
1416   }
1417
1418   return $collapsed;
1419 }
1420
1421 # _remove_alias
1422 #
1423 # Remove the specified alias from the specified query hash. A copy is made so
1424 # the original query is not modified.
1425
1426 sub _remove_alias {
1427   my ($self, $query, $alias) = @_;
1428
1429   my %orig = %{ $query || {} };
1430   my %unaliased;
1431
1432   foreach my $key (keys %orig) {
1433     if ($key !~ /\./) {
1434       $unaliased{$key} = $orig{$key};
1435       next;
1436     }
1437     $unaliased{$1} = $orig{$key}
1438       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1439   }
1440
1441   return \%unaliased;
1442 }
1443
1444 =head2 find_or_new
1445
1446 =over 4
1447
1448 =item Arguments: \%vals, \%attrs?
1449
1450 =item Return Value: $object
1451
1452 =back
1453
1454 Find an existing record from this resultset. If none exists, instantiate a new
1455 result object and return it. The object will not be saved into your storage
1456 until you call L<DBIx::Class::Row/insert> on it.
1457
1458 If you want objects to be saved immediately, use L</find_or_create> instead.
1459
1460 =cut
1461
1462 sub find_or_new {
1463   my $self     = shift;
1464   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1465   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1466   my $exists   = $self->find($hash, $attrs);
1467   return defined $exists ? $exists : $self->new_result($hash);
1468 }
1469
1470 =head2 create
1471
1472 =over 4
1473
1474 =item Arguments: \%vals
1475
1476 =item Return Value: $object
1477
1478 =back
1479
1480 Inserts a record into the resultset and returns the object representing it.
1481
1482 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1483
1484 =cut
1485
1486 sub create {
1487   my ($self, $attrs) = @_;
1488   $self->throw_exception( "create needs a hashref" )
1489     unless ref $attrs eq 'HASH';
1490   return $self->new_result($attrs)->insert;
1491 }
1492
1493 =head2 find_or_create
1494
1495 =over 4
1496
1497 =item Arguments: \%vals, \%attrs?
1498
1499 =item Return Value: $object
1500
1501 =back
1502
1503   $class->find_or_create({ key => $val, ... });
1504
1505 Tries to find a record based on its primary key or unique constraint; if none
1506 is found, creates one and returns that instead.
1507
1508   my $cd = $schema->resultset('CD')->find_or_create({
1509     cdid   => 5,
1510     artist => 'Massive Attack',
1511     title  => 'Mezzanine',
1512     year   => 2005,
1513   });
1514
1515 Also takes an optional C<key> attribute, to search by a specific key or unique
1516 constraint. For example:
1517
1518   my $cd = $schema->resultset('CD')->find_or_create(
1519     {
1520       artist => 'Massive Attack',
1521       title  => 'Mezzanine',
1522     },
1523     { key => 'cd_artist_title' }
1524   );
1525
1526 See also L</find> and L</update_or_create>. For information on how to declare
1527 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1528
1529 =cut
1530
1531 sub find_or_create {
1532   my $self     = shift;
1533   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1534   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1535   my $exists   = $self->find($hash, $attrs);
1536   return defined $exists ? $exists : $self->create($hash);
1537 }
1538
1539 =head2 update_or_create
1540
1541 =over 4
1542
1543 =item Arguments: \%col_values, { key => $unique_constraint }?
1544
1545 =item Return Value: $object
1546
1547 =back
1548
1549   $class->update_or_create({ col => $val, ... });
1550
1551 First, searches for an existing row matching one of the unique constraints
1552 (including the primary key) on the source of this resultset. If a row is
1553 found, updates it with the other given column values. Otherwise, creates a new
1554 row.
1555
1556 Takes an optional C<key> attribute to search on a specific unique constraint.
1557 For example:
1558
1559   # In your application
1560   my $cd = $schema->resultset('CD')->update_or_create(
1561     {
1562       artist => 'Massive Attack',
1563       title  => 'Mezzanine',
1564       year   => 1998,
1565     },
1566     { key => 'cd_artist_title' }
1567   );
1568
1569 If no C<key> is specified, it searches on all unique constraints defined on the
1570 source, including the primary key.
1571
1572 If the C<key> is specified as C<primary>, it searches only on the primary key.
1573
1574 See also L</find> and L</find_or_create>. For information on how to declare
1575 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1576
1577 =cut
1578
1579 sub update_or_create {
1580   my $self = shift;
1581   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1582   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1583
1584   my $row = $self->find($cond, $attrs);
1585   if (defined $row) {
1586     $row->update($cond);
1587     return $row;
1588   }
1589
1590   return $self->create($cond);
1591 }
1592
1593 =head2 get_cache
1594
1595 =over 4
1596
1597 =item Arguments: none
1598
1599 =item Return Value: \@cache_objects?
1600
1601 =back
1602
1603 Gets the contents of the cache for the resultset, if the cache is set.
1604
1605 =cut
1606
1607 sub get_cache {
1608   shift->{all_cache};
1609 }
1610
1611 =head2 set_cache
1612
1613 =over 4
1614
1615 =item Arguments: \@cache_objects
1616
1617 =item Return Value: \@cache_objects
1618
1619 =back
1620
1621 Sets the contents of the cache for the resultset. Expects an arrayref
1622 of objects of the same class as those produced by the resultset. Note that
1623 if the cache is set the resultset will return the cached objects rather
1624 than re-querying the database even if the cache attr is not set.
1625
1626 =cut
1627
1628 sub set_cache {
1629   my ( $self, $data ) = @_;
1630   $self->throw_exception("set_cache requires an arrayref")
1631       if defined($data) && (ref $data ne 'ARRAY');
1632   $self->{all_cache} = $data;
1633 }
1634
1635 =head2 clear_cache
1636
1637 =over 4
1638
1639 =item Arguments: none
1640
1641 =item Return Value: []
1642
1643 =back
1644
1645 Clears the cache for the resultset.
1646
1647 =cut
1648
1649 sub clear_cache {
1650   shift->set_cache(undef);
1651 }
1652
1653 =head2 related_resultset
1654
1655 =over 4
1656
1657 =item Arguments: $relationship_name
1658
1659 =item Return Value: $resultset
1660
1661 =back
1662
1663 Returns a related resultset for the supplied relationship name.
1664
1665   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1666
1667 =cut
1668
1669 sub related_resultset {
1670   my ($self, $rel) = @_;
1671
1672   $self->{related_resultsets} ||= {};
1673   return $self->{related_resultsets}{$rel} ||= do {
1674     my $rel_obj = $self->result_source->relationship_info($rel);
1675
1676     $self->throw_exception(
1677       "search_related: result source '" . $self->_source_handle->source_moniker .
1678         "' has no such relationship $rel")
1679       unless $rel_obj;
1680
1681     my ($from,$seen) = $self->_resolve_from($rel);
1682
1683     my $join_count = $seen->{$rel};
1684     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
1685
1686     $self->_source_handle->schema->resultset($rel_obj->{class})->search_rs(
1687       undef, {
1688         %{$self->{attrs}||{}},
1689         join => undef,
1690         prefetch => undef,
1691         select => undef,
1692         as => undef,
1693         alias => $alias,
1694         where => $self->{cond},
1695         seen_join => $seen,
1696         from => $from,
1697     });
1698   };
1699 }
1700
1701 sub _resolve_from {
1702   my ($self, $extra_join) = @_;
1703   my $source = $self->result_source;
1704   my $attrs = $self->{attrs};
1705
1706   my $from = $attrs->{from}
1707     || [ { $attrs->{alias} => $source->from } ];
1708
1709   my $seen = { %{$attrs->{seen_join}||{}} };
1710
1711   my $join = ($attrs->{join}
1712                ? [ $attrs->{join}, $extra_join ]
1713                : $extra_join);
1714   $from = [
1715     @$from,
1716     ($join ? $source->resolve_join($join, $attrs->{alias}, $seen) : ()),
1717   ];
1718
1719   return ($from,$seen);
1720 }
1721
1722 sub _resolved_attrs {
1723   my $self = shift;
1724   return $self->{_attrs} if $self->{_attrs};
1725
1726   my $attrs = { %{$self->{attrs}||{}} };
1727   my $source = $self->result_source;
1728   my $alias = $attrs->{alias};
1729
1730   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
1731   if ($attrs->{columns}) {
1732     delete $attrs->{as};
1733   } elsif (!$attrs->{select}) {
1734     $attrs->{columns} = [ $source->columns ];
1735   }
1736
1737   $attrs->{select} =
1738     ($attrs->{select}
1739       ? (ref $attrs->{select} eq 'ARRAY'
1740           ? [ @{$attrs->{select}} ]
1741           : [ $attrs->{select} ])
1742       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
1743     );
1744   $attrs->{as} =
1745     ($attrs->{as}
1746       ? (ref $attrs->{as} eq 'ARRAY'
1747           ? [ @{$attrs->{as}} ]
1748           : [ $attrs->{as} ])
1749       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
1750     );
1751
1752   my $adds;
1753   if ($adds = delete $attrs->{include_columns}) {
1754     $adds = [$adds] unless ref $adds eq 'ARRAY';
1755     push(@{$attrs->{select}}, @$adds);
1756     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
1757   }
1758   if ($adds = delete $attrs->{'+select'}) {
1759     $adds = [$adds] unless ref $adds eq 'ARRAY';
1760     push(@{$attrs->{select}},
1761            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
1762   }
1763   if (my $adds = delete $attrs->{'+as'}) {
1764     $adds = [$adds] unless ref $adds eq 'ARRAY';
1765     push(@{$attrs->{as}}, @$adds);
1766   }
1767
1768   $attrs->{from} ||= [ { 'me' => $source->from } ];
1769
1770   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
1771     my $join = delete $attrs->{join} || {};
1772
1773     if (defined $attrs->{prefetch}) {
1774       $join = $self->_merge_attr(
1775         $join, $attrs->{prefetch}
1776       );
1777     }
1778
1779     $attrs->{from} =   # have to copy here to avoid corrupting the original
1780       [
1781         @{$attrs->{from}},
1782         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
1783       ];
1784   }
1785
1786   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
1787   if ($attrs->{order_by}) {
1788     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
1789                            ? [ @{$attrs->{order_by}} ]
1790                            : [ $attrs->{order_by} ]);
1791   } else {
1792     $attrs->{order_by} = [];
1793   }
1794
1795   my $collapse = $attrs->{collapse} || {};
1796   if (my $prefetch = delete $attrs->{prefetch}) {
1797     $prefetch = $self->_merge_attr({}, $prefetch);
1798     my @pre_order;
1799     my $seen = $attrs->{seen_join} || {};
1800     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
1801       # bring joins back to level of current class
1802       my @prefetch = $source->resolve_prefetch(
1803         $p, $alias, $seen, \@pre_order, $collapse
1804       );
1805       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
1806       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
1807     }
1808     push(@{$attrs->{order_by}}, @pre_order);
1809   }
1810   $attrs->{collapse} = $collapse;
1811
1812   return $self->{_attrs} = $attrs;
1813 }
1814
1815 sub _merge_attr {
1816   my ($self, $a, $b) = @_;
1817   return $b unless defined($a);
1818   return $a unless defined($b);
1819
1820   if (ref $b eq 'HASH' && ref $a eq 'HASH') {
1821     foreach my $key (keys %{$b}) {
1822       if (exists $a->{$key}) {
1823         $a->{$key} = $self->_merge_attr($a->{$key}, $b->{$key});
1824       } else {
1825         $a->{$key} = $b->{$key};
1826       }
1827     }
1828     return $a;
1829   } else {
1830     $a = [$a] unless ref $a eq 'ARRAY';
1831     $b = [$b] unless ref $b eq 'ARRAY';
1832
1833     my $hash = {};
1834     my @array;
1835     foreach my $x ($a, $b) {
1836       foreach my $element (@{$x}) {
1837         if (ref $element eq 'HASH') {
1838           $hash = $self->_merge_attr($hash, $element);
1839         } elsif (ref $element eq 'ARRAY') {
1840           push(@array, @{$element});
1841         } else {
1842           push(@array, $element) unless $b == $x
1843             && grep { $_ eq $element } @array;
1844         }
1845       }
1846     }
1847
1848     @array = grep { !exists $hash->{$_} } @array;
1849
1850     return keys %{$hash}
1851       ? ( scalar(@array)
1852             ? [$hash, @array]
1853             : $hash
1854         )
1855       : \@array;
1856   }
1857 }
1858
1859 sub result_source {
1860     my $self = shift;
1861
1862     if (@_) {
1863         $self->_source_handle($_[0]->handle);
1864     } else {
1865         $self->_source_handle->resolve;
1866     }
1867 }
1868
1869 =head2 throw_exception
1870
1871 See L<DBIx::Class::Schema/throw_exception> for details.
1872
1873 =cut
1874
1875 sub throw_exception {
1876   my $self=shift;
1877   $self->_source_handle->schema->throw_exception(@_);
1878 }
1879
1880 # XXX: FIXME: Attributes docs need clearing up
1881
1882 =head1 ATTRIBUTES
1883
1884 The resultset takes various attributes that modify its behavior. Here's an
1885 overview of them:
1886
1887 =head2 order_by
1888
1889 =over 4
1890
1891 =item Value: ($order_by | \@order_by)
1892
1893 =back
1894
1895 Which column(s) to order the results by. This is currently passed
1896 through directly to SQL, so you can give e.g. C<year DESC> for a
1897 descending order on the column `year'.
1898
1899 Please note that if you have C<quote_char> enabled (see
1900 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
1901 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
1902 so you will need to manually quote things as appropriate.)
1903
1904 =head2 columns
1905
1906 =over 4
1907
1908 =item Value: \@columns
1909
1910 =back
1911
1912 Shortcut to request a particular set of columns to be retrieved.  Adds
1913 C<me.> onto the start of any column without a C<.> in it and sets C<select>
1914 from that, then auto-populates C<as> from C<select> as normal. (You may also
1915 use the C<cols> attribute, as in earlier versions of DBIC.)
1916
1917 =head2 include_columns
1918
1919 =over 4
1920
1921 =item Value: \@columns
1922
1923 =back
1924
1925 Shortcut to include additional columns in the returned results - for example
1926
1927   $schema->resultset('CD')->search(undef, {
1928     include_columns => ['artist.name'],
1929     join => ['artist']
1930   });
1931
1932 would return all CDs and include a 'name' column to the information
1933 passed to object inflation. Note that the 'artist' is the name of the
1934 column (or relationship) accessor, and 'name' is the name of the column
1935 accessor in the related table.
1936
1937 =head2 select
1938
1939 =over 4
1940
1941 =item Value: \@select_columns
1942
1943 =back
1944
1945 Indicates which columns should be selected from the storage. You can use
1946 column names, or in the case of RDBMS back ends, function or stored procedure
1947 names:
1948
1949   $rs = $schema->resultset('Employee')->search(undef, {
1950     select => [
1951       'name',
1952       { count => 'employeeid' },
1953       { sum => 'salary' }
1954     ]
1955   });
1956
1957 When you use function/stored procedure names and do not supply an C<as>
1958 attribute, the column names returned are storage-dependent. E.g. MySQL would
1959 return a column named C<count(employeeid)> in the above example.
1960
1961 =head2 +select
1962
1963 =over 4
1964
1965 Indicates additional columns to be selected from storage.  Works the same as
1966 L<select> but adds columns to the selection.
1967
1968 =back
1969
1970 =head2 +as
1971
1972 =over 4
1973
1974 Indicates additional column names for those added via L<+select>.
1975
1976 =back
1977
1978 =head2 as
1979
1980 =over 4
1981
1982 =item Value: \@inflation_names
1983
1984 =back
1985
1986 Indicates column names for object inflation. That is, c< as >
1987 indicates the name that the column can be accessed as via the
1988 C<get_column> method (or via the object accessor, B<if one already
1989 exists>).  It has nothing to do with the SQL code C< SELECT foo AS bar
1990 >.
1991
1992 The C< as > attribute is used in conjunction with C<select>,
1993 usually when C<select> contains one or more function or stored
1994 procedure names:
1995
1996   $rs = $schema->resultset('Employee')->search(undef, {
1997     select => [
1998       'name',
1999       { count => 'employeeid' }
2000     ],
2001     as => ['name', 'employee_count'],
2002   });
2003
2004   my $employee = $rs->first(); # get the first Employee
2005
2006 If the object against which the search is performed already has an accessor
2007 matching a column name specified in C<as>, the value can be retrieved using
2008 the accessor as normal:
2009
2010   my $name = $employee->name();
2011
2012 If on the other hand an accessor does not exist in the object, you need to
2013 use C<get_column> instead:
2014
2015   my $employee_count = $employee->get_column('employee_count');
2016
2017 You can create your own accessors if required - see
2018 L<DBIx::Class::Manual::Cookbook> for details.
2019
2020 Please note: This will NOT insert an C<AS employee_count> into the SQL
2021 statement produced, it is used for internal access only. Thus
2022 attempting to use the accessor in an C<order_by> clause or similar
2023 will fail miserably.
2024
2025 To get around this limitation, you can supply literal SQL to your
2026 C<select> attibute that contains the C<AS alias> text, eg:
2027
2028   select => [\'myfield AS alias']
2029
2030 =head2 join
2031
2032 =over 4
2033
2034 =item Value: ($rel_name | \@rel_names | \%rel_names)
2035
2036 =back
2037
2038 Contains a list of relationships that should be joined for this query.  For
2039 example:
2040
2041   # Get CDs by Nine Inch Nails
2042   my $rs = $schema->resultset('CD')->search(
2043     { 'artist.name' => 'Nine Inch Nails' },
2044     { join => 'artist' }
2045   );
2046
2047 Can also contain a hash reference to refer to the other relation's relations.
2048 For example:
2049
2050   package MyApp::Schema::Track;
2051   use base qw/DBIx::Class/;
2052   __PACKAGE__->table('track');
2053   __PACKAGE__->add_columns(qw/trackid cd position title/);
2054   __PACKAGE__->set_primary_key('trackid');
2055   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2056   1;
2057
2058   # In your application
2059   my $rs = $schema->resultset('Artist')->search(
2060     { 'track.title' => 'Teardrop' },
2061     {
2062       join     => { cd => 'track' },
2063       order_by => 'artist.name',
2064     }
2065   );
2066
2067 You need to use the relationship (not the table) name in  conditions,
2068 because they are aliased as such. The current table is aliased as "me", so
2069 you need to use me.column_name in order to avoid ambiguity. For example:
2070
2071   # Get CDs from 1984 with a 'Foo' track
2072   my $rs = $schema->resultset('CD')->search(
2073     {
2074       'me.year' => 1984,
2075       'tracks.name' => 'Foo'
2076     },
2077     { join => 'tracks' }
2078   );
2079
2080 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2081 similarly for a third time). For e.g.
2082
2083   my $rs = $schema->resultset('Artist')->search({
2084     'cds.title'   => 'Down to Earth',
2085     'cds_2.title' => 'Popular',
2086   }, {
2087     join => [ qw/cds cds/ ],
2088   });
2089
2090 will return a set of all artists that have both a cd with title 'Down
2091 to Earth' and a cd with title 'Popular'.
2092
2093 If you want to fetch related objects from other tables as well, see C<prefetch>
2094 below.
2095
2096 =head2 prefetch
2097
2098 =over 4
2099
2100 =item Value: ($rel_name | \@rel_names | \%rel_names)
2101
2102 =back
2103
2104 Contains one or more relationships that should be fetched along with the main
2105 query (when they are accessed afterwards they will have already been
2106 "prefetched").  This is useful for when you know you will need the related
2107 objects, because it saves at least one query:
2108
2109   my $rs = $schema->resultset('Tag')->search(
2110     undef,
2111     {
2112       prefetch => {
2113         cd => 'artist'
2114       }
2115     }
2116   );
2117
2118 The initial search results in SQL like the following:
2119
2120   SELECT tag.*, cd.*, artist.* FROM tag
2121   JOIN cd ON tag.cd = cd.cdid
2122   JOIN artist ON cd.artist = artist.artistid
2123
2124 L<DBIx::Class> has no need to go back to the database when we access the
2125 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2126 case.
2127
2128 Simple prefetches will be joined automatically, so there is no need
2129 for a C<join> attribute in the above search. If you're prefetching to
2130 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
2131 specify the join as well.
2132
2133 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2134 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2135 with an accessor type of 'single' or 'filter').
2136
2137 =head2 page
2138
2139 =over 4
2140
2141 =item Value: $page
2142
2143 =back
2144
2145 Makes the resultset paged and specifies the page to retrieve. Effectively
2146 identical to creating a non-pages resultset and then calling ->page($page)
2147 on it.
2148
2149 If L<rows> attribute is not specified it defualts to 10 rows per page.
2150
2151 =head2 rows
2152
2153 =over 4
2154
2155 =item Value: $rows
2156
2157 =back
2158
2159 Specifes the maximum number of rows for direct retrieval or the number of
2160 rows per page if the page attribute or method is used.
2161
2162 =head2 offset
2163
2164 =over 4
2165
2166 =item Value: $offset
2167
2168 =back
2169
2170 Specifies the (zero-based) row number for the  first row to be returned, or the
2171 of the first row of the first page if paging is used.
2172
2173 =head2 group_by
2174
2175 =over 4
2176
2177 =item Value: \@columns
2178
2179 =back
2180
2181 A arrayref of columns to group by. Can include columns of joined tables.
2182
2183   group_by => [qw/ column1 column2 ... /]
2184
2185 =head2 having
2186
2187 =over 4
2188
2189 =item Value: $condition
2190
2191 =back
2192
2193 HAVING is a select statement attribute that is applied between GROUP BY and
2194 ORDER BY. It is applied to the after the grouping calculations have been
2195 done.
2196
2197   having => { 'count(employee)' => { '>=', 100 } }
2198
2199 =head2 distinct
2200
2201 =over 4
2202
2203 =item Value: (0 | 1)
2204
2205 =back
2206
2207 Set to 1 to group by all columns.
2208
2209 =head2 where
2210
2211 =over 4
2212
2213 Adds to the WHERE clause.
2214
2215   # only return rows WHERE deleted IS NULL for all searches
2216   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2217
2218 Can be overridden by passing C<{ where => undef }> as an attribute
2219 to a resulset.
2220
2221 =back
2222
2223 =head2 cache
2224
2225 Set to 1 to cache search results. This prevents extra SQL queries if you
2226 revisit rows in your ResultSet:
2227
2228   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2229
2230   while( my $artist = $resultset->next ) {
2231     ... do stuff ...
2232   }
2233
2234   $rs->first; # without cache, this would issue a query
2235
2236 By default, searches are not cached.
2237
2238 For more examples of using these attributes, see
2239 L<DBIx::Class::Manual::Cookbook>.
2240
2241 =head2 from
2242
2243 =over 4
2244
2245 =item Value: \@from_clause
2246
2247 =back
2248
2249 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2250 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2251 clauses.
2252
2253 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2254
2255 C<join> will usually do what you need and it is strongly recommended that you
2256 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2257 And we really do mean "cannot", not just tried and failed. Attempting to use
2258 this because you're having problems with C<join> is like trying to use x86
2259 ASM because you've got a syntax error in your C. Trust us on this.
2260
2261 Now, if you're still really, really sure you need to use this (and if you're
2262 not 100% sure, ask the mailing list first), here's an explanation of how this
2263 works.
2264
2265 The syntax is as follows -
2266
2267   [
2268     { <alias1> => <table1> },
2269     [
2270       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2271       [], # nested JOIN (optional)
2272       { <table1.column1> => <table2.column2>, ... (more conditions) },
2273     ],
2274     # More of the above [ ] may follow for additional joins
2275   ]
2276
2277   <table1> <alias1>
2278   JOIN
2279     <table2> <alias2>
2280     [JOIN ...]
2281   ON <table1.column1> = <table2.column2>
2282   <more joins may follow>
2283
2284 An easy way to follow the examples below is to remember the following:
2285
2286     Anything inside "[]" is a JOIN
2287     Anything inside "{}" is a condition for the enclosing JOIN
2288
2289 The following examples utilize a "person" table in a family tree application.
2290 In order to express parent->child relationships, this table is self-joined:
2291
2292     # Person->belongs_to('father' => 'Person');
2293     # Person->belongs_to('mother' => 'Person');
2294
2295 C<from> can be used to nest joins. Here we return all children with a father,
2296 then search against all mothers of those children:
2297
2298   $rs = $schema->resultset('Person')->search(
2299       undef,
2300       {
2301           alias => 'mother', # alias columns in accordance with "from"
2302           from => [
2303               { mother => 'person' },
2304               [
2305                   [
2306                       { child => 'person' },
2307                       [
2308                           { father => 'person' },
2309                           { 'father.person_id' => 'child.father_id' }
2310                       ]
2311                   ],
2312                   { 'mother.person_id' => 'child.mother_id' }
2313               ],
2314           ]
2315       },
2316   );
2317
2318   # Equivalent SQL:
2319   # SELECT mother.* FROM person mother
2320   # JOIN (
2321   #   person child
2322   #   JOIN person father
2323   #   ON ( father.person_id = child.father_id )
2324   # )
2325   # ON ( mother.person_id = child.mother_id )
2326
2327 The type of any join can be controlled manually. To search against only people
2328 with a father in the person table, we could explicitly use C<INNER JOIN>:
2329
2330     $rs = $schema->resultset('Person')->search(
2331         undef,
2332         {
2333             alias => 'child', # alias columns in accordance with "from"
2334             from => [
2335                 { child => 'person' },
2336                 [
2337                     { father => 'person', -join_type => 'inner' },
2338                     { 'father.id' => 'child.father_id' }
2339                 ],
2340             ]
2341         },
2342     );
2343
2344     # Equivalent SQL:
2345     # SELECT child.* FROM person child
2346     # INNER JOIN person father ON child.father_id = father.id
2347
2348 =cut
2349
2350 1;