lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  77
  78 If you want to make your custom ResultSet classes with L<Moose>, use a template
  79 similar to:
  80
  81     package MyApp::Schema::ResultSet::User;
  82
  83     use Moose;
  84     use namespace::autoclean;
  85     use MooseX::NonMoose;
  86     extends 'DBIx::Class::ResultSet';
  87
  88     sub BUILDARGS { $_[2] }
  89
  90     ...your code...
  91
  92     __PACKAGE__->meta->make_immutable;
  93
  94     1;
  95
  96 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
  97 clash with the regular ResultSet constructor. Alternatively, you can use:
  98
  99     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 100
 101 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 102 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 103
 104 =head1 EXAMPLES
 105
 106 =head2 Chaining resultsets
 107
 108 Let's say you've got a query that needs to be run to return some data
 109 to the user. But, you have an authorization system in place that
 110 prevents certain users from seeing certain information. So, you want
 111 to construct the basic query in one method, but add constraints to it in
 112 another.
 113
 114   sub get_data {
 115     my $self = shift;
 116     my $request = $self->get_request; # Get a request object somehow.
 117     my $schema = $self->result_source->schema;
 118
 119     my $cd_rs = $schema->resultset('CD')->search({
 120       title => $request->param('title'),
 121       year => $request->param('year'),
 122     });
 123
 124     $cd_rs = $self->apply_security_policy( $cd_rs );
 125
 126     return $cd_rs->all();
 127   }
 128
 129   sub apply_security_policy {
 130     my $self = shift;
 131     my ($rs) = @_;
 132
 133     return $rs->search({
 134       subversive => 0,
 135     });
 136   }
 137
 138 =head3 Resolving conditions and attributes
 139
 140 When a resultset is chained from another resultset, conditions and
 141 attributes with the same keys need resolving.
 142
 143 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 144 into the existing ones from the original resultset.
 145
 146 The L</where> and L</having> attributes, and any search conditions, are
 147 merged with an SQL C<AND> to the existing condition from the original
 148 resultset.
 149
 150 All other attributes are overridden by any new ones supplied in the
 151 search attributes.
 152
 153 =head2 Multiple queries
 154
 155 Since a resultset just defines a query, you can do all sorts of
 156 things with it with the same object.
 157
 158   # Don't hit the DB yet.
 159   my $cd_rs = $schema->resultset('CD')->search({
 160     title => 'something',
 161     year => 2009,
 162   });
 163
 164   # Each of these hits the DB individually.
 165   my $count = $cd_rs->count;
 166   my $most_recent = $cd_rs->get_column('date_released')->max();
 167   my @records = $cd_rs->all;
 168
 169 And it's not just limited to SELECT statements.
 170
 171   $cd_rs->delete();
 172
 173 This is even cooler:
 174
 175   $cd_rs->create({ artist => 'Fred' });
 176
 177 Which is the same as:
 178
 179   $schema->resultset('CD')->create({
 180     title => 'something',
 181     year => 2009,
 182     artist => 'Fred'
 183   });
 184
 185 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 186
 187 =head1 METHODS
 188
 189 =head2 new
 190
 191 =over 4
 192
 193 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 194
 195 =item Return Value: L<$resultset|/search>
 196
 197 =back
 198
 199 The resultset constructor. Takes a source object (usually a
 200 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 201 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 202 executed as needed by the other methods.
 203
 204 Generally you never construct a resultset manually. Instead you get one
 205 from e.g. a
 206 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 207 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 208 scalar context):
 209
 210   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 211
 212 =over
 213
 214 =item WARNING
 215
 216 If called on an object, proxies to L</new_result> instead, so
 217
 218   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 219
 220 will return a CD object, not a ResultSet, and is equivalent to:
 221
 222   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 223
 224 Please also keep in mind that many internals call L</new_result> directly,
 225 so overloading this method with the idea of intercepting new result object
 226 creation B<will not work>. See also warning pertaining to L</create>.
 227
 228 =back
 229
 230 =cut
 231
 232 sub new {
 233   my $class = shift;
 234   return $class->new_result(@_) if ref $class;
 235
 236   my ($source, $attrs) = @_;
 237   $source = $source->resolve
 238     if $source->isa('DBIx::Class::ResultSourceHandle');
 239   $attrs = { %{$attrs||{}} };
 240
 241   if ($attrs->{page}) {
 242     $attrs->{rows} ||= 10;
 243   }
 244
 245   $attrs->{alias} ||= 'me';
 246
 247   my $self = bless {
 248     result_source => $source,
 249     cond => $attrs->{where},
 250     pager => undef,
 251     attrs => $attrs,
 252   }, $class;
 253
 254   # if there is a dark selector, this means we are already in a
 255   # chain and the cleanup/sanification was taken care of by
 256   # _search_rs already
 257   $self->_normalize_selection($attrs)
 258     unless $attrs->{_dark_selector};
 259
 260   $self->result_class(
 261     $attrs->{result_class} || $source->result_class
 262   );
 263
 264   $self;
 265 }
 266
 267 =head2 search
 268
 269 =over 4
 270
 271 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 272
 273 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 274
 275 =back
 276
 277   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 278   my $new_rs = $cd_rs->search({ year => 2005 });
 279
 280   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 281                  # year = 2005 OR year = 2004
 282
 283 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 284 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 285 To avoid that, use L</search_rs>.
 286
 287 If you need to pass in additional attributes but no additional condition,
 288 call it as C<search(undef, \%attrs)>.
 289
 290   # "SELECT name, artistid FROM $artist_table"
 291   my @all_artists = $schema->resultset('Artist')->search(undef, {
 292     columns => [qw/name artistid/],
 293   });
 294
 295 For a list of attributes that can be passed to C<search>, see
 296 L</ATTRIBUTES>. For more examples of using this function, see
 297 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 298 documentation for the first argument, see L<SQL::Abstract>
 299 and its extension L<DBIx::Class::SQLMaker>.
 300
 301 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 302
 303 =head3 CAVEAT
 304
 305 Note that L</search> does not process/deflate any of the values passed in the
 306 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 307 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 308 manually that any value passed to this method will stringify to something the
 309 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 310 objects, for more info see:
 311 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 312
 313 =cut
 314
 315 sub search {
 316   my $self = shift;
 317   my $rs = $self->search_rs( @_ );
 318
 319   if (wantarray) {
 320     return $rs->all;
 321   }
 322   elsif (defined wantarray) {
 323     return $rs;
 324   }
 325   else {
 326     # we can be called by a relationship helper, which in
 327     # turn may be called in void context due to some braindead
 328     # overload or whatever else the user decided to be clever
 329     # at this particular day. Thus limit the exception to
 330     # external code calls only
 331     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 332       if (caller)[0] !~ /^\QDBIx::Class::/;
 333
 334     return ();
 335   }
 336 }
 337
 338 =head2 search_rs
 339
 340 =over 4
 341
 342 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 343
 344 =item Return Value: L<$resultset|/search>
 345
 346 =back
 347
 348 This method does the same exact thing as search() except it will
 349 always return a resultset, even in list context.
 350
 351 =cut
 352
 353 sub search_rs {
 354   my $self = shift;
 355
 356   my $rsrc = $self->result_source;
 357   my ($call_cond, $call_attrs);
 358
 359   # Special-case handling for (undef, undef) or (undef)
 360   # Note that (foo => undef) is valid deprecated syntax
 361   @_ = () if not scalar grep { defined $_ } @_;
 362
 363   # just a cond
 364   if (@_ == 1) {
 365     $call_cond = shift;
 366   }
 367   # fish out attrs in the ($condref, $attr) case
 368   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 369     ($call_cond, $call_attrs) = @_;
 370   }
 371   elsif (@_ % 2) {
 372     $self->throw_exception('Odd number of arguments to search')
 373   }
 374   # legacy search
 375   elsif (@_) {
 376     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 377       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 378
 379     for my $i (0 .. $#_) {
 380       next if $i % 2;
 381       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 382         if (! defined $_[$i] or ref $_[$i] ne '');
 383     }
 384
 385     $call_cond = { @_ };
 386   }
 387
 388   # see if we can keep the cache (no $rs changes)
 389   my $cache;
 390   my %safe = (alias => 1, cache => 1);
 391   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 392     ! defined $_[0]
 393       or
 394     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 395       or
 396     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 397   )) {
 398     $cache = $self->get_cache;
 399   }
 400
 401   my $old_attrs = { %{$self->{attrs}} };
 402   my $old_having = delete $old_attrs->{having};
 403   my $old_where = delete $old_attrs->{where};
 404
 405   my $new_attrs = { %$old_attrs };
 406
 407   # take care of call attrs (only if anything is changing)
 408   if ($call_attrs and keys %$call_attrs) {
 409
 410     # copy for _normalize_selection
 411     $call_attrs = { %$call_attrs };
 412
 413     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 414
 415     # reset the current selector list if new selectors are supplied
 416     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 417       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 418     }
 419
 420     # Normalize the new selector list (operates on the passed-in attr structure)
 421     # Need to do it on every chain instead of only once on _resolved_attrs, in
 422     # order to allow detection of empty vs partial 'as'
 423     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 424       if $old_attrs->{_dark_selector};
 425     $self->_normalize_selection ($call_attrs);
 426
 427     # start with blind overwriting merge, exclude selector attrs
 428     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 429     delete @{$new_attrs}{@selector_attrs};
 430
 431     for (@selector_attrs) {
 432       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 433         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 434     }
 435
 436     # older deprecated name, use only if {columns} is not there
 437     if (my $c = delete $new_attrs->{cols}) {
 438       if ($new_attrs->{columns}) {
 439         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 440       }
 441       else {
 442         $new_attrs->{columns} = $c;
 443       }
 444     }
 445
 446
 447     # join/prefetch use their own crazy merging heuristics
 448     foreach my $key (qw/join prefetch/) {
 449       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 450         if exists $call_attrs->{$key};
 451     }
 452
 453     # stack binds together
 454     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 455   }
 456
 457
 458   for ($old_where, $call_cond) {
 459     if (defined $_) {
 460       $new_attrs->{where} = $self->_stack_cond (
 461         $_, $new_attrs->{where}
 462       );
 463     }
 464   }
 465
 466   if (defined $old_having) {
 467     $new_attrs->{having} = $self->_stack_cond (
 468       $old_having, $new_attrs->{having}
 469     )
 470   }
 471
 472   my $rs = (ref $self)->new($rsrc, $new_attrs);
 473
 474   $rs->set_cache($cache) if ($cache);
 475
 476   return $rs;
 477 }
 478
 479 my $dark_sel_dumper;
 480 sub _normalize_selection {
 481   my ($self, $attrs) = @_;
 482
 483   # legacy syntax
 484   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 485     if exists $attrs->{include_columns};
 486
 487   # columns are always placed first, however
 488
 489   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 490   # delay the decision on whether to use a default select list ($rsrc->columns)
 491   # allowing stuff like the remove_columns helper to work
 492   #
 493   # select/as +select/+as pairs need special handling - the amount of select/as
 494   # elements in each pair does *not* have to be equal (think multicolumn
 495   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 496   # supplied at all) - try to infer the alias, either from the -as parameter
 497   # of the selector spec, or use the parameter whole if it looks like a column
 498   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 499   # is ok as well), but make sure no more additions to the 'as' chain take place
 500   for my $pref ('', '+') {
 501
 502     my ($sel, $as) = map {
 503       my $key = "${pref}${_}";
 504
 505       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 506         ? @{$attrs->{$key}}
 507         : $attrs->{$key} || ()
 508       ];
 509       delete $attrs->{$key};
 510       $val;
 511     } qw/select as/;
 512
 513     if (! @$as and ! @$sel ) {
 514       next;
 515     }
 516     elsif (@$as and ! @$sel) {
 517       $self->throw_exception(
 518         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 519       );
 520     }
 521     elsif( ! @$as ) {
 522       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 523       # if any @$as has been supplied we assume the user knows what (s)he is doing
 524       # and blindly keep stacking up pieces
 525       unless ($attrs->{_dark_selector}) {
 526         SELECTOR:
 527         for (@$sel) {
 528           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 529             push @$as, $_->{-as};
 530           }
 531           # assume any plain no-space, no-parenthesis string to be a column spec
 532           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 533           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 534             push @$as, $_;
 535           }
 536           # if all else fails - raise a flag that no more aliasing will be allowed
 537           else {
 538             $attrs->{_dark_selector} = {
 539               plus_stage => $pref,
 540               string => ($dark_sel_dumper ||= do {
 541                   require Data::Dumper::Concise;
 542                   Data::Dumper::Concise::DumperObject()->Indent(0);
 543                 })->Values([$_])->Dump
 544               ,
 545             };
 546             last SELECTOR;
 547           }
 548         }
 549       }
 550     }
 551     elsif (@$as < @$sel) {
 552       $self->throw_exception(
 553         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 554       );
 555     }
 556     elsif ($pref and $attrs->{_dark_selector}) {
 557       $self->throw_exception(
 558         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 559       );
 560     }
 561
 562
 563     # merge result
 564     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 565     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 566   }
 567 }
 568
 569 sub _stack_cond {
 570   my ($self, $left, $right) = @_;
 571
 572   # collapse single element top-level conditions
 573   # (single pass only, unlikely to need recursion)
 574   for ($left, $right) {
 575     if (ref $_ eq 'ARRAY') {
 576       if (@$_ == 0) {
 577         $_ = undef;
 578       }
 579       elsif (@$_ == 1) {
 580         $_ = $_->[0];
 581       }
 582     }
 583     elsif (ref $_ eq 'HASH') {
 584       my ($first, $more) = keys %$_;
 585
 586       # empty hash
 587       if (! defined $first) {
 588         $_ = undef;
 589       }
 590       # one element hash
 591       elsif (! defined $more) {
 592         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 593           $_ = $_->{'-and'};
 594         }
 595         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 596           $_ = $_->{'-or'};
 597         }
 598       }
 599     }
 600   }
 601
 602   # merge hashes with weeding out of duplicates (simple cases only)
 603   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 604
 605     # shallow copy to destroy
 606     $right = { %$right };
 607     for (grep { exists $right->{$_} } keys %$left) {
 608       # the use of eq_deeply here is justified - the rhs of an
 609       # expression can contain a lot of twisted weird stuff
 610       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 611     }
 612
 613     $right = undef unless keys %$right;
 614   }
 615
 616
 617   if (defined $left xor defined $right) {
 618     return defined $left ? $left : $right;
 619   }
 620   elsif (! defined $left) {
 621     return undef;
 622   }
 623   else {
 624     return { -and => [ $left, $right ] };
 625   }
 626 }
 627
 628 =head2 search_literal
 629
 630 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 631 should only be used in that context. C<search_literal> is a convenience
 632 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 633 want to ensure columns are bound correctly, use L</search>.
 634
 635 See L<DBIx::Class::Manual::Cookbook/Searching> and
 636 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 637 require C<search_literal>.
 638
 639 =over 4
 640
 641 =item Arguments: $sql_fragment, @standalone_bind_values
 642
 643 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 644
 645 =back
 646
 647   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 648   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 649
 650 Pass a literal chunk of SQL to be added to the conditional part of the
 651 resultset query.
 652
 653 Example of how to use C<search> instead of C<search_literal>
 654
 655   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 656   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 657
 658 =cut
 659
 660 sub search_literal {
 661   my ($self, $sql, @bind) = @_;
 662   my $attr;
 663   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 664     $attr = pop @bind;
 665   }
 666   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 667 }
 668
 669 =head2 find
 670
 671 =over 4
 672
 673 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 674
 675 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 676
 677 =back
 678
 679 Finds and returns a single row based on supplied criteria. Takes either a
 680 hashref with the same format as L</create> (including inference of foreign
 681 keys from related objects), or a list of primary key values in the same
 682 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 683 declaration on the L</result_source>.
 684
 685 In either case an attempt is made to combine conditions already existing on
 686 the resultset with the condition passed to this method.
 687
 688 To aid with preparing the correct query for the storage you may supply the
 689 C<key> attribute, which is the name of a
 690 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 691 unique constraint corresponding to the
 692 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 693 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 694 to construct a query that satisfies the named unique constraint fully (
 695 non-NULL values for each column member of the constraint) an exception is
 696 thrown.
 697
 698 If no C<key> is specified, the search is carried over all unique constraints
 699 which are fully defined by the available condition.
 700
 701 If no such constraint is found, C<find> currently defaults to a simple
 702 C<< search->(\%column_values) >> which may or may not do what you expect.
 703 Note that this fallback behavior may be deprecated in further versions. If
 704 you need to search with arbitrary conditions - use L</search>. If the query
 705 resulting from this fallback produces more than one row, a warning to the
 706 effect is issued, though only the first row is constructed and returned as
 707 C<$result_object>.
 708
 709 In addition to C<key>, L</find> recognizes and applies standard
 710 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 711
 712 Note that if you have extra concerns about the correctness of the resulting
 713 query you need to specify the C<key> attribute and supply the entire condition
 714 as an argument to find (since it is not always possible to perform the
 715 combination of the resultset condition with the supplied one, especially if
 716 the resultset condition contains literal sql).
 717
 718 For example, to find a row by its primary key:
 719
 720   my $cd = $schema->resultset('CD')->find(5);
 721
 722 You can also find a row by a specific unique constraint:
 723
 724   my $cd = $schema->resultset('CD')->find(
 725     {
 726       artist => 'Massive Attack',
 727       title  => 'Mezzanine',
 728     },
 729     { key => 'cd_artist_title' }
 730   );
 731
 732 See also L</find_or_create> and L</update_or_create>.
 733
 734 =cut
 735
 736 sub find {
 737   my $self = shift;
 738   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 739
 740   my $rsrc = $self->result_source;
 741
 742   my $constraint_name;
 743   if (exists $attrs->{key}) {
 744     $constraint_name = defined $attrs->{key}
 745       ? $attrs->{key}
 746       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 747     ;
 748   }
 749
 750   # Parse out the condition from input
 751   my $call_cond;
 752
 753   if (ref $_[0] eq 'HASH') {
 754     $call_cond = { %{$_[0]} };
 755   }
 756   else {
 757     # if only values are supplied we need to default to 'primary'
 758     $constraint_name = 'primary' unless defined $constraint_name;
 759
 760     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 761
 762     $self->throw_exception(
 763       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 764     ) unless @c_cols;
 765
 766     $self->throw_exception (
 767       'find() expects either a column/value hashref, or a list of values '
 768     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 769     ) unless @c_cols == @_;
 770
 771     $call_cond = {};
 772     @{$call_cond}{@c_cols} = @_;
 773   }
 774
 775   my %related;
 776   for my $key (keys %$call_cond) {
 777     if (
 778       my $keyref = ref($call_cond->{$key})
 779         and
 780       my $relinfo = $rsrc->relationship_info($key)
 781     ) {
 782       my $val = delete $call_cond->{$key};
 783
 784       next if $keyref eq 'ARRAY'; # has_many for multi_create
 785
 786       my $rel_q = $rsrc->_resolve_condition(
 787         $relinfo->{cond}, $val, $key, $key
 788       );
 789       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 790       @related{keys %$rel_q} = values %$rel_q;
 791     }
 792   }
 793
 794   # relationship conditions take precedence (?)
 795   @{$call_cond}{keys %related} = values %related;
 796
 797   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 798   my $final_cond;
 799   if (defined $constraint_name) {
 800     $final_cond = $self->_qualify_cond_columns (
 801
 802       $self->_build_unique_cond (
 803         $constraint_name,
 804         $call_cond,
 805       ),
 806
 807       $alias,
 808     );
 809   }
 810   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 811     # This means that we got here after a merger of relationship conditions
 812     # in ::Relationship::Base::search_related (the row method), and furthermore
 813     # the relationship is of the 'single' type. This means that the condition
 814     # provided by the relationship (already attached to $self) is sufficient,
 815     # as there can be only one row in the database that would satisfy the
 816     # relationship
 817   }
 818   else {
 819     # no key was specified - fall down to heuristics mode:
 820     # run through all unique queries registered on the resultset, and
 821     # 'OR' all qualifying queries together
 822     my (@unique_queries, %seen_column_combinations);
 823     for my $c_name ($rsrc->unique_constraint_names) {
 824       next if $seen_column_combinations{
 825         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 826       }++;
 827
 828       push @unique_queries, try {
 829         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 830       } || ();
 831     }
 832
 833     $final_cond = @unique_queries
 834       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 835       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 836     ;
 837   }
 838
 839   # Run the query, passing the result_class since it should propagate for find
 840   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 841   if ($rs->_resolved_attrs->{collapse}) {
 842     my $row = $rs->next;
 843     carp "Query returned more than one row" if $rs->next;
 844     return $row;
 845   }
 846   else {
 847     return $rs->single;
 848   }
 849 }
 850
 851 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 852 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 853 #
 854 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 855 # condition. It is provided for overrides until a saner way forward is devised
 856 #
 857 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 858 # the road. Please adjust your tests accordingly to catch this situation early
 859 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 860 #
 861 # The method will not be removed without an adequately complete replacement
 862 # for strict-mode enforcement
 863 sub _non_unique_find_fallback {
 864   my ($self, $cond, $attrs) = @_;
 865
 866   return $self->_qualify_cond_columns(
 867     $cond,
 868     exists $attrs->{alias}
 869       ? $attrs->{alias}
 870       : $self->{attrs}{alias}
 871   );
 872 }
 873
 874
 875 sub _qualify_cond_columns {
 876   my ($self, $cond, $alias) = @_;
 877
 878   my %aliased = %$cond;
 879   for (keys %aliased) {
 880     $aliased{"$alias.$_"} = delete $aliased{$_}
 881       if $_ !~ /\./;
 882   }
 883
 884   return \%aliased;
 885 }
 886
 887 sub _build_unique_cond {
 888   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 889
 890   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 891
 892   # combination may fail if $self->{cond} is non-trivial
 893   my ($final_cond) = try {
 894     $self->_merge_with_rscond ($extra_cond)
 895   } catch {
 896     +{ %$extra_cond }
 897   };
 898
 899   # trim out everything not in $columns
 900   $final_cond = { map {
 901     exists $final_cond->{$_}
 902       ? ( $_ => $final_cond->{$_} )
 903       : ()
 904   } @c_cols };
 905
 906   if (my @missing = grep
 907     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 908     (@c_cols)
 909   ) {
 910     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 911       $constraint_name,
 912       join (', ', map { "'$_'" } @missing),
 913     ) );
 914   }
 915
 916   if (
 917     !$croak_on_null
 918       and
 919     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 920       and
 921     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 922   ) {
 923     carp_unique ( sprintf (
 924       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 925     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 926     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 927       $constraint_name,
 928       join (', ', map { "'$_'" } @undefs),
 929     ));
 930   }
 931
 932   return $final_cond;
 933 }
 934
 935 =head2 search_related
 936
 937 =over 4
 938
 939 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 940
 941 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 942
 943 =back
 944
 945   $new_rs = $cd_rs->search_related('artist', {
 946     name => 'Emo-R-Us',
 947   });
 948
 949 Searches the specified relationship, optionally specifying a condition and
 950 attributes for matching records. See L</ATTRIBUTES> for more information.
 951
 952 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 953 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 954
 955 See also L</search_related_rs>.
 956
 957 =cut
 958
 959 sub search_related {
 960   return shift->related_resultset(shift)->search(@_);
 961 }
 962
 963 =head2 search_related_rs
 964
 965 This method works exactly the same as search_related, except that
 966 it guarantees a resultset, even in list context.
 967
 968 =cut
 969
 970 sub search_related_rs {
 971   return shift->related_resultset(shift)->search_rs(@_);
 972 }
 973
 974 =head2 cursor
 975
 976 =over 4
 977
 978 =item Arguments: none
 979
 980 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 981
 982 =back
 983
 984 Returns a storage-driven cursor to the given resultset. See
 985 L<DBIx::Class::Cursor> for more information.
 986
 987 =cut
 988
 989 sub cursor {
 990   my $self = shift;
 991
 992   return $self->{cursor} ||= do {
 993     my $attrs = { %{$self->_resolved_attrs } };
 994     $self->result_source->storage->select(
 995       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 996     );
 997   };
 998 }
 999
1000 =head2 single
1001
1002 =over 4
1003
1004 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1005
1006 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1007
1008 =back
1009
1010   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1011
1012 Inflates the first result without creating a cursor if the resultset has
1013 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1014 of L</search>.
1015
1016 While this method can take an optional search condition (just like L</search>)
1017 being a fast-code-path it does not recognize search attributes. If you need to
1018 add extra joins or similar, call L</search> and then chain-call L</single> on the
1019 L<DBIx::Class::ResultSet> returned.
1020
1021 =over
1022
1023 =item B<Note>
1024
1025 As of 0.08100, this method enforces the assumption that the preceding
1026 query returns only one row. If more than one row is returned, you will receive
1027 a warning:
1028
1029   Query returned more than one row
1030
1031 In this case, you should be using L</next> or L</find> instead, or if you really
1032 know what you are doing, use the L</rows> attribute to explicitly limit the size
1033 of the resultset.
1034
1035 This method will also throw an exception if it is called on a resultset prefetching
1036 has_many, as such a prefetch implies fetching multiple rows from the database in
1037 order to assemble the resulting object.
1038
1039 =back
1040
1041 =cut
1042
1043 sub single {
1044   my ($self, $where) = @_;
1045   if(@_ > 2) {
1046       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1047   }
1048
1049   my $attrs = { %{$self->_resolved_attrs} };
1050
1051   $self->throw_exception(
1052     'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
1053   ) if $attrs->{collapse};
1054
1055   if ($where) {
1056     if (defined $attrs->{where}) {
1057       $attrs->{where} = {
1058         '-and' =>
1059             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1060                $where, delete $attrs->{where} ]
1061       };
1062     } else {
1063       $attrs->{where} = $where;
1064     }
1065   }
1066
1067   my $data = [ $self->result_source->storage->select_single(
1068     $attrs->{from}, $attrs->{select},
1069     $attrs->{where}, $attrs
1070   )];
1071   return undef unless @$data;
1072   $self->{stashed_rows} = [ $data ];
1073   $self->_construct_objects->[0];
1074 }
1075
1076
1077 # _collapse_query
1078 #
1079 # Recursively collapse the query, accumulating values for each column.
1080
1081 sub _collapse_query {
1082   my ($self, $query, $collapsed) = @_;
1083
1084   $collapsed ||= {};
1085
1086   if (ref $query eq 'ARRAY') {
1087     foreach my $subquery (@$query) {
1088       next unless ref $subquery;  # -or
1089       $collapsed = $self->_collapse_query($subquery, $collapsed);
1090     }
1091   }
1092   elsif (ref $query eq 'HASH') {
1093     if (keys %$query and (keys %$query)[0] eq '-and') {
1094       foreach my $subquery (@{$query->{-and}}) {
1095         $collapsed = $self->_collapse_query($subquery, $collapsed);
1096       }
1097     }
1098     else {
1099       foreach my $col (keys %$query) {
1100         my $value = $query->{$col};
1101         $collapsed->{$col}{$value}++;
1102       }
1103     }
1104   }
1105
1106   return $collapsed;
1107 }
1108
1109 =head2 get_column
1110
1111 =over 4
1112
1113 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1114
1115 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1116
1117 =back
1118
1119   my $max_length = $rs->get_column('length')->max;
1120
1121 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1122
1123 =cut
1124
1125 sub get_column {
1126   my ($self, $column) = @_;
1127   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1128   return $new;
1129 }
1130
1131 =head2 search_like
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1136
1137 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1138
1139 =back
1140
1141   # WHERE title LIKE '%blue%'
1142   $cd_rs = $rs->search_like({ title => '%blue%'});
1143
1144 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1145 that this is simply a convenience method retained for ex Class::DBI users.
1146 You most likely want to use L</search> with specific operators.
1147
1148 For more information, see L<DBIx::Class::Manual::Cookbook>.
1149
1150 This method is deprecated and will be removed in 0.09. Use L</search()>
1151 instead. An example conversion is:
1152
1153   ->search_like({ foo => 'bar' });
1154
1155   # Becomes
1156
1157   ->search({ foo => { like => 'bar' } });
1158
1159 =cut
1160
1161 sub search_like {
1162   my $class = shift;
1163   carp_unique (
1164     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1165    .' Instead use ->search({ x => { -like => "y%" } })'
1166    .' (note the outer pair of {}s - they are important!)'
1167   );
1168   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1169   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1170   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1171   return $class->search($query, { %$attrs });
1172 }
1173
1174 =head2 slice
1175
1176 =over 4
1177
1178 =item Arguments: $first, $last
1179
1180 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1181
1182 =back
1183
1184 Returns a resultset or object list representing a subset of elements from the
1185 resultset slice is called on. Indexes are from 0, i.e., to get the first
1186 three records, call:
1187
1188   my ($one, $two, $three) = $rs->slice(0, 2);
1189
1190 =cut
1191
1192 sub slice {
1193   my ($self, $min, $max) = @_;
1194   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1195   $attrs->{offset} = $self->{attrs}{offset} || 0;
1196   $attrs->{offset} += $min;
1197   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1198   return $self->search(undef, $attrs);
1199   #my $slice = (ref $self)->new($self->result_source, $attrs);
1200   #return (wantarray ? $slice->all : $slice);
1201 }
1202
1203 =head2 next
1204
1205 =over 4
1206
1207 =item Arguments: none
1208
1209 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1210
1211 =back
1212
1213 Returns the next element in the resultset (C<undef> is there is none).
1214
1215 Can be used to efficiently iterate over records in the resultset:
1216
1217   my $rs = $schema->resultset('CD')->search;
1218   while (my $cd = $rs->next) {
1219     print $cd->title;
1220   }
1221
1222 Note that you need to store the resultset object, and call C<next> on it.
1223 Calling C<< resultset('Table')->next >> repeatedly will always return the
1224 first record from the resultset.
1225
1226 =cut
1227
1228 sub next {
1229   my ($self) = @_;
1230
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235
1236   if ($self->{attrs}{cache}) {
1237     delete $self->{pager};
1238     $self->{all_cache_position} = 1;
1239     return ($self->all)[0];
1240   }
1241
1242   return shift(@{$self->{stashed_objects}}) if @{ $self->{stashed_objects}||[] };
1243
1244   $self->{stashed_objects} = $self->_construct_objects
1245     or return undef;
1246
1247   return shift @{$self->{stashed_objects}};
1248 }
1249
1250 # Constructs as many objects as it can in one pass while respecting
1251 # cursor laziness. Several modes of operation:
1252 #
1253 # * Always builds everything present in @{$self->{stashed_rows}}
1254 # * If called with $fetch_all true - pulls everything off the cursor and
1255 #   builds all objects in one pass
1256 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1257 #   and if the resultset is ordered properly by the left side:
1258 #   * Fetches stuff off the cursor until the "master object" changes,
1259 #     and saves the last extra row (if any) in @{$self->{stashed_rows}}
1260 #   OR
1261 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1262 #     was requested (there is no other way to collapse except for an
1263 #     eager cursor)
1264 # * If no collapse is requested - just get the next row, construct and
1265 #   return
1266 sub _construct_objects {
1267   my ($self, $fetch_all) = @_;
1268
1269   my $rsrc = $self->result_source;
1270   my $attrs = $self->_resolved_attrs;
1271
1272   if (!$fetch_all and ! $attrs->{order_by} and $attrs->{collapse}) {
1273     # default order for collapsing unless the user asked for something
1274     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} $rsrc->primary_columns ];
1275     $attrs->{_ordered_for_collapse} = 1;
1276     $attrs->{_order_is_artificial} = 1;
1277   }
1278
1279   my $cursor = $self->cursor;
1280
1281   # this will be used as both initial raw-row collector AND as a RV of
1282   # _construct_objects. Not regrowing the array twice matters a lot...
1283   # a suprising amount actually
1284   my $rows = (delete $self->{stashed_rows}) || [];
1285   if ($fetch_all) {
1286     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1287     $rows = [ @$rows, $cursor->all ];
1288   }
1289   elsif (!$attrs->{collapse}) {
1290     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1291     push @$rows, do { my @r = $cursor->next; @r ? \@r : () }
1292       unless @$rows;
1293   }
1294   else {
1295     $attrs->{_ordered_for_collapse} ||= (!$attrs->{order_by}) ? undef : do {
1296       my $st = $rsrc->schema->storage;
1297       my @ord_cols = map
1298         { $_->[0] }
1299         ( $st->_extract_order_criteria($attrs->{order_by}) )
1300       ;
1301
1302       my $colinfos = $st->_resolve_column_info($attrs->{from}, \@ord_cols);
1303
1304       for (0 .. $#ord_cols) {
1305         if (
1306           ! $colinfos->{$ord_cols[$_]}
1307             or
1308           $colinfos->{$ord_cols[$_]}{-result_source} != $rsrc
1309         ) {
1310           splice @ord_cols, $_;
1311           last;
1312         }
1313       }
1314
1315       # since all we check here are the start of the order_by belonging to the
1316       # top level $rsrc, a present identifying set will mean that the resultset
1317       # is ordered by its leftmost table in a tsable manner
1318       (@ord_cols and $rsrc->_identifying_column_set({ map
1319         { $colinfos->{$_}{-colname} => $colinfos->{$_} }
1320         @ord_cols
1321       })) ? 1 : 0;
1322     };
1323
1324     if ($attrs->{_ordered_for_collapse}) {
1325       push @$rows, do { my @r = $cursor->next; @r ? \@r : () };
1326     }
1327     # instead of looping over ->next, use ->all in stealth mode
1328     # *without* calling a ->reset afterwards
1329     # FIXME - encapsulation breach, got to be a better way
1330     elsif (! $cursor->{_done}) {
1331       push @$rows, $cursor->all;
1332       $cursor->{_done} = 1;
1333       $fetch_all = 1;
1334     }
1335   }
1336
1337   return undef unless @$rows;
1338
1339   my $res_class = $self->result_class;
1340   my $inflator = $res_class->can ('inflate_result')
1341     or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1342
1343   my $infmap = $attrs->{as};
1344
1345   if (!$attrs->{collapse} and $attrs->{_single_object_inflation}) {
1346     # construct a much simpler array->hash folder for the one-table cases right here
1347
1348     # FIXME SUBOPTIMAL this is a very very very hot spot
1349     # while rather optimal we can *still* do much better, by
1350     # building a smarter [Row|HRI]::inflate_result(), and
1351     # switch to feeding it data via a much leaner interface
1352     #
1353     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1354     # this particular resultset size
1355     if (@$rows < 60) {
1356       my @as_idx = 0..$#$infmap;
1357       for my $r (@$rows) {
1358         $r = $inflator->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } @as_idx } );
1359       }
1360     }
1361     else {
1362       eval sprintf (
1363         '$_ = $inflator->($res_class, $rsrc, { %s }) for @$rows',
1364         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1365       );
1366     }
1367   }
1368   else {
1369     $self->{_row_parser} ||= eval sprintf 'sub { %s }', $rsrc->_mk_row_parser({
1370       inflate_map => $infmap,
1371       selection => $attrs->{select},
1372       collapse => $attrs->{collapse},
1373       premultiplied => $attrs->{_main_source_premultiplied},
1374     }) or die $@;
1375
1376     # modify $rows in-place, shrinking/extending as necessary
1377     $self->{_row_parser}->($rows, $fetch_all ? () : (
1378       # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1379       sub { my @r = $cursor->next or return; \@r }, # how the collapser gets more rows
1380       ($self->{stashed_rows} = []),                 # where does it stuff excess
1381     ));
1382
1383     $_ = $inflator->($res_class, $rsrc, @$_) for @$rows;
1384   }
1385
1386   # CDBI compat stuff
1387   if ($attrs->{record_filter}) {
1388     $_ = $attrs->{record_filter}->($_) for @$rows;
1389   }
1390
1391   return $rows;
1392 }
1393
1394 =head2 result_source
1395
1396 =over 4
1397
1398 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1399
1400 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1401
1402 =back
1403
1404 An accessor for the primary ResultSource object from which this ResultSet
1405 is derived.
1406
1407 =head2 result_class
1408
1409 =over 4
1410
1411 =item Arguments: $result_class?
1412
1413 =item Return Value: $result_class
1414
1415 =back
1416
1417 An accessor for the class to use when creating result objects. Defaults to
1418 C<< result_source->result_class >> - which in most cases is the name of the
1419 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1420
1421 Note that changing the result_class will also remove any components
1422 that were originally loaded in the source class via
1423 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1424 in the original source class will not run.
1425
1426 =cut
1427
1428 sub result_class {
1429   my ($self, $result_class) = @_;
1430   if ($result_class) {
1431     unless (ref $result_class) { # don't fire this for an object
1432       $self->ensure_class_loaded($result_class);
1433     }
1434     $self->_result_class($result_class);
1435     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1436     # permit the user to set result class on one result set only; it only
1437     # chains if provided to search()
1438     #$self->{attrs}{result_class} = $result_class if ref $self;
1439   }
1440   $self->_result_class;
1441 }
1442
1443 =head2 count
1444
1445 =over 4
1446
1447 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1448
1449 =item Return Value: $count
1450
1451 =back
1452
1453 Performs an SQL C<COUNT> with the same query as the resultset was built
1454 with to find the number of elements. Passing arguments is equivalent to
1455 C<< $rs->search ($cond, \%attrs)->count >>
1456
1457 =cut
1458
1459 sub count {
1460   my $self = shift;
1461   return $self->search(@_)->count if @_ and defined $_[0];
1462   return scalar @{ $self->get_cache } if $self->get_cache;
1463
1464   my $attrs = { %{ $self->_resolved_attrs } };
1465
1466   # this is a little optimization - it is faster to do the limit
1467   # adjustments in software, instead of a subquery
1468   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1469
1470   my $crs;
1471   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1472     $crs = $self->_count_subq_rs ($attrs);
1473   }
1474   else {
1475     $crs = $self->_count_rs ($attrs);
1476   }
1477   my $count = $crs->next;
1478
1479   $count -= $offset if $offset;
1480   $count = $rows if $rows and $rows < $count;
1481   $count = 0 if ($count < 0);
1482
1483   return $count;
1484 }
1485
1486 =head2 count_rs
1487
1488 =over 4
1489
1490 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1491
1492 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1493
1494 =back
1495
1496 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1497 This can be very handy for subqueries:
1498
1499   ->search( { amount => $some_rs->count_rs->as_query } )
1500
1501 As with regular resultsets the SQL query will be executed only after
1502 the resultset is accessed via L</next> or L</all>. That would return
1503 the same single value obtainable via L</count>.
1504
1505 =cut
1506
1507 sub count_rs {
1508   my $self = shift;
1509   return $self->search(@_)->count_rs if @_;
1510
1511   # this may look like a lack of abstraction (count() does about the same)
1512   # but in fact an _rs *must* use a subquery for the limits, as the
1513   # software based limiting can not be ported if this $rs is to be used
1514   # in a subquery itself (i.e. ->as_query)
1515   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1516     return $self->_count_subq_rs;
1517   }
1518   else {
1519     return $self->_count_rs;
1520   }
1521 }
1522
1523 #
1524 # returns a ResultSetColumn object tied to the count query
1525 #
1526 sub _count_rs {
1527   my ($self, $attrs) = @_;
1528
1529   my $rsrc = $self->result_source;
1530   $attrs ||= $self->_resolved_attrs;
1531
1532   my $tmp_attrs = { %$attrs };
1533   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1534   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1535
1536   # overwrite the selector (supplied by the storage)
1537   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1538   $tmp_attrs->{as} = 'count';
1539
1540   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1541
1542   return $tmp_rs;
1543 }
1544
1545 #
1546 # same as above but uses a subquery
1547 #
1548 sub _count_subq_rs {
1549   my ($self, $attrs) = @_;
1550
1551   my $rsrc = $self->result_source;
1552   $attrs ||= $self->_resolved_attrs;
1553
1554   my $sub_attrs = { %$attrs };
1555   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1556   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range order_by for/};
1557
1558   # if we multi-prefetch we group_by something unique, as this is what we would
1559   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1560   if ( $attrs->{collapse}  ) {
1561     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1562       $rsrc->_identifying_column_set || $self->throw_exception(
1563         'Unable to construct a unique group_by criteria properly collapsing the '
1564       . 'has_many prefetch before count()'
1565       );
1566     } ]
1567   }
1568
1569   # Calculate subquery selector
1570   if (my $g = $sub_attrs->{group_by}) {
1571
1572     my $sql_maker = $rsrc->storage->sql_maker;
1573
1574     # necessary as the group_by may refer to aliased functions
1575     my $sel_index;
1576     for my $sel (@{$attrs->{select}}) {
1577       $sel_index->{$sel->{-as}} = $sel
1578         if (ref $sel eq 'HASH' and $sel->{-as});
1579     }
1580
1581     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1582     # also look for named aggregates referred in the having clause
1583     # having often contains scalarrefs - thus parse it out entirely
1584     my @parts = @$g;
1585     if ($attrs->{having}) {
1586       local $sql_maker->{having_bind};
1587       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1588       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1589       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1590         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1591         # if we don't unset it we screw up retarded but unfortunately working
1592         # 'MAX(foo.bar)' => { '>', 3 }
1593         $sql_maker->{name_sep} = '';
1594       }
1595
1596       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1597
1598       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1599       my %seen_having;
1600
1601       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1602       # and if all fails for an utterly naive quoted scalar-with-function
1603       while ($having_sql =~ /
1604         $rquote $sep $lquote (.+?) $rquote
1605           |
1606         [\s,] \w+ \. (\w+) [\s,]
1607           |
1608         [\s,] $lquote (.+?) $rquote [\s,]
1609       /gx) {
1610         my $part = $1 || $2 || $3;  # one of them matched if we got here
1611         unless ($seen_having{$part}++) {
1612           push @parts, $part;
1613         }
1614       }
1615     }
1616
1617     for (@parts) {
1618       my $colpiece = $sel_index->{$_} || $_;
1619
1620       # unqualify join-based group_by's. Arcane but possible query
1621       # also horrible horrible hack to alias a column (not a func.)
1622       # (probably need to introduce SQLA syntax)
1623       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1624         my $as = $colpiece;
1625         $as =~ s/\./__/;
1626         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1627       }
1628       push @{$sub_attrs->{select}}, $colpiece;
1629     }
1630   }
1631   else {
1632     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1633     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1634   }
1635
1636   return $rsrc->resultset_class
1637                ->new ($rsrc, $sub_attrs)
1638                 ->as_subselect_rs
1639                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1640                   ->get_column ('count');
1641 }
1642
1643 sub _bool {
1644   return 1;
1645 }
1646
1647 =head2 count_literal
1648
1649 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1650 should only be used in that context. See L</search_literal> for further info.
1651
1652 =over 4
1653
1654 =item Arguments: $sql_fragment, @standalone_bind_values
1655
1656 =item Return Value: $count
1657
1658 =back
1659
1660 Counts the results in a literal query. Equivalent to calling L</search_literal>
1661 with the passed arguments, then L</count>.
1662
1663 =cut
1664
1665 sub count_literal { shift->search_literal(@_)->count; }
1666
1667 =head2 all
1668
1669 =over 4
1670
1671 =item Arguments: none
1672
1673 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1674
1675 =back
1676
1677 Returns all elements in the resultset.
1678
1679 =cut
1680
1681 sub all {
1682   my $self = shift;
1683   if(@_) {
1684     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1685   }
1686
1687   delete @{$self}{qw/stashed_rows stashed_objects/};
1688
1689   if (my $c = $self->get_cache) {
1690     return @$c;
1691   }
1692
1693   $self->cursor->reset;
1694
1695   my $objs = $self->_construct_objects('fetch_all') || [];
1696
1697   $self->set_cache($objs) if $self->{attrs}{cache};
1698
1699   return @$objs;
1700 }
1701
1702 =head2 reset
1703
1704 =over 4
1705
1706 =item Arguments: none
1707
1708 =item Return Value: $self
1709
1710 =back
1711
1712 Resets the resultset's cursor, so you can iterate through the elements again.
1713 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1714 another query.
1715
1716 =cut
1717
1718 sub reset {
1719   my ($self) = @_;
1720
1721   delete @{$self}{qw/stashed_rows stashed_objects/};
1722   $self->{all_cache_position} = 0;
1723   $self->cursor->reset;
1724   return $self;
1725 }
1726
1727 =head2 first
1728
1729 =over 4
1730
1731 =item Arguments: none
1732
1733 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1734
1735 =back
1736
1737 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1738 an object for the first result (or C<undef> if the resultset is empty).
1739
1740 =cut
1741
1742 sub first {
1743   return $_[0]->reset->next;
1744 }
1745
1746
1747 # _rs_update_delete
1748 #
1749 # Determines whether and what type of subquery is required for the $rs operation.
1750 # If grouping is necessary either supplies its own, or verifies the current one
1751 # After all is done delegates to the proper storage method.
1752
1753 sub _rs_update_delete {
1754   my ($self, $op, $values) = @_;
1755
1756   my $rsrc = $self->result_source;
1757   my $storage = $rsrc->schema->storage;
1758
1759   my $attrs = { %{$self->_resolved_attrs} };
1760
1761   my $join_classifications;
1762   my $existing_group_by = delete $attrs->{group_by};
1763
1764   # do we need a subquery for any reason?
1765   my $needs_subq = (
1766     defined $existing_group_by
1767       or
1768     # if {from} is unparseable wrap a subq
1769     ref($attrs->{from}) ne 'ARRAY'
1770       or
1771     # limits call for a subq
1772     $self->_has_resolved_attr(qw/rows offset/)
1773   );
1774
1775   # simplify the joinmap, so we can further decide if a subq is necessary
1776   if (!$needs_subq and @{$attrs->{from}} > 1) {
1777     $attrs->{from} = $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1778
1779     # check if there are any joins left after the prune
1780     if ( @{$attrs->{from}} > 1 ) {
1781       $join_classifications = $storage->_resolve_aliastypes_from_select_args (
1782         [ @{$attrs->{from}}[1 .. $#{$attrs->{from}}] ],
1783         $attrs->{select},
1784         $self->{cond},
1785         $attrs
1786       );
1787
1788       # any non-pruneable joins imply subq
1789       $needs_subq = scalar keys %{ $join_classifications->{restricting} || {} };
1790     }
1791   }
1792
1793   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1794   $needs_subq ||= (
1795     (ref $attrs->{from}[0]) ne 'HASH'
1796       or
1797     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1798   );
1799
1800   my ($cond, $guard);
1801   # do we need anything like a subquery?
1802   if (! $needs_subq) {
1803     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1804     # a condition containing 'me' or other table prefixes will not work
1805     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1806     $cond = do {
1807       my $sqla = $rsrc->storage->sql_maker;
1808       local $sqla->{_dequalify_idents} = 1;
1809       \[ $sqla->_recurse_where($self->{cond}) ];
1810     };
1811   }
1812   else {
1813     # we got this far - means it is time to wrap a subquery
1814     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1815       sprintf(
1816         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1817         $op,
1818         $rsrc->source_name,
1819       )
1820     );
1821
1822     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1823     delete $attrs->{$_} for qw/collapse select _prefetch_selector_range as/;
1824     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1825     $attrs->{group_by} = \ '';  # FIXME - this is an evil hack, it causes the optimiser to kick in and throw away the LEFT joins
1826     my $subrs = (ref $self)->new($rsrc, $attrs);
1827
1828     if (@$idcols == 1) {
1829       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1830     }
1831     elsif ($storage->_use_multicolumn_in) {
1832       # no syntax for calling this properly yet
1833       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1834       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1835         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1836         $subrs->as_query
1837       ),
1838     }
1839     else {
1840       # if all else fails - get all primary keys and operate over a ORed set
1841       # wrap in a transaction for consistency
1842       # this is where the group_by/multiplication starts to matter
1843       if (
1844         $existing_group_by
1845           or
1846         keys %{ $join_classifications->{multiplying} || {} }
1847       ) {
1848         # make sure if there is a supplied group_by it matches the columns compiled above
1849         # perfectly. Anything else can not be sanely executed on most databases so croak
1850         # right then and there
1851         if ($existing_group_by) {
1852           my @current_group_by = map
1853             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1854             @$existing_group_by
1855           ;
1856
1857           if (
1858             join ("\x00", sort @current_group_by)
1859               ne
1860             join ("\x00", sort @{$attrs->{columns}} )
1861           ) {
1862             $self->throw_exception (
1863               "You have just attempted a $op operation on a resultset which does group_by"
1864               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1865               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1866               . ' kind of queries. Please retry the operation with a modified group_by or'
1867               . ' without using one at all.'
1868             );
1869           }
1870         }
1871
1872         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1873       }
1874
1875       $guard = $storage->txn_scope_guard;
1876
1877       $cond = [];
1878       for my $row ($subrs->cursor->all) {
1879         push @$cond, { map
1880           { $idcols->[$_] => $row->[$_] }
1881           (0 .. $#$idcols)
1882         };
1883       }
1884     }
1885   }
1886
1887   my $res = $storage->$op (
1888     $rsrc,
1889     $op eq 'update' ? $values : (),
1890     $cond,
1891   );
1892
1893   $guard->commit if $guard;
1894
1895   return $res;
1896 }
1897
1898 =head2 update
1899
1900 =over 4
1901
1902 =item Arguments: \%values
1903
1904 =item Return Value: $underlying_storage_rv
1905
1906 =back
1907
1908 Sets the specified columns in the resultset to the supplied values in a
1909 single query. Note that this will not run any accessor/set_column/update
1910 triggers, nor will it update any result object instances derived from this
1911 resultset (this includes the contents of the L<resultset cache|/set_cache>
1912 if any). See L</update_all> if you need to execute any on-update
1913 triggers or cascades defined either by you or a
1914 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1915
1916 The return value is a pass through of what the underlying
1917 storage backend returned, and may vary. See L<DBI/execute> for the most
1918 common case.
1919
1920 =head3 CAVEAT
1921
1922 Note that L</update> does not process/deflate any of the values passed in.
1923 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1924 ensure manually that any value passed to this method will stringify to
1925 something the RDBMS knows how to deal with. A notable example is the
1926 handling of L<DateTime> objects, for more info see:
1927 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
1928
1929 =cut
1930
1931 sub update {
1932   my ($self, $values) = @_;
1933   $self->throw_exception('Values for update must be a hash')
1934     unless ref $values eq 'HASH';
1935
1936   return $self->_rs_update_delete ('update', $values);
1937 }
1938
1939 =head2 update_all
1940
1941 =over 4
1942
1943 =item Arguments: \%values
1944
1945 =item Return Value: 1
1946
1947 =back
1948
1949 Fetches all objects and updates them one at a time via
1950 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1951 triggers, while L</update> will not.
1952
1953 =cut
1954
1955 sub update_all {
1956   my ($self, $values) = @_;
1957   $self->throw_exception('Values for update_all must be a hash')
1958     unless ref $values eq 'HASH';
1959
1960   my $guard = $self->result_source->schema->txn_scope_guard;
1961   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
1962   $guard->commit;
1963   return 1;
1964 }
1965
1966 =head2 delete
1967
1968 =over 4
1969
1970 =item Arguments: none
1971
1972 =item Return Value: $underlying_storage_rv
1973
1974 =back
1975
1976 Deletes the rows matching this resultset in a single query. Note that this
1977 will not run any delete triggers, nor will it alter the
1978 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
1979 derived from this resultset (this includes the contents of the
1980 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1981 execute any on-delete triggers or cascades defined either by you or a
1982 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
1983
1984 The return value is a pass through of what the underlying storage backend
1985 returned, and may vary. See L<DBI/execute> for the most common case.
1986
1987 =cut
1988
1989 sub delete {
1990   my $self = shift;
1991   $self->throw_exception('delete does not accept any arguments')
1992     if @_;
1993
1994   return $self->_rs_update_delete ('delete');
1995 }
1996
1997 =head2 delete_all
1998
1999 =over 4
2000
2001 =item Arguments: none
2002
2003 =item Return Value: 1
2004
2005 =back
2006
2007 Fetches all objects and deletes them one at a time via
2008 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2009 triggers, while L</delete> will not.
2010
2011 =cut
2012
2013 sub delete_all {
2014   my $self = shift;
2015   $self->throw_exception('delete_all does not accept any arguments')
2016     if @_;
2017
2018   my $guard = $self->result_source->schema->txn_scope_guard;
2019   $_->delete for $self->all;
2020   $guard->commit;
2021   return 1;
2022 }
2023
2024 =head2 populate
2025
2026 =over 4
2027
2028 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2029
2030 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2031
2032 =back
2033
2034 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2035 arrayrefs.
2036
2037 =over
2038
2039 =item NOTE
2040
2041 The context of this method call has an important effect on what is
2042 submitted to storage. In void context data is fed directly to fastpath
2043 insertion routines provided by the underlying storage (most often
2044 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2045 L<insert|DBIx::Class::Row/insert> calls on the
2046 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2047 augmentation of these methods provided by components. For example if you
2048 are using something like L<DBIx::Class::UUIDColumns> to create primary
2049 keys for you, you will find that your PKs are empty.  In this case you
2050 will have to explicitly force scalar or list context in order to create
2051 those values.
2052
2053 =back
2054
2055 In non-void (scalar or list) context, this method is simply a wrapper
2056 for L</create>. Depending on list or scalar context either a list of
2057 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2058 containing these objects is returned.
2059
2060 When supplying data in "arrayref of arrayrefs" invocation style, the
2061 first element should be a list of column names and each subsequent
2062 element should be a data value in the earlier specified column order.
2063 For example:
2064
2065   $Arstist_rs->populate([
2066     [ qw( artistid name ) ],
2067     [ 100, 'A Formally Unknown Singer' ],
2068     [ 101, 'A singer that jumped the shark two albums ago' ],
2069     [ 102, 'An actually cool singer' ],
2070   ]);
2071
2072 For the arrayref of hashrefs style each hashref should be a structure
2073 suitable for passing to L</create>. Multi-create is also permitted with
2074 this syntax.
2075
2076   $schema->resultset("Artist")->populate([
2077      { artistid => 4, name => 'Manufactured Crap', cds => [
2078         { title => 'My First CD', year => 2006 },
2079         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2080       ],
2081      },
2082      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2083         { title => 'My parents sold me to a record company', year => 2005 },
2084         { title => 'Why Am I So Ugly?', year => 2006 },
2085         { title => 'I Got Surgery and am now Popular', year => 2007 }
2086       ],
2087      },
2088   ]);
2089
2090 If you attempt a void-context multi-create as in the example above (each
2091 Artist also has the related list of CDs), and B<do not> supply the
2092 necessary autoinc foreign key information, this method will proxy to the
2093 less efficient L</create>, and then throw the Result objects away. In this
2094 case there are obviously no benefits to using this method over L</create>.
2095
2096 =cut
2097
2098 sub populate {
2099   my $self = shift;
2100
2101   # cruft placed in standalone method
2102   my $data = $self->_normalize_populate_args(@_);
2103
2104   return unless @$data;
2105
2106   if(defined wantarray) {
2107     my @created = map { $self->create($_) } @$data;
2108     return wantarray ? @created : \@created;
2109   }
2110   else {
2111     my $first = $data->[0];
2112
2113     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2114     # it relationship data
2115     my (@rels, @columns);
2116     my $rsrc = $self->result_source;
2117     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2118     for (keys %$first) {
2119       my $ref = ref $first->{$_};
2120       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2121         ? push @rels, $_
2122         : push @columns, $_
2123       ;
2124     }
2125
2126     my @pks = $rsrc->primary_columns;
2127
2128     ## do the belongs_to relationships
2129     foreach my $index (0..$#$data) {
2130
2131       # delegate to create() for any dataset without primary keys with specified relationships
2132       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2133         for my $r (@rels) {
2134           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2135             my @ret = $self->populate($data);
2136             return;
2137           }
2138         }
2139       }
2140
2141       foreach my $rel (@rels) {
2142         next unless ref $data->[$index]->{$rel} eq "HASH";
2143         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2144         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2145         my $related = $result->result_source->_resolve_condition(
2146           $reverse_relinfo->{cond},
2147           $self,
2148           $result,
2149           $rel,
2150         );
2151
2152         delete $data->[$index]->{$rel};
2153         $data->[$index] = {%{$data->[$index]}, %$related};
2154
2155         push @columns, keys %$related if $index == 0;
2156       }
2157     }
2158
2159     ## inherit the data locked in the conditions of the resultset
2160     my ($rs_data) = $self->_merge_with_rscond({});
2161     delete @{$rs_data}{@columns};
2162
2163     ## do bulk insert on current row
2164     $rsrc->storage->insert_bulk(
2165       $rsrc,
2166       [@columns, keys %$rs_data],
2167       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2168     );
2169
2170     ## do the has_many relationships
2171     foreach my $item (@$data) {
2172
2173       my $main_row;
2174
2175       foreach my $rel (@rels) {
2176         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2177
2178         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2179
2180         my $child = $main_row->$rel;
2181
2182         my $related = $child->result_source->_resolve_condition(
2183           $rels->{$rel}{cond},
2184           $child,
2185           $main_row,
2186           $rel,
2187         );
2188
2189         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2190         my @populate = map { {%$_, %$related} } @rows_to_add;
2191
2192         $child->populate( \@populate );
2193       }
2194     }
2195   }
2196 }
2197
2198
2199 # populate() argumnets went over several incarnations
2200 # What we ultimately support is AoH
2201 sub _normalize_populate_args {
2202   my ($self, $arg) = @_;
2203
2204   if (ref $arg eq 'ARRAY') {
2205     if (!@$arg) {
2206       return [];
2207     }
2208     elsif (ref $arg->[0] eq 'HASH') {
2209       return $arg;
2210     }
2211     elsif (ref $arg->[0] eq 'ARRAY') {
2212       my @ret;
2213       my @colnames = @{$arg->[0]};
2214       foreach my $values (@{$arg}[1 .. $#$arg]) {
2215         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2216       }
2217       return \@ret;
2218     }
2219   }
2220
2221   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2222 }
2223
2224 =head2 pager
2225
2226 =over 4
2227
2228 =item Arguments: none
2229
2230 =item Return Value: L<$pager|Data::Page>
2231
2232 =back
2233
2234 Returns a L<Data::Page> object for the current resultset. Only makes
2235 sense for queries with a C<page> attribute.
2236
2237 To get the full count of entries for a paged resultset, call
2238 C<total_entries> on the L<Data::Page> object.
2239
2240 =cut
2241
2242 sub pager {
2243   my ($self) = @_;
2244
2245   return $self->{pager} if $self->{pager};
2246
2247   my $attrs = $self->{attrs};
2248   if (!defined $attrs->{page}) {
2249     $self->throw_exception("Can't create pager for non-paged rs");
2250   }
2251   elsif ($attrs->{page} <= 0) {
2252     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2253   }
2254   $attrs->{rows} ||= 10;
2255
2256   # throw away the paging flags and re-run the count (possibly
2257   # with a subselect) to get the real total count
2258   my $count_attrs = { %$attrs };
2259   delete @{$count_attrs}{qw/rows offset page pager/};
2260
2261   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2262
2263   require DBIx::Class::ResultSet::Pager;
2264   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2265     sub { $total_rs->count },  #lazy-get the total
2266     $attrs->{rows},
2267     $self->{attrs}{page},
2268   );
2269 }
2270
2271 =head2 page
2272
2273 =over 4
2274
2275 =item Arguments: $page_number
2276
2277 =item Return Value: L<$resultset|/search>
2278
2279 =back
2280
2281 Returns a resultset for the $page_number page of the resultset on which page
2282 is called, where each page contains a number of rows equal to the 'rows'
2283 attribute set on the resultset (10 by default).
2284
2285 =cut
2286
2287 sub page {
2288   my ($self, $page) = @_;
2289   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2290 }
2291
2292 =head2 new_result
2293
2294 =over 4
2295
2296 =item Arguments: \%col_data
2297
2298 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2299
2300 =back
2301
2302 Creates a new result object in the resultset's result class and returns
2303 it. The row is not inserted into the database at this point, call
2304 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2305 will tell you whether the result object has been inserted or not.
2306
2307 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2308
2309 =cut
2310
2311 sub new_result {
2312   my ($self, $values) = @_;
2313
2314   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2315     if @_ > 2;
2316
2317   $self->throw_exception( "new_result expects a hashref" )
2318     unless (ref $values eq 'HASH');
2319
2320   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2321
2322   my %new = (
2323     %$merged_cond,
2324     @$cols_from_relations
2325       ? (-cols_from_relations => $cols_from_relations)
2326       : (),
2327     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2328   );
2329
2330   return $self->result_class->new(\%new);
2331 }
2332
2333 # _merge_with_rscond
2334 #
2335 # Takes a simple hash of K/V data and returns its copy merged with the
2336 # condition already present on the resultset. Additionally returns an
2337 # arrayref of value/condition names, which were inferred from related
2338 # objects (this is needed for in-memory related objects)
2339 sub _merge_with_rscond {
2340   my ($self, $data) = @_;
2341
2342   my (%new_data, @cols_from_relations);
2343
2344   my $alias = $self->{attrs}{alias};
2345
2346   if (! defined $self->{cond}) {
2347     # just massage $data below
2348   }
2349   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2350     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2351     @cols_from_relations = keys %new_data;
2352   }
2353   elsif (ref $self->{cond} ne 'HASH') {
2354     $self->throw_exception(
2355       "Can't abstract implicit construct, resultset condition not a hash"
2356     );
2357   }
2358   else {
2359     # precendence must be given to passed values over values inherited from
2360     # the cond, so the order here is important.
2361     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2362     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2363
2364     while ( my($col, $value) = each %implied ) {
2365       my $vref = ref $value;
2366       if (
2367         $vref eq 'HASH'
2368           and
2369         keys(%$value) == 1
2370           and
2371         (keys %$value)[0] eq '='
2372       ) {
2373         $new_data{$col} = $value->{'='};
2374       }
2375       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2376         $new_data{$col} = $value;
2377       }
2378     }
2379   }
2380
2381   %new_data = (
2382     %new_data,
2383     %{ $self->_remove_alias($data, $alias) },
2384   );
2385
2386   return (\%new_data, \@cols_from_relations);
2387 }
2388
2389 # _has_resolved_attr
2390 #
2391 # determines if the resultset defines at least one
2392 # of the attributes supplied
2393 #
2394 # used to determine if a subquery is neccessary
2395 #
2396 # supports some virtual attributes:
2397 #   -join
2398 #     This will scan for any joins being present on the resultset.
2399 #     It is not a mere key-search but a deep inspection of {from}
2400 #
2401
2402 sub _has_resolved_attr {
2403   my ($self, @attr_names) = @_;
2404
2405   my $attrs = $self->_resolved_attrs;
2406
2407   my %extra_checks;
2408
2409   for my $n (@attr_names) {
2410     if (grep { $n eq $_ } (qw/-join/) ) {
2411       $extra_checks{$n}++;
2412       next;
2413     }
2414
2415     my $attr =  $attrs->{$n};
2416
2417     next if not defined $attr;
2418
2419     if (ref $attr eq 'HASH') {
2420       return 1 if keys %$attr;
2421     }
2422     elsif (ref $attr eq 'ARRAY') {
2423       return 1 if @$attr;
2424     }
2425     else {
2426       return 1 if $attr;
2427     }
2428   }
2429
2430   # a resolved join is expressed as a multi-level from
2431   return 1 if (
2432     $extra_checks{-join}
2433       and
2434     ref $attrs->{from} eq 'ARRAY'
2435       and
2436     @{$attrs->{from}} > 1
2437   );
2438
2439   return 0;
2440 }
2441
2442 # _collapse_cond
2443 #
2444 # Recursively collapse the condition.
2445
2446 sub _collapse_cond {
2447   my ($self, $cond, $collapsed) = @_;
2448
2449   $collapsed ||= {};
2450
2451   if (ref $cond eq 'ARRAY') {
2452     foreach my $subcond (@$cond) {
2453       next unless ref $subcond;  # -or
2454       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2455     }
2456   }
2457   elsif (ref $cond eq 'HASH') {
2458     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2459       foreach my $subcond (@{$cond->{-and}}) {
2460         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2461       }
2462     }
2463     else {
2464       foreach my $col (keys %$cond) {
2465         my $value = $cond->{$col};
2466         $collapsed->{$col} = $value;
2467       }
2468     }
2469   }
2470
2471   return $collapsed;
2472 }
2473
2474 # _remove_alias
2475 #
2476 # Remove the specified alias from the specified query hash. A copy is made so
2477 # the original query is not modified.
2478
2479 sub _remove_alias {
2480   my ($self, $query, $alias) = @_;
2481
2482   my %orig = %{ $query || {} };
2483   my %unaliased;
2484
2485   foreach my $key (keys %orig) {
2486     if ($key !~ /\./) {
2487       $unaliased{$key} = $orig{$key};
2488       next;
2489     }
2490     $unaliased{$1} = $orig{$key}
2491       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2492   }
2493
2494   return \%unaliased;
2495 }
2496
2497 =head2 as_query
2498
2499 =over 4
2500
2501 =item Arguments: none
2502
2503 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2504
2505 =back
2506
2507 Returns the SQL query and bind vars associated with the invocant.
2508
2509 This is generally used as the RHS for a subquery.
2510
2511 =cut
2512
2513 sub as_query {
2514   my $self = shift;
2515
2516   my $attrs = { %{ $self->_resolved_attrs } };
2517
2518   # For future use:
2519   #
2520   # in list ctx:
2521   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2522   # $sql also has no wrapping parenthesis in list ctx
2523   #
2524   my $sqlbind = $self->result_source->storage
2525     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2526
2527   return $sqlbind;
2528 }
2529
2530 =head2 find_or_new
2531
2532 =over 4
2533
2534 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2535
2536 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2537
2538 =back
2539
2540   my $artist = $schema->resultset('Artist')->find_or_new(
2541     { artist => 'fred' }, { key => 'artists' });
2542
2543   $cd->cd_to_producer->find_or_new({ producer => $producer },
2544                                    { key => 'primary });
2545
2546 Find an existing record from this resultset using L</find>. if none exists,
2547 instantiate a new result object and return it. The object will not be saved
2548 into your storage until you call L<DBIx::Class::Row/insert> on it.
2549
2550 You most likely want this method when looking for existing rows using a unique
2551 constraint that is not the primary key, or looking for related rows.
2552
2553 If you want objects to be saved immediately, use L</find_or_create> instead.
2554
2555 B<Note>: Make sure to read the documentation of L</find> and understand the
2556 significance of the C<key> attribute, as its lack may skew your search, and
2557 subsequently result in spurious new objects.
2558
2559 B<Note>: Take care when using C<find_or_new> with a table having
2560 columns with default values that you intend to be automatically
2561 supplied by the database (e.g. an auto_increment primary key column).
2562 In normal usage, the value of such columns should NOT be included at
2563 all in the call to C<find_or_new>, even when set to C<undef>.
2564
2565 =cut
2566
2567 sub find_or_new {
2568   my $self     = shift;
2569   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2570   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2571   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2572     return $row;
2573   }
2574   return $self->new_result($hash);
2575 }
2576
2577 =head2 create
2578
2579 =over 4
2580
2581 =item Arguments: \%col_data
2582
2583 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2584
2585 =back
2586
2587 Attempt to create a single new row or a row with multiple related rows
2588 in the table represented by the resultset (and related tables). This
2589 will not check for duplicate rows before inserting, use
2590 L</find_or_create> to do that.
2591
2592 To create one row for this resultset, pass a hashref of key/value
2593 pairs representing the columns of the table and the values you wish to
2594 store. If the appropriate relationships are set up, foreign key fields
2595 can also be passed an object representing the foreign row, and the
2596 value will be set to its primary key.
2597
2598 To create related objects, pass a hashref of related-object column values
2599 B<keyed on the relationship name>. If the relationship is of type C<multi>
2600 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2601 The process will correctly identify columns holding foreign keys, and will
2602 transparently populate them from the keys of the corresponding relation.
2603 This can be applied recursively, and will work correctly for a structure
2604 with an arbitrary depth and width, as long as the relationships actually
2605 exists and the correct column data has been supplied.
2606
2607 Instead of hashrefs of plain related data (key/value pairs), you may
2608 also pass new or inserted objects. New objects (not inserted yet, see
2609 L</new_result>), will be inserted into their appropriate tables.
2610
2611 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2612
2613 Example of creating a new row.
2614
2615   $person_rs->create({
2616     name=>"Some Person",
2617     email=>"somebody@someplace.com"
2618   });
2619
2620 Example of creating a new row and also creating rows in a related C<has_many>
2621 or C<has_one> resultset.  Note Arrayref.
2622
2623   $artist_rs->create(
2624      { artistid => 4, name => 'Manufactured Crap', cds => [
2625         { title => 'My First CD', year => 2006 },
2626         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2627       ],
2628      },
2629   );
2630
2631 Example of creating a new row and also creating a row in a related
2632 C<belongs_to> resultset. Note Hashref.
2633
2634   $cd_rs->create({
2635     title=>"Music for Silly Walks",
2636     year=>2000,
2637     artist => {
2638       name=>"Silly Musician",
2639     }
2640   });
2641
2642 =over
2643
2644 =item WARNING
2645
2646 When subclassing ResultSet never attempt to override this method. Since
2647 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2648 lot of the internals simply never call it, so your override will be
2649 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2650 or L<DBIx::Class::Row/insert> depending on how early in the
2651 L</create> process you need to intervene. See also warning pertaining to
2652 L</new>.
2653
2654 =back
2655
2656 =cut
2657
2658 sub create {
2659   my ($self, $attrs) = @_;
2660   $self->throw_exception( "create needs a hashref" )
2661     unless ref $attrs eq 'HASH';
2662   return $self->new_result($attrs)->insert;
2663 }
2664
2665 =head2 find_or_create
2666
2667 =over 4
2668
2669 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2670
2671 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2672
2673 =back
2674
2675   $cd->cd_to_producer->find_or_create({ producer => $producer },
2676                                       { key => 'primary' });
2677
2678 Tries to find a record based on its primary key or unique constraints; if none
2679 is found, creates one and returns that instead.
2680
2681   my $cd = $schema->resultset('CD')->find_or_create({
2682     cdid   => 5,
2683     artist => 'Massive Attack',
2684     title  => 'Mezzanine',
2685     year   => 2005,
2686   });
2687
2688 Also takes an optional C<key> attribute, to search by a specific key or unique
2689 constraint. For example:
2690
2691   my $cd = $schema->resultset('CD')->find_or_create(
2692     {
2693       artist => 'Massive Attack',
2694       title  => 'Mezzanine',
2695     },
2696     { key => 'cd_artist_title' }
2697   );
2698
2699 B<Note>: Make sure to read the documentation of L</find> and understand the
2700 significance of the C<key> attribute, as its lack may skew your search, and
2701 subsequently result in spurious row creation.
2702
2703 B<Note>: Because find_or_create() reads from the database and then
2704 possibly inserts based on the result, this method is subject to a race
2705 condition. Another process could create a record in the table after
2706 the find has completed and before the create has started. To avoid
2707 this problem, use find_or_create() inside a transaction.
2708
2709 B<Note>: Take care when using C<find_or_create> with a table having
2710 columns with default values that you intend to be automatically
2711 supplied by the database (e.g. an auto_increment primary key column).
2712 In normal usage, the value of such columns should NOT be included at
2713 all in the call to C<find_or_create>, even when set to C<undef>.
2714
2715 See also L</find> and L</update_or_create>. For information on how to declare
2716 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2717
2718 If you need to know if an existing row was found or a new one created use
2719 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2720 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2721 database!
2722
2723   my $cd = $schema->resultset('CD')->find_or_new({
2724     cdid   => 5,
2725     artist => 'Massive Attack',
2726     title  => 'Mezzanine',
2727     year   => 2005,
2728   });
2729
2730   if( !$cd->in_storage ) {
2731       # do some stuff
2732       $cd->insert;
2733   }
2734
2735 =cut
2736
2737 sub find_or_create {
2738   my $self     = shift;
2739   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2740   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2741   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2742     return $row;
2743   }
2744   return $self->create($hash);
2745 }
2746
2747 =head2 update_or_create
2748
2749 =over 4
2750
2751 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2752
2753 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2754
2755 =back
2756
2757   $resultset->update_or_create({ col => $val, ... });
2758
2759 Like L</find_or_create>, but if a row is found it is immediately updated via
2760 C<< $found_row->update (\%col_data) >>.
2761
2762
2763 Takes an optional C<key> attribute to search on a specific unique constraint.
2764 For example:
2765
2766   # In your application
2767   my $cd = $schema->resultset('CD')->update_or_create(
2768     {
2769       artist => 'Massive Attack',
2770       title  => 'Mezzanine',
2771       year   => 1998,
2772     },
2773     { key => 'cd_artist_title' }
2774   );
2775
2776   $cd->cd_to_producer->update_or_create({
2777     producer => $producer,
2778     name => 'harry',
2779   }, {
2780     key => 'primary',
2781   });
2782
2783 B<Note>: Make sure to read the documentation of L</find> and understand the
2784 significance of the C<key> attribute, as its lack may skew your search, and
2785 subsequently result in spurious row creation.
2786
2787 B<Note>: Take care when using C<update_or_create> with a table having
2788 columns with default values that you intend to be automatically
2789 supplied by the database (e.g. an auto_increment primary key column).
2790 In normal usage, the value of such columns should NOT be included at
2791 all in the call to C<update_or_create>, even when set to C<undef>.
2792
2793 See also L</find> and L</find_or_create>. For information on how to declare
2794 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2795
2796 If you need to know if an existing row was updated or a new one created use
2797 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2798 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2799 database!
2800
2801 =cut
2802
2803 sub update_or_create {
2804   my $self = shift;
2805   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2806   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2807
2808   my $row = $self->find($cond, $attrs);
2809   if (defined $row) {
2810     $row->update($cond);
2811     return $row;
2812   }
2813
2814   return $self->create($cond);
2815 }
2816
2817 =head2 update_or_new
2818
2819 =over 4
2820
2821 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2822
2823 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2824
2825 =back
2826
2827   $resultset->update_or_new({ col => $val, ... });
2828
2829 Like L</find_or_new> but if a row is found it is immediately updated via
2830 C<< $found_row->update (\%col_data) >>.
2831
2832 For example:
2833
2834   # In your application
2835   my $cd = $schema->resultset('CD')->update_or_new(
2836     {
2837       artist => 'Massive Attack',
2838       title  => 'Mezzanine',
2839       year   => 1998,
2840     },
2841     { key => 'cd_artist_title' }
2842   );
2843
2844   if ($cd->in_storage) {
2845       # the cd was updated
2846   }
2847   else {
2848       # the cd is not yet in the database, let's insert it
2849       $cd->insert;
2850   }
2851
2852 B<Note>: Make sure to read the documentation of L</find> and understand the
2853 significance of the C<key> attribute, as its lack may skew your search, and
2854 subsequently result in spurious new objects.
2855
2856 B<Note>: Take care when using C<update_or_new> with a table having
2857 columns with default values that you intend to be automatically
2858 supplied by the database (e.g. an auto_increment primary key column).
2859 In normal usage, the value of such columns should NOT be included at
2860 all in the call to C<update_or_new>, even when set to C<undef>.
2861
2862 See also L</find>, L</find_or_create> and L</find_or_new>.
2863
2864 =cut
2865
2866 sub update_or_new {
2867     my $self  = shift;
2868     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2869     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2870
2871     my $row = $self->find( $cond, $attrs );
2872     if ( defined $row ) {
2873         $row->update($cond);
2874         return $row;
2875     }
2876
2877     return $self->new_result($cond);
2878 }
2879
2880 =head2 get_cache
2881
2882 =over 4
2883
2884 =item Arguments: none
2885
2886 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2887
2888 =back
2889
2890 Gets the contents of the cache for the resultset, if the cache is set.
2891
2892 The cache is populated either by using the L</prefetch> attribute to
2893 L</search> or by calling L</set_cache>.
2894
2895 =cut
2896
2897 sub get_cache {
2898   shift->{all_cache};
2899 }
2900
2901 =head2 set_cache
2902
2903 =over 4
2904
2905 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2906
2907 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
2908
2909 =back
2910
2911 Sets the contents of the cache for the resultset. Expects an arrayref
2912 of objects of the same class as those produced by the resultset. Note that
2913 if the cache is set, the resultset will return the cached objects rather
2914 than re-querying the database even if the cache attr is not set.
2915
2916 The contents of the cache can also be populated by using the
2917 L</prefetch> attribute to L</search>.
2918
2919 =cut
2920
2921 sub set_cache {
2922   my ( $self, $data ) = @_;
2923   $self->throw_exception("set_cache requires an arrayref")
2924       if defined($data) && (ref $data ne 'ARRAY');
2925   $self->{all_cache} = $data;
2926 }
2927
2928 =head2 clear_cache
2929
2930 =over 4
2931
2932 =item Arguments: none
2933
2934 =item Return Value: undef
2935
2936 =back
2937
2938 Clears the cache for the resultset.
2939
2940 =cut
2941
2942 sub clear_cache {
2943   shift->set_cache(undef);
2944 }
2945
2946 =head2 is_paged
2947
2948 =over 4
2949
2950 =item Arguments: none
2951
2952 =item Return Value: true, if the resultset has been paginated
2953
2954 =back
2955
2956 =cut
2957
2958 sub is_paged {
2959   my ($self) = @_;
2960   return !!$self->{attrs}{page};
2961 }
2962
2963 =head2 is_ordered
2964
2965 =over 4
2966
2967 =item Arguments: none
2968
2969 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2970
2971 =back
2972
2973 =cut
2974
2975 sub is_ordered {
2976   my ($self) = @_;
2977   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2978 }
2979
2980 =head2 related_resultset
2981
2982 =over 4
2983
2984 =item Arguments: $rel_name
2985
2986 =item Return Value: L<$resultset|/search>
2987
2988 =back
2989
2990 Returns a related resultset for the supplied relationship name.
2991
2992   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2993
2994 =cut
2995
2996 sub related_resultset {
2997   my ($self, $rel) = @_;
2998
2999   $self->{related_resultsets} ||= {};
3000   return $self->{related_resultsets}{$rel} ||= do {
3001     my $rsrc = $self->result_source;
3002     my $rel_info = $rsrc->relationship_info($rel);
3003
3004     $self->throw_exception(
3005       "search_related: result source '" . $rsrc->source_name .
3006         "' has no such relationship $rel")
3007       unless $rel_info;
3008
3009     my $attrs = $self->_chain_relationship($rel);
3010
3011     my $join_count = $attrs->{seen_join}{$rel};
3012
3013     my $alias = $self->result_source->storage
3014         ->relname_to_table_alias($rel, $join_count);
3015
3016     # since this is search_related, and we already slid the select window inwards
3017     # (the select/as attrs were deleted in the beginning), we need to flip all
3018     # left joins to inner, so we get the expected results
3019     # read the comment on top of the actual function to see what this does
3020     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3021
3022
3023     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3024     delete @{$attrs}{qw(result_class alias)};
3025
3026     my $new_cache;
3027
3028     if (my $cache = $self->get_cache) {
3029       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
3030         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache||[]} }
3031                         @$cache ];
3032       }
3033     }
3034
3035     my $rel_source = $rsrc->related_source($rel);
3036
3037     my $new = do {
3038
3039       # The reason we do this now instead of passing the alias to the
3040       # search_rs below is that if you wrap/overload resultset on the
3041       # source you need to know what alias it's -going- to have for things
3042       # to work sanely (e.g. RestrictWithObject wants to be able to add
3043       # extra query restrictions, and these may need to be $alias.)
3044
3045       my $rel_attrs = $rel_source->resultset_attributes;
3046       local $rel_attrs->{alias} = $alias;
3047
3048       $rel_source->resultset
3049                  ->search_rs(
3050                      undef, {
3051                        %$attrs,
3052                        where => $attrs->{where},
3053                    });
3054     };
3055     $new->set_cache($new_cache) if $new_cache;
3056     $new;
3057   };
3058 }
3059
3060 =head2 current_source_alias
3061
3062 =over 4
3063
3064 =item Arguments: none
3065
3066 =item Return Value: $source_alias
3067
3068 =back
3069
3070 Returns the current table alias for the result source this resultset is built
3071 on, that will be used in the SQL query. Usually it is C<me>.
3072
3073 Currently the source alias that refers to the result set returned by a
3074 L</search>/L</find> family method depends on how you got to the resultset: it's
3075 C<me> by default, but eg. L</search_related> aliases it to the related result
3076 source name (and keeps C<me> referring to the original result set). The long
3077 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3078 (and make this method unnecessary).
3079
3080 Thus it's currently necessary to use this method in predefined queries (see
3081 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3082 source alias of the current result set:
3083
3084   # in a result set class
3085   sub modified_by {
3086     my ($self, $user) = @_;
3087
3088     my $me = $self->current_source_alias;
3089
3090     return $self->search({
3091       "$me.modified" => $user->id,
3092     });
3093   }
3094
3095 =cut
3096
3097 sub current_source_alias {
3098   return (shift->{attrs} || {})->{alias} || 'me';
3099 }
3100
3101 =head2 as_subselect_rs
3102
3103 =over 4
3104
3105 =item Arguments: none
3106
3107 =item Return Value: L<$resultset|/search>
3108
3109 =back
3110
3111 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3112 "virtual view" by including it as a subquery within the from clause.  From this
3113 point on, any joined tables are inaccessible to ->search on the resultset (as if
3114 it were simply where-filtered without joins).  For example:
3115
3116  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3117
3118  # 'x' now pollutes the query namespace
3119
3120  # So the following works as expected
3121  my $ok_rs = $rs->search({'x.other' => 1});
3122
3123  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3124  # def) we look for one row with contradictory terms and join in another table
3125  # (aliased 'x_2') which we never use
3126  my $broken_rs = $rs->search({'x.name' => 'def'});
3127
3128  my $rs2 = $rs->as_subselect_rs;
3129
3130  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3131  my $not_joined_rs = $rs2->search({'x.other' => 1});
3132
3133  # works as expected: finds a 'table' row related to two x rows (abc and def)
3134  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3135
3136 Another example of when one might use this would be to select a subset of
3137 columns in a group by clause:
3138
3139  my $rs = $schema->resultset('Bar')->search(undef, {
3140    group_by => [qw{ id foo_id baz_id }],
3141  })->as_subselect_rs->search(undef, {
3142    columns => [qw{ id foo_id }]
3143  });
3144
3145 In the above example normally columns would have to be equal to the group by,
3146 but because we isolated the group by into a subselect the above works.
3147
3148 =cut
3149
3150 sub as_subselect_rs {
3151   my $self = shift;
3152
3153   my $attrs = $self->_resolved_attrs;
3154
3155   my $fresh_rs = (ref $self)->new (
3156     $self->result_source
3157   );
3158
3159   # these pieces will be locked in the subquery
3160   delete $fresh_rs->{cond};
3161   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3162
3163   return $fresh_rs->search( {}, {
3164     from => [{
3165       $attrs->{alias} => $self->as_query,
3166       -alias  => $attrs->{alias},
3167       -rsrc   => $self->result_source,
3168     }],
3169     alias => $attrs->{alias},
3170   });
3171 }
3172
3173 # This code is called by search_related, and makes sure there
3174 # is clear separation between the joins before, during, and
3175 # after the relationship. This information is needed later
3176 # in order to properly resolve prefetch aliases (any alias
3177 # with a relation_chain_depth less than the depth of the
3178 # current prefetch is not considered)
3179 #
3180 # The increments happen twice per join. An even number means a
3181 # relationship specified via a search_related, whereas an odd
3182 # number indicates a join/prefetch added via attributes
3183 #
3184 # Also this code will wrap the current resultset (the one we
3185 # chain to) in a subselect IFF it contains limiting attributes
3186 sub _chain_relationship {
3187   my ($self, $rel) = @_;
3188   my $source = $self->result_source;
3189   my $attrs = { %{$self->{attrs}||{}} };
3190
3191   # we need to take the prefetch the attrs into account before we
3192   # ->_resolve_join as otherwise they get lost - captainL
3193   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3194
3195   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3196
3197   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3198
3199   my $from;
3200   my @force_subq_attrs = qw/offset rows group_by having/;
3201
3202   if (
3203     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3204       ||
3205     $self->_has_resolved_attr (@force_subq_attrs)
3206   ) {
3207     # Nuke the prefetch (if any) before the new $rs attrs
3208     # are resolved (prefetch is useless - we are wrapping
3209     # a subquery anyway).
3210     my $rs_copy = $self->search;
3211     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3212       $rs_copy->{attrs}{join},
3213       delete $rs_copy->{attrs}{prefetch},
3214     );
3215
3216     $from = [{
3217       -rsrc   => $source,
3218       -alias  => $attrs->{alias},
3219       $attrs->{alias} => $rs_copy->as_query,
3220     }];
3221     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3222     $seen->{-relation_chain_depth} = 0;
3223   }
3224   elsif ($attrs->{from}) {  #shallow copy suffices
3225     $from = [ @{$attrs->{from}} ];
3226   }
3227   else {
3228     $from = [{
3229       -rsrc  => $source,
3230       -alias => $attrs->{alias},
3231       $attrs->{alias} => $source->from,
3232     }];
3233   }
3234
3235   my $jpath = ($seen->{-relation_chain_depth})
3236     ? $from->[-1][0]{-join_path}
3237     : [];
3238
3239   my @requested_joins = $source->_resolve_join(
3240     $join,
3241     $attrs->{alias},
3242     $seen,
3243     $jpath,
3244   );
3245
3246   push @$from, @requested_joins;
3247
3248   $seen->{-relation_chain_depth}++;
3249
3250   # if $self already had a join/prefetch specified on it, the requested
3251   # $rel might very well be already included. What we do in this case
3252   # is effectively a no-op (except that we bump up the chain_depth on
3253   # the join in question so we could tell it *is* the search_related)
3254   my $already_joined;
3255
3256   # we consider the last one thus reverse
3257   for my $j (reverse @requested_joins) {
3258     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3259     if ($rel eq $last_j) {
3260       $j->[0]{-relation_chain_depth}++;
3261       $already_joined++;
3262       last;
3263     }
3264   }
3265
3266   unless ($already_joined) {
3267     push @$from, $source->_resolve_join(
3268       $rel,
3269       $attrs->{alias},
3270       $seen,
3271       $jpath,
3272     );
3273   }
3274
3275   $seen->{-relation_chain_depth}++;
3276
3277   return {%$attrs, from => $from, seen_join => $seen};
3278 }
3279
3280 # FIXME - this needs to go live in Schema with the tree walker... or
3281 # something
3282 my $inflatemap_checker;
3283 $inflatemap_checker = sub {
3284   my ($rsrc, $relpaths) = @_;
3285
3286   my $rels;
3287
3288   for (@$relpaths) {
3289     $_ =~ /^ ( [^\.]+ ) \. (.+) $/x
3290       or next;
3291
3292     push @{$rels->{$1}}, $2;
3293   }
3294
3295   for my $rel (keys %$rels) {
3296     my $rel_rsrc = try {
3297       $rsrc->related_source ($rel)
3298     } catch {
3299     $rsrc->throw_exception(sprintf(
3300       "Inflation into non-existent relationship '%s' of '%s' requested, "
3301     . "check the inflation specification (columns/as) ending in '...%s.%s'",
3302       $rel,
3303       $rsrc->source_name,
3304       $rel,
3305       ( sort { length($a) <=> length ($b) } @{$rels->{$rel}} )[0],
3306     ))};
3307
3308     $inflatemap_checker->($rel_rsrc, $rels->{$rel});
3309   }
3310
3311   return;
3312 };
3313
3314 sub _resolved_attrs {
3315   my $self = shift;
3316   return $self->{_attrs} if $self->{_attrs};
3317
3318   my $attrs  = { %{ $self->{attrs} || {} } };
3319   my $source = $self->result_source;
3320   my $alias  = $attrs->{alias};
3321
3322   # default selection list
3323   $attrs->{columns} = [ $source->columns ]
3324     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3325
3326   # merge selectors together
3327   for (qw/columns select as/) {
3328     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3329       if $attrs->{$_} or $attrs->{"+$_"};
3330   }
3331
3332   # disassemble columns
3333   my (@sel, @as);
3334   if (my $cols = delete $attrs->{columns}) {
3335     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3336       if (ref $c eq 'HASH') {
3337         for my $as (sort keys %$c) {
3338           push @sel, $c->{$as};
3339           push @as, $as;
3340         }
3341       }
3342       else {
3343         push @sel, $c;
3344         push @as, $c;
3345       }
3346     }
3347   }
3348
3349   # when trying to weed off duplicates later do not go past this point -
3350   # everything added from here on is unbalanced "anyone's guess" stuff
3351   my $dedup_stop_idx = $#as;
3352
3353   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3354     if $attrs->{as};
3355   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3356     if $attrs->{select};
3357
3358   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3359   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3360
3361   # disqualify all $alias.col as-bits (inflate-map mandated)
3362   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3363
3364   # de-duplicate the result (remove *identical* select/as pairs)
3365   # and also die on duplicate {as} pointing to different {select}s
3366   # not using a c-style for as the condition is prone to shrinkage
3367   my $seen;
3368   my $i = 0;
3369   while ($i <= $dedup_stop_idx) {
3370     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3371       splice @sel, $i, 1;
3372       splice @as, $i, 1;
3373       $dedup_stop_idx--;
3374     }
3375     elsif ($seen->{$as[$i]}++) {
3376       $self->throw_exception(
3377         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3378       );
3379     }
3380     else {
3381       $i++;
3382     }
3383   }
3384
3385   # validate the user-supplied 'as' chain
3386   # folks get too confused by the (logical) exception message, need to
3387   # go to some lengths to clarify the text
3388   #
3389   # FIXME - this needs to go live in Schema with the tree walker... or
3390   # something
3391   $inflatemap_checker->($source, \@as);
3392
3393   $attrs->{select} = \@sel;
3394   $attrs->{as} = \@as;
3395
3396   $attrs->{from} ||= [{
3397     -rsrc   => $source,
3398     -alias  => $self->{attrs}{alias},
3399     $self->{attrs}{alias} => $source->from,
3400   }];
3401
3402   if ( $attrs->{join} || $attrs->{prefetch} ) {
3403
3404     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3405       if ref $attrs->{from} ne 'ARRAY';
3406
3407     my $join = (delete $attrs->{join}) || {};
3408
3409     if ( defined $attrs->{prefetch} ) {
3410       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3411     }
3412
3413     $attrs->{from} =    # have to copy here to avoid corrupting the original
3414       [
3415         @{ $attrs->{from} },
3416         $source->_resolve_join(
3417           $join,
3418           $alias,
3419           { %{ $attrs->{seen_join} || {} } },
3420           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3421             ? $attrs->{from}[-1][0]{-join_path}
3422             : []
3423           ,
3424         )
3425       ];
3426   }
3427
3428   if ( defined $attrs->{order_by} ) {
3429     $attrs->{order_by} = (
3430       ref( $attrs->{order_by} ) eq 'ARRAY'
3431       ? [ @{ $attrs->{order_by} } ]
3432       : [ $attrs->{order_by} || () ]
3433     );
3434   }
3435
3436   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3437     $attrs->{group_by} = [ $attrs->{group_by} ];
3438   }
3439
3440   # generate the distinct induced group_by early, as prefetch will be carried via a
3441   # subquery (since a group_by is present)
3442   if (delete $attrs->{distinct}) {
3443     if ($attrs->{group_by}) {
3444       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3445     }
3446     else {
3447       # distinct affects only the main selection part, not what prefetch may
3448       # add below.
3449       $attrs->{group_by} = $source->storage->_group_over_selection (
3450         $attrs->{from},
3451         $attrs->{select},
3452         $attrs->{order_by},
3453       );
3454     }
3455   }
3456
3457   # generate selections based on the prefetch helper
3458   my $prefetch;
3459   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3460     if defined $attrs->{prefetch};
3461
3462   if ($prefetch) {
3463
3464     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3465       if $attrs->{_dark_selector};
3466
3467     $attrs->{collapse} = 1;
3468
3469     # this is a separate structure (we don't look in {from} directly)
3470     # as the resolver needs to shift things off the lists to work
3471     # properly (identical-prefetches on different branches)
3472     my $join_map = {};
3473     if (ref $attrs->{from} eq 'ARRAY') {
3474
3475       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3476
3477       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3478         next unless $j->[0]{-alias};
3479         next unless $j->[0]{-join_path};
3480         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3481
3482         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3483
3484         my $p = $join_map;
3485         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3486         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3487       }
3488     }
3489
3490     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3491
3492     # we need to somehow mark which columns came from prefetch
3493     if (@prefetch) {
3494       my $sel_end = $#{$attrs->{select}};
3495       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3496     }
3497
3498     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3499     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3500   }
3501
3502   if ( ! List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3503     $attrs->{_single_object_inflation} = 1;
3504     $attrs->{collapse} = 0;
3505   }
3506
3507   # run through the resulting joinstructure (starting from our current slot)
3508   # and unset collapse if proven unnesessary
3509   #
3510   # also while we are at it find out if the current root source has
3511   # been premultiplied by previous related_source chaining
3512   #
3513   # this allows to predict whether a root object with all other relation
3514   # data set to NULL is in fact unique
3515   if ($attrs->{collapse}) {
3516
3517     if (ref $attrs->{from} eq 'ARRAY') {
3518
3519       if (@{$attrs->{from}} <= 1) {
3520         # no joins - no collapse
3521         $attrs->{collapse} = 0;
3522       }
3523       else {
3524         # find where our table-spec starts
3525         my @fromlist = @{$attrs->{from}};
3526         while (@fromlist) {
3527           my $t = shift @fromlist;
3528
3529           my $is_multi;
3530           # me vs join from-spec distinction - a ref means non-root
3531           if (ref $t eq 'ARRAY') {
3532             $t = $t->[0];
3533             $is_multi ||= ! $t->{-is_single};
3534           }
3535           last if ($t->{-alias} && $t->{-alias} eq $alias);
3536           $attrs->{_main_source_premultiplied} ||= $is_multi;
3537         }
3538
3539         # no non-singles remaining, nor any premultiplication - nothing to collapse
3540         if (
3541           ! $attrs->{_main_source_premultiplied}
3542             and
3543           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3544         ) {
3545           $attrs->{collapse} = 0;
3546         }
3547       }
3548     }
3549
3550     else {
3551       # if we can not analyze the from - err on the side of safety
3552       $attrs->{_main_source_premultiplied} = 1;
3553     }
3554   }
3555
3556   # if both page and offset are specified, produce a combined offset
3557   # even though it doesn't make much sense, this is what pre 081xx has
3558   # been doing
3559   if (my $page = delete $attrs->{page}) {
3560     $attrs->{offset} =
3561       ($attrs->{rows} * ($page - 1))
3562             +
3563       ($attrs->{offset} || 0)
3564     ;
3565   }
3566
3567   return $self->{_attrs} = $attrs;
3568 }
3569
3570 sub _rollout_attr {
3571   my ($self, $attr) = @_;
3572
3573   if (ref $attr eq 'HASH') {
3574     return $self->_rollout_hash($attr);
3575   } elsif (ref $attr eq 'ARRAY') {
3576     return $self->_rollout_array($attr);
3577   } else {
3578     return [$attr];
3579   }
3580 }
3581
3582 sub _rollout_array {
3583   my ($self, $attr) = @_;
3584
3585   my @rolled_array;
3586   foreach my $element (@{$attr}) {
3587     if (ref $element eq 'HASH') {
3588       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3589     } elsif (ref $element eq 'ARRAY') {
3590       #  XXX - should probably recurse here
3591       push( @rolled_array, @{$self->_rollout_array($element)} );
3592     } else {
3593       push( @rolled_array, $element );
3594     }
3595   }
3596   return \@rolled_array;
3597 }
3598
3599 sub _rollout_hash {
3600   my ($self, $attr) = @_;
3601
3602   my @rolled_array;
3603   foreach my $key (keys %{$attr}) {
3604     push( @rolled_array, { $key => $attr->{$key} } );
3605   }
3606   return \@rolled_array;
3607 }
3608
3609 sub _calculate_score {
3610   my ($self, $a, $b) = @_;
3611
3612   if (defined $a xor defined $b) {
3613     return 0;
3614   }
3615   elsif (not defined $a) {
3616     return 1;
3617   }
3618
3619   if (ref $b eq 'HASH') {
3620     my ($b_key) = keys %{$b};
3621     if (ref $a eq 'HASH') {
3622       my ($a_key) = keys %{$a};
3623       if ($a_key eq $b_key) {
3624         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3625       } else {
3626         return 0;
3627       }
3628     } else {
3629       return ($a eq $b_key) ? 1 : 0;
3630     }
3631   } else {
3632     if (ref $a eq 'HASH') {
3633       my ($a_key) = keys %{$a};
3634       return ($b eq $a_key) ? 1 : 0;
3635     } else {
3636       return ($b eq $a) ? 1 : 0;
3637     }
3638   }
3639 }
3640
3641 sub _merge_joinpref_attr {
3642   my ($self, $orig, $import) = @_;
3643
3644   return $import unless defined($orig);
3645   return $orig unless defined($import);
3646
3647   $orig = $self->_rollout_attr($orig);
3648   $import = $self->_rollout_attr($import);
3649
3650   my $seen_keys;
3651   foreach my $import_element ( @{$import} ) {
3652     # find best candidate from $orig to merge $b_element into
3653     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3654     foreach my $orig_element ( @{$orig} ) {
3655       my $score = $self->_calculate_score( $orig_element, $import_element );
3656       if ($score > $best_candidate->{score}) {
3657         $best_candidate->{position} = $position;
3658         $best_candidate->{score} = $score;
3659       }
3660       $position++;
3661     }
3662     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3663     $import_key = '' if not defined $import_key;
3664
3665     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3666       push( @{$orig}, $import_element );
3667     } else {
3668       my $orig_best = $orig->[$best_candidate->{position}];
3669       # merge orig_best and b_element together and replace original with merged
3670       if (ref $orig_best ne 'HASH') {
3671         $orig->[$best_candidate->{position}] = $import_element;
3672       } elsif (ref $import_element eq 'HASH') {
3673         my ($key) = keys %{$orig_best};
3674         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3675       }
3676     }
3677     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3678   }
3679
3680   return @$orig ? $orig : ();
3681 }
3682
3683 {
3684   my $hm;
3685
3686   sub _merge_attr {
3687     $hm ||= do {
3688       require Hash::Merge;
3689       my $hm = Hash::Merge->new;
3690
3691       $hm->specify_behavior({
3692         SCALAR => {
3693           SCALAR => sub {
3694             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3695
3696             if ($defl xor $defr) {
3697               return [ $defl ? $_[0] : $_[1] ];
3698             }
3699             elsif (! $defl) {
3700               return [];
3701             }
3702             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3703               return [ $_[0] ];
3704             }
3705             else {
3706               return [$_[0], $_[1]];
3707             }
3708           },
3709           ARRAY => sub {
3710             return $_[1] if !defined $_[0];
3711             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3712             return [$_[0], @{$_[1]}]
3713           },
3714           HASH  => sub {
3715             return [] if !defined $_[0] and !keys %{$_[1]};
3716             return [ $_[1] ] if !defined $_[0];
3717             return [ $_[0] ] if !keys %{$_[1]};
3718             return [$_[0], $_[1]]
3719           },
3720         },
3721         ARRAY => {
3722           SCALAR => sub {
3723             return $_[0] if !defined $_[1];
3724             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3725             return [@{$_[0]}, $_[1]]
3726           },
3727           ARRAY => sub {
3728             my @ret = @{$_[0]} or return $_[1];
3729             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3730             my %idx = map { $_ => 1 } @ret;
3731             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3732             \@ret;
3733           },
3734           HASH => sub {
3735             return [ $_[1] ] if ! @{$_[0]};
3736             return $_[0] if !keys %{$_[1]};
3737             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3738             return [ @{$_[0]}, $_[1] ];
3739           },
3740         },
3741         HASH => {
3742           SCALAR => sub {
3743             return [] if !keys %{$_[0]} and !defined $_[1];
3744             return [ $_[0] ] if !defined $_[1];
3745             return [ $_[1] ] if !keys %{$_[0]};
3746             return [$_[0], $_[1]]
3747           },
3748           ARRAY => sub {
3749             return [] if !keys %{$_[0]} and !@{$_[1]};
3750             return [ $_[0] ] if !@{$_[1]};
3751             return $_[1] if !keys %{$_[0]};
3752             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3753             return [ $_[0], @{$_[1]} ];
3754           },
3755           HASH => sub {
3756             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3757             return [ $_[0] ] if !keys %{$_[1]};
3758             return [ $_[1] ] if !keys %{$_[0]};
3759             return [ $_[0] ] if $_[0] eq $_[1];
3760             return [ $_[0], $_[1] ];
3761           },
3762         }
3763       } => 'DBIC_RS_ATTR_MERGER');
3764       $hm;
3765     };
3766
3767     return $hm->merge ($_[1], $_[2]);
3768   }
3769 }
3770
3771 sub STORABLE_freeze {
3772   my ($self, $cloning) = @_;
3773   my $to_serialize = { %$self };
3774
3775   # A cursor in progress can't be serialized (and would make little sense anyway)
3776   # the parser can be regenerated (and can't be serialized)
3777   delete @{$to_serialize}{qw/cursor _row_parser/};
3778
3779   # nor is it sensical to store a not-yet-fired-count pager
3780   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3781     delete $to_serialize->{pager};
3782   }
3783
3784   Storable::nfreeze($to_serialize);
3785 }
3786
3787 # need this hook for symmetry
3788 sub STORABLE_thaw {
3789   my ($self, $cloning, $serialized) = @_;
3790
3791   %$self = %{ Storable::thaw($serialized) };
3792
3793   $self;
3794 }
3795
3796
3797 =head2 throw_exception
3798
3799 See L<DBIx::Class::Schema/throw_exception> for details.
3800
3801 =cut
3802
3803 sub throw_exception {
3804   my $self=shift;
3805
3806   if (ref $self and my $rsrc = $self->result_source) {
3807     $rsrc->throw_exception(@_)
3808   }
3809   else {
3810     DBIx::Class::Exception->throw(@_);
3811   }
3812 }
3813
3814 # XXX: FIXME: Attributes docs need clearing up
3815
3816 =head1 ATTRIBUTES
3817
3818 Attributes are used to refine a ResultSet in various ways when
3819 searching for data. They can be passed to any method which takes an
3820 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3821 L</count>.
3822
3823 Default attributes can be set on the result class using
3824 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3825 the CAVEATS on that feature before using it!)
3826
3827 These are in no particular order:
3828
3829 =head2 order_by
3830
3831 =over 4
3832
3833 =item Value: ( $order_by | \@order_by | \%order_by )
3834
3835 =back
3836
3837 Which column(s) to order the results by.
3838
3839 [The full list of suitable values is documented in
3840 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3841 common options.]
3842
3843 If a single column name, or an arrayref of names is supplied, the
3844 argument is passed through directly to SQL. The hashref syntax allows
3845 for connection-agnostic specification of ordering direction:
3846
3847  For descending order:
3848
3849   order_by => { -desc => [qw/col1 col2 col3/] }
3850
3851  For explicit ascending order:
3852
3853   order_by => { -asc => 'col' }
3854
3855 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3856 supported, although you are strongly encouraged to use the hashref
3857 syntax as outlined above.
3858
3859 =head2 columns
3860
3861 =over 4
3862
3863 =item Value: \@columns
3864
3865 =back
3866
3867 Shortcut to request a particular set of columns to be retrieved. Each
3868 column spec may be a string (a table column name), or a hash (in which
3869 case the key is the C<as> value, and the value is used as the C<select>
3870 expression). Adds C<me.> onto the start of any column without a C<.> in
3871 it and sets C<select> from that, then auto-populates C<as> from
3872 C<select> as normal. (You may also use the C<cols> attribute, as in
3873 earlier versions of DBIC.)
3874
3875 Essentially C<columns> does the same as L</select> and L</as>.
3876
3877     columns => [ 'foo', { bar => 'baz' } ]
3878
3879 is the same as
3880
3881     select => [qw/foo baz/],
3882     as => [qw/foo bar/]
3883
3884 =head2 +columns
3885
3886 =over 4
3887
3888 =item Value: \@columns
3889
3890 =back
3891
3892 Indicates additional columns to be selected from storage. Works the same
3893 as L</columns> but adds columns to the selection. (You may also use the
3894 C<include_columns> attribute, as in earlier versions of DBIC). For
3895 example:-
3896
3897   $schema->resultset('CD')->search(undef, {
3898     '+columns' => ['artist.name'],
3899     join => ['artist']
3900   });
3901
3902 would return all CDs and include a 'name' column to the information
3903 passed to object inflation. Note that the 'artist' is the name of the
3904 column (or relationship) accessor, and 'name' is the name of the column
3905 accessor in the related table.
3906
3907 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3908 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3909 unary plus operator before it.
3910
3911 =head2 include_columns
3912
3913 =over 4
3914
3915 =item Value: \@columns
3916
3917 =back
3918
3919 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3920
3921 =head2 select
3922
3923 =over 4
3924
3925 =item Value: \@select_columns
3926
3927 =back
3928
3929 Indicates which columns should be selected from the storage. You can use
3930 column names, or in the case of RDBMS back ends, function or stored procedure
3931 names:
3932
3933   $rs = $schema->resultset('Employee')->search(undef, {
3934     select => [
3935       'name',
3936       { count => 'employeeid' },
3937       { max => { length => 'name' }, -as => 'longest_name' }
3938     ]
3939   });
3940
3941   # Equivalent SQL
3942   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3943
3944 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3945 use L</select>, to instruct DBIx::Class how to store the result of the column.
3946 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3947 identifier aliasing. You can however alias a function, so you can use it in
3948 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3949 attribute> supplied as shown in the example above.
3950
3951 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3952 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3953 unary plus operator before it.
3954
3955 =head2 +select
3956
3957 =over 4
3958
3959 Indicates additional columns to be selected from storage.  Works the same as
3960 L</select> but adds columns to the default selection, instead of specifying
3961 an explicit list.
3962
3963 =back
3964
3965 =head2 +as
3966
3967 =over 4
3968
3969 Indicates additional column names for those added via L</+select>. See L</as>.
3970
3971 =back
3972
3973 =head2 as
3974
3975 =over 4
3976
3977 =item Value: \@inflation_names
3978
3979 =back
3980
3981 Indicates column names for object inflation. That is L</as> indicates the
3982 slot name in which the column value will be stored within the
3983 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3984 identifier by the C<get_column> method (or via the object accessor B<if one
3985 with the same name already exists>) as shown below. The L</as> attribute has
3986 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3987
3988   $rs = $schema->resultset('Employee')->search(undef, {
3989     select => [
3990       'name',
3991       { count => 'employeeid' },
3992       { max => { length => 'name' }, -as => 'longest_name' }
3993     ],
3994     as => [qw/
3995       name
3996       employee_count
3997       max_name_length
3998     /],
3999   });
4000
4001 If the object against which the search is performed already has an accessor
4002 matching a column name specified in C<as>, the value can be retrieved using
4003 the accessor as normal:
4004
4005   my $name = $employee->name();
4006
4007 If on the other hand an accessor does not exist in the object, you need to
4008 use C<get_column> instead:
4009
4010   my $employee_count = $employee->get_column('employee_count');
4011
4012 You can create your own accessors if required - see
4013 L<DBIx::Class::Manual::Cookbook> for details.
4014
4015 =head2 join
4016
4017 =over 4
4018
4019 =item Value: ($rel_name | \@rel_names | \%rel_names)
4020
4021 =back
4022
4023 Contains a list of relationships that should be joined for this query.  For
4024 example:
4025
4026   # Get CDs by Nine Inch Nails
4027   my $rs = $schema->resultset('CD')->search(
4028     { 'artist.name' => 'Nine Inch Nails' },
4029     { join => 'artist' }
4030   );
4031
4032 Can also contain a hash reference to refer to the other relation's relations.
4033 For example:
4034
4035   package MyApp::Schema::Track;
4036   use base qw/DBIx::Class/;
4037   __PACKAGE__->table('track');
4038   __PACKAGE__->add_columns(qw/trackid cd position title/);
4039   __PACKAGE__->set_primary_key('trackid');
4040   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4041   1;
4042
4043   # In your application
4044   my $rs = $schema->resultset('Artist')->search(
4045     { 'track.title' => 'Teardrop' },
4046     {
4047       join     => { cd => 'track' },
4048       order_by => 'artist.name',
4049     }
4050   );
4051
4052 You need to use the relationship (not the table) name in  conditions,
4053 because they are aliased as such. The current table is aliased as "me", so
4054 you need to use me.column_name in order to avoid ambiguity. For example:
4055
4056   # Get CDs from 1984 with a 'Foo' track
4057   my $rs = $schema->resultset('CD')->search(
4058     {
4059       'me.year' => 1984,
4060       'tracks.name' => 'Foo'
4061     },
4062     { join => 'tracks' }
4063   );
4064
4065 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4066 similarly for a third time). For e.g.
4067
4068   my $rs = $schema->resultset('Artist')->search({
4069     'cds.title'   => 'Down to Earth',
4070     'cds_2.title' => 'Popular',
4071   }, {
4072     join => [ qw/cds cds/ ],
4073   });
4074
4075 will return a set of all artists that have both a cd with title 'Down
4076 to Earth' and a cd with title 'Popular'.
4077
4078 If you want to fetch related objects from other tables as well, see C<prefetch>
4079 below.
4080
4081  NOTE: An internal join-chain pruner will discard certain joins while
4082  constructing the actual SQL query, as long as the joins in question do not
4083  affect the retrieved result. This for example includes 1:1 left joins
4084  that are not part of the restriction specification (WHERE/HAVING) nor are
4085  a part of the query selection.
4086
4087 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4088
4089 =head2 prefetch
4090
4091 =over 4
4092
4093 =item Value: ($rel_name | \@rel_names | \%rel_names)
4094
4095 =back
4096
4097 Contains one or more relationships that should be fetched along with
4098 the main query (when they are accessed afterwards the data will
4099 already be available, without extra queries to the database).  This is
4100 useful for when you know you will need the related objects, because it
4101 saves at least one query:
4102
4103   my $rs = $schema->resultset('Tag')->search(
4104     undef,
4105     {
4106       prefetch => {
4107         cd => 'artist'
4108       }
4109     }
4110   );
4111
4112 The initial search results in SQL like the following:
4113
4114   SELECT tag.*, cd.*, artist.* FROM tag
4115   JOIN cd ON tag.cd = cd.cdid
4116   JOIN artist ON cd.artist = artist.artistid
4117
4118 L<DBIx::Class> has no need to go back to the database when we access the
4119 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4120 case.
4121
4122 Simple prefetches will be joined automatically, so there is no need
4123 for a C<join> attribute in the above search.
4124
4125 L</prefetch> can be used with the any of the relationship types and
4126 multiple prefetches can be specified together. Below is a more complex
4127 example that prefetches a CD's artist, its liner notes (if present),
4128 the cover image, the tracks on that cd, and the guests on those
4129 tracks.
4130
4131  # Assuming:
4132  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4133  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4134  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
4135  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4136
4137  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4138
4139  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4140
4141
4142  my $rs = $schema->resultset('CD')->search(
4143    undef,
4144    {
4145      prefetch => [
4146        { artist => 'record_label'},  # belongs_to => belongs_to
4147        'liner_note',                 # might_have
4148        'cover_image',                # has_one
4149        { tracks => 'guests' },       # has_many => has_many
4150      ]
4151    }
4152  );
4153
4154 This will produce SQL like the following:
4155
4156  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4157         tracks.*, guests.*
4158    FROM cd me
4159    JOIN artist artist
4160      ON artist.artistid = me.artistid
4161    JOIN record_label record_label
4162      ON record_label.labelid = artist.labelid
4163    LEFT JOIN track tracks
4164      ON tracks.cdid = me.cdid
4165    LEFT JOIN guest guests
4166      ON guests.trackid = track.trackid
4167    LEFT JOIN liner_notes liner_note
4168      ON liner_note.cdid = me.cdid
4169    JOIN cd_artwork cover_image
4170      ON cover_image.cdid = me.cdid
4171  ORDER BY tracks.cd
4172
4173 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4174 C<tracks>, and C<guests> of the CD will all be available through the
4175 relationship accessors without the need for additional queries to the
4176 database.
4177
4178 However, there is one caveat to be observed: it can be dangerous to
4179 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4180 relationship on a given level. e.g.:
4181
4182  my $rs = $schema->resultset('CD')->search(
4183    undef,
4184    {
4185      prefetch => [
4186        'tracks',                         # has_many
4187        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4188      ]
4189    }
4190  );
4191
4192 The collapser currently can't identify duplicate tuples for multiple
4193 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4194 result the second L<has_many|DBIx::Class::Relationship/has_many>
4195 relation could contain redundant objects.
4196
4197 =head3 Using L</prefetch> with L</join>
4198
4199 L</prefetch> implies a L</join> with the equivalent argument, and is
4200 properly merged with any existing L</join> specification. So the
4201 following:
4202
4203   my $rs = $schema->resultset('CD')->search(
4204    {'record_label.name' => 'Music Product Ltd.'},
4205    {
4206      join     => {artist => 'record_label'},
4207      prefetch => 'artist',
4208    }
4209  );
4210
4211 ... will work, searching on the record label's name, but only
4212 prefetching the C<artist>.
4213
4214 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4215
4216 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4217 prefetched relations.  So given:
4218
4219   my $rs = $schema->resultset('CD')->search(
4220    undef,
4221    {
4222      select   => ['cd.title'],
4223      as       => ['cd_title'],
4224      prefetch => 'artist',
4225    }
4226  );
4227
4228 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4229 becomes: C<'cd_title', 'artist.*'>.
4230
4231 =head3 CAVEATS
4232
4233 Prefetch does a lot of deep magic. As such, it may not behave exactly
4234 as you might expect.
4235
4236 =over 4
4237
4238 =item *
4239
4240 Prefetch uses the L</cache> to populate the prefetched relationships. This
4241 may or may not be what you want.
4242
4243 =item *
4244
4245 If you specify a condition on a prefetched relationship, ONLY those
4246 rows that match the prefetched condition will be fetched into that relationship.
4247 This means that adding prefetch to a search() B<may alter> what is returned by
4248 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4249
4250   my $artist_rs = $schema->resultset('Artist')->search({
4251       'cds.year' => 2008,
4252   }, {
4253       join => 'cds',
4254   });
4255
4256   my $count = $artist_rs->first->cds->count;
4257
4258   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4259
4260   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4261
4262   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4263
4264 that cmp_ok() may or may not pass depending on the datasets involved. This
4265 behavior may or may not survive the 0.09 transition.
4266
4267 =back
4268
4269 =head2 alias
4270
4271 =over 4
4272
4273 =item Value: $source_alias
4274
4275 =back
4276
4277 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4278 nested search queries (sub-SELECTs) might need specific aliases set to
4279 reference inner queries.  For example:
4280
4281    my $q = $rs
4282       ->related_resultset('CDs')
4283       ->related_resultset('Tracks')
4284       ->search({
4285          'track.id' => { -ident => 'none_search.id' },
4286       })
4287       ->as_query;
4288
4289    my $ids = $self->search({
4290       -not_exists => $q,
4291    }, {
4292       alias    => 'none_search',
4293       group_by => 'none_search.id',
4294    })->get_column('id')->as_query;
4295
4296    $self->search({ id => { -in => $ids } })
4297
4298 This attribute is directly tied to L</current_source_alias>.
4299
4300 =head2 page
4301
4302 =over 4
4303
4304 =item Value: $page
4305
4306 =back
4307
4308 Makes the resultset paged and specifies the page to retrieve. Effectively
4309 identical to creating a non-pages resultset and then calling ->page($page)
4310 on it.
4311
4312 If L</rows> attribute is not specified it defaults to 10 rows per page.
4313
4314 When you have a paged resultset, L</count> will only return the number
4315 of rows in the page. To get the total, use the L</pager> and call
4316 C<total_entries> on it.
4317
4318 =head2 rows
4319
4320 =over 4
4321
4322 =item Value: $rows
4323
4324 =back
4325
4326 Specifies the maximum number of rows for direct retrieval or the number of
4327 rows per page if the page attribute or method is used.
4328
4329 =head2 offset
4330
4331 =over 4
4332
4333 =item Value: $offset
4334
4335 =back
4336
4337 Specifies the (zero-based) row number for the  first row to be returned, or the
4338 of the first row of the first page if paging is used.
4339
4340 =head2 software_limit
4341
4342 =over 4
4343
4344 =item Value: (0 | 1)
4345
4346 =back
4347
4348 When combined with L</rows> and/or L</offset> the generated SQL will not
4349 include any limit dialect stanzas. Instead the entire result will be selected
4350 as if no limits were specified, and DBIC will perform the limit locally, by
4351 artificially advancing and finishing the resulting L</cursor>.
4352
4353 This is the recommended way of performing resultset limiting when no sane RDBMS
4354 implementation is available (e.g.
4355 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4356 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4357
4358 =head2 group_by
4359
4360 =over 4
4361
4362 =item Value: \@columns
4363
4364 =back
4365
4366 A arrayref of columns to group by. Can include columns of joined tables.
4367
4368   group_by => [qw/ column1 column2 ... /]
4369
4370 =head2 having
4371
4372 =over 4
4373
4374 =item Value: $condition
4375
4376 =back
4377
4378 HAVING is a select statement attribute that is applied between GROUP BY and
4379 ORDER BY. It is applied to the after the grouping calculations have been
4380 done.
4381
4382   having => { 'count_employee' => { '>=', 100 } }
4383
4384 or with an in-place function in which case literal SQL is required:
4385
4386   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4387
4388 =head2 distinct
4389
4390 =over 4
4391
4392 =item Value: (0 | 1)
4393
4394 =back
4395
4396 Set to 1 to group by all columns. If the resultset already has a group_by
4397 attribute, this setting is ignored and an appropriate warning is issued.
4398
4399 =head2 where
4400
4401 =over 4
4402
4403 Adds to the WHERE clause.
4404
4405   # only return rows WHERE deleted IS NULL for all searches
4406   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4407
4408 Can be overridden by passing C<< { where => undef } >> as an attribute
4409 to a resultset.
4410
4411 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4412
4413 =back
4414
4415 =head2 cache
4416
4417 Set to 1 to cache search results. This prevents extra SQL queries if you
4418 revisit rows in your ResultSet:
4419
4420   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4421
4422   while( my $artist = $resultset->next ) {
4423     ... do stuff ...
4424   }
4425
4426   $rs->first; # without cache, this would issue a query
4427
4428 By default, searches are not cached.
4429
4430 For more examples of using these attributes, see
4431 L<DBIx::Class::Manual::Cookbook>.
4432
4433 =head2 for
4434
4435 =over 4
4436
4437 =item Value: ( 'update' | 'shared' | \$scalar )
4438
4439 =back
4440
4441 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4442 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4443 query.
4444
4445 =head1 DBIC BIND VALUES
4446
4447 Because DBIC may need more information to bind values than just the column name
4448 and value itself, it uses a special format for both passing and receiving bind
4449 values.  Each bind value should be composed of an arrayref of
4450 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4451
4452 =over 4
4453
4454 =item dbd_attrs
4455
4456 If present (in any form), this is what is being passed directly to bind_param.
4457 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4458 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4459
4460 If this is specified, all other bind options described below are ignored.
4461
4462 =item sqlt_datatype
4463
4464 If present, this is used to infer the actual bind attribute by passing to
4465 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4466 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4467
4468 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4469 currently drivers are expected to "Do the Right Thing" when given a common
4470 datatype name.  (Not ideal, but that's what we got at this point.)
4471
4472 =item sqlt_size
4473
4474 Currently used to correctly allocate buffers for bind_param_inout().
4475 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4476 or to a sensible value based on the "data_type".
4477
4478 =item dbic_colname
4479
4480 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4481 explicitly specified they are never overriden).  Also used by some weird DBDs,
4482 where the column name should be available at bind_param time (e.g. Oracle).
4483
4484 =back
4485
4486 For backwards compatibility and convenience, the following shortcuts are
4487 supported:
4488
4489   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4490   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4491   [ undef,   $val ] === [ {}, $val ]
4492
4493 =head1 AUTHOR AND CONTRIBUTORS
4494
4495 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4496
4497 =head1 LICENSE
4498
4499 You may distribute this code under the same terms as Perl itself.
4500
4501 =cut
4502
4503 1;