lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::Exception;
   8 use DBIx::Class::ResultSetColumn;
   9 use Scalar::Util qw/blessed weaken/;
  10 use Try::Tiny;
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  29
  30 =head1 NAME
  31
  32 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  33
  34 =head1 SYNOPSIS
  35
  36   my $users_rs   = $schema->resultset('User');
  37   while( $user = $users_rs->next) {
  38     print $user->username;
  39   }
  40
  41   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  42   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  43
  44 =head1 DESCRIPTION
  45
  46 A ResultSet is an object which stores a set of conditions representing
  47 a query. It is the backbone of DBIx::Class (i.e. the really
  48 important/useful bit).
  49
  50 No SQL is executed on the database when a ResultSet is created, it
  51 just stores all the conditions needed to create the query.
  52
  53 A basic ResultSet representing the data of an entire table is returned
  54 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  55 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  56
  57   my $users_rs = $schema->resultset('User');
  58
  59 A new ResultSet is returned from calling L</search> on an existing
  60 ResultSet. The new one will contain all the conditions of the
  61 original, plus any new conditions added in the C<search> call.
  62
  63 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  64 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  65 represents.
  66
  67 The query that the ResultSet represents is B<only> executed against
  68 the database when these methods are called:
  69 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  70
  71 If a resultset is used in a numeric context it returns the L</count>.
  72 However, if it is used in a boolean context it is B<always> true.  So if
  73 you want to check if a resultset has any results, you must use C<if $rs
  74 != 0>.
  75
  76 =head1 EXAMPLES
  77
  78 =head2 Chaining resultsets
  79
  80 Let's say you've got a query that needs to be run to return some data
  81 to the user. But, you have an authorization system in place that
  82 prevents certain users from seeing certain information. So, you want
  83 to construct the basic query in one method, but add constraints to it in
  84 another.
  85
  86   sub get_data {
  87     my $self = shift;
  88     my $request = $self->get_request; # Get a request object somehow.
  89     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  90
  91     my $cd_rs = $schema->resultset('CD')->search({
  92       title => $request->param('title'),
  93       year => $request->param('year'),
  94     });
  95
  96     $cd_rs = $self->apply_security_policy( $cd_rs );
  97
  98     return $cd_rs->all();
  99   }
 100
 101   sub apply_security_policy {
 102     my $self = shift;
 103     my ($rs) = @_;
 104
 105     return $rs->search({
 106       subversive => 0,
 107     });
 108   }
 109
 110 =head3 Resolving conditions and attributes
 111
 112 When a resultset is chained from another resultset, conditions and
 113 attributes with the same keys need resolving.
 114
 115 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 116 into the existing ones from the original resultset.
 117
 118 The L</where> and L</having> attributes, and any search conditions, are
 119 merged with an SQL C<AND> to the existing condition from the original
 120 resultset.
 121
 122 All other attributes are overridden by any new ones supplied in the
 123 search attributes.
 124
 125 =head2 Multiple queries
 126
 127 Since a resultset just defines a query, you can do all sorts of
 128 things with it with the same object.
 129
 130   # Don't hit the DB yet.
 131   my $cd_rs = $schema->resultset('CD')->search({
 132     title => 'something',
 133     year => 2009,
 134   });
 135
 136   # Each of these hits the DB individually.
 137   my $count = $cd_rs->count;
 138   my $most_recent = $cd_rs->get_column('date_released')->max();
 139   my @records = $cd_rs->all;
 140
 141 And it's not just limited to SELECT statements.
 142
 143   $cd_rs->delete();
 144
 145 This is even cooler:
 146
 147   $cd_rs->create({ artist => 'Fred' });
 148
 149 Which is the same as:
 150
 151   $schema->resultset('CD')->create({
 152     title => 'something',
 153     year => 2009,
 154     artist => 'Fred'
 155   });
 156
 157 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 158
 159 =head1 METHODS
 160
 161 =head2 new
 162
 163 =over 4
 164
 165 =item Arguments: $source, \%$attrs
 166
 167 =item Return Value: $rs
 168
 169 =back
 170
 171 The resultset constructor. Takes a source object (usually a
 172 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 173 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 174 executed as needed by the other methods.
 175
 176 Generally you won't need to construct a resultset manually.  You'll
 177 automatically get one from e.g. a L</search> called in scalar context:
 178
 179   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 180
 181 IMPORTANT: If called on an object, proxies to new_result instead so
 182
 183   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 184
 185 will return a CD object, not a ResultSet.
 186
 187 =cut
 188
 189 sub new {
 190   my $class = shift;
 191   return $class->new_result(@_) if ref $class;
 192
 193   my ($source, $attrs) = @_;
 194   $source = $source->resolve
 195     if $source->isa('DBIx::Class::ResultSourceHandle');
 196   $attrs = { %{$attrs||{}} };
 197
 198   if ($attrs->{page}) {
 199     $attrs->{rows} ||= 10;
 200   }
 201
 202   $attrs->{alias} ||= 'me';
 203
 204   my $self = bless {
 205     result_source => $source,
 206     cond => $attrs->{where},
 207     pager => undef,
 208     attrs => $attrs,
 209   }, $class;
 210
 211   $self->result_class(
 212     $attrs->{result_class} || $source->result_class
 213   );
 214
 215   $self;
 216 }
 217
 218 =head2 search
 219
 220 =over 4
 221
 222 =item Arguments: $cond, \%attrs?
 223
 224 =item Return Value: $resultset (scalar context) ||  @row_objs (list context)
 225
 226 =back
 227
 228   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 229   my $new_rs = $cd_rs->search({ year => 2005 });
 230
 231   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 232                  # year = 2005 OR year = 2004
 233
 234 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 235 returning a list of row objects instead. To avoid that, use L</search_rs>.
 236
 237 If you need to pass in additional attributes but no additional condition,
 238 call it as C<search(undef, \%attrs)>.
 239
 240   # "SELECT name, artistid FROM $artist_table"
 241   my @all_artists = $schema->resultset('Artist')->search(undef, {
 242     columns => [qw/name artistid/],
 243   });
 244
 245 For a list of attributes that can be passed to C<search>, see
 246 L</ATTRIBUTES>. For more examples of using this function, see
 247 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 248 documentation for the first argument, see L<SQL::Abstract>.
 249
 250 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 251
 252 =head3 CAVEAT
 253
 254 Note that L</search> does not process/deflate any of the values passed in the
 255 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 256 condition-bound methods L</new>, L</create> and L</find>. The user must ensure
 257 manually that any value passed to this method will stringify to something the
 258 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 259 objects, for more info see:
 260 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
 261
 262 =cut
 263
 264 sub search {
 265   my $self = shift;
 266   my $rs = $self->search_rs( @_ );
 267
 268   if (wantarray) {
 269     return $rs->all;
 270   }
 271   elsif (defined wantarray) {
 272     return $rs;
 273   }
 274   else {
 275     # we can be called by a relationship helper, which in
 276     # turn may be called in void context due to some braindead
 277     # overload or whatever else the user decided to be clever
 278     # at this particular day. Thus limit the exception to
 279     # external code calls only
 280     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 281       if (caller)[0] !~ /^\QDBIx::Class::/;
 282
 283     return ();
 284   }
 285 }
 286
 287 =head2 search_rs
 288
 289 =over 4
 290
 291 =item Arguments: $cond, \%attrs?
 292
 293 =item Return Value: $resultset
 294
 295 =back
 296
 297 This method does the same exact thing as search() except it will
 298 always return a resultset, even in list context.
 299
 300 =cut
 301
 302 sub search_rs {
 303   my $self = shift;
 304
 305   # Special-case handling for (undef, undef).
 306   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 307     @_ = ();
 308   }
 309
 310   my $call_attrs = {};
 311   if (@_ > 1) {
 312     if (ref $_[-1] eq 'HASH') {
 313       # copy for _normalize_selection
 314       $call_attrs = { %{ pop @_ } };
 315     }
 316     elsif (! defined $_[-1] ) {
 317       pop @_;   # search({}, undef)
 318     }
 319   }
 320
 321   # see if we can keep the cache (no $rs changes)
 322   my $cache;
 323   my %safe = (alias => 1, cache => 1);
 324   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 325     ! defined $_[0]
 326       or
 327     ref $_[0] eq 'HASH' && ! keys %{$_[0]}
 328       or
 329     ref $_[0] eq 'ARRAY' && ! @{$_[0]}
 330   )) {
 331     $cache = $self->get_cache;
 332   }
 333
 334   my $rsrc = $self->result_source;
 335
 336   my $old_attrs = { %{$self->{attrs}} };
 337   my $old_having = delete $old_attrs->{having};
 338   my $old_where = delete $old_attrs->{where};
 339
 340   my $new_attrs = { %$old_attrs };
 341
 342   # take care of call attrs (only if anything is changing)
 343   if (keys %$call_attrs) {
 344
 345     $self->throw_exception ('_trailing_select is not a public attribute - do not use it in search()')
 346       if ( exists $call_attrs->{_trailing_select} or exists $call_attrs->{'+_trailing_select'} );
 347
 348     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns _trailing_select +_trailing_select/;
 349
 350     # Normalize the selector list (operates on the passed-in attr structure)
 351     # Need to do it on every chain instead of only once on _resolved_attrs, in
 352     # order to separate 'as'-ed from blind 'select's
 353     $self->_normalize_selection ($call_attrs);
 354
 355     # start with blind overwriting merge, exclude selector attrs
 356     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 357     delete @{$new_attrs}{@selector_attrs};
 358
 359     # reset the current selector list if new selectors are supplied
 360     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 361       delete @{$old_attrs}{@selector_attrs};
 362     }
 363
 364     for (@selector_attrs) {
 365       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 366         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 367     }
 368
 369     # older deprecated name, use only if {columns} is not there
 370     if (my $c = delete $new_attrs->{cols}) {
 371       if ($new_attrs->{columns}) {
 372         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 373       }
 374       else {
 375         $new_attrs->{columns} = $c;
 376       }
 377     }
 378
 379
 380     # join/prefetch use their own crazy merging heuristics
 381     foreach my $key (qw/join prefetch/) {
 382       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 383         if exists $call_attrs->{$key};
 384     }
 385
 386     # stack binds together
 387     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 388   }
 389
 390
 391   # rip apart the rest of @_, parse a condition
 392   my $call_cond = do {
 393
 394     if (ref $_[0] eq 'HASH') {
 395       (keys %{$_[0]}) ? $_[0] : undef
 396     }
 397     elsif (@_ == 1) {
 398       $_[0]
 399     }
 400     elsif (@_ % 2) {
 401       $self->throw_exception('Odd number of arguments to search')
 402     }
 403     else {
 404       +{ @_ }
 405     }
 406
 407   } if @_;
 408
 409   if( @_ > 1 and ! $rsrc->result_class->isa('DBIx::Class::CDBICompat') ) {
 410     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead';
 411   }
 412
 413   for ($old_where, $call_cond) {
 414     if (defined $_) {
 415       $new_attrs->{where} = $self->_stack_cond (
 416         $_, $new_attrs->{where}
 417       );
 418     }
 419   }
 420
 421   if (defined $old_having) {
 422     $new_attrs->{having} = $self->_stack_cond (
 423       $old_having, $new_attrs->{having}
 424     )
 425   }
 426
 427   my $rs = (ref $self)->new($rsrc, $new_attrs);
 428
 429   $rs->set_cache($cache) if ($cache);
 430
 431   return $rs;
 432 }
 433
 434 sub _normalize_selection {
 435   my ($self, $attrs) = @_;
 436
 437   # legacy syntax
 438   $attrs->{'+columns'} = $self->_merge_attr($attrs->{'+columns'}, delete $attrs->{include_columns})
 439     if exists $attrs->{include_columns};
 440
 441   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 442   # delay the decision on whether to use a default select list ($rsrc->columns)
 443   # allowing stuff like the remove_columns helper to work
 444   #
 445   # select/as +select/+as pairs need special handling - the amount of select/as
 446   # elements in each pair does *not* have to be equal (think multicolumn
 447   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 448   # supplied at all) - try to infer the alias, either from the -as parameter
 449   # of the selector spec, or use the parameter whole if it looks like a column
 450   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 451   # is ok as well), but transport it over a separate attribute to make sure it is
 452   # the last thing in the select list, thus unable to throw off the corresponding
 453   # 'as' chain
 454   for my $pref ('', '+') {
 455
 456     my ($sel, $as) = map {
 457       my $key = "${pref}${_}";
 458
 459       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 460         ? @{$attrs->{$key}}
 461         : $attrs->{$key} || ()
 462       ];
 463       delete $attrs->{$key};
 464       $val;
 465     } qw/select as/;
 466
 467     if (! @$as and ! @$sel ) {
 468       next;
 469     }
 470     elsif (@$as and ! @$sel) {
 471       $self->throw_exception(
 472         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 473       );
 474     }
 475     elsif( ! @$as ) {
 476       # no as part supplied at all - try to deduce
 477       # if any @$as has been supplied we assume the user knows what (s)he is doing
 478       # and blindly keep stacking up pieces
 479       my (@new_sel, @new_trailing);
 480       for (@$sel) {
 481         if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 482           push @$as, $_->{-as};
 483           push @new_sel, $_;
 484         }
 485         # assume any plain no-space, no-parenthesis string to be a column spec
 486         # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 487         elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 488           push @$as, $_;
 489           push @new_sel, $_;
 490         }
 491         # if all else fails - shove the selection to the trailing stack and move on
 492         else {
 493           push @new_trailing, $_;
 494         }
 495       }
 496
 497       @$sel = @new_sel;
 498       $attrs->{"${pref}_trailing_select"} = $self->_merge_attr($attrs->{"${pref}_trailing_select"}, \@new_trailing)
 499         if @new_trailing;
 500     }
 501     elsif (@$as < @$sel) {
 502       $self->throw_exception(
 503         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 504       );
 505     }
 506
 507     # now see what the result for this pair looks like:
 508     if (@$as == @$sel) {
 509
 510       # if balanced - treat as a columns entry
 511       $attrs->{"${pref}columns"} = $self->_merge_attr(
 512         $attrs->{"${pref}columns"},
 513         [ map { +{ $as->[$_] => $sel->[$_] } } ( 0 .. $#$as ) ]
 514       );
 515     }
 516     else {
 517       # unbalanced - shove in select/as, not subject to deduplication in _resolved_attrs
 518       $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 519       $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 520     }
 521   }
 522
 523 }
 524
 525 sub _stack_cond {
 526   my ($self, $left, $right) = @_;
 527   if (defined $left xor defined $right) {
 528     return defined $left ? $left : $right;
 529   }
 530   elsif (defined $left) {
 531     return { -and => [ map
 532       { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 533       ($left, $right)
 534     ]};
 535   }
 536
 537   return undef;
 538 }
 539
 540 =head2 search_literal
 541
 542 =over 4
 543
 544 =item Arguments: $sql_fragment, @bind_values
 545
 546 =item Return Value: $resultset (scalar context) || @row_objs (list context)
 547
 548 =back
 549
 550   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 551   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 552
 553 Pass a literal chunk of SQL to be added to the conditional part of the
 554 resultset query.
 555
 556 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 557 only be used in that context. C<search_literal> is a convenience method.
 558 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 559 columns are bound correctly, use C<search>.
 560
 561 Example of how to use C<search> instead of C<search_literal>
 562
 563   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 564   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 565
 566
 567 See L<DBIx::Class::Manual::Cookbook/Searching> and
 568 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 569 require C<search_literal>.
 570
 571 =cut
 572
 573 sub search_literal {
 574   my ($self, $sql, @bind) = @_;
 575   my $attr;
 576   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 577     $attr = pop @bind;
 578   }
 579   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 580 }
 581
 582 =head2 find
 583
 584 =over 4
 585
 586 =item Arguments: \%columns_values | @pk_values, \%attrs?
 587
 588 =item Return Value: $row_object | undef
 589
 590 =back
 591
 592 Finds and returns a single row based on supplied criteria. Takes either a
 593 hashref with the same format as L</create> (including inference of foreign
 594 keys from related objects), or a list of primary key values in the same
 595 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 596 declaration on the L</result_source>.
 597
 598 In either case an attempt is made to combine conditions already existing on
 599 the resultset with the condition passed to this method.
 600
 601 To aid with preparing the correct query for the storage you may supply the
 602 C<key> attribute, which is the name of a
 603 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 604 unique constraint corresponding to the
 605 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 606 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 607 to construct a query that satisfies the named unique constraint fully (
 608 non-NULL values for each column member of the constraint) an exception is
 609 thrown.
 610
 611 If no C<key> is specified, the search is carried over all unique constraints
 612 which are fully defined by the available condition.
 613
 614 If no such constraint is found, C<find> currently defaults to a simple
 615 C<< search->(\%column_values) >> which may or may not do what you expect.
 616 Note that this fallback behavior may be deprecated in further versions. If
 617 you need to search with arbitrary conditions - use L</search>. If the query
 618 resulting from this fallback produces more than one row, a warning to the
 619 effect is issued, though only the first row is constructed and returned as
 620 C<$row_object>.
 621
 622 In addition to C<key>, L</find> recognizes and applies standard
 623 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 624
 625 Note that if you have extra concerns about the correctness of the resulting
 626 query you need to specify the C<key> attribute and supply the entire condition
 627 as an argument to find (since it is not always possible to perform the
 628 combination of the resultset condition with the supplied one, especially if
 629 the resultset condition contains literal sql).
 630
 631 For example, to find a row by its primary key:
 632
 633   my $cd = $schema->resultset('CD')->find(5);
 634
 635 You can also find a row by a specific unique constraint:
 636
 637   my $cd = $schema->resultset('CD')->find(
 638     {
 639       artist => 'Massive Attack',
 640       title  => 'Mezzanine',
 641     },
 642     { key => 'cd_artist_title' }
 643   );
 644
 645 See also L</find_or_create> and L</update_or_create>.
 646
 647 =cut
 648
 649 sub find {
 650   my $self = shift;
 651   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 652
 653   my $rsrc = $self->result_source;
 654
 655   # Parse out the condition from input
 656   my $call_cond;
 657   if (ref $_[0] eq 'HASH') {
 658     $call_cond = { %{$_[0]} };
 659   }
 660   else {
 661     my $constraint = exists $attrs->{key} ? $attrs->{key} : 'primary';
 662     my @c_cols = $rsrc->unique_constraint_columns($constraint);
 663
 664     $self->throw_exception(
 665       "No constraint columns, maybe a malformed '$constraint' constraint?"
 666     ) unless @c_cols;
 667
 668     $self->throw_exception (
 669       'find() expects either a column/value hashref, or a list of values '
 670     . "corresponding to the columns of the specified unique constraint '$constraint'"
 671     ) unless @c_cols == @_;
 672
 673     $call_cond = {};
 674     @{$call_cond}{@c_cols} = @_;
 675   }
 676
 677   my %related;
 678   for my $key (keys %$call_cond) {
 679     if (
 680       my $keyref = ref($call_cond->{$key})
 681         and
 682       my $relinfo = $rsrc->relationship_info($key)
 683     ) {
 684       my $val = delete $call_cond->{$key};
 685
 686       next if $keyref eq 'ARRAY'; # has_many for multi_create
 687
 688       my $rel_q = $rsrc->_resolve_condition(
 689         $relinfo->{cond}, $val, $key, $key
 690       );
 691       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 692       @related{keys %$rel_q} = values %$rel_q;
 693     }
 694   }
 695
 696   # relationship conditions take precedence (?)
 697   @{$call_cond}{keys %related} = values %related;
 698
 699   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 700   my $final_cond;
 701   if (exists $attrs->{key}) {
 702     $final_cond = $self->_qualify_cond_columns (
 703
 704       $self->_build_unique_cond (
 705         $attrs->{key},
 706         $call_cond,
 707       ),
 708
 709       $alias,
 710     );
 711   }
 712   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 713     # This means that we got here after a merger of relationship conditions
 714     # in ::Relationship::Base::search_related (the row method), and furthermore
 715     # the relationship is of the 'single' type. This means that the condition
 716     # provided by the relationship (already attached to $self) is sufficient,
 717     # as there can be only one row in the database that would satisfy the
 718     # relationship
 719   }
 720   else {
 721     # no key was specified - fall down to heuristics mode:
 722     # run through all unique queries registered on the resultset, and
 723     # 'OR' all qualifying queries together
 724     my (@unique_queries, %seen_column_combinations);
 725     for my $c_name ($rsrc->unique_constraint_names) {
 726       next if $seen_column_combinations{
 727         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 728       }++;
 729
 730       push @unique_queries, try {
 731         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 732       } || ();
 733     }
 734
 735     $final_cond = @unique_queries
 736       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 737       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 738     ;
 739   }
 740
 741   # Run the query, passing the result_class since it should propagate for find
 742   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 743   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 744     my $row = $rs->next;
 745     carp "Query returned more than one row" if $rs->next;
 746     return $row;
 747   }
 748   else {
 749     return $rs->single;
 750   }
 751 }
 752
 753 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 754 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 755 #
 756 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 757 # condition. It is provided for overrides until a saner way forward is devised
 758 #
 759 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 760 # the road. Please adjust your tests accordingly to catch this situation early
 761 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 762 #
 763 # The method will not be removed without an adequately complete replacement
 764 # for strict-mode enforcement
 765 sub _non_unique_find_fallback {
 766   my ($self, $cond, $attrs) = @_;
 767
 768   return $self->_qualify_cond_columns(
 769     $cond,
 770     exists $attrs->{alias}
 771       ? $attrs->{alias}
 772       : $self->{attrs}{alias}
 773   );
 774 }
 775
 776
 777 sub _qualify_cond_columns {
 778   my ($self, $cond, $alias) = @_;
 779
 780   my %aliased = %$cond;
 781   for (keys %aliased) {
 782     $aliased{"$alias.$_"} = delete $aliased{$_}
 783       if $_ !~ /\./;
 784   }
 785
 786   return \%aliased;
 787 }
 788
 789 sub _build_unique_cond {
 790   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 791
 792   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 793
 794   # combination may fail if $self->{cond} is non-trivial
 795   my ($final_cond) = try {
 796     $self->_merge_with_rscond ($extra_cond)
 797   } catch {
 798     +{ %$extra_cond }
 799   };
 800
 801   # trim out everything not in $columns
 802   $final_cond = { map {
 803     exists $final_cond->{$_}
 804       ? ( $_ => $final_cond->{$_} )
 805       : ()
 806   } @c_cols };
 807
 808   if (my @missing = grep
 809     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 810     (@c_cols)
 811   ) {
 812     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 813       $constraint_name,
 814       join (', ', map { "'$_'" } @missing),
 815     ) );
 816   }
 817
 818   if (
 819     !$croak_on_null
 820       and
 821     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 822       and
 823     my @undefs = grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 824   ) {
 825     carp_unique ( sprintf (
 826       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 827     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 828     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 829       $constraint_name,
 830       join (', ', map { "'$_'" } @undefs),
 831     ));
 832   }
 833
 834   return $final_cond;
 835 }
 836
 837 =head2 search_related
 838
 839 =over 4
 840
 841 =item Arguments: $rel, $cond, \%attrs?
 842
 843 =item Return Value: $new_resultset (scalar context) || @row_objs (list context)
 844
 845 =back
 846
 847   $new_rs = $cd_rs->search_related('artist', {
 848     name => 'Emo-R-Us',
 849   });
 850
 851 Searches the specified relationship, optionally specifying a condition and
 852 attributes for matching records. See L</ATTRIBUTES> for more information.
 853
 854 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 855 returning a list of row objects instead. To avoid that, use L</search_related_rs>.
 856
 857 See also L</search_related_rs>.
 858
 859 =cut
 860
 861 sub search_related {
 862   return shift->related_resultset(shift)->search(@_);
 863 }
 864
 865 =head2 search_related_rs
 866
 867 This method works exactly the same as search_related, except that
 868 it guarantees a resultset, even in list context.
 869
 870 =cut
 871
 872 sub search_related_rs {
 873   return shift->related_resultset(shift)->search_rs(@_);
 874 }
 875
 876 =head2 cursor
 877
 878 =over 4
 879
 880 =item Arguments: none
 881
 882 =item Return Value: $cursor
 883
 884 =back
 885
 886 Returns a storage-driven cursor to the given resultset. See
 887 L<DBIx::Class::Cursor> for more information.
 888
 889 =cut
 890
 891 sub cursor {
 892   my ($self) = @_;
 893
 894   my $attrs = $self->_resolved_attrs_copy;
 895
 896   return $self->{cursor}
 897     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 898           $attrs->{where},$attrs);
 899 }
 900
 901 =head2 single
 902
 903 =over 4
 904
 905 =item Arguments: $cond?
 906
 907 =item Return Value: $row_object | undef
 908
 909 =back
 910
 911   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 912
 913 Inflates the first result without creating a cursor if the resultset has
 914 any records in it; if not returns C<undef>. Used by L</find> as a lean version
 915 of L</search>.
 916
 917 While this method can take an optional search condition (just like L</search>)
 918 being a fast-code-path it does not recognize search attributes. If you need to
 919 add extra joins or similar, call L</search> and then chain-call L</single> on the
 920 L<DBIx::Class::ResultSet> returned.
 921
 922 =over
 923
 924 =item B<Note>
 925
 926 As of 0.08100, this method enforces the assumption that the preceding
 927 query returns only one row. If more than one row is returned, you will receive
 928 a warning:
 929
 930   Query returned more than one row
 931
 932 In this case, you should be using L</next> or L</find> instead, or if you really
 933 know what you are doing, use the L</rows> attribute to explicitly limit the size
 934 of the resultset.
 935
 936 This method will also throw an exception if it is called on a resultset prefetching
 937 has_many, as such a prefetch implies fetching multiple rows from the database in
 938 order to assemble the resulting object.
 939
 940 =back
 941
 942 =cut
 943
 944 sub single {
 945   my ($self, $where) = @_;
 946   if(@_ > 2) {
 947       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 948   }
 949
 950   my $attrs = $self->_resolved_attrs_copy;
 951
 952   if (keys %{$attrs->{collapse}}) {
 953     $self->throw_exception(
 954       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 955     );
 956   }
 957
 958   if ($where) {
 959     if (defined $attrs->{where}) {
 960       $attrs->{where} = {
 961         '-and' =>
 962             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 963                $where, delete $attrs->{where} ]
 964       };
 965     } else {
 966       $attrs->{where} = $where;
 967     }
 968   }
 969
 970   my @data = $self->result_source->storage->select_single(
 971     $attrs->{from}, $attrs->{select},
 972     $attrs->{where}, $attrs
 973   );
 974
 975   return (@data ? ($self->_construct_object(@data))[0] : undef);
 976 }
 977
 978
 979 # _collapse_query
 980 #
 981 # Recursively collapse the query, accumulating values for each column.
 982
 983 sub _collapse_query {
 984   my ($self, $query, $collapsed) = @_;
 985
 986   $collapsed ||= {};
 987
 988   if (ref $query eq 'ARRAY') {
 989     foreach my $subquery (@$query) {
 990       next unless ref $subquery;  # -or
 991       $collapsed = $self->_collapse_query($subquery, $collapsed);
 992     }
 993   }
 994   elsif (ref $query eq 'HASH') {
 995     if (keys %$query and (keys %$query)[0] eq '-and') {
 996       foreach my $subquery (@{$query->{-and}}) {
 997         $collapsed = $self->_collapse_query($subquery, $collapsed);
 998       }
 999     }
1000     else {
1001       foreach my $col (keys %$query) {
1002         my $value = $query->{$col};
1003         $collapsed->{$col}{$value}++;
1004       }
1005     }
1006   }
1007
1008   return $collapsed;
1009 }
1010
1011 =head2 get_column
1012
1013 =over 4
1014
1015 =item Arguments: $cond?
1016
1017 =item Return Value: $resultsetcolumn
1018
1019 =back
1020
1021   my $max_length = $rs->get_column('length')->max;
1022
1023 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1024
1025 =cut
1026
1027 sub get_column {
1028   my ($self, $column) = @_;
1029   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1030   return $new;
1031 }
1032
1033 =head2 search_like
1034
1035 =over 4
1036
1037 =item Arguments: $cond, \%attrs?
1038
1039 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1040
1041 =back
1042
1043   # WHERE title LIKE '%blue%'
1044   $cd_rs = $rs->search_like({ title => '%blue%'});
1045
1046 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1047 that this is simply a convenience method retained for ex Class::DBI users.
1048 You most likely want to use L</search> with specific operators.
1049
1050 For more information, see L<DBIx::Class::Manual::Cookbook>.
1051
1052 This method is deprecated and will be removed in 0.09. Use L</search()>
1053 instead. An example conversion is:
1054
1055   ->search_like({ foo => 'bar' });
1056
1057   # Becomes
1058
1059   ->search({ foo => { like => 'bar' } });
1060
1061 =cut
1062
1063 sub search_like {
1064   my $class = shift;
1065   carp_unique (
1066     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1067    .' Instead use ->search({ x => { -like => "y%" } })'
1068    .' (note the outer pair of {}s - they are important!)'
1069   );
1070   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1071   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1072   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1073   return $class->search($query, { %$attrs });
1074 }
1075
1076 =head2 slice
1077
1078 =over 4
1079
1080 =item Arguments: $first, $last
1081
1082 =item Return Value: $resultset (scalar context) || @row_objs (list context)
1083
1084 =back
1085
1086 Returns a resultset or object list representing a subset of elements from the
1087 resultset slice is called on. Indexes are from 0, i.e., to get the first
1088 three records, call:
1089
1090   my ($one, $two, $three) = $rs->slice(0, 2);
1091
1092 =cut
1093
1094 sub slice {
1095   my ($self, $min, $max) = @_;
1096   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1097   $attrs->{offset} = $self->{attrs}{offset} || 0;
1098   $attrs->{offset} += $min;
1099   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1100   return $self->search(undef, $attrs);
1101   #my $slice = (ref $self)->new($self->result_source, $attrs);
1102   #return (wantarray ? $slice->all : $slice);
1103 }
1104
1105 =head2 next
1106
1107 =over 4
1108
1109 =item Arguments: none
1110
1111 =item Return Value: $result | undef
1112
1113 =back
1114
1115 Returns the next element in the resultset (C<undef> is there is none).
1116
1117 Can be used to efficiently iterate over records in the resultset:
1118
1119   my $rs = $schema->resultset('CD')->search;
1120   while (my $cd = $rs->next) {
1121     print $cd->title;
1122   }
1123
1124 Note that you need to store the resultset object, and call C<next> on it.
1125 Calling C<< resultset('Table')->next >> repeatedly will always return the
1126 first record from the resultset.
1127
1128 =cut
1129
1130 sub next {
1131   my ($self) = @_;
1132   if (my $cache = $self->get_cache) {
1133     $self->{all_cache_position} ||= 0;
1134     return $cache->[$self->{all_cache_position}++];
1135   }
1136   if ($self->{attrs}{cache}) {
1137     delete $self->{pager};
1138     $self->{all_cache_position} = 1;
1139     return ($self->all)[0];
1140   }
1141   if ($self->{stashed_objects}) {
1142     my $obj = shift(@{$self->{stashed_objects}});
1143     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
1144     return $obj;
1145   }
1146   my @row = (
1147     exists $self->{stashed_row}
1148       ? @{delete $self->{stashed_row}}
1149       : $self->cursor->next
1150   );
1151   return undef unless (@row);
1152   my ($row, @more) = $self->_construct_object(@row);
1153   $self->{stashed_objects} = \@more if @more;
1154   return $row;
1155 }
1156
1157 sub _construct_object {
1158   my ($self, @row) = @_;
1159
1160   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
1161     or return ();
1162   my @new = $self->result_class->inflate_result($self->result_source, @$info);
1163   @new = $self->{_attrs}{record_filter}->(@new)
1164     if exists $self->{_attrs}{record_filter};
1165   return @new;
1166 }
1167
1168 sub _collapse_result {
1169   my ($self, $as_proto, $row) = @_;
1170
1171   my @copy = @$row;
1172
1173   # 'foo'         => [ undef, 'foo' ]
1174   # 'foo.bar'     => [ 'foo', 'bar' ]
1175   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
1176
1177   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
1178
1179   my %collapse = %{$self->{_attrs}{collapse}||{}};
1180
1181   my @pri_index;
1182
1183   # if we're doing collapsing (has_many prefetch) we need to grab records
1184   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1185   # we know we don't have to bother.
1186
1187   # the reason for not using the collapse stuff directly is because if you
1188   # had for e.g. two artists in a row with no cds, the collapse info for
1189   # both would be NULL (undef) so you'd lose the second artist
1190
1191   # store just the index so we can check the array positions from the row
1192   # without having to contruct the full hash
1193
1194   if (keys %collapse) {
1195     my %pri = map { ($_ => 1) } $self->result_source->_pri_cols;
1196     foreach my $i (0 .. $#construct_as) {
1197       next if defined($construct_as[$i][0]); # only self table
1198       if (delete $pri{$construct_as[$i][1]}) {
1199         push(@pri_index, $i);
1200       }
1201       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1202     }
1203   }
1204
1205   # no need to do an if, it'll be empty if @pri_index is empty anyway
1206
1207   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1208
1209   my @const_rows;
1210
1211   do { # no need to check anything at the front, we always want the first row
1212
1213     my %const;
1214
1215     foreach my $this_as (@construct_as) {
1216       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1217     }
1218
1219     push(@const_rows, \%const);
1220
1221   } until ( # no pri_index => no collapse => drop straight out
1222       !@pri_index
1223     or
1224       do { # get another row, stash it, drop out if different PK
1225
1226         @copy = $self->cursor->next;
1227         $self->{stashed_row} = \@copy;
1228
1229         # last thing in do block, counts as true if anything doesn't match
1230
1231         # check xor defined first for NULL vs. NOT NULL then if one is
1232         # defined the other must be so check string equality
1233
1234         grep {
1235           (defined $pri_vals{$_} ^ defined $copy[$_])
1236           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1237         } @pri_index;
1238       }
1239   );
1240
1241   my $alias = $self->{attrs}{alias};
1242   my $info = [];
1243
1244   my %collapse_pos;
1245
1246   my @const_keys;
1247
1248   foreach my $const (@const_rows) {
1249     scalar @const_keys or do {
1250       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1251     };
1252     foreach my $key (@const_keys) {
1253       if (length $key) {
1254         my $target = $info;
1255         my @parts = split(/\./, $key);
1256         my $cur = '';
1257         my $data = $const->{$key};
1258         foreach my $p (@parts) {
1259           $target = $target->[1]->{$p} ||= [];
1260           $cur .= ".${p}";
1261           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1262             # collapsing at this point and on final part
1263             my $pos = $collapse_pos{$cur};
1264             CK: foreach my $ck (@ckey) {
1265               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1266                 $collapse_pos{$cur} = $data;
1267                 delete @collapse_pos{ # clear all positioning for sub-entries
1268                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1269                 };
1270                 push(@$target, []);
1271                 last CK;
1272               }
1273             }
1274           }
1275           if (exists $collapse{$cur}) {
1276             $target = $target->[-1];
1277           }
1278         }
1279         $target->[0] = $data;
1280       } else {
1281         $info->[0] = $const->{$key};
1282       }
1283     }
1284   }
1285
1286   return $info;
1287 }
1288
1289 =head2 result_source
1290
1291 =over 4
1292
1293 =item Arguments: $result_source?
1294
1295 =item Return Value: $result_source
1296
1297 =back
1298
1299 An accessor for the primary ResultSource object from which this ResultSet
1300 is derived.
1301
1302 =head2 result_class
1303
1304 =over 4
1305
1306 =item Arguments: $result_class?
1307
1308 =item Return Value: $result_class
1309
1310 =back
1311
1312 An accessor for the class to use when creating row objects. Defaults to
1313 C<< result_source->result_class >> - which in most cases is the name of the
1314 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1315
1316 Note that changing the result_class will also remove any components
1317 that were originally loaded in the source class via
1318 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1319 in the original source class will not run.
1320
1321 =cut
1322
1323 sub result_class {
1324   my ($self, $result_class) = @_;
1325   if ($result_class) {
1326     unless (ref $result_class) { # don't fire this for an object
1327       $self->ensure_class_loaded($result_class);
1328     }
1329     $self->_result_class($result_class);
1330     # THIS LINE WOULD BE A BUG - this accessor specifically exists to
1331     # permit the user to set result class on one result set only; it only
1332     # chains if provided to search()
1333     #$self->{attrs}{result_class} = $result_class if ref $self;
1334   }
1335   $self->_result_class;
1336 }
1337
1338 =head2 count
1339
1340 =over 4
1341
1342 =item Arguments: $cond, \%attrs??
1343
1344 =item Return Value: $count
1345
1346 =back
1347
1348 Performs an SQL C<COUNT> with the same query as the resultset was built
1349 with to find the number of elements. Passing arguments is equivalent to
1350 C<< $rs->search ($cond, \%attrs)->count >>
1351
1352 =cut
1353
1354 sub count {
1355   my $self = shift;
1356   return $self->search(@_)->count if @_ and defined $_[0];
1357   return scalar @{ $self->get_cache } if $self->get_cache;
1358
1359   my $attrs = $self->_resolved_attrs_copy;
1360
1361   # this is a little optimization - it is faster to do the limit
1362   # adjustments in software, instead of a subquery
1363   my $rows = delete $attrs->{rows};
1364   my $offset = delete $attrs->{offset};
1365
1366   my $crs;
1367   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1368     $crs = $self->_count_subq_rs ($attrs);
1369   }
1370   else {
1371     $crs = $self->_count_rs ($attrs);
1372   }
1373   my $count = $crs->next;
1374
1375   $count -= $offset if $offset;
1376   $count = $rows if $rows and $rows < $count;
1377   $count = 0 if ($count < 0);
1378
1379   return $count;
1380 }
1381
1382 =head2 count_rs
1383
1384 =over 4
1385
1386 =item Arguments: $cond, \%attrs??
1387
1388 =item Return Value: $count_rs
1389
1390 =back
1391
1392 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1393 This can be very handy for subqueries:
1394
1395   ->search( { amount => $some_rs->count_rs->as_query } )
1396
1397 As with regular resultsets the SQL query will be executed only after
1398 the resultset is accessed via L</next> or L</all>. That would return
1399 the same single value obtainable via L</count>.
1400
1401 =cut
1402
1403 sub count_rs {
1404   my $self = shift;
1405   return $self->search(@_)->count_rs if @_;
1406
1407   # this may look like a lack of abstraction (count() does about the same)
1408   # but in fact an _rs *must* use a subquery for the limits, as the
1409   # software based limiting can not be ported if this $rs is to be used
1410   # in a subquery itself (i.e. ->as_query)
1411   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1412     return $self->_count_subq_rs;
1413   }
1414   else {
1415     return $self->_count_rs;
1416   }
1417 }
1418
1419 #
1420 # returns a ResultSetColumn object tied to the count query
1421 #
1422 sub _count_rs {
1423   my ($self, $attrs) = @_;
1424
1425   my $rsrc = $self->result_source;
1426   $attrs ||= $self->_resolved_attrs;
1427
1428   my $tmp_attrs = { %$attrs };
1429   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1430   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1431
1432   # overwrite the selector (supplied by the storage)
1433   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $attrs);
1434   $tmp_attrs->{as} = 'count';
1435   delete @{$tmp_attrs}{qw/columns _trailing_select/};
1436
1437   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1438
1439   return $tmp_rs;
1440 }
1441
1442 #
1443 # same as above but uses a subquery
1444 #
1445 sub _count_subq_rs {
1446   my ($self, $attrs) = @_;
1447
1448   my $rsrc = $self->result_source;
1449   $attrs ||= $self->_resolved_attrs;
1450
1451   my $sub_attrs = { %$attrs };
1452   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1453   delete @{$sub_attrs}{qw/collapse columns as select _prefetch_selector_range _trailing_select order_by for/};
1454
1455   # if we multi-prefetch we group_by primary keys only as this is what we would
1456   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1457   if ( keys %{$attrs->{collapse}}  ) {
1458     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->_pri_cols) ]
1459   }
1460
1461   # Calculate subquery selector
1462   if (my $g = $sub_attrs->{group_by}) {
1463
1464     my $sql_maker = $rsrc->storage->sql_maker;
1465
1466     # necessary as the group_by may refer to aliased functions
1467     my $sel_index;
1468     for my $sel (@{$attrs->{select}}) {
1469       $sel_index->{$sel->{-as}} = $sel
1470         if (ref $sel eq 'HASH' and $sel->{-as});
1471     }
1472
1473     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1474     # also look for named aggregates referred in the having clause
1475     # having often contains scalarrefs - thus parse it out entirely
1476     my @parts = @$g;
1477     if ($attrs->{having}) {
1478       local $sql_maker->{having_bind};
1479       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1480       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1481       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1482         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1483         # if we don't unset it we screw up retarded but unfortunately working
1484         # 'MAX(foo.bar)' => { '>', 3 }
1485         $sql_maker->{name_sep} = '';
1486       }
1487
1488       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1489
1490       my $sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1491
1492       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1493       # and if all fails for an utterly naive quoted scalar-with-function
1494       while ($sql =~ /
1495         $rquote $sep $lquote (.+?) $rquote
1496           |
1497         [\s,] \w+ \. (\w+) [\s,]
1498           |
1499         [\s,] $lquote (.+?) $rquote [\s,]
1500       /gx) {
1501         push @parts, ($1 || $2 || $3);  # one of them matched if we got here
1502       }
1503     }
1504
1505     for (@parts) {
1506       my $colpiece = $sel_index->{$_} || $_;
1507
1508       # unqualify join-based group_by's. Arcane but possible query
1509       # also horrible horrible hack to alias a column (not a func.)
1510       # (probably need to introduce SQLA syntax)
1511       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1512         my $as = $colpiece;
1513         $as =~ s/\./__/;
1514         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1515       }
1516       push @{$sub_attrs->{select}}, $colpiece;
1517     }
1518   }
1519   else {
1520     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1521     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1522   }
1523
1524   return $rsrc->resultset_class
1525                ->new ($rsrc, $sub_attrs)
1526                 ->as_subselect_rs
1527                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1528                   ->get_column ('count');
1529 }
1530
1531 sub _bool {
1532   return 1;
1533 }
1534
1535 =head2 count_literal
1536
1537 =over 4
1538
1539 =item Arguments: $sql_fragment, @bind_values
1540
1541 =item Return Value: $count
1542
1543 =back
1544
1545 Counts the results in a literal query. Equivalent to calling L</search_literal>
1546 with the passed arguments, then L</count>.
1547
1548 =cut
1549
1550 sub count_literal { shift->search_literal(@_)->count; }
1551
1552 =head2 all
1553
1554 =over 4
1555
1556 =item Arguments: none
1557
1558 =item Return Value: @objects
1559
1560 =back
1561
1562 Returns all elements in the resultset.
1563
1564 =cut
1565
1566 sub all {
1567   my $self = shift;
1568   if(@_) {
1569       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1570   }
1571
1572   return @{ $self->get_cache } if $self->get_cache;
1573
1574   my @obj;
1575
1576   if (keys %{$self->_resolved_attrs->{collapse}}) {
1577     # Using $self->cursor->all is really just an optimisation.
1578     # If we're collapsing has_many prefetches it probably makes
1579     # very little difference, and this is cleaner than hacking
1580     # _construct_object to survive the approach
1581     $self->cursor->reset;
1582     my @row = $self->cursor->next;
1583     while (@row) {
1584       push(@obj, $self->_construct_object(@row));
1585       @row = (exists $self->{stashed_row}
1586                ? @{delete $self->{stashed_row}}
1587                : $self->cursor->next);
1588     }
1589   } else {
1590     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1591   }
1592
1593   $self->set_cache(\@obj) if $self->{attrs}{cache};
1594
1595   return @obj;
1596 }
1597
1598 =head2 reset
1599
1600 =over 4
1601
1602 =item Arguments: none
1603
1604 =item Return Value: $self
1605
1606 =back
1607
1608 Resets the resultset's cursor, so you can iterate through the elements again.
1609 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1610 another query.
1611
1612 =cut
1613
1614 sub reset {
1615   my ($self) = @_;
1616   delete $self->{_attrs} if exists $self->{_attrs};
1617   $self->{all_cache_position} = 0;
1618   $self->cursor->reset;
1619   return $self;
1620 }
1621
1622 =head2 first
1623
1624 =over 4
1625
1626 =item Arguments: none
1627
1628 =item Return Value: $object | undef
1629
1630 =back
1631
1632 Resets the resultset and returns an object for the first result (or C<undef>
1633 if the resultset is empty).
1634
1635 =cut
1636
1637 sub first {
1638   return $_[0]->reset->next;
1639 }
1640
1641
1642 # _rs_update_delete
1643 #
1644 # Determines whether and what type of subquery is required for the $rs operation.
1645 # If grouping is necessary either supplies its own, or verifies the current one
1646 # After all is done delegates to the proper storage method.
1647
1648 sub _rs_update_delete {
1649   my ($self, $op, $values) = @_;
1650
1651   my $rsrc = $self->result_source;
1652
1653   # if a condition exists we need to strip all table qualifiers
1654   # if this is not possible we'll force a subquery below
1655   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1656
1657   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1658   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/rows offset/);
1659
1660   if ($needs_group_by_subq or $needs_subq) {
1661
1662     # make a new $rs selecting only the PKs (that's all we really need)
1663     my $attrs = $self->_resolved_attrs_copy;
1664
1665
1666     delete $attrs->{$_} for qw/collapse _collapse_order_by select _prefetch_selector_range as/;
1667     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->_pri_cols) ];
1668
1669     if ($needs_group_by_subq) {
1670       # make sure no group_by was supplied, or if there is one - make sure it matches
1671       # the columns compiled above perfectly. Anything else can not be sanely executed
1672       # on most databases so croak right then and there
1673
1674       if (my $g = $attrs->{group_by}) {
1675         my @current_group_by = map
1676           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1677           @$g
1678         ;
1679
1680         if (
1681           join ("\x00", sort @current_group_by)
1682             ne
1683           join ("\x00", sort @{$attrs->{columns}} )
1684         ) {
1685           $self->throw_exception (
1686             "You have just attempted a $op operation on a resultset which does group_by"
1687             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1688             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1689             . ' kind of queries. Please retry the operation with a modified group_by or'
1690             . ' without using one at all.'
1691           );
1692         }
1693       }
1694       else {
1695         $attrs->{group_by} = $attrs->{columns};
1696       }
1697     }
1698
1699     my $subrs = (ref $self)->new($rsrc, $attrs);
1700     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1701   }
1702   else {
1703     return $rsrc->storage->$op(
1704       $rsrc,
1705       $op eq 'update' ? $values : (),
1706       $cond,
1707     );
1708   }
1709 }
1710
1711 =head2 update
1712
1713 =over 4
1714
1715 =item Arguments: \%values
1716
1717 =item Return Value: $storage_rv
1718
1719 =back
1720
1721 Sets the specified columns in the resultset to the supplied values in a
1722 single query. Note that this will not run any accessor/set_column/update
1723 triggers, nor will it update any row object instances derived from this
1724 resultset (this includes the contents of the L<resultset cache|/set_cache>
1725 if any). See L</update_all> if you need to execute any on-update
1726 triggers or cascades defined either by you or a
1727 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1728
1729 The return value is a pass through of what the underlying
1730 storage backend returned, and may vary. See L<DBI/execute> for the most
1731 common case.
1732
1733 =head3 CAVEAT
1734
1735 Note that L</update> does not process/deflate any of the values passed in.
1736 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
1737 ensure manually that any value passed to this method will stringify to
1738 something the RDBMS knows how to deal with. A notable example is the
1739 handling of L<DateTime> objects, for more info see:
1740 L<DBIx::Class::Manual::Cookbook/Formatting_DateTime_objects_in_queries>.
1741
1742 =cut
1743
1744 sub update {
1745   my ($self, $values) = @_;
1746   $self->throw_exception('Values for update must be a hash')
1747     unless ref $values eq 'HASH';
1748
1749   return $self->_rs_update_delete ('update', $values);
1750 }
1751
1752 =head2 update_all
1753
1754 =over 4
1755
1756 =item Arguments: \%values
1757
1758 =item Return Value: 1
1759
1760 =back
1761
1762 Fetches all objects and updates them one at a time via
1763 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
1764 triggers, while L</update> will not.
1765
1766 =cut
1767
1768 sub update_all {
1769   my ($self, $values) = @_;
1770   $self->throw_exception('Values for update_all must be a hash')
1771     unless ref $values eq 'HASH';
1772
1773   my $guard = $self->result_source->schema->txn_scope_guard;
1774   $_->update($values) for $self->all;
1775   $guard->commit;
1776   return 1;
1777 }
1778
1779 =head2 delete
1780
1781 =over 4
1782
1783 =item Arguments: none
1784
1785 =item Return Value: $storage_rv
1786
1787 =back
1788
1789 Deletes the rows matching this resultset in a single query. Note that this
1790 will not run any delete triggers, nor will it alter the
1791 L<in_storage|DBIx::Class::Row/in_storage> status of any row object instances
1792 derived from this resultset (this includes the contents of the
1793 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
1794 execute any on-delete triggers or cascades defined either by you or a
1795 L<result component|DBIx::Class::Manual::Component/WHAT_IS_A_COMPONENT>.
1796
1797 The return value is a pass through of what the underlying storage backend
1798 returned, and may vary. See L<DBI/execute> for the most common case.
1799
1800 =cut
1801
1802 sub delete {
1803   my $self = shift;
1804   $self->throw_exception('delete does not accept any arguments')
1805     if @_;
1806
1807   return $self->_rs_update_delete ('delete');
1808 }
1809
1810 =head2 delete_all
1811
1812 =over 4
1813
1814 =item Arguments: none
1815
1816 =item Return Value: 1
1817
1818 =back
1819
1820 Fetches all objects and deletes them one at a time via
1821 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
1822 triggers, while L</delete> will not.
1823
1824 =cut
1825
1826 sub delete_all {
1827   my $self = shift;
1828   $self->throw_exception('delete_all does not accept any arguments')
1829     if @_;
1830
1831   my $guard = $self->result_source->schema->txn_scope_guard;
1832   $_->delete for $self->all;
1833   $guard->commit;
1834   return 1;
1835 }
1836
1837 =head2 populate
1838
1839 =over 4
1840
1841 =item Arguments: \@data;
1842
1843 =back
1844
1845 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1846 For the arrayref of hashrefs style each hashref should be a structure suitable
1847 for submitting to a $resultset->create(...) method.
1848
1849 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1850 to insert the data, as this is a faster method.
1851
1852 Otherwise, each set of data is inserted into the database using
1853 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1854 accumulated into an array. The array itself, or an array reference
1855 is returned depending on scalar or list context.
1856
1857 Example:  Assuming an Artist Class that has many CDs Classes relating:
1858
1859   my $Artist_rs = $schema->resultset("Artist");
1860
1861   ## Void Context Example
1862   $Artist_rs->populate([
1863      { artistid => 4, name => 'Manufactured Crap', cds => [
1864         { title => 'My First CD', year => 2006 },
1865         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1866       ],
1867      },
1868      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1869         { title => 'My parents sold me to a record company', year => 2005 },
1870         { title => 'Why Am I So Ugly?', year => 2006 },
1871         { title => 'I Got Surgery and am now Popular', year => 2007 }
1872       ],
1873      },
1874   ]);
1875
1876   ## Array Context Example
1877   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1878     { name => "Artist One"},
1879     { name => "Artist Two"},
1880     { name => "Artist Three", cds=> [
1881     { title => "First CD", year => 2007},
1882     { title => "Second CD", year => 2008},
1883   ]}
1884   ]);
1885
1886   print $ArtistOne->name; ## response is 'Artist One'
1887   print $ArtistThree->cds->count ## reponse is '2'
1888
1889 For the arrayref of arrayrefs style,  the first element should be a list of the
1890 fieldsnames to which the remaining elements are rows being inserted.  For
1891 example:
1892
1893   $Arstist_rs->populate([
1894     [qw/artistid name/],
1895     [100, 'A Formally Unknown Singer'],
1896     [101, 'A singer that jumped the shark two albums ago'],
1897     [102, 'An actually cool singer'],
1898   ]);
1899
1900 Please note an important effect on your data when choosing between void and
1901 wantarray context. Since void context goes straight to C<insert_bulk> in
1902 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1903 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1904 create primary keys for you, you will find that your PKs are empty.  In this
1905 case you will have to use the wantarray context in order to create those
1906 values.
1907
1908 =cut
1909
1910 sub populate {
1911   my $self = shift;
1912
1913   # cruft placed in standalone method
1914   my $data = $self->_normalize_populate_args(@_);
1915
1916   if(defined wantarray) {
1917     my @created;
1918     foreach my $item (@$data) {
1919       push(@created, $self->create($item));
1920     }
1921     return wantarray ? @created : \@created;
1922   }
1923   else {
1924     my $first = $data->[0];
1925
1926     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1927     # it relationship data
1928     my (@rels, @columns);
1929     my $rsrc = $self->result_source;
1930     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
1931     for (keys %$first) {
1932       my $ref = ref $first->{$_};
1933       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
1934         ? push @rels, $_
1935         : push @columns, $_
1936       ;
1937     }
1938
1939     my @pks = $rsrc->primary_columns;
1940
1941     ## do the belongs_to relationships
1942     foreach my $index (0..$#$data) {
1943
1944       # delegate to create() for any dataset without primary keys with specified relationships
1945       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1946         for my $r (@rels) {
1947           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1948             my @ret = $self->populate($data);
1949             return;
1950           }
1951         }
1952       }
1953
1954       foreach my $rel (@rels) {
1955         next unless ref $data->[$index]->{$rel} eq "HASH";
1956         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1957         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
1958         my $related = $result->result_source->_resolve_condition(
1959           $reverse_relinfo->{cond},
1960           $self,
1961           $result,
1962           $rel,
1963         );
1964
1965         delete $data->[$index]->{$rel};
1966         $data->[$index] = {%{$data->[$index]}, %$related};
1967
1968         push @columns, keys %$related if $index == 0;
1969       }
1970     }
1971
1972     ## inherit the data locked in the conditions of the resultset
1973     my ($rs_data) = $self->_merge_with_rscond({});
1974     delete @{$rs_data}{@columns};
1975     my @inherit_cols = keys %$rs_data;
1976     my @inherit_data = values %$rs_data;
1977
1978     ## do bulk insert on current row
1979     $rsrc->storage->insert_bulk(
1980       $rsrc,
1981       [@columns, @inherit_cols],
1982       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1983     );
1984
1985     ## do the has_many relationships
1986     foreach my $item (@$data) {
1987
1988       my $main_row;
1989
1990       foreach my $rel (@rels) {
1991         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
1992
1993         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
1994
1995         my $child = $main_row->$rel;
1996
1997         my $related = $child->result_source->_resolve_condition(
1998           $rels->{$rel}{cond},
1999           $child,
2000           $main_row,
2001           $rel,
2002         );
2003
2004         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2005         my @populate = map { {%$_, %$related} } @rows_to_add;
2006
2007         $child->populate( \@populate );
2008       }
2009     }
2010   }
2011 }
2012
2013
2014 # populate() argumnets went over several incarnations
2015 # What we ultimately support is AoH
2016 sub _normalize_populate_args {
2017   my ($self, $arg) = @_;
2018
2019   if (ref $arg eq 'ARRAY') {
2020     if (ref $arg->[0] eq 'HASH') {
2021       return $arg;
2022     }
2023     elsif (ref $arg->[0] eq 'ARRAY') {
2024       my @ret;
2025       my @colnames = @{$arg->[0]};
2026       foreach my $values (@{$arg}[1 .. $#$arg]) {
2027         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2028       }
2029       return \@ret;
2030     }
2031   }
2032
2033   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2034 }
2035
2036 =head2 pager
2037
2038 =over 4
2039
2040 =item Arguments: none
2041
2042 =item Return Value: $pager
2043
2044 =back
2045
2046 Return Value a L<Data::Page> object for the current resultset. Only makes
2047 sense for queries with a C<page> attribute.
2048
2049 To get the full count of entries for a paged resultset, call
2050 C<total_entries> on the L<Data::Page> object.
2051
2052 =cut
2053
2054 # make a wizard good for both a scalar and a hashref
2055 my $mk_lazy_count_wizard = sub {
2056   require Variable::Magic;
2057
2058   my $stash = { total_rs => shift };
2059   my $slot = shift; # only used by the hashref magic
2060
2061   my $magic = Variable::Magic::wizard (
2062     data => sub { $stash },
2063
2064     (!$slot)
2065     ? (
2066       # the scalar magic
2067       get => sub {
2068         # set value lazily, and dispell for good
2069         ${$_[0]} = $_[1]{total_rs}->count;
2070         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref});
2071         return 1;
2072       },
2073       set => sub {
2074         # an explicit set implies dispell as well
2075         # the unless() is to work around "fun and giggles" below
2076         Variable::Magic::dispell (${$_[0]}, $_[1]{magic_selfref})
2077           unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2078         return 1;
2079       },
2080     )
2081     : (
2082       # the uvar magic
2083       fetch => sub {
2084         if ($_[2] eq $slot and !$_[1]{inactive}) {
2085           my $cnt = $_[1]{total_rs}->count;
2086           $_[0]->{$slot} = $cnt;
2087
2088           # attempting to dispell in a fetch handle (works in store), seems
2089           # to invariable segfault on 5.10, 5.12, 5.13 :(
2090           # so use an inactivator instead
2091           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2092           $_[1]{inactive}++;
2093         }
2094         return 1;
2095       },
2096       store => sub {
2097         if (! $_[1]{inactive} and $_[2] eq $slot) {
2098           #Variable::Magic::dispell (%{$_[0]}, $_[1]{magic_selfref});
2099           $_[1]{inactive}++
2100             unless (caller(2))[3] eq 'DBIx::Class::ResultSet::pager';
2101         }
2102         return 1;
2103       },
2104     ),
2105   );
2106
2107   $stash->{magic_selfref} = $magic;
2108   weaken ($stash->{magic_selfref}); # this fails on 5.8.1
2109
2110   return $magic;
2111 };
2112
2113 # the tie class for 5.8.1
2114 {
2115   package # hide from pause
2116     DBIx::Class::__DBIC_LAZY_RS_COUNT__;
2117   use base qw/Tie::Hash/;
2118
2119   sub FIRSTKEY { my $dummy = scalar keys %{$_[0]{data}}; each %{$_[0]{data}} }
2120   sub NEXTKEY  { each %{$_[0]{data}} }
2121   sub EXISTS   { exists $_[0]{data}{$_[1]} }
2122   sub DELETE   { delete $_[0]{data}{$_[1]} }
2123   sub CLEAR    { %{$_[0]{data}} = () }
2124   sub SCALAR   { scalar %{$_[0]{data}} }
2125
2126   sub TIEHASH {
2127     $_[1]{data} = {%{$_[1]{selfref}}};
2128     %{$_[1]{selfref}} = ();
2129     Scalar::Util::weaken ($_[1]{selfref});
2130     return bless ($_[1], $_[0]);
2131   };
2132
2133   sub FETCH {
2134     if ($_[1] eq $_[0]{slot}) {
2135       my $cnt = $_[0]{data}{$_[1]} = $_[0]{total_rs}->count;
2136       untie %{$_[0]{selfref}};
2137       %{$_[0]{selfref}} = %{$_[0]{data}};
2138       return $cnt;
2139     }
2140     else {
2141       $_[0]{data}{$_[1]};
2142     }
2143   }
2144
2145   sub STORE {
2146     $_[0]{data}{$_[1]} = $_[2];
2147     if ($_[1] eq $_[0]{slot}) {
2148       untie %{$_[0]{selfref}};
2149       %{$_[0]{selfref}} = %{$_[0]{data}};
2150     }
2151     $_[2];
2152   }
2153 }
2154
2155 sub pager {
2156   my ($self) = @_;
2157
2158   return $self->{pager} if $self->{pager};
2159
2160   if ($self->get_cache) {
2161     $self->throw_exception ('Pagers on cached resultsets are not supported');
2162   }
2163
2164   my $attrs = $self->{attrs};
2165   if (!defined $attrs->{page}) {
2166     $self->throw_exception("Can't create pager for non-paged rs");
2167   }
2168   elsif ($attrs->{page} <= 0) {
2169     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2170   }
2171   $attrs->{rows} ||= 10;
2172
2173   # throw away the paging flags and re-run the count (possibly
2174   # with a subselect) to get the real total count
2175   my $count_attrs = { %$attrs };
2176   delete $count_attrs->{$_} for qw/rows offset page pager/;
2177   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2178
2179
2180 ### the following may seem awkward and dirty, but it's a thought-experiment
2181 ### necessary for future development of DBIx::DS. Do *NOT* change this code
2182 ### before talking to ribasushi/mst
2183
2184   require Data::Page;
2185   my $pager = Data::Page->new(
2186     0,  #start with an empty set
2187     $attrs->{rows},
2188     $self->{attrs}{page},
2189   );
2190
2191   my $data_slot = 'total_entries';
2192
2193   # Since we are interested in a cached value (once it's set - it's set), every
2194   # technique will detach from the magic-host once the time comes to fire the
2195   # ->count (or in the segfaulting case of >= 5.10 it will deactivate itself)
2196
2197   if ($] < 5.008003) {
2198     # 5.8.1 throws 'Modification of a read-only value attempted' when one tries
2199     # to weakref the magic container :(
2200     # tested on 5.8.1
2201     tie (%$pager, 'DBIx::Class::__DBIC_LAZY_RS_COUNT__',
2202       { slot => $data_slot, total_rs => $total_rs, selfref => $pager }
2203     );
2204   }
2205   elsif ($] < 5.010) {
2206     # We can use magic on the hash value slot. It's interesting that the magic is
2207     # attached to the hash-slot, and does *not* stop working once I do the dummy
2208     # assignments after the cast()
2209     # tested on 5.8.3 and 5.8.9
2210     my $magic = $mk_lazy_count_wizard->($total_rs);
2211     Variable::Magic::cast ( $pager->{$data_slot}, $magic );
2212
2213     # this is for fun and giggles
2214     $pager->{$data_slot} = -1;
2215     $pager->{$data_slot} = 0;
2216
2217     # this does not work for scalars, but works with
2218     # uvar magic below
2219     #my %vals = %$pager;
2220     #%$pager = ();
2221     #%{$pager} = %vals;
2222   }
2223   else {
2224     # And the uvar magic
2225     # works on 5.10.1, 5.12.1 and 5.13.4 in its current form,
2226     # however see the wizard maker for more notes
2227     my $magic = $mk_lazy_count_wizard->($total_rs, $data_slot);
2228     Variable::Magic::cast ( %$pager, $magic );
2229
2230     # still works
2231     $pager->{$data_slot} = -1;
2232     $pager->{$data_slot} = 0;
2233
2234     # this now works
2235     my %vals = %$pager;
2236     %$pager = ();
2237     %{$pager} = %vals;
2238   }
2239
2240   return $self->{pager} = $pager;
2241 }
2242
2243 =head2 page
2244
2245 =over 4
2246
2247 =item Arguments: $page_number
2248
2249 =item Return Value: $rs
2250
2251 =back
2252
2253 Returns a resultset for the $page_number page of the resultset on which page
2254 is called, where each page contains a number of rows equal to the 'rows'
2255 attribute set on the resultset (10 by default).
2256
2257 =cut
2258
2259 sub page {
2260   my ($self, $page) = @_;
2261   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2262 }
2263
2264 =head2 new_result
2265
2266 =over 4
2267
2268 =item Arguments: \%vals
2269
2270 =item Return Value: $rowobject
2271
2272 =back
2273
2274 Creates a new row object in the resultset's result class and returns
2275 it. The row is not inserted into the database at this point, call
2276 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2277 will tell you whether the row object has been inserted or not.
2278
2279 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2280
2281 =cut
2282
2283 sub new_result {
2284   my ($self, $values) = @_;
2285   $self->throw_exception( "new_result needs a hash" )
2286     unless (ref $values eq 'HASH');
2287
2288   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2289
2290   my %new = (
2291     %$merged_cond,
2292     @$cols_from_relations
2293       ? (-cols_from_relations => $cols_from_relations)
2294       : (),
2295     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2296   );
2297
2298   return $self->result_class->new(\%new);
2299 }
2300
2301 # _merge_with_rscond
2302 #
2303 # Takes a simple hash of K/V data and returns its copy merged with the
2304 # condition already present on the resultset. Additionally returns an
2305 # arrayref of value/condition names, which were inferred from related
2306 # objects (this is needed for in-memory related objects)
2307 sub _merge_with_rscond {
2308   my ($self, $data) = @_;
2309
2310   my (%new_data, @cols_from_relations);
2311
2312   my $alias = $self->{attrs}{alias};
2313
2314   if (! defined $self->{cond}) {
2315     # just massage $data below
2316   }
2317   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2318     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2319     @cols_from_relations = keys %new_data;
2320   }
2321   elsif (ref $self->{cond} ne 'HASH') {
2322     $self->throw_exception(
2323       "Can't abstract implicit construct, resultset condition not a hash"
2324     );
2325   }
2326   else {
2327     # precendence must be given to passed values over values inherited from
2328     # the cond, so the order here is important.
2329     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2330     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2331
2332     while ( my($col, $value) = each %implied ) {
2333       my $vref = ref $value;
2334       if (
2335         $vref eq 'HASH'
2336           and
2337         keys(%$value) == 1
2338           and
2339         (keys %$value)[0] eq '='
2340       ) {
2341         $new_data{$col} = $value->{'='};
2342       }
2343       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2344         $new_data{$col} = $value;
2345       }
2346     }
2347   }
2348
2349   %new_data = (
2350     %new_data,
2351     %{ $self->_remove_alias($data, $alias) },
2352   );
2353
2354   return (\%new_data, \@cols_from_relations);
2355 }
2356
2357 # _has_resolved_attr
2358 #
2359 # determines if the resultset defines at least one
2360 # of the attributes supplied
2361 #
2362 # used to determine if a subquery is neccessary
2363 #
2364 # supports some virtual attributes:
2365 #   -join
2366 #     This will scan for any joins being present on the resultset.
2367 #     It is not a mere key-search but a deep inspection of {from}
2368 #
2369
2370 sub _has_resolved_attr {
2371   my ($self, @attr_names) = @_;
2372
2373   my $attrs = $self->_resolved_attrs;
2374
2375   my %extra_checks;
2376
2377   for my $n (@attr_names) {
2378     if (grep { $n eq $_ } (qw/-join/) ) {
2379       $extra_checks{$n}++;
2380       next;
2381     }
2382
2383     my $attr =  $attrs->{$n};
2384
2385     next if not defined $attr;
2386
2387     if (ref $attr eq 'HASH') {
2388       return 1 if keys %$attr;
2389     }
2390     elsif (ref $attr eq 'ARRAY') {
2391       return 1 if @$attr;
2392     }
2393     else {
2394       return 1 if $attr;
2395     }
2396   }
2397
2398   # a resolved join is expressed as a multi-level from
2399   return 1 if (
2400     $extra_checks{-join}
2401       and
2402     ref $attrs->{from} eq 'ARRAY'
2403       and
2404     @{$attrs->{from}} > 1
2405   );
2406
2407   return 0;
2408 }
2409
2410 # _collapse_cond
2411 #
2412 # Recursively collapse the condition.
2413
2414 sub _collapse_cond {
2415   my ($self, $cond, $collapsed) = @_;
2416
2417   $collapsed ||= {};
2418
2419   if (ref $cond eq 'ARRAY') {
2420     foreach my $subcond (@$cond) {
2421       next unless ref $subcond;  # -or
2422       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2423     }
2424   }
2425   elsif (ref $cond eq 'HASH') {
2426     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2427       foreach my $subcond (@{$cond->{-and}}) {
2428         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2429       }
2430     }
2431     else {
2432       foreach my $col (keys %$cond) {
2433         my $value = $cond->{$col};
2434         $collapsed->{$col} = $value;
2435       }
2436     }
2437   }
2438
2439   return $collapsed;
2440 }
2441
2442 # _remove_alias
2443 #
2444 # Remove the specified alias from the specified query hash. A copy is made so
2445 # the original query is not modified.
2446
2447 sub _remove_alias {
2448   my ($self, $query, $alias) = @_;
2449
2450   my %orig = %{ $query || {} };
2451   my %unaliased;
2452
2453   foreach my $key (keys %orig) {
2454     if ($key !~ /\./) {
2455       $unaliased{$key} = $orig{$key};
2456       next;
2457     }
2458     $unaliased{$1} = $orig{$key}
2459       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2460   }
2461
2462   return \%unaliased;
2463 }
2464
2465 =head2 as_query
2466
2467 =over 4
2468
2469 =item Arguments: none
2470
2471 =item Return Value: \[ $sql, @bind ]
2472
2473 =back
2474
2475 Returns the SQL query and bind vars associated with the invocant.
2476
2477 This is generally used as the RHS for a subquery.
2478
2479 =cut
2480
2481 sub as_query {
2482   my $self = shift;
2483
2484   my $attrs = $self->_resolved_attrs_copy;
2485
2486   # For future use:
2487   #
2488   # in list ctx:
2489   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2490   # $sql also has no wrapping parenthesis in list ctx
2491   #
2492   my $sqlbind = $self->result_source->storage
2493     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2494
2495   return $sqlbind;
2496 }
2497
2498 =head2 find_or_new
2499
2500 =over 4
2501
2502 =item Arguments: \%vals, \%attrs?
2503
2504 =item Return Value: $rowobject
2505
2506 =back
2507
2508   my $artist = $schema->resultset('Artist')->find_or_new(
2509     { artist => 'fred' }, { key => 'artists' });
2510
2511   $cd->cd_to_producer->find_or_new({ producer => $producer },
2512                                    { key => 'primary });
2513
2514 Find an existing record from this resultset using L</find>. if none exists,
2515 instantiate a new result object and return it. The object will not be saved
2516 into your storage until you call L<DBIx::Class::Row/insert> on it.
2517
2518 You most likely want this method when looking for existing rows using a unique
2519 constraint that is not the primary key, or looking for related rows.
2520
2521 If you want objects to be saved immediately, use L</find_or_create> instead.
2522
2523 B<Note>: Make sure to read the documentation of L</find> and understand the
2524 significance of the C<key> attribute, as its lack may skew your search, and
2525 subsequently result in spurious new objects.
2526
2527 B<Note>: Take care when using C<find_or_new> with a table having
2528 columns with default values that you intend to be automatically
2529 supplied by the database (e.g. an auto_increment primary key column).
2530 In normal usage, the value of such columns should NOT be included at
2531 all in the call to C<find_or_new>, even when set to C<undef>.
2532
2533 =cut
2534
2535 sub find_or_new {
2536   my $self     = shift;
2537   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2538   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2539   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2540     return $row;
2541   }
2542   return $self->new_result($hash);
2543 }
2544
2545 =head2 create
2546
2547 =over 4
2548
2549 =item Arguments: \%vals
2550
2551 =item Return Value: a L<DBIx::Class::Row> $object
2552
2553 =back
2554
2555 Attempt to create a single new row or a row with multiple related rows
2556 in the table represented by the resultset (and related tables). This
2557 will not check for duplicate rows before inserting, use
2558 L</find_or_create> to do that.
2559
2560 To create one row for this resultset, pass a hashref of key/value
2561 pairs representing the columns of the table and the values you wish to
2562 store. If the appropriate relationships are set up, foreign key fields
2563 can also be passed an object representing the foreign row, and the
2564 value will be set to its primary key.
2565
2566 To create related objects, pass a hashref of related-object column values
2567 B<keyed on the relationship name>. If the relationship is of type C<multi>
2568 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2569 The process will correctly identify columns holding foreign keys, and will
2570 transparently populate them from the keys of the corresponding relation.
2571 This can be applied recursively, and will work correctly for a structure
2572 with an arbitrary depth and width, as long as the relationships actually
2573 exists and the correct column data has been supplied.
2574
2575
2576 Instead of hashrefs of plain related data (key/value pairs), you may
2577 also pass new or inserted objects. New objects (not inserted yet, see
2578 L</new>), will be inserted into their appropriate tables.
2579
2580 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2581
2582 Example of creating a new row.
2583
2584   $person_rs->create({
2585     name=>"Some Person",
2586     email=>"somebody@someplace.com"
2587   });
2588
2589 Example of creating a new row and also creating rows in a related C<has_many>
2590 or C<has_one> resultset.  Note Arrayref.
2591
2592   $artist_rs->create(
2593      { artistid => 4, name => 'Manufactured Crap', cds => [
2594         { title => 'My First CD', year => 2006 },
2595         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2596       ],
2597      },
2598   );
2599
2600 Example of creating a new row and also creating a row in a related
2601 C<belongs_to> resultset. Note Hashref.
2602
2603   $cd_rs->create({
2604     title=>"Music for Silly Walks",
2605     year=>2000,
2606     artist => {
2607       name=>"Silly Musician",
2608     }
2609   });
2610
2611 =over
2612
2613 =item WARNING
2614
2615 When subclassing ResultSet never attempt to override this method. Since
2616 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2617 lot of the internals simply never call it, so your override will be
2618 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2619 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2620 L</create> process you need to intervene.
2621
2622 =back
2623
2624 =cut
2625
2626 sub create {
2627   my ($self, $attrs) = @_;
2628   $self->throw_exception( "create needs a hashref" )
2629     unless ref $attrs eq 'HASH';
2630   return $self->new_result($attrs)->insert;
2631 }
2632
2633 =head2 find_or_create
2634
2635 =over 4
2636
2637 =item Arguments: \%vals, \%attrs?
2638
2639 =item Return Value: $rowobject
2640
2641 =back
2642
2643   $cd->cd_to_producer->find_or_create({ producer => $producer },
2644                                       { key => 'primary' });
2645
2646 Tries to find a record based on its primary key or unique constraints; if none
2647 is found, creates one and returns that instead.
2648
2649   my $cd = $schema->resultset('CD')->find_or_create({
2650     cdid   => 5,
2651     artist => 'Massive Attack',
2652     title  => 'Mezzanine',
2653     year   => 2005,
2654   });
2655
2656 Also takes an optional C<key> attribute, to search by a specific key or unique
2657 constraint. For example:
2658
2659   my $cd = $schema->resultset('CD')->find_or_create(
2660     {
2661       artist => 'Massive Attack',
2662       title  => 'Mezzanine',
2663     },
2664     { key => 'cd_artist_title' }
2665   );
2666
2667 B<Note>: Make sure to read the documentation of L</find> and understand the
2668 significance of the C<key> attribute, as its lack may skew your search, and
2669 subsequently result in spurious row creation.
2670
2671 B<Note>: Because find_or_create() reads from the database and then
2672 possibly inserts based on the result, this method is subject to a race
2673 condition. Another process could create a record in the table after
2674 the find has completed and before the create has started. To avoid
2675 this problem, use find_or_create() inside a transaction.
2676
2677 B<Note>: Take care when using C<find_or_create> with a table having
2678 columns with default values that you intend to be automatically
2679 supplied by the database (e.g. an auto_increment primary key column).
2680 In normal usage, the value of such columns should NOT be included at
2681 all in the call to C<find_or_create>, even when set to C<undef>.
2682
2683 See also L</find> and L</update_or_create>. For information on how to declare
2684 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2685
2686 =cut
2687
2688 sub find_or_create {
2689   my $self     = shift;
2690   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2691   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2692   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2693     return $row;
2694   }
2695   return $self->create($hash);
2696 }
2697
2698 =head2 update_or_create
2699
2700 =over 4
2701
2702 =item Arguments: \%col_values, { key => $unique_constraint }?
2703
2704 =item Return Value: $row_object
2705
2706 =back
2707
2708   $resultset->update_or_create({ col => $val, ... });
2709
2710 Like L</find_or_create>, but if a row is found it is immediately updated via
2711 C<< $found_row->update (\%col_values) >>.
2712
2713
2714 Takes an optional C<key> attribute to search on a specific unique constraint.
2715 For example:
2716
2717   # In your application
2718   my $cd = $schema->resultset('CD')->update_or_create(
2719     {
2720       artist => 'Massive Attack',
2721       title  => 'Mezzanine',
2722       year   => 1998,
2723     },
2724     { key => 'cd_artist_title' }
2725   );
2726
2727   $cd->cd_to_producer->update_or_create({
2728     producer => $producer,
2729     name => 'harry',
2730   }, {
2731     key => 'primary',
2732   });
2733
2734 B<Note>: Make sure to read the documentation of L</find> and understand the
2735 significance of the C<key> attribute, as its lack may skew your search, and
2736 subsequently result in spurious row creation.
2737
2738 B<Note>: Take care when using C<update_or_create> with a table having
2739 columns with default values that you intend to be automatically
2740 supplied by the database (e.g. an auto_increment primary key column).
2741 In normal usage, the value of such columns should NOT be included at
2742 all in the call to C<update_or_create>, even when set to C<undef>.
2743
2744 See also L</find> and L</find_or_create>. For information on how to declare
2745 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2746
2747 =cut
2748
2749 sub update_or_create {
2750   my $self = shift;
2751   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2752   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2753
2754   my $row = $self->find($cond, $attrs);
2755   if (defined $row) {
2756     $row->update($cond);
2757     return $row;
2758   }
2759
2760   return $self->create($cond);
2761 }
2762
2763 =head2 update_or_new
2764
2765 =over 4
2766
2767 =item Arguments: \%col_values, { key => $unique_constraint }?
2768
2769 =item Return Value: $rowobject
2770
2771 =back
2772
2773   $resultset->update_or_new({ col => $val, ... });
2774
2775 Like L</find_or_new> but if a row is found it is immediately updated via
2776 C<< $found_row->update (\%col_values) >>.
2777
2778 For example:
2779
2780   # In your application
2781   my $cd = $schema->resultset('CD')->update_or_new(
2782     {
2783       artist => 'Massive Attack',
2784       title  => 'Mezzanine',
2785       year   => 1998,
2786     },
2787     { key => 'cd_artist_title' }
2788   );
2789
2790   if ($cd->in_storage) {
2791       # the cd was updated
2792   }
2793   else {
2794       # the cd is not yet in the database, let's insert it
2795       $cd->insert;
2796   }
2797
2798 B<Note>: Make sure to read the documentation of L</find> and understand the
2799 significance of the C<key> attribute, as its lack may skew your search, and
2800 subsequently result in spurious new objects.
2801
2802 B<Note>: Take care when using C<update_or_new> with a table having
2803 columns with default values that you intend to be automatically
2804 supplied by the database (e.g. an auto_increment primary key column).
2805 In normal usage, the value of such columns should NOT be included at
2806 all in the call to C<update_or_new>, even when set to C<undef>.
2807
2808 See also L</find>, L</find_or_create> and L</find_or_new>.
2809
2810 =cut
2811
2812 sub update_or_new {
2813     my $self  = shift;
2814     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2815     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2816
2817     my $row = $self->find( $cond, $attrs );
2818     if ( defined $row ) {
2819         $row->update($cond);
2820         return $row;
2821     }
2822
2823     return $self->new_result($cond);
2824 }
2825
2826 =head2 get_cache
2827
2828 =over 4
2829
2830 =item Arguments: none
2831
2832 =item Return Value: \@cache_objects | undef
2833
2834 =back
2835
2836 Gets the contents of the cache for the resultset, if the cache is set.
2837
2838 The cache is populated either by using the L</prefetch> attribute to
2839 L</search> or by calling L</set_cache>.
2840
2841 =cut
2842
2843 sub get_cache {
2844   shift->{all_cache};
2845 }
2846
2847 =head2 set_cache
2848
2849 =over 4
2850
2851 =item Arguments: \@cache_objects
2852
2853 =item Return Value: \@cache_objects
2854
2855 =back
2856
2857 Sets the contents of the cache for the resultset. Expects an arrayref
2858 of objects of the same class as those produced by the resultset. Note that
2859 if the cache is set the resultset will return the cached objects rather
2860 than re-querying the database even if the cache attr is not set.
2861
2862 The contents of the cache can also be populated by using the
2863 L</prefetch> attribute to L</search>.
2864
2865 =cut
2866
2867 sub set_cache {
2868   my ( $self, $data ) = @_;
2869   $self->throw_exception("set_cache requires an arrayref")
2870       if defined($data) && (ref $data ne 'ARRAY');
2871   $self->{all_cache} = $data;
2872 }
2873
2874 =head2 clear_cache
2875
2876 =over 4
2877
2878 =item Arguments: none
2879
2880 =item Return Value: undef
2881
2882 =back
2883
2884 Clears the cache for the resultset.
2885
2886 =cut
2887
2888 sub clear_cache {
2889   shift->set_cache(undef);
2890 }
2891
2892 =head2 is_paged
2893
2894 =over 4
2895
2896 =item Arguments: none
2897
2898 =item Return Value: true, if the resultset has been paginated
2899
2900 =back
2901
2902 =cut
2903
2904 sub is_paged {
2905   my ($self) = @_;
2906   return !!$self->{attrs}{page};
2907 }
2908
2909 =head2 is_ordered
2910
2911 =over 4
2912
2913 =item Arguments: none
2914
2915 =item Return Value: true, if the resultset has been ordered with C<order_by>.
2916
2917 =back
2918
2919 =cut
2920
2921 sub is_ordered {
2922   my ($self) = @_;
2923   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
2924 }
2925
2926 =head2 related_resultset
2927
2928 =over 4
2929
2930 =item Arguments: $relationship_name
2931
2932 =item Return Value: $resultset
2933
2934 =back
2935
2936 Returns a related resultset for the supplied relationship name.
2937
2938   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2939
2940 =cut
2941
2942 sub related_resultset {
2943   my ($self, $rel) = @_;
2944
2945   $self->{related_resultsets} ||= {};
2946   return $self->{related_resultsets}{$rel} ||= do {
2947     my $rsrc = $self->result_source;
2948     my $rel_info = $rsrc->relationship_info($rel);
2949
2950     $self->throw_exception(
2951       "search_related: result source '" . $rsrc->source_name .
2952         "' has no such relationship $rel")
2953       unless $rel_info;
2954
2955     my $attrs = $self->_chain_relationship($rel);
2956
2957     my $join_count = $attrs->{seen_join}{$rel};
2958
2959     my $alias = $self->result_source->storage
2960         ->relname_to_table_alias($rel, $join_count);
2961
2962     # since this is search_related, and we already slid the select window inwards
2963     # (the select/as attrs were deleted in the beginning), we need to flip all
2964     # left joins to inner, so we get the expected results
2965     # read the comment on top of the actual function to see what this does
2966     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
2967
2968
2969     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2970     delete @{$attrs}{qw(result_class alias)};
2971
2972     my $new_cache;
2973
2974     if (my $cache = $self->get_cache) {
2975       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2976         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2977                         @$cache ];
2978       }
2979     }
2980
2981     my $rel_source = $rsrc->related_source($rel);
2982
2983     my $new = do {
2984
2985       # The reason we do this now instead of passing the alias to the
2986       # search_rs below is that if you wrap/overload resultset on the
2987       # source you need to know what alias it's -going- to have for things
2988       # to work sanely (e.g. RestrictWithObject wants to be able to add
2989       # extra query restrictions, and these may need to be $alias.)
2990
2991       my $rel_attrs = $rel_source->resultset_attributes;
2992       local $rel_attrs->{alias} = $alias;
2993
2994       $rel_source->resultset
2995                  ->search_rs(
2996                      undef, {
2997                        %$attrs,
2998                        where => $attrs->{where},
2999                    });
3000     };
3001     $new->set_cache($new_cache) if $new_cache;
3002     $new;
3003   };
3004 }
3005
3006 =head2 current_source_alias
3007
3008 =over 4
3009
3010 =item Arguments: none
3011
3012 =item Return Value: $source_alias
3013
3014 =back
3015
3016 Returns the current table alias for the result source this resultset is built
3017 on, that will be used in the SQL query. Usually it is C<me>.
3018
3019 Currently the source alias that refers to the result set returned by a
3020 L</search>/L</find> family method depends on how you got to the resultset: it's
3021 C<me> by default, but eg. L</search_related> aliases it to the related result
3022 source name (and keeps C<me> referring to the original result set). The long
3023 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3024 (and make this method unnecessary).
3025
3026 Thus it's currently necessary to use this method in predefined queries (see
3027 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3028 source alias of the current result set:
3029
3030   # in a result set class
3031   sub modified_by {
3032     my ($self, $user) = @_;
3033
3034     my $me = $self->current_source_alias;
3035
3036     return $self->search(
3037       "$me.modified" => $user->id,
3038     );
3039   }
3040
3041 =cut
3042
3043 sub current_source_alias {
3044   my ($self) = @_;
3045
3046   return ($self->{attrs} || {})->{alias} || 'me';
3047 }
3048
3049 =head2 as_subselect_rs
3050
3051 =over 4
3052
3053 =item Arguments: none
3054
3055 =item Return Value: $resultset
3056
3057 =back
3058
3059 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3060 "virtual view" by including it as a subquery within the from clause.  From this
3061 point on, any joined tables are inaccessible to ->search on the resultset (as if
3062 it were simply where-filtered without joins).  For example:
3063
3064  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3065
3066  # 'x' now pollutes the query namespace
3067
3068  # So the following works as expected
3069  my $ok_rs = $rs->search({'x.other' => 1});
3070
3071  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3072  # def) we look for one row with contradictory terms and join in another table
3073  # (aliased 'x_2') which we never use
3074  my $broken_rs = $rs->search({'x.name' => 'def'});
3075
3076  my $rs2 = $rs->as_subselect_rs;
3077
3078  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3079  my $not_joined_rs = $rs2->search({'x.other' => 1});
3080
3081  # works as expected: finds a 'table' row related to two x rows (abc and def)
3082  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3083
3084 Another example of when one might use this would be to select a subset of
3085 columns in a group by clause:
3086
3087  my $rs = $schema->resultset('Bar')->search(undef, {
3088    group_by => [qw{ id foo_id baz_id }],
3089  })->as_subselect_rs->search(undef, {
3090    columns => [qw{ id foo_id }]
3091  });
3092
3093 In the above example normally columns would have to be equal to the group by,
3094 but because we isolated the group by into a subselect the above works.
3095
3096 =cut
3097
3098 sub as_subselect_rs {
3099   my $self = shift;
3100
3101   my $attrs = $self->_resolved_attrs;
3102
3103   my $fresh_rs = (ref $self)->new (
3104     $self->result_source
3105   );
3106
3107   # these pieces will be locked in the subquery
3108   delete $fresh_rs->{cond};
3109   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3110
3111   return $fresh_rs->search( {}, {
3112     from => [{
3113       $attrs->{alias} => $self->as_query,
3114       -alias  => $attrs->{alias},
3115       -rsrc   => $self->result_source,
3116     }],
3117     alias => $attrs->{alias},
3118   });
3119 }
3120
3121 # This code is called by search_related, and makes sure there
3122 # is clear separation between the joins before, during, and
3123 # after the relationship. This information is needed later
3124 # in order to properly resolve prefetch aliases (any alias
3125 # with a relation_chain_depth less than the depth of the
3126 # current prefetch is not considered)
3127 #
3128 # The increments happen twice per join. An even number means a
3129 # relationship specified via a search_related, whereas an odd
3130 # number indicates a join/prefetch added via attributes
3131 #
3132 # Also this code will wrap the current resultset (the one we
3133 # chain to) in a subselect IFF it contains limiting attributes
3134 sub _chain_relationship {
3135   my ($self, $rel) = @_;
3136   my $source = $self->result_source;
3137   my $attrs = { %{$self->{attrs}||{}} };
3138
3139   # we need to take the prefetch the attrs into account before we
3140   # ->_resolve_join as otherwise they get lost - captainL
3141   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3142
3143   delete @{$attrs}{qw/join prefetch collapse group_by distinct select as columns +select +as +columns/};
3144
3145   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3146
3147   my $from;
3148   my @force_subq_attrs = qw/offset rows group_by having/;
3149
3150   if (
3151     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3152       ||
3153     $self->_has_resolved_attr (@force_subq_attrs)
3154   ) {
3155     # Nuke the prefetch (if any) before the new $rs attrs
3156     # are resolved (prefetch is useless - we are wrapping
3157     # a subquery anyway).
3158     my $rs_copy = $self->search;
3159     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3160       $rs_copy->{attrs}{join},
3161       delete $rs_copy->{attrs}{prefetch},
3162     );
3163
3164     $from = [{
3165       -rsrc   => $source,
3166       -alias  => $attrs->{alias},
3167       $attrs->{alias} => $rs_copy->as_query,
3168     }];
3169     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3170     $seen->{-relation_chain_depth} = 0;
3171   }
3172   elsif ($attrs->{from}) {  #shallow copy suffices
3173     $from = [ @{$attrs->{from}} ];
3174   }
3175   else {
3176     $from = [{
3177       -rsrc  => $source,
3178       -alias => $attrs->{alias},
3179       $attrs->{alias} => $source->from,
3180     }];
3181   }
3182
3183   my $jpath = ($seen->{-relation_chain_depth})
3184     ? $from->[-1][0]{-join_path}
3185     : [];
3186
3187   my @requested_joins = $source->_resolve_join(
3188     $join,
3189     $attrs->{alias},
3190     $seen,
3191     $jpath,
3192   );
3193
3194   push @$from, @requested_joins;
3195
3196   $seen->{-relation_chain_depth}++;
3197
3198   # if $self already had a join/prefetch specified on it, the requested
3199   # $rel might very well be already included. What we do in this case
3200   # is effectively a no-op (except that we bump up the chain_depth on
3201   # the join in question so we could tell it *is* the search_related)
3202   my $already_joined;
3203
3204   # we consider the last one thus reverse
3205   for my $j (reverse @requested_joins) {
3206     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3207     if ($rel eq $last_j) {
3208       $j->[0]{-relation_chain_depth}++;
3209       $already_joined++;
3210       last;
3211     }
3212   }
3213
3214   unless ($already_joined) {
3215     push @$from, $source->_resolve_join(
3216       $rel,
3217       $attrs->{alias},
3218       $seen,
3219       $jpath,
3220     );
3221   }
3222
3223   $seen->{-relation_chain_depth}++;
3224
3225   return {%$attrs, from => $from, seen_join => $seen};
3226 }
3227
3228 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
3229 sub _resolved_attrs_copy {
3230   my $self = shift;
3231   return { %{$self->_resolved_attrs (@_)} };
3232 }
3233
3234 sub _resolved_attrs {
3235   my $self = shift;
3236   return $self->{_attrs} if $self->{_attrs};
3237
3238   my $attrs  = { %{ $self->{attrs} || {} } };
3239   my $source = $self->result_source;
3240   my $alias  = $attrs->{alias};
3241
3242   # one last pass of normalization
3243   $self->_normalize_selection($attrs);
3244
3245   # default selection list
3246   $attrs->{columns} = [ $source->columns ]
3247     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as _trailing_select/;
3248
3249   # merge selectors together
3250   for (qw/columns select as _trailing_select/) {
3251     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, $attrs->{"+$_"})
3252       if $attrs->{$_} or $attrs->{"+$_"};
3253   }
3254
3255   # disassemble columns
3256   my (@sel, @as);
3257   if (my $cols = delete $attrs->{columns}) {
3258     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3259       if (ref $c eq 'HASH') {
3260         for my $as (keys %$c) {
3261           push @sel, $c->{$as};
3262           push @as, $as;
3263         }
3264       }
3265       else {
3266         push @sel, $c;
3267         push @as, $c;
3268       }
3269     }
3270   }
3271
3272   # when trying to weed off duplicates later do not go past this point -
3273   # everything added from here on is unbalanced "anyone's guess" stuff
3274   my $dedup_stop_idx = $#as;
3275
3276   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3277     if $attrs->{as};
3278   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3279     if $attrs->{select};
3280
3281   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3282   for (@sel) {
3283     $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_";
3284   }
3285
3286   # disqualify all $alias.col as-bits (collapser mandated)
3287   for (@as) {
3288     $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_;
3289   }
3290
3291   # de-duplicate the result (remove *identical* select/as pairs)
3292   # and also die on duplicate {as} pointing to different {select}s
3293   # not using a c-style for as the condition is prone to shrinkage
3294   my $seen;
3295   my $i = 0;
3296   while ($i <= $dedup_stop_idx) {
3297     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3298       splice @sel, $i, 1;
3299       splice @as, $i, 1;
3300       $dedup_stop_idx--;
3301     }
3302     elsif ($seen->{$as[$i]}++) {
3303       $self->throw_exception(
3304         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3305       );
3306     }
3307     else {
3308       $i++;
3309     }
3310   }
3311
3312   $attrs->{select} = \@sel;
3313   $attrs->{as} = \@as;
3314
3315   $attrs->{from} ||= [{
3316     -rsrc   => $source,
3317     -alias  => $self->{attrs}{alias},
3318     $self->{attrs}{alias} => $source->from,
3319   }];
3320
3321   if ( $attrs->{join} || $attrs->{prefetch} ) {
3322
3323     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3324       if ref $attrs->{from} ne 'ARRAY';
3325
3326     my $join = (delete $attrs->{join}) || {};
3327
3328     if ( defined $attrs->{prefetch} ) {
3329       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3330     }
3331
3332     $attrs->{from} =    # have to copy here to avoid corrupting the original
3333       [
3334         @{ $attrs->{from} },
3335         $source->_resolve_join(
3336           $join,
3337           $alias,
3338           { %{ $attrs->{seen_join} || {} } },
3339           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3340             ? $attrs->{from}[-1][0]{-join_path}
3341             : []
3342           ,
3343         )
3344       ];
3345   }
3346
3347   if ( defined $attrs->{order_by} ) {
3348     $attrs->{order_by} = (
3349       ref( $attrs->{order_by} ) eq 'ARRAY'
3350       ? [ @{ $attrs->{order_by} } ]
3351       : [ $attrs->{order_by} || () ]
3352     );
3353   }
3354
3355   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3356     $attrs->{group_by} = [ $attrs->{group_by} ];
3357   }
3358
3359   # generate the distinct induced group_by early, as prefetch will be carried via a
3360   # subquery (since a group_by is present)
3361   if (delete $attrs->{distinct}) {
3362     if ($attrs->{group_by}) {
3363       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3364     }
3365     else {
3366       # distinct affects only the main selection part, not what prefetch may
3367       # add below. However trailing is not yet a part of the selection as
3368       # prefetch must insert before it
3369       $attrs->{group_by} = $source->storage->_group_over_selection (
3370         $attrs->{from},
3371         [ @{$attrs->{select}||[]}, @{$attrs->{_trailing_select}||[]} ],
3372         $attrs->{order_by},
3373       );
3374     }
3375   }
3376
3377   $attrs->{collapse} ||= {};
3378   if ($attrs->{prefetch}) {
3379     my $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} );
3380
3381     my $prefetch_ordering = [];
3382
3383     # this is a separate structure (we don't look in {from} directly)
3384     # as the resolver needs to shift things off the lists to work
3385     # properly (identical-prefetches on different branches)
3386     my $join_map = {};
3387     if (ref $attrs->{from} eq 'ARRAY') {
3388
3389       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3390
3391       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3392         next unless $j->[0]{-alias};
3393         next unless $j->[0]{-join_path};
3394         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3395
3396         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3397
3398         my $p = $join_map;
3399         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3400         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3401       }
3402     }
3403
3404     my @prefetch =
3405       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
3406
3407     # we need to somehow mark which columns came from prefetch
3408     if (@prefetch) {
3409       my $sel_end = $#{$attrs->{select}};
3410       $attrs->{_prefetch_selector_range} = [ $sel_end + 1, $sel_end + @prefetch ];
3411     }
3412
3413     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3414     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3415
3416     push( @{$attrs->{order_by}}, @$prefetch_ordering );
3417     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
3418   }
3419
3420
3421   push @{ $attrs->{select} }, @{$attrs->{_trailing_select}}
3422     if $attrs->{_trailing_select};
3423
3424   # if both page and offset are specified, produce a combined offset
3425   # even though it doesn't make much sense, this is what pre 081xx has
3426   # been doing
3427   if (my $page = delete $attrs->{page}) {
3428     $attrs->{offset} =
3429       ($attrs->{rows} * ($page - 1))
3430             +
3431       ($attrs->{offset} || 0)
3432     ;
3433   }
3434
3435   return $self->{_attrs} = $attrs;
3436 }
3437
3438 sub _rollout_attr {
3439   my ($self, $attr) = @_;
3440
3441   if (ref $attr eq 'HASH') {
3442     return $self->_rollout_hash($attr);
3443   } elsif (ref $attr eq 'ARRAY') {
3444     return $self->_rollout_array($attr);
3445   } else {
3446     return [$attr];
3447   }
3448 }
3449
3450 sub _rollout_array {
3451   my ($self, $attr) = @_;
3452
3453   my @rolled_array;
3454   foreach my $element (@{$attr}) {
3455     if (ref $element eq 'HASH') {
3456       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3457     } elsif (ref $element eq 'ARRAY') {
3458       #  XXX - should probably recurse here
3459       push( @rolled_array, @{$self->_rollout_array($element)} );
3460     } else {
3461       push( @rolled_array, $element );
3462     }
3463   }
3464   return \@rolled_array;
3465 }
3466
3467 sub _rollout_hash {
3468   my ($self, $attr) = @_;
3469
3470   my @rolled_array;
3471   foreach my $key (keys %{$attr}) {
3472     push( @rolled_array, { $key => $attr->{$key} } );
3473   }
3474   return \@rolled_array;
3475 }
3476
3477 sub _calculate_score {
3478   my ($self, $a, $b) = @_;
3479
3480   if (defined $a xor defined $b) {
3481     return 0;
3482   }
3483   elsif (not defined $a) {
3484     return 1;
3485   }
3486
3487   if (ref $b eq 'HASH') {
3488     my ($b_key) = keys %{$b};
3489     if (ref $a eq 'HASH') {
3490       my ($a_key) = keys %{$a};
3491       if ($a_key eq $b_key) {
3492         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3493       } else {
3494         return 0;
3495       }
3496     } else {
3497       return ($a eq $b_key) ? 1 : 0;
3498     }
3499   } else {
3500     if (ref $a eq 'HASH') {
3501       my ($a_key) = keys %{$a};
3502       return ($b eq $a_key) ? 1 : 0;
3503     } else {
3504       return ($b eq $a) ? 1 : 0;
3505     }
3506   }
3507 }
3508
3509 sub _merge_joinpref_attr {
3510   my ($self, $orig, $import) = @_;
3511
3512   return $import unless defined($orig);
3513   return $orig unless defined($import);
3514
3515   $orig = $self->_rollout_attr($orig);
3516   $import = $self->_rollout_attr($import);
3517
3518   my $seen_keys;
3519   foreach my $import_element ( @{$import} ) {
3520     # find best candidate from $orig to merge $b_element into
3521     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3522     foreach my $orig_element ( @{$orig} ) {
3523       my $score = $self->_calculate_score( $orig_element, $import_element );
3524       if ($score > $best_candidate->{score}) {
3525         $best_candidate->{position} = $position;
3526         $best_candidate->{score} = $score;
3527       }
3528       $position++;
3529     }
3530     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3531
3532     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3533       push( @{$orig}, $import_element );
3534     } else {
3535       my $orig_best = $orig->[$best_candidate->{position}];
3536       # merge orig_best and b_element together and replace original with merged
3537       if (ref $orig_best ne 'HASH') {
3538         $orig->[$best_candidate->{position}] = $import_element;
3539       } elsif (ref $import_element eq 'HASH') {
3540         my ($key) = keys %{$orig_best};
3541         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3542       }
3543     }
3544     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3545   }
3546
3547   return $orig;
3548 }
3549
3550 {
3551   my $hm;
3552
3553   sub _merge_attr {
3554     $hm ||= do {
3555       require Hash::Merge;
3556       my $hm = Hash::Merge->new;
3557
3558       $hm->specify_behavior({
3559         SCALAR => {
3560           SCALAR => sub {
3561             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3562
3563             if ($defl xor $defr) {
3564               return [ $defl ? $_[0] : $_[1] ];
3565             }
3566             elsif (! $defl) {
3567               return [];
3568             }
3569             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3570               return [ $_[0] ];
3571             }
3572             else {
3573               return [$_[0], $_[1]];
3574             }
3575           },
3576           ARRAY => sub {
3577             return $_[1] if !defined $_[0];
3578             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3579             return [$_[0], @{$_[1]}]
3580           },
3581           HASH  => sub {
3582             return [] if !defined $_[0] and !keys %{$_[1]};
3583             return [ $_[1] ] if !defined $_[0];
3584             return [ $_[0] ] if !keys %{$_[1]};
3585             return [$_[0], $_[1]]
3586           },
3587         },
3588         ARRAY => {
3589           SCALAR => sub {
3590             return $_[0] if !defined $_[1];
3591             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3592             return [@{$_[0]}, $_[1]]
3593           },
3594           ARRAY => sub {
3595             my @ret = @{$_[0]} or return $_[1];
3596             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3597             my %idx = map { $_ => 1 } @ret;
3598             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3599             \@ret;
3600           },
3601           HASH => sub {
3602             return [ $_[1] ] if ! @{$_[0]};
3603             return $_[0] if !keys %{$_[1]};
3604             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3605             return [ @{$_[0]}, $_[1] ];
3606           },
3607         },
3608         HASH => {
3609           SCALAR => sub {
3610             return [] if !keys %{$_[0]} and !defined $_[1];
3611             return [ $_[0] ] if !defined $_[1];
3612             return [ $_[1] ] if !keys %{$_[0]};
3613             return [$_[0], $_[1]]
3614           },
3615           ARRAY => sub {
3616             return [] if !keys %{$_[0]} and !@{$_[1]};
3617             return [ $_[0] ] if !@{$_[1]};
3618             return $_[1] if !keys %{$_[0]};
3619             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3620             return [ $_[0], @{$_[1]} ];
3621           },
3622           HASH => sub {
3623             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3624             return [ $_[0] ] if !keys %{$_[1]};
3625             return [ $_[1] ] if !keys %{$_[0]};
3626             return [ $_[0] ] if $_[0] eq $_[1];
3627             return [ $_[0], $_[1] ];
3628           },
3629         }
3630       } => 'DBIC_RS_ATTR_MERGER');
3631       $hm;
3632     };
3633
3634     return $hm->merge ($_[1], $_[2]);
3635   }
3636 }
3637
3638 sub STORABLE_freeze {
3639   my ($self, $cloning) = @_;
3640   my $to_serialize = { %$self };
3641
3642   # A cursor in progress can't be serialized (and would make little sense anyway)
3643   delete $to_serialize->{cursor};
3644
3645   Storable::nfreeze($to_serialize);
3646 }
3647
3648 # need this hook for symmetry
3649 sub STORABLE_thaw {
3650   my ($self, $cloning, $serialized) = @_;
3651
3652   %$self = %{ Storable::thaw($serialized) };
3653
3654   $self;
3655 }
3656
3657
3658 =head2 throw_exception
3659
3660 See L<DBIx::Class::Schema/throw_exception> for details.
3661
3662 =cut
3663
3664 sub throw_exception {
3665   my $self=shift;
3666
3667   if (ref $self and my $rsrc = $self->result_source) {
3668     $rsrc->throw_exception(@_)
3669   }
3670   else {
3671     DBIx::Class::Exception->throw(@_);
3672   }
3673 }
3674
3675 # XXX: FIXME: Attributes docs need clearing up
3676
3677 =head1 ATTRIBUTES
3678
3679 Attributes are used to refine a ResultSet in various ways when
3680 searching for data. They can be passed to any method which takes an
3681 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3682 L</count>.
3683
3684 These are in no particular order:
3685
3686 =head2 order_by
3687
3688 =over 4
3689
3690 =item Value: ( $order_by | \@order_by | \%order_by )
3691
3692 =back
3693
3694 Which column(s) to order the results by.
3695
3696 [The full list of suitable values is documented in
3697 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3698 common options.]
3699
3700 If a single column name, or an arrayref of names is supplied, the
3701 argument is passed through directly to SQL. The hashref syntax allows
3702 for connection-agnostic specification of ordering direction:
3703
3704  For descending order:
3705
3706   order_by => { -desc => [qw/col1 col2 col3/] }
3707
3708  For explicit ascending order:
3709
3710   order_by => { -asc => 'col' }
3711
3712 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3713 supported, although you are strongly encouraged to use the hashref
3714 syntax as outlined above.
3715
3716 =head2 columns
3717
3718 =over 4
3719
3720 =item Value: \@columns
3721
3722 =back
3723
3724 Shortcut to request a particular set of columns to be retrieved. Each
3725 column spec may be a string (a table column name), or a hash (in which
3726 case the key is the C<as> value, and the value is used as the C<select>
3727 expression). Adds C<me.> onto the start of any column without a C<.> in
3728 it and sets C<select> from that, then auto-populates C<as> from
3729 C<select> as normal. (You may also use the C<cols> attribute, as in
3730 earlier versions of DBIC.)
3731
3732 Essentially C<columns> does the same as L</select> and L</as>.
3733
3734     columns => [ 'foo', { bar => 'baz' } ]
3735
3736 is the same as
3737
3738     select => [qw/foo baz/],
3739     as => [qw/foo bar/]
3740
3741 =head2 +columns
3742
3743 =over 4
3744
3745 =item Value: \@columns
3746
3747 =back
3748
3749 Indicates additional columns to be selected from storage. Works the same
3750 as L</columns> but adds columns to the selection. (You may also use the
3751 C<include_columns> attribute, as in earlier versions of DBIC). For
3752 example:-
3753
3754   $schema->resultset('CD')->search(undef, {
3755     '+columns' => ['artist.name'],
3756     join => ['artist']
3757   });
3758
3759 would return all CDs and include a 'name' column to the information
3760 passed to object inflation. Note that the 'artist' is the name of the
3761 column (or relationship) accessor, and 'name' is the name of the column
3762 accessor in the related table.
3763
3764 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3765 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3766 unary plus operator before it.
3767
3768 =head2 include_columns
3769
3770 =over 4
3771
3772 =item Value: \@columns
3773
3774 =back
3775
3776 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3777
3778 =head2 select
3779
3780 =over 4
3781
3782 =item Value: \@select_columns
3783
3784 =back
3785
3786 Indicates which columns should be selected from the storage. You can use
3787 column names, or in the case of RDBMS back ends, function or stored procedure
3788 names:
3789
3790   $rs = $schema->resultset('Employee')->search(undef, {
3791     select => [
3792       'name',
3793       { count => 'employeeid' },
3794       { max => { length => 'name' }, -as => 'longest_name' }
3795     ]
3796   });
3797
3798   # Equivalent SQL
3799   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
3800
3801 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
3802 use L</select>, to instruct DBIx::Class how to store the result of the column.
3803 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
3804 identifier aliasing. You can however alias a function, so you can use it in
3805 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
3806 attribute> supplied as shown in the example above.
3807
3808 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
3809 Not doing so causes Perl to incorrectly interpret them as a bareword with a
3810 unary plus operator before it.
3811
3812 =head2 +select
3813
3814 =over 4
3815
3816 Indicates additional columns to be selected from storage.  Works the same as
3817 L</select> but adds columns to the default selection, instead of specifying
3818 an explicit list.
3819
3820 =back
3821
3822 =head2 +as
3823
3824 =over 4
3825
3826 Indicates additional column names for those added via L</+select>. See L</as>.
3827
3828 =back
3829
3830 =head2 as
3831
3832 =over 4
3833
3834 =item Value: \@inflation_names
3835
3836 =back
3837
3838 Indicates column names for object inflation. That is L</as> indicates the
3839 slot name in which the column value will be stored within the
3840 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
3841 identifier by the C<get_column> method (or via the object accessor B<if one
3842 with the same name already exists>) as shown below. The L</as> attribute has
3843 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
3844
3845   $rs = $schema->resultset('Employee')->search(undef, {
3846     select => [
3847       'name',
3848       { count => 'employeeid' },
3849       { max => { length => 'name' }, -as => 'longest_name' }
3850     ],
3851     as => [qw/
3852       name
3853       employee_count
3854       max_name_length
3855     /],
3856   });
3857
3858 If the object against which the search is performed already has an accessor
3859 matching a column name specified in C<as>, the value can be retrieved using
3860 the accessor as normal:
3861
3862   my $name = $employee->name();
3863
3864 If on the other hand an accessor does not exist in the object, you need to
3865 use C<get_column> instead:
3866
3867   my $employee_count = $employee->get_column('employee_count');
3868
3869 You can create your own accessors if required - see
3870 L<DBIx::Class::Manual::Cookbook> for details.
3871
3872 =head2 join
3873
3874 =over 4
3875
3876 =item Value: ($rel_name | \@rel_names | \%rel_names)
3877
3878 =back
3879
3880 Contains a list of relationships that should be joined for this query.  For
3881 example:
3882
3883   # Get CDs by Nine Inch Nails
3884   my $rs = $schema->resultset('CD')->search(
3885     { 'artist.name' => 'Nine Inch Nails' },
3886     { join => 'artist' }
3887   );
3888
3889 Can also contain a hash reference to refer to the other relation's relations.
3890 For example:
3891
3892   package MyApp::Schema::Track;
3893   use base qw/DBIx::Class/;
3894   __PACKAGE__->table('track');
3895   __PACKAGE__->add_columns(qw/trackid cd position title/);
3896   __PACKAGE__->set_primary_key('trackid');
3897   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3898   1;
3899
3900   # In your application
3901   my $rs = $schema->resultset('Artist')->search(
3902     { 'track.title' => 'Teardrop' },
3903     {
3904       join     => { cd => 'track' },
3905       order_by => 'artist.name',
3906     }
3907   );
3908
3909 You need to use the relationship (not the table) name in  conditions,
3910 because they are aliased as such. The current table is aliased as "me", so
3911 you need to use me.column_name in order to avoid ambiguity. For example:
3912
3913   # Get CDs from 1984 with a 'Foo' track
3914   my $rs = $schema->resultset('CD')->search(
3915     {
3916       'me.year' => 1984,
3917       'tracks.name' => 'Foo'
3918     },
3919     { join => 'tracks' }
3920   );
3921
3922 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3923 similarly for a third time). For e.g.
3924
3925   my $rs = $schema->resultset('Artist')->search({
3926     'cds.title'   => 'Down to Earth',
3927     'cds_2.title' => 'Popular',
3928   }, {
3929     join => [ qw/cds cds/ ],
3930   });
3931
3932 will return a set of all artists that have both a cd with title 'Down
3933 to Earth' and a cd with title 'Popular'.
3934
3935 If you want to fetch related objects from other tables as well, see C<prefetch>
3936 below.
3937
3938 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3939
3940 =head2 prefetch
3941
3942 =over 4
3943
3944 =item Value: ($rel_name | \@rel_names | \%rel_names)
3945
3946 =back
3947
3948 Contains one or more relationships that should be fetched along with
3949 the main query (when they are accessed afterwards the data will
3950 already be available, without extra queries to the database).  This is
3951 useful for when you know you will need the related objects, because it
3952 saves at least one query:
3953
3954   my $rs = $schema->resultset('Tag')->search(
3955     undef,
3956     {
3957       prefetch => {
3958         cd => 'artist'
3959       }
3960     }
3961   );
3962
3963 The initial search results in SQL like the following:
3964
3965   SELECT tag.*, cd.*, artist.* FROM tag
3966   JOIN cd ON tag.cd = cd.cdid
3967   JOIN artist ON cd.artist = artist.artistid
3968
3969 L<DBIx::Class> has no need to go back to the database when we access the
3970 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3971 case.
3972
3973 Simple prefetches will be joined automatically, so there is no need
3974 for a C<join> attribute in the above search.
3975
3976 L</prefetch> can be used with the any of the relationship types and
3977 multiple prefetches can be specified together. Below is a more complex
3978 example that prefetches a CD's artist, its liner notes (if present),
3979 the cover image, the tracks on that cd, and the guests on those
3980 tracks.
3981
3982  # Assuming:
3983  My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
3984  My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
3985  My::Schema::CD->has_one(    cover_image => 'My::Schema::Artwork'    );
3986  My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
3987
3988  My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
3989
3990  My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
3991
3992
3993  my $rs = $schema->resultset('CD')->search(
3994    undef,
3995    {
3996      prefetch => [
3997        { artist => 'record_label'},  # belongs_to => belongs_to
3998        'liner_note',                 # might_have
3999        'cover_image',                # has_one
4000        { tracks => 'guests' },       # has_many => has_many
4001      ]
4002    }
4003  );
4004
4005 This will produce SQL like the following:
4006
4007  SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4008         tracks.*, guests.*
4009    FROM cd me
4010    JOIN artist artist
4011      ON artist.artistid = me.artistid
4012    JOIN record_label record_label
4013      ON record_label.labelid = artist.labelid
4014    LEFT JOIN track tracks
4015      ON tracks.cdid = me.cdid
4016    LEFT JOIN guest guests
4017      ON guests.trackid = track.trackid
4018    LEFT JOIN liner_notes liner_note
4019      ON liner_note.cdid = me.cdid
4020    JOIN cd_artwork cover_image
4021      ON cover_image.cdid = me.cdid
4022  ORDER BY tracks.cd
4023
4024 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4025 C<tracks>, and C<guests> of the CD will all be available through the
4026 relationship accessors without the need for additional queries to the
4027 database.
4028
4029 However, there is one caveat to be observed: it can be dangerous to
4030 prefetch more than one L<has_many|DBIx::Class::Relationship/has_many>
4031 relationship on a given level. e.g.:
4032
4033  my $rs = $schema->resultset('CD')->search(
4034    undef,
4035    {
4036      prefetch => [
4037        'tracks',                         # has_many
4038        { cd_to_producer => 'producer' }, # has_many => belongs_to (i.e. m2m)
4039      ]
4040    }
4041  );
4042
4043 In fact, C<DBIx::Class> will emit the following warning:
4044
4045  Prefetching multiple has_many rels tracks and cd_to_producer at top
4046  level will explode the number of row objects retrievable via ->next
4047  or ->all. Use at your own risk.
4048
4049 The collapser currently can't identify duplicate tuples for multiple
4050 L<has_many|DBIx::Class::Relationship/has_many> relationships and as a
4051 result the second L<has_many|DBIx::Class::Relationship/has_many>
4052 relation could contain redundant objects.
4053
4054 =head3 Using L</prefetch> with L</join>
4055
4056 L</prefetch> implies a L</join> with the equivalent argument, and is
4057 properly merged with any existing L</join> specification. So the
4058 following:
4059
4060   my $rs = $schema->resultset('CD')->search(
4061    {'record_label.name' => 'Music Product Ltd.'},
4062    {
4063      join     => {artist => 'record_label'},
4064      prefetch => 'artist',
4065    }
4066  );
4067
4068 ... will work, searching on the record label's name, but only
4069 prefetching the C<artist>.
4070
4071 =head3 Using L</prefetch> with L</select> / L</+select> / L</as> / L</+as>
4072
4073 L</prefetch> implies a L</+select>/L</+as> with the fields of the
4074 prefetched relations.  So given:
4075
4076   my $rs = $schema->resultset('CD')->search(
4077    undef,
4078    {
4079      select   => ['cd.title'],
4080      as       => ['cd_title'],
4081      prefetch => 'artist',
4082    }
4083  );
4084
4085 The L</select> becomes: C<'cd.title', 'artist.*'> and the L</as>
4086 becomes: C<'cd_title', 'artist.*'>.
4087
4088 =head3 CAVEATS
4089
4090 Prefetch does a lot of deep magic. As such, it may not behave exactly
4091 as you might expect.
4092
4093 =over 4
4094
4095 =item *
4096
4097 Prefetch uses the L</cache> to populate the prefetched relationships. This
4098 may or may not be what you want.
4099
4100 =item *
4101
4102 If you specify a condition on a prefetched relationship, ONLY those
4103 rows that match the prefetched condition will be fetched into that relationship.
4104 This means that adding prefetch to a search() B<may alter> what is returned by
4105 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4106
4107   my $artist_rs = $schema->resultset('Artist')->search({
4108       'cds.year' => 2008,
4109   }, {
4110       join => 'cds',
4111   });
4112
4113   my $count = $artist_rs->first->cds->count;
4114
4115   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4116
4117   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4118
4119   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4120
4121 that cmp_ok() may or may not pass depending on the datasets involved. This
4122 behavior may or may not survive the 0.09 transition.
4123
4124 =back
4125
4126 =head2 page
4127
4128 =over 4
4129
4130 =item Value: $page
4131
4132 =back
4133
4134 Makes the resultset paged and specifies the page to retrieve. Effectively
4135 identical to creating a non-pages resultset and then calling ->page($page)
4136 on it.
4137
4138 If L</rows> attribute is not specified it defaults to 10 rows per page.
4139
4140 When you have a paged resultset, L</count> will only return the number
4141 of rows in the page. To get the total, use the L</pager> and call
4142 C<total_entries> on it.
4143
4144 =head2 rows
4145
4146 =over 4
4147
4148 =item Value: $rows
4149
4150 =back
4151
4152 Specifies the maximum number of rows for direct retrieval or the number of
4153 rows per page if the page attribute or method is used.
4154
4155 =head2 offset
4156
4157 =over 4
4158
4159 =item Value: $offset
4160
4161 =back
4162
4163 Specifies the (zero-based) row number for the  first row to be returned, or the
4164 of the first row of the first page if paging is used.
4165
4166 =head2 group_by
4167
4168 =over 4
4169
4170 =item Value: \@columns
4171
4172 =back
4173
4174 A arrayref of columns to group by. Can include columns of joined tables.
4175
4176   group_by => [qw/ column1 column2 ... /]
4177
4178 =head2 having
4179
4180 =over 4
4181
4182 =item Value: $condition
4183
4184 =back
4185
4186 HAVING is a select statement attribute that is applied between GROUP BY and
4187 ORDER BY. It is applied to the after the grouping calculations have been
4188 done.
4189
4190   having => { 'count_employee' => { '>=', 100 } }
4191
4192 or with an in-place function in which case literal SQL is required:
4193
4194   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4195
4196 =head2 distinct
4197
4198 =over 4
4199
4200 =item Value: (0 | 1)
4201
4202 =back
4203
4204 Set to 1 to group by all columns. If the resultset already has a group_by
4205 attribute, this setting is ignored and an appropriate warning is issued.
4206
4207 =head2 where
4208
4209 =over 4
4210
4211 Adds to the WHERE clause.
4212
4213   # only return rows WHERE deleted IS NULL for all searches
4214   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
4215
4216 Can be overridden by passing C<< { where => undef } >> as an attribute
4217 to a resultset.
4218
4219 =back
4220
4221 =head2 cache
4222
4223 Set to 1 to cache search results. This prevents extra SQL queries if you
4224 revisit rows in your ResultSet:
4225
4226   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4227
4228   while( my $artist = $resultset->next ) {
4229     ... do stuff ...
4230   }
4231
4232   $rs->first; # without cache, this would issue a query
4233
4234 By default, searches are not cached.
4235
4236 For more examples of using these attributes, see
4237 L<DBIx::Class::Manual::Cookbook>.
4238
4239 =head2 for
4240
4241 =over 4
4242
4243 =item Value: ( 'update' | 'shared' )
4244
4245 =back
4246
4247 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4248 ... FOR SHARED.
4249
4250 =cut
4251
4252 1;