lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  30
  31 =head1 NAME
  32
  33 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  34
  35 =head1 SYNOPSIS
  36
  37   my $users_rs   = $schema->resultset('User');
  38   while( $user = $users_rs->next) {
  39     print $user->username;
  40   }
  41
  42   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  43   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  44
  45 =head1 DESCRIPTION
  46
  47 A ResultSet is an object which stores a set of conditions representing
  48 a query. It is the backbone of DBIx::Class (i.e. the really
  49 important/useful bit).
  50
  51 No SQL is executed on the database when a ResultSet is created, it
  52 just stores all the conditions needed to create the query.
  53
  54 A basic ResultSet representing the data of an entire table is returned
  55 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  56 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  57
  58   my $users_rs = $schema->resultset('User');
  59
  60 A new ResultSet is returned from calling L</search> on an existing
  61 ResultSet. The new one will contain all the conditions of the
  62 original, plus any new conditions added in the C<search> call.
  63
  64 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  65 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  66 represents.
  67
  68 The query that the ResultSet represents is B<only> executed against
  69 the database when these methods are called:
  70 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  71
  72 If a resultset is used in a numeric context it returns the L</count>.
  73 However, if it is used in a boolean context it is B<always> true.  So if
  74 you want to check if a resultset has any results, you must use C<if $rs
  75 != 0>.
  76
  77 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  78
  79 If you want to make your custom ResultSet classes with L<Moose>, use a template
  80 similar to:
  81
  82     package MyApp::Schema::ResultSet::User;
  83
  84     use Moose;
  85     use namespace::autoclean;
  86     use MooseX::NonMoose;
  87     extends 'DBIx::Class::ResultSet';
  88
  89     sub BUILDARGS { $_[2] }
  90
  91     ...your code...
  92
  93     __PACKAGE__->meta->make_immutable;
  94
  95     1;
  96
  97 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  98 clash with the regular ResultSet constructor. Alternatively, you can use:
  99
 100     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 101
 102 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 103 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 104
 105 =head1 EXAMPLES
 106
 107 =head2 Chaining resultsets
 108
 109 Let's say you've got a query that needs to be run to return some data
 110 to the user. But, you have an authorization system in place that
 111 prevents certain users from seeing certain information. So, you want
 112 to construct the basic query in one method, but add constraints to it in
 113 another.
 114
 115   sub get_data {
 116     my $self = shift;
 117     my $request = $self->get_request; # Get a request object somehow.
 118     my $schema = $self->result_source->schema;
 119
 120     my $cd_rs = $schema->resultset('CD')->search({
 121       title => $request->param('title'),
 122       year => $request->param('year'),
 123     });
 124
 125     $cd_rs = $self->apply_security_policy( $cd_rs );
 126
 127     return $cd_rs->all();
 128   }
 129
 130   sub apply_security_policy {
 131     my $self = shift;
 132     my ($rs) = @_;
 133
 134     return $rs->search({
 135       subversive => 0,
 136     });
 137   }
 138
 139 =head3 Resolving conditions and attributes
 140
 141 When a resultset is chained from another resultset, conditions and
 142 attributes with the same keys need resolving.
 143
 144 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 145 into the existing ones from the original resultset.
 146
 147 The L</where> and L</having> attributes, and any search conditions, are
 148 merged with an SQL C<AND> to the existing condition from the original
 149 resultset.
 150
 151 All other attributes are overridden by any new ones supplied in the
 152 search attributes.
 153
 154 =head2 Multiple queries
 155
 156 Since a resultset just defines a query, you can do all sorts of
 157 things with it with the same object.
 158
 159   # Don't hit the DB yet.
 160   my $cd_rs = $schema->resultset('CD')->search({
 161     title => 'something',
 162     year => 2009,
 163   });
 164
 165   # Each of these hits the DB individually.
 166   my $count = $cd_rs->count;
 167   my $most_recent = $cd_rs->get_column('date_released')->max();
 168   my @records = $cd_rs->all;
 169
 170 And it's not just limited to SELECT statements.
 171
 172   $cd_rs->delete();
 173
 174 This is even cooler:
 175
 176   $cd_rs->create({ artist => 'Fred' });
 177
 178 Which is the same as:
 179
 180   $schema->resultset('CD')->create({
 181     title => 'something',
 182     year => 2009,
 183     artist => 'Fred'
 184   });
 185
 186 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 187
 188 =head1 METHODS
 189
 190 =head2 new
 191
 192 =over 4
 193
 194 =item Arguments: $source, \%$attrs
 195
 196 =item Return Value: $rs
 197
 198 =back
 199
 200 The resultset constructor. Takes a source object (usually a
 201 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 202 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 203 executed as needed by the other methods.
 204
 205 Generally you won't need to construct a resultset manually.  You'll
 206 automatically get one from e.g. a L</search> called in scalar context:
 207
 208   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 209
 210 =over
 211
 212 =item WARNING
 213
 214 If called on an object, proxies to L</new_result> instead, so
 215
 216   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 217
 218 will return a CD object, not a ResultSet, and is equivalent to:
 219
 220   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 221
 222 Please also keep in mind that many internals call C<new_result> directly,
 223 so overloading this method with the idea of intercepting new result object
 224 creation B<will not work>. See also warning pertaining to L</create>.
 225
 226 =back
 227
 228 =cut
 229
 230 sub new {
 231   my $class = shift;
 232   return $class->new_result(@_) if ref $class;
 233
 234   my ($source, $attrs) = @_;
 235   $source = $source->resolve
 236     if $source->isa('DBIx::Class::ResultSourceHandle');
 237   $attrs = { %{$attrs||{}} };
 238
 239   if ($attrs->{page}) {
 240     $attrs->{rows} ||= 10;
 241   }
 242
 243   $attrs->{alias} ||= 'me';
 244
 245   my $self = bless {
 246     result_source => $source,
 247     cond => $attrs->{where},
 248     pager => undef,
 249     attrs => $attrs,
 250   }, $class;
 251
 252   # if there is a dark selector, this means we are already in a
 253   # chain and the cleanup/sanification was taken care of by
 254   # _search_rs already
 255   $self->_normalize_selection($attrs)
 256     unless $attrs->{_dark_selector};
 257
 258   $self->result_class(
 259     $attrs->{result_class} || $source->result_class
 260   );
 261
 262   $self;
 263 }
 264
 265 =head2 search
 266
 267 =over 4
 268
 269 =item Arguments: $cond, \%attrs?
 270
 271 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 272
 273 =back
 274
 275   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 276   my $new_rs = $cd_rs->search({ year => 2005 });
 277
 278   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 279                  # year = 2005 OR year = 2004
 280
 281 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 282 returning a list of row objects instead. To avoid that, use L</search_rs>.
 283
 284 If you need to pass in additional attributes but no additional condition,
 285 call it as C<search(undef, \%attrs)>.
 286
 287   # "SELECT name, artistid FROM $artist_table"
 288   my @all_artists = $schema->resultset('Artist')->search(undef, {
 289     columns => [qw/name artistid/],
 290   });
 291
 292 For a list of attributes that can be passed to C<search>, see
 293 L</ATTRIBUTES>. For more examples of using this function, see
 294 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 295 documentation for the first argument, see L<SQL::Abstract>
 296 and its extension L<DBIx::Class::SQLMaker>.
 297
 298 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 299
 300 =head3 CAVEAT
 301
 302 Note that L</search> does not process/deflate any of the values passed in the
 303 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 304 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 305 manually that any value passed to this method will stringify to something the
 306 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 307 objects, for more info see:
 308 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 309
 310 =cut
 311
 312 sub search {
 313   my $self = shift;
 314   my $rs = $self->search_rs( @_ );
 315
 316   if (wantarray) {
 317     return $rs->all;
 318   }
 319   elsif (defined wantarray) {
 320     return $rs;
 321   }
 322   else {
 323     # we can be called by a relationship helper, which in
 324     # turn may be called in void context due to some braindead
 325     # overload or whatever else the user decided to be clever
 326     # at this particular day. Thus limit the exception to
 327     # external code calls only
 328     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 329       if (caller)[0] !~ /^\QDBIx::Class::/;
 330
 331     return ();
 332   }
 333 }
 334
 335 =head2 search_rs
 336
 337 =over 4
 338
 339 =item Arguments: $cond, \%attrs?
 340
 341 =item Return Value: $resultset
 342
 343 =back
 344
 345 This method does the same exact thing as search() except it will
 346 always return a resultset, even in list context.
 347
 348 =cut
 349
 350 sub search_rs {
 351   my $self = shift;
 352
 353   # Special-case handling for (undef, undef).
 354   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 355     @_ = ();
 356   }
 357
 358   my $call_attrs = {};
 359   if (@_ > 1) {
 360     if (ref $_[-1] eq 'HASH') {
 361       # copy for _normalize_selection
 362       $call_attrs = { %{ pop @_ } };
 363     }
 364     elsif (! defined $_[-1] ) {
 365       pop @_;   # search({}, undef)
 366     }
 367   }
 368
 369   # see if we can keep the cache (no $rs changes)
 370   my $cache;
 371   my %safe = (alias => 1, cache => 1);
 372   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 373     ! defined $_[0]
 374       or
 375     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 376       or
 377     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 378   )) {
 379     $cache = $self->get_cache;
 380   }
 381
 382   my $rsrc = $self->result_source;
 383
 384   my $old_attrs = { %{$self->{attrs}} };
 385   my $old_having = delete $old_attrs->{having};
 386   my $old_where = delete $old_attrs->{where};
 387
 388   my $new_attrs = { %$old_attrs };
 389
 390   # take care of call attrs (only if anything is changing)
 391   if (keys %$call_attrs) {
 392
 393     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 394
 395     # reset the current selector list if new selectors are supplied
 396     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 397       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 398     }
 399
 400     # Normalize the new selector list (operates on the passed-in attr structure)
 401     # Need to do it on every chain instead of only once on _resolved_attrs, in
 402     # order to allow detection of empty vs partial 'as'
 403     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 404       if $old_attrs->{_dark_selector};
 405     $self->_normalize_selection ($call_attrs);
 406
 407     # start with blind overwriting merge, exclude selector attrs
 408     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 409     delete @{$new_attrs}{@selector_attrs};
 410
 411     for (@selector_attrs) {
 412       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 413         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 414     }
 415
 416     # older deprecated name, use only if {columns} is not there
 417     if (my $c = delete $new_attrs->{cols}) {
 418       if ($new_attrs->{columns}) {
 419         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 420       }
 421       else {
 422         $new_attrs->{columns} = $c;
 423       }
 424     }
 425
 426
 427     # join/prefetch use their own crazy merging heuristics
 428     foreach my $key (qw/join prefetch/) {
 429       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 430         if exists $call_attrs->{$key};
 431     }
 432
 433     # stack binds together
 434     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 435   }
 436
 437
 438   # rip apart the rest of @_, parse a condition
 439   my $call_cond = do {
 440
 441     if (ref $_[0] eq 'HASH') {
 442       (keys %{$_[0]}) ? $_[0] : undef
 443     }
 444     elsif (@_ == 1) {
 445       $_[0]
 446     }
 447     elsif (@_ % 2) {
 448       $self->throw_exception('Odd number of arguments to search')
 449     }
 450     else {
 451       +{ @_ }
 452     }
 453
 454   } if @_;
 455
 456   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 457     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 458   }
 459
 460   for ($old_where, $call_cond) {
 461     if (defined $_) {
 462       $new_attrs->{where} = $self->_stack_cond (
 463         $_, $new_attrs->{where}
 464       );
 465     }
 466   }
 467
 468   if (defined $old_having) {
 469     $new_attrs->{having} = $self->_stack_cond (
 470       $old_having, $new_attrs->{having}
 471     )
 472   }
 473
 474   my $rs = (ref $self)->new($rsrc, $new_attrs);
 475
 476   $rs->set_cache($cache) if ($cache);
 477
 478   return $rs;
 479 }
 480
 481 my $dark_sel_dumper;
 482 sub _normalize_selection {
 483   my ($self, $attrs) = @_;
 484
 485   # legacy syntax
 486   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 487     if exists $attrs->{include_columns};
 488
 489   # columns are always placed first, however
 490
 491   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 492   # delay the decision on whether to use a default select list ($rsrc->columns)
 493   # allowing stuff like the remove_columns helper to work
 494   #
 495   # select/as +select/+as pairs need special handling - the amount of select/as
 496   # elements in each pair does *not* have to be equal (think multicolumn
 497   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 498   # supplied at all) - try to infer the alias, either from the -as parameter
 499   # of the selector spec, or use the parameter whole if it looks like a column
 500   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 501   # is ok as well), but make sure no more additions to the 'as' chain take place
 502   for my $pref ('', '+') {
 503
 504     my ($sel, $as) = map {
 505       my $key = "${pref}${_}";
 506
 507       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 508         ? @{$attrs->{$key}}
 509         : $attrs->{$key} || ()
 510       ];
 511       delete $attrs->{$key};
 512       $val;
 513     } qw/select as/;
 514
 515     if (! @$as and ! @$sel ) {
 516       next;
 517     }
 518     elsif (@$as and ! @$sel) {
 519       $self->throw_exception(
 520         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 521       );
 522     }
 523     elsif( ! @$as ) {
 524       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 525       # if any @$as has been supplied we assume the user knows what (s)he is doing
 526       # and blindly keep stacking up pieces
 527       unless ($attrs->{_dark_selector}) {
 528         SELECTOR:
 529         for (@$sel) {
 530           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 531             push @$as, $_->{-as};
 532           }
 533           # assume any plain no-space, no-parenthesis string to be a column spec
 534           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 535           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 536             push @$as, $_;
 537           }
 538           # if all else fails - raise a flag that no more aliasing will be allowed
 539           else {
 540             $attrs->{_dark_selector} = {
 541               plus_stage => $pref,
 542               string => ($dark_sel_dumper ||= do {
 543                   require Data::Dumper::Concise;
 544                   Data::Dumper::Concise::DumperObject()->Indent(0);
 545                 })->Values([$_])->Dump
 546               ,
 547             };
 548             last SELECTOR;
 549           }
 550         }
 551       }
 552     }
 553     elsif (@$as < @$sel) {
 554       $self->throw_exception(
 555         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 556       );
 557     }
 558     elsif ($pref and $attrs->{_dark_selector}) {
 559       $self->throw_exception(
 560         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 561       );
 562     }
 563
 564
 565     # merge result
 566     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 567     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 568   }
 569 }
 570
 571 sub _stack_cond {
 572   my ($self, $left, $right) = @_;
 573
 574   # collapse single element top-level conditions
 575   # (single pass only, unlikely to need recursion)
 576   for ($left, $right) {
 577     if (ref $_ eq 'ARRAY') {
 578       if (@$_ == 0) {
 579         $_ = undef;
 580       }
 581       elsif (@$_ == 1) {
 582         $_ = $_->[0];
 583       }
 584     }
 585     elsif (ref $_ eq 'HASH') {
 586       my ($first, $more) = keys %$_;
 587
 588       # empty hash
 589       if (! defined $first) {
 590         $_ = undef;
 591       }
 592       # one element hash
 593       elsif (! defined $more) {
 594         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 595           $_ = $_->{'-and'};
 596         }
 597         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 598           $_ = $_->{'-or'};
 599         }
 600       }
 601     }
 602   }
 603
 604   # merge hashes with weeding out of duplicates (simple cases only)
 605   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 606
 607     # shallow copy to destroy
 608     $right = { %$right };
 609     for (grep { exists $right->{$_} } keys %$left) {
 610       # the use of eq_deeply here is justified - the rhs of an
 611       # expression can contain a lot of twisted weird stuff
 612       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 613     }
 614
 615     $right = undef unless keys %$right;
 616   }
 617
 618
 619   if (defined $left xor defined $right) {
 620     return defined $left ? $left : $right;
 621   }
 622   elsif (! defined $left) {
 623     return undef;
 624   }
 625   else {
 626     return { -and => [ $left, $right ] };
 627   }
 628 }
 629
 630 =head2 search_literal
 631
 632 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 633 should only be used in that context. C<search_literal> is a convenience
 634 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 635 want to ensure columns are bound correctly, use L</search>.
 636
 637 See L<DBIx::Class::Manual::Cookbook/Searching> and
 638 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 639 require C<search_literal>.
 640
 641 =over 4
 642
 643 =item Arguments: $sql_fragment, @standalone_bind_values
 644
 645 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 646
 647 =back
 648
 649   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 650   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 651
 652 Pass a literal chunk of SQL to be added to the conditional part of the
 653 resultset query.
 654
 655 Example of how to use C<search> instead of C<search_literal>
 656
 657   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 658   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 659
 660 =cut
 661
 662 sub search_literal {
 663   my ($self, $sql, @bind) = @_;
 664   my $attr;
 665   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 666     $attr = pop @bind;
 667   }
 668   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 669 }
 670
 671 =head2 find
 672
 673 =over 4
 674
 675 =item Arguments: \%columns_values | @pk_values, \%attrs?
 676
 677 =item Return Value: $row_object | undef
 678
 679 =back
 680
 681 Finds and returns a single row based on supplied criteria. Takes either a
 682 hashref with the same format as L</create> (including inference of foreign
 683 keys from related objects), or a list of primary key values in the same
 684 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 685 declaration on the L</result_source>.
 686
 687 In either case an attempt is made to combine conditions already existing on
 688 the resultset with the condition passed to this method.
 689
 690 To aid with preparing the correct query for the storage you may supply the
 691 C<key> attribute, which is the name of a
 692 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 693 unique constraint corresponding to the
 694 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 695 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 696 to construct a query that satisfies the named unique constraint fully (
 697 non-NULL values for each column member of the constraint) an exception is
 698 thrown.
 699
 700 If no C<key> is specified, the search is carried over all unique constraints
 701 which are fully defined by the available condition.
 702
 703 If no such constraint is found, C<find> currently defaults to a simple
 704 C<< search->(\%column_values) >> which may or may not do what you expect.
 705 Note that this fallback behavior may be deprecated in further versions. If
 706 you need to search with arbitrary conditions - use L</search>. If the query
 707 resulting from this fallback produces more than one row, a warning to the
 708 effect is issued, though only the first row is constructed and returned as
 709 C<$row_object>.
 710
 711 In addition to C<key>, L</find> recognizes and applies standard
 712 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 713
 714 Note that if you have extra concerns about the correctness of the resulting
 715 query you need to specify the C<key> attribute and supply the entire condition
 716 as an argument to find (since it is not always possible to perform the
 717 combination of the resultset condition with the supplied one, especially if
 718 the resultset condition contains literal sql).
 719
 720 For example, to find a row by its primary key:
 721
 722   my $cd = $schema->resultset('CD')->find(5);
 723
 724 You can also find a row by a specific unique constraint:
 725
 726   my $cd = $schema->resultset('CD')->find(
 727     {
 728       artist => 'Massive Attack',
 729       title  => 'Mezzanine',
 730     },
 731     { key => 'cd_artist_title' }
 732   );
 733
 734 See also L</find_or_create> and L</update_or_create>.
 735
 736 =cut
 737
 738 sub find {
 739   my $self = shift;
 740   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 741
 742   my $rsrc = $self->result_source;
 743
 744   my $constraint_name;
 745   if (exists $attrs->{key}) {
 746     $constraint_name = defined $attrs->{key}
 747       ? $attrs->{key}
 748       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 749     ;
 750   }
 751
 752   # Parse out the condition from input
 753   my $call_cond;
 754
 755   if (ref $_[0] eq 'HASH') {
 756     $call_cond = { %{$_[0]} };
 757   }
 758   else {
 759     # if only values are supplied we need to default to 'primary'
 760     $constraint_name = 'primary' unless defined $constraint_name;
 761
 762     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 763
 764     $self->throw_exception(
 765       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 766     ) unless @c_cols;
 767
 768     $self->throw_exception (
 769       'find() expects either a column/value hashref, or a list of values '
 770     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 771     ) unless @c_cols == @_;
 772
 773     $call_cond = {};
 774     @{$call_cond}{@c_cols} = @_;
 775   }
 776
 777   my %related;
 778   for my $key (keys %$call_cond) {
 779     if (
 780       my $keyref = ref($call_cond->{$key})
 781         and
 782       my $relinfo = $rsrc->relationship_info($key)
 783     ) {
 784       my $val = delete $call_cond->{$key};
 785
 786       next if $keyref eq 'ARRAY'; # has_many for multi_create
 787
 788       my $rel_q = $rsrc->_resolve_condition(
 789         $relinfo->{cond}, $val, $key, $key
 790       );
 791       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 792       @related{keys %$rel_q} = values %$rel_q;
 793     }
 794   }
 795
 796   # relationship conditions take precedence (?)
 797   @{$call_cond}{keys %related} = values %related;
 798
 799   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 800   my $final_cond;
 801   if (defined $constraint_name) {
 802     $final_cond = $self->_qualify_cond_columns (
 803
 804       $self->_build_unique_cond (
 805         $constraint_name,
 806         $call_cond,
 807       ),
 808
 809       $alias,
 810     );
 811   }
 812   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 813     # This means that we got here after a merger of relationship conditions
 814     # in ::Relationship::Base::search_related (the row method), and furthermore
 815     # the relationship is of the 'single' type. This means that the condition
 816     # provided by the relationship (already attached to $self) is sufficient,
 817     # as there can be only one row in the database that would satisfy the
 818     # relationship
 819   }
 820   else {
 821     # no key was specified - fall down to heuristics mode:
 822     # run through all unique queries registered on the resultset, and
 823     # 'OR' all qualifying queries together
 824     my (@unique_queries, %seen_column_combinations);
 825     for my $c_name ($rsrc->unique_constraint_names) {
 826       next if $seen_column_combinations{
 827         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 828       }++;
 829
 830       push @unique_queries, try {
 831         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 832       } || ();
 833     }
 834
 835     $final_cond = @unique_queries
 836       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 837       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 838     ;
 839   }
 840
 841   # Run the query, passing the result_class since it should propagate for find
 842   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 843   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 844     my $row = $rs->next;
 845     carp "Query returned more than one row" if $rs->next;
 846     return $row;
 847   }
 848   else {
 849     return $rs->single;
 850   }
 851 }
 852
 853 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 854 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 855 #
 856 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 857 # condition. It is provided for overrides until a saner way forward is devised
 858 #
 859 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 860 # the road. Please adjust your tests accordingly to catch this situation early
 861 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 862 #
 863 # The method will not be removed without an adequately complete replacement
 864 # for strict-mode enforcement
 865 sub _non_unique_find_fallback {
 866   my ($self, $cond, $attrs) = @_;
 867
 868   return $self->_qualify_cond_columns(
 869     $cond,
 870     exists $attrs->{alias}
 871       ? $attrs->{alias}
 872       : $self->{attrs}{alias}
 873   );
 874 }
 875
 876
 877 sub _qualify_cond_columns {
 878   my ($self, $cond, $alias) = @_;
 879
 880   my %aliased = %$cond;
 881   for (keys %aliased) {
 882     $aliased{"$alias.$_"} = delete $aliased{$_}
 883       if $_ !~ /\./;
 884   }
 885
 886   return \%aliased;
 887 }
 888
 889 sub _build_unique_cond {
 890   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 891
 892   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 893
 894   # combination may fail if $self->{cond} is non-trivial
 895   my ($final_cond) = try {
 896     $self->_merge_with_rscond ($extra_cond)
 897   } catch {
 898     +{ %$extra_cond }
 899   };
 900
 901   # trim out everything not in $columns
 902   $final_cond = { map {
 903     exists $final_cond->{$_}
 904       ? ( $_ => $final_cond->{$_} )
 905       : ()
 906   } @c_cols };
 907
 908   if (my @missing = grep
 909     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 910     (@c_cols)
 911   ) {
 912     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 913       $constraint_name,
 914       join (', ', map { "'$_'" } @missing),
 915     ) );
 916   }
 917
 918   if (
 919     !$croak_on_null
 920       and
 921     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 922       and
 923     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 924   ) {
 925     carp_unique ( sprintf (
 926       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 927     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 928     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 929       $constraint_name,
 930       join (', ', map { "'$_'" } @undefs),
 931     ));
 932   }
 933
 934   return $final_cond;
 935 }
 936
 937 =head2 search_related
 938
 939 =over 4
 940
 941 =item Arguments: $rel, $cond?, \%attrs?
 942
 943 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 944
 945 =back
 946
 947   $new_rs = $cd_rs->search_related('artist', {
 948     name => 'Emo-R-Us',
 949   });
 950
 951 Searches the specified relationship, optionally specifying a condition and
 952 attributes for matching records. See L</ATTRIBUTES> for more information.
 953
 954 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 955 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 956
 957 See also L</search_related_rs>.
 958
 959 =cut
 960
 961 sub search_related {
 962   return shift->related_resultset(shift)->search(@_);
 963 }
 964
 965 =head2 search_related_rs
 966
 967 This method works exactly the same as search_related, except that
 968 it guarantees a resultset, even in list context.
 969
 970 =cut
 971
 972 sub search_related_rs {
 973   return shift->related_resultset(shift)->search_rs(@_);
 974 }
 975
 976 =head2 cursor
 977
 978 =over 4
 979
 980 =item Arguments: none
 981
 982 =item Return Value: $cursor
 983
 984 =back
 985
 986 Returns a storage-driven cursor to the given resultset. See
 987 L<DBIx::Class::Cursor> for more information.
 988
 989 =cut
 990
 991 sub cursor {
 992   my ($self) = @_;
 993
 994   my $attrs = $self->_resolved_attrs_copy;
 995
 996   return $self->{cursor}
 997     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 998           $attrs->{where},$attrs);
 999 }
1000
1001 =head2 single
1002
1003 =over 4
1004
1005 =item Arguments: $cond?
1006
1007 =item Return Value: $row_object | undef
1008
1009 =back
1010
1011   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1012
1013 Inflates the first result without creating a cursor if the resultset has
1014 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1015 of L</search>.
1016
1017 While this method can take an optional search condition (just like L</search>)
1018 being a fast-code-path it does not recognize search attributes. If you need to
1019 add extra joins or similar, call L</search> and then chain-call L</single> on the
1020 L<DBIx::Class::ResultSet> returned.
1021
1022 =over
1023
1024 =item B<Note>
1025
1026 As of 0.08100, this method enforces the assumption that the preceding
1027 query returns only one row. If more than one row is returned, you will receive
1028 a warning:
1029
1030   Query returned more than one row
1031
1032 In this case, you should be using L</next> or L</find> instead, or if you really
1033 know what you are doing, use the L</rows> attribute to explicitly limit the size
1034 of the resultset.
1035
1036 This method will also throw an exception if it is called on a resultset prefetching
1037 has_many, as such a prefetch implies fetching multiple rows from the database in
1038 order to assemble the resulting object.
1039
1040 =back
1041
1042 =cut
1043
1044 sub single {
1045   my ($self, $where) = @_;
1046   if(@_ > 2) {
1047       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1048   }
1049
1050   my $attrs = $self->_resolved_attrs_copy;
1051
1052   if (keys %{$attrs->{collapse}}) {
1053     $self->throw_exception(
1054       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1055     );
1056   }
1057
1058   if ($where) {
1059     if (defined $attrs->{where}) {
1060       $attrs->{where} = {
1061         '-and' =>
1062             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1063                $where, delete $attrs->{where} ]
1064       };
1065     } else {
1066       $attrs->{where} = $where;
1067     }
1068   }
1069
1070   my @data = $self->result_source->storage->select_single(
1071     $attrs->{from}, $attrs->{select},
1072     $attrs->{where}, $attrs
1073   );
1074
1075   return (@data ? ($self->_construct_object(@data))[0] : undef);
1076 }
1077
1078
1079 # _collapse_query
1080 #
1081 # Recursively collapse the query, accumulating values for each column.
1082
1083 sub _collapse_query {
1084   my ($self, $query, $collapsed) = @_;
1085
1086   $collapsed ||= {};
1087
1088   if (ref $query eq 'ARRAY') {
1089     foreach my $subquery (@$query) {
1090       next unless ref $subquery;  # -or
1091       $collapsed = $self->_collapse_query($subquery, $collapsed);
1092     }
1093   }
1094   elsif (ref $query eq 'HASH') {
1095     if (keys %$query and (keys %$query)[0] eq '-and') {
1096       foreach my $subquery (@{$query->{-and}}) {
1097         $collapsed = $self->_collapse_query($subquery, $collapsed);
1098       }
1099     }
1100     else {
1101       foreach my $col (keys %$query) {
1102         my $value = $query->{$col};
1103         $collapsed->{$col}{$value}++;
1104       }
1105     }
1106   }
1107
1108   return $collapsed;
1109 }
1110
1111 =head2 get_column
1112
1113 =over 4
1114
1115 =item Arguments: $cond?
1116
1117 =item Return Value: $resultsetcolumn
1118
1119 =back
1120
1121   my $max_length = $rs->get_column('length')->max;
1122
1123 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1124
1125 =cut
1126
1127 sub get_column {
1128   my ($self, $column) = @_;
1129   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1130   return $new;
1131 }
1132
1133 =head2 search_like
1134
1135 =over 4
1136
1137 =item Arguments: $cond, \%attrs?
1138
1139 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1140
1141 =back
1142
1143   # WHERE title LIKE '%blue%'
1144   $cd_rs = $rs->search_like({ title => '%blue%'});
1145
1146 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1147 that this is simply a convenience method retained for ex Class::DBI users.
1148 You most likely want to use L</search> with specific operators.
1149
1150 For more information, see L<DBIx::Class::Manual::Cookbook>.
1151
1152 This method is deprecated and will be removed in 0.09. Use L</search()>
1153 instead. An example conversion is:
1154
1155   ->search_like({ foo => 'bar' });
1156
1157   # Becomes
1158
1159   ->search({ foo => { like => 'bar' } });
1160
1161 =cut
1162
1163 sub search_like {
1164   my $class = shift;
1165   carp_unique (
1166     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1167    .' Instead use ->search({ x => { -like => "y%" } })'
1168    .' (note the outer pair of {}s - they are important!)'
1169   );
1170   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1171   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1172   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1173   return $class->search($query, { %$attrs });
1174 }
1175
1176 =head2 slice
1177
1178 =over 4
1179
1180 =item Arguments: $first, $last
1181
1182 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1183
1184 =back
1185
1186 Returns a resultset or object list representing a subset of elements from the
1187 resultset slice is called on. Indexes are from 0, i.e., to get the first
1188 three records, call:
1189
1190   my ($one, $two, $three) = $rs->slice(0, 2);
1191
1192 =cut
1193
1194 sub slice {
1195   my ($self, $min, $max) = @_;
1196   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1197   $attrs->{offset} = $self->{attrs}{offset} || 0;
1198   $attrs->{offset} += $min;
1199   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1200   return $self->search(undef, $attrs);
1201   #my $slice = (ref $self)->new($self->result_source, $attrs);
1202   #return (wantarray ? $slice->all : $slice);
1203 }
1204
1205 =head2 next
1206
1207 =over 4
1208
1209 =item Arguments: none
1210
1211 =item Return Value: $result | undef
1212
1213 =back
1214
1215 Returns the next element in the resultset (C<undef> is there is none).
1216
1217 Can be used to efficiently iterate over records in the resultset:
1218
1219   my $rs = $schema->resultset('CD')->search;
1220   while (my $cd = $rs->next) {
1221     print $cd->title;
1222   }
1223
1224 Note that you need to store the resultset object, and call C<next> on it.
1225 Calling C<< resultset('Table')->next >> repeatedly will always return the
1226 first record from the resultset.
1227
1228 =cut
1229
1230 sub next {
1231   my ($self) = @_;
1232   if (my $cache = $self->get_cache) {
1233     $self->{all_cache_position} ||= 0;
1234     return $cache->[$self->{all_cache_position}++];
1235   }
1236   if ($self->{attrs}{cache}) {
1237     delete $self->{pager};
1238     $self->{all_cache_position} = 1;
1239     return ($self->all)[0];
1240   }
1241   if ($self->{stashed_objects}) {
1242     my $obj = shift(@{$self->{stashed_objects}});
1243     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1244     return $obj;
1245   }
1246   my @row = (
1247     exists $self->{stashed_row}
1248       ? @{delete $self->{stashed_row}}
1249       : $self->cursor->next
1250   );
1251   return undef unless (@row);
1252   my ($row, @more) = $self->_construct_object(@row);
1253   $self->{stashed_objects} = \@more if @more;
1254   return $row;
1255 }
1256
1257 sub _construct_object {
1258   my ($self, @row) = @_;
1259
1260   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1261     or return ();
1262   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1263   @new = $self->{_attrs}{record_filter}->(@new)
1264     if exists $self->{_attrs}{record_filter};
1265   return @new;
1266 }
1267
1268 sub _collapse_result {
1269   my ($self, $as_proto, $row) = @_;
1270
1271   my @copy = @$row;
1272
1273   # 'foo'         => [ undef, 'foo' ]
1274   # 'foo.bar'     => [ 'foo', 'bar' ]
1275   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1276
1277   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1278
1279   my %collapse = %{$self->{_attrs}{collapse}||{}};
1280
1281   my @pri_index;
1282
1283   # if we're doing collapsing (has_many prefetch) we need to grab records
1284   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1285   # we know we don't have to bother.
1286
1287   # the reason for not using the collapse stuff directly is because if you
1288   # had for e.g. two artists in a row with no cds, the collapse info for
1289   # both would be NULL (undef) so you'd lose the second artist
1290
1291   # store just the index so we can check the array positions from the row
1292   # without having to contruct the full hash
1293
1294   if (keys %collapse) {
1295     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1296     foreach my $i (0 .. $#construct_as) {
1297       next if defined($construct_as[$i][0]); # only self table
1298       if (delete $pri{$construct_as[$i][1]}) {
1299         push(@pri_index, $i);
1300       }
1301       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1302     }
1303   }
1304
1305   # no need to do an if, it'll be empty if @pri_index is empty anyway
1306
1307   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1308
1309   my @const_rows;
1310
1311   do { # no need to check anything at the front, we always want the first row
1312
1313     my %const;
1314
1315     foreach my $this_as (@construct_as) {
1316       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1317     }
1318
1319     push(@const_rows, \%const);
1320
1321   } until ( # no pri_index => no collapse => drop straight out
1322       !@pri_index
1323     or
1324       do { # get another row, stash it, drop out if different PK
1325
1326         @copy = $self->cursor->next;
1327         $self->{stashed_row} = \@copy;
1328
1329         # last thing in do block, counts as true if anything doesn't match
1330
1331         # check xor defined first for NULL vs. NOT NULL then if one is
1332         # defined the other must be so check string equality
1333
1334         grep {
1335           (defined $pri_vals{$_} ^ defined $copy[$_])
1336           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1337         } @pri_index;
1338       }
1339   );
1340
1341   my $alias = $self->{attrs}{alias};
1342   my $info = [];
1343
1344   my %collapse_pos;
1345
1346   my @const_keys;
1347
1348   foreach my $const (@const_rows) {
1349     scalar @const_keys or do {
1350       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1351     };
1352     foreach my $key (@const_keys) {
1353       if (length $key) {
1354         my $target = $info;
1355         my @parts = split(/\./, $key);
1356         my $cur = '';
1357         my $data = $const->{$key};
1358         foreach my $p (@parts) {
1359           $target = $target->[1]->{$p} ||= [];
1360           $cur .= ".${p}";
1361           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1362             # collapsing at this point and on final part
1363             my $pos = $collapse_pos{$cur};
1364             CK: foreach my $ck (@ckey) {
1365               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1366                 $collapse_pos{$cur} = $data;
1367                 delete @collapse_pos{ # clear all positioning for sub-entries
1368                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1369                 };
1370                 push(@$target, []);
1371                 last CK;
1372               }
1373             }
1374           }
1375           if (exists $collapse{$cur}) {
1376             $target = $target->[-1];
1377           }
1378         }
1379         $target->[0] = $data;
1380       } else {
1381         $info->[0] = $const->{$key};
1382       }
1383     }
1384   }
1385
1386   return $info;
1387 }
1388
1389 =head2 result_source
1390
1391 =over 4
1392
1393 =item Arguments: $result_source?
1394
1395 =item Return Value: $result_source
1396
1397 =back
1398
1399 An accessor for the primary ResultSource object from which this ResultSet
1400 is derived.
1401
1402 =head2 result_class
1403
1404 =over 4
1405
1406 =item Arguments: $result_class?
1407
1408 =item Return Value: $result_class
1409
1410 =back
1411
1412 An accessor for the class to use when creating row objects. Defaults to
1413 C<< result_source->result_class >> - which in most cases is the name of the
1414 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1415
1416 Note that changing the result_class will also remove any components
1417 that were originally loaded in the source class via
1418 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1419 in the original source class will not run.
1420
1421 =cut
1422
1423 sub result_class {
1424   my ($self, $result_class) = @_;
1425   if ($result_class) {
1426     unless (ref $result_class) { # don't fire this for an object
1427       $self->ensure_class_loaded($result_class);
1428     }
1429     $self->_result_class($result_class);
1430     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1431     # permit the user to set result class on one result set only; it only
1432     # chains if provided to search()
1433     #$self->{attrs}{result_class} = $result_class if ref $self;
1434   }
1435   $self->_result_class;
1436 }
1437
1438 =head2 count
1439
1440 =over 4
1441
1442 =item Arguments: $cond, \%attrs??
1443
1444 =item Return Value: $count
1445
1446 =back
1447
1448 Performs an SQL C<COUNT> with the same query as the resultset was built
1449 with to find the number of elements. Passing arguments is equivalent to
1450 C<< $rs->search ($cond, \%attrs)->count >>
1451
1452 =cut
1453
1454 sub count {
1455   my $self = shift;
1456   return $self->search(@_)->count if @_ and defined $_[0];
1457   return scalar @{ $self->get_cache } if $self->get_cache;
1458
1459   my $attrs = $self->_resolved_attrs_copy;
1460
1461   # this is a little optimization - it is faster to do the limit
1462   # adjustments in software, instead of a subquery
1463   my $rows = delete $attrs->{rows};
1464   my $offset = delete $attrs->{offset};
1465
1466   my $crs;
1467   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1468     $crs = $self->_count_subq_rs ($attrs);
1469   }
1470   else {
1471     $crs = $self->_count_rs ($attrs);
1472   }
1473   my $count = $crs->next;
1474
1475   $count -= $offset if $offset;
1476   $count = $rows if $rows and $rows < $count;
1477   $count = 0 if ($count < 0);
1478
1479   return $count;
1480 }
1481
1482 =head2 count_rs
1483
1484 =over 4
1485
1486 =item Arguments: $cond, \%attrs??
1487
1488 =item Return Value: $count_rs
1489
1490 =back
1491
1492 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1493 This can be very handy for subqueries:
1494
1495   ->search( { amount => $some_rs->count_rs->as_query } )
1496
1497 As with regular resultsets the SQL query will be executed only after
1498 the resultset is accessed via L</next> or L</all>. That would return
1499 the same single value obtainable via L</count>.
1500
1501 =cut
1502
1503 sub count_rs {
1504   my $self = shift;
1505   return $self->search(@_)->count_rs if @_;
1506
1507   # this may look like a lack of abstraction (count() does about the same)
1508   # but in fact an _rs *must* use a subquery for the limits, as the
1509   # software based limiting can not be ported if this $rs is to be used
1510   # in a subquery itself (i.e. ->as_query)
1511   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1512     return $self->_count_subq_rs;
1513   }
1514   else {
1515     return $self->_count_rs;
1516   }
1517 }
1518
1519 #
1520 # returns a ResultSetColumn object tied to the count query
1521 #
1522 sub _count_rs {
1523   my ($self, $attrs) = @_;
1524
1525   my $rsrc = $self->result_source;
1526   $attrs ||= $self->_resolved_attrs;
1527
1528   my $tmp_attrs = { %$attrs };
1529   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1530   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1531
1532   # overwrite the selector (supplied by the storage)
1533   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1534   $tmp_attrs->{as} = 'count';
1535   delete @{$tmp_attrs}{qw/columns/};
1536
1537   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1538
1539   return $tmp_rs;
1540 }
1541
1542 #
1543 # same as above but uses a subquery
1544 #
1545 sub _count_subq_rs {
1546   my ($self, $attrs) = @_;
1547
1548   my $rsrc = $self->result_source;
1549   $attrs ||= $self->_resolved_attrs;
1550
1551   my $sub_attrs = { %$attrs };
1552   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1553   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1554
1555   # if we multi-prefetch we group_by something unique, as this is what we would
1556   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1557   if ( keys %{$attrs->{collapse}}  ) {
1558     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1559       $rsrc->_identifying_column_set || $self->throw_exception(
1560         'Unable to construct a unique group_by criteria properly collapsing the '
1561       . 'has_many prefetch before count()'
1562       );
1563     } ]
1564   }
1565
1566   # Calculate subquery selector
1567   if (my $g = $sub_attrs->{group_by}) {
1568
1569     my $sql_maker = $rsrc->storage->sql_maker;
1570
1571     # necessary as the group_by may refer to aliased functions
1572     my $sel_index;
1573     for my $sel (@{$attrs->{select}}) {
1574       $sel_index->{$sel->{-as}} = $sel
1575         if (ref $sel eq 'HASH' and $sel->{-as});
1576     }
1577
1578     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1579     # also look for named aggregates referred in the having clause
1580     # having often contains scalarrefs - thus parse it out entirely
1581     my @parts = @$g;
1582     if ($attrs->{having}) {
1583       local $sql_maker->{having_bind};
1584       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1585       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1586       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1587         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1588         # if we don't unset it we screw up retarded but unfortunately working
1589         # 'MAX(foo.bar)' => { '>', 3 }
1590         $sql_maker->{name_sep} = '';
1591       }
1592
1593       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1594
1595       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1596
1597       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1598       # and if all fails for an utterly naive quoted scalar-with-function
1599       while ($sql =~ /
1600         $rquote $sep $lquote (.+?) $rquote
1601           |
1602         [\s,] \w+ \. (\w+) [\s,]
1603           |
1604         [\s,] $lquote (.+?) $rquote [\s,]
1605       /gx) {
1606         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1607       }
1608     }
1609
1610     for (@parts) {
1611       my $colpiece = $sel_index->{$_} || $_;
1612
1613       # unqualify join-based group_by's. Arcane but possible query
1614       # also horrible horrible hack to alias a column (not a func.)
1615       # (probably need to introduce SQLA syntax)
1616       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1617         my $as = $colpiece;
1618         $as =~ s/\./__/;
1619         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1620       }
1621       push @{$sub_attrs->{select}}, $colpiece;
1622     }
1623   }
1624   else {
1625     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1626     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1627   }
1628
1629   return $rsrc->resultset_class
1630                ->new ($rsrc, $sub_attrs)
1631                 ->as_subselect_rs
1632                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1633                   ->get_column ('count');
1634 }
1635
1636 sub _bool {
1637   return 1;
1638 }
1639
1640 =head2 count_literal
1641
1642 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1643 should only be used in that context. See L</search_literal> for further info.
1644
1645 =over 4
1646
1647 =item Arguments: $sql_fragment, @standalone_bind_values
1648
1649 =item Return Value: $count
1650
1651 =back
1652
1653 Counts the results in a literal query. Equivalent to calling L</search_literal>
1654 with the passed arguments, then L</count>.
1655
1656 =cut
1657
1658 sub count_literal { shift->search_literal(@_)->count; }
1659
1660 =head2 all
1661
1662 =over 4
1663
1664 =item Arguments: none
1665
1666 =item Return Value: @objects
1667
1668 =back
1669
1670 Returns all elements in the resultset.
1671
1672 =cut
1673
1674 sub all {
1675   my $self = shift;
1676   if(@_) {
1677       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1678   }
1679
1680   return @{ $self->get_cache } if $self->get_cache;
1681
1682   my @obj;
1683
1684   if (keys %{$self->_resolved_attrs->{collapse}}) {
1685     # Using $self->cursor->all is really just an optimisation.
1686     # If we're collapsing has_many prefetches it probably makes
1687     # very little difference, and this is cleaner than hacking
1688     # _construct_object to survive the approach
1689     $self->cursor->reset;
1690     my @row = $self->cursor->next;
1691     while (@row) {
1692       push(@obj, $self->_construct_object(@row));
1693       @row = (exists $self->{stashed_row}
1694                ? @{delete $self->{stashed_row}}
1695                : $self->cursor->next);
1696     }
1697   } else {
1698     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1699   }
1700
1701   $self->set_cache(\@obj) if $self->{attrs}{cache};
1702
1703   return @obj;
1704 }
1705
1706 =head2 reset
1707
1708 =over 4
1709
1710 =item Arguments: none
1711
1712 =item Return Value: $self
1713
1714 =back
1715
1716 Resets the resultset's cursor, so you can iterate through the elements again.
1717 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1718 another query.
1719
1720 =cut
1721
1722 sub reset {
1723   my ($self) = @_;
1724   delete $self->{_attrs} if exists $self->{_attrs};
1725   $self->{all_cache_position} = 0;
1726   $self->cursor->reset;
1727   return $self;
1728 }
1729
1730 =head2 first
1731
1732 =over 4
1733
1734 =item Arguments: none
1735
1736 =item Return Value: $object | undef
1737
1738 =back
1739
1740 Resets the resultset and returns an object for the first result (or C<undef>
1741 if the resultset is empty).
1742
1743 =cut
1744
1745 sub first {
1746   return $_[0]->reset->next;
1747 }
1748
1749
1750 # _rs_update_delete
1751 #
1752 # Determines whether and what type of subquery is required for the $rs operation.
1753 # If grouping is necessary either supplies its own, or verifies the current one
1754 # After all is done delegates to the proper storage method.
1755
1756 sub _rs_update_delete {
1757   my ($self, $op, $values) = @_;
1758
1759   my $cond = $self->{cond};
1760   my $rsrc = $self->result_source;
1761   my $storage = $rsrc->schema->storage;
1762
1763   my $attrs = { %{$self->_resolved_attrs} };
1764
1765   my $existing_group_by = delete $attrs->{group_by};
1766   my $needs_subq = defined $existing_group_by;
1767
1768   # simplify the joinmap and maybe decide if a subquery is necessary
1769   my $relation_classifications = {};
1770
1771   if (ref($attrs->{from}) eq 'ARRAY') {
1772     # if we already know we need a subq, no point of classifying relations
1773     if (!$needs_subq and @{$attrs->{from}} > 1) {
1774       $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $cond, $attrs);
1775
1776       $relation_classifications = $storage->_resolve_aliastypes_from_select_args (
1777         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1778         $attrs->{select},
1779         $cond,
1780         $attrs
1781       );
1782     }
1783   }
1784   else {
1785     $needs_subq ||= 1; # if {from} is unparseable assume the worst
1786   }
1787
1788   # do we need anything like a subquery?
1789   if (
1790     ! $needs_subq
1791       and
1792     ! keys %{ $relation_classifications->{restricting} || {} }
1793       and
1794     ! $self->_has_resolved_attr(qw/rows offset/) # limits call for a subq
1795   ) {
1796     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1797     # a condition containing 'me' or other table prefixes will not work
1798     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1799     my $cond = do {
1800       my $sqla = $rsrc->storage->sql_maker;
1801       local $sqla->{_dequalify_idents} = 1;
1802       \[ $sqla->_recurse_where($self->{cond}) ];
1803     };
1804     return $rsrc->storage->$op(
1805       $rsrc,
1806       $op eq 'update' ? $values : (),
1807       $cond,
1808     );
1809   }
1810
1811   # we got this far - means it is time to wrap a subquery
1812   my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1813     sprintf(
1814       "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1815       $op,
1816       $rsrc->source_name,
1817     )
1818   );
1819
1820   # make a new $rs selecting only the PKs (that's all we really need for the subq)
1821   delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1822   $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1823   $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1824   my $subrs = (ref $self)->new($rsrc, $attrs);
1825
1826   if (@$idcols == 1) {
1827     return $storage->$op (
1828       $rsrc,
1829       $op eq 'update' ? $values : (),
1830       { $idcols->[0] => { -in => $subrs->as_query } },
1831     );
1832   }
1833   elsif ($storage->_use_multicolumn_in) {
1834     # This is hideously ugly, but SQLA does not understand multicol IN expressions
1835     my $sql_maker = $storage->sql_maker;
1836     my ($sql, @bind) = @${$subrs->as_query};
1837     $sql = sprintf ('(%s) IN %s', # the as_query already comes with a set of parenthesis
1838       join (', ', map { $sql_maker->_quote ($_) } @$idcols),
1839       $sql,
1840     );
1841
1842     return $storage->$op (
1843       $rsrc,
1844       $op eq 'update' ? $values : (),
1845       \[$sql, @bind],
1846     );
1847   }
1848   else {
1849
1850     # if all else fails - get all primary keys and operate over a ORed set
1851     # wrap in a transaction for consistency
1852     # this is where the group_by starts to matter
1853     if (
1854       $existing_group_by
1855         or
1856       keys %{ $relation_classifications->{multiplying} || {} }
1857     ) {
1858       # make sure if there is a supplied group_by it matches the columns compiled above
1859       # perfectly. Anything else can not be sanely executed on most databases so croak
1860       # right then and there
1861       if ($existing_group_by) {
1862         my @current_group_by = map
1863           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1864           @$existing_group_by
1865         ;
1866
1867         if (
1868           join ("\x00", sort @current_group_by)
1869             ne
1870           join ("\x00", sort @{$attrs->{columns}} )
1871         ) {
1872           $self->throw_exception (
1873             "You have just attempted a $op operation on a resultset which does group_by"
1874             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1875             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1876             . ' kind of queries. Please retry the operation with a modified group_by or'
1877             . ' without using one at all.'
1878           );
1879         }
1880       }
1881
1882       $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1883     }
1884
1885     my $guard = $storage->txn_scope_guard;
1886
1887     my @op_condition;
1888     for my $row ($subrs->cursor->all) {
1889       push @op_condition, { map
1890         { $idcols->[$_] => $row->[$_] }
1891         (0 .. $#$idcols)
1892       };
1893     }
1894
1895     my $res = $storage->$op (
1896       $rsrc,
1897       $op eq 'update' ? $values : (),
1898       \@op_condition,
1899     );
1900
1901     $guard->commit;
1902
1903     return $res;
1904   }
1905 }
1906
1907 =head2 update
1908
1909 =over 4
1910
1911 =item Arguments: \%values
1912
1913 =item Return Value: $storage_rv
1914
1915 =back
1916
1917 Sets the specified columns in the resultset to the supplied values in a
1918 single query. Note that this will not run any accessor/set_column/update
1919 triggers, nor will it update any row object instances derived from this
1920 resultset (this includes the contents of the L<resultset cache|/set_cache>
1921 if any). See L</update_all> if you need to execute any on-update
1922 triggers or cascades defined either by you or a
1923 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1924
1925 The return value is a pass through of what the underlying
1926 storage backend returned, and may vary. See L<DBI/execute> for the most
1927 common case.
1928
1929 =head3 CAVEAT
1930
1931 Note that L</update> does not process/deflate any of the values passed in.
1932 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1933 ensure manually that any value passed to this method will stringify to
1934 something the RDBMS knows how to deal with. A notable example is the
1935 handling of L<DateTime> objects, for more info see:
1936 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1937
1938 =cut
1939
1940 sub update {
1941   my ($self, $values) = @_;
1942   $self->throw_exception('Values for update must be a hash')
1943     unless ref $values eq 'HASH';
1944
1945   return $self->_rs_update_delete ('update', $values);
1946 }
1947
1948 =head2 update_all
1949
1950 =over 4
1951
1952 =item Arguments: \%values
1953
1954 =item Return Value: 1
1955
1956 =back
1957
1958 Fetches all objects and updates them one at a time via
1959 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1960 triggers, while L</update> will not.
1961
1962 =cut
1963
1964 sub update_all {
1965   my ($self, $values) = @_;
1966   $self->throw_exception('Values for update_all must be a hash')
1967     unless ref $values eq 'HASH';
1968
1969   my $guard = $self->result_source->schema->txn_scope_guard;
1970   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1971   $guard->commit;
1972   return 1;
1973 }
1974
1975 =head2 delete
1976
1977 =over 4
1978
1979 =item Arguments: none
1980
1981 =item Return Value: $storage_rv
1982
1983 =back
1984
1985 Deletes the rows matching this resultset in a single query. Note that this
1986 will not run any delete triggers, nor will it alter the
1987 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1988 derived from this resultset (this includes the contents of the
1989 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1990 execute any on-delete triggers or cascades defined either by you or a
1991 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1992
1993 The return value is a pass through of what the underlying storage backend
1994 returned, and may vary. See L<DBI/execute> for the most common case.
1995
1996 =cut
1997
1998 sub delete {
1999   my $self = shift;
2000   $self->throw_exception('delete does not accept any arguments')
2001     if @_;
2002
2003   return $self->_rs_update_delete ('delete');
2004 }
2005
2006 =head2 delete_all
2007
2008 =over 4
2009
2010 =item Arguments: none
2011
2012 =item Return Value: 1
2013
2014 =back
2015
2016 Fetches all objects and deletes them one at a time via
2017 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2018 triggers, while L</delete> will not.
2019
2020 =cut
2021
2022 sub delete_all {
2023   my $self = shift;
2024   $self->throw_exception('delete_all does not accept any arguments')
2025     if @_;
2026
2027   my $guard = $self->result_source->schema->txn_scope_guard;
2028   $_->delete for $self->all;
2029   $guard->commit;
2030   return 1;
2031 }
2032
2033 =head2 populate
2034
2035 =over 4
2036
2037 =item Arguments: \@data;
2038
2039 =back
2040
2041 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
2042 For the arrayref of hashrefs style each hashref should be a structure suitable
2043 for submitting to a $resultset->create(...) method.
2044
2045 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
2046 to insert the data, as this is a faster method.
2047
2048 Otherwise, each set of data is inserted into the database using
2049 L<DBIx::Class::ResultSet/create>, and the resulting objects are
2050 accumulated into an array. The array itself, or an array reference
2051 is returned depending on scalar or list context.
2052
2053 Example:  Assuming an Artist Class that has many CDs Classes relating:
2054
2055   my $Artist_rs = $schema->resultset("Artist");
2056
2057   ## Void Context Example
2058   $Artist_rs->populate([
2059      { artistid => 4, name => 'Manufactured Crap', cds => [
2060         { title => 'My First CD', year => 2006 },
2061         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2062       ],
2063      },
2064      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2065         { title => 'My parents sold me to a record company', year => 2005 },
2066         { title => 'Why Am I So Ugly?', year => 2006 },
2067         { title => 'I Got Surgery and am now Popular', year => 2007 }
2068       ],
2069      },
2070   ]);
2071
2072   ## Array Context Example
2073   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
2074     { name => "Artist One"},
2075     { name => "Artist Two"},
2076     { name => "Artist Three", cds=> [
2077     { title => "First CD", year => 2007},
2078     { title => "Second CD", year => 2008},
2079   ]}
2080   ]);
2081
2082   print $ArtistOne->name; ## response is 'Artist One'
2083   print $ArtistThree->cds->count ## reponse is '2'
2084
2085 For the arrayref of arrayrefs style,  the first element should be a list of the
2086 fieldsnames to which the remaining elements are rows being inserted.  For
2087 example:
2088
2089   $Arstist_rs->populate([
2090     [qw/artistid name/],
2091     [100, 'A Formally Unknown Singer'],
2092     [101, 'A singer that jumped the shark two albums ago'],
2093     [102, 'An actually cool singer'],
2094   ]);
2095
2096 Please note an important effect on your data when choosing between void and
2097 wantarray context. Since void context goes straight to C<insert_bulk> in
2098 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
2099 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
2100 create primary keys for you, you will find that your PKs are empty.  In this
2101 case you will have to use the wantarray context in order to create those
2102 values.
2103
2104 =cut
2105
2106 sub populate {
2107   my $self = shift;
2108
2109   # cruft placed in standalone method
2110   my $data = $self->_normalize_populate_args(@_);
2111
2112   return unless @$data;
2113
2114   if(defined wantarray) {
2115     my @created;
2116     foreach my $item (@$data) {
2117       push(@created, $self->create($item));
2118     }
2119     return wantarray ? @created : \@created;
2120   }
2121   else {
2122     my $first = $data->[0];
2123
2124     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2125     # it relationship data
2126     my (@rels, @columns);
2127     my $rsrc = $self->result_source;
2128     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2129     for (keys %$first) {
2130       my $ref = ref $first->{$_};
2131       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2132         ? push @rels, $_
2133         : push @columns, $_
2134       ;
2135     }
2136
2137     my @pks = $rsrc->primary_columns;
2138
2139     ## do the belongs_to relationships
2140     foreach my $index (0..$#$data) {
2141
2142       # delegate to create() for any dataset without primary keys with specified relationships
2143       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2144         for my $r (@rels) {
2145           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2146             my @ret = $self->populate($data);
2147             return;
2148           }
2149         }
2150       }
2151
2152       foreach my $rel (@rels) {
2153         next unless ref $data->[$index]->{$rel} eq "HASH";
2154         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2155         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2156         my $related = $result->result_source->_resolve_condition(
2157           $reverse_relinfo->{cond},
2158           $self,
2159           $result,
2160           $rel,
2161         );
2162
2163         delete $data->[$index]->{$rel};
2164         $data->[$index] = {%{$data->[$index]}, %$related};
2165
2166         push @columns, keys %$related if $index == 0;
2167       }
2168     }
2169
2170     ## inherit the data locked in the conditions of the resultset
2171     my ($rs_data) = $self->_merge_with_rscond({});
2172     delete @{$rs_data}{@columns};
2173     my @inherit_cols = keys %$rs_data;
2174     my @inherit_data = values %$rs_data;
2175
2176     ## do bulk insert on current row
2177     $rsrc->storage->insert_bulk(
2178       $rsrc,
2179       [@columns, @inherit_cols],
2180       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
2181     );
2182
2183     ## do the has_many relationships
2184     foreach my $item (@$data) {
2185
2186       my $main_row;
2187
2188       foreach my $rel (@rels) {
2189         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2190
2191         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2192
2193         my $child = $main_row->$rel;
2194
2195         my $related = $child->result_source->_resolve_condition(
2196           $rels->{$rel}{cond},
2197           $child,
2198           $main_row,
2199           $rel,
2200         );
2201
2202         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2203         my @populate = map { {%$_, %$related} } @rows_to_add;
2204
2205         $child->populate( \@populate );
2206       }
2207     }
2208   }
2209 }
2210
2211
2212 # populate() argumnets went over several incarnations
2213 # What we ultimately support is AoH
2214 sub _normalize_populate_args {
2215   my ($self, $arg) = @_;
2216
2217   if (ref $arg eq 'ARRAY') {
2218     if (!@$arg) {
2219       return [];
2220     }
2221     elsif (ref $arg->[0] eq 'HASH') {
2222       return $arg;
2223     }
2224     elsif (ref $arg->[0] eq 'ARRAY') {
2225       my @ret;
2226       my @colnames = @{$arg->[0]};
2227       foreach my $values (@{$arg}[1 .. $#$arg]) {
2228         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2229       }
2230       return \@ret;
2231     }
2232   }
2233
2234   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2235 }
2236
2237 =head2 pager
2238
2239 =over 4
2240
2241 =item Arguments: none
2242
2243 =item Return Value: $pager
2244
2245 =back
2246
2247 Return Value a L<Data::Page> object for the current resultset. Only makes
2248 sense for queries with a C<page> attribute.
2249
2250 To get the full count of entries for a paged resultset, call
2251 C<total_entries> on the L<Data::Page> object.
2252
2253 =cut
2254
2255 sub pager {
2256   my ($self) = @_;
2257
2258   return $self->{pager} if $self->{pager};
2259
2260   my $attrs = $self->{attrs};
2261   if (!defined $attrs->{page}) {
2262     $self->throw_exception("Can't create pager for non-paged rs");
2263   }
2264   elsif ($attrs->{page} <= 0) {
2265     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2266   }
2267   $attrs->{rows} ||= 10;
2268
2269   # throw away the paging flags and re-run the count (possibly
2270   # with a subselect) to get the real total count
2271   my $count_attrs = { %$attrs };
2272   delete $count_attrs->{$_} for qw/rows offset page pager/;
2273
2274   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2275
2276   require DBIx::Class::ResultSet::Pager;
2277   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2278     sub { $total_rs->count },  #lazy-get the total
2279     $attrs->{rows},
2280     $self->{attrs}{page},
2281   );
2282 }
2283
2284 =head2 page
2285
2286 =over 4
2287
2288 =item Arguments: $page_number
2289
2290 =item Return Value: $rs
2291
2292 =back
2293
2294 Returns a resultset for the $page_number page of the resultset on which page
2295 is called, where each page contains a number of rows equal to the 'rows'
2296 attribute set on the resultset (10 by default).
2297
2298 =cut
2299
2300 sub page {
2301   my ($self, $page) = @_;
2302   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2303 }
2304
2305 =head2 new_result
2306
2307 =over 4
2308
2309 =item Arguments: \%vals
2310
2311 =item Return Value: $rowobject
2312
2313 =back
2314
2315 Creates a new row object in the resultset's result class and returns
2316 it. The row is not inserted into the database at this point, call
2317 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2318 will tell you whether the row object has been inserted or not.
2319
2320 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2321
2322 =cut
2323
2324 sub new_result {
2325   my ($self, $values) = @_;
2326
2327   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2328     if @_ > 2;
2329
2330   $self->throw_exception( "new_result expects a hashref" )
2331     unless (ref $values eq 'HASH');
2332
2333   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2334
2335   my %new = (
2336     %$merged_cond,
2337     @$cols_from_relations
2338       ? (-cols_from_relations => $cols_from_relations)
2339       : (),
2340     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2341   );
2342
2343   return $self->result_class->new(\%new);
2344 }
2345
2346 # _merge_with_rscond
2347 #
2348 # Takes a simple hash of K/V data and returns its copy merged with the
2349 # condition already present on the resultset. Additionally returns an
2350 # arrayref of value/condition names, which were inferred from related
2351 # objects (this is needed for in-memory related objects)
2352 sub _merge_with_rscond {
2353   my ($self, $data) = @_;
2354
2355   my (%new_data, @cols_from_relations);
2356
2357   my $alias = $self->{attrs}{alias};
2358
2359   if (! defined $self->{cond}) {
2360     # just massage $data below
2361   }
2362   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2363     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2364     @cols_from_relations = keys %new_data;
2365   }
2366   elsif (ref $self->{cond} ne 'HASH') {
2367     $self->throw_exception(
2368       "Can't abstract implicit construct, resultset condition not a hash"
2369     );
2370   }
2371   else {
2372     # precendence must be given to passed values over values inherited from
2373     # the cond, so the order here is important.
2374     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2375     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2376
2377     while ( my($col, $value) = each %implied ) {
2378       my $vref = ref $value;
2379       if (
2380         $vref eq 'HASH'
2381           and
2382         keys(%$value) == 1
2383           and
2384         (keys %$value)[0] eq '='
2385       ) {
2386         $new_data{$col} = $value->{'='};
2387       }
2388       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2389         $new_data{$col} = $value;
2390       }
2391     }
2392   }
2393
2394   %new_data = (
2395     %new_data,
2396     %{ $self->_remove_alias($data, $alias) },
2397   );
2398
2399   return (\%new_data, \@cols_from_relations);
2400 }
2401
2402 # _has_resolved_attr
2403 #
2404 # determines if the resultset defines at least one
2405 # of the attributes supplied
2406 #
2407 # used to determine if a subquery is neccessary
2408 #
2409 # supports some virtual attributes:
2410 #   -join
2411 #     This will scan for any joins being present on the resultset.
2412 #     It is not a mere key-search but a deep inspection of {from}
2413 #
2414
2415 sub _has_resolved_attr {
2416   my ($self, @attr_names) = @_;
2417
2418   my $attrs = $self->_resolved_attrs;
2419
2420   my %extra_checks;
2421
2422   for my $n (@attr_names) {
2423     if (grep { $n eq $_ } (qw/-join/) ) {
2424       $extra_checks{$n}++;
2425       next;
2426     }
2427
2428     my $attr =  $attrs->{$n};
2429
2430     next if not defined $attr;
2431
2432     if (ref $attr eq 'HASH') {
2433       return 1 if keys %$attr;
2434     }
2435     elsif (ref $attr eq 'ARRAY') {
2436       return 1 if @$attr;
2437     }
2438     else {
2439       return 1 if $attr;
2440     }
2441   }
2442
2443   # a resolved join is expressed as a multi-level from
2444   return 1 if (
2445     $extra_checks{-join}
2446       and
2447     ref $attrs->{from} eq 'ARRAY'
2448       and
2449     @{$attrs->{from}} > 1
2450   );
2451
2452   return 0;
2453 }
2454
2455 # _collapse_cond
2456 #
2457 # Recursively collapse the condition.
2458
2459 sub _collapse_cond {
2460   my ($self, $cond, $collapsed) = @_;
2461
2462   $collapsed ||= {};
2463
2464   if (ref $cond eq 'ARRAY') {
2465     foreach my $subcond (@$cond) {
2466       next unless ref $subcond;  # -or
2467       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2468     }
2469   }
2470   elsif (ref $cond eq 'HASH') {
2471     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2472       foreach my $subcond (@{$cond->{-and}}) {
2473         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2474       }
2475     }
2476     else {
2477       foreach my $col (keys %$cond) {
2478         my $value = $cond->{$col};
2479         $collapsed->{$col} = $value;
2480       }
2481     }
2482   }
2483
2484   return $collapsed;
2485 }
2486
2487 # _remove_alias
2488 #
2489 # Remove the specified alias from the specified query hash. A copy is made so
2490 # the original query is not modified.
2491
2492 sub _remove_alias {
2493   my ($self, $query, $alias) = @_;
2494
2495   my %orig = %{ $query || {} };
2496   my %unaliased;
2497
2498   foreach my $key (keys %orig) {
2499     if ($key !~ /\./) {
2500       $unaliased{$key} = $orig{$key};
2501       next;
2502     }
2503     $unaliased{$1} = $orig{$key}
2504       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2505   }
2506
2507   return \%unaliased;
2508 }
2509
2510 =head2 as_query
2511
2512 =over 4
2513
2514 =item Arguments: none
2515
2516 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2517
2518 =back
2519
2520 Returns the SQL query and bind vars associated with the invocant.
2521
2522 This is generally used as the RHS for a subquery.
2523
2524 =cut
2525
2526 sub as_query {
2527   my $self = shift;
2528
2529   my $attrs = $self->_resolved_attrs_copy;
2530
2531   # For future use:
2532   #
2533   # in list ctx:
2534   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2535   # $sql also has no wrapping parenthesis in list ctx
2536   #
2537   my $sqlbind = $self->result_source->storage
2538     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2539
2540   return $sqlbind;
2541 }
2542
2543 =head2 find_or_new
2544
2545 =over 4
2546
2547 =item Arguments: \%vals, \%attrs?
2548
2549 =item Return Value: $rowobject
2550
2551 =back
2552
2553   my $artist = $schema->resultset('Artist')->find_or_new(
2554     { artist => 'fred' }, { key => 'artists' });
2555
2556   $cd->cd_to_producer->find_or_new({ producer => $producer },
2557                                    { key => 'primary });
2558
2559 Find an existing record from this resultset using L</find>. if none exists,
2560 instantiate a new result object and return it. The object will not be saved
2561 into your storage until you call L<DBIx::Class::Row/insert> on it.
2562
2563 You most likely want this method when looking for existing rows using a unique
2564 constraint that is not the primary key, or looking for related rows.
2565
2566 If you want objects to be saved immediately, use L</find_or_create> instead.
2567
2568 B<Note>: Make sure to read the documentation of L</find> and understand the
2569 significance of the C<key> attribute, as its lack may skew your search, and
2570 subsequently result in spurious new objects.
2571
2572 B<Note>: Take care when using C<find_or_new> with a table having
2573 columns with default values that you intend to be automatically
2574 supplied by the database (e.g. an auto_increment primary key column).
2575 In normal usage, the value of such columns should NOT be included at
2576 all in the call to C<find_or_new>, even when set to C<undef>.
2577
2578 =cut
2579
2580 sub find_or_new {
2581   my $self     = shift;
2582   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2583   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2584   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2585     return $row;
2586   }
2587   return $self->new_result($hash);
2588 }
2589
2590 =head2 create
2591
2592 =over 4
2593
2594 =item Arguments: \%vals
2595
2596 =item Return Value: a L<DBIx::Class::Row> $object
2597
2598 =back
2599
2600 Attempt to create a single new row or a row with multiple related rows
2601 in the table represented by the resultset (and related tables). This
2602 will not check for duplicate rows before inserting, use
2603 L</find_or_create> to do that.
2604
2605 To create one row for this resultset, pass a hashref of key/value
2606 pairs representing the columns of the table and the values you wish to
2607 store. If the appropriate relationships are set up, foreign key fields
2608 can also be passed an object representing the foreign row, and the
2609 value will be set to its primary key.
2610
2611 To create related objects, pass a hashref of related-object column values
2612 B<keyed on the relationship name>. If the relationship is of type C<multi>
2613 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2614 The process will correctly identify columns holding foreign keys, and will
2615 transparently populate them from the keys of the corresponding relation.
2616 This can be applied recursively, and will work correctly for a structure
2617 with an arbitrary depth and width, as long as the relationships actually
2618 exists and the correct column data has been supplied.
2619
2620 Instead of hashrefs of plain related data (key/value pairs), you may
2621 also pass new or inserted objects. New objects (not inserted yet, see
2622 L</new>), will be inserted into their appropriate tables.
2623
2624 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2625
2626 Example of creating a new row.
2627
2628   $person_rs->create({
2629     name=>"Some Person",
2630     email=>"somebody@someplace.com"
2631   });
2632
2633 Example of creating a new row and also creating rows in a related C<has_many>
2634 or C<has_one> resultset.  Note Arrayref.
2635
2636   $artist_rs->create(
2637      { artistid => 4, name => 'Manufactured Crap', cds => [
2638         { title => 'My First CD', year => 2006 },
2639         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2640       ],
2641      },
2642   );
2643
2644 Example of creating a new row and also creating a row in a related
2645 C<belongs_to> resultset. Note Hashref.
2646
2647   $cd_rs->create({
2648     title=>"Music for Silly Walks",
2649     year=>2000,
2650     artist => {
2651       name=>"Silly Musician",
2652     }
2653   });
2654
2655 =over
2656
2657 =item WARNING
2658
2659 When subclassing ResultSet never attempt to override this method. Since
2660 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2661 lot of the internals simply never call it, so your override will be
2662 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2663 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2664 L</create> process you need to intervene. See also warning pertaining to
2665 L</new>.
2666
2667 =back
2668
2669 =cut
2670
2671 sub create {
2672   my ($self, $attrs) = @_;
2673   $self->throw_exception( "create needs a hashref" )
2674     unless ref $attrs eq 'HASH';
2675   return $self->new_result($attrs)->insert;
2676 }
2677
2678 =head2 find_or_create
2679
2680 =over 4
2681
2682 =item Arguments: \%vals, \%attrs?
2683
2684 =item Return Value: $rowobject
2685
2686 =back
2687
2688   $cd->cd_to_producer->find_or_create({ producer => $producer },
2689                                       { key => 'primary' });
2690
2691 Tries to find a record based on its primary key or unique constraints; if none
2692 is found, creates one and returns that instead.
2693
2694   my $cd = $schema->resultset('CD')->find_or_create({
2695     cdid   => 5,
2696     artist => 'Massive Attack',
2697     title  => 'Mezzanine',
2698     year   => 2005,
2699   });
2700
2701 Also takes an optional C<key> attribute, to search by a specific key or unique
2702 constraint. For example:
2703
2704   my $cd = $schema->resultset('CD')->find_or_create(
2705     {
2706       artist => 'Massive Attack',
2707       title  => 'Mezzanine',
2708     },
2709     { key => 'cd_artist_title' }
2710   );
2711
2712 B<Note>: Make sure to read the documentation of L</find> and understand the
2713 significance of the C<key> attribute, as its lack may skew your search, and
2714 subsequently result in spurious row creation.
2715
2716 B<Note>: Because find_or_create() reads from the database and then
2717 possibly inserts based on the result, this method is subject to a race
2718 condition. Another process could create a record in the table after
2719 the find has completed and before the create has started. To avoid
2720 this problem, use find_or_create() inside a transaction.
2721
2722 B<Note>: Take care when using C<find_or_create> with a table having
2723 columns with default values that you intend to be automatically
2724 supplied by the database (e.g. an auto_increment primary key column).
2725 In normal usage, the value of such columns should NOT be included at
2726 all in the call to C<find_or_create>, even when set to C<undef>.
2727
2728 See also L</find> and L</update_or_create>. For information on how to declare
2729 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2730
2731 If you need to know if an existing row was found or a new one created use
2732 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2733 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2734 database!
2735
2736   my $cd = $schema->resultset('CD')->find_or_new({
2737     cdid   => 5,
2738     artist => 'Massive Attack',
2739     title  => 'Mezzanine',
2740     year   => 2005,
2741   });
2742
2743   if( !$cd->in_storage ) {
2744       # do some stuff
2745       $cd->insert;
2746   }
2747
2748 =cut
2749
2750 sub find_or_create {
2751   my $self     = shift;
2752   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2753   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2754   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2755     return $row;
2756   }
2757   return $self->create($hash);
2758 }
2759
2760 =head2 update_or_create
2761
2762 =over 4
2763
2764 =item Arguments: \%col_values, { key => $unique_constraint }?
2765
2766 =item Return Value: $row_object
2767
2768 =back
2769
2770   $resultset->update_or_create({ col => $val, ... });
2771
2772 Like L</find_or_create>, but if a row is found it is immediately updated via
2773 C<< $found_row->update (\%col_values) >>.
2774
2775
2776 Takes an optional C<key> attribute to search on a specific unique constraint.
2777 For example:
2778
2779   # In your application
2780   my $cd = $schema->resultset('CD')->update_or_create(
2781     {
2782       artist => 'Massive Attack',
2783       title  => 'Mezzanine',
2784       year   => 1998,
2785     },
2786     { key => 'cd_artist_title' }
2787   );
2788
2789   $cd->cd_to_producer->update_or_create({
2790     producer => $producer,
2791     name => 'harry',
2792   }, {
2793     key => 'primary',
2794   });
2795
2796 B<Note>: Make sure to read the documentation of L</find> and understand the
2797 significance of the C<key> attribute, as its lack may skew your search, and
2798 subsequently result in spurious row creation.
2799
2800 B<Note>: Take care when using C<update_or_create> with a table having
2801 columns with default values that you intend to be automatically
2802 supplied by the database (e.g. an auto_increment primary key column).
2803 In normal usage, the value of such columns should NOT be included at
2804 all in the call to C<update_or_create>, even when set to C<undef>.
2805
2806 See also L</find> and L</find_or_create>. For information on how to declare
2807 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2808
2809 If you need to know if an existing row was updated or a new one created use
2810 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2811 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2812 database!
2813
2814 =cut
2815
2816 sub update_or_create {
2817   my $self = shift;
2818   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2819   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2820
2821   my $row = $self->find($cond, $attrs);
2822   if (defined $row) {
2823     $row->update($cond);
2824     return $row;
2825   }
2826
2827   return $self->create($cond);
2828 }
2829
2830 =head2 update_or_new
2831
2832 =over 4
2833
2834 =item Arguments: \%col_values, { key => $unique_constraint }?
2835
2836 =item Return Value: $rowobject
2837
2838 =back
2839
2840   $resultset->update_or_new({ col => $val, ... });
2841
2842 Like L</find_or_new> but if a row is found it is immediately updated via
2843 C<< $found_row->update (\%col_values) >>.
2844
2845 For example:
2846
2847   # In your application
2848   my $cd = $schema->resultset('CD')->update_or_new(
2849     {
2850       artist => 'Massive Attack',
2851       title  => 'Mezzanine',
2852       year   => 1998,
2853     },
2854     { key => 'cd_artist_title' }
2855   );
2856
2857   if ($cd->in_storage) {
2858       # the cd was updated
2859   }
2860   else {
2861       # the cd is not yet in the database, let's insert it
2862       $cd->insert;
2863   }
2864
2865 B<Note>: Make sure to read the documentation of L</find> and understand the
2866 significance of the C<key> attribute, as its lack may skew your search, and
2867 subsequently result in spurious new objects.
2868
2869 B<Note>: Take care when using C<update_or_new> with a table having
2870 columns with default values that you intend to be automatically
2871 supplied by the database (e.g. an auto_increment primary key column).
2872 In normal usage, the value of such columns should NOT be included at
2873 all in the call to C<update_or_new>, even when set to C<undef>.
2874
2875 See also L</find>, L</find_or_create> and L</find_or_new>.
2876
2877 =cut
2878
2879 sub update_or_new {
2880     my $self  = shift;
2881     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2882     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2883
2884     my $row = $self->find( $cond, $attrs );
2885     if ( defined $row ) {
2886         $row->update($cond);
2887         return $row;
2888     }
2889
2890     return $self->new_result($cond);
2891 }
2892
2893 =head2 get_cache
2894
2895 =over 4
2896
2897 =item Arguments: none
2898
2899 =item Return Value: \@cache_objects | undef
2900
2901 =back
2902
2903 Gets the contents of the cache for the resultset, if the cache is set.
2904
2905 The cache is populated either by using the L</prefetch> attribute to
2906 L</search> or by calling L</set_cache>.
2907
2908 =cut
2909
2910 sub get_cache {
2911   shift->{all_cache};
2912 }
2913
2914 =head2 set_cache
2915
2916 =over 4
2917
2918 =item Arguments: \@cache_objects
2919
2920 =item Return Value: \@cache_objects
2921
2922 =back
2923
2924 Sets the contents of the cache for the resultset. Expects an arrayref
2925 of objects of the same class as those produced by the resultset. Note that
2926 if the cache is set the resultset will return the cached objects rather
2927 than re-querying the database even if the cache attr is not set.
2928
2929 The contents of the cache can also be populated by using the
2930 L</prefetch> attribute to L</search>.
2931
2932 =cut
2933
2934 sub set_cache {
2935   my ( $self, $data ) = @_;
2936   $self->throw_exception("set_cache requires an arrayref")
2937       if defined($data) && (ref $data ne 'ARRAY');
2938   $self->{all_cache} = $data;
2939 }
2940
2941 =head2 clear_cache
2942
2943 =over 4
2944
2945 =item Arguments: none
2946
2947 =item Return Value: undef
2948
2949 =back
2950
2951 Clears the cache for the resultset.
2952
2953 =cut
2954
2955 sub clear_cache {
2956   shift->set_cache(undef);
2957 }
2958
2959 =head2 is_paged
2960
2961 =over 4
2962
2963 =item Arguments: none
2964
2965 =item Return Value: true, if the resultset has been paginated
2966
2967 =back
2968
2969 =cut
2970
2971 sub is_paged {
2972   my ($self) = @_;
2973   return !!$self->{attrs}{page};
2974 }
2975
2976 =head2 is_ordered
2977
2978 =over 4
2979
2980 =item Arguments: none
2981
2982 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2983
2984 =back
2985
2986 =cut
2987
2988 sub is_ordered {
2989   my ($self) = @_;
2990   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2991 }
2992
2993 =head2 related_resultset
2994
2995 =over 4
2996
2997 =item Arguments: $relationship_name
2998
2999 =item Return Value: $resultset
3000
3001 =back
3002
3003 Returns a related resultset for the supplied relationship name.
3004
3005   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3006
3007 =cut
3008
3009 sub related_resultset {
3010   my ($self, $rel) = @_;
3011
3012   $self->{related_resultsets} ||= {};
3013   return $self->{related_resultsets}{$rel} ||= do {
3014     my $rsrc = $self->result_source;
3015     my $rel_info = $rsrc->relationship_info($rel);
3016
3017     $self->throw_exception(
3018       "search_related: result source '" . $rsrc->source_name .
3019         "' has no such relationship $rel")
3020       unless $rel_info;
3021
3022     my $attrs = $self->_chain_relationship($rel);
3023
3024     my $join_count = $attrs->{seen_join}{$rel};
3025
3026     my $alias = $self->result_source->storage
3027         ->relname_to_table_alias($rel, $join_count);
3028
3029     # since this is search_related, and we already slid the select window inwards
3030     # (the select/as attrs were deleted in the beginning), we need to flip all
3031     # left joins to inner, so we get the expected results
3032     # read the comment on top of the actual function to see what this does
3033     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3034
3035
3036     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3037     delete @{$attrs}{qw(result_class alias)};
3038
3039     my $new_cache;
3040
3041     if (my $cache = $self->get_cache) {
3042       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3043         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
3044                         @$cache ];
3045       }
3046     }
3047
3048     my $rel_source = $rsrc->related_source($rel);
3049
3050     my $new = do {
3051
3052       # The reason we do this now instead of passing the alias to the
3053       # search_rs below is that if you wrap/overload resultset on the
3054       # source you need to know what alias it's -going- to have for things
3055       # to work sanely (e.g. RestrictWithObject wants to be able to add
3056       # extra query restrictions, and these may need to be $alias.)
3057
3058       my $rel_attrs = $rel_source->resultset_attributes;
3059       local $rel_attrs->{alias} = $alias;
3060
3061       $rel_source->resultset
3062                  ->search_rs(
3063                      undef, {
3064                        %$attrs,
3065                        where => $attrs->{where},
3066                    });
3067     };
3068     $new->set_cache($new_cache) if $new_cache;
3069     $new;
3070   };
3071 }
3072
3073 =head2 current_source_alias
3074
3075 =over 4
3076
3077 =item Arguments: none
3078
3079 =item Return Value: $source_alias
3080
3081 =back
3082
3083 Returns the current table alias for the result source this resultset is built
3084 on, that will be used in the SQL query. Usually it is C<me>.
3085
3086 Currently the source alias that refers to the result set returned by a
3087 L</search>/L</find> family method depends on how you got to the resultset: it's
3088 C<me> by default, but eg. L</search_related> aliases it to the related result
3089 source name (and keeps C<me> referring to the original result set). The long
3090 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3091 (and make this method unnecessary).
3092
3093 Thus it's currently necessary to use this method in predefined queries (see
3094 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3095 source alias of the current result set:
3096
3097   # in a result set class
3098   sub modified_by {
3099     my ($self, $user) = @_;
3100
3101     my $me = $self->current_source_alias;
3102
3103     return $self->search({
3104       "$me.modified" => $user->id,
3105     });
3106   }
3107
3108 =cut
3109
3110 sub current_source_alias {
3111   my ($self) = @_;
3112
3113   return ($self->{attrs} || {})->{alias} || 'me';
3114 }
3115
3116 =head2 as_subselect_rs
3117
3118 =over 4
3119
3120 =item Arguments: none
3121
3122 =item Return Value: $resultset
3123
3124 =back
3125
3126 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3127 "virtual view" by including it as a subquery within the from clause.  From this
3128 point on, any joined tables are inaccessible to ->search on the resultset (as if
3129 it were simply where-filtered without joins).  For example:
3130
3131  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3132
3133  # 'x' now pollutes the query namespace
3134
3135  # So the following works as expected
3136  my $ok_rs = $rs->search({'x.other' => 1});
3137
3138  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3139  # def) we look for one row with contradictory terms and join in another table
3140  # (aliased 'x_2') which we never use
3141  my $broken_rs = $rs->search({'x.name' => 'def'});
3142
3143  my $rs2 = $rs->as_subselect_rs;
3144
3145  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3146  my $not_joined_rs = $rs2->search({'x.other' => 1});
3147
3148  # works as expected: finds a 'table' row related to two x rows (abc and def)
3149  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3150
3151 Another example of when one might use this would be to select a subset of
3152 columns in a group by clause:
3153
3154  my $rs = $schema->resultset('Bar')->search(undef, {
3155    group_by => [qw{ id foo_id baz_id }],
3156  })->as_subselect_rs->search(undef, {
3157    columns => [qw{ id foo_id }]
3158  });
3159
3160 In the above example normally columns would have to be equal to the group by,
3161 but because we isolated the group by into a subselect the above works.
3162
3163 =cut
3164
3165 sub as_subselect_rs {
3166   my $self = shift;
3167
3168   my $attrs = $self->_resolved_attrs;
3169
3170   my $fresh_rs = (ref $self)->new (
3171     $self->result_source
3172   );
3173
3174   # these pieces will be locked in the subquery
3175   delete $fresh_rs->{cond};
3176   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3177
3178   return $fresh_rs->search( {}, {
3179     from => [{
3180       $attrs->{alias} => $self->as_query,
3181       -alias  => $attrs->{alias},
3182       -rsrc   => $self->result_source,
3183     }],
3184     alias => $attrs->{alias},
3185   });
3186 }
3187
3188 # This code is called by search_related, and makes sure there
3189 # is clear separation between the joins before, during, and
3190 # after the relationship. This information is needed later
3191 # in order to properly resolve prefetch aliases (any alias
3192 # with a relation_chain_depth less than the depth of the
3193 # current prefetch is not considered)
3194 #
3195 # The increments happen twice per join. An even number means a
3196 # relationship specified via a search_related, whereas an odd
3197 # number indicates a join/prefetch added via attributes
3198 #
3199 # Also this code will wrap the current resultset (the one we
3200 # chain to) in a subselect IFF it contains limiting attributes
3201 sub _chain_relationship {
3202   my ($self, $rel) = @_;
3203   my $source = $self->result_source;
3204   my $attrs = { %{$self->{attrs}||{}} };
3205
3206   # we need to take the prefetch the attrs into account before we
3207   # ->_resolve_join as otherwise they get lost - captainL
3208   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3209
3210   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3211
3212   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3213
3214   my $from;
3215   my @force_subq_attrs = qw/offset rows group_by having/;
3216
3217   if (
3218     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3219       ||
3220     $self->_has_resolved_attr (@force_subq_attrs)
3221   ) {
3222     # Nuke the prefetch (if any) before the new $rs attrs
3223     # are resolved (prefetch is useless - we are wrapping
3224     # a subquery anyway).
3225     my $rs_copy = $self->search;
3226     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3227       $rs_copy->{attrs}{join},
3228       delete $rs_copy->{attrs}{prefetch},
3229     );
3230
3231     $from = [{
3232       -rsrc   => $source,
3233       -alias  => $attrs->{alias},
3234       $attrs->{alias} => $rs_copy->as_query,
3235     }];
3236     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3237     $seen->{-relation_chain_depth} = 0;
3238   }
3239   elsif ($attrs->{from}) {  #shallow copy suffices
3240     $from = [ @{$attrs->{from}} ];
3241   }
3242   else {
3243     $from = [{
3244       -rsrc  => $source,
3245       -alias => $attrs->{alias},
3246       $attrs->{alias} => $source->from,
3247     }];
3248   }
3249
3250   my $jpath = ($seen->{-relation_chain_depth})
3251     ? $from->[-1][0]{-join_path}
3252     : [];
3253
3254   my @requested_joins = $source->_resolve_join(
3255     $join,
3256     $attrs->{alias},
3257     $seen,
3258     $jpath,
3259   );
3260
3261   push @$from, @requested_joins;
3262
3263   $seen->{-relation_chain_depth}++;
3264
3265   # if $self already had a join/prefetch specified on it, the requested
3266   # $rel might very well be already included. What we do in this case
3267   # is effectively a no-op (except that we bump up the chain_depth on
3268   # the join in question so we could tell it *is* the search_related)
3269   my $already_joined;
3270
3271   # we consider the last one thus reverse
3272   for my $j (reverse @requested_joins) {
3273     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3274     if ($rel eq $last_j) {
3275       $j->[0]{-relation_chain_depth}++;
3276       $already_joined++;
3277       last;
3278     }
3279   }
3280
3281   unless ($already_joined) {
3282     push @$from, $source->_resolve_join(
3283       $rel,
3284       $attrs->{alias},
3285       $seen,
3286       $jpath,
3287     );
3288   }
3289
3290   $seen->{-relation_chain_depth}++;
3291
3292   return {%$attrs, from => $from, seen_join => $seen};
3293 }
3294
3295 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3296 sub _resolved_attrs_copy {
3297   my $self = shift;
3298   return { %{$self->_resolved_attrs (@_)} };
3299 }
3300
3301 sub _resolved_attrs {
3302   my $self = shift;
3303   return $self->{_attrs} if $self->{_attrs};
3304
3305   my $attrs  = { %{ $self->{attrs} || {} } };
3306   my $source = $self->result_source;
3307   my $alias  = $attrs->{alias};
3308
3309   # default selection list
3310   $attrs->{columns} = [ $source->columns ]
3311     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3312
3313   # merge selectors together
3314   for (qw/columns select as/) {
3315     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3316       if $attrs->{$_} or $attrs->{"+$_"};
3317   }
3318
3319   # disassemble columns
3320   my (@sel, @as);
3321   if (my $cols = delete $attrs->{columns}) {
3322     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3323       if (ref $c eq 'HASH') {
3324         for my $as (sort keys %$c) {
3325           push @sel, $c->{$as};
3326           push @as, $as;
3327         }
3328       }
3329       else {
3330         push @sel, $c;
3331         push @as, $c;
3332       }
3333     }
3334   }
3335
3336   # when trying to weed off duplicates later do not go past this point -
3337   # everything added from here on is unbalanced "anyone's guess" stuff
3338   my $dedup_stop_idx = $#as;
3339
3340   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3341     if $attrs->{as};
3342   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3343     if $attrs->{select};
3344
3345   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3346   for (@sel) {
3347     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3348   }
3349
3350   # disqualify all $alias.col as-bits (collapser mandated)
3351   for (@as) {
3352     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3353   }
3354
3355   # de-duplicate the result (remove *identical* select/as pairs)
3356   # and also die on duplicate {as} pointing to different {select}s
3357   # not using a c-style for as the condition is prone to shrinkage
3358   my $seen;
3359   my $i = 0;
3360   while ($i <= $dedup_stop_idx) {
3361     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3362       splice @sel, $i, 1;
3363       splice @as, $i, 1;
3364       $dedup_stop_idx--;
3365     }
3366     elsif ($seen->{$as[$i]}++) {
3367       $self->throw_exception(
3368         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3369       );
3370     }
3371     else {
3372       $i++;
3373     }
3374   }
3375
3376   $attrs->{select} = \@sel;
3377   $attrs->{as} = \@as;
3378
3379   $attrs->{from} ||= [{
3380     -rsrc   => $source,
3381     -alias  => $self->{attrs}{alias},
3382     $self->{attrs}{alias} => $source->from,
3383   }];
3384
3385   if ( $attrs->{join} || $attrs->{prefetch} ) {
3386
3387     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3388       if ref $attrs->{from} ne 'ARRAY';
3389
3390     my $join = (delete $attrs->{join}) || {};
3391
3392     if ( defined $attrs->{prefetch} ) {
3393       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3394     }
3395
3396     $attrs->{from} =    # have to copy here to avoid corrupting the original
3397       [
3398         @{ $attrs->{from} },
3399         $source->_resolve_join(
3400           $join,
3401           $alias,
3402           { %{ $attrs->{seen_join} || {} } },
3403           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3404             ? $attrs->{from}[-1][0]{-join_path}
3405             : []
3406           ,
3407         )
3408       ];
3409   }
3410
3411   if ( defined $attrs->{order_by} ) {
3412     $attrs->{order_by} = (
3413       ref( $attrs->{order_by} ) eq 'ARRAY'
3414       ? [ @{ $attrs->{order_by} } ]
3415       : [ $attrs->{order_by} || () ]
3416     );
3417   }
3418
3419   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3420     $attrs->{group_by} = [ $attrs->{group_by} ];
3421   }
3422
3423   # generate the distinct induced group_by early, as prefetch will be carried via a
3424   # subquery (since a group_by is present)
3425   if (delete $attrs->{distinct}) {
3426     if ($attrs->{group_by}) {
3427       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3428     }
3429     else {
3430       # distinct affects only the main selection part, not what prefetch may
3431       # add below.
3432       $attrs->{group_by} = $source->storage->_group_over_selection (
3433         $attrs->{from},
3434         $attrs->{select},
3435         $attrs->{order_by},
3436       );
3437     }
3438   }
3439
3440   $attrs->{collapse} ||= {};
3441   if ($attrs->{prefetch}) {
3442
3443     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3444       if $attrs->{_dark_selector};
3445
3446     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3447
3448     my $prefetch_ordering = [];
3449
3450     # this is a separate structure (we don't look in {from} directly)
3451     # as the resolver needs to shift things off the lists to work
3452     # properly (identical-prefetches on different branches)
3453     my $join_map = {};
3454     if (ref $attrs->{from} eq 'ARRAY') {
3455
3456       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3457
3458       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3459         next unless $j->[0]{-alias};
3460         next unless $j->[0]{-join_path};
3461         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3462
3463         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3464
3465         my $p = $join_map;
3466         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3467         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3468       }
3469     }
3470
3471     my @prefetch =
3472       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3473
3474     # we need to somehow mark which columns came from prefetch
3475     if (@prefetch) {
3476       my $sel_end = $#{$attrs->{select}};
3477       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3478     }
3479
3480     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3481     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3482
3483     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3484     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3485   }
3486
3487   # if both page and offset are specified, produce a combined offset
3488   # even though it doesn't make much sense, this is what pre 081xx has
3489   # been doing
3490   if (my $page = delete $attrs->{page}) {
3491     $attrs->{offset} =
3492       ($attrs->{rows} * ($page - 1))
3493             +
3494       ($attrs->{offset} || 0)
3495     ;
3496   }
3497
3498   return $self->{_attrs} = $attrs;
3499 }
3500
3501 sub _rollout_attr {
3502   my ($self, $attr) = @_;
3503
3504   if (ref $attr eq 'HASH') {
3505     return $self->_rollout_hash($attr);
3506   } elsif (ref $attr eq 'ARRAY') {
3507     return $self->_rollout_array($attr);
3508   } else {
3509     return [$attr];
3510   }
3511 }
3512
3513 sub _rollout_array {
3514   my ($self, $attr) = @_;
3515
3516   my @rolled_array;
3517   foreach my $element (@{$attr}) {
3518     if (ref $element eq 'HASH') {
3519       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3520     } elsif (ref $element eq 'ARRAY') {
3521       #  XXX - should probably recurse here
3522       push( @rolled_array, @{$self->_rollout_array($element)} );
3523     } else {
3524       push( @rolled_array, $element );
3525     }
3526   }
3527   return \@rolled_array;
3528 }
3529
3530 sub _rollout_hash {
3531   my ($self, $attr) = @_;
3532
3533   my @rolled_array;
3534   foreach my $key (keys %{$attr}) {
3535     push( @rolled_array, { $key => $attr->{$key} } );
3536   }
3537   return \@rolled_array;
3538 }
3539
3540 sub _calculate_score {
3541   my ($self, $a, $b) = @_;
3542
3543   if (defined $a xor defined $b) {
3544     return 0;
3545   }
3546   elsif (not defined $a) {
3547     return 1;
3548   }
3549
3550   if (ref $b eq 'HASH') {
3551     my ($b_key) = keys %{$b};
3552     if (ref $a eq 'HASH') {
3553       my ($a_key) = keys %{$a};
3554       if ($a_key eq $b_key) {
3555         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3556       } else {
3557         return 0;
3558       }
3559     } else {
3560       return ($a eq $b_key) ? 1 : 0;
3561     }
3562   } else {
3563     if (ref $a eq 'HASH') {
3564       my ($a_key) = keys %{$a};
3565       return ($b eq $a_key) ? 1 : 0;
3566     } else {
3567       return ($b eq $a) ? 1 : 0;
3568     }
3569   }
3570 }
3571
3572 sub _merge_joinpref_attr {
3573   my ($self, $orig, $import) = @_;
3574
3575   return $import unless defined($orig);
3576   return $orig unless defined($import);
3577
3578   $orig = $self->_rollout_attr($orig);
3579   $import = $self->_rollout_attr($import);
3580
3581   my $seen_keys;
3582   foreach my $import_element ( @{$import} ) {
3583     # find best candidate from $orig to merge $b_element into
3584     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3585     foreach my $orig_element ( @{$orig} ) {
3586       my $score = $self->_calculate_score( $orig_element, $import_element );
3587       if ($score > $best_candidate->{score}) {
3588         $best_candidate->{position} = $position;
3589         $best_candidate->{score} = $score;
3590       }
3591       $position++;
3592     }
3593     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3594     $import_key = '' if not defined $import_key;
3595
3596     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3597       push( @{$orig}, $import_element );
3598     } else {
3599       my $orig_best = $orig->[$best_candidate->{position}];
3600       # merge orig_best and b_element together and replace original with merged
3601       if (ref $orig_best ne 'HASH') {
3602         $orig->[$best_candidate->{position}] = $import_element;
3603       } elsif (ref $import_element eq 'HASH') {
3604         my ($key) = keys %{$orig_best};
3605         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3606       }
3607     }
3608     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3609   }
3610
3611   return $orig;
3612 }
3613
3614 {
3615   my $hm;
3616
3617   sub _merge_attr {
3618     $hm ||= do {
3619       require Hash::Merge;
3620       my $hm = Hash::Merge->new;
3621
3622       $hm->specify_behavior({
3623         SCALAR => {
3624           SCALAR => sub {
3625             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3626
3627             if ($defl xor $defr) {
3628               return [ $defl ? $_[0] : $_[1] ];
3629             }
3630             elsif (! $defl) {
3631               return [];
3632             }
3633             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3634               return [ $_[0] ];
3635             }
3636             else {
3637               return [$_[0], $_[1]];
3638             }
3639           },
3640           ARRAY => sub {
3641             return $_[1] if !defined $_[0];
3642             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3643             return [$_[0], @{$_[1]}]
3644           },
3645           HASH  => sub {
3646             return [] if !defined $_[0] and !keys %{$_[1]};
3647             return [ $_[1] ] if !defined $_[0];
3648             return [ $_[0] ] if !keys %{$_[1]};
3649             return [$_[0], $_[1]]
3650           },
3651         },
3652         ARRAY => {
3653           SCALAR => sub {
3654             return $_[0] if !defined $_[1];
3655             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3656             return [@{$_[0]}, $_[1]]
3657           },
3658           ARRAY => sub {
3659             my @ret = @{$_[0]} or return $_[1];
3660             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3661             my %idx = map { $_ => 1 } @ret;
3662             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3663             \@ret;
3664           },
3665           HASH => sub {
3666             return [ $_[1] ] if ! @{$_[0]};
3667             return $_[0] if !keys %{$_[1]};
3668             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3669             return [ @{$_[0]}, $_[1] ];
3670           },
3671         },
3672         HASH => {
3673           SCALAR => sub {
3674             return [] if !keys %{$_[0]} and !defined $_[1];
3675             return [ $_[0] ] if !defined $_[1];
3676             return [ $_[1] ] if !keys %{$_[0]};
3677             return [$_[0], $_[1]]
3678           },
3679           ARRAY => sub {
3680             return [] if !keys %{$_[0]} and !@{$_[1]};
3681             return [ $_[0] ] if !@{$_[1]};
3682             return $_[1] if !keys %{$_[0]};
3683             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3684             return [ $_[0], @{$_[1]} ];
3685           },
3686           HASH => sub {
3687             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3688             return [ $_[0] ] if !keys %{$_[1]};
3689             return [ $_[1] ] if !keys %{$_[0]};
3690             return [ $_[0] ] if $_[0] eq $_[1];
3691             return [ $_[0], $_[1] ];
3692           },
3693         }
3694       } => 'DBIC_RS_ATTR_MERGER');
3695       $hm;
3696     };
3697
3698     return $hm->merge ($_[1], $_[2]);
3699   }
3700 }
3701
3702 sub STORABLE_freeze {
3703   my ($self, $cloning) = @_;
3704   my $to_serialize = { %$self };
3705
3706   # A cursor in progress can't be serialized (and would make little sense anyway)
3707   delete $to_serialize->{cursor};
3708
3709   # nor is it sensical to store a not-yet-fired-count pager
3710   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3711     delete $to_serialize->{pager};
3712   }
3713
3714   Storable::nfreeze($to_serialize);
3715 }
3716
3717 # need this hook for symmetry
3718 sub STORABLE_thaw {
3719   my ($self, $cloning, $serialized) = @_;
3720
3721   %$self = %{ Storable::thaw($serialized) };
3722
3723   $self;
3724 }
3725
3726
3727 =head2 throw_exception
3728
3729 See L<DBIx::Class::Schema/throw_exception> for details.
3730
3731 =cut
3732
3733 sub throw_exception {
3734   my $self=shift;
3735
3736   if (ref $self and my $rsrc = $self->result_source) {
3737     $rsrc->throw_exception(@_)
3738   }
3739   else {
3740     DBIx::Class::Exception->throw(@_);
3741   }
3742 }
3743
3744 # XXX: FIXME: Attributes docs need clearing up
3745
3746 =head1 ATTRIBUTES
3747
3748 Attributes are used to refine a ResultSet in various ways when
3749 searching for data. They can be passed to any method which takes an
3750 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3751 L</count>.
3752
3753 Default attributes can be set on the result class using
3754 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3755 the CAVEATS on that feature before using it!)
3756
3757 These are in no particular order:
3758
3759 =head2 order_by
3760
3761 =over 4
3762
3763 =item Value: ( $order_by | \@order_by | \%order_by )
3764
3765 =back
3766
3767 Which column(s) to order the results by.
3768
3769 [The full list of suitable values is documented in
3770 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3771 common options.]
3772
3773 If a single column name, or an arrayref of names is supplied, the
3774 argument is passed through directly to SQL. The hashref syntax allows
3775 for connection-agnostic specification of ordering direction:
3776
3777  For descending order:
3778
3779   order_by => { -desc => [qw/col1 col2 col3/] }
3780
3781  For explicit ascending order:
3782
3783   order_by => { -asc => 'col' }
3784
3785 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3786 supported, although you are strongly encouraged to use the hashref
3787 syntax as outlined above.
3788
3789 =head2 columns
3790
3791 =over 4
3792
3793 =item Value: \@columns
3794
3795 =back
3796
3797 Shortcut to request a particular set of columns to be retrieved. Each
3798 column spec may be a string (a table column name), or a hash (in which
3799 case the key is the C<as> value, and the value is used as the C<select>
3800 expression). Adds C<me.> onto the start of any column without a C<.> in
3801 it and sets C<select> from that, then auto-populates C<as> from
3802 C<select> as normal. (You may also use the C<cols> attribute, as in
3803 earlier versions of DBIC.)
3804
3805 Essentially C<columns> does the same as L</select> and L</as>.
3806
3807     columns => [ 'foo', { bar => 'baz' } ]
3808
3809 is the same as
3810
3811     select => [qw/foo baz/],
3812     as => [qw/foo bar/]
3813
3814 =head2 +columns
3815
3816 =over 4
3817
3818 =item Value: \@columns
3819
3820 =back
3821
3822 Indicates additional columns to be selected from storage. Works the same
3823 as L</columns> but adds columns to the selection. (You may also use the
3824 C<include_columns> attribute, as in earlier versions of DBIC). For
3825 example:-
3826
3827   $schema->resultset('CD')->search(undef, {
3828     '+columns' => ['artist.name'],
3829     join => ['artist']
3830   });
3831
3832 would return all CDs and include a 'name' column to the information
3833 passed to object inflation. Note that the 'artist' is the name of the
3834 column (or relationship) accessor, and 'name' is the name of the column
3835 accessor in the related table.
3836
3837 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3838 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3839 unary plus operator before it.
3840
3841 =head2 include_columns
3842
3843 =over 4
3844
3845 =item Value: \@columns
3846
3847 =back
3848
3849 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3850
3851 =head2 select
3852
3853 =over 4
3854
3855 =item Value: \@select_columns
3856
3857 =back
3858
3859 Indicates which columns should be selected from the storage. You can use
3860 column names, or in the case of RDBMS back ends, function or stored procedure
3861 names:
3862
3863   $rs = $schema->resultset('Employee')->search(undef, {
3864     select => [
3865       'name',
3866       { count => 'employeeid' },
3867       { max => { length => 'name' }, -as => 'longest_name' }
3868     ]
3869   });
3870
3871   # Equivalent SQL
3872   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3873
3874 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3875 use L</select>, to instruct DBIx::Class how to store the result of the column.
3876 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3877 identifier aliasing. You can however alias a function, so you can use it in
3878 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3879 attribute> supplied as shown in the example above.
3880
3881 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3882 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3883 unary plus operator before it.
3884
3885 =head2 +select
3886
3887 =over 4
3888
3889 Indicates additional columns to be selected from storage.  Works the same as
3890 L</select> but adds columns to the default selection, instead of specifying
3891 an explicit list.
3892
3893 =back
3894
3895 =head2 +as
3896
3897 =over 4
3898
3899 Indicates additional column names for those added via L</+select>. See L</as>.
3900
3901 =back
3902
3903 =head2 as
3904
3905 =over 4
3906
3907 =item Value: \@inflation_names
3908
3909 =back
3910
3911 Indicates column names for object inflation. That is L</as> indicates the
3912 slot name in which the column value will be stored within the
3913 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3914 identifier by the C<get_column> method (or via the object accessor B<if one
3915 with the same name already exists>) as shown below. The L</as> attribute has
3916 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3917
3918   $rs = $schema->resultset('Employee')->search(undef, {
3919     select => [
3920       'name',
3921       { count => 'employeeid' },
3922       { max => { length => 'name' }, -as => 'longest_name' }
3923     ],
3924     as => [qw/
3925       name
3926       employee_count
3927       max_name_length
3928     /],
3929   });
3930
3931 If the object against which the search is performed already has an accessor
3932 matching a column name specified in C<as>, the value can be retrieved using
3933 the accessor as normal:
3934
3935   my $name = $employee->name();
3936
3937 If on the other hand an accessor does not exist in the object, you need to
3938 use C<get_column> instead:
3939
3940   my $employee_count = $employee->get_column('employee_count');
3941
3942 You can create your own accessors if required - see
3943 L<DBIx::Class::Manual::Cookbook> for details.
3944
3945 =head2 join
3946
3947 =over 4
3948
3949 =item Value: ($rel_name | \@rel_names | \%rel_names)
3950
3951 =back
3952
3953 Contains a list of relationships that should be joined for this query.  For
3954 example:
3955
3956   # Get CDs by Nine Inch Nails
3957   my $rs = $schema->resultset('CD')->search(
3958     { 'artist.name' => 'Nine Inch Nails' },
3959     { join => 'artist' }
3960   );
3961
3962 Can also contain a hash reference to refer to the other relation's relations.
3963 For example:
3964
3965   package MyApp::Schema::Track;
3966   use base qw/DBIx::Class/;
3967   __PACKAGE__->table('track');
3968   __PACKAGE__->add_columns(qw/trackid cd position title/);
3969   __PACKAGE__->set_primary_key('trackid');
3970   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3971   1;
3972
3973   # In your application
3974   my $rs = $schema->resultset('Artist')->search(
3975     { 'track.title' => 'Teardrop' },
3976     {
3977       join     => { cd => 'track' },
3978       order_by => 'artist.name',
3979     }
3980   );
3981
3982 You need to use the relationship (not the table) name in  conditions,
3983 because they are aliased as such. The current table is aliased as "me", so
3984 you need to use me.column_name in order to avoid ambiguity. For example:
3985
3986   # Get CDs from 1984 with a 'Foo' track
3987   my $rs = $schema->resultset('CD')->search(
3988     {
3989       'me.year' => 1984,
3990       'tracks.name' => 'Foo'
3991     },
3992     { join => 'tracks' }
3993   );
3994
3995 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3996 similarly for a third time). For e.g.
3997
3998   my $rs = $schema->resultset('Artist')->search({
3999     'cds.title'   => 'Down to Earth',
4000     'cds_2.title' => 'Popular',
4001   }, {
4002     join => [ qw/cds cds/ ],
4003   });
4004
4005 will return a set of all artists that have both a cd with title 'Down
4006 to Earth' and a cd with title 'Popular'.
4007
4008 If you want to fetch related objects from other tables as well, see C<prefetch>
4009 below.
4010
4011  NOTE: An internal join-chain pruner will discard certain joins while
4012  constructing the actual SQL query, as long as the joins in question do not
4013  affect the retrieved result. This for example includes 1:1 left joins
4014  that are not part of the restriction specification (WHERE/HAVING) nor are
4015  a part of the query selection.
4016
4017 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4018
4019 =head2 prefetch
4020
4021 =over 4
4022
4023 =item Value: ($rel_name | \@rel_names | \%rel_names)
4024
4025 =back
4026
4027 Contains one or more relationships that should be fetched along with
4028 the main query (when they are accessed afterwards the data will
4029 already be available, without extra queries to the database).  This is
4030 useful for when you know you will need the related objects, because it
4031 saves at least one query:
4032
4033   my $rs = $schema->resultset('Tag')->search(
4034     undef,
4035     {
4036       prefetch => {
4037         cd => 'artist'
4038       }
4039     }
4040   );
4041
4042 The initial search results in SQL like the following:
4043
4044   SELECT tag.*, cd.*, artist.* FROM tag
4045   JOIN cd ON tag.cd = cd.cdid
4046   JOIN artist ON cd.artist = artist.artistid
4047
4048 L<DBIx::Class> has no need to go back to the database when we access the
4049 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4050 case.
4051
4052 Simple prefetches will be joined automatically, so there is no need
4053 for a C<join> attribute in the above search.
4054
4055 L</prefetch> can be used with the any of the relationship types and
4056 multiple prefetches can be specified together. Below is a more complex
4057 example that prefetches a CD's artist, its liner notes (if present),
4058 the cover image, the tracks on that cd, and the guests on those
4059 tracks.
4060
4061  # Assuming:
4062  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4063  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4064  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4065  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4066
4067  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4068
4069  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4070
4071
4072  my $rs = $schema->resultset('CD')->search(
4073    undef,
4074    {
4075      prefetch => [
4076        { artist => 'record_label'},  # belongs_to => belongs_to
4077        'liner_note',                 # might_have
4078        'cover_image',                # has_one
4079        { tracks => 'guests' },       # has_many => has_many
4080      ]
4081    }
4082  );
4083
4084 This will produce SQL like the following:
4085
4086  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4087         tracks.*, guests.*
4088    FROM cd me
4089    JOIN artist artist
4090      ON artist.artistid = me.artistid
4091    JOIN record_label record_label
4092      ON record_label.labelid = artist.labelid
4093    LEFT JOIN track tracks
4094      ON tracks.cdid = me.cdid
4095    LEFT JOIN guest guests
4096      ON guests.trackid = track.trackid
4097    LEFT JOIN liner_notes liner_note
4098      ON liner_note.cdid = me.cdid
4099    JOIN cd_artwork cover_image
4100      ON cover_image.cdid = me.cdid
4101  ORDER BY tracks.cd
4102
4103 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4104 C<tracks>, and C<guests> of the CD will all be available through the
4105 relationship accessors without the need for additional queries to the
4106 database.
4107
4108 However, there is one caveat to be observed: it can be dangerous to
4109 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4110 relationship on a given level. e.g.:
4111
4112  my $rs = $schema->resultset('CD')->search(
4113    undef,
4114    {
4115      prefetch => [
4116        'tracks',                         # has_many
4117        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4118      ]
4119    }
4120  );
4121
4122 In fact, C<DBIx::Class> will emit the following warning:
4123
4124  Prefetching multiple has_many rels tracks and cd_to_producer at top
4125  level will explode the number of row objects retrievable via ->next
4126  or ->all. Use at your own risk.
4127
4128 The collapser currently can't identify duplicate tuples for multiple
4129 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4130 result the second L<has_many|DBIx::Class::Relationship/has_many>
4131 relation could contain redundant objects.
4132
4133 =head3 Using L</prefetch> with L</join>
4134
4135 L</prefetch> implies a L</join> with the equivalent argument, and is
4136 properly merged with any existing L</join> specification. So the
4137 following:
4138
4139   my $rs = $schema->resultset('CD')->search(
4140    {'record_label.name' => 'Music Product Ltd.'},
4141    {
4142      join     => {artist => 'record_label'},
4143      prefetch => 'artist',
4144    }
4145  );
4146
4147 ... will work, searching on the record label's name, but only
4148 prefetching the C<artist>.
4149
4150 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4151
4152 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4153 prefetched relations.  So given:
4154
4155   my $rs = $schema->resultset('CD')->search(
4156    undef,
4157    {
4158      select   => ['cd.title'],
4159      as       => ['cd_title'],
4160      prefetch => 'artist',
4161    }
4162  );
4163
4164 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4165 becomes: C<'cd_title', 'artist.*'>.
4166
4167 =head3 CAVEATS
4168
4169 Prefetch does a lot of deep magic. As such, it may not behave exactly
4170 as you might expect.
4171
4172 =over 4
4173
4174 =item *
4175
4176 Prefetch uses the L</cache> to populate the prefetched relationships. This
4177 may or may not be what you want.
4178
4179 =item *
4180
4181 If you specify a condition on a prefetched relationship, ONLY those
4182 rows that match the prefetched condition will be fetched into that relationship.
4183 This means that adding prefetch to a search() B<may alter> what is returned by
4184 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4185
4186   my $artist_rs = $schema->resultset('Artist')->search({
4187       'cds.year' => 2008,
4188   }, {
4189       join => 'cds',
4190   });
4191
4192   my $count = $artist_rs->first->cds->count;
4193
4194   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4195
4196   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4197
4198   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4199
4200 that cmp_ok() may or may not pass depending on the datasets involved. This
4201 behavior may or may not survive the 0.09 transition.
4202
4203 =back
4204
4205 =head2 alias
4206
4207 =over 4
4208
4209 =item Value: $source_alias
4210
4211 =back
4212
4213 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4214 nested search queries (sub-SELECTs) might need specific aliases set to
4215 reference inner queries.  For example:
4216
4217    my $q = $rs
4218       ->related_resultset('CDs')
4219       ->related_resultset('Tracks')
4220       ->search({
4221          'track.id' => { -ident => 'none_search.id' },
4222       })
4223       ->as_query;
4224
4225    my $ids = $self->search({
4226       -not_exists => $q,
4227    }, {
4228       alias    => 'none_search',
4229       group_by => 'none_search.id',
4230    })->get_column('id')->as_query;
4231
4232    $self->search({ id => { -in => $ids } })
4233
4234 This attribute is directly tied to L</current_source_alias>.
4235
4236 =head2 page
4237
4238 =over 4
4239
4240 =item Value: $page
4241
4242 =back
4243
4244 Makes the resultset paged and specifies the page to retrieve. Effectively
4245 identical to creating a non-pages resultset and then calling ->page($page)
4246 on it.
4247
4248 If L</rows> attribute is not specified it defaults to 10 rows per page.
4249
4250 When you have a paged resultset, L</count> will only return the number
4251 of rows in the page. To get the total, use the L</pager> and call
4252 C<total_entries> on it.
4253
4254 =head2 rows
4255
4256 =over 4
4257
4258 =item Value: $rows
4259
4260 =back
4261
4262 Specifies the maximum number of rows for direct retrieval or the number of
4263 rows per page if the page attribute or method is used.
4264
4265 =head2 offset
4266
4267 =over 4
4268
4269 =item Value: $offset
4270
4271 =back
4272
4273 Specifies the (zero-based) row number for the  first row to be returned, or the
4274 of the first row of the first page if paging is used.
4275
4276 =head2 software_limit
4277
4278 =over 4
4279
4280 =item Value: (0 | 1)
4281
4282 =back
4283
4284 When combined with L</rows> and/or L</offset> the generated SQL will not
4285 include any limit dialect stanzas. Instead the entire result will be selected
4286 as if no limits were specified, and DBIC will perform the limit locally, by
4287 artificially advancing and finishing the resulting L</cursor>.
4288
4289 This is the recommended way of performing resultset limiting when no sane RDBMS
4290 implementation is available (e.g.
4291 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4292 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4293
4294 =head2 group_by
4295
4296 =over 4
4297
4298 =item Value: \@columns
4299
4300 =back
4301
4302 A arrayref of columns to group by. Can include columns of joined tables.
4303
4304   group_by => [qw/ column1 column2 ... /]
4305
4306 =head2 having
4307
4308 =over 4
4309
4310 =item Value: $condition
4311
4312 =back
4313
4314 HAVING is a select statement attribute that is applied between GROUP BY and
4315 ORDER BY. It is applied to the after the grouping calculations have been
4316 done.
4317
4318   having => { 'count_employee' => { '>=', 100 } }
4319
4320 or with an in-place function in which case literal SQL is required:
4321
4322   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4323
4324 =head2 distinct
4325
4326 =over 4
4327
4328 =item Value: (0 | 1)
4329
4330 =back
4331
4332 Set to 1 to group by all columns. If the resultset already has a group_by
4333 attribute, this setting is ignored and an appropriate warning is issued.
4334
4335 =head2 where
4336
4337 =over 4
4338
4339 Adds to the WHERE clause.
4340
4341   # only return rows WHERE deleted IS NULL for all searches
4342   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4343
4344 Can be overridden by passing C<< { where => undef } >> as an attribute
4345 to a resultset.
4346
4347 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4348
4349 =back
4350
4351 =head2 cache
4352
4353 Set to 1 to cache search results. This prevents extra SQL queries if you
4354 revisit rows in your ResultSet:
4355
4356   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4357
4358   while( my $artist = $resultset->next ) {
4359     ... do stuff ...
4360   }
4361
4362   $rs->first; # without cache, this would issue a query
4363
4364 By default, searches are not cached.
4365
4366 For more examples of using these attributes, see
4367 L<DBIx::Class::Manual::Cookbook>.
4368
4369 =head2 for
4370
4371 =over 4
4372
4373 =item Value: ( 'update' | 'shared' | \$scalar )
4374
4375 =back
4376
4377 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4378 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4379 query.
4380
4381 =head1 DBIC BIND VALUES
4382
4383 Because DBIC may need more information to bind values than just the column name
4384 and value itself, it uses a special format for both passing and receiving bind
4385 values.  Each bind value should be composed of an arrayref of
4386 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4387
4388 =over 4
4389
4390 =item dbd_attrs
4391
4392 If present (in any form), this is what is being passed directly to bind_param.
4393 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4394 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4395
4396 If this is specified, all other bind options described below are ignored.
4397
4398 =item sqlt_datatype
4399
4400 If present, this is used to infer the actual bind attribute by passing to
4401 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4402 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4403
4404 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4405 currently drivers are expected to "Do the Right Thing" when given a common
4406 datatype name.  (Not ideal, but that's what we got at this point.)
4407
4408 =item sqlt_size
4409
4410 Currently used to correctly allocate buffers for bind_param_inout().
4411 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4412 or to a sensible value based on the "data_type".
4413
4414 =item dbic_colname
4415
4416 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4417 explicitly specified they are never overriden).  Also used by some weird DBDs,
4418 where the column name should be available at bind_param time (e.g. Oracle).
4419
4420 =back
4421
4422 For backwards compatibility and convenience, the following shortcuts are
4423 supported:
4424
4425   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4426   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4427   [ undef,   $val ] === [ {}, $val ]
4428
4429 =head1 AUTHOR AND CONTRIBUTORS
4430
4431 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4432
4433 =head1 LICENSE
4434
4435 You may distribute this code under the same terms as Perl itself.
4436
4437 =cut
4438
4439 1;