lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</first> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 =back
 706
 707 =cut
 708
 709 sub single {
 710   my ($self, $where) = @_;
 711   if(@_ > 2) {
 712       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 713   }
 714
 715   my $attrs = $self->_resolved_attrs_copy;
 716
 717   if ($where) {
 718     if (defined $attrs->{where}) {
 719       $attrs->{where} = {
 720         '-and' =>
 721             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 722                $where, delete $attrs->{where} ]
 723       };
 724     } else {
 725       $attrs->{where} = $where;
 726     }
 727   }
 728
 729 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 730 #  unless ($self->_is_unique_query($attrs->{where})) {
 731 #    carp "Query not guaranteed to return a single row"
 732 #      . "; please declare your unique constraints or use search instead";
 733 #  }
 734
 735   my @data = $self->result_source->storage->select_single(
 736     $attrs->{from}, $attrs->{select},
 737     $attrs->{where}, $attrs
 738   );
 739
 740   return (@data ? ($self->_construct_object(@data))[0] : undef);
 741 }
 742
 743
 744 # _is_unique_query
 745 #
 746 # Try to determine if the specified query is guaranteed to be unique, based on
 747 # the declared unique constraints.
 748
 749 sub _is_unique_query {
 750   my ($self, $query) = @_;
 751
 752   my $collapsed = $self->_collapse_query($query);
 753   my $alias = $self->{attrs}{alias};
 754
 755   foreach my $name ($self->result_source->unique_constraint_names) {
 756     my @unique_cols = map {
 757       "$alias.$_"
 758     } $self->result_source->unique_constraint_columns($name);
 759
 760     # Count the values for each unique column
 761     my %seen = map { $_ => 0 } @unique_cols;
 762
 763     foreach my $key (keys %$collapsed) {
 764       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 765       next unless exists $seen{$aliased};  # Additional constraints are okay
 766       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 767     }
 768
 769     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 770     return 1 unless grep { $_ != 1 } values %seen;
 771   }
 772
 773   return 0;
 774 }
 775
 776 # _collapse_query
 777 #
 778 # Recursively collapse the query, accumulating values for each column.
 779
 780 sub _collapse_query {
 781   my ($self, $query, $collapsed) = @_;
 782
 783   $collapsed ||= {};
 784
 785   if (ref $query eq 'ARRAY') {
 786     foreach my $subquery (@$query) {
 787       next unless ref $subquery;  # -or
 788       $collapsed = $self->_collapse_query($subquery, $collapsed);
 789     }
 790   }
 791   elsif (ref $query eq 'HASH') {
 792     if (keys %$query and (keys %$query)[0] eq '-and') {
 793       foreach my $subquery (@{$query->{-and}}) {
 794         $collapsed = $self->_collapse_query($subquery, $collapsed);
 795       }
 796     }
 797     else {
 798       foreach my $col (keys %$query) {
 799         my $value = $query->{$col};
 800         $collapsed->{$col}{$value}++;
 801       }
 802     }
 803   }
 804
 805   return $collapsed;
 806 }
 807
 808 =head2 get_column
 809
 810 =over 4
 811
 812 =item Arguments: $cond?
 813
 814 =item Return Value: $resultsetcolumn
 815
 816 =back
 817
 818   my $max_length = $rs->get_column('length')->max;
 819
 820 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 821
 822 =cut
 823
 824 sub get_column {
 825   my ($self, $column) = @_;
 826   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 827   return $new;
 828 }
 829
 830 =head2 search_like
 831
 832 =over 4
 833
 834 =item Arguments: $cond, \%attrs?
 835
 836 =item Return Value: $resultset (scalar context), @row_objs (list context)
 837
 838 =back
 839
 840   # WHERE title LIKE '%blue%'
 841   $cd_rs = $rs->search_like({ title => '%blue%'});
 842
 843 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 844 that this is simply a convenience method retained for ex Class::DBI users.
 845 You most likely want to use L</search> with specific operators.
 846
 847 For more information, see L<DBIx::Class::Manual::Cookbook>.
 848
 849 This method is deprecated and will be removed in 0.09. Use L</search()>
 850 instead. An example conversion is:
 851
 852   ->search_like({ foo => 'bar' });
 853
 854   # Becomes
 855
 856   ->search({ foo => { like => 'bar' } });
 857
 858 =cut
 859
 860 sub search_like {
 861   my $class = shift;
 862   carp (
 863     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 864    .' Instead use ->search({ x => { -like => "y%" } })'
 865    .' (note the outer pair of {}s - they are important!)'
 866   );
 867   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 868   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 869   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 870   return $class->search($query, { %$attrs });
 871 }
 872
 873 =head2 slice
 874
 875 =over 4
 876
 877 =item Arguments: $first, $last
 878
 879 =item Return Value: $resultset (scalar context), @row_objs (list context)
 880
 881 =back
 882
 883 Returns a resultset or object list representing a subset of elements from the
 884 resultset slice is called on. Indexes are from 0, i.e., to get the first
 885 three records, call:
 886
 887   my ($one, $two, $three) = $rs->slice(0, 2);
 888
 889 =cut
 890
 891 sub slice {
 892   my ($self, $min, $max) = @_;
 893   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 894   $attrs->{offset} = $self->{attrs}{offset} || 0;
 895   $attrs->{offset} += $min;
 896   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 897   return $self->search(undef(), $attrs);
 898   #my $slice = (ref $self)->new($self->result_source, $attrs);
 899   #return (wantarray ? $slice->all : $slice);
 900 }
 901
 902 =head2 next
 903
 904 =over 4
 905
 906 =item Arguments: none
 907
 908 =item Return Value: $result?
 909
 910 =back
 911
 912 Returns the next element in the resultset (C<undef> is there is none).
 913
 914 Can be used to efficiently iterate over records in the resultset:
 915
 916   my $rs = $schema->resultset('CD')->search;
 917   while (my $cd = $rs->next) {
 918     print $cd->title;
 919   }
 920
 921 Note that you need to store the resultset object, and call C<next> on it.
 922 Calling C<< resultset('Table')->next >> repeatedly will always return the
 923 first record from the resultset.
 924
 925 =cut
 926
 927 sub next {
 928   my ($self) = @_;
 929   if (my $cache = $self->get_cache) {
 930     $self->{all_cache_position} ||= 0;
 931     return $cache->[$self->{all_cache_position}++];
 932   }
 933   if ($self->{attrs}{cache}) {
 934     $self->{all_cache_position} = 1;
 935     return ($self->all)[0];
 936   }
 937   if ($self->{stashed_objects}) {
 938     my $obj = shift(@{$self->{stashed_objects}});
 939     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 940     return $obj;
 941   }
 942   my @row = (
 943     exists $self->{stashed_row}
 944       ? @{delete $self->{stashed_row}}
 945       : $self->cursor->next
 946   );
 947   return undef unless (@row);
 948   my ($row, @more) = $self->_construct_object(@row);
 949   $self->{stashed_objects} = \@more if @more;
 950   return $row;
 951 }
 952
 953 sub _construct_object {
 954   my ($self, @row) = @_;
 955   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 956   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 957   @new = $self->{_attrs}{record_filter}->(@new)
 958     if exists $self->{_attrs}{record_filter};
 959   return @new;
 960 }
 961
 962 sub _collapse_result {
 963   my ($self, $as_proto, $row) = @_;
 964
 965   my @copy = @$row;
 966
 967   # 'foo'         => [ undef, 'foo' ]
 968   # 'foo.bar'     => [ 'foo', 'bar' ]
 969   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 970
 971   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 972
 973   my %collapse = %{$self->{_attrs}{collapse}||{}};
 974
 975   my @pri_index;
 976
 977   # if we're doing collapsing (has_many prefetch) we need to grab records
 978   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 979   # we know we don't have to bother.
 980
 981   # the reason for not using the collapse stuff directly is because if you
 982   # had for e.g. two artists in a row with no cds, the collapse info for
 983   # both would be NULL (undef) so you'd lose the second artist
 984
 985   # store just the index so we can check the array positions from the row
 986   # without having to contruct the full hash
 987
 988   if (keys %collapse) {
 989     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 990     foreach my $i (0 .. $#construct_as) {
 991       next if defined($construct_as[$i][0]); # only self table
 992       if (delete $pri{$construct_as[$i][1]}) {
 993         push(@pri_index, $i);
 994       }
 995       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 996     }
 997   }
 998
 999   # no need to do an if, it'll be empty if @pri_index is empty anyway
1000
1001   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1002
1003   my @const_rows;
1004
1005   do { # no need to check anything at the front, we always want the first row
1006
1007     my %const;
1008
1009     foreach my $this_as (@construct_as) {
1010       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1011     }
1012
1013     push(@const_rows, \%const);
1014
1015   } until ( # no pri_index => no collapse => drop straight out
1016       !@pri_index
1017     or
1018       do { # get another row, stash it, drop out if different PK
1019
1020         @copy = $self->cursor->next;
1021         $self->{stashed_row} = \@copy;
1022
1023         # last thing in do block, counts as true if anything doesn't match
1024
1025         # check xor defined first for NULL vs. NOT NULL then if one is
1026         # defined the other must be so check string equality
1027
1028         grep {
1029           (defined $pri_vals{$_} ^ defined $copy[$_])
1030           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1031         } @pri_index;
1032       }
1033   );
1034
1035   my $alias = $self->{attrs}{alias};
1036   my $info = [];
1037
1038   my %collapse_pos;
1039
1040   my @const_keys;
1041
1042   foreach my $const (@const_rows) {
1043     scalar @const_keys or do {
1044       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1045     };
1046     foreach my $key (@const_keys) {
1047       if (length $key) {
1048         my $target = $info;
1049         my @parts = split(/\./, $key);
1050         my $cur = '';
1051         my $data = $const->{$key};
1052         foreach my $p (@parts) {
1053           $target = $target->[1]->{$p} ||= [];
1054           $cur .= ".${p}";
1055           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1056             # collapsing at this point and on final part
1057             my $pos = $collapse_pos{$cur};
1058             CK: foreach my $ck (@ckey) {
1059               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1060                 $collapse_pos{$cur} = $data;
1061                 delete @collapse_pos{ # clear all positioning for sub-entries
1062                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1063                 };
1064                 push(@$target, []);
1065                 last CK;
1066               }
1067             }
1068           }
1069           if (exists $collapse{$cur}) {
1070             $target = $target->[-1];
1071           }
1072         }
1073         $target->[0] = $data;
1074       } else {
1075         $info->[0] = $const->{$key};
1076       }
1077     }
1078   }
1079
1080   return $info;
1081 }
1082
1083 =head2 result_source
1084
1085 =over 4
1086
1087 =item Arguments: $result_source?
1088
1089 =item Return Value: $result_source
1090
1091 =back
1092
1093 An accessor for the primary ResultSource object from which this ResultSet
1094 is derived.
1095
1096 =head2 result_class
1097
1098 =over 4
1099
1100 =item Arguments: $result_class?
1101
1102 =item Return Value: $result_class
1103
1104 =back
1105
1106 An accessor for the class to use when creating row objects. Defaults to
1107 C<< result_source->result_class >> - which in most cases is the name of the
1108 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1109
1110 Note that changing the result_class will also remove any components
1111 that were originally loaded in the source class via
1112 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1113 in the original source class will not run.
1114
1115 =cut
1116
1117 sub result_class {
1118   my ($self, $result_class) = @_;
1119   if ($result_class) {
1120     $self->ensure_class_loaded($result_class);
1121     $self->_result_class($result_class);
1122   }
1123   $self->_result_class;
1124 }
1125
1126 =head2 count
1127
1128 =over 4
1129
1130 =item Arguments: $cond, \%attrs??
1131
1132 =item Return Value: $count
1133
1134 =back
1135
1136 Performs an SQL C<COUNT> with the same query as the resultset was built
1137 with to find the number of elements. Passing arguments is equivalent to
1138 C<< $rs->search ($cond, \%attrs)->count >>
1139
1140 =cut
1141
1142 sub count {
1143   my $self = shift;
1144   return $self->search(@_)->count if @_ and defined $_[0];
1145   return scalar @{ $self->get_cache } if $self->get_cache;
1146
1147   my $meth = $self->_has_attr (qw/prefetch collapse distinct group_by/)
1148     ? 'count_grouped'
1149     : 'count'
1150   ;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153   my $rsrc = $self->result_source;
1154
1155   return $rsrc->storage->$meth ($rsrc, $attrs);
1156 }
1157
1158 sub _bool {
1159   return 1;
1160 }
1161
1162 =head2 count_literal
1163
1164 =over 4
1165
1166 =item Arguments: $sql_fragment, @bind_values
1167
1168 =item Return Value: $count
1169
1170 =back
1171
1172 Counts the results in a literal query. Equivalent to calling L</search_literal>
1173 with the passed arguments, then L</count>.
1174
1175 =cut
1176
1177 sub count_literal { shift->search_literal(@_)->count; }
1178
1179 =head2 all
1180
1181 =over 4
1182
1183 =item Arguments: none
1184
1185 =item Return Value: @objects
1186
1187 =back
1188
1189 Returns all elements in the resultset. Called implicitly if the resultset
1190 is returned in list context.
1191
1192 =cut
1193
1194 sub all {
1195   my $self = shift;
1196   if(@_) {
1197       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1198   }
1199
1200   return @{ $self->get_cache } if $self->get_cache;
1201
1202   my @obj;
1203
1204   # TODO: don't call resolve here
1205   if (keys %{$self->_resolved_attrs->{collapse}}) {
1206 #  if ($self->{attrs}{prefetch}) {
1207       # Using $self->cursor->all is really just an optimisation.
1208       # If we're collapsing has_many prefetches it probably makes
1209       # very little difference, and this is cleaner than hacking
1210       # _construct_object to survive the approach
1211     my @row = $self->cursor->next;
1212     while (@row) {
1213       push(@obj, $self->_construct_object(@row));
1214       @row = (exists $self->{stashed_row}
1215                ? @{delete $self->{stashed_row}}
1216                : $self->cursor->next);
1217     }
1218   } else {
1219     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1220   }
1221
1222   $self->set_cache(\@obj) if $self->{attrs}{cache};
1223   return @obj;
1224 }
1225
1226 =head2 reset
1227
1228 =over 4
1229
1230 =item Arguments: none
1231
1232 =item Return Value: $self
1233
1234 =back
1235
1236 Resets the resultset's cursor, so you can iterate through the elements again.
1237
1238 =cut
1239
1240 sub reset {
1241   my ($self) = @_;
1242   delete $self->{_attrs} if exists $self->{_attrs};
1243   $self->{all_cache_position} = 0;
1244   $self->cursor->reset;
1245   return $self;
1246 }
1247
1248 =head2 first
1249
1250 =over 4
1251
1252 =item Arguments: none
1253
1254 =item Return Value: $object?
1255
1256 =back
1257
1258 Resets the resultset and returns an object for the first result (if the
1259 resultset returns anything).
1260
1261 =cut
1262
1263 sub first {
1264   return $_[0]->reset->next;
1265 }
1266
1267
1268 # _rs_update_delete
1269 #
1270 # Determines whether and what type of subquery is required for the $rs operation.
1271 # If grouping is necessary either supplies its own, or verifies the current one
1272 # After all is done delegates to the proper storage method.
1273
1274 sub _rs_update_delete {
1275   my ($self, $op, $values) = @_;
1276
1277   my $rsrc = $self->result_source;
1278
1279   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1280   my $needs_subq = $self->_has_attr (qw/row offset page/);
1281
1282   if ($needs_group_by_subq or $needs_subq) {
1283
1284     # make a new $rs selecting only the PKs (that's all we really need)
1285     my $attrs = $self->_resolved_attrs_copy;
1286
1287     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1288     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1289
1290     if ($needs_group_by_subq) {
1291       # make sure no group_by was supplied, or if there is one - make sure it matches
1292       # the columns compiled above perfectly. Anything else can not be sanely executed
1293       # on most databases so croak right then and there
1294
1295       if (my $g = $attrs->{group_by}) {
1296         my @current_group_by = map
1297           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1298           (ref $g eq 'ARRAY' ? @$g : $g );
1299
1300         if (
1301           join ("\x00", sort @current_group_by)
1302             ne
1303           join ("\x00", sort @{$attrs->{columns}} )
1304         ) {
1305           $self->throw_exception (
1306             "You have just attempted a $op operation on a resultset which does group_by"
1307             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1308             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1309             . ' kind of queries. Please retry the operation with a modified group_by or'
1310             . ' without using one at all.'
1311           );
1312         }
1313       }
1314       else {
1315         $attrs->{group_by} = $attrs->{columns};
1316       }
1317     }
1318
1319     my $subrs = (ref $self)->new($rsrc, $attrs);
1320
1321     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1322   }
1323   else {
1324     return $rsrc->storage->$op(
1325       $rsrc,
1326       $op eq 'update' ? $values : (),
1327       $self->_cond_for_update_delete,
1328     );
1329   }
1330 }
1331
1332
1333 # _cond_for_update_delete
1334 #
1335 # update/delete require the condition to be modified to handle
1336 # the differing SQL syntax available.  This transforms the $self->{cond}
1337 # appropriately, returning the new condition.
1338
1339 sub _cond_for_update_delete {
1340   my ($self, $full_cond) = @_;
1341   my $cond = {};
1342
1343   $full_cond ||= $self->{cond};
1344   # No-op. No condition, we're updating/deleting everything
1345   return $cond unless ref $full_cond;
1346
1347   if (ref $full_cond eq 'ARRAY') {
1348     $cond = [
1349       map {
1350         my %hash;
1351         foreach my $key (keys %{$_}) {
1352           $key =~ /([^.]+)$/;
1353           $hash{$1} = $_->{$key};
1354         }
1355         \%hash;
1356       } @{$full_cond}
1357     ];
1358   }
1359   elsif (ref $full_cond eq 'HASH') {
1360     if ((keys %{$full_cond})[0] eq '-and') {
1361       $cond->{-and} = [];
1362       my @cond = @{$full_cond->{-and}};
1363        for (my $i = 0; $i < @cond; $i++) {
1364         my $entry = $cond[$i];
1365         my $hash;
1366         if (ref $entry eq 'HASH') {
1367           $hash = $self->_cond_for_update_delete($entry);
1368         }
1369         else {
1370           $entry =~ /([^.]+)$/;
1371           $hash->{$1} = $cond[++$i];
1372         }
1373         push @{$cond->{-and}}, $hash;
1374       }
1375     }
1376     else {
1377       foreach my $key (keys %{$full_cond}) {
1378         $key =~ /([^.]+)$/;
1379         $cond->{$1} = $full_cond->{$key};
1380       }
1381     }
1382   }
1383   else {
1384     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1385   }
1386
1387   return $cond;
1388 }
1389
1390
1391 =head2 update
1392
1393 =over 4
1394
1395 =item Arguments: \%values
1396
1397 =item Return Value: $storage_rv
1398
1399 =back
1400
1401 Sets the specified columns in the resultset to the supplied values in a
1402 single query. Return value will be true if the update succeeded or false
1403 if no records were updated; exact type of success value is storage-dependent.
1404
1405 =cut
1406
1407 sub update {
1408   my ($self, $values) = @_;
1409   $self->throw_exception('Values for update must be a hash')
1410     unless ref $values eq 'HASH';
1411
1412   return $self->_rs_update_delete ('update', $values);
1413 }
1414
1415 =head2 update_all
1416
1417 =over 4
1418
1419 =item Arguments: \%values
1420
1421 =item Return Value: 1
1422
1423 =back
1424
1425 Fetches all objects and updates them one at a time. Note that C<update_all>
1426 will run DBIC cascade triggers, while L</update> will not.
1427
1428 =cut
1429
1430 sub update_all {
1431   my ($self, $values) = @_;
1432   $self->throw_exception('Values for update_all must be a hash')
1433     unless ref $values eq 'HASH';
1434   foreach my $obj ($self->all) {
1435     $obj->set_columns($values)->update;
1436   }
1437   return 1;
1438 }
1439
1440 =head2 delete
1441
1442 =over 4
1443
1444 =item Arguments: none
1445
1446 =item Return Value: $storage_rv
1447
1448 =back
1449
1450 Deletes the contents of the resultset from its result source. Note that this
1451 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1452 to run. See also L<DBIx::Class::Row/delete>.
1453
1454 Return value will be the amount of rows deleted; exact type of return value
1455 is storage-dependent.
1456
1457 =cut
1458
1459 sub delete {
1460   my $self = shift;
1461   $self->throw_exception('delete does not accept any arguments')
1462     if @_;
1463
1464   return $self->_rs_update_delete ('delete');
1465 }
1466
1467 =head2 delete_all
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: 1
1474
1475 =back
1476
1477 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1478 will run DBIC cascade triggers, while L</delete> will not.
1479
1480 =cut
1481
1482 sub delete_all {
1483   my $self = shift;
1484   $self->throw_exception('delete_all does not accept any arguments')
1485     if @_;
1486
1487   $_->delete for $self->all;
1488   return 1;
1489 }
1490
1491 =head2 populate
1492
1493 =over 4
1494
1495 =item Arguments: \@data;
1496
1497 =back
1498
1499 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1500 For the arrayref of hashrefs style each hashref should be a structure suitable
1501 forsubmitting to a $resultset->create(...) method.
1502
1503 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1504 to insert the data, as this is a faster method.
1505
1506 Otherwise, each set of data is inserted into the database using
1507 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1508 objects is returned.
1509
1510 Example:  Assuming an Artist Class that has many CDs Classes relating:
1511
1512   my $Artist_rs = $schema->resultset("Artist");
1513
1514   ## Void Context Example
1515   $Artist_rs->populate([
1516      { artistid => 4, name => 'Manufactured Crap', cds => [
1517         { title => 'My First CD', year => 2006 },
1518         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1519       ],
1520      },
1521      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1522         { title => 'My parents sold me to a record company' ,year => 2005 },
1523         { title => 'Why Am I So Ugly?', year => 2006 },
1524         { title => 'I Got Surgery and am now Popular', year => 2007 }
1525       ],
1526      },
1527   ]);
1528
1529   ## Array Context Example
1530   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1531     { name => "Artist One"},
1532     { name => "Artist Two"},
1533     { name => "Artist Three", cds=> [
1534     { title => "First CD", year => 2007},
1535     { title => "Second CD", year => 2008},
1536   ]}
1537   ]);
1538
1539   print $ArtistOne->name; ## response is 'Artist One'
1540   print $ArtistThree->cds->count ## reponse is '2'
1541
1542 For the arrayref of arrayrefs style,  the first element should be a list of the
1543 fieldsnames to which the remaining elements are rows being inserted.  For
1544 example:
1545
1546   $Arstist_rs->populate([
1547     [qw/artistid name/],
1548     [100, 'A Formally Unknown Singer'],
1549     [101, 'A singer that jumped the shark two albums ago'],
1550     [102, 'An actually cool singer.'],
1551   ]);
1552
1553 Please note an important effect on your data when choosing between void and
1554 wantarray context. Since void context goes straight to C<insert_bulk> in
1555 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1556 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1557 create primary keys for you, you will find that your PKs are empty.  In this
1558 case you will have to use the wantarray context in order to create those
1559 values.
1560
1561 =cut
1562
1563 sub populate {
1564   my $self = shift @_;
1565   my $data = ref $_[0][0] eq 'HASH'
1566     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1567     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1568
1569   if(defined wantarray) {
1570     my @created;
1571     foreach my $item (@$data) {
1572       push(@created, $self->create($item));
1573     }
1574     return @created;
1575   } else {
1576     my ($first, @rest) = @$data;
1577
1578     my @names = grep {!ref $first->{$_}} keys %$first;
1579     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1580     my @pks = $self->result_source->primary_columns;
1581
1582     ## do the belongs_to relationships
1583     foreach my $index (0..$#$data) {
1584
1585       # delegate to create() for any dataset without primary keys with specified relationships
1586       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1587         for my $r (@rels) {
1588           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1589             my @ret = $self->populate($data);
1590             return;
1591           }
1592         }
1593       }
1594
1595       foreach my $rel (@rels) {
1596         next unless ref $data->[$index]->{$rel} eq "HASH";
1597         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1598         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1599         my $related = $result->result_source->_resolve_condition(
1600           $result->result_source->relationship_info($reverse)->{cond},
1601           $self,
1602           $result,
1603         );
1604
1605         delete $data->[$index]->{$rel};
1606         $data->[$index] = {%{$data->[$index]}, %$related};
1607
1608         push @names, keys %$related if $index == 0;
1609       }
1610     }
1611
1612     ## do bulk insert on current row
1613     my @values = map { [ @$_{@names} ] } @$data;
1614
1615     $self->result_source->storage->insert_bulk(
1616       $self->result_source,
1617       \@names,
1618       \@values,
1619     );
1620
1621     ## do the has_many relationships
1622     foreach my $item (@$data) {
1623
1624       foreach my $rel (@rels) {
1625         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1626
1627         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1628      || $self->throw_exception('Cannot find the relating object.');
1629
1630         my $child = $parent->$rel;
1631
1632         my $related = $child->result_source->_resolve_condition(
1633           $parent->result_source->relationship_info($rel)->{cond},
1634           $child,
1635           $parent,
1636         );
1637
1638         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1639         my @populate = map { {%$_, %$related} } @rows_to_add;
1640
1641         $child->populate( \@populate );
1642       }
1643     }
1644   }
1645 }
1646
1647 =head2 _normalize_populate_args ($args)
1648
1649 Private method used by L</populate> to normalize its incoming arguments.  Factored
1650 out in case you want to subclass and accept new argument structures to the
1651 L</populate> method.
1652
1653 =cut
1654
1655 sub _normalize_populate_args {
1656   my ($self, $data) = @_;
1657   my @names = @{shift(@$data)};
1658   my @results_to_create;
1659   foreach my $datum (@$data) {
1660     my %result_to_create;
1661     foreach my $index (0..$#names) {
1662       $result_to_create{$names[$index]} = $$datum[$index];
1663     }
1664     push @results_to_create, \%result_to_create;
1665   }
1666   return \@results_to_create;
1667 }
1668
1669 =head2 pager
1670
1671 =over 4
1672
1673 =item Arguments: none
1674
1675 =item Return Value: $pager
1676
1677 =back
1678
1679 Return Value a L<Data::Page> object for the current resultset. Only makes
1680 sense for queries with a C<page> attribute.
1681
1682 To get the full count of entries for a paged resultset, call
1683 C<total_entries> on the L<Data::Page> object.
1684
1685 =cut
1686
1687 sub pager {
1688   my ($self) = @_;
1689
1690   return $self->{pager} if $self->{pager};
1691
1692   my $attrs = $self->{attrs};
1693   $self->throw_exception("Can't create pager for non-paged rs")
1694     unless $self->{attrs}{page};
1695   $attrs->{rows} ||= 10;
1696
1697   # throw away the paging flags and re-run the count (possibly
1698   # with a subselect) to get the real total count
1699   my $count_attrs = { %$attrs };
1700   delete $count_attrs->{$_} for qw/rows offset page pager/;
1701   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1702
1703   return $self->{pager} = Data::Page->new(
1704     $total_count,
1705     $attrs->{rows},
1706     $self->{attrs}{page}
1707   );
1708 }
1709
1710 =head2 page
1711
1712 =over 4
1713
1714 =item Arguments: $page_number
1715
1716 =item Return Value: $rs
1717
1718 =back
1719
1720 Returns a resultset for the $page_number page of the resultset on which page
1721 is called, where each page contains a number of rows equal to the 'rows'
1722 attribute set on the resultset (10 by default).
1723
1724 =cut
1725
1726 sub page {
1727   my ($self, $page) = @_;
1728   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1729 }
1730
1731 =head2 new_result
1732
1733 =over 4
1734
1735 =item Arguments: \%vals
1736
1737 =item Return Value: $rowobject
1738
1739 =back
1740
1741 Creates a new row object in the resultset's result class and returns
1742 it. The row is not inserted into the database at this point, call
1743 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1744 will tell you whether the row object has been inserted or not.
1745
1746 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1747
1748 =cut
1749
1750 sub new_result {
1751   my ($self, $values) = @_;
1752   $self->throw_exception( "new_result needs a hash" )
1753     unless (ref $values eq 'HASH');
1754
1755   my %new;
1756   my $alias = $self->{attrs}{alias};
1757
1758   if (
1759     defined $self->{cond}
1760     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1761   ) {
1762     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1763     $new{-from_resultset} = [ keys %new ] if keys %new;
1764   } else {
1765     $self->throw_exception(
1766       "Can't abstract implicit construct, condition not a hash"
1767     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1768
1769     my $collapsed_cond = (
1770       $self->{cond}
1771         ? $self->_collapse_cond($self->{cond})
1772         : {}
1773     );
1774
1775     # precendence must be given to passed values over values inherited from
1776     # the cond, so the order here is important.
1777     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1778     while( my($col,$value) = each %implied ){
1779       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1780         $new{$col} = $value->{'='};
1781         next;
1782       }
1783       $new{$col} = $value if $self->_is_deterministic_value($value);
1784     }
1785   }
1786
1787   %new = (
1788     %new,
1789     %{ $self->_remove_alias($values, $alias) },
1790     -source_handle => $self->_source_handle,
1791     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1792   );
1793
1794   return $self->result_class->new(\%new);
1795 }
1796
1797 # _is_deterministic_value
1798 #
1799 # Make an effor to strip non-deterministic values from the condition,
1800 # to make sure new_result chokes less
1801
1802 sub _is_deterministic_value {
1803   my $self = shift;
1804   my $value = shift;
1805   my $ref_type = ref $value;
1806   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1807   return 1 if Scalar::Util::blessed($value);
1808   return 0;
1809 }
1810
1811 # _has_attr
1812 #
1813 # determines if the resultset defines at least one
1814 # of the attributes supplied
1815 #
1816 # used to determine if a subquery is neccessary
1817
1818 sub _has_attr {
1819   my ($self, @attr_names) = @_;
1820
1821   my $attrs = $self->_resolved_attrs;
1822
1823   my $join_check_req;
1824
1825   for my $n (@attr_names) {
1826     ++$join_check_req if $n =~ /join/;
1827
1828     my $attr =  $attrs->{$n};
1829
1830     next if not defined $attr;
1831
1832     if (ref $attr eq 'HASH') {
1833       return 1 if keys %$attr;
1834     }
1835     elsif (ref $attr eq 'ARRAY') {
1836       return 1 if @$attr;
1837     }
1838     else {
1839       return 1 if $attr;
1840     }
1841   }
1842
1843   # a join can be expressed as a multi-level from
1844   return 1 if (
1845     $join_check_req
1846       and
1847     ref $attrs->{from} eq 'ARRAY'
1848       and
1849     @{$attrs->{from}} > 1
1850   );
1851
1852   return 0;
1853 }
1854
1855 # _collapse_cond
1856 #
1857 # Recursively collapse the condition.
1858
1859 sub _collapse_cond {
1860   my ($self, $cond, $collapsed) = @_;
1861
1862   $collapsed ||= {};
1863
1864   if (ref $cond eq 'ARRAY') {
1865     foreach my $subcond (@$cond) {
1866       next unless ref $subcond;  # -or
1867       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1868     }
1869   }
1870   elsif (ref $cond eq 'HASH') {
1871     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1872       foreach my $subcond (@{$cond->{-and}}) {
1873         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1874       }
1875     }
1876     else {
1877       foreach my $col (keys %$cond) {
1878         my $value = $cond->{$col};
1879         $collapsed->{$col} = $value;
1880       }
1881     }
1882   }
1883
1884   return $collapsed;
1885 }
1886
1887 # _remove_alias
1888 #
1889 # Remove the specified alias from the specified query hash. A copy is made so
1890 # the original query is not modified.
1891
1892 sub _remove_alias {
1893   my ($self, $query, $alias) = @_;
1894
1895   my %orig = %{ $query || {} };
1896   my %unaliased;
1897
1898   foreach my $key (keys %orig) {
1899     if ($key !~ /\./) {
1900       $unaliased{$key} = $orig{$key};
1901       next;
1902     }
1903     $unaliased{$1} = $orig{$key}
1904       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1905   }
1906
1907   return \%unaliased;
1908 }
1909
1910 =head2 as_query (EXPERIMENTAL)
1911
1912 =over 4
1913
1914 =item Arguments: none
1915
1916 =item Return Value: \[ $sql, @bind ]
1917
1918 =back
1919
1920 Returns the SQL query and bind vars associated with the invocant.
1921
1922 This is generally used as the RHS for a subquery.
1923
1924 B<NOTE>: This feature is still experimental.
1925
1926 =cut
1927
1928 sub as_query {
1929   my $self = shift;
1930   return $self->result_source->storage->as_query($self->_resolved_attrs);
1931 }
1932
1933 =head2 find_or_new
1934
1935 =over 4
1936
1937 =item Arguments: \%vals, \%attrs?
1938
1939 =item Return Value: $rowobject
1940
1941 =back
1942
1943   my $artist = $schema->resultset('Artist')->find_or_new(
1944     { artist => 'fred' }, { key => 'artists' });
1945
1946   $cd->cd_to_producer->find_or_new({ producer => $producer },
1947                                    { key => 'primary });
1948
1949 Find an existing record from this resultset, based on its primary
1950 key, or a unique constraint. If none exists, instantiate a new result
1951 object and return it. The object will not be saved into your storage
1952 until you call L<DBIx::Class::Row/insert> on it.
1953
1954 You most likely want this method when looking for existing rows using
1955 a unique constraint that is not the primary key, or looking for
1956 related rows.
1957
1958 If you want objects to be saved immediately, use L</find_or_create> instead.
1959
1960 B<Note>: C<find_or_new> is probably not what you want when creating a
1961 new row in a table that uses primary keys supplied by the
1962 database. Passing in a primary key column with a value of I<undef>
1963 will cause L</find> to attempt to search for a row with a value of
1964 I<NULL>.
1965
1966 =cut
1967
1968 sub find_or_new {
1969   my $self     = shift;
1970   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1971   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1972   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
1973     return $row;
1974   }
1975   return $self->new_result($hash);
1976 }
1977
1978 =head2 create
1979
1980 =over 4
1981
1982 =item Arguments: \%vals
1983
1984 =item Return Value: a L<DBIx::Class::Row> $object
1985
1986 =back
1987
1988 Attempt to create a single new row or a row with multiple related rows
1989 in the table represented by the resultset (and related tables). This
1990 will not check for duplicate rows before inserting, use
1991 L</find_or_create> to do that.
1992
1993 To create one row for this resultset, pass a hashref of key/value
1994 pairs representing the columns of the table and the values you wish to
1995 store. If the appropriate relationships are set up, foreign key fields
1996 can also be passed an object representing the foreign row, and the
1997 value will be set to its primary key.
1998
1999 To create related objects, pass a hashref for the value if the related
2000 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2001 and use the name of the relationship as the key. (NOT the name of the field,
2002 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2003 of hashrefs containing the data for each of the rows to create in the foreign
2004 tables, again using the relationship name as the key.
2005
2006 Instead of hashrefs of plain related data (key/value pairs), you may
2007 also pass new or inserted objects. New objects (not inserted yet, see
2008 L</new>), will be inserted into their appropriate tables.
2009
2010 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2011
2012 Example of creating a new row.
2013
2014   $person_rs->create({
2015     name=>"Some Person",
2016     email=>"somebody@someplace.com"
2017   });
2018
2019 Example of creating a new row and also creating rows in a related C<has_many>
2020 or C<has_one> resultset.  Note Arrayref.
2021
2022   $artist_rs->create(
2023      { artistid => 4, name => 'Manufactured Crap', cds => [
2024         { title => 'My First CD', year => 2006 },
2025         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2026       ],
2027      },
2028   );
2029
2030 Example of creating a new row and also creating a row in a related
2031 C<belongs_to>resultset. Note Hashref.
2032
2033   $cd_rs->create({
2034     title=>"Music for Silly Walks",
2035     year=>2000,
2036     artist => {
2037       name=>"Silly Musician",
2038     }
2039   });
2040
2041 =cut
2042
2043 sub create {
2044   my ($self, $attrs) = @_;
2045   $self->throw_exception( "create needs a hashref" )
2046     unless ref $attrs eq 'HASH';
2047   return $self->new_result($attrs)->insert;
2048 }
2049
2050 =head2 find_or_create
2051
2052 =over 4
2053
2054 =item Arguments: \%vals, \%attrs?
2055
2056 =item Return Value: $rowobject
2057
2058 =back
2059
2060   $cd->cd_to_producer->find_or_create({ producer => $producer },
2061                                       { key => 'primary });
2062
2063 Tries to find a record based on its primary key or unique constraints; if none
2064 is found, creates one and returns that instead.
2065
2066   my $cd = $schema->resultset('CD')->find_or_create({
2067     cdid   => 5,
2068     artist => 'Massive Attack',
2069     title  => 'Mezzanine',
2070     year   => 2005,
2071   });
2072
2073 Also takes an optional C<key> attribute, to search by a specific key or unique
2074 constraint. For example:
2075
2076   my $cd = $schema->resultset('CD')->find_or_create(
2077     {
2078       artist => 'Massive Attack',
2079       title  => 'Mezzanine',
2080     },
2081     { key => 'cd_artist_title' }
2082   );
2083
2084 B<Note>: Because find_or_create() reads from the database and then
2085 possibly inserts based on the result, this method is subject to a race
2086 condition. Another process could create a record in the table after
2087 the find has completed and before the create has started. To avoid
2088 this problem, use find_or_create() inside a transaction.
2089
2090 B<Note>: C<find_or_create> is probably not what you want when creating
2091 a new row in a table that uses primary keys supplied by the
2092 database. Passing in a primary key column with a value of I<undef>
2093 will cause L</find> to attempt to search for a row with a value of
2094 I<NULL>.
2095
2096 See also L</find> and L</update_or_create>. For information on how to declare
2097 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2098
2099 =cut
2100
2101 sub find_or_create {
2102   my $self     = shift;
2103   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2104   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2105   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2106     return $row;
2107   }
2108   return $self->create($hash);
2109 }
2110
2111 =head2 update_or_create
2112
2113 =over 4
2114
2115 =item Arguments: \%col_values, { key => $unique_constraint }?
2116
2117 =item Return Value: $rowobject
2118
2119 =back
2120
2121   $resultset->update_or_create({ col => $val, ... });
2122
2123 First, searches for an existing row matching one of the unique constraints
2124 (including the primary key) on the source of this resultset. If a row is
2125 found, updates it with the other given column values. Otherwise, creates a new
2126 row.
2127
2128 Takes an optional C<key> attribute to search on a specific unique constraint.
2129 For example:
2130
2131   # In your application
2132   my $cd = $schema->resultset('CD')->update_or_create(
2133     {
2134       artist => 'Massive Attack',
2135       title  => 'Mezzanine',
2136       year   => 1998,
2137     },
2138     { key => 'cd_artist_title' }
2139   );
2140
2141   $cd->cd_to_producer->update_or_create({
2142     producer => $producer,
2143     name => 'harry',
2144   }, {
2145     key => 'primary,
2146   });
2147
2148
2149 If no C<key> is specified, it searches on all unique constraints defined on the
2150 source, including the primary key.
2151
2152 If the C<key> is specified as C<primary>, it searches only on the primary key.
2153
2154 See also L</find> and L</find_or_create>. For information on how to declare
2155 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2156
2157 B<Note>: C<update_or_create> is probably not what you want when
2158 looking for a row in a table that uses primary keys supplied by the
2159 database, unless you actually have a key value. Passing in a primary
2160 key column with a value of I<undef> will cause L</find> to attempt to
2161 search for a row with a value of I<NULL>.
2162
2163 =cut
2164
2165 sub update_or_create {
2166   my $self = shift;
2167   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2168   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2169
2170   my $row = $self->find($cond, $attrs);
2171   if (defined $row) {
2172     $row->update($cond);
2173     return $row;
2174   }
2175
2176   return $self->create($cond);
2177 }
2178
2179 =head2 update_or_new
2180
2181 =over 4
2182
2183 =item Arguments: \%col_values, { key => $unique_constraint }?
2184
2185 =item Return Value: $rowobject
2186
2187 =back
2188
2189   $resultset->update_or_new({ col => $val, ... });
2190
2191 First, searches for an existing row matching one of the unique constraints
2192 (including the primary key) on the source of this resultset. If a row is
2193 found, updates it with the other given column values. Otherwise, instantiate
2194 a new result object and return it. The object will not be saved into your storage
2195 until you call L<DBIx::Class::Row/insert> on it.
2196
2197 Takes an optional C<key> attribute to search on a specific unique constraint.
2198 For example:
2199
2200   # In your application
2201   my $cd = $schema->resultset('CD')->update_or_new(
2202     {
2203       artist => 'Massive Attack',
2204       title  => 'Mezzanine',
2205       year   => 1998,
2206     },
2207     { key => 'cd_artist_title' }
2208   );
2209
2210   if ($cd->in_storage) {
2211       # the cd was updated
2212   }
2213   else {
2214       # the cd is not yet in the database, let's insert it
2215       $cd->insert;
2216   }
2217
2218 See also L</find>, L</find_or_create> and L<find_or_new>.
2219
2220 =cut
2221
2222 sub update_or_new {
2223     my $self  = shift;
2224     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2225     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2226
2227     my $row = $self->find( $cond, $attrs );
2228     if ( defined $row ) {
2229         $row->update($cond);
2230         return $row;
2231     }
2232
2233     return $self->new_result($cond);
2234 }
2235
2236 =head2 get_cache
2237
2238 =over 4
2239
2240 =item Arguments: none
2241
2242 =item Return Value: \@cache_objects?
2243
2244 =back
2245
2246 Gets the contents of the cache for the resultset, if the cache is set.
2247
2248 The cache is populated either by using the L</prefetch> attribute to
2249 L</search> or by calling L</set_cache>.
2250
2251 =cut
2252
2253 sub get_cache {
2254   shift->{all_cache};
2255 }
2256
2257 =head2 set_cache
2258
2259 =over 4
2260
2261 =item Arguments: \@cache_objects
2262
2263 =item Return Value: \@cache_objects
2264
2265 =back
2266
2267 Sets the contents of the cache for the resultset. Expects an arrayref
2268 of objects of the same class as those produced by the resultset. Note that
2269 if the cache is set the resultset will return the cached objects rather
2270 than re-querying the database even if the cache attr is not set.
2271
2272 The contents of the cache can also be populated by using the
2273 L</prefetch> attribute to L</search>.
2274
2275 =cut
2276
2277 sub set_cache {
2278   my ( $self, $data ) = @_;
2279   $self->throw_exception("set_cache requires an arrayref")
2280       if defined($data) && (ref $data ne 'ARRAY');
2281   $self->{all_cache} = $data;
2282 }
2283
2284 =head2 clear_cache
2285
2286 =over 4
2287
2288 =item Arguments: none
2289
2290 =item Return Value: []
2291
2292 =back
2293
2294 Clears the cache for the resultset.
2295
2296 =cut
2297
2298 sub clear_cache {
2299   shift->set_cache(undef);
2300 }
2301
2302 =head2 related_resultset
2303
2304 =over 4
2305
2306 =item Arguments: $relationship_name
2307
2308 =item Return Value: $resultset
2309
2310 =back
2311
2312 Returns a related resultset for the supplied relationship name.
2313
2314   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2315
2316 =cut
2317
2318 sub related_resultset {
2319   my ($self, $rel) = @_;
2320
2321   $self->{related_resultsets} ||= {};
2322   return $self->{related_resultsets}{$rel} ||= do {
2323     my $rel_obj = $self->result_source->relationship_info($rel);
2324
2325     $self->throw_exception(
2326       "search_related: result source '" . $self->result_source->source_name .
2327         "' has no such relationship $rel")
2328       unless $rel_obj;
2329
2330     my ($from,$seen) = $self->_resolve_from($rel);
2331
2332     my $join_count = $seen->{$rel};
2333     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2334
2335     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2336     my %attrs = %{$self->{attrs}||{}};
2337     delete @attrs{qw(result_class alias)};
2338
2339     my $new_cache;
2340
2341     if (my $cache = $self->get_cache) {
2342       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2343         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2344                         @$cache ];
2345       }
2346     }
2347
2348     my $rel_source = $self->result_source->related_source($rel);
2349
2350     my $new = do {
2351
2352       # The reason we do this now instead of passing the alias to the
2353       # search_rs below is that if you wrap/overload resultset on the
2354       # source you need to know what alias it's -going- to have for things
2355       # to work sanely (e.g. RestrictWithObject wants to be able to add
2356       # extra query restrictions, and these may need to be $alias.)
2357
2358       my $attrs = $rel_source->resultset_attributes;
2359       local $attrs->{alias} = $alias;
2360
2361       $rel_source->resultset
2362                  ->search_rs(
2363                      undef, {
2364                        %attrs,
2365                        join => undef,
2366                        prefetch => undef,
2367                        select => undef,
2368                        as => undef,
2369                        where => $self->{cond},
2370                        seen_join => $seen,
2371                        from => $from,
2372                    });
2373     };
2374     $new->set_cache($new_cache) if $new_cache;
2375     $new;
2376   };
2377 }
2378
2379 =head2 current_source_alias
2380
2381 =over 4
2382
2383 =item Arguments: none
2384
2385 =item Return Value: $source_alias
2386
2387 =back
2388
2389 Returns the current table alias for the result source this resultset is built
2390 on, that will be used in the SQL query. Usually it is C<me>.
2391
2392 Currently the source alias that refers to the result set returned by a
2393 L</search>/L</find> family method depends on how you got to the resultset: it's
2394 C<me> by default, but eg. L</search_related> aliases it to the related result
2395 source name (and keeps C<me> referring to the original result set). The long
2396 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2397 (and make this method unnecessary).
2398
2399 Thus it's currently necessary to use this method in predefined queries (see
2400 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2401 source alias of the current result set:
2402
2403   # in a result set class
2404   sub modified_by {
2405     my ($self, $user) = @_;
2406
2407     my $me = $self->current_source_alias;
2408
2409     return $self->search(
2410       "$me.modified" => $user->id,
2411     );
2412   }
2413
2414 =cut
2415
2416 sub current_source_alias {
2417   my ($self) = @_;
2418
2419   return ($self->{attrs} || {})->{alias} || 'me';
2420 }
2421
2422 # This code is called by search_related, and makes sure there
2423 # is clear separation between the joins before, during, and
2424 # after the relationship. This information is needed later
2425 # in order to properly resolve prefetch aliases (any alias
2426 # with a relation_chain_depth less than the depth of the
2427 # current prefetch is not considered)
2428 sub _resolve_from {
2429   my ($self, $extra_join) = @_;
2430   my $source = $self->result_source;
2431   my $attrs = $self->{attrs};
2432
2433   my $from = [ @{
2434       $attrs->{from}
2435         ||
2436       [{
2437         -result_source => $source,
2438         -alias => $attrs->{alias},
2439         $attrs->{alias} => $source->from,
2440       }]
2441   }];
2442
2443   my $seen = { %{$attrs->{seen_join} || {} } };
2444
2445   # we need to take the prefetch the attrs into account before we
2446   # ->_resolve_join as otherwise they get lost - captainL
2447   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2448
2449   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2450
2451   ++$seen->{-relation_chain_depth};
2452
2453   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2454
2455   ++$seen->{-relation_chain_depth};
2456
2457   return ($from,$seen);
2458 }
2459
2460 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2461 sub _resolved_attrs_copy {
2462   my $self = shift;
2463   return { %{$self->_resolved_attrs (@_)} };
2464 }
2465
2466 sub _resolved_attrs {
2467   my $self = shift;
2468   return $self->{_attrs} if $self->{_attrs};
2469
2470   my $attrs  = { %{ $self->{attrs} || {} } };
2471   my $source = $self->result_source;
2472   my $alias  = $attrs->{alias};
2473
2474   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2475   my @colbits;
2476
2477   # build columns (as long as select isn't set) into a set of as/select hashes
2478   unless ( $attrs->{select} ) {
2479       @colbits = map {
2480           ( ref($_) eq 'HASH' )
2481               ? $_
2482               : {
2483                   (
2484                     /^\Q${alias}.\E(.+)$/
2485                       ? "$1"
2486                       : "$_"
2487                   )
2488                 =>
2489                   (
2490                     /\./
2491                       ? "$_"
2492                       : "${alias}.$_"
2493                   )
2494             }
2495       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2496   }
2497   # add the additional columns on
2498   foreach ( 'include_columns', '+columns' ) {
2499       push @colbits, map {
2500           ( ref($_) eq 'HASH' )
2501             ? $_
2502             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2503       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2504   }
2505
2506   # start with initial select items
2507   if ( $attrs->{select} ) {
2508     $attrs->{select} =
2509         ( ref $attrs->{select} eq 'ARRAY' )
2510       ? [ @{ $attrs->{select} } ]
2511       : [ $attrs->{select} ];
2512     $attrs->{as} = (
2513       $attrs->{as}
2514       ? (
2515         ref $attrs->{as} eq 'ARRAY'
2516         ? [ @{ $attrs->{as} } ]
2517         : [ $attrs->{as} ]
2518         )
2519       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2520     );
2521   }
2522   else {
2523
2524     # otherwise we intialise select & as to empty
2525     $attrs->{select} = [];
2526     $attrs->{as}     = [];
2527   }
2528
2529   # now add colbits to select/as
2530   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2531   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2532
2533   my $adds;
2534   if ( $adds = delete $attrs->{'+select'} ) {
2535     $adds = [$adds] unless ref $adds eq 'ARRAY';
2536     push(
2537       @{ $attrs->{select} },
2538       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2539     );
2540   }
2541   if ( $adds = delete $attrs->{'+as'} ) {
2542     $adds = [$adds] unless ref $adds eq 'ARRAY';
2543     push( @{ $attrs->{as} }, @$adds );
2544   }
2545
2546   $attrs->{from} ||= [ {
2547     -result_source => $source,
2548     -alias => $self->{attrs}{alias},
2549     $self->{attrs}{alias} => $source->from,
2550   } ];
2551
2552   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2553     my $join = delete $attrs->{join} || {};
2554
2555     if ( defined $attrs->{prefetch} ) {
2556       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2557
2558     }
2559
2560     $attrs->{from} =    # have to copy here to avoid corrupting the original
2561       [
2562       @{ $attrs->{from} },
2563       $source->_resolve_join(
2564         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2565       )
2566       ];
2567
2568   }
2569
2570   if ( $attrs->{order_by} ) {
2571     $attrs->{order_by} = (
2572       ref( $attrs->{order_by} ) eq 'ARRAY'
2573       ? [ @{ $attrs->{order_by} } ]
2574       : [ $attrs->{order_by} ]
2575     );
2576   }
2577   else {
2578     $attrs->{order_by} = [];
2579   }
2580
2581   # If the order_by is otherwise empty - we will use this for TOP limit
2582   # emulation and the like.
2583   # Although this is needed only if the order_by is not defined, it is
2584   # actually cheaper to just populate this rather than properly examining
2585   # order_by (stuf like [ {} ] and the like)
2586   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2587
2588
2589   my $collapse = $attrs->{collapse} || {};
2590   if ( my $prefetch = delete $attrs->{prefetch} ) {
2591     $prefetch = $self->_merge_attr( {}, $prefetch );
2592     my @pre_order;
2593     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2594
2595       # bring joins back to level of current class
2596       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2597       my @prefetch =
2598         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2599       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2600       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2601     }
2602     push( @{ $attrs->{order_by} }, @pre_order );
2603   }
2604
2605   if (delete $attrs->{distinct}) {
2606     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2607   }
2608
2609   $attrs->{collapse} = $collapse;
2610
2611   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2612     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2613   }
2614
2615   return $self->{_attrs} = $attrs;
2616 }
2617
2618 sub _joinpath_aliases {
2619   my ($self, $fromspec, $seen) = @_;
2620
2621   my $paths = {};
2622   return $paths unless ref $fromspec eq 'ARRAY';
2623
2624   for my $j (@$fromspec) {
2625
2626     next if ref $j ne 'ARRAY';
2627     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2628
2629     my $p = $paths;
2630     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2631     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2632   }
2633
2634   return $paths;
2635 }
2636
2637 sub _rollout_attr {
2638   my ($self, $attr) = @_;
2639
2640   if (ref $attr eq 'HASH') {
2641     return $self->_rollout_hash($attr);
2642   } elsif (ref $attr eq 'ARRAY') {
2643     return $self->_rollout_array($attr);
2644   } else {
2645     return [$attr];
2646   }
2647 }
2648
2649 sub _rollout_array {
2650   my ($self, $attr) = @_;
2651
2652   my @rolled_array;
2653   foreach my $element (@{$attr}) {
2654     if (ref $element eq 'HASH') {
2655       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2656     } elsif (ref $element eq 'ARRAY') {
2657       #  XXX - should probably recurse here
2658       push( @rolled_array, @{$self->_rollout_array($element)} );
2659     } else {
2660       push( @rolled_array, $element );
2661     }
2662   }
2663   return \@rolled_array;
2664 }
2665
2666 sub _rollout_hash {
2667   my ($self, $attr) = @_;
2668
2669   my @rolled_array;
2670   foreach my $key (keys %{$attr}) {
2671     push( @rolled_array, { $key => $attr->{$key} } );
2672   }
2673   return \@rolled_array;
2674 }
2675
2676 sub _calculate_score {
2677   my ($self, $a, $b) = @_;
2678
2679   if (ref $b eq 'HASH') {
2680     my ($b_key) = keys %{$b};
2681     if (ref $a eq 'HASH') {
2682       my ($a_key) = keys %{$a};
2683       if ($a_key eq $b_key) {
2684         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2685       } else {
2686         return 0;
2687       }
2688     } else {
2689       return ($a eq $b_key) ? 1 : 0;
2690     }
2691   } else {
2692     if (ref $a eq 'HASH') {
2693       my ($a_key) = keys %{$a};
2694       return ($b eq $a_key) ? 1 : 0;
2695     } else {
2696       return ($b eq $a) ? 1 : 0;
2697     }
2698   }
2699 }
2700
2701 sub _merge_attr {
2702   my ($self, $orig, $import) = @_;
2703
2704   return $import unless defined($orig);
2705   return $orig unless defined($import);
2706
2707   $orig = $self->_rollout_attr($orig);
2708   $import = $self->_rollout_attr($import);
2709
2710   my $seen_keys;
2711   foreach my $import_element ( @{$import} ) {
2712     # find best candidate from $orig to merge $b_element into
2713     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2714     foreach my $orig_element ( @{$orig} ) {
2715       my $score = $self->_calculate_score( $orig_element, $import_element );
2716       if ($score > $best_candidate->{score}) {
2717         $best_candidate->{position} = $position;
2718         $best_candidate->{score} = $score;
2719       }
2720       $position++;
2721     }
2722     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2723
2724     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2725       push( @{$orig}, $import_element );
2726     } else {
2727       my $orig_best = $orig->[$best_candidate->{position}];
2728       # merge orig_best and b_element together and replace original with merged
2729       if (ref $orig_best ne 'HASH') {
2730         $orig->[$best_candidate->{position}] = $import_element;
2731       } elsif (ref $import_element eq 'HASH') {
2732         my ($key) = keys %{$orig_best};
2733         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2734       }
2735     }
2736     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2737   }
2738
2739   return $orig;
2740 }
2741
2742 sub result_source {
2743     my $self = shift;
2744
2745     if (@_) {
2746         $self->_source_handle($_[0]->handle);
2747     } else {
2748         $self->_source_handle->resolve;
2749     }
2750 }
2751
2752 =head2 throw_exception
2753
2754 See L<DBIx::Class::Schema/throw_exception> for details.
2755
2756 =cut
2757
2758 sub throw_exception {
2759   my $self=shift;
2760   if (ref $self && $self->_source_handle->schema) {
2761     $self->_source_handle->schema->throw_exception(@_)
2762   } else {
2763     croak(@_);
2764   }
2765
2766 }
2767
2768 # XXX: FIXME: Attributes docs need clearing up
2769
2770 =head1 ATTRIBUTES
2771
2772 Attributes are used to refine a ResultSet in various ways when
2773 searching for data. They can be passed to any method which takes an
2774 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2775 L</count>.
2776
2777 These are in no particular order:
2778
2779 =head2 order_by
2780
2781 =over 4
2782
2783 =item Value: ( $order_by | \@order_by | \%order_by )
2784
2785 =back
2786
2787 Which column(s) to order the results by. If a single column name, or
2788 an arrayref of names is supplied, the argument is passed through
2789 directly to SQL. The hashref syntax allows for connection-agnostic
2790 specification of ordering direction:
2791
2792  For descending order:
2793
2794   order_by => { -desc => [qw/col1 col2 col3/] }
2795
2796  For explicit ascending order:
2797
2798   order_by => { -asc => 'col' }
2799
2800 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2801 supported, although you are strongly encouraged to use the hashref
2802 syntax as outlined above.
2803
2804 =head2 columns
2805
2806 =over 4
2807
2808 =item Value: \@columns
2809
2810 =back
2811
2812 Shortcut to request a particular set of columns to be retrieved. Each
2813 column spec may be a string (a table column name), or a hash (in which
2814 case the key is the C<as> value, and the value is used as the C<select>
2815 expression). Adds C<me.> onto the start of any column without a C<.> in
2816 it and sets C<select> from that, then auto-populates C<as> from
2817 C<select> as normal. (You may also use the C<cols> attribute, as in
2818 earlier versions of DBIC.)
2819
2820 =head2 +columns
2821
2822 =over 4
2823
2824 =item Value: \@columns
2825
2826 =back
2827
2828 Indicates additional columns to be selected from storage. Works the same
2829 as L</columns> but adds columns to the selection. (You may also use the
2830 C<include_columns> attribute, as in earlier versions of DBIC). For
2831 example:-
2832
2833   $schema->resultset('CD')->search(undef, {
2834     '+columns' => ['artist.name'],
2835     join => ['artist']
2836   });
2837
2838 would return all CDs and include a 'name' column to the information
2839 passed to object inflation. Note that the 'artist' is the name of the
2840 column (or relationship) accessor, and 'name' is the name of the column
2841 accessor in the related table.
2842
2843 =head2 include_columns
2844
2845 =over 4
2846
2847 =item Value: \@columns
2848
2849 =back
2850
2851 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2852
2853 =head2 select
2854
2855 =over 4
2856
2857 =item Value: \@select_columns
2858
2859 =back
2860
2861 Indicates which columns should be selected from the storage. You can use
2862 column names, or in the case of RDBMS back ends, function or stored procedure
2863 names:
2864
2865   $rs = $schema->resultset('Employee')->search(undef, {
2866     select => [
2867       'name',
2868       { count => 'employeeid' },
2869       { sum => 'salary' }
2870     ]
2871   });
2872
2873 When you use function/stored procedure names and do not supply an C<as>
2874 attribute, the column names returned are storage-dependent. E.g. MySQL would
2875 return a column named C<count(employeeid)> in the above example.
2876
2877 =head2 +select
2878
2879 =over 4
2880
2881 Indicates additional columns to be selected from storage.  Works the same as
2882 L</select> but adds columns to the selection.
2883
2884 =back
2885
2886 =head2 +as
2887
2888 =over 4
2889
2890 Indicates additional column names for those added via L</+select>. See L</as>.
2891
2892 =back
2893
2894 =head2 as
2895
2896 =over 4
2897
2898 =item Value: \@inflation_names
2899
2900 =back
2901
2902 Indicates column names for object inflation. That is, C<as>
2903 indicates the name that the column can be accessed as via the
2904 C<get_column> method (or via the object accessor, B<if one already
2905 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2906
2907 The C<as> attribute is used in conjunction with C<select>,
2908 usually when C<select> contains one or more function or stored
2909 procedure names:
2910
2911   $rs = $schema->resultset('Employee')->search(undef, {
2912     select => [
2913       'name',
2914       { count => 'employeeid' }
2915     ],
2916     as => ['name', 'employee_count'],
2917   });
2918
2919   my $employee = $rs->first(); # get the first Employee
2920
2921 If the object against which the search is performed already has an accessor
2922 matching a column name specified in C<as>, the value can be retrieved using
2923 the accessor as normal:
2924
2925   my $name = $employee->name();
2926
2927 If on the other hand an accessor does not exist in the object, you need to
2928 use C<get_column> instead:
2929
2930   my $employee_count = $employee->get_column('employee_count');
2931
2932 You can create your own accessors if required - see
2933 L<DBIx::Class::Manual::Cookbook> for details.
2934
2935 Please note: This will NOT insert an C<AS employee_count> into the SQL
2936 statement produced, it is used for internal access only. Thus
2937 attempting to use the accessor in an C<order_by> clause or similar
2938 will fail miserably.
2939
2940 To get around this limitation, you can supply literal SQL to your
2941 C<select> attibute that contains the C<AS alias> text, eg:
2942
2943   select => [\'myfield AS alias']
2944
2945 =head2 join
2946
2947 =over 4
2948
2949 =item Value: ($rel_name | \@rel_names | \%rel_names)
2950
2951 =back
2952
2953 Contains a list of relationships that should be joined for this query.  For
2954 example:
2955
2956   # Get CDs by Nine Inch Nails
2957   my $rs = $schema->resultset('CD')->search(
2958     { 'artist.name' => 'Nine Inch Nails' },
2959     { join => 'artist' }
2960   );
2961
2962 Can also contain a hash reference to refer to the other relation's relations.
2963 For example:
2964
2965   package MyApp::Schema::Track;
2966   use base qw/DBIx::Class/;
2967   __PACKAGE__->table('track');
2968   __PACKAGE__->add_columns(qw/trackid cd position title/);
2969   __PACKAGE__->set_primary_key('trackid');
2970   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2971   1;
2972
2973   # In your application
2974   my $rs = $schema->resultset('Artist')->search(
2975     { 'track.title' => 'Teardrop' },
2976     {
2977       join     => { cd => 'track' },
2978       order_by => 'artist.name',
2979     }
2980   );
2981
2982 You need to use the relationship (not the table) name in  conditions,
2983 because they are aliased as such. The current table is aliased as "me", so
2984 you need to use me.column_name in order to avoid ambiguity. For example:
2985
2986   # Get CDs from 1984 with a 'Foo' track
2987   my $rs = $schema->resultset('CD')->search(
2988     {
2989       'me.year' => 1984,
2990       'tracks.name' => 'Foo'
2991     },
2992     { join => 'tracks' }
2993   );
2994
2995 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2996 similarly for a third time). For e.g.
2997
2998   my $rs = $schema->resultset('Artist')->search({
2999     'cds.title'   => 'Down to Earth',
3000     'cds_2.title' => 'Popular',
3001   }, {
3002     join => [ qw/cds cds/ ],
3003   });
3004
3005 will return a set of all artists that have both a cd with title 'Down
3006 to Earth' and a cd with title 'Popular'.
3007
3008 If you want to fetch related objects from other tables as well, see C<prefetch>
3009 below.
3010
3011 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3012
3013 =head2 prefetch
3014
3015 =over 4
3016
3017 =item Value: ($rel_name | \@rel_names | \%rel_names)
3018
3019 =back
3020
3021 Contains one or more relationships that should be fetched along with
3022 the main query (when they are accessed afterwards the data will
3023 already be available, without extra queries to the database).  This is
3024 useful for when you know you will need the related objects, because it
3025 saves at least one query:
3026
3027   my $rs = $schema->resultset('Tag')->search(
3028     undef,
3029     {
3030       prefetch => {
3031         cd => 'artist'
3032       }
3033     }
3034   );
3035
3036 The initial search results in SQL like the following:
3037
3038   SELECT tag.*, cd.*, artist.* FROM tag
3039   JOIN cd ON tag.cd = cd.cdid
3040   JOIN artist ON cd.artist = artist.artistid
3041
3042 L<DBIx::Class> has no need to go back to the database when we access the
3043 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3044 case.
3045
3046 Simple prefetches will be joined automatically, so there is no need
3047 for a C<join> attribute in the above search.
3048
3049 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3050 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3051 with an accessor type of 'single' or 'filter'). A more complex example that
3052 prefetches an artists cds, the tracks on those cds, and the tags associted
3053 with that artist is given below (assuming many-to-many from artists to tags):
3054
3055  my $rs = $schema->resultset('Artist')->search(
3056    undef,
3057    {
3058      prefetch => [
3059        { cds => 'tracks' },
3060        { artist_tags => 'tags' }
3061      ]
3062    }
3063  );
3064
3065
3066 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3067 attributes will be ignored.
3068
3069 =head2 page
3070
3071 =over 4
3072
3073 =item Value: $page
3074
3075 =back
3076
3077 Makes the resultset paged and specifies the page to retrieve. Effectively
3078 identical to creating a non-pages resultset and then calling ->page($page)
3079 on it.
3080
3081 If L<rows> attribute is not specified it defualts to 10 rows per page.
3082
3083 When you have a paged resultset, L</count> will only return the number
3084 of rows in the page. To get the total, use the L</pager> and call
3085 C<total_entries> on it.
3086
3087 =head2 rows
3088
3089 =over 4
3090
3091 =item Value: $rows
3092
3093 =back
3094
3095 Specifes the maximum number of rows for direct retrieval or the number of
3096 rows per page if the page attribute or method is used.
3097
3098 =head2 offset
3099
3100 =over 4
3101
3102 =item Value: $offset
3103
3104 =back
3105
3106 Specifies the (zero-based) row number for the  first row to be returned, or the
3107 of the first row of the first page if paging is used.
3108
3109 =head2 group_by
3110
3111 =over 4
3112
3113 =item Value: \@columns
3114
3115 =back
3116
3117 A arrayref of columns to group by. Can include columns of joined tables.
3118
3119   group_by => [qw/ column1 column2 ... /]
3120
3121 =head2 having
3122
3123 =over 4
3124
3125 =item Value: $condition
3126
3127 =back
3128
3129 HAVING is a select statement attribute that is applied between GROUP BY and
3130 ORDER BY. It is applied to the after the grouping calculations have been
3131 done.
3132
3133   having => { 'count(employee)' => { '>=', 100 } }
3134
3135 =head2 distinct
3136
3137 =over 4
3138
3139 =item Value: (0 | 1)
3140
3141 =back
3142
3143 Set to 1 to group by all columns.
3144
3145 =head2 where
3146
3147 =over 4
3148
3149 Adds to the WHERE clause.
3150
3151   # only return rows WHERE deleted IS NULL for all searches
3152   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3153
3154 Can be overridden by passing C<{ where => undef }> as an attribute
3155 to a resulset.
3156
3157 =back
3158
3159 =head2 cache
3160
3161 Set to 1 to cache search results. This prevents extra SQL queries if you
3162 revisit rows in your ResultSet:
3163
3164   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3165
3166   while( my $artist = $resultset->next ) {
3167     ... do stuff ...
3168   }
3169
3170   $rs->first; # without cache, this would issue a query
3171
3172 By default, searches are not cached.
3173
3174 For more examples of using these attributes, see
3175 L<DBIx::Class::Manual::Cookbook>.
3176
3177 =head2 from
3178
3179 =over 4
3180
3181 =item Value: \@from_clause
3182
3183 =back
3184
3185 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3186 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3187 clauses.
3188
3189 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3190
3191 C<join> will usually do what you need and it is strongly recommended that you
3192 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3193 And we really do mean "cannot", not just tried and failed. Attempting to use
3194 this because you're having problems with C<join> is like trying to use x86
3195 ASM because you've got a syntax error in your C. Trust us on this.
3196
3197 Now, if you're still really, really sure you need to use this (and if you're
3198 not 100% sure, ask the mailing list first), here's an explanation of how this
3199 works.
3200
3201 The syntax is as follows -
3202
3203   [
3204     { <alias1> => <table1> },
3205     [
3206       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3207       [], # nested JOIN (optional)
3208       { <table1.column1> => <table2.column2>, ... (more conditions) },
3209     ],
3210     # More of the above [ ] may follow for additional joins
3211   ]
3212
3213   <table1> <alias1>
3214   JOIN
3215     <table2> <alias2>
3216     [JOIN ...]
3217   ON <table1.column1> = <table2.column2>
3218   <more joins may follow>
3219
3220 An easy way to follow the examples below is to remember the following:
3221
3222     Anything inside "[]" is a JOIN
3223     Anything inside "{}" is a condition for the enclosing JOIN
3224
3225 The following examples utilize a "person" table in a family tree application.
3226 In order to express parent->child relationships, this table is self-joined:
3227
3228     # Person->belongs_to('father' => 'Person');
3229     # Person->belongs_to('mother' => 'Person');
3230
3231 C<from> can be used to nest joins. Here we return all children with a father,
3232 then search against all mothers of those children:
3233
3234   $rs = $schema->resultset('Person')->search(
3235       undef,
3236       {
3237           alias => 'mother', # alias columns in accordance with "from"
3238           from => [
3239               { mother => 'person' },
3240               [
3241                   [
3242                       { child => 'person' },
3243                       [
3244                           { father => 'person' },
3245                           { 'father.person_id' => 'child.father_id' }
3246                       ]
3247                   ],
3248                   { 'mother.person_id' => 'child.mother_id' }
3249               ],
3250           ]
3251       },
3252   );
3253
3254   # Equivalent SQL:
3255   # SELECT mother.* FROM person mother
3256   # JOIN (
3257   #   person child
3258   #   JOIN person father
3259   #   ON ( father.person_id = child.father_id )
3260   # )
3261   # ON ( mother.person_id = child.mother_id )
3262
3263 The type of any join can be controlled manually. To search against only people
3264 with a father in the person table, we could explicitly use C<INNER JOIN>:
3265
3266     $rs = $schema->resultset('Person')->search(
3267         undef,
3268         {
3269             alias => 'child', # alias columns in accordance with "from"
3270             from => [
3271                 { child => 'person' },
3272                 [
3273                     { father => 'person', -join_type => 'inner' },
3274                     { 'father.id' => 'child.father_id' }
3275                 ],
3276             ]
3277         },
3278     );
3279
3280     # Equivalent SQL:
3281     # SELECT child.* FROM person child
3282     # INNER JOIN person father ON child.father_id = father.id
3283
3284 If you need to express really complex joins or you need a subselect, you
3285 can supply literal SQL to C<from> via a scalar reference. In this case
3286 the contents of the scalar will replace the table name asscoiated with the
3287 resultsource.
3288
3289 WARNING: This technique might very well not work as expected on chained
3290 searches - you have been warned.
3291
3292     # Assuming the Event resultsource is defined as:
3293
3294         MySchema::Event->add_columns (
3295             sequence => {
3296                 data_type => 'INT',
3297                 is_auto_increment => 1,
3298             },
3299             location => {
3300                 data_type => 'INT',
3301             },
3302             type => {
3303                 data_type => 'INT',
3304             },
3305         );
3306         MySchema::Event->set_primary_key ('sequence');
3307
3308     # This will get back the latest event for every location. The column
3309     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3310     # combo to limit the resultset
3311
3312     $rs = $schema->resultset('Event');
3313     $table = $rs->result_source->name;
3314     $latest = $rs->search (
3315         undef,
3316         { from => \ "
3317             (SELECT e1.* FROM $table e1
3318                 JOIN $table e2
3319                     ON e1.location = e2.location
3320                     AND e1.sequence < e2.sequence
3321                 WHERE e2.sequence is NULL
3322             ) me",
3323         },
3324     );
3325
3326     # Equivalent SQL (with the DBIC chunks added):
3327
3328     SELECT me.sequence, me.location, me.type FROM
3329        (SELECT e1.* FROM events e1
3330            JOIN events e2
3331                ON e1.location = e2.location
3332                AND e1.sequence < e2.sequence
3333            WHERE e2.sequence is NULL
3334        ) me;
3335
3336 =head2 for
3337
3338 =over 4
3339
3340 =item Value: ( 'update' | 'shared' )
3341
3342 =back
3343
3344 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3345 ... FOR SHARED.
3346
3347 =cut
3348
3349 1;